lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80029';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 =cut
 374
 375 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 376
 377 =head2 $c->detach( $action [, \@arguments ] )
 378
 379 =head2 $c->detach( $class, $method, [, \@arguments ] )
 380
 381 =head2 $c->detach()
 382
 383 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 384 doesn't return to the previous action when processing is finished.
 385
 386 When called with no arguments it escapes the processing chain entirely.
 387
 388 =cut
 389
 390 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 391
 392 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 393
 394 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 395
 396 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 397 but does a full dispatch, instead of just calling the new C<$action> /
 398 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 399 you go to are called, just like a new request.
 400
 401 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 402 This means, for example, that C<< $c->action >> methods such as
 403 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 404 L<reverse|Catalyst::Action/reverse> return information for the visited action
 405 when they are invoked within the visited action.  This is different from the
 406 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 407 continues to use the $c->action object from the caller action even when
 408 invoked from the callee.
 409
 410 C<< $c->stash >> is kept unchanged.
 411
 412 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 413 allows you to "wrap" another action, just as it would have been called by
 414 dispatching from a URL, while the analogous
 415 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 416 transfer control to another action as if it had been reached directly from a URL.
 417
 418 =cut
 419
 420 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 421
 422 =head2 $c->go( $action [, \@captures, \@arguments ] )
 423
 424 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 425
 426 The relationship between C<go> and
 427 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 428 the relationship between
 429 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 430 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 431 C<< $c->go >> will perform a full dispatch on the specified action or method,
 432 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 433 C<go> escapes the processing of the current request chain on completion, and
 434 does not return to its caller.
 435
 436 @arguments are arguments to the final destination of $action. @captures are
 437 arguments to the intermediate steps, if any, on the way to the final sub of
 438 $action.
 439
 440 =cut
 441
 442 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 443
 444 =head2 $c->response
 445
 446 =head2 $c->res
 447
 448 Returns the current L<Catalyst::Response> object, see there for details.
 449
 450 =head2 $c->stash
 451
 452 Returns a hashref to the stash, which may be used to store data and pass
 453 it between components during a request. You can also set hash keys by
 454 passing arguments. The stash is automatically sent to the view. The
 455 stash is cleared at the end of a request; it cannot be used for
 456 persistent storage (for this you must use a session; see
 457 L<Catalyst::Plugin::Session> for a complete system integrated with
 458 Catalyst).
 459
 460     $c->stash->{foo} = $bar;
 461     $c->stash( { moose => 'majestic', qux => 0 } );
 462     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 463
 464     # stash is automatically passed to the view for use in a template
 465     $c->forward( 'MyApp::View::TT' );
 466
 467 =cut
 468
 469 around stash => sub {
 470     my $orig = shift;
 471     my $c = shift;
 472     my $stash = $orig->($c);
 473     if (@_) {
 474         my $new_stash = @_ > 1 ? {@_} : $_[0];
 475         croak('stash takes a hash or hashref') unless ref $new_stash;
 476         foreach my $key ( keys %$new_stash ) {
 477           $stash->{$key} = $new_stash->{$key};
 478         }
 479     }
 480
 481     return $stash;
 482 };
 483
 484
 485 =head2 $c->error
 486
 487 =head2 $c->error($error, ...)
 488
 489 =head2 $c->error($arrayref)
 490
 491 Returns an arrayref containing error messages.  If Catalyst encounters an
 492 error while processing a request, it stores the error in $c->error.  This
 493 method should only be used to store fatal error messages.
 494
 495     my @error = @{ $c->error };
 496
 497 Add a new error.
 498
 499     $c->error('Something bad happened');
 500
 501 =cut
 502
 503 sub error {
 504     my $c = shift;
 505     if ( $_[0] ) {
 506         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 507         croak @$error unless ref $c;
 508         push @{ $c->{error} }, @$error;
 509     }
 510     elsif ( defined $_[0] ) { $c->{error} = undef }
 511     return $c->{error} || [];
 512 }
 513
 514
 515 =head2 $c->state
 516
 517 Contains the return value of the last executed action.
 518 Note that << $c->state >> operates in a scalar context which means that all
 519 values it returns are scalar.
 520
 521 =head2 $c->clear_errors
 522
 523 Clear errors.  You probably don't want to clear the errors unless you are
 524 implementing a custom error screen.
 525
 526 This is equivalent to running
 527
 528     $c->error(0);
 529
 530 =cut
 531
 532 sub clear_errors {
 533     my $c = shift;
 534     $c->error(0);
 535 }
 536
 537 sub _comp_search_prefixes {
 538     my $c = shift;
 539     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 540 }
 541
 542 # search components given a name and some prefixes
 543 sub _comp_names_search_prefixes {
 544     my ( $c, $name, @prefixes ) = @_;
 545     my $appclass = ref $c || $c;
 546     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 547     $filter = qr/$filter/; # Compile regex now rather than once per loop
 548
 549     # map the original component name to the sub part that we will search against
 550     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 551         grep { /$filter/ } keys %{ $c->components };
 552
 553     # undef for a name will return all
 554     return keys %eligible if !defined $name;
 555
 556     my $query  = ref $name ? $name : qr/^$name$/i;
 557     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 558
 559     return @result if @result;
 560
 561     # if we were given a regexp to search against, we're done.
 562     return if ref $name;
 563
 564     # skip regexp fallback if configured
 565     return
 566         if $appclass->config->{disable_component_resolution_regex_fallback};
 567
 568     # regexp fallback
 569     $query  = qr/$name/i;
 570     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 571
 572     # no results? try against full names
 573     if( !@result ) {
 574         @result = grep { m{$query} } keys %eligible;
 575     }
 576
 577     # don't warn if we didn't find any results, it just might not exist
 578     if( @result ) {
 579         # Disgusting hack to work out correct method name
 580         my $warn_for = lc $prefixes[0];
 581         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 582            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 583            "component resolution is unreliable and unsafe.";
 584         my $short = $result[0];
 585         # remove the component namespace prefix
 586         $short =~ s/.*?(Model|Controller|View):://;
 587         my $shortmess = Carp::shortmess('');
 588         if ($shortmess =~ m#Catalyst/Plugin#) {
 589            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 590               "plugin's config";
 591         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 592            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 593               "component's config";
 594         } else {
 595            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 596               "but if you really wanted to search, pass in a regexp as the argument " .
 597               "like so: \$c->${warn_for}(qr/${name}/)";
 598         }
 599         $c->log->warn( "${msg}$shortmess" );
 600     }
 601
 602     return @result;
 603 }
 604
 605 # Find possible names for a prefix
 606 sub _comp_names {
 607     my ( $c, @prefixes ) = @_;
 608     my $appclass = ref $c || $c;
 609
 610     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 611
 612     my @names = map { s{$filter}{}; $_; }
 613         $c->_comp_names_search_prefixes( undef, @prefixes );
 614
 615     return @names;
 616 }
 617
 618 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 619 sub _filter_component {
 620     my ( $c, $comp, @args ) = @_;
 621
 622     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 623         return $comp->ACCEPT_CONTEXT( $c, @args );
 624     }
 625
 626     return $comp;
 627 }
 628
 629 =head2 COMPONENT ACCESSORS
 630
 631 =head2 $c->controller($name)
 632
 633 Gets a L<Catalyst::Controller> instance by name.
 634
 635     $c->controller('Foo')->do_stuff;
 636
 637 If the name is omitted, will return the controller for the dispatched
 638 action.
 639
 640 If you want to search for controllers, pass in a regexp as the argument.
 641
 642     # find all controllers that start with Foo
 643     my @foo_controllers = $c->controller(qr{^Foo});
 644
 645
 646 =cut
 647
 648 sub controller {
 649     my ( $c, $name, @args ) = @_;
 650
 651     my $appclass = ref($c) || $c;
 652     if( $name ) {
 653         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 654             my $comps = $c->components;
 655             my $check = $appclass."::Controller::".$name;
 656             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 657         }
 658         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 659         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 660         return $c->_filter_component( $result[ 0 ], @args );
 661     }
 662
 663     return $c->component( $c->action->class );
 664 }
 665
 666 =head2 $c->model($name)
 667
 668 Gets a L<Catalyst::Model> instance by name.
 669
 670     $c->model('Foo')->do_stuff;
 671
 672 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 673
 674 If the name is omitted, it will look for
 675  - a model object in $c->stash->{current_model_instance}, then
 676  - a model name in $c->stash->{current_model}, then
 677  - a config setting 'default_model', or
 678  - check if there is only one model, and return it if that's the case.
 679
 680 If you want to search for models, pass in a regexp as the argument.
 681
 682     # find all models that start with Foo
 683     my @foo_models = $c->model(qr{^Foo});
 684
 685 =cut
 686
 687 sub model {
 688     my ( $c, $name, @args ) = @_;
 689     my $appclass = ref($c) || $c;
 690     if( $name ) {
 691         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 692             my $comps = $c->components;
 693             my $check = $appclass."::Model::".$name;
 694             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 695         }
 696         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 697         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 698         return $c->_filter_component( $result[ 0 ], @args );
 699     }
 700
 701     if (ref $c) {
 702         return $c->stash->{current_model_instance}
 703           if $c->stash->{current_model_instance};
 704         return $c->model( $c->stash->{current_model} )
 705           if $c->stash->{current_model};
 706     }
 707     return $c->model( $appclass->config->{default_model} )
 708       if $appclass->config->{default_model};
 709
 710     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 711
 712     if( $rest ) {
 713         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 714         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 715         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 716         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 717         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 718     }
 719
 720     return $c->_filter_component( $comp );
 721 }
 722
 723
 724 =head2 $c->view($name)
 725
 726 Gets a L<Catalyst::View> instance by name.
 727
 728     $c->view('Foo')->do_stuff;
 729
 730 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 731
 732 If the name is omitted, it will look for
 733  - a view object in $c->stash->{current_view_instance}, then
 734  - a view name in $c->stash->{current_view}, then
 735  - a config setting 'default_view', or
 736  - check if there is only one view, and return it if that's the case.
 737
 738 If you want to search for views, pass in a regexp as the argument.
 739
 740     # find all views that start with Foo
 741     my @foo_views = $c->view(qr{^Foo});
 742
 743 =cut
 744
 745 sub view {
 746     my ( $c, $name, @args ) = @_;
 747
 748     my $appclass = ref($c) || $c;
 749     if( $name ) {
 750         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 751             my $comps = $c->components;
 752             my $check = $appclass."::View::".$name;
 753             if( exists $comps->{$check} ) {
 754                 return $c->_filter_component( $comps->{$check}, @args );
 755             }
 756             else {
 757                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 758             }
 759         }
 760         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 761         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 762         return $c->_filter_component( $result[ 0 ], @args );
 763     }
 764
 765     if (ref $c) {
 766         return $c->stash->{current_view_instance}
 767           if $c->stash->{current_view_instance};
 768         return $c->view( $c->stash->{current_view} )
 769           if $c->stash->{current_view};
 770     }
 771     return $c->view( $appclass->config->{default_view} )
 772       if $appclass->config->{default_view};
 773
 774     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 775
 776     if( $rest ) {
 777         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 778         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 779         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 780         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 781         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 782     }
 783
 784     return $c->_filter_component( $comp );
 785 }
 786
 787 =head2 $c->controllers
 788
 789 Returns the available names which can be passed to $c->controller
 790
 791 =cut
 792
 793 sub controllers {
 794     my ( $c ) = @_;
 795     return $c->_comp_names(qw/Controller C/);
 796 }
 797
 798 =head2 $c->models
 799
 800 Returns the available names which can be passed to $c->model
 801
 802 =cut
 803
 804 sub models {
 805     my ( $c ) = @_;
 806     return $c->_comp_names(qw/Model M/);
 807 }
 808
 809
 810 =head2 $c->views
 811
 812 Returns the available names which can be passed to $c->view
 813
 814 =cut
 815
 816 sub views {
 817     my ( $c ) = @_;
 818     return $c->_comp_names(qw/View V/);
 819 }
 820
 821 =head2 $c->comp($name)
 822
 823 =head2 $c->component($name)
 824
 825 Gets a component object by name. This method is not recommended,
 826 unless you want to get a specific component by full
 827 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 828 should be used instead.
 829
 830 If C<$name> is a regexp, a list of components matched against the full
 831 component name will be returned.
 832
 833 If Catalyst can't find a component by name, it will fallback to regex
 834 matching by default. To disable this behaviour set
 835 disable_component_resolution_regex_fallback to a true value.
 836
 837     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 838
 839 =cut
 840
 841 sub component {
 842     my ( $c, $name, @args ) = @_;
 843
 844     if( $name ) {
 845         my $comps = $c->components;
 846
 847         if( !ref $name ) {
 848             # is it the exact name?
 849             return $c->_filter_component( $comps->{ $name }, @args )
 850                        if exists $comps->{ $name };
 851
 852             # perhaps we just omitted "MyApp"?
 853             my $composed = ( ref $c || $c ) . "::${name}";
 854             return $c->_filter_component( $comps->{ $composed }, @args )
 855                        if exists $comps->{ $composed };
 856
 857             # search all of the models, views and controllers
 858             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 859             return $c->_filter_component( $comp, @args ) if $comp;
 860         }
 861
 862         # This is here so $c->comp( '::M::' ) works
 863         my $query = ref $name ? $name : qr{$name}i;
 864
 865         my @result = grep { m{$query} } keys %{ $c->components };
 866         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 867
 868         if( $result[ 0 ] ) {
 869             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 870             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 871             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 872             return $c->_filter_component( $result[ 0 ], @args );
 873         }
 874
 875         # I would expect to return an empty list here, but that breaks back-compat
 876     }
 877
 878     # fallback
 879     return sort keys %{ $c->components };
 880 }
 881
 882 =head2 CLASS DATA AND HELPER CLASSES
 883
 884 =head2 $c->config
 885
 886 Returns or takes a hashref containing the application's configuration.
 887
 888     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 889
 890 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 891 like C<myapp.conf> in your applications home directory. See
 892 L<Catalyst::Plugin::ConfigLoader>.
 893
 894 =head3 Cascading configuration
 895
 896 The config method is present on all Catalyst components, and configuration
 897 will be merged when an application is started. Configuration loaded with
 898 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 899 followed by configuration in your top level C<MyApp> class. These two
 900 configurations are merged, and then configuration data whose hash key matches a
 901 component name is merged with configuration for that component.
 902
 903 The configuration for a component is then passed to the C<new> method when a
 904 component is constructed.
 905
 906 For example:
 907
 908     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 909     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 910
 911 will mean that C<MyApp::Model::Foo> receives the following data when
 912 constructed:
 913
 914     MyApp::Model::Foo->new({
 915         bar => 'baz',
 916         quux => 'frob',
 917         overrides => 'me',
 918     });
 919
 920 It's common practice to use a Moose attribute
 921 on the receiving component to access the config value.
 922
 923     package MyApp::Model::Foo;
 924
 925     use Moose;
 926
 927     # this attr will receive 'baz' at construction time
 928     has 'bar' => (
 929         is  => 'rw',
 930         isa => 'Str',
 931     );
 932
 933 You can then get the value 'baz' by calling $c->model('Foo')->bar
 934 (or $self->bar inside code in the model).
 935
 936 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 937 as a way of reading config within your code, as this B<will not> give you the
 938 correctly merged config back. You B<MUST> take the config values supplied to
 939 the constructor and use those instead.
 940
 941 =cut
 942
 943 around config => sub {
 944     my $orig = shift;
 945     my $c = shift;
 946
 947     croak('Setting config after setup has been run is not allowed.')
 948         if ( @_ and $c->setup_finished );
 949
 950     $c->$orig(@_);
 951 };
 952
 953 =head2 $c->log
 954
 955 Returns the logging object instance. Unless it is already set, Catalyst
 956 sets this up with a L<Catalyst::Log> object. To use your own log class,
 957 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 958 C<< __PACKAGE__->setup >>.
 959
 960  __PACKAGE__->log( MyLogger->new );
 961  __PACKAGE__->setup;
 962
 963 And later:
 964
 965     $c->log->info( 'Now logging with my own logger!' );
 966
 967 Your log class should implement the methods described in
 968 L<Catalyst::Log>.
 969
 970
 971 =head2 $c->debug
 972
 973 Returns 1 if debug mode is enabled, 0 otherwise.
 974
 975 You can enable debug mode in several ways:
 976
 977 =over
 978
 979 =item By calling myapp_server.pl with the -d flag
 980
 981 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 982
 983 =item The -Debug option in your MyApp.pm
 984
 985 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 986
 987 =back
 988
 989 The first three also set the log level to 'debug'.
 990
 991 Calling C<< $c->debug(1) >> has no effect.
 992
 993 =cut
 994
 995 sub debug { 0 }
 996
 997 =head2 $c->dispatcher
 998
 999 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1000
1001 =head2 $c->engine
1002
1003 Returns the engine instance. See L<Catalyst::Engine>.
1004
1005
1006 =head2 UTILITY METHODS
1007
1008 =head2 $c->path_to(@path)
1009
1010 Merges C<@path> with C<< $c->config->{home} >> and returns a
1011 L<Path::Class::Dir> object. Note you can usually use this object as
1012 a filename, but sometimes you will have to explicitly stringify it
1013 yourself by calling the C<< ->stringify >> method.
1014
1015 For example:
1016
1017     $c->path_to( 'db', 'sqlite.db' );
1018
1019 =cut
1020
1021 sub path_to {
1022     my ( $c, @path ) = @_;
1023     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1024     if ( -d $path ) { return $path }
1025     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1026 }
1027
1028 =head2 $c->plugin( $name, $class, @args )
1029
1030 Helper method for plugins. It creates a class data accessor/mutator and
1031 loads and instantiates the given class.
1032
1033     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1034
1035     $c->prototype->define_javascript_functions;
1036
1037 B<Note:> This method of adding plugins is deprecated. The ability
1038 to add plugins like this B<will be removed> in a Catalyst 5.81.
1039 Please do not use this functionality in new code.
1040
1041 =cut
1042
1043 sub plugin {
1044     my ( $class, $name, $plugin, @args ) = @_;
1045
1046     # See block comment in t/unit_core_plugin.t
1047     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1048
1049     $class->_register_plugin( $plugin, 1 );
1050
1051     eval { $plugin->import };
1052     $class->mk_classdata($name);
1053     my $obj;
1054     eval { $obj = $plugin->new(@args) };
1055
1056     if ($@) {
1057         Catalyst::Exception->throw( message =>
1058               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1059     }
1060
1061     $class->$name($obj);
1062     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1063       if $class->debug;
1064 }
1065
1066 =head2 MyApp->setup
1067
1068 Initializes the dispatcher and engine, loads any plugins, and loads the
1069 model, view, and controller components. You may also specify an array
1070 of plugins to load here, if you choose to not load them in the C<use
1071 Catalyst> line.
1072
1073     MyApp->setup;
1074     MyApp->setup( qw/-Debug/ );
1075
1076 =cut
1077
1078 sub setup {
1079     my ( $class, @arguments ) = @_;
1080     croak('Running setup more than once')
1081         if ( $class->setup_finished );
1082
1083     unless ( $class->isa('Catalyst') ) {
1084
1085         Catalyst::Exception->throw(
1086             message => qq/'$class' does not inherit from Catalyst/ );
1087     }
1088
1089     if ( $class->arguments ) {
1090         @arguments = ( @arguments, @{ $class->arguments } );
1091     }
1092
1093     # Process options
1094     my $flags = {};
1095
1096     foreach (@arguments) {
1097
1098         if (/^-Debug$/) {
1099             $flags->{log} =
1100               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1101         }
1102         elsif (/^-(\w+)=?(.*)$/) {
1103             $flags->{ lc $1 } = $2;
1104         }
1105         else {
1106             push @{ $flags->{plugins} }, $_;
1107         }
1108     }
1109
1110     $class->setup_home( delete $flags->{home} );
1111
1112     $class->setup_log( delete $flags->{log} );
1113     $class->setup_plugins( delete $flags->{plugins} );
1114     $class->setup_dispatcher( delete $flags->{dispatcher} );
1115     $class->setup_engine( delete $flags->{engine} );
1116     $class->setup_stats( delete $flags->{stats} );
1117
1118     for my $flag ( sort keys %{$flags} ) {
1119
1120         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1121             &$code( $class, delete $flags->{$flag} );
1122         }
1123         else {
1124             $class->log->warn(qq/Unknown flag "$flag"/);
1125         }
1126     }
1127
1128     eval { require Catalyst::Devel; };
1129     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1130         $class->log->warn(<<"EOF");
1131 You are running an old script!
1132
1133   Please update by running (this will overwrite existing files):
1134     catalyst.pl -force -scripts $class
1135
1136   or (this will not overwrite existing files):
1137     catalyst.pl -scripts $class
1138
1139 EOF
1140     }
1141
1142     if ( $class->debug ) {
1143         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1144
1145         if (@plugins) {
1146             my $column_width = Catalyst::Utils::term_width() - 6;
1147             my $t = Text::SimpleTable->new($column_width);
1148             $t->row($_) for @plugins;
1149             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1150         }
1151
1152         my $dispatcher = $class->dispatcher;
1153         my $engine     = $class->engine;
1154         my $home       = $class->config->{home};
1155
1156         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1157         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1158
1159         $home
1160           ? ( -d $home )
1161           ? $class->log->debug(qq/Found home "$home"/)
1162           : $class->log->debug(qq/Home "$home" doesn't exist/)
1163           : $class->log->debug(q/Couldn't find home/);
1164     }
1165
1166     # Call plugins setup, this is stupid and evil.
1167     # Also screws C3 badly on 5.10, hack to avoid.
1168     {
1169         no warnings qw/redefine/;
1170         local *setup = sub { };
1171         $class->setup unless $Catalyst::__AM_RESTARTING;
1172     }
1173
1174     # Initialize our data structure
1175     $class->components( {} );
1176
1177     $class->setup_components;
1178
1179     if ( $class->debug ) {
1180         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1181         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1182         for my $comp ( sort keys %{ $class->components } ) {
1183             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1184             $t->row( $comp, $type );
1185         }
1186         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1187           if ( keys %{ $class->components } );
1188     }
1189
1190     # Add our self to components, since we are also a component
1191     if( $class->isa('Catalyst::Controller') ){
1192       $class->components->{$class} = $class;
1193     }
1194
1195     $class->setup_actions;
1196
1197     if ( $class->debug ) {
1198         my $name = $class->config->{name} || 'Application';
1199         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1200     }
1201
1202     # Make sure that the application class becomes immutable at this point,
1203     B::Hooks::EndOfScope::on_scope_end {
1204         return if $@;
1205         my $meta = Class::MOP::get_metaclass_by_name($class);
1206         if (
1207             $meta->is_immutable
1208             && ! { $meta->immutable_options }->{replace_constructor}
1209             && (
1210                    $class->isa('Class::Accessor::Fast')
1211                 || $class->isa('Class::Accessor')
1212             )
1213         ) {
1214             warn "You made your application class ($class) immutable, "
1215                 . "but did not inline the\nconstructor. "
1216                 . "This will break catalyst, as your app \@ISA "
1217                 . "Class::Accessor(::Fast)?\nPlease pass "
1218                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1219         }
1220         $meta->make_immutable(
1221             replace_constructor => 1,
1222         ) unless $meta->is_immutable;
1223     };
1224
1225     if ($class->config->{case_sensitive}) {
1226         $class->log->warn($class . "->config->{case_sensitive} is set.");
1227         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1228     }
1229
1230     $class->setup_finalize;
1231     # Should be the last thing we do so that user things hooking
1232     # setup_finalize can log..
1233     $class->log->_flush() if $class->log->can('_flush');
1234     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1235 }
1236
1237 =head2 $app->setup_finalize
1238
1239 A hook to attach modifiers to. This method does not do anything except set the
1240 C<setup_finished> accessor.
1241
1242 Applying method modifiers to the C<setup> method doesn't work, because of quirky thingsdone for plugin setup.
1243
1244 Example:
1245
1246     after setup_finalize => sub {
1247         my $app = shift;
1248
1249         ## do stuff here..
1250     };
1251
1252 =cut
1253
1254 sub setup_finalize {
1255     my ($class) = @_;
1256     $class->setup_finished(1);
1257 }
1258
1259 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1260
1261 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1262
1263 Constructs an absolute L<URI> object based on the application root, the
1264 provided path, and the additional arguments and query parameters provided.
1265 When used as a string, provides a textual URI.  If you need more flexibility
1266 than this (i.e. the option to provide relative URIs etc.) see
1267 L<Catalyst::Plugin::SmartURI>.
1268
1269 If no arguments are provided, the URI for the current action is returned.
1270 To return the current action and also provide @args, use
1271 C<< $c->uri_for( $c->action, @args ) >>.
1272
1273 If the first argument is a string, it is taken as a public URI path relative
1274 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1275 relative to the application root (if it does). It is then merged with
1276 C<< $c->request->base >>; any C<@args> are appended as additional path
1277 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1278
1279 If the first argument is a L<Catalyst::Action> it represents an action which
1280 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1281 optional C<\@captures> argument (an arrayref) allows passing the captured
1282 variables that are needed to fill in the paths of Chained and Regex actions;
1283 once the path is resolved, C<uri_for> continues as though a path was
1284 provided, appending any arguments or parameters and creating an absolute
1285 URI.
1286
1287 The captures for the current request can be found in
1288 C<< $c->request->captures >>, and actions can be resolved using
1289 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1290 path, use C<< $c->uri_for_action >> instead.
1291
1292   # Equivalent to $c->req->uri
1293   $c->uri_for($c->action, $c->req->captures,
1294       @{ $c->req->args }, $c->req->params);
1295
1296   # For the Foo action in the Bar controller
1297   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1298
1299   # Path to a static resource
1300   $c->uri_for('/static/images/logo.png');
1301
1302 =cut
1303
1304 sub uri_for {
1305     my ( $c, $path, @args ) = @_;
1306
1307     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1308         $path = $path->path_prefix;
1309         $path =~ s{/+\z}{};
1310         $path .= '/';
1311     }
1312
1313     undef($path) if (defined $path && $path eq '');
1314
1315     my $params =
1316       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1317
1318     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1319     foreach my $arg (@args) {
1320         utf8::encode($arg) if utf8::is_utf8($arg);
1321         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1322     }
1323
1324     if ( blessed($path) ) { # action object
1325         s|/|%2F|g for @args;
1326         my $captures = [ map { s|/|%2F|g; $_; }
1327                         ( scalar @args && ref $args[0] eq 'ARRAY'
1328                          ? @{ shift(@args) }
1329                          : ()) ];
1330
1331         foreach my $capture (@$captures) {
1332             utf8::encode($capture) if utf8::is_utf8($capture);
1333             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1334         }
1335
1336         my $action = $path;
1337         $path = $c->dispatcher->uri_for_action($action, $captures);
1338         if (not defined $path) {
1339             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1340                 if $c->debug;
1341             return undef;
1342         }
1343         $path = '/' if $path eq '';
1344     }
1345
1346     unshift(@args, $path);
1347
1348     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1349         my $namespace = $c->namespace;
1350         if (defined $path) { # cheesy hack to handle path '../foo'
1351            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1352         }
1353         unshift(@args, $namespace || '');
1354     }
1355
1356     # join args with '/', or a blank string
1357     my $args = join('/', grep { defined($_) } @args);
1358     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1359     $args =~ s!^/+!!;
1360     my $base = $c->req->base;
1361     my $class = ref($base);
1362     $base =~ s{(?<!/)$}{/};
1363
1364     my $query = '';
1365
1366     if (my @keys = keys %$params) {
1367       # somewhat lifted from URI::_query's query_form
1368       $query = '?'.join('&', map {
1369           my $val = $params->{$_};
1370           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1371           s/ /+/g;
1372           my $key = $_;
1373           $val = '' unless defined $val;
1374           (map {
1375               my $param = "$_";
1376               utf8::encode( $param ) if utf8::is_utf8($param);
1377               # using the URI::Escape pattern here so utf8 chars survive
1378               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1379               $param =~ s/ /+/g;
1380               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1381       } @keys);
1382     }
1383
1384     my $res = bless(\"${base}${args}${query}", $class);
1385     $res;
1386 }
1387
1388 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1389
1390 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1391
1392 =over
1393
1394 =item $path
1395
1396 A private path to the Catalyst action you want to create a URI for.
1397
1398 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1399 >> and passing the resulting C<$action> and the remaining arguments to C<<
1400 $c->uri_for >>.
1401
1402 You can also pass in a Catalyst::Action object, in which case it is passed to
1403 C<< $c->uri_for >>.
1404
1405 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1406
1407 For example, if the action looks like:
1408
1409  package MyApp::Controller::Users;
1410
1411  sub lst : Path('the-list') {}
1412
1413 You can use:
1414
1415  $c->uri_for_action('/users/lst')
1416
1417 and it will create the URI /users/the-list.
1418
1419 =back
1420
1421 =cut
1422
1423 sub uri_for_action {
1424     my ( $c, $path, @args ) = @_;
1425     my $action = blessed($path)
1426       ? $path
1427       : $c->dispatcher->get_action_by_path($path);
1428     unless (defined $action) {
1429       croak "Can't find action for path '$path'";
1430     }
1431     return $c->uri_for( $action, @args );
1432 }
1433
1434 =head2 $c->welcome_message
1435
1436 Returns the Catalyst welcome HTML page.
1437
1438 =cut
1439
1440 sub welcome_message {
1441     my $c      = shift;
1442     my $name   = $c->config->{name};
1443     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1444     my $prefix = Catalyst::Utils::appprefix( ref $c );
1445     $c->response->content_type('text/html; charset=utf-8');
1446     return <<"EOF";
1447 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1448     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1449 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1450     <head>
1451     <meta http-equiv="Content-Language" content="en" />
1452     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1453         <title>$name on Catalyst $VERSION</title>
1454         <style type="text/css">
1455             body {
1456                 color: #000;
1457                 background-color: #eee;
1458             }
1459             div#content {
1460                 width: 640px;
1461                 margin-left: auto;
1462                 margin-right: auto;
1463                 margin-top: 10px;
1464                 margin-bottom: 10px;
1465                 text-align: left;
1466                 background-color: #ccc;
1467                 border: 1px solid #aaa;
1468             }
1469             p, h1, h2 {
1470                 margin-left: 20px;
1471                 margin-right: 20px;
1472                 font-family: verdana, tahoma, sans-serif;
1473             }
1474             a {
1475                 font-family: verdana, tahoma, sans-serif;
1476             }
1477             :link, :visited {
1478                     text-decoration: none;
1479                     color: #b00;
1480                     border-bottom: 1px dotted #bbb;
1481             }
1482             :link:hover, :visited:hover {
1483                     color: #555;
1484             }
1485             div#topbar {
1486                 margin: 0px;
1487             }
1488             pre {
1489                 margin: 10px;
1490                 padding: 8px;
1491             }
1492             div#answers {
1493                 padding: 8px;
1494                 margin: 10px;
1495                 background-color: #fff;
1496                 border: 1px solid #aaa;
1497             }
1498             h1 {
1499                 font-size: 0.9em;
1500                 font-weight: normal;
1501                 text-align: center;
1502             }
1503             h2 {
1504                 font-size: 1.0em;
1505             }
1506             p {
1507                 font-size: 0.9em;
1508             }
1509             p img {
1510                 float: right;
1511                 margin-left: 10px;
1512             }
1513             span#appname {
1514                 font-weight: bold;
1515                 font-size: 1.6em;
1516             }
1517         </style>
1518     </head>
1519     <body>
1520         <div id="content">
1521             <div id="topbar">
1522                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1523                     $VERSION</h1>
1524              </div>
1525              <div id="answers">
1526                  <p>
1527                  <img src="$logo" alt="Catalyst Logo" />
1528                  </p>
1529                  <p>Welcome to the  world of Catalyst.
1530                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1531                     framework will make web development something you had
1532                     never expected it to be: Fun, rewarding, and quick.</p>
1533                  <h2>What to do now?</h2>
1534                  <p>That really depends  on what <b>you</b> want to do.
1535                     We do, however, provide you with a few starting points.</p>
1536                  <p>If you want to jump right into web development with Catalyst
1537                     you might want to start with a tutorial.</p>
1538 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1539 </pre>
1540 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1541 <pre>
1542 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1543 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1544 </code></pre>
1545                  <h2>What to do next?</h2>
1546                  <p>Next it's time to write an actual application. Use the
1547                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1548                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1549                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1550                     they can save you a lot of work.</p>
1551                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1552                     <p>Also, be sure to check out the vast and growing
1553                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1554                     you are likely to find what you need there.
1555                     </p>
1556
1557                  <h2>Need help?</h2>
1558                  <p>Catalyst has a very active community. Here are the main places to
1559                     get in touch with us.</p>
1560                  <ul>
1561                      <li>
1562                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1563                      </li>
1564                      <li>
1565                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1566                      </li>
1567                      <li>
1568                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1569                      </li>
1570                  </ul>
1571                  <h2>In conclusion</h2>
1572                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1573                     as we enjoyed making it. Please contact us if you have ideas
1574                     for improvement or other feedback.</p>
1575              </div>
1576          </div>
1577     </body>
1578 </html>
1579 EOF
1580 }
1581
1582 =head1 INTERNAL METHODS
1583
1584 These methods are not meant to be used by end users.
1585
1586 =head2 $c->components
1587
1588 Returns a hash of components.
1589
1590 =head2 $c->context_class
1591
1592 Returns or sets the context class.
1593
1594 =head2 $c->counter
1595
1596 Returns a hashref containing coderefs and execution counts (needed for
1597 deep recursion detection).
1598
1599 =head2 $c->depth
1600
1601 Returns the number of actions on the current internal execution stack.
1602
1603 =head2 $c->dispatch
1604
1605 Dispatches a request to actions.
1606
1607 =cut
1608
1609 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1610
1611 =head2 $c->dispatcher_class
1612
1613 Returns or sets the dispatcher class.
1614
1615 =head2 $c->dump_these
1616
1617 Returns a list of 2-element array references (name, structure) pairs
1618 that will be dumped on the error page in debug mode.
1619
1620 =cut
1621
1622 sub dump_these {
1623     my $c = shift;
1624     [ Request => $c->req ],
1625     [ Response => $c->res ],
1626     [ Stash => $c->stash ],
1627     [ Config => $c->config ];
1628 }
1629
1630 =head2 $c->engine_class
1631
1632 Returns or sets the engine class.
1633
1634 =head2 $c->execute( $class, $coderef )
1635
1636 Execute a coderef in given class and catch exceptions. Errors are available
1637 via $c->error.
1638
1639 =cut
1640
1641 sub execute {
1642     my ( $c, $class, $code ) = @_;
1643     $class = $c->component($class) || $class;
1644     $c->state(0);
1645
1646     if ( $c->depth >= $RECURSION ) {
1647         my $action = $code->reverse();
1648         $action = "/$action" unless $action =~ /->/;
1649         my $error = qq/Deep recursion detected calling "${action}"/;
1650         $c->log->error($error);
1651         $c->error($error);
1652         $c->state(0);
1653         return $c->state;
1654     }
1655
1656     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1657
1658     push( @{ $c->stack }, $code );
1659
1660     no warnings 'recursion';
1661     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1662
1663     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1664
1665     my $last = pop( @{ $c->stack } );
1666
1667     if ( my $error = $@ ) {
1668         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1669             $error->rethrow if $c->depth > 1;
1670         }
1671         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1672             $error->rethrow if $c->depth > 0;
1673         }
1674         else {
1675             unless ( ref $error ) {
1676                 no warnings 'uninitialized';
1677                 chomp $error;
1678                 my $class = $last->class;
1679                 my $name  = $last->name;
1680                 $error = qq/Caught exception in $class->$name "$error"/;
1681             }
1682             $c->error($error);
1683             $c->state(0);
1684         }
1685     }
1686     return $c->state;
1687 }
1688
1689 sub _stats_start_execute {
1690     my ( $c, $code ) = @_;
1691     my $appclass = ref($c) || $c;
1692     return if ( ( $code->name =~ /^_.*/ )
1693         && ( !$appclass->config->{show_internal_actions} ) );
1694
1695     my $action_name = $code->reverse();
1696     $c->counter->{$action_name}++;
1697
1698     my $action = $action_name;
1699     $action = "/$action" unless $action =~ /->/;
1700
1701     # determine if the call was the result of a forward
1702     # this is done by walking up the call stack and looking for a calling
1703     # sub of Catalyst::forward before the eval
1704     my $callsub = q{};
1705     for my $index ( 2 .. 11 ) {
1706         last
1707         if ( ( caller($index) )[0] eq 'Catalyst'
1708             && ( caller($index) )[3] eq '(eval)' );
1709
1710         if ( ( caller($index) )[3] =~ /forward$/ ) {
1711             $callsub = ( caller($index) )[3];
1712             $action  = "-> $action";
1713             last;
1714         }
1715     }
1716
1717     my $uid = $action_name . $c->counter->{$action_name};
1718
1719     # is this a root-level call or a forwarded call?
1720     if ( $callsub =~ /forward$/ ) {
1721         my $parent = $c->stack->[-1];
1722
1723         # forward, locate the caller
1724         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1725             $c->stats->profile(
1726                 begin  => $action,
1727                 parent => "$parent" . $c->counter->{"$parent"},
1728                 uid    => $uid,
1729             );
1730         }
1731         else {
1732
1733             # forward with no caller may come from a plugin
1734             $c->stats->profile(
1735                 begin => $action,
1736                 uid   => $uid,
1737             );
1738         }
1739     }
1740     else {
1741
1742         # root-level call
1743         $c->stats->profile(
1744             begin => $action,
1745             uid   => $uid,
1746         );
1747     }
1748     return $action;
1749
1750 }
1751
1752 sub _stats_finish_execute {
1753     my ( $c, $info ) = @_;
1754     $c->stats->profile( end => $info );
1755 }
1756
1757 =head2 $c->finalize
1758
1759 Finalizes the request.
1760
1761 =cut
1762
1763 sub finalize {
1764     my $c = shift;
1765
1766     for my $error ( @{ $c->error } ) {
1767         $c->log->error($error);
1768     }
1769
1770     # Allow engine to handle finalize flow (for POE)
1771     my $engine = $c->engine;
1772     if ( my $code = $engine->can('finalize') ) {
1773         $engine->$code($c);
1774     }
1775     else {
1776
1777         $c->finalize_uploads;
1778
1779         # Error
1780         if ( $#{ $c->error } >= 0 ) {
1781             $c->finalize_error;
1782         }
1783
1784         $c->finalize_headers;
1785
1786         # HEAD request
1787         if ( $c->request->method eq 'HEAD' ) {
1788             $c->response->body('');
1789         }
1790
1791         $c->finalize_body;
1792     }
1793
1794     $c->log_response;
1795
1796     if ($c->use_stats) {
1797         my $elapsed = sprintf '%f', $c->stats->elapsed;
1798         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1799         $c->log->info(
1800             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1801     }
1802
1803     return $c->response->status;
1804 }
1805
1806 =head2 $c->finalize_body
1807
1808 Finalizes body.
1809
1810 =cut
1811
1812 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1813
1814 =head2 $c->finalize_cookies
1815
1816 Finalizes cookies.
1817
1818 =cut
1819
1820 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1821
1822 =head2 $c->finalize_error
1823
1824 Finalizes error.
1825
1826 =cut
1827
1828 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1829
1830 =head2 $c->finalize_headers
1831
1832 Finalizes headers.
1833
1834 =cut
1835
1836 sub finalize_headers {
1837     my $c = shift;
1838
1839     my $response = $c->response; #accessor calls can add up?
1840
1841     # Check if we already finalized headers
1842     return if $response->finalized_headers;
1843
1844     # Handle redirects
1845     if ( my $location = $response->redirect ) {
1846         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1847         $response->header( Location => $location );
1848
1849         if ( !$response->has_body ) {
1850             # Add a default body if none is already present
1851             $response->body(
1852                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1853             );
1854         }
1855     }
1856
1857     # Content-Length
1858     if ( $response->body && !$response->content_length ) {
1859
1860         # get the length from a filehandle
1861         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1862         {
1863             my $stat = stat $response->body;
1864             if ( $stat && $stat->size > 0 ) {
1865                 $response->content_length( $stat->size );
1866             }
1867             else {
1868                 $c->log->warn('Serving filehandle without a content-length');
1869             }
1870         }
1871         else {
1872             # everything should be bytes at this point, but just in case
1873             $response->content_length( length( $response->body ) );
1874         }
1875     }
1876
1877     # Errors
1878     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1879         $response->headers->remove_header("Content-Length");
1880         $response->body('');
1881     }
1882
1883     $c->finalize_cookies;
1884
1885     $c->engine->finalize_headers( $c, @_ );
1886
1887     # Done
1888     $response->finalized_headers(1);
1889 }
1890
1891 =head2 $c->finalize_output
1892
1893 An alias for finalize_body.
1894
1895 =head2 $c->finalize_read
1896
1897 Finalizes the input after reading is complete.
1898
1899 =cut
1900
1901 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1902
1903 =head2 $c->finalize_uploads
1904
1905 Finalizes uploads. Cleans up any temporary files.
1906
1907 =cut
1908
1909 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1910
1911 =head2 $c->get_action( $action, $namespace )
1912
1913 Gets an action in a given namespace.
1914
1915 =cut
1916
1917 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1918
1919 =head2 $c->get_actions( $action, $namespace )
1920
1921 Gets all actions of a given name in a namespace and all parent
1922 namespaces.
1923
1924 =cut
1925
1926 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1927
1928 =head2 $app->handle_request( @arguments )
1929
1930 Called to handle each HTTP request.
1931
1932 =cut
1933
1934 sub handle_request {
1935     my ( $class, @arguments ) = @_;
1936
1937     # Always expect worst case!
1938     my $status = -1;
1939     eval {
1940         if ($class->debug) {
1941             my $secs = time - $START || 1;
1942             my $av = sprintf '%.3f', $COUNT / $secs;
1943             my $time = localtime time;
1944             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1945         }
1946
1947         my $c = $class->prepare(@arguments);
1948         $c->dispatch;
1949         $status = $c->finalize;
1950     };
1951
1952     if ( my $error = $@ ) {
1953         chomp $error;
1954         $class->log->error(qq/Caught exception in engine "$error"/);
1955     }
1956
1957     $COUNT++;
1958
1959     if(my $coderef = $class->log->can('_flush')){
1960         $class->log->$coderef();
1961     }
1962     return $status;
1963 }
1964
1965 =head2 $c->prepare( @arguments )
1966
1967 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1968 etc.).
1969
1970 =cut
1971
1972 sub prepare {
1973     my ( $class, @arguments ) = @_;
1974
1975     # XXX
1976     # After the app/ctxt split, this should become an attribute based on something passed
1977     # into the application.
1978     $class->context_class( ref $class || $class ) unless $class->context_class;
1979
1980     my $c = $class->context_class->new({});
1981
1982     # For on-demand data
1983     $c->request->_context($c);
1984     $c->response->_context($c);
1985
1986     #surely this is not the most efficient way to do things...
1987     $c->stats($class->stats_class->new)->enable($c->use_stats);
1988     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1989         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1990     }
1991
1992     #XXX reuse coderef from can
1993     # Allow engine to direct the prepare flow (for POE)
1994     if ( $c->engine->can('prepare') ) {
1995         $c->engine->prepare( $c, @arguments );
1996     }
1997     else {
1998         $c->prepare_request(@arguments);
1999         $c->prepare_connection;
2000         $c->prepare_query_parameters;
2001         $c->prepare_headers;
2002         $c->prepare_cookies;
2003         $c->prepare_path;
2004
2005         # Prepare the body for reading, either by prepare_body
2006         # or the user, if they are using $c->read
2007         $c->prepare_read;
2008
2009         # Parse the body unless the user wants it on-demand
2010         unless ( ref($c)->config->{parse_on_demand} ) {
2011             $c->prepare_body;
2012         }
2013     }
2014
2015     my $method  = $c->req->method  || '';
2016     my $path    = $c->req->path;
2017     $path       = '/' unless length $path;
2018     my $address = $c->req->address || '';
2019
2020     $c->log_request;
2021
2022     $c->prepare_action;
2023
2024     return $c;
2025 }
2026
2027 =head2 $c->prepare_action
2028
2029 Prepares action. See L<Catalyst::Dispatcher>.
2030
2031 =cut
2032
2033 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2034
2035 =head2 $c->prepare_body
2036
2037 Prepares message body.
2038
2039 =cut
2040
2041 sub prepare_body {
2042     my $c = shift;
2043
2044     return if $c->request->_has_body;
2045
2046     # Initialize on-demand data
2047     $c->engine->prepare_body( $c, @_ );
2048     $c->prepare_parameters;
2049     $c->prepare_uploads;
2050 }
2051
2052 =head2 $c->prepare_body_chunk( $chunk )
2053
2054 Prepares a chunk of data before sending it to L<HTTP::Body>.
2055
2056 See L<Catalyst::Engine>.
2057
2058 =cut
2059
2060 sub prepare_body_chunk {
2061     my $c = shift;
2062     $c->engine->prepare_body_chunk( $c, @_ );
2063 }
2064
2065 =head2 $c->prepare_body_parameters
2066
2067 Prepares body parameters.
2068
2069 =cut
2070
2071 sub prepare_body_parameters {
2072     my $c = shift;
2073     $c->engine->prepare_body_parameters( $c, @_ );
2074 }
2075
2076 =head2 $c->prepare_connection
2077
2078 Prepares connection.
2079
2080 =cut
2081
2082 sub prepare_connection {
2083     my $c = shift;
2084     $c->engine->prepare_connection( $c, @_ );
2085 }
2086
2087 =head2 $c->prepare_cookies
2088
2089 Prepares cookies.
2090
2091 =cut
2092
2093 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2094
2095 =head2 $c->prepare_headers
2096
2097 Prepares headers.
2098
2099 =cut
2100
2101 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2102
2103 =head2 $c->prepare_parameters
2104
2105 Prepares parameters.
2106
2107 =cut
2108
2109 sub prepare_parameters {
2110     my $c = shift;
2111     $c->prepare_body_parameters;
2112     $c->engine->prepare_parameters( $c, @_ );
2113 }
2114
2115 =head2 $c->prepare_path
2116
2117 Prepares path and base.
2118
2119 =cut
2120
2121 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2122
2123 =head2 $c->prepare_query_parameters
2124
2125 Prepares query parameters.
2126
2127 =cut
2128
2129 sub prepare_query_parameters {
2130     my $c = shift;
2131
2132     $c->engine->prepare_query_parameters( $c, @_ );
2133 }
2134
2135 =head2 $c->log_request
2136
2137 Writes information about the request to the debug logs.  This includes:
2138
2139 =over 4
2140
2141 =item * Request method, path, and remote IP address
2142
2143 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2144
2145 =item * Request parameters
2146
2147 =item * File uploads
2148
2149 =back
2150
2151 =cut
2152
2153 sub log_request {
2154     my $c = shift;
2155
2156     return unless $c->debug;
2157
2158     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2159     my $request = $dump->[1];
2160
2161     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2162     $method ||= '';
2163     $path = '/' unless length $path;
2164     $address ||= '';
2165     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2166
2167     $c->log_request_headers($request->headers);
2168
2169     if ( my $keywords = $request->query_keywords ) {
2170         $c->log->debug("Query keywords are: $keywords");
2171     }
2172
2173     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2174
2175     $c->log_request_uploads($request);
2176 }
2177
2178 =head2 $c->log_response
2179
2180 Writes information about the response to the debug logs by calling
2181 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2182
2183 =cut
2184
2185 sub log_response {
2186     my $c = shift;
2187
2188     return unless $c->debug;
2189
2190     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2191     my $response = $dump->[1];
2192
2193     $c->log_response_status_line($response);
2194     $c->log_response_headers($response->headers);
2195 }
2196
2197 =head2 $c->log_response_status_line($response)
2198
2199 Writes one line of information about the response to the debug logs.  This includes:
2200
2201 =over 4
2202
2203 =item * Response status code
2204
2205 =item * Content-Type header (if present)
2206
2207 =item * Content-Length header (if present)
2208
2209 =back
2210
2211 =cut
2212
2213 sub log_response_status_line {
2214     my ($c, $response) = @_;
2215
2216     $c->log->debug(
2217         sprintf(
2218             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2219             $response->status                            || 'unknown',
2220             $response->headers->header('Content-Type')   || 'unknown',
2221             $response->headers->header('Content-Length') || 'unknown'
2222         )
2223     );
2224 }
2225
2226 =head2 $c->log_response_headers($headers);
2227
2228 Hook method which can be wrapped by plugins to log the responseheaders.
2229 No-op in the default implementation.
2230
2231 =cut
2232
2233 sub log_response_headers {}
2234
2235 =head2 $c->log_request_parameters( query => {}, body => {} )
2236
2237 Logs request parameters to debug logs
2238
2239 =cut
2240
2241 sub log_request_parameters {
2242     my $c          = shift;
2243     my %all_params = @_;
2244
2245     return unless $c->debug;
2246
2247     my $column_width = Catalyst::Utils::term_width() - 44;
2248     foreach my $type (qw(query body)) {
2249         my $params = $all_params{$type};
2250         next if ! keys %$params;
2251         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2252         for my $key ( sort keys %$params ) {
2253             my $param = $params->{$key};
2254             my $value = defined($param) ? $param : '';
2255             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2256         }
2257         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2258     }
2259 }
2260
2261 =head2 $c->log_request_uploads
2262
2263 Logs file uploads included in the request to the debug logs.
2264 The parameter name, filename, file type, and file size are all included in
2265 the debug logs.
2266
2267 =cut
2268
2269 sub log_request_uploads {
2270     my $c = shift;
2271     my $request = shift;
2272     return unless $c->debug;
2273     my $uploads = $request->uploads;
2274     if ( keys %$uploads ) {
2275         my $t = Text::SimpleTable->new(
2276             [ 12, 'Parameter' ],
2277             [ 26, 'Filename' ],
2278             [ 18, 'Type' ],
2279             [ 9,  'Size' ]
2280         );
2281         for my $key ( sort keys %$uploads ) {
2282             my $upload = $uploads->{$key};
2283             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2284                 $t->row( $key, $u->filename, $u->type, $u->size );
2285             }
2286         }
2287         $c->log->debug( "File Uploads are:\n" . $t->draw );
2288     }
2289 }
2290
2291 =head2 $c->log_request_headers($headers);
2292
2293 Hook method which can be wrapped by plugins to log the request headers.
2294 No-op in the default implementation.
2295
2296 =cut
2297
2298 sub log_request_headers {}
2299
2300 =head2 $c->log_headers($type => $headers)
2301
2302 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2303
2304 =cut
2305
2306 sub log_headers {
2307     my $c       = shift;
2308     my $type    = shift;
2309     my $headers = shift;    # an HTTP::Headers instance
2310
2311     return unless $c->debug;
2312
2313     my $column_width = Catalyst::Utils::term_width() - 28;
2314     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2315     $headers->scan(
2316         sub {
2317             my ( $name, $value ) = @_;
2318             $t->row( $name, $value );
2319         }
2320     );
2321     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2322 }
2323
2324
2325 =head2 $c->prepare_read
2326
2327 Prepares the input for reading.
2328
2329 =cut
2330
2331 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2332
2333 =head2 $c->prepare_request
2334
2335 Prepares the engine request.
2336
2337 =cut
2338
2339 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2340
2341 =head2 $c->prepare_uploads
2342
2343 Prepares uploads.
2344
2345 =cut
2346
2347 sub prepare_uploads {
2348     my $c = shift;
2349
2350     $c->engine->prepare_uploads( $c, @_ );
2351 }
2352
2353 =head2 $c->prepare_write
2354
2355 Prepares the output for writing.
2356
2357 =cut
2358
2359 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2360
2361 =head2 $c->request_class
2362
2363 Returns or sets the request class.
2364
2365 =head2 $c->response_class
2366
2367 Returns or sets the response class.
2368
2369 =head2 $c->read( [$maxlength] )
2370
2371 Reads a chunk of data from the request body. This method is designed to
2372 be used in a while loop, reading C<$maxlength> bytes on every call.
2373 C<$maxlength> defaults to the size of the request if not specified.
2374
2375 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2376 directly.
2377
2378 Warning: If you use read(), Catalyst will not process the body,
2379 so you will not be able to access POST parameters or file uploads via
2380 $c->request.  You must handle all body parsing yourself.
2381
2382 =cut
2383
2384 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2385
2386 =head2 $c->run
2387
2388 Starts the engine.
2389
2390 =cut
2391
2392 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2393
2394 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2395
2396 Sets an action in a given namespace.
2397
2398 =cut
2399
2400 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2401
2402 =head2 $c->setup_actions($component)
2403
2404 Sets up actions for a component.
2405
2406 =cut
2407
2408 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2409
2410 =head2 $c->setup_components
2411
2412 This method is called internally to set up the application's components.
2413
2414 It finds modules by calling the L<locate_components> method, expands them to
2415 package names with the L<expand_component_module> method, and then installs
2416 each component into the application.
2417
2418 The C<setup_components> config option is passed to both of the above methods.
2419
2420 Installation of each component is performed by the L<setup_component> method,
2421 below.
2422
2423 =cut
2424
2425 sub setup_components {
2426     my $class = shift;
2427
2428     my $config  = $class->config->{ setup_components };
2429
2430     my @comps = $class->locate_components($config);
2431     my %comps = map { $_ => 1 } @comps;
2432
2433     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2434     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2435         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2436     ) if $deprecatedcatalyst_component_names;
2437
2438     for my $component ( @comps ) {
2439
2440         # We pass ignore_loaded here so that overlay files for (e.g.)
2441         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2442         # we know M::P::O found a file on disk so this is safe
2443
2444         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2445     }
2446
2447     for my $component (@comps) {
2448         my $instance = $class->components->{ $component } = $class->setup_component($component);
2449         my @expanded_components = $instance->can('expand_modules')
2450             ? $instance->expand_modules( $component, $config )
2451             : $class->expand_component_module( $component, $config );
2452         for my $component (@expanded_components) {
2453             next if $comps{$component};
2454             $class->components->{ $component } = $class->setup_component($component);
2455         }
2456     }
2457 }
2458
2459 =head2 $c->locate_components( $setup_component_config )
2460
2461 This method is meant to provide a list of component modules that should be
2462 setup for the application.  By default, it will use L<Module::Pluggable>.
2463
2464 Specify a C<setup_components> config option to pass additional options directly
2465 to L<Module::Pluggable>. To add additional search paths, specify a key named
2466 C<search_extra> as an array reference. Items in the array beginning with C<::>
2467 will have the application class name prepended to them.
2468
2469 =cut
2470
2471 sub locate_components {
2472     my $class  = shift;
2473     my $config = shift;
2474
2475     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2476     my $extra   = delete $config->{ search_extra } || [];
2477
2478     push @paths, @$extra;
2479
2480     my $locator = Module::Pluggable::Object->new(
2481         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2482         %$config
2483     );
2484
2485     # XXX think about ditching this sort entirely
2486     my @comps = sort { length $a <=> length $b } $locator->plugins;
2487
2488     return @comps;
2489 }
2490
2491 =head2 $c->expand_component_module( $component, $setup_component_config )
2492
2493 Components found by C<locate_components> will be passed to this method, which
2494 is expected to return a list of component (package) names to be set up.
2495
2496 =cut
2497
2498 sub expand_component_module {
2499     my ($class, $module) = @_;
2500     return Devel::InnerPackage::list_packages( $module );
2501 }
2502
2503 =head2 $c->setup_component
2504
2505 =cut
2506
2507 sub setup_component {
2508     my( $class, $component ) = @_;
2509
2510     unless ( $component->can( 'COMPONENT' ) ) {
2511         return $component;
2512     }
2513
2514     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2515     my $config = $class->config->{ $suffix } || {};
2516     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2517     # methods also pass it. local to avoid pointlessly shitting in config
2518     # for the debug screen, as $component is already the key name.
2519     local $config->{catalyst_component_name} = $component;
2520
2521     my $instance = eval { $component->COMPONENT( $class, $config ); };
2522
2523     if ( my $error = $@ ) {
2524         chomp $error;
2525         Catalyst::Exception->throw(
2526             message => qq/Couldn't instantiate component "$component", "$error"/
2527         );
2528     }
2529
2530     unless (blessed $instance) {
2531         my $metaclass = Moose::Util::find_meta($component);
2532         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2533         my $component_method_from = $method_meta->associated_metaclass->name;
2534         my $value = defined($instance) ? $instance : 'undef';
2535         Catalyst::Exception->throw(
2536             message =>
2537             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2538         );
2539     }
2540     return $instance;
2541 }
2542
2543 =head2 $c->setup_dispatcher
2544
2545 Sets up dispatcher.
2546
2547 =cut
2548
2549 sub setup_dispatcher {
2550     my ( $class, $dispatcher ) = @_;
2551
2552     if ($dispatcher) {
2553         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2554     }
2555
2556     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2557         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2558     }
2559
2560     unless ($dispatcher) {
2561         $dispatcher = $class->dispatcher_class;
2562     }
2563
2564     Class::MOP::load_class($dispatcher);
2565
2566     # dispatcher instance
2567     $class->dispatcher( $dispatcher->new );
2568 }
2569
2570 =head2 $c->setup_engine
2571
2572 Sets up engine.
2573
2574 =cut
2575
2576 sub setup_engine {
2577     my ( $class, $engine ) = @_;
2578
2579     if ($engine) {
2580         $engine = 'Catalyst::Engine::' . $engine;
2581     }
2582
2583     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2584         $engine = 'Catalyst::Engine::' . $env;
2585     }
2586
2587     if ( $ENV{MOD_PERL} ) {
2588         my $meta = Class::MOP::get_metaclass_by_name($class);
2589
2590         # create the apache method
2591         $meta->add_method('apache' => sub { shift->engine->apache });
2592
2593         my ( $software, $version ) =
2594           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2595
2596         $version =~ s/_//g;
2597         $version =~ s/(\.[^.]+)\./$1/g;
2598
2599         if ( $software eq 'mod_perl' ) {
2600
2601             if ( !$engine ) {
2602
2603                 if ( $version >= 1.99922 ) {
2604                     $engine = 'Catalyst::Engine::Apache2::MP20';
2605                 }
2606
2607                 elsif ( $version >= 1.9901 ) {
2608                     $engine = 'Catalyst::Engine::Apache2::MP19';
2609                 }
2610
2611                 elsif ( $version >= 1.24 ) {
2612                     $engine = 'Catalyst::Engine::Apache::MP13';
2613                 }
2614
2615                 else {
2616                     Catalyst::Exception->throw( message =>
2617                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2618                 }
2619
2620             }
2621
2622             # install the correct mod_perl handler
2623             if ( $version >= 1.9901 ) {
2624                 *handler = sub  : method {
2625                     shift->handle_request(@_);
2626                 };
2627             }
2628             else {
2629                 *handler = sub ($$) { shift->handle_request(@_) };
2630             }
2631
2632         }
2633
2634         elsif ( $software eq 'Zeus-Perl' ) {
2635             $engine = 'Catalyst::Engine::Zeus';
2636         }
2637
2638         else {
2639             Catalyst::Exception->throw(
2640                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2641         }
2642     }
2643
2644     unless ($engine) {
2645         $engine = $class->engine_class;
2646     }
2647
2648     Class::MOP::load_class($engine);
2649
2650     # check for old engines that are no longer compatible
2651     my $old_engine;
2652     if ( $engine->isa('Catalyst::Engine::Apache')
2653         && !Catalyst::Engine::Apache->VERSION )
2654     {
2655         $old_engine = 1;
2656     }
2657
2658     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2659         && Catalyst::Engine::Server->VERSION le '0.02' )
2660     {
2661         $old_engine = 1;
2662     }
2663
2664     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2665         && $engine->VERSION eq '0.01' )
2666     {
2667         $old_engine = 1;
2668     }
2669
2670     elsif ($engine->isa('Catalyst::Engine::Zeus')
2671         && $engine->VERSION eq '0.01' )
2672     {
2673         $old_engine = 1;
2674     }
2675
2676     if ($old_engine) {
2677         Catalyst::Exception->throw( message =>
2678               qq/Engine "$engine" is not supported by this version of Catalyst/
2679         );
2680     }
2681
2682     # engine instance
2683     $class->engine( $engine->new );
2684 }
2685
2686 =head2 $c->setup_home
2687
2688 Sets up the home directory.
2689
2690 =cut
2691
2692 sub setup_home {
2693     my ( $class, $home ) = @_;
2694
2695     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2696         $home = $env;
2697     }
2698
2699     $home ||= Catalyst::Utils::home($class);
2700
2701     if ($home) {
2702         #I remember recently being scolded for assigning config values like this
2703         $class->config->{home} ||= $home;
2704         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2705     }
2706 }
2707
2708 =head2 $c->setup_log
2709
2710 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2711 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2712 log to.
2713
2714 This method also installs a C<debug> method that returns a true value into the
2715 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2716 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2717
2718 Note that if the log has already been setup, by either a previous call to
2719 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2720 that this method won't actually set up the log object.
2721
2722 =cut
2723
2724 sub setup_log {
2725     my ( $class, $levels ) = @_;
2726
2727     $levels ||= '';
2728     $levels =~ s/^\s+//;
2729     $levels =~ s/\s+$//;
2730     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2731
2732     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2733     if ( defined $env_debug ) {
2734         $levels{debug} = 1 if $env_debug; # Ugly!
2735         delete($levels{debug}) unless $env_debug;
2736     }
2737
2738     unless ( $class->log ) {
2739         $class->log( Catalyst::Log->new(keys %levels) );
2740     }
2741
2742     if ( $levels{debug} ) {
2743         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2744         $class->log->debug('Debug messages enabled');
2745     }
2746 }
2747
2748 =head2 $c->setup_plugins
2749
2750 Sets up plugins.
2751
2752 =cut
2753
2754 =head2 $c->setup_stats
2755
2756 Sets up timing statistics class.
2757
2758 =cut
2759
2760 sub setup_stats {
2761     my ( $class, $stats ) = @_;
2762
2763     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2764
2765     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2766     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2767         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2768         $class->log->debug('Statistics enabled');
2769     }
2770 }
2771
2772
2773 =head2 $c->registered_plugins
2774
2775 Returns a sorted list of the plugins which have either been stated in the
2776 import list or which have been added via C<< MyApp->plugin(@args); >>.
2777
2778 If passed a given plugin name, it will report a boolean value indicating
2779 whether or not that plugin is loaded.  A fully qualified name is required if
2780 the plugin name does not begin with C<Catalyst::Plugin::>.
2781
2782  if ($c->registered_plugins('Some::Plugin')) {
2783      ...
2784  }
2785
2786 =cut
2787
2788 {
2789
2790     sub registered_plugins {
2791         my $proto = shift;
2792         return sort keys %{ $proto->_plugins } unless @_;
2793         my $plugin = shift;
2794         return 1 if exists $proto->_plugins->{$plugin};
2795         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2796     }
2797
2798     sub _register_plugin {
2799         my ( $proto, $plugin, $instant ) = @_;
2800         my $class = ref $proto || $proto;
2801
2802         Class::MOP::load_class( $plugin );
2803         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2804             if $plugin->isa( 'Catalyst::Component' );
2805         $proto->_plugins->{$plugin} = 1;
2806         unless ($instant) {
2807             my $meta = Class::MOP::get_metaclass_by_name($class);
2808             $meta->superclasses($plugin, $meta->superclasses);
2809         }
2810         return $class;
2811     }
2812
2813     sub setup_plugins {
2814         my ( $class, $plugins ) = @_;
2815
2816         $class->_plugins( {} ) unless $class->_plugins;
2817         $plugins = Data::OptList::mkopt($plugins || []);
2818
2819         my @plugins = map {
2820             [ Catalyst::Utils::resolve_namespace(
2821                   $class . '::Plugin',
2822                   'Catalyst::Plugin', $_->[0]
2823               ),
2824               $_->[1],
2825             ]
2826          } @{ $plugins };
2827
2828         for my $plugin ( reverse @plugins ) {
2829             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2830             my $meta = find_meta($plugin->[0]);
2831             next if $meta && $meta->isa('Moose::Meta::Role');
2832
2833             $class->_register_plugin($plugin->[0]);
2834         }
2835
2836         my @roles =
2837             map  { $_->[0]->name, $_->[1] }
2838             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2839             map  { [find_meta($_->[0]), $_->[1]] }
2840             @plugins;
2841
2842         Moose::Util::apply_all_roles(
2843             $class => @roles
2844         ) if @roles;
2845     }
2846 }
2847
2848 =head2 $c->stack
2849
2850 Returns an arrayref of the internal execution stack (actions that are
2851 currently executing).
2852
2853 =head2 $c->stats
2854
2855 Returns the current timing statistics object. By default Catalyst uses
2856 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2857 L<< stats_class|/"$c->stats_class" >>.
2858
2859 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2860 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2861 profile explicitly, although MyApp.pm still won't profile nor output anything
2862 by itself.
2863
2864 =head2 $c->stats_class
2865
2866 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2867
2868 =head2 $c->use_stats
2869
2870 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2871
2872 Note that this is a static method, not an accessor and should be overridden
2873 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2874
2875 =cut
2876
2877 sub use_stats { 0 }
2878
2879
2880 =head2 $c->write( $data )
2881
2882 Writes $data to the output stream. When using this method directly, you
2883 will need to manually set the C<Content-Length> header to the length of
2884 your output data, if known.
2885
2886 =cut
2887
2888 sub write {
2889     my $c = shift;
2890
2891     # Finalize headers if someone manually writes output
2892     $c->finalize_headers;
2893
2894     return $c->engine->write( $c, @_ );
2895 }
2896
2897 =head2 version
2898
2899 Returns the Catalyst version number. Mostly useful for "powered by"
2900 messages in template systems.
2901
2902 =cut
2903
2904 sub version { return $Catalyst::VERSION }
2905
2906 =head1 CONFIGURATION
2907
2908 There are a number of 'base' config variables which can be set:
2909
2910 =over
2911
2912 =item *
2913
2914 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2915
2916 =item *
2917
2918 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2919
2920 =item *
2921
2922 C<disable_component_resolution_regex_fallback> - Turns
2923 off the deprecated component resolution functionality so
2924 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2925 are called then regex search will not be attempted on string values and
2926 instead C<undef> will be returned.
2927
2928 =item *
2929
2930 C<home> - The application home directory. In an uninstalled application,
2931 this is the top level application directory. In an installed application,
2932 this will be the directory containing C<< MyApp.pm >>.
2933
2934 =item *
2935
2936 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2937
2938 =item *
2939
2940 C<name> - The name of the application in debug messages and the debug and
2941 welcome screens
2942
2943 =item *
2944
2945 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2946 until it is accessed. This allows you to (for example) check authentication (and reject
2947 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2948
2949 =item *
2950
2951 C<root> - The root directory for templates. Usually this is just a
2952 subdirectory of the home directory, but you can set it to change the
2953 templates to a different directory.
2954
2955 =item *
2956
2957 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2958 namespaces from which components will be loaded (and constructed and stored in
2959 C<< $c->components >>).
2960
2961 =item *
2962
2963 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2964 to be shown in hit debug tables in the test server.
2965
2966 =item *
2967
2968 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2969 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2970 for more information.
2971
2972 =item *
2973
2974 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2975
2976 =back
2977
2978 =head1 INTERNAL ACTIONS
2979
2980 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2981 C<_ACTION>, and C<_END>. These are by default not shown in the private
2982 action table, but you can make them visible with a config parameter.
2983
2984     MyApp->config(show_internal_actions => 1);
2985
2986 =head1 ON-DEMAND PARSER
2987
2988 The request body is usually parsed at the beginning of a request,
2989 but if you want to handle input yourself, you can enable on-demand
2990 parsing with a config parameter.
2991
2992     MyApp->config(parse_on_demand => 1);
2993
2994 =head1 PROXY SUPPORT
2995
2996 Many production servers operate using the common double-server approach,
2997 with a lightweight frontend web server passing requests to a larger
2998 backend server. An application running on the backend server must deal
2999 with two problems: the remote user always appears to be C<127.0.0.1> and
3000 the server's hostname will appear to be C<localhost> regardless of the
3001 virtual host that the user connected through.
3002
3003 Catalyst will automatically detect this situation when you are running
3004 the frontend and backend servers on the same machine. The following
3005 changes are made to the request.
3006
3007     $c->req->address is set to the user's real IP address, as read from
3008     the HTTP X-Forwarded-For header.
3009
3010     The host value for $c->req->base and $c->req->uri is set to the real
3011     host, as read from the HTTP X-Forwarded-Host header.
3012
3013 Additionally, you may be running your backend application on an insecure
3014 connection (port 80) while your frontend proxy is running under SSL.  If there
3015 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3016 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3017 be created properly.
3018
3019 In the case of passing in:
3020
3021     X-Forwarded-Port: 443
3022
3023 All calls to C<uri_for> will result in an https link, as is expected.
3024
3025 Obviously, your web server must support these headers for this to work.
3026
3027 In a more complex server farm environment where you may have your
3028 frontend proxy server(s) on different machines, you will need to set a
3029 configuration option to tell Catalyst to read the proxied data from the
3030 headers.
3031
3032     MyApp->config(using_frontend_proxy => 1);
3033
3034 If you do not wish to use the proxy support at all, you may set:
3035
3036     MyApp->config(ignore_frontend_proxy => 1);
3037
3038 =head1 THREAD SAFETY
3039
3040 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3041 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3042 believe the Catalyst core to be thread-safe.
3043
3044 If you plan to operate in a threaded environment, remember that all other
3045 modules you are using must also be thread-safe. Some modules, most notably
3046 L<DBD::SQLite>, are not thread-safe.
3047
3048 =head1 SUPPORT
3049
3050 IRC:
3051
3052     Join #catalyst on irc.perl.org.
3053
3054 Mailing Lists:
3055
3056     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3057     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3058
3059 Web:
3060
3061     http://catalyst.perl.org
3062
3063 Wiki:
3064
3065     http://dev.catalyst.perl.org
3066
3067 =head1 SEE ALSO
3068
3069 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3070
3071 =head2 L<Catalyst::Manual> - The Catalyst Manual
3072
3073 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3074
3075 =head2 L<Catalyst::Engine> - Core engine
3076
3077 =head2 L<Catalyst::Log> - Log class.
3078
3079 =head2 L<Catalyst::Request> - Request object
3080
3081 =head2 L<Catalyst::Response> - Response object
3082
3083 =head2 L<Catalyst::Test> - The test suite.
3084
3085 =head1 PROJECT FOUNDER
3086
3087 sri: Sebastian Riedel <sri@cpan.org>
3088
3089 =head1 CONTRIBUTORS
3090
3091 abw: Andy Wardley
3092
3093 acme: Leon Brocard <leon@astray.com>
3094
3095 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3096
3097 Andrew Bramble
3098
3099 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3100
3101 Andrew Ruthven
3102
3103 andyg: Andy Grundman <andy@hybridized.org>
3104
3105 audreyt: Audrey Tang
3106
3107 bricas: Brian Cassidy <bricas@cpan.org>
3108
3109 Caelum: Rafael Kitover <rkitover@io.com>
3110
3111 chansen: Christian Hansen
3112
3113 chicks: Christopher Hicks
3114
3115 Chisel Wright C<pause@herlpacker.co.uk>
3116
3117 Danijel Milicevic C<me@danijel.de>
3118
3119 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3120
3121 David Naughton, C<naughton@umn.edu>
3122
3123 David E. Wheeler
3124
3125 dhoss: Devin Austin <dhoss@cpan.org>
3126
3127 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3128
3129 Drew Taylor
3130
3131 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3132
3133 esskar: Sascha Kiefer
3134
3135 fireartist: Carl Franks <cfranks@cpan.org>
3136
3137 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3138
3139 gabb: Danijel Milicevic
3140
3141 Gary Ashton Jones
3142
3143 Gavin Henry C<ghenry@perl.me.uk>
3144
3145 Geoff Richards
3146
3147 groditi: Guillermo Roditi <groditi@gmail.com>
3148
3149 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3150
3151 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3152
3153 jcamacho: Juan Camacho
3154
3155 jester: Jesse Sheidlower C<jester@panix.com>
3156
3157 jhannah: Jay Hannah <jay@jays.net>
3158
3159 Jody Belka
3160
3161 Johan Lindstrom
3162
3163 jon: Jon Schutz <jjschutz@cpan.org>
3164
3165 Jonathan Rockway C<< <jrockway@cpan.org> >>
3166
3167 Kieren Diment C<kd@totaldatasolution.com>
3168
3169 konobi: Scott McWhirter <konobi@cpan.org>
3170
3171 marcus: Marcus Ramberg <mramberg@cpan.org>
3172
3173 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3174
3175 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3176
3177 mugwump: Sam Vilain
3178
3179 naughton: David Naughton
3180
3181 ningu: David Kamholz <dkamholz@cpan.org>
3182
3183 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3184
3185 numa: Dan Sully <daniel@cpan.org>
3186
3187 obra: Jesse Vincent
3188
3189 Octavian Rasnita
3190
3191 omega: Andreas Marienborg
3192
3193 Oleg Kostyuk <cub.uanic@gmail.com>
3194
3195 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3196
3197 rafl: Florian Ragwitz <rafl@debian.org>
3198
3199 random: Roland Lammel <lammel@cpan.org>
3200
3201 Robert Sedlacek C<< <rs@474.at> >>
3202
3203 SpiceMan: Marcel Montes
3204
3205 sky: Arthur Bergman
3206
3207 szbalint: Balint Szilakszi <szbalint@cpan.org>
3208
3209 t0m: Tomas Doran <bobtfish@bobtfish.net>
3210
3211 Ulf Edvinsson
3212
3213 Viljo Marrandi C<vilts@yahoo.com>
3214
3215 Will Hawes C<info@whawes.co.uk>
3216
3217 willert: Sebastian Willert <willert@cpan.org>
3218
3219 wreis: Wallace Reis <wallace@reis.org.br>
3220
3221 Yuval Kogman, C<nothingmuch@woobling.org>
3222
3223 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3224
3225 =head1 LICENSE
3226
3227 This library is free software. You can redistribute it and/or modify it under
3228 the same terms as Perl itself.
3229
3230 =cut
3231
3232 no Moose;
3233
3234 __PACKAGE__->meta->make_immutable;
3235
3236 1;