lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         $self->request_class->new($self->_build_request_constructor_args);
  67     },
  68     lazy => 1,
  69 );
  70 sub _build_request_constructor_args {
  71     my $self = shift;
  72     my %p = ( _log => $self->log );
  73     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  74     $p{data_handlers} = {$self->registered_data_handlers};
  75     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  76       if $self->config->{use_hash_multivalue_in_request};
  77     \%p;
  78 }
  79
  80 has response => (
  81     is => 'rw',
  82     default => sub {
  83         my $self = shift;
  84         $self->response_class->new($self->_build_response_constructor_args);
  85     },
  86     lazy => 1,
  87 );
  88 sub _build_response_constructor_args {
  89     my $self = shift;
  90     { _log => $self->log };
  91 }
  92
  93 has namespace => (is => 'rw');
  94
  95 sub depth { scalar @{ shift->stack || [] }; }
  96 sub comp { shift->component(@_) }
  97
  98 sub req {
  99     my $self = shift; return $self->request(@_);
 100 }
 101 sub res {
 102     my $self = shift; return $self->response(@_);
 103 }
 104
 105 # For backwards compatibility
 106 sub finalize_output { shift->finalize_body(@_) };
 107
 108 # For statistics
 109 our $COUNT     = 1;
 110 our $START     = time;
 111 our $RECURSION = 1000;
 112 our $DETACH    = Catalyst::Exception::Detach->new;
 113 our $GO        = Catalyst::Exception::Go->new;
 114
 115 #I imagine that very few of these really need to be class variables. if any.
 116 #maybe we should just make them attributes with a default?
 117 __PACKAGE__->mk_classdata($_)
 118   for qw/components arguments dispatcher engine log dispatcher_class
 119   engine_loader context_class request_class response_class stats_class
 120   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 121   _data_handlers _encoding _encode_check/;
 122
 123 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 124 __PACKAGE__->request_class('Catalyst::Request');
 125 __PACKAGE__->response_class('Catalyst::Response');
 126 __PACKAGE__->stats_class('Catalyst::Stats');
 127 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 128
 129 # Remember to update this in Catalyst::Runtime as well!
 130 our $VERSION = '5.90080_001';
 131 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 132
 133 sub import {
 134     my ( $class, @arguments ) = @_;
 135
 136     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 137     # callers @ISA.
 138     return unless $class eq 'Catalyst';
 139
 140     my $caller = caller();
 141     return if $caller eq 'main';
 142
 143     my $meta = Moose::Meta::Class->initialize($caller);
 144     unless ( $caller->isa('Catalyst') ) {
 145         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 146         $meta->superclasses(@superclasses);
 147     }
 148     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 149     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 150
 151     unless( $meta->has_method('meta') ){
 152         if ($Moose::VERSION >= 1.15) {
 153             $meta->_add_meta_method('meta');
 154         }
 155         else {
 156             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 157         }
 158     }
 159
 160     $caller->arguments( [@arguments] );
 161     $caller->setup_home;
 162 }
 163
 164 sub _application { $_[0] }
 165
 166 =encoding UTF-8
 167
 168 =head1 NAME
 169
 170 Catalyst - The Elegant MVC Web Application Framework
 171
 172 =head1 SYNOPSIS
 173
 174 See the L<Catalyst::Manual> distribution for comprehensive
 175 documentation and tutorials.
 176
 177     # Install Catalyst::Devel for helpers and other development tools
 178     # use the helper to create a new application
 179     catalyst.pl MyApp
 180
 181     # add models, views, controllers
 182     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 183     script/myapp_create.pl view MyTemplate TT
 184     script/myapp_create.pl controller Search
 185
 186     # built in testserver -- use -r to restart automatically on changes
 187     # --help to see all available options
 188     script/myapp_server.pl
 189
 190     # command line testing interface
 191     script/myapp_test.pl /yada
 192
 193     ### in lib/MyApp.pm
 194     use Catalyst qw/-Debug/; # include plugins here as well
 195
 196     ### In lib/MyApp/Controller/Root.pm (autocreated)
 197     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 198         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 199         $c->stash->{template} = 'foo.tt'; # set the template
 200         # lookup something from db -- stash vars are passed to TT
 201         $c->stash->{data} =
 202           $c->model('Database::Foo')->search( { country => $args[0] } );
 203         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 204             $c->forward( 'bar' ); # process another action
 205             # do something else after forward returns
 206         }
 207     }
 208
 209     # The foo.tt TT template can use the stash data from the database
 210     [% WHILE (item = data.next) %]
 211         [% item.foo %]
 212     [% END %]
 213
 214     # called for /bar/of/soap, /bar/of/soap/10, etc.
 215     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 216
 217     # called after all actions are finished
 218     sub end : Action {
 219         my ( $self, $c ) = @_;
 220         if ( scalar @{ $c->error } ) { ... } # handle errors
 221         return if $c->res->body; # already have a response
 222         $c->forward( 'MyApp::View::TT' ); # render template
 223     }
 224
 225 See L<Catalyst::Manual::Intro> for additional information.
 226
 227 =head1 DESCRIPTION
 228
 229 Catalyst is a modern framework for making web applications without the
 230 pain usually associated with this process. This document is a reference
 231 to the main Catalyst application. If you are a new user, we suggest you
 232 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 233
 234 See L<Catalyst::Manual> for more documentation.
 235
 236 Catalyst plugins can be loaded by naming them as arguments to the "use
 237 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 238 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 239 C<My::Module>.
 240
 241     use Catalyst qw/My::Module/;
 242
 243 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 244 fully qualify the name by using a unary plus:
 245
 246     use Catalyst qw/
 247         My::Module
 248         +Fully::Qualified::Plugin::Name
 249     /;
 250
 251 Special flags like C<-Debug> can also be specified as
 252 arguments when Catalyst is loaded:
 253
 254     use Catalyst qw/-Debug My::Module/;
 255
 256 The position of plugins and flags in the chain is important, because
 257 they are loaded in the order in which they appear.
 258
 259 The following flags are supported:
 260
 261 =head2 -Debug
 262
 263 Enables debug output. You can also force this setting from the system
 264 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 265 settings override the application, with <MYAPP>_DEBUG having the highest
 266 priority.
 267
 268 This sets the log level to 'debug' and enables full debug output on the
 269 error screen. If you only want the latter, see L<< $c->debug >>.
 270
 271 =head2 -Home
 272
 273 Forces Catalyst to use a specific home directory, e.g.:
 274
 275     use Catalyst qw[-Home=/usr/mst];
 276
 277 This can also be done in the shell environment by setting either the
 278 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 279 is replaced with the uppercased name of your application, any "::" in
 280 the name will be replaced with underscores, e.g. MyApp::Web should use
 281 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 282
 283 If none of these are set, Catalyst will attempt to automatically detect the
 284 home directory. If you are working in a development environment, Catalyst
 285 will try and find the directory containing either Makefile.PL, Build.PL,
 286 dist.ini, or cpanfile. If the application has been installed into the system
 287 (i.e. you have done C<make install>), then Catalyst will use the path to your
 288 application module, without the .pm extension (e.g., /foo/MyApp if your
 289 application was installed at /foo/MyApp.pm)
 290
 291 =head2 -Log
 292
 293     use Catalyst '-Log=warn,fatal,error';
 294
 295 Specifies a comma-delimited list of log levels.
 296
 297 =head2 -Stats
 298
 299 Enables statistics collection and reporting.
 300
 301    use Catalyst qw/-Stats=1/;
 302
 303 You can also force this setting from the system environment with CATALYST_STATS
 304 or <MYAPP>_STATS. The environment settings override the application, with
 305 <MYAPP>_STATS having the highest priority.
 306
 307 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 308
 309 =head1 METHODS
 310
 311 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 312
 313 =head2 $c->action
 314
 315 Returns a L<Catalyst::Action> object for the current action, which
 316 stringifies to the action name. See L<Catalyst::Action>.
 317
 318 =head2 $c->namespace
 319
 320 Returns the namespace of the current action, i.e., the URI prefix
 321 corresponding to the controller of the current action. For example:
 322
 323     # in Controller::Foo::Bar
 324     $c->namespace; # returns 'foo/bar';
 325
 326 =head2 $c->request
 327
 328 =head2 $c->req
 329
 330 Returns the current L<Catalyst::Request> object, giving access to
 331 information about the current client request (including parameters,
 332 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 333
 334 =head2 REQUEST FLOW HANDLING
 335
 336 =head2 $c->forward( $action [, \@arguments ] )
 337
 338 =head2 $c->forward( $class, $method, [, \@arguments ] )
 339
 340 This is one way of calling another action (method) in the same or
 341 a different controller. You can also use C<< $self->my_method($c, @args) >>
 342 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 343 in a different controller.
 344 The main difference is that 'forward' uses some of the Catalyst request
 345 cycle overhead, including debugging, which may be useful to you. On the
 346 other hand, there are some complications to using 'forward', restrictions
 347 on values returned from 'forward', and it may not handle errors as you prefer.
 348 Whether you use 'forward' or not is up to you; it is not considered superior to
 349 the other ways to call a method.
 350
 351 'forward' calls  another action, by its private name. If you give a
 352 class name but no method, C<process()> is called. You may also optionally
 353 pass arguments in an arrayref. The action will receive the arguments in
 354 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 355 C<< $c->req->args >> will be restored to the previous values.
 356
 357 Any data C<return>ed from the action forwarded to, will be returned by the
 358 call to forward.
 359
 360     my $foodata = $c->forward('/foo');
 361     $c->forward('index');
 362     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 363     $c->forward('View::TT');
 364
 365 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 366 an C<< eval { } >> around the call (actually
 367 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 368 exceptions thrown by the called action non-fatal and pushing them onto
 369 $c->error instead. If you want C<die> to propagate you need to do something
 370 like:
 371
 372     $c->forward('foo');
 373     die join "\n", @{ $c->error } if @{ $c->error };
 374
 375 Or make sure to always return true values from your actions and write
 376 your code like this:
 377
 378     $c->forward('foo') || return;
 379
 380 Another note is that C<< $c->forward >> always returns a scalar because it
 381 actually returns $c->state which operates in a scalar context.
 382 Thus, something like:
 383
 384     return @array;
 385
 386 in an action that is forwarded to is going to return a scalar,
 387 i.e. how many items are in that array, which is probably not what you want.
 388 If you need to return an array then return a reference to it,
 389 or stash it like so:
 390
 391     $c->stash->{array} = \@array;
 392
 393 and access it from the stash.
 394
 395 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 396
 397 =cut
 398
 399 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 400
 401 =head2 $c->detach( $action [, \@arguments ] )
 402
 403 =head2 $c->detach( $class, $method, [, \@arguments ] )
 404
 405 =head2 $c->detach()
 406
 407 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 408 doesn't return to the previous action when processing is finished.
 409
 410 When called with no arguments it escapes the processing chain entirely.
 411
 412 =cut
 413
 414 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 415
 416 =head2 $c->visit( $action [, \@arguments ] )
 417
 418 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 419
 420 =head2 $c->visit( $class, $method, [, \@arguments ] )
 421
 422 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 423
 424 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 425 but does a full dispatch, instead of just calling the new C<$action> /
 426 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 427 you go to are called, just like a new request.
 428
 429 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 430 This means, for example, that C<< $c->action >> methods such as
 431 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 432 L<reverse|Catalyst::Action/reverse> return information for the visited action
 433 when they are invoked within the visited action.  This is different from the
 434 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 435 continues to use the $c->action object from the caller action even when
 436 invoked from the called action.
 437
 438 C<< $c->stash >> is kept unchanged.
 439
 440 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 441 allows you to "wrap" another action, just as it would have been called by
 442 dispatching from a URL, while the analogous
 443 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 444 transfer control to another action as if it had been reached directly from a URL.
 445
 446 =cut
 447
 448 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 449
 450 =head2 $c->go( $action [, \@arguments ] )
 451
 452 =head2 $c->go( $action [, \@captures, \@arguments ] )
 453
 454 =head2 $c->go( $class, $method, [, \@arguments ] )
 455
 456 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 457
 458 The relationship between C<go> and
 459 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 460 the relationship between
 461 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 462 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 463 C<< $c->go >> will perform a full dispatch on the specified action or method,
 464 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 465 C<go> escapes the processing of the current request chain on completion, and
 466 does not return to its caller.
 467
 468 @arguments are arguments to the final destination of $action. @captures are
 469 arguments to the intermediate steps, if any, on the way to the final sub of
 470 $action.
 471
 472 =cut
 473
 474 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 475
 476 =head2 $c->response
 477
 478 =head2 $c->res
 479
 480 Returns the current L<Catalyst::Response> object, see there for details.
 481
 482 =head2 $c->stash
 483
 484 Returns a hashref to the stash, which may be used to store data and pass
 485 it between components during a request. You can also set hash keys by
 486 passing arguments. The stash is automatically sent to the view. The
 487 stash is cleared at the end of a request; it cannot be used for
 488 persistent storage (for this you must use a session; see
 489 L<Catalyst::Plugin::Session> for a complete system integrated with
 490 Catalyst).
 491
 492     $c->stash->{foo} = $bar;
 493     $c->stash( { moose => 'majestic', qux => 0 } );
 494     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 495
 496     # stash is automatically passed to the view for use in a template
 497     $c->forward( 'MyApp::View::TT' );
 498
 499 The stash hash is currently stored in the PSGI C<$env> and is managed by
 500 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 501 the stash can be accessed in sub applications mounted under your main
 502 L<Catalyst> application.  For example if you delegate the response of an
 503 action to another L<Catalyst> application, that sub application will have
 504 access to all the stash keys of the main one, and if can of course add
 505 more keys of its own.  However those new keys will not 'bubble' back up
 506 to the main application.
 507
 508 For more information the best thing to do is to review the test case:
 509 t/middleware-stash.t in the distribution /t directory.
 510
 511 =cut
 512
 513 sub stash {
 514   my $c = shift;
 515   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 516 }
 517
 518 =head2 $c->error
 519
 520 =head2 $c->error($error, ...)
 521
 522 =head2 $c->error($arrayref)
 523
 524 Returns an arrayref containing error messages.  If Catalyst encounters an
 525 error while processing a request, it stores the error in $c->error.  This
 526 method should only be used to store fatal error messages.
 527
 528     my @error = @{ $c->error };
 529
 530 Add a new error.
 531
 532     $c->error('Something bad happened');
 533
 534 =cut
 535
 536 sub error {
 537     my $c = shift;
 538     if ( $_[0] ) {
 539         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 540         croak @$error unless ref $c;
 541         push @{ $c->{error} }, @$error;
 542     }
 543     elsif ( defined $_[0] ) { $c->{error} = undef }
 544     return $c->{error} || [];
 545 }
 546
 547
 548 =head2 $c->state
 549
 550 Contains the return value of the last executed action.
 551 Note that << $c->state >> operates in a scalar context which means that all
 552 values it returns are scalar.
 553
 554 =head2 $c->clear_errors
 555
 556 Clear errors.  You probably don't want to clear the errors unless you are
 557 implementing a custom error screen.
 558
 559 This is equivalent to running
 560
 561     $c->error(0);
 562
 563 =cut
 564
 565 sub clear_errors {
 566     my $c = shift;
 567     $c->error(0);
 568 }
 569
 570 =head2 $c->has_errors
 571
 572 Returns true if you have errors
 573
 574 =cut
 575
 576 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 577
 578 sub _comp_search_prefixes {
 579     my $c = shift;
 580     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 581 }
 582
 583 # search components given a name and some prefixes
 584 sub _comp_names_search_prefixes {
 585     my ( $c, $name, @prefixes ) = @_;
 586     my $appclass = ref $c || $c;
 587     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 588     $filter = qr/$filter/; # Compile regex now rather than once per loop
 589
 590     # map the original component name to the sub part that we will search against
 591     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 592         grep { /$filter/ } keys %{ $c->components };
 593
 594     # undef for a name will return all
 595     return keys %eligible if !defined $name;
 596
 597     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 598     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 599
 600     return @result if @result;
 601
 602     # if we were given a regexp to search against, we're done.
 603     return if $name->$_isa('Regexp');
 604
 605     # skip regexp fallback if configured
 606     return
 607         if $appclass->config->{disable_component_resolution_regex_fallback};
 608
 609     # regexp fallback
 610     $query  = qr/$name/i;
 611     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 612
 613     # no results? try against full names
 614     if( !@result ) {
 615         @result = grep { m{$query} } keys %eligible;
 616     }
 617
 618     # don't warn if we didn't find any results, it just might not exist
 619     if( @result ) {
 620         # Disgusting hack to work out correct method name
 621         my $warn_for = lc $prefixes[0];
 622         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 623            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 624            "component resolution is unreliable and unsafe.";
 625         my $short = $result[0];
 626         # remove the component namespace prefix
 627         $short =~ s/.*?(Model|Controller|View):://;
 628         my $shortmess = Carp::shortmess('');
 629         if ($shortmess =~ m#Catalyst/Plugin#) {
 630            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 631               "plugin's config";
 632         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 633            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 634               "component's config";
 635         } else {
 636            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 637               "but if you really wanted to search, pass in a regexp as the argument " .
 638               "like so: \$c->${warn_for}(qr/${name}/)";
 639         }
 640         $c->log->warn( "${msg}$shortmess" );
 641     }
 642
 643     return @result;
 644 }
 645
 646 # Find possible names for a prefix
 647 sub _comp_names {
 648     my ( $c, @prefixes ) = @_;
 649     my $appclass = ref $c || $c;
 650
 651     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 652
 653     my @names = map { s{$filter}{}; $_; }
 654         $c->_comp_names_search_prefixes( undef, @prefixes );
 655
 656     return @names;
 657 }
 658
 659 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 660 sub _filter_component {
 661     my ( $c, $comp, @args ) = @_;
 662
 663     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 664         return $comp->ACCEPT_CONTEXT( $c, @args );
 665     }
 666
 667     return $comp;
 668 }
 669
 670 =head2 COMPONENT ACCESSORS
 671
 672 =head2 $c->controller($name)
 673
 674 Gets a L<Catalyst::Controller> instance by name.
 675
 676     $c->controller('Foo')->do_stuff;
 677
 678 If the name is omitted, will return the controller for the dispatched
 679 action.
 680
 681 If you want to search for controllers, pass in a regexp as the argument.
 682
 683     # find all controllers that start with Foo
 684     my @foo_controllers = $c->controller(qr{^Foo});
 685
 686
 687 =cut
 688
 689 sub controller {
 690     my ( $c, $name, @args ) = @_;
 691
 692     my $appclass = ref($c) || $c;
 693     if( $name ) {
 694         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 695             my $comps = $c->components;
 696             my $check = $appclass."::Controller::".$name;
 697             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 698         }
 699         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 700         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 701         return $c->_filter_component( $result[ 0 ], @args );
 702     }
 703
 704     return $c->component( $c->action->class );
 705 }
 706
 707 =head2 $c->model($name)
 708
 709 Gets a L<Catalyst::Model> instance by name.
 710
 711     $c->model('Foo')->do_stuff;
 712
 713 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 714
 715 If the name is omitted, it will look for
 716  - a model object in $c->stash->{current_model_instance}, then
 717  - a model name in $c->stash->{current_model}, then
 718  - a config setting 'default_model', or
 719  - check if there is only one model, and return it if that's the case.
 720
 721 If you want to search for models, pass in a regexp as the argument.
 722
 723     # find all models that start with Foo
 724     my @foo_models = $c->model(qr{^Foo});
 725
 726 =cut
 727
 728 sub model {
 729     my ( $c, $name, @args ) = @_;
 730     my $appclass = ref($c) || $c;
 731     if( $name ) {
 732         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 733             my $comps = $c->components;
 734             my $check = $appclass."::Model::".$name;
 735             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 736         }
 737         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 738         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 739         return $c->_filter_component( $result[ 0 ], @args );
 740     }
 741
 742     if (ref $c) {
 743         return $c->stash->{current_model_instance}
 744           if $c->stash->{current_model_instance};
 745         return $c->model( $c->stash->{current_model} )
 746           if $c->stash->{current_model};
 747     }
 748     return $c->model( $appclass->config->{default_model} )
 749       if $appclass->config->{default_model};
 750
 751     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 752
 753     if( $rest ) {
 754         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 755         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 756         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 757         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 758         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 759     }
 760
 761     return $c->_filter_component( $comp );
 762 }
 763
 764
 765 =head2 $c->view($name)
 766
 767 Gets a L<Catalyst::View> instance by name.
 768
 769     $c->view('Foo')->do_stuff;
 770
 771 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 772
 773 If the name is omitted, it will look for
 774  - a view object in $c->stash->{current_view_instance}, then
 775  - a view name in $c->stash->{current_view}, then
 776  - a config setting 'default_view', or
 777  - check if there is only one view, and return it if that's the case.
 778
 779 If you want to search for views, pass in a regexp as the argument.
 780
 781     # find all views that start with Foo
 782     my @foo_views = $c->view(qr{^Foo});
 783
 784 =cut
 785
 786 sub view {
 787     my ( $c, $name, @args ) = @_;
 788
 789     my $appclass = ref($c) || $c;
 790     if( $name ) {
 791         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 792             my $comps = $c->components;
 793             my $check = $appclass."::View::".$name;
 794             if( exists $comps->{$check} ) {
 795                 return $c->_filter_component( $comps->{$check}, @args );
 796             }
 797             else {
 798                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 799             }
 800         }
 801         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 802         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 803         return $c->_filter_component( $result[ 0 ], @args );
 804     }
 805
 806     if (ref $c) {
 807         return $c->stash->{current_view_instance}
 808           if $c->stash->{current_view_instance};
 809         return $c->view( $c->stash->{current_view} )
 810           if $c->stash->{current_view};
 811     }
 812     return $c->view( $appclass->config->{default_view} )
 813       if $appclass->config->{default_view};
 814
 815     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 816
 817     if( $rest ) {
 818         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 819         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 820         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 821         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 822         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 823     }
 824
 825     return $c->_filter_component( $comp );
 826 }
 827
 828 =head2 $c->controllers
 829
 830 Returns the available names which can be passed to $c->controller
 831
 832 =cut
 833
 834 sub controllers {
 835     my ( $c ) = @_;
 836     return $c->_comp_names(qw/Controller C/);
 837 }
 838
 839 =head2 $c->models
 840
 841 Returns the available names which can be passed to $c->model
 842
 843 =cut
 844
 845 sub models {
 846     my ( $c ) = @_;
 847     return $c->_comp_names(qw/Model M/);
 848 }
 849
 850
 851 =head2 $c->views
 852
 853 Returns the available names which can be passed to $c->view
 854
 855 =cut
 856
 857 sub views {
 858     my ( $c ) = @_;
 859     return $c->_comp_names(qw/View V/);
 860 }
 861
 862 =head2 $c->comp($name)
 863
 864 =head2 $c->component($name)
 865
 866 Gets a component object by name. This method is not recommended,
 867 unless you want to get a specific component by full
 868 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 869 should be used instead.
 870
 871 If C<$name> is a regexp, a list of components matched against the full
 872 component name will be returned.
 873
 874 If Catalyst can't find a component by name, it will fallback to regex
 875 matching by default. To disable this behaviour set
 876 disable_component_resolution_regex_fallback to a true value.
 877
 878     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 879
 880 =cut
 881
 882 sub component {
 883     my ( $c, $name, @args ) = @_;
 884
 885     if( $name ) {
 886         my $comps = $c->components;
 887
 888         if( !ref $name ) {
 889             # is it the exact name?
 890             return $c->_filter_component( $comps->{ $name }, @args )
 891                        if exists $comps->{ $name };
 892
 893             # perhaps we just omitted "MyApp"?
 894             my $composed = ( ref $c || $c ) . "::${name}";
 895             return $c->_filter_component( $comps->{ $composed }, @args )
 896                        if exists $comps->{ $composed };
 897
 898             # search all of the models, views and controllers
 899             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 900             return $c->_filter_component( $comp, @args ) if $comp;
 901         }
 902
 903         return
 904             if $c->config->{disable_component_resolution_regex_fallback};
 905
 906         # This is here so $c->comp( '::M::' ) works
 907         my $query = ref $name ? $name : qr{$name}i;
 908
 909         my @result = grep { m{$query} } keys %{ $c->components };
 910         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 911
 912         if( $result[ 0 ] ) {
 913             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 914             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 915             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 916             return $c->_filter_component( $result[ 0 ], @args );
 917         }
 918
 919         # I would expect to return an empty list here, but that breaks back-compat
 920     }
 921
 922     # fallback
 923     return sort keys %{ $c->components };
 924 }
 925
 926 =head2 CLASS DATA AND HELPER CLASSES
 927
 928 =head2 $c->config
 929
 930 Returns or takes a hashref containing the application's configuration.
 931
 932     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 933
 934 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 935 like C<myapp.conf> in your applications home directory. See
 936 L<Catalyst::Plugin::ConfigLoader>.
 937
 938 =head3 Cascading configuration
 939
 940 The config method is present on all Catalyst components, and configuration
 941 will be merged when an application is started. Configuration loaded with
 942 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 943 followed by configuration in your top level C<MyApp> class. These two
 944 configurations are merged, and then configuration data whose hash key matches a
 945 component name is merged with configuration for that component.
 946
 947 The configuration for a component is then passed to the C<new> method when a
 948 component is constructed.
 949
 950 For example:
 951
 952     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 953     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 954
 955 will mean that C<MyApp::Model::Foo> receives the following data when
 956 constructed:
 957
 958     MyApp::Model::Foo->new({
 959         bar => 'baz',
 960         quux => 'frob',
 961         overrides => 'me',
 962     });
 963
 964 It's common practice to use a Moose attribute
 965 on the receiving component to access the config value.
 966
 967     package MyApp::Model::Foo;
 968
 969     use Moose;
 970
 971     # this attr will receive 'baz' at construction time
 972     has 'bar' => (
 973         is  => 'rw',
 974         isa => 'Str',
 975     );
 976
 977 You can then get the value 'baz' by calling $c->model('Foo')->bar
 978 (or $self->bar inside code in the model).
 979
 980 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 981 as a way of reading config within your code, as this B<will not> give you the
 982 correctly merged config back. You B<MUST> take the config values supplied to
 983 the constructor and use those instead.
 984
 985 =cut
 986
 987 around config => sub {
 988     my $orig = shift;
 989     my $c = shift;
 990
 991     croak('Setting config after setup has been run is not allowed.')
 992         if ( @_ and $c->setup_finished );
 993
 994     $c->$orig(@_);
 995 };
 996
 997 =head2 $c->log
 998
 999 Returns the logging object instance. Unless it is already set, Catalyst
1000 sets this up with a L<Catalyst::Log> object. To use your own log class,
1001 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1002 C<< __PACKAGE__->setup >>.
1003
1004  __PACKAGE__->log( MyLogger->new );
1005  __PACKAGE__->setup;
1006
1007 And later:
1008
1009     $c->log->info( 'Now logging with my own logger!' );
1010
1011 Your log class should implement the methods described in
1012 L<Catalyst::Log>.
1013
1014 =head2 encoding
1015
1016 Sets or gets the application encoding.
1017
1018 =cut
1019
1020 sub encoding {
1021     my $c = shift;
1022     my $encoding;
1023
1024     if ( scalar @_ ) {
1025         # Let it be set to undef
1026         if (my $wanted = shift)  {
1027             $encoding = Encode::find_encoding($wanted)
1028               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1029             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1030         }
1031         else {
1032             binmode(STDERR);
1033         }
1034
1035         $encoding = ref $c
1036                   ? $c->{encoding} = $encoding
1037                   : $c->_encoding($encoding);
1038     } else {
1039       $encoding = ref $c && exists $c->{encoding}
1040                 ? $c->{encoding}
1041                 : $c->_encoding;
1042     }
1043
1044     return $encoding;
1045 }
1046
1047 =head2 $c->debug
1048
1049 Returns 1 if debug mode is enabled, 0 otherwise.
1050
1051 You can enable debug mode in several ways:
1052
1053 =over
1054
1055 =item By calling myapp_server.pl with the -d flag
1056
1057 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1058
1059 =item The -Debug option in your MyApp.pm
1060
1061 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1062
1063 =back
1064
1065 The first three also set the log level to 'debug'.
1066
1067 Calling C<< $c->debug(1) >> has no effect.
1068
1069 =cut
1070
1071 sub debug { 0 }
1072
1073 =head2 $c->dispatcher
1074
1075 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1076
1077 =head2 $c->engine
1078
1079 Returns the engine instance. See L<Catalyst::Engine>.
1080
1081
1082 =head2 UTILITY METHODS
1083
1084 =head2 $c->path_to(@path)
1085
1086 Merges C<@path> with C<< $c->config->{home} >> and returns a
1087 L<Path::Class::Dir> object. Note you can usually use this object as
1088 a filename, but sometimes you will have to explicitly stringify it
1089 yourself by calling the C<< ->stringify >> method.
1090
1091 For example:
1092
1093     $c->path_to( 'db', 'sqlite.db' );
1094
1095 =cut
1096
1097 sub path_to {
1098     my ( $c, @path ) = @_;
1099     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1100     if ( -d $path ) { return $path }
1101     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1102 }
1103
1104 sub plugin {
1105     my ( $class, $name, $plugin, @args ) = @_;
1106
1107     # See block comment in t/unit_core_plugin.t
1108     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1109
1110     $class->_register_plugin( $plugin, 1 );
1111
1112     eval { $plugin->import };
1113     $class->mk_classdata($name);
1114     my $obj;
1115     eval { $obj = $plugin->new(@args) };
1116
1117     if ($@) {
1118         Catalyst::Exception->throw( message =>
1119               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1120     }
1121
1122     $class->$name($obj);
1123     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1124       if $class->debug;
1125 }
1126
1127 =head2 MyApp->setup
1128
1129 Initializes the dispatcher and engine, loads any plugins, and loads the
1130 model, view, and controller components. You may also specify an array
1131 of plugins to load here, if you choose to not load them in the C<use
1132 Catalyst> line.
1133
1134     MyApp->setup;
1135     MyApp->setup( qw/-Debug/ );
1136
1137 B<Note:> You B<should not> wrap this method with method modifiers
1138 or bad things will happen - wrap the C<setup_finalize> method instead.
1139
1140 =cut
1141
1142 sub setup {
1143     my ( $class, @arguments ) = @_;
1144     croak('Running setup more than once')
1145         if ( $class->setup_finished );
1146
1147     unless ( $class->isa('Catalyst') ) {
1148
1149         Catalyst::Exception->throw(
1150             message => qq/'$class' does not inherit from Catalyst/ );
1151     }
1152
1153     if ( $class->arguments ) {
1154         @arguments = ( @arguments, @{ $class->arguments } );
1155     }
1156
1157     # Process options
1158     my $flags = {};
1159
1160     foreach (@arguments) {
1161
1162         if (/^-Debug$/) {
1163             $flags->{log} =
1164               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1165         }
1166         elsif (/^-(\w+)=?(.*)$/) {
1167             $flags->{ lc $1 } = $2;
1168         }
1169         else {
1170             push @{ $flags->{plugins} }, $_;
1171         }
1172     }
1173
1174     $class->setup_home( delete $flags->{home} );
1175
1176     $class->setup_log( delete $flags->{log} );
1177     $class->setup_plugins( delete $flags->{plugins} );
1178
1179     $class->setup_data_handlers();
1180     $class->setup_dispatcher( delete $flags->{dispatcher} );
1181     if (my $engine = delete $flags->{engine}) {
1182         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1183     }
1184     $class->setup_engine();
1185     $class->setup_stats( delete $flags->{stats} );
1186
1187     for my $flag ( sort keys %{$flags} ) {
1188
1189         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1190             &$code( $class, delete $flags->{$flag} );
1191         }
1192         else {
1193             $class->log->warn(qq/Unknown flag "$flag"/);
1194         }
1195     }
1196
1197     eval { require Catalyst::Devel; };
1198     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1199         $class->log->warn(<<"EOF");
1200 You are running an old script!
1201
1202   Please update by running (this will overwrite existing files):
1203     catalyst.pl -force -scripts $class
1204
1205   or (this will not overwrite existing files):
1206     catalyst.pl -scripts $class
1207
1208 EOF
1209     }
1210
1211     # Call plugins setup, this is stupid and evil.
1212     # Also screws C3 badly on 5.10, hack to avoid.
1213     {
1214         no warnings qw/redefine/;
1215         local *setup = sub { };
1216         $class->setup unless $Catalyst::__AM_RESTARTING;
1217     }
1218
1219     # If you are expecting configuration info as part of your setup, it needs
1220     # to get called here and below, since we need the above line to support
1221     # ConfigLoader based configs.
1222
1223     $class->setup_encoding();
1224     $class->setup_middleware();
1225
1226     # Initialize our data structure
1227     $class->components( {} );
1228
1229     $class->setup_components;
1230
1231     if ( $class->debug ) {
1232         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1233
1234         if (@plugins) {
1235             my $column_width = Catalyst::Utils::term_width() - 6;
1236             my $t = Text::SimpleTable->new($column_width);
1237             $t->row($_) for @plugins;
1238             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1239         }
1240
1241         my @middleware = map {
1242           ref $_ eq 'CODE' ?
1243             "Inline Coderef" :
1244               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1245                 || '')  } $class->registered_middlewares;
1246
1247         if (@middleware) {
1248             my $column_width = Catalyst::Utils::term_width() - 6;
1249             my $t = Text::SimpleTable->new($column_width);
1250             $t->row($_) for @middleware;
1251             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1252         }
1253
1254         my %dh = $class->registered_data_handlers;
1255         if (my @data_handlers = keys %dh) {
1256             my $column_width = Catalyst::Utils::term_width() - 6;
1257             my $t = Text::SimpleTable->new($column_width);
1258             $t->row($_) for @data_handlers;
1259             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1260         }
1261
1262         my $dispatcher = $class->dispatcher;
1263         my $engine     = $class->engine;
1264         my $home       = $class->config->{home};
1265
1266         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1267         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1268
1269         $home
1270           ? ( -d $home )
1271           ? $class->log->debug(qq/Found home "$home"/)
1272           : $class->log->debug(qq/Home "$home" doesn't exist/)
1273           : $class->log->debug(q/Couldn't find home/);
1274
1275         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1276         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1277         for my $comp ( sort keys %{ $class->components } ) {
1278             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1279             $t->row( $comp, $type );
1280         }
1281         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1282           if ( keys %{ $class->components } );
1283     }
1284
1285     # Add our self to components, since we are also a component
1286     if( $class->isa('Catalyst::Controller') ){
1287       $class->components->{$class} = $class;
1288     }
1289
1290     $class->setup_actions;
1291
1292     if ( $class->debug ) {
1293         my $name = $class->config->{name} || 'Application';
1294         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1295     }
1296
1297     if ($class->config->{case_sensitive}) {
1298         $class->log->warn($class . "->config->{case_sensitive} is set.");
1299         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1300     }
1301
1302     $class->setup_finalize;
1303
1304     # Flush the log for good measure (in case something turned off 'autoflush' early)
1305     $class->log->_flush() if $class->log->can('_flush');
1306
1307     return $class || 1; # Just in case someone named their Application 0...
1308 }
1309
1310 =head2 $app->setup_finalize
1311
1312 A hook to attach modifiers to. This method does not do anything except set the
1313 C<setup_finished> accessor.
1314
1315 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1316
1317 Example:
1318
1319     after setup_finalize => sub {
1320         my $app = shift;
1321
1322         ## do stuff here..
1323     };
1324
1325 =cut
1326
1327 sub setup_finalize {
1328     my ($class) = @_;
1329     $class->setup_finished(1);
1330 }
1331
1332 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1333
1334 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1335
1336 Constructs an absolute L<URI> object based on the application root, the
1337 provided path, and the additional arguments and query parameters provided.
1338 When used as a string, provides a textual URI.  If you need more flexibility
1339 than this (i.e. the option to provide relative URIs etc.) see
1340 L<Catalyst::Plugin::SmartURI>.
1341
1342 If no arguments are provided, the URI for the current action is returned.
1343 To return the current action and also provide @args, use
1344 C<< $c->uri_for( $c->action, @args ) >>.
1345
1346 If the first argument is a string, it is taken as a public URI path relative
1347 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1348 relative to the application root (if it does). It is then merged with
1349 C<< $c->request->base >>; any C<@args> are appended as additional path
1350 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1351
1352 If the first argument is a L<Catalyst::Action> it represents an action which
1353 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1354 optional C<\@captures> argument (an arrayref) allows passing the captured
1355 variables that are needed to fill in the paths of Chained and Regex actions;
1356 once the path is resolved, C<uri_for> continues as though a path was
1357 provided, appending any arguments or parameters and creating an absolute
1358 URI.
1359
1360 The captures for the current request can be found in
1361 C<< $c->request->captures >>, and actions can be resolved using
1362 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1363 path, use C<< $c->uri_for_action >> instead.
1364
1365   # Equivalent to $c->req->uri
1366   $c->uri_for($c->action, $c->req->captures,
1367       @{ $c->req->args }, $c->req->params);
1368
1369   # For the Foo action in the Bar controller
1370   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1371
1372   # Path to a static resource
1373   $c->uri_for('/static/images/logo.png');
1374
1375 =cut
1376
1377 sub uri_for {
1378     my ( $c, $path, @args ) = @_;
1379
1380     if ( $path->$_isa('Catalyst::Controller') ) {
1381         $path = $path->path_prefix;
1382         $path =~ s{/+\z}{};
1383         $path .= '/';
1384     }
1385
1386     undef($path) if (defined $path && $path eq '');
1387
1388     my $params =
1389       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1390
1391     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1392
1393     my @encoded_args = ();
1394     foreach my $arg (@args) {
1395       if(ref($arg)||'' eq 'ARRAY') {
1396         push @encoded_args, [map {
1397           my $encoded = encode_utf8 $_;
1398           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1399          $encoded;
1400         } @$arg];
1401       } else {
1402         push @encoded_args, do {
1403           my $encoded = encode_utf8 $arg;
1404           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1405           $encoded;
1406         }
1407       }
1408     }
1409
1410     if ( $path->$_isa('Catalyst::Action') ) { # action object
1411         s|/|%2F|g for @encoded_args;
1412         my $captures = [ map { s|/|%2F|g; $_; }
1413                         ( scalar @encoded_args && ref $encoded_args[0] eq 'ARRAY'
1414                          ? @{ shift(@encoded_args) }
1415                          : ()) ];
1416
1417         my $action = $path;
1418         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1419         if( !@encoded_args && $action->number_of_args ) {
1420             my $expanded_action = $c->dispatcher->expand_action( $action );
1421
1422             my $num_captures = $expanded_action->number_of_captures;
1423             unshift @encoded_args, splice @$captures, $num_captures;
1424         }
1425
1426        $path = $c->dispatcher->uri_for_action($action, $captures);
1427         if (not defined $path) {
1428             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1429                 if $c->debug;
1430             return undef;
1431         }
1432         $path = '/' if $path eq '';
1433     }
1434
1435     unshift(@encoded_args, $path);
1436
1437     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1438         my $namespace = $c->namespace;
1439         if (defined $path) { # cheesy hack to handle path '../foo'
1440            $namespace =~ s{(?:^|/)[^/]+$}{} while $encoded_args[0] =~ s{^\.\./}{};
1441         }
1442         unshift(@encoded_args, $namespace || '');
1443     }
1444
1445     # join args with '/', or a blank string
1446     my $args = join('/', grep { defined($_) } @encoded_args);
1447     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1448     $args =~ s!^/+!!;
1449
1450     my ($base, $class) = ('/', 'URI::_generic');
1451     if(blessed($c)) {
1452       $base = $c->req->base;
1453       $class = ref($base);
1454       $base =~ s{(?<!/)$}{/};
1455     }
1456
1457     my $query = '';
1458
1459     if (my @keys = keys %$params) {
1460       # somewhat lifted from URI::_query's query_form
1461       $query = '?'.join('&', map {
1462           my $val = $params->{$_};
1463           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1464           s/ /+/g;
1465           my $key = $_;
1466           $val = '' unless defined $val;
1467           (map {
1468               my $param = "$_";
1469               $param = encode_utf8($param);
1470               # using the URI::Escape pattern here so utf8 chars survive
1471               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1472               $param =~ s/ /+/g;
1473
1474               $key = encode_utf8($key);
1475               # using the URI::Escape pattern here so utf8 chars survive
1476               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1477               $key =~ s/ /+/g;
1478
1479               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1480       } @keys);
1481     }
1482
1483     my $res = bless(\"${base}${args}${query}", $class);
1484     $res;
1485 }
1486
1487 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1488
1489 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1490
1491 =over
1492
1493 =item $path
1494
1495 A private path to the Catalyst action you want to create a URI for.
1496
1497 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1498 >> and passing the resulting C<$action> and the remaining arguments to C<<
1499 $c->uri_for >>.
1500
1501 You can also pass in a Catalyst::Action object, in which case it is passed to
1502 C<< $c->uri_for >>.
1503
1504 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1505
1506 For example, if the action looks like:
1507
1508  package MyApp::Controller::Users;
1509
1510  sub lst : Path('the-list') {}
1511
1512 You can use:
1513
1514  $c->uri_for_action('/users/lst')
1515
1516 and it will create the URI /users/the-list.
1517
1518 =item \@captures_and_args?
1519
1520 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1521 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1522 to interpolate all the parameters in the URI.
1523
1524 =item @args?
1525
1526 Optional list of extra arguments - can be supplied in the
1527 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1528 code.
1529
1530 Your action can have zero, a fixed or a variable number of args (e.g.
1531 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1532
1533 =item \%query_values?
1534
1535 Optional array reference of query parameters to append. E.g.
1536
1537   { foo => 'bar' }
1538
1539 will generate
1540
1541   /rest/of/your/uri?foo=bar
1542
1543 =back
1544
1545 =cut
1546
1547 sub uri_for_action {
1548     my ( $c, $path, @args ) = @_;
1549     my $action = blessed($path)
1550       ? $path
1551       : $c->dispatcher->get_action_by_path($path);
1552     unless (defined $action) {
1553       croak "Can't find action for path '$path'";
1554     }
1555     return $c->uri_for( $action, @args );
1556 }
1557
1558 =head2 $c->welcome_message
1559
1560 Returns the Catalyst welcome HTML page.
1561
1562 =cut
1563
1564 sub welcome_message {
1565     my $c      = shift;
1566     my $name   = $c->config->{name};
1567     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1568     my $prefix = Catalyst::Utils::appprefix( ref $c );
1569     $c->response->content_type('text/html; charset=utf-8');
1570     return <<"EOF";
1571 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1572     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1573 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1574     <head>
1575     <meta http-equiv="Content-Language" content="en" />
1576     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1577         <title>$name on Catalyst $VERSION</title>
1578         <style type="text/css">
1579             body {
1580                 color: #000;
1581                 background-color: #eee;
1582             }
1583             div#content {
1584                 width: 640px;
1585                 margin-left: auto;
1586                 margin-right: auto;
1587                 margin-top: 10px;
1588                 margin-bottom: 10px;
1589                 text-align: left;
1590                 background-color: #ccc;
1591                 border: 1px solid #aaa;
1592             }
1593             p, h1, h2 {
1594                 margin-left: 20px;
1595                 margin-right: 20px;
1596                 font-family: verdana, tahoma, sans-serif;
1597             }
1598             a {
1599                 font-family: verdana, tahoma, sans-serif;
1600             }
1601             :link, :visited {
1602                     text-decoration: none;
1603                     color: #b00;
1604                     border-bottom: 1px dotted #bbb;
1605             }
1606             :link:hover, :visited:hover {
1607                     color: #555;
1608             }
1609             div#topbar {
1610                 margin: 0px;
1611             }
1612             pre {
1613                 margin: 10px;
1614                 padding: 8px;
1615             }
1616             div#answers {
1617                 padding: 8px;
1618                 margin: 10px;
1619                 background-color: #fff;
1620                 border: 1px solid #aaa;
1621             }
1622             h1 {
1623                 font-size: 0.9em;
1624                 font-weight: normal;
1625                 text-align: center;
1626             }
1627             h2 {
1628                 font-size: 1.0em;
1629             }
1630             p {
1631                 font-size: 0.9em;
1632             }
1633             p img {
1634                 float: right;
1635                 margin-left: 10px;
1636             }
1637             span#appname {
1638                 font-weight: bold;
1639                 font-size: 1.6em;
1640             }
1641         </style>
1642     </head>
1643     <body>
1644         <div id="content">
1645             <div id="topbar">
1646                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1647                     $VERSION</h1>
1648              </div>
1649              <div id="answers">
1650                  <p>
1651                  <img src="$logo" alt="Catalyst Logo" />
1652                  </p>
1653                  <p>Welcome to the  world of Catalyst.
1654                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1655                     framework will make web development something you had
1656                     never expected it to be: Fun, rewarding, and quick.</p>
1657                  <h2>What to do now?</h2>
1658                  <p>That really depends  on what <b>you</b> want to do.
1659                     We do, however, provide you with a few starting points.</p>
1660                  <p>If you want to jump right into web development with Catalyst
1661                     you might want to start with a tutorial.</p>
1662 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1663 </pre>
1664 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1665 <pre>
1666 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1667 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1668 </code></pre>
1669                  <h2>What to do next?</h2>
1670                  <p>Next it's time to write an actual application. Use the
1671                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1672                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1673                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1674                     they can save you a lot of work.</p>
1675                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1676                     <p>Also, be sure to check out the vast and growing
1677                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1678                     you are likely to find what you need there.
1679                     </p>
1680
1681                  <h2>Need help?</h2>
1682                  <p>Catalyst has a very active community. Here are the main places to
1683                     get in touch with us.</p>
1684                  <ul>
1685                      <li>
1686                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1687                      </li>
1688                      <li>
1689                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1690                      </li>
1691                      <li>
1692                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1693                      </li>
1694                  </ul>
1695                  <h2>In conclusion</h2>
1696                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1697                     as we enjoyed making it. Please contact us if you have ideas
1698                     for improvement or other feedback.</p>
1699              </div>
1700          </div>
1701     </body>
1702 </html>
1703 EOF
1704 }
1705
1706 =head2 run_options
1707
1708 Contains a hash of options passed from the application script, including
1709 the original ARGV the script received, the processed values from that
1710 ARGV and any extra arguments to the script which were not processed.
1711
1712 This can be used to add custom options to your application's scripts
1713 and setup your application differently depending on the values of these
1714 options.
1715
1716 =head1 INTERNAL METHODS
1717
1718 These methods are not meant to be used by end users.
1719
1720 =head2 $c->components
1721
1722 Returns a hash of components.
1723
1724 =head2 $c->context_class
1725
1726 Returns or sets the context class.
1727
1728 =head2 $c->counter
1729
1730 Returns a hashref containing coderefs and execution counts (needed for
1731 deep recursion detection).
1732
1733 =head2 $c->depth
1734
1735 Returns the number of actions on the current internal execution stack.
1736
1737 =head2 $c->dispatch
1738
1739 Dispatches a request to actions.
1740
1741 =cut
1742
1743 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1744
1745 =head2 $c->dispatcher_class
1746
1747 Returns or sets the dispatcher class.
1748
1749 =head2 $c->dump_these
1750
1751 Returns a list of 2-element array references (name, structure) pairs
1752 that will be dumped on the error page in debug mode.
1753
1754 =cut
1755
1756 sub dump_these {
1757     my $c = shift;
1758     [ Request => $c->req ],
1759     [ Response => $c->res ],
1760     [ Stash => $c->stash ],
1761     [ Config => $c->config ];
1762 }
1763
1764 =head2 $c->engine_class
1765
1766 Returns or sets the engine class.
1767
1768 =head2 $c->execute( $class, $coderef )
1769
1770 Execute a coderef in given class and catch exceptions. Errors are available
1771 via $c->error.
1772
1773 =cut
1774
1775 sub execute {
1776     my ( $c, $class, $code ) = @_;
1777     $class = $c->component($class) || $class;
1778     $c->state(0);
1779
1780     if ( $c->depth >= $RECURSION ) {
1781         my $action = $code->reverse();
1782         $action = "/$action" unless $action =~ /->/;
1783         my $error = qq/Deep recursion detected calling "${action}"/;
1784         $c->log->error($error);
1785         $c->error($error);
1786         $c->state(0);
1787         return $c->state;
1788     }
1789
1790     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1791
1792     push( @{ $c->stack }, $code );
1793
1794     no warnings 'recursion';
1795     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1796     #      I have no idea how, ergo $ret (which appears to fix the issue)
1797     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1798
1799     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1800
1801     my $last = pop( @{ $c->stack } );
1802
1803     if ( my $error = $@ ) {
1804         #rethow if this can be handled by middleware
1805         if(blessed $error && ($error->can('as_psgi') || $error->can('code'))) {
1806             foreach my $err (@{$c->error}) {
1807                 $c->log->error($err);
1808             }
1809             $c->clear_errors;
1810             $c->log->_flush if $c->log->can('_flush');
1811
1812             $error->can('rethrow') ? $error->rethrow : croak $error;
1813         }
1814         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1815             $error->rethrow if $c->depth > 1;
1816         }
1817         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1818             $error->rethrow if $c->depth > 0;
1819         }
1820         else {
1821             unless ( ref $error ) {
1822                 no warnings 'uninitialized';
1823                 chomp $error;
1824                 my $class = $last->class;
1825                 my $name  = $last->name;
1826                 $error = qq/Caught exception in $class->$name "$error"/;
1827             }
1828             $c->error($error);
1829         }
1830         $c->state(0);
1831     }
1832     return $c->state;
1833 }
1834
1835 sub _stats_start_execute {
1836     my ( $c, $code ) = @_;
1837     my $appclass = ref($c) || $c;
1838     return if ( ( $code->name =~ /^_.*/ )
1839         && ( !$appclass->config->{show_internal_actions} ) );
1840
1841     my $action_name = $code->reverse();
1842     $c->counter->{$action_name}++;
1843
1844     my $action = $action_name;
1845     $action = "/$action" unless $action =~ /->/;
1846
1847     # determine if the call was the result of a forward
1848     # this is done by walking up the call stack and looking for a calling
1849     # sub of Catalyst::forward before the eval
1850     my $callsub = q{};
1851     for my $index ( 2 .. 11 ) {
1852         last
1853         if ( ( caller($index) )[0] eq 'Catalyst'
1854             && ( caller($index) )[3] eq '(eval)' );
1855
1856         if ( ( caller($index) )[3] =~ /forward$/ ) {
1857             $callsub = ( caller($index) )[3];
1858             $action  = "-> $action";
1859             last;
1860         }
1861     }
1862
1863     my $uid = $action_name . $c->counter->{$action_name};
1864
1865     # is this a root-level call or a forwarded call?
1866     if ( $callsub =~ /forward$/ ) {
1867         my $parent = $c->stack->[-1];
1868
1869         # forward, locate the caller
1870         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1871             $c->stats->profile(
1872                 begin  => $action,
1873                 parent => "$parent" . $c->counter->{"$parent"},
1874                 uid    => $uid,
1875             );
1876         }
1877         else {
1878
1879             # forward with no caller may come from a plugin
1880             $c->stats->profile(
1881                 begin => $action,
1882                 uid   => $uid,
1883             );
1884         }
1885     }
1886     else {
1887
1888         # root-level call
1889         $c->stats->profile(
1890             begin => $action,
1891             uid   => $uid,
1892         );
1893     }
1894     return $action;
1895
1896 }
1897
1898 sub _stats_finish_execute {
1899     my ( $c, $info ) = @_;
1900     $c->stats->profile( end => $info );
1901 }
1902
1903 =head2 $c->finalize
1904
1905 Finalizes the request.
1906
1907 =cut
1908
1909 sub finalize {
1910     my $c = shift;
1911
1912     for my $error ( @{ $c->error } ) {
1913         $c->log->error($error);
1914     }
1915
1916     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1917     # stuff like cometd and websockets
1918
1919     if($c->request->_has_io_fh) {
1920       $c->log_response;
1921       return;
1922     }
1923
1924     # Allow engine to handle finalize flow (for POE)
1925     my $engine = $c->engine;
1926     if ( my $code = $engine->can('finalize') ) {
1927         $engine->$code($c);
1928     }
1929     else {
1930
1931         $c->finalize_uploads;
1932
1933         # Error
1934         if ( $#{ $c->error } >= 0 ) {
1935             $c->finalize_error;
1936         }
1937
1938         $c->finalize_encoding;
1939         $c->finalize_headers unless $c->response->finalized_headers;
1940         $c->finalize_body;
1941     }
1942
1943     $c->log_response;
1944
1945     if ($c->use_stats) {
1946         my $elapsed = $c->stats->elapsed;
1947         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1948         $c->log->info(
1949             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1950     }
1951
1952     return $c->response->status;
1953 }
1954
1955 =head2 $c->finalize_body
1956
1957 Finalizes body.
1958
1959 =cut
1960
1961 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1962
1963 =head2 $c->finalize_cookies
1964
1965 Finalizes cookies.
1966
1967 =cut
1968
1969 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1970
1971 =head2 $c->finalize_error
1972
1973 Finalizes error.  If there is only one error in L</error> and it is an object that
1974 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
1975 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
1976 return the default error page (production mode).
1977
1978 =cut
1979
1980 sub finalize_error {
1981     my $c = shift;
1982     if($#{$c->error} > 0) {
1983         $c->engine->finalize_error( $c, @_ );
1984     } else {
1985         my ($error) = @{$c->error};
1986         if(
1987           blessed $error &&
1988           ($error->can('as_psgi') || $error->can('code'))
1989         ) {
1990             # In the case where the error 'knows what it wants', becauses its PSGI
1991             # aware, just rethow and let middleware catch it
1992             $error->can('rethrow') ? $error->rethrow : croak $error;
1993         } else {
1994             $c->engine->finalize_error( $c, @_ )
1995         }
1996     }
1997 }
1998
1999 =head2 $c->finalize_headers
2000
2001 Finalizes headers.
2002
2003 =cut
2004
2005 sub finalize_headers {
2006     my $c = shift;
2007
2008     my $response = $c->response; #accessor calls can add up?
2009
2010     # Check if we already finalized headers
2011     return if $response->finalized_headers;
2012
2013     # Handle redirects
2014     if ( my $location = $response->redirect ) {
2015         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2016         $response->header( Location => $location );
2017     }
2018
2019     # Remove incorrectly added body and content related meta data when returning
2020     # an information response, or a response the is required to not include a body
2021
2022     $c->finalize_cookies;
2023
2024     $c->response->finalize_headers();
2025
2026     # Done
2027     $response->finalized_headers(1);
2028 }
2029
2030 =head2 $c->finalize_encoding
2031
2032 Make sure your headers and body are encoded properly IF you set an encoding.
2033 See L</ENCODING>.
2034
2035 =cut
2036
2037 sub finalize_encoding {
2038     my $c = shift;
2039
2040     my $body = $c->response->body;
2041
2042     return unless defined($body);
2043
2044     my $enc = $c->encoding;
2045
2046     return unless $enc;
2047
2048     my ($ct, $ct_enc) = $c->response->content_type;
2049
2050     # Only touch 'text-like' contents
2051     return unless $c->response->content_type =~ /^text|xml$|javascript$/;
2052
2053     if ($ct_enc && $ct_enc =~ /charset=([^;]*)/) {
2054         if (uc($1) ne uc($enc->mime_name)) {
2055             $c->log->debug("Unicode::Encoding is set to encode in '" .
2056                            $enc->mime_name .
2057                            "', content type is '$1', not encoding ");
2058             return;
2059         }
2060     } else {
2061         $c->res->content_type($c->res->content_type . "; charset=" . $enc->mime_name);
2062     }
2063
2064     # Oh my, I wonder what filehandle responses and streams do... - jnap.
2065     # Encode expects plain scalars (IV, NV or PV) and segfaults on ref's
2066     if (ref(\$body) eq 'SCALAR') {
2067       $c->response->body( $c->encoding->encode( $body, $c->_encode_check ) );
2068     };
2069 }
2070
2071 =head2 $c->finalize_output
2072
2073 An alias for finalize_body.
2074
2075 =head2 $c->finalize_read
2076
2077 Finalizes the input after reading is complete.
2078
2079 =cut
2080
2081 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2082
2083 =head2 $c->finalize_uploads
2084
2085 Finalizes uploads. Cleans up any temporary files.
2086
2087 =cut
2088
2089 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2090
2091 =head2 $c->get_action( $action, $namespace )
2092
2093 Gets an action in a given namespace.
2094
2095 =cut
2096
2097 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2098
2099 =head2 $c->get_actions( $action, $namespace )
2100
2101 Gets all actions of a given name in a namespace and all parent
2102 namespaces.
2103
2104 =cut
2105
2106 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2107
2108 =head2 $app->handle_request( @arguments )
2109
2110 Called to handle each HTTP request.
2111
2112 =cut
2113
2114 sub handle_request {
2115     my ( $class, @arguments ) = @_;
2116
2117     # Always expect worst case!
2118     my $status = -1;
2119     try {
2120         if ($class->debug) {
2121             my $secs = time - $START || 1;
2122             my $av = sprintf '%.3f', $COUNT / $secs;
2123             my $time = localtime time;
2124             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2125         }
2126
2127         my $c = $class->prepare(@arguments);
2128         $c->dispatch;
2129         $status = $c->finalize;
2130     } catch {
2131         #rethow if this can be handled by middleware
2132         if(blessed $_ && ($_->can('as_psgi') || $_->can('code'))) {
2133             $_->can('rethrow') ? $_->rethrow : croak $_;
2134         }
2135         chomp(my $error = $_);
2136         $class->log->error(qq/Caught exception in engine "$error"/);
2137     };
2138
2139     $COUNT++;
2140
2141     if(my $coderef = $class->log->can('_flush')){
2142         $class->log->$coderef();
2143     }
2144     return $status;
2145 }
2146
2147 =head2 $class->prepare( @arguments )
2148
2149 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2150 etc.).
2151
2152 =cut
2153
2154 has _uploadtmp => (
2155     is => 'ro',
2156     predicate => '_has_uploadtmp',
2157 );
2158
2159 sub prepare {
2160     my ( $class, @arguments ) = @_;
2161
2162     # XXX
2163     # After the app/ctxt split, this should become an attribute based on something passed
2164     # into the application.
2165     $class->context_class( ref $class || $class ) unless $class->context_class;
2166
2167     my $uploadtmp = $class->config->{uploadtmp};
2168     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2169
2170     $c->response->_context($c);
2171
2172     #surely this is not the most efficient way to do things...
2173     $c->stats($class->stats_class->new)->enable($c->use_stats);
2174     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2175         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2176     }
2177
2178     try {
2179         # Allow engine to direct the prepare flow (for POE)
2180         if ( my $prepare = $c->engine->can('prepare') ) {
2181             $c->engine->$prepare( $c, @arguments );
2182         }
2183         else {
2184             $c->prepare_request(@arguments);
2185             $c->prepare_connection;
2186             $c->prepare_query_parameters;
2187             $c->prepare_headers; # Just hooks, no longer needed - they just
2188             $c->prepare_cookies; # cause the lazy attribute on req to build
2189             $c->prepare_path;
2190
2191             # Prepare the body for reading, either by prepare_body
2192             # or the user, if they are using $c->read
2193             $c->prepare_read;
2194
2195             # Parse the body unless the user wants it on-demand
2196             unless ( ref($c)->config->{parse_on_demand} ) {
2197                 $c->prepare_body;
2198             }
2199         }
2200         $c->prepare_action;
2201     }
2202     # VERY ugly and probably shouldn't rely on ->finalize actually working
2203     catch {
2204         # failed prepare is always due to an invalid request, right?
2205         $c->response->status(400);
2206         $c->response->content_type('text/plain');
2207         $c->response->body('Bad Request');
2208         # Note we call finalize and then die here, which escapes
2209         # finalize being called in the enclosing block..
2210         # It in fact couldn't be called, as we don't return $c..
2211         # This is a mess - but I'm unsure you can fix this without
2212         # breaking compat for people doing crazy things (we should set
2213         # the 400 and just return the ctx here IMO, letting finalize get called
2214         # above...
2215         $c->finalize;
2216         die $_;
2217     };
2218
2219     $c->log_request;
2220
2221     return $c;
2222 }
2223
2224 =head2 $c->prepare_action
2225
2226 Prepares action. See L<Catalyst::Dispatcher>.
2227
2228 =cut
2229
2230 sub prepare_action {
2231     my $c = shift;
2232     my $ret = $c->dispatcher->prepare_action( $c, @_);
2233
2234     if($c->encoding) {
2235         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2236           $_ = $c->_handle_param_unicode_decoding($_);
2237         }
2238     }
2239
2240     return $ret;
2241 }
2242
2243
2244 =head2 $c->prepare_body
2245
2246 Prepares message body.
2247
2248 =cut
2249
2250 sub prepare_body {
2251     my $c = shift;
2252
2253     return if $c->request->_has_body;
2254
2255     # Initialize on-demand data
2256     $c->engine->prepare_body( $c, @_ );
2257     $c->prepare_parameters;
2258     $c->prepare_uploads;
2259 }
2260
2261 =head2 $c->prepare_body_chunk( $chunk )
2262
2263 Prepares a chunk of data before sending it to L<HTTP::Body>.
2264
2265 See L<Catalyst::Engine>.
2266
2267 =cut
2268
2269 sub prepare_body_chunk {
2270     my $c = shift;
2271     $c->engine->prepare_body_chunk( $c, @_ );
2272 }
2273
2274 =head2 $c->prepare_body_parameters
2275
2276 Prepares body parameters.
2277
2278 =cut
2279
2280 sub prepare_body_parameters {
2281     my $c = shift;
2282     $c->request->prepare_body_parameters( $c, @_ );
2283 }
2284
2285 =head2 $c->prepare_connection
2286
2287 Prepares connection.
2288
2289 =cut
2290
2291 sub prepare_connection {
2292     my $c = shift;
2293     $c->request->prepare_connection($c);
2294 }
2295
2296 =head2 $c->prepare_cookies
2297
2298 Prepares cookies by ensuring that the attribute on the request
2299 object has been built.
2300
2301 =cut
2302
2303 sub prepare_cookies { my $c = shift; $c->request->cookies }
2304
2305 =head2 $c->prepare_headers
2306
2307 Prepares request headers by ensuring that the attribute on the request
2308 object has been built.
2309
2310 =cut
2311
2312 sub prepare_headers { my $c = shift; $c->request->headers }
2313
2314 =head2 $c->prepare_parameters
2315
2316 Prepares parameters.
2317
2318 =cut
2319
2320 sub prepare_parameters {
2321     my $c = shift;
2322     $c->prepare_body_parameters;
2323     $c->engine->prepare_parameters( $c, @_ );
2324 }
2325
2326 =head2 $c->prepare_path
2327
2328 Prepares path and base.
2329
2330 =cut
2331
2332 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2333
2334 =head2 $c->prepare_query_parameters
2335
2336 Prepares query parameters.
2337
2338 =cut
2339
2340 sub prepare_query_parameters {
2341     my $c = shift;
2342
2343     $c->engine->prepare_query_parameters( $c, @_ );
2344 }
2345
2346 =head2 $c->log_request
2347
2348 Writes information about the request to the debug logs.  This includes:
2349
2350 =over 4
2351
2352 =item * Request method, path, and remote IP address
2353
2354 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2355
2356 =item * Request parameters
2357
2358 =item * File uploads
2359
2360 =back
2361
2362 =cut
2363
2364 sub log_request {
2365     my $c = shift;
2366
2367     return unless $c->debug;
2368
2369     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2370     my $request = $dump->[1];
2371
2372     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2373     $method ||= '';
2374     $path = '/' unless length $path;
2375     $address ||= '';
2376
2377     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2378     $path = decode_utf8($path);
2379
2380     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2381
2382     $c->log_request_headers($request->headers);
2383
2384     if ( my $keywords = $request->query_keywords ) {
2385         $c->log->debug("Query keywords are: $keywords");
2386     }
2387
2388     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2389
2390     $c->log_request_uploads($request);
2391 }
2392
2393 =head2 $c->log_response
2394
2395 Writes information about the response to the debug logs by calling
2396 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2397
2398 =cut
2399
2400 sub log_response {
2401     my $c = shift;
2402
2403     return unless $c->debug;
2404
2405     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2406     my $response = $dump->[1];
2407
2408     $c->log_response_status_line($response);
2409     $c->log_response_headers($response->headers);
2410 }
2411
2412 =head2 $c->log_response_status_line($response)
2413
2414 Writes one line of information about the response to the debug logs.  This includes:
2415
2416 =over 4
2417
2418 =item * Response status code
2419
2420 =item * Content-Type header (if present)
2421
2422 =item * Content-Length header (if present)
2423
2424 =back
2425
2426 =cut
2427
2428 sub log_response_status_line {
2429     my ($c, $response) = @_;
2430
2431     $c->log->debug(
2432         sprintf(
2433             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2434             $response->status                            || 'unknown',
2435             $response->headers->header('Content-Type')   || 'unknown',
2436             $response->headers->header('Content-Length') || 'unknown'
2437         )
2438     );
2439 }
2440
2441 =head2 $c->log_response_headers($headers);
2442
2443 Hook method which can be wrapped by plugins to log the response headers.
2444 No-op in the default implementation.
2445
2446 =cut
2447
2448 sub log_response_headers {}
2449
2450 =head2 $c->log_request_parameters( query => {}, body => {} )
2451
2452 Logs request parameters to debug logs
2453
2454 =cut
2455
2456 sub log_request_parameters {
2457     my $c          = shift;
2458     my %all_params = @_;
2459
2460     return unless $c->debug;
2461
2462     my $column_width = Catalyst::Utils::term_width() - 44;
2463     foreach my $type (qw(query body)) {
2464         my $params = $all_params{$type};
2465         next if ! keys %$params;
2466         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2467         for my $key ( sort keys %$params ) {
2468             my $param = $params->{$key};
2469             my $value = defined($param) ? $param : '';
2470             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2471         }
2472         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2473     }
2474 }
2475
2476 =head2 $c->log_request_uploads
2477
2478 Logs file uploads included in the request to the debug logs.
2479 The parameter name, filename, file type, and file size are all included in
2480 the debug logs.
2481
2482 =cut
2483
2484 sub log_request_uploads {
2485     my $c = shift;
2486     my $request = shift;
2487     return unless $c->debug;
2488     my $uploads = $request->uploads;
2489     if ( keys %$uploads ) {
2490         my $t = Text::SimpleTable->new(
2491             [ 12, 'Parameter' ],
2492             [ 26, 'Filename' ],
2493             [ 18, 'Type' ],
2494             [ 9,  'Size' ]
2495         );
2496         for my $key ( sort keys %$uploads ) {
2497             my $upload = $uploads->{$key};
2498             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2499                 $t->row( $key, $u->filename, $u->type, $u->size );
2500             }
2501         }
2502         $c->log->debug( "File Uploads are:\n" . $t->draw );
2503     }
2504 }
2505
2506 =head2 $c->log_request_headers($headers);
2507
2508 Hook method which can be wrapped by plugins to log the request headers.
2509 No-op in the default implementation.
2510
2511 =cut
2512
2513 sub log_request_headers {}
2514
2515 =head2 $c->log_headers($type => $headers)
2516
2517 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2518
2519 =cut
2520
2521 sub log_headers {
2522     my $c       = shift;
2523     my $type    = shift;
2524     my $headers = shift;    # an HTTP::Headers instance
2525
2526     return unless $c->debug;
2527
2528     my $column_width = Catalyst::Utils::term_width() - 28;
2529     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2530     $headers->scan(
2531         sub {
2532             my ( $name, $value ) = @_;
2533             $t->row( $name, $value );
2534         }
2535     );
2536     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2537 }
2538
2539
2540 =head2 $c->prepare_read
2541
2542 Prepares the input for reading.
2543
2544 =cut
2545
2546 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2547
2548 =head2 $c->prepare_request
2549
2550 Prepares the engine request.
2551
2552 =cut
2553
2554 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2555
2556 =head2 $c->prepare_uploads
2557
2558 Prepares uploads.
2559
2560 =cut
2561
2562 sub prepare_uploads {
2563     my $c = shift;
2564     $c->engine->prepare_uploads( $c, @_ );
2565 }
2566
2567 =head2 $c->prepare_write
2568
2569 Prepares the output for writing.
2570
2571 =cut
2572
2573 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2574
2575 =head2 $c->request_class
2576
2577 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2578
2579 =head2 $c->response_class
2580
2581 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2582
2583 =head2 $c->read( [$maxlength] )
2584
2585 Reads a chunk of data from the request body. This method is designed to
2586 be used in a while loop, reading C<$maxlength> bytes on every call.
2587 C<$maxlength> defaults to the size of the request if not specified.
2588
2589 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2590 directly.
2591
2592 Warning: If you use read(), Catalyst will not process the body,
2593 so you will not be able to access POST parameters or file uploads via
2594 $c->request.  You must handle all body parsing yourself.
2595
2596 =cut
2597
2598 sub read { my $c = shift; return $c->request->read( @_ ) }
2599
2600 =head2 $c->run
2601
2602 Starts the engine.
2603
2604 =cut
2605
2606 sub run {
2607   my $app = shift;
2608   $app->_make_immutable_if_needed;
2609   $app->engine_loader->needs_psgi_engine_compat_hack ?
2610     $app->engine->run($app, @_) :
2611       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2612 }
2613
2614 sub _make_immutable_if_needed {
2615     my $class = shift;
2616     my $meta = find_meta($class);
2617     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2618     if (
2619         $meta->is_immutable
2620         && ! { $meta->immutable_options }->{replace_constructor}
2621         && $isa_ca
2622     ) {
2623         warn("You made your application class ($class) immutable, "
2624             . "but did not inline the\nconstructor. "
2625             . "This will break catalyst, as your app \@ISA "
2626             . "Class::Accessor(::Fast)?\nPlease pass "
2627             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2628     }
2629     unless ($meta->is_immutable) {
2630         # XXX - FIXME warning here as you should make your app immutable yourself.
2631         $meta->make_immutable(
2632             replace_constructor => 1,
2633         );
2634     }
2635 }
2636
2637 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2638
2639 Sets an action in a given namespace.
2640
2641 =cut
2642
2643 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2644
2645 =head2 $c->setup_actions($component)
2646
2647 Sets up actions for a component.
2648
2649 =cut
2650
2651 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2652
2653 =head2 $c->setup_components
2654
2655 This method is called internally to set up the application's components.
2656
2657 It finds modules by calling the L<locate_components> method, expands them to
2658 package names with the L<expand_component_module> method, and then installs
2659 each component into the application.
2660
2661 The C<setup_components> config option is passed to both of the above methods.
2662
2663 Installation of each component is performed by the L<setup_component> method,
2664 below.
2665
2666 =cut
2667
2668 sub setup_components {
2669     my $class = shift;
2670
2671     my $config  = $class->config->{ setup_components };
2672
2673     my @comps = $class->locate_components($config);
2674     my %comps = map { $_ => 1 } @comps;
2675
2676     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2677     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2678         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2679     ) if $deprecatedcatalyst_component_names;
2680
2681     for my $component ( @comps ) {
2682
2683         # We pass ignore_loaded here so that overlay files for (e.g.)
2684         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2685         # we know M::P::O found a file on disk so this is safe
2686
2687         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2688     }
2689
2690     for my $component (@comps) {
2691         my $instance = $class->components->{ $component } = $class->setup_component($component);
2692         my @expanded_components = $instance->can('expand_modules')
2693             ? $instance->expand_modules( $component, $config )
2694             : $class->expand_component_module( $component, $config );
2695         for my $component (@expanded_components) {
2696             next if $comps{$component};
2697             $class->components->{ $component } = $class->setup_component($component);
2698         }
2699     }
2700 }
2701
2702 =head2 $c->locate_components( $setup_component_config )
2703
2704 This method is meant to provide a list of component modules that should be
2705 setup for the application.  By default, it will use L<Module::Pluggable>.
2706
2707 Specify a C<setup_components> config option to pass additional options directly
2708 to L<Module::Pluggable>. To add additional search paths, specify a key named
2709 C<search_extra> as an array reference. Items in the array beginning with C<::>
2710 will have the application class name prepended to them.
2711
2712 =cut
2713
2714 sub locate_components {
2715     my $class  = shift;
2716     my $config = shift;
2717
2718     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2719     my $extra   = delete $config->{ search_extra } || [];
2720
2721     unshift @paths, @$extra;
2722
2723     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2724       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2725       %$config
2726     )->plugins } @paths;
2727
2728     return @comps;
2729 }
2730
2731 =head2 $c->expand_component_module( $component, $setup_component_config )
2732
2733 Components found by C<locate_components> will be passed to this method, which
2734 is expected to return a list of component (package) names to be set up.
2735
2736 =cut
2737
2738 sub expand_component_module {
2739     my ($class, $module) = @_;
2740     return Devel::InnerPackage::list_packages( $module );
2741 }
2742
2743 =head2 $c->setup_component
2744
2745 =cut
2746
2747 sub setup_component {
2748     my( $class, $component ) = @_;
2749
2750     unless ( $component->can( 'COMPONENT' ) ) {
2751         return $component;
2752     }
2753
2754     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2755     my $config = $class->config->{ $suffix } || {};
2756     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2757     # methods also pass it. local to avoid pointlessly shitting in config
2758     # for the debug screen, as $component is already the key name.
2759     local $config->{catalyst_component_name} = $component;
2760
2761     my $instance = eval { $component->COMPONENT( $class, $config ); };
2762
2763     if ( my $error = $@ ) {
2764         chomp $error;
2765         Catalyst::Exception->throw(
2766             message => qq/Couldn't instantiate component "$component", "$error"/
2767         );
2768     }
2769
2770     unless (blessed $instance) {
2771         my $metaclass = Moose::Util::find_meta($component);
2772         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2773         my $component_method_from = $method_meta->associated_metaclass->name;
2774         my $value = defined($instance) ? $instance : 'undef';
2775         Catalyst::Exception->throw(
2776             message =>
2777             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2778         );
2779     }
2780     return $instance;
2781 }
2782
2783 =head2 $c->setup_dispatcher
2784
2785 Sets up dispatcher.
2786
2787 =cut
2788
2789 sub setup_dispatcher {
2790     my ( $class, $dispatcher ) = @_;
2791
2792     if ($dispatcher) {
2793         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2794     }
2795
2796     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2797         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2798     }
2799
2800     unless ($dispatcher) {
2801         $dispatcher = $class->dispatcher_class;
2802     }
2803
2804     load_class($dispatcher);
2805
2806     # dispatcher instance
2807     $class->dispatcher( $dispatcher->new );
2808 }
2809
2810 =head2 $c->setup_engine
2811
2812 Sets up engine.
2813
2814 =cut
2815
2816 sub engine_class {
2817     my ($class, $requested_engine) = @_;
2818
2819     if (!$class->engine_loader || $requested_engine) {
2820         $class->engine_loader(
2821             Catalyst::EngineLoader->new({
2822                 application_name => $class,
2823                 (defined $requested_engine
2824                      ? (catalyst_engine_class => $requested_engine) : ()),
2825             }),
2826         );
2827     }
2828
2829     $class->engine_loader->catalyst_engine_class;
2830 }
2831
2832 sub setup_engine {
2833     my ($class, $requested_engine) = @_;
2834
2835     my $engine = do {
2836         my $loader = $class->engine_loader;
2837
2838         if (!$loader || $requested_engine) {
2839             $loader = Catalyst::EngineLoader->new({
2840                 application_name => $class,
2841                 (defined $requested_engine
2842                      ? (requested_engine => $requested_engine) : ()),
2843             }),
2844
2845             $class->engine_loader($loader);
2846         }
2847
2848         $loader->catalyst_engine_class;
2849     };
2850
2851     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2852     return if $class->loading_psgi_file;
2853
2854     load_class($engine);
2855
2856     if ($ENV{MOD_PERL}) {
2857         my $apache = $class->engine_loader->auto;
2858
2859         my $meta = find_meta($class);
2860         my $was_immutable = $meta->is_immutable;
2861         my %immutable_options = $meta->immutable_options;
2862         $meta->make_mutable if $was_immutable;
2863
2864         $meta->add_method(handler => sub {
2865             my $r = shift;
2866             my $psgi_app = $class->_finalized_psgi_app;
2867             $apache->call_app($r, $psgi_app);
2868         });
2869
2870         $meta->make_immutable(%immutable_options) if $was_immutable;
2871     }
2872
2873     $class->engine( $engine->new );
2874
2875     return;
2876 }
2877
2878 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2879 ## build in server support (back compat support for pre psgi port behavior).
2880 ## This is so that we don't build a new psgi app for each request when using
2881 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2882
2883 sub _finalized_psgi_app {
2884     my ($app) = @_;
2885
2886     unless ($app->_psgi_app) {
2887         my $psgi_app = $app->_setup_psgi_app;
2888         $app->_psgi_app($psgi_app);
2889     }
2890
2891     return $app->_psgi_app;
2892 }
2893
2894 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2895 ## home directory and load that and return it (just assume it is doing the
2896 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2897 ## in default_middleware and return it ( this is for backward compatibility
2898 ## with pre psgi port behavior ).
2899
2900 sub _setup_psgi_app {
2901     my ($app) = @_;
2902
2903     for my $home (Path::Class::Dir->new($app->config->{home})) {
2904         my $psgi_file = $home->file(
2905             Catalyst::Utils::appprefix($app) . '.psgi',
2906         );
2907
2908         next unless -e $psgi_file;
2909
2910         # If $psgi_file calls ->setup_engine, it's doing so to load
2911         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2912         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2913         # anyway. So set a flag (ick) that tells setup_engine not to populate
2914         # $c->engine or do any other things we might regret.
2915
2916         $app->loading_psgi_file(1);
2917         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2918         $app->loading_psgi_file(0);
2919
2920         return $psgi_app
2921             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2922
2923         warn <<"EOW";
2924 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2925
2926 Its content has been ignored. Please consult the Catalyst::Upgrading
2927 documentation on how to upgrade from Catalyst::Engine::PSGI.
2928 EOW
2929     }
2930
2931     return $app->apply_default_middlewares($app->psgi_app);
2932 }
2933
2934 =head2 $c->apply_default_middlewares
2935
2936 Adds the following L<Plack> middlewares to your application, since they are
2937 useful and commonly needed:
2938
2939 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2940 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2941 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2942 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2943 applied since this middleware is smart enough to conditionally apply itself).
2944
2945 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2946 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2947 $ENV{SCRIPT_NAME}
2948
2949 =cut
2950
2951
2952 sub apply_default_middlewares {
2953     my ($app, $psgi_app) = @_;
2954
2955     $psgi_app = Plack::Middleware::Conditional->wrap(
2956         $psgi_app,
2957         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2958         condition => sub {
2959             my ($env) = @_;
2960             return if $app->config->{ignore_frontend_proxy};
2961             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2962                 || $app->config->{using_frontend_proxy};
2963         },
2964     );
2965
2966     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2967     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2968     $psgi_app = Plack::Middleware::Conditional->wrap(
2969         $psgi_app,
2970         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2971         condition => sub {
2972             my ($env) = @_;
2973             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2974             return unless $1 < 4.23;
2975             1;
2976         },
2977     );
2978
2979     # we're applying this unconditionally as the middleware itself already makes
2980     # sure it doesn't fuck things up if it's not running under one of the right
2981     # IIS versions
2982     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2983
2984     # And another IIS issue, this time with IIS7.
2985     $psgi_app = Plack::Middleware::Conditional->wrap(
2986         $psgi_app,
2987         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2988         condition => sub {
2989             my ($env) = @_;
2990             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2991         },
2992     );
2993
2994     return $psgi_app;
2995 }
2996
2997 =head2 App->psgi_app
2998
2999 =head2 App->to_app
3000
3001 Returns a PSGI application code reference for the catalyst application
3002 C<$c>. This is the bare application without any middlewares
3003 applied. C<${myapp}.psgi> is not taken into account.
3004
3005 This is what you want to be using to retrieve the PSGI application code
3006 reference of your Catalyst application for use in F<.psgi> files.
3007
3008 =cut
3009
3010 *to_app = \&psgi_app;
3011
3012 sub psgi_app {
3013     my ($app) = @_;
3014     my $psgi = $app->engine->build_psgi_app($app);
3015     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3016 }
3017
3018 =head2 $c->setup_home
3019
3020 Sets up the home directory.
3021
3022 =cut
3023
3024 sub setup_home {
3025     my ( $class, $home ) = @_;
3026
3027     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3028         $home = $env;
3029     }
3030
3031     $home ||= Catalyst::Utils::home($class);
3032
3033     if ($home) {
3034         #I remember recently being scolded for assigning config values like this
3035         $class->config->{home} ||= $home;
3036         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3037     }
3038 }
3039
3040 =head2 $c->setup_encoding
3041
3042 Sets up the input/output encoding.  See L<ENCODING>
3043
3044 =cut
3045
3046 sub setup_encoding {
3047     my $c = shift;
3048     # This is where you'd set a default encoding
3049     my $enc = delete $c->config->{encoding};
3050     $c->encoding( $enc ) if defined $enc;
3051 }
3052
3053 =head2 handle_unicode_encoding_exception
3054
3055 Hook to let you customize how encoding errors are handled.  By default
3056 we just throw an exception.  Receives a hashref of debug information.
3057 Example:
3058
3059     $c->handle_unicode_encoding_exception({
3060         param_value => $value,
3061         error_msg => $_,
3062             encoding_step => 'params',
3063         });
3064
3065 =cut
3066
3067 sub handle_unicode_encoding_exception {
3068     my ( $self, $exception_ctx ) = @_;
3069     die $exception_ctx->{error_msg};
3070 }
3071
3072 # Some unicode helpers cargo culted from the old plugin.  These could likely
3073 # be neater.
3074
3075 sub _handle_unicode_decoding {
3076     my ( $self, $value ) = @_;
3077
3078     return unless defined $value;
3079
3080     ## I think this mess is to support the old nested
3081     if ( ref $value eq 'ARRAY' ) {
3082         foreach ( @$value ) {
3083             $_ = $self->_handle_unicode_decoding($_);
3084         }
3085         return $value;
3086     }
3087     elsif ( ref $value eq 'HASH' ) {
3088         foreach (keys %$value) {
3089             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3090             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3091
3092             # If the key was encoded we now have two (the original and current so
3093             # delete the original.
3094             delete $value->{$_} if $_ ne $encoded_key;
3095         }
3096         return $value;
3097     }
3098     else {
3099         return $self->_handle_param_unicode_decoding($value);
3100     }
3101 }
3102
3103 sub _handle_param_unicode_decoding {
3104     my ( $self, $value ) = @_;
3105     return unless defined $value; # not in love with just ignoring undefs - jnap
3106
3107     my $enc = $self->encoding;
3108     return try {
3109       $enc->decode( $value, $self->_encode_check );
3110     }
3111     catch {
3112         $self->handle_unicode_encoding_exception({
3113             param_value => $value,
3114             error_msg => $_,
3115             encoding_step => 'params',
3116         });
3117     };
3118 }
3119
3120 =head2 $c->setup_log
3121
3122 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3123 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3124 log to.
3125
3126 This method also installs a C<debug> method that returns a true value into the
3127 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3128 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3129
3130 Note that if the log has already been setup, by either a previous call to
3131 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3132 that this method won't actually set up the log object.
3133
3134 =cut
3135
3136 sub setup_log {
3137     my ( $class, $levels ) = @_;
3138
3139     $levels ||= '';
3140     $levels =~ s/^\s+//;
3141     $levels =~ s/\s+$//;
3142     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3143
3144     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3145     if ( defined $env_debug ) {
3146         $levels{debug} = 1 if $env_debug; # Ugly!
3147         delete($levels{debug}) unless $env_debug;
3148     }
3149
3150     unless ( $class->log ) {
3151         $class->log( Catalyst::Log->new(keys %levels) );
3152     }
3153
3154     if ( $levels{debug} ) {
3155         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3156         $class->log->debug('Debug messages enabled');
3157     }
3158 }
3159
3160 =head2 $c->setup_plugins
3161
3162 Sets up plugins.
3163
3164 =cut
3165
3166 =head2 $c->setup_stats
3167
3168 Sets up timing statistics class.
3169
3170 =cut
3171
3172 sub setup_stats {
3173     my ( $class, $stats ) = @_;
3174
3175     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3176
3177     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3178     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3179         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3180         $class->log->debug('Statistics enabled');
3181     }
3182 }
3183
3184
3185 =head2 $c->registered_plugins
3186
3187 Returns a sorted list of the plugins which have either been stated in the
3188 import list.
3189
3190 If passed a given plugin name, it will report a boolean value indicating
3191 whether or not that plugin is loaded.  A fully qualified name is required if
3192 the plugin name does not begin with C<Catalyst::Plugin::>.
3193
3194  if ($c->registered_plugins('Some::Plugin')) {
3195      ...
3196  }
3197
3198 =cut
3199
3200 {
3201
3202     sub registered_plugins {
3203         my $proto = shift;
3204         return sort keys %{ $proto->_plugins } unless @_;
3205         my $plugin = shift;
3206         return 1 if exists $proto->_plugins->{$plugin};
3207         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3208     }
3209
3210     sub _register_plugin {
3211         my ( $proto, $plugin, $instant ) = @_;
3212         my $class = ref $proto || $proto;
3213
3214         load_class( $plugin );
3215         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3216             if $plugin->isa( 'Catalyst::Component' );
3217         my $plugin_meta = Moose::Meta::Class->create($plugin);
3218         if (!$plugin_meta->has_method('new')
3219             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3220             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3221         }
3222         if (!$instant && !$proto->_plugins->{$plugin}) {
3223             my $meta = Class::MOP::get_metaclass_by_name($class);
3224             $meta->superclasses($plugin, $meta->superclasses);
3225         }
3226         $proto->_plugins->{$plugin} = 1;
3227         return $class;
3228     }
3229
3230     sub _default_plugins { return qw() }
3231
3232     sub setup_plugins {
3233         my ( $class, $plugins ) = @_;
3234
3235         $class->_plugins( {} ) unless $class->_plugins;
3236         $plugins = [ grep {
3237             m/Unicode::Encoding/ ? do {
3238                 $class->log->warn(
3239                     'Unicode::Encoding plugin is auto-applied,'
3240                     . ' please remove this from your appclass'
3241                     . ' and make sure to define "encoding" config'
3242                 );
3243                 unless (exists $class->config->{'encoding'}) {
3244                   $class->config->{'encoding'} = 'UTF-8';
3245                 }
3246                 () }
3247                 : $_
3248         } @$plugins ];
3249         push @$plugins, $class->_default_plugins;
3250         $plugins = Data::OptList::mkopt($plugins || []);
3251
3252         my @plugins = map {
3253             [ Catalyst::Utils::resolve_namespace(
3254                   $class . '::Plugin',
3255                   'Catalyst::Plugin', $_->[0]
3256               ),
3257               $_->[1],
3258             ]
3259          } @{ $plugins };
3260
3261         for my $plugin ( reverse @plugins ) {
3262             load_class($plugin->[0], $plugin->[1]);
3263             my $meta = find_meta($plugin->[0]);
3264             next if $meta && $meta->isa('Moose::Meta::Role');
3265
3266             $class->_register_plugin($plugin->[0]);
3267         }
3268
3269         my @roles =
3270             map  { $_->[0]->name, $_->[1] }
3271             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3272             map  { [find_meta($_->[0]), $_->[1]] }
3273             @plugins;
3274
3275         Moose::Util::apply_all_roles(
3276             $class => @roles
3277         ) if @roles;
3278     }
3279 }
3280
3281 =head2 registered_middlewares
3282
3283 Read only accessor that returns an array of all the middleware in the order
3284 that they were added (which is the REVERSE of the order they will be applied).
3285
3286 The values returned will be either instances of L<Plack::Middleware> or of a
3287 compatible interface, or a coderef, which is assumed to be inlined middleware
3288
3289 =head2 setup_middleware (?@middleware)
3290
3291 Read configuration information stored in configuration key C<psgi_middleware> or
3292 from passed @args.
3293
3294 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3295 to use it to enable L<Plack::Middleware>
3296
3297 This method is automatically called during 'setup' of your application, so
3298 you really don't need to invoke it.  However you may do so if you find the idea
3299 of loading middleware via configuration weird :).  For example:
3300
3301     package MyApp;
3302
3303     use Catalyst;
3304
3305     __PACKAGE__->setup_middleware('Head');
3306     __PACKAGE__->setup;
3307
3308 When we read middleware definitions from configuration, we reverse the list
3309 which sounds odd but is likely how you expect it to work if you have prior
3310 experience with L<Plack::Builder> or if you previously used the plugin
3311 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3312
3313 So basically your middleware handles an incoming request from the first
3314 registered middleware, down and handles the response from the last middleware
3315 up.
3316
3317 =cut
3318
3319 sub registered_middlewares {
3320     my $class = shift;
3321     if(my $middleware = $class->_psgi_middleware) {
3322         return (
3323           Catalyst::Middleware::Stash->new,
3324           Plack::Middleware::HTTPExceptions->new,
3325           Plack::Middleware::RemoveRedundantBody->new,
3326           Plack::Middleware::FixMissingBodyInRedirect->new,
3327           Plack::Middleware::ContentLength->new,
3328           Plack::Middleware::MethodOverride->new,
3329           Plack::Middleware::Head->new,
3330           @$middleware);
3331     } else {
3332         die "You cannot call ->registered_middlewares until middleware has been setup";
3333     }
3334 }
3335
3336 sub setup_middleware {
3337     my $class = shift;
3338     my @middleware_definitions = @_ ?
3339       reverse(@_) : reverse(@{$class->config->{'psgi_middleware'}||[]});
3340
3341     my @middleware = ();
3342     while(my $next = shift(@middleware_definitions)) {
3343         if(ref $next) {
3344             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3345                 push @middleware, $next;
3346             } elsif(ref $next eq 'CODE') {
3347                 push @middleware, $next;
3348             } elsif(ref $next eq 'HASH') {
3349                 my $namespace = shift @middleware_definitions;
3350                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3351                 push @middleware, $mw;
3352             } else {
3353               die "I can't handle middleware definition ${\ref $next}";
3354             }
3355         } else {
3356           my $mw = $class->Catalyst::Utils::build_middleware($next);
3357           push @middleware, $mw;
3358         }
3359     }
3360
3361     my @existing = @{$class->_psgi_middleware || []};
3362     $class->_psgi_middleware([@middleware,@existing,]);
3363 }
3364
3365 =head2 registered_data_handlers
3366
3367 A read only copy of registered Data Handlers returned as a Hash, where each key
3368 is a content type and each value is a subref that attempts to decode that content
3369 type.
3370
3371 =head2 setup_data_handlers (?@data_handler)
3372
3373 Read configuration information stored in configuration key C<data_handlers> or
3374 from passed @args.
3375
3376 See under L</CONFIGURATION> information regarding C<data_handlers>.
3377
3378 This method is automatically called during 'setup' of your application, so
3379 you really don't need to invoke it.
3380
3381 =head2 default_data_handlers
3382
3383 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3384 only two default data handlers, for 'application/json' and an alternative to
3385 'application/x-www-form-urlencoded' which supposed nested form parameters via
3386 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3387
3388 The 'application/json' data handler is used to parse incoming JSON into a Perl
3389 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3390 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3391 JSON decoder, and has the smallest dependency impact.
3392
3393 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3394 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3395 order to get the best performance.  You should add either to your dependency
3396 list (Makefile.PL, dist.ini, cpanfile, etc.)
3397
3398 =cut
3399
3400 sub registered_data_handlers {
3401     my $class = shift;
3402     if(my $data_handlers = $class->_data_handlers) {
3403         return %$data_handlers;
3404     } else {
3405         $class->setup_data_handlers;
3406         return $class->registered_data_handlers;
3407     }
3408 }
3409
3410 sub setup_data_handlers {
3411     my ($class, %data_handler_callbacks) = @_;
3412     %data_handler_callbacks = (
3413       %{$class->default_data_handlers},
3414       %{$class->config->{'data_handlers'}||+{}},
3415       %data_handler_callbacks);
3416
3417     $class->_data_handlers(\%data_handler_callbacks);
3418 }
3419
3420 sub default_data_handlers {
3421     my ($class) = @_;
3422     return +{
3423       'application/x-www-form-urlencoded' => sub {
3424           my ($fh, $req) = @_;
3425           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3426           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3427             ->can('build_cgi_struct')->($params);
3428       },
3429       'application/json' => sub {
3430           Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON')
3431             ->can('decode_json')->(do { local $/; $_->getline });
3432       },
3433     };
3434 }
3435
3436 =head2 $c->stack
3437
3438 Returns an arrayref of the internal execution stack (actions that are
3439 currently executing).
3440
3441 =head2 $c->stats
3442
3443 Returns the current timing statistics object. By default Catalyst uses
3444 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3445 L<< stats_class|/"$c->stats_class" >>.
3446
3447 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3448 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3449 profile explicitly, although MyApp.pm still won't profile nor output anything
3450 by itself.
3451
3452 =head2 $c->stats_class
3453
3454 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3455
3456 =head2 $c->use_stats
3457
3458 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3459
3460 Note that this is a static method, not an accessor and should be overridden
3461 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3462
3463 =cut
3464
3465 sub use_stats { 0 }
3466
3467
3468 =head2 $c->write( $data )
3469
3470 Writes $data to the output stream. When using this method directly, you
3471 will need to manually set the C<Content-Length> header to the length of
3472 your output data, if known.
3473
3474 =cut
3475
3476 sub write {
3477     my $c = shift;
3478
3479     # Finalize headers if someone manually writes output (for compat)
3480     $c->finalize_headers;
3481
3482     return $c->response->write( @_ );
3483 }
3484
3485 =head2 version
3486
3487 Returns the Catalyst version number. Mostly useful for "powered by"
3488 messages in template systems.
3489
3490 =cut
3491
3492 sub version { return $Catalyst::VERSION }
3493
3494 =head1 CONFIGURATION
3495
3496 There are a number of 'base' config variables which can be set:
3497
3498 =over
3499
3500 =item *
3501
3502 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3503
3504 =item *
3505
3506 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3507
3508 =item *
3509
3510 C<disable_component_resolution_regex_fallback> - Turns
3511 off the deprecated component resolution functionality so
3512 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3513 are called then regex search will not be attempted on string values and
3514 instead C<undef> will be returned.
3515
3516 =item *
3517
3518 C<home> - The application home directory. In an uninstalled application,
3519 this is the top level application directory. In an installed application,
3520 this will be the directory containing C<< MyApp.pm >>.
3521
3522 =item *
3523
3524 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3525
3526 =item *
3527
3528 C<name> - The name of the application in debug messages and the debug and
3529 welcome screens
3530
3531 =item *
3532
3533 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3534 until it is accessed. This allows you to (for example) check authentication (and reject
3535 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3536
3537 =item *
3538
3539 C<root> - The root directory for templates. Usually this is just a
3540 subdirectory of the home directory, but you can set it to change the
3541 templates to a different directory.
3542
3543 =item *
3544
3545 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3546 namespaces from which components will be loaded (and constructed and stored in
3547 C<< $c->components >>).
3548
3549 =item *
3550
3551 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3552 to be shown in hit debug tables in the test server.
3553
3554 =item *
3555
3556 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3557 variable should be used for determining the request path.
3558
3559 Most web server environments pass the requested path to the application using environment variables,
3560 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3561 exposed as C<< $c->request->base >>) and the request path below that base.
3562
3563 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3564 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3565
3566 =over
3567
3568 =item use_request_uri_for_path => 0
3569
3570 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3571 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3572 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3573 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3574
3575 However this method has the major disadvantage that it is impossible to correctly decode some elements
3576 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3577 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3578 can't distinguish / vs %2F in paths (in addition to other encoded values).
3579
3580 =item use_request_uri_for_path => 1
3581
3582 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3583 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3584 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3585
3586 Given that this method of path resolution is provably more correct, it is recommended that you use
3587 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3588 aware of the implications of not being able to handle encoded URI paths correctly.
3589
3590 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3591 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3592 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3593 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3594 C<< $c->request->base >> will be incorrect.
3595
3596 =back
3597
3598 =item *
3599
3600 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3601
3602 =item *
3603
3604 C<encoding> - See L</ENCODING>
3605
3606 =item *
3607
3608 C<abort_chain_on_error_fix>
3609
3610 When there is an error in an action chain, the default behavior is to continue
3611 processing the remaining actions and then catch the error upon chain end.  This
3612 can lead to running actions when the application is in an unexpected state.  If
3613 you have this issue, setting this config value to true will promptly exit a
3614 chain when there is an error raised in any action (thus terminating the chain
3615 early.)
3616
3617 use like:
3618
3619     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3620
3621 In the future this might become the default behavior.
3622
3623 =item *
3624
3625 C<use_hash_multivalue_in_request>
3626
3627 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3628 and C<parameters> return a hashref where values might be scalar or an arrayref
3629 depending on the incoming data.  In many cases this can be undesirable as it
3630 leads one to writing defensive code like the following:
3631
3632     my ($val) = ref($c->req->parameters->{a}) ?
3633       @{$c->req->parameters->{a}} :
3634         $c->req->parameters->{a};
3635
3636 Setting this configuration item to true will make L<Catalyst> populate the
3637 attributes underlying these methods with an instance of L<Hash::MultiValue>
3638 which is used by L<Plack::Request> and others to solve this very issue.  You
3639 may prefer this behavior to the default, if so enable this option (be warned
3640 if you enable it in a legacy application we are not sure if it is completely
3641 backwardly compatible).
3642
3643 =item *
3644
3645 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3646
3647 =item *
3648
3649 C<data_handlers> - See L<DATA HANDLERS>.
3650
3651 =back
3652
3653 =head1 EXCEPTIONS
3654
3655 Generally when you throw an exception inside an Action (or somewhere in
3656 your stack, such as in a model that an Action is calling) that exception
3657 is caught by Catalyst and unless you either catch it yourself (via eval
3658 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3659 will eventually reach L</finalize_errors> and return either the debugging
3660 error stack page, or the default error page.  However, if your exception
3661 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3662 instead rethrow it so that it can be handled by that middleware (which
3663 is part of the default middleware).  For example this would allow
3664
3665     use HTTP::Throwable::Factory 'http_throw';
3666
3667     sub throws_exception :Local {
3668       my ($self, $c) = @_;
3669
3670       http_throw(SeeOther => { location =>
3671         $c->uri_for($self->action_for('redirect')) });
3672
3673     }
3674
3675 =head1 INTERNAL ACTIONS
3676
3677 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3678 C<_ACTION>, and C<_END>. These are by default not shown in the private
3679 action table, but you can make them visible with a config parameter.
3680
3681     MyApp->config(show_internal_actions => 1);
3682
3683 =head1 ON-DEMAND PARSER
3684
3685 The request body is usually parsed at the beginning of a request,
3686 but if you want to handle input yourself, you can enable on-demand
3687 parsing with a config parameter.
3688
3689     MyApp->config(parse_on_demand => 1);
3690
3691 =head1 PROXY SUPPORT
3692
3693 Many production servers operate using the common double-server approach,
3694 with a lightweight frontend web server passing requests to a larger
3695 backend server. An application running on the backend server must deal
3696 with two problems: the remote user always appears to be C<127.0.0.1> and
3697 the server's hostname will appear to be C<localhost> regardless of the
3698 virtual host that the user connected through.
3699
3700 Catalyst will automatically detect this situation when you are running
3701 the frontend and backend servers on the same machine. The following
3702 changes are made to the request.
3703
3704     $c->req->address is set to the user's real IP address, as read from
3705     the HTTP X-Forwarded-For header.
3706
3707     The host value for $c->req->base and $c->req->uri is set to the real
3708     host, as read from the HTTP X-Forwarded-Host header.
3709
3710 Additionally, you may be running your backend application on an insecure
3711 connection (port 80) while your frontend proxy is running under SSL.  If there
3712 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3713 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3714 be created properly.
3715
3716 In the case of passing in:
3717
3718     X-Forwarded-Port: 443
3719
3720 All calls to C<uri_for> will result in an https link, as is expected.
3721
3722 Obviously, your web server must support these headers for this to work.
3723
3724 In a more complex server farm environment where you may have your
3725 frontend proxy server(s) on different machines, you will need to set a
3726 configuration option to tell Catalyst to read the proxied data from the
3727 headers.
3728
3729     MyApp->config(using_frontend_proxy => 1);
3730
3731 If you do not wish to use the proxy support at all, you may set:
3732
3733     MyApp->config(ignore_frontend_proxy => 0);
3734
3735 =head2 Note about psgi files
3736
3737 Note that if you supply your own .psgi file, calling
3738 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3739
3740 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3741 in your psgi, for example:
3742
3743     builder {
3744         enable "Plack::Middleware::ReverseProxy";
3745         MyApp->psgi_app
3746     };
3747
3748 This will unconditionally add the ReverseProxy support, or you need to call
3749 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3750 apply the support depending upon your config).
3751
3752 See L<Catalyst::PSGI> for more information.
3753
3754 =head1 THREAD SAFETY
3755
3756 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3757 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3758 believe the Catalyst core to be thread-safe.
3759
3760 If you plan to operate in a threaded environment, remember that all other
3761 modules you are using must also be thread-safe. Some modules, most notably
3762 L<DBD::SQLite>, are not thread-safe.
3763
3764 =head1 DATA HANDLERS
3765
3766 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3767 form parameters and URL search query fields.  However it has become common
3768 for various alternative content types to be PUT or POSTed to your controllers
3769 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3770 XML and other content types when communicating with an application server.  In
3771 order to better support this use case, L<Catalyst> defines a global configuration
3772 option, C<data_handlers>, which lets you associate a content type with a coderef
3773 that parses that content type into something Perl can readily access.
3774
3775     package MyApp::Web;
3776
3777     use Catalyst;
3778     use JSON::Maybe;
3779
3780     __PACKAGE__->config(
3781       data_handlers => {
3782         'application/json' => sub { local $/; decode_json $_->getline },
3783       },
3784       ## Any other configuration.
3785     );
3786
3787     __PACKAGE__->setup;
3788
3789 By default L<Catalyst> comes with a generic JSON data handler similar to the
3790 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3791 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3792 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3793 or dist.ini, cpanfile, etc.)
3794
3795 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
3796 (matched against the incoming request type using a regexp such as to be case
3797 insensitive) and whose values are coderefs that receive a localized version of
3798 C<$_> which is a filehandle object pointing to received body.
3799
3800 This feature is considered an early access release and we reserve the right
3801 to alter the interface in order to provide a performant and secure solution to
3802 alternative request body content.  Your reports welcomed!
3803
3804 =head1 PSGI MIDDLEWARE
3805
3806 You can define middleware, defined as L<Plack::Middleware> or a compatible
3807 interface in configuration.  Your middleware definitions are in the form of an
3808 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3809 with details to follow:
3810
3811     package MyApp::Web;
3812
3813     use Catalyst;
3814     use Plack::Middleware::StackTrace;
3815
3816     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3817
3818     __PACKAGE__->config(
3819       'psgi_middleware', [
3820         'Debug',
3821         '+MyApp::Custom',
3822         $stacktrace_middleware,
3823         'Session' => {store => 'File'},
3824         sub {
3825           my $app = shift;
3826           return sub {
3827             my $env = shift;
3828             $env->{myapp.customkey} = 'helloworld';
3829             $app->($env);
3830           },
3831         },
3832       ],
3833     );
3834
3835     __PACKAGE__->setup;
3836
3837 So the general form is:
3838
3839     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3840
3841 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3842 the order listed (to make it function similarly to L<Plack::Builder>:
3843
3844 Alternatively, you may also define middleware by calling the L</setup_middleware>
3845 package method:
3846
3847     package MyApp::Web;
3848
3849     use Catalyst;
3850
3851     __PACKAGE__->setup_middleware( \@middleware_definitions);
3852     __PACKAGE__->setup;
3853
3854 In the case where you do both (use 'setup_middleware' and configuration) the
3855 package call to setup_middleware will be applied earlier (in other words its
3856 middleware will wrap closer to the application).  Keep this in mind since in
3857 some cases the order of middleware is important.
3858
3859 The two approaches are not exclusive.
3860
3861 =over 4
3862
3863 =item Middleware Object
3864
3865 An already initialized object that conforms to the L<Plack::Middleware>
3866 specification:
3867
3868     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3869
3870     __PACKAGE__->config(
3871       'psgi_middleware', [
3872         $stacktrace_middleware,
3873       ]);
3874
3875
3876 =item coderef
3877
3878 A coderef that is an inlined middleware:
3879
3880     __PACKAGE__->config(
3881       'psgi_middleware', [
3882         sub {
3883           my $app = shift;
3884           return sub {
3885             my $env = shift;
3886             if($env->{PATH_INFO} =~m/forced/) {
3887               Plack::App::File
3888                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3889                 ->call($env);
3890             } else {
3891               return $app->($env);
3892             }
3893          },
3894       },
3895     ]);
3896
3897
3898
3899 =item a scalar
3900
3901 We assume the scalar refers to a namespace after normalizing it using the
3902 following rules:
3903
3904 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3905 is assumed to be 'as is', and we just install and use the middleware.
3906
3907 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3908 (the package name of your Catalyst application subclass), we also assume then
3909 that it is a full namespace, and use it.
3910
3911 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3912 resolve it first by looking for it under your application namespace (for example
3913 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3914 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3915 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3916 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3917 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3918 you find that a good idea.
3919
3920 Examples:
3921
3922     package MyApp::Web;
3923
3924     __PACKAGE__->config(
3925       'psgi_middleware', [
3926         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3927         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3928         '+MyApp::Custom',  ## MyApp::Custom->wrap
3929       ],
3930     );
3931
3932 =item a scalar followed by a hashref
3933
3934 Just like the previous, except the following C<HashRef> is used as arguments
3935 to initialize the middleware object.
3936
3937     __PACKAGE__->config(
3938       'psgi_middleware', [
3939          'Session' => {store => 'File'},
3940     ]);
3941
3942 =back
3943
3944 Please see L<PSGI> for more on middleware.
3945
3946 =head1 ENCODING
3947
3948 On request, decodes all params from encoding into a sequence of
3949 logical characters. On response, encodes body into encoding.
3950
3951 =head2 Methods
3952
3953 =over 4
3954
3955 =item encoding
3956
3957 Returns an instance of an C<Encode> encoding
3958
3959     print $c->encoding->name
3960
3961 =item handle_unicode_encoding_exception ($exception_context)
3962
3963 Method called when decoding process for a request fails.
3964
3965 An C<$exception_context> hashref is provided to allow you to override the
3966 behaviour of your application when given data with incorrect encodings.
3967
3968 The default method throws exceptions in the case of invalid request parameters
3969 (resulting in a 500 error), but ignores errors in upload filenames.
3970
3971 The keys passed in the C<$exception_context> hash are:
3972
3973 =over
3974
3975 =item param_value
3976
3977 The value which was not able to be decoded.
3978
3979 =item error_msg
3980
3981 The exception received from L<Encode>.
3982
3983 =item encoding_step
3984
3985 What type of data was being decoded. Valid values are (currently)
3986 C<params> - for request parameters / arguments / captures
3987 and C<uploads> - for request upload filenames.
3988
3989 =back
3990
3991 =back
3992
3993 =head1 SUPPORT
3994
3995 IRC:
3996
3997     Join #catalyst on irc.perl.org.
3998
3999 Mailing Lists:
4000
4001     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4002     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4003
4004 Web:
4005
4006     http://catalyst.perl.org
4007
4008 Wiki:
4009
4010     http://dev.catalyst.perl.org
4011
4012 =head1 SEE ALSO
4013
4014 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4015
4016 =head2 L<Catalyst::Manual> - The Catalyst Manual
4017
4018 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4019
4020 =head2 L<Catalyst::Engine> - Core engine
4021
4022 =head2 L<Catalyst::Log> - Log class.
4023
4024 =head2 L<Catalyst::Request> - Request object
4025
4026 =head2 L<Catalyst::Response> - Response object
4027
4028 =head2 L<Catalyst::Test> - The test suite.
4029
4030 =head1 PROJECT FOUNDER
4031
4032 sri: Sebastian Riedel <sri@cpan.org>
4033
4034 =head1 CONTRIBUTORS
4035
4036 abw: Andy Wardley
4037
4038 acme: Leon Brocard <leon@astray.com>
4039
4040 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4041
4042 Andrew Bramble
4043
4044 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4045
4046 Andrew Ruthven
4047
4048 andyg: Andy Grundman <andy@hybridized.org>
4049
4050 audreyt: Audrey Tang
4051
4052 bricas: Brian Cassidy <bricas@cpan.org>
4053
4054 Caelum: Rafael Kitover <rkitover@io.com>
4055
4056 chansen: Christian Hansen
4057
4058 chicks: Christopher Hicks
4059
4060 Chisel Wright C<pause@herlpacker.co.uk>
4061
4062 Danijel Milicevic C<me@danijel.de>
4063
4064 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4065
4066 David Naughton, C<naughton@umn.edu>
4067
4068 David E. Wheeler
4069
4070 dhoss: Devin Austin <dhoss@cpan.org>
4071
4072 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4073
4074 Drew Taylor
4075
4076 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4077
4078 esskar: Sascha Kiefer
4079
4080 fireartist: Carl Franks <cfranks@cpan.org>
4081
4082 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4083
4084 gabb: Danijel Milicevic
4085
4086 Gary Ashton Jones
4087
4088 Gavin Henry C<ghenry@perl.me.uk>
4089
4090 Geoff Richards
4091
4092 groditi: Guillermo Roditi <groditi@gmail.com>
4093
4094 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4095
4096 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4097
4098 jcamacho: Juan Camacho
4099
4100 jester: Jesse Sheidlower C<jester@panix.com>
4101
4102 jhannah: Jay Hannah <jay@jays.net>
4103
4104 Jody Belka
4105
4106 Johan Lindstrom
4107
4108 jon: Jon Schutz <jjschutz@cpan.org>
4109
4110 Jonathan Rockway C<< <jrockway@cpan.org> >>
4111
4112 Kieren Diment C<kd@totaldatasolution.com>
4113
4114 konobi: Scott McWhirter <konobi@cpan.org>
4115
4116 marcus: Marcus Ramberg <mramberg@cpan.org>
4117
4118 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4119
4120 mgrimes: Mark Grimes <mgrimes@cpan.org>
4121
4122 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4123
4124 mugwump: Sam Vilain
4125
4126 naughton: David Naughton
4127
4128 ningu: David Kamholz <dkamholz@cpan.org>
4129
4130 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4131
4132 numa: Dan Sully <daniel@cpan.org>
4133
4134 obra: Jesse Vincent
4135
4136 Octavian Rasnita
4137
4138 omega: Andreas Marienborg
4139
4140 Oleg Kostyuk <cub.uanic@gmail.com>
4141
4142 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4143
4144 rafl: Florian Ragwitz <rafl@debian.org>
4145
4146 random: Roland Lammel <lammel@cpan.org>
4147
4148 Robert Sedlacek C<< <rs@474.at> >>
4149
4150 SpiceMan: Marcel Montes
4151
4152 sky: Arthur Bergman
4153
4154 szbalint: Balint Szilakszi <szbalint@cpan.org>
4155
4156 t0m: Tomas Doran <bobtfish@bobtfish.net>
4157
4158 Ulf Edvinsson
4159
4160 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4161
4162 Viljo Marrandi C<vilts@yahoo.com>
4163
4164 Will Hawes C<info@whawes.co.uk>
4165
4166 willert: Sebastian Willert <willert@cpan.org>
4167
4168 wreis: Wallace Reis <wreis@cpan.org>
4169
4170 Yuval Kogman, C<nothingmuch@woobling.org>
4171
4172 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4173
4174 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4175
4176 Upasana <me@upasana.me>
4177
4178 =head1 COPYRIGHT
4179
4180 Copyright (c) 2005-2014, the above named PROJECT FOUNDER and CONTRIBUTORS.
4181
4182 =head1 LICENSE
4183
4184 This library is free software. You can redistribute it and/or modify it under
4185 the same terms as Perl itself.
4186
4187 =cut
4188
4189 no Moose;
4190
4191 __PACKAGE__->meta->make_immutable;
4192
4193 1;