lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/container components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80032';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 sub _find_component_regexp {
 540     my ( $c, $container, $name, $args ) = @_;
 541
 542     return
 543         if $c->config->{disable_component_resolution_regex_fallback} && !ref $name;
 544
 545     my $appclass = ref $c || $c;
 546     my $prefix   = ucfirst $container->name;
 547     my $p        = substr $prefix, 0, 1;
 548
 549     my $query = ref $name ? $name : qr{$name}i;
 550     $query =~ s/^${appclass}::($p|$prefix):://i;
 551
 552     my @comps  = $container->get_service_list;
 553     my @result = map {
 554         $container->resolve( service => $_, parameters => { context => $args } )
 555     } grep { m/$query/ } @comps;
 556
 557     if (!ref $name && $result[0]) {
 558         $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 559         $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 560         $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 561         return $result[0];
 562     }
 563
 564     return @result;
 565 }
 566
 567 =head2 COMPONENT ACCESSORS
 568
 569 =head2 $c->controller($name)
 570
 571 Gets a L<Catalyst::Controller> instance by name.
 572
 573     $c->controller('Foo')->do_stuff;
 574
 575 If the name is omitted, will return the controller for the dispatched
 576 action.
 577
 578 If you want to search for controllers, pass in a regexp as the argument.
 579
 580     # find all controllers that start with Foo
 581     my @foo_controllers = $c->controller(qr{^Foo});
 582
 583
 584 =cut
 585
 586 sub controller {
 587     my ( $c, $name, @args ) = @_;
 588     my $container = $c->container->get_sub_container('controller');
 589     unshift @args, $c;
 590
 591     if( $name ) {
 592         return $c->container->get_component('controller', $name, \@args)
 593             if $container->has_service($name) && !ref $name;
 594
 595         return $c->_find_component_regexp( $container, $name, \@args );
 596     }
 597
 598     return $c->component( $c->action->class );
 599 }
 600
 601 =head2 $c->model($name)
 602
 603 Gets a L<Catalyst::Model> instance by name.
 604
 605     $c->model('Foo')->do_stuff;
 606
 607 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 608
 609 If the name is omitted, it will look for
 610  - a model object in $c->stash->{current_model_instance}, then
 611  - a model name in $c->stash->{current_model}, then
 612  - a config setting 'default_model', or
 613  - check if there is only one model, and return it if that's the case.
 614
 615 If you want to search for models, pass in a regexp as the argument.
 616
 617     # find all models that start with Foo
 618     my @foo_models = $c->model(qr{^Foo});
 619
 620 =cut
 621
 622 sub model {
 623     my ( $c, $name, @args ) = @_;
 624     my $appclass = ref($c) || $c;
 625     my $container = $c->container->get_sub_container('model');
 626     unshift @args, $c;
 627
 628     if( $name ) {
 629         # Direct component hash lookup to avoid costly regexps
 630         return $c->container->get_component('model', $name, \@args)
 631             if ( !ref $name && $container->has_service($name));
 632
 633         return $c->_find_component_regexp( $container, $name, \@args );
 634     }
 635
 636     if (ref $c) {
 637         return $c->stash->{current_model_instance}
 638           if $c->stash->{current_model_instance};
 639         return $c->model( $c->stash->{current_model} )
 640           if $c->stash->{current_model};
 641     }
 642     return $c->model( $appclass->config->{default_model} )
 643       if $appclass->config->{default_model};
 644
 645 # FIXME: will this still be mantained?
 646     my( $comp, $rest ) = $container->get_service_list;
 647
 648     if( $rest ) {
 649         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 650         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 651         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 652         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 653         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 654     }
 655
 656     return $container->resolve( service => $comp, parameters => { context => \@args } );
 657 }
 658
 659
 660 =head2 $c->view($name)
 661
 662 Gets a L<Catalyst::View> instance by name.
 663
 664     $c->view('Foo')->do_stuff;
 665
 666 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 667
 668 If the name is omitted, it will look for
 669  - a view object in $c->stash->{current_view_instance}, then
 670  - a view name in $c->stash->{current_view}, then
 671  - a config setting 'default_view', or
 672  - check if there is only one view, and return it if that's the case.
 673
 674 If you want to search for views, pass in a regexp as the argument.
 675
 676     # find all views that start with Foo
 677     my @foo_views = $c->view(qr{^Foo});
 678
 679 =cut
 680
 681 sub view {
 682     my ( $c, $name, @args ) = @_;
 683     my $appclass = ref($c) || $c;
 684     my $container = $c->container->get_sub_container('view');
 685     unshift @args, $c;
 686
 687     if( $name ) {
 688         if ( !ref $name ) { # Direct component hash lookup to avoid costly regexps
 689             if ( $container->has_service($name) ) {
 690                 return $c->container->get_component('view', $name, \@args);
 691             }
 692             else {
 693                 $c->log->warn( "Attempted to use view '$name', but does not exist" );
 694             }
 695         }
 696
 697         return $c->_find_component_regexp( $container, $name, \@args );
 698     }
 699
 700     if (ref $c) {
 701         return $c->stash->{current_view_instance}
 702           if $c->stash->{current_view_instance};
 703         return $c->view( $c->stash->{current_view} )
 704           if $c->stash->{current_view};
 705     }
 706     return $c->view( $appclass->config->{default_view} )
 707       if $appclass->config->{default_view};
 708
 709     my( $comp, $rest ) = $container->get_service_list;
 710
 711     if( $rest ) {
 712         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 713         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 714         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 715         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 716         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 717     }
 718
 719     return $container->resolve( service => $comp, parameters => { context => \@args } );
 720 }
 721
 722 =head2 $c->controllers
 723
 724 Returns the available names which can be passed to $c->controller
 725
 726 =cut
 727
 728 sub controllers {
 729     my ( $c ) = @_;
 730     return $c->container->get_sub_container('controller')->get_service_list;
 731 }
 732
 733 =head2 $c->models
 734
 735 Returns the available names which can be passed to $c->model
 736
 737 =cut
 738
 739 sub models {
 740     my ( $c ) = @_;
 741     return $c->container->get_sub_container('model')->get_service_list;
 742 }
 743
 744
 745 =head2 $c->views
 746
 747 Returns the available names which can be passed to $c->view
 748
 749 =cut
 750
 751 sub views {
 752     my ( $c ) = @_;
 753     return $c->container->get_sub_container('view')->get_service_list;
 754 }
 755
 756 =head2 $c->comp($name)
 757
 758 =head2 $c->component($name)
 759
 760 Gets a component object by name. This method is not recommended,
 761 unless you want to get a specific component by full
 762 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 763 should be used instead.
 764
 765 If C<$name> is a regexp, a list of components matched against the full
 766 component name will be returned.
 767
 768 If Catalyst can't find a component by name, it will fallback to regex
 769 matching by default. To disable this behaviour set
 770 disable_component_resolution_regex_fallback to a true value.
 771
 772     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 773
 774 =cut
 775
 776 sub component {
 777     my ( $c, $component, @args ) = @_;
 778
 779     if ( $component ) {
 780         my ($type, $name) = _get_component_type_name($component);
 781
 782         if ($type && $c->container->has_sub_container($type)) {
 783             my $container = $c->container->get_sub_container($type);
 784
 785             if( !ref $component && $container->has_service($name) ) {
 786                 return $container->resolve( service => $name, parameters => { context => [ $c, @args ] } );
 787             }
 788
 789             return
 790                 if $c->config->{disable_component_resolution_regex_fallback};
 791
 792             my $query      = qr{$name}i;
 793             my @components = $container->get_service_list;
 794             my @result     = grep { m{$query} } @components;
 795
 796             if (@result) {
 797                 $c->log->warn( Carp::shortmess(qq(Found results for "${component}" using regexp fallback)) );
 798                 $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 799                 $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 800
 801                 return $container->resolve( service => $result[0], parameters => { context => [$c, @args] } );
 802             }
 803         }
 804
 805         return
 806             if $c->config->{disable_component_resolution_regex_fallback} && !ref $component;
 807
 808         # This is here so $c->comp( '::M::' ) works
 809         my $query = ref $component ? $component : qr{$component}i;
 810
 811         for my $subcontainer_name (qw/model view controller/) {
 812             my $subcontainer = $c->container->get_sub_container($subcontainer_name);
 813             my @components   = $subcontainer->get_service_list;
 814             my @result       = grep { m{$query} } @components;
 815
 816             if (@result) {
 817                 return map { $subcontainer->resolve( service => $_, parameters => { context => [$c, @args] } ) } @result
 818                     if ref $component;
 819
 820                 $c->log->warn( Carp::shortmess(qq(Found results for "${component}" using regexp fallback)) );
 821                 $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 822                 $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 823
 824                 return $subcontainer->resolve( service => $result[0], parameters => { context => [$c, @args] } );
 825             }
 826         }
 827
 828         # I would expect to return an empty list here, but that breaks back-compat
 829     }
 830
 831     # fallback
 832     return sort keys %{ $c->components };
 833 }
 834
 835 =head2 CLASS DATA AND HELPER CLASSES
 836
 837 =head2 $c->config
 838
 839 Returns or takes a hashref containing the application's configuration.
 840
 841     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 842
 843 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 844 like C<myapp.conf> in your applications home directory. See
 845 L<Catalyst::Plugin::ConfigLoader>.
 846
 847 =head3 Cascading configuration
 848
 849 The config method is present on all Catalyst components, and configuration
 850 will be merged when an application is started. Configuration loaded with
 851 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 852 followed by configuration in your top level C<MyApp> class. These two
 853 configurations are merged, and then configuration data whose hash key matches a
 854 component name is merged with configuration for that component.
 855
 856 The configuration for a component is then passed to the C<new> method when a
 857 component is constructed.
 858
 859 For example:
 860
 861     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 862     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 863
 864 will mean that C<MyApp::Model::Foo> receives the following data when
 865 constructed:
 866
 867     MyApp::Model::Foo->new({
 868         bar => 'baz',
 869         quux => 'frob',
 870         overrides => 'me',
 871     });
 872
 873 It's common practice to use a Moose attribute
 874 on the receiving component to access the config value.
 875
 876     package MyApp::Model::Foo;
 877
 878     use Moose;
 879
 880     # this attr will receive 'baz' at construction time
 881     has 'bar' => (
 882         is  => 'rw',
 883         isa => 'Str',
 884     );
 885
 886 You can then get the value 'baz' by calling $c->model('Foo')->bar
 887 (or $self->bar inside code in the model).
 888
 889 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 890 as a way of reading config within your code, as this B<will not> give you the
 891 correctly merged config back. You B<MUST> take the config values supplied to
 892 the constructor and use those instead.
 893
 894 =cut
 895
 896 around config => sub {
 897     my $orig = shift;
 898     my $c = shift;
 899
 900     croak('Setting config after setup has been run is not allowed.')
 901         if ( @_ and $c->setup_finished );
 902
 903     $c->$orig(@_);
 904 };
 905
 906 =head2 $c->log
 907
 908 Returns the logging object instance. Unless it is already set, Catalyst
 909 sets this up with a L<Catalyst::Log> object. To use your own log class,
 910 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 911 C<< __PACKAGE__->setup >>.
 912
 913  __PACKAGE__->log( MyLogger->new );
 914  __PACKAGE__->setup;
 915
 916 And later:
 917
 918     $c->log->info( 'Now logging with my own logger!' );
 919
 920 Your log class should implement the methods described in
 921 L<Catalyst::Log>.
 922
 923
 924 =head2 $c->debug
 925
 926 Returns 1 if debug mode is enabled, 0 otherwise.
 927
 928 You can enable debug mode in several ways:
 929
 930 =over
 931
 932 =item By calling myapp_server.pl with the -d flag
 933
 934 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 935
 936 =item The -Debug option in your MyApp.pm
 937
 938 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 939
 940 =back
 941
 942 The first three also set the log level to 'debug'.
 943
 944 Calling C<< $c->debug(1) >> has no effect.
 945
 946 =cut
 947
 948 sub debug { 0 }
 949
 950 =head2 $c->dispatcher
 951
 952 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 953
 954 =head2 $c->engine
 955
 956 Returns the engine instance. See L<Catalyst::Engine>.
 957
 958
 959 =head2 UTILITY METHODS
 960
 961 =head2 $c->path_to(@path)
 962
 963 Merges C<@path> with C<< $c->config->{home} >> and returns a
 964 L<Path::Class::Dir> object. Note you can usually use this object as
 965 a filename, but sometimes you will have to explicitly stringify it
 966 yourself by calling the C<< ->stringify >> method.
 967
 968 For example:
 969
 970     $c->path_to( 'db', 'sqlite.db' );
 971
 972 =cut
 973
 974 sub path_to {
 975     my ( $c, @path ) = @_;
 976     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 977     if ( -d $path ) { return $path }
 978     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 979 }
 980
 981 =head2 $c->plugin( $name, $class, @args )
 982
 983 Helper method for plugins. It creates a class data accessor/mutator and
 984 loads and instantiates the given class.
 985
 986     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 987
 988     $c->prototype->define_javascript_functions;
 989
 990 B<Note:> This method of adding plugins is deprecated. The ability
 991 to add plugins like this B<will be removed> in a Catalyst 5.81.
 992 Please do not use this functionality in new code.
 993
 994 =cut
 995
 996 sub plugin {
 997     my ( $class, $name, $plugin, @args ) = @_;
 998
 999     # See block comment in t/unit_core_plugin.t
1000     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1001
1002     $class->_register_plugin( $plugin, 1 );
1003
1004     eval { $plugin->import };
1005     $class->mk_classdata($name);
1006     my $obj;
1007     eval { $obj = $plugin->new(@args) };
1008
1009     if ($@) {
1010         Catalyst::Exception->throw( message =>
1011               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1012     }
1013
1014     $class->$name($obj);
1015     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1016       if $class->debug;
1017 }
1018
1019 =head2 MyApp->setup
1020
1021 Initializes the dispatcher and engine, loads any plugins, and loads the
1022 model, view, and controller components. You may also specify an array
1023 of plugins to load here, if you choose to not load them in the C<use
1024 Catalyst> line.
1025
1026     MyApp->setup;
1027     MyApp->setup( qw/-Debug/ );
1028
1029 =cut
1030
1031 sub setup {
1032     my ( $class, @arguments ) = @_;
1033     croak('Running setup more than once')
1034         if ( $class->setup_finished );
1035
1036     unless ( $class->isa('Catalyst') ) {
1037
1038         Catalyst::Exception->throw(
1039             message => qq/'$class' does not inherit from Catalyst/ );
1040     }
1041
1042     if ( $class->arguments ) {
1043         @arguments = ( @arguments, @{ $class->arguments } );
1044     }
1045
1046     # Process options
1047     my $flags = {};
1048
1049     foreach (@arguments) {
1050
1051         if (/^-Debug$/) {
1052             $flags->{log} =
1053               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1054         }
1055         elsif (/^-(\w+)=?(.*)$/) {
1056             $flags->{ lc $1 } = $2;
1057         }
1058         else {
1059             push @{ $flags->{plugins} }, $_;
1060         }
1061     }
1062
1063     $class->setup_config();
1064     $class->setup_home( delete $flags->{home} );
1065
1066     $class->setup_log( delete $flags->{log} );
1067     $class->setup_plugins( delete $flags->{plugins} );
1068     $class->setup_dispatcher( delete $flags->{dispatcher} );
1069     $class->setup_engine( delete $flags->{engine} );
1070     $class->setup_stats( delete $flags->{stats} );
1071
1072     for my $flag ( sort keys %{$flags} ) {
1073
1074         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1075             &$code( $class, delete $flags->{$flag} );
1076         }
1077         else {
1078             $class->log->warn(qq/Unknown flag "$flag"/);
1079         }
1080     }
1081
1082     eval { require Catalyst::Devel; };
1083     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1084         $class->log->warn(<<"EOF");
1085 You are running an old script!
1086
1087   Please update by running (this will overwrite existing files):
1088     catalyst.pl -force -scripts $class
1089
1090   or (this will not overwrite existing files):
1091     catalyst.pl -scripts $class
1092
1093 EOF
1094     }
1095
1096     if ( $class->debug ) {
1097         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1098
1099         if (@plugins) {
1100             my $column_width = Catalyst::Utils::term_width() - 6;
1101             my $t = Text::SimpleTable->new($column_width);
1102             $t->row($_) for @plugins;
1103             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1104         }
1105
1106         my $dispatcher = $class->dispatcher;
1107         my $engine     = $class->engine;
1108         my $home       = $class->config->{home};
1109
1110         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1111         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1112
1113         $home
1114           ? ( -d $home )
1115           ? $class->log->debug(qq/Found home "$home"/)
1116           : $class->log->debug(qq/Home "$home" doesn't exist/)
1117           : $class->log->debug(q/Couldn't find home/);
1118     }
1119
1120     # Call plugins setup, this is stupid and evil.
1121     # Also screws C3 badly on 5.10, hack to avoid.
1122     {
1123         no warnings qw/redefine/;
1124         local *setup = sub { };
1125         $class->setup unless $Catalyst::__AM_RESTARTING;
1126     }
1127
1128     # Initialize our data structure
1129     $class->components( {} );
1130
1131     $class->setup_components;
1132
1133     if ( $class->debug ) {
1134         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1135         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1136         for my $comp ( sort keys %{ $class->components } ) {
1137             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1138             $t->row( $comp, $type );
1139         }
1140         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1141           if ( keys %{ $class->components } );
1142     }
1143
1144     # Add our self to components, since we are also a component
1145     if( $class->isa('Catalyst::Controller') ){
1146       $class->components->{$class} = $class;
1147     }
1148
1149     $class->setup_actions;
1150
1151     if ( $class->debug ) {
1152         my $name = $class->config->{name} || 'Application';
1153         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1154     }
1155
1156     # Make sure that the application class becomes immutable at this point,
1157     B::Hooks::EndOfScope::on_scope_end {
1158         return if $@;
1159         my $meta = Class::MOP::get_metaclass_by_name($class);
1160         if (
1161             $meta->is_immutable
1162             && ! { $meta->immutable_options }->{replace_constructor}
1163             && (
1164                    $class->isa('Class::Accessor::Fast')
1165                 || $class->isa('Class::Accessor')
1166             )
1167         ) {
1168             warn "You made your application class ($class) immutable, "
1169                 . "but did not inline the\nconstructor. "
1170                 . "This will break catalyst, as your app \@ISA "
1171                 . "Class::Accessor(::Fast)?\nPlease pass "
1172                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1173         }
1174         $meta->make_immutable(
1175             replace_constructor => 1,
1176         ) unless $meta->is_immutable;
1177     };
1178
1179     if ($class->config->{case_sensitive}) {
1180         $class->log->warn($class . "->config->{case_sensitive} is set.");
1181         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1182     }
1183
1184     $class->setup_finalize;
1185     # Should be the last thing we do so that user things hooking
1186     # setup_finalize can log..
1187     $class->log->_flush() if $class->log->can('_flush');
1188     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1189 }
1190
1191 =head2 $app->setup_finalize
1192
1193 A hook to attach modifiers to. This method does not do anything except set the
1194 C<setup_finished> accessor.
1195
1196 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1197
1198 Example:
1199
1200     after setup_finalize => sub {
1201         my $app = shift;
1202
1203         ## do stuff here..
1204     };
1205
1206 =cut
1207
1208 sub setup_finalize {
1209     my ($class) = @_;
1210     $class->setup_finished(1);
1211 }
1212
1213 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1214
1215 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1216
1217 Constructs an absolute L<URI> object based on the application root, the
1218 provided path, and the additional arguments and query parameters provided.
1219 When used as a string, provides a textual URI.  If you need more flexibility
1220 than this (i.e. the option to provide relative URIs etc.) see
1221 L<Catalyst::Plugin::SmartURI>.
1222
1223 If no arguments are provided, the URI for the current action is returned.
1224 To return the current action and also provide @args, use
1225 C<< $c->uri_for( $c->action, @args ) >>.
1226
1227 If the first argument is a string, it is taken as a public URI path relative
1228 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1229 relative to the application root (if it does). It is then merged with
1230 C<< $c->request->base >>; any C<@args> are appended as additional path
1231 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1232
1233 If the first argument is a L<Catalyst::Action> it represents an action which
1234 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1235 optional C<\@captures> argument (an arrayref) allows passing the captured
1236 variables that are needed to fill in the paths of Chained and Regex actions;
1237 once the path is resolved, C<uri_for> continues as though a path was
1238 provided, appending any arguments or parameters and creating an absolute
1239 URI.
1240
1241 The captures for the current request can be found in
1242 C<< $c->request->captures >>, and actions can be resolved using
1243 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1244 path, use C<< $c->uri_for_action >> instead.
1245
1246   # Equivalent to $c->req->uri
1247   $c->uri_for($c->action, $c->req->captures,
1248       @{ $c->req->args }, $c->req->params);
1249
1250   # For the Foo action in the Bar controller
1251   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1252
1253   # Path to a static resource
1254   $c->uri_for('/static/images/logo.png');
1255
1256 =cut
1257
1258 sub uri_for {
1259     my ( $c, $path, @args ) = @_;
1260
1261     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1262         $path = $path->path_prefix;
1263         $path =~ s{/+\z}{};
1264         $path .= '/';
1265     }
1266
1267     undef($path) if (defined $path && $path eq '');
1268
1269     my $params =
1270       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1271
1272     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1273     foreach my $arg (@args) {
1274         utf8::encode($arg) if utf8::is_utf8($arg);
1275         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1276     }
1277
1278     if ( blessed($path) ) { # action object
1279         s|/|%2F|g for @args;
1280         my $captures = [ map { s|/|%2F|g; $_; }
1281                         ( scalar @args && ref $args[0] eq 'ARRAY'
1282                          ? @{ shift(@args) }
1283                          : ()) ];
1284
1285         foreach my $capture (@$captures) {
1286             utf8::encode($capture) if utf8::is_utf8($capture);
1287             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1288         }
1289
1290         my $action = $path;
1291         $path = $c->dispatcher->uri_for_action($action, $captures);
1292         if (not defined $path) {
1293             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1294                 if $c->debug;
1295             return undef;
1296         }
1297         $path = '/' if $path eq '';
1298     }
1299
1300     unshift(@args, $path);
1301
1302     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1303         my $namespace = $c->namespace;
1304         if (defined $path) { # cheesy hack to handle path '../foo'
1305            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1306         }
1307         unshift(@args, $namespace || '');
1308     }
1309
1310     # join args with '/', or a blank string
1311     my $args = join('/', grep { defined($_) } @args);
1312     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1313     $args =~ s!^/+!!;
1314     my $base = $c->req->base;
1315     my $class = ref($base);
1316     $base =~ s{(?<!/)$}{/};
1317
1318     my $query = '';
1319
1320     if (my @keys = keys %$params) {
1321       # somewhat lifted from URI::_query's query_form
1322       $query = '?'.join('&', map {
1323           my $val = $params->{$_};
1324           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1325           s/ /+/g;
1326           my $key = $_;
1327           $val = '' unless defined $val;
1328           (map {
1329               my $param = "$_";
1330               utf8::encode( $param ) if utf8::is_utf8($param);
1331               # using the URI::Escape pattern here so utf8 chars survive
1332               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1333               $param =~ s/ /+/g;
1334               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1335       } @keys);
1336     }
1337
1338     my $res = bless(\"${base}${args}${query}", $class);
1339     $res;
1340 }
1341
1342 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1343
1344 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1345
1346 =over
1347
1348 =item $path
1349
1350 A private path to the Catalyst action you want to create a URI for.
1351
1352 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1353 >> and passing the resulting C<$action> and the remaining arguments to C<<
1354 $c->uri_for >>.
1355
1356 You can also pass in a Catalyst::Action object, in which case it is passed to
1357 C<< $c->uri_for >>.
1358
1359 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1360
1361 For example, if the action looks like:
1362
1363  package MyApp::Controller::Users;
1364
1365  sub lst : Path('the-list') {}
1366
1367 You can use:
1368
1369  $c->uri_for_action('/users/lst')
1370
1371 and it will create the URI /users/the-list.
1372
1373 =back
1374
1375 =cut
1376
1377 sub uri_for_action {
1378     my ( $c, $path, @args ) = @_;
1379     my $action = blessed($path)
1380       ? $path
1381       : $c->dispatcher->get_action_by_path($path);
1382     unless (defined $action) {
1383       croak "Can't find action for path '$path'";
1384     }
1385     return $c->uri_for( $action, @args );
1386 }
1387
1388 =head2 $c->welcome_message
1389
1390 Returns the Catalyst welcome HTML page.
1391
1392 =cut
1393
1394 sub welcome_message {
1395     my $c      = shift;
1396     my $name   = $c->config->{name};
1397     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1398     my $prefix = Catalyst::Utils::appprefix( ref $c );
1399     $c->response->content_type('text/html; charset=utf-8');
1400     return <<"EOF";
1401 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1402     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1403 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1404     <head>
1405     <meta http-equiv="Content-Language" content="en" />
1406     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1407         <title>$name on Catalyst $VERSION</title>
1408         <style type="text/css">
1409             body {
1410                 color: #000;
1411                 background-color: #eee;
1412             }
1413             div#content {
1414                 width: 640px;
1415                 margin-left: auto;
1416                 margin-right: auto;
1417                 margin-top: 10px;
1418                 margin-bottom: 10px;
1419                 text-align: left;
1420                 background-color: #ccc;
1421                 border: 1px solid #aaa;
1422             }
1423             p, h1, h2 {
1424                 margin-left: 20px;
1425                 margin-right: 20px;
1426                 font-family: verdana, tahoma, sans-serif;
1427             }
1428             a {
1429                 font-family: verdana, tahoma, sans-serif;
1430             }
1431             :link, :visited {
1432                     text-decoration: none;
1433                     color: #b00;
1434                     border-bottom: 1px dotted #bbb;
1435             }
1436             :link:hover, :visited:hover {
1437                     color: #555;
1438             }
1439             div#topbar {
1440                 margin: 0px;
1441             }
1442             pre {
1443                 margin: 10px;
1444                 padding: 8px;
1445             }
1446             div#answers {
1447                 padding: 8px;
1448                 margin: 10px;
1449                 background-color: #fff;
1450                 border: 1px solid #aaa;
1451             }
1452             h1 {
1453                 font-size: 0.9em;
1454                 font-weight: normal;
1455                 text-align: center;
1456             }
1457             h2 {
1458                 font-size: 1.0em;
1459             }
1460             p {
1461                 font-size: 0.9em;
1462             }
1463             p img {
1464                 float: right;
1465                 margin-left: 10px;
1466             }
1467             span#appname {
1468                 font-weight: bold;
1469                 font-size: 1.6em;
1470             }
1471         </style>
1472     </head>
1473     <body>
1474         <div id="content">
1475             <div id="topbar">
1476                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1477                     $VERSION</h1>
1478              </div>
1479              <div id="answers">
1480                  <p>
1481                  <img src="$logo" alt="Catalyst Logo" />
1482                  </p>
1483                  <p>Welcome to the  world of Catalyst.
1484                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1485                     framework will make web development something you had
1486                     never expected it to be: Fun, rewarding, and quick.</p>
1487                  <h2>What to do now?</h2>
1488                  <p>That really depends  on what <b>you</b> want to do.
1489                     We do, however, provide you with a few starting points.</p>
1490                  <p>If you want to jump right into web development with Catalyst
1491                     you might want to start with a tutorial.</p>
1492 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1493 </pre>
1494 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1495 <pre>
1496 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1497 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1498 </code></pre>
1499                  <h2>What to do next?</h2>
1500                  <p>Next it's time to write an actual application. Use the
1501                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1502                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1503                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1504                     they can save you a lot of work.</p>
1505                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1506                     <p>Also, be sure to check out the vast and growing
1507                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1508                     you are likely to find what you need there.
1509                     </p>
1510
1511                  <h2>Need help?</h2>
1512                  <p>Catalyst has a very active community. Here are the main places to
1513                     get in touch with us.</p>
1514                  <ul>
1515                      <li>
1516                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1517                      </li>
1518                      <li>
1519                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1520                      </li>
1521                      <li>
1522                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1523                      </li>
1524                  </ul>
1525                  <h2>In conclusion</h2>
1526                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1527                     as we enjoyed making it. Please contact us if you have ideas
1528                     for improvement or other feedback.</p>
1529              </div>
1530          </div>
1531     </body>
1532 </html>
1533 EOF
1534 }
1535
1536 =head1 INTERNAL METHODS
1537
1538 These methods are not meant to be used by end users.
1539
1540 =head2 $c->components
1541
1542 Returns a hash of components.
1543
1544 =cut
1545
1546 around components => sub {
1547     my $orig  = shift;
1548     my $class = shift;
1549     my $comps = shift;
1550
1551     return $class->$orig if ( !$comps );
1552
1553 # FIXME: should this ugly kludge exist?
1554     $class->setup_config unless defined $class->container;
1555
1556 # FIXME: should there be a warning here, not to use this accessor to create the components?
1557     my $components = {};
1558
1559     my $containers;
1560     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
1561
1562     for my $component ( keys %$comps ) {
1563         $components->{ $component } = $comps->{$component};
1564
1565         my ($type, $name) = _get_component_type_name($component);
1566
1567 # FIXME: shouldn't the service name be $name?
1568         $containers->{$type}->add_service(Catalyst::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
1569     }
1570
1571     return $class->$orig($components);
1572 };
1573
1574 =head2 $c->context_class
1575
1576 Returns or sets the context class.
1577
1578 =head2 $c->counter
1579
1580 Returns a hashref containing coderefs and execution counts (needed for
1581 deep recursion detection).
1582
1583 =head2 $c->depth
1584
1585 Returns the number of actions on the current internal execution stack.
1586
1587 =head2 $c->dispatch
1588
1589 Dispatches a request to actions.
1590
1591 =cut
1592
1593 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1594
1595 =head2 $c->dispatcher_class
1596
1597 Returns or sets the dispatcher class.
1598
1599 =head2 $c->dump_these
1600
1601 Returns a list of 2-element array references (name, structure) pairs
1602 that will be dumped on the error page in debug mode.
1603
1604 =cut
1605
1606 sub dump_these {
1607     my $c = shift;
1608     [ Request => $c->req ],
1609     [ Response => $c->res ],
1610     [ Stash => $c->stash ],
1611     [ Config => $c->config ];
1612 }
1613
1614 =head2 $c->engine_class
1615
1616 Returns or sets the engine class.
1617
1618 =head2 $c->execute( $class, $coderef )
1619
1620 Execute a coderef in given class and catch exceptions. Errors are available
1621 via $c->error.
1622
1623 =cut
1624
1625 sub execute {
1626     my ( $c, $class, $code ) = @_;
1627     $class = $c->component($class) || $class;
1628     $c->state(0);
1629
1630     if ( $c->depth >= $RECURSION ) {
1631         my $action = $code->reverse();
1632         $action = "/$action" unless $action =~ /->/;
1633         my $error = qq/Deep recursion detected calling "${action}"/;
1634         $c->log->error($error);
1635         $c->error($error);
1636         $c->state(0);
1637         return $c->state;
1638     }
1639
1640     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1641
1642     push( @{ $c->stack }, $code );
1643
1644     no warnings 'recursion';
1645     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1646     #      I have no idea how, ergo $ret (which appears to fix the issue)
1647     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1648
1649     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1650
1651     my $last = pop( @{ $c->stack } );
1652
1653     if ( my $error = $@ ) {
1654         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1655             $error->rethrow if $c->depth > 1;
1656         }
1657         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1658             $error->rethrow if $c->depth > 0;
1659         }
1660         else {
1661             unless ( ref $error ) {
1662                 no warnings 'uninitialized';
1663                 chomp $error;
1664                 my $class = $last->class;
1665                 my $name  = $last->name;
1666                 $error = qq/Caught exception in $class->$name "$error"/;
1667             }
1668             $c->error($error);
1669         }
1670         $c->state(0);
1671     }
1672     return $c->state;
1673 }
1674
1675 sub _stats_start_execute {
1676     my ( $c, $code ) = @_;
1677     my $appclass = ref($c) || $c;
1678     return if ( ( $code->name =~ /^_.*/ )
1679         && ( !$appclass->config->{show_internal_actions} ) );
1680
1681     my $action_name = $code->reverse();
1682     $c->counter->{$action_name}++;
1683
1684     my $action = $action_name;
1685     $action = "/$action" unless $action =~ /->/;
1686
1687     # determine if the call was the result of a forward
1688     # this is done by walking up the call stack and looking for a calling
1689     # sub of Catalyst::forward before the eval
1690     my $callsub = q{};
1691     for my $index ( 2 .. 11 ) {
1692         last
1693         if ( ( caller($index) )[0] eq 'Catalyst'
1694             && ( caller($index) )[3] eq '(eval)' );
1695
1696         if ( ( caller($index) )[3] =~ /forward$/ ) {
1697             $callsub = ( caller($index) )[3];
1698             $action  = "-> $action";
1699             last;
1700         }
1701     }
1702
1703     my $uid = $action_name . $c->counter->{$action_name};
1704
1705     # is this a root-level call or a forwarded call?
1706     if ( $callsub =~ /forward$/ ) {
1707         my $parent = $c->stack->[-1];
1708
1709         # forward, locate the caller
1710         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1711             $c->stats->profile(
1712                 begin  => $action,
1713                 parent => "$parent" . $c->counter->{"$parent"},
1714                 uid    => $uid,
1715             );
1716         }
1717         else {
1718
1719             # forward with no caller may come from a plugin
1720             $c->stats->profile(
1721                 begin => $action,
1722                 uid   => $uid,
1723             );
1724         }
1725     }
1726     else {
1727
1728         # root-level call
1729         $c->stats->profile(
1730             begin => $action,
1731             uid   => $uid,
1732         );
1733     }
1734     return $action;
1735
1736 }
1737
1738 sub _stats_finish_execute {
1739     my ( $c, $info ) = @_;
1740     $c->stats->profile( end => $info );
1741 }
1742
1743 =head2 $c->finalize
1744
1745 Finalizes the request.
1746
1747 =cut
1748
1749 sub finalize {
1750     my $c = shift;
1751
1752     for my $error ( @{ $c->error } ) {
1753         $c->log->error($error);
1754     }
1755
1756     # Allow engine to handle finalize flow (for POE)
1757     my $engine = $c->engine;
1758     if ( my $code = $engine->can('finalize') ) {
1759         $engine->$code($c);
1760     }
1761     else {
1762
1763         $c->finalize_uploads;
1764
1765         # Error
1766         if ( $#{ $c->error } >= 0 ) {
1767             $c->finalize_error;
1768         }
1769
1770         $c->finalize_headers;
1771
1772         # HEAD request
1773         if ( $c->request->method eq 'HEAD' ) {
1774             $c->response->body('');
1775         }
1776
1777         $c->finalize_body;
1778     }
1779
1780     $c->log_response;
1781
1782     if ($c->use_stats) {
1783         my $elapsed = sprintf '%f', $c->stats->elapsed;
1784         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1785         $c->log->info(
1786             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1787     }
1788
1789     return $c->response->status;
1790 }
1791
1792 =head2 $c->finalize_body
1793
1794 Finalizes body.
1795
1796 =cut
1797
1798 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1799
1800 =head2 $c->finalize_cookies
1801
1802 Finalizes cookies.
1803
1804 =cut
1805
1806 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1807
1808 =head2 $c->finalize_error
1809
1810 Finalizes error.
1811
1812 =cut
1813
1814 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1815
1816 =head2 $c->finalize_headers
1817
1818 Finalizes headers.
1819
1820 =cut
1821
1822 sub finalize_headers {
1823     my $c = shift;
1824
1825     my $response = $c->response; #accessor calls can add up?
1826
1827     # Check if we already finalized headers
1828     return if $response->finalized_headers;
1829
1830     # Handle redirects
1831     if ( my $location = $response->redirect ) {
1832         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1833         $response->header( Location => $location );
1834
1835         if ( !$response->has_body ) {
1836             # Add a default body if none is already present
1837             $response->body(
1838                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1839             );
1840         }
1841     }
1842
1843     # Content-Length
1844     if ( defined $response->body && length $response->body && !$response->content_length ) {
1845
1846         # get the length from a filehandle
1847         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1848         {
1849             my $stat = stat $response->body;
1850             if ( $stat && $stat->size > 0 ) {
1851                 $response->content_length( $stat->size );
1852             }
1853             else {
1854                 $c->log->warn('Serving filehandle without a content-length');
1855             }
1856         }
1857         else {
1858             # everything should be bytes at this point, but just in case
1859             $response->content_length( length( $response->body ) );
1860         }
1861     }
1862
1863     # Errors
1864     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1865         $response->headers->remove_header("Content-Length");
1866         $response->body('');
1867     }
1868
1869     $c->finalize_cookies;
1870
1871     $c->engine->finalize_headers( $c, @_ );
1872
1873     # Done
1874     $response->finalized_headers(1);
1875 }
1876
1877 =head2 $c->finalize_output
1878
1879 An alias for finalize_body.
1880
1881 =head2 $c->finalize_read
1882
1883 Finalizes the input after reading is complete.
1884
1885 =cut
1886
1887 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1888
1889 =head2 $c->finalize_uploads
1890
1891 Finalizes uploads. Cleans up any temporary files.
1892
1893 =cut
1894
1895 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1896
1897 =head2 $c->get_action( $action, $namespace )
1898
1899 Gets an action in a given namespace.
1900
1901 =cut
1902
1903 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1904
1905 =head2 $c->get_actions( $action, $namespace )
1906
1907 Gets all actions of a given name in a namespace and all parent
1908 namespaces.
1909
1910 =cut
1911
1912 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1913
1914 =head2 $app->handle_request( @arguments )
1915
1916 Called to handle each HTTP request.
1917
1918 =cut
1919
1920 sub handle_request {
1921     my ( $class, @arguments ) = @_;
1922
1923     # Always expect worst case!
1924     my $status = -1;
1925     eval {
1926         if ($class->debug) {
1927             my $secs = time - $START || 1;
1928             my $av = sprintf '%.3f', $COUNT / $secs;
1929             my $time = localtime time;
1930             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1931         }
1932
1933         my $c = $class->prepare(@arguments);
1934         $c->dispatch;
1935         $status = $c->finalize;
1936     };
1937
1938     if ( my $error = $@ ) {
1939         chomp $error;
1940         $class->log->error(qq/Caught exception in engine "$error"/);
1941     }
1942
1943     $COUNT++;
1944
1945     if(my $coderef = $class->log->can('_flush')){
1946         $class->log->$coderef();
1947     }
1948     return $status;
1949 }
1950
1951 =head2 $c->prepare( @arguments )
1952
1953 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1954 etc.).
1955
1956 =cut
1957
1958 sub prepare {
1959     my ( $class, @arguments ) = @_;
1960
1961     # XXX
1962     # After the app/ctxt split, this should become an attribute based on something passed
1963     # into the application.
1964     $class->context_class( ref $class || $class ) unless $class->context_class;
1965
1966     my $c = $class->context_class->new({});
1967
1968     # For on-demand data
1969     $c->request->_context($c);
1970     $c->response->_context($c);
1971
1972     #surely this is not the most efficient way to do things...
1973     $c->stats($class->stats_class->new)->enable($c->use_stats);
1974     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1975         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1976     }
1977
1978     #XXX reuse coderef from can
1979     # Allow engine to direct the prepare flow (for POE)
1980     if ( $c->engine->can('prepare') ) {
1981         $c->engine->prepare( $c, @arguments );
1982     }
1983     else {
1984         $c->prepare_request(@arguments);
1985         $c->prepare_connection;
1986         $c->prepare_query_parameters;
1987         $c->prepare_headers;
1988         $c->prepare_cookies;
1989         $c->prepare_path;
1990
1991         # Prepare the body for reading, either by prepare_body
1992         # or the user, if they are using $c->read
1993         $c->prepare_read;
1994
1995         # Parse the body unless the user wants it on-demand
1996         unless ( ref($c)->config->{parse_on_demand} ) {
1997             $c->prepare_body;
1998         }
1999     }
2000
2001     my $method  = $c->req->method  || '';
2002     my $path    = $c->req->path;
2003     $path       = '/' unless length $path;
2004     my $address = $c->req->address || '';
2005
2006     $c->log_request;
2007
2008     $c->prepare_action;
2009
2010     return $c;
2011 }
2012
2013 =head2 $c->prepare_action
2014
2015 Prepares action. See L<Catalyst::Dispatcher>.
2016
2017 =cut
2018
2019 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2020
2021 =head2 $c->prepare_body
2022
2023 Prepares message body.
2024
2025 =cut
2026
2027 sub prepare_body {
2028     my $c = shift;
2029
2030     return if $c->request->_has_body;
2031
2032     # Initialize on-demand data
2033     $c->engine->prepare_body( $c, @_ );
2034     $c->prepare_parameters;
2035     $c->prepare_uploads;
2036 }
2037
2038 =head2 $c->prepare_body_chunk( $chunk )
2039
2040 Prepares a chunk of data before sending it to L<HTTP::Body>.
2041
2042 See L<Catalyst::Engine>.
2043
2044 =cut
2045
2046 sub prepare_body_chunk {
2047     my $c = shift;
2048     $c->engine->prepare_body_chunk( $c, @_ );
2049 }
2050
2051 =head2 $c->prepare_body_parameters
2052
2053 Prepares body parameters.
2054
2055 =cut
2056
2057 sub prepare_body_parameters {
2058     my $c = shift;
2059     $c->engine->prepare_body_parameters( $c, @_ );
2060 }
2061
2062 =head2 $c->prepare_connection
2063
2064 Prepares connection.
2065
2066 =cut
2067
2068 sub prepare_connection {
2069     my $c = shift;
2070     $c->engine->prepare_connection( $c, @_ );
2071 }
2072
2073 =head2 $c->prepare_cookies
2074
2075 Prepares cookies.
2076
2077 =cut
2078
2079 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2080
2081 =head2 $c->prepare_headers
2082
2083 Prepares headers.
2084
2085 =cut
2086
2087 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2088
2089 =head2 $c->prepare_parameters
2090
2091 Prepares parameters.
2092
2093 =cut
2094
2095 sub prepare_parameters {
2096     my $c = shift;
2097     $c->prepare_body_parameters;
2098     $c->engine->prepare_parameters( $c, @_ );
2099 }
2100
2101 =head2 $c->prepare_path
2102
2103 Prepares path and base.
2104
2105 =cut
2106
2107 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2108
2109 =head2 $c->prepare_query_parameters
2110
2111 Prepares query parameters.
2112
2113 =cut
2114
2115 sub prepare_query_parameters {
2116     my $c = shift;
2117
2118     $c->engine->prepare_query_parameters( $c, @_ );
2119 }
2120
2121 =head2 $c->log_request
2122
2123 Writes information about the request to the debug logs.  This includes:
2124
2125 =over 4
2126
2127 =item * Request method, path, and remote IP address
2128
2129 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2130
2131 =item * Request parameters
2132
2133 =item * File uploads
2134
2135 =back
2136
2137 =cut
2138
2139 sub log_request {
2140     my $c = shift;
2141
2142     return unless $c->debug;
2143
2144     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2145     my $request = $dump->[1];
2146
2147     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2148     $method ||= '';
2149     $path = '/' unless length $path;
2150     $address ||= '';
2151     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2152
2153     $c->log_request_headers($request->headers);
2154
2155     if ( my $keywords = $request->query_keywords ) {
2156         $c->log->debug("Query keywords are: $keywords");
2157     }
2158
2159     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2160
2161     $c->log_request_uploads($request);
2162 }
2163
2164 =head2 $c->log_response
2165
2166 Writes information about the response to the debug logs by calling
2167 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2168
2169 =cut
2170
2171 sub log_response {
2172     my $c = shift;
2173
2174     return unless $c->debug;
2175
2176     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2177     my $response = $dump->[1];
2178
2179     $c->log_response_status_line($response);
2180     $c->log_response_headers($response->headers);
2181 }
2182
2183 =head2 $c->log_response_status_line($response)
2184
2185 Writes one line of information about the response to the debug logs.  This includes:
2186
2187 =over 4
2188
2189 =item * Response status code
2190
2191 =item * Content-Type header (if present)
2192
2193 =item * Content-Length header (if present)
2194
2195 =back
2196
2197 =cut
2198
2199 sub log_response_status_line {
2200     my ($c, $response) = @_;
2201
2202     $c->log->debug(
2203         sprintf(
2204             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2205             $response->status                            || 'unknown',
2206             $response->headers->header('Content-Type')   || 'unknown',
2207             $response->headers->header('Content-Length') || 'unknown'
2208         )
2209     );
2210 }
2211
2212 =head2 $c->log_response_headers($headers);
2213
2214 Hook method which can be wrapped by plugins to log the responseheaders.
2215 No-op in the default implementation.
2216
2217 =cut
2218
2219 sub log_response_headers {}
2220
2221 =head2 $c->log_request_parameters( query => {}, body => {} )
2222
2223 Logs request parameters to debug logs
2224
2225 =cut
2226
2227 sub log_request_parameters {
2228     my $c          = shift;
2229     my %all_params = @_;
2230
2231     return unless $c->debug;
2232
2233     my $column_width = Catalyst::Utils::term_width() - 44;
2234     foreach my $type (qw(query body)) {
2235         my $params = $all_params{$type};
2236         next if ! keys %$params;
2237         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2238         for my $key ( sort keys %$params ) {
2239             my $param = $params->{$key};
2240             my $value = defined($param) ? $param : '';
2241             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2242         }
2243         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2244     }
2245 }
2246
2247 =head2 $c->log_request_uploads
2248
2249 Logs file uploads included in the request to the debug logs.
2250 The parameter name, filename, file type, and file size are all included in
2251 the debug logs.
2252
2253 =cut
2254
2255 sub log_request_uploads {
2256     my $c = shift;
2257     my $request = shift;
2258     return unless $c->debug;
2259     my $uploads = $request->uploads;
2260     if ( keys %$uploads ) {
2261         my $t = Text::SimpleTable->new(
2262             [ 12, 'Parameter' ],
2263             [ 26, 'Filename' ],
2264             [ 18, 'Type' ],
2265             [ 9,  'Size' ]
2266         );
2267         for my $key ( sort keys %$uploads ) {
2268             my $upload = $uploads->{$key};
2269             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2270                 $t->row( $key, $u->filename, $u->type, $u->size );
2271             }
2272         }
2273         $c->log->debug( "File Uploads are:\n" . $t->draw );
2274     }
2275 }
2276
2277 =head2 $c->log_request_headers($headers);
2278
2279 Hook method which can be wrapped by plugins to log the request headers.
2280 No-op in the default implementation.
2281
2282 =cut
2283
2284 sub log_request_headers {}
2285
2286 =head2 $c->log_headers($type => $headers)
2287
2288 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2289
2290 =cut
2291
2292 sub log_headers {
2293     my $c       = shift;
2294     my $type    = shift;
2295     my $headers = shift;    # an HTTP::Headers instance
2296
2297     return unless $c->debug;
2298
2299     my $column_width = Catalyst::Utils::term_width() - 28;
2300     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2301     $headers->scan(
2302         sub {
2303             my ( $name, $value ) = @_;
2304             $t->row( $name, $value );
2305         }
2306     );
2307     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2308 }
2309
2310
2311 =head2 $c->prepare_read
2312
2313 Prepares the input for reading.
2314
2315 =cut
2316
2317 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2318
2319 =head2 $c->prepare_request
2320
2321 Prepares the engine request.
2322
2323 =cut
2324
2325 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2326
2327 =head2 $c->prepare_uploads
2328
2329 Prepares uploads.
2330
2331 =cut
2332
2333 sub prepare_uploads {
2334     my $c = shift;
2335
2336     $c->engine->prepare_uploads( $c, @_ );
2337 }
2338
2339 =head2 $c->prepare_write
2340
2341 Prepares the output for writing.
2342
2343 =cut
2344
2345 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2346
2347 =head2 $c->request_class
2348
2349 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2350
2351 =head2 $c->response_class
2352
2353 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2354
2355 =head2 $c->read( [$maxlength] )
2356
2357 Reads a chunk of data from the request body. This method is designed to
2358 be used in a while loop, reading C<$maxlength> bytes on every call.
2359 C<$maxlength> defaults to the size of the request if not specified.
2360
2361 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2362 directly.
2363
2364 Warning: If you use read(), Catalyst will not process the body,
2365 so you will not be able to access POST parameters or file uploads via
2366 $c->request.  You must handle all body parsing yourself.
2367
2368 =cut
2369
2370 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2371
2372 =head2 $c->run
2373
2374 Starts the engine.
2375
2376 =cut
2377
2378 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2379
2380 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2381
2382 Sets an action in a given namespace.
2383
2384 =cut
2385
2386 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2387
2388 =head2 $c->setup_actions($component)
2389
2390 Sets up actions for a component.
2391
2392 =cut
2393
2394 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2395
2396 =head2 $c->setup_config
2397
2398 =cut
2399
2400 sub setup_config {
2401     my $class = shift;
2402
2403     my %args = %{ $class->config || {} };
2404
2405     my @container_classes = ( "${class}::Container", 'Catalyst::Container');
2406     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2407
2408     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2409
2410     my $container = $container_class->new( %args, name => "$class" );
2411     $class->container($container);
2412
2413     my $config = $container->resolve(service => 'config');
2414     $class->config($config);
2415     $class->finalize_config; # back-compat
2416 }
2417
2418 =head $c->finalize_config
2419
2420 =cut
2421
2422 sub finalize_config { }
2423
2424 =head2 $c->setup_components
2425
2426 This method is called internally to set up the application's components.
2427
2428 It finds modules by calling the L<locate_components> method, expands them to
2429 package names with the L<expand_component_module> method, and then installs
2430 each component into the application.
2431
2432 The C<setup_components> config option is passed to both of the above methods.
2433
2434 Installation of each component is performed by the L<setup_component> method,
2435 below.
2436
2437 =cut
2438
2439 sub setup_components {
2440     my $class = shift;
2441
2442     my $config  = $class->config->{ setup_components };
2443
2444     my @comps = $class->locate_components($config);
2445     my %comps = map { $_ => 1 } @comps;
2446
2447     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2448     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2449         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2450     ) if $deprecatedcatalyst_component_names;
2451
2452     for my $component ( @comps ) {
2453
2454         # We pass ignore_loaded here so that overlay files for (e.g.)
2455         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2456         # we know M::P::O found a file on disk so this is safe
2457
2458         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2459     }
2460
2461     my $containers;
2462     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
2463
2464     for my $component (@comps) {
2465         my $instance = $class->components->{ $component } = $class->setup_component($component);
2466         if ( my ($type, $name) = _get_component_type_name($component) ) {
2467             $containers->{$type}->add_service(Catalyst::BlockInjection->new( name => $name, block => sub { return $instance } ));
2468         }
2469         my @expanded_components = $instance->can('expand_modules')
2470             ? $instance->expand_modules( $component, $config )
2471             : $class->expand_component_module( $component, $config );
2472         for my $component (@expanded_components) {
2473             next if $comps{$component};
2474
2475             $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @expanded_components;
2476             $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2477                 qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2478             ) if $deprecatedcatalyst_component_names;
2479
2480             if (my ($type, $name) = _get_component_type_name($component)) {
2481                 $containers->{$type}->add_service(Catalyst::BlockInjection->new( name => $name, block => sub { return $class->setup_component($component) } ));
2482             }
2483
2484             $class->components->{ $component } = $class->setup_component($component);
2485         }
2486     }
2487 }
2488
2489 sub _get_component_type_name {
2490     my $component = shift;
2491     my @parts     = split /::/, $component;
2492
2493     while (my $type = shift @parts) {
2494         return ('controller', join '::', @parts)
2495             if $type =~ /^(c|controller)$/i;
2496
2497         return ('model', join '::', @parts)
2498             if $type =~ /^(m|model)$/i;
2499
2500         return ('view', join '::', @parts)
2501             if $type =~ /^(v|view)$/i;
2502     }
2503 }
2504
2505 =head2 $c->locate_components( $setup_component_config )
2506
2507 This method is meant to provide a list of component modules that should be
2508 setup for the application.  By default, it will use L<Module::Pluggable>.
2509
2510 Specify a C<setup_components> config option to pass additional options directly
2511 to L<Module::Pluggable>. To add additional search paths, specify a key named
2512 C<search_extra> as an array reference. Items in the array beginning with C<::>
2513 will have the application class name prepended to them.
2514
2515 =cut
2516
2517 sub locate_components {
2518     my $class  = shift;
2519     my $config = shift;
2520
2521     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2522     my $extra   = delete $config->{ search_extra } || [];
2523
2524     push @paths, @$extra;
2525
2526     my $locator = Module::Pluggable::Object->new(
2527         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2528         %$config
2529     );
2530
2531     # XXX think about ditching this sort entirely
2532     my @comps = sort { length $a <=> length $b } $locator->plugins;
2533
2534     return @comps;
2535 }
2536
2537 =head2 $c->expand_component_module( $component, $setup_component_config )
2538
2539 Components found by C<locate_components> will be passed to this method, which
2540 is expected to return a list of component (package) names to be set up.
2541
2542 =cut
2543
2544 sub expand_component_module {
2545     my ($class, $module) = @_;
2546     return Devel::InnerPackage::list_packages( $module );
2547 }
2548
2549 =head2 $c->setup_component
2550
2551 =cut
2552
2553 sub setup_component {
2554     my( $class, $component ) = @_;
2555
2556     unless ( $component->can( 'COMPONENT' ) ) {
2557         return $component;
2558     }
2559
2560     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2561     my $config = $class->config->{ $suffix } || {};
2562     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2563     # methods also pass it. local to avoid pointlessly shitting in config
2564     # for the debug screen, as $component is already the key name.
2565     local $config->{catalyst_component_name} = $component;
2566
2567     my $instance = eval { $component->COMPONENT( $class, $config ); };
2568
2569     if ( my $error = $@ ) {
2570         chomp $error;
2571         Catalyst::Exception->throw(
2572             message => qq/Couldn't instantiate component "$component", "$error"/
2573         );
2574     }
2575     elsif (!blessed $instance) {
2576         my $metaclass = Moose::Util::find_meta($component);
2577         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2578         my $component_method_from = $method_meta->associated_metaclass->name;
2579         my $value = defined($instance) ? $instance : 'undef';
2580         Catalyst::Exception->throw(
2581             message =>
2582             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2583         );
2584     }
2585
2586     return $instance;
2587 }
2588
2589 =head2 $c->setup_dispatcher
2590
2591 Sets up dispatcher.
2592
2593 =cut
2594
2595 sub setup_dispatcher {
2596     my ( $class, $dispatcher ) = @_;
2597
2598     if ($dispatcher) {
2599         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2600     }
2601
2602     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2603         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2604     }
2605
2606     unless ($dispatcher) {
2607         $dispatcher = $class->dispatcher_class;
2608     }
2609
2610     Class::MOP::load_class($dispatcher);
2611
2612     # dispatcher instance
2613     $class->dispatcher( $dispatcher->new );
2614 }
2615
2616 =head2 $c->setup_engine
2617
2618 Sets up engine.
2619
2620 =cut
2621
2622 sub setup_engine {
2623     my ( $class, $engine ) = @_;
2624
2625     if ($engine) {
2626         $engine = 'Catalyst::Engine::' . $engine;
2627     }
2628
2629     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2630         $engine = 'Catalyst::Engine::' . $env;
2631     }
2632
2633     if ( $ENV{MOD_PERL} ) {
2634         my $meta = Class::MOP::get_metaclass_by_name($class);
2635
2636         # create the apache method
2637         $meta->add_method('apache' => sub { shift->engine->apache });
2638
2639         my ( $software, $version ) =
2640           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2641
2642         $version =~ s/_//g;
2643         $version =~ s/(\.[^.]+)\./$1/g;
2644
2645         if ( $software eq 'mod_perl' ) {
2646
2647             if ( !$engine ) {
2648
2649                 if ( $version >= 1.99922 ) {
2650                     $engine = 'Catalyst::Engine::Apache2::MP20';
2651                 }
2652
2653                 elsif ( $version >= 1.9901 ) {
2654                     $engine = 'Catalyst::Engine::Apache2::MP19';
2655                 }
2656
2657                 elsif ( $version >= 1.24 ) {
2658                     $engine = 'Catalyst::Engine::Apache::MP13';
2659                 }
2660
2661                 else {
2662                     Catalyst::Exception->throw( message =>
2663                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2664                 }
2665
2666             }
2667
2668             # install the correct mod_perl handler
2669             if ( $version >= 1.9901 ) {
2670                 *handler = sub  : method {
2671                     shift->handle_request(@_);
2672                 };
2673             }
2674             else {
2675                 *handler = sub ($$) { shift->handle_request(@_) };
2676             }
2677
2678         }
2679
2680         elsif ( $software eq 'Zeus-Perl' ) {
2681             $engine = 'Catalyst::Engine::Zeus';
2682         }
2683
2684         else {
2685             Catalyst::Exception->throw(
2686                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2687         }
2688     }
2689
2690     unless ($engine) {
2691         $engine = $class->engine_class;
2692     }
2693
2694     Class::MOP::load_class($engine);
2695
2696     # check for old engines that are no longer compatible
2697     my $old_engine;
2698     if ( $engine->isa('Catalyst::Engine::Apache')
2699         && !Catalyst::Engine::Apache->VERSION )
2700     {
2701         $old_engine = 1;
2702     }
2703
2704     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2705         && Catalyst::Engine::Server->VERSION le '0.02' )
2706     {
2707         $old_engine = 1;
2708     }
2709
2710     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2711         && $engine->VERSION eq '0.01' )
2712     {
2713         $old_engine = 1;
2714     }
2715
2716     elsif ($engine->isa('Catalyst::Engine::Zeus')
2717         && $engine->VERSION eq '0.01' )
2718     {
2719         $old_engine = 1;
2720     }
2721
2722     if ($old_engine) {
2723         Catalyst::Exception->throw( message =>
2724               qq/Engine "$engine" is not supported by this version of Catalyst/
2725         );
2726     }
2727
2728     # engine instance
2729     $class->engine( $engine->new );
2730 }
2731
2732 =head2 $c->setup_home
2733
2734 Sets up the home directory.
2735
2736 =cut
2737
2738 sub setup_home {
2739     my ( $class, $home ) = @_;
2740
2741     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2742         $home = $env;
2743     }
2744
2745     $home ||= Catalyst::Utils::home($class);
2746
2747     if ($home) {
2748         #I remember recently being scolded for assigning config values like this
2749         $class->config->{home} ||= $home;
2750         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2751     }
2752 }
2753
2754 =head2 $c->setup_log
2755
2756 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2757 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2758 log to.
2759
2760 This method also installs a C<debug> method that returns a true value into the
2761 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2762 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2763
2764 Note that if the log has already been setup, by either a previous call to
2765 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2766 that this method won't actually set up the log object.
2767
2768 =cut
2769
2770 sub setup_log {
2771     my ( $class, $levels ) = @_;
2772
2773     $levels ||= '';
2774     $levels =~ s/^\s+//;
2775     $levels =~ s/\s+$//;
2776     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2777
2778     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2779     if ( defined $env_debug ) {
2780         $levels{debug} = 1 if $env_debug; # Ugly!
2781         delete($levels{debug}) unless $env_debug;
2782     }
2783
2784     unless ( $class->log ) {
2785         $class->log( Catalyst::Log->new(keys %levels) );
2786     }
2787
2788     if ( $levels{debug} ) {
2789         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2790         $class->log->debug('Debug messages enabled');
2791     }
2792 }
2793
2794 =head2 $c->setup_plugins
2795
2796 Sets up plugins.
2797
2798 =cut
2799
2800 =head2 $c->setup_stats
2801
2802 Sets up timing statistics class.
2803
2804 =cut
2805
2806 sub setup_stats {
2807     my ( $class, $stats ) = @_;
2808
2809     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2810
2811     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2812     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2813         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2814         $class->log->debug('Statistics enabled');
2815     }
2816 }
2817
2818
2819 =head2 $c->registered_plugins
2820
2821 Returns a sorted list of the plugins which have either been stated in the
2822 import list or which have been added via C<< MyApp->plugin(@args); >>.
2823
2824 If passed a given plugin name, it will report a boolean value indicating
2825 whether or not that plugin is loaded.  A fully qualified name is required if
2826 the plugin name does not begin with C<Catalyst::Plugin::>.
2827
2828  if ($c->registered_plugins('Some::Plugin')) {
2829      ...
2830  }
2831
2832 =cut
2833
2834 {
2835
2836     sub registered_plugins {
2837         my $proto = shift;
2838         return sort keys %{ $proto->_plugins } unless @_;
2839         my $plugin = shift;
2840         return 1 if exists $proto->_plugins->{$plugin};
2841         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2842     }
2843
2844     sub _register_plugin {
2845         my ( $proto, $plugin, $instant ) = @_;
2846         my $class = ref $proto || $proto;
2847
2848         Class::MOP::load_class( $plugin );
2849         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2850             if $plugin->isa( 'Catalyst::Component' );
2851         $proto->_plugins->{$plugin} = 1;
2852         unless ($instant) {
2853             my $meta = Class::MOP::get_metaclass_by_name($class);
2854             $meta->superclasses($plugin, $meta->superclasses);
2855         }
2856         return $class;
2857     }
2858
2859     sub setup_plugins {
2860         my ( $class, $plugins ) = @_;
2861
2862         $class->_plugins( {} ) unless $class->_plugins;
2863         $plugins = Data::OptList::mkopt($plugins || []);
2864
2865         my @plugins = map {
2866             [ Catalyst::Utils::resolve_namespace(
2867                   $class . '::Plugin',
2868                   'Catalyst::Plugin', $_->[0]
2869               ),
2870               $_->[1],
2871             ]
2872          } @{ $plugins };
2873
2874         for my $plugin ( reverse @plugins ) {
2875             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2876             my $meta = find_meta($plugin->[0]);
2877             next if $meta && $meta->isa('Moose::Meta::Role');
2878
2879             $class->_register_plugin($plugin->[0]);
2880         }
2881
2882         my @roles =
2883             map  { $_->[0]->name, $_->[1] }
2884             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2885             map  { [find_meta($_->[0]), $_->[1]] }
2886             @plugins;
2887
2888         Moose::Util::apply_all_roles(
2889             $class => @roles
2890         ) if @roles;
2891     }
2892 }
2893
2894 =head2 $c->stack
2895
2896 Returns an arrayref of the internal execution stack (actions that are
2897 currently executing).
2898
2899 =head2 $c->stats
2900
2901 Returns the current timing statistics object. By default Catalyst uses
2902 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2903 L<< stats_class|/"$c->stats_class" >>.
2904
2905 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2906 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2907 profile explicitly, although MyApp.pm still won't profile nor output anything
2908 by itself.
2909
2910 =head2 $c->stats_class
2911
2912 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2913
2914 =head2 $c->use_stats
2915
2916 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2917
2918 Note that this is a static method, not an accessor and should be overridden
2919 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2920
2921 =cut
2922
2923 sub use_stats { 0 }
2924
2925
2926 =head2 $c->write( $data )
2927
2928 Writes $data to the output stream. When using this method directly, you
2929 will need to manually set the C<Content-Length> header to the length of
2930 your output data, if known.
2931
2932 =cut
2933
2934 sub write {
2935     my $c = shift;
2936
2937     # Finalize headers if someone manually writes output
2938     $c->finalize_headers;
2939
2940     return $c->engine->write( $c, @_ );
2941 }
2942
2943 =head2 version
2944
2945 Returns the Catalyst version number. Mostly useful for "powered by"
2946 messages in template systems.
2947
2948 =cut
2949
2950 sub version { return $Catalyst::VERSION }
2951
2952 =head1 CONFIGURATION
2953
2954 There are a number of 'base' config variables which can be set:
2955
2956 =over
2957
2958 =item *
2959
2960 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2961
2962 =item *
2963
2964 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2965
2966 =item *
2967
2968 C<disable_component_resolution_regex_fallback> - Turns
2969 off the deprecated component resolution functionality so
2970 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2971 are called then regex search will not be attempted on string values and
2972 instead C<undef> will be returned.
2973
2974 =item *
2975
2976 C<home> - The application home directory. In an uninstalled application,
2977 this is the top level application directory. In an installed application,
2978 this will be the directory containing C<< MyApp.pm >>.
2979
2980 =item *
2981
2982 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2983
2984 =item *
2985
2986 C<name> - The name of the application in debug messages and the debug and
2987 welcome screens
2988
2989 =item *
2990
2991 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2992 until it is accessed. This allows you to (for example) check authentication (and reject
2993 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2994
2995 =item *
2996
2997 C<root> - The root directory for templates. Usually this is just a
2998 subdirectory of the home directory, but you can set it to change the
2999 templates to a different directory.
3000
3001 =item *
3002
3003 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3004 namespaces from which components will be loaded (and constructed and stored in
3005 C<< $c->components >>).
3006
3007 =item *
3008
3009 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3010 to be shown in hit debug tables in the test server.
3011
3012 =item *
3013
3014 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3015 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
3016 for more information.
3017
3018 =item *
3019
3020 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3021
3022 =back
3023
3024 =head1 INTERNAL ACTIONS
3025
3026 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3027 C<_ACTION>, and C<_END>. These are by default not shown in the private
3028 action table, but you can make them visible with a config parameter.
3029
3030     MyApp->config(show_internal_actions => 1);
3031
3032 =head1 ON-DEMAND PARSER
3033
3034 The request body is usually parsed at the beginning of a request,
3035 but if you want to handle input yourself, you can enable on-demand
3036 parsing with a config parameter.
3037
3038     MyApp->config(parse_on_demand => 1);
3039
3040 =head1 PROXY SUPPORT
3041
3042 Many production servers operate using the common double-server approach,
3043 with a lightweight frontend web server passing requests to a larger
3044 backend server. An application running on the backend server must deal
3045 with two problems: the remote user always appears to be C<127.0.0.1> and
3046 the server's hostname will appear to be C<localhost> regardless of the
3047 virtual host that the user connected through.
3048
3049 Catalyst will automatically detect this situation when you are running
3050 the frontend and backend servers on the same machine. The following
3051 changes are made to the request.
3052
3053     $c->req->address is set to the user's real IP address, as read from
3054     the HTTP X-Forwarded-For header.
3055
3056     The host value for $c->req->base and $c->req->uri is set to the real
3057     host, as read from the HTTP X-Forwarded-Host header.
3058
3059 Additionally, you may be running your backend application on an insecure
3060 connection (port 80) while your frontend proxy is running under SSL.  If there
3061 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3062 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3063 be created properly.
3064
3065 In the case of passing in:
3066
3067     X-Forwarded-Port: 443
3068
3069 All calls to C<uri_for> will result in an https link, as is expected.
3070
3071 Obviously, your web server must support these headers for this to work.
3072
3073 In a more complex server farm environment where you may have your
3074 frontend proxy server(s) on different machines, you will need to set a
3075 configuration option to tell Catalyst to read the proxied data from the
3076 headers.
3077
3078     MyApp->config(using_frontend_proxy => 1);
3079
3080 If you do not wish to use the proxy support at all, you may set:
3081
3082     MyApp->config(ignore_frontend_proxy => 1);
3083
3084 =head1 THREAD SAFETY
3085
3086 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3087 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3088 believe the Catalyst core to be thread-safe.
3089
3090 If you plan to operate in a threaded environment, remember that all other
3091 modules you are using must also be thread-safe. Some modules, most notably
3092 L<DBD::SQLite>, are not thread-safe.
3093
3094 =head1 SUPPORT
3095
3096 IRC:
3097
3098     Join #catalyst on irc.perl.org.
3099
3100 Mailing Lists:
3101
3102     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3103     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3104
3105 Web:
3106
3107     http://catalyst.perl.org
3108
3109 Wiki:
3110
3111     http://dev.catalyst.perl.org
3112
3113 =head1 SEE ALSO
3114
3115 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3116
3117 =head2 L<Catalyst::Manual> - The Catalyst Manual
3118
3119 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3120
3121 =head2 L<Catalyst::Engine> - Core engine
3122
3123 =head2 L<Catalyst::Log> - Log class.
3124
3125 =head2 L<Catalyst::Request> - Request object
3126
3127 =head2 L<Catalyst::Response> - Response object
3128
3129 =head2 L<Catalyst::Test> - The test suite.
3130
3131 =head1 PROJECT FOUNDER
3132
3133 sri: Sebastian Riedel <sri@cpan.org>
3134
3135 =head1 CONTRIBUTORS
3136
3137 abw: Andy Wardley
3138
3139 acme: Leon Brocard <leon@astray.com>
3140
3141 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3142
3143 Andrew Bramble
3144
3145 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3146
3147 Andrew Ruthven
3148
3149 andyg: Andy Grundman <andy@hybridized.org>
3150
3151 audreyt: Audrey Tang
3152
3153 bricas: Brian Cassidy <bricas@cpan.org>
3154
3155 Caelum: Rafael Kitover <rkitover@io.com>
3156
3157 chansen: Christian Hansen
3158
3159 chicks: Christopher Hicks
3160
3161 Chisel Wright C<pause@herlpacker.co.uk>
3162
3163 Danijel Milicevic C<me@danijel.de>
3164
3165 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3166
3167 David Naughton, C<naughton@umn.edu>
3168
3169 David E. Wheeler
3170
3171 dhoss: Devin Austin <dhoss@cpan.org>
3172
3173 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3174
3175 Drew Taylor
3176
3177 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3178
3179 esskar: Sascha Kiefer
3180
3181 fireartist: Carl Franks <cfranks@cpan.org>
3182
3183 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3184
3185 gabb: Danijel Milicevic
3186
3187 Gary Ashton Jones
3188
3189 Gavin Henry C<ghenry@perl.me.uk>
3190
3191 Geoff Richards
3192
3193 groditi: Guillermo Roditi <groditi@gmail.com>
3194
3195 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3196
3197 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3198
3199 jcamacho: Juan Camacho
3200
3201 jester: Jesse Sheidlower C<jester@panix.com>
3202
3203 jhannah: Jay Hannah <jay@jays.net>
3204
3205 Jody Belka
3206
3207 Johan Lindstrom
3208
3209 jon: Jon Schutz <jjschutz@cpan.org>
3210
3211 Jonathan Rockway C<< <jrockway@cpan.org> >>
3212
3213 Kieren Diment C<kd@totaldatasolution.com>
3214
3215 konobi: Scott McWhirter <konobi@cpan.org>
3216
3217 marcus: Marcus Ramberg <mramberg@cpan.org>
3218
3219 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3220
3221 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3222
3223 mugwump: Sam Vilain
3224
3225 naughton: David Naughton
3226
3227 ningu: David Kamholz <dkamholz@cpan.org>
3228
3229 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3230
3231 numa: Dan Sully <daniel@cpan.org>
3232
3233 obra: Jesse Vincent
3234
3235 Octavian Rasnita
3236
3237 omega: Andreas Marienborg
3238
3239 Oleg Kostyuk <cub.uanic@gmail.com>
3240
3241 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3242
3243 rafl: Florian Ragwitz <rafl@debian.org>
3244
3245 random: Roland Lammel <lammel@cpan.org>
3246
3247 Robert Sedlacek C<< <rs@474.at> >>
3248
3249 SpiceMan: Marcel Montes
3250
3251 sky: Arthur Bergman
3252
3253 szbalint: Balint Szilakszi <szbalint@cpan.org>
3254
3255 t0m: Tomas Doran <bobtfish@bobtfish.net>
3256
3257 Ulf Edvinsson
3258
3259 Viljo Marrandi C<vilts@yahoo.com>
3260
3261 Will Hawes C<info@whawes.co.uk>
3262
3263 willert: Sebastian Willert <willert@cpan.org>
3264
3265 wreis: Wallace Reis <wallace@reis.org.br>
3266
3267 Yuval Kogman, C<nothingmuch@woobling.org>
3268
3269 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3270
3271 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3272
3273 =head1 COPYRIGHT
3274
3275 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3276
3277 =head1 LICENSE
3278
3279 This library is free software. You can redistribute it and/or modify it under
3280 the same terms as Perl itself.
3281
3282 =cut
3283
3284 no Moose;
3285
3286 __PACKAGE__->meta->make_immutable;
3287
3288 1;