lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Safe::Isa;
  37 use Plack::Middleware::Conditional;
  38 use Plack::Middleware::ReverseProxy;
  39 use Plack::Middleware::IIS6ScriptNameFix;
  40 use Plack::Middleware::IIS7KeepAliveFix;
  41 use Plack::Middleware::LighttpdScriptNameFix;
  42
  43 BEGIN { require 5.008003; }
  44
  45 has stack => (is => 'ro', default => sub { [] });
  46 has stash => (is => 'rw', default => sub { {} });
  47 has state => (is => 'rw', default => 0);
  48 has stats => (is => 'rw');
  49 has action => (is => 'rw');
  50 has counter => (is => 'rw', default => sub { {} });
  51 has request => (
  52     is => 'rw',
  53     default => sub {
  54         my $self = shift;
  55         my %p = ( _log => $self->log );
  56         $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  57         $self->request_class->new(\%p);
  58     },
  59     lazy => 1,
  60 );
  61 has response => (
  62     is => 'rw',
  63     default => sub {
  64         my $self = shift;
  65         $self->response_class->new({ _log => $self->log });
  66     },
  67     lazy => 1,
  68 );
  69 has namespace => (is => 'rw');
  70
  71 sub depth { scalar @{ shift->stack || [] }; }
  72 sub comp { shift->component(@_) }
  73
  74 sub req {
  75     my $self = shift; return $self->request(@_);
  76 }
  77 sub res {
  78     my $self = shift; return $self->response(@_);
  79 }
  80
  81 # For backwards compatibility
  82 sub finalize_output { shift->finalize_body(@_) };
  83
  84 # For statistics
  85 our $COUNT     = 1;
  86 our $START     = time;
  87 our $RECURSION = 1000;
  88 our $DETACH    = Catalyst::Exception::Detach->new;
  89 our $GO        = Catalyst::Exception::Go->new;
  90
  91 #I imagine that very few of these really need to be class variables. if any.
  92 #maybe we should just make them attributes with a default?
  93 __PACKAGE__->mk_classdata($_)
  94   for qw/components arguments dispatcher engine log dispatcher_class
  95   engine_loader context_class request_class response_class stats_class
  96   setup_finished _psgi_app loading_psgi_file run_options/;
  97
  98 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  99 __PACKAGE__->request_class('Catalyst::Request');
 100 __PACKAGE__->response_class('Catalyst::Response');
 101 __PACKAGE__->stats_class('Catalyst::Stats');
 102
 103 # Remember to update this in Catalyst::Runtime as well!
 104
 105 our $VERSION = '5.90016';
 106
 107 sub import {
 108     my ( $class, @arguments ) = @_;
 109
 110     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 111     # callers @ISA.
 112     return unless $class eq 'Catalyst';
 113
 114     my $caller = caller();
 115     return if $caller eq 'main';
 116
 117     my $meta = Moose::Meta::Class->initialize($caller);
 118     unless ( $caller->isa('Catalyst') ) {
 119         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 120         $meta->superclasses(@superclasses);
 121     }
 122     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 123     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 124
 125     unless( $meta->has_method('meta') ){
 126         if ($Moose::VERSION >= 1.15) {
 127             $meta->_add_meta_method('meta');
 128         }
 129         else {
 130             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 131         }
 132     }
 133
 134     $caller->arguments( [@arguments] );
 135     $caller->setup_home;
 136 }
 137
 138 sub _application { $_[0] }
 139
 140 =encoding UTF-8
 141
 142 =head1 NAME
 143
 144 Catalyst - The Elegant MVC Web Application Framework
 145
 146 =head1 SYNOPSIS
 147
 148 See the L<Catalyst::Manual> distribution for comprehensive
 149 documentation and tutorials.
 150
 151     # Install Catalyst::Devel for helpers and other development tools
 152     # use the helper to create a new application
 153     catalyst.pl MyApp
 154
 155     # add models, views, controllers
 156     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 157     script/myapp_create.pl view MyTemplate TT
 158     script/myapp_create.pl controller Search
 159
 160     # built in testserver -- use -r to restart automatically on changes
 161     # --help to see all available options
 162     script/myapp_server.pl
 163
 164     # command line testing interface
 165     script/myapp_test.pl /yada
 166
 167     ### in lib/MyApp.pm
 168     use Catalyst qw/-Debug/; # include plugins here as well
 169
 170     ### In lib/MyApp/Controller/Root.pm (autocreated)
 171     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 172         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 173         $c->stash->{template} = 'foo.tt'; # set the template
 174         # lookup something from db -- stash vars are passed to TT
 175         $c->stash->{data} =
 176           $c->model('Database::Foo')->search( { country => $args[0] } );
 177         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 178             $c->forward( 'bar' ); # process another action
 179             # do something else after forward returns
 180         }
 181     }
 182
 183     # The foo.tt TT template can use the stash data from the database
 184     [% WHILE (item = data.next) %]
 185         [% item.foo %]
 186     [% END %]
 187
 188     # called for /bar/of/soap, /bar/of/soap/10, etc.
 189     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 190
 191     # called after all actions are finished
 192     sub end : Action {
 193         my ( $self, $c ) = @_;
 194         if ( scalar @{ $c->error } ) { ... } # handle errors
 195         return if $c->res->body; # already have a response
 196         $c->forward( 'MyApp::View::TT' ); # render template
 197     }
 198
 199 See L<Catalyst::Manual::Intro> for additional information.
 200
 201 =head1 DESCRIPTION
 202
 203 Catalyst is a modern framework for making web applications without the
 204 pain usually associated with this process. This document is a reference
 205 to the main Catalyst application. If you are a new user, we suggest you
 206 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 207
 208 See L<Catalyst::Manual> for more documentation.
 209
 210 Catalyst plugins can be loaded by naming them as arguments to the "use
 211 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 212 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 213 C<My::Module>.
 214
 215     use Catalyst qw/My::Module/;
 216
 217 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 218 fully qualify the name by using a unary plus:
 219
 220     use Catalyst qw/
 221         My::Module
 222         +Fully::Qualified::Plugin::Name
 223     /;
 224
 225 Special flags like C<-Debug> can also be specified as
 226 arguments when Catalyst is loaded:
 227
 228     use Catalyst qw/-Debug My::Module/;
 229
 230 The position of plugins and flags in the chain is important, because
 231 they are loaded in the order in which they appear.
 232
 233 The following flags are supported:
 234
 235 =head2 -Debug
 236
 237 Enables debug output. You can also force this setting from the system
 238 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 239 settings override the application, with <MYAPP>_DEBUG having the highest
 240 priority.
 241
 242 This sets the log level to 'debug' and enables full debug output on the
 243 error screen. If you only want the latter, see L<< $c->debug >>.
 244
 245 =head2 -Home
 246
 247 Forces Catalyst to use a specific home directory, e.g.:
 248
 249     use Catalyst qw[-Home=/usr/mst];
 250
 251 This can also be done in the shell environment by setting either the
 252 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 253 is replaced with the uppercased name of your application, any "::" in
 254 the name will be replaced with underscores, e.g. MyApp::Web should use
 255 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 256
 257 If none of these are set, Catalyst will attempt to automatically detect the
 258 home directory. If you are working in a development environment, Catalyst
 259 will try and find the directory containing either Makefile.PL, Build.PL or
 260 dist.ini. If the application has been installed into the system (i.e.
 261 you have done C<make install>), then Catalyst will use the path to your
 262 application module, without the .pm extension (e.g., /foo/MyApp if your
 263 application was installed at /foo/MyApp.pm)
 264
 265 =head2 -Log
 266
 267     use Catalyst '-Log=warn,fatal,error';
 268
 269 Specifies a comma-delimited list of log levels.
 270
 271 =head2 -Stats
 272
 273 Enables statistics collection and reporting.
 274
 275    use Catalyst qw/-Stats=1/;
 276
 277 You can also force this setting from the system environment with CATALYST_STATS
 278 or <MYAPP>_STATS. The environment settings override the application, with
 279 <MYAPP>_STATS having the highest priority.
 280
 281 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 282
 283 =head1 METHODS
 284
 285 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 286
 287 =head2 $c->action
 288
 289 Returns a L<Catalyst::Action> object for the current action, which
 290 stringifies to the action name. See L<Catalyst::Action>.
 291
 292 =head2 $c->namespace
 293
 294 Returns the namespace of the current action, i.e., the URI prefix
 295 corresponding to the controller of the current action. For example:
 296
 297     # in Controller::Foo::Bar
 298     $c->namespace; # returns 'foo/bar';
 299
 300 =head2 $c->request
 301
 302 =head2 $c->req
 303
 304 Returns the current L<Catalyst::Request> object, giving access to
 305 information about the current client request (including parameters,
 306 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 307
 308 =head2 REQUEST FLOW HANDLING
 309
 310 =head2 $c->forward( $action [, \@arguments ] )
 311
 312 =head2 $c->forward( $class, $method, [, \@arguments ] )
 313
 314 Forwards processing to another action, by its private name. If you give a
 315 class name but no method, C<process()> is called. You may also optionally
 316 pass arguments in an arrayref. The action will receive the arguments in
 317 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 318 C<< $c->req->args >> will be restored to the previous values.
 319
 320 Any data C<return>ed from the action forwarded to, will be returned by the
 321 call to forward.
 322
 323     my $foodata = $c->forward('/foo');
 324     $c->forward('index');
 325     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 326     $c->forward('View::TT');
 327
 328 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 329 an C<< eval { } >> around the call (actually
 330 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 331 exceptions thrown by the called action non-fatal and pushing them onto
 332 $c->error instead. If you want C<die> to propagate you need to do something
 333 like:
 334
 335     $c->forward('foo');
 336     die join "\n", @{ $c->error } if @{ $c->error };
 337
 338 Or make sure to always return true values from your actions and write
 339 your code like this:
 340
 341     $c->forward('foo') || return;
 342
 343 Another note is that C<< $c->forward >> always returns a scalar because it
 344 actually returns $c->state which operates in a scalar context.
 345 Thus, something like:
 346
 347     return @array;
 348
 349 in an action that is forwarded to is going to return a scalar,
 350 i.e. how many items are in that array, which is probably not what you want.
 351 If you need to return an array then return a reference to it,
 352 or stash it like so:
 353
 354     $c->stash->{array} = \@array;
 355
 356 and access it from the stash.
 357
 358 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 359
 360 =cut
 361
 362 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 363
 364 =head2 $c->detach( $action [, \@arguments ] )
 365
 366 =head2 $c->detach( $class, $method, [, \@arguments ] )
 367
 368 =head2 $c->detach()
 369
 370 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 371 doesn't return to the previous action when processing is finished.
 372
 373 When called with no arguments it escapes the processing chain entirely.
 374
 375 =cut
 376
 377 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 378
 379 =head2 $c->visit( $action [, \@arguments ] )
 380
 381 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 382
 383 =head2 $c->visit( $class, $method, [, \@arguments ] )
 384
 385 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 386
 387 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 388 but does a full dispatch, instead of just calling the new C<$action> /
 389 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 390 you go to are called, just like a new request.
 391
 392 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 393 This means, for example, that C<< $c->action >> methods such as
 394 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 395 L<reverse|Catalyst::Action/reverse> return information for the visited action
 396 when they are invoked within the visited action.  This is different from the
 397 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 398 continues to use the $c->action object from the caller action even when
 399 invoked from the called action.
 400
 401 C<< $c->stash >> is kept unchanged.
 402
 403 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 404 allows you to "wrap" another action, just as it would have been called by
 405 dispatching from a URL, while the analogous
 406 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 407 transfer control to another action as if it had been reached directly from a URL.
 408
 409 =cut
 410
 411 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 412
 413 =head2 $c->go( $action [, \@arguments ] )
 414
 415 =head2 $c->go( $action [, \@captures, \@arguments ] )
 416
 417 =head2 $c->go( $class, $method, [, \@arguments ] )
 418
 419 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 420
 421 The relationship between C<go> and
 422 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 423 the relationship between
 424 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 425 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 426 C<< $c->go >> will perform a full dispatch on the specified action or method,
 427 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 428 C<go> escapes the processing of the current request chain on completion, and
 429 does not return to its caller.
 430
 431 @arguments are arguments to the final destination of $action. @captures are
 432 arguments to the intermediate steps, if any, on the way to the final sub of
 433 $action.
 434
 435 =cut
 436
 437 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 438
 439 =head2 $c->response
 440
 441 =head2 $c->res
 442
 443 Returns the current L<Catalyst::Response> object, see there for details.
 444
 445 =head2 $c->stash
 446
 447 Returns a hashref to the stash, which may be used to store data and pass
 448 it between components during a request. You can also set hash keys by
 449 passing arguments. The stash is automatically sent to the view. The
 450 stash is cleared at the end of a request; it cannot be used for
 451 persistent storage (for this you must use a session; see
 452 L<Catalyst::Plugin::Session> for a complete system integrated with
 453 Catalyst).
 454
 455     $c->stash->{foo} = $bar;
 456     $c->stash( { moose => 'majestic', qux => 0 } );
 457     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 458
 459     # stash is automatically passed to the view for use in a template
 460     $c->forward( 'MyApp::View::TT' );
 461
 462 =cut
 463
 464 around stash => sub {
 465     my $orig = shift;
 466     my $c = shift;
 467     my $stash = $orig->($c);
 468     if (@_) {
 469         my $new_stash = @_ > 1 ? {@_} : $_[0];
 470         croak('stash takes a hash or hashref') unless ref $new_stash;
 471         foreach my $key ( keys %$new_stash ) {
 472           $stash->{$key} = $new_stash->{$key};
 473         }
 474     }
 475
 476     return $stash;
 477 };
 478
 479
 480 =head2 $c->error
 481
 482 =head2 $c->error($error, ...)
 483
 484 =head2 $c->error($arrayref)
 485
 486 Returns an arrayref containing error messages.  If Catalyst encounters an
 487 error while processing a request, it stores the error in $c->error.  This
 488 method should only be used to store fatal error messages.
 489
 490     my @error = @{ $c->error };
 491
 492 Add a new error.
 493
 494     $c->error('Something bad happened');
 495
 496 =cut
 497
 498 sub error {
 499     my $c = shift;
 500     if ( $_[0] ) {
 501         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 502         croak @$error unless ref $c;
 503         push @{ $c->{error} }, @$error;
 504     }
 505     elsif ( defined $_[0] ) { $c->{error} = undef }
 506     return $c->{error} || [];
 507 }
 508
 509
 510 =head2 $c->state
 511
 512 Contains the return value of the last executed action.
 513 Note that << $c->state >> operates in a scalar context which means that all
 514 values it returns are scalar.
 515
 516 =head2 $c->clear_errors
 517
 518 Clear errors.  You probably don't want to clear the errors unless you are
 519 implementing a custom error screen.
 520
 521 This is equivalent to running
 522
 523     $c->error(0);
 524
 525 =cut
 526
 527 sub clear_errors {
 528     my $c = shift;
 529     $c->error(0);
 530 }
 531
 532 sub _comp_search_prefixes {
 533     my $c = shift;
 534     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 535 }
 536
 537 # search components given a name and some prefixes
 538 sub _comp_names_search_prefixes {
 539     my ( $c, $name, @prefixes ) = @_;
 540     my $appclass = ref $c || $c;
 541     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 542     $filter = qr/$filter/; # Compile regex now rather than once per loop
 543
 544     # map the original component name to the sub part that we will search against
 545     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 546         grep { /$filter/ } keys %{ $c->components };
 547
 548     # undef for a name will return all
 549     return keys %eligible if !defined $name;
 550
 551     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 552     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 553
 554     return @result if @result;
 555
 556     # if we were given a regexp to search against, we're done.
 557     return if $name->$_isa('Regexp');
 558
 559     # skip regexp fallback if configured
 560     return
 561         if $appclass->config->{disable_component_resolution_regex_fallback};
 562
 563     # regexp fallback
 564     $query  = qr/$name/i;
 565     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 566
 567     # no results? try against full names
 568     if( !@result ) {
 569         @result = grep { m{$query} } keys %eligible;
 570     }
 571
 572     # don't warn if we didn't find any results, it just might not exist
 573     if( @result ) {
 574         # Disgusting hack to work out correct method name
 575         my $warn_for = lc $prefixes[0];
 576         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 577            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 578            "component resolution is unreliable and unsafe.";
 579         my $short = $result[0];
 580         # remove the component namespace prefix
 581         $short =~ s/.*?(Model|Controller|View):://;
 582         my $shortmess = Carp::shortmess('');
 583         if ($shortmess =~ m#Catalyst/Plugin#) {
 584            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 585               "plugin's config";
 586         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 587            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 588               "component's config";
 589         } else {
 590            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 591               "but if you really wanted to search, pass in a regexp as the argument " .
 592               "like so: \$c->${warn_for}(qr/${name}/)";
 593         }
 594         $c->log->warn( "${msg}$shortmess" );
 595     }
 596
 597     return @result;
 598 }
 599
 600 # Find possible names for a prefix
 601 sub _comp_names {
 602     my ( $c, @prefixes ) = @_;
 603     my $appclass = ref $c || $c;
 604
 605     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 606
 607     my @names = map { s{$filter}{}; $_; }
 608         $c->_comp_names_search_prefixes( undef, @prefixes );
 609
 610     return @names;
 611 }
 612
 613 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 614 sub _filter_component {
 615     my ( $c, $comp, @args ) = @_;
 616
 617     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 618         return $comp->ACCEPT_CONTEXT( $c, @args );
 619     }
 620
 621     return $comp;
 622 }
 623
 624 =head2 COMPONENT ACCESSORS
 625
 626 =head2 $c->controller($name)
 627
 628 Gets a L<Catalyst::Controller> instance by name.
 629
 630     $c->controller('Foo')->do_stuff;
 631
 632 If the name is omitted, will return the controller for the dispatched
 633 action.
 634
 635 If you want to search for controllers, pass in a regexp as the argument.
 636
 637     # find all controllers that start with Foo
 638     my @foo_controllers = $c->controller(qr{^Foo});
 639
 640
 641 =cut
 642
 643 sub controller {
 644     my ( $c, $name, @args ) = @_;
 645
 646     my $appclass = ref($c) || $c;
 647     if( $name ) {
 648         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 649             my $comps = $c->components;
 650             my $check = $appclass."::Controller::".$name;
 651             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 652         }
 653         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 654         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 655         return $c->_filter_component( $result[ 0 ], @args );
 656     }
 657
 658     return $c->component( $c->action->class );
 659 }
 660
 661 =head2 $c->model($name)
 662
 663 Gets a L<Catalyst::Model> instance by name.
 664
 665     $c->model('Foo')->do_stuff;
 666
 667 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 668
 669 If the name is omitted, it will look for
 670  - a model object in $c->stash->{current_model_instance}, then
 671  - a model name in $c->stash->{current_model}, then
 672  - a config setting 'default_model', or
 673  - check if there is only one model, and return it if that's the case.
 674
 675 If you want to search for models, pass in a regexp as the argument.
 676
 677     # find all models that start with Foo
 678     my @foo_models = $c->model(qr{^Foo});
 679
 680 =cut
 681
 682 sub model {
 683     my ( $c, $name, @args ) = @_;
 684     my $appclass = ref($c) || $c;
 685     if( $name ) {
 686         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 687             my $comps = $c->components;
 688             my $check = $appclass."::Model::".$name;
 689             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 690         }
 691         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 692         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 693         return $c->_filter_component( $result[ 0 ], @args );
 694     }
 695
 696     if (ref $c) {
 697         return $c->stash->{current_model_instance}
 698           if $c->stash->{current_model_instance};
 699         return $c->model( $c->stash->{current_model} )
 700           if $c->stash->{current_model};
 701     }
 702     return $c->model( $appclass->config->{default_model} )
 703       if $appclass->config->{default_model};
 704
 705     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 706
 707     if( $rest ) {
 708         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 709         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 710         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 711         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 712         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 713     }
 714
 715     return $c->_filter_component( $comp );
 716 }
 717
 718
 719 =head2 $c->view($name)
 720
 721 Gets a L<Catalyst::View> instance by name.
 722
 723     $c->view('Foo')->do_stuff;
 724
 725 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 726
 727 If the name is omitted, it will look for
 728  - a view object in $c->stash->{current_view_instance}, then
 729  - a view name in $c->stash->{current_view}, then
 730  - a config setting 'default_view', or
 731  - check if there is only one view, and return it if that's the case.
 732
 733 If you want to search for views, pass in a regexp as the argument.
 734
 735     # find all views that start with Foo
 736     my @foo_views = $c->view(qr{^Foo});
 737
 738 =cut
 739
 740 sub view {
 741     my ( $c, $name, @args ) = @_;
 742
 743     my $appclass = ref($c) || $c;
 744     if( $name ) {
 745         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 746             my $comps = $c->components;
 747             my $check = $appclass."::View::".$name;
 748             if( exists $comps->{$check} ) {
 749                 return $c->_filter_component( $comps->{$check}, @args );
 750             }
 751             else {
 752                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 753             }
 754         }
 755         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 756         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 757         return $c->_filter_component( $result[ 0 ], @args );
 758     }
 759
 760     if (ref $c) {
 761         return $c->stash->{current_view_instance}
 762           if $c->stash->{current_view_instance};
 763         return $c->view( $c->stash->{current_view} )
 764           if $c->stash->{current_view};
 765     }
 766     return $c->view( $appclass->config->{default_view} )
 767       if $appclass->config->{default_view};
 768
 769     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 770
 771     if( $rest ) {
 772         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 773         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 774         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 775         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 776         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 777     }
 778
 779     return $c->_filter_component( $comp );
 780 }
 781
 782 =head2 $c->controllers
 783
 784 Returns the available names which can be passed to $c->controller
 785
 786 =cut
 787
 788 sub controllers {
 789     my ( $c ) = @_;
 790     return $c->_comp_names(qw/Controller C/);
 791 }
 792
 793 =head2 $c->models
 794
 795 Returns the available names which can be passed to $c->model
 796
 797 =cut
 798
 799 sub models {
 800     my ( $c ) = @_;
 801     return $c->_comp_names(qw/Model M/);
 802 }
 803
 804
 805 =head2 $c->views
 806
 807 Returns the available names which can be passed to $c->view
 808
 809 =cut
 810
 811 sub views {
 812     my ( $c ) = @_;
 813     return $c->_comp_names(qw/View V/);
 814 }
 815
 816 =head2 $c->comp($name)
 817
 818 =head2 $c->component($name)
 819
 820 Gets a component object by name. This method is not recommended,
 821 unless you want to get a specific component by full
 822 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 823 should be used instead.
 824
 825 If C<$name> is a regexp, a list of components matched against the full
 826 component name will be returned.
 827
 828 If Catalyst can't find a component by name, it will fallback to regex
 829 matching by default. To disable this behaviour set
 830 disable_component_resolution_regex_fallback to a true value.
 831
 832     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 833
 834 =cut
 835
 836 sub component {
 837     my ( $c, $name, @args ) = @_;
 838
 839     if( $name ) {
 840         my $comps = $c->components;
 841
 842         if( !ref $name ) {
 843             # is it the exact name?
 844             return $c->_filter_component( $comps->{ $name }, @args )
 845                        if exists $comps->{ $name };
 846
 847             # perhaps we just omitted "MyApp"?
 848             my $composed = ( ref $c || $c ) . "::${name}";
 849             return $c->_filter_component( $comps->{ $composed }, @args )
 850                        if exists $comps->{ $composed };
 851
 852             # search all of the models, views and controllers
 853             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 854             return $c->_filter_component( $comp, @args ) if $comp;
 855         }
 856
 857         return
 858             if $c->config->{disable_component_resolution_regex_fallback};
 859
 860         # This is here so $c->comp( '::M::' ) works
 861         my $query = ref $name ? $name : qr{$name}i;
 862
 863         my @result = grep { m{$query} } keys %{ $c->components };
 864         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 865
 866         if( $result[ 0 ] ) {
 867             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 868             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 869             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 870             return $c->_filter_component( $result[ 0 ], @args );
 871         }
 872
 873         # I would expect to return an empty list here, but that breaks back-compat
 874     }
 875
 876     # fallback
 877     return sort keys %{ $c->components };
 878 }
 879
 880 =head2 CLASS DATA AND HELPER CLASSES
 881
 882 =head2 $c->config
 883
 884 Returns or takes a hashref containing the application's configuration.
 885
 886     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 887
 888 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 889 like C<myapp.conf> in your applications home directory. See
 890 L<Catalyst::Plugin::ConfigLoader>.
 891
 892 =head3 Cascading configuration
 893
 894 The config method is present on all Catalyst components, and configuration
 895 will be merged when an application is started. Configuration loaded with
 896 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 897 followed by configuration in your top level C<MyApp> class. These two
 898 configurations are merged, and then configuration data whose hash key matches a
 899 component name is merged with configuration for that component.
 900
 901 The configuration for a component is then passed to the C<new> method when a
 902 component is constructed.
 903
 904 For example:
 905
 906     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 907     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 908
 909 will mean that C<MyApp::Model::Foo> receives the following data when
 910 constructed:
 911
 912     MyApp::Model::Foo->new({
 913         bar => 'baz',
 914         quux => 'frob',
 915         overrides => 'me',
 916     });
 917
 918 It's common practice to use a Moose attribute
 919 on the receiving component to access the config value.
 920
 921     package MyApp::Model::Foo;
 922
 923     use Moose;
 924
 925     # this attr will receive 'baz' at construction time
 926     has 'bar' => (
 927         is  => 'rw',
 928         isa => 'Str',
 929     );
 930
 931 You can then get the value 'baz' by calling $c->model('Foo')->bar
 932 (or $self->bar inside code in the model).
 933
 934 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 935 as a way of reading config within your code, as this B<will not> give you the
 936 correctly merged config back. You B<MUST> take the config values supplied to
 937 the constructor and use those instead.
 938
 939 =cut
 940
 941 around config => sub {
 942     my $orig = shift;
 943     my $c = shift;
 944
 945     croak('Setting config after setup has been run is not allowed.')
 946         if ( @_ and $c->setup_finished );
 947
 948     $c->$orig(@_);
 949 };
 950
 951 =head2 $c->log
 952
 953 Returns the logging object instance. Unless it is already set, Catalyst
 954 sets this up with a L<Catalyst::Log> object. To use your own log class,
 955 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 956 C<< __PACKAGE__->setup >>.
 957
 958  __PACKAGE__->log( MyLogger->new );
 959  __PACKAGE__->setup;
 960
 961 And later:
 962
 963     $c->log->info( 'Now logging with my own logger!' );
 964
 965 Your log class should implement the methods described in
 966 L<Catalyst::Log>.
 967
 968
 969 =head2 $c->debug
 970
 971 Returns 1 if debug mode is enabled, 0 otherwise.
 972
 973 You can enable debug mode in several ways:
 974
 975 =over
 976
 977 =item By calling myapp_server.pl with the -d flag
 978
 979 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 980
 981 =item The -Debug option in your MyApp.pm
 982
 983 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 984
 985 =back
 986
 987 The first three also set the log level to 'debug'.
 988
 989 Calling C<< $c->debug(1) >> has no effect.
 990
 991 =cut
 992
 993 sub debug { 0 }
 994
 995 =head2 $c->dispatcher
 996
 997 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 998
 999 =head2 $c->engine
1000
1001 Returns the engine instance. See L<Catalyst::Engine>.
1002
1003
1004 =head2 UTILITY METHODS
1005
1006 =head2 $c->path_to(@path)
1007
1008 Merges C<@path> with C<< $c->config->{home} >> and returns a
1009 L<Path::Class::Dir> object. Note you can usually use this object as
1010 a filename, but sometimes you will have to explicitly stringify it
1011 yourself by calling the C<< ->stringify >> method.
1012
1013 For example:
1014
1015     $c->path_to( 'db', 'sqlite.db' );
1016
1017 =cut
1018
1019 sub path_to {
1020     my ( $c, @path ) = @_;
1021     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1022     if ( -d $path ) { return $path }
1023     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1024 }
1025
1026 sub plugin {
1027     my ( $class, $name, $plugin, @args ) = @_;
1028
1029     # See block comment in t/unit_core_plugin.t
1030     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1031
1032     $class->_register_plugin( $plugin, 1 );
1033
1034     eval { $plugin->import };
1035     $class->mk_classdata($name);
1036     my $obj;
1037     eval { $obj = $plugin->new(@args) };
1038
1039     if ($@) {
1040         Catalyst::Exception->throw( message =>
1041               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1042     }
1043
1044     $class->$name($obj);
1045     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1046       if $class->debug;
1047 }
1048
1049 =head2 MyApp->setup
1050
1051 Initializes the dispatcher and engine, loads any plugins, and loads the
1052 model, view, and controller components. You may also specify an array
1053 of plugins to load here, if you choose to not load them in the C<use
1054 Catalyst> line.
1055
1056     MyApp->setup;
1057     MyApp->setup( qw/-Debug/ );
1058
1059 B<Note:> You B<should not> wrap this method with method modifiers
1060 or bad things will happen - wrap the C<setup_finalize> method instead.
1061
1062 =cut
1063
1064 sub setup {
1065     my ( $class, @arguments ) = @_;
1066     croak('Running setup more than once')
1067         if ( $class->setup_finished );
1068
1069     unless ( $class->isa('Catalyst') ) {
1070
1071         Catalyst::Exception->throw(
1072             message => qq/'$class' does not inherit from Catalyst/ );
1073     }
1074
1075     if ( $class->arguments ) {
1076         @arguments = ( @arguments, @{ $class->arguments } );
1077     }
1078
1079     # Process options
1080     my $flags = {};
1081
1082     foreach (@arguments) {
1083
1084         if (/^-Debug$/) {
1085             $flags->{log} =
1086               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1087         }
1088         elsif (/^-(\w+)=?(.*)$/) {
1089             $flags->{ lc $1 } = $2;
1090         }
1091         else {
1092             push @{ $flags->{plugins} }, $_;
1093         }
1094     }
1095
1096     $class->setup_home( delete $flags->{home} );
1097
1098     $class->setup_log( delete $flags->{log} );
1099     $class->setup_plugins( delete $flags->{plugins} );
1100     $class->setup_dispatcher( delete $flags->{dispatcher} );
1101     if (my $engine = delete $flags->{engine}) {
1102         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1103     }
1104     $class->setup_engine();
1105     $class->setup_stats( delete $flags->{stats} );
1106
1107     for my $flag ( sort keys %{$flags} ) {
1108
1109         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1110             &$code( $class, delete $flags->{$flag} );
1111         }
1112         else {
1113             $class->log->warn(qq/Unknown flag "$flag"/);
1114         }
1115     }
1116
1117     eval { require Catalyst::Devel; };
1118     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1119         $class->log->warn(<<"EOF");
1120 You are running an old script!
1121
1122   Please update by running (this will overwrite existing files):
1123     catalyst.pl -force -scripts $class
1124
1125   or (this will not overwrite existing files):
1126     catalyst.pl -scripts $class
1127
1128 EOF
1129     }
1130
1131     if ( $class->debug ) {
1132         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1133
1134         if (@plugins) {
1135             my $column_width = Catalyst::Utils::term_width() - 6;
1136             my $t = Text::SimpleTable->new($column_width);
1137             $t->row($_) for @plugins;
1138             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1139         }
1140
1141         my $dispatcher = $class->dispatcher;
1142         my $engine     = $class->engine;
1143         my $home       = $class->config->{home};
1144
1145         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1146         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1147
1148         $home
1149           ? ( -d $home )
1150           ? $class->log->debug(qq/Found home "$home"/)
1151           : $class->log->debug(qq/Home "$home" doesn't exist/)
1152           : $class->log->debug(q/Couldn't find home/);
1153     }
1154
1155     # Call plugins setup, this is stupid and evil.
1156     # Also screws C3 badly on 5.10, hack to avoid.
1157     {
1158         no warnings qw/redefine/;
1159         local *setup = sub { };
1160         $class->setup unless $Catalyst::__AM_RESTARTING;
1161     }
1162
1163     # Initialize our data structure
1164     $class->components( {} );
1165
1166     $class->setup_components;
1167
1168     if ( $class->debug ) {
1169         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1170         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1171         for my $comp ( sort keys %{ $class->components } ) {
1172             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1173             $t->row( $comp, $type );
1174         }
1175         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1176           if ( keys %{ $class->components } );
1177     }
1178
1179     # Add our self to components, since we are also a component
1180     if( $class->isa('Catalyst::Controller') ){
1181       $class->components->{$class} = $class;
1182     }
1183
1184     $class->setup_actions;
1185
1186     if ( $class->debug ) {
1187         my $name = $class->config->{name} || 'Application';
1188         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1189     }
1190
1191     if ($class->config->{case_sensitive}) {
1192         $class->log->warn($class . "->config->{case_sensitive} is set.");
1193         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1194     }
1195
1196     $class->setup_finalize;
1197     # Should be the last thing we do so that user things hooking
1198     # setup_finalize can log..
1199     $class->log->_flush() if $class->log->can('_flush');
1200     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1201 }
1202
1203 =head2 $app->setup_finalize
1204
1205 A hook to attach modifiers to. This method does not do anything except set the
1206 C<setup_finished> accessor.
1207
1208 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1209
1210 Example:
1211
1212     after setup_finalize => sub {
1213         my $app = shift;
1214
1215         ## do stuff here..
1216     };
1217
1218 =cut
1219
1220 sub setup_finalize {
1221     my ($class) = @_;
1222     $class->setup_finished(1);
1223 }
1224
1225 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1226
1227 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1228
1229 Constructs an absolute L<URI> object based on the application root, the
1230 provided path, and the additional arguments and query parameters provided.
1231 When used as a string, provides a textual URI.  If you need more flexibility
1232 than this (i.e. the option to provide relative URIs etc.) see
1233 L<Catalyst::Plugin::SmartURI>.
1234
1235 If no arguments are provided, the URI for the current action is returned.
1236 To return the current action and also provide @args, use
1237 C<< $c->uri_for( $c->action, @args ) >>.
1238
1239 If the first argument is a string, it is taken as a public URI path relative
1240 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1241 relative to the application root (if it does). It is then merged with
1242 C<< $c->request->base >>; any C<@args> are appended as additional path
1243 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1244
1245 If the first argument is a L<Catalyst::Action> it represents an action which
1246 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1247 optional C<\@captures> argument (an arrayref) allows passing the captured
1248 variables that are needed to fill in the paths of Chained and Regex actions;
1249 once the path is resolved, C<uri_for> continues as though a path was
1250 provided, appending any arguments or parameters and creating an absolute
1251 URI.
1252
1253 The captures for the current request can be found in
1254 C<< $c->request->captures >>, and actions can be resolved using
1255 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1256 path, use C<< $c->uri_for_action >> instead.
1257
1258   # Equivalent to $c->req->uri
1259   $c->uri_for($c->action, $c->req->captures,
1260       @{ $c->req->args }, $c->req->params);
1261
1262   # For the Foo action in the Bar controller
1263   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1264
1265   # Path to a static resource
1266   $c->uri_for('/static/images/logo.png');
1267
1268 =cut
1269
1270 sub uri_for {
1271     my ( $c, $path, @args ) = @_;
1272
1273     if ( $path->$_isa('Catalyst::Controller') ) {
1274         $path = $path->path_prefix;
1275         $path =~ s{/+\z}{};
1276         $path .= '/';
1277     }
1278
1279     undef($path) if (defined $path && $path eq '');
1280
1281     my $params =
1282       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1283
1284     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1285     foreach my $arg (@args) {
1286         utf8::encode($arg) if utf8::is_utf8($arg);
1287         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1288     }
1289
1290     if ( $path->$_isa('Catalyst::Action') ) { # action object
1291         s|/|%2F|g for @args;
1292         my $captures = [ map { s|/|%2F|g; $_; }
1293                         ( scalar @args && ref $args[0] eq 'ARRAY'
1294                          ? @{ shift(@args) }
1295                          : ()) ];
1296
1297         foreach my $capture (@$captures) {
1298             utf8::encode($capture) if utf8::is_utf8($capture);
1299             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1300         }
1301
1302         my $action = $path;
1303         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1304         if( !@args && $action->number_of_args ) {
1305             my $expanded_action = $c->dispatcher->expand_action( $action );
1306
1307             my $num_captures = $expanded_action->number_of_captures;
1308             unshift @args, splice @$captures, $num_captures;
1309         }
1310
1311        $path = $c->dispatcher->uri_for_action($action, $captures);
1312         if (not defined $path) {
1313             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1314                 if $c->debug;
1315             return undef;
1316         }
1317         $path = '/' if $path eq '';
1318     }
1319
1320     unshift(@args, $path);
1321
1322     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1323         my $namespace = $c->namespace;
1324         if (defined $path) { # cheesy hack to handle path '../foo'
1325            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1326         }
1327         unshift(@args, $namespace || '');
1328     }
1329
1330     # join args with '/', or a blank string
1331     my $args = join('/', grep { defined($_) } @args);
1332     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1333     $args =~ s!^/+!!;
1334     my $base = $c->req->base;
1335     my $class = ref($base);
1336     $base =~ s{(?<!/)$}{/};
1337
1338     my $query = '';
1339
1340     if (my @keys = keys %$params) {
1341       # somewhat lifted from URI::_query's query_form
1342       $query = '?'.join('&', map {
1343           my $val = $params->{$_};
1344           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1345           s/ /+/g;
1346           my $key = $_;
1347           $val = '' unless defined $val;
1348           (map {
1349               my $param = "$_";
1350               utf8::encode( $param ) if utf8::is_utf8($param);
1351               # using the URI::Escape pattern here so utf8 chars survive
1352               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1353               $param =~ s/ /+/g;
1354               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1355       } @keys);
1356     }
1357
1358     my $res = bless(\"${base}${args}${query}", $class);
1359     $res;
1360 }
1361
1362 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1363
1364 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1365
1366 =over
1367
1368 =item $path
1369
1370 A private path to the Catalyst action you want to create a URI for.
1371
1372 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1373 >> and passing the resulting C<$action> and the remaining arguments to C<<
1374 $c->uri_for >>.
1375
1376 You can also pass in a Catalyst::Action object, in which case it is passed to
1377 C<< $c->uri_for >>.
1378
1379 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1380
1381 For example, if the action looks like:
1382
1383  package MyApp::Controller::Users;
1384
1385  sub lst : Path('the-list') {}
1386
1387 You can use:
1388
1389  $c->uri_for_action('/users/lst')
1390
1391 and it will create the URI /users/the-list.
1392
1393 =item \@captures_and_args?
1394
1395 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1396 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1397 to interpolate all the parameters in the URI.
1398
1399 =item @args?
1400
1401 Optional list of extra arguments - can be supplied in the
1402 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1403 code.
1404
1405 Your action can have zero, a fixed or a variable number of args (e.g.
1406 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1407
1408 =item \%query_values?
1409
1410 Optional array reference of query parameters to append. E.g.
1411
1412   { foo => 'bar' }
1413
1414 will generate
1415
1416   /rest/of/your/uri?foo=bar
1417
1418 =back
1419
1420 =cut
1421
1422 sub uri_for_action {
1423     my ( $c, $path, @args ) = @_;
1424     my $action = blessed($path)
1425       ? $path
1426       : $c->dispatcher->get_action_by_path($path);
1427     unless (defined $action) {
1428       croak "Can't find action for path '$path'";
1429     }
1430     return $c->uri_for( $action, @args );
1431 }
1432
1433 =head2 $c->welcome_message
1434
1435 Returns the Catalyst welcome HTML page.
1436
1437 =cut
1438
1439 sub welcome_message {
1440     my $c      = shift;
1441     my $name   = $c->config->{name};
1442     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1443     my $prefix = Catalyst::Utils::appprefix( ref $c );
1444     $c->response->content_type('text/html; charset=utf-8');
1445     return <<"EOF";
1446 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1447     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1448 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1449     <head>
1450     <meta http-equiv="Content-Language" content="en" />
1451     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1452         <title>$name on Catalyst $VERSION</title>
1453         <style type="text/css">
1454             body {
1455                 color: #000;
1456                 background-color: #eee;
1457             }
1458             div#content {
1459                 width: 640px;
1460                 margin-left: auto;
1461                 margin-right: auto;
1462                 margin-top: 10px;
1463                 margin-bottom: 10px;
1464                 text-align: left;
1465                 background-color: #ccc;
1466                 border: 1px solid #aaa;
1467             }
1468             p, h1, h2 {
1469                 margin-left: 20px;
1470                 margin-right: 20px;
1471                 font-family: verdana, tahoma, sans-serif;
1472             }
1473             a {
1474                 font-family: verdana, tahoma, sans-serif;
1475             }
1476             :link, :visited {
1477                     text-decoration: none;
1478                     color: #b00;
1479                     border-bottom: 1px dotted #bbb;
1480             }
1481             :link:hover, :visited:hover {
1482                     color: #555;
1483             }
1484             div#topbar {
1485                 margin: 0px;
1486             }
1487             pre {
1488                 margin: 10px;
1489                 padding: 8px;
1490             }
1491             div#answers {
1492                 padding: 8px;
1493                 margin: 10px;
1494                 background-color: #fff;
1495                 border: 1px solid #aaa;
1496             }
1497             h1 {
1498                 font-size: 0.9em;
1499                 font-weight: normal;
1500                 text-align: center;
1501             }
1502             h2 {
1503                 font-size: 1.0em;
1504             }
1505             p {
1506                 font-size: 0.9em;
1507             }
1508             p img {
1509                 float: right;
1510                 margin-left: 10px;
1511             }
1512             span#appname {
1513                 font-weight: bold;
1514                 font-size: 1.6em;
1515             }
1516         </style>
1517     </head>
1518     <body>
1519         <div id="content">
1520             <div id="topbar">
1521                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1522                     $VERSION</h1>
1523              </div>
1524              <div id="answers">
1525                  <p>
1526                  <img src="$logo" alt="Catalyst Logo" />
1527                  </p>
1528                  <p>Welcome to the  world of Catalyst.
1529                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1530                     framework will make web development something you had
1531                     never expected it to be: Fun, rewarding, and quick.</p>
1532                  <h2>What to do now?</h2>
1533                  <p>That really depends  on what <b>you</b> want to do.
1534                     We do, however, provide you with a few starting points.</p>
1535                  <p>If you want to jump right into web development with Catalyst
1536                     you might want to start with a tutorial.</p>
1537 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1538 </pre>
1539 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1540 <pre>
1541 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1542 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1543 </code></pre>
1544                  <h2>What to do next?</h2>
1545                  <p>Next it's time to write an actual application. Use the
1546                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1547                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1548                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1549                     they can save you a lot of work.</p>
1550                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1551                     <p>Also, be sure to check out the vast and growing
1552                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1553                     you are likely to find what you need there.
1554                     </p>
1555
1556                  <h2>Need help?</h2>
1557                  <p>Catalyst has a very active community. Here are the main places to
1558                     get in touch with us.</p>
1559                  <ul>
1560                      <li>
1561                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1562                      </li>
1563                      <li>
1564                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1565                      </li>
1566                      <li>
1567                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1568                      </li>
1569                  </ul>
1570                  <h2>In conclusion</h2>
1571                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1572                     as we enjoyed making it. Please contact us if you have ideas
1573                     for improvement or other feedback.</p>
1574              </div>
1575          </div>
1576     </body>
1577 </html>
1578 EOF
1579 }
1580
1581 =head2 run_options
1582
1583 Contains a hash of options passed from the application script, including
1584 the original ARGV the script received, the processed values from that
1585 ARGV and any extra arguments to the script which were not processed.
1586
1587 This can be used to add custom options to your application's scripts
1588 and setup your application differently depending on the values of these
1589 options.
1590
1591 =head1 INTERNAL METHODS
1592
1593 These methods are not meant to be used by end users.
1594
1595 =head2 $c->components
1596
1597 Returns a hash of components.
1598
1599 =head2 $c->context_class
1600
1601 Returns or sets the context class.
1602
1603 =head2 $c->counter
1604
1605 Returns a hashref containing coderefs and execution counts (needed for
1606 deep recursion detection).
1607
1608 =head2 $c->depth
1609
1610 Returns the number of actions on the current internal execution stack.
1611
1612 =head2 $c->dispatch
1613
1614 Dispatches a request to actions.
1615
1616 =cut
1617
1618 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1619
1620 =head2 $c->dispatcher_class
1621
1622 Returns or sets the dispatcher class.
1623
1624 =head2 $c->dump_these
1625
1626 Returns a list of 2-element array references (name, structure) pairs
1627 that will be dumped on the error page in debug mode.
1628
1629 =cut
1630
1631 sub dump_these {
1632     my $c = shift;
1633     [ Request => $c->req ],
1634     [ Response => $c->res ],
1635     [ Stash => $c->stash ],
1636     [ Config => $c->config ];
1637 }
1638
1639 =head2 $c->engine_class
1640
1641 Returns or sets the engine class.
1642
1643 =head2 $c->execute( $class, $coderef )
1644
1645 Execute a coderef in given class and catch exceptions. Errors are available
1646 via $c->error.
1647
1648 =cut
1649
1650 sub execute {
1651     my ( $c, $class, $code ) = @_;
1652     $class = $c->component($class) || $class;
1653     $c->state(0);
1654
1655     if ( $c->depth >= $RECURSION ) {
1656         my $action = $code->reverse();
1657         $action = "/$action" unless $action =~ /->/;
1658         my $error = qq/Deep recursion detected calling "${action}"/;
1659         $c->log->error($error);
1660         $c->error($error);
1661         $c->state(0);
1662         return $c->state;
1663     }
1664
1665     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1666
1667     push( @{ $c->stack }, $code );
1668
1669     no warnings 'recursion';
1670     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1671     #      I have no idea how, ergo $ret (which appears to fix the issue)
1672     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1673
1674     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1675
1676     my $last = pop( @{ $c->stack } );
1677
1678     if ( my $error = $@ ) {
1679         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1680             $error->rethrow if $c->depth > 1;
1681         }
1682         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1683             $error->rethrow if $c->depth > 0;
1684         }
1685         else {
1686             unless ( ref $error ) {
1687                 no warnings 'uninitialized';
1688                 chomp $error;
1689                 my $class = $last->class;
1690                 my $name  = $last->name;
1691                 $error = qq/Caught exception in $class->$name "$error"/;
1692             }
1693             $c->error($error);
1694         }
1695         $c->state(0);
1696     }
1697     return $c->state;
1698 }
1699
1700 sub _stats_start_execute {
1701     my ( $c, $code ) = @_;
1702     my $appclass = ref($c) || $c;
1703     return if ( ( $code->name =~ /^_.*/ )
1704         && ( !$appclass->config->{show_internal_actions} ) );
1705
1706     my $action_name = $code->reverse();
1707     $c->counter->{$action_name}++;
1708
1709     my $action = $action_name;
1710     $action = "/$action" unless $action =~ /->/;
1711
1712     # determine if the call was the result of a forward
1713     # this is done by walking up the call stack and looking for a calling
1714     # sub of Catalyst::forward before the eval
1715     my $callsub = q{};
1716     for my $index ( 2 .. 11 ) {
1717         last
1718         if ( ( caller($index) )[0] eq 'Catalyst'
1719             && ( caller($index) )[3] eq '(eval)' );
1720
1721         if ( ( caller($index) )[3] =~ /forward$/ ) {
1722             $callsub = ( caller($index) )[3];
1723             $action  = "-> $action";
1724             last;
1725         }
1726     }
1727
1728     my $uid = $action_name . $c->counter->{$action_name};
1729
1730     # is this a root-level call or a forwarded call?
1731     if ( $callsub =~ /forward$/ ) {
1732         my $parent = $c->stack->[-1];
1733
1734         # forward, locate the caller
1735         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1736             $c->stats->profile(
1737                 begin  => $action,
1738                 parent => "$parent" . $c->counter->{"$parent"},
1739                 uid    => $uid,
1740             );
1741         }
1742         else {
1743
1744             # forward with no caller may come from a plugin
1745             $c->stats->profile(
1746                 begin => $action,
1747                 uid   => $uid,
1748             );
1749         }
1750     }
1751     else {
1752
1753         # root-level call
1754         $c->stats->profile(
1755             begin => $action,
1756             uid   => $uid,
1757         );
1758     }
1759     return $action;
1760
1761 }
1762
1763 sub _stats_finish_execute {
1764     my ( $c, $info ) = @_;
1765     $c->stats->profile( end => $info );
1766 }
1767
1768 =head2 $c->finalize
1769
1770 Finalizes the request.
1771
1772 =cut
1773
1774 sub finalize {
1775     my $c = shift;
1776
1777     for my $error ( @{ $c->error } ) {
1778         $c->log->error($error);
1779     }
1780
1781     # Allow engine to handle finalize flow (for POE)
1782     my $engine = $c->engine;
1783     if ( my $code = $engine->can('finalize') ) {
1784         $engine->$code($c);
1785     }
1786     else {
1787
1788         $c->finalize_uploads;
1789
1790         # Error
1791         if ( $#{ $c->error } >= 0 ) {
1792             $c->finalize_error;
1793         }
1794
1795         $c->finalize_headers unless $c->response->finalized_headers;
1796
1797         # HEAD request
1798         if ( $c->request->method eq 'HEAD' ) {
1799             $c->response->body('');
1800         }
1801
1802         $c->finalize_body;
1803     }
1804
1805     $c->log_response;
1806
1807     if ($c->use_stats) {
1808         my $elapsed = sprintf '%f', $c->stats->elapsed;
1809         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1810         $c->log->info(
1811             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1812     }
1813
1814     return $c->response->status;
1815 }
1816
1817 =head2 $c->finalize_body
1818
1819 Finalizes body.
1820
1821 =cut
1822
1823 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1824
1825 =head2 $c->finalize_cookies
1826
1827 Finalizes cookies.
1828
1829 =cut
1830
1831 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1832
1833 =head2 $c->finalize_error
1834
1835 Finalizes error.
1836
1837 =cut
1838
1839 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1840
1841 =head2 $c->finalize_headers
1842
1843 Finalizes headers.
1844
1845 =cut
1846
1847 sub finalize_headers {
1848     my $c = shift;
1849
1850     my $response = $c->response; #accessor calls can add up?
1851
1852     # Check if we already finalized headers
1853     return if $response->finalized_headers;
1854
1855     # Handle redirects
1856     if ( my $location = $response->redirect ) {
1857         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1858         $response->header( Location => $location );
1859
1860         if ( !$response->has_body ) {
1861             # Add a default body if none is already present
1862             $response->body(<<"EOF");
1863 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1864 <html xmlns="http://www.w3.org/1999/xhtml">
1865   <head>
1866     <title>Moved</title>
1867   </head>
1868   <body>
1869      <p>This item has moved <a href="$location">here</a>.</p>
1870   </body>
1871 </html>
1872 EOF
1873             $response->content_type('text/html; charset=utf-8');
1874         }
1875     }
1876
1877     # Content-Length
1878     if ( defined $response->body && length $response->body && !$response->content_length ) {
1879
1880         # get the length from a filehandle
1881         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1882         {
1883             my $size = -s $response->body;
1884             if ( $size ) {
1885                 $response->content_length( $size );
1886             }
1887             else {
1888                 $c->log->warn('Serving filehandle without a content-length');
1889             }
1890         }
1891         else {
1892             # everything should be bytes at this point, but just in case
1893             $response->content_length( length( $response->body ) );
1894         }
1895     }
1896
1897     # Errors
1898     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1899         $response->headers->remove_header("Content-Length");
1900         $response->body('');
1901     }
1902
1903     $c->finalize_cookies;
1904
1905     $c->response->finalize_headers();
1906
1907     # Done
1908     $response->finalized_headers(1);
1909 }
1910
1911 =head2 $c->finalize_output
1912
1913 An alias for finalize_body.
1914
1915 =head2 $c->finalize_read
1916
1917 Finalizes the input after reading is complete.
1918
1919 =cut
1920
1921 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1922
1923 =head2 $c->finalize_uploads
1924
1925 Finalizes uploads. Cleans up any temporary files.
1926
1927 =cut
1928
1929 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1930
1931 =head2 $c->get_action( $action, $namespace )
1932
1933 Gets an action in a given namespace.
1934
1935 =cut
1936
1937 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1938
1939 =head2 $c->get_actions( $action, $namespace )
1940
1941 Gets all actions of a given name in a namespace and all parent
1942 namespaces.
1943
1944 =cut
1945
1946 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1947
1948 =head2 $app->handle_request( @arguments )
1949
1950 Called to handle each HTTP request.
1951
1952 =cut
1953
1954 sub handle_request {
1955     my ( $class, @arguments ) = @_;
1956
1957     # Always expect worst case!
1958     my $status = -1;
1959     try {
1960         if ($class->debug) {
1961             my $secs = time - $START || 1;
1962             my $av = sprintf '%.3f', $COUNT / $secs;
1963             my $time = localtime time;
1964             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1965         }
1966
1967         my $c = $class->prepare(@arguments);
1968         $c->dispatch;
1969         $status = $c->finalize;
1970     }
1971     catch {
1972         chomp(my $error = $_);
1973         $class->log->error(qq/Caught exception in engine "$error"/);
1974     };
1975
1976     $COUNT++;
1977
1978     if(my $coderef = $class->log->can('_flush')){
1979         $class->log->$coderef();
1980     }
1981     return $status;
1982 }
1983
1984 =head2 $class->prepare( @arguments )
1985
1986 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1987 etc.).
1988
1989 =cut
1990
1991 has _uploadtmp => (
1992     is => 'ro',
1993     predicate => '_has_uploadtmp',
1994 );
1995
1996 sub prepare {
1997     my ( $class, @arguments ) = @_;
1998
1999     # XXX
2000     # After the app/ctxt split, this should become an attribute based on something passed
2001     # into the application.
2002     $class->context_class( ref $class || $class ) unless $class->context_class;
2003
2004     my $uploadtmp = $class->config->{uploadtmp};
2005     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2006
2007     $c->response->_context($c);
2008
2009     #surely this is not the most efficient way to do things...
2010     $c->stats($class->stats_class->new)->enable($c->use_stats);
2011     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2012         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2013     }
2014
2015     try {
2016         # Allow engine to direct the prepare flow (for POE)
2017         if ( my $prepare = $c->engine->can('prepare') ) {
2018             $c->engine->$prepare( $c, @arguments );
2019         }
2020         else {
2021             $c->prepare_request(@arguments);
2022             $c->prepare_connection;
2023             $c->prepare_query_parameters;
2024             $c->prepare_headers; # Just hooks, no longer needed - they just
2025             $c->prepare_cookies; # cause the lazy attribute on req to build
2026             $c->prepare_path;
2027
2028             # Prepare the body for reading, either by prepare_body
2029             # or the user, if they are using $c->read
2030             $c->prepare_read;
2031
2032             # Parse the body unless the user wants it on-demand
2033             unless ( ref($c)->config->{parse_on_demand} ) {
2034                 $c->prepare_body;
2035             }
2036         }
2037         $c->prepare_action;
2038     }
2039     # VERY ugly and probably shouldn't rely on ->finalize actually working
2040     catch {
2041         # failed prepare is always due to an invalid request, right?
2042         $c->response->status(400);
2043         $c->response->content_type('text/plain');
2044         $c->response->body('Bad Request');
2045         # Note we call finalize and then die here, which escapes
2046         # finalize being called in the enclosing block..
2047         # It in fact couldn't be called, as we don't return $c..
2048         # This is a mess - but I'm unsure you can fix this without
2049         # breaking compat for people doing crazy things (we should set
2050         # the 400 and just return the ctx here IMO, letting finalize get called
2051         # above...
2052         $c->finalize;
2053         die $_;
2054     };
2055
2056     $c->log_request;
2057
2058     return $c;
2059 }
2060
2061 =head2 $c->prepare_action
2062
2063 Prepares action. See L<Catalyst::Dispatcher>.
2064
2065 =cut
2066
2067 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2068
2069 =head2 $c->prepare_body
2070
2071 Prepares message body.
2072
2073 =cut
2074
2075 sub prepare_body {
2076     my $c = shift;
2077
2078     return if $c->request->_has_body;
2079
2080     # Initialize on-demand data
2081     $c->engine->prepare_body( $c, @_ );
2082     $c->prepare_parameters;
2083     $c->prepare_uploads;
2084 }
2085
2086 =head2 $c->prepare_body_chunk( $chunk )
2087
2088 Prepares a chunk of data before sending it to L<HTTP::Body>.
2089
2090 See L<Catalyst::Engine>.
2091
2092 =cut
2093
2094 sub prepare_body_chunk {
2095     my $c = shift;
2096     $c->engine->prepare_body_chunk( $c, @_ );
2097 }
2098
2099 =head2 $c->prepare_body_parameters
2100
2101 Prepares body parameters.
2102
2103 =cut
2104
2105 sub prepare_body_parameters {
2106     my $c = shift;
2107     $c->engine->prepare_body_parameters( $c, @_ );
2108 }
2109
2110 =head2 $c->prepare_connection
2111
2112 Prepares connection.
2113
2114 =cut
2115
2116 sub prepare_connection {
2117     my $c = shift;
2118     # XXX - This is called on the engine (not the request) to maintain
2119     #       Engine::PSGI back compat.
2120     $c->engine->prepare_connection($c);
2121 }
2122
2123 =head2 $c->prepare_cookies
2124
2125 Prepares cookies by ensuring that the attribute on the request
2126 object has been built.
2127
2128 =cut
2129
2130 sub prepare_cookies { my $c = shift; $c->request->cookies }
2131
2132 =head2 $c->prepare_headers
2133
2134 Prepares request headers by ensuring that the attribute on the request
2135 object has been built.
2136
2137 =cut
2138
2139 sub prepare_headers { my $c = shift; $c->request->headers }
2140
2141 =head2 $c->prepare_parameters
2142
2143 Prepares parameters.
2144
2145 =cut
2146
2147 sub prepare_parameters {
2148     my $c = shift;
2149     $c->prepare_body_parameters;
2150     $c->engine->prepare_parameters( $c, @_ );
2151 }
2152
2153 =head2 $c->prepare_path
2154
2155 Prepares path and base.
2156
2157 =cut
2158
2159 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2160
2161 =head2 $c->prepare_query_parameters
2162
2163 Prepares query parameters.
2164
2165 =cut
2166
2167 sub prepare_query_parameters {
2168     my $c = shift;
2169
2170     $c->engine->prepare_query_parameters( $c, @_ );
2171 }
2172
2173 =head2 $c->log_request
2174
2175 Writes information about the request to the debug logs.  This includes:
2176
2177 =over 4
2178
2179 =item * Request method, path, and remote IP address
2180
2181 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2182
2183 =item * Request parameters
2184
2185 =item * File uploads
2186
2187 =back
2188
2189 =cut
2190
2191 sub log_request {
2192     my $c = shift;
2193
2194     return unless $c->debug;
2195
2196     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2197     my $request = $dump->[1];
2198
2199     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2200     $method ||= '';
2201     $path = '/' unless length $path;
2202     $address ||= '';
2203     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2204
2205     $c->log_request_headers($request->headers);
2206
2207     if ( my $keywords = $request->query_keywords ) {
2208         $c->log->debug("Query keywords are: $keywords");
2209     }
2210
2211     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2212
2213     $c->log_request_uploads($request);
2214 }
2215
2216 =head2 $c->log_response
2217
2218 Writes information about the response to the debug logs by calling
2219 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2220
2221 =cut
2222
2223 sub log_response {
2224     my $c = shift;
2225
2226     return unless $c->debug;
2227
2228     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2229     my $response = $dump->[1];
2230
2231     $c->log_response_status_line($response);
2232     $c->log_response_headers($response->headers);
2233 }
2234
2235 =head2 $c->log_response_status_line($response)
2236
2237 Writes one line of information about the response to the debug logs.  This includes:
2238
2239 =over 4
2240
2241 =item * Response status code
2242
2243 =item * Content-Type header (if present)
2244
2245 =item * Content-Length header (if present)
2246
2247 =back
2248
2249 =cut
2250
2251 sub log_response_status_line {
2252     my ($c, $response) = @_;
2253
2254     $c->log->debug(
2255         sprintf(
2256             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2257             $response->status                            || 'unknown',
2258             $response->headers->header('Content-Type')   || 'unknown',
2259             $response->headers->header('Content-Length') || 'unknown'
2260         )
2261     );
2262 }
2263
2264 =head2 $c->log_response_headers($headers);
2265
2266 Hook method which can be wrapped by plugins to log the response headers.
2267 No-op in the default implementation.
2268
2269 =cut
2270
2271 sub log_response_headers {}
2272
2273 =head2 $c->log_request_parameters( query => {}, body => {} )
2274
2275 Logs request parameters to debug logs
2276
2277 =cut
2278
2279 sub log_request_parameters {
2280     my $c          = shift;
2281     my %all_params = @_;
2282
2283     return unless $c->debug;
2284
2285     my $column_width = Catalyst::Utils::term_width() - 44;
2286     foreach my $type (qw(query body)) {
2287         my $params = $all_params{$type};
2288         next if ! keys %$params;
2289         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2290         for my $key ( sort keys %$params ) {
2291             my $param = $params->{$key};
2292             my $value = defined($param) ? $param : '';
2293             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2294         }
2295         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2296     }
2297 }
2298
2299 =head2 $c->log_request_uploads
2300
2301 Logs file uploads included in the request to the debug logs.
2302 The parameter name, filename, file type, and file size are all included in
2303 the debug logs.
2304
2305 =cut
2306
2307 sub log_request_uploads {
2308     my $c = shift;
2309     my $request = shift;
2310     return unless $c->debug;
2311     my $uploads = $request->uploads;
2312     if ( keys %$uploads ) {
2313         my $t = Text::SimpleTable->new(
2314             [ 12, 'Parameter' ],
2315             [ 26, 'Filename' ],
2316             [ 18, 'Type' ],
2317             [ 9,  'Size' ]
2318         );
2319         for my $key ( sort keys %$uploads ) {
2320             my $upload = $uploads->{$key};
2321             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2322                 $t->row( $key, $u->filename, $u->type, $u->size );
2323             }
2324         }
2325         $c->log->debug( "File Uploads are:\n" . $t->draw );
2326     }
2327 }
2328
2329 =head2 $c->log_request_headers($headers);
2330
2331 Hook method which can be wrapped by plugins to log the request headers.
2332 No-op in the default implementation.
2333
2334 =cut
2335
2336 sub log_request_headers {}
2337
2338 =head2 $c->log_headers($type => $headers)
2339
2340 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2341
2342 =cut
2343
2344 sub log_headers {
2345     my $c       = shift;
2346     my $type    = shift;
2347     my $headers = shift;    # an HTTP::Headers instance
2348
2349     return unless $c->debug;
2350
2351     my $column_width = Catalyst::Utils::term_width() - 28;
2352     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2353     $headers->scan(
2354         sub {
2355             my ( $name, $value ) = @_;
2356             $t->row( $name, $value );
2357         }
2358     );
2359     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2360 }
2361
2362
2363 =head2 $c->prepare_read
2364
2365 Prepares the input for reading.
2366
2367 =cut
2368
2369 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2370
2371 =head2 $c->prepare_request
2372
2373 Prepares the engine request.
2374
2375 =cut
2376
2377 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2378
2379 =head2 $c->prepare_uploads
2380
2381 Prepares uploads.
2382
2383 =cut
2384
2385 sub prepare_uploads {
2386     my $c = shift;
2387
2388     $c->engine->prepare_uploads( $c, @_ );
2389 }
2390
2391 =head2 $c->prepare_write
2392
2393 Prepares the output for writing.
2394
2395 =cut
2396
2397 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2398
2399 =head2 $c->request_class
2400
2401 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2402
2403 =head2 $c->response_class
2404
2405 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2406
2407 =head2 $c->read( [$maxlength] )
2408
2409 Reads a chunk of data from the request body. This method is designed to
2410 be used in a while loop, reading C<$maxlength> bytes on every call.
2411 C<$maxlength> defaults to the size of the request if not specified.
2412
2413 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2414 directly.
2415
2416 Warning: If you use read(), Catalyst will not process the body,
2417 so you will not be able to access POST parameters or file uploads via
2418 $c->request.  You must handle all body parsing yourself.
2419
2420 =cut
2421
2422 sub read { my $c = shift; return $c->request->read( @_ ) }
2423
2424 =head2 $c->run
2425
2426 Starts the engine.
2427
2428 =cut
2429
2430 sub run {
2431   my $app = shift;
2432   $app->_make_immutable_if_needed;
2433   $app->engine_loader->needs_psgi_engine_compat_hack ?
2434     $app->engine->run($app, @_) :
2435       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2436 }
2437
2438 sub _make_immutable_if_needed {
2439     my $class = shift;
2440     my $meta = Class::MOP::get_metaclass_by_name($class);
2441     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2442     if (
2443         $meta->is_immutable
2444         && ! { $meta->immutable_options }->{replace_constructor}
2445         && $isa_ca
2446     ) {
2447         warn("You made your application class ($class) immutable, "
2448             . "but did not inline the\nconstructor. "
2449             . "This will break catalyst, as your app \@ISA "
2450             . "Class::Accessor(::Fast)?\nPlease pass "
2451             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2452     }
2453     unless ($meta->is_immutable) {
2454         # XXX - FIXME warning here as you should make your app immutable yourself.
2455         $meta->make_immutable(
2456             replace_constructor => 1,
2457         );
2458     }
2459 }
2460
2461 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2462
2463 Sets an action in a given namespace.
2464
2465 =cut
2466
2467 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2468
2469 =head2 $c->setup_actions($component)
2470
2471 Sets up actions for a component.
2472
2473 =cut
2474
2475 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2476
2477 =head2 $c->setup_components
2478
2479 This method is called internally to set up the application's components.
2480
2481 It finds modules by calling the L<locate_components> method, expands them to
2482 package names with the L<expand_component_module> method, and then installs
2483 each component into the application.
2484
2485 The C<setup_components> config option is passed to both of the above methods.
2486
2487 Installation of each component is performed by the L<setup_component> method,
2488 below.
2489
2490 =cut
2491
2492 sub setup_components {
2493     my $class = shift;
2494
2495     my $config  = $class->config->{ setup_components };
2496
2497     my @comps = $class->locate_components($config);
2498     my %comps = map { $_ => 1 } @comps;
2499
2500     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2501     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2502         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2503     ) if $deprecatedcatalyst_component_names;
2504
2505     for my $component ( @comps ) {
2506
2507         # We pass ignore_loaded here so that overlay files for (e.g.)
2508         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2509         # we know M::P::O found a file on disk so this is safe
2510
2511         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2512     }
2513
2514     for my $component (@comps) {
2515         my $instance = $class->components->{ $component } = $class->setup_component($component);
2516         my @expanded_components = $instance->can('expand_modules')
2517             ? $instance->expand_modules( $component, $config )
2518             : $class->expand_component_module( $component, $config );
2519         for my $component (@expanded_components) {
2520             next if $comps{$component};
2521             $class->components->{ $component } = $class->setup_component($component);
2522         }
2523     }
2524 }
2525
2526 =head2 $c->locate_components( $setup_component_config )
2527
2528 This method is meant to provide a list of component modules that should be
2529 setup for the application.  By default, it will use L<Module::Pluggable>.
2530
2531 Specify a C<setup_components> config option to pass additional options directly
2532 to L<Module::Pluggable>. To add additional search paths, specify a key named
2533 C<search_extra> as an array reference. Items in the array beginning with C<::>
2534 will have the application class name prepended to them.
2535
2536 =cut
2537
2538 sub locate_components {
2539     my $class  = shift;
2540     my $config = shift;
2541
2542     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2543     my $extra   = delete $config->{ search_extra } || [];
2544
2545     push @paths, @$extra;
2546
2547     my $locator = Module::Pluggable::Object->new(
2548         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2549         %$config
2550     );
2551
2552     # XXX think about ditching this sort entirely
2553     my @comps = sort { length $a <=> length $b } $locator->plugins;
2554
2555     return @comps;
2556 }
2557
2558 =head2 $c->expand_component_module( $component, $setup_component_config )
2559
2560 Components found by C<locate_components> will be passed to this method, which
2561 is expected to return a list of component (package) names to be set up.
2562
2563 =cut
2564
2565 sub expand_component_module {
2566     my ($class, $module) = @_;
2567     return Devel::InnerPackage::list_packages( $module );
2568 }
2569
2570 =head2 $c->setup_component
2571
2572 =cut
2573
2574 sub setup_component {
2575     my( $class, $component ) = @_;
2576
2577     unless ( $component->can( 'COMPONENT' ) ) {
2578         return $component;
2579     }
2580
2581     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2582     my $config = $class->config->{ $suffix } || {};
2583     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2584     # methods also pass it. local to avoid pointlessly shitting in config
2585     # for the debug screen, as $component is already the key name.
2586     local $config->{catalyst_component_name} = $component;
2587
2588     my $instance = eval { $component->COMPONENT( $class, $config ); };
2589
2590     if ( my $error = $@ ) {
2591         chomp $error;
2592         Catalyst::Exception->throw(
2593             message => qq/Couldn't instantiate component "$component", "$error"/
2594         );
2595     }
2596
2597     unless (blessed $instance) {
2598         my $metaclass = Moose::Util::find_meta($component);
2599         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2600         my $component_method_from = $method_meta->associated_metaclass->name;
2601         my $value = defined($instance) ? $instance : 'undef';
2602         Catalyst::Exception->throw(
2603             message =>
2604             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2605         );
2606     }
2607     return $instance;
2608 }
2609
2610 =head2 $c->setup_dispatcher
2611
2612 Sets up dispatcher.
2613
2614 =cut
2615
2616 sub setup_dispatcher {
2617     my ( $class, $dispatcher ) = @_;
2618
2619     if ($dispatcher) {
2620         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2621     }
2622
2623     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2624         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2625     }
2626
2627     unless ($dispatcher) {
2628         $dispatcher = $class->dispatcher_class;
2629     }
2630
2631     Class::MOP::load_class($dispatcher);
2632
2633     # dispatcher instance
2634     $class->dispatcher( $dispatcher->new );
2635 }
2636
2637 =head2 $c->setup_engine
2638
2639 Sets up engine.
2640
2641 =cut
2642
2643 sub engine_class {
2644     my ($class, $requested_engine) = @_;
2645
2646     if (!$class->engine_loader || $requested_engine) {
2647         $class->engine_loader(
2648             Catalyst::EngineLoader->new({
2649                 application_name => $class,
2650                 (defined $requested_engine
2651                      ? (catalyst_engine_class => $requested_engine) : ()),
2652             }),
2653         );
2654     }
2655
2656     $class->engine_loader->catalyst_engine_class;
2657 }
2658
2659 sub setup_engine {
2660     my ($class, $requested_engine) = @_;
2661
2662     my $engine = do {
2663         my $loader = $class->engine_loader;
2664
2665         if (!$loader || $requested_engine) {
2666             $loader = Catalyst::EngineLoader->new({
2667                 application_name => $class,
2668                 (defined $requested_engine
2669                      ? (requested_engine => $requested_engine) : ()),
2670             }),
2671
2672             $class->engine_loader($loader);
2673         }
2674
2675         $loader->catalyst_engine_class;
2676     };
2677
2678     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2679     return if $class->loading_psgi_file;
2680
2681     Class::MOP::load_class($engine);
2682
2683     if ($ENV{MOD_PERL}) {
2684         my $apache = $class->engine_loader->auto;
2685
2686         my $meta = find_meta($class);
2687         my $was_immutable = $meta->is_immutable;
2688         my %immutable_options = $meta->immutable_options;
2689         $meta->make_mutable if $was_immutable;
2690
2691         $meta->add_method(handler => sub {
2692             my $r = shift;
2693             my $psgi_app = $class->_finalized_psgi_app;
2694             $apache->call_app($r, $psgi_app);
2695         });
2696
2697         $meta->make_immutable(%immutable_options) if $was_immutable;
2698     }
2699
2700     $class->engine( $engine->new );
2701
2702     return;
2703 }
2704
2705 sub _finalized_psgi_app {
2706     my ($app) = @_;
2707
2708     unless ($app->_psgi_app) {
2709         my $psgi_app = $app->_setup_psgi_app;
2710         $app->_psgi_app($psgi_app);
2711     }
2712
2713     return $app->_psgi_app;
2714 }
2715
2716 sub _setup_psgi_app {
2717     my ($app) = @_;
2718
2719     for my $home (Path::Class::Dir->new($app->config->{home})) {
2720         my $psgi_file = $home->file(
2721             Catalyst::Utils::appprefix($app) . '.psgi',
2722         );
2723
2724         next unless -e $psgi_file;
2725
2726         # If $psgi_file calls ->setup_engine, it's doing so to load
2727         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2728         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2729         # anyway. So set a flag (ick) that tells setup_engine not to populate
2730         # $c->engine or do any other things we might regret.
2731
2732         $app->loading_psgi_file(1);
2733         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2734         $app->loading_psgi_file(0);
2735
2736         return $psgi_app
2737             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2738
2739         warn <<"EOW";
2740 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2741
2742 Its content has been ignored. Please consult the Catalyst::Upgrading
2743 documentation on how to upgrade from Catalyst::Engine::PSGI.
2744 EOW
2745     }
2746
2747     return $app->apply_default_middlewares($app->psgi_app);
2748 }
2749
2750 =head2 $c->apply_default_middlewares
2751
2752 Adds the following L<Plack> middlewares to your application, since they are
2753 useful and commonly needed:
2754
2755 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2756 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2757 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2758 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2759 applied since this middleware is smart enough to conditionally apply itself).
2760
2761 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2762 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2763 $ENV{SCRIPT_NAME}
2764
2765 =cut
2766
2767
2768 sub apply_default_middlewares {
2769     my ($app, $psgi_app) = @_;
2770
2771     $psgi_app = Plack::Middleware::Conditional->wrap(
2772         $psgi_app,
2773         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2774         condition => sub {
2775             my ($env) = @_;
2776             return if $app->config->{ignore_frontend_proxy};
2777             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2778                 || $app->config->{using_frontend_proxy};
2779         },
2780     );
2781
2782     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2783     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2784     $psgi_app = Plack::Middleware::Conditional->wrap(
2785         $psgi_app,
2786         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2787         condition => sub {
2788             my ($env) = @_;
2789             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2790             return unless $1 < 4.23;
2791             1;
2792         },
2793     );
2794
2795     # we're applying this unconditionally as the middleware itself already makes
2796     # sure it doesn't fuck things up if it's not running under one of the right
2797     # IIS versions
2798     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2799
2800     # And another IIS issue, this time with IIS7.
2801     $psgi_app = Plack::Middleware::Conditional->wrap(
2802         $psgi_app,
2803         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2804         condition => sub {
2805             my ($env) = @_;
2806             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2807         },
2808     );
2809
2810     return $psgi_app;
2811 }
2812
2813 =head2 $c->psgi_app
2814
2815 Returns a PSGI application code reference for the catalyst application
2816 C<$c>. This is the bare application without any middlewares
2817 applied. C<${myapp}.psgi> is not taken into account.
2818
2819 This is what you want to be using to retrieve the PSGI application code
2820 reference of your Catalyst application for use in F<.psgi> files.
2821
2822 =cut
2823
2824 sub psgi_app {
2825     my ($app) = @_;
2826     return $app->engine->build_psgi_app($app);
2827 }
2828
2829 =head2 $c->setup_home
2830
2831 Sets up the home directory.
2832
2833 =cut
2834
2835 sub setup_home {
2836     my ( $class, $home ) = @_;
2837
2838     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2839         $home = $env;
2840     }
2841
2842     $home ||= Catalyst::Utils::home($class);
2843
2844     if ($home) {
2845         #I remember recently being scolded for assigning config values like this
2846         $class->config->{home} ||= $home;
2847         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2848     }
2849 }
2850
2851 =head2 $c->setup_log
2852
2853 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2854 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2855 log to.
2856
2857 This method also installs a C<debug> method that returns a true value into the
2858 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2859 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2860
2861 Note that if the log has already been setup, by either a previous call to
2862 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2863 that this method won't actually set up the log object.
2864
2865 =cut
2866
2867 sub setup_log {
2868     my ( $class, $levels ) = @_;
2869
2870     $levels ||= '';
2871     $levels =~ s/^\s+//;
2872     $levels =~ s/\s+$//;
2873     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2874
2875     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2876     if ( defined $env_debug ) {
2877         $levels{debug} = 1 if $env_debug; # Ugly!
2878         delete($levels{debug}) unless $env_debug;
2879     }
2880
2881     unless ( $class->log ) {
2882         $class->log( Catalyst::Log->new(keys %levels) );
2883     }
2884
2885     if ( $levels{debug} ) {
2886         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2887         $class->log->debug('Debug messages enabled');
2888     }
2889 }
2890
2891 =head2 $c->setup_plugins
2892
2893 Sets up plugins.
2894
2895 =cut
2896
2897 =head2 $c->setup_stats
2898
2899 Sets up timing statistics class.
2900
2901 =cut
2902
2903 sub setup_stats {
2904     my ( $class, $stats ) = @_;
2905
2906     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2907
2908     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2909     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2910         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2911         $class->log->debug('Statistics enabled');
2912     }
2913 }
2914
2915
2916 =head2 $c->registered_plugins
2917
2918 Returns a sorted list of the plugins which have either been stated in the
2919 import list.
2920
2921 If passed a given plugin name, it will report a boolean value indicating
2922 whether or not that plugin is loaded.  A fully qualified name is required if
2923 the plugin name does not begin with C<Catalyst::Plugin::>.
2924
2925  if ($c->registered_plugins('Some::Plugin')) {
2926      ...
2927  }
2928
2929 =cut
2930
2931 {
2932
2933     sub registered_plugins {
2934         my $proto = shift;
2935         return sort keys %{ $proto->_plugins } unless @_;
2936         my $plugin = shift;
2937         return 1 if exists $proto->_plugins->{$plugin};
2938         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2939     }
2940
2941     sub _register_plugin {
2942         my ( $proto, $plugin, $instant ) = @_;
2943         my $class = ref $proto || $proto;
2944
2945         Class::MOP::load_class( $plugin );
2946         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2947             if $plugin->isa( 'Catalyst::Component' );
2948         my $plugin_meta = Moose::Meta::Class->create($plugin);
2949         if (!$plugin_meta->has_method('new')
2950             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
2951             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
2952         }
2953         if (!$instant && !$proto->_plugins->{$plugin}) {
2954             my $meta = Class::MOP::get_metaclass_by_name($class);
2955             $meta->superclasses($plugin, $meta->superclasses);
2956         }
2957         $proto->_plugins->{$plugin} = 1;
2958         return $class;
2959     }
2960
2961     sub setup_plugins {
2962         my ( $class, $plugins ) = @_;
2963
2964         $class->_plugins( {} ) unless $class->_plugins;
2965         $plugins = Data::OptList::mkopt($plugins || []);
2966
2967         my @plugins = map {
2968             [ Catalyst::Utils::resolve_namespace(
2969                   $class . '::Plugin',
2970                   'Catalyst::Plugin', $_->[0]
2971               ),
2972               $_->[1],
2973             ]
2974          } @{ $plugins };
2975
2976         for my $plugin ( reverse @plugins ) {
2977             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2978             my $meta = find_meta($plugin->[0]);
2979             next if $meta && $meta->isa('Moose::Meta::Role');
2980
2981             $class->_register_plugin($plugin->[0]);
2982         }
2983
2984         my @roles =
2985             map  { $_->[0]->name, $_->[1] }
2986             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2987             map  { [find_meta($_->[0]), $_->[1]] }
2988             @plugins;
2989
2990         Moose::Util::apply_all_roles(
2991             $class => @roles
2992         ) if @roles;
2993     }
2994 }
2995
2996 =head2 $c->stack
2997
2998 Returns an arrayref of the internal execution stack (actions that are
2999 currently executing).
3000
3001 =head2 $c->stats
3002
3003 Returns the current timing statistics object. By default Catalyst uses
3004 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3005 L<< stats_class|/"$c->stats_class" >>.
3006
3007 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3008 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3009 profile explicitly, although MyApp.pm still won't profile nor output anything
3010 by itself.
3011
3012 =head2 $c->stats_class
3013
3014 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3015
3016 =head2 $c->use_stats
3017
3018 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3019
3020 Note that this is a static method, not an accessor and should be overridden
3021 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3022
3023 =cut
3024
3025 sub use_stats { 0 }
3026
3027
3028 =head2 $c->write( $data )
3029
3030 Writes $data to the output stream. When using this method directly, you
3031 will need to manually set the C<Content-Length> header to the length of
3032 your output data, if known.
3033
3034 =cut
3035
3036 sub write {
3037     my $c = shift;
3038
3039     # Finalize headers if someone manually writes output (for compat)
3040     $c->finalize_headers;
3041
3042     return $c->response->write( @_ );
3043 }
3044
3045 =head2 version
3046
3047 Returns the Catalyst version number. Mostly useful for "powered by"
3048 messages in template systems.
3049
3050 =cut
3051
3052 sub version { return $Catalyst::VERSION }
3053
3054 =head1 CONFIGURATION
3055
3056 There are a number of 'base' config variables which can be set:
3057
3058 =over
3059
3060 =item *
3061
3062 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3063
3064 =item *
3065
3066 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3067
3068 =item *
3069
3070 C<disable_component_resolution_regex_fallback> - Turns
3071 off the deprecated component resolution functionality so
3072 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3073 are called then regex search will not be attempted on string values and
3074 instead C<undef> will be returned.
3075
3076 =item *
3077
3078 C<home> - The application home directory. In an uninstalled application,
3079 this is the top level application directory. In an installed application,
3080 this will be the directory containing C<< MyApp.pm >>.
3081
3082 =item *
3083
3084 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3085
3086 =item *
3087
3088 C<name> - The name of the application in debug messages and the debug and
3089 welcome screens
3090
3091 =item *
3092
3093 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3094 until it is accessed. This allows you to (for example) check authentication (and reject
3095 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3096
3097 =item *
3098
3099 C<root> - The root directory for templates. Usually this is just a
3100 subdirectory of the home directory, but you can set it to change the
3101 templates to a different directory.
3102
3103 =item *
3104
3105 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3106 namespaces from which components will be loaded (and constructed and stored in
3107 C<< $c->components >>).
3108
3109 =item *
3110
3111 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3112 to be shown in hit debug tables in the test server.
3113
3114 =item *
3115
3116 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3117 variable should be used for determining the request path.
3118
3119 Most web server environments pass the requested path to the application using environment variables,
3120 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3121 exposed as C<< $c->request->base >>) and the request path below that base.
3122
3123 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3124 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3125
3126 =over
3127
3128 =item use_request_uri_for_path => 0
3129
3130 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3131 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3132 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3133 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3134
3135 However this method has the major disadvantage that it is impossible to correctly decode some elements
3136 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3137 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3138 can't distinguish / vs %2F in paths (in addition to other encoded values).
3139
3140 =item use_request_uri_for_path => 1
3141
3142 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3143 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3144 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3145
3146 Given that this method of path resolution is provably more correct, it is recommended that you use
3147 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3148 aware of the implications of not being able to handle encoded URI paths correctly.
3149
3150 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3151 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3152 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3153 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3154 C<< $c->request->base >> will be incorrect.
3155
3156 =back
3157
3158 =item *
3159
3160 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3161
3162 =back
3163
3164 =head1 INTERNAL ACTIONS
3165
3166 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3167 C<_ACTION>, and C<_END>. These are by default not shown in the private
3168 action table, but you can make them visible with a config parameter.
3169
3170     MyApp->config(show_internal_actions => 1);
3171
3172 =head1 ON-DEMAND PARSER
3173
3174 The request body is usually parsed at the beginning of a request,
3175 but if you want to handle input yourself, you can enable on-demand
3176 parsing with a config parameter.
3177
3178     MyApp->config(parse_on_demand => 1);
3179
3180 =head1 PROXY SUPPORT
3181
3182 Many production servers operate using the common double-server approach,
3183 with a lightweight frontend web server passing requests to a larger
3184 backend server. An application running on the backend server must deal
3185 with two problems: the remote user always appears to be C<127.0.0.1> and
3186 the server's hostname will appear to be C<localhost> regardless of the
3187 virtual host that the user connected through.
3188
3189 Catalyst will automatically detect this situation when you are running
3190 the frontend and backend servers on the same machine. The following
3191 changes are made to the request.
3192
3193     $c->req->address is set to the user's real IP address, as read from
3194     the HTTP X-Forwarded-For header.
3195
3196     The host value for $c->req->base and $c->req->uri is set to the real
3197     host, as read from the HTTP X-Forwarded-Host header.
3198
3199 Additionally, you may be running your backend application on an insecure
3200 connection (port 80) while your frontend proxy is running under SSL.  If there
3201 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3202 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3203 be created properly.
3204
3205 In the case of passing in:
3206
3207     X-Forwarded-Port: 443
3208
3209 All calls to C<uri_for> will result in an https link, as is expected.
3210
3211 Obviously, your web server must support these headers for this to work.
3212
3213 In a more complex server farm environment where you may have your
3214 frontend proxy server(s) on different machines, you will need to set a
3215 configuration option to tell Catalyst to read the proxied data from the
3216 headers.
3217
3218     MyApp->config(using_frontend_proxy => 1);
3219
3220 If you do not wish to use the proxy support at all, you may set:
3221
3222     MyApp->config(ignore_frontend_proxy => 0);
3223
3224 =head2 Note about psgi files
3225
3226 Note that if you supply your own .psgi file, calling
3227 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3228
3229 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3230 in your psgi, for example:
3231
3232     builder {
3233         enable "Plack::Middleware::ReverseProxy";
3234         MyApp->psgi_app
3235     };
3236
3237 This will unconditionally add the ReverseProxy support, or you need to call
3238 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3239 apply the support depending upon your config).
3240
3241 See L<Catalyst::PSGI> for more information.
3242
3243 =head1 THREAD SAFETY
3244
3245 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3246 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3247 believe the Catalyst core to be thread-safe.
3248
3249 If you plan to operate in a threaded environment, remember that all other
3250 modules you are using must also be thread-safe. Some modules, most notably
3251 L<DBD::SQLite>, are not thread-safe.
3252
3253 =head1 SUPPORT
3254
3255 IRC:
3256
3257     Join #catalyst on irc.perl.org.
3258
3259 Mailing Lists:
3260
3261     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3262     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3263
3264 Web:
3265
3266     http://catalyst.perl.org
3267
3268 Wiki:
3269
3270     http://dev.catalyst.perl.org
3271
3272 =head1 SEE ALSO
3273
3274 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3275
3276 =head2 L<Catalyst::Manual> - The Catalyst Manual
3277
3278 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3279
3280 =head2 L<Catalyst::Engine> - Core engine
3281
3282 =head2 L<Catalyst::Log> - Log class.
3283
3284 =head2 L<Catalyst::Request> - Request object
3285
3286 =head2 L<Catalyst::Response> - Response object
3287
3288 =head2 L<Catalyst::Test> - The test suite.
3289
3290 =head1 PROJECT FOUNDER
3291
3292 sri: Sebastian Riedel <sri@cpan.org>
3293
3294 =head1 CONTRIBUTORS
3295
3296 abw: Andy Wardley
3297
3298 acme: Leon Brocard <leon@astray.com>
3299
3300 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3301
3302 Andrew Bramble
3303
3304 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3305
3306 Andrew Ruthven
3307
3308 andyg: Andy Grundman <andy@hybridized.org>
3309
3310 audreyt: Audrey Tang
3311
3312 bricas: Brian Cassidy <bricas@cpan.org>
3313
3314 Caelum: Rafael Kitover <rkitover@io.com>
3315
3316 chansen: Christian Hansen
3317
3318 chicks: Christopher Hicks
3319
3320 Chisel Wright C<pause@herlpacker.co.uk>
3321
3322 Danijel Milicevic C<me@danijel.de>
3323
3324 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3325
3326 David Naughton, C<naughton@umn.edu>
3327
3328 David E. Wheeler
3329
3330 dhoss: Devin Austin <dhoss@cpan.org>
3331
3332 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3333
3334 Drew Taylor
3335
3336 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3337
3338 esskar: Sascha Kiefer
3339
3340 fireartist: Carl Franks <cfranks@cpan.org>
3341
3342 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3343
3344 gabb: Danijel Milicevic
3345
3346 Gary Ashton Jones
3347
3348 Gavin Henry C<ghenry@perl.me.uk>
3349
3350 Geoff Richards
3351
3352 groditi: Guillermo Roditi <groditi@gmail.com>
3353
3354 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3355
3356 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3357
3358 jcamacho: Juan Camacho
3359
3360 jester: Jesse Sheidlower C<jester@panix.com>
3361
3362 jhannah: Jay Hannah <jay@jays.net>
3363
3364 Jody Belka
3365
3366 Johan Lindstrom
3367
3368 jon: Jon Schutz <jjschutz@cpan.org>
3369
3370 Jonathan Rockway C<< <jrockway@cpan.org> >>
3371
3372 Kieren Diment C<kd@totaldatasolution.com>
3373
3374 konobi: Scott McWhirter <konobi@cpan.org>
3375
3376 marcus: Marcus Ramberg <mramberg@cpan.org>
3377
3378 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3379
3380 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3381
3382 mugwump: Sam Vilain
3383
3384 naughton: David Naughton
3385
3386 ningu: David Kamholz <dkamholz@cpan.org>
3387
3388 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3389
3390 numa: Dan Sully <daniel@cpan.org>
3391
3392 obra: Jesse Vincent
3393
3394 Octavian Rasnita
3395
3396 omega: Andreas Marienborg
3397
3398 Oleg Kostyuk <cub.uanic@gmail.com>
3399
3400 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3401
3402 rafl: Florian Ragwitz <rafl@debian.org>
3403
3404 random: Roland Lammel <lammel@cpan.org>
3405
3406 Robert Sedlacek C<< <rs@474.at> >>
3407
3408 SpiceMan: Marcel Montes
3409
3410 sky: Arthur Bergman
3411
3412 szbalint: Balint Szilakszi <szbalint@cpan.org>
3413
3414 t0m: Tomas Doran <bobtfish@bobtfish.net>
3415
3416 Ulf Edvinsson
3417
3418 Viljo Marrandi C<vilts@yahoo.com>
3419
3420 Will Hawes C<info@whawes.co.uk>
3421
3422 willert: Sebastian Willert <willert@cpan.org>
3423
3424 wreis: Wallace Reis <wallace@reis.org.br>
3425
3426 Yuval Kogman, C<nothingmuch@woobling.org>
3427
3428 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3429
3430 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3431
3432 =head1 COPYRIGHT
3433
3434 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3435
3436 =head1 LICENSE
3437
3438 This library is free software. You can redistribute it and/or modify it under
3439 the same terms as Perl itself.
3440
3441 =cut
3442
3443 no Moose;
3444
3445 __PACKAGE__->meta->make_immutable;
3446
3447 1;