lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Plack::Middleware::Conditional;
  39 use Plack::Middleware::ReverseProxy;
  40 use Plack::Middleware::IIS6ScriptNameFix;
  41 use Plack::Middleware::IIS7KeepAliveFix;
  42 use Plack::Middleware::LighttpdScriptNameFix;
  43 use Plack::Util;
  44 use JSON::MaybeXS qw(decode_json);
  45
  46 BEGIN { require 5.008003; }
  47
  48 has stack => (is => 'ro', default => sub { [] });
  49 has stash => (is => 'rw', default => sub { {} });
  50 has state => (is => 'rw', default => 0);
  51 has stats => (is => 'rw');
  52 has action => (is => 'rw');
  53 has counter => (is => 'rw', default => sub { {} });
  54 has request => (
  55     is => 'rw',
  56     default => sub {
  57         my $self = shift;
  58         $self->request_class->new($self->_build_request_constructor_args);
  59     },
  60     lazy => 1,
  61 );
  62 sub _build_request_constructor_args {
  63     my $self = shift;
  64     my %p = ( _log => $self->log );
  65     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  66     $p{data_handlers} = {$self->registered_data_handlers};
  67     \%p;
  68 }
  69
  70 has response => (
  71     is => 'rw',
  72     default => sub {
  73         my $self = shift;
  74         $self->response_class->new($self->_build_response_constructor_args);
  75     },
  76     lazy => 1,
  77 );
  78 sub _build_response_constructor_args {
  79     my $self = shift;
  80     { _log => $self->log };
  81 }
  82
  83 has namespace => (is => 'rw');
  84
  85 sub depth { scalar @{ shift->stack || [] }; }
  86 sub comp { shift->component(@_) }
  87
  88 sub req {
  89     my $self = shift; return $self->request(@_);
  90 }
  91 sub res {
  92     my $self = shift; return $self->response(@_);
  93 }
  94
  95 # For backwards compatibility
  96 sub finalize_output { shift->finalize_body(@_) };
  97
  98 # For statistics
  99 our $COUNT     = 1;
 100 our $START     = time;
 101 our $RECURSION = 1000;
 102 our $DETACH    = Catalyst::Exception::Detach->new;
 103 our $GO        = Catalyst::Exception::Go->new;
 104
 105 #I imagine that very few of these really need to be class variables. if any.
 106 #maybe we should just make them attributes with a default?
 107 __PACKAGE__->mk_classdata($_)
 108   for qw/components arguments dispatcher engine log dispatcher_class
 109   engine_loader context_class request_class response_class stats_class
 110   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 111   _data_handlers/;
 112
 113 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 114 __PACKAGE__->request_class('Catalyst::Request');
 115 __PACKAGE__->response_class('Catalyst::Response');
 116 __PACKAGE__->stats_class('Catalyst::Stats');
 117
 118 # Remember to update this in Catalyst::Runtime as well!
 119
 120 our $VERSION = '5.90049_001';
 121
 122 sub import {
 123     my ( $class, @arguments ) = @_;
 124
 125     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 126     # callers @ISA.
 127     return unless $class eq 'Catalyst';
 128
 129     my $caller = caller();
 130     return if $caller eq 'main';
 131
 132     my $meta = Moose::Meta::Class->initialize($caller);
 133     unless ( $caller->isa('Catalyst') ) {
 134         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 135         $meta->superclasses(@superclasses);
 136     }
 137     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 138     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 139
 140     unless( $meta->has_method('meta') ){
 141         if ($Moose::VERSION >= 1.15) {
 142             $meta->_add_meta_method('meta');
 143         }
 144         else {
 145             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 146         }
 147     }
 148
 149     $caller->arguments( [@arguments] );
 150     $caller->setup_home;
 151 }
 152
 153 sub _application { $_[0] }
 154
 155 =encoding UTF-8
 156
 157 =head1 NAME
 158
 159 Catalyst - The Elegant MVC Web Application Framework
 160
 161 =head1 SYNOPSIS
 162
 163 See the L<Catalyst::Manual> distribution for comprehensive
 164 documentation and tutorials.
 165
 166     # Install Catalyst::Devel for helpers and other development tools
 167     # use the helper to create a new application
 168     catalyst.pl MyApp
 169
 170     # add models, views, controllers
 171     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 172     script/myapp_create.pl view MyTemplate TT
 173     script/myapp_create.pl controller Search
 174
 175     # built in testserver -- use -r to restart automatically on changes
 176     # --help to see all available options
 177     script/myapp_server.pl
 178
 179     # command line testing interface
 180     script/myapp_test.pl /yada
 181
 182     ### in lib/MyApp.pm
 183     use Catalyst qw/-Debug/; # include plugins here as well
 184
 185     ### In lib/MyApp/Controller/Root.pm (autocreated)
 186     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 187         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 188         $c->stash->{template} = 'foo.tt'; # set the template
 189         # lookup something from db -- stash vars are passed to TT
 190         $c->stash->{data} =
 191           $c->model('Database::Foo')->search( { country => $args[0] } );
 192         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 193             $c->forward( 'bar' ); # process another action
 194             # do something else after forward returns
 195         }
 196     }
 197
 198     # The foo.tt TT template can use the stash data from the database
 199     [% WHILE (item = data.next) %]
 200         [% item.foo %]
 201     [% END %]
 202
 203     # called for /bar/of/soap, /bar/of/soap/10, etc.
 204     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 205
 206     # called after all actions are finished
 207     sub end : Action {
 208         my ( $self, $c ) = @_;
 209         if ( scalar @{ $c->error } ) { ... } # handle errors
 210         return if $c->res->body; # already have a response
 211         $c->forward( 'MyApp::View::TT' ); # render template
 212     }
 213
 214 See L<Catalyst::Manual::Intro> for additional information.
 215
 216 =head1 DESCRIPTION
 217
 218 Catalyst is a modern framework for making web applications without the
 219 pain usually associated with this process. This document is a reference
 220 to the main Catalyst application. If you are a new user, we suggest you
 221 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 222
 223 See L<Catalyst::Manual> for more documentation.
 224
 225 Catalyst plugins can be loaded by naming them as arguments to the "use
 226 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 227 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 228 C<My::Module>.
 229
 230     use Catalyst qw/My::Module/;
 231
 232 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 233 fully qualify the name by using a unary plus:
 234
 235     use Catalyst qw/
 236         My::Module
 237         +Fully::Qualified::Plugin::Name
 238     /;
 239
 240 Special flags like C<-Debug> can also be specified as
 241 arguments when Catalyst is loaded:
 242
 243     use Catalyst qw/-Debug My::Module/;
 244
 245 The position of plugins and flags in the chain is important, because
 246 they are loaded in the order in which they appear.
 247
 248 The following flags are supported:
 249
 250 =head2 -Debug
 251
 252 Enables debug output. You can also force this setting from the system
 253 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 254 settings override the application, with <MYAPP>_DEBUG having the highest
 255 priority.
 256
 257 This sets the log level to 'debug' and enables full debug output on the
 258 error screen. If you only want the latter, see L<< $c->debug >>.
 259
 260 =head2 -Home
 261
 262 Forces Catalyst to use a specific home directory, e.g.:
 263
 264     use Catalyst qw[-Home=/usr/mst];
 265
 266 This can also be done in the shell environment by setting either the
 267 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 268 is replaced with the uppercased name of your application, any "::" in
 269 the name will be replaced with underscores, e.g. MyApp::Web should use
 270 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 271
 272 If none of these are set, Catalyst will attempt to automatically detect the
 273 home directory. If you are working in a development environment, Catalyst
 274 will try and find the directory containing either Makefile.PL, Build.PL,
 275 dist.ini, or cpanfile. If the application has been installed into the system
 276 (i.e. you have done C<make install>), then Catalyst will use the path to your
 277 application module, without the .pm extension (e.g., /foo/MyApp if your
 278 application was installed at /foo/MyApp.pm)
 279
 280 =head2 -Log
 281
 282     use Catalyst '-Log=warn,fatal,error';
 283
 284 Specifies a comma-delimited list of log levels.
 285
 286 =head2 -Stats
 287
 288 Enables statistics collection and reporting.
 289
 290    use Catalyst qw/-Stats=1/;
 291
 292 You can also force this setting from the system environment with CATALYST_STATS
 293 or <MYAPP>_STATS. The environment settings override the application, with
 294 <MYAPP>_STATS having the highest priority.
 295
 296 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 297
 298 =head1 METHODS
 299
 300 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 301
 302 =head2 $c->action
 303
 304 Returns a L<Catalyst::Action> object for the current action, which
 305 stringifies to the action name. See L<Catalyst::Action>.
 306
 307 =head2 $c->namespace
 308
 309 Returns the namespace of the current action, i.e., the URI prefix
 310 corresponding to the controller of the current action. For example:
 311
 312     # in Controller::Foo::Bar
 313     $c->namespace; # returns 'foo/bar';
 314
 315 =head2 $c->request
 316
 317 =head2 $c->req
 318
 319 Returns the current L<Catalyst::Request> object, giving access to
 320 information about the current client request (including parameters,
 321 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 322
 323 =head2 REQUEST FLOW HANDLING
 324
 325 =head2 $c->forward( $action [, \@arguments ] )
 326
 327 =head2 $c->forward( $class, $method, [, \@arguments ] )
 328
 329 Forwards processing to another action, by its private name. If you give a
 330 class name but no method, C<process()> is called. You may also optionally
 331 pass arguments in an arrayref. The action will receive the arguments in
 332 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 333 C<< $c->req->args >> will be restored to the previous values.
 334
 335 Any data C<return>ed from the action forwarded to, will be returned by the
 336 call to forward.
 337
 338     my $foodata = $c->forward('/foo');
 339     $c->forward('index');
 340     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 341     $c->forward('View::TT');
 342
 343 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 344 an C<< eval { } >> around the call (actually
 345 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 346 exceptions thrown by the called action non-fatal and pushing them onto
 347 $c->error instead. If you want C<die> to propagate you need to do something
 348 like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@arguments ] )
 395
 396 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 397
 398 =head2 $c->visit( $class, $method, [, \@arguments ] )
 399
 400 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 401
 402 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 403 but does a full dispatch, instead of just calling the new C<$action> /
 404 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 405 you go to are called, just like a new request.
 406
 407 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 408 This means, for example, that C<< $c->action >> methods such as
 409 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 410 L<reverse|Catalyst::Action/reverse> return information for the visited action
 411 when they are invoked within the visited action.  This is different from the
 412 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 413 continues to use the $c->action object from the caller action even when
 414 invoked from the called action.
 415
 416 C<< $c->stash >> is kept unchanged.
 417
 418 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 419 allows you to "wrap" another action, just as it would have been called by
 420 dispatching from a URL, while the analogous
 421 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 422 transfer control to another action as if it had been reached directly from a URL.
 423
 424 =cut
 425
 426 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 427
 428 =head2 $c->go( $action [, \@arguments ] )
 429
 430 =head2 $c->go( $action [, \@captures, \@arguments ] )
 431
 432 =head2 $c->go( $class, $method, [, \@arguments ] )
 433
 434 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 435
 436 The relationship between C<go> and
 437 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 438 the relationship between
 439 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 440 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 441 C<< $c->go >> will perform a full dispatch on the specified action or method,
 442 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 443 C<go> escapes the processing of the current request chain on completion, and
 444 does not return to its caller.
 445
 446 @arguments are arguments to the final destination of $action. @captures are
 447 arguments to the intermediate steps, if any, on the way to the final sub of
 448 $action.
 449
 450 =cut
 451
 452 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 453
 454 =head2 $c->response
 455
 456 =head2 $c->res
 457
 458 Returns the current L<Catalyst::Response> object, see there for details.
 459
 460 =head2 $c->stash
 461
 462 Returns a hashref to the stash, which may be used to store data and pass
 463 it between components during a request. You can also set hash keys by
 464 passing arguments. The stash is automatically sent to the view. The
 465 stash is cleared at the end of a request; it cannot be used for
 466 persistent storage (for this you must use a session; see
 467 L<Catalyst::Plugin::Session> for a complete system integrated with
 468 Catalyst).
 469
 470     $c->stash->{foo} = $bar;
 471     $c->stash( { moose => 'majestic', qux => 0 } );
 472     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 473
 474     # stash is automatically passed to the view for use in a template
 475     $c->forward( 'MyApp::View::TT' );
 476
 477 =cut
 478
 479 around stash => sub {
 480     my $orig = shift;
 481     my $c = shift;
 482     my $stash = $orig->($c);
 483     if (@_) {
 484         my $new_stash = @_ > 1 ? {@_} : $_[0];
 485         croak('stash takes a hash or hashref') unless ref $new_stash;
 486         foreach my $key ( keys %$new_stash ) {
 487           $stash->{$key} = $new_stash->{$key};
 488         }
 489     }
 490
 491     return $stash;
 492 };
 493
 494
 495 =head2 $c->error
 496
 497 =head2 $c->error($error, ...)
 498
 499 =head2 $c->error($arrayref)
 500
 501 Returns an arrayref containing error messages.  If Catalyst encounters an
 502 error while processing a request, it stores the error in $c->error.  This
 503 method should only be used to store fatal error messages.
 504
 505     my @error = @{ $c->error };
 506
 507 Add a new error.
 508
 509     $c->error('Something bad happened');
 510
 511 =cut
 512
 513 sub error {
 514     my $c = shift;
 515     if ( $_[0] ) {
 516         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 517         croak @$error unless ref $c;
 518         push @{ $c->{error} }, @$error;
 519     }
 520     elsif ( defined $_[0] ) { $c->{error} = undef }
 521     return $c->{error} || [];
 522 }
 523
 524
 525 =head2 $c->state
 526
 527 Contains the return value of the last executed action.
 528 Note that << $c->state >> operates in a scalar context which means that all
 529 values it returns are scalar.
 530
 531 =head2 $c->clear_errors
 532
 533 Clear errors.  You probably don't want to clear the errors unless you are
 534 implementing a custom error screen.
 535
 536 This is equivalent to running
 537
 538     $c->error(0);
 539
 540 =cut
 541
 542 sub clear_errors {
 543     my $c = shift;
 544     $c->error(0);
 545 }
 546
 547 sub _comp_search_prefixes {
 548     my $c = shift;
 549     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 550 }
 551
 552 # search components given a name and some prefixes
 553 sub _comp_names_search_prefixes {
 554     my ( $c, $name, @prefixes ) = @_;
 555     my $appclass = ref $c || $c;
 556     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 557     $filter = qr/$filter/; # Compile regex now rather than once per loop
 558
 559     # map the original component name to the sub part that we will search against
 560     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 561         grep { /$filter/ } keys %{ $c->components };
 562
 563     # undef for a name will return all
 564     return keys %eligible if !defined $name;
 565
 566     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 567     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 568
 569     return @result if @result;
 570
 571     # if we were given a regexp to search against, we're done.
 572     return if $name->$_isa('Regexp');
 573
 574     # skip regexp fallback if configured
 575     return
 576         if $appclass->config->{disable_component_resolution_regex_fallback};
 577
 578     # regexp fallback
 579     $query  = qr/$name/i;
 580     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 581
 582     # no results? try against full names
 583     if( !@result ) {
 584         @result = grep { m{$query} } keys %eligible;
 585     }
 586
 587     # don't warn if we didn't find any results, it just might not exist
 588     if( @result ) {
 589         # Disgusting hack to work out correct method name
 590         my $warn_for = lc $prefixes[0];
 591         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 592            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 593            "component resolution is unreliable and unsafe.";
 594         my $short = $result[0];
 595         # remove the component namespace prefix
 596         $short =~ s/.*?(Model|Controller|View):://;
 597         my $shortmess = Carp::shortmess('');
 598         if ($shortmess =~ m#Catalyst/Plugin#) {
 599            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 600               "plugin's config";
 601         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 602            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 603               "component's config";
 604         } else {
 605            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 606               "but if you really wanted to search, pass in a regexp as the argument " .
 607               "like so: \$c->${warn_for}(qr/${name}/)";
 608         }
 609         $c->log->warn( "${msg}$shortmess" );
 610     }
 611
 612     return @result;
 613 }
 614
 615 # Find possible names for a prefix
 616 sub _comp_names {
 617     my ( $c, @prefixes ) = @_;
 618     my $appclass = ref $c || $c;
 619
 620     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 621
 622     my @names = map { s{$filter}{}; $_; }
 623         $c->_comp_names_search_prefixes( undef, @prefixes );
 624
 625     return @names;
 626 }
 627
 628 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 629 sub _filter_component {
 630     my ( $c, $comp, @args ) = @_;
 631
 632     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 633         return $comp->ACCEPT_CONTEXT( $c, @args );
 634     }
 635
 636     return $comp;
 637 }
 638
 639 =head2 COMPONENT ACCESSORS
 640
 641 =head2 $c->controller($name)
 642
 643 Gets a L<Catalyst::Controller> instance by name.
 644
 645     $c->controller('Foo')->do_stuff;
 646
 647 If the name is omitted, will return the controller for the dispatched
 648 action.
 649
 650 If you want to search for controllers, pass in a regexp as the argument.
 651
 652     # find all controllers that start with Foo
 653     my @foo_controllers = $c->controller(qr{^Foo});
 654
 655
 656 =cut
 657
 658 sub controller {
 659     my ( $c, $name, @args ) = @_;
 660
 661     my $appclass = ref($c) || $c;
 662     if( $name ) {
 663         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 664             my $comps = $c->components;
 665             my $check = $appclass."::Controller::".$name;
 666             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 667         }
 668         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 669         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 670         return $c->_filter_component( $result[ 0 ], @args );
 671     }
 672
 673     return $c->component( $c->action->class );
 674 }
 675
 676 =head2 $c->model($name)
 677
 678 Gets a L<Catalyst::Model> instance by name.
 679
 680     $c->model('Foo')->do_stuff;
 681
 682 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 683
 684 If the name is omitted, it will look for
 685  - a model object in $c->stash->{current_model_instance}, then
 686  - a model name in $c->stash->{current_model}, then
 687  - a config setting 'default_model', or
 688  - check if there is only one model, and return it if that's the case.
 689
 690 If you want to search for models, pass in a regexp as the argument.
 691
 692     # find all models that start with Foo
 693     my @foo_models = $c->model(qr{^Foo});
 694
 695 =cut
 696
 697 sub model {
 698     my ( $c, $name, @args ) = @_;
 699     my $appclass = ref($c) || $c;
 700     if( $name ) {
 701         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 702             my $comps = $c->components;
 703             my $check = $appclass."::Model::".$name;
 704             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 705         }
 706         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 707         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 708         return $c->_filter_component( $result[ 0 ], @args );
 709     }
 710
 711     if (ref $c) {
 712         return $c->stash->{current_model_instance}
 713           if $c->stash->{current_model_instance};
 714         return $c->model( $c->stash->{current_model} )
 715           if $c->stash->{current_model};
 716     }
 717     return $c->model( $appclass->config->{default_model} )
 718       if $appclass->config->{default_model};
 719
 720     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 721
 722     if( $rest ) {
 723         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 724         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 725         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 726         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 727         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 728     }
 729
 730     return $c->_filter_component( $comp );
 731 }
 732
 733
 734 =head2 $c->view($name)
 735
 736 Gets a L<Catalyst::View> instance by name.
 737
 738     $c->view('Foo')->do_stuff;
 739
 740 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 741
 742 If the name is omitted, it will look for
 743  - a view object in $c->stash->{current_view_instance}, then
 744  - a view name in $c->stash->{current_view}, then
 745  - a config setting 'default_view', or
 746  - check if there is only one view, and return it if that's the case.
 747
 748 If you want to search for views, pass in a regexp as the argument.
 749
 750     # find all views that start with Foo
 751     my @foo_views = $c->view(qr{^Foo});
 752
 753 =cut
 754
 755 sub view {
 756     my ( $c, $name, @args ) = @_;
 757
 758     my $appclass = ref($c) || $c;
 759     if( $name ) {
 760         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 761             my $comps = $c->components;
 762             my $check = $appclass."::View::".$name;
 763             if( exists $comps->{$check} ) {
 764                 return $c->_filter_component( $comps->{$check}, @args );
 765             }
 766             else {
 767                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 768             }
 769         }
 770         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 771         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 772         return $c->_filter_component( $result[ 0 ], @args );
 773     }
 774
 775     if (ref $c) {
 776         return $c->stash->{current_view_instance}
 777           if $c->stash->{current_view_instance};
 778         return $c->view( $c->stash->{current_view} )
 779           if $c->stash->{current_view};
 780     }
 781     return $c->view( $appclass->config->{default_view} )
 782       if $appclass->config->{default_view};
 783
 784     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 785
 786     if( $rest ) {
 787         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 788         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 789         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 790         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 791         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 792     }
 793
 794     return $c->_filter_component( $comp );
 795 }
 796
 797 =head2 $c->controllers
 798
 799 Returns the available names which can be passed to $c->controller
 800
 801 =cut
 802
 803 sub controllers {
 804     my ( $c ) = @_;
 805     return $c->_comp_names(qw/Controller C/);
 806 }
 807
 808 =head2 $c->models
 809
 810 Returns the available names which can be passed to $c->model
 811
 812 =cut
 813
 814 sub models {
 815     my ( $c ) = @_;
 816     return $c->_comp_names(qw/Model M/);
 817 }
 818
 819
 820 =head2 $c->views
 821
 822 Returns the available names which can be passed to $c->view
 823
 824 =cut
 825
 826 sub views {
 827     my ( $c ) = @_;
 828     return $c->_comp_names(qw/View V/);
 829 }
 830
 831 =head2 $c->comp($name)
 832
 833 =head2 $c->component($name)
 834
 835 Gets a component object by name. This method is not recommended,
 836 unless you want to get a specific component by full
 837 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 838 should be used instead.
 839
 840 If C<$name> is a regexp, a list of components matched against the full
 841 component name will be returned.
 842
 843 If Catalyst can't find a component by name, it will fallback to regex
 844 matching by default. To disable this behaviour set
 845 disable_component_resolution_regex_fallback to a true value.
 846
 847     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 848
 849 =cut
 850
 851 sub component {
 852     my ( $c, $name, @args ) = @_;
 853
 854     if( $name ) {
 855         my $comps = $c->components;
 856
 857         if( !ref $name ) {
 858             # is it the exact name?
 859             return $c->_filter_component( $comps->{ $name }, @args )
 860                        if exists $comps->{ $name };
 861
 862             # perhaps we just omitted "MyApp"?
 863             my $composed = ( ref $c || $c ) . "::${name}";
 864             return $c->_filter_component( $comps->{ $composed }, @args )
 865                        if exists $comps->{ $composed };
 866
 867             # search all of the models, views and controllers
 868             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 869             return $c->_filter_component( $comp, @args ) if $comp;
 870         }
 871
 872         return
 873             if $c->config->{disable_component_resolution_regex_fallback};
 874
 875         # This is here so $c->comp( '::M::' ) works
 876         my $query = ref $name ? $name : qr{$name}i;
 877
 878         my @result = grep { m{$query} } keys %{ $c->components };
 879         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 880
 881         if( $result[ 0 ] ) {
 882             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 883             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 884             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 885             return $c->_filter_component( $result[ 0 ], @args );
 886         }
 887
 888         # I would expect to return an empty list here, but that breaks back-compat
 889     }
 890
 891     # fallback
 892     return sort keys %{ $c->components };
 893 }
 894
 895 =head2 CLASS DATA AND HELPER CLASSES
 896
 897 =head2 $c->config
 898
 899 Returns or takes a hashref containing the application's configuration.
 900
 901     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 902
 903 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 904 like C<myapp.conf> in your applications home directory. See
 905 L<Catalyst::Plugin::ConfigLoader>.
 906
 907 =head3 Cascading configuration
 908
 909 The config method is present on all Catalyst components, and configuration
 910 will be merged when an application is started. Configuration loaded with
 911 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 912 followed by configuration in your top level C<MyApp> class. These two
 913 configurations are merged, and then configuration data whose hash key matches a
 914 component name is merged with configuration for that component.
 915
 916 The configuration for a component is then passed to the C<new> method when a
 917 component is constructed.
 918
 919 For example:
 920
 921     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 922     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 923
 924 will mean that C<MyApp::Model::Foo> receives the following data when
 925 constructed:
 926
 927     MyApp::Model::Foo->new({
 928         bar => 'baz',
 929         quux => 'frob',
 930         overrides => 'me',
 931     });
 932
 933 It's common practice to use a Moose attribute
 934 on the receiving component to access the config value.
 935
 936     package MyApp::Model::Foo;
 937
 938     use Moose;
 939
 940     # this attr will receive 'baz' at construction time
 941     has 'bar' => (
 942         is  => 'rw',
 943         isa => 'Str',
 944     );
 945
 946 You can then get the value 'baz' by calling $c->model('Foo')->bar
 947 (or $self->bar inside code in the model).
 948
 949 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 950 as a way of reading config within your code, as this B<will not> give you the
 951 correctly merged config back. You B<MUST> take the config values supplied to
 952 the constructor and use those instead.
 953
 954 =cut
 955
 956 around config => sub {
 957     my $orig = shift;
 958     my $c = shift;
 959
 960     croak('Setting config after setup has been run is not allowed.')
 961         if ( @_ and $c->setup_finished );
 962
 963     $c->$orig(@_);
 964 };
 965
 966 =head2 $c->log
 967
 968 Returns the logging object instance. Unless it is already set, Catalyst
 969 sets this up with a L<Catalyst::Log> object. To use your own log class,
 970 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 971 C<< __PACKAGE__->setup >>.
 972
 973  __PACKAGE__->log( MyLogger->new );
 974  __PACKAGE__->setup;
 975
 976 And later:
 977
 978     $c->log->info( 'Now logging with my own logger!' );
 979
 980 Your log class should implement the methods described in
 981 L<Catalyst::Log>.
 982
 983
 984 =head2 $c->debug
 985
 986 Returns 1 if debug mode is enabled, 0 otherwise.
 987
 988 You can enable debug mode in several ways:
 989
 990 =over
 991
 992 =item By calling myapp_server.pl with the -d flag
 993
 994 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 995
 996 =item The -Debug option in your MyApp.pm
 997
 998 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 999
1000 =back
1001
1002 The first three also set the log level to 'debug'.
1003
1004 Calling C<< $c->debug(1) >> has no effect.
1005
1006 =cut
1007
1008 sub debug { 0 }
1009
1010 =head2 $c->dispatcher
1011
1012 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1013
1014 =head2 $c->engine
1015
1016 Returns the engine instance. See L<Catalyst::Engine>.
1017
1018
1019 =head2 UTILITY METHODS
1020
1021 =head2 $c->path_to(@path)
1022
1023 Merges C<@path> with C<< $c->config->{home} >> and returns a
1024 L<Path::Class::Dir> object. Note you can usually use this object as
1025 a filename, but sometimes you will have to explicitly stringify it
1026 yourself by calling the C<< ->stringify >> method.
1027
1028 For example:
1029
1030     $c->path_to( 'db', 'sqlite.db' );
1031
1032 =cut
1033
1034 sub path_to {
1035     my ( $c, @path ) = @_;
1036     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1037     if ( -d $path ) { return $path }
1038     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1039 }
1040
1041 sub plugin {
1042     my ( $class, $name, $plugin, @args ) = @_;
1043
1044     # See block comment in t/unit_core_plugin.t
1045     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1046
1047     $class->_register_plugin( $plugin, 1 );
1048
1049     eval { $plugin->import };
1050     $class->mk_classdata($name);
1051     my $obj;
1052     eval { $obj = $plugin->new(@args) };
1053
1054     if ($@) {
1055         Catalyst::Exception->throw( message =>
1056               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1057     }
1058
1059     $class->$name($obj);
1060     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1061       if $class->debug;
1062 }
1063
1064 =head2 MyApp->setup
1065
1066 Initializes the dispatcher and engine, loads any plugins, and loads the
1067 model, view, and controller components. You may also specify an array
1068 of plugins to load here, if you choose to not load them in the C<use
1069 Catalyst> line.
1070
1071     MyApp->setup;
1072     MyApp->setup( qw/-Debug/ );
1073
1074 B<Note:> You B<should not> wrap this method with method modifiers
1075 or bad things will happen - wrap the C<setup_finalize> method instead.
1076
1077 =cut
1078
1079 sub setup {
1080     my ( $class, @arguments ) = @_;
1081     croak('Running setup more than once')
1082         if ( $class->setup_finished );
1083
1084     unless ( $class->isa('Catalyst') ) {
1085
1086         Catalyst::Exception->throw(
1087             message => qq/'$class' does not inherit from Catalyst/ );
1088     }
1089
1090     if ( $class->arguments ) {
1091         @arguments = ( @arguments, @{ $class->arguments } );
1092     }
1093
1094     # Process options
1095     my $flags = {};
1096
1097     foreach (@arguments) {
1098
1099         if (/^-Debug$/) {
1100             $flags->{log} =
1101               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1102         }
1103         elsif (/^-(\w+)=?(.*)$/) {
1104             $flags->{ lc $1 } = $2;
1105         }
1106         else {
1107             push @{ $flags->{plugins} }, $_;
1108         }
1109     }
1110
1111     $class->setup_home( delete $flags->{home} );
1112
1113     $class->setup_log( delete $flags->{log} );
1114     $class->setup_plugins( delete $flags->{plugins} );
1115     $class->setup_middleware();
1116     $class->setup_data_handlers();
1117     $class->setup_dispatcher( delete $flags->{dispatcher} );
1118     if (my $engine = delete $flags->{engine}) {
1119         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1120     }
1121     $class->setup_engine();
1122     $class->setup_stats( delete $flags->{stats} );
1123
1124     for my $flag ( sort keys %{$flags} ) {
1125
1126         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1127             &$code( $class, delete $flags->{$flag} );
1128         }
1129         else {
1130             $class->log->warn(qq/Unknown flag "$flag"/);
1131         }
1132     }
1133
1134     eval { require Catalyst::Devel; };
1135     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1136         $class->log->warn(<<"EOF");
1137 You are running an old script!
1138
1139   Please update by running (this will overwrite existing files):
1140     catalyst.pl -force -scripts $class
1141
1142   or (this will not overwrite existing files):
1143     catalyst.pl -scripts $class
1144
1145 EOF
1146     }
1147
1148     if ( $class->debug ) {
1149         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1150
1151         if (@plugins) {
1152             my $column_width = Catalyst::Utils::term_width() - 6;
1153             my $t = Text::SimpleTable->new($column_width);
1154             $t->row($_) for @plugins;
1155             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1156         }
1157
1158         my @middleware = map {
1159           ref $_ eq 'CODE' ?
1160             "Inline Coderef" :
1161               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1162                 || '')  } $class->registered_middlewares;
1163
1164         if (@middleware) {
1165             my $column_width = Catalyst::Utils::term_width() - 6;
1166             my $t = Text::SimpleTable->new($column_width);
1167             $t->row($_) for @middleware;
1168             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1169         }
1170
1171         my %dh = $class->registered_data_handlers;
1172         if (my @data_handlers = keys %dh) {
1173             my $column_width = Catalyst::Utils::term_width() - 6;
1174             my $t = Text::SimpleTable->new($column_width);
1175             $t->row($_) for @data_handlers;
1176             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1177         }
1178
1179         my $dispatcher = $class->dispatcher;
1180         my $engine     = $class->engine;
1181         my $home       = $class->config->{home};
1182
1183         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1184         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1185
1186         $home
1187           ? ( -d $home )
1188           ? $class->log->debug(qq/Found home "$home"/)
1189           : $class->log->debug(qq/Home "$home" doesn't exist/)
1190           : $class->log->debug(q/Couldn't find home/);
1191     }
1192
1193     # Call plugins setup, this is stupid and evil.
1194     # Also screws C3 badly on 5.10, hack to avoid.
1195     {
1196         no warnings qw/redefine/;
1197         local *setup = sub { };
1198         $class->setup unless $Catalyst::__AM_RESTARTING;
1199     }
1200
1201     # Initialize our data structure
1202     $class->components( {} );
1203
1204     $class->setup_components;
1205
1206     if ( $class->debug ) {
1207         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1208         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1209         for my $comp ( sort keys %{ $class->components } ) {
1210             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1211             $t->row( $comp, $type );
1212         }
1213         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1214           if ( keys %{ $class->components } );
1215     }
1216
1217     # Add our self to components, since we are also a component
1218     if( $class->isa('Catalyst::Controller') ){
1219       $class->components->{$class} = $class;
1220     }
1221
1222     $class->setup_actions;
1223
1224     if ( $class->debug ) {
1225         my $name = $class->config->{name} || 'Application';
1226         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1227     }
1228
1229     if ($class->config->{case_sensitive}) {
1230         $class->log->warn($class . "->config->{case_sensitive} is set.");
1231         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1232     }
1233
1234     $class->setup_finalize;
1235     # Should be the last thing we do so that user things hooking
1236     # setup_finalize can log..
1237     $class->log->_flush() if $class->log->can('_flush');
1238     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1239 }
1240
1241 =head2 $app->setup_finalize
1242
1243 A hook to attach modifiers to. This method does not do anything except set the
1244 C<setup_finished> accessor.
1245
1246 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1247
1248 Example:
1249
1250     after setup_finalize => sub {
1251         my $app = shift;
1252
1253         ## do stuff here..
1254     };
1255
1256 =cut
1257
1258 sub setup_finalize {
1259     my ($class) = @_;
1260     $class->setup_finished(1);
1261 }
1262
1263 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1264
1265 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1266
1267 Constructs an absolute L<URI> object based on the application root, the
1268 provided path, and the additional arguments and query parameters provided.
1269 When used as a string, provides a textual URI.  If you need more flexibility
1270 than this (i.e. the option to provide relative URIs etc.) see
1271 L<Catalyst::Plugin::SmartURI>.
1272
1273 If no arguments are provided, the URI for the current action is returned.
1274 To return the current action and also provide @args, use
1275 C<< $c->uri_for( $c->action, @args ) >>.
1276
1277 If the first argument is a string, it is taken as a public URI path relative
1278 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1279 relative to the application root (if it does). It is then merged with
1280 C<< $c->request->base >>; any C<@args> are appended as additional path
1281 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1282
1283 If the first argument is a L<Catalyst::Action> it represents an action which
1284 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1285 optional C<\@captures> argument (an arrayref) allows passing the captured
1286 variables that are needed to fill in the paths of Chained and Regex actions;
1287 once the path is resolved, C<uri_for> continues as though a path was
1288 provided, appending any arguments or parameters and creating an absolute
1289 URI.
1290
1291 The captures for the current request can be found in
1292 C<< $c->request->captures >>, and actions can be resolved using
1293 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1294 path, use C<< $c->uri_for_action >> instead.
1295
1296   # Equivalent to $c->req->uri
1297   $c->uri_for($c->action, $c->req->captures,
1298       @{ $c->req->args }, $c->req->params);
1299
1300   # For the Foo action in the Bar controller
1301   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1302
1303   # Path to a static resource
1304   $c->uri_for('/static/images/logo.png');
1305
1306 =cut
1307
1308 sub uri_for {
1309     my ( $c, $path, @args ) = @_;
1310
1311     if ( $path->$_isa('Catalyst::Controller') ) {
1312         $path = $path->path_prefix;
1313         $path =~ s{/+\z}{};
1314         $path .= '/';
1315     }
1316
1317     undef($path) if (defined $path && $path eq '');
1318
1319     my $params =
1320       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1321
1322     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1323     foreach my $arg (@args) {
1324         utf8::encode($arg) if utf8::is_utf8($arg);
1325         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1326     }
1327
1328     if ( $path->$_isa('Catalyst::Action') ) { # action object
1329         s|/|%2F|g for @args;
1330         my $captures = [ map { s|/|%2F|g; $_; }
1331                         ( scalar @args && ref $args[0] eq 'ARRAY'
1332                          ? @{ shift(@args) }
1333                          : ()) ];
1334
1335         foreach my $capture (@$captures) {
1336             utf8::encode($capture) if utf8::is_utf8($capture);
1337             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1338         }
1339
1340         my $action = $path;
1341         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1342         if( !@args && $action->number_of_args ) {
1343             my $expanded_action = $c->dispatcher->expand_action( $action );
1344
1345             my $num_captures = $expanded_action->number_of_captures;
1346             unshift @args, splice @$captures, $num_captures;
1347         }
1348
1349        $path = $c->dispatcher->uri_for_action($action, $captures);
1350         if (not defined $path) {
1351             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1352                 if $c->debug;
1353             return undef;
1354         }
1355         $path = '/' if $path eq '';
1356     }
1357
1358     unshift(@args, $path);
1359
1360     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1361         my $namespace = $c->namespace;
1362         if (defined $path) { # cheesy hack to handle path '../foo'
1363            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1364         }
1365         unshift(@args, $namespace || '');
1366     }
1367
1368     # join args with '/', or a blank string
1369     my $args = join('/', grep { defined($_) } @args);
1370     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1371     $args =~ s!^/+!!;
1372
1373     my ($base, $class) = ('/', 'URI::_generic');
1374     if(blessed($c)) {
1375       $base = $c->req->base;
1376       $class = ref($base);
1377       $base =~ s{(?<!/)$}{/};
1378     }
1379
1380     my $query = '';
1381
1382     if (my @keys = keys %$params) {
1383       # somewhat lifted from URI::_query's query_form
1384       $query = '?'.join('&', map {
1385           my $val = $params->{$_};
1386           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1387           s/ /+/g;
1388           my $key = $_;
1389           $val = '' unless defined $val;
1390           (map {
1391               my $param = "$_";
1392               utf8::encode( $param ) if utf8::is_utf8($param);
1393               # using the URI::Escape pattern here so utf8 chars survive
1394               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1395               $param =~ s/ /+/g;
1396               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1397       } @keys);
1398     }
1399
1400     my $res = bless(\"${base}${args}${query}", $class);
1401     $res;
1402 }
1403
1404 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1405
1406 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1407
1408 =over
1409
1410 =item $path
1411
1412 A private path to the Catalyst action you want to create a URI for.
1413
1414 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1415 >> and passing the resulting C<$action> and the remaining arguments to C<<
1416 $c->uri_for >>.
1417
1418 You can also pass in a Catalyst::Action object, in which case it is passed to
1419 C<< $c->uri_for >>.
1420
1421 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1422
1423 For example, if the action looks like:
1424
1425  package MyApp::Controller::Users;
1426
1427  sub lst : Path('the-list') {}
1428
1429 You can use:
1430
1431  $c->uri_for_action('/users/lst')
1432
1433 and it will create the URI /users/the-list.
1434
1435 =item \@captures_and_args?
1436
1437 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1438 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1439 to interpolate all the parameters in the URI.
1440
1441 =item @args?
1442
1443 Optional list of extra arguments - can be supplied in the
1444 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1445 code.
1446
1447 Your action can have zero, a fixed or a variable number of args (e.g.
1448 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1449
1450 =item \%query_values?
1451
1452 Optional array reference of query parameters to append. E.g.
1453
1454   { foo => 'bar' }
1455
1456 will generate
1457
1458   /rest/of/your/uri?foo=bar
1459
1460 =back
1461
1462 =cut
1463
1464 sub uri_for_action {
1465     my ( $c, $path, @args ) = @_;
1466     my $action = blessed($path)
1467       ? $path
1468       : $c->dispatcher->get_action_by_path($path);
1469     unless (defined $action) {
1470       croak "Can't find action for path '$path'";
1471     }
1472     return $c->uri_for( $action, @args );
1473 }
1474
1475 =head2 $c->welcome_message
1476
1477 Returns the Catalyst welcome HTML page.
1478
1479 =cut
1480
1481 sub welcome_message {
1482     my $c      = shift;
1483     my $name   = $c->config->{name};
1484     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1485     my $prefix = Catalyst::Utils::appprefix( ref $c );
1486     $c->response->content_type('text/html; charset=utf-8');
1487     return <<"EOF";
1488 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1489     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1490 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1491     <head>
1492     <meta http-equiv="Content-Language" content="en" />
1493     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1494         <title>$name on Catalyst $VERSION</title>
1495         <style type="text/css">
1496             body {
1497                 color: #000;
1498                 background-color: #eee;
1499             }
1500             div#content {
1501                 width: 640px;
1502                 margin-left: auto;
1503                 margin-right: auto;
1504                 margin-top: 10px;
1505                 margin-bottom: 10px;
1506                 text-align: left;
1507                 background-color: #ccc;
1508                 border: 1px solid #aaa;
1509             }
1510             p, h1, h2 {
1511                 margin-left: 20px;
1512                 margin-right: 20px;
1513                 font-family: verdana, tahoma, sans-serif;
1514             }
1515             a {
1516                 font-family: verdana, tahoma, sans-serif;
1517             }
1518             :link, :visited {
1519                     text-decoration: none;
1520                     color: #b00;
1521                     border-bottom: 1px dotted #bbb;
1522             }
1523             :link:hover, :visited:hover {
1524                     color: #555;
1525             }
1526             div#topbar {
1527                 margin: 0px;
1528             }
1529             pre {
1530                 margin: 10px;
1531                 padding: 8px;
1532             }
1533             div#answers {
1534                 padding: 8px;
1535                 margin: 10px;
1536                 background-color: #fff;
1537                 border: 1px solid #aaa;
1538             }
1539             h1 {
1540                 font-size: 0.9em;
1541                 font-weight: normal;
1542                 text-align: center;
1543             }
1544             h2 {
1545                 font-size: 1.0em;
1546             }
1547             p {
1548                 font-size: 0.9em;
1549             }
1550             p img {
1551                 float: right;
1552                 margin-left: 10px;
1553             }
1554             span#appname {
1555                 font-weight: bold;
1556                 font-size: 1.6em;
1557             }
1558         </style>
1559     </head>
1560     <body>
1561         <div id="content">
1562             <div id="topbar">
1563                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1564                     $VERSION</h1>
1565              </div>
1566              <div id="answers">
1567                  <p>
1568                  <img src="$logo" alt="Catalyst Logo" />
1569                  </p>
1570                  <p>Welcome to the  world of Catalyst.
1571                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1572                     framework will make web development something you had
1573                     never expected it to be: Fun, rewarding, and quick.</p>
1574                  <h2>What to do now?</h2>
1575                  <p>That really depends  on what <b>you</b> want to do.
1576                     We do, however, provide you with a few starting points.</p>
1577                  <p>If you want to jump right into web development with Catalyst
1578                     you might want to start with a tutorial.</p>
1579 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1580 </pre>
1581 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1582 <pre>
1583 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1584 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1585 </code></pre>
1586                  <h2>What to do next?</h2>
1587                  <p>Next it's time to write an actual application. Use the
1588                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1589                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1590                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1591                     they can save you a lot of work.</p>
1592                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1593                     <p>Also, be sure to check out the vast and growing
1594                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1595                     you are likely to find what you need there.
1596                     </p>
1597
1598                  <h2>Need help?</h2>
1599                  <p>Catalyst has a very active community. Here are the main places to
1600                     get in touch with us.</p>
1601                  <ul>
1602                      <li>
1603                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1604                      </li>
1605                      <li>
1606                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1607                      </li>
1608                      <li>
1609                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1610                      </li>
1611                  </ul>
1612                  <h2>In conclusion</h2>
1613                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1614                     as we enjoyed making it. Please contact us if you have ideas
1615                     for improvement or other feedback.</p>
1616              </div>
1617          </div>
1618     </body>
1619 </html>
1620 EOF
1621 }
1622
1623 =head2 run_options
1624
1625 Contains a hash of options passed from the application script, including
1626 the original ARGV the script received, the processed values from that
1627 ARGV and any extra arguments to the script which were not processed.
1628
1629 This can be used to add custom options to your application's scripts
1630 and setup your application differently depending on the values of these
1631 options.
1632
1633 =head1 INTERNAL METHODS
1634
1635 These methods are not meant to be used by end users.
1636
1637 =head2 $c->components
1638
1639 Returns a hash of components.
1640
1641 =head2 $c->context_class
1642
1643 Returns or sets the context class.
1644
1645 =head2 $c->counter
1646
1647 Returns a hashref containing coderefs and execution counts (needed for
1648 deep recursion detection).
1649
1650 =head2 $c->depth
1651
1652 Returns the number of actions on the current internal execution stack.
1653
1654 =head2 $c->dispatch
1655
1656 Dispatches a request to actions.
1657
1658 =cut
1659
1660 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1661
1662 =head2 $c->dispatcher_class
1663
1664 Returns or sets the dispatcher class.
1665
1666 =head2 $c->dump_these
1667
1668 Returns a list of 2-element array references (name, structure) pairs
1669 that will be dumped on the error page in debug mode.
1670
1671 =cut
1672
1673 sub dump_these {
1674     my $c = shift;
1675     [ Request => $c->req ],
1676     [ Response => $c->res ],
1677     [ Stash => $c->stash ],
1678     [ Config => $c->config ];
1679 }
1680
1681 =head2 $c->engine_class
1682
1683 Returns or sets the engine class.
1684
1685 =head2 $c->execute( $class, $coderef )
1686
1687 Execute a coderef in given class and catch exceptions. Errors are available
1688 via $c->error.
1689
1690 =cut
1691
1692 sub execute {
1693     my ( $c, $class, $code ) = @_;
1694     $class = $c->component($class) || $class;
1695     $c->state(0);
1696
1697     if ( $c->depth >= $RECURSION ) {
1698         my $action = $code->reverse();
1699         $action = "/$action" unless $action =~ /->/;
1700         my $error = qq/Deep recursion detected calling "${action}"/;
1701         $c->log->error($error);
1702         $c->error($error);
1703         $c->state(0);
1704         return $c->state;
1705     }
1706
1707     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1708
1709     push( @{ $c->stack }, $code );
1710
1711     no warnings 'recursion';
1712     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1713     #      I have no idea how, ergo $ret (which appears to fix the issue)
1714     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1715
1716     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1717
1718     my $last = pop( @{ $c->stack } );
1719
1720     if ( my $error = $@ ) {
1721         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1722             $error->rethrow if $c->depth > 1;
1723         }
1724         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1725             $error->rethrow if $c->depth > 0;
1726         }
1727         else {
1728             unless ( ref $error ) {
1729                 no warnings 'uninitialized';
1730                 chomp $error;
1731                 my $class = $last->class;
1732                 my $name  = $last->name;
1733                 $error = qq/Caught exception in $class->$name "$error"/;
1734             }
1735             $c->error($error);
1736         }
1737         $c->state(0);
1738     }
1739     return $c->state;
1740 }
1741
1742 sub _stats_start_execute {
1743     my ( $c, $code ) = @_;
1744     my $appclass = ref($c) || $c;
1745     return if ( ( $code->name =~ /^_.*/ )
1746         && ( !$appclass->config->{show_internal_actions} ) );
1747
1748     my $action_name = $code->reverse();
1749     $c->counter->{$action_name}++;
1750
1751     my $action = $action_name;
1752     $action = "/$action" unless $action =~ /->/;
1753
1754     # determine if the call was the result of a forward
1755     # this is done by walking up the call stack and looking for a calling
1756     # sub of Catalyst::forward before the eval
1757     my $callsub = q{};
1758     for my $index ( 2 .. 11 ) {
1759         last
1760         if ( ( caller($index) )[0] eq 'Catalyst'
1761             && ( caller($index) )[3] eq '(eval)' );
1762
1763         if ( ( caller($index) )[3] =~ /forward$/ ) {
1764             $callsub = ( caller($index) )[3];
1765             $action  = "-> $action";
1766             last;
1767         }
1768     }
1769
1770     my $uid = $action_name . $c->counter->{$action_name};
1771
1772     # is this a root-level call or a forwarded call?
1773     if ( $callsub =~ /forward$/ ) {
1774         my $parent = $c->stack->[-1];
1775
1776         # forward, locate the caller
1777         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1778             $c->stats->profile(
1779                 begin  => $action,
1780                 parent => "$parent" . $c->counter->{"$parent"},
1781                 uid    => $uid,
1782             );
1783         }
1784         else {
1785
1786             # forward with no caller may come from a plugin
1787             $c->stats->profile(
1788                 begin => $action,
1789                 uid   => $uid,
1790             );
1791         }
1792     }
1793     else {
1794
1795         # root-level call
1796         $c->stats->profile(
1797             begin => $action,
1798             uid   => $uid,
1799         );
1800     }
1801     return $action;
1802
1803 }
1804
1805 sub _stats_finish_execute {
1806     my ( $c, $info ) = @_;
1807     $c->stats->profile( end => $info );
1808 }
1809
1810 =head2 $c->finalize
1811
1812 Finalizes the request.
1813
1814 =cut
1815
1816 sub finalize {
1817     my $c = shift;
1818
1819     for my $error ( @{ $c->error } ) {
1820         $c->log->error($error);
1821     }
1822
1823     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1824     # stuff like cometd and websockets
1825
1826     if($c->request->has_io_fh) {
1827       $c->log_response;
1828       return;
1829     }
1830
1831     # Allow engine to handle finalize flow (for POE)
1832     my $engine = $c->engine;
1833     if ( my $code = $engine->can('finalize') ) {
1834         $engine->$code($c);
1835     }
1836     else {
1837
1838         $c->finalize_uploads;
1839
1840         # Error
1841         if ( $#{ $c->error } >= 0 ) {
1842             $c->finalize_error;
1843         }
1844
1845         $c->finalize_headers unless $c->response->finalized_headers;
1846
1847         # HEAD request
1848         if ( $c->request->method eq 'HEAD' ) {
1849             $c->response->body('');
1850         }
1851
1852         $c->finalize_body;
1853     }
1854
1855     $c->log_response;
1856
1857     if ($c->use_stats) {
1858         my $elapsed = $c->stats->elapsed;
1859         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1860         $c->log->info(
1861             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1862     }
1863
1864     return $c->response->status;
1865 }
1866
1867 =head2 $c->finalize_body
1868
1869 Finalizes body.
1870
1871 =cut
1872
1873 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1874
1875 =head2 $c->finalize_cookies
1876
1877 Finalizes cookies.
1878
1879 =cut
1880
1881 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1882
1883 =head2 $c->finalize_error
1884
1885 Finalizes error.
1886
1887 =cut
1888
1889 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1890
1891 =head2 $c->finalize_headers
1892
1893 Finalizes headers.
1894
1895 =cut
1896
1897 sub finalize_headers {
1898     my $c = shift;
1899
1900     my $response = $c->response; #accessor calls can add up?
1901
1902     # Check if we already finalized headers
1903     return if $response->finalized_headers;
1904
1905     # Handle redirects
1906     if ( my $location = $response->redirect ) {
1907         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1908         $response->header( Location => $location );
1909
1910         if ( !$response->has_body ) {
1911             # Add a default body if none is already present
1912             my $encoded_location = encode_entities($location);
1913             $response->body(<<"EOF");
1914 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1915 <html xmlns="http://www.w3.org/1999/xhtml">
1916   <head>
1917     <title>Moved</title>
1918   </head>
1919   <body>
1920      <p>This item has moved <a href="$encoded_location">here</a>.</p>
1921   </body>
1922 </html>
1923 EOF
1924             $response->content_type('text/html; charset=utf-8');
1925         }
1926     }
1927
1928     # Content-Length
1929     if ( defined $response->body && length $response->body && !$response->content_length ) {
1930
1931         # get the length from a filehandle
1932         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1933         {
1934             my $size = -s $response->body;
1935             if ( $size ) {
1936                 $response->content_length( $size );
1937             }
1938             else {
1939                 $c->log->warn('Serving filehandle without a content-length');
1940             }
1941         }
1942         else {
1943             # everything should be bytes at this point, but just in case
1944             $response->content_length( length( $response->body ) );
1945         }
1946     }
1947
1948     # Errors
1949     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1950         $response->headers->remove_header("Content-Length");
1951         $response->body('');
1952     }
1953
1954     $c->finalize_cookies;
1955
1956     $c->response->finalize_headers();
1957
1958     # Done
1959     $response->finalized_headers(1);
1960 }
1961
1962 =head2 $c->finalize_output
1963
1964 An alias for finalize_body.
1965
1966 =head2 $c->finalize_read
1967
1968 Finalizes the input after reading is complete.
1969
1970 =cut
1971
1972 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1973
1974 =head2 $c->finalize_uploads
1975
1976 Finalizes uploads. Cleans up any temporary files.
1977
1978 =cut
1979
1980 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1981
1982 =head2 $c->get_action( $action, $namespace )
1983
1984 Gets an action in a given namespace.
1985
1986 =cut
1987
1988 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1989
1990 =head2 $c->get_actions( $action, $namespace )
1991
1992 Gets all actions of a given name in a namespace and all parent
1993 namespaces.
1994
1995 =cut
1996
1997 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1998
1999 =head2 $app->handle_request( @arguments )
2000
2001 Called to handle each HTTP request.
2002
2003 =cut
2004
2005 sub handle_request {
2006     my ( $class, @arguments ) = @_;
2007
2008     # Always expect worst case!
2009     my $status = -1;
2010     try {
2011         if ($class->debug) {
2012             my $secs = time - $START || 1;
2013             my $av = sprintf '%.3f', $COUNT / $secs;
2014             my $time = localtime time;
2015             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2016         }
2017
2018         my $c = $class->prepare(@arguments);
2019         $c->dispatch;
2020         $status = $c->finalize;
2021     }
2022     catch {
2023         chomp(my $error = $_);
2024         $class->log->error(qq/Caught exception in engine "$error"/);
2025     };
2026
2027     $COUNT++;
2028
2029     if(my $coderef = $class->log->can('_flush')){
2030         $class->log->$coderef();
2031     }
2032     return $status;
2033 }
2034
2035 =head2 $class->prepare( @arguments )
2036
2037 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2038 etc.).
2039
2040 =cut
2041
2042 has _uploadtmp => (
2043     is => 'ro',
2044     predicate => '_has_uploadtmp',
2045 );
2046
2047 sub prepare {
2048     my ( $class, @arguments ) = @_;
2049
2050     # XXX
2051     # After the app/ctxt split, this should become an attribute based on something passed
2052     # into the application.
2053     $class->context_class( ref $class || $class ) unless $class->context_class;
2054
2055     my $uploadtmp = $class->config->{uploadtmp};
2056     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2057
2058     $c->response->_context($c);
2059
2060     #surely this is not the most efficient way to do things...
2061     $c->stats($class->stats_class->new)->enable($c->use_stats);
2062     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2063         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2064     }
2065
2066     try {
2067         # Allow engine to direct the prepare flow (for POE)
2068         if ( my $prepare = $c->engine->can('prepare') ) {
2069             $c->engine->$prepare( $c, @arguments );
2070         }
2071         else {
2072             $c->prepare_request(@arguments);
2073             $c->prepare_connection;
2074             $c->prepare_query_parameters;
2075             $c->prepare_headers; # Just hooks, no longer needed - they just
2076             $c->prepare_cookies; # cause the lazy attribute on req to build
2077             $c->prepare_path;
2078
2079             # Prepare the body for reading, either by prepare_body
2080             # or the user, if they are using $c->read
2081             $c->prepare_read;
2082
2083             # Parse the body unless the user wants it on-demand
2084             unless ( ref($c)->config->{parse_on_demand} ) {
2085                 $c->prepare_body;
2086             }
2087         }
2088         $c->prepare_action;
2089     }
2090     # VERY ugly and probably shouldn't rely on ->finalize actually working
2091     catch {
2092         # failed prepare is always due to an invalid request, right?
2093         $c->response->status(400);
2094         $c->response->content_type('text/plain');
2095         $c->response->body('Bad Request');
2096         # Note we call finalize and then die here, which escapes
2097         # finalize being called in the enclosing block..
2098         # It in fact couldn't be called, as we don't return $c..
2099         # This is a mess - but I'm unsure you can fix this without
2100         # breaking compat for people doing crazy things (we should set
2101         # the 400 and just return the ctx here IMO, letting finalize get called
2102         # above...
2103         $c->finalize;
2104         die $_;
2105     };
2106
2107     $c->log_request;
2108
2109     return $c;
2110 }
2111
2112 =head2 $c->prepare_action
2113
2114 Prepares action. See L<Catalyst::Dispatcher>.
2115
2116 =cut
2117
2118 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2119
2120 =head2 $c->prepare_body
2121
2122 Prepares message body.
2123
2124 =cut
2125
2126 sub prepare_body {
2127     my $c = shift;
2128
2129     return if $c->request->_has_body;
2130
2131     # Initialize on-demand data
2132     $c->engine->prepare_body( $c, @_ );
2133     $c->prepare_parameters;
2134     $c->prepare_uploads;
2135 }
2136
2137 =head2 $c->prepare_body_chunk( $chunk )
2138
2139 Prepares a chunk of data before sending it to L<HTTP::Body>.
2140
2141 See L<Catalyst::Engine>.
2142
2143 =cut
2144
2145 sub prepare_body_chunk {
2146     my $c = shift;
2147     $c->engine->prepare_body_chunk( $c, @_ );
2148 }
2149
2150 =head2 $c->prepare_body_parameters
2151
2152 Prepares body parameters.
2153
2154 =cut
2155
2156 sub prepare_body_parameters {
2157     my $c = shift;
2158     $c->engine->prepare_body_parameters( $c, @_ );
2159 }
2160
2161 =head2 $c->prepare_connection
2162
2163 Prepares connection.
2164
2165 =cut
2166
2167 sub prepare_connection {
2168     my $c = shift;
2169     # XXX - This is called on the engine (not the request) to maintain
2170     #       Engine::PSGI back compat.
2171     $c->engine->prepare_connection($c);
2172 }
2173
2174 =head2 $c->prepare_cookies
2175
2176 Prepares cookies by ensuring that the attribute on the request
2177 object has been built.
2178
2179 =cut
2180
2181 sub prepare_cookies { my $c = shift; $c->request->cookies }
2182
2183 =head2 $c->prepare_headers
2184
2185 Prepares request headers by ensuring that the attribute on the request
2186 object has been built.
2187
2188 =cut
2189
2190 sub prepare_headers { my $c = shift; $c->request->headers }
2191
2192 =head2 $c->prepare_parameters
2193
2194 Prepares parameters.
2195
2196 =cut
2197
2198 sub prepare_parameters {
2199     my $c = shift;
2200     $c->prepare_body_parameters;
2201     $c->engine->prepare_parameters( $c, @_ );
2202 }
2203
2204 =head2 $c->prepare_path
2205
2206 Prepares path and base.
2207
2208 =cut
2209
2210 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2211
2212 =head2 $c->prepare_query_parameters
2213
2214 Prepares query parameters.
2215
2216 =cut
2217
2218 sub prepare_query_parameters {
2219     my $c = shift;
2220
2221     $c->engine->prepare_query_parameters( $c, @_ );
2222 }
2223
2224 =head2 $c->log_request
2225
2226 Writes information about the request to the debug logs.  This includes:
2227
2228 =over 4
2229
2230 =item * Request method, path, and remote IP address
2231
2232 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2233
2234 =item * Request parameters
2235
2236 =item * File uploads
2237
2238 =back
2239
2240 =cut
2241
2242 sub log_request {
2243     my $c = shift;
2244
2245     return unless $c->debug;
2246
2247     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2248     my $request = $dump->[1];
2249
2250     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2251     $method ||= '';
2252     $path = '/' unless length $path;
2253     $address ||= '';
2254     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2255
2256     $c->log_request_headers($request->headers);
2257
2258     if ( my $keywords = $request->query_keywords ) {
2259         $c->log->debug("Query keywords are: $keywords");
2260     }
2261
2262     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2263
2264     $c->log_request_uploads($request);
2265 }
2266
2267 =head2 $c->log_response
2268
2269 Writes information about the response to the debug logs by calling
2270 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2271
2272 =cut
2273
2274 sub log_response {
2275     my $c = shift;
2276
2277     return unless $c->debug;
2278
2279     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2280     my $response = $dump->[1];
2281
2282     $c->log_response_status_line($response);
2283     $c->log_response_headers($response->headers);
2284 }
2285
2286 =head2 $c->log_response_status_line($response)
2287
2288 Writes one line of information about the response to the debug logs.  This includes:
2289
2290 =over 4
2291
2292 =item * Response status code
2293
2294 =item * Content-Type header (if present)
2295
2296 =item * Content-Length header (if present)
2297
2298 =back
2299
2300 =cut
2301
2302 sub log_response_status_line {
2303     my ($c, $response) = @_;
2304
2305     $c->log->debug(
2306         sprintf(
2307             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2308             $response->status                            || 'unknown',
2309             $response->headers->header('Content-Type')   || 'unknown',
2310             $response->headers->header('Content-Length') || 'unknown'
2311         )
2312     );
2313 }
2314
2315 =head2 $c->log_response_headers($headers);
2316
2317 Hook method which can be wrapped by plugins to log the response headers.
2318 No-op in the default implementation.
2319
2320 =cut
2321
2322 sub log_response_headers {}
2323
2324 =head2 $c->log_request_parameters( query => {}, body => {} )
2325
2326 Logs request parameters to debug logs
2327
2328 =cut
2329
2330 sub log_request_parameters {
2331     my $c          = shift;
2332     my %all_params = @_;
2333
2334     return unless $c->debug;
2335
2336     my $column_width = Catalyst::Utils::term_width() - 44;
2337     foreach my $type (qw(query body)) {
2338         my $params = $all_params{$type};
2339         next if ! keys %$params;
2340         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2341         for my $key ( sort keys %$params ) {
2342             my $param = $params->{$key};
2343             my $value = defined($param) ? $param : '';
2344             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2345         }
2346         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2347     }
2348 }
2349
2350 =head2 $c->log_request_uploads
2351
2352 Logs file uploads included in the request to the debug logs.
2353 The parameter name, filename, file type, and file size are all included in
2354 the debug logs.
2355
2356 =cut
2357
2358 sub log_request_uploads {
2359     my $c = shift;
2360     my $request = shift;
2361     return unless $c->debug;
2362     my $uploads = $request->uploads;
2363     if ( keys %$uploads ) {
2364         my $t = Text::SimpleTable->new(
2365             [ 12, 'Parameter' ],
2366             [ 26, 'Filename' ],
2367             [ 18, 'Type' ],
2368             [ 9,  'Size' ]
2369         );
2370         for my $key ( sort keys %$uploads ) {
2371             my $upload = $uploads->{$key};
2372             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2373                 $t->row( $key, $u->filename, $u->type, $u->size );
2374             }
2375         }
2376         $c->log->debug( "File Uploads are:\n" . $t->draw );
2377     }
2378 }
2379
2380 =head2 $c->log_request_headers($headers);
2381
2382 Hook method which can be wrapped by plugins to log the request headers.
2383 No-op in the default implementation.
2384
2385 =cut
2386
2387 sub log_request_headers {}
2388
2389 =head2 $c->log_headers($type => $headers)
2390
2391 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2392
2393 =cut
2394
2395 sub log_headers {
2396     my $c       = shift;
2397     my $type    = shift;
2398     my $headers = shift;    # an HTTP::Headers instance
2399
2400     return unless $c->debug;
2401
2402     my $column_width = Catalyst::Utils::term_width() - 28;
2403     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2404     $headers->scan(
2405         sub {
2406             my ( $name, $value ) = @_;
2407             $t->row( $name, $value );
2408         }
2409     );
2410     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2411 }
2412
2413
2414 =head2 $c->prepare_read
2415
2416 Prepares the input for reading.
2417
2418 =cut
2419
2420 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2421
2422 =head2 $c->prepare_request
2423
2424 Prepares the engine request.
2425
2426 =cut
2427
2428 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2429
2430 =head2 $c->prepare_uploads
2431
2432 Prepares uploads.
2433
2434 =cut
2435
2436 sub prepare_uploads {
2437     my $c = shift;
2438
2439     $c->engine->prepare_uploads( $c, @_ );
2440 }
2441
2442 =head2 $c->prepare_write
2443
2444 Prepares the output for writing.
2445
2446 =cut
2447
2448 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2449
2450 =head2 $c->request_class
2451
2452 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2453
2454 =head2 $c->response_class
2455
2456 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2457
2458 =head2 $c->read( [$maxlength] )
2459
2460 Reads a chunk of data from the request body. This method is designed to
2461 be used in a while loop, reading C<$maxlength> bytes on every call.
2462 C<$maxlength> defaults to the size of the request if not specified.
2463
2464 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2465 directly.
2466
2467 Warning: If you use read(), Catalyst will not process the body,
2468 so you will not be able to access POST parameters or file uploads via
2469 $c->request.  You must handle all body parsing yourself.
2470
2471 =cut
2472
2473 sub read { my $c = shift; return $c->request->read( @_ ) }
2474
2475 =head2 $c->run
2476
2477 Starts the engine.
2478
2479 =cut
2480
2481 sub run {
2482   my $app = shift;
2483   $app->_make_immutable_if_needed;
2484   $app->engine_loader->needs_psgi_engine_compat_hack ?
2485     $app->engine->run($app, @_) :
2486       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2487 }
2488
2489 sub _make_immutable_if_needed {
2490     my $class = shift;
2491     my $meta = Class::MOP::get_metaclass_by_name($class);
2492     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2493     if (
2494         $meta->is_immutable
2495         && ! { $meta->immutable_options }->{replace_constructor}
2496         && $isa_ca
2497     ) {
2498         warn("You made your application class ($class) immutable, "
2499             . "but did not inline the\nconstructor. "
2500             . "This will break catalyst, as your app \@ISA "
2501             . "Class::Accessor(::Fast)?\nPlease pass "
2502             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2503     }
2504     unless ($meta->is_immutable) {
2505         # XXX - FIXME warning here as you should make your app immutable yourself.
2506         $meta->make_immutable(
2507             replace_constructor => 1,
2508         );
2509     }
2510 }
2511
2512 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2513
2514 Sets an action in a given namespace.
2515
2516 =cut
2517
2518 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2519
2520 =head2 $c->setup_actions($component)
2521
2522 Sets up actions for a component.
2523
2524 =cut
2525
2526 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2527
2528 =head2 $c->setup_components
2529
2530 This method is called internally to set up the application's components.
2531
2532 It finds modules by calling the L<locate_components> method, expands them to
2533 package names with the L<expand_component_module> method, and then installs
2534 each component into the application.
2535
2536 The C<setup_components> config option is passed to both of the above methods.
2537
2538 Installation of each component is performed by the L<setup_component> method,
2539 below.
2540
2541 =cut
2542
2543 sub setup_components {
2544     my $class = shift;
2545
2546     my $config  = $class->config->{ setup_components };
2547
2548     my @comps = $class->locate_components($config);
2549     my %comps = map { $_ => 1 } @comps;
2550
2551     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2552     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2553         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2554     ) if $deprecatedcatalyst_component_names;
2555
2556     for my $component ( @comps ) {
2557
2558         # We pass ignore_loaded here so that overlay files for (e.g.)
2559         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2560         # we know M::P::O found a file on disk so this is safe
2561
2562         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2563     }
2564
2565     for my $component (@comps) {
2566         my $instance = $class->components->{ $component } = $class->setup_component($component);
2567         my @expanded_components = $instance->can('expand_modules')
2568             ? $instance->expand_modules( $component, $config )
2569             : $class->expand_component_module( $component, $config );
2570         for my $component (@expanded_components) {
2571             next if $comps{$component};
2572             $class->components->{ $component } = $class->setup_component($component);
2573         }
2574     }
2575 }
2576
2577 =head2 $c->locate_components( $setup_component_config )
2578
2579 This method is meant to provide a list of component modules that should be
2580 setup for the application.  By default, it will use L<Module::Pluggable>.
2581
2582 Specify a C<setup_components> config option to pass additional options directly
2583 to L<Module::Pluggable>. To add additional search paths, specify a key named
2584 C<search_extra> as an array reference. Items in the array beginning with C<::>
2585 will have the application class name prepended to them.
2586
2587 =cut
2588
2589 sub locate_components {
2590     my $class  = shift;
2591     my $config = shift;
2592
2593     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2594     my $extra   = delete $config->{ search_extra } || [];
2595
2596     push @paths, @$extra;
2597
2598     my $locator = Module::Pluggable::Object->new(
2599         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2600         %$config
2601     );
2602
2603     # XXX think about ditching this sort entirely
2604     my @comps = sort { length $a <=> length $b } $locator->plugins;
2605
2606     return @comps;
2607 }
2608
2609 =head2 $c->expand_component_module( $component, $setup_component_config )
2610
2611 Components found by C<locate_components> will be passed to this method, which
2612 is expected to return a list of component (package) names to be set up.
2613
2614 =cut
2615
2616 sub expand_component_module {
2617     my ($class, $module) = @_;
2618     return Devel::InnerPackage::list_packages( $module );
2619 }
2620
2621 =head2 $c->setup_component
2622
2623 =cut
2624
2625 sub setup_component {
2626     my( $class, $component ) = @_;
2627
2628     unless ( $component->can( 'COMPONENT' ) ) {
2629         return $component;
2630     }
2631
2632     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2633     my $config = $class->config->{ $suffix } || {};
2634     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2635     # methods also pass it. local to avoid pointlessly shitting in config
2636     # for the debug screen, as $component is already the key name.
2637     local $config->{catalyst_component_name} = $component;
2638
2639     my $instance = eval { $component->COMPONENT( $class, $config ); };
2640
2641     if ( my $error = $@ ) {
2642         chomp $error;
2643         Catalyst::Exception->throw(
2644             message => qq/Couldn't instantiate component "$component", "$error"/
2645         );
2646     }
2647
2648     unless (blessed $instance) {
2649         my $metaclass = Moose::Util::find_meta($component);
2650         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2651         my $component_method_from = $method_meta->associated_metaclass->name;
2652         my $value = defined($instance) ? $instance : 'undef';
2653         Catalyst::Exception->throw(
2654             message =>
2655             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2656         );
2657     }
2658     return $instance;
2659 }
2660
2661 =head2 $c->setup_dispatcher
2662
2663 Sets up dispatcher.
2664
2665 =cut
2666
2667 sub setup_dispatcher {
2668     my ( $class, $dispatcher ) = @_;
2669
2670     if ($dispatcher) {
2671         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2672     }
2673
2674     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2675         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2676     }
2677
2678     unless ($dispatcher) {
2679         $dispatcher = $class->dispatcher_class;
2680     }
2681
2682     Class::MOP::load_class($dispatcher);
2683
2684     # dispatcher instance
2685     $class->dispatcher( $dispatcher->new );
2686 }
2687
2688 =head2 $c->setup_engine
2689
2690 Sets up engine.
2691
2692 =cut
2693
2694 sub engine_class {
2695     my ($class, $requested_engine) = @_;
2696
2697     if (!$class->engine_loader || $requested_engine) {
2698         $class->engine_loader(
2699             Catalyst::EngineLoader->new({
2700                 application_name => $class,
2701                 (defined $requested_engine
2702                      ? (catalyst_engine_class => $requested_engine) : ()),
2703             }),
2704         );
2705     }
2706
2707     $class->engine_loader->catalyst_engine_class;
2708 }
2709
2710 sub setup_engine {
2711     my ($class, $requested_engine) = @_;
2712
2713     my $engine = do {
2714         my $loader = $class->engine_loader;
2715
2716         if (!$loader || $requested_engine) {
2717             $loader = Catalyst::EngineLoader->new({
2718                 application_name => $class,
2719                 (defined $requested_engine
2720                      ? (requested_engine => $requested_engine) : ()),
2721             }),
2722
2723             $class->engine_loader($loader);
2724         }
2725
2726         $loader->catalyst_engine_class;
2727     };
2728
2729     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2730     return if $class->loading_psgi_file;
2731
2732     Class::MOP::load_class($engine);
2733
2734     if ($ENV{MOD_PERL}) {
2735         my $apache = $class->engine_loader->auto;
2736
2737         my $meta = find_meta($class);
2738         my $was_immutable = $meta->is_immutable;
2739         my %immutable_options = $meta->immutable_options;
2740         $meta->make_mutable if $was_immutable;
2741
2742         $meta->add_method(handler => sub {
2743             my $r = shift;
2744             my $psgi_app = $class->_finalized_psgi_app;
2745             $apache->call_app($r, $psgi_app);
2746         });
2747
2748         $meta->make_immutable(%immutable_options) if $was_immutable;
2749     }
2750
2751     $class->engine( $engine->new );
2752
2753     return;
2754 }
2755
2756 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2757 ## build in server support (back compat support for pre psgi port behavior).
2758 ## This is so that we don't build a new psgi app for each request when using
2759 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2760
2761 sub _finalized_psgi_app {
2762     my ($app) = @_;
2763
2764     unless ($app->_psgi_app) {
2765         my $psgi_app = $app->_setup_psgi_app;
2766         $app->_psgi_app($psgi_app);
2767     }
2768
2769     return $app->_psgi_app;
2770 }
2771
2772 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2773 ## home directory and load that and return it (just assume it is doing the
2774 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2775 ## in default_middleware and return it ( this is for backward compatibility
2776 ## with pre psgi port behavior ).
2777
2778 sub _setup_psgi_app {
2779     my ($app) = @_;
2780
2781     for my $home (Path::Class::Dir->new($app->config->{home})) {
2782         my $psgi_file = $home->file(
2783             Catalyst::Utils::appprefix($app) . '.psgi',
2784         );
2785
2786         next unless -e $psgi_file;
2787
2788         # If $psgi_file calls ->setup_engine, it's doing so to load
2789         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2790         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2791         # anyway. So set a flag (ick) that tells setup_engine not to populate
2792         # $c->engine or do any other things we might regret.
2793
2794         $app->loading_psgi_file(1);
2795         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2796         $app->loading_psgi_file(0);
2797
2798         return $psgi_app
2799             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2800
2801         warn <<"EOW";
2802 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2803
2804 Its content has been ignored. Please consult the Catalyst::Upgrading
2805 documentation on how to upgrade from Catalyst::Engine::PSGI.
2806 EOW
2807     }
2808
2809     return $app->apply_default_middlewares($app->psgi_app);
2810 }
2811
2812 =head2 $c->apply_default_middlewares
2813
2814 Adds the following L<Plack> middlewares to your application, since they are
2815 useful and commonly needed:
2816
2817 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2818 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2819 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2820 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2821 applied since this middleware is smart enough to conditionally apply itself).
2822
2823 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2824 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2825 $ENV{SCRIPT_NAME}
2826
2827 =cut
2828
2829
2830 sub apply_default_middlewares {
2831     my ($app, $psgi_app) = @_;
2832
2833     $psgi_app = Plack::Middleware::Conditional->wrap(
2834         $psgi_app,
2835         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2836         condition => sub {
2837             my ($env) = @_;
2838             return if $app->config->{ignore_frontend_proxy};
2839             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2840                 || $app->config->{using_frontend_proxy};
2841         },
2842     );
2843
2844     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2845     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2846     $psgi_app = Plack::Middleware::Conditional->wrap(
2847         $psgi_app,
2848         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2849         condition => sub {
2850             my ($env) = @_;
2851             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2852             return unless $1 < 4.23;
2853             1;
2854         },
2855     );
2856
2857     # we're applying this unconditionally as the middleware itself already makes
2858     # sure it doesn't fuck things up if it's not running under one of the right
2859     # IIS versions
2860     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2861
2862     # And another IIS issue, this time with IIS7.
2863     $psgi_app = Plack::Middleware::Conditional->wrap(
2864         $psgi_app,
2865         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2866         condition => sub {
2867             my ($env) = @_;
2868             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2869         },
2870     );
2871
2872     return $psgi_app;
2873 }
2874
2875 =head2 $c->psgi_app
2876
2877 Returns a PSGI application code reference for the catalyst application
2878 C<$c>. This is the bare application without any middlewares
2879 applied. C<${myapp}.psgi> is not taken into account.
2880
2881 This is what you want to be using to retrieve the PSGI application code
2882 reference of your Catalyst application for use in F<.psgi> files.
2883
2884 =cut
2885
2886 sub psgi_app {
2887     my ($app) = @_;
2888     my $psgi = $app->engine->build_psgi_app($app);
2889     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
2890 }
2891
2892 =head2 $c->setup_home
2893
2894 Sets up the home directory.
2895
2896 =cut
2897
2898 sub setup_home {
2899     my ( $class, $home ) = @_;
2900
2901     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2902         $home = $env;
2903     }
2904
2905     $home ||= Catalyst::Utils::home($class);
2906
2907     if ($home) {
2908         #I remember recently being scolded for assigning config values like this
2909         $class->config->{home} ||= $home;
2910         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2911     }
2912 }
2913
2914 =head2 $c->setup_log
2915
2916 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2917 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2918 log to.
2919
2920 This method also installs a C<debug> method that returns a true value into the
2921 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2922 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2923
2924 Note that if the log has already been setup, by either a previous call to
2925 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2926 that this method won't actually set up the log object.
2927
2928 =cut
2929
2930 sub setup_log {
2931     my ( $class, $levels ) = @_;
2932
2933     $levels ||= '';
2934     $levels =~ s/^\s+//;
2935     $levels =~ s/\s+$//;
2936     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2937
2938     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2939     if ( defined $env_debug ) {
2940         $levels{debug} = 1 if $env_debug; # Ugly!
2941         delete($levels{debug}) unless $env_debug;
2942     }
2943
2944     unless ( $class->log ) {
2945         $class->log( Catalyst::Log->new(keys %levels) );
2946     }
2947
2948     if ( $levels{debug} ) {
2949         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2950         $class->log->debug('Debug messages enabled');
2951     }
2952 }
2953
2954 =head2 $c->setup_plugins
2955
2956 Sets up plugins.
2957
2958 =cut
2959
2960 =head2 $c->setup_stats
2961
2962 Sets up timing statistics class.
2963
2964 =cut
2965
2966 sub setup_stats {
2967     my ( $class, $stats ) = @_;
2968
2969     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2970
2971     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2972     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2973         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2974         $class->log->debug('Statistics enabled');
2975     }
2976 }
2977
2978
2979 =head2 $c->registered_plugins
2980
2981 Returns a sorted list of the plugins which have either been stated in the
2982 import list.
2983
2984 If passed a given plugin name, it will report a boolean value indicating
2985 whether or not that plugin is loaded.  A fully qualified name is required if
2986 the plugin name does not begin with C<Catalyst::Plugin::>.
2987
2988  if ($c->registered_plugins('Some::Plugin')) {
2989      ...
2990  }
2991
2992 =cut
2993
2994 {
2995
2996     sub registered_plugins {
2997         my $proto = shift;
2998         return sort keys %{ $proto->_plugins } unless @_;
2999         my $plugin = shift;
3000         return 1 if exists $proto->_plugins->{$plugin};
3001         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3002     }
3003
3004     sub _register_plugin {
3005         my ( $proto, $plugin, $instant ) = @_;
3006         my $class = ref $proto || $proto;
3007
3008         Class::MOP::load_class( $plugin );
3009         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3010             if $plugin->isa( 'Catalyst::Component' );
3011         my $plugin_meta = Moose::Meta::Class->create($plugin);
3012         if (!$plugin_meta->has_method('new')
3013             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3014             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3015         }
3016         if (!$instant && !$proto->_plugins->{$plugin}) {
3017             my $meta = Class::MOP::get_metaclass_by_name($class);
3018             $meta->superclasses($plugin, $meta->superclasses);
3019         }
3020         $proto->_plugins->{$plugin} = 1;
3021         return $class;
3022     }
3023
3024     sub _default_plugins { return qw(Unicode::Encoding) }
3025
3026     sub setup_plugins {
3027         my ( $class, $plugins ) = @_;
3028
3029         $class->_plugins( {} ) unless $class->_plugins;
3030         $plugins = [ grep {
3031             m/Unicode::Encoding/ ? do {
3032                 $class->log->warn(
3033                     'Unicode::Encoding plugin is auto-applied,'
3034                     . ' please remove this from your appclass'
3035                     . ' and make sure to define "encoding" config'
3036                 );
3037                 unless (exists $class->config->{'encoding'}) {
3038                   $class->config->{'encoding'} = 'UTF-8';
3039                 }
3040                 () }
3041                 : $_
3042         } @$plugins ];
3043         push @$plugins, $class->_default_plugins;
3044         $plugins = Data::OptList::mkopt($plugins || []);
3045
3046         my @plugins = map {
3047             [ Catalyst::Utils::resolve_namespace(
3048                   $class . '::Plugin',
3049                   'Catalyst::Plugin', $_->[0]
3050               ),
3051               $_->[1],
3052             ]
3053          } @{ $plugins };
3054
3055         for my $plugin ( reverse @plugins ) {
3056             Class::MOP::load_class($plugin->[0], $plugin->[1]);
3057             my $meta = find_meta($plugin->[0]);
3058             next if $meta && $meta->isa('Moose::Meta::Role');
3059
3060             $class->_register_plugin($plugin->[0]);
3061         }
3062
3063         my @roles =
3064             map  { $_->[0]->name, $_->[1] }
3065             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3066             map  { [find_meta($_->[0]), $_->[1]] }
3067             @plugins;
3068
3069         Moose::Util::apply_all_roles(
3070             $class => @roles
3071         ) if @roles;
3072     }
3073 }
3074
3075 =head2 registered_middlewares
3076
3077 Read only accessor that returns an array of all the middleware in the order
3078 that they were added (which is the REVERSE of the order they will be applied).
3079
3080 The values returned will be either instances of L<Plack::Middleware> or of a
3081 compatible interface, or a coderef, which is assumed to be inlined middleware
3082
3083 =head2 setup_middleware (?@middleware)
3084
3085 Read configuration information stored in configuration key C<psgi_middleware> or
3086 from passed @args.
3087
3088 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3089 to use it to enable L<Plack::Middleware>
3090
3091 This method is automatically called during 'setup' of your application, so
3092 you really don't need to invoke it.
3093
3094 When we read middleware definitions from configuration, we reverse the list
3095 which sounds odd but is likely how you expect it to work if you have prior
3096 experience with L<Plack::Builder> or if you previously used the plugin
3097 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3098
3099 =cut
3100
3101 sub registered_middlewares {
3102     my $class = shift;
3103     if(my $middleware = $class->_psgi_middleware) {
3104         return @$middleware;
3105     } else {
3106         die "You cannot call ->registered_middlewares until middleware has been setup";
3107     }
3108 }
3109
3110 sub setup_middleware {
3111     my ($class, @middleware_definitions) = @_;
3112     push @middleware_definitions, reverse(
3113       @{$class->config->{'psgi_middleware'}||[]});
3114
3115     my @middleware = ();
3116     while(my $next = shift(@middleware_definitions)) {
3117         if(ref $next) {
3118             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3119                 push @middleware, $next;
3120             } elsif(ref $next eq 'CODE') {
3121                 push @middleware, $next;
3122             } elsif(ref $next eq 'HASH') {
3123                 my $namespace = shift @middleware_definitions;
3124                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3125                 push @middleware, $mw;
3126             } else {
3127               die "I can't handle middleware definition ${\ref $next}";
3128             }
3129         } else {
3130           my $mw = $class->Catalyst::Utils::build_middleware($next);
3131           push @middleware, $mw;
3132         }
3133     }
3134
3135     $class->_psgi_middleware(\@middleware);
3136 }
3137
3138 =head2 registered_data_handlers
3139
3140 A read only copy of registered Data Handlers returned as a Hash, where each key
3141 is a content type and each value is a subref that attempts to decode that content
3142 type.
3143
3144 =head2 setup_data_handlers (?@data_handler)
3145
3146 Read configuration information stored in configuration key C<data_handlers> or
3147 from passed @args.
3148
3149 See under L</CONFIGURATION> information regarding C<data_handlers>.
3150
3151 This method is automatically called during 'setup' of your application, so
3152 you really don't need to invoke it.
3153
3154 =head2 default_data_handlers
3155
3156 Default Data Handler that come bundled with L<Catalyst>.  Currently there is
3157 only one default data handler, for 'application/json'.  This uses L<JSON::MaybeXS>
3158 which uses the dependency free L<JSON::PP> OR L<Cpanel::JSON::XS> if you have
3159 installed it.  If you don't mind the XS dependency, you should add the faster
3160 L<Cpanel::JSON::XS> to you dependency list (in your Makefile.PL or dist.ini, or
3161 cpanfile, etc.)
3162
3163 =cut
3164
3165 sub registered_data_handlers {
3166     my $class = shift;
3167     if(my $data_handlers = $class->_data_handlers) {
3168         return %$data_handlers;
3169     } else {
3170         die "You cannot call ->registered_data_handlers until data_handers has been setup";
3171     }
3172 }
3173
3174 sub setup_data_handlers {
3175     my ($class, %data_handler_callbacks) = @_;
3176     %data_handler_callbacks = (
3177       %{$class->default_data_handlers},
3178       %{$class->config->{'data_handlers'}||+{}},
3179       %data_handler_callbacks);
3180
3181     $class->_data_handlers(\%data_handler_callbacks);
3182 }
3183
3184 sub default_data_handlers {
3185     my ($class) = @_;
3186     return +{
3187       'application/json' => sub { local $/; decode_json $_->getline },
3188     };
3189 }
3190
3191 =head2 $c->stack
3192
3193 Returns an arrayref of the internal execution stack (actions that are
3194 currently executing).
3195
3196 =head2 $c->stats
3197
3198 Returns the current timing statistics object. By default Catalyst uses
3199 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3200 L<< stats_class|/"$c->stats_class" >>.
3201
3202 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3203 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3204 profile explicitly, although MyApp.pm still won't profile nor output anything
3205 by itself.
3206
3207 =head2 $c->stats_class
3208
3209 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3210
3211 =head2 $c->use_stats
3212
3213 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3214
3215 Note that this is a static method, not an accessor and should be overridden
3216 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3217
3218 =cut
3219
3220 sub use_stats { 0 }
3221
3222
3223 =head2 $c->write( $data )
3224
3225 Writes $data to the output stream. When using this method directly, you
3226 will need to manually set the C<Content-Length> header to the length of
3227 your output data, if known.
3228
3229 =cut
3230
3231 sub write {
3232     my $c = shift;
3233
3234     # Finalize headers if someone manually writes output (for compat)
3235     $c->finalize_headers;
3236
3237     return $c->response->write( @_ );
3238 }
3239
3240 =head2 version
3241
3242 Returns the Catalyst version number. Mostly useful for "powered by"
3243 messages in template systems.
3244
3245 =cut
3246
3247 sub version { return $Catalyst::VERSION }
3248
3249 =head1 CONFIGURATION
3250
3251 There are a number of 'base' config variables which can be set:
3252
3253 =over
3254
3255 =item *
3256
3257 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3258
3259 =item *
3260
3261 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3262
3263 =item *
3264
3265 C<disable_component_resolution_regex_fallback> - Turns
3266 off the deprecated component resolution functionality so
3267 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3268 are called then regex search will not be attempted on string values and
3269 instead C<undef> will be returned.
3270
3271 =item *
3272
3273 C<home> - The application home directory. In an uninstalled application,
3274 this is the top level application directory. In an installed application,
3275 this will be the directory containing C<< MyApp.pm >>.
3276
3277 =item *
3278
3279 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3280
3281 =item *
3282
3283 C<name> - The name of the application in debug messages and the debug and
3284 welcome screens
3285
3286 =item *
3287
3288 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3289 until it is accessed. This allows you to (for example) check authentication (and reject
3290 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3291
3292 =item *
3293
3294 C<root> - The root directory for templates. Usually this is just a
3295 subdirectory of the home directory, but you can set it to change the
3296 templates to a different directory.
3297
3298 =item *
3299
3300 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3301 namespaces from which components will be loaded (and constructed and stored in
3302 C<< $c->components >>).
3303
3304 =item *
3305
3306 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3307 to be shown in hit debug tables in the test server.
3308
3309 =item *
3310
3311 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3312 variable should be used for determining the request path.
3313
3314 Most web server environments pass the requested path to the application using environment variables,
3315 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3316 exposed as C<< $c->request->base >>) and the request path below that base.
3317
3318 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3319 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3320
3321 =over
3322
3323 =item use_request_uri_for_path => 0
3324
3325 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3326 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3327 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3328 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3329
3330 However this method has the major disadvantage that it is impossible to correctly decode some elements
3331 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3332 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3333 can't distinguish / vs %2F in paths (in addition to other encoded values).
3334
3335 =item use_request_uri_for_path => 1
3336
3337 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3338 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3339 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3340
3341 Given that this method of path resolution is provably more correct, it is recommended that you use
3342 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3343 aware of the implications of not being able to handle encoded URI paths correctly.
3344
3345 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3346 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3347 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3348 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3349 C<< $c->request->base >> will be incorrect.
3350
3351 =back
3352
3353 =item *
3354
3355 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3356
3357 =item *
3358
3359 C<encoding> - See L</ENCODING>
3360
3361 =item *
3362
3363 C<abort_chain_on_error_fix>
3364
3365 When there is an error in an action chain, the default behavior is to continue
3366 processing the remaining actions and then catch the error upon chain end.  This
3367 can lead to running actions when the application is in an unexpected state.  If
3368 you have this issue, setting this config value to true will promptly exit a
3369 chain when there is an error raised in any action (thus terminating the chain
3370 early.)
3371
3372 use like:
3373
3374     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3375
3376 In the future this might become the default behavior.
3377
3378 =item *
3379
3380 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3381
3382 =item *
3383
3384 C<data_handlers> - See L<DATA HANDLERS>.
3385
3386 =back
3387
3388 =head1 INTERNAL ACTIONS
3389
3390 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3391 C<_ACTION>, and C<_END>. These are by default not shown in the private
3392 action table, but you can make them visible with a config parameter.
3393
3394     MyApp->config(show_internal_actions => 1);
3395
3396 =head1 ON-DEMAND PARSER
3397
3398 The request body is usually parsed at the beginning of a request,
3399 but if you want to handle input yourself, you can enable on-demand
3400 parsing with a config parameter.
3401
3402     MyApp->config(parse_on_demand => 1);
3403
3404 =head1 PROXY SUPPORT
3405
3406 Many production servers operate using the common double-server approach,
3407 with a lightweight frontend web server passing requests to a larger
3408 backend server. An application running on the backend server must deal
3409 with two problems: the remote user always appears to be C<127.0.0.1> and
3410 the server's hostname will appear to be C<localhost> regardless of the
3411 virtual host that the user connected through.
3412
3413 Catalyst will automatically detect this situation when you are running
3414 the frontend and backend servers on the same machine. The following
3415 changes are made to the request.
3416
3417     $c->req->address is set to the user's real IP address, as read from
3418     the HTTP X-Forwarded-For header.
3419
3420     The host value for $c->req->base and $c->req->uri is set to the real
3421     host, as read from the HTTP X-Forwarded-Host header.
3422
3423 Additionally, you may be running your backend application on an insecure
3424 connection (port 80) while your frontend proxy is running under SSL.  If there
3425 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3426 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3427 be created properly.
3428
3429 In the case of passing in:
3430
3431     X-Forwarded-Port: 443
3432
3433 All calls to C<uri_for> will result in an https link, as is expected.
3434
3435 Obviously, your web server must support these headers for this to work.
3436
3437 In a more complex server farm environment where you may have your
3438 frontend proxy server(s) on different machines, you will need to set a
3439 configuration option to tell Catalyst to read the proxied data from the
3440 headers.
3441
3442     MyApp->config(using_frontend_proxy => 1);
3443
3444 If you do not wish to use the proxy support at all, you may set:
3445
3446     MyApp->config(ignore_frontend_proxy => 0);
3447
3448 =head2 Note about psgi files
3449
3450 Note that if you supply your own .psgi file, calling
3451 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3452
3453 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3454 in your psgi, for example:
3455
3456     builder {
3457         enable "Plack::Middleware::ReverseProxy";
3458         MyApp->psgi_app
3459     };
3460
3461 This will unconditionally add the ReverseProxy support, or you need to call
3462 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3463 apply the support depending upon your config).
3464
3465 See L<Catalyst::PSGI> for more information.
3466
3467 =head1 THREAD SAFETY
3468
3469 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3470 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3471 believe the Catalyst core to be thread-safe.
3472
3473 If you plan to operate in a threaded environment, remember that all other
3474 modules you are using must also be thread-safe. Some modules, most notably
3475 L<DBD::SQLite>, are not thread-safe.
3476
3477 =head1 DATA HANDLERS
3478
3479 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3480 form parameters and URL search query fields.  However it has become common
3481 for various alternative content types to be PUT or POSTed to your controllers
3482 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3483 XML and other content types when communicating with an application server.  In
3484 order to better support this use case, L<Catalyst> defines a global configuration
3485 option, C<data_handlers>, which lets you associate a content type with a coderef
3486 that parses that content type into something Perl can readily access.
3487
3488     package MyApp::Web;
3489
3490     use Catalyst;
3491     use JSON::Maybe;
3492
3493     __PACKAGE__->config(
3494       data_handlers => {
3495         'application/json' => sub { local $/; decode_json $_->getline },
3496       },
3497       ## Any other configuration.
3498     );
3499
3500     __PACKAGE__->setup;
3501
3502 By default L<Catalyst> comes with a generic JSON data handler similar to the
3503 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3504 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3505 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3506 or dist.ini, cpanfile, etc.)
3507
3508 The C<data_handlers> configuation is a hashref whose keys are HTTP Content-Types
3509 (matched against the incoming request type using a regexp such as to be case
3510 insensitive) and whose values are coderefs that receive a localized version of
3511 C<$_> which is a filehandle object pointing to received body.
3512
3513 This feature is considered an early access release and we reserve the right
3514 to alter the interface in order to provide a performant and secure solution to
3515 alternative request body content.  Your reports welcomed!
3516
3517 =head1 PSGI MIDDLEWARE
3518
3519 You can define middleware, defined as L<Plack::Middleware> or a compatible
3520 interface in configuration.  Your middleware definitions are in the form of an
3521 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3522 with details to follow:
3523
3524     package MyApp::Web;
3525
3526     use Catalyst;
3527     use Plack::Middleware::StackTrace;
3528
3529     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3530
3531     __PACKAGE__->config(
3532       'psgi_middleware', [
3533         'Debug',
3534         '+MyApp::Custom',
3535         $stacktrace_middleware,
3536         'Session' => {store => 'File'},
3537         sub {
3538           my $app = shift;
3539           return sub {
3540             my $env = shift;
3541             $env->{myapp.customkey} = 'helloworld';
3542             $app->($env);
3543           },
3544         },
3545       ],
3546     );
3547
3548     __PACKAGE__->setup;
3549
3550 So the general form is:
3551
3552     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3553
3554 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3555 the order listed (to make it function similarly to L<Plack::Builder>:
3556
3557 =over 4
3558
3559 =item Middleware Object
3560
3561 An already initialized object that conforms to the L<Plack::Middleware>
3562 specification:
3563
3564     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3565
3566     __PACKAGE__->config(
3567       'psgi_middleware', [
3568         $stacktrace_middleware,
3569       ]);
3570
3571
3572 =item coderef
3573
3574 A coderef that is an inlined middleware:
3575
3576     __PACKAGE__->config(
3577       'psgi_middleware', [
3578         sub {
3579           my $app = shift;
3580           return sub {
3581             my $env = shift;
3582             if($env->{PATH_INFO} =~m/forced/) {
3583               Plack::App::File
3584                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3585                 ->call($env);
3586             } else {
3587               return $app->($env);
3588             }
3589          },
3590       },
3591     ]);
3592
3593
3594
3595 =item a scalar
3596
3597 We assume the scalar refers to a namespace after normalizing it using the
3598 following rules:
3599
3600 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3601 is assumed to be 'as is', and we just install and use the middleware.
3602
3603 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3604 (the package name of your Catalyst application subclass), we also assume then
3605 that it is a full namespace, and use it.
3606
3607 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3608 resolve it first by looking for it under your application namespace (for example
3609 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3610 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3611 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3612 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3613 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3614 you find that a good idea.
3615
3616 Examples:
3617
3618     package MyApp::Web;
3619
3620     __PACKAGE__->config(
3621       'psgi_middleware', [
3622         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3623         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3624         '+MyApp::Custom',  ## MyApp::Custom->wrap
3625       ],
3626     );
3627
3628 =item a scalar followed by a hashref
3629
3630 Just like the previous, except the following C<HashRef> is used as arguments
3631 to initialize the middleware object.
3632
3633     __PACKAGE__->config(
3634       'psgi_middleware', [
3635          'Session' => {store => 'File'},
3636     ]);
3637
3638 =back
3639
3640 Please see L<PSGI> for more on middleware.
3641
3642 =head1 ENCODING
3643
3644 On request, decodes all params from encoding into a sequence of
3645 logical characters. On response, encodes body into encoding.
3646
3647 =head2 Methods
3648
3649 =over 4
3650
3651 =item encoding
3652
3653 Returns an instance of an C<Encode> encoding
3654
3655     print $c->encoding->name
3656
3657 =item handle_unicode_encoding_exception ($exception_context)
3658
3659 Method called when decoding process for a request fails.
3660
3661 An C<$exception_context> hashref is provided to allow you to override the
3662 behaviour of your application when given data with incorrect encodings.
3663
3664 The default method throws exceptions in the case of invalid request parameters
3665 (resulting in a 500 error), but ignores errors in upload filenames.
3666
3667 The keys passed in the C<$exception_context> hash are:
3668
3669 =over
3670
3671 =item param_value
3672
3673 The value which was not able to be decoded.
3674
3675 =item error_msg
3676
3677 The exception received from L<Encode>.
3678
3679 =item encoding_step
3680
3681 What type of data was being decoded. Valid values are (currently)
3682 C<params> - for request parameters / arguments / captures
3683 and C<uploads> - for request upload filenames.
3684
3685 =back
3686
3687 =back
3688
3689 =head1 SUPPORT
3690
3691 IRC:
3692
3693     Join #catalyst on irc.perl.org.
3694
3695 Mailing Lists:
3696
3697     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3698     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3699
3700 Web:
3701
3702     http://catalyst.perl.org
3703
3704 Wiki:
3705
3706     http://dev.catalyst.perl.org
3707
3708 =head1 SEE ALSO
3709
3710 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3711
3712 =head2 L<Catalyst::Manual> - The Catalyst Manual
3713
3714 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3715
3716 =head2 L<Catalyst::Engine> - Core engine
3717
3718 =head2 L<Catalyst::Log> - Log class.
3719
3720 =head2 L<Catalyst::Request> - Request object
3721
3722 =head2 L<Catalyst::Response> - Response object
3723
3724 =head2 L<Catalyst::Test> - The test suite.
3725
3726 =head1 PROJECT FOUNDER
3727
3728 sri: Sebastian Riedel <sri@cpan.org>
3729
3730 =head1 CONTRIBUTORS
3731
3732 abw: Andy Wardley
3733
3734 acme: Leon Brocard <leon@astray.com>
3735
3736 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3737
3738 Andrew Bramble
3739
3740 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3741
3742 Andrew Ruthven
3743
3744 andyg: Andy Grundman <andy@hybridized.org>
3745
3746 audreyt: Audrey Tang
3747
3748 bricas: Brian Cassidy <bricas@cpan.org>
3749
3750 Caelum: Rafael Kitover <rkitover@io.com>
3751
3752 chansen: Christian Hansen
3753
3754 chicks: Christopher Hicks
3755
3756 Chisel Wright C<pause@herlpacker.co.uk>
3757
3758 Danijel Milicevic C<me@danijel.de>
3759
3760 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3761
3762 David Naughton, C<naughton@umn.edu>
3763
3764 David E. Wheeler
3765
3766 dhoss: Devin Austin <dhoss@cpan.org>
3767
3768 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3769
3770 Drew Taylor
3771
3772 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3773
3774 esskar: Sascha Kiefer
3775
3776 fireartist: Carl Franks <cfranks@cpan.org>
3777
3778 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3779
3780 gabb: Danijel Milicevic
3781
3782 Gary Ashton Jones
3783
3784 Gavin Henry C<ghenry@perl.me.uk>
3785
3786 Geoff Richards
3787
3788 groditi: Guillermo Roditi <groditi@gmail.com>
3789
3790 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3791
3792 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3793
3794 jcamacho: Juan Camacho
3795
3796 jester: Jesse Sheidlower C<jester@panix.com>
3797
3798 jhannah: Jay Hannah <jay@jays.net>
3799
3800 Jody Belka
3801
3802 Johan Lindstrom
3803
3804 jon: Jon Schutz <jjschutz@cpan.org>
3805
3806 Jonathan Rockway C<< <jrockway@cpan.org> >>
3807
3808 Kieren Diment C<kd@totaldatasolution.com>
3809
3810 konobi: Scott McWhirter <konobi@cpan.org>
3811
3812 marcus: Marcus Ramberg <mramberg@cpan.org>
3813
3814 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3815
3816 mgrimes: Mark Grimes <mgrimes@cpan.org>
3817
3818 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3819
3820 mugwump: Sam Vilain
3821
3822 naughton: David Naughton
3823
3824 ningu: David Kamholz <dkamholz@cpan.org>
3825
3826 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3827
3828 numa: Dan Sully <daniel@cpan.org>
3829
3830 obra: Jesse Vincent
3831
3832 Octavian Rasnita
3833
3834 omega: Andreas Marienborg
3835
3836 Oleg Kostyuk <cub.uanic@gmail.com>
3837
3838 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3839
3840 rafl: Florian Ragwitz <rafl@debian.org>
3841
3842 random: Roland Lammel <lammel@cpan.org>
3843
3844 Robert Sedlacek C<< <rs@474.at> >>
3845
3846 SpiceMan: Marcel Montes
3847
3848 sky: Arthur Bergman
3849
3850 szbalint: Balint Szilakszi <szbalint@cpan.org>
3851
3852 t0m: Tomas Doran <bobtfish@bobtfish.net>
3853
3854 Ulf Edvinsson
3855
3856 Viljo Marrandi C<vilts@yahoo.com>
3857
3858 Will Hawes C<info@whawes.co.uk>
3859
3860 willert: Sebastian Willert <willert@cpan.org>
3861
3862 wreis: Wallace Reis <wreis@cpan.org>
3863
3864 Yuval Kogman, C<nothingmuch@woobling.org>
3865
3866 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3867
3868 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3869
3870 =head1 COPYRIGHT
3871
3872 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3873
3874 =head1 LICENSE
3875
3876 This library is free software. You can redistribute it and/or modify it under
3877 the same terms as Perl itself.
3878
3879 =cut
3880
3881 no Moose;
3882
3883 __PACKAGE__->meta->make_immutable;
3884
3885 1;