lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken blessed/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 __PACKAGE__->mk_accessors(
  34     qw/counter request response state action stack namespace stats/
  35 );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class stats_class
  56   setup_finished/;
  57
  58 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  59 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  60 __PACKAGE__->request_class('Catalyst::Request');
  61 __PACKAGE__->response_class('Catalyst::Response');
  62 __PACKAGE__->stats_class('Catalyst::Stats');
  63
  64 # Remember to update this in Catalyst::Runtime as well!
  65
  66 our $VERSION = '5.7099_03';
  67
  68 sub import {
  69     my ( $class, @arguments ) = @_;
  70
  71     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  72     # callers @ISA.
  73     return unless $class eq 'Catalyst';
  74
  75     my $caller = caller(0);
  76
  77     unless ( $caller->isa('Catalyst') ) {
  78         no strict 'refs';
  79         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  80     }
  81
  82     $caller->arguments( [@arguments] );
  83     $caller->setup_home;
  84 }
  85
  86 =head1 NAME
  87
  88 Catalyst - The Elegant MVC Web Application Framework
  89
  90 =head1 SYNOPSIS
  91
  92 See the L<Catalyst::Manual> distribution for comprehensive
  93 documentation and tutorials.
  94
  95     # Install Catalyst::Devel for helpers and other development tools
  96     # use the helper to create a new application
  97     catalyst.pl MyApp
  98
  99     # add models, views, controllers
 100     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 101     script/myapp_create.pl view MyTemplate TT
 102     script/myapp_create.pl controller Search
 103
 104     # built in testserver -- use -r to restart automatically on changes
 105     # --help to see all available options
 106     script/myapp_server.pl
 107
 108     # command line testing interface
 109     script/myapp_test.pl /yada
 110
 111     ### in lib/MyApp.pm
 112     use Catalyst qw/-Debug/; # include plugins here as well
 113
 114     ### In lib/MyApp/Controller/Root.pm (autocreated)
 115     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 116         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 117         $c->stash->{template} = 'foo.tt'; # set the template
 118         # lookup something from db -- stash vars are passed to TT
 119         $c->stash->{data} =
 120           $c->model('Database::Foo')->search( { country => $args[0] } );
 121         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 122             $c->forward( 'bar' ); # process another action
 123             # do something else after forward returns
 124         }
 125     }
 126
 127     # The foo.tt TT template can use the stash data from the database
 128     [% WHILE (item = data.next) %]
 129         [% item.foo %]
 130     [% END %]
 131
 132     # called for /bar/of/soap, /bar/of/soap/10, etc.
 133     sub bar : Path('/bar/of/soap') { ... }
 134
 135     # called for all actions, from the top-most controller downwards
 136     sub auto : Private {
 137         my ( $self, $c ) = @_;
 138         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 139             $c->res->redirect( '/login' ); # require login
 140             return 0; # abort request and go immediately to end()
 141         }
 142         return 1; # success; carry on to next action
 143     }
 144
 145     # called after all actions are finished
 146     sub end : Private {
 147         my ( $self, $c ) = @_;
 148         if ( scalar @{ $c->error } ) { ... } # handle errors
 149         return if $c->res->body; # already have a response
 150         $c->forward( 'MyApp::View::TT' ); # render template
 151     }
 152
 153     ### in MyApp/Controller/Foo.pm
 154     # called for /foo/bar
 155     sub bar : Local { ... }
 156
 157     # called for /blargle
 158     sub blargle : Global { ... }
 159
 160     # an index action matches /foo, but not /foo/1, etc.
 161     sub index : Private { ... }
 162
 163     ### in MyApp/Controller/Foo/Bar.pm
 164     # called for /foo/bar/baz
 165     sub baz : Local { ... }
 166
 167     # first Root auto is called, then Foo auto, then this
 168     sub auto : Private { ... }
 169
 170     # powerful regular expression paths are also possible
 171     sub details : Regex('^product/(\w+)/details$') {
 172         my ( $self, $c ) = @_;
 173         # extract the (\w+) from the URI
 174         my $product = $c->req->captures->[0];
 175     }
 176
 177 See L<Catalyst::Manual::Intro> for additional information.
 178
 179 =head1 DESCRIPTION
 180
 181 Catalyst is a modern framework for making web applications without the
 182 pain usually associated with this process. This document is a reference
 183 to the main Catalyst application. If you are a new user, we suggest you
 184 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 185
 186 See L<Catalyst::Manual> for more documentation.
 187
 188 Catalyst plugins can be loaded by naming them as arguments to the "use
 189 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 190 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 191 C<My::Module>.
 192
 193     use Catalyst qw/My::Module/;
 194
 195 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 196 fully qualify the name by using a unary plus:
 197
 198     use Catalyst qw/
 199         My::Module
 200         +Fully::Qualified::Plugin::Name
 201     /;
 202
 203 Special flags like C<-Debug> and C<-Engine> can also be specified as
 204 arguments when Catalyst is loaded:
 205
 206     use Catalyst qw/-Debug My::Module/;
 207
 208 The position of plugins and flags in the chain is important, because
 209 they are loaded in the order in which they appear.
 210
 211 The following flags are supported:
 212
 213 =head2 -Debug
 214
 215 Enables debug output. You can also force this setting from the system
 216 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 217 settings override the application, with <MYAPP>_DEBUG having the highest
 218 priority.
 219
 220 =head2 -Engine
 221
 222 Forces Catalyst to use a specific engine. Omit the
 223 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 224
 225     use Catalyst qw/-Engine=CGI/;
 226
 227 =head2 -Home
 228
 229 Forces Catalyst to use a specific home directory, e.g.:
 230
 231     use Catalyst qw[-Home=/usr/mst];
 232
 233 This can also be done in the shell environment by setting either the
 234 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 235 is replaced with the uppercased name of your application, any "::" in
 236 the name will be replaced with underscores, e.g. MyApp::Web should use
 237 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 238
 239 =head2 -Log
 240
 241 Specifies log level.
 242
 243 =head2 -Stats
 244
 245 Enables statistics collection and reporting. You can also force this setting
 246 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 247 environment settings override the application, with <MYAPP>_STATS having the
 248 highest priority.
 249
 250 e.g.
 251
 252    use Catalyst qw/-Stats=1/
 253
 254 =head1 METHODS
 255
 256 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 257
 258 =head2 $c->action
 259
 260 Returns a L<Catalyst::Action> object for the current action, which
 261 stringifies to the action name. See L<Catalyst::Action>.
 262
 263 =head2 $c->namespace
 264
 265 Returns the namespace of the current action, i.e., the URI prefix
 266 corresponding to the controller of the current action. For example:
 267
 268     # in Controller::Foo::Bar
 269     $c->namespace; # returns 'foo/bar';
 270
 271 =head2 $c->request
 272
 273 =head2 $c->req
 274
 275 Returns the current L<Catalyst::Request> object, giving access to
 276 information about the current client request (including parameters,
 277 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 278
 279 =head2 REQUEST FLOW HANDLING
 280
 281 =head2 $c->forward( $action [, \@arguments ] )
 282
 283 =head2 $c->forward( $class, $method, [, \@arguments ] )
 284
 285 Forwards processing to another action, by its private name. If you give a
 286 class name but no method, C<process()> is called. You may also optionally
 287 pass arguments in an arrayref. The action will receive the arguments in
 288 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 289 C<< $c->req->args >> will be restored to the previous values.
 290
 291 Any data C<return>ed from the action forwarded to, will be returned by the
 292 call to forward.
 293
 294     my $foodata = $c->forward('/foo');
 295     $c->forward('index');
 296     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 297     $c->forward('MyApp::View::TT');
 298
 299 Note that forward implies an C<<eval { }>> around the call (actually
 300 C<execute> does), thus de-fatalizing all 'dies' within the called
 301 action. If you want C<die> to propagate you need to do something like:
 302
 303     $c->forward('foo');
 304     die $c->error if $c->error;
 305
 306 Or make sure to always return true values from your actions and write
 307 your code like this:
 308
 309     $c->forward('foo') || return;
 310
 311 =cut
 312
 313 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 314
 315 =head2 $c->detach( $action [, \@arguments ] )
 316
 317 =head2 $c->detach( $class, $method, [, \@arguments ] )
 318
 319 =head2 $c->detach()
 320
 321 The same as C<forward>, but doesn't return to the previous action when
 322 processing is finished.
 323
 324 When called with no arguments it escapes the processing chain entirely.
 325
 326 =cut
 327
 328 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 329
 330 =head2 $c->response
 331
 332 =head2 $c->res
 333
 334 Returns the current L<Catalyst::Response> object, see there for details.
 335
 336 =head2 $c->stash
 337
 338 Returns a hashref to the stash, which may be used to store data and pass
 339 it between components during a request. You can also set hash keys by
 340 passing arguments. The stash is automatically sent to the view. The
 341 stash is cleared at the end of a request; it cannot be used for
 342 persistent storage (for this you must use a session; see
 343 L<Catalyst::Plugin::Session> for a complete system integrated with
 344 Catalyst).
 345
 346     $c->stash->{foo} = $bar;
 347     $c->stash( { moose => 'majestic', qux => 0 } );
 348     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 349
 350     # stash is automatically passed to the view for use in a template
 351     $c->forward( 'MyApp::View::TT' );
 352
 353 =cut
 354
 355 sub stash {
 356     my $c = shift;
 357     if (@_) {
 358         my $stash = @_ > 1 ? {@_} : $_[0];
 359         croak('stash takes a hash or hashref') unless ref $stash;
 360         foreach my $key ( keys %$stash ) {
 361             $c->{stash}->{$key} = $stash->{$key};
 362         }
 363     }
 364     return $c->{stash};
 365 }
 366
 367 =head2 $c->error
 368
 369 =head2 $c->error($error, ...)
 370
 371 =head2 $c->error($arrayref)
 372
 373 Returns an arrayref containing error messages.  If Catalyst encounters an
 374 error while processing a request, it stores the error in $c->error.  This
 375 method should only be used to store fatal error messages.
 376
 377     my @error = @{ $c->error };
 378
 379 Add a new error.
 380
 381     $c->error('Something bad happened');
 382
 383 =cut
 384
 385 sub error {
 386     my $c = shift;
 387     if ( $_[0] ) {
 388         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 389         croak @$error unless ref $c;
 390         push @{ $c->{error} }, @$error;
 391     }
 392     elsif ( defined $_[0] ) { $c->{error} = undef }
 393     return $c->{error} || [];
 394 }
 395
 396
 397 =head2 $c->state
 398
 399 Contains the return value of the last executed action.
 400
 401 =head2 $c->clear_errors
 402
 403 Clear errors.  You probably don't want to clear the errors unless you are
 404 implementing a custom error screen.
 405
 406 This is equivalent to running
 407
 408     $c->error(0);
 409
 410 =cut
 411
 412 sub clear_errors {
 413     my $c = shift;
 414     $c->error(0);
 415 }
 416
 417 # search components given a name and some prefixes
 418 sub _comp_search_prefixes {
 419     my ( $c, $name, @prefixes ) = @_;
 420     my $appclass = ref $c || $c;
 421     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 422
 423     # map the original component name to the sub part that we will search against
 424     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 425         grep { /$filter/ } keys %{ $c->components };
 426
 427     # undef for a name will return all
 428     return keys %eligible if !defined $name;
 429
 430     my $query  = ref $name ? $name : qr/^$name$/i;
 431     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 432
 433     return map { $c->components->{ $_ } } @result if @result;
 434
 435     # if we were given a regexp to search against, we're done.
 436     return if ref $name;
 437
 438     # regexp fallback
 439     $query  = qr/$name/i;
 440     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 441
 442     # no results? try against full names
 443     if( !@result ) {
 444         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 445     }
 446
 447     # don't warn if we didn't find any results, it just might not exist
 448     if( @result ) {
 449         $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 450         $c->log->warn( 'Relying on the regexp fallback behavior for component resolution is unreliable and unsafe.' );
 451         $c->log->warn( 'If you really want to search, pass in a regexp as the argument.' );
 452     }
 453
 454     return @result;
 455 }
 456
 457 # Find possible names for a prefix
 458 sub _comp_names {
 459     my ( $c, @prefixes ) = @_;
 460     my $appclass = ref $c || $c;
 461
 462     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 463
 464     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 465     return @names;
 466 }
 467
 468 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 469 sub _filter_component {
 470     my ( $c, $comp, @args ) = @_;
 471
 472     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 473         return $comp->ACCEPT_CONTEXT( $c, @args );
 474     }
 475
 476     return $comp;
 477 }
 478
 479 =head2 COMPONENT ACCESSORS
 480
 481 =head2 $c->controller($name)
 482
 483 Gets a L<Catalyst::Controller> instance by name.
 484
 485     $c->controller('Foo')->do_stuff;
 486
 487 If the name is omitted, will return the controller for the dispatched
 488 action.
 489
 490 If you want to search for controllers, pass in a regexp as the argument.
 491
 492     # find all controllers that start with Foo
 493     my @foo_controllers = $c->controller(qr{^Foo});
 494
 495
 496 =cut
 497
 498 sub controller {
 499     my ( $c, $name, @args ) = @_;
 500
 501     if( $name ) {
 502         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 503         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 504         return $c->_filter_component( $result[ 0 ], @args );
 505     }
 506
 507     return $c->component( $c->action->class );
 508 }
 509
 510 =head2 $c->model($name)
 511
 512 Gets a L<Catalyst::Model> instance by name.
 513
 514     $c->model('Foo')->do_stuff;
 515
 516 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 517
 518 If the name is omitted, it will look for
 519  - a model object in $c->stash->{current_model_instance}, then
 520  - a model name in $c->stash->{current_model}, then
 521  - a config setting 'default_model', or
 522  - check if there is only one model, and return it if that's the case.
 523
 524 If you want to search for models, pass in a regexp as the argument.
 525
 526     # find all models that start with Foo
 527     my @foo_models = $c->model(qr{^Foo});
 528
 529 =cut
 530
 531 sub model {
 532     my ( $c, $name, @args ) = @_;
 533
 534     if( $name ) {
 535         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 536         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 537         return $c->_filter_component( $result[ 0 ], @args );
 538     }
 539
 540     if (ref $c) {
 541         return $c->stash->{current_model_instance}
 542           if $c->stash->{current_model_instance};
 543         return $c->model( $c->stash->{current_model} )
 544           if $c->stash->{current_model};
 545     }
 546     return $c->model( $c->config->{default_model} )
 547       if $c->config->{default_model};
 548
 549     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 550
 551     if( $rest ) {
 552         $c->log->warn( 'Calling $c->model() will return a random model unless you specify one of:' );
 553         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 554         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 555         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 556         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 557     }
 558
 559     return $c->_filter_component( $comp );
 560 }
 561
 562
 563 =head2 $c->view($name)
 564
 565 Gets a L<Catalyst::View> instance by name.
 566
 567     $c->view('Foo')->do_stuff;
 568
 569 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 570
 571 If the name is omitted, it will look for
 572  - a view object in $c->stash->{current_view_instance}, then
 573  - a view name in $c->stash->{current_view}, then
 574  - a config setting 'default_view', or
 575  - check if there is only one view, and return it if that's the case.
 576
 577 If you want to search for views, pass in a regexp as the argument.
 578
 579     # find all views that start with Foo
 580     my @foo_views = $c->view(qr{^Foo});
 581
 582 =cut
 583
 584 sub view {
 585     my ( $c, $name, @args ) = @_;
 586
 587     if( $name ) {
 588         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 589         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 590         return $c->_filter_component( $result[ 0 ], @args );
 591     }
 592
 593     if (ref $c) {
 594         return $c->stash->{current_view_instance}
 595           if $c->stash->{current_view_instance};
 596         return $c->view( $c->stash->{current_view} )
 597           if $c->stash->{current_view};
 598     }
 599     return $c->view( $c->config->{default_view} )
 600       if $c->config->{default_view};
 601
 602     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 603
 604     if( $rest ) {
 605         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 606         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 607         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 608         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 609         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 610     }
 611
 612     return $c->_filter_component( $comp );
 613 }
 614
 615 =head2 $c->controllers
 616
 617 Returns the available names which can be passed to $c->controller
 618
 619 =cut
 620
 621 sub controllers {
 622     my ( $c ) = @_;
 623     return $c->_comp_names(qw/Controller C/);
 624 }
 625
 626 =head2 $c->models
 627
 628 Returns the available names which can be passed to $c->model
 629
 630 =cut
 631
 632 sub models {
 633     my ( $c ) = @_;
 634     return $c->_comp_names(qw/Model M/);
 635 }
 636
 637
 638 =head2 $c->views
 639
 640 Returns the available names which can be passed to $c->view
 641
 642 =cut
 643
 644 sub views {
 645     my ( $c ) = @_;
 646     return $c->_comp_names(qw/View V/);
 647 }
 648
 649 =head2 $c->comp($name)
 650
 651 =head2 $c->component($name)
 652
 653 Gets a component object by name. This method is not recommended,
 654 unless you want to get a specific component by full
 655 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 656 should be used instead.
 657
 658 If C<$name> is a regexp, a list of components matched against the full
 659 component name will be returned.
 660
 661 =cut
 662
 663 sub component {
 664     my ( $c, $name, @args ) = @_;
 665
 666     if( $name ) {
 667         my $comps = $c->components;
 668
 669         if( !ref $name ) {
 670             # is it the exact name?
 671             return $c->_filter_component( $comps->{ $name }, @args )
 672                        if exists $comps->{ $name };
 673
 674             # perhaps we just omitted "MyApp"?
 675             my $composed = ( ref $c || $c ) . "::${name}";
 676             return $c->_filter_component( $comps->{ $composed }, @args )
 677                        if exists $comps->{ $composed };
 678
 679             # search all of the models, views and controllers
 680             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 681             return $c->_filter_component( $comp, @args ) if $comp;
 682         }
 683
 684         # This is here so $c->comp( '::M::' ) works
 685         my $query = ref $name ? $name : qr{$name}i;
 686
 687         my @result = grep { m{$query} } keys %{ $c->components };
 688         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 689
 690         if( $result[ 0 ] ) {
 691             $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 692             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 693             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 694             return $c->_filter_component( $result[ 0 ], @args );
 695         }
 696
 697         # I would expect to return an empty list here, but that breaks back-compat
 698     }
 699
 700     # fallback
 701     return sort keys %{ $c->components };
 702 }
 703
 704 =head2 CLASS DATA AND HELPER CLASSES
 705
 706 =head2 $c->config
 707
 708 Returns or takes a hashref containing the application's configuration.
 709
 710     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 711
 712 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 713 like myapp.yml in your applications home directory. See
 714 L<Catalyst::Plugin::ConfigLoader>.
 715
 716     ---
 717     db: dsn:SQLite:foo.db
 718
 719
 720 =cut
 721
 722 sub config {
 723     my $c = shift;
 724
 725     $c->log->warn("Setting config after setup has been run is not a good idea.")
 726       if ( @_ and $c->setup_finished );
 727
 728     $c->NEXT::config(@_);
 729 }
 730
 731 =head2 $c->log
 732
 733 Returns the logging object instance. Unless it is already set, Catalyst
 734 sets this up with a L<Catalyst::Log> object. To use your own log class,
 735 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 736 C<< __PACKAGE__->setup >>.
 737
 738  __PACKAGE__->log( MyLogger->new );
 739  __PACKAGE__->setup;
 740
 741 And later:
 742
 743     $c->log->info( 'Now logging with my own logger!' );
 744
 745 Your log class should implement the methods described in
 746 L<Catalyst::Log>.
 747
 748
 749 =head2 $c->debug
 750
 751 Overload to enable debug messages (same as -Debug option).
 752
 753 Note that this is a static method, not an accessor and should be overloaded
 754 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 755
 756 =cut
 757
 758 sub debug { 0 }
 759
 760 =head2 $c->dispatcher
 761
 762 Returns the dispatcher instance. Stringifies to class name. See
 763 L<Catalyst::Dispatcher>.
 764
 765 =head2 $c->engine
 766
 767 Returns the engine instance. Stringifies to the class name. See
 768 L<Catalyst::Engine>.
 769
 770
 771 =head2 UTILITY METHODS
 772
 773 =head2 $c->path_to(@path)
 774
 775 Merges C<@path> with C<< $c->config->{home} >> and returns a
 776 L<Path::Class::Dir> object.
 777
 778 For example:
 779
 780     $c->path_to( 'db', 'sqlite.db' );
 781
 782 =cut
 783
 784 sub path_to {
 785     my ( $c, @path ) = @_;
 786     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 787     if ( -d $path ) { return $path }
 788     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 789 }
 790
 791 =head2 $c->plugin( $name, $class, @args )
 792
 793 Helper method for plugins. It creates a classdata accessor/mutator and
 794 loads and instantiates the given class.
 795
 796     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 797
 798     $c->prototype->define_javascript_functions;
 799
 800 =cut
 801
 802 sub plugin {
 803     my ( $class, $name, $plugin, @args ) = @_;
 804     $class->_register_plugin( $plugin, 1 );
 805
 806     eval { $plugin->import };
 807     $class->mk_classdata($name);
 808     my $obj;
 809     eval { $obj = $plugin->new(@args) };
 810
 811     if ($@) {
 812         Catalyst::Exception->throw( message =>
 813               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 814     }
 815
 816     $class->$name($obj);
 817     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 818       if $class->debug;
 819 }
 820
 821 =head2 MyApp->setup
 822
 823 Initializes the dispatcher and engine, loads any plugins, and loads the
 824 model, view, and controller components. You may also specify an array
 825 of plugins to load here, if you choose to not load them in the C<use
 826 Catalyst> line.
 827
 828     MyApp->setup;
 829     MyApp->setup( qw/-Debug/ );
 830
 831 =cut
 832
 833 sub setup {
 834     my ( $class, @arguments ) = @_;
 835
 836     $class->log->warn("Running setup twice is not a good idea.")
 837       if ( $class->setup_finished );
 838
 839     unless ( $class->isa('Catalyst') ) {
 840
 841         Catalyst::Exception->throw(
 842             message => qq/'$class' does not inherit from Catalyst/ );
 843     }
 844
 845     if ( $class->arguments ) {
 846         @arguments = ( @arguments, @{ $class->arguments } );
 847     }
 848
 849     # Process options
 850     my $flags = {};
 851
 852     foreach (@arguments) {
 853
 854         if (/^-Debug$/) {
 855             $flags->{log} =
 856               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 857         }
 858         elsif (/^-(\w+)=?(.*)$/) {
 859             $flags->{ lc $1 } = $2;
 860         }
 861         else {
 862             push @{ $flags->{plugins} }, $_;
 863         }
 864     }
 865
 866     $class->setup_home( delete $flags->{home} );
 867
 868     $class->setup_log( delete $flags->{log} );
 869     $class->setup_plugins( delete $flags->{plugins} );
 870     $class->setup_dispatcher( delete $flags->{dispatcher} );
 871     $class->setup_engine( delete $flags->{engine} );
 872     $class->setup_stats( delete $flags->{stats} );
 873
 874     for my $flag ( sort keys %{$flags} ) {
 875
 876         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 877             &$code( $class, delete $flags->{$flag} );
 878         }
 879         else {
 880             $class->log->warn(qq/Unknown flag "$flag"/);
 881         }
 882     }
 883
 884     eval { require Catalyst::Devel; };
 885     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 886         $class->log->warn(<<"EOF");
 887 You are running an old script!
 888
 889   Please update by running (this will overwrite existing files):
 890     catalyst.pl -force -scripts $class
 891
 892   or (this will not overwrite existing files):
 893     catalyst.pl -scripts $class
 894
 895 EOF
 896     }
 897
 898     if ( $class->debug ) {
 899         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 900
 901         if (@plugins) {
 902             my $t = Text::SimpleTable->new(74);
 903             $t->row($_) for @plugins;
 904             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 905         }
 906
 907         my $dispatcher = $class->dispatcher;
 908         my $engine     = $class->engine;
 909         my $home       = $class->config->{home};
 910
 911         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 912         $class->log->debug(qq/Loaded engine "$engine"/);
 913
 914         $home
 915           ? ( -d $home )
 916           ? $class->log->debug(qq/Found home "$home"/)
 917           : $class->log->debug(qq/Home "$home" doesn't exist/)
 918           : $class->log->debug(q/Couldn't find home/);
 919     }
 920
 921     # Call plugins setup
 922     {
 923         no warnings qw/redefine/;
 924         local *setup = sub { };
 925         $class->setup;
 926     }
 927
 928     # Initialize our data structure
 929     $class->components( {} );
 930
 931     $class->setup_components;
 932
 933     if ( $class->debug ) {
 934         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 935         for my $comp ( sort keys %{ $class->components } ) {
 936             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 937             $t->row( $comp, $type );
 938         }
 939         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 940           if ( keys %{ $class->components } );
 941     }
 942
 943     # Add our self to components, since we are also a component
 944     $class->components->{$class} = $class;
 945
 946     $class->setup_actions;
 947
 948     if ( $class->debug ) {
 949         my $name = $class->config->{name} || 'Application';
 950         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 951     }
 952     $class->log->_flush() if $class->log->can('_flush');
 953
 954     $class->setup_finished(1);
 955 }
 956
 957 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
 958
 959 =head2 $c->uri_for( $path, @args?, \%query_values? )
 960
 961 =over
 962
 963 =item $action
 964
 965 A Catalyst::Action object representing the Catalyst action you want to
 966 create a URI for. To get one for an action in the current controller,
 967 use C<< $c->action('someactionname') >>. To get one from different
 968 controller, fetch the controller using C<< $c->controller() >>, then
 969 call C<action_for> on it.
 970
 971 This method must be used to create URIs for
 972 L<Catalyst::DispatchType::Chained> actions.
 973
 974 =item $path
 975
 976 The actual path you wish to create a URI for, this is a public path,
 977 not a private action path.
 978
 979 =item \@captures
 980
 981 If provided, this argument is used to insert values into a I<Chained>
 982 action in the parts where the definitions contain I<CaptureArgs>. If
 983 not needed, leave out this argument.
 984
 985 =item @args
 986
 987 If provided, this is used as a list of further path sections to append
 988 to the URI. In a I<Chained> action these are the equivalent to the
 989 endpoint L<Args>.
 990
 991 =item \%query_values
 992
 993 If provided, the query_values hashref is used to add query parameters
 994 to the URI, with the keys as the names, and the values as the values.
 995
 996 =back
 997
 998 Returns a L<URI> object.
 999
1000   ## Ex 1: a path with args and a query parameter
1001   $c->uri_for('user/list', 'short', { page => 2});
1002   ## -> ($c->req->base is 'http://localhost:3000/'
1003   URI->new('http://localhost:3000/user/list/short?page=2)
1004
1005   ## Ex 2: a chained view action that captures the user id
1006   ## In controller:
1007   sub user : Chained('/'): PathPart('myuser'): CaptureArgs(1) {}
1008   sub viewuser : Chained('user'): PathPart('view') {}
1009
1010   ## In uri creating code:
1011   my $uaction = $c->controller('Users')->action_for('viewuser');
1012   $c->uri_for($uaction, [ 42 ]);
1013   ## outputs:
1014   URI->new('http://localhost:3000/myuser/42/view')
1015
1016 Creates a URI object using C<< $c->request->base >> and a path. If an
1017 Action object is given instead of a path, the path is constructed
1018 using C<< $c->dispatcher->uri_for_action >> and passing it the
1019 @captures array, if supplied.
1020
1021 If any query parameters are passed they are added to the end of the
1022 URI in the usual way.
1023
1024 Note that uri_for is destructive to the passed query values hashref.
1025 Subsequent calls with the same hashref may have unintended results.
1026
1027 =cut
1028
1029 sub uri_for {
1030     my ( $c, $path, @args ) = @_;
1031
1032     if ( Scalar::Util::blessed($path) ) { # action object
1033         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1034                          ? shift(@args)
1035                          : [] );
1036         $path = $c->dispatcher->uri_for_action($path, $captures);
1037         return undef unless defined($path);
1038         $path = '/' if $path eq '';
1039     }
1040
1041     undef($path) if (defined $path && $path eq '');
1042
1043     my $params =
1044       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1045
1046     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1047     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1048
1049     unshift(@args, $path);
1050
1051     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1052         my $namespace = $c->namespace;
1053         if (defined $path) { # cheesy hack to handle path '../foo'
1054            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1055         }
1056         unshift(@args, $namespace || '');
1057     }
1058
1059     # join args with '/', or a blank string
1060     my $args = join('/', grep { defined($_) } @args);
1061     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1062     $args =~ s!^/!!;
1063     my $base = $c->req->base;
1064     my $class = ref($base);
1065     $base =~ s{(?<!/)$}{/};
1066
1067     my $query = '';
1068
1069     if (my @keys = keys %$params) {
1070       # somewhat lifted from URI::_query's query_form
1071       $query = '?'.join('&', map {
1072           my $val = $params->{$_};
1073           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1074           s/ /+/g;
1075           my $key = $_;
1076           $val = '' unless defined $val;
1077           (map {
1078               $_ = "$_";
1079               utf8::encode( $_ ) if utf8::is_utf8($_);
1080               # using the URI::Escape pattern here so utf8 chars survive
1081               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1082               s/ /+/g;
1083               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1084       } @keys);
1085     }
1086
1087     my $res = bless(\"${base}${args}${query}", $class);
1088     $res;
1089 }
1090
1091 =head2 $c->welcome_message
1092
1093 Returns the Catalyst welcome HTML page.
1094
1095 =cut
1096
1097 sub welcome_message {
1098     my $c      = shift;
1099     my $name   = $c->config->{name};
1100     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1101     my $prefix = Catalyst::Utils::appprefix( ref $c );
1102     $c->response->content_type('text/html; charset=utf-8');
1103     return <<"EOF";
1104 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1105     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1106 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1107     <head>
1108     <meta http-equiv="Content-Language" content="en" />
1109     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1110         <title>$name on Catalyst $VERSION</title>
1111         <style type="text/css">
1112             body {
1113                 color: #000;
1114                 background-color: #eee;
1115             }
1116             div#content {
1117                 width: 640px;
1118                 margin-left: auto;
1119                 margin-right: auto;
1120                 margin-top: 10px;
1121                 margin-bottom: 10px;
1122                 text-align: left;
1123                 background-color: #ccc;
1124                 border: 1px solid #aaa;
1125             }
1126             p, h1, h2 {
1127                 margin-left: 20px;
1128                 margin-right: 20px;
1129                 font-family: verdana, tahoma, sans-serif;
1130             }
1131             a {
1132                 font-family: verdana, tahoma, sans-serif;
1133             }
1134             :link, :visited {
1135                     text-decoration: none;
1136                     color: #b00;
1137                     border-bottom: 1px dotted #bbb;
1138             }
1139             :link:hover, :visited:hover {
1140                     color: #555;
1141             }
1142             div#topbar {
1143                 margin: 0px;
1144             }
1145             pre {
1146                 margin: 10px;
1147                 padding: 8px;
1148             }
1149             div#answers {
1150                 padding: 8px;
1151                 margin: 10px;
1152                 background-color: #fff;
1153                 border: 1px solid #aaa;
1154             }
1155             h1 {
1156                 font-size: 0.9em;
1157                 font-weight: normal;
1158                 text-align: center;
1159             }
1160             h2 {
1161                 font-size: 1.0em;
1162             }
1163             p {
1164                 font-size: 0.9em;
1165             }
1166             p img {
1167                 float: right;
1168                 margin-left: 10px;
1169             }
1170             span#appname {
1171                 font-weight: bold;
1172                 font-size: 1.6em;
1173             }
1174         </style>
1175     </head>
1176     <body>
1177         <div id="content">
1178             <div id="topbar">
1179                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1180                     $VERSION</h1>
1181              </div>
1182              <div id="answers">
1183                  <p>
1184                  <img src="$logo" alt="Catalyst Logo" />
1185                  </p>
1186                  <p>Welcome to the  world of Catalyst.
1187                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1188                     framework will make web development something you had
1189                     never expected it to be: Fun, rewarding, and quick.</p>
1190                  <h2>What to do now?</h2>
1191                  <p>That really depends  on what <b>you</b> want to do.
1192                     We do, however, provide you with a few starting points.</p>
1193                  <p>If you want to jump right into web development with Catalyst
1194                     you might want to start with a tutorial.</p>
1195 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1196 </pre>
1197 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1198 <pre>
1199 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1200 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1201 </code></pre>
1202                  <h2>What to do next?</h2>
1203                  <p>Next it's time to write an actual application. Use the
1204                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1205                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1206                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1207                     they can save you a lot of work.</p>
1208                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1209                     <p>Also, be sure to check out the vast and growing
1210                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1211                     you are likely to find what you need there.
1212                     </p>
1213
1214                  <h2>Need help?</h2>
1215                  <p>Catalyst has a very active community. Here are the main places to
1216                     get in touch with us.</p>
1217                  <ul>
1218                      <li>
1219                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1220                      </li>
1221                      <li>
1222                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1223                      </li>
1224                      <li>
1225                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1226                      </li>
1227                  </ul>
1228                  <h2>In conclusion</h2>
1229                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1230                     as we enjoyed making it. Please contact us if you have ideas
1231                     for improvement or other feedback.</p>
1232              </div>
1233          </div>
1234     </body>
1235 </html>
1236 EOF
1237 }
1238
1239 =head1 INTERNAL METHODS
1240
1241 These methods are not meant to be used by end users.
1242
1243 =head2 $c->components
1244
1245 Returns a hash of components.
1246
1247 =head2 $c->context_class
1248
1249 Returns or sets the context class.
1250
1251 =head2 $c->counter
1252
1253 Returns a hashref containing coderefs and execution counts (needed for
1254 deep recursion detection).
1255
1256 =head2 $c->depth
1257
1258 Returns the number of actions on the current internal execution stack.
1259
1260 =head2 $c->dispatch
1261
1262 Dispatches a request to actions.
1263
1264 =cut
1265
1266 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1267
1268 =head2 $c->dispatcher_class
1269
1270 Returns or sets the dispatcher class.
1271
1272 =head2 $c->dump_these
1273
1274 Returns a list of 2-element array references (name, structure) pairs
1275 that will be dumped on the error page in debug mode.
1276
1277 =cut
1278
1279 sub dump_these {
1280     my $c = shift;
1281     [ Request => $c->req ],
1282     [ Response => $c->res ],
1283     [ Stash => $c->stash ],
1284     [ Config => $c->config ];
1285 }
1286
1287 =head2 $c->engine_class
1288
1289 Returns or sets the engine class.
1290
1291 =head2 $c->execute( $class, $coderef )
1292
1293 Execute a coderef in given class and catch exceptions. Errors are available
1294 via $c->error.
1295
1296 =cut
1297
1298 sub execute {
1299     my ( $c, $class, $code ) = @_;
1300     $class = $c->component($class) || $class;
1301     $c->state(0);
1302
1303     if ( $c->depth >= $RECURSION ) {
1304         my $action = "$code";
1305         $action = "/$action" unless $action =~ /->/;
1306         my $error = qq/Deep recursion detected calling "$action"/;
1307         $c->log->error($error);
1308         $c->error($error);
1309         $c->state(0);
1310         return $c->state;
1311     }
1312
1313     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1314
1315     push( @{ $c->stack }, $code );
1316
1317     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1318
1319     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1320
1321     my $last = pop( @{ $c->stack } );
1322
1323     if ( my $error = $@ ) {
1324         if ( !ref($error) and $error eq $DETACH ) {
1325             die $DETACH if($c->depth > 1);
1326         }
1327         else {
1328             unless ( ref $error ) {
1329                 no warnings 'uninitialized';
1330                 chomp $error;
1331                 my $class = $last->class;
1332                 my $name  = $last->name;
1333                 $error = qq/Caught exception in $class->$name "$error"/;
1334             }
1335             $c->error($error);
1336             $c->state(0);
1337         }
1338     }
1339     return $c->state;
1340 }
1341
1342 sub _stats_start_execute {
1343     my ( $c, $code ) = @_;
1344
1345     return if ( ( $code->name =~ /^_.*/ )
1346         && ( !$c->config->{show_internal_actions} ) );
1347
1348     $c->counter->{"$code"}++;
1349
1350     my $action = "$code";
1351     $action = "/$action" unless $action =~ /->/;
1352
1353     # determine if the call was the result of a forward
1354     # this is done by walking up the call stack and looking for a calling
1355     # sub of Catalyst::forward before the eval
1356     my $callsub = q{};
1357     for my $index ( 2 .. 11 ) {
1358         last
1359         if ( ( caller($index) )[0] eq 'Catalyst'
1360             && ( caller($index) )[3] eq '(eval)' );
1361
1362         if ( ( caller($index) )[3] =~ /forward$/ ) {
1363             $callsub = ( caller($index) )[3];
1364             $action  = "-> $action";
1365             last;
1366         }
1367     }
1368
1369     my $uid = "$code" . $c->counter->{"$code"};
1370
1371     # is this a root-level call or a forwarded call?
1372     if ( $callsub =~ /forward$/ ) {
1373
1374         # forward, locate the caller
1375         if ( my $parent = $c->stack->[-1] ) {
1376             $c->stats->profile(
1377                 begin  => $action,
1378                 parent => "$parent" . $c->counter->{"$parent"},
1379                 uid    => $uid,
1380             );
1381         }
1382         else {
1383
1384             # forward with no caller may come from a plugin
1385             $c->stats->profile(
1386                 begin => $action,
1387                 uid   => $uid,
1388             );
1389         }
1390     }
1391     else {
1392
1393         # root-level call
1394         $c->stats->profile(
1395             begin => $action,
1396             uid   => $uid,
1397         );
1398     }
1399     return $action;
1400
1401 }
1402
1403 sub _stats_finish_execute {
1404     my ( $c, $info ) = @_;
1405     $c->stats->profile( end => $info );
1406 }
1407
1408 =head2 $c->_localize_fields( sub { }, \%keys );
1409
1410 =cut
1411
1412 sub _localize_fields {
1413     my ( $c, $localized, $code ) = ( @_ );
1414
1415     my $request = delete $localized->{request} || {};
1416     my $response = delete $localized->{response} || {};
1417
1418     local @{ $c }{ keys %$localized } = values %$localized;
1419     local @{ $c->request }{ keys %$request } = values %$request;
1420     local @{ $c->response }{ keys %$response } = values %$response;
1421
1422     $code->();
1423 }
1424
1425 =head2 $c->finalize
1426
1427 Finalizes the request.
1428
1429 =cut
1430
1431 sub finalize {
1432     my $c = shift;
1433
1434     for my $error ( @{ $c->error } ) {
1435         $c->log->error($error);
1436     }
1437
1438     # Allow engine to handle finalize flow (for POE)
1439     if ( $c->engine->can('finalize') ) {
1440         $c->engine->finalize($c);
1441     }
1442     else {
1443
1444         $c->finalize_uploads;
1445
1446         # Error
1447         if ( $#{ $c->error } >= 0 ) {
1448             $c->finalize_error;
1449         }
1450
1451         $c->finalize_headers;
1452
1453         # HEAD request
1454         if ( $c->request->method eq 'HEAD' ) {
1455             $c->response->body('');
1456         }
1457
1458         $c->finalize_body;
1459     }
1460
1461     if ($c->use_stats) {
1462         my $elapsed = sprintf '%f', $c->stats->elapsed;
1463         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1464         $c->log->info(
1465             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1466     }
1467
1468     return $c->response->status;
1469 }
1470
1471 =head2 $c->finalize_body
1472
1473 Finalizes body.
1474
1475 =cut
1476
1477 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1478
1479 =head2 $c->finalize_cookies
1480
1481 Finalizes cookies.
1482
1483 =cut
1484
1485 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1486
1487 =head2 $c->finalize_error
1488
1489 Finalizes error.
1490
1491 =cut
1492
1493 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1494
1495 =head2 $c->finalize_headers
1496
1497 Finalizes headers.
1498
1499 =cut
1500
1501 sub finalize_headers {
1502     my $c = shift;
1503
1504     # Check if we already finalized headers
1505     return if $c->response->{_finalized_headers};
1506
1507     # Handle redirects
1508     if ( my $location = $c->response->redirect ) {
1509         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1510         $c->response->header( Location => $location );
1511
1512         if ( !$c->response->body ) {
1513             # Add a default body if none is already present
1514             $c->response->body(
1515                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1516             );
1517         }
1518     }
1519
1520     # Content-Length
1521     if ( $c->response->body && !$c->response->content_length ) {
1522
1523         # get the length from a filehandle
1524         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1525         {
1526             my $stat = stat $c->response->body;
1527             if ( $stat && $stat->size > 0 ) {
1528                 $c->response->content_length( $stat->size );
1529             }
1530             else {
1531                 $c->log->warn('Serving filehandle without a content-length');
1532             }
1533         }
1534         else {
1535             # everything should be bytes at this point, but just in case
1536             $c->response->content_length( bytes::length( $c->response->body ) );
1537         }
1538     }
1539
1540     # Errors
1541     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1542         $c->response->headers->remove_header("Content-Length");
1543         $c->response->body('');
1544     }
1545
1546     $c->finalize_cookies;
1547
1548     $c->engine->finalize_headers( $c, @_ );
1549
1550     # Done
1551     $c->response->{_finalized_headers} = 1;
1552 }
1553
1554 =head2 $c->finalize_output
1555
1556 An alias for finalize_body.
1557
1558 =head2 $c->finalize_read
1559
1560 Finalizes the input after reading is complete.
1561
1562 =cut
1563
1564 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1565
1566 =head2 $c->finalize_uploads
1567
1568 Finalizes uploads. Cleans up any temporary files.
1569
1570 =cut
1571
1572 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1573
1574 =head2 $c->get_action( $action, $namespace )
1575
1576 Gets an action in a given namespace.
1577
1578 =cut
1579
1580 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1581
1582 =head2 $c->get_actions( $action, $namespace )
1583
1584 Gets all actions of a given name in a namespace and all parent
1585 namespaces.
1586
1587 =cut
1588
1589 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1590
1591 =head2 $c->handle_request( $class, @arguments )
1592
1593 Called to handle each HTTP request.
1594
1595 =cut
1596
1597 sub handle_request {
1598     my ( $class, @arguments ) = @_;
1599
1600     # Always expect worst case!
1601     my $status = -1;
1602     eval {
1603         if ($class->debug) {
1604             my $secs = time - $START || 1;
1605             my $av = sprintf '%.3f', $COUNT / $secs;
1606             my $time = localtime time;
1607             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1608         }
1609
1610         my $c = $class->prepare(@arguments);
1611         $c->dispatch;
1612         $status = $c->finalize;
1613     };
1614
1615     if ( my $error = $@ ) {
1616         chomp $error;
1617         $class->log->error(qq/Caught exception in engine "$error"/);
1618     }
1619
1620     $COUNT++;
1621     $class->log->_flush() if $class->log->can('_flush');
1622     return $status;
1623 }
1624
1625 =head2 $c->prepare( @arguments )
1626
1627 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1628 etc.).
1629
1630 =cut
1631
1632 sub prepare {
1633     my ( $class, @arguments ) = @_;
1634
1635     $class->context_class( ref $class || $class ) unless $class->context_class;
1636     my $c = $class->context_class->new(
1637         {
1638             counter => {},
1639             stack   => [],
1640             request => $class->request_class->new(
1641                 {
1642                     arguments        => [],
1643                     body_parameters  => {},
1644                     cookies          => {},
1645                     headers          => HTTP::Headers->new,
1646                     parameters       => {},
1647                     query_parameters => {},
1648                     secure           => 0,
1649                     captures         => [],
1650                     uploads          => {}
1651                 }
1652             ),
1653             response => $class->response_class->new(
1654                 {
1655                     body    => '',
1656                     cookies => {},
1657                     headers => HTTP::Headers->new(),
1658                     status  => 200
1659                 }
1660             ),
1661             stash => {},
1662             state => 0
1663         }
1664     );
1665
1666     $c->stats($class->stats_class->new)->enable($c->use_stats);
1667     if ( $c->debug ) {
1668         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1669     }
1670
1671     # For on-demand data
1672     $c->request->{_context}  = $c;
1673     $c->response->{_context} = $c;
1674     weaken( $c->request->{_context} );
1675     weaken( $c->response->{_context} );
1676
1677     # Allow engine to direct the prepare flow (for POE)
1678     if ( $c->engine->can('prepare') ) {
1679         $c->engine->prepare( $c, @arguments );
1680     }
1681     else {
1682         $c->prepare_request(@arguments);
1683         $c->prepare_connection;
1684         $c->prepare_query_parameters;
1685         $c->prepare_headers;
1686         $c->prepare_cookies;
1687         $c->prepare_path;
1688
1689         # Prepare the body for reading, either by prepare_body
1690         # or the user, if they are using $c->read
1691         $c->prepare_read;
1692
1693         # Parse the body unless the user wants it on-demand
1694         unless ( $c->config->{parse_on_demand} ) {
1695             $c->prepare_body;
1696         }
1697     }
1698
1699     my $method  = $c->req->method  || '';
1700     my $path    = $c->req->path;
1701     $path       = '/' unless length $path;
1702     my $address = $c->req->address || '';
1703
1704     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1705       if $c->debug;
1706
1707     $c->prepare_action;
1708
1709     return $c;
1710 }
1711
1712 =head2 $c->prepare_action
1713
1714 Prepares action. See L<Catalyst::Dispatcher>.
1715
1716 =cut
1717
1718 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1719
1720 =head2 $c->prepare_body
1721
1722 Prepares message body.
1723
1724 =cut
1725
1726 sub prepare_body {
1727     my $c = shift;
1728
1729     # Do we run for the first time?
1730     return if defined $c->request->{_body};
1731
1732     # Initialize on-demand data
1733     $c->engine->prepare_body( $c, @_ );
1734     $c->prepare_parameters;
1735     $c->prepare_uploads;
1736
1737     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1738         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1739         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1740             my $param = $c->req->body_parameters->{$key};
1741             my $value = defined($param) ? $param : '';
1742             $t->row( $key,
1743                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1744         }
1745         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1746     }
1747 }
1748
1749 =head2 $c->prepare_body_chunk( $chunk )
1750
1751 Prepares a chunk of data before sending it to L<HTTP::Body>.
1752
1753 See L<Catalyst::Engine>.
1754
1755 =cut
1756
1757 sub prepare_body_chunk {
1758     my $c = shift;
1759     $c->engine->prepare_body_chunk( $c, @_ );
1760 }
1761
1762 =head2 $c->prepare_body_parameters
1763
1764 Prepares body parameters.
1765
1766 =cut
1767
1768 sub prepare_body_parameters {
1769     my $c = shift;
1770     $c->engine->prepare_body_parameters( $c, @_ );
1771 }
1772
1773 =head2 $c->prepare_connection
1774
1775 Prepares connection.
1776
1777 =cut
1778
1779 sub prepare_connection {
1780     my $c = shift;
1781     $c->engine->prepare_connection( $c, @_ );
1782 }
1783
1784 =head2 $c->prepare_cookies
1785
1786 Prepares cookies.
1787
1788 =cut
1789
1790 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1791
1792 =head2 $c->prepare_headers
1793
1794 Prepares headers.
1795
1796 =cut
1797
1798 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1799
1800 =head2 $c->prepare_parameters
1801
1802 Prepares parameters.
1803
1804 =cut
1805
1806 sub prepare_parameters {
1807     my $c = shift;
1808     $c->prepare_body_parameters;
1809     $c->engine->prepare_parameters( $c, @_ );
1810 }
1811
1812 =head2 $c->prepare_path
1813
1814 Prepares path and base.
1815
1816 =cut
1817
1818 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1819
1820 =head2 $c->prepare_query_parameters
1821
1822 Prepares query parameters.
1823
1824 =cut
1825
1826 sub prepare_query_parameters {
1827     my $c = shift;
1828
1829     $c->engine->prepare_query_parameters( $c, @_ );
1830
1831     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1832         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1833         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1834             my $param = $c->req->query_parameters->{$key};
1835             my $value = defined($param) ? $param : '';
1836             $t->row( $key,
1837                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1838         }
1839         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1840     }
1841 }
1842
1843 =head2 $c->prepare_read
1844
1845 Prepares the input for reading.
1846
1847 =cut
1848
1849 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1850
1851 =head2 $c->prepare_request
1852
1853 Prepares the engine request.
1854
1855 =cut
1856
1857 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1858
1859 =head2 $c->prepare_uploads
1860
1861 Prepares uploads.
1862
1863 =cut
1864
1865 sub prepare_uploads {
1866     my $c = shift;
1867
1868     $c->engine->prepare_uploads( $c, @_ );
1869
1870     if ( $c->debug && keys %{ $c->request->uploads } ) {
1871         my $t = Text::SimpleTable->new(
1872             [ 12, 'Parameter' ],
1873             [ 26, 'Filename' ],
1874             [ 18, 'Type' ],
1875             [ 9,  'Size' ]
1876         );
1877         for my $key ( sort keys %{ $c->request->uploads } ) {
1878             my $upload = $c->request->uploads->{$key};
1879             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1880                 $t->row( $key, $u->filename, $u->type, $u->size );
1881             }
1882         }
1883         $c->log->debug( "File Uploads are:\n" . $t->draw );
1884     }
1885 }
1886
1887 =head2 $c->prepare_write
1888
1889 Prepares the output for writing.
1890
1891 =cut
1892
1893 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1894
1895 =head2 $c->request_class
1896
1897 Returns or sets the request class.
1898
1899 =head2 $c->response_class
1900
1901 Returns or sets the response class.
1902
1903 =head2 $c->read( [$maxlength] )
1904
1905 Reads a chunk of data from the request body. This method is designed to
1906 be used in a while loop, reading C<$maxlength> bytes on every call.
1907 C<$maxlength> defaults to the size of the request if not specified.
1908
1909 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1910 directly.
1911
1912 Warning: If you use read(), Catalyst will not process the body,
1913 so you will not be able to access POST parameters or file uploads via
1914 $c->request.  You must handle all body parsing yourself.
1915
1916 =cut
1917
1918 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1919
1920 =head2 $c->run
1921
1922 Starts the engine.
1923
1924 =cut
1925
1926 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1927
1928 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1929
1930 Sets an action in a given namespace.
1931
1932 =cut
1933
1934 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1935
1936 =head2 $c->setup_actions($component)
1937
1938 Sets up actions for a component.
1939
1940 =cut
1941
1942 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1943
1944 =head2 $c->setup_components
1945
1946 Sets up components. Specify a C<setup_components> config option to pass
1947 additional options directly to L<Module::Pluggable>. To add additional
1948 search paths, specify a key named C<search_extra> as an array
1949 reference. Items in the array beginning with C<::> will have the
1950 application class name prepended to them.
1951
1952 All components found will also have any
1953 L<Devel::InnerPackage|inner packages> loaded and set up as components.
1954 Note, that modules which are B<not> an I<inner package> of the main
1955 file namespace loaded will not be instantiated as components.
1956
1957 =cut
1958
1959 sub setup_components {
1960     my $class = shift;
1961
1962     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1963     my $config  = $class->config->{ setup_components };
1964     my $extra   = delete $config->{ search_extra } || [];
1965
1966     push @paths, @$extra;
1967
1968     my $locator = Module::Pluggable::Object->new(
1969         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1970         %$config
1971     );
1972
1973     my @comps = sort { length $a <=> length $b } $locator->plugins;
1974     my %comps = map { $_ => 1 } @comps;
1975
1976     for my $component ( @comps ) {
1977
1978         # We pass ignore_loaded here so that overlay files for (e.g.)
1979         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1980         # we know M::P::O found a file on disk so this is safe
1981
1982         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1983
1984         my $module  = $class->setup_component( $component );
1985         my %modules = (
1986             $component => $module,
1987             map {
1988                 $_ => $class->setup_component( $_ )
1989             } grep {
1990               not exists $comps{$_}
1991             } Devel::InnerPackage::list_packages( $component )
1992         );
1993
1994         for my $key ( keys %modules ) {
1995             $class->components->{ $key } = $modules{ $key };
1996         }
1997     }
1998 }
1999
2000 =head2 $c->setup_component
2001
2002 =cut
2003
2004 sub setup_component {
2005     my( $class, $component ) = @_;
2006
2007     unless ( $component->can( 'COMPONENT' ) ) {
2008         return $component;
2009     }
2010
2011     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2012     my $config = $class->config->{ $suffix } || {};
2013
2014     my $instance = eval { $component->COMPONENT( $class, $config ); };
2015
2016     if ( my $error = $@ ) {
2017         chomp $error;
2018         Catalyst::Exception->throw(
2019             message => qq/Couldn't instantiate component "$component", "$error"/
2020         );
2021     }
2022
2023     Catalyst::Exception->throw(
2024         message =>
2025         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2026     ) unless eval { $instance->can( 'can' ) };
2027
2028     return $instance;
2029 }
2030
2031 =head2 $c->setup_dispatcher
2032
2033 Sets up dispatcher.
2034
2035 =cut
2036
2037 sub setup_dispatcher {
2038     my ( $class, $dispatcher ) = @_;
2039
2040     if ($dispatcher) {
2041         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2042     }
2043
2044     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2045         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2046     }
2047
2048     unless ($dispatcher) {
2049         $dispatcher = $class->dispatcher_class;
2050     }
2051
2052     unless (Class::Inspector->loaded($dispatcher)) {
2053         require Class::Inspector->filename($dispatcher);
2054     }
2055
2056     # dispatcher instance
2057     $class->dispatcher( $dispatcher->new );
2058 }
2059
2060 =head2 $c->setup_engine
2061
2062 Sets up engine.
2063
2064 =cut
2065
2066 sub setup_engine {
2067     my ( $class, $engine ) = @_;
2068
2069     if ($engine) {
2070         $engine = 'Catalyst::Engine::' . $engine;
2071     }
2072
2073     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2074         $engine = 'Catalyst::Engine::' . $env;
2075     }
2076
2077     if ( $ENV{MOD_PERL} ) {
2078
2079         # create the apache method
2080         {
2081             no strict 'refs';
2082             *{"$class\::apache"} = sub { shift->engine->apache };
2083         }
2084
2085         my ( $software, $version ) =
2086           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2087
2088         $version =~ s/_//g;
2089         $version =~ s/(\.[^.]+)\./$1/g;
2090
2091         if ( $software eq 'mod_perl' ) {
2092
2093             if ( !$engine ) {
2094
2095                 if ( $version >= 1.99922 ) {
2096                     $engine = 'Catalyst::Engine::Apache2::MP20';
2097                 }
2098
2099                 elsif ( $version >= 1.9901 ) {
2100                     $engine = 'Catalyst::Engine::Apache2::MP19';
2101                 }
2102
2103                 elsif ( $version >= 1.24 ) {
2104                     $engine = 'Catalyst::Engine::Apache::MP13';
2105                 }
2106
2107                 else {
2108                     Catalyst::Exception->throw( message =>
2109                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2110                 }
2111
2112             }
2113
2114             # install the correct mod_perl handler
2115             if ( $version >= 1.9901 ) {
2116                 *handler = sub  : method {
2117                     shift->handle_request(@_);
2118                 };
2119             }
2120             else {
2121                 *handler = sub ($$) { shift->handle_request(@_) };
2122             }
2123
2124         }
2125
2126         elsif ( $software eq 'Zeus-Perl' ) {
2127             $engine = 'Catalyst::Engine::Zeus';
2128         }
2129
2130         else {
2131             Catalyst::Exception->throw(
2132                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2133         }
2134     }
2135
2136     unless ($engine) {
2137         $engine = $class->engine_class;
2138     }
2139
2140     unless (Class::Inspector->loaded($engine)) {
2141         require Class::Inspector->filename($engine);
2142     }
2143
2144     # check for old engines that are no longer compatible
2145     my $old_engine;
2146     if ( $engine->isa('Catalyst::Engine::Apache')
2147         && !Catalyst::Engine::Apache->VERSION )
2148     {
2149         $old_engine = 1;
2150     }
2151
2152     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2153         && Catalyst::Engine::Server->VERSION le '0.02' )
2154     {
2155         $old_engine = 1;
2156     }
2157
2158     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2159         && $engine->VERSION eq '0.01' )
2160     {
2161         $old_engine = 1;
2162     }
2163
2164     elsif ($engine->isa('Catalyst::Engine::Zeus')
2165         && $engine->VERSION eq '0.01' )
2166     {
2167         $old_engine = 1;
2168     }
2169
2170     if ($old_engine) {
2171         Catalyst::Exception->throw( message =>
2172               qq/Engine "$engine" is not supported by this version of Catalyst/
2173         );
2174     }
2175
2176     # engine instance
2177     $class->engine( $engine->new );
2178 }
2179
2180 =head2 $c->setup_home
2181
2182 Sets up the home directory.
2183
2184 =cut
2185
2186 sub setup_home {
2187     my ( $class, $home ) = @_;
2188
2189     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2190         $home = $env;
2191     }
2192
2193     unless ($home) {
2194         $home = Catalyst::Utils::home($class);
2195     }
2196
2197     if ($home) {
2198         $class->config->{home} ||= $home;
2199         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2200     }
2201 }
2202
2203 =head2 $c->setup_log
2204
2205 Sets up log.
2206
2207 =cut
2208
2209 sub setup_log {
2210     my ( $class, $debug ) = @_;
2211
2212     unless ( $class->log ) {
2213         $class->log( Catalyst::Log->new );
2214     }
2215
2216     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2217     if ( defined($env_debug) ? $env_debug : $debug ) {
2218         no strict 'refs';
2219         *{"$class\::debug"} = sub { 1 };
2220         $class->log->debug('Debug messages enabled');
2221     }
2222 }
2223
2224 =head2 $c->setup_plugins
2225
2226 Sets up plugins.
2227
2228 =cut
2229
2230 =head2 $c->setup_stats
2231
2232 Sets up timing statistics class.
2233
2234 =cut
2235
2236 sub setup_stats {
2237     my ( $class, $stats ) = @_;
2238
2239     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2240
2241     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2242     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2243         no strict 'refs';
2244         *{"$class\::use_stats"} = sub { 1 };
2245         $class->log->debug('Statistics enabled');
2246     }
2247 }
2248
2249
2250 =head2 $c->registered_plugins
2251
2252 Returns a sorted list of the plugins which have either been stated in the
2253 import list or which have been added via C<< MyApp->plugin(@args); >>.
2254
2255 If passed a given plugin name, it will report a boolean value indicating
2256 whether or not that plugin is loaded.  A fully qualified name is required if
2257 the plugin name does not begin with C<Catalyst::Plugin::>.
2258
2259  if ($c->registered_plugins('Some::Plugin')) {
2260      ...
2261  }
2262
2263 =cut
2264
2265 {
2266
2267     sub registered_plugins {
2268         my $proto = shift;
2269         return sort keys %{ $proto->_plugins } unless @_;
2270         my $plugin = shift;
2271         return 1 if exists $proto->_plugins->{$plugin};
2272         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2273     }
2274
2275     sub _register_plugin {
2276         my ( $proto, $plugin, $instant ) = @_;
2277         my $class = ref $proto || $proto;
2278
2279         # no ignore_loaded here, the plugin may already have been
2280         # defined in memory and we don't want to error on "no file" if so
2281
2282         Catalyst::Utils::ensure_class_loaded( $plugin );
2283
2284         $proto->_plugins->{$plugin} = 1;
2285         unless ($instant) {
2286             no strict 'refs';
2287             unshift @{"$class\::ISA"}, $plugin;
2288         }
2289         return $class;
2290     }
2291
2292     sub setup_plugins {
2293         my ( $class, $plugins ) = @_;
2294
2295         $class->_plugins( {} ) unless $class->_plugins;
2296         $plugins ||= [];
2297         for my $plugin ( reverse @$plugins ) {
2298
2299             unless ( $plugin =~ s/\A\+// ) {
2300                 $plugin = "Catalyst::Plugin::$plugin";
2301             }
2302
2303             $class->_register_plugin($plugin);
2304         }
2305     }
2306 }
2307
2308 =head2 $c->stack
2309
2310 Returns an arrayref of the internal execution stack (actions that are
2311 currently executing).
2312
2313 =head2 $c->stats_class
2314
2315 Returns or sets the stats (timing statistics) class.
2316
2317 =head2 $c->use_stats
2318
2319 Returns 1 when stats collection is enabled.  Stats collection is enabled
2320 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2321 environment variable is set.
2322
2323 Note that this is a static method, not an accessor and should be overloaded
2324 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2325
2326 =cut
2327
2328 sub use_stats { 0 }
2329
2330
2331 =head2 $c->write( $data )
2332
2333 Writes $data to the output stream. When using this method directly, you
2334 will need to manually set the C<Content-Length> header to the length of
2335 your output data, if known.
2336
2337 =cut
2338
2339 sub write {
2340     my $c = shift;
2341
2342     # Finalize headers if someone manually writes output
2343     $c->finalize_headers;
2344
2345     return $c->engine->write( $c, @_ );
2346 }
2347
2348 =head2 version
2349
2350 Returns the Catalyst version number. Mostly useful for "powered by"
2351 messages in template systems.
2352
2353 =cut
2354
2355 sub version { return $Catalyst::VERSION }
2356
2357 =head1 INTERNAL ACTIONS
2358
2359 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2360 C<_ACTION>, and C<_END>. These are by default not shown in the private
2361 action table, but you can make them visible with a config parameter.
2362
2363     MyApp->config->{show_internal_actions} = 1;
2364
2365 =head1 CASE SENSITIVITY
2366
2367 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2368 mapped to C</foo/bar>. You can activate case sensitivity with a config
2369 parameter.
2370
2371     MyApp->config->{case_sensitive} = 1;
2372
2373 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2374
2375 =head1 ON-DEMAND PARSER
2376
2377 The request body is usually parsed at the beginning of a request,
2378 but if you want to handle input yourself, you can enable on-demand
2379 parsing with a config parameter.
2380
2381     MyApp->config->{parse_on_demand} = 1;
2382
2383 =head1 PROXY SUPPORT
2384
2385 Many production servers operate using the common double-server approach,
2386 with a lightweight frontend web server passing requests to a larger
2387 backend server. An application running on the backend server must deal
2388 with two problems: the remote user always appears to be C<127.0.0.1> and
2389 the server's hostname will appear to be C<localhost> regardless of the
2390 virtual host that the user connected through.
2391
2392 Catalyst will automatically detect this situation when you are running
2393 the frontend and backend servers on the same machine. The following
2394 changes are made to the request.
2395
2396     $c->req->address is set to the user's real IP address, as read from
2397     the HTTP X-Forwarded-For header.
2398
2399     The host value for $c->req->base and $c->req->uri is set to the real
2400     host, as read from the HTTP X-Forwarded-Host header.
2401
2402 Obviously, your web server must support these headers for this to work.
2403
2404 In a more complex server farm environment where you may have your
2405 frontend proxy server(s) on different machines, you will need to set a
2406 configuration option to tell Catalyst to read the proxied data from the
2407 headers.
2408
2409     MyApp->config->{using_frontend_proxy} = 1;
2410
2411 If you do not wish to use the proxy support at all, you may set:
2412
2413     MyApp->config->{ignore_frontend_proxy} = 1;
2414
2415 =head1 THREAD SAFETY
2416
2417 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2418 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2419 believe the Catalyst core to be thread-safe.
2420
2421 If you plan to operate in a threaded environment, remember that all other
2422 modules you are using must also be thread-safe. Some modules, most notably
2423 L<DBD::SQLite>, are not thread-safe.
2424
2425 =head1 SUPPORT
2426
2427 IRC:
2428
2429     Join #catalyst on irc.perl.org.
2430
2431 Mailing Lists:
2432
2433     http://lists.rawmode.org/mailman/listinfo/catalyst
2434     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2435
2436 Web:
2437
2438     http://catalyst.perl.org
2439
2440 Wiki:
2441
2442     http://dev.catalyst.perl.org
2443
2444 =head1 SEE ALSO
2445
2446 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2447
2448 =head2 L<Catalyst::Manual> - The Catalyst Manual
2449
2450 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2451
2452 =head2 L<Catalyst::Engine> - Core engine
2453
2454 =head2 L<Catalyst::Log> - Log class.
2455
2456 =head2 L<Catalyst::Request> - Request object
2457
2458 =head2 L<Catalyst::Response> - Response object
2459
2460 =head2 L<Catalyst::Test> - The test suite.
2461
2462 =head1 PROJECT FOUNDER
2463
2464 sri: Sebastian Riedel <sri@cpan.org>
2465
2466 =head1 CONTRIBUTORS
2467
2468 abw: Andy Wardley
2469
2470 acme: Leon Brocard <leon@astray.com>
2471
2472 Andrew Bramble
2473
2474 Andrew Ford
2475
2476 Andrew Ruthven
2477
2478 andyg: Andy Grundman <andy@hybridized.org>
2479
2480 audreyt: Audrey Tang
2481
2482 bricas: Brian Cassidy <bricas@cpan.org>
2483
2484 chansen: Christian Hansen
2485
2486 chicks: Christopher Hicks
2487
2488 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2489
2490 Drew Taylor
2491
2492 esskar: Sascha Kiefer
2493
2494 fireartist: Carl Franks <cfranks@cpan.org>
2495
2496 gabb: Danijel Milicevic
2497
2498 Gary Ashton Jones
2499
2500 Geoff Richards
2501
2502 jcamacho: Juan Camacho
2503
2504 Jody Belka
2505
2506 Johan Lindstrom
2507
2508 jon: Jon Schutz <jjschutz@cpan.org>
2509
2510 marcus: Marcus Ramberg <mramberg@cpan.org>
2511
2512 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2513
2514 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2515
2516 mugwump: Sam Vilain
2517
2518 naughton: David Naughton
2519
2520 ningu: David Kamholz <dkamholz@cpan.org>
2521
2522 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2523
2524 numa: Dan Sully <daniel@cpan.org>
2525
2526 obra: Jesse Vincent
2527
2528 omega: Andreas Marienborg
2529
2530 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2531
2532 sky: Arthur Bergman
2533
2534 the_jester: Jesse Sheidlower
2535
2536 Ulf Edvinsson
2537
2538 willert: Sebastian Willert <willert@cpan.org>
2539
2540 =head1 LICENSE
2541
2542 This library is free software, you can redistribute it and/or modify it under
2543 the same terms as Perl itself.
2544
2545 =cut
2546
2547 1;