lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         $self->request_class->new($self->_build_request_constructor_args);
  67     },
  68     lazy => 1,
  69 );
  70 sub _build_request_constructor_args {
  71     my $self = shift;
  72     my %p = ( _log => $self->log );
  73     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  74     $p{data_handlers} = {$self->registered_data_handlers};
  75     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  76       if $self->config->{use_hash_multivalue_in_request};
  77     \%p;
  78 }
  79
  80 has response => (
  81     is => 'rw',
  82     default => sub {
  83         my $self = shift;
  84         $self->response_class->new($self->_build_response_constructor_args);
  85     },
  86     lazy => 1,
  87 );
  88 sub _build_response_constructor_args {
  89     return +{
  90       _log => $_[0]->log,
  91       encoding => $_[0]->encoding,
  92     };
  93 }
  94
  95 has namespace => (is => 'rw');
  96
  97 sub depth { scalar @{ shift->stack || [] }; }
  98 sub comp { shift->component(@_) }
  99
 100 sub req {
 101     my $self = shift; return $self->request(@_);
 102 }
 103 sub res {
 104     my $self = shift; return $self->response(@_);
 105 }
 106
 107 # For backwards compatibility
 108 sub finalize_output { shift->finalize_body(@_) };
 109
 110 # For statistics
 111 our $COUNT     = 1;
 112 our $START     = time;
 113 our $RECURSION = 1000;
 114 our $DETACH    = Catalyst::Exception::Detach->new;
 115 our $GO        = Catalyst::Exception::Go->new;
 116
 117 #I imagine that very few of these really need to be class variables. if any.
 118 #maybe we should just make them attributes with a default?
 119 __PACKAGE__->mk_classdata($_)
 120   for qw/components arguments dispatcher engine log dispatcher_class
 121   engine_loader context_class request_class response_class stats_class
 122   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 123   _data_handlers _encoding _encode_check/;
 124
 125 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 126 __PACKAGE__->request_class('Catalyst::Request');
 127 __PACKAGE__->response_class('Catalyst::Response');
 128 __PACKAGE__->stats_class('Catalyst::Stats');
 129 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 130
 131 # Remember to update this in Catalyst::Runtime as well!
 132 our $VERSION = '5.90079_002';
 133 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 134
 135 sub import {
 136     my ( $class, @arguments ) = @_;
 137
 138     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 139     # callers @ISA.
 140     return unless $class eq 'Catalyst';
 141
 142     my $caller = caller();
 143     return if $caller eq 'main';
 144
 145     my $meta = Moose::Meta::Class->initialize($caller);
 146     unless ( $caller->isa('Catalyst') ) {
 147         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 148         $meta->superclasses(@superclasses);
 149     }
 150     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 151     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 152
 153     unless( $meta->has_method('meta') ){
 154         if ($Moose::VERSION >= 1.15) {
 155             $meta->_add_meta_method('meta');
 156         }
 157         else {
 158             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 159         }
 160     }
 161
 162     $caller->arguments( [@arguments] );
 163     $caller->setup_home;
 164 }
 165
 166 sub _application { $_[0] }
 167
 168 =encoding UTF-8
 169
 170 =head1 NAME
 171
 172 Catalyst - The Elegant MVC Web Application Framework
 173
 174 =head1 SYNOPSIS
 175
 176 See the L<Catalyst::Manual> distribution for comprehensive
 177 documentation and tutorials.
 178
 179     # Install Catalyst::Devel for helpers and other development tools
 180     # use the helper to create a new application
 181     catalyst.pl MyApp
 182
 183     # add models, views, controllers
 184     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 185     script/myapp_create.pl view MyTemplate TT
 186     script/myapp_create.pl controller Search
 187
 188     # built in testserver -- use -r to restart automatically on changes
 189     # --help to see all available options
 190     script/myapp_server.pl
 191
 192     # command line testing interface
 193     script/myapp_test.pl /yada
 194
 195     ### in lib/MyApp.pm
 196     use Catalyst qw/-Debug/; # include plugins here as well
 197
 198     ### In lib/MyApp/Controller/Root.pm (autocreated)
 199     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 200         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 201         $c->stash->{template} = 'foo.tt'; # set the template
 202         # lookup something from db -- stash vars are passed to TT
 203         $c->stash->{data} =
 204           $c->model('Database::Foo')->search( { country => $args[0] } );
 205         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 206             $c->forward( 'bar' ); # process another action
 207             # do something else after forward returns
 208         }
 209     }
 210
 211     # The foo.tt TT template can use the stash data from the database
 212     [% WHILE (item = data.next) %]
 213         [% item.foo %]
 214     [% END %]
 215
 216     # called for /bar/of/soap, /bar/of/soap/10, etc.
 217     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 218
 219     # called after all actions are finished
 220     sub end : Action {
 221         my ( $self, $c ) = @_;
 222         if ( scalar @{ $c->error } ) { ... } # handle errors
 223         return if $c->res->body; # already have a response
 224         $c->forward( 'MyApp::View::TT' ); # render template
 225     }
 226
 227 See L<Catalyst::Manual::Intro> for additional information.
 228
 229 =head1 DESCRIPTION
 230
 231 Catalyst is a modern framework for making web applications without the
 232 pain usually associated with this process. This document is a reference
 233 to the main Catalyst application. If you are a new user, we suggest you
 234 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 235
 236 See L<Catalyst::Manual> for more documentation.
 237
 238 Catalyst plugins can be loaded by naming them as arguments to the "use
 239 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 240 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 241 C<My::Module>.
 242
 243     use Catalyst qw/My::Module/;
 244
 245 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 246 fully qualify the name by using a unary plus:
 247
 248     use Catalyst qw/
 249         My::Module
 250         +Fully::Qualified::Plugin::Name
 251     /;
 252
 253 Special flags like C<-Debug> can also be specified as
 254 arguments when Catalyst is loaded:
 255
 256     use Catalyst qw/-Debug My::Module/;
 257
 258 The position of plugins and flags in the chain is important, because
 259 they are loaded in the order in which they appear.
 260
 261 The following flags are supported:
 262
 263 =head2 -Debug
 264
 265 Enables debug output. You can also force this setting from the system
 266 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 267 settings override the application, with <MYAPP>_DEBUG having the highest
 268 priority.
 269
 270 This sets the log level to 'debug' and enables full debug output on the
 271 error screen. If you only want the latter, see L<< $c->debug >>.
 272
 273 =head2 -Home
 274
 275 Forces Catalyst to use a specific home directory, e.g.:
 276
 277     use Catalyst qw[-Home=/usr/mst];
 278
 279 This can also be done in the shell environment by setting either the
 280 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 281 is replaced with the uppercased name of your application, any "::" in
 282 the name will be replaced with underscores, e.g. MyApp::Web should use
 283 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 284
 285 If none of these are set, Catalyst will attempt to automatically detect the
 286 home directory. If you are working in a development environment, Catalyst
 287 will try and find the directory containing either Makefile.PL, Build.PL,
 288 dist.ini, or cpanfile. If the application has been installed into the system
 289 (i.e. you have done C<make install>), then Catalyst will use the path to your
 290 application module, without the .pm extension (e.g., /foo/MyApp if your
 291 application was installed at /foo/MyApp.pm)
 292
 293 =head2 -Log
 294
 295     use Catalyst '-Log=warn,fatal,error';
 296
 297 Specifies a comma-delimited list of log levels.
 298
 299 =head2 -Stats
 300
 301 Enables statistics collection and reporting.
 302
 303    use Catalyst qw/-Stats=1/;
 304
 305 You can also force this setting from the system environment with CATALYST_STATS
 306 or <MYAPP>_STATS. The environment settings override the application, with
 307 <MYAPP>_STATS having the highest priority.
 308
 309 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 310
 311 =head1 METHODS
 312
 313 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 314
 315 =head2 $c->action
 316
 317 Returns a L<Catalyst::Action> object for the current action, which
 318 stringifies to the action name. See L<Catalyst::Action>.
 319
 320 =head2 $c->namespace
 321
 322 Returns the namespace of the current action, i.e., the URI prefix
 323 corresponding to the controller of the current action. For example:
 324
 325     # in Controller::Foo::Bar
 326     $c->namespace; # returns 'foo/bar';
 327
 328 =head2 $c->request
 329
 330 =head2 $c->req
 331
 332 Returns the current L<Catalyst::Request> object, giving access to
 333 information about the current client request (including parameters,
 334 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 335
 336 =head2 REQUEST FLOW HANDLING
 337
 338 =head2 $c->forward( $action [, \@arguments ] )
 339
 340 =head2 $c->forward( $class, $method, [, \@arguments ] )
 341
 342 This is one way of calling another action (method) in the same or
 343 a different controller. You can also use C<< $self->my_method($c, @args) >>
 344 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 345 in a different controller.
 346 The main difference is that 'forward' uses some of the Catalyst request
 347 cycle overhead, including debugging, which may be useful to you. On the
 348 other hand, there are some complications to using 'forward', restrictions
 349 on values returned from 'forward', and it may not handle errors as you prefer.
 350 Whether you use 'forward' or not is up to you; it is not considered superior to
 351 the other ways to call a method.
 352
 353 'forward' calls  another action, by its private name. If you give a
 354 class name but no method, C<process()> is called. You may also optionally
 355 pass arguments in an arrayref. The action will receive the arguments in
 356 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 357 C<< $c->req->args >> will be restored to the previous values.
 358
 359 Any data C<return>ed from the action forwarded to, will be returned by the
 360 call to forward.
 361
 362     my $foodata = $c->forward('/foo');
 363     $c->forward('index');
 364     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 365     $c->forward('View::TT');
 366
 367 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 368 an C<< eval { } >> around the call (actually
 369 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 370 exceptions thrown by the called action non-fatal and pushing them onto
 371 $c->error instead. If you want C<die> to propagate you need to do something
 372 like:
 373
 374     $c->forward('foo');
 375     die join "\n", @{ $c->error } if @{ $c->error };
 376
 377 Or make sure to always return true values from your actions and write
 378 your code like this:
 379
 380     $c->forward('foo') || return;
 381
 382 Another note is that C<< $c->forward >> always returns a scalar because it
 383 actually returns $c->state which operates in a scalar context.
 384 Thus, something like:
 385
 386     return @array;
 387
 388 in an action that is forwarded to is going to return a scalar,
 389 i.e. how many items are in that array, which is probably not what you want.
 390 If you need to return an array then return a reference to it,
 391 or stash it like so:
 392
 393     $c->stash->{array} = \@array;
 394
 395 and access it from the stash.
 396
 397 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 398
 399 =cut
 400
 401 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 402
 403 =head2 $c->detach( $action [, \@arguments ] )
 404
 405 =head2 $c->detach( $class, $method, [, \@arguments ] )
 406
 407 =head2 $c->detach()
 408
 409 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 410 doesn't return to the previous action when processing is finished.
 411
 412 When called with no arguments it escapes the processing chain entirely.
 413
 414 =cut
 415
 416 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 417
 418 =head2 $c->visit( $action [, \@arguments ] )
 419
 420 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 421
 422 =head2 $c->visit( $class, $method, [, \@arguments ] )
 423
 424 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 425
 426 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 427 but does a full dispatch, instead of just calling the new C<$action> /
 428 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 429 you go to are called, just like a new request.
 430
 431 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 432 This means, for example, that C<< $c->action >> methods such as
 433 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 434 L<reverse|Catalyst::Action/reverse> return information for the visited action
 435 when they are invoked within the visited action.  This is different from the
 436 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 437 continues to use the $c->action object from the caller action even when
 438 invoked from the called action.
 439
 440 C<< $c->stash >> is kept unchanged.
 441
 442 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 443 allows you to "wrap" another action, just as it would have been called by
 444 dispatching from a URL, while the analogous
 445 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 446 transfer control to another action as if it had been reached directly from a URL.
 447
 448 =cut
 449
 450 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 451
 452 =head2 $c->go( $action [, \@arguments ] )
 453
 454 =head2 $c->go( $action [, \@captures, \@arguments ] )
 455
 456 =head2 $c->go( $class, $method, [, \@arguments ] )
 457
 458 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 459
 460 The relationship between C<go> and
 461 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 462 the relationship between
 463 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 464 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 465 C<< $c->go >> will perform a full dispatch on the specified action or method,
 466 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 467 C<go> escapes the processing of the current request chain on completion, and
 468 does not return to its caller.
 469
 470 @arguments are arguments to the final destination of $action. @captures are
 471 arguments to the intermediate steps, if any, on the way to the final sub of
 472 $action.
 473
 474 =cut
 475
 476 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 477
 478 =head2 $c->response
 479
 480 =head2 $c->res
 481
 482 Returns the current L<Catalyst::Response> object, see there for details.
 483
 484 =head2 $c->stash
 485
 486 Returns a hashref to the stash, which may be used to store data and pass
 487 it between components during a request. You can also set hash keys by
 488 passing arguments. The stash is automatically sent to the view. The
 489 stash is cleared at the end of a request; it cannot be used for
 490 persistent storage (for this you must use a session; see
 491 L<Catalyst::Plugin::Session> for a complete system integrated with
 492 Catalyst).
 493
 494     $c->stash->{foo} = $bar;
 495     $c->stash( { moose => 'majestic', qux => 0 } );
 496     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 497
 498     # stash is automatically passed to the view for use in a template
 499     $c->forward( 'MyApp::View::TT' );
 500
 501 The stash hash is currently stored in the PSGI C<$env> and is managed by
 502 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 503 the stash can be accessed in sub applications mounted under your main
 504 L<Catalyst> application.  For example if you delegate the response of an
 505 action to another L<Catalyst> application, that sub application will have
 506 access to all the stash keys of the main one, and if can of course add
 507 more keys of its own.  However those new keys will not 'bubble' back up
 508 to the main application.
 509
 510 For more information the best thing to do is to review the test case:
 511 t/middleware-stash.t in the distribution /t directory.
 512
 513 =cut
 514
 515 sub stash {
 516   my $c = shift;
 517   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 518 }
 519
 520 =head2 $c->error
 521
 522 =head2 $c->error($error, ...)
 523
 524 =head2 $c->error($arrayref)
 525
 526 Returns an arrayref containing error messages.  If Catalyst encounters an
 527 error while processing a request, it stores the error in $c->error.  This
 528 method should only be used to store fatal error messages.
 529
 530     my @error = @{ $c->error };
 531
 532 Add a new error.
 533
 534     $c->error('Something bad happened');
 535
 536 =cut
 537
 538 sub error {
 539     my $c = shift;
 540     if ( $_[0] ) {
 541         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 542         croak @$error unless ref $c;
 543         push @{ $c->{error} }, @$error;
 544     }
 545     elsif ( defined $_[0] ) { $c->{error} = undef }
 546     return $c->{error} || [];
 547 }
 548
 549
 550 =head2 $c->state
 551
 552 Contains the return value of the last executed action.
 553 Note that << $c->state >> operates in a scalar context which means that all
 554 values it returns are scalar.
 555
 556 =head2 $c->clear_errors
 557
 558 Clear errors.  You probably don't want to clear the errors unless you are
 559 implementing a custom error screen.
 560
 561 This is equivalent to running
 562
 563     $c->error(0);
 564
 565 =cut
 566
 567 sub clear_errors {
 568     my $c = shift;
 569     $c->error(0);
 570 }
 571
 572 =head2 $c->has_errors
 573
 574 Returns true if you have errors
 575
 576 =cut
 577
 578 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 579
 580 sub _comp_search_prefixes {
 581     my $c = shift;
 582     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 583 }
 584
 585 # search components given a name and some prefixes
 586 sub _comp_names_search_prefixes {
 587     my ( $c, $name, @prefixes ) = @_;
 588     my $appclass = ref $c || $c;
 589     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 590     $filter = qr/$filter/; # Compile regex now rather than once per loop
 591
 592     # map the original component name to the sub part that we will search against
 593     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 594         grep { /$filter/ } keys %{ $c->components };
 595
 596     # undef for a name will return all
 597     return keys %eligible if !defined $name;
 598
 599     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 600     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 601
 602     return @result if @result;
 603
 604     # if we were given a regexp to search against, we're done.
 605     return if $name->$_isa('Regexp');
 606
 607     # skip regexp fallback if configured
 608     return
 609         if $appclass->config->{disable_component_resolution_regex_fallback};
 610
 611     # regexp fallback
 612     $query  = qr/$name/i;
 613     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 614
 615     # no results? try against full names
 616     if( !@result ) {
 617         @result = grep { m{$query} } keys %eligible;
 618     }
 619
 620     # don't warn if we didn't find any results, it just might not exist
 621     if( @result ) {
 622         # Disgusting hack to work out correct method name
 623         my $warn_for = lc $prefixes[0];
 624         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 625            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 626            "component resolution is unreliable and unsafe.";
 627         my $short = $result[0];
 628         # remove the component namespace prefix
 629         $short =~ s/.*?(Model|Controller|View):://;
 630         my $shortmess = Carp::shortmess('');
 631         if ($shortmess =~ m#Catalyst/Plugin#) {
 632            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 633               "plugin's config";
 634         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 635            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 636               "component's config";
 637         } else {
 638            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 639               "but if you really wanted to search, pass in a regexp as the argument " .
 640               "like so: \$c->${warn_for}(qr/${name}/)";
 641         }
 642         $c->log->warn( "${msg}$shortmess" );
 643     }
 644
 645     return @result;
 646 }
 647
 648 # Find possible names for a prefix
 649 sub _comp_names {
 650     my ( $c, @prefixes ) = @_;
 651     my $appclass = ref $c || $c;
 652
 653     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 654
 655     my @names = map { s{$filter}{}; $_; }
 656         $c->_comp_names_search_prefixes( undef, @prefixes );
 657
 658     return @names;
 659 }
 660
 661 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 662 sub _filter_component {
 663     my ( $c, $comp, @args ) = @_;
 664
 665     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 666         return $comp->ACCEPT_CONTEXT( $c, @args );
 667     }
 668
 669     return $comp;
 670 }
 671
 672 =head2 COMPONENT ACCESSORS
 673
 674 =head2 $c->controller($name)
 675
 676 Gets a L<Catalyst::Controller> instance by name.
 677
 678     $c->controller('Foo')->do_stuff;
 679
 680 If the name is omitted, will return the controller for the dispatched
 681 action.
 682
 683 If you want to search for controllers, pass in a regexp as the argument.
 684
 685     # find all controllers that start with Foo
 686     my @foo_controllers = $c->controller(qr{^Foo});
 687
 688
 689 =cut
 690
 691 sub controller {
 692     my ( $c, $name, @args ) = @_;
 693
 694     my $appclass = ref($c) || $c;
 695     if( $name ) {
 696         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 697             my $comps = $c->components;
 698             my $check = $appclass."::Controller::".$name;
 699             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 700         }
 701         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 702         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 703         return $c->_filter_component( $result[ 0 ], @args );
 704     }
 705
 706     return $c->component( $c->action->class );
 707 }
 708
 709 =head2 $c->model($name)
 710
 711 Gets a L<Catalyst::Model> instance by name.
 712
 713     $c->model('Foo')->do_stuff;
 714
 715 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 716
 717 If the name is omitted, it will look for
 718  - a model object in $c->stash->{current_model_instance}, then
 719  - a model name in $c->stash->{current_model}, then
 720  - a config setting 'default_model', or
 721  - check if there is only one model, and return it if that's the case.
 722
 723 If you want to search for models, pass in a regexp as the argument.
 724
 725     # find all models that start with Foo
 726     my @foo_models = $c->model(qr{^Foo});
 727
 728 =cut
 729
 730 sub model {
 731     my ( $c, $name, @args ) = @_;
 732     my $appclass = ref($c) || $c;
 733     if( $name ) {
 734         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 735             my $comps = $c->components;
 736             my $check = $appclass."::Model::".$name;
 737             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 738         }
 739         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 740         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 741         return $c->_filter_component( $result[ 0 ], @args );
 742     }
 743
 744     if (ref $c) {
 745         return $c->stash->{current_model_instance}
 746           if $c->stash->{current_model_instance};
 747         return $c->model( $c->stash->{current_model} )
 748           if $c->stash->{current_model};
 749     }
 750     return $c->model( $appclass->config->{default_model} )
 751       if $appclass->config->{default_model};
 752
 753     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 754
 755     if( $rest ) {
 756         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 757         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 758         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 759         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 760         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 761     }
 762
 763     return $c->_filter_component( $comp );
 764 }
 765
 766
 767 =head2 $c->view($name)
 768
 769 Gets a L<Catalyst::View> instance by name.
 770
 771     $c->view('Foo')->do_stuff;
 772
 773 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 774
 775 If the name is omitted, it will look for
 776  - a view object in $c->stash->{current_view_instance}, then
 777  - a view name in $c->stash->{current_view}, then
 778  - a config setting 'default_view', or
 779  - check if there is only one view, and return it if that's the case.
 780
 781 If you want to search for views, pass in a regexp as the argument.
 782
 783     # find all views that start with Foo
 784     my @foo_views = $c->view(qr{^Foo});
 785
 786 =cut
 787
 788 sub view {
 789     my ( $c, $name, @args ) = @_;
 790
 791     my $appclass = ref($c) || $c;
 792     if( $name ) {
 793         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 794             my $comps = $c->components;
 795             my $check = $appclass."::View::".$name;
 796             if( exists $comps->{$check} ) {
 797                 return $c->_filter_component( $comps->{$check}, @args );
 798             }
 799             else {
 800                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 801             }
 802         }
 803         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 804         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 805         return $c->_filter_component( $result[ 0 ], @args );
 806     }
 807
 808     if (ref $c) {
 809         return $c->stash->{current_view_instance}
 810           if $c->stash->{current_view_instance};
 811         return $c->view( $c->stash->{current_view} )
 812           if $c->stash->{current_view};
 813     }
 814     return $c->view( $appclass->config->{default_view} )
 815       if $appclass->config->{default_view};
 816
 817     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 818
 819     if( $rest ) {
 820         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 821         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 822         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 823         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 824         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 825     }
 826
 827     return $c->_filter_component( $comp );
 828 }
 829
 830 =head2 $c->controllers
 831
 832 Returns the available names which can be passed to $c->controller
 833
 834 =cut
 835
 836 sub controllers {
 837     my ( $c ) = @_;
 838     return $c->_comp_names(qw/Controller C/);
 839 }
 840
 841 =head2 $c->models
 842
 843 Returns the available names which can be passed to $c->model
 844
 845 =cut
 846
 847 sub models {
 848     my ( $c ) = @_;
 849     return $c->_comp_names(qw/Model M/);
 850 }
 851
 852
 853 =head2 $c->views
 854
 855 Returns the available names which can be passed to $c->view
 856
 857 =cut
 858
 859 sub views {
 860     my ( $c ) = @_;
 861     return $c->_comp_names(qw/View V/);
 862 }
 863
 864 =head2 $c->comp($name)
 865
 866 =head2 $c->component($name)
 867
 868 Gets a component object by name. This method is not recommended,
 869 unless you want to get a specific component by full
 870 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 871 should be used instead.
 872
 873 If C<$name> is a regexp, a list of components matched against the full
 874 component name will be returned.
 875
 876 If Catalyst can't find a component by name, it will fallback to regex
 877 matching by default. To disable this behaviour set
 878 disable_component_resolution_regex_fallback to a true value.
 879
 880     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 881
 882 =cut
 883
 884 sub component {
 885     my ( $c, $name, @args ) = @_;
 886
 887     if( $name ) {
 888         my $comps = $c->components;
 889
 890         if( !ref $name ) {
 891             # is it the exact name?
 892             return $c->_filter_component( $comps->{ $name }, @args )
 893                        if exists $comps->{ $name };
 894
 895             # perhaps we just omitted "MyApp"?
 896             my $composed = ( ref $c || $c ) . "::${name}";
 897             return $c->_filter_component( $comps->{ $composed }, @args )
 898                        if exists $comps->{ $composed };
 899
 900             # search all of the models, views and controllers
 901             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 902             return $c->_filter_component( $comp, @args ) if $comp;
 903         }
 904
 905         return
 906             if $c->config->{disable_component_resolution_regex_fallback};
 907
 908         # This is here so $c->comp( '::M::' ) works
 909         my $query = ref $name ? $name : qr{$name}i;
 910
 911         my @result = grep { m{$query} } keys %{ $c->components };
 912         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 913
 914         if( $result[ 0 ] ) {
 915             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 916             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 917             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 918             return $c->_filter_component( $result[ 0 ], @args );
 919         }
 920
 921         # I would expect to return an empty list here, but that breaks back-compat
 922     }
 923
 924     # fallback
 925     return sort keys %{ $c->components };
 926 }
 927
 928 =head2 CLASS DATA AND HELPER CLASSES
 929
 930 =head2 $c->config
 931
 932 Returns or takes a hashref containing the application's configuration.
 933
 934     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 935
 936 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 937 like C<myapp.conf> in your applications home directory. See
 938 L<Catalyst::Plugin::ConfigLoader>.
 939
 940 =head3 Cascading configuration
 941
 942 The config method is present on all Catalyst components, and configuration
 943 will be merged when an application is started. Configuration loaded with
 944 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 945 followed by configuration in your top level C<MyApp> class. These two
 946 configurations are merged, and then configuration data whose hash key matches a
 947 component name is merged with configuration for that component.
 948
 949 The configuration for a component is then passed to the C<new> method when a
 950 component is constructed.
 951
 952 For example:
 953
 954     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 955     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 956
 957 will mean that C<MyApp::Model::Foo> receives the following data when
 958 constructed:
 959
 960     MyApp::Model::Foo->new({
 961         bar => 'baz',
 962         quux => 'frob',
 963         overrides => 'me',
 964     });
 965
 966 It's common practice to use a Moose attribute
 967 on the receiving component to access the config value.
 968
 969     package MyApp::Model::Foo;
 970
 971     use Moose;
 972
 973     # this attr will receive 'baz' at construction time
 974     has 'bar' => (
 975         is  => 'rw',
 976         isa => 'Str',
 977     );
 978
 979 You can then get the value 'baz' by calling $c->model('Foo')->bar
 980 (or $self->bar inside code in the model).
 981
 982 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 983 as a way of reading config within your code, as this B<will not> give you the
 984 correctly merged config back. You B<MUST> take the config values supplied to
 985 the constructor and use those instead.
 986
 987 =cut
 988
 989 around config => sub {
 990     my $orig = shift;
 991     my $c = shift;
 992
 993     croak('Setting config after setup has been run is not allowed.')
 994         if ( @_ and $c->setup_finished );
 995
 996     $c->$orig(@_);
 997 };
 998
 999 =head2 $c->log
1000
1001 Returns the logging object instance. Unless it is already set, Catalyst
1002 sets this up with a L<Catalyst::Log> object. To use your own log class,
1003 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1004 C<< __PACKAGE__->setup >>.
1005
1006  __PACKAGE__->log( MyLogger->new );
1007  __PACKAGE__->setup;
1008
1009 And later:
1010
1011     $c->log->info( 'Now logging with my own logger!' );
1012
1013 Your log class should implement the methods described in
1014 L<Catalyst::Log>.
1015
1016 =head2 encoding
1017
1018 Sets or gets the application encoding.
1019
1020 =cut
1021
1022 sub encoding {
1023     my $c = shift;
1024     my $encoding;
1025
1026     if ( scalar @_ ) {
1027         # Let it be set to undef
1028         if (my $wanted = shift)  {
1029             $encoding = Encode::find_encoding($wanted)
1030               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1031             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1032         }
1033         else {
1034             binmode(STDERR);
1035         }
1036
1037         $encoding = ref $c
1038                   ? $c->{encoding} = $encoding
1039                   : $c->_encoding($encoding);
1040     } else {
1041       $encoding = ref $c && exists $c->{encoding}
1042                 ? $c->{encoding}
1043                 : $c->_encoding;
1044     }
1045
1046     return $encoding;
1047 }
1048
1049 =head2 $c->debug
1050
1051 Returns 1 if debug mode is enabled, 0 otherwise.
1052
1053 You can enable debug mode in several ways:
1054
1055 =over
1056
1057 =item By calling myapp_server.pl with the -d flag
1058
1059 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1060
1061 =item The -Debug option in your MyApp.pm
1062
1063 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1064
1065 =back
1066
1067 The first three also set the log level to 'debug'.
1068
1069 Calling C<< $c->debug(1) >> has no effect.
1070
1071 =cut
1072
1073 sub debug { 0 }
1074
1075 =head2 $c->dispatcher
1076
1077 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1078
1079 =head2 $c->engine
1080
1081 Returns the engine instance. See L<Catalyst::Engine>.
1082
1083
1084 =head2 UTILITY METHODS
1085
1086 =head2 $c->path_to(@path)
1087
1088 Merges C<@path> with C<< $c->config->{home} >> and returns a
1089 L<Path::Class::Dir> object. Note you can usually use this object as
1090 a filename, but sometimes you will have to explicitly stringify it
1091 yourself by calling the C<< ->stringify >> method.
1092
1093 For example:
1094
1095     $c->path_to( 'db', 'sqlite.db' );
1096
1097 =cut
1098
1099 sub path_to {
1100     my ( $c, @path ) = @_;
1101     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1102     if ( -d $path ) { return $path }
1103     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1104 }
1105
1106 sub plugin {
1107     my ( $class, $name, $plugin, @args ) = @_;
1108
1109     # See block comment in t/unit_core_plugin.t
1110     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1111
1112     $class->_register_plugin( $plugin, 1 );
1113
1114     eval { $plugin->import };
1115     $class->mk_classdata($name);
1116     my $obj;
1117     eval { $obj = $plugin->new(@args) };
1118
1119     if ($@) {
1120         Catalyst::Exception->throw( message =>
1121               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1122     }
1123
1124     $class->$name($obj);
1125     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1126       if $class->debug;
1127 }
1128
1129 =head2 MyApp->setup
1130
1131 Initializes the dispatcher and engine, loads any plugins, and loads the
1132 model, view, and controller components. You may also specify an array
1133 of plugins to load here, if you choose to not load them in the C<use
1134 Catalyst> line.
1135
1136     MyApp->setup;
1137     MyApp->setup( qw/-Debug/ );
1138
1139 B<Note:> You B<should not> wrap this method with method modifiers
1140 or bad things will happen - wrap the C<setup_finalize> method instead.
1141
1142 =cut
1143
1144 sub setup {
1145     my ( $class, @arguments ) = @_;
1146     croak('Running setup more than once')
1147         if ( $class->setup_finished );
1148
1149     unless ( $class->isa('Catalyst') ) {
1150
1151         Catalyst::Exception->throw(
1152             message => qq/'$class' does not inherit from Catalyst/ );
1153     }
1154
1155     if ( $class->arguments ) {
1156         @arguments = ( @arguments, @{ $class->arguments } );
1157     }
1158
1159     # Process options
1160     my $flags = {};
1161
1162     foreach (@arguments) {
1163
1164         if (/^-Debug$/) {
1165             $flags->{log} =
1166               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1167         }
1168         elsif (/^-(\w+)=?(.*)$/) {
1169             $flags->{ lc $1 } = $2;
1170         }
1171         else {
1172             push @{ $flags->{plugins} }, $_;
1173         }
1174     }
1175
1176     $class->setup_home( delete $flags->{home} );
1177
1178     $class->setup_log( delete $flags->{log} );
1179     $class->setup_plugins( delete $flags->{plugins} );
1180
1181     $class->setup_data_handlers();
1182     $class->setup_dispatcher( delete $flags->{dispatcher} );
1183     if (my $engine = delete $flags->{engine}) {
1184         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1185     }
1186     $class->setup_engine();
1187     $class->setup_stats( delete $flags->{stats} );
1188
1189     for my $flag ( sort keys %{$flags} ) {
1190
1191         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1192             &$code( $class, delete $flags->{$flag} );
1193         }
1194         else {
1195             $class->log->warn(qq/Unknown flag "$flag"/);
1196         }
1197     }
1198
1199     eval { require Catalyst::Devel; };
1200     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1201         $class->log->warn(<<"EOF");
1202 You are running an old script!
1203
1204   Please update by running (this will overwrite existing files):
1205     catalyst.pl -force -scripts $class
1206
1207   or (this will not overwrite existing files):
1208     catalyst.pl -scripts $class
1209
1210 EOF
1211     }
1212
1213     # Call plugins setup, this is stupid and evil.
1214     # Also screws C3 badly on 5.10, hack to avoid.
1215     {
1216         no warnings qw/redefine/;
1217         local *setup = sub { };
1218         $class->setup unless $Catalyst::__AM_RESTARTING;
1219     }
1220
1221     # If you are expecting configuration info as part of your setup, it needs
1222     # to get called here and below, since we need the above line to support
1223     # ConfigLoader based configs.
1224
1225     $class->setup_encoding();
1226     $class->setup_middleware();
1227
1228     # Initialize our data structure
1229     $class->components( {} );
1230
1231     $class->setup_components;
1232
1233     if ( $class->debug ) {
1234         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1235
1236         if (@plugins) {
1237             my $column_width = Catalyst::Utils::term_width() - 6;
1238             my $t = Text::SimpleTable->new($column_width);
1239             $t->row($_) for @plugins;
1240             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1241         }
1242
1243         my @middleware = map {
1244           ref $_ eq 'CODE' ?
1245             "Inline Coderef" :
1246               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1247                 || '')  } $class->registered_middlewares;
1248
1249         if (@middleware) {
1250             my $column_width = Catalyst::Utils::term_width() - 6;
1251             my $t = Text::SimpleTable->new($column_width);
1252             $t->row($_) for @middleware;
1253             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1254         }
1255
1256         my %dh = $class->registered_data_handlers;
1257         if (my @data_handlers = keys %dh) {
1258             my $column_width = Catalyst::Utils::term_width() - 6;
1259             my $t = Text::SimpleTable->new($column_width);
1260             $t->row($_) for @data_handlers;
1261             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1262         }
1263
1264         my $dispatcher = $class->dispatcher;
1265         my $engine     = $class->engine;
1266         my $home       = $class->config->{home};
1267
1268         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1269         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1270
1271         $home
1272           ? ( -d $home )
1273           ? $class->log->debug(qq/Found home "$home"/)
1274           : $class->log->debug(qq/Home "$home" doesn't exist/)
1275           : $class->log->debug(q/Couldn't find home/);
1276
1277         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1278         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1279         for my $comp ( sort keys %{ $class->components } ) {
1280             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1281             $t->row( $comp, $type );
1282         }
1283         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1284           if ( keys %{ $class->components } );
1285     }
1286
1287     # Add our self to components, since we are also a component
1288     if( $class->isa('Catalyst::Controller') ){
1289       $class->components->{$class} = $class;
1290     }
1291
1292     $class->setup_actions;
1293
1294     if ( $class->debug ) {
1295         my $name = $class->config->{name} || 'Application';
1296         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1297     }
1298
1299     if ($class->config->{case_sensitive}) {
1300         $class->log->warn($class . "->config->{case_sensitive} is set.");
1301         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1302     }
1303
1304     $class->setup_finalize;
1305
1306     # Flush the log for good measure (in case something turned off 'autoflush' early)
1307     $class->log->_flush() if $class->log->can('_flush');
1308
1309     return $class || 1; # Just in case someone named their Application 0...
1310 }
1311
1312 =head2 $app->setup_finalize
1313
1314 A hook to attach modifiers to. This method does not do anything except set the
1315 C<setup_finished> accessor.
1316
1317 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1318
1319 Example:
1320
1321     after setup_finalize => sub {
1322         my $app = shift;
1323
1324         ## do stuff here..
1325     };
1326
1327 =cut
1328
1329 sub setup_finalize {
1330     my ($class) = @_;
1331     $class->setup_finished(1);
1332 }
1333
1334 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1335
1336 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1337
1338 Constructs an absolute L<URI> object based on the application root, the
1339 provided path, and the additional arguments and query parameters provided.
1340 When used as a string, provides a textual URI.  If you need more flexibility
1341 than this (i.e. the option to provide relative URIs etc.) see
1342 L<Catalyst::Plugin::SmartURI>.
1343
1344 If no arguments are provided, the URI for the current action is returned.
1345 To return the current action and also provide @args, use
1346 C<< $c->uri_for( $c->action, @args ) >>.
1347
1348 If the first argument is a string, it is taken as a public URI path relative
1349 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1350 relative to the application root (if it does). It is then merged with
1351 C<< $c->request->base >>; any C<@args> are appended as additional path
1352 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1353
1354 If the first argument is a L<Catalyst::Action> it represents an action which
1355 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1356 optional C<\@captures> argument (an arrayref) allows passing the captured
1357 variables that are needed to fill in the paths of Chained and Regex actions;
1358 once the path is resolved, C<uri_for> continues as though a path was
1359 provided, appending any arguments or parameters and creating an absolute
1360 URI.
1361
1362 The captures for the current request can be found in
1363 C<< $c->request->captures >>, and actions can be resolved using
1364 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1365 path, use C<< $c->uri_for_action >> instead.
1366
1367   # Equivalent to $c->req->uri
1368   $c->uri_for($c->action, $c->req->captures,
1369       @{ $c->req->args }, $c->req->params);
1370
1371   # For the Foo action in the Bar controller
1372   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1373
1374   # Path to a static resource
1375   $c->uri_for('/static/images/logo.png');
1376
1377 In general the scheme of the generated URI object will follow the incoming request
1378 however if your targeted action or action chain has the Scheme attribute it will
1379 use that instead.
1380
1381 =cut
1382
1383 sub uri_for {
1384     my ( $c, $path, @args ) = @_;
1385
1386     if ( $path->$_isa('Catalyst::Controller') ) {
1387         $path = $path->path_prefix;
1388         $path =~ s{/+\z}{};
1389         $path .= '/';
1390     }
1391
1392     undef($path) if (defined $path && $path eq '');
1393
1394     my $params =
1395       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1396
1397     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1398
1399     my @encoded_args = ();
1400     foreach my $arg (@args) {
1401       if(ref($arg)||'' eq 'ARRAY') {
1402         push @encoded_args, [map {
1403           my $encoded = encode_utf8 $_;
1404           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1405          $encoded;
1406         } @$arg];
1407       } else {
1408         push @encoded_args, do {
1409           my $encoded = encode_utf8 $arg;
1410           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1411           $encoded;
1412         }
1413       }
1414     }
1415
1416     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1417     if ( $path->$_isa('Catalyst::Action') ) { # action object
1418         s|/|%2F|g for @encoded_args;
1419         my $captures = [ map { s|/|%2F|g; $_; }
1420                         ( scalar @encoded_args && ref $encoded_args[0] eq 'ARRAY'
1421                          ? @{ shift(@encoded_args) }
1422                          : ()) ];
1423
1424         my $action = $path;
1425         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1426         if( !@encoded_args && $action->number_of_args ) {
1427             my $expanded_action = $c->dispatcher->expand_action( $action );
1428             my $num_captures = $expanded_action->number_of_captures;
1429             unshift @encoded_args, splice @$captures, $num_captures;
1430         }
1431
1432        $path = $c->dispatcher->uri_for_action($action, $captures);
1433         if (not defined $path) {
1434             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1435                 if $c->debug;
1436             return undef;
1437         }
1438         $path = '/' if $path eq '';
1439     }
1440
1441     unshift(@encoded_args, $path);
1442
1443     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1444         my $namespace = $c->namespace;
1445         if (defined $path) { # cheesy hack to handle path '../foo'
1446            $namespace =~ s{(?:^|/)[^/]+$}{} while $encoded_args[0] =~ s{^\.\./}{};
1447         }
1448         unshift(@encoded_args, $namespace || '');
1449     }
1450
1451     # join args with '/', or a blank string
1452     my $args = join('/', grep { defined($_) } @encoded_args);
1453     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1454     $args =~ s!^/+!!;
1455
1456     my ($base, $class) = ('/', 'URI::_generic');
1457     if(blessed($c)) {
1458       $base = $c->req->base;
1459       if($target_action) {
1460         $target_action = $c->dispatcher->expand_action($target_action);
1461         if(my $s = $target_action->scheme) {
1462           $s = lc($s);
1463           $class = "URI::$s";
1464           $base->scheme($s);
1465         } else {
1466           $class = ref($base);
1467         }
1468       } else {
1469         $class = ref($base);
1470       }
1471
1472       $base =~ s{(?<!/)$}{/};
1473     }
1474
1475     my $query = '';
1476
1477     if (my @keys = keys %$params) {
1478       # somewhat lifted from URI::_query's query_form
1479       $query = '?'.join('&', map {
1480           my $val = $params->{$_};
1481           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1482           s/ /+/g;
1483           my $key = $_;
1484           $val = '' unless defined $val;
1485           (map {
1486               my $param = "$_";
1487               $param = encode_utf8($param);
1488               # using the URI::Escape pattern here so utf8 chars survive
1489               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1490               $param =~ s/ /+/g;
1491
1492               $key = encode_utf8($key);
1493               # using the URI::Escape pattern here so utf8 chars survive
1494               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1495               $key =~ s/ /+/g;
1496
1497               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1498       } @keys);
1499     }
1500
1501     my $res = bless(\"${base}${args}${query}", $class);
1502     $res;
1503 }
1504
1505 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1506
1507 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1508
1509 =over
1510
1511 =item $path
1512
1513 A private path to the Catalyst action you want to create a URI for.
1514
1515 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1516 >> and passing the resulting C<$action> and the remaining arguments to C<<
1517 $c->uri_for >>.
1518
1519 You can also pass in a Catalyst::Action object, in which case it is passed to
1520 C<< $c->uri_for >>.
1521
1522 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1523
1524 For example, if the action looks like:
1525
1526  package MyApp::Controller::Users;
1527
1528  sub lst : Path('the-list') {}
1529
1530 You can use:
1531
1532  $c->uri_for_action('/users/lst')
1533
1534 and it will create the URI /users/the-list.
1535
1536 =item \@captures_and_args?
1537
1538 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1539 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1540 to interpolate all the parameters in the URI.
1541
1542 =item @args?
1543
1544 Optional list of extra arguments - can be supplied in the
1545 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1546 code.
1547
1548 Your action can have zero, a fixed or a variable number of args (e.g.
1549 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1550
1551 =item \%query_values?
1552
1553 Optional array reference of query parameters to append. E.g.
1554
1555   { foo => 'bar' }
1556
1557 will generate
1558
1559   /rest/of/your/uri?foo=bar
1560
1561 =back
1562
1563 =cut
1564
1565 sub uri_for_action {
1566     my ( $c, $path, @args ) = @_;
1567     my $action = blessed($path)
1568       ? $path
1569       : $c->dispatcher->get_action_by_path($path);
1570     unless (defined $action) {
1571       croak "Can't find action for path '$path'";
1572     }
1573     return $c->uri_for( $action, @args );
1574 }
1575
1576 =head2 $c->welcome_message
1577
1578 Returns the Catalyst welcome HTML page.
1579
1580 =cut
1581
1582 sub welcome_message {
1583     my $c      = shift;
1584     my $name   = $c->config->{name};
1585     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1586     my $prefix = Catalyst::Utils::appprefix( ref $c );
1587     $c->response->content_type('text/html; charset=utf-8');
1588     return <<"EOF";
1589 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1590     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1591 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1592     <head>
1593     <meta http-equiv="Content-Language" content="en" />
1594     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1595         <title>$name on Catalyst $VERSION</title>
1596         <style type="text/css">
1597             body {
1598                 color: #000;
1599                 background-color: #eee;
1600             }
1601             div#content {
1602                 width: 640px;
1603                 margin-left: auto;
1604                 margin-right: auto;
1605                 margin-top: 10px;
1606                 margin-bottom: 10px;
1607                 text-align: left;
1608                 background-color: #ccc;
1609                 border: 1px solid #aaa;
1610             }
1611             p, h1, h2 {
1612                 margin-left: 20px;
1613                 margin-right: 20px;
1614                 font-family: verdana, tahoma, sans-serif;
1615             }
1616             a {
1617                 font-family: verdana, tahoma, sans-serif;
1618             }
1619             :link, :visited {
1620                     text-decoration: none;
1621                     color: #b00;
1622                     border-bottom: 1px dotted #bbb;
1623             }
1624             :link:hover, :visited:hover {
1625                     color: #555;
1626             }
1627             div#topbar {
1628                 margin: 0px;
1629             }
1630             pre {
1631                 margin: 10px;
1632                 padding: 8px;
1633             }
1634             div#answers {
1635                 padding: 8px;
1636                 margin: 10px;
1637                 background-color: #fff;
1638                 border: 1px solid #aaa;
1639             }
1640             h1 {
1641                 font-size: 0.9em;
1642                 font-weight: normal;
1643                 text-align: center;
1644             }
1645             h2 {
1646                 font-size: 1.0em;
1647             }
1648             p {
1649                 font-size: 0.9em;
1650             }
1651             p img {
1652                 float: right;
1653                 margin-left: 10px;
1654             }
1655             span#appname {
1656                 font-weight: bold;
1657                 font-size: 1.6em;
1658             }
1659         </style>
1660     </head>
1661     <body>
1662         <div id="content">
1663             <div id="topbar">
1664                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1665                     $VERSION</h1>
1666              </div>
1667              <div id="answers">
1668                  <p>
1669                  <img src="$logo" alt="Catalyst Logo" />
1670                  </p>
1671                  <p>Welcome to the  world of Catalyst.
1672                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1673                     framework will make web development something you had
1674                     never expected it to be: Fun, rewarding, and quick.</p>
1675                  <h2>What to do now?</h2>
1676                  <p>That really depends  on what <b>you</b> want to do.
1677                     We do, however, provide you with a few starting points.</p>
1678                  <p>If you want to jump right into web development with Catalyst
1679                     you might want to start with a tutorial.</p>
1680 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1681 </pre>
1682 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1683 <pre>
1684 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1685 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1686 </code></pre>
1687                  <h2>What to do next?</h2>
1688                  <p>Next it's time to write an actual application. Use the
1689                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1690                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1691                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1692                     they can save you a lot of work.</p>
1693                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1694                     <p>Also, be sure to check out the vast and growing
1695                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1696                     you are likely to find what you need there.
1697                     </p>
1698
1699                  <h2>Need help?</h2>
1700                  <p>Catalyst has a very active community. Here are the main places to
1701                     get in touch with us.</p>
1702                  <ul>
1703                      <li>
1704                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1705                      </li>
1706                      <li>
1707                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1708                      </li>
1709                      <li>
1710                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1711                      </li>
1712                  </ul>
1713                  <h2>In conclusion</h2>
1714                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1715                     as we enjoyed making it. Please contact us if you have ideas
1716                     for improvement or other feedback.</p>
1717              </div>
1718          </div>
1719     </body>
1720 </html>
1721 EOF
1722 }
1723
1724 =head2 run_options
1725
1726 Contains a hash of options passed from the application script, including
1727 the original ARGV the script received, the processed values from that
1728 ARGV and any extra arguments to the script which were not processed.
1729
1730 This can be used to add custom options to your application's scripts
1731 and setup your application differently depending on the values of these
1732 options.
1733
1734 =head1 INTERNAL METHODS
1735
1736 These methods are not meant to be used by end users.
1737
1738 =head2 $c->components
1739
1740 Returns a hash of components.
1741
1742 =head2 $c->context_class
1743
1744 Returns or sets the context class.
1745
1746 =head2 $c->counter
1747
1748 Returns a hashref containing coderefs and execution counts (needed for
1749 deep recursion detection).
1750
1751 =head2 $c->depth
1752
1753 Returns the number of actions on the current internal execution stack.
1754
1755 =head2 $c->dispatch
1756
1757 Dispatches a request to actions.
1758
1759 =cut
1760
1761 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1762
1763 =head2 $c->dispatcher_class
1764
1765 Returns or sets the dispatcher class.
1766
1767 =head2 $c->dump_these
1768
1769 Returns a list of 2-element array references (name, structure) pairs
1770 that will be dumped on the error page in debug mode.
1771
1772 =cut
1773
1774 sub dump_these {
1775     my $c = shift;
1776     [ Request => $c->req ],
1777     [ Response => $c->res ],
1778     [ Stash => $c->stash ],
1779     [ Config => $c->config ];
1780 }
1781
1782 =head2 $c->engine_class
1783
1784 Returns or sets the engine class.
1785
1786 =head2 $c->execute( $class, $coderef )
1787
1788 Execute a coderef in given class and catch exceptions. Errors are available
1789 via $c->error.
1790
1791 =cut
1792
1793 sub execute {
1794     my ( $c, $class, $code ) = @_;
1795     $class = $c->component($class) || $class;
1796     $c->state(0);
1797
1798     if ( $c->depth >= $RECURSION ) {
1799         my $action = $code->reverse();
1800         $action = "/$action" unless $action =~ /->/;
1801         my $error = qq/Deep recursion detected calling "${action}"/;
1802         $c->log->error($error);
1803         $c->error($error);
1804         $c->state(0);
1805         return $c->state;
1806     }
1807
1808     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1809
1810     push( @{ $c->stack }, $code );
1811
1812     no warnings 'recursion';
1813     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1814     #      I have no idea how, ergo $ret (which appears to fix the issue)
1815     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1816
1817     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1818
1819     my $last = pop( @{ $c->stack } );
1820
1821     if ( my $error = $@ ) {
1822         #rethow if this can be handled by middleware
1823         if(
1824           blessed $error && (
1825             $error->can('as_psgi') ||
1826             (
1827               $error->can('code') &&
1828               $error->code =~m/^[1-5][0-9][0-9]$/
1829             )
1830           )
1831         ) {
1832             foreach my $err (@{$c->error}) {
1833                 $c->log->error($err);
1834             }
1835             $c->clear_errors;
1836             $c->log->_flush if $c->log->can('_flush');
1837
1838             $error->can('rethrow') ? $error->rethrow : croak $error;
1839         }
1840         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1841             $error->rethrow if $c->depth > 1;
1842         }
1843         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1844             $error->rethrow if $c->depth > 0;
1845         }
1846         else {
1847             unless ( ref $error ) {
1848                 no warnings 'uninitialized';
1849                 chomp $error;
1850                 my $class = $last->class;
1851                 my $name  = $last->name;
1852                 $error = qq/Caught exception in $class->$name "$error"/;
1853             }
1854             $c->error($error);
1855         }
1856         $c->state(0);
1857     }
1858     return $c->state;
1859 }
1860
1861 sub _stats_start_execute {
1862     my ( $c, $code ) = @_;
1863     my $appclass = ref($c) || $c;
1864     return if ( ( $code->name =~ /^_.*/ )
1865         && ( !$appclass->config->{show_internal_actions} ) );
1866
1867     my $action_name = $code->reverse();
1868     $c->counter->{$action_name}++;
1869
1870     my $action = $action_name;
1871     $action = "/$action" unless $action =~ /->/;
1872
1873     # determine if the call was the result of a forward
1874     # this is done by walking up the call stack and looking for a calling
1875     # sub of Catalyst::forward before the eval
1876     my $callsub = q{};
1877     for my $index ( 2 .. 11 ) {
1878         last
1879         if ( ( caller($index) )[0] eq 'Catalyst'
1880             && ( caller($index) )[3] eq '(eval)' );
1881
1882         if ( ( caller($index) )[3] =~ /forward$/ ) {
1883             $callsub = ( caller($index) )[3];
1884             $action  = "-> $action";
1885             last;
1886         }
1887     }
1888
1889     my $uid = $action_name . $c->counter->{$action_name};
1890
1891     # is this a root-level call or a forwarded call?
1892     if ( $callsub =~ /forward$/ ) {
1893         my $parent = $c->stack->[-1];
1894
1895         # forward, locate the caller
1896         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1897             $c->stats->profile(
1898                 begin  => $action,
1899                 parent => "$parent" . $c->counter->{"$parent"},
1900                 uid    => $uid,
1901             );
1902         }
1903         else {
1904
1905             # forward with no caller may come from a plugin
1906             $c->stats->profile(
1907                 begin => $action,
1908                 uid   => $uid,
1909             );
1910         }
1911     }
1912     else {
1913
1914         # root-level call
1915         $c->stats->profile(
1916             begin => $action,
1917             uid   => $uid,
1918         );
1919     }
1920     return $action;
1921
1922 }
1923
1924 sub _stats_finish_execute {
1925     my ( $c, $info ) = @_;
1926     $c->stats->profile( end => $info );
1927 }
1928
1929 =head2 $c->finalize
1930
1931 Finalizes the request.
1932
1933 =cut
1934
1935 sub finalize {
1936     my $c = shift;
1937
1938     for my $error ( @{ $c->error } ) {
1939         $c->log->error($error);
1940     }
1941
1942     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1943     # stuff like cometd and websockets
1944
1945     if($c->request->_has_io_fh) {
1946       $c->log_response;
1947       return;
1948     }
1949
1950     # Allow engine to handle finalize flow (for POE)
1951     my $engine = $c->engine;
1952     if ( my $code = $engine->can('finalize') ) {
1953         $engine->$code($c);
1954     }
1955     else {
1956
1957         $c->finalize_uploads;
1958
1959         # Error
1960         if ( $#{ $c->error } >= 0 ) {
1961             $c->finalize_error;
1962         }
1963
1964         $c->finalize_encoding;
1965         $c->finalize_headers unless $c->response->finalized_headers;
1966         $c->finalize_body;
1967     }
1968
1969     $c->log_response;
1970
1971     if ($c->use_stats) {
1972         my $elapsed = $c->stats->elapsed;
1973         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1974         $c->log->info(
1975             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1976     }
1977
1978     return $c->response->status;
1979 }
1980
1981 =head2 $c->finalize_body
1982
1983 Finalizes body.
1984
1985 =cut
1986
1987 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1988
1989 =head2 $c->finalize_cookies
1990
1991 Finalizes cookies.
1992
1993 =cut
1994
1995 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1996
1997 =head2 $c->finalize_error
1998
1999 Finalizes error.  If there is only one error in L</error> and it is an object that
2000 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2001 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2002 return the default error page (production mode).
2003
2004 =cut
2005
2006 sub finalize_error {
2007     my $c = shift;
2008     if($#{$c->error} > 0) {
2009         $c->engine->finalize_error( $c, @_ );
2010     } else {
2011         my ($error) = @{$c->error};
2012         if(
2013           blessed $error &&
2014           ($error->can('as_psgi') || $error->can('code'))
2015         ) {
2016             # In the case where the error 'knows what it wants', becauses its PSGI
2017             # aware, just rethow and let middleware catch it
2018             $error->can('rethrow') ? $error->rethrow : croak $error;
2019         } else {
2020             $c->engine->finalize_error( $c, @_ )
2021         }
2022     }
2023 }
2024
2025 =head2 $c->finalize_headers
2026
2027 Finalizes headers.
2028
2029 =cut
2030
2031 sub finalize_headers {
2032     my $c = shift;
2033
2034     my $response = $c->response; #accessor calls can add up?
2035
2036     # Check if we already finalized headers
2037     return if $response->finalized_headers;
2038
2039     # Handle redirects
2040     if ( my $location = $response->redirect ) {
2041         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2042         $response->header( Location => $location );
2043     }
2044
2045     # Remove incorrectly added body and content related meta data when returning
2046     # an information response, or a response the is required to not include a body
2047
2048     $c->finalize_cookies;
2049
2050     $c->response->finalize_headers();
2051
2052     if(my $enc = $c->encoding) {
2053        my ($ct, $ct_enc) = $c->response->content_type;
2054
2055         # Only touch 'text-like' contents
2056         if($c->response->content_type =~ /^text|xml$|javascript$/) {
2057           if ($ct_enc && $ct_enc =~ /charset=([^;]*)/) {
2058             if (uc($1) ne uc($enc->mime_name)) {
2059               $c->log->debug("Catalyst encoding config is set to encode in '" .
2060                            $enc->mime_name .
2061                            "', content type is '$1', not encoding ");
2062             }
2063           } else {
2064             $c->res->content_type($c->res->content_type . "; charset=" . $enc->mime_name);
2065           }
2066         }
2067     }
2068
2069     # Done
2070     $response->finalized_headers(1);
2071 }
2072
2073 =head2 $c->finalize_encoding
2074
2075 Make sure your body is encoded properly IF you set an encoding.  By
2076 default the encoding is UTF-8 but you can disable it by explictly setting the
2077 encoding configuration value to undef.
2078
2079 See L</ENCODING>.
2080
2081 =cut
2082
2083 sub finalize_encoding {
2084     my $c = shift;
2085
2086     my $body = $c->response->body;
2087
2088     return unless defined($body);
2089
2090     my $enc = $c->encoding;
2091
2092     return unless $enc;
2093
2094     # Only touch 'text-like' contents
2095     if($c->response->content_type =~ /^text|xml$|javascript$/) {
2096       if (ref(\$body) eq 'SCALAR') {
2097         $c->response->body( $c->encoding->encode( $body, $c->_encode_check ) );
2098       }
2099     }
2100 }
2101
2102 =head2 $c->finalize_output
2103
2104 An alias for finalize_body.
2105
2106 =head2 $c->finalize_read
2107
2108 Finalizes the input after reading is complete.
2109
2110 =cut
2111
2112 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2113
2114 =head2 $c->finalize_uploads
2115
2116 Finalizes uploads. Cleans up any temporary files.
2117
2118 =cut
2119
2120 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2121
2122 =head2 $c->get_action( $action, $namespace )
2123
2124 Gets an action in a given namespace.
2125
2126 =cut
2127
2128 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2129
2130 =head2 $c->get_actions( $action, $namespace )
2131
2132 Gets all actions of a given name in a namespace and all parent
2133 namespaces.
2134
2135 =cut
2136
2137 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2138
2139 =head2 $app->handle_request( @arguments )
2140
2141 Called to handle each HTTP request.
2142
2143 =cut
2144
2145 sub handle_request {
2146     my ( $class, @arguments ) = @_;
2147
2148     # Always expect worst case!
2149     my $status = -1;
2150     try {
2151         if ($class->debug) {
2152             my $secs = time - $START || 1;
2153             my $av = sprintf '%.3f', $COUNT / $secs;
2154             my $time = localtime time;
2155             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2156         }
2157
2158         my $c = $class->prepare(@arguments);
2159         $c->dispatch;
2160         $status = $c->finalize;
2161     } catch {
2162         #rethow if this can be handled by middleware
2163         if(
2164           blessed($_) && (
2165             $_->can('as_psgi') ||
2166             (
2167               $_->can('code') &&
2168               $_->code =~m/^[1-5][0-9][0-9]$/
2169             )
2170           )
2171         ) {
2172             $_->can('rethrow') ? $_->rethrow : croak $_;
2173         }
2174         chomp(my $error = $_);
2175         $class->log->error(qq/Caught exception in engine "$error"/);
2176     };
2177
2178     $COUNT++;
2179
2180     if(my $coderef = $class->log->can('_flush')){
2181         $class->log->$coderef();
2182     }
2183     return $status;
2184 }
2185
2186 =head2 $class->prepare( @arguments )
2187
2188 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2189 etc.).
2190
2191 =cut
2192
2193 has _uploadtmp => (
2194     is => 'ro',
2195     predicate => '_has_uploadtmp',
2196 );
2197
2198 sub prepare {
2199     my ( $class, @arguments ) = @_;
2200
2201     # XXX
2202     # After the app/ctxt split, this should become an attribute based on something passed
2203     # into the application.
2204     $class->context_class( ref $class || $class ) unless $class->context_class;
2205
2206     my $uploadtmp = $class->config->{uploadtmp};
2207     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2208
2209     $c->response->_context($c);
2210
2211     #surely this is not the most efficient way to do things...
2212     $c->stats($class->stats_class->new)->enable($c->use_stats);
2213     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2214         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2215     }
2216
2217     try {
2218         # Allow engine to direct the prepare flow (for POE)
2219         if ( my $prepare = $c->engine->can('prepare') ) {
2220             $c->engine->$prepare( $c, @arguments );
2221         }
2222         else {
2223             $c->prepare_request(@arguments);
2224             $c->prepare_connection;
2225             $c->prepare_query_parameters;
2226             $c->prepare_headers; # Just hooks, no longer needed - they just
2227             $c->prepare_cookies; # cause the lazy attribute on req to build
2228             $c->prepare_path;
2229
2230             # Prepare the body for reading, either by prepare_body
2231             # or the user, if they are using $c->read
2232             $c->prepare_read;
2233
2234             # Parse the body unless the user wants it on-demand
2235             unless ( ref($c)->config->{parse_on_demand} ) {
2236                 $c->prepare_body;
2237             }
2238         }
2239         $c->prepare_action;
2240     }
2241     # VERY ugly and probably shouldn't rely on ->finalize actually working
2242     catch {
2243         # failed prepare is always due to an invalid request, right?
2244         $c->response->status(400);
2245         $c->response->content_type('text/plain');
2246         $c->response->body('Bad Request');
2247         # Note we call finalize and then die here, which escapes
2248         # finalize being called in the enclosing block..
2249         # It in fact couldn't be called, as we don't return $c..
2250         # This is a mess - but I'm unsure you can fix this without
2251         # breaking compat for people doing crazy things (we should set
2252         # the 400 and just return the ctx here IMO, letting finalize get called
2253         # above...
2254         $c->finalize;
2255         die $_;
2256     };
2257
2258     $c->log_request;
2259
2260     return $c;
2261 }
2262
2263 =head2 $c->prepare_action
2264
2265 Prepares action. See L<Catalyst::Dispatcher>.
2266
2267 =cut
2268
2269 sub prepare_action {
2270     my $c = shift;
2271     my $ret = $c->dispatcher->prepare_action( $c, @_);
2272
2273     if($c->encoding) {
2274         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2275           $_ = $c->_handle_param_unicode_decoding($_);
2276         }
2277     }
2278
2279     return $ret;
2280 }
2281
2282
2283 =head2 $c->prepare_body
2284
2285 Prepares message body.
2286
2287 =cut
2288
2289 sub prepare_body {
2290     my $c = shift;
2291
2292     return if $c->request->_has_body;
2293
2294     # Initialize on-demand data
2295     $c->engine->prepare_body( $c, @_ );
2296     $c->prepare_parameters;
2297     $c->prepare_uploads;
2298 }
2299
2300 =head2 $c->prepare_body_chunk( $chunk )
2301
2302 Prepares a chunk of data before sending it to L<HTTP::Body>.
2303
2304 See L<Catalyst::Engine>.
2305
2306 =cut
2307
2308 sub prepare_body_chunk {
2309     my $c = shift;
2310     $c->engine->prepare_body_chunk( $c, @_ );
2311 }
2312
2313 =head2 $c->prepare_body_parameters
2314
2315 Prepares body parameters.
2316
2317 =cut
2318
2319 sub prepare_body_parameters {
2320     my $c = shift;
2321     $c->request->prepare_body_parameters( $c, @_ );
2322 }
2323
2324 =head2 $c->prepare_connection
2325
2326 Prepares connection.
2327
2328 =cut
2329
2330 sub prepare_connection {
2331     my $c = shift;
2332     $c->request->prepare_connection($c);
2333 }
2334
2335 =head2 $c->prepare_cookies
2336
2337 Prepares cookies by ensuring that the attribute on the request
2338 object has been built.
2339
2340 =cut
2341
2342 sub prepare_cookies { my $c = shift; $c->request->cookies }
2343
2344 =head2 $c->prepare_headers
2345
2346 Prepares request headers by ensuring that the attribute on the request
2347 object has been built.
2348
2349 =cut
2350
2351 sub prepare_headers { my $c = shift; $c->request->headers }
2352
2353 =head2 $c->prepare_parameters
2354
2355 Prepares parameters.
2356
2357 =cut
2358
2359 sub prepare_parameters {
2360     my $c = shift;
2361     $c->prepare_body_parameters;
2362     $c->engine->prepare_parameters( $c, @_ );
2363 }
2364
2365 =head2 $c->prepare_path
2366
2367 Prepares path and base.
2368
2369 =cut
2370
2371 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2372
2373 =head2 $c->prepare_query_parameters
2374
2375 Prepares query parameters.
2376
2377 =cut
2378
2379 sub prepare_query_parameters {
2380     my $c = shift;
2381
2382     $c->engine->prepare_query_parameters( $c, @_ );
2383 }
2384
2385 =head2 $c->log_request
2386
2387 Writes information about the request to the debug logs.  This includes:
2388
2389 =over 4
2390
2391 =item * Request method, path, and remote IP address
2392
2393 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2394
2395 =item * Request parameters
2396
2397 =item * File uploads
2398
2399 =back
2400
2401 =cut
2402
2403 sub log_request {
2404     my $c = shift;
2405
2406     return unless $c->debug;
2407
2408     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2409     my $request = $dump->[1];
2410
2411     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2412     $method ||= '';
2413     $path = '/' unless length $path;
2414     $address ||= '';
2415
2416     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2417     $path = decode_utf8($path);
2418
2419     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2420
2421     $c->log_request_headers($request->headers);
2422
2423     if ( my $keywords = $request->query_keywords ) {
2424         $c->log->debug("Query keywords are: $keywords");
2425     }
2426
2427     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2428
2429     $c->log_request_uploads($request);
2430 }
2431
2432 =head2 $c->log_response
2433
2434 Writes information about the response to the debug logs by calling
2435 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2436
2437 =cut
2438
2439 sub log_response {
2440     my $c = shift;
2441
2442     return unless $c->debug;
2443
2444     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2445     my $response = $dump->[1];
2446
2447     $c->log_response_status_line($response);
2448     $c->log_response_headers($response->headers);
2449 }
2450
2451 =head2 $c->log_response_status_line($response)
2452
2453 Writes one line of information about the response to the debug logs.  This includes:
2454
2455 =over 4
2456
2457 =item * Response status code
2458
2459 =item * Content-Type header (if present)
2460
2461 =item * Content-Length header (if present)
2462
2463 =back
2464
2465 =cut
2466
2467 sub log_response_status_line {
2468     my ($c, $response) = @_;
2469
2470     $c->log->debug(
2471         sprintf(
2472             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2473             $response->status                            || 'unknown',
2474             $response->headers->header('Content-Type')   || 'unknown',
2475             $response->headers->header('Content-Length') || 'unknown'
2476         )
2477     );
2478 }
2479
2480 =head2 $c->log_response_headers($headers);
2481
2482 Hook method which can be wrapped by plugins to log the response headers.
2483 No-op in the default implementation.
2484
2485 =cut
2486
2487 sub log_response_headers {}
2488
2489 =head2 $c->log_request_parameters( query => {}, body => {} )
2490
2491 Logs request parameters to debug logs
2492
2493 =cut
2494
2495 sub log_request_parameters {
2496     my $c          = shift;
2497     my %all_params = @_;
2498
2499     return unless $c->debug;
2500
2501     my $column_width = Catalyst::Utils::term_width() - 44;
2502     foreach my $type (qw(query body)) {
2503         my $params = $all_params{$type};
2504         next if ! keys %$params;
2505         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2506         for my $key ( sort keys %$params ) {
2507             my $param = $params->{$key};
2508             my $value = defined($param) ? $param : '';
2509             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2510         }
2511         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2512     }
2513 }
2514
2515 =head2 $c->log_request_uploads
2516
2517 Logs file uploads included in the request to the debug logs.
2518 The parameter name, filename, file type, and file size are all included in
2519 the debug logs.
2520
2521 =cut
2522
2523 sub log_request_uploads {
2524     my $c = shift;
2525     my $request = shift;
2526     return unless $c->debug;
2527     my $uploads = $request->uploads;
2528     if ( keys %$uploads ) {
2529         my $t = Text::SimpleTable->new(
2530             [ 12, 'Parameter' ],
2531             [ 26, 'Filename' ],
2532             [ 18, 'Type' ],
2533             [ 9,  'Size' ]
2534         );
2535         for my $key ( sort keys %$uploads ) {
2536             my $upload = $uploads->{$key};
2537             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2538                 $t->row( $key, $u->filename, $u->type, $u->size );
2539             }
2540         }
2541         $c->log->debug( "File Uploads are:\n" . $t->draw );
2542     }
2543 }
2544
2545 =head2 $c->log_request_headers($headers);
2546
2547 Hook method which can be wrapped by plugins to log the request headers.
2548 No-op in the default implementation.
2549
2550 =cut
2551
2552 sub log_request_headers {}
2553
2554 =head2 $c->log_headers($type => $headers)
2555
2556 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2557
2558 =cut
2559
2560 sub log_headers {
2561     my $c       = shift;
2562     my $type    = shift;
2563     my $headers = shift;    # an HTTP::Headers instance
2564
2565     return unless $c->debug;
2566
2567     my $column_width = Catalyst::Utils::term_width() - 28;
2568     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2569     $headers->scan(
2570         sub {
2571             my ( $name, $value ) = @_;
2572             $t->row( $name, $value );
2573         }
2574     );
2575     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2576 }
2577
2578
2579 =head2 $c->prepare_read
2580
2581 Prepares the input for reading.
2582
2583 =cut
2584
2585 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2586
2587 =head2 $c->prepare_request
2588
2589 Prepares the engine request.
2590
2591 =cut
2592
2593 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2594
2595 =head2 $c->prepare_uploads
2596
2597 Prepares uploads.
2598
2599 =cut
2600
2601 sub prepare_uploads {
2602     my $c = shift;
2603     $c->engine->prepare_uploads( $c, @_ );
2604 }
2605
2606 =head2 $c->prepare_write
2607
2608 Prepares the output for writing.
2609
2610 =cut
2611
2612 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2613
2614 =head2 $c->request_class
2615
2616 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2617
2618 =head2 $c->response_class
2619
2620 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2621
2622 =head2 $c->read( [$maxlength] )
2623
2624 Reads a chunk of data from the request body. This method is designed to
2625 be used in a while loop, reading C<$maxlength> bytes on every call.
2626 C<$maxlength> defaults to the size of the request if not specified.
2627
2628 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2629 directly.
2630
2631 Warning: If you use read(), Catalyst will not process the body,
2632 so you will not be able to access POST parameters or file uploads via
2633 $c->request.  You must handle all body parsing yourself.
2634
2635 =cut
2636
2637 sub read { my $c = shift; return $c->request->read( @_ ) }
2638
2639 =head2 $c->run
2640
2641 Starts the engine.
2642
2643 =cut
2644
2645 sub run {
2646   my $app = shift;
2647   $app->_make_immutable_if_needed;
2648   $app->engine_loader->needs_psgi_engine_compat_hack ?
2649     $app->engine->run($app, @_) :
2650       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2651 }
2652
2653 sub _make_immutable_if_needed {
2654     my $class = shift;
2655     my $meta = find_meta($class);
2656     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2657     if (
2658         $meta->is_immutable
2659         && ! { $meta->immutable_options }->{replace_constructor}
2660         && $isa_ca
2661     ) {
2662         warn("You made your application class ($class) immutable, "
2663             . "but did not inline the\nconstructor. "
2664             . "This will break catalyst, as your app \@ISA "
2665             . "Class::Accessor(::Fast)?\nPlease pass "
2666             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2667     }
2668     unless ($meta->is_immutable) {
2669         # XXX - FIXME warning here as you should make your app immutable yourself.
2670         $meta->make_immutable(
2671             replace_constructor => 1,
2672         );
2673     }
2674 }
2675
2676 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2677
2678 Sets an action in a given namespace.
2679
2680 =cut
2681
2682 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2683
2684 =head2 $c->setup_actions($component)
2685
2686 Sets up actions for a component.
2687
2688 =cut
2689
2690 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2691
2692 =head2 $c->setup_components
2693
2694 This method is called internally to set up the application's components.
2695
2696 It finds modules by calling the L<locate_components> method, expands them to
2697 package names with the L<expand_component_module> method, and then installs
2698 each component into the application.
2699
2700 The C<setup_components> config option is passed to both of the above methods.
2701
2702 Installation of each component is performed by the L<setup_component> method,
2703 below.
2704
2705 =cut
2706
2707 sub setup_components {
2708     my $class = shift;
2709
2710     my $config  = $class->config->{ setup_components };
2711
2712     my @comps = $class->locate_components($config);
2713     my %comps = map { $_ => 1 } @comps;
2714
2715     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2716     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2717         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2718     ) if $deprecatedcatalyst_component_names;
2719
2720     for my $component ( @comps ) {
2721
2722         # We pass ignore_loaded here so that overlay files for (e.g.)
2723         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2724         # we know M::P::O found a file on disk so this is safe
2725
2726         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2727     }
2728
2729     for my $component (@comps) {
2730         my $instance = $class->components->{ $component } = $class->setup_component($component);
2731         my @expanded_components = $instance->can('expand_modules')
2732             ? $instance->expand_modules( $component, $config )
2733             : $class->expand_component_module( $component, $config );
2734         for my $component (@expanded_components) {
2735             next if $comps{$component};
2736             $class->components->{ $component } = $class->setup_component($component);
2737         }
2738     }
2739 }
2740
2741 =head2 $c->locate_components( $setup_component_config )
2742
2743 This method is meant to provide a list of component modules that should be
2744 setup for the application.  By default, it will use L<Module::Pluggable>.
2745
2746 Specify a C<setup_components> config option to pass additional options directly
2747 to L<Module::Pluggable>. To add additional search paths, specify a key named
2748 C<search_extra> as an array reference. Items in the array beginning with C<::>
2749 will have the application class name prepended to them.
2750
2751 =cut
2752
2753 sub locate_components {
2754     my $class  = shift;
2755     my $config = shift;
2756
2757     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2758     my $extra   = delete $config->{ search_extra } || [];
2759
2760     unshift @paths, @$extra;
2761
2762     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2763       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2764       %$config
2765     )->plugins } @paths;
2766
2767     return @comps;
2768 }
2769
2770 =head2 $c->expand_component_module( $component, $setup_component_config )
2771
2772 Components found by C<locate_components> will be passed to this method, which
2773 is expected to return a list of component (package) names to be set up.
2774
2775 =cut
2776
2777 sub expand_component_module {
2778     my ($class, $module) = @_;
2779     return Devel::InnerPackage::list_packages( $module );
2780 }
2781
2782 =head2 $c->setup_component
2783
2784 =cut
2785
2786 sub setup_component {
2787     my( $class, $component ) = @_;
2788
2789     unless ( $component->can( 'COMPONENT' ) ) {
2790         return $component;
2791     }
2792
2793     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2794     my $config = $class->config->{ $suffix } || {};
2795     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2796     # methods also pass it. local to avoid pointlessly shitting in config
2797     # for the debug screen, as $component is already the key name.
2798     local $config->{catalyst_component_name} = $component;
2799
2800     my $instance = eval { $component->COMPONENT( $class, $config ); };
2801
2802     if ( my $error = $@ ) {
2803         chomp $error;
2804         Catalyst::Exception->throw(
2805             message => qq/Couldn't instantiate component "$component", "$error"/
2806         );
2807     }
2808
2809     unless (blessed $instance) {
2810         my $metaclass = Moose::Util::find_meta($component);
2811         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2812         my $component_method_from = $method_meta->associated_metaclass->name;
2813         my $value = defined($instance) ? $instance : 'undef';
2814         Catalyst::Exception->throw(
2815             message =>
2816             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2817         );
2818     }
2819     return $instance;
2820 }
2821
2822 =head2 $c->setup_dispatcher
2823
2824 Sets up dispatcher.
2825
2826 =cut
2827
2828 sub setup_dispatcher {
2829     my ( $class, $dispatcher ) = @_;
2830
2831     if ($dispatcher) {
2832         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2833     }
2834
2835     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2836         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2837     }
2838
2839     unless ($dispatcher) {
2840         $dispatcher = $class->dispatcher_class;
2841     }
2842
2843     load_class($dispatcher);
2844
2845     # dispatcher instance
2846     $class->dispatcher( $dispatcher->new );
2847 }
2848
2849 =head2 $c->setup_engine
2850
2851 Sets up engine.
2852
2853 =cut
2854
2855 sub engine_class {
2856     my ($class, $requested_engine) = @_;
2857
2858     if (!$class->engine_loader || $requested_engine) {
2859         $class->engine_loader(
2860             Catalyst::EngineLoader->new({
2861                 application_name => $class,
2862                 (defined $requested_engine
2863                      ? (catalyst_engine_class => $requested_engine) : ()),
2864             }),
2865         );
2866     }
2867
2868     $class->engine_loader->catalyst_engine_class;
2869 }
2870
2871 sub setup_engine {
2872     my ($class, $requested_engine) = @_;
2873
2874     my $engine = do {
2875         my $loader = $class->engine_loader;
2876
2877         if (!$loader || $requested_engine) {
2878             $loader = Catalyst::EngineLoader->new({
2879                 application_name => $class,
2880                 (defined $requested_engine
2881                      ? (requested_engine => $requested_engine) : ()),
2882             }),
2883
2884             $class->engine_loader($loader);
2885         }
2886
2887         $loader->catalyst_engine_class;
2888     };
2889
2890     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2891     return if $class->loading_psgi_file;
2892
2893     load_class($engine);
2894
2895     if ($ENV{MOD_PERL}) {
2896         my $apache = $class->engine_loader->auto;
2897
2898         my $meta = find_meta($class);
2899         my $was_immutable = $meta->is_immutable;
2900         my %immutable_options = $meta->immutable_options;
2901         $meta->make_mutable if $was_immutable;
2902
2903         $meta->add_method(handler => sub {
2904             my $r = shift;
2905             my $psgi_app = $class->_finalized_psgi_app;
2906             $apache->call_app($r, $psgi_app);
2907         });
2908
2909         $meta->make_immutable(%immutable_options) if $was_immutable;
2910     }
2911
2912     $class->engine( $engine->new );
2913
2914     return;
2915 }
2916
2917 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2918 ## build in server support (back compat support for pre psgi port behavior).
2919 ## This is so that we don't build a new psgi app for each request when using
2920 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2921
2922 sub _finalized_psgi_app {
2923     my ($app) = @_;
2924
2925     unless ($app->_psgi_app) {
2926         my $psgi_app = $app->_setup_psgi_app;
2927         $app->_psgi_app($psgi_app);
2928     }
2929
2930     return $app->_psgi_app;
2931 }
2932
2933 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2934 ## home directory and load that and return it (just assume it is doing the
2935 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2936 ## in default_middleware and return it ( this is for backward compatibility
2937 ## with pre psgi port behavior ).
2938
2939 sub _setup_psgi_app {
2940     my ($app) = @_;
2941
2942     for my $home (Path::Class::Dir->new($app->config->{home})) {
2943         my $psgi_file = $home->file(
2944             Catalyst::Utils::appprefix($app) . '.psgi',
2945         );
2946
2947         next unless -e $psgi_file;
2948
2949         # If $psgi_file calls ->setup_engine, it's doing so to load
2950         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2951         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2952         # anyway. So set a flag (ick) that tells setup_engine not to populate
2953         # $c->engine or do any other things we might regret.
2954
2955         $app->loading_psgi_file(1);
2956         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2957         $app->loading_psgi_file(0);
2958
2959         return $psgi_app
2960             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2961
2962         warn <<"EOW";
2963 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2964
2965 Its content has been ignored. Please consult the Catalyst::Upgrading
2966 documentation on how to upgrade from Catalyst::Engine::PSGI.
2967 EOW
2968     }
2969
2970     return $app->apply_default_middlewares($app->psgi_app);
2971 }
2972
2973 =head2 $c->apply_default_middlewares
2974
2975 Adds the following L<Plack> middlewares to your application, since they are
2976 useful and commonly needed:
2977
2978 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2979 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2980 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2981 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2982 applied since this middleware is smart enough to conditionally apply itself).
2983
2984 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2985 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2986 $ENV{SCRIPT_NAME}
2987
2988 =cut
2989
2990
2991 sub apply_default_middlewares {
2992     my ($app, $psgi_app) = @_;
2993
2994     $psgi_app = Plack::Middleware::Conditional->wrap(
2995         $psgi_app,
2996         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2997         condition => sub {
2998             my ($env) = @_;
2999             return if $app->config->{ignore_frontend_proxy};
3000             return $env->{REMOTE_ADDR} eq '127.0.0.1'
3001                 || $app->config->{using_frontend_proxy};
3002         },
3003     );
3004
3005     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3006     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3007     $psgi_app = Plack::Middleware::Conditional->wrap(
3008         $psgi_app,
3009         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3010         condition => sub {
3011             my ($env) = @_;
3012             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3013             return unless $1 < 4.23;
3014             1;
3015         },
3016     );
3017
3018     # we're applying this unconditionally as the middleware itself already makes
3019     # sure it doesn't fuck things up if it's not running under one of the right
3020     # IIS versions
3021     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3022
3023     # And another IIS issue, this time with IIS7.
3024     $psgi_app = Plack::Middleware::Conditional->wrap(
3025         $psgi_app,
3026         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3027         condition => sub {
3028             my ($env) = @_;
3029             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3030         },
3031     );
3032
3033     return $psgi_app;
3034 }
3035
3036 =head2 App->psgi_app
3037
3038 =head2 App->to_app
3039
3040 Returns a PSGI application code reference for the catalyst application
3041 C<$c>. This is the bare application without any middlewares
3042 applied. C<${myapp}.psgi> is not taken into account.
3043
3044 This is what you want to be using to retrieve the PSGI application code
3045 reference of your Catalyst application for use in F<.psgi> files.
3046
3047 =cut
3048
3049 *to_app = \&psgi_app;
3050
3051 sub psgi_app {
3052     my ($app) = @_;
3053     my $psgi = $app->engine->build_psgi_app($app);
3054     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3055 }
3056
3057 =head2 $c->setup_home
3058
3059 Sets up the home directory.
3060
3061 =cut
3062
3063 sub setup_home {
3064     my ( $class, $home ) = @_;
3065
3066     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3067         $home = $env;
3068     }
3069
3070     $home ||= Catalyst::Utils::home($class);
3071
3072     if ($home) {
3073         #I remember recently being scolded for assigning config values like this
3074         $class->config->{home} ||= $home;
3075         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3076     }
3077 }
3078
3079 =head2 $c->setup_encoding
3080
3081 Sets up the input/output encoding.  See L<ENCODING>
3082
3083 =cut
3084
3085 sub setup_encoding {
3086     my $c = shift;
3087     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3088         # Ok, so the user has explicitly said "I don't want encoding..."
3089         return;
3090     } else {
3091       my $enc = defined($c->config->{encoding}) ?
3092         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3093       $c->encoding($enc);
3094     }
3095 }
3096
3097 =head2 handle_unicode_encoding_exception
3098
3099 Hook to let you customize how encoding errors are handled.  By default
3100 we just throw an exception.  Receives a hashref of debug information.
3101 Example:
3102
3103     $c->handle_unicode_encoding_exception({
3104         param_value => $value,
3105         error_msg => $_,
3106             encoding_step => 'params',
3107         });
3108
3109 =cut
3110
3111 sub handle_unicode_encoding_exception {
3112     my ( $self, $exception_ctx ) = @_;
3113     die $exception_ctx->{error_msg};
3114 }
3115
3116 # Some unicode helpers cargo culted from the old plugin.  These could likely
3117 # be neater.
3118
3119 sub _handle_unicode_decoding {
3120     my ( $self, $value ) = @_;
3121
3122     return unless defined $value;
3123
3124     ## I think this mess is to support the old nested
3125     if ( ref $value eq 'ARRAY' ) {
3126         foreach ( @$value ) {
3127             $_ = $self->_handle_unicode_decoding($_);
3128         }
3129         return $value;
3130     }
3131     elsif ( ref $value eq 'HASH' ) {
3132         foreach (keys %$value) {
3133             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3134             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3135
3136             # If the key was encoded we now have two (the original and current so
3137             # delete the original.
3138             delete $value->{$_} if $_ ne $encoded_key;
3139         }
3140         return $value;
3141     }
3142     else {
3143         return $self->_handle_param_unicode_decoding($value);
3144     }
3145 }
3146
3147 sub _handle_param_unicode_decoding {
3148     my ( $self, $value ) = @_;
3149     return unless defined $value; # not in love with just ignoring undefs - jnap
3150
3151     my $enc = $self->encoding;
3152     return try {
3153       $enc->decode( $value, $self->_encode_check );
3154     }
3155     catch {
3156         $self->handle_unicode_encoding_exception({
3157             param_value => $value,
3158             error_msg => $_,
3159             encoding_step => 'params',
3160         });
3161     };
3162 }
3163
3164 =head2 $c->setup_log
3165
3166 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3167 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3168 log to.
3169
3170 This method also installs a C<debug> method that returns a true value into the
3171 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3172 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3173
3174 Note that if the log has already been setup, by either a previous call to
3175 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3176 that this method won't actually set up the log object.
3177
3178 =cut
3179
3180 sub setup_log {
3181     my ( $class, $levels ) = @_;
3182
3183     $levels ||= '';
3184     $levels =~ s/^\s+//;
3185     $levels =~ s/\s+$//;
3186     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3187
3188     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3189     if ( defined $env_debug ) {
3190         $levels{debug} = 1 if $env_debug; # Ugly!
3191         delete($levels{debug}) unless $env_debug;
3192     }
3193
3194     unless ( $class->log ) {
3195         $class->log( Catalyst::Log->new(keys %levels) );
3196     }
3197
3198     if ( $levels{debug} ) {
3199         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3200         $class->log->debug('Debug messages enabled');
3201     }
3202 }
3203
3204 =head2 $c->setup_plugins
3205
3206 Sets up plugins.
3207
3208 =cut
3209
3210 =head2 $c->setup_stats
3211
3212 Sets up timing statistics class.
3213
3214 =cut
3215
3216 sub setup_stats {
3217     my ( $class, $stats ) = @_;
3218
3219     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3220
3221     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3222     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3223         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3224         $class->log->debug('Statistics enabled');
3225     }
3226 }
3227
3228
3229 =head2 $c->registered_plugins
3230
3231 Returns a sorted list of the plugins which have either been stated in the
3232 import list.
3233
3234 If passed a given plugin name, it will report a boolean value indicating
3235 whether or not that plugin is loaded.  A fully qualified name is required if
3236 the plugin name does not begin with C<Catalyst::Plugin::>.
3237
3238  if ($c->registered_plugins('Some::Plugin')) {
3239      ...
3240  }
3241
3242 =cut
3243
3244 {
3245
3246     sub registered_plugins {
3247         my $proto = shift;
3248         return sort keys %{ $proto->_plugins } unless @_;
3249         my $plugin = shift;
3250         return 1 if exists $proto->_plugins->{$plugin};
3251         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3252     }
3253
3254     sub _register_plugin {
3255         my ( $proto, $plugin, $instant ) = @_;
3256         my $class = ref $proto || $proto;
3257
3258         load_class( $plugin );
3259         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3260             if $plugin->isa( 'Catalyst::Component' );
3261         my $plugin_meta = Moose::Meta::Class->create($plugin);
3262         if (!$plugin_meta->has_method('new')
3263             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3264             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3265         }
3266         if (!$instant && !$proto->_plugins->{$plugin}) {
3267             my $meta = Class::MOP::get_metaclass_by_name($class);
3268             $meta->superclasses($plugin, $meta->superclasses);
3269         }
3270         $proto->_plugins->{$plugin} = 1;
3271         return $class;
3272     }
3273
3274     sub _default_plugins { return qw() }
3275
3276     sub setup_plugins {
3277         my ( $class, $plugins ) = @_;
3278
3279         $class->_plugins( {} ) unless $class->_plugins;
3280         $plugins = [ grep {
3281             m/Unicode::Encoding/ ? do {
3282                 $class->log->warn(
3283                     'Unicode::Encoding plugin is auto-applied,'
3284                     . ' please remove this from your appclass'
3285                     . ' and make sure to define "encoding" config'
3286                 );
3287                 unless (exists $class->config->{'encoding'}) {
3288                   $class->config->{'encoding'} = 'UTF-8';
3289                 }
3290                 () }
3291                 : $_
3292         } @$plugins ];
3293         push @$plugins, $class->_default_plugins;
3294         $plugins = Data::OptList::mkopt($plugins || []);
3295
3296         my @plugins = map {
3297             [ Catalyst::Utils::resolve_namespace(
3298                   $class . '::Plugin',
3299                   'Catalyst::Plugin', $_->[0]
3300               ),
3301               $_->[1],
3302             ]
3303          } @{ $plugins };
3304
3305         for my $plugin ( reverse @plugins ) {
3306             load_class($plugin->[0], $plugin->[1]);
3307             my $meta = find_meta($plugin->[0]);
3308             next if $meta && $meta->isa('Moose::Meta::Role');
3309
3310             $class->_register_plugin($plugin->[0]);
3311         }
3312
3313         my @roles =
3314             map  { $_->[0]->name, $_->[1] }
3315             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3316             map  { [find_meta($_->[0]), $_->[1]] }
3317             @plugins;
3318
3319         Moose::Util::apply_all_roles(
3320             $class => @roles
3321         ) if @roles;
3322     }
3323 }
3324
3325 =head2 registered_middlewares
3326
3327 Read only accessor that returns an array of all the middleware in the order
3328 that they were added (which is the REVERSE of the order they will be applied).
3329
3330 The values returned will be either instances of L<Plack::Middleware> or of a
3331 compatible interface, or a coderef, which is assumed to be inlined middleware
3332
3333 =head2 setup_middleware (?@middleware)
3334
3335 Read configuration information stored in configuration key C<psgi_middleware> or
3336 from passed @args.
3337
3338 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3339 to use it to enable L<Plack::Middleware>
3340
3341 This method is automatically called during 'setup' of your application, so
3342 you really don't need to invoke it.  However you may do so if you find the idea
3343 of loading middleware via configuration weird :).  For example:
3344
3345     package MyApp;
3346
3347     use Catalyst;
3348
3349     __PACKAGE__->setup_middleware('Head');
3350     __PACKAGE__->setup;
3351
3352 When we read middleware definitions from configuration, we reverse the list
3353 which sounds odd but is likely how you expect it to work if you have prior
3354 experience with L<Plack::Builder> or if you previously used the plugin
3355 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3356
3357 So basically your middleware handles an incoming request from the first
3358 registered middleware, down and handles the response from the last middleware
3359 up.
3360
3361 =cut
3362
3363 sub registered_middlewares {
3364     my $class = shift;
3365     if(my $middleware = $class->_psgi_middleware) {
3366         return (
3367           Catalyst::Middleware::Stash->new,
3368           Plack::Middleware::HTTPExceptions->new,
3369           Plack::Middleware::RemoveRedundantBody->new,
3370           Plack::Middleware::FixMissingBodyInRedirect->new,
3371           Plack::Middleware::ContentLength->new,
3372           Plack::Middleware::MethodOverride->new,
3373           Plack::Middleware::Head->new,
3374           @$middleware);
3375     } else {
3376         die "You cannot call ->registered_middlewares until middleware has been setup";
3377     }
3378 }
3379
3380 sub setup_middleware {
3381     my $class = shift;
3382     my @middleware_definitions = @_ ?
3383       reverse(@_) : reverse(@{$class->config->{'psgi_middleware'}||[]});
3384
3385     my @middleware = ();
3386     while(my $next = shift(@middleware_definitions)) {
3387         if(ref $next) {
3388             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3389                 push @middleware, $next;
3390             } elsif(ref $next eq 'CODE') {
3391                 push @middleware, $next;
3392             } elsif(ref $next eq 'HASH') {
3393                 my $namespace = shift @middleware_definitions;
3394                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3395                 push @middleware, $mw;
3396             } else {
3397               die "I can't handle middleware definition ${\ref $next}";
3398             }
3399         } else {
3400           my $mw = $class->Catalyst::Utils::build_middleware($next);
3401           push @middleware, $mw;
3402         }
3403     }
3404
3405     my @existing = @{$class->_psgi_middleware || []};
3406     $class->_psgi_middleware([@middleware,@existing,]);
3407 }
3408
3409 =head2 registered_data_handlers
3410
3411 A read only copy of registered Data Handlers returned as a Hash, where each key
3412 is a content type and each value is a subref that attempts to decode that content
3413 type.
3414
3415 =head2 setup_data_handlers (?@data_handler)
3416
3417 Read configuration information stored in configuration key C<data_handlers> or
3418 from passed @args.
3419
3420 See under L</CONFIGURATION> information regarding C<data_handlers>.
3421
3422 This method is automatically called during 'setup' of your application, so
3423 you really don't need to invoke it.
3424
3425 =head2 default_data_handlers
3426
3427 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3428 only two default data handlers, for 'application/json' and an alternative to
3429 'application/x-www-form-urlencoded' which supposed nested form parameters via
3430 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3431
3432 The 'application/json' data handler is used to parse incoming JSON into a Perl
3433 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3434 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3435 JSON decoder, and has the smallest dependency impact.
3436
3437 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3438 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3439 order to get the best performance.  You should add either to your dependency
3440 list (Makefile.PL, dist.ini, cpanfile, etc.)
3441
3442 =cut
3443
3444 sub registered_data_handlers {
3445     my $class = shift;
3446     if(my $data_handlers = $class->_data_handlers) {
3447         return %$data_handlers;
3448     } else {
3449         $class->setup_data_handlers;
3450         return $class->registered_data_handlers;
3451     }
3452 }
3453
3454 sub setup_data_handlers {
3455     my ($class, %data_handler_callbacks) = @_;
3456     %data_handler_callbacks = (
3457       %{$class->default_data_handlers},
3458       %{$class->config->{'data_handlers'}||+{}},
3459       %data_handler_callbacks);
3460
3461     $class->_data_handlers(\%data_handler_callbacks);
3462 }
3463
3464 sub default_data_handlers {
3465     my ($class) = @_;
3466     return +{
3467       'application/x-www-form-urlencoded' => sub {
3468           my ($fh, $req) = @_;
3469           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3470           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3471             ->can('build_cgi_struct')->($params);
3472       },
3473       'application/json' => sub {
3474           Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON')
3475             ->can('decode_json')->(do { local $/; $_->getline });
3476       },
3477     };
3478 }
3479
3480 =head2 $c->stack
3481
3482 Returns an arrayref of the internal execution stack (actions that are
3483 currently executing).
3484
3485 =head2 $c->stats
3486
3487 Returns the current timing statistics object. By default Catalyst uses
3488 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3489 L<< stats_class|/"$c->stats_class" >>.
3490
3491 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3492 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3493 profile explicitly, although MyApp.pm still won't profile nor output anything
3494 by itself.
3495
3496 =head2 $c->stats_class
3497
3498 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3499
3500 =head2 $c->use_stats
3501
3502 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3503
3504 Note that this is a static method, not an accessor and should be overridden
3505 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3506
3507 =cut
3508
3509 sub use_stats { 0 }
3510
3511
3512 =head2 $c->write( $data )
3513
3514 Writes $data to the output stream. When using this method directly, you
3515 will need to manually set the C<Content-Length> header to the length of
3516 your output data, if known.
3517
3518 =cut
3519
3520 sub write {
3521     my $c = shift;
3522
3523     # Finalize headers if someone manually writes output (for compat)
3524     $c->finalize_headers;
3525
3526     return $c->response->write( @_ );
3527 }
3528
3529 =head2 version
3530
3531 Returns the Catalyst version number. Mostly useful for "powered by"
3532 messages in template systems.
3533
3534 =cut
3535
3536 sub version { return $Catalyst::VERSION }
3537
3538 =head1 CONFIGURATION
3539
3540 There are a number of 'base' config variables which can be set:
3541
3542 =over
3543
3544 =item *
3545
3546 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3547
3548 =item *
3549
3550 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3551
3552 =item *
3553
3554 C<disable_component_resolution_regex_fallback> - Turns
3555 off the deprecated component resolution functionality so
3556 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3557 are called then regex search will not be attempted on string values and
3558 instead C<undef> will be returned.
3559
3560 =item *
3561
3562 C<home> - The application home directory. In an uninstalled application,
3563 this is the top level application directory. In an installed application,
3564 this will be the directory containing C<< MyApp.pm >>.
3565
3566 =item *
3567
3568 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3569
3570 =item *
3571
3572 C<name> - The name of the application in debug messages and the debug and
3573 welcome screens
3574
3575 =item *
3576
3577 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3578 until it is accessed. This allows you to (for example) check authentication (and reject
3579 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3580
3581 =item *
3582
3583 C<root> - The root directory for templates. Usually this is just a
3584 subdirectory of the home directory, but you can set it to change the
3585 templates to a different directory.
3586
3587 =item *
3588
3589 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3590 namespaces from which components will be loaded (and constructed and stored in
3591 C<< $c->components >>).
3592
3593 =item *
3594
3595 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3596 to be shown in hit debug tables in the test server.
3597
3598 =item *
3599
3600 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3601 variable should be used for determining the request path.
3602
3603 Most web server environments pass the requested path to the application using environment variables,
3604 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3605 exposed as C<< $c->request->base >>) and the request path below that base.
3606
3607 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3608 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3609
3610 =over
3611
3612 =item use_request_uri_for_path => 0
3613
3614 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3615 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3616 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3617 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3618
3619 However this method has the major disadvantage that it is impossible to correctly decode some elements
3620 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3621 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3622 can't distinguish / vs %2F in paths (in addition to other encoded values).
3623
3624 =item use_request_uri_for_path => 1
3625
3626 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3627 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3628 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3629
3630 Given that this method of path resolution is provably more correct, it is recommended that you use
3631 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3632 aware of the implications of not being able to handle encoded URI paths correctly.
3633
3634 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3635 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3636 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3637 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3638 C<< $c->request->base >> will be incorrect.
3639
3640 =back
3641
3642 =item *
3643
3644 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3645
3646 =item *
3647
3648 C<encoding> - See L</ENCODING>
3649
3650 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
3651 value to undef.
3652
3653 =item *
3654
3655 C<abort_chain_on_error_fix>
3656
3657 When there is an error in an action chain, the default behavior is to continue
3658 processing the remaining actions and then catch the error upon chain end.  This
3659 can lead to running actions when the application is in an unexpected state.  If
3660 you have this issue, setting this config value to true will promptly exit a
3661 chain when there is an error raised in any action (thus terminating the chain
3662 early.)
3663
3664 use like:
3665
3666     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3667
3668 In the future this might become the default behavior.
3669
3670 =item *
3671
3672 C<use_hash_multivalue_in_request>
3673
3674 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3675 and C<parameters> return a hashref where values might be scalar or an arrayref
3676 depending on the incoming data.  In many cases this can be undesirable as it
3677 leads one to writing defensive code like the following:
3678
3679     my ($val) = ref($c->req->parameters->{a}) ?
3680       @{$c->req->parameters->{a}} :
3681         $c->req->parameters->{a};
3682
3683 Setting this configuration item to true will make L<Catalyst> populate the
3684 attributes underlying these methods with an instance of L<Hash::MultiValue>
3685 which is used by L<Plack::Request> and others to solve this very issue.  You
3686 may prefer this behavior to the default, if so enable this option (be warned
3687 if you enable it in a legacy application we are not sure if it is completely
3688 backwardly compatible).
3689
3690 =item *
3691
3692 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3693
3694 =item *
3695
3696 C<data_handlers> - See L<DATA HANDLERS>.
3697
3698 =back
3699
3700 =head1 EXCEPTIONS
3701
3702 Generally when you throw an exception inside an Action (or somewhere in
3703 your stack, such as in a model that an Action is calling) that exception
3704 is caught by Catalyst and unless you either catch it yourself (via eval
3705 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3706 will eventually reach L</finalize_errors> and return either the debugging
3707 error stack page, or the default error page.  However, if your exception
3708 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3709 instead rethrow it so that it can be handled by that middleware (which
3710 is part of the default middleware).  For example this would allow
3711
3712     use HTTP::Throwable::Factory 'http_throw';
3713
3714     sub throws_exception :Local {
3715       my ($self, $c) = @_;
3716
3717       http_throw(SeeOther => { location =>
3718         $c->uri_for($self->action_for('redirect')) });
3719
3720     }
3721
3722 =head1 INTERNAL ACTIONS
3723
3724 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3725 C<_ACTION>, and C<_END>. These are by default not shown in the private
3726 action table, but you can make them visible with a config parameter.
3727
3728     MyApp->config(show_internal_actions => 1);
3729
3730 =head1 ON-DEMAND PARSER
3731
3732 The request body is usually parsed at the beginning of a request,
3733 but if you want to handle input yourself, you can enable on-demand
3734 parsing with a config parameter.
3735
3736     MyApp->config(parse_on_demand => 1);
3737
3738 =head1 PROXY SUPPORT
3739
3740 Many production servers operate using the common double-server approach,
3741 with a lightweight frontend web server passing requests to a larger
3742 backend server. An application running on the backend server must deal
3743 with two problems: the remote user always appears to be C<127.0.0.1> and
3744 the server's hostname will appear to be C<localhost> regardless of the
3745 virtual host that the user connected through.
3746
3747 Catalyst will automatically detect this situation when you are running
3748 the frontend and backend servers on the same machine. The following
3749 changes are made to the request.
3750
3751     $c->req->address is set to the user's real IP address, as read from
3752     the HTTP X-Forwarded-For header.
3753
3754     The host value for $c->req->base and $c->req->uri is set to the real
3755     host, as read from the HTTP X-Forwarded-Host header.
3756
3757 Additionally, you may be running your backend application on an insecure
3758 connection (port 80) while your frontend proxy is running under SSL.  If there
3759 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3760 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3761 be created properly.
3762
3763 In the case of passing in:
3764
3765     X-Forwarded-Port: 443
3766
3767 All calls to C<uri_for> will result in an https link, as is expected.
3768
3769 Obviously, your web server must support these headers for this to work.
3770
3771 In a more complex server farm environment where you may have your
3772 frontend proxy server(s) on different machines, you will need to set a
3773 configuration option to tell Catalyst to read the proxied data from the
3774 headers.
3775
3776     MyApp->config(using_frontend_proxy => 1);
3777
3778 If you do not wish to use the proxy support at all, you may set:
3779
3780     MyApp->config(ignore_frontend_proxy => 0);
3781
3782 =head2 Note about psgi files
3783
3784 Note that if you supply your own .psgi file, calling
3785 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3786
3787 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3788 in your psgi, for example:
3789
3790     builder {
3791         enable "Plack::Middleware::ReverseProxy";
3792         MyApp->psgi_app
3793     };
3794
3795 This will unconditionally add the ReverseProxy support, or you need to call
3796 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3797 apply the support depending upon your config).
3798
3799 See L<Catalyst::PSGI> for more information.
3800
3801 =head1 THREAD SAFETY
3802
3803 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3804 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3805 believe the Catalyst core to be thread-safe.
3806
3807 If you plan to operate in a threaded environment, remember that all other
3808 modules you are using must also be thread-safe. Some modules, most notably
3809 L<DBD::SQLite>, are not thread-safe.
3810
3811 =head1 DATA HANDLERS
3812
3813 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3814 form parameters and URL search query fields.  However it has become common
3815 for various alternative content types to be PUT or POSTed to your controllers
3816 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3817 XML and other content types when communicating with an application server.  In
3818 order to better support this use case, L<Catalyst> defines a global configuration
3819 option, C<data_handlers>, which lets you associate a content type with a coderef
3820 that parses that content type into something Perl can readily access.
3821
3822     package MyApp::Web;
3823
3824     use Catalyst;
3825     use JSON::Maybe;
3826
3827     __PACKAGE__->config(
3828       data_handlers => {
3829         'application/json' => sub { local $/; decode_json $_->getline },
3830       },
3831       ## Any other configuration.
3832     );
3833
3834     __PACKAGE__->setup;
3835
3836 By default L<Catalyst> comes with a generic JSON data handler similar to the
3837 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3838 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3839 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3840 or dist.ini, cpanfile, etc.)
3841
3842 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
3843 (matched against the incoming request type using a regexp such as to be case
3844 insensitive) and whose values are coderefs that receive a localized version of
3845 C<$_> which is a filehandle object pointing to received body.
3846
3847 This feature is considered an early access release and we reserve the right
3848 to alter the interface in order to provide a performant and secure solution to
3849 alternative request body content.  Your reports welcomed!
3850
3851 =head1 PSGI MIDDLEWARE
3852
3853 You can define middleware, defined as L<Plack::Middleware> or a compatible
3854 interface in configuration.  Your middleware definitions are in the form of an
3855 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3856 with details to follow:
3857
3858     package MyApp::Web;
3859
3860     use Catalyst;
3861     use Plack::Middleware::StackTrace;
3862
3863     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3864
3865     __PACKAGE__->config(
3866       'psgi_middleware', [
3867         'Debug',
3868         '+MyApp::Custom',
3869         $stacktrace_middleware,
3870         'Session' => {store => 'File'},
3871         sub {
3872           my $app = shift;
3873           return sub {
3874             my $env = shift;
3875             $env->{myapp.customkey} = 'helloworld';
3876             $app->($env);
3877           },
3878         },
3879       ],
3880     );
3881
3882     __PACKAGE__->setup;
3883
3884 So the general form is:
3885
3886     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3887
3888 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3889 the order listed (to make it function similarly to L<Plack::Builder>:
3890
3891 Alternatively, you may also define middleware by calling the L</setup_middleware>
3892 package method:
3893
3894     package MyApp::Web;
3895
3896     use Catalyst;
3897
3898     __PACKAGE__->setup_middleware( \@middleware_definitions);
3899     __PACKAGE__->setup;
3900
3901 In the case where you do both (use 'setup_middleware' and configuration) the
3902 package call to setup_middleware will be applied earlier (in other words its
3903 middleware will wrap closer to the application).  Keep this in mind since in
3904 some cases the order of middleware is important.
3905
3906 The two approaches are not exclusive.
3907
3908 =over 4
3909
3910 =item Middleware Object
3911
3912 An already initialized object that conforms to the L<Plack::Middleware>
3913 specification:
3914
3915     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3916
3917     __PACKAGE__->config(
3918       'psgi_middleware', [
3919         $stacktrace_middleware,
3920       ]);
3921
3922
3923 =item coderef
3924
3925 A coderef that is an inlined middleware:
3926
3927     __PACKAGE__->config(
3928       'psgi_middleware', [
3929         sub {
3930           my $app = shift;
3931           return sub {
3932             my $env = shift;
3933             if($env->{PATH_INFO} =~m/forced/) {
3934               Plack::App::File
3935                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3936                 ->call($env);
3937             } else {
3938               return $app->($env);
3939             }
3940          },
3941       },
3942     ]);
3943
3944
3945
3946 =item a scalar
3947
3948 We assume the scalar refers to a namespace after normalizing it using the
3949 following rules:
3950
3951 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3952 is assumed to be 'as is', and we just install and use the middleware.
3953
3954 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3955 (the package name of your Catalyst application subclass), we also assume then
3956 that it is a full namespace, and use it.
3957
3958 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3959 resolve it first by looking for it under your application namespace (for example
3960 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3961 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3962 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3963 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3964 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3965 you find that a good idea.
3966
3967 Examples:
3968
3969     package MyApp::Web;
3970
3971     __PACKAGE__->config(
3972       'psgi_middleware', [
3973         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3974         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3975         '+MyApp::Custom',  ## MyApp::Custom->wrap
3976       ],
3977     );
3978
3979 =item a scalar followed by a hashref
3980
3981 Just like the previous, except the following C<HashRef> is used as arguments
3982 to initialize the middleware object.
3983
3984     __PACKAGE__->config(
3985       'psgi_middleware', [
3986          'Session' => {store => 'File'},
3987     ]);
3988
3989 =back
3990
3991 Please see L<PSGI> for more on middleware.
3992
3993 =head1 ENCODING
3994
3995 On request, decodes all params from encoding into a sequence of
3996 logical characters. On response, encodes body into encoding.
3997
3998 By default encoding is now 'UTF-8'.  You may turn it off by setting
3999 the encoding configuration to undef.
4000
4001 =head2 Methods
4002
4003 =over 4
4004
4005 =item encoding
4006
4007 Returns an instance of an C<Encode> encoding
4008
4009     print $c->encoding->name
4010
4011 =item handle_unicode_encoding_exception ($exception_context)
4012
4013 Method called when decoding process for a request fails.
4014
4015 An C<$exception_context> hashref is provided to allow you to override the
4016 behaviour of your application when given data with incorrect encodings.
4017
4018 The default method throws exceptions in the case of invalid request parameters
4019 (resulting in a 500 error), but ignores errors in upload filenames.
4020
4021 The keys passed in the C<$exception_context> hash are:
4022
4023 =over
4024
4025 =item param_value
4026
4027 The value which was not able to be decoded.
4028
4029 =item error_msg
4030
4031 The exception received from L<Encode>.
4032
4033 =item encoding_step
4034
4035 What type of data was being decoded. Valid values are (currently)
4036 C<params> - for request parameters / arguments / captures
4037 and C<uploads> - for request upload filenames.
4038
4039 =back
4040
4041 =back
4042
4043 =head1 SUPPORT
4044
4045 IRC:
4046
4047     Join #catalyst on irc.perl.org.
4048
4049 Mailing Lists:
4050
4051     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4052     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4053
4054 Web:
4055
4056     http://catalyst.perl.org
4057
4058 Wiki:
4059
4060     http://dev.catalyst.perl.org
4061
4062 =head1 SEE ALSO
4063
4064 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4065
4066 =head2 L<Catalyst::Manual> - The Catalyst Manual
4067
4068 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4069
4070 =head2 L<Catalyst::Engine> - Core engine
4071
4072 =head2 L<Catalyst::Log> - Log class.
4073
4074 =head2 L<Catalyst::Request> - Request object
4075
4076 =head2 L<Catalyst::Response> - Response object
4077
4078 =head2 L<Catalyst::Test> - The test suite.
4079
4080 =head1 PROJECT FOUNDER
4081
4082 sri: Sebastian Riedel <sri@cpan.org>
4083
4084 =head1 CONTRIBUTORS
4085
4086 abw: Andy Wardley
4087
4088 acme: Leon Brocard <leon@astray.com>
4089
4090 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4091
4092 Andrew Bramble
4093
4094 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4095
4096 Andrew Ruthven
4097
4098 andyg: Andy Grundman <andy@hybridized.org>
4099
4100 audreyt: Audrey Tang
4101
4102 bricas: Brian Cassidy <bricas@cpan.org>
4103
4104 Caelum: Rafael Kitover <rkitover@io.com>
4105
4106 chansen: Christian Hansen
4107
4108 chicks: Christopher Hicks
4109
4110 Chisel Wright C<pause@herlpacker.co.uk>
4111
4112 Danijel Milicevic C<me@danijel.de>
4113
4114 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4115
4116 David Naughton, C<naughton@umn.edu>
4117
4118 David E. Wheeler
4119
4120 dhoss: Devin Austin <dhoss@cpan.org>
4121
4122 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4123
4124 Drew Taylor
4125
4126 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4127
4128 esskar: Sascha Kiefer
4129
4130 fireartist: Carl Franks <cfranks@cpan.org>
4131
4132 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4133
4134 gabb: Danijel Milicevic
4135
4136 Gary Ashton Jones
4137
4138 Gavin Henry C<ghenry@perl.me.uk>
4139
4140 Geoff Richards
4141
4142 groditi: Guillermo Roditi <groditi@gmail.com>
4143
4144 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4145
4146 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4147
4148 jcamacho: Juan Camacho
4149
4150 jester: Jesse Sheidlower C<jester@panix.com>
4151
4152 jhannah: Jay Hannah <jay@jays.net>
4153
4154 Jody Belka
4155
4156 Johan Lindstrom
4157
4158 jon: Jon Schutz <jjschutz@cpan.org>
4159
4160 Jonathan Rockway C<< <jrockway@cpan.org> >>
4161
4162 Kieren Diment C<kd@totaldatasolution.com>
4163
4164 konobi: Scott McWhirter <konobi@cpan.org>
4165
4166 marcus: Marcus Ramberg <mramberg@cpan.org>
4167
4168 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4169
4170 mgrimes: Mark Grimes <mgrimes@cpan.org>
4171
4172 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4173
4174 mugwump: Sam Vilain
4175
4176 naughton: David Naughton
4177
4178 ningu: David Kamholz <dkamholz@cpan.org>
4179
4180 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4181
4182 numa: Dan Sully <daniel@cpan.org>
4183
4184 obra: Jesse Vincent
4185
4186 Octavian Rasnita
4187
4188 omega: Andreas Marienborg
4189
4190 Oleg Kostyuk <cub.uanic@gmail.com>
4191
4192 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4193
4194 rafl: Florian Ragwitz <rafl@debian.org>
4195
4196 random: Roland Lammel <lammel@cpan.org>
4197
4198 Robert Sedlacek C<< <rs@474.at> >>
4199
4200 SpiceMan: Marcel Montes
4201
4202 sky: Arthur Bergman
4203
4204 szbalint: Balint Szilakszi <szbalint@cpan.org>
4205
4206 t0m: Tomas Doran <bobtfish@bobtfish.net>
4207
4208 Ulf Edvinsson
4209
4210 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4211
4212 Viljo Marrandi C<vilts@yahoo.com>
4213
4214 Will Hawes C<info@whawes.co.uk>
4215
4216 willert: Sebastian Willert <willert@cpan.org>
4217
4218 wreis: Wallace Reis <wreis@cpan.org>
4219
4220 Yuval Kogman, C<nothingmuch@woobling.org>
4221
4222 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4223
4224 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4225
4226 Upasana <me@upasana.me>
4227
4228 =head1 COPYRIGHT
4229
4230 Copyright (c) 2005-2014, the above named PROJECT FOUNDER and CONTRIBUTORS.
4231
4232 =head1 LICENSE
4233
4234 This library is free software. You can redistribute it and/or modify it under
4235 the same terms as Perl itself.
4236
4237 =cut
4238
4239 no Moose;
4240
4241 __PACKAGE__->meta->make_immutable;
4242
4243 1;