lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken blessed/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 __PACKAGE__->mk_accessors(
  34     qw/counter request response state action stack namespace stats/
  35 );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52 our $GO        = "catalyst_go\n";
  53
  54 __PACKAGE__->mk_classdata($_)
  55   for qw/components arguments dispatcher engine log dispatcher_class
  56   engine_class context_class request_class response_class stats_class
  57   setup_finished/;
  58
  59 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  60 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  61 __PACKAGE__->request_class('Catalyst::Request');
  62 __PACKAGE__->response_class('Catalyst::Response');
  63 __PACKAGE__->stats_class('Catalyst::Stats');
  64
  65 # Remember to update this in Catalyst::Runtime as well!
  66
  67 our $VERSION = '5.7099_03';
  68
  69 sub import {
  70     my ( $class, @arguments ) = @_;
  71
  72     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  73     # callers @ISA.
  74     return unless $class eq 'Catalyst';
  75
  76     my $caller = caller(0);
  77
  78     unless ( $caller->isa('Catalyst') ) {
  79         no strict 'refs';
  80         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  81     }
  82
  83     $caller->arguments( [@arguments] );
  84     $caller->setup_home;
  85 }
  86
  87 =head1 NAME
  88
  89 Catalyst - The Elegant MVC Web Application Framework
  90
  91 =head1 SYNOPSIS
  92
  93 See the L<Catalyst::Manual> distribution for comprehensive
  94 documentation and tutorials.
  95
  96     # Install Catalyst::Devel for helpers and other development tools
  97     # use the helper to create a new application
  98     catalyst.pl MyApp
  99
 100     # add models, views, controllers
 101     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 102     script/myapp_create.pl view MyTemplate TT
 103     script/myapp_create.pl controller Search
 104
 105     # built in testserver -- use -r to restart automatically on changes
 106     # --help to see all available options
 107     script/myapp_server.pl
 108
 109     # command line testing interface
 110     script/myapp_test.pl /yada
 111
 112     ### in lib/MyApp.pm
 113     use Catalyst qw/-Debug/; # include plugins here as well
 114
 115     ### In lib/MyApp/Controller/Root.pm (autocreated)
 116     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 117         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 118         $c->stash->{template} = 'foo.tt'; # set the template
 119         # lookup something from db -- stash vars are passed to TT
 120         $c->stash->{data} =
 121           $c->model('Database::Foo')->search( { country => $args[0] } );
 122         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 123             $c->forward( 'bar' ); # process another action
 124             # do something else after forward returns
 125         }
 126     }
 127
 128     # The foo.tt TT template can use the stash data from the database
 129     [% WHILE (item = data.next) %]
 130         [% item.foo %]
 131     [% END %]
 132
 133     # called for /bar/of/soap, /bar/of/soap/10, etc.
 134     sub bar : Path('/bar/of/soap') { ... }
 135
 136     # called for all actions, from the top-most controller downwards
 137     sub auto : Private {
 138         my ( $self, $c ) = @_;
 139         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 140             $c->res->redirect( '/login' ); # require login
 141             return 0; # abort request and go immediately to end()
 142         }
 143         return 1; # success; carry on to next action
 144     }
 145
 146     # called after all actions are finished
 147     sub end : Private {
 148         my ( $self, $c ) = @_;
 149         if ( scalar @{ $c->error } ) { ... } # handle errors
 150         return if $c->res->body; # already have a response
 151         $c->forward( 'MyApp::View::TT' ); # render template
 152     }
 153
 154     ### in MyApp/Controller/Foo.pm
 155     # called for /foo/bar
 156     sub bar : Local { ... }
 157
 158     # called for /blargle
 159     sub blargle : Global { ... }
 160
 161     # an index action matches /foo, but not /foo/1, etc.
 162     sub index : Private { ... }
 163
 164     ### in MyApp/Controller/Foo/Bar.pm
 165     # called for /foo/bar/baz
 166     sub baz : Local { ... }
 167
 168     # first Root auto is called, then Foo auto, then this
 169     sub auto : Private { ... }
 170
 171     # powerful regular expression paths are also possible
 172     sub details : Regex('^product/(\w+)/details$') {
 173         my ( $self, $c ) = @_;
 174         # extract the (\w+) from the URI
 175         my $product = $c->req->captures->[0];
 176     }
 177
 178 See L<Catalyst::Manual::Intro> for additional information.
 179
 180 =head1 DESCRIPTION
 181
 182 Catalyst is a modern framework for making web applications without the
 183 pain usually associated with this process. This document is a reference
 184 to the main Catalyst application. If you are a new user, we suggest you
 185 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 186
 187 See L<Catalyst::Manual> for more documentation.
 188
 189 Catalyst plugins can be loaded by naming them as arguments to the "use
 190 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 191 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 192 C<My::Module>.
 193
 194     use Catalyst qw/My::Module/;
 195
 196 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 197 fully qualify the name by using a unary plus:
 198
 199     use Catalyst qw/
 200         My::Module
 201         +Fully::Qualified::Plugin::Name
 202     /;
 203
 204 Special flags like C<-Debug> and C<-Engine> can also be specified as
 205 arguments when Catalyst is loaded:
 206
 207     use Catalyst qw/-Debug My::Module/;
 208
 209 The position of plugins and flags in the chain is important, because
 210 they are loaded in the order in which they appear.
 211
 212 The following flags are supported:
 213
 214 =head2 -Debug
 215
 216 Enables debug output. You can also force this setting from the system
 217 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 218 settings override the application, with <MYAPP>_DEBUG having the highest
 219 priority.
 220
 221 =head2 -Engine
 222
 223 Forces Catalyst to use a specific engine. Omit the
 224 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 225
 226     use Catalyst qw/-Engine=CGI/;
 227
 228 =head2 -Home
 229
 230 Forces Catalyst to use a specific home directory, e.g.:
 231
 232     use Catalyst qw[-Home=/usr/mst];
 233
 234 This can also be done in the shell environment by setting either the
 235 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 236 is replaced with the uppercased name of your application, any "::" in
 237 the name will be replaced with underscores, e.g. MyApp::Web should use
 238 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 239
 240 =head2 -Log
 241
 242 Specifies log level.
 243
 244 =head2 -Stats
 245
 246 Enables statistics collection and reporting. You can also force this setting
 247 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 248 environment settings override the application, with <MYAPP>_STATS having the
 249 highest priority.
 250
 251 e.g.
 252
 253    use Catalyst qw/-Stats=1/
 254
 255 =head1 METHODS
 256
 257 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 258
 259 =head2 $c->action
 260
 261 Returns a L<Catalyst::Action> object for the current action, which
 262 stringifies to the action name. See L<Catalyst::Action>.
 263
 264 =head2 $c->namespace
 265
 266 Returns the namespace of the current action, i.e., the URI prefix
 267 corresponding to the controller of the current action. For example:
 268
 269     # in Controller::Foo::Bar
 270     $c->namespace; # returns 'foo/bar';
 271
 272 =head2 $c->request
 273
 274 =head2 $c->req
 275
 276 Returns the current L<Catalyst::Request> object, giving access to
 277 information about the current client request (including parameters,
 278 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 279
 280 =head2 REQUEST FLOW HANDLING
 281
 282 =head2 $c->forward( $action [, \@arguments ] )
 283
 284 =head2 $c->forward( $class, $method, [, \@arguments ] )
 285
 286 Forwards processing to another action, by its private name. If you give a
 287 class name but no method, C<process()> is called. You may also optionally
 288 pass arguments in an arrayref. The action will receive the arguments in
 289 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 290 C<< $c->req->args >> will be restored to the previous values.
 291
 292 Any data C<return>ed from the action forwarded to, will be returned by the
 293 call to forward.
 294
 295     my $foodata = $c->forward('/foo');
 296     $c->forward('index');
 297     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 298     $c->forward('MyApp::View::TT');
 299
 300 Note that forward implies an C<<eval { }>> around the call (actually
 301 C<execute> does), thus de-fatalizing all 'dies' within the called
 302 action. If you want C<die> to propagate you need to do something like:
 303
 304     $c->forward('foo');
 305     die $c->error if $c->error;
 306
 307 Or make sure to always return true values from your actions and write
 308 your code like this:
 309
 310     $c->forward('foo') || return;
 311
 312 =cut
 313
 314 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 315
 316 =head2 $c->detach( $action [, \@arguments ] )
 317
 318 =head2 $c->detach( $class, $method, [, \@arguments ] )
 319
 320 =head2 $c->detach()
 321
 322 The same as C<forward>, but doesn't return to the previous action when
 323 processing is finished.
 324
 325 When called with no arguments it escapes the processing chain entirely.
 326
 327 =cut
 328
 329 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 330
 331 =head2 $c->go( $action [, \@arguments ] )
 332
 333 =head2 $c->go( $class, $method, [, \@arguments ] )
 334
 335 Almost the same as C<detach>, but does a full dispatch, instead of just
 336 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 337 C<auto> and the method you go to is called, just like a new request.
 338
 339 C<$c-E<gt>stash> is kept unchanged.
 340
 341 =cut
 342
 343 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 344
 345 =head2 $c->response
 346
 347 =head2 $c->res
 348
 349 Returns the current L<Catalyst::Response> object, see there for details.
 350
 351 =head2 $c->stash
 352
 353 Returns a hashref to the stash, which may be used to store data and pass
 354 it between components during a request. You can also set hash keys by
 355 passing arguments. The stash is automatically sent to the view. The
 356 stash is cleared at the end of a request; it cannot be used for
 357 persistent storage (for this you must use a session; see
 358 L<Catalyst::Plugin::Session> for a complete system integrated with
 359 Catalyst).
 360
 361     $c->stash->{foo} = $bar;
 362     $c->stash( { moose => 'majestic', qux => 0 } );
 363     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 364
 365     # stash is automatically passed to the view for use in a template
 366     $c->forward( 'MyApp::View::TT' );
 367
 368 =cut
 369
 370 sub stash {
 371     my $c = shift;
 372     if (@_) {
 373         my $stash = @_ > 1 ? {@_} : $_[0];
 374         croak('stash takes a hash or hashref') unless ref $stash;
 375         foreach my $key ( keys %$stash ) {
 376             $c->{stash}->{$key} = $stash->{$key};
 377         }
 378     }
 379     return $c->{stash};
 380 }
 381
 382 =head2 $c->error
 383
 384 =head2 $c->error($error, ...)
 385
 386 =head2 $c->error($arrayref)
 387
 388 Returns an arrayref containing error messages.  If Catalyst encounters an
 389 error while processing a request, it stores the error in $c->error.  This
 390 method should only be used to store fatal error messages.
 391
 392     my @error = @{ $c->error };
 393
 394 Add a new error.
 395
 396     $c->error('Something bad happened');
 397
 398 =cut
 399
 400 sub error {
 401     my $c = shift;
 402     if ( $_[0] ) {
 403         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 404         croak @$error unless ref $c;
 405         push @{ $c->{error} }, @$error;
 406     }
 407     elsif ( defined $_[0] ) { $c->{error} = undef }
 408     return $c->{error} || [];
 409 }
 410
 411
 412 =head2 $c->state
 413
 414 Contains the return value of the last executed action.
 415
 416 =head2 $c->clear_errors
 417
 418 Clear errors.  You probably don't want to clear the errors unless you are
 419 implementing a custom error screen.
 420
 421 This is equivalent to running
 422
 423     $c->error(0);
 424
 425 =cut
 426
 427 sub clear_errors {
 428     my $c = shift;
 429     $c->error(0);
 430 }
 431
 432 # search components given a name and some prefixes
 433 sub _comp_search_prefixes {
 434     my ( $c, $name, @prefixes ) = @_;
 435     my $appclass = ref $c || $c;
 436     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 437
 438     # map the original component name to the sub part that we will search against
 439     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 440         grep { /$filter/ } keys %{ $c->components };
 441
 442     # undef for a name will return all
 443     return keys %eligible if !defined $name;
 444
 445     my $query  = ref $name ? $name : qr/^$name$/i;
 446     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 447
 448     return map { $c->components->{ $_ } } @result if @result;
 449
 450     # if we were given a regexp to search against, we're done.
 451     return if ref $name;
 452
 453     # regexp fallback
 454     $query  = qr/$name/i;
 455     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 456
 457     # no results? try against full names
 458     if( !@result ) {
 459         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 460     }
 461
 462     # don't warn if we didn't find any results, it just might not exist
 463     if( @result ) {
 464         $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 465         $c->log->warn( 'Relying on the regexp fallback behavior for component resolution is unreliable and unsafe.' );
 466         $c->log->warn( 'If you really want to search, pass in a regexp as the argument.' );
 467     }
 468
 469     return @result;
 470 }
 471
 472 # Find possible names for a prefix
 473 sub _comp_names {
 474     my ( $c, @prefixes ) = @_;
 475     my $appclass = ref $c || $c;
 476
 477     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 478
 479     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 480     return @names;
 481 }
 482
 483 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 484 sub _filter_component {
 485     my ( $c, $comp, @args ) = @_;
 486
 487     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 488         return $comp->ACCEPT_CONTEXT( $c, @args );
 489     }
 490
 491     return $comp;
 492 }
 493
 494 =head2 COMPONENT ACCESSORS
 495
 496 =head2 $c->controller($name)
 497
 498 Gets a L<Catalyst::Controller> instance by name.
 499
 500     $c->controller('Foo')->do_stuff;
 501
 502 If the name is omitted, will return the controller for the dispatched
 503 action.
 504
 505 If you want to search for controllers, pass in a regexp as the argument.
 506
 507     # find all controllers that start with Foo
 508     my @foo_controllers = $c->controller(qr{^Foo});
 509
 510
 511 =cut
 512
 513 sub controller {
 514     my ( $c, $name, @args ) = @_;
 515
 516     if( $name ) {
 517         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 518         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 519         return $c->_filter_component( $result[ 0 ], @args );
 520     }
 521
 522     return $c->component( $c->action->class );
 523 }
 524
 525 =head2 $c->model($name)
 526
 527 Gets a L<Catalyst::Model> instance by name.
 528
 529     $c->model('Foo')->do_stuff;
 530
 531 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 532
 533 If the name is omitted, it will look for
 534  - a model object in $c->stash->{current_model_instance}, then
 535  - a model name in $c->stash->{current_model}, then
 536  - a config setting 'default_model', or
 537  - check if there is only one model, and return it if that's the case.
 538
 539 If you want to search for models, pass in a regexp as the argument.
 540
 541     # find all models that start with Foo
 542     my @foo_models = $c->model(qr{^Foo});
 543
 544 =cut
 545
 546 sub model {
 547     my ( $c, $name, @args ) = @_;
 548
 549     if( $name ) {
 550         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 551         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 552         return $c->_filter_component( $result[ 0 ], @args );
 553     }
 554
 555     if (ref $c) {
 556         return $c->stash->{current_model_instance}
 557           if $c->stash->{current_model_instance};
 558         return $c->model( $c->stash->{current_model} )
 559           if $c->stash->{current_model};
 560     }
 561     return $c->model( $c->config->{default_model} )
 562       if $c->config->{default_model};
 563
 564     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 565
 566     if( $rest ) {
 567         $c->log->warn( 'Calling $c->model() will return a random model unless you specify one of:' );
 568         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 569         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 570         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 571         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 572     }
 573
 574     return $c->_filter_component( $comp );
 575 }
 576
 577
 578 =head2 $c->view($name)
 579
 580 Gets a L<Catalyst::View> instance by name.
 581
 582     $c->view('Foo')->do_stuff;
 583
 584 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 585
 586 If the name is omitted, it will look for
 587  - a view object in $c->stash->{current_view_instance}, then
 588  - a view name in $c->stash->{current_view}, then
 589  - a config setting 'default_view', or
 590  - check if there is only one view, and return it if that's the case.
 591
 592 If you want to search for views, pass in a regexp as the argument.
 593
 594     # find all views that start with Foo
 595     my @foo_views = $c->view(qr{^Foo});
 596
 597 =cut
 598
 599 sub view {
 600     my ( $c, $name, @args ) = @_;
 601
 602     if( $name ) {
 603         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 604         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 605         return $c->_filter_component( $result[ 0 ], @args );
 606     }
 607
 608     if (ref $c) {
 609         return $c->stash->{current_view_instance}
 610           if $c->stash->{current_view_instance};
 611         return $c->view( $c->stash->{current_view} )
 612           if $c->stash->{current_view};
 613     }
 614     return $c->view( $c->config->{default_view} )
 615       if $c->config->{default_view};
 616
 617     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 618
 619     if( $rest ) {
 620         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 621         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 622         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 623         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 624         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 625     }
 626
 627     return $c->_filter_component( $comp );
 628 }
 629
 630 =head2 $c->controllers
 631
 632 Returns the available names which can be passed to $c->controller
 633
 634 =cut
 635
 636 sub controllers {
 637     my ( $c ) = @_;
 638     return $c->_comp_names(qw/Controller C/);
 639 }
 640
 641 =head2 $c->models
 642
 643 Returns the available names which can be passed to $c->model
 644
 645 =cut
 646
 647 sub models {
 648     my ( $c ) = @_;
 649     return $c->_comp_names(qw/Model M/);
 650 }
 651
 652
 653 =head2 $c->views
 654
 655 Returns the available names which can be passed to $c->view
 656
 657 =cut
 658
 659 sub views {
 660     my ( $c ) = @_;
 661     return $c->_comp_names(qw/View V/);
 662 }
 663
 664 =head2 $c->comp($name)
 665
 666 =head2 $c->component($name)
 667
 668 Gets a component object by name. This method is not recommended,
 669 unless you want to get a specific component by full
 670 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 671 should be used instead.
 672
 673 If C<$name> is a regexp, a list of components matched against the full
 674 component name will be returned.
 675
 676 =cut
 677
 678 sub component {
 679     my ( $c, $name, @args ) = @_;
 680
 681     if( $name ) {
 682         my $comps = $c->components;
 683
 684         if( !ref $name ) {
 685             # is it the exact name?
 686             return $c->_filter_component( $comps->{ $name }, @args )
 687                        if exists $comps->{ $name };
 688
 689             # perhaps we just omitted "MyApp"?
 690             my $composed = ( ref $c || $c ) . "::${name}";
 691             return $c->_filter_component( $comps->{ $composed }, @args )
 692                        if exists $comps->{ $composed };
 693
 694             # search all of the models, views and controllers
 695             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 696             return $c->_filter_component( $comp, @args ) if $comp;
 697         }
 698
 699         # This is here so $c->comp( '::M::' ) works
 700         my $query = ref $name ? $name : qr{$name}i;
 701
 702         my @result = grep { m{$query} } keys %{ $c->components };
 703         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 704
 705         if( $result[ 0 ] ) {
 706             $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 707             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 708             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 709             return $c->_filter_component( $result[ 0 ], @args );
 710         }
 711
 712         # I would expect to return an empty list here, but that breaks back-compat
 713     }
 714
 715     # fallback
 716     return sort keys %{ $c->components };
 717 }
 718
 719 =head2 CLASS DATA AND HELPER CLASSES
 720
 721 =head2 $c->config
 722
 723 Returns or takes a hashref containing the application's configuration.
 724
 725     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 726
 727 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 728 like myapp.yml in your applications home directory. See
 729 L<Catalyst::Plugin::ConfigLoader>.
 730
 731     ---
 732     db: dsn:SQLite:foo.db
 733
 734
 735 =cut
 736
 737 sub config {
 738     my $c = shift;
 739
 740     $c->log->warn("Setting config after setup has been run is not a good idea.")
 741       if ( @_ and $c->setup_finished );
 742
 743     $c->NEXT::config(@_);
 744 }
 745
 746 =head2 $c->log
 747
 748 Returns the logging object instance. Unless it is already set, Catalyst
 749 sets this up with a L<Catalyst::Log> object. To use your own log class,
 750 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 751 C<< __PACKAGE__->setup >>.
 752
 753  __PACKAGE__->log( MyLogger->new );
 754  __PACKAGE__->setup;
 755
 756 And later:
 757
 758     $c->log->info( 'Now logging with my own logger!' );
 759
 760 Your log class should implement the methods described in
 761 L<Catalyst::Log>.
 762
 763
 764 =head2 $c->debug
 765
 766 Overload to enable debug messages (same as -Debug option).
 767
 768 Note that this is a static method, not an accessor and should be overloaded
 769 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 770
 771 =cut
 772
 773 sub debug { 0 }
 774
 775 =head2 $c->dispatcher
 776
 777 Returns the dispatcher instance. Stringifies to class name. See
 778 L<Catalyst::Dispatcher>.
 779
 780 =head2 $c->engine
 781
 782 Returns the engine instance. Stringifies to the class name. See
 783 L<Catalyst::Engine>.
 784
 785
 786 =head2 UTILITY METHODS
 787
 788 =head2 $c->path_to(@path)
 789
 790 Merges C<@path> with C<< $c->config->{home} >> and returns a
 791 L<Path::Class::Dir> object.
 792
 793 For example:
 794
 795     $c->path_to( 'db', 'sqlite.db' );
 796
 797 =cut
 798
 799 sub path_to {
 800     my ( $c, @path ) = @_;
 801     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 802     if ( -d $path ) { return $path }
 803     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 804 }
 805
 806 =head2 $c->plugin( $name, $class, @args )
 807
 808 Helper method for plugins. It creates a classdata accessor/mutator and
 809 loads and instantiates the given class.
 810
 811     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 812
 813     $c->prototype->define_javascript_functions;
 814
 815 =cut
 816
 817 sub plugin {
 818     my ( $class, $name, $plugin, @args ) = @_;
 819     $class->_register_plugin( $plugin, 1 );
 820
 821     eval { $plugin->import };
 822     $class->mk_classdata($name);
 823     my $obj;
 824     eval { $obj = $plugin->new(@args) };
 825
 826     if ($@) {
 827         Catalyst::Exception->throw( message =>
 828               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 829     }
 830
 831     $class->$name($obj);
 832     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 833       if $class->debug;
 834 }
 835
 836 =head2 MyApp->setup
 837
 838 Initializes the dispatcher and engine, loads any plugins, and loads the
 839 model, view, and controller components. You may also specify an array
 840 of plugins to load here, if you choose to not load them in the C<use
 841 Catalyst> line.
 842
 843     MyApp->setup;
 844     MyApp->setup( qw/-Debug/ );
 845
 846 =cut
 847
 848 sub setup {
 849     my ( $class, @arguments ) = @_;
 850
 851     $class->log->warn("Running setup twice is not a good idea.")
 852       if ( $class->setup_finished );
 853
 854     unless ( $class->isa('Catalyst') ) {
 855
 856         Catalyst::Exception->throw(
 857             message => qq/'$class' does not inherit from Catalyst/ );
 858     }
 859
 860     if ( $class->arguments ) {
 861         @arguments = ( @arguments, @{ $class->arguments } );
 862     }
 863
 864     # Process options
 865     my $flags = {};
 866
 867     foreach (@arguments) {
 868
 869         if (/^-Debug$/) {
 870             $flags->{log} =
 871               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 872         }
 873         elsif (/^-(\w+)=?(.*)$/) {
 874             $flags->{ lc $1 } = $2;
 875         }
 876         else {
 877             push @{ $flags->{plugins} }, $_;
 878         }
 879     }
 880
 881     $class->setup_home( delete $flags->{home} );
 882
 883     $class->setup_log( delete $flags->{log} );
 884     $class->setup_plugins( delete $flags->{plugins} );
 885     $class->setup_dispatcher( delete $flags->{dispatcher} );
 886     $class->setup_engine( delete $flags->{engine} );
 887     $class->setup_stats( delete $flags->{stats} );
 888
 889     for my $flag ( sort keys %{$flags} ) {
 890
 891         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 892             &$code( $class, delete $flags->{$flag} );
 893         }
 894         else {
 895             $class->log->warn(qq/Unknown flag "$flag"/);
 896         }
 897     }
 898
 899     eval { require Catalyst::Devel; };
 900     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 901         $class->log->warn(<<"EOF");
 902 You are running an old script!
 903
 904   Please update by running (this will overwrite existing files):
 905     catalyst.pl -force -scripts $class
 906
 907   or (this will not overwrite existing files):
 908     catalyst.pl -scripts $class
 909
 910 EOF
 911     }
 912
 913     if ( $class->debug ) {
 914         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 915
 916         if (@plugins) {
 917             my $t = Text::SimpleTable->new(74);
 918             $t->row($_) for @plugins;
 919             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 920         }
 921
 922         my $dispatcher = $class->dispatcher;
 923         my $engine     = $class->engine;
 924         my $home       = $class->config->{home};
 925
 926         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 927         $class->log->debug(qq/Loaded engine "$engine"/);
 928
 929         $home
 930           ? ( -d $home )
 931           ? $class->log->debug(qq/Found home "$home"/)
 932           : $class->log->debug(qq/Home "$home" doesn't exist/)
 933           : $class->log->debug(q/Couldn't find home/);
 934     }
 935
 936     # Call plugins setup
 937     {
 938         no warnings qw/redefine/;
 939         local *setup = sub { };
 940         $class->setup;
 941     }
 942
 943     # Initialize our data structure
 944     $class->components( {} );
 945
 946     $class->setup_components;
 947
 948     if ( $class->debug ) {
 949         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 950         for my $comp ( sort keys %{ $class->components } ) {
 951             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 952             $t->row( $comp, $type );
 953         }
 954         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 955           if ( keys %{ $class->components } );
 956     }
 957
 958     # Add our self to components, since we are also a component
 959     $class->components->{$class} = $class;
 960
 961     $class->setup_actions;
 962
 963     if ( $class->debug ) {
 964         my $name = $class->config->{name} || 'Application';
 965         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 966     }
 967     $class->log->_flush() if $class->log->can('_flush');
 968
 969     $class->setup_finished(1);
 970 }
 971
 972 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
 973
 974 =head2 $c->uri_for( $path, @args?, \%query_values? )
 975
 976 =over
 977
 978 =item $action
 979
 980 A Catalyst::Action object representing the Catalyst action you want to
 981 create a URI for. To get one for an action in the current controller,
 982 use C<< $c->action('someactionname') >>. To get one from different
 983 controller, fetch the controller using C<< $c->controller() >>, then
 984 call C<action_for> on it.
 985
 986 This method must be used to create URIs for
 987 L<Catalyst::DispatchType::Chained> actions.
 988
 989 =item $path
 990
 991 The actual path you wish to create a URI for, this is a public path,
 992 not a private action path.
 993
 994 =item \@captures
 995
 996 If provided, this argument is used to insert values into a I<Chained>
 997 action in the parts where the definitions contain I<CaptureArgs>. If
 998 not needed, leave out this argument.
 999
1000 =item @args
1001
1002 If provided, this is used as a list of further path sections to append
1003 to the URI. In a I<Chained> action these are the equivalent to the
1004 endpoint L<Args>.
1005
1006 =item \%query_values
1007
1008 If provided, the query_values hashref is used to add query parameters
1009 to the URI, with the keys as the names, and the values as the values.
1010
1011 =back
1012
1013 Returns a L<URI> object.
1014
1015   ## Ex 1: a path with args and a query parameter
1016   $c->uri_for('user/list', 'short', { page => 2});
1017   ## -> ($c->req->base is 'http://localhost:3000/'
1018   URI->new('http://localhost:3000/user/list/short?page=2)
1019
1020   ## Ex 2: a chained view action that captures the user id
1021   ## In controller:
1022   sub user : Chained('/'): PathPart('myuser'): CaptureArgs(1) {}
1023   sub viewuser : Chained('user'): PathPart('view') {}
1024
1025   ## In uri creating code:
1026   my $uaction = $c->controller('Users')->action_for('viewuser');
1027   $c->uri_for($uaction, [ 42 ]);
1028   ## outputs:
1029   URI->new('http://localhost:3000/myuser/42/view')
1030
1031 Creates a URI object using C<< $c->request->base >> and a path. If an
1032 Action object is given instead of a path, the path is constructed
1033 using C<< $c->dispatcher->uri_for_action >> and passing it the
1034 @captures array, if supplied.
1035
1036 If any query parameters are passed they are added to the end of the
1037 URI in the usual way.
1038
1039 Note that uri_for is destructive to the passed query values hashref.
1040 Subsequent calls with the same hashref may have unintended results.
1041
1042 =cut
1043
1044 sub uri_for {
1045     my ( $c, $path, @args ) = @_;
1046
1047     if ( Scalar::Util::blessed($path) ) { # action object
1048         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1049                          ? shift(@args)
1050                          : [] );
1051         $path = $c->dispatcher->uri_for_action($path, $captures);
1052         return undef unless defined($path);
1053         $path = '/' if $path eq '';
1054     }
1055
1056     undef($path) if (defined $path && $path eq '');
1057
1058     my $params =
1059       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1060
1061     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1062     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1063
1064     unshift(@args, $path);
1065
1066     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1067         my $namespace = $c->namespace;
1068         if (defined $path) { # cheesy hack to handle path '../foo'
1069            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1070         }
1071         unshift(@args, $namespace || '');
1072     }
1073
1074     # join args with '/', or a blank string
1075     my $args = join('/', grep { defined($_) } @args);
1076     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1077     $args =~ s!^/!!;
1078     my $base = $c->req->base;
1079     my $class = ref($base);
1080     $base =~ s{(?<!/)$}{/};
1081
1082     my $query = '';
1083
1084     if (my @keys = keys %$params) {
1085       # somewhat lifted from URI::_query's query_form
1086       $query = '?'.join('&', map {
1087           my $val = $params->{$_};
1088           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1089           s/ /+/g;
1090           my $key = $_;
1091           $val = '' unless defined $val;
1092           (map {
1093               $_ = "$_";
1094               utf8::encode( $_ ) if utf8::is_utf8($_);
1095               # using the URI::Escape pattern here so utf8 chars survive
1096               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1097               s/ /+/g;
1098               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1099       } @keys);
1100     }
1101
1102     my $res = bless(\"${base}${args}${query}", $class);
1103     $res;
1104 }
1105
1106 =head2 $c->welcome_message
1107
1108 Returns the Catalyst welcome HTML page.
1109
1110 =cut
1111
1112 sub welcome_message {
1113     my $c      = shift;
1114     my $name   = $c->config->{name};
1115     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1116     my $prefix = Catalyst::Utils::appprefix( ref $c );
1117     $c->response->content_type('text/html; charset=utf-8');
1118     return <<"EOF";
1119 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1120     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1121 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1122     <head>
1123     <meta http-equiv="Content-Language" content="en" />
1124     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1125         <title>$name on Catalyst $VERSION</title>
1126         <style type="text/css">
1127             body {
1128                 color: #000;
1129                 background-color: #eee;
1130             }
1131             div#content {
1132                 width: 640px;
1133                 margin-left: auto;
1134                 margin-right: auto;
1135                 margin-top: 10px;
1136                 margin-bottom: 10px;
1137                 text-align: left;
1138                 background-color: #ccc;
1139                 border: 1px solid #aaa;
1140             }
1141             p, h1, h2 {
1142                 margin-left: 20px;
1143                 margin-right: 20px;
1144                 font-family: verdana, tahoma, sans-serif;
1145             }
1146             a {
1147                 font-family: verdana, tahoma, sans-serif;
1148             }
1149             :link, :visited {
1150                     text-decoration: none;
1151                     color: #b00;
1152                     border-bottom: 1px dotted #bbb;
1153             }
1154             :link:hover, :visited:hover {
1155                     color: #555;
1156             }
1157             div#topbar {
1158                 margin: 0px;
1159             }
1160             pre {
1161                 margin: 10px;
1162                 padding: 8px;
1163             }
1164             div#answers {
1165                 padding: 8px;
1166                 margin: 10px;
1167                 background-color: #fff;
1168                 border: 1px solid #aaa;
1169             }
1170             h1 {
1171                 font-size: 0.9em;
1172                 font-weight: normal;
1173                 text-align: center;
1174             }
1175             h2 {
1176                 font-size: 1.0em;
1177             }
1178             p {
1179                 font-size: 0.9em;
1180             }
1181             p img {
1182                 float: right;
1183                 margin-left: 10px;
1184             }
1185             span#appname {
1186                 font-weight: bold;
1187                 font-size: 1.6em;
1188             }
1189         </style>
1190     </head>
1191     <body>
1192         <div id="content">
1193             <div id="topbar">
1194                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1195                     $VERSION</h1>
1196              </div>
1197              <div id="answers">
1198                  <p>
1199                  <img src="$logo" alt="Catalyst Logo" />
1200                  </p>
1201                  <p>Welcome to the  world of Catalyst.
1202                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1203                     framework will make web development something you had
1204                     never expected it to be: Fun, rewarding, and quick.</p>
1205                  <h2>What to do now?</h2>
1206                  <p>That really depends  on what <b>you</b> want to do.
1207                     We do, however, provide you with a few starting points.</p>
1208                  <p>If you want to jump right into web development with Catalyst
1209                     you might want to start with a tutorial.</p>
1210 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1211 </pre>
1212 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1213 <pre>
1214 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1215 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1216 </code></pre>
1217                  <h2>What to do next?</h2>
1218                  <p>Next it's time to write an actual application. Use the
1219                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1220                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1221                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1222                     they can save you a lot of work.</p>
1223                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1224                     <p>Also, be sure to check out the vast and growing
1225                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1226                     you are likely to find what you need there.
1227                     </p>
1228
1229                  <h2>Need help?</h2>
1230                  <p>Catalyst has a very active community. Here are the main places to
1231                     get in touch with us.</p>
1232                  <ul>
1233                      <li>
1234                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1235                      </li>
1236                      <li>
1237                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1238                      </li>
1239                      <li>
1240                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1241                      </li>
1242                  </ul>
1243                  <h2>In conclusion</h2>
1244                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1245                     as we enjoyed making it. Please contact us if you have ideas
1246                     for improvement or other feedback.</p>
1247              </div>
1248          </div>
1249     </body>
1250 </html>
1251 EOF
1252 }
1253
1254 =head1 INTERNAL METHODS
1255
1256 These methods are not meant to be used by end users.
1257
1258 =head2 $c->components
1259
1260 Returns a hash of components.
1261
1262 =head2 $c->context_class
1263
1264 Returns or sets the context class.
1265
1266 =head2 $c->counter
1267
1268 Returns a hashref containing coderefs and execution counts (needed for
1269 deep recursion detection).
1270
1271 =head2 $c->depth
1272
1273 Returns the number of actions on the current internal execution stack.
1274
1275 =head2 $c->dispatch
1276
1277 Dispatches a request to actions.
1278
1279 =cut
1280
1281 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1282
1283 =head2 $c->dispatcher_class
1284
1285 Returns or sets the dispatcher class.
1286
1287 =head2 $c->dump_these
1288
1289 Returns a list of 2-element array references (name, structure) pairs
1290 that will be dumped on the error page in debug mode.
1291
1292 =cut
1293
1294 sub dump_these {
1295     my $c = shift;
1296     [ Request => $c->req ],
1297     [ Response => $c->res ],
1298     [ Stash => $c->stash ],
1299     [ Config => $c->config ];
1300 }
1301
1302 =head2 $c->engine_class
1303
1304 Returns or sets the engine class.
1305
1306 =head2 $c->execute( $class, $coderef )
1307
1308 Execute a coderef in given class and catch exceptions. Errors are available
1309 via $c->error.
1310
1311 =cut
1312
1313 sub execute {
1314     my ( $c, $class, $code ) = @_;
1315     $class = $c->component($class) || $class;
1316     $c->state(0);
1317
1318     if ( $c->depth >= $RECURSION ) {
1319         my $action = "$code";
1320         $action = "/$action" unless $action =~ /->/;
1321         my $error = qq/Deep recursion detected calling "$action"/;
1322         $c->log->error($error);
1323         $c->error($error);
1324         $c->state(0);
1325         return $c->state;
1326     }
1327
1328     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1329
1330     push( @{ $c->stack }, $code );
1331
1332     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1333
1334     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1335
1336     my $last = pop( @{ $c->stack } );
1337
1338     if ( my $error = $@ ) {
1339         if ( !ref($error) and $error eq $DETACH ) {
1340             die $DETACH if($c->depth > 1);
1341         }
1342         elsif ( !ref($error) and $error eq $GO ) {
1343             die $GO if($c->depth > 0);
1344         }
1345         else {
1346             unless ( ref $error ) {
1347                 no warnings 'uninitialized';
1348                 chomp $error;
1349                 my $class = $last->class;
1350                 my $name  = $last->name;
1351                 $error = qq/Caught exception in $class->$name "$error"/;
1352             }
1353             $c->error($error);
1354             $c->state(0);
1355         }
1356     }
1357     return $c->state;
1358 }
1359
1360 sub _stats_start_execute {
1361     my ( $c, $code ) = @_;
1362
1363     return if ( ( $code->name =~ /^_.*/ )
1364         && ( !$c->config->{show_internal_actions} ) );
1365
1366     $c->counter->{"$code"}++;
1367
1368     my $action = "$code";
1369     $action = "/$action" unless $action =~ /->/;
1370
1371     # determine if the call was the result of a forward
1372     # this is done by walking up the call stack and looking for a calling
1373     # sub of Catalyst::forward before the eval
1374     my $callsub = q{};
1375     for my $index ( 2 .. 11 ) {
1376         last
1377         if ( ( caller($index) )[0] eq 'Catalyst'
1378             && ( caller($index) )[3] eq '(eval)' );
1379
1380         if ( ( caller($index) )[3] =~ /forward$/ ) {
1381             $callsub = ( caller($index) )[3];
1382             $action  = "-> $action";
1383             last;
1384         }
1385     }
1386
1387     my $uid = "$code" . $c->counter->{"$code"};
1388
1389     # is this a root-level call or a forwarded call?
1390     if ( $callsub =~ /forward$/ ) {
1391
1392         # forward, locate the caller
1393         if ( my $parent = $c->stack->[-1] ) {
1394             $c->stats->profile(
1395                 begin  => $action,
1396                 parent => "$parent" . $c->counter->{"$parent"},
1397                 uid    => $uid,
1398             );
1399         }
1400         else {
1401
1402             # forward with no caller may come from a plugin
1403             $c->stats->profile(
1404                 begin => $action,
1405                 uid   => $uid,
1406             );
1407         }
1408     }
1409     else {
1410
1411         # root-level call
1412         $c->stats->profile(
1413             begin => $action,
1414             uid   => $uid,
1415         );
1416     }
1417     return $action;
1418
1419 }
1420
1421 sub _stats_finish_execute {
1422     my ( $c, $info ) = @_;
1423     $c->stats->profile( end => $info );
1424 }
1425
1426 =head2 $c->_localize_fields( sub { }, \%keys );
1427
1428 =cut
1429
1430 sub _localize_fields {
1431     my ( $c, $localized, $code ) = ( @_ );
1432
1433     my $request = delete $localized->{request} || {};
1434     my $response = delete $localized->{response} || {};
1435
1436     local @{ $c }{ keys %$localized } = values %$localized;
1437     local @{ $c->request }{ keys %$request } = values %$request;
1438     local @{ $c->response }{ keys %$response } = values %$response;
1439
1440     $code->();
1441 }
1442
1443 =head2 $c->finalize
1444
1445 Finalizes the request.
1446
1447 =cut
1448
1449 sub finalize {
1450     my $c = shift;
1451
1452     for my $error ( @{ $c->error } ) {
1453         $c->log->error($error);
1454     }
1455
1456     # Allow engine to handle finalize flow (for POE)
1457     if ( $c->engine->can('finalize') ) {
1458         $c->engine->finalize($c);
1459     }
1460     else {
1461
1462         $c->finalize_uploads;
1463
1464         # Error
1465         if ( $#{ $c->error } >= 0 ) {
1466             $c->finalize_error;
1467         }
1468
1469         $c->finalize_headers;
1470
1471         # HEAD request
1472         if ( $c->request->method eq 'HEAD' ) {
1473             $c->response->body('');
1474         }
1475
1476         $c->finalize_body;
1477     }
1478
1479     if ($c->use_stats) {
1480         my $elapsed = sprintf '%f', $c->stats->elapsed;
1481         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1482         $c->log->info(
1483             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1484     }
1485
1486     return $c->response->status;
1487 }
1488
1489 =head2 $c->finalize_body
1490
1491 Finalizes body.
1492
1493 =cut
1494
1495 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1496
1497 =head2 $c->finalize_cookies
1498
1499 Finalizes cookies.
1500
1501 =cut
1502
1503 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1504
1505 =head2 $c->finalize_error
1506
1507 Finalizes error.
1508
1509 =cut
1510
1511 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1512
1513 =head2 $c->finalize_headers
1514
1515 Finalizes headers.
1516
1517 =cut
1518
1519 sub finalize_headers {
1520     my $c = shift;
1521
1522     # Check if we already finalized headers
1523     return if $c->response->{_finalized_headers};
1524
1525     # Handle redirects
1526     if ( my $location = $c->response->redirect ) {
1527         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1528         $c->response->header( Location => $location );
1529
1530         if ( !$c->response->body ) {
1531             # Add a default body if none is already present
1532             $c->response->body(
1533                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1534             );
1535         }
1536     }
1537
1538     # Content-Length
1539     if ( $c->response->body && !$c->response->content_length ) {
1540
1541         # get the length from a filehandle
1542         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1543         {
1544             my $stat = stat $c->response->body;
1545             if ( $stat && $stat->size > 0 ) {
1546                 $c->response->content_length( $stat->size );
1547             }
1548             else {
1549                 $c->log->warn('Serving filehandle without a content-length');
1550             }
1551         }
1552         else {
1553             # everything should be bytes at this point, but just in case
1554             $c->response->content_length( bytes::length( $c->response->body ) );
1555         }
1556     }
1557
1558     # Errors
1559     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1560         $c->response->headers->remove_header("Content-Length");
1561         $c->response->body('');
1562     }
1563
1564     $c->finalize_cookies;
1565
1566     $c->engine->finalize_headers( $c, @_ );
1567
1568     # Done
1569     $c->response->{_finalized_headers} = 1;
1570 }
1571
1572 =head2 $c->finalize_output
1573
1574 An alias for finalize_body.
1575
1576 =head2 $c->finalize_read
1577
1578 Finalizes the input after reading is complete.
1579
1580 =cut
1581
1582 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1583
1584 =head2 $c->finalize_uploads
1585
1586 Finalizes uploads. Cleans up any temporary files.
1587
1588 =cut
1589
1590 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1591
1592 =head2 $c->get_action( $action, $namespace )
1593
1594 Gets an action in a given namespace.
1595
1596 =cut
1597
1598 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1599
1600 =head2 $c->get_actions( $action, $namespace )
1601
1602 Gets all actions of a given name in a namespace and all parent
1603 namespaces.
1604
1605 =cut
1606
1607 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1608
1609 =head2 $c->handle_request( $class, @arguments )
1610
1611 Called to handle each HTTP request.
1612
1613 =cut
1614
1615 sub handle_request {
1616     my ( $class, @arguments ) = @_;
1617
1618     # Always expect worst case!
1619     my $status = -1;
1620     eval {
1621         if ($class->debug) {
1622             my $secs = time - $START || 1;
1623             my $av = sprintf '%.3f', $COUNT / $secs;
1624             my $time = localtime time;
1625             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1626         }
1627
1628         my $c = $class->prepare(@arguments);
1629         $c->dispatch;
1630         $status = $c->finalize;
1631     };
1632
1633     if ( my $error = $@ ) {
1634         chomp $error;
1635         $class->log->error(qq/Caught exception in engine "$error"/);
1636     }
1637
1638     $COUNT++;
1639     $class->log->_flush() if $class->log->can('_flush');
1640     return $status;
1641 }
1642
1643 =head2 $c->prepare( @arguments )
1644
1645 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1646 etc.).
1647
1648 =cut
1649
1650 sub prepare {
1651     my ( $class, @arguments ) = @_;
1652
1653     $class->context_class( ref $class || $class ) unless $class->context_class;
1654     my $c = $class->context_class->new(
1655         {
1656             counter => {},
1657             stack   => [],
1658             request => $class->request_class->new(
1659                 {
1660                     arguments        => [],
1661                     body_parameters  => {},
1662                     cookies          => {},
1663                     headers          => HTTP::Headers->new,
1664                     parameters       => {},
1665                     query_parameters => {},
1666                     secure           => 0,
1667                     captures         => [],
1668                     uploads          => {}
1669                 }
1670             ),
1671             response => $class->response_class->new(
1672                 {
1673                     body    => '',
1674                     cookies => {},
1675                     headers => HTTP::Headers->new(),
1676                     status  => 200
1677                 }
1678             ),
1679             stash => {},
1680             state => 0
1681         }
1682     );
1683
1684     $c->stats($class->stats_class->new)->enable($c->use_stats);
1685     if ( $c->debug ) {
1686         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1687     }
1688
1689     # For on-demand data
1690     $c->request->{_context}  = $c;
1691     $c->response->{_context} = $c;
1692     weaken( $c->request->{_context} );
1693     weaken( $c->response->{_context} );
1694
1695     # Allow engine to direct the prepare flow (for POE)
1696     if ( $c->engine->can('prepare') ) {
1697         $c->engine->prepare( $c, @arguments );
1698     }
1699     else {
1700         $c->prepare_request(@arguments);
1701         $c->prepare_connection;
1702         $c->prepare_query_parameters;
1703         $c->prepare_headers;
1704         $c->prepare_cookies;
1705         $c->prepare_path;
1706
1707         # Prepare the body for reading, either by prepare_body
1708         # or the user, if they are using $c->read
1709         $c->prepare_read;
1710
1711         # Parse the body unless the user wants it on-demand
1712         unless ( $c->config->{parse_on_demand} ) {
1713             $c->prepare_body;
1714         }
1715     }
1716
1717     my $method  = $c->req->method  || '';
1718     my $path    = $c->req->path;
1719     $path       = '/' unless length $path;
1720     my $address = $c->req->address || '';
1721
1722     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1723       if $c->debug;
1724
1725     $c->prepare_action;
1726
1727     return $c;
1728 }
1729
1730 =head2 $c->prepare_action
1731
1732 Prepares action. See L<Catalyst::Dispatcher>.
1733
1734 =cut
1735
1736 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1737
1738 =head2 $c->prepare_body
1739
1740 Prepares message body.
1741
1742 =cut
1743
1744 sub prepare_body {
1745     my $c = shift;
1746
1747     # Do we run for the first time?
1748     return if defined $c->request->{_body};
1749
1750     # Initialize on-demand data
1751     $c->engine->prepare_body( $c, @_ );
1752     $c->prepare_parameters;
1753     $c->prepare_uploads;
1754
1755     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1756         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1757         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1758             my $param = $c->req->body_parameters->{$key};
1759             my $value = defined($param) ? $param : '';
1760             $t->row( $key,
1761                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1762         }
1763         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1764     }
1765 }
1766
1767 =head2 $c->prepare_body_chunk( $chunk )
1768
1769 Prepares a chunk of data before sending it to L<HTTP::Body>.
1770
1771 See L<Catalyst::Engine>.
1772
1773 =cut
1774
1775 sub prepare_body_chunk {
1776     my $c = shift;
1777     $c->engine->prepare_body_chunk( $c, @_ );
1778 }
1779
1780 =head2 $c->prepare_body_parameters
1781
1782 Prepares body parameters.
1783
1784 =cut
1785
1786 sub prepare_body_parameters {
1787     my $c = shift;
1788     $c->engine->prepare_body_parameters( $c, @_ );
1789 }
1790
1791 =head2 $c->prepare_connection
1792
1793 Prepares connection.
1794
1795 =cut
1796
1797 sub prepare_connection {
1798     my $c = shift;
1799     $c->engine->prepare_connection( $c, @_ );
1800 }
1801
1802 =head2 $c->prepare_cookies
1803
1804 Prepares cookies.
1805
1806 =cut
1807
1808 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1809
1810 =head2 $c->prepare_headers
1811
1812 Prepares headers.
1813
1814 =cut
1815
1816 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1817
1818 =head2 $c->prepare_parameters
1819
1820 Prepares parameters.
1821
1822 =cut
1823
1824 sub prepare_parameters {
1825     my $c = shift;
1826     $c->prepare_body_parameters;
1827     $c->engine->prepare_parameters( $c, @_ );
1828 }
1829
1830 =head2 $c->prepare_path
1831
1832 Prepares path and base.
1833
1834 =cut
1835
1836 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1837
1838 =head2 $c->prepare_query_parameters
1839
1840 Prepares query parameters.
1841
1842 =cut
1843
1844 sub prepare_query_parameters {
1845     my $c = shift;
1846
1847     $c->engine->prepare_query_parameters( $c, @_ );
1848
1849     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1850         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1851         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1852             my $param = $c->req->query_parameters->{$key};
1853             my $value = defined($param) ? $param : '';
1854             $t->row( $key,
1855                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1856         }
1857         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1858     }
1859 }
1860
1861 =head2 $c->prepare_read
1862
1863 Prepares the input for reading.
1864
1865 =cut
1866
1867 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1868
1869 =head2 $c->prepare_request
1870
1871 Prepares the engine request.
1872
1873 =cut
1874
1875 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1876
1877 =head2 $c->prepare_uploads
1878
1879 Prepares uploads.
1880
1881 =cut
1882
1883 sub prepare_uploads {
1884     my $c = shift;
1885
1886     $c->engine->prepare_uploads( $c, @_ );
1887
1888     if ( $c->debug && keys %{ $c->request->uploads } ) {
1889         my $t = Text::SimpleTable->new(
1890             [ 12, 'Parameter' ],
1891             [ 26, 'Filename' ],
1892             [ 18, 'Type' ],
1893             [ 9,  'Size' ]
1894         );
1895         for my $key ( sort keys %{ $c->request->uploads } ) {
1896             my $upload = $c->request->uploads->{$key};
1897             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1898                 $t->row( $key, $u->filename, $u->type, $u->size );
1899             }
1900         }
1901         $c->log->debug( "File Uploads are:\n" . $t->draw );
1902     }
1903 }
1904
1905 =head2 $c->prepare_write
1906
1907 Prepares the output for writing.
1908
1909 =cut
1910
1911 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1912
1913 =head2 $c->request_class
1914
1915 Returns or sets the request class.
1916
1917 =head2 $c->response_class
1918
1919 Returns or sets the response class.
1920
1921 =head2 $c->read( [$maxlength] )
1922
1923 Reads a chunk of data from the request body. This method is designed to
1924 be used in a while loop, reading C<$maxlength> bytes on every call.
1925 C<$maxlength> defaults to the size of the request if not specified.
1926
1927 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1928 directly.
1929
1930 Warning: If you use read(), Catalyst will not process the body,
1931 so you will not be able to access POST parameters or file uploads via
1932 $c->request.  You must handle all body parsing yourself.
1933
1934 =cut
1935
1936 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1937
1938 =head2 $c->run
1939
1940 Starts the engine.
1941
1942 =cut
1943
1944 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1945
1946 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1947
1948 Sets an action in a given namespace.
1949
1950 =cut
1951
1952 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1953
1954 =head2 $c->setup_actions($component)
1955
1956 Sets up actions for a component.
1957
1958 =cut
1959
1960 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1961
1962 =head2 $c->setup_components
1963
1964 Sets up components. Specify a C<setup_components> config option to pass
1965 additional options directly to L<Module::Pluggable>. To add additional
1966 search paths, specify a key named C<search_extra> as an array
1967 reference. Items in the array beginning with C<::> will have the
1968 application class name prepended to them.
1969
1970 All components found will also have any
1971 L<Devel::InnerPackage|inner packages> loaded and set up as components.
1972 Note, that modules which are B<not> an I<inner package> of the main
1973 file namespace loaded will not be instantiated as components.
1974
1975 =cut
1976
1977 sub setup_components {
1978     my $class = shift;
1979
1980     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1981     my $config  = $class->config->{ setup_components };
1982     my $extra   = delete $config->{ search_extra } || [];
1983
1984     push @paths, @$extra;
1985
1986     my $locator = Module::Pluggable::Object->new(
1987         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1988         %$config
1989     );
1990
1991     my @comps = sort { length $a <=> length $b } $locator->plugins;
1992     my %comps = map { $_ => 1 } @comps;
1993
1994     for my $component ( @comps ) {
1995
1996         # We pass ignore_loaded here so that overlay files for (e.g.)
1997         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1998         # we know M::P::O found a file on disk so this is safe
1999
2000         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2001
2002         my $module  = $class->setup_component( $component );
2003         my %modules = (
2004             $component => $module,
2005             map {
2006                 $_ => $class->setup_component( $_ )
2007             } grep {
2008               not exists $comps{$_}
2009             } Devel::InnerPackage::list_packages( $component )
2010         );
2011
2012         for my $key ( keys %modules ) {
2013             $class->components->{ $key } = $modules{ $key };
2014         }
2015     }
2016 }
2017
2018 =head2 $c->setup_component
2019
2020 =cut
2021
2022 sub setup_component {
2023     my( $class, $component ) = @_;
2024
2025     unless ( $component->can( 'COMPONENT' ) ) {
2026         return $component;
2027     }
2028
2029     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2030     my $config = $class->config->{ $suffix } || {};
2031
2032     my $instance = eval { $component->COMPONENT( $class, $config ); };
2033
2034     if ( my $error = $@ ) {
2035         chomp $error;
2036         Catalyst::Exception->throw(
2037             message => qq/Couldn't instantiate component "$component", "$error"/
2038         );
2039     }
2040
2041     Catalyst::Exception->throw(
2042         message =>
2043         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2044     ) unless eval { $instance->can( 'can' ) };
2045
2046     return $instance;
2047 }
2048
2049 =head2 $c->setup_dispatcher
2050
2051 Sets up dispatcher.
2052
2053 =cut
2054
2055 sub setup_dispatcher {
2056     my ( $class, $dispatcher ) = @_;
2057
2058     if ($dispatcher) {
2059         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2060     }
2061
2062     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2063         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2064     }
2065
2066     unless ($dispatcher) {
2067         $dispatcher = $class->dispatcher_class;
2068     }
2069
2070     unless (Class::Inspector->loaded($dispatcher)) {
2071         require Class::Inspector->filename($dispatcher);
2072     }
2073
2074     # dispatcher instance
2075     $class->dispatcher( $dispatcher->new );
2076 }
2077
2078 =head2 $c->setup_engine
2079
2080 Sets up engine.
2081
2082 =cut
2083
2084 sub setup_engine {
2085     my ( $class, $engine ) = @_;
2086
2087     if ($engine) {
2088         $engine = 'Catalyst::Engine::' . $engine;
2089     }
2090
2091     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2092         $engine = 'Catalyst::Engine::' . $env;
2093     }
2094
2095     if ( $ENV{MOD_PERL} ) {
2096
2097         # create the apache method
2098         {
2099             no strict 'refs';
2100             *{"$class\::apache"} = sub { shift->engine->apache };
2101         }
2102
2103         my ( $software, $version ) =
2104           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2105
2106         $version =~ s/_//g;
2107         $version =~ s/(\.[^.]+)\./$1/g;
2108
2109         if ( $software eq 'mod_perl' ) {
2110
2111             if ( !$engine ) {
2112
2113                 if ( $version >= 1.99922 ) {
2114                     $engine = 'Catalyst::Engine::Apache2::MP20';
2115                 }
2116
2117                 elsif ( $version >= 1.9901 ) {
2118                     $engine = 'Catalyst::Engine::Apache2::MP19';
2119                 }
2120
2121                 elsif ( $version >= 1.24 ) {
2122                     $engine = 'Catalyst::Engine::Apache::MP13';
2123                 }
2124
2125                 else {
2126                     Catalyst::Exception->throw( message =>
2127                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2128                 }
2129
2130             }
2131
2132             # install the correct mod_perl handler
2133             if ( $version >= 1.9901 ) {
2134                 *handler = sub  : method {
2135                     shift->handle_request(@_);
2136                 };
2137             }
2138             else {
2139                 *handler = sub ($$) { shift->handle_request(@_) };
2140             }
2141
2142         }
2143
2144         elsif ( $software eq 'Zeus-Perl' ) {
2145             $engine = 'Catalyst::Engine::Zeus';
2146         }
2147
2148         else {
2149             Catalyst::Exception->throw(
2150                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2151         }
2152     }
2153
2154     unless ($engine) {
2155         $engine = $class->engine_class;
2156     }
2157
2158     unless (Class::Inspector->loaded($engine)) {
2159         require Class::Inspector->filename($engine);
2160     }
2161
2162     # check for old engines that are no longer compatible
2163     my $old_engine;
2164     if ( $engine->isa('Catalyst::Engine::Apache')
2165         && !Catalyst::Engine::Apache->VERSION )
2166     {
2167         $old_engine = 1;
2168     }
2169
2170     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2171         && Catalyst::Engine::Server->VERSION le '0.02' )
2172     {
2173         $old_engine = 1;
2174     }
2175
2176     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2177         && $engine->VERSION eq '0.01' )
2178     {
2179         $old_engine = 1;
2180     }
2181
2182     elsif ($engine->isa('Catalyst::Engine::Zeus')
2183         && $engine->VERSION eq '0.01' )
2184     {
2185         $old_engine = 1;
2186     }
2187
2188     if ($old_engine) {
2189         Catalyst::Exception->throw( message =>
2190               qq/Engine "$engine" is not supported by this version of Catalyst/
2191         );
2192     }
2193
2194     # engine instance
2195     $class->engine( $engine->new );
2196 }
2197
2198 =head2 $c->setup_home
2199
2200 Sets up the home directory.
2201
2202 =cut
2203
2204 sub setup_home {
2205     my ( $class, $home ) = @_;
2206
2207     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2208         $home = $env;
2209     }
2210
2211     unless ($home) {
2212         $home = Catalyst::Utils::home($class);
2213     }
2214
2215     if ($home) {
2216         $class->config->{home} ||= $home;
2217         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2218     }
2219 }
2220
2221 =head2 $c->setup_log
2222
2223 Sets up log.
2224
2225 =cut
2226
2227 sub setup_log {
2228     my ( $class, $debug ) = @_;
2229
2230     unless ( $class->log ) {
2231         $class->log( Catalyst::Log->new );
2232     }
2233
2234     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2235     if ( defined($env_debug) ? $env_debug : $debug ) {
2236         no strict 'refs';
2237         *{"$class\::debug"} = sub { 1 };
2238         $class->log->debug('Debug messages enabled');
2239     }
2240 }
2241
2242 =head2 $c->setup_plugins
2243
2244 Sets up plugins.
2245
2246 =cut
2247
2248 =head2 $c->setup_stats
2249
2250 Sets up timing statistics class.
2251
2252 =cut
2253
2254 sub setup_stats {
2255     my ( $class, $stats ) = @_;
2256
2257     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2258
2259     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2260     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2261         no strict 'refs';
2262         *{"$class\::use_stats"} = sub { 1 };
2263         $class->log->debug('Statistics enabled');
2264     }
2265 }
2266
2267
2268 =head2 $c->registered_plugins
2269
2270 Returns a sorted list of the plugins which have either been stated in the
2271 import list or which have been added via C<< MyApp->plugin(@args); >>.
2272
2273 If passed a given plugin name, it will report a boolean value indicating
2274 whether or not that plugin is loaded.  A fully qualified name is required if
2275 the plugin name does not begin with C<Catalyst::Plugin::>.
2276
2277  if ($c->registered_plugins('Some::Plugin')) {
2278      ...
2279  }
2280
2281 =cut
2282
2283 {
2284
2285     sub registered_plugins {
2286         my $proto = shift;
2287         return sort keys %{ $proto->_plugins } unless @_;
2288         my $plugin = shift;
2289         return 1 if exists $proto->_plugins->{$plugin};
2290         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2291     }
2292
2293     sub _register_plugin {
2294         my ( $proto, $plugin, $instant ) = @_;
2295         my $class = ref $proto || $proto;
2296
2297         # no ignore_loaded here, the plugin may already have been
2298         # defined in memory and we don't want to error on "no file" if so
2299
2300         Catalyst::Utils::ensure_class_loaded( $plugin );
2301
2302         $proto->_plugins->{$plugin} = 1;
2303         unless ($instant) {
2304             no strict 'refs';
2305             unshift @{"$class\::ISA"}, $plugin;
2306         }
2307         return $class;
2308     }
2309
2310     sub setup_plugins {
2311         my ( $class, $plugins ) = @_;
2312
2313         $class->_plugins( {} ) unless $class->_plugins;
2314         $plugins ||= [];
2315         for my $plugin ( reverse @$plugins ) {
2316
2317             unless ( $plugin =~ s/\A\+// ) {
2318                 $plugin = "Catalyst::Plugin::$plugin";
2319             }
2320
2321             $class->_register_plugin($plugin);
2322         }
2323     }
2324 }
2325
2326 =head2 $c->stack
2327
2328 Returns an arrayref of the internal execution stack (actions that are
2329 currently executing).
2330
2331 =head2 $c->stats_class
2332
2333 Returns or sets the stats (timing statistics) class.
2334
2335 =head2 $c->use_stats
2336
2337 Returns 1 when stats collection is enabled.  Stats collection is enabled
2338 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2339 environment variable is set.
2340
2341 Note that this is a static method, not an accessor and should be overloaded
2342 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2343
2344 =cut
2345
2346 sub use_stats { 0 }
2347
2348
2349 =head2 $c->write( $data )
2350
2351 Writes $data to the output stream. When using this method directly, you
2352 will need to manually set the C<Content-Length> header to the length of
2353 your output data, if known.
2354
2355 =cut
2356
2357 sub write {
2358     my $c = shift;
2359
2360     # Finalize headers if someone manually writes output
2361     $c->finalize_headers;
2362
2363     return $c->engine->write( $c, @_ );
2364 }
2365
2366 =head2 version
2367
2368 Returns the Catalyst version number. Mostly useful for "powered by"
2369 messages in template systems.
2370
2371 =cut
2372
2373 sub version { return $Catalyst::VERSION }
2374
2375 =head1 INTERNAL ACTIONS
2376
2377 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2378 C<_ACTION>, and C<_END>. These are by default not shown in the private
2379 action table, but you can make them visible with a config parameter.
2380
2381     MyApp->config->{show_internal_actions} = 1;
2382
2383 =head1 CASE SENSITIVITY
2384
2385 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2386 mapped to C</foo/bar>. You can activate case sensitivity with a config
2387 parameter.
2388
2389     MyApp->config->{case_sensitive} = 1;
2390
2391 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2392
2393 =head1 ON-DEMAND PARSER
2394
2395 The request body is usually parsed at the beginning of a request,
2396 but if you want to handle input yourself, you can enable on-demand
2397 parsing with a config parameter.
2398
2399     MyApp->config->{parse_on_demand} = 1;
2400
2401 =head1 PROXY SUPPORT
2402
2403 Many production servers operate using the common double-server approach,
2404 with a lightweight frontend web server passing requests to a larger
2405 backend server. An application running on the backend server must deal
2406 with two problems: the remote user always appears to be C<127.0.0.1> and
2407 the server's hostname will appear to be C<localhost> regardless of the
2408 virtual host that the user connected through.
2409
2410 Catalyst will automatically detect this situation when you are running
2411 the frontend and backend servers on the same machine. The following
2412 changes are made to the request.
2413
2414     $c->req->address is set to the user's real IP address, as read from
2415     the HTTP X-Forwarded-For header.
2416
2417     The host value for $c->req->base and $c->req->uri is set to the real
2418     host, as read from the HTTP X-Forwarded-Host header.
2419
2420 Obviously, your web server must support these headers for this to work.
2421
2422 In a more complex server farm environment where you may have your
2423 frontend proxy server(s) on different machines, you will need to set a
2424 configuration option to tell Catalyst to read the proxied data from the
2425 headers.
2426
2427     MyApp->config->{using_frontend_proxy} = 1;
2428
2429 If you do not wish to use the proxy support at all, you may set:
2430
2431     MyApp->config->{ignore_frontend_proxy} = 1;
2432
2433 =head1 THREAD SAFETY
2434
2435 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2436 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2437 believe the Catalyst core to be thread-safe.
2438
2439 If you plan to operate in a threaded environment, remember that all other
2440 modules you are using must also be thread-safe. Some modules, most notably
2441 L<DBD::SQLite>, are not thread-safe.
2442
2443 =head1 SUPPORT
2444
2445 IRC:
2446
2447     Join #catalyst on irc.perl.org.
2448
2449 Mailing Lists:
2450
2451     http://lists.rawmode.org/mailman/listinfo/catalyst
2452     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2453
2454 Web:
2455
2456     http://catalyst.perl.org
2457
2458 Wiki:
2459
2460     http://dev.catalyst.perl.org
2461
2462 =head1 SEE ALSO
2463
2464 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2465
2466 =head2 L<Catalyst::Manual> - The Catalyst Manual
2467
2468 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2469
2470 =head2 L<Catalyst::Engine> - Core engine
2471
2472 =head2 L<Catalyst::Log> - Log class.
2473
2474 =head2 L<Catalyst::Request> - Request object
2475
2476 =head2 L<Catalyst::Response> - Response object
2477
2478 =head2 L<Catalyst::Test> - The test suite.
2479
2480 =head1 PROJECT FOUNDER
2481
2482 sri: Sebastian Riedel <sri@cpan.org>
2483
2484 =head1 CONTRIBUTORS
2485
2486 abw: Andy Wardley
2487
2488 acme: Leon Brocard <leon@astray.com>
2489
2490 Andrew Bramble
2491
2492 Andrew Ford
2493
2494 Andrew Ruthven
2495
2496 andyg: Andy Grundman <andy@hybridized.org>
2497
2498 audreyt: Audrey Tang
2499
2500 bricas: Brian Cassidy <bricas@cpan.org>
2501
2502 chansen: Christian Hansen
2503
2504 chicks: Christopher Hicks
2505
2506 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2507
2508 Drew Taylor
2509
2510 esskar: Sascha Kiefer
2511
2512 fireartist: Carl Franks <cfranks@cpan.org>
2513
2514 gabb: Danijel Milicevic
2515
2516 Gary Ashton Jones
2517
2518 Geoff Richards
2519
2520 jcamacho: Juan Camacho
2521
2522 Jody Belka
2523
2524 Johan Lindstrom
2525
2526 jon: Jon Schutz <jjschutz@cpan.org>
2527
2528 marcus: Marcus Ramberg <mramberg@cpan.org>
2529
2530 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2531
2532 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2533
2534 mugwump: Sam Vilain
2535
2536 naughton: David Naughton
2537
2538 ningu: David Kamholz <dkamholz@cpan.org>
2539
2540 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2541
2542 numa: Dan Sully <daniel@cpan.org>
2543
2544 obra: Jesse Vincent
2545
2546 omega: Andreas Marienborg
2547
2548 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2549
2550 sky: Arthur Bergman
2551
2552 the_jester: Jesse Sheidlower
2553
2554 Ulf Edvinsson
2555
2556 willert: Sebastian Willert <willert@cpan.org>
2557
2558 =head1 LICENSE
2559
2560 This library is free software, you can redistribute it and/or modify it under
2561 the same terms as Perl itself.
2562
2563 =cut
2564
2565 1;