lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::LighttpdScriptNameFix;
  40
  41 BEGIN { require 5.008004; }
  42
  43 has stack => (is => 'ro', default => sub { [] });
  44 has stash => (is => 'rw', default => sub { {} });
  45 has state => (is => 'rw', default => 0);
  46 has stats => (is => 'rw');
  47 has action => (is => 'rw');
  48 has counter => (is => 'rw', default => sub { {} });
  49 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  50 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  51 has namespace => (is => 'rw');
  52
  53 sub depth { scalar @{ shift->stack || [] }; }
  54 sub comp { shift->component(@_) }
  55
  56 sub req {
  57     my $self = shift; return $self->request(@_);
  58 }
  59 sub res {
  60     my $self = shift; return $self->response(@_);
  61 }
  62
  63 # For backwards compatibility
  64 sub finalize_output { shift->finalize_body(@_) };
  65
  66 # For statistics
  67 our $COUNT     = 1;
  68 our $START     = time;
  69 our $RECURSION = 1000;
  70 our $DETACH    = Catalyst::Exception::Detach->new;
  71 our $GO        = Catalyst::Exception::Go->new;
  72
  73 #I imagine that very few of these really need to be class variables. if any.
  74 #maybe we should just make them attributes with a default?
  75 __PACKAGE__->mk_classdata($_)
  76   for qw/components arguments dispatcher engine log dispatcher_class
  77   engine_loader context_class request_class response_class stats_class
  78   setup_finished _psgi_app loading_psgi_file/;
  79
  80 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  81 __PACKAGE__->request_class('Catalyst::Request');
  82 __PACKAGE__->response_class('Catalyst::Response');
  83 __PACKAGE__->stats_class('Catalyst::Stats');
  84
  85 # Remember to update this in Catalyst::Runtime as well!
  86
  87 our $VERSION = '5.90002';
  88
  89 sub import {
  90     my ( $class, @arguments ) = @_;
  91
  92     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  93     # callers @ISA.
  94     return unless $class eq 'Catalyst';
  95
  96     my $caller = caller();
  97     return if $caller eq 'main';
  98
  99     my $meta = Moose::Meta::Class->initialize($caller);
 100     unless ( $caller->isa('Catalyst') ) {
 101         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 102         $meta->superclasses(@superclasses);
 103     }
 104     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 105     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 106
 107     unless( $meta->has_method('meta') ){
 108         if ($Moose::VERSION >= 1.15) {
 109             $meta->_add_meta_method('meta');
 110         }
 111         else {
 112             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 113         }
 114     }
 115
 116     $caller->arguments( [@arguments] );
 117     $caller->setup_home;
 118 }
 119
 120 sub _application { $_[0] }
 121
 122 =head1 NAME
 123
 124 Catalyst - The Elegant MVC Web Application Framework
 125
 126 =head1 SYNOPSIS
 127
 128 See the L<Catalyst::Manual> distribution for comprehensive
 129 documentation and tutorials.
 130
 131     # Install Catalyst::Devel for helpers and other development tools
 132     # use the helper to create a new application
 133     catalyst.pl MyApp
 134
 135     # add models, views, controllers
 136     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 137     script/myapp_create.pl view MyTemplate TT
 138     script/myapp_create.pl controller Search
 139
 140     # built in testserver -- use -r to restart automatically on changes
 141     # --help to see all available options
 142     script/myapp_server.pl
 143
 144     # command line testing interface
 145     script/myapp_test.pl /yada
 146
 147     ### in lib/MyApp.pm
 148     use Catalyst qw/-Debug/; # include plugins here as well
 149
 150     ### In lib/MyApp/Controller/Root.pm (autocreated)
 151     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 152         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 153         $c->stash->{template} = 'foo.tt'; # set the template
 154         # lookup something from db -- stash vars are passed to TT
 155         $c->stash->{data} =
 156           $c->model('Database::Foo')->search( { country => $args[0] } );
 157         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 158             $c->forward( 'bar' ); # process another action
 159             # do something else after forward returns
 160         }
 161     }
 162
 163     # The foo.tt TT template can use the stash data from the database
 164     [% WHILE (item = data.next) %]
 165         [% item.foo %]
 166     [% END %]
 167
 168     # called for /bar/of/soap, /bar/of/soap/10, etc.
 169     sub bar : Path('/bar/of/soap') { ... }
 170
 171     # called for all actions, from the top-most controller downwards
 172     sub auto : Private {
 173         my ( $self, $c ) = @_;
 174         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 175             $c->res->redirect( '/login' ); # require login
 176             return 0; # abort request and go immediately to end()
 177         }
 178         return 1; # success; carry on to next action
 179     }
 180
 181     # called after all actions are finished
 182     sub end : Private {
 183         my ( $self, $c ) = @_;
 184         if ( scalar @{ $c->error } ) { ... } # handle errors
 185         return if $c->res->body; # already have a response
 186         $c->forward( 'MyApp::View::TT' ); # render template
 187     }
 188
 189     ### in MyApp/Controller/Foo.pm
 190     # called for /foo/bar
 191     sub bar : Local { ... }
 192
 193     # called for /blargle
 194     sub blargle : Global { ... }
 195
 196     # an index action matches /foo, but not /foo/1, etc.
 197     sub index : Private { ... }
 198
 199     ### in MyApp/Controller/Foo/Bar.pm
 200     # called for /foo/bar/baz
 201     sub baz : Local { ... }
 202
 203     # first Root auto is called, then Foo auto, then this
 204     sub auto : Private { ... }
 205
 206     # powerful regular expression paths are also possible
 207     sub details : Regex('^product/(\w+)/details$') {
 208         my ( $self, $c ) = @_;
 209         # extract the (\w+) from the URI
 210         my $product = $c->req->captures->[0];
 211     }
 212
 213 See L<Catalyst::Manual::Intro> for additional information.
 214
 215 =head1 DESCRIPTION
 216
 217 Catalyst is a modern framework for making web applications without the
 218 pain usually associated with this process. This document is a reference
 219 to the main Catalyst application. If you are a new user, we suggest you
 220 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 221
 222 See L<Catalyst::Manual> for more documentation.
 223
 224 Catalyst plugins can be loaded by naming them as arguments to the "use
 225 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 226 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 227 C<My::Module>.
 228
 229     use Catalyst qw/My::Module/;
 230
 231 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 232 fully qualify the name by using a unary plus:
 233
 234     use Catalyst qw/
 235         My::Module
 236         +Fully::Qualified::Plugin::Name
 237     /;
 238
 239 Special flags like C<-Debug> and C<-Engine> can also be specified as
 240 arguments when Catalyst is loaded:
 241
 242     use Catalyst qw/-Debug My::Module/;
 243
 244 The position of plugins and flags in the chain is important, because
 245 they are loaded in the order in which they appear.
 246
 247 The following flags are supported:
 248
 249 =head2 -Debug
 250
 251 Enables debug output. You can also force this setting from the system
 252 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 253 settings override the application, with <MYAPP>_DEBUG having the highest
 254 priority.
 255
 256 This sets the log level to 'debug' and enables full debug output on the
 257 error screen. If you only want the latter, see L<< $c->debug >>.
 258
 259 =head2 -Engine
 260
 261 Forces Catalyst to use a specific engine. Omit the
 262 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 263
 264     use Catalyst qw/-Engine=CGI/;
 265
 266 =head2 -Home
 267
 268 Forces Catalyst to use a specific home directory, e.g.:
 269
 270     use Catalyst qw[-Home=/usr/mst];
 271
 272 This can also be done in the shell environment by setting either the
 273 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 274 is replaced with the uppercased name of your application, any "::" in
 275 the name will be replaced with underscores, e.g. MyApp::Web should use
 276 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 277
 278 If none of these are set, Catalyst will attempt to automatically detect the
 279 home directory. If you are working in a development envirnoment, Catalyst
 280 will try and find the directory containing either Makefile.PL, Build.PL or
 281 dist.ini. If the application has been installed into the system (i.e.
 282 you have done C<make install>), then Catalyst will use the path to your
 283 application module, without the .pm extension (ie, /foo/MyApp if your
 284 application was installed at /foo/MyApp.pm)
 285
 286 =head2 -Log
 287
 288     use Catalyst '-Log=warn,fatal,error';
 289
 290 Specifies a comma-delimited list of log levels.
 291
 292 =head2 -Stats
 293
 294 Enables statistics collection and reporting.
 295
 296    use Catalyst qw/-Stats=1/;
 297
 298 You can also force this setting from the system environment with CATALYST_STATS
 299 or <MYAPP>_STATS. The environment settings override the application, with
 300 <MYAPP>_STATS having the highest priority.
 301
 302 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 303
 304 =head1 METHODS
 305
 306 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 307
 308 =head2 $c->action
 309
 310 Returns a L<Catalyst::Action> object for the current action, which
 311 stringifies to the action name. See L<Catalyst::Action>.
 312
 313 =head2 $c->namespace
 314
 315 Returns the namespace of the current action, i.e., the URI prefix
 316 corresponding to the controller of the current action. For example:
 317
 318     # in Controller::Foo::Bar
 319     $c->namespace; # returns 'foo/bar';
 320
 321 =head2 $c->request
 322
 323 =head2 $c->req
 324
 325 Returns the current L<Catalyst::Request> object, giving access to
 326 information about the current client request (including parameters,
 327 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 328
 329 =head2 REQUEST FLOW HANDLING
 330
 331 =head2 $c->forward( $action [, \@arguments ] )
 332
 333 =head2 $c->forward( $class, $method, [, \@arguments ] )
 334
 335 Forwards processing to another action, by its private name. If you give a
 336 class name but no method, C<process()> is called. You may also optionally
 337 pass arguments in an arrayref. The action will receive the arguments in
 338 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 339 C<< $c->req->args >> will be restored to the previous values.
 340
 341 Any data C<return>ed from the action forwarded to, will be returned by the
 342 call to forward.
 343
 344     my $foodata = $c->forward('/foo');
 345     $c->forward('index');
 346     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 347     $c->forward('View::TT');
 348
 349 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 350 an C<< eval { } >> around the call (actually
 351 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 352 all 'dies' within the called action. If you want C<die> to propagate you
 353 need to do something like:
 354
 355     $c->forward('foo');
 356     die join "\n", @{ $c->error } if @{ $c->error };
 357
 358 Or make sure to always return true values from your actions and write
 359 your code like this:
 360
 361     $c->forward('foo') || return;
 362
 363 Another note is that C<< $c->forward >> always returns a scalar because it
 364 actually returns $c->state which operates in a scalar context.
 365 Thus, something like:
 366
 367     return @array;
 368
 369 in an action that is forwarded to is going to return a scalar,
 370 i.e. how many items are in that array, which is probably not what you want.
 371 If you need to return an array then return a reference to it,
 372 or stash it like so:
 373
 374     $c->stash->{array} = \@array;
 375
 376 and access it from the stash.
 377
 378 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 379
 380 =cut
 381
 382 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 383
 384 =head2 $c->detach( $action [, \@arguments ] )
 385
 386 =head2 $c->detach( $class, $method, [, \@arguments ] )
 387
 388 =head2 $c->detach()
 389
 390 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 391 doesn't return to the previous action when processing is finished.
 392
 393 When called with no arguments it escapes the processing chain entirely.
 394
 395 =cut
 396
 397 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 398
 399 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 400
 401 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 402
 403 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 404 but does a full dispatch, instead of just calling the new C<$action> /
 405 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 406 you go to are called, just like a new request.
 407
 408 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 409 This means, for example, that C<< $c->action >> methods such as
 410 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 411 L<reverse|Catalyst::Action/reverse> return information for the visited action
 412 when they are invoked within the visited action.  This is different from the
 413 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 414 continues to use the $c->action object from the caller action even when
 415 invoked from the callee.
 416
 417 C<< $c->stash >> is kept unchanged.
 418
 419 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 420 allows you to "wrap" another action, just as it would have been called by
 421 dispatching from a URL, while the analogous
 422 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 423 transfer control to another action as if it had been reached directly from a URL.
 424
 425 =cut
 426
 427 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 428
 429 =head2 $c->go( $action [, \@captures, \@arguments ] )
 430
 431 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 432
 433 The relationship between C<go> and
 434 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 435 the relationship between
 436 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 437 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 438 C<< $c->go >> will perform a full dispatch on the specified action or method,
 439 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 440 C<go> escapes the processing of the current request chain on completion, and
 441 does not return to its caller.
 442
 443 @arguments are arguments to the final destination of $action. @captures are
 444 arguments to the intermediate steps, if any, on the way to the final sub of
 445 $action.
 446
 447 =cut
 448
 449 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 450
 451 =head2 $c->response
 452
 453 =head2 $c->res
 454
 455 Returns the current L<Catalyst::Response> object, see there for details.
 456
 457 =head2 $c->stash
 458
 459 Returns a hashref to the stash, which may be used to store data and pass
 460 it between components during a request. You can also set hash keys by
 461 passing arguments. The stash is automatically sent to the view. The
 462 stash is cleared at the end of a request; it cannot be used for
 463 persistent storage (for this you must use a session; see
 464 L<Catalyst::Plugin::Session> for a complete system integrated with
 465 Catalyst).
 466
 467     $c->stash->{foo} = $bar;
 468     $c->stash( { moose => 'majestic', qux => 0 } );
 469     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 470
 471     # stash is automatically passed to the view for use in a template
 472     $c->forward( 'MyApp::View::TT' );
 473
 474 =cut
 475
 476 around stash => sub {
 477     my $orig = shift;
 478     my $c = shift;
 479     my $stash = $orig->($c);
 480     if (@_) {
 481         my $new_stash = @_ > 1 ? {@_} : $_[0];
 482         croak('stash takes a hash or hashref') unless ref $new_stash;
 483         foreach my $key ( keys %$new_stash ) {
 484           $stash->{$key} = $new_stash->{$key};
 485         }
 486     }
 487
 488     return $stash;
 489 };
 490
 491
 492 =head2 $c->error
 493
 494 =head2 $c->error($error, ...)
 495
 496 =head2 $c->error($arrayref)
 497
 498 Returns an arrayref containing error messages.  If Catalyst encounters an
 499 error while processing a request, it stores the error in $c->error.  This
 500 method should only be used to store fatal error messages.
 501
 502     my @error = @{ $c->error };
 503
 504 Add a new error.
 505
 506     $c->error('Something bad happened');
 507
 508 =cut
 509
 510 sub error {
 511     my $c = shift;
 512     if ( $_[0] ) {
 513         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 514         croak @$error unless ref $c;
 515         push @{ $c->{error} }, @$error;
 516     }
 517     elsif ( defined $_[0] ) { $c->{error} = undef }
 518     return $c->{error} || [];
 519 }
 520
 521
 522 =head2 $c->state
 523
 524 Contains the return value of the last executed action.
 525 Note that << $c->state >> operates in a scalar context which means that all
 526 values it returns are scalar.
 527
 528 =head2 $c->clear_errors
 529
 530 Clear errors.  You probably don't want to clear the errors unless you are
 531 implementing a custom error screen.
 532
 533 This is equivalent to running
 534
 535     $c->error(0);
 536
 537 =cut
 538
 539 sub clear_errors {
 540     my $c = shift;
 541     $c->error(0);
 542 }
 543
 544 sub _comp_search_prefixes {
 545     my $c = shift;
 546     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 547 }
 548
 549 # search components given a name and some prefixes
 550 sub _comp_names_search_prefixes {
 551     my ( $c, $name, @prefixes ) = @_;
 552     my $appclass = ref $c || $c;
 553     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 554     $filter = qr/$filter/; # Compile regex now rather than once per loop
 555
 556     # map the original component name to the sub part that we will search against
 557     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 558         grep { /$filter/ } keys %{ $c->components };
 559
 560     # undef for a name will return all
 561     return keys %eligible if !defined $name;
 562
 563     my $query  = ref $name ? $name : qr/^$name$/i;
 564     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 565
 566     return @result if @result;
 567
 568     # if we were given a regexp to search against, we're done.
 569     return if ref $name;
 570
 571     # skip regexp fallback if configured
 572     return
 573         if $appclass->config->{disable_component_resolution_regex_fallback};
 574
 575     # regexp fallback
 576     $query  = qr/$name/i;
 577     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 578
 579     # no results? try against full names
 580     if( !@result ) {
 581         @result = grep { m{$query} } keys %eligible;
 582     }
 583
 584     # don't warn if we didn't find any results, it just might not exist
 585     if( @result ) {
 586         # Disgusting hack to work out correct method name
 587         my $warn_for = lc $prefixes[0];
 588         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 589            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 590            "component resolution is unreliable and unsafe.";
 591         my $short = $result[0];
 592         # remove the component namespace prefix
 593         $short =~ s/.*?(Model|Controller|View):://;
 594         my $shortmess = Carp::shortmess('');
 595         if ($shortmess =~ m#Catalyst/Plugin#) {
 596            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 597               "plugin's config";
 598         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 599            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 600               "component's config";
 601         } else {
 602            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 603               "but if you really wanted to search, pass in a regexp as the argument " .
 604               "like so: \$c->${warn_for}(qr/${name}/)";
 605         }
 606         $c->log->warn( "${msg}$shortmess" );
 607     }
 608
 609     return @result;
 610 }
 611
 612 # Find possible names for a prefix
 613 sub _comp_names {
 614     my ( $c, @prefixes ) = @_;
 615     my $appclass = ref $c || $c;
 616
 617     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 618
 619     my @names = map { s{$filter}{}; $_; }
 620         $c->_comp_names_search_prefixes( undef, @prefixes );
 621
 622     return @names;
 623 }
 624
 625 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 626 sub _filter_component {
 627     my ( $c, $comp, @args ) = @_;
 628
 629     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 630         return $comp->ACCEPT_CONTEXT( $c, @args );
 631     }
 632
 633     return $comp;
 634 }
 635
 636 =head2 COMPONENT ACCESSORS
 637
 638 =head2 $c->controller($name)
 639
 640 Gets a L<Catalyst::Controller> instance by name.
 641
 642     $c->controller('Foo')->do_stuff;
 643
 644 If the name is omitted, will return the controller for the dispatched
 645 action.
 646
 647 If you want to search for controllers, pass in a regexp as the argument.
 648
 649     # find all controllers that start with Foo
 650     my @foo_controllers = $c->controller(qr{^Foo});
 651
 652
 653 =cut
 654
 655 sub controller {
 656     my ( $c, $name, @args ) = @_;
 657
 658     my $appclass = ref($c) || $c;
 659     if( $name ) {
 660         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 661             my $comps = $c->components;
 662             my $check = $appclass."::Controller::".$name;
 663             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 664         }
 665         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 666         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 667         return $c->_filter_component( $result[ 0 ], @args );
 668     }
 669
 670     return $c->component( $c->action->class );
 671 }
 672
 673 =head2 $c->model($name)
 674
 675 Gets a L<Catalyst::Model> instance by name.
 676
 677     $c->model('Foo')->do_stuff;
 678
 679 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 680
 681 If the name is omitted, it will look for
 682  - a model object in $c->stash->{current_model_instance}, then
 683  - a model name in $c->stash->{current_model}, then
 684  - a config setting 'default_model', or
 685  - check if there is only one model, and return it if that's the case.
 686
 687 If you want to search for models, pass in a regexp as the argument.
 688
 689     # find all models that start with Foo
 690     my @foo_models = $c->model(qr{^Foo});
 691
 692 =cut
 693
 694 sub model {
 695     my ( $c, $name, @args ) = @_;
 696     my $appclass = ref($c) || $c;
 697     if( $name ) {
 698         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 699             my $comps = $c->components;
 700             my $check = $appclass."::Model::".$name;
 701             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 702         }
 703         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 704         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 705         return $c->_filter_component( $result[ 0 ], @args );
 706     }
 707
 708     if (ref $c) {
 709         return $c->stash->{current_model_instance}
 710           if $c->stash->{current_model_instance};
 711         return $c->model( $c->stash->{current_model} )
 712           if $c->stash->{current_model};
 713     }
 714     return $c->model( $appclass->config->{default_model} )
 715       if $appclass->config->{default_model};
 716
 717     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 718
 719     if( $rest ) {
 720         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 721         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 722         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 723         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 724         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 725     }
 726
 727     return $c->_filter_component( $comp );
 728 }
 729
 730
 731 =head2 $c->view($name)
 732
 733 Gets a L<Catalyst::View> instance by name.
 734
 735     $c->view('Foo')->do_stuff;
 736
 737 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 738
 739 If the name is omitted, it will look for
 740  - a view object in $c->stash->{current_view_instance}, then
 741  - a view name in $c->stash->{current_view}, then
 742  - a config setting 'default_view', or
 743  - check if there is only one view, and return it if that's the case.
 744
 745 If you want to search for views, pass in a regexp as the argument.
 746
 747     # find all views that start with Foo
 748     my @foo_views = $c->view(qr{^Foo});
 749
 750 =cut
 751
 752 sub view {
 753     my ( $c, $name, @args ) = @_;
 754
 755     my $appclass = ref($c) || $c;
 756     if( $name ) {
 757         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 758             my $comps = $c->components;
 759             my $check = $appclass."::View::".$name;
 760             if( exists $comps->{$check} ) {
 761                 return $c->_filter_component( $comps->{$check}, @args );
 762             }
 763             else {
 764                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 765             }
 766         }
 767         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 768         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 769         return $c->_filter_component( $result[ 0 ], @args );
 770     }
 771
 772     if (ref $c) {
 773         return $c->stash->{current_view_instance}
 774           if $c->stash->{current_view_instance};
 775         return $c->view( $c->stash->{current_view} )
 776           if $c->stash->{current_view};
 777     }
 778     return $c->view( $appclass->config->{default_view} )
 779       if $appclass->config->{default_view};
 780
 781     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 782
 783     if( $rest ) {
 784         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 785         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 786         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 787         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 788         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 789     }
 790
 791     return $c->_filter_component( $comp );
 792 }
 793
 794 =head2 $c->controllers
 795
 796 Returns the available names which can be passed to $c->controller
 797
 798 =cut
 799
 800 sub controllers {
 801     my ( $c ) = @_;
 802     return $c->_comp_names(qw/Controller C/);
 803 }
 804
 805 =head2 $c->models
 806
 807 Returns the available names which can be passed to $c->model
 808
 809 =cut
 810
 811 sub models {
 812     my ( $c ) = @_;
 813     return $c->_comp_names(qw/Model M/);
 814 }
 815
 816
 817 =head2 $c->views
 818
 819 Returns the available names which can be passed to $c->view
 820
 821 =cut
 822
 823 sub views {
 824     my ( $c ) = @_;
 825     return $c->_comp_names(qw/View V/);
 826 }
 827
 828 =head2 $c->comp($name)
 829
 830 =head2 $c->component($name)
 831
 832 Gets a component object by name. This method is not recommended,
 833 unless you want to get a specific component by full
 834 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 835 should be used instead.
 836
 837 If C<$name> is a regexp, a list of components matched against the full
 838 component name will be returned.
 839
 840 If Catalyst can't find a component by name, it will fallback to regex
 841 matching by default. To disable this behaviour set
 842 disable_component_resolution_regex_fallback to a true value.
 843
 844     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 845
 846 =cut
 847
 848 sub component {
 849     my ( $c, $name, @args ) = @_;
 850
 851     if( $name ) {
 852         my $comps = $c->components;
 853
 854         if( !ref $name ) {
 855             # is it the exact name?
 856             return $c->_filter_component( $comps->{ $name }, @args )
 857                        if exists $comps->{ $name };
 858
 859             # perhaps we just omitted "MyApp"?
 860             my $composed = ( ref $c || $c ) . "::${name}";
 861             return $c->_filter_component( $comps->{ $composed }, @args )
 862                        if exists $comps->{ $composed };
 863
 864             # search all of the models, views and controllers
 865             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 866             return $c->_filter_component( $comp, @args ) if $comp;
 867         }
 868
 869         return
 870             if $c->config->{disable_component_resolution_regex_fallback};
 871
 872         # This is here so $c->comp( '::M::' ) works
 873         my $query = ref $name ? $name : qr{$name}i;
 874
 875         my @result = grep { m{$query} } keys %{ $c->components };
 876         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 877
 878         if( $result[ 0 ] ) {
 879             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 880             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 881             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 882             return $c->_filter_component( $result[ 0 ], @args );
 883         }
 884
 885         # I would expect to return an empty list here, but that breaks back-compat
 886     }
 887
 888     # fallback
 889     return sort keys %{ $c->components };
 890 }
 891
 892 =head2 CLASS DATA AND HELPER CLASSES
 893
 894 =head2 $c->config
 895
 896 Returns or takes a hashref containing the application's configuration.
 897
 898     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 899
 900 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 901 like C<myapp.conf> in your applications home directory. See
 902 L<Catalyst::Plugin::ConfigLoader>.
 903
 904 =head3 Cascading configuration
 905
 906 The config method is present on all Catalyst components, and configuration
 907 will be merged when an application is started. Configuration loaded with
 908 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 909 followed by configuration in your top level C<MyApp> class. These two
 910 configurations are merged, and then configuration data whose hash key matches a
 911 component name is merged with configuration for that component.
 912
 913 The configuration for a component is then passed to the C<new> method when a
 914 component is constructed.
 915
 916 For example:
 917
 918     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 919     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 920
 921 will mean that C<MyApp::Model::Foo> receives the following data when
 922 constructed:
 923
 924     MyApp::Model::Foo->new({
 925         bar => 'baz',
 926         quux => 'frob',
 927         overrides => 'me',
 928     });
 929
 930 It's common practice to use a Moose attribute
 931 on the receiving component to access the config value.
 932
 933     package MyApp::Model::Foo;
 934
 935     use Moose;
 936
 937     # this attr will receive 'baz' at construction time
 938     has 'bar' => (
 939         is  => 'rw',
 940         isa => 'Str',
 941     );
 942
 943 You can then get the value 'baz' by calling $c->model('Foo')->bar
 944 (or $self->bar inside code in the model).
 945
 946 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 947 as a way of reading config within your code, as this B<will not> give you the
 948 correctly merged config back. You B<MUST> take the config values supplied to
 949 the constructor and use those instead.
 950
 951 =cut
 952
 953 around config => sub {
 954     my $orig = shift;
 955     my $c = shift;
 956
 957     croak('Setting config after setup has been run is not allowed.')
 958         if ( @_ and $c->setup_finished );
 959
 960     $c->$orig(@_);
 961 };
 962
 963 =head2 $c->log
 964
 965 Returns the logging object instance. Unless it is already set, Catalyst
 966 sets this up with a L<Catalyst::Log> object. To use your own log class,
 967 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 968 C<< __PACKAGE__->setup >>.
 969
 970  __PACKAGE__->log( MyLogger->new );
 971  __PACKAGE__->setup;
 972
 973 And later:
 974
 975     $c->log->info( 'Now logging with my own logger!' );
 976
 977 Your log class should implement the methods described in
 978 L<Catalyst::Log>.
 979
 980
 981 =head2 $c->debug
 982
 983 Returns 1 if debug mode is enabled, 0 otherwise.
 984
 985 You can enable debug mode in several ways:
 986
 987 =over
 988
 989 =item By calling myapp_server.pl with the -d flag
 990
 991 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 992
 993 =item The -Debug option in your MyApp.pm
 994
 995 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 996
 997 =back
 998
 999 The first three also set the log level to 'debug'.
1000
1001 Calling C<< $c->debug(1) >> has no effect.
1002
1003 =cut
1004
1005 sub debug { 0 }
1006
1007 =head2 $c->dispatcher
1008
1009 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1010
1011 =head2 $c->engine
1012
1013 Returns the engine instance. See L<Catalyst::Engine>.
1014
1015
1016 =head2 UTILITY METHODS
1017
1018 =head2 $c->path_to(@path)
1019
1020 Merges C<@path> with C<< $c->config->{home} >> and returns a
1021 L<Path::Class::Dir> object. Note you can usually use this object as
1022 a filename, but sometimes you will have to explicitly stringify it
1023 yourself by calling the C<< ->stringify >> method.
1024
1025 For example:
1026
1027     $c->path_to( 'db', 'sqlite.db' );
1028
1029 =cut
1030
1031 sub path_to {
1032     my ( $c, @path ) = @_;
1033     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1034     if ( -d $path ) { return $path }
1035     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1036 }
1037
1038 =head2 $c->plugin( $name, $class, @args )
1039
1040 Helper method for plugins. It creates a class data accessor/mutator and
1041 loads and instantiates the given class.
1042
1043     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1044
1045     $c->prototype->define_javascript_functions;
1046
1047 B<Note:> This method of adding plugins is deprecated. The ability
1048 to add plugins like this B<will be removed> in a Catalyst 5.81.
1049 Please do not use this functionality in new code.
1050
1051 =cut
1052
1053 sub plugin {
1054     my ( $class, $name, $plugin, @args ) = @_;
1055
1056     # See block comment in t/unit_core_plugin.t
1057     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1058
1059     $class->_register_plugin( $plugin, 1 );
1060
1061     eval { $plugin->import };
1062     $class->mk_classdata($name);
1063     my $obj;
1064     eval { $obj = $plugin->new(@args) };
1065
1066     if ($@) {
1067         Catalyst::Exception->throw( message =>
1068               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1069     }
1070
1071     $class->$name($obj);
1072     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1073       if $class->debug;
1074 }
1075
1076 =head2 MyApp->setup
1077
1078 Initializes the dispatcher and engine, loads any plugins, and loads the
1079 model, view, and controller components. You may also specify an array
1080 of plugins to load here, if you choose to not load them in the C<use
1081 Catalyst> line.
1082
1083     MyApp->setup;
1084     MyApp->setup( qw/-Debug/ );
1085
1086 =cut
1087
1088 sub setup {
1089     my ( $class, @arguments ) = @_;
1090     croak('Running setup more than once')
1091         if ( $class->setup_finished );
1092
1093     unless ( $class->isa('Catalyst') ) {
1094
1095         Catalyst::Exception->throw(
1096             message => qq/'$class' does not inherit from Catalyst/ );
1097     }
1098
1099     if ( $class->arguments ) {
1100         @arguments = ( @arguments, @{ $class->arguments } );
1101     }
1102
1103     # Process options
1104     my $flags = {};
1105
1106     foreach (@arguments) {
1107
1108         if (/^-Debug$/) {
1109             $flags->{log} =
1110               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1111         }
1112         elsif (/^-(\w+)=?(.*)$/) {
1113             $flags->{ lc $1 } = $2;
1114         }
1115         else {
1116             push @{ $flags->{plugins} }, $_;
1117         }
1118     }
1119
1120     $class->setup_home( delete $flags->{home} );
1121
1122     $class->setup_log( delete $flags->{log} );
1123     $class->setup_plugins( delete $flags->{plugins} );
1124     $class->setup_dispatcher( delete $flags->{dispatcher} );
1125     if (my $engine = delete $flags->{engine}) {
1126         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1127     }
1128     $class->setup_engine();
1129     $class->setup_stats( delete $flags->{stats} );
1130
1131     for my $flag ( sort keys %{$flags} ) {
1132
1133         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1134             &$code( $class, delete $flags->{$flag} );
1135         }
1136         else {
1137             $class->log->warn(qq/Unknown flag "$flag"/);
1138         }
1139     }
1140
1141     eval { require Catalyst::Devel; };
1142     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1143         $class->log->warn(<<"EOF");
1144 You are running an old script!
1145
1146   Please update by running (this will overwrite existing files):
1147     catalyst.pl -force -scripts $class
1148
1149   or (this will not overwrite existing files):
1150     catalyst.pl -scripts $class
1151
1152 EOF
1153     }
1154
1155     if ( $class->debug ) {
1156         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1157
1158         if (@plugins) {
1159             my $column_width = Catalyst::Utils::term_width() - 6;
1160             my $t = Text::SimpleTable->new($column_width);
1161             $t->row($_) for @plugins;
1162             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1163         }
1164
1165         my $dispatcher = $class->dispatcher;
1166         my $engine     = $class->engine;
1167         my $home       = $class->config->{home};
1168
1169         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1170         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1171
1172         $home
1173           ? ( -d $home )
1174           ? $class->log->debug(qq/Found home "$home"/)
1175           : $class->log->debug(qq/Home "$home" doesn't exist/)
1176           : $class->log->debug(q/Couldn't find home/);
1177     }
1178
1179     # Call plugins setup, this is stupid and evil.
1180     # Also screws C3 badly on 5.10, hack to avoid.
1181     {
1182         no warnings qw/redefine/;
1183         local *setup = sub { };
1184         $class->setup unless $Catalyst::__AM_RESTARTING;
1185     }
1186
1187     # Initialize our data structure
1188     $class->components( {} );
1189
1190     $class->setup_components;
1191
1192     if ( $class->debug ) {
1193         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1194         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1195         for my $comp ( sort keys %{ $class->components } ) {
1196             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1197             $t->row( $comp, $type );
1198         }
1199         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1200           if ( keys %{ $class->components } );
1201     }
1202
1203     # Add our self to components, since we are also a component
1204     if( $class->isa('Catalyst::Controller') ){
1205       $class->components->{$class} = $class;
1206     }
1207
1208     $class->setup_actions;
1209
1210     if ( $class->debug ) {
1211         my $name = $class->config->{name} || 'Application';
1212         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1213     }
1214
1215     # Make sure that the application class becomes immutable at this point,
1216     B::Hooks::EndOfScope::on_scope_end {
1217         return if $@;
1218         my $meta = Class::MOP::get_metaclass_by_name($class);
1219         if (
1220             $meta->is_immutable
1221             && ! { $meta->immutable_options }->{replace_constructor}
1222             && (
1223                    $class->isa('Class::Accessor::Fast')
1224                 || $class->isa('Class::Accessor')
1225             )
1226         ) {
1227             warn "You made your application class ($class) immutable, "
1228                 . "but did not inline the\nconstructor. "
1229                 . "This will break catalyst, as your app \@ISA "
1230                 . "Class::Accessor(::Fast)?\nPlease pass "
1231                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1232         }
1233         $meta->make_immutable(
1234             replace_constructor => 1,
1235         ) unless $meta->is_immutable;
1236     };
1237
1238     if ($class->config->{case_sensitive}) {
1239         $class->log->warn($class . "->config->{case_sensitive} is set.");
1240         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1241     }
1242
1243     $class->setup_finalize;
1244     # Should be the last thing we do so that user things hooking
1245     # setup_finalize can log..
1246     $class->log->_flush() if $class->log->can('_flush');
1247     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1248 }
1249
1250 =head2 $app->setup_finalize
1251
1252 A hook to attach modifiers to. This method does not do anything except set the
1253 C<setup_finished> accessor.
1254
1255 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1256
1257 Example:
1258
1259     after setup_finalize => sub {
1260         my $app = shift;
1261
1262         ## do stuff here..
1263     };
1264
1265 =cut
1266
1267 sub setup_finalize {
1268     my ($class) = @_;
1269     $class->setup_finished(1);
1270 }
1271
1272 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1273
1274 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1275
1276 Constructs an absolute L<URI> object based on the application root, the
1277 provided path, and the additional arguments and query parameters provided.
1278 When used as a string, provides a textual URI.  If you need more flexibility
1279 than this (i.e. the option to provide relative URIs etc.) see
1280 L<Catalyst::Plugin::SmartURI>.
1281
1282 If no arguments are provided, the URI for the current action is returned.
1283 To return the current action and also provide @args, use
1284 C<< $c->uri_for( $c->action, @args ) >>.
1285
1286 If the first argument is a string, it is taken as a public URI path relative
1287 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1288 relative to the application root (if it does). It is then merged with
1289 C<< $c->request->base >>; any C<@args> are appended as additional path
1290 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1291
1292 If the first argument is a L<Catalyst::Action> it represents an action which
1293 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1294 optional C<\@captures> argument (an arrayref) allows passing the captured
1295 variables that are needed to fill in the paths of Chained and Regex actions;
1296 once the path is resolved, C<uri_for> continues as though a path was
1297 provided, appending any arguments or parameters and creating an absolute
1298 URI.
1299
1300 The captures for the current request can be found in
1301 C<< $c->request->captures >>, and actions can be resolved using
1302 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1303 path, use C<< $c->uri_for_action >> instead.
1304
1305   # Equivalent to $c->req->uri
1306   $c->uri_for($c->action, $c->req->captures,
1307       @{ $c->req->args }, $c->req->params);
1308
1309   # For the Foo action in the Bar controller
1310   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1311
1312   # Path to a static resource
1313   $c->uri_for('/static/images/logo.png');
1314
1315 =cut
1316
1317 sub uri_for {
1318     my ( $c, $path, @args ) = @_;
1319
1320     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1321         $path = $path->path_prefix;
1322         $path =~ s{/+\z}{};
1323         $path .= '/';
1324     }
1325
1326     undef($path) if (defined $path && $path eq '');
1327
1328     my $params =
1329       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1330
1331     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1332     foreach my $arg (@args) {
1333         utf8::encode($arg) if utf8::is_utf8($arg);
1334         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1335     }
1336
1337     if ( blessed($path) ) { # action object
1338         s|/|%2F|g for @args;
1339         my $captures = [ map { s|/|%2F|g; $_; }
1340                         ( scalar @args && ref $args[0] eq 'ARRAY'
1341                          ? @{ shift(@args) }
1342                          : ()) ];
1343
1344         foreach my $capture (@$captures) {
1345             utf8::encode($capture) if utf8::is_utf8($capture);
1346             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1347         }
1348
1349         my $action = $path;
1350         $path = $c->dispatcher->uri_for_action($action, $captures);
1351         if (not defined $path) {
1352             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1353                 if $c->debug;
1354             return undef;
1355         }
1356         $path = '/' if $path eq '';
1357     }
1358
1359     unshift(@args, $path);
1360
1361     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1362         my $namespace = $c->namespace;
1363         if (defined $path) { # cheesy hack to handle path '../foo'
1364            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1365         }
1366         unshift(@args, $namespace || '');
1367     }
1368
1369     # join args with '/', or a blank string
1370     my $args = join('/', grep { defined($_) } @args);
1371     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1372     $args =~ s!^/+!!;
1373     my $base = $c->req->base;
1374     my $class = ref($base);
1375     $base =~ s{(?<!/)$}{/};
1376
1377     my $query = '';
1378
1379     if (my @keys = keys %$params) {
1380       # somewhat lifted from URI::_query's query_form
1381       $query = '?'.join('&', map {
1382           my $val = $params->{$_};
1383           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1384           s/ /+/g;
1385           my $key = $_;
1386           $val = '' unless defined $val;
1387           (map {
1388               my $param = "$_";
1389               utf8::encode( $param ) if utf8::is_utf8($param);
1390               # using the URI::Escape pattern here so utf8 chars survive
1391               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1392               $param =~ s/ /+/g;
1393               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1394       } @keys);
1395     }
1396
1397     my $res = bless(\"${base}${args}${query}", $class);
1398     $res;
1399 }
1400
1401 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1402
1403 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1404
1405 =over
1406
1407 =item $path
1408
1409 A private path to the Catalyst action you want to create a URI for.
1410
1411 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1412 >> and passing the resulting C<$action> and the remaining arguments to C<<
1413 $c->uri_for >>.
1414
1415 You can also pass in a Catalyst::Action object, in which case it is passed to
1416 C<< $c->uri_for >>.
1417
1418 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1419
1420 For example, if the action looks like:
1421
1422  package MyApp::Controller::Users;
1423
1424  sub lst : Path('the-list') {}
1425
1426 You can use:
1427
1428  $c->uri_for_action('/users/lst')
1429
1430 and it will create the URI /users/the-list.
1431
1432 =back
1433
1434 =cut
1435
1436 sub uri_for_action {
1437     my ( $c, $path, @args ) = @_;
1438     my $action = blessed($path)
1439       ? $path
1440       : $c->dispatcher->get_action_by_path($path);
1441     unless (defined $action) {
1442       croak "Can't find action for path '$path'";
1443     }
1444     return $c->uri_for( $action, @args );
1445 }
1446
1447 =head2 $c->welcome_message
1448
1449 Returns the Catalyst welcome HTML page.
1450
1451 =cut
1452
1453 sub welcome_message {
1454     my $c      = shift;
1455     my $name   = $c->config->{name};
1456     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1457     my $prefix = Catalyst::Utils::appprefix( ref $c );
1458     $c->response->content_type('text/html; charset=utf-8');
1459     return <<"EOF";
1460 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1461     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1462 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1463     <head>
1464     <meta http-equiv="Content-Language" content="en" />
1465     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1466         <title>$name on Catalyst $VERSION</title>
1467         <style type="text/css">
1468             body {
1469                 color: #000;
1470                 background-color: #eee;
1471             }
1472             div#content {
1473                 width: 640px;
1474                 margin-left: auto;
1475                 margin-right: auto;
1476                 margin-top: 10px;
1477                 margin-bottom: 10px;
1478                 text-align: left;
1479                 background-color: #ccc;
1480                 border: 1px solid #aaa;
1481             }
1482             p, h1, h2 {
1483                 margin-left: 20px;
1484                 margin-right: 20px;
1485                 font-family: verdana, tahoma, sans-serif;
1486             }
1487             a {
1488                 font-family: verdana, tahoma, sans-serif;
1489             }
1490             :link, :visited {
1491                     text-decoration: none;
1492                     color: #b00;
1493                     border-bottom: 1px dotted #bbb;
1494             }
1495             :link:hover, :visited:hover {
1496                     color: #555;
1497             }
1498             div#topbar {
1499                 margin: 0px;
1500             }
1501             pre {
1502                 margin: 10px;
1503                 padding: 8px;
1504             }
1505             div#answers {
1506                 padding: 8px;
1507                 margin: 10px;
1508                 background-color: #fff;
1509                 border: 1px solid #aaa;
1510             }
1511             h1 {
1512                 font-size: 0.9em;
1513                 font-weight: normal;
1514                 text-align: center;
1515             }
1516             h2 {
1517                 font-size: 1.0em;
1518             }
1519             p {
1520                 font-size: 0.9em;
1521             }
1522             p img {
1523                 float: right;
1524                 margin-left: 10px;
1525             }
1526             span#appname {
1527                 font-weight: bold;
1528                 font-size: 1.6em;
1529             }
1530         </style>
1531     </head>
1532     <body>
1533         <div id="content">
1534             <div id="topbar">
1535                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1536                     $VERSION</h1>
1537              </div>
1538              <div id="answers">
1539                  <p>
1540                  <img src="$logo" alt="Catalyst Logo" />
1541                  </p>
1542                  <p>Welcome to the  world of Catalyst.
1543                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1544                     framework will make web development something you had
1545                     never expected it to be: Fun, rewarding, and quick.</p>
1546                  <h2>What to do now?</h2>
1547                  <p>That really depends  on what <b>you</b> want to do.
1548                     We do, however, provide you with a few starting points.</p>
1549                  <p>If you want to jump right into web development with Catalyst
1550                     you might want to start with a tutorial.</p>
1551 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1552 </pre>
1553 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1554 <pre>
1555 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1556 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1557 </code></pre>
1558                  <h2>What to do next?</h2>
1559                  <p>Next it's time to write an actual application. Use the
1560                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1561                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1562                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1563                     they can save you a lot of work.</p>
1564                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1565                     <p>Also, be sure to check out the vast and growing
1566                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1567                     you are likely to find what you need there.
1568                     </p>
1569
1570                  <h2>Need help?</h2>
1571                  <p>Catalyst has a very active community. Here are the main places to
1572                     get in touch with us.</p>
1573                  <ul>
1574                      <li>
1575                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1576                      </li>
1577                      <li>
1578                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1579                      </li>
1580                      <li>
1581                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1582                      </li>
1583                  </ul>
1584                  <h2>In conclusion</h2>
1585                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1586                     as we enjoyed making it. Please contact us if you have ideas
1587                     for improvement or other feedback.</p>
1588              </div>
1589          </div>
1590     </body>
1591 </html>
1592 EOF
1593 }
1594
1595 =head1 INTERNAL METHODS
1596
1597 These methods are not meant to be used by end users.
1598
1599 =head2 $c->components
1600
1601 Returns a hash of components.
1602
1603 =head2 $c->context_class
1604
1605 Returns or sets the context class.
1606
1607 =head2 $c->counter
1608
1609 Returns a hashref containing coderefs and execution counts (needed for
1610 deep recursion detection).
1611
1612 =head2 $c->depth
1613
1614 Returns the number of actions on the current internal execution stack.
1615
1616 =head2 $c->dispatch
1617
1618 Dispatches a request to actions.
1619
1620 =cut
1621
1622 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1623
1624 =head2 $c->dispatcher_class
1625
1626 Returns or sets the dispatcher class.
1627
1628 =head2 $c->dump_these
1629
1630 Returns a list of 2-element array references (name, structure) pairs
1631 that will be dumped on the error page in debug mode.
1632
1633 =cut
1634
1635 sub dump_these {
1636     my $c = shift;
1637     [ Request => $c->req ],
1638     [ Response => $c->res ],
1639     [ Stash => $c->stash ],
1640     [ Config => $c->config ];
1641 }
1642
1643 =head2 $c->engine_class
1644
1645 Returns or sets the engine class.
1646
1647 =head2 $c->execute( $class, $coderef )
1648
1649 Execute a coderef in given class and catch exceptions. Errors are available
1650 via $c->error.
1651
1652 =cut
1653
1654 sub execute {
1655     my ( $c, $class, $code ) = @_;
1656     $class = $c->component($class) || $class;
1657     $c->state(0);
1658
1659     if ( $c->depth >= $RECURSION ) {
1660         my $action = $code->reverse();
1661         $action = "/$action" unless $action =~ /->/;
1662         my $error = qq/Deep recursion detected calling "${action}"/;
1663         $c->log->error($error);
1664         $c->error($error);
1665         $c->state(0);
1666         return $c->state;
1667     }
1668
1669     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1670
1671     push( @{ $c->stack }, $code );
1672
1673     no warnings 'recursion';
1674     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1675     #      I have no idea how, ergo $ret (which appears to fix the issue)
1676     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1677
1678     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1679
1680     my $last = pop( @{ $c->stack } );
1681
1682     if ( my $error = $@ ) {
1683         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1684             $error->rethrow if $c->depth > 1;
1685         }
1686         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1687             $error->rethrow if $c->depth > 0;
1688         }
1689         else {
1690             unless ( ref $error ) {
1691                 no warnings 'uninitialized';
1692                 chomp $error;
1693                 my $class = $last->class;
1694                 my $name  = $last->name;
1695                 $error = qq/Caught exception in $class->$name "$error"/;
1696             }
1697             $c->error($error);
1698         }
1699         $c->state(0);
1700     }
1701     return $c->state;
1702 }
1703
1704 sub _stats_start_execute {
1705     my ( $c, $code ) = @_;
1706     my $appclass = ref($c) || $c;
1707     return if ( ( $code->name =~ /^_.*/ )
1708         && ( !$appclass->config->{show_internal_actions} ) );
1709
1710     my $action_name = $code->reverse();
1711     $c->counter->{$action_name}++;
1712
1713     my $action = $action_name;
1714     $action = "/$action" unless $action =~ /->/;
1715
1716     # determine if the call was the result of a forward
1717     # this is done by walking up the call stack and looking for a calling
1718     # sub of Catalyst::forward before the eval
1719     my $callsub = q{};
1720     for my $index ( 2 .. 11 ) {
1721         last
1722         if ( ( caller($index) )[0] eq 'Catalyst'
1723             && ( caller($index) )[3] eq '(eval)' );
1724
1725         if ( ( caller($index) )[3] =~ /forward$/ ) {
1726             $callsub = ( caller($index) )[3];
1727             $action  = "-> $action";
1728             last;
1729         }
1730     }
1731
1732     my $uid = $action_name . $c->counter->{$action_name};
1733
1734     # is this a root-level call or a forwarded call?
1735     if ( $callsub =~ /forward$/ ) {
1736         my $parent = $c->stack->[-1];
1737
1738         # forward, locate the caller
1739         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1740             $c->stats->profile(
1741                 begin  => $action,
1742                 parent => "$parent" . $c->counter->{"$parent"},
1743                 uid    => $uid,
1744             );
1745         }
1746         else {
1747
1748             # forward with no caller may come from a plugin
1749             $c->stats->profile(
1750                 begin => $action,
1751                 uid   => $uid,
1752             );
1753         }
1754     }
1755     else {
1756
1757         # root-level call
1758         $c->stats->profile(
1759             begin => $action,
1760             uid   => $uid,
1761         );
1762     }
1763     return $action;
1764
1765 }
1766
1767 sub _stats_finish_execute {
1768     my ( $c, $info ) = @_;
1769     $c->stats->profile( end => $info );
1770 }
1771
1772 =head2 $c->finalize
1773
1774 Finalizes the request.
1775
1776 =cut
1777
1778 sub finalize {
1779     my $c = shift;
1780
1781     for my $error ( @{ $c->error } ) {
1782         $c->log->error($error);
1783     }
1784
1785     # Allow engine to handle finalize flow (for POE)
1786     my $engine = $c->engine;
1787     if ( my $code = $engine->can('finalize') ) {
1788         $engine->$code($c);
1789     }
1790     else {
1791
1792         $c->finalize_uploads;
1793
1794         # Error
1795         if ( $#{ $c->error } >= 0 ) {
1796             $c->finalize_error;
1797         }
1798
1799         $c->finalize_headers;
1800
1801         # HEAD request
1802         if ( $c->request->method eq 'HEAD' ) {
1803             $c->response->body('');
1804         }
1805
1806         $c->finalize_body;
1807     }
1808
1809     $c->log_response;
1810
1811     if ($c->use_stats) {
1812         my $elapsed = sprintf '%f', $c->stats->elapsed;
1813         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1814         $c->log->info(
1815             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1816     }
1817
1818     return $c->response->status;
1819 }
1820
1821 =head2 $c->finalize_body
1822
1823 Finalizes body.
1824
1825 =cut
1826
1827 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1828
1829 =head2 $c->finalize_cookies
1830
1831 Finalizes cookies.
1832
1833 =cut
1834
1835 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1836
1837 =head2 $c->finalize_error
1838
1839 Finalizes error.
1840
1841 =cut
1842
1843 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1844
1845 =head2 $c->finalize_headers
1846
1847 Finalizes headers.
1848
1849 =cut
1850
1851 sub finalize_headers {
1852     my $c = shift;
1853
1854     my $response = $c->response; #accessor calls can add up?
1855
1856     # Check if we already finalized headers
1857     return if $response->finalized_headers;
1858
1859     # Handle redirects
1860     if ( my $location = $response->redirect ) {
1861         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1862         $response->header( Location => $location );
1863
1864         if ( !$response->has_body ) {
1865             # Add a default body if none is already present
1866             $response->body(
1867                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1868             );
1869             $response->content_type('text/html; charset=utf-8');
1870         }
1871     }
1872
1873     # Content-Length
1874     if ( defined $response->body && length $response->body && !$response->content_length ) {
1875
1876         # get the length from a filehandle
1877         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1878         {
1879             my $size = -s $response->body;
1880             if ( $size ) {
1881                 $response->content_length( $size );
1882             }
1883             else {
1884                 $c->log->warn('Serving filehandle without a content-length');
1885             }
1886         }
1887         else {
1888             # everything should be bytes at this point, but just in case
1889             $response->content_length( length( $response->body ) );
1890         }
1891     }
1892
1893     # Errors
1894     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1895         $response->headers->remove_header("Content-Length");
1896         $response->body('');
1897     }
1898
1899     $c->finalize_cookies;
1900
1901     $c->engine->finalize_headers( $c, @_ );
1902
1903     # Done
1904     $response->finalized_headers(1);
1905 }
1906
1907 =head2 $c->finalize_output
1908
1909 An alias for finalize_body.
1910
1911 =head2 $c->finalize_read
1912
1913 Finalizes the input after reading is complete.
1914
1915 =cut
1916
1917 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1918
1919 =head2 $c->finalize_uploads
1920
1921 Finalizes uploads. Cleans up any temporary files.
1922
1923 =cut
1924
1925 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1926
1927 =head2 $c->get_action( $action, $namespace )
1928
1929 Gets an action in a given namespace.
1930
1931 =cut
1932
1933 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1934
1935 =head2 $c->get_actions( $action, $namespace )
1936
1937 Gets all actions of a given name in a namespace and all parent
1938 namespaces.
1939
1940 =cut
1941
1942 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1943
1944 =head2 $app->handle_request( @arguments )
1945
1946 Called to handle each HTTP request.
1947
1948 =cut
1949
1950 sub handle_request {
1951     my ( $class, @arguments ) = @_;
1952
1953     # Always expect worst case!
1954     my $status = -1;
1955     try {
1956         if ($class->debug) {
1957             my $secs = time - $START || 1;
1958             my $av = sprintf '%.3f', $COUNT / $secs;
1959             my $time = localtime time;
1960             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1961         }
1962
1963         my $c = $class->prepare(@arguments);
1964         $c->dispatch;
1965         $status = $c->finalize;
1966     }
1967     catch {
1968         chomp(my $error = $_);
1969         $class->log->error(qq/Caught exception in engine "$error"/);
1970     };
1971
1972     $COUNT++;
1973
1974     if(my $coderef = $class->log->can('_flush')){
1975         $class->log->$coderef();
1976     }
1977     return $status;
1978 }
1979
1980 =head2 $class->prepare( @arguments )
1981
1982 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1983 etc.).
1984
1985 =cut
1986
1987 sub prepare {
1988     my ( $class, @arguments ) = @_;
1989
1990     # XXX
1991     # After the app/ctxt split, this should become an attribute based on something passed
1992     # into the application.
1993     $class->context_class( ref $class || $class ) unless $class->context_class;
1994
1995     my $c = $class->context_class->new({});
1996
1997     # For on-demand data
1998     $c->request->_context($c);
1999     $c->response->_context($c);
2000
2001     #surely this is not the most efficient way to do things...
2002     $c->stats($class->stats_class->new)->enable($c->use_stats);
2003     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2004         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2005     }
2006
2007     try {
2008         # Allow engine to direct the prepare flow (for POE)
2009         if ( my $prepare = $c->engine->can('prepare') ) {
2010             $c->engine->$prepare( $c, @arguments );
2011         }
2012         else {
2013             $c->prepare_request(@arguments);
2014             $c->prepare_connection;
2015             $c->prepare_query_parameters;
2016             $c->prepare_headers;
2017             $c->prepare_cookies;
2018             $c->prepare_path;
2019
2020             # Prepare the body for reading, either by prepare_body
2021             # or the user, if they are using $c->read
2022             $c->prepare_read;
2023
2024             # Parse the body unless the user wants it on-demand
2025             unless ( ref($c)->config->{parse_on_demand} ) {
2026                 $c->prepare_body;
2027             }
2028         }
2029     }
2030     # VERY ugly and probably shouldn't rely on ->finalize actually working
2031     catch {
2032         # failed prepare is always due to an invalid request, right?
2033         $c->response->status(400);
2034         $c->response->content_type('text/plain');
2035         $c->response->body('Bad Request');
2036         $c->finalize;
2037         die $_;
2038     };
2039
2040     my $method  = $c->req->method  || '';
2041     my $path    = $c->req->path;
2042     $path       = '/' unless length $path;
2043     my $address = $c->req->address || '';
2044
2045     $c->log_request;
2046
2047     $c->prepare_action;
2048
2049     return $c;
2050 }
2051
2052 =head2 $c->prepare_action
2053
2054 Prepares action. See L<Catalyst::Dispatcher>.
2055
2056 =cut
2057
2058 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2059
2060 =head2 $c->prepare_body
2061
2062 Prepares message body.
2063
2064 =cut
2065
2066 sub prepare_body {
2067     my $c = shift;
2068
2069     return if $c->request->_has_body;
2070
2071     # Initialize on-demand data
2072     $c->engine->prepare_body( $c, @_ );
2073     $c->prepare_parameters;
2074     $c->prepare_uploads;
2075 }
2076
2077 =head2 $c->prepare_body_chunk( $chunk )
2078
2079 Prepares a chunk of data before sending it to L<HTTP::Body>.
2080
2081 See L<Catalyst::Engine>.
2082
2083 =cut
2084
2085 sub prepare_body_chunk {
2086     my $c = shift;
2087     $c->engine->prepare_body_chunk( $c, @_ );
2088 }
2089
2090 =head2 $c->prepare_body_parameters
2091
2092 Prepares body parameters.
2093
2094 =cut
2095
2096 sub prepare_body_parameters {
2097     my $c = shift;
2098     $c->engine->prepare_body_parameters( $c, @_ );
2099 }
2100
2101 =head2 $c->prepare_connection
2102
2103 Prepares connection.
2104
2105 =cut
2106
2107 sub prepare_connection {
2108     my $c = shift;
2109     $c->engine->prepare_connection( $c, @_ );
2110 }
2111
2112 =head2 $c->prepare_cookies
2113
2114 Prepares cookies.
2115
2116 =cut
2117
2118 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2119
2120 =head2 $c->prepare_headers
2121
2122 Prepares headers.
2123
2124 =cut
2125
2126 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2127
2128 =head2 $c->prepare_parameters
2129
2130 Prepares parameters.
2131
2132 =cut
2133
2134 sub prepare_parameters {
2135     my $c = shift;
2136     $c->prepare_body_parameters;
2137     $c->engine->prepare_parameters( $c, @_ );
2138 }
2139
2140 =head2 $c->prepare_path
2141
2142 Prepares path and base.
2143
2144 =cut
2145
2146 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2147
2148 =head2 $c->prepare_query_parameters
2149
2150 Prepares query parameters.
2151
2152 =cut
2153
2154 sub prepare_query_parameters {
2155     my $c = shift;
2156
2157     $c->engine->prepare_query_parameters( $c, @_ );
2158 }
2159
2160 =head2 $c->log_request
2161
2162 Writes information about the request to the debug logs.  This includes:
2163
2164 =over 4
2165
2166 =item * Request method, path, and remote IP address
2167
2168 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2169
2170 =item * Request parameters
2171
2172 =item * File uploads
2173
2174 =back
2175
2176 =cut
2177
2178 sub log_request {
2179     my $c = shift;
2180
2181     return unless $c->debug;
2182
2183     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2184     my $request = $dump->[1];
2185
2186     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2187     $method ||= '';
2188     $path = '/' unless length $path;
2189     $address ||= '';
2190     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2191
2192     $c->log_request_headers($request->headers);
2193
2194     if ( my $keywords = $request->query_keywords ) {
2195         $c->log->debug("Query keywords are: $keywords");
2196     }
2197
2198     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2199
2200     $c->log_request_uploads($request);
2201 }
2202
2203 =head2 $c->log_response
2204
2205 Writes information about the response to the debug logs by calling
2206 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2207
2208 =cut
2209
2210 sub log_response {
2211     my $c = shift;
2212
2213     return unless $c->debug;
2214
2215     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2216     my $response = $dump->[1];
2217
2218     $c->log_response_status_line($response);
2219     $c->log_response_headers($response->headers);
2220 }
2221
2222 =head2 $c->log_response_status_line($response)
2223
2224 Writes one line of information about the response to the debug logs.  This includes:
2225
2226 =over 4
2227
2228 =item * Response status code
2229
2230 =item * Content-Type header (if present)
2231
2232 =item * Content-Length header (if present)
2233
2234 =back
2235
2236 =cut
2237
2238 sub log_response_status_line {
2239     my ($c, $response) = @_;
2240
2241     $c->log->debug(
2242         sprintf(
2243             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2244             $response->status                            || 'unknown',
2245             $response->headers->header('Content-Type')   || 'unknown',
2246             $response->headers->header('Content-Length') || 'unknown'
2247         )
2248     );
2249 }
2250
2251 =head2 $c->log_response_headers($headers);
2252
2253 Hook method which can be wrapped by plugins to log the responseheaders.
2254 No-op in the default implementation.
2255
2256 =cut
2257
2258 sub log_response_headers {}
2259
2260 =head2 $c->log_request_parameters( query => {}, body => {} )
2261
2262 Logs request parameters to debug logs
2263
2264 =cut
2265
2266 sub log_request_parameters {
2267     my $c          = shift;
2268     my %all_params = @_;
2269
2270     return unless $c->debug;
2271
2272     my $column_width = Catalyst::Utils::term_width() - 44;
2273     foreach my $type (qw(query body)) {
2274         my $params = $all_params{$type};
2275         next if ! keys %$params;
2276         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2277         for my $key ( sort keys %$params ) {
2278             my $param = $params->{$key};
2279             my $value = defined($param) ? $param : '';
2280             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2281         }
2282         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2283     }
2284 }
2285
2286 =head2 $c->log_request_uploads
2287
2288 Logs file uploads included in the request to the debug logs.
2289 The parameter name, filename, file type, and file size are all included in
2290 the debug logs.
2291
2292 =cut
2293
2294 sub log_request_uploads {
2295     my $c = shift;
2296     my $request = shift;
2297     return unless $c->debug;
2298     my $uploads = $request->uploads;
2299     if ( keys %$uploads ) {
2300         my $t = Text::SimpleTable->new(
2301             [ 12, 'Parameter' ],
2302             [ 26, 'Filename' ],
2303             [ 18, 'Type' ],
2304             [ 9,  'Size' ]
2305         );
2306         for my $key ( sort keys %$uploads ) {
2307             my $upload = $uploads->{$key};
2308             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2309                 $t->row( $key, $u->filename, $u->type, $u->size );
2310             }
2311         }
2312         $c->log->debug( "File Uploads are:\n" . $t->draw );
2313     }
2314 }
2315
2316 =head2 $c->log_request_headers($headers);
2317
2318 Hook method which can be wrapped by plugins to log the request headers.
2319 No-op in the default implementation.
2320
2321 =cut
2322
2323 sub log_request_headers {}
2324
2325 =head2 $c->log_headers($type => $headers)
2326
2327 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2328
2329 =cut
2330
2331 sub log_headers {
2332     my $c       = shift;
2333     my $type    = shift;
2334     my $headers = shift;    # an HTTP::Headers instance
2335
2336     return unless $c->debug;
2337
2338     my $column_width = Catalyst::Utils::term_width() - 28;
2339     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2340     $headers->scan(
2341         sub {
2342             my ( $name, $value ) = @_;
2343             $t->row( $name, $value );
2344         }
2345     );
2346     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2347 }
2348
2349
2350 =head2 $c->prepare_read
2351
2352 Prepares the input for reading.
2353
2354 =cut
2355
2356 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2357
2358 =head2 $c->prepare_request
2359
2360 Prepares the engine request.
2361
2362 =cut
2363
2364 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2365
2366 =head2 $c->prepare_uploads
2367
2368 Prepares uploads.
2369
2370 =cut
2371
2372 sub prepare_uploads {
2373     my $c = shift;
2374
2375     $c->engine->prepare_uploads( $c, @_ );
2376 }
2377
2378 =head2 $c->prepare_write
2379
2380 Prepares the output for writing.
2381
2382 =cut
2383
2384 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2385
2386 =head2 $c->request_class
2387
2388 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2389
2390 =head2 $c->response_class
2391
2392 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2393
2394 =head2 $c->read( [$maxlength] )
2395
2396 Reads a chunk of data from the request body. This method is designed to
2397 be used in a while loop, reading C<$maxlength> bytes on every call.
2398 C<$maxlength> defaults to the size of the request if not specified.
2399
2400 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2401 directly.
2402
2403 Warning: If you use read(), Catalyst will not process the body,
2404 so you will not be able to access POST parameters or file uploads via
2405 $c->request.  You must handle all body parsing yourself.
2406
2407 =cut
2408
2409 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2410
2411 =head2 $c->run
2412
2413 Starts the engine.
2414
2415 =cut
2416
2417 sub run {
2418   my $app = shift;
2419   $app->engine_loader->needs_psgi_engine_compat_hack ?
2420     $app->engine->run($app, @_) :
2421       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2422 }
2423
2424 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2425
2426 Sets an action in a given namespace.
2427
2428 =cut
2429
2430 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2431
2432 =head2 $c->setup_actions($component)
2433
2434 Sets up actions for a component.
2435
2436 =cut
2437
2438 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2439
2440 =head2 $c->setup_components
2441
2442 This method is called internally to set up the application's components.
2443
2444 It finds modules by calling the L<locate_components> method, expands them to
2445 package names with the L<expand_component_module> method, and then installs
2446 each component into the application.
2447
2448 The C<setup_components> config option is passed to both of the above methods.
2449
2450 Installation of each component is performed by the L<setup_component> method,
2451 below.
2452
2453 =cut
2454
2455 sub setup_components {
2456     my $class = shift;
2457
2458     my $config  = $class->config->{ setup_components };
2459
2460     my @comps = $class->locate_components($config);
2461     my %comps = map { $_ => 1 } @comps;
2462
2463     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2464     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2465         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2466     ) if $deprecatedcatalyst_component_names;
2467
2468     for my $component ( @comps ) {
2469
2470         # We pass ignore_loaded here so that overlay files for (e.g.)
2471         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2472         # we know M::P::O found a file on disk so this is safe
2473
2474         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2475     }
2476
2477     for my $component (@comps) {
2478         my $instance = $class->components->{ $component } = $class->setup_component($component);
2479         my @expanded_components = $instance->can('expand_modules')
2480             ? $instance->expand_modules( $component, $config )
2481             : $class->expand_component_module( $component, $config );
2482         for my $component (@expanded_components) {
2483             next if $comps{$component};
2484             $class->components->{ $component } = $class->setup_component($component);
2485         }
2486     }
2487 }
2488
2489 =head2 $c->locate_components( $setup_component_config )
2490
2491 This method is meant to provide a list of component modules that should be
2492 setup for the application.  By default, it will use L<Module::Pluggable>.
2493
2494 Specify a C<setup_components> config option to pass additional options directly
2495 to L<Module::Pluggable>. To add additional search paths, specify a key named
2496 C<search_extra> as an array reference. Items in the array beginning with C<::>
2497 will have the application class name prepended to them.
2498
2499 =cut
2500
2501 sub locate_components {
2502     my $class  = shift;
2503     my $config = shift;
2504
2505     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2506     my $extra   = delete $config->{ search_extra } || [];
2507
2508     push @paths, @$extra;
2509
2510     my $locator = Module::Pluggable::Object->new(
2511         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2512         %$config
2513     );
2514
2515     # XXX think about ditching this sort entirely
2516     my @comps = sort { length $a <=> length $b } $locator->plugins;
2517
2518     return @comps;
2519 }
2520
2521 =head2 $c->expand_component_module( $component, $setup_component_config )
2522
2523 Components found by C<locate_components> will be passed to this method, which
2524 is expected to return a list of component (package) names to be set up.
2525
2526 =cut
2527
2528 sub expand_component_module {
2529     my ($class, $module) = @_;
2530     return Devel::InnerPackage::list_packages( $module );
2531 }
2532
2533 =head2 $c->setup_component
2534
2535 =cut
2536
2537 sub setup_component {
2538     my( $class, $component ) = @_;
2539
2540     unless ( $component->can( 'COMPONENT' ) ) {
2541         return $component;
2542     }
2543
2544     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2545     my $config = $class->config->{ $suffix } || {};
2546     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2547     # methods also pass it. local to avoid pointlessly shitting in config
2548     # for the debug screen, as $component is already the key name.
2549     local $config->{catalyst_component_name} = $component;
2550
2551     my $instance = eval { $component->COMPONENT( $class, $config ); };
2552
2553     if ( my $error = $@ ) {
2554         chomp $error;
2555         Catalyst::Exception->throw(
2556             message => qq/Couldn't instantiate component "$component", "$error"/
2557         );
2558     }
2559
2560     unless (blessed $instance) {
2561         my $metaclass = Moose::Util::find_meta($component);
2562         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2563         my $component_method_from = $method_meta->associated_metaclass->name;
2564         my $value = defined($instance) ? $instance : 'undef';
2565         Catalyst::Exception->throw(
2566             message =>
2567             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2568         );
2569     }
2570     return $instance;
2571 }
2572
2573 =head2 $c->setup_dispatcher
2574
2575 Sets up dispatcher.
2576
2577 =cut
2578
2579 sub setup_dispatcher {
2580     my ( $class, $dispatcher ) = @_;
2581
2582     if ($dispatcher) {
2583         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2584     }
2585
2586     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2587         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2588     }
2589
2590     unless ($dispatcher) {
2591         $dispatcher = $class->dispatcher_class;
2592     }
2593
2594     Class::MOP::load_class($dispatcher);
2595
2596     # dispatcher instance
2597     $class->dispatcher( $dispatcher->new );
2598 }
2599
2600 =head2 $c->setup_engine
2601
2602 Sets up engine.
2603
2604 =cut
2605
2606 sub engine_class {
2607     my ($class, $requested_engine) = @_;
2608
2609     if (!$class->engine_loader || $requested_engine) {
2610         $class->engine_loader(
2611             Catalyst::EngineLoader->new({
2612                 application_name => $class,
2613                 (defined $requested_engine
2614                      ? (requested_engine => $requested_engine) : ()),
2615             }),
2616         );
2617     }
2618     $class->engine_loader->catalyst_engine_class;
2619 }
2620
2621 sub setup_engine {
2622     my ($class, $requested_engine) = @_;
2623
2624     my $engine = $class->engine_class($requested_engine);
2625
2626     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2627     return if $class->loading_psgi_file;
2628
2629     Class::MOP::load_class($engine);
2630
2631     if ($ENV{MOD_PERL}) {
2632         my $apache = $class->engine_loader->auto;
2633
2634         my $meta = find_meta($class);
2635         my $was_immutable = $meta->is_immutable;
2636         my %immutable_options = $meta->immutable_options;
2637         $meta->make_mutable if $was_immutable;
2638
2639         $meta->add_method(handler => sub {
2640             my $r = shift;
2641             my $psgi_app = $class->psgi_app;
2642             $apache->call_app($r, $psgi_app);
2643         });
2644
2645         $meta->make_immutable(%immutable_options) if $was_immutable;
2646     }
2647
2648     $class->engine( $engine->new );
2649
2650     return;
2651 }
2652
2653 sub _finalized_psgi_app {
2654     my ($app) = @_;
2655
2656     unless ($app->_psgi_app) {
2657         my $psgi_app = $app->_setup_psgi_app;
2658         $app->_psgi_app($psgi_app);
2659     }
2660
2661     return $app->_psgi_app;
2662 }
2663
2664 sub _setup_psgi_app {
2665     my ($app) = @_;
2666
2667     for my $home (Path::Class::Dir->new($app->config->{home})) {
2668         my $psgi_file = $home->file(
2669             Catalyst::Utils::appprefix($app) . '.psgi',
2670         );
2671
2672         next unless -e $psgi_file;
2673
2674         # If $psgi_file calls ->setup_engine, it's doing so to load
2675         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2676         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2677         # anyway. So set a flag (ick) that tells setup_engine not to populate
2678         # $c->engine or do any other things we might regret.
2679
2680         $app->loading_psgi_file(1);
2681         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2682         $app->loading_psgi_file(0);
2683
2684         return $psgi_app
2685             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2686
2687         warn <<"EOW";
2688 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2689
2690 Its content has been ignored. Please consult the Catalyst::Upgrading
2691 documentation on how to upgrade from Catalyst::Engine::PSGI.
2692 EOW
2693     }
2694
2695     return $app->apply_default_middlewares($app->psgi_app);
2696 }
2697
2698 =head2 $c->apply_default_middlewares
2699
2700 Adds the following L<Plack> middlewares to your application, since they are
2701 useful and commonly needed:
2702
2703 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2704 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2705 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2706 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2707 applied since this middleware is smart enough to conditionally apply itself).
2708
2709 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2710 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2711 $ENV{SCRIPT_NAME}
2712
2713 =cut
2714
2715
2716 sub apply_default_middlewares {
2717     my ($app, $psgi_app) = @_;
2718
2719     $psgi_app = Plack::Middleware::Conditional->wrap(
2720         $psgi_app,
2721         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2722         condition => sub {
2723             my ($env) = @_;
2724             return if $app->config->{ignore_frontend_proxy};
2725             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2726                 || $app->config->{using_frontend_proxy};
2727         },
2728     );
2729
2730     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2731     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2732     $psgi_app = Plack::Middleware::LighttpdScriptNameFix->wrap($psgi_app);
2733
2734     # we're applying this unconditionally as the middleware itself already makes
2735     # sure it doesn't fuck things up if it's not running under one of the right
2736     # IIS versions
2737     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2738
2739     return $psgi_app;
2740 }
2741
2742 =head2 $c->psgi_app
2743
2744 Returns a PSGI application code reference for the catalyst application
2745 C<$c>. This is the bare application without any middlewares
2746 applied. C<${myapp}.psgi> is not taken into account.
2747
2748 This is what you want to be using to retrieve the PSGI application code
2749 reference of your Catalyst application for use in F<.psgi> files.
2750
2751 =cut
2752
2753 sub psgi_app {
2754     my ($app) = @_;
2755     return $app->engine->build_psgi_app($app);
2756 }
2757
2758 =head2 $c->setup_home
2759
2760 Sets up the home directory.
2761
2762 =cut
2763
2764 sub setup_home {
2765     my ( $class, $home ) = @_;
2766
2767     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2768         $home = $env;
2769     }
2770
2771     $home ||= Catalyst::Utils::home($class);
2772
2773     if ($home) {
2774         #I remember recently being scolded for assigning config values like this
2775         $class->config->{home} ||= $home;
2776         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2777     }
2778 }
2779
2780 =head2 $c->setup_log
2781
2782 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2783 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2784 log to.
2785
2786 This method also installs a C<debug> method that returns a true value into the
2787 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2788 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2789
2790 Note that if the log has already been setup, by either a previous call to
2791 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2792 that this method won't actually set up the log object.
2793
2794 =cut
2795
2796 sub setup_log {
2797     my ( $class, $levels ) = @_;
2798
2799     $levels ||= '';
2800     $levels =~ s/^\s+//;
2801     $levels =~ s/\s+$//;
2802     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2803
2804     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2805     if ( defined $env_debug ) {
2806         $levels{debug} = 1 if $env_debug; # Ugly!
2807         delete($levels{debug}) unless $env_debug;
2808     }
2809
2810     unless ( $class->log ) {
2811         $class->log( Catalyst::Log->new(keys %levels) );
2812     }
2813
2814     if ( $levels{debug} ) {
2815         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2816         $class->log->debug('Debug messages enabled');
2817     }
2818 }
2819
2820 =head2 $c->setup_plugins
2821
2822 Sets up plugins.
2823
2824 =cut
2825
2826 =head2 $c->setup_stats
2827
2828 Sets up timing statistics class.
2829
2830 =cut
2831
2832 sub setup_stats {
2833     my ( $class, $stats ) = @_;
2834
2835     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2836
2837     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2838     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2839         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2840         $class->log->debug('Statistics enabled');
2841     }
2842 }
2843
2844
2845 =head2 $c->registered_plugins
2846
2847 Returns a sorted list of the plugins which have either been stated in the
2848 import list or which have been added via C<< MyApp->plugin(@args); >>.
2849
2850 If passed a given plugin name, it will report a boolean value indicating
2851 whether or not that plugin is loaded.  A fully qualified name is required if
2852 the plugin name does not begin with C<Catalyst::Plugin::>.
2853
2854  if ($c->registered_plugins('Some::Plugin')) {
2855      ...
2856  }
2857
2858 =cut
2859
2860 {
2861
2862     sub registered_plugins {
2863         my $proto = shift;
2864         return sort keys %{ $proto->_plugins } unless @_;
2865         my $plugin = shift;
2866         return 1 if exists $proto->_plugins->{$plugin};
2867         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2868     }
2869
2870     sub _register_plugin {
2871         my ( $proto, $plugin, $instant ) = @_;
2872         my $class = ref $proto || $proto;
2873
2874         Class::MOP::load_class( $plugin );
2875         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2876             if $plugin->isa( 'Catalyst::Component' );
2877         $proto->_plugins->{$plugin} = 1;
2878         unless ($instant) {
2879             my $meta = Class::MOP::get_metaclass_by_name($class);
2880             $meta->superclasses($plugin, $meta->superclasses);
2881         }
2882         return $class;
2883     }
2884
2885     sub setup_plugins {
2886         my ( $class, $plugins ) = @_;
2887
2888         $class->_plugins( {} ) unless $class->_plugins;
2889         $plugins = Data::OptList::mkopt($plugins || []);
2890
2891         my @plugins = map {
2892             [ Catalyst::Utils::resolve_namespace(
2893                   $class . '::Plugin',
2894                   'Catalyst::Plugin', $_->[0]
2895               ),
2896               $_->[1],
2897             ]
2898          } @{ $plugins };
2899
2900         for my $plugin ( reverse @plugins ) {
2901             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2902             my $meta = find_meta($plugin->[0]);
2903             next if $meta && $meta->isa('Moose::Meta::Role');
2904
2905             $class->_register_plugin($plugin->[0]);
2906         }
2907
2908         my @roles =
2909             map  { $_->[0]->name, $_->[1] }
2910             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2911             map  { [find_meta($_->[0]), $_->[1]] }
2912             @plugins;
2913
2914         Moose::Util::apply_all_roles(
2915             $class => @roles
2916         ) if @roles;
2917     }
2918 }
2919
2920 =head2 $c->stack
2921
2922 Returns an arrayref of the internal execution stack (actions that are
2923 currently executing).
2924
2925 =head2 $c->stats
2926
2927 Returns the current timing statistics object. By default Catalyst uses
2928 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2929 L<< stats_class|/"$c->stats_class" >>.
2930
2931 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2932 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2933 profile explicitly, although MyApp.pm still won't profile nor output anything
2934 by itself.
2935
2936 =head2 $c->stats_class
2937
2938 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2939
2940 =head2 $c->use_stats
2941
2942 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2943
2944 Note that this is a static method, not an accessor and should be overridden
2945 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2946
2947 =cut
2948
2949 sub use_stats { 0 }
2950
2951
2952 =head2 $c->write( $data )
2953
2954 Writes $data to the output stream. When using this method directly, you
2955 will need to manually set the C<Content-Length> header to the length of
2956 your output data, if known.
2957
2958 =cut
2959
2960 sub write {
2961     my $c = shift;
2962
2963     # Finalize headers if someone manually writes output
2964     $c->finalize_headers;
2965
2966     return $c->engine->write( $c, @_ );
2967 }
2968
2969 =head2 version
2970
2971 Returns the Catalyst version number. Mostly useful for "powered by"
2972 messages in template systems.
2973
2974 =cut
2975
2976 sub version { return $Catalyst::VERSION }
2977
2978 =head1 CONFIGURATION
2979
2980 There are a number of 'base' config variables which can be set:
2981
2982 =over
2983
2984 =item *
2985
2986 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2987
2988 =item *
2989
2990 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2991
2992 =item *
2993
2994 C<disable_component_resolution_regex_fallback> - Turns
2995 off the deprecated component resolution functionality so
2996 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2997 are called then regex search will not be attempted on string values and
2998 instead C<undef> will be returned.
2999
3000 =item *
3001
3002 C<home> - The application home directory. In an uninstalled application,
3003 this is the top level application directory. In an installed application,
3004 this will be the directory containing C<< MyApp.pm >>.
3005
3006 =item *
3007
3008 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3009
3010 =item *
3011
3012 C<name> - The name of the application in debug messages and the debug and
3013 welcome screens
3014
3015 =item *
3016
3017 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3018 until it is accessed. This allows you to (for example) check authentication (and reject
3019 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
3020
3021 =item *
3022
3023 C<root> - The root directory for templates. Usually this is just a
3024 subdirectory of the home directory, but you can set it to change the
3025 templates to a different directory.
3026
3027 =item *
3028
3029 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3030 namespaces from which components will be loaded (and constructed and stored in
3031 C<< $c->components >>).
3032
3033 =item *
3034
3035 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3036 to be shown in hit debug tables in the test server.
3037
3038 =item *
3039
3040 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3041 variable should be used for determining the request path.
3042
3043 Most web server environments pass the requested path to the application using environment variables,
3044 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3045 exposed as C<< $c->request->base >>) and the request path below that base.
3046
3047 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3048 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3049
3050 =over
3051
3052 =item use_request_uri_for_path => 0
3053
3054 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3055 The path is synthesised from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3056 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3057 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3058
3059 However this method has the major disadvantage that it is impossible to correctly decode some elements
3060 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3061 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3062 can't distinguish / vs %2F in paths (in addition to other encoded values).
3063
3064 =item use_request_uri_for_path => 1
3065
3066 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3067 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3068 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3069
3070 Given that this method of path resolution is provably more correct, it is recommended that you use
3071 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3072 aware of the implications of not being able to handle encoded URI paths correctly.
3073
3074 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3075 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3076 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3077 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3078 C<< $c->request->base >> will be incorrect.
3079
3080 =back
3081
3082 =item *
3083
3084 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3085
3086 =back
3087
3088 =head1 INTERNAL ACTIONS
3089
3090 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3091 C<_ACTION>, and C<_END>. These are by default not shown in the private
3092 action table, but you can make them visible with a config parameter.
3093
3094     MyApp->config(show_internal_actions => 1);
3095
3096 =head1 ON-DEMAND PARSER
3097
3098 The request body is usually parsed at the beginning of a request,
3099 but if you want to handle input yourself, you can enable on-demand
3100 parsing with a config parameter.
3101
3102     MyApp->config(parse_on_demand => 1);
3103
3104 =head1 PROXY SUPPORT
3105
3106 Many production servers operate using the common double-server approach,
3107 with a lightweight frontend web server passing requests to a larger
3108 backend server. An application running on the backend server must deal
3109 with two problems: the remote user always appears to be C<127.0.0.1> and
3110 the server's hostname will appear to be C<localhost> regardless of the
3111 virtual host that the user connected through.
3112
3113 Catalyst will automatically detect this situation when you are running
3114 the frontend and backend servers on the same machine. The following
3115 changes are made to the request.
3116
3117     $c->req->address is set to the user's real IP address, as read from
3118     the HTTP X-Forwarded-For header.
3119
3120     The host value for $c->req->base and $c->req->uri is set to the real
3121     host, as read from the HTTP X-Forwarded-Host header.
3122
3123 Additionally, you may be running your backend application on an insecure
3124 connection (port 80) while your frontend proxy is running under SSL.  If there
3125 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3126 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3127 be created properly.
3128
3129 In the case of passing in:
3130
3131     X-Forwarded-Port: 443
3132
3133 All calls to C<uri_for> will result in an https link, as is expected.
3134
3135 Obviously, your web server must support these headers for this to work.
3136
3137 In a more complex server farm environment where you may have your
3138 frontend proxy server(s) on different machines, you will need to set a
3139 configuration option to tell Catalyst to read the proxied data from the
3140 headers.
3141
3142     MyApp->config(using_frontend_proxy => 1);
3143
3144 If you do not wish to use the proxy support at all, you may set:
3145
3146     MyApp->config(ignore_frontend_proxy => 1);
3147
3148 =head1 THREAD SAFETY
3149
3150 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3151 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3152 believe the Catalyst core to be thread-safe.
3153
3154 If you plan to operate in a threaded environment, remember that all other
3155 modules you are using must also be thread-safe. Some modules, most notably
3156 L<DBD::SQLite>, are not thread-safe.
3157
3158 =head1 SUPPORT
3159
3160 IRC:
3161
3162     Join #catalyst on irc.perl.org.
3163
3164 Mailing Lists:
3165
3166     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3167     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3168
3169 Web:
3170
3171     http://catalyst.perl.org
3172
3173 Wiki:
3174
3175     http://dev.catalyst.perl.org
3176
3177 =head1 SEE ALSO
3178
3179 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3180
3181 =head2 L<Catalyst::Manual> - The Catalyst Manual
3182
3183 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3184
3185 =head2 L<Catalyst::Engine> - Core engine
3186
3187 =head2 L<Catalyst::Log> - Log class.
3188
3189 =head2 L<Catalyst::Request> - Request object
3190
3191 =head2 L<Catalyst::Response> - Response object
3192
3193 =head2 L<Catalyst::Test> - The test suite.
3194
3195 =head1 PROJECT FOUNDER
3196
3197 sri: Sebastian Riedel <sri@cpan.org>
3198
3199 =head1 CONTRIBUTORS
3200
3201 abw: Andy Wardley
3202
3203 acme: Leon Brocard <leon@astray.com>
3204
3205 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3206
3207 Andrew Bramble
3208
3209 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3210
3211 Andrew Ruthven
3212
3213 andyg: Andy Grundman <andy@hybridized.org>
3214
3215 audreyt: Audrey Tang
3216
3217 bricas: Brian Cassidy <bricas@cpan.org>
3218
3219 Caelum: Rafael Kitover <rkitover@io.com>
3220
3221 chansen: Christian Hansen
3222
3223 chicks: Christopher Hicks
3224
3225 Chisel Wright C<pause@herlpacker.co.uk>
3226
3227 Danijel Milicevic C<me@danijel.de>
3228
3229 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3230
3231 David Naughton, C<naughton@umn.edu>
3232
3233 David E. Wheeler
3234
3235 dhoss: Devin Austin <dhoss@cpan.org>
3236
3237 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3238
3239 Drew Taylor
3240
3241 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3242
3243 esskar: Sascha Kiefer
3244
3245 fireartist: Carl Franks <cfranks@cpan.org>
3246
3247 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3248
3249 gabb: Danijel Milicevic
3250
3251 Gary Ashton Jones
3252
3253 Gavin Henry C<ghenry@perl.me.uk>
3254
3255 Geoff Richards
3256
3257 groditi: Guillermo Roditi <groditi@gmail.com>
3258
3259 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3260
3261 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3262
3263 jcamacho: Juan Camacho
3264
3265 jester: Jesse Sheidlower C<jester@panix.com>
3266
3267 jhannah: Jay Hannah <jay@jays.net>
3268
3269 Jody Belka
3270
3271 Johan Lindstrom
3272
3273 jon: Jon Schutz <jjschutz@cpan.org>
3274
3275 Jonathan Rockway C<< <jrockway@cpan.org> >>
3276
3277 Kieren Diment C<kd@totaldatasolution.com>
3278
3279 konobi: Scott McWhirter <konobi@cpan.org>
3280
3281 marcus: Marcus Ramberg <mramberg@cpan.org>
3282
3283 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3284
3285 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3286
3287 mugwump: Sam Vilain
3288
3289 naughton: David Naughton
3290
3291 ningu: David Kamholz <dkamholz@cpan.org>
3292
3293 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3294
3295 numa: Dan Sully <daniel@cpan.org>
3296
3297 obra: Jesse Vincent
3298
3299 Octavian Rasnita
3300
3301 omega: Andreas Marienborg
3302
3303 Oleg Kostyuk <cub.uanic@gmail.com>
3304
3305 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3306
3307 rafl: Florian Ragwitz <rafl@debian.org>
3308
3309 random: Roland Lammel <lammel@cpan.org>
3310
3311 Robert Sedlacek C<< <rs@474.at> >>
3312
3313 SpiceMan: Marcel Montes
3314
3315 sky: Arthur Bergman
3316
3317 szbalint: Balint Szilakszi <szbalint@cpan.org>
3318
3319 t0m: Tomas Doran <bobtfish@bobtfish.net>
3320
3321 Ulf Edvinsson
3322
3323 Viljo Marrandi C<vilts@yahoo.com>
3324
3325 Will Hawes C<info@whawes.co.uk>
3326
3327 willert: Sebastian Willert <willert@cpan.org>
3328
3329 wreis: Wallace Reis <wallace@reis.org.br>
3330
3331 Yuval Kogman, C<nothingmuch@woobling.org>
3332
3333 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3334
3335 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3336
3337 =head1 COPYRIGHT
3338
3339 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3340
3341 =head1 LICENSE
3342
3343 This library is free software. You can redistribute it and/or modify it under
3344 the same terms as Perl itself.
3345
3346 =cut
3347
3348 no Moose;
3349
3350 __PACKAGE__->meta->make_immutable;
3351
3352 1;