lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80023';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 104     }
 105
 106     $caller->arguments( [@arguments] );
 107     $caller->setup_home;
 108 }
 109
 110 sub _application { $_[0] }
 111
 112 =head1 NAME
 113
 114 Catalyst - The Elegant MVC Web Application Framework
 115
 116 =head1 SYNOPSIS
 117
 118 See the L<Catalyst::Manual> distribution for comprehensive
 119 documentation and tutorials.
 120
 121     # Install Catalyst::Devel for helpers and other development tools
 122     # use the helper to create a new application
 123     catalyst.pl MyApp
 124
 125     # add models, views, controllers
 126     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 127     script/myapp_create.pl view MyTemplate TT
 128     script/myapp_create.pl controller Search
 129
 130     # built in testserver -- use -r to restart automatically on changes
 131     # --help to see all available options
 132     script/myapp_server.pl
 133
 134     # command line testing interface
 135     script/myapp_test.pl /yada
 136
 137     ### in lib/MyApp.pm
 138     use Catalyst qw/-Debug/; # include plugins here as well
 139
 140     ### In lib/MyApp/Controller/Root.pm (autocreated)
 141     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 142         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 143         $c->stash->{template} = 'foo.tt'; # set the template
 144         # lookup something from db -- stash vars are passed to TT
 145         $c->stash->{data} =
 146           $c->model('Database::Foo')->search( { country => $args[0] } );
 147         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 148             $c->forward( 'bar' ); # process another action
 149             # do something else after forward returns
 150         }
 151     }
 152
 153     # The foo.tt TT template can use the stash data from the database
 154     [% WHILE (item = data.next) %]
 155         [% item.foo %]
 156     [% END %]
 157
 158     # called for /bar/of/soap, /bar/of/soap/10, etc.
 159     sub bar : Path('/bar/of/soap') { ... }
 160
 161     # called for all actions, from the top-most controller downwards
 162     sub auto : Private {
 163         my ( $self, $c ) = @_;
 164         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 165             $c->res->redirect( '/login' ); # require login
 166             return 0; # abort request and go immediately to end()
 167         }
 168         return 1; # success; carry on to next action
 169     }
 170
 171     # called after all actions are finished
 172     sub end : Private {
 173         my ( $self, $c ) = @_;
 174         if ( scalar @{ $c->error } ) { ... } # handle errors
 175         return if $c->res->body; # already have a response
 176         $c->forward( 'MyApp::View::TT' ); # render template
 177     }
 178
 179     ### in MyApp/Controller/Foo.pm
 180     # called for /foo/bar
 181     sub bar : Local { ... }
 182
 183     # called for /blargle
 184     sub blargle : Global { ... }
 185
 186     # an index action matches /foo, but not /foo/1, etc.
 187     sub index : Private { ... }
 188
 189     ### in MyApp/Controller/Foo/Bar.pm
 190     # called for /foo/bar/baz
 191     sub baz : Local { ... }
 192
 193     # first Root auto is called, then Foo auto, then this
 194     sub auto : Private { ... }
 195
 196     # powerful regular expression paths are also possible
 197     sub details : Regex('^product/(\w+)/details$') {
 198         my ( $self, $c ) = @_;
 199         # extract the (\w+) from the URI
 200         my $product = $c->req->captures->[0];
 201     }
 202
 203 See L<Catalyst::Manual::Intro> for additional information.
 204
 205 =head1 DESCRIPTION
 206
 207 Catalyst is a modern framework for making web applications without the
 208 pain usually associated with this process. This document is a reference
 209 to the main Catalyst application. If you are a new user, we suggest you
 210 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 211
 212 See L<Catalyst::Manual> for more documentation.
 213
 214 Catalyst plugins can be loaded by naming them as arguments to the "use
 215 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 216 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 217 C<My::Module>.
 218
 219     use Catalyst qw/My::Module/;
 220
 221 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 222 fully qualify the name by using a unary plus:
 223
 224     use Catalyst qw/
 225         My::Module
 226         +Fully::Qualified::Plugin::Name
 227     /;
 228
 229 Special flags like C<-Debug> and C<-Engine> can also be specified as
 230 arguments when Catalyst is loaded:
 231
 232     use Catalyst qw/-Debug My::Module/;
 233
 234 The position of plugins and flags in the chain is important, because
 235 they are loaded in the order in which they appear.
 236
 237 The following flags are supported:
 238
 239 =head2 -Debug
 240
 241 Enables debug output. You can also force this setting from the system
 242 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 243 settings override the application, with <MYAPP>_DEBUG having the highest
 244 priority.
 245
 246 This sets the log level to 'debug' and enables full debug output on the
 247 error screen. If you only want the latter, see L<< $c->debug >>.
 248
 249 =head2 -Engine
 250
 251 Forces Catalyst to use a specific engine. Omit the
 252 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 253
 254     use Catalyst qw/-Engine=CGI/;
 255
 256 =head2 -Home
 257
 258 Forces Catalyst to use a specific home directory, e.g.:
 259
 260     use Catalyst qw[-Home=/usr/mst];
 261
 262 This can also be done in the shell environment by setting either the
 263 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 264 is replaced with the uppercased name of your application, any "::" in
 265 the name will be replaced with underscores, e.g. MyApp::Web should use
 266 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 267
 268 If none of these are set, Catalyst will attempt to automatically detect the
 269 home directory. If you are working in a development envirnoment, Catalyst
 270 will try and find the directory containing either Makefile.PL, Build.PL or
 271 dist.ini. If the application has been installed into the system (i.e.
 272 you have done C<make install>), then Catalyst will use the path to your
 273 application module, without the .pm extension (ie, /foo/MyApp if your
 274 application was installed at /foo/MyApp.pm)
 275
 276 =head2 -Log
 277
 278     use Catalyst '-Log=warn,fatal,error';
 279
 280 Specifies a comma-delimited list of log levels.
 281
 282 =head2 -Stats
 283
 284 Enables statistics collection and reporting. You can also force this setting
 285 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 286 environment settings override the application, with <MYAPP>_STATS having the
 287 highest priority.
 288
 289 e.g.
 290
 291    use Catalyst qw/-Stats=1/
 292
 293 =head1 METHODS
 294
 295 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 296
 297 =head2 $c->action
 298
 299 Returns a L<Catalyst::Action> object for the current action, which
 300 stringifies to the action name. See L<Catalyst::Action>.
 301
 302 =head2 $c->namespace
 303
 304 Returns the namespace of the current action, i.e., the URI prefix
 305 corresponding to the controller of the current action. For example:
 306
 307     # in Controller::Foo::Bar
 308     $c->namespace; # returns 'foo/bar';
 309
 310 =head2 $c->request
 311
 312 =head2 $c->req
 313
 314 Returns the current L<Catalyst::Request> object, giving access to
 315 information about the current client request (including parameters,
 316 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 317
 318 =head2 REQUEST FLOW HANDLING
 319
 320 =head2 $c->forward( $action [, \@arguments ] )
 321
 322 =head2 $c->forward( $class, $method, [, \@arguments ] )
 323
 324 Forwards processing to another action, by its private name. If you give a
 325 class name but no method, C<process()> is called. You may also optionally
 326 pass arguments in an arrayref. The action will receive the arguments in
 327 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 328 C<< $c->req->args >> will be restored to the previous values.
 329
 330 Any data C<return>ed from the action forwarded to, will be returned by the
 331 call to forward.
 332
 333     my $foodata = $c->forward('/foo');
 334     $c->forward('index');
 335     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 336     $c->forward('View::TT');
 337
 338 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 339 an C<< eval { } >> around the call (actually
 340 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 341 all 'dies' within the called action. If you want C<die> to propagate you
 342 need to do something like:
 343
 344     $c->forward('foo');
 345     die join "\n", @{ $c->error } if @{ $c->error };
 346
 347 Or make sure to always return true values from your actions and write
 348 your code like this:
 349
 350     $c->forward('foo') || return;
 351
 352 Another note is that C<< $c->forward >> always returns a scalar because it
 353 actually returns $c->state which operates in a scalar context.
 354 Thus, something like:
 355
 356     return @array;
 357
 358 in an action that is forwarded to is going to return a scalar,
 359 i.e. how many items are in that array, which is probably not what you want.
 360 If you need to return an array then return a reference to it,
 361 or stash it like so:
 362
 363     $c->stash->{array} = \@array;
 364
 365 and access it from the stash.
 366
 367 =cut
 368
 369 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 370
 371 =head2 $c->detach( $action [, \@arguments ] )
 372
 373 =head2 $c->detach( $class, $method, [, \@arguments ] )
 374
 375 =head2 $c->detach()
 376
 377 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 378 doesn't return to the previous action when processing is finished.
 379
 380 When called with no arguments it escapes the processing chain entirely.
 381
 382 =cut
 383
 384 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 385
 386 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 387
 388 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 389
 390 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 391 but does a full dispatch, instead of just calling the new C<$action> /
 392 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 393 you go to are called, just like a new request.
 394
 395 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 396 This means, for example, that C<< $c->action >> methods such as
 397 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 398 L<reverse|Catalyst::Action/reverse> return information for the visited action
 399 when they are invoked within the visited action.  This is different from the
 400 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 401 continues to use the $c->action object from the caller action even when
 402 invoked from the callee.
 403
 404 C<< $c->stash >> is kept unchanged.
 405
 406 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 407 allows you to "wrap" another action, just as it would have been called by
 408 dispatching from a URL, while the analogous
 409 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 410 transfer control to another action as if it had been reached directly from a URL.
 411
 412 =cut
 413
 414 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 415
 416 =head2 $c->go( $action [, \@captures, \@arguments ] )
 417
 418 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 419
 420 The relationship between C<go> and
 421 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 422 the relationship between
 423 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 424 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 425 C<< $c->go >> will perform a full dispatch on the specified action or method,
 426 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 427 C<go> escapes the processing of the current request chain on completion, and
 428 does not return to its caller.
 429
 430 =cut
 431
 432 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 433
 434 =head2 $c->response
 435
 436 =head2 $c->res
 437
 438 Returns the current L<Catalyst::Response> object, see there for details.
 439
 440 =head2 $c->stash
 441
 442 Returns a hashref to the stash, which may be used to store data and pass
 443 it between components during a request. You can also set hash keys by
 444 passing arguments. The stash is automatically sent to the view. The
 445 stash is cleared at the end of a request; it cannot be used for
 446 persistent storage (for this you must use a session; see
 447 L<Catalyst::Plugin::Session> for a complete system integrated with
 448 Catalyst).
 449
 450     $c->stash->{foo} = $bar;
 451     $c->stash( { moose => 'majestic', qux => 0 } );
 452     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 453
 454     # stash is automatically passed to the view for use in a template
 455     $c->forward( 'MyApp::View::TT' );
 456
 457 =cut
 458
 459 around stash => sub {
 460     my $orig = shift;
 461     my $c = shift;
 462     my $stash = $orig->($c);
 463     if (@_) {
 464         my $new_stash = @_ > 1 ? {@_} : $_[0];
 465         croak('stash takes a hash or hashref') unless ref $new_stash;
 466         foreach my $key ( keys %$new_stash ) {
 467           $stash->{$key} = $new_stash->{$key};
 468         }
 469     }
 470
 471     return $stash;
 472 };
 473
 474
 475 =head2 $c->error
 476
 477 =head2 $c->error($error, ...)
 478
 479 =head2 $c->error($arrayref)
 480
 481 Returns an arrayref containing error messages.  If Catalyst encounters an
 482 error while processing a request, it stores the error in $c->error.  This
 483 method should only be used to store fatal error messages.
 484
 485     my @error = @{ $c->error };
 486
 487 Add a new error.
 488
 489     $c->error('Something bad happened');
 490
 491 =cut
 492
 493 sub error {
 494     my $c = shift;
 495     if ( $_[0] ) {
 496         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 497         croak @$error unless ref $c;
 498         push @{ $c->{error} }, @$error;
 499     }
 500     elsif ( defined $_[0] ) { $c->{error} = undef }
 501     return $c->{error} || [];
 502 }
 503
 504
 505 =head2 $c->state
 506
 507 Contains the return value of the last executed action.
 508 Note that << $c->state >> operates in a scalar context which means that all
 509 values it returns are scalar.
 510
 511 =head2 $c->clear_errors
 512
 513 Clear errors.  You probably don't want to clear the errors unless you are
 514 implementing a custom error screen.
 515
 516 This is equivalent to running
 517
 518     $c->error(0);
 519
 520 =cut
 521
 522 sub clear_errors {
 523     my $c = shift;
 524     $c->error(0);
 525 }
 526
 527 sub _comp_search_prefixes {
 528     my $c = shift;
 529     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 530 }
 531
 532 # search components given a name and some prefixes
 533 sub _comp_names_search_prefixes {
 534     my ( $c, $name, @prefixes ) = @_;
 535     my $appclass = ref $c || $c;
 536     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 537     $filter = qr/$filter/; # Compile regex now rather than once per loop
 538
 539     # map the original component name to the sub part that we will search against
 540     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 541         grep { /$filter/ } keys %{ $c->components };
 542
 543     # undef for a name will return all
 544     return keys %eligible if !defined $name;
 545
 546     my $query  = ref $name ? $name : qr/^$name$/i;
 547     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 548
 549     return @result if @result;
 550
 551     # if we were given a regexp to search against, we're done.
 552     return if ref $name;
 553
 554     # skip regexp fallback if configured
 555     return
 556         if $appclass->config->{disable_component_resolution_regex_fallback};
 557
 558     # regexp fallback
 559     $query  = qr/$name/i;
 560     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 561
 562     # no results? try against full names
 563     if( !@result ) {
 564         @result = grep { m{$query} } keys %eligible;
 565     }
 566
 567     # don't warn if we didn't find any results, it just might not exist
 568     if( @result ) {
 569         # Disgusting hack to work out correct method name
 570         my $warn_for = lc $prefixes[0];
 571         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 572            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 573            "component resolution is unreliable and unsafe.";
 574         my $short = $result[0];
 575         # remove the component namespace prefix
 576         $short =~ s/.*?(Model|Controller|View):://;
 577         my $shortmess = Carp::shortmess('');
 578         if ($shortmess =~ m#Catalyst/Plugin#) {
 579            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 580               "plugin's config";
 581         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 582            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 583               "component's config";
 584         } else {
 585            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 586               "but if you really wanted to search, pass in a regexp as the argument " .
 587               "like so: \$c->${warn_for}(qr/${name}/)";
 588         }
 589         $c->log->warn( "${msg}$shortmess" );
 590     }
 591
 592     return @result;
 593 }
 594
 595 # Find possible names for a prefix
 596 sub _comp_names {
 597     my ( $c, @prefixes ) = @_;
 598     my $appclass = ref $c || $c;
 599
 600     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 601
 602     my @names = map { s{$filter}{}; $_; }
 603         $c->_comp_names_search_prefixes( undef, @prefixes );
 604
 605     return @names;
 606 }
 607
 608 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 609 sub _filter_component {
 610     my ( $c, $comp, @args ) = @_;
 611
 612     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 613         return $comp->ACCEPT_CONTEXT( $c, @args );
 614     }
 615
 616     return $comp;
 617 }
 618
 619 =head2 COMPONENT ACCESSORS
 620
 621 =head2 $c->controller($name)
 622
 623 Gets a L<Catalyst::Controller> instance by name.
 624
 625     $c->controller('Foo')->do_stuff;
 626
 627 If the name is omitted, will return the controller for the dispatched
 628 action.
 629
 630 If you want to search for controllers, pass in a regexp as the argument.
 631
 632     # find all controllers that start with Foo
 633     my @foo_controllers = $c->controller(qr{^Foo});
 634
 635
 636 =cut
 637
 638 sub controller {
 639     my ( $c, $name, @args ) = @_;
 640
 641     my $appclass = ref($c) || $c;
 642     if( $name ) {
 643         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 644             my $comps = $c->components;
 645             my $check = $appclass."::Controller::".$name;
 646             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 647         }
 648         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 649         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 650         return $c->_filter_component( $result[ 0 ], @args );
 651     }
 652
 653     return $c->component( $c->action->class );
 654 }
 655
 656 =head2 $c->model($name)
 657
 658 Gets a L<Catalyst::Model> instance by name.
 659
 660     $c->model('Foo')->do_stuff;
 661
 662 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 663
 664 If the name is omitted, it will look for
 665  - a model object in $c->stash->{current_model_instance}, then
 666  - a model name in $c->stash->{current_model}, then
 667  - a config setting 'default_model', or
 668  - check if there is only one model, and return it if that's the case.
 669
 670 If you want to search for models, pass in a regexp as the argument.
 671
 672     # find all models that start with Foo
 673     my @foo_models = $c->model(qr{^Foo});
 674
 675 =cut
 676
 677 sub model {
 678     my ( $c, $name, @args ) = @_;
 679     my $appclass = ref($c) || $c;
 680     if( $name ) {
 681         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 682             my $comps = $c->components;
 683             my $check = $appclass."::Model::".$name;
 684             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 685         }
 686         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 687         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 688         return $c->_filter_component( $result[ 0 ], @args );
 689     }
 690
 691     if (ref $c) {
 692         return $c->stash->{current_model_instance}
 693           if $c->stash->{current_model_instance};
 694         return $c->model( $c->stash->{current_model} )
 695           if $c->stash->{current_model};
 696     }
 697     return $c->model( $appclass->config->{default_model} )
 698       if $appclass->config->{default_model};
 699
 700     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 701
 702     if( $rest ) {
 703         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 704         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 705         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 706         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 707         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 708     }
 709
 710     return $c->_filter_component( $comp );
 711 }
 712
 713
 714 =head2 $c->view($name)
 715
 716 Gets a L<Catalyst::View> instance by name.
 717
 718     $c->view('Foo')->do_stuff;
 719
 720 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 721
 722 If the name is omitted, it will look for
 723  - a view object in $c->stash->{current_view_instance}, then
 724  - a view name in $c->stash->{current_view}, then
 725  - a config setting 'default_view', or
 726  - check if there is only one view, and return it if that's the case.
 727
 728 If you want to search for views, pass in a regexp as the argument.
 729
 730     # find all views that start with Foo
 731     my @foo_views = $c->view(qr{^Foo});
 732
 733 =cut
 734
 735 sub view {
 736     my ( $c, $name, @args ) = @_;
 737
 738     my $appclass = ref($c) || $c;
 739     if( $name ) {
 740         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 741             my $comps = $c->components;
 742             my $check = $appclass."::View::".$name;
 743             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 744         }
 745         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 746         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 747         return $c->_filter_component( $result[ 0 ], @args );
 748     }
 749
 750     if (ref $c) {
 751         return $c->stash->{current_view_instance}
 752           if $c->stash->{current_view_instance};
 753         return $c->view( $c->stash->{current_view} )
 754           if $c->stash->{current_view};
 755     }
 756     return $c->view( $appclass->config->{default_view} )
 757       if $appclass->config->{default_view};
 758
 759     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 760
 761     if( $rest ) {
 762         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 763         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 764         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 765         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 766         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 767     }
 768
 769     return $c->_filter_component( $comp );
 770 }
 771
 772 =head2 $c->controllers
 773
 774 Returns the available names which can be passed to $c->controller
 775
 776 =cut
 777
 778 sub controllers {
 779     my ( $c ) = @_;
 780     return $c->_comp_names(qw/Controller C/);
 781 }
 782
 783 =head2 $c->models
 784
 785 Returns the available names which can be passed to $c->model
 786
 787 =cut
 788
 789 sub models {
 790     my ( $c ) = @_;
 791     return $c->_comp_names(qw/Model M/);
 792 }
 793
 794
 795 =head2 $c->views
 796
 797 Returns the available names which can be passed to $c->view
 798
 799 =cut
 800
 801 sub views {
 802     my ( $c ) = @_;
 803     return $c->_comp_names(qw/View V/);
 804 }
 805
 806 =head2 $c->comp($name)
 807
 808 =head2 $c->component($name)
 809
 810 Gets a component object by name. This method is not recommended,
 811 unless you want to get a specific component by full
 812 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 813 should be used instead.
 814
 815 If C<$name> is a regexp, a list of components matched against the full
 816 component name will be returned.
 817
 818 If Catalyst can't find a component by name, it will fallback to regex
 819 matching by default. To disable this behaviour set
 820 disable_component_resolution_regex_fallback to a true value.
 821
 822     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 823
 824 =cut
 825
 826 sub component {
 827     my ( $c, $name, @args ) = @_;
 828
 829     if( $name ) {
 830         my $comps = $c->components;
 831
 832         if( !ref $name ) {
 833             # is it the exact name?
 834             return $c->_filter_component( $comps->{ $name }, @args )
 835                        if exists $comps->{ $name };
 836
 837             # perhaps we just omitted "MyApp"?
 838             my $composed = ( ref $c || $c ) . "::${name}";
 839             return $c->_filter_component( $comps->{ $composed }, @args )
 840                        if exists $comps->{ $composed };
 841
 842             # search all of the models, views and controllers
 843             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 844             return $c->_filter_component( $comp, @args ) if $comp;
 845         }
 846
 847         # This is here so $c->comp( '::M::' ) works
 848         my $query = ref $name ? $name : qr{$name}i;
 849
 850         my @result = grep { m{$query} } keys %{ $c->components };
 851         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 852
 853         if( $result[ 0 ] ) {
 854             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 855             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 856             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 857             return $c->_filter_component( $result[ 0 ], @args );
 858         }
 859
 860         # I would expect to return an empty list here, but that breaks back-compat
 861     }
 862
 863     # fallback
 864     return sort keys %{ $c->components };
 865 }
 866
 867 =head2 CLASS DATA AND HELPER CLASSES
 868
 869 =head2 $c->config
 870
 871 Returns or takes a hashref containing the application's configuration.
 872
 873     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 874
 875 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 876 like C<myapp.conf> in your applications home directory. See
 877 L<Catalyst::Plugin::ConfigLoader>.
 878
 879 =head3 Cascading configuration
 880
 881 The config method is present on all Catalyst components, and configuration
 882 will be merged when an application is started. Configuration loaded with
 883 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 884 followed by configuration in your top level C<MyApp> class. These two
 885 configurations are merged, and then configuration data whose hash key matches a
 886 component name is merged with configuration for that component.
 887
 888 The configuration for a component is then passed to the C<new> method when a
 889 component is constructed.
 890
 891 For example:
 892
 893     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 894     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 895
 896 will mean that C<MyApp::Model::Foo> receives the following data when
 897 constructed:
 898
 899     MyApp::Model::Foo->new({
 900         bar => 'baz',
 901         quux => 'frob',
 902         overrides => 'me',
 903     });
 904
 905 =cut
 906
 907 around config => sub {
 908     my $orig = shift;
 909     my $c = shift;
 910
 911     croak('Setting config after setup has been run is not allowed.')
 912         if ( @_ and $c->setup_finished );
 913
 914     $c->$orig(@_);
 915 };
 916
 917 =head2 $c->log
 918
 919 Returns the logging object instance. Unless it is already set, Catalyst
 920 sets this up with a L<Catalyst::Log> object. To use your own log class,
 921 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 922 C<< __PACKAGE__->setup >>.
 923
 924  __PACKAGE__->log( MyLogger->new );
 925  __PACKAGE__->setup;
 926
 927 And later:
 928
 929     $c->log->info( 'Now logging with my own logger!' );
 930
 931 Your log class should implement the methods described in
 932 L<Catalyst::Log>.
 933
 934
 935 =head2 $c->debug
 936
 937 Returns 1 if debug mode is enabled, 0 otherwise.
 938
 939 You can enable debug mode in several ways:
 940
 941 =over
 942
 943 =item By calling myapp_server.pl with the -d flag
 944
 945 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 946
 947 =item The -Debug option in your MyApp.pm
 948
 949 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 950
 951 =back
 952
 953 The first three also set the log level to 'debug'.
 954
 955 Calling C<< $c->debug(1) >> has no effect.
 956
 957 =cut
 958
 959 sub debug { 0 }
 960
 961 =head2 $c->dispatcher
 962
 963 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 964
 965 =head2 $c->engine
 966
 967 Returns the engine instance. See L<Catalyst::Engine>.
 968
 969
 970 =head2 UTILITY METHODS
 971
 972 =head2 $c->path_to(@path)
 973
 974 Merges C<@path> with C<< $c->config->{home} >> and returns a
 975 L<Path::Class::Dir> object. Note you can usually use this object as
 976 a filename, but sometimes you will have to explicitly stringify it
 977 yourself by calling the C<< ->stringify >> method.
 978
 979 For example:
 980
 981     $c->path_to( 'db', 'sqlite.db' );
 982
 983 =cut
 984
 985 sub path_to {
 986     my ( $c, @path ) = @_;
 987     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 988     if ( -d $path ) { return $path }
 989     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 990 }
 991
 992 =head2 $c->plugin( $name, $class, @args )
 993
 994 Helper method for plugins. It creates a class data accessor/mutator and
 995 loads and instantiates the given class.
 996
 997     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 998
 999     $c->prototype->define_javascript_functions;
1000
1001 B<Note:> This method of adding plugins is deprecated. The ability
1002 to add plugins like this B<will be removed> in a Catalyst 5.81.
1003 Please do not use this functionality in new code.
1004
1005 =cut
1006
1007 sub plugin {
1008     my ( $class, $name, $plugin, @args ) = @_;
1009
1010     # See block comment in t/unit_core_plugin.t
1011     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1012
1013     $class->_register_plugin( $plugin, 1 );
1014
1015     eval { $plugin->import };
1016     $class->mk_classdata($name);
1017     my $obj;
1018     eval { $obj = $plugin->new(@args) };
1019
1020     if ($@) {
1021         Catalyst::Exception->throw( message =>
1022               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1023     }
1024
1025     $class->$name($obj);
1026     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1027       if $class->debug;
1028 }
1029
1030 =head2 MyApp->setup
1031
1032 Initializes the dispatcher and engine, loads any plugins, and loads the
1033 model, view, and controller components. You may also specify an array
1034 of plugins to load here, if you choose to not load them in the C<use
1035 Catalyst> line.
1036
1037     MyApp->setup;
1038     MyApp->setup( qw/-Debug/ );
1039
1040 =cut
1041
1042 sub setup {
1043     my ( $class, @arguments ) = @_;
1044     croak('Running setup more than once')
1045         if ( $class->setup_finished );
1046
1047     unless ( $class->isa('Catalyst') ) {
1048
1049         Catalyst::Exception->throw(
1050             message => qq/'$class' does not inherit from Catalyst/ );
1051     }
1052
1053     if ( $class->arguments ) {
1054         @arguments = ( @arguments, @{ $class->arguments } );
1055     }
1056
1057     # Process options
1058     my $flags = {};
1059
1060     foreach (@arguments) {
1061
1062         if (/^-Debug$/) {
1063             $flags->{log} =
1064               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1065         }
1066         elsif (/^-(\w+)=?(.*)$/) {
1067             $flags->{ lc $1 } = $2;
1068         }
1069         else {
1070             push @{ $flags->{plugins} }, $_;
1071         }
1072     }
1073
1074     $class->setup_home( delete $flags->{home} );
1075
1076     $class->setup_log( delete $flags->{log} );
1077     $class->setup_plugins( delete $flags->{plugins} );
1078     $class->setup_dispatcher( delete $flags->{dispatcher} );
1079     $class->setup_engine( delete $flags->{engine} );
1080     $class->setup_stats( delete $flags->{stats} );
1081
1082     for my $flag ( sort keys %{$flags} ) {
1083
1084         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1085             &$code( $class, delete $flags->{$flag} );
1086         }
1087         else {
1088             $class->log->warn(qq/Unknown flag "$flag"/);
1089         }
1090     }
1091
1092     eval { require Catalyst::Devel; };
1093     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1094         $class->log->warn(<<"EOF");
1095 You are running an old script!
1096
1097   Please update by running (this will overwrite existing files):
1098     catalyst.pl -force -scripts $class
1099
1100   or (this will not overwrite existing files):
1101     catalyst.pl -scripts $class
1102
1103 EOF
1104     }
1105
1106     if ( $class->debug ) {
1107         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1108
1109         if (@plugins) {
1110             my $column_width = Catalyst::Utils::term_width() - 6;
1111             my $t = Text::SimpleTable->new($column_width);
1112             $t->row($_) for @plugins;
1113             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1114         }
1115
1116         my $dispatcher = $class->dispatcher;
1117         my $engine     = $class->engine;
1118         my $home       = $class->config->{home};
1119
1120         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1121         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1122
1123         $home
1124           ? ( -d $home )
1125           ? $class->log->debug(qq/Found home "$home"/)
1126           : $class->log->debug(qq/Home "$home" doesn't exist/)
1127           : $class->log->debug(q/Couldn't find home/);
1128     }
1129
1130     # Call plugins setup, this is stupid and evil.
1131     # Also screws C3 badly on 5.10, hack to avoid.
1132     {
1133         no warnings qw/redefine/;
1134         local *setup = sub { };
1135         $class->setup unless $Catalyst::__AM_RESTARTING;
1136     }
1137
1138     # Initialize our data structure
1139     $class->components( {} );
1140
1141     $class->setup_components;
1142
1143     if ( $class->debug ) {
1144         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1145         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1146         for my $comp ( sort keys %{ $class->components } ) {
1147             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1148             $t->row( $comp, $type );
1149         }
1150         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1151           if ( keys %{ $class->components } );
1152     }
1153
1154     # Add our self to components, since we are also a component
1155     if( $class->isa('Catalyst::Controller') ){
1156       $class->components->{$class} = $class;
1157     }
1158
1159     $class->setup_actions;
1160
1161     if ( $class->debug ) {
1162         my $name = $class->config->{name} || 'Application';
1163         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1164     }
1165
1166     # Make sure that the application class becomes immutable at this point,
1167     B::Hooks::EndOfScope::on_scope_end {
1168         return if $@;
1169         my $meta = Class::MOP::get_metaclass_by_name($class);
1170         if (
1171             $meta->is_immutable
1172             && ! { $meta->immutable_options }->{replace_constructor}
1173             && (
1174                    $class->isa('Class::Accessor::Fast')
1175                 || $class->isa('Class::Accessor')
1176             )
1177         ) {
1178             warn "You made your application class ($class) immutable, "
1179                 . "but did not inline the\nconstructor. "
1180                 . "This will break catalyst, as your app \@ISA "
1181                 . "Class::Accessor(::Fast)?\nPlease pass "
1182                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1183         }
1184         $meta->make_immutable(
1185             replace_constructor => 1,
1186         ) unless $meta->is_immutable;
1187     };
1188
1189     if ($class->config->{case_sensitive}) {
1190         $class->log->warn($class . "->config->{case_sensitive} is set.");
1191         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1192     }
1193
1194     $class->setup_finalize;
1195     # Should be the last thing we do so that user things hooking
1196     # setup_finalize can log..
1197     $class->log->_flush() if $class->log->can('_flush');
1198     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1199 }
1200
1201 =head2 $app->setup_finalize
1202
1203 A hook to attach modifiers to. This method does not do anything except set the
1204 C<setup_finished> accessor.
1205
1206 Applying method modifiers to the C<setup> method doesn't work, because of quirky thingsdone for plugin setup.
1207
1208 Example:
1209
1210     after setup_finalize => sub {
1211         my $app = shift;
1212
1213         ## do stuff here..
1214     };
1215
1216 =cut
1217
1218 sub setup_finalize {
1219     my ($class) = @_;
1220     $class->setup_finished(1);
1221 }
1222
1223 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1224
1225 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1226
1227 Constructs an absolute L<URI> object based on the application root, the
1228 provided path, and the additional arguments and query parameters provided.
1229 When used as a string, provides a textual URI.
1230
1231 If no arguments are provided, the URI for the current action is returned.
1232 To return the current action and also provide @args, use
1233 C<< $c->uri_for( $c->action, @args ) >>.
1234
1235 If the first argument is a string, it is taken as a public URI path relative
1236 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1237 relative to the application root (if it does). It is then merged with
1238 C<< $c->request->base >>; any C<@args> are appended as additional path
1239 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1240
1241 If the first argument is a L<Catalyst::Action> it represents an action which
1242 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1243 optional C<\@captures> argument (an arrayref) allows passing the captured
1244 variables that are needed to fill in the paths of Chained and Regex actions;
1245 once the path is resolved, C<uri_for> continues as though a path was
1246 provided, appending any arguments or parameters and creating an absolute
1247 URI.
1248
1249 The captures for the current request can be found in
1250 C<< $c->request->captures >>, and actions can be resolved using
1251 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1252 path, use C<< $c->uri_for_action >> instead.
1253
1254   # Equivalent to $c->req->uri
1255   $c->uri_for($c->action, $c->req->captures,
1256       @{ $c->req->args }, $c->req->params);
1257
1258   # For the Foo action in the Bar controller
1259   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1260
1261   # Path to a static resource
1262   $c->uri_for('/static/images/logo.png');
1263
1264 =cut
1265
1266 sub uri_for {
1267     my ( $c, $path, @args ) = @_;
1268
1269     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1270         $path = $path->path_prefix;
1271         $path =~ s{/+\z}{};
1272         $path .= '/';
1273     }
1274
1275     undef($path) if (defined $path && $path eq '');
1276
1277     my $params =
1278       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1279
1280     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1281     foreach my $arg (@args) {
1282         utf8::encode($arg) if utf8::is_utf8($arg);
1283         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1284     }
1285
1286     if ( blessed($path) ) { # action object
1287         s|/|%2F|g for @args;
1288         my $captures = [ map { s|/|%2F|g; $_; }
1289                         ( scalar @args && ref $args[0] eq 'ARRAY'
1290                          ? @{ shift(@args) }
1291                          : ()) ];
1292
1293         foreach my $capture (@$captures) {
1294             utf8::encode($capture) if utf8::is_utf8($capture);
1295             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1296         }
1297
1298         my $action = $path;
1299         $path = $c->dispatcher->uri_for_action($action, $captures);
1300         if (not defined $path) {
1301             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1302                 if $c->debug;
1303             return undef;
1304         }
1305         $path = '/' if $path eq '';
1306     }
1307
1308     unshift(@args, $path);
1309
1310     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1311         my $namespace = $c->namespace;
1312         if (defined $path) { # cheesy hack to handle path '../foo'
1313            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1314         }
1315         unshift(@args, $namespace || '');
1316     }
1317
1318     # join args with '/', or a blank string
1319     my $args = join('/', grep { defined($_) } @args);
1320     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1321     $args =~ s!^/+!!;
1322     my $base = $c->req->base;
1323     my $class = ref($base);
1324     $base =~ s{(?<!/)$}{/};
1325
1326     my $query = '';
1327
1328     if (my @keys = keys %$params) {
1329       # somewhat lifted from URI::_query's query_form
1330       $query = '?'.join('&', map {
1331           my $val = $params->{$_};
1332           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1333           s/ /+/g;
1334           my $key = $_;
1335           $val = '' unless defined $val;
1336           (map {
1337               my $param = "$_";
1338               utf8::encode( $param ) if utf8::is_utf8($param);
1339               # using the URI::Escape pattern here so utf8 chars survive
1340               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1341               $param =~ s/ /+/g;
1342               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1343       } @keys);
1344     }
1345
1346     my $res = bless(\"${base}${args}${query}", $class);
1347     $res;
1348 }
1349
1350 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1351
1352 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1353
1354 =over
1355
1356 =item $path
1357
1358 A private path to the Catalyst action you want to create a URI for.
1359
1360 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1361 >> and passing the resulting C<$action> and the remaining arguments to C<<
1362 $c->uri_for >>.
1363
1364 You can also pass in a Catalyst::Action object, in which case it is passed to
1365 C<< $c->uri_for >>.
1366
1367 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1368
1369 For example, if the action looks like:
1370
1371  package MyApp::Controller::Users;
1372
1373  sub lst : Path('the-list') {}
1374
1375 You can use:
1376
1377  $c->uri_for_action('/users/lst')
1378
1379 and it will create the URI /users/the-list.
1380
1381 =back
1382
1383 =cut
1384
1385 sub uri_for_action {
1386     my ( $c, $path, @args ) = @_;
1387     my $action = blessed($path)
1388       ? $path
1389       : $c->dispatcher->get_action_by_path($path);
1390     unless (defined $action) {
1391       croak "Can't find action for path '$path'";
1392     }
1393     return $c->uri_for( $action, @args );
1394 }
1395
1396 =head2 $c->welcome_message
1397
1398 Returns the Catalyst welcome HTML page.
1399
1400 =cut
1401
1402 sub welcome_message {
1403     my $c      = shift;
1404     my $name   = $c->config->{name};
1405     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1406     my $prefix = Catalyst::Utils::appprefix( ref $c );
1407     $c->response->content_type('text/html; charset=utf-8');
1408     return <<"EOF";
1409 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1410     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1411 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1412     <head>
1413     <meta http-equiv="Content-Language" content="en" />
1414     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1415         <title>$name on Catalyst $VERSION</title>
1416         <style type="text/css">
1417             body {
1418                 color: #000;
1419                 background-color: #eee;
1420             }
1421             div#content {
1422                 width: 640px;
1423                 margin-left: auto;
1424                 margin-right: auto;
1425                 margin-top: 10px;
1426                 margin-bottom: 10px;
1427                 text-align: left;
1428                 background-color: #ccc;
1429                 border: 1px solid #aaa;
1430             }
1431             p, h1, h2 {
1432                 margin-left: 20px;
1433                 margin-right: 20px;
1434                 font-family: verdana, tahoma, sans-serif;
1435             }
1436             a {
1437                 font-family: verdana, tahoma, sans-serif;
1438             }
1439             :link, :visited {
1440                     text-decoration: none;
1441                     color: #b00;
1442                     border-bottom: 1px dotted #bbb;
1443             }
1444             :link:hover, :visited:hover {
1445                     color: #555;
1446             }
1447             div#topbar {
1448                 margin: 0px;
1449             }
1450             pre {
1451                 margin: 10px;
1452                 padding: 8px;
1453             }
1454             div#answers {
1455                 padding: 8px;
1456                 margin: 10px;
1457                 background-color: #fff;
1458                 border: 1px solid #aaa;
1459             }
1460             h1 {
1461                 font-size: 0.9em;
1462                 font-weight: normal;
1463                 text-align: center;
1464             }
1465             h2 {
1466                 font-size: 1.0em;
1467             }
1468             p {
1469                 font-size: 0.9em;
1470             }
1471             p img {
1472                 float: right;
1473                 margin-left: 10px;
1474             }
1475             span#appname {
1476                 font-weight: bold;
1477                 font-size: 1.6em;
1478             }
1479         </style>
1480     </head>
1481     <body>
1482         <div id="content">
1483             <div id="topbar">
1484                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1485                     $VERSION</h1>
1486              </div>
1487              <div id="answers">
1488                  <p>
1489                  <img src="$logo" alt="Catalyst Logo" />
1490                  </p>
1491                  <p>Welcome to the  world of Catalyst.
1492                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1493                     framework will make web development something you had
1494                     never expected it to be: Fun, rewarding, and quick.</p>
1495                  <h2>What to do now?</h2>
1496                  <p>That really depends  on what <b>you</b> want to do.
1497                     We do, however, provide you with a few starting points.</p>
1498                  <p>If you want to jump right into web development with Catalyst
1499                     you might want to start with a tutorial.</p>
1500 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1501 </pre>
1502 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1503 <pre>
1504 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1505 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1506 </code></pre>
1507                  <h2>What to do next?</h2>
1508                  <p>Next it's time to write an actual application. Use the
1509                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1510                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1511                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1512                     they can save you a lot of work.</p>
1513                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1514                     <p>Also, be sure to check out the vast and growing
1515                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1516                     you are likely to find what you need there.
1517                     </p>
1518
1519                  <h2>Need help?</h2>
1520                  <p>Catalyst has a very active community. Here are the main places to
1521                     get in touch with us.</p>
1522                  <ul>
1523                      <li>
1524                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1525                      </li>
1526                      <li>
1527                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1528                      </li>
1529                      <li>
1530                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1531                      </li>
1532                  </ul>
1533                  <h2>In conclusion</h2>
1534                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1535                     as we enjoyed making it. Please contact us if you have ideas
1536                     for improvement or other feedback.</p>
1537              </div>
1538          </div>
1539     </body>
1540 </html>
1541 EOF
1542 }
1543
1544 =head1 INTERNAL METHODS
1545
1546 These methods are not meant to be used by end users.
1547
1548 =head2 $c->components
1549
1550 Returns a hash of components.
1551
1552 =head2 $c->context_class
1553
1554 Returns or sets the context class.
1555
1556 =head2 $c->counter
1557
1558 Returns a hashref containing coderefs and execution counts (needed for
1559 deep recursion detection).
1560
1561 =head2 $c->depth
1562
1563 Returns the number of actions on the current internal execution stack.
1564
1565 =head2 $c->dispatch
1566
1567 Dispatches a request to actions.
1568
1569 =cut
1570
1571 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1572
1573 =head2 $c->dispatcher_class
1574
1575 Returns or sets the dispatcher class.
1576
1577 =head2 $c->dump_these
1578
1579 Returns a list of 2-element array references (name, structure) pairs
1580 that will be dumped on the error page in debug mode.
1581
1582 =cut
1583
1584 sub dump_these {
1585     my $c = shift;
1586     [ Request => $c->req ],
1587     [ Response => $c->res ],
1588     [ Stash => $c->stash ],
1589     [ Config => $c->config ];
1590 }
1591
1592 =head2 $c->engine_class
1593
1594 Returns or sets the engine class.
1595
1596 =head2 $c->execute( $class, $coderef )
1597
1598 Execute a coderef in given class and catch exceptions. Errors are available
1599 via $c->error.
1600
1601 =cut
1602
1603 sub execute {
1604     my ( $c, $class, $code ) = @_;
1605     $class = $c->component($class) || $class;
1606     $c->state(0);
1607
1608     if ( $c->depth >= $RECURSION ) {
1609         my $action = $code->reverse();
1610         $action = "/$action" unless $action =~ /->/;
1611         my $error = qq/Deep recursion detected calling "${action}"/;
1612         $c->log->error($error);
1613         $c->error($error);
1614         $c->state(0);
1615         return $c->state;
1616     }
1617
1618     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1619
1620     push( @{ $c->stack }, $code );
1621
1622     no warnings 'recursion';
1623     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1624
1625     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1626
1627     my $last = pop( @{ $c->stack } );
1628
1629     if ( my $error = $@ ) {
1630         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1631             $error->rethrow if $c->depth > 1;
1632         }
1633         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1634             $error->rethrow if $c->depth > 0;
1635         }
1636         else {
1637             unless ( ref $error ) {
1638                 no warnings 'uninitialized';
1639                 chomp $error;
1640                 my $class = $last->class;
1641                 my $name  = $last->name;
1642                 $error = qq/Caught exception in $class->$name "$error"/;
1643             }
1644             $c->error($error);
1645             $c->state(0);
1646         }
1647     }
1648     return $c->state;
1649 }
1650
1651 sub _stats_start_execute {
1652     my ( $c, $code ) = @_;
1653     my $appclass = ref($c) || $c;
1654     return if ( ( $code->name =~ /^_.*/ )
1655         && ( !$appclass->config->{show_internal_actions} ) );
1656
1657     my $action_name = $code->reverse();
1658     $c->counter->{$action_name}++;
1659
1660     my $action = $action_name;
1661     $action = "/$action" unless $action =~ /->/;
1662
1663     # determine if the call was the result of a forward
1664     # this is done by walking up the call stack and looking for a calling
1665     # sub of Catalyst::forward before the eval
1666     my $callsub = q{};
1667     for my $index ( 2 .. 11 ) {
1668         last
1669         if ( ( caller($index) )[0] eq 'Catalyst'
1670             && ( caller($index) )[3] eq '(eval)' );
1671
1672         if ( ( caller($index) )[3] =~ /forward$/ ) {
1673             $callsub = ( caller($index) )[3];
1674             $action  = "-> $action";
1675             last;
1676         }
1677     }
1678
1679     my $uid = $action_name . $c->counter->{$action_name};
1680
1681     # is this a root-level call or a forwarded call?
1682     if ( $callsub =~ /forward$/ ) {
1683         my $parent = $c->stack->[-1];
1684
1685         # forward, locate the caller
1686         if ( exists $c->counter->{"$parent"} ) {
1687             $c->stats->profile(
1688                 begin  => $action,
1689                 parent => "$parent" . $c->counter->{"$parent"},
1690                 uid    => $uid,
1691             );
1692         }
1693         else {
1694
1695             # forward with no caller may come from a plugin
1696             $c->stats->profile(
1697                 begin => $action,
1698                 uid   => $uid,
1699             );
1700         }
1701     }
1702     else {
1703
1704         # root-level call
1705         $c->stats->profile(
1706             begin => $action,
1707             uid   => $uid,
1708         );
1709     }
1710     return $action;
1711
1712 }
1713
1714 sub _stats_finish_execute {
1715     my ( $c, $info ) = @_;
1716     $c->stats->profile( end => $info );
1717 }
1718
1719 =head2 $c->finalize
1720
1721 Finalizes the request.
1722
1723 =cut
1724
1725 sub finalize {
1726     my $c = shift;
1727
1728     for my $error ( @{ $c->error } ) {
1729         $c->log->error($error);
1730     }
1731
1732     # Allow engine to handle finalize flow (for POE)
1733     my $engine = $c->engine;
1734     if ( my $code = $engine->can('finalize') ) {
1735         $engine->$code($c);
1736     }
1737     else {
1738
1739         $c->finalize_uploads;
1740
1741         # Error
1742         if ( $#{ $c->error } >= 0 ) {
1743             $c->finalize_error;
1744         }
1745
1746         $c->finalize_headers;
1747
1748         # HEAD request
1749         if ( $c->request->method eq 'HEAD' ) {
1750             $c->response->body('');
1751         }
1752
1753         $c->finalize_body;
1754     }
1755
1756     $c->log_response;
1757
1758     if ($c->use_stats) {
1759         my $elapsed = sprintf '%f', $c->stats->elapsed;
1760         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1761         $c->log->info(
1762             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1763     }
1764
1765     return $c->response->status;
1766 }
1767
1768 =head2 $c->finalize_body
1769
1770 Finalizes body.
1771
1772 =cut
1773
1774 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1775
1776 =head2 $c->finalize_cookies
1777
1778 Finalizes cookies.
1779
1780 =cut
1781
1782 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1783
1784 =head2 $c->finalize_error
1785
1786 Finalizes error.
1787
1788 =cut
1789
1790 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1791
1792 =head2 $c->finalize_headers
1793
1794 Finalizes headers.
1795
1796 =cut
1797
1798 sub finalize_headers {
1799     my $c = shift;
1800
1801     my $response = $c->response; #accessor calls can add up?
1802
1803     # Check if we already finalized headers
1804     return if $response->finalized_headers;
1805
1806     # Handle redirects
1807     if ( my $location = $response->redirect ) {
1808         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1809         $response->header( Location => $location );
1810
1811         if ( !$response->has_body ) {
1812             # Add a default body if none is already present
1813             $response->body(
1814                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1815             );
1816         }
1817     }
1818
1819     # Content-Length
1820     if ( $response->body && !$response->content_length ) {
1821
1822         # get the length from a filehandle
1823         if ( blessed( $response->body ) && $response->body->can('read') )
1824         {
1825             my $stat = stat $response->body;
1826             if ( $stat && $stat->size > 0 ) {
1827                 $response->content_length( $stat->size );
1828             }
1829             else {
1830                 $c->log->warn('Serving filehandle without a content-length');
1831             }
1832         }
1833         else {
1834             # everything should be bytes at this point, but just in case
1835             $response->content_length( length( $response->body ) );
1836         }
1837     }
1838
1839     # Errors
1840     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1841         $response->headers->remove_header("Content-Length");
1842         $response->body('');
1843     }
1844
1845     $c->finalize_cookies;
1846
1847     $c->engine->finalize_headers( $c, @_ );
1848
1849     # Done
1850     $response->finalized_headers(1);
1851 }
1852
1853 =head2 $c->finalize_output
1854
1855 An alias for finalize_body.
1856
1857 =head2 $c->finalize_read
1858
1859 Finalizes the input after reading is complete.
1860
1861 =cut
1862
1863 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1864
1865 =head2 $c->finalize_uploads
1866
1867 Finalizes uploads. Cleans up any temporary files.
1868
1869 =cut
1870
1871 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1872
1873 =head2 $c->get_action( $action, $namespace )
1874
1875 Gets an action in a given namespace.
1876
1877 =cut
1878
1879 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1880
1881 =head2 $c->get_actions( $action, $namespace )
1882
1883 Gets all actions of a given name in a namespace and all parent
1884 namespaces.
1885
1886 =cut
1887
1888 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1889
1890 =head2 $app->handle_request( @arguments )
1891
1892 Called to handle each HTTP request.
1893
1894 =cut
1895
1896 sub handle_request {
1897     my ( $class, @arguments ) = @_;
1898
1899     # Always expect worst case!
1900     my $status = -1;
1901     eval {
1902         if ($class->debug) {
1903             my $secs = time - $START || 1;
1904             my $av = sprintf '%.3f', $COUNT / $secs;
1905             my $time = localtime time;
1906             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1907         }
1908
1909         my $c = $class->prepare(@arguments);
1910         $c->dispatch;
1911         $status = $c->finalize;
1912     };
1913
1914     if ( my $error = $@ ) {
1915         chomp $error;
1916         $class->log->error(qq/Caught exception in engine "$error"/);
1917     }
1918
1919     $COUNT++;
1920
1921     if(my $coderef = $class->log->can('_flush')){
1922         $class->log->$coderef();
1923     }
1924     return $status;
1925 }
1926
1927 =head2 $c->prepare( @arguments )
1928
1929 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1930 etc.).
1931
1932 =cut
1933
1934 sub prepare {
1935     my ( $class, @arguments ) = @_;
1936
1937     # XXX
1938     # After the app/ctxt split, this should become an attribute based on something passed
1939     # into the application.
1940     $class->context_class( ref $class || $class ) unless $class->context_class;
1941
1942     my $c = $class->context_class->new({});
1943
1944     # For on-demand data
1945     $c->request->_context($c);
1946     $c->response->_context($c);
1947
1948     #surely this is not the most efficient way to do things...
1949     $c->stats($class->stats_class->new)->enable($c->use_stats);
1950     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1951         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1952     }
1953
1954     #XXX reuse coderef from can
1955     # Allow engine to direct the prepare flow (for POE)
1956     if ( $c->engine->can('prepare') ) {
1957         $c->engine->prepare( $c, @arguments );
1958     }
1959     else {
1960         $c->prepare_request(@arguments);
1961         $c->prepare_connection;
1962         $c->prepare_query_parameters;
1963         $c->prepare_headers;
1964         $c->prepare_cookies;
1965         $c->prepare_path;
1966
1967         # Prepare the body for reading, either by prepare_body
1968         # or the user, if they are using $c->read
1969         $c->prepare_read;
1970
1971         # Parse the body unless the user wants it on-demand
1972         unless ( ref($c)->config->{parse_on_demand} ) {
1973             $c->prepare_body;
1974         }
1975     }
1976
1977     my $method  = $c->req->method  || '';
1978     my $path    = $c->req->path;
1979     $path       = '/' unless length $path;
1980     my $address = $c->req->address || '';
1981
1982     $c->log_request;
1983
1984     $c->prepare_action;
1985
1986     return $c;
1987 }
1988
1989 =head2 $c->prepare_action
1990
1991 Prepares action. See L<Catalyst::Dispatcher>.
1992
1993 =cut
1994
1995 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1996
1997 =head2 $c->prepare_body
1998
1999 Prepares message body.
2000
2001 =cut
2002
2003 sub prepare_body {
2004     my $c = shift;
2005
2006     return if $c->request->_has_body;
2007
2008     # Initialize on-demand data
2009     $c->engine->prepare_body( $c, @_ );
2010     $c->prepare_parameters;
2011     $c->prepare_uploads;
2012 }
2013
2014 =head2 $c->prepare_body_chunk( $chunk )
2015
2016 Prepares a chunk of data before sending it to L<HTTP::Body>.
2017
2018 See L<Catalyst::Engine>.
2019
2020 =cut
2021
2022 sub prepare_body_chunk {
2023     my $c = shift;
2024     $c->engine->prepare_body_chunk( $c, @_ );
2025 }
2026
2027 =head2 $c->prepare_body_parameters
2028
2029 Prepares body parameters.
2030
2031 =cut
2032
2033 sub prepare_body_parameters {
2034     my $c = shift;
2035     $c->engine->prepare_body_parameters( $c, @_ );
2036 }
2037
2038 =head2 $c->prepare_connection
2039
2040 Prepares connection.
2041
2042 =cut
2043
2044 sub prepare_connection {
2045     my $c = shift;
2046     $c->engine->prepare_connection( $c, @_ );
2047 }
2048
2049 =head2 $c->prepare_cookies
2050
2051 Prepares cookies.
2052
2053 =cut
2054
2055 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2056
2057 =head2 $c->prepare_headers
2058
2059 Prepares headers.
2060
2061 =cut
2062
2063 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2064
2065 =head2 $c->prepare_parameters
2066
2067 Prepares parameters.
2068
2069 =cut
2070
2071 sub prepare_parameters {
2072     my $c = shift;
2073     $c->prepare_body_parameters;
2074     $c->engine->prepare_parameters( $c, @_ );
2075 }
2076
2077 =head2 $c->prepare_path
2078
2079 Prepares path and base.
2080
2081 =cut
2082
2083 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2084
2085 =head2 $c->prepare_query_parameters
2086
2087 Prepares query parameters.
2088
2089 =cut
2090
2091 sub prepare_query_parameters {
2092     my $c = shift;
2093
2094     $c->engine->prepare_query_parameters( $c, @_ );
2095 }
2096
2097 =head2 $c->log_request
2098
2099 Writes information about the request to the debug logs.  This includes:
2100
2101 =over 4
2102
2103 =item * Request method, path, and remote IP address
2104
2105 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2106
2107 =item * Request parameters
2108
2109 =item * File uploads
2110
2111 =back
2112
2113 =cut
2114
2115 sub log_request {
2116     my $c = shift;
2117
2118     return unless $c->debug;
2119
2120     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2121     my $request = $dump->[1];
2122
2123     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2124     $method ||= '';
2125     $path = '/' unless length $path;
2126     $address ||= '';
2127     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2128
2129     $c->log_request_headers($request->headers);
2130
2131     if ( my $keywords = $request->query_keywords ) {
2132         $c->log->debug("Query keywords are: $keywords");
2133     }
2134
2135     $c->log_request_parameters( query => $request->query_parameters, body => $request->body_parameters );
2136
2137     $c->log_request_uploads($request);
2138 }
2139
2140 =head2 $c->log_response
2141
2142 Writes information about the response to the debug logs by calling
2143 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2144
2145 =cut
2146
2147 sub log_response {
2148     my $c = shift;
2149
2150     return unless $c->debug;
2151
2152     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2153     my $response = $dump->[1];
2154
2155     $c->log_response_status_line($response);
2156     $c->log_response_headers($response->headers);
2157 }
2158
2159 =head2 $c->log_response_status_line($response)
2160
2161 Writes one line of information about the response to the debug logs.  This includes:
2162
2163 =over 4
2164
2165 =item * Response status code
2166
2167 =item * Content-Type header (if present)
2168
2169 =item * Content-Length header (if present)
2170
2171 =back
2172
2173 =cut
2174
2175 sub log_response_status_line {
2176     my ($c, $response) = @_;
2177
2178     $c->log->debug(
2179         sprintf(
2180             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2181             $response->status                            || 'unknown',
2182             $response->headers->header('Content-Type')   || 'unknown',
2183             $response->headers->header('Content-Length') || 'unknown'
2184         )
2185     );
2186 }
2187
2188 =head2 $c->log_response_headers($headers);
2189
2190 Hook method which can be wrapped by plugins to log the responseheaders.
2191 No-op in the default implementation.
2192
2193 =cut
2194
2195 sub log_response_headers {}
2196
2197 =head2 $c->log_request_parameters( query => {}, body => {} )
2198
2199 Logs request parameters to debug logs
2200
2201 =cut
2202
2203 sub log_request_parameters {
2204     my $c          = shift;
2205     my %all_params = @_;
2206
2207     return unless $c->debug;
2208
2209     my $column_width = Catalyst::Utils::term_width() - 44;
2210     foreach my $type (qw(query body)) {
2211         my $params = $all_params{$type};
2212         next if ! keys %$params;
2213         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2214         for my $key ( sort keys %$params ) {
2215             my $param = $params->{$key};
2216             my $value = defined($param) ? $param : '';
2217             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2218         }
2219         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2220     }
2221 }
2222
2223 =head2 $c->log_request_uploads
2224
2225 Logs file uploads included in the request to the debug logs.
2226 The parameter name, filename, file type, and file size are all included in
2227 the debug logs.
2228
2229 =cut
2230
2231 sub log_request_uploads {
2232     my $c = shift;
2233     my $request = shift;
2234     return unless $c->debug;
2235     my $uploads = $request->uploads;
2236     if ( keys %$uploads ) {
2237         my $t = Text::SimpleTable->new(
2238             [ 12, 'Parameter' ],
2239             [ 26, 'Filename' ],
2240             [ 18, 'Type' ],
2241             [ 9,  'Size' ]
2242         );
2243         for my $key ( sort keys %$uploads ) {
2244             my $upload = $uploads->{$key};
2245             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2246                 $t->row( $key, $u->filename, $u->type, $u->size );
2247             }
2248         }
2249         $c->log->debug( "File Uploads are:\n" . $t->draw );
2250     }
2251 }
2252
2253 =head2 $c->log_request_headers($headers);
2254
2255 Hook method which can be wrapped by plugins to log the request headers.
2256 No-op in the default implementation.
2257
2258 =cut
2259
2260 sub log_request_headers {}
2261
2262 =head2 $c->log_headers($type => $headers)
2263
2264 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2265
2266 =cut
2267
2268 sub log_headers {
2269     my $c       = shift;
2270     my $type    = shift;
2271     my $headers = shift;    # an HTTP::Headers instance
2272
2273     return unless $c->debug;
2274
2275     my $column_width = Catalyst::Utils::term_width() - 28;
2276     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2277     $headers->scan(
2278         sub {
2279             my ( $name, $value ) = @_;
2280             $t->row( $name, $value );
2281         }
2282     );
2283     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2284 }
2285
2286
2287 =head2 $c->prepare_read
2288
2289 Prepares the input for reading.
2290
2291 =cut
2292
2293 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2294
2295 =head2 $c->prepare_request
2296
2297 Prepares the engine request.
2298
2299 =cut
2300
2301 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2302
2303 =head2 $c->prepare_uploads
2304
2305 Prepares uploads.
2306
2307 =cut
2308
2309 sub prepare_uploads {
2310     my $c = shift;
2311
2312     $c->engine->prepare_uploads( $c, @_ );
2313 }
2314
2315 =head2 $c->prepare_write
2316
2317 Prepares the output for writing.
2318
2319 =cut
2320
2321 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2322
2323 =head2 $c->request_class
2324
2325 Returns or sets the request class.
2326
2327 =head2 $c->response_class
2328
2329 Returns or sets the response class.
2330
2331 =head2 $c->read( [$maxlength] )
2332
2333 Reads a chunk of data from the request body. This method is designed to
2334 be used in a while loop, reading C<$maxlength> bytes on every call.
2335 C<$maxlength> defaults to the size of the request if not specified.
2336
2337 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2338 directly.
2339
2340 Warning: If you use read(), Catalyst will not process the body,
2341 so you will not be able to access POST parameters or file uploads via
2342 $c->request.  You must handle all body parsing yourself.
2343
2344 =cut
2345
2346 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2347
2348 =head2 $c->run
2349
2350 Starts the engine.
2351
2352 =cut
2353
2354 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2355
2356 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2357
2358 Sets an action in a given namespace.
2359
2360 =cut
2361
2362 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2363
2364 =head2 $c->setup_actions($component)
2365
2366 Sets up actions for a component.
2367
2368 =cut
2369
2370 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2371
2372 =head2 $c->setup_components
2373
2374 This method is called internally to set up the application's components.
2375
2376 It finds modules by calling the L<locate_components> method, expands them to
2377 package names with the L<expand_component_module> method, and then installs
2378 each component into the application.
2379
2380 The C<setup_components> config option is passed to both of the above methods.
2381
2382 Installation of each component is performed by the L<setup_component> method,
2383 below.
2384
2385 =cut
2386
2387 sub setup_components {
2388     my $class = shift;
2389
2390     my $config  = $class->config->{ setup_components };
2391
2392     my @comps = sort { length $a <=> length $b }
2393                 $class->locate_components($config);
2394     my %comps = map { $_ => 1 } @comps;
2395
2396     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2397     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2398         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2399     ) if $deprecatedcatalyst_component_names;
2400
2401     for my $component ( @comps ) {
2402
2403         # We pass ignore_loaded here so that overlay files for (e.g.)
2404         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2405         # we know M::P::O found a file on disk so this is safe
2406
2407         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2408
2409         # Needs to be done as soon as the component is loaded, as loading a sub-component
2410         # (next time round the loop) can cause us to get the wrong metaclass..
2411         $class->_controller_init_base_classes($component);
2412     }
2413
2414     for my $component (@comps) {
2415         my $instance = $class->components->{ $component } = $class->setup_component($component);
2416         my @expanded_components = $instance->can('expand_modules')
2417             ? $instance->expand_modules( $component, $config )
2418             : $class->expand_component_module( $component, $config );
2419         for my $component (@expanded_components) {
2420             next if $comps{$component};
2421             $class->_controller_init_base_classes($component); # Also cover inner packages
2422             $class->components->{ $component } = $class->setup_component($component);
2423         }
2424     }
2425 }
2426
2427 =head2 $c->locate_components( $setup_component_config )
2428
2429 This method is meant to provide a list of component modules that should be
2430 setup for the application.  By default, it will use L<Module::Pluggable>.
2431
2432 Specify a C<setup_components> config option to pass additional options directly
2433 to L<Module::Pluggable>. To add additional search paths, specify a key named
2434 C<search_extra> as an array reference. Items in the array beginning with C<::>
2435 will have the application class name prepended to them.
2436
2437 =cut
2438
2439 sub locate_components {
2440     my $class  = shift;
2441     my $config = shift;
2442
2443     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2444     my $extra   = delete $config->{ search_extra } || [];
2445
2446     push @paths, @$extra;
2447
2448     my $locator = Module::Pluggable::Object->new(
2449         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2450         %$config
2451     );
2452
2453     my @comps = $locator->plugins;
2454
2455     return @comps;
2456 }
2457
2458 =head2 $c->expand_component_module( $component, $setup_component_config )
2459
2460 Components found by C<locate_components> will be passed to this method, which
2461 is expected to return a list of component (package) names to be set up.
2462
2463 =cut
2464
2465 sub expand_component_module {
2466     my ($class, $module) = @_;
2467     return Devel::InnerPackage::list_packages( $module );
2468 }
2469
2470 =head2 $c->setup_component
2471
2472 =cut
2473
2474 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2475 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2476 #         to be loaded. There are TODO tests in Moose for this, see
2477 #         f2391d17574eff81d911b97be15ea51080500003
2478 sub _controller_init_base_classes {
2479     my ($app_class, $component) = @_;
2480     return unless $component->isa('Catalyst::Controller');
2481     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2482         Moose::Meta::Class->initialize( $class )
2483             unless find_meta($class);
2484     }
2485 }
2486
2487 sub setup_component {
2488     my( $class, $component ) = @_;
2489
2490     unless ( $component->can( 'COMPONENT' ) ) {
2491         return $component;
2492     }
2493
2494     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2495     my $config = $class->config->{ $suffix } || {};
2496     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2497     # methods also pass it. local to avoid pointlessly shitting in config
2498     # for the debug screen, as $component is already the key name.
2499     local $config->{catalyst_component_name} = $component;
2500
2501     my $instance = eval { $component->COMPONENT( $class, $config ); };
2502
2503     if ( my $error = $@ ) {
2504         chomp $error;
2505         Catalyst::Exception->throw(
2506             message => qq/Couldn't instantiate component "$component", "$error"/
2507         );
2508     }
2509
2510     unless (blessed $instance) {
2511         my $metaclass = Moose::Util::find_meta($component);
2512         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2513         my $component_method_from = $method_meta->associated_metaclass->name;
2514         my $value = defined($instance) ? $instance : 'undef';
2515         Catalyst::Exception->throw(
2516             message =>
2517             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2518         );
2519     }
2520     return $instance;
2521 }
2522
2523 =head2 $c->setup_dispatcher
2524
2525 Sets up dispatcher.
2526
2527 =cut
2528
2529 sub setup_dispatcher {
2530     my ( $class, $dispatcher ) = @_;
2531
2532     if ($dispatcher) {
2533         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2534     }
2535
2536     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2537         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2538     }
2539
2540     unless ($dispatcher) {
2541         $dispatcher = $class->dispatcher_class;
2542     }
2543
2544     Class::MOP::load_class($dispatcher);
2545
2546     # dispatcher instance
2547     $class->dispatcher( $dispatcher->new );
2548 }
2549
2550 =head2 $c->setup_engine
2551
2552 Sets up engine.
2553
2554 =cut
2555
2556 sub setup_engine {
2557     my ( $class, $engine ) = @_;
2558
2559     if ($engine) {
2560         $engine = 'Catalyst::Engine::' . $engine;
2561     }
2562
2563     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2564         $engine = 'Catalyst::Engine::' . $env;
2565     }
2566
2567     if ( $ENV{MOD_PERL} ) {
2568         my $meta = Class::MOP::get_metaclass_by_name($class);
2569
2570         # create the apache method
2571         $meta->add_method('apache' => sub { shift->engine->apache });
2572
2573         my ( $software, $version ) =
2574           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2575
2576         $version =~ s/_//g;
2577         $version =~ s/(\.[^.]+)\./$1/g;
2578
2579         if ( $software eq 'mod_perl' ) {
2580
2581             if ( !$engine ) {
2582
2583                 if ( $version >= 1.99922 ) {
2584                     $engine = 'Catalyst::Engine::Apache2::MP20';
2585                 }
2586
2587                 elsif ( $version >= 1.9901 ) {
2588                     $engine = 'Catalyst::Engine::Apache2::MP19';
2589                 }
2590
2591                 elsif ( $version >= 1.24 ) {
2592                     $engine = 'Catalyst::Engine::Apache::MP13';
2593                 }
2594
2595                 else {
2596                     Catalyst::Exception->throw( message =>
2597                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2598                 }
2599
2600             }
2601
2602             # install the correct mod_perl handler
2603             if ( $version >= 1.9901 ) {
2604                 *handler = sub  : method {
2605                     shift->handle_request(@_);
2606                 };
2607             }
2608             else {
2609                 *handler = sub ($$) { shift->handle_request(@_) };
2610             }
2611
2612         }
2613
2614         elsif ( $software eq 'Zeus-Perl' ) {
2615             $engine = 'Catalyst::Engine::Zeus';
2616         }
2617
2618         else {
2619             Catalyst::Exception->throw(
2620                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2621         }
2622     }
2623
2624     unless ($engine) {
2625         $engine = $class->engine_class;
2626     }
2627
2628     Class::MOP::load_class($engine);
2629
2630     # check for old engines that are no longer compatible
2631     my $old_engine;
2632     if ( $engine->isa('Catalyst::Engine::Apache')
2633         && !Catalyst::Engine::Apache->VERSION )
2634     {
2635         $old_engine = 1;
2636     }
2637
2638     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2639         && Catalyst::Engine::Server->VERSION le '0.02' )
2640     {
2641         $old_engine = 1;
2642     }
2643
2644     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2645         && $engine->VERSION eq '0.01' )
2646     {
2647         $old_engine = 1;
2648     }
2649
2650     elsif ($engine->isa('Catalyst::Engine::Zeus')
2651         && $engine->VERSION eq '0.01' )
2652     {
2653         $old_engine = 1;
2654     }
2655
2656     if ($old_engine) {
2657         Catalyst::Exception->throw( message =>
2658               qq/Engine "$engine" is not supported by this version of Catalyst/
2659         );
2660     }
2661
2662     # engine instance
2663     $class->engine( $engine->new );
2664 }
2665
2666 =head2 $c->setup_home
2667
2668 Sets up the home directory.
2669
2670 =cut
2671
2672 sub setup_home {
2673     my ( $class, $home ) = @_;
2674
2675     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2676         $home = $env;
2677     }
2678
2679     $home ||= Catalyst::Utils::home($class);
2680
2681     if ($home) {
2682         #I remember recently being scolded for assigning config values like this
2683         $class->config->{home} ||= $home;
2684         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2685     }
2686 }
2687
2688 =head2 $c->setup_log
2689
2690 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2691 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2692 log to.
2693
2694 This method also installs a C<debug> method that returns a true value into the
2695 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2696 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2697
2698 Note that if the log has already been setup, by either a previous call to
2699 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2700 that this method won't actually set up the log object.
2701
2702 =cut
2703
2704 sub setup_log {
2705     my ( $class, $levels ) = @_;
2706
2707     $levels ||= '';
2708     $levels =~ s/^\s+//;
2709     $levels =~ s/\s+$//;
2710     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2711
2712     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2713     if ( defined $env_debug ) {
2714         $levels{debug} = 1 if $env_debug; # Ugly!
2715         delete($levels{debug}) unless $env_debug;
2716     }
2717
2718     unless ( $class->log ) {
2719         $class->log( Catalyst::Log->new(keys %levels) );
2720     }
2721
2722     if ( $levels{debug} ) {
2723         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2724         $class->log->debug('Debug messages enabled');
2725     }
2726 }
2727
2728 =head2 $c->setup_plugins
2729
2730 Sets up plugins.
2731
2732 =cut
2733
2734 =head2 $c->setup_stats
2735
2736 Sets up timing statistics class.
2737
2738 =cut
2739
2740 sub setup_stats {
2741     my ( $class, $stats ) = @_;
2742
2743     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2744
2745     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2746     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2747         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2748         $class->log->debug('Statistics enabled');
2749     }
2750 }
2751
2752
2753 =head2 $c->registered_plugins
2754
2755 Returns a sorted list of the plugins which have either been stated in the
2756 import list or which have been added via C<< MyApp->plugin(@args); >>.
2757
2758 If passed a given plugin name, it will report a boolean value indicating
2759 whether or not that plugin is loaded.  A fully qualified name is required if
2760 the plugin name does not begin with C<Catalyst::Plugin::>.
2761
2762  if ($c->registered_plugins('Some::Plugin')) {
2763      ...
2764  }
2765
2766 =cut
2767
2768 {
2769
2770     sub registered_plugins {
2771         my $proto = shift;
2772         return sort keys %{ $proto->_plugins } unless @_;
2773         my $plugin = shift;
2774         return 1 if exists $proto->_plugins->{$plugin};
2775         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2776     }
2777
2778     sub _register_plugin {
2779         my ( $proto, $plugin, $instant ) = @_;
2780         my $class = ref $proto || $proto;
2781
2782         Class::MOP::load_class( $plugin );
2783         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2784             if $plugin->isa( 'Catalyst::Component' );
2785         $proto->_plugins->{$plugin} = 1;
2786         unless ($instant) {
2787             my $meta = Class::MOP::get_metaclass_by_name($class);
2788             $meta->superclasses($plugin, $meta->superclasses);
2789         }
2790         return $class;
2791     }
2792
2793     sub setup_plugins {
2794         my ( $class, $plugins ) = @_;
2795
2796         $class->_plugins( {} ) unless $class->_plugins;
2797         $plugins = Data::OptList::mkopt($plugins || []);
2798
2799         my @plugins = map {
2800             [ Catalyst::Utils::resolve_namespace(
2801                   $class . '::Plugin',
2802                   'Catalyst::Plugin', $_->[0]
2803               ),
2804               $_->[1],
2805             ]
2806          } @{ $plugins };
2807
2808         for my $plugin ( reverse @plugins ) {
2809             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2810             my $meta = find_meta($plugin->[0]);
2811             next if $meta && $meta->isa('Moose::Meta::Role');
2812
2813             $class->_register_plugin($plugin->[0]);
2814         }
2815
2816         my @roles =
2817             map  { $_->[0]->name, $_->[1] }
2818             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2819             map  { [find_meta($_->[0]), $_->[1]] }
2820             @plugins;
2821
2822         Moose::Util::apply_all_roles(
2823             $class => @roles
2824         ) if @roles;
2825     }
2826 }
2827
2828 =head2 $c->stack
2829
2830 Returns an arrayref of the internal execution stack (actions that are
2831 currently executing).
2832
2833 =head2 $c->stats_class
2834
2835 Returns or sets the stats (timing statistics) class.
2836
2837 =head2 $c->use_stats
2838
2839 Returns 1 when stats collection is enabled.  Stats collection is enabled
2840 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2841 environment variable is set.
2842
2843 Note that this is a static method, not an accessor and should be overridden
2844 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2845
2846 =cut
2847
2848 sub use_stats { 0 }
2849
2850
2851 =head2 $c->write( $data )
2852
2853 Writes $data to the output stream. When using this method directly, you
2854 will need to manually set the C<Content-Length> header to the length of
2855 your output data, if known.
2856
2857 =cut
2858
2859 sub write {
2860     my $c = shift;
2861
2862     # Finalize headers if someone manually writes output
2863     $c->finalize_headers;
2864
2865     return $c->engine->write( $c, @_ );
2866 }
2867
2868 =head2 version
2869
2870 Returns the Catalyst version number. Mostly useful for "powered by"
2871 messages in template systems.
2872
2873 =cut
2874
2875 sub version { return $Catalyst::VERSION }
2876
2877 =head1 CONFIGURATION
2878
2879 There are a number of 'base' config variables which can be set:
2880
2881 =over
2882
2883 =item *
2884
2885 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2886
2887 =item *
2888
2889 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2890
2891 =item *
2892
2893 C<disable_component_resolution_regex_fallback> - Turns
2894 off the deprecated component resolution functionality so
2895 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2896 are called then regex search will not be attempted on string values and
2897 instead C<undef> will be returned.
2898
2899 =item *
2900
2901 C<home> - The application home directory. In an uninstalled application,
2902 this is the top level application directory. In an installed application,
2903 this will be the directory containing C<< MyApp.pm >>.
2904
2905 =item *
2906
2907 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2908
2909 =item *
2910
2911 C<name> - The name of the application in debug messages and the debug and
2912 welcome screens
2913
2914 =item *
2915
2916 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2917 until it is accessed. This allows you to (for example) check authentication (and reject
2918 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2919
2920 =item *
2921
2922 C<root> - The root directory for templates. Usually this is just a
2923 subdirectory of the home directory, but you can set it to change the
2924 templates to a different directory.
2925
2926 =item *
2927
2928 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2929 namespaces from which components will be loaded (and constructed and stored in
2930 C<< $c->components >>).
2931
2932 =item *
2933
2934 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2935 to be shown in hit debug tables in the test server.
2936
2937 =item *
2938
2939 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2940
2941 =back
2942
2943 =head1 INTERNAL ACTIONS
2944
2945 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2946 C<_ACTION>, and C<_END>. These are by default not shown in the private
2947 action table, but you can make them visible with a config parameter.
2948
2949     MyApp->config(show_internal_actions => 1);
2950
2951 =head1 ON-DEMAND PARSER
2952
2953 The request body is usually parsed at the beginning of a request,
2954 but if you want to handle input yourself, you can enable on-demand
2955 parsing with a config parameter.
2956
2957     MyApp->config(parse_on_demand => 1);
2958
2959 =head1 PROXY SUPPORT
2960
2961 Many production servers operate using the common double-server approach,
2962 with a lightweight frontend web server passing requests to a larger
2963 backend server. An application running on the backend server must deal
2964 with two problems: the remote user always appears to be C<127.0.0.1> and
2965 the server's hostname will appear to be C<localhost> regardless of the
2966 virtual host that the user connected through.
2967
2968 Catalyst will automatically detect this situation when you are running
2969 the frontend and backend servers on the same machine. The following
2970 changes are made to the request.
2971
2972     $c->req->address is set to the user's real IP address, as read from
2973     the HTTP X-Forwarded-For header.
2974
2975     The host value for $c->req->base and $c->req->uri is set to the real
2976     host, as read from the HTTP X-Forwarded-Host header.
2977
2978 Additionally, you may be running your backend application on an insecure
2979 connection (port 80) while your frontend proxy is running under SSL.  If there
2980 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2981 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2982 be created properly.
2983
2984 In the case of passing in:
2985
2986     X-Forwarded-Port: 443
2987
2988 All calls to C<uri_for> will result in an https link, as is expected.
2989
2990 Obviously, your web server must support these headers for this to work.
2991
2992 In a more complex server farm environment where you may have your
2993 frontend proxy server(s) on different machines, you will need to set a
2994 configuration option to tell Catalyst to read the proxied data from the
2995 headers.
2996
2997     MyApp->config(using_frontend_proxy => 1);
2998
2999 If you do not wish to use the proxy support at all, you may set:
3000
3001     MyApp->config(ignore_frontend_proxy => 1);
3002
3003 =head1 THREAD SAFETY
3004
3005 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3006 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3007 believe the Catalyst core to be thread-safe.
3008
3009 If you plan to operate in a threaded environment, remember that all other
3010 modules you are using must also be thread-safe. Some modules, most notably
3011 L<DBD::SQLite>, are not thread-safe.
3012
3013 =head1 SUPPORT
3014
3015 IRC:
3016
3017     Join #catalyst on irc.perl.org.
3018
3019 Mailing Lists:
3020
3021     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3022     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3023
3024 Web:
3025
3026     http://catalyst.perl.org
3027
3028 Wiki:
3029
3030     http://dev.catalyst.perl.org
3031
3032 =head1 SEE ALSO
3033
3034 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3035
3036 =head2 L<Catalyst::Manual> - The Catalyst Manual
3037
3038 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3039
3040 =head2 L<Catalyst::Engine> - Core engine
3041
3042 =head2 L<Catalyst::Log> - Log class.
3043
3044 =head2 L<Catalyst::Request> - Request object
3045
3046 =head2 L<Catalyst::Response> - Response object
3047
3048 =head2 L<Catalyst::Test> - The test suite.
3049
3050 =head1 PROJECT FOUNDER
3051
3052 sri: Sebastian Riedel <sri@cpan.org>
3053
3054 =head1 CONTRIBUTORS
3055
3056 abw: Andy Wardley
3057
3058 acme: Leon Brocard <leon@astray.com>
3059
3060 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3061
3062 Andrew Bramble
3063
3064 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3065
3066 Andrew Ruthven
3067
3068 andyg: Andy Grundman <andy@hybridized.org>
3069
3070 audreyt: Audrey Tang
3071
3072 bricas: Brian Cassidy <bricas@cpan.org>
3073
3074 Caelum: Rafael Kitover <rkitover@io.com>
3075
3076 chansen: Christian Hansen
3077
3078 chicks: Christopher Hicks
3079
3080 Chisel Wright C<pause@herlpacker.co.uk>
3081
3082 Danijel Milicevic C<me@danijel.de>
3083
3084 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3085
3086 David Naughton, C<naughton@umn.edu>
3087
3088 David E. Wheeler
3089
3090 dhoss: Devin Austin <dhoss@cpan.org>
3091
3092 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3093
3094 Drew Taylor
3095
3096 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3097
3098 esskar: Sascha Kiefer
3099
3100 fireartist: Carl Franks <cfranks@cpan.org>
3101
3102 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3103
3104 gabb: Danijel Milicevic
3105
3106 Gary Ashton Jones
3107
3108 Gavin Henry C<ghenry@perl.me.uk>
3109
3110 Geoff Richards
3111
3112 groditi: Guillermo Roditi <groditi@gmail.com>
3113
3114 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3115
3116 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3117
3118 jcamacho: Juan Camacho
3119
3120 jester: Jesse Sheidlower C<jester@panix.com>
3121
3122 jhannah: Jay Hannah <jay@jays.net>
3123
3124 Jody Belka
3125
3126 Johan Lindstrom
3127
3128 jon: Jon Schutz <jjschutz@cpan.org>
3129
3130 Jonathan Rockway C<< <jrockway@cpan.org> >>
3131
3132 Kieren Diment C<kd@totaldatasolution.com>
3133
3134 konobi: Scott McWhirter <konobi@cpan.org>
3135
3136 marcus: Marcus Ramberg <mramberg@cpan.org>
3137
3138 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3139
3140 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3141
3142 mugwump: Sam Vilain
3143
3144 naughton: David Naughton
3145
3146 ningu: David Kamholz <dkamholz@cpan.org>
3147
3148 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3149
3150 numa: Dan Sully <daniel@cpan.org>
3151
3152 obra: Jesse Vincent
3153
3154 Octavian Rasnita
3155
3156 omega: Andreas Marienborg
3157
3158 Oleg Kostyuk <cub.uanic@gmail.com>
3159
3160 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3161
3162 rafl: Florian Ragwitz <rafl@debian.org>
3163
3164 random: Roland Lammel <lammel@cpan.org>
3165
3166 Robert Sedlacek C<< <rs@474.at> >>
3167
3168 sky: Arthur Bergman
3169
3170 szbalint: Balint Szilakszi <szbalint@cpan.org>
3171
3172 t0m: Tomas Doran <bobtfish@bobtfish.net>
3173
3174 Ulf Edvinsson
3175
3176 Viljo Marrandi C<vilts@yahoo.com>
3177
3178 Will Hawes C<info@whawes.co.uk>
3179
3180 willert: Sebastian Willert <willert@cpan.org>
3181
3182 wreis: Wallace Reis <wallace@reis.org.br>
3183
3184 Yuval Kogman, C<nothingmuch@woobling.org>
3185
3186 =head1 LICENSE
3187
3188 This library is free software. You can redistribute it and/or modify it under
3189 the same terms as Perl itself.
3190
3191 =cut
3192
3193 no Moose;
3194
3195 __PACKAGE__->meta->make_immutable;
3196
3197 1;