lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use Scalar::Util qw/weaken blessed/;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use attributes;
  26 use utf8;
  27 use Carp qw/croak/;
  28
  29 BEGIN { require 5.008001; }
  30
  31 __PACKAGE__->mk_accessors(
  32     qw/counter request response state action stack namespace stats/
  33 );
  34
  35 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class setup_finished/;
  56
  57 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  58 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  59 __PACKAGE__->request_class('Catalyst::Request');
  60 __PACKAGE__->response_class('Catalyst::Response');
  61
  62 # Remember to update this in Catalyst::Runtime as well!
  63
  64 our $VERSION = '5.7003';
  65
  66 sub import {
  67     my ( $class, @arguments ) = @_;
  68
  69     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  70     # callers @ISA.
  71     return unless $class eq 'Catalyst';
  72
  73     my $caller = caller(0);
  74
  75     unless ( $caller->isa('Catalyst') ) {
  76         no strict 'refs';
  77         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  78     }
  79
  80     $caller->arguments( [@arguments] );
  81     $caller->setup_home;
  82 }
  83
  84 =head1 NAME
  85
  86 Catalyst - The Elegant MVC Web Application Framework
  87
  88 =head1 SYNOPSIS
  89
  90     # Install Catalyst::Devel for helpers and other development tools
  91     # use the helper to create a new application
  92     catalyst.pl MyApp
  93
  94     # add models, views, controllers
  95     script/myapp_create.pl model Database DBIC::SchemaLoader dbi:SQLite:/path/to/db
  96     script/myapp_create.pl view TT TT
  97     script/myapp_create.pl controller Search
  98
  99     # built in testserver -- use -r to restart automatically on changes
 100     script/myapp_server.pl
 101
 102     # command line testing interface
 103     script/myapp_test.pl /yada
 104
 105     ### in lib/MyApp.pm
 106     use Catalyst qw/-Debug/; # include plugins here as well
 107
 108         ### In lib/MyApp/Controller/Root.pm (autocreated)
 109     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 110         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 111         $c->stash->{template} = 'foo.tt'; # set the template
 112         # lookup something from db -- stash vars are passed to TT
 113         $c->stash->{data} =
 114           $c->model('Database::Foo')->search( { country => $args[0] } );
 115         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 116             $c->forward( 'bar' ); # process another action
 117             # do something else after forward returns
 118         }
 119     }
 120
 121     # The foo.tt TT template can use the stash data from the database
 122     [% WHILE (item = data.next) %]
 123         [% item.foo %]
 124     [% END %]
 125
 126     # called for /bar/of/soap, /bar/of/soap/10, etc.
 127     sub bar : Path('/bar/of/soap') { ... }
 128
 129     # called for all actions, from the top-most controller downwards
 130     sub auto : Private {
 131         my ( $self, $c ) = @_;
 132         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 133             $c->res->redirect( '/login' ); # require login
 134             return 0; # abort request and go immediately to end()
 135         }
 136         return 1; # success; carry on to next action
 137     }
 138
 139     # called after all actions are finished
 140     sub end : Private {
 141         my ( $self, $c ) = @_;
 142         if ( scalar @{ $c->error } ) { ... } # handle errors
 143         return if $c->res->body; # already have a response
 144         $c->forward( 'MyApp::View::TT' ); # render template
 145     }
 146
 147     ### in MyApp/Controller/Foo.pm
 148     # called for /foo/bar
 149     sub bar : Local { ... }
 150
 151     # called for /blargle
 152     sub blargle : Global { ... }
 153
 154     # an index action matches /foo, but not /foo/1, etc.
 155     sub index : Private { ... }
 156
 157     ### in MyApp/Controller/Foo/Bar.pm
 158     # called for /foo/bar/baz
 159     sub baz : Local { ... }
 160
 161     # first Root auto is called, then Foo auto, then this
 162     sub auto : Private { ... }
 163
 164     # powerful regular expression paths are also possible
 165     sub details : Regex('^product/(\w+)/details$') {
 166         my ( $self, $c ) = @_;
 167         # extract the (\w+) from the URI
 168         my $product = $c->req->captures->[0];
 169     }
 170
 171 See L<Catalyst::Manual::Intro> for additional information.
 172
 173 =head1 DESCRIPTION
 174
 175 Catalyst is a modern framework for making web applications without the
 176 pain usually associated with this process. This document is a reference
 177 to the main Catalyst application. If you are a new user, we suggest you
 178 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 179
 180 See L<Catalyst::Manual> for more documentation.
 181
 182 Catalyst plugins can be loaded by naming them as arguments to the "use
 183 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 184 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 185 C<My::Module>.
 186
 187     use Catalyst qw/My::Module/;
 188
 189 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 190 fully qualify the name by using a unary plus:
 191
 192     use Catalyst qw/
 193         My::Module
 194         +Fully::Qualified::Plugin::Name
 195     /;
 196
 197 Special flags like C<-Debug> and C<-Engine> can also be specified as
 198 arguments when Catalyst is loaded:
 199
 200     use Catalyst qw/-Debug My::Module/;
 201
 202 The position of plugins and flags in the chain is important, because
 203 they are loaded in the order in which they appear.
 204
 205 The following flags are supported:
 206
 207 =head2 -Debug
 208
 209 Enables debug output. You can also force this setting from the system
 210 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 211 settings override the application, with <MYAPP>_DEBUG having the highest
 212 priority.
 213
 214 =head2 -Engine
 215
 216 Forces Catalyst to use a specific engine. Omit the
 217 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 218
 219     use Catalyst qw/-Engine=CGI/;
 220
 221 =head2 -Home
 222
 223 Forces Catalyst to use a specific home directory, e.g.:
 224
 225     use Catalyst qw[-Home=/usr/mst];
 226
 227 =head2 -Log
 228
 229 Specifies log level.
 230
 231 =head1 METHODS
 232
 233 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 234
 235 =head2 $c->action
 236
 237 Returns a L<Catalyst::Action> object for the current action, which
 238 stringifies to the action name. See L<Catalyst::Action>.
 239
 240 =head2 $c->namespace
 241
 242 Returns the namespace of the current action, i.e., the URI prefix
 243 corresponding to the controller of the current action. For example:
 244
 245     # in Controller::Foo::Bar
 246     $c->namespace; # returns 'foo/bar';
 247
 248 =head2 $c->request
 249
 250 =head2 $c->req
 251
 252 Returns the current L<Catalyst::Request> object, giving access to
 253 information about the current client request (including parameters,
 254 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 255
 256 =head2 REQUEST FLOW HANDLING
 257
 258 =head2 $c->forward( $action [, \@arguments ] )
 259
 260 =head2 $c->forward( $class, $method, [, \@arguments ] )
 261
 262 Forwards processing to another action, by its private name. If you give a
 263 class name but no method, C<process()> is called. You may also optionally
 264 pass arguments in an arrayref. The action will receive the arguments in
 265 C<@_> and C<$c-E<gt>req-E<gt>args>. Upon returning from the function,
 266 C<$c-E<gt>req-E<gt>args> will be restored to the previous values.
 267
 268 Any data C<return>ed from the action forwarded to, will be returned by the
 269 call to forward.
 270
 271     my $foodata = $c->forward('/foo');
 272     $c->forward('index');
 273     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 274     $c->forward('MyApp::View::TT');
 275
 276 Note that forward implies an C<<eval { }>> around the call (actually
 277 C<execute> does), thus de-fatalizing all 'dies' within the called
 278 action. If you want C<die> to propagate you need to do something like:
 279
 280     $c->forward('foo');
 281     die $c->error if $c->error;
 282
 283 Or make sure to always return true values from your actions and write
 284 your code like this:
 285
 286     $c->forward('foo') || return;
 287
 288 =cut
 289
 290 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 291
 292 =head2 $c->detach( $action [, \@arguments ] )
 293
 294 =head2 $c->detach( $class, $method, [, \@arguments ] )
 295
 296 =head2 $c->detach()
 297
 298 The same as C<forward>, but doesn't return to the previous action when
 299 processing is finished.
 300
 301 When called with no arguments it escapes the processing chain entirely.
 302
 303 =cut
 304
 305 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 306
 307 =head2 $c->response
 308
 309 =head2 $c->res
 310
 311 Returns the current L<Catalyst::Response> object, q.v.
 312
 313 =head2 $c->stash
 314
 315 Returns a hashref to the stash, which may be used to store data and pass
 316 it between components during a request. You can also set hash keys by
 317 passing arguments. The stash is automatically sent to the view. The
 318 stash is cleared at the end of a request; it cannot be used for
 319 persistent storage (for this you must use a session; see
 320 L<Catalyst::Plugin::Session> for a complete system integrated with
 321 Catalyst).
 322
 323     $c->stash->{foo} = $bar;
 324     $c->stash( { moose => 'majestic', qux => 0 } );
 325     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 326
 327     # stash is automatically passed to the view for use in a template
 328     $c->forward( 'MyApp::V::TT' );
 329
 330 =cut
 331
 332 sub stash {
 333     my $c = shift;
 334     if (@_) {
 335         my $stash = @_ > 1 ? {@_} : $_[0];
 336         croak('stash takes a hash or hashref') unless ref $stash;
 337         foreach my $key ( keys %$stash ) {
 338             $c->{stash}->{$key} = $stash->{$key};
 339         }
 340     }
 341     return $c->{stash};
 342 }
 343
 344 =head2 $c->error
 345
 346 =head2 $c->error($error, ...)
 347
 348 =head2 $c->error($arrayref)
 349
 350 Returns an arrayref containing error messages.  If Catalyst encounters an
 351 error while processing a request, it stores the error in $c->error.  This
 352 method should not be used to store non-fatal error messages.
 353
 354     my @error = @{ $c->error };
 355
 356 Add a new error.
 357
 358     $c->error('Something bad happened');
 359
 360 =cut
 361
 362 sub error {
 363     my $c = shift;
 364     if ( $_[0] ) {
 365         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 366         croak @$error unless ref $c;
 367         push @{ $c->{error} }, @$error;
 368     }
 369     elsif ( defined $_[0] ) { $c->{error} = undef }
 370     return $c->{error} || [];
 371 }
 372
 373
 374 =head2 $c->state
 375
 376 Contains the return value of the last executed action.
 377
 378 =head2 $c->clear_errors
 379
 380 Clear errors.  You probably don't want to clear the errors unless you are
 381 implementing a custom error screen.
 382
 383 This is equivalent to running
 384
 385     $c->error(0);
 386
 387 =cut
 388
 389 sub clear_errors {
 390     my $c = shift;
 391     $c->error(0);
 392 }
 393
 394
 395 # search via regex
 396 sub _comp_search {
 397     my ( $c, @names ) = @_;
 398
 399     foreach my $name (@names) {
 400         foreach my $component ( keys %{ $c->components } ) {
 401             return $c->components->{$component} if $component =~ /$name/i;
 402         }
 403     }
 404
 405     return undef;
 406 }
 407
 408 # try explicit component names
 409 sub _comp_explicit {
 410     my ( $c, @names ) = @_;
 411
 412     foreach my $try (@names) {
 413         return $c->components->{$try} if ( exists $c->components->{$try} );
 414     }
 415
 416     return undef;
 417 }
 418
 419 # like component, but try just these prefixes before regex searching,
 420 #  and do not try to return "sort keys %{ $c->components }"
 421 sub _comp_prefixes {
 422     my ( $c, $name, @prefixes ) = @_;
 423
 424     my $appclass = ref $c || $c;
 425
 426     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 427
 428     my $comp = $c->_comp_explicit(@names);
 429     return $comp if defined($comp);
 430     $comp = $c->_comp_search($name);
 431     return $comp;
 432 }
 433
 434 # Find possible names for a prefix
 435
 436 sub _comp_names {
 437     my ( $c, @prefixes ) = @_;
 438
 439     my $appclass = ref $c || $c;
 440
 441     my @pre = map { "${appclass}::${_}::" } @prefixes;
 442
 443     my @names;
 444
 445     COMPONENT: foreach my $comp ($c->component) {
 446         foreach my $p (@pre) {
 447             if ($comp =~ s/^$p//) {
 448                 push(@names, $comp);
 449                 next COMPONENT;
 450             }
 451         }
 452     }
 453
 454     return @names;
 455 }
 456
 457 # Return a component if only one matches.
 458 sub _comp_singular {
 459     my ( $c, @prefixes ) = @_;
 460
 461     my $appclass = ref $c || $c;
 462
 463     my ( $comp, $rest ) =
 464       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 465     return $comp unless $rest;
 466 }
 467
 468 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 469 sub _filter_component {
 470     my ( $c, $comp, @args ) = @_;
 471     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 472         return $comp->ACCEPT_CONTEXT( $c, @args );
 473     }
 474     else { return $comp }
 475 }
 476
 477 =head2 COMPONENT ACCESSORS
 478
 479 =head2 $c->controller($name)
 480
 481 Gets a L<Catalyst::Controller> instance by name.
 482
 483     $c->controller('Foo')->do_stuff;
 484
 485 If the name is omitted, will return the controller for the dispatched
 486 action.
 487
 488 =cut
 489
 490 sub controller {
 491     my ( $c, $name, @args ) = @_;
 492     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 493         @args )
 494       if ($name);
 495     return $c->component( $c->action->class );
 496 }
 497
 498 =head2 $c->model($name)
 499
 500 Gets a L<Catalyst::Model> instance by name.
 501
 502     $c->model('Foo')->do_stuff;
 503
 504 If the name is omitted, it will look for a config setting 'default_model',
 505 or check if there is only one view, and return it if that's the case.
 506
 507 =cut
 508
 509 sub model {
 510     my ( $c, $name, @args ) = @_;
 511     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 512         @args )
 513       if $name;
 514     return $c->component( $c->config->{default_model} )
 515       if $c->config->{default_model};
 516     return $c->_filter_component( $c->_comp_singular(qw/Model M/), @args );
 517
 518 }
 519
 520 =head2 $c->controllers
 521
 522 Returns the available names which can be passed to $c->controller
 523
 524 =cut
 525
 526 sub controllers {
 527     my ( $c ) = @_;
 528     return $c->_comp_names(qw/Controller C/);
 529 }
 530
 531
 532 =head2 $c->view($name)
 533
 534 Gets a L<Catalyst::View> instance by name.
 535
 536     $c->view('Foo')->do_stuff;
 537
 538 If the name is omitted, it will look for a config setting
 539 'default_view', or check if there is only one view, and forward to it if
 540 that's the case.
 541
 542 =cut
 543
 544 sub view {
 545     my ( $c, $name, @args ) = @_;
 546     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 547         @args )
 548       if $name;
 549     return $c->component( $c->config->{default_view} )
 550       if $c->config->{default_view};
 551     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 552 }
 553
 554 =head2 $c->models
 555
 556 Returns the available names which can be passed to $c->model
 557
 558 =cut
 559
 560 sub models {
 561     my ( $c ) = @_;
 562     return $c->_comp_names(qw/Model M/);
 563 }
 564
 565
 566 =head2 $c->views
 567
 568 Returns the available names which can be passed to $c->view
 569
 570 =cut
 571
 572 sub views {
 573     my ( $c ) = @_;
 574     return $c->_comp_names(qw/View V/);
 575 }
 576
 577 =head2 $c->comp($name)
 578
 579 =head2 $c->component($name)
 580
 581 Gets a component object by name. This method is no longer recommended,
 582 unless you want to get a specific component by full
 583 class. C<$c-E<gt>controller>, C<$c-E<gt>model>, and C<$c-E<gt>view>
 584 should be used instead.
 585
 586 =cut
 587
 588 sub component {
 589     my $c = shift;
 590
 591     if (@_) {
 592
 593         my $name = shift;
 594
 595         my $appclass = ref $c || $c;
 596
 597         my @names = (
 598             $name, "${appclass}::${name}",
 599             map { "${appclass}::${_}::${name}" }
 600               qw/Model M Controller C View V/
 601         );
 602
 603         my $comp = $c->_comp_explicit(@names);
 604         return $c->_filter_component( $comp, @_ ) if defined($comp);
 605
 606         $comp = $c->_comp_search($name);
 607         return $c->_filter_component( $comp, @_ ) if defined($comp);
 608     }
 609
 610     return sort keys %{ $c->components };
 611 }
 612
 613
 614
 615 =head2 CLASS DATA AND HELPER CLASSES
 616
 617 =head2 $c->config
 618
 619 Returns or takes a hashref containing the application's configuration.
 620
 621     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 622
 623 You can also use a L<YAML> config file like myapp.yml in your
 624 applications home directory.
 625
 626     ---
 627     db: dsn:SQLite:foo.db
 628
 629
 630 =cut
 631
 632 sub config {
 633     my $c = shift;
 634
 635     $c->log->warn("Setting config after setup has been run is not a good idea.")
 636       if ( @_ and $c->setup_finished );
 637
 638     $c->NEXT::config(@_);
 639 }
 640
 641 =head2 $c->log
 642
 643 Returns the logging object instance. Unless it is already set, Catalyst
 644 sets this up with a L<Catalyst::Log> object. To use your own log class,
 645 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 646 C<< __PACKAGE__->setup >>.
 647
 648  __PACKAGE__->log( MyLogger->new );
 649  __PACKAGE__->setup;
 650
 651 And later:
 652
 653     $c->log->info( 'Now logging with my own logger!' );
 654
 655 Your log class should implement the methods described in
 656 L<Catalyst::Log>.
 657
 658
 659 =head2 $c->debug
 660
 661 Overload to enable debug messages (same as -Debug option).
 662
 663 Note that this is a static method, not an accessor and should be overloaded
 664 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 665
 666 =cut
 667
 668 sub debug { 0 }
 669
 670 =head2 $c->dispatcher
 671
 672 Returns the dispatcher instance. Stringifies to class name. See
 673 L<Catalyst::Dispatcher>.
 674
 675 =head2 $c->engine
 676
 677 Returns the engine instance. Stringifies to the class name. See
 678 L<Catalyst::Engine>.
 679
 680
 681 =head2 UTILITY METHODS
 682
 683 =head2 $c->path_to(@path)
 684
 685 Merges C<@path> with C<$c-E<gt>config-E<gt>{home}> and returns a
 686 L<Path::Class> object.
 687
 688 For example:
 689
 690     $c->path_to( 'db', 'sqlite.db' );
 691
 692 =cut
 693
 694 sub path_to {
 695     my ( $c, @path ) = @_;
 696     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 697     if ( -d $path ) { return $path }
 698     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 699 }
 700
 701 =head2 $c->plugin( $name, $class, @args )
 702
 703 Helper method for plugins. It creates a classdata accessor/mutator and
 704 loads and instantiates the given class.
 705
 706     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 707
 708     $c->prototype->define_javascript_functions;
 709
 710 =cut
 711
 712 sub plugin {
 713     my ( $class, $name, $plugin, @args ) = @_;
 714     $class->_register_plugin( $plugin, 1 );
 715
 716     eval { $plugin->import };
 717     $class->mk_classdata($name);
 718     my $obj;
 719     eval { $obj = $plugin->new(@args) };
 720
 721     if ($@) {
 722         Catalyst::Exception->throw( message =>
 723               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 724     }
 725
 726     $class->$name($obj);
 727     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 728       if $class->debug;
 729 }
 730
 731 =head2 MyApp->setup
 732
 733 Initializes the dispatcher and engine, loads any plugins, and loads the
 734 model, view, and controller components. You may also specify an array
 735 of plugins to load here, if you choose to not load them in the C<use
 736 Catalyst> line.
 737
 738     MyApp->setup;
 739     MyApp->setup( qw/-Debug/ );
 740
 741 =cut
 742
 743 sub setup {
 744     my ( $class, @arguments ) = @_;
 745
 746     $class->log->warn("Running setup twice is not a good idea.")
 747       if ( $class->setup_finished );
 748
 749     unless ( $class->isa('Catalyst') ) {
 750
 751         Catalyst::Exception->throw(
 752             message => qq/'$class' does not inherit from Catalyst/ );
 753     }
 754
 755     if ( $class->arguments ) {
 756         @arguments = ( @arguments, @{ $class->arguments } );
 757     }
 758
 759     # Process options
 760     my $flags = {};
 761
 762     foreach (@arguments) {
 763
 764         if (/^-Debug$/) {
 765             $flags->{log} =
 766               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 767         }
 768         elsif (/^-(\w+)=?(.*)$/) {
 769             $flags->{ lc $1 } = $2;
 770         }
 771         else {
 772             push @{ $flags->{plugins} }, $_;
 773         }
 774     }
 775
 776     $class->setup_home( delete $flags->{home} );
 777
 778     $class->setup_log( delete $flags->{log} );
 779     $class->setup_plugins( delete $flags->{plugins} );
 780     $class->setup_dispatcher( delete $flags->{dispatcher} );
 781     $class->setup_engine( delete $flags->{engine} );
 782
 783     for my $flag ( sort keys %{$flags} ) {
 784
 785         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 786             &$code( $class, delete $flags->{$flag} );
 787         }
 788         else {
 789             $class->log->warn(qq/Unknown flag "$flag"/);
 790         }
 791     }
 792
 793     eval { require Catalyst::Devel; };
 794     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 795         $class->log->warn(<<"EOF");
 796 You are running an old script!
 797
 798   Please update by running (this will overwrite existing files):
 799     catalyst.pl -force -scripts $class
 800
 801   or (this will not overwrite existing files):
 802     catalyst.pl -scripts $class
 803 EOF
 804     }
 805
 806     if ( $class->debug ) {
 807         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 808
 809         if (@plugins) {
 810             my $t = Text::SimpleTable->new(74);
 811             $t->row($_) for @plugins;
 812             $class->log->debug( "Loaded plugins:\n" . $t->draw );
 813         }
 814
 815         my $dispatcher = $class->dispatcher;
 816         my $engine     = $class->engine;
 817         my $home       = $class->config->{home};
 818
 819         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 820         $class->log->debug(qq/Loaded engine "$engine"/);
 821
 822         $home
 823           ? ( -d $home )
 824           ? $class->log->debug(qq/Found home "$home"/)
 825           : $class->log->debug(qq/Home "$home" doesn't exist/)
 826           : $class->log->debug(q/Couldn't find home/);
 827     }
 828
 829     # Call plugins setup
 830     {
 831         no warnings qw/redefine/;
 832         local *setup = sub { };
 833         $class->setup;
 834     }
 835
 836     # Initialize our data structure
 837     $class->components( {} );
 838
 839     $class->setup_components;
 840
 841     if ( $class->debug ) {
 842         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 843         for my $comp ( sort keys %{ $class->components } ) {
 844             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 845             $t->row( $comp, $type );
 846         }
 847         $class->log->debug( "Loaded components:\n" . $t->draw )
 848           if ( keys %{ $class->components } );
 849     }
 850
 851     # Add our self to components, since we are also a component
 852     $class->components->{$class} = $class;
 853
 854     $class->setup_actions;
 855
 856     if ( $class->debug ) {
 857         my $name = $class->config->{name} || 'Application';
 858         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 859     }
 860     $class->log->_flush() if $class->log->can('_flush');
 861
 862     $class->setup_finished(1);
 863 }
 864
 865 =head2 $c->uri_for( $path, @args?, \%query_values? )
 866
 867 Merges path with C<< $c->request->base >> for absolute URIs and with
 868 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 869 object. If any args are passed, they are added at the end of the path.
 870 If the last argument to C<uri_for> is a hash reference, it is assumed to
 871 contain GET parameter key/value pairs, which will be appended to the URI
 872 in standard fashion.
 873
 874 Instead of C<$path>, you can also optionally pass a C<$action> object
 875 which will be resolved to a path using
 876 C<< $c->dispatcher->uri_for_action >>; if the first element of
 877 C<@args> is an arrayref it is treated as a list of captures to be passed
 878 to C<uri_for_action>.
 879
 880 =cut
 881
 882 sub uri_for {
 883     my ( $c, $path, @args ) = @_;
 884     my $base     = $c->request->base->clone;
 885     my $basepath = $base->path;
 886     $basepath =~ s/\/$//;
 887     $basepath .= '/';
 888     my $namespace = $c->namespace || '';
 889
 890     if ( Scalar::Util::blessed($path) ) { # action object
 891         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 892                          ? shift(@args)
 893                          : [] );
 894         $path = $c->dispatcher->uri_for_action($path, $captures);
 895         return undef unless defined($path);
 896         $path = '/' if $path eq '';
 897     }
 898
 899     # massage namespace, empty if absolute path
 900     $namespace =~ s/^\/// if $namespace;
 901     $namespace .= '/' if $namespace;
 902     $path ||= '';
 903     $namespace = '' if $path =~ /^\//;
 904     $path =~ s/^\///;
 905
 906     my $params =
 907       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 908
 909     for my $value ( values %$params ) {
 910         for ( ref $value eq 'ARRAY' ? @$value : $value ) {
 911             $_ = "$_";
 912             utf8::encode( $_ );
 913         }
 914     };
 915
 916     # join args with '/', or a blank string
 917     my $args = ( scalar @args ? '/' . join( '/', @args ) : '' );
 918     $args =~ s/^\/// unless $path;
 919     my $res =
 920       URI->new_abs( URI->new_abs( "$path$args", "$basepath$namespace" ), $base )
 921       ->canonical;
 922     $res->query_form(%$params);
 923     $res;
 924 }
 925
 926 =head2 $c->welcome_message
 927
 928 Returns the Catalyst welcome HTML page.
 929
 930 =cut
 931
 932 sub welcome_message {
 933     my $c      = shift;
 934     my $name   = $c->config->{name};
 935     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
 936     my $prefix = Catalyst::Utils::appprefix( ref $c );
 937     $c->response->content_type('text/html; charset=utf-8');
 938     return <<"EOF";
 939 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
 940     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 941 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 942     <head>
 943         <meta http-equiv="Content-Language" content="en" />
 944         <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
 945         <title>$name on Catalyst $VERSION</title>
 946         <style type="text/css">
 947             body {
 948                 color: #000;
 949                 background-color: #eee;
 950             }
 951             div#content {
 952                 width: 640px;
 953                 margin-left: auto;
 954                 margin-right: auto;
 955                 margin-top: 10px;
 956                 margin-bottom: 10px;
 957                 text-align: left;
 958                 background-color: #ccc;
 959                 border: 1px solid #aaa;
 960             }
 961             p, h1, h2 {
 962                 margin-left: 20px;
 963                 margin-right: 20px;
 964                 font-family: verdana, tahoma, sans-serif;
 965             }
 966             a {
 967                 font-family: verdana, tahoma, sans-serif;
 968             }
 969             :link, :visited {
 970                     text-decoration: none;
 971                     color: #b00;
 972                     border-bottom: 1px dotted #bbb;
 973             }
 974             :link:hover, :visited:hover {
 975                     color: #555;
 976             }
 977             div#topbar {
 978                 margin: 0px;
 979             }
 980             pre {
 981                 margin: 10px;
 982                 padding: 8px;
 983             }
 984             div#answers {
 985                 padding: 8px;
 986                 margin: 10px;
 987                 background-color: #fff;
 988                 border: 1px solid #aaa;
 989             }
 990             h1 {
 991                 font-size: 0.9em;
 992                 font-weight: normal;
 993                 text-align: center;
 994             }
 995             h2 {
 996                 font-size: 1.0em;
 997             }
 998             p {
 999                 font-size: 0.9em;
1000             }
1001             p img {
1002                 float: right;
1003                 margin-left: 10px;
1004             }
1005             span#appname {
1006                 font-weight: bold;
1007                 font-size: 1.6em;
1008             }
1009         </style>
1010     </head>
1011     <body>
1012         <div id="content">
1013             <div id="topbar">
1014                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1015                     $VERSION</h1>
1016              </div>
1017              <div id="answers">
1018                  <p>
1019                  <img src="$logo" alt="Catalyst Logo" />
1020                  </p>
1021                  <p>Welcome to the wonderful world of Catalyst.
1022                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1023                     framework will make web development something you had
1024                     never expected it to be: Fun, rewarding, and quick.</p>
1025                  <h2>What to do now?</h2>
1026                  <p>That really depends  on what <b>you</b> want to do.
1027                     We do, however, provide you with a few starting points.</p>
1028                  <p>If you want to jump right into web development with Catalyst
1029                     you might want to check out the documentation.</p>
1030                  <pre><code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1031 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1032 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual.pod">Catalyst::Manual</a></code></pre>
1033                  <h2>What to do next?</h2>
1034                  <p>Next it's time to write an actual application. Use the
1035                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1036                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1037                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1038                     they can save you a lot of work.</p>
1039                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1040                     <p>Also, be sure to check out the vast and growing
1041                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1042                     you are likely to find what you need there.
1043                     </p>
1044
1045                  <h2>Need help?</h2>
1046                  <p>Catalyst has a very active community. Here are the main places to
1047                     get in touch with us.</p>
1048                  <ul>
1049                      <li>
1050                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1051                      </li>
1052                      <li>
1053                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1054                      </li>
1055                      <li>
1056                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1057                      </li>
1058                  </ul>
1059                  <h2>In conclusion</h2>
1060                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1061                     as we enjoyed making it. Please contact us if you have ideas
1062                     for improvement or other feedback.</p>
1063              </div>
1064          </div>
1065     </body>
1066 </html>
1067 EOF
1068 }
1069
1070 =head1 INTERNAL METHODS
1071
1072 These methods are not meant to be used by end users.
1073
1074 =head2 $c->components
1075
1076 Returns a hash of components.
1077
1078 =head2 $c->context_class
1079
1080 Returns or sets the context class.
1081
1082 =head2 $c->counter
1083
1084 Returns a hashref containing coderefs and execution counts (needed for
1085 deep recursion detection).
1086
1087 =head2 $c->depth
1088
1089 Returns the number of actions on the current internal execution stack.
1090
1091 =head2 $c->dispatch
1092
1093 Dispatches a request to actions.
1094
1095 =cut
1096
1097 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1098
1099 =head2 $c->dispatcher_class
1100
1101 Returns or sets the dispatcher class.
1102
1103 =head2 $c->dump_these
1104
1105 Returns a list of 2-element array references (name, structure) pairs
1106 that will be dumped on the error page in debug mode.
1107
1108 =cut
1109
1110 sub dump_these {
1111     my $c = shift;
1112     [ Request => $c->req ],
1113     [ Response => $c->res ],
1114     [ Stash => $c->stash ],
1115     [ Config => $c->config ];
1116 }
1117
1118 =head2 $c->engine_class
1119
1120 Returns or sets the engine class.
1121
1122 =head2 $c->execute( $class, $coderef )
1123
1124 Execute a coderef in given class and catch exceptions. Errors are available
1125 via $c->error.
1126
1127 =cut
1128
1129 sub execute {
1130     my ( $c, $class, $code ) = @_;
1131     $class = $c->component($class) || $class;
1132     $c->state(0);
1133
1134     if ( $c->depth >= $RECURSION ) {
1135         my $action = "$code";
1136         $action = "/$action" unless $action =~ /->/;
1137         my $error = qq/Deep recursion detected calling "$action"/;
1138         $c->log->error($error);
1139         $c->error($error);
1140         $c->state(0);
1141         return $c->state;
1142     }
1143
1144     my $stats_info = $c->_stats_start_execute( $code ) if $c->debug;
1145
1146     push( @{ $c->stack }, $code );
1147
1148     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1149
1150     $c->_stats_finish_execute( $stats_info ) if $c->debug and $stats_info;
1151
1152     my $last = pop( @{ $c->stack } );
1153
1154     if ( my $error = $@ ) {
1155         if ( !ref($error) and $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1156         else {
1157             unless ( ref $error ) {
1158                 no warnings 'uninitialized';
1159                 chomp $error;
1160                 my $class = $last->class;
1161                 my $name  = $last->name;
1162                 $error = qq/Caught exception in $class->$name "$error"/;
1163             }
1164             $c->error($error);
1165             $c->state(0);
1166         }
1167     }
1168     return $c->state;
1169 }
1170
1171 sub _stats_start_execute {
1172     my ( $c, $code ) = @_;
1173
1174     return if ( ( $code->name =~ /^_.*/ )
1175         && ( !$c->config->{show_internal_actions} ) );
1176
1177     $c->counter->{"$code"}++;
1178
1179     my $action = "$code";
1180     $action = "/$action" unless $action =~ /->/;
1181
1182     # determine if the call was the result of a forward
1183     # this is done by walking up the call stack and looking for a calling
1184     # sub of Catalyst::forward before the eval
1185     my $callsub = q{};
1186     for my $index ( 2 .. 11 ) {
1187         last
1188         if ( ( caller($index) )[0] eq 'Catalyst'
1189             && ( caller($index) )[3] eq '(eval)' );
1190
1191         if ( ( caller($index) )[3] =~ /forward$/ ) {
1192             $callsub = ( caller($index) )[3];
1193             $action  = "-> $action";
1194             last;
1195         }
1196     }
1197
1198     my $node = Tree::Simple->new(
1199         {
1200             action  => $action,
1201             elapsed => undef,     # to be filled in later
1202             comment => "",
1203         }
1204     );
1205     $node->setUID( "$code" . $c->counter->{"$code"} );
1206
1207     # is this a root-level call or a forwarded call?
1208     if ( $callsub =~ /forward$/ ) {
1209
1210         # forward, locate the caller
1211         if ( my $parent = $c->stack->[-1] ) {
1212             my $visitor = Tree::Simple::Visitor::FindByUID->new;
1213             $visitor->searchForUID(
1214                 "$parent" . $c->counter->{"$parent"} );
1215             $c->stats->accept($visitor);
1216             if ( my $result = $visitor->getResult ) {
1217                 $result->addChild($node);
1218             }
1219         }
1220         else {
1221
1222             # forward with no caller may come from a plugin
1223             $c->stats->addChild($node);
1224         }
1225     }
1226     else {
1227
1228         # root-level call
1229         $c->stats->addChild($node);
1230     }
1231
1232     return {
1233         start   => [gettimeofday],
1234         node    => $node,
1235     };
1236 }
1237
1238 sub _stats_finish_execute {
1239     my ( $c, $info ) = @_;
1240     my $elapsed = tv_interval $info->{start};
1241     my $value = $info->{node}->getNodeValue;
1242     $value->{elapsed} = sprintf( '%fs', $elapsed );
1243 }
1244
1245 =head2 $c->_localize_fields( sub { }, \%keys );
1246
1247 =cut
1248
1249 sub _localize_fields {
1250     my ( $c, $localized, $code ) = ( @_ );
1251
1252     my $request = delete $localized->{request} || {};
1253     my $response = delete $localized->{response} || {};
1254
1255     local @{ $c }{ keys %$localized } = values %$localized;
1256     local @{ $c->request }{ keys %$request } = values %$request;
1257     local @{ $c->response }{ keys %$response } = values %$response;
1258
1259     $code->();
1260 }
1261
1262 =head2 $c->finalize
1263
1264 Finalizes the request.
1265
1266 =cut
1267
1268 sub finalize {
1269     my $c = shift;
1270
1271     for my $error ( @{ $c->error } ) {
1272         $c->log->error($error);
1273     }
1274
1275     # Allow engine to handle finalize flow (for POE)
1276     if ( $c->engine->can('finalize') ) {
1277         $c->engine->finalize($c);
1278     }
1279     else {
1280
1281         $c->finalize_uploads;
1282
1283         # Error
1284         if ( $#{ $c->error } >= 0 ) {
1285             $c->finalize_error;
1286         }
1287
1288         $c->finalize_headers;
1289
1290         # HEAD request
1291         if ( $c->request->method eq 'HEAD' ) {
1292             $c->response->body('');
1293         }
1294
1295         $c->finalize_body;
1296     }
1297
1298     return $c->response->status;
1299 }
1300
1301 =head2 $c->finalize_body
1302
1303 Finalizes body.
1304
1305 =cut
1306
1307 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1308
1309 =head2 $c->finalize_cookies
1310
1311 Finalizes cookies.
1312
1313 =cut
1314
1315 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1316
1317 =head2 $c->finalize_error
1318
1319 Finalizes error.
1320
1321 =cut
1322
1323 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1324
1325 =head2 $c->finalize_headers
1326
1327 Finalizes headers.
1328
1329 =cut
1330
1331 sub finalize_headers {
1332     my $c = shift;
1333
1334     # Check if we already finalized headers
1335     return if $c->response->{_finalized_headers};
1336
1337     # Handle redirects
1338     if ( my $location = $c->response->redirect ) {
1339         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1340         $c->response->header( Location => $location );
1341     }
1342
1343     # Content-Length
1344     if ( $c->response->body && !$c->response->content_length ) {
1345
1346         # get the length from a filehandle
1347         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1348         {
1349             if ( my $stat = stat $c->response->body ) {
1350                 $c->response->content_length( $stat->size );
1351             }
1352             else {
1353                 $c->log->warn('Serving filehandle without a content-length');
1354             }
1355         }
1356         else {
1357             $c->response->content_length( bytes::length( $c->response->body ) );
1358         }
1359     }
1360
1361     # Errors
1362     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1363         $c->response->headers->remove_header("Content-Length");
1364         $c->response->body('');
1365     }
1366
1367     $c->finalize_cookies;
1368
1369     $c->engine->finalize_headers( $c, @_ );
1370
1371     # Done
1372     $c->response->{_finalized_headers} = 1;
1373 }
1374
1375 =head2 $c->finalize_output
1376
1377 An alias for finalize_body.
1378
1379 =head2 $c->finalize_read
1380
1381 Finalizes the input after reading is complete.
1382
1383 =cut
1384
1385 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1386
1387 =head2 $c->finalize_uploads
1388
1389 Finalizes uploads. Cleans up any temporary files.
1390
1391 =cut
1392
1393 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1394
1395 =head2 $c->get_action( $action, $namespace )
1396
1397 Gets an action in a given namespace.
1398
1399 =cut
1400
1401 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1402
1403 =head2 $c->get_actions( $action, $namespace )
1404
1405 Gets all actions of a given name in a namespace and all parent
1406 namespaces.
1407
1408 =cut
1409
1410 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1411
1412 =head2 $c->handle_request( $class, @arguments )
1413
1414 Called to handle each HTTP request.
1415
1416 =cut
1417
1418 sub handle_request {
1419     my ( $class, @arguments ) = @_;
1420
1421     # Always expect worst case!
1422     my $status = -1;
1423     eval {
1424         if ($class->debug) {
1425             my $start = [gettimeofday];
1426             my $c = $class->prepare(@arguments);
1427             $c->stats(Tree::Simple->new);
1428             $c->dispatch;
1429             $status = $c->finalize;
1430
1431             my $elapsed = tv_interval $start;
1432             $elapsed = sprintf '%f', $elapsed;
1433             my $av = sprintf '%.3f',
1434               ( $elapsed == 0 ? '??' : ( 1 / $elapsed ) );
1435             my $t = Text::SimpleTable->new( [ 62, 'Action' ], [ 9, 'Time' ] );
1436
1437             $c->stats->traverse(
1438                 sub {
1439                     my $action = shift;
1440                     my $stat   = $action->getNodeValue;
1441                     $t->row( ( q{ } x $action->getDepth ) . $stat->{action} . $stat->{comment},
1442                         $stat->{elapsed} || '??' );
1443                 }
1444             );
1445
1446             $class->log->info(
1447                 "Request took ${elapsed}s ($av/s)\n" . $t->draw );
1448         }
1449         else {
1450             my $c = $class->prepare(@arguments);
1451             $c->dispatch;
1452             $status = $c->finalize;
1453         }
1454     };
1455
1456     if ( my $error = $@ ) {
1457         chomp $error;
1458         $class->log->error(qq/Caught exception in engine "$error"/);
1459     }
1460
1461     $COUNT++;
1462     $class->log->_flush() if $class->log->can('_flush');
1463     return $status;
1464 }
1465
1466 =head2 $c->prepare( @arguments )
1467
1468 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1469 etc.).
1470
1471 =cut
1472
1473 sub prepare {
1474     my ( $class, @arguments ) = @_;
1475
1476     $class->context_class( ref $class || $class ) unless $class->context_class;
1477     my $c = $class->context_class->new(
1478         {
1479             counter => {},
1480             stack   => [],
1481             request => $class->request_class->new(
1482                 {
1483                     arguments        => [],
1484                     body_parameters  => {},
1485                     cookies          => {},
1486                     headers          => HTTP::Headers->new,
1487                     parameters       => {},
1488                     query_parameters => {},
1489                     secure           => 0,
1490                     captures         => [],
1491                     uploads          => {}
1492                 }
1493             ),
1494             response => $class->response_class->new(
1495                 {
1496                     body    => '',
1497                     cookies => {},
1498                     headers => HTTP::Headers->new(),
1499                     status  => 200
1500                 }
1501             ),
1502             stash => {},
1503             state => 0
1504         }
1505     );
1506
1507     # For on-demand data
1508     $c->request->{_context}  = $c;
1509     $c->response->{_context} = $c;
1510     weaken( $c->request->{_context} );
1511     weaken( $c->response->{_context} );
1512
1513     if ( $c->debug ) {
1514         my $secs = time - $START || 1;
1515         my $av = sprintf '%.3f', $COUNT / $secs;
1516         my $time = localtime time;
1517         $c->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1518         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1519     }
1520
1521     # Allow engine to direct the prepare flow (for POE)
1522     if ( $c->engine->can('prepare') ) {
1523         $c->engine->prepare( $c, @arguments );
1524     }
1525     else {
1526         $c->prepare_request(@arguments);
1527         $c->prepare_connection;
1528         $c->prepare_query_parameters;
1529         $c->prepare_headers;
1530         $c->prepare_cookies;
1531         $c->prepare_path;
1532
1533         # On-demand parsing
1534         $c->prepare_body unless $c->config->{parse_on_demand};
1535     }
1536
1537     my $method  = $c->req->method  || '';
1538     my $path    = $c->req->path    || '/';
1539     my $address = $c->req->address || '';
1540
1541     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1542       if $c->debug;
1543
1544     $c->prepare_action;
1545
1546     return $c;
1547 }
1548
1549 =head2 $c->prepare_action
1550
1551 Prepares action. See L<Catalyst::Dispatcher>.
1552
1553 =cut
1554
1555 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1556
1557 =head2 $c->prepare_body
1558
1559 Prepares message body.
1560
1561 =cut
1562
1563 sub prepare_body {
1564     my $c = shift;
1565
1566     # Do we run for the first time?
1567     return if defined $c->request->{_body};
1568
1569     # Initialize on-demand data
1570     $c->engine->prepare_body( $c, @_ );
1571     $c->prepare_parameters;
1572     $c->prepare_uploads;
1573
1574     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1575         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1576         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1577             my $param = $c->req->body_parameters->{$key};
1578             my $value = defined($param) ? $param : '';
1579             $t->row( $key,
1580                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1581         }
1582         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1583     }
1584 }
1585
1586 =head2 $c->prepare_body_chunk( $chunk )
1587
1588 Prepares a chunk of data before sending it to L<HTTP::Body>.
1589
1590 See L<Catalyst::Engine>.
1591
1592 =cut
1593
1594 sub prepare_body_chunk {
1595     my $c = shift;
1596     $c->engine->prepare_body_chunk( $c, @_ );
1597 }
1598
1599 =head2 $c->prepare_body_parameters
1600
1601 Prepares body parameters.
1602
1603 =cut
1604
1605 sub prepare_body_parameters {
1606     my $c = shift;
1607     $c->engine->prepare_body_parameters( $c, @_ );
1608 }
1609
1610 =head2 $c->prepare_connection
1611
1612 Prepares connection.
1613
1614 =cut
1615
1616 sub prepare_connection {
1617     my $c = shift;
1618     $c->engine->prepare_connection( $c, @_ );
1619 }
1620
1621 =head2 $c->prepare_cookies
1622
1623 Prepares cookies.
1624
1625 =cut
1626
1627 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1628
1629 =head2 $c->prepare_headers
1630
1631 Prepares headers.
1632
1633 =cut
1634
1635 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1636
1637 =head2 $c->prepare_parameters
1638
1639 Prepares parameters.
1640
1641 =cut
1642
1643 sub prepare_parameters {
1644     my $c = shift;
1645     $c->prepare_body_parameters;
1646     $c->engine->prepare_parameters( $c, @_ );
1647 }
1648
1649 =head2 $c->prepare_path
1650
1651 Prepares path and base.
1652
1653 =cut
1654
1655 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1656
1657 =head2 $c->prepare_query_parameters
1658
1659 Prepares query parameters.
1660
1661 =cut
1662
1663 sub prepare_query_parameters {
1664     my $c = shift;
1665
1666     $c->engine->prepare_query_parameters( $c, @_ );
1667
1668     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1669         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1670         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1671             my $param = $c->req->query_parameters->{$key};
1672             my $value = defined($param) ? $param : '';
1673             $t->row( $key,
1674                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1675         }
1676         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1677     }
1678 }
1679
1680 =head2 $c->prepare_read
1681
1682 Prepares the input for reading.
1683
1684 =cut
1685
1686 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1687
1688 =head2 $c->prepare_request
1689
1690 Prepares the engine request.
1691
1692 =cut
1693
1694 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1695
1696 =head2 $c->prepare_uploads
1697
1698 Prepares uploads.
1699
1700 =cut
1701
1702 sub prepare_uploads {
1703     my $c = shift;
1704
1705     $c->engine->prepare_uploads( $c, @_ );
1706
1707     if ( $c->debug && keys %{ $c->request->uploads } ) {
1708         my $t = Text::SimpleTable->new(
1709             [ 12, 'Parameter' ],
1710             [ 26, 'Filename' ],
1711             [ 18, 'Type' ],
1712             [ 9,  'Size' ]
1713         );
1714         for my $key ( sort keys %{ $c->request->uploads } ) {
1715             my $upload = $c->request->uploads->{$key};
1716             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1717                 $t->row( $key, $u->filename, $u->type, $u->size );
1718             }
1719         }
1720         $c->log->debug( "File Uploads are:\n" . $t->draw );
1721     }
1722 }
1723
1724 =head2 $c->prepare_write
1725
1726 Prepares the output for writing.
1727
1728 =cut
1729
1730 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1731
1732 =head2 $c->request_class
1733
1734 Returns or sets the request class.
1735
1736 =head2 $c->response_class
1737
1738 Returns or sets the response class.
1739
1740 =head2 $c->read( [$maxlength] )
1741
1742 Reads a chunk of data from the request body. This method is designed to
1743 be used in a while loop, reading C<$maxlength> bytes on every call.
1744 C<$maxlength> defaults to the size of the request if not specified.
1745
1746 You have to set C<MyApp-E<gt>config-E<gt>{parse_on_demand}> to use this
1747 directly.
1748
1749 =cut
1750
1751 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1752
1753 =head2 $c->run
1754
1755 Starts the engine.
1756
1757 =cut
1758
1759 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1760
1761 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1762
1763 Sets an action in a given namespace.
1764
1765 =cut
1766
1767 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1768
1769 =head2 $c->setup_actions($component)
1770
1771 Sets up actions for a component.
1772
1773 =cut
1774
1775 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1776
1777 =head2 $c->setup_components
1778
1779 Sets up components. Specify a C<setup_components> config option to pass
1780 additional options directly to L<Module::Pluggable>. To add additional
1781 search paths, specify a key named C<search_extra> as an array
1782 reference. Items in the array beginning with C<::> will have the
1783 application class name prepended to them.
1784
1785 =cut
1786
1787 sub setup_components {
1788     my $class = shift;
1789
1790     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1791     my $config  = $class->config->{ setup_components };
1792     my $extra   = delete $config->{ search_extra } || [];
1793
1794     push @paths, @$extra;
1795
1796     my $locator = Module::Pluggable::Object->new(
1797         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1798         %$config
1799     );
1800
1801     for my $component ( sort { length $a <=> length $b } $locator->plugins ) {
1802         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1803
1804         my $module  = $class->setup_component( $component );
1805         my %modules = (
1806             $component => $module,
1807             map {
1808                 $_ => $class->setup_component( $_ )
1809             } Devel::InnerPackage::list_packages( $component )
1810         );
1811
1812         for my $key ( keys %modules ) {
1813             $class->components->{ $key } = $modules{ $key };
1814         }
1815     }
1816 }
1817
1818 =head2 $c->setup_component
1819
1820 =cut
1821
1822 sub setup_component {
1823     my( $class, $component ) = @_;
1824
1825     unless ( $component->can( 'COMPONENT' ) ) {
1826         return $component;
1827     }
1828
1829     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1830     my $config = $class->config->{ $suffix } || {};
1831
1832     my $instance = eval { $component->COMPONENT( $class, $config ); };
1833
1834     if ( my $error = $@ ) {
1835         chomp $error;
1836         Catalyst::Exception->throw(
1837             message => qq/Couldn't instantiate component "$component", "$error"/
1838         );
1839     }
1840
1841     Catalyst::Exception->throw(
1842         message =>
1843         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1844     ) unless eval { $instance->can( 'can' ) };
1845
1846     return $instance;
1847 }
1848
1849 =head2 $c->setup_dispatcher
1850
1851 Sets up dispatcher.
1852
1853 =cut
1854
1855 sub setup_dispatcher {
1856     my ( $class, $dispatcher ) = @_;
1857
1858     if ($dispatcher) {
1859         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1860     }
1861
1862     if ( $ENV{CATALYST_DISPATCHER} ) {
1863         $dispatcher = 'Catalyst::Dispatcher::' . $ENV{CATALYST_DISPATCHER};
1864     }
1865
1866     if ( $ENV{ uc($class) . '_DISPATCHER' } ) {
1867         $dispatcher =
1868           'Catalyst::Dispatcher::' . $ENV{ uc($class) . '_DISPATCHER' };
1869     }
1870
1871     unless ($dispatcher) {
1872         $dispatcher = $class->dispatcher_class;
1873     }
1874
1875     unless (Class::Inspector->loaded($dispatcher)) {
1876         require Class::Inspector->filename($dispatcher);
1877     }
1878
1879     # dispatcher instance
1880     $class->dispatcher( $dispatcher->new );
1881 }
1882
1883 =head2 $c->setup_engine
1884
1885 Sets up engine.
1886
1887 =cut
1888
1889 sub setup_engine {
1890     my ( $class, $engine ) = @_;
1891
1892     if ($engine) {
1893         $engine = 'Catalyst::Engine::' . $engine;
1894     }
1895
1896     if ( $ENV{CATALYST_ENGINE} ) {
1897         $engine = 'Catalyst::Engine::' . $ENV{CATALYST_ENGINE};
1898     }
1899
1900     if ( $ENV{ uc($class) . '_ENGINE' } ) {
1901         $engine = 'Catalyst::Engine::' . $ENV{ uc($class) . '_ENGINE' };
1902     }
1903
1904     if ( $ENV{MOD_PERL} ) {
1905
1906         # create the apache method
1907         {
1908             no strict 'refs';
1909             *{"$class\::apache"} = sub { shift->engine->apache };
1910         }
1911
1912         my ( $software, $version ) =
1913           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1914
1915         $version =~ s/_//g;
1916         $version =~ s/(\.[^.]+)\./$1/g;
1917
1918         if ( $software eq 'mod_perl' ) {
1919
1920             if ( !$engine ) {
1921
1922                 if ( $version >= 1.99922 ) {
1923                     $engine = 'Catalyst::Engine::Apache2::MP20';
1924                 }
1925
1926                 elsif ( $version >= 1.9901 ) {
1927                     $engine = 'Catalyst::Engine::Apache2::MP19';
1928                 }
1929
1930                 elsif ( $version >= 1.24 ) {
1931                     $engine = 'Catalyst::Engine::Apache::MP13';
1932                 }
1933
1934                 else {
1935                     Catalyst::Exception->throw( message =>
1936                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
1937                 }
1938
1939             }
1940
1941             # install the correct mod_perl handler
1942             if ( $version >= 1.9901 ) {
1943                 *handler = sub  : method {
1944                     shift->handle_request(@_);
1945                 };
1946             }
1947             else {
1948                 *handler = sub ($$) { shift->handle_request(@_) };
1949             }
1950
1951         }
1952
1953         elsif ( $software eq 'Zeus-Perl' ) {
1954             $engine = 'Catalyst::Engine::Zeus';
1955         }
1956
1957         else {
1958             Catalyst::Exception->throw(
1959                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
1960         }
1961     }
1962
1963     unless ($engine) {
1964         $engine = $class->engine_class;
1965     }
1966
1967     unless (Class::Inspector->loaded($engine)) {
1968         require Class::Inspector->filename($engine);
1969     }
1970
1971     # check for old engines that are no longer compatible
1972     my $old_engine;
1973     if ( $engine->isa('Catalyst::Engine::Apache')
1974         && !Catalyst::Engine::Apache->VERSION )
1975     {
1976         $old_engine = 1;
1977     }
1978
1979     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
1980         && Catalyst::Engine::Server->VERSION le '0.02' )
1981     {
1982         $old_engine = 1;
1983     }
1984
1985     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
1986         && $engine->VERSION eq '0.01' )
1987     {
1988         $old_engine = 1;
1989     }
1990
1991     elsif ($engine->isa('Catalyst::Engine::Zeus')
1992         && $engine->VERSION eq '0.01' )
1993     {
1994         $old_engine = 1;
1995     }
1996
1997     if ($old_engine) {
1998         Catalyst::Exception->throw( message =>
1999               qq/Engine "$engine" is not supported by this version of Catalyst/
2000         );
2001     }
2002
2003     # engine instance
2004     $class->engine( $engine->new );
2005 }
2006
2007 =head2 $c->setup_home
2008
2009 Sets up the home directory.
2010
2011 =cut
2012
2013 sub setup_home {
2014     my ( $class, $home ) = @_;
2015
2016     if ( $ENV{CATALYST_HOME} ) {
2017         $home = $ENV{CATALYST_HOME};
2018     }
2019
2020     if ( $ENV{ uc($class) . '_HOME' } ) {
2021         $home = $ENV{ uc($class) . '_HOME' };
2022     }
2023
2024     unless ($home) {
2025         $home = Catalyst::Utils::home($class);
2026     }
2027
2028     if ($home) {
2029         $class->config->{home} ||= $home;
2030         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2031     }
2032 }
2033
2034 =head2 $c->setup_log
2035
2036 Sets up log.
2037
2038 =cut
2039
2040 sub setup_log {
2041     my ( $class, $debug ) = @_;
2042
2043     unless ( $class->log ) {
2044         $class->log( Catalyst::Log->new );
2045     }
2046
2047     my $app_flag = Catalyst::Utils::class2env($class) . '_DEBUG';
2048
2049     if (
2050           ( defined( $ENV{CATALYST_DEBUG} ) || defined( $ENV{$app_flag} ) )
2051         ? ( $ENV{CATALYST_DEBUG} || $ENV{$app_flag} )
2052         : $debug
2053       )
2054     {
2055         no strict 'refs';
2056         *{"$class\::debug"} = sub { 1 };
2057         $class->log->debug('Debug messages enabled');
2058     }
2059 }
2060
2061 =head2 $c->setup_plugins
2062
2063 Sets up plugins.
2064
2065 =cut
2066
2067 =head2 $c->registered_plugins
2068
2069 Returns a sorted list of the plugins which have either been stated in the
2070 import list or which have been added via C<< MyApp->plugin(@args); >>.
2071
2072 If passed a given plugin name, it will report a boolean value indicating
2073 whether or not that plugin is loaded.  A fully qualified name is required if
2074 the plugin name does not begin with C<Catalyst::Plugin::>.
2075
2076  if ($c->registered_plugins('Some::Plugin')) {
2077      ...
2078  }
2079
2080 =cut
2081
2082 {
2083
2084     sub registered_plugins {
2085         my $proto = shift;
2086         return sort keys %{ $proto->_plugins } unless @_;
2087         my $plugin = shift;
2088         return 1 if exists $proto->_plugins->{$plugin};
2089         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2090     }
2091
2092     sub _register_plugin {
2093         my ( $proto, $plugin, $instant ) = @_;
2094         my $class = ref $proto || $proto;
2095
2096         unless (Class::Inspector->loaded($plugin)) {
2097             require Class::Inspector->filename($plugin);
2098         }
2099
2100         $proto->_plugins->{$plugin} = 1;
2101         unless ($instant) {
2102             no strict 'refs';
2103             unshift @{"$class\::ISA"}, $plugin;
2104         }
2105         return $class;
2106     }
2107
2108     sub setup_plugins {
2109         my ( $class, $plugins ) = @_;
2110
2111         $class->_plugins( {} ) unless $class->_plugins;
2112         $plugins ||= [];
2113         for my $plugin ( reverse @$plugins ) {
2114
2115             unless ( $plugin =~ s/\A\+// ) {
2116                 $plugin = "Catalyst::Plugin::$plugin";
2117             }
2118
2119             $class->_register_plugin($plugin);
2120         }
2121     }
2122 }
2123
2124 =head2 $c->stack
2125
2126 Returns an arrayref of the internal execution stack (actions that are
2127 currently executing).
2128
2129 =head2 $c->write( $data )
2130
2131 Writes $data to the output stream. When using this method directly, you
2132 will need to manually set the C<Content-Length> header to the length of
2133 your output data, if known.
2134
2135 =cut
2136
2137 sub write {
2138     my $c = shift;
2139
2140     # Finalize headers if someone manually writes output
2141     $c->finalize_headers;
2142
2143     return $c->engine->write( $c, @_ );
2144 }
2145
2146 =head2 version
2147
2148 Returns the Catalyst version number. Mostly useful for "powered by"
2149 messages in template systems.
2150
2151 =cut
2152
2153 sub version { return $Catalyst::VERSION }
2154
2155 =head1 INTERNAL ACTIONS
2156
2157 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2158 C<_ACTION>, and C<_END>. These are by default not shown in the private
2159 action table, but you can make them visible with a config parameter.
2160
2161     MyApp->config->{show_internal_actions} = 1;
2162
2163 =head1 CASE SENSITIVITY
2164
2165 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2166 mapped to C</foo/bar>. You can activate case sensitivity with a config
2167 parameter.
2168
2169     MyApp->config->{case_sensitive} = 1;
2170
2171 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2172
2173 =head1 ON-DEMAND PARSER
2174
2175 The request body is usually parsed at the beginning of a request,
2176 but if you want to handle input yourself or speed things up a bit,
2177 you can enable on-demand parsing with a config parameter.
2178
2179     MyApp->config->{parse_on_demand} = 1;
2180
2181 =head1 PROXY SUPPORT
2182
2183 Many production servers operate using the common double-server approach,
2184 with a lightweight frontend web server passing requests to a larger
2185 backend server. An application running on the backend server must deal
2186 with two problems: the remote user always appears to be C<127.0.0.1> and
2187 the server's hostname will appear to be C<localhost> regardless of the
2188 virtual host that the user connected through.
2189
2190 Catalyst will automatically detect this situation when you are running
2191 the frontend and backend servers on the same machine. The following
2192 changes are made to the request.
2193
2194     $c->req->address is set to the user's real IP address, as read from
2195     the HTTP X-Forwarded-For header.
2196
2197     The host value for $c->req->base and $c->req->uri is set to the real
2198     host, as read from the HTTP X-Forwarded-Host header.
2199
2200 Obviously, your web server must support these headers for this to work.
2201
2202 In a more complex server farm environment where you may have your
2203 frontend proxy server(s) on different machines, you will need to set a
2204 configuration option to tell Catalyst to read the proxied data from the
2205 headers.
2206
2207     MyApp->config->{using_frontend_proxy} = 1;
2208
2209 If you do not wish to use the proxy support at all, you may set:
2210
2211     MyApp->config->{ignore_frontend_proxy} = 1;
2212
2213 =head1 THREAD SAFETY
2214
2215 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2216 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2217 believe the Catalyst core to be thread-safe.
2218
2219 If you plan to operate in a threaded environment, remember that all other
2220 modules you are using must also be thread-safe. Some modules, most notably
2221 L<DBD::SQLite>, are not thread-safe.
2222
2223 =head1 SUPPORT
2224
2225 IRC:
2226
2227     Join #catalyst on irc.perl.org.
2228
2229 Mailing Lists:
2230
2231     http://lists.rawmode.org/mailman/listinfo/catalyst
2232     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2233
2234 Web:
2235
2236     http://catalyst.perl.org
2237
2238 Wiki:
2239
2240     http://dev.catalyst.perl.org
2241
2242 =head1 SEE ALSO
2243
2244 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2245
2246 =head2 L<Catalyst::Manual> - The Catalyst Manual
2247
2248 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2249
2250 =head2 L<Catalyst::Engine> - Core engine
2251
2252 =head2 L<Catalyst::Log> - Log class.
2253
2254 =head2 L<Catalyst::Request> - Request object
2255
2256 =head2 L<Catalyst::Response> - Response object
2257
2258 =head2 L<Catalyst::Test> - The test suite.
2259
2260 =head1 CREDITS
2261
2262 Andy Grundman
2263
2264 Andy Wardley
2265
2266 Andreas Marienborg
2267
2268 Andrew Bramble
2269
2270 Andrew Ford
2271
2272 Andrew Ruthven
2273
2274 Arthur Bergman
2275
2276 Autrijus Tang
2277
2278 Brian Cassidy
2279
2280 Carl Franks
2281
2282 Christian Hansen
2283
2284 Christopher Hicks
2285
2286 Dan Sully
2287
2288 Danijel Milicevic
2289
2290 David Kamholz
2291
2292 David Naughton
2293
2294 Drew Taylor
2295
2296 Gary Ashton Jones
2297
2298 Geoff Richards
2299
2300 Jesse Sheidlower
2301
2302 Jesse Vincent
2303
2304 Jody Belka
2305
2306 Johan Lindstrom
2307
2308 Juan Camacho
2309
2310 Leon Brocard
2311
2312 Marcus Ramberg
2313
2314 Matt S Trout
2315
2316 Robert Sedlacek
2317
2318 Sam Vilain
2319
2320 Sascha Kiefer
2321
2322 Tatsuhiko Miyagawa
2323
2324 Ulf Edvinsson
2325
2326 Yuval Kogman
2327
2328 =head1 AUTHOR
2329
2330 Sebastian Riedel, C<sri@oook.de>
2331
2332 =head1 LICENSE
2333
2334 This library is free software, you can redistribute it and/or modify it under
2335 the same terms as Perl itself.
2336
2337 =cut
2338
2339 1;