lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken blessed/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 __PACKAGE__->mk_accessors(
  34     qw/counter request response state action stack namespace stats/
  35 );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class stats_class
  56   setup_finished/;
  57
  58 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  59 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  60 __PACKAGE__->request_class('Catalyst::Request');
  61 __PACKAGE__->response_class('Catalyst::Response');
  62 __PACKAGE__->stats_class('Catalyst::Stats');
  63
  64 # Remember to update this in Catalyst::Runtime as well!
  65
  66 our $VERSION = '5.7014';
  67
  68 sub import {
  69     my ( $class, @arguments ) = @_;
  70
  71     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  72     # callers @ISA.
  73     return unless $class eq 'Catalyst';
  74
  75     my $caller = caller(0);
  76
  77     unless ( $caller->isa('Catalyst') ) {
  78         no strict 'refs';
  79         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  80     }
  81
  82     $caller->arguments( [@arguments] );
  83     $caller->setup_home;
  84 }
  85
  86 =head1 NAME
  87
  88 Catalyst - The Elegant MVC Web Application Framework
  89
  90 =head1 SYNOPSIS
  91
  92 See the L<Catalyst::Manual> distribution for comprehensive
  93 documentation and tutorials.
  94
  95     # Install Catalyst::Devel for helpers and other development tools
  96     # use the helper to create a new application
  97     catalyst.pl MyApp
  98
  99     # add models, views, controllers
 100     script/myapp_create.pl model MyDatabase DBIC::Schema create=dynamic dbi:SQLite:/path/to/db
 101     script/myapp_create.pl view MyTemplate TT
 102     script/myapp_create.pl controller Search
 103
 104     # built in testserver -- use -r to restart automatically on changes
 105     # --help to see all available options
 106     script/myapp_server.pl
 107
 108     # command line testing interface
 109     script/myapp_test.pl /yada
 110
 111     ### in lib/MyApp.pm
 112     use Catalyst qw/-Debug/; # include plugins here as well
 113
 114     ### In lib/MyApp/Controller/Root.pm (autocreated)
 115     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 116         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 117         $c->stash->{template} = 'foo.tt'; # set the template
 118         # lookup something from db -- stash vars are passed to TT
 119         $c->stash->{data} =
 120           $c->model('Database::Foo')->search( { country => $args[0] } );
 121         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 122             $c->forward( 'bar' ); # process another action
 123             # do something else after forward returns
 124         }
 125     }
 126
 127     # The foo.tt TT template can use the stash data from the database
 128     [% WHILE (item = data.next) %]
 129         [% item.foo %]
 130     [% END %]
 131
 132     # called for /bar/of/soap, /bar/of/soap/10, etc.
 133     sub bar : Path('/bar/of/soap') { ... }
 134
 135     # called for all actions, from the top-most controller downwards
 136     sub auto : Private {
 137         my ( $self, $c ) = @_;
 138         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 139             $c->res->redirect( '/login' ); # require login
 140             return 0; # abort request and go immediately to end()
 141         }
 142         return 1; # success; carry on to next action
 143     }
 144
 145     # called after all actions are finished
 146     sub end : Private {
 147         my ( $self, $c ) = @_;
 148         if ( scalar @{ $c->error } ) { ... } # handle errors
 149         return if $c->res->body; # already have a response
 150         $c->forward( 'MyApp::View::TT' ); # render template
 151     }
 152
 153     ### in MyApp/Controller/Foo.pm
 154     # called for /foo/bar
 155     sub bar : Local { ... }
 156
 157     # called for /blargle
 158     sub blargle : Global { ... }
 159
 160     # an index action matches /foo, but not /foo/1, etc.
 161     sub index : Private { ... }
 162
 163     ### in MyApp/Controller/Foo/Bar.pm
 164     # called for /foo/bar/baz
 165     sub baz : Local { ... }
 166
 167     # first Root auto is called, then Foo auto, then this
 168     sub auto : Private { ... }
 169
 170     # powerful regular expression paths are also possible
 171     sub details : Regex('^product/(\w+)/details$') {
 172         my ( $self, $c ) = @_;
 173         # extract the (\w+) from the URI
 174         my $product = $c->req->captures->[0];
 175     }
 176
 177 See L<Catalyst::Manual::Intro> for additional information.
 178
 179 =head1 DESCRIPTION
 180
 181 Catalyst is a modern framework for making web applications without the
 182 pain usually associated with this process. This document is a reference
 183 to the main Catalyst application. If you are a new user, we suggest you
 184 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 185
 186 See L<Catalyst::Manual> for more documentation.
 187
 188 Catalyst plugins can be loaded by naming them as arguments to the "use
 189 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 190 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 191 C<My::Module>.
 192
 193     use Catalyst qw/My::Module/;
 194
 195 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 196 fully qualify the name by using a unary plus:
 197
 198     use Catalyst qw/
 199         My::Module
 200         +Fully::Qualified::Plugin::Name
 201     /;
 202
 203 Special flags like C<-Debug> and C<-Engine> can also be specified as
 204 arguments when Catalyst is loaded:
 205
 206     use Catalyst qw/-Debug My::Module/;
 207
 208 The position of plugins and flags in the chain is important, because
 209 they are loaded in the order in which they appear.
 210
 211 The following flags are supported:
 212
 213 =head2 -Debug
 214
 215 Enables debug output. You can also force this setting from the system
 216 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 217 settings override the application, with <MYAPP>_DEBUG having the highest
 218 priority.
 219
 220 =head2 -Engine
 221
 222 Forces Catalyst to use a specific engine. Omit the
 223 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 224
 225     use Catalyst qw/-Engine=CGI/;
 226
 227 =head2 -Home
 228
 229 Forces Catalyst to use a specific home directory, e.g.:
 230
 231     use Catalyst qw[-Home=/usr/mst];
 232
 233 This can also be done in the shell environment by setting either the
 234 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 235 is replaced with the uppercased name of your application, any "::" in
 236 the name will be replaced with underscores, e.g. MyApp::Web should use
 237 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 238
 239 =head2 -Log
 240
 241 Specifies log level.
 242
 243 =head2 -Stats
 244
 245 Enables statistics collection and reporting. You can also force this setting
 246 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 247 environment settings override the application, with <MYAPP>_STATS having the
 248 highest priority.
 249
 250 e.g.
 251
 252    use Catalyst qw/-Stats=1/
 253
 254 =head1 METHODS
 255
 256 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 257
 258 =head2 $c->action
 259
 260 Returns a L<Catalyst::Action> object for the current action, which
 261 stringifies to the action name. See L<Catalyst::Action>.
 262
 263 =head2 $c->namespace
 264
 265 Returns the namespace of the current action, i.e., the URI prefix
 266 corresponding to the controller of the current action. For example:
 267
 268     # in Controller::Foo::Bar
 269     $c->namespace; # returns 'foo/bar';
 270
 271 =head2 $c->request
 272
 273 =head2 $c->req
 274
 275 Returns the current L<Catalyst::Request> object, giving access to
 276 information about the current client request (including parameters,
 277 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 278
 279 =head2 REQUEST FLOW HANDLING
 280
 281 =head2 $c->forward( $action [, \@arguments ] )
 282
 283 =head2 $c->forward( $class, $method, [, \@arguments ] )
 284
 285 Forwards processing to another action, by its private name. If you give a
 286 class name but no method, C<process()> is called. You may also optionally
 287 pass arguments in an arrayref. The action will receive the arguments in
 288 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 289 C<< $c->req->args >> will be restored to the previous values.
 290
 291 Any data C<return>ed from the action forwarded to, will be returned by the
 292 call to forward.
 293
 294     my $foodata = $c->forward('/foo');
 295     $c->forward('index');
 296     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 297     $c->forward('MyApp::View::TT');
 298
 299 Note that forward implies an C<<eval { }>> around the call (actually
 300 C<execute> does), thus de-fatalizing all 'dies' within the called
 301 action. If you want C<die> to propagate you need to do something like:
 302
 303     $c->forward('foo');
 304     die $c->error if $c->error;
 305
 306 Or make sure to always return true values from your actions and write
 307 your code like this:
 308
 309     $c->forward('foo') || return;
 310
 311 =cut
 312
 313 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 314
 315 =head2 $c->detach( $action [, \@arguments ] )
 316
 317 =head2 $c->detach( $class, $method, [, \@arguments ] )
 318
 319 =head2 $c->detach()
 320
 321 The same as C<forward>, but doesn't return to the previous action when
 322 processing is finished.
 323
 324 When called with no arguments it escapes the processing chain entirely.
 325
 326 =cut
 327
 328 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 329
 330 =head2 $c->response
 331
 332 =head2 $c->res
 333
 334 Returns the current L<Catalyst::Response> object, see there for details.
 335
 336 =head2 $c->stash
 337
 338 Returns a hashref to the stash, which may be used to store data and pass
 339 it between components during a request. You can also set hash keys by
 340 passing arguments. The stash is automatically sent to the view. The
 341 stash is cleared at the end of a request; it cannot be used for
 342 persistent storage (for this you must use a session; see
 343 L<Catalyst::Plugin::Session> for a complete system integrated with
 344 Catalyst).
 345
 346     $c->stash->{foo} = $bar;
 347     $c->stash( { moose => 'majestic', qux => 0 } );
 348     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 349
 350     # stash is automatically passed to the view for use in a template
 351     $c->forward( 'MyApp::View::TT' );
 352
 353 =cut
 354
 355 sub stash {
 356     my $c = shift;
 357     if (@_) {
 358         my $stash = @_ > 1 ? {@_} : $_[0];
 359         croak('stash takes a hash or hashref') unless ref $stash;
 360         foreach my $key ( keys %$stash ) {
 361             $c->{stash}->{$key} = $stash->{$key};
 362         }
 363     }
 364     return $c->{stash};
 365 }
 366
 367 =head2 $c->error
 368
 369 =head2 $c->error($error, ...)
 370
 371 =head2 $c->error($arrayref)
 372
 373 Returns an arrayref containing error messages.  If Catalyst encounters an
 374 error while processing a request, it stores the error in $c->error.  This
 375 method should only be used to store fatal error messages.
 376
 377     my @error = @{ $c->error };
 378
 379 Add a new error.
 380
 381     $c->error('Something bad happened');
 382
 383 =cut
 384
 385 sub error {
 386     my $c = shift;
 387     if ( $_[0] ) {
 388         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 389         croak @$error unless ref $c;
 390         push @{ $c->{error} }, @$error;
 391     }
 392     elsif ( defined $_[0] ) { $c->{error} = undef }
 393     return $c->{error} || [];
 394 }
 395
 396
 397 =head2 $c->state
 398
 399 Contains the return value of the last executed action.
 400
 401 =head2 $c->clear_errors
 402
 403 Clear errors.  You probably don't want to clear the errors unless you are
 404 implementing a custom error screen.
 405
 406 This is equivalent to running
 407
 408     $c->error(0);
 409
 410 =cut
 411
 412 sub clear_errors {
 413     my $c = shift;
 414     $c->error(0);
 415 }
 416
 417 # search components given a name and some prefixes
 418 sub _comp_search_prefixes {
 419     my ( $c, $name, @prefixes ) = @_;
 420     my $appclass = ref $c || $c;
 421     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 422
 423     # map the original component name to the sub part that we will search against
 424     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 425         grep { /$filter/ } keys %{ $c->components };
 426
 427     # undef for a name will return all
 428     return keys %eligible if !defined $name;
 429
 430     my $query  = ref $name ? $name : qr/^$name$/i;
 431     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 432
 433     return map { $c->components->{ $_ } } @result if @result;
 434
 435     # if we were given a regexp to search against, we're done.
 436     return if ref $name;
 437
 438     # regexp fallback
 439     $query  = qr/$name/i;
 440     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 441
 442     # don't warn if we didn't find any results, it just might not exist
 443     if( @result ) {
 444         $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 445         $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 446     }
 447
 448     return @result;
 449 }
 450
 451 # Find possible names for a prefix
 452 sub _comp_names {
 453     my ( $c, @prefixes ) = @_;
 454     my $appclass = ref $c || $c;
 455
 456     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 457
 458     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 459     return @names;
 460 }
 461
 462 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 463 sub _filter_component {
 464     my ( $c, $comp, @args ) = @_;
 465
 466     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 467         return $comp->ACCEPT_CONTEXT( $c, @args );
 468     }
 469
 470     return $comp;
 471 }
 472
 473 =head2 COMPONENT ACCESSORS
 474
 475 =head2 $c->controller($name)
 476
 477 Gets a L<Catalyst::Controller> instance by name.
 478
 479     $c->controller('Foo')->do_stuff;
 480
 481 If the name is omitted, will return the controller for the dispatched
 482 action.
 483
 484 =cut
 485
 486 sub controller {
 487     my ( $c, $name, @args ) = @_;
 488
 489     if( $name ) {
 490         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 491         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 492         return $c->_filter_component( $result[ 0 ], @args );
 493     }
 494
 495     return $c->component( $c->action->class );
 496 }
 497
 498 =head2 $c->model($name)
 499
 500 Gets a L<Catalyst::Model> instance by name.
 501
 502     $c->model('Foo')->do_stuff;
 503
 504 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 505
 506 If the name is omitted, it will look for
 507  - a model object in $c->stash{current_model_instance}, then
 508  - a model name in $c->stash->{current_model}, then
 509  - a config setting 'default_model', or
 510  - check if there is only one model, and return it if that's the case.
 511
 512 =cut
 513
 514 sub model {
 515     my ( $c, $name, @args ) = @_;
 516
 517     if( $name ) {
 518         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 519         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 520         return $c->_filter_component( $result[ 0 ], @args );
 521     }
 522
 523     if (ref $c) {
 524         return $c->stash->{current_model_instance}
 525           if $c->stash->{current_model_instance};
 526         return $c->model( $c->stash->{current_model} )
 527           if $c->stash->{current_model};
 528     }
 529     return $c->model( $c->config->{default_model} )
 530       if $c->config->{default_model};
 531
 532     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 533
 534     if( $rest ) {
 535         $c->log->warn( 'Calling $c->model() will return a random model unless you specify one of:' );
 536         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 537         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 538         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 539         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 540     }
 541
 542     return $c->_filter_component( $comp );
 543 }
 544
 545
 546 =head2 $c->view($name)
 547
 548 Gets a L<Catalyst::View> instance by name.
 549
 550     $c->view('Foo')->do_stuff;
 551
 552 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 553
 554 If the name is omitted, it will look for
 555  - a view object in $c->stash{current_view_instance}, then
 556  - a view name in $c->stash->{current_view}, then
 557  - a config setting 'default_view', or
 558  - check if there is only one view, and return it if that's the case.
 559
 560 =cut
 561
 562 sub view {
 563     my ( $c, $name, @args ) = @_;
 564
 565     if( $name ) {
 566         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 567         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 568         return $c->_filter_component( $result[ 0 ], @args );
 569     }
 570
 571     if (ref $c) {
 572         return $c->stash->{current_view_instance}
 573           if $c->stash->{current_view_instance};
 574         return $c->view( $c->stash->{current_view} )
 575           if $c->stash->{current_view};
 576     }
 577     return $c->view( $c->config->{default_view} )
 578       if $c->config->{default_view};
 579
 580     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 581
 582     if( $rest ) {
 583         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 584         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 585         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 586         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 587         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 588     }
 589
 590     return $c->_filter_component( $comp );
 591 }
 592
 593 =head2 $c->controllers
 594
 595 Returns the available names which can be passed to $c->controller
 596
 597 =cut
 598
 599 sub controllers {
 600     my ( $c ) = @_;
 601     return $c->_comp_names(qw/Controller C/);
 602 }
 603
 604 =head2 $c->models
 605
 606 Returns the available names which can be passed to $c->model
 607
 608 =cut
 609
 610 sub models {
 611     my ( $c ) = @_;
 612     return $c->_comp_names(qw/Model M/);
 613 }
 614
 615
 616 =head2 $c->views
 617
 618 Returns the available names which can be passed to $c->view
 619
 620 =cut
 621
 622 sub views {
 623     my ( $c ) = @_;
 624     return $c->_comp_names(qw/View V/);
 625 }
 626
 627 =head2 $c->comp($name)
 628
 629 =head2 $c->component($name)
 630
 631 Gets a component object by name. This method is not recommended,
 632 unless you want to get a specific component by full
 633 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 634 should be used instead.
 635
 636 =cut
 637
 638 sub component {
 639     my ( $c, $name, @args ) = @_;
 640
 641     if( $name ) {
 642         my $comps = $c->components;
 643
 644         if( !ref $name ) {
 645             # is it the exact name?
 646             return $comps->{ $name } if exists $comps->{ $name };
 647
 648             # perhaps we just omitted "MyApp"?
 649             my $composed = ( ref $c || $c ) . "::${name}";
 650             return $comps->{ $composed } if exists $comps->{ $composed };
 651
 652             # search all of the models, views and controllers
 653             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 654             return $c->_filter_component( $comp, @args ) if $comp;
 655         }
 656
 657         # This is here so $c->comp( '::M::' ) works
 658         my $query = ref $name ? $name : qr{$name}i;
 659
 660         my @result = grep { m{$query} } keys %{ $c->components };
 661         return @result if ref $name;
 662
 663         if( $result[ 0 ] ) {
 664             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 665             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 666             return $result[ 0 ];
 667         }
 668
 669         # I would expect to return an empty list here, but that breaks back-compat
 670     }
 671
 672     # fallback
 673     return sort keys %{ $c->components };
 674 }
 675
 676 =head2 CLASS DATA AND HELPER CLASSES
 677
 678 =head2 $c->config
 679
 680 Returns or takes a hashref containing the application's configuration.
 681
 682     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 683
 684 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 685 like myapp.yml in your applications home directory. See
 686 L<Catalyst::Plugin::ConfigLoader>.
 687
 688     ---
 689     db: dsn:SQLite:foo.db
 690
 691
 692 =cut
 693
 694 sub config {
 695     my $c = shift;
 696
 697     $c->log->warn("Setting config after setup has been run is not a good idea.")
 698       if ( @_ and $c->setup_finished );
 699
 700     $c->NEXT::config(@_);
 701 }
 702
 703 =head2 $c->log
 704
 705 Returns the logging object instance. Unless it is already set, Catalyst
 706 sets this up with a L<Catalyst::Log> object. To use your own log class,
 707 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 708 C<< __PACKAGE__->setup >>.
 709
 710  __PACKAGE__->log( MyLogger->new );
 711  __PACKAGE__->setup;
 712
 713 And later:
 714
 715     $c->log->info( 'Now logging with my own logger!' );
 716
 717 Your log class should implement the methods described in
 718 L<Catalyst::Log>.
 719
 720
 721 =head2 $c->debug
 722
 723 Overload to enable debug messages (same as -Debug option).
 724
 725 Note that this is a static method, not an accessor and should be overloaded
 726 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 727
 728 =cut
 729
 730 sub debug { 0 }
 731
 732 =head2 $c->dispatcher
 733
 734 Returns the dispatcher instance. Stringifies to class name. See
 735 L<Catalyst::Dispatcher>.
 736
 737 =head2 $c->engine
 738
 739 Returns the engine instance. Stringifies to the class name. See
 740 L<Catalyst::Engine>.
 741
 742
 743 =head2 UTILITY METHODS
 744
 745 =head2 $c->path_to(@path)
 746
 747 Merges C<@path> with C<< $c->config->{home} >> and returns a
 748 L<Path::Class::Dir> object.
 749
 750 For example:
 751
 752     $c->path_to( 'db', 'sqlite.db' );
 753
 754 =cut
 755
 756 sub path_to {
 757     my ( $c, @path ) = @_;
 758     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 759     if ( -d $path ) { return $path }
 760     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 761 }
 762
 763 =head2 $c->plugin( $name, $class, @args )
 764
 765 Helper method for plugins. It creates a classdata accessor/mutator and
 766 loads and instantiates the given class.
 767
 768     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 769
 770     $c->prototype->define_javascript_functions;
 771
 772 =cut
 773
 774 sub plugin {
 775     my ( $class, $name, $plugin, @args ) = @_;
 776     $class->_register_plugin( $plugin, 1 );
 777
 778     eval { $plugin->import };
 779     $class->mk_classdata($name);
 780     my $obj;
 781     eval { $obj = $plugin->new(@args) };
 782
 783     if ($@) {
 784         Catalyst::Exception->throw( message =>
 785               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 786     }
 787
 788     $class->$name($obj);
 789     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 790       if $class->debug;
 791 }
 792
 793 =head2 MyApp->setup
 794
 795 Initializes the dispatcher and engine, loads any plugins, and loads the
 796 model, view, and controller components. You may also specify an array
 797 of plugins to load here, if you choose to not load them in the C<use
 798 Catalyst> line.
 799
 800     MyApp->setup;
 801     MyApp->setup( qw/-Debug/ );
 802
 803 =cut
 804
 805 sub setup {
 806     my ( $class, @arguments ) = @_;
 807
 808     $class->log->warn("Running setup twice is not a good idea.")
 809       if ( $class->setup_finished );
 810
 811     unless ( $class->isa('Catalyst') ) {
 812
 813         Catalyst::Exception->throw(
 814             message => qq/'$class' does not inherit from Catalyst/ );
 815     }
 816
 817     if ( $class->arguments ) {
 818         @arguments = ( @arguments, @{ $class->arguments } );
 819     }
 820
 821     # Process options
 822     my $flags = {};
 823
 824     foreach (@arguments) {
 825
 826         if (/^-Debug$/) {
 827             $flags->{log} =
 828               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 829         }
 830         elsif (/^-(\w+)=?(.*)$/) {
 831             $flags->{ lc $1 } = $2;
 832         }
 833         else {
 834             push @{ $flags->{plugins} }, $_;
 835         }
 836     }
 837
 838     $class->setup_home( delete $flags->{home} );
 839
 840     $class->setup_log( delete $flags->{log} );
 841     $class->setup_plugins( delete $flags->{plugins} );
 842     $class->setup_dispatcher( delete $flags->{dispatcher} );
 843     $class->setup_engine( delete $flags->{engine} );
 844     $class->setup_stats( delete $flags->{stats} );
 845
 846     for my $flag ( sort keys %{$flags} ) {
 847
 848         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 849             &$code( $class, delete $flags->{$flag} );
 850         }
 851         else {
 852             $class->log->warn(qq/Unknown flag "$flag"/);
 853         }
 854     }
 855
 856     eval { require Catalyst::Devel; };
 857     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 858         $class->log->warn(<<"EOF");
 859 You are running an old script!
 860
 861   Please update by running (this will overwrite existing files):
 862     catalyst.pl -force -scripts $class
 863
 864   or (this will not overwrite existing files):
 865     catalyst.pl -scripts $class
 866
 867 EOF
 868     }
 869
 870     if ( $class->debug ) {
 871         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 872
 873         if (@plugins) {
 874             my $t = Text::SimpleTable->new(74);
 875             $t->row($_) for @plugins;
 876             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 877         }
 878
 879         my $dispatcher = $class->dispatcher;
 880         my $engine     = $class->engine;
 881         my $home       = $class->config->{home};
 882
 883         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 884         $class->log->debug(qq/Loaded engine "$engine"/);
 885
 886         $home
 887           ? ( -d $home )
 888           ? $class->log->debug(qq/Found home "$home"/)
 889           : $class->log->debug(qq/Home "$home" doesn't exist/)
 890           : $class->log->debug(q/Couldn't find home/);
 891     }
 892
 893     # Call plugins setup
 894     {
 895         no warnings qw/redefine/;
 896         local *setup = sub { };
 897         $class->setup;
 898     }
 899
 900     # Initialize our data structure
 901     $class->components( {} );
 902
 903     $class->setup_components;
 904
 905     if ( $class->debug ) {
 906         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 907         for my $comp ( sort keys %{ $class->components } ) {
 908             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 909             $t->row( $comp, $type );
 910         }
 911         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 912           if ( keys %{ $class->components } );
 913     }
 914
 915     # Add our self to components, since we are also a component
 916     $class->components->{$class} = $class;
 917
 918     $class->setup_actions;
 919
 920     if ( $class->debug ) {
 921         my $name = $class->config->{name} || 'Application';
 922         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 923     }
 924     $class->log->_flush() if $class->log->can('_flush');
 925
 926     $class->setup_finished(1);
 927 }
 928
 929 =head2 $c->uri_for( $path, @args?, \%query_values? )
 930
 931 Merges path with C<< $c->request->base >> for absolute URIs and with
 932 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 933 object. If any args are passed, they are added at the end of the path.
 934 If the last argument to C<uri_for> is a hash reference, it is assumed to
 935 contain GET parameter key/value pairs, which will be appended to the URI
 936 in standard fashion.
 937
 938 Note that uri_for is destructive to the passed hashref.  Subsequent calls
 939 with the same hashref may have unintended results.
 940
 941 Instead of C<$path>, you can also optionally pass a C<$action> object
 942 which will be resolved to a path using
 943 C<< $c->dispatcher->uri_for_action >>; if the first element of
 944 C<@args> is an arrayref it is treated as a list of captures to be passed
 945 to C<uri_for_action>.
 946
 947 =cut
 948
 949 sub uri_for {
 950     my ( $c, $path, @args ) = @_;
 951
 952     if ( Scalar::Util::blessed($path) ) { # action object
 953         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 954                          ? shift(@args)
 955                          : [] );
 956         $path = $c->dispatcher->uri_for_action($path, $captures);
 957         return undef unless defined($path);
 958         $path = '/' if $path eq '';
 959     }
 960
 961     undef($path) if (defined $path && $path eq '');
 962
 963     my $params =
 964       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 965
 966     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
 967     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
 968
 969     unshift(@args, $path);
 970
 971     unless (defined $path && $path =~ s!^/!!) { # in-place strip
 972         my $namespace = $c->namespace;
 973         if (defined $path) { # cheesy hack to handle path '../foo'
 974            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
 975         }
 976         unshift(@args, $namespace || '');
 977     }
 978
 979     # join args with '/', or a blank string
 980     my $args = join('/', grep { defined($_) } @args);
 981     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
 982     $args =~ s!^/!!;
 983     my $base = $c->req->base;
 984     my $class = ref($base);
 985     $base =~ s{(?<!/)$}{/};
 986
 987     my $query = '';
 988
 989     if (my @keys = keys %$params) {
 990       # somewhat lifted from URI::_query's query_form
 991       $query = '?'.join('&', map {
 992           my $val = $params->{$_};
 993           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
 994           s/ /+/g;
 995           my $key = $_;
 996           $val = '' unless defined $val;
 997           (map {
 998               $_ = "$_";
 999               utf8::encode( $_ ) if utf8::is_utf8($_);
1000               # using the URI::Escape pattern here so utf8 chars survive
1001               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1002               s/ /+/g;
1003               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1004       } @keys);
1005     }
1006
1007     my $res = bless(\"${base}${args}${query}", $class);
1008     $res;
1009 }
1010
1011 =head2 $c->welcome_message
1012
1013 Returns the Catalyst welcome HTML page.
1014
1015 =cut
1016
1017 sub welcome_message {
1018     my $c      = shift;
1019     my $name   = $c->config->{name};
1020     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1021     my $prefix = Catalyst::Utils::appprefix( ref $c );
1022     $c->response->content_type('text/html; charset=utf-8');
1023     return <<"EOF";
1024 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1025     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1026 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1027     <head>
1028     <meta http-equiv="Content-Language" content="en" />
1029     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1030         <title>$name on Catalyst $VERSION</title>
1031         <style type="text/css">
1032             body {
1033                 color: #000;
1034                 background-color: #eee;
1035             }
1036             div#content {
1037                 width: 640px;
1038                 margin-left: auto;
1039                 margin-right: auto;
1040                 margin-top: 10px;
1041                 margin-bottom: 10px;
1042                 text-align: left;
1043                 background-color: #ccc;
1044                 border: 1px solid #aaa;
1045             }
1046             p, h1, h2 {
1047                 margin-left: 20px;
1048                 margin-right: 20px;
1049                 font-family: verdana, tahoma, sans-serif;
1050             }
1051             a {
1052                 font-family: verdana, tahoma, sans-serif;
1053             }
1054             :link, :visited {
1055                     text-decoration: none;
1056                     color: #b00;
1057                     border-bottom: 1px dotted #bbb;
1058             }
1059             :link:hover, :visited:hover {
1060                     color: #555;
1061             }
1062             div#topbar {
1063                 margin: 0px;
1064             }
1065             pre {
1066                 margin: 10px;
1067                 padding: 8px;
1068             }
1069             div#answers {
1070                 padding: 8px;
1071                 margin: 10px;
1072                 background-color: #fff;
1073                 border: 1px solid #aaa;
1074             }
1075             h1 {
1076                 font-size: 0.9em;
1077                 font-weight: normal;
1078                 text-align: center;
1079             }
1080             h2 {
1081                 font-size: 1.0em;
1082             }
1083             p {
1084                 font-size: 0.9em;
1085             }
1086             p img {
1087                 float: right;
1088                 margin-left: 10px;
1089             }
1090             span#appname {
1091                 font-weight: bold;
1092                 font-size: 1.6em;
1093             }
1094         </style>
1095     </head>
1096     <body>
1097         <div id="content">
1098             <div id="topbar">
1099                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1100                     $VERSION</h1>
1101              </div>
1102              <div id="answers">
1103                  <p>
1104                  <img src="$logo" alt="Catalyst Logo" />
1105                  </p>
1106                  <p>Welcome to the  world of Catalyst.
1107                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1108                     framework will make web development something you had
1109                     never expected it to be: Fun, rewarding, and quick.</p>
1110                  <h2>What to do now?</h2>
1111                  <p>That really depends  on what <b>you</b> want to do.
1112                     We do, however, provide you with a few starting points.</p>
1113                  <p>If you want to jump right into web development with Catalyst
1114                     you might want to start with a tutorial.</p>
1115 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1116 </pre>
1117 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1118 <pre>
1119 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1120 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1121 </code></pre>
1122                  <h2>What to do next?</h2>
1123                  <p>Next it's time to write an actual application. Use the
1124                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1125                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1126                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1127                     they can save you a lot of work.</p>
1128                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1129                     <p>Also, be sure to check out the vast and growing
1130                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1131                     you are likely to find what you need there.
1132                     </p>
1133
1134                  <h2>Need help?</h2>
1135                  <p>Catalyst has a very active community. Here are the main places to
1136                     get in touch with us.</p>
1137                  <ul>
1138                      <li>
1139                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1140                      </li>
1141                      <li>
1142                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1143                      </li>
1144                      <li>
1145                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1146                      </li>
1147                  </ul>
1148                  <h2>In conclusion</h2>
1149                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1150                     as we enjoyed making it. Please contact us if you have ideas
1151                     for improvement or other feedback.</p>
1152              </div>
1153          </div>
1154     </body>
1155 </html>
1156 EOF
1157 }
1158
1159 =head1 INTERNAL METHODS
1160
1161 These methods are not meant to be used by end users.
1162
1163 =head2 $c->components
1164
1165 Returns a hash of components.
1166
1167 =head2 $c->context_class
1168
1169 Returns or sets the context class.
1170
1171 =head2 $c->counter
1172
1173 Returns a hashref containing coderefs and execution counts (needed for
1174 deep recursion detection).
1175
1176 =head2 $c->depth
1177
1178 Returns the number of actions on the current internal execution stack.
1179
1180 =head2 $c->dispatch
1181
1182 Dispatches a request to actions.
1183
1184 =cut
1185
1186 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1187
1188 =head2 $c->dispatcher_class
1189
1190 Returns or sets the dispatcher class.
1191
1192 =head2 $c->dump_these
1193
1194 Returns a list of 2-element array references (name, structure) pairs
1195 that will be dumped on the error page in debug mode.
1196
1197 =cut
1198
1199 sub dump_these {
1200     my $c = shift;
1201     [ Request => $c->req ],
1202     [ Response => $c->res ],
1203     [ Stash => $c->stash ],
1204     [ Config => $c->config ];
1205 }
1206
1207 =head2 $c->engine_class
1208
1209 Returns or sets the engine class.
1210
1211 =head2 $c->execute( $class, $coderef )
1212
1213 Execute a coderef in given class and catch exceptions. Errors are available
1214 via $c->error.
1215
1216 =cut
1217
1218 sub execute {
1219     my ( $c, $class, $code ) = @_;
1220     $class = $c->component($class) || $class;
1221     $c->state(0);
1222
1223     if ( $c->depth >= $RECURSION ) {
1224         my $action = "$code";
1225         $action = "/$action" unless $action =~ /->/;
1226         my $error = qq/Deep recursion detected calling "$action"/;
1227         $c->log->error($error);
1228         $c->error($error);
1229         $c->state(0);
1230         return $c->state;
1231     }
1232
1233     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1234
1235     push( @{ $c->stack }, $code );
1236
1237     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1238
1239     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1240
1241     my $last = pop( @{ $c->stack } );
1242
1243     if ( my $error = $@ ) {
1244         if ( !ref($error) and $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1245         else {
1246             unless ( ref $error ) {
1247                 no warnings 'uninitialized';
1248                 chomp $error;
1249                 my $class = $last->class;
1250                 my $name  = $last->name;
1251                 $error = qq/Caught exception in $class->$name "$error"/;
1252             }
1253             $c->error($error);
1254             $c->state(0);
1255         }
1256     }
1257     return $c->state;
1258 }
1259
1260 sub _stats_start_execute {
1261     my ( $c, $code ) = @_;
1262
1263     return if ( ( $code->name =~ /^_.*/ )
1264         && ( !$c->config->{show_internal_actions} ) );
1265
1266     $c->counter->{"$code"}++;
1267
1268     my $action = "$code";
1269     $action = "/$action" unless $action =~ /->/;
1270
1271     # determine if the call was the result of a forward
1272     # this is done by walking up the call stack and looking for a calling
1273     # sub of Catalyst::forward before the eval
1274     my $callsub = q{};
1275     for my $index ( 2 .. 11 ) {
1276         last
1277         if ( ( caller($index) )[0] eq 'Catalyst'
1278             && ( caller($index) )[3] eq '(eval)' );
1279
1280         if ( ( caller($index) )[3] =~ /forward$/ ) {
1281             $callsub = ( caller($index) )[3];
1282             $action  = "-> $action";
1283             last;
1284         }
1285     }
1286
1287     my $uid = "$code" . $c->counter->{"$code"};
1288
1289     # is this a root-level call or a forwarded call?
1290     if ( $callsub =~ /forward$/ ) {
1291
1292         # forward, locate the caller
1293         if ( my $parent = $c->stack->[-1] ) {
1294             $c->stats->profile(
1295                 begin  => $action,
1296                 parent => "$parent" . $c->counter->{"$parent"},
1297                 uid    => $uid,
1298             );
1299         }
1300         else {
1301
1302             # forward with no caller may come from a plugin
1303             $c->stats->profile(
1304                 begin => $action,
1305                 uid   => $uid,
1306             );
1307         }
1308     }
1309     else {
1310
1311         # root-level call
1312         $c->stats->profile(
1313             begin => $action,
1314             uid   => $uid,
1315         );
1316     }
1317     return $action;
1318
1319 }
1320
1321 sub _stats_finish_execute {
1322     my ( $c, $info ) = @_;
1323     $c->stats->profile( end => $info );
1324 }
1325
1326 =head2 $c->_localize_fields( sub { }, \%keys );
1327
1328 =cut
1329
1330 sub _localize_fields {
1331     my ( $c, $localized, $code ) = ( @_ );
1332
1333     my $request = delete $localized->{request} || {};
1334     my $response = delete $localized->{response} || {};
1335
1336     local @{ $c }{ keys %$localized } = values %$localized;
1337     local @{ $c->request }{ keys %$request } = values %$request;
1338     local @{ $c->response }{ keys %$response } = values %$response;
1339
1340     $code->();
1341 }
1342
1343 =head2 $c->finalize
1344
1345 Finalizes the request.
1346
1347 =cut
1348
1349 sub finalize {
1350     my $c = shift;
1351
1352     for my $error ( @{ $c->error } ) {
1353         $c->log->error($error);
1354     }
1355
1356     # Allow engine to handle finalize flow (for POE)
1357     if ( $c->engine->can('finalize') ) {
1358         $c->engine->finalize($c);
1359     }
1360     else {
1361
1362         $c->finalize_uploads;
1363
1364         # Error
1365         if ( $#{ $c->error } >= 0 ) {
1366             $c->finalize_error;
1367         }
1368
1369         $c->finalize_headers;
1370
1371         # HEAD request
1372         if ( $c->request->method eq 'HEAD' ) {
1373             $c->response->body('');
1374         }
1375
1376         $c->finalize_body;
1377     }
1378
1379     if ($c->use_stats) {
1380         my $elapsed = sprintf '%f', $c->stats->elapsed;
1381         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1382         $c->log->info(
1383             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1384     }
1385
1386     return $c->response->status;
1387 }
1388
1389 =head2 $c->finalize_body
1390
1391 Finalizes body.
1392
1393 =cut
1394
1395 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1396
1397 =head2 $c->finalize_cookies
1398
1399 Finalizes cookies.
1400
1401 =cut
1402
1403 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1404
1405 =head2 $c->finalize_error
1406
1407 Finalizes error.
1408
1409 =cut
1410
1411 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1412
1413 =head2 $c->finalize_headers
1414
1415 Finalizes headers.
1416
1417 =cut
1418
1419 sub finalize_headers {
1420     my $c = shift;
1421
1422     # Check if we already finalized headers
1423     return if $c->response->{_finalized_headers};
1424
1425     # Handle redirects
1426     if ( my $location = $c->response->redirect ) {
1427         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1428         $c->response->header( Location => $location );
1429
1430         if ( !$c->response->body ) {
1431             # Add a default body if none is already present
1432             $c->response->body(
1433                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1434             );
1435         }
1436     }
1437
1438     # Content-Length
1439     if ( $c->response->body && !$c->response->content_length ) {
1440
1441         # get the length from a filehandle
1442         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1443         {
1444             my $stat = stat $c->response->body;
1445             if ( $stat && $stat->size > 0 ) {
1446                 $c->response->content_length( $stat->size );
1447             }
1448             else {
1449                 $c->log->warn('Serving filehandle without a content-length');
1450             }
1451         }
1452         else {
1453             # everything should be bytes at this point, but just in case
1454             $c->response->content_length( bytes::length( $c->response->body ) );
1455         }
1456     }
1457
1458     # Errors
1459     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1460         $c->response->headers->remove_header("Content-Length");
1461         $c->response->body('');
1462     }
1463
1464     $c->finalize_cookies;
1465
1466     $c->engine->finalize_headers( $c, @_ );
1467
1468     # Done
1469     $c->response->{_finalized_headers} = 1;
1470 }
1471
1472 =head2 $c->finalize_output
1473
1474 An alias for finalize_body.
1475
1476 =head2 $c->finalize_read
1477
1478 Finalizes the input after reading is complete.
1479
1480 =cut
1481
1482 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1483
1484 =head2 $c->finalize_uploads
1485
1486 Finalizes uploads. Cleans up any temporary files.
1487
1488 =cut
1489
1490 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1491
1492 =head2 $c->get_action( $action, $namespace )
1493
1494 Gets an action in a given namespace.
1495
1496 =cut
1497
1498 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1499
1500 =head2 $c->get_actions( $action, $namespace )
1501
1502 Gets all actions of a given name in a namespace and all parent
1503 namespaces.
1504
1505 =cut
1506
1507 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1508
1509 =head2 $c->handle_request( $class, @arguments )
1510
1511 Called to handle each HTTP request.
1512
1513 =cut
1514
1515 sub handle_request {
1516     my ( $class, @arguments ) = @_;
1517
1518     # Always expect worst case!
1519     my $status = -1;
1520     eval {
1521         if ($class->debug) {
1522             my $secs = time - $START || 1;
1523             my $av = sprintf '%.3f', $COUNT / $secs;
1524             my $time = localtime time;
1525             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1526         }
1527
1528         my $c = $class->prepare(@arguments);
1529         $c->dispatch;
1530         $status = $c->finalize;
1531     };
1532
1533     if ( my $error = $@ ) {
1534         chomp $error;
1535         $class->log->error(qq/Caught exception in engine "$error"/);
1536     }
1537
1538     $COUNT++;
1539     $class->log->_flush() if $class->log->can('_flush');
1540     return $status;
1541 }
1542
1543 =head2 $c->prepare( @arguments )
1544
1545 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1546 etc.).
1547
1548 =cut
1549
1550 sub prepare {
1551     my ( $class, @arguments ) = @_;
1552
1553     $class->context_class( ref $class || $class ) unless $class->context_class;
1554     my $c = $class->context_class->new(
1555         {
1556             counter => {},
1557             stack   => [],
1558             request => $class->request_class->new(
1559                 {
1560                     arguments        => [],
1561                     body_parameters  => {},
1562                     cookies          => {},
1563                     headers          => HTTP::Headers->new,
1564                     parameters       => {},
1565                     query_parameters => {},
1566                     secure           => 0,
1567                     captures         => [],
1568                     uploads          => {}
1569                 }
1570             ),
1571             response => $class->response_class->new(
1572                 {
1573                     body    => '',
1574                     cookies => {},
1575                     headers => HTTP::Headers->new(),
1576                     status  => 200
1577                 }
1578             ),
1579             stash => {},
1580             state => 0
1581         }
1582     );
1583
1584     $c->stats($class->stats_class->new)->enable($c->use_stats);
1585     if ( $c->debug ) {
1586         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1587     }
1588
1589     # For on-demand data
1590     $c->request->{_context}  = $c;
1591     $c->response->{_context} = $c;
1592     weaken( $c->request->{_context} );
1593     weaken( $c->response->{_context} );
1594
1595     # Allow engine to direct the prepare flow (for POE)
1596     if ( $c->engine->can('prepare') ) {
1597         $c->engine->prepare( $c, @arguments );
1598     }
1599     else {
1600         $c->prepare_request(@arguments);
1601         $c->prepare_connection;
1602         $c->prepare_query_parameters;
1603         $c->prepare_headers;
1604         $c->prepare_cookies;
1605         $c->prepare_path;
1606
1607         # Prepare the body for reading, either by prepare_body
1608         # or the user, if they are using $c->read
1609         $c->prepare_read;
1610
1611         # Parse the body unless the user wants it on-demand
1612         unless ( $c->config->{parse_on_demand} ) {
1613             $c->prepare_body;
1614         }
1615     }
1616
1617     my $method  = $c->req->method  || '';
1618     my $path    = $c->req->path;
1619     $path       = '/' unless length $path;
1620     my $address = $c->req->address || '';
1621
1622     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1623       if $c->debug;
1624
1625     $c->prepare_action;
1626
1627     return $c;
1628 }
1629
1630 =head2 $c->prepare_action
1631
1632 Prepares action. See L<Catalyst::Dispatcher>.
1633
1634 =cut
1635
1636 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1637
1638 =head2 $c->prepare_body
1639
1640 Prepares message body.
1641
1642 =cut
1643
1644 sub prepare_body {
1645     my $c = shift;
1646
1647     # Do we run for the first time?
1648     return if defined $c->request->{_body};
1649
1650     # Initialize on-demand data
1651     $c->engine->prepare_body( $c, @_ );
1652     $c->prepare_parameters;
1653     $c->prepare_uploads;
1654
1655     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1656         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1657         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1658             my $param = $c->req->body_parameters->{$key};
1659             my $value = defined($param) ? $param : '';
1660             $t->row( $key,
1661                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1662         }
1663         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1664     }
1665 }
1666
1667 =head2 $c->prepare_body_chunk( $chunk )
1668
1669 Prepares a chunk of data before sending it to L<HTTP::Body>.
1670
1671 See L<Catalyst::Engine>.
1672
1673 =cut
1674
1675 sub prepare_body_chunk {
1676     my $c = shift;
1677     $c->engine->prepare_body_chunk( $c, @_ );
1678 }
1679
1680 =head2 $c->prepare_body_parameters
1681
1682 Prepares body parameters.
1683
1684 =cut
1685
1686 sub prepare_body_parameters {
1687     my $c = shift;
1688     $c->engine->prepare_body_parameters( $c, @_ );
1689 }
1690
1691 =head2 $c->prepare_connection
1692
1693 Prepares connection.
1694
1695 =cut
1696
1697 sub prepare_connection {
1698     my $c = shift;
1699     $c->engine->prepare_connection( $c, @_ );
1700 }
1701
1702 =head2 $c->prepare_cookies
1703
1704 Prepares cookies.
1705
1706 =cut
1707
1708 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1709
1710 =head2 $c->prepare_headers
1711
1712 Prepares headers.
1713
1714 =cut
1715
1716 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1717
1718 =head2 $c->prepare_parameters
1719
1720 Prepares parameters.
1721
1722 =cut
1723
1724 sub prepare_parameters {
1725     my $c = shift;
1726     $c->prepare_body_parameters;
1727     $c->engine->prepare_parameters( $c, @_ );
1728 }
1729
1730 =head2 $c->prepare_path
1731
1732 Prepares path and base.
1733
1734 =cut
1735
1736 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1737
1738 =head2 $c->prepare_query_parameters
1739
1740 Prepares query parameters.
1741
1742 =cut
1743
1744 sub prepare_query_parameters {
1745     my $c = shift;
1746
1747     $c->engine->prepare_query_parameters( $c, @_ );
1748
1749     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1750         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1751         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1752             my $param = $c->req->query_parameters->{$key};
1753             my $value = defined($param) ? $param : '';
1754             $t->row( $key,
1755                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1756         }
1757         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1758     }
1759 }
1760
1761 =head2 $c->prepare_read
1762
1763 Prepares the input for reading.
1764
1765 =cut
1766
1767 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1768
1769 =head2 $c->prepare_request
1770
1771 Prepares the engine request.
1772
1773 =cut
1774
1775 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1776
1777 =head2 $c->prepare_uploads
1778
1779 Prepares uploads.
1780
1781 =cut
1782
1783 sub prepare_uploads {
1784     my $c = shift;
1785
1786     $c->engine->prepare_uploads( $c, @_ );
1787
1788     if ( $c->debug && keys %{ $c->request->uploads } ) {
1789         my $t = Text::SimpleTable->new(
1790             [ 12, 'Parameter' ],
1791             [ 26, 'Filename' ],
1792             [ 18, 'Type' ],
1793             [ 9,  'Size' ]
1794         );
1795         for my $key ( sort keys %{ $c->request->uploads } ) {
1796             my $upload = $c->request->uploads->{$key};
1797             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1798                 $t->row( $key, $u->filename, $u->type, $u->size );
1799             }
1800         }
1801         $c->log->debug( "File Uploads are:\n" . $t->draw );
1802     }
1803 }
1804
1805 =head2 $c->prepare_write
1806
1807 Prepares the output for writing.
1808
1809 =cut
1810
1811 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1812
1813 =head2 $c->request_class
1814
1815 Returns or sets the request class.
1816
1817 =head2 $c->response_class
1818
1819 Returns or sets the response class.
1820
1821 =head2 $c->read( [$maxlength] )
1822
1823 Reads a chunk of data from the request body. This method is designed to
1824 be used in a while loop, reading C<$maxlength> bytes on every call.
1825 C<$maxlength> defaults to the size of the request if not specified.
1826
1827 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1828 directly.
1829
1830 Warning: If you use read(), Catalyst will not process the body,
1831 so you will not be able to access POST parameters or file uploads via
1832 $c->request.  You must handle all body parsing yourself.
1833
1834 =cut
1835
1836 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1837
1838 =head2 $c->run
1839
1840 Starts the engine.
1841
1842 =cut
1843
1844 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1845
1846 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1847
1848 Sets an action in a given namespace.
1849
1850 =cut
1851
1852 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1853
1854 =head2 $c->setup_actions($component)
1855
1856 Sets up actions for a component.
1857
1858 =cut
1859
1860 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1861
1862 =head2 $c->setup_components
1863
1864 Sets up components. Specify a C<setup_components> config option to pass
1865 additional options directly to L<Module::Pluggable>. To add additional
1866 search paths, specify a key named C<search_extra> as an array
1867 reference. Items in the array beginning with C<::> will have the
1868 application class name prepended to them.
1869
1870 =cut
1871
1872 sub setup_components {
1873     my $class = shift;
1874
1875     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1876     my $config  = $class->config->{ setup_components };
1877     my $extra   = delete $config->{ search_extra } || [];
1878
1879     push @paths, @$extra;
1880
1881     my $locator = Module::Pluggable::Object->new(
1882         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1883         %$config
1884     );
1885
1886     my @comps = sort { length $a <=> length $b } $locator->plugins;
1887     my %comps = map { $_ => 1 } @comps;
1888
1889     for my $component ( @comps ) {
1890
1891         # We pass ignore_loaded here so that overlay files for (e.g.)
1892         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1893         # we know M::P::O found a file on disk so this is safe
1894
1895         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1896
1897         my $module  = $class->setup_component( $component );
1898         my %modules = (
1899             $component => $module,
1900             map {
1901                 $_ => $class->setup_component( $_ )
1902             } grep {
1903               not exists $comps{$_}
1904             } Devel::InnerPackage::list_packages( $component )
1905         );
1906
1907         for my $key ( keys %modules ) {
1908             $class->components->{ $key } = $modules{ $key };
1909         }
1910     }
1911 }
1912
1913 =head2 $c->setup_component
1914
1915 =cut
1916
1917 sub setup_component {
1918     my( $class, $component ) = @_;
1919
1920     unless ( $component->can( 'COMPONENT' ) ) {
1921         return $component;
1922     }
1923
1924     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1925     my $config = $class->config->{ $suffix } || {};
1926
1927     my $instance = eval { $component->COMPONENT( $class, $config ); };
1928
1929     if ( my $error = $@ ) {
1930         chomp $error;
1931         Catalyst::Exception->throw(
1932             message => qq/Couldn't instantiate component "$component", "$error"/
1933         );
1934     }
1935
1936     Catalyst::Exception->throw(
1937         message =>
1938         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1939     ) unless eval { $instance->can( 'can' ) };
1940
1941     return $instance;
1942 }
1943
1944 =head2 $c->setup_dispatcher
1945
1946 Sets up dispatcher.
1947
1948 =cut
1949
1950 sub setup_dispatcher {
1951     my ( $class, $dispatcher ) = @_;
1952
1953     if ($dispatcher) {
1954         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1955     }
1956
1957     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
1958         $dispatcher = 'Catalyst::Dispatcher::' . $env;
1959     }
1960
1961     unless ($dispatcher) {
1962         $dispatcher = $class->dispatcher_class;
1963     }
1964
1965     unless (Class::Inspector->loaded($dispatcher)) {
1966         require Class::Inspector->filename($dispatcher);
1967     }
1968
1969     # dispatcher instance
1970     $class->dispatcher( $dispatcher->new );
1971 }
1972
1973 =head2 $c->setup_engine
1974
1975 Sets up engine.
1976
1977 =cut
1978
1979 sub setup_engine {
1980     my ( $class, $engine ) = @_;
1981
1982     if ($engine) {
1983         $engine = 'Catalyst::Engine::' . $engine;
1984     }
1985
1986     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
1987         $engine = 'Catalyst::Engine::' . $env;
1988     }
1989
1990     if ( $ENV{MOD_PERL} ) {
1991
1992         # create the apache method
1993         {
1994             no strict 'refs';
1995             *{"$class\::apache"} = sub { shift->engine->apache };
1996         }
1997
1998         my ( $software, $version ) =
1999           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2000
2001         $version =~ s/_//g;
2002         $version =~ s/(\.[^.]+)\./$1/g;
2003
2004         if ( $software eq 'mod_perl' ) {
2005
2006             if ( !$engine ) {
2007
2008                 if ( $version >= 1.99922 ) {
2009                     $engine = 'Catalyst::Engine::Apache2::MP20';
2010                 }
2011
2012                 elsif ( $version >= 1.9901 ) {
2013                     $engine = 'Catalyst::Engine::Apache2::MP19';
2014                 }
2015
2016                 elsif ( $version >= 1.24 ) {
2017                     $engine = 'Catalyst::Engine::Apache::MP13';
2018                 }
2019
2020                 else {
2021                     Catalyst::Exception->throw( message =>
2022                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2023                 }
2024
2025             }
2026
2027             # install the correct mod_perl handler
2028             if ( $version >= 1.9901 ) {
2029                 *handler = sub  : method {
2030                     shift->handle_request(@_);
2031                 };
2032             }
2033             else {
2034                 *handler = sub ($$) { shift->handle_request(@_) };
2035             }
2036
2037         }
2038
2039         elsif ( $software eq 'Zeus-Perl' ) {
2040             $engine = 'Catalyst::Engine::Zeus';
2041         }
2042
2043         else {
2044             Catalyst::Exception->throw(
2045                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2046         }
2047     }
2048
2049     unless ($engine) {
2050         $engine = $class->engine_class;
2051     }
2052
2053     unless (Class::Inspector->loaded($engine)) {
2054         require Class::Inspector->filename($engine);
2055     }
2056
2057     # check for old engines that are no longer compatible
2058     my $old_engine;
2059     if ( $engine->isa('Catalyst::Engine::Apache')
2060         && !Catalyst::Engine::Apache->VERSION )
2061     {
2062         $old_engine = 1;
2063     }
2064
2065     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2066         && Catalyst::Engine::Server->VERSION le '0.02' )
2067     {
2068         $old_engine = 1;
2069     }
2070
2071     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2072         && $engine->VERSION eq '0.01' )
2073     {
2074         $old_engine = 1;
2075     }
2076
2077     elsif ($engine->isa('Catalyst::Engine::Zeus')
2078         && $engine->VERSION eq '0.01' )
2079     {
2080         $old_engine = 1;
2081     }
2082
2083     if ($old_engine) {
2084         Catalyst::Exception->throw( message =>
2085               qq/Engine "$engine" is not supported by this version of Catalyst/
2086         );
2087     }
2088
2089     # engine instance
2090     $class->engine( $engine->new );
2091 }
2092
2093 =head2 $c->setup_home
2094
2095 Sets up the home directory.
2096
2097 =cut
2098
2099 sub setup_home {
2100     my ( $class, $home ) = @_;
2101
2102     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2103         $home = $env;
2104     }
2105
2106     unless ($home) {
2107         $home = Catalyst::Utils::home($class);
2108     }
2109
2110     if ($home) {
2111         $class->config->{home} ||= $home;
2112         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2113     }
2114 }
2115
2116 =head2 $c->setup_log
2117
2118 Sets up log.
2119
2120 =cut
2121
2122 sub setup_log {
2123     my ( $class, $debug ) = @_;
2124
2125     unless ( $class->log ) {
2126         $class->log( Catalyst::Log->new );
2127     }
2128
2129     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2130     if ( defined($env_debug) ? $env_debug : $debug ) {
2131         no strict 'refs';
2132         *{"$class\::debug"} = sub { 1 };
2133         $class->log->debug('Debug messages enabled');
2134     }
2135 }
2136
2137 =head2 $c->setup_plugins
2138
2139 Sets up plugins.
2140
2141 =cut
2142
2143 =head2 $c->setup_stats
2144
2145 Sets up timing statistics class.
2146
2147 =cut
2148
2149 sub setup_stats {
2150     my ( $class, $stats ) = @_;
2151
2152     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2153
2154     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2155     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2156         no strict 'refs';
2157         *{"$class\::use_stats"} = sub { 1 };
2158         $class->log->debug('Statistics enabled');
2159     }
2160 }
2161
2162
2163 =head2 $c->registered_plugins
2164
2165 Returns a sorted list of the plugins which have either been stated in the
2166 import list or which have been added via C<< MyApp->plugin(@args); >>.
2167
2168 If passed a given plugin name, it will report a boolean value indicating
2169 whether or not that plugin is loaded.  A fully qualified name is required if
2170 the plugin name does not begin with C<Catalyst::Plugin::>.
2171
2172  if ($c->registered_plugins('Some::Plugin')) {
2173      ...
2174  }
2175
2176 =cut
2177
2178 {
2179
2180     sub registered_plugins {
2181         my $proto = shift;
2182         return sort keys %{ $proto->_plugins } unless @_;
2183         my $plugin = shift;
2184         return 1 if exists $proto->_plugins->{$plugin};
2185         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2186     }
2187
2188     sub _register_plugin {
2189         my ( $proto, $plugin, $instant ) = @_;
2190         my $class = ref $proto || $proto;
2191
2192         # no ignore_loaded here, the plugin may already have been
2193         # defined in memory and we don't want to error on "no file" if so
2194
2195         Catalyst::Utils::ensure_class_loaded( $plugin );
2196
2197         $proto->_plugins->{$plugin} = 1;
2198         unless ($instant) {
2199             no strict 'refs';
2200             unshift @{"$class\::ISA"}, $plugin;
2201         }
2202         return $class;
2203     }
2204
2205     sub setup_plugins {
2206         my ( $class, $plugins ) = @_;
2207
2208         $class->_plugins( {} ) unless $class->_plugins;
2209         $plugins ||= [];
2210         for my $plugin ( reverse @$plugins ) {
2211
2212             unless ( $plugin =~ s/\A\+// ) {
2213                 $plugin = "Catalyst::Plugin::$plugin";
2214             }
2215
2216             $class->_register_plugin($plugin);
2217         }
2218     }
2219 }
2220
2221 =head2 $c->stack
2222
2223 Returns an arrayref of the internal execution stack (actions that are
2224 currently executing).
2225
2226 =head2 $c->stats_class
2227
2228 Returns or sets the stats (timing statistics) class.
2229
2230 =head2 $c->use_stats
2231
2232 Returns 1 when stats collection is enabled.  Stats collection is enabled
2233 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2234 environment variable is set.
2235
2236 Note that this is a static method, not an accessor and should be overloaded
2237 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2238
2239 =cut
2240
2241 sub use_stats { 0 }
2242
2243
2244 =head2 $c->write( $data )
2245
2246 Writes $data to the output stream. When using this method directly, you
2247 will need to manually set the C<Content-Length> header to the length of
2248 your output data, if known.
2249
2250 =cut
2251
2252 sub write {
2253     my $c = shift;
2254
2255     # Finalize headers if someone manually writes output
2256     $c->finalize_headers;
2257
2258     return $c->engine->write( $c, @_ );
2259 }
2260
2261 =head2 version
2262
2263 Returns the Catalyst version number. Mostly useful for "powered by"
2264 messages in template systems.
2265
2266 =cut
2267
2268 sub version { return $Catalyst::VERSION }
2269
2270 =head1 INTERNAL ACTIONS
2271
2272 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2273 C<_ACTION>, and C<_END>. These are by default not shown in the private
2274 action table, but you can make them visible with a config parameter.
2275
2276     MyApp->config->{show_internal_actions} = 1;
2277
2278 =head1 CASE SENSITIVITY
2279
2280 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2281 mapped to C</foo/bar>. You can activate case sensitivity with a config
2282 parameter.
2283
2284     MyApp->config->{case_sensitive} = 1;
2285
2286 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2287
2288 =head1 ON-DEMAND PARSER
2289
2290 The request body is usually parsed at the beginning of a request,
2291 but if you want to handle input yourself, you can enable on-demand
2292 parsing with a config parameter.
2293
2294     MyApp->config->{parse_on_demand} = 1;
2295
2296 =head1 PROXY SUPPORT
2297
2298 Many production servers operate using the common double-server approach,
2299 with a lightweight frontend web server passing requests to a larger
2300 backend server. An application running on the backend server must deal
2301 with two problems: the remote user always appears to be C<127.0.0.1> and
2302 the server's hostname will appear to be C<localhost> regardless of the
2303 virtual host that the user connected through.
2304
2305 Catalyst will automatically detect this situation when you are running
2306 the frontend and backend servers on the same machine. The following
2307 changes are made to the request.
2308
2309     $c->req->address is set to the user's real IP address, as read from
2310     the HTTP X-Forwarded-For header.
2311
2312     The host value for $c->req->base and $c->req->uri is set to the real
2313     host, as read from the HTTP X-Forwarded-Host header.
2314
2315 Obviously, your web server must support these headers for this to work.
2316
2317 In a more complex server farm environment where you may have your
2318 frontend proxy server(s) on different machines, you will need to set a
2319 configuration option to tell Catalyst to read the proxied data from the
2320 headers.
2321
2322     MyApp->config->{using_frontend_proxy} = 1;
2323
2324 If you do not wish to use the proxy support at all, you may set:
2325
2326     MyApp->config->{ignore_frontend_proxy} = 1;
2327
2328 =head1 THREAD SAFETY
2329
2330 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2331 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2332 believe the Catalyst core to be thread-safe.
2333
2334 If you plan to operate in a threaded environment, remember that all other
2335 modules you are using must also be thread-safe. Some modules, most notably
2336 L<DBD::SQLite>, are not thread-safe.
2337
2338 =head1 SUPPORT
2339
2340 IRC:
2341
2342     Join #catalyst on irc.perl.org.
2343
2344 Mailing Lists:
2345
2346     http://lists.rawmode.org/mailman/listinfo/catalyst
2347     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2348
2349 Web:
2350
2351     http://catalyst.perl.org
2352
2353 Wiki:
2354
2355     http://dev.catalyst.perl.org
2356
2357 =head1 SEE ALSO
2358
2359 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2360
2361 =head2 L<Catalyst::Manual> - The Catalyst Manual
2362
2363 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2364
2365 =head2 L<Catalyst::Engine> - Core engine
2366
2367 =head2 L<Catalyst::Log> - Log class.
2368
2369 =head2 L<Catalyst::Request> - Request object
2370
2371 =head2 L<Catalyst::Response> - Response object
2372
2373 =head2 L<Catalyst::Test> - The test suite.
2374
2375 =head1 CREDITS
2376
2377 Andy Grundman
2378
2379 Andy Wardley
2380
2381 Andreas Marienborg
2382
2383 Andrew Bramble
2384
2385 Andrew Ford
2386
2387 Andrew Ruthven
2388
2389 Arthur Bergman
2390
2391 Autrijus Tang
2392
2393 Brian Cassidy
2394
2395 Carl Franks
2396
2397 Christian Hansen
2398
2399 Christopher Hicks
2400
2401 Dan Sully
2402
2403 Danijel Milicevic
2404
2405 David Kamholz
2406
2407 David Naughton
2408
2409 Drew Taylor
2410
2411 Gary Ashton Jones
2412
2413 Geoff Richards
2414
2415 Jesse Sheidlower
2416
2417 Jesse Vincent
2418
2419 Jody Belka
2420
2421 Johan Lindstrom
2422
2423 Juan Camacho
2424
2425 Leon Brocard
2426
2427 Marcus Ramberg
2428
2429 Matt S Trout
2430
2431 Robert Sedlacek
2432
2433 Sam Vilain
2434
2435 Sascha Kiefer
2436
2437 Sebastian Willert
2438
2439 Tatsuhiko Miyagawa
2440
2441 Ulf Edvinsson
2442
2443 Yuval Kogman
2444
2445 =head1 AUTHOR
2446
2447 Sebastian Riedel, C<sri@oook.de>
2448
2449 =head1 LICENSE
2450
2451 This library is free software, you can redistribute it and/or modify it under
2452 the same terms as Perl itself.
2453
2454 =cut
2455
2456 1;