lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use Scalar::Util qw/weaken blessed/;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use attributes;
  26 use utf8;
  27 use Carp qw/croak/;
  28
  29 BEGIN { require 5.008001; }
  30
  31 __PACKAGE__->mk_accessors(
  32     qw/counter request response state action stack namespace stats/
  33 );
  34
  35 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class setup_finished/;
  56
  57 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  58 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  59 __PACKAGE__->request_class('Catalyst::Request');
  60 __PACKAGE__->response_class('Catalyst::Response');
  61
  62 # Remember to update this in Catalyst::Runtime as well!
  63
  64 our $VERSION = '5.7006';
  65
  66 sub import {
  67     my ( $class, @arguments ) = @_;
  68
  69     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  70     # callers @ISA.
  71     return unless $class eq 'Catalyst';
  72
  73     my $caller = caller(0);
  74
  75     unless ( $caller->isa('Catalyst') ) {
  76         no strict 'refs';
  77         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  78     }
  79
  80     $caller->arguments( [@arguments] );
  81     $caller->setup_home;
  82 }
  83
  84 =head1 NAME
  85
  86 Catalyst - The Elegant MVC Web Application Framework
  87
  88 =head1 SYNOPSIS
  89
  90     # Install Catalyst::Devel for helpers and other development tools
  91     # use the helper to create a new application
  92     catalyst.pl MyApp
  93
  94     # add models, views, controllers
  95     script/myapp_create.pl model MyDatabase DBIC::Schema create=dynamic dbi:SQLite:/path/to/db
  96     script/myapp_create.pl view MyTemplate TT
  97     script/myapp_create.pl controller Search
  98
  99     # built in testserver -- use -r to restart automatically on changes
 100     # --help to see all available options
 101     script/myapp_server.pl
 102
 103     # command line testing interface
 104     script/myapp_test.pl /yada
 105
 106     ### in lib/MyApp.pm
 107     use Catalyst qw/-Debug/; # include plugins here as well
 108
 109         ### In lib/MyApp/Controller/Root.pm (autocreated)
 110     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 111         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 112         $c->stash->{template} = 'foo.tt'; # set the template
 113         # lookup something from db -- stash vars are passed to TT
 114         $c->stash->{data} =
 115           $c->model('Database::Foo')->search( { country => $args[0] } );
 116         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 117             $c->forward( 'bar' ); # process another action
 118             # do something else after forward returns
 119         }
 120     }
 121
 122     # The foo.tt TT template can use the stash data from the database
 123     [% WHILE (item = data.next) %]
 124         [% item.foo %]
 125     [% END %]
 126
 127     # called for /bar/of/soap, /bar/of/soap/10, etc.
 128     sub bar : Path('/bar/of/soap') { ... }
 129
 130     # called for all actions, from the top-most controller downwards
 131     sub auto : Private {
 132         my ( $self, $c ) = @_;
 133         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 134             $c->res->redirect( '/login' ); # require login
 135             return 0; # abort request and go immediately to end()
 136         }
 137         return 1; # success; carry on to next action
 138     }
 139
 140     # called after all actions are finished
 141     sub end : Private {
 142         my ( $self, $c ) = @_;
 143         if ( scalar @{ $c->error } ) { ... } # handle errors
 144         return if $c->res->body; # already have a response
 145         $c->forward( 'MyApp::View::TT' ); # render template
 146     }
 147
 148     ### in MyApp/Controller/Foo.pm
 149     # called for /foo/bar
 150     sub bar : Local { ... }
 151
 152     # called for /blargle
 153     sub blargle : Global { ... }
 154
 155     # an index action matches /foo, but not /foo/1, etc.
 156     sub index : Private { ... }
 157
 158     ### in MyApp/Controller/Foo/Bar.pm
 159     # called for /foo/bar/baz
 160     sub baz : Local { ... }
 161
 162     # first Root auto is called, then Foo auto, then this
 163     sub auto : Private { ... }
 164
 165     # powerful regular expression paths are also possible
 166     sub details : Regex('^product/(\w+)/details$') {
 167         my ( $self, $c ) = @_;
 168         # extract the (\w+) from the URI
 169         my $product = $c->req->captures->[0];
 170     }
 171
 172 See L<Catalyst::Manual::Intro> for additional information.
 173
 174 =head1 DESCRIPTION
 175
 176 Catalyst is a modern framework for making web applications without the
 177 pain usually associated with this process. This document is a reference
 178 to the main Catalyst application. If you are a new user, we suggest you
 179 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 180
 181 See L<Catalyst::Manual> for more documentation.
 182
 183 Catalyst plugins can be loaded by naming them as arguments to the "use
 184 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 185 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 186 C<My::Module>.
 187
 188     use Catalyst qw/My::Module/;
 189
 190 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 191 fully qualify the name by using a unary plus:
 192
 193     use Catalyst qw/
 194         My::Module
 195         +Fully::Qualified::Plugin::Name
 196     /;
 197
 198 Special flags like C<-Debug> and C<-Engine> can also be specified as
 199 arguments when Catalyst is loaded:
 200
 201     use Catalyst qw/-Debug My::Module/;
 202
 203 The position of plugins and flags in the chain is important, because
 204 they are loaded in the order in which they appear.
 205
 206 The following flags are supported:
 207
 208 =head2 -Debug
 209
 210 Enables debug output. You can also force this setting from the system
 211 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 212 settings override the application, with <MYAPP>_DEBUG having the highest
 213 priority.
 214
 215 =head2 -Engine
 216
 217 Forces Catalyst to use a specific engine. Omit the
 218 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 219
 220     use Catalyst qw/-Engine=CGI/;
 221
 222 =head2 -Home
 223
 224 Forces Catalyst to use a specific home directory, e.g.:
 225
 226     use Catalyst qw[-Home=/usr/mst];
 227
 228 This can also be done in the shell environment by setting either the
 229 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 230 is replaced with the uppercased name of your application, any "::" in
 231 the name will be replaced with underscores, e.g. MyApp::Web should use
 232 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 233
 234 =head2 -Log
 235
 236 Specifies log level.
 237
 238 =head1 METHODS
 239
 240 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 241
 242 =head2 $c->action
 243
 244 Returns a L<Catalyst::Action> object for the current action, which
 245 stringifies to the action name. See L<Catalyst::Action>.
 246
 247 =head2 $c->namespace
 248
 249 Returns the namespace of the current action, i.e., the URI prefix
 250 corresponding to the controller of the current action. For example:
 251
 252     # in Controller::Foo::Bar
 253     $c->namespace; # returns 'foo/bar';
 254
 255 =head2 $c->request
 256
 257 =head2 $c->req
 258
 259 Returns the current L<Catalyst::Request> object, giving access to
 260 information about the current client request (including parameters,
 261 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 262
 263 =head2 REQUEST FLOW HANDLING
 264
 265 =head2 $c->forward( $action [, \@arguments ] )
 266
 267 =head2 $c->forward( $class, $method, [, \@arguments ] )
 268
 269 Forwards processing to another action, by its private name. If you give a
 270 class name but no method, C<process()> is called. You may also optionally
 271 pass arguments in an arrayref. The action will receive the arguments in
 272 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 273 C<< $c->req->args >> will be restored to the previous values.
 274
 275 Any data C<return>ed from the action forwarded to, will be returned by the
 276 call to forward.
 277
 278     my $foodata = $c->forward('/foo');
 279     $c->forward('index');
 280     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 281     $c->forward('MyApp::View::TT');
 282
 283 Note that forward implies an C<<eval { }>> around the call (actually
 284 C<execute> does), thus de-fatalizing all 'dies' within the called
 285 action. If you want C<die> to propagate you need to do something like:
 286
 287     $c->forward('foo');
 288     die $c->error if $c->error;
 289
 290 Or make sure to always return true values from your actions and write
 291 your code like this:
 292
 293     $c->forward('foo') || return;
 294
 295 =cut
 296
 297 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 298
 299 =head2 $c->detach( $action [, \@arguments ] )
 300
 301 =head2 $c->detach( $class, $method, [, \@arguments ] )
 302
 303 =head2 $c->detach()
 304
 305 The same as C<forward>, but doesn't return to the previous action when
 306 processing is finished.
 307
 308 When called with no arguments it escapes the processing chain entirely.
 309
 310 =cut
 311
 312 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 313
 314 =head2 $c->response
 315
 316 =head2 $c->res
 317
 318 Returns the current L<Catalyst::Response> object, see there for details.
 319
 320 =head2 $c->stash
 321
 322 Returns a hashref to the stash, which may be used to store data and pass
 323 it between components during a request. You can also set hash keys by
 324 passing arguments. The stash is automatically sent to the view. The
 325 stash is cleared at the end of a request; it cannot be used for
 326 persistent storage (for this you must use a session; see
 327 L<Catalyst::Plugin::Session> for a complete system integrated with
 328 Catalyst).
 329
 330     $c->stash->{foo} = $bar;
 331     $c->stash( { moose => 'majestic', qux => 0 } );
 332     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 333
 334     # stash is automatically passed to the view for use in a template
 335     $c->forward( 'MyApp::View::TT' );
 336
 337 =cut
 338
 339 sub stash {
 340     my $c = shift;
 341     if (@_) {
 342         my $stash = @_ > 1 ? {@_} : $_[0];
 343         croak('stash takes a hash or hashref') unless ref $stash;
 344         foreach my $key ( keys %$stash ) {
 345             $c->{stash}->{$key} = $stash->{$key};
 346         }
 347     }
 348     return $c->{stash};
 349 }
 350
 351 =head2 $c->error
 352
 353 =head2 $c->error($error, ...)
 354
 355 =head2 $c->error($arrayref)
 356
 357 Returns an arrayref containing error messages.  If Catalyst encounters an
 358 error while processing a request, it stores the error in $c->error.  This
 359 method should not be used to store non-fatal error messages.
 360
 361     my @error = @{ $c->error };
 362
 363 Add a new error.
 364
 365     $c->error('Something bad happened');
 366
 367 =cut
 368
 369 sub error {
 370     my $c = shift;
 371     if ( $_[0] ) {
 372         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 373         croak @$error unless ref $c;
 374         push @{ $c->{error} }, @$error;
 375     }
 376     elsif ( defined $_[0] ) { $c->{error} = undef }
 377     return $c->{error} || [];
 378 }
 379
 380
 381 =head2 $c->state
 382
 383 Contains the return value of the last executed action.
 384
 385 =head2 $c->clear_errors
 386
 387 Clear errors.  You probably don't want to clear the errors unless you are
 388 implementing a custom error screen.
 389
 390 This is equivalent to running
 391
 392     $c->error(0);
 393
 394 =cut
 395
 396 sub clear_errors {
 397     my $c = shift;
 398     $c->error(0);
 399 }
 400
 401
 402 # search via regex
 403 sub _comp_search {
 404     my ( $c, @names ) = @_;
 405
 406     foreach my $name (@names) {
 407         foreach my $component ( keys %{ $c->components } ) {
 408             return $c->components->{$component} if $component =~ /$name/i;
 409         }
 410     }
 411
 412     return undef;
 413 }
 414
 415 # try explicit component names
 416 sub _comp_explicit {
 417     my ( $c, @names ) = @_;
 418
 419     foreach my $try (@names) {
 420         return $c->components->{$try} if ( exists $c->components->{$try} );
 421     }
 422
 423     return undef;
 424 }
 425
 426 # like component, but try just these prefixes before regex searching,
 427 #  and do not try to return "sort keys %{ $c->components }"
 428 sub _comp_prefixes {
 429     my ( $c, $name, @prefixes ) = @_;
 430
 431     my $appclass = ref $c || $c;
 432
 433     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 434
 435     my $comp = $c->_comp_explicit(@names);
 436     return $comp if defined($comp);
 437     $comp = $c->_comp_search($name);
 438     return $comp;
 439 }
 440
 441 # Find possible names for a prefix
 442
 443 sub _comp_names {
 444     my ( $c, @prefixes ) = @_;
 445
 446     my $appclass = ref $c || $c;
 447
 448     my @pre = map { "${appclass}::${_}::" } @prefixes;
 449
 450     my @names;
 451
 452     COMPONENT: foreach my $comp ($c->component) {
 453         foreach my $p (@pre) {
 454             if ($comp =~ s/^$p//) {
 455                 push(@names, $comp);
 456                 next COMPONENT;
 457             }
 458         }
 459     }
 460
 461     return @names;
 462 }
 463
 464 # Return a component if only one matches.
 465 sub _comp_singular {
 466     my ( $c, @prefixes ) = @_;
 467
 468     my $appclass = ref $c || $c;
 469
 470     my ( $comp, $rest ) =
 471       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 472     return $comp unless $rest;
 473 }
 474
 475 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 476 sub _filter_component {
 477     my ( $c, $comp, @args ) = @_;
 478     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 479         return $comp->ACCEPT_CONTEXT( $c, @args );
 480     }
 481     else { return $comp }
 482 }
 483
 484 =head2 COMPONENT ACCESSORS
 485
 486 =head2 $c->controller($name)
 487
 488 Gets a L<Catalyst::Controller> instance by name.
 489
 490     $c->controller('Foo')->do_stuff;
 491
 492 If the name is omitted, will return the controller for the dispatched
 493 action.
 494
 495 =cut
 496
 497 sub controller {
 498     my ( $c, $name, @args ) = @_;
 499     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 500         @args )
 501       if ($name);
 502     return $c->component( $c->action->class );
 503 }
 504
 505 =head2 $c->model($name)
 506
 507 Gets a L<Catalyst::Model> instance by name.
 508
 509     $c->model('Foo')->do_stuff;
 510
 511 If the name is omitted, it will look for
 512  - a model object in $c->stash{current_model_instance}, then
 513  - a model name in $c->stash->{current_model}, then
 514  - a config setting 'default_model', or
 515  - check if there is only one model, and return it if that's the case.
 516
 517 =cut
 518
 519 sub model {
 520     my ( $c, $name, @args ) = @_;
 521     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 522         @args )
 523       if $name;
 524     if (ref $c) {
 525         return $c->stash->{current_model_instance}
 526           if $c->stash->{current_model_instance};
 527         return $c->model( $c->stash->{current_model} )
 528           if $c->stash->{current_model};
 529         return $c->model( $c->config->{default_model} )
 530           if $c->config->{default_model};
 531     }
 532     return $c->_filter_component( $c->_comp_singular(qw/Model M/), @args );
 533
 534 }
 535
 536 =head2 $c->controllers
 537
 538 Returns the available names which can be passed to $c->controller
 539
 540 =cut
 541
 542 sub controllers {
 543     my ( $c ) = @_;
 544     return $c->_comp_names(qw/Controller C/);
 545 }
 546
 547
 548 =head2 $c->view($name)
 549
 550 Gets a L<Catalyst::View> instance by name.
 551
 552     $c->view('Foo')->do_stuff;
 553
 554 If the name is omitted, it will look for
 555  - a view object in $c->stash{current_view_instance}, then
 556  - a view name in $c->stash->{current_view}, then
 557  - a config setting 'default_view', or
 558  - check if there is only one view, and return it if that's the case.
 559
 560 =cut
 561
 562 sub view {
 563     my ( $c, $name, @args ) = @_;
 564     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 565         @args )
 566       if $name;
 567     if (ref $c) {
 568         return $c->stash->{current_view_instance}
 569           if $c->stash->{current_view_instance};
 570         return $c->view( $c->stash->{current_view} )
 571           if $c->stash->{current_view};
 572         return $c->view( $c->config->{default_view} )
 573           if $c->config->{default_view};
 574     }
 575     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 576 }
 577
 578 =head2 $c->models
 579
 580 Returns the available names which can be passed to $c->model
 581
 582 =cut
 583
 584 sub models {
 585     my ( $c ) = @_;
 586     return $c->_comp_names(qw/Model M/);
 587 }
 588
 589
 590 =head2 $c->views
 591
 592 Returns the available names which can be passed to $c->view
 593
 594 =cut
 595
 596 sub views {
 597     my ( $c ) = @_;
 598     return $c->_comp_names(qw/View V/);
 599 }
 600
 601 =head2 $c->comp($name)
 602
 603 =head2 $c->component($name)
 604
 605 Gets a component object by name. This method is not recommended,
 606 unless you want to get a specific component by full
 607 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 608 should be used instead.
 609
 610 =cut
 611
 612 sub component {
 613     my $c = shift;
 614
 615     if (@_) {
 616
 617         my $name = shift;
 618
 619         my $appclass = ref $c || $c;
 620
 621         my @names = (
 622             $name, "${appclass}::${name}",
 623             map { "${appclass}::${_}::${name}" }
 624               qw/Model M Controller C View V/
 625         );
 626
 627         my $comp = $c->_comp_explicit(@names);
 628         return $c->_filter_component( $comp, @_ ) if defined($comp);
 629
 630         $comp = $c->_comp_search($name);
 631         return $c->_filter_component( $comp, @_ ) if defined($comp);
 632     }
 633
 634     return sort keys %{ $c->components };
 635 }
 636
 637
 638
 639 =head2 CLASS DATA AND HELPER CLASSES
 640
 641 =head2 $c->config
 642
 643 Returns or takes a hashref containing the application's configuration.
 644
 645     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 646
 647 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 648 like myapp.yml in your applications home directory. See
 649 L<Catalyst::Plugin::ConfigLoader>.
 650
 651     ---
 652     db: dsn:SQLite:foo.db
 653
 654
 655 =cut
 656
 657 sub config {
 658     my $c = shift;
 659
 660     $c->log->warn("Setting config after setup has been run is not a good idea.")
 661       if ( @_ and $c->setup_finished );
 662
 663     $c->NEXT::config(@_);
 664 }
 665
 666 =head2 $c->log
 667
 668 Returns the logging object instance. Unless it is already set, Catalyst
 669 sets this up with a L<Catalyst::Log> object. To use your own log class,
 670 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 671 C<< __PACKAGE__->setup >>.
 672
 673  __PACKAGE__->log( MyLogger->new );
 674  __PACKAGE__->setup;
 675
 676 And later:
 677
 678     $c->log->info( 'Now logging with my own logger!' );
 679
 680 Your log class should implement the methods described in
 681 L<Catalyst::Log>.
 682
 683
 684 =head2 $c->debug
 685
 686 Overload to enable debug messages (same as -Debug option).
 687
 688 Note that this is a static method, not an accessor and should be overloaded
 689 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 690
 691 =cut
 692
 693 sub debug { 0 }
 694
 695 =head2 $c->dispatcher
 696
 697 Returns the dispatcher instance. Stringifies to class name. See
 698 L<Catalyst::Dispatcher>.
 699
 700 =head2 $c->engine
 701
 702 Returns the engine instance. Stringifies to the class name. See
 703 L<Catalyst::Engine>.
 704
 705
 706 =head2 UTILITY METHODS
 707
 708 =head2 $c->path_to(@path)
 709
 710 Merges C<@path> with C<< $c->config->{home} >> and returns a
 711 L<Path::Class::Dir> object.
 712
 713 For example:
 714
 715     $c->path_to( 'db', 'sqlite.db' );
 716
 717 =cut
 718
 719 sub path_to {
 720     my ( $c, @path ) = @_;
 721     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 722     if ( -d $path ) { return $path }
 723     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 724 }
 725
 726 =head2 $c->plugin( $name, $class, @args )
 727
 728 Helper method for plugins. It creates a classdata accessor/mutator and
 729 loads and instantiates the given class.
 730
 731     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 732
 733     $c->prototype->define_javascript_functions;
 734
 735 =cut
 736
 737 sub plugin {
 738     my ( $class, $name, $plugin, @args ) = @_;
 739     $class->_register_plugin( $plugin, 1 );
 740
 741     eval { $plugin->import };
 742     $class->mk_classdata($name);
 743     my $obj;
 744     eval { $obj = $plugin->new(@args) };
 745
 746     if ($@) {
 747         Catalyst::Exception->throw( message =>
 748               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 749     }
 750
 751     $class->$name($obj);
 752     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 753       if $class->debug;
 754 }
 755
 756 =head2 MyApp->setup
 757
 758 Initializes the dispatcher and engine, loads any plugins, and loads the
 759 model, view, and controller components. You may also specify an array
 760 of plugins to load here, if you choose to not load them in the C<use
 761 Catalyst> line.
 762
 763     MyApp->setup;
 764     MyApp->setup( qw/-Debug/ );
 765
 766 =cut
 767
 768 sub setup {
 769     my ( $class, @arguments ) = @_;
 770
 771     $class->log->warn("Running setup twice is not a good idea.")
 772       if ( $class->setup_finished );
 773
 774     unless ( $class->isa('Catalyst') ) {
 775
 776         Catalyst::Exception->throw(
 777             message => qq/'$class' does not inherit from Catalyst/ );
 778     }
 779
 780     if ( $class->arguments ) {
 781         @arguments = ( @arguments, @{ $class->arguments } );
 782     }
 783
 784     # Process options
 785     my $flags = {};
 786
 787     foreach (@arguments) {
 788
 789         if (/^-Debug$/) {
 790             $flags->{log} =
 791               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 792         }
 793         elsif (/^-(\w+)=?(.*)$/) {
 794             $flags->{ lc $1 } = $2;
 795         }
 796         else {
 797             push @{ $flags->{plugins} }, $_;
 798         }
 799     }
 800
 801     $class->setup_home( delete $flags->{home} );
 802
 803     $class->setup_log( delete $flags->{log} );
 804     $class->setup_plugins( delete $flags->{plugins} );
 805     $class->setup_dispatcher( delete $flags->{dispatcher} );
 806     $class->setup_engine( delete $flags->{engine} );
 807
 808     for my $flag ( sort keys %{$flags} ) {
 809
 810         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 811             &$code( $class, delete $flags->{$flag} );
 812         }
 813         else {
 814             $class->log->warn(qq/Unknown flag "$flag"/);
 815         }
 816     }
 817
 818     eval { require Catalyst::Devel; };
 819     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 820         $class->log->warn(<<"EOF");
 821 You are running an old script!
 822
 823   Please update by running (this will overwrite existing files):
 824     catalyst.pl -force -scripts $class
 825
 826   or (this will not overwrite existing files):
 827     catalyst.pl -scripts $class
 828
 829 EOF
 830     }
 831
 832     if ( $class->debug ) {
 833         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 834
 835         if (@plugins) {
 836             my $t = Text::SimpleTable->new(74);
 837             $t->row($_) for @plugins;
 838             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 839         }
 840
 841         my $dispatcher = $class->dispatcher;
 842         my $engine     = $class->engine;
 843         my $home       = $class->config->{home};
 844
 845         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 846         $class->log->debug(qq/Loaded engine "$engine"/);
 847
 848         $home
 849           ? ( -d $home )
 850           ? $class->log->debug(qq/Found home "$home"/)
 851           : $class->log->debug(qq/Home "$home" doesn't exist/)
 852           : $class->log->debug(q/Couldn't find home/);
 853     }
 854
 855     # Call plugins setup
 856     {
 857         no warnings qw/redefine/;
 858         local *setup = sub { };
 859         $class->setup;
 860     }
 861
 862     # Initialize our data structure
 863     $class->components( {} );
 864
 865     $class->setup_components;
 866
 867     if ( $class->debug ) {
 868         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 869         for my $comp ( sort keys %{ $class->components } ) {
 870             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 871             $t->row( $comp, $type );
 872         }
 873         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 874           if ( keys %{ $class->components } );
 875     }
 876
 877     # Add our self to components, since we are also a component
 878     $class->components->{$class} = $class;
 879
 880     $class->setup_actions;
 881
 882     if ( $class->debug ) {
 883         my $name = $class->config->{name} || 'Application';
 884         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 885     }
 886     $class->log->_flush() if $class->log->can('_flush');
 887
 888     $class->setup_finished(1);
 889 }
 890
 891 =head2 $c->uri_for( $path, @args?, \%query_values? )
 892
 893 Merges path with C<< $c->request->base >> for absolute URIs and with
 894 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 895 object. If any args are passed, they are added at the end of the path.
 896 If the last argument to C<uri_for> is a hash reference, it is assumed to
 897 contain GET parameter key/value pairs, which will be appended to the URI
 898 in standard fashion.
 899
 900 Instead of C<$path>, you can also optionally pass a C<$action> object
 901 which will be resolved to a path using
 902 C<< $c->dispatcher->uri_for_action >>; if the first element of
 903 C<@args> is an arrayref it is treated as a list of captures to be passed
 904 to C<uri_for_action>.
 905
 906 =cut
 907
 908 sub uri_for {
 909     my ( $c, $path, @args ) = @_;
 910     my $base     = $c->request->base->clone;
 911     my $basepath = $base->path;
 912     $basepath =~ s/\/$//;
 913     $basepath .= '/';
 914     my $namespace = $c->namespace || '';
 915
 916     if ( Scalar::Util::blessed($path) ) { # action object
 917         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 918                          ? shift(@args)
 919                          : [] );
 920         $path = $c->dispatcher->uri_for_action($path, $captures);
 921         return undef unless defined($path);
 922         $path = '/' if $path eq '';
 923     }
 924
 925     # massage namespace, empty if absolute path
 926     $namespace =~ s/^\/// if $namespace;
 927     $namespace .= '/' if $namespace;
 928     $path ||= '';
 929     $namespace = '' if $path =~ /^\//;
 930     $path =~ s/^\///;
 931     $path =~ s/\?/%3F/g;
 932
 933     my $params =
 934       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 935
 936     for my $value ( values %$params ) {
 937         next unless defined $value;
 938         for ( ref $value eq 'ARRAY' ? @$value : $value ) {
 939             $_ = "$_";
 940             utf8::encode( $_ );
 941         }
 942     };
 943
 944     # join args with '/', or a blank string
 945     my $args = ( scalar @args ? '/' . join( '/', map {s/\?/%3F/g; $_} @args ) : '' );
 946     $args =~ s/^\/// unless $path;
 947     my $res =
 948       URI->new_abs( URI->new_abs( "$path$args", "$basepath$namespace" ), $base )
 949       ->canonical;
 950     $res->query_form(%$params);
 951     $res;
 952 }
 953
 954 =head2 $c->welcome_message
 955
 956 Returns the Catalyst welcome HTML page.
 957
 958 =cut
 959
 960 sub welcome_message {
 961     my $c      = shift;
 962     my $name   = $c->config->{name};
 963     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
 964     my $prefix = Catalyst::Utils::appprefix( ref $c );
 965     $c->response->content_type('text/html; charset=utf-8');
 966     return <<"EOF";
 967 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
 968     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 969 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 970     <head>
 971         <meta http-equiv="Content-Language" content="en" />
 972         <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
 973         <title>$name on Catalyst $VERSION</title>
 974         <style type="text/css">
 975             body {
 976                 color: #000;
 977                 background-color: #eee;
 978             }
 979             div#content {
 980                 width: 640px;
 981                 margin-left: auto;
 982                 margin-right: auto;
 983                 margin-top: 10px;
 984                 margin-bottom: 10px;
 985                 text-align: left;
 986                 background-color: #ccc;
 987                 border: 1px solid #aaa;
 988             }
 989             p, h1, h2 {
 990                 margin-left: 20px;
 991                 margin-right: 20px;
 992                 font-family: verdana, tahoma, sans-serif;
 993             }
 994             a {
 995                 font-family: verdana, tahoma, sans-serif;
 996             }
 997             :link, :visited {
 998                     text-decoration: none;
 999                     color: #b00;
1000                     border-bottom: 1px dotted #bbb;
1001             }
1002             :link:hover, :visited:hover {
1003                     color: #555;
1004             }
1005             div#topbar {
1006                 margin: 0px;
1007             }
1008             pre {
1009                 margin: 10px;
1010                 padding: 8px;
1011             }
1012             div#answers {
1013                 padding: 8px;
1014                 margin: 10px;
1015                 background-color: #fff;
1016                 border: 1px solid #aaa;
1017             }
1018             h1 {
1019                 font-size: 0.9em;
1020                 font-weight: normal;
1021                 text-align: center;
1022             }
1023             h2 {
1024                 font-size: 1.0em;
1025             }
1026             p {
1027                 font-size: 0.9em;
1028             }
1029             p img {
1030                 float: right;
1031                 margin-left: 10px;
1032             }
1033             span#appname {
1034                 font-weight: bold;
1035                 font-size: 1.6em;
1036             }
1037         </style>
1038     </head>
1039     <body>
1040         <div id="content">
1041             <div id="topbar">
1042                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1043                     $VERSION</h1>
1044              </div>
1045              <div id="answers">
1046                  <p>
1047                  <img src="$logo" alt="Catalyst Logo" />
1048                  </p>
1049                  <p>Welcome to the  world of Catalyst.
1050                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1051                     framework will make web development something you had
1052                     never expected it to be: Fun, rewarding, and quick.</p>
1053                  <h2>What to do now?</h2>
1054                  <p>That really depends  on what <b>you</b> want to do.
1055                     We do, however, provide you with a few starting points.</p>
1056                  <p>If you want to jump right into web development with Catalyst
1057                     you might want want to start with a tutorial.</p>
1058 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1059 </pre>
1060 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1061 <pre>
1062 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1063 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1064 </code></pre>
1065                  <h2>What to do next?</h2>
1066                  <p>Next it's time to write an actual application. Use the
1067                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1068                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1069                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1070                     they can save you a lot of work.</p>
1071                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1072                     <p>Also, be sure to check out the vast and growing
1073                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1074                     you are likely to find what you need there.
1075                     </p>
1076
1077                  <h2>Need help?</h2>
1078                  <p>Catalyst has a very active community. Here are the main places to
1079                     get in touch with us.</p>
1080                  <ul>
1081                      <li>
1082                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1083                      </li>
1084                      <li>
1085                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1086                      </li>
1087                      <li>
1088                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1089                      </li>
1090                  </ul>
1091                  <h2>In conclusion</h2>
1092                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1093                     as we enjoyed making it. Please contact us if you have ideas
1094                     for improvement or other feedback.</p>
1095              </div>
1096          </div>
1097     </body>
1098 </html>
1099 EOF
1100 }
1101
1102 =head1 INTERNAL METHODS
1103
1104 These methods are not meant to be used by end users.
1105
1106 =head2 $c->components
1107
1108 Returns a hash of components.
1109
1110 =head2 $c->context_class
1111
1112 Returns or sets the context class.
1113
1114 =head2 $c->counter
1115
1116 Returns a hashref containing coderefs and execution counts (needed for
1117 deep recursion detection).
1118
1119 =head2 $c->depth
1120
1121 Returns the number of actions on the current internal execution stack.
1122
1123 =head2 $c->dispatch
1124
1125 Dispatches a request to actions.
1126
1127 =cut
1128
1129 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1130
1131 =head2 $c->dispatcher_class
1132
1133 Returns or sets the dispatcher class.
1134
1135 =head2 $c->dump_these
1136
1137 Returns a list of 2-element array references (name, structure) pairs
1138 that will be dumped on the error page in debug mode.
1139
1140 =cut
1141
1142 sub dump_these {
1143     my $c = shift;
1144     [ Request => $c->req ],
1145     [ Response => $c->res ],
1146     [ Stash => $c->stash ],
1147     [ Config => $c->config ];
1148 }
1149
1150 =head2 $c->engine_class
1151
1152 Returns or sets the engine class.
1153
1154 =head2 $c->execute( $class, $coderef )
1155
1156 Execute a coderef in given class and catch exceptions. Errors are available
1157 via $c->error.
1158
1159 =cut
1160
1161 sub execute {
1162     my ( $c, $class, $code ) = @_;
1163     $class = $c->component($class) || $class;
1164     $c->state(0);
1165
1166     if ( $c->depth >= $RECURSION ) {
1167         my $action = "$code";
1168         $action = "/$action" unless $action =~ /->/;
1169         my $error = qq/Deep recursion detected calling "$action"/;
1170         $c->log->error($error);
1171         $c->error($error);
1172         $c->state(0);
1173         return $c->state;
1174     }
1175
1176     my $stats_info = $c->_stats_start_execute( $code ) if $c->debug;
1177
1178     push( @{ $c->stack }, $code );
1179
1180     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1181
1182     $c->_stats_finish_execute( $stats_info ) if $c->debug and $stats_info;
1183
1184     my $last = pop( @{ $c->stack } );
1185
1186     if ( my $error = $@ ) {
1187         if ( !ref($error) and $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1188         else {
1189             unless ( ref $error ) {
1190                 no warnings 'uninitialized';
1191                 chomp $error;
1192                 my $class = $last->class;
1193                 my $name  = $last->name;
1194                 $error = qq/Caught exception in $class->$name "$error"/;
1195             }
1196             $c->error($error);
1197             $c->state(0);
1198         }
1199     }
1200     return $c->state;
1201 }
1202
1203 sub _stats_start_execute {
1204     my ( $c, $code ) = @_;
1205
1206     return if ( ( $code->name =~ /^_.*/ )
1207         && ( !$c->config->{show_internal_actions} ) );
1208
1209     $c->counter->{"$code"}++;
1210
1211     my $action = "$code";
1212     $action = "/$action" unless $action =~ /->/;
1213
1214     # determine if the call was the result of a forward
1215     # this is done by walking up the call stack and looking for a calling
1216     # sub of Catalyst::forward before the eval
1217     my $callsub = q{};
1218     for my $index ( 2 .. 11 ) {
1219         last
1220         if ( ( caller($index) )[0] eq 'Catalyst'
1221             && ( caller($index) )[3] eq '(eval)' );
1222
1223         if ( ( caller($index) )[3] =~ /forward$/ ) {
1224             $callsub = ( caller($index) )[3];
1225             $action  = "-> $action";
1226             last;
1227         }
1228     }
1229
1230     my $node = Tree::Simple->new(
1231         {
1232             action  => $action,
1233             elapsed => undef,     # to be filled in later
1234             comment => "",
1235         }
1236     );
1237     $node->setUID( "$code" . $c->counter->{"$code"} );
1238
1239     # is this a root-level call or a forwarded call?
1240     if ( $callsub =~ /forward$/ ) {
1241
1242         # forward, locate the caller
1243         if ( my $parent = $c->stack->[-1] ) {
1244             my $visitor = Tree::Simple::Visitor::FindByUID->new;
1245             $visitor->searchForUID(
1246                 "$parent" . $c->counter->{"$parent"} );
1247             $c->stats->accept($visitor);
1248             if ( my $result = $visitor->getResult ) {
1249                 $result->addChild($node);
1250             }
1251         }
1252         else {
1253
1254             # forward with no caller may come from a plugin
1255             $c->stats->addChild($node);
1256         }
1257     }
1258     else {
1259
1260         # root-level call
1261         $c->stats->addChild($node);
1262     }
1263
1264     return {
1265         start   => [gettimeofday],
1266         node    => $node,
1267     };
1268 }
1269
1270 sub _stats_finish_execute {
1271     my ( $c, $info ) = @_;
1272     my $elapsed = tv_interval $info->{start};
1273     my $value = $info->{node}->getNodeValue;
1274     $value->{elapsed} = sprintf( '%fs', $elapsed );
1275 }
1276
1277 =head2 $c->_localize_fields( sub { }, \%keys );
1278
1279 =cut
1280
1281 sub _localize_fields {
1282     my ( $c, $localized, $code ) = ( @_ );
1283
1284     my $request = delete $localized->{request} || {};
1285     my $response = delete $localized->{response} || {};
1286
1287     local @{ $c }{ keys %$localized } = values %$localized;
1288     local @{ $c->request }{ keys %$request } = values %$request;
1289     local @{ $c->response }{ keys %$response } = values %$response;
1290
1291     $code->();
1292 }
1293
1294 =head2 $c->finalize
1295
1296 Finalizes the request.
1297
1298 =cut
1299
1300 sub finalize {
1301     my $c = shift;
1302
1303     for my $error ( @{ $c->error } ) {
1304         $c->log->error($error);
1305     }
1306
1307     # Allow engine to handle finalize flow (for POE)
1308     if ( $c->engine->can('finalize') ) {
1309         $c->engine->finalize($c);
1310     }
1311     else {
1312
1313         $c->finalize_uploads;
1314
1315         # Error
1316         if ( $#{ $c->error } >= 0 ) {
1317             $c->finalize_error;
1318         }
1319
1320         $c->finalize_headers;
1321
1322         # HEAD request
1323         if ( $c->request->method eq 'HEAD' ) {
1324             $c->response->body('');
1325         }
1326
1327         $c->finalize_body;
1328     }
1329
1330     if ($c->debug) {
1331         my $elapsed = sprintf '%f', tv_interval($c->stats->getNodeValue);
1332         my $av = sprintf '%.3f', ( $elapsed == 0 ? '??' : ( 1 / $elapsed ) );
1333
1334         my $t = Text::SimpleTable->new( [ 62, 'Action' ], [ 9, 'Time' ] );
1335         $c->stats->traverse(
1336             sub {
1337                 my $action = shift;
1338                 my $stat   = $action->getNodeValue;
1339                 $t->row( ( q{ } x $action->getDepth ) . $stat->{action} . $stat->{comment},
1340                     $stat->{elapsed} || '??' );
1341             }
1342         );
1343
1344         $c->log->info(
1345             "Request took ${elapsed}s ($av/s)\n" . $t->draw . "\n" );
1346     }
1347
1348     return $c->response->status;
1349 }
1350
1351 =head2 $c->finalize_body
1352
1353 Finalizes body.
1354
1355 =cut
1356
1357 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1358
1359 =head2 $c->finalize_cookies
1360
1361 Finalizes cookies.
1362
1363 =cut
1364
1365 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1366
1367 =head2 $c->finalize_error
1368
1369 Finalizes error.
1370
1371 =cut
1372
1373 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1374
1375 =head2 $c->finalize_headers
1376
1377 Finalizes headers.
1378
1379 =cut
1380
1381 sub finalize_headers {
1382     my $c = shift;
1383
1384     # Check if we already finalized headers
1385     return if $c->response->{_finalized_headers};
1386
1387     # Handle redirects
1388     if ( my $location = $c->response->redirect ) {
1389         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1390         $c->response->header( Location => $location );
1391     }
1392
1393     # Content-Length
1394     if ( $c->response->body && !$c->response->content_length ) {
1395
1396         # get the length from a filehandle
1397         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1398         {
1399             if ( my $stat = stat $c->response->body ) {
1400                 $c->response->content_length( $stat->size );
1401             }
1402             else {
1403                 $c->log->warn('Serving filehandle without a content-length');
1404             }
1405         }
1406         else {
1407             $c->response->content_length( bytes::length( $c->response->body ) );
1408         }
1409     }
1410
1411     # Errors
1412     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1413         $c->response->headers->remove_header("Content-Length");
1414         $c->response->body('');
1415     }
1416
1417     $c->finalize_cookies;
1418
1419     $c->engine->finalize_headers( $c, @_ );
1420
1421     # Done
1422     $c->response->{_finalized_headers} = 1;
1423 }
1424
1425 =head2 $c->finalize_output
1426
1427 An alias for finalize_body.
1428
1429 =head2 $c->finalize_read
1430
1431 Finalizes the input after reading is complete.
1432
1433 =cut
1434
1435 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1436
1437 =head2 $c->finalize_uploads
1438
1439 Finalizes uploads. Cleans up any temporary files.
1440
1441 =cut
1442
1443 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1444
1445 =head2 $c->get_action( $action, $namespace )
1446
1447 Gets an action in a given namespace.
1448
1449 =cut
1450
1451 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1452
1453 =head2 $c->get_actions( $action, $namespace )
1454
1455 Gets all actions of a given name in a namespace and all parent
1456 namespaces.
1457
1458 =cut
1459
1460 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1461
1462 =head2 $c->handle_request( $class, @arguments )
1463
1464 Called to handle each HTTP request.
1465
1466 =cut
1467
1468 sub handle_request {
1469     my ( $class, @arguments ) = @_;
1470
1471     # Always expect worst case!
1472     my $status = -1;
1473     eval {
1474         if ($class->debug) {
1475             my $secs = time - $START || 1;
1476             my $av = sprintf '%.3f', $COUNT / $secs;
1477             my $time = localtime time;
1478             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1479         }
1480
1481         my $c = $class->prepare(@arguments);
1482         $c->dispatch;
1483         $status = $c->finalize;
1484     };
1485
1486     if ( my $error = $@ ) {
1487         chomp $error;
1488         $class->log->error(qq/Caught exception in engine "$error"/);
1489     }
1490
1491     $COUNT++;
1492     $class->log->_flush() if $class->log->can('_flush');
1493     return $status;
1494 }
1495
1496 =head2 $c->prepare( @arguments )
1497
1498 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1499 etc.).
1500
1501 =cut
1502
1503 sub prepare {
1504     my ( $class, @arguments ) = @_;
1505
1506     $class->context_class( ref $class || $class ) unless $class->context_class;
1507     my $c = $class->context_class->new(
1508         {
1509             counter => {},
1510             stack   => [],
1511             request => $class->request_class->new(
1512                 {
1513                     arguments        => [],
1514                     body_parameters  => {},
1515                     cookies          => {},
1516                     headers          => HTTP::Headers->new,
1517                     parameters       => {},
1518                     query_parameters => {},
1519                     secure           => 0,
1520                     captures         => [],
1521                     uploads          => {}
1522                 }
1523             ),
1524             response => $class->response_class->new(
1525                 {
1526                     body    => '',
1527                     cookies => {},
1528                     headers => HTTP::Headers->new(),
1529                     status  => 200
1530                 }
1531             ),
1532             stash => {},
1533             state => 0
1534         }
1535     );
1536
1537     if ( $c->debug ) {
1538         $c->stats(Tree::Simple->new([gettimeofday]));
1539         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1540     }
1541
1542     # For on-demand data
1543     $c->request->{_context}  = $c;
1544     $c->response->{_context} = $c;
1545     weaken( $c->request->{_context} );
1546     weaken( $c->response->{_context} );
1547
1548     # Allow engine to direct the prepare flow (for POE)
1549     if ( $c->engine->can('prepare') ) {
1550         $c->engine->prepare( $c, @arguments );
1551     }
1552     else {
1553         $c->prepare_request(@arguments);
1554         $c->prepare_connection;
1555         $c->prepare_query_parameters;
1556         $c->prepare_headers;
1557         $c->prepare_cookies;
1558         $c->prepare_path;
1559
1560         # On-demand parsing
1561         $c->prepare_body unless $c->config->{parse_on_demand};
1562     }
1563
1564     my $method  = $c->req->method  || '';
1565     my $path    = $c->req->path    || '/';
1566     my $address = $c->req->address || '';
1567
1568     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1569       if $c->debug;
1570
1571     $c->prepare_action;
1572
1573     return $c;
1574 }
1575
1576 =head2 $c->prepare_action
1577
1578 Prepares action. See L<Catalyst::Dispatcher>.
1579
1580 =cut
1581
1582 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1583
1584 =head2 $c->prepare_body
1585
1586 Prepares message body.
1587
1588 =cut
1589
1590 sub prepare_body {
1591     my $c = shift;
1592
1593     # Do we run for the first time?
1594     return if defined $c->request->{_body};
1595
1596     # Initialize on-demand data
1597     $c->engine->prepare_body( $c, @_ );
1598     $c->prepare_parameters;
1599     $c->prepare_uploads;
1600
1601     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1602         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1603         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1604             my $param = $c->req->body_parameters->{$key};
1605             my $value = defined($param) ? $param : '';
1606             $t->row( $key,
1607                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1608         }
1609         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1610     }
1611 }
1612
1613 =head2 $c->prepare_body_chunk( $chunk )
1614
1615 Prepares a chunk of data before sending it to L<HTTP::Body>.
1616
1617 See L<Catalyst::Engine>.
1618
1619 =cut
1620
1621 sub prepare_body_chunk {
1622     my $c = shift;
1623     $c->engine->prepare_body_chunk( $c, @_ );
1624 }
1625
1626 =head2 $c->prepare_body_parameters
1627
1628 Prepares body parameters.
1629
1630 =cut
1631
1632 sub prepare_body_parameters {
1633     my $c = shift;
1634     $c->engine->prepare_body_parameters( $c, @_ );
1635 }
1636
1637 =head2 $c->prepare_connection
1638
1639 Prepares connection.
1640
1641 =cut
1642
1643 sub prepare_connection {
1644     my $c = shift;
1645     $c->engine->prepare_connection( $c, @_ );
1646 }
1647
1648 =head2 $c->prepare_cookies
1649
1650 Prepares cookies.
1651
1652 =cut
1653
1654 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1655
1656 =head2 $c->prepare_headers
1657
1658 Prepares headers.
1659
1660 =cut
1661
1662 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1663
1664 =head2 $c->prepare_parameters
1665
1666 Prepares parameters.
1667
1668 =cut
1669
1670 sub prepare_parameters {
1671     my $c = shift;
1672     $c->prepare_body_parameters;
1673     $c->engine->prepare_parameters( $c, @_ );
1674 }
1675
1676 =head2 $c->prepare_path
1677
1678 Prepares path and base.
1679
1680 =cut
1681
1682 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1683
1684 =head2 $c->prepare_query_parameters
1685
1686 Prepares query parameters.
1687
1688 =cut
1689
1690 sub prepare_query_parameters {
1691     my $c = shift;
1692
1693     $c->engine->prepare_query_parameters( $c, @_ );
1694
1695     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1696         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1697         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1698             my $param = $c->req->query_parameters->{$key};
1699             my $value = defined($param) ? $param : '';
1700             $t->row( $key,
1701                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1702         }
1703         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1704     }
1705 }
1706
1707 =head2 $c->prepare_read
1708
1709 Prepares the input for reading.
1710
1711 =cut
1712
1713 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1714
1715 =head2 $c->prepare_request
1716
1717 Prepares the engine request.
1718
1719 =cut
1720
1721 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1722
1723 =head2 $c->prepare_uploads
1724
1725 Prepares uploads.
1726
1727 =cut
1728
1729 sub prepare_uploads {
1730     my $c = shift;
1731
1732     $c->engine->prepare_uploads( $c, @_ );
1733
1734     if ( $c->debug && keys %{ $c->request->uploads } ) {
1735         my $t = Text::SimpleTable->new(
1736             [ 12, 'Parameter' ],
1737             [ 26, 'Filename' ],
1738             [ 18, 'Type' ],
1739             [ 9,  'Size' ]
1740         );
1741         for my $key ( sort keys %{ $c->request->uploads } ) {
1742             my $upload = $c->request->uploads->{$key};
1743             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1744                 $t->row( $key, $u->filename, $u->type, $u->size );
1745             }
1746         }
1747         $c->log->debug( "File Uploads are:\n" . $t->draw );
1748     }
1749 }
1750
1751 =head2 $c->prepare_write
1752
1753 Prepares the output for writing.
1754
1755 =cut
1756
1757 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1758
1759 =head2 $c->request_class
1760
1761 Returns or sets the request class.
1762
1763 =head2 $c->response_class
1764
1765 Returns or sets the response class.
1766
1767 =head2 $c->read( [$maxlength] )
1768
1769 Reads a chunk of data from the request body. This method is designed to
1770 be used in a while loop, reading C<$maxlength> bytes on every call.
1771 C<$maxlength> defaults to the size of the request if not specified.
1772
1773 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1774 directly.
1775
1776 =cut
1777
1778 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1779
1780 =head2 $c->run
1781
1782 Starts the engine.
1783
1784 =cut
1785
1786 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1787
1788 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1789
1790 Sets an action in a given namespace.
1791
1792 =cut
1793
1794 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1795
1796 =head2 $c->setup_actions($component)
1797
1798 Sets up actions for a component.
1799
1800 =cut
1801
1802 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1803
1804 =head2 $c->setup_components
1805
1806 Sets up components. Specify a C<setup_components> config option to pass
1807 additional options directly to L<Module::Pluggable>. To add additional
1808 search paths, specify a key named C<search_extra> as an array
1809 reference. Items in the array beginning with C<::> will have the
1810 application class name prepended to them.
1811
1812 =cut
1813
1814 sub setup_components {
1815     my $class = shift;
1816
1817     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1818     my $config  = $class->config->{ setup_components };
1819     my $extra   = delete $config->{ search_extra } || [];
1820
1821     push @paths, @$extra;
1822
1823     my $locator = Module::Pluggable::Object->new(
1824         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1825         %$config
1826     );
1827
1828     for my $component ( sort { length $a <=> length $b } $locator->plugins ) {
1829         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1830
1831         my $module  = $class->setup_component( $component );
1832         my %modules = (
1833             $component => $module,
1834             map {
1835                 $_ => $class->setup_component( $_ )
1836             } Devel::InnerPackage::list_packages( $component )
1837         );
1838
1839         for my $key ( keys %modules ) {
1840             $class->components->{ $key } = $modules{ $key };
1841         }
1842     }
1843 }
1844
1845 =head2 $c->setup_component
1846
1847 =cut
1848
1849 sub setup_component {
1850     my( $class, $component ) = @_;
1851
1852     unless ( $component->can( 'COMPONENT' ) ) {
1853         return $component;
1854     }
1855
1856     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1857     my $config = $class->config->{ $suffix } || {};
1858
1859     my $instance = eval { $component->COMPONENT( $class, $config ); };
1860
1861     if ( my $error = $@ ) {
1862         chomp $error;
1863         Catalyst::Exception->throw(
1864             message => qq/Couldn't instantiate component "$component", "$error"/
1865         );
1866     }
1867
1868     Catalyst::Exception->throw(
1869         message =>
1870         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1871     ) unless eval { $instance->can( 'can' ) };
1872
1873     return $instance;
1874 }
1875
1876 =head2 $c->setup_dispatcher
1877
1878 Sets up dispatcher.
1879
1880 =cut
1881
1882 sub setup_dispatcher {
1883     my ( $class, $dispatcher ) = @_;
1884
1885     if ($dispatcher) {
1886         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1887     }
1888
1889     if ( $ENV{CATALYST_DISPATCHER} ) {
1890         $dispatcher = 'Catalyst::Dispatcher::' . $ENV{CATALYST_DISPATCHER};
1891     }
1892
1893     if ( $ENV{ uc($class) . '_DISPATCHER' } ) {
1894         $dispatcher =
1895           'Catalyst::Dispatcher::' . $ENV{ uc($class) . '_DISPATCHER' };
1896     }
1897
1898     unless ($dispatcher) {
1899         $dispatcher = $class->dispatcher_class;
1900     }
1901
1902     unless (Class::Inspector->loaded($dispatcher)) {
1903         require Class::Inspector->filename($dispatcher);
1904     }
1905
1906     # dispatcher instance
1907     $class->dispatcher( $dispatcher->new );
1908 }
1909
1910 =head2 $c->setup_engine
1911
1912 Sets up engine.
1913
1914 =cut
1915
1916 sub setup_engine {
1917     my ( $class, $engine ) = @_;
1918
1919     if ($engine) {
1920         $engine = 'Catalyst::Engine::' . $engine;
1921     }
1922
1923     if ( $ENV{CATALYST_ENGINE} ) {
1924         $engine = 'Catalyst::Engine::' . $ENV{CATALYST_ENGINE};
1925     }
1926
1927     if ( $ENV{ uc($class) . '_ENGINE' } ) {
1928         $engine = 'Catalyst::Engine::' . $ENV{ uc($class) . '_ENGINE' };
1929     }
1930
1931     if ( $ENV{MOD_PERL} ) {
1932
1933         # create the apache method
1934         {
1935             no strict 'refs';
1936             *{"$class\::apache"} = sub { shift->engine->apache };
1937         }
1938
1939         my ( $software, $version ) =
1940           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1941
1942         $version =~ s/_//g;
1943         $version =~ s/(\.[^.]+)\./$1/g;
1944
1945         if ( $software eq 'mod_perl' ) {
1946
1947             if ( !$engine ) {
1948
1949                 if ( $version >= 1.99922 ) {
1950                     $engine = 'Catalyst::Engine::Apache2::MP20';
1951                 }
1952
1953                 elsif ( $version >= 1.9901 ) {
1954                     $engine = 'Catalyst::Engine::Apache2::MP19';
1955                 }
1956
1957                 elsif ( $version >= 1.24 ) {
1958                     $engine = 'Catalyst::Engine::Apache::MP13';
1959                 }
1960
1961                 else {
1962                     Catalyst::Exception->throw( message =>
1963                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
1964                 }
1965
1966             }
1967
1968             # install the correct mod_perl handler
1969             if ( $version >= 1.9901 ) {
1970                 *handler = sub  : method {
1971                     shift->handle_request(@_);
1972                 };
1973             }
1974             else {
1975                 *handler = sub ($$) { shift->handle_request(@_) };
1976             }
1977
1978         }
1979
1980         elsif ( $software eq 'Zeus-Perl' ) {
1981             $engine = 'Catalyst::Engine::Zeus';
1982         }
1983
1984         else {
1985             Catalyst::Exception->throw(
1986                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
1987         }
1988     }
1989
1990     unless ($engine) {
1991         $engine = $class->engine_class;
1992     }
1993
1994     unless (Class::Inspector->loaded($engine)) {
1995         require Class::Inspector->filename($engine);
1996     }
1997
1998     # check for old engines that are no longer compatible
1999     my $old_engine;
2000     if ( $engine->isa('Catalyst::Engine::Apache')
2001         && !Catalyst::Engine::Apache->VERSION )
2002     {
2003         $old_engine = 1;
2004     }
2005
2006     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2007         && Catalyst::Engine::Server->VERSION le '0.02' )
2008     {
2009         $old_engine = 1;
2010     }
2011
2012     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2013         && $engine->VERSION eq '0.01' )
2014     {
2015         $old_engine = 1;
2016     }
2017
2018     elsif ($engine->isa('Catalyst::Engine::Zeus')
2019         && $engine->VERSION eq '0.01' )
2020     {
2021         $old_engine = 1;
2022     }
2023
2024     if ($old_engine) {
2025         Catalyst::Exception->throw( message =>
2026               qq/Engine "$engine" is not supported by this version of Catalyst/
2027         );
2028     }
2029
2030     # engine instance
2031     $class->engine( $engine->new );
2032 }
2033
2034 =head2 $c->setup_home
2035
2036 Sets up the home directory.
2037
2038 =cut
2039
2040 sub setup_home {
2041     my ( $class, $home ) = @_;
2042
2043     if ( $ENV{CATALYST_HOME} ) {
2044         $home = $ENV{CATALYST_HOME};
2045     }
2046
2047     if ( $ENV{ uc($class) . '_HOME' } ) {
2048         $class =~ s/::/_/g;
2049         $home = $ENV{ uc($class) . '_HOME' };
2050     }
2051
2052     unless ($home) {
2053         $home = Catalyst::Utils::home($class);
2054     }
2055
2056     if ($home) {
2057         $class->config->{home} ||= $home;
2058         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2059     }
2060 }
2061
2062 =head2 $c->setup_log
2063
2064 Sets up log.
2065
2066 =cut
2067
2068 sub setup_log {
2069     my ( $class, $debug ) = @_;
2070
2071     unless ( $class->log ) {
2072         $class->log( Catalyst::Log->new );
2073     }
2074
2075     my $app_flag = Catalyst::Utils::class2env($class) . '_DEBUG';
2076
2077     if (
2078           ( defined( $ENV{CATALYST_DEBUG} ) || defined( $ENV{$app_flag} ) )
2079         ? ( $ENV{CATALYST_DEBUG} || $ENV{$app_flag} )
2080         : $debug
2081       )
2082     {
2083         no strict 'refs';
2084         *{"$class\::debug"} = sub { 1 };
2085         $class->log->debug('Debug messages enabled');
2086     }
2087 }
2088
2089 =head2 $c->setup_plugins
2090
2091 Sets up plugins.
2092
2093 =cut
2094
2095 =head2 $c->registered_plugins
2096
2097 Returns a sorted list of the plugins which have either been stated in the
2098 import list or which have been added via C<< MyApp->plugin(@args); >>.
2099
2100 If passed a given plugin name, it will report a boolean value indicating
2101 whether or not that plugin is loaded.  A fully qualified name is required if
2102 the plugin name does not begin with C<Catalyst::Plugin::>.
2103
2104  if ($c->registered_plugins('Some::Plugin')) {
2105      ...
2106  }
2107
2108 =cut
2109
2110 {
2111
2112     sub registered_plugins {
2113         my $proto = shift;
2114         return sort keys %{ $proto->_plugins } unless @_;
2115         my $plugin = shift;
2116         return 1 if exists $proto->_plugins->{$plugin};
2117         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2118     }
2119
2120     sub _register_plugin {
2121         my ( $proto, $plugin, $instant ) = @_;
2122         my $class = ref $proto || $proto;
2123
2124         unless (Class::Inspector->loaded($plugin)) {
2125             require Class::Inspector->filename($plugin);
2126         }
2127
2128         $proto->_plugins->{$plugin} = 1;
2129         unless ($instant) {
2130             no strict 'refs';
2131             unshift @{"$class\::ISA"}, $plugin;
2132         }
2133         return $class;
2134     }
2135
2136     sub setup_plugins {
2137         my ( $class, $plugins ) = @_;
2138
2139         $class->_plugins( {} ) unless $class->_plugins;
2140         $plugins ||= [];
2141         for my $plugin ( reverse @$plugins ) {
2142
2143             unless ( $plugin =~ s/\A\+// ) {
2144                 $plugin = "Catalyst::Plugin::$plugin";
2145             }
2146
2147             $class->_register_plugin($plugin);
2148         }
2149     }
2150 }
2151
2152 =head2 $c->stack
2153
2154 Returns an arrayref of the internal execution stack (actions that are
2155 currently executing).
2156
2157 =head2 $c->write( $data )
2158
2159 Writes $data to the output stream. When using this method directly, you
2160 will need to manually set the C<Content-Length> header to the length of
2161 your output data, if known.
2162
2163 =cut
2164
2165 sub write {
2166     my $c = shift;
2167
2168     # Finalize headers if someone manually writes output
2169     $c->finalize_headers;
2170
2171     return $c->engine->write( $c, @_ );
2172 }
2173
2174 =head2 version
2175
2176 Returns the Catalyst version number. Mostly useful for "powered by"
2177 messages in template systems.
2178
2179 =cut
2180
2181 sub version { return $Catalyst::VERSION }
2182
2183 =head1 INTERNAL ACTIONS
2184
2185 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2186 C<_ACTION>, and C<_END>. These are by default not shown in the private
2187 action table, but you can make them visible with a config parameter.
2188
2189     MyApp->config->{show_internal_actions} = 1;
2190
2191 =head1 CASE SENSITIVITY
2192
2193 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2194 mapped to C</foo/bar>. You can activate case sensitivity with a config
2195 parameter.
2196
2197     MyApp->config->{case_sensitive} = 1;
2198
2199 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2200
2201 =head1 ON-DEMAND PARSER
2202
2203 The request body is usually parsed at the beginning of a request,
2204 but if you want to handle input yourself or speed things up a bit,
2205 you can enable on-demand parsing with a config parameter.
2206
2207     MyApp->config->{parse_on_demand} = 1;
2208
2209 =head1 PROXY SUPPORT
2210
2211 Many production servers operate using the common double-server approach,
2212 with a lightweight frontend web server passing requests to a larger
2213 backend server. An application running on the backend server must deal
2214 with two problems: the remote user always appears to be C<127.0.0.1> and
2215 the server's hostname will appear to be C<localhost> regardless of the
2216 virtual host that the user connected through.
2217
2218 Catalyst will automatically detect this situation when you are running
2219 the frontend and backend servers on the same machine. The following
2220 changes are made to the request.
2221
2222     $c->req->address is set to the user's real IP address, as read from
2223     the HTTP X-Forwarded-For header.
2224
2225     The host value for $c->req->base and $c->req->uri is set to the real
2226     host, as read from the HTTP X-Forwarded-Host header.
2227
2228 Obviously, your web server must support these headers for this to work.
2229
2230 In a more complex server farm environment where you may have your
2231 frontend proxy server(s) on different machines, you will need to set a
2232 configuration option to tell Catalyst to read the proxied data from the
2233 headers.
2234
2235     MyApp->config->{using_frontend_proxy} = 1;
2236
2237 If you do not wish to use the proxy support at all, you may set:
2238
2239     MyApp->config->{ignore_frontend_proxy} = 1;
2240
2241 =head1 THREAD SAFETY
2242
2243 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2244 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2245 believe the Catalyst core to be thread-safe.
2246
2247 If you plan to operate in a threaded environment, remember that all other
2248 modules you are using must also be thread-safe. Some modules, most notably
2249 L<DBD::SQLite>, are not thread-safe.
2250
2251 =head1 SUPPORT
2252
2253 IRC:
2254
2255     Join #catalyst on irc.perl.org.
2256
2257 Mailing Lists:
2258
2259     http://lists.rawmode.org/mailman/listinfo/catalyst
2260     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2261
2262 Web:
2263
2264     http://catalyst.perl.org
2265
2266 Wiki:
2267
2268     http://dev.catalyst.perl.org
2269
2270 =head1 SEE ALSO
2271
2272 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2273
2274 =head2 L<Catalyst::Manual> - The Catalyst Manual
2275
2276 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2277
2278 =head2 L<Catalyst::Engine> - Core engine
2279
2280 =head2 L<Catalyst::Log> - Log class.
2281
2282 =head2 L<Catalyst::Request> - Request object
2283
2284 =head2 L<Catalyst::Response> - Response object
2285
2286 =head2 L<Catalyst::Test> - The test suite.
2287
2288 =head1 CREDITS
2289
2290 Andy Grundman
2291
2292 Andy Wardley
2293
2294 Andreas Marienborg
2295
2296 Andrew Bramble
2297
2298 Andrew Ford
2299
2300 Andrew Ruthven
2301
2302 Arthur Bergman
2303
2304 Autrijus Tang
2305
2306 Brian Cassidy
2307
2308 Carl Franks
2309
2310 Christian Hansen
2311
2312 Christopher Hicks
2313
2314 Dan Sully
2315
2316 Danijel Milicevic
2317
2318 David Kamholz
2319
2320 David Naughton
2321
2322 Drew Taylor
2323
2324 Gary Ashton Jones
2325
2326 Geoff Richards
2327
2328 Jesse Sheidlower
2329
2330 Jesse Vincent
2331
2332 Jody Belka
2333
2334 Johan Lindstrom
2335
2336 Juan Camacho
2337
2338 Leon Brocard
2339
2340 Marcus Ramberg
2341
2342 Matt S Trout
2343
2344 Robert Sedlacek
2345
2346 Sam Vilain
2347
2348 Sascha Kiefer
2349
2350 Tatsuhiko Miyagawa
2351
2352 Ulf Edvinsson
2353
2354 Yuval Kogman
2355
2356 =head1 AUTHOR
2357
2358 Sebastian Riedel, C<sri@oook.de>
2359
2360 =head1 LICENSE
2361
2362 This library is free software, you can redistribute it and/or modify it under
2363 the same terms as Perl itself.
2364
2365 =cut
2366
2367 1;