lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Util;
  49 use Class::Load 'load_class';
  50
  51 BEGIN { require 5.008003; }
  52
  53 has stack => (is => 'ro', default => sub { [] });
  54 has stash => (is => 'rw', default => sub { {} });
  55 has state => (is => 'rw', default => 0);
  56 has stats => (is => 'rw');
  57 has action => (is => 'rw');
  58 has counter => (is => 'rw', default => sub { {} });
  59 has request => (
  60     is => 'rw',
  61     default => sub {
  62         my $self = shift;
  63         $self->request_class->new($self->_build_request_constructor_args);
  64     },
  65     lazy => 1,
  66 );
  67 sub _build_request_constructor_args {
  68     my $self = shift;
  69     my %p = ( _log => $self->log );
  70     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  71     $p{data_handlers} = {$self->registered_data_handlers};
  72     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  73       if $self->config->{use_hash_multivalue_in_request};
  74     \%p;
  75 }
  76
  77 has response => (
  78     is => 'rw',
  79     default => sub {
  80         my $self = shift;
  81         $self->response_class->new($self->_build_response_constructor_args);
  82     },
  83     lazy => 1,
  84 );
  85 sub _build_response_constructor_args {
  86     my $self = shift;
  87     { _log => $self->log };
  88 }
  89
  90 has namespace => (is => 'rw');
  91
  92 sub depth { scalar @{ shift->stack || [] }; }
  93 sub comp { shift->component(@_) }
  94
  95 sub req {
  96     my $self = shift; return $self->request(@_);
  97 }
  98 sub res {
  99     my $self = shift; return $self->response(@_);
 100 }
 101
 102 # For backwards compatibility
 103 sub finalize_output { shift->finalize_body(@_) };
 104
 105 # For statistics
 106 our $COUNT     = 1;
 107 our $START     = time;
 108 our $RECURSION = 1000;
 109 our $DETACH    = Catalyst::Exception::Detach->new;
 110 our $GO        = Catalyst::Exception::Go->new;
 111
 112 #I imagine that very few of these really need to be class variables. if any.
 113 #maybe we should just make them attributes with a default?
 114 __PACKAGE__->mk_classdata($_)
 115   for qw/components arguments dispatcher engine log dispatcher_class
 116   engine_loader context_class request_class response_class stats_class
 117   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 118   _data_handlers/;
 119
 120 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 121 __PACKAGE__->request_class('Catalyst::Request');
 122 __PACKAGE__->response_class('Catalyst::Response');
 123 __PACKAGE__->stats_class('Catalyst::Stats');
 124
 125 # Remember to update this in Catalyst::Runtime as well!
 126
 127 our $VERSION = '5.90059_004';
 128
 129 sub import {
 130     my ( $class, @arguments ) = @_;
 131
 132     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 133     # callers @ISA.
 134     return unless $class eq 'Catalyst';
 135
 136     my $caller = caller();
 137     return if $caller eq 'main';
 138
 139     my $meta = Moose::Meta::Class->initialize($caller);
 140     unless ( $caller->isa('Catalyst') ) {
 141         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 142         $meta->superclasses(@superclasses);
 143     }
 144     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 145     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 146
 147     unless( $meta->has_method('meta') ){
 148         if ($Moose::VERSION >= 1.15) {
 149             $meta->_add_meta_method('meta');
 150         }
 151         else {
 152             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 153         }
 154     }
 155
 156     $caller->arguments( [@arguments] );
 157     $caller->setup_home;
 158 }
 159
 160 sub _application { $_[0] }
 161
 162 =encoding UTF-8
 163
 164 =head1 NAME
 165
 166 Catalyst - The Elegant MVC Web Application Framework
 167
 168 =head1 SYNOPSIS
 169
 170 See the L<Catalyst::Manual> distribution for comprehensive
 171 documentation and tutorials.
 172
 173     # Install Catalyst::Devel for helpers and other development tools
 174     # use the helper to create a new application
 175     catalyst.pl MyApp
 176
 177     # add models, views, controllers
 178     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 179     script/myapp_create.pl view MyTemplate TT
 180     script/myapp_create.pl controller Search
 181
 182     # built in testserver -- use -r to restart automatically on changes
 183     # --help to see all available options
 184     script/myapp_server.pl
 185
 186     # command line testing interface
 187     script/myapp_test.pl /yada
 188
 189     ### in lib/MyApp.pm
 190     use Catalyst qw/-Debug/; # include plugins here as well
 191
 192     ### In lib/MyApp/Controller/Root.pm (autocreated)
 193     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 194         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 195         $c->stash->{template} = 'foo.tt'; # set the template
 196         # lookup something from db -- stash vars are passed to TT
 197         $c->stash->{data} =
 198           $c->model('Database::Foo')->search( { country => $args[0] } );
 199         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 200             $c->forward( 'bar' ); # process another action
 201             # do something else after forward returns
 202         }
 203     }
 204
 205     # The foo.tt TT template can use the stash data from the database
 206     [% WHILE (item = data.next) %]
 207         [% item.foo %]
 208     [% END %]
 209
 210     # called for /bar/of/soap, /bar/of/soap/10, etc.
 211     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 212
 213     # called after all actions are finished
 214     sub end : Action {
 215         my ( $self, $c ) = @_;
 216         if ( scalar @{ $c->error } ) { ... } # handle errors
 217         return if $c->res->body; # already have a response
 218         $c->forward( 'MyApp::View::TT' ); # render template
 219     }
 220
 221 See L<Catalyst::Manual::Intro> for additional information.
 222
 223 =head1 DESCRIPTION
 224
 225 Catalyst is a modern framework for making web applications without the
 226 pain usually associated with this process. This document is a reference
 227 to the main Catalyst application. If you are a new user, we suggest you
 228 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 229
 230 See L<Catalyst::Manual> for more documentation.
 231
 232 Catalyst plugins can be loaded by naming them as arguments to the "use
 233 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 234 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 235 C<My::Module>.
 236
 237     use Catalyst qw/My::Module/;
 238
 239 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 240 fully qualify the name by using a unary plus:
 241
 242     use Catalyst qw/
 243         My::Module
 244         +Fully::Qualified::Plugin::Name
 245     /;
 246
 247 Special flags like C<-Debug> can also be specified as
 248 arguments when Catalyst is loaded:
 249
 250     use Catalyst qw/-Debug My::Module/;
 251
 252 The position of plugins and flags in the chain is important, because
 253 they are loaded in the order in which they appear.
 254
 255 The following flags are supported:
 256
 257 =head2 -Debug
 258
 259 Enables debug output. You can also force this setting from the system
 260 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 261 settings override the application, with <MYAPP>_DEBUG having the highest
 262 priority.
 263
 264 This sets the log level to 'debug' and enables full debug output on the
 265 error screen. If you only want the latter, see L<< $c->debug >>.
 266
 267 =head2 -Home
 268
 269 Forces Catalyst to use a specific home directory, e.g.:
 270
 271     use Catalyst qw[-Home=/usr/mst];
 272
 273 This can also be done in the shell environment by setting either the
 274 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 275 is replaced with the uppercased name of your application, any "::" in
 276 the name will be replaced with underscores, e.g. MyApp::Web should use
 277 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 278
 279 If none of these are set, Catalyst will attempt to automatically detect the
 280 home directory. If you are working in a development environment, Catalyst
 281 will try and find the directory containing either Makefile.PL, Build.PL,
 282 dist.ini, or cpanfile. If the application has been installed into the system
 283 (i.e. you have done C<make install>), then Catalyst will use the path to your
 284 application module, without the .pm extension (e.g., /foo/MyApp if your
 285 application was installed at /foo/MyApp.pm)
 286
 287 =head2 -Log
 288
 289     use Catalyst '-Log=warn,fatal,error';
 290
 291 Specifies a comma-delimited list of log levels.
 292
 293 =head2 -Stats
 294
 295 Enables statistics collection and reporting.
 296
 297    use Catalyst qw/-Stats=1/;
 298
 299 You can also force this setting from the system environment with CATALYST_STATS
 300 or <MYAPP>_STATS. The environment settings override the application, with
 301 <MYAPP>_STATS having the highest priority.
 302
 303 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 304
 305 =head1 METHODS
 306
 307 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 308
 309 =head2 $c->action
 310
 311 Returns a L<Catalyst::Action> object for the current action, which
 312 stringifies to the action name. See L<Catalyst::Action>.
 313
 314 =head2 $c->namespace
 315
 316 Returns the namespace of the current action, i.e., the URI prefix
 317 corresponding to the controller of the current action. For example:
 318
 319     # in Controller::Foo::Bar
 320     $c->namespace; # returns 'foo/bar';
 321
 322 =head2 $c->request
 323
 324 =head2 $c->req
 325
 326 Returns the current L<Catalyst::Request> object, giving access to
 327 information about the current client request (including parameters,
 328 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 329
 330 =head2 REQUEST FLOW HANDLING
 331
 332 =head2 $c->forward( $action [, \@arguments ] )
 333
 334 =head2 $c->forward( $class, $method, [, \@arguments ] )
 335
 336 This is one way of calling another action (method) in the same or
 337 a different controller. You can also use C<< $self->my_method($c, @args) >>
 338 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 339 in a different controller.
 340 The main difference is that 'forward' uses some of the Catalyst request
 341 cycle overhead, including debugging, which may be useful to you. On the
 342 other hand, there are some complications to using 'forward', restrictions
 343 on values returned from 'forward', and it may not handle errors as you prefer.
 344 Whether you use 'forward' or not is up to you; it is not considered superior to
 345 the other ways to call a method.
 346
 347 'forward' calls  another action, by its private name. If you give a
 348 class name but no method, C<process()> is called. You may also optionally
 349 pass arguments in an arrayref. The action will receive the arguments in
 350 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 351 C<< $c->req->args >> will be restored to the previous values.
 352
 353 Any data C<return>ed from the action forwarded to, will be returned by the
 354 call to forward.
 355
 356     my $foodata = $c->forward('/foo');
 357     $c->forward('index');
 358     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 359     $c->forward('View::TT');
 360
 361 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 362 an C<< eval { } >> around the call (actually
 363 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 364 exceptions thrown by the called action non-fatal and pushing them onto
 365 $c->error instead. If you want C<die> to propagate you need to do something
 366 like:
 367
 368     $c->forward('foo');
 369     die join "\n", @{ $c->error } if @{ $c->error };
 370
 371 Or make sure to always return true values from your actions and write
 372 your code like this:
 373
 374     $c->forward('foo') || return;
 375
 376 Another note is that C<< $c->forward >> always returns a scalar because it
 377 actually returns $c->state which operates in a scalar context.
 378 Thus, something like:
 379
 380     return @array;
 381
 382 in an action that is forwarded to is going to return a scalar,
 383 i.e. how many items are in that array, which is probably not what you want.
 384 If you need to return an array then return a reference to it,
 385 or stash it like so:
 386
 387     $c->stash->{array} = \@array;
 388
 389 and access it from the stash.
 390
 391 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 392
 393 =cut
 394
 395 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 396
 397 =head2 $c->detach( $action [, \@arguments ] )
 398
 399 =head2 $c->detach( $class, $method, [, \@arguments ] )
 400
 401 =head2 $c->detach()
 402
 403 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 404 doesn't return to the previous action when processing is finished.
 405
 406 When called with no arguments it escapes the processing chain entirely.
 407
 408 =cut
 409
 410 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 411
 412 =head2 $c->visit( $action [, \@arguments ] )
 413
 414 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 415
 416 =head2 $c->visit( $class, $method, [, \@arguments ] )
 417
 418 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 419
 420 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 421 but does a full dispatch, instead of just calling the new C<$action> /
 422 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 423 you go to are called, just like a new request.
 424
 425 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 426 This means, for example, that C<< $c->action >> methods such as
 427 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 428 L<reverse|Catalyst::Action/reverse> return information for the visited action
 429 when they are invoked within the visited action.  This is different from the
 430 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 431 continues to use the $c->action object from the caller action even when
 432 invoked from the called action.
 433
 434 C<< $c->stash >> is kept unchanged.
 435
 436 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 437 allows you to "wrap" another action, just as it would have been called by
 438 dispatching from a URL, while the analogous
 439 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 440 transfer control to another action as if it had been reached directly from a URL.
 441
 442 =cut
 443
 444 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 445
 446 =head2 $c->go( $action [, \@arguments ] )
 447
 448 =head2 $c->go( $action [, \@captures, \@arguments ] )
 449
 450 =head2 $c->go( $class, $method, [, \@arguments ] )
 451
 452 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 453
 454 The relationship between C<go> and
 455 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 456 the relationship between
 457 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 458 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 459 C<< $c->go >> will perform a full dispatch on the specified action or method,
 460 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 461 C<go> escapes the processing of the current request chain on completion, and
 462 does not return to its caller.
 463
 464 @arguments are arguments to the final destination of $action. @captures are
 465 arguments to the intermediate steps, if any, on the way to the final sub of
 466 $action.
 467
 468 =cut
 469
 470 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 471
 472 =head2 $c->response
 473
 474 =head2 $c->res
 475
 476 Returns the current L<Catalyst::Response> object, see there for details.
 477
 478 =head2 $c->stash
 479
 480 Returns a hashref to the stash, which may be used to store data and pass
 481 it between components during a request. You can also set hash keys by
 482 passing arguments. The stash is automatically sent to the view. The
 483 stash is cleared at the end of a request; it cannot be used for
 484 persistent storage (for this you must use a session; see
 485 L<Catalyst::Plugin::Session> for a complete system integrated with
 486 Catalyst).
 487
 488     $c->stash->{foo} = $bar;
 489     $c->stash( { moose => 'majestic', qux => 0 } );
 490     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 491
 492     # stash is automatically passed to the view for use in a template
 493     $c->forward( 'MyApp::View::TT' );
 494
 495 =cut
 496
 497 around stash => sub {
 498     my $orig = shift;
 499     my $c = shift;
 500     my $stash = $orig->($c);
 501     if (@_) {
 502         my $new_stash = @_ > 1 ? {@_} : $_[0];
 503         croak('stash takes a hash or hashref') unless ref $new_stash;
 504         foreach my $key ( keys %$new_stash ) {
 505           $stash->{$key} = $new_stash->{$key};
 506         }
 507     }
 508
 509     return $stash;
 510 };
 511
 512
 513 =head2 $c->error
 514
 515 =head2 $c->error($error, ...)
 516
 517 =head2 $c->error($arrayref)
 518
 519 Returns an arrayref containing error messages.  If Catalyst encounters an
 520 error while processing a request, it stores the error in $c->error.  This
 521 method should only be used to store fatal error messages.
 522
 523     my @error = @{ $c->error };
 524
 525 Add a new error.
 526
 527     $c->error('Something bad happened');
 528
 529 =cut
 530
 531 sub error {
 532     my $c = shift;
 533     if ( $_[0] ) {
 534         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 535         croak @$error unless ref $c;
 536         push @{ $c->{error} }, @$error;
 537     }
 538     elsif ( defined $_[0] ) { $c->{error} = undef }
 539     return $c->{error} || [];
 540 }
 541
 542
 543 =head2 $c->state
 544
 545 Contains the return value of the last executed action.
 546 Note that << $c->state >> operates in a scalar context which means that all
 547 values it returns are scalar.
 548
 549 =head2 $c->clear_errors
 550
 551 Clear errors.  You probably don't want to clear the errors unless you are
 552 implementing a custom error screen.
 553
 554 This is equivalent to running
 555
 556     $c->error(0);
 557
 558 =cut
 559
 560 sub clear_errors {
 561     my $c = shift;
 562     $c->error(0);
 563 }
 564
 565 sub _comp_search_prefixes {
 566     my $c = shift;
 567     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 568 }
 569
 570 # search components given a name and some prefixes
 571 sub _comp_names_search_prefixes {
 572     my ( $c, $name, @prefixes ) = @_;
 573     my $appclass = ref $c || $c;
 574     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 575     $filter = qr/$filter/; # Compile regex now rather than once per loop
 576
 577     # map the original component name to the sub part that we will search against
 578     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 579         grep { /$filter/ } keys %{ $c->components };
 580
 581     # undef for a name will return all
 582     return keys %eligible if !defined $name;
 583
 584     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 585     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 586
 587     return @result if @result;
 588
 589     # if we were given a regexp to search against, we're done.
 590     return if $name->$_isa('Regexp');
 591
 592     # skip regexp fallback if configured
 593     return
 594         if $appclass->config->{disable_component_resolution_regex_fallback};
 595
 596     # regexp fallback
 597     $query  = qr/$name/i;
 598     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 599
 600     # no results? try against full names
 601     if( !@result ) {
 602         @result = grep { m{$query} } keys %eligible;
 603     }
 604
 605     # don't warn if we didn't find any results, it just might not exist
 606     if( @result ) {
 607         # Disgusting hack to work out correct method name
 608         my $warn_for = lc $prefixes[0];
 609         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 610            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 611            "component resolution is unreliable and unsafe.";
 612         my $short = $result[0];
 613         # remove the component namespace prefix
 614         $short =~ s/.*?(Model|Controller|View):://;
 615         my $shortmess = Carp::shortmess('');
 616         if ($shortmess =~ m#Catalyst/Plugin#) {
 617            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 618               "plugin's config";
 619         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 620            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 621               "component's config";
 622         } else {
 623            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 624               "but if you really wanted to search, pass in a regexp as the argument " .
 625               "like so: \$c->${warn_for}(qr/${name}/)";
 626         }
 627         $c->log->warn( "${msg}$shortmess" );
 628     }
 629
 630     return @result;
 631 }
 632
 633 # Find possible names for a prefix
 634 sub _comp_names {
 635     my ( $c, @prefixes ) = @_;
 636     my $appclass = ref $c || $c;
 637
 638     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 639
 640     my @names = map { s{$filter}{}; $_; }
 641         $c->_comp_names_search_prefixes( undef, @prefixes );
 642
 643     return @names;
 644 }
 645
 646 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 647 sub _filter_component {
 648     my ( $c, $comp, @args ) = @_;
 649
 650     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 651         return $comp->ACCEPT_CONTEXT( $c, @args );
 652     }
 653
 654     return $comp;
 655 }
 656
 657 =head2 COMPONENT ACCESSORS
 658
 659 =head2 $c->controller($name)
 660
 661 Gets a L<Catalyst::Controller> instance by name.
 662
 663     $c->controller('Foo')->do_stuff;
 664
 665 If the name is omitted, will return the controller for the dispatched
 666 action.
 667
 668 If you want to search for controllers, pass in a regexp as the argument.
 669
 670     # find all controllers that start with Foo
 671     my @foo_controllers = $c->controller(qr{^Foo});
 672
 673
 674 =cut
 675
 676 sub controller {
 677     my ( $c, $name, @args ) = @_;
 678
 679     my $appclass = ref($c) || $c;
 680     if( $name ) {
 681         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 682             my $comps = $c->components;
 683             my $check = $appclass."::Controller::".$name;
 684             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 685         }
 686         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 687         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 688         return $c->_filter_component( $result[ 0 ], @args );
 689     }
 690
 691     return $c->component( $c->action->class );
 692 }
 693
 694 =head2 $c->model($name)
 695
 696 Gets a L<Catalyst::Model> instance by name.
 697
 698     $c->model('Foo')->do_stuff;
 699
 700 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 701
 702 If the name is omitted, it will look for
 703  - a model object in $c->stash->{current_model_instance}, then
 704  - a model name in $c->stash->{current_model}, then
 705  - a config setting 'default_model', or
 706  - check if there is only one model, and return it if that's the case.
 707
 708 If you want to search for models, pass in a regexp as the argument.
 709
 710     # find all models that start with Foo
 711     my @foo_models = $c->model(qr{^Foo});
 712
 713 =cut
 714
 715 sub model {
 716     my ( $c, $name, @args ) = @_;
 717     my $appclass = ref($c) || $c;
 718     if( $name ) {
 719         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 720             my $comps = $c->components;
 721             my $check = $appclass."::Model::".$name;
 722             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 723         }
 724         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 725         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 726         return $c->_filter_component( $result[ 0 ], @args );
 727     }
 728
 729     if (ref $c) {
 730         return $c->stash->{current_model_instance}
 731           if $c->stash->{current_model_instance};
 732         return $c->model( $c->stash->{current_model} )
 733           if $c->stash->{current_model};
 734     }
 735     return $c->model( $appclass->config->{default_model} )
 736       if $appclass->config->{default_model};
 737
 738     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 739
 740     if( $rest ) {
 741         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 742         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 743         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 744         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 745         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 746     }
 747
 748     return $c->_filter_component( $comp );
 749 }
 750
 751
 752 =head2 $c->view($name)
 753
 754 Gets a L<Catalyst::View> instance by name.
 755
 756     $c->view('Foo')->do_stuff;
 757
 758 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 759
 760 If the name is omitted, it will look for
 761  - a view object in $c->stash->{current_view_instance}, then
 762  - a view name in $c->stash->{current_view}, then
 763  - a config setting 'default_view', or
 764  - check if there is only one view, and return it if that's the case.
 765
 766 If you want to search for views, pass in a regexp as the argument.
 767
 768     # find all views that start with Foo
 769     my @foo_views = $c->view(qr{^Foo});
 770
 771 =cut
 772
 773 sub view {
 774     my ( $c, $name, @args ) = @_;
 775
 776     my $appclass = ref($c) || $c;
 777     if( $name ) {
 778         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 779             my $comps = $c->components;
 780             my $check = $appclass."::View::".$name;
 781             if( exists $comps->{$check} ) {
 782                 return $c->_filter_component( $comps->{$check}, @args );
 783             }
 784             else {
 785                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 786             }
 787         }
 788         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 789         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 790         return $c->_filter_component( $result[ 0 ], @args );
 791     }
 792
 793     if (ref $c) {
 794         return $c->stash->{current_view_instance}
 795           if $c->stash->{current_view_instance};
 796         return $c->view( $c->stash->{current_view} )
 797           if $c->stash->{current_view};
 798     }
 799     return $c->view( $appclass->config->{default_view} )
 800       if $appclass->config->{default_view};
 801
 802     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 803
 804     if( $rest ) {
 805         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 806         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 807         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 808         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 809         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 810     }
 811
 812     return $c->_filter_component( $comp );
 813 }
 814
 815 =head2 $c->controllers
 816
 817 Returns the available names which can be passed to $c->controller
 818
 819 =cut
 820
 821 sub controllers {
 822     my ( $c ) = @_;
 823     return $c->_comp_names(qw/Controller C/);
 824 }
 825
 826 =head2 $c->models
 827
 828 Returns the available names which can be passed to $c->model
 829
 830 =cut
 831
 832 sub models {
 833     my ( $c ) = @_;
 834     return $c->_comp_names(qw/Model M/);
 835 }
 836
 837
 838 =head2 $c->views
 839
 840 Returns the available names which can be passed to $c->view
 841
 842 =cut
 843
 844 sub views {
 845     my ( $c ) = @_;
 846     return $c->_comp_names(qw/View V/);
 847 }
 848
 849 =head2 $c->comp($name)
 850
 851 =head2 $c->component($name)
 852
 853 Gets a component object by name. This method is not recommended,
 854 unless you want to get a specific component by full
 855 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 856 should be used instead.
 857
 858 If C<$name> is a regexp, a list of components matched against the full
 859 component name will be returned.
 860
 861 If Catalyst can't find a component by name, it will fallback to regex
 862 matching by default. To disable this behaviour set
 863 disable_component_resolution_regex_fallback to a true value.
 864
 865     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 866
 867 =cut
 868
 869 sub component {
 870     my ( $c, $name, @args ) = @_;
 871
 872     if( $name ) {
 873         my $comps = $c->components;
 874
 875         if( !ref $name ) {
 876             # is it the exact name?
 877             return $c->_filter_component( $comps->{ $name }, @args )
 878                        if exists $comps->{ $name };
 879
 880             # perhaps we just omitted "MyApp"?
 881             my $composed = ( ref $c || $c ) . "::${name}";
 882             return $c->_filter_component( $comps->{ $composed }, @args )
 883                        if exists $comps->{ $composed };
 884
 885             # search all of the models, views and controllers
 886             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 887             return $c->_filter_component( $comp, @args ) if $comp;
 888         }
 889
 890         return
 891             if $c->config->{disable_component_resolution_regex_fallback};
 892
 893         # This is here so $c->comp( '::M::' ) works
 894         my $query = ref $name ? $name : qr{$name}i;
 895
 896         my @result = grep { m{$query} } keys %{ $c->components };
 897         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 898
 899         if( $result[ 0 ] ) {
 900             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 901             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 902             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 903             return $c->_filter_component( $result[ 0 ], @args );
 904         }
 905
 906         # I would expect to return an empty list here, but that breaks back-compat
 907     }
 908
 909     # fallback
 910     return sort keys %{ $c->components };
 911 }
 912
 913 =head2 CLASS DATA AND HELPER CLASSES
 914
 915 =head2 $c->config
 916
 917 Returns or takes a hashref containing the application's configuration.
 918
 919     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 920
 921 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 922 like C<myapp.conf> in your applications home directory. See
 923 L<Catalyst::Plugin::ConfigLoader>.
 924
 925 =head3 Cascading configuration
 926
 927 The config method is present on all Catalyst components, and configuration
 928 will be merged when an application is started. Configuration loaded with
 929 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 930 followed by configuration in your top level C<MyApp> class. These two
 931 configurations are merged, and then configuration data whose hash key matches a
 932 component name is merged with configuration for that component.
 933
 934 The configuration for a component is then passed to the C<new> method when a
 935 component is constructed.
 936
 937 For example:
 938
 939     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 940     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 941
 942 will mean that C<MyApp::Model::Foo> receives the following data when
 943 constructed:
 944
 945     MyApp::Model::Foo->new({
 946         bar => 'baz',
 947         quux => 'frob',
 948         overrides => 'me',
 949     });
 950
 951 It's common practice to use a Moose attribute
 952 on the receiving component to access the config value.
 953
 954     package MyApp::Model::Foo;
 955
 956     use Moose;
 957
 958     # this attr will receive 'baz' at construction time
 959     has 'bar' => (
 960         is  => 'rw',
 961         isa => 'Str',
 962     );
 963
 964 You can then get the value 'baz' by calling $c->model('Foo')->bar
 965 (or $self->bar inside code in the model).
 966
 967 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 968 as a way of reading config within your code, as this B<will not> give you the
 969 correctly merged config back. You B<MUST> take the config values supplied to
 970 the constructor and use those instead.
 971
 972 =cut
 973
 974 around config => sub {
 975     my $orig = shift;
 976     my $c = shift;
 977
 978     croak('Setting config after setup has been run is not allowed.')
 979         if ( @_ and $c->setup_finished );
 980
 981     $c->$orig(@_);
 982 };
 983
 984 =head2 $c->log
 985
 986 Returns the logging object instance. Unless it is already set, Catalyst
 987 sets this up with a L<Catalyst::Log> object. To use your own log class,
 988 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 989 C<< __PACKAGE__->setup >>.
 990
 991  __PACKAGE__->log( MyLogger->new );
 992  __PACKAGE__->setup;
 993
 994 And later:
 995
 996     $c->log->info( 'Now logging with my own logger!' );
 997
 998 Your log class should implement the methods described in
 999 L<Catalyst::Log>.
1000
1001
1002 =head2 $c->debug
1003
1004 Returns 1 if debug mode is enabled, 0 otherwise.
1005
1006 You can enable debug mode in several ways:
1007
1008 =over
1009
1010 =item By calling myapp_server.pl with the -d flag
1011
1012 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1013
1014 =item The -Debug option in your MyApp.pm
1015
1016 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1017
1018 =back
1019
1020 The first three also set the log level to 'debug'.
1021
1022 Calling C<< $c->debug(1) >> has no effect.
1023
1024 =cut
1025
1026 sub debug { 0 }
1027
1028 =head2 $c->dispatcher
1029
1030 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1031
1032 =head2 $c->engine
1033
1034 Returns the engine instance. See L<Catalyst::Engine>.
1035
1036
1037 =head2 UTILITY METHODS
1038
1039 =head2 $c->path_to(@path)
1040
1041 Merges C<@path> with C<< $c->config->{home} >> and returns a
1042 L<Path::Class::Dir> object. Note you can usually use this object as
1043 a filename, but sometimes you will have to explicitly stringify it
1044 yourself by calling the C<< ->stringify >> method.
1045
1046 For example:
1047
1048     $c->path_to( 'db', 'sqlite.db' );
1049
1050 =cut
1051
1052 sub path_to {
1053     my ( $c, @path ) = @_;
1054     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1055     if ( -d $path ) { return $path }
1056     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1057 }
1058
1059 sub plugin {
1060     my ( $class, $name, $plugin, @args ) = @_;
1061
1062     # See block comment in t/unit_core_plugin.t
1063     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1064
1065     $class->_register_plugin( $plugin, 1 );
1066
1067     eval { $plugin->import };
1068     $class->mk_classdata($name);
1069     my $obj;
1070     eval { $obj = $plugin->new(@args) };
1071
1072     if ($@) {
1073         Catalyst::Exception->throw( message =>
1074               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1075     }
1076
1077     $class->$name($obj);
1078     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1079       if $class->debug;
1080 }
1081
1082 =head2 MyApp->setup
1083
1084 Initializes the dispatcher and engine, loads any plugins, and loads the
1085 model, view, and controller components. You may also specify an array
1086 of plugins to load here, if you choose to not load them in the C<use
1087 Catalyst> line.
1088
1089     MyApp->setup;
1090     MyApp->setup( qw/-Debug/ );
1091
1092 B<Note:> You B<should not> wrap this method with method modifiers
1093 or bad things will happen - wrap the C<setup_finalize> method instead.
1094
1095 =cut
1096
1097 sub setup {
1098     my ( $class, @arguments ) = @_;
1099     croak('Running setup more than once')
1100         if ( $class->setup_finished );
1101
1102     unless ( $class->isa('Catalyst') ) {
1103
1104         Catalyst::Exception->throw(
1105             message => qq/'$class' does not inherit from Catalyst/ );
1106     }
1107
1108     if ( $class->arguments ) {
1109         @arguments = ( @arguments, @{ $class->arguments } );
1110     }
1111
1112     # Process options
1113     my $flags = {};
1114
1115     foreach (@arguments) {
1116
1117         if (/^-Debug$/) {
1118             $flags->{log} =
1119               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1120         }
1121         elsif (/^-(\w+)=?(.*)$/) {
1122             $flags->{ lc $1 } = $2;
1123         }
1124         else {
1125             push @{ $flags->{plugins} }, $_;
1126         }
1127     }
1128
1129     $class->setup_home( delete $flags->{home} );
1130
1131     $class->setup_log( delete $flags->{log} );
1132     $class->setup_plugins( delete $flags->{plugins} );
1133
1134     # Call plugins setup, this is stupid and evil.
1135     # Also screws C3 badly on 5.10, hack to avoid.
1136     {
1137         no warnings qw/redefine/;
1138         local *setup = sub { };
1139         $class->setup unless $Catalyst::__AM_RESTARTING;
1140     }
1141
1142     $class->setup_middleware();
1143     $class->setup_data_handlers();
1144     $class->setup_dispatcher( delete $flags->{dispatcher} );
1145     if (my $engine = delete $flags->{engine}) {
1146         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1147     }
1148     $class->setup_engine();
1149     $class->setup_stats( delete $flags->{stats} );
1150
1151     for my $flag ( sort keys %{$flags} ) {
1152
1153         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1154             &$code( $class, delete $flags->{$flag} );
1155         }
1156         else {
1157             $class->log->warn(qq/Unknown flag "$flag"/);
1158         }
1159     }
1160
1161     eval { require Catalyst::Devel; };
1162     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1163         $class->log->warn(<<"EOF");
1164 You are running an old script!
1165
1166   Please update by running (this will overwrite existing files):
1167     catalyst.pl -force -scripts $class
1168
1169   or (this will not overwrite existing files):
1170     catalyst.pl -scripts $class
1171
1172 EOF
1173     }
1174
1175     # Initialize our data structure
1176     $class->components( {} );
1177
1178     $class->setup_components;
1179
1180     if ( $class->debug ) {
1181         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1182
1183         if (@plugins) {
1184             my $column_width = Catalyst::Utils::term_width() - 6;
1185             my $t = Text::SimpleTable->new($column_width);
1186             $t->row($_) for @plugins;
1187             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1188         }
1189
1190         my @middleware = map {
1191           ref $_ eq 'CODE' ?
1192             "Inline Coderef" :
1193               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1194                 || '')  } $class->registered_middlewares;
1195
1196         if (@middleware) {
1197             my $column_width = Catalyst::Utils::term_width() - 6;
1198             my $t = Text::SimpleTable->new($column_width);
1199             $t->row($_) for @middleware;
1200             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1201         }
1202
1203         my %dh = $class->registered_data_handlers;
1204         if (my @data_handlers = keys %dh) {
1205             my $column_width = Catalyst::Utils::term_width() - 6;
1206             my $t = Text::SimpleTable->new($column_width);
1207             $t->row($_) for @data_handlers;
1208             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1209         }
1210
1211         my $dispatcher = $class->dispatcher;
1212         my $engine     = $class->engine;
1213         my $home       = $class->config->{home};
1214
1215         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1216         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1217
1218         $home
1219           ? ( -d $home )
1220           ? $class->log->debug(qq/Found home "$home"/)
1221           : $class->log->debug(qq/Home "$home" doesn't exist/)
1222           : $class->log->debug(q/Couldn't find home/);
1223
1224         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1225         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1226         for my $comp ( sort keys %{ $class->components } ) {
1227             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1228             $t->row( $comp, $type );
1229         }
1230         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1231           if ( keys %{ $class->components } );
1232     }
1233
1234     # Add our self to components, since we are also a component
1235     if( $class->isa('Catalyst::Controller') ){
1236       $class->components->{$class} = $class;
1237     }
1238
1239     $class->setup_actions;
1240
1241     if ( $class->debug ) {
1242         my $name = $class->config->{name} || 'Application';
1243         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1244     }
1245
1246     if ($class->config->{case_sensitive}) {
1247         $class->log->warn($class . "->config->{case_sensitive} is set.");
1248         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1249     }
1250
1251     $class->setup_finalize;
1252     # Should be the last thing we do so that user things hooking
1253     # setup_finalize can log..
1254     $class->log->_flush() if $class->log->can('_flush');
1255     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1256 }
1257
1258 =head2 $app->setup_finalize
1259
1260 A hook to attach modifiers to. This method does not do anything except set the
1261 C<setup_finished> accessor.
1262
1263 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1264
1265 Example:
1266
1267     after setup_finalize => sub {
1268         my $app = shift;
1269
1270         ## do stuff here..
1271     };
1272
1273 =cut
1274
1275 sub setup_finalize {
1276     my ($class) = @_;
1277     $class->setup_finished(1);
1278 }
1279
1280 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1281
1282 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1283
1284 Constructs an absolute L<URI> object based on the application root, the
1285 provided path, and the additional arguments and query parameters provided.
1286 When used as a string, provides a textual URI.  If you need more flexibility
1287 than this (i.e. the option to provide relative URIs etc.) see
1288 L<Catalyst::Plugin::SmartURI>.
1289
1290 If no arguments are provided, the URI for the current action is returned.
1291 To return the current action and also provide @args, use
1292 C<< $c->uri_for( $c->action, @args ) >>.
1293
1294 If the first argument is a string, it is taken as a public URI path relative
1295 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1296 relative to the application root (if it does). It is then merged with
1297 C<< $c->request->base >>; any C<@args> are appended as additional path
1298 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1299
1300 If the first argument is a L<Catalyst::Action> it represents an action which
1301 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1302 optional C<\@captures> argument (an arrayref) allows passing the captured
1303 variables that are needed to fill in the paths of Chained and Regex actions;
1304 once the path is resolved, C<uri_for> continues as though a path was
1305 provided, appending any arguments or parameters and creating an absolute
1306 URI.
1307
1308 The captures for the current request can be found in
1309 C<< $c->request->captures >>, and actions can be resolved using
1310 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1311 path, use C<< $c->uri_for_action >> instead.
1312
1313   # Equivalent to $c->req->uri
1314   $c->uri_for($c->action, $c->req->captures,
1315       @{ $c->req->args }, $c->req->params);
1316
1317   # For the Foo action in the Bar controller
1318   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1319
1320   # Path to a static resource
1321   $c->uri_for('/static/images/logo.png');
1322
1323 =cut
1324
1325 sub uri_for {
1326     my ( $c, $path, @args ) = @_;
1327
1328     if ( $path->$_isa('Catalyst::Controller') ) {
1329         $path = $path->path_prefix;
1330         $path =~ s{/+\z}{};
1331         $path .= '/';
1332     }
1333
1334     undef($path) if (defined $path && $path eq '');
1335
1336     my $params =
1337       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1338
1339     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1340     foreach my $arg (@args) {
1341         utf8::encode($arg) if utf8::is_utf8($arg);
1342         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1343     }
1344
1345     if ( $path->$_isa('Catalyst::Action') ) { # action object
1346         s|/|%2F|g for @args;
1347         my $captures = [ map { s|/|%2F|g; $_; }
1348                         ( scalar @args && ref $args[0] eq 'ARRAY'
1349                          ? @{ shift(@args) }
1350                          : ()) ];
1351
1352         foreach my $capture (@$captures) {
1353             utf8::encode($capture) if utf8::is_utf8($capture);
1354             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1355         }
1356
1357         my $action = $path;
1358         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1359         if( !@args && $action->number_of_args ) {
1360             my $expanded_action = $c->dispatcher->expand_action( $action );
1361
1362             my $num_captures = $expanded_action->number_of_captures;
1363             unshift @args, splice @$captures, $num_captures;
1364         }
1365
1366        $path = $c->dispatcher->uri_for_action($action, $captures);
1367         if (not defined $path) {
1368             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1369                 if $c->debug;
1370             return undef;
1371         }
1372         $path = '/' if $path eq '';
1373     }
1374
1375     unshift(@args, $path);
1376
1377     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1378         my $namespace = $c->namespace;
1379         if (defined $path) { # cheesy hack to handle path '../foo'
1380            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1381         }
1382         unshift(@args, $namespace || '');
1383     }
1384
1385     # join args with '/', or a blank string
1386     my $args = join('/', grep { defined($_) } @args);
1387     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1388     $args =~ s!^/+!!;
1389
1390     my ($base, $class) = ('/', 'URI::_generic');
1391     if(blessed($c)) {
1392       $base = $c->req->base;
1393       $class = ref($base);
1394       $base =~ s{(?<!/)$}{/};
1395     }
1396
1397     my $query = '';
1398
1399     if (my @keys = keys %$params) {
1400       # somewhat lifted from URI::_query's query_form
1401       $query = '?'.join('&', map {
1402           my $val = $params->{$_};
1403           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1404           s/ /+/g;
1405           my $key = $_;
1406           $val = '' unless defined $val;
1407           (map {
1408               my $param = "$_";
1409               utf8::encode( $param ) if utf8::is_utf8($param);
1410               # using the URI::Escape pattern here so utf8 chars survive
1411               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1412               $param =~ s/ /+/g;
1413               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1414       } @keys);
1415     }
1416
1417     my $res = bless(\"${base}${args}${query}", $class);
1418     $res;
1419 }
1420
1421 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1422
1423 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1424
1425 =over
1426
1427 =item $path
1428
1429 A private path to the Catalyst action you want to create a URI for.
1430
1431 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1432 >> and passing the resulting C<$action> and the remaining arguments to C<<
1433 $c->uri_for >>.
1434
1435 You can also pass in a Catalyst::Action object, in which case it is passed to
1436 C<< $c->uri_for >>.
1437
1438 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1439
1440 For example, if the action looks like:
1441
1442  package MyApp::Controller::Users;
1443
1444  sub lst : Path('the-list') {}
1445
1446 You can use:
1447
1448  $c->uri_for_action('/users/lst')
1449
1450 and it will create the URI /users/the-list.
1451
1452 =item \@captures_and_args?
1453
1454 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1455 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1456 to interpolate all the parameters in the URI.
1457
1458 =item @args?
1459
1460 Optional list of extra arguments - can be supplied in the
1461 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1462 code.
1463
1464 Your action can have zero, a fixed or a variable number of args (e.g.
1465 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1466
1467 =item \%query_values?
1468
1469 Optional array reference of query parameters to append. E.g.
1470
1471   { foo => 'bar' }
1472
1473 will generate
1474
1475   /rest/of/your/uri?foo=bar
1476
1477 =back
1478
1479 =cut
1480
1481 sub uri_for_action {
1482     my ( $c, $path, @args ) = @_;
1483     my $action = blessed($path)
1484       ? $path
1485       : $c->dispatcher->get_action_by_path($path);
1486     unless (defined $action) {
1487       croak "Can't find action for path '$path'";
1488     }
1489     return $c->uri_for( $action, @args );
1490 }
1491
1492 =head2 $c->welcome_message
1493
1494 Returns the Catalyst welcome HTML page.
1495
1496 =cut
1497
1498 sub welcome_message {
1499     my $c      = shift;
1500     my $name   = $c->config->{name};
1501     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1502     my $prefix = Catalyst::Utils::appprefix( ref $c );
1503     $c->response->content_type('text/html; charset=utf-8');
1504     return <<"EOF";
1505 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1506     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1507 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1508     <head>
1509     <meta http-equiv="Content-Language" content="en" />
1510     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1511         <title>$name on Catalyst $VERSION</title>
1512         <style type="text/css">
1513             body {
1514                 color: #000;
1515                 background-color: #eee;
1516             }
1517             div#content {
1518                 width: 640px;
1519                 margin-left: auto;
1520                 margin-right: auto;
1521                 margin-top: 10px;
1522                 margin-bottom: 10px;
1523                 text-align: left;
1524                 background-color: #ccc;
1525                 border: 1px solid #aaa;
1526             }
1527             p, h1, h2 {
1528                 margin-left: 20px;
1529                 margin-right: 20px;
1530                 font-family: verdana, tahoma, sans-serif;
1531             }
1532             a {
1533                 font-family: verdana, tahoma, sans-serif;
1534             }
1535             :link, :visited {
1536                     text-decoration: none;
1537                     color: #b00;
1538                     border-bottom: 1px dotted #bbb;
1539             }
1540             :link:hover, :visited:hover {
1541                     color: #555;
1542             }
1543             div#topbar {
1544                 margin: 0px;
1545             }
1546             pre {
1547                 margin: 10px;
1548                 padding: 8px;
1549             }
1550             div#answers {
1551                 padding: 8px;
1552                 margin: 10px;
1553                 background-color: #fff;
1554                 border: 1px solid #aaa;
1555             }
1556             h1 {
1557                 font-size: 0.9em;
1558                 font-weight: normal;
1559                 text-align: center;
1560             }
1561             h2 {
1562                 font-size: 1.0em;
1563             }
1564             p {
1565                 font-size: 0.9em;
1566             }
1567             p img {
1568                 float: right;
1569                 margin-left: 10px;
1570             }
1571             span#appname {
1572                 font-weight: bold;
1573                 font-size: 1.6em;
1574             }
1575         </style>
1576     </head>
1577     <body>
1578         <div id="content">
1579             <div id="topbar">
1580                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1581                     $VERSION</h1>
1582              </div>
1583              <div id="answers">
1584                  <p>
1585                  <img src="$logo" alt="Catalyst Logo" />
1586                  </p>
1587                  <p>Welcome to the  world of Catalyst.
1588                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1589                     framework will make web development something you had
1590                     never expected it to be: Fun, rewarding, and quick.</p>
1591                  <h2>What to do now?</h2>
1592                  <p>That really depends  on what <b>you</b> want to do.
1593                     We do, however, provide you with a few starting points.</p>
1594                  <p>If you want to jump right into web development with Catalyst
1595                     you might want to start with a tutorial.</p>
1596 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1597 </pre>
1598 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1599 <pre>
1600 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1601 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1602 </code></pre>
1603                  <h2>What to do next?</h2>
1604                  <p>Next it's time to write an actual application. Use the
1605                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1606                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1607                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1608                     they can save you a lot of work.</p>
1609                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1610                     <p>Also, be sure to check out the vast and growing
1611                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1612                     you are likely to find what you need there.
1613                     </p>
1614
1615                  <h2>Need help?</h2>
1616                  <p>Catalyst has a very active community. Here are the main places to
1617                     get in touch with us.</p>
1618                  <ul>
1619                      <li>
1620                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1621                      </li>
1622                      <li>
1623                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1624                      </li>
1625                      <li>
1626                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1627                      </li>
1628                  </ul>
1629                  <h2>In conclusion</h2>
1630                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1631                     as we enjoyed making it. Please contact us if you have ideas
1632                     for improvement or other feedback.</p>
1633              </div>
1634          </div>
1635     </body>
1636 </html>
1637 EOF
1638 }
1639
1640 =head2 run_options
1641
1642 Contains a hash of options passed from the application script, including
1643 the original ARGV the script received, the processed values from that
1644 ARGV and any extra arguments to the script which were not processed.
1645
1646 This can be used to add custom options to your application's scripts
1647 and setup your application differently depending on the values of these
1648 options.
1649
1650 =head1 INTERNAL METHODS
1651
1652 These methods are not meant to be used by end users.
1653
1654 =head2 $c->components
1655
1656 Returns a hash of components.
1657
1658 =head2 $c->context_class
1659
1660 Returns or sets the context class.
1661
1662 =head2 $c->counter
1663
1664 Returns a hashref containing coderefs and execution counts (needed for
1665 deep recursion detection).
1666
1667 =head2 $c->depth
1668
1669 Returns the number of actions on the current internal execution stack.
1670
1671 =head2 $c->dispatch
1672
1673 Dispatches a request to actions.
1674
1675 =cut
1676
1677 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1678
1679 =head2 $c->dispatcher_class
1680
1681 Returns or sets the dispatcher class.
1682
1683 =head2 $c->dump_these
1684
1685 Returns a list of 2-element array references (name, structure) pairs
1686 that will be dumped on the error page in debug mode.
1687
1688 =cut
1689
1690 sub dump_these {
1691     my $c = shift;
1692     [ Request => $c->req ],
1693     [ Response => $c->res ],
1694     [ Stash => $c->stash ],
1695     [ Config => $c->config ];
1696 }
1697
1698 =head2 $c->engine_class
1699
1700 Returns or sets the engine class.
1701
1702 =head2 $c->execute( $class, $coderef )
1703
1704 Execute a coderef in given class and catch exceptions. Errors are available
1705 via $c->error.
1706
1707 =cut
1708
1709 sub execute {
1710     my ( $c, $class, $code ) = @_;
1711     $class = $c->component($class) || $class;
1712     $c->state(0);
1713
1714     if ( $c->depth >= $RECURSION ) {
1715         my $action = $code->reverse();
1716         $action = "/$action" unless $action =~ /->/;
1717         my $error = qq/Deep recursion detected calling "${action}"/;
1718         $c->log->error($error);
1719         $c->error($error);
1720         $c->state(0);
1721         return $c->state;
1722     }
1723
1724     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1725
1726     push( @{ $c->stack }, $code );
1727
1728     no warnings 'recursion';
1729     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1730     #      I have no idea how, ergo $ret (which appears to fix the issue)
1731     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1732
1733     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1734
1735     my $last = pop( @{ $c->stack } );
1736
1737     if ( my $error = $@ ) {
1738         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1739             $error->rethrow if $c->depth > 1;
1740         }
1741         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1742             $error->rethrow if $c->depth > 0;
1743         }
1744         else {
1745             unless ( ref $error ) {
1746                 no warnings 'uninitialized';
1747                 chomp $error;
1748                 my $class = $last->class;
1749                 my $name  = $last->name;
1750                 $error = qq/Caught exception in $class->$name "$error"/;
1751             }
1752             $c->error($error);
1753         }
1754         $c->state(0);
1755     }
1756     return $c->state;
1757 }
1758
1759 sub _stats_start_execute {
1760     my ( $c, $code ) = @_;
1761     my $appclass = ref($c) || $c;
1762     return if ( ( $code->name =~ /^_.*/ )
1763         && ( !$appclass->config->{show_internal_actions} ) );
1764
1765     my $action_name = $code->reverse();
1766     $c->counter->{$action_name}++;
1767
1768     my $action = $action_name;
1769     $action = "/$action" unless $action =~ /->/;
1770
1771     # determine if the call was the result of a forward
1772     # this is done by walking up the call stack and looking for a calling
1773     # sub of Catalyst::forward before the eval
1774     my $callsub = q{};
1775     for my $index ( 2 .. 11 ) {
1776         last
1777         if ( ( caller($index) )[0] eq 'Catalyst'
1778             && ( caller($index) )[3] eq '(eval)' );
1779
1780         if ( ( caller($index) )[3] =~ /forward$/ ) {
1781             $callsub = ( caller($index) )[3];
1782             $action  = "-> $action";
1783             last;
1784         }
1785     }
1786
1787     my $uid = $action_name . $c->counter->{$action_name};
1788
1789     # is this a root-level call or a forwarded call?
1790     if ( $callsub =~ /forward$/ ) {
1791         my $parent = $c->stack->[-1];
1792
1793         # forward, locate the caller
1794         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1795             $c->stats->profile(
1796                 begin  => $action,
1797                 parent => "$parent" . $c->counter->{"$parent"},
1798                 uid    => $uid,
1799             );
1800         }
1801         else {
1802
1803             # forward with no caller may come from a plugin
1804             $c->stats->profile(
1805                 begin => $action,
1806                 uid   => $uid,
1807             );
1808         }
1809     }
1810     else {
1811
1812         # root-level call
1813         $c->stats->profile(
1814             begin => $action,
1815             uid   => $uid,
1816         );
1817     }
1818     return $action;
1819
1820 }
1821
1822 sub _stats_finish_execute {
1823     my ( $c, $info ) = @_;
1824     $c->stats->profile( end => $info );
1825 }
1826
1827 =head2 $c->finalize
1828
1829 Finalizes the request.
1830
1831 =cut
1832
1833 sub finalize {
1834     my $c = shift;
1835
1836     for my $error ( @{ $c->error } ) {
1837         $c->log->error($error);
1838     }
1839
1840     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1841     # stuff like cometd and websockets
1842
1843     if($c->request->_has_io_fh) {
1844       $c->log_response;
1845       return;
1846     }
1847
1848     # Allow engine to handle finalize flow (for POE)
1849     my $engine = $c->engine;
1850     if ( my $code = $engine->can('finalize') ) {
1851         $engine->$code($c);
1852     }
1853     else {
1854
1855         $c->finalize_uploads;
1856
1857         # Error
1858         if ( $#{ $c->error } >= 0 ) {
1859             $c->finalize_error;
1860         }
1861
1862         $c->finalize_headers unless $c->response->finalized_headers;
1863
1864         $c->finalize_body;
1865     }
1866
1867     $c->log_response;
1868
1869     if ($c->use_stats) {
1870         my $elapsed = $c->stats->elapsed;
1871         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1872         $c->log->info(
1873             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1874     }
1875
1876     return $c->response->status;
1877 }
1878
1879 =head2 $c->finalize_body
1880
1881 Finalizes body.
1882
1883 =cut
1884
1885 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1886
1887 =head2 $c->finalize_cookies
1888
1889 Finalizes cookies.
1890
1891 =cut
1892
1893 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1894
1895 =head2 $c->finalize_error
1896
1897 Finalizes error.
1898
1899 =cut
1900
1901 sub finalize_error {
1902     my $c = shift;
1903     if($#{$c->error} > 0) {
1904         $c->engine->finalize_error( $c, @_ );
1905     } else {
1906         my ($error) = @{$c->error};
1907         if(
1908           blessed $error &&
1909           ($error->can('as_psgi') || $error->can('code'))
1910         ) {
1911             # In the case where the error 'knows what it wants', becauses its PSGI
1912             # aware, just rethow and let middleware catch it
1913             $error->can('rethrow') ? $error->rethrow : croak $error;
1914             croak $error;
1915         } else {
1916             $c->engine->finalize_error( $c, @_ )
1917         }
1918     }
1919 }
1920
1921 =head2 $c->finalize_headers
1922
1923 Finalizes headers.
1924
1925 =cut
1926
1927 sub finalize_headers {
1928     my $c = shift;
1929
1930     my $response = $c->response; #accessor calls can add up?
1931
1932     # Check if we already finalized headers
1933     return if $response->finalized_headers;
1934
1935     # Handle redirects
1936     if ( my $location = $response->redirect ) {
1937         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1938         $response->header( Location => $location );
1939     }
1940
1941     # Remove incorrectly added body and content related meta data when returning
1942     # an information response, or a response the is required to not include a body
1943
1944     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1945         if($response->has_body) {
1946           $c->log->debug('Removing body for informational or no content http responses');
1947           $response->body('');
1948           $response->headers->remove_header("Content-Length");
1949         }
1950     }
1951
1952     $c->finalize_cookies;
1953
1954     $c->response->finalize_headers();
1955
1956     # Done
1957     $response->finalized_headers(1);
1958 }
1959
1960 =head2 $c->finalize_output
1961
1962 An alias for finalize_body.
1963
1964 =head2 $c->finalize_read
1965
1966 Finalizes the input after reading is complete.
1967
1968 =cut
1969
1970 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1971
1972 =head2 $c->finalize_uploads
1973
1974 Finalizes uploads. Cleans up any temporary files.
1975
1976 =cut
1977
1978 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1979
1980 =head2 $c->get_action( $action, $namespace )
1981
1982 Gets an action in a given namespace.
1983
1984 =cut
1985
1986 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1987
1988 =head2 $c->get_actions( $action, $namespace )
1989
1990 Gets all actions of a given name in a namespace and all parent
1991 namespaces.
1992
1993 =cut
1994
1995 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1996
1997 =head2 $app->handle_request( @arguments )
1998
1999 Called to handle each HTTP request.
2000
2001 =cut
2002
2003 sub handle_request {
2004     my ( $class, @arguments ) = @_;
2005
2006     # Always expect worst case!
2007     my $status = -1;
2008     try {
2009         if ($class->debug) {
2010             my $secs = time - $START || 1;
2011             my $av = sprintf '%.3f', $COUNT / $secs;
2012             my $time = localtime time;
2013             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2014         }
2015
2016         my $c = $class->prepare(@arguments);
2017         $c->dispatch;
2018         $status = $c->finalize;
2019     } catch {
2020         chomp(my $error = $_);
2021         $class->log->error(qq/Caught exception in engine "$error"/);
2022         #rethow if this can be handled by middleware
2023         if(blessed $error && ($error->can('as_psgi') || $error->can('code'))) {
2024             $error->can('rethrow') ? $error->rethrow : croak $error;
2025         }
2026     };
2027
2028     $COUNT++;
2029
2030     if(my $coderef = $class->log->can('_flush')){
2031         $class->log->$coderef();
2032     }
2033     return $status;
2034 }
2035
2036 =head2 $class->prepare( @arguments )
2037
2038 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2039 etc.).
2040
2041 =cut
2042
2043 has _uploadtmp => (
2044     is => 'ro',
2045     predicate => '_has_uploadtmp',
2046 );
2047
2048 sub prepare {
2049     my ( $class, @arguments ) = @_;
2050
2051     # XXX
2052     # After the app/ctxt split, this should become an attribute based on something passed
2053     # into the application.
2054     $class->context_class( ref $class || $class ) unless $class->context_class;
2055
2056     my $uploadtmp = $class->config->{uploadtmp};
2057     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2058
2059     $c->response->_context($c);
2060
2061     #surely this is not the most efficient way to do things...
2062     $c->stats($class->stats_class->new)->enable($c->use_stats);
2063     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2064         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2065     }
2066
2067     try {
2068         # Allow engine to direct the prepare flow (for POE)
2069         if ( my $prepare = $c->engine->can('prepare') ) {
2070             $c->engine->$prepare( $c, @arguments );
2071         }
2072         else {
2073             $c->prepare_request(@arguments);
2074             $c->prepare_connection;
2075             $c->prepare_query_parameters;
2076             $c->prepare_headers; # Just hooks, no longer needed - they just
2077             $c->prepare_cookies; # cause the lazy attribute on req to build
2078             $c->prepare_path;
2079
2080             # Prepare the body for reading, either by prepare_body
2081             # or the user, if they are using $c->read
2082             $c->prepare_read;
2083
2084             # Parse the body unless the user wants it on-demand
2085             unless ( ref($c)->config->{parse_on_demand} ) {
2086                 $c->prepare_body;
2087             }
2088         }
2089         $c->prepare_action;
2090     }
2091     # VERY ugly and probably shouldn't rely on ->finalize actually working
2092     catch {
2093         # failed prepare is always due to an invalid request, right?
2094         $c->response->status(400);
2095         $c->response->content_type('text/plain');
2096         $c->response->body('Bad Request');
2097         # Note we call finalize and then die here, which escapes
2098         # finalize being called in the enclosing block..
2099         # It in fact couldn't be called, as we don't return $c..
2100         # This is a mess - but I'm unsure you can fix this without
2101         # breaking compat for people doing crazy things (we should set
2102         # the 400 and just return the ctx here IMO, letting finalize get called
2103         # above...
2104         $c->finalize;
2105         die $_;
2106     };
2107
2108     $c->log_request;
2109
2110     return $c;
2111 }
2112
2113 =head2 $c->prepare_action
2114
2115 Prepares action. See L<Catalyst::Dispatcher>.
2116
2117 =cut
2118
2119 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2120
2121 =head2 $c->prepare_body
2122
2123 Prepares message body.
2124
2125 =cut
2126
2127 sub prepare_body {
2128     my $c = shift;
2129
2130     return if $c->request->_has_body;
2131
2132     # Initialize on-demand data
2133     $c->engine->prepare_body( $c, @_ );
2134     $c->prepare_parameters;
2135     $c->prepare_uploads;
2136 }
2137
2138 =head2 $c->prepare_body_chunk( $chunk )
2139
2140 Prepares a chunk of data before sending it to L<HTTP::Body>.
2141
2142 See L<Catalyst::Engine>.
2143
2144 =cut
2145
2146 sub prepare_body_chunk {
2147     my $c = shift;
2148     $c->engine->prepare_body_chunk( $c, @_ );
2149 }
2150
2151 =head2 $c->prepare_body_parameters
2152
2153 Prepares body parameters.
2154
2155 =cut
2156
2157 sub prepare_body_parameters {
2158     my $c = shift;
2159     $c->engine->prepare_body_parameters( $c, @_ );
2160 }
2161
2162 =head2 $c->prepare_connection
2163
2164 Prepares connection.
2165
2166 =cut
2167
2168 sub prepare_connection {
2169     my $c = shift;
2170     # XXX - This is called on the engine (not the request) to maintain
2171     #       Engine::PSGI back compat.
2172     $c->engine->prepare_connection($c);
2173 }
2174
2175 =head2 $c->prepare_cookies
2176
2177 Prepares cookies by ensuring that the attribute on the request
2178 object has been built.
2179
2180 =cut
2181
2182 sub prepare_cookies { my $c = shift; $c->request->cookies }
2183
2184 =head2 $c->prepare_headers
2185
2186 Prepares request headers by ensuring that the attribute on the request
2187 object has been built.
2188
2189 =cut
2190
2191 sub prepare_headers { my $c = shift; $c->request->headers }
2192
2193 =head2 $c->prepare_parameters
2194
2195 Prepares parameters.
2196
2197 =cut
2198
2199 sub prepare_parameters {
2200     my $c = shift;
2201     $c->prepare_body_parameters;
2202     $c->engine->prepare_parameters( $c, @_ );
2203 }
2204
2205 =head2 $c->prepare_path
2206
2207 Prepares path and base.
2208
2209 =cut
2210
2211 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2212
2213 =head2 $c->prepare_query_parameters
2214
2215 Prepares query parameters.
2216
2217 =cut
2218
2219 sub prepare_query_parameters {
2220     my $c = shift;
2221
2222     $c->engine->prepare_query_parameters( $c, @_ );
2223 }
2224
2225 =head2 $c->log_request
2226
2227 Writes information about the request to the debug logs.  This includes:
2228
2229 =over 4
2230
2231 =item * Request method, path, and remote IP address
2232
2233 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2234
2235 =item * Request parameters
2236
2237 =item * File uploads
2238
2239 =back
2240
2241 =cut
2242
2243 sub log_request {
2244     my $c = shift;
2245
2246     return unless $c->debug;
2247
2248     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2249     my $request = $dump->[1];
2250
2251     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2252     $method ||= '';
2253     $path = '/' unless length $path;
2254     $address ||= '';
2255     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2256
2257     $c->log_request_headers($request->headers);
2258
2259     if ( my $keywords = $request->query_keywords ) {
2260         $c->log->debug("Query keywords are: $keywords");
2261     }
2262
2263     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2264
2265     $c->log_request_uploads($request);
2266 }
2267
2268 =head2 $c->log_response
2269
2270 Writes information about the response to the debug logs by calling
2271 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2272
2273 =cut
2274
2275 sub log_response {
2276     my $c = shift;
2277
2278     return unless $c->debug;
2279
2280     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2281     my $response = $dump->[1];
2282
2283     $c->log_response_status_line($response);
2284     $c->log_response_headers($response->headers);
2285 }
2286
2287 =head2 $c->log_response_status_line($response)
2288
2289 Writes one line of information about the response to the debug logs.  This includes:
2290
2291 =over 4
2292
2293 =item * Response status code
2294
2295 =item * Content-Type header (if present)
2296
2297 =item * Content-Length header (if present)
2298
2299 =back
2300
2301 =cut
2302
2303 sub log_response_status_line {
2304     my ($c, $response) = @_;
2305
2306     $c->log->debug(
2307         sprintf(
2308             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2309             $response->status                            || 'unknown',
2310             $response->headers->header('Content-Type')   || 'unknown',
2311             $response->headers->header('Content-Length') || 'unknown'
2312         )
2313     );
2314 }
2315
2316 =head2 $c->log_response_headers($headers);
2317
2318 Hook method which can be wrapped by plugins to log the response headers.
2319 No-op in the default implementation.
2320
2321 =cut
2322
2323 sub log_response_headers {}
2324
2325 =head2 $c->log_request_parameters( query => {}, body => {} )
2326
2327 Logs request parameters to debug logs
2328
2329 =cut
2330
2331 sub log_request_parameters {
2332     my $c          = shift;
2333     my %all_params = @_;
2334
2335     return unless $c->debug;
2336
2337     my $column_width = Catalyst::Utils::term_width() - 44;
2338     foreach my $type (qw(query body)) {
2339         my $params = $all_params{$type};
2340         next if ! keys %$params;
2341         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2342         for my $key ( sort keys %$params ) {
2343             my $param = $params->{$key};
2344             my $value = defined($param) ? $param : '';
2345             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2346         }
2347         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2348     }
2349 }
2350
2351 =head2 $c->log_request_uploads
2352
2353 Logs file uploads included in the request to the debug logs.
2354 The parameter name, filename, file type, and file size are all included in
2355 the debug logs.
2356
2357 =cut
2358
2359 sub log_request_uploads {
2360     my $c = shift;
2361     my $request = shift;
2362     return unless $c->debug;
2363     my $uploads = $request->uploads;
2364     if ( keys %$uploads ) {
2365         my $t = Text::SimpleTable->new(
2366             [ 12, 'Parameter' ],
2367             [ 26, 'Filename' ],
2368             [ 18, 'Type' ],
2369             [ 9,  'Size' ]
2370         );
2371         for my $key ( sort keys %$uploads ) {
2372             my $upload = $uploads->{$key};
2373             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2374                 $t->row( $key, $u->filename, $u->type, $u->size );
2375             }
2376         }
2377         $c->log->debug( "File Uploads are:\n" . $t->draw );
2378     }
2379 }
2380
2381 =head2 $c->log_request_headers($headers);
2382
2383 Hook method which can be wrapped by plugins to log the request headers.
2384 No-op in the default implementation.
2385
2386 =cut
2387
2388 sub log_request_headers {}
2389
2390 =head2 $c->log_headers($type => $headers)
2391
2392 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2393
2394 =cut
2395
2396 sub log_headers {
2397     my $c       = shift;
2398     my $type    = shift;
2399     my $headers = shift;    # an HTTP::Headers instance
2400
2401     return unless $c->debug;
2402
2403     my $column_width = Catalyst::Utils::term_width() - 28;
2404     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2405     $headers->scan(
2406         sub {
2407             my ( $name, $value ) = @_;
2408             $t->row( $name, $value );
2409         }
2410     );
2411     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2412 }
2413
2414
2415 =head2 $c->prepare_read
2416
2417 Prepares the input for reading.
2418
2419 =cut
2420
2421 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2422
2423 =head2 $c->prepare_request
2424
2425 Prepares the engine request.
2426
2427 =cut
2428
2429 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2430
2431 =head2 $c->prepare_uploads
2432
2433 Prepares uploads.
2434
2435 =cut
2436
2437 sub prepare_uploads {
2438     my $c = shift;
2439
2440     $c->engine->prepare_uploads( $c, @_ );
2441 }
2442
2443 =head2 $c->prepare_write
2444
2445 Prepares the output for writing.
2446
2447 =cut
2448
2449 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2450
2451 =head2 $c->request_class
2452
2453 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2454
2455 =head2 $c->response_class
2456
2457 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2458
2459 =head2 $c->read( [$maxlength] )
2460
2461 Reads a chunk of data from the request body. This method is designed to
2462 be used in a while loop, reading C<$maxlength> bytes on every call.
2463 C<$maxlength> defaults to the size of the request if not specified.
2464
2465 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2466 directly.
2467
2468 Warning: If you use read(), Catalyst will not process the body,
2469 so you will not be able to access POST parameters or file uploads via
2470 $c->request.  You must handle all body parsing yourself.
2471
2472 =cut
2473
2474 sub read { my $c = shift; return $c->request->read( @_ ) }
2475
2476 =head2 $c->run
2477
2478 Starts the engine.
2479
2480 =cut
2481
2482 sub run {
2483   my $app = shift;
2484   $app->_make_immutable_if_needed;
2485   $app->engine_loader->needs_psgi_engine_compat_hack ?
2486     $app->engine->run($app, @_) :
2487       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2488 }
2489
2490 sub _make_immutable_if_needed {
2491     my $class = shift;
2492     my $meta = find_meta($class);
2493     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2494     if (
2495         $meta->is_immutable
2496         && ! { $meta->immutable_options }->{replace_constructor}
2497         && $isa_ca
2498     ) {
2499         warn("You made your application class ($class) immutable, "
2500             . "but did not inline the\nconstructor. "
2501             . "This will break catalyst, as your app \@ISA "
2502             . "Class::Accessor(::Fast)?\nPlease pass "
2503             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2504     }
2505     unless ($meta->is_immutable) {
2506         # XXX - FIXME warning here as you should make your app immutable yourself.
2507         $meta->make_immutable(
2508             replace_constructor => 1,
2509         );
2510     }
2511 }
2512
2513 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2514
2515 Sets an action in a given namespace.
2516
2517 =cut
2518
2519 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2520
2521 =head2 $c->setup_actions($component)
2522
2523 Sets up actions for a component.
2524
2525 =cut
2526
2527 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2528
2529 =head2 $c->setup_components
2530
2531 This method is called internally to set up the application's components.
2532
2533 It finds modules by calling the L<locate_components> method, expands them to
2534 package names with the L<expand_component_module> method, and then installs
2535 each component into the application.
2536
2537 The C<setup_components> config option is passed to both of the above methods.
2538
2539 Installation of each component is performed by the L<setup_component> method,
2540 below.
2541
2542 =cut
2543
2544 sub setup_components {
2545     my $class = shift;
2546
2547     my $config  = $class->config->{ setup_components };
2548
2549     my @comps = $class->locate_components($config);
2550     my %comps = map { $_ => 1 } @comps;
2551
2552     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2553     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2554         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2555     ) if $deprecatedcatalyst_component_names;
2556
2557     for my $component ( @comps ) {
2558
2559         # We pass ignore_loaded here so that overlay files for (e.g.)
2560         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2561         # we know M::P::O found a file on disk so this is safe
2562
2563         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2564     }
2565
2566     for my $component (@comps) {
2567         my $instance = $class->components->{ $component } = $class->setup_component($component);
2568         my @expanded_components = $instance->can('expand_modules')
2569             ? $instance->expand_modules( $component, $config )
2570             : $class->expand_component_module( $component, $config );
2571         for my $component (@expanded_components) {
2572             next if $comps{$component};
2573             $class->components->{ $component } = $class->setup_component($component);
2574         }
2575     }
2576 }
2577
2578 =head2 $c->locate_components( $setup_component_config )
2579
2580 This method is meant to provide a list of component modules that should be
2581 setup for the application.  By default, it will use L<Module::Pluggable>.
2582
2583 Specify a C<setup_components> config option to pass additional options directly
2584 to L<Module::Pluggable>. To add additional search paths, specify a key named
2585 C<search_extra> as an array reference. Items in the array beginning with C<::>
2586 will have the application class name prepended to them.
2587
2588 =cut
2589
2590 sub locate_components {
2591     my $class  = shift;
2592     my $config = shift;
2593
2594     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2595     my $extra   = delete $config->{ search_extra } || [];
2596
2597     push @paths, @$extra;
2598
2599     my $locator = Module::Pluggable::Object->new(
2600         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2601         %$config
2602     );
2603
2604     # XXX think about ditching this sort entirely
2605     my @comps = sort { length $a <=> length $b } $locator->plugins;
2606
2607     return @comps;
2608 }
2609
2610 =head2 $c->expand_component_module( $component, $setup_component_config )
2611
2612 Components found by C<locate_components> will be passed to this method, which
2613 is expected to return a list of component (package) names to be set up.
2614
2615 =cut
2616
2617 sub expand_component_module {
2618     my ($class, $module) = @_;
2619     return Devel::InnerPackage::list_packages( $module );
2620 }
2621
2622 =head2 $c->setup_component
2623
2624 =cut
2625
2626 sub setup_component {
2627     my( $class, $component ) = @_;
2628
2629     unless ( $component->can( 'COMPONENT' ) ) {
2630         return $component;
2631     }
2632
2633     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2634     my $config = $class->config->{ $suffix } || {};
2635     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2636     # methods also pass it. local to avoid pointlessly shitting in config
2637     # for the debug screen, as $component is already the key name.
2638     local $config->{catalyst_component_name} = $component;
2639
2640     my $instance = eval { $component->COMPONENT( $class, $config ); };
2641
2642     if ( my $error = $@ ) {
2643         chomp $error;
2644         Catalyst::Exception->throw(
2645             message => qq/Couldn't instantiate component "$component", "$error"/
2646         );
2647     }
2648
2649     unless (blessed $instance) {
2650         my $metaclass = Moose::Util::find_meta($component);
2651         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2652         my $component_method_from = $method_meta->associated_metaclass->name;
2653         my $value = defined($instance) ? $instance : 'undef';
2654         Catalyst::Exception->throw(
2655             message =>
2656             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2657         );
2658     }
2659     return $instance;
2660 }
2661
2662 =head2 $c->setup_dispatcher
2663
2664 Sets up dispatcher.
2665
2666 =cut
2667
2668 sub setup_dispatcher {
2669     my ( $class, $dispatcher ) = @_;
2670
2671     if ($dispatcher) {
2672         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2673     }
2674
2675     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2676         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2677     }
2678
2679     unless ($dispatcher) {
2680         $dispatcher = $class->dispatcher_class;
2681     }
2682
2683     load_class($dispatcher);
2684
2685     # dispatcher instance
2686     $class->dispatcher( $dispatcher->new );
2687 }
2688
2689 =head2 $c->setup_engine
2690
2691 Sets up engine.
2692
2693 =cut
2694
2695 sub engine_class {
2696     my ($class, $requested_engine) = @_;
2697
2698     if (!$class->engine_loader || $requested_engine) {
2699         $class->engine_loader(
2700             Catalyst::EngineLoader->new({
2701                 application_name => $class,
2702                 (defined $requested_engine
2703                      ? (catalyst_engine_class => $requested_engine) : ()),
2704             }),
2705         );
2706     }
2707
2708     $class->engine_loader->catalyst_engine_class;
2709 }
2710
2711 sub setup_engine {
2712     my ($class, $requested_engine) = @_;
2713
2714     my $engine = do {
2715         my $loader = $class->engine_loader;
2716
2717         if (!$loader || $requested_engine) {
2718             $loader = Catalyst::EngineLoader->new({
2719                 application_name => $class,
2720                 (defined $requested_engine
2721                      ? (requested_engine => $requested_engine) : ()),
2722             }),
2723
2724             $class->engine_loader($loader);
2725         }
2726
2727         $loader->catalyst_engine_class;
2728     };
2729
2730     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2731     return if $class->loading_psgi_file;
2732
2733     load_class($engine);
2734
2735     if ($ENV{MOD_PERL}) {
2736         my $apache = $class->engine_loader->auto;
2737
2738         my $meta = find_meta($class);
2739         my $was_immutable = $meta->is_immutable;
2740         my %immutable_options = $meta->immutable_options;
2741         $meta->make_mutable if $was_immutable;
2742
2743         $meta->add_method(handler => sub {
2744             my $r = shift;
2745             my $psgi_app = $class->_finalized_psgi_app;
2746             $apache->call_app($r, $psgi_app);
2747         });
2748
2749         $meta->make_immutable(%immutable_options) if $was_immutable;
2750     }
2751
2752     $class->engine( $engine->new );
2753
2754     return;
2755 }
2756
2757 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2758 ## build in server support (back compat support for pre psgi port behavior).
2759 ## This is so that we don't build a new psgi app for each request when using
2760 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2761
2762 sub _finalized_psgi_app {
2763     my ($app) = @_;
2764
2765     unless ($app->_psgi_app) {
2766         my $psgi_app = $app->_setup_psgi_app;
2767         $app->_psgi_app($psgi_app);
2768     }
2769
2770     return $app->_psgi_app;
2771 }
2772
2773 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2774 ## home directory and load that and return it (just assume it is doing the
2775 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2776 ## in default_middleware and return it ( this is for backward compatibility
2777 ## with pre psgi port behavior ).
2778
2779 sub _setup_psgi_app {
2780     my ($app) = @_;
2781
2782     for my $home (Path::Class::Dir->new($app->config->{home})) {
2783         my $psgi_file = $home->file(
2784             Catalyst::Utils::appprefix($app) . '.psgi',
2785         );
2786
2787         next unless -e $psgi_file;
2788
2789         # If $psgi_file calls ->setup_engine, it's doing so to load
2790         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2791         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2792         # anyway. So set a flag (ick) that tells setup_engine not to populate
2793         # $c->engine or do any other things we might regret.
2794
2795         $app->loading_psgi_file(1);
2796         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2797         $app->loading_psgi_file(0);
2798
2799         return $psgi_app
2800             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2801
2802         warn <<"EOW";
2803 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2804
2805 Its content has been ignored. Please consult the Catalyst::Upgrading
2806 documentation on how to upgrade from Catalyst::Engine::PSGI.
2807 EOW
2808     }
2809
2810     return $app->apply_default_middlewares($app->psgi_app);
2811 }
2812
2813 =head2 $c->apply_default_middlewares
2814
2815 Adds the following L<Plack> middlewares to your application, since they are
2816 useful and commonly needed:
2817
2818 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2819 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2820 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2821 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2822 applied since this middleware is smart enough to conditionally apply itself).
2823
2824 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2825 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2826 $ENV{SCRIPT_NAME}
2827
2828 =cut
2829
2830
2831 sub apply_default_middlewares {
2832     my ($app, $psgi_app) = @_;
2833
2834     $psgi_app = Plack::Middleware::Conditional->wrap(
2835         $psgi_app,
2836         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2837         condition => sub {
2838             my ($env) = @_;
2839             return if $app->config->{ignore_frontend_proxy};
2840             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2841                 || $app->config->{using_frontend_proxy};
2842         },
2843     );
2844
2845     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2846     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2847     $psgi_app = Plack::Middleware::Conditional->wrap(
2848         $psgi_app,
2849         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2850         condition => sub {
2851             my ($env) = @_;
2852             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2853             return unless $1 < 4.23;
2854             1;
2855         },
2856     );
2857
2858     # we're applying this unconditionally as the middleware itself already makes
2859     # sure it doesn't fuck things up if it's not running under one of the right
2860     # IIS versions
2861     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2862
2863     # And another IIS issue, this time with IIS7.
2864     $psgi_app = Plack::Middleware::Conditional->wrap(
2865         $psgi_app,
2866         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2867         condition => sub {
2868             my ($env) = @_;
2869             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2870         },
2871     );
2872
2873     return $psgi_app;
2874 }
2875
2876 =head2 $c->psgi_app
2877
2878 Returns a PSGI application code reference for the catalyst application
2879 C<$c>. This is the bare application without any middlewares
2880 applied. C<${myapp}.psgi> is not taken into account.
2881
2882 This is what you want to be using to retrieve the PSGI application code
2883 reference of your Catalyst application for use in F<.psgi> files.
2884
2885 =cut
2886
2887 sub psgi_app {
2888     my ($app) = @_;
2889     my $psgi = $app->engine->build_psgi_app($app);
2890     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
2891 }
2892
2893 =head2 $c->setup_home
2894
2895 Sets up the home directory.
2896
2897 =cut
2898
2899 sub setup_home {
2900     my ( $class, $home ) = @_;
2901
2902     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2903         $home = $env;
2904     }
2905
2906     $home ||= Catalyst::Utils::home($class);
2907
2908     if ($home) {
2909         #I remember recently being scolded for assigning config values like this
2910         $class->config->{home} ||= $home;
2911         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2912     }
2913 }
2914
2915 =head2 $c->setup_log
2916
2917 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2918 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2919 log to.
2920
2921 This method also installs a C<debug> method that returns a true value into the
2922 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2923 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2924
2925 Note that if the log has already been setup, by either a previous call to
2926 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2927 that this method won't actually set up the log object.
2928
2929 =cut
2930
2931 sub setup_log {
2932     my ( $class, $levels ) = @_;
2933
2934     $levels ||= '';
2935     $levels =~ s/^\s+//;
2936     $levels =~ s/\s+$//;
2937     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2938
2939     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2940     if ( defined $env_debug ) {
2941         $levels{debug} = 1 if $env_debug; # Ugly!
2942         delete($levels{debug}) unless $env_debug;
2943     }
2944
2945     unless ( $class->log ) {
2946         $class->log( Catalyst::Log->new(keys %levels) );
2947     }
2948
2949     if ( $levels{debug} ) {
2950         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2951         $class->log->debug('Debug messages enabled');
2952     }
2953 }
2954
2955 =head2 $c->setup_plugins
2956
2957 Sets up plugins.
2958
2959 =cut
2960
2961 =head2 $c->setup_stats
2962
2963 Sets up timing statistics class.
2964
2965 =cut
2966
2967 sub setup_stats {
2968     my ( $class, $stats ) = @_;
2969
2970     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2971
2972     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2973     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2974         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2975         $class->log->debug('Statistics enabled');
2976     }
2977 }
2978
2979
2980 =head2 $c->registered_plugins
2981
2982 Returns a sorted list of the plugins which have either been stated in the
2983 import list.
2984
2985 If passed a given plugin name, it will report a boolean value indicating
2986 whether or not that plugin is loaded.  A fully qualified name is required if
2987 the plugin name does not begin with C<Catalyst::Plugin::>.
2988
2989  if ($c->registered_plugins('Some::Plugin')) {
2990      ...
2991  }
2992
2993 =cut
2994
2995 {
2996
2997     sub registered_plugins {
2998         my $proto = shift;
2999         return sort keys %{ $proto->_plugins } unless @_;
3000         my $plugin = shift;
3001         return 1 if exists $proto->_plugins->{$plugin};
3002         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3003     }
3004
3005     sub _register_plugin {
3006         my ( $proto, $plugin, $instant ) = @_;
3007         my $class = ref $proto || $proto;
3008
3009         load_class( $plugin );
3010         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3011             if $plugin->isa( 'Catalyst::Component' );
3012         my $plugin_meta = Moose::Meta::Class->create($plugin);
3013         if (!$plugin_meta->has_method('new')
3014             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3015             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3016         }
3017         if (!$instant && !$proto->_plugins->{$plugin}) {
3018             my $meta = Class::MOP::get_metaclass_by_name($class);
3019             $meta->superclasses($plugin, $meta->superclasses);
3020         }
3021         $proto->_plugins->{$plugin} = 1;
3022         return $class;
3023     }
3024
3025     sub _default_plugins { return qw(Unicode::Encoding) }
3026
3027     sub setup_plugins {
3028         my ( $class, $plugins ) = @_;
3029
3030         $class->_plugins( {} ) unless $class->_plugins;
3031         $plugins = [ grep {
3032             m/Unicode::Encoding/ ? do {
3033                 $class->log->warn(
3034                     'Unicode::Encoding plugin is auto-applied,'
3035                     . ' please remove this from your appclass'
3036                     . ' and make sure to define "encoding" config'
3037                 );
3038                 unless (exists $class->config->{'encoding'}) {
3039                   $class->config->{'encoding'} = 'UTF-8';
3040                 }
3041                 () }
3042                 : $_
3043         } @$plugins ];
3044         push @$plugins, $class->_default_plugins;
3045         $plugins = Data::OptList::mkopt($plugins || []);
3046
3047         my @plugins = map {
3048             [ Catalyst::Utils::resolve_namespace(
3049                   $class . '::Plugin',
3050                   'Catalyst::Plugin', $_->[0]
3051               ),
3052               $_->[1],
3053             ]
3054          } @{ $plugins };
3055
3056         for my $plugin ( reverse @plugins ) {
3057             load_class($plugin->[0], $plugin->[1]);
3058             my $meta = find_meta($plugin->[0]);
3059             next if $meta && $meta->isa('Moose::Meta::Role');
3060
3061             $class->_register_plugin($plugin->[0]);
3062         }
3063
3064         my @roles =
3065             map  { $_->[0]->name, $_->[1] }
3066             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3067             map  { [find_meta($_->[0]), $_->[1]] }
3068             @plugins;
3069
3070         Moose::Util::apply_all_roles(
3071             $class => @roles
3072         ) if @roles;
3073     }
3074 }
3075
3076 =head2 registered_middlewares
3077
3078 Read only accessor that returns an array of all the middleware in the order
3079 that they were added (which is the REVERSE of the order they will be applied).
3080
3081 The values returned will be either instances of L<Plack::Middleware> or of a
3082 compatible interface, or a coderef, which is assumed to be inlined middleware
3083
3084 =head2 setup_middleware (?@middleware)
3085
3086 Read configuration information stored in configuration key C<psgi_middleware> or
3087 from passed @args.
3088
3089 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3090 to use it to enable L<Plack::Middleware>
3091
3092 This method is automatically called during 'setup' of your application, so
3093 you really don't need to invoke it.  However you may do so if you find the idea
3094 of loading middleware via configuration weird :).  For example:
3095
3096     package MyApp;
3097
3098     use Catalyst;
3099
3100     __PACKAGE__->setup_middleware('Head');
3101     __PACKAGE__->setup;
3102
3103 When we read middleware definitions from configuration, we reverse the list
3104 which sounds odd but is likely how you expect it to work if you have prior
3105 experience with L<Plack::Builder> or if you previously used the plugin
3106 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3107
3108 =cut
3109
3110 sub registered_middlewares {
3111     my $class = shift;
3112     if(my $middleware = $class->_psgi_middleware) {
3113         return (
3114           Plack::Middleware::HTTPExceptions->new,
3115           Plack::Middleware::FixMissingBodyInRedirect->new,
3116           Plack::Middleware::ContentLength->new,
3117           Plack::Middleware::Head->new,
3118           @$middleware);
3119     } else {
3120         die "You cannot call ->registered_middlewares until middleware has been setup";
3121     }
3122 }
3123
3124 sub setup_middleware {
3125     my $class = shift;
3126     my @middleware_definitions = @_ ?
3127       @_ : reverse(@{$class->config->{'psgi_middleware'}||[]});
3128
3129     my @middleware = ();
3130     while(my $next = shift(@middleware_definitions)) {
3131         if(ref $next) {
3132             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3133                 push @middleware, $next;
3134             } elsif(ref $next eq 'CODE') {
3135                 push @middleware, $next;
3136             } elsif(ref $next eq 'HASH') {
3137                 my $namespace = shift @middleware_definitions;
3138                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3139                 push @middleware, $mw;
3140             } else {
3141               die "I can't handle middleware definition ${\ref $next}";
3142             }
3143         } else {
3144           my $mw = $class->Catalyst::Utils::build_middleware($next);
3145           push @middleware, $mw;
3146         }
3147     }
3148
3149     my @existing = @{$class->_psgi_middleware || []};
3150     $class->_psgi_middleware([@middleware,@existing,]);
3151 }
3152
3153 =head2 registered_data_handlers
3154
3155 A read only copy of registered Data Handlers returned as a Hash, where each key
3156 is a content type and each value is a subref that attempts to decode that content
3157 type.
3158
3159 =head2 setup_data_handlers (?@data_handler)
3160
3161 Read configuration information stored in configuration key C<data_handlers> or
3162 from passed @args.
3163
3164 See under L</CONFIGURATION> information regarding C<data_handlers>.
3165
3166 This method is automatically called during 'setup' of your application, so
3167 you really don't need to invoke it.
3168
3169 =head2 default_data_handlers
3170
3171 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3172 only two default data handlers, for 'application/json' and an alternative to
3173 'application/x-www-form-urlencoded' which supposed nested form parameters via
3174 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3175
3176 The 'application/json' data handler is used to parse incoming JSON into a Perl
3177 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3178 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3179 JSON decoder, and has the smallest dependency impact.
3180
3181 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3182 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3183 order to get the best performance.  You should add either to your dependency
3184 list (Makefile.PL, dist.ini, cpanfile, etc.)
3185
3186 =cut
3187
3188 sub registered_data_handlers {
3189     my $class = shift;
3190     if(my $data_handlers = $class->_data_handlers) {
3191         return %$data_handlers;
3192     } else {
3193         die "You cannot call ->registered_data_handlers until data_handers has been setup";
3194     }
3195 }
3196
3197 sub setup_data_handlers {
3198     my ($class, %data_handler_callbacks) = @_;
3199     %data_handler_callbacks = (
3200       %{$class->default_data_handlers},
3201       %{$class->config->{'data_handlers'}||+{}},
3202       %data_handler_callbacks);
3203
3204     $class->_data_handlers(\%data_handler_callbacks);
3205 }
3206
3207 sub default_data_handlers {
3208     my ($class) = @_;
3209     return +{
3210       'application/x-www-form-urlencoded' => sub {
3211           my ($fh, $req) = @_;
3212           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3213           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3214             ->can('build_cgi_struct')->($params);
3215       },
3216       'application/json' => sub {
3217           Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON')
3218             ->can('decode_json')->(do { local $/; $_->getline });
3219       },
3220     };
3221 }
3222
3223 =head2 $c->stack
3224
3225 Returns an arrayref of the internal execution stack (actions that are
3226 currently executing).
3227
3228 =head2 $c->stats
3229
3230 Returns the current timing statistics object. By default Catalyst uses
3231 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3232 L<< stats_class|/"$c->stats_class" >>.
3233
3234 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3235 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3236 profile explicitly, although MyApp.pm still won't profile nor output anything
3237 by itself.
3238
3239 =head2 $c->stats_class
3240
3241 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3242
3243 =head2 $c->use_stats
3244
3245 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3246
3247 Note that this is a static method, not an accessor and should be overridden
3248 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3249
3250 =cut
3251
3252 sub use_stats { 0 }
3253
3254
3255 =head2 $c->write( $data )
3256
3257 Writes $data to the output stream. When using this method directly, you
3258 will need to manually set the C<Content-Length> header to the length of
3259 your output data, if known.
3260
3261 =cut
3262
3263 sub write {
3264     my $c = shift;
3265
3266     # Finalize headers if someone manually writes output (for compat)
3267     $c->finalize_headers;
3268
3269     return $c->response->write( @_ );
3270 }
3271
3272 =head2 version
3273
3274 Returns the Catalyst version number. Mostly useful for "powered by"
3275 messages in template systems.
3276
3277 =cut
3278
3279 sub version { return $Catalyst::VERSION }
3280
3281 =head1 CONFIGURATION
3282
3283 There are a number of 'base' config variables which can be set:
3284
3285 =over
3286
3287 =item *
3288
3289 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3290
3291 =item *
3292
3293 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3294
3295 =item *
3296
3297 C<disable_component_resolution_regex_fallback> - Turns
3298 off the deprecated component resolution functionality so
3299 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3300 are called then regex search will not be attempted on string values and
3301 instead C<undef> will be returned.
3302
3303 =item *
3304
3305 C<home> - The application home directory. In an uninstalled application,
3306 this is the top level application directory. In an installed application,
3307 this will be the directory containing C<< MyApp.pm >>.
3308
3309 =item *
3310
3311 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3312
3313 =item *
3314
3315 C<name> - The name of the application in debug messages and the debug and
3316 welcome screens
3317
3318 =item *
3319
3320 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3321 until it is accessed. This allows you to (for example) check authentication (and reject
3322 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3323
3324 =item *
3325
3326 C<root> - The root directory for templates. Usually this is just a
3327 subdirectory of the home directory, but you can set it to change the
3328 templates to a different directory.
3329
3330 =item *
3331
3332 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3333 namespaces from which components will be loaded (and constructed and stored in
3334 C<< $c->components >>).
3335
3336 =item *
3337
3338 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3339 to be shown in hit debug tables in the test server.
3340
3341 =item *
3342
3343 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3344 variable should be used for determining the request path.
3345
3346 Most web server environments pass the requested path to the application using environment variables,
3347 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3348 exposed as C<< $c->request->base >>) and the request path below that base.
3349
3350 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3351 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3352
3353 =over
3354
3355 =item use_request_uri_for_path => 0
3356
3357 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3358 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3359 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3360 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3361
3362 However this method has the major disadvantage that it is impossible to correctly decode some elements
3363 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3364 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3365 can't distinguish / vs %2F in paths (in addition to other encoded values).
3366
3367 =item use_request_uri_for_path => 1
3368
3369 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3370 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3371 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3372
3373 Given that this method of path resolution is provably more correct, it is recommended that you use
3374 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3375 aware of the implications of not being able to handle encoded URI paths correctly.
3376
3377 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3378 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3379 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3380 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3381 C<< $c->request->base >> will be incorrect.
3382
3383 =back
3384
3385 =item *
3386
3387 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3388
3389 =item *
3390
3391 C<encoding> - See L</ENCODING>
3392
3393 =item *
3394
3395 C<abort_chain_on_error_fix>
3396
3397 When there is an error in an action chain, the default behavior is to continue
3398 processing the remaining actions and then catch the error upon chain end.  This
3399 can lead to running actions when the application is in an unexpected state.  If
3400 you have this issue, setting this config value to true will promptly exit a
3401 chain when there is an error raised in any action (thus terminating the chain
3402 early.)
3403
3404 use like:
3405
3406     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3407
3408 In the future this might become the default behavior.
3409
3410 =item *
3411
3412 C<use_hash_multivalue_in_request>
3413
3414 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3415 and C<parameters> return a hashref where values might be scalar or an arrayref
3416 depending on the incoming data.  In many cases this can be undesirable as it
3417 leads one to writing defensive code like the following:
3418
3419     my ($val) = ref($c->req->parameters->{a}) ?
3420       @{$c->req->parameters->{a}} :
3421         $c->req->parameters->{a};
3422
3423 Setting this configuration item to true will make L<Catalyst> populate the
3424 attributes underlying these methods with an instance of L<Hash::MultiValue>
3425 which is used by L<Plack::Request> and others to solve this very issue.  You
3426 may prefer this behavior to the default, if so enable this option (be warned
3427 if you enable it in a legacy application we are not sure if it is completely
3428 backwardly compatible).
3429
3430 =item *
3431
3432 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3433
3434 =item *
3435
3436 C<data_handlers> - See L<DATA HANDLERS>.
3437
3438 =back
3439
3440 =head1 INTERNAL ACTIONS
3441
3442 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3443 C<_ACTION>, and C<_END>. These are by default not shown in the private
3444 action table, but you can make them visible with a config parameter.
3445
3446     MyApp->config(show_internal_actions => 1);
3447
3448 =head1 ON-DEMAND PARSER
3449
3450 The request body is usually parsed at the beginning of a request,
3451 but if you want to handle input yourself, you can enable on-demand
3452 parsing with a config parameter.
3453
3454     MyApp->config(parse_on_demand => 1);
3455
3456 =head1 PROXY SUPPORT
3457
3458 Many production servers operate using the common double-server approach,
3459 with a lightweight frontend web server passing requests to a larger
3460 backend server. An application running on the backend server must deal
3461 with two problems: the remote user always appears to be C<127.0.0.1> and
3462 the server's hostname will appear to be C<localhost> regardless of the
3463 virtual host that the user connected through.
3464
3465 Catalyst will automatically detect this situation when you are running
3466 the frontend and backend servers on the same machine. The following
3467 changes are made to the request.
3468
3469     $c->req->address is set to the user's real IP address, as read from
3470     the HTTP X-Forwarded-For header.
3471
3472     The host value for $c->req->base and $c->req->uri is set to the real
3473     host, as read from the HTTP X-Forwarded-Host header.
3474
3475 Additionally, you may be running your backend application on an insecure
3476 connection (port 80) while your frontend proxy is running under SSL.  If there
3477 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3478 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3479 be created properly.
3480
3481 In the case of passing in:
3482
3483     X-Forwarded-Port: 443
3484
3485 All calls to C<uri_for> will result in an https link, as is expected.
3486
3487 Obviously, your web server must support these headers for this to work.
3488
3489 In a more complex server farm environment where you may have your
3490 frontend proxy server(s) on different machines, you will need to set a
3491 configuration option to tell Catalyst to read the proxied data from the
3492 headers.
3493
3494     MyApp->config(using_frontend_proxy => 1);
3495
3496 If you do not wish to use the proxy support at all, you may set:
3497
3498     MyApp->config(ignore_frontend_proxy => 0);
3499
3500 =head2 Note about psgi files
3501
3502 Note that if you supply your own .psgi file, calling
3503 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3504
3505 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3506 in your psgi, for example:
3507
3508     builder {
3509         enable "Plack::Middleware::ReverseProxy";
3510         MyApp->psgi_app
3511     };
3512
3513 This will unconditionally add the ReverseProxy support, or you need to call
3514 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3515 apply the support depending upon your config).
3516
3517 See L<Catalyst::PSGI> for more information.
3518
3519 =head1 THREAD SAFETY
3520
3521 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3522 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3523 believe the Catalyst core to be thread-safe.
3524
3525 If you plan to operate in a threaded environment, remember that all other
3526 modules you are using must also be thread-safe. Some modules, most notably
3527 L<DBD::SQLite>, are not thread-safe.
3528
3529 =head1 DATA HANDLERS
3530
3531 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3532 form parameters and URL search query fields.  However it has become common
3533 for various alternative content types to be PUT or POSTed to your controllers
3534 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3535 XML and other content types when communicating with an application server.  In
3536 order to better support this use case, L<Catalyst> defines a global configuration
3537 option, C<data_handlers>, which lets you associate a content type with a coderef
3538 that parses that content type into something Perl can readily access.
3539
3540     package MyApp::Web;
3541
3542     use Catalyst;
3543     use JSON::Maybe;
3544
3545     __PACKAGE__->config(
3546       data_handlers => {
3547         'application/json' => sub { local $/; decode_json $_->getline },
3548       },
3549       ## Any other configuration.
3550     );
3551
3552     __PACKAGE__->setup;
3553
3554 By default L<Catalyst> comes with a generic JSON data handler similar to the
3555 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3556 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3557 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3558 or dist.ini, cpanfile, etc.)
3559
3560 The C<data_handlers> configuation is a hashref whose keys are HTTP Content-Types
3561 (matched against the incoming request type using a regexp such as to be case
3562 insensitive) and whose values are coderefs that receive a localized version of
3563 C<$_> which is a filehandle object pointing to received body.
3564
3565 This feature is considered an early access release and we reserve the right
3566 to alter the interface in order to provide a performant and secure solution to
3567 alternative request body content.  Your reports welcomed!
3568
3569 =head1 PSGI MIDDLEWARE
3570
3571 You can define middleware, defined as L<Plack::Middleware> or a compatible
3572 interface in configuration.  Your middleware definitions are in the form of an
3573 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3574 with details to follow:
3575
3576     package MyApp::Web;
3577
3578     use Catalyst;
3579     use Plack::Middleware::StackTrace;
3580
3581     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3582
3583     __PACKAGE__->config(
3584       'psgi_middleware', [
3585         'Debug',
3586         '+MyApp::Custom',
3587         $stacktrace_middleware,
3588         'Session' => {store => 'File'},
3589         sub {
3590           my $app = shift;
3591           return sub {
3592             my $env = shift;
3593             $env->{myapp.customkey} = 'helloworld';
3594             $app->($env);
3595           },
3596         },
3597       ],
3598     );
3599
3600     __PACKAGE__->setup;
3601
3602 So the general form is:
3603
3604     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3605
3606 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3607 the order listed (to make it function similarly to L<Plack::Builder>:
3608
3609 Alternatively, you may also define middleware by calling the L</setup_middleware>
3610 package method:
3611
3612     package MyApp::Web;
3613
3614     use Catalyst;
3615
3616     __PACKAGE__->setup_middleware( \@middleware_definitions);
3617     __PACKAGE__->setup;
3618
3619 In the case where you do both (use 'setup_middleware' and configuration) the
3620 package call to setup_middleware will be applied earlier (in other words its
3621 middleware will wrap closer to the application).  Keep this in mind since in
3622 some cases the order of middleware is important.
3623
3624 The two approaches are not exclusive.
3625
3626 =over 4
3627
3628 =item Middleware Object
3629
3630 An already initialized object that conforms to the L<Plack::Middleware>
3631 specification:
3632
3633     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3634
3635     __PACKAGE__->config(
3636       'psgi_middleware', [
3637         $stacktrace_middleware,
3638       ]);
3639
3640
3641 =item coderef
3642
3643 A coderef that is an inlined middleware:
3644
3645     __PACKAGE__->config(
3646       'psgi_middleware', [
3647         sub {
3648           my $app = shift;
3649           return sub {
3650             my $env = shift;
3651             if($env->{PATH_INFO} =~m/forced/) {
3652               Plack::App::File
3653                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3654                 ->call($env);
3655             } else {
3656               return $app->($env);
3657             }
3658          },
3659       },
3660     ]);
3661
3662
3663
3664 =item a scalar
3665
3666 We assume the scalar refers to a namespace after normalizing it using the
3667 following rules:
3668
3669 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3670 is assumed to be 'as is', and we just install and use the middleware.
3671
3672 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3673 (the package name of your Catalyst application subclass), we also assume then
3674 that it is a full namespace, and use it.
3675
3676 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3677 resolve it first by looking for it under your application namespace (for example
3678 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3679 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3680 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3681 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3682 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3683 you find that a good idea.
3684
3685 Examples:
3686
3687     package MyApp::Web;
3688
3689     __PACKAGE__->config(
3690       'psgi_middleware', [
3691         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3692         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3693         '+MyApp::Custom',  ## MyApp::Custom->wrap
3694       ],
3695     );
3696
3697 =item a scalar followed by a hashref
3698
3699 Just like the previous, except the following C<HashRef> is used as arguments
3700 to initialize the middleware object.
3701
3702     __PACKAGE__->config(
3703       'psgi_middleware', [
3704          'Session' => {store => 'File'},
3705     ]);
3706
3707 =back
3708
3709 Please see L<PSGI> for more on middleware.
3710
3711 =head1 ENCODING
3712
3713 On request, decodes all params from encoding into a sequence of
3714 logical characters. On response, encodes body into encoding.
3715
3716 =head2 Methods
3717
3718 =over 4
3719
3720 =item encoding
3721
3722 Returns an instance of an C<Encode> encoding
3723
3724     print $c->encoding->name
3725
3726 =item handle_unicode_encoding_exception ($exception_context)
3727
3728 Method called when decoding process for a request fails.
3729
3730 An C<$exception_context> hashref is provided to allow you to override the
3731 behaviour of your application when given data with incorrect encodings.
3732
3733 The default method throws exceptions in the case of invalid request parameters
3734 (resulting in a 500 error), but ignores errors in upload filenames.
3735
3736 The keys passed in the C<$exception_context> hash are:
3737
3738 =over
3739
3740 =item param_value
3741
3742 The value which was not able to be decoded.
3743
3744 =item error_msg
3745
3746 The exception received from L<Encode>.
3747
3748 =item encoding_step
3749
3750 What type of data was being decoded. Valid values are (currently)
3751 C<params> - for request parameters / arguments / captures
3752 and C<uploads> - for request upload filenames.
3753
3754 =back
3755
3756 =back
3757
3758 =head1 SUPPORT
3759
3760 IRC:
3761
3762     Join #catalyst on irc.perl.org.
3763
3764 Mailing Lists:
3765
3766     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3767     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3768
3769 Web:
3770
3771     http://catalyst.perl.org
3772
3773 Wiki:
3774
3775     http://dev.catalyst.perl.org
3776
3777 =head1 SEE ALSO
3778
3779 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3780
3781 =head2 L<Catalyst::Manual> - The Catalyst Manual
3782
3783 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3784
3785 =head2 L<Catalyst::Engine> - Core engine
3786
3787 =head2 L<Catalyst::Log> - Log class.
3788
3789 =head2 L<Catalyst::Request> - Request object
3790
3791 =head2 L<Catalyst::Response> - Response object
3792
3793 =head2 L<Catalyst::Test> - The test suite.
3794
3795 =head1 PROJECT FOUNDER
3796
3797 sri: Sebastian Riedel <sri@cpan.org>
3798
3799 =head1 CONTRIBUTORS
3800
3801 abw: Andy Wardley
3802
3803 acme: Leon Brocard <leon@astray.com>
3804
3805 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3806
3807 Andrew Bramble
3808
3809 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3810
3811 Andrew Ruthven
3812
3813 andyg: Andy Grundman <andy@hybridized.org>
3814
3815 audreyt: Audrey Tang
3816
3817 bricas: Brian Cassidy <bricas@cpan.org>
3818
3819 Caelum: Rafael Kitover <rkitover@io.com>
3820
3821 chansen: Christian Hansen
3822
3823 chicks: Christopher Hicks
3824
3825 Chisel Wright C<pause@herlpacker.co.uk>
3826
3827 Danijel Milicevic C<me@danijel.de>
3828
3829 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3830
3831 David Naughton, C<naughton@umn.edu>
3832
3833 David E. Wheeler
3834
3835 dhoss: Devin Austin <dhoss@cpan.org>
3836
3837 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3838
3839 Drew Taylor
3840
3841 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3842
3843 esskar: Sascha Kiefer
3844
3845 fireartist: Carl Franks <cfranks@cpan.org>
3846
3847 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3848
3849 gabb: Danijel Milicevic
3850
3851 Gary Ashton Jones
3852
3853 Gavin Henry C<ghenry@perl.me.uk>
3854
3855 Geoff Richards
3856
3857 groditi: Guillermo Roditi <groditi@gmail.com>
3858
3859 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3860
3861 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3862
3863 jcamacho: Juan Camacho
3864
3865 jester: Jesse Sheidlower C<jester@panix.com>
3866
3867 jhannah: Jay Hannah <jay@jays.net>
3868
3869 Jody Belka
3870
3871 Johan Lindstrom
3872
3873 jon: Jon Schutz <jjschutz@cpan.org>
3874
3875 Jonathan Rockway C<< <jrockway@cpan.org> >>
3876
3877 Kieren Diment C<kd@totaldatasolution.com>
3878
3879 konobi: Scott McWhirter <konobi@cpan.org>
3880
3881 marcus: Marcus Ramberg <mramberg@cpan.org>
3882
3883 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3884
3885 mgrimes: Mark Grimes <mgrimes@cpan.org>
3886
3887 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3888
3889 mugwump: Sam Vilain
3890
3891 naughton: David Naughton
3892
3893 ningu: David Kamholz <dkamholz@cpan.org>
3894
3895 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3896
3897 numa: Dan Sully <daniel@cpan.org>
3898
3899 obra: Jesse Vincent
3900
3901 Octavian Rasnita
3902
3903 omega: Andreas Marienborg
3904
3905 Oleg Kostyuk <cub.uanic@gmail.com>
3906
3907 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3908
3909 rafl: Florian Ragwitz <rafl@debian.org>
3910
3911 random: Roland Lammel <lammel@cpan.org>
3912
3913 Robert Sedlacek C<< <rs@474.at> >>
3914
3915 SpiceMan: Marcel Montes
3916
3917 sky: Arthur Bergman
3918
3919 szbalint: Balint Szilakszi <szbalint@cpan.org>
3920
3921 t0m: Tomas Doran <bobtfish@bobtfish.net>
3922
3923 Ulf Edvinsson
3924
3925 Viljo Marrandi C<vilts@yahoo.com>
3926
3927 Will Hawes C<info@whawes.co.uk>
3928
3929 willert: Sebastian Willert <willert@cpan.org>
3930
3931 wreis: Wallace Reis <wreis@cpan.org>
3932
3933 Yuval Kogman, C<nothingmuch@woobling.org>
3934
3935 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3936
3937 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3938
3939 Upasana <me@upasana.me>
3940
3941 =head1 COPYRIGHT
3942
3943 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3944
3945 =head1 LICENSE
3946
3947 This library is free software. You can redistribute it and/or modify it under
3948 the same terms as Perl itself.
3949
3950 =cut
3951
3952 no Moose;
3953
3954 __PACKAGE__->meta->make_immutable;
3955
3956 1;