lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use Scalar::Util qw/weaken blessed/;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use attributes;
  26 use utf8;
  27 use Carp qw/croak/;
  28
  29 BEGIN { require 5.008001; }
  30
  31 __PACKAGE__->mk_accessors(
  32     qw/counter request response state action stack namespace stats/
  33 );
  34
  35 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class setup_finished/;
  56
  57 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  58 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  59 __PACKAGE__->request_class('Catalyst::Request');
  60 __PACKAGE__->response_class('Catalyst::Response');
  61
  62 # Remember to update this in Catalyst::Runtime as well!
  63
  64 our $VERSION = '5.7001';
  65
  66 sub import {
  67     my ( $class, @arguments ) = @_;
  68
  69     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  70     # callers @ISA.
  71     return unless $class eq 'Catalyst';
  72
  73     my $caller = caller(0);
  74
  75     unless ( $caller->isa('Catalyst') ) {
  76         no strict 'refs';
  77         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  78     }
  79
  80     $caller->arguments( [@arguments] );
  81     $caller->setup_home;
  82 }
  83
  84 =head1 NAME
  85
  86 Catalyst - The Elegant MVC Web Application Framework
  87
  88 =head1 SYNOPSIS
  89
  90     # Install Catalyst::Devel for helpers and other development tools
  91     # use the helper to create a new application
  92     catalyst.pl MyApp
  93
  94     # add models, views, controllers
  95     script/myapp_create.pl model Database DBIC::SchemaLoader dbi:SQLite:/path/to/db
  96     script/myapp_create.pl view TT TT
  97     script/myapp_create.pl controller Search
  98
  99     # built in testserver -- use -r to restart automatically on changes
 100     script/myapp_server.pl
 101
 102     # command line testing interface
 103     script/myapp_test.pl /yada
 104
 105     ### in lib/MyApp.pm
 106     use Catalyst qw/-Debug/; # include plugins here as well
 107
 108         ### In lib/MyApp/Controller/Root.pm (autocreated)
 109     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 110         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 111         $c->stash->{template} = 'foo.tt'; # set the template
 112         # lookup something from db -- stash vars are passed to TT
 113         $c->stash->{data} =
 114           $c->model('Database::Foo')->search( { country => $args[0] } );
 115         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 116             $c->forward( 'bar' ); # process another action
 117             # do something else after forward returns
 118         }
 119     }
 120
 121     # The foo.tt TT template can use the stash data from the database
 122     [% WHILE (item = data.next) %]
 123         [% item.foo %]
 124     [% END %]
 125
 126     # called for /bar/of/soap, /bar/of/soap/10, etc.
 127     sub bar : Path('/bar/of/soap') { ... }
 128
 129     # called for all actions, from the top-most controller downwards
 130     sub auto : Private {
 131         my ( $self, $c ) = @_;
 132         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 133             $c->res->redirect( '/login' ); # require login
 134             return 0; # abort request and go immediately to end()
 135         }
 136         return 1; # success; carry on to next action
 137     }
 138
 139     # called after all actions are finished
 140     sub end : Private {
 141         my ( $self, $c ) = @_;
 142         if ( scalar @{ $c->error } ) { ... } # handle errors
 143         return if $c->res->body; # already have a response
 144         $c->forward( 'MyApp::View::TT' ); # render template
 145     }
 146
 147     ### in MyApp/Controller/Foo.pm
 148     # called for /foo/bar
 149     sub bar : Local { ... }
 150
 151     # called for /blargle
 152     sub blargle : Global { ... }
 153
 154     # an index action matches /foo, but not /foo/1, etc.
 155     sub index : Private { ... }
 156
 157     ### in MyApp/Controller/Foo/Bar.pm
 158     # called for /foo/bar/baz
 159     sub baz : Local { ... }
 160
 161     # first Root auto is called, then Foo auto, then this
 162     sub auto : Private { ... }
 163
 164     # powerful regular expression paths are also possible
 165     sub details : Regex('^product/(\w+)/details$') {
 166         my ( $self, $c ) = @_;
 167         # extract the (\w+) from the URI
 168         my $product = $c->req->captures->[0];
 169     }
 170
 171 See L<Catalyst::Manual::Intro> for additional information.
 172
 173 =head1 DESCRIPTION
 174
 175 Catalyst is a modern framework for making web applications without the
 176 pain usually associated with this process. This document is a reference
 177 to the main Catalyst application. If you are a new user, we suggest you
 178 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 179
 180 See L<Catalyst::Manual> for more documentation.
 181
 182 Catalyst plugins can be loaded by naming them as arguments to the "use
 183 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 184 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 185 C<My::Module>.
 186
 187     use Catalyst qw/My::Module/;
 188
 189 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 190 fully qualify the name by using a unary plus:
 191
 192     use Catalyst qw/
 193         My::Module
 194         +Fully::Qualified::Plugin::Name
 195     /;
 196
 197 Special flags like C<-Debug> and C<-Engine> can also be specified as
 198 arguments when Catalyst is loaded:
 199
 200     use Catalyst qw/-Debug My::Module/;
 201
 202 The position of plugins and flags in the chain is important, because
 203 they are loaded in the order in which they appear.
 204
 205 The following flags are supported:
 206
 207 =head2 -Debug
 208
 209 Enables debug output. You can also force this setting from the system
 210 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 211 settings override the application, with <MYAPP>_DEBUG having the highest
 212 priority.
 213
 214 =head2 -Engine
 215
 216 Forces Catalyst to use a specific engine. Omit the
 217 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 218
 219     use Catalyst qw/-Engine=CGI/;
 220
 221 =head2 -Home
 222
 223 Forces Catalyst to use a specific home directory, e.g.:
 224
 225     use Catalyst qw[-Home=/usr/mst];
 226
 227 =head2 -Log
 228
 229 Specifies log level.
 230
 231 =head1 METHODS
 232
 233 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 234
 235 =head2 $c->action
 236
 237 Returns a L<Catalyst::Action> object for the current action, which
 238 stringifies to the action name. See L<Catalyst::Action>.
 239
 240 =head2 $c->namespace
 241
 242 Returns the namespace of the current action, i.e., the URI prefix
 243 corresponding to the controller of the current action. For example:
 244
 245     # in Controller::Foo::Bar
 246     $c->namespace; # returns 'foo/bar';
 247
 248 =head2 $c->request
 249
 250 =head2 $c->req
 251
 252 Returns the current L<Catalyst::Request> object, giving access to
 253 information about the current client request (including parameters,
 254 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 255
 256 =head2 REQUEST FLOW HANDLING
 257
 258 =head2 $c->forward( $action [, \@arguments ] )
 259
 260 =head2 $c->forward( $class, $method, [, \@arguments ] )
 261
 262 Forwards processing to another action, by its private name. If you give a
 263 class name but no method, C<process()> is called. You may also optionally
 264 pass arguments in an arrayref. The action will receive the arguments in
 265 C<@_> and C<$c-E<gt>req-E<gt>args>. Upon returning from the function,
 266 C<$c-E<gt>req-E<gt>args> will be restored to the previous values.
 267
 268 Any data C<return>ed from the action forwarded to, will be returned by the
 269 call to forward.
 270
 271     my $foodata = $c->forward('/foo');
 272     $c->forward('index');
 273     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 274     $c->forward('MyApp::View::TT');
 275
 276 Note that forward implies an C<<eval { }>> around the call (actually
 277 C<execute> does), thus de-fatalizing all 'dies' within the called
 278 action. If you want C<die> to propagate you need to do something like:
 279
 280     $c->forward('foo');
 281     die $c->error if $c->error;
 282
 283 Or make sure to always return true values from your actions and write
 284 your code like this:
 285
 286     $c->forward('foo') || return;
 287
 288 =cut
 289
 290 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 291
 292 =head2 $c->detach( $action [, \@arguments ] )
 293
 294 =head2 $c->detach( $class, $method, [, \@arguments ] )
 295
 296 The same as C<forward>, but doesn't return to the previous action when
 297 processing is finished.
 298
 299 =cut
 300
 301 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 302
 303 =head2 $c->response
 304
 305 =head2 $c->res
 306
 307 Returns the current L<Catalyst::Response> object, q.v.
 308
 309 =head2 $c->stash
 310
 311 Returns a hashref to the stash, which may be used to store data and pass
 312 it between components during a request. You can also set hash keys by
 313 passing arguments. The stash is automatically sent to the view. The
 314 stash is cleared at the end of a request; it cannot be used for
 315 persistent storage (for this you must use a session; see
 316 L<Catalyst::Plugin::Session> for a complete system integrated with
 317 Catalyst).
 318
 319     $c->stash->{foo} = $bar;
 320     $c->stash( { moose => 'majestic', qux => 0 } );
 321     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 322
 323     # stash is automatically passed to the view for use in a template
 324     $c->forward( 'MyApp::V::TT' );
 325
 326 =cut
 327
 328 sub stash {
 329     my $c = shift;
 330     if (@_) {
 331         my $stash = @_ > 1 ? {@_} : $_[0];
 332         croak('stash takes a hash or hashref') unless ref $stash;
 333         foreach my $key ( keys %$stash ) {
 334             $c->{stash}->{$key} = $stash->{$key};
 335         }
 336     }
 337     return $c->{stash};
 338 }
 339
 340 =head2 $c->error
 341
 342 =head2 $c->error($error, ...)
 343
 344 =head2 $c->error($arrayref)
 345
 346 Returns an arrayref containing error messages.  If Catalyst encounters an
 347 error while processing a request, it stores the error in $c->error.  This
 348 method should not be used to store non-fatal error messages.
 349
 350     my @error = @{ $c->error };
 351
 352 Add a new error.
 353
 354     $c->error('Something bad happened');
 355
 356 =cut
 357
 358 sub error {
 359     my $c = shift;
 360     if ( $_[0] ) {
 361         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 362         croak @$error unless ref $c;
 363         push @{ $c->{error} }, @$error;
 364     }
 365     elsif ( defined $_[0] ) { $c->{error} = undef }
 366     return $c->{error} || [];
 367 }
 368
 369
 370 =head2 $c->state
 371
 372 Contains the return value of the last executed action.
 373
 374 =head2 $c->clear_errors
 375
 376 Clear errors.  You probably don't want to clear the errors unless you are
 377 implementing a custom error screen.
 378
 379 This is equivalent to running
 380
 381     $c->error(0);
 382
 383 =cut
 384
 385 sub clear_errors {
 386     my $c = shift;
 387     $c->error(0);
 388 }
 389
 390
 391 # search via regex
 392 sub _comp_search {
 393     my ( $c, @names ) = @_;
 394
 395     foreach my $name (@names) {
 396         foreach my $component ( keys %{ $c->components } ) {
 397             return $c->components->{$component} if $component =~ /$name/i;
 398         }
 399     }
 400
 401     return undef;
 402 }
 403
 404 # try explicit component names
 405 sub _comp_explicit {
 406     my ( $c, @names ) = @_;
 407
 408     foreach my $try (@names) {
 409         return $c->components->{$try} if ( exists $c->components->{$try} );
 410     }
 411
 412     return undef;
 413 }
 414
 415 # like component, but try just these prefixes before regex searching,
 416 #  and do not try to return "sort keys %{ $c->components }"
 417 sub _comp_prefixes {
 418     my ( $c, $name, @prefixes ) = @_;
 419
 420     my $appclass = ref $c || $c;
 421
 422     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 423
 424     my $comp = $c->_comp_explicit(@names);
 425     return $comp if defined($comp);
 426     $comp = $c->_comp_search($name);
 427     return $comp;
 428 }
 429
 430 # Find possible names for a prefix
 431
 432 sub _comp_names {
 433     my ( $c, @prefixes ) = @_;
 434
 435     my $appclass = ref $c || $c;
 436
 437     my @pre = map { "${appclass}::${_}::" } @prefixes;
 438
 439     my @names;
 440
 441     COMPONENT: foreach my $comp ($c->component) {
 442         foreach my $p (@pre) {
 443             if ($comp =~ s/^$p//) {
 444                 push(@names, $comp);
 445                 next COMPONENT;
 446             }
 447         }
 448     }
 449
 450     return @names;
 451 }
 452
 453 # Return a component if only one matches.
 454 sub _comp_singular {
 455     my ( $c, @prefixes ) = @_;
 456
 457     my $appclass = ref $c || $c;
 458
 459     my ( $comp, $rest ) =
 460       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 461     return $comp unless $rest;
 462 }
 463
 464 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 465 sub _filter_component {
 466     my ( $c, $comp, @args ) = @_;
 467     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 468         return $comp->ACCEPT_CONTEXT( $c, @args );
 469     }
 470     else { return $comp }
 471 }
 472
 473 =head2 COMPONENT ACCESSORS
 474
 475 =head2 $c->controller($name)
 476
 477 Gets a L<Catalyst::Controller> instance by name.
 478
 479     $c->controller('Foo')->do_stuff;
 480
 481 If the name is omitted, will return the controller for the dispatched
 482 action.
 483
 484 =cut
 485
 486 sub controller {
 487     my ( $c, $name, @args ) = @_;
 488     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 489         @args )
 490       if ($name);
 491     return $c->component( $c->action->class );
 492 }
 493
 494 =head2 $c->model($name)
 495
 496 Gets a L<Catalyst::Model> instance by name.
 497
 498     $c->model('Foo')->do_stuff;
 499
 500 If the name is omitted, it will look for a config setting 'default_model',
 501 or check if there is only one view, and return it if that's the case.
 502
 503 =cut
 504
 505 sub model {
 506     my ( $c, $name, @args ) = @_;
 507     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 508         @args )
 509       if $name;
 510     return $c->component( $c->config->{default_model} )
 511       if $c->config->{default_model};
 512     return $c->_filter_component( $c->_comp_singular(qw/Model M/), @args );
 513
 514 }
 515
 516 =head2 $c->controllers
 517
 518 Returns the available names which can be passed to $c->controller
 519
 520 =cut
 521
 522 sub controllers {
 523     my ( $c ) = @_;
 524     return $c->_comp_names(qw/Controller C/);
 525 }
 526
 527
 528 =head2 $c->view($name)
 529
 530 Gets a L<Catalyst::View> instance by name.
 531
 532     $c->view('Foo')->do_stuff;
 533
 534 If the name is omitted, it will look for a config setting
 535 'default_view', or check if there is only one view, and forward to it if
 536 that's the case.
 537
 538 =cut
 539
 540 sub view {
 541     my ( $c, $name, @args ) = @_;
 542     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 543         @args )
 544       if $name;
 545     return $c->component( $c->config->{default_view} )
 546       if $c->config->{default_view};
 547     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 548 }
 549
 550 =head2 $c->models
 551
 552 Returns the available names which can be passed to $c->model
 553
 554 =cut
 555
 556 sub models {
 557     my ( $c ) = @_;
 558     return $c->_comp_names(qw/Model M/);
 559 }
 560
 561
 562 =head2 $c->views
 563
 564 Returns the available names which can be passed to $c->view
 565
 566 =cut
 567
 568 sub views {
 569     my ( $c ) = @_;
 570     return $c->_comp_names(qw/View V/);
 571 }
 572
 573 =head2 $c->comp($name)
 574
 575 =head2 $c->component($name)
 576
 577 Gets a component object by name. This method is no longer recommended,
 578 unless you want to get a specific component by full
 579 class. C<$c-E<gt>controller>, C<$c-E<gt>model>, and C<$c-E<gt>view>
 580 should be used instead.
 581
 582 =cut
 583
 584 sub component {
 585     my $c = shift;
 586
 587     if (@_) {
 588
 589         my $name = shift;
 590
 591         my $appclass = ref $c || $c;
 592
 593         my @names = (
 594             $name, "${appclass}::${name}",
 595             map { "${appclass}::${_}::${name}" }
 596               qw/Model M Controller C View V/
 597         );
 598
 599         my $comp = $c->_comp_explicit(@names);
 600         return $c->_filter_component( $comp, @_ ) if defined($comp);
 601
 602         $comp = $c->_comp_search($name);
 603         return $c->_filter_component( $comp, @_ ) if defined($comp);
 604     }
 605
 606     return sort keys %{ $c->components };
 607 }
 608
 609
 610
 611 =head2 CLASS DATA AND HELPER CLASSES
 612
 613 =head2 $c->config
 614
 615 Returns or takes a hashref containing the application's configuration.
 616
 617     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 618
 619 You can also use a L<YAML> config file like myapp.yml in your
 620 applications home directory.
 621
 622     ---
 623     db: dsn:SQLite:foo.db
 624
 625
 626 =cut
 627
 628 sub config {
 629     my $c = shift;
 630
 631     $c->log->warn("Setting config after setup has been run is not a good idea.")
 632       if ( @_ and $c->setup_finished );
 633
 634     $c->NEXT::config(@_);
 635 }
 636
 637 =head2 $c->log
 638
 639 Returns the logging object instance. Unless it is already set, Catalyst
 640 sets this up with a L<Catalyst::Log> object. To use your own log class,
 641 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 642 C<< __PACKAGE__->setup >>.
 643
 644  __PACKAGE__->log( MyLogger->new );
 645  __PACKAGE__->setup;
 646
 647 And later:
 648
 649     $c->log->info( 'Now logging with my own logger!' );
 650
 651 Your log class should implement the methods described in
 652 L<Catalyst::Log>.
 653
 654
 655 =head2 $c->debug
 656
 657 Overload to enable debug messages (same as -Debug option).
 658
 659 Note that this is a static method, not an accessor and should be overloaded
 660 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 661
 662 =cut
 663
 664 sub debug { 0 }
 665
 666 =head2 $c->dispatcher
 667
 668 Returns the dispatcher instance. Stringifies to class name. See
 669 L<Catalyst::Dispatcher>.
 670
 671 =head2 $c->engine
 672
 673 Returns the engine instance. Stringifies to the class name. See
 674 L<Catalyst::Engine>.
 675
 676
 677 =head2 UTILITY METHODS
 678
 679 =head2 $c->path_to(@path)
 680
 681 Merges C<@path> with C<$c-E<gt>config-E<gt>{home}> and returns a
 682 L<Path::Class> object.
 683
 684 For example:
 685
 686     $c->path_to( 'db', 'sqlite.db' );
 687
 688 =cut
 689
 690 sub path_to {
 691     my ( $c, @path ) = @_;
 692     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 693     if ( -d $path ) { return $path }
 694     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 695 }
 696
 697 =head2 $c->plugin( $name, $class, @args )
 698
 699 Helper method for plugins. It creates a classdata accessor/mutator and
 700 loads and instantiates the given class.
 701
 702     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 703
 704     $c->prototype->define_javascript_functions;
 705
 706 =cut
 707
 708 sub plugin {
 709     my ( $class, $name, $plugin, @args ) = @_;
 710     $class->_register_plugin( $plugin, 1 );
 711
 712     eval { $plugin->import };
 713     $class->mk_classdata($name);
 714     my $obj;
 715     eval { $obj = $plugin->new(@args) };
 716
 717     if ($@) {
 718         Catalyst::Exception->throw( message =>
 719               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 720     }
 721
 722     $class->$name($obj);
 723     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 724       if $class->debug;
 725 }
 726
 727 =head2 MyApp->setup
 728
 729 Initializes the dispatcher and engine, loads any plugins, and loads the
 730 model, view, and controller components. You may also specify an array
 731 of plugins to load here, if you choose to not load them in the C<use
 732 Catalyst> line.
 733
 734     MyApp->setup;
 735     MyApp->setup( qw/-Debug/ );
 736
 737 =cut
 738
 739 sub setup {
 740     my ( $class, @arguments ) = @_;
 741
 742     $class->log->warn("Running setup twice is not a good idea.")
 743       if ( $class->setup_finished );
 744
 745     unless ( $class->isa('Catalyst') ) {
 746
 747         Catalyst::Exception->throw(
 748             message => qq/'$class' does not inherit from Catalyst/ );
 749     }
 750
 751     if ( $class->arguments ) {
 752         @arguments = ( @arguments, @{ $class->arguments } );
 753     }
 754
 755     # Process options
 756     my $flags = {};
 757
 758     foreach (@arguments) {
 759
 760         if (/^-Debug$/) {
 761             $flags->{log} =
 762               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 763         }
 764         elsif (/^-(\w+)=?(.*)$/) {
 765             $flags->{ lc $1 } = $2;
 766         }
 767         else {
 768             push @{ $flags->{plugins} }, $_;
 769         }
 770     }
 771
 772     $class->setup_home( delete $flags->{home} );
 773
 774     $class->setup_log( delete $flags->{log} );
 775     $class->setup_plugins( delete $flags->{plugins} );
 776     $class->setup_dispatcher( delete $flags->{dispatcher} );
 777     $class->setup_engine( delete $flags->{engine} );
 778
 779     for my $flag ( sort keys %{$flags} ) {
 780
 781         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 782             &$code( $class, delete $flags->{$flag} );
 783         }
 784         else {
 785             $class->log->warn(qq/Unknown flag "$flag"/);
 786         }
 787     }
 788
 789     eval { require Catalyst::Devel; };
 790     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 791         $class->log->warn(<<"EOF");
 792 You are running an old script!
 793
 794   Please update by running (this will overwrite existing files):
 795     catalyst.pl -force -scripts $class
 796
 797   or (this will not overwrite existing files):
 798     catalyst.pl -scripts $class
 799 EOF
 800     }
 801
 802     if ( $class->debug ) {
 803         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 804
 805         if (@plugins) {
 806             my $t = Text::SimpleTable->new(74);
 807             $t->row($_) for @plugins;
 808             $class->log->debug( "Loaded plugins:\n" . $t->draw );
 809         }
 810
 811         my $dispatcher = $class->dispatcher;
 812         my $engine     = $class->engine;
 813         my $home       = $class->config->{home};
 814
 815         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 816         $class->log->debug(qq/Loaded engine "$engine"/);
 817
 818         $home
 819           ? ( -d $home )
 820           ? $class->log->debug(qq/Found home "$home"/)
 821           : $class->log->debug(qq/Home "$home" doesn't exist/)
 822           : $class->log->debug(q/Couldn't find home/);
 823     }
 824
 825     # Call plugins setup
 826     {
 827         no warnings qw/redefine/;
 828         local *setup = sub { };
 829         $class->setup;
 830     }
 831
 832     # Initialize our data structure
 833     $class->components( {} );
 834
 835     $class->setup_components;
 836
 837     if ( $class->debug ) {
 838         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 839         for my $comp ( sort keys %{ $class->components } ) {
 840             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 841             $t->row( $comp, $type );
 842         }
 843         $class->log->debug( "Loaded components:\n" . $t->draw )
 844           if ( keys %{ $class->components } );
 845     }
 846
 847     # Add our self to components, since we are also a component
 848     $class->components->{$class} = $class;
 849
 850     $class->setup_actions;
 851
 852     if ( $class->debug ) {
 853         my $name = $class->config->{name} || 'Application';
 854         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 855     }
 856     $class->log->_flush() if $class->log->can('_flush');
 857
 858     $class->setup_finished(1);
 859 }
 860
 861 =head2 $c->uri_for( $path, @args?, \%query_values? )
 862
 863 Merges path with C<< $c->request->base >> for absolute URIs and with
 864 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 865 object. If any args are passed, they are added at the end of the path.
 866 If the last argument to C<uri_for> is a hash reference, it is assumed to
 867 contain GET parameter key/value pairs, which will be appended to the URI
 868 in standard fashion.
 869
 870 Instead of C<$path>, you can also optionally pass a C<$action> object
 871 which will be resolved to a path using
 872 C<< $c->dispatcher->uri_for_action >>; if the first element of
 873 C<@args> is an arrayref it is treated as a list of captures to be passed
 874 to C<uri_for_action>.
 875
 876 =cut
 877
 878 sub uri_for {
 879     my ( $c, $path, @args ) = @_;
 880     my $base     = $c->request->base->clone;
 881     my $basepath = $base->path;
 882     $basepath =~ s/\/$//;
 883     $basepath .= '/';
 884     my $namespace = $c->namespace || '';
 885
 886     if ( Scalar::Util::blessed($path) ) { # action object
 887         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 888                          ? shift(@args)
 889                          : [] );
 890         $path = $c->dispatcher->uri_for_action($path, $captures);
 891         return undef unless defined($path);
 892         $path = '/' if $path eq '';
 893     }
 894
 895     # massage namespace, empty if absolute path
 896     $namespace =~ s/^\/// if $namespace;
 897     $namespace .= '/' if $namespace;
 898     $path ||= '';
 899     $namespace = '' if $path =~ /^\//;
 900     $path =~ s/^\///;
 901
 902     my $params =
 903       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 904
 905     for my $value ( values %$params ) {
 906         for ( ref $value eq 'ARRAY' ? @$value : $value ) {
 907             $_ = "$_";
 908             utf8::encode( $_ );
 909         }
 910     };
 911
 912     # join args with '/', or a blank string
 913     my $args = ( scalar @args ? '/' . join( '/', @args ) : '' );
 914     $args =~ s/^\/// unless $path;
 915     my $res =
 916       URI->new_abs( URI->new_abs( "$path$args", "$basepath$namespace" ), $base )
 917       ->canonical;
 918     $res->query_form(%$params);
 919     $res;
 920 }
 921
 922 =head2 $c->welcome_message
 923
 924 Returns the Catalyst welcome HTML page.
 925
 926 =cut
 927
 928 sub welcome_message {
 929     my $c      = shift;
 930     my $name   = $c->config->{name};
 931     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
 932     my $prefix = Catalyst::Utils::appprefix( ref $c );
 933     $c->response->content_type('text/html; charset=utf-8');
 934     return <<"EOF";
 935 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
 936     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 937 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 938     <head>
 939         <meta http-equiv="Content-Language" content="en" />
 940         <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
 941         <title>$name on Catalyst $VERSION</title>
 942         <style type="text/css">
 943             body {
 944                 color: #000;
 945                 background-color: #eee;
 946             }
 947             div#content {
 948                 width: 640px;
 949                 margin-left: auto;
 950                 margin-right: auto;
 951                 margin-top: 10px;
 952                 margin-bottom: 10px;
 953                 text-align: left;
 954                 background-color: #ccc;
 955                 border: 1px solid #aaa;
 956             }
 957             p, h1, h2 {
 958                 margin-left: 20px;
 959                 margin-right: 20px;
 960                 font-family: verdana, tahoma, sans-serif;
 961             }
 962             a {
 963                 font-family: verdana, tahoma, sans-serif;
 964             }
 965             :link, :visited {
 966                     text-decoration: none;
 967                     color: #b00;
 968                     border-bottom: 1px dotted #bbb;
 969             }
 970             :link:hover, :visited:hover {
 971                     color: #555;
 972             }
 973             div#topbar {
 974                 margin: 0px;
 975             }
 976             pre {
 977                 margin: 10px;
 978                 padding: 8px;
 979             }
 980             div#answers {
 981                 padding: 8px;
 982                 margin: 10px;
 983                 background-color: #fff;
 984                 border: 1px solid #aaa;
 985             }
 986             h1 {
 987                 font-size: 0.9em;
 988                 font-weight: normal;
 989                 text-align: center;
 990             }
 991             h2 {
 992                 font-size: 1.0em;
 993             }
 994             p {
 995                 font-size: 0.9em;
 996             }
 997             p img {
 998                 float: right;
 999                 margin-left: 10px;
1000             }
1001             span#appname {
1002                 font-weight: bold;
1003                 font-size: 1.6em;
1004             }
1005         </style>
1006     </head>
1007     <body>
1008         <div id="content">
1009             <div id="topbar">
1010                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1011                     $VERSION</h1>
1012              </div>
1013              <div id="answers">
1014                  <p>
1015                  <img src="$logo" alt="Catalyst Logo" />
1016                  </p>
1017                  <p>Welcome to the wonderful world of Catalyst.
1018                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1019                     framework will make web development something you had
1020                     never expected it to be: Fun, rewarding, and quick.</p>
1021                  <h2>What to do now?</h2>
1022                  <p>That really depends  on what <b>you</b> want to do.
1023                     We do, however, provide you with a few starting points.</p>
1024                  <p>If you want to jump right into web development with Catalyst
1025                     you might want to check out the documentation.</p>
1026                  <pre><code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1027 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1028 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual.pod">Catalyst::Manual</a></code></pre>
1029                  <h2>What to do next?</h2>
1030                  <p>Next it's time to write an actual application. Use the
1031                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1032                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1033                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1034                     they can save you a lot of work.</p>
1035                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1036                     <p>Also, be sure to check out the vast and growing
1037                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1038                     you are likely to find what you need there.
1039                     </p>
1040
1041                  <h2>Need help?</h2>
1042                  <p>Catalyst has a very active community. Here are the main places to
1043                     get in touch with us.</p>
1044                  <ul>
1045                      <li>
1046                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1047                      </li>
1048                      <li>
1049                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1050                      </li>
1051                      <li>
1052                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1053                      </li>
1054                  </ul>
1055                  <h2>In conclusion</h2>
1056                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1057                     as we enjoyed making it. Please contact us if you have ideas
1058                     for improvement or other feedback.</p>
1059              </div>
1060          </div>
1061     </body>
1062 </html>
1063 EOF
1064 }
1065
1066 =head1 INTERNAL METHODS
1067
1068 These methods are not meant to be used by end users.
1069
1070 =head2 $c->components
1071
1072 Returns a hash of components.
1073
1074 =head2 $c->context_class
1075
1076 Returns or sets the context class.
1077
1078 =head2 $c->counter
1079
1080 Returns a hashref containing coderefs and execution counts (needed for
1081 deep recursion detection).
1082
1083 =head2 $c->depth
1084
1085 Returns the number of actions on the current internal execution stack.
1086
1087 =head2 $c->dispatch
1088
1089 Dispatches a request to actions.
1090
1091 =cut
1092
1093 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1094
1095 =head2 $c->dispatcher_class
1096
1097 Returns or sets the dispatcher class.
1098
1099 =head2 $c->dump_these
1100
1101 Returns a list of 2-element array references (name, structure) pairs
1102 that will be dumped on the error page in debug mode.
1103
1104 =cut
1105
1106 sub dump_these {
1107     my $c = shift;
1108     [ Request => $c->req ],
1109     [ Response => $c->res ],
1110     [ Stash => $c->stash ],
1111     [ Config => $c->config ];
1112 }
1113
1114 =head2 $c->engine_class
1115
1116 Returns or sets the engine class.
1117
1118 =head2 $c->execute( $class, $coderef )
1119
1120 Execute a coderef in given class and catch exceptions. Errors are available
1121 via $c->error.
1122
1123 =cut
1124
1125 sub execute {
1126     my ( $c, $class, $code ) = @_;
1127     $class = $c->component($class) || $class;
1128     $c->state(0);
1129
1130     if ( $c->depth >= $RECURSION ) {
1131         my $action = "$code";
1132         $action = "/$action" unless $action =~ /->/;
1133         my $error = qq/Deep recursion detected calling "$action"/;
1134         $c->log->error($error);
1135         $c->error($error);
1136         $c->state(0);
1137         return $c->state;
1138     }
1139
1140     my $stats_info = $c->_stats_start_execute( $code ) if $c->debug;
1141
1142     push( @{ $c->stack }, $code );
1143
1144     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1145
1146     $c->_stats_finish_execute( $stats_info ) if $c->debug and $stats_info;
1147
1148     my $last = pop( @{ $c->stack } );
1149
1150     if ( my $error = $@ ) {
1151         if ( !ref($error) and $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1152         else {
1153             unless ( ref $error ) {
1154                 no warnings 'uninitialized';
1155                 chomp $error;
1156                 my $class = $last->class;
1157                 my $name  = $last->name;
1158                 $error = qq/Caught exception in $class->$name "$error"/;
1159             }
1160             $c->error($error);
1161             $c->state(0);
1162         }
1163     }
1164     return $c->state;
1165 }
1166
1167 sub _stats_start_execute {
1168     my ( $c, $code ) = @_;
1169
1170     return if ( ( $code->name =~ /^_.*/ )
1171         && ( !$c->config->{show_internal_actions} ) );
1172
1173     $c->counter->{"$code"}++;
1174
1175     my $action = "$code";
1176     $action = "/$action" unless $action =~ /->/;
1177
1178     # determine if the call was the result of a forward
1179     # this is done by walking up the call stack and looking for a calling
1180     # sub of Catalyst::forward before the eval
1181     my $callsub = q{};
1182     for my $index ( 2 .. 11 ) {
1183         last
1184         if ( ( caller($index) )[0] eq 'Catalyst'
1185             && ( caller($index) )[3] eq '(eval)' );
1186
1187         if ( ( caller($index) )[3] =~ /forward$/ ) {
1188             $callsub = ( caller($index) )[3];
1189             $action  = "-> $action";
1190             last;
1191         }
1192     }
1193
1194     my $node = Tree::Simple->new(
1195         {
1196             action  => $action,
1197             elapsed => undef,     # to be filled in later
1198             comment => "",
1199         }
1200     );
1201     $node->setUID( "$code" . $c->counter->{"$code"} );
1202
1203     # is this a root-level call or a forwarded call?
1204     if ( $callsub =~ /forward$/ ) {
1205
1206         # forward, locate the caller
1207         if ( my $parent = $c->stack->[-1] ) {
1208             my $visitor = Tree::Simple::Visitor::FindByUID->new;
1209             $visitor->searchForUID(
1210                 "$parent" . $c->counter->{"$parent"} );
1211             $c->stats->accept($visitor);
1212             if ( my $result = $visitor->getResult ) {
1213                 $result->addChild($node);
1214             }
1215         }
1216         else {
1217
1218             # forward with no caller may come from a plugin
1219             $c->stats->addChild($node);
1220         }
1221     }
1222     else {
1223
1224         # root-level call
1225         $c->stats->addChild($node);
1226     }
1227
1228     return {
1229         start   => [gettimeofday],
1230         node    => $node,
1231     };
1232 }
1233
1234 sub _stats_finish_execute {
1235     my ( $c, $info ) = @_;
1236     my $elapsed = tv_interval $info->{start};
1237     my $value = $info->{node}->getNodeValue;
1238     $value->{elapsed} = sprintf( '%fs', $elapsed );
1239 }
1240
1241 =head2 $c->_localize_fields( sub { }, \%keys );
1242
1243 =cut
1244
1245 sub _localize_fields {
1246     my ( $c, $localized, $code ) = ( @_ );
1247
1248     my $request = delete $localized->{request} || {};
1249     my $response = delete $localized->{response} || {};
1250
1251     local @{ $c }{ keys %$localized } = values %$localized;
1252     local @{ $c->request }{ keys %$request } = values %$request;
1253     local @{ $c->response }{ keys %$response } = values %$response;
1254
1255     $code->();
1256 }
1257
1258 =head2 $c->finalize
1259
1260 Finalizes the request.
1261
1262 =cut
1263
1264 sub finalize {
1265     my $c = shift;
1266
1267     for my $error ( @{ $c->error } ) {
1268         $c->log->error($error);
1269     }
1270
1271     # Allow engine to handle finalize flow (for POE)
1272     if ( $c->engine->can('finalize') ) {
1273         $c->engine->finalize($c);
1274     }
1275     else {
1276
1277         $c->finalize_uploads;
1278
1279         # Error
1280         if ( $#{ $c->error } >= 0 ) {
1281             $c->finalize_error;
1282         }
1283
1284         $c->finalize_headers;
1285
1286         # HEAD request
1287         if ( $c->request->method eq 'HEAD' ) {
1288             $c->response->body('');
1289         }
1290
1291         $c->finalize_body;
1292     }
1293
1294     return $c->response->status;
1295 }
1296
1297 =head2 $c->finalize_body
1298
1299 Finalizes body.
1300
1301 =cut
1302
1303 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1304
1305 =head2 $c->finalize_cookies
1306
1307 Finalizes cookies.
1308
1309 =cut
1310
1311 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1312
1313 =head2 $c->finalize_error
1314
1315 Finalizes error.
1316
1317 =cut
1318
1319 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1320
1321 =head2 $c->finalize_headers
1322
1323 Finalizes headers.
1324
1325 =cut
1326
1327 sub finalize_headers {
1328     my $c = shift;
1329
1330     # Check if we already finalized headers
1331     return if $c->response->{_finalized_headers};
1332
1333     # Handle redirects
1334     if ( my $location = $c->response->redirect ) {
1335         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1336         $c->response->header( Location => $location );
1337     }
1338
1339     # Content-Length
1340     if ( $c->response->body && !$c->response->content_length ) {
1341
1342         # get the length from a filehandle
1343         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1344         {
1345             if ( my $stat = stat $c->response->body ) {
1346                 $c->response->content_length( $stat->size );
1347             }
1348             else {
1349                 $c->log->warn('Serving filehandle without a content-length');
1350             }
1351         }
1352         else {
1353             $c->response->content_length( bytes::length( $c->response->body ) );
1354         }
1355     }
1356
1357     # Errors
1358     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1359         $c->response->headers->remove_header("Content-Length");
1360         $c->response->body('');
1361     }
1362
1363     $c->finalize_cookies;
1364
1365     $c->engine->finalize_headers( $c, @_ );
1366
1367     # Done
1368     $c->response->{_finalized_headers} = 1;
1369 }
1370
1371 =head2 $c->finalize_output
1372
1373 An alias for finalize_body.
1374
1375 =head2 $c->finalize_read
1376
1377 Finalizes the input after reading is complete.
1378
1379 =cut
1380
1381 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1382
1383 =head2 $c->finalize_uploads
1384
1385 Finalizes uploads. Cleans up any temporary files.
1386
1387 =cut
1388
1389 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1390
1391 =head2 $c->get_action( $action, $namespace )
1392
1393 Gets an action in a given namespace.
1394
1395 =cut
1396
1397 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1398
1399 =head2 $c->get_actions( $action, $namespace )
1400
1401 Gets all actions of a given name in a namespace and all parent
1402 namespaces.
1403
1404 =cut
1405
1406 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1407
1408 =head2 $c->handle_request( $class, @arguments )
1409
1410 Called to handle each HTTP request.
1411
1412 =cut
1413
1414 sub handle_request {
1415     my ( $class, @arguments ) = @_;
1416
1417     # Always expect worst case!
1418     my $status = -1;
1419     eval {
1420         if ($class->debug) {
1421             my $start = [gettimeofday];
1422             my $c = $class->prepare(@arguments);
1423             $c->stats(Tree::Simple->new);
1424             $c->dispatch;
1425             $status = $c->finalize;
1426
1427             my $elapsed = tv_interval $start;
1428             $elapsed = sprintf '%f', $elapsed;
1429             my $av = sprintf '%.3f',
1430               ( $elapsed == 0 ? '??' : ( 1 / $elapsed ) );
1431             my $t = Text::SimpleTable->new( [ 62, 'Action' ], [ 9, 'Time' ] );
1432
1433             $c->stats->traverse(
1434                 sub {
1435                     my $action = shift;
1436                     my $stat   = $action->getNodeValue;
1437                     $t->row( ( q{ } x $action->getDepth ) . $stat->{action} . $stat->{comment},
1438                         $stat->{elapsed} || '??' );
1439                 }
1440             );
1441
1442             $class->log->info(
1443                 "Request took ${elapsed}s ($av/s)\n" . $t->draw );
1444         }
1445         else {
1446             my $c = $class->prepare(@arguments);
1447             $c->dispatch;
1448             $status = $c->finalize;
1449         }
1450     };
1451
1452     if ( my $error = $@ ) {
1453         chomp $error;
1454         $class->log->error(qq/Caught exception in engine "$error"/);
1455     }
1456
1457     $COUNT++;
1458     $class->log->_flush() if $class->log->can('_flush');
1459     return $status;
1460 }
1461
1462 =head2 $c->prepare( @arguments )
1463
1464 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1465 etc.).
1466
1467 =cut
1468
1469 sub prepare {
1470     my ( $class, @arguments ) = @_;
1471
1472     $class->context_class( ref $class || $class ) unless $class->context_class;
1473     my $c = $class->context_class->new(
1474         {
1475             counter => {},
1476             stack   => [],
1477             request => $class->request_class->new(
1478                 {
1479                     arguments        => [],
1480                     body_parameters  => {},
1481                     cookies          => {},
1482                     headers          => HTTP::Headers->new,
1483                     parameters       => {},
1484                     query_parameters => {},
1485                     secure           => 0,
1486                     captures         => [],
1487                     uploads          => {}
1488                 }
1489             ),
1490             response => $class->response_class->new(
1491                 {
1492                     body    => '',
1493                     cookies => {},
1494                     headers => HTTP::Headers->new(),
1495                     status  => 200
1496                 }
1497             ),
1498             stash => {},
1499             state => 0
1500         }
1501     );
1502
1503     # For on-demand data
1504     $c->request->{_context}  = $c;
1505     $c->response->{_context} = $c;
1506     weaken( $c->request->{_context} );
1507     weaken( $c->response->{_context} );
1508
1509     if ( $c->debug ) {
1510         my $secs = time - $START || 1;
1511         my $av = sprintf '%.3f', $COUNT / $secs;
1512         my $time = localtime time;
1513         $c->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1514         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1515     }
1516
1517     # Allow engine to direct the prepare flow (for POE)
1518     if ( $c->engine->can('prepare') ) {
1519         $c->engine->prepare( $c, @arguments );
1520     }
1521     else {
1522         $c->prepare_request(@arguments);
1523         $c->prepare_connection;
1524         $c->prepare_query_parameters;
1525         $c->prepare_headers;
1526         $c->prepare_cookies;
1527         $c->prepare_path;
1528
1529         # On-demand parsing
1530         $c->prepare_body unless $c->config->{parse_on_demand};
1531     }
1532
1533     my $method  = $c->req->method  || '';
1534     my $path    = $c->req->path    || '/';
1535     my $address = $c->req->address || '';
1536
1537     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1538       if $c->debug;
1539
1540     $c->prepare_action;
1541
1542     return $c;
1543 }
1544
1545 =head2 $c->prepare_action
1546
1547 Prepares action. See L<Catalyst::Dispatcher>.
1548
1549 =cut
1550
1551 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1552
1553 =head2 $c->prepare_body
1554
1555 Prepares message body.
1556
1557 =cut
1558
1559 sub prepare_body {
1560     my $c = shift;
1561
1562     # Do we run for the first time?
1563     return if defined $c->request->{_body};
1564
1565     # Initialize on-demand data
1566     $c->engine->prepare_body( $c, @_ );
1567     $c->prepare_parameters;
1568     $c->prepare_uploads;
1569
1570     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1571         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1572         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1573             my $param = $c->req->body_parameters->{$key};
1574             my $value = defined($param) ? $param : '';
1575             $t->row( $key,
1576                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1577         }
1578         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1579     }
1580 }
1581
1582 =head2 $c->prepare_body_chunk( $chunk )
1583
1584 Prepares a chunk of data before sending it to L<HTTP::Body>.
1585
1586 See L<Catalyst::Engine>.
1587
1588 =cut
1589
1590 sub prepare_body_chunk {
1591     my $c = shift;
1592     $c->engine->prepare_body_chunk( $c, @_ );
1593 }
1594
1595 =head2 $c->prepare_body_parameters
1596
1597 Prepares body parameters.
1598
1599 =cut
1600
1601 sub prepare_body_parameters {
1602     my $c = shift;
1603     $c->engine->prepare_body_parameters( $c, @_ );
1604 }
1605
1606 =head2 $c->prepare_connection
1607
1608 Prepares connection.
1609
1610 =cut
1611
1612 sub prepare_connection {
1613     my $c = shift;
1614     $c->engine->prepare_connection( $c, @_ );
1615 }
1616
1617 =head2 $c->prepare_cookies
1618
1619 Prepares cookies.
1620
1621 =cut
1622
1623 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1624
1625 =head2 $c->prepare_headers
1626
1627 Prepares headers.
1628
1629 =cut
1630
1631 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1632
1633 =head2 $c->prepare_parameters
1634
1635 Prepares parameters.
1636
1637 =cut
1638
1639 sub prepare_parameters {
1640     my $c = shift;
1641     $c->prepare_body_parameters;
1642     $c->engine->prepare_parameters( $c, @_ );
1643 }
1644
1645 =head2 $c->prepare_path
1646
1647 Prepares path and base.
1648
1649 =cut
1650
1651 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1652
1653 =head2 $c->prepare_query_parameters
1654
1655 Prepares query parameters.
1656
1657 =cut
1658
1659 sub prepare_query_parameters {
1660     my $c = shift;
1661
1662     $c->engine->prepare_query_parameters( $c, @_ );
1663
1664     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1665         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1666         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1667             my $param = $c->req->query_parameters->{$key};
1668             my $value = defined($param) ? $param : '';
1669             $t->row( $key,
1670                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1671         }
1672         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1673     }
1674 }
1675
1676 =head2 $c->prepare_read
1677
1678 Prepares the input for reading.
1679
1680 =cut
1681
1682 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1683
1684 =head2 $c->prepare_request
1685
1686 Prepares the engine request.
1687
1688 =cut
1689
1690 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1691
1692 =head2 $c->prepare_uploads
1693
1694 Prepares uploads.
1695
1696 =cut
1697
1698 sub prepare_uploads {
1699     my $c = shift;
1700
1701     $c->engine->prepare_uploads( $c, @_ );
1702
1703     if ( $c->debug && keys %{ $c->request->uploads } ) {
1704         my $t = Text::SimpleTable->new(
1705             [ 12, 'Parameter' ],
1706             [ 26, 'Filename' ],
1707             [ 18, 'Type' ],
1708             [ 9,  'Size' ]
1709         );
1710         for my $key ( sort keys %{ $c->request->uploads } ) {
1711             my $upload = $c->request->uploads->{$key};
1712             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1713                 $t->row( $key, $u->filename, $u->type, $u->size );
1714             }
1715         }
1716         $c->log->debug( "File Uploads are:\n" . $t->draw );
1717     }
1718 }
1719
1720 =head2 $c->prepare_write
1721
1722 Prepares the output for writing.
1723
1724 =cut
1725
1726 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1727
1728 =head2 $c->request_class
1729
1730 Returns or sets the request class.
1731
1732 =head2 $c->response_class
1733
1734 Returns or sets the response class.
1735
1736 =head2 $c->read( [$maxlength] )
1737
1738 Reads a chunk of data from the request body. This method is designed to
1739 be used in a while loop, reading C<$maxlength> bytes on every call.
1740 C<$maxlength> defaults to the size of the request if not specified.
1741
1742 You have to set C<MyApp-E<gt>config-E<gt>{parse_on_demand}> to use this
1743 directly.
1744
1745 =cut
1746
1747 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1748
1749 =head2 $c->run
1750
1751 Starts the engine.
1752
1753 =cut
1754
1755 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1756
1757 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1758
1759 Sets an action in a given namespace.
1760
1761 =cut
1762
1763 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1764
1765 =head2 $c->setup_actions($component)
1766
1767 Sets up actions for a component.
1768
1769 =cut
1770
1771 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1772
1773 =head2 $c->setup_components
1774
1775 Sets up components. Specify a C<setup_components> config option to pass
1776 additional options directly to L<Module::Pluggable>. To add additional
1777 search paths, specify a key named C<search_extra> as an array
1778 reference. Items in the array beginning with C<::> will have the
1779 application class name prepended to them.
1780
1781 =cut
1782
1783 sub setup_components {
1784     my $class = shift;
1785
1786     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1787     my $config  = $class->config->{ setup_components };
1788     my $extra   = delete $config->{ search_extra } || [];
1789
1790     push @paths, @$extra;
1791
1792     my $locator = Module::Pluggable::Object->new(
1793         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1794         %$config
1795     );
1796
1797     for my $component ( sort { length $a <=> length $b } $locator->plugins ) {
1798         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1799
1800         my $module  = $class->setup_component( $component );
1801         my %modules = (
1802             $component => $module,
1803             map {
1804                 $_ => $class->setup_component( $_ )
1805             } Devel::InnerPackage::list_packages( $component )
1806         );
1807
1808         for my $key ( keys %modules ) {
1809             $class->components->{ $key } = $modules{ $key };
1810         }
1811     }
1812 }
1813
1814 =head2 $c->setup_component
1815
1816 =cut
1817
1818 sub setup_component {
1819     my( $class, $component ) = @_;
1820
1821     unless ( $component->can( 'COMPONENT' ) ) {
1822         return $component;
1823     }
1824
1825     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1826     my $config = $class->config->{ $suffix } || {};
1827
1828     my $instance = eval { $component->COMPONENT( $class, $config ); };
1829
1830     if ( my $error = $@ ) {
1831         chomp $error;
1832         Catalyst::Exception->throw(
1833             message => qq/Couldn't instantiate component "$component", "$error"/
1834         );
1835     }
1836
1837     Catalyst::Exception->throw(
1838         message =>
1839         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1840     ) unless eval { $instance->can( 'can' ) };
1841
1842     return $instance;
1843 }
1844
1845 =head2 $c->setup_dispatcher
1846
1847 Sets up dispatcher.
1848
1849 =cut
1850
1851 sub setup_dispatcher {
1852     my ( $class, $dispatcher ) = @_;
1853
1854     if ($dispatcher) {
1855         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1856     }
1857
1858     if ( $ENV{CATALYST_DISPATCHER} ) {
1859         $dispatcher = 'Catalyst::Dispatcher::' . $ENV{CATALYST_DISPATCHER};
1860     }
1861
1862     if ( $ENV{ uc($class) . '_DISPATCHER' } ) {
1863         $dispatcher =
1864           'Catalyst::Dispatcher::' . $ENV{ uc($class) . '_DISPATCHER' };
1865     }
1866
1867     unless ($dispatcher) {
1868         $dispatcher = $class->dispatcher_class;
1869     }
1870
1871     unless (Class::Inspector->loaded($dispatcher)) {
1872         require Class::Inspector->filename($dispatcher);
1873     }
1874
1875     # dispatcher instance
1876     $class->dispatcher( $dispatcher->new );
1877 }
1878
1879 =head2 $c->setup_engine
1880
1881 Sets up engine.
1882
1883 =cut
1884
1885 sub setup_engine {
1886     my ( $class, $engine ) = @_;
1887
1888     if ($engine) {
1889         $engine = 'Catalyst::Engine::' . $engine;
1890     }
1891
1892     if ( $ENV{CATALYST_ENGINE} ) {
1893         $engine = 'Catalyst::Engine::' . $ENV{CATALYST_ENGINE};
1894     }
1895
1896     if ( $ENV{ uc($class) . '_ENGINE' } ) {
1897         $engine = 'Catalyst::Engine::' . $ENV{ uc($class) . '_ENGINE' };
1898     }
1899
1900     if ( $ENV{MOD_PERL} ) {
1901
1902         # create the apache method
1903         {
1904             no strict 'refs';
1905             *{"$class\::apache"} = sub { shift->engine->apache };
1906         }
1907
1908         my ( $software, $version ) =
1909           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1910
1911         $version =~ s/_//g;
1912         $version =~ s/(\.[^.]+)\./$1/g;
1913
1914         if ( $software eq 'mod_perl' ) {
1915
1916             if ( !$engine ) {
1917
1918                 if ( $version >= 1.99922 ) {
1919                     $engine = 'Catalyst::Engine::Apache2::MP20';
1920                 }
1921
1922                 elsif ( $version >= 1.9901 ) {
1923                     $engine = 'Catalyst::Engine::Apache2::MP19';
1924                 }
1925
1926                 elsif ( $version >= 1.24 ) {
1927                     $engine = 'Catalyst::Engine::Apache::MP13';
1928                 }
1929
1930                 else {
1931                     Catalyst::Exception->throw( message =>
1932                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
1933                 }
1934
1935             }
1936
1937             # install the correct mod_perl handler
1938             if ( $version >= 1.9901 ) {
1939                 *handler = sub  : method {
1940                     shift->handle_request(@_);
1941                 };
1942             }
1943             else {
1944                 *handler = sub ($$) { shift->handle_request(@_) };
1945             }
1946
1947         }
1948
1949         elsif ( $software eq 'Zeus-Perl' ) {
1950             $engine = 'Catalyst::Engine::Zeus';
1951         }
1952
1953         else {
1954             Catalyst::Exception->throw(
1955                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
1956         }
1957     }
1958
1959     unless ($engine) {
1960         $engine = $class->engine_class;
1961     }
1962
1963     unless (Class::Inspector->loaded($engine)) {
1964         require Class::Inspector->filename($engine);
1965     }
1966
1967     # check for old engines that are no longer compatible
1968     my $old_engine;
1969     if ( $engine->isa('Catalyst::Engine::Apache')
1970         && !Catalyst::Engine::Apache->VERSION )
1971     {
1972         $old_engine = 1;
1973     }
1974
1975     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
1976         && Catalyst::Engine::Server->VERSION le '0.02' )
1977     {
1978         $old_engine = 1;
1979     }
1980
1981     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
1982         && $engine->VERSION eq '0.01' )
1983     {
1984         $old_engine = 1;
1985     }
1986
1987     elsif ($engine->isa('Catalyst::Engine::Zeus')
1988         && $engine->VERSION eq '0.01' )
1989     {
1990         $old_engine = 1;
1991     }
1992
1993     if ($old_engine) {
1994         Catalyst::Exception->throw( message =>
1995               qq/Engine "$engine" is not supported by this version of Catalyst/
1996         );
1997     }
1998
1999     # engine instance
2000     $class->engine( $engine->new );
2001 }
2002
2003 =head2 $c->setup_home
2004
2005 Sets up the home directory.
2006
2007 =cut
2008
2009 sub setup_home {
2010     my ( $class, $home ) = @_;
2011
2012     if ( $ENV{CATALYST_HOME} ) {
2013         $home = $ENV{CATALYST_HOME};
2014     }
2015
2016     if ( $ENV{ uc($class) . '_HOME' } ) {
2017         $home = $ENV{ uc($class) . '_HOME' };
2018     }
2019
2020     unless ($home) {
2021         $home = Catalyst::Utils::home($class);
2022     }
2023
2024     if ($home) {
2025         $class->config->{home} ||= $home;
2026         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2027     }
2028 }
2029
2030 =head2 $c->setup_log
2031
2032 Sets up log.
2033
2034 =cut
2035
2036 sub setup_log {
2037     my ( $class, $debug ) = @_;
2038
2039     unless ( $class->log ) {
2040         $class->log( Catalyst::Log->new );
2041     }
2042
2043     my $app_flag = Catalyst::Utils::class2env($class) . '_DEBUG';
2044
2045     if (
2046           ( defined( $ENV{CATALYST_DEBUG} ) || defined( $ENV{$app_flag} ) )
2047         ? ( $ENV{CATALYST_DEBUG} || $ENV{$app_flag} )
2048         : $debug
2049       )
2050     {
2051         no strict 'refs';
2052         *{"$class\::debug"} = sub { 1 };
2053         $class->log->debug('Debug messages enabled');
2054     }
2055 }
2056
2057 =head2 $c->setup_plugins
2058
2059 Sets up plugins.
2060
2061 =cut
2062
2063 =head2 $c->registered_plugins
2064
2065 Returns a sorted list of the plugins which have either been stated in the
2066 import list or which have been added via C<< MyApp->plugin(@args); >>.
2067
2068 If passed a given plugin name, it will report a boolean value indicating
2069 whether or not that plugin is loaded.  A fully qualified name is required if
2070 the plugin name does not begin with C<Catalyst::Plugin::>.
2071
2072  if ($c->registered_plugins('Some::Plugin')) {
2073      ...
2074  }
2075
2076 =cut
2077
2078 {
2079
2080     sub registered_plugins {
2081         my $proto = shift;
2082         return sort keys %{ $proto->_plugins } unless @_;
2083         my $plugin = shift;
2084         return 1 if exists $proto->_plugins->{$plugin};
2085         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2086     }
2087
2088     sub _register_plugin {
2089         my ( $proto, $plugin, $instant ) = @_;
2090         my $class = ref $proto || $proto;
2091
2092         unless (Class::Inspector->loaded($plugin)) {
2093             require Class::Inspector->filename($plugin);
2094         }
2095
2096         $proto->_plugins->{$plugin} = 1;
2097         unless ($instant) {
2098             no strict 'refs';
2099             unshift @{"$class\::ISA"}, $plugin;
2100         }
2101         return $class;
2102     }
2103
2104     sub setup_plugins {
2105         my ( $class, $plugins ) = @_;
2106
2107         $class->_plugins( {} ) unless $class->_plugins;
2108         $plugins ||= [];
2109         for my $plugin ( reverse @$plugins ) {
2110
2111             unless ( $plugin =~ s/\A\+// ) {
2112                 $plugin = "Catalyst::Plugin::$plugin";
2113             }
2114
2115             $class->_register_plugin($plugin);
2116         }
2117     }
2118 }
2119
2120 =head2 $c->stack
2121
2122 Returns an arrayref of the internal execution stack (actions that are
2123 currently executing).
2124
2125 =head2 $c->write( $data )
2126
2127 Writes $data to the output stream. When using this method directly, you
2128 will need to manually set the C<Content-Length> header to the length of
2129 your output data, if known.
2130
2131 =cut
2132
2133 sub write {
2134     my $c = shift;
2135
2136     # Finalize headers if someone manually writes output
2137     $c->finalize_headers;
2138
2139     return $c->engine->write( $c, @_ );
2140 }
2141
2142 =head2 version
2143
2144 Returns the Catalyst version number. Mostly useful for "powered by"
2145 messages in template systems.
2146
2147 =cut
2148
2149 sub version { return $Catalyst::VERSION }
2150
2151 =head1 INTERNAL ACTIONS
2152
2153 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2154 C<_ACTION>, and C<_END>. These are by default not shown in the private
2155 action table, but you can make them visible with a config parameter.
2156
2157     MyApp->config->{show_internal_actions} = 1;
2158
2159 =head1 CASE SENSITIVITY
2160
2161 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2162 mapped to C</foo/bar>. You can activate case sensitivity with a config
2163 parameter.
2164
2165     MyApp->config->{case_sensitive} = 1;
2166
2167 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2168
2169 =head1 ON-DEMAND PARSER
2170
2171 The request body is usually parsed at the beginning of a request,
2172 but if you want to handle input yourself or speed things up a bit,
2173 you can enable on-demand parsing with a config parameter.
2174
2175     MyApp->config->{parse_on_demand} = 1;
2176
2177 =head1 PROXY SUPPORT
2178
2179 Many production servers operate using the common double-server approach,
2180 with a lightweight frontend web server passing requests to a larger
2181 backend server. An application running on the backend server must deal
2182 with two problems: the remote user always appears to be C<127.0.0.1> and
2183 the server's hostname will appear to be C<localhost> regardless of the
2184 virtual host that the user connected through.
2185
2186 Catalyst will automatically detect this situation when you are running
2187 the frontend and backend servers on the same machine. The following
2188 changes are made to the request.
2189
2190     $c->req->address is set to the user's real IP address, as read from
2191     the HTTP X-Forwarded-For header.
2192
2193     The host value for $c->req->base and $c->req->uri is set to the real
2194     host, as read from the HTTP X-Forwarded-Host header.
2195
2196 Obviously, your web server must support these headers for this to work.
2197
2198 In a more complex server farm environment where you may have your
2199 frontend proxy server(s) on different machines, you will need to set a
2200 configuration option to tell Catalyst to read the proxied data from the
2201 headers.
2202
2203     MyApp->config->{using_frontend_proxy} = 1;
2204
2205 If you do not wish to use the proxy support at all, you may set:
2206
2207     MyApp->config->{ignore_frontend_proxy} = 1;
2208
2209 =head1 THREAD SAFETY
2210
2211 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2212 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2213 believe the Catalyst core to be thread-safe.
2214
2215 If you plan to operate in a threaded environment, remember that all other
2216 modules you are using must also be thread-safe. Some modules, most notably
2217 L<DBD::SQLite>, are not thread-safe.
2218
2219 =head1 SUPPORT
2220
2221 IRC:
2222
2223     Join #catalyst on irc.perl.org.
2224
2225 Mailing Lists:
2226
2227     http://lists.rawmode.org/mailman/listinfo/catalyst
2228     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2229
2230 Web:
2231
2232     http://catalyst.perl.org
2233
2234 Wiki:
2235
2236     http://dev.catalyst.perl.org
2237
2238 =head1 SEE ALSO
2239
2240 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2241
2242 =head2 L<Catalyst::Manual> - The Catalyst Manual
2243
2244 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2245
2246 =head2 L<Catalyst::Engine> - Core engine
2247
2248 =head2 L<Catalyst::Log> - Log class.
2249
2250 =head2 L<Catalyst::Request> - Request object
2251
2252 =head2 L<Catalyst::Response> - Response object
2253
2254 =head2 L<Catalyst::Test> - The test suite.
2255
2256 =head1 CREDITS
2257
2258 Andy Grundman
2259
2260 Andy Wardley
2261
2262 Andreas Marienborg
2263
2264 Andrew Bramble
2265
2266 Andrew Ford
2267
2268 Andrew Ruthven
2269
2270 Arthur Bergman
2271
2272 Autrijus Tang
2273
2274 Brian Cassidy
2275
2276 Carl Franks
2277
2278 Christian Hansen
2279
2280 Christopher Hicks
2281
2282 Dan Sully
2283
2284 Danijel Milicevic
2285
2286 David Kamholz
2287
2288 David Naughton
2289
2290 Drew Taylor
2291
2292 Gary Ashton Jones
2293
2294 Geoff Richards
2295
2296 Jesse Sheidlower
2297
2298 Jesse Vincent
2299
2300 Jody Belka
2301
2302 Johan Lindstrom
2303
2304 Juan Camacho
2305
2306 Leon Brocard
2307
2308 Marcus Ramberg
2309
2310 Matt S Trout
2311
2312 Robert Sedlacek
2313
2314 Sam Vilain
2315
2316 Sascha Kiefer
2317
2318 Tatsuhiko Miyagawa
2319
2320 Ulf Edvinsson
2321
2322 Yuval Kogman
2323
2324 =head1 AUTHOR
2325
2326 Sebastian Riedel, C<sri@oook.de>
2327
2328 =head1 LICENSE
2329
2330 This library is free software, you can redistribute it and/or modify it under
2331 the same terms as Perl itself.
2332
2333 =cut
2334
2335 1;