lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use Moose::Util qw/find_meta/;
   6 use bytes;
   7 use Scope::Upper ();
   8 use Catalyst::Exception;
   9 use Catalyst::Log;
  10 use Catalyst::Request;
  11 use Catalyst::Request::Upload;
  12 use Catalyst::Response;
  13 use Catalyst::Utils;
  14 use Catalyst::Controller;
  15 use Devel::InnerPackage ();
  16 use File::stat;
  17 use Module::Pluggable::Object ();
  18 use Text::SimpleTable ();
  19 use Path::Class::Dir ();
  20 use Path::Class::File ();
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Tree::Simple qw/use_weak_refs/;
  25 use Tree::Simple::Visitor::FindByUID;
  26 use Class::C3::Adopt::NEXT;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp shortmess/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 has stack => (is => 'ro', default => sub { [] });
  34 has stash => (is => 'rw', default => sub { {} });
  35 has state => (is => 'rw', default => 0);
  36 has stats => (is => 'rw');
  37 has action => (is => 'rw');
  38 has counter => (is => 'rw', default => sub { {} });
  39 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  40 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  41 has namespace => (is => 'rw');
  42
  43 sub depth { scalar @{ shift->stack || [] }; }
  44 sub comp { shift->component(@_) }
  45
  46 sub req {
  47     my $self = shift; return $self->request(@_);
  48 }
  49 sub res {
  50     my $self = shift; return $self->response(@_);
  51 }
  52
  53 # For backwards compatibility
  54 sub finalize_output { shift->finalize_body(@_) };
  55
  56 # For statistics
  57 our $COUNT     = 1;
  58 our $START     = time;
  59 our $RECURSION = 1000;
  60 our $DETACH    = "catalyst_detach\n";
  61 our $GO        = "catalyst_go\n";
  62
  63 #I imagine that very few of these really need to be class variables. if any.
  64 #maybe we should just make them attributes with a default?
  65 __PACKAGE__->mk_classdata($_)
  66   for qw/components arguments dispatcher engine log dispatcher_class
  67   engine_class context_class request_class response_class stats_class
  68   setup_finished/;
  69
  70 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  71 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  72 __PACKAGE__->request_class('Catalyst::Request');
  73 __PACKAGE__->response_class('Catalyst::Response');
  74 __PACKAGE__->stats_class('Catalyst::Stats');
  75
  76 # Remember to update this in Catalyst::Runtime as well!
  77
  78 our $VERSION = '5.80002';
  79
  80 {
  81     my $dev_version = $VERSION =~ /_\d{2}$/;
  82     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  83 }
  84
  85 $VERSION = eval $VERSION;
  86
  87 sub import {
  88     my ( $class, @arguments ) = @_;
  89
  90     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  91     # callers @ISA.
  92     return unless $class eq 'Catalyst';
  93
  94     my $caller = caller();
  95     return if $caller eq 'main';
  96
  97     # Kill Adopt::NEXT warnings if we're a non-RC version
  98     unless (_IS_DEVELOPMENT_VERSION()) {
  99         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 100     }
 101
 102     my $meta = Moose::Meta::Class->initialize($caller);
 103     #Moose->import({ into => $caller }); #do we want to do this?
 104
 105     unless ( $caller->isa('Catalyst') ) {
 106         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 107         $meta->superclasses(@superclasses);
 108     }
 109     unless( $meta->has_method('meta') ){
 110         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 111     }
 112
 113     $caller->arguments( [@arguments] );
 114     $caller->setup_home;
 115 }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 =head2 -Engine
 252
 253 Forces Catalyst to use a specific engine. Omit the
 254 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 255
 256     use Catalyst qw/-Engine=CGI/;
 257
 258 =head2 -Home
 259
 260 Forces Catalyst to use a specific home directory, e.g.:
 261
 262     use Catalyst qw[-Home=/usr/mst];
 263
 264 This can also be done in the shell environment by setting either the
 265 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 266 is replaced with the uppercased name of your application, any "::" in
 267 the name will be replaced with underscores, e.g. MyApp::Web should use
 268 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 269
 270 =head2 -Log
 271
 272     use Catalyst '-Log=warn,fatal,error';
 273
 274 Specifies a comma-delimited list of log levels.
 275
 276 =head2 -Stats
 277
 278 Enables statistics collection and reporting. You can also force this setting
 279 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 280 environment settings override the application, with <MYAPP>_STATS having the
 281 highest priority.
 282
 283 e.g.
 284
 285    use Catalyst qw/-Stats=1/
 286
 287 =head1 METHODS
 288
 289 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 290
 291 =head2 $c->action
 292
 293 Returns a L<Catalyst::Action> object for the current action, which
 294 stringifies to the action name. See L<Catalyst::Action>.
 295
 296 =head2 $c->namespace
 297
 298 Returns the namespace of the current action, i.e., the URI prefix
 299 corresponding to the controller of the current action. For example:
 300
 301     # in Controller::Foo::Bar
 302     $c->namespace; # returns 'foo/bar';
 303
 304 =head2 $c->request
 305
 306 =head2 $c->req
 307
 308 Returns the current L<Catalyst::Request> object, giving access to
 309 information about the current client request (including parameters,
 310 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 311
 312 =head2 REQUEST FLOW HANDLING
 313
 314 =head2 $c->forward( $action [, \@arguments ] )
 315
 316 =head2 $c->forward( $class, $method, [, \@arguments ] )
 317
 318 Forwards processing to another action, by its private name. If you give a
 319 class name but no method, C<process()> is called. You may also optionally
 320 pass arguments in an arrayref. The action will receive the arguments in
 321 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 322 C<< $c->req->args >> will be restored to the previous values.
 323
 324 Any data C<return>ed from the action forwarded to, will be returned by the
 325 call to forward.
 326
 327     my $foodata = $c->forward('/foo');
 328     $c->forward('index');
 329     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 330     $c->forward('MyApp::View::TT');
 331
 332 Note that forward implies an C<<eval { }>> around the call (actually
 333 C<execute> does), thus de-fatalizing all 'dies' within the called
 334 action. If you want C<die> to propagate you need to do something like:
 335
 336     $c->forward('foo');
 337     die $c->error if $c->error;
 338
 339 Or make sure to always return true values from your actions and write
 340 your code like this:
 341
 342     $c->forward('foo') || return;
 343
 344 =cut
 345
 346 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 347
 348 =head2 $c->detach( $action [, \@arguments ] )
 349
 350 =head2 $c->detach( $class, $method, [, \@arguments ] )
 351
 352 =head2 $c->detach()
 353
 354 The same as C<forward>, but doesn't return to the previous action when
 355 processing is finished.
 356
 357 When called with no arguments it escapes the processing chain entirely.
 358
 359 =cut
 360
 361 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 362
 363 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 364
 365 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 366
 367 Almost the same as C<forward>, but does a full dispatch, instead of just
 368 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 369 C<auto> and the method you go to are called, just like a new request.
 370
 371 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 372 This means, for example, that $c->action methods such as C<name>, C<class> and
 373 C<reverse> return information for the visited action when they are invoked
 374 within the visited action.  This is different from the behavior of C<forward>
 375 which continues to use the $c->action object from the caller action even when
 376 invoked from the callee.
 377
 378 C<$c-E<gt>stash> is kept unchanged.
 379
 380 In effect, C<visit> allows you to "wrap" another action, just as it
 381 would have been called by dispatching from a URL, while the analogous
 382 C<go> allows you to transfer control to another action as if it had
 383 been reached directly from a URL.
 384
 385 =cut
 386
 387 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 388
 389 =head2 $c->go( $action [, \@captures, \@arguments ] )
 390
 391 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 392
 393 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 394 instead of just calling the new C<$action> /
 395 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 396 method you visit are called, just like a new request.
 397
 398 C<$c-E<gt>stash> is kept unchanged.
 399
 400 =cut
 401
 402 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 403
 404 =head2 $c->response
 405
 406 =head2 $c->res
 407
 408 Returns the current L<Catalyst::Response> object, see there for details.
 409
 410 =head2 $c->stash
 411
 412 Returns a hashref to the stash, which may be used to store data and pass
 413 it between components during a request. You can also set hash keys by
 414 passing arguments. The stash is automatically sent to the view. The
 415 stash is cleared at the end of a request; it cannot be used for
 416 persistent storage (for this you must use a session; see
 417 L<Catalyst::Plugin::Session> for a complete system integrated with
 418 Catalyst).
 419
 420     $c->stash->{foo} = $bar;
 421     $c->stash( { moose => 'majestic', qux => 0 } );
 422     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 423
 424     # stash is automatically passed to the view for use in a template
 425     $c->forward( 'MyApp::View::TT' );
 426
 427 =cut
 428
 429 around stash => sub {
 430     my $orig = shift;
 431     my $c = shift;
 432     my $stash = $orig->($c);
 433     if (@_) {
 434         my $new_stash = @_ > 1 ? {@_} : $_[0];
 435         croak('stash takes a hash or hashref') unless ref $new_stash;
 436         foreach my $key ( keys %$new_stash ) {
 437           $stash->{$key} = $new_stash->{$key};
 438         }
 439     }
 440
 441     return $stash;
 442 };
 443
 444
 445 =head2 $c->error
 446
 447 =head2 $c->error($error, ...)
 448
 449 =head2 $c->error($arrayref)
 450
 451 Returns an arrayref containing error messages.  If Catalyst encounters an
 452 error while processing a request, it stores the error in $c->error.  This
 453 method should only be used to store fatal error messages.
 454
 455     my @error = @{ $c->error };
 456
 457 Add a new error.
 458
 459     $c->error('Something bad happened');
 460
 461 =cut
 462
 463 sub error {
 464     my $c = shift;
 465     if ( $_[0] ) {
 466         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 467         croak @$error unless ref $c;
 468         push @{ $c->{error} }, @$error;
 469     }
 470     elsif ( defined $_[0] ) { $c->{error} = undef }
 471     return $c->{error} || [];
 472 }
 473
 474
 475 =head2 $c->state
 476
 477 Contains the return value of the last executed action.
 478
 479 =head2 $c->clear_errors
 480
 481 Clear errors.  You probably don't want to clear the errors unless you are
 482 implementing a custom error screen.
 483
 484 This is equivalent to running
 485
 486     $c->error(0);
 487
 488 =cut
 489
 490 sub clear_errors {
 491     my $c = shift;
 492     $c->error(0);
 493 }
 494
 495 # search components given a name and some prefixes
 496 sub _comp_search_prefixes {
 497     my ( $c, $name, @prefixes ) = @_;
 498     my $appclass = ref $c || $c;
 499     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 500     $filter = qr/$filter/; # Compile regex now rather than once per loop
 501
 502     # map the original component name to the sub part that we will search against
 503     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 504         grep { /$filter/ } keys %{ $c->components };
 505
 506     # undef for a name will return all
 507     return keys %eligible if !defined $name;
 508
 509     my $query  = ref $name ? $name : qr/^$name$/i;
 510     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 511
 512     return map { $c->components->{ $_ } } @result if @result;
 513
 514     # if we were given a regexp to search against, we're done.
 515     return if ref $name;
 516
 517     # regexp fallback
 518     $query  = qr/$name/i;
 519     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 520
 521     # no results? try against full names
 522     if( !@result ) {
 523         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 524     }
 525
 526     # don't warn if we didn't find any results, it just might not exist
 527     if( @result ) {
 528         # Disgusting hack to work out correct method name
 529         my $warn_for = lc $prefixes[0];
 530         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 531            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 532            "component resolution is unreliable and unsafe.";
 533         my $short = $result[0];
 534         $short =~ s/.*?Model:://;
 535         my $shortmess = Carp::shortmess('');
 536         if ($shortmess =~ m#Catalyst/Plugin#) {
 537            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 538               "plugin's config";
 539         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 540            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 541               "component's config";
 542         } else {
 543            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 544               "but if you really wanted to search, pass in a regexp as the argument " .
 545               "like so: \$c->${warn_for}(qr/${name}/)";
 546         }
 547         $c->log->warn( "${msg}$shortmess" );
 548     }
 549
 550     return @result;
 551 }
 552
 553 # Find possible names for a prefix
 554 sub _comp_names {
 555     my ( $c, @prefixes ) = @_;
 556     my $appclass = ref $c || $c;
 557
 558     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 559
 560     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 561     return @names;
 562 }
 563
 564 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 565 sub _filter_component {
 566     my ( $c, $comp, @args ) = @_;
 567
 568     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 569         return $comp->ACCEPT_CONTEXT( $c, @args );
 570     }
 571
 572     return $comp;
 573 }
 574
 575 =head2 COMPONENT ACCESSORS
 576
 577 =head2 $c->controller($name)
 578
 579 Gets a L<Catalyst::Controller> instance by name.
 580
 581     $c->controller('Foo')->do_stuff;
 582
 583 If the name is omitted, will return the controller for the dispatched
 584 action.
 585
 586 If you want to search for controllers, pass in a regexp as the argument.
 587
 588     # find all controllers that start with Foo
 589     my @foo_controllers = $c->controller(qr{^Foo});
 590
 591
 592 =cut
 593
 594 sub controller {
 595     my ( $c, $name, @args ) = @_;
 596
 597     if( $name ) {
 598         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 599         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 600         return $c->_filter_component( $result[ 0 ], @args );
 601     }
 602
 603     return $c->component( $c->action->class );
 604 }
 605
 606 =head2 $c->model($name)
 607
 608 Gets a L<Catalyst::Model> instance by name.
 609
 610     $c->model('Foo')->do_stuff;
 611
 612 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 613
 614 If the name is omitted, it will look for
 615  - a model object in $c->stash->{current_model_instance}, then
 616  - a model name in $c->stash->{current_model}, then
 617  - a config setting 'default_model', or
 618  - check if there is only one model, and return it if that's the case.
 619
 620 If you want to search for models, pass in a regexp as the argument.
 621
 622     # find all models that start with Foo
 623     my @foo_models = $c->model(qr{^Foo});
 624
 625 =cut
 626
 627 sub model {
 628     my ( $c, $name, @args ) = @_;
 629
 630     if( $name ) {
 631         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 632         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 633         return $c->_filter_component( $result[ 0 ], @args );
 634     }
 635
 636     if (ref $c) {
 637         return $c->stash->{current_model_instance}
 638           if $c->stash->{current_model_instance};
 639         return $c->model( $c->stash->{current_model} )
 640           if $c->stash->{current_model};
 641     }
 642     return $c->model( $c->config->{default_model} )
 643       if $c->config->{default_model};
 644
 645     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 646
 647     if( $rest ) {
 648         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 649         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 650         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 651         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 652         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 653     }
 654
 655     return $c->_filter_component( $comp );
 656 }
 657
 658
 659 =head2 $c->view($name)
 660
 661 Gets a L<Catalyst::View> instance by name.
 662
 663     $c->view('Foo')->do_stuff;
 664
 665 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 666
 667 If the name is omitted, it will look for
 668  - a view object in $c->stash->{current_view_instance}, then
 669  - a view name in $c->stash->{current_view}, then
 670  - a config setting 'default_view', or
 671  - check if there is only one view, and return it if that's the case.
 672
 673 If you want to search for views, pass in a regexp as the argument.
 674
 675     # find all views that start with Foo
 676     my @foo_views = $c->view(qr{^Foo});
 677
 678 =cut
 679
 680 sub view {
 681     my ( $c, $name, @args ) = @_;
 682
 683     if( $name ) {
 684         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 685         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 686         return $c->_filter_component( $result[ 0 ], @args );
 687     }
 688
 689     if (ref $c) {
 690         return $c->stash->{current_view_instance}
 691           if $c->stash->{current_view_instance};
 692         return $c->view( $c->stash->{current_view} )
 693           if $c->stash->{current_view};
 694     }
 695     return $c->view( $c->config->{default_view} )
 696       if $c->config->{default_view};
 697
 698     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 699
 700     if( $rest ) {
 701         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 702         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 703         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 704         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 705         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 706     }
 707
 708     return $c->_filter_component( $comp );
 709 }
 710
 711 =head2 $c->controllers
 712
 713 Returns the available names which can be passed to $c->controller
 714
 715 =cut
 716
 717 sub controllers {
 718     my ( $c ) = @_;
 719     return $c->_comp_names(qw/Controller C/);
 720 }
 721
 722 =head2 $c->models
 723
 724 Returns the available names which can be passed to $c->model
 725
 726 =cut
 727
 728 sub models {
 729     my ( $c ) = @_;
 730     return $c->_comp_names(qw/Model M/);
 731 }
 732
 733
 734 =head2 $c->views
 735
 736 Returns the available names which can be passed to $c->view
 737
 738 =cut
 739
 740 sub views {
 741     my ( $c ) = @_;
 742     return $c->_comp_names(qw/View V/);
 743 }
 744
 745 =head2 $c->comp($name)
 746
 747 =head2 $c->component($name)
 748
 749 Gets a component object by name. This method is not recommended,
 750 unless you want to get a specific component by full
 751 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 752 should be used instead.
 753
 754 If C<$name> is a regexp, a list of components matched against the full
 755 component name will be returned.
 756
 757 =cut
 758
 759 sub component {
 760     my ( $c, $name, @args ) = @_;
 761
 762     if( $name ) {
 763         my $comps = $c->components;
 764
 765         if( !ref $name ) {
 766             # is it the exact name?
 767             return $c->_filter_component( $comps->{ $name }, @args )
 768                        if exists $comps->{ $name };
 769
 770             # perhaps we just omitted "MyApp"?
 771             my $composed = ( ref $c || $c ) . "::${name}";
 772             return $c->_filter_component( $comps->{ $composed }, @args )
 773                        if exists $comps->{ $composed };
 774
 775             # search all of the models, views and controllers
 776             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 777             return $c->_filter_component( $comp, @args ) if $comp;
 778         }
 779
 780         # This is here so $c->comp( '::M::' ) works
 781         my $query = ref $name ? $name : qr{$name}i;
 782
 783         my @result = grep { m{$query} } keys %{ $c->components };
 784         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 785
 786         if( $result[ 0 ] ) {
 787             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 788             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 789             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 790             return $c->_filter_component( $result[ 0 ], @args );
 791         }
 792
 793         # I would expect to return an empty list here, but that breaks back-compat
 794     }
 795
 796     # fallback
 797     return sort keys %{ $c->components };
 798 }
 799
 800 =head2 CLASS DATA AND HELPER CLASSES
 801
 802 =head2 $c->config
 803
 804 Returns or takes a hashref containing the application's configuration.
 805
 806     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 807
 808 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 809 like myapp.conf in your applications home directory. See
 810 L<Catalyst::Plugin::ConfigLoader>.
 811
 812 =head3 Cascading configuration.
 813
 814 The config method is present on all Catalyst components, and configuration
 815 will be merged when an application is started. Configuration loaded with
 816 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 817 followed by configuration in your top level C<MyApp> class. These two
 818 configurations are merged, and then configuration data whose hash key matches a
 819 component name is merged with configuration for that component.
 820
 821 The configuration for a component is then passed to the C<new> method when a
 822 component is constructed.
 823
 824 For example:
 825
 826     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 827     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 828
 829 will mean that C<MyApp::Model::Foo> receives the following data when
 830 constructed:
 831
 832     MyApp::Model::Foo->new({
 833         bar => 'baz',
 834         quux => 'frob',
 835         overrides => 'me',
 836     });
 837
 838 =cut
 839
 840 around config => sub {
 841     my $orig = shift;
 842     my $c = shift;
 843
 844     croak('Setting config after setup has been run is not allowed.')
 845         if ( @_ and $c->setup_finished );
 846
 847     $c->$orig(@_);
 848 };
 849
 850 =head2 $c->log
 851
 852 Returns the logging object instance. Unless it is already set, Catalyst
 853 sets this up with a L<Catalyst::Log> object. To use your own log class,
 854 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 855 C<< __PACKAGE__->setup >>.
 856
 857  __PACKAGE__->log( MyLogger->new );
 858  __PACKAGE__->setup;
 859
 860 And later:
 861
 862     $c->log->info( 'Now logging with my own logger!' );
 863
 864 Your log class should implement the methods described in
 865 L<Catalyst::Log>.
 866
 867
 868 =head2 $c->debug
 869
 870 Returns 1 if debug mode is enabled, 0 otherwise.
 871
 872 You can enable debug mode in several ways:
 873
 874 =over
 875
 876 =item By calling myapp_server.pl with the -d flag
 877
 878 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 879
 880 =item The -Debug option in your MyApp.pm
 881
 882 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 883
 884 =back
 885
 886 Calling C<< $c->debug(1) >> has no effect.
 887
 888 =cut
 889
 890 sub debug { 0 }
 891
 892 =head2 $c->dispatcher
 893
 894 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 895
 896 =head2 $c->engine
 897
 898 Returns the engine instance. See L<Catalyst::Engine>.
 899
 900
 901 =head2 UTILITY METHODS
 902
 903 =head2 $c->path_to(@path)
 904
 905 Merges C<@path> with C<< $c->config->{home} >> and returns a
 906 L<Path::Class::Dir> object.
 907
 908 For example:
 909
 910     $c->path_to( 'db', 'sqlite.db' );
 911
 912 =cut
 913
 914 sub path_to {
 915     my ( $c, @path ) = @_;
 916     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 917     if ( -d $path ) { return $path }
 918     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 919 }
 920
 921 =head2 $c->plugin( $name, $class, @args )
 922
 923 Helper method for plugins. It creates a class data accessor/mutator and
 924 loads and instantiates the given class.
 925
 926     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 927
 928     $c->prototype->define_javascript_functions;
 929
 930 B<Note:> This method of adding plugins is deprecated. The ability
 931 to add plugins like this B<will be removed> in a Catalyst 5.81.
 932 Please do not use this functionality in new code.
 933
 934 =cut
 935
 936 sub plugin {
 937     my ( $class, $name, $plugin, @args ) = @_;
 938
 939     # See block comment in t/unit_core_plugin.t
 940     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 941
 942     $class->_register_plugin( $plugin, 1 );
 943
 944     eval { $plugin->import };
 945     $class->mk_classdata($name);
 946     my $obj;
 947     eval { $obj = $plugin->new(@args) };
 948
 949     if ($@) {
 950         Catalyst::Exception->throw( message =>
 951               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 952     }
 953
 954     $class->$name($obj);
 955     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 956       if $class->debug;
 957 }
 958
 959 =head2 MyApp->setup
 960
 961 Initializes the dispatcher and engine, loads any plugins, and loads the
 962 model, view, and controller components. You may also specify an array
 963 of plugins to load here, if you choose to not load them in the C<use
 964 Catalyst> line.
 965
 966     MyApp->setup;
 967     MyApp->setup( qw/-Debug/ );
 968
 969 =cut
 970
 971 sub setup {
 972     my ( $class, @arguments ) = @_;
 973     croak('Running setup more than once')
 974         if ( $class->setup_finished );
 975
 976     unless ( $class->isa('Catalyst') ) {
 977
 978         Catalyst::Exception->throw(
 979             message => qq/'$class' does not inherit from Catalyst/ );
 980     }
 981
 982     if ( $class->arguments ) {
 983         @arguments = ( @arguments, @{ $class->arguments } );
 984     }
 985
 986     # Process options
 987     my $flags = {};
 988
 989     foreach (@arguments) {
 990
 991         if (/^-Debug$/) {
 992             $flags->{log} =
 993               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 994         }
 995         elsif (/^-(\w+)=?(.*)$/) {
 996             $flags->{ lc $1 } = $2;
 997         }
 998         else {
 999             push @{ $flags->{plugins} }, $_;
1000         }
1001     }
1002
1003     $class->setup_home( delete $flags->{home} );
1004
1005     $class->setup_log( delete $flags->{log} );
1006     $class->setup_plugins( delete $flags->{plugins} );
1007     $class->setup_dispatcher( delete $flags->{dispatcher} );
1008     $class->setup_engine( delete $flags->{engine} );
1009     $class->setup_stats( delete $flags->{stats} );
1010
1011     for my $flag ( sort keys %{$flags} ) {
1012
1013         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1014             &$code( $class, delete $flags->{$flag} );
1015         }
1016         else {
1017             $class->log->warn(qq/Unknown flag "$flag"/);
1018         }
1019     }
1020
1021     eval { require Catalyst::Devel; };
1022     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1023         $class->log->warn(<<"EOF");
1024 You are running an old script!
1025
1026   Please update by running (this will overwrite existing files):
1027     catalyst.pl -force -scripts $class
1028
1029   or (this will not overwrite existing files):
1030     catalyst.pl -scripts $class
1031
1032 EOF
1033     }
1034
1035     if ( $class->debug ) {
1036         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1037
1038         if (@plugins) {
1039             my $column_width = Catalyst::Utils::term_width() - 6;
1040             my $t = Text::SimpleTable->new($column_width);
1041             $t->row($_) for @plugins;
1042             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1043         }
1044
1045         my $dispatcher = $class->dispatcher;
1046         my $engine     = $class->engine;
1047         my $home       = $class->config->{home};
1048
1049         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1050         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1051
1052         $home
1053           ? ( -d $home )
1054           ? $class->log->debug(qq/Found home "$home"/)
1055           : $class->log->debug(qq/Home "$home" doesn't exist/)
1056           : $class->log->debug(q/Couldn't find home/);
1057     }
1058
1059     # Call plugins setup, this is stupid and evil.
1060     # Also screws C3 badly on 5.10, hack to avoid.
1061     {
1062         no warnings qw/redefine/;
1063         local *setup = sub { };
1064         $class->setup unless $Catalyst::__AM_RESTARTING;
1065     }
1066
1067     # Initialize our data structure
1068     $class->components( {} );
1069
1070     $class->setup_components;
1071
1072     if ( $class->debug ) {
1073         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1074         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1075         for my $comp ( sort keys %{ $class->components } ) {
1076             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1077             $t->row( $comp, $type );
1078         }
1079         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1080           if ( keys %{ $class->components } );
1081     }
1082
1083     # Add our self to components, since we are also a component
1084     if( $class->isa('Catalyst::Controller') ){
1085       $class->components->{$class} = $class;
1086     }
1087
1088     $class->setup_actions;
1089
1090     if ( $class->debug ) {
1091         my $name = $class->config->{name} || 'Application';
1092         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1093     }
1094     $class->log->_flush() if $class->log->can('_flush');
1095
1096     # Make sure that the application class becomes immutable at this point,
1097     # which ensures that it gets an inlined constructor. This means that it
1098     # works even if the user has added a plugin which contains a new method.
1099     # Note however that we have to do the work on scope end, so that method
1100     # modifiers work correctly in MyApp (as you have to call setup _before_
1101     # applying modifiers).
1102     Scope::Upper::reap(sub {
1103         my $meta = Class::MOP::get_metaclass_by_name($class);
1104         $meta->make_immutable(replace_constructor => 1) unless $meta->is_immutable;
1105     }, Scope::Upper::SCOPE(1));
1106
1107     $class->setup_finalize;
1108 }
1109
1110
1111 =head2 $app->setup_finalize
1112
1113 A hook to attach modifiers to.
1114 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1115 Also better than C< setup_finished(); >, as that is a getter method.
1116
1117     sub setup_finalize {
1118
1119         my $app = shift;
1120
1121         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1122
1123         $app->next::method(@_);
1124
1125
1126     }
1127
1128 =cut
1129
1130 sub setup_finalize {
1131     my ($class) = @_;
1132     $class->setup_finished(1);
1133 }
1134
1135 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1136
1137 =head2 $c->uri_for( $path, @args?, \%query_values? )
1138
1139 =over
1140
1141 =item $action
1142
1143 A Catalyst::Action object representing the Catalyst action you want to
1144 create a URI for. To get one for an action in the current controller,
1145 use C<< $c->action('someactionname') >>. To get one from different
1146 controller, fetch the controller using C<< $c->controller() >>, then
1147 call C<action_for> on it.
1148
1149 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1150 using C<< $c->req->captures >>.
1151
1152   # For the current action
1153   $c->uri_for($c->action, $c->req->captures);
1154
1155   # For the Foo action in the Bar controller
1156   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1157
1158 =back
1159
1160 =cut
1161
1162 sub uri_for {
1163     my ( $c, $path, @args ) = @_;
1164
1165     if ( blessed($path) ) { # action object
1166         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1167                          ? shift(@args)
1168                          : [] );
1169         my $action = $path;
1170         $path = $c->dispatcher->uri_for_action($action, $captures);
1171         if (not defined $path) {
1172             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1173                 if $c->debug;
1174             return undef;
1175         }
1176         $path = '/' if $path eq '';
1177     }
1178
1179     undef($path) if (defined $path && $path eq '');
1180
1181     my $params =
1182       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1183
1184     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1185     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1186
1187     unshift(@args, $path);
1188
1189     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1190         my $namespace = $c->namespace;
1191         if (defined $path) { # cheesy hack to handle path '../foo'
1192            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1193         }
1194         unshift(@args, $namespace || '');
1195     }
1196
1197     # join args with '/', or a blank string
1198     my $args = join('/', grep { defined($_) } @args);
1199     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1200     $args =~ s!^/+!!;
1201     my $base = $c->req->base;
1202     my $class = ref($base);
1203     $base =~ s{(?<!/)$}{/};
1204
1205     my $query = '';
1206
1207     if (my @keys = keys %$params) {
1208       # somewhat lifted from URI::_query's query_form
1209       $query = '?'.join('&', map {
1210           my $val = $params->{$_};
1211           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1212           s/ /+/g;
1213           my $key = $_;
1214           $val = '' unless defined $val;
1215           (map {
1216               $_ = "$_";
1217               utf8::encode( $_ ) if utf8::is_utf8($_);
1218               # using the URI::Escape pattern here so utf8 chars survive
1219               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1220               s/ /+/g;
1221               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1222       } @keys);
1223     }
1224
1225     my $res = bless(\"${base}${args}${query}", $class);
1226     $res;
1227 }
1228
1229 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1230
1231 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1232
1233 =over
1234
1235 =item $path
1236
1237 A private path to the Catalyst action you want to create a URI for.
1238
1239 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1240 >> and passing the resulting C<$action> and the remaining arguments to C<<
1241 $c->uri_for >>.
1242
1243 You can also pass in a Catalyst::Action object, in which case it is passed to
1244 C<< $c->uri_for >>.
1245
1246 =back
1247
1248 =cut
1249
1250 sub uri_for_action {
1251     my ( $c, $path, @args ) = @_;
1252     my $action = blessed($path)
1253       ? $path
1254       : $c->dispatcher->get_action_by_path($path);
1255     unless (defined $action) {
1256       croak "Can't find action for path '$path'";
1257     }
1258     return $c->uri_for( $action, @args );
1259 }
1260
1261 =head2 $c->welcome_message
1262
1263 Returns the Catalyst welcome HTML page.
1264
1265 =cut
1266
1267 sub welcome_message {
1268     my $c      = shift;
1269     my $name   = $c->config->{name};
1270     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1271     my $prefix = Catalyst::Utils::appprefix( ref $c );
1272     $c->response->content_type('text/html; charset=utf-8');
1273     return <<"EOF";
1274 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1275     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1276 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1277     <head>
1278     <meta http-equiv="Content-Language" content="en" />
1279     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1280         <title>$name on Catalyst $VERSION</title>
1281         <style type="text/css">
1282             body {
1283                 color: #000;
1284                 background-color: #eee;
1285             }
1286             div#content {
1287                 width: 640px;
1288                 margin-left: auto;
1289                 margin-right: auto;
1290                 margin-top: 10px;
1291                 margin-bottom: 10px;
1292                 text-align: left;
1293                 background-color: #ccc;
1294                 border: 1px solid #aaa;
1295             }
1296             p, h1, h2 {
1297                 margin-left: 20px;
1298                 margin-right: 20px;
1299                 font-family: verdana, tahoma, sans-serif;
1300             }
1301             a {
1302                 font-family: verdana, tahoma, sans-serif;
1303             }
1304             :link, :visited {
1305                     text-decoration: none;
1306                     color: #b00;
1307                     border-bottom: 1px dotted #bbb;
1308             }
1309             :link:hover, :visited:hover {
1310                     color: #555;
1311             }
1312             div#topbar {
1313                 margin: 0px;
1314             }
1315             pre {
1316                 margin: 10px;
1317                 padding: 8px;
1318             }
1319             div#answers {
1320                 padding: 8px;
1321                 margin: 10px;
1322                 background-color: #fff;
1323                 border: 1px solid #aaa;
1324             }
1325             h1 {
1326                 font-size: 0.9em;
1327                 font-weight: normal;
1328                 text-align: center;
1329             }
1330             h2 {
1331                 font-size: 1.0em;
1332             }
1333             p {
1334                 font-size: 0.9em;
1335             }
1336             p img {
1337                 float: right;
1338                 margin-left: 10px;
1339             }
1340             span#appname {
1341                 font-weight: bold;
1342                 font-size: 1.6em;
1343             }
1344         </style>
1345     </head>
1346     <body>
1347         <div id="content">
1348             <div id="topbar">
1349                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1350                     $VERSION</h1>
1351              </div>
1352              <div id="answers">
1353                  <p>
1354                  <img src="$logo" alt="Catalyst Logo" />
1355                  </p>
1356                  <p>Welcome to the  world of Catalyst.
1357                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1358                     framework will make web development something you had
1359                     never expected it to be: Fun, rewarding, and quick.</p>
1360                  <h2>What to do now?</h2>
1361                  <p>That really depends  on what <b>you</b> want to do.
1362                     We do, however, provide you with a few starting points.</p>
1363                  <p>If you want to jump right into web development with Catalyst
1364                     you might want to start with a tutorial.</p>
1365 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1366 </pre>
1367 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1368 <pre>
1369 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1370 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1371 </code></pre>
1372                  <h2>What to do next?</h2>
1373                  <p>Next it's time to write an actual application. Use the
1374                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1375                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1376                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1377                     they can save you a lot of work.</p>
1378                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1379                     <p>Also, be sure to check out the vast and growing
1380                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1381                     you are likely to find what you need there.
1382                     </p>
1383
1384                  <h2>Need help?</h2>
1385                  <p>Catalyst has a very active community. Here are the main places to
1386                     get in touch with us.</p>
1387                  <ul>
1388                      <li>
1389                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1390                      </li>
1391                      <li>
1392                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1393                      </li>
1394                      <li>
1395                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1396                      </li>
1397                  </ul>
1398                  <h2>In conclusion</h2>
1399                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1400                     as we enjoyed making it. Please contact us if you have ideas
1401                     for improvement or other feedback.</p>
1402              </div>
1403          </div>
1404     </body>
1405 </html>
1406 EOF
1407 }
1408
1409 =head1 INTERNAL METHODS
1410
1411 These methods are not meant to be used by end users.
1412
1413 =head2 $c->components
1414
1415 Returns a hash of components.
1416
1417 =head2 $c->context_class
1418
1419 Returns or sets the context class.
1420
1421 =head2 $c->counter
1422
1423 Returns a hashref containing coderefs and execution counts (needed for
1424 deep recursion detection).
1425
1426 =head2 $c->depth
1427
1428 Returns the number of actions on the current internal execution stack.
1429
1430 =head2 $c->dispatch
1431
1432 Dispatches a request to actions.
1433
1434 =cut
1435
1436 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1437
1438 =head2 $c->dispatcher_class
1439
1440 Returns or sets the dispatcher class.
1441
1442 =head2 $c->dump_these
1443
1444 Returns a list of 2-element array references (name, structure) pairs
1445 that will be dumped on the error page in debug mode.
1446
1447 =cut
1448
1449 sub dump_these {
1450     my $c = shift;
1451     [ Request => $c->req ],
1452     [ Response => $c->res ],
1453     [ Stash => $c->stash ],
1454     [ Config => $c->config ];
1455 }
1456
1457 =head2 $c->engine_class
1458
1459 Returns or sets the engine class.
1460
1461 =head2 $c->execute( $class, $coderef )
1462
1463 Execute a coderef in given class and catch exceptions. Errors are available
1464 via $c->error.
1465
1466 =cut
1467
1468 sub execute {
1469     my ( $c, $class, $code ) = @_;
1470     $class = $c->component($class) || $class;
1471     $c->state(0);
1472
1473     if ( $c->depth >= $RECURSION ) {
1474         my $action = $code->reverse();
1475         $action = "/$action" unless $action =~ /->/;
1476         my $error = qq/Deep recursion detected calling "${action}"/;
1477         $c->log->error($error);
1478         $c->error($error);
1479         $c->state(0);
1480         return $c->state;
1481     }
1482
1483     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1484
1485     push( @{ $c->stack }, $code );
1486
1487     no warnings 'recursion';
1488     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1489
1490     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1491
1492     my $last = pop( @{ $c->stack } );
1493
1494     if ( my $error = $@ ) {
1495         if ( !ref($error) and $error eq $DETACH ) {
1496             die $DETACH if($c->depth > 1);
1497         }
1498         elsif ( !ref($error) and $error eq $GO ) {
1499             die $GO if($c->depth > 0);
1500         }
1501         else {
1502             unless ( ref $error ) {
1503                 no warnings 'uninitialized';
1504                 chomp $error;
1505                 my $class = $last->class;
1506                 my $name  = $last->name;
1507                 $error = qq/Caught exception in $class->$name "$error"/;
1508             }
1509             $c->error($error);
1510             $c->state(0);
1511         }
1512     }
1513     return $c->state;
1514 }
1515
1516 sub _stats_start_execute {
1517     my ( $c, $code ) = @_;
1518
1519     return if ( ( $code->name =~ /^_.*/ )
1520         && ( !$c->config->{show_internal_actions} ) );
1521
1522     my $action_name = $code->reverse();
1523     $c->counter->{$action_name}++;
1524
1525     my $action = $action_name;
1526     $action = "/$action" unless $action =~ /->/;
1527
1528     # determine if the call was the result of a forward
1529     # this is done by walking up the call stack and looking for a calling
1530     # sub of Catalyst::forward before the eval
1531     my $callsub = q{};
1532     for my $index ( 2 .. 11 ) {
1533         last
1534         if ( ( caller($index) )[0] eq 'Catalyst'
1535             && ( caller($index) )[3] eq '(eval)' );
1536
1537         if ( ( caller($index) )[3] =~ /forward$/ ) {
1538             $callsub = ( caller($index) )[3];
1539             $action  = "-> $action";
1540             last;
1541         }
1542     }
1543
1544     my $uid = $action_name . $c->counter->{$action_name};
1545
1546     # is this a root-level call or a forwarded call?
1547     if ( $callsub =~ /forward$/ ) {
1548
1549         # forward, locate the caller
1550         if ( my $parent = $c->stack->[-1] ) {
1551             $c->stats->profile(
1552                 begin  => $action,
1553                 parent => "$parent" . $c->counter->{"$parent"},
1554                 uid    => $uid,
1555             );
1556         }
1557         else {
1558
1559             # forward with no caller may come from a plugin
1560             $c->stats->profile(
1561                 begin => $action,
1562                 uid   => $uid,
1563             );
1564         }
1565     }
1566     else {
1567
1568         # root-level call
1569         $c->stats->profile(
1570             begin => $action,
1571             uid   => $uid,
1572         );
1573     }
1574     return $action;
1575
1576 }
1577
1578 sub _stats_finish_execute {
1579     my ( $c, $info ) = @_;
1580     $c->stats->profile( end => $info );
1581 }
1582
1583 =head2 $c->_localize_fields( sub { }, \%keys );
1584
1585 =cut
1586
1587 #Why does this exist? This is no longer safe and WILL NOT WORK.
1588 # it doesnt seem to be used anywhere. can we remove it?
1589 sub _localize_fields {
1590     my ( $c, $localized, $code ) = ( @_ );
1591
1592     my $request = delete $localized->{request} || {};
1593     my $response = delete $localized->{response} || {};
1594
1595     local @{ $c }{ keys %$localized } = values %$localized;
1596     local @{ $c->request }{ keys %$request } = values %$request;
1597     local @{ $c->response }{ keys %$response } = values %$response;
1598
1599     $code->();
1600 }
1601
1602 =head2 $c->finalize
1603
1604 Finalizes the request.
1605
1606 =cut
1607
1608 sub finalize {
1609     my $c = shift;
1610
1611     for my $error ( @{ $c->error } ) {
1612         $c->log->error($error);
1613     }
1614
1615     # Allow engine to handle finalize flow (for POE)
1616     my $engine = $c->engine;
1617     if ( my $code = $engine->can('finalize') ) {
1618         $engine->$code($c);
1619     }
1620     else {
1621
1622         $c->finalize_uploads;
1623
1624         # Error
1625         if ( $#{ $c->error } >= 0 ) {
1626             $c->finalize_error;
1627         }
1628
1629         $c->finalize_headers;
1630
1631         # HEAD request
1632         if ( $c->request->method eq 'HEAD' ) {
1633             $c->response->body('');
1634         }
1635
1636         $c->finalize_body;
1637     }
1638
1639     if ($c->use_stats) {
1640         my $elapsed = sprintf '%f', $c->stats->elapsed;
1641         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1642         $c->log->info(
1643             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1644     }
1645
1646     return $c->response->status;
1647 }
1648
1649 =head2 $c->finalize_body
1650
1651 Finalizes body.
1652
1653 =cut
1654
1655 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1656
1657 =head2 $c->finalize_cookies
1658
1659 Finalizes cookies.
1660
1661 =cut
1662
1663 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1664
1665 =head2 $c->finalize_error
1666
1667 Finalizes error.
1668
1669 =cut
1670
1671 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1672
1673 =head2 $c->finalize_headers
1674
1675 Finalizes headers.
1676
1677 =cut
1678
1679 sub finalize_headers {
1680     my $c = shift;
1681
1682     my $response = $c->response; #accessor calls can add up?
1683
1684     # Check if we already finalized headers
1685     return if $response->finalized_headers;
1686
1687     # Handle redirects
1688     if ( my $location = $response->redirect ) {
1689         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1690         $response->header( Location => $location );
1691
1692         if ( !$response->has_body ) {
1693             # Add a default body if none is already present
1694             $response->body(
1695                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1696             );
1697         }
1698     }
1699
1700     # Content-Length
1701     if ( $response->body && !$response->content_length ) {
1702
1703         # get the length from a filehandle
1704         if ( blessed( $response->body ) && $response->body->can('read') )
1705         {
1706             my $stat = stat $response->body;
1707             if ( $stat && $stat->size > 0 ) {
1708                 $response->content_length( $stat->size );
1709             }
1710             else {
1711                 $c->log->warn('Serving filehandle without a content-length');
1712             }
1713         }
1714         else {
1715             # everything should be bytes at this point, but just in case
1716             $response->content_length( bytes::length( $response->body ) );
1717         }
1718     }
1719
1720     # Errors
1721     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1722         $response->headers->remove_header("Content-Length");
1723         $response->body('');
1724     }
1725
1726     $c->finalize_cookies;
1727
1728     $c->engine->finalize_headers( $c, @_ );
1729
1730     # Done
1731     $response->finalized_headers(1);
1732 }
1733
1734 =head2 $c->finalize_output
1735
1736 An alias for finalize_body.
1737
1738 =head2 $c->finalize_read
1739
1740 Finalizes the input after reading is complete.
1741
1742 =cut
1743
1744 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1745
1746 =head2 $c->finalize_uploads
1747
1748 Finalizes uploads. Cleans up any temporary files.
1749
1750 =cut
1751
1752 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1753
1754 =head2 $c->get_action( $action, $namespace )
1755
1756 Gets an action in a given namespace.
1757
1758 =cut
1759
1760 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1761
1762 =head2 $c->get_actions( $action, $namespace )
1763
1764 Gets all actions of a given name in a namespace and all parent
1765 namespaces.
1766
1767 =cut
1768
1769 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1770
1771 =head2 $c->handle_request( $class, @arguments )
1772
1773 Called to handle each HTTP request.
1774
1775 =cut
1776
1777 sub handle_request {
1778     my ( $class, @arguments ) = @_;
1779
1780     # Always expect worst case!
1781     my $status = -1;
1782     eval {
1783         if ($class->debug) {
1784             my $secs = time - $START || 1;
1785             my $av = sprintf '%.3f', $COUNT / $secs;
1786             my $time = localtime time;
1787             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1788         }
1789
1790         my $c = $class->prepare(@arguments);
1791         $c->dispatch;
1792         $status = $c->finalize;
1793     };
1794
1795     if ( my $error = $@ ) {
1796         chomp $error;
1797         $class->log->error(qq/Caught exception in engine "$error"/);
1798     }
1799
1800     $COUNT++;
1801
1802     if(my $coderef = $class->log->can('_flush')){
1803         $class->log->$coderef();
1804     }
1805     return $status;
1806 }
1807
1808 =head2 $c->prepare( @arguments )
1809
1810 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1811 etc.).
1812
1813 =cut
1814
1815 sub prepare {
1816     my ( $class, @arguments ) = @_;
1817
1818     # XXX
1819     # After the app/ctxt split, this should become an attribute based on something passed
1820     # into the application.
1821     $class->context_class( ref $class || $class ) unless $class->context_class;
1822
1823     my $c = $class->context_class->new({});
1824
1825     # For on-demand data
1826     $c->request->_context($c);
1827     $c->response->_context($c);
1828
1829     #surely this is not the most efficient way to do things...
1830     $c->stats($class->stats_class->new)->enable($c->use_stats);
1831     if ( $c->debug ) {
1832         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1833     }
1834
1835     #XXX reuse coderef from can
1836     # Allow engine to direct the prepare flow (for POE)
1837     if ( $c->engine->can('prepare') ) {
1838         $c->engine->prepare( $c, @arguments );
1839     }
1840     else {
1841         $c->prepare_request(@arguments);
1842         $c->prepare_connection;
1843         $c->prepare_query_parameters;
1844         $c->prepare_headers;
1845         $c->prepare_cookies;
1846         $c->prepare_path;
1847
1848         # Prepare the body for reading, either by prepare_body
1849         # or the user, if they are using $c->read
1850         $c->prepare_read;
1851
1852         # Parse the body unless the user wants it on-demand
1853         unless ( $c->config->{parse_on_demand} ) {
1854             $c->prepare_body;
1855         }
1856     }
1857
1858     my $method  = $c->req->method  || '';
1859     my $path    = $c->req->path;
1860     $path       = '/' unless length $path;
1861     my $address = $c->req->address || '';
1862
1863     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1864       if $c->debug;
1865
1866     $c->prepare_action;
1867
1868     return $c;
1869 }
1870
1871 =head2 $c->prepare_action
1872
1873 Prepares action. See L<Catalyst::Dispatcher>.
1874
1875 =cut
1876
1877 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1878
1879 =head2 $c->prepare_body
1880
1881 Prepares message body.
1882
1883 =cut
1884
1885 sub prepare_body {
1886     my $c = shift;
1887
1888     return if $c->request->_has_body;
1889
1890     # Initialize on-demand data
1891     $c->engine->prepare_body( $c, @_ );
1892     $c->prepare_parameters;
1893     $c->prepare_uploads;
1894
1895     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1896         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1897         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1898             my $param = $c->req->body_parameters->{$key};
1899             my $value = defined($param) ? $param : '';
1900             $t->row( $key,
1901                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1902         }
1903         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1904     }
1905 }
1906
1907 =head2 $c->prepare_body_chunk( $chunk )
1908
1909 Prepares a chunk of data before sending it to L<HTTP::Body>.
1910
1911 See L<Catalyst::Engine>.
1912
1913 =cut
1914
1915 sub prepare_body_chunk {
1916     my $c = shift;
1917     $c->engine->prepare_body_chunk( $c, @_ );
1918 }
1919
1920 =head2 $c->prepare_body_parameters
1921
1922 Prepares body parameters.
1923
1924 =cut
1925
1926 sub prepare_body_parameters {
1927     my $c = shift;
1928     $c->engine->prepare_body_parameters( $c, @_ );
1929 }
1930
1931 =head2 $c->prepare_connection
1932
1933 Prepares connection.
1934
1935 =cut
1936
1937 sub prepare_connection {
1938     my $c = shift;
1939     $c->engine->prepare_connection( $c, @_ );
1940 }
1941
1942 =head2 $c->prepare_cookies
1943
1944 Prepares cookies.
1945
1946 =cut
1947
1948 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1949
1950 =head2 $c->prepare_headers
1951
1952 Prepares headers.
1953
1954 =cut
1955
1956 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1957
1958 =head2 $c->prepare_parameters
1959
1960 Prepares parameters.
1961
1962 =cut
1963
1964 sub prepare_parameters {
1965     my $c = shift;
1966     $c->prepare_body_parameters;
1967     $c->engine->prepare_parameters( $c, @_ );
1968 }
1969
1970 =head2 $c->prepare_path
1971
1972 Prepares path and base.
1973
1974 =cut
1975
1976 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1977
1978 =head2 $c->prepare_query_parameters
1979
1980 Prepares query parameters.
1981
1982 =cut
1983
1984 sub prepare_query_parameters {
1985     my $c = shift;
1986
1987     $c->engine->prepare_query_parameters( $c, @_ );
1988
1989     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1990         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1991         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1992             my $param = $c->req->query_parameters->{$key};
1993             my $value = defined($param) ? $param : '';
1994             $t->row( $key,
1995                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1996         }
1997         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1998     }
1999 }
2000
2001 =head2 $c->prepare_read
2002
2003 Prepares the input for reading.
2004
2005 =cut
2006
2007 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2008
2009 =head2 $c->prepare_request
2010
2011 Prepares the engine request.
2012
2013 =cut
2014
2015 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2016
2017 =head2 $c->prepare_uploads
2018
2019 Prepares uploads.
2020
2021 =cut
2022
2023 sub prepare_uploads {
2024     my $c = shift;
2025
2026     $c->engine->prepare_uploads( $c, @_ );
2027
2028     if ( $c->debug && keys %{ $c->request->uploads } ) {
2029         my $t = Text::SimpleTable->new(
2030             [ 12, 'Parameter' ],
2031             [ 26, 'Filename' ],
2032             [ 18, 'Type' ],
2033             [ 9,  'Size' ]
2034         );
2035         for my $key ( sort keys %{ $c->request->uploads } ) {
2036             my $upload = $c->request->uploads->{$key};
2037             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2038                 $t->row( $key, $u->filename, $u->type, $u->size );
2039             }
2040         }
2041         $c->log->debug( "File Uploads are:\n" . $t->draw );
2042     }
2043 }
2044
2045 =head2 $c->prepare_write
2046
2047 Prepares the output for writing.
2048
2049 =cut
2050
2051 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2052
2053 =head2 $c->request_class
2054
2055 Returns or sets the request class.
2056
2057 =head2 $c->response_class
2058
2059 Returns or sets the response class.
2060
2061 =head2 $c->read( [$maxlength] )
2062
2063 Reads a chunk of data from the request body. This method is designed to
2064 be used in a while loop, reading C<$maxlength> bytes on every call.
2065 C<$maxlength> defaults to the size of the request if not specified.
2066
2067 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
2068 directly.
2069
2070 Warning: If you use read(), Catalyst will not process the body,
2071 so you will not be able to access POST parameters or file uploads via
2072 $c->request.  You must handle all body parsing yourself.
2073
2074 =cut
2075
2076 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2077
2078 =head2 $c->run
2079
2080 Starts the engine.
2081
2082 =cut
2083
2084 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2085
2086 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2087
2088 Sets an action in a given namespace.
2089
2090 =cut
2091
2092 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2093
2094 =head2 $c->setup_actions($component)
2095
2096 Sets up actions for a component.
2097
2098 =cut
2099
2100 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2101
2102 =head2 $c->setup_components
2103
2104 Sets up components. Specify a C<setup_components> config option to pass
2105 additional options directly to L<Module::Pluggable>. To add additional
2106 search paths, specify a key named C<search_extra> as an array
2107 reference. Items in the array beginning with C<::> will have the
2108 application class name prepended to them.
2109
2110 All components found will also have any
2111 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2112 Note, that modules which are B<not> an I<inner package> of the main
2113 file namespace loaded will not be instantiated as components.
2114
2115 =cut
2116
2117 sub setup_components {
2118     my $class = shift;
2119
2120     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2121     my $config  = $class->config->{ setup_components };
2122     my $extra   = delete $config->{ search_extra } || [];
2123
2124     push @paths, @$extra;
2125
2126     my $locator = Module::Pluggable::Object->new(
2127         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2128         %$config
2129     );
2130
2131     my @comps = sort { length $a <=> length $b } $locator->plugins;
2132     my %comps = map { $_ => 1 } @comps;
2133
2134     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2135     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2136         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2137     ) if $deprecated_component_names;
2138
2139     for my $component ( @comps ) {
2140
2141         # We pass ignore_loaded here so that overlay files for (e.g.)
2142         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2143         # we know M::P::O found a file on disk so this is safe
2144
2145         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2146         #Class::MOP::load_class($component);
2147
2148         my $module  = $class->setup_component( $component );
2149         my %modules = (
2150             $component => $module,
2151             map {
2152                 $_ => $class->setup_component( $_ )
2153             } grep {
2154               not exists $comps{$_}
2155             } Devel::InnerPackage::list_packages( $component )
2156         );
2157
2158         for my $key ( keys %modules ) {
2159             $class->components->{ $key } = $modules{ $key };
2160         }
2161     }
2162 }
2163
2164 =head2 $c->setup_component
2165
2166 =cut
2167
2168 sub _controller_init_base_classes {
2169     my ($app_class, $component) = @_;
2170     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2171         Moose->init_meta( for_class => $class )
2172             unless find_meta($class);
2173     }
2174 }
2175
2176 sub setup_component {
2177     my( $class, $component ) = @_;
2178
2179     unless ( $component->can( 'COMPONENT' ) ) {
2180         return $component;
2181     }
2182
2183     # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2184     #         nearest to Catalyst::Controller first, no matter what order stuff happens
2185     #         to be loaded. There are TODO tests in Moose for this, see
2186     #         f2391d17574eff81d911b97be15ea51080500003
2187     if ($component->isa('Catalyst::Controller')) {
2188         $class->_controller_init_base_classes($component);
2189     }
2190
2191     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2192     my $config = $class->config->{ $suffix } || {};
2193
2194     my $instance = eval { $component->COMPONENT( $class, $config ); };
2195
2196     if ( my $error = $@ ) {
2197         chomp $error;
2198         Catalyst::Exception->throw(
2199             message => qq/Couldn't instantiate component "$component", "$error"/
2200         );
2201     }
2202
2203     unless (blessed $instance) {
2204         my $metaclass = Moose::Util::find_meta($component);
2205         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2206         my $component_method_from = $method_meta->associated_metaclass->name;
2207         my $value = defined($instance) ? $instance : 'undef';
2208         Catalyst::Exception->throw(
2209             message =>
2210             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2211         );
2212     }
2213     return $instance;
2214 }
2215
2216 =head2 $c->setup_dispatcher
2217
2218 Sets up dispatcher.
2219
2220 =cut
2221
2222 sub setup_dispatcher {
2223     my ( $class, $dispatcher ) = @_;
2224
2225     if ($dispatcher) {
2226         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2227     }
2228
2229     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2230         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2231     }
2232
2233     unless ($dispatcher) {
2234         $dispatcher = $class->dispatcher_class;
2235     }
2236
2237     Class::MOP::load_class($dispatcher);
2238
2239     # dispatcher instance
2240     $class->dispatcher( $dispatcher->new );
2241 }
2242
2243 =head2 $c->setup_engine
2244
2245 Sets up engine.
2246
2247 =cut
2248
2249 sub setup_engine {
2250     my ( $class, $engine ) = @_;
2251
2252     if ($engine) {
2253         $engine = 'Catalyst::Engine::' . $engine;
2254     }
2255
2256     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2257         $engine = 'Catalyst::Engine::' . $env;
2258     }
2259
2260     if ( $ENV{MOD_PERL} ) {
2261         my $meta = Class::MOP::get_metaclass_by_name($class);
2262
2263         # create the apache method
2264         $meta->add_method('apache' => sub { shift->engine->apache });
2265
2266         my ( $software, $version ) =
2267           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2268
2269         $version =~ s/_//g;
2270         $version =~ s/(\.[^.]+)\./$1/g;
2271
2272         if ( $software eq 'mod_perl' ) {
2273
2274             if ( !$engine ) {
2275
2276                 if ( $version >= 1.99922 ) {
2277                     $engine = 'Catalyst::Engine::Apache2::MP20';
2278                 }
2279
2280                 elsif ( $version >= 1.9901 ) {
2281                     $engine = 'Catalyst::Engine::Apache2::MP19';
2282                 }
2283
2284                 elsif ( $version >= 1.24 ) {
2285                     $engine = 'Catalyst::Engine::Apache::MP13';
2286                 }
2287
2288                 else {
2289                     Catalyst::Exception->throw( message =>
2290                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2291                 }
2292
2293             }
2294
2295             # install the correct mod_perl handler
2296             if ( $version >= 1.9901 ) {
2297                 *handler = sub  : method {
2298                     shift->handle_request(@_);
2299                 };
2300             }
2301             else {
2302                 *handler = sub ($$) { shift->handle_request(@_) };
2303             }
2304
2305         }
2306
2307         elsif ( $software eq 'Zeus-Perl' ) {
2308             $engine = 'Catalyst::Engine::Zeus';
2309         }
2310
2311         else {
2312             Catalyst::Exception->throw(
2313                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2314         }
2315     }
2316
2317     unless ($engine) {
2318         $engine = $class->engine_class;
2319     }
2320
2321     Class::MOP::load_class($engine);
2322
2323     # check for old engines that are no longer compatible
2324     my $old_engine;
2325     if ( $engine->isa('Catalyst::Engine::Apache')
2326         && !Catalyst::Engine::Apache->VERSION )
2327     {
2328         $old_engine = 1;
2329     }
2330
2331     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2332         && Catalyst::Engine::Server->VERSION le '0.02' )
2333     {
2334         $old_engine = 1;
2335     }
2336
2337     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2338         && $engine->VERSION eq '0.01' )
2339     {
2340         $old_engine = 1;
2341     }
2342
2343     elsif ($engine->isa('Catalyst::Engine::Zeus')
2344         && $engine->VERSION eq '0.01' )
2345     {
2346         $old_engine = 1;
2347     }
2348
2349     if ($old_engine) {
2350         Catalyst::Exception->throw( message =>
2351               qq/Engine "$engine" is not supported by this version of Catalyst/
2352         );
2353     }
2354
2355     # engine instance
2356     $class->engine( $engine->new );
2357 }
2358
2359 =head2 $c->setup_home
2360
2361 Sets up the home directory.
2362
2363 =cut
2364
2365 sub setup_home {
2366     my ( $class, $home ) = @_;
2367
2368     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2369         $home = $env;
2370     }
2371
2372     $home ||= Catalyst::Utils::home($class);
2373
2374     if ($home) {
2375         #I remember recently being scolded for assigning config values like this
2376         $class->config->{home} ||= $home;
2377         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2378     }
2379 }
2380
2381 =head2 $c->setup_log
2382
2383 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2384 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2385 log to.
2386
2387 This method also installs a C<debug> method that returns a true value into the
2388 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2389 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2390
2391 Note that if the log has already been setup, by either a previous call to
2392 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2393 that this method won't actually set up the log object.
2394
2395 =cut
2396
2397 sub setup_log {
2398     my ( $class, $levels ) = @_;
2399
2400     $levels ||= '';
2401     $levels =~ s/^\s+//;
2402     $levels =~ s/\s+$//;
2403     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2404
2405     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2406     if ( defined $env_debug ) {
2407         $levels{debug} = 1 if $env_debug; # Ugly!
2408         delete($levels{debug}) unless $env_debug;
2409     }
2410
2411     unless ( $class->log ) {
2412         $class->log( Catalyst::Log->new(keys %levels) );
2413     }
2414
2415     if ( $levels{debug} ) {
2416         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2417         $class->log->debug('Debug messages enabled');
2418     }
2419 }
2420
2421 =head2 $c->setup_plugins
2422
2423 Sets up plugins.
2424
2425 =cut
2426
2427 =head2 $c->setup_stats
2428
2429 Sets up timing statistics class.
2430
2431 =cut
2432
2433 sub setup_stats {
2434     my ( $class, $stats ) = @_;
2435
2436     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2437
2438     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2439     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2440         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2441         $class->log->debug('Statistics enabled');
2442     }
2443 }
2444
2445
2446 =head2 $c->registered_plugins
2447
2448 Returns a sorted list of the plugins which have either been stated in the
2449 import list or which have been added via C<< MyApp->plugin(@args); >>.
2450
2451 If passed a given plugin name, it will report a boolean value indicating
2452 whether or not that plugin is loaded.  A fully qualified name is required if
2453 the plugin name does not begin with C<Catalyst::Plugin::>.
2454
2455  if ($c->registered_plugins('Some::Plugin')) {
2456      ...
2457  }
2458
2459 =cut
2460
2461 {
2462
2463     sub registered_plugins {
2464         my $proto = shift;
2465         return sort keys %{ $proto->_plugins } unless @_;
2466         my $plugin = shift;
2467         return 1 if exists $proto->_plugins->{$plugin};
2468         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2469     }
2470
2471     sub _register_plugin {
2472         my ( $proto, $plugin, $instant ) = @_;
2473         my $class = ref $proto || $proto;
2474
2475         # no ignore_loaded here, the plugin may already have been
2476         # defined in memory and we don't want to error on "no file" if so
2477
2478         Class::MOP::load_class( $plugin );
2479
2480         $proto->_plugins->{$plugin} = 1;
2481         unless ($instant) {
2482             no strict 'refs';
2483             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2484               my @superclasses = ($plugin, $meta->superclasses );
2485               $meta->superclasses(@superclasses);
2486             } else {
2487               unshift @{"$class\::ISA"}, $plugin;
2488             }
2489         }
2490         return $class;
2491     }
2492
2493     sub setup_plugins {
2494         my ( $class, $plugins ) = @_;
2495
2496         $class->_plugins( {} ) unless $class->_plugins;
2497         $plugins ||= [];
2498         for my $plugin ( reverse @$plugins ) {
2499
2500             unless ( $plugin =~ s/\A\+// ) {
2501                 $plugin = "Catalyst::Plugin::$plugin";
2502             }
2503
2504             $class->_register_plugin($plugin);
2505         }
2506     }
2507 }
2508
2509 =head2 $c->stack
2510
2511 Returns an arrayref of the internal execution stack (actions that are
2512 currently executing).
2513
2514 =head2 $c->stats_class
2515
2516 Returns or sets the stats (timing statistics) class.
2517
2518 =head2 $c->use_stats
2519
2520 Returns 1 when stats collection is enabled.  Stats collection is enabled
2521 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2522 environment variable is set.
2523
2524 Note that this is a static method, not an accessor and should be overridden
2525 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2526
2527 =cut
2528
2529 sub use_stats { 0 }
2530
2531
2532 =head2 $c->write( $data )
2533
2534 Writes $data to the output stream. When using this method directly, you
2535 will need to manually set the C<Content-Length> header to the length of
2536 your output data, if known.
2537
2538 =cut
2539
2540 sub write {
2541     my $c = shift;
2542
2543     # Finalize headers if someone manually writes output
2544     $c->finalize_headers;
2545
2546     return $c->engine->write( $c, @_ );
2547 }
2548
2549 =head2 version
2550
2551 Returns the Catalyst version number. Mostly useful for "powered by"
2552 messages in template systems.
2553
2554 =cut
2555
2556 sub version { return $Catalyst::VERSION }
2557
2558 =head1 INTERNAL ACTIONS
2559
2560 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2561 C<_ACTION>, and C<_END>. These are by default not shown in the private
2562 action table, but you can make them visible with a config parameter.
2563
2564     MyApp->config->{show_internal_actions} = 1;
2565
2566 =head1 CASE SENSITIVITY
2567
2568 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2569 mapped to C</foo/bar>. You can activate case sensitivity with a config
2570 parameter.
2571
2572     MyApp->config->{case_sensitive} = 1;
2573
2574 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2575
2576 =head1 ON-DEMAND PARSER
2577
2578 The request body is usually parsed at the beginning of a request,
2579 but if you want to handle input yourself, you can enable on-demand
2580 parsing with a config parameter.
2581
2582     MyApp->config->{parse_on_demand} = 1;
2583
2584 =head1 PROXY SUPPORT
2585
2586 Many production servers operate using the common double-server approach,
2587 with a lightweight frontend web server passing requests to a larger
2588 backend server. An application running on the backend server must deal
2589 with two problems: the remote user always appears to be C<127.0.0.1> and
2590 the server's hostname will appear to be C<localhost> regardless of the
2591 virtual host that the user connected through.
2592
2593 Catalyst will automatically detect this situation when you are running
2594 the frontend and backend servers on the same machine. The following
2595 changes are made to the request.
2596
2597     $c->req->address is set to the user's real IP address, as read from
2598     the HTTP X-Forwarded-For header.
2599
2600     The host value for $c->req->base and $c->req->uri is set to the real
2601     host, as read from the HTTP X-Forwarded-Host header.
2602
2603 Obviously, your web server must support these headers for this to work.
2604
2605 In a more complex server farm environment where you may have your
2606 frontend proxy server(s) on different machines, you will need to set a
2607 configuration option to tell Catalyst to read the proxied data from the
2608 headers.
2609
2610     MyApp->config->{using_frontend_proxy} = 1;
2611
2612 If you do not wish to use the proxy support at all, you may set:
2613
2614     MyApp->config->{ignore_frontend_proxy} = 1;
2615
2616 =head1 THREAD SAFETY
2617
2618 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2619 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2620 believe the Catalyst core to be thread-safe.
2621
2622 If you plan to operate in a threaded environment, remember that all other
2623 modules you are using must also be thread-safe. Some modules, most notably
2624 L<DBD::SQLite>, are not thread-safe.
2625
2626 =head1 SUPPORT
2627
2628 IRC:
2629
2630     Join #catalyst on irc.perl.org.
2631
2632 Mailing Lists:
2633
2634     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2635     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2636
2637 Web:
2638
2639     http://catalyst.perl.org
2640
2641 Wiki:
2642
2643     http://dev.catalyst.perl.org
2644
2645 =head1 SEE ALSO
2646
2647 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2648
2649 =head2 L<Catalyst::Manual> - The Catalyst Manual
2650
2651 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2652
2653 =head2 L<Catalyst::Engine> - Core engine
2654
2655 =head2 L<Catalyst::Log> - Log class.
2656
2657 =head2 L<Catalyst::Request> - Request object
2658
2659 =head2 L<Catalyst::Response> - Response object
2660
2661 =head2 L<Catalyst::Test> - The test suite.
2662
2663 =head1 PROJECT FOUNDER
2664
2665 sri: Sebastian Riedel <sri@cpan.org>
2666
2667 =head1 CONTRIBUTORS
2668
2669 abw: Andy Wardley
2670
2671 acme: Leon Brocard <leon@astray.com>
2672
2673 Andrew Bramble
2674
2675 Andrew Ford
2676
2677 Andrew Ruthven
2678
2679 andyg: Andy Grundman <andy@hybridized.org>
2680
2681 audreyt: Audrey Tang
2682
2683 bricas: Brian Cassidy <bricas@cpan.org>
2684
2685 Caelum: Rafael Kitover <rkitover@io.com>
2686
2687 chansen: Christian Hansen
2688
2689 chicks: Christopher Hicks
2690
2691 David E. Wheeler
2692
2693 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2694
2695 Drew Taylor
2696
2697 esskar: Sascha Kiefer
2698
2699 fireartist: Carl Franks <cfranks@cpan.org>
2700
2701 gabb: Danijel Milicevic
2702
2703 Gary Ashton Jones
2704
2705 Geoff Richards
2706
2707 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2708
2709 jcamacho: Juan Camacho
2710
2711 jhannah: Jay Hannah <jay@jays.net>
2712
2713 Jody Belka
2714
2715 Johan Lindstrom
2716
2717 jon: Jon Schutz <jjschutz@cpan.org>
2718
2719 marcus: Marcus Ramberg <mramberg@cpan.org>
2720
2721 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2722
2723 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2724
2725 mugwump: Sam Vilain
2726
2727 naughton: David Naughton
2728
2729 ningu: David Kamholz <dkamholz@cpan.org>
2730
2731 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2732
2733 numa: Dan Sully <daniel@cpan.org>
2734
2735 obra: Jesse Vincent
2736
2737 omega: Andreas Marienborg
2738
2739 Oleg Kostyuk <cub.uanic@gmail.com>
2740
2741 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2742
2743 rafl: Florian Ragwitz <rafl@debian.org>
2744
2745 sky: Arthur Bergman
2746
2747 the_jester: Jesse Sheidlower
2748
2749 t0m: Tomas Doran <bobtfish@bobtfish.net>
2750
2751 Ulf Edvinsson
2752
2753 willert: Sebastian Willert <willert@cpan.org>
2754
2755 =head1 LICENSE
2756
2757 This library is free software, you can redistribute it and/or modify it under
2758 the same terms as Perl itself.
2759
2760 =cut
2761
2762 no Moose;
2763
2764 __PACKAGE__->meta->make_immutable;
2765
2766 1;