lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Plack::Middleware::Conditional;
  39 use Plack::Middleware::ReverseProxy;
  40 use Plack::Middleware::IIS6ScriptNameFix;
  41 use Plack::Middleware::IIS7KeepAliveFix;
  42 use Plack::Middleware::LighttpdScriptNameFix;
  43 use Plack::Util;
  44 use JSON::MaybeXS qw(decode_json);
  45
  46 BEGIN { require 5.008003; }
  47
  48 has stack => (is => 'ro', default => sub { [] });
  49 has stash => (is => 'rw', default => sub { {} });
  50 has state => (is => 'rw', default => 0);
  51 has stats => (is => 'rw');
  52 has action => (is => 'rw');
  53 has counter => (is => 'rw', default => sub { {} });
  54 has request => (
  55     is => 'rw',
  56     default => sub {
  57         my $self = shift;
  58         $self->request_class->new($self->_build_request_constructor_args);
  59     },
  60     lazy => 1,
  61 );
  62 sub _build_request_constructor_args {
  63     my $self = shift;
  64     my %p = ( _log => $self->log );
  65     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  66     $p{data_handlers} = {$self->registered_data_handlers};
  67     \%p;
  68 }
  69
  70 has response => (
  71     is => 'rw',
  72     default => sub {
  73         my $self = shift;
  74         $self->response_class->new($self->_build_response_constructor_args);
  75     },
  76     lazy => 1,
  77 );
  78 sub _build_response_constructor_args {
  79     my $self = shift;
  80     { _log => $self->log };
  81 }
  82
  83 has namespace => (is => 'rw');
  84
  85 sub depth { scalar @{ shift->stack || [] }; }
  86 sub comp { shift->component(@_) }
  87
  88 sub req {
  89     my $self = shift; return $self->request(@_);
  90 }
  91 sub res {
  92     my $self = shift; return $self->response(@_);
  93 }
  94
  95 # For backwards compatibility
  96 sub finalize_output { shift->finalize_body(@_) };
  97
  98 # For statistics
  99 our $COUNT     = 1;
 100 our $START     = time;
 101 our $RECURSION = 1000;
 102 our $DETACH    = Catalyst::Exception::Detach->new;
 103 our $GO        = Catalyst::Exception::Go->new;
 104
 105 #I imagine that very few of these really need to be class variables. if any.
 106 #maybe we should just make them attributes with a default?
 107 __PACKAGE__->mk_classdata($_)
 108   for qw/components arguments dispatcher engine log dispatcher_class
 109   engine_loader context_class request_class response_class stats_class
 110   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 111   _data_handlers/;
 112
 113 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 114 __PACKAGE__->request_class('Catalyst::Request');
 115 __PACKAGE__->response_class('Catalyst::Response');
 116 __PACKAGE__->stats_class('Catalyst::Stats');
 117
 118 # Remember to update this in Catalyst::Runtime as well!
 119
 120 our $VERSION = '5.90049_001';
 121
 122 sub import {
 123     my ( $class, @arguments ) = @_;
 124
 125     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 126     # callers @ISA.
 127     return unless $class eq 'Catalyst';
 128
 129     my $caller = caller();
 130     return if $caller eq 'main';
 131
 132     my $meta = Moose::Meta::Class->initialize($caller);
 133     unless ( $caller->isa('Catalyst') ) {
 134         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 135         $meta->superclasses(@superclasses);
 136     }
 137     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 138     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 139
 140     unless( $meta->has_method('meta') ){
 141         if ($Moose::VERSION >= 1.15) {
 142             $meta->_add_meta_method('meta');
 143         }
 144         else {
 145             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 146         }
 147     }
 148
 149     $caller->arguments( [@arguments] );
 150     $caller->setup_home;
 151 }
 152
 153 sub _application { $_[0] }
 154
 155 =encoding UTF-8
 156
 157 =head1 NAME
 158
 159 Catalyst - The Elegant MVC Web Application Framework
 160
 161 =head1 SYNOPSIS
 162
 163 See the L<Catalyst::Manual> distribution for comprehensive
 164 documentation and tutorials.
 165
 166     # Install Catalyst::Devel for helpers and other development tools
 167     # use the helper to create a new application
 168     catalyst.pl MyApp
 169
 170     # add models, views, controllers
 171     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 172     script/myapp_create.pl view MyTemplate TT
 173     script/myapp_create.pl controller Search
 174
 175     # built in testserver -- use -r to restart automatically on changes
 176     # --help to see all available options
 177     script/myapp_server.pl
 178
 179     # command line testing interface
 180     script/myapp_test.pl /yada
 181
 182     ### in lib/MyApp.pm
 183     use Catalyst qw/-Debug/; # include plugins here as well
 184
 185     ### In lib/MyApp/Controller/Root.pm (autocreated)
 186     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 187         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 188         $c->stash->{template} = 'foo.tt'; # set the template
 189         # lookup something from db -- stash vars are passed to TT
 190         $c->stash->{data} =
 191           $c->model('Database::Foo')->search( { country => $args[0] } );
 192         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 193             $c->forward( 'bar' ); # process another action
 194             # do something else after forward returns
 195         }
 196     }
 197
 198     # The foo.tt TT template can use the stash data from the database
 199     [% WHILE (item = data.next) %]
 200         [% item.foo %]
 201     [% END %]
 202
 203     # called for /bar/of/soap, /bar/of/soap/10, etc.
 204     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 205
 206     # called after all actions are finished
 207     sub end : Action {
 208         my ( $self, $c ) = @_;
 209         if ( scalar @{ $c->error } ) { ... } # handle errors
 210         return if $c->res->body; # already have a response
 211         $c->forward( 'MyApp::View::TT' ); # render template
 212     }
 213
 214 See L<Catalyst::Manual::Intro> for additional information.
 215
 216 =head1 DESCRIPTION
 217
 218 Catalyst is a modern framework for making web applications without the
 219 pain usually associated with this process. This document is a reference
 220 to the main Catalyst application. If you are a new user, we suggest you
 221 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 222
 223 See L<Catalyst::Manual> for more documentation.
 224
 225 Catalyst plugins can be loaded by naming them as arguments to the "use
 226 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 227 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 228 C<My::Module>.
 229
 230     use Catalyst qw/My::Module/;
 231
 232 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 233 fully qualify the name by using a unary plus:
 234
 235     use Catalyst qw/
 236         My::Module
 237         +Fully::Qualified::Plugin::Name
 238     /;
 239
 240 Special flags like C<-Debug> can also be specified as
 241 arguments when Catalyst is loaded:
 242
 243     use Catalyst qw/-Debug My::Module/;
 244
 245 The position of plugins and flags in the chain is important, because
 246 they are loaded in the order in which they appear.
 247
 248 The following flags are supported:
 249
 250 =head2 -Debug
 251
 252 Enables debug output. You can also force this setting from the system
 253 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 254 settings override the application, with <MYAPP>_DEBUG having the highest
 255 priority.
 256
 257 This sets the log level to 'debug' and enables full debug output on the
 258 error screen. If you only want the latter, see L<< $c->debug >>.
 259
 260 =head2 -Home
 261
 262 Forces Catalyst to use a specific home directory, e.g.:
 263
 264     use Catalyst qw[-Home=/usr/mst];
 265
 266 This can also be done in the shell environment by setting either the
 267 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 268 is replaced with the uppercased name of your application, any "::" in
 269 the name will be replaced with underscores, e.g. MyApp::Web should use
 270 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 271
 272 If none of these are set, Catalyst will attempt to automatically detect the
 273 home directory. If you are working in a development environment, Catalyst
 274 will try and find the directory containing either Makefile.PL, Build.PL,
 275 dist.ini, or cpanfile. If the application has been installed into the system
 276 (i.e. you have done C<make install>), then Catalyst will use the path to your
 277 application module, without the .pm extension (e.g., /foo/MyApp if your
 278 application was installed at /foo/MyApp.pm)
 279
 280 =head2 -Log
 281
 282     use Catalyst '-Log=warn,fatal,error';
 283
 284 Specifies a comma-delimited list of log levels.
 285
 286 =head2 -Stats
 287
 288 Enables statistics collection and reporting.
 289
 290    use Catalyst qw/-Stats=1/;
 291
 292 You can also force this setting from the system environment with CATALYST_STATS
 293 or <MYAPP>_STATS. The environment settings override the application, with
 294 <MYAPP>_STATS having the highest priority.
 295
 296 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 297
 298 =head1 METHODS
 299
 300 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 301
 302 =head2 $c->action
 303
 304 Returns a L<Catalyst::Action> object for the current action, which
 305 stringifies to the action name. See L<Catalyst::Action>.
 306
 307 =head2 $c->namespace
 308
 309 Returns the namespace of the current action, i.e., the URI prefix
 310 corresponding to the controller of the current action. For example:
 311
 312     # in Controller::Foo::Bar
 313     $c->namespace; # returns 'foo/bar';
 314
 315 =head2 $c->request
 316
 317 =head2 $c->req
 318
 319 Returns the current L<Catalyst::Request> object, giving access to
 320 information about the current client request (including parameters,
 321 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 322
 323 =head2 REQUEST FLOW HANDLING
 324
 325 =head2 $c->forward( $action [, \@arguments ] )
 326
 327 =head2 $c->forward( $class, $method, [, \@arguments ] )
 328
 329 Forwards processing to another action, by its private name. If you give a
 330 class name but no method, C<process()> is called. You may also optionally
 331 pass arguments in an arrayref. The action will receive the arguments in
 332 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 333 C<< $c->req->args >> will be restored to the previous values.
 334
 335 Any data C<return>ed from the action forwarded to, will be returned by the
 336 call to forward.
 337
 338     my $foodata = $c->forward('/foo');
 339     $c->forward('index');
 340     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 341     $c->forward('View::TT');
 342
 343 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 344 an C<< eval { } >> around the call (actually
 345 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 346 exceptions thrown by the called action non-fatal and pushing them onto
 347 $c->error instead. If you want C<die> to propagate you need to do something
 348 like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@arguments ] )
 395
 396 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 397
 398 =head2 $c->visit( $class, $method, [, \@arguments ] )
 399
 400 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 401
 402 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 403 but does a full dispatch, instead of just calling the new C<$action> /
 404 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 405 you go to are called, just like a new request.
 406
 407 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 408 This means, for example, that C<< $c->action >> methods such as
 409 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 410 L<reverse|Catalyst::Action/reverse> return information for the visited action
 411 when they are invoked within the visited action.  This is different from the
 412 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 413 continues to use the $c->action object from the caller action even when
 414 invoked from the called action.
 415
 416 C<< $c->stash >> is kept unchanged.
 417
 418 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 419 allows you to "wrap" another action, just as it would have been called by
 420 dispatching from a URL, while the analogous
 421 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 422 transfer control to another action as if it had been reached directly from a URL.
 423
 424 =cut
 425
 426 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 427
 428 =head2 $c->go( $action [, \@arguments ] )
 429
 430 =head2 $c->go( $action [, \@captures, \@arguments ] )
 431
 432 =head2 $c->go( $class, $method, [, \@arguments ] )
 433
 434 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 435
 436 The relationship between C<go> and
 437 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 438 the relationship between
 439 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 440 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 441 C<< $c->go >> will perform a full dispatch on the specified action or method,
 442 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 443 C<go> escapes the processing of the current request chain on completion, and
 444 does not return to its caller.
 445
 446 @arguments are arguments to the final destination of $action. @captures are
 447 arguments to the intermediate steps, if any, on the way to the final sub of
 448 $action.
 449
 450 =cut
 451
 452 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 453
 454 =head2 $c->response
 455
 456 =head2 $c->res
 457
 458 Returns the current L<Catalyst::Response> object, see there for details.
 459
 460 =head2 $c->stash
 461
 462 Returns a hashref to the stash, which may be used to store data and pass
 463 it between components during a request. You can also set hash keys by
 464 passing arguments. The stash is automatically sent to the view. The
 465 stash is cleared at the end of a request; it cannot be used for
 466 persistent storage (for this you must use a session; see
 467 L<Catalyst::Plugin::Session> for a complete system integrated with
 468 Catalyst).
 469
 470     $c->stash->{foo} = $bar;
 471     $c->stash( { moose => 'majestic', qux => 0 } );
 472     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 473
 474     # stash is automatically passed to the view for use in a template
 475     $c->forward( 'MyApp::View::TT' );
 476
 477 =cut
 478
 479 around stash => sub {
 480     my $orig = shift;
 481     my $c = shift;
 482     my $stash = $orig->($c);
 483     if (@_) {
 484         my $new_stash = @_ > 1 ? {@_} : $_[0];
 485         croak('stash takes a hash or hashref') unless ref $new_stash;
 486         foreach my $key ( keys %$new_stash ) {
 487           $stash->{$key} = $new_stash->{$key};
 488         }
 489     }
 490
 491     return $stash;
 492 };
 493
 494
 495 =head2 $c->error
 496
 497 =head2 $c->error($error, ...)
 498
 499 =head2 $c->error($arrayref)
 500
 501 Returns an arrayref containing error messages.  If Catalyst encounters an
 502 error while processing a request, it stores the error in $c->error.  This
 503 method should only be used to store fatal error messages.
 504
 505     my @error = @{ $c->error };
 506
 507 Add a new error.
 508
 509     $c->error('Something bad happened');
 510
 511 =cut
 512
 513 sub error {
 514     my $c = shift;
 515     if ( $_[0] ) {
 516         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 517         croak @$error unless ref $c;
 518         push @{ $c->{error} }, @$error;
 519     }
 520     elsif ( defined $_[0] ) { $c->{error} = undef }
 521     return $c->{error} || [];
 522 }
 523
 524
 525 =head2 $c->state
 526
 527 Contains the return value of the last executed action.
 528 Note that << $c->state >> operates in a scalar context which means that all
 529 values it returns are scalar.
 530
 531 =head2 $c->clear_errors
 532
 533 Clear errors.  You probably don't want to clear the errors unless you are
 534 implementing a custom error screen.
 535
 536 This is equivalent to running
 537
 538     $c->error(0);
 539
 540 =cut
 541
 542 sub clear_errors {
 543     my $c = shift;
 544     $c->error(0);
 545 }
 546
 547 sub _comp_search_prefixes {
 548     my $c = shift;
 549     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 550 }
 551
 552 # search components given a name and some prefixes
 553 sub _comp_names_search_prefixes {
 554     my ( $c, $name, @prefixes ) = @_;
 555     my $appclass = ref $c || $c;
 556     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 557     $filter = qr/$filter/; # Compile regex now rather than once per loop
 558
 559     # map the original component name to the sub part that we will search against
 560     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 561         grep { /$filter/ } keys %{ $c->components };
 562
 563     # undef for a name will return all
 564     return keys %eligible if !defined $name;
 565
 566     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 567     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 568
 569     return @result if @result;
 570
 571     # if we were given a regexp to search against, we're done.
 572     return if $name->$_isa('Regexp');
 573
 574     # skip regexp fallback if configured
 575     return
 576         if $appclass->config->{disable_component_resolution_regex_fallback};
 577
 578     # regexp fallback
 579     $query  = qr/$name/i;
 580     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 581
 582     # no results? try against full names
 583     if( !@result ) {
 584         @result = grep { m{$query} } keys %eligible;
 585     }
 586
 587     # don't warn if we didn't find any results, it just might not exist
 588     if( @result ) {
 589         # Disgusting hack to work out correct method name
 590         my $warn_for = lc $prefixes[0];
 591         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 592            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 593            "component resolution is unreliable and unsafe.";
 594         my $short = $result[0];
 595         # remove the component namespace prefix
 596         $short =~ s/.*?(Model|Controller|View):://;
 597         my $shortmess = Carp::shortmess('');
 598         if ($shortmess =~ m#Catalyst/Plugin#) {
 599            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 600               "plugin's config";
 601         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 602            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 603               "component's config";
 604         } else {
 605            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 606               "but if you really wanted to search, pass in a regexp as the argument " .
 607               "like so: \$c->${warn_for}(qr/${name}/)";
 608         }
 609         $c->log->warn( "${msg}$shortmess" );
 610     }
 611
 612     return @result;
 613 }
 614
 615 # Find possible names for a prefix
 616 sub _comp_names {
 617     my ( $c, @prefixes ) = @_;
 618     my $appclass = ref $c || $c;
 619
 620     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 621
 622     my @names = map { s{$filter}{}; $_; }
 623         $c->_comp_names_search_prefixes( undef, @prefixes );
 624
 625     return @names;
 626 }
 627
 628 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 629 sub _filter_component {
 630     my ( $c, $comp, @args ) = @_;
 631
 632     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 633         return $comp->ACCEPT_CONTEXT( $c, @args );
 634     }
 635
 636     return $comp;
 637 }
 638
 639 =head2 COMPONENT ACCESSORS
 640
 641 =head2 $c->controller($name)
 642
 643 Gets a L<Catalyst::Controller> instance by name.
 644
 645     $c->controller('Foo')->do_stuff;
 646
 647 If the name is omitted, will return the controller for the dispatched
 648 action.
 649
 650 If you want to search for controllers, pass in a regexp as the argument.
 651
 652     # find all controllers that start with Foo
 653     my @foo_controllers = $c->controller(qr{^Foo});
 654
 655
 656 =cut
 657
 658 sub controller {
 659     my ( $c, $name, @args ) = @_;
 660
 661     my $appclass = ref($c) || $c;
 662     if( $name ) {
 663         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 664             my $comps = $c->components;
 665             my $check = $appclass."::Controller::".$name;
 666             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 667         }
 668         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 669         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 670         return $c->_filter_component( $result[ 0 ], @args );
 671     }
 672
 673     return $c->component( $c->action->class );
 674 }
 675
 676 =head2 $c->model($name)
 677
 678 Gets a L<Catalyst::Model> instance by name.
 679
 680     $c->model('Foo')->do_stuff;
 681
 682 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 683
 684 If the name is omitted, it will look for
 685  - a model object in $c->stash->{current_model_instance}, then
 686  - a model name in $c->stash->{current_model}, then
 687  - a config setting 'default_model', or
 688  - check if there is only one model, and return it if that's the case.
 689
 690 If you want to search for models, pass in a regexp as the argument.
 691
 692     # find all models that start with Foo
 693     my @foo_models = $c->model(qr{^Foo});
 694
 695 =cut
 696
 697 sub model {
 698     my ( $c, $name, @args ) = @_;
 699     my $appclass = ref($c) || $c;
 700     if( $name ) {
 701         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 702             my $comps = $c->components;
 703             my $check = $appclass."::Model::".$name;
 704             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 705         }
 706         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 707         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 708         return $c->_filter_component( $result[ 0 ], @args );
 709     }
 710
 711     if (ref $c) {
 712         return $c->stash->{current_model_instance}
 713           if $c->stash->{current_model_instance};
 714         return $c->model( $c->stash->{current_model} )
 715           if $c->stash->{current_model};
 716     }
 717     return $c->model( $appclass->config->{default_model} )
 718       if $appclass->config->{default_model};
 719
 720     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 721
 722     if( $rest ) {
 723         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 724         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 725         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 726         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 727         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 728     }
 729
 730     return $c->_filter_component( $comp );
 731 }
 732
 733
 734 =head2 $c->view($name)
 735
 736 Gets a L<Catalyst::View> instance by name.
 737
 738     $c->view('Foo')->do_stuff;
 739
 740 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 741
 742 If the name is omitted, it will look for
 743  - a view object in $c->stash->{current_view_instance}, then
 744  - a view name in $c->stash->{current_view}, then
 745  - a config setting 'default_view', or
 746  - check if there is only one view, and return it if that's the case.
 747
 748 If you want to search for views, pass in a regexp as the argument.
 749
 750     # find all views that start with Foo
 751     my @foo_views = $c->view(qr{^Foo});
 752
 753 =cut
 754
 755 sub view {
 756     my ( $c, $name, @args ) = @_;
 757
 758     my $appclass = ref($c) || $c;
 759     if( $name ) {
 760         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 761             my $comps = $c->components;
 762             my $check = $appclass."::View::".$name;
 763             if( exists $comps->{$check} ) {
 764                 return $c->_filter_component( $comps->{$check}, @args );
 765             }
 766             else {
 767                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 768             }
 769         }
 770         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 771         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 772         return $c->_filter_component( $result[ 0 ], @args );
 773     }
 774
 775     if (ref $c) {
 776         return $c->stash->{current_view_instance}
 777           if $c->stash->{current_view_instance};
 778         return $c->view( $c->stash->{current_view} )
 779           if $c->stash->{current_view};
 780     }
 781     return $c->view( $appclass->config->{default_view} )
 782       if $appclass->config->{default_view};
 783
 784     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 785
 786     if( $rest ) {
 787         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 788         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 789         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 790         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 791         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 792     }
 793
 794     return $c->_filter_component( $comp );
 795 }
 796
 797 =head2 $c->controllers
 798
 799 Returns the available names which can be passed to $c->controller
 800
 801 =cut
 802
 803 sub controllers {
 804     my ( $c ) = @_;
 805     return $c->_comp_names(qw/Controller C/);
 806 }
 807
 808 =head2 $c->models
 809
 810 Returns the available names which can be passed to $c->model
 811
 812 =cut
 813
 814 sub models {
 815     my ( $c ) = @_;
 816     return $c->_comp_names(qw/Model M/);
 817 }
 818
 819
 820 =head2 $c->views
 821
 822 Returns the available names which can be passed to $c->view
 823
 824 =cut
 825
 826 sub views {
 827     my ( $c ) = @_;
 828     return $c->_comp_names(qw/View V/);
 829 }
 830
 831 =head2 $c->comp($name)
 832
 833 =head2 $c->component($name)
 834
 835 Gets a component object by name. This method is not recommended,
 836 unless you want to get a specific component by full
 837 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 838 should be used instead.
 839
 840 If C<$name> is a regexp, a list of components matched against the full
 841 component name will be returned.
 842
 843 If Catalyst can't find a component by name, it will fallback to regex
 844 matching by default. To disable this behaviour set
 845 disable_component_resolution_regex_fallback to a true value.
 846
 847     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 848
 849 =cut
 850
 851 sub component {
 852     my ( $c, $name, @args ) = @_;
 853
 854     if( $name ) {
 855         my $comps = $c->components;
 856
 857         if( !ref $name ) {
 858             # is it the exact name?
 859             return $c->_filter_component( $comps->{ $name }, @args )
 860                        if exists $comps->{ $name };
 861
 862             # perhaps we just omitted "MyApp"?
 863             my $composed = ( ref $c || $c ) . "::${name}";
 864             return $c->_filter_component( $comps->{ $composed }, @args )
 865                        if exists $comps->{ $composed };
 866
 867             # search all of the models, views and controllers
 868             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 869             return $c->_filter_component( $comp, @args ) if $comp;
 870         }
 871
 872         return
 873             if $c->config->{disable_component_resolution_regex_fallback};
 874
 875         # This is here so $c->comp( '::M::' ) works
 876         my $query = ref $name ? $name : qr{$name}i;
 877
 878         my @result = grep { m{$query} } keys %{ $c->components };
 879         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 880
 881         if( $result[ 0 ] ) {
 882             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 883             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 884             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 885             return $c->_filter_component( $result[ 0 ], @args );
 886         }
 887
 888         # I would expect to return an empty list here, but that breaks back-compat
 889     }
 890
 891     # fallback
 892     return sort keys %{ $c->components };
 893 }
 894
 895 =head2 CLASS DATA AND HELPER CLASSES
 896
 897 =head2 $c->config
 898
 899 Returns or takes a hashref containing the application's configuration.
 900
 901     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 902
 903 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 904 like C<myapp.conf> in your applications home directory. See
 905 L<Catalyst::Plugin::ConfigLoader>.
 906
 907 =head3 Cascading configuration
 908
 909 The config method is present on all Catalyst components, and configuration
 910 will be merged when an application is started. Configuration loaded with
 911 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 912 followed by configuration in your top level C<MyApp> class. These two
 913 configurations are merged, and then configuration data whose hash key matches a
 914 component name is merged with configuration for that component.
 915
 916 The configuration for a component is then passed to the C<new> method when a
 917 component is constructed.
 918
 919 For example:
 920
 921     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 922     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 923
 924 will mean that C<MyApp::Model::Foo> receives the following data when
 925 constructed:
 926
 927     MyApp::Model::Foo->new({
 928         bar => 'baz',
 929         quux => 'frob',
 930         overrides => 'me',
 931     });
 932
 933 It's common practice to use a Moose attribute
 934 on the receiving component to access the config value.
 935
 936     package MyApp::Model::Foo;
 937
 938     use Moose;
 939
 940     # this attr will receive 'baz' at construction time
 941     has 'bar' => (
 942         is  => 'rw',
 943         isa => 'Str',
 944     );
 945
 946 You can then get the value 'baz' by calling $c->model('Foo')->bar
 947 (or $self->bar inside code in the model).
 948
 949 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 950 as a way of reading config within your code, as this B<will not> give you the
 951 correctly merged config back. You B<MUST> take the config values supplied to
 952 the constructor and use those instead.
 953
 954 =cut
 955
 956 around config => sub {
 957     my $orig = shift;
 958     my $c = shift;
 959
 960     croak('Setting config after setup has been run is not allowed.')
 961         if ( @_ and $c->setup_finished );
 962
 963     $c->$orig(@_);
 964 };
 965
 966 =head2 $c->log
 967
 968 Returns the logging object instance. Unless it is already set, Catalyst
 969 sets this up with a L<Catalyst::Log> object. To use your own log class,
 970 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 971 C<< __PACKAGE__->setup >>.
 972
 973  __PACKAGE__->log( MyLogger->new );
 974  __PACKAGE__->setup;
 975
 976 And later:
 977
 978     $c->log->info( 'Now logging with my own logger!' );
 979
 980 Your log class should implement the methods described in
 981 L<Catalyst::Log>.
 982
 983
 984 =head2 $c->debug
 985
 986 Returns 1 if debug mode is enabled, 0 otherwise.
 987
 988 You can enable debug mode in several ways:
 989
 990 =over
 991
 992 =item By calling myapp_server.pl with the -d flag
 993
 994 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 995
 996 =item The -Debug option in your MyApp.pm
 997
 998 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 999
1000 =back
1001
1002 The first three also set the log level to 'debug'.
1003
1004 Calling C<< $c->debug(1) >> has no effect.
1005
1006 =cut
1007
1008 sub debug { 0 }
1009
1010 =head2 $c->dispatcher
1011
1012 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1013
1014 =head2 $c->engine
1015
1016 Returns the engine instance. See L<Catalyst::Engine>.
1017
1018
1019 =head2 UTILITY METHODS
1020
1021 =head2 $c->path_to(@path)
1022
1023 Merges C<@path> with C<< $c->config->{home} >> and returns a
1024 L<Path::Class::Dir> object. Note you can usually use this object as
1025 a filename, but sometimes you will have to explicitly stringify it
1026 yourself by calling the C<< ->stringify >> method.
1027
1028 For example:
1029
1030     $c->path_to( 'db', 'sqlite.db' );
1031
1032 =cut
1033
1034 sub path_to {
1035     my ( $c, @path ) = @_;
1036     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1037     if ( -d $path ) { return $path }
1038     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1039 }
1040
1041 sub plugin {
1042     my ( $class, $name, $plugin, @args ) = @_;
1043
1044     # See block comment in t/unit_core_plugin.t
1045     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1046
1047     $class->_register_plugin( $plugin, 1 );
1048
1049     eval { $plugin->import };
1050     $class->mk_classdata($name);
1051     my $obj;
1052     eval { $obj = $plugin->new(@args) };
1053
1054     if ($@) {
1055         Catalyst::Exception->throw( message =>
1056               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1057     }
1058
1059     $class->$name($obj);
1060     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1061       if $class->debug;
1062 }
1063
1064 =head2 MyApp->setup
1065
1066 Initializes the dispatcher and engine, loads any plugins, and loads the
1067 model, view, and controller components. You may also specify an array
1068 of plugins to load here, if you choose to not load them in the C<use
1069 Catalyst> line.
1070
1071     MyApp->setup;
1072     MyApp->setup( qw/-Debug/ );
1073
1074 B<Note:> You B<should not> wrap this method with method modifiers
1075 or bad things will happen - wrap the C<setup_finalize> method instead.
1076
1077 =cut
1078
1079 sub setup {
1080     my ( $class, @arguments ) = @_;
1081     croak('Running setup more than once')
1082         if ( $class->setup_finished );
1083
1084     unless ( $class->isa('Catalyst') ) {
1085
1086         Catalyst::Exception->throw(
1087             message => qq/'$class' does not inherit from Catalyst/ );
1088     }
1089
1090     if ( $class->arguments ) {
1091         @arguments = ( @arguments, @{ $class->arguments } );
1092     }
1093
1094     # Process options
1095     my $flags = {};
1096
1097     foreach (@arguments) {
1098
1099         if (/^-Debug$/) {
1100             $flags->{log} =
1101               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1102         }
1103         elsif (/^-(\w+)=?(.*)$/) {
1104             $flags->{ lc $1 } = $2;
1105         }
1106         else {
1107             push @{ $flags->{plugins} }, $_;
1108         }
1109     }
1110
1111     $class->setup_home( delete $flags->{home} );
1112
1113     $class->setup_log( delete $flags->{log} );
1114     $class->setup_plugins( delete $flags->{plugins} );
1115     $class->setup_middleware();
1116     $class->setup_data_handlers();
1117     $class->setup_dispatcher( delete $flags->{dispatcher} );
1118     if (my $engine = delete $flags->{engine}) {
1119         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1120     }
1121     $class->setup_engine();
1122     $class->setup_stats( delete $flags->{stats} );
1123
1124     for my $flag ( sort keys %{$flags} ) {
1125
1126         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1127             &$code( $class, delete $flags->{$flag} );
1128         }
1129         else {
1130             $class->log->warn(qq/Unknown flag "$flag"/);
1131         }
1132     }
1133
1134     eval { require Catalyst::Devel; };
1135     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1136         $class->log->warn(<<"EOF");
1137 You are running an old script!
1138
1139   Please update by running (this will overwrite existing files):
1140     catalyst.pl -force -scripts $class
1141
1142   or (this will not overwrite existing files):
1143     catalyst.pl -scripts $class
1144
1145 EOF
1146     }
1147
1148     if ( $class->debug ) {
1149         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1150
1151         if (@plugins) {
1152             my $column_width = Catalyst::Utils::term_width() - 6;
1153             my $t = Text::SimpleTable->new($column_width);
1154             $t->row($_) for @plugins;
1155             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1156         }
1157
1158         my @middleware = map {
1159           ref $_ eq 'CODE' ?
1160             "Inline Coderef" :
1161               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION : '')
1162                 || '')  } $class->registered_middlewares;
1163
1164         if (@middleware) {
1165             my $column_width = Catalyst::Utils::term_width() - 6;
1166             my $t = Text::SimpleTable->new($column_width);
1167             $t->row($_) for @middleware;
1168             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1169         }
1170
1171         my %dh = $class->registered_data_handlers || ();
1172         my @data_handlers = keys %dh;
1173
1174         if (@data_handlers) {
1175             my $column_width = Catalyst::Utils::term_width() - 6;
1176             my $t = Text::SimpleTable->new($column_width);
1177             $t->row($_) for @data_handlers;
1178             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1179         }
1180
1181         my $dispatcher = $class->dispatcher;
1182         my $engine     = $class->engine;
1183         my $home       = $class->config->{home};
1184
1185         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1186         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1187
1188         $home
1189           ? ( -d $home )
1190           ? $class->log->debug(qq/Found home "$home"/)
1191           : $class->log->debug(qq/Home "$home" doesn't exist/)
1192           : $class->log->debug(q/Couldn't find home/);
1193     }
1194
1195     # Call plugins setup, this is stupid and evil.
1196     # Also screws C3 badly on 5.10, hack to avoid.
1197     {
1198         no warnings qw/redefine/;
1199         local *setup = sub { };
1200         $class->setup unless $Catalyst::__AM_RESTARTING;
1201     }
1202
1203     # Initialize our data structure
1204     $class->components( {} );
1205
1206     $class->setup_components;
1207
1208     if ( $class->debug ) {
1209         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1210         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1211         for my $comp ( sort keys %{ $class->components } ) {
1212             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1213             $t->row( $comp, $type );
1214         }
1215         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1216           if ( keys %{ $class->components } );
1217     }
1218
1219     # Add our self to components, since we are also a component
1220     if( $class->isa('Catalyst::Controller') ){
1221       $class->components->{$class} = $class;
1222     }
1223
1224     $class->setup_actions;
1225
1226     if ( $class->debug ) {
1227         my $name = $class->config->{name} || 'Application';
1228         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1229     }
1230
1231     if ($class->config->{case_sensitive}) {
1232         $class->log->warn($class . "->config->{case_sensitive} is set.");
1233         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1234     }
1235
1236     $class->setup_finalize;
1237     # Should be the last thing we do so that user things hooking
1238     # setup_finalize can log..
1239     $class->log->_flush() if $class->log->can('_flush');
1240     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1241 }
1242
1243 =head2 $app->setup_finalize
1244
1245 A hook to attach modifiers to. This method does not do anything except set the
1246 C<setup_finished> accessor.
1247
1248 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1249
1250 Example:
1251
1252     after setup_finalize => sub {
1253         my $app = shift;
1254
1255         ## do stuff here..
1256     };
1257
1258 =cut
1259
1260 sub setup_finalize {
1261     my ($class) = @_;
1262     $class->setup_finished(1);
1263 }
1264
1265 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1266
1267 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1268
1269 Constructs an absolute L<URI> object based on the application root, the
1270 provided path, and the additional arguments and query parameters provided.
1271 When used as a string, provides a textual URI.  If you need more flexibility
1272 than this (i.e. the option to provide relative URIs etc.) see
1273 L<Catalyst::Plugin::SmartURI>.
1274
1275 If no arguments are provided, the URI for the current action is returned.
1276 To return the current action and also provide @args, use
1277 C<< $c->uri_for( $c->action, @args ) >>.
1278
1279 If the first argument is a string, it is taken as a public URI path relative
1280 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1281 relative to the application root (if it does). It is then merged with
1282 C<< $c->request->base >>; any C<@args> are appended as additional path
1283 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1284
1285 If the first argument is a L<Catalyst::Action> it represents an action which
1286 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1287 optional C<\@captures> argument (an arrayref) allows passing the captured
1288 variables that are needed to fill in the paths of Chained and Regex actions;
1289 once the path is resolved, C<uri_for> continues as though a path was
1290 provided, appending any arguments or parameters and creating an absolute
1291 URI.
1292
1293 The captures for the current request can be found in
1294 C<< $c->request->captures >>, and actions can be resolved using
1295 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1296 path, use C<< $c->uri_for_action >> instead.
1297
1298   # Equivalent to $c->req->uri
1299   $c->uri_for($c->action, $c->req->captures,
1300       @{ $c->req->args }, $c->req->params);
1301
1302   # For the Foo action in the Bar controller
1303   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1304
1305   # Path to a static resource
1306   $c->uri_for('/static/images/logo.png');
1307
1308 =cut
1309
1310 sub uri_for {
1311     my ( $c, $path, @args ) = @_;
1312
1313     if ( $path->$_isa('Catalyst::Controller') ) {
1314         $path = $path->path_prefix;
1315         $path =~ s{/+\z}{};
1316         $path .= '/';
1317     }
1318
1319     undef($path) if (defined $path && $path eq '');
1320
1321     my $params =
1322       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1323
1324     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1325     foreach my $arg (@args) {
1326         utf8::encode($arg) if utf8::is_utf8($arg);
1327         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1328     }
1329
1330     if ( $path->$_isa('Catalyst::Action') ) { # action object
1331         s|/|%2F|g for @args;
1332         my $captures = [ map { s|/|%2F|g; $_; }
1333                         ( scalar @args && ref $args[0] eq 'ARRAY'
1334                          ? @{ shift(@args) }
1335                          : ()) ];
1336
1337         foreach my $capture (@$captures) {
1338             utf8::encode($capture) if utf8::is_utf8($capture);
1339             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1340         }
1341
1342         my $action = $path;
1343         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1344         if( !@args && $action->number_of_args ) {
1345             my $expanded_action = $c->dispatcher->expand_action( $action );
1346
1347             my $num_captures = $expanded_action->number_of_captures;
1348             unshift @args, splice @$captures, $num_captures;
1349         }
1350
1351        $path = $c->dispatcher->uri_for_action($action, $captures);
1352         if (not defined $path) {
1353             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1354                 if $c->debug;
1355             return undef;
1356         }
1357         $path = '/' if $path eq '';
1358     }
1359
1360     unshift(@args, $path);
1361
1362     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1363         my $namespace = $c->namespace;
1364         if (defined $path) { # cheesy hack to handle path '../foo'
1365            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1366         }
1367         unshift(@args, $namespace || '');
1368     }
1369
1370     # join args with '/', or a blank string
1371     my $args = join('/', grep { defined($_) } @args);
1372     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1373     $args =~ s!^/+!!;
1374
1375     my ($base, $class) = ('/', 'URI::_generic');
1376     if(blessed($c)) {
1377       $base = $c->req->base;
1378       $class = ref($base);
1379       $base =~ s{(?<!/)$}{/};
1380     }
1381
1382     my $query = '';
1383
1384     if (my @keys = keys %$params) {
1385       # somewhat lifted from URI::_query's query_form
1386       $query = '?'.join('&', map {
1387           my $val = $params->{$_};
1388           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1389           s/ /+/g;
1390           my $key = $_;
1391           $val = '' unless defined $val;
1392           (map {
1393               my $param = "$_";
1394               utf8::encode( $param ) if utf8::is_utf8($param);
1395               # using the URI::Escape pattern here so utf8 chars survive
1396               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1397               $param =~ s/ /+/g;
1398               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1399       } @keys);
1400     }
1401
1402     my $res = bless(\"${base}${args}${query}", $class);
1403     $res;
1404 }
1405
1406 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1407
1408 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1409
1410 =over
1411
1412 =item $path
1413
1414 A private path to the Catalyst action you want to create a URI for.
1415
1416 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1417 >> and passing the resulting C<$action> and the remaining arguments to C<<
1418 $c->uri_for >>.
1419
1420 You can also pass in a Catalyst::Action object, in which case it is passed to
1421 C<< $c->uri_for >>.
1422
1423 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1424
1425 For example, if the action looks like:
1426
1427  package MyApp::Controller::Users;
1428
1429  sub lst : Path('the-list') {}
1430
1431 You can use:
1432
1433  $c->uri_for_action('/users/lst')
1434
1435 and it will create the URI /users/the-list.
1436
1437 =item \@captures_and_args?
1438
1439 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1440 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1441 to interpolate all the parameters in the URI.
1442
1443 =item @args?
1444
1445 Optional list of extra arguments - can be supplied in the
1446 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1447 code.
1448
1449 Your action can have zero, a fixed or a variable number of args (e.g.
1450 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1451
1452 =item \%query_values?
1453
1454 Optional array reference of query parameters to append. E.g.
1455
1456   { foo => 'bar' }
1457
1458 will generate
1459
1460   /rest/of/your/uri?foo=bar
1461
1462 =back
1463
1464 =cut
1465
1466 sub uri_for_action {
1467     my ( $c, $path, @args ) = @_;
1468     my $action = blessed($path)
1469       ? $path
1470       : $c->dispatcher->get_action_by_path($path);
1471     unless (defined $action) {
1472       croak "Can't find action for path '$path'";
1473     }
1474     return $c->uri_for( $action, @args );
1475 }
1476
1477 =head2 $c->welcome_message
1478
1479 Returns the Catalyst welcome HTML page.
1480
1481 =cut
1482
1483 sub welcome_message {
1484     my $c      = shift;
1485     my $name   = $c->config->{name};
1486     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1487     my $prefix = Catalyst::Utils::appprefix( ref $c );
1488     $c->response->content_type('text/html; charset=utf-8');
1489     return <<"EOF";
1490 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1491     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1492 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1493     <head>
1494     <meta http-equiv="Content-Language" content="en" />
1495     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1496         <title>$name on Catalyst $VERSION</title>
1497         <style type="text/css">
1498             body {
1499                 color: #000;
1500                 background-color: #eee;
1501             }
1502             div#content {
1503                 width: 640px;
1504                 margin-left: auto;
1505                 margin-right: auto;
1506                 margin-top: 10px;
1507                 margin-bottom: 10px;
1508                 text-align: left;
1509                 background-color: #ccc;
1510                 border: 1px solid #aaa;
1511             }
1512             p, h1, h2 {
1513                 margin-left: 20px;
1514                 margin-right: 20px;
1515                 font-family: verdana, tahoma, sans-serif;
1516             }
1517             a {
1518                 font-family: verdana, tahoma, sans-serif;
1519             }
1520             :link, :visited {
1521                     text-decoration: none;
1522                     color: #b00;
1523                     border-bottom: 1px dotted #bbb;
1524             }
1525             :link:hover, :visited:hover {
1526                     color: #555;
1527             }
1528             div#topbar {
1529                 margin: 0px;
1530             }
1531             pre {
1532                 margin: 10px;
1533                 padding: 8px;
1534             }
1535             div#answers {
1536                 padding: 8px;
1537                 margin: 10px;
1538                 background-color: #fff;
1539                 border: 1px solid #aaa;
1540             }
1541             h1 {
1542                 font-size: 0.9em;
1543                 font-weight: normal;
1544                 text-align: center;
1545             }
1546             h2 {
1547                 font-size: 1.0em;
1548             }
1549             p {
1550                 font-size: 0.9em;
1551             }
1552             p img {
1553                 float: right;
1554                 margin-left: 10px;
1555             }
1556             span#appname {
1557                 font-weight: bold;
1558                 font-size: 1.6em;
1559             }
1560         </style>
1561     </head>
1562     <body>
1563         <div id="content">
1564             <div id="topbar">
1565                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1566                     $VERSION</h1>
1567              </div>
1568              <div id="answers">
1569                  <p>
1570                  <img src="$logo" alt="Catalyst Logo" />
1571                  </p>
1572                  <p>Welcome to the  world of Catalyst.
1573                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1574                     framework will make web development something you had
1575                     never expected it to be: Fun, rewarding, and quick.</p>
1576                  <h2>What to do now?</h2>
1577                  <p>That really depends  on what <b>you</b> want to do.
1578                     We do, however, provide you with a few starting points.</p>
1579                  <p>If you want to jump right into web development with Catalyst
1580                     you might want to start with a tutorial.</p>
1581 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1582 </pre>
1583 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1584 <pre>
1585 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1586 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1587 </code></pre>
1588                  <h2>What to do next?</h2>
1589                  <p>Next it's time to write an actual application. Use the
1590                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1591                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1592                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1593                     they can save you a lot of work.</p>
1594                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1595                     <p>Also, be sure to check out the vast and growing
1596                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1597                     you are likely to find what you need there.
1598                     </p>
1599
1600                  <h2>Need help?</h2>
1601                  <p>Catalyst has a very active community. Here are the main places to
1602                     get in touch with us.</p>
1603                  <ul>
1604                      <li>
1605                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1606                      </li>
1607                      <li>
1608                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1609                      </li>
1610                      <li>
1611                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1612                      </li>
1613                  </ul>
1614                  <h2>In conclusion</h2>
1615                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1616                     as we enjoyed making it. Please contact us if you have ideas
1617                     for improvement or other feedback.</p>
1618              </div>
1619          </div>
1620     </body>
1621 </html>
1622 EOF
1623 }
1624
1625 =head2 run_options
1626
1627 Contains a hash of options passed from the application script, including
1628 the original ARGV the script received, the processed values from that
1629 ARGV and any extra arguments to the script which were not processed.
1630
1631 This can be used to add custom options to your application's scripts
1632 and setup your application differently depending on the values of these
1633 options.
1634
1635 =head1 INTERNAL METHODS
1636
1637 These methods are not meant to be used by end users.
1638
1639 =head2 $c->components
1640
1641 Returns a hash of components.
1642
1643 =head2 $c->context_class
1644
1645 Returns or sets the context class.
1646
1647 =head2 $c->counter
1648
1649 Returns a hashref containing coderefs and execution counts (needed for
1650 deep recursion detection).
1651
1652 =head2 $c->depth
1653
1654 Returns the number of actions on the current internal execution stack.
1655
1656 =head2 $c->dispatch
1657
1658 Dispatches a request to actions.
1659
1660 =cut
1661
1662 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1663
1664 =head2 $c->dispatcher_class
1665
1666 Returns or sets the dispatcher class.
1667
1668 =head2 $c->dump_these
1669
1670 Returns a list of 2-element array references (name, structure) pairs
1671 that will be dumped on the error page in debug mode.
1672
1673 =cut
1674
1675 sub dump_these {
1676     my $c = shift;
1677     [ Request => $c->req ],
1678     [ Response => $c->res ],
1679     [ Stash => $c->stash ],
1680     [ Config => $c->config ];
1681 }
1682
1683 =head2 $c->engine_class
1684
1685 Returns or sets the engine class.
1686
1687 =head2 $c->execute( $class, $coderef )
1688
1689 Execute a coderef in given class and catch exceptions. Errors are available
1690 via $c->error.
1691
1692 =cut
1693
1694 sub execute {
1695     my ( $c, $class, $code ) = @_;
1696     $class = $c->component($class) || $class;
1697     $c->state(0);
1698
1699     if ( $c->depth >= $RECURSION ) {
1700         my $action = $code->reverse();
1701         $action = "/$action" unless $action =~ /->/;
1702         my $error = qq/Deep recursion detected calling "${action}"/;
1703         $c->log->error($error);
1704         $c->error($error);
1705         $c->state(0);
1706         return $c->state;
1707     }
1708
1709     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1710
1711     push( @{ $c->stack }, $code );
1712
1713     no warnings 'recursion';
1714     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1715     #      I have no idea how, ergo $ret (which appears to fix the issue)
1716     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1717
1718     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1719
1720     my $last = pop( @{ $c->stack } );
1721
1722     if ( my $error = $@ ) {
1723         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1724             $error->rethrow if $c->depth > 1;
1725         }
1726         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1727             $error->rethrow if $c->depth > 0;
1728         }
1729         else {
1730             unless ( ref $error ) {
1731                 no warnings 'uninitialized';
1732                 chomp $error;
1733                 my $class = $last->class;
1734                 my $name  = $last->name;
1735                 $error = qq/Caught exception in $class->$name "$error"/;
1736             }
1737             $c->error($error);
1738         }
1739         $c->state(0);
1740     }
1741     return $c->state;
1742 }
1743
1744 sub _stats_start_execute {
1745     my ( $c, $code ) = @_;
1746     my $appclass = ref($c) || $c;
1747     return if ( ( $code->name =~ /^_.*/ )
1748         && ( !$appclass->config->{show_internal_actions} ) );
1749
1750     my $action_name = $code->reverse();
1751     $c->counter->{$action_name}++;
1752
1753     my $action = $action_name;
1754     $action = "/$action" unless $action =~ /->/;
1755
1756     # determine if the call was the result of a forward
1757     # this is done by walking up the call stack and looking for a calling
1758     # sub of Catalyst::forward before the eval
1759     my $callsub = q{};
1760     for my $index ( 2 .. 11 ) {
1761         last
1762         if ( ( caller($index) )[0] eq 'Catalyst'
1763             && ( caller($index) )[3] eq '(eval)' );
1764
1765         if ( ( caller($index) )[3] =~ /forward$/ ) {
1766             $callsub = ( caller($index) )[3];
1767             $action  = "-> $action";
1768             last;
1769         }
1770     }
1771
1772     my $uid = $action_name . $c->counter->{$action_name};
1773
1774     # is this a root-level call or a forwarded call?
1775     if ( $callsub =~ /forward$/ ) {
1776         my $parent = $c->stack->[-1];
1777
1778         # forward, locate the caller
1779         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1780             $c->stats->profile(
1781                 begin  => $action,
1782                 parent => "$parent" . $c->counter->{"$parent"},
1783                 uid    => $uid,
1784             );
1785         }
1786         else {
1787
1788             # forward with no caller may come from a plugin
1789             $c->stats->profile(
1790                 begin => $action,
1791                 uid   => $uid,
1792             );
1793         }
1794     }
1795     else {
1796
1797         # root-level call
1798         $c->stats->profile(
1799             begin => $action,
1800             uid   => $uid,
1801         );
1802     }
1803     return $action;
1804
1805 }
1806
1807 sub _stats_finish_execute {
1808     my ( $c, $info ) = @_;
1809     $c->stats->profile( end => $info );
1810 }
1811
1812 =head2 $c->finalize
1813
1814 Finalizes the request.
1815
1816 =cut
1817
1818 sub finalize {
1819     my $c = shift;
1820
1821     for my $error ( @{ $c->error } ) {
1822         $c->log->error($error);
1823     }
1824
1825     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1826     # stuff like cometd and websockets
1827
1828     if($c->request->has_io_fh) {
1829       $c->log_response;
1830       return;
1831     }
1832
1833     # Allow engine to handle finalize flow (for POE)
1834     my $engine = $c->engine;
1835     if ( my $code = $engine->can('finalize') ) {
1836         $engine->$code($c);
1837     }
1838     else {
1839
1840         $c->finalize_uploads;
1841
1842         # Error
1843         if ( $#{ $c->error } >= 0 ) {
1844             $c->finalize_error;
1845         }
1846
1847         $c->finalize_headers unless $c->response->finalized_headers;
1848
1849         # HEAD request
1850         if ( $c->request->method eq 'HEAD' ) {
1851             $c->response->body('');
1852         }
1853
1854         $c->finalize_body;
1855     }
1856
1857     $c->log_response;
1858
1859     if ($c->use_stats) {
1860         my $elapsed = $c->stats->elapsed;
1861         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1862         $c->log->info(
1863             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1864     }
1865
1866     return $c->response->status;
1867 }
1868
1869 =head2 $c->finalize_body
1870
1871 Finalizes body.
1872
1873 =cut
1874
1875 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1876
1877 =head2 $c->finalize_cookies
1878
1879 Finalizes cookies.
1880
1881 =cut
1882
1883 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1884
1885 =head2 $c->finalize_error
1886
1887 Finalizes error.
1888
1889 =cut
1890
1891 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1892
1893 =head2 $c->finalize_headers
1894
1895 Finalizes headers.
1896
1897 =cut
1898
1899 sub finalize_headers {
1900     my $c = shift;
1901
1902     my $response = $c->response; #accessor calls can add up?
1903
1904     # Check if we already finalized headers
1905     return if $response->finalized_headers;
1906
1907     # Handle redirects
1908     if ( my $location = $response->redirect ) {
1909         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1910         $response->header( Location => $location );
1911
1912         if ( !$response->has_body ) {
1913             # Add a default body if none is already present
1914             my $encoded_location = encode_entities($location);
1915             $response->body(<<"EOF");
1916 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1917 <html xmlns="http://www.w3.org/1999/xhtml">
1918   <head>
1919     <title>Moved</title>
1920   </head>
1921   <body>
1922      <p>This item has moved <a href="$encoded_location">here</a>.</p>
1923   </body>
1924 </html>
1925 EOF
1926             $response->content_type('text/html; charset=utf-8');
1927         }
1928     }
1929
1930     # Content-Length
1931     if ( defined $response->body && length $response->body && !$response->content_length ) {
1932
1933         # get the length from a filehandle
1934         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1935         {
1936             my $size = -s $response->body;
1937             if ( $size ) {
1938                 $response->content_length( $size );
1939             }
1940             else {
1941                 $c->log->warn('Serving filehandle without a content-length');
1942             }
1943         }
1944         else {
1945             # everything should be bytes at this point, but just in case
1946             $response->content_length( length( $response->body ) );
1947         }
1948     }
1949
1950     # Errors
1951     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1952         $response->headers->remove_header("Content-Length");
1953         $response->body('');
1954     }
1955
1956     $c->finalize_cookies;
1957
1958     $c->response->finalize_headers();
1959
1960     # Done
1961     $response->finalized_headers(1);
1962 }
1963
1964 =head2 $c->finalize_output
1965
1966 An alias for finalize_body.
1967
1968 =head2 $c->finalize_read
1969
1970 Finalizes the input after reading is complete.
1971
1972 =cut
1973
1974 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1975
1976 =head2 $c->finalize_uploads
1977
1978 Finalizes uploads. Cleans up any temporary files.
1979
1980 =cut
1981
1982 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1983
1984 =head2 $c->get_action( $action, $namespace )
1985
1986 Gets an action in a given namespace.
1987
1988 =cut
1989
1990 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1991
1992 =head2 $c->get_actions( $action, $namespace )
1993
1994 Gets all actions of a given name in a namespace and all parent
1995 namespaces.
1996
1997 =cut
1998
1999 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2000
2001 =head2 $app->handle_request( @arguments )
2002
2003 Called to handle each HTTP request.
2004
2005 =cut
2006
2007 sub handle_request {
2008     my ( $class, @arguments ) = @_;
2009
2010     # Always expect worst case!
2011     my $status = -1;
2012     try {
2013         if ($class->debug) {
2014             my $secs = time - $START || 1;
2015             my $av = sprintf '%.3f', $COUNT / $secs;
2016             my $time = localtime time;
2017             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2018         }
2019
2020         my $c = $class->prepare(@arguments);
2021         $c->dispatch;
2022         $status = $c->finalize;
2023     }
2024     catch {
2025         chomp(my $error = $_);
2026         $class->log->error(qq/Caught exception in engine "$error"/);
2027     };
2028
2029     $COUNT++;
2030
2031     if(my $coderef = $class->log->can('_flush')){
2032         $class->log->$coderef();
2033     }
2034     return $status;
2035 }
2036
2037 =head2 $class->prepare( @arguments )
2038
2039 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2040 etc.).
2041
2042 =cut
2043
2044 has _uploadtmp => (
2045     is => 'ro',
2046     predicate => '_has_uploadtmp',
2047 );
2048
2049 sub prepare {
2050     my ( $class, @arguments ) = @_;
2051
2052     # XXX
2053     # After the app/ctxt split, this should become an attribute based on something passed
2054     # into the application.
2055     $class->context_class( ref $class || $class ) unless $class->context_class;
2056
2057     my $uploadtmp = $class->config->{uploadtmp};
2058     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2059
2060     $c->response->_context($c);
2061
2062     #surely this is not the most efficient way to do things...
2063     $c->stats($class->stats_class->new)->enable($c->use_stats);
2064     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2065         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2066     }
2067
2068     try {
2069         # Allow engine to direct the prepare flow (for POE)
2070         if ( my $prepare = $c->engine->can('prepare') ) {
2071             $c->engine->$prepare( $c, @arguments );
2072         }
2073         else {
2074             $c->prepare_request(@arguments);
2075             $c->prepare_connection;
2076             $c->prepare_query_parameters;
2077             $c->prepare_headers; # Just hooks, no longer needed - they just
2078             $c->prepare_cookies; # cause the lazy attribute on req to build
2079             $c->prepare_path;
2080
2081             # Prepare the body for reading, either by prepare_body
2082             # or the user, if they are using $c->read
2083             $c->prepare_read;
2084
2085             # Parse the body unless the user wants it on-demand
2086             unless ( ref($c)->config->{parse_on_demand} ) {
2087                 $c->prepare_body;
2088             }
2089         }
2090         $c->prepare_action;
2091     }
2092     # VERY ugly and probably shouldn't rely on ->finalize actually working
2093     catch {
2094         # failed prepare is always due to an invalid request, right?
2095         $c->response->status(400);
2096         $c->response->content_type('text/plain');
2097         $c->response->body('Bad Request');
2098         # Note we call finalize and then die here, which escapes
2099         # finalize being called in the enclosing block..
2100         # It in fact couldn't be called, as we don't return $c..
2101         # This is a mess - but I'm unsure you can fix this without
2102         # breaking compat for people doing crazy things (we should set
2103         # the 400 and just return the ctx here IMO, letting finalize get called
2104         # above...
2105         $c->finalize;
2106         die $_;
2107     };
2108
2109     $c->log_request;
2110
2111     return $c;
2112 }
2113
2114 =head2 $c->prepare_action
2115
2116 Prepares action. See L<Catalyst::Dispatcher>.
2117
2118 =cut
2119
2120 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2121
2122 =head2 $c->prepare_body
2123
2124 Prepares message body.
2125
2126 =cut
2127
2128 sub prepare_body {
2129     my $c = shift;
2130
2131     return if $c->request->_has_body;
2132
2133     # Initialize on-demand data
2134     $c->engine->prepare_body( $c, @_ );
2135     $c->prepare_parameters;
2136     $c->prepare_uploads;
2137 }
2138
2139 =head2 $c->prepare_body_chunk( $chunk )
2140
2141 Prepares a chunk of data before sending it to L<HTTP::Body>.
2142
2143 See L<Catalyst::Engine>.
2144
2145 =cut
2146
2147 sub prepare_body_chunk {
2148     my $c = shift;
2149     $c->engine->prepare_body_chunk( $c, @_ );
2150 }
2151
2152 =head2 $c->prepare_body_parameters
2153
2154 Prepares body parameters.
2155
2156 =cut
2157
2158 sub prepare_body_parameters {
2159     my $c = shift;
2160     $c->engine->prepare_body_parameters( $c, @_ );
2161 }
2162
2163 =head2 $c->prepare_connection
2164
2165 Prepares connection.
2166
2167 =cut
2168
2169 sub prepare_connection {
2170     my $c = shift;
2171     # XXX - This is called on the engine (not the request) to maintain
2172     #       Engine::PSGI back compat.
2173     $c->engine->prepare_connection($c);
2174 }
2175
2176 =head2 $c->prepare_cookies
2177
2178 Prepares cookies by ensuring that the attribute on the request
2179 object has been built.
2180
2181 =cut
2182
2183 sub prepare_cookies { my $c = shift; $c->request->cookies }
2184
2185 =head2 $c->prepare_headers
2186
2187 Prepares request headers by ensuring that the attribute on the request
2188 object has been built.
2189
2190 =cut
2191
2192 sub prepare_headers { my $c = shift; $c->request->headers }
2193
2194 =head2 $c->prepare_parameters
2195
2196 Prepares parameters.
2197
2198 =cut
2199
2200 sub prepare_parameters {
2201     my $c = shift;
2202     $c->prepare_body_parameters;
2203     $c->engine->prepare_parameters( $c, @_ );
2204 }
2205
2206 =head2 $c->prepare_path
2207
2208 Prepares path and base.
2209
2210 =cut
2211
2212 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2213
2214 =head2 $c->prepare_query_parameters
2215
2216 Prepares query parameters.
2217
2218 =cut
2219
2220 sub prepare_query_parameters {
2221     my $c = shift;
2222
2223     $c->engine->prepare_query_parameters( $c, @_ );
2224 }
2225
2226 =head2 $c->log_request
2227
2228 Writes information about the request to the debug logs.  This includes:
2229
2230 =over 4
2231
2232 =item * Request method, path, and remote IP address
2233
2234 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2235
2236 =item * Request parameters
2237
2238 =item * File uploads
2239
2240 =back
2241
2242 =cut
2243
2244 sub log_request {
2245     my $c = shift;
2246
2247     return unless $c->debug;
2248
2249     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2250     my $request = $dump->[1];
2251
2252     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2253     $method ||= '';
2254     $path = '/' unless length $path;
2255     $address ||= '';
2256     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2257
2258     $c->log_request_headers($request->headers);
2259
2260     if ( my $keywords = $request->query_keywords ) {
2261         $c->log->debug("Query keywords are: $keywords");
2262     }
2263
2264     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2265
2266     $c->log_request_uploads($request);
2267 }
2268
2269 =head2 $c->log_response
2270
2271 Writes information about the response to the debug logs by calling
2272 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2273
2274 =cut
2275
2276 sub log_response {
2277     my $c = shift;
2278
2279     return unless $c->debug;
2280
2281     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2282     my $response = $dump->[1];
2283
2284     $c->log_response_status_line($response);
2285     $c->log_response_headers($response->headers);
2286 }
2287
2288 =head2 $c->log_response_status_line($response)
2289
2290 Writes one line of information about the response to the debug logs.  This includes:
2291
2292 =over 4
2293
2294 =item * Response status code
2295
2296 =item * Content-Type header (if present)
2297
2298 =item * Content-Length header (if present)
2299
2300 =back
2301
2302 =cut
2303
2304 sub log_response_status_line {
2305     my ($c, $response) = @_;
2306
2307     $c->log->debug(
2308         sprintf(
2309             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2310             $response->status                            || 'unknown',
2311             $response->headers->header('Content-Type')   || 'unknown',
2312             $response->headers->header('Content-Length') || 'unknown'
2313         )
2314     );
2315 }
2316
2317 =head2 $c->log_response_headers($headers);
2318
2319 Hook method which can be wrapped by plugins to log the response headers.
2320 No-op in the default implementation.
2321
2322 =cut
2323
2324 sub log_response_headers {}
2325
2326 =head2 $c->log_request_parameters( query => {}, body => {} )
2327
2328 Logs request parameters to debug logs
2329
2330 =cut
2331
2332 sub log_request_parameters {
2333     my $c          = shift;
2334     my %all_params = @_;
2335
2336     return unless $c->debug;
2337
2338     my $column_width = Catalyst::Utils::term_width() - 44;
2339     foreach my $type (qw(query body)) {
2340         my $params = $all_params{$type};
2341         next if ! keys %$params;
2342         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2343         for my $key ( sort keys %$params ) {
2344             my $param = $params->{$key};
2345             my $value = defined($param) ? $param : '';
2346             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2347         }
2348         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2349     }
2350 }
2351
2352 =head2 $c->log_request_uploads
2353
2354 Logs file uploads included in the request to the debug logs.
2355 The parameter name, filename, file type, and file size are all included in
2356 the debug logs.
2357
2358 =cut
2359
2360 sub log_request_uploads {
2361     my $c = shift;
2362     my $request = shift;
2363     return unless $c->debug;
2364     my $uploads = $request->uploads;
2365     if ( keys %$uploads ) {
2366         my $t = Text::SimpleTable->new(
2367             [ 12, 'Parameter' ],
2368             [ 26, 'Filename' ],
2369             [ 18, 'Type' ],
2370             [ 9,  'Size' ]
2371         );
2372         for my $key ( sort keys %$uploads ) {
2373             my $upload = $uploads->{$key};
2374             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2375                 $t->row( $key, $u->filename, $u->type, $u->size );
2376             }
2377         }
2378         $c->log->debug( "File Uploads are:\n" . $t->draw );
2379     }
2380 }
2381
2382 =head2 $c->log_request_headers($headers);
2383
2384 Hook method which can be wrapped by plugins to log the request headers.
2385 No-op in the default implementation.
2386
2387 =cut
2388
2389 sub log_request_headers {}
2390
2391 =head2 $c->log_headers($type => $headers)
2392
2393 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2394
2395 =cut
2396
2397 sub log_headers {
2398     my $c       = shift;
2399     my $type    = shift;
2400     my $headers = shift;    # an HTTP::Headers instance
2401
2402     return unless $c->debug;
2403
2404     my $column_width = Catalyst::Utils::term_width() - 28;
2405     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2406     $headers->scan(
2407         sub {
2408             my ( $name, $value ) = @_;
2409             $t->row( $name, $value );
2410         }
2411     );
2412     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2413 }
2414
2415
2416 =head2 $c->prepare_read
2417
2418 Prepares the input for reading.
2419
2420 =cut
2421
2422 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2423
2424 =head2 $c->prepare_request
2425
2426 Prepares the engine request.
2427
2428 =cut
2429
2430 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2431
2432 =head2 $c->prepare_uploads
2433
2434 Prepares uploads.
2435
2436 =cut
2437
2438 sub prepare_uploads {
2439     my $c = shift;
2440
2441     $c->engine->prepare_uploads( $c, @_ );
2442 }
2443
2444 =head2 $c->prepare_write
2445
2446 Prepares the output for writing.
2447
2448 =cut
2449
2450 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2451
2452 =head2 $c->request_class
2453
2454 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2455
2456 =head2 $c->response_class
2457
2458 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2459
2460 =head2 $c->read( [$maxlength] )
2461
2462 Reads a chunk of data from the request body. This method is designed to
2463 be used in a while loop, reading C<$maxlength> bytes on every call.
2464 C<$maxlength> defaults to the size of the request if not specified.
2465
2466 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2467 directly.
2468
2469 Warning: If you use read(), Catalyst will not process the body,
2470 so you will not be able to access POST parameters or file uploads via
2471 $c->request.  You must handle all body parsing yourself.
2472
2473 =cut
2474
2475 sub read { my $c = shift; return $c->request->read( @_ ) }
2476
2477 =head2 $c->run
2478
2479 Starts the engine.
2480
2481 =cut
2482
2483 sub run {
2484   my $app = shift;
2485   $app->_make_immutable_if_needed;
2486   $app->engine_loader->needs_psgi_engine_compat_hack ?
2487     $app->engine->run($app, @_) :
2488       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2489 }
2490
2491 sub _make_immutable_if_needed {
2492     my $class = shift;
2493     my $meta = Class::MOP::get_metaclass_by_name($class);
2494     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2495     if (
2496         $meta->is_immutable
2497         && ! { $meta->immutable_options }->{replace_constructor}
2498         && $isa_ca
2499     ) {
2500         warn("You made your application class ($class) immutable, "
2501             . "but did not inline the\nconstructor. "
2502             . "This will break catalyst, as your app \@ISA "
2503             . "Class::Accessor(::Fast)?\nPlease pass "
2504             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2505     }
2506     unless ($meta->is_immutable) {
2507         # XXX - FIXME warning here as you should make your app immutable yourself.
2508         $meta->make_immutable(
2509             replace_constructor => 1,
2510         );
2511     }
2512 }
2513
2514 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2515
2516 Sets an action in a given namespace.
2517
2518 =cut
2519
2520 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2521
2522 =head2 $c->setup_actions($component)
2523
2524 Sets up actions for a component.
2525
2526 =cut
2527
2528 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2529
2530 =head2 $c->setup_components
2531
2532 This method is called internally to set up the application's components.
2533
2534 It finds modules by calling the L<locate_components> method, expands them to
2535 package names with the L<expand_component_module> method, and then installs
2536 each component into the application.
2537
2538 The C<setup_components> config option is passed to both of the above methods.
2539
2540 Installation of each component is performed by the L<setup_component> method,
2541 below.
2542
2543 =cut
2544
2545 sub setup_components {
2546     my $class = shift;
2547
2548     my $config  = $class->config->{ setup_components };
2549
2550     my @comps = $class->locate_components($config);
2551     my %comps = map { $_ => 1 } @comps;
2552
2553     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2554     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2555         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2556     ) if $deprecatedcatalyst_component_names;
2557
2558     for my $component ( @comps ) {
2559
2560         # We pass ignore_loaded here so that overlay files for (e.g.)
2561         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2562         # we know M::P::O found a file on disk so this is safe
2563
2564         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2565     }
2566
2567     for my $component (@comps) {
2568         my $instance = $class->components->{ $component } = $class->setup_component($component);
2569         my @expanded_components = $instance->can('expand_modules')
2570             ? $instance->expand_modules( $component, $config )
2571             : $class->expand_component_module( $component, $config );
2572         for my $component (@expanded_components) {
2573             next if $comps{$component};
2574             $class->components->{ $component } = $class->setup_component($component);
2575         }
2576     }
2577 }
2578
2579 =head2 $c->locate_components( $setup_component_config )
2580
2581 This method is meant to provide a list of component modules that should be
2582 setup for the application.  By default, it will use L<Module::Pluggable>.
2583
2584 Specify a C<setup_components> config option to pass additional options directly
2585 to L<Module::Pluggable>. To add additional search paths, specify a key named
2586 C<search_extra> as an array reference. Items in the array beginning with C<::>
2587 will have the application class name prepended to them.
2588
2589 =cut
2590
2591 sub locate_components {
2592     my $class  = shift;
2593     my $config = shift;
2594
2595     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2596     my $extra   = delete $config->{ search_extra } || [];
2597
2598     push @paths, @$extra;
2599
2600     my $locator = Module::Pluggable::Object->new(
2601         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2602         %$config
2603     );
2604
2605     # XXX think about ditching this sort entirely
2606     my @comps = sort { length $a <=> length $b } $locator->plugins;
2607
2608     return @comps;
2609 }
2610
2611 =head2 $c->expand_component_module( $component, $setup_component_config )
2612
2613 Components found by C<locate_components> will be passed to this method, which
2614 is expected to return a list of component (package) names to be set up.
2615
2616 =cut
2617
2618 sub expand_component_module {
2619     my ($class, $module) = @_;
2620     return Devel::InnerPackage::list_packages( $module );
2621 }
2622
2623 =head2 $c->setup_component
2624
2625 =cut
2626
2627 sub setup_component {
2628     my( $class, $component ) = @_;
2629
2630     unless ( $component->can( 'COMPONENT' ) ) {
2631         return $component;
2632     }
2633
2634     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2635     my $config = $class->config->{ $suffix } || {};
2636     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2637     # methods also pass it. local to avoid pointlessly shitting in config
2638     # for the debug screen, as $component is already the key name.
2639     local $config->{catalyst_component_name} = $component;
2640
2641     my $instance = eval { $component->COMPONENT( $class, $config ); };
2642
2643     if ( my $error = $@ ) {
2644         chomp $error;
2645         Catalyst::Exception->throw(
2646             message => qq/Couldn't instantiate component "$component", "$error"/
2647         );
2648     }
2649
2650     unless (blessed $instance) {
2651         my $metaclass = Moose::Util::find_meta($component);
2652         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2653         my $component_method_from = $method_meta->associated_metaclass->name;
2654         my $value = defined($instance) ? $instance : 'undef';
2655         Catalyst::Exception->throw(
2656             message =>
2657             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2658         );
2659     }
2660     return $instance;
2661 }
2662
2663 =head2 $c->setup_dispatcher
2664
2665 Sets up dispatcher.
2666
2667 =cut
2668
2669 sub setup_dispatcher {
2670     my ( $class, $dispatcher ) = @_;
2671
2672     if ($dispatcher) {
2673         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2674     }
2675
2676     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2677         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2678     }
2679
2680     unless ($dispatcher) {
2681         $dispatcher = $class->dispatcher_class;
2682     }
2683
2684     Class::MOP::load_class($dispatcher);
2685
2686     # dispatcher instance
2687     $class->dispatcher( $dispatcher->new );
2688 }
2689
2690 =head2 $c->setup_engine
2691
2692 Sets up engine.
2693
2694 =cut
2695
2696 sub engine_class {
2697     my ($class, $requested_engine) = @_;
2698
2699     if (!$class->engine_loader || $requested_engine) {
2700         $class->engine_loader(
2701             Catalyst::EngineLoader->new({
2702                 application_name => $class,
2703                 (defined $requested_engine
2704                      ? (catalyst_engine_class => $requested_engine) : ()),
2705             }),
2706         );
2707     }
2708
2709     $class->engine_loader->catalyst_engine_class;
2710 }
2711
2712 sub setup_engine {
2713     my ($class, $requested_engine) = @_;
2714
2715     my $engine = do {
2716         my $loader = $class->engine_loader;
2717
2718         if (!$loader || $requested_engine) {
2719             $loader = Catalyst::EngineLoader->new({
2720                 application_name => $class,
2721                 (defined $requested_engine
2722                      ? (requested_engine => $requested_engine) : ()),
2723             }),
2724
2725             $class->engine_loader($loader);
2726         }
2727
2728         $loader->catalyst_engine_class;
2729     };
2730
2731     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2732     return if $class->loading_psgi_file;
2733
2734     Class::MOP::load_class($engine);
2735
2736     if ($ENV{MOD_PERL}) {
2737         my $apache = $class->engine_loader->auto;
2738
2739         my $meta = find_meta($class);
2740         my $was_immutable = $meta->is_immutable;
2741         my %immutable_options = $meta->immutable_options;
2742         $meta->make_mutable if $was_immutable;
2743
2744         $meta->add_method(handler => sub {
2745             my $r = shift;
2746             my $psgi_app = $class->_finalized_psgi_app;
2747             $apache->call_app($r, $psgi_app);
2748         });
2749
2750         $meta->make_immutable(%immutable_options) if $was_immutable;
2751     }
2752
2753     $class->engine( $engine->new );
2754
2755     return;
2756 }
2757
2758 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2759 ## build in server support (back compat support for pre psgi port behavior).
2760 ## This is so that we don't build a new psgi app for each request when using
2761 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2762
2763 sub _finalized_psgi_app {
2764     my ($app) = @_;
2765
2766     unless ($app->_psgi_app) {
2767         my $psgi_app = $app->_setup_psgi_app;
2768         $app->_psgi_app($psgi_app);
2769     }
2770
2771     return $app->_psgi_app;
2772 }
2773
2774 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2775 ## home directory and load that and return it (just assume it is doing the
2776 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2777 ## in default_middleware and return it ( this is for backward compatibility
2778 ## with pre psgi port behavior ).
2779
2780 sub _setup_psgi_app {
2781     my ($app) = @_;
2782
2783     for my $home (Path::Class::Dir->new($app->config->{home})) {
2784         my $psgi_file = $home->file(
2785             Catalyst::Utils::appprefix($app) . '.psgi',
2786         );
2787
2788         next unless -e $psgi_file;
2789
2790         # If $psgi_file calls ->setup_engine, it's doing so to load
2791         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2792         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2793         # anyway. So set a flag (ick) that tells setup_engine not to populate
2794         # $c->engine or do any other things we might regret.
2795
2796         $app->loading_psgi_file(1);
2797         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2798         $app->loading_psgi_file(0);
2799
2800         return $psgi_app
2801             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2802
2803         warn <<"EOW";
2804 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2805
2806 Its content has been ignored. Please consult the Catalyst::Upgrading
2807 documentation on how to upgrade from Catalyst::Engine::PSGI.
2808 EOW
2809     }
2810
2811     return $app->apply_default_middlewares($app->psgi_app);
2812 }
2813
2814 =head2 $c->apply_default_middlewares
2815
2816 Adds the following L<Plack> middlewares to your application, since they are
2817 useful and commonly needed:
2818
2819 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2820 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2821 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2822 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2823 applied since this middleware is smart enough to conditionally apply itself).
2824
2825 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2826 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2827 $ENV{SCRIPT_NAME}
2828
2829 =cut
2830
2831
2832 sub apply_default_middlewares {
2833     my ($app, $psgi_app) = @_;
2834
2835     $psgi_app = Plack::Middleware::Conditional->wrap(
2836         $psgi_app,
2837         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2838         condition => sub {
2839             my ($env) = @_;
2840             return if $app->config->{ignore_frontend_proxy};
2841             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2842                 || $app->config->{using_frontend_proxy};
2843         },
2844     );
2845
2846     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2847     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2848     $psgi_app = Plack::Middleware::Conditional->wrap(
2849         $psgi_app,
2850         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2851         condition => sub {
2852             my ($env) = @_;
2853             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2854             return unless $1 < 4.23;
2855             1;
2856         },
2857     );
2858
2859     # we're applying this unconditionally as the middleware itself already makes
2860     # sure it doesn't fuck things up if it's not running under one of the right
2861     # IIS versions
2862     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2863
2864     # And another IIS issue, this time with IIS7.
2865     $psgi_app = Plack::Middleware::Conditional->wrap(
2866         $psgi_app,
2867         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2868         condition => sub {
2869             my ($env) = @_;
2870             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2871         },
2872     );
2873
2874     return $psgi_app;
2875 }
2876
2877 =head2 $c->psgi_app
2878
2879 Returns a PSGI application code reference for the catalyst application
2880 C<$c>. This is the bare application without any middlewares
2881 applied. C<${myapp}.psgi> is not taken into account.
2882
2883 This is what you want to be using to retrieve the PSGI application code
2884 reference of your Catalyst application for use in F<.psgi> files.
2885
2886 =cut
2887
2888 sub psgi_app {
2889     my ($app) = @_;
2890     my $psgi = $app->engine->build_psgi_app($app);
2891     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
2892 }
2893
2894 =head2 $c->setup_home
2895
2896 Sets up the home directory.
2897
2898 =cut
2899
2900 sub setup_home {
2901     my ( $class, $home ) = @_;
2902
2903     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2904         $home = $env;
2905     }
2906
2907     $home ||= Catalyst::Utils::home($class);
2908
2909     if ($home) {
2910         #I remember recently being scolded for assigning config values like this
2911         $class->config->{home} ||= $home;
2912         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2913     }
2914 }
2915
2916 =head2 $c->setup_log
2917
2918 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2919 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2920 log to.
2921
2922 This method also installs a C<debug> method that returns a true value into the
2923 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2924 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2925
2926 Note that if the log has already been setup, by either a previous call to
2927 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2928 that this method won't actually set up the log object.
2929
2930 =cut
2931
2932 sub setup_log {
2933     my ( $class, $levels ) = @_;
2934
2935     $levels ||= '';
2936     $levels =~ s/^\s+//;
2937     $levels =~ s/\s+$//;
2938     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2939
2940     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2941     if ( defined $env_debug ) {
2942         $levels{debug} = 1 if $env_debug; # Ugly!
2943         delete($levels{debug}) unless $env_debug;
2944     }
2945
2946     unless ( $class->log ) {
2947         $class->log( Catalyst::Log->new(keys %levels) );
2948     }
2949
2950     if ( $levels{debug} ) {
2951         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2952         $class->log->debug('Debug messages enabled');
2953     }
2954 }
2955
2956 =head2 $c->setup_plugins
2957
2958 Sets up plugins.
2959
2960 =cut
2961
2962 =head2 $c->setup_stats
2963
2964 Sets up timing statistics class.
2965
2966 =cut
2967
2968 sub setup_stats {
2969     my ( $class, $stats ) = @_;
2970
2971     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2972
2973     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2974     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2975         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2976         $class->log->debug('Statistics enabled');
2977     }
2978 }
2979
2980
2981 =head2 $c->registered_plugins
2982
2983 Returns a sorted list of the plugins which have either been stated in the
2984 import list.
2985
2986 If passed a given plugin name, it will report a boolean value indicating
2987 whether or not that plugin is loaded.  A fully qualified name is required if
2988 the plugin name does not begin with C<Catalyst::Plugin::>.
2989
2990  if ($c->registered_plugins('Some::Plugin')) {
2991      ...
2992  }
2993
2994 =cut
2995
2996 {
2997
2998     sub registered_plugins {
2999         my $proto = shift;
3000         return sort keys %{ $proto->_plugins } unless @_;
3001         my $plugin = shift;
3002         return 1 if exists $proto->_plugins->{$plugin};
3003         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3004     }
3005
3006     sub _register_plugin {
3007         my ( $proto, $plugin, $instant ) = @_;
3008         my $class = ref $proto || $proto;
3009
3010         Class::MOP::load_class( $plugin );
3011         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3012             if $plugin->isa( 'Catalyst::Component' );
3013         my $plugin_meta = Moose::Meta::Class->create($plugin);
3014         if (!$plugin_meta->has_method('new')
3015             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3016             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3017         }
3018         if (!$instant && !$proto->_plugins->{$plugin}) {
3019             my $meta = Class::MOP::get_metaclass_by_name($class);
3020             $meta->superclasses($plugin, $meta->superclasses);
3021         }
3022         $proto->_plugins->{$plugin} = 1;
3023         return $class;
3024     }
3025
3026     sub _default_plugins { return qw(Unicode::Encoding) }
3027
3028     sub setup_plugins {
3029         my ( $class, $plugins ) = @_;
3030
3031         $class->_plugins( {} ) unless $class->_plugins;
3032         $plugins = [ grep {
3033             m/Unicode::Encoding/ ? do {
3034                 $class->log->warn(
3035                     'Unicode::Encoding plugin is auto-applied,'
3036                     . ' please remove this from your appclass'
3037                     . ' and make sure to define "encoding" config'
3038                 );
3039                 unless (exists $class->config->{'encoding'}) {
3040                   $class->config->{'encoding'} = 'UTF-8';
3041                 }
3042                 () }
3043                 : $_
3044         } @$plugins ];
3045         push @$plugins, $class->_default_plugins;
3046         $plugins = Data::OptList::mkopt($plugins || []);
3047
3048         my @plugins = map {
3049             [ Catalyst::Utils::resolve_namespace(
3050                   $class . '::Plugin',
3051                   'Catalyst::Plugin', $_->[0]
3052               ),
3053               $_->[1],
3054             ]
3055          } @{ $plugins };
3056
3057         for my $plugin ( reverse @plugins ) {
3058             Class::MOP::load_class($plugin->[0], $plugin->[1]);
3059             my $meta = find_meta($plugin->[0]);
3060             next if $meta && $meta->isa('Moose::Meta::Role');
3061
3062             $class->_register_plugin($plugin->[0]);
3063         }
3064
3065         my @roles =
3066             map  { $_->[0]->name, $_->[1] }
3067             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3068             map  { [find_meta($_->[0]), $_->[1]] }
3069             @plugins;
3070
3071         Moose::Util::apply_all_roles(
3072             $class => @roles
3073         ) if @roles;
3074     }
3075 }
3076
3077 =head2 registered_middlewares
3078
3079 Read only accessor that returns an array of all the middleware in the order
3080 that they were added (which is the REVERSE of the order they will be applied).
3081
3082 The values returned will be either instances of L<Plack::Middleware> or of a
3083 compatible interface, or a coderef, which is assumed to be inlined middleware
3084
3085 =head2 setup_middleware (?@middleware)
3086
3087 Read configuration information stored in configuration key C<psgi_middleware> or
3088 from passed @args.
3089
3090 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3091 to use it to enable L<Plack::Middleware>
3092
3093 This method is automatically called during 'setup' of your application, so
3094 you really don't need to invoke it.
3095
3096 When we read middleware definitions from configuration, we reverse the list
3097 which sounds odd but is likely how you expect it to work if you have prior
3098 experience with L<Plack::Builder> or if you previously used the plugin
3099 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3100
3101 =cut
3102
3103 sub registered_middlewares {
3104     my $class = shift;
3105     if(my $middleware = $class->_psgi_middleware) {
3106         return @$middleware;
3107     } else {
3108         die "You cannot call ->registered_middlewares until middleware has been setup";
3109     }
3110 }
3111
3112 sub setup_middleware {
3113     my ($class, @middleware_definitions) = @_;
3114     push @middleware_definitions, reverse(
3115       @{$class->config->{'psgi_middleware'}||[]});
3116
3117     my @middleware = ();
3118     while(my $next = shift(@middleware_definitions)) {
3119         if(ref $next) {
3120             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3121                 push @middleware, $next;
3122             } elsif(ref $next eq 'CODE') {
3123                 push @middleware, $next;
3124             } elsif(ref $next eq 'HASH') {
3125                 my $namespace = shift @middleware_definitions;
3126                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3127                 push @middleware, $mw;
3128             } else {
3129               die "I can't handle middleware definition ${\ref $next}";
3130             }
3131         } else {
3132           my $mw = $class->Catalyst::Utils::build_middleware($next);
3133           push @middleware, $mw;
3134         }
3135     }
3136
3137     $class->_psgi_middleware(\@middleware);
3138 }
3139
3140 =head2 registered_data_handlers
3141
3142 A read only copy of registered Data Handlers returned as a Hash, where each key
3143 is a content type and each value is a subref that attempts to decode that content
3144 type.
3145
3146 =head2 setup_data_handlers (?@data_handler)
3147
3148 Read configuration information stored in configuration key C<data_handlers> or
3149 from passed @args.
3150
3151 See under L</CONFIGURATION> information regarding C<data_handlers>.
3152
3153 This method is automatically called during 'setup' of your application, so
3154 you really don't need to invoke it.
3155
3156 =head2 default_data_handlers
3157
3158 Default Data Handler that come bundled with L<Catalyst>.  Currently there is
3159 only one default data handler, for 'application/json'.  This uses L<JSON::MaybeXS>
3160 which uses the dependency free L<JSON::PP> OR L<Cpanel::JSON::XS> if you have
3161 installed it.  If you don't mind the XS dependency, you should add the faster
3162 L<Cpanel::JSON::XS> to you dependency list (in your Makefile.PL or dist.ini, or
3163 cpanfile, etc.)
3164
3165 =cut
3166
3167 sub registered_data_handlers {
3168     my $class = shift;
3169     if(my $data_handlers = $class->_data_handlers) {
3170         return %$data_handlers;
3171     } else {
3172         die "You cannot call ->registered_data_handlers until data_handers has been setup";
3173     }
3174 }
3175
3176 sub setup_data_handlers {
3177     my ($class, %data_handler_callbacks) = @_;
3178     %data_handler_callbacks = (
3179       %{$class->default_data_handlers},
3180       %{$class->config->{'data_handlers'}||+{}},
3181       %data_handler_callbacks);
3182
3183     $class->_data_handlers(\%data_handler_callbacks);
3184 }
3185
3186 sub default_data_handlers {
3187     my ($class) = @_;
3188     return +{
3189       'application/json' => sub { local $/; decode_json $_->getline },
3190     };
3191 }
3192
3193 =head2 $c->stack
3194
3195 Returns an arrayref of the internal execution stack (actions that are
3196 currently executing).
3197
3198 =head2 $c->stats
3199
3200 Returns the current timing statistics object. By default Catalyst uses
3201 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3202 L<< stats_class|/"$c->stats_class" >>.
3203
3204 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3205 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3206 profile explicitly, although MyApp.pm still won't profile nor output anything
3207 by itself.
3208
3209 =head2 $c->stats_class
3210
3211 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3212
3213 =head2 $c->use_stats
3214
3215 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3216
3217 Note that this is a static method, not an accessor and should be overridden
3218 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3219
3220 =cut
3221
3222 sub use_stats { 0 }
3223
3224
3225 =head2 $c->write( $data )
3226
3227 Writes $data to the output stream. When using this method directly, you
3228 will need to manually set the C<Content-Length> header to the length of
3229 your output data, if known.
3230
3231 =cut
3232
3233 sub write {
3234     my $c = shift;
3235
3236     # Finalize headers if someone manually writes output (for compat)
3237     $c->finalize_headers;
3238
3239     return $c->response->write( @_ );
3240 }
3241
3242 =head2 version
3243
3244 Returns the Catalyst version number. Mostly useful for "powered by"
3245 messages in template systems.
3246
3247 =cut
3248
3249 sub version { return $Catalyst::VERSION }
3250
3251 =head1 CONFIGURATION
3252
3253 There are a number of 'base' config variables which can be set:
3254
3255 =over
3256
3257 =item *
3258
3259 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3260
3261 =item *
3262
3263 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3264
3265 =item *
3266
3267 C<disable_component_resolution_regex_fallback> - Turns
3268 off the deprecated component resolution functionality so
3269 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3270 are called then regex search will not be attempted on string values and
3271 instead C<undef> will be returned.
3272
3273 =item *
3274
3275 C<home> - The application home directory. In an uninstalled application,
3276 this is the top level application directory. In an installed application,
3277 this will be the directory containing C<< MyApp.pm >>.
3278
3279 =item *
3280
3281 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3282
3283 =item *
3284
3285 C<name> - The name of the application in debug messages and the debug and
3286 welcome screens
3287
3288 =item *
3289
3290 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3291 until it is accessed. This allows you to (for example) check authentication (and reject
3292 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3293
3294 =item *
3295
3296 C<root> - The root directory for templates. Usually this is just a
3297 subdirectory of the home directory, but you can set it to change the
3298 templates to a different directory.
3299
3300 =item *
3301
3302 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3303 namespaces from which components will be loaded (and constructed and stored in
3304 C<< $c->components >>).
3305
3306 =item *
3307
3308 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3309 to be shown in hit debug tables in the test server.
3310
3311 =item *
3312
3313 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3314 variable should be used for determining the request path.
3315
3316 Most web server environments pass the requested path to the application using environment variables,
3317 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3318 exposed as C<< $c->request->base >>) and the request path below that base.
3319
3320 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3321 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3322
3323 =over
3324
3325 =item use_request_uri_for_path => 0
3326
3327 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3328 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3329 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3330 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3331
3332 However this method has the major disadvantage that it is impossible to correctly decode some elements
3333 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3334 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3335 can't distinguish / vs %2F in paths (in addition to other encoded values).
3336
3337 =item use_request_uri_for_path => 1
3338
3339 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3340 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3341 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3342
3343 Given that this method of path resolution is provably more correct, it is recommended that you use
3344 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3345 aware of the implications of not being able to handle encoded URI paths correctly.
3346
3347 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3348 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3349 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3350 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3351 C<< $c->request->base >> will be incorrect.
3352
3353 =back
3354
3355 =item *
3356
3357 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3358
3359 =item *
3360
3361 C<encoding> - See L</ENCODING>
3362
3363 =item *
3364
3365 C<abort_chain_on_error_fix>
3366
3367 When there is an error in an action chain, the default behavior is to continue
3368 processing the remaining actions and then catch the error upon chain end.  This
3369 can lead to running actions when the application is in an unexpected state.  If
3370 you have this issue, setting this config value to true will promptly exit a
3371 chain when there is an error raised in any action (thus terminating the chain
3372 early.)
3373
3374 use like:
3375
3376     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3377
3378 In the future this might become the default behavior.
3379
3380 =item *
3381
3382 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3383
3384 =item *
3385
3386 C<data_handlers> - See L<DATA HANDLERS>.
3387
3388 =back
3389
3390 =head1 INTERNAL ACTIONS
3391
3392 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3393 C<_ACTION>, and C<_END>. These are by default not shown in the private
3394 action table, but you can make them visible with a config parameter.
3395
3396     MyApp->config(show_internal_actions => 1);
3397
3398 =head1 ON-DEMAND PARSER
3399
3400 The request body is usually parsed at the beginning of a request,
3401 but if you want to handle input yourself, you can enable on-demand
3402 parsing with a config parameter.
3403
3404     MyApp->config(parse_on_demand => 1);
3405
3406 =head1 PROXY SUPPORT
3407
3408 Many production servers operate using the common double-server approach,
3409 with a lightweight frontend web server passing requests to a larger
3410 backend server. An application running on the backend server must deal
3411 with two problems: the remote user always appears to be C<127.0.0.1> and
3412 the server's hostname will appear to be C<localhost> regardless of the
3413 virtual host that the user connected through.
3414
3415 Catalyst will automatically detect this situation when you are running
3416 the frontend and backend servers on the same machine. The following
3417 changes are made to the request.
3418
3419     $c->req->address is set to the user's real IP address, as read from
3420     the HTTP X-Forwarded-For header.
3421
3422     The host value for $c->req->base and $c->req->uri is set to the real
3423     host, as read from the HTTP X-Forwarded-Host header.
3424
3425 Additionally, you may be running your backend application on an insecure
3426 connection (port 80) while your frontend proxy is running under SSL.  If there
3427 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3428 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3429 be created properly.
3430
3431 In the case of passing in:
3432
3433     X-Forwarded-Port: 443
3434
3435 All calls to C<uri_for> will result in an https link, as is expected.
3436
3437 Obviously, your web server must support these headers for this to work.
3438
3439 In a more complex server farm environment where you may have your
3440 frontend proxy server(s) on different machines, you will need to set a
3441 configuration option to tell Catalyst to read the proxied data from the
3442 headers.
3443
3444     MyApp->config(using_frontend_proxy => 1);
3445
3446 If you do not wish to use the proxy support at all, you may set:
3447
3448     MyApp->config(ignore_frontend_proxy => 0);
3449
3450 =head2 Note about psgi files
3451
3452 Note that if you supply your own .psgi file, calling
3453 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3454
3455 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3456 in your psgi, for example:
3457
3458     builder {
3459         enable "Plack::Middleware::ReverseProxy";
3460         MyApp->psgi_app
3461     };
3462
3463 This will unconditionally add the ReverseProxy support, or you need to call
3464 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3465 apply the support depending upon your config).
3466
3467 See L<Catalyst::PSGI> for more information.
3468
3469 =head1 THREAD SAFETY
3470
3471 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3472 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3473 believe the Catalyst core to be thread-safe.
3474
3475 If you plan to operate in a threaded environment, remember that all other
3476 modules you are using must also be thread-safe. Some modules, most notably
3477 L<DBD::SQLite>, are not thread-safe.
3478
3479 =head1 DATA HANDLERS
3480
3481 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3482 form parameters and URL search query fields.  However it has become common
3483 for various alternative content types to be PUT or POSTed to your controllers
3484 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3485 XML and other content types when communicating with an application server.  In
3486 order to better support this use case, L<Catalyst> defines a global configuration
3487 option, C<data_handlers>, which lets you associate a content type with a coderef
3488 that parses that content type into something Perl can readily access.
3489
3490     package MyApp::Web;
3491
3492     use Catalyst;
3493     use JSON::Maybe;
3494
3495     __PACKAGE__->config(
3496       data_handlers => {
3497         'application/json' => sub { local $/; decode_json $_->getline },
3498       },
3499       ## Any other configuration.
3500     );
3501
3502     __PACKAGE__->setup;
3503
3504 By default L<Catalyst> comes with a generic JSON data handler similar to the
3505 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3506 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3507 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3508 or dist.ini, cpanfile, etc.)
3509
3510 The C<data_handlers> configuation is a hashref whose keys are HTTP Content-Types
3511 (matched against the incoming request type using a regexp such as to be case
3512 insensitive) and whose values are coderefs that receive a localized version of
3513 C<$_> which is a filehandle object pointing to received body.
3514
3515 This feature is considered an early access release and we reserve the right
3516 to alter the interface in order to provide a performant and secure solution to
3517 alternative request body content.  Your reports welcomed!
3518
3519 =head1 PSGI MIDDLEWARE
3520
3521 You can define middleware, defined as L<Plack::Middleware> or a compatible
3522 interface in configuration.  Your middleware definitions are in the form of an
3523 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3524 with details to follow:
3525
3526     package MyApp::Web;
3527
3528     use Catalyst;
3529     use Plack::Middleware::StackTrace;
3530
3531     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3532
3533     __PACKAGE__->config(
3534       'psgi_middleware', [
3535         'Debug',
3536         '+MyApp::Custom',
3537         $stacktrace_middleware,
3538         'Session' => {store => 'File'},
3539         sub {
3540           my $app = shift;
3541           return sub {
3542             my $env = shift;
3543             $env->{myapp.customkey} = 'helloworld';
3544             $app->($env);
3545           },
3546         },
3547       ],
3548     );
3549
3550     __PACKAGE__->setup;
3551
3552 So the general form is:
3553
3554     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3555
3556 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3557 the order listed (to make it function similarly to L<Plack::Builder>:
3558
3559 =over 4
3560
3561 =item Middleware Object
3562
3563 An already initialized object that conforms to the L<Plack::Middleware>
3564 specification:
3565
3566     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3567
3568     __PACKAGE__->config(
3569       'psgi_middleware', [
3570         $stacktrace_middleware,
3571       ]);
3572
3573
3574 =item coderef
3575
3576 A coderef that is an inlined middleware:
3577
3578     __PACKAGE__->config(
3579       'psgi_middleware', [
3580         sub {
3581           my $app = shift;
3582           return sub {
3583             my $env = shift;
3584             if($env->{PATH_INFO} =~m/forced/) {
3585               Plack::App::File
3586                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3587                 ->call($env);
3588             } else {
3589               return $app->($env);
3590             }
3591          },
3592       },
3593     ]);
3594
3595
3596
3597 =item a scalar
3598
3599 We assume the scalar refers to a namespace after normalizing it using the
3600 following rules:
3601
3602 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3603 is assumed to be 'as is', and we just install and use the middleware.
3604
3605 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3606 (the package name of your Catalyst application subclass), we also assume then
3607 that it is a full namespace, and use it.
3608
3609 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3610 resolve it first by looking for it under your application namespace (for example
3611 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3612 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3613 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3614 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3615 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3616 you find that a good idea.
3617
3618 Examples:
3619
3620     package MyApp::Web;
3621
3622     __PACKAGE__->config(
3623       'psgi_middleware', [
3624         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3625         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3626         '+MyApp::Custom',  ## MyApp::Custom->wrap
3627       ],
3628     );
3629
3630 =item a scalar followed by a hashref
3631
3632 Just like the previous, except the following C<HashRef> is used as arguments
3633 to initialize the middleware object.
3634
3635     __PACKAGE__->config(
3636       'psgi_middleware', [
3637          'Session' => {store => 'File'},
3638     ]);
3639
3640 =back
3641
3642 Please see L<PSGI> for more on middleware.
3643
3644 =head1 ENCODING
3645
3646 On request, decodes all params from encoding into a sequence of
3647 logical characters. On response, encodes body into encoding.
3648
3649 =head2 Methods
3650
3651 =over 4
3652
3653 =item encoding
3654
3655 Returns an instance of an C<Encode> encoding
3656
3657     print $c->encoding->name
3658
3659 =item handle_unicode_encoding_exception ($exception_context)
3660
3661 Method called when decoding process for a request fails.
3662
3663 An C<$exception_context> hashref is provided to allow you to override the
3664 behaviour of your application when given data with incorrect encodings.
3665
3666 The default method throws exceptions in the case of invalid request parameters
3667 (resulting in a 500 error), but ignores errors in upload filenames.
3668
3669 The keys passed in the C<$exception_context> hash are:
3670
3671 =over
3672
3673 =item param_value
3674
3675 The value which was not able to be decoded.
3676
3677 =item error_msg
3678
3679 The exception received from L<Encode>.
3680
3681 =item encoding_step
3682
3683 What type of data was being decoded. Valid values are (currently)
3684 C<params> - for request parameters / arguments / captures
3685 and C<uploads> - for request upload filenames.
3686
3687 =back
3688
3689 =back
3690
3691 =head1 SUPPORT
3692
3693 IRC:
3694
3695     Join #catalyst on irc.perl.org.
3696
3697 Mailing Lists:
3698
3699     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3700     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3701
3702 Web:
3703
3704     http://catalyst.perl.org
3705
3706 Wiki:
3707
3708     http://dev.catalyst.perl.org
3709
3710 =head1 SEE ALSO
3711
3712 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3713
3714 =head2 L<Catalyst::Manual> - The Catalyst Manual
3715
3716 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3717
3718 =head2 L<Catalyst::Engine> - Core engine
3719
3720 =head2 L<Catalyst::Log> - Log class.
3721
3722 =head2 L<Catalyst::Request> - Request object
3723
3724 =head2 L<Catalyst::Response> - Response object
3725
3726 =head2 L<Catalyst::Test> - The test suite.
3727
3728 =head1 PROJECT FOUNDER
3729
3730 sri: Sebastian Riedel <sri@cpan.org>
3731
3732 =head1 CONTRIBUTORS
3733
3734 abw: Andy Wardley
3735
3736 acme: Leon Brocard <leon@astray.com>
3737
3738 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3739
3740 Andrew Bramble
3741
3742 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3743
3744 Andrew Ruthven
3745
3746 andyg: Andy Grundman <andy@hybridized.org>
3747
3748 audreyt: Audrey Tang
3749
3750 bricas: Brian Cassidy <bricas@cpan.org>
3751
3752 Caelum: Rafael Kitover <rkitover@io.com>
3753
3754 chansen: Christian Hansen
3755
3756 chicks: Christopher Hicks
3757
3758 Chisel Wright C<pause@herlpacker.co.uk>
3759
3760 Danijel Milicevic C<me@danijel.de>
3761
3762 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3763
3764 David Naughton, C<naughton@umn.edu>
3765
3766 David E. Wheeler
3767
3768 dhoss: Devin Austin <dhoss@cpan.org>
3769
3770 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3771
3772 Drew Taylor
3773
3774 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3775
3776 esskar: Sascha Kiefer
3777
3778 fireartist: Carl Franks <cfranks@cpan.org>
3779
3780 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3781
3782 gabb: Danijel Milicevic
3783
3784 Gary Ashton Jones
3785
3786 Gavin Henry C<ghenry@perl.me.uk>
3787
3788 Geoff Richards
3789
3790 groditi: Guillermo Roditi <groditi@gmail.com>
3791
3792 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3793
3794 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3795
3796 jcamacho: Juan Camacho
3797
3798 jester: Jesse Sheidlower C<jester@panix.com>
3799
3800 jhannah: Jay Hannah <jay@jays.net>
3801
3802 Jody Belka
3803
3804 Johan Lindstrom
3805
3806 jon: Jon Schutz <jjschutz@cpan.org>
3807
3808 Jonathan Rockway C<< <jrockway@cpan.org> >>
3809
3810 Kieren Diment C<kd@totaldatasolution.com>
3811
3812 konobi: Scott McWhirter <konobi@cpan.org>
3813
3814 marcus: Marcus Ramberg <mramberg@cpan.org>
3815
3816 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3817
3818 mgrimes: Mark Grimes <mgrimes@cpan.org>
3819
3820 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3821
3822 mugwump: Sam Vilain
3823
3824 naughton: David Naughton
3825
3826 ningu: David Kamholz <dkamholz@cpan.org>
3827
3828 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3829
3830 numa: Dan Sully <daniel@cpan.org>
3831
3832 obra: Jesse Vincent
3833
3834 Octavian Rasnita
3835
3836 omega: Andreas Marienborg
3837
3838 Oleg Kostyuk <cub.uanic@gmail.com>
3839
3840 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3841
3842 rafl: Florian Ragwitz <rafl@debian.org>
3843
3844 random: Roland Lammel <lammel@cpan.org>
3845
3846 Robert Sedlacek C<< <rs@474.at> >>
3847
3848 SpiceMan: Marcel Montes
3849
3850 sky: Arthur Bergman
3851
3852 szbalint: Balint Szilakszi <szbalint@cpan.org>
3853
3854 t0m: Tomas Doran <bobtfish@bobtfish.net>
3855
3856 Ulf Edvinsson
3857
3858 Viljo Marrandi C<vilts@yahoo.com>
3859
3860 Will Hawes C<info@whawes.co.uk>
3861
3862 willert: Sebastian Willert <willert@cpan.org>
3863
3864 wreis: Wallace Reis <wreis@cpan.org>
3865
3866 Yuval Kogman, C<nothingmuch@woobling.org>
3867
3868 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3869
3870 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3871
3872 =head1 COPYRIGHT
3873
3874 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3875
3876 =head1 LICENSE
3877
3878 This library is free software. You can redistribute it and/or modify it under
3879 the same terms as Perl itself.
3880
3881 =cut
3882
3883 no Moose;
3884
3885 __PACKAGE__->meta->make_immutable;
3886
3887 1;