lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         $self->request_class->new($self->_build_request_constructor_args);
  67     },
  68     lazy => 1,
  69 );
  70 sub _build_request_constructor_args {
  71     my $self = shift;
  72     my %p = ( _log => $self->log );
  73     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  74     $p{data_handlers} = {$self->registered_data_handlers};
  75     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  76       if $self->config->{use_hash_multivalue_in_request};
  77     \%p;
  78 }
  79
  80 has response => (
  81     is => 'rw',
  82     default => sub {
  83         my $self = shift;
  84         $self->response_class->new($self->_build_response_constructor_args);
  85     },
  86     lazy => 1,
  87 );
  88 sub _build_response_constructor_args {
  89     return +{
  90       _log => $_[0]->log,
  91       encoding => $_[0]->encoding,
  92     };
  93 }
  94
  95 has namespace => (is => 'rw');
  96
  97 sub depth { scalar @{ shift->stack || [] }; }
  98 sub comp { shift->component(@_) }
  99
 100 sub req {
 101     my $self = shift; return $self->request(@_);
 102 }
 103 sub res {
 104     my $self = shift; return $self->response(@_);
 105 }
 106
 107 # For backwards compatibility
 108 sub finalize_output { shift->finalize_body(@_) };
 109
 110 # For statistics
 111 our $COUNT     = 1;
 112 our $START     = time;
 113 our $RECURSION = 1000;
 114 our $DETACH    = Catalyst::Exception::Detach->new;
 115 our $GO        = Catalyst::Exception::Go->new;
 116
 117 #I imagine that very few of these really need to be class variables. if any.
 118 #maybe we should just make them attributes with a default?
 119 __PACKAGE__->mk_classdata($_)
 120   for qw/components arguments dispatcher engine log dispatcher_class
 121   engine_loader context_class request_class response_class stats_class
 122   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 123   _data_handlers _encoding _encode_check/;
 124
 125 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 126 __PACKAGE__->request_class('Catalyst::Request');
 127 __PACKAGE__->response_class('Catalyst::Response');
 128 __PACKAGE__->stats_class('Catalyst::Stats');
 129 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 130
 131 # Remember to update this in Catalyst::Runtime as well!
 132 our $VERSION = '5.90079_006';
 133 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 134
 135 sub import {
 136     my ( $class, @arguments ) = @_;
 137
 138     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 139     # callers @ISA.
 140     return unless $class eq 'Catalyst';
 141
 142     my $caller = caller();
 143     return if $caller eq 'main';
 144
 145     my $meta = Moose::Meta::Class->initialize($caller);
 146     unless ( $caller->isa('Catalyst') ) {
 147         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 148         $meta->superclasses(@superclasses);
 149     }
 150     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 151     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 152
 153     unless( $meta->has_method('meta') ){
 154         if ($Moose::VERSION >= 1.15) {
 155             $meta->_add_meta_method('meta');
 156         }
 157         else {
 158             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 159         }
 160     }
 161
 162     $caller->arguments( [@arguments] );
 163     $caller->setup_home;
 164 }
 165
 166 sub _application { $_[0] }
 167
 168 =encoding UTF-8
 169
 170 =head1 NAME
 171
 172 Catalyst - The Elegant MVC Web Application Framework
 173
 174 =head1 SYNOPSIS
 175
 176 See the L<Catalyst::Manual> distribution for comprehensive
 177 documentation and tutorials.
 178
 179     # Install Catalyst::Devel for helpers and other development tools
 180     # use the helper to create a new application
 181     catalyst.pl MyApp
 182
 183     # add models, views, controllers
 184     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 185     script/myapp_create.pl view MyTemplate TT
 186     script/myapp_create.pl controller Search
 187
 188     # built in testserver -- use -r to restart automatically on changes
 189     # --help to see all available options
 190     script/myapp_server.pl
 191
 192     # command line testing interface
 193     script/myapp_test.pl /yada
 194
 195     ### in lib/MyApp.pm
 196     use Catalyst qw/-Debug/; # include plugins here as well
 197
 198     ### In lib/MyApp/Controller/Root.pm (autocreated)
 199     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 200         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 201         $c->stash->{template} = 'foo.tt'; # set the template
 202         # lookup something from db -- stash vars are passed to TT
 203         $c->stash->{data} =
 204           $c->model('Database::Foo')->search( { country => $args[0] } );
 205         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 206             $c->forward( 'bar' ); # process another action
 207             # do something else after forward returns
 208         }
 209     }
 210
 211     # The foo.tt TT template can use the stash data from the database
 212     [% WHILE (item = data.next) %]
 213         [% item.foo %]
 214     [% END %]
 215
 216     # called for /bar/of/soap, /bar/of/soap/10, etc.
 217     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 218
 219     # called after all actions are finished
 220     sub end : Action {
 221         my ( $self, $c ) = @_;
 222         if ( scalar @{ $c->error } ) { ... } # handle errors
 223         return if $c->res->body; # already have a response
 224         $c->forward( 'MyApp::View::TT' ); # render template
 225     }
 226
 227 See L<Catalyst::Manual::Intro> for additional information.
 228
 229 =head1 DESCRIPTION
 230
 231 Catalyst is a modern framework for making web applications without the
 232 pain usually associated with this process. This document is a reference
 233 to the main Catalyst application. If you are a new user, we suggest you
 234 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 235
 236 See L<Catalyst::Manual> for more documentation.
 237
 238 Catalyst plugins can be loaded by naming them as arguments to the "use
 239 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 240 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 241 C<My::Module>.
 242
 243     use Catalyst qw/My::Module/;
 244
 245 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 246 fully qualify the name by using a unary plus:
 247
 248     use Catalyst qw/
 249         My::Module
 250         +Fully::Qualified::Plugin::Name
 251     /;
 252
 253 Special flags like C<-Debug> can also be specified as
 254 arguments when Catalyst is loaded:
 255
 256     use Catalyst qw/-Debug My::Module/;
 257
 258 The position of plugins and flags in the chain is important, because
 259 they are loaded in the order in which they appear.
 260
 261 The following flags are supported:
 262
 263 =head2 -Debug
 264
 265 Enables debug output. You can also force this setting from the system
 266 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 267 settings override the application, with <MYAPP>_DEBUG having the highest
 268 priority.
 269
 270 This sets the log level to 'debug' and enables full debug output on the
 271 error screen. If you only want the latter, see L<< $c->debug >>.
 272
 273 =head2 -Home
 274
 275 Forces Catalyst to use a specific home directory, e.g.:
 276
 277     use Catalyst qw[-Home=/usr/mst];
 278
 279 This can also be done in the shell environment by setting either the
 280 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 281 is replaced with the uppercased name of your application, any "::" in
 282 the name will be replaced with underscores, e.g. MyApp::Web should use
 283 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 284
 285 If none of these are set, Catalyst will attempt to automatically detect the
 286 home directory. If you are working in a development environment, Catalyst
 287 will try and find the directory containing either Makefile.PL, Build.PL,
 288 dist.ini, or cpanfile. If the application has been installed into the system
 289 (i.e. you have done C<make install>), then Catalyst will use the path to your
 290 application module, without the .pm extension (e.g., /foo/MyApp if your
 291 application was installed at /foo/MyApp.pm)
 292
 293 =head2 -Log
 294
 295     use Catalyst '-Log=warn,fatal,error';
 296
 297 Specifies a comma-delimited list of log levels.
 298
 299 =head2 -Stats
 300
 301 Enables statistics collection and reporting.
 302
 303    use Catalyst qw/-Stats=1/;
 304
 305 You can also force this setting from the system environment with CATALYST_STATS
 306 or <MYAPP>_STATS. The environment settings override the application, with
 307 <MYAPP>_STATS having the highest priority.
 308
 309 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 310
 311 =head1 METHODS
 312
 313 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 314
 315 =head2 $c->action
 316
 317 Returns a L<Catalyst::Action> object for the current action, which
 318 stringifies to the action name. See L<Catalyst::Action>.
 319
 320 =head2 $c->namespace
 321
 322 Returns the namespace of the current action, i.e., the URI prefix
 323 corresponding to the controller of the current action. For example:
 324
 325     # in Controller::Foo::Bar
 326     $c->namespace; # returns 'foo/bar';
 327
 328 =head2 $c->request
 329
 330 =head2 $c->req
 331
 332 Returns the current L<Catalyst::Request> object, giving access to
 333 information about the current client request (including parameters,
 334 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 335
 336 =head2 REQUEST FLOW HANDLING
 337
 338 =head2 $c->forward( $action [, \@arguments ] )
 339
 340 =head2 $c->forward( $class, $method, [, \@arguments ] )
 341
 342 This is one way of calling another action (method) in the same or
 343 a different controller. You can also use C<< $self->my_method($c, @args) >>
 344 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 345 in a different controller.
 346 The main difference is that 'forward' uses some of the Catalyst request
 347 cycle overhead, including debugging, which may be useful to you. On the
 348 other hand, there are some complications to using 'forward', restrictions
 349 on values returned from 'forward', and it may not handle errors as you prefer.
 350 Whether you use 'forward' or not is up to you; it is not considered superior to
 351 the other ways to call a method.
 352
 353 'forward' calls  another action, by its private name. If you give a
 354 class name but no method, C<process()> is called. You may also optionally
 355 pass arguments in an arrayref. The action will receive the arguments in
 356 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 357 C<< $c->req->args >> will be restored to the previous values.
 358
 359 Any data C<return>ed from the action forwarded to, will be returned by the
 360 call to forward.
 361
 362     my $foodata = $c->forward('/foo');
 363     $c->forward('index');
 364     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 365     $c->forward('View::TT');
 366
 367 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 368 an C<< eval { } >> around the call (actually
 369 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 370 exceptions thrown by the called action non-fatal and pushing them onto
 371 $c->error instead. If you want C<die> to propagate you need to do something
 372 like:
 373
 374     $c->forward('foo');
 375     die join "\n", @{ $c->error } if @{ $c->error };
 376
 377 Or make sure to always return true values from your actions and write
 378 your code like this:
 379
 380     $c->forward('foo') || return;
 381
 382 Another note is that C<< $c->forward >> always returns a scalar because it
 383 actually returns $c->state which operates in a scalar context.
 384 Thus, something like:
 385
 386     return @array;
 387
 388 in an action that is forwarded to is going to return a scalar,
 389 i.e. how many items are in that array, which is probably not what you want.
 390 If you need to return an array then return a reference to it,
 391 or stash it like so:
 392
 393     $c->stash->{array} = \@array;
 394
 395 and access it from the stash.
 396
 397 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 398
 399 =cut
 400
 401 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 402
 403 =head2 $c->detach( $action [, \@arguments ] )
 404
 405 =head2 $c->detach( $class, $method, [, \@arguments ] )
 406
 407 =head2 $c->detach()
 408
 409 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 410 doesn't return to the previous action when processing is finished.
 411
 412 When called with no arguments it escapes the processing chain entirely.
 413
 414 =cut
 415
 416 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 417
 418 =head2 $c->visit( $action [, \@arguments ] )
 419
 420 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 421
 422 =head2 $c->visit( $class, $method, [, \@arguments ] )
 423
 424 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 425
 426 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 427 but does a full dispatch, instead of just calling the new C<$action> /
 428 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 429 you go to are called, just like a new request.
 430
 431 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 432 This means, for example, that C<< $c->action >> methods such as
 433 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 434 L<reverse|Catalyst::Action/reverse> return information for the visited action
 435 when they are invoked within the visited action.  This is different from the
 436 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 437 continues to use the $c->action object from the caller action even when
 438 invoked from the called action.
 439
 440 C<< $c->stash >> is kept unchanged.
 441
 442 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 443 allows you to "wrap" another action, just as it would have been called by
 444 dispatching from a URL, while the analogous
 445 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 446 transfer control to another action as if it had been reached directly from a URL.
 447
 448 =cut
 449
 450 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 451
 452 =head2 $c->go( $action [, \@arguments ] )
 453
 454 =head2 $c->go( $action [, \@captures, \@arguments ] )
 455
 456 =head2 $c->go( $class, $method, [, \@arguments ] )
 457
 458 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 459
 460 The relationship between C<go> and
 461 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 462 the relationship between
 463 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 464 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 465 C<< $c->go >> will perform a full dispatch on the specified action or method,
 466 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 467 C<go> escapes the processing of the current request chain on completion, and
 468 does not return to its caller.
 469
 470 @arguments are arguments to the final destination of $action. @captures are
 471 arguments to the intermediate steps, if any, on the way to the final sub of
 472 $action.
 473
 474 =cut
 475
 476 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 477
 478 =head2 $c->response
 479
 480 =head2 $c->res
 481
 482 Returns the current L<Catalyst::Response> object, see there for details.
 483
 484 =head2 $c->stash
 485
 486 Returns a hashref to the stash, which may be used to store data and pass
 487 it between components during a request. You can also set hash keys by
 488 passing arguments. The stash is automatically sent to the view. The
 489 stash is cleared at the end of a request; it cannot be used for
 490 persistent storage (for this you must use a session; see
 491 L<Catalyst::Plugin::Session> for a complete system integrated with
 492 Catalyst).
 493
 494     $c->stash->{foo} = $bar;
 495     $c->stash( { moose => 'majestic', qux => 0 } );
 496     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 497
 498     # stash is automatically passed to the view for use in a template
 499     $c->forward( 'MyApp::View::TT' );
 500
 501 The stash hash is currently stored in the PSGI C<$env> and is managed by
 502 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 503 the stash can be accessed in sub applications mounted under your main
 504 L<Catalyst> application.  For example if you delegate the response of an
 505 action to another L<Catalyst> application, that sub application will have
 506 access to all the stash keys of the main one, and if can of course add
 507 more keys of its own.  However those new keys will not 'bubble' back up
 508 to the main application.
 509
 510 For more information the best thing to do is to review the test case:
 511 t/middleware-stash.t in the distribution /t directory.
 512
 513 =cut
 514
 515 sub stash {
 516   my $c = shift;
 517   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 518 }
 519
 520 =head2 $c->error
 521
 522 =head2 $c->error($error, ...)
 523
 524 =head2 $c->error($arrayref)
 525
 526 Returns an arrayref containing error messages.  If Catalyst encounters an
 527 error while processing a request, it stores the error in $c->error.  This
 528 method should only be used to store fatal error messages.
 529
 530     my @error = @{ $c->error };
 531
 532 Add a new error.
 533
 534     $c->error('Something bad happened');
 535
 536 Calling this will always return an arrayref (if there are no errors it
 537 will be an empty arrayref.
 538
 539 =cut
 540
 541 sub error {
 542     my $c = shift;
 543     if ( $_[0] ) {
 544         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 545         croak @$error unless ref $c;
 546         push @{ $c->{error} }, @$error;
 547     }
 548     elsif ( defined $_[0] ) { $c->{error} = undef }
 549     return $c->{error} || [];
 550 }
 551
 552
 553 =head2 $c->state
 554
 555 Contains the return value of the last executed action.
 556 Note that << $c->state >> operates in a scalar context which means that all
 557 values it returns are scalar.
 558
 559 =head2 $c->clear_errors
 560
 561 Clear errors.  You probably don't want to clear the errors unless you are
 562 implementing a custom error screen.
 563
 564 This is equivalent to running
 565
 566     $c->error(0);
 567
 568 =cut
 569
 570 sub clear_errors {
 571     my $c = shift;
 572     $c->error(0);
 573 }
 574
 575 =head2 $c->has_errors
 576
 577 Returns true if you have errors
 578
 579 =cut
 580
 581 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 582
 583 =head2 $c->last_error
 584
 585 Returns the most recent error in the stack (the one most recently added...)
 586 or nothing if there are no errors.
 587
 588 =cut
 589
 590 sub last_error { my ($err, @errs) = @{shift->error}; return $err }
 591
 592 =head2 shift_errors
 593
 594 shifts the most recently added error off the error stack and returns if.  Returns
 595 nothing if there are nomore errors.
 596
 597 =cut
 598
 599 sub shift_errors {
 600     my ($self) = @_;
 601     my ($err, @errors) = @{$self->error};
 602     $self->{error} = \@errors;
 603     return $err;
 604 }
 605
 606 sub _comp_search_prefixes {
 607     my $c = shift;
 608     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 609 }
 610
 611 # search components given a name and some prefixes
 612 sub _comp_names_search_prefixes {
 613     my ( $c, $name, @prefixes ) = @_;
 614     my $appclass = ref $c || $c;
 615     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 616     $filter = qr/$filter/; # Compile regex now rather than once per loop
 617
 618     # map the original component name to the sub part that we will search against
 619     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 620         grep { /$filter/ } keys %{ $c->components };
 621
 622     # undef for a name will return all
 623     return keys %eligible if !defined $name;
 624
 625     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 626     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 627
 628     return @result if @result;
 629
 630     # if we were given a regexp to search against, we're done.
 631     return if $name->$_isa('Regexp');
 632
 633     # skip regexp fallback if configured
 634     return
 635         if $appclass->config->{disable_component_resolution_regex_fallback};
 636
 637     # regexp fallback
 638     $query  = qr/$name/i;
 639     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 640
 641     # no results? try against full names
 642     if( !@result ) {
 643         @result = grep { m{$query} } keys %eligible;
 644     }
 645
 646     # don't warn if we didn't find any results, it just might not exist
 647     if( @result ) {
 648         # Disgusting hack to work out correct method name
 649         my $warn_for = lc $prefixes[0];
 650         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 651            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 652            "component resolution is unreliable and unsafe.";
 653         my $short = $result[0];
 654         # remove the component namespace prefix
 655         $short =~ s/.*?(Model|Controller|View):://;
 656         my $shortmess = Carp::shortmess('');
 657         if ($shortmess =~ m#Catalyst/Plugin#) {
 658            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 659               "plugin's config";
 660         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 661            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 662               "component's config";
 663         } else {
 664            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 665               "but if you really wanted to search, pass in a regexp as the argument " .
 666               "like so: \$c->${warn_for}(qr/${name}/)";
 667         }
 668         $c->log->warn( "${msg}$shortmess" );
 669     }
 670
 671     return @result;
 672 }
 673
 674 # Find possible names for a prefix
 675 sub _comp_names {
 676     my ( $c, @prefixes ) = @_;
 677     my $appclass = ref $c || $c;
 678
 679     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 680
 681     my @names = map { s{$filter}{}; $_; }
 682         $c->_comp_names_search_prefixes( undef, @prefixes );
 683
 684     return @names;
 685 }
 686
 687 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 688 sub _filter_component {
 689     my ( $c, $comp, @args ) = @_;
 690
 691     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 692         return $comp->ACCEPT_CONTEXT( $c, @args );
 693     }
 694
 695     return $comp;
 696 }
 697
 698 =head2 COMPONENT ACCESSORS
 699
 700 =head2 $c->controller($name)
 701
 702 Gets a L<Catalyst::Controller> instance by name.
 703
 704     $c->controller('Foo')->do_stuff;
 705
 706 If the name is omitted, will return the controller for the dispatched
 707 action.
 708
 709 If you want to search for controllers, pass in a regexp as the argument.
 710
 711     # find all controllers that start with Foo
 712     my @foo_controllers = $c->controller(qr{^Foo});
 713
 714
 715 =cut
 716
 717 sub controller {
 718     my ( $c, $name, @args ) = @_;
 719
 720     my $appclass = ref($c) || $c;
 721     if( $name ) {
 722         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 723             my $comps = $c->components;
 724             my $check = $appclass."::Controller::".$name;
 725             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 726         }
 727         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 728         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 729         return $c->_filter_component( $result[ 0 ], @args );
 730     }
 731
 732     return $c->component( $c->action->class );
 733 }
 734
 735 =head2 $c->model($name)
 736
 737 Gets a L<Catalyst::Model> instance by name.
 738
 739     $c->model('Foo')->do_stuff;
 740
 741 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 742
 743 If the name is omitted, it will look for
 744  - a model object in $c->stash->{current_model_instance}, then
 745  - a model name in $c->stash->{current_model}, then
 746  - a config setting 'default_model', or
 747  - check if there is only one model, and return it if that's the case.
 748
 749 If you want to search for models, pass in a regexp as the argument.
 750
 751     # find all models that start with Foo
 752     my @foo_models = $c->model(qr{^Foo});
 753
 754 =cut
 755
 756 sub model {
 757     my ( $c, $name, @args ) = @_;
 758     my $appclass = ref($c) || $c;
 759     if( $name ) {
 760         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 761             my $comps = $c->components;
 762             my $check = $appclass."::Model::".$name;
 763             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 764         }
 765         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 766         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 767         return $c->_filter_component( $result[ 0 ], @args );
 768     }
 769
 770     if (ref $c) {
 771         return $c->stash->{current_model_instance}
 772           if $c->stash->{current_model_instance};
 773         return $c->model( $c->stash->{current_model} )
 774           if $c->stash->{current_model};
 775     }
 776     return $c->model( $appclass->config->{default_model} )
 777       if $appclass->config->{default_model};
 778
 779     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 780
 781     if( $rest ) {
 782         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 783         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 784         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 785         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 786         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 787     }
 788
 789     return $c->_filter_component( $comp );
 790 }
 791
 792
 793 =head2 $c->view($name)
 794
 795 Gets a L<Catalyst::View> instance by name.
 796
 797     $c->view('Foo')->do_stuff;
 798
 799 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 800
 801 If the name is omitted, it will look for
 802  - a view object in $c->stash->{current_view_instance}, then
 803  - a view name in $c->stash->{current_view}, then
 804  - a config setting 'default_view', or
 805  - check if there is only one view, and return it if that's the case.
 806
 807 If you want to search for views, pass in a regexp as the argument.
 808
 809     # find all views that start with Foo
 810     my @foo_views = $c->view(qr{^Foo});
 811
 812 =cut
 813
 814 sub view {
 815     my ( $c, $name, @args ) = @_;
 816
 817     my $appclass = ref($c) || $c;
 818     if( $name ) {
 819         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 820             my $comps = $c->components;
 821             my $check = $appclass."::View::".$name;
 822             if( exists $comps->{$check} ) {
 823                 return $c->_filter_component( $comps->{$check}, @args );
 824             }
 825             else {
 826                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 827             }
 828         }
 829         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 830         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 831         return $c->_filter_component( $result[ 0 ], @args );
 832     }
 833
 834     if (ref $c) {
 835         return $c->stash->{current_view_instance}
 836           if $c->stash->{current_view_instance};
 837         return $c->view( $c->stash->{current_view} )
 838           if $c->stash->{current_view};
 839     }
 840     return $c->view( $appclass->config->{default_view} )
 841       if $appclass->config->{default_view};
 842
 843     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 844
 845     if( $rest ) {
 846         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 847         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 848         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 849         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 850         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 851     }
 852
 853     return $c->_filter_component( $comp );
 854 }
 855
 856 =head2 $c->controllers
 857
 858 Returns the available names which can be passed to $c->controller
 859
 860 =cut
 861
 862 sub controllers {
 863     my ( $c ) = @_;
 864     return $c->_comp_names(qw/Controller C/);
 865 }
 866
 867 =head2 $c->models
 868
 869 Returns the available names which can be passed to $c->model
 870
 871 =cut
 872
 873 sub models {
 874     my ( $c ) = @_;
 875     return $c->_comp_names(qw/Model M/);
 876 }
 877
 878
 879 =head2 $c->views
 880
 881 Returns the available names which can be passed to $c->view
 882
 883 =cut
 884
 885 sub views {
 886     my ( $c ) = @_;
 887     return $c->_comp_names(qw/View V/);
 888 }
 889
 890 =head2 $c->comp($name)
 891
 892 =head2 $c->component($name)
 893
 894 Gets a component object by name. This method is not recommended,
 895 unless you want to get a specific component by full
 896 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 897 should be used instead.
 898
 899 If C<$name> is a regexp, a list of components matched against the full
 900 component name will be returned.
 901
 902 If Catalyst can't find a component by name, it will fallback to regex
 903 matching by default. To disable this behaviour set
 904 disable_component_resolution_regex_fallback to a true value.
 905
 906     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 907
 908 =cut
 909
 910 sub component {
 911     my ( $c, $name, @args ) = @_;
 912
 913     if( $name ) {
 914         my $comps = $c->components;
 915
 916         if( !ref $name ) {
 917             # is it the exact name?
 918             return $c->_filter_component( $comps->{ $name }, @args )
 919                        if exists $comps->{ $name };
 920
 921             # perhaps we just omitted "MyApp"?
 922             my $composed = ( ref $c || $c ) . "::${name}";
 923             return $c->_filter_component( $comps->{ $composed }, @args )
 924                        if exists $comps->{ $composed };
 925
 926             # search all of the models, views and controllers
 927             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 928             return $c->_filter_component( $comp, @args ) if $comp;
 929         }
 930
 931         return
 932             if $c->config->{disable_component_resolution_regex_fallback};
 933
 934         # This is here so $c->comp( '::M::' ) works
 935         my $query = ref $name ? $name : qr{$name}i;
 936
 937         my @result = grep { m{$query} } keys %{ $c->components };
 938         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 939
 940         if( $result[ 0 ] ) {
 941             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 942             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 943             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 944             return $c->_filter_component( $result[ 0 ], @args );
 945         }
 946
 947         # I would expect to return an empty list here, but that breaks back-compat
 948     }
 949
 950     # fallback
 951     return sort keys %{ $c->components };
 952 }
 953
 954 =head2 CLASS DATA AND HELPER CLASSES
 955
 956 =head2 $c->config
 957
 958 Returns or takes a hashref containing the application's configuration.
 959
 960     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 961
 962 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 963 like C<myapp.conf> in your applications home directory. See
 964 L<Catalyst::Plugin::ConfigLoader>.
 965
 966 =head3 Cascading configuration
 967
 968 The config method is present on all Catalyst components, and configuration
 969 will be merged when an application is started. Configuration loaded with
 970 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 971 followed by configuration in your top level C<MyApp> class. These two
 972 configurations are merged, and then configuration data whose hash key matches a
 973 component name is merged with configuration for that component.
 974
 975 The configuration for a component is then passed to the C<new> method when a
 976 component is constructed.
 977
 978 For example:
 979
 980     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 981     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 982
 983 will mean that C<MyApp::Model::Foo> receives the following data when
 984 constructed:
 985
 986     MyApp::Model::Foo->new({
 987         bar => 'baz',
 988         quux => 'frob',
 989         overrides => 'me',
 990     });
 991
 992 It's common practice to use a Moose attribute
 993 on the receiving component to access the config value.
 994
 995     package MyApp::Model::Foo;
 996
 997     use Moose;
 998
 999     # this attr will receive 'baz' at construction time
1000     has 'bar' => (
1001         is  => 'rw',
1002         isa => 'Str',
1003     );
1004
1005 You can then get the value 'baz' by calling $c->model('Foo')->bar
1006 (or $self->bar inside code in the model).
1007
1008 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1009 as a way of reading config within your code, as this B<will not> give you the
1010 correctly merged config back. You B<MUST> take the config values supplied to
1011 the constructor and use those instead.
1012
1013 =cut
1014
1015 around config => sub {
1016     my $orig = shift;
1017     my $c = shift;
1018
1019     croak('Setting config after setup has been run is not allowed.')
1020         if ( @_ and $c->setup_finished );
1021
1022     $c->$orig(@_);
1023 };
1024
1025 =head2 $c->log
1026
1027 Returns the logging object instance. Unless it is already set, Catalyst
1028 sets this up with a L<Catalyst::Log> object. To use your own log class,
1029 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1030 C<< __PACKAGE__->setup >>.
1031
1032  __PACKAGE__->log( MyLogger->new );
1033  __PACKAGE__->setup;
1034
1035 And later:
1036
1037     $c->log->info( 'Now logging with my own logger!' );
1038
1039 Your log class should implement the methods described in
1040 L<Catalyst::Log>.
1041
1042 =head2 has_encoding
1043
1044 Returned True if there's a valid encoding
1045
1046 =head2 clear_encoding
1047
1048 Clears the encoding for the current context
1049
1050 =head2 encoding
1051
1052 Sets or gets the application encoding.
1053
1054 =cut
1055
1056 sub has_encoding { shift->encoding ? 1:0 }
1057
1058 sub clear_encoding {
1059     my $c = shift;
1060     if(blessed $c) {
1061         $c->encoding(undef);
1062     } else {
1063         $c->debug->error("You can't clear encoding on the application");
1064     }
1065 }
1066
1067 sub encoding {
1068     my $c = shift;
1069     my $encoding;
1070
1071     if ( scalar @_ ) {
1072         # Let it be set to undef
1073         if (my $wanted = shift)  {
1074             $encoding = Encode::find_encoding($wanted)
1075               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1076             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1077         }
1078         else {
1079             binmode(STDERR);
1080         }
1081
1082         $encoding = ref $c
1083                   ? $c->{encoding} = $encoding
1084                   : $c->_encoding($encoding);
1085     } else {
1086       $encoding = ref $c && exists $c->{encoding}
1087                 ? $c->{encoding}
1088                 : $c->_encoding;
1089     }
1090
1091     return $encoding;
1092 }
1093
1094 =head2 $c->debug
1095
1096 Returns 1 if debug mode is enabled, 0 otherwise.
1097
1098 You can enable debug mode in several ways:
1099
1100 =over
1101
1102 =item By calling myapp_server.pl with the -d flag
1103
1104 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1105
1106 =item The -Debug option in your MyApp.pm
1107
1108 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1109
1110 =back
1111
1112 The first three also set the log level to 'debug'.
1113
1114 Calling C<< $c->debug(1) >> has no effect.
1115
1116 =cut
1117
1118 sub debug { 0 }
1119
1120 =head2 $c->dispatcher
1121
1122 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1123
1124 =head2 $c->engine
1125
1126 Returns the engine instance. See L<Catalyst::Engine>.
1127
1128
1129 =head2 UTILITY METHODS
1130
1131 =head2 $c->path_to(@path)
1132
1133 Merges C<@path> with C<< $c->config->{home} >> and returns a
1134 L<Path::Class::Dir> object. Note you can usually use this object as
1135 a filename, but sometimes you will have to explicitly stringify it
1136 yourself by calling the C<< ->stringify >> method.
1137
1138 For example:
1139
1140     $c->path_to( 'db', 'sqlite.db' );
1141
1142 =cut
1143
1144 sub path_to {
1145     my ( $c, @path ) = @_;
1146     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1147     if ( -d $path ) { return $path }
1148     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1149 }
1150
1151 sub plugin {
1152     my ( $class, $name, $plugin, @args ) = @_;
1153
1154     # See block comment in t/unit_core_plugin.t
1155     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1156
1157     $class->_register_plugin( $plugin, 1 );
1158
1159     eval { $plugin->import };
1160     $class->mk_classdata($name);
1161     my $obj;
1162     eval { $obj = $plugin->new(@args) };
1163
1164     if ($@) {
1165         Catalyst::Exception->throw( message =>
1166               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1167     }
1168
1169     $class->$name($obj);
1170     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1171       if $class->debug;
1172 }
1173
1174 =head2 MyApp->setup
1175
1176 Initializes the dispatcher and engine, loads any plugins, and loads the
1177 model, view, and controller components. You may also specify an array
1178 of plugins to load here, if you choose to not load them in the C<use
1179 Catalyst> line.
1180
1181     MyApp->setup;
1182     MyApp->setup( qw/-Debug/ );
1183
1184 B<Note:> You B<should not> wrap this method with method modifiers
1185 or bad things will happen - wrap the C<setup_finalize> method instead.
1186
1187 B<Note:> You can create a custom setup stage that will execute when the
1188 application is starting.  Use this to customize setup.
1189
1190     MyApp->setup(-Custom=value);
1191
1192     sub setup_custom {
1193       my ($class, $value) = @_;
1194     }
1195
1196 Can be handy if you want to hook into the setup phase.
1197
1198 =cut
1199
1200 sub setup {
1201     my ( $class, @arguments ) = @_;
1202     croak('Running setup more than once')
1203         if ( $class->setup_finished );
1204
1205     unless ( $class->isa('Catalyst') ) {
1206
1207         Catalyst::Exception->throw(
1208             message => qq/'$class' does not inherit from Catalyst/ );
1209     }
1210
1211     if ( $class->arguments ) {
1212         @arguments = ( @arguments, @{ $class->arguments } );
1213     }
1214
1215     # Process options
1216     my $flags = {};
1217
1218     foreach (@arguments) {
1219
1220         if (/^-Debug$/) {
1221             $flags->{log} =
1222               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1223         }
1224         elsif (/^-(\w+)=?(.*)$/) {
1225             $flags->{ lc $1 } = $2;
1226         }
1227         else {
1228             push @{ $flags->{plugins} }, $_;
1229         }
1230     }
1231
1232     $class->setup_home( delete $flags->{home} );
1233
1234     $class->setup_log( delete $flags->{log} );
1235     $class->setup_plugins( delete $flags->{plugins} );
1236
1237     $class->setup_data_handlers();
1238     $class->setup_dispatcher( delete $flags->{dispatcher} );
1239     if (my $engine = delete $flags->{engine}) {
1240         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1241     }
1242     $class->setup_engine();
1243     $class->setup_stats( delete $flags->{stats} );
1244
1245     for my $flag ( sort keys %{$flags} ) {
1246
1247         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1248             &$code( $class, delete $flags->{$flag} );
1249         }
1250         else {
1251             $class->log->warn(qq/Unknown flag "$flag"/);
1252         }
1253     }
1254
1255     eval { require Catalyst::Devel; };
1256     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1257         $class->log->warn(<<"EOF");
1258 You are running an old script!
1259
1260   Please update by running (this will overwrite existing files):
1261     catalyst.pl -force -scripts $class
1262
1263   or (this will not overwrite existing files):
1264     catalyst.pl -scripts $class
1265
1266 EOF
1267     }
1268
1269     # Call plugins setup, this is stupid and evil.
1270     # Also screws C3 badly on 5.10, hack to avoid.
1271     {
1272         no warnings qw/redefine/;
1273         local *setup = sub { };
1274         $class->setup unless $Catalyst::__AM_RESTARTING;
1275     }
1276
1277     # If you are expecting configuration info as part of your setup, it needs
1278     # to get called here and below, since we need the above line to support
1279     # ConfigLoader based configs.
1280
1281     $class->setup_encoding();
1282     $class->setup_middleware();
1283
1284     # Initialize our data structure
1285     $class->components( {} );
1286
1287     $class->setup_components;
1288
1289     if ( $class->debug ) {
1290         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1291
1292         if (@plugins) {
1293             my $column_width = Catalyst::Utils::term_width() - 6;
1294             my $t = Text::SimpleTable->new($column_width);
1295             $t->row($_) for @plugins;
1296             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1297         }
1298
1299         my @middleware = map {
1300           ref $_ eq 'CODE' ?
1301             "Inline Coderef" :
1302               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1303                 || '')  } $class->registered_middlewares;
1304
1305         if (@middleware) {
1306             my $column_width = Catalyst::Utils::term_width() - 6;
1307             my $t = Text::SimpleTable->new($column_width);
1308             $t->row($_) for @middleware;
1309             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1310         }
1311
1312         my %dh = $class->registered_data_handlers;
1313         if (my @data_handlers = keys %dh) {
1314             my $column_width = Catalyst::Utils::term_width() - 6;
1315             my $t = Text::SimpleTable->new($column_width);
1316             $t->row($_) for @data_handlers;
1317             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1318         }
1319
1320         my $dispatcher = $class->dispatcher;
1321         my $engine     = $class->engine;
1322         my $home       = $class->config->{home};
1323
1324         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1325         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1326
1327         $home
1328           ? ( -d $home )
1329           ? $class->log->debug(qq/Found home "$home"/)
1330           : $class->log->debug(qq/Home "$home" doesn't exist/)
1331           : $class->log->debug(q/Couldn't find home/);
1332
1333         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1334         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1335         for my $comp ( sort keys %{ $class->components } ) {
1336             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1337             $t->row( $comp, $type );
1338         }
1339         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1340           if ( keys %{ $class->components } );
1341     }
1342
1343     # Add our self to components, since we are also a component
1344     if( $class->isa('Catalyst::Controller') ){
1345       $class->components->{$class} = $class;
1346     }
1347
1348     $class->setup_actions;
1349
1350     if ( $class->debug ) {
1351         my $name = $class->config->{name} || 'Application';
1352         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1353     }
1354
1355     if ($class->config->{case_sensitive}) {
1356         $class->log->warn($class . "->config->{case_sensitive} is set.");
1357         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1358     }
1359
1360     $class->setup_finalize;
1361
1362     # Flush the log for good measure (in case something turned off 'autoflush' early)
1363     $class->log->_flush() if $class->log->can('_flush');
1364
1365     return $class || 1; # Just in case someone named their Application 0...
1366 }
1367
1368 =head2 $app->setup_finalize
1369
1370 A hook to attach modifiers to. This method does not do anything except set the
1371 C<setup_finished> accessor.
1372
1373 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1374
1375 Example:
1376
1377     after setup_finalize => sub {
1378         my $app = shift;
1379
1380         ## do stuff here..
1381     };
1382
1383 =cut
1384
1385 sub setup_finalize {
1386     my ($class) = @_;
1387     $class->setup_finished(1);
1388 }
1389
1390 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1391
1392 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1393
1394 =head2 $c->uri_for( $action, [@captures, @args], \%query_values? )
1395
1396 Constructs an absolute L<URI> object based on the application root, the
1397 provided path, and the additional arguments and query parameters provided.
1398 When used as a string, provides a textual URI.  If you need more flexibility
1399 than this (i.e. the option to provide relative URIs etc.) see
1400 L<Catalyst::Plugin::SmartURI>.
1401
1402 If no arguments are provided, the URI for the current action is returned.
1403 To return the current action and also provide @args, use
1404 C<< $c->uri_for( $c->action, @args ) >>.
1405
1406 If the first argument is a string, it is taken as a public URI path relative
1407 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1408 relative to the application root (if it does). It is then merged with
1409 C<< $c->request->base >>; any C<@args> are appended as additional path
1410 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1411
1412 If the first argument is a L<Catalyst::Action> it represents an action which
1413 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1414 optional C<\@captures> argument (an arrayref) allows passing the captured
1415 variables that are needed to fill in the paths of Chained and Regex actions;
1416 once the path is resolved, C<uri_for> continues as though a path was
1417 provided, appending any arguments or parameters and creating an absolute
1418 URI.
1419
1420 The captures for the current request can be found in
1421 C<< $c->request->captures >>, and actions can be resolved using
1422 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1423 path, use C<< $c->uri_for_action >> instead.
1424
1425   # Equivalent to $c->req->uri
1426   $c->uri_for($c->action, $c->req->captures,
1427       @{ $c->req->args }, $c->req->params);
1428
1429   # For the Foo action in the Bar controller
1430   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1431
1432   # Path to a static resource
1433   $c->uri_for('/static/images/logo.png');
1434
1435 In general the scheme of the generated URI object will follow the incoming request
1436 however if your targeted action or action chain has the Scheme attribute it will
1437 use that instead.
1438
1439 =cut
1440
1441 sub uri_for {
1442     my ( $c, $path, @args ) = @_;
1443
1444     if ( $path->$_isa('Catalyst::Controller') ) {
1445         $path = $path->path_prefix;
1446         $path =~ s{/+\z}{};
1447         $path .= '/';
1448     }
1449
1450     undef($path) if (defined $path && $path eq '');
1451
1452     my $params =
1453       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1454
1455     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1456
1457     my @encoded_args = ();
1458     foreach my $arg (@args) {
1459       if(ref($arg)||'' eq 'ARRAY') {
1460         push @encoded_args, [map {
1461           my $encoded = encode_utf8 $_;
1462           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1463          $encoded;
1464         } @$arg];
1465       } else {
1466         push @encoded_args, do {
1467           my $encoded = encode_utf8 $arg;
1468           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1469           $encoded;
1470         }
1471       }
1472     }
1473
1474     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1475     if ( $path->$_isa('Catalyst::Action') ) { # action object
1476         s|/|%2F|g for @encoded_args;
1477         my $captures = [ map { s|/|%2F|g; $_; }
1478                         ( scalar @encoded_args && ref $encoded_args[0] eq 'ARRAY'
1479                          ? @{ shift(@encoded_args) }
1480                          : ()) ];
1481
1482         my $action = $path;
1483         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1484         if( !@encoded_args && $action->number_of_args ) {
1485             my $expanded_action = $c->dispatcher->expand_action( $action );
1486             my $num_captures = $expanded_action->number_of_captures;
1487             unshift @encoded_args, splice @$captures, $num_captures;
1488         }
1489
1490        $path = $c->dispatcher->uri_for_action($action, $captures);
1491         if (not defined $path) {
1492             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1493                 if $c->debug;
1494             return undef;
1495         }
1496         $path = '/' if $path eq '';
1497     }
1498
1499     unshift(@encoded_args, $path);
1500
1501     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1502         my $namespace = $c->namespace;
1503         if (defined $path) { # cheesy hack to handle path '../foo'
1504            $namespace =~ s{(?:^|/)[^/]+$}{} while $encoded_args[0] =~ s{^\.\./}{};
1505         }
1506         unshift(@encoded_args, $namespace || '');
1507     }
1508
1509     # join args with '/', or a blank string
1510     my $args = join('/', grep { defined($_) } @encoded_args);
1511     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1512     $args =~ s!^/+!!;
1513
1514     my ($base, $class) = ('/', 'URI::_generic');
1515     if(blessed($c)) {
1516       $base = $c->req->base;
1517       if($target_action) {
1518         $target_action = $c->dispatcher->expand_action($target_action);
1519         if(my $s = $target_action->scheme) {
1520           $s = lc($s);
1521           $class = "URI::$s";
1522           $base->scheme($s);
1523         } else {
1524           $class = ref($base);
1525         }
1526       } else {
1527         $class = ref($base);
1528       }
1529
1530       $base =~ s{(?<!/)$}{/};
1531     }
1532
1533     my $query = '';
1534
1535     if (my @keys = keys %$params) {
1536       # somewhat lifted from URI::_query's query_form
1537       $query = '?'.join('&', map {
1538           my $val = $params->{$_};
1539           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1540           s/ /+/g;
1541           my $key = $_;
1542           $val = '' unless defined $val;
1543           (map {
1544               my $param = "$_";
1545               $param = encode_utf8($param);
1546               # using the URI::Escape pattern here so utf8 chars survive
1547               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1548               $param =~ s/ /+/g;
1549
1550               $key = encode_utf8($key);
1551               # using the URI::Escape pattern here so utf8 chars survive
1552               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1553               $key =~ s/ /+/g;
1554
1555               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1556       } @keys);
1557     }
1558
1559     my $res = bless(\"${base}${args}${query}", $class);
1560     $res;
1561 }
1562
1563 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1564
1565 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1566
1567 =over
1568
1569 =item $path
1570
1571 A private path to the Catalyst action you want to create a URI for.
1572
1573 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1574 >> and passing the resulting C<$action> and the remaining arguments to C<<
1575 $c->uri_for >>.
1576
1577 You can also pass in a Catalyst::Action object, in which case it is passed to
1578 C<< $c->uri_for >>.
1579
1580 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1581
1582 For example, if the action looks like:
1583
1584  package MyApp::Controller::Users;
1585
1586  sub lst : Path('the-list') {}
1587
1588 You can use:
1589
1590  $c->uri_for_action('/users/lst')
1591
1592 and it will create the URI /users/the-list.
1593
1594 =item \@captures_and_args?
1595
1596 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1597 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1598 to interpolate all the parameters in the URI.
1599
1600 =item @args?
1601
1602 Optional list of extra arguments - can be supplied in the
1603 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1604 code.
1605
1606 Your action can have zero, a fixed or a variable number of args (e.g.
1607 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1608
1609 =item \%query_values?
1610
1611 Optional array reference of query parameters to append. E.g.
1612
1613   { foo => 'bar' }
1614
1615 will generate
1616
1617   /rest/of/your/uri?foo=bar
1618
1619 =back
1620
1621 =cut
1622
1623 sub uri_for_action {
1624     my ( $c, $path, @args ) = @_;
1625     my $action = blessed($path)
1626       ? $path
1627       : $c->dispatcher->get_action_by_path($path);
1628     unless (defined $action) {
1629       croak "Can't find action for path '$path'";
1630     }
1631     return $c->uri_for( $action, @args );
1632 }
1633
1634 =head2 $c->welcome_message
1635
1636 Returns the Catalyst welcome HTML page.
1637
1638 =cut
1639
1640 sub welcome_message {
1641     my $c      = shift;
1642     my $name   = $c->config->{name};
1643     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1644     my $prefix = Catalyst::Utils::appprefix( ref $c );
1645     $c->response->content_type('text/html; charset=utf-8');
1646     return <<"EOF";
1647 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1648     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1649 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1650     <head>
1651     <meta http-equiv="Content-Language" content="en" />
1652     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1653         <title>$name on Catalyst $VERSION</title>
1654         <style type="text/css">
1655             body {
1656                 color: #000;
1657                 background-color: #eee;
1658             }
1659             div#content {
1660                 width: 640px;
1661                 margin-left: auto;
1662                 margin-right: auto;
1663                 margin-top: 10px;
1664                 margin-bottom: 10px;
1665                 text-align: left;
1666                 background-color: #ccc;
1667                 border: 1px solid #aaa;
1668             }
1669             p, h1, h2 {
1670                 margin-left: 20px;
1671                 margin-right: 20px;
1672                 font-family: verdana, tahoma, sans-serif;
1673             }
1674             a {
1675                 font-family: verdana, tahoma, sans-serif;
1676             }
1677             :link, :visited {
1678                     text-decoration: none;
1679                     color: #b00;
1680                     border-bottom: 1px dotted #bbb;
1681             }
1682             :link:hover, :visited:hover {
1683                     color: #555;
1684             }
1685             div#topbar {
1686                 margin: 0px;
1687             }
1688             pre {
1689                 margin: 10px;
1690                 padding: 8px;
1691             }
1692             div#answers {
1693                 padding: 8px;
1694                 margin: 10px;
1695                 background-color: #fff;
1696                 border: 1px solid #aaa;
1697             }
1698             h1 {
1699                 font-size: 0.9em;
1700                 font-weight: normal;
1701                 text-align: center;
1702             }
1703             h2 {
1704                 font-size: 1.0em;
1705             }
1706             p {
1707                 font-size: 0.9em;
1708             }
1709             p img {
1710                 float: right;
1711                 margin-left: 10px;
1712             }
1713             span#appname {
1714                 font-weight: bold;
1715                 font-size: 1.6em;
1716             }
1717         </style>
1718     </head>
1719     <body>
1720         <div id="content">
1721             <div id="topbar">
1722                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1723                     $VERSION</h1>
1724              </div>
1725              <div id="answers">
1726                  <p>
1727                  <img src="$logo" alt="Catalyst Logo" />
1728                  </p>
1729                  <p>Welcome to the  world of Catalyst.
1730                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1731                     framework will make web development something you had
1732                     never expected it to be: Fun, rewarding, and quick.</p>
1733                  <h2>What to do now?</h2>
1734                  <p>That really depends  on what <b>you</b> want to do.
1735                     We do, however, provide you with a few starting points.</p>
1736                  <p>If you want to jump right into web development with Catalyst
1737                     you might want to start with a tutorial.</p>
1738 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1739 </pre>
1740 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1741 <pre>
1742 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1743 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1744 </code></pre>
1745                  <h2>What to do next?</h2>
1746                  <p>Next it's time to write an actual application. Use the
1747                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1748                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1749                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1750                     they can save you a lot of work.</p>
1751                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1752                     <p>Also, be sure to check out the vast and growing
1753                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1754                     you are likely to find what you need there.
1755                     </p>
1756
1757                  <h2>Need help?</h2>
1758                  <p>Catalyst has a very active community. Here are the main places to
1759                     get in touch with us.</p>
1760                  <ul>
1761                      <li>
1762                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1763                      </li>
1764                      <li>
1765                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1766                      </li>
1767                      <li>
1768                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1769                      </li>
1770                  </ul>
1771                  <h2>In conclusion</h2>
1772                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1773                     as we enjoyed making it. Please contact us if you have ideas
1774                     for improvement or other feedback.</p>
1775              </div>
1776          </div>
1777     </body>
1778 </html>
1779 EOF
1780 }
1781
1782 =head2 run_options
1783
1784 Contains a hash of options passed from the application script, including
1785 the original ARGV the script received, the processed values from that
1786 ARGV and any extra arguments to the script which were not processed.
1787
1788 This can be used to add custom options to your application's scripts
1789 and setup your application differently depending on the values of these
1790 options.
1791
1792 =head1 INTERNAL METHODS
1793
1794 These methods are not meant to be used by end users.
1795
1796 =head2 $c->components
1797
1798 Returns a hash of components.
1799
1800 =head2 $c->context_class
1801
1802 Returns or sets the context class.
1803
1804 =head2 $c->counter
1805
1806 Returns a hashref containing coderefs and execution counts (needed for
1807 deep recursion detection).
1808
1809 =head2 $c->depth
1810
1811 Returns the number of actions on the current internal execution stack.
1812
1813 =head2 $c->dispatch
1814
1815 Dispatches a request to actions.
1816
1817 =cut
1818
1819 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1820
1821 =head2 $c->dispatcher_class
1822
1823 Returns or sets the dispatcher class.
1824
1825 =head2 $c->dump_these
1826
1827 Returns a list of 2-element array references (name, structure) pairs
1828 that will be dumped on the error page in debug mode.
1829
1830 =cut
1831
1832 sub dump_these {
1833     my $c = shift;
1834     [ Request => $c->req ],
1835     [ Response => $c->res ],
1836     [ Stash => $c->stash ],
1837     [ Config => $c->config ];
1838 }
1839
1840 =head2 $c->engine_class
1841
1842 Returns or sets the engine class.
1843
1844 =head2 $c->execute( $class, $coderef )
1845
1846 Execute a coderef in given class and catch exceptions. Errors are available
1847 via $c->error.
1848
1849 =cut
1850
1851 sub execute {
1852     my ( $c, $class, $code ) = @_;
1853     $class = $c->component($class) || $class;
1854     $c->state(0);
1855
1856     if ( $c->depth >= $RECURSION ) {
1857         my $action = $code->reverse();
1858         $action = "/$action" unless $action =~ /->/;
1859         my $error = qq/Deep recursion detected calling "${action}"/;
1860         $c->log->error($error);
1861         $c->error($error);
1862         $c->state(0);
1863         return $c->state;
1864     }
1865
1866     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1867
1868     push( @{ $c->stack }, $code );
1869
1870     no warnings 'recursion';
1871     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1872     #      I have no idea how, ergo $ret (which appears to fix the issue)
1873     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1874
1875     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1876
1877     my $last = pop( @{ $c->stack } );
1878
1879     if ( my $error = $@ ) {
1880         #rethow if this can be handled by middleware
1881         if ( $c->_handle_http_exception($error) ) {
1882             foreach my $err (@{$c->error}) {
1883                 $c->log->error($err);
1884             }
1885             $c->clear_errors;
1886             $c->log->_flush if $c->log->can('_flush');
1887
1888             $error->can('rethrow') ? $error->rethrow : croak $error;
1889         }
1890         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1891             $error->rethrow if $c->depth > 1;
1892         }
1893         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1894             $error->rethrow if $c->depth > 0;
1895         }
1896         else {
1897             unless ( ref $error ) {
1898                 no warnings 'uninitialized';
1899                 chomp $error;
1900                 my $class = $last->class;
1901                 my $name  = $last->name;
1902                 $error = qq/Caught exception in $class->$name "$error"/;
1903             }
1904             $c->error($error);
1905         }
1906         $c->state(0);
1907     }
1908     return $c->state;
1909 }
1910
1911 sub _stats_start_execute {
1912     my ( $c, $code ) = @_;
1913     my $appclass = ref($c) || $c;
1914     return if ( ( $code->name =~ /^_.*/ )
1915         && ( !$appclass->config->{show_internal_actions} ) );
1916
1917     my $action_name = $code->reverse();
1918     $c->counter->{$action_name}++;
1919
1920     my $action = $action_name;
1921     $action = "/$action" unless $action =~ /->/;
1922
1923     # determine if the call was the result of a forward
1924     # this is done by walking up the call stack and looking for a calling
1925     # sub of Catalyst::forward before the eval
1926     my $callsub = q{};
1927     for my $index ( 2 .. 11 ) {
1928         last
1929         if ( ( caller($index) )[0] eq 'Catalyst'
1930             && ( caller($index) )[3] eq '(eval)' );
1931
1932         if ( ( caller($index) )[3] =~ /forward$/ ) {
1933             $callsub = ( caller($index) )[3];
1934             $action  = "-> $action";
1935             last;
1936         }
1937     }
1938
1939     my $uid = $action_name . $c->counter->{$action_name};
1940
1941     # is this a root-level call or a forwarded call?
1942     if ( $callsub =~ /forward$/ ) {
1943         my $parent = $c->stack->[-1];
1944
1945         # forward, locate the caller
1946         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1947             $c->stats->profile(
1948                 begin  => $action,
1949                 parent => "$parent" . $c->counter->{"$parent"},
1950                 uid    => $uid,
1951             );
1952         }
1953         else {
1954
1955             # forward with no caller may come from a plugin
1956             $c->stats->profile(
1957                 begin => $action,
1958                 uid   => $uid,
1959             );
1960         }
1961     }
1962     else {
1963
1964         # root-level call
1965         $c->stats->profile(
1966             begin => $action,
1967             uid   => $uid,
1968         );
1969     }
1970     return $action;
1971
1972 }
1973
1974 sub _stats_finish_execute {
1975     my ( $c, $info ) = @_;
1976     $c->stats->profile( end => $info );
1977 }
1978
1979 =head2 $c->finalize
1980
1981 Finalizes the request.
1982
1983 =cut
1984
1985 sub finalize {
1986     my $c = shift;
1987
1988     for my $error ( @{ $c->error } ) {
1989         $c->log->error($error);
1990     }
1991
1992     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1993     # stuff like cometd and websockets
1994
1995     if($c->request->_has_io_fh) {
1996       $c->log_response;
1997       return;
1998     }
1999
2000     # Allow engine to handle finalize flow (for POE)
2001     my $engine = $c->engine;
2002     if ( my $code = $engine->can('finalize') ) {
2003         $engine->$code($c);
2004     }
2005     else {
2006
2007         $c->finalize_uploads;
2008
2009         # Error
2010         if ( $#{ $c->error } >= 0 ) {
2011             $c->finalize_error;
2012         }
2013
2014         $c->finalize_encoding;
2015         $c->finalize_headers unless $c->response->finalized_headers;
2016         $c->finalize_body;
2017     }
2018
2019     $c->log_response;
2020
2021     if ($c->use_stats) {
2022         my $elapsed = $c->stats->elapsed;
2023         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2024         $c->log->info(
2025             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2026     }
2027
2028     return $c->response->status;
2029 }
2030
2031 =head2 $c->finalize_body
2032
2033 Finalizes body.
2034
2035 =cut
2036
2037 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2038
2039 =head2 $c->finalize_cookies
2040
2041 Finalizes cookies.
2042
2043 =cut
2044
2045 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2046
2047 =head2 $c->finalize_error
2048
2049 Finalizes error.  If there is only one error in L</error> and it is an object that
2050 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2051 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2052 return the default error page (production mode).
2053
2054 =cut
2055
2056 sub finalize_error {
2057     my $c = shift;
2058     if($#{$c->error} > 0) {
2059         $c->engine->finalize_error( $c, @_ );
2060     } else {
2061         my ($error) = @{$c->error};
2062         if ( $c->_handle_http_exception($error) ) {
2063             # In the case where the error 'knows what it wants', becauses its PSGI
2064             # aware, just rethow and let middleware catch it
2065             $error->can('rethrow') ? $error->rethrow : croak $error;
2066         } else {
2067             $c->engine->finalize_error( $c, @_ )
2068         }
2069     }
2070 }
2071
2072 =head2 $c->finalize_headers
2073
2074 Finalizes headers.
2075
2076 =cut
2077
2078 sub finalize_headers {
2079     my $c = shift;
2080
2081     my $response = $c->response; #accessor calls can add up?
2082
2083     # Check if we already finalized headers
2084     return if $response->finalized_headers;
2085
2086     # Handle redirects
2087     if ( my $location = $response->redirect ) {
2088         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2089         $response->header( Location => $location );
2090     }
2091
2092     # Remove incorrectly added body and content related meta data when returning
2093     # an information response, or a response the is required to not include a body
2094
2095     $c->finalize_cookies;
2096
2097     # This currently is a NOOP but I don't want to remove it since I guess people
2098     # might have Response subclasses that use it for something... (JNAP)
2099     $c->response->finalize_headers();
2100
2101     # Done
2102     $response->finalized_headers(1);
2103 }
2104
2105 =head2 $c->finalize_encoding
2106
2107 Make sure your body is encoded properly IF you set an encoding.  By
2108 default the encoding is UTF-8 but you can disable it by explictly setting the
2109 encoding configuration value to undef.
2110
2111 We can only encode when the body is a scalar.  Methods for encoding via the
2112 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2113 are available).
2114
2115 See L</ENCODING>.
2116
2117 =cut
2118
2119 sub finalize_encoding {
2120     my $c = shift;
2121     my $res = $c->res || return;
2122
2123     # Warn if the set charset is different from the one you put into encoding.  We need
2124     # to do this early since encodable_response is false for this condition and we need
2125     # to match the debug output for backcompat (there's a test for this...) -JNAP
2126     if(
2127       $res->content_type_charset and $c->encoding and
2128       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2129     ) {
2130         my $ct = lc($res->content_type_charset);
2131         $c->log->debug("Catalyst encoding config is set to encode in '" .
2132             $c->encoding->mime_name .
2133             "', content type is '$ct', not encoding ");
2134     }
2135
2136     if(
2137       ($res->encodable_response) and
2138       (defined($res->body)) and
2139       (ref(\$res->body) eq 'SCALAR')
2140     ) {
2141         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2142
2143         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2144         # is false when the set charset is not the same as the encoding mimetype (maybe
2145         # confusing action at a distance here..
2146         # Don't try to set the charset if one already exists
2147         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2148           unless($c->res->content_type_charset);
2149     }
2150 }
2151
2152 =head2 $c->finalize_output
2153
2154 An alias for finalize_body.
2155
2156 =head2 $c->finalize_read
2157
2158 Finalizes the input after reading is complete.
2159
2160 =cut
2161
2162 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2163
2164 =head2 $c->finalize_uploads
2165
2166 Finalizes uploads. Cleans up any temporary files.
2167
2168 =cut
2169
2170 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2171
2172 =head2 $c->get_action( $action, $namespace )
2173
2174 Gets an action in a given namespace.
2175
2176 =cut
2177
2178 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2179
2180 =head2 $c->get_actions( $action, $namespace )
2181
2182 Gets all actions of a given name in a namespace and all parent
2183 namespaces.
2184
2185 =cut
2186
2187 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2188
2189 =head2 $app->handle_request( @arguments )
2190
2191 Called to handle each HTTP request.
2192
2193 =cut
2194
2195 sub handle_request {
2196     my ( $class, @arguments ) = @_;
2197
2198     # Always expect worst case!
2199     my $status = -1;
2200     try {
2201         if ($class->debug) {
2202             my $secs = time - $START || 1;
2203             my $av = sprintf '%.3f', $COUNT / $secs;
2204             my $time = localtime time;
2205             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2206         }
2207
2208         my $c = $class->prepare(@arguments);
2209         $c->dispatch;
2210         $status = $c->finalize;
2211     } catch {
2212         #rethow if this can be handled by middleware
2213         if ( $class->_handle_http_exception($_) ) {
2214             $_->can('rethrow') ? $_->rethrow : croak $_;
2215         }
2216         chomp(my $error = $_);
2217         $class->log->error(qq/Caught exception in engine "$error"/);
2218     };
2219
2220     $COUNT++;
2221
2222     if(my $coderef = $class->log->can('_flush')){
2223         $class->log->$coderef();
2224     }
2225     return $status;
2226 }
2227
2228 =head2 $class->prepare( @arguments )
2229
2230 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2231 etc.).
2232
2233 =cut
2234
2235 has _uploadtmp => (
2236     is => 'ro',
2237     predicate => '_has_uploadtmp',
2238 );
2239
2240 sub prepare {
2241     my ( $class, @arguments ) = @_;
2242
2243     # XXX
2244     # After the app/ctxt split, this should become an attribute based on something passed
2245     # into the application.
2246     $class->context_class( ref $class || $class ) unless $class->context_class;
2247
2248     my $uploadtmp = $class->config->{uploadtmp};
2249     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2250
2251     $c->response->_context($c);
2252
2253     #surely this is not the most efficient way to do things...
2254     $c->stats($class->stats_class->new)->enable($c->use_stats);
2255     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2256         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2257     }
2258
2259     try {
2260         # Allow engine to direct the prepare flow (for POE)
2261         if ( my $prepare = $c->engine->can('prepare') ) {
2262             $c->engine->$prepare( $c, @arguments );
2263         }
2264         else {
2265             $c->prepare_request(@arguments);
2266             $c->prepare_connection;
2267             $c->prepare_query_parameters;
2268             $c->prepare_headers; # Just hooks, no longer needed - they just
2269             $c->prepare_cookies; # cause the lazy attribute on req to build
2270             $c->prepare_path;
2271
2272             # Prepare the body for reading, either by prepare_body
2273             # or the user, if they are using $c->read
2274             $c->prepare_read;
2275
2276             # Parse the body unless the user wants it on-demand
2277             unless ( ref($c)->config->{parse_on_demand} ) {
2278                 $c->prepare_body;
2279             }
2280         }
2281         $c->prepare_action;
2282     }
2283     # VERY ugly and probably shouldn't rely on ->finalize actually working
2284     catch {
2285         # failed prepare is always due to an invalid request, right?
2286         $c->response->status(400);
2287         $c->response->content_type('text/plain');
2288         $c->response->body('Bad Request');
2289         # Note we call finalize and then die here, which escapes
2290         # finalize being called in the enclosing block..
2291         # It in fact couldn't be called, as we don't return $c..
2292         # This is a mess - but I'm unsure you can fix this without
2293         # breaking compat for people doing crazy things (we should set
2294         # the 400 and just return the ctx here IMO, letting finalize get called
2295         # above...
2296         $c->finalize;
2297         die $_;
2298     };
2299
2300     $c->log_request;
2301
2302     return $c;
2303 }
2304
2305 =head2 $c->prepare_action
2306
2307 Prepares action. See L<Catalyst::Dispatcher>.
2308
2309 =cut
2310
2311 sub prepare_action {
2312     my $c = shift;
2313     my $ret = $c->dispatcher->prepare_action( $c, @_);
2314
2315     if($c->encoding) {
2316         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2317           $_ = $c->_handle_param_unicode_decoding($_);
2318         }
2319     }
2320
2321     return $ret;
2322 }
2323
2324
2325 =head2 $c->prepare_body
2326
2327 Prepares message body.
2328
2329 =cut
2330
2331 sub prepare_body {
2332     my $c = shift;
2333
2334     return if $c->request->_has_body;
2335
2336     # Initialize on-demand data
2337     $c->engine->prepare_body( $c, @_ );
2338     $c->prepare_parameters;
2339     $c->prepare_uploads;
2340 }
2341
2342 =head2 $c->prepare_body_chunk( $chunk )
2343
2344 Prepares a chunk of data before sending it to L<HTTP::Body>.
2345
2346 See L<Catalyst::Engine>.
2347
2348 =cut
2349
2350 sub prepare_body_chunk {
2351     my $c = shift;
2352     $c->engine->prepare_body_chunk( $c, @_ );
2353 }
2354
2355 =head2 $c->prepare_body_parameters
2356
2357 Prepares body parameters.
2358
2359 =cut
2360
2361 sub prepare_body_parameters {
2362     my $c = shift;
2363     $c->request->prepare_body_parameters( $c, @_ );
2364 }
2365
2366 =head2 $c->prepare_connection
2367
2368 Prepares connection.
2369
2370 =cut
2371
2372 sub prepare_connection {
2373     my $c = shift;
2374     $c->request->prepare_connection($c);
2375 }
2376
2377 =head2 $c->prepare_cookies
2378
2379 Prepares cookies by ensuring that the attribute on the request
2380 object has been built.
2381
2382 =cut
2383
2384 sub prepare_cookies { my $c = shift; $c->request->cookies }
2385
2386 =head2 $c->prepare_headers
2387
2388 Prepares request headers by ensuring that the attribute on the request
2389 object has been built.
2390
2391 =cut
2392
2393 sub prepare_headers { my $c = shift; $c->request->headers }
2394
2395 =head2 $c->prepare_parameters
2396
2397 Prepares parameters.
2398
2399 =cut
2400
2401 sub prepare_parameters {
2402     my $c = shift;
2403     $c->prepare_body_parameters;
2404     $c->engine->prepare_parameters( $c, @_ );
2405 }
2406
2407 =head2 $c->prepare_path
2408
2409 Prepares path and base.
2410
2411 =cut
2412
2413 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2414
2415 =head2 $c->prepare_query_parameters
2416
2417 Prepares query parameters.
2418
2419 =cut
2420
2421 sub prepare_query_parameters {
2422     my $c = shift;
2423
2424     $c->engine->prepare_query_parameters( $c, @_ );
2425 }
2426
2427 =head2 $c->log_request
2428
2429 Writes information about the request to the debug logs.  This includes:
2430
2431 =over 4
2432
2433 =item * Request method, path, and remote IP address
2434
2435 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2436
2437 =item * Request parameters
2438
2439 =item * File uploads
2440
2441 =back
2442
2443 =cut
2444
2445 sub log_request {
2446     my $c = shift;
2447
2448     return unless $c->debug;
2449
2450     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2451     my $request = $dump->[1];
2452
2453     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2454     $method ||= '';
2455     $path = '/' unless length $path;
2456     $address ||= '';
2457
2458     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2459     $path = decode_utf8($path);
2460
2461     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2462
2463     $c->log_request_headers($request->headers);
2464
2465     if ( my $keywords = $request->query_keywords ) {
2466         $c->log->debug("Query keywords are: $keywords");
2467     }
2468
2469     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2470
2471     $c->log_request_uploads($request);
2472 }
2473
2474 =head2 $c->log_response
2475
2476 Writes information about the response to the debug logs by calling
2477 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2478
2479 =cut
2480
2481 sub log_response {
2482     my $c = shift;
2483
2484     return unless $c->debug;
2485
2486     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2487     my $response = $dump->[1];
2488
2489     $c->log_response_status_line($response);
2490     $c->log_response_headers($response->headers);
2491 }
2492
2493 =head2 $c->log_response_status_line($response)
2494
2495 Writes one line of information about the response to the debug logs.  This includes:
2496
2497 =over 4
2498
2499 =item * Response status code
2500
2501 =item * Content-Type header (if present)
2502
2503 =item * Content-Length header (if present)
2504
2505 =back
2506
2507 =cut
2508
2509 sub log_response_status_line {
2510     my ($c, $response) = @_;
2511
2512     $c->log->debug(
2513         sprintf(
2514             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2515             $response->status                            || 'unknown',
2516             $response->headers->header('Content-Type')   || 'unknown',
2517             $response->headers->header('Content-Length') || 'unknown'
2518         )
2519     );
2520 }
2521
2522 =head2 $c->log_response_headers($headers);
2523
2524 Hook method which can be wrapped by plugins to log the response headers.
2525 No-op in the default implementation.
2526
2527 =cut
2528
2529 sub log_response_headers {}
2530
2531 =head2 $c->log_request_parameters( query => {}, body => {} )
2532
2533 Logs request parameters to debug logs
2534
2535 =cut
2536
2537 sub log_request_parameters {
2538     my $c          = shift;
2539     my %all_params = @_;
2540
2541     return unless $c->debug;
2542
2543     my $column_width = Catalyst::Utils::term_width() - 44;
2544     foreach my $type (qw(query body)) {
2545         my $params = $all_params{$type};
2546         next if ! keys %$params;
2547         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2548         for my $key ( sort keys %$params ) {
2549             my $param = $params->{$key};
2550             my $value = defined($param) ? $param : '';
2551             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2552         }
2553         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2554     }
2555 }
2556
2557 =head2 $c->log_request_uploads
2558
2559 Logs file uploads included in the request to the debug logs.
2560 The parameter name, filename, file type, and file size are all included in
2561 the debug logs.
2562
2563 =cut
2564
2565 sub log_request_uploads {
2566     my $c = shift;
2567     my $request = shift;
2568     return unless $c->debug;
2569     my $uploads = $request->uploads;
2570     if ( keys %$uploads ) {
2571         my $t = Text::SimpleTable->new(
2572             [ 12, 'Parameter' ],
2573             [ 26, 'Filename' ],
2574             [ 18, 'Type' ],
2575             [ 9,  'Size' ]
2576         );
2577         for my $key ( sort keys %$uploads ) {
2578             my $upload = $uploads->{$key};
2579             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2580                 $t->row( $key, $u->filename, $u->type, $u->size );
2581             }
2582         }
2583         $c->log->debug( "File Uploads are:\n" . $t->draw );
2584     }
2585 }
2586
2587 =head2 $c->log_request_headers($headers);
2588
2589 Hook method which can be wrapped by plugins to log the request headers.
2590 No-op in the default implementation.
2591
2592 =cut
2593
2594 sub log_request_headers {}
2595
2596 =head2 $c->log_headers($type => $headers)
2597
2598 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2599
2600 =cut
2601
2602 sub log_headers {
2603     my $c       = shift;
2604     my $type    = shift;
2605     my $headers = shift;    # an HTTP::Headers instance
2606
2607     return unless $c->debug;
2608
2609     my $column_width = Catalyst::Utils::term_width() - 28;
2610     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2611     $headers->scan(
2612         sub {
2613             my ( $name, $value ) = @_;
2614             $t->row( $name, $value );
2615         }
2616     );
2617     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2618 }
2619
2620
2621 =head2 $c->prepare_read
2622
2623 Prepares the input for reading.
2624
2625 =cut
2626
2627 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2628
2629 =head2 $c->prepare_request
2630
2631 Prepares the engine request.
2632
2633 =cut
2634
2635 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2636
2637 =head2 $c->prepare_uploads
2638
2639 Prepares uploads.
2640
2641 =cut
2642
2643 sub prepare_uploads {
2644     my $c = shift;
2645     $c->engine->prepare_uploads( $c, @_ );
2646 }
2647
2648 =head2 $c->prepare_write
2649
2650 Prepares the output for writing.
2651
2652 =cut
2653
2654 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2655
2656 =head2 $c->request_class
2657
2658 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2659
2660 =head2 $c->response_class
2661
2662 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2663
2664 =head2 $c->read( [$maxlength] )
2665
2666 Reads a chunk of data from the request body. This method is designed to
2667 be used in a while loop, reading C<$maxlength> bytes on every call.
2668 C<$maxlength> defaults to the size of the request if not specified.
2669
2670 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2671 directly.
2672
2673 Warning: If you use read(), Catalyst will not process the body,
2674 so you will not be able to access POST parameters or file uploads via
2675 $c->request.  You must handle all body parsing yourself.
2676
2677 =cut
2678
2679 sub read { my $c = shift; return $c->request->read( @_ ) }
2680
2681 =head2 $c->run
2682
2683 Starts the engine.
2684
2685 =cut
2686
2687 sub run {
2688   my $app = shift;
2689   $app->_make_immutable_if_needed;
2690   $app->engine_loader->needs_psgi_engine_compat_hack ?
2691     $app->engine->run($app, @_) :
2692       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2693 }
2694
2695 sub _make_immutable_if_needed {
2696     my $class = shift;
2697     my $meta = find_meta($class);
2698     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2699     if (
2700         $meta->is_immutable
2701         && ! { $meta->immutable_options }->{replace_constructor}
2702         && $isa_ca
2703     ) {
2704         warn("You made your application class ($class) immutable, "
2705             . "but did not inline the\nconstructor. "
2706             . "This will break catalyst, as your app \@ISA "
2707             . "Class::Accessor(::Fast)?\nPlease pass "
2708             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2709     }
2710     unless ($meta->is_immutable) {
2711         # XXX - FIXME warning here as you should make your app immutable yourself.
2712         $meta->make_immutable(
2713             replace_constructor => 1,
2714         );
2715     }
2716 }
2717
2718 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2719
2720 Sets an action in a given namespace.
2721
2722 =cut
2723
2724 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2725
2726 =head2 $c->setup_actions($component)
2727
2728 Sets up actions for a component.
2729
2730 =cut
2731
2732 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2733
2734 =head2 $c->setup_components
2735
2736 This method is called internally to set up the application's components.
2737
2738 It finds modules by calling the L<locate_components> method, expands them to
2739 package names with the L<expand_component_module> method, and then installs
2740 each component into the application.
2741
2742 The C<setup_components> config option is passed to both of the above methods.
2743
2744 Installation of each component is performed by the L<setup_component> method,
2745 below.
2746
2747 =cut
2748
2749 sub setup_components {
2750     my $class = shift;
2751
2752     my $config  = $class->config->{ setup_components };
2753
2754     my @comps = $class->locate_components($config);
2755     my %comps = map { $_ => 1 } @comps;
2756
2757     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2758     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2759         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2760     ) if $deprecatedcatalyst_component_names;
2761
2762     for my $component ( @comps ) {
2763
2764         # We pass ignore_loaded here so that overlay files for (e.g.)
2765         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2766         # we know M::P::O found a file on disk so this is safe
2767
2768         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2769     }
2770
2771     for my $component (@comps) {
2772         my $instance = $class->components->{ $component } = $class->setup_component($component);
2773         my @expanded_components = $instance->can('expand_modules')
2774             ? $instance->expand_modules( $component, $config )
2775             : $class->expand_component_module( $component, $config );
2776         for my $component (@expanded_components) {
2777             next if $comps{$component};
2778             $class->components->{ $component } = $class->setup_component($component);
2779         }
2780     }
2781 }
2782
2783 =head2 $c->locate_components( $setup_component_config )
2784
2785 This method is meant to provide a list of component modules that should be
2786 setup for the application.  By default, it will use L<Module::Pluggable>.
2787
2788 Specify a C<setup_components> config option to pass additional options directly
2789 to L<Module::Pluggable>. To add additional search paths, specify a key named
2790 C<search_extra> as an array reference. Items in the array beginning with C<::>
2791 will have the application class name prepended to them.
2792
2793 =cut
2794
2795 sub locate_components {
2796     my $class  = shift;
2797     my $config = shift;
2798
2799     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2800     my $extra   = delete $config->{ search_extra } || [];
2801
2802     unshift @paths, @$extra;
2803
2804     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2805       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2806       %$config
2807     )->plugins } @paths;
2808
2809     return @comps;
2810 }
2811
2812 =head2 $c->expand_component_module( $component, $setup_component_config )
2813
2814 Components found by C<locate_components> will be passed to this method, which
2815 is expected to return a list of component (package) names to be set up.
2816
2817 =cut
2818
2819 sub expand_component_module {
2820     my ($class, $module) = @_;
2821     return Devel::InnerPackage::list_packages( $module );
2822 }
2823
2824 =head2 $c->setup_component
2825
2826 =cut
2827
2828 sub setup_component {
2829     my( $class, $component ) = @_;
2830
2831     unless ( $component->can( 'COMPONENT' ) ) {
2832         return $component;
2833     }
2834
2835     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2836     my $config = $class->config->{ $suffix } || {};
2837     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2838     # methods also pass it. local to avoid pointlessly shitting in config
2839     # for the debug screen, as $component is already the key name.
2840     local $config->{catalyst_component_name} = $component;
2841
2842     my $instance = eval { $component->COMPONENT( $class, $config ); };
2843
2844     if ( my $error = $@ ) {
2845         chomp $error;
2846         Catalyst::Exception->throw(
2847             message => qq/Couldn't instantiate component "$component", "$error"/
2848         );
2849     }
2850
2851     unless (blessed $instance) {
2852         my $metaclass = Moose::Util::find_meta($component);
2853         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2854         my $component_method_from = $method_meta->associated_metaclass->name;
2855         my $value = defined($instance) ? $instance : 'undef';
2856         Catalyst::Exception->throw(
2857             message =>
2858             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2859         );
2860     }
2861     return $instance;
2862 }
2863
2864 =head2 $c->setup_dispatcher
2865
2866 Sets up dispatcher.
2867
2868 =cut
2869
2870 sub setup_dispatcher {
2871     my ( $class, $dispatcher ) = @_;
2872
2873     if ($dispatcher) {
2874         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2875     }
2876
2877     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2878         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2879     }
2880
2881     unless ($dispatcher) {
2882         $dispatcher = $class->dispatcher_class;
2883     }
2884
2885     load_class($dispatcher);
2886
2887     # dispatcher instance
2888     $class->dispatcher( $dispatcher->new );
2889 }
2890
2891 =head2 $c->setup_engine
2892
2893 Sets up engine.
2894
2895 =cut
2896
2897 sub engine_class {
2898     my ($class, $requested_engine) = @_;
2899
2900     if (!$class->engine_loader || $requested_engine) {
2901         $class->engine_loader(
2902             Catalyst::EngineLoader->new({
2903                 application_name => $class,
2904                 (defined $requested_engine
2905                      ? (catalyst_engine_class => $requested_engine) : ()),
2906             }),
2907         );
2908     }
2909
2910     $class->engine_loader->catalyst_engine_class;
2911 }
2912
2913 sub setup_engine {
2914     my ($class, $requested_engine) = @_;
2915
2916     my $engine = do {
2917         my $loader = $class->engine_loader;
2918
2919         if (!$loader || $requested_engine) {
2920             $loader = Catalyst::EngineLoader->new({
2921                 application_name => $class,
2922                 (defined $requested_engine
2923                      ? (requested_engine => $requested_engine) : ()),
2924             }),
2925
2926             $class->engine_loader($loader);
2927         }
2928
2929         $loader->catalyst_engine_class;
2930     };
2931
2932     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2933     return if $class->loading_psgi_file;
2934
2935     load_class($engine);
2936
2937     if ($ENV{MOD_PERL}) {
2938         my $apache = $class->engine_loader->auto;
2939
2940         my $meta = find_meta($class);
2941         my $was_immutable = $meta->is_immutable;
2942         my %immutable_options = $meta->immutable_options;
2943         $meta->make_mutable if $was_immutable;
2944
2945         $meta->add_method(handler => sub {
2946             my $r = shift;
2947             my $psgi_app = $class->_finalized_psgi_app;
2948             $apache->call_app($r, $psgi_app);
2949         });
2950
2951         $meta->make_immutable(%immutable_options) if $was_immutable;
2952     }
2953
2954     $class->engine( $engine->new );
2955
2956     return;
2957 }
2958
2959 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2960 ## build in server support (back compat support for pre psgi port behavior).
2961 ## This is so that we don't build a new psgi app for each request when using
2962 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2963
2964 sub _finalized_psgi_app {
2965     my ($app) = @_;
2966
2967     unless ($app->_psgi_app) {
2968         my $psgi_app = $app->_setup_psgi_app;
2969         $app->_psgi_app($psgi_app);
2970     }
2971
2972     return $app->_psgi_app;
2973 }
2974
2975 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2976 ## home directory and load that and return it (just assume it is doing the
2977 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2978 ## in default_middleware and return it ( this is for backward compatibility
2979 ## with pre psgi port behavior ).
2980
2981 sub _setup_psgi_app {
2982     my ($app) = @_;
2983
2984     for my $home (Path::Class::Dir->new($app->config->{home})) {
2985         my $psgi_file = $home->file(
2986             Catalyst::Utils::appprefix($app) . '.psgi',
2987         );
2988
2989         next unless -e $psgi_file;
2990
2991         # If $psgi_file calls ->setup_engine, it's doing so to load
2992         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2993         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2994         # anyway. So set a flag (ick) that tells setup_engine not to populate
2995         # $c->engine or do any other things we might regret.
2996
2997         $app->loading_psgi_file(1);
2998         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2999         $app->loading_psgi_file(0);
3000
3001         return $psgi_app
3002             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3003
3004         warn <<"EOW";
3005 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3006
3007 Its content has been ignored. Please consult the Catalyst::Upgrading
3008 documentation on how to upgrade from Catalyst::Engine::PSGI.
3009 EOW
3010     }
3011
3012     return $app->apply_default_middlewares($app->psgi_app);
3013 }
3014
3015 =head2 $c->apply_default_middlewares
3016
3017 Adds the following L<Plack> middlewares to your application, since they are
3018 useful and commonly needed:
3019
3020 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3021 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3022 is smart enough to conditionally apply itself).
3023
3024 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3025 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3026 an indication that your server is running behind a proxy frontend.  However in
3027 2014 this is often not the case.  We preserve this code for backwards compatibility
3028 however I B<highly> recommend that if you are running the server behind a front
3029 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3030 setting to true for your environment configurations that run behind a proxy.  This
3031 way if you change your front end proxy address someday your code would inexplicably
3032 stop working as expected.
3033
3034 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3035 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3036 $ENV{SCRIPT_NAME}.
3037
3038 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3039 adding via C<registered_middleware> rather than this method.
3040
3041 If you are using Lighttp or IIS6 you may wish to apply these middlewares.  In
3042 general this is no longer a common case but we have this here for backward
3043 compatibility.
3044
3045 =cut
3046
3047
3048 sub apply_default_middlewares {
3049     my ($app, $psgi_app) = @_;
3050
3051     # Don't add this conditional IF we are explicitly saying we want the
3052     # frontend proxy support.  We don't need it here since if that is the
3053     # case it will be always loaded in the default_middleware.
3054
3055     unless($app->config->{using_frontend_proxy}) {
3056       $psgi_app = Plack::Middleware::Conditional->wrap(
3057           $psgi_app,
3058           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3059           condition => sub {
3060               my ($env) = @_;
3061               return if $app->config->{ignore_frontend_proxy};
3062               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3063           },
3064       );
3065     }
3066
3067     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3068     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3069     $psgi_app = Plack::Middleware::Conditional->wrap(
3070         $psgi_app,
3071         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3072         condition => sub {
3073             my ($env) = @_;
3074             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3075             return unless $1 < 4.23;
3076             1;
3077         },
3078     );
3079
3080     # we're applying this unconditionally as the middleware itself already makes
3081     # sure it doesn't fuck things up if it's not running under one of the right
3082     # IIS versions
3083     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3084
3085     # And another IIS issue, this time with IIS7.
3086     $psgi_app = Plack::Middleware::Conditional->wrap(
3087         $psgi_app,
3088         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3089         condition => sub {
3090             my ($env) = @_;
3091             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3092         },
3093     );
3094
3095     return $psgi_app;
3096 }
3097
3098 =head2 App->psgi_app
3099
3100 =head2 App->to_app
3101
3102 Returns a PSGI application code reference for the catalyst application
3103 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3104 method called.  We do however apply C<registered_middleware> since those are
3105 integral to how L<Catalyst> functions.  Also, unlike starting your application
3106 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3107 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3108 scripts in your $HOME directory.
3109
3110 B<NOTE> C<apply_default_middlewares> was orginally created when the first PSGI
3111 port was done for v5.90000.  These are middlewares that are added to achieve
3112 backward compatibility with older applications.  If you start your application
3113 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3114 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3115 automatically.  This was done so that pre and post PSGI port applications would
3116 work the same way.
3117
3118 This is what you want to be using to retrieve the PSGI application code
3119 reference of your Catalyst application for use in a custom F<.psgi> or in your
3120 own created server modules.
3121
3122 =cut
3123
3124 *to_app = \&psgi_app;
3125
3126 sub psgi_app {
3127     my ($app) = @_;
3128     my $psgi = $app->engine->build_psgi_app($app);
3129     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3130 }
3131
3132 =head2 $c->setup_home
3133
3134 Sets up the home directory.
3135
3136 =cut
3137
3138 sub setup_home {
3139     my ( $class, $home ) = @_;
3140
3141     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3142         $home = $env;
3143     }
3144
3145     $home ||= Catalyst::Utils::home($class);
3146
3147     if ($home) {
3148         #I remember recently being scolded for assigning config values like this
3149         $class->config->{home} ||= $home;
3150         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3151     }
3152 }
3153
3154 =head2 $c->setup_encoding
3155
3156 Sets up the input/output encoding. See L<ENCODING>
3157
3158 =cut
3159
3160 sub setup_encoding {
3161     my $c = shift;
3162     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3163         # Ok, so the user has explicitly said "I don't want encoding..."
3164         return;
3165     } else {
3166       my $enc = defined($c->config->{encoding}) ?
3167         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3168       $c->encoding($enc);
3169     }
3170 }
3171
3172 =head2 handle_unicode_encoding_exception
3173
3174 Hook to let you customize how encoding errors are handled.  By default
3175 we just throw an exception.  Receives a hashref of debug information.
3176 Example:
3177
3178     $c->handle_unicode_encoding_exception({
3179         param_value => $value,
3180         error_msg => $_,
3181             encoding_step => 'params',
3182         });
3183
3184 =cut
3185
3186 sub handle_unicode_encoding_exception {
3187     my ( $self, $exception_ctx ) = @_;
3188     die $exception_ctx->{error_msg};
3189 }
3190
3191 # Some unicode helpers cargo culted from the old plugin.  These could likely
3192 # be neater.
3193
3194 sub _handle_unicode_decoding {
3195     my ( $self, $value ) = @_;
3196
3197     return unless defined $value;
3198
3199     ## I think this mess is to support the old nested
3200     if ( ref $value eq 'ARRAY' ) {
3201         foreach ( @$value ) {
3202             $_ = $self->_handle_unicode_decoding($_);
3203         }
3204         return $value;
3205     }
3206     elsif ( ref $value eq 'HASH' ) {
3207         foreach (keys %$value) {
3208             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3209             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3210
3211             # If the key was encoded we now have two (the original and current so
3212             # delete the original.
3213             delete $value->{$_} if $_ ne $encoded_key;
3214         }
3215         return $value;
3216     }
3217     else {
3218         return $self->_handle_param_unicode_decoding($value);
3219     }
3220 }
3221
3222 sub _handle_param_unicode_decoding {
3223     my ( $self, $value ) = @_;
3224     return unless defined $value; # not in love with just ignoring undefs - jnap
3225
3226     my $enc = $self->encoding;
3227     return try {
3228       $enc->decode( $value, $self->_encode_check );
3229     }
3230     catch {
3231         $self->handle_unicode_encoding_exception({
3232             param_value => $value,
3233             error_msg => $_,
3234             encoding_step => 'params',
3235         });
3236     };
3237 }
3238
3239 =head2 $c->setup_log
3240
3241 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3242 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3243 log to.
3244
3245 This method also installs a C<debug> method that returns a true value into the
3246 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3247 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3248
3249 Note that if the log has already been setup, by either a previous call to
3250 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3251 that this method won't actually set up the log object.
3252
3253 =cut
3254
3255 sub setup_log {
3256     my ( $class, $levels ) = @_;
3257
3258     $levels ||= '';
3259     $levels =~ s/^\s+//;
3260     $levels =~ s/\s+$//;
3261     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3262
3263     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3264     if ( defined $env_debug ) {
3265         $levels{debug} = 1 if $env_debug; # Ugly!
3266         delete($levels{debug}) unless $env_debug;
3267     }
3268
3269     unless ( $class->log ) {
3270         $class->log( Catalyst::Log->new(keys %levels) );
3271     }
3272
3273     if ( $levels{debug} ) {
3274         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3275         $class->log->debug('Debug messages enabled');
3276     }
3277 }
3278
3279 =head2 $c->setup_plugins
3280
3281 Sets up plugins.
3282
3283 =cut
3284
3285 =head2 $c->setup_stats
3286
3287 Sets up timing statistics class.
3288
3289 =cut
3290
3291 sub setup_stats {
3292     my ( $class, $stats ) = @_;
3293
3294     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3295
3296     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3297     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3298         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3299         $class->log->debug('Statistics enabled');
3300     }
3301 }
3302
3303
3304 =head2 $c->registered_plugins
3305
3306 Returns a sorted list of the plugins which have either been stated in the
3307 import list.
3308
3309 If passed a given plugin name, it will report a boolean value indicating
3310 whether or not that plugin is loaded.  A fully qualified name is required if
3311 the plugin name does not begin with C<Catalyst::Plugin::>.
3312
3313  if ($c->registered_plugins('Some::Plugin')) {
3314      ...
3315  }
3316
3317 =cut
3318
3319 {
3320
3321     sub registered_plugins {
3322         my $proto = shift;
3323         return sort keys %{ $proto->_plugins } unless @_;
3324         my $plugin = shift;
3325         return 1 if exists $proto->_plugins->{$plugin};
3326         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3327     }
3328
3329     sub _register_plugin {
3330         my ( $proto, $plugin, $instant ) = @_;
3331         my $class = ref $proto || $proto;
3332
3333         load_class( $plugin );
3334         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3335             if $plugin->isa( 'Catalyst::Component' );
3336         my $plugin_meta = Moose::Meta::Class->create($plugin);
3337         if (!$plugin_meta->has_method('new')
3338             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3339             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3340         }
3341         if (!$instant && !$proto->_plugins->{$plugin}) {
3342             my $meta = Class::MOP::get_metaclass_by_name($class);
3343             $meta->superclasses($plugin, $meta->superclasses);
3344         }
3345         $proto->_plugins->{$plugin} = 1;
3346         return $class;
3347     }
3348
3349     sub _default_plugins { return qw() }
3350
3351     sub setup_plugins {
3352         my ( $class, $plugins ) = @_;
3353
3354         $class->_plugins( {} ) unless $class->_plugins;
3355         $plugins = [ grep {
3356             m/Unicode::Encoding/ ? do {
3357                 $class->log->warn(
3358                     'Unicode::Encoding plugin is auto-applied,'
3359                     . ' please remove this from your appclass'
3360                     . ' and make sure to define "encoding" config'
3361                 );
3362                 unless (exists $class->config->{'encoding'}) {
3363                   $class->config->{'encoding'} = 'UTF-8';
3364                 }
3365                 () }
3366                 : $_
3367         } @$plugins ];
3368         push @$plugins, $class->_default_plugins;
3369         $plugins = Data::OptList::mkopt($plugins || []);
3370
3371         my @plugins = map {
3372             [ Catalyst::Utils::resolve_namespace(
3373                   $class . '::Plugin',
3374                   'Catalyst::Plugin', $_->[0]
3375               ),
3376               $_->[1],
3377             ]
3378          } @{ $plugins };
3379
3380         for my $plugin ( reverse @plugins ) {
3381             load_class($plugin->[0], $plugin->[1]);
3382             my $meta = find_meta($plugin->[0]);
3383             next if $meta && $meta->isa('Moose::Meta::Role');
3384
3385             $class->_register_plugin($plugin->[0]);
3386         }
3387
3388         my @roles =
3389             map  { $_->[0]->name, $_->[1] }
3390             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3391             map  { [find_meta($_->[0]), $_->[1]] }
3392             @plugins;
3393
3394         Moose::Util::apply_all_roles(
3395             $class => @roles
3396         ) if @roles;
3397     }
3398 }
3399
3400 =head2 default_middleware
3401
3402 Returns a list of instantiated PSGI middleware objects which is the default
3403 middleware that is active for this application (taking any configuration
3404 options into account, excluding your custom added middleware via the C<psgi_middleware>
3405 configuration option).  You can override this method if you wish to change
3406 the default middleware (although do so at risk since some middleware is vital
3407 to application function.)
3408
3409 The current default middleware list is:
3410
3411       Catalyst::Middleware::Stash
3412       Plack::Middleware::HTTPExceptions
3413       Plack::Middleware::RemoveRedundantBody
3414       Plack::Middleware::FixMissingBodyInRedirect
3415       Plack::Middleware::ContentLength
3416       Plack::Middleware::MethodOverride
3417       Plack::Middleware::Head
3418
3419 If the configuration setting C<using_frontend_proxy> is true we add:
3420
3421       Plack::Middleware::ReverseProxy
3422
3423 If the configuration setting C<using_frontend_proxy_path> is true we add:
3424
3425       Plack::Middleware::ReverseProxyPath
3426
3427 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3428 L<Catalyst> distribution so if you want to use this option you should add it to
3429 your project distribution file.
3430
3431 These middlewares will be added at L</setup_middleware> during the
3432 L</setup> phase of application startup.
3433
3434 =cut
3435
3436 sub default_middleware {
3437     my $class = shift;
3438     my @mw = (
3439       Catalyst::Middleware::Stash->new,
3440       Plack::Middleware::HTTPExceptions->new,
3441       Plack::Middleware::RemoveRedundantBody->new,
3442       Plack::Middleware::FixMissingBodyInRedirect->new,
3443       Plack::Middleware::ContentLength->new,
3444       Plack::Middleware::MethodOverride->new,
3445       Plack::Middleware::Head->new);
3446
3447     if($class->config->{using_frontend_proxy}) {
3448         push @mw, Plack::Middleware::ReverseProxy->new;
3449     }
3450
3451     if($class->config->{using_frontend_proxy_path}) {
3452         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3453             push @mw, Plack::Middleware::ReverseProxyPath->new;
3454         } else {
3455           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3456         }
3457     }
3458
3459     return @mw;
3460 }
3461
3462 =head2 registered_middlewares
3463
3464 Read only accessor that returns an array of all the middleware in the order
3465 that they were added (which is the REVERSE of the order they will be applied).
3466
3467 The values returned will be either instances of L<Plack::Middleware> or of a
3468 compatible interface, or a coderef, which is assumed to be inlined middleware
3469
3470 =head2 setup_middleware (?@middleware)
3471
3472 Read configuration information stored in configuration key C<psgi_middleware> or
3473 from passed @args.
3474
3475 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3476 to use it to enable L<Plack::Middleware>
3477
3478 This method is automatically called during 'setup' of your application, so
3479 you really don't need to invoke it.  However you may do so if you find the idea
3480 of loading middleware via configuration weird :).  For example:
3481
3482     package MyApp;
3483
3484     use Catalyst;
3485
3486     __PACKAGE__->setup_middleware('Head');
3487     __PACKAGE__->setup;
3488
3489 When we read middleware definitions from configuration, we reverse the list
3490 which sounds odd but is likely how you expect it to work if you have prior
3491 experience with L<Plack::Builder> or if you previously used the plugin
3492 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3493
3494 So basically your middleware handles an incoming request from the first
3495 registered middleware, down and handles the response from the last middleware
3496 up.
3497
3498 =cut
3499
3500 sub registered_middlewares {
3501     my $class = shift;
3502     if(my $middleware = $class->_psgi_middleware) {
3503         my @mw = ($class->default_middleware, @$middleware);
3504
3505         if($class->config->{using_frontend_proxy}) {
3506           push @mw, Plack::Middleware::ReverseProxy->new;
3507         }
3508
3509         return @mw;
3510     } else {
3511         die "You cannot call ->registered_middlewares until middleware has been setup";
3512     }
3513 }
3514
3515 sub setup_middleware {
3516     my $class = shift;
3517     my @middleware_definitions;
3518
3519     # If someone calls this method you can add middleware with args.  However if its
3520     # called without an arg we need to setup the configuration middleware.
3521     if(@_) {
3522       @middleware_definitions = reverse(@_);
3523     } else {
3524       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3525         unless $class->config->{__configured_from_psgi_middleware};
3526       $class->config->{__configured_from_psgi_middleware} = 1; # Only do this once, just in case some people call setup over and over...
3527     }
3528
3529     my @middleware = ();
3530     while(my $next = shift(@middleware_definitions)) {
3531         if(ref $next) {
3532             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3533                 push @middleware, $next;
3534             } elsif(ref $next eq 'CODE') {
3535                 push @middleware, $next;
3536             } elsif(ref $next eq 'HASH') {
3537                 my $namespace = shift @middleware_definitions;
3538                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3539                 push @middleware, $mw;
3540             } else {
3541               die "I can't handle middleware definition ${\ref $next}";
3542             }
3543         } else {
3544           my $mw = $class->Catalyst::Utils::build_middleware($next);
3545           push @middleware, $mw;
3546         }
3547     }
3548
3549     my @existing = @{$class->_psgi_middleware || []};
3550     $class->_psgi_middleware([@middleware,@existing,]);
3551 }
3552
3553 =head2 registered_data_handlers
3554
3555 A read only copy of registered Data Handlers returned as a Hash, where each key
3556 is a content type and each value is a subref that attempts to decode that content
3557 type.
3558
3559 =head2 setup_data_handlers (?@data_handler)
3560
3561 Read configuration information stored in configuration key C<data_handlers> or
3562 from passed @args.
3563
3564 See under L</CONFIGURATION> information regarding C<data_handlers>.
3565
3566 This method is automatically called during 'setup' of your application, so
3567 you really don't need to invoke it.
3568
3569 =head2 default_data_handlers
3570
3571 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3572 only two default data handlers, for 'application/json' and an alternative to
3573 'application/x-www-form-urlencoded' which supposed nested form parameters via
3574 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3575
3576 The 'application/json' data handler is used to parse incoming JSON into a Perl
3577 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3578 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3579 JSON decoder, and has the smallest dependency impact.
3580
3581 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3582 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3583 order to get the best performance.  You should add either to your dependency
3584 list (Makefile.PL, dist.ini, cpanfile, etc.)
3585
3586 =cut
3587
3588 sub registered_data_handlers {
3589     my $class = shift;
3590     if(my $data_handlers = $class->_data_handlers) {
3591         return %$data_handlers;
3592     } else {
3593         $class->setup_data_handlers;
3594         return $class->registered_data_handlers;
3595     }
3596 }
3597
3598 sub setup_data_handlers {
3599     my ($class, %data_handler_callbacks) = @_;
3600     %data_handler_callbacks = (
3601       %{$class->default_data_handlers},
3602       %{$class->config->{'data_handlers'}||+{}},
3603       %data_handler_callbacks);
3604
3605     $class->_data_handlers(\%data_handler_callbacks);
3606 }
3607
3608 sub default_data_handlers {
3609     my ($class) = @_;
3610     return +{
3611       'application/x-www-form-urlencoded' => sub {
3612           my ($fh, $req) = @_;
3613           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3614           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3615             ->can('build_cgi_struct')->($params);
3616       },
3617       'application/json' => sub {
3618           my ($fh, $req) = @_;
3619           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
3620           my $slurped;
3621           return eval {
3622             local $/;
3623             $slurped = $fh->getline;
3624             $parser->can("decode_json")->($slurped);
3625           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
3626         },
3627     };
3628 }
3629
3630 sub _handle_http_exception {
3631     my ( $self, $error ) = @_;
3632     if (
3633            !$self->config->{always_catch_http_exceptions}
3634         && blessed $error
3635         && (
3636             $error->can('as_psgi')
3637             || (   $error->can('code')
3638                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
3639         )
3640       )
3641     {
3642         return 1;
3643     }
3644 }
3645
3646 =head2 $c->stack
3647
3648 Returns an arrayref of the internal execution stack (actions that are
3649 currently executing).
3650
3651 =head2 $c->stats
3652
3653 Returns the current timing statistics object. By default Catalyst uses
3654 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3655 L<< stats_class|/"$c->stats_class" >>.
3656
3657 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3658 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3659 profile explicitly, although MyApp.pm still won't profile nor output anything
3660 by itself.
3661
3662 =head2 $c->stats_class
3663
3664 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3665
3666 =head2 $c->use_stats
3667
3668 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3669
3670 Note that this is a static method, not an accessor and should be overridden
3671 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3672
3673 =cut
3674
3675 sub use_stats { 0 }
3676
3677
3678 =head2 $c->write( $data )
3679
3680 Writes $data to the output stream. When using this method directly, you
3681 will need to manually set the C<Content-Length> header to the length of
3682 your output data, if known.
3683
3684 =cut
3685
3686 sub write {
3687     my $c = shift;
3688
3689     # Finalize headers if someone manually writes output (for compat)
3690     $c->finalize_headers;
3691
3692     return $c->response->write( @_ );
3693 }
3694
3695 =head2 version
3696
3697 Returns the Catalyst version number. Mostly useful for "powered by"
3698 messages in template systems.
3699
3700 =cut
3701
3702 sub version { return $Catalyst::VERSION }
3703
3704 =head1 CONFIGURATION
3705
3706 There are a number of 'base' config variables which can be set:
3707
3708 =over
3709
3710 =item *
3711
3712 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
3713 rethrows errors conforming to the interface described by
3714 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
3715 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
3716
3717 =item *
3718
3719 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3720
3721 =item *
3722
3723 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3724
3725 =item *
3726
3727 C<disable_component_resolution_regex_fallback> - Turns
3728 off the deprecated component resolution functionality so
3729 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3730 are called then regex search will not be attempted on string values and
3731 instead C<undef> will be returned.
3732
3733 =item *
3734
3735 C<home> - The application home directory. In an uninstalled application,
3736 this is the top level application directory. In an installed application,
3737 this will be the directory containing C<< MyApp.pm >>.
3738
3739 =item *
3740
3741 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3742
3743 =item *
3744
3745 C<name> - The name of the application in debug messages and the debug and
3746 welcome screens
3747
3748 =item *
3749
3750 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3751 until it is accessed. This allows you to (for example) check authentication (and reject
3752 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3753
3754 =item *
3755
3756 C<root> - The root directory for templates. Usually this is just a
3757 subdirectory of the home directory, but you can set it to change the
3758 templates to a different directory.
3759
3760 =item *
3761
3762 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3763 namespaces from which components will be loaded (and constructed and stored in
3764 C<< $c->components >>).
3765
3766 =item *
3767
3768 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3769 to be shown in hit debug tables in the test server.
3770
3771 =item *
3772
3773 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3774 variable should be used for determining the request path.
3775
3776 Most web server environments pass the requested path to the application using environment variables,
3777 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3778 exposed as C<< $c->request->base >>) and the request path below that base.
3779
3780 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3781 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3782
3783 =over
3784
3785 =item use_request_uri_for_path => 0
3786
3787 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3788 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3789 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3790 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3791
3792 However this method has the major disadvantage that it is impossible to correctly decode some elements
3793 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3794 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3795 can't distinguish / vs %2F in paths (in addition to other encoded values).
3796
3797 =item use_request_uri_for_path => 1
3798
3799 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3800 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3801 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3802
3803 Given that this method of path resolution is provably more correct, it is recommended that you use
3804 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3805 aware of the implications of not being able to handle encoded URI paths correctly.
3806
3807 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3808 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3809 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3810 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3811 C<< $c->request->base >> will be incorrect.
3812
3813 =back
3814
3815 =item *
3816
3817 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3818
3819 =item *
3820
3821 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
3822 installed, otherwise log an error).  This is useful if your application is not running on the
3823 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
3824 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
3825 This has been done since not all people need this feature and we wish to restrict the growth of
3826 L<Catalyst> dependencies.
3827
3828 =item *
3829
3830 C<encoding> - See L</ENCODING>
3831
3832 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
3833 value to undef.
3834
3835 =item *
3836
3837 C<abort_chain_on_error_fix>
3838
3839 When there is an error in an action chain, the default behavior is to continue
3840 processing the remaining actions and then catch the error upon chain end.  This
3841 can lead to running actions when the application is in an unexpected state.  If
3842 you have this issue, setting this config value to true will promptly exit a
3843 chain when there is an error raised in any action (thus terminating the chain
3844 early.)
3845
3846 use like:
3847
3848     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3849
3850 In the future this might become the default behavior.
3851
3852 =item *
3853
3854 C<use_hash_multivalue_in_request>
3855
3856 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3857 and C<parameters> return a hashref where values might be scalar or an arrayref
3858 depending on the incoming data.  In many cases this can be undesirable as it
3859 leads one to writing defensive code like the following:
3860
3861     my ($val) = ref($c->req->parameters->{a}) ?
3862       @{$c->req->parameters->{a}} :
3863         $c->req->parameters->{a};
3864
3865 Setting this configuration item to true will make L<Catalyst> populate the
3866 attributes underlying these methods with an instance of L<Hash::MultiValue>
3867 which is used by L<Plack::Request> and others to solve this very issue.  You
3868 may prefer this behavior to the default, if so enable this option (be warned
3869 if you enable it in a legacy application we are not sure if it is completely
3870 backwardly compatible).
3871
3872 =item *
3873
3874 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3875
3876 =item *
3877
3878 C<data_handlers> - See L<DATA HANDLERS>.
3879
3880 =back
3881
3882 =head1 EXCEPTIONS
3883
3884 Generally when you throw an exception inside an Action (or somewhere in
3885 your stack, such as in a model that an Action is calling) that exception
3886 is caught by Catalyst and unless you either catch it yourself (via eval
3887 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3888 will eventually reach L</finalize_errors> and return either the debugging
3889 error stack page, or the default error page.  However, if your exception
3890 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3891 instead rethrow it so that it can be handled by that middleware (which
3892 is part of the default middleware).  For example this would allow
3893
3894     use HTTP::Throwable::Factory 'http_throw';
3895
3896     sub throws_exception :Local {
3897       my ($self, $c) = @_;
3898
3899       http_throw(SeeOther => { location =>
3900         $c->uri_for($self->action_for('redirect')) });
3901
3902     }
3903
3904 =head1 INTERNAL ACTIONS
3905
3906 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3907 C<_ACTION>, and C<_END>. These are by default not shown in the private
3908 action table, but you can make them visible with a config parameter.
3909
3910     MyApp->config(show_internal_actions => 1);
3911
3912 =head1 ON-DEMAND PARSER
3913
3914 The request body is usually parsed at the beginning of a request,
3915 but if you want to handle input yourself, you can enable on-demand
3916 parsing with a config parameter.
3917
3918     MyApp->config(parse_on_demand => 1);
3919
3920 =head1 PROXY SUPPORT
3921
3922 Many production servers operate using the common double-server approach,
3923 with a lightweight frontend web server passing requests to a larger
3924 backend server. An application running on the backend server must deal
3925 with two problems: the remote user always appears to be C<127.0.0.1> and
3926 the server's hostname will appear to be C<localhost> regardless of the
3927 virtual host that the user connected through.
3928
3929 Catalyst will automatically detect this situation when you are running
3930 the frontend and backend servers on the same machine. The following
3931 changes are made to the request.
3932
3933     $c->req->address is set to the user's real IP address, as read from
3934     the HTTP X-Forwarded-For header.
3935
3936     The host value for $c->req->base and $c->req->uri is set to the real
3937     host, as read from the HTTP X-Forwarded-Host header.
3938
3939 Additionally, you may be running your backend application on an insecure
3940 connection (port 80) while your frontend proxy is running under SSL.  If there
3941 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3942 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3943 be created properly.
3944
3945 In the case of passing in:
3946
3947     X-Forwarded-Port: 443
3948
3949 All calls to C<uri_for> will result in an https link, as is expected.
3950
3951 Obviously, your web server must support these headers for this to work.
3952
3953 In a more complex server farm environment where you may have your
3954 frontend proxy server(s) on different machines, you will need to set a
3955 configuration option to tell Catalyst to read the proxied data from the
3956 headers.
3957
3958     MyApp->config(using_frontend_proxy => 1);
3959
3960 If you do not wish to use the proxy support at all, you may set:
3961
3962     MyApp->config(ignore_frontend_proxy => 0);
3963
3964 =head2 Note about psgi files
3965
3966 Note that if you supply your own .psgi file, calling
3967 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3968
3969 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3970 in your psgi, for example:
3971
3972     builder {
3973         enable "Plack::Middleware::ReverseProxy";
3974         MyApp->psgi_app
3975     };
3976
3977 This will unconditionally add the ReverseProxy support, or you need to call
3978 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3979 apply the support depending upon your config).
3980
3981 See L<Catalyst::PSGI> for more information.
3982
3983 =head1 THREAD SAFETY
3984
3985 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3986 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3987 believe the Catalyst core to be thread-safe.
3988
3989 If you plan to operate in a threaded environment, remember that all other
3990 modules you are using must also be thread-safe. Some modules, most notably
3991 L<DBD::SQLite>, are not thread-safe.
3992
3993 =head1 DATA HANDLERS
3994
3995 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3996 form parameters and URL search query fields.  However it has become common
3997 for various alternative content types to be PUT or POSTed to your controllers
3998 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3999 XML and other content types when communicating with an application server.  In
4000 order to better support this use case, L<Catalyst> defines a global configuration
4001 option, C<data_handlers>, which lets you associate a content type with a coderef
4002 that parses that content type into something Perl can readily access.
4003
4004     package MyApp::Web;
4005
4006     use Catalyst;
4007     use JSON::Maybe;
4008
4009     __PACKAGE__->config(
4010       data_handlers => {
4011         'application/json' => sub { local $/; decode_json $_->getline },
4012       },
4013       ## Any other configuration.
4014     );
4015
4016     __PACKAGE__->setup;
4017
4018 By default L<Catalyst> comes with a generic JSON data handler similar to the
4019 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4020 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4021 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4022 or dist.ini, cpanfile, etc.)
4023
4024 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4025 (matched against the incoming request type using a regexp such as to be case
4026 insensitive) and whose values are coderefs that receive a localized version of
4027 C<$_> which is a filehandle object pointing to received body.
4028
4029 This feature is considered an early access release and we reserve the right
4030 to alter the interface in order to provide a performant and secure solution to
4031 alternative request body content.  Your reports welcomed!
4032
4033 =head1 PSGI MIDDLEWARE
4034
4035 You can define middleware, defined as L<Plack::Middleware> or a compatible
4036 interface in configuration.  Your middleware definitions are in the form of an
4037 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4038 with details to follow:
4039
4040     package MyApp::Web;
4041
4042     use Catalyst;
4043     use Plack::Middleware::StackTrace;
4044
4045     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4046
4047     __PACKAGE__->config(
4048       'psgi_middleware', [
4049         'Debug',
4050         '+MyApp::Custom',
4051         $stacktrace_middleware,
4052         'Session' => {store => 'File'},
4053         sub {
4054           my $app = shift;
4055           return sub {
4056             my $env = shift;
4057             $env->{myapp.customkey} = 'helloworld';
4058             $app->($env);
4059           },
4060         },
4061       ],
4062     );
4063
4064     __PACKAGE__->setup;
4065
4066 So the general form is:
4067
4068     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4069
4070 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4071 the order listed (to make it function similarly to L<Plack::Builder>:
4072
4073 Alternatively, you may also define middleware by calling the L</setup_middleware>
4074 package method:
4075
4076     package MyApp::Web;
4077
4078     use Catalyst;
4079
4080     __PACKAGE__->setup_middleware( \@middleware_definitions);
4081     __PACKAGE__->setup;
4082
4083 In the case where you do both (use 'setup_middleware' and configuration) the
4084 package call to setup_middleware will be applied earlier (in other words its
4085 middleware will wrap closer to the application).  Keep this in mind since in
4086 some cases the order of middleware is important.
4087
4088 The two approaches are not exclusive.
4089
4090 =over 4
4091
4092 =item Middleware Object
4093
4094 An already initialized object that conforms to the L<Plack::Middleware>
4095 specification:
4096
4097     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4098
4099     __PACKAGE__->config(
4100       'psgi_middleware', [
4101         $stacktrace_middleware,
4102       ]);
4103
4104
4105 =item coderef
4106
4107 A coderef that is an inlined middleware:
4108
4109     __PACKAGE__->config(
4110       'psgi_middleware', [
4111         sub {
4112           my $app = shift;
4113           return sub {
4114             my $env = shift;
4115             if($env->{PATH_INFO} =~m/forced/) {
4116               Plack::App::File
4117                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4118                 ->call($env);
4119             } else {
4120               return $app->($env);
4121             }
4122          },
4123       },
4124     ]);
4125
4126
4127
4128 =item a scalar
4129
4130 We assume the scalar refers to a namespace after normalizing it using the
4131 following rules:
4132
4133 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4134 is assumed to be 'as is', and we just install and use the middleware.
4135
4136 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4137 (the package name of your Catalyst application subclass), we also assume then
4138 that it is a full namespace, and use it.
4139
4140 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4141 resolve it first by looking for it under your application namespace (for example
4142 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4143 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4144 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4145 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4146 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4147 you find that a good idea.
4148
4149 Examples:
4150
4151     package MyApp::Web;
4152
4153     __PACKAGE__->config(
4154       'psgi_middleware', [
4155         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4156         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4157         '+MyApp::Custom',  ## MyApp::Custom->wrap
4158       ],
4159     );
4160
4161 =item a scalar followed by a hashref
4162
4163 Just like the previous, except the following C<HashRef> is used as arguments
4164 to initialize the middleware object.
4165
4166     __PACKAGE__->config(
4167       'psgi_middleware', [
4168          'Session' => {store => 'File'},
4169     ]);
4170
4171 =back
4172
4173 Please see L<PSGI> for more on middleware.
4174
4175 =head1 ENCODING
4176
4177 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4178 and set to encode all body responses to UTF8 when possible and applicable.
4179 Following is documentation on this process.  If you are using an older
4180 version of L<Catalyst> you should review documentation for that version since
4181 a lot has changed.
4182
4183 By default encoding is now 'UTF-8'.  You may turn it off by setting
4184 the encoding configuration to undef.
4185
4186     MyApp->config(encoding => undef);
4187
4188 This is recommended for temporary backwards compatibility only.
4189
4190 Encoding is automatically applied when the content-type is set to
4191 a type that can be encoded.  Currently we encode when the content type
4192 matches the following regular expression:
4193
4194     $content_type =~ /^text|xml$|javascript$/
4195
4196 Encoding is set on the application, but it is copied to the context object
4197 so that you can override it on a request basis.
4198
4199 Be default we don't automatically encode 'application/json' since the most
4200 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4201 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4202 encoding issues.
4203
4204 If you are producing JSON response in an unconventional manner (such
4205 as via a template or manual strings) you should perform the UTF8 encoding
4206 manually as well such as to conform to the JSON specification.
4207
4208 NOTE: We also examine the value of $c->response->content_encoding.  If
4209 you set this (like for example 'gzip', and manually gzipping the body)
4210 we assume that you have done all the neccessary encoding yourself, since
4211 we cannot encode the gzipped contents.  If you use a plugin like
4212 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4213 to have this function correctly  with the new UTF8 encoding code, or you
4214 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4215 a front end proxy.
4216
4217 =head2 Methods
4218
4219 =over 4
4220
4221 =item encoding
4222
4223 Returns an instance of an C<Encode> encoding
4224
4225     print $c->encoding->name
4226
4227 =item handle_unicode_encoding_exception ($exception_context)
4228
4229 Method called when decoding process for a request fails.
4230
4231 An C<$exception_context> hashref is provided to allow you to override the
4232 behaviour of your application when given data with incorrect encodings.
4233
4234 The default method throws exceptions in the case of invalid request parameters
4235 (resulting in a 500 error), but ignores errors in upload filenames.
4236
4237 The keys passed in the C<$exception_context> hash are:
4238
4239 =over
4240
4241 =item param_value
4242
4243 The value which was not able to be decoded.
4244
4245 =item error_msg
4246
4247 The exception received from L<Encode>.
4248
4249 =item encoding_step
4250
4251 What type of data was being decoded. Valid values are (currently)
4252 C<params> - for request parameters / arguments / captures
4253 and C<uploads> - for request upload filenames.
4254
4255 =back
4256
4257 =back
4258
4259 =head1 SUPPORT
4260
4261 IRC:
4262
4263     Join #catalyst on irc.perl.org.
4264
4265 Mailing Lists:
4266
4267     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4268     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4269
4270 Web:
4271
4272     http://catalyst.perl.org
4273
4274 Wiki:
4275
4276     http://dev.catalyst.perl.org
4277
4278 =head1 SEE ALSO
4279
4280 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4281
4282 =head2 L<Catalyst::Manual> - The Catalyst Manual
4283
4284 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4285
4286 =head2 L<Catalyst::Engine> - Core engine
4287
4288 =head2 L<Catalyst::Log> - Log class.
4289
4290 =head2 L<Catalyst::Request> - Request object
4291
4292 =head2 L<Catalyst::Response> - Response object
4293
4294 =head2 L<Catalyst::Test> - The test suite.
4295
4296 =head1 PROJECT FOUNDER
4297
4298 sri: Sebastian Riedel <sri@cpan.org>
4299
4300 =head1 CONTRIBUTORS
4301
4302 abw: Andy Wardley
4303
4304 acme: Leon Brocard <leon@astray.com>
4305
4306 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4307
4308 Andrew Bramble
4309
4310 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4311
4312 Andrew Ruthven
4313
4314 andyg: Andy Grundman <andy@hybridized.org>
4315
4316 audreyt: Audrey Tang
4317
4318 bricas: Brian Cassidy <bricas@cpan.org>
4319
4320 Caelum: Rafael Kitover <rkitover@io.com>
4321
4322 chansen: Christian Hansen
4323
4324 chicks: Christopher Hicks
4325
4326 Chisel Wright C<pause@herlpacker.co.uk>
4327
4328 Danijel Milicevic C<me@danijel.de>
4329
4330 davewood: David Schmidt <davewood@cpan.org>
4331
4332 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4333
4334 David Naughton, C<naughton@umn.edu>
4335
4336 David E. Wheeler
4337
4338 dhoss: Devin Austin <dhoss@cpan.org>
4339
4340 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4341
4342 Drew Taylor
4343
4344 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4345
4346 esskar: Sascha Kiefer
4347
4348 fireartist: Carl Franks <cfranks@cpan.org>
4349
4350 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4351
4352 gabb: Danijel Milicevic
4353
4354 Gary Ashton Jones
4355
4356 Gavin Henry C<ghenry@perl.me.uk>
4357
4358 Geoff Richards
4359
4360 groditi: Guillermo Roditi <groditi@gmail.com>
4361
4362 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4363
4364 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4365
4366 jcamacho: Juan Camacho
4367
4368 jester: Jesse Sheidlower C<jester@panix.com>
4369
4370 jhannah: Jay Hannah <jay@jays.net>
4371
4372 Jody Belka
4373
4374 Johan Lindstrom
4375
4376 jon: Jon Schutz <jjschutz@cpan.org>
4377
4378 Jonathan Rockway C<< <jrockway@cpan.org> >>
4379
4380 Kieren Diment C<kd@totaldatasolution.com>
4381
4382 konobi: Scott McWhirter <konobi@cpan.org>
4383
4384 marcus: Marcus Ramberg <mramberg@cpan.org>
4385
4386 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4387
4388 mgrimes: Mark Grimes <mgrimes@cpan.org>
4389
4390 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4391
4392 mugwump: Sam Vilain
4393
4394 naughton: David Naughton
4395
4396 ningu: David Kamholz <dkamholz@cpan.org>
4397
4398 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4399
4400 numa: Dan Sully <daniel@cpan.org>
4401
4402 obra: Jesse Vincent
4403
4404 Octavian Rasnita
4405
4406 omega: Andreas Marienborg
4407
4408 Oleg Kostyuk <cub.uanic@gmail.com>
4409
4410 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4411
4412 rafl: Florian Ragwitz <rafl@debian.org>
4413
4414 random: Roland Lammel <lammel@cpan.org>
4415
4416 Robert Sedlacek C<< <rs@474.at> >>
4417
4418 SpiceMan: Marcel Montes
4419
4420 sky: Arthur Bergman
4421
4422 szbalint: Balint Szilakszi <szbalint@cpan.org>
4423
4424 t0m: Tomas Doran <bobtfish@bobtfish.net>
4425
4426 Ulf Edvinsson
4427
4428 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4429
4430 Viljo Marrandi C<vilts@yahoo.com>
4431
4432 Will Hawes C<info@whawes.co.uk>
4433
4434 willert: Sebastian Willert <willert@cpan.org>
4435
4436 wreis: Wallace Reis <wreis@cpan.org>
4437
4438 Yuval Kogman, C<nothingmuch@woobling.org>
4439
4440 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4441
4442 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4443
4444 Upasana <me@upasana.me>
4445
4446 John Napiorkowski (jnap) <jjnapiork@cpan.org>
4447
4448 =head1 COPYRIGHT
4449
4450 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
4451
4452 =head1 LICENSE
4453
4454 This library is free software. You can redistribute it and/or modify it under
4455 the same terms as Perl itself.
4456
4457 =cut
4458
4459 no Moose;
4460
4461 __PACKAGE__->meta->make_immutable;
4462
4463 1;