lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Plack::Util;
  51 use Class::Load 'load_class';
  52
  53 BEGIN { require 5.008003; }
  54
  55 has stack => (is => 'ro', default => sub { [] });
  56 has stash => (is => 'rw', default => sub { {} });
  57 has state => (is => 'rw', default => 0);
  58 has stats => (is => 'rw');
  59 has action => (is => 'rw');
  60 has counter => (is => 'rw', default => sub { {} });
  61 has request => (
  62     is => 'rw',
  63     default => sub {
  64         my $self = shift;
  65         $self->request_class->new($self->_build_request_constructor_args);
  66     },
  67     lazy => 1,
  68 );
  69 sub _build_request_constructor_args {
  70     my $self = shift;
  71     my %p = ( _log => $self->log );
  72     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  73     $p{data_handlers} = {$self->registered_data_handlers};
  74     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  75       if $self->config->{use_hash_multivalue_in_request};
  76     \%p;
  77 }
  78
  79 has response => (
  80     is => 'rw',
  81     default => sub {
  82         my $self = shift;
  83         $self->response_class->new($self->_build_response_constructor_args);
  84     },
  85     lazy => 1,
  86 );
  87 sub _build_response_constructor_args {
  88     my $self = shift;
  89     { _log => $self->log };
  90 }
  91
  92 has namespace => (is => 'rw');
  93
  94 sub depth { scalar @{ shift->stack || [] }; }
  95 sub comp { shift->component(@_) }
  96
  97 sub req {
  98     my $self = shift; return $self->request(@_);
  99 }
 100 sub res {
 101     my $self = shift; return $self->response(@_);
 102 }
 103
 104 # For backwards compatibility
 105 sub finalize_output { shift->finalize_body(@_) };
 106
 107 # For statistics
 108 our $COUNT     = 1;
 109 our $START     = time;
 110 our $RECURSION = 1000;
 111 our $DETACH    = Catalyst::Exception::Detach->new;
 112 our $GO        = Catalyst::Exception::Go->new;
 113
 114 #I imagine that very few of these really need to be class variables. if any.
 115 #maybe we should just make them attributes with a default?
 116 __PACKAGE__->mk_classdata($_)
 117   for qw/components arguments dispatcher engine log dispatcher_class
 118   engine_loader context_class request_class response_class stats_class
 119   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 120   _data_handlers/;
 121
 122 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 123 __PACKAGE__->request_class('Catalyst::Request');
 124 __PACKAGE__->response_class('Catalyst::Response');
 125 __PACKAGE__->stats_class('Catalyst::Stats');
 126
 127 # Remember to update this in Catalyst::Runtime as well!
 128
 129 our $VERSION = '5.90064';
 130
 131 sub import {
 132     my ( $class, @arguments ) = @_;
 133
 134     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 135     # callers @ISA.
 136     return unless $class eq 'Catalyst';
 137
 138     my $caller = caller();
 139     return if $caller eq 'main';
 140
 141     my $meta = Moose::Meta::Class->initialize($caller);
 142     unless ( $caller->isa('Catalyst') ) {
 143         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 144         $meta->superclasses(@superclasses);
 145     }
 146     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 147     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 148
 149     unless( $meta->has_method('meta') ){
 150         if ($Moose::VERSION >= 1.15) {
 151             $meta->_add_meta_method('meta');
 152         }
 153         else {
 154             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 155         }
 156     }
 157
 158     $caller->arguments( [@arguments] );
 159     $caller->setup_home;
 160 }
 161
 162 sub _application { $_[0] }
 163
 164 =encoding UTF-8
 165
 166 =head1 NAME
 167
 168 Catalyst - The Elegant MVC Web Application Framework
 169
 170 =head1 SYNOPSIS
 171
 172 See the L<Catalyst::Manual> distribution for comprehensive
 173 documentation and tutorials.
 174
 175     # Install Catalyst::Devel for helpers and other development tools
 176     # use the helper to create a new application
 177     catalyst.pl MyApp
 178
 179     # add models, views, controllers
 180     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 181     script/myapp_create.pl view MyTemplate TT
 182     script/myapp_create.pl controller Search
 183
 184     # built in testserver -- use -r to restart automatically on changes
 185     # --help to see all available options
 186     script/myapp_server.pl
 187
 188     # command line testing interface
 189     script/myapp_test.pl /yada
 190
 191     ### in lib/MyApp.pm
 192     use Catalyst qw/-Debug/; # include plugins here as well
 193
 194     ### In lib/MyApp/Controller/Root.pm (autocreated)
 195     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 196         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 197         $c->stash->{template} = 'foo.tt'; # set the template
 198         # lookup something from db -- stash vars are passed to TT
 199         $c->stash->{data} =
 200           $c->model('Database::Foo')->search( { country => $args[0] } );
 201         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 202             $c->forward( 'bar' ); # process another action
 203             # do something else after forward returns
 204         }
 205     }
 206
 207     # The foo.tt TT template can use the stash data from the database
 208     [% WHILE (item = data.next) %]
 209         [% item.foo %]
 210     [% END %]
 211
 212     # called for /bar/of/soap, /bar/of/soap/10, etc.
 213     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 214
 215     # called after all actions are finished
 216     sub end : Action {
 217         my ( $self, $c ) = @_;
 218         if ( scalar @{ $c->error } ) { ... } # handle errors
 219         return if $c->res->body; # already have a response
 220         $c->forward( 'MyApp::View::TT' ); # render template
 221     }
 222
 223 See L<Catalyst::Manual::Intro> for additional information.
 224
 225 =head1 DESCRIPTION
 226
 227 Catalyst is a modern framework for making web applications without the
 228 pain usually associated with this process. This document is a reference
 229 to the main Catalyst application. If you are a new user, we suggest you
 230 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 231
 232 See L<Catalyst::Manual> for more documentation.
 233
 234 Catalyst plugins can be loaded by naming them as arguments to the "use
 235 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 236 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 237 C<My::Module>.
 238
 239     use Catalyst qw/My::Module/;
 240
 241 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 242 fully qualify the name by using a unary plus:
 243
 244     use Catalyst qw/
 245         My::Module
 246         +Fully::Qualified::Plugin::Name
 247     /;
 248
 249 Special flags like C<-Debug> can also be specified as
 250 arguments when Catalyst is loaded:
 251
 252     use Catalyst qw/-Debug My::Module/;
 253
 254 The position of plugins and flags in the chain is important, because
 255 they are loaded in the order in which they appear.
 256
 257 The following flags are supported:
 258
 259 =head2 -Debug
 260
 261 Enables debug output. You can also force this setting from the system
 262 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 263 settings override the application, with <MYAPP>_DEBUG having the highest
 264 priority.
 265
 266 This sets the log level to 'debug' and enables full debug output on the
 267 error screen. If you only want the latter, see L<< $c->debug >>.
 268
 269 =head2 -Home
 270
 271 Forces Catalyst to use a specific home directory, e.g.:
 272
 273     use Catalyst qw[-Home=/usr/mst];
 274
 275 This can also be done in the shell environment by setting either the
 276 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 277 is replaced with the uppercased name of your application, any "::" in
 278 the name will be replaced with underscores, e.g. MyApp::Web should use
 279 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 280
 281 If none of these are set, Catalyst will attempt to automatically detect the
 282 home directory. If you are working in a development environment, Catalyst
 283 will try and find the directory containing either Makefile.PL, Build.PL,
 284 dist.ini, or cpanfile. If the application has been installed into the system
 285 (i.e. you have done C<make install>), then Catalyst will use the path to your
 286 application module, without the .pm extension (e.g., /foo/MyApp if your
 287 application was installed at /foo/MyApp.pm)
 288
 289 =head2 -Log
 290
 291     use Catalyst '-Log=warn,fatal,error';
 292
 293 Specifies a comma-delimited list of log levels.
 294
 295 =head2 -Stats
 296
 297 Enables statistics collection and reporting.
 298
 299    use Catalyst qw/-Stats=1/;
 300
 301 You can also force this setting from the system environment with CATALYST_STATS
 302 or <MYAPP>_STATS. The environment settings override the application, with
 303 <MYAPP>_STATS having the highest priority.
 304
 305 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 306
 307 =head1 METHODS
 308
 309 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 310
 311 =head2 $c->action
 312
 313 Returns a L<Catalyst::Action> object for the current action, which
 314 stringifies to the action name. See L<Catalyst::Action>.
 315
 316 =head2 $c->namespace
 317
 318 Returns the namespace of the current action, i.e., the URI prefix
 319 corresponding to the controller of the current action. For example:
 320
 321     # in Controller::Foo::Bar
 322     $c->namespace; # returns 'foo/bar';
 323
 324 =head2 $c->request
 325
 326 =head2 $c->req
 327
 328 Returns the current L<Catalyst::Request> object, giving access to
 329 information about the current client request (including parameters,
 330 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 331
 332 =head2 REQUEST FLOW HANDLING
 333
 334 =head2 $c->forward( $action [, \@arguments ] )
 335
 336 =head2 $c->forward( $class, $method, [, \@arguments ] )
 337
 338 This is one way of calling another action (method) in the same or
 339 a different controller. You can also use C<< $self->my_method($c, @args) >>
 340 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 341 in a different controller.
 342 The main difference is that 'forward' uses some of the Catalyst request
 343 cycle overhead, including debugging, which may be useful to you. On the
 344 other hand, there are some complications to using 'forward', restrictions
 345 on values returned from 'forward', and it may not handle errors as you prefer.
 346 Whether you use 'forward' or not is up to you; it is not considered superior to
 347 the other ways to call a method.
 348
 349 'forward' calls  another action, by its private name. If you give a
 350 class name but no method, C<process()> is called. You may also optionally
 351 pass arguments in an arrayref. The action will receive the arguments in
 352 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 353 C<< $c->req->args >> will be restored to the previous values.
 354
 355 Any data C<return>ed from the action forwarded to, will be returned by the
 356 call to forward.
 357
 358     my $foodata = $c->forward('/foo');
 359     $c->forward('index');
 360     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 361     $c->forward('View::TT');
 362
 363 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 364 an C<< eval { } >> around the call (actually
 365 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 366 exceptions thrown by the called action non-fatal and pushing them onto
 367 $c->error instead. If you want C<die> to propagate you need to do something
 368 like:
 369
 370     $c->forward('foo');
 371     die join "\n", @{ $c->error } if @{ $c->error };
 372
 373 Or make sure to always return true values from your actions and write
 374 your code like this:
 375
 376     $c->forward('foo') || return;
 377
 378 Another note is that C<< $c->forward >> always returns a scalar because it
 379 actually returns $c->state which operates in a scalar context.
 380 Thus, something like:
 381
 382     return @array;
 383
 384 in an action that is forwarded to is going to return a scalar,
 385 i.e. how many items are in that array, which is probably not what you want.
 386 If you need to return an array then return a reference to it,
 387 or stash it like so:
 388
 389     $c->stash->{array} = \@array;
 390
 391 and access it from the stash.
 392
 393 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 394
 395 =cut
 396
 397 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 398
 399 =head2 $c->detach( $action [, \@arguments ] )
 400
 401 =head2 $c->detach( $class, $method, [, \@arguments ] )
 402
 403 =head2 $c->detach()
 404
 405 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 406 doesn't return to the previous action when processing is finished.
 407
 408 When called with no arguments it escapes the processing chain entirely.
 409
 410 =cut
 411
 412 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 413
 414 =head2 $c->visit( $action [, \@arguments ] )
 415
 416 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 417
 418 =head2 $c->visit( $class, $method, [, \@arguments ] )
 419
 420 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 421
 422 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 423 but does a full dispatch, instead of just calling the new C<$action> /
 424 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 425 you go to are called, just like a new request.
 426
 427 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 428 This means, for example, that C<< $c->action >> methods such as
 429 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 430 L<reverse|Catalyst::Action/reverse> return information for the visited action
 431 when they are invoked within the visited action.  This is different from the
 432 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 433 continues to use the $c->action object from the caller action even when
 434 invoked from the called action.
 435
 436 C<< $c->stash >> is kept unchanged.
 437
 438 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 439 allows you to "wrap" another action, just as it would have been called by
 440 dispatching from a URL, while the analogous
 441 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 442 transfer control to another action as if it had been reached directly from a URL.
 443
 444 =cut
 445
 446 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 447
 448 =head2 $c->go( $action [, \@arguments ] )
 449
 450 =head2 $c->go( $action [, \@captures, \@arguments ] )
 451
 452 =head2 $c->go( $class, $method, [, \@arguments ] )
 453
 454 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 455
 456 The relationship between C<go> and
 457 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 458 the relationship between
 459 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 460 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 461 C<< $c->go >> will perform a full dispatch on the specified action or method,
 462 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 463 C<go> escapes the processing of the current request chain on completion, and
 464 does not return to its caller.
 465
 466 @arguments are arguments to the final destination of $action. @captures are
 467 arguments to the intermediate steps, if any, on the way to the final sub of
 468 $action.
 469
 470 =cut
 471
 472 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 473
 474 =head2 $c->response
 475
 476 =head2 $c->res
 477
 478 Returns the current L<Catalyst::Response> object, see there for details.
 479
 480 =head2 $c->stash
 481
 482 Returns a hashref to the stash, which may be used to store data and pass
 483 it between components during a request. You can also set hash keys by
 484 passing arguments. The stash is automatically sent to the view. The
 485 stash is cleared at the end of a request; it cannot be used for
 486 persistent storage (for this you must use a session; see
 487 L<Catalyst::Plugin::Session> for a complete system integrated with
 488 Catalyst).
 489
 490     $c->stash->{foo} = $bar;
 491     $c->stash( { moose => 'majestic', qux => 0 } );
 492     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 493
 494     # stash is automatically passed to the view for use in a template
 495     $c->forward( 'MyApp::View::TT' );
 496
 497 =cut
 498
 499 around stash => sub {
 500     my $orig = shift;
 501     my $c = shift;
 502     my $stash = $orig->($c);
 503     if (@_) {
 504         my $new_stash = @_ > 1 ? {@_} : $_[0];
 505         croak('stash takes a hash or hashref') unless ref $new_stash;
 506         foreach my $key ( keys %$new_stash ) {
 507           $stash->{$key} = $new_stash->{$key};
 508         }
 509     }
 510
 511     return $stash;
 512 };
 513
 514
 515 =head2 $c->error
 516
 517 =head2 $c->error($error, ...)
 518
 519 =head2 $c->error($arrayref)
 520
 521 Returns an arrayref containing error messages.  If Catalyst encounters an
 522 error while processing a request, it stores the error in $c->error.  This
 523 method should only be used to store fatal error messages.
 524
 525     my @error = @{ $c->error };
 526
 527 Add a new error.
 528
 529     $c->error('Something bad happened');
 530
 531 =cut
 532
 533 sub error {
 534     my $c = shift;
 535     if ( $_[0] ) {
 536         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 537         croak @$error unless ref $c;
 538         push @{ $c->{error} }, @$error;
 539     }
 540     elsif ( defined $_[0] ) { $c->{error} = undef }
 541     return $c->{error} || [];
 542 }
 543
 544
 545 =head2 $c->state
 546
 547 Contains the return value of the last executed action.
 548 Note that << $c->state >> operates in a scalar context which means that all
 549 values it returns are scalar.
 550
 551 =head2 $c->clear_errors
 552
 553 Clear errors.  You probably don't want to clear the errors unless you are
 554 implementing a custom error screen.
 555
 556 This is equivalent to running
 557
 558     $c->error(0);
 559
 560 =cut
 561
 562 sub clear_errors {
 563     my $c = shift;
 564     $c->error(0);
 565 }
 566
 567 sub _comp_search_prefixes {
 568     my $c = shift;
 569     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 570 }
 571
 572 # search components given a name and some prefixes
 573 sub _comp_names_search_prefixes {
 574     my ( $c, $name, @prefixes ) = @_;
 575     my $appclass = ref $c || $c;
 576     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 577     $filter = qr/$filter/; # Compile regex now rather than once per loop
 578
 579     # map the original component name to the sub part that we will search against
 580     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 581         grep { /$filter/ } keys %{ $c->components };
 582
 583     # undef for a name will return all
 584     return keys %eligible if !defined $name;
 585
 586     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 587     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 588
 589     return @result if @result;
 590
 591     # if we were given a regexp to search against, we're done.
 592     return if $name->$_isa('Regexp');
 593
 594     # skip regexp fallback if configured
 595     return
 596         if $appclass->config->{disable_component_resolution_regex_fallback};
 597
 598     # regexp fallback
 599     $query  = qr/$name/i;
 600     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 601
 602     # no results? try against full names
 603     if( !@result ) {
 604         @result = grep { m{$query} } keys %eligible;
 605     }
 606
 607     # don't warn if we didn't find any results, it just might not exist
 608     if( @result ) {
 609         # Disgusting hack to work out correct method name
 610         my $warn_for = lc $prefixes[0];
 611         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 612            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 613            "component resolution is unreliable and unsafe.";
 614         my $short = $result[0];
 615         # remove the component namespace prefix
 616         $short =~ s/.*?(Model|Controller|View):://;
 617         my $shortmess = Carp::shortmess('');
 618         if ($shortmess =~ m#Catalyst/Plugin#) {
 619            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 620               "plugin's config";
 621         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 622            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 623               "component's config";
 624         } else {
 625            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 626               "but if you really wanted to search, pass in a regexp as the argument " .
 627               "like so: \$c->${warn_for}(qr/${name}/)";
 628         }
 629         $c->log->warn( "${msg}$shortmess" );
 630     }
 631
 632     return @result;
 633 }
 634
 635 # Find possible names for a prefix
 636 sub _comp_names {
 637     my ( $c, @prefixes ) = @_;
 638     my $appclass = ref $c || $c;
 639
 640     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 641
 642     my @names = map { s{$filter}{}; $_; }
 643         $c->_comp_names_search_prefixes( undef, @prefixes );
 644
 645     return @names;
 646 }
 647
 648 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 649 sub _filter_component {
 650     my ( $c, $comp, @args ) = @_;
 651
 652     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 653         return $comp->ACCEPT_CONTEXT( $c, @args );
 654     }
 655
 656     return $comp;
 657 }
 658
 659 =head2 COMPONENT ACCESSORS
 660
 661 =head2 $c->controller($name)
 662
 663 Gets a L<Catalyst::Controller> instance by name.
 664
 665     $c->controller('Foo')->do_stuff;
 666
 667 If the name is omitted, will return the controller for the dispatched
 668 action.
 669
 670 If you want to search for controllers, pass in a regexp as the argument.
 671
 672     # find all controllers that start with Foo
 673     my @foo_controllers = $c->controller(qr{^Foo});
 674
 675
 676 =cut
 677
 678 sub controller {
 679     my ( $c, $name, @args ) = @_;
 680
 681     my $appclass = ref($c) || $c;
 682     if( $name ) {
 683         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 684             my $comps = $c->components;
 685             my $check = $appclass."::Controller::".$name;
 686             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 687         }
 688         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 689         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 690         return $c->_filter_component( $result[ 0 ], @args );
 691     }
 692
 693     return $c->component( $c->action->class );
 694 }
 695
 696 =head2 $c->model($name)
 697
 698 Gets a L<Catalyst::Model> instance by name.
 699
 700     $c->model('Foo')->do_stuff;
 701
 702 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 703
 704 If the name is omitted, it will look for
 705  - a model object in $c->stash->{current_model_instance}, then
 706  - a model name in $c->stash->{current_model}, then
 707  - a config setting 'default_model', or
 708  - check if there is only one model, and return it if that's the case.
 709
 710 If you want to search for models, pass in a regexp as the argument.
 711
 712     # find all models that start with Foo
 713     my @foo_models = $c->model(qr{^Foo});
 714
 715 =cut
 716
 717 sub model {
 718     my ( $c, $name, @args ) = @_;
 719     my $appclass = ref($c) || $c;
 720     if( $name ) {
 721         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 722             my $comps = $c->components;
 723             my $check = $appclass."::Model::".$name;
 724             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 725         }
 726         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 727         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 728         return $c->_filter_component( $result[ 0 ], @args );
 729     }
 730
 731     if (ref $c) {
 732         return $c->stash->{current_model_instance}
 733           if $c->stash->{current_model_instance};
 734         return $c->model( $c->stash->{current_model} )
 735           if $c->stash->{current_model};
 736     }
 737     return $c->model( $appclass->config->{default_model} )
 738       if $appclass->config->{default_model};
 739
 740     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 741
 742     if( $rest ) {
 743         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 744         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 745         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 746         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 747         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 748     }
 749
 750     return $c->_filter_component( $comp );
 751 }
 752
 753
 754 =head2 $c->view($name)
 755
 756 Gets a L<Catalyst::View> instance by name.
 757
 758     $c->view('Foo')->do_stuff;
 759
 760 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 761
 762 If the name is omitted, it will look for
 763  - a view object in $c->stash->{current_view_instance}, then
 764  - a view name in $c->stash->{current_view}, then
 765  - a config setting 'default_view', or
 766  - check if there is only one view, and return it if that's the case.
 767
 768 If you want to search for views, pass in a regexp as the argument.
 769
 770     # find all views that start with Foo
 771     my @foo_views = $c->view(qr{^Foo});
 772
 773 =cut
 774
 775 sub view {
 776     my ( $c, $name, @args ) = @_;
 777
 778     my $appclass = ref($c) || $c;
 779     if( $name ) {
 780         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 781             my $comps = $c->components;
 782             my $check = $appclass."::View::".$name;
 783             if( exists $comps->{$check} ) {
 784                 return $c->_filter_component( $comps->{$check}, @args );
 785             }
 786             else {
 787                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 788             }
 789         }
 790         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 791         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 792         return $c->_filter_component( $result[ 0 ], @args );
 793     }
 794
 795     if (ref $c) {
 796         return $c->stash->{current_view_instance}
 797           if $c->stash->{current_view_instance};
 798         return $c->view( $c->stash->{current_view} )
 799           if $c->stash->{current_view};
 800     }
 801     return $c->view( $appclass->config->{default_view} )
 802       if $appclass->config->{default_view};
 803
 804     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 805
 806     if( $rest ) {
 807         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 808         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 809         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 810         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 811         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 812     }
 813
 814     return $c->_filter_component( $comp );
 815 }
 816
 817 =head2 $c->controllers
 818
 819 Returns the available names which can be passed to $c->controller
 820
 821 =cut
 822
 823 sub controllers {
 824     my ( $c ) = @_;
 825     return $c->_comp_names(qw/Controller C/);
 826 }
 827
 828 =head2 $c->models
 829
 830 Returns the available names which can be passed to $c->model
 831
 832 =cut
 833
 834 sub models {
 835     my ( $c ) = @_;
 836     return $c->_comp_names(qw/Model M/);
 837 }
 838
 839
 840 =head2 $c->views
 841
 842 Returns the available names which can be passed to $c->view
 843
 844 =cut
 845
 846 sub views {
 847     my ( $c ) = @_;
 848     return $c->_comp_names(qw/View V/);
 849 }
 850
 851 =head2 $c->comp($name)
 852
 853 =head2 $c->component($name)
 854
 855 Gets a component object by name. This method is not recommended,
 856 unless you want to get a specific component by full
 857 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 858 should be used instead.
 859
 860 If C<$name> is a regexp, a list of components matched against the full
 861 component name will be returned.
 862
 863 If Catalyst can't find a component by name, it will fallback to regex
 864 matching by default. To disable this behaviour set
 865 disable_component_resolution_regex_fallback to a true value.
 866
 867     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 868
 869 =cut
 870
 871 sub component {
 872     my ( $c, $name, @args ) = @_;
 873
 874     if( $name ) {
 875         my $comps = $c->components;
 876
 877         if( !ref $name ) {
 878             # is it the exact name?
 879             return $c->_filter_component( $comps->{ $name }, @args )
 880                        if exists $comps->{ $name };
 881
 882             # perhaps we just omitted "MyApp"?
 883             my $composed = ( ref $c || $c ) . "::${name}";
 884             return $c->_filter_component( $comps->{ $composed }, @args )
 885                        if exists $comps->{ $composed };
 886
 887             # search all of the models, views and controllers
 888             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 889             return $c->_filter_component( $comp, @args ) if $comp;
 890         }
 891
 892         return
 893             if $c->config->{disable_component_resolution_regex_fallback};
 894
 895         # This is here so $c->comp( '::M::' ) works
 896         my $query = ref $name ? $name : qr{$name}i;
 897
 898         my @result = grep { m{$query} } keys %{ $c->components };
 899         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 900
 901         if( $result[ 0 ] ) {
 902             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 903             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 904             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 905             return $c->_filter_component( $result[ 0 ], @args );
 906         }
 907
 908         # I would expect to return an empty list here, but that breaks back-compat
 909     }
 910
 911     # fallback
 912     return sort keys %{ $c->components };
 913 }
 914
 915 =head2 CLASS DATA AND HELPER CLASSES
 916
 917 =head2 $c->config
 918
 919 Returns or takes a hashref containing the application's configuration.
 920
 921     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 922
 923 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 924 like C<myapp.conf> in your applications home directory. See
 925 L<Catalyst::Plugin::ConfigLoader>.
 926
 927 =head3 Cascading configuration
 928
 929 The config method is present on all Catalyst components, and configuration
 930 will be merged when an application is started. Configuration loaded with
 931 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 932 followed by configuration in your top level C<MyApp> class. These two
 933 configurations are merged, and then configuration data whose hash key matches a
 934 component name is merged with configuration for that component.
 935
 936 The configuration for a component is then passed to the C<new> method when a
 937 component is constructed.
 938
 939 For example:
 940
 941     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 942     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 943
 944 will mean that C<MyApp::Model::Foo> receives the following data when
 945 constructed:
 946
 947     MyApp::Model::Foo->new({
 948         bar => 'baz',
 949         quux => 'frob',
 950         overrides => 'me',
 951     });
 952
 953 It's common practice to use a Moose attribute
 954 on the receiving component to access the config value.
 955
 956     package MyApp::Model::Foo;
 957
 958     use Moose;
 959
 960     # this attr will receive 'baz' at construction time
 961     has 'bar' => (
 962         is  => 'rw',
 963         isa => 'Str',
 964     );
 965
 966 You can then get the value 'baz' by calling $c->model('Foo')->bar
 967 (or $self->bar inside code in the model).
 968
 969 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 970 as a way of reading config within your code, as this B<will not> give you the
 971 correctly merged config back. You B<MUST> take the config values supplied to
 972 the constructor and use those instead.
 973
 974 =cut
 975
 976 around config => sub {
 977     my $orig = shift;
 978     my $c = shift;
 979
 980     croak('Setting config after setup has been run is not allowed.')
 981         if ( @_ and $c->setup_finished );
 982
 983     $c->$orig(@_);
 984 };
 985
 986 =head2 $c->log
 987
 988 Returns the logging object instance. Unless it is already set, Catalyst
 989 sets this up with a L<Catalyst::Log> object. To use your own log class,
 990 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 991 C<< __PACKAGE__->setup >>.
 992
 993  __PACKAGE__->log( MyLogger->new );
 994  __PACKAGE__->setup;
 995
 996 And later:
 997
 998     $c->log->info( 'Now logging with my own logger!' );
 999
1000 Your log class should implement the methods described in
1001 L<Catalyst::Log>.
1002
1003
1004 =head2 $c->debug
1005
1006 Returns 1 if debug mode is enabled, 0 otherwise.
1007
1008 You can enable debug mode in several ways:
1009
1010 =over
1011
1012 =item By calling myapp_server.pl with the -d flag
1013
1014 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1015
1016 =item The -Debug option in your MyApp.pm
1017
1018 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1019
1020 =back
1021
1022 The first three also set the log level to 'debug'.
1023
1024 Calling C<< $c->debug(1) >> has no effect.
1025
1026 =cut
1027
1028 sub debug { 0 }
1029
1030 =head2 $c->dispatcher
1031
1032 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1033
1034 =head2 $c->engine
1035
1036 Returns the engine instance. See L<Catalyst::Engine>.
1037
1038
1039 =head2 UTILITY METHODS
1040
1041 =head2 $c->path_to(@path)
1042
1043 Merges C<@path> with C<< $c->config->{home} >> and returns a
1044 L<Path::Class::Dir> object. Note you can usually use this object as
1045 a filename, but sometimes you will have to explicitly stringify it
1046 yourself by calling the C<< ->stringify >> method.
1047
1048 For example:
1049
1050     $c->path_to( 'db', 'sqlite.db' );
1051
1052 =cut
1053
1054 sub path_to {
1055     my ( $c, @path ) = @_;
1056     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1057     if ( -d $path ) { return $path }
1058     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1059 }
1060
1061 sub plugin {
1062     my ( $class, $name, $plugin, @args ) = @_;
1063
1064     # See block comment in t/unit_core_plugin.t
1065     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1066
1067     $class->_register_plugin( $plugin, 1 );
1068
1069     eval { $plugin->import };
1070     $class->mk_classdata($name);
1071     my $obj;
1072     eval { $obj = $plugin->new(@args) };
1073
1074     if ($@) {
1075         Catalyst::Exception->throw( message =>
1076               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1077     }
1078
1079     $class->$name($obj);
1080     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1081       if $class->debug;
1082 }
1083
1084 =head2 MyApp->setup
1085
1086 Initializes the dispatcher and engine, loads any plugins, and loads the
1087 model, view, and controller components. You may also specify an array
1088 of plugins to load here, if you choose to not load them in the C<use
1089 Catalyst> line.
1090
1091     MyApp->setup;
1092     MyApp->setup( qw/-Debug/ );
1093
1094 B<Note:> You B<should not> wrap this method with method modifiers
1095 or bad things will happen - wrap the C<setup_finalize> method instead.
1096
1097 =cut
1098
1099 sub setup {
1100     my ( $class, @arguments ) = @_;
1101     croak('Running setup more than once')
1102         if ( $class->setup_finished );
1103
1104     unless ( $class->isa('Catalyst') ) {
1105
1106         Catalyst::Exception->throw(
1107             message => qq/'$class' does not inherit from Catalyst/ );
1108     }
1109
1110     if ( $class->arguments ) {
1111         @arguments = ( @arguments, @{ $class->arguments } );
1112     }
1113
1114     # Process options
1115     my $flags = {};
1116
1117     foreach (@arguments) {
1118
1119         if (/^-Debug$/) {
1120             $flags->{log} =
1121               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1122         }
1123         elsif (/^-(\w+)=?(.*)$/) {
1124             $flags->{ lc $1 } = $2;
1125         }
1126         else {
1127             push @{ $flags->{plugins} }, $_;
1128         }
1129     }
1130
1131     $class->setup_home( delete $flags->{home} );
1132
1133     $class->setup_log( delete $flags->{log} );
1134     $class->setup_plugins( delete $flags->{plugins} );
1135
1136     $class->setup_data_handlers();
1137     $class->setup_dispatcher( delete $flags->{dispatcher} );
1138     if (my $engine = delete $flags->{engine}) {
1139         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1140     }
1141     $class->setup_engine();
1142     $class->setup_stats( delete $flags->{stats} );
1143
1144     for my $flag ( sort keys %{$flags} ) {
1145
1146         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1147             &$code( $class, delete $flags->{$flag} );
1148         }
1149         else {
1150             $class->log->warn(qq/Unknown flag "$flag"/);
1151         }
1152     }
1153
1154     eval { require Catalyst::Devel; };
1155     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1156         $class->log->warn(<<"EOF");
1157 You are running an old script!
1158
1159   Please update by running (this will overwrite existing files):
1160     catalyst.pl -force -scripts $class
1161
1162   or (this will not overwrite existing files):
1163     catalyst.pl -scripts $class
1164
1165 EOF
1166     }
1167
1168     # Call plugins setup, this is stupid and evil.
1169     # Also screws C3 badly on 5.10, hack to avoid.
1170     {
1171         no warnings qw/redefine/;
1172         local *setup = sub { };
1173         $class->setup unless $Catalyst::__AM_RESTARTING;
1174     }
1175
1176     $class->setup_middleware();
1177
1178     # Initialize our data structure
1179     $class->components( {} );
1180
1181     $class->setup_components;
1182
1183     if ( $class->debug ) {
1184         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1185
1186         if (@plugins) {
1187             my $column_width = Catalyst::Utils::term_width() - 6;
1188             my $t = Text::SimpleTable->new($column_width);
1189             $t->row($_) for @plugins;
1190             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1191         }
1192
1193         my @middleware = map {
1194           ref $_ eq 'CODE' ?
1195             "Inline Coderef" :
1196               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1197                 || '')  } $class->registered_middlewares;
1198
1199         if (@middleware) {
1200             my $column_width = Catalyst::Utils::term_width() - 6;
1201             my $t = Text::SimpleTable->new($column_width);
1202             $t->row($_) for @middleware;
1203             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1204         }
1205
1206         my %dh = $class->registered_data_handlers;
1207         if (my @data_handlers = keys %dh) {
1208             my $column_width = Catalyst::Utils::term_width() - 6;
1209             my $t = Text::SimpleTable->new($column_width);
1210             $t->row($_) for @data_handlers;
1211             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1212         }
1213
1214         my $dispatcher = $class->dispatcher;
1215         my $engine     = $class->engine;
1216         my $home       = $class->config->{home};
1217
1218         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1219         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1220
1221         $home
1222           ? ( -d $home )
1223           ? $class->log->debug(qq/Found home "$home"/)
1224           : $class->log->debug(qq/Home "$home" doesn't exist/)
1225           : $class->log->debug(q/Couldn't find home/);
1226
1227         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1228         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1229         for my $comp ( sort keys %{ $class->components } ) {
1230             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1231             $t->row( $comp, $type );
1232         }
1233         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1234           if ( keys %{ $class->components } );
1235     }
1236
1237     # Add our self to components, since we are also a component
1238     if( $class->isa('Catalyst::Controller') ){
1239       $class->components->{$class} = $class;
1240     }
1241
1242     $class->setup_actions;
1243
1244     if ( $class->debug ) {
1245         my $name = $class->config->{name} || 'Application';
1246         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1247     }
1248
1249     if ($class->config->{case_sensitive}) {
1250         $class->log->warn($class . "->config->{case_sensitive} is set.");
1251         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1252     }
1253
1254     $class->setup_finalize;
1255
1256     # Turn autoflush back off once setup is finished.
1257     # TODO: this is being done purely for Static::Simple (legacy API), and has been suggested by
1258     # mst to be removed and require/update Static::Simple to set this flag itself
1259     $class->log->autoflush(0) if ($class->log->can('autoflush'));
1260
1261     return $class || 1; # Just in case someone named their Application 0...
1262 }
1263
1264 =head2 $app->setup_finalize
1265
1266 A hook to attach modifiers to. This method does not do anything except set the
1267 C<setup_finished> accessor.
1268
1269 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1270
1271 Example:
1272
1273     after setup_finalize => sub {
1274         my $app = shift;
1275
1276         ## do stuff here..
1277     };
1278
1279 =cut
1280
1281 sub setup_finalize {
1282     my ($class) = @_;
1283     $class->setup_finished(1);
1284 }
1285
1286 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1287
1288 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1289
1290 Constructs an absolute L<URI> object based on the application root, the
1291 provided path, and the additional arguments and query parameters provided.
1292 When used as a string, provides a textual URI.  If you need more flexibility
1293 than this (i.e. the option to provide relative URIs etc.) see
1294 L<Catalyst::Plugin::SmartURI>.
1295
1296 If no arguments are provided, the URI for the current action is returned.
1297 To return the current action and also provide @args, use
1298 C<< $c->uri_for( $c->action, @args ) >>.
1299
1300 If the first argument is a string, it is taken as a public URI path relative
1301 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1302 relative to the application root (if it does). It is then merged with
1303 C<< $c->request->base >>; any C<@args> are appended as additional path
1304 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1305
1306 If the first argument is a L<Catalyst::Action> it represents an action which
1307 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1308 optional C<\@captures> argument (an arrayref) allows passing the captured
1309 variables that are needed to fill in the paths of Chained and Regex actions;
1310 once the path is resolved, C<uri_for> continues as though a path was
1311 provided, appending any arguments or parameters and creating an absolute
1312 URI.
1313
1314 The captures for the current request can be found in
1315 C<< $c->request->captures >>, and actions can be resolved using
1316 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1317 path, use C<< $c->uri_for_action >> instead.
1318
1319   # Equivalent to $c->req->uri
1320   $c->uri_for($c->action, $c->req->captures,
1321       @{ $c->req->args }, $c->req->params);
1322
1323   # For the Foo action in the Bar controller
1324   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1325
1326   # Path to a static resource
1327   $c->uri_for('/static/images/logo.png');
1328
1329 =cut
1330
1331 sub uri_for {
1332     my ( $c, $path, @args ) = @_;
1333
1334     if ( $path->$_isa('Catalyst::Controller') ) {
1335         $path = $path->path_prefix;
1336         $path =~ s{/+\z}{};
1337         $path .= '/';
1338     }
1339
1340     undef($path) if (defined $path && $path eq '');
1341
1342     my $params =
1343       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1344
1345     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1346     foreach my $arg (@args) {
1347         utf8::encode($arg) if utf8::is_utf8($arg);
1348         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1349     }
1350
1351     if ( $path->$_isa('Catalyst::Action') ) { # action object
1352         s|/|%2F|g for @args;
1353         my $captures = [ map { s|/|%2F|g; $_; }
1354                         ( scalar @args && ref $args[0] eq 'ARRAY'
1355                          ? @{ shift(@args) }
1356                          : ()) ];
1357
1358         foreach my $capture (@$captures) {
1359             utf8::encode($capture) if utf8::is_utf8($capture);
1360             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1361         }
1362
1363         my $action = $path;
1364         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1365         if( !@args && $action->number_of_args ) {
1366             my $expanded_action = $c->dispatcher->expand_action( $action );
1367
1368             my $num_captures = $expanded_action->number_of_captures;
1369             unshift @args, splice @$captures, $num_captures;
1370         }
1371
1372        $path = $c->dispatcher->uri_for_action($action, $captures);
1373         if (not defined $path) {
1374             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1375                 if $c->debug;
1376             return undef;
1377         }
1378         $path = '/' if $path eq '';
1379     }
1380
1381     unshift(@args, $path);
1382
1383     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1384         my $namespace = $c->namespace;
1385         if (defined $path) { # cheesy hack to handle path '../foo'
1386            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1387         }
1388         unshift(@args, $namespace || '');
1389     }
1390
1391     # join args with '/', or a blank string
1392     my $args = join('/', grep { defined($_) } @args);
1393     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1394     $args =~ s!^/+!!;
1395
1396     my ($base, $class) = ('/', 'URI::_generic');
1397     if(blessed($c)) {
1398       $base = $c->req->base;
1399       $class = ref($base);
1400       $base =~ s{(?<!/)$}{/};
1401     }
1402
1403     my $query = '';
1404
1405     if (my @keys = keys %$params) {
1406       # somewhat lifted from URI::_query's query_form
1407       $query = '?'.join('&', map {
1408           my $val = $params->{$_};
1409           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1410           s/ /+/g;
1411           my $key = $_;
1412           $val = '' unless defined $val;
1413           (map {
1414               my $param = "$_";
1415               utf8::encode( $param ) if utf8::is_utf8($param);
1416               # using the URI::Escape pattern here so utf8 chars survive
1417               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1418               $param =~ s/ /+/g;
1419               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1420       } @keys);
1421     }
1422
1423     my $res = bless(\"${base}${args}${query}", $class);
1424     $res;
1425 }
1426
1427 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1428
1429 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1430
1431 =over
1432
1433 =item $path
1434
1435 A private path to the Catalyst action you want to create a URI for.
1436
1437 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1438 >> and passing the resulting C<$action> and the remaining arguments to C<<
1439 $c->uri_for >>.
1440
1441 You can also pass in a Catalyst::Action object, in which case it is passed to
1442 C<< $c->uri_for >>.
1443
1444 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1445
1446 For example, if the action looks like:
1447
1448  package MyApp::Controller::Users;
1449
1450  sub lst : Path('the-list') {}
1451
1452 You can use:
1453
1454  $c->uri_for_action('/users/lst')
1455
1456 and it will create the URI /users/the-list.
1457
1458 =item \@captures_and_args?
1459
1460 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1461 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1462 to interpolate all the parameters in the URI.
1463
1464 =item @args?
1465
1466 Optional list of extra arguments - can be supplied in the
1467 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1468 code.
1469
1470 Your action can have zero, a fixed or a variable number of args (e.g.
1471 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1472
1473 =item \%query_values?
1474
1475 Optional array reference of query parameters to append. E.g.
1476
1477   { foo => 'bar' }
1478
1479 will generate
1480
1481   /rest/of/your/uri?foo=bar
1482
1483 =back
1484
1485 =cut
1486
1487 sub uri_for_action {
1488     my ( $c, $path, @args ) = @_;
1489     my $action = blessed($path)
1490       ? $path
1491       : $c->dispatcher->get_action_by_path($path);
1492     unless (defined $action) {
1493       croak "Can't find action for path '$path'";
1494     }
1495     return $c->uri_for( $action, @args );
1496 }
1497
1498 =head2 $c->welcome_message
1499
1500 Returns the Catalyst welcome HTML page.
1501
1502 =cut
1503
1504 sub welcome_message {
1505     my $c      = shift;
1506     my $name   = $c->config->{name};
1507     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1508     my $prefix = Catalyst::Utils::appprefix( ref $c );
1509     $c->response->content_type('text/html; charset=utf-8');
1510     return <<"EOF";
1511 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1512     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1513 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1514     <head>
1515     <meta http-equiv="Content-Language" content="en" />
1516     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1517         <title>$name on Catalyst $VERSION</title>
1518         <style type="text/css">
1519             body {
1520                 color: #000;
1521                 background-color: #eee;
1522             }
1523             div#content {
1524                 width: 640px;
1525                 margin-left: auto;
1526                 margin-right: auto;
1527                 margin-top: 10px;
1528                 margin-bottom: 10px;
1529                 text-align: left;
1530                 background-color: #ccc;
1531                 border: 1px solid #aaa;
1532             }
1533             p, h1, h2 {
1534                 margin-left: 20px;
1535                 margin-right: 20px;
1536                 font-family: verdana, tahoma, sans-serif;
1537             }
1538             a {
1539                 font-family: verdana, tahoma, sans-serif;
1540             }
1541             :link, :visited {
1542                     text-decoration: none;
1543                     color: #b00;
1544                     border-bottom: 1px dotted #bbb;
1545             }
1546             :link:hover, :visited:hover {
1547                     color: #555;
1548             }
1549             div#topbar {
1550                 margin: 0px;
1551             }
1552             pre {
1553                 margin: 10px;
1554                 padding: 8px;
1555             }
1556             div#answers {
1557                 padding: 8px;
1558                 margin: 10px;
1559                 background-color: #fff;
1560                 border: 1px solid #aaa;
1561             }
1562             h1 {
1563                 font-size: 0.9em;
1564                 font-weight: normal;
1565                 text-align: center;
1566             }
1567             h2 {
1568                 font-size: 1.0em;
1569             }
1570             p {
1571                 font-size: 0.9em;
1572             }
1573             p img {
1574                 float: right;
1575                 margin-left: 10px;
1576             }
1577             span#appname {
1578                 font-weight: bold;
1579                 font-size: 1.6em;
1580             }
1581         </style>
1582     </head>
1583     <body>
1584         <div id="content">
1585             <div id="topbar">
1586                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1587                     $VERSION</h1>
1588              </div>
1589              <div id="answers">
1590                  <p>
1591                  <img src="$logo" alt="Catalyst Logo" />
1592                  </p>
1593                  <p>Welcome to the  world of Catalyst.
1594                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1595                     framework will make web development something you had
1596                     never expected it to be: Fun, rewarding, and quick.</p>
1597                  <h2>What to do now?</h2>
1598                  <p>That really depends  on what <b>you</b> want to do.
1599                     We do, however, provide you with a few starting points.</p>
1600                  <p>If you want to jump right into web development with Catalyst
1601                     you might want to start with a tutorial.</p>
1602 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1603 </pre>
1604 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1605 <pre>
1606 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1607 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1608 </code></pre>
1609                  <h2>What to do next?</h2>
1610                  <p>Next it's time to write an actual application. Use the
1611                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1612                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1613                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1614                     they can save you a lot of work.</p>
1615                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1616                     <p>Also, be sure to check out the vast and growing
1617                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1618                     you are likely to find what you need there.
1619                     </p>
1620
1621                  <h2>Need help?</h2>
1622                  <p>Catalyst has a very active community. Here are the main places to
1623                     get in touch with us.</p>
1624                  <ul>
1625                      <li>
1626                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1627                      </li>
1628                      <li>
1629                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1630                      </li>
1631                      <li>
1632                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1633                      </li>
1634                  </ul>
1635                  <h2>In conclusion</h2>
1636                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1637                     as we enjoyed making it. Please contact us if you have ideas
1638                     for improvement or other feedback.</p>
1639              </div>
1640          </div>
1641     </body>
1642 </html>
1643 EOF
1644 }
1645
1646 =head2 run_options
1647
1648 Contains a hash of options passed from the application script, including
1649 the original ARGV the script received, the processed values from that
1650 ARGV and any extra arguments to the script which were not processed.
1651
1652 This can be used to add custom options to your application's scripts
1653 and setup your application differently depending on the values of these
1654 options.
1655
1656 =head1 INTERNAL METHODS
1657
1658 These methods are not meant to be used by end users.
1659
1660 =head2 $c->components
1661
1662 Returns a hash of components.
1663
1664 =head2 $c->context_class
1665
1666 Returns or sets the context class.
1667
1668 =head2 $c->counter
1669
1670 Returns a hashref containing coderefs and execution counts (needed for
1671 deep recursion detection).
1672
1673 =head2 $c->depth
1674
1675 Returns the number of actions on the current internal execution stack.
1676
1677 =head2 $c->dispatch
1678
1679 Dispatches a request to actions.
1680
1681 =cut
1682
1683 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1684
1685 =head2 $c->dispatcher_class
1686
1687 Returns or sets the dispatcher class.
1688
1689 =head2 $c->dump_these
1690
1691 Returns a list of 2-element array references (name, structure) pairs
1692 that will be dumped on the error page in debug mode.
1693
1694 =cut
1695
1696 sub dump_these {
1697     my $c = shift;
1698     [ Request => $c->req ],
1699     [ Response => $c->res ],
1700     [ Stash => $c->stash ],
1701     [ Config => $c->config ];
1702 }
1703
1704 =head2 $c->engine_class
1705
1706 Returns or sets the engine class.
1707
1708 =head2 $c->execute( $class, $coderef )
1709
1710 Execute a coderef in given class and catch exceptions. Errors are available
1711 via $c->error.
1712
1713 =cut
1714
1715 sub execute {
1716     my ( $c, $class, $code ) = @_;
1717     $class = $c->component($class) || $class;
1718     $c->state(0);
1719
1720     if ( $c->depth >= $RECURSION ) {
1721         my $action = $code->reverse();
1722         $action = "/$action" unless $action =~ /->/;
1723         my $error = qq/Deep recursion detected calling "${action}"/;
1724         $c->log->error($error);
1725         $c->error($error);
1726         $c->state(0);
1727         return $c->state;
1728     }
1729
1730     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1731
1732     push( @{ $c->stack }, $code );
1733
1734     no warnings 'recursion';
1735     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1736     #      I have no idea how, ergo $ret (which appears to fix the issue)
1737     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1738
1739     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1740
1741     my $last = pop( @{ $c->stack } );
1742
1743     if ( my $error = $@ ) {
1744         #rethow if this can be handled by middleware
1745         if(blessed $error && ($error->can('as_psgi') || $error->can('code'))) {
1746             $error->can('rethrow') ? $error->rethrow : croak $error;
1747         }
1748         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1749             $error->rethrow if $c->depth > 1;
1750         }
1751         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1752             $error->rethrow if $c->depth > 0;
1753         }
1754         else {
1755             unless ( ref $error ) {
1756                 no warnings 'uninitialized';
1757                 chomp $error;
1758                 my $class = $last->class;
1759                 my $name  = $last->name;
1760                 $error = qq/Caught exception in $class->$name "$error"/;
1761             }
1762             $c->error($error);
1763         }
1764         $c->state(0);
1765     }
1766     return $c->state;
1767 }
1768
1769 sub _stats_start_execute {
1770     my ( $c, $code ) = @_;
1771     my $appclass = ref($c) || $c;
1772     return if ( ( $code->name =~ /^_.*/ )
1773         && ( !$appclass->config->{show_internal_actions} ) );
1774
1775     my $action_name = $code->reverse();
1776     $c->counter->{$action_name}++;
1777
1778     my $action = $action_name;
1779     $action = "/$action" unless $action =~ /->/;
1780
1781     # determine if the call was the result of a forward
1782     # this is done by walking up the call stack and looking for a calling
1783     # sub of Catalyst::forward before the eval
1784     my $callsub = q{};
1785     for my $index ( 2 .. 11 ) {
1786         last
1787         if ( ( caller($index) )[0] eq 'Catalyst'
1788             && ( caller($index) )[3] eq '(eval)' );
1789
1790         if ( ( caller($index) )[3] =~ /forward$/ ) {
1791             $callsub = ( caller($index) )[3];
1792             $action  = "-> $action";
1793             last;
1794         }
1795     }
1796
1797     my $uid = $action_name . $c->counter->{$action_name};
1798
1799     # is this a root-level call or a forwarded call?
1800     if ( $callsub =~ /forward$/ ) {
1801         my $parent = $c->stack->[-1];
1802
1803         # forward, locate the caller
1804         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1805             $c->stats->profile(
1806                 begin  => $action,
1807                 parent => "$parent" . $c->counter->{"$parent"},
1808                 uid    => $uid,
1809             );
1810         }
1811         else {
1812
1813             # forward with no caller may come from a plugin
1814             $c->stats->profile(
1815                 begin => $action,
1816                 uid   => $uid,
1817             );
1818         }
1819     }
1820     else {
1821
1822         # root-level call
1823         $c->stats->profile(
1824             begin => $action,
1825             uid   => $uid,
1826         );
1827     }
1828     return $action;
1829
1830 }
1831
1832 sub _stats_finish_execute {
1833     my ( $c, $info ) = @_;
1834     $c->stats->profile( end => $info );
1835 }
1836
1837 =head2 $c->finalize
1838
1839 Finalizes the request.
1840
1841 =cut
1842
1843 sub finalize {
1844     my $c = shift;
1845
1846     for my $error ( @{ $c->error } ) {
1847         $c->log->error($error);
1848     }
1849
1850     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1851     # stuff like cometd and websockets
1852
1853     if($c->request->_has_io_fh) {
1854       $c->log_response;
1855       return;
1856     }
1857
1858     # Allow engine to handle finalize flow (for POE)
1859     my $engine = $c->engine;
1860     if ( my $code = $engine->can('finalize') ) {
1861         $engine->$code($c);
1862     }
1863     else {
1864
1865         $c->finalize_uploads;
1866
1867         # Error
1868         if ( $#{ $c->error } >= 0 ) {
1869             $c->finalize_error;
1870         }
1871
1872         $c->finalize_headers unless $c->response->finalized_headers;
1873
1874         $c->finalize_body;
1875     }
1876
1877     $c->log_response;
1878
1879     if ($c->use_stats) {
1880         my $elapsed = $c->stats->elapsed;
1881         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1882         $c->log->info(
1883             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1884     }
1885
1886     return $c->response->status;
1887 }
1888
1889 =head2 $c->finalize_body
1890
1891 Finalizes body.
1892
1893 =cut
1894
1895 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1896
1897 =head2 $c->finalize_cookies
1898
1899 Finalizes cookies.
1900
1901 =cut
1902
1903 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1904
1905 =head2 $c->finalize_error
1906
1907 Finalizes error.  If there is only one error in L</error> and it is an object that
1908 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
1909 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
1910 return the default error page (production mode).
1911
1912 =cut
1913
1914 sub finalize_error {
1915     my $c = shift;
1916     if($#{$c->error} > 0) {
1917         $c->engine->finalize_error( $c, @_ );
1918     } else {
1919         my ($error) = @{$c->error};
1920         if(
1921           blessed $error &&
1922           ($error->can('as_psgi') || $error->can('code'))
1923         ) {
1924             # In the case where the error 'knows what it wants', becauses its PSGI
1925             # aware, just rethow and let middleware catch it
1926             $error->can('rethrow') ? $error->rethrow : croak $error;
1927             croak $error;
1928         } else {
1929             $c->engine->finalize_error( $c, @_ )
1930         }
1931     }
1932 }
1933
1934 =head2 $c->finalize_headers
1935
1936 Finalizes headers.
1937
1938 =cut
1939
1940 sub finalize_headers {
1941     my $c = shift;
1942
1943     my $response = $c->response; #accessor calls can add up?
1944
1945     # Check if we already finalized headers
1946     return if $response->finalized_headers;
1947
1948     # Handle redirects
1949     if ( my $location = $response->redirect ) {
1950         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1951         $response->header( Location => $location );
1952     }
1953
1954     # Remove incorrectly added body and content related meta data when returning
1955     # an information response, or a response the is required to not include a body
1956
1957     $c->finalize_cookies;
1958
1959     $c->response->finalize_headers();
1960
1961     # Done
1962     $response->finalized_headers(1);
1963 }
1964
1965 =head2 $c->finalize_output
1966
1967 An alias for finalize_body.
1968
1969 =head2 $c->finalize_read
1970
1971 Finalizes the input after reading is complete.
1972
1973 =cut
1974
1975 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1976
1977 =head2 $c->finalize_uploads
1978
1979 Finalizes uploads. Cleans up any temporary files.
1980
1981 =cut
1982
1983 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1984
1985 =head2 $c->get_action( $action, $namespace )
1986
1987 Gets an action in a given namespace.
1988
1989 =cut
1990
1991 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1992
1993 =head2 $c->get_actions( $action, $namespace )
1994
1995 Gets all actions of a given name in a namespace and all parent
1996 namespaces.
1997
1998 =cut
1999
2000 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2001
2002 =head2 $app->handle_request( @arguments )
2003
2004 Called to handle each HTTP request.
2005
2006 =cut
2007
2008 sub handle_request {
2009     my ( $class, @arguments ) = @_;
2010
2011     # Always expect worst case!
2012     my $status = -1;
2013     try {
2014         if ($class->debug) {
2015             my $secs = time - $START || 1;
2016             my $av = sprintf '%.3f', $COUNT / $secs;
2017             my $time = localtime time;
2018             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2019         }
2020
2021         my $c = $class->prepare(@arguments);
2022         $c->dispatch;
2023         $status = $c->finalize;
2024     } catch {
2025         #rethow if this can be handled by middleware
2026         if(blessed $_ && ($_->can('as_psgi') || $_->can('code'))) {
2027             $_->can('rethrow') ? $_->rethrow : croak $_;
2028         }
2029         chomp(my $error = $_);
2030         $class->log->error(qq/Caught exception in engine "$error"/);
2031     };
2032
2033     $COUNT++;
2034
2035     if(my $coderef = $class->log->can('_flush')){
2036         $class->log->$coderef();
2037     }
2038     return $status;
2039 }
2040
2041 =head2 $class->prepare( @arguments )
2042
2043 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2044 etc.).
2045
2046 =cut
2047
2048 has _uploadtmp => (
2049     is => 'ro',
2050     predicate => '_has_uploadtmp',
2051 );
2052
2053 sub prepare {
2054     my ( $class, @arguments ) = @_;
2055
2056     # XXX
2057     # After the app/ctxt split, this should become an attribute based on something passed
2058     # into the application.
2059     $class->context_class( ref $class || $class ) unless $class->context_class;
2060
2061     my $uploadtmp = $class->config->{uploadtmp};
2062     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2063
2064     $c->response->_context($c);
2065
2066     #surely this is not the most efficient way to do things...
2067     $c->stats($class->stats_class->new)->enable($c->use_stats);
2068     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2069         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2070     }
2071
2072     try {
2073         # Allow engine to direct the prepare flow (for POE)
2074         if ( my $prepare = $c->engine->can('prepare') ) {
2075             $c->engine->$prepare( $c, @arguments );
2076         }
2077         else {
2078             $c->prepare_request(@arguments);
2079             $c->prepare_connection;
2080             $c->prepare_query_parameters;
2081             $c->prepare_headers; # Just hooks, no longer needed - they just
2082             $c->prepare_cookies; # cause the lazy attribute on req to build
2083             $c->prepare_path;
2084
2085             # Prepare the body for reading, either by prepare_body
2086             # or the user, if they are using $c->read
2087             $c->prepare_read;
2088
2089             # Parse the body unless the user wants it on-demand
2090             unless ( ref($c)->config->{parse_on_demand} ) {
2091                 $c->prepare_body;
2092             }
2093         }
2094         $c->prepare_action;
2095     }
2096     # VERY ugly and probably shouldn't rely on ->finalize actually working
2097     catch {
2098         # failed prepare is always due to an invalid request, right?
2099         $c->response->status(400);
2100         $c->response->content_type('text/plain');
2101         $c->response->body('Bad Request');
2102         # Note we call finalize and then die here, which escapes
2103         # finalize being called in the enclosing block..
2104         # It in fact couldn't be called, as we don't return $c..
2105         # This is a mess - but I'm unsure you can fix this without
2106         # breaking compat for people doing crazy things (we should set
2107         # the 400 and just return the ctx here IMO, letting finalize get called
2108         # above...
2109         $c->finalize;
2110         die $_;
2111     };
2112
2113     $c->log_request;
2114
2115     return $c;
2116 }
2117
2118 =head2 $c->prepare_action
2119
2120 Prepares action. See L<Catalyst::Dispatcher>.
2121
2122 =cut
2123
2124 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2125
2126 =head2 $c->prepare_body
2127
2128 Prepares message body.
2129
2130 =cut
2131
2132 sub prepare_body {
2133     my $c = shift;
2134
2135     return if $c->request->_has_body;
2136
2137     # Initialize on-demand data
2138     $c->engine->prepare_body( $c, @_ );
2139     $c->prepare_parameters;
2140     $c->prepare_uploads;
2141 }
2142
2143 =head2 $c->prepare_body_chunk( $chunk )
2144
2145 Prepares a chunk of data before sending it to L<HTTP::Body>.
2146
2147 See L<Catalyst::Engine>.
2148
2149 =cut
2150
2151 sub prepare_body_chunk {
2152     my $c = shift;
2153     $c->engine->prepare_body_chunk( $c, @_ );
2154 }
2155
2156 =head2 $c->prepare_body_parameters
2157
2158 Prepares body parameters.
2159
2160 =cut
2161
2162 sub prepare_body_parameters {
2163     my $c = shift;
2164     $c->engine->prepare_body_parameters( $c, @_ );
2165 }
2166
2167 =head2 $c->prepare_connection
2168
2169 Prepares connection.
2170
2171 =cut
2172
2173 sub prepare_connection {
2174     my $c = shift;
2175     # XXX - This is called on the engine (not the request) to maintain
2176     #       Engine::PSGI back compat.
2177     $c->engine->prepare_connection($c);
2178 }
2179
2180 =head2 $c->prepare_cookies
2181
2182 Prepares cookies by ensuring that the attribute on the request
2183 object has been built.
2184
2185 =cut
2186
2187 sub prepare_cookies { my $c = shift; $c->request->cookies }
2188
2189 =head2 $c->prepare_headers
2190
2191 Prepares request headers by ensuring that the attribute on the request
2192 object has been built.
2193
2194 =cut
2195
2196 sub prepare_headers { my $c = shift; $c->request->headers }
2197
2198 =head2 $c->prepare_parameters
2199
2200 Prepares parameters.
2201
2202 =cut
2203
2204 sub prepare_parameters {
2205     my $c = shift;
2206     $c->prepare_body_parameters;
2207     $c->engine->prepare_parameters( $c, @_ );
2208 }
2209
2210 =head2 $c->prepare_path
2211
2212 Prepares path and base.
2213
2214 =cut
2215
2216 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2217
2218 =head2 $c->prepare_query_parameters
2219
2220 Prepares query parameters.
2221
2222 =cut
2223
2224 sub prepare_query_parameters {
2225     my $c = shift;
2226
2227     $c->engine->prepare_query_parameters( $c, @_ );
2228 }
2229
2230 =head2 $c->log_request
2231
2232 Writes information about the request to the debug logs.  This includes:
2233
2234 =over 4
2235
2236 =item * Request method, path, and remote IP address
2237
2238 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2239
2240 =item * Request parameters
2241
2242 =item * File uploads
2243
2244 =back
2245
2246 =cut
2247
2248 sub log_request {
2249     my $c = shift;
2250
2251     return unless $c->debug;
2252
2253     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2254     my $request = $dump->[1];
2255
2256     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2257     $method ||= '';
2258     $path = '/' unless length $path;
2259     $address ||= '';
2260     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2261
2262     $c->log_request_headers($request->headers);
2263
2264     if ( my $keywords = $request->query_keywords ) {
2265         $c->log->debug("Query keywords are: $keywords");
2266     }
2267
2268     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2269
2270     $c->log_request_uploads($request);
2271 }
2272
2273 =head2 $c->log_response
2274
2275 Writes information about the response to the debug logs by calling
2276 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2277
2278 =cut
2279
2280 sub log_response {
2281     my $c = shift;
2282
2283     return unless $c->debug;
2284
2285     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2286     my $response = $dump->[1];
2287
2288     $c->log_response_status_line($response);
2289     $c->log_response_headers($response->headers);
2290 }
2291
2292 =head2 $c->log_response_status_line($response)
2293
2294 Writes one line of information about the response to the debug logs.  This includes:
2295
2296 =over 4
2297
2298 =item * Response status code
2299
2300 =item * Content-Type header (if present)
2301
2302 =item * Content-Length header (if present)
2303
2304 =back
2305
2306 =cut
2307
2308 sub log_response_status_line {
2309     my ($c, $response) = @_;
2310
2311     $c->log->debug(
2312         sprintf(
2313             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2314             $response->status                            || 'unknown',
2315             $response->headers->header('Content-Type')   || 'unknown',
2316             $response->headers->header('Content-Length') || 'unknown'
2317         )
2318     );
2319 }
2320
2321 =head2 $c->log_response_headers($headers);
2322
2323 Hook method which can be wrapped by plugins to log the response headers.
2324 No-op in the default implementation.
2325
2326 =cut
2327
2328 sub log_response_headers {}
2329
2330 =head2 $c->log_request_parameters( query => {}, body => {} )
2331
2332 Logs request parameters to debug logs
2333
2334 =cut
2335
2336 sub log_request_parameters {
2337     my $c          = shift;
2338     my %all_params = @_;
2339
2340     return unless $c->debug;
2341
2342     my $column_width = Catalyst::Utils::term_width() - 44;
2343     foreach my $type (qw(query body)) {
2344         my $params = $all_params{$type};
2345         next if ! keys %$params;
2346         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2347         for my $key ( sort keys %$params ) {
2348             my $param = $params->{$key};
2349             my $value = defined($param) ? $param : '';
2350             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2351         }
2352         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2353     }
2354 }
2355
2356 =head2 $c->log_request_uploads
2357
2358 Logs file uploads included in the request to the debug logs.
2359 The parameter name, filename, file type, and file size are all included in
2360 the debug logs.
2361
2362 =cut
2363
2364 sub log_request_uploads {
2365     my $c = shift;
2366     my $request = shift;
2367     return unless $c->debug;
2368     my $uploads = $request->uploads;
2369     if ( keys %$uploads ) {
2370         my $t = Text::SimpleTable->new(
2371             [ 12, 'Parameter' ],
2372             [ 26, 'Filename' ],
2373             [ 18, 'Type' ],
2374             [ 9,  'Size' ]
2375         );
2376         for my $key ( sort keys %$uploads ) {
2377             my $upload = $uploads->{$key};
2378             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2379                 $t->row( $key, $u->filename, $u->type, $u->size );
2380             }
2381         }
2382         $c->log->debug( "File Uploads are:\n" . $t->draw );
2383     }
2384 }
2385
2386 =head2 $c->log_request_headers($headers);
2387
2388 Hook method which can be wrapped by plugins to log the request headers.
2389 No-op in the default implementation.
2390
2391 =cut
2392
2393 sub log_request_headers {}
2394
2395 =head2 $c->log_headers($type => $headers)
2396
2397 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2398
2399 =cut
2400
2401 sub log_headers {
2402     my $c       = shift;
2403     my $type    = shift;
2404     my $headers = shift;    # an HTTP::Headers instance
2405
2406     return unless $c->debug;
2407
2408     my $column_width = Catalyst::Utils::term_width() - 28;
2409     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2410     $headers->scan(
2411         sub {
2412             my ( $name, $value ) = @_;
2413             $t->row( $name, $value );
2414         }
2415     );
2416     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2417 }
2418
2419
2420 =head2 $c->prepare_read
2421
2422 Prepares the input for reading.
2423
2424 =cut
2425
2426 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2427
2428 =head2 $c->prepare_request
2429
2430 Prepares the engine request.
2431
2432 =cut
2433
2434 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2435
2436 =head2 $c->prepare_uploads
2437
2438 Prepares uploads.
2439
2440 =cut
2441
2442 sub prepare_uploads {
2443     my $c = shift;
2444
2445     $c->engine->prepare_uploads( $c, @_ );
2446 }
2447
2448 =head2 $c->prepare_write
2449
2450 Prepares the output for writing.
2451
2452 =cut
2453
2454 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2455
2456 =head2 $c->request_class
2457
2458 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2459
2460 =head2 $c->response_class
2461
2462 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2463
2464 =head2 $c->read( [$maxlength] )
2465
2466 Reads a chunk of data from the request body. This method is designed to
2467 be used in a while loop, reading C<$maxlength> bytes on every call.
2468 C<$maxlength> defaults to the size of the request if not specified.
2469
2470 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2471 directly.
2472
2473 Warning: If you use read(), Catalyst will not process the body,
2474 so you will not be able to access POST parameters or file uploads via
2475 $c->request.  You must handle all body parsing yourself.
2476
2477 =cut
2478
2479 sub read { my $c = shift; return $c->request->read( @_ ) }
2480
2481 =head2 $c->run
2482
2483 Starts the engine.
2484
2485 =cut
2486
2487 sub run {
2488   my $app = shift;
2489   $app->_make_immutable_if_needed;
2490   $app->engine_loader->needs_psgi_engine_compat_hack ?
2491     $app->engine->run($app, @_) :
2492       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2493 }
2494
2495 sub _make_immutable_if_needed {
2496     my $class = shift;
2497     my $meta = find_meta($class);
2498     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2499     if (
2500         $meta->is_immutable
2501         && ! { $meta->immutable_options }->{replace_constructor}
2502         && $isa_ca
2503     ) {
2504         warn("You made your application class ($class) immutable, "
2505             . "but did not inline the\nconstructor. "
2506             . "This will break catalyst, as your app \@ISA "
2507             . "Class::Accessor(::Fast)?\nPlease pass "
2508             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2509     }
2510     unless ($meta->is_immutable) {
2511         # XXX - FIXME warning here as you should make your app immutable yourself.
2512         $meta->make_immutable(
2513             replace_constructor => 1,
2514         );
2515     }
2516 }
2517
2518 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2519
2520 Sets an action in a given namespace.
2521
2522 =cut
2523
2524 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2525
2526 =head2 $c->setup_actions($component)
2527
2528 Sets up actions for a component.
2529
2530 =cut
2531
2532 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2533
2534 =head2 $c->setup_components
2535
2536 This method is called internally to set up the application's components.
2537
2538 It finds modules by calling the L<locate_components> method, expands them to
2539 package names with the L<expand_component_module> method, and then installs
2540 each component into the application.
2541
2542 The C<setup_components> config option is passed to both of the above methods.
2543
2544 Installation of each component is performed by the L<setup_component> method,
2545 below.
2546
2547 =cut
2548
2549 sub setup_components {
2550     my $class = shift;
2551
2552     my $config  = $class->config->{ setup_components };
2553
2554     my @comps = $class->locate_components($config);
2555     my %comps = map { $_ => 1 } @comps;
2556
2557     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2558     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2559         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2560     ) if $deprecatedcatalyst_component_names;
2561
2562     for my $component ( @comps ) {
2563
2564         # We pass ignore_loaded here so that overlay files for (e.g.)
2565         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2566         # we know M::P::O found a file on disk so this is safe
2567
2568         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2569     }
2570
2571     for my $component (@comps) {
2572         my $instance = $class->components->{ $component } = $class->setup_component($component);
2573         my @expanded_components = $instance->can('expand_modules')
2574             ? $instance->expand_modules( $component, $config )
2575             : $class->expand_component_module( $component, $config );
2576         for my $component (@expanded_components) {
2577             next if $comps{$component};
2578             $class->components->{ $component } = $class->setup_component($component);
2579         }
2580     }
2581 }
2582
2583 =head2 $c->locate_components( $setup_component_config )
2584
2585 This method is meant to provide a list of component modules that should be
2586 setup for the application.  By default, it will use L<Module::Pluggable>.
2587
2588 Specify a C<setup_components> config option to pass additional options directly
2589 to L<Module::Pluggable>. To add additional search paths, specify a key named
2590 C<search_extra> as an array reference. Items in the array beginning with C<::>
2591 will have the application class name prepended to them.
2592
2593 =cut
2594
2595 sub locate_components {
2596     my $class  = shift;
2597     my $config = shift;
2598
2599     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2600     my $extra   = delete $config->{ search_extra } || [];
2601
2602     push @paths, @$extra;
2603
2604     my $locator = Module::Pluggable::Object->new(
2605         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2606         %$config
2607     );
2608
2609     # XXX think about ditching this sort entirely
2610     my @comps = sort { length $a <=> length $b } $locator->plugins;
2611
2612     return @comps;
2613 }
2614
2615 =head2 $c->expand_component_module( $component, $setup_component_config )
2616
2617 Components found by C<locate_components> will be passed to this method, which
2618 is expected to return a list of component (package) names to be set up.
2619
2620 =cut
2621
2622 sub expand_component_module {
2623     my ($class, $module) = @_;
2624     return Devel::InnerPackage::list_packages( $module );
2625 }
2626
2627 =head2 $c->setup_component
2628
2629 =cut
2630
2631 sub setup_component {
2632     my( $class, $component ) = @_;
2633
2634     unless ( $component->can( 'COMPONENT' ) ) {
2635         return $component;
2636     }
2637
2638     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2639     my $config = $class->config->{ $suffix } || {};
2640     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2641     # methods also pass it. local to avoid pointlessly shitting in config
2642     # for the debug screen, as $component is already the key name.
2643     local $config->{catalyst_component_name} = $component;
2644
2645     my $instance = eval { $component->COMPONENT( $class, $config ); };
2646
2647     if ( my $error = $@ ) {
2648         chomp $error;
2649         Catalyst::Exception->throw(
2650             message => qq/Couldn't instantiate component "$component", "$error"/
2651         );
2652     }
2653
2654     unless (blessed $instance) {
2655         my $metaclass = Moose::Util::find_meta($component);
2656         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2657         my $component_method_from = $method_meta->associated_metaclass->name;
2658         my $value = defined($instance) ? $instance : 'undef';
2659         Catalyst::Exception->throw(
2660             message =>
2661             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2662         );
2663     }
2664     return $instance;
2665 }
2666
2667 =head2 $c->setup_dispatcher
2668
2669 Sets up dispatcher.
2670
2671 =cut
2672
2673 sub setup_dispatcher {
2674     my ( $class, $dispatcher ) = @_;
2675
2676     if ($dispatcher) {
2677         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2678     }
2679
2680     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2681         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2682     }
2683
2684     unless ($dispatcher) {
2685         $dispatcher = $class->dispatcher_class;
2686     }
2687
2688     load_class($dispatcher);
2689
2690     # dispatcher instance
2691     $class->dispatcher( $dispatcher->new );
2692 }
2693
2694 =head2 $c->setup_engine
2695
2696 Sets up engine.
2697
2698 =cut
2699
2700 sub engine_class {
2701     my ($class, $requested_engine) = @_;
2702
2703     if (!$class->engine_loader || $requested_engine) {
2704         $class->engine_loader(
2705             Catalyst::EngineLoader->new({
2706                 application_name => $class,
2707                 (defined $requested_engine
2708                      ? (catalyst_engine_class => $requested_engine) : ()),
2709             }),
2710         );
2711     }
2712
2713     $class->engine_loader->catalyst_engine_class;
2714 }
2715
2716 sub setup_engine {
2717     my ($class, $requested_engine) = @_;
2718
2719     my $engine = do {
2720         my $loader = $class->engine_loader;
2721
2722         if (!$loader || $requested_engine) {
2723             $loader = Catalyst::EngineLoader->new({
2724                 application_name => $class,
2725                 (defined $requested_engine
2726                      ? (requested_engine => $requested_engine) : ()),
2727             }),
2728
2729             $class->engine_loader($loader);
2730         }
2731
2732         $loader->catalyst_engine_class;
2733     };
2734
2735     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2736     return if $class->loading_psgi_file;
2737
2738     load_class($engine);
2739
2740     if ($ENV{MOD_PERL}) {
2741         my $apache = $class->engine_loader->auto;
2742
2743         my $meta = find_meta($class);
2744         my $was_immutable = $meta->is_immutable;
2745         my %immutable_options = $meta->immutable_options;
2746         $meta->make_mutable if $was_immutable;
2747
2748         $meta->add_method(handler => sub {
2749             my $r = shift;
2750             my $psgi_app = $class->_finalized_psgi_app;
2751             $apache->call_app($r, $psgi_app);
2752         });
2753
2754         $meta->make_immutable(%immutable_options) if $was_immutable;
2755     }
2756
2757     $class->engine( $engine->new );
2758
2759     return;
2760 }
2761
2762 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2763 ## build in server support (back compat support for pre psgi port behavior).
2764 ## This is so that we don't build a new psgi app for each request when using
2765 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2766
2767 sub _finalized_psgi_app {
2768     my ($app) = @_;
2769
2770     unless ($app->_psgi_app) {
2771         my $psgi_app = $app->_setup_psgi_app;
2772         $app->_psgi_app($psgi_app);
2773     }
2774
2775     return $app->_psgi_app;
2776 }
2777
2778 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2779 ## home directory and load that and return it (just assume it is doing the
2780 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2781 ## in default_middleware and return it ( this is for backward compatibility
2782 ## with pre psgi port behavior ).
2783
2784 sub _setup_psgi_app {
2785     my ($app) = @_;
2786
2787     for my $home (Path::Class::Dir->new($app->config->{home})) {
2788         my $psgi_file = $home->file(
2789             Catalyst::Utils::appprefix($app) . '.psgi',
2790         );
2791
2792         next unless -e $psgi_file;
2793
2794         # If $psgi_file calls ->setup_engine, it's doing so to load
2795         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2796         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2797         # anyway. So set a flag (ick) that tells setup_engine not to populate
2798         # $c->engine or do any other things we might regret.
2799
2800         $app->loading_psgi_file(1);
2801         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2802         $app->loading_psgi_file(0);
2803
2804         return $psgi_app
2805             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2806
2807         warn <<"EOW";
2808 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2809
2810 Its content has been ignored. Please consult the Catalyst::Upgrading
2811 documentation on how to upgrade from Catalyst::Engine::PSGI.
2812 EOW
2813     }
2814
2815     return $app->apply_default_middlewares($app->psgi_app);
2816 }
2817
2818 =head2 $c->apply_default_middlewares
2819
2820 Adds the following L<Plack> middlewares to your application, since they are
2821 useful and commonly needed:
2822
2823 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2824 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2825 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2826 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2827 applied since this middleware is smart enough to conditionally apply itself).
2828
2829 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2830 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2831 $ENV{SCRIPT_NAME}
2832
2833 =cut
2834
2835
2836 sub apply_default_middlewares {
2837     my ($app, $psgi_app) = @_;
2838
2839     $psgi_app = Plack::Middleware::Conditional->wrap(
2840         $psgi_app,
2841         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2842         condition => sub {
2843             my ($env) = @_;
2844             return if $app->config->{ignore_frontend_proxy};
2845             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2846                 || $app->config->{using_frontend_proxy};
2847         },
2848     );
2849
2850     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2851     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2852     $psgi_app = Plack::Middleware::Conditional->wrap(
2853         $psgi_app,
2854         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2855         condition => sub {
2856             my ($env) = @_;
2857             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2858             return unless $1 < 4.23;
2859             1;
2860         },
2861     );
2862
2863     # we're applying this unconditionally as the middleware itself already makes
2864     # sure it doesn't fuck things up if it's not running under one of the right
2865     # IIS versions
2866     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2867
2868     # And another IIS issue, this time with IIS7.
2869     $psgi_app = Plack::Middleware::Conditional->wrap(
2870         $psgi_app,
2871         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2872         condition => sub {
2873             my ($env) = @_;
2874             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2875         },
2876     );
2877
2878     return $psgi_app;
2879 }
2880
2881 =head2 $c->psgi_app
2882
2883 Returns a PSGI application code reference for the catalyst application
2884 C<$c>. This is the bare application without any middlewares
2885 applied. C<${myapp}.psgi> is not taken into account.
2886
2887 This is what you want to be using to retrieve the PSGI application code
2888 reference of your Catalyst application for use in F<.psgi> files.
2889
2890 =cut
2891
2892 sub psgi_app {
2893     my ($app) = @_;
2894     my $psgi = $app->engine->build_psgi_app($app);
2895     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
2896 }
2897
2898 =head2 $c->setup_home
2899
2900 Sets up the home directory.
2901
2902 =cut
2903
2904 sub setup_home {
2905     my ( $class, $home ) = @_;
2906
2907     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2908         $home = $env;
2909     }
2910
2911     $home ||= Catalyst::Utils::home($class);
2912
2913     if ($home) {
2914         #I remember recently being scolded for assigning config values like this
2915         $class->config->{home} ||= $home;
2916         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2917     }
2918 }
2919
2920 =head2 $c->setup_log
2921
2922 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2923 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2924 log to.
2925
2926 This method also installs a C<debug> method that returns a true value into the
2927 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2928 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2929
2930 Note that if the log has already been setup, by either a previous call to
2931 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2932 that this method won't actually set up the log object.
2933
2934 =cut
2935
2936 sub setup_log {
2937     my ( $class, $levels ) = @_;
2938
2939     $levels ||= '';
2940     $levels =~ s/^\s+//;
2941     $levels =~ s/\s+$//;
2942     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2943
2944     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2945     if ( defined $env_debug ) {
2946         $levels{debug} = 1 if $env_debug; # Ugly!
2947         delete($levels{debug}) unless $env_debug;
2948     }
2949
2950     unless ( $class->log ) {
2951         $class->log( Catalyst::Log->new(keys %levels) );
2952     }
2953
2954     # Turn on autoflush by default:
2955     $class->log->autoflush(1) if ($class->log->can('autoflush'));
2956
2957     if ( $levels{debug} ) {
2958         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2959         $class->log->debug('Debug messages enabled');
2960     }
2961 }
2962
2963 =head2 $c->setup_plugins
2964
2965 Sets up plugins.
2966
2967 =cut
2968
2969 =head2 $c->setup_stats
2970
2971 Sets up timing statistics class.
2972
2973 =cut
2974
2975 sub setup_stats {
2976     my ( $class, $stats ) = @_;
2977
2978     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2979
2980     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2981     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2982         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2983         $class->log->debug('Statistics enabled');
2984     }
2985 }
2986
2987
2988 =head2 $c->registered_plugins
2989
2990 Returns a sorted list of the plugins which have either been stated in the
2991 import list.
2992
2993 If passed a given plugin name, it will report a boolean value indicating
2994 whether or not that plugin is loaded.  A fully qualified name is required if
2995 the plugin name does not begin with C<Catalyst::Plugin::>.
2996
2997  if ($c->registered_plugins('Some::Plugin')) {
2998      ...
2999  }
3000
3001 =cut
3002
3003 {
3004
3005     sub registered_plugins {
3006         my $proto = shift;
3007         return sort keys %{ $proto->_plugins } unless @_;
3008         my $plugin = shift;
3009         return 1 if exists $proto->_plugins->{$plugin};
3010         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3011     }
3012
3013     sub _register_plugin {
3014         my ( $proto, $plugin, $instant ) = @_;
3015         my $class = ref $proto || $proto;
3016
3017         load_class( $plugin );
3018         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3019             if $plugin->isa( 'Catalyst::Component' );
3020         my $plugin_meta = Moose::Meta::Class->create($plugin);
3021         if (!$plugin_meta->has_method('new')
3022             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3023             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3024         }
3025         if (!$instant && !$proto->_plugins->{$plugin}) {
3026             my $meta = Class::MOP::get_metaclass_by_name($class);
3027             $meta->superclasses($plugin, $meta->superclasses);
3028         }
3029         $proto->_plugins->{$plugin} = 1;
3030         return $class;
3031     }
3032
3033     sub _default_plugins { return qw(Unicode::Encoding) }
3034
3035     sub setup_plugins {
3036         my ( $class, $plugins ) = @_;
3037
3038         $class->_plugins( {} ) unless $class->_plugins;
3039         $plugins = [ grep {
3040             m/Unicode::Encoding/ ? do {
3041                 $class->log->warn(
3042                     'Unicode::Encoding plugin is auto-applied,'
3043                     . ' please remove this from your appclass'
3044                     . ' and make sure to define "encoding" config'
3045                 );
3046                 unless (exists $class->config->{'encoding'}) {
3047                   $class->config->{'encoding'} = 'UTF-8';
3048                 }
3049                 () }
3050                 : $_
3051         } @$plugins ];
3052         push @$plugins, $class->_default_plugins;
3053         $plugins = Data::OptList::mkopt($plugins || []);
3054
3055         my @plugins = map {
3056             [ Catalyst::Utils::resolve_namespace(
3057                   $class . '::Plugin',
3058                   'Catalyst::Plugin', $_->[0]
3059               ),
3060               $_->[1],
3061             ]
3062          } @{ $plugins };
3063
3064         for my $plugin ( reverse @plugins ) {
3065             load_class($plugin->[0], $plugin->[1]);
3066             my $meta = find_meta($plugin->[0]);
3067             next if $meta && $meta->isa('Moose::Meta::Role');
3068
3069             $class->_register_plugin($plugin->[0]);
3070         }
3071
3072         my @roles =
3073             map  { $_->[0]->name, $_->[1] }
3074             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3075             map  { [find_meta($_->[0]), $_->[1]] }
3076             @plugins;
3077
3078         Moose::Util::apply_all_roles(
3079             $class => @roles
3080         ) if @roles;
3081     }
3082 }
3083
3084 =head2 registered_middlewares
3085
3086 Read only accessor that returns an array of all the middleware in the order
3087 that they were added (which is the REVERSE of the order they will be applied).
3088
3089 The values returned will be either instances of L<Plack::Middleware> or of a
3090 compatible interface, or a coderef, which is assumed to be inlined middleware
3091
3092 =head2 setup_middleware (?@middleware)
3093
3094 Read configuration information stored in configuration key C<psgi_middleware> or
3095 from passed @args.
3096
3097 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3098 to use it to enable L<Plack::Middleware>
3099
3100 This method is automatically called during 'setup' of your application, so
3101 you really don't need to invoke it.  However you may do so if you find the idea
3102 of loading middleware via configuration weird :).  For example:
3103
3104     package MyApp;
3105
3106     use Catalyst;
3107
3108     __PACKAGE__->setup_middleware('Head');
3109     __PACKAGE__->setup;
3110
3111 When we read middleware definitions from configuration, we reverse the list
3112 which sounds odd but is likely how you expect it to work if you have prior
3113 experience with L<Plack::Builder> or if you previously used the plugin
3114 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3115
3116 So basically your middleware handles an incoming request from the first
3117 registered middleware, down and handles the response from the last middleware
3118 up.
3119
3120 =cut
3121
3122 sub registered_middlewares {
3123     my $class = shift;
3124     if(my $middleware = $class->_psgi_middleware) {
3125         return (
3126           Plack::Middleware::HTTPExceptions->new,
3127           Plack::Middleware::RemoveRedundantBody->new,
3128           Plack::Middleware::FixMissingBodyInRedirect->new,
3129           Plack::Middleware::ContentLength->new,
3130           Plack::Middleware::MethodOverride->new,
3131           Plack::Middleware::Head->new,
3132           @$middleware);
3133     } else {
3134         die "You cannot call ->registered_middlewares until middleware has been setup";
3135     }
3136 }
3137
3138 sub setup_middleware {
3139     my $class = shift;
3140     my @middleware_definitions = @_ ?
3141       reverse(@_) : reverse(@{$class->config->{'psgi_middleware'}||[]});
3142
3143     my @middleware = ();
3144     while(my $next = shift(@middleware_definitions)) {
3145         if(ref $next) {
3146             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3147                 push @middleware, $next;
3148             } elsif(ref $next eq 'CODE') {
3149                 push @middleware, $next;
3150             } elsif(ref $next eq 'HASH') {
3151                 my $namespace = shift @middleware_definitions;
3152                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3153                 push @middleware, $mw;
3154             } else {
3155               die "I can't handle middleware definition ${\ref $next}";
3156             }
3157         } else {
3158           my $mw = $class->Catalyst::Utils::build_middleware($next);
3159           push @middleware, $mw;
3160         }
3161     }
3162
3163     my @existing = @{$class->_psgi_middleware || []};
3164     $class->_psgi_middleware([@middleware,@existing,]);
3165 }
3166
3167 =head2 registered_data_handlers
3168
3169 A read only copy of registered Data Handlers returned as a Hash, where each key
3170 is a content type and each value is a subref that attempts to decode that content
3171 type.
3172
3173 =head2 setup_data_handlers (?@data_handler)
3174
3175 Read configuration information stored in configuration key C<data_handlers> or
3176 from passed @args.
3177
3178 See under L</CONFIGURATION> information regarding C<data_handlers>.
3179
3180 This method is automatically called during 'setup' of your application, so
3181 you really don't need to invoke it.
3182
3183 =head2 default_data_handlers
3184
3185 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3186 only two default data handlers, for 'application/json' and an alternative to
3187 'application/x-www-form-urlencoded' which supposed nested form parameters via
3188 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3189
3190 The 'application/json' data handler is used to parse incoming JSON into a Perl
3191 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3192 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3193 JSON decoder, and has the smallest dependency impact.
3194
3195 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3196 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3197 order to get the best performance.  You should add either to your dependency
3198 list (Makefile.PL, dist.ini, cpanfile, etc.)
3199
3200 =cut
3201
3202 sub registered_data_handlers {
3203     my $class = shift;
3204     if(my $data_handlers = $class->_data_handlers) {
3205         return %$data_handlers;
3206     } else {
3207         die "You cannot call ->registered_data_handlers until data_handers has been setup";
3208     }
3209 }
3210
3211 sub setup_data_handlers {
3212     my ($class, %data_handler_callbacks) = @_;
3213     %data_handler_callbacks = (
3214       %{$class->default_data_handlers},
3215       %{$class->config->{'data_handlers'}||+{}},
3216       %data_handler_callbacks);
3217
3218     $class->_data_handlers(\%data_handler_callbacks);
3219 }
3220
3221 sub default_data_handlers {
3222     my ($class) = @_;
3223     return +{
3224       'application/x-www-form-urlencoded' => sub {
3225           my ($fh, $req) = @_;
3226           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3227           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3228             ->can('build_cgi_struct')->($params);
3229       },
3230       'application/json' => sub {
3231           Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON')
3232             ->can('decode_json')->(do { local $/; $_->getline });
3233       },
3234     };
3235 }
3236
3237 =head2 $c->stack
3238
3239 Returns an arrayref of the internal execution stack (actions that are
3240 currently executing).
3241
3242 =head2 $c->stats
3243
3244 Returns the current timing statistics object. By default Catalyst uses
3245 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3246 L<< stats_class|/"$c->stats_class" >>.
3247
3248 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3249 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3250 profile explicitly, although MyApp.pm still won't profile nor output anything
3251 by itself.
3252
3253 =head2 $c->stats_class
3254
3255 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3256
3257 =head2 $c->use_stats
3258
3259 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3260
3261 Note that this is a static method, not an accessor and should be overridden
3262 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3263
3264 =cut
3265
3266 sub use_stats { 0 }
3267
3268
3269 =head2 $c->write( $data )
3270
3271 Writes $data to the output stream. When using this method directly, you
3272 will need to manually set the C<Content-Length> header to the length of
3273 your output data, if known.
3274
3275 =cut
3276
3277 sub write {
3278     my $c = shift;
3279
3280     # Finalize headers if someone manually writes output (for compat)
3281     $c->finalize_headers;
3282
3283     return $c->response->write( @_ );
3284 }
3285
3286 =head2 version
3287
3288 Returns the Catalyst version number. Mostly useful for "powered by"
3289 messages in template systems.
3290
3291 =cut
3292
3293 sub version { return $Catalyst::VERSION }
3294
3295 =head1 CONFIGURATION
3296
3297 There are a number of 'base' config variables which can be set:
3298
3299 =over
3300
3301 =item *
3302
3303 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3304
3305 =item *
3306
3307 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3308
3309 =item *
3310
3311 C<disable_component_resolution_regex_fallback> - Turns
3312 off the deprecated component resolution functionality so
3313 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3314 are called then regex search will not be attempted on string values and
3315 instead C<undef> will be returned.
3316
3317 =item *
3318
3319 C<home> - The application home directory. In an uninstalled application,
3320 this is the top level application directory. In an installed application,
3321 this will be the directory containing C<< MyApp.pm >>.
3322
3323 =item *
3324
3325 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3326
3327 =item *
3328
3329 C<name> - The name of the application in debug messages and the debug and
3330 welcome screens
3331
3332 =item *
3333
3334 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3335 until it is accessed. This allows you to (for example) check authentication (and reject
3336 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3337
3338 =item *
3339
3340 C<root> - The root directory for templates. Usually this is just a
3341 subdirectory of the home directory, but you can set it to change the
3342 templates to a different directory.
3343
3344 =item *
3345
3346 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3347 namespaces from which components will be loaded (and constructed and stored in
3348 C<< $c->components >>).
3349
3350 =item *
3351
3352 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3353 to be shown in hit debug tables in the test server.
3354
3355 =item *
3356
3357 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3358 variable should be used for determining the request path.
3359
3360 Most web server environments pass the requested path to the application using environment variables,
3361 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3362 exposed as C<< $c->request->base >>) and the request path below that base.
3363
3364 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3365 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3366
3367 =over
3368
3369 =item use_request_uri_for_path => 0
3370
3371 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3372 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3373 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3374 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3375
3376 However this method has the major disadvantage that it is impossible to correctly decode some elements
3377 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3378 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3379 can't distinguish / vs %2F in paths (in addition to other encoded values).
3380
3381 =item use_request_uri_for_path => 1
3382
3383 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3384 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3385 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3386
3387 Given that this method of path resolution is provably more correct, it is recommended that you use
3388 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3389 aware of the implications of not being able to handle encoded URI paths correctly.
3390
3391 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3392 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3393 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3394 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3395 C<< $c->request->base >> will be incorrect.
3396
3397 =back
3398
3399 =item *
3400
3401 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3402
3403 =item *
3404
3405 C<encoding> - See L</ENCODING>
3406
3407 =item *
3408
3409 C<abort_chain_on_error_fix>
3410
3411 When there is an error in an action chain, the default behavior is to continue
3412 processing the remaining actions and then catch the error upon chain end.  This
3413 can lead to running actions when the application is in an unexpected state.  If
3414 you have this issue, setting this config value to true will promptly exit a
3415 chain when there is an error raised in any action (thus terminating the chain
3416 early.)
3417
3418 use like:
3419
3420     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3421
3422 In the future this might become the default behavior.
3423
3424 =item *
3425
3426 C<use_hash_multivalue_in_request>
3427
3428 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3429 and C<parameters> return a hashref where values might be scalar or an arrayref
3430 depending on the incoming data.  In many cases this can be undesirable as it
3431 leads one to writing defensive code like the following:
3432
3433     my ($val) = ref($c->req->parameters->{a}) ?
3434       @{$c->req->parameters->{a}} :
3435         $c->req->parameters->{a};
3436
3437 Setting this configuration item to true will make L<Catalyst> populate the
3438 attributes underlying these methods with an instance of L<Hash::MultiValue>
3439 which is used by L<Plack::Request> and others to solve this very issue.  You
3440 may prefer this behavior to the default, if so enable this option (be warned
3441 if you enable it in a legacy application we are not sure if it is completely
3442 backwardly compatible).
3443
3444 =item *
3445
3446 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3447
3448 =item *
3449
3450 C<data_handlers> - See L<DATA HANDLERS>.
3451
3452 =back
3453
3454 =head1 EXCEPTIONS
3455
3456 Generally when you throw an exception inside an Action (or somewhere in
3457 your stack, such as in a model that an Action is calling) that exception
3458 is caught by Catalyst and unless you either catch it yourself (via eval
3459 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3460 will eventually reach L</finalize_errors> and return either the debugging
3461 error stack page, or the default error page.  However, if your exception
3462 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3463 instead rethrow it so that it can be handled by that middleware (which
3464 is part of the default middleware).  For example this would allow
3465
3466     use HTTP::Throwable::Factory 'http_throw';
3467
3468     sub throws_exception :Local {
3469       my ($self, $c) = @_;
3470
3471       http_throw(SeeOther => { location =>
3472         $c->uri_for($self->action_for('redirect')) });
3473
3474     }
3475
3476 =head1 INTERNAL ACTIONS
3477
3478 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3479 C<_ACTION>, and C<_END>. These are by default not shown in the private
3480 action table, but you can make them visible with a config parameter.
3481
3482     MyApp->config(show_internal_actions => 1);
3483
3484 =head1 ON-DEMAND PARSER
3485
3486 The request body is usually parsed at the beginning of a request,
3487 but if you want to handle input yourself, you can enable on-demand
3488 parsing with a config parameter.
3489
3490     MyApp->config(parse_on_demand => 1);
3491
3492 =head1 PROXY SUPPORT
3493
3494 Many production servers operate using the common double-server approach,
3495 with a lightweight frontend web server passing requests to a larger
3496 backend server. An application running on the backend server must deal
3497 with two problems: the remote user always appears to be C<127.0.0.1> and
3498 the server's hostname will appear to be C<localhost> regardless of the
3499 virtual host that the user connected through.
3500
3501 Catalyst will automatically detect this situation when you are running
3502 the frontend and backend servers on the same machine. The following
3503 changes are made to the request.
3504
3505     $c->req->address is set to the user's real IP address, as read from
3506     the HTTP X-Forwarded-For header.
3507
3508     The host value for $c->req->base and $c->req->uri is set to the real
3509     host, as read from the HTTP X-Forwarded-Host header.
3510
3511 Additionally, you may be running your backend application on an insecure
3512 connection (port 80) while your frontend proxy is running under SSL.  If there
3513 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3514 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3515 be created properly.
3516
3517 In the case of passing in:
3518
3519     X-Forwarded-Port: 443
3520
3521 All calls to C<uri_for> will result in an https link, as is expected.
3522
3523 Obviously, your web server must support these headers for this to work.
3524
3525 In a more complex server farm environment where you may have your
3526 frontend proxy server(s) on different machines, you will need to set a
3527 configuration option to tell Catalyst to read the proxied data from the
3528 headers.
3529
3530     MyApp->config(using_frontend_proxy => 1);
3531
3532 If you do not wish to use the proxy support at all, you may set:
3533
3534     MyApp->config(ignore_frontend_proxy => 0);
3535
3536 =head2 Note about psgi files
3537
3538 Note that if you supply your own .psgi file, calling
3539 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3540
3541 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3542 in your psgi, for example:
3543
3544     builder {
3545         enable "Plack::Middleware::ReverseProxy";
3546         MyApp->psgi_app
3547     };
3548
3549 This will unconditionally add the ReverseProxy support, or you need to call
3550 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3551 apply the support depending upon your config).
3552
3553 See L<Catalyst::PSGI> for more information.
3554
3555 =head1 THREAD SAFETY
3556
3557 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3558 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3559 believe the Catalyst core to be thread-safe.
3560
3561 If you plan to operate in a threaded environment, remember that all other
3562 modules you are using must also be thread-safe. Some modules, most notably
3563 L<DBD::SQLite>, are not thread-safe.
3564
3565 =head1 DATA HANDLERS
3566
3567 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3568 form parameters and URL search query fields.  However it has become common
3569 for various alternative content types to be PUT or POSTed to your controllers
3570 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3571 XML and other content types when communicating with an application server.  In
3572 order to better support this use case, L<Catalyst> defines a global configuration
3573 option, C<data_handlers>, which lets you associate a content type with a coderef
3574 that parses that content type into something Perl can readily access.
3575
3576     package MyApp::Web;
3577
3578     use Catalyst;
3579     use JSON::Maybe;
3580
3581     __PACKAGE__->config(
3582       data_handlers => {
3583         'application/json' => sub { local $/; decode_json $_->getline },
3584       },
3585       ## Any other configuration.
3586     );
3587
3588     __PACKAGE__->setup;
3589
3590 By default L<Catalyst> comes with a generic JSON data handler similar to the
3591 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3592 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3593 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3594 or dist.ini, cpanfile, etc.)
3595
3596 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
3597 (matched against the incoming request type using a regexp such as to be case
3598 insensitive) and whose values are coderefs that receive a localized version of
3599 C<$_> which is a filehandle object pointing to received body.
3600
3601 This feature is considered an early access release and we reserve the right
3602 to alter the interface in order to provide a performant and secure solution to
3603 alternative request body content.  Your reports welcomed!
3604
3605 =head1 PSGI MIDDLEWARE
3606
3607 You can define middleware, defined as L<Plack::Middleware> or a compatible
3608 interface in configuration.  Your middleware definitions are in the form of an
3609 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3610 with details to follow:
3611
3612     package MyApp::Web;
3613
3614     use Catalyst;
3615     use Plack::Middleware::StackTrace;
3616
3617     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3618
3619     __PACKAGE__->config(
3620       'psgi_middleware', [
3621         'Debug',
3622         '+MyApp::Custom',
3623         $stacktrace_middleware,
3624         'Session' => {store => 'File'},
3625         sub {
3626           my $app = shift;
3627           return sub {
3628             my $env = shift;
3629             $env->{myapp.customkey} = 'helloworld';
3630             $app->($env);
3631           },
3632         },
3633       ],
3634     );
3635
3636     __PACKAGE__->setup;
3637
3638 So the general form is:
3639
3640     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3641
3642 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3643 the order listed (to make it function similarly to L<Plack::Builder>:
3644
3645 Alternatively, you may also define middleware by calling the L</setup_middleware>
3646 package method:
3647
3648     package MyApp::Web;
3649
3650     use Catalyst;
3651
3652     __PACKAGE__->setup_middleware( \@middleware_definitions);
3653     __PACKAGE__->setup;
3654
3655 In the case where you do both (use 'setup_middleware' and configuration) the
3656 package call to setup_middleware will be applied earlier (in other words its
3657 middleware will wrap closer to the application).  Keep this in mind since in
3658 some cases the order of middleware is important.
3659
3660 The two approaches are not exclusive.
3661
3662 =over 4
3663
3664 =item Middleware Object
3665
3666 An already initialized object that conforms to the L<Plack::Middleware>
3667 specification:
3668
3669     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3670
3671     __PACKAGE__->config(
3672       'psgi_middleware', [
3673         $stacktrace_middleware,
3674       ]);
3675
3676
3677 =item coderef
3678
3679 A coderef that is an inlined middleware:
3680
3681     __PACKAGE__->config(
3682       'psgi_middleware', [
3683         sub {
3684           my $app = shift;
3685           return sub {
3686             my $env = shift;
3687             if($env->{PATH_INFO} =~m/forced/) {
3688               Plack::App::File
3689                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3690                 ->call($env);
3691             } else {
3692               return $app->($env);
3693             }
3694          },
3695       },
3696     ]);
3697
3698
3699
3700 =item a scalar
3701
3702 We assume the scalar refers to a namespace after normalizing it using the
3703 following rules:
3704
3705 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3706 is assumed to be 'as is', and we just install and use the middleware.
3707
3708 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3709 (the package name of your Catalyst application subclass), we also assume then
3710 that it is a full namespace, and use it.
3711
3712 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3713 resolve it first by looking for it under your application namespace (for example
3714 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3715 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3716 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3717 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3718 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3719 you find that a good idea.
3720
3721 Examples:
3722
3723     package MyApp::Web;
3724
3725     __PACKAGE__->config(
3726       'psgi_middleware', [
3727         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3728         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3729         '+MyApp::Custom',  ## MyApp::Custom->wrap
3730       ],
3731     );
3732
3733 =item a scalar followed by a hashref
3734
3735 Just like the previous, except the following C<HashRef> is used as arguments
3736 to initialize the middleware object.
3737
3738     __PACKAGE__->config(
3739       'psgi_middleware', [
3740          'Session' => {store => 'File'},
3741     ]);
3742
3743 =back
3744
3745 Please see L<PSGI> for more on middleware.
3746
3747 =head1 ENCODING
3748
3749 On request, decodes all params from encoding into a sequence of
3750 logical characters. On response, encodes body into encoding.
3751
3752 =head2 Methods
3753
3754 =over 4
3755
3756 =item encoding
3757
3758 Returns an instance of an C<Encode> encoding
3759
3760     print $c->encoding->name
3761
3762 =item handle_unicode_encoding_exception ($exception_context)
3763
3764 Method called when decoding process for a request fails.
3765
3766 An C<$exception_context> hashref is provided to allow you to override the
3767 behaviour of your application when given data with incorrect encodings.
3768
3769 The default method throws exceptions in the case of invalid request parameters
3770 (resulting in a 500 error), but ignores errors in upload filenames.
3771
3772 The keys passed in the C<$exception_context> hash are:
3773
3774 =over
3775
3776 =item param_value
3777
3778 The value which was not able to be decoded.
3779
3780 =item error_msg
3781
3782 The exception received from L<Encode>.
3783
3784 =item encoding_step
3785
3786 What type of data was being decoded. Valid values are (currently)
3787 C<params> - for request parameters / arguments / captures
3788 and C<uploads> - for request upload filenames.
3789
3790 =back
3791
3792 =back
3793
3794 =head1 SUPPORT
3795
3796 IRC:
3797
3798     Join #catalyst on irc.perl.org.
3799
3800 Mailing Lists:
3801
3802     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3803     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3804
3805 Web:
3806
3807     http://catalyst.perl.org
3808
3809 Wiki:
3810
3811     http://dev.catalyst.perl.org
3812
3813 =head1 SEE ALSO
3814
3815 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3816
3817 =head2 L<Catalyst::Manual> - The Catalyst Manual
3818
3819 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3820
3821 =head2 L<Catalyst::Engine> - Core engine
3822
3823 =head2 L<Catalyst::Log> - Log class.
3824
3825 =head2 L<Catalyst::Request> - Request object
3826
3827 =head2 L<Catalyst::Response> - Response object
3828
3829 =head2 L<Catalyst::Test> - The test suite.
3830
3831 =head1 PROJECT FOUNDER
3832
3833 sri: Sebastian Riedel <sri@cpan.org>
3834
3835 =head1 CONTRIBUTORS
3836
3837 abw: Andy Wardley
3838
3839 acme: Leon Brocard <leon@astray.com>
3840
3841 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3842
3843 Andrew Bramble
3844
3845 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3846
3847 Andrew Ruthven
3848
3849 andyg: Andy Grundman <andy@hybridized.org>
3850
3851 audreyt: Audrey Tang
3852
3853 bricas: Brian Cassidy <bricas@cpan.org>
3854
3855 Caelum: Rafael Kitover <rkitover@io.com>
3856
3857 chansen: Christian Hansen
3858
3859 chicks: Christopher Hicks
3860
3861 Chisel Wright C<pause@herlpacker.co.uk>
3862
3863 Danijel Milicevic C<me@danijel.de>
3864
3865 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3866
3867 David Naughton, C<naughton@umn.edu>
3868
3869 David E. Wheeler
3870
3871 dhoss: Devin Austin <dhoss@cpan.org>
3872
3873 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3874
3875 Drew Taylor
3876
3877 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3878
3879 esskar: Sascha Kiefer
3880
3881 fireartist: Carl Franks <cfranks@cpan.org>
3882
3883 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3884
3885 gabb: Danijel Milicevic
3886
3887 Gary Ashton Jones
3888
3889 Gavin Henry C<ghenry@perl.me.uk>
3890
3891 Geoff Richards
3892
3893 groditi: Guillermo Roditi <groditi@gmail.com>
3894
3895 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3896
3897 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3898
3899 jcamacho: Juan Camacho
3900
3901 jester: Jesse Sheidlower C<jester@panix.com>
3902
3903 jhannah: Jay Hannah <jay@jays.net>
3904
3905 Jody Belka
3906
3907 Johan Lindstrom
3908
3909 jon: Jon Schutz <jjschutz@cpan.org>
3910
3911 Jonathan Rockway C<< <jrockway@cpan.org> >>
3912
3913 Kieren Diment C<kd@totaldatasolution.com>
3914
3915 konobi: Scott McWhirter <konobi@cpan.org>
3916
3917 marcus: Marcus Ramberg <mramberg@cpan.org>
3918
3919 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3920
3921 mgrimes: Mark Grimes <mgrimes@cpan.org>
3922
3923 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3924
3925 mugwump: Sam Vilain
3926
3927 naughton: David Naughton
3928
3929 ningu: David Kamholz <dkamholz@cpan.org>
3930
3931 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3932
3933 numa: Dan Sully <daniel@cpan.org>
3934
3935 obra: Jesse Vincent
3936
3937 Octavian Rasnita
3938
3939 omega: Andreas Marienborg
3940
3941 Oleg Kostyuk <cub.uanic@gmail.com>
3942
3943 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3944
3945 rafl: Florian Ragwitz <rafl@debian.org>
3946
3947 random: Roland Lammel <lammel@cpan.org>
3948
3949 Robert Sedlacek C<< <rs@474.at> >>
3950
3951 SpiceMan: Marcel Montes
3952
3953 sky: Arthur Bergman
3954
3955 szbalint: Balint Szilakszi <szbalint@cpan.org>
3956
3957 t0m: Tomas Doran <bobtfish@bobtfish.net>
3958
3959 Ulf Edvinsson
3960
3961 Viljo Marrandi C<vilts@yahoo.com>
3962
3963 Will Hawes C<info@whawes.co.uk>
3964
3965 willert: Sebastian Willert <willert@cpan.org>
3966
3967 wreis: Wallace Reis <wreis@cpan.org>
3968
3969 Yuval Kogman, C<nothingmuch@woobling.org>
3970
3971 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3972
3973 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3974
3975 Upasana <me@upasana.me>
3976
3977 =head1 COPYRIGHT
3978
3979 Copyright (c) 2005-2014, the above named PROJECT FOUNDER and CONTRIBUTORS.
3980
3981 =head1 LICENSE
3982
3983 This library is free software. You can redistribute it and/or modify it under
3984 the same terms as Perl itself.
3985
3986 =cut
3987
3988 no Moose;
3989
3990 __PACKAGE__->meta->make_immutable;
3991
3992 1;