lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object;
  16 use NEXT;
  17 use Text::SimpleTable;
  18 use Path::Class::Dir;
  19 use Path::Class::File;
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI;
  22 use Scalar::Util qw/weaken blessed/;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use attributes;
  26 use utf8;
  27 use Carp qw/croak/;
  28
  29 BEGIN { require 5.008001; }
  30
  31 __PACKAGE__->mk_accessors(
  32     qw/counter request response state action stack namespace stats/
  33 );
  34
  35 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class setup_finished/;
  56
  57 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  58 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  59 __PACKAGE__->request_class('Catalyst::Request');
  60 __PACKAGE__->response_class('Catalyst::Response');
  61
  62 # Remember to update this in Catalyst::Runtime as well!
  63
  64 our $VERSION = '5.70_03';
  65
  66 sub import {
  67     my ( $class, @arguments ) = @_;
  68
  69     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  70     # callers @ISA.
  71     return unless $class eq 'Catalyst';
  72
  73     my $caller = caller(0);
  74
  75     unless ( $caller->isa('Catalyst') ) {
  76         no strict 'refs';
  77         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  78     }
  79
  80     $caller->arguments( [@arguments] );
  81     $caller->setup_home;
  82 }
  83
  84 =head1 NAME
  85
  86 Catalyst - The Elegant MVC Web Application Framework
  87
  88 =head1 SYNOPSIS
  89
  90     # use the helper to create a new application
  91     catalyst.pl MyApp
  92
  93     # add models, views, controllers
  94     script/myapp_create.pl model Database DBIC::SchemaLoader dbi:SQLite:/path/to/db
  95     script/myapp_create.pl view TT TT
  96     script/myapp_create.pl controller Search
  97
  98     # built in testserver -- use -r to restart automatically on changes
  99     script/myapp_server.pl
 100
 101     # command line testing interface
 102     script/myapp_test.pl /yada
 103
 104     ### in lib/MyApp.pm
 105     use Catalyst qw/-Debug/; # include plugins here as well
 106
 107         ### In lib/MyApp/Controller/Root.pm (autocreated)
 108     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 109         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 110         $c->stash->{template} = 'foo.tt'; # set the template
 111         # lookup something from db -- stash vars are passed to TT
 112         $c->stash->{data} =
 113           $c->model('Database::Foo')->search( { country => $args[0] } );
 114         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 115             $c->forward( 'bar' ); # process another action
 116             # do something else after forward returns
 117         }
 118     }
 119
 120     # The foo.tt TT template can use the stash data from the database
 121     [% WHILE (item = data.next) %]
 122         [% item.foo %]
 123     [% END %]
 124
 125     # called for /bar/of/soap, /bar/of/soap/10, etc.
 126     sub bar : Path('/bar/of/soap') { ... }
 127
 128     # called for all actions, from the top-most controller downwards
 129     sub auto : Private {
 130         my ( $self, $c ) = @_;
 131         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 132             $c->res->redirect( '/login' ); # require login
 133             return 0; # abort request and go immediately to end()
 134         }
 135         return 1; # success; carry on to next action
 136     }
 137
 138     # called after all actions are finished
 139     sub end : Private {
 140         my ( $self, $c ) = @_;
 141         if ( scalar @{ $c->error } ) { ... } # handle errors
 142         return if $c->res->body; # already have a response
 143         $c->forward( 'MyApp::View::TT' ); # render template
 144     }
 145
 146     ### in MyApp/Controller/Foo.pm
 147     # called for /foo/bar
 148     sub bar : Local { ... }
 149
 150     # called for /blargle
 151     sub blargle : Global { ... }
 152
 153     # an index action matches /foo, but not /foo/1, etc.
 154     sub index : Private { ... }
 155
 156     ### in MyApp/Controller/Foo/Bar.pm
 157     # called for /foo/bar/baz
 158     sub baz : Local { ... }
 159
 160     # first Root auto is called, then Foo auto, then this
 161     sub auto : Private { ... }
 162
 163     # powerful regular expression paths are also possible
 164     sub details : Regex('^product/(\w+)/details$') {
 165         my ( $self, $c ) = @_;
 166         # extract the (\w+) from the URI
 167         my $product = $c->req->captures->[0];
 168     }
 169
 170 See L<Catalyst::Manual::Intro> for additional information.
 171
 172 =head1 DESCRIPTION
 173
 174 Catalyst is a modern framework for making web applications without the pain usually associated with this process. This document is a reference to the main Catalyst application. If you are a new user, we suggest you start with L<Catalyst::Manual::Tutorial> or  L<Catalyst::Manual::Intro>
 175
 176 See L<Catalyst::Manual> for more documentation.
 177
 178 Catalyst plugins can be loaded by naming them as arguments to the "use
 179 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 180 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 181 C<My::Module>.
 182
 183     use Catalyst qw/My::Module/;
 184
 185 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 186 fully qualify the name by using a unary plus:
 187
 188     use Catalyst qw/
 189         My::Module
 190         +Fully::Qualified::Plugin::Name
 191     /;
 192
 193 Special flags like C<-Debug> and C<-Engine> can also be specified as
 194 arguments when Catalyst is loaded:
 195
 196     use Catalyst qw/-Debug My::Module/;
 197
 198 The position of plugins and flags in the chain is important, because
 199 they are loaded in exactly the order in which they appear.
 200
 201 The following flags are supported:
 202
 203 =head2 -Debug
 204
 205 Enables debug output. You can also force this setting from the system
 206 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment settings
 207 override the app, with <MYAPP>_DEBUG having highest priority.
 208
 209 =head2 -Engine
 210
 211 Forces Catalyst to use a specific engine. Omit the
 212 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 213
 214     use Catalyst qw/-Engine=CGI/;
 215
 216 =head2 -Home
 217
 218 Forces Catalyst to use a specific home directory, e.g.:
 219
 220     use Catalyst qw[-Home=/usr/sri];
 221
 222 =head2 -Log
 223
 224 Specifies log level.
 225
 226 =head1 METHODS
 227
 228 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 229
 230 =head2 $c->action
 231
 232 Returns a L<Catalyst::Action> object for the current action, which
 233 stringifies to the action name. See L<Catalyst::Action>.
 234
 235 =head2 $c->namespace
 236
 237 Returns the namespace of the current action, i.e., the uri prefix
 238 corresponding to the controller of the current action. For example:
 239
 240     # in Controller::Foo::Bar
 241     $c->namespace; # returns 'foo/bar';
 242
 243 =head2 $c->request
 244
 245 =head2 $c->req
 246
 247 Returns the current L<Catalyst::Request> object. See
 248 L<Catalyst::Request>.
 249
 250 =head2 REQUEST FLOW HANDLING
 251
 252 =head2 $c->forward( $action [, \@arguments ] )
 253
 254 =head2 $c->forward( $class, $method, [, \@arguments ] )
 255
 256 Forwards processing to another action, by it's private name. If you give a
 257 class name but no method, C<process()> is called. You may also optionally
 258 pass arguments in an arrayref. The action will receive the arguments in
 259 C<@_> and C<$c-E<gt>req-E<gt>args>. Upon returning from the function,
 260 C<$c-E<gt>req-E<gt>args> will be restored to the previous values.
 261
 262 Any data C<return>ed from the action forwarded to, will be returned by the
 263 call to forward.
 264
 265     my $foodata = $c->forward('/foo');
 266     $c->forward('index');
 267     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 268     $c->forward('MyApp::View::TT');
 269
 270 Note that forward implies an C<<eval { }>> around the call (well, actually
 271 C<execute> does), thus de-fatalizing all 'dies' within the called action. If
 272 you want C<die> to propagate you need to do something like:
 273
 274     $c->forward('foo');
 275     die $c->error if $c->error;
 276
 277 Or make sure to always return true values from your actions and write your code
 278 like this:
 279
 280     $c->forward('foo') || return;
 281
 282 =cut
 283
 284 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 285
 286 =head2 $c->detach( $action [, \@arguments ] )
 287
 288 =head2 $c->detach( $class, $method, [, \@arguments ] )
 289
 290 The same as C<forward>, but doesn't return to the previous action when
 291 processing is finished.
 292
 293 =cut
 294
 295 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 296
 297 =head2 $c->response
 298
 299 =head2 $c->res
 300
 301 Returns the current L<Catalyst::Response> object.
 302
 303 =head2 $c->stash
 304
 305 Returns a hashref to the stash, which may be used to store data and pass
 306 it between components during a request. You can also set hash keys by
 307 passing arguments. The stash is automatically sent to the view. The
 308 stash is cleared at the end of a request; it cannot be used for
 309 persistent storage.
 310
 311     $c->stash->{foo} = $bar;
 312     $c->stash( { moose => 'majestic', qux => 0 } );
 313     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 314
 315     # stash is automatically passed to the view for use in a template
 316     $c->forward( 'MyApp::V::TT' );
 317
 318 =cut
 319
 320 sub stash {
 321     my $c = shift;
 322     if (@_) {
 323         my $stash = @_ > 1 ? {@_} : $_[0];
 324         croak('stash takes a hash or hashref') unless ref $stash;
 325         foreach my $key ( keys %$stash ) {
 326             $c->{stash}->{$key} = $stash->{$key};
 327         }
 328     }
 329     return $c->{stash};
 330 }
 331
 332 =head2 $c->error
 333
 334 =head2 $c->error($error, ...)
 335
 336 =head2 $c->error($arrayref)
 337
 338 Returns an arrayref containing error messages.  If Catalyst encounters an
 339 error while processing a request, it stores the error in $c->error.  This
 340 method should not be used to store non-fatal error messages.
 341
 342     my @error = @{ $c->error };
 343
 344 Add a new error.
 345
 346     $c->error('Something bad happened');
 347
 348 =cut
 349
 350 sub error {
 351     my $c = shift;
 352     if ( $_[0] ) {
 353         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 354         croak @$error unless ref $c;
 355         push @{ $c->{error} }, @$error;
 356     }
 357     elsif ( defined $_[0] ) { $c->{error} = undef }
 358     return $c->{error} || [];
 359 }
 360
 361
 362 =head2 $c->state
 363
 364 Contains the return value of the last executed action.
 365
 366 =head2 $c->clear_errors
 367
 368 Clear errors.  You probably don't want to clear the errors unless you are
 369 implementing a custom error screen.
 370
 371 This is equivalent to running
 372
 373     $c->error(0);
 374
 375 =cut
 376
 377 sub clear_errors {
 378     my $c = shift;
 379     $c->error(0);
 380 }
 381
 382
 383
 384
 385 # search via regex
 386 sub _comp_search {
 387     my ( $c, @names ) = @_;
 388
 389     foreach my $name (@names) {
 390         foreach my $component ( keys %{ $c->components } ) {
 391             return $c->components->{$component} if $component =~ /$name/i;
 392         }
 393     }
 394
 395     return undef;
 396 }
 397
 398 # try explicit component names
 399 sub _comp_explicit {
 400     my ( $c, @names ) = @_;
 401
 402     foreach my $try (@names) {
 403         return $c->components->{$try} if ( exists $c->components->{$try} );
 404     }
 405
 406     return undef;
 407 }
 408
 409 # like component, but try just these prefixes before regex searching,
 410 #  and do not try to return "sort keys %{ $c->components }"
 411 sub _comp_prefixes {
 412     my ( $c, $name, @prefixes ) = @_;
 413
 414     my $appclass = ref $c || $c;
 415
 416     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 417
 418     my $comp = $c->_comp_explicit(@names);
 419     return $comp if defined($comp);
 420     $comp = $c->_comp_search($name);
 421     return $comp;
 422 }
 423
 424 # Find possible names for a prefix
 425
 426 sub _comp_names {
 427     my ( $c, @prefixes ) = @_;
 428
 429     my $appclass = ref $c || $c;
 430
 431     my @pre = map { "${appclass}::${_}::" } @prefixes;
 432
 433     my @names;
 434
 435     COMPONENT: foreach my $comp ($c->component) {
 436         foreach my $p (@pre) {
 437             if ($comp =~ s/^$p//) {
 438                 push(@names, $comp);
 439                 next COMPONENT;
 440             }
 441         }
 442     }
 443
 444     return @names;
 445 }
 446
 447 # Return a component if only one matches.
 448 sub _comp_singular {
 449     my ( $c, @prefixes ) = @_;
 450
 451     my $appclass = ref $c || $c;
 452
 453     my ( $comp, $rest ) =
 454       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 455     return $comp unless $rest;
 456 }
 457
 458 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 459 sub _filter_component {
 460     my ( $c, $comp, @args ) = @_;
 461     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 462         return $comp->ACCEPT_CONTEXT( $c, @args );
 463     }
 464     else { return $comp }
 465 }
 466
 467 =head2 COMPONENT ACCESSORS
 468
 469 =head2 $c->controller($name)
 470
 471 Gets a L<Catalyst::Controller> instance by name.
 472
 473     $c->controller('Foo')->do_stuff;
 474
 475 If name is omitted, will return the controller for the dispatched action.
 476
 477 =cut
 478
 479 sub controller {
 480     my ( $c, $name, @args ) = @_;
 481     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 482         @args )
 483       if ($name);
 484     return $c->component( $c->action->class );
 485 }
 486
 487 =head2 $c->model($name)
 488
 489 Gets a L<Catalyst::Model> instance by name.
 490
 491     $c->model('Foo')->do_stuff;
 492
 493 If the name is omitted, it will look for a config setting 'default_model',
 494 or check if there is only one view, and return it if that's the case.
 495
 496 =cut
 497
 498 sub model {
 499     my ( $c, $name, @args ) = @_;
 500     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 501         @args )
 502       if $name;
 503     return $c->component( $c->config->{default_model} )
 504       if $c->config->{default_model};
 505     return $c->_filter_component( $c->_comp_singular(qw/Model M/), @args );
 506
 507 }
 508
 509 =head2 $c->controllers
 510
 511 Returns the available names which can be passed to $c->controller
 512
 513 =cut
 514
 515 sub controllers {
 516     my ( $c ) = @_;
 517     return $c->_comp_names(qw/Controller C/);
 518 }
 519
 520
 521 =head2 $c->view($name)
 522
 523 Gets a L<Catalyst::View> instance by name.
 524
 525     $c->view('Foo')->do_stuff;
 526
 527 If the name is omitted, it will look for a config setting 'default_view',
 528 or check if there is only one view, and forward to it if that's the case.
 529
 530 =cut
 531
 532 sub view {
 533     my ( $c, $name, @args ) = @_;
 534     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 535         @args )
 536       if $name;
 537     return $c->component( $c->config->{default_view} )
 538       if $c->config->{default_view};
 539     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 540 }
 541
 542 =head2 $c->models
 543
 544 Returns the available names which can be passed to $c->model
 545
 546 =cut
 547
 548 sub models {
 549     my ( $c ) = @_;
 550     return $c->_comp_names(qw/Model M/);
 551 }
 552
 553
 554 =head2 $c->views
 555
 556 Returns the available names which can be passed to $c->view
 557
 558 =cut
 559
 560 sub views {
 561     my ( $c ) = @_;
 562     return $c->_comp_names(qw/View V/);
 563 }
 564
 565 =head2 $c->comp($name)
 566
 567 =head2 $c->component($name)
 568
 569 Gets a component object by name. This method is no longer recommended,
 570 unless you want to get a specific component by full
 571 class. C<$c-E<gt>controller>, C<$c-E<gt>model>, and C<$c-E<gt>view>
 572 should be used instead.
 573
 574 =cut
 575
 576 sub component {
 577     my $c = shift;
 578
 579     if (@_) {
 580
 581         my $name = shift;
 582
 583         my $appclass = ref $c || $c;
 584
 585         my @names = (
 586             $name, "${appclass}::${name}",
 587             map { "${appclass}::${_}::${name}" }
 588               qw/Model M Controller C View V/
 589         );
 590
 591         my $comp = $c->_comp_explicit(@names);
 592         return $c->_filter_component( $comp, @_ ) if defined($comp);
 593
 594         $comp = $c->_comp_search($name);
 595         return $c->_filter_component( $comp, @_ ) if defined($comp);
 596     }
 597
 598     return sort keys %{ $c->components };
 599 }
 600
 601
 602
 603 =head2 CLASS DATA AND HELPER CLASSES
 604
 605 =head2 $c->config
 606
 607 Returns or takes a hashref containing the application's configuration.
 608
 609     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 610
 611 You can also use a L<YAML> config file like myapp.yml in your
 612 applications home directory.
 613
 614     ---
 615     db: dsn:SQLite:foo.db
 616
 617
 618 =cut
 619
 620 sub config {
 621     my $c = shift;
 622
 623     $c->log->warn("Setting config after setup has been run is not a good idea.")
 624       if ( @_ and $c->setup_finished );
 625
 626     $c->NEXT::config(@_);
 627 }
 628
 629 =head2 $c->log
 630
 631 Returns the logging object instance. Unless it is already set, Catalyst sets
 632 this up with a L<Catalyst::Log> object. To use your own log class, set the
 633 logger with the C<< __PACKAGE__->log >> method prior to calling
 634 C<< __PACKAGE__->setup >>.
 635
 636  __PACKAGE__->log( MyLogger->new );
 637  __PACKAGE__->setup;
 638
 639 And later:
 640
 641     $c->log->info( 'Now logging with my own logger!' );
 642
 643 Your log class should implement the methods described in the
 644 L<Catalyst::Log> man page.
 645
 646
 647 =head2 $c->debug
 648
 649 Overload to enable debug messages (same as -Debug option).
 650
 651 Note that this is a static method, not an accessor and should be overloaded
 652 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 653
 654 =cut
 655
 656 sub debug { 0 }
 657
 658 =head2 $c->dispatcher
 659
 660 Returns the dispatcher instance. Stringifies to class name. See
 661 L<Catalyst::Dispatcher>.
 662
 663 =head2 $c->engine
 664
 665 Returns the engine instance. Stringifies to the class name. See
 666 L<Catalyst::Engine>.
 667
 668
 669 =head2 UTILITY METHODS
 670
 671 =head2 $c->path_to(@path)
 672
 673 Merges C<@path> with C<$c-E<gt>config-E<gt>{home}> and returns a
 674 L<Path::Class> object.
 675
 676 For example:
 677
 678     $c->path_to( 'db', 'sqlite.db' );
 679
 680 =cut
 681
 682 sub path_to {
 683     my ( $c, @path ) = @_;
 684     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 685     if ( -d $path ) { return $path }
 686     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 687 }
 688
 689 =head2 $c->plugin( $name, $class, @args )
 690
 691 Helper method for plugins. It creates a classdata accessor/mutator and
 692 loads and instantiates the given class.
 693
 694     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 695
 696     $c->prototype->define_javascript_functions;
 697
 698 =cut
 699
 700 sub plugin {
 701     my ( $class, $name, $plugin, @args ) = @_;
 702     $class->_register_plugin( $plugin, 1 );
 703
 704     eval { $plugin->import };
 705     $class->mk_classdata($name);
 706     my $obj;
 707     eval { $obj = $plugin->new(@args) };
 708
 709     if ($@) {
 710         Catalyst::Exception->throw( message =>
 711               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 712     }
 713
 714     $class->$name($obj);
 715     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 716       if $class->debug;
 717 }
 718
 719 =head2 MyApp->setup
 720
 721 Initializes the dispatcher and engine, loads any plugins, and loads the
 722 model, view, and controller components. You may also specify an array
 723 of plugins to load here, if you choose to not load them in the C<use
 724 Catalyst> line.
 725
 726     MyApp->setup;
 727     MyApp->setup( qw/-Debug/ );
 728
 729 =cut
 730
 731 sub setup {
 732     my ( $class, @arguments ) = @_;
 733
 734     $class->log->warn("Running setup twice is not a good idea.")
 735       if ( $class->setup_finished );
 736
 737     unless ( $class->isa('Catalyst') ) {
 738
 739         Catalyst::Exception->throw(
 740             message => qq/'$class' does not inherit from Catalyst/ );
 741     }
 742
 743     if ( $class->arguments ) {
 744         @arguments = ( @arguments, @{ $class->arguments } );
 745     }
 746
 747     # Process options
 748     my $flags = {};
 749
 750     foreach (@arguments) {
 751
 752         if (/^-Debug$/) {
 753             $flags->{log} =
 754               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 755         }
 756         elsif (/^-(\w+)=?(.*)$/) {
 757             $flags->{ lc $1 } = $2;
 758         }
 759         else {
 760             push @{ $flags->{plugins} }, $_;
 761         }
 762     }
 763
 764     $class->setup_home( delete $flags->{home} );
 765
 766     $class->setup_log( delete $flags->{log} );
 767     $class->setup_plugins( delete $flags->{plugins} );
 768     $class->setup_dispatcher( delete $flags->{dispatcher} );
 769     $class->setup_engine( delete $flags->{engine} );
 770
 771     for my $flag ( sort keys %{$flags} ) {
 772
 773         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 774             &$code( $class, delete $flags->{$flag} );
 775         }
 776         else {
 777             $class->log->warn(qq/Unknown flag "$flag"/);
 778         }
 779     }
 780
 781     eval { require Catalyst::Devel; };
 782     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 783         $class->log->warn(<<"EOF");
 784 You are running an old script!
 785
 786   Please update by running (this will overwrite existing files):
 787     catalyst.pl -force -scripts $class
 788
 789   or (this will not overwrite existing files):
 790     catalyst.pl -scripts $class
 791 EOF
 792     }
 793
 794     if ( $class->debug ) {
 795         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 796
 797         if (@plugins) {
 798             my $t = Text::SimpleTable->new(74);
 799             $t->row($_) for @plugins;
 800             $class->log->debug( "Loaded plugins:\n" . $t->draw );
 801         }
 802
 803         my $dispatcher = $class->dispatcher;
 804         my $engine     = $class->engine;
 805         my $home       = $class->config->{home};
 806
 807         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 808         $class->log->debug(qq/Loaded engine "$engine"/);
 809
 810         $home
 811           ? ( -d $home )
 812           ? $class->log->debug(qq/Found home "$home"/)
 813           : $class->log->debug(qq/Home "$home" doesn't exist/)
 814           : $class->log->debug(q/Couldn't find home/);
 815     }
 816
 817     # Call plugins setup
 818     {
 819         no warnings qw/redefine/;
 820         local *setup = sub { };
 821         $class->setup;
 822     }
 823
 824     # Initialize our data structure
 825     $class->components( {} );
 826
 827     $class->setup_components;
 828
 829     if ( $class->debug ) {
 830         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 831         for my $comp ( sort keys %{ $class->components } ) {
 832             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 833             $t->row( $comp, $type );
 834         }
 835         $class->log->debug( "Loaded components:\n" . $t->draw )
 836           if ( keys %{ $class->components } );
 837     }
 838
 839     # Add our self to components, since we are also a component
 840     $class->components->{$class} = $class;
 841
 842     $class->setup_actions;
 843
 844     if ( $class->debug ) {
 845         my $name = $class->config->{name} || 'Application';
 846         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 847     }
 848     $class->log->_flush() if $class->log->can('_flush');
 849
 850     $class->setup_finished(1);
 851 }
 852
 853 =head2 $c->uri_for( $path, @args?, \%query_values? )
 854
 855 Merges path with C<$c-E<gt>request-E<gt>base> for absolute uri's and
 856 with C<$c-E<gt>namespace> for relative uri's, then returns a
 857 normalized L<URI> object. If any args are passed, they are added at the
 858 end of the path.  If the last argument to uri_for is a hash reference,
 859 it is assumed to contain GET parameter key/value pairs, which will be
 860 appended to the URI in standard fashion.
 861
 862 Instead of $path, you can also optionally pass a $action object which will
 863 be resolved to a path using $c->dispatcher->uri_for_action; if the first
 864 element of @args is an arrayref it is treated as a list of captures to be
 865 passed to uri_for_action.
 866
 867 =cut
 868
 869 sub uri_for {
 870     my ( $c, $path, @args ) = @_;
 871     my $base     = $c->request->base->clone;
 872     my $basepath = $base->path;
 873     $basepath =~ s/\/$//;
 874     $basepath .= '/';
 875     my $namespace = $c->namespace || '';
 876
 877     if ( Scalar::Util::blessed($path) ) { # action object
 878         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 879                          ? shift(@args)
 880                          : [] );
 881         $path = $c->dispatcher->uri_for_action($path, $captures);
 882         return undef unless defined($path);
 883     }
 884
 885     # massage namespace, empty if absolute path
 886     $namespace =~ s/^\/// if $namespace;
 887     $namespace .= '/' if $namespace;
 888     $path ||= '';
 889     $namespace = '' if $path =~ /^\//;
 890     $path =~ s/^\///;
 891
 892     my $params =
 893       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 894
 895     for my $value ( values %$params ) {
 896         my $isa_ref = ref $value;
 897         if( $isa_ref and $isa_ref ne 'ARRAY' ) {
 898             croak( "Non-array reference ($isa_ref) passed to uri_for()" );
 899         }
 900         utf8::encode( $_ ) for grep { defined } $isa_ref ? @$value : $value;
 901     };
 902
 903     # join args with '/', or a blank string
 904     my $args = ( scalar @args ? '/' . join( '/', @args ) : '' );
 905     $args =~ s/^\/// unless $path;
 906     my $res =
 907       URI->new_abs( URI->new_abs( "$path$args", "$basepath$namespace" ), $base )
 908       ->canonical;
 909     $res->query_form(%$params);
 910     $res;
 911 }
 912
 913 =head2 $c->welcome_message
 914
 915 Returns the Catalyst welcome HTML page.
 916
 917 =cut
 918
 919 sub welcome_message {
 920     my $c      = shift;
 921     my $name   = $c->config->{name};
 922     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
 923     my $prefix = Catalyst::Utils::appprefix( ref $c );
 924     $c->response->content_type('text/html; charset=utf-8');
 925     return <<"EOF";
 926 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
 927     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 928 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 929     <head>
 930         <meta http-equiv="Content-Language" content="en" />
 931         <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
 932         <title>$name on Catalyst $VERSION</title>
 933         <style type="text/css">
 934             body {
 935                 color: #000;
 936                 background-color: #eee;
 937             }
 938             div#content {
 939                 width: 640px;
 940                 margin-left: auto;
 941                 margin-right: auto;
 942                 margin-top: 10px;
 943                 margin-bottom: 10px;
 944                 text-align: left;
 945                 background-color: #ccc;
 946                 border: 1px solid #aaa;
 947             }
 948             p, h1, h2 {
 949                 margin-left: 20px;
 950                 margin-right: 20px;
 951                 font-family: verdana, tahoma, sans-serif;
 952             }
 953             a {
 954                 font-family: verdana, tahoma, sans-serif;
 955             }
 956             :link, :visited {
 957                     text-decoration: none;
 958                     color: #b00;
 959                     border-bottom: 1px dotted #bbb;
 960             }
 961             :link:hover, :visited:hover {
 962                     color: #555;
 963             }
 964             div#topbar {
 965                 margin: 0px;
 966             }
 967             pre {
 968                 margin: 10px;
 969                 padding: 8px;
 970             }
 971             div#answers {
 972                 padding: 8px;
 973                 margin: 10px;
 974                 background-color: #fff;
 975                 border: 1px solid #aaa;
 976             }
 977             h1 {
 978                 font-size: 0.9em;
 979                 font-weight: normal;
 980                 text-align: center;
 981             }
 982             h2 {
 983                 font-size: 1.0em;
 984             }
 985             p {
 986                 font-size: 0.9em;
 987             }
 988             p img {
 989                 float: right;
 990                 margin-left: 10px;
 991             }
 992             span#appname {
 993                 font-weight: bold;
 994                 font-size: 1.6em;
 995             }
 996         </style>
 997     </head>
 998     <body>
 999         <div id="content">
1000             <div id="topbar">
1001                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1002                     $VERSION</h1>
1003              </div>
1004              <div id="answers">
1005                  <p>
1006                  <img src="$logo" alt="Catalyst Logo" />
1007                  </p>
1008                  <p>Welcome to the wonderful world of Catalyst.
1009                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1010                     framework will make web development something you had
1011                     never expected it to be: Fun, rewarding, and quick.</p>
1012                  <h2>What to do now?</h2>
1013                  <p>That really depends  on what <b>you</b> want to do.
1014                     We do, however, provide you with a few starting points.</p>
1015                  <p>If you want to jump right into web development with Catalyst
1016                     you might want to check out the documentation.</p>
1017                  <pre><code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1018 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1019 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual.pod">Catalyst::Manual</a></code></pre>
1020                  <h2>What to do next?</h2>
1021                  <p>Next it's time to write an actual application. Use the
1022                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1023                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1024                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1025                     they can save you a lot of work.</p>
1026                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1027                     <p>Also, be sure to check out the vast and growing
1028                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1029                     you are likely to find what you need there.
1030                     </p>
1031
1032                  <h2>Need help?</h2>
1033                  <p>Catalyst has a very active community. Here are the main places to
1034                     get in touch with us.</p>
1035                  <ul>
1036                      <li>
1037                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1038                      </li>
1039                      <li>
1040                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1041                      </li>
1042                      <li>
1043                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1044                      </li>
1045                  </ul>
1046                  <h2>In conclusion</h2>
1047                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1048                     as we enjoyed making it. Please contact us if you have ideas
1049                     for improvement or other feedback.</p>
1050              </div>
1051          </div>
1052     </body>
1053 </html>
1054 EOF
1055 }
1056
1057 =head1 INTERNAL METHODS
1058
1059 These methods are not meant to be used by end users.
1060
1061 =head2 $c->components
1062
1063 Returns a hash of components.
1064
1065 =head2 $c->context_class
1066
1067 Returns or sets the context class.
1068
1069 =head2 $c->counter
1070
1071 Returns a hashref containing coderefs and execution counts (needed for
1072 deep recursion detection).
1073
1074 =head2 $c->depth
1075
1076 Returns the number of actions on the current internal execution stack.
1077
1078 =head2 $c->dispatch
1079
1080 Dispatches a request to actions.
1081
1082 =cut
1083
1084 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1085
1086 =head2 $c->dispatcher_class
1087
1088 Returns or sets the dispatcher class.
1089
1090 =head2 $c->dump_these
1091
1092 Returns a list of 2-element array references (name, structure) pairs
1093 that will be dumped on the error page in debug mode.
1094
1095 =cut
1096
1097 sub dump_these {
1098     my $c = shift;
1099     [ Request => $c->req ],
1100     [ Response => $c->res ],
1101     [ Stash => $c->stash ],
1102     [ Config => $c->config ];
1103 }
1104
1105 =head2 $c->engine_class
1106
1107 Returns or sets the engine class.
1108
1109 =head2 $c->execute( $class, $coderef )
1110
1111 Execute a coderef in given class and catch exceptions. Errors are available
1112 via $c->error.
1113
1114 =cut
1115
1116 sub execute {
1117     my ( $c, $class, $code ) = @_;
1118     $class = $c->component($class) || $class;
1119     $c->state(0);
1120
1121     if ( $c->depth >= $RECURSION ) {
1122         my $action = "$code";
1123         $action = "/$action" unless $action =~ /\-\>/;
1124         my $error = qq/Deep recursion detected calling "$action"/;
1125         $c->log->error($error);
1126         $c->error($error);
1127         $c->state(0);
1128         return $c->state;
1129     }
1130
1131     my $stats_info = $c->_stats_start_execute( $code ) if $c->debug;
1132
1133     push( @{ $c->stack }, $code );
1134
1135     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1136
1137     $c->_stats_finish_execute( $stats_info ) if $c->debug and $stats_info;
1138
1139     my $last = pop( @{ $c->stack } );
1140
1141     if ( my $error = $@ ) {
1142         if ( $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1143         else {
1144             unless ( ref $error ) {
1145                 chomp $error;
1146                 my $class = $last->class;
1147                 my $name  = $last->name;
1148                 $error = qq/Caught exception in $class->$name "$error"/;
1149             }
1150             $c->error($error);
1151             $c->state(0);
1152         }
1153     }
1154     return $c->state;
1155 }
1156
1157 sub _stats_start_execute {
1158     my ( $c, $code ) = @_;
1159
1160     return if ( ( $code->name =~ /^_.*/ )
1161         && ( !$c->config->{show_internal_actions} ) );
1162
1163     $c->counter->{"$code"}++;
1164
1165     my $action = "$code";
1166     $action = "/$action" unless $action =~ /->/;
1167
1168     # determine if the call was the result of a forward
1169     # this is done by walking up the call stack and looking for a calling
1170     # sub of Catalyst::forward before the eval
1171     my $callsub = q{};
1172     for my $index ( 2 .. 11 ) {
1173         last
1174         if ( ( caller($index) )[0] eq 'Catalyst'
1175             && ( caller($index) )[3] eq '(eval)' );
1176
1177         if ( ( caller($index) )[3] =~ /forward$/ ) {
1178             $callsub = ( caller($index) )[3];
1179             $action  = "-> $action";
1180             last;
1181         }
1182     }
1183
1184     my $node = Tree::Simple->new(
1185         {
1186             action  => $action,
1187             elapsed => undef,     # to be filled in later
1188             comment => "",
1189         }
1190     );
1191     $node->setUID( "$code" . $c->counter->{"$code"} );
1192
1193     # is this a root-level call or a forwarded call?
1194     if ( $callsub =~ /forward$/ ) {
1195
1196         # forward, locate the caller
1197         if ( my $parent = $c->stack->[-1] ) {
1198             my $visitor = Tree::Simple::Visitor::FindByUID->new;
1199             $visitor->searchForUID(
1200                 "$parent" . $c->counter->{"$parent"} );
1201             $c->stats->accept($visitor);
1202             if ( my $result = $visitor->getResult ) {
1203                 $result->addChild($node);
1204             }
1205         }
1206         else {
1207
1208             # forward with no caller may come from a plugin
1209             $c->stats->addChild($node);
1210         }
1211     }
1212     else {
1213
1214         # root-level call
1215         $c->stats->addChild($node);
1216     }
1217
1218     return {
1219         start   => [gettimeofday],
1220         node    => $node,
1221     };
1222 }
1223
1224 sub _stats_finish_execute {
1225     my ( $c, $info ) = @_;
1226     my $elapsed = tv_interval $info->{start};
1227     my $value = $info->{node}->getNodeValue;
1228     $value->{elapsed} = sprintf( '%fs', $elapsed );
1229 }
1230
1231 =head2 $c->_localize_fields( sub { }, \%keys );
1232
1233 =cut
1234
1235 sub _localize_fields {
1236     my ( $c, $localized, $code ) = ( @_ );
1237
1238     my $request = delete $localized->{request} || {};
1239     my $response = delete $localized->{response} || {};
1240
1241     local @{ $c }{ keys %$localized } = values %$localized;
1242     local @{ $c->request }{ keys %$request } = values %$request;
1243     local @{ $c->response }{ keys %$response } = values %$response;
1244
1245     $code->();
1246 }
1247
1248 =head2 $c->finalize
1249
1250 Finalizes the request.
1251
1252 =cut
1253
1254 sub finalize {
1255     my $c = shift;
1256
1257     for my $error ( @{ $c->error } ) {
1258         $c->log->error($error);
1259     }
1260
1261     # Allow engine to handle finalize flow (for POE)
1262     if ( $c->engine->can('finalize') ) {
1263         $c->engine->finalize($c);
1264     }
1265     else {
1266
1267         $c->finalize_uploads;
1268
1269         # Error
1270         if ( $#{ $c->error } >= 0 ) {
1271             $c->finalize_error;
1272         }
1273
1274         $c->finalize_headers;
1275
1276         # HEAD request
1277         if ( $c->request->method eq 'HEAD' ) {
1278             $c->response->body('');
1279         }
1280
1281         $c->finalize_body;
1282     }
1283
1284     return $c->response->status;
1285 }
1286
1287 =head2 $c->finalize_body
1288
1289 Finalizes body.
1290
1291 =cut
1292
1293 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1294
1295 =head2 $c->finalize_cookies
1296
1297 Finalizes cookies.
1298
1299 =cut
1300
1301 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1302
1303 =head2 $c->finalize_error
1304
1305 Finalizes error.
1306
1307 =cut
1308
1309 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1310
1311 =head2 $c->finalize_headers
1312
1313 Finalizes headers.
1314
1315 =cut
1316
1317 sub finalize_headers {
1318     my $c = shift;
1319
1320     # Check if we already finalized headers
1321     return if $c->response->{_finalized_headers};
1322
1323     # Handle redirects
1324     if ( my $location = $c->response->redirect ) {
1325         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1326         $c->response->header( Location => $location );
1327     }
1328
1329     # Content-Length
1330     if ( $c->response->body && !$c->response->content_length ) {
1331
1332         # get the length from a filehandle
1333         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1334         {
1335             if ( my $stat = stat $c->response->body ) {
1336                 $c->response->content_length( $stat->size );
1337             }
1338             else {
1339                 $c->log->warn('Serving filehandle without a content-length');
1340             }
1341         }
1342         else {
1343             $c->response->content_length( bytes::length( $c->response->body ) );
1344         }
1345     }
1346
1347     # Errors
1348     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1349         $c->response->headers->remove_header("Content-Length");
1350         $c->response->body('');
1351     }
1352
1353     $c->finalize_cookies;
1354
1355     $c->engine->finalize_headers( $c, @_ );
1356
1357     # Done
1358     $c->response->{_finalized_headers} = 1;
1359 }
1360
1361 =head2 $c->finalize_output
1362
1363 An alias for finalize_body.
1364
1365 =head2 $c->finalize_read
1366
1367 Finalizes the input after reading is complete.
1368
1369 =cut
1370
1371 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1372
1373 =head2 $c->finalize_uploads
1374
1375 Finalizes uploads. Cleans up any temporary files.
1376
1377 =cut
1378
1379 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1380
1381 =head2 $c->get_action( $action, $namespace )
1382
1383 Gets an action in a given namespace.
1384
1385 =cut
1386
1387 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1388
1389 =head2 $c->get_actions( $action, $namespace )
1390
1391 Gets all actions of a given name in a namespace and all parent
1392 namespaces.
1393
1394 =cut
1395
1396 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1397
1398 =head2 $c->handle_request( $class, @arguments )
1399
1400 Called to handle each HTTP request.
1401
1402 =cut
1403
1404 sub handle_request {
1405     my ( $class, @arguments ) = @_;
1406
1407     # Always expect worst case!
1408     my $status = -1;
1409     eval {
1410         if ($class->debug) {
1411             my $start = [gettimeofday];
1412             my $c = $class->prepare(@arguments);
1413             $c->stats(Tree::Simple->new);
1414             $c->dispatch;
1415             $status = $c->finalize;
1416
1417             my $elapsed = tv_interval $start;
1418             $elapsed = sprintf '%f', $elapsed;
1419             my $av = sprintf '%.3f',
1420               ( $elapsed == 0 ? '??' : ( 1 / $elapsed ) );
1421             my $t = Text::SimpleTable->new( [ 62, 'Action' ], [ 9, 'Time' ] );
1422
1423             $c->stats->traverse(
1424                 sub {
1425                     my $action = shift;
1426                     my $stat   = $action->getNodeValue;
1427                     $t->row( ( q{ } x $action->getDepth ) . $stat->{action} . $stat->{comment},
1428                         $stat->{elapsed} || '??' );
1429                 }
1430             );
1431
1432             $class->log->info(
1433                 "Request took ${elapsed}s ($av/s)\n" . $t->draw );
1434         }
1435         else {
1436             my $c = $class->prepare(@arguments);
1437             $c->dispatch;
1438             $status = $c->finalize;
1439         }
1440     };
1441
1442     if ( my $error = $@ ) {
1443         chomp $error;
1444         $class->log->error(qq/Caught exception in engine "$error"/);
1445     }
1446
1447     $COUNT++;
1448     $class->log->_flush() if $class->log->can('_flush');
1449     return $status;
1450 }
1451
1452 =head2 $c->prepare( @arguments )
1453
1454 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1455 etc.).
1456
1457 =cut
1458
1459 sub prepare {
1460     my ( $class, @arguments ) = @_;
1461
1462     $class->context_class( ref $class || $class ) unless $class->context_class;
1463     my $c = $class->context_class->new(
1464         {
1465             counter => {},
1466             stack   => [],
1467             request => $class->request_class->new(
1468                 {
1469                     arguments        => [],
1470                     body_parameters  => {},
1471                     cookies          => {},
1472                     headers          => HTTP::Headers->new,
1473                     parameters       => {},
1474                     query_parameters => {},
1475                     secure           => 0,
1476                     captures         => [],
1477                     uploads          => {}
1478                 }
1479             ),
1480             response => $class->response_class->new(
1481                 {
1482                     body    => '',
1483                     cookies => {},
1484                     headers => HTTP::Headers->new(),
1485                     status  => 200
1486                 }
1487             ),
1488             stash => {},
1489             state => 0
1490         }
1491     );
1492
1493     # For on-demand data
1494     $c->request->{_context}  = $c;
1495     $c->response->{_context} = $c;
1496     weaken( $c->request->{_context} );
1497     weaken( $c->response->{_context} );
1498
1499     if ( $c->debug ) {
1500         my $secs = time - $START || 1;
1501         my $av = sprintf '%.3f', $COUNT / $secs;
1502         my $time = localtime time;
1503         $c->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1504         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1505     }
1506
1507     # Allow engine to direct the prepare flow (for POE)
1508     if ( $c->engine->can('prepare') ) {
1509         $c->engine->prepare( $c, @arguments );
1510     }
1511     else {
1512         $c->prepare_request(@arguments);
1513         $c->prepare_connection;
1514         $c->prepare_query_parameters;
1515         $c->prepare_headers;
1516         $c->prepare_cookies;
1517         $c->prepare_path;
1518
1519         # On-demand parsing
1520         $c->prepare_body unless $c->config->{parse_on_demand};
1521     }
1522
1523     my $method  = $c->req->method  || '';
1524     my $path    = $c->req->path    || '/';
1525     my $address = $c->req->address || '';
1526
1527     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1528       if $c->debug;
1529
1530     $c->prepare_action;
1531
1532     return $c;
1533 }
1534
1535 =head2 $c->prepare_action
1536
1537 Prepares action. See L<Catalyst::Dispatcher>.
1538
1539 =cut
1540
1541 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1542
1543 =head2 $c->prepare_body
1544
1545 Prepares message body.
1546
1547 =cut
1548
1549 sub prepare_body {
1550     my $c = shift;
1551
1552     # Do we run for the first time?
1553     return if defined $c->request->{_body};
1554
1555     # Initialize on-demand data
1556     $c->engine->prepare_body( $c, @_ );
1557     $c->prepare_parameters;
1558     $c->prepare_uploads;
1559
1560     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1561         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1562         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1563             my $param = $c->req->body_parameters->{$key};
1564             my $value = defined($param) ? $param : '';
1565             $t->row( $key,
1566                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1567         }
1568         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1569     }
1570 }
1571
1572 =head2 $c->prepare_body_chunk( $chunk )
1573
1574 Prepares a chunk of data before sending it to L<HTTP::Body>.
1575
1576 See L<Catalyst::Engine>.
1577
1578 =cut
1579
1580 sub prepare_body_chunk {
1581     my $c = shift;
1582     $c->engine->prepare_body_chunk( $c, @_ );
1583 }
1584
1585 =head2 $c->prepare_body_parameters
1586
1587 Prepares body parameters.
1588
1589 =cut
1590
1591 sub prepare_body_parameters {
1592     my $c = shift;
1593     $c->engine->prepare_body_parameters( $c, @_ );
1594 }
1595
1596 =head2 $c->prepare_connection
1597
1598 Prepares connection.
1599
1600 =cut
1601
1602 sub prepare_connection {
1603     my $c = shift;
1604     $c->engine->prepare_connection( $c, @_ );
1605 }
1606
1607 =head2 $c->prepare_cookies
1608
1609 Prepares cookies.
1610
1611 =cut
1612
1613 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1614
1615 =head2 $c->prepare_headers
1616
1617 Prepares headers.
1618
1619 =cut
1620
1621 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1622
1623 =head2 $c->prepare_parameters
1624
1625 Prepares parameters.
1626
1627 =cut
1628
1629 sub prepare_parameters {
1630     my $c = shift;
1631     $c->prepare_body_parameters;
1632     $c->engine->prepare_parameters( $c, @_ );
1633 }
1634
1635 =head2 $c->prepare_path
1636
1637 Prepares path and base.
1638
1639 =cut
1640
1641 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1642
1643 =head2 $c->prepare_query_parameters
1644
1645 Prepares query parameters.
1646
1647 =cut
1648
1649 sub prepare_query_parameters {
1650     my $c = shift;
1651
1652     $c->engine->prepare_query_parameters( $c, @_ );
1653
1654     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1655         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1656         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1657             my $param = $c->req->query_parameters->{$key};
1658             my $value = defined($param) ? $param : '';
1659             $t->row( $key,
1660                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1661         }
1662         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1663     }
1664 }
1665
1666 =head2 $c->prepare_read
1667
1668 Prepares the input for reading.
1669
1670 =cut
1671
1672 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1673
1674 =head2 $c->prepare_request
1675
1676 Prepares the engine request.
1677
1678 =cut
1679
1680 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1681
1682 =head2 $c->prepare_uploads
1683
1684 Prepares uploads.
1685
1686 =cut
1687
1688 sub prepare_uploads {
1689     my $c = shift;
1690
1691     $c->engine->prepare_uploads( $c, @_ );
1692
1693     if ( $c->debug && keys %{ $c->request->uploads } ) {
1694         my $t = Text::SimpleTable->new(
1695             [ 12, 'Parameter' ],
1696             [ 26, 'Filename' ],
1697             [ 18, 'Type' ],
1698             [ 9,  'Size' ]
1699         );
1700         for my $key ( sort keys %{ $c->request->uploads } ) {
1701             my $upload = $c->request->uploads->{$key};
1702             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1703                 $t->row( $key, $u->filename, $u->type, $u->size );
1704             }
1705         }
1706         $c->log->debug( "File Uploads are:\n" . $t->draw );
1707     }
1708 }
1709
1710 =head2 $c->prepare_write
1711
1712 Prepares the output for writing.
1713
1714 =cut
1715
1716 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1717
1718 =head2 $c->request_class
1719
1720 Returns or sets the request class.
1721
1722 =head2 $c->response_class
1723
1724 Returns or sets the response class.
1725
1726 =head2 $c->read( [$maxlength] )
1727
1728 Reads a chunk of data from the request body. This method is designed to
1729 be used in a while loop, reading C<$maxlength> bytes on every call.
1730 C<$maxlength> defaults to the size of the request if not specified.
1731
1732 You have to set C<MyApp-E<gt>config-E<gt>{parse_on_demand}> to use this
1733 directly.
1734
1735 =cut
1736
1737 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1738
1739 =head2 $c->run
1740
1741 Starts the engine.
1742
1743 =cut
1744
1745 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1746
1747 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1748
1749 Sets an action in a given namespace.
1750
1751 =cut
1752
1753 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1754
1755 =head2 $c->setup_actions($component)
1756
1757 Sets up actions for a component.
1758
1759 =cut
1760
1761 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1762
1763 =head2 $c->setup_components
1764
1765 Sets up components. Specify a C<setup_components> config option to pass additional options
1766 directly to L<Module::Pluggable>. To add additional search paths, specify a key named
1767 C<search_extra> as an array reference. Items in the array beginning with C<::> will have the
1768 application class name prepended to them.
1769
1770 =cut
1771
1772 sub setup_components {
1773     my $class = shift;
1774
1775     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1776     my $config  = $class->config->{ setup_components };
1777     my $extra   = delete $config->{ search_extra } || [];
1778
1779     push @paths, @$extra;
1780
1781     my $locator = Module::Pluggable::Object->new(
1782         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1783         %$config
1784     );
1785
1786     for my $component ( sort { length $a <=> length $b } $locator->plugins ) {
1787         Catalyst::Utils::ensure_class_loaded( $component );
1788
1789         my $module  = $class->setup_component( $component );
1790         my %modules = (
1791             $component => $module,
1792             map {
1793                 $_ => $class->setup_component( $_ )
1794             } Devel::InnerPackage::list_packages( $component )
1795         );
1796
1797         for my $key ( keys %modules ) {
1798             $class->components->{ $key } = $modules{ $key };
1799         }
1800     }
1801 }
1802
1803 =head2 $c->setup_component
1804
1805 =cut
1806
1807 sub setup_component {
1808     my( $class, $component ) = @_;
1809
1810     unless ( $component->can( 'COMPONENT' ) ) {
1811         return $component;
1812     }
1813
1814     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1815     my $config = $class->config->{ $suffix } || {};
1816
1817     my $instance = eval { $component->COMPONENT( $class, $config ); };
1818
1819     if ( my $error = $@ ) {
1820         chomp $error;
1821         Catalyst::Exception->throw(
1822             message => qq/Couldn't instantiate component "$component", "$error"/
1823         );
1824     }
1825
1826     Catalyst::Exception->throw(
1827         message =>
1828         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1829     ) unless eval { $instance->can( 'can' ) };
1830
1831     return $instance;
1832 }
1833
1834 =head2 $c->setup_dispatcher
1835
1836 Sets up dispatcher.
1837
1838 =cut
1839
1840 sub setup_dispatcher {
1841     my ( $class, $dispatcher ) = @_;
1842
1843     if ($dispatcher) {
1844         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1845     }
1846
1847     if ( $ENV{CATALYST_DISPATCHER} ) {
1848         $dispatcher = 'Catalyst::Dispatcher::' . $ENV{CATALYST_DISPATCHER};
1849     }
1850
1851     if ( $ENV{ uc($class) . '_DISPATCHER' } ) {
1852         $dispatcher =
1853           'Catalyst::Dispatcher::' . $ENV{ uc($class) . '_DISPATCHER' };
1854     }
1855
1856     unless ($dispatcher) {
1857         $dispatcher = $class->dispatcher_class;
1858     }
1859
1860     unless (Class::Inspector->loaded($dispatcher)) {
1861         require Class::Inspector->filename($dispatcher);
1862     }
1863
1864     # dispatcher instance
1865     $class->dispatcher( $dispatcher->new );
1866 }
1867
1868 =head2 $c->setup_engine
1869
1870 Sets up engine.
1871
1872 =cut
1873
1874 sub setup_engine {
1875     my ( $class, $engine ) = @_;
1876
1877     if ($engine) {
1878         $engine = 'Catalyst::Engine::' . $engine;
1879     }
1880
1881     if ( $ENV{CATALYST_ENGINE} ) {
1882         $engine = 'Catalyst::Engine::' . $ENV{CATALYST_ENGINE};
1883     }
1884
1885     if ( $ENV{ uc($class) . '_ENGINE' } ) {
1886         $engine = 'Catalyst::Engine::' . $ENV{ uc($class) . '_ENGINE' };
1887     }
1888
1889     if ( $ENV{MOD_PERL} ) {
1890
1891         # create the apache method
1892         {
1893             no strict 'refs';
1894             *{"$class\::apache"} = sub { shift->engine->apache };
1895         }
1896
1897         my ( $software, $version ) =
1898           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1899
1900         $version =~ s/_//g;
1901         $version =~ s/(\.[^.]+)\./$1/g;
1902
1903         if ( $software eq 'mod_perl' ) {
1904
1905             if ( !$engine ) {
1906
1907                 if ( $version >= 1.99922 ) {
1908                     $engine = 'Catalyst::Engine::Apache2::MP20';
1909                 }
1910
1911                 elsif ( $version >= 1.9901 ) {
1912                     $engine = 'Catalyst::Engine::Apache2::MP19';
1913                 }
1914
1915                 elsif ( $version >= 1.24 ) {
1916                     $engine = 'Catalyst::Engine::Apache::MP13';
1917                 }
1918
1919                 else {
1920                     Catalyst::Exception->throw( message =>
1921                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
1922                 }
1923
1924             }
1925
1926             # install the correct mod_perl handler
1927             if ( $version >= 1.9901 ) {
1928                 *handler = sub  : method {
1929                     shift->handle_request(@_);
1930                 };
1931             }
1932             else {
1933                 *handler = sub ($$) { shift->handle_request(@_) };
1934             }
1935
1936         }
1937
1938         elsif ( $software eq 'Zeus-Perl' ) {
1939             $engine = 'Catalyst::Engine::Zeus';
1940         }
1941
1942         else {
1943             Catalyst::Exception->throw(
1944                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
1945         }
1946     }
1947
1948     unless ($engine) {
1949         $engine = $class->engine_class;
1950     }
1951
1952     unless (Class::Inspector->loaded($engine)) {
1953         require Class::Inspector->filename($engine);
1954     }
1955
1956     # check for old engines that are no longer compatible
1957     my $old_engine;
1958     if ( $engine->isa('Catalyst::Engine::Apache')
1959         && !Catalyst::Engine::Apache->VERSION )
1960     {
1961         $old_engine = 1;
1962     }
1963
1964     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
1965         && Catalyst::Engine::Server->VERSION le '0.02' )
1966     {
1967         $old_engine = 1;
1968     }
1969
1970     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
1971         && $engine->VERSION eq '0.01' )
1972     {
1973         $old_engine = 1;
1974     }
1975
1976     elsif ($engine->isa('Catalyst::Engine::Zeus')
1977         && $engine->VERSION eq '0.01' )
1978     {
1979         $old_engine = 1;
1980     }
1981
1982     if ($old_engine) {
1983         Catalyst::Exception->throw( message =>
1984               qq/Engine "$engine" is not supported by this version of Catalyst/
1985         );
1986     }
1987
1988     # engine instance
1989     $class->engine( $engine->new );
1990 }
1991
1992 =head2 $c->setup_home
1993
1994 Sets up the home directory.
1995
1996 =cut
1997
1998 sub setup_home {
1999     my ( $class, $home ) = @_;
2000
2001     if ( $ENV{CATALYST_HOME} ) {
2002         $home = $ENV{CATALYST_HOME};
2003     }
2004
2005     if ( $ENV{ uc($class) . '_HOME' } ) {
2006         $home = $ENV{ uc($class) . '_HOME' };
2007     }
2008
2009     unless ($home) {
2010         $home = Catalyst::Utils::home($class);
2011     }
2012
2013     if ($home) {
2014         $class->config->{home} ||= $home;
2015         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2016     }
2017 }
2018
2019 =head2 $c->setup_log
2020
2021 Sets up log.
2022
2023 =cut
2024
2025 sub setup_log {
2026     my ( $class, $debug ) = @_;
2027
2028     unless ( $class->log ) {
2029         $class->log( Catalyst::Log->new );
2030     }
2031
2032     my $app_flag = Catalyst::Utils::class2env($class) . '_DEBUG';
2033
2034     if (
2035           ( defined( $ENV{CATALYST_DEBUG} ) || defined( $ENV{$app_flag} ) )
2036         ? ( $ENV{CATALYST_DEBUG} || $ENV{$app_flag} )
2037         : $debug
2038       )
2039     {
2040         no strict 'refs';
2041         *{"$class\::debug"} = sub { 1 };
2042         $class->log->debug('Debug messages enabled');
2043     }
2044 }
2045
2046 =head2 $c->setup_plugins
2047
2048 Sets up plugins.
2049
2050 =cut
2051
2052 =head2 $c->registered_plugins
2053
2054 Returns a sorted list of the plugins which have either been stated in the
2055 import list or which have been added via C<< MyApp->plugin(@args); >>.
2056
2057 If passed a given plugin name, it will report a boolean value indicating
2058 whether or not that plugin is loaded.  A fully qualified name is required if
2059 the plugin name does not begin with C<Catalyst::Plugin::>.
2060
2061  if ($c->registered_plugins('Some::Plugin')) {
2062      ...
2063  }
2064
2065 =cut
2066
2067 {
2068
2069     sub registered_plugins {
2070         my $proto = shift;
2071         return sort keys %{ $proto->_plugins } unless @_;
2072         my $plugin = shift;
2073         return 1 if exists $proto->_plugins->{$plugin};
2074         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2075     }
2076
2077     sub _register_plugin {
2078         my ( $proto, $plugin, $instant ) = @_;
2079         my $class = ref $proto || $proto;
2080
2081         unless (Class::Inspector->loaded($plugin)) {
2082             require Class::Inspector->filename($plugin);
2083         }
2084
2085         $proto->_plugins->{$plugin} = 1;
2086         unless ($instant) {
2087             no strict 'refs';
2088             unshift @{"$class\::ISA"}, $plugin;
2089         }
2090         return $class;
2091     }
2092
2093     sub setup_plugins {
2094         my ( $class, $plugins ) = @_;
2095
2096         $class->_plugins( {} ) unless $class->_plugins;
2097         $plugins ||= [];
2098         for my $plugin ( reverse @$plugins ) {
2099
2100             unless ( $plugin =~ s/\A\+// ) {
2101                 $plugin = "Catalyst::Plugin::$plugin";
2102             }
2103
2104             $class->_register_plugin($plugin);
2105         }
2106     }
2107 }
2108
2109 =head2 $c->stack
2110
2111 Returns an arrayref of the internal execution stack (actions that are currently
2112 executing).
2113
2114 =head2 $c->write( $data )
2115
2116 Writes $data to the output stream. When using this method directly, you
2117 will need to manually set the C<Content-Length> header to the length of
2118 your output data, if known.
2119
2120 =cut
2121
2122 sub write {
2123     my $c = shift;
2124
2125     # Finalize headers if someone manually writes output
2126     $c->finalize_headers;
2127
2128     return $c->engine->write( $c, @_ );
2129 }
2130
2131 =head2 version
2132
2133 Returns the Catalyst version number. Mostly useful for "powered by"
2134 messages in template systems.
2135
2136 =cut
2137
2138 sub version { return $Catalyst::VERSION }
2139
2140 =head1 INTERNAL ACTIONS
2141
2142 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2143 C<_ACTION>, and C<_END>. These are by default not shown in the private
2144 action table, but you can make them visible with a config parameter.
2145
2146     MyApp->config->{show_internal_actions} = 1;
2147
2148 =head1 CASE SENSITIVITY
2149
2150 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2151 mapped to C</foo/bar>. You can activate case sensitivity with a config
2152 parameter.
2153
2154     MyApp->config->{case_sensitive} = 1;
2155
2156 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2157
2158 =head1 ON-DEMAND PARSER
2159
2160 The request body is usually parsed at the beginning of a request,
2161 but if you want to handle input yourself or speed things up a bit,
2162 you can enable on-demand parsing with a config parameter.
2163
2164     MyApp->config->{parse_on_demand} = 1;
2165
2166 =head1 PROXY SUPPORT
2167
2168 Many production servers operate using the common double-server approach,
2169 with a lightweight frontend web server passing requests to a larger
2170 backend server. An application running on the backend server must deal
2171 with two problems: the remote user always appears to be C<127.0.0.1> and
2172 the server's hostname will appear to be C<localhost> regardless of the
2173 virtual host that the user connected through.
2174
2175 Catalyst will automatically detect this situation when you are running
2176 the frontend and backend servers on the same machine. The following
2177 changes are made to the request.
2178
2179     $c->req->address is set to the user's real IP address, as read from
2180     the HTTP X-Forwarded-For header.
2181
2182     The host value for $c->req->base and $c->req->uri is set to the real
2183     host, as read from the HTTP X-Forwarded-Host header.
2184
2185 Obviously, your web server must support these headers for this to work.
2186
2187 In a more complex server farm environment where you may have your
2188 frontend proxy server(s) on different machines, you will need to set a
2189 configuration option to tell Catalyst to read the proxied data from the
2190 headers.
2191
2192     MyApp->config->{using_frontend_proxy} = 1;
2193
2194 If you do not wish to use the proxy support at all, you may set:
2195
2196     MyApp->config->{ignore_frontend_proxy} = 1;
2197
2198 =head1 THREAD SAFETY
2199
2200 Catalyst has been tested under Apache 2's threading mpm_worker, mpm_winnt,
2201 and the standalone forking HTTP server on Windows. We believe the Catalyst
2202 core to be thread-safe.
2203
2204 If you plan to operate in a threaded environment, remember that all other
2205 modules you are using must also be thread-safe. Some modules, most notably
2206 L<DBD::SQLite>, are not thread-safe.
2207
2208 =head1 SUPPORT
2209
2210 IRC:
2211
2212     Join #catalyst on irc.perl.org.
2213
2214 Mailing Lists:
2215
2216     http://lists.rawmode.org/mailman/listinfo/catalyst
2217     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2218
2219 Web:
2220
2221     http://catalyst.perl.org
2222
2223 Wiki:
2224
2225     http://dev.catalyst.perl.org
2226
2227 =head1 SEE ALSO
2228
2229 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2230
2231 =head2 L<Catalyst::Manual> - The Catalyst Manual
2232
2233 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2234
2235 =head2 L<Catalyst::Engine> - Core engine
2236
2237 =head2 L<Catalyst::Log> - Log class.
2238
2239 =head2 L<Catalyst::Request> - Request object
2240
2241 =head2 L<Catalyst::Response> - Response object
2242
2243 =head2 L<Catalyst::Test> - The test suite.
2244
2245 =head1 CREDITS
2246
2247 Andy Grundman
2248
2249 Andy Wardley
2250
2251 Andreas Marienborg
2252
2253 Andrew Bramble
2254
2255 Andrew Ford
2256
2257 Andrew Ruthven
2258
2259 Arthur Bergman
2260
2261 Autrijus Tang
2262
2263 Brian Cassidy
2264
2265 Carl Franks
2266
2267 Christian Hansen
2268
2269 Christopher Hicks
2270
2271 Dan Sully
2272
2273 Danijel Milicevic
2274
2275 David Kamholz
2276
2277 David Naughton
2278
2279 Drew Taylor
2280
2281 Gary Ashton Jones
2282
2283 Geoff Richards
2284
2285 Jesse Sheidlower
2286
2287 Jesse Vincent
2288
2289 Jody Belka
2290
2291 Johan Lindstrom
2292
2293 Juan Camacho
2294
2295 Leon Brocard
2296
2297 Marcus Ramberg
2298
2299 Matt S Trout
2300
2301 Robert Sedlacek
2302
2303 Sam Vilain
2304
2305 Sascha Kiefer
2306
2307 Tatsuhiko Miyagawa
2308
2309 Ulf Edvinsson
2310
2311 Yuval Kogman
2312
2313 =head1 AUTHOR
2314
2315 Sebastian Riedel, C<sri@oook.de>
2316
2317 =head1 LICENSE
2318
2319 This library is free software, you can redistribute it and/or modify it under
2320 the same terms as Perl itself.
2321
2322 =cut
2323
2324 1;