lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken blessed/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp shortmess/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 __PACKAGE__->mk_accessors(
  34     qw/counter request response state action stack namespace stats/
  35 );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52 our $GO        = "catalyst_go\n";
  53
  54 __PACKAGE__->mk_classdata($_)
  55   for qw/components arguments dispatcher engine log dispatcher_class
  56   engine_class context_class request_class response_class stats_class
  57   setup_finished/;
  58
  59 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  60 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  61 __PACKAGE__->request_class('Catalyst::Request');
  62 __PACKAGE__->response_class('Catalyst::Response');
  63 __PACKAGE__->stats_class('Catalyst::Stats');
  64
  65 # Remember to update this in Catalyst::Runtime as well!
  66
  67 our $VERSION = '5.7099_04';
  68
  69 sub import {
  70     my ( $class, @arguments ) = @_;
  71
  72     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  73     # callers @ISA.
  74     return unless $class eq 'Catalyst';
  75
  76     my $caller = caller(0);
  77
  78     unless ( $caller->isa('Catalyst') ) {
  79         no strict 'refs';
  80         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  81     }
  82
  83     $caller->arguments( [@arguments] );
  84     $caller->setup_home;
  85 }
  86
  87 =head1 NAME
  88
  89 Catalyst - The Elegant MVC Web Application Framework
  90
  91 =head1 SYNOPSIS
  92
  93 See the L<Catalyst::Manual> distribution for comprehensive
  94 documentation and tutorials.
  95
  96     # Install Catalyst::Devel for helpers and other development tools
  97     # use the helper to create a new application
  98     catalyst.pl MyApp
  99
 100     # add models, views, controllers
 101     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 102     script/myapp_create.pl view MyTemplate TT
 103     script/myapp_create.pl controller Search
 104
 105     # built in testserver -- use -r to restart automatically on changes
 106     # --help to see all available options
 107     script/myapp_server.pl
 108
 109     # command line testing interface
 110     script/myapp_test.pl /yada
 111
 112     ### in lib/MyApp.pm
 113     use Catalyst qw/-Debug/; # include plugins here as well
 114
 115     ### In lib/MyApp/Controller/Root.pm (autocreated)
 116     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 117         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 118         $c->stash->{template} = 'foo.tt'; # set the template
 119         # lookup something from db -- stash vars are passed to TT
 120         $c->stash->{data} =
 121           $c->model('Database::Foo')->search( { country => $args[0] } );
 122         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 123             $c->forward( 'bar' ); # process another action
 124             # do something else after forward returns
 125         }
 126     }
 127
 128     # The foo.tt TT template can use the stash data from the database
 129     [% WHILE (item = data.next) %]
 130         [% item.foo %]
 131     [% END %]
 132
 133     # called for /bar/of/soap, /bar/of/soap/10, etc.
 134     sub bar : Path('/bar/of/soap') { ... }
 135
 136     # called for all actions, from the top-most controller downwards
 137     sub auto : Private {
 138         my ( $self, $c ) = @_;
 139         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 140             $c->res->redirect( '/login' ); # require login
 141             return 0; # abort request and go immediately to end()
 142         }
 143         return 1; # success; carry on to next action
 144     }
 145
 146     # called after all actions are finished
 147     sub end : Private {
 148         my ( $self, $c ) = @_;
 149         if ( scalar @{ $c->error } ) { ... } # handle errors
 150         return if $c->res->body; # already have a response
 151         $c->forward( 'MyApp::View::TT' ); # render template
 152     }
 153
 154     ### in MyApp/Controller/Foo.pm
 155     # called for /foo/bar
 156     sub bar : Local { ... }
 157
 158     # called for /blargle
 159     sub blargle : Global { ... }
 160
 161     # an index action matches /foo, but not /foo/1, etc.
 162     sub index : Private { ... }
 163
 164     ### in MyApp/Controller/Foo/Bar.pm
 165     # called for /foo/bar/baz
 166     sub baz : Local { ... }
 167
 168     # first Root auto is called, then Foo auto, then this
 169     sub auto : Private { ... }
 170
 171     # powerful regular expression paths are also possible
 172     sub details : Regex('^product/(\w+)/details$') {
 173         my ( $self, $c ) = @_;
 174         # extract the (\w+) from the URI
 175         my $product = $c->req->captures->[0];
 176     }
 177
 178 See L<Catalyst::Manual::Intro> for additional information.
 179
 180 =head1 DESCRIPTION
 181
 182 Catalyst is a modern framework for making web applications without the
 183 pain usually associated with this process. This document is a reference
 184 to the main Catalyst application. If you are a new user, we suggest you
 185 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 186
 187 See L<Catalyst::Manual> for more documentation.
 188
 189 Catalyst plugins can be loaded by naming them as arguments to the "use
 190 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 191 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 192 C<My::Module>.
 193
 194     use Catalyst qw/My::Module/;
 195
 196 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 197 fully qualify the name by using a unary plus:
 198
 199     use Catalyst qw/
 200         My::Module
 201         +Fully::Qualified::Plugin::Name
 202     /;
 203
 204 Special flags like C<-Debug> and C<-Engine> can also be specified as
 205 arguments when Catalyst is loaded:
 206
 207     use Catalyst qw/-Debug My::Module/;
 208
 209 The position of plugins and flags in the chain is important, because
 210 they are loaded in the order in which they appear.
 211
 212 The following flags are supported:
 213
 214 =head2 -Debug
 215
 216 Enables debug output. You can also force this setting from the system
 217 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 218 settings override the application, with <MYAPP>_DEBUG having the highest
 219 priority.
 220
 221 =head2 -Engine
 222
 223 Forces Catalyst to use a specific engine. Omit the
 224 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 225
 226     use Catalyst qw/-Engine=CGI/;
 227
 228 =head2 -Home
 229
 230 Forces Catalyst to use a specific home directory, e.g.:
 231
 232     use Catalyst qw[-Home=/usr/mst];
 233
 234 This can also be done in the shell environment by setting either the
 235 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 236 is replaced with the uppercased name of your application, any "::" in
 237 the name will be replaced with underscores, e.g. MyApp::Web should use
 238 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 239
 240 =head2 -Log
 241
 242 Specifies log level.
 243
 244 =head2 -Stats
 245
 246 Enables statistics collection and reporting. You can also force this setting
 247 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 248 environment settings override the application, with <MYAPP>_STATS having the
 249 highest priority.
 250
 251 e.g.
 252
 253    use Catalyst qw/-Stats=1/
 254
 255 =head1 METHODS
 256
 257 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 258
 259 =head2 $c->action
 260
 261 Returns a L<Catalyst::Action> object for the current action, which
 262 stringifies to the action name. See L<Catalyst::Action>.
 263
 264 =head2 $c->namespace
 265
 266 Returns the namespace of the current action, i.e., the URI prefix
 267 corresponding to the controller of the current action. For example:
 268
 269     # in Controller::Foo::Bar
 270     $c->namespace; # returns 'foo/bar';
 271
 272 =head2 $c->request
 273
 274 =head2 $c->req
 275
 276 Returns the current L<Catalyst::Request> object, giving access to
 277 information about the current client request (including parameters,
 278 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 279
 280 =head2 REQUEST FLOW HANDLING
 281
 282 =head2 $c->forward( $action [, \@arguments ] )
 283
 284 =head2 $c->forward( $class, $method, [, \@arguments ] )
 285
 286 Forwards processing to another action, by its private name. If you give a
 287 class name but no method, C<process()> is called. You may also optionally
 288 pass arguments in an arrayref. The action will receive the arguments in
 289 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 290 C<< $c->req->args >> will be restored to the previous values.
 291
 292 Any data C<return>ed from the action forwarded to, will be returned by the
 293 call to forward.
 294
 295     my $foodata = $c->forward('/foo');
 296     $c->forward('index');
 297     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 298     $c->forward('MyApp::View::TT');
 299
 300 Note that forward implies an C<<eval { }>> around the call (actually
 301 C<execute> does), thus de-fatalizing all 'dies' within the called
 302 action. If you want C<die> to propagate you need to do something like:
 303
 304     $c->forward('foo');
 305     die $c->error if $c->error;
 306
 307 Or make sure to always return true values from your actions and write
 308 your code like this:
 309
 310     $c->forward('foo') || return;
 311
 312 =cut
 313
 314 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 315
 316 =head2 $c->detach( $action [, \@arguments ] )
 317
 318 =head2 $c->detach( $class, $method, [, \@arguments ] )
 319
 320 =head2 $c->detach()
 321
 322 The same as C<forward>, but doesn't return to the previous action when
 323 processing is finished.
 324
 325 When called with no arguments it escapes the processing chain entirely.
 326
 327 =cut
 328
 329 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 330
 331 =head2 $c->visit( $action [, \@arguments ] )
 332
 333 =head2 $c->visit( $class, $method, [, \@arguments ] )
 334
 335 Almost the same as C<forward>, but does a full dispatch, instead of just
 336 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 337 C<auto> and the method you go to are called, just like a new request.
 338
 339 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 340 This means, for example, that $c->action methods such as C<name>, C<class> and
 341 C<reverse> return information for the visited action when they are invoked
 342 within the visited action.  This is different from the behavior of C<forward>
 343 which continues to use the $c->action object from the caller action even when
 344 invoked from the callee.
 345
 346 C<$c-E<gt>stash> is kept unchanged.
 347
 348 In effect, C<visit> allows you to "wrap" another action, just as it
 349 would have been called by dispatching from a URL, while the analogous
 350 C<go> allows you to transfer control to another action as if it had
 351 been reached directly from a URL.
 352
 353 =cut
 354
 355 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 356
 357 =head2 $c->go( $action [, \@arguments ] )
 358
 359 =head2 $c->go( $class, $method, [, \@arguments ] )
 360
 361 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 362 instead of just calling the new C<$action> /
 363 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 364 method you visit are called, just like a new request.
 365
 366 C<$c-E<gt>stash> is kept unchanged.
 367
 368 =cut
 369
 370 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 371
 372 =head2 $c->response
 373
 374 =head2 $c->res
 375
 376 Returns the current L<Catalyst::Response> object, see there for details.
 377
 378 =head2 $c->stash
 379
 380 Returns a hashref to the stash, which may be used to store data and pass
 381 it between components during a request. You can also set hash keys by
 382 passing arguments. The stash is automatically sent to the view. The
 383 stash is cleared at the end of a request; it cannot be used for
 384 persistent storage (for this you must use a session; see
 385 L<Catalyst::Plugin::Session> for a complete system integrated with
 386 Catalyst).
 387
 388     $c->stash->{foo} = $bar;
 389     $c->stash( { moose => 'majestic', qux => 0 } );
 390     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 391
 392     # stash is automatically passed to the view for use in a template
 393     $c->forward( 'MyApp::View::TT' );
 394
 395 =cut
 396
 397 sub stash {
 398     my $c = shift;
 399     if (@_) {
 400         my $stash = @_ > 1 ? {@_} : $_[0];
 401         croak('stash takes a hash or hashref') unless ref $stash;
 402         foreach my $key ( keys %$stash ) {
 403             $c->{stash}->{$key} = $stash->{$key};
 404         }
 405     }
 406     return $c->{stash};
 407 }
 408
 409 =head2 $c->error
 410
 411 =head2 $c->error($error, ...)
 412
 413 =head2 $c->error($arrayref)
 414
 415 Returns an arrayref containing error messages.  If Catalyst encounters an
 416 error while processing a request, it stores the error in $c->error.  This
 417 method should only be used to store fatal error messages.
 418
 419     my @error = @{ $c->error };
 420
 421 Add a new error.
 422
 423     $c->error('Something bad happened');
 424
 425 =cut
 426
 427 sub error {
 428     my $c = shift;
 429     if ( $_[0] ) {
 430         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 431         croak @$error unless ref $c;
 432         push @{ $c->{error} }, @$error;
 433     }
 434     elsif ( defined $_[0] ) { $c->{error} = undef }
 435     return $c->{error} || [];
 436 }
 437
 438
 439 =head2 $c->state
 440
 441 Contains the return value of the last executed action.
 442
 443 =head2 $c->clear_errors
 444
 445 Clear errors.  You probably don't want to clear the errors unless you are
 446 implementing a custom error screen.
 447
 448 This is equivalent to running
 449
 450     $c->error(0);
 451
 452 =cut
 453
 454 sub clear_errors {
 455     my $c = shift;
 456     $c->error(0);
 457 }
 458
 459 # search components given a name and some prefixes
 460 sub _comp_search_prefixes {
 461     my ( $c, $name, @prefixes ) = @_;
 462     my $appclass = ref $c || $c;
 463     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 464
 465     # map the original component name to the sub part that we will search against
 466     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 467         grep { /$filter/ } keys %{ $c->components };
 468
 469     # undef for a name will return all
 470     return keys %eligible if !defined $name;
 471
 472     my $query  = ref $name ? $name : qr/^$name$/i;
 473     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 474
 475     return map { $c->components->{ $_ } } @result if @result;
 476
 477     # if we were given a regexp to search against, we're done.
 478     return if ref $name;
 479
 480     # regexp fallback
 481     $query  = qr/$name/i;
 482     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 483
 484     # no results? try against full names
 485     if( !@result ) {
 486         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 487     }
 488
 489     # don't warn if we didn't find any results, it just might not exist
 490     if( @result ) {
 491         my $msg = "Used regexp fallback for \$c->model('${name}'), which found '" .
 492            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 493            "component resolution is unreliable and unsafe.";
 494         my $short = $result[0];
 495         $short =~ s/.*?Model:://;
 496         my $shortmess = Carp::shortmess('');
 497         if ($shortmess =~ m#Catalyst/Plugin#) {
 498            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 499               "plugin's config";
 500         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 501            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 502               "component's config";
 503         } else {
 504            $msg .= " You probably meant \$c->model('$short') instead of \$c->model{'${name}'}, " .
 505               "but if you really wanted to search, pass in a regexp as the argument " .
 506               "like so: \$c->model(qr/${name}/)";
 507         }
 508         $c->log->warn( "${msg}$shortmess" );
 509     }
 510
 511     return @result;
 512 }
 513
 514 # Find possible names for a prefix
 515 sub _comp_names {
 516     my ( $c, @prefixes ) = @_;
 517     my $appclass = ref $c || $c;
 518
 519     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 520
 521     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 522     return @names;
 523 }
 524
 525 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 526 sub _filter_component {
 527     my ( $c, $comp, @args ) = @_;
 528
 529     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 530         return $comp->ACCEPT_CONTEXT( $c, @args );
 531     }
 532
 533     return $comp;
 534 }
 535
 536 =head2 COMPONENT ACCESSORS
 537
 538 =head2 $c->controller($name)
 539
 540 Gets a L<Catalyst::Controller> instance by name.
 541
 542     $c->controller('Foo')->do_stuff;
 543
 544 If the name is omitted, will return the controller for the dispatched
 545 action.
 546
 547 If you want to search for controllers, pass in a regexp as the argument.
 548
 549     # find all controllers that start with Foo
 550     my @foo_controllers = $c->controller(qr{^Foo});
 551
 552
 553 =cut
 554
 555 sub controller {
 556     my ( $c, $name, @args ) = @_;
 557
 558     if( $name ) {
 559         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 560         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 561         return $c->_filter_component( $result[ 0 ], @args );
 562     }
 563
 564     return $c->component( $c->action->class );
 565 }
 566
 567 =head2 $c->model($name)
 568
 569 Gets a L<Catalyst::Model> instance by name.
 570
 571     $c->model('Foo')->do_stuff;
 572
 573 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 574
 575 If the name is omitted, it will look for
 576  - a model object in $c->stash->{current_model_instance}, then
 577  - a model name in $c->stash->{current_model}, then
 578  - a config setting 'default_model', or
 579  - check if there is only one model, and return it if that's the case.
 580
 581 If you want to search for models, pass in a regexp as the argument.
 582
 583     # find all models that start with Foo
 584     my @foo_models = $c->model(qr{^Foo});
 585
 586 =cut
 587
 588 sub model {
 589     my ( $c, $name, @args ) = @_;
 590
 591     if( $name ) {
 592         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 593         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 594         return $c->_filter_component( $result[ 0 ], @args );
 595     }
 596
 597     if (ref $c) {
 598         return $c->stash->{current_model_instance}
 599           if $c->stash->{current_model_instance};
 600         return $c->model( $c->stash->{current_model} )
 601           if $c->stash->{current_model};
 602     }
 603     return $c->model( $c->config->{default_model} )
 604       if $c->config->{default_model};
 605
 606     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 607
 608     if( $rest ) {
 609         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 610         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 611         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 612         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 613         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 614     }
 615
 616     return $c->_filter_component( $comp );
 617 }
 618
 619
 620 =head2 $c->view($name)
 621
 622 Gets a L<Catalyst::View> instance by name.
 623
 624     $c->view('Foo')->do_stuff;
 625
 626 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 627
 628 If the name is omitted, it will look for
 629  - a view object in $c->stash->{current_view_instance}, then
 630  - a view name in $c->stash->{current_view}, then
 631  - a config setting 'default_view', or
 632  - check if there is only one view, and return it if that's the case.
 633
 634 If you want to search for views, pass in a regexp as the argument.
 635
 636     # find all views that start with Foo
 637     my @foo_views = $c->view(qr{^Foo});
 638
 639 =cut
 640
 641 sub view {
 642     my ( $c, $name, @args ) = @_;
 643
 644     if( $name ) {
 645         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 646         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 647         return $c->_filter_component( $result[ 0 ], @args );
 648     }
 649
 650     if (ref $c) {
 651         return $c->stash->{current_view_instance}
 652           if $c->stash->{current_view_instance};
 653         return $c->view( $c->stash->{current_view} )
 654           if $c->stash->{current_view};
 655     }
 656     return $c->view( $c->config->{default_view} )
 657       if $c->config->{default_view};
 658
 659     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 660
 661     if( $rest ) {
 662         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 663         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 664         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 665         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 666         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 667     }
 668
 669     return $c->_filter_component( $comp );
 670 }
 671
 672 =head2 $c->controllers
 673
 674 Returns the available names which can be passed to $c->controller
 675
 676 =cut
 677
 678 sub controllers {
 679     my ( $c ) = @_;
 680     return $c->_comp_names(qw/Controller C/);
 681 }
 682
 683 =head2 $c->models
 684
 685 Returns the available names which can be passed to $c->model
 686
 687 =cut
 688
 689 sub models {
 690     my ( $c ) = @_;
 691     return $c->_comp_names(qw/Model M/);
 692 }
 693
 694
 695 =head2 $c->views
 696
 697 Returns the available names which can be passed to $c->view
 698
 699 =cut
 700
 701 sub views {
 702     my ( $c ) = @_;
 703     return $c->_comp_names(qw/View V/);
 704 }
 705
 706 =head2 $c->comp($name)
 707
 708 =head2 $c->component($name)
 709
 710 Gets a component object by name. This method is not recommended,
 711 unless you want to get a specific component by full
 712 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 713 should be used instead.
 714
 715 If C<$name> is a regexp, a list of components matched against the full
 716 component name will be returned.
 717
 718 =cut
 719
 720 sub component {
 721     my ( $c, $name, @args ) = @_;
 722
 723     if( $name ) {
 724         my $comps = $c->components;
 725
 726         if( !ref $name ) {
 727             # is it the exact name?
 728             return $c->_filter_component( $comps->{ $name }, @args )
 729                        if exists $comps->{ $name };
 730
 731             # perhaps we just omitted "MyApp"?
 732             my $composed = ( ref $c || $c ) . "::${name}";
 733             return $c->_filter_component( $comps->{ $composed }, @args )
 734                        if exists $comps->{ $composed };
 735
 736             # search all of the models, views and controllers
 737             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 738             return $c->_filter_component( $comp, @args ) if $comp;
 739         }
 740
 741         # This is here so $c->comp( '::M::' ) works
 742         my $query = ref $name ? $name : qr{$name}i;
 743
 744         my @result = grep { m{$query} } keys %{ $c->components };
 745         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 746
 747         if( $result[ 0 ] ) {
 748             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 749             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 750             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 751             return $c->_filter_component( $result[ 0 ], @args );
 752         }
 753
 754         # I would expect to return an empty list here, but that breaks back-compat
 755     }
 756
 757     # fallback
 758     return sort keys %{ $c->components };
 759 }
 760
 761 =head2 CLASS DATA AND HELPER CLASSES
 762
 763 =head2 $c->config
 764
 765 Returns or takes a hashref containing the application's configuration.
 766
 767     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 768
 769 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 770 like myapp.yml in your applications home directory. See
 771 L<Catalyst::Plugin::ConfigLoader>.
 772
 773     ---
 774     db: dsn:SQLite:foo.db
 775
 776
 777 =cut
 778
 779 sub config {
 780     my $c = shift;
 781
 782     $c->log->warn("Setting config after setup has been run is not a good idea.")
 783       if ( @_ and $c->setup_finished );
 784
 785     $c->NEXT::config(@_);
 786 }
 787
 788 =head2 $c->log
 789
 790 Returns the logging object instance. Unless it is already set, Catalyst
 791 sets this up with a L<Catalyst::Log> object. To use your own log class,
 792 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 793 C<< __PACKAGE__->setup >>.
 794
 795  __PACKAGE__->log( MyLogger->new );
 796  __PACKAGE__->setup;
 797
 798 And later:
 799
 800     $c->log->info( 'Now logging with my own logger!' );
 801
 802 Your log class should implement the methods described in
 803 L<Catalyst::Log>.
 804
 805
 806 =head2 $c->debug
 807
 808 Overload to enable debug messages (same as -Debug option).
 809
 810 Note that this is a static method, not an accessor and should be overloaded
 811 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 812
 813 =cut
 814
 815 sub debug { 0 }
 816
 817 =head2 $c->dispatcher
 818
 819 Returns the dispatcher instance. Stringifies to class name. See
 820 L<Catalyst::Dispatcher>.
 821
 822 =head2 $c->engine
 823
 824 Returns the engine instance. Stringifies to the class name. See
 825 L<Catalyst::Engine>.
 826
 827
 828 =head2 UTILITY METHODS
 829
 830 =head2 $c->path_to(@path)
 831
 832 Merges C<@path> with C<< $c->config->{home} >> and returns a
 833 L<Path::Class::Dir> object.
 834
 835 For example:
 836
 837     $c->path_to( 'db', 'sqlite.db' );
 838
 839 =cut
 840
 841 sub path_to {
 842     my ( $c, @path ) = @_;
 843     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 844     if ( -d $path ) { return $path }
 845     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 846 }
 847
 848 =head2 $c->plugin( $name, $class, @args )
 849
 850 Helper method for plugins. It creates a classdata accessor/mutator and
 851 loads and instantiates the given class.
 852
 853     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 854
 855     $c->prototype->define_javascript_functions;
 856
 857 =cut
 858
 859 sub plugin {
 860     my ( $class, $name, $plugin, @args ) = @_;
 861     $class->_register_plugin( $plugin, 1 );
 862
 863     eval { $plugin->import };
 864     $class->mk_classdata($name);
 865     my $obj;
 866     eval { $obj = $plugin->new(@args) };
 867
 868     if ($@) {
 869         Catalyst::Exception->throw( message =>
 870               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 871     }
 872
 873     $class->$name($obj);
 874     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 875       if $class->debug;
 876 }
 877
 878 =head2 MyApp->setup
 879
 880 Initializes the dispatcher and engine, loads any plugins, and loads the
 881 model, view, and controller components. You may also specify an array
 882 of plugins to load here, if you choose to not load them in the C<use
 883 Catalyst> line.
 884
 885     MyApp->setup;
 886     MyApp->setup( qw/-Debug/ );
 887
 888 =cut
 889
 890 sub setup {
 891     my ( $class, @arguments ) = @_;
 892
 893     $class->log->warn("Running setup twice is not a good idea.")
 894       if ( $class->setup_finished );
 895
 896     unless ( $class->isa('Catalyst') ) {
 897
 898         Catalyst::Exception->throw(
 899             message => qq/'$class' does not inherit from Catalyst/ );
 900     }
 901
 902     if ( $class->arguments ) {
 903         @arguments = ( @arguments, @{ $class->arguments } );
 904     }
 905
 906     # Process options
 907     my $flags = {};
 908
 909     foreach (@arguments) {
 910
 911         if (/^-Debug$/) {
 912             $flags->{log} =
 913               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 914         }
 915         elsif (/^-(\w+)=?(.*)$/) {
 916             $flags->{ lc $1 } = $2;
 917         }
 918         else {
 919             push @{ $flags->{plugins} }, $_;
 920         }
 921     }
 922
 923     $class->setup_home( delete $flags->{home} );
 924
 925     $class->setup_log( delete $flags->{log} );
 926     $class->setup_plugins( delete $flags->{plugins} );
 927     $class->setup_dispatcher( delete $flags->{dispatcher} );
 928     $class->setup_engine( delete $flags->{engine} );
 929     $class->setup_stats( delete $flags->{stats} );
 930
 931     for my $flag ( sort keys %{$flags} ) {
 932
 933         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 934             &$code( $class, delete $flags->{$flag} );
 935         }
 936         else {
 937             $class->log->warn(qq/Unknown flag "$flag"/);
 938         }
 939     }
 940
 941     eval { require Catalyst::Devel; };
 942     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 943         $class->log->warn(<<"EOF");
 944 You are running an old script!
 945
 946   Please update by running (this will overwrite existing files):
 947     catalyst.pl -force -scripts $class
 948
 949   or (this will not overwrite existing files):
 950     catalyst.pl -scripts $class
 951
 952 EOF
 953     }
 954
 955     if ( $class->debug ) {
 956         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 957
 958         if (@plugins) {
 959             my $t = Text::SimpleTable->new(74);
 960             $t->row($_) for @plugins;
 961             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 962         }
 963
 964         my $dispatcher = $class->dispatcher;
 965         my $engine     = $class->engine;
 966         my $home       = $class->config->{home};
 967
 968         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 969         $class->log->debug(qq/Loaded engine "$engine"/);
 970
 971         $home
 972           ? ( -d $home )
 973           ? $class->log->debug(qq/Found home "$home"/)
 974           : $class->log->debug(qq/Home "$home" doesn't exist/)
 975           : $class->log->debug(q/Couldn't find home/);
 976     }
 977
 978     # Call plugins setup
 979     {
 980         no warnings qw/redefine/;
 981         local *setup = sub { };
 982         $class->setup;
 983     }
 984
 985     # Initialize our data structure
 986     $class->components( {} );
 987
 988     $class->setup_components;
 989
 990     if ( $class->debug ) {
 991         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 992         for my $comp ( sort keys %{ $class->components } ) {
 993             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 994             $t->row( $comp, $type );
 995         }
 996         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 997           if ( keys %{ $class->components } );
 998     }
 999
1000     # Add our self to components, since we are also a component
1001     $class->components->{$class} = $class;
1002
1003     $class->setup_actions;
1004
1005     if ( $class->debug ) {
1006         my $name = $class->config->{name} || 'Application';
1007         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1008     }
1009     $class->log->_flush() if $class->log->can('_flush');
1010
1011     $class->setup_finished(1);
1012 }
1013
1014 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1015
1016 =head2 $c->uri_for( $path, @args?, \%query_values? )
1017
1018 =over
1019
1020 =item $action
1021
1022 A Catalyst::Action object representing the Catalyst action you want to
1023 create a URI for. To get one for an action in the current controller,
1024 use C<< $c->action('someactionname') >>. To get one from different
1025 controller, fetch the controller using C<< $c->controller() >>, then
1026 call C<action_for> on it.
1027
1028 This method must be used to create URIs for
1029 L<Catalyst::DispatchType::Chained> actions.
1030
1031 =item $path
1032
1033 The actual path you wish to create a URI for, this is a public path,
1034 not a private action path.
1035
1036 =item \@captures
1037
1038 If provided, this argument is used to insert values into a I<Chained>
1039 action in the parts where the definitions contain I<CaptureArgs>. If
1040 not needed, leave out this argument.
1041
1042 =item @args
1043
1044 If provided, this is used as a list of further path sections to append
1045 to the URI. In a I<Chained> action these are the equivalent to the
1046 endpoint L<Args>.
1047
1048 =item \%query_values
1049
1050 If provided, the query_values hashref is used to add query parameters
1051 to the URI, with the keys as the names, and the values as the values.
1052
1053 =back
1054
1055 Returns a L<URI> object.
1056
1057   ## Ex 1: a path with args and a query parameter
1058   $c->uri_for('user/list', 'short', { page => 2});
1059   ## -> ($c->req->base is 'http://localhost:3000/'
1060   URI->new('http://localhost:3000/user/list/short?page=2)
1061
1062   ## Ex 2: a chained view action that captures the user id
1063   ## In controller:
1064   sub user : Chained('/'): PathPart('myuser'): CaptureArgs(1) {}
1065   sub viewuser : Chained('user'): PathPart('view') {}
1066
1067   ## In uri creating code:
1068   my $uaction = $c->controller('Users')->action_for('viewuser');
1069   $c->uri_for($uaction, [ 42 ]);
1070   ## outputs:
1071   URI->new('http://localhost:3000/myuser/42/view')
1072
1073 Creates a URI object using C<< $c->request->base >> and a path. If an
1074 Action object is given instead of a path, the path is constructed
1075 using C<< $c->dispatcher->uri_for_action >> and passing it the
1076 @captures array, if supplied.
1077
1078 If any query parameters are passed they are added to the end of the
1079 URI in the usual way.
1080
1081 Note that uri_for is destructive to the passed query values hashref.
1082 Subsequent calls with the same hashref may have unintended results.
1083
1084 =cut
1085
1086 sub uri_for {
1087     my ( $c, $path, @args ) = @_;
1088
1089     if ( Scalar::Util::blessed($path) ) { # action object
1090         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1091                          ? shift(@args)
1092                          : [] );
1093         $path = $c->dispatcher->uri_for_action($path, $captures);
1094         return undef unless defined($path);
1095         $path = '/' if $path eq '';
1096     }
1097
1098     undef($path) if (defined $path && $path eq '');
1099
1100     my $params =
1101       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1102
1103     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1104     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1105
1106     unshift(@args, $path);
1107
1108     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1109         my $namespace = $c->namespace;
1110         if (defined $path) { # cheesy hack to handle path '../foo'
1111            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1112         }
1113         unshift(@args, $namespace || '');
1114     }
1115
1116     # join args with '/', or a blank string
1117     my $args = join('/', grep { defined($_) } @args);
1118     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1119     $args =~ s!^/!!;
1120     my $base = $c->req->base;
1121     my $class = ref($base);
1122     $base =~ s{(?<!/)$}{/};
1123
1124     my $query = '';
1125
1126     if (my @keys = keys %$params) {
1127       # somewhat lifted from URI::_query's query_form
1128       $query = '?'.join('&', map {
1129           my $val = $params->{$_};
1130           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1131           s/ /+/g;
1132           my $key = $_;
1133           $val = '' unless defined $val;
1134           (map {
1135               $_ = "$_";
1136               utf8::encode( $_ ) if utf8::is_utf8($_);
1137               # using the URI::Escape pattern here so utf8 chars survive
1138               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1139               s/ /+/g;
1140               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1141       } @keys);
1142     }
1143
1144     my $res = bless(\"${base}${args}${query}", $class);
1145     $res;
1146 }
1147
1148 =head2 $c->welcome_message
1149
1150 Returns the Catalyst welcome HTML page.
1151
1152 =cut
1153
1154 sub welcome_message {
1155     my $c      = shift;
1156     my $name   = $c->config->{name};
1157     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1158     my $prefix = Catalyst::Utils::appprefix( ref $c );
1159     $c->response->content_type('text/html; charset=utf-8');
1160     return <<"EOF";
1161 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1162     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1163 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1164     <head>
1165     <meta http-equiv="Content-Language" content="en" />
1166     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1167         <title>$name on Catalyst $VERSION</title>
1168         <style type="text/css">
1169             body {
1170                 color: #000;
1171                 background-color: #eee;
1172             }
1173             div#content {
1174                 width: 640px;
1175                 margin-left: auto;
1176                 margin-right: auto;
1177                 margin-top: 10px;
1178                 margin-bottom: 10px;
1179                 text-align: left;
1180                 background-color: #ccc;
1181                 border: 1px solid #aaa;
1182             }
1183             p, h1, h2 {
1184                 margin-left: 20px;
1185                 margin-right: 20px;
1186                 font-family: verdana, tahoma, sans-serif;
1187             }
1188             a {
1189                 font-family: verdana, tahoma, sans-serif;
1190             }
1191             :link, :visited {
1192                     text-decoration: none;
1193                     color: #b00;
1194                     border-bottom: 1px dotted #bbb;
1195             }
1196             :link:hover, :visited:hover {
1197                     color: #555;
1198             }
1199             div#topbar {
1200                 margin: 0px;
1201             }
1202             pre {
1203                 margin: 10px;
1204                 padding: 8px;
1205             }
1206             div#answers {
1207                 padding: 8px;
1208                 margin: 10px;
1209                 background-color: #fff;
1210                 border: 1px solid #aaa;
1211             }
1212             h1 {
1213                 font-size: 0.9em;
1214                 font-weight: normal;
1215                 text-align: center;
1216             }
1217             h2 {
1218                 font-size: 1.0em;
1219             }
1220             p {
1221                 font-size: 0.9em;
1222             }
1223             p img {
1224                 float: right;
1225                 margin-left: 10px;
1226             }
1227             span#appname {
1228                 font-weight: bold;
1229                 font-size: 1.6em;
1230             }
1231         </style>
1232     </head>
1233     <body>
1234         <div id="content">
1235             <div id="topbar">
1236                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1237                     $VERSION</h1>
1238              </div>
1239              <div id="answers">
1240                  <p>
1241                  <img src="$logo" alt="Catalyst Logo" />
1242                  </p>
1243                  <p>Welcome to the  world of Catalyst.
1244                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1245                     framework will make web development something you had
1246                     never expected it to be: Fun, rewarding, and quick.</p>
1247                  <h2>What to do now?</h2>
1248                  <p>That really depends  on what <b>you</b> want to do.
1249                     We do, however, provide you with a few starting points.</p>
1250                  <p>If you want to jump right into web development with Catalyst
1251                     you might want to start with a tutorial.</p>
1252 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1253 </pre>
1254 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1255 <pre>
1256 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1257 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1258 </code></pre>
1259                  <h2>What to do next?</h2>
1260                  <p>Next it's time to write an actual application. Use the
1261                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1262                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1263                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1264                     they can save you a lot of work.</p>
1265                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1266                     <p>Also, be sure to check out the vast and growing
1267                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1268                     you are likely to find what you need there.
1269                     </p>
1270
1271                  <h2>Need help?</h2>
1272                  <p>Catalyst has a very active community. Here are the main places to
1273                     get in touch with us.</p>
1274                  <ul>
1275                      <li>
1276                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1277                      </li>
1278                      <li>
1279                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1280                      </li>
1281                      <li>
1282                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1283                      </li>
1284                  </ul>
1285                  <h2>In conclusion</h2>
1286                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1287                     as we enjoyed making it. Please contact us if you have ideas
1288                     for improvement or other feedback.</p>
1289              </div>
1290          </div>
1291     </body>
1292 </html>
1293 EOF
1294 }
1295
1296 =head1 INTERNAL METHODS
1297
1298 These methods are not meant to be used by end users.
1299
1300 =head2 $c->components
1301
1302 Returns a hash of components.
1303
1304 =head2 $c->context_class
1305
1306 Returns or sets the context class.
1307
1308 =head2 $c->counter
1309
1310 Returns a hashref containing coderefs and execution counts (needed for
1311 deep recursion detection).
1312
1313 =head2 $c->depth
1314
1315 Returns the number of actions on the current internal execution stack.
1316
1317 =head2 $c->dispatch
1318
1319 Dispatches a request to actions.
1320
1321 =cut
1322
1323 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1324
1325 =head2 $c->dispatcher_class
1326
1327 Returns or sets the dispatcher class.
1328
1329 =head2 $c->dump_these
1330
1331 Returns a list of 2-element array references (name, structure) pairs
1332 that will be dumped on the error page in debug mode.
1333
1334 =cut
1335
1336 sub dump_these {
1337     my $c = shift;
1338     [ Request => $c->req ],
1339     [ Response => $c->res ],
1340     [ Stash => $c->stash ],
1341     [ Config => $c->config ];
1342 }
1343
1344 =head2 $c->engine_class
1345
1346 Returns or sets the engine class.
1347
1348 =head2 $c->execute( $class, $coderef )
1349
1350 Execute a coderef in given class and catch exceptions. Errors are available
1351 via $c->error.
1352
1353 =cut
1354
1355 sub execute {
1356     my ( $c, $class, $code ) = @_;
1357     $class = $c->component($class) || $class;
1358     $c->state(0);
1359
1360     if ( $c->depth >= $RECURSION ) {
1361         my $action = "$code";
1362         $action = "/$action" unless $action =~ /->/;
1363         my $error = qq/Deep recursion detected calling "$action"/;
1364         $c->log->error($error);
1365         $c->error($error);
1366         $c->state(0);
1367         return $c->state;
1368     }
1369
1370     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1371
1372     push( @{ $c->stack }, $code );
1373
1374     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1375
1376     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1377
1378     my $last = pop( @{ $c->stack } );
1379
1380     if ( my $error = $@ ) {
1381         if ( !ref($error) and $error eq $DETACH ) {
1382             die $DETACH if($c->depth > 1);
1383         }
1384         elsif ( !ref($error) and $error eq $GO ) {
1385             die $GO if($c->depth > 0);
1386         }
1387         else {
1388             unless ( ref $error ) {
1389                 no warnings 'uninitialized';
1390                 chomp $error;
1391                 my $class = $last->class;
1392                 my $name  = $last->name;
1393                 $error = qq/Caught exception in $class->$name "$error"/;
1394             }
1395             $c->error($error);
1396             $c->state(0);
1397         }
1398     }
1399     return $c->state;
1400 }
1401
1402 sub _stats_start_execute {
1403     my ( $c, $code ) = @_;
1404
1405     return if ( ( $code->name =~ /^_.*/ )
1406         && ( !$c->config->{show_internal_actions} ) );
1407
1408     $c->counter->{"$code"}++;
1409
1410     my $action = "$code";
1411     $action = "/$action" unless $action =~ /->/;
1412
1413     # determine if the call was the result of a forward
1414     # this is done by walking up the call stack and looking for a calling
1415     # sub of Catalyst::forward before the eval
1416     my $callsub = q{};
1417     for my $index ( 2 .. 11 ) {
1418         last
1419         if ( ( caller($index) )[0] eq 'Catalyst'
1420             && ( caller($index) )[3] eq '(eval)' );
1421
1422         if ( ( caller($index) )[3] =~ /forward$/ ) {
1423             $callsub = ( caller($index) )[3];
1424             $action  = "-> $action";
1425             last;
1426         }
1427     }
1428
1429     my $uid = "$code" . $c->counter->{"$code"};
1430
1431     # is this a root-level call or a forwarded call?
1432     if ( $callsub =~ /forward$/ ) {
1433
1434         # forward, locate the caller
1435         if ( my $parent = $c->stack->[-1] ) {
1436             $c->stats->profile(
1437                 begin  => $action,
1438                 parent => "$parent" . $c->counter->{"$parent"},
1439                 uid    => $uid,
1440             );
1441         }
1442         else {
1443
1444             # forward with no caller may come from a plugin
1445             $c->stats->profile(
1446                 begin => $action,
1447                 uid   => $uid,
1448             );
1449         }
1450     }
1451     else {
1452
1453         # root-level call
1454         $c->stats->profile(
1455             begin => $action,
1456             uid   => $uid,
1457         );
1458     }
1459     return $action;
1460
1461 }
1462
1463 sub _stats_finish_execute {
1464     my ( $c, $info ) = @_;
1465     $c->stats->profile( end => $info );
1466 }
1467
1468 =head2 $c->_localize_fields( sub { }, \%keys );
1469
1470 =cut
1471
1472 sub _localize_fields {
1473     my ( $c, $localized, $code ) = ( @_ );
1474
1475     my $request = delete $localized->{request} || {};
1476     my $response = delete $localized->{response} || {};
1477
1478     local @{ $c }{ keys %$localized } = values %$localized;
1479     local @{ $c->request }{ keys %$request } = values %$request;
1480     local @{ $c->response }{ keys %$response } = values %$response;
1481
1482     $code->();
1483 }
1484
1485 =head2 $c->finalize
1486
1487 Finalizes the request.
1488
1489 =cut
1490
1491 sub finalize {
1492     my $c = shift;
1493
1494     for my $error ( @{ $c->error } ) {
1495         $c->log->error($error);
1496     }
1497
1498     # Allow engine to handle finalize flow (for POE)
1499     if ( $c->engine->can('finalize') ) {
1500         $c->engine->finalize($c);
1501     }
1502     else {
1503
1504         $c->finalize_uploads;
1505
1506         # Error
1507         if ( $#{ $c->error } >= 0 ) {
1508             $c->finalize_error;
1509         }
1510
1511         $c->finalize_headers;
1512
1513         # HEAD request
1514         if ( $c->request->method eq 'HEAD' ) {
1515             $c->response->body('');
1516         }
1517
1518         $c->finalize_body;
1519     }
1520
1521     if ($c->use_stats) {
1522         my $elapsed = sprintf '%f', $c->stats->elapsed;
1523         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1524         $c->log->info(
1525             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1526     }
1527
1528     return $c->response->status;
1529 }
1530
1531 =head2 $c->finalize_body
1532
1533 Finalizes body.
1534
1535 =cut
1536
1537 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1538
1539 =head2 $c->finalize_cookies
1540
1541 Finalizes cookies.
1542
1543 =cut
1544
1545 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1546
1547 =head2 $c->finalize_error
1548
1549 Finalizes error.
1550
1551 =cut
1552
1553 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1554
1555 =head2 $c->finalize_headers
1556
1557 Finalizes headers.
1558
1559 =cut
1560
1561 sub finalize_headers {
1562     my $c = shift;
1563
1564     # Check if we already finalized headers
1565     return if $c->response->{_finalized_headers};
1566
1567     # Handle redirects
1568     if ( my $location = $c->response->redirect ) {
1569         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1570         $c->response->header( Location => $location );
1571
1572         if ( !$c->response->body ) {
1573             # Add a default body if none is already present
1574             $c->response->body(
1575                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1576             );
1577         }
1578     }
1579
1580     # Content-Length
1581     if ( $c->response->body && !$c->response->content_length ) {
1582
1583         # get the length from a filehandle
1584         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1585         {
1586             my $stat = stat $c->response->body;
1587             if ( $stat && $stat->size > 0 ) {
1588                 $c->response->content_length( $stat->size );
1589             }
1590             else {
1591                 $c->log->warn('Serving filehandle without a content-length');
1592             }
1593         }
1594         else {
1595             # everything should be bytes at this point, but just in case
1596             $c->response->content_length( bytes::length( $c->response->body ) );
1597         }
1598     }
1599
1600     # Errors
1601     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1602         $c->response->headers->remove_header("Content-Length");
1603         $c->response->body('');
1604     }
1605
1606     $c->finalize_cookies;
1607
1608     $c->engine->finalize_headers( $c, @_ );
1609
1610     # Done
1611     $c->response->{_finalized_headers} = 1;
1612 }
1613
1614 =head2 $c->finalize_output
1615
1616 An alias for finalize_body.
1617
1618 =head2 $c->finalize_read
1619
1620 Finalizes the input after reading is complete.
1621
1622 =cut
1623
1624 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1625
1626 =head2 $c->finalize_uploads
1627
1628 Finalizes uploads. Cleans up any temporary files.
1629
1630 =cut
1631
1632 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1633
1634 =head2 $c->get_action( $action, $namespace )
1635
1636 Gets an action in a given namespace.
1637
1638 =cut
1639
1640 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1641
1642 =head2 $c->get_actions( $action, $namespace )
1643
1644 Gets all actions of a given name in a namespace and all parent
1645 namespaces.
1646
1647 =cut
1648
1649 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1650
1651 =head2 $c->handle_request( $class, @arguments )
1652
1653 Called to handle each HTTP request.
1654
1655 =cut
1656
1657 sub handle_request {
1658     my ( $class, @arguments ) = @_;
1659
1660     # Always expect worst case!
1661     my $status = -1;
1662     eval {
1663         if ($class->debug) {
1664             my $secs = time - $START || 1;
1665             my $av = sprintf '%.3f', $COUNT / $secs;
1666             my $time = localtime time;
1667             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1668         }
1669
1670         my $c = $class->prepare(@arguments);
1671         $c->dispatch;
1672         $status = $c->finalize;
1673     };
1674
1675     if ( my $error = $@ ) {
1676         chomp $error;
1677         $class->log->error(qq/Caught exception in engine "$error"/);
1678     }
1679
1680     $COUNT++;
1681     $class->log->_flush() if $class->log->can('_flush');
1682     return $status;
1683 }
1684
1685 =head2 $c->prepare( @arguments )
1686
1687 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1688 etc.).
1689
1690 =cut
1691
1692 sub prepare {
1693     my ( $class, @arguments ) = @_;
1694
1695     $class->context_class( ref $class || $class ) unless $class->context_class;
1696     my $c = $class->context_class->new(
1697         {
1698             counter => {},
1699             stack   => [],
1700             request => $class->request_class->new(
1701                 {
1702                     arguments        => [],
1703                     body_parameters  => {},
1704                     cookies          => {},
1705                     headers          => HTTP::Headers->new,
1706                     parameters       => {},
1707                     query_parameters => {},
1708                     secure           => 0,
1709                     captures         => [],
1710                     uploads          => {}
1711                 }
1712             ),
1713             response => $class->response_class->new(
1714                 {
1715                     body    => '',
1716                     cookies => {},
1717                     headers => HTTP::Headers->new(),
1718                     status  => 200
1719                 }
1720             ),
1721             stash => {},
1722             state => 0
1723         }
1724     );
1725
1726     $c->stats($class->stats_class->new)->enable($c->use_stats);
1727     if ( $c->debug ) {
1728         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1729     }
1730
1731     # For on-demand data
1732     $c->request->{_context}  = $c;
1733     $c->response->{_context} = $c;
1734     weaken( $c->request->{_context} );
1735     weaken( $c->response->{_context} );
1736
1737     # Allow engine to direct the prepare flow (for POE)
1738     if ( $c->engine->can('prepare') ) {
1739         $c->engine->prepare( $c, @arguments );
1740     }
1741     else {
1742         $c->prepare_request(@arguments);
1743         $c->prepare_connection;
1744         $c->prepare_query_parameters;
1745         $c->prepare_headers;
1746         $c->prepare_cookies;
1747         $c->prepare_path;
1748
1749         # Prepare the body for reading, either by prepare_body
1750         # or the user, if they are using $c->read
1751         $c->prepare_read;
1752
1753         # Parse the body unless the user wants it on-demand
1754         unless ( $c->config->{parse_on_demand} ) {
1755             $c->prepare_body;
1756         }
1757     }
1758
1759     my $method  = $c->req->method  || '';
1760     my $path    = $c->req->path;
1761     $path       = '/' unless length $path;
1762     my $address = $c->req->address || '';
1763
1764     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1765       if $c->debug;
1766
1767     $c->prepare_action;
1768
1769     return $c;
1770 }
1771
1772 =head2 $c->prepare_action
1773
1774 Prepares action. See L<Catalyst::Dispatcher>.
1775
1776 =cut
1777
1778 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1779
1780 =head2 $c->prepare_body
1781
1782 Prepares message body.
1783
1784 =cut
1785
1786 sub prepare_body {
1787     my $c = shift;
1788
1789     # Do we run for the first time?
1790     return if defined $c->request->{_body};
1791
1792     # Initialize on-demand data
1793     $c->engine->prepare_body( $c, @_ );
1794     $c->prepare_parameters;
1795     $c->prepare_uploads;
1796
1797     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1798         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1799         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1800             my $param = $c->req->body_parameters->{$key};
1801             my $value = defined($param) ? $param : '';
1802             $t->row( $key,
1803                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1804         }
1805         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1806     }
1807 }
1808
1809 =head2 $c->prepare_body_chunk( $chunk )
1810
1811 Prepares a chunk of data before sending it to L<HTTP::Body>.
1812
1813 See L<Catalyst::Engine>.
1814
1815 =cut
1816
1817 sub prepare_body_chunk {
1818     my $c = shift;
1819     $c->engine->prepare_body_chunk( $c, @_ );
1820 }
1821
1822 =head2 $c->prepare_body_parameters
1823
1824 Prepares body parameters.
1825
1826 =cut
1827
1828 sub prepare_body_parameters {
1829     my $c = shift;
1830     $c->engine->prepare_body_parameters( $c, @_ );
1831 }
1832
1833 =head2 $c->prepare_connection
1834
1835 Prepares connection.
1836
1837 =cut
1838
1839 sub prepare_connection {
1840     my $c = shift;
1841     $c->engine->prepare_connection( $c, @_ );
1842 }
1843
1844 =head2 $c->prepare_cookies
1845
1846 Prepares cookies.
1847
1848 =cut
1849
1850 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1851
1852 =head2 $c->prepare_headers
1853
1854 Prepares headers.
1855
1856 =cut
1857
1858 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1859
1860 =head2 $c->prepare_parameters
1861
1862 Prepares parameters.
1863
1864 =cut
1865
1866 sub prepare_parameters {
1867     my $c = shift;
1868     $c->prepare_body_parameters;
1869     $c->engine->prepare_parameters( $c, @_ );
1870 }
1871
1872 =head2 $c->prepare_path
1873
1874 Prepares path and base.
1875
1876 =cut
1877
1878 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1879
1880 =head2 $c->prepare_query_parameters
1881
1882 Prepares query parameters.
1883
1884 =cut
1885
1886 sub prepare_query_parameters {
1887     my $c = shift;
1888
1889     $c->engine->prepare_query_parameters( $c, @_ );
1890
1891     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1892         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1893         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1894             my $param = $c->req->query_parameters->{$key};
1895             my $value = defined($param) ? $param : '';
1896             $t->row( $key,
1897                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1898         }
1899         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1900     }
1901 }
1902
1903 =head2 $c->prepare_read
1904
1905 Prepares the input for reading.
1906
1907 =cut
1908
1909 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1910
1911 =head2 $c->prepare_request
1912
1913 Prepares the engine request.
1914
1915 =cut
1916
1917 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1918
1919 =head2 $c->prepare_uploads
1920
1921 Prepares uploads.
1922
1923 =cut
1924
1925 sub prepare_uploads {
1926     my $c = shift;
1927
1928     $c->engine->prepare_uploads( $c, @_ );
1929
1930     if ( $c->debug && keys %{ $c->request->uploads } ) {
1931         my $t = Text::SimpleTable->new(
1932             [ 12, 'Parameter' ],
1933             [ 26, 'Filename' ],
1934             [ 18, 'Type' ],
1935             [ 9,  'Size' ]
1936         );
1937         for my $key ( sort keys %{ $c->request->uploads } ) {
1938             my $upload = $c->request->uploads->{$key};
1939             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1940                 $t->row( $key, $u->filename, $u->type, $u->size );
1941             }
1942         }
1943         $c->log->debug( "File Uploads are:\n" . $t->draw );
1944     }
1945 }
1946
1947 =head2 $c->prepare_write
1948
1949 Prepares the output for writing.
1950
1951 =cut
1952
1953 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1954
1955 =head2 $c->request_class
1956
1957 Returns or sets the request class.
1958
1959 =head2 $c->response_class
1960
1961 Returns or sets the response class.
1962
1963 =head2 $c->read( [$maxlength] )
1964
1965 Reads a chunk of data from the request body. This method is designed to
1966 be used in a while loop, reading C<$maxlength> bytes on every call.
1967 C<$maxlength> defaults to the size of the request if not specified.
1968
1969 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1970 directly.
1971
1972 Warning: If you use read(), Catalyst will not process the body,
1973 so you will not be able to access POST parameters or file uploads via
1974 $c->request.  You must handle all body parsing yourself.
1975
1976 =cut
1977
1978 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1979
1980 =head2 $c->run
1981
1982 Starts the engine.
1983
1984 =cut
1985
1986 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1987
1988 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1989
1990 Sets an action in a given namespace.
1991
1992 =cut
1993
1994 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1995
1996 =head2 $c->setup_actions($component)
1997
1998 Sets up actions for a component.
1999
2000 =cut
2001
2002 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2003
2004 =head2 $c->setup_components
2005
2006 Sets up components. Specify a C<setup_components> config option to pass
2007 additional options directly to L<Module::Pluggable>. To add additional
2008 search paths, specify a key named C<search_extra> as an array
2009 reference. Items in the array beginning with C<::> will have the
2010 application class name prepended to them.
2011
2012 All components found will also have any
2013 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2014 Note, that modules which are B<not> an I<inner package> of the main
2015 file namespace loaded will not be instantiated as components.
2016
2017 =cut
2018
2019 sub setup_components {
2020     my $class = shift;
2021
2022     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2023     my $config  = $class->config->{ setup_components };
2024     my $extra   = delete $config->{ search_extra } || [];
2025
2026     push @paths, @$extra;
2027
2028     my $locator = Module::Pluggable::Object->new(
2029         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2030         %$config
2031     );
2032
2033     my @comps = sort { length $a <=> length $b } $locator->plugins;
2034     my %comps = map { $_ => 1 } @comps;
2035
2036     for my $component ( @comps ) {
2037
2038         # We pass ignore_loaded here so that overlay files for (e.g.)
2039         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2040         # we know M::P::O found a file on disk so this is safe
2041
2042         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2043
2044         my $module  = $class->setup_component( $component );
2045         my %modules = (
2046             $component => $module,
2047             map {
2048                 $_ => $class->setup_component( $_ )
2049             } grep {
2050               not exists $comps{$_}
2051             } Devel::InnerPackage::list_packages( $component )
2052         );
2053
2054         for my $key ( keys %modules ) {
2055             $class->components->{ $key } = $modules{ $key };
2056         }
2057     }
2058 }
2059
2060 =head2 $c->setup_component
2061
2062 =cut
2063
2064 sub setup_component {
2065     my( $class, $component ) = @_;
2066
2067     unless ( $component->can( 'COMPONENT' ) ) {
2068         return $component;
2069     }
2070
2071     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2072     my $config = $class->config->{ $suffix } || {};
2073
2074     my $instance = eval { $component->COMPONENT( $class, $config ); };
2075
2076     if ( my $error = $@ ) {
2077         chomp $error;
2078         Catalyst::Exception->throw(
2079             message => qq/Couldn't instantiate component "$component", "$error"/
2080         );
2081     }
2082
2083     Catalyst::Exception->throw(
2084         message =>
2085         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2086     ) unless eval { $instance->can( 'can' ) };
2087
2088     return $instance;
2089 }
2090
2091 =head2 $c->setup_dispatcher
2092
2093 Sets up dispatcher.
2094
2095 =cut
2096
2097 sub setup_dispatcher {
2098     my ( $class, $dispatcher ) = @_;
2099
2100     if ($dispatcher) {
2101         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2102     }
2103
2104     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2105         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2106     }
2107
2108     unless ($dispatcher) {
2109         $dispatcher = $class->dispatcher_class;
2110     }
2111
2112     unless (Class::Inspector->loaded($dispatcher)) {
2113         require Class::Inspector->filename($dispatcher);
2114     }
2115
2116     # dispatcher instance
2117     $class->dispatcher( $dispatcher->new );
2118 }
2119
2120 =head2 $c->setup_engine
2121
2122 Sets up engine.
2123
2124 =cut
2125
2126 sub setup_engine {
2127     my ( $class, $engine ) = @_;
2128
2129     if ($engine) {
2130         $engine = 'Catalyst::Engine::' . $engine;
2131     }
2132
2133     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2134         $engine = 'Catalyst::Engine::' . $env;
2135     }
2136
2137     if ( $ENV{MOD_PERL} ) {
2138
2139         # create the apache method
2140         {
2141             no strict 'refs';
2142             *{"$class\::apache"} = sub { shift->engine->apache };
2143         }
2144
2145         my ( $software, $version ) =
2146           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2147
2148         $version =~ s/_//g;
2149         $version =~ s/(\.[^.]+)\./$1/g;
2150
2151         if ( $software eq 'mod_perl' ) {
2152
2153             if ( !$engine ) {
2154
2155                 if ( $version >= 1.99922 ) {
2156                     $engine = 'Catalyst::Engine::Apache2::MP20';
2157                 }
2158
2159                 elsif ( $version >= 1.9901 ) {
2160                     $engine = 'Catalyst::Engine::Apache2::MP19';
2161                 }
2162
2163                 elsif ( $version >= 1.24 ) {
2164                     $engine = 'Catalyst::Engine::Apache::MP13';
2165                 }
2166
2167                 else {
2168                     Catalyst::Exception->throw( message =>
2169                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2170                 }
2171
2172             }
2173
2174             # install the correct mod_perl handler
2175             if ( $version >= 1.9901 ) {
2176                 *handler = sub  : method {
2177                     shift->handle_request(@_);
2178                 };
2179             }
2180             else {
2181                 *handler = sub ($$) { shift->handle_request(@_) };
2182             }
2183
2184         }
2185
2186         elsif ( $software eq 'Zeus-Perl' ) {
2187             $engine = 'Catalyst::Engine::Zeus';
2188         }
2189
2190         else {
2191             Catalyst::Exception->throw(
2192                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2193         }
2194     }
2195
2196     unless ($engine) {
2197         $engine = $class->engine_class;
2198     }
2199
2200     unless (Class::Inspector->loaded($engine)) {
2201         require Class::Inspector->filename($engine);
2202     }
2203
2204     # check for old engines that are no longer compatible
2205     my $old_engine;
2206     if ( $engine->isa('Catalyst::Engine::Apache')
2207         && !Catalyst::Engine::Apache->VERSION )
2208     {
2209         $old_engine = 1;
2210     }
2211
2212     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2213         && Catalyst::Engine::Server->VERSION le '0.02' )
2214     {
2215         $old_engine = 1;
2216     }
2217
2218     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2219         && $engine->VERSION eq '0.01' )
2220     {
2221         $old_engine = 1;
2222     }
2223
2224     elsif ($engine->isa('Catalyst::Engine::Zeus')
2225         && $engine->VERSION eq '0.01' )
2226     {
2227         $old_engine = 1;
2228     }
2229
2230     if ($old_engine) {
2231         Catalyst::Exception->throw( message =>
2232               qq/Engine "$engine" is not supported by this version of Catalyst/
2233         );
2234     }
2235
2236     # engine instance
2237     $class->engine( $engine->new );
2238 }
2239
2240 =head2 $c->setup_home
2241
2242 Sets up the home directory.
2243
2244 =cut
2245
2246 sub setup_home {
2247     my ( $class, $home ) = @_;
2248
2249     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2250         $home = $env;
2251     }
2252
2253     unless ($home) {
2254         $home = Catalyst::Utils::home($class);
2255     }
2256
2257     if ($home) {
2258         $class->config->{home} ||= $home;
2259         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2260     }
2261 }
2262
2263 =head2 $c->setup_log
2264
2265 Sets up log.
2266
2267 =cut
2268
2269 sub setup_log {
2270     my ( $class, $debug ) = @_;
2271
2272     unless ( $class->log ) {
2273         $class->log( Catalyst::Log->new );
2274     }
2275
2276     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2277     if ( defined($env_debug) ? $env_debug : $debug ) {
2278         no strict 'refs';
2279         *{"$class\::debug"} = sub { 1 };
2280         $class->log->debug('Debug messages enabled');
2281     }
2282 }
2283
2284 =head2 $c->setup_plugins
2285
2286 Sets up plugins.
2287
2288 =cut
2289
2290 =head2 $c->setup_stats
2291
2292 Sets up timing statistics class.
2293
2294 =cut
2295
2296 sub setup_stats {
2297     my ( $class, $stats ) = @_;
2298
2299     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2300
2301     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2302     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2303         no strict 'refs';
2304         *{"$class\::use_stats"} = sub { 1 };
2305         $class->log->debug('Statistics enabled');
2306     }
2307 }
2308
2309
2310 =head2 $c->registered_plugins
2311
2312 Returns a sorted list of the plugins which have either been stated in the
2313 import list or which have been added via C<< MyApp->plugin(@args); >>.
2314
2315 If passed a given plugin name, it will report a boolean value indicating
2316 whether or not that plugin is loaded.  A fully qualified name is required if
2317 the plugin name does not begin with C<Catalyst::Plugin::>.
2318
2319  if ($c->registered_plugins('Some::Plugin')) {
2320      ...
2321  }
2322
2323 =cut
2324
2325 {
2326
2327     sub registered_plugins {
2328         my $proto = shift;
2329         return sort keys %{ $proto->_plugins } unless @_;
2330         my $plugin = shift;
2331         return 1 if exists $proto->_plugins->{$plugin};
2332         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2333     }
2334
2335     sub _register_plugin {
2336         my ( $proto, $plugin, $instant ) = @_;
2337         my $class = ref $proto || $proto;
2338
2339         # no ignore_loaded here, the plugin may already have been
2340         # defined in memory and we don't want to error on "no file" if so
2341
2342         Catalyst::Utils::ensure_class_loaded( $plugin );
2343
2344         $proto->_plugins->{$plugin} = 1;
2345         unless ($instant) {
2346             no strict 'refs';
2347             unshift @{"$class\::ISA"}, $plugin;
2348         }
2349         return $class;
2350     }
2351
2352     sub setup_plugins {
2353         my ( $class, $plugins ) = @_;
2354
2355         $class->_plugins( {} ) unless $class->_plugins;
2356         $plugins ||= [];
2357         for my $plugin ( reverse @$plugins ) {
2358
2359             unless ( $plugin =~ s/\A\+// ) {
2360                 $plugin = "Catalyst::Plugin::$plugin";
2361             }
2362
2363             $class->_register_plugin($plugin);
2364         }
2365     }
2366 }
2367
2368 =head2 $c->stack
2369
2370 Returns an arrayref of the internal execution stack (actions that are
2371 currently executing).
2372
2373 =head2 $c->stats_class
2374
2375 Returns or sets the stats (timing statistics) class.
2376
2377 =head2 $c->use_stats
2378
2379 Returns 1 when stats collection is enabled.  Stats collection is enabled
2380 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2381 environment variable is set.
2382
2383 Note that this is a static method, not an accessor and should be overloaded
2384 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2385
2386 =cut
2387
2388 sub use_stats { 0 }
2389
2390
2391 =head2 $c->write( $data )
2392
2393 Writes $data to the output stream. When using this method directly, you
2394 will need to manually set the C<Content-Length> header to the length of
2395 your output data, if known.
2396
2397 =cut
2398
2399 sub write {
2400     my $c = shift;
2401
2402     # Finalize headers if someone manually writes output
2403     $c->finalize_headers;
2404
2405     return $c->engine->write( $c, @_ );
2406 }
2407
2408 =head2 version
2409
2410 Returns the Catalyst version number. Mostly useful for "powered by"
2411 messages in template systems.
2412
2413 =cut
2414
2415 sub version { return $Catalyst::VERSION }
2416
2417 =head1 INTERNAL ACTIONS
2418
2419 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2420 C<_ACTION>, and C<_END>. These are by default not shown in the private
2421 action table, but you can make them visible with a config parameter.
2422
2423     MyApp->config->{show_internal_actions} = 1;
2424
2425 =head1 CASE SENSITIVITY
2426
2427 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2428 mapped to C</foo/bar>. You can activate case sensitivity with a config
2429 parameter.
2430
2431     MyApp->config->{case_sensitive} = 1;
2432
2433 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2434
2435 =head1 ON-DEMAND PARSER
2436
2437 The request body is usually parsed at the beginning of a request,
2438 but if you want to handle input yourself, you can enable on-demand
2439 parsing with a config parameter.
2440
2441     MyApp->config->{parse_on_demand} = 1;
2442
2443 =head1 PROXY SUPPORT
2444
2445 Many production servers operate using the common double-server approach,
2446 with a lightweight frontend web server passing requests to a larger
2447 backend server. An application running on the backend server must deal
2448 with two problems: the remote user always appears to be C<127.0.0.1> and
2449 the server's hostname will appear to be C<localhost> regardless of the
2450 virtual host that the user connected through.
2451
2452 Catalyst will automatically detect this situation when you are running
2453 the frontend and backend servers on the same machine. The following
2454 changes are made to the request.
2455
2456     $c->req->address is set to the user's real IP address, as read from
2457     the HTTP X-Forwarded-For header.
2458
2459     The host value for $c->req->base and $c->req->uri is set to the real
2460     host, as read from the HTTP X-Forwarded-Host header.
2461
2462 Obviously, your web server must support these headers for this to work.
2463
2464 In a more complex server farm environment where you may have your
2465 frontend proxy server(s) on different machines, you will need to set a
2466 configuration option to tell Catalyst to read the proxied data from the
2467 headers.
2468
2469     MyApp->config->{using_frontend_proxy} = 1;
2470
2471 If you do not wish to use the proxy support at all, you may set:
2472
2473     MyApp->config->{ignore_frontend_proxy} = 1;
2474
2475 =head1 THREAD SAFETY
2476
2477 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2478 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2479 believe the Catalyst core to be thread-safe.
2480
2481 If you plan to operate in a threaded environment, remember that all other
2482 modules you are using must also be thread-safe. Some modules, most notably
2483 L<DBD::SQLite>, are not thread-safe.
2484
2485 =head1 SUPPORT
2486
2487 IRC:
2488
2489     Join #catalyst on irc.perl.org.
2490
2491 Mailing Lists:
2492
2493     http://lists.rawmode.org/mailman/listinfo/catalyst
2494     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2495
2496 Web:
2497
2498     http://catalyst.perl.org
2499
2500 Wiki:
2501
2502     http://dev.catalyst.perl.org
2503
2504 =head1 SEE ALSO
2505
2506 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2507
2508 =head2 L<Catalyst::Manual> - The Catalyst Manual
2509
2510 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2511
2512 =head2 L<Catalyst::Engine> - Core engine
2513
2514 =head2 L<Catalyst::Log> - Log class.
2515
2516 =head2 L<Catalyst::Request> - Request object
2517
2518 =head2 L<Catalyst::Response> - Response object
2519
2520 =head2 L<Catalyst::Test> - The test suite.
2521
2522 =head1 PROJECT FOUNDER
2523
2524 sri: Sebastian Riedel <sri@cpan.org>
2525
2526 =head1 CONTRIBUTORS
2527
2528 abw: Andy Wardley
2529
2530 acme: Leon Brocard <leon@astray.com>
2531
2532 Andrew Bramble
2533
2534 Andrew Ford
2535
2536 Andrew Ruthven
2537
2538 andyg: Andy Grundman <andy@hybridized.org>
2539
2540 audreyt: Audrey Tang
2541
2542 bricas: Brian Cassidy <bricas@cpan.org>
2543
2544 chansen: Christian Hansen
2545
2546 chicks: Christopher Hicks
2547
2548 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2549
2550 Drew Taylor
2551
2552 esskar: Sascha Kiefer
2553
2554 fireartist: Carl Franks <cfranks@cpan.org>
2555
2556 gabb: Danijel Milicevic
2557
2558 Gary Ashton Jones
2559
2560 Geoff Richards
2561
2562 jcamacho: Juan Camacho
2563
2564 jhannah: Jay Hannah <jay@jays.net>
2565
2566 Jody Belka
2567
2568 Johan Lindstrom
2569
2570 jon: Jon Schutz <jjschutz@cpan.org>
2571
2572 marcus: Marcus Ramberg <mramberg@cpan.org>
2573
2574 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2575
2576 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2577
2578 mugwump: Sam Vilain
2579
2580 naughton: David Naughton
2581
2582 ningu: David Kamholz <dkamholz@cpan.org>
2583
2584 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2585
2586 numa: Dan Sully <daniel@cpan.org>
2587
2588 obra: Jesse Vincent
2589
2590 omega: Andreas Marienborg
2591
2592 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2593
2594 sky: Arthur Bergman
2595
2596 the_jester: Jesse Sheidlower
2597
2598 Ulf Edvinsson
2599
2600 willert: Sebastian Willert <willert@cpan.org>
2601
2602 batman: Jan Henning Thorsen <pm@flodhest.net>
2603
2604 =head1 LICENSE
2605
2606 This library is free software, you can redistribute it and/or modify it under
2607 the same terms as Perl itself.
2608
2609 =cut
2610
2611 1;