lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34 use Try::Tiny;
  35
  36 BEGIN { require 5.008004; }
  37
  38 has stack => (is => 'ro', default => sub { [] });
  39 has stash => (is => 'rw', default => sub { {} });
  40 has state => (is => 'rw', default => 0);
  41 has stats => (is => 'rw');
  42 has action => (is => 'rw');
  43 has counter => (is => 'rw', default => sub { {} });
  44 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  45 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  46 has namespace => (is => 'rw');
  47
  48 sub depth { scalar @{ shift->stack || [] }; }
  49 sub comp { shift->component(@_) }
  50
  51 sub req {
  52     my $self = shift; return $self->request(@_);
  53 }
  54 sub res {
  55     my $self = shift; return $self->response(@_);
  56 }
  57
  58 # For backwards compatibility
  59 sub finalize_output { shift->finalize_body(@_) };
  60
  61 # For statistics
  62 our $COUNT     = 1;
  63 our $START     = time;
  64 our $RECURSION = 1000;
  65 our $DETACH    = Catalyst::Exception::Detach->new;
  66 our $GO        = Catalyst::Exception::Go->new;
  67
  68 #I imagine that very few of these really need to be class variables. if any.
  69 #maybe we should just make them attributes with a default?
  70 __PACKAGE__->mk_classdata($_)
  71   for qw/components arguments dispatcher engine log dispatcher_class
  72   engine_class context_class request_class response_class stats_class
  73   setup_finished psgi_app/;
  74
  75 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  76 __PACKAGE__->engine_class('Catalyst::Engine');
  77 __PACKAGE__->request_class('Catalyst::Request');
  78 __PACKAGE__->response_class('Catalyst::Response');
  79 __PACKAGE__->stats_class('Catalyst::Stats');
  80
  81 # Remember to update this in Catalyst::Runtime as well!
  82
  83 our $VERSION = '5.80024';
  84
  85 sub import {
  86     my ( $class, @arguments ) = @_;
  87
  88     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  89     # callers @ISA.
  90     return unless $class eq 'Catalyst';
  91
  92     my $caller = caller();
  93     return if $caller eq 'main';
  94
  95     my $meta = Moose::Meta::Class->initialize($caller);
  96     unless ( $caller->isa('Catalyst') ) {
  97         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  98         $meta->superclasses(@superclasses);
  99     }
 100     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 101     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 102
 103     unless( $meta->has_method('meta') ){
 104         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 105     }
 106
 107     $caller->arguments( [@arguments] );
 108     $caller->setup_home;
 109 }
 110
 111 sub _application { $_[0] }
 112
 113 =head1 NAME
 114
 115 Catalyst - The Elegant MVC Web Application Framework
 116
 117 =head1 SYNOPSIS
 118
 119 See the L<Catalyst::Manual> distribution for comprehensive
 120 documentation and tutorials.
 121
 122     # Install Catalyst::Devel for helpers and other development tools
 123     # use the helper to create a new application
 124     catalyst.pl MyApp
 125
 126     # add models, views, controllers
 127     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 128     script/myapp_create.pl view MyTemplate TT
 129     script/myapp_create.pl controller Search
 130
 131     # built in testserver -- use -r to restart automatically on changes
 132     # --help to see all available options
 133     script/myapp_server.pl
 134
 135     # command line testing interface
 136     script/myapp_test.pl /yada
 137
 138     ### in lib/MyApp.pm
 139     use Catalyst qw/-Debug/; # include plugins here as well
 140
 141     ### In lib/MyApp/Controller/Root.pm (autocreated)
 142     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 143         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 144         $c->stash->{template} = 'foo.tt'; # set the template
 145         # lookup something from db -- stash vars are passed to TT
 146         $c->stash->{data} =
 147           $c->model('Database::Foo')->search( { country => $args[0] } );
 148         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 149             $c->forward( 'bar' ); # process another action
 150             # do something else after forward returns
 151         }
 152     }
 153
 154     # The foo.tt TT template can use the stash data from the database
 155     [% WHILE (item = data.next) %]
 156         [% item.foo %]
 157     [% END %]
 158
 159     # called for /bar/of/soap, /bar/of/soap/10, etc.
 160     sub bar : Path('/bar/of/soap') { ... }
 161
 162     # called for all actions, from the top-most controller downwards
 163     sub auto : Private {
 164         my ( $self, $c ) = @_;
 165         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 166             $c->res->redirect( '/login' ); # require login
 167             return 0; # abort request and go immediately to end()
 168         }
 169         return 1; # success; carry on to next action
 170     }
 171
 172     # called after all actions are finished
 173     sub end : Private {
 174         my ( $self, $c ) = @_;
 175         if ( scalar @{ $c->error } ) { ... } # handle errors
 176         return if $c->res->body; # already have a response
 177         $c->forward( 'MyApp::View::TT' ); # render template
 178     }
 179
 180     ### in MyApp/Controller/Foo.pm
 181     # called for /foo/bar
 182     sub bar : Local { ... }
 183
 184     # called for /blargle
 185     sub blargle : Global { ... }
 186
 187     # an index action matches /foo, but not /foo/1, etc.
 188     sub index : Private { ... }
 189
 190     ### in MyApp/Controller/Foo/Bar.pm
 191     # called for /foo/bar/baz
 192     sub baz : Local { ... }
 193
 194     # first Root auto is called, then Foo auto, then this
 195     sub auto : Private { ... }
 196
 197     # powerful regular expression paths are also possible
 198     sub details : Regex('^product/(\w+)/details$') {
 199         my ( $self, $c ) = @_;
 200         # extract the (\w+) from the URI
 201         my $product = $c->req->captures->[0];
 202     }
 203
 204 See L<Catalyst::Manual::Intro> for additional information.
 205
 206 =head1 DESCRIPTION
 207
 208 Catalyst is a modern framework for making web applications without the
 209 pain usually associated with this process. This document is a reference
 210 to the main Catalyst application. If you are a new user, we suggest you
 211 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 212
 213 See L<Catalyst::Manual> for more documentation.
 214
 215 Catalyst plugins can be loaded by naming them as arguments to the "use
 216 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 217 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 218 C<My::Module>.
 219
 220     use Catalyst qw/My::Module/;
 221
 222 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 223 fully qualify the name by using a unary plus:
 224
 225     use Catalyst qw/
 226         My::Module
 227         +Fully::Qualified::Plugin::Name
 228     /;
 229
 230 Special flags like C<-Debug> and C<-Engine> can also be specified as
 231 arguments when Catalyst is loaded:
 232
 233     use Catalyst qw/-Debug My::Module/;
 234
 235 The position of plugins and flags in the chain is important, because
 236 they are loaded in the order in which they appear.
 237
 238 The following flags are supported:
 239
 240 =head2 -Debug
 241
 242 Enables debug output. You can also force this setting from the system
 243 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 244 settings override the application, with <MYAPP>_DEBUG having the highest
 245 priority.
 246
 247 This sets the log level to 'debug' and enables full debug output on the
 248 error screen. If you only want the latter, see L<< $c->debug >>.
 249
 250 =head2 -Engine
 251
 252 Forces Catalyst to use a specific engine. Omit the
 253 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 254
 255     use Catalyst qw/-Engine=CGI/;
 256
 257 =head2 -Home
 258
 259 Forces Catalyst to use a specific home directory, e.g.:
 260
 261     use Catalyst qw[-Home=/usr/mst];
 262
 263 This can also be done in the shell environment by setting either the
 264 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 265 is replaced with the uppercased name of your application, any "::" in
 266 the name will be replaced with underscores, e.g. MyApp::Web should use
 267 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 268
 269 If none of these are set, Catalyst will attempt to automatically detect the
 270 home directory. If you are working in a development envirnoment, Catalyst
 271 will try and find the directory containing either Makefile.PL, Build.PL or
 272 dist.ini. If the application has been installed into the system (i.e.
 273 you have done C<make install>), then Catalyst will use the path to your
 274 application module, without the .pm extension (ie, /foo/MyApp if your
 275 application was installed at /foo/MyApp.pm)
 276
 277 =head2 -Log
 278
 279     use Catalyst '-Log=warn,fatal,error';
 280
 281 Specifies a comma-delimited list of log levels.
 282
 283 =head2 -Stats
 284
 285 Enables statistics collection and reporting.
 286
 287    use Catalyst qw/-Stats=1/;
 288
 289 You can also force this setting from the system environment with CATALYST_STATS
 290 or <MYAPP>_STATS. The environment settings override the application, with
 291 <MYAPP>_STATS having the highest priority.
 292
 293 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 294
 295 =head1 METHODS
 296
 297 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 298
 299 =head2 $c->action
 300
 301 Returns a L<Catalyst::Action> object for the current action, which
 302 stringifies to the action name. See L<Catalyst::Action>.
 303
 304 =head2 $c->namespace
 305
 306 Returns the namespace of the current action, i.e., the URI prefix
 307 corresponding to the controller of the current action. For example:
 308
 309     # in Controller::Foo::Bar
 310     $c->namespace; # returns 'foo/bar';
 311
 312 =head2 $c->request
 313
 314 =head2 $c->req
 315
 316 Returns the current L<Catalyst::Request> object, giving access to
 317 information about the current client request (including parameters,
 318 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 319
 320 =head2 REQUEST FLOW HANDLING
 321
 322 =head2 $c->forward( $action [, \@arguments ] )
 323
 324 =head2 $c->forward( $class, $method, [, \@arguments ] )
 325
 326 Forwards processing to another action, by its private name. If you give a
 327 class name but no method, C<process()> is called. You may also optionally
 328 pass arguments in an arrayref. The action will receive the arguments in
 329 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 330 C<< $c->req->args >> will be restored to the previous values.
 331
 332 Any data C<return>ed from the action forwarded to, will be returned by the
 333 call to forward.
 334
 335     my $foodata = $c->forward('/foo');
 336     $c->forward('index');
 337     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 338     $c->forward('View::TT');
 339
 340 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 341 an C<< eval { } >> around the call (actually
 342 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 343 all 'dies' within the called action. If you want C<die> to propagate you
 344 need to do something like:
 345
 346     $c->forward('foo');
 347     die join "\n", @{ $c->error } if @{ $c->error };
 348
 349 Or make sure to always return true values from your actions and write
 350 your code like this:
 351
 352     $c->forward('foo') || return;
 353
 354 Another note is that C<< $c->forward >> always returns a scalar because it
 355 actually returns $c->state which operates in a scalar context.
 356 Thus, something like:
 357
 358     return @array;
 359
 360 in an action that is forwarded to is going to return a scalar,
 361 i.e. how many items are in that array, which is probably not what you want.
 362 If you need to return an array then return a reference to it,
 363 or stash it like so:
 364
 365     $c->stash->{array} = \@array;
 366
 367 and access it from the stash.
 368
 369 =cut
 370
 371 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 372
 373 =head2 $c->detach( $action [, \@arguments ] )
 374
 375 =head2 $c->detach( $class, $method, [, \@arguments ] )
 376
 377 =head2 $c->detach()
 378
 379 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 380 doesn't return to the previous action when processing is finished.
 381
 382 When called with no arguments it escapes the processing chain entirely.
 383
 384 =cut
 385
 386 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 387
 388 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 389
 390 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 391
 392 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 393 but does a full dispatch, instead of just calling the new C<$action> /
 394 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 395 you go to are called, just like a new request.
 396
 397 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 398 This means, for example, that C<< $c->action >> methods such as
 399 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 400 L<reverse|Catalyst::Action/reverse> return information for the visited action
 401 when they are invoked within the visited action.  This is different from the
 402 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 403 continues to use the $c->action object from the caller action even when
 404 invoked from the callee.
 405
 406 C<< $c->stash >> is kept unchanged.
 407
 408 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 409 allows you to "wrap" another action, just as it would have been called by
 410 dispatching from a URL, while the analogous
 411 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 412 transfer control to another action as if it had been reached directly from a URL.
 413
 414 =cut
 415
 416 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 417
 418 =head2 $c->go( $action [, \@captures, \@arguments ] )
 419
 420 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 421
 422 The relationship between C<go> and
 423 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 424 the relationship between
 425 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 426 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 427 C<< $c->go >> will perform a full dispatch on the specified action or method,
 428 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 429 C<go> escapes the processing of the current request chain on completion, and
 430 does not return to its caller.
 431
 432 =cut
 433
 434 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 435
 436 =head2 $c->response
 437
 438 =head2 $c->res
 439
 440 Returns the current L<Catalyst::Response> object, see there for details.
 441
 442 =head2 $c->stash
 443
 444 Returns a hashref to the stash, which may be used to store data and pass
 445 it between components during a request. You can also set hash keys by
 446 passing arguments. The stash is automatically sent to the view. The
 447 stash is cleared at the end of a request; it cannot be used for
 448 persistent storage (for this you must use a session; see
 449 L<Catalyst::Plugin::Session> for a complete system integrated with
 450 Catalyst).
 451
 452     $c->stash->{foo} = $bar;
 453     $c->stash( { moose => 'majestic', qux => 0 } );
 454     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 455
 456     # stash is automatically passed to the view for use in a template
 457     $c->forward( 'MyApp::View::TT' );
 458
 459 =cut
 460
 461 around stash => sub {
 462     my $orig = shift;
 463     my $c = shift;
 464     my $stash = $orig->($c);
 465     if (@_) {
 466         my $new_stash = @_ > 1 ? {@_} : $_[0];
 467         croak('stash takes a hash or hashref') unless ref $new_stash;
 468         foreach my $key ( keys %$new_stash ) {
 469           $stash->{$key} = $new_stash->{$key};
 470         }
 471     }
 472
 473     return $stash;
 474 };
 475
 476
 477 =head2 $c->error
 478
 479 =head2 $c->error($error, ...)
 480
 481 =head2 $c->error($arrayref)
 482
 483 Returns an arrayref containing error messages.  If Catalyst encounters an
 484 error while processing a request, it stores the error in $c->error.  This
 485 method should only be used to store fatal error messages.
 486
 487     my @error = @{ $c->error };
 488
 489 Add a new error.
 490
 491     $c->error('Something bad happened');
 492
 493 =cut
 494
 495 sub error {
 496     my $c = shift;
 497     if ( $_[0] ) {
 498         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 499         croak @$error unless ref $c;
 500         push @{ $c->{error} }, @$error;
 501     }
 502     elsif ( defined $_[0] ) { $c->{error} = undef }
 503     return $c->{error} || [];
 504 }
 505
 506
 507 =head2 $c->state
 508
 509 Contains the return value of the last executed action.
 510 Note that << $c->state >> operates in a scalar context which means that all
 511 values it returns are scalar.
 512
 513 =head2 $c->clear_errors
 514
 515 Clear errors.  You probably don't want to clear the errors unless you are
 516 implementing a custom error screen.
 517
 518 This is equivalent to running
 519
 520     $c->error(0);
 521
 522 =cut
 523
 524 sub clear_errors {
 525     my $c = shift;
 526     $c->error(0);
 527 }
 528
 529 sub _comp_search_prefixes {
 530     my $c = shift;
 531     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 532 }
 533
 534 # search components given a name and some prefixes
 535 sub _comp_names_search_prefixes {
 536     my ( $c, $name, @prefixes ) = @_;
 537     my $appclass = ref $c || $c;
 538     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 539     $filter = qr/$filter/; # Compile regex now rather than once per loop
 540
 541     # map the original component name to the sub part that we will search against
 542     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 543         grep { /$filter/ } keys %{ $c->components };
 544
 545     # undef for a name will return all
 546     return keys %eligible if !defined $name;
 547
 548     my $query  = ref $name ? $name : qr/^$name$/i;
 549     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 550
 551     return @result if @result;
 552
 553     # if we were given a regexp to search against, we're done.
 554     return if ref $name;
 555
 556     # skip regexp fallback if configured
 557     return
 558         if $appclass->config->{disable_component_resolution_regex_fallback};
 559
 560     # regexp fallback
 561     $query  = qr/$name/i;
 562     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 563
 564     # no results? try against full names
 565     if( !@result ) {
 566         @result = grep { m{$query} } keys %eligible;
 567     }
 568
 569     # don't warn if we didn't find any results, it just might not exist
 570     if( @result ) {
 571         # Disgusting hack to work out correct method name
 572         my $warn_for = lc $prefixes[0];
 573         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 574            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 575            "component resolution is unreliable and unsafe.";
 576         my $short = $result[0];
 577         # remove the component namespace prefix
 578         $short =~ s/.*?(Model|Controller|View):://;
 579         my $shortmess = Carp::shortmess('');
 580         if ($shortmess =~ m#Catalyst/Plugin#) {
 581            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 582               "plugin's config";
 583         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 584            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 585               "component's config";
 586         } else {
 587            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 588               "but if you really wanted to search, pass in a regexp as the argument " .
 589               "like so: \$c->${warn_for}(qr/${name}/)";
 590         }
 591         $c->log->warn( "${msg}$shortmess" );
 592     }
 593
 594     return @result;
 595 }
 596
 597 # Find possible names for a prefix
 598 sub _comp_names {
 599     my ( $c, @prefixes ) = @_;
 600     my $appclass = ref $c || $c;
 601
 602     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 603
 604     my @names = map { s{$filter}{}; $_; }
 605         $c->_comp_names_search_prefixes( undef, @prefixes );
 606
 607     return @names;
 608 }
 609
 610 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 611 sub _filter_component {
 612     my ( $c, $comp, @args ) = @_;
 613
 614     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 615         return $comp->ACCEPT_CONTEXT( $c, @args );
 616     }
 617
 618     return $comp;
 619 }
 620
 621 =head2 COMPONENT ACCESSORS
 622
 623 =head2 $c->controller($name)
 624
 625 Gets a L<Catalyst::Controller> instance by name.
 626
 627     $c->controller('Foo')->do_stuff;
 628
 629 If the name is omitted, will return the controller for the dispatched
 630 action.
 631
 632 If you want to search for controllers, pass in a regexp as the argument.
 633
 634     # find all controllers that start with Foo
 635     my @foo_controllers = $c->controller(qr{^Foo});
 636
 637
 638 =cut
 639
 640 sub controller {
 641     my ( $c, $name, @args ) = @_;
 642
 643     my $appclass = ref($c) || $c;
 644     if( $name ) {
 645         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 646             my $comps = $c->components;
 647             my $check = $appclass."::Controller::".$name;
 648             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 649         }
 650         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 651         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 652         return $c->_filter_component( $result[ 0 ], @args );
 653     }
 654
 655     return $c->component( $c->action->class );
 656 }
 657
 658 =head2 $c->model($name)
 659
 660 Gets a L<Catalyst::Model> instance by name.
 661
 662     $c->model('Foo')->do_stuff;
 663
 664 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 665
 666 If the name is omitted, it will look for
 667  - a model object in $c->stash->{current_model_instance}, then
 668  - a model name in $c->stash->{current_model}, then
 669  - a config setting 'default_model', or
 670  - check if there is only one model, and return it if that's the case.
 671
 672 If you want to search for models, pass in a regexp as the argument.
 673
 674     # find all models that start with Foo
 675     my @foo_models = $c->model(qr{^Foo});
 676
 677 =cut
 678
 679 sub model {
 680     my ( $c, $name, @args ) = @_;
 681     my $appclass = ref($c) || $c;
 682     if( $name ) {
 683         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 684             my $comps = $c->components;
 685             my $check = $appclass."::Model::".$name;
 686             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 687         }
 688         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 689         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 690         return $c->_filter_component( $result[ 0 ], @args );
 691     }
 692
 693     if (ref $c) {
 694         return $c->stash->{current_model_instance}
 695           if $c->stash->{current_model_instance};
 696         return $c->model( $c->stash->{current_model} )
 697           if $c->stash->{current_model};
 698     }
 699     return $c->model( $appclass->config->{default_model} )
 700       if $appclass->config->{default_model};
 701
 702     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 703
 704     if( $rest ) {
 705         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 706         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 707         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 708         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 709         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 710     }
 711
 712     return $c->_filter_component( $comp );
 713 }
 714
 715
 716 =head2 $c->view($name)
 717
 718 Gets a L<Catalyst::View> instance by name.
 719
 720     $c->view('Foo')->do_stuff;
 721
 722 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 723
 724 If the name is omitted, it will look for
 725  - a view object in $c->stash->{current_view_instance}, then
 726  - a view name in $c->stash->{current_view}, then
 727  - a config setting 'default_view', or
 728  - check if there is only one view, and return it if that's the case.
 729
 730 If you want to search for views, pass in a regexp as the argument.
 731
 732     # find all views that start with Foo
 733     my @foo_views = $c->view(qr{^Foo});
 734
 735 =cut
 736
 737 sub view {
 738     my ( $c, $name, @args ) = @_;
 739
 740     my $appclass = ref($c) || $c;
 741     if( $name ) {
 742         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 743             my $comps = $c->components;
 744             my $check = $appclass."::View::".$name;
 745             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 746         }
 747         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 748         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 749         return $c->_filter_component( $result[ 0 ], @args );
 750     }
 751
 752     if (ref $c) {
 753         return $c->stash->{current_view_instance}
 754           if $c->stash->{current_view_instance};
 755         return $c->view( $c->stash->{current_view} )
 756           if $c->stash->{current_view};
 757     }
 758     return $c->view( $appclass->config->{default_view} )
 759       if $appclass->config->{default_view};
 760
 761     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 762
 763     if( $rest ) {
 764         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 765         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 766         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 767         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 768         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 769     }
 770
 771     return $c->_filter_component( $comp );
 772 }
 773
 774 =head2 $c->controllers
 775
 776 Returns the available names which can be passed to $c->controller
 777
 778 =cut
 779
 780 sub controllers {
 781     my ( $c ) = @_;
 782     return $c->_comp_names(qw/Controller C/);
 783 }
 784
 785 =head2 $c->models
 786
 787 Returns the available names which can be passed to $c->model
 788
 789 =cut
 790
 791 sub models {
 792     my ( $c ) = @_;
 793     return $c->_comp_names(qw/Model M/);
 794 }
 795
 796
 797 =head2 $c->views
 798
 799 Returns the available names which can be passed to $c->view
 800
 801 =cut
 802
 803 sub views {
 804     my ( $c ) = @_;
 805     return $c->_comp_names(qw/View V/);
 806 }
 807
 808 =head2 $c->comp($name)
 809
 810 =head2 $c->component($name)
 811
 812 Gets a component object by name. This method is not recommended,
 813 unless you want to get a specific component by full
 814 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 815 should be used instead.
 816
 817 If C<$name> is a regexp, a list of components matched against the full
 818 component name will be returned.
 819
 820 If Catalyst can't find a component by name, it will fallback to regex
 821 matching by default. To disable this behaviour set
 822 disable_component_resolution_regex_fallback to a true value.
 823
 824     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 825
 826 =cut
 827
 828 sub component {
 829     my ( $c, $name, @args ) = @_;
 830
 831     if( $name ) {
 832         my $comps = $c->components;
 833
 834         if( !ref $name ) {
 835             # is it the exact name?
 836             return $c->_filter_component( $comps->{ $name }, @args )
 837                        if exists $comps->{ $name };
 838
 839             # perhaps we just omitted "MyApp"?
 840             my $composed = ( ref $c || $c ) . "::${name}";
 841             return $c->_filter_component( $comps->{ $composed }, @args )
 842                        if exists $comps->{ $composed };
 843
 844             # search all of the models, views and controllers
 845             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 846             return $c->_filter_component( $comp, @args ) if $comp;
 847         }
 848
 849         # This is here so $c->comp( '::M::' ) works
 850         my $query = ref $name ? $name : qr{$name}i;
 851
 852         my @result = grep { m{$query} } keys %{ $c->components };
 853         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 854
 855         if( $result[ 0 ] ) {
 856             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 857             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 858             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 859             return $c->_filter_component( $result[ 0 ], @args );
 860         }
 861
 862         # I would expect to return an empty list here, but that breaks back-compat
 863     }
 864
 865     # fallback
 866     return sort keys %{ $c->components };
 867 }
 868
 869 =head2 CLASS DATA AND HELPER CLASSES
 870
 871 =head2 $c->config
 872
 873 Returns or takes a hashref containing the application's configuration.
 874
 875     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 876
 877 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 878 like C<myapp.conf> in your applications home directory. See
 879 L<Catalyst::Plugin::ConfigLoader>.
 880
 881 =head3 Cascading configuration
 882
 883 The config method is present on all Catalyst components, and configuration
 884 will be merged when an application is started. Configuration loaded with
 885 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 886 followed by configuration in your top level C<MyApp> class. These two
 887 configurations are merged, and then configuration data whose hash key matches a
 888 component name is merged with configuration for that component.
 889
 890 The configuration for a component is then passed to the C<new> method when a
 891 component is constructed.
 892
 893 For example:
 894
 895     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 896     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 897
 898 will mean that C<MyApp::Model::Foo> receives the following data when
 899 constructed:
 900
 901     MyApp::Model::Foo->new({
 902         bar => 'baz',
 903         quux => 'frob',
 904         overrides => 'me',
 905     });
 906
 907 =cut
 908
 909 around config => sub {
 910     my $orig = shift;
 911     my $c = shift;
 912
 913     croak('Setting config after setup has been run is not allowed.')
 914         if ( @_ and $c->setup_finished );
 915
 916     $c->$orig(@_);
 917 };
 918
 919 =head2 $c->log
 920
 921 Returns the logging object instance. Unless it is already set, Catalyst
 922 sets this up with a L<Catalyst::Log> object. To use your own log class,
 923 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 924 C<< __PACKAGE__->setup >>.
 925
 926  __PACKAGE__->log( MyLogger->new );
 927  __PACKAGE__->setup;
 928
 929 And later:
 930
 931     $c->log->info( 'Now logging with my own logger!' );
 932
 933 Your log class should implement the methods described in
 934 L<Catalyst::Log>.
 935
 936
 937 =head2 $c->debug
 938
 939 Returns 1 if debug mode is enabled, 0 otherwise.
 940
 941 You can enable debug mode in several ways:
 942
 943 =over
 944
 945 =item By calling myapp_server.pl with the -d flag
 946
 947 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 948
 949 =item The -Debug option in your MyApp.pm
 950
 951 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 952
 953 =back
 954
 955 The first three also set the log level to 'debug'.
 956
 957 Calling C<< $c->debug(1) >> has no effect.
 958
 959 =cut
 960
 961 sub debug { 0 }
 962
 963 =head2 $c->dispatcher
 964
 965 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 966
 967 =head2 $c->engine
 968
 969 Returns the engine instance. See L<Catalyst::Engine>.
 970
 971
 972 =head2 UTILITY METHODS
 973
 974 =head2 $c->path_to(@path)
 975
 976 Merges C<@path> with C<< $c->config->{home} >> and returns a
 977 L<Path::Class::Dir> object. Note you can usually use this object as
 978 a filename, but sometimes you will have to explicitly stringify it
 979 yourself by calling the C<< ->stringify >> method.
 980
 981 For example:
 982
 983     $c->path_to( 'db', 'sqlite.db' );
 984
 985 =cut
 986
 987 sub path_to {
 988     my ( $c, @path ) = @_;
 989     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 990     if ( -d $path ) { return $path }
 991     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 992 }
 993
 994 =head2 $c->plugin( $name, $class, @args )
 995
 996 Helper method for plugins. It creates a class data accessor/mutator and
 997 loads and instantiates the given class.
 998
 999     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1000
1001     $c->prototype->define_javascript_functions;
1002
1003 B<Note:> This method of adding plugins is deprecated. The ability
1004 to add plugins like this B<will be removed> in a Catalyst 5.81.
1005 Please do not use this functionality in new code.
1006
1007 =cut
1008
1009 sub plugin {
1010     my ( $class, $name, $plugin, @args ) = @_;
1011
1012     # See block comment in t/unit_core_plugin.t
1013     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1014
1015     $class->_register_plugin( $plugin, 1 );
1016
1017     eval { $plugin->import };
1018     $class->mk_classdata($name);
1019     my $obj;
1020     eval { $obj = $plugin->new(@args) };
1021
1022     if ($@) {
1023         Catalyst::Exception->throw( message =>
1024               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1025     }
1026
1027     $class->$name($obj);
1028     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1029       if $class->debug;
1030 }
1031
1032 =head2 MyApp->setup
1033
1034 Initializes the dispatcher and engine, loads any plugins, and loads the
1035 model, view, and controller components. You may also specify an array
1036 of plugins to load here, if you choose to not load them in the C<use
1037 Catalyst> line.
1038
1039     MyApp->setup;
1040     MyApp->setup( qw/-Debug/ );
1041
1042 =cut
1043
1044 sub setup {
1045     my ( $class, @arguments ) = @_;
1046     croak('Running setup more than once')
1047         if ( $class->setup_finished );
1048
1049     unless ( $class->isa('Catalyst') ) {
1050
1051         Catalyst::Exception->throw(
1052             message => qq/'$class' does not inherit from Catalyst/ );
1053     }
1054
1055     if ( $class->arguments ) {
1056         @arguments = ( @arguments, @{ $class->arguments } );
1057     }
1058
1059     # Process options
1060     my $flags = {};
1061
1062     foreach (@arguments) {
1063
1064         if (/^-Debug$/) {
1065             $flags->{log} =
1066               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1067         }
1068         elsif (/^-(\w+)=?(.*)$/) {
1069             $flags->{ lc $1 } = $2;
1070         }
1071         else {
1072             push @{ $flags->{plugins} }, $_;
1073         }
1074     }
1075
1076     $class->setup_home( delete $flags->{home} );
1077
1078     $class->setup_log( delete $flags->{log} );
1079     $class->setup_plugins( delete $flags->{plugins} );
1080     $class->setup_dispatcher( delete $flags->{dispatcher} );
1081     $class->setup_engine( delete $flags->{engine} );
1082     $class->setup_stats( delete $flags->{stats} );
1083
1084     for my $flag ( sort keys %{$flags} ) {
1085
1086         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1087             &$code( $class, delete $flags->{$flag} );
1088         }
1089         else {
1090             $class->log->warn(qq/Unknown flag "$flag"/);
1091         }
1092     }
1093
1094     eval { require Catalyst::Devel; };
1095     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1096         $class->log->warn(<<"EOF");
1097 You are running an old script!
1098
1099   Please update by running (this will overwrite existing files):
1100     catalyst.pl -force -scripts $class
1101
1102   or (this will not overwrite existing files):
1103     catalyst.pl -scripts $class
1104
1105 EOF
1106     }
1107
1108     if ( $class->debug ) {
1109         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1110
1111         if (@plugins) {
1112             my $column_width = Catalyst::Utils::term_width() - 6;
1113             my $t = Text::SimpleTable->new($column_width);
1114             $t->row($_) for @plugins;
1115             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1116         }
1117
1118         my $dispatcher = $class->dispatcher;
1119         my $engine     = $class->engine;
1120         my $home       = $class->config->{home};
1121
1122         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1123         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1124
1125         $home
1126           ? ( -d $home )
1127           ? $class->log->debug(qq/Found home "$home"/)
1128           : $class->log->debug(qq/Home "$home" doesn't exist/)
1129           : $class->log->debug(q/Couldn't find home/);
1130     }
1131
1132     # Call plugins setup, this is stupid and evil.
1133     # Also screws C3 badly on 5.10, hack to avoid.
1134     {
1135         no warnings qw/redefine/;
1136         local *setup = sub { };
1137         $class->setup unless $Catalyst::__AM_RESTARTING;
1138     }
1139
1140     # Initialize our data structure
1141     $class->components( {} );
1142
1143     $class->setup_components;
1144
1145     if ( $class->debug ) {
1146         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1147         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1148         for my $comp ( sort keys %{ $class->components } ) {
1149             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1150             $t->row( $comp, $type );
1151         }
1152         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1153           if ( keys %{ $class->components } );
1154     }
1155
1156     # Add our self to components, since we are also a component
1157     if( $class->isa('Catalyst::Controller') ){
1158       $class->components->{$class} = $class;
1159     }
1160
1161     $class->setup_actions;
1162
1163     if ( $class->debug ) {
1164         my $name = $class->config->{name} || 'Application';
1165         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1166     }
1167
1168     # Make sure that the application class becomes immutable at this point,
1169     B::Hooks::EndOfScope::on_scope_end {
1170         return if $@;
1171         my $meta = Class::MOP::get_metaclass_by_name($class);
1172         if (
1173             $meta->is_immutable
1174             && ! { $meta->immutable_options }->{replace_constructor}
1175             && (
1176                    $class->isa('Class::Accessor::Fast')
1177                 || $class->isa('Class::Accessor')
1178             )
1179         ) {
1180             warn "You made your application class ($class) immutable, "
1181                 . "but did not inline the\nconstructor. "
1182                 . "This will break catalyst, as your app \@ISA "
1183                 . "Class::Accessor(::Fast)?\nPlease pass "
1184                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1185         }
1186         $meta->make_immutable(
1187             replace_constructor => 1,
1188         ) unless $meta->is_immutable;
1189     };
1190
1191     if ($class->config->{case_sensitive}) {
1192         $class->log->warn($class . "->config->{case_sensitive} is set.");
1193         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1194     }
1195
1196     $class->setup_finalize;
1197     # Should be the last thing we do so that user things hooking
1198     # setup_finalize can log..
1199     $class->log->_flush() if $class->log->can('_flush');
1200     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1201 }
1202
1203 =head2 $app->setup_finalize
1204
1205 A hook to attach modifiers to. This method does not do anything except set the
1206 C<setup_finished> accessor.
1207
1208 Applying method modifiers to the C<setup> method doesn't work, because of quirky thingsdone for plugin setup.
1209
1210 Example:
1211
1212     after setup_finalize => sub {
1213         my $app = shift;
1214
1215         ## do stuff here..
1216     };
1217
1218 =cut
1219
1220 sub setup_finalize {
1221     my ($class) = @_;
1222     $class->setup_finished(1);
1223 }
1224
1225 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1226
1227 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1228
1229 Constructs an absolute L<URI> object based on the application root, the
1230 provided path, and the additional arguments and query parameters provided.
1231 When used as a string, provides a textual URI.
1232
1233 If no arguments are provided, the URI for the current action is returned.
1234 To return the current action and also provide @args, use
1235 C<< $c->uri_for( $c->action, @args ) >>.
1236
1237 If the first argument is a string, it is taken as a public URI path relative
1238 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1239 relative to the application root (if it does). It is then merged with
1240 C<< $c->request->base >>; any C<@args> are appended as additional path
1241 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1242
1243 If the first argument is a L<Catalyst::Action> it represents an action which
1244 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1245 optional C<\@captures> argument (an arrayref) allows passing the captured
1246 variables that are needed to fill in the paths of Chained and Regex actions;
1247 once the path is resolved, C<uri_for> continues as though a path was
1248 provided, appending any arguments or parameters and creating an absolute
1249 URI.
1250
1251 The captures for the current request can be found in
1252 C<< $c->request->captures >>, and actions can be resolved using
1253 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1254 path, use C<< $c->uri_for_action >> instead.
1255
1256   # Equivalent to $c->req->uri
1257   $c->uri_for($c->action, $c->req->captures,
1258       @{ $c->req->args }, $c->req->params);
1259
1260   # For the Foo action in the Bar controller
1261   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1262
1263   # Path to a static resource
1264   $c->uri_for('/static/images/logo.png');
1265
1266 =cut
1267
1268 sub uri_for {
1269     my ( $c, $path, @args ) = @_;
1270
1271     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1272         $path = $path->path_prefix;
1273         $path =~ s{/+\z}{};
1274         $path .= '/';
1275     }
1276
1277     undef($path) if (defined $path && $path eq '');
1278
1279     my $params =
1280       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1281
1282     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1283     foreach my $arg (@args) {
1284         utf8::encode($arg) if utf8::is_utf8($arg);
1285         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1286     }
1287
1288     if ( blessed($path) ) { # action object
1289         s|/|%2F|g for @args;
1290         my $captures = [ map { s|/|%2F|g; $_; }
1291                         ( scalar @args && ref $args[0] eq 'ARRAY'
1292                          ? @{ shift(@args) }
1293                          : ()) ];
1294
1295         foreach my $capture (@$captures) {
1296             utf8::encode($capture) if utf8::is_utf8($capture);
1297             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1298         }
1299
1300         my $action = $path;
1301         $path = $c->dispatcher->uri_for_action($action, $captures);
1302         if (not defined $path) {
1303             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1304                 if $c->debug;
1305             return undef;
1306         }
1307         $path = '/' if $path eq '';
1308     }
1309
1310     unshift(@args, $path);
1311
1312     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1313         my $namespace = $c->namespace;
1314         if (defined $path) { # cheesy hack to handle path '../foo'
1315            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1316         }
1317         unshift(@args, $namespace || '');
1318     }
1319
1320     # join args with '/', or a blank string
1321     my $args = join('/', grep { defined($_) } @args);
1322     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1323     $args =~ s!^/+!!;
1324     my $base = $c->req->base;
1325     my $class = ref($base);
1326     $base =~ s{(?<!/)$}{/};
1327
1328     my $query = '';
1329
1330     if (my @keys = keys %$params) {
1331       # somewhat lifted from URI::_query's query_form
1332       $query = '?'.join('&', map {
1333           my $val = $params->{$_};
1334           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1335           s/ /+/g;
1336           my $key = $_;
1337           $val = '' unless defined $val;
1338           (map {
1339               my $param = "$_";
1340               utf8::encode( $param ) if utf8::is_utf8($param);
1341               # using the URI::Escape pattern here so utf8 chars survive
1342               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1343               $param =~ s/ /+/g;
1344               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1345       } @keys);
1346     }
1347
1348     my $res = bless(\"${base}${args}${query}", $class);
1349     $res;
1350 }
1351
1352 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1353
1354 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1355
1356 =over
1357
1358 =item $path
1359
1360 A private path to the Catalyst action you want to create a URI for.
1361
1362 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1363 >> and passing the resulting C<$action> and the remaining arguments to C<<
1364 $c->uri_for >>.
1365
1366 You can also pass in a Catalyst::Action object, in which case it is passed to
1367 C<< $c->uri_for >>.
1368
1369 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1370
1371 For example, if the action looks like:
1372
1373  package MyApp::Controller::Users;
1374
1375  sub lst : Path('the-list') {}
1376
1377 You can use:
1378
1379  $c->uri_for_action('/users/lst')
1380
1381 and it will create the URI /users/the-list.
1382
1383 =back
1384
1385 =cut
1386
1387 sub uri_for_action {
1388     my ( $c, $path, @args ) = @_;
1389     my $action = blessed($path)
1390       ? $path
1391       : $c->dispatcher->get_action_by_path($path);
1392     unless (defined $action) {
1393       croak "Can't find action for path '$path'";
1394     }
1395     return $c->uri_for( $action, @args );
1396 }
1397
1398 =head2 $c->welcome_message
1399
1400 Returns the Catalyst welcome HTML page.
1401
1402 =cut
1403
1404 sub welcome_message {
1405     my $c      = shift;
1406     my $name   = $c->config->{name};
1407     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1408     my $prefix = Catalyst::Utils::appprefix( ref $c );
1409     $c->response->content_type('text/html; charset=utf-8');
1410     return <<"EOF";
1411 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1412     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1413 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1414     <head>
1415     <meta http-equiv="Content-Language" content="en" />
1416     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1417         <title>$name on Catalyst $VERSION</title>
1418         <style type="text/css">
1419             body {
1420                 color: #000;
1421                 background-color: #eee;
1422             }
1423             div#content {
1424                 width: 640px;
1425                 margin-left: auto;
1426                 margin-right: auto;
1427                 margin-top: 10px;
1428                 margin-bottom: 10px;
1429                 text-align: left;
1430                 background-color: #ccc;
1431                 border: 1px solid #aaa;
1432             }
1433             p, h1, h2 {
1434                 margin-left: 20px;
1435                 margin-right: 20px;
1436                 font-family: verdana, tahoma, sans-serif;
1437             }
1438             a {
1439                 font-family: verdana, tahoma, sans-serif;
1440             }
1441             :link, :visited {
1442                     text-decoration: none;
1443                     color: #b00;
1444                     border-bottom: 1px dotted #bbb;
1445             }
1446             :link:hover, :visited:hover {
1447                     color: #555;
1448             }
1449             div#topbar {
1450                 margin: 0px;
1451             }
1452             pre {
1453                 margin: 10px;
1454                 padding: 8px;
1455             }
1456             div#answers {
1457                 padding: 8px;
1458                 margin: 10px;
1459                 background-color: #fff;
1460                 border: 1px solid #aaa;
1461             }
1462             h1 {
1463                 font-size: 0.9em;
1464                 font-weight: normal;
1465                 text-align: center;
1466             }
1467             h2 {
1468                 font-size: 1.0em;
1469             }
1470             p {
1471                 font-size: 0.9em;
1472             }
1473             p img {
1474                 float: right;
1475                 margin-left: 10px;
1476             }
1477             span#appname {
1478                 font-weight: bold;
1479                 font-size: 1.6em;
1480             }
1481         </style>
1482     </head>
1483     <body>
1484         <div id="content">
1485             <div id="topbar">
1486                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1487                     $VERSION</h1>
1488              </div>
1489              <div id="answers">
1490                  <p>
1491                  <img src="$logo" alt="Catalyst Logo" />
1492                  </p>
1493                  <p>Welcome to the  world of Catalyst.
1494                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1495                     framework will make web development something you had
1496                     never expected it to be: Fun, rewarding, and quick.</p>
1497                  <h2>What to do now?</h2>
1498                  <p>That really depends  on what <b>you</b> want to do.
1499                     We do, however, provide you with a few starting points.</p>
1500                  <p>If you want to jump right into web development with Catalyst
1501                     you might want to start with a tutorial.</p>
1502 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1503 </pre>
1504 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1505 <pre>
1506 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1507 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1508 </code></pre>
1509                  <h2>What to do next?</h2>
1510                  <p>Next it's time to write an actual application. Use the
1511                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1512                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1513                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1514                     they can save you a lot of work.</p>
1515                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1516                     <p>Also, be sure to check out the vast and growing
1517                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1518                     you are likely to find what you need there.
1519                     </p>
1520
1521                  <h2>Need help?</h2>
1522                  <p>Catalyst has a very active community. Here are the main places to
1523                     get in touch with us.</p>
1524                  <ul>
1525                      <li>
1526                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1527                      </li>
1528                      <li>
1529                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1530                      </li>
1531                      <li>
1532                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1533                      </li>
1534                  </ul>
1535                  <h2>In conclusion</h2>
1536                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1537                     as we enjoyed making it. Please contact us if you have ideas
1538                     for improvement or other feedback.</p>
1539              </div>
1540          </div>
1541     </body>
1542 </html>
1543 EOF
1544 }
1545
1546 =head1 INTERNAL METHODS
1547
1548 These methods are not meant to be used by end users.
1549
1550 =head2 $c->components
1551
1552 Returns a hash of components.
1553
1554 =head2 $c->context_class
1555
1556 Returns or sets the context class.
1557
1558 =head2 $c->counter
1559
1560 Returns a hashref containing coderefs and execution counts (needed for
1561 deep recursion detection).
1562
1563 =head2 $c->depth
1564
1565 Returns the number of actions on the current internal execution stack.
1566
1567 =head2 $c->dispatch
1568
1569 Dispatches a request to actions.
1570
1571 =cut
1572
1573 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1574
1575 =head2 $c->dispatcher_class
1576
1577 Returns or sets the dispatcher class.
1578
1579 =head2 $c->dump_these
1580
1581 Returns a list of 2-element array references (name, structure) pairs
1582 that will be dumped on the error page in debug mode.
1583
1584 =cut
1585
1586 sub dump_these {
1587     my $c = shift;
1588     [ Request => $c->req ],
1589     [ Response => $c->res ],
1590     [ Stash => $c->stash ],
1591     [ Config => $c->config ];
1592 }
1593
1594 =head2 $c->engine_class
1595
1596 Returns or sets the engine class.
1597
1598 =head2 $c->execute( $class, $coderef )
1599
1600 Execute a coderef in given class and catch exceptions. Errors are available
1601 via $c->error.
1602
1603 =cut
1604
1605 sub execute {
1606     my ( $c, $class, $code ) = @_;
1607     $class = $c->component($class) || $class;
1608     $c->state(0);
1609
1610     if ( $c->depth >= $RECURSION ) {
1611         my $action = $code->reverse();
1612         $action = "/$action" unless $action =~ /->/;
1613         my $error = qq/Deep recursion detected calling "${action}"/;
1614         $c->log->error($error);
1615         $c->error($error);
1616         $c->state(0);
1617         return $c->state;
1618     }
1619
1620     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1621
1622     push( @{ $c->stack }, $code );
1623
1624     no warnings 'recursion';
1625     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1626
1627     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1628
1629     my $last = pop( @{ $c->stack } );
1630
1631     if ( my $error = $@ ) {
1632         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1633             $error->rethrow if $c->depth > 1;
1634         }
1635         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1636             $error->rethrow if $c->depth > 0;
1637         }
1638         else {
1639             unless ( ref $error ) {
1640                 no warnings 'uninitialized';
1641                 chomp $error;
1642                 my $class = $last->class;
1643                 my $name  = $last->name;
1644                 $error = qq/Caught exception in $class->$name "$error"/;
1645             }
1646             $c->error($error);
1647             $c->state(0);
1648         }
1649     }
1650     return $c->state;
1651 }
1652
1653 sub _stats_start_execute {
1654     my ( $c, $code ) = @_;
1655     my $appclass = ref($c) || $c;
1656     return if ( ( $code->name =~ /^_.*/ )
1657         && ( !$appclass->config->{show_internal_actions} ) );
1658
1659     my $action_name = $code->reverse();
1660     $c->counter->{$action_name}++;
1661
1662     my $action = $action_name;
1663     $action = "/$action" unless $action =~ /->/;
1664
1665     # determine if the call was the result of a forward
1666     # this is done by walking up the call stack and looking for a calling
1667     # sub of Catalyst::forward before the eval
1668     my $callsub = q{};
1669     for my $index ( 2 .. 11 ) {
1670         last
1671         if ( ( caller($index) )[0] eq 'Catalyst'
1672             && ( caller($index) )[3] eq '(eval)' );
1673
1674         if ( ( caller($index) )[3] =~ /forward$/ ) {
1675             $callsub = ( caller($index) )[3];
1676             $action  = "-> $action";
1677             last;
1678         }
1679     }
1680
1681     my $uid = $action_name . $c->counter->{$action_name};
1682
1683     # is this a root-level call or a forwarded call?
1684     if ( $callsub =~ /forward$/ ) {
1685         my $parent = $c->stack->[-1];
1686
1687         # forward, locate the caller
1688         if ( exists $c->counter->{"$parent"} ) {
1689             $c->stats->profile(
1690                 begin  => $action,
1691                 parent => "$parent" . $c->counter->{"$parent"},
1692                 uid    => $uid,
1693             );
1694         }
1695         else {
1696
1697             # forward with no caller may come from a plugin
1698             $c->stats->profile(
1699                 begin => $action,
1700                 uid   => $uid,
1701             );
1702         }
1703     }
1704     else {
1705
1706         # root-level call
1707         $c->stats->profile(
1708             begin => $action,
1709             uid   => $uid,
1710         );
1711     }
1712     return $action;
1713
1714 }
1715
1716 sub _stats_finish_execute {
1717     my ( $c, $info ) = @_;
1718     $c->stats->profile( end => $info );
1719 }
1720
1721 =head2 $c->finalize
1722
1723 Finalizes the request.
1724
1725 =cut
1726
1727 sub finalize {
1728     my $c = shift;
1729
1730     for my $error ( @{ $c->error } ) {
1731         $c->log->error($error);
1732     }
1733
1734     # Allow engine to handle finalize flow (for POE)
1735     my $engine = $c->engine;
1736     if ( my $code = $engine->can('finalize') ) {
1737         $engine->$code($c);
1738     }
1739     else {
1740
1741         $c->finalize_uploads;
1742
1743         # Error
1744         if ( $#{ $c->error } >= 0 ) {
1745             $c->finalize_error;
1746         }
1747
1748         $c->finalize_headers;
1749
1750         # HEAD request
1751         if ( $c->request->method eq 'HEAD' ) {
1752             $c->response->body('');
1753         }
1754
1755         $c->finalize_body;
1756     }
1757
1758     $c->log_response;
1759
1760     if ($c->use_stats) {
1761         my $elapsed = sprintf '%f', $c->stats->elapsed;
1762         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1763         $c->log->info(
1764             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1765     }
1766
1767     return $c->response->status;
1768 }
1769
1770 =head2 $c->finalize_body
1771
1772 Finalizes body.
1773
1774 =cut
1775
1776 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1777
1778 =head2 $c->finalize_cookies
1779
1780 Finalizes cookies.
1781
1782 =cut
1783
1784 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1785
1786 =head2 $c->finalize_error
1787
1788 Finalizes error.
1789
1790 =cut
1791
1792 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1793
1794 =head2 $c->finalize_headers
1795
1796 Finalizes headers.
1797
1798 =cut
1799
1800 sub finalize_headers {
1801     my $c = shift;
1802
1803     my $response = $c->response; #accessor calls can add up?
1804
1805     # Check if we already finalized headers
1806     return if $response->finalized_headers;
1807
1808     # Handle redirects
1809     if ( my $location = $response->redirect ) {
1810         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1811         $response->header( Location => $location );
1812
1813         if ( !$response->has_body ) {
1814             # Add a default body if none is already present
1815             $response->body(
1816                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1817             );
1818         }
1819     }
1820
1821     # Content-Length
1822     if ( $response->body && !$response->content_length ) {
1823
1824         # get the length from a filehandle
1825         if ( blessed( $response->body ) && $response->body->can('read') )
1826         {
1827             my $stat = stat $response->body;
1828             if ( $stat && $stat->size > 0 ) {
1829                 $response->content_length( $stat->size );
1830             }
1831             else {
1832                 $c->log->warn('Serving filehandle without a content-length');
1833             }
1834         }
1835         else {
1836             # everything should be bytes at this point, but just in case
1837             $response->content_length( length( $response->body ) );
1838         }
1839     }
1840
1841     # Errors
1842     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1843         $response->headers->remove_header("Content-Length");
1844         $response->body('');
1845     }
1846
1847     $c->finalize_cookies;
1848
1849     $c->engine->finalize_headers( $c, @_ );
1850
1851     # Done
1852     $response->finalized_headers(1);
1853 }
1854
1855 =head2 $c->finalize_output
1856
1857 An alias for finalize_body.
1858
1859 =head2 $c->finalize_read
1860
1861 Finalizes the input after reading is complete.
1862
1863 =cut
1864
1865 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1866
1867 =head2 $c->finalize_uploads
1868
1869 Finalizes uploads. Cleans up any temporary files.
1870
1871 =cut
1872
1873 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1874
1875 =head2 $c->get_action( $action, $namespace )
1876
1877 Gets an action in a given namespace.
1878
1879 =cut
1880
1881 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1882
1883 =head2 $c->get_actions( $action, $namespace )
1884
1885 Gets all actions of a given name in a namespace and all parent
1886 namespaces.
1887
1888 =cut
1889
1890 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1891
1892 =head2 $app->handle_request( @arguments )
1893
1894 Called to handle each HTTP request.
1895
1896 =cut
1897
1898 sub handle_request {
1899     my ( $class, @arguments ) = @_;
1900
1901     # Always expect worst case!
1902     my $status = -1;
1903     try {
1904         if ($class->debug) {
1905             my $secs = time - $START || 1;
1906             my $av = sprintf '%.3f', $COUNT / $secs;
1907             my $time = localtime time;
1908             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1909         }
1910
1911         my $c = $class->prepare(@arguments);
1912         $c->dispatch;
1913         $status = $c->finalize;
1914     }
1915     catch {
1916         chomp(my $error = $_);
1917         $class->log->error(qq/Caught exception in engine "$error"/);
1918     };
1919
1920     $COUNT++;
1921
1922     if(my $coderef = $class->log->can('_flush')){
1923         $class->log->$coderef();
1924     }
1925     return $status;
1926 }
1927
1928 =head2 $c->prepare( @arguments )
1929
1930 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1931 etc.).
1932
1933 =cut
1934
1935 sub prepare {
1936     my ( $class, @arguments ) = @_;
1937
1938     # XXX
1939     # After the app/ctxt split, this should become an attribute based on something passed
1940     # into the application.
1941     $class->context_class( ref $class || $class ) unless $class->context_class;
1942
1943     my $c = $class->context_class->new({});
1944
1945     # For on-demand data
1946     $c->request->_context($c);
1947     $c->response->_context($c);
1948
1949     #surely this is not the most efficient way to do things...
1950     $c->stats($class->stats_class->new)->enable($c->use_stats);
1951     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1952         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1953     }
1954
1955     try {
1956         # Allow engine to direct the prepare flow (for POE)
1957         if ( my $prepare = $c->engine->can('prepare') ) {
1958             $c->engine->$prepare( $c, @arguments );
1959         }
1960         else {
1961             $c->prepare_request(@arguments);
1962             $c->prepare_connection;
1963             $c->prepare_query_parameters;
1964             $c->prepare_headers;
1965             $c->prepare_cookies;
1966             $c->prepare_path;
1967
1968             # Prepare the body for reading, either by prepare_body
1969             # or the user, if they are using $c->read
1970             $c->prepare_read;
1971
1972             # Parse the body unless the user wants it on-demand
1973             unless ( ref($c)->config->{parse_on_demand} ) {
1974                 $c->prepare_body;
1975             }
1976         }
1977     }
1978     # VERY ugly and probably shouldn't rely on ->finalize actually working
1979     catch {
1980         # failed prepare is always due to an invalid request, right?
1981         $c->response->status(400);
1982         $c->response->content_type('text/plain');
1983         $c->response->body('Bad Request');
1984         $c->finalize;
1985         die $_;
1986     };
1987
1988     my $method  = $c->req->method  || '';
1989     my $path    = $c->req->path;
1990     $path       = '/' unless length $path;
1991     my $address = $c->req->address || '';
1992
1993     $c->log_request;
1994
1995     $c->prepare_action;
1996
1997     return $c;
1998 }
1999
2000 =head2 $c->prepare_action
2001
2002 Prepares action. See L<Catalyst::Dispatcher>.
2003
2004 =cut
2005
2006 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2007
2008 =head2 $c->prepare_body
2009
2010 Prepares message body.
2011
2012 =cut
2013
2014 sub prepare_body {
2015     my $c = shift;
2016
2017     return if $c->request->_has_body;
2018
2019     # Initialize on-demand data
2020     $c->engine->prepare_body( $c, @_ );
2021     $c->prepare_parameters;
2022     $c->prepare_uploads;
2023 }
2024
2025 =head2 $c->prepare_body_chunk( $chunk )
2026
2027 Prepares a chunk of data before sending it to L<HTTP::Body>.
2028
2029 See L<Catalyst::Engine>.
2030
2031 =cut
2032
2033 sub prepare_body_chunk {
2034     my $c = shift;
2035     $c->engine->prepare_body_chunk( $c, @_ );
2036 }
2037
2038 =head2 $c->prepare_body_parameters
2039
2040 Prepares body parameters.
2041
2042 =cut
2043
2044 sub prepare_body_parameters {
2045     my $c = shift;
2046     $c->engine->prepare_body_parameters( $c, @_ );
2047 }
2048
2049 =head2 $c->prepare_connection
2050
2051 Prepares connection.
2052
2053 =cut
2054
2055 sub prepare_connection {
2056     my $c = shift;
2057     $c->engine->prepare_connection( $c, @_ );
2058 }
2059
2060 =head2 $c->prepare_cookies
2061
2062 Prepares cookies.
2063
2064 =cut
2065
2066 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2067
2068 =head2 $c->prepare_headers
2069
2070 Prepares headers.
2071
2072 =cut
2073
2074 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2075
2076 =head2 $c->prepare_parameters
2077
2078 Prepares parameters.
2079
2080 =cut
2081
2082 sub prepare_parameters {
2083     my $c = shift;
2084     $c->prepare_body_parameters;
2085     $c->engine->prepare_parameters( $c, @_ );
2086 }
2087
2088 =head2 $c->prepare_path
2089
2090 Prepares path and base.
2091
2092 =cut
2093
2094 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2095
2096 =head2 $c->prepare_query_parameters
2097
2098 Prepares query parameters.
2099
2100 =cut
2101
2102 sub prepare_query_parameters {
2103     my $c = shift;
2104
2105     $c->engine->prepare_query_parameters( $c, @_ );
2106 }
2107
2108 =head2 $c->log_request
2109
2110 Writes information about the request to the debug logs.  This includes:
2111
2112 =over 4
2113
2114 =item * Request method, path, and remote IP address
2115
2116 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2117
2118 =item * Request parameters
2119
2120 =item * File uploads
2121
2122 =back
2123
2124 =cut
2125
2126 sub log_request {
2127     my $c = shift;
2128
2129     return unless $c->debug;
2130
2131     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2132     my $request = $dump->[1];
2133
2134     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2135     $method ||= '';
2136     $path = '/' unless length $path;
2137     $address ||= '';
2138     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2139
2140     $c->log_request_headers($request->headers);
2141
2142     if ( my $keywords = $request->query_keywords ) {
2143         $c->log->debug("Query keywords are: $keywords");
2144     }
2145
2146     $c->log_request_parameters( query => $request->query_parameters, body => $request->body_parameters );
2147
2148     $c->log_request_uploads($request);
2149 }
2150
2151 =head2 $c->log_response
2152
2153 Writes information about the response to the debug logs by calling
2154 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2155
2156 =cut
2157
2158 sub log_response {
2159     my $c = shift;
2160
2161     return unless $c->debug;
2162
2163     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2164     my $response = $dump->[1];
2165
2166     $c->log_response_status_line($response);
2167     $c->log_response_headers($response->headers);
2168 }
2169
2170 =head2 $c->log_response_status_line($response)
2171
2172 Writes one line of information about the response to the debug logs.  This includes:
2173
2174 =over 4
2175
2176 =item * Response status code
2177
2178 =item * Content-Type header (if present)
2179
2180 =item * Content-Length header (if present)
2181
2182 =back
2183
2184 =cut
2185
2186 sub log_response_status_line {
2187     my ($c, $response) = @_;
2188
2189     $c->log->debug(
2190         sprintf(
2191             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2192             $response->status                            || 'unknown',
2193             $response->headers->header('Content-Type')   || 'unknown',
2194             $response->headers->header('Content-Length') || 'unknown'
2195         )
2196     );
2197 }
2198
2199 =head2 $c->log_response_headers($headers);
2200
2201 Hook method which can be wrapped by plugins to log the responseheaders.
2202 No-op in the default implementation.
2203
2204 =cut
2205
2206 sub log_response_headers {}
2207
2208 =head2 $c->log_request_parameters( query => {}, body => {} )
2209
2210 Logs request parameters to debug logs
2211
2212 =cut
2213
2214 sub log_request_parameters {
2215     my $c          = shift;
2216     my %all_params = @_;
2217
2218     return unless $c->debug;
2219
2220     my $column_width = Catalyst::Utils::term_width() - 44;
2221     foreach my $type (qw(query body)) {
2222         my $params = $all_params{$type};
2223         next if ! keys %$params;
2224         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2225         for my $key ( sort keys %$params ) {
2226             my $param = $params->{$key};
2227             my $value = defined($param) ? $param : '';
2228             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2229         }
2230         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2231     }
2232 }
2233
2234 =head2 $c->log_request_uploads
2235
2236 Logs file uploads included in the request to the debug logs.
2237 The parameter name, filename, file type, and file size are all included in
2238 the debug logs.
2239
2240 =cut
2241
2242 sub log_request_uploads {
2243     my $c = shift;
2244     my $request = shift;
2245     return unless $c->debug;
2246     my $uploads = $request->uploads;
2247     if ( keys %$uploads ) {
2248         my $t = Text::SimpleTable->new(
2249             [ 12, 'Parameter' ],
2250             [ 26, 'Filename' ],
2251             [ 18, 'Type' ],
2252             [ 9,  'Size' ]
2253         );
2254         for my $key ( sort keys %$uploads ) {
2255             my $upload = $uploads->{$key};
2256             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2257                 $t->row( $key, $u->filename, $u->type, $u->size );
2258             }
2259         }
2260         $c->log->debug( "File Uploads are:\n" . $t->draw );
2261     }
2262 }
2263
2264 =head2 $c->log_request_headers($headers);
2265
2266 Hook method which can be wrapped by plugins to log the request headers.
2267 No-op in the default implementation.
2268
2269 =cut
2270
2271 sub log_request_headers {}
2272
2273 =head2 $c->log_headers($type => $headers)
2274
2275 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2276
2277 =cut
2278
2279 sub log_headers {
2280     my $c       = shift;
2281     my $type    = shift;
2282     my $headers = shift;    # an HTTP::Headers instance
2283
2284     return unless $c->debug;
2285
2286     my $column_width = Catalyst::Utils::term_width() - 28;
2287     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2288     $headers->scan(
2289         sub {
2290             my ( $name, $value ) = @_;
2291             $t->row( $name, $value );
2292         }
2293     );
2294     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2295 }
2296
2297
2298 =head2 $c->prepare_read
2299
2300 Prepares the input for reading.
2301
2302 =cut
2303
2304 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2305
2306 =head2 $c->prepare_request
2307
2308 Prepares the engine request.
2309
2310 =cut
2311
2312 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2313
2314 =head2 $c->prepare_uploads
2315
2316 Prepares uploads.
2317
2318 =cut
2319
2320 sub prepare_uploads {
2321     my $c = shift;
2322
2323     $c->engine->prepare_uploads( $c, @_ );
2324 }
2325
2326 =head2 $c->prepare_write
2327
2328 Prepares the output for writing.
2329
2330 =cut
2331
2332 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2333
2334 =head2 $c->request_class
2335
2336 Returns or sets the request class.
2337
2338 =head2 $c->response_class
2339
2340 Returns or sets the response class.
2341
2342 =head2 $c->read( [$maxlength] )
2343
2344 Reads a chunk of data from the request body. This method is designed to
2345 be used in a while loop, reading C<$maxlength> bytes on every call.
2346 C<$maxlength> defaults to the size of the request if not specified.
2347
2348 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2349 directly.
2350
2351 Warning: If you use read(), Catalyst will not process the body,
2352 so you will not be able to access POST parameters or file uploads via
2353 $c->request.  You must handle all body parsing yourself.
2354
2355 =cut
2356
2357 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2358
2359 =head2 $c->run
2360
2361 Starts the engine.
2362
2363 =cut
2364
2365 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2366
2367 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2368
2369 Sets an action in a given namespace.
2370
2371 =cut
2372
2373 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2374
2375 =head2 $c->setup_actions($component)
2376
2377 Sets up actions for a component.
2378
2379 =cut
2380
2381 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2382
2383 =head2 $c->setup_components
2384
2385 This method is called internally to set up the application's components.
2386
2387 It finds modules by calling the L<locate_components> method, expands them to
2388 package names with the L<expand_component_module> method, and then installs
2389 each component into the application.
2390
2391 The C<setup_components> config option is passed to both of the above methods.
2392
2393 Installation of each component is performed by the L<setup_component> method,
2394 below.
2395
2396 =cut
2397
2398 sub setup_components {
2399     my $class = shift;
2400
2401     my $config  = $class->config->{ setup_components };
2402
2403     my @comps = sort { length $a <=> length $b }
2404                 $class->locate_components($config);
2405     my %comps = map { $_ => 1 } @comps;
2406
2407     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2408     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2409         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2410     ) if $deprecatedcatalyst_component_names;
2411
2412     for my $component ( @comps ) {
2413
2414         # We pass ignore_loaded here so that overlay files for (e.g.)
2415         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2416         # we know M::P::O found a file on disk so this is safe
2417
2418         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2419     }
2420
2421     for my $component (@comps) {
2422         my $instance = $class->components->{ $component } = $class->setup_component($component);
2423         my @expanded_components = $instance->can('expand_modules')
2424             ? $instance->expand_modules( $component, $config )
2425             : $class->expand_component_module( $component, $config );
2426         for my $component (@expanded_components) {
2427             next if $comps{$component};
2428             $class->components->{ $component } = $class->setup_component($component);
2429         }
2430     }
2431 }
2432
2433 =head2 $c->locate_components( $setup_component_config )
2434
2435 This method is meant to provide a list of component modules that should be
2436 setup for the application.  By default, it will use L<Module::Pluggable>.
2437
2438 Specify a C<setup_components> config option to pass additional options directly
2439 to L<Module::Pluggable>. To add additional search paths, specify a key named
2440 C<search_extra> as an array reference. Items in the array beginning with C<::>
2441 will have the application class name prepended to them.
2442
2443 =cut
2444
2445 sub locate_components {
2446     my $class  = shift;
2447     my $config = shift;
2448
2449     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2450     my $extra   = delete $config->{ search_extra } || [];
2451
2452     push @paths, @$extra;
2453
2454     my $locator = Module::Pluggable::Object->new(
2455         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2456         %$config
2457     );
2458
2459     my @comps = $locator->plugins;
2460
2461     return @comps;
2462 }
2463
2464 =head2 $c->expand_component_module( $component, $setup_component_config )
2465
2466 Components found by C<locate_components> will be passed to this method, which
2467 is expected to return a list of component (package) names to be set up.
2468
2469 =cut
2470
2471 sub expand_component_module {
2472     my ($class, $module) = @_;
2473     return Devel::InnerPackage::list_packages( $module );
2474 }
2475
2476 =head2 $c->setup_component
2477
2478 =cut
2479
2480 sub setup_component {
2481     my( $class, $component ) = @_;
2482
2483     unless ( $component->can( 'COMPONENT' ) ) {
2484         return $component;
2485     }
2486
2487     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2488     my $config = $class->config->{ $suffix } || {};
2489     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2490     # methods also pass it. local to avoid pointlessly shitting in config
2491     # for the debug screen, as $component is already the key name.
2492     local $config->{catalyst_component_name} = $component;
2493
2494     my $instance = eval { $component->COMPONENT( $class, $config ); };
2495
2496     if ( my $error = $@ ) {
2497         chomp $error;
2498         Catalyst::Exception->throw(
2499             message => qq/Couldn't instantiate component "$component", "$error"/
2500         );
2501     }
2502
2503     unless (blessed $instance) {
2504         my $metaclass = Moose::Util::find_meta($component);
2505         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2506         my $component_method_from = $method_meta->associated_metaclass->name;
2507         my $value = defined($instance) ? $instance : 'undef';
2508         Catalyst::Exception->throw(
2509             message =>
2510             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2511         );
2512     }
2513     return $instance;
2514 }
2515
2516 =head2 $c->setup_dispatcher
2517
2518 Sets up dispatcher.
2519
2520 =cut
2521
2522 sub setup_dispatcher {
2523     my ( $class, $dispatcher ) = @_;
2524
2525     if ($dispatcher) {
2526         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2527     }
2528
2529     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2530         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2531     }
2532
2533     unless ($dispatcher) {
2534         $dispatcher = $class->dispatcher_class;
2535     }
2536
2537     Class::MOP::load_class($dispatcher);
2538
2539     # dispatcher instance
2540     $class->dispatcher( $dispatcher->new );
2541 }
2542
2543 =head2 $c->setup_engine
2544
2545 Sets up engine.
2546
2547 =cut
2548
2549 sub setup_engine {
2550     my ($class, $engine) = @_;
2551
2552     unless ($engine) {
2553         $engine = $class->engine_class;
2554     }
2555     $engine = 'Catalyst::Engine::' . $engine
2556         unless $engine =~ /^Catalyst::Engine/;
2557
2558     $engine = 'Catalyst::Engine' if $engine eq 'Catalyst::Engine::HTTP';
2559
2560     Class::MOP::load_class($engine);
2561
2562     # check for old engines that are no longer compatible
2563     my $old_engine;
2564     if ( $engine->isa('Catalyst::Engine::Apache')
2565         && !Catalyst::Engine::Apache->VERSION )
2566     {
2567         $old_engine = 1;
2568     }
2569
2570     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2571         && Catalyst::Engine::Server->VERSION le '0.02' )
2572     {
2573         $old_engine = 1;
2574     }
2575
2576     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2577         && $engine->VERSION eq '0.01' )
2578     {
2579         $old_engine = 1;
2580     }
2581
2582     elsif ($engine->isa('Catalyst::Engine::Zeus')
2583         && $engine->VERSION eq '0.01' )
2584     {
2585         $old_engine = 1;
2586     }
2587
2588     if ($old_engine) {
2589         Catalyst::Exception->throw( message =>
2590               qq/Engine "$engine" is not supported by this version of Catalyst/
2591         );
2592     }
2593
2594     $class->engine( $engine->new );
2595     $class->psgi_app( $class->engine->build_psgi_app($class) );
2596 }
2597
2598 =head2 $c->setup_home
2599
2600 Sets up the home directory.
2601
2602 =cut
2603
2604 sub setup_home {
2605     my ( $class, $home ) = @_;
2606
2607     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2608         $home = $env;
2609     }
2610
2611     $home ||= Catalyst::Utils::home($class);
2612
2613     if ($home) {
2614         #I remember recently being scolded for assigning config values like this
2615         $class->config->{home} ||= $home;
2616         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2617     }
2618 }
2619
2620 =head2 $c->setup_log
2621
2622 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2623 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2624 log to.
2625
2626 This method also installs a C<debug> method that returns a true value into the
2627 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2628 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2629
2630 Note that if the log has already been setup, by either a previous call to
2631 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2632 that this method won't actually set up the log object.
2633
2634 =cut
2635
2636 sub setup_log {
2637     my ( $class, $levels ) = @_;
2638
2639     $levels ||= '';
2640     $levels =~ s/^\s+//;
2641     $levels =~ s/\s+$//;
2642     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2643
2644     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2645     if ( defined $env_debug ) {
2646         $levels{debug} = 1 if $env_debug; # Ugly!
2647         delete($levels{debug}) unless $env_debug;
2648     }
2649
2650     unless ( $class->log ) {
2651         $class->log( Catalyst::Log->new(keys %levels) );
2652     }
2653
2654     if ( $levels{debug} ) {
2655         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2656         $class->log->debug('Debug messages enabled');
2657     }
2658 }
2659
2660 =head2 $c->setup_plugins
2661
2662 Sets up plugins.
2663
2664 =cut
2665
2666 =head2 $c->setup_stats
2667
2668 Sets up timing statistics class.
2669
2670 =cut
2671
2672 sub setup_stats {
2673     my ( $class, $stats ) = @_;
2674
2675     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2676
2677     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2678     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2679         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2680         $class->log->debug('Statistics enabled');
2681     }
2682 }
2683
2684
2685 =head2 $c->registered_plugins
2686
2687 Returns a sorted list of the plugins which have either been stated in the
2688 import list or which have been added via C<< MyApp->plugin(@args); >>.
2689
2690 If passed a given plugin name, it will report a boolean value indicating
2691 whether or not that plugin is loaded.  A fully qualified name is required if
2692 the plugin name does not begin with C<Catalyst::Plugin::>.
2693
2694  if ($c->registered_plugins('Some::Plugin')) {
2695      ...
2696  }
2697
2698 =cut
2699
2700 {
2701
2702     sub registered_plugins {
2703         my $proto = shift;
2704         return sort keys %{ $proto->_plugins } unless @_;
2705         my $plugin = shift;
2706         return 1 if exists $proto->_plugins->{$plugin};
2707         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2708     }
2709
2710     sub _register_plugin {
2711         my ( $proto, $plugin, $instant ) = @_;
2712         my $class = ref $proto || $proto;
2713
2714         Class::MOP::load_class( $plugin );
2715         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2716             if $plugin->isa( 'Catalyst::Component' );
2717         $proto->_plugins->{$plugin} = 1;
2718         unless ($instant) {
2719             my $meta = Class::MOP::get_metaclass_by_name($class);
2720             $meta->superclasses($plugin, $meta->superclasses);
2721         }
2722         return $class;
2723     }
2724
2725     sub setup_plugins {
2726         my ( $class, $plugins ) = @_;
2727
2728         $class->_plugins( {} ) unless $class->_plugins;
2729         $plugins = Data::OptList::mkopt($plugins || []);
2730
2731         my @plugins = map {
2732             [ Catalyst::Utils::resolve_namespace(
2733                   $class . '::Plugin',
2734                   'Catalyst::Plugin', $_->[0]
2735               ),
2736               $_->[1],
2737             ]
2738          } @{ $plugins };
2739
2740         for my $plugin ( reverse @plugins ) {
2741             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2742             my $meta = find_meta($plugin->[0]);
2743             next if $meta && $meta->isa('Moose::Meta::Role');
2744
2745             $class->_register_plugin($plugin->[0]);
2746         }
2747
2748         my @roles =
2749             map  { $_->[0]->name, $_->[1] }
2750             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2751             map  { [find_meta($_->[0]), $_->[1]] }
2752             @plugins;
2753
2754         Moose::Util::apply_all_roles(
2755             $class => @roles
2756         ) if @roles;
2757     }
2758 }
2759
2760 =head2 $c->stack
2761
2762 Returns an arrayref of the internal execution stack (actions that are
2763 currently executing).
2764
2765 =head2 $c->stats
2766
2767 Returns the current timing statistics object. By default Catalyst uses
2768 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2769 L<< stats_class|/"$c->stats_class" >>.
2770
2771 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2772 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2773 profile explicitly, although MyApp.pm still won't profile nor output anything
2774 by itself.
2775
2776 =head2 $c->stats_class
2777
2778 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2779
2780 =head2 $c->use_stats
2781
2782 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2783
2784 Note that this is a static method, not an accessor and should be overridden
2785 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2786
2787 =cut
2788
2789 sub use_stats { 0 }
2790
2791
2792 =head2 $c->write( $data )
2793
2794 Writes $data to the output stream. When using this method directly, you
2795 will need to manually set the C<Content-Length> header to the length of
2796 your output data, if known.
2797
2798 =cut
2799
2800 sub write {
2801     my $c = shift;
2802
2803     # Finalize headers if someone manually writes output
2804     $c->finalize_headers;
2805
2806     return $c->engine->write( $c, @_ );
2807 }
2808
2809 =head2 version
2810
2811 Returns the Catalyst version number. Mostly useful for "powered by"
2812 messages in template systems.
2813
2814 =cut
2815
2816 sub version { return $Catalyst::VERSION }
2817
2818 =head1 CONFIGURATION
2819
2820 There are a number of 'base' config variables which can be set:
2821
2822 =over
2823
2824 =item *
2825
2826 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2827
2828 =item *
2829
2830 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2831
2832 =item *
2833
2834 C<disable_component_resolution_regex_fallback> - Turns
2835 off the deprecated component resolution functionality so
2836 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2837 are called then regex search will not be attempted on string values and
2838 instead C<undef> will be returned.
2839
2840 =item *
2841
2842 C<home> - The application home directory. In an uninstalled application,
2843 this is the top level application directory. In an installed application,
2844 this will be the directory containing C<< MyApp.pm >>.
2845
2846 =item *
2847
2848 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2849
2850 =item *
2851
2852 C<name> - The name of the application in debug messages and the debug and
2853 welcome screens
2854
2855 =item *
2856
2857 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2858 until it is accessed. This allows you to (for example) check authentication (and reject
2859 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2860
2861 =item *
2862
2863 C<root> - The root directory for templates. Usually this is just a
2864 subdirectory of the home directory, but you can set it to change the
2865 templates to a different directory.
2866
2867 =item *
2868
2869 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2870 namespaces from which components will be loaded (and constructed and stored in
2871 C<< $c->components >>).
2872
2873 =item *
2874
2875 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2876 to be shown in hit debug tables in the test server.
2877
2878 =item *
2879
2880 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2881 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2882 for more information.
2883
2884 =item *
2885
2886 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2887
2888 =back
2889
2890 =head1 INTERNAL ACTIONS
2891
2892 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2893 C<_ACTION>, and C<_END>. These are by default not shown in the private
2894 action table, but you can make them visible with a config parameter.
2895
2896     MyApp->config(show_internal_actions => 1);
2897
2898 =head1 ON-DEMAND PARSER
2899
2900 The request body is usually parsed at the beginning of a request,
2901 but if you want to handle input yourself, you can enable on-demand
2902 parsing with a config parameter.
2903
2904     MyApp->config(parse_on_demand => 1);
2905
2906 =head1 PROXY SUPPORT
2907
2908 Many production servers operate using the common double-server approach,
2909 with a lightweight frontend web server passing requests to a larger
2910 backend server. An application running on the backend server must deal
2911 with two problems: the remote user always appears to be C<127.0.0.1> and
2912 the server's hostname will appear to be C<localhost> regardless of the
2913 virtual host that the user connected through.
2914
2915 Catalyst will automatically detect this situation when you are running
2916 the frontend and backend servers on the same machine. The following
2917 changes are made to the request.
2918
2919     $c->req->address is set to the user's real IP address, as read from
2920     the HTTP X-Forwarded-For header.
2921
2922     The host value for $c->req->base and $c->req->uri is set to the real
2923     host, as read from the HTTP X-Forwarded-Host header.
2924
2925 Additionally, you may be running your backend application on an insecure
2926 connection (port 80) while your frontend proxy is running under SSL.  If there
2927 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2928 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2929 be created properly.
2930
2931 In the case of passing in:
2932
2933     X-Forwarded-Port: 443
2934
2935 All calls to C<uri_for> will result in an https link, as is expected.
2936
2937 Obviously, your web server must support these headers for this to work.
2938
2939 In a more complex server farm environment where you may have your
2940 frontend proxy server(s) on different machines, you will need to set a
2941 configuration option to tell Catalyst to read the proxied data from the
2942 headers.
2943
2944     MyApp->config(using_frontend_proxy => 1);
2945
2946 If you do not wish to use the proxy support at all, you may set:
2947
2948     MyApp->config(ignore_frontend_proxy => 1);
2949
2950 =head1 THREAD SAFETY
2951
2952 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2953 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2954 believe the Catalyst core to be thread-safe.
2955
2956 If you plan to operate in a threaded environment, remember that all other
2957 modules you are using must also be thread-safe. Some modules, most notably
2958 L<DBD::SQLite>, are not thread-safe.
2959
2960 =head1 SUPPORT
2961
2962 IRC:
2963
2964     Join #catalyst on irc.perl.org.
2965
2966 Mailing Lists:
2967
2968     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2969     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2970
2971 Web:
2972
2973     http://catalyst.perl.org
2974
2975 Wiki:
2976
2977     http://dev.catalyst.perl.org
2978
2979 =head1 SEE ALSO
2980
2981 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2982
2983 =head2 L<Catalyst::Manual> - The Catalyst Manual
2984
2985 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2986
2987 =head2 L<Catalyst::Engine> - Core engine
2988
2989 =head2 L<Catalyst::Log> - Log class.
2990
2991 =head2 L<Catalyst::Request> - Request object
2992
2993 =head2 L<Catalyst::Response> - Response object
2994
2995 =head2 L<Catalyst::Test> - The test suite.
2996
2997 =head1 PROJECT FOUNDER
2998
2999 sri: Sebastian Riedel <sri@cpan.org>
3000
3001 =head1 CONTRIBUTORS
3002
3003 abw: Andy Wardley
3004
3005 acme: Leon Brocard <leon@astray.com>
3006
3007 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3008
3009 Andrew Bramble
3010
3011 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3012
3013 Andrew Ruthven
3014
3015 andyg: Andy Grundman <andy@hybridized.org>
3016
3017 audreyt: Audrey Tang
3018
3019 bricas: Brian Cassidy <bricas@cpan.org>
3020
3021 Caelum: Rafael Kitover <rkitover@io.com>
3022
3023 chansen: Christian Hansen
3024
3025 chicks: Christopher Hicks
3026
3027 Chisel Wright C<pause@herlpacker.co.uk>
3028
3029 Danijel Milicevic C<me@danijel.de>
3030
3031 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3032
3033 David Naughton, C<naughton@umn.edu>
3034
3035 David E. Wheeler
3036
3037 dhoss: Devin Austin <dhoss@cpan.org>
3038
3039 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3040
3041 Drew Taylor
3042
3043 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3044
3045 esskar: Sascha Kiefer
3046
3047 fireartist: Carl Franks <cfranks@cpan.org>
3048
3049 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3050
3051 gabb: Danijel Milicevic
3052
3053 Gary Ashton Jones
3054
3055 Gavin Henry C<ghenry@perl.me.uk>
3056
3057 Geoff Richards
3058
3059 groditi: Guillermo Roditi <groditi@gmail.com>
3060
3061 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3062
3063 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3064
3065 jcamacho: Juan Camacho
3066
3067 jester: Jesse Sheidlower C<jester@panix.com>
3068
3069 jhannah: Jay Hannah <jay@jays.net>
3070
3071 Jody Belka
3072
3073 Johan Lindstrom
3074
3075 jon: Jon Schutz <jjschutz@cpan.org>
3076
3077 Jonathan Rockway C<< <jrockway@cpan.org> >>
3078
3079 Kieren Diment C<kd@totaldatasolution.com>
3080
3081 konobi: Scott McWhirter <konobi@cpan.org>
3082
3083 marcus: Marcus Ramberg <mramberg@cpan.org>
3084
3085 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3086
3087 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3088
3089 mugwump: Sam Vilain
3090
3091 naughton: David Naughton
3092
3093 ningu: David Kamholz <dkamholz@cpan.org>
3094
3095 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3096
3097 numa: Dan Sully <daniel@cpan.org>
3098
3099 obra: Jesse Vincent
3100
3101 Octavian Rasnita
3102
3103 omega: Andreas Marienborg
3104
3105 Oleg Kostyuk <cub.uanic@gmail.com>
3106
3107 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3108
3109 rafl: Florian Ragwitz <rafl@debian.org>
3110
3111 random: Roland Lammel <lammel@cpan.org>
3112
3113 Robert Sedlacek C<< <rs@474.at> >>
3114
3115 SpiceMan: Marcel Montes
3116
3117 sky: Arthur Bergman
3118
3119 szbalint: Balint Szilakszi <szbalint@cpan.org>
3120
3121 t0m: Tomas Doran <bobtfish@bobtfish.net>
3122
3123 Ulf Edvinsson
3124
3125 Viljo Marrandi C<vilts@yahoo.com>
3126
3127 Will Hawes C<info@whawes.co.uk>
3128
3129 willert: Sebastian Willert <willert@cpan.org>
3130
3131 wreis: Wallace Reis <wallace@reis.org.br>
3132
3133 Yuval Kogman, C<nothingmuch@woobling.org>
3134
3135 =head1 LICENSE
3136
3137 This library is free software. You can redistribute it and/or modify it under
3138 the same terms as Perl itself.
3139
3140 =cut
3141
3142 no Moose;
3143
3144 __PACKAGE__->meta->make_immutable;
3145
3146 1;