lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Class::Load 'load_class';
  45
  46 BEGIN { require 5.008003; }
  47
  48 has stack => (is => 'ro', default => sub { [] });
  49 has stash => (is => 'rw', default => sub { {} });
  50 has state => (is => 'rw', default => 0);
  51 has stats => (is => 'rw');
  52 has action => (is => 'rw');
  53 has counter => (is => 'rw', default => sub { {} });
  54 has request => (
  55     is => 'rw',
  56     default => sub {
  57         my $self = shift;
  58         $self->request_class->new($self->_build_request_constructor_args);
  59     },
  60     lazy => 1,
  61 );
  62 sub _build_request_constructor_args {
  63     my $self = shift;
  64     my %p = ( _log => $self->log );
  65     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  66     \%p;
  67 }
  68
  69 has response => (
  70     is => 'rw',
  71     default => sub {
  72         my $self = shift;
  73         $self->response_class->new($self->_build_response_constructor_args);
  74     },
  75     lazy => 1,
  76 );
  77 sub _build_response_constructor_args {
  78     my $self = shift;
  79     { _log => $self->log };
  80 }
  81
  82 has namespace => (is => 'rw');
  83
  84 sub depth { scalar @{ shift->stack || [] }; }
  85 sub comp { shift->component(@_) }
  86
  87 sub req {
  88     my $self = shift; return $self->request(@_);
  89 }
  90 sub res {
  91     my $self = shift; return $self->response(@_);
  92 }
  93
  94 # For backwards compatibility
  95 sub finalize_output { shift->finalize_body(@_) };
  96
  97 # For statistics
  98 our $COUNT     = 1;
  99 our $START     = time;
 100 our $RECURSION = 1000;
 101 our $DETACH    = Catalyst::Exception::Detach->new;
 102 our $GO        = Catalyst::Exception::Go->new;
 103
 104 #I imagine that very few of these really need to be class variables. if any.
 105 #maybe we should just make them attributes with a default?
 106 __PACKAGE__->mk_classdata($_)
 107   for qw/components arguments dispatcher engine log dispatcher_class
 108   engine_loader context_class request_class response_class stats_class
 109   setup_finished _psgi_app loading_psgi_file run_options/;
 110
 111 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 112 __PACKAGE__->request_class('Catalyst::Request');
 113 __PACKAGE__->response_class('Catalyst::Response');
 114 __PACKAGE__->stats_class('Catalyst::Stats');
 115
 116 # Remember to update this in Catalyst::Runtime as well!
 117
 118 our $VERSION = '5.90042';
 119
 120 sub import {
 121     my ( $class, @arguments ) = @_;
 122
 123     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 124     # callers @ISA.
 125     return unless $class eq 'Catalyst';
 126
 127     my $caller = caller();
 128     return if $caller eq 'main';
 129
 130     my $meta = Moose::Meta::Class->initialize($caller);
 131     unless ( $caller->isa('Catalyst') ) {
 132         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 133         $meta->superclasses(@superclasses);
 134     }
 135     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 136     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 137
 138     unless( $meta->has_method('meta') ){
 139         if ($Moose::VERSION >= 1.15) {
 140             $meta->_add_meta_method('meta');
 141         }
 142         else {
 143             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 144         }
 145     }
 146
 147     $caller->arguments( [@arguments] );
 148     $caller->setup_home;
 149 }
 150
 151 sub _application { $_[0] }
 152
 153 =encoding UTF-8
 154
 155 =head1 NAME
 156
 157 Catalyst - The Elegant MVC Web Application Framework
 158
 159 =head1 SYNOPSIS
 160
 161 See the L<Catalyst::Manual> distribution for comprehensive
 162 documentation and tutorials.
 163
 164     # Install Catalyst::Devel for helpers and other development tools
 165     # use the helper to create a new application
 166     catalyst.pl MyApp
 167
 168     # add models, views, controllers
 169     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 170     script/myapp_create.pl view MyTemplate TT
 171     script/myapp_create.pl controller Search
 172
 173     # built in testserver -- use -r to restart automatically on changes
 174     # --help to see all available options
 175     script/myapp_server.pl
 176
 177     # command line testing interface
 178     script/myapp_test.pl /yada
 179
 180     ### in lib/MyApp.pm
 181     use Catalyst qw/-Debug/; # include plugins here as well
 182
 183     ### In lib/MyApp/Controller/Root.pm (autocreated)
 184     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 185         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 186         $c->stash->{template} = 'foo.tt'; # set the template
 187         # lookup something from db -- stash vars are passed to TT
 188         $c->stash->{data} =
 189           $c->model('Database::Foo')->search( { country => $args[0] } );
 190         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 191             $c->forward( 'bar' ); # process another action
 192             # do something else after forward returns
 193         }
 194     }
 195
 196     # The foo.tt TT template can use the stash data from the database
 197     [% WHILE (item = data.next) %]
 198         [% item.foo %]
 199     [% END %]
 200
 201     # called for /bar/of/soap, /bar/of/soap/10, etc.
 202     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 203
 204     # called after all actions are finished
 205     sub end : Action {
 206         my ( $self, $c ) = @_;
 207         if ( scalar @{ $c->error } ) { ... } # handle errors
 208         return if $c->res->body; # already have a response
 209         $c->forward( 'MyApp::View::TT' ); # render template
 210     }
 211
 212 See L<Catalyst::Manual::Intro> for additional information.
 213
 214 =head1 DESCRIPTION
 215
 216 Catalyst is a modern framework for making web applications without the
 217 pain usually associated with this process. This document is a reference
 218 to the main Catalyst application. If you are a new user, we suggest you
 219 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 220
 221 See L<Catalyst::Manual> for more documentation.
 222
 223 Catalyst plugins can be loaded by naming them as arguments to the "use
 224 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 225 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 226 C<My::Module>.
 227
 228     use Catalyst qw/My::Module/;
 229
 230 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 231 fully qualify the name by using a unary plus:
 232
 233     use Catalyst qw/
 234         My::Module
 235         +Fully::Qualified::Plugin::Name
 236     /;
 237
 238 Special flags like C<-Debug> can also be specified as
 239 arguments when Catalyst is loaded:
 240
 241     use Catalyst qw/-Debug My::Module/;
 242
 243 The position of plugins and flags in the chain is important, because
 244 they are loaded in the order in which they appear.
 245
 246 The following flags are supported:
 247
 248 =head2 -Debug
 249
 250 Enables debug output. You can also force this setting from the system
 251 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 252 settings override the application, with <MYAPP>_DEBUG having the highest
 253 priority.
 254
 255 This sets the log level to 'debug' and enables full debug output on the
 256 error screen. If you only want the latter, see L<< $c->debug >>.
 257
 258 =head2 -Home
 259
 260 Forces Catalyst to use a specific home directory, e.g.:
 261
 262     use Catalyst qw[-Home=/usr/mst];
 263
 264 This can also be done in the shell environment by setting either the
 265 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 266 is replaced with the uppercased name of your application, any "::" in
 267 the name will be replaced with underscores, e.g. MyApp::Web should use
 268 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 269
 270 If none of these are set, Catalyst will attempt to automatically detect the
 271 home directory. If you are working in a development environment, Catalyst
 272 will try and find the directory containing either Makefile.PL, Build.PL,
 273 dist.ini, or cpanfile. If the application has been installed into the system
 274 (i.e. you have done C<make install>), then Catalyst will use the path to your
 275 application module, without the .pm extension (e.g., /foo/MyApp if your
 276 application was installed at /foo/MyApp.pm)
 277
 278 =head2 -Log
 279
 280     use Catalyst '-Log=warn,fatal,error';
 281
 282 Specifies a comma-delimited list of log levels.
 283
 284 =head2 -Stats
 285
 286 Enables statistics collection and reporting.
 287
 288    use Catalyst qw/-Stats=1/;
 289
 290 You can also force this setting from the system environment with CATALYST_STATS
 291 or <MYAPP>_STATS. The environment settings override the application, with
 292 <MYAPP>_STATS having the highest priority.
 293
 294 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 295
 296 =head1 METHODS
 297
 298 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 299
 300 =head2 $c->action
 301
 302 Returns a L<Catalyst::Action> object for the current action, which
 303 stringifies to the action name. See L<Catalyst::Action>.
 304
 305 =head2 $c->namespace
 306
 307 Returns the namespace of the current action, i.e., the URI prefix
 308 corresponding to the controller of the current action. For example:
 309
 310     # in Controller::Foo::Bar
 311     $c->namespace; # returns 'foo/bar';
 312
 313 =head2 $c->request
 314
 315 =head2 $c->req
 316
 317 Returns the current L<Catalyst::Request> object, giving access to
 318 information about the current client request (including parameters,
 319 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 320
 321 =head2 REQUEST FLOW HANDLING
 322
 323 =head2 $c->forward( $action [, \@arguments ] )
 324
 325 =head2 $c->forward( $class, $method, [, \@arguments ] )
 326
 327 This is one way of calling another action (method) in the same or
 328 a different controller. You can also use C<< $self->my_method($c, @args) >>
 329 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 330 in a different controller.
 331 The main difference is that 'forward' uses some of the Catalyst request
 332 cycle overhead, including debugging, which may be useful to you. On the
 333 other hand, there are some complications to using 'forward', restrictions
 334 on values returned from 'forward', and it may not handle errors as you prefer.
 335 Whether you use 'forward' or not is up to you; it is not considered superior to
 336 the other ways to call a method.
 337
 338 'forward' calls  another action, by its private name. If you give a
 339 class name but no method, C<process()> is called. You may also optionally
 340 pass arguments in an arrayref. The action will receive the arguments in
 341 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 342 C<< $c->req->args >> will be restored to the previous values.
 343
 344 Any data C<return>ed from the action forwarded to, will be returned by the
 345 call to forward.
 346
 347     my $foodata = $c->forward('/foo');
 348     $c->forward('index');
 349     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 350     $c->forward('View::TT');
 351
 352 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 353 an C<< eval { } >> around the call (actually
 354 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 355 exceptions thrown by the called action non-fatal and pushing them onto
 356 $c->error instead. If you want C<die> to propagate you need to do something
 357 like:
 358
 359     $c->forward('foo');
 360     die join "\n", @{ $c->error } if @{ $c->error };
 361
 362 Or make sure to always return true values from your actions and write
 363 your code like this:
 364
 365     $c->forward('foo') || return;
 366
 367 Another note is that C<< $c->forward >> always returns a scalar because it
 368 actually returns $c->state which operates in a scalar context.
 369 Thus, something like:
 370
 371     return @array;
 372
 373 in an action that is forwarded to is going to return a scalar,
 374 i.e. how many items are in that array, which is probably not what you want.
 375 If you need to return an array then return a reference to it,
 376 or stash it like so:
 377
 378     $c->stash->{array} = \@array;
 379
 380 and access it from the stash.
 381
 382 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 383
 384 =cut
 385
 386 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 387
 388 =head2 $c->detach( $action [, \@arguments ] )
 389
 390 =head2 $c->detach( $class, $method, [, \@arguments ] )
 391
 392 =head2 $c->detach()
 393
 394 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 395 doesn't return to the previous action when processing is finished.
 396
 397 When called with no arguments it escapes the processing chain entirely.
 398
 399 =cut
 400
 401 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 402
 403 =head2 $c->visit( $action [, \@arguments ] )
 404
 405 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 406
 407 =head2 $c->visit( $class, $method, [, \@arguments ] )
 408
 409 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 410
 411 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 412 but does a full dispatch, instead of just calling the new C<$action> /
 413 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 414 you go to are called, just like a new request.
 415
 416 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 417 This means, for example, that C<< $c->action >> methods such as
 418 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 419 L<reverse|Catalyst::Action/reverse> return information for the visited action
 420 when they are invoked within the visited action.  This is different from the
 421 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 422 continues to use the $c->action object from the caller action even when
 423 invoked from the called action.
 424
 425 C<< $c->stash >> is kept unchanged.
 426
 427 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 428 allows you to "wrap" another action, just as it would have been called by
 429 dispatching from a URL, while the analogous
 430 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 431 transfer control to another action as if it had been reached directly from a URL.
 432
 433 =cut
 434
 435 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 436
 437 =head2 $c->go( $action [, \@arguments ] )
 438
 439 =head2 $c->go( $action [, \@captures, \@arguments ] )
 440
 441 =head2 $c->go( $class, $method, [, \@arguments ] )
 442
 443 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 444
 445 The relationship between C<go> and
 446 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 447 the relationship between
 448 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 449 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 450 C<< $c->go >> will perform a full dispatch on the specified action or method,
 451 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 452 C<go> escapes the processing of the current request chain on completion, and
 453 does not return to its caller.
 454
 455 @arguments are arguments to the final destination of $action. @captures are
 456 arguments to the intermediate steps, if any, on the way to the final sub of
 457 $action.
 458
 459 =cut
 460
 461 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 462
 463 =head2 $c->response
 464
 465 =head2 $c->res
 466
 467 Returns the current L<Catalyst::Response> object, see there for details.
 468
 469 =head2 $c->stash
 470
 471 Returns a hashref to the stash, which may be used to store data and pass
 472 it between components during a request. You can also set hash keys by
 473 passing arguments. The stash is automatically sent to the view. The
 474 stash is cleared at the end of a request; it cannot be used for
 475 persistent storage (for this you must use a session; see
 476 L<Catalyst::Plugin::Session> for a complete system integrated with
 477 Catalyst).
 478
 479     $c->stash->{foo} = $bar;
 480     $c->stash( { moose => 'majestic', qux => 0 } );
 481     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 482
 483     # stash is automatically passed to the view for use in a template
 484     $c->forward( 'MyApp::View::TT' );
 485
 486 =cut
 487
 488 around stash => sub {
 489     my $orig = shift;
 490     my $c = shift;
 491     my $stash = $orig->($c);
 492     if (@_) {
 493         my $new_stash = @_ > 1 ? {@_} : $_[0];
 494         croak('stash takes a hash or hashref') unless ref $new_stash;
 495         foreach my $key ( keys %$new_stash ) {
 496           $stash->{$key} = $new_stash->{$key};
 497         }
 498     }
 499
 500     return $stash;
 501 };
 502
 503
 504 =head2 $c->error
 505
 506 =head2 $c->error($error, ...)
 507
 508 =head2 $c->error($arrayref)
 509
 510 Returns an arrayref containing error messages.  If Catalyst encounters an
 511 error while processing a request, it stores the error in $c->error.  This
 512 method should only be used to store fatal error messages.
 513
 514     my @error = @{ $c->error };
 515
 516 Add a new error.
 517
 518     $c->error('Something bad happened');
 519
 520 =cut
 521
 522 sub error {
 523     my $c = shift;
 524     if ( $_[0] ) {
 525         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 526         croak @$error unless ref $c;
 527         push @{ $c->{error} }, @$error;
 528     }
 529     elsif ( defined $_[0] ) { $c->{error} = undef }
 530     return $c->{error} || [];
 531 }
 532
 533
 534 =head2 $c->state
 535
 536 Contains the return value of the last executed action.
 537 Note that << $c->state >> operates in a scalar context which means that all
 538 values it returns are scalar.
 539
 540 =head2 $c->clear_errors
 541
 542 Clear errors.  You probably don't want to clear the errors unless you are
 543 implementing a custom error screen.
 544
 545 This is equivalent to running
 546
 547     $c->error(0);
 548
 549 =cut
 550
 551 sub clear_errors {
 552     my $c = shift;
 553     $c->error(0);
 554 }
 555
 556 sub _comp_search_prefixes {
 557     my $c = shift;
 558     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 559 }
 560
 561 # search components given a name and some prefixes
 562 sub _comp_names_search_prefixes {
 563     my ( $c, $name, @prefixes ) = @_;
 564     my $appclass = ref $c || $c;
 565     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 566     $filter = qr/$filter/; # Compile regex now rather than once per loop
 567
 568     # map the original component name to the sub part that we will search against
 569     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 570         grep { /$filter/ } keys %{ $c->components };
 571
 572     # undef for a name will return all
 573     return keys %eligible if !defined $name;
 574
 575     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 576     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 577
 578     return @result if @result;
 579
 580     # if we were given a regexp to search against, we're done.
 581     return if $name->$_isa('Regexp');
 582
 583     # skip regexp fallback if configured
 584     return
 585         if $appclass->config->{disable_component_resolution_regex_fallback};
 586
 587     # regexp fallback
 588     $query  = qr/$name/i;
 589     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 590
 591     # no results? try against full names
 592     if( !@result ) {
 593         @result = grep { m{$query} } keys %eligible;
 594     }
 595
 596     # don't warn if we didn't find any results, it just might not exist
 597     if( @result ) {
 598         # Disgusting hack to work out correct method name
 599         my $warn_for = lc $prefixes[0];
 600         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 601            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 602            "component resolution is unreliable and unsafe.";
 603         my $short = $result[0];
 604         # remove the component namespace prefix
 605         $short =~ s/.*?(Model|Controller|View):://;
 606         my $shortmess = Carp::shortmess('');
 607         if ($shortmess =~ m#Catalyst/Plugin#) {
 608            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 609               "plugin's config";
 610         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 611            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 612               "component's config";
 613         } else {
 614            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 615               "but if you really wanted to search, pass in a regexp as the argument " .
 616               "like so: \$c->${warn_for}(qr/${name}/)";
 617         }
 618         $c->log->warn( "${msg}$shortmess" );
 619     }
 620
 621     return @result;
 622 }
 623
 624 # Find possible names for a prefix
 625 sub _comp_names {
 626     my ( $c, @prefixes ) = @_;
 627     my $appclass = ref $c || $c;
 628
 629     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 630
 631     my @names = map { s{$filter}{}; $_; }
 632         $c->_comp_names_search_prefixes( undef, @prefixes );
 633
 634     return @names;
 635 }
 636
 637 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 638 sub _filter_component {
 639     my ( $c, $comp, @args ) = @_;
 640
 641     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 642         return $comp->ACCEPT_CONTEXT( $c, @args );
 643     }
 644
 645     return $comp;
 646 }
 647
 648 =head2 COMPONENT ACCESSORS
 649
 650 =head2 $c->controller($name)
 651
 652 Gets a L<Catalyst::Controller> instance by name.
 653
 654     $c->controller('Foo')->do_stuff;
 655
 656 If the name is omitted, will return the controller for the dispatched
 657 action.
 658
 659 If you want to search for controllers, pass in a regexp as the argument.
 660
 661     # find all controllers that start with Foo
 662     my @foo_controllers = $c->controller(qr{^Foo});
 663
 664
 665 =cut
 666
 667 sub controller {
 668     my ( $c, $name, @args ) = @_;
 669
 670     my $appclass = ref($c) || $c;
 671     if( $name ) {
 672         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 673             my $comps = $c->components;
 674             my $check = $appclass."::Controller::".$name;
 675             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 676         }
 677         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 678         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 679         return $c->_filter_component( $result[ 0 ], @args );
 680     }
 681
 682     return $c->component( $c->action->class );
 683 }
 684
 685 =head2 $c->model($name)
 686
 687 Gets a L<Catalyst::Model> instance by name.
 688
 689     $c->model('Foo')->do_stuff;
 690
 691 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 692
 693 If the name is omitted, it will look for
 694  - a model object in $c->stash->{current_model_instance}, then
 695  - a model name in $c->stash->{current_model}, then
 696  - a config setting 'default_model', or
 697  - check if there is only one model, and return it if that's the case.
 698
 699 If you want to search for models, pass in a regexp as the argument.
 700
 701     # find all models that start with Foo
 702     my @foo_models = $c->model(qr{^Foo});
 703
 704 =cut
 705
 706 sub model {
 707     my ( $c, $name, @args ) = @_;
 708     my $appclass = ref($c) || $c;
 709     if( $name ) {
 710         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 711             my $comps = $c->components;
 712             my $check = $appclass."::Model::".$name;
 713             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 714         }
 715         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 716         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 717         return $c->_filter_component( $result[ 0 ], @args );
 718     }
 719
 720     if (ref $c) {
 721         return $c->stash->{current_model_instance}
 722           if $c->stash->{current_model_instance};
 723         return $c->model( $c->stash->{current_model} )
 724           if $c->stash->{current_model};
 725     }
 726     return $c->model( $appclass->config->{default_model} )
 727       if $appclass->config->{default_model};
 728
 729     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 730
 731     if( $rest ) {
 732         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 733         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 734         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 735         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 736         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 737     }
 738
 739     return $c->_filter_component( $comp );
 740 }
 741
 742
 743 =head2 $c->view($name)
 744
 745 Gets a L<Catalyst::View> instance by name.
 746
 747     $c->view('Foo')->do_stuff;
 748
 749 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 750
 751 If the name is omitted, it will look for
 752  - a view object in $c->stash->{current_view_instance}, then
 753  - a view name in $c->stash->{current_view}, then
 754  - a config setting 'default_view', or
 755  - check if there is only one view, and return it if that's the case.
 756
 757 If you want to search for views, pass in a regexp as the argument.
 758
 759     # find all views that start with Foo
 760     my @foo_views = $c->view(qr{^Foo});
 761
 762 =cut
 763
 764 sub view {
 765     my ( $c, $name, @args ) = @_;
 766
 767     my $appclass = ref($c) || $c;
 768     if( $name ) {
 769         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 770             my $comps = $c->components;
 771             my $check = $appclass."::View::".$name;
 772             if( exists $comps->{$check} ) {
 773                 return $c->_filter_component( $comps->{$check}, @args );
 774             }
 775             else {
 776                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 777             }
 778         }
 779         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 780         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 781         return $c->_filter_component( $result[ 0 ], @args );
 782     }
 783
 784     if (ref $c) {
 785         return $c->stash->{current_view_instance}
 786           if $c->stash->{current_view_instance};
 787         return $c->view( $c->stash->{current_view} )
 788           if $c->stash->{current_view};
 789     }
 790     return $c->view( $appclass->config->{default_view} )
 791       if $appclass->config->{default_view};
 792
 793     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 794
 795     if( $rest ) {
 796         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 797         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 798         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 799         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 800         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 801     }
 802
 803     return $c->_filter_component( $comp );
 804 }
 805
 806 =head2 $c->controllers
 807
 808 Returns the available names which can be passed to $c->controller
 809
 810 =cut
 811
 812 sub controllers {
 813     my ( $c ) = @_;
 814     return $c->_comp_names(qw/Controller C/);
 815 }
 816
 817 =head2 $c->models
 818
 819 Returns the available names which can be passed to $c->model
 820
 821 =cut
 822
 823 sub models {
 824     my ( $c ) = @_;
 825     return $c->_comp_names(qw/Model M/);
 826 }
 827
 828
 829 =head2 $c->views
 830
 831 Returns the available names which can be passed to $c->view
 832
 833 =cut
 834
 835 sub views {
 836     my ( $c ) = @_;
 837     return $c->_comp_names(qw/View V/);
 838 }
 839
 840 =head2 $c->comp($name)
 841
 842 =head2 $c->component($name)
 843
 844 Gets a component object by name. This method is not recommended,
 845 unless you want to get a specific component by full
 846 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 847 should be used instead.
 848
 849 If C<$name> is a regexp, a list of components matched against the full
 850 component name will be returned.
 851
 852 If Catalyst can't find a component by name, it will fallback to regex
 853 matching by default. To disable this behaviour set
 854 disable_component_resolution_regex_fallback to a true value.
 855
 856     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 857
 858 =cut
 859
 860 sub component {
 861     my ( $c, $name, @args ) = @_;
 862
 863     if( $name ) {
 864         my $comps = $c->components;
 865
 866         if( !ref $name ) {
 867             # is it the exact name?
 868             return $c->_filter_component( $comps->{ $name }, @args )
 869                        if exists $comps->{ $name };
 870
 871             # perhaps we just omitted "MyApp"?
 872             my $composed = ( ref $c || $c ) . "::${name}";
 873             return $c->_filter_component( $comps->{ $composed }, @args )
 874                        if exists $comps->{ $composed };
 875
 876             # search all of the models, views and controllers
 877             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 878             return $c->_filter_component( $comp, @args ) if $comp;
 879         }
 880
 881         return
 882             if $c->config->{disable_component_resolution_regex_fallback};
 883
 884         # This is here so $c->comp( '::M::' ) works
 885         my $query = ref $name ? $name : qr{$name}i;
 886
 887         my @result = grep { m{$query} } keys %{ $c->components };
 888         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 889
 890         if( $result[ 0 ] ) {
 891             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 892             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 893             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 894             return $c->_filter_component( $result[ 0 ], @args );
 895         }
 896
 897         # I would expect to return an empty list here, but that breaks back-compat
 898     }
 899
 900     # fallback
 901     return sort keys %{ $c->components };
 902 }
 903
 904 =head2 CLASS DATA AND HELPER CLASSES
 905
 906 =head2 $c->config
 907
 908 Returns or takes a hashref containing the application's configuration.
 909
 910     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 911
 912 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 913 like C<myapp.conf> in your applications home directory. See
 914 L<Catalyst::Plugin::ConfigLoader>.
 915
 916 =head3 Cascading configuration
 917
 918 The config method is present on all Catalyst components, and configuration
 919 will be merged when an application is started. Configuration loaded with
 920 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 921 followed by configuration in your top level C<MyApp> class. These two
 922 configurations are merged, and then configuration data whose hash key matches a
 923 component name is merged with configuration for that component.
 924
 925 The configuration for a component is then passed to the C<new> method when a
 926 component is constructed.
 927
 928 For example:
 929
 930     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 931     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 932
 933 will mean that C<MyApp::Model::Foo> receives the following data when
 934 constructed:
 935
 936     MyApp::Model::Foo->new({
 937         bar => 'baz',
 938         quux => 'frob',
 939         overrides => 'me',
 940     });
 941
 942 It's common practice to use a Moose attribute
 943 on the receiving component to access the config value.
 944
 945     package MyApp::Model::Foo;
 946
 947     use Moose;
 948
 949     # this attr will receive 'baz' at construction time
 950     has 'bar' => (
 951         is  => 'rw',
 952         isa => 'Str',
 953     );
 954
 955 You can then get the value 'baz' by calling $c->model('Foo')->bar
 956 (or $self->bar inside code in the model).
 957
 958 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 959 as a way of reading config within your code, as this B<will not> give you the
 960 correctly merged config back. You B<MUST> take the config values supplied to
 961 the constructor and use those instead.
 962
 963 =cut
 964
 965 around config => sub {
 966     my $orig = shift;
 967     my $c = shift;
 968
 969     croak('Setting config after setup has been run is not allowed.')
 970         if ( @_ and $c->setup_finished );
 971
 972     $c->$orig(@_);
 973 };
 974
 975 =head2 $c->log
 976
 977 Returns the logging object instance. Unless it is already set, Catalyst
 978 sets this up with a L<Catalyst::Log> object. To use your own log class,
 979 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 980 C<< __PACKAGE__->setup >>.
 981
 982  __PACKAGE__->log( MyLogger->new );
 983  __PACKAGE__->setup;
 984
 985 And later:
 986
 987     $c->log->info( 'Now logging with my own logger!' );
 988
 989 Your log class should implement the methods described in
 990 L<Catalyst::Log>.
 991
 992
 993 =head2 $c->debug
 994
 995 Returns 1 if debug mode is enabled, 0 otherwise.
 996
 997 You can enable debug mode in several ways:
 998
 999 =over
1000
1001 =item By calling myapp_server.pl with the -d flag
1002
1003 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1004
1005 =item The -Debug option in your MyApp.pm
1006
1007 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1008
1009 =back
1010
1011 The first three also set the log level to 'debug'.
1012
1013 Calling C<< $c->debug(1) >> has no effect.
1014
1015 =cut
1016
1017 sub debug { 0 }
1018
1019 =head2 $c->dispatcher
1020
1021 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1022
1023 =head2 $c->engine
1024
1025 Returns the engine instance. See L<Catalyst::Engine>.
1026
1027
1028 =head2 UTILITY METHODS
1029
1030 =head2 $c->path_to(@path)
1031
1032 Merges C<@path> with C<< $c->config->{home} >> and returns a
1033 L<Path::Class::Dir> object. Note you can usually use this object as
1034 a filename, but sometimes you will have to explicitly stringify it
1035 yourself by calling the C<< ->stringify >> method.
1036
1037 For example:
1038
1039     $c->path_to( 'db', 'sqlite.db' );
1040
1041 =cut
1042
1043 sub path_to {
1044     my ( $c, @path ) = @_;
1045     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1046     if ( -d $path ) { return $path }
1047     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1048 }
1049
1050 sub plugin {
1051     my ( $class, $name, $plugin, @args ) = @_;
1052
1053     # See block comment in t/unit_core_plugin.t
1054     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1055
1056     $class->_register_plugin( $plugin, 1 );
1057
1058     eval { $plugin->import };
1059     $class->mk_classdata($name);
1060     my $obj;
1061     eval { $obj = $plugin->new(@args) };
1062
1063     if ($@) {
1064         Catalyst::Exception->throw( message =>
1065               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1066     }
1067
1068     $class->$name($obj);
1069     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1070       if $class->debug;
1071 }
1072
1073 =head2 MyApp->setup
1074
1075 Initializes the dispatcher and engine, loads any plugins, and loads the
1076 model, view, and controller components. You may also specify an array
1077 of plugins to load here, if you choose to not load them in the C<use
1078 Catalyst> line.
1079
1080     MyApp->setup;
1081     MyApp->setup( qw/-Debug/ );
1082
1083 B<Note:> You B<should not> wrap this method with method modifiers
1084 or bad things will happen - wrap the C<setup_finalize> method instead.
1085
1086 =cut
1087
1088 sub setup {
1089     my ( $class, @arguments ) = @_;
1090     croak('Running setup more than once')
1091         if ( $class->setup_finished );
1092
1093     unless ( $class->isa('Catalyst') ) {
1094
1095         Catalyst::Exception->throw(
1096             message => qq/'$class' does not inherit from Catalyst/ );
1097     }
1098
1099     if ( $class->arguments ) {
1100         @arguments = ( @arguments, @{ $class->arguments } );
1101     }
1102
1103     # Process options
1104     my $flags = {};
1105
1106     foreach (@arguments) {
1107
1108         if (/^-Debug$/) {
1109             $flags->{log} =
1110               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1111         }
1112         elsif (/^-(\w+)=?(.*)$/) {
1113             $flags->{ lc $1 } = $2;
1114         }
1115         else {
1116             push @{ $flags->{plugins} }, $_;
1117         }
1118     }
1119
1120     $class->setup_home( delete $flags->{home} );
1121
1122     $class->setup_log( delete $flags->{log} );
1123     $class->setup_plugins( delete $flags->{plugins} );
1124     $class->setup_dispatcher( delete $flags->{dispatcher} );
1125     if (my $engine = delete $flags->{engine}) {
1126         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1127     }
1128     $class->setup_engine();
1129     $class->setup_stats( delete $flags->{stats} );
1130
1131     for my $flag ( sort keys %{$flags} ) {
1132
1133         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1134             &$code( $class, delete $flags->{$flag} );
1135         }
1136         else {
1137             $class->log->warn(qq/Unknown flag "$flag"/);
1138         }
1139     }
1140
1141     eval { require Catalyst::Devel; };
1142     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1143         $class->log->warn(<<"EOF");
1144 You are running an old script!
1145
1146   Please update by running (this will overwrite existing files):
1147     catalyst.pl -force -scripts $class
1148
1149   or (this will not overwrite existing files):
1150     catalyst.pl -scripts $class
1151
1152 EOF
1153     }
1154
1155     if ( $class->debug ) {
1156         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1157
1158         if (@plugins) {
1159             my $column_width = Catalyst::Utils::term_width() - 6;
1160             my $t = Text::SimpleTable->new($column_width);
1161             $t->row($_) for @plugins;
1162             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1163         }
1164
1165         my $dispatcher = $class->dispatcher;
1166         my $engine     = $class->engine;
1167         my $home       = $class->config->{home};
1168
1169         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1170         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1171
1172         $home
1173           ? ( -d $home )
1174           ? $class->log->debug(qq/Found home "$home"/)
1175           : $class->log->debug(qq/Home "$home" doesn't exist/)
1176           : $class->log->debug(q/Couldn't find home/);
1177     }
1178
1179     # Call plugins setup, this is stupid and evil.
1180     # Also screws C3 badly on 5.10, hack to avoid.
1181     {
1182         no warnings qw/redefine/;
1183         local *setup = sub { };
1184         $class->setup unless $Catalyst::__AM_RESTARTING;
1185     }
1186
1187     # Initialize our data structure
1188     $class->components( {} );
1189
1190     $class->setup_components;
1191
1192     if ( $class->debug ) {
1193         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1194         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1195         for my $comp ( sort keys %{ $class->components } ) {
1196             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1197             $t->row( $comp, $type );
1198         }
1199         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1200           if ( keys %{ $class->components } );
1201     }
1202
1203     # Add our self to components, since we are also a component
1204     if( $class->isa('Catalyst::Controller') ){
1205       $class->components->{$class} = $class;
1206     }
1207
1208     $class->setup_actions;
1209
1210     if ( $class->debug ) {
1211         my $name = $class->config->{name} || 'Application';
1212         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1213     }
1214
1215     if ($class->config->{case_sensitive}) {
1216         $class->log->warn($class . "->config->{case_sensitive} is set.");
1217         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1218     }
1219
1220     $class->setup_finalize;
1221     # Should be the last thing we do so that user things hooking
1222     # setup_finalize can log..
1223     $class->log->_flush() if $class->log->can('_flush');
1224     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1225 }
1226
1227 =head2 $app->setup_finalize
1228
1229 A hook to attach modifiers to. This method does not do anything except set the
1230 C<setup_finished> accessor.
1231
1232 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1233
1234 Example:
1235
1236     after setup_finalize => sub {
1237         my $app = shift;
1238
1239         ## do stuff here..
1240     };
1241
1242 =cut
1243
1244 sub setup_finalize {
1245     my ($class) = @_;
1246     $class->setup_finished(1);
1247 }
1248
1249 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1250
1251 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1252
1253 Constructs an absolute L<URI> object based on the application root, the
1254 provided path, and the additional arguments and query parameters provided.
1255 When used as a string, provides a textual URI.  If you need more flexibility
1256 than this (i.e. the option to provide relative URIs etc.) see
1257 L<Catalyst::Plugin::SmartURI>.
1258
1259 If no arguments are provided, the URI for the current action is returned.
1260 To return the current action and also provide @args, use
1261 C<< $c->uri_for( $c->action, @args ) >>.
1262
1263 If the first argument is a string, it is taken as a public URI path relative
1264 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1265 relative to the application root (if it does). It is then merged with
1266 C<< $c->request->base >>; any C<@args> are appended as additional path
1267 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1268
1269 If the first argument is a L<Catalyst::Action> it represents an action which
1270 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1271 optional C<\@captures> argument (an arrayref) allows passing the captured
1272 variables that are needed to fill in the paths of Chained and Regex actions;
1273 once the path is resolved, C<uri_for> continues as though a path was
1274 provided, appending any arguments or parameters and creating an absolute
1275 URI.
1276
1277 The captures for the current request can be found in
1278 C<< $c->request->captures >>, and actions can be resolved using
1279 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1280 path, use C<< $c->uri_for_action >> instead.
1281
1282   # Equivalent to $c->req->uri
1283   $c->uri_for($c->action, $c->req->captures,
1284       @{ $c->req->args }, $c->req->params);
1285
1286   # For the Foo action in the Bar controller
1287   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1288
1289   # Path to a static resource
1290   $c->uri_for('/static/images/logo.png');
1291
1292 =cut
1293
1294 sub uri_for {
1295     my ( $c, $path, @args ) = @_;
1296
1297     if ( $path->$_isa('Catalyst::Controller') ) {
1298         $path = $path->path_prefix;
1299         $path =~ s{/+\z}{};
1300         $path .= '/';
1301     }
1302
1303     undef($path) if (defined $path && $path eq '');
1304
1305     my $params =
1306       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1307
1308     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1309     foreach my $arg (@args) {
1310         utf8::encode($arg) if utf8::is_utf8($arg);
1311         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1312     }
1313
1314     if ( $path->$_isa('Catalyst::Action') ) { # action object
1315         s|/|%2F|g for @args;
1316         my $captures = [ map { s|/|%2F|g; $_; }
1317                         ( scalar @args && ref $args[0] eq 'ARRAY'
1318                          ? @{ shift(@args) }
1319                          : ()) ];
1320
1321         foreach my $capture (@$captures) {
1322             utf8::encode($capture) if utf8::is_utf8($capture);
1323             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1324         }
1325
1326         my $action = $path;
1327         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1328         if( !@args && $action->number_of_args ) {
1329             my $expanded_action = $c->dispatcher->expand_action( $action );
1330
1331             my $num_captures = $expanded_action->number_of_captures;
1332             unshift @args, splice @$captures, $num_captures;
1333         }
1334
1335        $path = $c->dispatcher->uri_for_action($action, $captures);
1336         if (not defined $path) {
1337             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1338                 if $c->debug;
1339             return undef;
1340         }
1341         $path = '/' if $path eq '';
1342     }
1343
1344     unshift(@args, $path);
1345
1346     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1347         my $namespace = $c->namespace;
1348         if (defined $path) { # cheesy hack to handle path '../foo'
1349            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1350         }
1351         unshift(@args, $namespace || '');
1352     }
1353
1354     # join args with '/', or a blank string
1355     my $args = join('/', grep { defined($_) } @args);
1356     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1357     $args =~ s!^/+!!;
1358
1359     my ($base, $class) = ('/', 'URI::_generic');
1360     if(blessed($c)) {
1361       $base = $c->req->base;
1362       $class = ref($base);
1363       $base =~ s{(?<!/)$}{/};
1364     }
1365
1366     my $query = '';
1367
1368     if (my @keys = keys %$params) {
1369       # somewhat lifted from URI::_query's query_form
1370       $query = '?'.join('&', map {
1371           my $val = $params->{$_};
1372           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1373           s/ /+/g;
1374           my $key = $_;
1375           $val = '' unless defined $val;
1376           (map {
1377               my $param = "$_";
1378               utf8::encode( $param ) if utf8::is_utf8($param);
1379               # using the URI::Escape pattern here so utf8 chars survive
1380               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1381               $param =~ s/ /+/g;
1382               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1383       } @keys);
1384     }
1385
1386     my $res = bless(\"${base}${args}${query}", $class);
1387     $res;
1388 }
1389
1390 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1391
1392 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1393
1394 =over
1395
1396 =item $path
1397
1398 A private path to the Catalyst action you want to create a URI for.
1399
1400 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1401 >> and passing the resulting C<$action> and the remaining arguments to C<<
1402 $c->uri_for >>.
1403
1404 You can also pass in a Catalyst::Action object, in which case it is passed to
1405 C<< $c->uri_for >>.
1406
1407 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1408
1409 For example, if the action looks like:
1410
1411  package MyApp::Controller::Users;
1412
1413  sub lst : Path('the-list') {}
1414
1415 You can use:
1416
1417  $c->uri_for_action('/users/lst')
1418
1419 and it will create the URI /users/the-list.
1420
1421 =item \@captures_and_args?
1422
1423 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1424 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1425 to interpolate all the parameters in the URI.
1426
1427 =item @args?
1428
1429 Optional list of extra arguments - can be supplied in the
1430 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1431 code.
1432
1433 Your action can have zero, a fixed or a variable number of args (e.g.
1434 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1435
1436 =item \%query_values?
1437
1438 Optional array reference of query parameters to append. E.g.
1439
1440   { foo => 'bar' }
1441
1442 will generate
1443
1444   /rest/of/your/uri?foo=bar
1445
1446 =back
1447
1448 =cut
1449
1450 sub uri_for_action {
1451     my ( $c, $path, @args ) = @_;
1452     my $action = blessed($path)
1453       ? $path
1454       : $c->dispatcher->get_action_by_path($path);
1455     unless (defined $action) {
1456       croak "Can't find action for path '$path'";
1457     }
1458     return $c->uri_for( $action, @args );
1459 }
1460
1461 =head2 $c->welcome_message
1462
1463 Returns the Catalyst welcome HTML page.
1464
1465 =cut
1466
1467 sub welcome_message {
1468     my $c      = shift;
1469     my $name   = $c->config->{name};
1470     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1471     my $prefix = Catalyst::Utils::appprefix( ref $c );
1472     $c->response->content_type('text/html; charset=utf-8');
1473     return <<"EOF";
1474 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1475     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1476 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1477     <head>
1478     <meta http-equiv="Content-Language" content="en" />
1479     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1480         <title>$name on Catalyst $VERSION</title>
1481         <style type="text/css">
1482             body {
1483                 color: #000;
1484                 background-color: #eee;
1485             }
1486             div#content {
1487                 width: 640px;
1488                 margin-left: auto;
1489                 margin-right: auto;
1490                 margin-top: 10px;
1491                 margin-bottom: 10px;
1492                 text-align: left;
1493                 background-color: #ccc;
1494                 border: 1px solid #aaa;
1495             }
1496             p, h1, h2 {
1497                 margin-left: 20px;
1498                 margin-right: 20px;
1499                 font-family: verdana, tahoma, sans-serif;
1500             }
1501             a {
1502                 font-family: verdana, tahoma, sans-serif;
1503             }
1504             :link, :visited {
1505                     text-decoration: none;
1506                     color: #b00;
1507                     border-bottom: 1px dotted #bbb;
1508             }
1509             :link:hover, :visited:hover {
1510                     color: #555;
1511             }
1512             div#topbar {
1513                 margin: 0px;
1514             }
1515             pre {
1516                 margin: 10px;
1517                 padding: 8px;
1518             }
1519             div#answers {
1520                 padding: 8px;
1521                 margin: 10px;
1522                 background-color: #fff;
1523                 border: 1px solid #aaa;
1524             }
1525             h1 {
1526                 font-size: 0.9em;
1527                 font-weight: normal;
1528                 text-align: center;
1529             }
1530             h2 {
1531                 font-size: 1.0em;
1532             }
1533             p {
1534                 font-size: 0.9em;
1535             }
1536             p img {
1537                 float: right;
1538                 margin-left: 10px;
1539             }
1540             span#appname {
1541                 font-weight: bold;
1542                 font-size: 1.6em;
1543             }
1544         </style>
1545     </head>
1546     <body>
1547         <div id="content">
1548             <div id="topbar">
1549                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1550                     $VERSION</h1>
1551              </div>
1552              <div id="answers">
1553                  <p>
1554                  <img src="$logo" alt="Catalyst Logo" />
1555                  </p>
1556                  <p>Welcome to the  world of Catalyst.
1557                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1558                     framework will make web development something you had
1559                     never expected it to be: Fun, rewarding, and quick.</p>
1560                  <h2>What to do now?</h2>
1561                  <p>That really depends  on what <b>you</b> want to do.
1562                     We do, however, provide you with a few starting points.</p>
1563                  <p>If you want to jump right into web development with Catalyst
1564                     you might want to start with a tutorial.</p>
1565 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1566 </pre>
1567 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1568 <pre>
1569 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1570 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1571 </code></pre>
1572                  <h2>What to do next?</h2>
1573                  <p>Next it's time to write an actual application. Use the
1574                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1575                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1576                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1577                     they can save you a lot of work.</p>
1578                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1579                     <p>Also, be sure to check out the vast and growing
1580                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1581                     you are likely to find what you need there.
1582                     </p>
1583
1584                  <h2>Need help?</h2>
1585                  <p>Catalyst has a very active community. Here are the main places to
1586                     get in touch with us.</p>
1587                  <ul>
1588                      <li>
1589                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1590                      </li>
1591                      <li>
1592                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1593                      </li>
1594                      <li>
1595                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1596                      </li>
1597                  </ul>
1598                  <h2>In conclusion</h2>
1599                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1600                     as we enjoyed making it. Please contact us if you have ideas
1601                     for improvement or other feedback.</p>
1602              </div>
1603          </div>
1604     </body>
1605 </html>
1606 EOF
1607 }
1608
1609 =head2 run_options
1610
1611 Contains a hash of options passed from the application script, including
1612 the original ARGV the script received, the processed values from that
1613 ARGV and any extra arguments to the script which were not processed.
1614
1615 This can be used to add custom options to your application's scripts
1616 and setup your application differently depending on the values of these
1617 options.
1618
1619 =head1 INTERNAL METHODS
1620
1621 These methods are not meant to be used by end users.
1622
1623 =head2 $c->components
1624
1625 Returns a hash of components.
1626
1627 =head2 $c->context_class
1628
1629 Returns or sets the context class.
1630
1631 =head2 $c->counter
1632
1633 Returns a hashref containing coderefs and execution counts (needed for
1634 deep recursion detection).
1635
1636 =head2 $c->depth
1637
1638 Returns the number of actions on the current internal execution stack.
1639
1640 =head2 $c->dispatch
1641
1642 Dispatches a request to actions.
1643
1644 =cut
1645
1646 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1647
1648 =head2 $c->dispatcher_class
1649
1650 Returns or sets the dispatcher class.
1651
1652 =head2 $c->dump_these
1653
1654 Returns a list of 2-element array references (name, structure) pairs
1655 that will be dumped on the error page in debug mode.
1656
1657 =cut
1658
1659 sub dump_these {
1660     my $c = shift;
1661     [ Request => $c->req ],
1662     [ Response => $c->res ],
1663     [ Stash => $c->stash ],
1664     [ Config => $c->config ];
1665 }
1666
1667 =head2 $c->engine_class
1668
1669 Returns or sets the engine class.
1670
1671 =head2 $c->execute( $class, $coderef )
1672
1673 Execute a coderef in given class and catch exceptions. Errors are available
1674 via $c->error.
1675
1676 =cut
1677
1678 sub execute {
1679     my ( $c, $class, $code ) = @_;
1680     $class = $c->component($class) || $class;
1681     $c->state(0);
1682
1683     if ( $c->depth >= $RECURSION ) {
1684         my $action = $code->reverse();
1685         $action = "/$action" unless $action =~ /->/;
1686         my $error = qq/Deep recursion detected calling "${action}"/;
1687         $c->log->error($error);
1688         $c->error($error);
1689         $c->state(0);
1690         return $c->state;
1691     }
1692
1693     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1694
1695     push( @{ $c->stack }, $code );
1696
1697     no warnings 'recursion';
1698     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1699     #      I have no idea how, ergo $ret (which appears to fix the issue)
1700     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1701
1702     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1703
1704     my $last = pop( @{ $c->stack } );
1705
1706     if ( my $error = $@ ) {
1707         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1708             $error->rethrow if $c->depth > 1;
1709         }
1710         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1711             $error->rethrow if $c->depth > 0;
1712         }
1713         else {
1714             unless ( ref $error ) {
1715                 no warnings 'uninitialized';
1716                 chomp $error;
1717                 my $class = $last->class;
1718                 my $name  = $last->name;
1719                 $error = qq/Caught exception in $class->$name "$error"/;
1720             }
1721             $c->error($error);
1722         }
1723         $c->state(0);
1724     }
1725     return $c->state;
1726 }
1727
1728 sub _stats_start_execute {
1729     my ( $c, $code ) = @_;
1730     my $appclass = ref($c) || $c;
1731     return if ( ( $code->name =~ /^_.*/ )
1732         && ( !$appclass->config->{show_internal_actions} ) );
1733
1734     my $action_name = $code->reverse();
1735     $c->counter->{$action_name}++;
1736
1737     my $action = $action_name;
1738     $action = "/$action" unless $action =~ /->/;
1739
1740     # determine if the call was the result of a forward
1741     # this is done by walking up the call stack and looking for a calling
1742     # sub of Catalyst::forward before the eval
1743     my $callsub = q{};
1744     for my $index ( 2 .. 11 ) {
1745         last
1746         if ( ( caller($index) )[0] eq 'Catalyst'
1747             && ( caller($index) )[3] eq '(eval)' );
1748
1749         if ( ( caller($index) )[3] =~ /forward$/ ) {
1750             $callsub = ( caller($index) )[3];
1751             $action  = "-> $action";
1752             last;
1753         }
1754     }
1755
1756     my $uid = $action_name . $c->counter->{$action_name};
1757
1758     # is this a root-level call or a forwarded call?
1759     if ( $callsub =~ /forward$/ ) {
1760         my $parent = $c->stack->[-1];
1761
1762         # forward, locate the caller
1763         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1764             $c->stats->profile(
1765                 begin  => $action,
1766                 parent => "$parent" . $c->counter->{"$parent"},
1767                 uid    => $uid,
1768             );
1769         }
1770         else {
1771
1772             # forward with no caller may come from a plugin
1773             $c->stats->profile(
1774                 begin => $action,
1775                 uid   => $uid,
1776             );
1777         }
1778     }
1779     else {
1780
1781         # root-level call
1782         $c->stats->profile(
1783             begin => $action,
1784             uid   => $uid,
1785         );
1786     }
1787     return $action;
1788
1789 }
1790
1791 sub _stats_finish_execute {
1792     my ( $c, $info ) = @_;
1793     $c->stats->profile( end => $info );
1794 }
1795
1796 =head2 $c->finalize
1797
1798 Finalizes the request.
1799
1800 =cut
1801
1802 sub finalize {
1803     my $c = shift;
1804
1805     for my $error ( @{ $c->error } ) {
1806         $c->log->error($error);
1807     }
1808
1809     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1810     # stuff like cometd and websockets
1811
1812     if($c->request->has_io_fh) {
1813       $c->log_response;
1814       return;
1815     }
1816
1817     # Allow engine to handle finalize flow (for POE)
1818     my $engine = $c->engine;
1819     if ( my $code = $engine->can('finalize') ) {
1820         $engine->$code($c);
1821     }
1822     else {
1823
1824         $c->finalize_uploads;
1825
1826         # Error
1827         if ( $#{ $c->error } >= 0 ) {
1828             $c->finalize_error;
1829         }
1830
1831         $c->finalize_headers unless $c->response->finalized_headers;
1832
1833         # HEAD request
1834         if ( $c->request->method eq 'HEAD' ) {
1835             $c->response->body('');
1836         }
1837
1838         $c->finalize_body;
1839     }
1840
1841     $c->log_response;
1842
1843     if ($c->use_stats) {
1844         my $elapsed = $c->stats->elapsed;
1845         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1846         $c->log->info(
1847             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1848     }
1849
1850     return $c->response->status;
1851 }
1852
1853 =head2 $c->finalize_body
1854
1855 Finalizes body.
1856
1857 =cut
1858
1859 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1860
1861 =head2 $c->finalize_cookies
1862
1863 Finalizes cookies.
1864
1865 =cut
1866
1867 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1868
1869 =head2 $c->finalize_error
1870
1871 Finalizes error.
1872
1873 =cut
1874
1875 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1876
1877 =head2 $c->finalize_headers
1878
1879 Finalizes headers.
1880
1881 =cut
1882
1883 sub finalize_headers {
1884     my $c = shift;
1885
1886     my $response = $c->response; #accessor calls can add up?
1887
1888     # Check if we already finalized headers
1889     return if $response->finalized_headers;
1890
1891     # Handle redirects
1892     if ( my $location = $response->redirect ) {
1893         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1894         $response->header( Location => $location );
1895
1896         if ( !$response->has_body ) {
1897             # Add a default body if none is already present
1898             my $encoded_location = encode_entities($location);
1899             $response->body(<<"EOF");
1900 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1901 <html xmlns="http://www.w3.org/1999/xhtml">
1902   <head>
1903     <title>Moved</title>
1904   </head>
1905   <body>
1906      <p>This item has moved <a href="$encoded_location">here</a>.</p>
1907   </body>
1908 </html>
1909 EOF
1910             $response->content_type('text/html; charset=utf-8');
1911         }
1912     }
1913
1914     # Content-Length
1915     if ( defined $response->body && length $response->body && !$response->content_length ) {
1916
1917         # get the length from a filehandle
1918         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1919         {
1920             my $size = -s $response->body;
1921             if ( $size ) {
1922                 $response->content_length( $size );
1923             }
1924             else {
1925                 $c->log->warn('Serving filehandle without a content-length');
1926             }
1927         }
1928         else {
1929             # everything should be bytes at this point, but just in case
1930             $response->content_length( length( $response->body ) );
1931         }
1932     }
1933
1934     # Errors
1935     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1936         $response->headers->remove_header("Content-Length");
1937         $response->body('');
1938     }
1939
1940     $c->finalize_cookies;
1941
1942     $c->response->finalize_headers();
1943
1944     # Done
1945     $response->finalized_headers(1);
1946 }
1947
1948 =head2 $c->finalize_output
1949
1950 An alias for finalize_body.
1951
1952 =head2 $c->finalize_read
1953
1954 Finalizes the input after reading is complete.
1955
1956 =cut
1957
1958 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1959
1960 =head2 $c->finalize_uploads
1961
1962 Finalizes uploads. Cleans up any temporary files.
1963
1964 =cut
1965
1966 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1967
1968 =head2 $c->get_action( $action, $namespace )
1969
1970 Gets an action in a given namespace.
1971
1972 =cut
1973
1974 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1975
1976 =head2 $c->get_actions( $action, $namespace )
1977
1978 Gets all actions of a given name in a namespace and all parent
1979 namespaces.
1980
1981 =cut
1982
1983 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1984
1985 =head2 $app->handle_request( @arguments )
1986
1987 Called to handle each HTTP request.
1988
1989 =cut
1990
1991 sub handle_request {
1992     my ( $class, @arguments ) = @_;
1993
1994     # Always expect worst case!
1995     my $status = -1;
1996     try {
1997         if ($class->debug) {
1998             my $secs = time - $START || 1;
1999             my $av = sprintf '%.3f', $COUNT / $secs;
2000             my $time = localtime time;
2001             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2002         }
2003
2004         my $c = $class->prepare(@arguments);
2005         $c->dispatch;
2006         $status = $c->finalize;
2007     }
2008     catch {
2009         chomp(my $error = $_);
2010         $class->log->error(qq/Caught exception in engine "$error"/);
2011     };
2012
2013     $COUNT++;
2014
2015     if(my $coderef = $class->log->can('_flush')){
2016         $class->log->$coderef();
2017     }
2018     return $status;
2019 }
2020
2021 =head2 $class->prepare( @arguments )
2022
2023 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2024 etc.).
2025
2026 =cut
2027
2028 has _uploadtmp => (
2029     is => 'ro',
2030     predicate => '_has_uploadtmp',
2031 );
2032
2033 sub prepare {
2034     my ( $class, @arguments ) = @_;
2035
2036     # XXX
2037     # After the app/ctxt split, this should become an attribute based on something passed
2038     # into the application.
2039     $class->context_class( ref $class || $class ) unless $class->context_class;
2040
2041     my $uploadtmp = $class->config->{uploadtmp};
2042     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2043
2044     $c->response->_context($c);
2045
2046     #surely this is not the most efficient way to do things...
2047     $c->stats($class->stats_class->new)->enable($c->use_stats);
2048     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2049         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2050     }
2051
2052     try {
2053         # Allow engine to direct the prepare flow (for POE)
2054         if ( my $prepare = $c->engine->can('prepare') ) {
2055             $c->engine->$prepare( $c, @arguments );
2056         }
2057         else {
2058             $c->prepare_request(@arguments);
2059             $c->prepare_connection;
2060             $c->prepare_query_parameters;
2061             $c->prepare_headers; # Just hooks, no longer needed - they just
2062             $c->prepare_cookies; # cause the lazy attribute on req to build
2063             $c->prepare_path;
2064
2065             # Prepare the body for reading, either by prepare_body
2066             # or the user, if they are using $c->read
2067             $c->prepare_read;
2068
2069             # Parse the body unless the user wants it on-demand
2070             unless ( ref($c)->config->{parse_on_demand} ) {
2071                 $c->prepare_body;
2072             }
2073         }
2074         $c->prepare_action;
2075     }
2076     # VERY ugly and probably shouldn't rely on ->finalize actually working
2077     catch {
2078         # failed prepare is always due to an invalid request, right?
2079         $c->response->status(400);
2080         $c->response->content_type('text/plain');
2081         $c->response->body('Bad Request');
2082         # Note we call finalize and then die here, which escapes
2083         # finalize being called in the enclosing block..
2084         # It in fact couldn't be called, as we don't return $c..
2085         # This is a mess - but I'm unsure you can fix this without
2086         # breaking compat for people doing crazy things (we should set
2087         # the 400 and just return the ctx here IMO, letting finalize get called
2088         # above...
2089         $c->finalize;
2090         die $_;
2091     };
2092
2093     $c->log_request;
2094
2095     return $c;
2096 }
2097
2098 =head2 $c->prepare_action
2099
2100 Prepares action. See L<Catalyst::Dispatcher>.
2101
2102 =cut
2103
2104 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2105
2106 =head2 $c->prepare_body
2107
2108 Prepares message body.
2109
2110 =cut
2111
2112 sub prepare_body {
2113     my $c = shift;
2114
2115     return if $c->request->_has_body;
2116
2117     # Initialize on-demand data
2118     $c->engine->prepare_body( $c, @_ );
2119     $c->prepare_parameters;
2120     $c->prepare_uploads;
2121 }
2122
2123 =head2 $c->prepare_body_chunk( $chunk )
2124
2125 Prepares a chunk of data before sending it to L<HTTP::Body>.
2126
2127 See L<Catalyst::Engine>.
2128
2129 =cut
2130
2131 sub prepare_body_chunk {
2132     my $c = shift;
2133     $c->engine->prepare_body_chunk( $c, @_ );
2134 }
2135
2136 =head2 $c->prepare_body_parameters
2137
2138 Prepares body parameters.
2139
2140 =cut
2141
2142 sub prepare_body_parameters {
2143     my $c = shift;
2144     $c->engine->prepare_body_parameters( $c, @_ );
2145 }
2146
2147 =head2 $c->prepare_connection
2148
2149 Prepares connection.
2150
2151 =cut
2152
2153 sub prepare_connection {
2154     my $c = shift;
2155     # XXX - This is called on the engine (not the request) to maintain
2156     #       Engine::PSGI back compat.
2157     $c->engine->prepare_connection($c);
2158 }
2159
2160 =head2 $c->prepare_cookies
2161
2162 Prepares cookies by ensuring that the attribute on the request
2163 object has been built.
2164
2165 =cut
2166
2167 sub prepare_cookies { my $c = shift; $c->request->cookies }
2168
2169 =head2 $c->prepare_headers
2170
2171 Prepares request headers by ensuring that the attribute on the request
2172 object has been built.
2173
2174 =cut
2175
2176 sub prepare_headers { my $c = shift; $c->request->headers }
2177
2178 =head2 $c->prepare_parameters
2179
2180 Prepares parameters.
2181
2182 =cut
2183
2184 sub prepare_parameters {
2185     my $c = shift;
2186     $c->prepare_body_parameters;
2187     $c->engine->prepare_parameters( $c, @_ );
2188 }
2189
2190 =head2 $c->prepare_path
2191
2192 Prepares path and base.
2193
2194 =cut
2195
2196 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2197
2198 =head2 $c->prepare_query_parameters
2199
2200 Prepares query parameters.
2201
2202 =cut
2203
2204 sub prepare_query_parameters {
2205     my $c = shift;
2206
2207     $c->engine->prepare_query_parameters( $c, @_ );
2208 }
2209
2210 =head2 $c->log_request
2211
2212 Writes information about the request to the debug logs.  This includes:
2213
2214 =over 4
2215
2216 =item * Request method, path, and remote IP address
2217
2218 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2219
2220 =item * Request parameters
2221
2222 =item * File uploads
2223
2224 =back
2225
2226 =cut
2227
2228 sub log_request {
2229     my $c = shift;
2230
2231     return unless $c->debug;
2232
2233     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2234     my $request = $dump->[1];
2235
2236     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2237     $method ||= '';
2238     $path = '/' unless length $path;
2239     $address ||= '';
2240     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2241
2242     $c->log_request_headers($request->headers);
2243
2244     if ( my $keywords = $request->query_keywords ) {
2245         $c->log->debug("Query keywords are: $keywords");
2246     }
2247
2248     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2249
2250     $c->log_request_uploads($request);
2251 }
2252
2253 =head2 $c->log_response
2254
2255 Writes information about the response to the debug logs by calling
2256 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2257
2258 =cut
2259
2260 sub log_response {
2261     my $c = shift;
2262
2263     return unless $c->debug;
2264
2265     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2266     my $response = $dump->[1];
2267
2268     $c->log_response_status_line($response);
2269     $c->log_response_headers($response->headers);
2270 }
2271
2272 =head2 $c->log_response_status_line($response)
2273
2274 Writes one line of information about the response to the debug logs.  This includes:
2275
2276 =over 4
2277
2278 =item * Response status code
2279
2280 =item * Content-Type header (if present)
2281
2282 =item * Content-Length header (if present)
2283
2284 =back
2285
2286 =cut
2287
2288 sub log_response_status_line {
2289     my ($c, $response) = @_;
2290
2291     $c->log->debug(
2292         sprintf(
2293             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2294             $response->status                            || 'unknown',
2295             $response->headers->header('Content-Type')   || 'unknown',
2296             $response->headers->header('Content-Length') || 'unknown'
2297         )
2298     );
2299 }
2300
2301 =head2 $c->log_response_headers($headers);
2302
2303 Hook method which can be wrapped by plugins to log the response headers.
2304 No-op in the default implementation.
2305
2306 =cut
2307
2308 sub log_response_headers {}
2309
2310 =head2 $c->log_request_parameters( query => {}, body => {} )
2311
2312 Logs request parameters to debug logs
2313
2314 =cut
2315
2316 sub log_request_parameters {
2317     my $c          = shift;
2318     my %all_params = @_;
2319
2320     return unless $c->debug;
2321
2322     my $column_width = Catalyst::Utils::term_width() - 44;
2323     foreach my $type (qw(query body)) {
2324         my $params = $all_params{$type};
2325         next if ! keys %$params;
2326         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2327         for my $key ( sort keys %$params ) {
2328             my $param = $params->{$key};
2329             my $value = defined($param) ? $param : '';
2330             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2331         }
2332         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2333     }
2334 }
2335
2336 =head2 $c->log_request_uploads
2337
2338 Logs file uploads included in the request to the debug logs.
2339 The parameter name, filename, file type, and file size are all included in
2340 the debug logs.
2341
2342 =cut
2343
2344 sub log_request_uploads {
2345     my $c = shift;
2346     my $request = shift;
2347     return unless $c->debug;
2348     my $uploads = $request->uploads;
2349     if ( keys %$uploads ) {
2350         my $t = Text::SimpleTable->new(
2351             [ 12, 'Parameter' ],
2352             [ 26, 'Filename' ],
2353             [ 18, 'Type' ],
2354             [ 9,  'Size' ]
2355         );
2356         for my $key ( sort keys %$uploads ) {
2357             my $upload = $uploads->{$key};
2358             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2359                 $t->row( $key, $u->filename, $u->type, $u->size );
2360             }
2361         }
2362         $c->log->debug( "File Uploads are:\n" . $t->draw );
2363     }
2364 }
2365
2366 =head2 $c->log_request_headers($headers);
2367
2368 Hook method which can be wrapped by plugins to log the request headers.
2369 No-op in the default implementation.
2370
2371 =cut
2372
2373 sub log_request_headers {}
2374
2375 =head2 $c->log_headers($type => $headers)
2376
2377 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2378
2379 =cut
2380
2381 sub log_headers {
2382     my $c       = shift;
2383     my $type    = shift;
2384     my $headers = shift;    # an HTTP::Headers instance
2385
2386     return unless $c->debug;
2387
2388     my $column_width = Catalyst::Utils::term_width() - 28;
2389     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2390     $headers->scan(
2391         sub {
2392             my ( $name, $value ) = @_;
2393             $t->row( $name, $value );
2394         }
2395     );
2396     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2397 }
2398
2399
2400 =head2 $c->prepare_read
2401
2402 Prepares the input for reading.
2403
2404 =cut
2405
2406 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2407
2408 =head2 $c->prepare_request
2409
2410 Prepares the engine request.
2411
2412 =cut
2413
2414 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2415
2416 =head2 $c->prepare_uploads
2417
2418 Prepares uploads.
2419
2420 =cut
2421
2422 sub prepare_uploads {
2423     my $c = shift;
2424
2425     $c->engine->prepare_uploads( $c, @_ );
2426 }
2427
2428 =head2 $c->prepare_write
2429
2430 Prepares the output for writing.
2431
2432 =cut
2433
2434 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2435
2436 =head2 $c->request_class
2437
2438 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2439
2440 =head2 $c->response_class
2441
2442 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2443
2444 =head2 $c->read( [$maxlength] )
2445
2446 Reads a chunk of data from the request body. This method is designed to
2447 be used in a while loop, reading C<$maxlength> bytes on every call.
2448 C<$maxlength> defaults to the size of the request if not specified.
2449
2450 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2451 directly.
2452
2453 Warning: If you use read(), Catalyst will not process the body,
2454 so you will not be able to access POST parameters or file uploads via
2455 $c->request.  You must handle all body parsing yourself.
2456
2457 =cut
2458
2459 sub read { my $c = shift; return $c->request->read( @_ ) }
2460
2461 =head2 $c->run
2462
2463 Starts the engine.
2464
2465 =cut
2466
2467 sub run {
2468   my $app = shift;
2469   $app->_make_immutable_if_needed;
2470   $app->engine_loader->needs_psgi_engine_compat_hack ?
2471     $app->engine->run($app, @_) :
2472       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2473 }
2474
2475 sub _make_immutable_if_needed {
2476     my $class = shift;
2477     my $meta = find_meta($class);
2478     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2479     if (
2480         $meta->is_immutable
2481         && ! { $meta->immutable_options }->{replace_constructor}
2482         && $isa_ca
2483     ) {
2484         warn("You made your application class ($class) immutable, "
2485             . "but did not inline the\nconstructor. "
2486             . "This will break catalyst, as your app \@ISA "
2487             . "Class::Accessor(::Fast)?\nPlease pass "
2488             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2489     }
2490     unless ($meta->is_immutable) {
2491         # XXX - FIXME warning here as you should make your app immutable yourself.
2492         $meta->make_immutable(
2493             replace_constructor => 1,
2494         );
2495     }
2496 }
2497
2498 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2499
2500 Sets an action in a given namespace.
2501
2502 =cut
2503
2504 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2505
2506 =head2 $c->setup_actions($component)
2507
2508 Sets up actions for a component.
2509
2510 =cut
2511
2512 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2513
2514 =head2 $c->setup_components
2515
2516 This method is called internally to set up the application's components.
2517
2518 It finds modules by calling the L<locate_components> method, expands them to
2519 package names with the L<expand_component_module> method, and then installs
2520 each component into the application.
2521
2522 The C<setup_components> config option is passed to both of the above methods.
2523
2524 Installation of each component is performed by the L<setup_component> method,
2525 below.
2526
2527 =cut
2528
2529 sub setup_components {
2530     my $class = shift;
2531
2532     my $config  = $class->config->{ setup_components };
2533
2534     my @comps = $class->locate_components($config);
2535     my %comps = map { $_ => 1 } @comps;
2536
2537     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2538     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2539         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2540     ) if $deprecatedcatalyst_component_names;
2541
2542     for my $component ( @comps ) {
2543
2544         # We pass ignore_loaded here so that overlay files for (e.g.)
2545         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2546         # we know M::P::O found a file on disk so this is safe
2547
2548         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2549     }
2550
2551     for my $component (@comps) {
2552         my $instance = $class->components->{ $component } = $class->setup_component($component);
2553         my @expanded_components = $instance->can('expand_modules')
2554             ? $instance->expand_modules( $component, $config )
2555             : $class->expand_component_module( $component, $config );
2556         for my $component (@expanded_components) {
2557             next if $comps{$component};
2558             $class->components->{ $component } = $class->setup_component($component);
2559         }
2560     }
2561 }
2562
2563 =head2 $c->locate_components( $setup_component_config )
2564
2565 This method is meant to provide a list of component modules that should be
2566 setup for the application.  By default, it will use L<Module::Pluggable>.
2567
2568 Specify a C<setup_components> config option to pass additional options directly
2569 to L<Module::Pluggable>. To add additional search paths, specify a key named
2570 C<search_extra> as an array reference. Items in the array beginning with C<::>
2571 will have the application class name prepended to them.
2572
2573 =cut
2574
2575 sub locate_components {
2576     my $class  = shift;
2577     my $config = shift;
2578
2579     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2580     my $extra   = delete $config->{ search_extra } || [];
2581
2582     push @paths, @$extra;
2583
2584     my $locator = Module::Pluggable::Object->new(
2585         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2586         %$config
2587     );
2588
2589     # XXX think about ditching this sort entirely
2590     my @comps = sort { length $a <=> length $b } $locator->plugins;
2591
2592     return @comps;
2593 }
2594
2595 =head2 $c->expand_component_module( $component, $setup_component_config )
2596
2597 Components found by C<locate_components> will be passed to this method, which
2598 is expected to return a list of component (package) names to be set up.
2599
2600 =cut
2601
2602 sub expand_component_module {
2603     my ($class, $module) = @_;
2604     return Devel::InnerPackage::list_packages( $module );
2605 }
2606
2607 =head2 $c->setup_component
2608
2609 =cut
2610
2611 sub setup_component {
2612     my( $class, $component ) = @_;
2613
2614     unless ( $component->can( 'COMPONENT' ) ) {
2615         return $component;
2616     }
2617
2618     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2619     my $config = $class->config->{ $suffix } || {};
2620     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2621     # methods also pass it. local to avoid pointlessly shitting in config
2622     # for the debug screen, as $component is already the key name.
2623     local $config->{catalyst_component_name} = $component;
2624
2625     my $instance = eval { $component->COMPONENT( $class, $config ); };
2626
2627     if ( my $error = $@ ) {
2628         chomp $error;
2629         Catalyst::Exception->throw(
2630             message => qq/Couldn't instantiate component "$component", "$error"/
2631         );
2632     }
2633
2634     unless (blessed $instance) {
2635         my $metaclass = Moose::Util::find_meta($component);
2636         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2637         my $component_method_from = $method_meta->associated_metaclass->name;
2638         my $value = defined($instance) ? $instance : 'undef';
2639         Catalyst::Exception->throw(
2640             message =>
2641             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2642         );
2643     }
2644     return $instance;
2645 }
2646
2647 =head2 $c->setup_dispatcher
2648
2649 Sets up dispatcher.
2650
2651 =cut
2652
2653 sub setup_dispatcher {
2654     my ( $class, $dispatcher ) = @_;
2655
2656     if ($dispatcher) {
2657         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2658     }
2659
2660     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2661         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2662     }
2663
2664     unless ($dispatcher) {
2665         $dispatcher = $class->dispatcher_class;
2666     }
2667
2668     load_class($dispatcher);
2669
2670     # dispatcher instance
2671     $class->dispatcher( $dispatcher->new );
2672 }
2673
2674 =head2 $c->setup_engine
2675
2676 Sets up engine.
2677
2678 =cut
2679
2680 sub engine_class {
2681     my ($class, $requested_engine) = @_;
2682
2683     if (!$class->engine_loader || $requested_engine) {
2684         $class->engine_loader(
2685             Catalyst::EngineLoader->new({
2686                 application_name => $class,
2687                 (defined $requested_engine
2688                      ? (catalyst_engine_class => $requested_engine) : ()),
2689             }),
2690         );
2691     }
2692
2693     $class->engine_loader->catalyst_engine_class;
2694 }
2695
2696 sub setup_engine {
2697     my ($class, $requested_engine) = @_;
2698
2699     my $engine = do {
2700         my $loader = $class->engine_loader;
2701
2702         if (!$loader || $requested_engine) {
2703             $loader = Catalyst::EngineLoader->new({
2704                 application_name => $class,
2705                 (defined $requested_engine
2706                      ? (requested_engine => $requested_engine) : ()),
2707             }),
2708
2709             $class->engine_loader($loader);
2710         }
2711
2712         $loader->catalyst_engine_class;
2713     };
2714
2715     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2716     return if $class->loading_psgi_file;
2717
2718     load_class($engine);
2719
2720     if ($ENV{MOD_PERL}) {
2721         my $apache = $class->engine_loader->auto;
2722
2723         my $meta = find_meta($class);
2724         my $was_immutable = $meta->is_immutable;
2725         my %immutable_options = $meta->immutable_options;
2726         $meta->make_mutable if $was_immutable;
2727
2728         $meta->add_method(handler => sub {
2729             my $r = shift;
2730             my $psgi_app = $class->_finalized_psgi_app;
2731             $apache->call_app($r, $psgi_app);
2732         });
2733
2734         $meta->make_immutable(%immutable_options) if $was_immutable;
2735     }
2736
2737     $class->engine( $engine->new );
2738
2739     return;
2740 }
2741
2742 sub _finalized_psgi_app {
2743     my ($app) = @_;
2744
2745     unless ($app->_psgi_app) {
2746         my $psgi_app = $app->_setup_psgi_app;
2747         $app->_psgi_app($psgi_app);
2748     }
2749
2750     return $app->_psgi_app;
2751 }
2752
2753 sub _setup_psgi_app {
2754     my ($app) = @_;
2755
2756     for my $home (Path::Class::Dir->new($app->config->{home})) {
2757         my $psgi_file = $home->file(
2758             Catalyst::Utils::appprefix($app) . '.psgi',
2759         );
2760
2761         next unless -e $psgi_file;
2762
2763         # If $psgi_file calls ->setup_engine, it's doing so to load
2764         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2765         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2766         # anyway. So set a flag (ick) that tells setup_engine not to populate
2767         # $c->engine or do any other things we might regret.
2768
2769         $app->loading_psgi_file(1);
2770         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2771         $app->loading_psgi_file(0);
2772
2773         return $psgi_app
2774             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2775
2776         warn <<"EOW";
2777 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2778
2779 Its content has been ignored. Please consult the Catalyst::Upgrading
2780 documentation on how to upgrade from Catalyst::Engine::PSGI.
2781 EOW
2782     }
2783
2784     return $app->apply_default_middlewares($app->psgi_app);
2785 }
2786
2787 =head2 $c->apply_default_middlewares
2788
2789 Adds the following L<Plack> middlewares to your application, since they are
2790 useful and commonly needed:
2791
2792 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2793 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2794 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2795 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2796 applied since this middleware is smart enough to conditionally apply itself).
2797
2798 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2799 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2800 $ENV{SCRIPT_NAME}
2801
2802 =cut
2803
2804
2805 sub apply_default_middlewares {
2806     my ($app, $psgi_app) = @_;
2807
2808     $psgi_app = Plack::Middleware::Conditional->wrap(
2809         $psgi_app,
2810         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2811         condition => sub {
2812             my ($env) = @_;
2813             return if $app->config->{ignore_frontend_proxy};
2814             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2815                 || $app->config->{using_frontend_proxy};
2816         },
2817     );
2818
2819     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2820     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2821     $psgi_app = Plack::Middleware::Conditional->wrap(
2822         $psgi_app,
2823         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2824         condition => sub {
2825             my ($env) = @_;
2826             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2827             return unless $1 < 4.23;
2828             1;
2829         },
2830     );
2831
2832     # we're applying this unconditionally as the middleware itself already makes
2833     # sure it doesn't fuck things up if it's not running under one of the right
2834     # IIS versions
2835     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2836
2837     # And another IIS issue, this time with IIS7.
2838     $psgi_app = Plack::Middleware::Conditional->wrap(
2839         $psgi_app,
2840         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2841         condition => sub {
2842             my ($env) = @_;
2843             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2844         },
2845     );
2846
2847     return $psgi_app;
2848 }
2849
2850 =head2 $c->psgi_app
2851
2852 Returns a PSGI application code reference for the catalyst application
2853 C<$c>. This is the bare application without any middlewares
2854 applied. C<${myapp}.psgi> is not taken into account.
2855
2856 This is what you want to be using to retrieve the PSGI application code
2857 reference of your Catalyst application for use in F<.psgi> files.
2858
2859 =cut
2860
2861 sub psgi_app {
2862     my ($app) = @_;
2863     return $app->engine->build_psgi_app($app);
2864 }
2865
2866 =head2 $c->setup_home
2867
2868 Sets up the home directory.
2869
2870 =cut
2871
2872 sub setup_home {
2873     my ( $class, $home ) = @_;
2874
2875     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2876         $home = $env;
2877     }
2878
2879     $home ||= Catalyst::Utils::home($class);
2880
2881     if ($home) {
2882         #I remember recently being scolded for assigning config values like this
2883         $class->config->{home} ||= $home;
2884         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2885     }
2886 }
2887
2888 =head2 $c->setup_log
2889
2890 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2891 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2892 log to.
2893
2894 This method also installs a C<debug> method that returns a true value into the
2895 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2896 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2897
2898 Note that if the log has already been setup, by either a previous call to
2899 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2900 that this method won't actually set up the log object.
2901
2902 =cut
2903
2904 sub setup_log {
2905     my ( $class, $levels ) = @_;
2906
2907     $levels ||= '';
2908     $levels =~ s/^\s+//;
2909     $levels =~ s/\s+$//;
2910     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2911
2912     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2913     if ( defined $env_debug ) {
2914         $levels{debug} = 1 if $env_debug; # Ugly!
2915         delete($levels{debug}) unless $env_debug;
2916     }
2917
2918     unless ( $class->log ) {
2919         $class->log( Catalyst::Log->new(keys %levels) );
2920     }
2921
2922     if ( $levels{debug} ) {
2923         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2924         $class->log->debug('Debug messages enabled');
2925     }
2926 }
2927
2928 =head2 $c->setup_plugins
2929
2930 Sets up plugins.
2931
2932 =cut
2933
2934 =head2 $c->setup_stats
2935
2936 Sets up timing statistics class.
2937
2938 =cut
2939
2940 sub setup_stats {
2941     my ( $class, $stats ) = @_;
2942
2943     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2944
2945     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2946     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2947         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2948         $class->log->debug('Statistics enabled');
2949     }
2950 }
2951
2952
2953 =head2 $c->registered_plugins
2954
2955 Returns a sorted list of the plugins which have either been stated in the
2956 import list.
2957
2958 If passed a given plugin name, it will report a boolean value indicating
2959 whether or not that plugin is loaded.  A fully qualified name is required if
2960 the plugin name does not begin with C<Catalyst::Plugin::>.
2961
2962  if ($c->registered_plugins('Some::Plugin')) {
2963      ...
2964  }
2965
2966 =cut
2967
2968 {
2969
2970     sub registered_plugins {
2971         my $proto = shift;
2972         return sort keys %{ $proto->_plugins } unless @_;
2973         my $plugin = shift;
2974         return 1 if exists $proto->_plugins->{$plugin};
2975         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2976     }
2977
2978     sub _register_plugin {
2979         my ( $proto, $plugin, $instant ) = @_;
2980         my $class = ref $proto || $proto;
2981
2982         load_class( $plugin );
2983         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2984             if $plugin->isa( 'Catalyst::Component' );
2985         my $plugin_meta = Moose::Meta::Class->create($plugin);
2986         if (!$plugin_meta->has_method('new')
2987             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
2988             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
2989         }
2990         if (!$instant && !$proto->_plugins->{$plugin}) {
2991             my $meta = Class::MOP::get_metaclass_by_name($class);
2992             $meta->superclasses($plugin, $meta->superclasses);
2993         }
2994         $proto->_plugins->{$plugin} = 1;
2995         return $class;
2996     }
2997
2998     sub _default_plugins { return qw(Unicode::Encoding) }
2999
3000     sub setup_plugins {
3001         my ( $class, $plugins ) = @_;
3002
3003         $class->_plugins( {} ) unless $class->_plugins;
3004         $plugins = [ grep {
3005             m/Unicode::Encoding/ ? do {
3006                 $class->log->warn(
3007                     'Unicode::Encoding plugin is auto-applied,'
3008                     . ' please remove this from your appclass'
3009                     . ' and make sure to define "encoding" config'
3010                 );
3011                 unless (exists $class->config->{'encoding'}) {
3012                   $class->config->{'encoding'} = 'UTF-8';
3013                 }
3014                 () }
3015                 : $_
3016         } @$plugins ];
3017         push @$plugins, $class->_default_plugins;
3018         $plugins = Data::OptList::mkopt($plugins || []);
3019
3020         my @plugins = map {
3021             [ Catalyst::Utils::resolve_namespace(
3022                   $class . '::Plugin',
3023                   'Catalyst::Plugin', $_->[0]
3024               ),
3025               $_->[1],
3026             ]
3027          } @{ $plugins };
3028
3029         for my $plugin ( reverse @plugins ) {
3030             load_class($plugin->[0], $plugin->[1]);
3031             my $meta = find_meta($plugin->[0]);
3032             next if $meta && $meta->isa('Moose::Meta::Role');
3033
3034             $class->_register_plugin($plugin->[0]);
3035         }
3036
3037         my @roles =
3038             map  { $_->[0]->name, $_->[1] }
3039             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3040             map  { [find_meta($_->[0]), $_->[1]] }
3041             @plugins;
3042
3043         Moose::Util::apply_all_roles(
3044             $class => @roles
3045         ) if @roles;
3046     }
3047 }
3048
3049 =head2 $c->stack
3050
3051 Returns an arrayref of the internal execution stack (actions that are
3052 currently executing).
3053
3054 =head2 $c->stats
3055
3056 Returns the current timing statistics object. By default Catalyst uses
3057 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3058 L<< stats_class|/"$c->stats_class" >>.
3059
3060 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3061 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3062 profile explicitly, although MyApp.pm still won't profile nor output anything
3063 by itself.
3064
3065 =head2 $c->stats_class
3066
3067 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3068
3069 =head2 $c->use_stats
3070
3071 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3072
3073 Note that this is a static method, not an accessor and should be overridden
3074 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3075
3076 =cut
3077
3078 sub use_stats { 0 }
3079
3080
3081 =head2 $c->write( $data )
3082
3083 Writes $data to the output stream. When using this method directly, you
3084 will need to manually set the C<Content-Length> header to the length of
3085 your output data, if known.
3086
3087 =cut
3088
3089 sub write {
3090     my $c = shift;
3091
3092     # Finalize headers if someone manually writes output (for compat)
3093     $c->finalize_headers;
3094
3095     return $c->response->write( @_ );
3096 }
3097
3098 =head2 version
3099
3100 Returns the Catalyst version number. Mostly useful for "powered by"
3101 messages in template systems.
3102
3103 =cut
3104
3105 sub version { return $Catalyst::VERSION }
3106
3107 =head1 CONFIGURATION
3108
3109 There are a number of 'base' config variables which can be set:
3110
3111 =over
3112
3113 =item *
3114
3115 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3116
3117 =item *
3118
3119 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3120
3121 =item *
3122
3123 C<disable_component_resolution_regex_fallback> - Turns
3124 off the deprecated component resolution functionality so
3125 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3126 are called then regex search will not be attempted on string values and
3127 instead C<undef> will be returned.
3128
3129 =item *
3130
3131 C<home> - The application home directory. In an uninstalled application,
3132 this is the top level application directory. In an installed application,
3133 this will be the directory containing C<< MyApp.pm >>.
3134
3135 =item *
3136
3137 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3138
3139 =item *
3140
3141 C<name> - The name of the application in debug messages and the debug and
3142 welcome screens
3143
3144 =item *
3145
3146 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3147 until it is accessed. This allows you to (for example) check authentication (and reject
3148 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3149
3150 =item *
3151
3152 C<root> - The root directory for templates. Usually this is just a
3153 subdirectory of the home directory, but you can set it to change the
3154 templates to a different directory.
3155
3156 =item *
3157
3158 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3159 namespaces from which components will be loaded (and constructed and stored in
3160 C<< $c->components >>).
3161
3162 =item *
3163
3164 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3165 to be shown in hit debug tables in the test server.
3166
3167 =item *
3168
3169 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3170 variable should be used for determining the request path.
3171
3172 Most web server environments pass the requested path to the application using environment variables,
3173 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3174 exposed as C<< $c->request->base >>) and the request path below that base.
3175
3176 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3177 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3178
3179 =over
3180
3181 =item use_request_uri_for_path => 0
3182
3183 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3184 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3185 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3186 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3187
3188 However this method has the major disadvantage that it is impossible to correctly decode some elements
3189 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3190 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3191 can't distinguish / vs %2F in paths (in addition to other encoded values).
3192
3193 =item use_request_uri_for_path => 1
3194
3195 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3196 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3197 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3198
3199 Given that this method of path resolution is provably more correct, it is recommended that you use
3200 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3201 aware of the implications of not being able to handle encoded URI paths correctly.
3202
3203 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3204 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3205 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3206 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3207 C<< $c->request->base >> will be incorrect.
3208
3209 =back
3210
3211 =item *
3212
3213 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3214
3215 =item *
3216
3217 C<encoding> - See L</ENCODING>
3218
3219 =item *
3220
3221 C<abort_chain_on_error_fix>
3222
3223 When there is an error in an action chain, the default behavior is to continue
3224 processing the remaining actions and then catch the error upon chain end.  This
3225 can lead to running actions when the application is in an unexpected state.  If
3226 you have this issue, setting this config value to true will promptly exit a
3227 chain when there is an error raised in any action (thus terminating the chain
3228 early.)
3229
3230 use like:
3231
3232     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3233
3234 In the future this might become the default behavior.
3235
3236 =back
3237
3238 =head1 INTERNAL ACTIONS
3239
3240 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3241 C<_ACTION>, and C<_END>. These are by default not shown in the private
3242 action table, but you can make them visible with a config parameter.
3243
3244     MyApp->config(show_internal_actions => 1);
3245
3246 =head1 ON-DEMAND PARSER
3247
3248 The request body is usually parsed at the beginning of a request,
3249 but if you want to handle input yourself, you can enable on-demand
3250 parsing with a config parameter.
3251
3252     MyApp->config(parse_on_demand => 1);
3253
3254 =head1 PROXY SUPPORT
3255
3256 Many production servers operate using the common double-server approach,
3257 with a lightweight frontend web server passing requests to a larger
3258 backend server. An application running on the backend server must deal
3259 with two problems: the remote user always appears to be C<127.0.0.1> and
3260 the server's hostname will appear to be C<localhost> regardless of the
3261 virtual host that the user connected through.
3262
3263 Catalyst will automatically detect this situation when you are running
3264 the frontend and backend servers on the same machine. The following
3265 changes are made to the request.
3266
3267     $c->req->address is set to the user's real IP address, as read from
3268     the HTTP X-Forwarded-For header.
3269
3270     The host value for $c->req->base and $c->req->uri is set to the real
3271     host, as read from the HTTP X-Forwarded-Host header.
3272
3273 Additionally, you may be running your backend application on an insecure
3274 connection (port 80) while your frontend proxy is running under SSL.  If there
3275 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3276 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3277 be created properly.
3278
3279 In the case of passing in:
3280
3281     X-Forwarded-Port: 443
3282
3283 All calls to C<uri_for> will result in an https link, as is expected.
3284
3285 Obviously, your web server must support these headers for this to work.
3286
3287 In a more complex server farm environment where you may have your
3288 frontend proxy server(s) on different machines, you will need to set a
3289 configuration option to tell Catalyst to read the proxied data from the
3290 headers.
3291
3292     MyApp->config(using_frontend_proxy => 1);
3293
3294 If you do not wish to use the proxy support at all, you may set:
3295
3296     MyApp->config(ignore_frontend_proxy => 0);
3297
3298 =head2 Note about psgi files
3299
3300 Note that if you supply your own .psgi file, calling
3301 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3302
3303 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3304 in your psgi, for example:
3305
3306     builder {
3307         enable "Plack::Middleware::ReverseProxy";
3308         MyApp->psgi_app
3309     };
3310
3311 This will unconditionally add the ReverseProxy support, or you need to call
3312 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3313 apply the support depending upon your config).
3314
3315 See L<Catalyst::PSGI> for more information.
3316
3317 =head1 THREAD SAFETY
3318
3319 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3320 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3321 believe the Catalyst core to be thread-safe.
3322
3323 If you plan to operate in a threaded environment, remember that all other
3324 modules you are using must also be thread-safe. Some modules, most notably
3325 L<DBD::SQLite>, are not thread-safe.
3326
3327 =head1 ENCODING
3328
3329 On request, decodes all params from encoding into a sequence of
3330 logical characters. On response, encodes body into encoding.
3331
3332 =head2 Methods
3333
3334 =over 4
3335
3336 =item encoding
3337
3338 Returns an instance of an C<Encode> encoding
3339
3340     print $c->encoding->name
3341
3342 =item handle_unicode_encoding_exception ($exception_context)
3343
3344 Method called when decoding process for a request fails.
3345
3346 An C<$exception_context> hashref is provided to allow you to override the
3347 behaviour of your application when given data with incorrect encodings.
3348
3349 The default method throws exceptions in the case of invalid request parameters
3350 (resulting in a 500 error), but ignores errors in upload filenames.
3351
3352 The keys passed in the C<$exception_context> hash are:
3353
3354 =over
3355
3356 =item param_value
3357
3358 The value which was not able to be decoded.
3359
3360 =item error_msg
3361
3362 The exception received from L<Encode>.
3363
3364 =item encoding_step
3365
3366 What type of data was being decoded. Valid values are (currently)
3367 C<params> - for request parameters / arguments / captures
3368 and C<uploads> - for request upload filenames.
3369
3370 =back
3371
3372 =back
3373
3374 =head1 SUPPORT
3375
3376 IRC:
3377
3378     Join #catalyst on irc.perl.org.
3379
3380 Mailing Lists:
3381
3382     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3383     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3384
3385 Web:
3386
3387     http://catalyst.perl.org
3388
3389 Wiki:
3390
3391     http://dev.catalyst.perl.org
3392
3393 =head1 SEE ALSO
3394
3395 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3396
3397 =head2 L<Catalyst::Manual> - The Catalyst Manual
3398
3399 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3400
3401 =head2 L<Catalyst::Engine> - Core engine
3402
3403 =head2 L<Catalyst::Log> - Log class.
3404
3405 =head2 L<Catalyst::Request> - Request object
3406
3407 =head2 L<Catalyst::Response> - Response object
3408
3409 =head2 L<Catalyst::Test> - The test suite.
3410
3411 =head1 PROJECT FOUNDER
3412
3413 sri: Sebastian Riedel <sri@cpan.org>
3414
3415 =head1 CONTRIBUTORS
3416
3417 abw: Andy Wardley
3418
3419 acme: Leon Brocard <leon@astray.com>
3420
3421 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3422
3423 Andrew Bramble
3424
3425 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3426
3427 Andrew Ruthven
3428
3429 andyg: Andy Grundman <andy@hybridized.org>
3430
3431 audreyt: Audrey Tang
3432
3433 bricas: Brian Cassidy <bricas@cpan.org>
3434
3435 Caelum: Rafael Kitover <rkitover@io.com>
3436
3437 chansen: Christian Hansen
3438
3439 chicks: Christopher Hicks
3440
3441 Chisel Wright C<pause@herlpacker.co.uk>
3442
3443 Danijel Milicevic C<me@danijel.de>
3444
3445 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3446
3447 David Naughton, C<naughton@umn.edu>
3448
3449 David E. Wheeler
3450
3451 dhoss: Devin Austin <dhoss@cpan.org>
3452
3453 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3454
3455 Drew Taylor
3456
3457 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3458
3459 esskar: Sascha Kiefer
3460
3461 fireartist: Carl Franks <cfranks@cpan.org>
3462
3463 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3464
3465 gabb: Danijel Milicevic
3466
3467 Gary Ashton Jones
3468
3469 Gavin Henry C<ghenry@perl.me.uk>
3470
3471 Geoff Richards
3472
3473 groditi: Guillermo Roditi <groditi@gmail.com>
3474
3475 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3476
3477 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3478
3479 jcamacho: Juan Camacho
3480
3481 jester: Jesse Sheidlower C<jester@panix.com>
3482
3483 jhannah: Jay Hannah <jay@jays.net>
3484
3485 Jody Belka
3486
3487 Johan Lindstrom
3488
3489 jon: Jon Schutz <jjschutz@cpan.org>
3490
3491 Jonathan Rockway C<< <jrockway@cpan.org> >>
3492
3493 Kieren Diment C<kd@totaldatasolution.com>
3494
3495 konobi: Scott McWhirter <konobi@cpan.org>
3496
3497 marcus: Marcus Ramberg <mramberg@cpan.org>
3498
3499 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3500
3501 mgrimes: Mark Grimes <mgrimes@cpan.org>
3502
3503 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3504
3505 mugwump: Sam Vilain
3506
3507 naughton: David Naughton
3508
3509 ningu: David Kamholz <dkamholz@cpan.org>
3510
3511 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3512
3513 numa: Dan Sully <daniel@cpan.org>
3514
3515 obra: Jesse Vincent
3516
3517 Octavian Rasnita
3518
3519 omega: Andreas Marienborg
3520
3521 Oleg Kostyuk <cub.uanic@gmail.com>
3522
3523 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3524
3525 rafl: Florian Ragwitz <rafl@debian.org>
3526
3527 random: Roland Lammel <lammel@cpan.org>
3528
3529 Robert Sedlacek C<< <rs@474.at> >>
3530
3531 SpiceMan: Marcel Montes
3532
3533 sky: Arthur Bergman
3534
3535 szbalint: Balint Szilakszi <szbalint@cpan.org>
3536
3537 t0m: Tomas Doran <bobtfish@bobtfish.net>
3538
3539 Ulf Edvinsson
3540
3541 Viljo Marrandi C<vilts@yahoo.com>
3542
3543 Will Hawes C<info@whawes.co.uk>
3544
3545 willert: Sebastian Willert <willert@cpan.org>
3546
3547 wreis: Wallace Reis <wreis@cpan.org>
3548
3549 Yuval Kogman, C<nothingmuch@woobling.org>
3550
3551 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3552
3553 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3554
3555 =head1 COPYRIGHT
3556
3557 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3558
3559 =head1 LICENSE
3560
3561 This library is free software. You can redistribute it and/or modify it under
3562 the same terms as Perl itself.
3563
3564 =cut
3565
3566 no Moose;
3567
3568 __PACKAGE__->meta->make_immutable;
3569
3570 1;