lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use bytes;
   6 use Scope::Upper ();
   7 use Catalyst::Exception;
   8 use Catalyst::Log;
   9 use Catalyst::Request;
  10 use Catalyst::Request::Upload;
  11 use Catalyst::Response;
  12 use Catalyst::Utils;
  13 use Catalyst::Controller;
  14 use Devel::InnerPackage ();
  15 use File::stat;
  16 use Module::Pluggable::Object ();
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use URI ();
  21 use URI::http;
  22 use URI::https;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use Class::C3::Adopt::NEXT;
  26 use attributes;
  27 use utf8;
  28 use Carp qw/croak carp shortmess/;
  29
  30 BEGIN { require 5.008001; }
  31
  32 has stack => (is => 'ro', default => sub { [] });
  33 has stash => (is => 'rw', default => sub { {} });
  34 has state => (is => 'rw', default => 0);
  35 has stats => (is => 'rw');
  36 has action => (is => 'rw');
  37 has counter => (is => 'rw', default => sub { {} });
  38 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  39 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  40 has namespace => (is => 'rw');
  41
  42 sub depth { scalar @{ shift->stack || [] }; }
  43 sub comp { shift->component(@_) }
  44
  45 sub req {
  46     my $self = shift; return $self->request(@_);
  47 }
  48 sub res {
  49     my $self = shift; return $self->response(@_);
  50 }
  51
  52 # For backwards compatibility
  53 sub finalize_output { shift->finalize_body(@_) };
  54
  55 # For statistics
  56 our $COUNT     = 1;
  57 our $START     = time;
  58 our $RECURSION = 1000;
  59 our $DETACH    = "catalyst_detach\n";
  60 our $GO        = "catalyst_go\n";
  61
  62 #I imagine that very few of these really need to be class variables. if any.
  63 #maybe we should just make them attributes with a default?
  64 __PACKAGE__->mk_classdata($_)
  65   for qw/components arguments dispatcher engine log dispatcher_class
  66   engine_class context_class request_class response_class stats_class
  67   setup_finished/;
  68
  69 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  70 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  71 __PACKAGE__->request_class('Catalyst::Request');
  72 __PACKAGE__->response_class('Catalyst::Response');
  73 __PACKAGE__->stats_class('Catalyst::Stats');
  74
  75 # Remember to update this in Catalyst::Runtime as well!
  76
  77 our $VERSION = '5.8000_07';
  78
  79 {
  80     my $dev_version = $VERSION =~ /_\d{2}$/;
  81     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  82 }
  83
  84 $VERSION = eval $VERSION;
  85
  86 sub import {
  87     my ( $class, @arguments ) = @_;
  88
  89     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  90     # callers @ISA.
  91     return unless $class eq 'Catalyst';
  92
  93     my $caller = caller();
  94     return if $caller eq 'main';
  95
  96     # Kill Adopt::NEXT warnings if we're a non-RC version
  97     unless (_IS_DEVELOPMENT_VERSION()) {
  98         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
  99     }
 100
 101     my $meta = Moose::Meta::Class->initialize($caller);
 102     #Moose->import({ into => $caller }); #do we want to do this?
 103
 104     unless ( $caller->isa('Catalyst') ) {
 105         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 106         $meta->superclasses(@superclasses);
 107     }
 108     unless( $meta->has_method('meta') ){
 109         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 110     }
 111
 112     $caller->arguments( [@arguments] );
 113     $caller->setup_home;
 114 }
 115
 116 =head1 NAME
 117
 118 Catalyst - The Elegant MVC Web Application Framework
 119
 120 =head1 SYNOPSIS
 121
 122 See the L<Catalyst::Manual> distribution for comprehensive
 123 documentation and tutorials.
 124
 125     # Install Catalyst::Devel for helpers and other development tools
 126     # use the helper to create a new application
 127     catalyst.pl MyApp
 128
 129     # add models, views, controllers
 130     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 131     script/myapp_create.pl view MyTemplate TT
 132     script/myapp_create.pl controller Search
 133
 134     # built in testserver -- use -r to restart automatically on changes
 135     # --help to see all available options
 136     script/myapp_server.pl
 137
 138     # command line testing interface
 139     script/myapp_test.pl /yada
 140
 141     ### in lib/MyApp.pm
 142     use Catalyst qw/-Debug/; # include plugins here as well
 143
 144     ### In lib/MyApp/Controller/Root.pm (autocreated)
 145     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 146         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 147         $c->stash->{template} = 'foo.tt'; # set the template
 148         # lookup something from db -- stash vars are passed to TT
 149         $c->stash->{data} =
 150           $c->model('Database::Foo')->search( { country => $args[0] } );
 151         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 152             $c->forward( 'bar' ); # process another action
 153             # do something else after forward returns
 154         }
 155     }
 156
 157     # The foo.tt TT template can use the stash data from the database
 158     [% WHILE (item = data.next) %]
 159         [% item.foo %]
 160     [% END %]
 161
 162     # called for /bar/of/soap, /bar/of/soap/10, etc.
 163     sub bar : Path('/bar/of/soap') { ... }
 164
 165     # called for all actions, from the top-most controller downwards
 166     sub auto : Private {
 167         my ( $self, $c ) = @_;
 168         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 169             $c->res->redirect( '/login' ); # require login
 170             return 0; # abort request and go immediately to end()
 171         }
 172         return 1; # success; carry on to next action
 173     }
 174
 175     # called after all actions are finished
 176     sub end : Private {
 177         my ( $self, $c ) = @_;
 178         if ( scalar @{ $c->error } ) { ... } # handle errors
 179         return if $c->res->body; # already have a response
 180         $c->forward( 'MyApp::View::TT' ); # render template
 181     }
 182
 183     ### in MyApp/Controller/Foo.pm
 184     # called for /foo/bar
 185     sub bar : Local { ... }
 186
 187     # called for /blargle
 188     sub blargle : Global { ... }
 189
 190     # an index action matches /foo, but not /foo/1, etc.
 191     sub index : Private { ... }
 192
 193     ### in MyApp/Controller/Foo/Bar.pm
 194     # called for /foo/bar/baz
 195     sub baz : Local { ... }
 196
 197     # first Root auto is called, then Foo auto, then this
 198     sub auto : Private { ... }
 199
 200     # powerful regular expression paths are also possible
 201     sub details : Regex('^product/(\w+)/details$') {
 202         my ( $self, $c ) = @_;
 203         # extract the (\w+) from the URI
 204         my $product = $c->req->captures->[0];
 205     }
 206
 207 See L<Catalyst::Manual::Intro> for additional information.
 208
 209 =head1 DESCRIPTION
 210
 211 Catalyst is a modern framework for making web applications without the
 212 pain usually associated with this process. This document is a reference
 213 to the main Catalyst application. If you are a new user, we suggest you
 214 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 215
 216 See L<Catalyst::Manual> for more documentation.
 217
 218 Catalyst plugins can be loaded by naming them as arguments to the "use
 219 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 220 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 221 C<My::Module>.
 222
 223     use Catalyst qw/My::Module/;
 224
 225 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 226 fully qualify the name by using a unary plus:
 227
 228     use Catalyst qw/
 229         My::Module
 230         +Fully::Qualified::Plugin::Name
 231     /;
 232
 233 Special flags like C<-Debug> and C<-Engine> can also be specified as
 234 arguments when Catalyst is loaded:
 235
 236     use Catalyst qw/-Debug My::Module/;
 237
 238 The position of plugins and flags in the chain is important, because
 239 they are loaded in the order in which they appear.
 240
 241 The following flags are supported:
 242
 243 =head2 -Debug
 244
 245 Enables debug output. You can also force this setting from the system
 246 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 247 settings override the application, with <MYAPP>_DEBUG having the highest
 248 priority.
 249
 250 =head2 -Engine
 251
 252 Forces Catalyst to use a specific engine. Omit the
 253 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 254
 255     use Catalyst qw/-Engine=CGI/;
 256
 257 =head2 -Home
 258
 259 Forces Catalyst to use a specific home directory, e.g.:
 260
 261     use Catalyst qw[-Home=/usr/mst];
 262
 263 This can also be done in the shell environment by setting either the
 264 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 265 is replaced with the uppercased name of your application, any "::" in
 266 the name will be replaced with underscores, e.g. MyApp::Web should use
 267 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 268
 269 =head2 -Log
 270
 271     use Catalyst '-Log=warn,fatal,error';
 272
 273 Specifies a comma-delimited list of log levels.
 274
 275 =head2 -Stats
 276
 277 Enables statistics collection and reporting. You can also force this setting
 278 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 279 environment settings override the application, with <MYAPP>_STATS having the
 280 highest priority.
 281
 282 e.g.
 283
 284    use Catalyst qw/-Stats=1/
 285
 286 =head1 METHODS
 287
 288 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 289
 290 =head2 $c->action
 291
 292 Returns a L<Catalyst::Action> object for the current action, which
 293 stringifies to the action name. See L<Catalyst::Action>.
 294
 295 =head2 $c->namespace
 296
 297 Returns the namespace of the current action, i.e., the URI prefix
 298 corresponding to the controller of the current action. For example:
 299
 300     # in Controller::Foo::Bar
 301     $c->namespace; # returns 'foo/bar';
 302
 303 =head2 $c->request
 304
 305 =head2 $c->req
 306
 307 Returns the current L<Catalyst::Request> object, giving access to
 308 information about the current client request (including parameters,
 309 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 310
 311 =head2 REQUEST FLOW HANDLING
 312
 313 =head2 $c->forward( $action [, \@arguments ] )
 314
 315 =head2 $c->forward( $class, $method, [, \@arguments ] )
 316
 317 Forwards processing to another action, by its private name. If you give a
 318 class name but no method, C<process()> is called. You may also optionally
 319 pass arguments in an arrayref. The action will receive the arguments in
 320 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 321 C<< $c->req->args >> will be restored to the previous values.
 322
 323 Any data C<return>ed from the action forwarded to, will be returned by the
 324 call to forward.
 325
 326     my $foodata = $c->forward('/foo');
 327     $c->forward('index');
 328     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 329     $c->forward('MyApp::View::TT');
 330
 331 Note that forward implies an C<<eval { }>> around the call (actually
 332 C<execute> does), thus de-fatalizing all 'dies' within the called
 333 action. If you want C<die> to propagate you need to do something like:
 334
 335     $c->forward('foo');
 336     die $c->error if $c->error;
 337
 338 Or make sure to always return true values from your actions and write
 339 your code like this:
 340
 341     $c->forward('foo') || return;
 342
 343 =cut
 344
 345 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 346
 347 =head2 $c->detach( $action [, \@arguments ] )
 348
 349 =head2 $c->detach( $class, $method, [, \@arguments ] )
 350
 351 =head2 $c->detach()
 352
 353 The same as C<forward>, but doesn't return to the previous action when
 354 processing is finished.
 355
 356 When called with no arguments it escapes the processing chain entirely.
 357
 358 =cut
 359
 360 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 361
 362 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 363
 364 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 365
 366 Almost the same as C<forward>, but does a full dispatch, instead of just
 367 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 368 C<auto> and the method you go to are called, just like a new request.
 369
 370 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 371 This means, for example, that $c->action methods such as C<name>, C<class> and
 372 C<reverse> return information for the visited action when they are invoked
 373 within the visited action.  This is different from the behavior of C<forward>
 374 which continues to use the $c->action object from the caller action even when
 375 invoked from the callee.
 376
 377 C<$c-E<gt>stash> is kept unchanged.
 378
 379 In effect, C<visit> allows you to "wrap" another action, just as it
 380 would have been called by dispatching from a URL, while the analogous
 381 C<go> allows you to transfer control to another action as if it had
 382 been reached directly from a URL.
 383
 384 =cut
 385
 386 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 387
 388 =head2 $c->go( $action [, \@captures, \@arguments ] )
 389
 390 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 391
 392 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 393 instead of just calling the new C<$action> /
 394 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 395 method you visit are called, just like a new request.
 396
 397 C<$c-E<gt>stash> is kept unchanged.
 398
 399 =cut
 400
 401 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 402
 403 =head2 $c->response
 404
 405 =head2 $c->res
 406
 407 Returns the current L<Catalyst::Response> object, see there for details.
 408
 409 =head2 $c->stash
 410
 411 Returns a hashref to the stash, which may be used to store data and pass
 412 it between components during a request. You can also set hash keys by
 413 passing arguments. The stash is automatically sent to the view. The
 414 stash is cleared at the end of a request; it cannot be used for
 415 persistent storage (for this you must use a session; see
 416 L<Catalyst::Plugin::Session> for a complete system integrated with
 417 Catalyst).
 418
 419     $c->stash->{foo} = $bar;
 420     $c->stash( { moose => 'majestic', qux => 0 } );
 421     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 422
 423     # stash is automatically passed to the view for use in a template
 424     $c->forward( 'MyApp::View::TT' );
 425
 426 =cut
 427
 428 around stash => sub {
 429     my $orig = shift;
 430     my $c = shift;
 431     my $stash = $orig->($c);
 432     if (@_) {
 433         my $new_stash = @_ > 1 ? {@_} : $_[0];
 434         croak('stash takes a hash or hashref') unless ref $new_stash;
 435         foreach my $key ( keys %$new_stash ) {
 436           $stash->{$key} = $new_stash->{$key};
 437         }
 438     }
 439
 440     return $stash;
 441 };
 442
 443
 444 =head2 $c->error
 445
 446 =head2 $c->error($error, ...)
 447
 448 =head2 $c->error($arrayref)
 449
 450 Returns an arrayref containing error messages.  If Catalyst encounters an
 451 error while processing a request, it stores the error in $c->error.  This
 452 method should only be used to store fatal error messages.
 453
 454     my @error = @{ $c->error };
 455
 456 Add a new error.
 457
 458     $c->error('Something bad happened');
 459
 460 =cut
 461
 462 sub error {
 463     my $c = shift;
 464     if ( $_[0] ) {
 465         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 466         croak @$error unless ref $c;
 467         push @{ $c->{error} }, @$error;
 468     }
 469     elsif ( defined $_[0] ) { $c->{error} = undef }
 470     return $c->{error} || [];
 471 }
 472
 473
 474 =head2 $c->state
 475
 476 Contains the return value of the last executed action.
 477
 478 =head2 $c->clear_errors
 479
 480 Clear errors.  You probably don't want to clear the errors unless you are
 481 implementing a custom error screen.
 482
 483 This is equivalent to running
 484
 485     $c->error(0);
 486
 487 =cut
 488
 489 sub clear_errors {
 490     my $c = shift;
 491     $c->error(0);
 492 }
 493
 494 # search components given a name and some prefixes
 495 sub _comp_search_prefixes {
 496     my ( $c, $name, @prefixes ) = @_;
 497     my $appclass = ref $c || $c;
 498     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 499     $filter = qr/$filter/; # Compile regex now rather than once per loop
 500
 501     # map the original component name to the sub part that we will search against
 502     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 503         grep { /$filter/ } keys %{ $c->components };
 504
 505     # undef for a name will return all
 506     return keys %eligible if !defined $name;
 507
 508     my $query  = ref $name ? $name : qr/^$name$/i;
 509     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 510
 511     return map { $c->components->{ $_ } } @result if @result;
 512
 513     # if we were given a regexp to search against, we're done.
 514     return if ref $name;
 515
 516     # regexp fallback
 517     $query  = qr/$name/i;
 518     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 519
 520     # no results? try against full names
 521     if( !@result ) {
 522         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 523     }
 524
 525     # don't warn if we didn't find any results, it just might not exist
 526     if( @result ) {
 527         # Disgusting hack to work out correct method name
 528         my $warn_for = lc $prefixes[0];
 529         my $msg = "Used regexp fallback for \$c->{$warn_for}('${name}'), which found '" .
 530            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 531            "component resolution is unreliable and unsafe.";
 532         my $short = $result[0];
 533         $short =~ s/.*?Model:://;
 534         my $shortmess = Carp::shortmess('');
 535         if ($shortmess =~ m#Catalyst/Plugin#) {
 536            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 537               "plugin's config";
 538         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 539            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 540               "component's config";
 541         } else {
 542            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}({'${name}'}), " .
 543               "but if you really wanted to search, pass in a regexp as the argument " .
 544               "like so: \$c->${warn_for}(qr/${name}/)";
 545         }
 546         $c->log->warn( "${msg}$shortmess" );
 547     }
 548
 549     return @result;
 550 }
 551
 552 # Find possible names for a prefix
 553 sub _comp_names {
 554     my ( $c, @prefixes ) = @_;
 555     my $appclass = ref $c || $c;
 556
 557     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 558
 559     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 560     return @names;
 561 }
 562
 563 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 564 sub _filter_component {
 565     my ( $c, $comp, @args ) = @_;
 566
 567     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 568         return $comp->ACCEPT_CONTEXT( $c, @args );
 569     }
 570
 571     return $comp;
 572 }
 573
 574 =head2 COMPONENT ACCESSORS
 575
 576 =head2 $c->controller($name)
 577
 578 Gets a L<Catalyst::Controller> instance by name.
 579
 580     $c->controller('Foo')->do_stuff;
 581
 582 If the name is omitted, will return the controller for the dispatched
 583 action.
 584
 585 If you want to search for controllers, pass in a regexp as the argument.
 586
 587     # find all controllers that start with Foo
 588     my @foo_controllers = $c->controller(qr{^Foo});
 589
 590
 591 =cut
 592
 593 sub controller {
 594     my ( $c, $name, @args ) = @_;
 595
 596     if( $name ) {
 597         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 598         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 599         return $c->_filter_component( $result[ 0 ], @args );
 600     }
 601
 602     return $c->component( $c->action->class );
 603 }
 604
 605 =head2 $c->model($name)
 606
 607 Gets a L<Catalyst::Model> instance by name.
 608
 609     $c->model('Foo')->do_stuff;
 610
 611 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 612
 613 If the name is omitted, it will look for
 614  - a model object in $c->stash->{current_model_instance}, then
 615  - a model name in $c->stash->{current_model}, then
 616  - a config setting 'default_model', or
 617  - check if there is only one model, and return it if that's the case.
 618
 619 If you want to search for models, pass in a regexp as the argument.
 620
 621     # find all models that start with Foo
 622     my @foo_models = $c->model(qr{^Foo});
 623
 624 =cut
 625
 626 sub model {
 627     my ( $c, $name, @args ) = @_;
 628
 629     if( $name ) {
 630         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 631         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 632         return $c->_filter_component( $result[ 0 ], @args );
 633     }
 634
 635     if (ref $c) {
 636         return $c->stash->{current_model_instance}
 637           if $c->stash->{current_model_instance};
 638         return $c->model( $c->stash->{current_model} )
 639           if $c->stash->{current_model};
 640     }
 641     return $c->model( $c->config->{default_model} )
 642       if $c->config->{default_model};
 643
 644     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 645
 646     if( $rest ) {
 647         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 648         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 649         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 650         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 651         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 652     }
 653
 654     return $c->_filter_component( $comp );
 655 }
 656
 657
 658 =head2 $c->view($name)
 659
 660 Gets a L<Catalyst::View> instance by name.
 661
 662     $c->view('Foo')->do_stuff;
 663
 664 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 665
 666 If the name is omitted, it will look for
 667  - a view object in $c->stash->{current_view_instance}, then
 668  - a view name in $c->stash->{current_view}, then
 669  - a config setting 'default_view', or
 670  - check if there is only one view, and return it if that's the case.
 671
 672 If you want to search for views, pass in a regexp as the argument.
 673
 674     # find all views that start with Foo
 675     my @foo_views = $c->view(qr{^Foo});
 676
 677 =cut
 678
 679 sub view {
 680     my ( $c, $name, @args ) = @_;
 681
 682     if( $name ) {
 683         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 684         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 685         return $c->_filter_component( $result[ 0 ], @args );
 686     }
 687
 688     if (ref $c) {
 689         return $c->stash->{current_view_instance}
 690           if $c->stash->{current_view_instance};
 691         return $c->view( $c->stash->{current_view} )
 692           if $c->stash->{current_view};
 693     }
 694     return $c->view( $c->config->{default_view} )
 695       if $c->config->{default_view};
 696
 697     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 698
 699     if( $rest ) {
 700         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 701         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 702         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 703         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 704         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 705     }
 706
 707     return $c->_filter_component( $comp );
 708 }
 709
 710 =head2 $c->controllers
 711
 712 Returns the available names which can be passed to $c->controller
 713
 714 =cut
 715
 716 sub controllers {
 717     my ( $c ) = @_;
 718     return $c->_comp_names(qw/Controller C/);
 719 }
 720
 721 =head2 $c->models
 722
 723 Returns the available names which can be passed to $c->model
 724
 725 =cut
 726
 727 sub models {
 728     my ( $c ) = @_;
 729     return $c->_comp_names(qw/Model M/);
 730 }
 731
 732
 733 =head2 $c->views
 734
 735 Returns the available names which can be passed to $c->view
 736
 737 =cut
 738
 739 sub views {
 740     my ( $c ) = @_;
 741     return $c->_comp_names(qw/View V/);
 742 }
 743
 744 =head2 $c->comp($name)
 745
 746 =head2 $c->component($name)
 747
 748 Gets a component object by name. This method is not recommended,
 749 unless you want to get a specific component by full
 750 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 751 should be used instead.
 752
 753 If C<$name> is a regexp, a list of components matched against the full
 754 component name will be returned.
 755
 756 =cut
 757
 758 sub component {
 759     my ( $c, $name, @args ) = @_;
 760
 761     if( $name ) {
 762         my $comps = $c->components;
 763
 764         if( !ref $name ) {
 765             # is it the exact name?
 766             return $c->_filter_component( $comps->{ $name }, @args )
 767                        if exists $comps->{ $name };
 768
 769             # perhaps we just omitted "MyApp"?
 770             my $composed = ( ref $c || $c ) . "::${name}";
 771             return $c->_filter_component( $comps->{ $composed }, @args )
 772                        if exists $comps->{ $composed };
 773
 774             # search all of the models, views and controllers
 775             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 776             return $c->_filter_component( $comp, @args ) if $comp;
 777         }
 778
 779         # This is here so $c->comp( '::M::' ) works
 780         my $query = ref $name ? $name : qr{$name}i;
 781
 782         my @result = grep { m{$query} } keys %{ $c->components };
 783         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 784
 785         if( $result[ 0 ] ) {
 786             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 787             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 788             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 789             return $c->_filter_component( $result[ 0 ], @args );
 790         }
 791
 792         # I would expect to return an empty list here, but that breaks back-compat
 793     }
 794
 795     # fallback
 796     return sort keys %{ $c->components };
 797 }
 798
 799 =head2 CLASS DATA AND HELPER CLASSES
 800
 801 =head2 $c->config
 802
 803 Returns or takes a hashref containing the application's configuration.
 804
 805     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 806
 807 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 808 like myapp.conf in your applications home directory. See
 809 L<Catalyst::Plugin::ConfigLoader>.
 810
 811 =head3 Cascading configuration.
 812
 813 The config method is present on all Catalyst components, and configuration
 814 will be merged when an application is started. Configuration loaded with
 815 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 816 followed by configuration in your top level C<MyApp> class. These two
 817 configurations are merged, and then configuration data whos hash key matches a
 818 component name is merged with configuration for that component.
 819
 820 The configuration for a component is then passed to the C<new> method when a
 821 component is constructed.
 822
 823 For example:
 824
 825     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 826     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 827
 828 will mean that C<MyApp::Model::Foo> receives the following data when
 829 constructed:
 830
 831     MyApp::Model::Foo->new({
 832         bar => 'baz',
 833         quux => 'frob',
 834         overrides => 'me',
 835     });
 836
 837 =cut
 838
 839 around config => sub {
 840     my $orig = shift;
 841     my $c = shift;
 842
 843     croak('Setting config after setup has been run is not allowed.')
 844         if ( @_ and $c->setup_finished );
 845
 846     $c->$orig(@_);
 847 };
 848
 849 =head2 $c->log
 850
 851 Returns the logging object instance. Unless it is already set, Catalyst
 852 sets this up with a L<Catalyst::Log> object. To use your own log class,
 853 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 854 C<< __PACKAGE__->setup >>.
 855
 856  __PACKAGE__->log( MyLogger->new );
 857  __PACKAGE__->setup;
 858
 859 And later:
 860
 861     $c->log->info( 'Now logging with my own logger!' );
 862
 863 Your log class should implement the methods described in
 864 L<Catalyst::Log>.
 865
 866
 867 =head2 $c->debug
 868
 869 Returns 1 if debug mode is enabled, 0 otherwise.
 870
 871 You can enable debug mode in several ways:
 872
 873 =over
 874
 875 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 876
 877 =item The -Debug option in your MyApp.pm
 878
 879 =item By declaring "sub debug { 1 }" in your MyApp.pm.
 880
 881 =back
 882
 883 Calling $c->debug(1) has no effect.
 884
 885 =cut
 886
 887 sub debug { 0 }
 888
 889 =head2 $c->dispatcher
 890
 891 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 892
 893 =head2 $c->engine
 894
 895 Returns the engine instance. See L<Catalyst::Engine>.
 896
 897
 898 =head2 UTILITY METHODS
 899
 900 =head2 $c->path_to(@path)
 901
 902 Merges C<@path> with C<< $c->config->{home} >> and returns a
 903 L<Path::Class::Dir> object.
 904
 905 For example:
 906
 907     $c->path_to( 'db', 'sqlite.db' );
 908
 909 =cut
 910
 911 sub path_to {
 912     my ( $c, @path ) = @_;
 913     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 914     if ( -d $path ) { return $path }
 915     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 916 }
 917
 918 =head2 $c->plugin( $name, $class, @args )
 919
 920 Helper method for plugins. It creates a class data accessor/mutator and
 921 loads and instantiates the given class.
 922
 923     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 924
 925     $c->prototype->define_javascript_functions;
 926
 927 B<Note:> This method of adding plugins is deprecated. The ability
 928 to add plugins like this B<will be removed> in a Catalyst 5.81.
 929 Please do not use this functionality in new code.
 930
 931 =cut
 932
 933 sub plugin {
 934     my ( $class, $name, $plugin, @args ) = @_;
 935
 936     # See block comment in t/unit_core_plugin.t
 937     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 938
 939     $class->_register_plugin( $plugin, 1 );
 940
 941     eval { $plugin->import };
 942     $class->mk_classdata($name);
 943     my $obj;
 944     eval { $obj = $plugin->new(@args) };
 945
 946     if ($@) {
 947         Catalyst::Exception->throw( message =>
 948               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 949     }
 950
 951     $class->$name($obj);
 952     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 953       if $class->debug;
 954 }
 955
 956 =head2 MyApp->setup
 957
 958 Initializes the dispatcher and engine, loads any plugins, and loads the
 959 model, view, and controller components. You may also specify an array
 960 of plugins to load here, if you choose to not load them in the C<use
 961 Catalyst> line.
 962
 963     MyApp->setup;
 964     MyApp->setup( qw/-Debug/ );
 965
 966 =cut
 967
 968 sub setup {
 969     my ( $class, @arguments ) = @_;
 970     croak('Running setup more than once')
 971         if ( $class->setup_finished );
 972
 973     unless ( $class->isa('Catalyst') ) {
 974
 975         Catalyst::Exception->throw(
 976             message => qq/'$class' does not inherit from Catalyst/ );
 977     }
 978
 979     if ( $class->arguments ) {
 980         @arguments = ( @arguments, @{ $class->arguments } );
 981     }
 982
 983     # Process options
 984     my $flags = {};
 985
 986     foreach (@arguments) {
 987
 988         if (/^-Debug$/) {
 989             $flags->{log} =
 990               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 991         }
 992         elsif (/^-(\w+)=?(.*)$/) {
 993             $flags->{ lc $1 } = $2;
 994         }
 995         else {
 996             push @{ $flags->{plugins} }, $_;
 997         }
 998     }
 999
1000     $class->setup_home( delete $flags->{home} );
1001
1002     $class->setup_log( delete $flags->{log} );
1003     $class->setup_plugins( delete $flags->{plugins} );
1004     $class->setup_dispatcher( delete $flags->{dispatcher} );
1005     $class->setup_engine( delete $flags->{engine} );
1006     $class->setup_stats( delete $flags->{stats} );
1007
1008     for my $flag ( sort keys %{$flags} ) {
1009
1010         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1011             &$code( $class, delete $flags->{$flag} );
1012         }
1013         else {
1014             $class->log->warn(qq/Unknown flag "$flag"/);
1015         }
1016     }
1017
1018     eval { require Catalyst::Devel; };
1019     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1020         $class->log->warn(<<"EOF");
1021 You are running an old script!
1022
1023   Please update by running (this will overwrite existing files):
1024     catalyst.pl -force -scripts $class
1025
1026   or (this will not overwrite existing files):
1027     catalyst.pl -scripts $class
1028
1029 EOF
1030     }
1031
1032     if ( $class->debug ) {
1033         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1034
1035         if (@plugins) {
1036             my $column_width = Catalyst::Utils::term_width() - 6;
1037             my $t = Text::SimpleTable->new($column_width);
1038             $t->row($_) for @plugins;
1039             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1040         }
1041
1042         my $dispatcher = $class->dispatcher;
1043         my $engine     = $class->engine;
1044         my $home       = $class->config->{home};
1045
1046         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1047         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1048
1049         $home
1050           ? ( -d $home )
1051           ? $class->log->debug(qq/Found home "$home"/)
1052           : $class->log->debug(qq/Home "$home" doesn't exist/)
1053           : $class->log->debug(q/Couldn't find home/);
1054     }
1055
1056     # Call plugins setup, this is stupid and evil.
1057     {
1058         no warnings qw/redefine/;
1059         local *setup = sub { };
1060         $class->setup;
1061     }
1062
1063     # Initialize our data structure
1064     $class->components( {} );
1065
1066     $class->setup_components;
1067
1068     if ( $class->debug ) {
1069         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1070         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1071         for my $comp ( sort keys %{ $class->components } ) {
1072             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1073             $t->row( $comp, $type );
1074         }
1075         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1076           if ( keys %{ $class->components } );
1077     }
1078
1079     # Add our self to components, since we are also a component
1080     if( $class->isa('Catalyst::Controller') ){
1081       $class->components->{$class} = $class;
1082     }
1083
1084     $class->setup_actions;
1085
1086     if ( $class->debug ) {
1087         my $name = $class->config->{name} || 'Application';
1088         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1089     }
1090     $class->log->_flush() if $class->log->can('_flush');
1091
1092     # Make sure that the application class becomes immutable at this point,
1093     # which ensures that it gets an inlined constructor. This means that it
1094     # works even if the user has added a plugin which contains a new method.
1095     # Note however that we have to do the work on scope end, so that method
1096     # modifiers work correctly in MyApp (as you have to call setup _before_
1097     # applying modifiers).
1098     Scope::Upper::reap(sub {
1099         my $meta = Class::MOP::get_metaclass_by_name($class);
1100         $meta->make_immutable unless $meta->is_immutable;
1101     }, Scope::Upper::SCOPE(1));
1102
1103     $class->setup_finalize;
1104 }
1105
1106
1107 =head2 $app->setup_finalize
1108
1109 A hook to attach modifiers to.
1110 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1111 Also better than C< setup_finished(); >, as that is a getter method.
1112
1113     sub setup_finalize {
1114
1115         my $app = shift;
1116
1117         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1118
1119         $app->next::method(@_);
1120
1121
1122     }
1123
1124 =cut
1125
1126 sub setup_finalize {
1127     my ($class) = @_;
1128     $class->setup_finished(1);
1129 }
1130
1131 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1132
1133 =head2 $c->uri_for( $path, @args?, \%query_values? )
1134
1135 =over
1136
1137 =item $action
1138
1139 A Catalyst::Action object representing the Catalyst action you want to
1140 create a URI for. To get one for an action in the current controller,
1141 use C<< $c->action('someactionname') >>. To get one from different
1142 controller, fetch the controller using C<< $c->controller() >>, then
1143 call C<action_for> on it.
1144
1145 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1146 using C<< $c->req->captures >>.
1147
1148   # For the current action
1149   $c->uri_for($c->action, $c->req->captures);
1150
1151   # For the Foo action in the Bar controller
1152   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1153
1154 =back
1155
1156 =cut
1157
1158 sub uri_for {
1159     my ( $c, $path, @args ) = @_;
1160
1161     if ( blessed($path) ) { # action object
1162         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1163                          ? shift(@args)
1164                          : [] );
1165         my $action = $path;
1166         $path = $c->dispatcher->uri_for_action($action, $captures);
1167         if (not defined $path) {
1168             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1169                 if $c->debug;
1170             return undef;
1171         }
1172         $path = '/' if $path eq '';
1173     }
1174
1175     undef($path) if (defined $path && $path eq '');
1176
1177     my $params =
1178       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1179
1180     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1181     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1182
1183     unshift(@args, $path);
1184
1185     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1186         my $namespace = $c->namespace;
1187         if (defined $path) { # cheesy hack to handle path '../foo'
1188            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1189         }
1190         unshift(@args, $namespace || '');
1191     }
1192
1193     # join args with '/', or a blank string
1194     my $args = join('/', grep { defined($_) } @args);
1195     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1196     $args =~ s!^/+!!;
1197     my $base = $c->req->base;
1198     my $class = ref($base);
1199     $base =~ s{(?<!/)$}{/};
1200
1201     my $query = '';
1202
1203     if (my @keys = keys %$params) {
1204       # somewhat lifted from URI::_query's query_form
1205       $query = '?'.join('&', map {
1206           my $val = $params->{$_};
1207           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1208           s/ /+/g;
1209           my $key = $_;
1210           $val = '' unless defined $val;
1211           (map {
1212               $_ = "$_";
1213               utf8::encode( $_ ) if utf8::is_utf8($_);
1214               # using the URI::Escape pattern here so utf8 chars survive
1215               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1216               s/ /+/g;
1217               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1218       } @keys);
1219     }
1220
1221     my $res = bless(\"${base}${args}${query}", $class);
1222     $res;
1223 }
1224
1225 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1226
1227 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1228
1229 =over
1230
1231 =item $path
1232
1233 A private path to the Catalyst action you want to create a URI for.
1234
1235 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1236 >> and passing the resulting C<$action> and the remaining arguments to C<<
1237 $c->uri_for >>.
1238
1239 You can also pass in a Catalyst::Action object, in which case it is passed to
1240 C<< $c->uri_for >>.
1241
1242 =back
1243
1244 =cut
1245
1246 sub uri_for_action {
1247     my ( $c, $path, @args ) = @_;
1248     my $action = blessed($path)
1249       ? $path
1250       : $c->dispatcher->get_action_by_path($path);
1251     unless (defined $action) {
1252       croak "Can't find action for path '$path'";
1253     }
1254     return $c->uri_for( $action, @args );
1255 }
1256
1257 =head2 $c->welcome_message
1258
1259 Returns the Catalyst welcome HTML page.
1260
1261 =cut
1262
1263 sub welcome_message {
1264     my $c      = shift;
1265     my $name   = $c->config->{name};
1266     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1267     my $prefix = Catalyst::Utils::appprefix( ref $c );
1268     $c->response->content_type('text/html; charset=utf-8');
1269     return <<"EOF";
1270 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1271     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1272 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1273     <head>
1274     <meta http-equiv="Content-Language" content="en" />
1275     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1276         <title>$name on Catalyst $VERSION</title>
1277         <style type="text/css">
1278             body {
1279                 color: #000;
1280                 background-color: #eee;
1281             }
1282             div#content {
1283                 width: 640px;
1284                 margin-left: auto;
1285                 margin-right: auto;
1286                 margin-top: 10px;
1287                 margin-bottom: 10px;
1288                 text-align: left;
1289                 background-color: #ccc;
1290                 border: 1px solid #aaa;
1291             }
1292             p, h1, h2 {
1293                 margin-left: 20px;
1294                 margin-right: 20px;
1295                 font-family: verdana, tahoma, sans-serif;
1296             }
1297             a {
1298                 font-family: verdana, tahoma, sans-serif;
1299             }
1300             :link, :visited {
1301                     text-decoration: none;
1302                     color: #b00;
1303                     border-bottom: 1px dotted #bbb;
1304             }
1305             :link:hover, :visited:hover {
1306                     color: #555;
1307             }
1308             div#topbar {
1309                 margin: 0px;
1310             }
1311             pre {
1312                 margin: 10px;
1313                 padding: 8px;
1314             }
1315             div#answers {
1316                 padding: 8px;
1317                 margin: 10px;
1318                 background-color: #fff;
1319                 border: 1px solid #aaa;
1320             }
1321             h1 {
1322                 font-size: 0.9em;
1323                 font-weight: normal;
1324                 text-align: center;
1325             }
1326             h2 {
1327                 font-size: 1.0em;
1328             }
1329             p {
1330                 font-size: 0.9em;
1331             }
1332             p img {
1333                 float: right;
1334                 margin-left: 10px;
1335             }
1336             span#appname {
1337                 font-weight: bold;
1338                 font-size: 1.6em;
1339             }
1340         </style>
1341     </head>
1342     <body>
1343         <div id="content">
1344             <div id="topbar">
1345                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1346                     $VERSION</h1>
1347              </div>
1348              <div id="answers">
1349                  <p>
1350                  <img src="$logo" alt="Catalyst Logo" />
1351                  </p>
1352                  <p>Welcome to the  world of Catalyst.
1353                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1354                     framework will make web development something you had
1355                     never expected it to be: Fun, rewarding, and quick.</p>
1356                  <h2>What to do now?</h2>
1357                  <p>That really depends  on what <b>you</b> want to do.
1358                     We do, however, provide you with a few starting points.</p>
1359                  <p>If you want to jump right into web development with Catalyst
1360                     you might want to start with a tutorial.</p>
1361 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1362 </pre>
1363 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1364 <pre>
1365 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1366 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1367 </code></pre>
1368                  <h2>What to do next?</h2>
1369                  <p>Next it's time to write an actual application. Use the
1370                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1371                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1372                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1373                     they can save you a lot of work.</p>
1374                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1375                     <p>Also, be sure to check out the vast and growing
1376                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1377                     you are likely to find what you need there.
1378                     </p>
1379
1380                  <h2>Need help?</h2>
1381                  <p>Catalyst has a very active community. Here are the main places to
1382                     get in touch with us.</p>
1383                  <ul>
1384                      <li>
1385                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1386                      </li>
1387                      <li>
1388                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1389                      </li>
1390                      <li>
1391                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1392                      </li>
1393                  </ul>
1394                  <h2>In conclusion</h2>
1395                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1396                     as we enjoyed making it. Please contact us if you have ideas
1397                     for improvement or other feedback.</p>
1398              </div>
1399          </div>
1400     </body>
1401 </html>
1402 EOF
1403 }
1404
1405 =head1 INTERNAL METHODS
1406
1407 These methods are not meant to be used by end users.
1408
1409 =head2 $c->components
1410
1411 Returns a hash of components.
1412
1413 =head2 $c->context_class
1414
1415 Returns or sets the context class.
1416
1417 =head2 $c->counter
1418
1419 Returns a hashref containing coderefs and execution counts (needed for
1420 deep recursion detection).
1421
1422 =head2 $c->depth
1423
1424 Returns the number of actions on the current internal execution stack.
1425
1426 =head2 $c->dispatch
1427
1428 Dispatches a request to actions.
1429
1430 =cut
1431
1432 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1433
1434 =head2 $c->dispatcher_class
1435
1436 Returns or sets the dispatcher class.
1437
1438 =head2 $c->dump_these
1439
1440 Returns a list of 2-element array references (name, structure) pairs
1441 that will be dumped on the error page in debug mode.
1442
1443 =cut
1444
1445 sub dump_these {
1446     my $c = shift;
1447     [ Request => $c->req ],
1448     [ Response => $c->res ],
1449     [ Stash => $c->stash ],
1450     [ Config => $c->config ];
1451 }
1452
1453 =head2 $c->engine_class
1454
1455 Returns or sets the engine class.
1456
1457 =head2 $c->execute( $class, $coderef )
1458
1459 Execute a coderef in given class and catch exceptions. Errors are available
1460 via $c->error.
1461
1462 =cut
1463
1464 sub execute {
1465     my ( $c, $class, $code ) = @_;
1466     $class = $c->component($class) || $class;
1467     $c->state(0);
1468
1469     if ( $c->depth >= $RECURSION ) {
1470         my $action = $code->reverse();
1471         $action = "/$action" unless $action =~ /->/;
1472         my $error = qq/Deep recursion detected calling "${action}"/;
1473         $c->log->error($error);
1474         $c->error($error);
1475         $c->state(0);
1476         return $c->state;
1477     }
1478
1479     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1480
1481     push( @{ $c->stack }, $code );
1482
1483     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1484
1485     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1486
1487     my $last = pop( @{ $c->stack } );
1488
1489     if ( my $error = $@ ) {
1490         if ( !ref($error) and $error eq $DETACH ) {
1491             die $DETACH if($c->depth > 1);
1492         }
1493         elsif ( !ref($error) and $error eq $GO ) {
1494             die $GO if($c->depth > 0);
1495         }
1496         else {
1497             unless ( ref $error ) {
1498                 no warnings 'uninitialized';
1499                 chomp $error;
1500                 my $class = $last->class;
1501                 my $name  = $last->name;
1502                 $error = qq/Caught exception in $class->$name "$error"/;
1503             }
1504             $c->error($error);
1505             $c->state(0);
1506         }
1507     }
1508     return $c->state;
1509 }
1510
1511 sub _stats_start_execute {
1512     my ( $c, $code ) = @_;
1513
1514     return if ( ( $code->name =~ /^_.*/ )
1515         && ( !$c->config->{show_internal_actions} ) );
1516
1517     my $action_name = $code->reverse();
1518     $c->counter->{$action_name}++;
1519
1520     my $action = $action_name;
1521     $action = "/$action" unless $action =~ /->/;
1522
1523     # determine if the call was the result of a forward
1524     # this is done by walking up the call stack and looking for a calling
1525     # sub of Catalyst::forward before the eval
1526     my $callsub = q{};
1527     for my $index ( 2 .. 11 ) {
1528         last
1529         if ( ( caller($index) )[0] eq 'Catalyst'
1530             && ( caller($index) )[3] eq '(eval)' );
1531
1532         if ( ( caller($index) )[3] =~ /forward$/ ) {
1533             $callsub = ( caller($index) )[3];
1534             $action  = "-> $action";
1535             last;
1536         }
1537     }
1538
1539     my $uid = $action_name . $c->counter->{$action_name};
1540
1541     # is this a root-level call or a forwarded call?
1542     if ( $callsub =~ /forward$/ ) {
1543
1544         # forward, locate the caller
1545         if ( my $parent = $c->stack->[-1] ) {
1546             $c->stats->profile(
1547                 begin  => $action,
1548                 parent => "$parent" . $c->counter->{"$parent"},
1549                 uid    => $uid,
1550             );
1551         }
1552         else {
1553
1554             # forward with no caller may come from a plugin
1555             $c->stats->profile(
1556                 begin => $action,
1557                 uid   => $uid,
1558             );
1559         }
1560     }
1561     else {
1562
1563         # root-level call
1564         $c->stats->profile(
1565             begin => $action,
1566             uid   => $uid,
1567         );
1568     }
1569     return $action;
1570
1571 }
1572
1573 sub _stats_finish_execute {
1574     my ( $c, $info ) = @_;
1575     $c->stats->profile( end => $info );
1576 }
1577
1578 =head2 $c->_localize_fields( sub { }, \%keys );
1579
1580 =cut
1581
1582 #Why does this exist? This is no longer safe and WILL NOT WORK.
1583 # it doesnt seem to be used anywhere. can we remove it?
1584 sub _localize_fields {
1585     my ( $c, $localized, $code ) = ( @_ );
1586
1587     my $request = delete $localized->{request} || {};
1588     my $response = delete $localized->{response} || {};
1589
1590     local @{ $c }{ keys %$localized } = values %$localized;
1591     local @{ $c->request }{ keys %$request } = values %$request;
1592     local @{ $c->response }{ keys %$response } = values %$response;
1593
1594     $code->();
1595 }
1596
1597 =head2 $c->finalize
1598
1599 Finalizes the request.
1600
1601 =cut
1602
1603 sub finalize {
1604     my $c = shift;
1605
1606     for my $error ( @{ $c->error } ) {
1607         $c->log->error($error);
1608     }
1609
1610     # Allow engine to handle finalize flow (for POE)
1611     my $engine = $c->engine;
1612     if ( my $code = $engine->can('finalize') ) {
1613         $engine->$code($c);
1614     }
1615     else {
1616
1617         $c->finalize_uploads;
1618
1619         # Error
1620         if ( $#{ $c->error } >= 0 ) {
1621             $c->finalize_error;
1622         }
1623
1624         $c->finalize_headers;
1625
1626         # HEAD request
1627         if ( $c->request->method eq 'HEAD' ) {
1628             $c->response->body('');
1629         }
1630
1631         $c->finalize_body;
1632     }
1633
1634     if ($c->use_stats) {
1635         my $elapsed = sprintf '%f', $c->stats->elapsed;
1636         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1637         $c->log->info(
1638             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1639     }
1640
1641     return $c->response->status;
1642 }
1643
1644 =head2 $c->finalize_body
1645
1646 Finalizes body.
1647
1648 =cut
1649
1650 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1651
1652 =head2 $c->finalize_cookies
1653
1654 Finalizes cookies.
1655
1656 =cut
1657
1658 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1659
1660 =head2 $c->finalize_error
1661
1662 Finalizes error.
1663
1664 =cut
1665
1666 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1667
1668 =head2 $c->finalize_headers
1669
1670 Finalizes headers.
1671
1672 =cut
1673
1674 sub finalize_headers {
1675     my $c = shift;
1676
1677     my $response = $c->response; #accessor calls can add up?
1678
1679     # Check if we already finalized headers
1680     return if $response->finalized_headers;
1681
1682     # Handle redirects
1683     if ( my $location = $response->redirect ) {
1684         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1685         $response->header( Location => $location );
1686
1687         if ( !$response->has_body ) {
1688             # Add a default body if none is already present
1689             $response->body(
1690                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1691             );
1692         }
1693     }
1694
1695     # Content-Length
1696     if ( $response->body && !$response->content_length ) {
1697
1698         # get the length from a filehandle
1699         if ( blessed( $response->body ) && $response->body->can('read') )
1700         {
1701             my $stat = stat $response->body;
1702             if ( $stat && $stat->size > 0 ) {
1703                 $response->content_length( $stat->size );
1704             }
1705             else {
1706                 $c->log->warn('Serving filehandle without a content-length');
1707             }
1708         }
1709         else {
1710             # everything should be bytes at this point, but just in case
1711             $response->content_length( bytes::length( $response->body ) );
1712         }
1713     }
1714
1715     # Errors
1716     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1717         $response->headers->remove_header("Content-Length");
1718         $response->body('');
1719     }
1720
1721     $c->finalize_cookies;
1722
1723     $c->engine->finalize_headers( $c, @_ );
1724
1725     # Done
1726     $response->finalized_headers(1);
1727 }
1728
1729 =head2 $c->finalize_output
1730
1731 An alias for finalize_body.
1732
1733 =head2 $c->finalize_read
1734
1735 Finalizes the input after reading is complete.
1736
1737 =cut
1738
1739 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1740
1741 =head2 $c->finalize_uploads
1742
1743 Finalizes uploads. Cleans up any temporary files.
1744
1745 =cut
1746
1747 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1748
1749 =head2 $c->get_action( $action, $namespace )
1750
1751 Gets an action in a given namespace.
1752
1753 =cut
1754
1755 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1756
1757 =head2 $c->get_actions( $action, $namespace )
1758
1759 Gets all actions of a given name in a namespace and all parent
1760 namespaces.
1761
1762 =cut
1763
1764 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1765
1766 =head2 $c->handle_request( $class, @arguments )
1767
1768 Called to handle each HTTP request.
1769
1770 =cut
1771
1772 sub handle_request {
1773     my ( $class, @arguments ) = @_;
1774
1775     # Always expect worst case!
1776     my $status = -1;
1777     eval {
1778         if ($class->debug) {
1779             my $secs = time - $START || 1;
1780             my $av = sprintf '%.3f', $COUNT / $secs;
1781             my $time = localtime time;
1782             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1783         }
1784
1785         my $c = $class->prepare(@arguments);
1786         $c->dispatch;
1787         $status = $c->finalize;
1788     };
1789
1790     if ( my $error = $@ ) {
1791         chomp $error;
1792         $class->log->error(qq/Caught exception in engine "$error"/);
1793     }
1794
1795     $COUNT++;
1796
1797     if(my $coderef = $class->log->can('_flush')){
1798         $class->log->$coderef();
1799     }
1800     return $status;
1801 }
1802
1803 =head2 $c->prepare( @arguments )
1804
1805 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1806 etc.).
1807
1808 =cut
1809
1810 sub prepare {
1811     my ( $class, @arguments ) = @_;
1812
1813     # XXX
1814     # After the app/ctxt split, this should become an attribute based on something passed
1815     # into the application.
1816     $class->context_class( ref $class || $class ) unless $class->context_class;
1817
1818     my $c = $class->context_class->new({});
1819
1820     # For on-demand data
1821     $c->request->_context($c);
1822     $c->response->_context($c);
1823
1824     #surely this is not the most efficient way to do things...
1825     $c->stats($class->stats_class->new)->enable($c->use_stats);
1826     if ( $c->debug ) {
1827         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1828     }
1829
1830     #XXX reuse coderef from can
1831     # Allow engine to direct the prepare flow (for POE)
1832     if ( $c->engine->can('prepare') ) {
1833         $c->engine->prepare( $c, @arguments );
1834     }
1835     else {
1836         $c->prepare_request(@arguments);
1837         $c->prepare_connection;
1838         $c->prepare_query_parameters;
1839         $c->prepare_headers;
1840         $c->prepare_cookies;
1841         $c->prepare_path;
1842
1843         # Prepare the body for reading, either by prepare_body
1844         # or the user, if they are using $c->read
1845         $c->prepare_read;
1846
1847         # Parse the body unless the user wants it on-demand
1848         unless ( $c->config->{parse_on_demand} ) {
1849             $c->prepare_body;
1850         }
1851     }
1852
1853     my $method  = $c->req->method  || '';
1854     my $path    = $c->req->path;
1855     $path       = '/' unless length $path;
1856     my $address = $c->req->address || '';
1857
1858     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1859       if $c->debug;
1860
1861     $c->prepare_action;
1862
1863     return $c;
1864 }
1865
1866 =head2 $c->prepare_action
1867
1868 Prepares action. See L<Catalyst::Dispatcher>.
1869
1870 =cut
1871
1872 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1873
1874 =head2 $c->prepare_body
1875
1876 Prepares message body.
1877
1878 =cut
1879
1880 sub prepare_body {
1881     my $c = shift;
1882
1883     return if $c->request->_has_body;
1884
1885     # Initialize on-demand data
1886     $c->engine->prepare_body( $c, @_ );
1887     $c->prepare_parameters;
1888     $c->prepare_uploads;
1889
1890     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1891         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1892         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1893             my $param = $c->req->body_parameters->{$key};
1894             my $value = defined($param) ? $param : '';
1895             $t->row( $key,
1896                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1897         }
1898         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1899     }
1900 }
1901
1902 =head2 $c->prepare_body_chunk( $chunk )
1903
1904 Prepares a chunk of data before sending it to L<HTTP::Body>.
1905
1906 See L<Catalyst::Engine>.
1907
1908 =cut
1909
1910 sub prepare_body_chunk {
1911     my $c = shift;
1912     $c->engine->prepare_body_chunk( $c, @_ );
1913 }
1914
1915 =head2 $c->prepare_body_parameters
1916
1917 Prepares body parameters.
1918
1919 =cut
1920
1921 sub prepare_body_parameters {
1922     my $c = shift;
1923     $c->engine->prepare_body_parameters( $c, @_ );
1924 }
1925
1926 =head2 $c->prepare_connection
1927
1928 Prepares connection.
1929
1930 =cut
1931
1932 sub prepare_connection {
1933     my $c = shift;
1934     $c->engine->prepare_connection( $c, @_ );
1935 }
1936
1937 =head2 $c->prepare_cookies
1938
1939 Prepares cookies.
1940
1941 =cut
1942
1943 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1944
1945 =head2 $c->prepare_headers
1946
1947 Prepares headers.
1948
1949 =cut
1950
1951 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1952
1953 =head2 $c->prepare_parameters
1954
1955 Prepares parameters.
1956
1957 =cut
1958
1959 sub prepare_parameters {
1960     my $c = shift;
1961     $c->prepare_body_parameters;
1962     $c->engine->prepare_parameters( $c, @_ );
1963 }
1964
1965 =head2 $c->prepare_path
1966
1967 Prepares path and base.
1968
1969 =cut
1970
1971 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1972
1973 =head2 $c->prepare_query_parameters
1974
1975 Prepares query parameters.
1976
1977 =cut
1978
1979 sub prepare_query_parameters {
1980     my $c = shift;
1981
1982     $c->engine->prepare_query_parameters( $c, @_ );
1983
1984     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1985         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1986         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1987             my $param = $c->req->query_parameters->{$key};
1988             my $value = defined($param) ? $param : '';
1989             $t->row( $key,
1990                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1991         }
1992         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1993     }
1994 }
1995
1996 =head2 $c->prepare_read
1997
1998 Prepares the input for reading.
1999
2000 =cut
2001
2002 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2003
2004 =head2 $c->prepare_request
2005
2006 Prepares the engine request.
2007
2008 =cut
2009
2010 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2011
2012 =head2 $c->prepare_uploads
2013
2014 Prepares uploads.
2015
2016 =cut
2017
2018 sub prepare_uploads {
2019     my $c = shift;
2020
2021     $c->engine->prepare_uploads( $c, @_ );
2022
2023     if ( $c->debug && keys %{ $c->request->uploads } ) {
2024         my $t = Text::SimpleTable->new(
2025             [ 12, 'Parameter' ],
2026             [ 26, 'Filename' ],
2027             [ 18, 'Type' ],
2028             [ 9,  'Size' ]
2029         );
2030         for my $key ( sort keys %{ $c->request->uploads } ) {
2031             my $upload = $c->request->uploads->{$key};
2032             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2033                 $t->row( $key, $u->filename, $u->type, $u->size );
2034             }
2035         }
2036         $c->log->debug( "File Uploads are:\n" . $t->draw );
2037     }
2038 }
2039
2040 =head2 $c->prepare_write
2041
2042 Prepares the output for writing.
2043
2044 =cut
2045
2046 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2047
2048 =head2 $c->request_class
2049
2050 Returns or sets the request class.
2051
2052 =head2 $c->response_class
2053
2054 Returns or sets the response class.
2055
2056 =head2 $c->read( [$maxlength] )
2057
2058 Reads a chunk of data from the request body. This method is designed to
2059 be used in a while loop, reading C<$maxlength> bytes on every call.
2060 C<$maxlength> defaults to the size of the request if not specified.
2061
2062 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
2063 directly.
2064
2065 Warning: If you use read(), Catalyst will not process the body,
2066 so you will not be able to access POST parameters or file uploads via
2067 $c->request.  You must handle all body parsing yourself.
2068
2069 =cut
2070
2071 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2072
2073 =head2 $c->run
2074
2075 Starts the engine.
2076
2077 =cut
2078
2079 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2080
2081 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2082
2083 Sets an action in a given namespace.
2084
2085 =cut
2086
2087 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2088
2089 =head2 $c->setup_actions($component)
2090
2091 Sets up actions for a component.
2092
2093 =cut
2094
2095 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2096
2097 =head2 $c->setup_components
2098
2099 Sets up components. Specify a C<setup_components> config option to pass
2100 additional options directly to L<Module::Pluggable>. To add additional
2101 search paths, specify a key named C<search_extra> as an array
2102 reference. Items in the array beginning with C<::> will have the
2103 application class name prepended to them.
2104
2105 All components found will also have any
2106 L<Devel::InnerPackage|inner packages> loaded and set up as components.
2107 Note, that modules which are B<not> an I<inner package> of the main
2108 file namespace loaded will not be instantiated as components.
2109
2110 =cut
2111
2112 sub setup_components {
2113     my $class = shift;
2114
2115     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2116     my $config  = $class->config->{ setup_components };
2117     my $extra   = delete $config->{ search_extra } || [];
2118
2119     push @paths, @$extra;
2120
2121     my $locator = Module::Pluggable::Object->new(
2122         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2123         %$config
2124     );
2125
2126     my @comps = sort { length $a <=> length $b } $locator->plugins;
2127     my %comps = map { $_ => 1 } @comps;
2128
2129     my $deprecated_component_names = grep { /::[CMV]::/ } @comps;
2130     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2131         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2132     ) if $deprecated_component_names;
2133
2134     for my $component ( @comps ) {
2135
2136         # We pass ignore_loaded here so that overlay files for (e.g.)
2137         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2138         # we know M::P::O found a file on disk so this is safe
2139
2140         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2141         #Class::MOP::load_class($component);
2142
2143         my $module  = $class->setup_component( $component );
2144         my %modules = (
2145             $component => $module,
2146             map {
2147                 $_ => $class->setup_component( $_ )
2148             } grep {
2149               not exists $comps{$_}
2150             } Devel::InnerPackage::list_packages( $component )
2151         );
2152
2153         for my $key ( keys %modules ) {
2154             $class->components->{ $key } = $modules{ $key };
2155         }
2156     }
2157 }
2158
2159 =head2 $c->setup_component
2160
2161 =cut
2162
2163 sub setup_component {
2164     my( $class, $component ) = @_;
2165
2166     unless ( $component->can( 'COMPONENT' ) ) {
2167         return $component;
2168     }
2169
2170     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2171     my $config = $class->config->{ $suffix } || {};
2172
2173     my $instance = eval { $component->COMPONENT( $class, $config ); };
2174
2175     if ( my $error = $@ ) {
2176         chomp $error;
2177         Catalyst::Exception->throw(
2178             message => qq/Couldn't instantiate component "$component", "$error"/
2179         );
2180     }
2181
2182     unless (blessed $instance) {
2183         my $metaclass = Moose::Util::find_meta($component);
2184         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2185         my $component_method_from = $method_meta->associated_metaclass->name;
2186         my $value = defined($instance) ? $instance : 'undef';
2187         Catalyst::Exception->throw(
2188             message =>
2189             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2190         );
2191     }
2192     return $instance;
2193 }
2194
2195 =head2 $c->setup_dispatcher
2196
2197 Sets up dispatcher.
2198
2199 =cut
2200
2201 sub setup_dispatcher {
2202     my ( $class, $dispatcher ) = @_;
2203
2204     if ($dispatcher) {
2205         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2206     }
2207
2208     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2209         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2210     }
2211
2212     unless ($dispatcher) {
2213         $dispatcher = $class->dispatcher_class;
2214     }
2215
2216     Class::MOP::load_class($dispatcher);
2217
2218     # dispatcher instance
2219     $class->dispatcher( $dispatcher->new );
2220 }
2221
2222 =head2 $c->setup_engine
2223
2224 Sets up engine.
2225
2226 =cut
2227
2228 sub setup_engine {
2229     my ( $class, $engine ) = @_;
2230
2231     if ($engine) {
2232         $engine = 'Catalyst::Engine::' . $engine;
2233     }
2234
2235     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2236         $engine = 'Catalyst::Engine::' . $env;
2237     }
2238
2239     if ( $ENV{MOD_PERL} ) {
2240         my $meta = Class::MOP::get_metaclass_by_name($class);
2241
2242         # create the apache method
2243         $meta->add_method('apache' => sub { shift->engine->apache });
2244
2245         my ( $software, $version ) =
2246           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2247
2248         $version =~ s/_//g;
2249         $version =~ s/(\.[^.]+)\./$1/g;
2250
2251         if ( $software eq 'mod_perl' ) {
2252
2253             if ( !$engine ) {
2254
2255                 if ( $version >= 1.99922 ) {
2256                     $engine = 'Catalyst::Engine::Apache2::MP20';
2257                 }
2258
2259                 elsif ( $version >= 1.9901 ) {
2260                     $engine = 'Catalyst::Engine::Apache2::MP19';
2261                 }
2262
2263                 elsif ( $version >= 1.24 ) {
2264                     $engine = 'Catalyst::Engine::Apache::MP13';
2265                 }
2266
2267                 else {
2268                     Catalyst::Exception->throw( message =>
2269                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2270                 }
2271
2272             }
2273
2274             # install the correct mod_perl handler
2275             if ( $version >= 1.9901 ) {
2276                 *handler = sub  : method {
2277                     shift->handle_request(@_);
2278                 };
2279             }
2280             else {
2281                 *handler = sub ($$) { shift->handle_request(@_) };
2282             }
2283
2284         }
2285
2286         elsif ( $software eq 'Zeus-Perl' ) {
2287             $engine = 'Catalyst::Engine::Zeus';
2288         }
2289
2290         else {
2291             Catalyst::Exception->throw(
2292                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2293         }
2294     }
2295
2296     unless ($engine) {
2297         $engine = $class->engine_class;
2298     }
2299
2300     Class::MOP::load_class($engine);
2301
2302     # check for old engines that are no longer compatible
2303     my $old_engine;
2304     if ( $engine->isa('Catalyst::Engine::Apache')
2305         && !Catalyst::Engine::Apache->VERSION )
2306     {
2307         $old_engine = 1;
2308     }
2309
2310     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2311         && Catalyst::Engine::Server->VERSION le '0.02' )
2312     {
2313         $old_engine = 1;
2314     }
2315
2316     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2317         && $engine->VERSION eq '0.01' )
2318     {
2319         $old_engine = 1;
2320     }
2321
2322     elsif ($engine->isa('Catalyst::Engine::Zeus')
2323         && $engine->VERSION eq '0.01' )
2324     {
2325         $old_engine = 1;
2326     }
2327
2328     if ($old_engine) {
2329         Catalyst::Exception->throw( message =>
2330               qq/Engine "$engine" is not supported by this version of Catalyst/
2331         );
2332     }
2333
2334     # engine instance
2335     $class->engine( $engine->new );
2336 }
2337
2338 =head2 $c->setup_home
2339
2340 Sets up the home directory.
2341
2342 =cut
2343
2344 sub setup_home {
2345     my ( $class, $home ) = @_;
2346
2347     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2348         $home = $env;
2349     }
2350
2351     $home ||= Catalyst::Utils::home($class);
2352
2353     if ($home) {
2354         #I remember recently being scolded for assigning config values like this
2355         $class->config->{home} ||= $home;
2356         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2357     }
2358 }
2359
2360 =head2 $c->setup_log
2361
2362 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2363 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2364 log to.
2365
2366 This method also installs a C<debug> method that returns a true value into the
2367 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2368 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2369
2370 Note that if the log has already been setup, by either a previous call to
2371 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2372 that this method won't actually set up the log object.
2373
2374 =cut
2375
2376 sub setup_log {
2377     my ( $class, $levels ) = @_;
2378
2379     $levels ||= '';
2380     $levels =~ s/^\s+//;
2381     $levels =~ s/\s+$//;
2382     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels || '';
2383
2384     unless ( $class->log ) {
2385         $class->log( Catalyst::Log->new(keys %levels) );
2386     }
2387
2388     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2389     if ( defined($env_debug) or $levels{debug} ) {
2390         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2391         $class->log->debug('Debug messages enabled');
2392     }
2393 }
2394
2395 =head2 $c->setup_plugins
2396
2397 Sets up plugins.
2398
2399 =cut
2400
2401 =head2 $c->setup_stats
2402
2403 Sets up timing statistics class.
2404
2405 =cut
2406
2407 sub setup_stats {
2408     my ( $class, $stats ) = @_;
2409
2410     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2411
2412     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2413     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2414         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2415         $class->log->debug('Statistics enabled');
2416     }
2417 }
2418
2419
2420 =head2 $c->registered_plugins
2421
2422 Returns a sorted list of the plugins which have either been stated in the
2423 import list or which have been added via C<< MyApp->plugin(@args); >>.
2424
2425 If passed a given plugin name, it will report a boolean value indicating
2426 whether or not that plugin is loaded.  A fully qualified name is required if
2427 the plugin name does not begin with C<Catalyst::Plugin::>.
2428
2429  if ($c->registered_plugins('Some::Plugin')) {
2430      ...
2431  }
2432
2433 =cut
2434
2435 {
2436
2437     sub registered_plugins {
2438         my $proto = shift;
2439         return sort keys %{ $proto->_plugins } unless @_;
2440         my $plugin = shift;
2441         return 1 if exists $proto->_plugins->{$plugin};
2442         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2443     }
2444
2445     sub _register_plugin {
2446         my ( $proto, $plugin, $instant ) = @_;
2447         my $class = ref $proto || $proto;
2448
2449         # no ignore_loaded here, the plugin may already have been
2450         # defined in memory and we don't want to error on "no file" if so
2451
2452         Class::MOP::load_class( $plugin );
2453
2454         $proto->_plugins->{$plugin} = 1;
2455         unless ($instant) {
2456             no strict 'refs';
2457             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2458               my @superclasses = ($plugin, $meta->superclasses );
2459               $meta->superclasses(@superclasses);
2460             } else {
2461               unshift @{"$class\::ISA"}, $plugin;
2462             }
2463         }
2464         return $class;
2465     }
2466
2467     sub setup_plugins {
2468         my ( $class, $plugins ) = @_;
2469
2470         $class->_plugins( {} ) unless $class->_plugins;
2471         $plugins ||= [];
2472         for my $plugin ( reverse @$plugins ) {
2473
2474             unless ( $plugin =~ s/\A\+// ) {
2475                 $plugin = "Catalyst::Plugin::$plugin";
2476             }
2477
2478             $class->_register_plugin($plugin);
2479         }
2480     }
2481 }
2482
2483 =head2 $c->stack
2484
2485 Returns an arrayref of the internal execution stack (actions that are
2486 currently executing).
2487
2488 =head2 $c->stats_class
2489
2490 Returns or sets the stats (timing statistics) class.
2491
2492 =head2 $c->use_stats
2493
2494 Returns 1 when stats collection is enabled.  Stats collection is enabled
2495 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2496 environment variable is set.
2497
2498 Note that this is a static method, not an accessor and should be overloaded
2499 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2500
2501 =cut
2502
2503 sub use_stats { 0 }
2504
2505
2506 =head2 $c->write( $data )
2507
2508 Writes $data to the output stream. When using this method directly, you
2509 will need to manually set the C<Content-Length> header to the length of
2510 your output data, if known.
2511
2512 =cut
2513
2514 sub write {
2515     my $c = shift;
2516
2517     # Finalize headers if someone manually writes output
2518     $c->finalize_headers;
2519
2520     return $c->engine->write( $c, @_ );
2521 }
2522
2523 =head2 version
2524
2525 Returns the Catalyst version number. Mostly useful for "powered by"
2526 messages in template systems.
2527
2528 =cut
2529
2530 sub version { return $Catalyst::VERSION }
2531
2532 =head1 INTERNAL ACTIONS
2533
2534 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2535 C<_ACTION>, and C<_END>. These are by default not shown in the private
2536 action table, but you can make them visible with a config parameter.
2537
2538     MyApp->config->{show_internal_actions} = 1;
2539
2540 =head1 CASE SENSITIVITY
2541
2542 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2543 mapped to C</foo/bar>. You can activate case sensitivity with a config
2544 parameter.
2545
2546     MyApp->config->{case_sensitive} = 1;
2547
2548 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2549
2550 =head1 ON-DEMAND PARSER
2551
2552 The request body is usually parsed at the beginning of a request,
2553 but if you want to handle input yourself, you can enable on-demand
2554 parsing with a config parameter.
2555
2556     MyApp->config->{parse_on_demand} = 1;
2557
2558 =head1 PROXY SUPPORT
2559
2560 Many production servers operate using the common double-server approach,
2561 with a lightweight frontend web server passing requests to a larger
2562 backend server. An application running on the backend server must deal
2563 with two problems: the remote user always appears to be C<127.0.0.1> and
2564 the server's hostname will appear to be C<localhost> regardless of the
2565 virtual host that the user connected through.
2566
2567 Catalyst will automatically detect this situation when you are running
2568 the frontend and backend servers on the same machine. The following
2569 changes are made to the request.
2570
2571     $c->req->address is set to the user's real IP address, as read from
2572     the HTTP X-Forwarded-For header.
2573
2574     The host value for $c->req->base and $c->req->uri is set to the real
2575     host, as read from the HTTP X-Forwarded-Host header.
2576
2577 Obviously, your web server must support these headers for this to work.
2578
2579 In a more complex server farm environment where you may have your
2580 frontend proxy server(s) on different machines, you will need to set a
2581 configuration option to tell Catalyst to read the proxied data from the
2582 headers.
2583
2584     MyApp->config->{using_frontend_proxy} = 1;
2585
2586 If you do not wish to use the proxy support at all, you may set:
2587
2588     MyApp->config->{ignore_frontend_proxy} = 1;
2589
2590 =head1 THREAD SAFETY
2591
2592 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2593 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2594 believe the Catalyst core to be thread-safe.
2595
2596 If you plan to operate in a threaded environment, remember that all other
2597 modules you are using must also be thread-safe. Some modules, most notably
2598 L<DBD::SQLite>, are not thread-safe.
2599
2600 =head1 SUPPORT
2601
2602 IRC:
2603
2604     Join #catalyst on irc.perl.org.
2605
2606 Mailing Lists:
2607
2608     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2609     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2610
2611 Web:
2612
2613     http://catalyst.perl.org
2614
2615 Wiki:
2616
2617     http://dev.catalyst.perl.org
2618
2619 =head1 SEE ALSO
2620
2621 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2622
2623 =head2 L<Catalyst::Manual> - The Catalyst Manual
2624
2625 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2626
2627 =head2 L<Catalyst::Engine> - Core engine
2628
2629 =head2 L<Catalyst::Log> - Log class.
2630
2631 =head2 L<Catalyst::Request> - Request object
2632
2633 =head2 L<Catalyst::Response> - Response object
2634
2635 =head2 L<Catalyst::Test> - The test suite.
2636
2637 =head1 PROJECT FOUNDER
2638
2639 sri: Sebastian Riedel <sri@cpan.org>
2640
2641 =head1 CONTRIBUTORS
2642
2643 abw: Andy Wardley
2644
2645 acme: Leon Brocard <leon@astray.com>
2646
2647 Andrew Bramble
2648
2649 Andrew Ford
2650
2651 Andrew Ruthven
2652
2653 andyg: Andy Grundman <andy@hybridized.org>
2654
2655 audreyt: Audrey Tang
2656
2657 bricas: Brian Cassidy <bricas@cpan.org>
2658
2659 Caelum: Rafael Kitover <rkitover@io.com>
2660
2661 chansen: Christian Hansen
2662
2663 chicks: Christopher Hicks
2664
2665 David E. Wheeler
2666
2667 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2668
2669 Drew Taylor
2670
2671 esskar: Sascha Kiefer
2672
2673 fireartist: Carl Franks <cfranks@cpan.org>
2674
2675 gabb: Danijel Milicevic
2676
2677 Gary Ashton Jones
2678
2679 Geoff Richards
2680
2681 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2682
2683 jcamacho: Juan Camacho
2684
2685 jhannah: Jay Hannah <jay@jays.net>
2686
2687 Jody Belka
2688
2689 Johan Lindstrom
2690
2691 jon: Jon Schutz <jjschutz@cpan.org>
2692
2693 marcus: Marcus Ramberg <mramberg@cpan.org>
2694
2695 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2696
2697 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2698
2699 mugwump: Sam Vilain
2700
2701 naughton: David Naughton
2702
2703 ningu: David Kamholz <dkamholz@cpan.org>
2704
2705 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2706
2707 numa: Dan Sully <daniel@cpan.org>
2708
2709 obra: Jesse Vincent
2710
2711 omega: Andreas Marienborg
2712
2713 Oleg Kostyuk <cub.uanic@gmail.com>
2714
2715 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2716
2717 rafl: Florian Ragwitz <rafl@debian.org>
2718
2719 sky: Arthur Bergman
2720
2721 the_jester: Jesse Sheidlower
2722
2723 t0m: Tomas Doran <bobtfish@bobtfish.net>
2724
2725 Ulf Edvinsson
2726
2727 willert: Sebastian Willert <willert@cpan.org>
2728
2729 =head1 LICENSE
2730
2731 This library is free software, you can redistribute it and/or modify it under
2732 the same terms as Perl itself.
2733
2734 =cut
2735
2736 no Moose;
2737
2738 __PACKAGE__->meta->make_immutable;
2739
2740 1;