lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use Text::SimpleTable ();
  17 use Path::Class::Dir ();
  18 use Path::Class::File ();
  19 use Time::HiRes qw/gettimeofday tv_interval/;
  20 use URI ();
  21 use URI::http;
  22 use URI::https;
  23 use Scalar::Util qw/weaken blessed/;
  24 use Tree::Simple qw/use_weak_refs/;
  25 use Tree::Simple::Visitor::FindByUID;
  26 use attributes;
  27 use utf8;
  28 use Carp qw/croak carp/;
  29
  30 BEGIN { require 5.008001; }
  31
  32 has stack => (is => 'rw', default => sub { [] });
  33 has stash => (is => 'rw', default => sub { {} });
  34 has state => (is => 'rw', default => 0);
  35 has stats => (is => 'rw');
  36 has action => (is => 'rw');
  37 has counter => (is => 'rw', default => sub { {} });
  38 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  39 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  40 has namespace => (is => 'rw');
  41
  42 sub depth { scalar @{ shift->stack || [] }; }
  43 sub comp { shift->component(@_) }
  44
  45 sub req {
  46     # carp "the use of req() is deprecated in favour of request()";
  47     my $self = shift; return $self->request(@_);
  48 }
  49 sub res {
  50     # carp "the use of res() is deprecated in favour of response()";
  51     my $self = shift; return $self->response(@_);
  52 }
  53
  54 # For backwards compatibility
  55 sub finalize_output { shift->finalize_body(@_) };
  56
  57 # For statistics
  58 our $COUNT     = 1;
  59 our $START     = time;
  60 our $RECURSION = 1000;
  61 our $DETACH    = "catalyst_detach\n";
  62 our $GO        = "catalyst_go\n";
  63
  64 #I imagine that very few of these really need to be class variables. if any.
  65 #maybe we should just make them attributes with a default?
  66 __PACKAGE__->mk_classdata($_)
  67   for qw/components arguments dispatcher engine log dispatcher_class
  68   engine_class context_class request_class response_class stats_class
  69   setup_finished/;
  70
  71 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  72 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  73 __PACKAGE__->request_class('Catalyst::Request');
  74 __PACKAGE__->response_class('Catalyst::Response');
  75 __PACKAGE__->stats_class('Catalyst::Stats');
  76
  77 # Remember to update this in Catalyst::Runtime as well!
  78
  79 our $VERSION = '5.8000_02';
  80
  81 sub import {
  82     my ( $class, @arguments ) = @_;
  83
  84     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  85     # callers @ISA.
  86     return unless $class eq 'Catalyst';
  87
  88     my $caller = caller();
  89     return if $caller eq 'main';
  90     my $meta = Moose::Meta::Class->initialize($caller);
  91     #Moose->import({ into => $caller }); #do we want to do this?
  92
  93     unless ( $caller->isa('Catalyst') ) {
  94         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  95         $meta->superclasses(@superclasses);
  96     }
  97     unless( $meta->has_method('meta') ){
  98         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
  99     }
 100
 101     $caller->arguments( [@arguments] );
 102     $caller->setup_home;
 103 }
 104
 105 =head1 NAME
 106
 107 Catalyst - The Elegant MVC Web Application Framework
 108
 109 =head1 SYNOPSIS
 110
 111 See the L<Catalyst::Manual> distribution for comprehensive
 112 documentation and tutorials.
 113
 114     # Install Catalyst::Devel for helpers and other development tools
 115     # use the helper to create a new application
 116     catalyst.pl MyApp
 117
 118     # add models, views, controllers
 119     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 120     script/myapp_create.pl view MyTemplate TT
 121     script/myapp_create.pl controller Search
 122
 123     # built in testserver -- use -r to restart automatically on changes
 124     # --help to see all available options
 125     script/myapp_server.pl
 126
 127     # command line testing interface
 128     script/myapp_test.pl /yada
 129
 130     ### in lib/MyApp.pm
 131     use Catalyst qw/-Debug/; # include plugins here as well
 132
 133     ### In lib/MyApp/Controller/Root.pm (autocreated)
 134     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 135         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 136         $c->stash->{template} = 'foo.tt'; # set the template
 137         # lookup something from db -- stash vars are passed to TT
 138         $c->stash->{data} =
 139           $c->model('Database::Foo')->search( { country => $args[0] } );
 140         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 141             $c->forward( 'bar' ); # process another action
 142             # do something else after forward returns
 143         }
 144     }
 145
 146     # The foo.tt TT template can use the stash data from the database
 147     [% WHILE (item = data.next) %]
 148         [% item.foo %]
 149     [% END %]
 150
 151     # called for /bar/of/soap, /bar/of/soap/10, etc.
 152     sub bar : Path('/bar/of/soap') { ... }
 153
 154     # called for all actions, from the top-most controller downwards
 155     sub auto : Private {
 156         my ( $self, $c ) = @_;
 157         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 158             $c->res->redirect( '/login' ); # require login
 159             return 0; # abort request and go immediately to end()
 160         }
 161         return 1; # success; carry on to next action
 162     }
 163
 164     # called after all actions are finished
 165     sub end : Private {
 166         my ( $self, $c ) = @_;
 167         if ( scalar @{ $c->error } ) { ... } # handle errors
 168         return if $c->res->body; # already have a response
 169         $c->forward( 'MyApp::View::TT' ); # render template
 170     }
 171
 172     ### in MyApp/Controller/Foo.pm
 173     # called for /foo/bar
 174     sub bar : Local { ... }
 175
 176     # called for /blargle
 177     sub blargle : Global { ... }
 178
 179     # an index action matches /foo, but not /foo/1, etc.
 180     sub index : Private { ... }
 181
 182     ### in MyApp/Controller/Foo/Bar.pm
 183     # called for /foo/bar/baz
 184     sub baz : Local { ... }
 185
 186     # first Root auto is called, then Foo auto, then this
 187     sub auto : Private { ... }
 188
 189     # powerful regular expression paths are also possible
 190     sub details : Regex('^product/(\w+)/details$') {
 191         my ( $self, $c ) = @_;
 192         # extract the (\w+) from the URI
 193         my $product = $c->req->captures->[0];
 194     }
 195
 196 See L<Catalyst::Manual::Intro> for additional information.
 197
 198 =head1 DESCRIPTION
 199
 200 Catalyst is a modern framework for making web applications without the
 201 pain usually associated with this process. This document is a reference
 202 to the main Catalyst application. If you are a new user, we suggest you
 203 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 204
 205 See L<Catalyst::Manual> for more documentation.
 206
 207 Catalyst plugins can be loaded by naming them as arguments to the "use
 208 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 209 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 210 C<My::Module>.
 211
 212     use Catalyst qw/My::Module/;
 213
 214 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 215 fully qualify the name by using a unary plus:
 216
 217     use Catalyst qw/
 218         My::Module
 219         +Fully::Qualified::Plugin::Name
 220     /;
 221
 222 Special flags like C<-Debug> and C<-Engine> can also be specified as
 223 arguments when Catalyst is loaded:
 224
 225     use Catalyst qw/-Debug My::Module/;
 226
 227 The position of plugins and flags in the chain is important, because
 228 they are loaded in the order in which they appear.
 229
 230 The following flags are supported:
 231
 232 =head2 -Debug
 233
 234 Enables debug output. You can also force this setting from the system
 235 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 236 settings override the application, with <MYAPP>_DEBUG having the highest
 237 priority.
 238
 239 =head2 -Engine
 240
 241 Forces Catalyst to use a specific engine. Omit the
 242 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 243
 244     use Catalyst qw/-Engine=CGI/;
 245
 246 =head2 -Home
 247
 248 Forces Catalyst to use a specific home directory, e.g.:
 249
 250     use Catalyst qw[-Home=/usr/mst];
 251
 252 This can also be done in the shell environment by setting either the
 253 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 254 is replaced with the uppercased name of your application, any "::" in
 255 the name will be replaced with underscores, e.g. MyApp::Web should use
 256 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 257
 258 =head2 -Log
 259
 260 Specifies log level.
 261
 262 =head2 -Stats
 263
 264 Enables statistics collection and reporting. You can also force this setting
 265 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 266 environment settings override the application, with <MYAPP>_STATS having the
 267 highest priority.
 268
 269 e.g.
 270
 271    use Catalyst qw/-Stats=1/
 272
 273 =head1 METHODS
 274
 275 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 276
 277 =head2 $c->action
 278
 279 Returns a L<Catalyst::Action> object for the current action, which
 280 stringifies to the action name. See L<Catalyst::Action>.
 281
 282 =head2 $c->namespace
 283
 284 Returns the namespace of the current action, i.e., the URI prefix
 285 corresponding to the controller of the current action. For example:
 286
 287     # in Controller::Foo::Bar
 288     $c->namespace; # returns 'foo/bar';
 289
 290 =head2 $c->request
 291
 292 =head2 $c->req
 293
 294 Returns the current L<Catalyst::Request> object, giving access to
 295 information about the current client request (including parameters,
 296 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 297
 298 =head2 REQUEST FLOW HANDLING
 299
 300 =head2 $c->forward( $action [, \@arguments ] )
 301
 302 =head2 $c->forward( $class, $method, [, \@arguments ] )
 303
 304 Forwards processing to another action, by its private name. If you give a
 305 class name but no method, C<process()> is called. You may also optionally
 306 pass arguments in an arrayref. The action will receive the arguments in
 307 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 308 C<< $c->req->args >> will be restored to the previous values.
 309
 310 Any data C<return>ed from the action forwarded to, will be returned by the
 311 call to forward.
 312
 313     my $foodata = $c->forward('/foo');
 314     $c->forward('index');
 315     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 316     $c->forward('MyApp::View::TT');
 317
 318 Note that forward implies an C<<eval { }>> around the call (actually
 319 C<execute> does), thus de-fatalizing all 'dies' within the called
 320 action. If you want C<die> to propagate you need to do something like:
 321
 322     $c->forward('foo');
 323     die $c->error if $c->error;
 324
 325 Or make sure to always return true values from your actions and write
 326 your code like this:
 327
 328     $c->forward('foo') || return;
 329
 330 =cut
 331
 332 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 333
 334 =head2 $c->detach( $action [, \@arguments ] )
 335
 336 =head2 $c->detach( $class, $method, [, \@arguments ] )
 337
 338 =head2 $c->detach()
 339
 340 The same as C<forward>, but doesn't return to the previous action when
 341 processing is finished.
 342
 343 When called with no arguments it escapes the processing chain entirely.
 344
 345 =cut
 346
 347 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 348
 349 =head2 $c->visit( $action [, \@arguments ] )
 350
 351 =head2 $c->visit( $class, $method, [, \@arguments ] )
 352
 353 Almost the same as C<forward>, but does a full dispatch, instead of just
 354 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 355 C<auto> and the method you go to are called, just like a new request.
 356
 357 C<$c-E<gt>stash> is kept unchanged.
 358
 359 In effect, C<visit> allows you to "wrap" another action, just as it
 360 would have been called by dispatching from a URL, while the analogous
 361 C<go> allows you to transfer control to another action as if it had
 362 been reached directly from a URL.
 363
 364 =cut
 365
 366 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 367
 368 =head2 $c->go( $action [, \@arguments ] )
 369
 370 =head2 $c->go( $class, $method, [, \@arguments ] )
 371
 372 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 373 instead of just calling the new C<$action> /
 374 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 375 method you visit are called, just like a new request.
 376
 377 C<$c-E<gt>stash> is kept unchanged.
 378
 379 =cut
 380
 381 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 382
 383 =head2 $c->response
 384
 385 =head2 $c->res
 386
 387 Returns the current L<Catalyst::Response> object, see there for details.
 388
 389 =head2 $c->stash
 390
 391 Returns a hashref to the stash, which may be used to store data and pass
 392 it between components during a request. You can also set hash keys by
 393 passing arguments. The stash is automatically sent to the view. The
 394 stash is cleared at the end of a request; it cannot be used for
 395 persistent storage (for this you must use a session; see
 396 L<Catalyst::Plugin::Session> for a complete system integrated with
 397 Catalyst).
 398
 399     $c->stash->{foo} = $bar;
 400     $c->stash( { moose => 'majestic', qux => 0 } );
 401     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 402
 403     # stash is automatically passed to the view for use in a template
 404     $c->forward( 'MyApp::View::TT' );
 405
 406 =cut
 407
 408 around stash => sub {
 409     my $orig = shift;
 410     my $c = shift;
 411     my $stash = $orig->($c);
 412     if (@_) {
 413         my $new_stash = @_ > 1 ? {@_} : $_[0];
 414         croak('stash takes a hash or hashref') unless ref $new_stash;
 415         foreach my $key ( keys %$new_stash ) {
 416           $stash->{$key} = $new_stash->{$key};
 417         }
 418     }
 419
 420     return $stash;
 421 };
 422
 423
 424 =head2 $c->error
 425
 426 =head2 $c->error($error, ...)
 427
 428 =head2 $c->error($arrayref)
 429
 430 Returns an arrayref containing error messages.  If Catalyst encounters an
 431 error while processing a request, it stores the error in $c->error.  This
 432 method should only be used to store fatal error messages.
 433
 434     my @error = @{ $c->error };
 435
 436 Add a new error.
 437
 438     $c->error('Something bad happened');
 439
 440 =cut
 441
 442 sub error {
 443     my $c = shift;
 444     if ( $_[0] ) {
 445         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 446         croak @$error unless ref $c;
 447         push @{ $c->{error} }, @$error;
 448     }
 449     elsif ( defined $_[0] ) { $c->{error} = undef }
 450     return $c->{error} || [];
 451 }
 452
 453
 454 =head2 $c->state
 455
 456 Contains the return value of the last executed action.
 457
 458 =head2 $c->clear_errors
 459
 460 Clear errors.  You probably don't want to clear the errors unless you are
 461 implementing a custom error screen.
 462
 463 This is equivalent to running
 464
 465     $c->error(0);
 466
 467 =cut
 468
 469 sub clear_errors {
 470     my $c = shift;
 471     $c->error(0);
 472 }
 473
 474 # search components given a name and some prefixes
 475 sub _comp_search_prefixes {
 476     my ( $c, $name, @prefixes ) = @_;
 477     my $appclass = ref $c || $c;
 478     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 479
 480     # map the original component name to the sub part that we will search against
 481     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 482         grep { /$filter/ } keys %{ $c->components };
 483
 484     # undef for a name will return all
 485     return keys %eligible if !defined $name;
 486
 487     my $query  = ref $name ? $name : qr/^$name$/i;
 488     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 489
 490     return map { $c->components->{ $_ } } @result if @result;
 491
 492     # if we were given a regexp to search against, we're done.
 493     return if ref $name;
 494
 495     # regexp fallback
 496     $query  = qr/$name/i;
 497     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 498
 499     # no results? try against full names
 500     if( !@result ) {
 501         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 502     }
 503
 504     # don't warn if we didn't find any results, it just might not exist
 505     if( @result ) {
 506         $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 507         $c->log->warn( 'Relying on the regexp fallback behavior for component resolution is unreliable and unsafe.' );
 508         $c->log->warn( 'If you really want to search, pass in a regexp as the argument.' );
 509     }
 510
 511     return @result;
 512 }
 513
 514 # Find possible names for a prefix
 515 sub _comp_names {
 516     my ( $c, @prefixes ) = @_;
 517     my $appclass = ref $c || $c;
 518
 519     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 520
 521     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 522     return @names;
 523 }
 524
 525 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 526 sub _filter_component {
 527     my ( $c, $comp, @args ) = @_;
 528
 529     if ( Scalar::Util::blessed($c) && eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 530         return $comp->ACCEPT_CONTEXT( $c, @args );
 531     }
 532
 533     return $comp;
 534 }
 535
 536 =head2 COMPONENT ACCESSORS
 537
 538 =head2 $c->controller($name)
 539
 540 Gets a L<Catalyst::Controller> instance by name.
 541
 542     $c->controller('Foo')->do_stuff;
 543
 544 If the name is omitted, will return the controller for the dispatched
 545 action.
 546
 547 If you want to search for controllers, pass in a regexp as the argument.
 548
 549     # find all controllers that start with Foo
 550     my @foo_controllers = $c->controller(qr{^Foo});
 551
 552
 553 =cut
 554
 555 sub controller {
 556     my ( $c, $name, @args ) = @_;
 557
 558     if( $name ) {
 559         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 560         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 561         return $c->_filter_component( $result[ 0 ], @args );
 562     }
 563
 564     return $c->component( $c->action->class );
 565 }
 566
 567 =head2 $c->model($name)
 568
 569 Gets a L<Catalyst::Model> instance by name.
 570
 571     $c->model('Foo')->do_stuff;
 572
 573 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 574
 575 If the name is omitted, it will look for
 576  - a model object in $c->stash->{current_model_instance}, then
 577  - a model name in $c->stash->{current_model}, then
 578  - a config setting 'default_model', or
 579  - check if there is only one model, and return it if that's the case.
 580
 581 If you want to search for models, pass in a regexp as the argument.
 582
 583     # find all models that start with Foo
 584     my @foo_models = $c->model(qr{^Foo});
 585
 586 =cut
 587
 588 sub model {
 589     my ( $c, $name, @args ) = @_;
 590
 591     if( $name ) {
 592         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 593         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 594         return $c->_filter_component( $result[ 0 ], @args );
 595     }
 596
 597     if (ref $c) {
 598         return $c->stash->{current_model_instance}
 599           if $c->stash->{current_model_instance};
 600         return $c->model( $c->stash->{current_model} )
 601           if $c->stash->{current_model};
 602     }
 603     return $c->model( $c->config->{default_model} )
 604       if $c->config->{default_model};
 605
 606     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 607
 608     if( $rest ) {
 609         $c->log->warn( 'Calling $c->model() will return a random model unless you specify one of:' );
 610         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 611         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 612         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 613         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 614     }
 615
 616     return $c->_filter_component( $comp );
 617 }
 618
 619
 620 =head2 $c->view($name)
 621
 622 Gets a L<Catalyst::View> instance by name.
 623
 624     $c->view('Foo')->do_stuff;
 625
 626 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 627
 628 If the name is omitted, it will look for
 629  - a view object in $c->stash->{current_view_instance}, then
 630  - a view name in $c->stash->{current_view}, then
 631  - a config setting 'default_view', or
 632  - check if there is only one view, and return it if that's the case.
 633
 634 If you want to search for views, pass in a regexp as the argument.
 635
 636     # find all views that start with Foo
 637     my @foo_views = $c->view(qr{^Foo});
 638
 639 =cut
 640
 641 sub view {
 642     my ( $c, $name, @args ) = @_;
 643
 644     if( $name ) {
 645         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 646         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 647         return $c->_filter_component( $result[ 0 ], @args );
 648     }
 649
 650     if (ref $c) {
 651         return $c->stash->{current_view_instance}
 652           if $c->stash->{current_view_instance};
 653         return $c->view( $c->stash->{current_view} )
 654           if $c->stash->{current_view};
 655     }
 656     return $c->view( $c->config->{default_view} )
 657       if $c->config->{default_view};
 658
 659     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 660
 661     if( $rest ) {
 662         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 663         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 664         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 665         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 666         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 667     }
 668
 669     return $c->_filter_component( $comp );
 670 }
 671
 672 =head2 $c->controllers
 673
 674 Returns the available names which can be passed to $c->controller
 675
 676 =cut
 677
 678 sub controllers {
 679     my ( $c ) = @_;
 680     return $c->_comp_names(qw/Controller C/);
 681 }
 682
 683 =head2 $c->models
 684
 685 Returns the available names which can be passed to $c->model
 686
 687 =cut
 688
 689 sub models {
 690     my ( $c ) = @_;
 691     return $c->_comp_names(qw/Model M/);
 692 }
 693
 694
 695 =head2 $c->views
 696
 697 Returns the available names which can be passed to $c->view
 698
 699 =cut
 700
 701 sub views {
 702     my ( $c ) = @_;
 703     return $c->_comp_names(qw/View V/);
 704 }
 705
 706 =head2 $c->comp($name)
 707
 708 =head2 $c->component($name)
 709
 710 Gets a component object by name. This method is not recommended,
 711 unless you want to get a specific component by full
 712 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 713 should be used instead.
 714
 715 If C<$name> is a regexp, a list of components matched against the full
 716 component name will be returned.
 717
 718 =cut
 719
 720 sub component {
 721     my ( $c, $name, @args ) = @_;
 722
 723     if( $name ) {
 724         my $comps = $c->components;
 725
 726         if( !ref $name ) {
 727             # is it the exact name?
 728             return $c->_filter_component( $comps->{ $name }, @args )
 729                        if exists $comps->{ $name };
 730
 731             # perhaps we just omitted "MyApp"?
 732             my $composed = ( ref $c || $c ) . "::${name}";
 733             return $c->_filter_component( $comps->{ $composed }, @args )
 734                        if exists $comps->{ $composed };
 735
 736             # search all of the models, views and controllers
 737             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 738             return $c->_filter_component( $comp, @args ) if $comp;
 739         }
 740
 741         # This is here so $c->comp( '::M::' ) works
 742         my $query = ref $name ? $name : qr{$name}i;
 743
 744         my @result = grep { m{$query} } keys %{ $c->components };
 745         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 746
 747         if( $result[ 0 ] ) {
 748             $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 749             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 750             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 751             return $c->_filter_component( $result[ 0 ], @args );
 752         }
 753
 754         # I would expect to return an empty list here, but that breaks back-compat
 755     }
 756
 757     # fallback
 758     return sort keys %{ $c->components };
 759 }
 760
 761 =head2 CLASS DATA AND HELPER CLASSES
 762
 763 =head2 $c->config
 764
 765 Returns or takes a hashref containing the application's configuration.
 766
 767     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 768
 769 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 770 like myapp.yml in your applications home directory. See
 771 L<Catalyst::Plugin::ConfigLoader>.
 772
 773     ---
 774     db: dsn:SQLite:foo.db
 775
 776
 777 =cut
 778
 779 around config => sub {
 780     my $orig = shift;
 781     my $c = shift;
 782
 783     $c->log->warn("Setting config after setup has been run is not a good idea.")
 784       if ( @_ and $c->setup_finished );
 785
 786     $c->$orig(@_);
 787 };
 788
 789 =head2 $c->log
 790
 791 Returns the logging object instance. Unless it is already set, Catalyst
 792 sets this up with a L<Catalyst::Log> object. To use your own log class,
 793 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 794 C<< __PACKAGE__->setup >>.
 795
 796  __PACKAGE__->log( MyLogger->new );
 797  __PACKAGE__->setup;
 798
 799 And later:
 800
 801     $c->log->info( 'Now logging with my own logger!' );
 802
 803 Your log class should implement the methods described in
 804 L<Catalyst::Log>.
 805
 806
 807 =head2 $c->debug
 808
 809 Overload to enable debug messages (same as -Debug option).
 810
 811 Note that this is a static method, not an accessor and should be overloaded
 812 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 813
 814 =cut
 815
 816 sub debug { 0 }
 817
 818 =head2 $c->dispatcher
 819
 820 Returns the dispatcher instance. Stringifies to class name. See
 821 L<Catalyst::Dispatcher>.
 822
 823 =head2 $c->engine
 824
 825 Returns the engine instance. Stringifies to the class name. See
 826 L<Catalyst::Engine>.
 827
 828
 829 =head2 UTILITY METHODS
 830
 831 =head2 $c->path_to(@path)
 832
 833 Merges C<@path> with C<< $c->config->{home} >> and returns a
 834 L<Path::Class::Dir> object.
 835
 836 For example:
 837
 838     $c->path_to( 'db', 'sqlite.db' );
 839
 840 =cut
 841
 842 sub path_to {
 843     my ( $c, @path ) = @_;
 844     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 845     if ( -d $path ) { return $path }
 846     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 847 }
 848
 849 =head2 $c->plugin( $name, $class, @args )
 850
 851 Helper method for plugins. It creates a classdata accessor/mutator and
 852 loads and instantiates the given class.
 853
 854     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 855
 856     $c->prototype->define_javascript_functions;
 857
 858 =cut
 859
 860 sub plugin {
 861     my ( $class, $name, $plugin, @args ) = @_;
 862     $class->_register_plugin( $plugin, 1 );
 863
 864     eval { $plugin->import };
 865     $class->mk_classdata($name);
 866     my $obj;
 867     eval { $obj = $plugin->new(@args) };
 868
 869     if ($@) {
 870         Catalyst::Exception->throw( message =>
 871               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 872     }
 873
 874     $class->$name($obj);
 875     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 876       if $class->debug;
 877 }
 878
 879 =head2 MyApp->setup
 880
 881 Initializes the dispatcher and engine, loads any plugins, and loads the
 882 model, view, and controller components. You may also specify an array
 883 of plugins to load here, if you choose to not load them in the C<use
 884 Catalyst> line.
 885
 886     MyApp->setup;
 887     MyApp->setup( qw/-Debug/ );
 888
 889 =cut
 890
 891 sub setup {
 892     my ( $class, @arguments ) = @_;
 893     $class->log->warn("Running setup twice is not a good idea.")
 894       if ( $class->setup_finished );
 895
 896     unless ( $class->isa('Catalyst') ) {
 897
 898         Catalyst::Exception->throw(
 899             message => qq/'$class' does not inherit from Catalyst/ );
 900     }
 901
 902     if ( $class->arguments ) {
 903         @arguments = ( @arguments, @{ $class->arguments } );
 904     }
 905
 906     # Process options
 907     my $flags = {};
 908
 909     foreach (@arguments) {
 910
 911         if (/^-Debug$/) {
 912             $flags->{log} =
 913               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 914         }
 915         elsif (/^-(\w+)=?(.*)$/) {
 916             $flags->{ lc $1 } = $2;
 917         }
 918         else {
 919             push @{ $flags->{plugins} }, $_;
 920         }
 921     }
 922
 923     $class->setup_home( delete $flags->{home} );
 924
 925     $class->setup_log( delete $flags->{log} );
 926     $class->setup_plugins( delete $flags->{plugins} );
 927     $class->setup_dispatcher( delete $flags->{dispatcher} );
 928     $class->setup_engine( delete $flags->{engine} );
 929     $class->setup_stats( delete $flags->{stats} );
 930
 931     for my $flag ( sort keys %{$flags} ) {
 932
 933         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 934             &$code( $class, delete $flags->{$flag} );
 935         }
 936         else {
 937             $class->log->warn(qq/Unknown flag "$flag"/);
 938         }
 939     }
 940
 941     eval { require Catalyst::Devel; };
 942     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 943         $class->log->warn(<<"EOF");
 944 You are running an old script!
 945
 946   Please update by running (this will overwrite existing files):
 947     catalyst.pl -force -scripts $class
 948
 949   or (this will not overwrite existing files):
 950     catalyst.pl -scripts $class
 951
 952 EOF
 953     }
 954
 955     if ( $class->debug ) {
 956         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 957
 958         if (@plugins) {
 959             my $t = Text::SimpleTable->new(74);
 960             $t->row($_) for @plugins;
 961             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 962         }
 963
 964         my $dispatcher = $class->dispatcher;
 965         my $engine     = $class->engine;
 966         my $home       = $class->config->{home};
 967
 968         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 969         $class->log->debug(qq/Loaded engine "$engine"/);
 970
 971         $home
 972           ? ( -d $home )
 973           ? $class->log->debug(qq/Found home "$home"/)
 974           : $class->log->debug(qq/Home "$home" doesn't exist/)
 975           : $class->log->debug(q/Couldn't find home/);
 976     }
 977
 978     # Call plugins setup
 979     {
 980         no warnings qw/redefine/;
 981         local *setup = sub { };
 982         $class->setup;
 983     }
 984
 985     # Initialize our data structure
 986     $class->components( {} );
 987
 988     $class->setup_components;
 989
 990     if ( $class->debug ) {
 991         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 992         for my $comp ( sort keys %{ $class->components } ) {
 993             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 994             $t->row( $comp, $type );
 995         }
 996         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 997           if ( keys %{ $class->components } );
 998     }
 999
1000     # Add our self to components, since we are also a component
1001     if( $class->isa('Catalyst::Controller') ){
1002       $class->components->{$class} = $class;
1003     }
1004
1005     $class->setup_actions;
1006
1007     if ( $class->debug ) {
1008         my $name = $class->config->{name} || 'Application';
1009         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1010     }
1011     $class->log->_flush() if $class->log->can('_flush');
1012
1013     $class->setup_finished(1);
1014 }
1015
1016 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1017
1018 =head2 $c->uri_for( $path, @args?, \%query_values? )
1019
1020 =over
1021
1022 =item $action
1023
1024 A Catalyst::Action object representing the Catalyst action you want to
1025 create a URI for. To get one for an action in the current controller,
1026 use C<< $c->action('someactionname') >>. To get one from different
1027 controller, fetch the controller using C<< $c->controller() >>, then
1028 call C<action_for> on it.
1029
1030 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1031 using C<< $c->req->captures >>.
1032
1033   # For the current action
1034   $c->uri_for($c->action, $c->req->captures);
1035
1036   # For the Foo action in the Bar controller
1037   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1038
1039 =cut
1040
1041 =back
1042
1043 sub uri_for {
1044     my ( $c, $path, @args ) = @_;
1045
1046     if ( Scalar::Util::blessed($path) ) { # action object
1047         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1048                          ? shift(@args)
1049                          : [] );
1050         $path = $c->dispatcher->uri_for_action($path, $captures);
1051         return undef unless defined($path);
1052         $path = '/' if $path eq '';
1053     }
1054
1055     undef($path) if (defined $path && $path eq '');
1056
1057     my $params =
1058       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1059
1060     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1061     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1062
1063     unshift(@args, $path);
1064
1065     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1066         my $namespace = $c->namespace;
1067         if (defined $path) { # cheesy hack to handle path '../foo'
1068            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1069         }
1070         unshift(@args, $namespace || '');
1071     }
1072
1073     # join args with '/', or a blank string
1074     my $args = join('/', grep { defined($_) } @args);
1075     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1076     $args =~ s!^/!!;
1077     my $base = $c->req->base;
1078     my $class = ref($base);
1079     $base =~ s{(?<!/)$}{/};
1080
1081     my $query = '';
1082
1083     if (my @keys = keys %$params) {
1084       # somewhat lifted from URI::_query's query_form
1085       $query = '?'.join('&', map {
1086           my $val = $params->{$_};
1087           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1088           s/ /+/g;
1089           my $key = $_;
1090           $val = '' unless defined $val;
1091           (map {
1092               $_ = "$_";
1093               utf8::encode( $_ ) if utf8::is_utf8($_);
1094               # using the URI::Escape pattern here so utf8 chars survive
1095               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1096               s/ /+/g;
1097               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1098       } @keys);
1099     }
1100
1101     my $res = bless(\"${base}${args}${query}", $class);
1102     $res;
1103 }
1104
1105 =head2 $c->welcome_message
1106
1107 Returns the Catalyst welcome HTML page.
1108
1109 =cut
1110
1111 sub welcome_message {
1112     my $c      = shift;
1113     my $name   = $c->config->{name};
1114     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1115     my $prefix = Catalyst::Utils::appprefix( ref $c );
1116     $c->response->content_type('text/html; charset=utf-8');
1117     return <<"EOF";
1118 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1119     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1120 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1121     <head>
1122     <meta http-equiv="Content-Language" content="en" />
1123     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1124         <title>$name on Catalyst $VERSION</title>
1125         <style type="text/css">
1126             body {
1127                 color: #000;
1128                 background-color: #eee;
1129             }
1130             div#content {
1131                 width: 640px;
1132                 margin-left: auto;
1133                 margin-right: auto;
1134                 margin-top: 10px;
1135                 margin-bottom: 10px;
1136                 text-align: left;
1137                 background-color: #ccc;
1138                 border: 1px solid #aaa;
1139             }
1140             p, h1, h2 {
1141                 margin-left: 20px;
1142                 margin-right: 20px;
1143                 font-family: verdana, tahoma, sans-serif;
1144             }
1145             a {
1146                 font-family: verdana, tahoma, sans-serif;
1147             }
1148             :link, :visited {
1149                     text-decoration: none;
1150                     color: #b00;
1151                     border-bottom: 1px dotted #bbb;
1152             }
1153             :link:hover, :visited:hover {
1154                     color: #555;
1155             }
1156             div#topbar {
1157                 margin: 0px;
1158             }
1159             pre {
1160                 margin: 10px;
1161                 padding: 8px;
1162             }
1163             div#answers {
1164                 padding: 8px;
1165                 margin: 10px;
1166                 background-color: #fff;
1167                 border: 1px solid #aaa;
1168             }
1169             h1 {
1170                 font-size: 0.9em;
1171                 font-weight: normal;
1172                 text-align: center;
1173             }
1174             h2 {
1175                 font-size: 1.0em;
1176             }
1177             p {
1178                 font-size: 0.9em;
1179             }
1180             p img {
1181                 float: right;
1182                 margin-left: 10px;
1183             }
1184             span#appname {
1185                 font-weight: bold;
1186                 font-size: 1.6em;
1187             }
1188         </style>
1189     </head>
1190     <body>
1191         <div id="content">
1192             <div id="topbar">
1193                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1194                     $VERSION</h1>
1195              </div>
1196              <div id="answers">
1197                  <p>
1198                  <img src="$logo" alt="Catalyst Logo" />
1199                  </p>
1200                  <p>Welcome to the  world of Catalyst.
1201                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1202                     framework will make web development something you had
1203                     never expected it to be: Fun, rewarding, and quick.</p>
1204                  <h2>What to do now?</h2>
1205                  <p>That really depends  on what <b>you</b> want to do.
1206                     We do, however, provide you with a few starting points.</p>
1207                  <p>If you want to jump right into web development with Catalyst
1208                     you might want to start with a tutorial.</p>
1209 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1210 </pre>
1211 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1212 <pre>
1213 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1214 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1215 </code></pre>
1216                  <h2>What to do next?</h2>
1217                  <p>Next it's time to write an actual application. Use the
1218                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1219                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1220                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1221                     they can save you a lot of work.</p>
1222                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1223                     <p>Also, be sure to check out the vast and growing
1224                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1225                     you are likely to find what you need there.
1226                     </p>
1227
1228                  <h2>Need help?</h2>
1229                  <p>Catalyst has a very active community. Here are the main places to
1230                     get in touch with us.</p>
1231                  <ul>
1232                      <li>
1233                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1234                      </li>
1235                      <li>
1236                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1237                      </li>
1238                      <li>
1239                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1240                      </li>
1241                  </ul>
1242                  <h2>In conclusion</h2>
1243                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1244                     as we enjoyed making it. Please contact us if you have ideas
1245                     for improvement or other feedback.</p>
1246              </div>
1247          </div>
1248     </body>
1249 </html>
1250 EOF
1251 }
1252
1253 =head1 INTERNAL METHODS
1254
1255 These methods are not meant to be used by end users.
1256
1257 =head2 $c->components
1258
1259 Returns a hash of components.
1260
1261 =head2 $c->context_class
1262
1263 Returns or sets the context class.
1264
1265 =head2 $c->counter
1266
1267 Returns a hashref containing coderefs and execution counts (needed for
1268 deep recursion detection).
1269
1270 =head2 $c->depth
1271
1272 Returns the number of actions on the current internal execution stack.
1273
1274 =head2 $c->dispatch
1275
1276 Dispatches a request to actions.
1277
1278 =cut
1279
1280 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1281
1282 =head2 $c->dispatcher_class
1283
1284 Returns or sets the dispatcher class.
1285
1286 =head2 $c->dump_these
1287
1288 Returns a list of 2-element array references (name, structure) pairs
1289 that will be dumped on the error page in debug mode.
1290
1291 =cut
1292
1293 sub dump_these {
1294     my $c = shift;
1295     [ Request => $c->req ],
1296     [ Response => $c->res ],
1297     [ Stash => $c->stash ],
1298     [ Config => $c->config ];
1299 }
1300
1301 =head2 $c->engine_class
1302
1303 Returns or sets the engine class.
1304
1305 =head2 $c->execute( $class, $coderef )
1306
1307 Execute a coderef in given class and catch exceptions. Errors are available
1308 via $c->error.
1309
1310 =cut
1311
1312 sub execute {
1313     my ( $c, $class, $code ) = @_;
1314     $class = $c->component($class) || $class;
1315     $c->state(0);
1316
1317     if ( $c->depth >= $RECURSION ) {
1318         my $action = $code->reverse();
1319         $action = "/$action" unless $action =~ /->/;
1320         my $error = qq/Deep recursion detected calling "${action}"/;
1321         $c->log->error($error);
1322         $c->error($error);
1323         $c->state(0);
1324         return $c->state;
1325     }
1326
1327     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1328
1329     push( @{ $c->stack }, $code );
1330
1331     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1332
1333     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1334
1335     my $last = pop( @{ $c->stack } );
1336
1337     if ( my $error = $@ ) {
1338         if ( !ref($error) and $error eq $DETACH ) {
1339             die $DETACH if($c->depth > 1);
1340         }
1341         elsif ( !ref($error) and $error eq $GO ) {
1342             die $GO if($c->depth > 0);
1343         }
1344         else {
1345             unless ( ref $error ) {
1346                 no warnings 'uninitialized';
1347                 chomp $error;
1348                 my $class = $last->class;
1349                 my $name  = $last->name;
1350                 $error = qq/Caught exception in $class->$name "$error"/;
1351             }
1352             $c->error($error);
1353             $c->state(0);
1354         }
1355     }
1356     return $c->state;
1357 }
1358
1359 sub _stats_start_execute {
1360     my ( $c, $code ) = @_;
1361
1362     return if ( ( $code->name =~ /^_.*/ )
1363         && ( !$c->config->{show_internal_actions} ) );
1364
1365     my $action_name = $code->reverse();
1366     $c->counter->{$action_name}++;
1367
1368     my $action = $action_name;
1369     $action = "/$action" unless $action =~ /->/;
1370
1371     # determine if the call was the result of a forward
1372     # this is done by walking up the call stack and looking for a calling
1373     # sub of Catalyst::forward before the eval
1374     my $callsub = q{};
1375     for my $index ( 2 .. 11 ) {
1376         last
1377         if ( ( caller($index) )[0] eq 'Catalyst'
1378             && ( caller($index) )[3] eq '(eval)' );
1379
1380         if ( ( caller($index) )[3] =~ /forward$/ ) {
1381             $callsub = ( caller($index) )[3];
1382             $action  = "-> $action";
1383             last;
1384         }
1385     }
1386
1387     my $uid = $action_name . $c->counter->{$action_name};
1388
1389     # is this a root-level call or a forwarded call?
1390     if ( $callsub =~ /forward$/ ) {
1391
1392         # forward, locate the caller
1393         if ( my $parent = $c->stack->[-1] ) {
1394             $c->stats->profile(
1395                 begin  => $action,
1396                 parent => "$parent" . $c->counter->{"$parent"},
1397                 uid    => $uid,
1398             );
1399         }
1400         else {
1401
1402             # forward with no caller may come from a plugin
1403             $c->stats->profile(
1404                 begin => $action,
1405                 uid   => $uid,
1406             );
1407         }
1408     }
1409     else {
1410
1411         # root-level call
1412         $c->stats->profile(
1413             begin => $action,
1414             uid   => $uid,
1415         );
1416     }
1417     return $action;
1418
1419 }
1420
1421 sub _stats_finish_execute {
1422     my ( $c, $info ) = @_;
1423     $c->stats->profile( end => $info );
1424 }
1425
1426 =head2 $c->_localize_fields( sub { }, \%keys );
1427
1428 =cut
1429
1430 #Why does this exist? This is no longer safe and WILL NOT WORK.
1431 # it doesnt seem to be used anywhere. can we remove it?
1432 sub _localize_fields {
1433     my ( $c, $localized, $code ) = ( @_ );
1434
1435     my $request = delete $localized->{request} || {};
1436     my $response = delete $localized->{response} || {};
1437
1438     local @{ $c }{ keys %$localized } = values %$localized;
1439     local @{ $c->request }{ keys %$request } = values %$request;
1440     local @{ $c->response }{ keys %$response } = values %$response;
1441
1442     $code->();
1443 }
1444
1445 =head2 $c->finalize
1446
1447 Finalizes the request.
1448
1449 =cut
1450
1451 sub finalize {
1452     my $c = shift;
1453
1454     for my $error ( @{ $c->error } ) {
1455         $c->log->error($error);
1456     }
1457
1458     # Allow engine to handle finalize flow (for POE)
1459     my $engine = $c->engine;
1460     if ( my $code = $engine->can('finalize') ) {
1461         $engine->$code($c);
1462     }
1463     else {
1464
1465         $c->finalize_uploads;
1466
1467         # Error
1468         if ( $#{ $c->error } >= 0 ) {
1469             $c->finalize_error;
1470         }
1471
1472         $c->finalize_headers;
1473
1474         # HEAD request
1475         if ( $c->request->method eq 'HEAD' ) {
1476             $c->response->body('');
1477         }
1478
1479         $c->finalize_body;
1480     }
1481
1482     if ($c->use_stats) {
1483         my $elapsed = sprintf '%f', $c->stats->elapsed;
1484         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1485         $c->log->info(
1486             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1487     }
1488
1489     return $c->response->status;
1490 }
1491
1492 =head2 $c->finalize_body
1493
1494 Finalizes body.
1495
1496 =cut
1497
1498 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1499
1500 =head2 $c->finalize_cookies
1501
1502 Finalizes cookies.
1503
1504 =cut
1505
1506 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1507
1508 =head2 $c->finalize_error
1509
1510 Finalizes error.
1511
1512 =cut
1513
1514 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1515
1516 =head2 $c->finalize_headers
1517
1518 Finalizes headers.
1519
1520 =cut
1521
1522 sub finalize_headers {
1523     my $c = shift;
1524
1525     my $response = $c->response; #accessor calls can add up?
1526
1527     # Check if we already finalized headers
1528     return if $response->finalized_headers;
1529
1530     # Handle redirects
1531     if ( my $location = $response->redirect ) {
1532         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1533         $response->header( Location => $location );
1534
1535         #Moose TODO: we should probably be using a predicate method here ?
1536         if ( !$response->body ) {
1537             # Add a default body if none is already present
1538             $response->body(
1539                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1540             );
1541         }
1542     }
1543
1544     # Content-Length
1545     if ( $response->body && !$response->content_length ) {
1546
1547         # get the length from a filehandle
1548         if ( blessed( $response->body ) && $response->body->can('read') )
1549         {
1550             my $stat = stat $response->body;
1551             if ( $stat && $stat->size > 0 ) {
1552                 $response->content_length( $stat->size );
1553             }
1554             else {
1555                 $c->log->warn('Serving filehandle without a content-length');
1556             }
1557         }
1558         else {
1559             # everything should be bytes at this point, but just in case
1560             $response->content_length( bytes::length( $response->body ) );
1561         }
1562     }
1563
1564     # Errors
1565     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1566         $response->headers->remove_header("Content-Length");
1567         $response->body('');
1568     }
1569
1570     $c->finalize_cookies;
1571
1572     $c->engine->finalize_headers( $c, @_ );
1573
1574     # Done
1575     $response->finalized_headers(1);
1576 }
1577
1578 =head2 $c->finalize_output
1579
1580 An alias for finalize_body.
1581
1582 =head2 $c->finalize_read
1583
1584 Finalizes the input after reading is complete.
1585
1586 =cut
1587
1588 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1589
1590 =head2 $c->finalize_uploads
1591
1592 Finalizes uploads. Cleans up any temporary files.
1593
1594 =cut
1595
1596 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1597
1598 =head2 $c->get_action( $action, $namespace )
1599
1600 Gets an action in a given namespace.
1601
1602 =cut
1603
1604 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1605
1606 =head2 $c->get_actions( $action, $namespace )
1607
1608 Gets all actions of a given name in a namespace and all parent
1609 namespaces.
1610
1611 =cut
1612
1613 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1614
1615 =head2 $c->handle_request( $class, @arguments )
1616
1617 Called to handle each HTTP request.
1618
1619 =cut
1620
1621 sub handle_request {
1622     my ( $class, @arguments ) = @_;
1623
1624     # Always expect worst case!
1625     my $status = -1;
1626     eval {
1627         if ($class->debug) {
1628             my $secs = time - $START || 1;
1629             my $av = sprintf '%.3f', $COUNT / $secs;
1630             my $time = localtime time;
1631             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1632         }
1633
1634         my $c = $class->prepare(@arguments);
1635         $c->dispatch;
1636         $status = $c->finalize;
1637     };
1638
1639     if ( my $error = $@ ) {
1640         chomp $error;
1641         $class->log->error(qq/Caught exception in engine "$error"/);
1642     }
1643
1644     $COUNT++;
1645
1646     if(my $coderef = $class->log->can('_flush')){
1647         $class->log->$coderef();
1648     }
1649     return $status;
1650 }
1651
1652 =head2 $c->prepare( @arguments )
1653
1654 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1655 etc.).
1656
1657 =cut
1658
1659 sub prepare {
1660     my ( $class, @arguments ) = @_;
1661
1662     # XXX
1663     # After the app/ctxt split, this should become an attribute based on something passed
1664     # into the application.
1665     $class->context_class( ref $class || $class ) unless $class->context_class;
1666
1667     my $c = $class->context_class->new({});
1668
1669     # For on-demand data
1670     $c->request->_context($c);
1671     $c->response->_context($c);
1672
1673     #surely this is not the most efficient way to do things...
1674     $c->stats($class->stats_class->new)->enable($c->use_stats);
1675     if ( $c->debug ) {
1676         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1677     }
1678
1679     #XXX reuse coderef from can
1680     # Allow engine to direct the prepare flow (for POE)
1681     if ( $c->engine->can('prepare') ) {
1682         $c->engine->prepare( $c, @arguments );
1683     }
1684     else {
1685         $c->prepare_request(@arguments);
1686         $c->prepare_connection;
1687         $c->prepare_query_parameters;
1688         $c->prepare_headers;
1689         $c->prepare_cookies;
1690         $c->prepare_path;
1691
1692         # Prepare the body for reading, either by prepare_body
1693         # or the user, if they are using $c->read
1694         $c->prepare_read;
1695
1696         # Parse the body unless the user wants it on-demand
1697         unless ( $c->config->{parse_on_demand} ) {
1698             $c->prepare_body;
1699         }
1700     }
1701
1702     my $method  = $c->req->method  || '';
1703     my $path    = $c->req->path;
1704     $path       = '/' unless length $path;
1705     my $address = $c->req->address || '';
1706
1707     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1708       if $c->debug;
1709
1710     $c->prepare_action;
1711
1712     return $c;
1713 }
1714
1715 =head2 $c->prepare_action
1716
1717 Prepares action. See L<Catalyst::Dispatcher>.
1718
1719 =cut
1720
1721 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1722
1723 =head2 $c->prepare_body
1724
1725 Prepares message body.
1726
1727 =cut
1728
1729 sub prepare_body {
1730     my $c = shift;
1731
1732     #Moose TODO: what is  _body ??
1733     # Do we run for the first time?
1734     return if defined $c->request->{_body};
1735
1736     # Initialize on-demand data
1737     $c->engine->prepare_body( $c, @_ );
1738     $c->prepare_parameters;
1739     $c->prepare_uploads;
1740
1741     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1742         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1743         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1744             my $param = $c->req->body_parameters->{$key};
1745             my $value = defined($param) ? $param : '';
1746             $t->row( $key,
1747                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1748         }
1749         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1750     }
1751 }
1752
1753 =head2 $c->prepare_body_chunk( $chunk )
1754
1755 Prepares a chunk of data before sending it to L<HTTP::Body>.
1756
1757 See L<Catalyst::Engine>.
1758
1759 =cut
1760
1761 sub prepare_body_chunk {
1762     my $c = shift;
1763     $c->engine->prepare_body_chunk( $c, @_ );
1764 }
1765
1766 =head2 $c->prepare_body_parameters
1767
1768 Prepares body parameters.
1769
1770 =cut
1771
1772 sub prepare_body_parameters {
1773     my $c = shift;
1774     $c->engine->prepare_body_parameters( $c, @_ );
1775 }
1776
1777 =head2 $c->prepare_connection
1778
1779 Prepares connection.
1780
1781 =cut
1782
1783 sub prepare_connection {
1784     my $c = shift;
1785     $c->engine->prepare_connection( $c, @_ );
1786 }
1787
1788 =head2 $c->prepare_cookies
1789
1790 Prepares cookies.
1791
1792 =cut
1793
1794 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1795
1796 =head2 $c->prepare_headers
1797
1798 Prepares headers.
1799
1800 =cut
1801
1802 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1803
1804 =head2 $c->prepare_parameters
1805
1806 Prepares parameters.
1807
1808 =cut
1809
1810 sub prepare_parameters {
1811     my $c = shift;
1812     $c->prepare_body_parameters;
1813     $c->engine->prepare_parameters( $c, @_ );
1814 }
1815
1816 =head2 $c->prepare_path
1817
1818 Prepares path and base.
1819
1820 =cut
1821
1822 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1823
1824 =head2 $c->prepare_query_parameters
1825
1826 Prepares query parameters.
1827
1828 =cut
1829
1830 sub prepare_query_parameters {
1831     my $c = shift;
1832
1833     $c->engine->prepare_query_parameters( $c, @_ );
1834
1835     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1836         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1837         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1838             my $param = $c->req->query_parameters->{$key};
1839             my $value = defined($param) ? $param : '';
1840             $t->row( $key,
1841                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1842         }
1843         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1844     }
1845 }
1846
1847 =head2 $c->prepare_read
1848
1849 Prepares the input for reading.
1850
1851 =cut
1852
1853 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1854
1855 =head2 $c->prepare_request
1856
1857 Prepares the engine request.
1858
1859 =cut
1860
1861 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1862
1863 =head2 $c->prepare_uploads
1864
1865 Prepares uploads.
1866
1867 =cut
1868
1869 sub prepare_uploads {
1870     my $c = shift;
1871
1872     $c->engine->prepare_uploads( $c, @_ );
1873
1874     if ( $c->debug && keys %{ $c->request->uploads } ) {
1875         my $t = Text::SimpleTable->new(
1876             [ 12, 'Parameter' ],
1877             [ 26, 'Filename' ],
1878             [ 18, 'Type' ],
1879             [ 9,  'Size' ]
1880         );
1881         for my $key ( sort keys %{ $c->request->uploads } ) {
1882             my $upload = $c->request->uploads->{$key};
1883             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1884                 $t->row( $key, $u->filename, $u->type, $u->size );
1885             }
1886         }
1887         $c->log->debug( "File Uploads are:\n" . $t->draw );
1888     }
1889 }
1890
1891 =head2 $c->prepare_write
1892
1893 Prepares the output for writing.
1894
1895 =cut
1896
1897 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1898
1899 =head2 $c->request_class
1900
1901 Returns or sets the request class.
1902
1903 =head2 $c->response_class
1904
1905 Returns or sets the response class.
1906
1907 =head2 $c->read( [$maxlength] )
1908
1909 Reads a chunk of data from the request body. This method is designed to
1910 be used in a while loop, reading C<$maxlength> bytes on every call.
1911 C<$maxlength> defaults to the size of the request if not specified.
1912
1913 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1914 directly.
1915
1916 Warning: If you use read(), Catalyst will not process the body,
1917 so you will not be able to access POST parameters or file uploads via
1918 $c->request.  You must handle all body parsing yourself.
1919
1920 =cut
1921
1922 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1923
1924 =head2 $c->run
1925
1926 Starts the engine.
1927
1928 =cut
1929
1930 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1931
1932 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1933
1934 Sets an action in a given namespace.
1935
1936 =cut
1937
1938 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1939
1940 =head2 $c->setup_actions($component)
1941
1942 Sets up actions for a component.
1943
1944 =cut
1945
1946 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1947
1948 =head2 $c->setup_components
1949
1950 Sets up components. Specify a C<setup_components> config option to pass
1951 additional options directly to L<Module::Pluggable>. To add additional
1952 search paths, specify a key named C<search_extra> as an array
1953 reference. Items in the array beginning with C<::> will have the
1954 application class name prepended to them.
1955
1956 All components found will also have any
1957 L<Devel::InnerPackage|inner packages> loaded and set up as components.
1958 Note, that modules which are B<not> an I<inner package> of the main
1959 file namespace loaded will not be instantiated as components.
1960
1961 =cut
1962
1963 sub setup_components {
1964     my $class = shift;
1965
1966     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1967     my $config  = $class->config->{ setup_components };
1968     my $extra   = delete $config->{ search_extra } || [];
1969
1970     push @paths, @$extra;
1971
1972     my $locator = Module::Pluggable::Object->new(
1973         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1974         %$config
1975     );
1976
1977     my @comps = sort { length $a <=> length $b } $locator->plugins;
1978     my %comps = map { $_ => 1 } @comps;
1979
1980     for my $component ( @comps ) {
1981
1982         # We pass ignore_loaded here so that overlay files for (e.g.)
1983         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1984         # we know M::P::O found a file on disk so this is safe
1985
1986         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1987         #Class::MOP::load_class($component);
1988
1989         my $module  = $class->setup_component( $component );
1990         my %modules = (
1991             $component => $module,
1992             map {
1993                 $_ => $class->setup_component( $_ )
1994             } grep {
1995               not exists $comps{$_}
1996             } Devel::InnerPackage::list_packages( $component )
1997         );
1998
1999         for my $key ( keys %modules ) {
2000             $class->components->{ $key } = $modules{ $key };
2001         }
2002     }
2003 }
2004
2005 =head2 $c->setup_component
2006
2007 =cut
2008
2009 sub setup_component {
2010     my( $class, $component ) = @_;
2011
2012     unless ( $component->can( 'COMPONENT' ) ) {
2013         return $component;
2014     }
2015
2016     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2017     my $config = $class->config->{ $suffix } || {};
2018
2019     my $instance = eval { $component->COMPONENT( $class, $config ); };
2020
2021     if ( my $error = $@ ) {
2022         chomp $error;
2023         Catalyst::Exception->throw(
2024             message => qq/Couldn't instantiate component "$component", "$error"/
2025         );
2026     }
2027
2028     Catalyst::Exception->throw(
2029         message =>
2030         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2031     ) unless blessed($instance);
2032
2033     return $instance;
2034 }
2035
2036 =head2 $c->setup_dispatcher
2037
2038 Sets up dispatcher.
2039
2040 =cut
2041
2042 sub setup_dispatcher {
2043     my ( $class, $dispatcher ) = @_;
2044
2045     if ($dispatcher) {
2046         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2047     }
2048
2049     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2050         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2051     }
2052
2053     unless ($dispatcher) {
2054         $dispatcher = $class->dispatcher_class;
2055     }
2056
2057     Class::MOP::load_class($dispatcher);
2058
2059     # dispatcher instance
2060     $class->dispatcher( $dispatcher->new );
2061 }
2062
2063 =head2 $c->setup_engine
2064
2065 Sets up engine.
2066
2067 =cut
2068
2069 sub setup_engine {
2070     my ( $class, $engine ) = @_;
2071
2072     if ($engine) {
2073         $engine = 'Catalyst::Engine::' . $engine;
2074     }
2075
2076     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2077         $engine = 'Catalyst::Engine::' . $env;
2078     }
2079
2080     if ( $ENV{MOD_PERL} ) {
2081
2082         # create the apache method
2083         $class->meta->add_method('apache' => sub { shift->engine->apache });
2084
2085         my ( $software, $version ) =
2086           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2087
2088         $version =~ s/_//g;
2089         $version =~ s/(\.[^.]+)\./$1/g;
2090
2091         if ( $software eq 'mod_perl' ) {
2092
2093             if ( !$engine ) {
2094
2095                 if ( $version >= 1.99922 ) {
2096                     $engine = 'Catalyst::Engine::Apache2::MP20';
2097                 }
2098
2099                 elsif ( $version >= 1.9901 ) {
2100                     $engine = 'Catalyst::Engine::Apache2::MP19';
2101                 }
2102
2103                 elsif ( $version >= 1.24 ) {
2104                     $engine = 'Catalyst::Engine::Apache::MP13';
2105                 }
2106
2107                 else {
2108                     Catalyst::Exception->throw( message =>
2109                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2110                 }
2111
2112             }
2113
2114             # install the correct mod_perl handler
2115             if ( $version >= 1.9901 ) {
2116                 *handler = sub  : method {
2117                     shift->handle_request(@_);
2118                 };
2119             }
2120             else {
2121                 *handler = sub ($$) { shift->handle_request(@_) };
2122             }
2123
2124         }
2125
2126         elsif ( $software eq 'Zeus-Perl' ) {
2127             $engine = 'Catalyst::Engine::Zeus';
2128         }
2129
2130         else {
2131             Catalyst::Exception->throw(
2132                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2133         }
2134     }
2135
2136     unless ($engine) {
2137         $engine = $class->engine_class;
2138     }
2139
2140     Class::MOP::load_class($engine);
2141     #unless (Class::Inspector->loaded($engine)) {
2142     #    require Class::Inspector->filename($engine);
2143     #}
2144
2145     # check for old engines that are no longer compatible
2146     my $old_engine;
2147     if ( $engine->isa('Catalyst::Engine::Apache')
2148         && !Catalyst::Engine::Apache->VERSION )
2149     {
2150         $old_engine = 1;
2151     }
2152
2153     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2154         && Catalyst::Engine::Server->VERSION le '0.02' )
2155     {
2156         $old_engine = 1;
2157     }
2158
2159     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2160         && $engine->VERSION eq '0.01' )
2161     {
2162         $old_engine = 1;
2163     }
2164
2165     elsif ($engine->isa('Catalyst::Engine::Zeus')
2166         && $engine->VERSION eq '0.01' )
2167     {
2168         $old_engine = 1;
2169     }
2170
2171     if ($old_engine) {
2172         Catalyst::Exception->throw( message =>
2173               qq/Engine "$engine" is not supported by this version of Catalyst/
2174         );
2175     }
2176
2177     # engine instance
2178     $class->engine( $engine->new );
2179 }
2180
2181 =head2 $c->setup_home
2182
2183 Sets up the home directory.
2184
2185 =cut
2186
2187 sub setup_home {
2188     my ( $class, $home ) = @_;
2189
2190     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2191         $home = $env;
2192     }
2193
2194     $home ||= Catalyst::Utils::home($class);
2195
2196     if ($home) {
2197         #I remember recently being scolded for assigning config values like this
2198         $class->config->{home} ||= $home;
2199         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2200     }
2201 }
2202
2203 =head2 $c->setup_log
2204
2205 Sets up log.
2206
2207 =cut
2208
2209 sub setup_log {
2210     my ( $class, $debug ) = @_;
2211
2212     unless ( $class->log ) {
2213         $class->log( Catalyst::Log->new );
2214     }
2215
2216     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2217     if ( defined($env_debug) ? $env_debug : $debug ) {
2218         $class->meta->add_method('debug' => sub { 1 });
2219         $class->log->debug('Debug messages enabled');
2220     }
2221 }
2222
2223 =head2 $c->setup_plugins
2224
2225 Sets up plugins.
2226
2227 =cut
2228
2229 =head2 $c->setup_stats
2230
2231 Sets up timing statistics class.
2232
2233 =cut
2234
2235 sub setup_stats {
2236     my ( $class, $stats ) = @_;
2237
2238     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2239
2240     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2241     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2242         $class->meta->add_method('use_stats' => sub { 1 });
2243         $class->log->debug('Statistics enabled');
2244     }
2245 }
2246
2247
2248 =head2 $c->registered_plugins
2249
2250 Returns a sorted list of the plugins which have either been stated in the
2251 import list or which have been added via C<< MyApp->plugin(@args); >>.
2252
2253 If passed a given plugin name, it will report a boolean value indicating
2254 whether or not that plugin is loaded.  A fully qualified name is required if
2255 the plugin name does not begin with C<Catalyst::Plugin::>.
2256
2257  if ($c->registered_plugins('Some::Plugin')) {
2258      ...
2259  }
2260
2261 =cut
2262
2263 {
2264
2265     sub registered_plugins {
2266         my $proto = shift;
2267         return sort keys %{ $proto->_plugins } unless @_;
2268         my $plugin = shift;
2269         return 1 if exists $proto->_plugins->{$plugin};
2270         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2271     }
2272
2273     sub _register_plugin {
2274         my ( $proto, $plugin, $instant ) = @_;
2275         my $class = ref $proto || $proto;
2276
2277         # no ignore_loaded here, the plugin may already have been
2278         # defined in memory and we don't want to error on "no file" if so
2279
2280         Class::MOP::load_class( $plugin );
2281
2282         $proto->_plugins->{$plugin} = 1;
2283         unless ($instant) {
2284             no strict 'refs';
2285             if( $class->can('meta') ){
2286               my @superclasses = ($plugin, $class->meta->superclasses );
2287               $class->meta->superclasses(@superclasses);
2288             } else {
2289               unshift @{"$class\::ISA"}, $plugin;
2290             }
2291         }
2292         return $class;
2293     }
2294
2295     sub setup_plugins {
2296         my ( $class, $plugins ) = @_;
2297
2298         $class->_plugins( {} ) unless $class->_plugins;
2299         $plugins ||= [];
2300         for my $plugin ( reverse @$plugins ) {
2301
2302             unless ( $plugin =~ s/\A\+// ) {
2303                 $plugin = "Catalyst::Plugin::$plugin";
2304             }
2305
2306             $class->_register_plugin($plugin);
2307         }
2308     }
2309 }
2310
2311 =head2 $c->stack
2312
2313 Returns an arrayref of the internal execution stack (actions that are
2314 currently executing).
2315
2316 =head2 $c->stats_class
2317
2318 Returns or sets the stats (timing statistics) class.
2319
2320 =head2 $c->use_stats
2321
2322 Returns 1 when stats collection is enabled.  Stats collection is enabled
2323 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2324 environment variable is set.
2325
2326 Note that this is a static method, not an accessor and should be overloaded
2327 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2328
2329 =cut
2330
2331 sub use_stats { 0 }
2332
2333
2334 =head2 $c->write( $data )
2335
2336 Writes $data to the output stream. When using this method directly, you
2337 will need to manually set the C<Content-Length> header to the length of
2338 your output data, if known.
2339
2340 =cut
2341
2342 sub write {
2343     my $c = shift;
2344
2345     # Finalize headers if someone manually writes output
2346     $c->finalize_headers;
2347
2348     return $c->engine->write( $c, @_ );
2349 }
2350
2351 =head2 version
2352
2353 Returns the Catalyst version number. Mostly useful for "powered by"
2354 messages in template systems.
2355
2356 =cut
2357
2358 sub version { return $Catalyst::VERSION }
2359
2360 =head1 INTERNAL ACTIONS
2361
2362 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2363 C<_ACTION>, and C<_END>. These are by default not shown in the private
2364 action table, but you can make them visible with a config parameter.
2365
2366     MyApp->config->{show_internal_actions} = 1;
2367
2368 =head1 CASE SENSITIVITY
2369
2370 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2371 mapped to C</foo/bar>. You can activate case sensitivity with a config
2372 parameter.
2373
2374     MyApp->config->{case_sensitive} = 1;
2375
2376 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2377
2378 =head1 ON-DEMAND PARSER
2379
2380 The request body is usually parsed at the beginning of a request,
2381 but if you want to handle input yourself, you can enable on-demand
2382 parsing with a config parameter.
2383
2384     MyApp->config->{parse_on_demand} = 1;
2385
2386 =head1 PROXY SUPPORT
2387
2388 Many production servers operate using the common double-server approach,
2389 with a lightweight frontend web server passing requests to a larger
2390 backend server. An application running on the backend server must deal
2391 with two problems: the remote user always appears to be C<127.0.0.1> and
2392 the server's hostname will appear to be C<localhost> regardless of the
2393 virtual host that the user connected through.
2394
2395 Catalyst will automatically detect this situation when you are running
2396 the frontend and backend servers on the same machine. The following
2397 changes are made to the request.
2398
2399     $c->req->address is set to the user's real IP address, as read from
2400     the HTTP X-Forwarded-For header.
2401
2402     The host value for $c->req->base and $c->req->uri is set to the real
2403     host, as read from the HTTP X-Forwarded-Host header.
2404
2405 Obviously, your web server must support these headers for this to work.
2406
2407 In a more complex server farm environment where you may have your
2408 frontend proxy server(s) on different machines, you will need to set a
2409 configuration option to tell Catalyst to read the proxied data from the
2410 headers.
2411
2412     MyApp->config->{using_frontend_proxy} = 1;
2413
2414 If you do not wish to use the proxy support at all, you may set:
2415
2416     MyApp->config->{ignore_frontend_proxy} = 1;
2417
2418 =head1 THREAD SAFETY
2419
2420 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2421 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2422 believe the Catalyst core to be thread-safe.
2423
2424 If you plan to operate in a threaded environment, remember that all other
2425 modules you are using must also be thread-safe. Some modules, most notably
2426 L<DBD::SQLite>, are not thread-safe.
2427
2428 =head1 SUPPORT
2429
2430 IRC:
2431
2432     Join #catalyst on irc.perl.org.
2433
2434 Mailing Lists:
2435
2436     http://lists.rawmode.org/mailman/listinfo/catalyst
2437     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2438
2439 Web:
2440
2441     http://catalyst.perl.org
2442
2443 Wiki:
2444
2445     http://dev.catalyst.perl.org
2446
2447 =head1 SEE ALSO
2448
2449 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2450
2451 =head2 L<Catalyst::Manual> - The Catalyst Manual
2452
2453 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2454
2455 =head2 L<Catalyst::Engine> - Core engine
2456
2457 =head2 L<Catalyst::Log> - Log class.
2458
2459 =head2 L<Catalyst::Request> - Request object
2460
2461 =head2 L<Catalyst::Response> - Response object
2462
2463 =head2 L<Catalyst::Test> - The test suite.
2464
2465 =head1 PROJECT FOUNDER
2466
2467 sri: Sebastian Riedel <sri@cpan.org>
2468
2469 =head1 CONTRIBUTORS
2470
2471 abw: Andy Wardley
2472
2473 acme: Leon Brocard <leon@astray.com>
2474
2475 Andrew Bramble
2476
2477 Andrew Ford
2478
2479 Andrew Ruthven
2480
2481 andyg: Andy Grundman <andy@hybridized.org>
2482
2483 audreyt: Audrey Tang
2484
2485 bricas: Brian Cassidy <bricas@cpan.org>
2486
2487 chansen: Christian Hansen
2488
2489 chicks: Christopher Hicks
2490
2491 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2492
2493 Drew Taylor
2494
2495 esskar: Sascha Kiefer
2496
2497 fireartist: Carl Franks <cfranks@cpan.org>
2498
2499 gabb: Danijel Milicevic
2500
2501 Gary Ashton Jones
2502
2503 Geoff Richards
2504
2505 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2506
2507 jcamacho: Juan Camacho
2508
2509 Jody Belka
2510
2511 Johan Lindstrom
2512
2513 jon: Jon Schutz <jjschutz@cpan.org>
2514
2515 marcus: Marcus Ramberg <mramberg@cpan.org>
2516
2517 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2518
2519 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2520
2521 mugwump: Sam Vilain
2522
2523 naughton: David Naughton
2524
2525 ningu: David Kamholz <dkamholz@cpan.org>
2526
2527 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2528
2529 numa: Dan Sully <daniel@cpan.org>
2530
2531 obra: Jesse Vincent
2532
2533 omega: Andreas Marienborg
2534
2535 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2536
2537 rafl: Florian Ragwitz <rafl@debian.org>
2538
2539 sky: Arthur Bergman
2540
2541 the_jester: Jesse Sheidlower
2542
2543 Ulf Edvinsson
2544
2545 willert: Sebastian Willert <willert@cpan.org>
2546
2547 =head1 LICENSE
2548
2549 This library is free software, you can redistribute it and/or modify it under
2550 the same terms as Perl itself.
2551
2552 =cut
2553
2554 no Moose;
2555
2556 __PACKAGE__->meta->make_immutable;
2557
2558 1;