lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Devel::InnerPackage ();
  18 use File::stat;
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use utf8;
  32 use Carp qw/croak carp shortmess/;
  33
  34 BEGIN { require 5.008004; }
  35
  36 has stack => (is => 'ro', default => sub { [] });
  37 has stash => (is => 'rw', default => sub { {} });
  38 has state => (is => 'rw', default => 0);
  39 has stats => (is => 'rw');
  40 has action => (is => 'rw');
  41 has counter => (is => 'rw', default => sub { {} });
  42 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  43 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  44 has namespace => (is => 'rw');
  45
  46 sub depth { scalar @{ shift->stack || [] }; }
  47 sub comp { shift->component(@_) }
  48
  49 sub req {
  50     my $self = shift; return $self->request(@_);
  51 }
  52 sub res {
  53     my $self = shift; return $self->response(@_);
  54 }
  55
  56 # For backwards compatibility
  57 sub finalize_output { shift->finalize_body(@_) };
  58
  59 # For statistics
  60 our $COUNT     = 1;
  61 our $START     = time;
  62 our $RECURSION = 1000;
  63 our $DETACH    = Catalyst::Exception::Detach->new;
  64 our $GO        = Catalyst::Exception::Go->new;
  65
  66 #I imagine that very few of these really need to be class variables. if any.
  67 #maybe we should just make them attributes with a default?
  68 __PACKAGE__->mk_classdata($_)
  69   for qw/components arguments dispatcher engine log dispatcher_class
  70   engine_class context_class request_class response_class stats_class
  71   setup_finished/;
  72
  73 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  74 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  75 __PACKAGE__->request_class('Catalyst::Request');
  76 __PACKAGE__->response_class('Catalyst::Response');
  77 __PACKAGE__->stats_class('Catalyst::Stats');
  78
  79 # Remember to update this in Catalyst::Runtime as well!
  80
  81 our $VERSION = '5.80014_02';
  82
  83 {
  84     my $dev_version = $VERSION =~ /_\d{2}$/;
  85     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  86 }
  87
  88 $VERSION = eval $VERSION;
  89
  90 sub import {
  91     my ( $class, @arguments ) = @_;
  92
  93     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  94     # callers @ISA.
  95     return unless $class eq 'Catalyst';
  96
  97     my $caller = caller();
  98     return if $caller eq 'main';
  99
 100     # Kill Adopt::NEXT warnings if we're a non-RC version
 101     unless (_IS_DEVELOPMENT_VERSION()) {
 102         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 103     }
 104
 105     my $meta = Moose::Meta::Class->initialize($caller);
 106     unless ( $caller->isa('Catalyst') ) {
 107         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 108         $meta->superclasses(@superclasses);
 109     }
 110     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 111     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 112
 113     unless( $meta->has_method('meta') ){
 114         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 115     }
 116
 117     $caller->arguments( [@arguments] );
 118     $caller->setup_home;
 119 }
 120
 121 sub _application { $_[0] }
 122
 123 =head1 NAME
 124
 125 Catalyst - The Elegant MVC Web Application Framework
 126
 127 =head1 SYNOPSIS
 128
 129 See the L<Catalyst::Manual> distribution for comprehensive
 130 documentation and tutorials.
 131
 132     # Install Catalyst::Devel for helpers and other development tools
 133     # use the helper to create a new application
 134     catalyst.pl MyApp
 135
 136     # add models, views, controllers
 137     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 138     script/myapp_create.pl view MyTemplate TT
 139     script/myapp_create.pl controller Search
 140
 141     # built in testserver -- use -r to restart automatically on changes
 142     # --help to see all available options
 143     script/myapp_server.pl
 144
 145     # command line testing interface
 146     script/myapp_test.pl /yada
 147
 148     ### in lib/MyApp.pm
 149     use Catalyst qw/-Debug/; # include plugins here as well
 150
 151     ### In lib/MyApp/Controller/Root.pm (autocreated)
 152     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 153         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 154         $c->stash->{template} = 'foo.tt'; # set the template
 155         # lookup something from db -- stash vars are passed to TT
 156         $c->stash->{data} =
 157           $c->model('Database::Foo')->search( { country => $args[0] } );
 158         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 159             $c->forward( 'bar' ); # process another action
 160             # do something else after forward returns
 161         }
 162     }
 163
 164     # The foo.tt TT template can use the stash data from the database
 165     [% WHILE (item = data.next) %]
 166         [% item.foo %]
 167     [% END %]
 168
 169     # called for /bar/of/soap, /bar/of/soap/10, etc.
 170     sub bar : Path('/bar/of/soap') { ... }
 171
 172     # called for all actions, from the top-most controller downwards
 173     sub auto : Private {
 174         my ( $self, $c ) = @_;
 175         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 176             $c->res->redirect( '/login' ); # require login
 177             return 0; # abort request and go immediately to end()
 178         }
 179         return 1; # success; carry on to next action
 180     }
 181
 182     # called after all actions are finished
 183     sub end : Private {
 184         my ( $self, $c ) = @_;
 185         if ( scalar @{ $c->error } ) { ... } # handle errors
 186         return if $c->res->body; # already have a response
 187         $c->forward( 'MyApp::View::TT' ); # render template
 188     }
 189
 190     ### in MyApp/Controller/Foo.pm
 191     # called for /foo/bar
 192     sub bar : Local { ... }
 193
 194     # called for /blargle
 195     sub blargle : Global { ... }
 196
 197     # an index action matches /foo, but not /foo/1, etc.
 198     sub index : Private { ... }
 199
 200     ### in MyApp/Controller/Foo/Bar.pm
 201     # called for /foo/bar/baz
 202     sub baz : Local { ... }
 203
 204     # first Root auto is called, then Foo auto, then this
 205     sub auto : Private { ... }
 206
 207     # powerful regular expression paths are also possible
 208     sub details : Regex('^product/(\w+)/details$') {
 209         my ( $self, $c ) = @_;
 210         # extract the (\w+) from the URI
 211         my $product = $c->req->captures->[0];
 212     }
 213
 214 See L<Catalyst::Manual::Intro> for additional information.
 215
 216 =head1 DESCRIPTION
 217
 218 Catalyst is a modern framework for making web applications without the
 219 pain usually associated with this process. This document is a reference
 220 to the main Catalyst application. If you are a new user, we suggest you
 221 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 222
 223 See L<Catalyst::Manual> for more documentation.
 224
 225 Catalyst plugins can be loaded by naming them as arguments to the "use
 226 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 227 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 228 C<My::Module>.
 229
 230     use Catalyst qw/My::Module/;
 231
 232 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 233 fully qualify the name by using a unary plus:
 234
 235     use Catalyst qw/
 236         My::Module
 237         +Fully::Qualified::Plugin::Name
 238     /;
 239
 240 Special flags like C<-Debug> and C<-Engine> can also be specified as
 241 arguments when Catalyst is loaded:
 242
 243     use Catalyst qw/-Debug My::Module/;
 244
 245 The position of plugins and flags in the chain is important, because
 246 they are loaded in the order in which they appear.
 247
 248 The following flags are supported:
 249
 250 =head2 -Debug
 251
 252 Enables debug output. You can also force this setting from the system
 253 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 254 settings override the application, with <MYAPP>_DEBUG having the highest
 255 priority.
 256
 257 =head2 -Engine
 258
 259 Forces Catalyst to use a specific engine. Omit the
 260 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 261
 262     use Catalyst qw/-Engine=CGI/;
 263
 264 =head2 -Home
 265
 266 Forces Catalyst to use a specific home directory, e.g.:
 267
 268     use Catalyst qw[-Home=/usr/mst];
 269
 270 This can also be done in the shell environment by setting either the
 271 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 272 is replaced with the uppercased name of your application, any "::" in
 273 the name will be replaced with underscores, e.g. MyApp::Web should use
 274 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 275
 276 =head2 -Log
 277
 278     use Catalyst '-Log=warn,fatal,error';
 279
 280 Specifies a comma-delimited list of log levels.
 281
 282 =head2 -Stats
 283
 284 Enables statistics collection and reporting. You can also force this setting
 285 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 286 environment settings override the application, with <MYAPP>_STATS having the
 287 highest priority.
 288
 289 e.g.
 290
 291    use Catalyst qw/-Stats=1/
 292
 293 =head1 METHODS
 294
 295 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 296
 297 =head2 $c->action
 298
 299 Returns a L<Catalyst::Action> object for the current action, which
 300 stringifies to the action name. See L<Catalyst::Action>.
 301
 302 =head2 $c->namespace
 303
 304 Returns the namespace of the current action, i.e., the URI prefix
 305 corresponding to the controller of the current action. For example:
 306
 307     # in Controller::Foo::Bar
 308     $c->namespace; # returns 'foo/bar';
 309
 310 =head2 $c->request
 311
 312 =head2 $c->req
 313
 314 Returns the current L<Catalyst::Request> object, giving access to
 315 information about the current client request (including parameters,
 316 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 317
 318 =head2 REQUEST FLOW HANDLING
 319
 320 =head2 $c->forward( $action [, \@arguments ] )
 321
 322 =head2 $c->forward( $class, $method, [, \@arguments ] )
 323
 324 Forwards processing to another action, by its private name. If you give a
 325 class name but no method, C<process()> is called. You may also optionally
 326 pass arguments in an arrayref. The action will receive the arguments in
 327 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 328 C<< $c->req->args >> will be restored to the previous values.
 329
 330 Any data C<return>ed from the action forwarded to, will be returned by the
 331 call to forward.
 332
 333     my $foodata = $c->forward('/foo');
 334     $c->forward('index');
 335     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 336     $c->forward('MyApp::View::TT');
 337
 338 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 339 an C<< eval { } >> around the call (actually
 340 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 341 all 'dies' within the called action. If you want C<die> to propagate you
 342 need to do something like:
 343
 344     $c->forward('foo');
 345     die $c->error if $c->error;
 346
 347 Or make sure to always return true values from your actions and write
 348 your code like this:
 349
 350     $c->forward('foo') || return;
 351
 352 Another note is that C<< $c->forward >> always returns a scalar because it
 353 actually returns $c->state which operates in a scalar context.
 354 Thus, something like:
 355
 356     return @array;
 357
 358 in an action that is forwarded to is going to return a scalar,
 359 i.e. how many items are in that array, which is probably not what you want.
 360 If you need to return an array then return a reference to it,
 361 or stash it like so:
 362
 363     $c->stash->{array} = \@array;
 364
 365 and access it from the stash.
 366
 367 =cut
 368
 369 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 370
 371 =head2 $c->detach( $action [, \@arguments ] )
 372
 373 =head2 $c->detach( $class, $method, [, \@arguments ] )
 374
 375 =head2 $c->detach()
 376
 377 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 378 doesn't return to the previous action when processing is finished.
 379
 380 When called with no arguments it escapes the processing chain entirely.
 381
 382 =cut
 383
 384 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 385
 386 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 387
 388 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 389
 390 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 391 but does a full dispatch, instead of just calling the new C<$action> /
 392 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 393 you go to are called, just like a new request.
 394
 395 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 396 This means, for example, that C<< $c->action >> methods such as
 397 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 398 L<reverse|Catalyst::Action/reverse> return information for the visited action
 399 when they are invoked within the visited action.  This is different from the
 400 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 401 continues to use the $c->action object from the caller action even when
 402 invoked from the callee.
 403
 404 C<< $c->stash >> is kept unchanged.
 405
 406 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 407 allows you to "wrap" another action, just as it would have been called by
 408 dispatching from a URL, while the analogous
 409 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 410 transfer control to another action as if it had been reached directly from a URL.
 411
 412 =cut
 413
 414 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 415
 416 =head2 $c->go( $action [, \@captures, \@arguments ] )
 417
 418 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 419
 420 The relationship between C<go> and
 421 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 422 the relationship between
 423 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 424 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 425 C<< $c->go >> will perform a full dispatch on the specified action or method,
 426 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 427 C<go> escapes the processing of the current request chain on completion, and
 428 does not return to its caller.
 429
 430 =cut
 431
 432 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 433
 434 =head2 $c->response
 435
 436 =head2 $c->res
 437
 438 Returns the current L<Catalyst::Response> object, see there for details.
 439
 440 =head2 $c->stash
 441
 442 Returns a hashref to the stash, which may be used to store data and pass
 443 it between components during a request. You can also set hash keys by
 444 passing arguments. The stash is automatically sent to the view. The
 445 stash is cleared at the end of a request; it cannot be used for
 446 persistent storage (for this you must use a session; see
 447 L<Catalyst::Plugin::Session> for a complete system integrated with
 448 Catalyst).
 449
 450     $c->stash->{foo} = $bar;
 451     $c->stash( { moose => 'majestic', qux => 0 } );
 452     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 453
 454     # stash is automatically passed to the view for use in a template
 455     $c->forward( 'MyApp::View::TT' );
 456
 457 =cut
 458
 459 around stash => sub {
 460     my $orig = shift;
 461     my $c = shift;
 462     my $stash = $orig->($c);
 463     if (@_) {
 464         my $new_stash = @_ > 1 ? {@_} : $_[0];
 465         croak('stash takes a hash or hashref') unless ref $new_stash;
 466         foreach my $key ( keys %$new_stash ) {
 467           $stash->{$key} = $new_stash->{$key};
 468         }
 469     }
 470
 471     return $stash;
 472 };
 473
 474
 475 =head2 $c->error
 476
 477 =head2 $c->error($error, ...)
 478
 479 =head2 $c->error($arrayref)
 480
 481 Returns an arrayref containing error messages.  If Catalyst encounters an
 482 error while processing a request, it stores the error in $c->error.  This
 483 method should only be used to store fatal error messages.
 484
 485     my @error = @{ $c->error };
 486
 487 Add a new error.
 488
 489     $c->error('Something bad happened');
 490
 491 =cut
 492
 493 sub error {
 494     my $c = shift;
 495     if ( $_[0] ) {
 496         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 497         croak @$error unless ref $c;
 498         push @{ $c->{error} }, @$error;
 499     }
 500     elsif ( defined $_[0] ) { $c->{error} = undef }
 501     return $c->{error} || [];
 502 }
 503
 504
 505 =head2 $c->state
 506
 507 Contains the return value of the last executed action.
 508 Note that << $c->state >> operates in a scalar context which means that all
 509 values it returns are scalar.
 510
 511 =head2 $c->clear_errors
 512
 513 Clear errors.  You probably don't want to clear the errors unless you are
 514 implementing a custom error screen.
 515
 516 This is equivalent to running
 517
 518     $c->error(0);
 519
 520 =cut
 521
 522 sub clear_errors {
 523     my $c = shift;
 524     $c->error(0);
 525 }
 526
 527 sub _comp_search_prefixes {
 528     my $c = shift;
 529     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 530 }
 531
 532 # search components given a name and some prefixes
 533 sub _comp_names_search_prefixes {
 534     my ( $c, $name, @prefixes ) = @_;
 535     my $appclass = ref $c || $c;
 536     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 537     $filter = qr/$filter/; # Compile regex now rather than once per loop
 538
 539     # map the original component name to the sub part that we will search against
 540     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 541         grep { /$filter/ } keys %{ $c->components };
 542
 543     # undef for a name will return all
 544     return keys %eligible if !defined $name;
 545
 546     my $query  = ref $name ? $name : qr/^$name$/i;
 547     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 548
 549     return @result if @result;
 550
 551     # if we were given a regexp to search against, we're done.
 552     return if ref $name;
 553
 554     # skip regexp fallback if configured
 555     return
 556         if $appclass->config->{disable_component_resolution_regex_fallback};
 557
 558     # regexp fallback
 559     $query  = qr/$name/i;
 560     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 561
 562     # no results? try against full names
 563     if( !@result ) {
 564         @result = grep { m{$query} } keys %eligible;
 565     }
 566
 567     # don't warn if we didn't find any results, it just might not exist
 568     if( @result ) {
 569         # Disgusting hack to work out correct method name
 570         my $warn_for = lc $prefixes[0];
 571         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 572            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 573            "component resolution is unreliable and unsafe.";
 574         my $short = $result[0];
 575         # remove the component namespace prefix
 576         $short =~ s/.*?(Model|Controller|View):://;
 577         my $shortmess = Carp::shortmess('');
 578         if ($shortmess =~ m#Catalyst/Plugin#) {
 579            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 580               "plugin's config";
 581         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 582            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 583               "component's config";
 584         } else {
 585            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 586               "but if you really wanted to search, pass in a regexp as the argument " .
 587               "like so: \$c->${warn_for}(qr/${name}/)";
 588         }
 589         $c->log->warn( "${msg}$shortmess" );
 590     }
 591
 592     return @result;
 593 }
 594
 595 # Find possible names for a prefix
 596 sub _comp_names {
 597     my ( $c, @prefixes ) = @_;
 598     my $appclass = ref $c || $c;
 599
 600     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 601
 602     my @names = map { s{$filter}{}; $_; }
 603         $c->_comp_names_search_prefixes( undef, @prefixes );
 604
 605     return @names;
 606 }
 607
 608 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 609 sub _filter_component {
 610     my ( $c, $comp, @args ) = @_;
 611
 612     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 613         return $comp->ACCEPT_CONTEXT( $c, @args );
 614     }
 615
 616     return $comp;
 617 }
 618
 619 =head2 COMPONENT ACCESSORS
 620
 621 =head2 $c->controller($name)
 622
 623 Gets a L<Catalyst::Controller> instance by name.
 624
 625     $c->controller('Foo')->do_stuff;
 626
 627 If the name is omitted, will return the controller for the dispatched
 628 action.
 629
 630 If you want to search for controllers, pass in a regexp as the argument.
 631
 632     # find all controllers that start with Foo
 633     my @foo_controllers = $c->controller(qr{^Foo});
 634
 635
 636 =cut
 637
 638 sub controller {
 639     my ( $c, $name, @args ) = @_;
 640
 641     if( $name ) {
 642         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 643         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 644         return $c->_filter_component( $result[ 0 ], @args );
 645     }
 646
 647     return $c->component( $c->action->class );
 648 }
 649
 650 =head2 $c->model($name)
 651
 652 Gets a L<Catalyst::Model> instance by name.
 653
 654     $c->model('Foo')->do_stuff;
 655
 656 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 657
 658 If the name is omitted, it will look for
 659  - a model object in $c->stash->{current_model_instance}, then
 660  - a model name in $c->stash->{current_model}, then
 661  - a config setting 'default_model', or
 662  - check if there is only one model, and return it if that's the case.
 663
 664 If you want to search for models, pass in a regexp as the argument.
 665
 666     # find all models that start with Foo
 667     my @foo_models = $c->model(qr{^Foo});
 668
 669 =cut
 670
 671 sub model {
 672     my ( $c, $name, @args ) = @_;
 673     my $appclass = ref($c) || $c;
 674     if( $name ) {
 675         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 676         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 677         return $c->_filter_component( $result[ 0 ], @args );
 678     }
 679
 680     if (ref $c) {
 681         return $c->stash->{current_model_instance}
 682           if $c->stash->{current_model_instance};
 683         return $c->model( $c->stash->{current_model} )
 684           if $c->stash->{current_model};
 685     }
 686     return $c->model( $appclass->config->{default_model} )
 687       if $appclass->config->{default_model};
 688
 689     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 690
 691     if( $rest ) {
 692         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 693         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 694         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 695         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 696         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 697     }
 698
 699     return $c->_filter_component( $comp );
 700 }
 701
 702
 703 =head2 $c->view($name)
 704
 705 Gets a L<Catalyst::View> instance by name.
 706
 707     $c->view('Foo')->do_stuff;
 708
 709 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 710
 711 If the name is omitted, it will look for
 712  - a view object in $c->stash->{current_view_instance}, then
 713  - a view name in $c->stash->{current_view}, then
 714  - a config setting 'default_view', or
 715  - check if there is only one view, and return it if that's the case.
 716
 717 If you want to search for views, pass in a regexp as the argument.
 718
 719     # find all views that start with Foo
 720     my @foo_views = $c->view(qr{^Foo});
 721
 722 =cut
 723
 724 sub view {
 725     my ( $c, $name, @args ) = @_;
 726
 727     my $appclass = ref($c) || $c;
 728     if( $name ) {
 729         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 730         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 731         return $c->_filter_component( $result[ 0 ], @args );
 732     }
 733
 734     if (ref $c) {
 735         return $c->stash->{current_view_instance}
 736           if $c->stash->{current_view_instance};
 737         return $c->view( $c->stash->{current_view} )
 738           if $c->stash->{current_view};
 739     }
 740     return $c->view( $appclass->config->{default_view} )
 741       if $appclass->config->{default_view};
 742
 743     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 744
 745     if( $rest ) {
 746         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 747         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 748         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 749         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 750         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 751     }
 752
 753     return $c->_filter_component( $comp );
 754 }
 755
 756 =head2 $c->controllers
 757
 758 Returns the available names which can be passed to $c->controller
 759
 760 =cut
 761
 762 sub controllers {
 763     my ( $c ) = @_;
 764     return $c->_comp_names(qw/Controller C/);
 765 }
 766
 767 =head2 $c->models
 768
 769 Returns the available names which can be passed to $c->model
 770
 771 =cut
 772
 773 sub models {
 774     my ( $c ) = @_;
 775     return $c->_comp_names(qw/Model M/);
 776 }
 777
 778
 779 =head2 $c->views
 780
 781 Returns the available names which can be passed to $c->view
 782
 783 =cut
 784
 785 sub views {
 786     my ( $c ) = @_;
 787     return $c->_comp_names(qw/View V/);
 788 }
 789
 790 =head2 $c->comp($name)
 791
 792 =head2 $c->component($name)
 793
 794 Gets a component object by name. This method is not recommended,
 795 unless you want to get a specific component by full
 796 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 797 should be used instead.
 798
 799 If C<$name> is a regexp, a list of components matched against the full
 800 component name will be returned.
 801
 802 If Catalyst can't find a component by name, it will fallback to regex
 803 matching by default. To disable this behaviour set
 804 disable_component_resolution_regex_fallback to a true value.
 805
 806     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 807
 808 =cut
 809
 810 sub component {
 811     my ( $c, $name, @args ) = @_;
 812
 813     if( $name ) {
 814         my $comps = $c->components;
 815
 816         if( !ref $name ) {
 817             # is it the exact name?
 818             return $c->_filter_component( $comps->{ $name }, @args )
 819                        if exists $comps->{ $name };
 820
 821             # perhaps we just omitted "MyApp"?
 822             my $composed = ( ref $c || $c ) . "::${name}";
 823             return $c->_filter_component( $comps->{ $composed }, @args )
 824                        if exists $comps->{ $composed };
 825
 826             # search all of the models, views and controllers
 827             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 828             return $c->_filter_component( $comp, @args ) if $comp;
 829         }
 830
 831         # This is here so $c->comp( '::M::' ) works
 832         my $query = ref $name ? $name : qr{$name}i;
 833
 834         my @result = grep { m{$query} } keys %{ $c->components };
 835         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 836
 837         if( $result[ 0 ] ) {
 838             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 839             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 840             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 841             return $c->_filter_component( $result[ 0 ], @args );
 842         }
 843
 844         # I would expect to return an empty list here, but that breaks back-compat
 845     }
 846
 847     # fallback
 848     return sort keys %{ $c->components };
 849 }
 850
 851 =head2 CLASS DATA AND HELPER CLASSES
 852
 853 =head2 $c->config
 854
 855 Returns or takes a hashref containing the application's configuration.
 856
 857     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 858
 859 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 860 like C<myapp.conf> in your applications home directory. See
 861 L<Catalyst::Plugin::ConfigLoader>.
 862
 863 =head3 Cascading configuration
 864
 865 The config method is present on all Catalyst components, and configuration
 866 will be merged when an application is started. Configuration loaded with
 867 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 868 followed by configuration in your top level C<MyApp> class. These two
 869 configurations are merged, and then configuration data whose hash key matches a
 870 component name is merged with configuration for that component.
 871
 872 The configuration for a component is then passed to the C<new> method when a
 873 component is constructed.
 874
 875 For example:
 876
 877     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 878     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 879
 880 will mean that C<MyApp::Model::Foo> receives the following data when
 881 constructed:
 882
 883     MyApp::Model::Foo->new({
 884         bar => 'baz',
 885         quux => 'frob',
 886         overrides => 'me',
 887     });
 888
 889 =cut
 890
 891 around config => sub {
 892     my $orig = shift;
 893     my $c = shift;
 894
 895     croak('Setting config after setup has been run is not allowed.')
 896         if ( @_ and $c->setup_finished );
 897
 898     $c->$orig(@_);
 899 };
 900
 901 =head2 $c->log
 902
 903 Returns the logging object instance. Unless it is already set, Catalyst
 904 sets this up with a L<Catalyst::Log> object. To use your own log class,
 905 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 906 C<< __PACKAGE__->setup >>.
 907
 908  __PACKAGE__->log( MyLogger->new );
 909  __PACKAGE__->setup;
 910
 911 And later:
 912
 913     $c->log->info( 'Now logging with my own logger!' );
 914
 915 Your log class should implement the methods described in
 916 L<Catalyst::Log>.
 917
 918
 919 =head2 $c->debug
 920
 921 Returns 1 if debug mode is enabled, 0 otherwise.
 922
 923 You can enable debug mode in several ways:
 924
 925 =over
 926
 927 =item By calling myapp_server.pl with the -d flag
 928
 929 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 930
 931 =item The -Debug option in your MyApp.pm
 932
 933 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 934
 935 =back
 936
 937 Calling C<< $c->debug(1) >> has no effect.
 938
 939 =cut
 940
 941 sub debug { 0 }
 942
 943 =head2 $c->dispatcher
 944
 945 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 946
 947 =head2 $c->engine
 948
 949 Returns the engine instance. See L<Catalyst::Engine>.
 950
 951
 952 =head2 UTILITY METHODS
 953
 954 =head2 $c->path_to(@path)
 955
 956 Merges C<@path> with C<< $c->config->{home} >> and returns a
 957 L<Path::Class::Dir> object. Note you can usually use this object as
 958 a filename, but sometimes you will have to explicitly stringify it
 959 yourself by calling the C<< ->stringify >> method.
 960
 961 For example:
 962
 963     $c->path_to( 'db', 'sqlite.db' );
 964
 965 =cut
 966
 967 sub path_to {
 968     my ( $c, @path ) = @_;
 969     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 970     if ( -d $path ) { return $path }
 971     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 972 }
 973
 974 =head2 $c->plugin( $name, $class, @args )
 975
 976 Helper method for plugins. It creates a class data accessor/mutator and
 977 loads and instantiates the given class.
 978
 979     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 980
 981     $c->prototype->define_javascript_functions;
 982
 983 B<Note:> This method of adding plugins is deprecated. The ability
 984 to add plugins like this B<will be removed> in a Catalyst 5.81.
 985 Please do not use this functionality in new code.
 986
 987 =cut
 988
 989 sub plugin {
 990     my ( $class, $name, $plugin, @args ) = @_;
 991
 992     # See block comment in t/unit_core_plugin.t
 993     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 994
 995     $class->_register_plugin( $plugin, 1 );
 996
 997     eval { $plugin->import };
 998     $class->mk_classdata($name);
 999     my $obj;
1000     eval { $obj = $plugin->new(@args) };
1001
1002     if ($@) {
1003         Catalyst::Exception->throw( message =>
1004               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1005     }
1006
1007     $class->$name($obj);
1008     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1009       if $class->debug;
1010 }
1011
1012 =head2 MyApp->setup
1013
1014 Initializes the dispatcher and engine, loads any plugins, and loads the
1015 model, view, and controller components. You may also specify an array
1016 of plugins to load here, if you choose to not load them in the C<use
1017 Catalyst> line.
1018
1019     MyApp->setup;
1020     MyApp->setup( qw/-Debug/ );
1021
1022 =cut
1023
1024 sub setup {
1025     my ( $class, @arguments ) = @_;
1026     croak('Running setup more than once')
1027         if ( $class->setup_finished );
1028
1029     unless ( $class->isa('Catalyst') ) {
1030
1031         Catalyst::Exception->throw(
1032             message => qq/'$class' does not inherit from Catalyst/ );
1033     }
1034
1035     if ( $class->arguments ) {
1036         @arguments = ( @arguments, @{ $class->arguments } );
1037     }
1038
1039     # Process options
1040     my $flags = {};
1041
1042     foreach (@arguments) {
1043
1044         if (/^-Debug$/) {
1045             $flags->{log} =
1046               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1047         }
1048         elsif (/^-(\w+)=?(.*)$/) {
1049             $flags->{ lc $1 } = $2;
1050         }
1051         else {
1052             push @{ $flags->{plugins} }, $_;
1053         }
1054     }
1055
1056     $class->setup_home( delete $flags->{home} );
1057
1058     $class->setup_log( delete $flags->{log} );
1059     $class->setup_plugins( delete $flags->{plugins} );
1060     $class->setup_dispatcher( delete $flags->{dispatcher} );
1061     $class->setup_engine( delete $flags->{engine} );
1062     $class->setup_stats( delete $flags->{stats} );
1063
1064     for my $flag ( sort keys %{$flags} ) {
1065
1066         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1067             &$code( $class, delete $flags->{$flag} );
1068         }
1069         else {
1070             $class->log->warn(qq/Unknown flag "$flag"/);
1071         }
1072     }
1073
1074     eval { require Catalyst::Devel; };
1075     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1076         $class->log->warn(<<"EOF");
1077 You are running an old script!
1078
1079   Please update by running (this will overwrite existing files):
1080     catalyst.pl -force -scripts $class
1081
1082   or (this will not overwrite existing files):
1083     catalyst.pl -scripts $class
1084
1085 EOF
1086     }
1087
1088     if ( $class->debug ) {
1089         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1090
1091         if (@plugins) {
1092             my $column_width = Catalyst::Utils::term_width() - 6;
1093             my $t = Text::SimpleTable->new($column_width);
1094             $t->row($_) for @plugins;
1095             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1096         }
1097
1098         my $dispatcher = $class->dispatcher;
1099         my $engine     = $class->engine;
1100         my $home       = $class->config->{home};
1101
1102         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1103         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1104
1105         $home
1106           ? ( -d $home )
1107           ? $class->log->debug(qq/Found home "$home"/)
1108           : $class->log->debug(qq/Home "$home" doesn't exist/)
1109           : $class->log->debug(q/Couldn't find home/);
1110     }
1111
1112     # Call plugins setup, this is stupid and evil.
1113     # Also screws C3 badly on 5.10, hack to avoid.
1114     {
1115         no warnings qw/redefine/;
1116         local *setup = sub { };
1117         $class->setup unless $Catalyst::__AM_RESTARTING;
1118     }
1119
1120     # Initialize our data structure
1121     $class->components( {} );
1122
1123     $class->setup_components;
1124
1125     if ( $class->debug ) {
1126         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1127         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1128         for my $comp ( sort keys %{ $class->components } ) {
1129             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1130             $t->row( $comp, $type );
1131         }
1132         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1133           if ( keys %{ $class->components } );
1134     }
1135
1136     # Add our self to components, since we are also a component
1137     if( $class->isa('Catalyst::Controller') ){
1138       $class->components->{$class} = $class;
1139     }
1140
1141     $class->setup_actions;
1142
1143     if ( $class->debug ) {
1144         my $name = $class->config->{name} || 'Application';
1145         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1146     }
1147
1148     # Make sure that the application class becomes immutable at this point,
1149     B::Hooks::EndOfScope::on_scope_end {
1150         return if $@;
1151         my $meta = Class::MOP::get_metaclass_by_name($class);
1152         if (
1153             $meta->is_immutable
1154             && ! { $meta->immutable_options }->{replace_constructor}
1155             && (
1156                    $class->isa('Class::Accessor::Fast')
1157                 || $class->isa('Class::Accessor')
1158             )
1159         ) {
1160             warn "You made your application class ($class) immutable, "
1161                 . "but did not inline the\nconstructor. "
1162                 . "This will break catalyst, as your app \@ISA "
1163                 . "Class::Accessor(::Fast)?\nPlease pass "
1164                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1165         }
1166         $meta->make_immutable(
1167             replace_constructor => 1,
1168         ) unless $meta->is_immutable;
1169     };
1170
1171     if ($class->config->{case_sensitive}) {
1172         $class->log->warn($class . "->config->{case_sensitive} is set.");
1173         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1174     }
1175
1176     $class->setup_finalize;
1177     # Should be the last thing we do so that user things hooking
1178     # setup_finalize can log..
1179     $class->log->_flush() if $class->log->can('_flush');
1180     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1181 }
1182
1183
1184 =head2 $app->setup_finalize
1185
1186 A hook to attach modifiers to.
1187 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1188 Also better than C< setup_finished(); >, as that is a getter method.
1189
1190     sub setup_finalize {
1191
1192         my $app = shift;
1193
1194         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1195
1196         $app->next::method(@_);
1197
1198
1199     }
1200
1201 =cut
1202
1203 sub setup_finalize {
1204     my ($class) = @_;
1205     $class->setup_finished(1);
1206 }
1207
1208 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1209
1210 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1211
1212 Constructs an absolute L<URI> object based on the application root, the
1213 provided path, and the additional arguments and query parameters provided.
1214 When used as a string, provides a textual URI.
1215
1216 If no arguments are provided, the URI for the current action is returned.
1217 To return the current action and also provide @args, use
1218 C<< $c->uri_for( $c->action, @args ) >>.
1219
1220 If the first argument is a string, it is taken as a public URI path relative
1221 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1222 relative to the application root (if it does). It is then merged with
1223 C<< $c->request->base >>; any C<@args> are appended as additional path
1224 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1225
1226 If the first argument is a L<Catalyst::Action> it represents an action which
1227 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1228 optional C<\@captures> argument (an arrayref) allows passing the captured
1229 variables that are needed to fill in the paths of Chained and Regex actions;
1230 once the path is resolved, C<uri_for> continues as though a path was
1231 provided, appending any arguments or parameters and creating an absolute
1232 URI.
1233
1234 The captures for the current request can be found in
1235 C<< $c->request->captures >>, and actions can be resolved using
1236 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1237 path, use C<< $c->uri_for_action >> instead.
1238
1239   # Equivalent to $c->req->uri
1240   $c->uri_for($c->action, $c->req->captures,
1241       @{ $c->req->args }, $c->req->params);
1242
1243   # For the Foo action in the Bar controller
1244   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1245
1246   # Path to a static resource
1247   $c->uri_for('/static/images/logo.png');
1248
1249 =cut
1250
1251 sub uri_for {
1252     my ( $c, $path, @args ) = @_;
1253
1254     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1255         $path = $path->path_prefix;
1256         $path =~ s{/+\z}{};
1257         $path .= '/';
1258     }
1259
1260     if ( blessed($path) ) { # action object
1261         my $captures = [ map { s|/|%2F|; $_; }
1262                         ( scalar @args && ref $args[0] eq 'ARRAY'
1263                          ? @{ shift(@args) }
1264                          : ()) ];
1265         my $action = $path;
1266         $path = $c->dispatcher->uri_for_action($action, $captures);
1267         if (not defined $path) {
1268             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1269                 if $c->debug;
1270             return undef;
1271         }
1272         $path = '/' if $path eq '';
1273     }
1274
1275     undef($path) if (defined $path && $path eq '');
1276
1277     my $params =
1278       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1279
1280     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1281     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1282     s|/|%2F| for @args;
1283
1284     unshift(@args, $path);
1285
1286     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1287         my $namespace = $c->namespace;
1288         if (defined $path) { # cheesy hack to handle path '../foo'
1289            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1290         }
1291         unshift(@args, $namespace || '');
1292     }
1293
1294     # join args with '/', or a blank string
1295     my $args = join('/', grep { defined($_) } @args);
1296     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1297     $args =~ s!^/+!!;
1298     my $base = $c->req->base;
1299     my $class = ref($base);
1300     $base =~ s{(?<!/)$}{/};
1301
1302     my $query = '';
1303
1304     if (my @keys = keys %$params) {
1305       # somewhat lifted from URI::_query's query_form
1306       $query = '?'.join('&', map {
1307           my $val = $params->{$_};
1308           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1309           s/ /+/g;
1310           my $key = $_;
1311           $val = '' unless defined $val;
1312           (map {
1313               my $param = "$_";
1314               utf8::encode( $param ) if utf8::is_utf8($param);
1315               # using the URI::Escape pattern here so utf8 chars survive
1316               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1317               $param =~ s/ /+/g;
1318               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1319       } @keys);
1320     }
1321
1322     my $res = bless(\"${base}${args}${query}", $class);
1323     $res;
1324 }
1325
1326 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1327
1328 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1329
1330 =over
1331
1332 =item $path
1333
1334 A private path to the Catalyst action you want to create a URI for.
1335
1336 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1337 >> and passing the resulting C<$action> and the remaining arguments to C<<
1338 $c->uri_for >>.
1339
1340 You can also pass in a Catalyst::Action object, in which case it is passed to
1341 C<< $c->uri_for >>.
1342
1343 =back
1344
1345 =cut
1346
1347 sub uri_for_action {
1348     my ( $c, $path, @args ) = @_;
1349     my $action = blessed($path)
1350       ? $path
1351       : $c->dispatcher->get_action_by_path($path);
1352     unless (defined $action) {
1353       croak "Can't find action for path '$path'";
1354     }
1355     return $c->uri_for( $action, @args );
1356 }
1357
1358 =head2 $c->welcome_message
1359
1360 Returns the Catalyst welcome HTML page.
1361
1362 =cut
1363
1364 sub welcome_message {
1365     my $c      = shift;
1366     my $name   = $c->config->{name};
1367     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1368     my $prefix = Catalyst::Utils::appprefix( ref $c );
1369     $c->response->content_type('text/html; charset=utf-8');
1370     return <<"EOF";
1371 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1372     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1373 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1374     <head>
1375     <meta http-equiv="Content-Language" content="en" />
1376     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1377         <title>$name on Catalyst $VERSION</title>
1378         <style type="text/css">
1379             body {
1380                 color: #000;
1381                 background-color: #eee;
1382             }
1383             div#content {
1384                 width: 640px;
1385                 margin-left: auto;
1386                 margin-right: auto;
1387                 margin-top: 10px;
1388                 margin-bottom: 10px;
1389                 text-align: left;
1390                 background-color: #ccc;
1391                 border: 1px solid #aaa;
1392             }
1393             p, h1, h2 {
1394                 margin-left: 20px;
1395                 margin-right: 20px;
1396                 font-family: verdana, tahoma, sans-serif;
1397             }
1398             a {
1399                 font-family: verdana, tahoma, sans-serif;
1400             }
1401             :link, :visited {
1402                     text-decoration: none;
1403                     color: #b00;
1404                     border-bottom: 1px dotted #bbb;
1405             }
1406             :link:hover, :visited:hover {
1407                     color: #555;
1408             }
1409             div#topbar {
1410                 margin: 0px;
1411             }
1412             pre {
1413                 margin: 10px;
1414                 padding: 8px;
1415             }
1416             div#answers {
1417                 padding: 8px;
1418                 margin: 10px;
1419                 background-color: #fff;
1420                 border: 1px solid #aaa;
1421             }
1422             h1 {
1423                 font-size: 0.9em;
1424                 font-weight: normal;
1425                 text-align: center;
1426             }
1427             h2 {
1428                 font-size: 1.0em;
1429             }
1430             p {
1431                 font-size: 0.9em;
1432             }
1433             p img {
1434                 float: right;
1435                 margin-left: 10px;
1436             }
1437             span#appname {
1438                 font-weight: bold;
1439                 font-size: 1.6em;
1440             }
1441         </style>
1442     </head>
1443     <body>
1444         <div id="content">
1445             <div id="topbar">
1446                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1447                     $VERSION</h1>
1448              </div>
1449              <div id="answers">
1450                  <p>
1451                  <img src="$logo" alt="Catalyst Logo" />
1452                  </p>
1453                  <p>Welcome to the  world of Catalyst.
1454                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1455                     framework will make web development something you had
1456                     never expected it to be: Fun, rewarding, and quick.</p>
1457                  <h2>What to do now?</h2>
1458                  <p>That really depends  on what <b>you</b> want to do.
1459                     We do, however, provide you with a few starting points.</p>
1460                  <p>If you want to jump right into web development with Catalyst
1461                     you might want to start with a tutorial.</p>
1462 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1463 </pre>
1464 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1465 <pre>
1466 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1467 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1468 </code></pre>
1469                  <h2>What to do next?</h2>
1470                  <p>Next it's time to write an actual application. Use the
1471                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1472                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1473                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1474                     they can save you a lot of work.</p>
1475                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1476                     <p>Also, be sure to check out the vast and growing
1477                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1478                     you are likely to find what you need there.
1479                     </p>
1480
1481                  <h2>Need help?</h2>
1482                  <p>Catalyst has a very active community. Here are the main places to
1483                     get in touch with us.</p>
1484                  <ul>
1485                      <li>
1486                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1487                      </li>
1488                      <li>
1489                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1490                      </li>
1491                      <li>
1492                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1493                      </li>
1494                  </ul>
1495                  <h2>In conclusion</h2>
1496                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1497                     as we enjoyed making it. Please contact us if you have ideas
1498                     for improvement or other feedback.</p>
1499              </div>
1500          </div>
1501     </body>
1502 </html>
1503 EOF
1504 }
1505
1506 =head1 INTERNAL METHODS
1507
1508 These methods are not meant to be used by end users.
1509
1510 =head2 $c->components
1511
1512 Returns a hash of components.
1513
1514 =head2 $c->context_class
1515
1516 Returns or sets the context class.
1517
1518 =head2 $c->counter
1519
1520 Returns a hashref containing coderefs and execution counts (needed for
1521 deep recursion detection).
1522
1523 =head2 $c->depth
1524
1525 Returns the number of actions on the current internal execution stack.
1526
1527 =head2 $c->dispatch
1528
1529 Dispatches a request to actions.
1530
1531 =cut
1532
1533 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1534
1535 =head2 $c->dispatcher_class
1536
1537 Returns or sets the dispatcher class.
1538
1539 =head2 $c->dump_these
1540
1541 Returns a list of 2-element array references (name, structure) pairs
1542 that will be dumped on the error page in debug mode.
1543
1544 =cut
1545
1546 sub dump_these {
1547     my $c = shift;
1548     [ Request => $c->req ],
1549     [ Response => $c->res ],
1550     [ Stash => $c->stash ],
1551     [ Config => $c->config ];
1552 }
1553
1554 =head2 $c->engine_class
1555
1556 Returns or sets the engine class.
1557
1558 =head2 $c->execute( $class, $coderef )
1559
1560 Execute a coderef in given class and catch exceptions. Errors are available
1561 via $c->error.
1562
1563 =cut
1564
1565 sub execute {
1566     my ( $c, $class, $code ) = @_;
1567     $class = $c->component($class) || $class;
1568     $c->state(0);
1569
1570     if ( $c->depth >= $RECURSION ) {
1571         my $action = $code->reverse();
1572         $action = "/$action" unless $action =~ /->/;
1573         my $error = qq/Deep recursion detected calling "${action}"/;
1574         $c->log->error($error);
1575         $c->error($error);
1576         $c->state(0);
1577         return $c->state;
1578     }
1579
1580     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1581
1582     push( @{ $c->stack }, $code );
1583
1584     no warnings 'recursion';
1585     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1586
1587     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1588
1589     my $last = pop( @{ $c->stack } );
1590
1591     if ( my $error = $@ ) {
1592         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1593             $error->rethrow if $c->depth > 1;
1594         }
1595         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1596             $error->rethrow if $c->depth > 0;
1597         }
1598         else {
1599             unless ( ref $error ) {
1600                 no warnings 'uninitialized';
1601                 chomp $error;
1602                 my $class = $last->class;
1603                 my $name  = $last->name;
1604                 $error = qq/Caught exception in $class->$name "$error"/;
1605             }
1606             $c->error($error);
1607             $c->state(0);
1608         }
1609     }
1610     return $c->state;
1611 }
1612
1613 sub _stats_start_execute {
1614     my ( $c, $code ) = @_;
1615     my $appclass = ref($c) || $c;
1616     return if ( ( $code->name =~ /^_.*/ )
1617         && ( !$appclass->config->{show_internal_actions} ) );
1618
1619     my $action_name = $code->reverse();
1620     $c->counter->{$action_name}++;
1621
1622     my $action = $action_name;
1623     $action = "/$action" unless $action =~ /->/;
1624
1625     # determine if the call was the result of a forward
1626     # this is done by walking up the call stack and looking for a calling
1627     # sub of Catalyst::forward before the eval
1628     my $callsub = q{};
1629     for my $index ( 2 .. 11 ) {
1630         last
1631         if ( ( caller($index) )[0] eq 'Catalyst'
1632             && ( caller($index) )[3] eq '(eval)' );
1633
1634         if ( ( caller($index) )[3] =~ /forward$/ ) {
1635             $callsub = ( caller($index) )[3];
1636             $action  = "-> $action";
1637             last;
1638         }
1639     }
1640
1641     my $uid = $action_name . $c->counter->{$action_name};
1642
1643     # is this a root-level call or a forwarded call?
1644     if ( $callsub =~ /forward$/ ) {
1645         my $parent = $c->stack->[-1];
1646
1647         # forward, locate the caller
1648         if ( exists $c->counter->{"$parent"} ) {
1649             $c->stats->profile(
1650                 begin  => $action,
1651                 parent => "$parent" . $c->counter->{"$parent"},
1652                 uid    => $uid,
1653             );
1654         }
1655         else {
1656
1657             # forward with no caller may come from a plugin
1658             $c->stats->profile(
1659                 begin => $action,
1660                 uid   => $uid,
1661             );
1662         }
1663     }
1664     else {
1665
1666         # root-level call
1667         $c->stats->profile(
1668             begin => $action,
1669             uid   => $uid,
1670         );
1671     }
1672     return $action;
1673
1674 }
1675
1676 sub _stats_finish_execute {
1677     my ( $c, $info ) = @_;
1678     $c->stats->profile( end => $info );
1679 }
1680
1681 =head2 $c->finalize
1682
1683 Finalizes the request.
1684
1685 =cut
1686
1687 sub finalize {
1688     my $c = shift;
1689
1690     for my $error ( @{ $c->error } ) {
1691         $c->log->error($error);
1692     }
1693
1694     # Allow engine to handle finalize flow (for POE)
1695     my $engine = $c->engine;
1696     if ( my $code = $engine->can('finalize') ) {
1697         $engine->$code($c);
1698     }
1699     else {
1700
1701         $c->finalize_uploads;
1702
1703         # Error
1704         if ( $#{ $c->error } >= 0 ) {
1705             $c->finalize_error;
1706         }
1707
1708         $c->finalize_headers;
1709
1710         # HEAD request
1711         if ( $c->request->method eq 'HEAD' ) {
1712             $c->response->body('');
1713         }
1714
1715         $c->finalize_body;
1716     }
1717
1718         $c->log_response;
1719
1720     if ($c->use_stats) {
1721         my $elapsed = sprintf '%f', $c->stats->elapsed;
1722         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1723         $c->log->info(
1724             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1725     }
1726
1727     return $c->response->status;
1728 }
1729
1730 =head2 $c->finalize_body
1731
1732 Finalizes body.
1733
1734 =cut
1735
1736 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1737
1738 =head2 $c->finalize_cookies
1739
1740 Finalizes cookies.
1741
1742 =cut
1743
1744 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1745
1746 =head2 $c->finalize_error
1747
1748 Finalizes error.
1749
1750 =cut
1751
1752 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1753
1754 =head2 $c->finalize_headers
1755
1756 Finalizes headers.
1757
1758 =cut
1759
1760 sub finalize_headers {
1761     my $c = shift;
1762
1763     my $response = $c->response; #accessor calls can add up?
1764
1765     # Check if we already finalized headers
1766     return if $response->finalized_headers;
1767
1768     # Handle redirects
1769     if ( my $location = $response->redirect ) {
1770         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1771         $response->header( Location => $location );
1772
1773         if ( !$response->has_body ) {
1774             # Add a default body if none is already present
1775             $response->body(
1776                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1777             );
1778         }
1779     }
1780
1781     # Content-Length
1782     if ( $response->body && !$response->content_length ) {
1783
1784         # get the length from a filehandle
1785         if ( blessed( $response->body ) && $response->body->can('read') )
1786         {
1787             my $stat = stat $response->body;
1788             if ( $stat && $stat->size > 0 ) {
1789                 $response->content_length( $stat->size );
1790             }
1791             else {
1792                 $c->log->warn('Serving filehandle without a content-length');
1793             }
1794         }
1795         else {
1796             # everything should be bytes at this point, but just in case
1797             $response->content_length( length( $response->body ) );
1798         }
1799     }
1800
1801     # Errors
1802     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1803         $response->headers->remove_header("Content-Length");
1804         $response->body('');
1805     }
1806
1807     $c->finalize_cookies;
1808
1809     $c->engine->finalize_headers( $c, @_ );
1810
1811     # Done
1812     $response->finalized_headers(1);
1813 }
1814
1815 =head2 $c->finalize_output
1816
1817 An alias for finalize_body.
1818
1819 =head2 $c->finalize_read
1820
1821 Finalizes the input after reading is complete.
1822
1823 =cut
1824
1825 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1826
1827 =head2 $c->finalize_uploads
1828
1829 Finalizes uploads. Cleans up any temporary files.
1830
1831 =cut
1832
1833 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1834
1835 =head2 $c->get_action( $action, $namespace )
1836
1837 Gets an action in a given namespace.
1838
1839 =cut
1840
1841 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1842
1843 =head2 $c->get_actions( $action, $namespace )
1844
1845 Gets all actions of a given name in a namespace and all parent
1846 namespaces.
1847
1848 =cut
1849
1850 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1851
1852 =head2 $c->handle_request( $class, @arguments )
1853
1854 Called to handle each HTTP request.
1855
1856 =cut
1857
1858 sub handle_request {
1859     my ( $class, @arguments ) = @_;
1860
1861     # Always expect worst case!
1862     my $status = -1;
1863     eval {
1864         if ($class->debug) {
1865             my $secs = time - $START || 1;
1866             my $av = sprintf '%.3f', $COUNT / $secs;
1867             my $time = localtime time;
1868             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1869         }
1870
1871         my $c = $class->prepare(@arguments);
1872         $c->dispatch;
1873         $status = $c->finalize;
1874     };
1875
1876     if ( my $error = $@ ) {
1877         chomp $error;
1878         $class->log->error(qq/Caught exception in engine "$error"/);
1879     }
1880
1881     $COUNT++;
1882
1883     if(my $coderef = $class->log->can('_flush')){
1884         $class->log->$coderef();
1885     }
1886     return $status;
1887 }
1888
1889 =head2 $c->prepare( @arguments )
1890
1891 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1892 etc.).
1893
1894 =cut
1895
1896 sub prepare {
1897     my ( $class, @arguments ) = @_;
1898
1899     # XXX
1900     # After the app/ctxt split, this should become an attribute based on something passed
1901     # into the application.
1902     $class->context_class( ref $class || $class ) unless $class->context_class;
1903
1904     my $c = $class->context_class->new({});
1905
1906     # For on-demand data
1907     $c->request->_context($c);
1908     $c->response->_context($c);
1909
1910     #surely this is not the most efficient way to do things...
1911     $c->stats($class->stats_class->new)->enable($c->use_stats);
1912     if ( $c->debug ) {
1913         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1914     }
1915
1916     #XXX reuse coderef from can
1917     # Allow engine to direct the prepare flow (for POE)
1918     if ( $c->engine->can('prepare') ) {
1919         $c->engine->prepare( $c, @arguments );
1920     }
1921     else {
1922         $c->prepare_request(@arguments);
1923         $c->prepare_connection;
1924         $c->prepare_query_parameters;
1925         $c->prepare_headers;
1926         $c->prepare_cookies;
1927         $c->prepare_path;
1928
1929         # Prepare the body for reading, either by prepare_body
1930         # or the user, if they are using $c->read
1931         $c->prepare_read;
1932
1933         # Parse the body unless the user wants it on-demand
1934         unless ( ref($c)->config->{parse_on_demand} ) {
1935             $c->prepare_body;
1936         }
1937     }
1938
1939     my $method  = $c->req->method  || '';
1940     my $path    = $c->req->path;
1941     $path       = '/' unless length $path;
1942     my $address = $c->req->address || '';
1943
1944     $c->log_request;
1945
1946     $c->prepare_action;
1947
1948     return $c;
1949 }
1950
1951 =head2 $c->prepare_action
1952
1953 Prepares action. See L<Catalyst::Dispatcher>.
1954
1955 =cut
1956
1957 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1958
1959 =head2 $c->prepare_body
1960
1961 Prepares message body.
1962
1963 =cut
1964
1965 sub prepare_body {
1966     my $c = shift;
1967
1968     return if $c->request->_has_body;
1969
1970     # Initialize on-demand data
1971     $c->engine->prepare_body( $c, @_ );
1972     $c->prepare_parameters;
1973     $c->prepare_uploads;
1974 }
1975
1976 =head2 $c->prepare_body_chunk( $chunk )
1977
1978 Prepares a chunk of data before sending it to L<HTTP::Body>.
1979
1980 See L<Catalyst::Engine>.
1981
1982 =cut
1983
1984 sub prepare_body_chunk {
1985     my $c = shift;
1986     $c->engine->prepare_body_chunk( $c, @_ );
1987 }
1988
1989 =head2 $c->prepare_body_parameters
1990
1991 Prepares body parameters.
1992
1993 =cut
1994
1995 sub prepare_body_parameters {
1996     my $c = shift;
1997     $c->engine->prepare_body_parameters( $c, @_ );
1998 }
1999
2000 =head2 $c->prepare_connection
2001
2002 Prepares connection.
2003
2004 =cut
2005
2006 sub prepare_connection {
2007     my $c = shift;
2008     $c->engine->prepare_connection( $c, @_ );
2009 }
2010
2011 =head2 $c->prepare_cookies
2012
2013 Prepares cookies.
2014
2015 =cut
2016
2017 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2018
2019 =head2 $c->prepare_headers
2020
2021 Prepares headers.
2022
2023 =cut
2024
2025 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2026
2027 =head2 $c->prepare_parameters
2028
2029 Prepares parameters.
2030
2031 =cut
2032
2033 sub prepare_parameters {
2034     my $c = shift;
2035     $c->prepare_body_parameters;
2036     $c->engine->prepare_parameters( $c, @_ );
2037 }
2038
2039 =head2 $c->prepare_path
2040
2041 Prepares path and base.
2042
2043 =cut
2044
2045 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2046
2047 =head2 $c->prepare_query_parameters
2048
2049 Prepares query parameters.
2050
2051 =cut
2052
2053 sub prepare_query_parameters {
2054     my $c = shift;
2055
2056     $c->engine->prepare_query_parameters( $c, @_ );
2057 }
2058
2059 =head2 $c->apply_parameter_debug_filters($params)
2060
2061 =cut
2062
2063 sub _apply_parameter_debug_filters {
2064     my $c      = shift;
2065     my $type   = shift;
2066     my $params = shift;
2067
2068     # take a copy since we don't want to modify the original
2069     my $filtered_params = {%$params};
2070
2071     my @filters;
2072
2073     my $filter_param_config = $c->config->{Debug}->{param_filters};
2074     if ( ref($filter_param_config) eq 'HASH' ) {
2075
2076         # filters broken out by parameter type (i.e. body, query, all)
2077         my $type_filters = $filter_param_config->{$type} || [];
2078         $type_filters = [$type_filters] if ref $type_filters ne 'ARRAY';
2079
2080         my $all_filters = $filter_param_config->{'all'} || [];
2081         $all_filters = [$all_filters] if ref $all_filters ne 'ARRAY';
2082
2083         @filters = $c->_normalize_debug_filters( [ @$type_filters, @$all_filters ] );
2084     } elsif ($filter_param_config) {
2085         @filters = $c->_normalize_debug_filters($filter_param_config);
2086     }
2087
2088     # allow callback to modify each parameter
2089     foreach my $k ( keys %$filtered_params ) {
2090
2091         # apply filters to each param
2092         foreach my $f (@filters) {
2093
2094             # take a copy of the key to avoid the callback inadvertantly
2095             # modifying things
2096             my $copy_key = $k;
2097
2098             my $returned = $f->( $copy_key => $filtered_params->{$k} );
2099
2100             if ( defined $returned ) {
2101
2102                 # if no value is returned, we assume the filter chose not to modify anything
2103                 # otherwise, the returned value is the logged value
2104                 $filtered_params->{$k} = $returned;
2105
2106                 last;    # skip the rest of the filters since this one matched
2107             }
2108         }
2109     }
2110     return $filtered_params;
2111 }
2112
2113 # turn debug filters into a list of CodeRef's
2114 sub _normalize_debug_filters {
2115     my $c = shift;
2116
2117     my @filters = ref( $_[0] ) eq 'ARRAY' ? @{ $_[0] } : grep { defined $_ } @_;
2118
2119     my @normalized = map { _make_filter_callback($_) } @filters;
2120
2121     return @normalized;
2122 }
2123
2124 sub _make_filter_callback {
2125     my $filter = shift;
2126
2127     my $filter_str = '[FILTERED]';
2128     if ( ref($filter) eq 'Regexp' ) {
2129         return sub { return $_[0] =~ $filter ? $filter_str  : undef };
2130     } elsif ( ref($filter) eq 'CODE' ) {
2131         return $filter;
2132     } else {
2133         return sub { return $_[0] eq $filter ? $filter_str : undef };
2134     }
2135 }
2136
2137 =head2 $c->log_request
2138
2139 Writes information about the request to the debug logs.  This includes:
2140
2141 =over 4
2142
2143 =item * Request method, path, and remote IP address
2144
2145 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2146
2147 =item * Request parameters (see L</log_request_parameters>)
2148
2149 =item * File uploads
2150
2151 =back
2152
2153 =cut
2154
2155 sub log_request {
2156     my $c = shift;
2157
2158     return unless $c->debug;
2159
2160     my ( $method, $path, $address ) = ( $c->req->method, $c->req->path, $c->req->address );
2161     $method ||= '';
2162     $path = '/' unless length $path;
2163     $address ||= '';
2164     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2165
2166     if ( my $keywords = $c->req->query_keywords ) {
2167         $c->log->debug("Query keywords are: $keywords");
2168     }
2169
2170     $c->log_request_parameters( query => $c->req->query_parameters, body => $c->req->body_parameters );
2171
2172     $c->log_request_uploads;
2173 }
2174
2175 =head2 $c->log_response
2176
2177 Writes information about the response to the debug logs.  This includes:
2178
2179 =over 4
2180
2181 =item * Response status code
2182
2183 =item * Response headers (see L</log_headers>)
2184
2185 =back
2186
2187 This logging is not enabled by default.  To enable it, you must set a flag in your Catalyst config:
2188
2189         __PACKAGE__->config( Debug => { log_response => 1 } );
2190
2191 =cut
2192
2193 sub log_response {
2194     my $c = shift;
2195
2196     return unless $c->debug && $c->config->{Debug}->{log_response};
2197
2198     $c->log->debug('Response Status: ' . $c->response->status);
2199     $c->log_headers('response', $c->response->headers);
2200 }
2201
2202 =head2 $c->log_request_parameters( query => {}, body => {} )
2203
2204 Logs request parameters to debug logs
2205
2206 If you have sensitive data that you do not want written to the Catalyst
2207 debug logs, you can set options in your config to filter those values out.
2208 There are a few different ways you can set these up depending on what
2209 exactly you need to filter.
2210
2211 =head3 Filtering parameters by name
2212
2213 The most basic means of filtering is to add an entry into your config
2214 as shown below.  You can have a simple scalar to just filter a
2215 single parameter or an ARRAY ref to filter out multiple params.
2216
2217     # filters a single param
2218     __PACKAGE__->config( Debug => { param_filters => 'param_name' } );
2219
2220     # filters multiple params
2221     __PACKAGE__->config( Debug => { param_filters => [qw(param1 param2)] } );
2222
2223 When the debug logs are generated for a given request, any parameters
2224 (query or body) that exactly match the specified value(s) will have
2225 their values replaced with '[FILTERED]'.  For instance:
2226
2227     [debug] Query Parameters are:
2228     .-------------------------------------+--------------------------------------.
2229     | Parameter                           | Value                                |
2230     +-------------------------------------+--------------------------------------+
2231     | password                            | [FILTERED]                           |
2232     .-------------------------------------+--------------------------------------.
2233
2234 =head3 Filtering parameters by regular expression
2235
2236 If you have a set of parameters you need to filter, you can specify a
2237 regular expression that will be used to match against parameter names.
2238
2239     # filters parameters starting with "private."
2240     __PACKAGE__->config( Debug => { param_filters => qr/^private\./ } );
2241
2242     # filters parameters named "param1" or starting with "private." or "secret."
2243     __PACKAGE__->config( Debug => { param_filters => [ 'param1', qr/^private\./, qr/^secret\./ ] } );
2244
2245 Notice on the second example, the arrayref contains a string as well
2246 as two regular expressions.  This should DWIM and filter parameters that
2247 match any of the filters specified.
2248
2249 =head3 Filtering parameters by callback
2250
2251 If you want even more flexible filtering, you can specify an anonymous
2252 subroutine.  The subroutine is given the parameter name and value and
2253 is expected to return the new value that will be shown in the debug log.
2254 An C<undef> return value indicates that no change should be made to
2255 the value.
2256
2257     # transform any "password" param to "********"
2258     __PACKAGE__->config(
2259         Debug => {
2260             param_filters => sub { my ( $k, $v ) = @_; return unless $k eq 'password'; return '*' x 8; }
2261         }
2262     );
2263
2264     # combine several param filtering methods
2265     __PACKAGE__->config(
2266         Debug => {
2267             param_filters => [
2268                 'simple_param_name',
2269                 qr/^private\./,
2270                 sub { my ( $k, $v ) = @_; return unless $k eq 'password'; return '*' x 8; },
2271             ]
2272         }
2273     );
2274
2275 An example of the debug log for a request with
2276 C<password=secret&some_other_param=some_other_value> would be:
2277
2278     [debug] Body Parameters are:
2279     .-------------------------------------+--------------------------------------.
2280     | Parameter                           | Value                                |
2281     +-------------------------------------+--------------------------------------+
2282     | some_other_param                    | some_other_value                     |
2283     | password                            | ********                             |
2284     .-------------------------------------+--------------------------------------.
2285
2286 =head3 Filtering by parameter location
2287
2288 If you have different filters that depend on whether a param was passed
2289 as a query or body param (or as either), you can specify a hashref with
2290 different sets of filters:
2291
2292     # filters all body parameters
2293     __PACKAGE__->config( Debug => { param_filters => { body => qr// } } );
2294
2295     # filters query parameters starting with 'private'.
2296     __PACKAGE__->config( Debug => { param_filters => { query => qr/^private\./ } } );
2297
2298     # filters all parameters (query or body) through the specified callback
2299     __PACKAGE__->config(
2300         Debug => {
2301             param_filters => {
2302                 all => sub { return unless $_[0] eq 'fizzbuzz'; return 'FIZZBUZZ FILTER' }
2303             }
2304         }
2305     );
2306
2307 Of course, you can use any of the above filtering methods with these
2308 "location-specific" filters:
2309
2310     # body parameter filters
2311     __PACKAGE__->config(
2312         Debug => {
2313             param_filters => {
2314                 body => [
2315                     'some_param',
2316                     qr/^private\./,
2317                     sub { return 'XXX' if shift eq 'other_param' }
2318                 ]
2319             }
2320         }
2321     );
2322
2323     # query parameter filters
2324     __PACKAGE__->config(
2325         Debug => {
2326             param_filters => {
2327                 body => [
2328                     'some_param',
2329                     qr/^private\./,
2330                     sub { return 'XXX' if shift eq 'other_param' }
2331                 ]
2332             }
2333         }
2334     );
2335
2336     # query parameter filters
2337     __PACKAGE__->config( Debug => { param_filters => { all => [qw(foo bar)] } } );
2338
2339 =cut
2340
2341 sub log_request_parameters {
2342     my $c          = shift;
2343     my %all_params = @_;
2344
2345     my $column_width = Catalyst::Utils::term_width() - 44;
2346     foreach my $type (qw(query body)) {
2347         my $filtered_params = $c->_apply_parameter_debug_filters( $type, $all_params{$type} || {} );
2348         next unless keys %$filtered_params;
2349         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2350         for my $key ( sort keys %$filtered_params ) {
2351             my $param = $filtered_params->{$key};
2352             my $value = defined($param) ? $param : '';
2353             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2354         }
2355         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2356     }
2357 }
2358
2359 =head2 $c->log_request_uploads
2360
2361 Logs file uploads included in the request to the debug logs.
2362 The parameter name, filename, file type, and file size are all included in
2363 the debug logs.
2364
2365 =cut
2366
2367 sub log_request_uploads {
2368     my $c = shift;
2369     my $uploads = $c->req->uploads;
2370     if ( keys %$uploads ) {
2371         my $t = Text::SimpleTable->new(
2372             [ 12, 'Parameter' ],
2373             [ 26, 'Filename' ],
2374             [ 18, 'Type' ],
2375             [ 9,  'Size' ]
2376         );
2377         for my $key ( sort keys %$uploads ) {
2378             my $upload = $uploads->{$key};
2379             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2380                 $t->row( $key, $u->filename, $u->type, $u->size );
2381             }
2382         }
2383         $c->log->debug( "File Uploads are:\n" . $t->draw );
2384     }
2385 }
2386
2387 =head2 $c->log_headers($type => $headers)
2388
2389 Writes HTTP::Headers to debug logs, applying filters as configured.
2390
2391 Similarly to how L</log_request_parameters> is configured, you can
2392 configure Catalyst to filter response header values to avoid writing
2393 sensitive data to your logs (e.g. cookie values, etc.). The configuration
2394 works in virtually the same way as the examples in
2395 L</log_request_parameters>.  Here are a few specific examples:
2396
2397     # filters all "Set-Cookie" headers from response logging
2398     __PACKAGE__->config(Debug => { response_header_filters => 'Set-Cookie' } );
2399
2400     # filters only the value of the cookie (and leaves the name, path, expiration)
2401     __PACKAGE__->config(
2402         Debug => {
2403             response_header_filters => sub {
2404                 my ( $n, $v ) = @_;
2405                 return unless $n eq 'Set-Cookie';
2406                 $v =~ s/^.*?;//;
2407                 return $v;
2408             },
2409         }
2410     );
2411
2412 =cut
2413
2414 sub log_headers {
2415     my $c       = shift;
2416     my $type    = shift;
2417     my $headers = shift;    # an HTTP::Headers instance
2418
2419     my $filtered = $c->_apply_header_debug_filters( $type, $headers );
2420
2421     my $t = Text::SimpleTable->new( [ 35, 'Header Name' ], [ 40, 'Value' ] );
2422     $filtered->scan(
2423         sub {
2424             my ( $name, $value ) = @_;
2425             $t->row( $name, $value );
2426         }
2427     );
2428     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2429 }
2430
2431 # Applies debug filters to $headers and returns a new HTTP::Headers object which has (potentially) filtered values.
2432 sub _apply_header_debug_filters {
2433     my $c    = shift;
2434     my $type    = shift;
2435     my $headers = shift;
2436
2437     my @header_filters   = $c->_normalize_debug_filters( $c->config->{Debug}->{ $type . '_header_filters' } );
2438     my $filtered_headers = HTTP::Headers->new();
2439     foreach my $name ( $headers->header_field_names ) {
2440         my @values = $headers->header($name);
2441
2442         # headers can be multi-valued
2443         foreach my $value (@values) {
2444             foreach my $f (@header_filters) {
2445                 my $new_value = $f->( $name, $value );
2446
2447                 # if a defined value is returned, we use that
2448                 if ( defined $new_value ) {
2449                     $value = $new_value;
2450                     last;    # skip the rest of the filters
2451                 }
2452             }
2453             $filtered_headers->push_header( $name, $value );
2454         }
2455     }
2456     return $filtered_headers;
2457 }
2458
2459 =head2 $c->prepare_read
2460
2461 Prepares the input for reading.
2462
2463 =cut
2464
2465 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2466
2467 =head2 $c->prepare_request
2468
2469 Prepares the engine request.
2470
2471 =cut
2472
2473 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2474
2475 =head2 $c->prepare_uploads
2476
2477 Prepares uploads.
2478
2479 =cut
2480
2481 sub prepare_uploads {
2482     my $c = shift;
2483
2484     $c->engine->prepare_uploads( $c, @_ );
2485 }
2486
2487 =head2 $c->prepare_write
2488
2489 Prepares the output for writing.
2490
2491 =cut
2492
2493 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2494
2495 =head2 $c->request_class
2496
2497 Returns or sets the request class.
2498
2499 =head2 $c->response_class
2500
2501 Returns or sets the response class.
2502
2503 =head2 $c->read( [$maxlength] )
2504
2505 Reads a chunk of data from the request body. This method is designed to
2506 be used in a while loop, reading C<$maxlength> bytes on every call.
2507 C<$maxlength> defaults to the size of the request if not specified.
2508
2509 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2510 directly.
2511
2512 Warning: If you use read(), Catalyst will not process the body,
2513 so you will not be able to access POST parameters or file uploads via
2514 $c->request.  You must handle all body parsing yourself.
2515
2516 =cut
2517
2518 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2519
2520 =head2 $c->run
2521
2522 Starts the engine.
2523
2524 =cut
2525
2526 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2527
2528 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2529
2530 Sets an action in a given namespace.
2531
2532 =cut
2533
2534 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2535
2536 =head2 $c->setup_actions($component)
2537
2538 Sets up actions for a component.
2539
2540 =cut
2541
2542 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2543
2544 =head2 $c->setup_components
2545
2546 This method is called internally to set up the application's components.
2547
2548 It finds modules by calling the L<locate_components> method, expands them to
2549 package names with the L<expand_component_module> method, and then installs
2550 each component into the application.
2551
2552 The C<setup_components> config option is passed to both of the above methods.
2553
2554 Installation of each component is performed by the L<setup_component> method,
2555 below.
2556
2557 =cut
2558
2559 sub setup_components {
2560     my $class = shift;
2561
2562     my $config  = $class->config->{ setup_components };
2563
2564     my @comps = sort { length $a <=> length $b }
2565                 $class->locate_components($config);
2566     my %comps = map { $_ => 1 } @comps;
2567
2568     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2569     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2570         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2571     ) if $deprecatedcatalyst_component_names;
2572
2573     for my $component ( @comps ) {
2574
2575         # We pass ignore_loaded here so that overlay files for (e.g.)
2576         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2577         # we know M::P::O found a file on disk so this is safe
2578
2579         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2580
2581         # Needs to be done as soon as the component is loaded, as loading a sub-component
2582         # (next time round the loop) can cause us to get the wrong metaclass..
2583         $class->_controller_init_base_classes($component);
2584     }
2585
2586     for my $component (@comps) {
2587         $class->components->{ $component } = $class->setup_component($component);
2588         for my $component ($class->expand_component_module( $component, $config )) {
2589             next if $comps{$component};
2590             $class->_controller_init_base_classes($component); # Also cover inner packages
2591             $class->components->{ $component } = $class->setup_component($component);
2592         }
2593     }
2594 }
2595
2596 =head2 $c->locate_components( $setup_component_config )
2597
2598 This method is meant to provide a list of component modules that should be
2599 setup for the application.  By default, it will use L<Module::Pluggable>.
2600
2601 Specify a C<setup_components> config option to pass additional options directly
2602 to L<Module::Pluggable>. To add additional search paths, specify a key named
2603 C<search_extra> as an array reference. Items in the array beginning with C<::>
2604 will have the application class name prepended to them.
2605
2606 =cut
2607
2608 sub locate_components {
2609     my $class  = shift;
2610     my $config = shift;
2611
2612     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2613     my $extra   = delete $config->{ search_extra } || [];
2614
2615     push @paths, @$extra;
2616
2617     my $locator = Module::Pluggable::Object->new(
2618         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2619         %$config
2620     );
2621
2622     my @comps = $locator->plugins;
2623
2624     return @comps;
2625 }
2626
2627 =head2 $c->expand_component_module( $component, $setup_component_config )
2628
2629 Components found by C<locate_components> will be passed to this method, which
2630 is expected to return a list of component (package) names to be set up.
2631
2632 =cut
2633
2634 sub expand_component_module {
2635     my ($class, $module) = @_;
2636     return Devel::InnerPackage::list_packages( $module );
2637 }
2638
2639 =head2 $c->setup_component
2640
2641 =cut
2642
2643 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2644 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2645 #         to be loaded. There are TODO tests in Moose for this, see
2646 #         f2391d17574eff81d911b97be15ea51080500003
2647 sub _controller_init_base_classes {
2648     my ($app_class, $component) = @_;
2649     return unless $component->isa('Catalyst::Controller');
2650     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2651         Moose::Meta::Class->initialize( $class )
2652             unless find_meta($class);
2653     }
2654 }
2655
2656 sub setup_component {
2657     my( $class, $component ) = @_;
2658
2659     unless ( $component->can( 'COMPONENT' ) ) {
2660         return $component;
2661     }
2662
2663     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2664     my $config = $class->config->{ $suffix } || {};
2665     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2666     # methods also pass it. local to avoid pointlessly shitting in config
2667     # for the debug screen, as $component is already the key name.
2668     local $config->{catalyst_component_name} = $component;
2669
2670     my $instance = eval { $component->COMPONENT( $class, $config ); };
2671
2672     if ( my $error = $@ ) {
2673         chomp $error;
2674         Catalyst::Exception->throw(
2675             message => qq/Couldn't instantiate component "$component", "$error"/
2676         );
2677     }
2678
2679     unless (blessed $instance) {
2680         my $metaclass = Moose::Util::find_meta($component);
2681         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2682         my $component_method_from = $method_meta->associated_metaclass->name;
2683         my $value = defined($instance) ? $instance : 'undef';
2684         Catalyst::Exception->throw(
2685             message =>
2686             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2687         );
2688     }
2689     return $instance;
2690 }
2691
2692 =head2 $c->setup_dispatcher
2693
2694 Sets up dispatcher.
2695
2696 =cut
2697
2698 sub setup_dispatcher {
2699     my ( $class, $dispatcher ) = @_;
2700
2701     if ($dispatcher) {
2702         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2703     }
2704
2705     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2706         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2707     }
2708
2709     unless ($dispatcher) {
2710         $dispatcher = $class->dispatcher_class;
2711     }
2712
2713     Class::MOP::load_class($dispatcher);
2714
2715     # dispatcher instance
2716     $class->dispatcher( $dispatcher->new );
2717 }
2718
2719 =head2 $c->setup_engine
2720
2721 Sets up engine.
2722
2723 =cut
2724
2725 sub setup_engine {
2726     my ( $class, $engine ) = @_;
2727
2728     if ($engine) {
2729         $engine = 'Catalyst::Engine::' . $engine;
2730     }
2731
2732     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2733         $engine = 'Catalyst::Engine::' . $env;
2734     }
2735
2736     if ( $ENV{MOD_PERL} ) {
2737         my $meta = Class::MOP::get_metaclass_by_name($class);
2738
2739         # create the apache method
2740         $meta->add_method('apache' => sub { shift->engine->apache });
2741
2742         my ( $software, $version ) =
2743           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2744
2745         $version =~ s/_//g;
2746         $version =~ s/(\.[^.]+)\./$1/g;
2747
2748         if ( $software eq 'mod_perl' ) {
2749
2750             if ( !$engine ) {
2751
2752                 if ( $version >= 1.99922 ) {
2753                     $engine = 'Catalyst::Engine::Apache2::MP20';
2754                 }
2755
2756                 elsif ( $version >= 1.9901 ) {
2757                     $engine = 'Catalyst::Engine::Apache2::MP19';
2758                 }
2759
2760                 elsif ( $version >= 1.24 ) {
2761                     $engine = 'Catalyst::Engine::Apache::MP13';
2762                 }
2763
2764                 else {
2765                     Catalyst::Exception->throw( message =>
2766                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2767                 }
2768
2769             }
2770
2771             # install the correct mod_perl handler
2772             if ( $version >= 1.9901 ) {
2773                 *handler = sub  : method {
2774                     shift->handle_request(@_);
2775                 };
2776             }
2777             else {
2778                 *handler = sub ($$) { shift->handle_request(@_) };
2779             }
2780
2781         }
2782
2783         elsif ( $software eq 'Zeus-Perl' ) {
2784             $engine = 'Catalyst::Engine::Zeus';
2785         }
2786
2787         else {
2788             Catalyst::Exception->throw(
2789                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2790         }
2791     }
2792
2793     unless ($engine) {
2794         $engine = $class->engine_class;
2795     }
2796
2797     Class::MOP::load_class($engine);
2798
2799     # check for old engines that are no longer compatible
2800     my $old_engine;
2801     if ( $engine->isa('Catalyst::Engine::Apache')
2802         && !Catalyst::Engine::Apache->VERSION )
2803     {
2804         $old_engine = 1;
2805     }
2806
2807     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2808         && Catalyst::Engine::Server->VERSION le '0.02' )
2809     {
2810         $old_engine = 1;
2811     }
2812
2813     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2814         && $engine->VERSION eq '0.01' )
2815     {
2816         $old_engine = 1;
2817     }
2818
2819     elsif ($engine->isa('Catalyst::Engine::Zeus')
2820         && $engine->VERSION eq '0.01' )
2821     {
2822         $old_engine = 1;
2823     }
2824
2825     if ($old_engine) {
2826         Catalyst::Exception->throw( message =>
2827               qq/Engine "$engine" is not supported by this version of Catalyst/
2828         );
2829     }
2830
2831     # engine instance
2832     $class->engine( $engine->new );
2833 }
2834
2835 =head2 $c->setup_home
2836
2837 Sets up the home directory.
2838
2839 =cut
2840
2841 sub setup_home {
2842     my ( $class, $home ) = @_;
2843
2844     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2845         $home = $env;
2846     }
2847
2848     $home ||= Catalyst::Utils::home($class);
2849
2850     if ($home) {
2851         #I remember recently being scolded for assigning config values like this
2852         $class->config->{home} ||= $home;
2853         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2854     }
2855 }
2856
2857 =head2 $c->setup_log
2858
2859 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2860 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2861 log to.
2862
2863 This method also installs a C<debug> method that returns a true value into the
2864 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2865 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2866
2867 Note that if the log has already been setup, by either a previous call to
2868 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2869 that this method won't actually set up the log object.
2870
2871 =cut
2872
2873 sub setup_log {
2874     my ( $class, $levels ) = @_;
2875
2876     $levels ||= '';
2877     $levels =~ s/^\s+//;
2878     $levels =~ s/\s+$//;
2879     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2880
2881     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2882     if ( defined $env_debug ) {
2883         $levels{debug} = 1 if $env_debug; # Ugly!
2884         delete($levels{debug}) unless $env_debug;
2885     }
2886
2887     unless ( $class->log ) {
2888         $class->log( Catalyst::Log->new(keys %levels) );
2889     }
2890
2891     if ( $levels{debug} ) {
2892         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2893         $class->log->debug('Debug messages enabled');
2894     }
2895 }
2896
2897 =head2 $c->setup_plugins
2898
2899 Sets up plugins.
2900
2901 =cut
2902
2903 =head2 $c->setup_stats
2904
2905 Sets up timing statistics class.
2906
2907 =cut
2908
2909 sub setup_stats {
2910     my ( $class, $stats ) = @_;
2911
2912     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2913
2914     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2915     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2916         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2917         $class->log->debug('Statistics enabled');
2918     }
2919 }
2920
2921
2922 =head2 $c->registered_plugins
2923
2924 Returns a sorted list of the plugins which have either been stated in the
2925 import list or which have been added via C<< MyApp->plugin(@args); >>.
2926
2927 If passed a given plugin name, it will report a boolean value indicating
2928 whether or not that plugin is loaded.  A fully qualified name is required if
2929 the plugin name does not begin with C<Catalyst::Plugin::>.
2930
2931  if ($c->registered_plugins('Some::Plugin')) {
2932      ...
2933  }
2934
2935 =cut
2936
2937 {
2938
2939     sub registered_plugins {
2940         my $proto = shift;
2941         return sort keys %{ $proto->_plugins } unless @_;
2942         my $plugin = shift;
2943         return 1 if exists $proto->_plugins->{$plugin};
2944         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2945     }
2946
2947     sub _register_plugin {
2948         my ( $proto, $plugin, $instant ) = @_;
2949         my $class = ref $proto || $proto;
2950
2951         Class::MOP::load_class( $plugin );
2952         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2953             if $plugin->isa( 'Catalyst::Component' );
2954         $proto->_plugins->{$plugin} = 1;
2955         unless ($instant) {
2956             no strict 'refs';
2957             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2958               my @superclasses = ($plugin, $meta->superclasses );
2959               $meta->superclasses(@superclasses);
2960             } else {
2961               unshift @{"$class\::ISA"}, $plugin;
2962             }
2963         }
2964         return $class;
2965     }
2966
2967     sub setup_plugins {
2968         my ( $class, $plugins ) = @_;
2969
2970         $class->_plugins( {} ) unless $class->_plugins;
2971         $plugins ||= [];
2972
2973         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2974
2975         for my $plugin ( reverse @plugins ) {
2976             Class::MOP::load_class($plugin);
2977             my $meta = find_meta($plugin);
2978             next if $meta && $meta->isa('Moose::Meta::Role');
2979
2980             $class->_register_plugin($plugin);
2981         }
2982
2983         my @roles =
2984             map { $_->name }
2985             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2986             map { find_meta($_) }
2987             @plugins;
2988
2989         Moose::Util::apply_all_roles(
2990             $class => @roles
2991         ) if @roles;
2992     }
2993 }
2994
2995 =head2 $c->stack
2996
2997 Returns an arrayref of the internal execution stack (actions that are
2998 currently executing).
2999
3000 =head2 $c->stats_class
3001
3002 Returns or sets the stats (timing statistics) class.
3003
3004 =head2 $c->use_stats
3005
3006 Returns 1 when stats collection is enabled.  Stats collection is enabled
3007 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
3008 environment variable is set.
3009
3010 Note that this is a static method, not an accessor and should be overridden
3011 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3012
3013 =cut
3014
3015 sub use_stats { 0 }
3016
3017
3018 =head2 $c->write( $data )
3019
3020 Writes $data to the output stream. When using this method directly, you
3021 will need to manually set the C<Content-Length> header to the length of
3022 your output data, if known.
3023
3024 =cut
3025
3026 sub write {
3027     my $c = shift;
3028
3029     # Finalize headers if someone manually writes output
3030     $c->finalize_headers;
3031
3032     return $c->engine->write( $c, @_ );
3033 }
3034
3035 =head2 version
3036
3037 Returns the Catalyst version number. Mostly useful for "powered by"
3038 messages in template systems.
3039
3040 =cut
3041
3042 sub version { return $Catalyst::VERSION }
3043
3044 =head1 CONFIGURATION
3045
3046 There are a number of 'base' config variables which can be set:
3047
3048 =over
3049
3050 =item *
3051
3052 C<default_model> - The default model picked if you say C<< $c->model >>. See L</$c->model($name)>.
3053
3054 =item *
3055
3056 C<default_view> - The default view to be rendered or returned when C<< $c->view >>. See L</$c->view($name)>.
3057 is called.
3058
3059 =item *
3060
3061 C<disable_component_resolution_regex_fallback> - Turns
3062 off the deprecated component resolution functionality so
3063 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3064 are called then regex search will not be attempted on string values and
3065 instead C<undef> will be returned.
3066
3067 =item *
3068
3069 C<home> - The application home directory. In an uninstalled application,
3070 this is the top level application directory. In an installed application,
3071 this will be the directory containing C<< MyApp.pm >>.
3072
3073 =item *
3074
3075 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3076
3077 =item *
3078
3079 C<name> - The name of the application in debug messages and the debug and
3080 welcome screens
3081
3082 =item *
3083
3084 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3085 until it is accessed. This allows you to (for example) check authentication (and reject
3086 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
3087
3088 =item *
3089
3090 C<root> - The root directory for templates. Usually this is just a
3091 subdirectory of the home directory, but you can set it to change the
3092 templates to a different directory.
3093
3094 =item *
3095
3096 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3097 namespaces from which components will be loaded (and constructed and stored in
3098 C<< $c->components >>).
3099
3100 =item *
3101
3102 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3103 to be shown in hit debug tables in the test server.
3104
3105 =item *
3106
3107 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3108
3109 =back
3110
3111 =head1 INTERNAL ACTIONS
3112
3113 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3114 C<_ACTION>, and C<_END>. These are by default not shown in the private
3115 action table, but you can make them visible with a config parameter.
3116
3117     MyApp->config(show_internal_actions => 1);
3118
3119 =head1 ON-DEMAND PARSER
3120
3121 The request body is usually parsed at the beginning of a request,
3122 but if you want to handle input yourself, you can enable on-demand
3123 parsing with a config parameter.
3124
3125     MyApp->config(parse_on_demand => 1);
3126
3127 =head1 PROXY SUPPORT
3128
3129 Many production servers operate using the common double-server approach,
3130 with a lightweight frontend web server passing requests to a larger
3131 backend server. An application running on the backend server must deal
3132 with two problems: the remote user always appears to be C<127.0.0.1> and
3133 the server's hostname will appear to be C<localhost> regardless of the
3134 virtual host that the user connected through.
3135
3136 Catalyst will automatically detect this situation when you are running
3137 the frontend and backend servers on the same machine. The following
3138 changes are made to the request.
3139
3140     $c->req->address is set to the user's real IP address, as read from
3141     the HTTP X-Forwarded-For header.
3142
3143     The host value for $c->req->base and $c->req->uri is set to the real
3144     host, as read from the HTTP X-Forwarded-Host header.
3145
3146 Additionally, you may be running your backend application on an insecure
3147 connection (port 80) while your frontend proxy is running under SSL.  If there
3148 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3149 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3150 be created properly.
3151
3152 In the case of passing in:
3153
3154     X-Forwarded-Port: 443
3155
3156 All calls to C<uri_for> will result in an https link, as is expected.
3157
3158 Obviously, your web server must support these headers for this to work.
3159
3160 In a more complex server farm environment where you may have your
3161 frontend proxy server(s) on different machines, you will need to set a
3162 configuration option to tell Catalyst to read the proxied data from the
3163 headers.
3164
3165     MyApp->config(using_frontend_proxy => 1);
3166
3167 If you do not wish to use the proxy support at all, you may set:
3168
3169     MyApp->config(ignore_frontend_proxy => 1);
3170
3171 =head1 THREAD SAFETY
3172
3173 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3174 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3175 believe the Catalyst core to be thread-safe.
3176
3177 If you plan to operate in a threaded environment, remember that all other
3178 modules you are using must also be thread-safe. Some modules, most notably
3179 L<DBD::SQLite>, are not thread-safe.
3180
3181 =head1 SUPPORT
3182
3183 IRC:
3184
3185     Join #catalyst on irc.perl.org.
3186
3187 Mailing Lists:
3188
3189     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3190     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3191
3192 Web:
3193
3194     http://catalyst.perl.org
3195
3196 Wiki:
3197
3198     http://dev.catalyst.perl.org
3199
3200 =head1 SEE ALSO
3201
3202 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3203
3204 =head2 L<Catalyst::Manual> - The Catalyst Manual
3205
3206 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3207
3208 =head2 L<Catalyst::Engine> - Core engine
3209
3210 =head2 L<Catalyst::Log> - Log class.
3211
3212 =head2 L<Catalyst::Request> - Request object
3213
3214 =head2 L<Catalyst::Response> - Response object
3215
3216 =head2 L<Catalyst::Test> - The test suite.
3217
3218 =head1 PROJECT FOUNDER
3219
3220 sri: Sebastian Riedel <sri@cpan.org>
3221
3222 =head1 CONTRIBUTORS
3223
3224 abw: Andy Wardley
3225
3226 acme: Leon Brocard <leon@astray.com>
3227
3228 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3229
3230 Andrew Bramble
3231
3232 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3233
3234 Andrew Ruthven
3235
3236 andyg: Andy Grundman <andy@hybridized.org>
3237
3238 audreyt: Audrey Tang
3239
3240 bricas: Brian Cassidy <bricas@cpan.org>
3241
3242 Caelum: Rafael Kitover <rkitover@io.com>
3243
3244 chansen: Christian Hansen
3245
3246 chicks: Christopher Hicks
3247
3248 Chisel Wright C<pause@herlpacker.co.uk>
3249
3250 Danijel Milicevic C<me@danijel.de>
3251
3252 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3253
3254 David Naughton, C<naughton@umn.edu>
3255
3256 David E. Wheeler
3257
3258 dhoss: Devin Austin <dhoss@cpan.org>
3259
3260 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3261
3262 Drew Taylor
3263
3264 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3265
3266 esskar: Sascha Kiefer
3267
3268 fireartist: Carl Franks <cfranks@cpan.org>
3269
3270 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3271
3272 gabb: Danijel Milicevic
3273
3274 Gary Ashton Jones
3275
3276 Gavin Henry C<ghenry@perl.me.uk>
3277
3278 Geoff Richards
3279
3280 groditi: Guillermo Roditi <groditi@gmail.com>
3281
3282 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3283
3284 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3285
3286 jcamacho: Juan Camacho
3287
3288 jester: Jesse Sheidlower C<jester@panix.com>
3289
3290 jhannah: Jay Hannah <jay@jays.net>
3291
3292 Jody Belka
3293
3294 Johan Lindstrom
3295
3296 jon: Jon Schutz <jjschutz@cpan.org>
3297
3298 Jonathan Rockway C<< <jrockway@cpan.org> >>
3299
3300 Kieren Diment C<kd@totaldatasolution.com>
3301
3302 konobi: Scott McWhirter <konobi@cpan.org>
3303
3304 marcus: Marcus Ramberg <mramberg@cpan.org>
3305
3306 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3307
3308 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3309
3310 mugwump: Sam Vilain
3311
3312 naughton: David Naughton
3313
3314 ningu: David Kamholz <dkamholz@cpan.org>
3315
3316 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3317
3318 numa: Dan Sully <daniel@cpan.org>
3319
3320 obra: Jesse Vincent
3321
3322 omega: Andreas Marienborg
3323
3324 Oleg Kostyuk <cub.uanic@gmail.com>
3325
3326 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3327
3328 rafl: Florian Ragwitz <rafl@debian.org>
3329
3330 random: Roland Lammel <lammel@cpan.org>
3331
3332 Robert Sedlacek C<< <rs@474.at> >>
3333
3334 sky: Arthur Bergman
3335
3336 t0m: Tomas Doran <bobtfish@bobtfish.net>
3337
3338 Ulf Edvinsson
3339
3340 Viljo Marrandi C<vilts@yahoo.com>
3341
3342 Will Hawes C<info@whawes.co.uk>
3343
3344 willert: Sebastian Willert <willert@cpan.org>
3345
3346 Yuval Kogman, C<nothingmuch@woobling.org>
3347
3348 =head1 LICENSE
3349
3350 This library is free software. You can redistribute it and/or modify it under
3351 the same terms as Perl itself.
3352
3353 =cut
3354
3355 no Moose;
3356
3357 __PACKAGE__->meta->make_immutable;
3358
3359 1;