lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Util;
  45 use Class::Load 'load_class';
  46
  47 BEGIN { require 5.008003; }
  48
  49 has stack => (is => 'ro', default => sub { [] });
  50 has stash => (is => 'rw', default => sub { {} });
  51 has state => (is => 'rw', default => 0);
  52 has stats => (is => 'rw');
  53 has action => (is => 'rw');
  54 has counter => (is => 'rw', default => sub { {} });
  55 has request => (
  56     is => 'rw',
  57     default => sub {
  58         my $self = shift;
  59         $self->request_class->new($self->_build_request_constructor_args);
  60     },
  61     lazy => 1,
  62 );
  63 sub _build_request_constructor_args {
  64     my $self = shift;
  65     my %p = ( _log => $self->log );
  66     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  67     $p{data_handlers} = {$self->registered_data_handlers};
  68     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  69       if $self->config->{use_hash_multivalue_in_request};
  70     \%p;
  71 }
  72
  73 has response => (
  74     is => 'rw',
  75     default => sub {
  76         my $self = shift;
  77         $self->response_class->new($self->_build_response_constructor_args);
  78     },
  79     lazy => 1,
  80 );
  81 sub _build_response_constructor_args {
  82     my $self = shift;
  83     { _log => $self->log };
  84 }
  85
  86 has namespace => (is => 'rw');
  87
  88 sub depth { scalar @{ shift->stack || [] }; }
  89 sub comp { shift->component(@_) }
  90
  91 sub req {
  92     my $self = shift; return $self->request(@_);
  93 }
  94 sub res {
  95     my $self = shift; return $self->response(@_);
  96 }
  97
  98 # For backwards compatibility
  99 sub finalize_output { shift->finalize_body(@_) };
 100
 101 # For statistics
 102 our $COUNT     = 1;
 103 our $START     = time;
 104 our $RECURSION = 1000;
 105 our $DETACH    = Catalyst::Exception::Detach->new;
 106 our $GO        = Catalyst::Exception::Go->new;
 107
 108 #I imagine that very few of these really need to be class variables. if any.
 109 #maybe we should just make them attributes with a default?
 110 __PACKAGE__->mk_classdata($_)
 111   for qw/components arguments dispatcher engine log dispatcher_class
 112   engine_loader context_class request_class response_class stats_class
 113   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 114   _data_handlers/;
 115
 116 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 117 __PACKAGE__->request_class('Catalyst::Request');
 118 __PACKAGE__->response_class('Catalyst::Response');
 119 __PACKAGE__->stats_class('Catalyst::Stats');
 120
 121 # Remember to update this in Catalyst::Runtime as well!
 122
 123 our $VERSION = '5.90049_005';
 124
 125 sub import {
 126     my ( $class, @arguments ) = @_;
 127
 128     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 129     # callers @ISA.
 130     return unless $class eq 'Catalyst';
 131
 132     my $caller = caller();
 133     return if $caller eq 'main';
 134
 135     my $meta = Moose::Meta::Class->initialize($caller);
 136     unless ( $caller->isa('Catalyst') ) {
 137         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 138         $meta->superclasses(@superclasses);
 139     }
 140     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 141     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 142
 143     unless( $meta->has_method('meta') ){
 144         if ($Moose::VERSION >= 1.15) {
 145             $meta->_add_meta_method('meta');
 146         }
 147         else {
 148             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 149         }
 150     }
 151
 152     $caller->arguments( [@arguments] );
 153     $caller->setup_home;
 154 }
 155
 156 sub _application { $_[0] }
 157
 158 =encoding UTF-8
 159
 160 =head1 NAME
 161
 162 Catalyst - The Elegant MVC Web Application Framework
 163
 164 =head1 SYNOPSIS
 165
 166 See the L<Catalyst::Manual> distribution for comprehensive
 167 documentation and tutorials.
 168
 169     # Install Catalyst::Devel for helpers and other development tools
 170     # use the helper to create a new application
 171     catalyst.pl MyApp
 172
 173     # add models, views, controllers
 174     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 175     script/myapp_create.pl view MyTemplate TT
 176     script/myapp_create.pl controller Search
 177
 178     # built in testserver -- use -r to restart automatically on changes
 179     # --help to see all available options
 180     script/myapp_server.pl
 181
 182     # command line testing interface
 183     script/myapp_test.pl /yada
 184
 185     ### in lib/MyApp.pm
 186     use Catalyst qw/-Debug/; # include plugins here as well
 187
 188     ### In lib/MyApp/Controller/Root.pm (autocreated)
 189     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 190         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 191         $c->stash->{template} = 'foo.tt'; # set the template
 192         # lookup something from db -- stash vars are passed to TT
 193         $c->stash->{data} =
 194           $c->model('Database::Foo')->search( { country => $args[0] } );
 195         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 196             $c->forward( 'bar' ); # process another action
 197             # do something else after forward returns
 198         }
 199     }
 200
 201     # The foo.tt TT template can use the stash data from the database
 202     [% WHILE (item = data.next) %]
 203         [% item.foo %]
 204     [% END %]
 205
 206     # called for /bar/of/soap, /bar/of/soap/10, etc.
 207     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 208
 209     # called after all actions are finished
 210     sub end : Action {
 211         my ( $self, $c ) = @_;
 212         if ( scalar @{ $c->error } ) { ... } # handle errors
 213         return if $c->res->body; # already have a response
 214         $c->forward( 'MyApp::View::TT' ); # render template
 215     }
 216
 217 See L<Catalyst::Manual::Intro> for additional information.
 218
 219 =head1 DESCRIPTION
 220
 221 Catalyst is a modern framework for making web applications without the
 222 pain usually associated with this process. This document is a reference
 223 to the main Catalyst application. If you are a new user, we suggest you
 224 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 225
 226 See L<Catalyst::Manual> for more documentation.
 227
 228 Catalyst plugins can be loaded by naming them as arguments to the "use
 229 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 230 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 231 C<My::Module>.
 232
 233     use Catalyst qw/My::Module/;
 234
 235 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 236 fully qualify the name by using a unary plus:
 237
 238     use Catalyst qw/
 239         My::Module
 240         +Fully::Qualified::Plugin::Name
 241     /;
 242
 243 Special flags like C<-Debug> can also be specified as
 244 arguments when Catalyst is loaded:
 245
 246     use Catalyst qw/-Debug My::Module/;
 247
 248 The position of plugins and flags in the chain is important, because
 249 they are loaded in the order in which they appear.
 250
 251 The following flags are supported:
 252
 253 =head2 -Debug
 254
 255 Enables debug output. You can also force this setting from the system
 256 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 257 settings override the application, with <MYAPP>_DEBUG having the highest
 258 priority.
 259
 260 This sets the log level to 'debug' and enables full debug output on the
 261 error screen. If you only want the latter, see L<< $c->debug >>.
 262
 263 =head2 -Home
 264
 265 Forces Catalyst to use a specific home directory, e.g.:
 266
 267     use Catalyst qw[-Home=/usr/mst];
 268
 269 This can also be done in the shell environment by setting either the
 270 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 271 is replaced with the uppercased name of your application, any "::" in
 272 the name will be replaced with underscores, e.g. MyApp::Web should use
 273 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 274
 275 If none of these are set, Catalyst will attempt to automatically detect the
 276 home directory. If you are working in a development environment, Catalyst
 277 will try and find the directory containing either Makefile.PL, Build.PL,
 278 dist.ini, or cpanfile. If the application has been installed into the system
 279 (i.e. you have done C<make install>), then Catalyst will use the path to your
 280 application module, without the .pm extension (e.g., /foo/MyApp if your
 281 application was installed at /foo/MyApp.pm)
 282
 283 =head2 -Log
 284
 285     use Catalyst '-Log=warn,fatal,error';
 286
 287 Specifies a comma-delimited list of log levels.
 288
 289 =head2 -Stats
 290
 291 Enables statistics collection and reporting.
 292
 293    use Catalyst qw/-Stats=1/;
 294
 295 You can also force this setting from the system environment with CATALYST_STATS
 296 or <MYAPP>_STATS. The environment settings override the application, with
 297 <MYAPP>_STATS having the highest priority.
 298
 299 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 300
 301 =head1 METHODS
 302
 303 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 304
 305 =head2 $c->action
 306
 307 Returns a L<Catalyst::Action> object for the current action, which
 308 stringifies to the action name. See L<Catalyst::Action>.
 309
 310 =head2 $c->namespace
 311
 312 Returns the namespace of the current action, i.e., the URI prefix
 313 corresponding to the controller of the current action. For example:
 314
 315     # in Controller::Foo::Bar
 316     $c->namespace; # returns 'foo/bar';
 317
 318 =head2 $c->request
 319
 320 =head2 $c->req
 321
 322 Returns the current L<Catalyst::Request> object, giving access to
 323 information about the current client request (including parameters,
 324 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 325
 326 =head2 REQUEST FLOW HANDLING
 327
 328 =head2 $c->forward( $action [, \@arguments ] )
 329
 330 =head2 $c->forward( $class, $method, [, \@arguments ] )
 331
 332 This is one way of calling another action (method) in the same or
 333 a different controller. You can also use C<< $self->my_method($c, @args) >>
 334 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 335 in a different controller.
 336 The main difference is that 'forward' uses some of the Catalyst request
 337 cycle overhead, including debugging, which may be useful to you. On the
 338 other hand, there are some complications to using 'forward', restrictions
 339 on values returned from 'forward', and it may not handle errors as you prefer.
 340 Whether you use 'forward' or not is up to you; it is not considered superior to
 341 the other ways to call a method.
 342
 343 'forward' calls  another action, by its private name. If you give a
 344 class name but no method, C<process()> is called. You may also optionally
 345 pass arguments in an arrayref. The action will receive the arguments in
 346 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 347 C<< $c->req->args >> will be restored to the previous values.
 348
 349 Any data C<return>ed from the action forwarded to, will be returned by the
 350 call to forward.
 351
 352     my $foodata = $c->forward('/foo');
 353     $c->forward('index');
 354     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 355     $c->forward('View::TT');
 356
 357 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 358 an C<< eval { } >> around the call (actually
 359 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 360 exceptions thrown by the called action non-fatal and pushing them onto
 361 $c->error instead. If you want C<die> to propagate you need to do something
 362 like:
 363
 364     $c->forward('foo');
 365     die join "\n", @{ $c->error } if @{ $c->error };
 366
 367 Or make sure to always return true values from your actions and write
 368 your code like this:
 369
 370     $c->forward('foo') || return;
 371
 372 Another note is that C<< $c->forward >> always returns a scalar because it
 373 actually returns $c->state which operates in a scalar context.
 374 Thus, something like:
 375
 376     return @array;
 377
 378 in an action that is forwarded to is going to return a scalar,
 379 i.e. how many items are in that array, which is probably not what you want.
 380 If you need to return an array then return a reference to it,
 381 or stash it like so:
 382
 383     $c->stash->{array} = \@array;
 384
 385 and access it from the stash.
 386
 387 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 388
 389 =cut
 390
 391 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 392
 393 =head2 $c->detach( $action [, \@arguments ] )
 394
 395 =head2 $c->detach( $class, $method, [, \@arguments ] )
 396
 397 =head2 $c->detach()
 398
 399 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 400 doesn't return to the previous action when processing is finished.
 401
 402 When called with no arguments it escapes the processing chain entirely.
 403
 404 =cut
 405
 406 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 407
 408 =head2 $c->visit( $action [, \@arguments ] )
 409
 410 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 411
 412 =head2 $c->visit( $class, $method, [, \@arguments ] )
 413
 414 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 415
 416 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 417 but does a full dispatch, instead of just calling the new C<$action> /
 418 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 419 you go to are called, just like a new request.
 420
 421 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 422 This means, for example, that C<< $c->action >> methods such as
 423 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 424 L<reverse|Catalyst::Action/reverse> return information for the visited action
 425 when they are invoked within the visited action.  This is different from the
 426 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 427 continues to use the $c->action object from the caller action even when
 428 invoked from the called action.
 429
 430 C<< $c->stash >> is kept unchanged.
 431
 432 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 433 allows you to "wrap" another action, just as it would have been called by
 434 dispatching from a URL, while the analogous
 435 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 436 transfer control to another action as if it had been reached directly from a URL.
 437
 438 =cut
 439
 440 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 441
 442 =head2 $c->go( $action [, \@arguments ] )
 443
 444 =head2 $c->go( $action [, \@captures, \@arguments ] )
 445
 446 =head2 $c->go( $class, $method, [, \@arguments ] )
 447
 448 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 449
 450 The relationship between C<go> and
 451 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 452 the relationship between
 453 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 454 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 455 C<< $c->go >> will perform a full dispatch on the specified action or method,
 456 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 457 C<go> escapes the processing of the current request chain on completion, and
 458 does not return to its caller.
 459
 460 @arguments are arguments to the final destination of $action. @captures are
 461 arguments to the intermediate steps, if any, on the way to the final sub of
 462 $action.
 463
 464 =cut
 465
 466 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 467
 468 =head2 $c->response
 469
 470 =head2 $c->res
 471
 472 Returns the current L<Catalyst::Response> object, see there for details.
 473
 474 =head2 $c->stash
 475
 476 Returns a hashref to the stash, which may be used to store data and pass
 477 it between components during a request. You can also set hash keys by
 478 passing arguments. The stash is automatically sent to the view. The
 479 stash is cleared at the end of a request; it cannot be used for
 480 persistent storage (for this you must use a session; see
 481 L<Catalyst::Plugin::Session> for a complete system integrated with
 482 Catalyst).
 483
 484     $c->stash->{foo} = $bar;
 485     $c->stash( { moose => 'majestic', qux => 0 } );
 486     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 487
 488     # stash is automatically passed to the view for use in a template
 489     $c->forward( 'MyApp::View::TT' );
 490
 491 =cut
 492
 493 around stash => sub {
 494     my $orig = shift;
 495     my $c = shift;
 496     my $stash = $orig->($c);
 497     if (@_) {
 498         my $new_stash = @_ > 1 ? {@_} : $_[0];
 499         croak('stash takes a hash or hashref') unless ref $new_stash;
 500         foreach my $key ( keys %$new_stash ) {
 501           $stash->{$key} = $new_stash->{$key};
 502         }
 503     }
 504
 505     return $stash;
 506 };
 507
 508
 509 =head2 $c->error
 510
 511 =head2 $c->error($error, ...)
 512
 513 =head2 $c->error($arrayref)
 514
 515 Returns an arrayref containing error messages.  If Catalyst encounters an
 516 error while processing a request, it stores the error in $c->error.  This
 517 method should only be used to store fatal error messages.
 518
 519     my @error = @{ $c->error };
 520
 521 Add a new error.
 522
 523     $c->error('Something bad happened');
 524
 525 =cut
 526
 527 sub error {
 528     my $c = shift;
 529     if ( $_[0] ) {
 530         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 531         croak @$error unless ref $c;
 532         push @{ $c->{error} }, @$error;
 533     }
 534     elsif ( defined $_[0] ) { $c->{error} = undef }
 535     return $c->{error} || [];
 536 }
 537
 538
 539 =head2 $c->state
 540
 541 Contains the return value of the last executed action.
 542 Note that << $c->state >> operates in a scalar context which means that all
 543 values it returns are scalar.
 544
 545 =head2 $c->clear_errors
 546
 547 Clear errors.  You probably don't want to clear the errors unless you are
 548 implementing a custom error screen.
 549
 550 This is equivalent to running
 551
 552     $c->error(0);
 553
 554 =cut
 555
 556 sub clear_errors {
 557     my $c = shift;
 558     $c->error(0);
 559 }
 560
 561 sub _comp_search_prefixes {
 562     my $c = shift;
 563     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 564 }
 565
 566 # search components given a name and some prefixes
 567 sub _comp_names_search_prefixes {
 568     my ( $c, $name, @prefixes ) = @_;
 569     my $appclass = ref $c || $c;
 570     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 571     $filter = qr/$filter/; # Compile regex now rather than once per loop
 572
 573     # map the original component name to the sub part that we will search against
 574     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 575         grep { /$filter/ } keys %{ $c->components };
 576
 577     # undef for a name will return all
 578     return keys %eligible if !defined $name;
 579
 580     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 581     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 582
 583     return @result if @result;
 584
 585     # if we were given a regexp to search against, we're done.
 586     return if $name->$_isa('Regexp');
 587
 588     # skip regexp fallback if configured
 589     return
 590         if $appclass->config->{disable_component_resolution_regex_fallback};
 591
 592     # regexp fallback
 593     $query  = qr/$name/i;
 594     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 595
 596     # no results? try against full names
 597     if( !@result ) {
 598         @result = grep { m{$query} } keys %eligible;
 599     }
 600
 601     # don't warn if we didn't find any results, it just might not exist
 602     if( @result ) {
 603         # Disgusting hack to work out correct method name
 604         my $warn_for = lc $prefixes[0];
 605         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 606            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 607            "component resolution is unreliable and unsafe.";
 608         my $short = $result[0];
 609         # remove the component namespace prefix
 610         $short =~ s/.*?(Model|Controller|View):://;
 611         my $shortmess = Carp::shortmess('');
 612         if ($shortmess =~ m#Catalyst/Plugin#) {
 613            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 614               "plugin's config";
 615         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 616            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 617               "component's config";
 618         } else {
 619            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 620               "but if you really wanted to search, pass in a regexp as the argument " .
 621               "like so: \$c->${warn_for}(qr/${name}/)";
 622         }
 623         $c->log->warn( "${msg}$shortmess" );
 624     }
 625
 626     return @result;
 627 }
 628
 629 # Find possible names for a prefix
 630 sub _comp_names {
 631     my ( $c, @prefixes ) = @_;
 632     my $appclass = ref $c || $c;
 633
 634     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 635
 636     my @names = map { s{$filter}{}; $_; }
 637         $c->_comp_names_search_prefixes( undef, @prefixes );
 638
 639     return @names;
 640 }
 641
 642 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 643 sub _filter_component {
 644     my ( $c, $comp, @args ) = @_;
 645
 646     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 647         return $comp->ACCEPT_CONTEXT( $c, @args );
 648     }
 649
 650     return $comp;
 651 }
 652
 653 =head2 COMPONENT ACCESSORS
 654
 655 =head2 $c->controller($name)
 656
 657 Gets a L<Catalyst::Controller> instance by name.
 658
 659     $c->controller('Foo')->do_stuff;
 660
 661 If the name is omitted, will return the controller for the dispatched
 662 action.
 663
 664 If you want to search for controllers, pass in a regexp as the argument.
 665
 666     # find all controllers that start with Foo
 667     my @foo_controllers = $c->controller(qr{^Foo});
 668
 669
 670 =cut
 671
 672 sub controller {
 673     my ( $c, $name, @args ) = @_;
 674
 675     my $appclass = ref($c) || $c;
 676     if( $name ) {
 677         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 678             my $comps = $c->components;
 679             my $check = $appclass."::Controller::".$name;
 680             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 681         }
 682         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 683         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 684         return $c->_filter_component( $result[ 0 ], @args );
 685     }
 686
 687     return $c->component( $c->action->class );
 688 }
 689
 690 =head2 $c->model($name)
 691
 692 Gets a L<Catalyst::Model> instance by name.
 693
 694     $c->model('Foo')->do_stuff;
 695
 696 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 697
 698 If the name is omitted, it will look for
 699  - a model object in $c->stash->{current_model_instance}, then
 700  - a model name in $c->stash->{current_model}, then
 701  - a config setting 'default_model', or
 702  - check if there is only one model, and return it if that's the case.
 703
 704 If you want to search for models, pass in a regexp as the argument.
 705
 706     # find all models that start with Foo
 707     my @foo_models = $c->model(qr{^Foo});
 708
 709 =cut
 710
 711 sub model {
 712     my ( $c, $name, @args ) = @_;
 713     my $appclass = ref($c) || $c;
 714     if( $name ) {
 715         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 716             my $comps = $c->components;
 717             my $check = $appclass."::Model::".$name;
 718             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 719         }
 720         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 721         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 722         return $c->_filter_component( $result[ 0 ], @args );
 723     }
 724
 725     if (ref $c) {
 726         return $c->stash->{current_model_instance}
 727           if $c->stash->{current_model_instance};
 728         return $c->model( $c->stash->{current_model} )
 729           if $c->stash->{current_model};
 730     }
 731     return $c->model( $appclass->config->{default_model} )
 732       if $appclass->config->{default_model};
 733
 734     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 735
 736     if( $rest ) {
 737         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 738         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 739         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 740         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 741         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 742     }
 743
 744     return $c->_filter_component( $comp );
 745 }
 746
 747
 748 =head2 $c->view($name)
 749
 750 Gets a L<Catalyst::View> instance by name.
 751
 752     $c->view('Foo')->do_stuff;
 753
 754 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 755
 756 If the name is omitted, it will look for
 757  - a view object in $c->stash->{current_view_instance}, then
 758  - a view name in $c->stash->{current_view}, then
 759  - a config setting 'default_view', or
 760  - check if there is only one view, and return it if that's the case.
 761
 762 If you want to search for views, pass in a regexp as the argument.
 763
 764     # find all views that start with Foo
 765     my @foo_views = $c->view(qr{^Foo});
 766
 767 =cut
 768
 769 sub view {
 770     my ( $c, $name, @args ) = @_;
 771
 772     my $appclass = ref($c) || $c;
 773     if( $name ) {
 774         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 775             my $comps = $c->components;
 776             my $check = $appclass."::View::".$name;
 777             if( exists $comps->{$check} ) {
 778                 return $c->_filter_component( $comps->{$check}, @args );
 779             }
 780             else {
 781                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 782             }
 783         }
 784         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 785         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 786         return $c->_filter_component( $result[ 0 ], @args );
 787     }
 788
 789     if (ref $c) {
 790         return $c->stash->{current_view_instance}
 791           if $c->stash->{current_view_instance};
 792         return $c->view( $c->stash->{current_view} )
 793           if $c->stash->{current_view};
 794     }
 795     return $c->view( $appclass->config->{default_view} )
 796       if $appclass->config->{default_view};
 797
 798     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 799
 800     if( $rest ) {
 801         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 802         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 803         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 804         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 805         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 806     }
 807
 808     return $c->_filter_component( $comp );
 809 }
 810
 811 =head2 $c->controllers
 812
 813 Returns the available names which can be passed to $c->controller
 814
 815 =cut
 816
 817 sub controllers {
 818     my ( $c ) = @_;
 819     return $c->_comp_names(qw/Controller C/);
 820 }
 821
 822 =head2 $c->models
 823
 824 Returns the available names which can be passed to $c->model
 825
 826 =cut
 827
 828 sub models {
 829     my ( $c ) = @_;
 830     return $c->_comp_names(qw/Model M/);
 831 }
 832
 833
 834 =head2 $c->views
 835
 836 Returns the available names which can be passed to $c->view
 837
 838 =cut
 839
 840 sub views {
 841     my ( $c ) = @_;
 842     return $c->_comp_names(qw/View V/);
 843 }
 844
 845 =head2 $c->comp($name)
 846
 847 =head2 $c->component($name)
 848
 849 Gets a component object by name. This method is not recommended,
 850 unless you want to get a specific component by full
 851 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 852 should be used instead.
 853
 854 If C<$name> is a regexp, a list of components matched against the full
 855 component name will be returned.
 856
 857 If Catalyst can't find a component by name, it will fallback to regex
 858 matching by default. To disable this behaviour set
 859 disable_component_resolution_regex_fallback to a true value.
 860
 861     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 862
 863 =cut
 864
 865 sub component {
 866     my ( $c, $name, @args ) = @_;
 867
 868     if( $name ) {
 869         my $comps = $c->components;
 870
 871         if( !ref $name ) {
 872             # is it the exact name?
 873             return $c->_filter_component( $comps->{ $name }, @args )
 874                        if exists $comps->{ $name };
 875
 876             # perhaps we just omitted "MyApp"?
 877             my $composed = ( ref $c || $c ) . "::${name}";
 878             return $c->_filter_component( $comps->{ $composed }, @args )
 879                        if exists $comps->{ $composed };
 880
 881             # search all of the models, views and controllers
 882             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 883             return $c->_filter_component( $comp, @args ) if $comp;
 884         }
 885
 886         return
 887             if $c->config->{disable_component_resolution_regex_fallback};
 888
 889         # This is here so $c->comp( '::M::' ) works
 890         my $query = ref $name ? $name : qr{$name}i;
 891
 892         my @result = grep { m{$query} } keys %{ $c->components };
 893         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 894
 895         if( $result[ 0 ] ) {
 896             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 897             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 898             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 899             return $c->_filter_component( $result[ 0 ], @args );
 900         }
 901
 902         # I would expect to return an empty list here, but that breaks back-compat
 903     }
 904
 905     # fallback
 906     return sort keys %{ $c->components };
 907 }
 908
 909 =head2 CLASS DATA AND HELPER CLASSES
 910
 911 =head2 $c->config
 912
 913 Returns or takes a hashref containing the application's configuration.
 914
 915     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 916
 917 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 918 like C<myapp.conf> in your applications home directory. See
 919 L<Catalyst::Plugin::ConfigLoader>.
 920
 921 =head3 Cascading configuration
 922
 923 The config method is present on all Catalyst components, and configuration
 924 will be merged when an application is started. Configuration loaded with
 925 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 926 followed by configuration in your top level C<MyApp> class. These two
 927 configurations are merged, and then configuration data whose hash key matches a
 928 component name is merged with configuration for that component.
 929
 930 The configuration for a component is then passed to the C<new> method when a
 931 component is constructed.
 932
 933 For example:
 934
 935     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 936     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 937
 938 will mean that C<MyApp::Model::Foo> receives the following data when
 939 constructed:
 940
 941     MyApp::Model::Foo->new({
 942         bar => 'baz',
 943         quux => 'frob',
 944         overrides => 'me',
 945     });
 946
 947 It's common practice to use a Moose attribute
 948 on the receiving component to access the config value.
 949
 950     package MyApp::Model::Foo;
 951
 952     use Moose;
 953
 954     # this attr will receive 'baz' at construction time
 955     has 'bar' => (
 956         is  => 'rw',
 957         isa => 'Str',
 958     );
 959
 960 You can then get the value 'baz' by calling $c->model('Foo')->bar
 961 (or $self->bar inside code in the model).
 962
 963 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 964 as a way of reading config within your code, as this B<will not> give you the
 965 correctly merged config back. You B<MUST> take the config values supplied to
 966 the constructor and use those instead.
 967
 968 =cut
 969
 970 around config => sub {
 971     my $orig = shift;
 972     my $c = shift;
 973
 974     croak('Setting config after setup has been run is not allowed.')
 975         if ( @_ and $c->setup_finished );
 976
 977     $c->$orig(@_);
 978 };
 979
 980 =head2 $c->log
 981
 982 Returns the logging object instance. Unless it is already set, Catalyst
 983 sets this up with a L<Catalyst::Log> object. To use your own log class,
 984 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 985 C<< __PACKAGE__->setup >>.
 986
 987  __PACKAGE__->log( MyLogger->new );
 988  __PACKAGE__->setup;
 989
 990 And later:
 991
 992     $c->log->info( 'Now logging with my own logger!' );
 993
 994 Your log class should implement the methods described in
 995 L<Catalyst::Log>.
 996
 997
 998 =head2 $c->debug
 999
1000 Returns 1 if debug mode is enabled, 0 otherwise.
1001
1002 You can enable debug mode in several ways:
1003
1004 =over
1005
1006 =item By calling myapp_server.pl with the -d flag
1007
1008 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1009
1010 =item The -Debug option in your MyApp.pm
1011
1012 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1013
1014 =back
1015
1016 The first three also set the log level to 'debug'.
1017
1018 Calling C<< $c->debug(1) >> has no effect.
1019
1020 =cut
1021
1022 sub debug { 0 }
1023
1024 =head2 $c->dispatcher
1025
1026 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1027
1028 =head2 $c->engine
1029
1030 Returns the engine instance. See L<Catalyst::Engine>.
1031
1032
1033 =head2 UTILITY METHODS
1034
1035 =head2 $c->path_to(@path)
1036
1037 Merges C<@path> with C<< $c->config->{home} >> and returns a
1038 L<Path::Class::Dir> object. Note you can usually use this object as
1039 a filename, but sometimes you will have to explicitly stringify it
1040 yourself by calling the C<< ->stringify >> method.
1041
1042 For example:
1043
1044     $c->path_to( 'db', 'sqlite.db' );
1045
1046 =cut
1047
1048 sub path_to {
1049     my ( $c, @path ) = @_;
1050     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1051     if ( -d $path ) { return $path }
1052     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1053 }
1054
1055 sub plugin {
1056     my ( $class, $name, $plugin, @args ) = @_;
1057
1058     # See block comment in t/unit_core_plugin.t
1059     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1060
1061     $class->_register_plugin( $plugin, 1 );
1062
1063     eval { $plugin->import };
1064     $class->mk_classdata($name);
1065     my $obj;
1066     eval { $obj = $plugin->new(@args) };
1067
1068     if ($@) {
1069         Catalyst::Exception->throw( message =>
1070               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1071     }
1072
1073     $class->$name($obj);
1074     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1075       if $class->debug;
1076 }
1077
1078 =head2 MyApp->setup
1079
1080 Initializes the dispatcher and engine, loads any plugins, and loads the
1081 model, view, and controller components. You may also specify an array
1082 of plugins to load here, if you choose to not load them in the C<use
1083 Catalyst> line.
1084
1085     MyApp->setup;
1086     MyApp->setup( qw/-Debug/ );
1087
1088 B<Note:> You B<should not> wrap this method with method modifiers
1089 or bad things will happen - wrap the C<setup_finalize> method instead.
1090
1091 =cut
1092
1093 sub setup {
1094     my ( $class, @arguments ) = @_;
1095     croak('Running setup more than once')
1096         if ( $class->setup_finished );
1097
1098     unless ( $class->isa('Catalyst') ) {
1099
1100         Catalyst::Exception->throw(
1101             message => qq/'$class' does not inherit from Catalyst/ );
1102     }
1103
1104     if ( $class->arguments ) {
1105         @arguments = ( @arguments, @{ $class->arguments } );
1106     }
1107
1108     # Process options
1109     my $flags = {};
1110
1111     foreach (@arguments) {
1112
1113         if (/^-Debug$/) {
1114             $flags->{log} =
1115               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1116         }
1117         elsif (/^-(\w+)=?(.*)$/) {
1118             $flags->{ lc $1 } = $2;
1119         }
1120         else {
1121             push @{ $flags->{plugins} }, $_;
1122         }
1123     }
1124
1125     $class->setup_home( delete $flags->{home} );
1126
1127     $class->setup_log( delete $flags->{log} );
1128     $class->setup_plugins( delete $flags->{plugins} );
1129     $class->setup_middleware();
1130     $class->setup_data_handlers();
1131     $class->setup_dispatcher( delete $flags->{dispatcher} );
1132     if (my $engine = delete $flags->{engine}) {
1133         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1134     }
1135     $class->setup_engine();
1136     $class->setup_stats( delete $flags->{stats} );
1137
1138     for my $flag ( sort keys %{$flags} ) {
1139
1140         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1141             &$code( $class, delete $flags->{$flag} );
1142         }
1143         else {
1144             $class->log->warn(qq/Unknown flag "$flag"/);
1145         }
1146     }
1147
1148     eval { require Catalyst::Devel; };
1149     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1150         $class->log->warn(<<"EOF");
1151 You are running an old script!
1152
1153   Please update by running (this will overwrite existing files):
1154     catalyst.pl -force -scripts $class
1155
1156   or (this will not overwrite existing files):
1157     catalyst.pl -scripts $class
1158
1159 EOF
1160     }
1161
1162     if ( $class->debug ) {
1163         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1164
1165         if (@plugins) {
1166             my $column_width = Catalyst::Utils::term_width() - 6;
1167             my $t = Text::SimpleTable->new($column_width);
1168             $t->row($_) for @plugins;
1169             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1170         }
1171
1172         my @middleware = map {
1173           ref $_ eq 'CODE' ?
1174             "Inline Coderef" :
1175               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1176                 || '')  } $class->registered_middlewares;
1177
1178         if (@middleware) {
1179             my $column_width = Catalyst::Utils::term_width() - 6;
1180             my $t = Text::SimpleTable->new($column_width);
1181             $t->row($_) for @middleware;
1182             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1183         }
1184
1185         my %dh = $class->registered_data_handlers;
1186         if (my @data_handlers = keys %dh) {
1187             my $column_width = Catalyst::Utils::term_width() - 6;
1188             my $t = Text::SimpleTable->new($column_width);
1189             $t->row($_) for @data_handlers;
1190             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1191         }
1192
1193         my $dispatcher = $class->dispatcher;
1194         my $engine     = $class->engine;
1195         my $home       = $class->config->{home};
1196
1197         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1198         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1199
1200         $home
1201           ? ( -d $home )
1202           ? $class->log->debug(qq/Found home "$home"/)
1203           : $class->log->debug(qq/Home "$home" doesn't exist/)
1204           : $class->log->debug(q/Couldn't find home/);
1205     }
1206
1207     # Call plugins setup, this is stupid and evil.
1208     # Also screws C3 badly on 5.10, hack to avoid.
1209     {
1210         no warnings qw/redefine/;
1211         local *setup = sub { };
1212         $class->setup unless $Catalyst::__AM_RESTARTING;
1213     }
1214
1215     # Initialize our data structure
1216     $class->components( {} );
1217
1218     $class->setup_components;
1219
1220     if ( $class->debug ) {
1221         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1222         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1223         for my $comp ( sort keys %{ $class->components } ) {
1224             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1225             $t->row( $comp, $type );
1226         }
1227         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1228           if ( keys %{ $class->components } );
1229     }
1230
1231     # Add our self to components, since we are also a component
1232     if( $class->isa('Catalyst::Controller') ){
1233       $class->components->{$class} = $class;
1234     }
1235
1236     $class->setup_actions;
1237
1238     if ( $class->debug ) {
1239         my $name = $class->config->{name} || 'Application';
1240         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1241     }
1242
1243     if ($class->config->{case_sensitive}) {
1244         $class->log->warn($class . "->config->{case_sensitive} is set.");
1245         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1246     }
1247
1248     $class->setup_finalize;
1249     # Should be the last thing we do so that user things hooking
1250     # setup_finalize can log..
1251     $class->log->_flush() if $class->log->can('_flush');
1252     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1253 }
1254
1255 =head2 $app->setup_finalize
1256
1257 A hook to attach modifiers to. This method does not do anything except set the
1258 C<setup_finished> accessor.
1259
1260 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1261
1262 Example:
1263
1264     after setup_finalize => sub {
1265         my $app = shift;
1266
1267         ## do stuff here..
1268     };
1269
1270 =cut
1271
1272 sub setup_finalize {
1273     my ($class) = @_;
1274     $class->setup_finished(1);
1275 }
1276
1277 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1278
1279 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1280
1281 Constructs an absolute L<URI> object based on the application root, the
1282 provided path, and the additional arguments and query parameters provided.
1283 When used as a string, provides a textual URI.  If you need more flexibility
1284 than this (i.e. the option to provide relative URIs etc.) see
1285 L<Catalyst::Plugin::SmartURI>.
1286
1287 If no arguments are provided, the URI for the current action is returned.
1288 To return the current action and also provide @args, use
1289 C<< $c->uri_for( $c->action, @args ) >>.
1290
1291 If the first argument is a string, it is taken as a public URI path relative
1292 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1293 relative to the application root (if it does). It is then merged with
1294 C<< $c->request->base >>; any C<@args> are appended as additional path
1295 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1296
1297 If the first argument is a L<Catalyst::Action> it represents an action which
1298 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1299 optional C<\@captures> argument (an arrayref) allows passing the captured
1300 variables that are needed to fill in the paths of Chained and Regex actions;
1301 once the path is resolved, C<uri_for> continues as though a path was
1302 provided, appending any arguments or parameters and creating an absolute
1303 URI.
1304
1305 The captures for the current request can be found in
1306 C<< $c->request->captures >>, and actions can be resolved using
1307 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1308 path, use C<< $c->uri_for_action >> instead.
1309
1310   # Equivalent to $c->req->uri
1311   $c->uri_for($c->action, $c->req->captures,
1312       @{ $c->req->args }, $c->req->params);
1313
1314   # For the Foo action in the Bar controller
1315   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1316
1317   # Path to a static resource
1318   $c->uri_for('/static/images/logo.png');
1319
1320 =cut
1321
1322 sub uri_for {
1323     my ( $c, $path, @args ) = @_;
1324
1325     if ( $path->$_isa('Catalyst::Controller') ) {
1326         $path = $path->path_prefix;
1327         $path =~ s{/+\z}{};
1328         $path .= '/';
1329     }
1330
1331     undef($path) if (defined $path && $path eq '');
1332
1333     my $params =
1334       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1335
1336     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1337     foreach my $arg (@args) {
1338         utf8::encode($arg) if utf8::is_utf8($arg);
1339         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1340     }
1341
1342     if ( $path->$_isa('Catalyst::Action') ) { # action object
1343         s|/|%2F|g for @args;
1344         my $captures = [ map { s|/|%2F|g; $_; }
1345                         ( scalar @args && ref $args[0] eq 'ARRAY'
1346                          ? @{ shift(@args) }
1347                          : ()) ];
1348
1349         foreach my $capture (@$captures) {
1350             utf8::encode($capture) if utf8::is_utf8($capture);
1351             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1352         }
1353
1354         my $action = $path;
1355         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1356         if( !@args && $action->number_of_args ) {
1357             my $expanded_action = $c->dispatcher->expand_action( $action );
1358
1359             my $num_captures = $expanded_action->number_of_captures;
1360             unshift @args, splice @$captures, $num_captures;
1361         }
1362
1363        $path = $c->dispatcher->uri_for_action($action, $captures);
1364         if (not defined $path) {
1365             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1366                 if $c->debug;
1367             return undef;
1368         }
1369         $path = '/' if $path eq '';
1370     }
1371
1372     unshift(@args, $path);
1373
1374     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1375         my $namespace = $c->namespace;
1376         if (defined $path) { # cheesy hack to handle path '../foo'
1377            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1378         }
1379         unshift(@args, $namespace || '');
1380     }
1381
1382     # join args with '/', or a blank string
1383     my $args = join('/', grep { defined($_) } @args);
1384     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1385     $args =~ s!^/+!!;
1386
1387     my ($base, $class) = ('/', 'URI::_generic');
1388     if(blessed($c)) {
1389       $base = $c->req->base;
1390       $class = ref($base);
1391       $base =~ s{(?<!/)$}{/};
1392     }
1393
1394     my $query = '';
1395
1396     if (my @keys = keys %$params) {
1397       # somewhat lifted from URI::_query's query_form
1398       $query = '?'.join('&', map {
1399           my $val = $params->{$_};
1400           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1401           s/ /+/g;
1402           my $key = $_;
1403           $val = '' unless defined $val;
1404           (map {
1405               my $param = "$_";
1406               utf8::encode( $param ) if utf8::is_utf8($param);
1407               # using the URI::Escape pattern here so utf8 chars survive
1408               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1409               $param =~ s/ /+/g;
1410               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1411       } @keys);
1412     }
1413
1414     my $res = bless(\"${base}${args}${query}", $class);
1415     $res;
1416 }
1417
1418 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1419
1420 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1421
1422 =over
1423
1424 =item $path
1425
1426 A private path to the Catalyst action you want to create a URI for.
1427
1428 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1429 >> and passing the resulting C<$action> and the remaining arguments to C<<
1430 $c->uri_for >>.
1431
1432 You can also pass in a Catalyst::Action object, in which case it is passed to
1433 C<< $c->uri_for >>.
1434
1435 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1436
1437 For example, if the action looks like:
1438
1439  package MyApp::Controller::Users;
1440
1441  sub lst : Path('the-list') {}
1442
1443 You can use:
1444
1445  $c->uri_for_action('/users/lst')
1446
1447 and it will create the URI /users/the-list.
1448
1449 =item \@captures_and_args?
1450
1451 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1452 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1453 to interpolate all the parameters in the URI.
1454
1455 =item @args?
1456
1457 Optional list of extra arguments - can be supplied in the
1458 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1459 code.
1460
1461 Your action can have zero, a fixed or a variable number of args (e.g.
1462 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1463
1464 =item \%query_values?
1465
1466 Optional array reference of query parameters to append. E.g.
1467
1468   { foo => 'bar' }
1469
1470 will generate
1471
1472   /rest/of/your/uri?foo=bar
1473
1474 =back
1475
1476 =cut
1477
1478 sub uri_for_action {
1479     my ( $c, $path, @args ) = @_;
1480     my $action = blessed($path)
1481       ? $path
1482       : $c->dispatcher->get_action_by_path($path);
1483     unless (defined $action) {
1484       croak "Can't find action for path '$path'";
1485     }
1486     return $c->uri_for( $action, @args );
1487 }
1488
1489 =head2 $c->welcome_message
1490
1491 Returns the Catalyst welcome HTML page.
1492
1493 =cut
1494
1495 sub welcome_message {
1496     my $c      = shift;
1497     my $name   = $c->config->{name};
1498     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1499     my $prefix = Catalyst::Utils::appprefix( ref $c );
1500     $c->response->content_type('text/html; charset=utf-8');
1501     return <<"EOF";
1502 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1503     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1504 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1505     <head>
1506     <meta http-equiv="Content-Language" content="en" />
1507     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1508         <title>$name on Catalyst $VERSION</title>
1509         <style type="text/css">
1510             body {
1511                 color: #000;
1512                 background-color: #eee;
1513             }
1514             div#content {
1515                 width: 640px;
1516                 margin-left: auto;
1517                 margin-right: auto;
1518                 margin-top: 10px;
1519                 margin-bottom: 10px;
1520                 text-align: left;
1521                 background-color: #ccc;
1522                 border: 1px solid #aaa;
1523             }
1524             p, h1, h2 {
1525                 margin-left: 20px;
1526                 margin-right: 20px;
1527                 font-family: verdana, tahoma, sans-serif;
1528             }
1529             a {
1530                 font-family: verdana, tahoma, sans-serif;
1531             }
1532             :link, :visited {
1533                     text-decoration: none;
1534                     color: #b00;
1535                     border-bottom: 1px dotted #bbb;
1536             }
1537             :link:hover, :visited:hover {
1538                     color: #555;
1539             }
1540             div#topbar {
1541                 margin: 0px;
1542             }
1543             pre {
1544                 margin: 10px;
1545                 padding: 8px;
1546             }
1547             div#answers {
1548                 padding: 8px;
1549                 margin: 10px;
1550                 background-color: #fff;
1551                 border: 1px solid #aaa;
1552             }
1553             h1 {
1554                 font-size: 0.9em;
1555                 font-weight: normal;
1556                 text-align: center;
1557             }
1558             h2 {
1559                 font-size: 1.0em;
1560             }
1561             p {
1562                 font-size: 0.9em;
1563             }
1564             p img {
1565                 float: right;
1566                 margin-left: 10px;
1567             }
1568             span#appname {
1569                 font-weight: bold;
1570                 font-size: 1.6em;
1571             }
1572         </style>
1573     </head>
1574     <body>
1575         <div id="content">
1576             <div id="topbar">
1577                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1578                     $VERSION</h1>
1579              </div>
1580              <div id="answers">
1581                  <p>
1582                  <img src="$logo" alt="Catalyst Logo" />
1583                  </p>
1584                  <p>Welcome to the  world of Catalyst.
1585                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1586                     framework will make web development something you had
1587                     never expected it to be: Fun, rewarding, and quick.</p>
1588                  <h2>What to do now?</h2>
1589                  <p>That really depends  on what <b>you</b> want to do.
1590                     We do, however, provide you with a few starting points.</p>
1591                  <p>If you want to jump right into web development with Catalyst
1592                     you might want to start with a tutorial.</p>
1593 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1594 </pre>
1595 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1596 <pre>
1597 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1598 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1599 </code></pre>
1600                  <h2>What to do next?</h2>
1601                  <p>Next it's time to write an actual application. Use the
1602                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1603                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1604                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1605                     they can save you a lot of work.</p>
1606                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1607                     <p>Also, be sure to check out the vast and growing
1608                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1609                     you are likely to find what you need there.
1610                     </p>
1611
1612                  <h2>Need help?</h2>
1613                  <p>Catalyst has a very active community. Here are the main places to
1614                     get in touch with us.</p>
1615                  <ul>
1616                      <li>
1617                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1618                      </li>
1619                      <li>
1620                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1621                      </li>
1622                      <li>
1623                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1624                      </li>
1625                  </ul>
1626                  <h2>In conclusion</h2>
1627                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1628                     as we enjoyed making it. Please contact us if you have ideas
1629                     for improvement or other feedback.</p>
1630              </div>
1631          </div>
1632     </body>
1633 </html>
1634 EOF
1635 }
1636
1637 =head2 run_options
1638
1639 Contains a hash of options passed from the application script, including
1640 the original ARGV the script received, the processed values from that
1641 ARGV and any extra arguments to the script which were not processed.
1642
1643 This can be used to add custom options to your application's scripts
1644 and setup your application differently depending on the values of these
1645 options.
1646
1647 =head1 INTERNAL METHODS
1648
1649 These methods are not meant to be used by end users.
1650
1651 =head2 $c->components
1652
1653 Returns a hash of components.
1654
1655 =head2 $c->context_class
1656
1657 Returns or sets the context class.
1658
1659 =head2 $c->counter
1660
1661 Returns a hashref containing coderefs and execution counts (needed for
1662 deep recursion detection).
1663
1664 =head2 $c->depth
1665
1666 Returns the number of actions on the current internal execution stack.
1667
1668 =head2 $c->dispatch
1669
1670 Dispatches a request to actions.
1671
1672 =cut
1673
1674 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1675
1676 =head2 $c->dispatcher_class
1677
1678 Returns or sets the dispatcher class.
1679
1680 =head2 $c->dump_these
1681
1682 Returns a list of 2-element array references (name, structure) pairs
1683 that will be dumped on the error page in debug mode.
1684
1685 =cut
1686
1687 sub dump_these {
1688     my $c = shift;
1689     [ Request => $c->req ],
1690     [ Response => $c->res ],
1691     [ Stash => $c->stash ],
1692     [ Config => $c->config ];
1693 }
1694
1695 =head2 $c->engine_class
1696
1697 Returns or sets the engine class.
1698
1699 =head2 $c->execute( $class, $coderef )
1700
1701 Execute a coderef in given class and catch exceptions. Errors are available
1702 via $c->error.
1703
1704 =cut
1705
1706 sub execute {
1707     my ( $c, $class, $code ) = @_;
1708     $class = $c->component($class) || $class;
1709     $c->state(0);
1710
1711     if ( $c->depth >= $RECURSION ) {
1712         my $action = $code->reverse();
1713         $action = "/$action" unless $action =~ /->/;
1714         my $error = qq/Deep recursion detected calling "${action}"/;
1715         $c->log->error($error);
1716         $c->error($error);
1717         $c->state(0);
1718         return $c->state;
1719     }
1720
1721     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1722
1723     push( @{ $c->stack }, $code );
1724
1725     no warnings 'recursion';
1726     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1727     #      I have no idea how, ergo $ret (which appears to fix the issue)
1728     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1729
1730     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1731
1732     my $last = pop( @{ $c->stack } );
1733
1734     if ( my $error = $@ ) {
1735         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1736             $error->rethrow if $c->depth > 1;
1737         }
1738         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1739             $error->rethrow if $c->depth > 0;
1740         }
1741         else {
1742             unless ( ref $error ) {
1743                 no warnings 'uninitialized';
1744                 chomp $error;
1745                 my $class = $last->class;
1746                 my $name  = $last->name;
1747                 $error = qq/Caught exception in $class->$name "$error"/;
1748             }
1749             $c->error($error);
1750         }
1751         $c->state(0);
1752     }
1753     return $c->state;
1754 }
1755
1756 sub _stats_start_execute {
1757     my ( $c, $code ) = @_;
1758     my $appclass = ref($c) || $c;
1759     return if ( ( $code->name =~ /^_.*/ )
1760         && ( !$appclass->config->{show_internal_actions} ) );
1761
1762     my $action_name = $code->reverse();
1763     $c->counter->{$action_name}++;
1764
1765     my $action = $action_name;
1766     $action = "/$action" unless $action =~ /->/;
1767
1768     # determine if the call was the result of a forward
1769     # this is done by walking up the call stack and looking for a calling
1770     # sub of Catalyst::forward before the eval
1771     my $callsub = q{};
1772     for my $index ( 2 .. 11 ) {
1773         last
1774         if ( ( caller($index) )[0] eq 'Catalyst'
1775             && ( caller($index) )[3] eq '(eval)' );
1776
1777         if ( ( caller($index) )[3] =~ /forward$/ ) {
1778             $callsub = ( caller($index) )[3];
1779             $action  = "-> $action";
1780             last;
1781         }
1782     }
1783
1784     my $uid = $action_name . $c->counter->{$action_name};
1785
1786     # is this a root-level call or a forwarded call?
1787     if ( $callsub =~ /forward$/ ) {
1788         my $parent = $c->stack->[-1];
1789
1790         # forward, locate the caller
1791         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1792             $c->stats->profile(
1793                 begin  => $action,
1794                 parent => "$parent" . $c->counter->{"$parent"},
1795                 uid    => $uid,
1796             );
1797         }
1798         else {
1799
1800             # forward with no caller may come from a plugin
1801             $c->stats->profile(
1802                 begin => $action,
1803                 uid   => $uid,
1804             );
1805         }
1806     }
1807     else {
1808
1809         # root-level call
1810         $c->stats->profile(
1811             begin => $action,
1812             uid   => $uid,
1813         );
1814     }
1815     return $action;
1816
1817 }
1818
1819 sub _stats_finish_execute {
1820     my ( $c, $info ) = @_;
1821     $c->stats->profile( end => $info );
1822 }
1823
1824 =head2 $c->finalize
1825
1826 Finalizes the request.
1827
1828 =cut
1829
1830 sub finalize {
1831     my $c = shift;
1832
1833     for my $error ( @{ $c->error } ) {
1834         $c->log->error($error);
1835     }
1836
1837     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1838     # stuff like cometd and websockets
1839
1840     if($c->request->has_io_fh) {
1841       $c->log_response;
1842       return;
1843     }
1844
1845     # Allow engine to handle finalize flow (for POE)
1846     my $engine = $c->engine;
1847     if ( my $code = $engine->can('finalize') ) {
1848         $engine->$code($c);
1849     }
1850     else {
1851
1852         $c->finalize_uploads;
1853
1854         # Error
1855         if ( $#{ $c->error } >= 0 ) {
1856             $c->finalize_error;
1857         }
1858
1859         $c->finalize_headers unless $c->response->finalized_headers;
1860
1861         # HEAD request
1862         if ( $c->request->method eq 'HEAD' ) {
1863             $c->response->body('');
1864         }
1865
1866         $c->finalize_body;
1867     }
1868
1869     $c->log_response;
1870
1871     if ($c->use_stats) {
1872         my $elapsed = $c->stats->elapsed;
1873         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1874         $c->log->info(
1875             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1876     }
1877
1878     return $c->response->status;
1879 }
1880
1881 =head2 $c->finalize_body
1882
1883 Finalizes body.
1884
1885 =cut
1886
1887 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1888
1889 =head2 $c->finalize_cookies
1890
1891 Finalizes cookies.
1892
1893 =cut
1894
1895 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1896
1897 =head2 $c->finalize_error
1898
1899 Finalizes error.
1900
1901 =cut
1902
1903 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1904
1905 =head2 $c->finalize_headers
1906
1907 Finalizes headers.
1908
1909 =cut
1910
1911 sub finalize_headers {
1912     my $c = shift;
1913
1914     my $response = $c->response; #accessor calls can add up?
1915
1916     # Check if we already finalized headers
1917     return if $response->finalized_headers;
1918
1919     # Handle redirects
1920     if ( my $location = $response->redirect ) {
1921         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1922         $response->header( Location => $location );
1923
1924         if ( !$response->has_body ) {
1925             # Add a default body if none is already present
1926             my $encoded_location = encode_entities($location);
1927             $response->body(<<"EOF");
1928 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1929 <html xmlns="http://www.w3.org/1999/xhtml">
1930   <head>
1931     <title>Moved</title>
1932   </head>
1933   <body>
1934      <p>This item has moved <a href="$encoded_location">here</a>.</p>
1935   </body>
1936 </html>
1937 EOF
1938             $response->content_type('text/html; charset=utf-8');
1939         }
1940     }
1941
1942     # Content-Length
1943     if ( defined $response->body && length $response->body && !$response->content_length ) {
1944
1945         # get the length from a filehandle
1946         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1947         {
1948             my $size = -s $response->body;
1949             if ( $size ) {
1950                 $response->content_length( $size );
1951             }
1952             else {
1953                 $c->log->warn('Serving filehandle without a content-length');
1954             }
1955         }
1956         else {
1957             # everything should be bytes at this point, but just in case
1958             $response->content_length( length( $response->body ) );
1959         }
1960     }
1961
1962     # Errors
1963     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1964         $response->headers->remove_header("Content-Length");
1965         $response->body('');
1966     }
1967
1968     $c->finalize_cookies;
1969
1970     $c->response->finalize_headers();
1971
1972     # Done
1973     $response->finalized_headers(1);
1974 }
1975
1976 =head2 $c->finalize_output
1977
1978 An alias for finalize_body.
1979
1980 =head2 $c->finalize_read
1981
1982 Finalizes the input after reading is complete.
1983
1984 =cut
1985
1986 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1987
1988 =head2 $c->finalize_uploads
1989
1990 Finalizes uploads. Cleans up any temporary files.
1991
1992 =cut
1993
1994 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1995
1996 =head2 $c->get_action( $action, $namespace )
1997
1998 Gets an action in a given namespace.
1999
2000 =cut
2001
2002 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2003
2004 =head2 $c->get_actions( $action, $namespace )
2005
2006 Gets all actions of a given name in a namespace and all parent
2007 namespaces.
2008
2009 =cut
2010
2011 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2012
2013 =head2 $app->handle_request( @arguments )
2014
2015 Called to handle each HTTP request.
2016
2017 =cut
2018
2019 sub handle_request {
2020     my ( $class, @arguments ) = @_;
2021
2022     # Always expect worst case!
2023     my $status = -1;
2024     try {
2025         if ($class->debug) {
2026             my $secs = time - $START || 1;
2027             my $av = sprintf '%.3f', $COUNT / $secs;
2028             my $time = localtime time;
2029             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2030         }
2031
2032         my $c = $class->prepare(@arguments);
2033         $c->dispatch;
2034         $status = $c->finalize;
2035     }
2036     catch {
2037         chomp(my $error = $_);
2038         $class->log->error(qq/Caught exception in engine "$error"/);
2039     };
2040
2041     $COUNT++;
2042
2043     if(my $coderef = $class->log->can('_flush')){
2044         $class->log->$coderef();
2045     }
2046     return $status;
2047 }
2048
2049 =head2 $class->prepare( @arguments )
2050
2051 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2052 etc.).
2053
2054 =cut
2055
2056 has _uploadtmp => (
2057     is => 'ro',
2058     predicate => '_has_uploadtmp',
2059 );
2060
2061 sub prepare {
2062     my ( $class, @arguments ) = @_;
2063
2064     # XXX
2065     # After the app/ctxt split, this should become an attribute based on something passed
2066     # into the application.
2067     $class->context_class( ref $class || $class ) unless $class->context_class;
2068
2069     my $uploadtmp = $class->config->{uploadtmp};
2070     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2071
2072     $c->response->_context($c);
2073
2074     #surely this is not the most efficient way to do things...
2075     $c->stats($class->stats_class->new)->enable($c->use_stats);
2076     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2077         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2078     }
2079
2080     try {
2081         # Allow engine to direct the prepare flow (for POE)
2082         if ( my $prepare = $c->engine->can('prepare') ) {
2083             $c->engine->$prepare( $c, @arguments );
2084         }
2085         else {
2086             $c->prepare_request(@arguments);
2087             $c->prepare_connection;
2088             $c->prepare_query_parameters;
2089             $c->prepare_headers; # Just hooks, no longer needed - they just
2090             $c->prepare_cookies; # cause the lazy attribute on req to build
2091             $c->prepare_path;
2092
2093             # Prepare the body for reading, either by prepare_body
2094             # or the user, if they are using $c->read
2095             $c->prepare_read;
2096
2097             # Parse the body unless the user wants it on-demand
2098             unless ( ref($c)->config->{parse_on_demand} ) {
2099                 $c->prepare_body;
2100             }
2101         }
2102         $c->prepare_action;
2103     }
2104     # VERY ugly and probably shouldn't rely on ->finalize actually working
2105     catch {
2106         # failed prepare is always due to an invalid request, right?
2107         $c->response->status(400);
2108         $c->response->content_type('text/plain');
2109         $c->response->body('Bad Request');
2110         # Note we call finalize and then die here, which escapes
2111         # finalize being called in the enclosing block..
2112         # It in fact couldn't be called, as we don't return $c..
2113         # This is a mess - but I'm unsure you can fix this without
2114         # breaking compat for people doing crazy things (we should set
2115         # the 400 and just return the ctx here IMO, letting finalize get called
2116         # above...
2117         $c->finalize;
2118         die $_;
2119     };
2120
2121     $c->log_request;
2122
2123     return $c;
2124 }
2125
2126 =head2 $c->prepare_action
2127
2128 Prepares action. See L<Catalyst::Dispatcher>.
2129
2130 =cut
2131
2132 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2133
2134 =head2 $c->prepare_body
2135
2136 Prepares message body.
2137
2138 =cut
2139
2140 sub prepare_body {
2141     my $c = shift;
2142
2143     return if $c->request->_has_body;
2144
2145     # Initialize on-demand data
2146     $c->engine->prepare_body( $c, @_ );
2147     $c->prepare_parameters;
2148     $c->prepare_uploads;
2149 }
2150
2151 =head2 $c->prepare_body_chunk( $chunk )
2152
2153 Prepares a chunk of data before sending it to L<HTTP::Body>.
2154
2155 See L<Catalyst::Engine>.
2156
2157 =cut
2158
2159 sub prepare_body_chunk {
2160     my $c = shift;
2161     $c->engine->prepare_body_chunk( $c, @_ );
2162 }
2163
2164 =head2 $c->prepare_body_parameters
2165
2166 Prepares body parameters.
2167
2168 =cut
2169
2170 sub prepare_body_parameters {
2171     my $c = shift;
2172     $c->engine->prepare_body_parameters( $c, @_ );
2173 }
2174
2175 =head2 $c->prepare_connection
2176
2177 Prepares connection.
2178
2179 =cut
2180
2181 sub prepare_connection {
2182     my $c = shift;
2183     # XXX - This is called on the engine (not the request) to maintain
2184     #       Engine::PSGI back compat.
2185     $c->engine->prepare_connection($c);
2186 }
2187
2188 =head2 $c->prepare_cookies
2189
2190 Prepares cookies by ensuring that the attribute on the request
2191 object has been built.
2192
2193 =cut
2194
2195 sub prepare_cookies { my $c = shift; $c->request->cookies }
2196
2197 =head2 $c->prepare_headers
2198
2199 Prepares request headers by ensuring that the attribute on the request
2200 object has been built.
2201
2202 =cut
2203
2204 sub prepare_headers { my $c = shift; $c->request->headers }
2205
2206 =head2 $c->prepare_parameters
2207
2208 Prepares parameters.
2209
2210 =cut
2211
2212 sub prepare_parameters {
2213     my $c = shift;
2214     $c->prepare_body_parameters;
2215     $c->engine->prepare_parameters( $c, @_ );
2216 }
2217
2218 =head2 $c->prepare_path
2219
2220 Prepares path and base.
2221
2222 =cut
2223
2224 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2225
2226 =head2 $c->prepare_query_parameters
2227
2228 Prepares query parameters.
2229
2230 =cut
2231
2232 sub prepare_query_parameters {
2233     my $c = shift;
2234
2235     $c->engine->prepare_query_parameters( $c, @_ );
2236 }
2237
2238 =head2 $c->log_request
2239
2240 Writes information about the request to the debug logs.  This includes:
2241
2242 =over 4
2243
2244 =item * Request method, path, and remote IP address
2245
2246 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2247
2248 =item * Request parameters
2249
2250 =item * File uploads
2251
2252 =back
2253
2254 =cut
2255
2256 sub log_request {
2257     my $c = shift;
2258
2259     return unless $c->debug;
2260
2261     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2262     my $request = $dump->[1];
2263
2264     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2265     $method ||= '';
2266     $path = '/' unless length $path;
2267     $address ||= '';
2268     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2269
2270     $c->log_request_headers($request->headers);
2271
2272     if ( my $keywords = $request->query_keywords ) {
2273         $c->log->debug("Query keywords are: $keywords");
2274     }
2275
2276     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2277
2278     $c->log_request_uploads($request);
2279 }
2280
2281 =head2 $c->log_response
2282
2283 Writes information about the response to the debug logs by calling
2284 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2285
2286 =cut
2287
2288 sub log_response {
2289     my $c = shift;
2290
2291     return unless $c->debug;
2292
2293     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2294     my $response = $dump->[1];
2295
2296     $c->log_response_status_line($response);
2297     $c->log_response_headers($response->headers);
2298 }
2299
2300 =head2 $c->log_response_status_line($response)
2301
2302 Writes one line of information about the response to the debug logs.  This includes:
2303
2304 =over 4
2305
2306 =item * Response status code
2307
2308 =item * Content-Type header (if present)
2309
2310 =item * Content-Length header (if present)
2311
2312 =back
2313
2314 =cut
2315
2316 sub log_response_status_line {
2317     my ($c, $response) = @_;
2318
2319     $c->log->debug(
2320         sprintf(
2321             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2322             $response->status                            || 'unknown',
2323             $response->headers->header('Content-Type')   || 'unknown',
2324             $response->headers->header('Content-Length') || 'unknown'
2325         )
2326     );
2327 }
2328
2329 =head2 $c->log_response_headers($headers);
2330
2331 Hook method which can be wrapped by plugins to log the response headers.
2332 No-op in the default implementation.
2333
2334 =cut
2335
2336 sub log_response_headers {}
2337
2338 =head2 $c->log_request_parameters( query => {}, body => {} )
2339
2340 Logs request parameters to debug logs
2341
2342 =cut
2343
2344 sub log_request_parameters {
2345     my $c          = shift;
2346     my %all_params = @_;
2347
2348     return unless $c->debug;
2349
2350     my $column_width = Catalyst::Utils::term_width() - 44;
2351     foreach my $type (qw(query body)) {
2352         my $params = $all_params{$type};
2353         next if ! keys %$params;
2354         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2355         for my $key ( sort keys %$params ) {
2356             my $param = $params->{$key};
2357             my $value = defined($param) ? $param : '';
2358             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2359         }
2360         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2361     }
2362 }
2363
2364 =head2 $c->log_request_uploads
2365
2366 Logs file uploads included in the request to the debug logs.
2367 The parameter name, filename, file type, and file size are all included in
2368 the debug logs.
2369
2370 =cut
2371
2372 sub log_request_uploads {
2373     my $c = shift;
2374     my $request = shift;
2375     return unless $c->debug;
2376     my $uploads = $request->uploads;
2377     if ( keys %$uploads ) {
2378         my $t = Text::SimpleTable->new(
2379             [ 12, 'Parameter' ],
2380             [ 26, 'Filename' ],
2381             [ 18, 'Type' ],
2382             [ 9,  'Size' ]
2383         );
2384         for my $key ( sort keys %$uploads ) {
2385             my $upload = $uploads->{$key};
2386             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2387                 $t->row( $key, $u->filename, $u->type, $u->size );
2388             }
2389         }
2390         $c->log->debug( "File Uploads are:\n" . $t->draw );
2391     }
2392 }
2393
2394 =head2 $c->log_request_headers($headers);
2395
2396 Hook method which can be wrapped by plugins to log the request headers.
2397 No-op in the default implementation.
2398
2399 =cut
2400
2401 sub log_request_headers {}
2402
2403 =head2 $c->log_headers($type => $headers)
2404
2405 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2406
2407 =cut
2408
2409 sub log_headers {
2410     my $c       = shift;
2411     my $type    = shift;
2412     my $headers = shift;    # an HTTP::Headers instance
2413
2414     return unless $c->debug;
2415
2416     my $column_width = Catalyst::Utils::term_width() - 28;
2417     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2418     $headers->scan(
2419         sub {
2420             my ( $name, $value ) = @_;
2421             $t->row( $name, $value );
2422         }
2423     );
2424     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2425 }
2426
2427
2428 =head2 $c->prepare_read
2429
2430 Prepares the input for reading.
2431
2432 =cut
2433
2434 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2435
2436 =head2 $c->prepare_request
2437
2438 Prepares the engine request.
2439
2440 =cut
2441
2442 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2443
2444 =head2 $c->prepare_uploads
2445
2446 Prepares uploads.
2447
2448 =cut
2449
2450 sub prepare_uploads {
2451     my $c = shift;
2452
2453     $c->engine->prepare_uploads( $c, @_ );
2454 }
2455
2456 =head2 $c->prepare_write
2457
2458 Prepares the output for writing.
2459
2460 =cut
2461
2462 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2463
2464 =head2 $c->request_class
2465
2466 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2467
2468 =head2 $c->response_class
2469
2470 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2471
2472 =head2 $c->read( [$maxlength] )
2473
2474 Reads a chunk of data from the request body. This method is designed to
2475 be used in a while loop, reading C<$maxlength> bytes on every call.
2476 C<$maxlength> defaults to the size of the request if not specified.
2477
2478 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2479 directly.
2480
2481 Warning: If you use read(), Catalyst will not process the body,
2482 so you will not be able to access POST parameters or file uploads via
2483 $c->request.  You must handle all body parsing yourself.
2484
2485 =cut
2486
2487 sub read { my $c = shift; return $c->request->read( @_ ) }
2488
2489 =head2 $c->run
2490
2491 Starts the engine.
2492
2493 =cut
2494
2495 sub run {
2496   my $app = shift;
2497   $app->_make_immutable_if_needed;
2498   $app->engine_loader->needs_psgi_engine_compat_hack ?
2499     $app->engine->run($app, @_) :
2500       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2501 }
2502
2503 sub _make_immutable_if_needed {
2504     my $class = shift;
2505     my $meta = find_meta($class);
2506     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2507     if (
2508         $meta->is_immutable
2509         && ! { $meta->immutable_options }->{replace_constructor}
2510         && $isa_ca
2511     ) {
2512         warn("You made your application class ($class) immutable, "
2513             . "but did not inline the\nconstructor. "
2514             . "This will break catalyst, as your app \@ISA "
2515             . "Class::Accessor(::Fast)?\nPlease pass "
2516             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2517     }
2518     unless ($meta->is_immutable) {
2519         # XXX - FIXME warning here as you should make your app immutable yourself.
2520         $meta->make_immutable(
2521             replace_constructor => 1,
2522         );
2523     }
2524 }
2525
2526 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2527
2528 Sets an action in a given namespace.
2529
2530 =cut
2531
2532 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2533
2534 =head2 $c->setup_actions($component)
2535
2536 Sets up actions for a component.
2537
2538 =cut
2539
2540 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2541
2542 =head2 $c->setup_components
2543
2544 This method is called internally to set up the application's components.
2545
2546 It finds modules by calling the L<locate_components> method, expands them to
2547 package names with the L<expand_component_module> method, and then installs
2548 each component into the application.
2549
2550 The C<setup_components> config option is passed to both of the above methods.
2551
2552 Installation of each component is performed by the L<setup_component> method,
2553 below.
2554
2555 =cut
2556
2557 sub setup_components {
2558     my $class = shift;
2559
2560     my $config  = $class->config->{ setup_components };
2561
2562     my @comps = $class->locate_components($config);
2563     my %comps = map { $_ => 1 } @comps;
2564
2565     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2566     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2567         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2568     ) if $deprecatedcatalyst_component_names;
2569
2570     for my $component ( @comps ) {
2571
2572         # We pass ignore_loaded here so that overlay files for (e.g.)
2573         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2574         # we know M::P::O found a file on disk so this is safe
2575
2576         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2577     }
2578
2579     for my $component (@comps) {
2580         my $instance = $class->components->{ $component } = $class->setup_component($component);
2581         my @expanded_components = $instance->can('expand_modules')
2582             ? $instance->expand_modules( $component, $config )
2583             : $class->expand_component_module( $component, $config );
2584         for my $component (@expanded_components) {
2585             next if $comps{$component};
2586             $class->components->{ $component } = $class->setup_component($component);
2587         }
2588     }
2589 }
2590
2591 =head2 $c->locate_components( $setup_component_config )
2592
2593 This method is meant to provide a list of component modules that should be
2594 setup for the application.  By default, it will use L<Module::Pluggable>.
2595
2596 Specify a C<setup_components> config option to pass additional options directly
2597 to L<Module::Pluggable>. To add additional search paths, specify a key named
2598 C<search_extra> as an array reference. Items in the array beginning with C<::>
2599 will have the application class name prepended to them.
2600
2601 =cut
2602
2603 sub locate_components {
2604     my $class  = shift;
2605     my $config = shift;
2606
2607     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2608     my $extra   = delete $config->{ search_extra } || [];
2609
2610     push @paths, @$extra;
2611
2612     my $locator = Module::Pluggable::Object->new(
2613         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2614         %$config
2615     );
2616
2617     # XXX think about ditching this sort entirely
2618     my @comps = sort { length $a <=> length $b } $locator->plugins;
2619
2620     return @comps;
2621 }
2622
2623 =head2 $c->expand_component_module( $component, $setup_component_config )
2624
2625 Components found by C<locate_components> will be passed to this method, which
2626 is expected to return a list of component (package) names to be set up.
2627
2628 =cut
2629
2630 sub expand_component_module {
2631     my ($class, $module) = @_;
2632     return Devel::InnerPackage::list_packages( $module );
2633 }
2634
2635 =head2 $c->setup_component
2636
2637 =cut
2638
2639 sub setup_component {
2640     my( $class, $component ) = @_;
2641
2642     unless ( $component->can( 'COMPONENT' ) ) {
2643         return $component;
2644     }
2645
2646     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2647     my $config = $class->config->{ $suffix } || {};
2648     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2649     # methods also pass it. local to avoid pointlessly shitting in config
2650     # for the debug screen, as $component is already the key name.
2651     local $config->{catalyst_component_name} = $component;
2652
2653     my $instance = eval { $component->COMPONENT( $class, $config ); };
2654
2655     if ( my $error = $@ ) {
2656         chomp $error;
2657         Catalyst::Exception->throw(
2658             message => qq/Couldn't instantiate component "$component", "$error"/
2659         );
2660     }
2661
2662     unless (blessed $instance) {
2663         my $metaclass = Moose::Util::find_meta($component);
2664         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2665         my $component_method_from = $method_meta->associated_metaclass->name;
2666         my $value = defined($instance) ? $instance : 'undef';
2667         Catalyst::Exception->throw(
2668             message =>
2669             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2670         );
2671     }
2672     return $instance;
2673 }
2674
2675 =head2 $c->setup_dispatcher
2676
2677 Sets up dispatcher.
2678
2679 =cut
2680
2681 sub setup_dispatcher {
2682     my ( $class, $dispatcher ) = @_;
2683
2684     if ($dispatcher) {
2685         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2686     }
2687
2688     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2689         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2690     }
2691
2692     unless ($dispatcher) {
2693         $dispatcher = $class->dispatcher_class;
2694     }
2695
2696     load_class($dispatcher);
2697
2698     # dispatcher instance
2699     $class->dispatcher( $dispatcher->new );
2700 }
2701
2702 =head2 $c->setup_engine
2703
2704 Sets up engine.
2705
2706 =cut
2707
2708 sub engine_class {
2709     my ($class, $requested_engine) = @_;
2710
2711     if (!$class->engine_loader || $requested_engine) {
2712         $class->engine_loader(
2713             Catalyst::EngineLoader->new({
2714                 application_name => $class,
2715                 (defined $requested_engine
2716                      ? (catalyst_engine_class => $requested_engine) : ()),
2717             }),
2718         );
2719     }
2720
2721     $class->engine_loader->catalyst_engine_class;
2722 }
2723
2724 sub setup_engine {
2725     my ($class, $requested_engine) = @_;
2726
2727     my $engine = do {
2728         my $loader = $class->engine_loader;
2729
2730         if (!$loader || $requested_engine) {
2731             $loader = Catalyst::EngineLoader->new({
2732                 application_name => $class,
2733                 (defined $requested_engine
2734                      ? (requested_engine => $requested_engine) : ()),
2735             }),
2736
2737             $class->engine_loader($loader);
2738         }
2739
2740         $loader->catalyst_engine_class;
2741     };
2742
2743     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2744     return if $class->loading_psgi_file;
2745
2746     load_class($engine);
2747
2748     if ($ENV{MOD_PERL}) {
2749         my $apache = $class->engine_loader->auto;
2750
2751         my $meta = find_meta($class);
2752         my $was_immutable = $meta->is_immutable;
2753         my %immutable_options = $meta->immutable_options;
2754         $meta->make_mutable if $was_immutable;
2755
2756         $meta->add_method(handler => sub {
2757             my $r = shift;
2758             my $psgi_app = $class->_finalized_psgi_app;
2759             $apache->call_app($r, $psgi_app);
2760         });
2761
2762         $meta->make_immutable(%immutable_options) if $was_immutable;
2763     }
2764
2765     $class->engine( $engine->new );
2766
2767     return;
2768 }
2769
2770 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2771 ## build in server support (back compat support for pre psgi port behavior).
2772 ## This is so that we don't build a new psgi app for each request when using
2773 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2774
2775 sub _finalized_psgi_app {
2776     my ($app) = @_;
2777
2778     unless ($app->_psgi_app) {
2779         my $psgi_app = $app->_setup_psgi_app;
2780         $app->_psgi_app($psgi_app);
2781     }
2782
2783     return $app->_psgi_app;
2784 }
2785
2786 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2787 ## home directory and load that and return it (just assume it is doing the
2788 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2789 ## in default_middleware and return it ( this is for backward compatibility
2790 ## with pre psgi port behavior ).
2791
2792 sub _setup_psgi_app {
2793     my ($app) = @_;
2794
2795     for my $home (Path::Class::Dir->new($app->config->{home})) {
2796         my $psgi_file = $home->file(
2797             Catalyst::Utils::appprefix($app) . '.psgi',
2798         );
2799
2800         next unless -e $psgi_file;
2801
2802         # If $psgi_file calls ->setup_engine, it's doing so to load
2803         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2804         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2805         # anyway. So set a flag (ick) that tells setup_engine not to populate
2806         # $c->engine or do any other things we might regret.
2807
2808         $app->loading_psgi_file(1);
2809         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2810         $app->loading_psgi_file(0);
2811
2812         return $psgi_app
2813             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2814
2815         warn <<"EOW";
2816 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2817
2818 Its content has been ignored. Please consult the Catalyst::Upgrading
2819 documentation on how to upgrade from Catalyst::Engine::PSGI.
2820 EOW
2821     }
2822
2823     return $app->apply_default_middlewares($app->psgi_app);
2824 }
2825
2826 =head2 $c->apply_default_middlewares
2827
2828 Adds the following L<Plack> middlewares to your application, since they are
2829 useful and commonly needed:
2830
2831 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2832 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2833 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2834 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2835 applied since this middleware is smart enough to conditionally apply itself).
2836
2837 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2838 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2839 $ENV{SCRIPT_NAME}
2840
2841 =cut
2842
2843
2844 sub apply_default_middlewares {
2845     my ($app, $psgi_app) = @_;
2846
2847     $psgi_app = Plack::Middleware::Conditional->wrap(
2848         $psgi_app,
2849         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2850         condition => sub {
2851             my ($env) = @_;
2852             return if $app->config->{ignore_frontend_proxy};
2853             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2854                 || $app->config->{using_frontend_proxy};
2855         },
2856     );
2857
2858     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2859     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2860     $psgi_app = Plack::Middleware::Conditional->wrap(
2861         $psgi_app,
2862         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2863         condition => sub {
2864             my ($env) = @_;
2865             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2866             return unless $1 < 4.23;
2867             1;
2868         },
2869     );
2870
2871     # we're applying this unconditionally as the middleware itself already makes
2872     # sure it doesn't fuck things up if it's not running under one of the right
2873     # IIS versions
2874     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2875
2876     # And another IIS issue, this time with IIS7.
2877     $psgi_app = Plack::Middleware::Conditional->wrap(
2878         $psgi_app,
2879         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2880         condition => sub {
2881             my ($env) = @_;
2882             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2883         },
2884     );
2885
2886     return $psgi_app;
2887 }
2888
2889 =head2 $c->psgi_app
2890
2891 Returns a PSGI application code reference for the catalyst application
2892 C<$c>. This is the bare application without any middlewares
2893 applied. C<${myapp}.psgi> is not taken into account.
2894
2895 This is what you want to be using to retrieve the PSGI application code
2896 reference of your Catalyst application for use in F<.psgi> files.
2897
2898 =cut
2899
2900 sub psgi_app {
2901     my ($app) = @_;
2902     my $psgi = $app->engine->build_psgi_app($app);
2903     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
2904 }
2905
2906 =head2 $c->setup_home
2907
2908 Sets up the home directory.
2909
2910 =cut
2911
2912 sub setup_home {
2913     my ( $class, $home ) = @_;
2914
2915     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2916         $home = $env;
2917     }
2918
2919     $home ||= Catalyst::Utils::home($class);
2920
2921     if ($home) {
2922         #I remember recently being scolded for assigning config values like this
2923         $class->config->{home} ||= $home;
2924         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2925     }
2926 }
2927
2928 =head2 $c->setup_log
2929
2930 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2931 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2932 log to.
2933
2934 This method also installs a C<debug> method that returns a true value into the
2935 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2936 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2937
2938 Note that if the log has already been setup, by either a previous call to
2939 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2940 that this method won't actually set up the log object.
2941
2942 =cut
2943
2944 sub setup_log {
2945     my ( $class, $levels ) = @_;
2946
2947     $levels ||= '';
2948     $levels =~ s/^\s+//;
2949     $levels =~ s/\s+$//;
2950     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2951
2952     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2953     if ( defined $env_debug ) {
2954         $levels{debug} = 1 if $env_debug; # Ugly!
2955         delete($levels{debug}) unless $env_debug;
2956     }
2957
2958     unless ( $class->log ) {
2959         $class->log( Catalyst::Log->new(keys %levels) );
2960     }
2961
2962     if ( $levels{debug} ) {
2963         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2964         $class->log->debug('Debug messages enabled');
2965     }
2966 }
2967
2968 =head2 $c->setup_plugins
2969
2970 Sets up plugins.
2971
2972 =cut
2973
2974 =head2 $c->setup_stats
2975
2976 Sets up timing statistics class.
2977
2978 =cut
2979
2980 sub setup_stats {
2981     my ( $class, $stats ) = @_;
2982
2983     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2984
2985     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2986     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2987         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2988         $class->log->debug('Statistics enabled');
2989     }
2990 }
2991
2992
2993 =head2 $c->registered_plugins
2994
2995 Returns a sorted list of the plugins which have either been stated in the
2996 import list.
2997
2998 If passed a given plugin name, it will report a boolean value indicating
2999 whether or not that plugin is loaded.  A fully qualified name is required if
3000 the plugin name does not begin with C<Catalyst::Plugin::>.
3001
3002  if ($c->registered_plugins('Some::Plugin')) {
3003      ...
3004  }
3005
3006 =cut
3007
3008 {
3009
3010     sub registered_plugins {
3011         my $proto = shift;
3012         return sort keys %{ $proto->_plugins } unless @_;
3013         my $plugin = shift;
3014         return 1 if exists $proto->_plugins->{$plugin};
3015         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3016     }
3017
3018     sub _register_plugin {
3019         my ( $proto, $plugin, $instant ) = @_;
3020         my $class = ref $proto || $proto;
3021
3022         load_class( $plugin );
3023         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3024             if $plugin->isa( 'Catalyst::Component' );
3025         my $plugin_meta = Moose::Meta::Class->create($plugin);
3026         if (!$plugin_meta->has_method('new')
3027             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3028             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3029         }
3030         if (!$instant && !$proto->_plugins->{$plugin}) {
3031             my $meta = Class::MOP::get_metaclass_by_name($class);
3032             $meta->superclasses($plugin, $meta->superclasses);
3033         }
3034         $proto->_plugins->{$plugin} = 1;
3035         return $class;
3036     }
3037
3038     sub _default_plugins { return qw(Unicode::Encoding) }
3039
3040     sub setup_plugins {
3041         my ( $class, $plugins ) = @_;
3042
3043         $class->_plugins( {} ) unless $class->_plugins;
3044         $plugins = [ grep {
3045             m/Unicode::Encoding/ ? do {
3046                 $class->log->warn(
3047                     'Unicode::Encoding plugin is auto-applied,'
3048                     . ' please remove this from your appclass'
3049                     . ' and make sure to define "encoding" config'
3050                 );
3051                 unless (exists $class->config->{'encoding'}) {
3052                   $class->config->{'encoding'} = 'UTF-8';
3053                 }
3054                 () }
3055                 : $_
3056         } @$plugins ];
3057         push @$plugins, $class->_default_plugins;
3058         $plugins = Data::OptList::mkopt($plugins || []);
3059
3060         my @plugins = map {
3061             [ Catalyst::Utils::resolve_namespace(
3062                   $class . '::Plugin',
3063                   'Catalyst::Plugin', $_->[0]
3064               ),
3065               $_->[1],
3066             ]
3067          } @{ $plugins };
3068
3069         for my $plugin ( reverse @plugins ) {
3070             load_class($plugin->[0], $plugin->[1]);
3071             my $meta = find_meta($plugin->[0]);
3072             next if $meta && $meta->isa('Moose::Meta::Role');
3073
3074             $class->_register_plugin($plugin->[0]);
3075         }
3076
3077         my @roles =
3078             map  { $_->[0]->name, $_->[1] }
3079             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3080             map  { [find_meta($_->[0]), $_->[1]] }
3081             @plugins;
3082
3083         Moose::Util::apply_all_roles(
3084             $class => @roles
3085         ) if @roles;
3086     }
3087 }
3088
3089 =head2 registered_middlewares
3090
3091 Read only accessor that returns an array of all the middleware in the order
3092 that they were added (which is the REVERSE of the order they will be applied).
3093
3094 The values returned will be either instances of L<Plack::Middleware> or of a
3095 compatible interface, or a coderef, which is assumed to be inlined middleware
3096
3097 =head2 setup_middleware (?@middleware)
3098
3099 Read configuration information stored in configuration key C<psgi_middleware> or
3100 from passed @args.
3101
3102 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3103 to use it to enable L<Plack::Middleware>
3104
3105 This method is automatically called during 'setup' of your application, so
3106 you really don't need to invoke it.
3107
3108 When we read middleware definitions from configuration, we reverse the list
3109 which sounds odd but is likely how you expect it to work if you have prior
3110 experience with L<Plack::Builder> or if you previously used the plugin
3111 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3112
3113 =cut
3114
3115 sub registered_middlewares {
3116     my $class = shift;
3117     if(my $middleware = $class->_psgi_middleware) {
3118         return @$middleware;
3119     } else {
3120         die "You cannot call ->registered_middlewares until middleware has been setup";
3121     }
3122 }
3123
3124 sub setup_middleware {
3125     my ($class, @middleware_definitions) = @_;
3126     push @middleware_definitions, reverse(
3127       @{$class->config->{'psgi_middleware'}||[]});
3128
3129     my @middleware = ();
3130     while(my $next = shift(@middleware_definitions)) {
3131         if(ref $next) {
3132             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3133                 push @middleware, $next;
3134             } elsif(ref $next eq 'CODE') {
3135                 push @middleware, $next;
3136             } elsif(ref $next eq 'HASH') {
3137                 my $namespace = shift @middleware_definitions;
3138                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3139                 push @middleware, $mw;
3140             } else {
3141               die "I can't handle middleware definition ${\ref $next}";
3142             }
3143         } else {
3144           my $mw = $class->Catalyst::Utils::build_middleware($next);
3145           push @middleware, $mw;
3146         }
3147     }
3148
3149     $class->_psgi_middleware(\@middleware);
3150 }
3151
3152 =head2 registered_data_handlers
3153
3154 A read only copy of registered Data Handlers returned as a Hash, where each key
3155 is a content type and each value is a subref that attempts to decode that content
3156 type.
3157
3158 =head2 setup_data_handlers (?@data_handler)
3159
3160 Read configuration information stored in configuration key C<data_handlers> or
3161 from passed @args.
3162
3163 See under L</CONFIGURATION> information regarding C<data_handlers>.
3164
3165 This method is automatically called during 'setup' of your application, so
3166 you really don't need to invoke it.
3167
3168 =head2 default_data_handlers
3169
3170 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3171 only two default data handlers, for 'application/json' and an alternative to
3172 'application/x-www-form-urlencoded' which supposed nested form parameters via
3173 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3174
3175 The 'application/json' data handler is used to parse incoming JSON into a Perl
3176 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3177 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3178 JSON decoder, and has the smallest dependency impact.
3179
3180 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3181 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3182 order to get the best performance.  You should add either to your dependency
3183 list (Makefile.PL, dist.ini, cpanfile, etc.)
3184
3185 =cut
3186
3187 sub registered_data_handlers {
3188     my $class = shift;
3189     if(my $data_handlers = $class->_data_handlers) {
3190         return %$data_handlers;
3191     } else {
3192         die "You cannot call ->registered_data_handlers until data_handers has been setup";
3193     }
3194 }
3195
3196 sub setup_data_handlers {
3197     my ($class, %data_handler_callbacks) = @_;
3198     %data_handler_callbacks = (
3199       %{$class->default_data_handlers},
3200       %{$class->config->{'data_handlers'}||+{}},
3201       %data_handler_callbacks);
3202
3203     $class->_data_handlers(\%data_handler_callbacks);
3204 }
3205
3206 sub default_data_handlers {
3207     my ($class) = @_;
3208     return +{
3209       'application/x-www-form-urlencoded' => sub {
3210           my ($fh, $req) = @_;
3211           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3212           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3213             ->can('build_cgi_struct')->($params);
3214       },
3215       'application/json' => sub {
3216           Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON')
3217             ->can('decode_json')->(do { local $/; $_->getline });
3218       },
3219     };
3220 }
3221
3222 =head2 $c->stack
3223
3224 Returns an arrayref of the internal execution stack (actions that are
3225 currently executing).
3226
3227 =head2 $c->stats
3228
3229 Returns the current timing statistics object. By default Catalyst uses
3230 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3231 L<< stats_class|/"$c->stats_class" >>.
3232
3233 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3234 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3235 profile explicitly, although MyApp.pm still won't profile nor output anything
3236 by itself.
3237
3238 =head2 $c->stats_class
3239
3240 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3241
3242 =head2 $c->use_stats
3243
3244 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3245
3246 Note that this is a static method, not an accessor and should be overridden
3247 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3248
3249 =cut
3250
3251 sub use_stats { 0 }
3252
3253
3254 =head2 $c->write( $data )
3255
3256 Writes $data to the output stream. When using this method directly, you
3257 will need to manually set the C<Content-Length> header to the length of
3258 your output data, if known.
3259
3260 =cut
3261
3262 sub write {
3263     my $c = shift;
3264
3265     # Finalize headers if someone manually writes output (for compat)
3266     $c->finalize_headers;
3267
3268     return $c->response->write( @_ );
3269 }
3270
3271 =head2 version
3272
3273 Returns the Catalyst version number. Mostly useful for "powered by"
3274 messages in template systems.
3275
3276 =cut
3277
3278 sub version { return $Catalyst::VERSION }
3279
3280 =head1 CONFIGURATION
3281
3282 There are a number of 'base' config variables which can be set:
3283
3284 =over
3285
3286 =item *
3287
3288 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3289
3290 =item *
3291
3292 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3293
3294 =item *
3295
3296 C<disable_component_resolution_regex_fallback> - Turns
3297 off the deprecated component resolution functionality so
3298 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3299 are called then regex search will not be attempted on string values and
3300 instead C<undef> will be returned.
3301
3302 =item *
3303
3304 C<home> - The application home directory. In an uninstalled application,
3305 this is the top level application directory. In an installed application,
3306 this will be the directory containing C<< MyApp.pm >>.
3307
3308 =item *
3309
3310 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3311
3312 =item *
3313
3314 C<name> - The name of the application in debug messages and the debug and
3315 welcome screens
3316
3317 =item *
3318
3319 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3320 until it is accessed. This allows you to (for example) check authentication (and reject
3321 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3322
3323 =item *
3324
3325 C<root> - The root directory for templates. Usually this is just a
3326 subdirectory of the home directory, but you can set it to change the
3327 templates to a different directory.
3328
3329 =item *
3330
3331 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3332 namespaces from which components will be loaded (and constructed and stored in
3333 C<< $c->components >>).
3334
3335 =item *
3336
3337 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3338 to be shown in hit debug tables in the test server.
3339
3340 =item *
3341
3342 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3343 variable should be used for determining the request path.
3344
3345 Most web server environments pass the requested path to the application using environment variables,
3346 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3347 exposed as C<< $c->request->base >>) and the request path below that base.
3348
3349 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3350 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3351
3352 =over
3353
3354 =item use_request_uri_for_path => 0
3355
3356 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3357 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3358 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3359 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3360
3361 However this method has the major disadvantage that it is impossible to correctly decode some elements
3362 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3363 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3364 can't distinguish / vs %2F in paths (in addition to other encoded values).
3365
3366 =item use_request_uri_for_path => 1
3367
3368 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3369 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3370 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3371
3372 Given that this method of path resolution is provably more correct, it is recommended that you use
3373 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3374 aware of the implications of not being able to handle encoded URI paths correctly.
3375
3376 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3377 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3378 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3379 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3380 C<< $c->request->base >> will be incorrect.
3381
3382 =back
3383
3384 =item *
3385
3386 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3387
3388 =item *
3389
3390 C<encoding> - See L</ENCODING>
3391
3392 =item *
3393
3394 C<abort_chain_on_error_fix>
3395
3396 When there is an error in an action chain, the default behavior is to continue
3397 processing the remaining actions and then catch the error upon chain end.  This
3398 can lead to running actions when the application is in an unexpected state.  If
3399 you have this issue, setting this config value to true will promptly exit a
3400 chain when there is an error raised in any action (thus terminating the chain
3401 early.)
3402
3403 use like:
3404
3405     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3406
3407 In the future this might become the default behavior.
3408
3409 =item *
3410
3411 C<use_hash_multivalue_in_request>
3412
3413 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3414 and C<parameters> return a hashref where values might be scalar or an arrayref
3415 depending on the incoming data.  In many cases this can be undesirable as it
3416 leads one to writing defensive code like the following:
3417
3418     my ($val) = ref($c->req->parameters->{a}) ?
3419       @{$c->req->parameters->{a}} :
3420         $c->req->parameters->{a};
3421
3422 Setting this configuration item to true will make L<Catalyst> populate the
3423 attributes underlying these methods with an instance of L<Hash::MultiValue>
3424 which is used by L<Plack::Request> and others to solve this very issue.  You
3425 may prefer this behavior to the default, if so enable this option (be warned
3426 if you enable it in a legacy application we are not sure if it is completely
3427 backwardly compatible).
3428
3429 =item *
3430
3431 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3432
3433 =item *
3434
3435 C<data_handlers> - See L<DATA HANDLERS>.
3436
3437 =back
3438
3439 =head1 INTERNAL ACTIONS
3440
3441 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3442 C<_ACTION>, and C<_END>. These are by default not shown in the private
3443 action table, but you can make them visible with a config parameter.
3444
3445     MyApp->config(show_internal_actions => 1);
3446
3447 =head1 ON-DEMAND PARSER
3448
3449 The request body is usually parsed at the beginning of a request,
3450 but if you want to handle input yourself, you can enable on-demand
3451 parsing with a config parameter.
3452
3453     MyApp->config(parse_on_demand => 1);
3454
3455 =head1 PROXY SUPPORT
3456
3457 Many production servers operate using the common double-server approach,
3458 with a lightweight frontend web server passing requests to a larger
3459 backend server. An application running on the backend server must deal
3460 with two problems: the remote user always appears to be C<127.0.0.1> and
3461 the server's hostname will appear to be C<localhost> regardless of the
3462 virtual host that the user connected through.
3463
3464 Catalyst will automatically detect this situation when you are running
3465 the frontend and backend servers on the same machine. The following
3466 changes are made to the request.
3467
3468     $c->req->address is set to the user's real IP address, as read from
3469     the HTTP X-Forwarded-For header.
3470
3471     The host value for $c->req->base and $c->req->uri is set to the real
3472     host, as read from the HTTP X-Forwarded-Host header.
3473
3474 Additionally, you may be running your backend application on an insecure
3475 connection (port 80) while your frontend proxy is running under SSL.  If there
3476 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3477 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3478 be created properly.
3479
3480 In the case of passing in:
3481
3482     X-Forwarded-Port: 443
3483
3484 All calls to C<uri_for> will result in an https link, as is expected.
3485
3486 Obviously, your web server must support these headers for this to work.
3487
3488 In a more complex server farm environment where you may have your
3489 frontend proxy server(s) on different machines, you will need to set a
3490 configuration option to tell Catalyst to read the proxied data from the
3491 headers.
3492
3493     MyApp->config(using_frontend_proxy => 1);
3494
3495 If you do not wish to use the proxy support at all, you may set:
3496
3497     MyApp->config(ignore_frontend_proxy => 0);
3498
3499 =head2 Note about psgi files
3500
3501 Note that if you supply your own .psgi file, calling
3502 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3503
3504 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3505 in your psgi, for example:
3506
3507     builder {
3508         enable "Plack::Middleware::ReverseProxy";
3509         MyApp->psgi_app
3510     };
3511
3512 This will unconditionally add the ReverseProxy support, or you need to call
3513 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3514 apply the support depending upon your config).
3515
3516 See L<Catalyst::PSGI> for more information.
3517
3518 =head1 THREAD SAFETY
3519
3520 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3521 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3522 believe the Catalyst core to be thread-safe.
3523
3524 If you plan to operate in a threaded environment, remember that all other
3525 modules you are using must also be thread-safe. Some modules, most notably
3526 L<DBD::SQLite>, are not thread-safe.
3527
3528 =head1 DATA HANDLERS
3529
3530 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3531 form parameters and URL search query fields.  However it has become common
3532 for various alternative content types to be PUT or POSTed to your controllers
3533 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3534 XML and other content types when communicating with an application server.  In
3535 order to better support this use case, L<Catalyst> defines a global configuration
3536 option, C<data_handlers>, which lets you associate a content type with a coderef
3537 that parses that content type into something Perl can readily access.
3538
3539     package MyApp::Web;
3540
3541     use Catalyst;
3542     use JSON::Maybe;
3543
3544     __PACKAGE__->config(
3545       data_handlers => {
3546         'application/json' => sub { local $/; decode_json $_->getline },
3547       },
3548       ## Any other configuration.
3549     );
3550
3551     __PACKAGE__->setup;
3552
3553 By default L<Catalyst> comes with a generic JSON data handler similar to the
3554 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3555 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3556 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3557 or dist.ini, cpanfile, etc.)
3558
3559 The C<data_handlers> configuation is a hashref whose keys are HTTP Content-Types
3560 (matched against the incoming request type using a regexp such as to be case
3561 insensitive) and whose values are coderefs that receive a localized version of
3562 C<$_> which is a filehandle object pointing to received body.
3563
3564 This feature is considered an early access release and we reserve the right
3565 to alter the interface in order to provide a performant and secure solution to
3566 alternative request body content.  Your reports welcomed!
3567
3568 =head1 PSGI MIDDLEWARE
3569
3570 You can define middleware, defined as L<Plack::Middleware> or a compatible
3571 interface in configuration.  Your middleware definitions are in the form of an
3572 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3573 with details to follow:
3574
3575     package MyApp::Web;
3576
3577     use Catalyst;
3578     use Plack::Middleware::StackTrace;
3579
3580     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3581
3582     __PACKAGE__->config(
3583       'psgi_middleware', [
3584         'Debug',
3585         '+MyApp::Custom',
3586         $stacktrace_middleware,
3587         'Session' => {store => 'File'},
3588         sub {
3589           my $app = shift;
3590           return sub {
3591             my $env = shift;
3592             $env->{myapp.customkey} = 'helloworld';
3593             $app->($env);
3594           },
3595         },
3596       ],
3597     );
3598
3599     __PACKAGE__->setup;
3600
3601 So the general form is:
3602
3603     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3604
3605 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3606 the order listed (to make it function similarly to L<Plack::Builder>:
3607
3608 =over 4
3609
3610 =item Middleware Object
3611
3612 An already initialized object that conforms to the L<Plack::Middleware>
3613 specification:
3614
3615     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3616
3617     __PACKAGE__->config(
3618       'psgi_middleware', [
3619         $stacktrace_middleware,
3620       ]);
3621
3622
3623 =item coderef
3624
3625 A coderef that is an inlined middleware:
3626
3627     __PACKAGE__->config(
3628       'psgi_middleware', [
3629         sub {
3630           my $app = shift;
3631           return sub {
3632             my $env = shift;
3633             if($env->{PATH_INFO} =~m/forced/) {
3634               Plack::App::File
3635                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3636                 ->call($env);
3637             } else {
3638               return $app->($env);
3639             }
3640          },
3641       },
3642     ]);
3643
3644
3645
3646 =item a scalar
3647
3648 We assume the scalar refers to a namespace after normalizing it using the
3649 following rules:
3650
3651 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3652 is assumed to be 'as is', and we just install and use the middleware.
3653
3654 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3655 (the package name of your Catalyst application subclass), we also assume then
3656 that it is a full namespace, and use it.
3657
3658 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3659 resolve it first by looking for it under your application namespace (for example
3660 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3661 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3662 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3663 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3664 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3665 you find that a good idea.
3666
3667 Examples:
3668
3669     package MyApp::Web;
3670
3671     __PACKAGE__->config(
3672       'psgi_middleware', [
3673         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3674         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3675         '+MyApp::Custom',  ## MyApp::Custom->wrap
3676       ],
3677     );
3678
3679 =item a scalar followed by a hashref
3680
3681 Just like the previous, except the following C<HashRef> is used as arguments
3682 to initialize the middleware object.
3683
3684     __PACKAGE__->config(
3685       'psgi_middleware', [
3686          'Session' => {store => 'File'},
3687     ]);
3688
3689 =back
3690
3691 Please see L<PSGI> for more on middleware.
3692
3693 =head1 ENCODING
3694
3695 On request, decodes all params from encoding into a sequence of
3696 logical characters. On response, encodes body into encoding.
3697
3698 =head2 Methods
3699
3700 =over 4
3701
3702 =item encoding
3703
3704 Returns an instance of an C<Encode> encoding
3705
3706     print $c->encoding->name
3707
3708 =item handle_unicode_encoding_exception ($exception_context)
3709
3710 Method called when decoding process for a request fails.
3711
3712 An C<$exception_context> hashref is provided to allow you to override the
3713 behaviour of your application when given data with incorrect encodings.
3714
3715 The default method throws exceptions in the case of invalid request parameters
3716 (resulting in a 500 error), but ignores errors in upload filenames.
3717
3718 The keys passed in the C<$exception_context> hash are:
3719
3720 =over
3721
3722 =item param_value
3723
3724 The value which was not able to be decoded.
3725
3726 =item error_msg
3727
3728 The exception received from L<Encode>.
3729
3730 =item encoding_step
3731
3732 What type of data was being decoded. Valid values are (currently)
3733 C<params> - for request parameters / arguments / captures
3734 and C<uploads> - for request upload filenames.
3735
3736 =back
3737
3738 =back
3739
3740 =head1 SUPPORT
3741
3742 IRC:
3743
3744     Join #catalyst on irc.perl.org.
3745
3746 Mailing Lists:
3747
3748     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3749     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3750
3751 Web:
3752
3753     http://catalyst.perl.org
3754
3755 Wiki:
3756
3757     http://dev.catalyst.perl.org
3758
3759 =head1 SEE ALSO
3760
3761 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3762
3763 =head2 L<Catalyst::Manual> - The Catalyst Manual
3764
3765 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3766
3767 =head2 L<Catalyst::Engine> - Core engine
3768
3769 =head2 L<Catalyst::Log> - Log class.
3770
3771 =head2 L<Catalyst::Request> - Request object
3772
3773 =head2 L<Catalyst::Response> - Response object
3774
3775 =head2 L<Catalyst::Test> - The test suite.
3776
3777 =head1 PROJECT FOUNDER
3778
3779 sri: Sebastian Riedel <sri@cpan.org>
3780
3781 =head1 CONTRIBUTORS
3782
3783 abw: Andy Wardley
3784
3785 acme: Leon Brocard <leon@astray.com>
3786
3787 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3788
3789 Andrew Bramble
3790
3791 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3792
3793 Andrew Ruthven
3794
3795 andyg: Andy Grundman <andy@hybridized.org>
3796
3797 audreyt: Audrey Tang
3798
3799 bricas: Brian Cassidy <bricas@cpan.org>
3800
3801 Caelum: Rafael Kitover <rkitover@io.com>
3802
3803 chansen: Christian Hansen
3804
3805 chicks: Christopher Hicks
3806
3807 Chisel Wright C<pause@herlpacker.co.uk>
3808
3809 Danijel Milicevic C<me@danijel.de>
3810
3811 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3812
3813 David Naughton, C<naughton@umn.edu>
3814
3815 David E. Wheeler
3816
3817 dhoss: Devin Austin <dhoss@cpan.org>
3818
3819 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3820
3821 Drew Taylor
3822
3823 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3824
3825 esskar: Sascha Kiefer
3826
3827 fireartist: Carl Franks <cfranks@cpan.org>
3828
3829 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3830
3831 gabb: Danijel Milicevic
3832
3833 Gary Ashton Jones
3834
3835 Gavin Henry C<ghenry@perl.me.uk>
3836
3837 Geoff Richards
3838
3839 groditi: Guillermo Roditi <groditi@gmail.com>
3840
3841 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3842
3843 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3844
3845 jcamacho: Juan Camacho
3846
3847 jester: Jesse Sheidlower C<jester@panix.com>
3848
3849 jhannah: Jay Hannah <jay@jays.net>
3850
3851 Jody Belka
3852
3853 Johan Lindstrom
3854
3855 jon: Jon Schutz <jjschutz@cpan.org>
3856
3857 Jonathan Rockway C<< <jrockway@cpan.org> >>
3858
3859 Kieren Diment C<kd@totaldatasolution.com>
3860
3861 konobi: Scott McWhirter <konobi@cpan.org>
3862
3863 marcus: Marcus Ramberg <mramberg@cpan.org>
3864
3865 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3866
3867 mgrimes: Mark Grimes <mgrimes@cpan.org>
3868
3869 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3870
3871 mugwump: Sam Vilain
3872
3873 naughton: David Naughton
3874
3875 ningu: David Kamholz <dkamholz@cpan.org>
3876
3877 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3878
3879 numa: Dan Sully <daniel@cpan.org>
3880
3881 obra: Jesse Vincent
3882
3883 Octavian Rasnita
3884
3885 omega: Andreas Marienborg
3886
3887 Oleg Kostyuk <cub.uanic@gmail.com>
3888
3889 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3890
3891 rafl: Florian Ragwitz <rafl@debian.org>
3892
3893 random: Roland Lammel <lammel@cpan.org>
3894
3895 Robert Sedlacek C<< <rs@474.at> >>
3896
3897 SpiceMan: Marcel Montes
3898
3899 sky: Arthur Bergman
3900
3901 szbalint: Balint Szilakszi <szbalint@cpan.org>
3902
3903 t0m: Tomas Doran <bobtfish@bobtfish.net>
3904
3905 Ulf Edvinsson
3906
3907 Viljo Marrandi C<vilts@yahoo.com>
3908
3909 Will Hawes C<info@whawes.co.uk>
3910
3911 willert: Sebastian Willert <willert@cpan.org>
3912
3913 wreis: Wallace Reis <wreis@cpan.org>
3914
3915 Yuval Kogman, C<nothingmuch@woobling.org>
3916
3917 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3918
3919 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3920
3921 =head1 COPYRIGHT
3922
3923 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3924
3925 =head1 LICENSE
3926
3927 This library is free software. You can redistribute it and/or modify it under
3928 the same terms as Perl itself.
3929
3930 =cut
3931
3932 no Moose;
3933
3934 __PACKAGE__->meta->make_immutable;
3935
3936 1;