lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use bytes;
   8 use B::Hooks::EndOfScope ();
   9 use Catalyst::Exception;
  10 use Catalyst::Exception::Detach;
  11 use Catalyst::Exception::Go;
  12 use Catalyst::Log;
  13 use Catalyst::Request;
  14 use Catalyst::Request::Upload;
  15 use Catalyst::Response;
  16 use Catalyst::Utils;
  17 use Catalyst::Controller;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80013';
  83
  84 {
  85     my $dev_version = $VERSION =~ /_\d{2}$/;
  86     *_IS_DEVELOPMENT_VERSION = sub () { $dev_version };
  87 }
  88
  89 $VERSION = eval $VERSION;
  90
  91 sub import {
  92     my ( $class, @arguments ) = @_;
  93
  94     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  95     # callers @ISA.
  96     return unless $class eq 'Catalyst';
  97
  98     my $caller = caller();
  99     return if $caller eq 'main';
 100
 101     # Kill Adopt::NEXT warnings if we're a non-RC version
 102     unless (_IS_DEVELOPMENT_VERSION()) {
 103         Class::C3::Adopt::NEXT->unimport(qr/^Catalyst::/);
 104     }
 105
 106     my $meta = Moose::Meta::Class->initialize($caller);
 107     unless ( $caller->isa('Catalyst') ) {
 108         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 109         $meta->superclasses(@superclasses);
 110     }
 111     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 112     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 113
 114     unless( $meta->has_method('meta') ){
 115         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 116     }
 117
 118     $caller->arguments( [@arguments] );
 119     $caller->setup_home;
 120 }
 121
 122 sub _application { $_[0] }
 123
 124 =head1 NAME
 125
 126 Catalyst - The Elegant MVC Web Application Framework
 127
 128 =head1 SYNOPSIS
 129
 130 See the L<Catalyst::Manual> distribution for comprehensive
 131 documentation and tutorials.
 132
 133     # Install Catalyst::Devel for helpers and other development tools
 134     # use the helper to create a new application
 135     catalyst.pl MyApp
 136
 137     # add models, views, controllers
 138     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 139     script/myapp_create.pl view MyTemplate TT
 140     script/myapp_create.pl controller Search
 141
 142     # built in testserver -- use -r to restart automatically on changes
 143     # --help to see all available options
 144     script/myapp_server.pl
 145
 146     # command line testing interface
 147     script/myapp_test.pl /yada
 148
 149     ### in lib/MyApp.pm
 150     use Catalyst qw/-Debug/; # include plugins here as well
 151
 152     ### In lib/MyApp/Controller/Root.pm (autocreated)
 153     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 154         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 155         $c->stash->{template} = 'foo.tt'; # set the template
 156         # lookup something from db -- stash vars are passed to TT
 157         $c->stash->{data} =
 158           $c->model('Database::Foo')->search( { country => $args[0] } );
 159         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 160             $c->forward( 'bar' ); # process another action
 161             # do something else after forward returns
 162         }
 163     }
 164
 165     # The foo.tt TT template can use the stash data from the database
 166     [% WHILE (item = data.next) %]
 167         [% item.foo %]
 168     [% END %]
 169
 170     # called for /bar/of/soap, /bar/of/soap/10, etc.
 171     sub bar : Path('/bar/of/soap') { ... }
 172
 173     # called for all actions, from the top-most controller downwards
 174     sub auto : Private {
 175         my ( $self, $c ) = @_;
 176         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 177             $c->res->redirect( '/login' ); # require login
 178             return 0; # abort request and go immediately to end()
 179         }
 180         return 1; # success; carry on to next action
 181     }
 182
 183     # called after all actions are finished
 184     sub end : Private {
 185         my ( $self, $c ) = @_;
 186         if ( scalar @{ $c->error } ) { ... } # handle errors
 187         return if $c->res->body; # already have a response
 188         $c->forward( 'MyApp::View::TT' ); # render template
 189     }
 190
 191     ### in MyApp/Controller/Foo.pm
 192     # called for /foo/bar
 193     sub bar : Local { ... }
 194
 195     # called for /blargle
 196     sub blargle : Global { ... }
 197
 198     # an index action matches /foo, but not /foo/1, etc.
 199     sub index : Private { ... }
 200
 201     ### in MyApp/Controller/Foo/Bar.pm
 202     # called for /foo/bar/baz
 203     sub baz : Local { ... }
 204
 205     # first Root auto is called, then Foo auto, then this
 206     sub auto : Private { ... }
 207
 208     # powerful regular expression paths are also possible
 209     sub details : Regex('^product/(\w+)/details$') {
 210         my ( $self, $c ) = @_;
 211         # extract the (\w+) from the URI
 212         my $product = $c->req->captures->[0];
 213     }
 214
 215 See L<Catalyst::Manual::Intro> for additional information.
 216
 217 =head1 DESCRIPTION
 218
 219 Catalyst is a modern framework for making web applications without the
 220 pain usually associated with this process. This document is a reference
 221 to the main Catalyst application. If you are a new user, we suggest you
 222 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 223
 224 See L<Catalyst::Manual> for more documentation.
 225
 226 Catalyst plugins can be loaded by naming them as arguments to the "use
 227 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 228 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 229 C<My::Module>.
 230
 231     use Catalyst qw/My::Module/;
 232
 233 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 234 fully qualify the name by using a unary plus:
 235
 236     use Catalyst qw/
 237         My::Module
 238         +Fully::Qualified::Plugin::Name
 239     /;
 240
 241 Special flags like C<-Debug> and C<-Engine> can also be specified as
 242 arguments when Catalyst is loaded:
 243
 244     use Catalyst qw/-Debug My::Module/;
 245
 246 The position of plugins and flags in the chain is important, because
 247 they are loaded in the order in which they appear.
 248
 249 The following flags are supported:
 250
 251 =head2 -Debug
 252
 253 Enables debug output. You can also force this setting from the system
 254 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 255 settings override the application, with <MYAPP>_DEBUG having the highest
 256 priority.
 257
 258 =head2 -Engine
 259
 260 Forces Catalyst to use a specific engine. Omit the
 261 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 262
 263     use Catalyst qw/-Engine=CGI/;
 264
 265 =head2 -Home
 266
 267 Forces Catalyst to use a specific home directory, e.g.:
 268
 269     use Catalyst qw[-Home=/usr/mst];
 270
 271 This can also be done in the shell environment by setting either the
 272 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 273 is replaced with the uppercased name of your application, any "::" in
 274 the name will be replaced with underscores, e.g. MyApp::Web should use
 275 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 276
 277 =head2 -Log
 278
 279     use Catalyst '-Log=warn,fatal,error';
 280
 281 Specifies a comma-delimited list of log levels.
 282
 283 =head2 -Stats
 284
 285 Enables statistics collection and reporting. You can also force this setting
 286 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 287 environment settings override the application, with <MYAPP>_STATS having the
 288 highest priority.
 289
 290 e.g.
 291
 292    use Catalyst qw/-Stats=1/
 293
 294 =head1 METHODS
 295
 296 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 297
 298 =head2 $c->action
 299
 300 Returns a L<Catalyst::Action> object for the current action, which
 301 stringifies to the action name. See L<Catalyst::Action>.
 302
 303 =head2 $c->namespace
 304
 305 Returns the namespace of the current action, i.e., the URI prefix
 306 corresponding to the controller of the current action. For example:
 307
 308     # in Controller::Foo::Bar
 309     $c->namespace; # returns 'foo/bar';
 310
 311 =head2 $c->request
 312
 313 =head2 $c->req
 314
 315 Returns the current L<Catalyst::Request> object, giving access to
 316 information about the current client request (including parameters,
 317 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 318
 319 =head2 REQUEST FLOW HANDLING
 320
 321 =head2 $c->forward( $action [, \@arguments ] )
 322
 323 =head2 $c->forward( $class, $method, [, \@arguments ] )
 324
 325 Forwards processing to another action, by its private name. If you give a
 326 class name but no method, C<process()> is called. You may also optionally
 327 pass arguments in an arrayref. The action will receive the arguments in
 328 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 329 C<< $c->req->args >> will be restored to the previous values.
 330
 331 Any data C<return>ed from the action forwarded to, will be returned by the
 332 call to forward.
 333
 334     my $foodata = $c->forward('/foo');
 335     $c->forward('index');
 336     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 337     $c->forward('MyApp::View::TT');
 338
 339 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 340 an C<< eval { } >> around the call (actually
 341 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 342 all 'dies' within the called action. If you want C<die> to propagate you
 343 need to do something like:
 344
 345     $c->forward('foo');
 346     die $c->error if $c->error;
 347
 348 Or make sure to always return true values from your actions and write
 349 your code like this:
 350
 351     $c->forward('foo') || return;
 352
 353 Another note is that C<< $c->forward >> always returns a scalar because it
 354 actually returns $c->state which operates in a scalar context.
 355 Thus, something like:
 356
 357     return @array;
 358
 359 in an action that is forwarded to is going to return a scalar,
 360 i.e. how many items are in that array, which is probably not what you want.
 361 If you need to return an array then return a reference to it,
 362 or stash it like so:
 363
 364     $c->stash->{array} = \@array;
 365
 366 and access it from the stash.
 367
 368 =cut
 369
 370 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 371
 372 =head2 $c->detach( $action [, \@arguments ] )
 373
 374 =head2 $c->detach( $class, $method, [, \@arguments ] )
 375
 376 =head2 $c->detach()
 377
 378 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 379 doesn't return to the previous action when processing is finished.
 380
 381 When called with no arguments it escapes the processing chain entirely.
 382
 383 =cut
 384
 385 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 386
 387 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 388
 389 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 390
 391 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 392 but does a full dispatch, instead of just calling the new C<$action> /
 393 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 394 you go to are called, just like a new request.
 395
 396 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 397 This means, for example, that C<< $c->action >> methods such as
 398 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 399 L<reverse|Catalyst::Action/reverse> return information for the visited action
 400 when they are invoked within the visited action.  This is different from the
 401 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 402 continues to use the $c->action object from the caller action even when
 403 invoked from the callee.
 404
 405 C<< $c->stash >> is kept unchanged.
 406
 407 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 408 allows you to "wrap" another action, just as it would have been called by
 409 dispatching from a URL, while the analogous
 410 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 411 transfer control to another action as if it had been reached directly from a URL.
 412
 413 =cut
 414
 415 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 416
 417 =head2 $c->go( $action [, \@captures, \@arguments ] )
 418
 419 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 420
 421 The relationship between C<go> and
 422 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 423 the relationship between
 424 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 425 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 426 C<< $c->go >> will perform a full dispatch on the specified action or method,
 427 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 428 C<go> escapes the processing of the current request chain on completion, and
 429 does not return to its caller.
 430
 431 =cut
 432
 433 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 434
 435 =head2 $c->response
 436
 437 =head2 $c->res
 438
 439 Returns the current L<Catalyst::Response> object, see there for details.
 440
 441 =head2 $c->stash
 442
 443 Returns a hashref to the stash, which may be used to store data and pass
 444 it between components during a request. You can also set hash keys by
 445 passing arguments. The stash is automatically sent to the view. The
 446 stash is cleared at the end of a request; it cannot be used for
 447 persistent storage (for this you must use a session; see
 448 L<Catalyst::Plugin::Session> for a complete system integrated with
 449 Catalyst).
 450
 451     $c->stash->{foo} = $bar;
 452     $c->stash( { moose => 'majestic', qux => 0 } );
 453     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 454
 455     # stash is automatically passed to the view for use in a template
 456     $c->forward( 'MyApp::View::TT' );
 457
 458 =cut
 459
 460 around stash => sub {
 461     my $orig = shift;
 462     my $c = shift;
 463     my $stash = $orig->($c);
 464     if (@_) {
 465         my $new_stash = @_ > 1 ? {@_} : $_[0];
 466         croak('stash takes a hash or hashref') unless ref $new_stash;
 467         foreach my $key ( keys %$new_stash ) {
 468           $stash->{$key} = $new_stash->{$key};
 469         }
 470     }
 471
 472     return $stash;
 473 };
 474
 475
 476 =head2 $c->error
 477
 478 =head2 $c->error($error, ...)
 479
 480 =head2 $c->error($arrayref)
 481
 482 Returns an arrayref containing error messages.  If Catalyst encounters an
 483 error while processing a request, it stores the error in $c->error.  This
 484 method should only be used to store fatal error messages.
 485
 486     my @error = @{ $c->error };
 487
 488 Add a new error.
 489
 490     $c->error('Something bad happened');
 491
 492 =cut
 493
 494 sub error {
 495     my $c = shift;
 496     if ( $_[0] ) {
 497         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 498         croak @$error unless ref $c;
 499         push @{ $c->{error} }, @$error;
 500     }
 501     elsif ( defined $_[0] ) { $c->{error} = undef }
 502     return $c->{error} || [];
 503 }
 504
 505
 506 =head2 $c->state
 507
 508 Contains the return value of the last executed action.
 509 Note that << $c->state >> operates in a scalar context which means that all
 510 values it returns are scalar.
 511
 512 =head2 $c->clear_errors
 513
 514 Clear errors.  You probably don't want to clear the errors unless you are
 515 implementing a custom error screen.
 516
 517 This is equivalent to running
 518
 519     $c->error(0);
 520
 521 =cut
 522
 523 sub clear_errors {
 524     my $c = shift;
 525     $c->error(0);
 526 }
 527
 528 sub _comp_search_prefixes {
 529     my $c = shift;
 530     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 531 }
 532
 533 # search components given a name and some prefixes
 534 sub _comp_names_search_prefixes {
 535     my ( $c, $name, @prefixes ) = @_;
 536     my $appclass = ref $c || $c;
 537     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 538     $filter = qr/$filter/; # Compile regex now rather than once per loop
 539
 540     # map the original component name to the sub part that we will search against
 541     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 542         grep { /$filter/ } keys %{ $c->components };
 543
 544     # undef for a name will return all
 545     return keys %eligible if !defined $name;
 546
 547     my $query  = ref $name ? $name : qr/^$name$/i;
 548     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 549
 550     return @result if @result;
 551
 552     # if we were given a regexp to search against, we're done.
 553     return if ref $name;
 554
 555     # skip regexp fallback if configured
 556     return
 557         if $appclass->config->{disable_component_resolution_regex_fallback};
 558
 559     # regexp fallback
 560     $query  = qr/$name/i;
 561     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 562
 563     # no results? try against full names
 564     if( !@result ) {
 565         @result = grep { m{$query} } keys %eligible;
 566     }
 567
 568     # don't warn if we didn't find any results, it just might not exist
 569     if( @result ) {
 570         # Disgusting hack to work out correct method name
 571         my $warn_for = lc $prefixes[0];
 572         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 573            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 574            "component resolution is unreliable and unsafe.";
 575         my $short = $result[0];
 576         # remove the component namespace prefix
 577         $short =~ s/.*?(Model|Controller|View):://;
 578         my $shortmess = Carp::shortmess('');
 579         if ($shortmess =~ m#Catalyst/Plugin#) {
 580            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 581               "plugin's config";
 582         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 583            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 584               "component's config";
 585         } else {
 586            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 587               "but if you really wanted to search, pass in a regexp as the argument " .
 588               "like so: \$c->${warn_for}(qr/${name}/)";
 589         }
 590         $c->log->warn( "${msg}$shortmess" );
 591     }
 592
 593     return @result;
 594 }
 595
 596 # Find possible names for a prefix
 597 sub _comp_names {
 598     my ( $c, @prefixes ) = @_;
 599     my $appclass = ref $c || $c;
 600
 601     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 602
 603     my @names = map { s{$filter}{}; $_; }
 604         $c->_comp_names_search_prefixes( undef, @prefixes );
 605
 606     return @names;
 607 }
 608
 609 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 610 sub _filter_component {
 611     my ( $c, $comp, @args ) = @_;
 612
 613     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 614         return $comp->ACCEPT_CONTEXT( $c, @args );
 615     }
 616
 617     return $comp;
 618 }
 619
 620 =head2 COMPONENT ACCESSORS
 621
 622 =head2 $c->controller($name)
 623
 624 Gets a L<Catalyst::Controller> instance by name.
 625
 626     $c->controller('Foo')->do_stuff;
 627
 628 If the name is omitted, will return the controller for the dispatched
 629 action.
 630
 631 If you want to search for controllers, pass in a regexp as the argument.
 632
 633     # find all controllers that start with Foo
 634     my @foo_controllers = $c->controller(qr{^Foo});
 635
 636
 637 =cut
 638
 639 sub controller {
 640     my ( $c, $name, @args ) = @_;
 641
 642     if( $name ) {
 643         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 644         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 645         return $c->_filter_component( $result[ 0 ], @args );
 646     }
 647
 648     return $c->component( $c->action->class );
 649 }
 650
 651 =head2 $c->model($name)
 652
 653 Gets a L<Catalyst::Model> instance by name.
 654
 655     $c->model('Foo')->do_stuff;
 656
 657 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 658
 659 If the name is omitted, it will look for
 660  - a model object in $c->stash->{current_model_instance}, then
 661  - a model name in $c->stash->{current_model}, then
 662  - a config setting 'default_model', or
 663  - check if there is only one model, and return it if that's the case.
 664
 665 If you want to search for models, pass in a regexp as the argument.
 666
 667     # find all models that start with Foo
 668     my @foo_models = $c->model(qr{^Foo});
 669
 670 =cut
 671
 672 sub model {
 673     my ( $c, $name, @args ) = @_;
 674     my $appclass = ref($c) || $c;
 675     if( $name ) {
 676         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 677         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 678         return $c->_filter_component( $result[ 0 ], @args );
 679     }
 680
 681     if (ref $c) {
 682         return $c->stash->{current_model_instance}
 683           if $c->stash->{current_model_instance};
 684         return $c->model( $c->stash->{current_model} )
 685           if $c->stash->{current_model};
 686     }
 687     return $c->model( $appclass->config->{default_model} )
 688       if $appclass->config->{default_model};
 689
 690     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 691
 692     if( $rest ) {
 693         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 694         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 695         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 696         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 697         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 698     }
 699
 700     return $c->_filter_component( $comp );
 701 }
 702
 703
 704 =head2 $c->view($name)
 705
 706 Gets a L<Catalyst::View> instance by name.
 707
 708     $c->view('Foo')->do_stuff;
 709
 710 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 711
 712 If the name is omitted, it will look for
 713  - a view object in $c->stash->{current_view_instance}, then
 714  - a view name in $c->stash->{current_view}, then
 715  - a config setting 'default_view', or
 716  - check if there is only one view, and return it if that's the case.
 717
 718 If you want to search for views, pass in a regexp as the argument.
 719
 720     # find all views that start with Foo
 721     my @foo_views = $c->view(qr{^Foo});
 722
 723 =cut
 724
 725 sub view {
 726     my ( $c, $name, @args ) = @_;
 727
 728     my $appclass = ref($c) || $c;
 729     if( $name ) {
 730         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 731         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 732         return $c->_filter_component( $result[ 0 ], @args );
 733     }
 734
 735     if (ref $c) {
 736         return $c->stash->{current_view_instance}
 737           if $c->stash->{current_view_instance};
 738         return $c->view( $c->stash->{current_view} )
 739           if $c->stash->{current_view};
 740     }
 741     return $c->view( $appclass->config->{default_view} )
 742       if $appclass->config->{default_view};
 743
 744     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 745
 746     if( $rest ) {
 747         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 748         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 749         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 750         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 751         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 752     }
 753
 754     return $c->_filter_component( $comp );
 755 }
 756
 757 =head2 $c->controllers
 758
 759 Returns the available names which can be passed to $c->controller
 760
 761 =cut
 762
 763 sub controllers {
 764     my ( $c ) = @_;
 765     return $c->_comp_names(qw/Controller C/);
 766 }
 767
 768 =head2 $c->models
 769
 770 Returns the available names which can be passed to $c->model
 771
 772 =cut
 773
 774 sub models {
 775     my ( $c ) = @_;
 776     return $c->_comp_names(qw/Model M/);
 777 }
 778
 779
 780 =head2 $c->views
 781
 782 Returns the available names which can be passed to $c->view
 783
 784 =cut
 785
 786 sub views {
 787     my ( $c ) = @_;
 788     return $c->_comp_names(qw/View V/);
 789 }
 790
 791 =head2 $c->comp($name)
 792
 793 =head2 $c->component($name)
 794
 795 Gets a component object by name. This method is not recommended,
 796 unless you want to get a specific component by full
 797 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 798 should be used instead.
 799
 800 If C<$name> is a regexp, a list of components matched against the full
 801 component name will be returned.
 802
 803 If Catalyst can't find a component by name, it will fallback to regex
 804 matching by default. To disable this behaviour set
 805 disable_component_resolution_regex_fallback to a true value.
 806
 807     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 808
 809 =cut
 810
 811 sub component {
 812     my ( $c, $name, @args ) = @_;
 813
 814     if( $name ) {
 815         my $comps = $c->components;
 816
 817         if( !ref $name ) {
 818             # is it the exact name?
 819             return $c->_filter_component( $comps->{ $name }, @args )
 820                        if exists $comps->{ $name };
 821
 822             # perhaps we just omitted "MyApp"?
 823             my $composed = ( ref $c || $c ) . "::${name}";
 824             return $c->_filter_component( $comps->{ $composed }, @args )
 825                        if exists $comps->{ $composed };
 826
 827             # search all of the models, views and controllers
 828             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 829             return $c->_filter_component( $comp, @args ) if $comp;
 830         }
 831
 832         # This is here so $c->comp( '::M::' ) works
 833         my $query = ref $name ? $name : qr{$name}i;
 834
 835         my @result = grep { m{$query} } keys %{ $c->components };
 836         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 837
 838         if( $result[ 0 ] ) {
 839             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 840             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 841             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 842             return $c->_filter_component( $result[ 0 ], @args );
 843         }
 844
 845         # I would expect to return an empty list here, but that breaks back-compat
 846     }
 847
 848     # fallback
 849     return sort keys %{ $c->components };
 850 }
 851
 852 =head2 CLASS DATA AND HELPER CLASSES
 853
 854 =head2 $c->config
 855
 856 Returns or takes a hashref containing the application's configuration.
 857
 858     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 859
 860 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 861 like C<myapp.conf> in your applications home directory. See
 862 L<Catalyst::Plugin::ConfigLoader>.
 863
 864 =head3 Cascading configuration
 865
 866 The config method is present on all Catalyst components, and configuration
 867 will be merged when an application is started. Configuration loaded with
 868 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 869 followed by configuration in your top level C<MyApp> class. These two
 870 configurations are merged, and then configuration data whose hash key matches a
 871 component name is merged with configuration for that component.
 872
 873 The configuration for a component is then passed to the C<new> method when a
 874 component is constructed.
 875
 876 For example:
 877
 878     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 879     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 880
 881 will mean that C<MyApp::Model::Foo> receives the following data when
 882 constructed:
 883
 884     MyApp::Model::Foo->new({
 885         bar => 'baz',
 886         quux => 'frob',
 887         overrides => 'me',
 888     });
 889
 890 =cut
 891
 892 around config => sub {
 893     my $orig = shift;
 894     my $c = shift;
 895
 896     croak('Setting config after setup has been run is not allowed.')
 897         if ( @_ and $c->setup_finished );
 898
 899     $c->$orig(@_);
 900 };
 901
 902 =head2 $c->log
 903
 904 Returns the logging object instance. Unless it is already set, Catalyst
 905 sets this up with a L<Catalyst::Log> object. To use your own log class,
 906 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 907 C<< __PACKAGE__->setup >>.
 908
 909  __PACKAGE__->log( MyLogger->new );
 910  __PACKAGE__->setup;
 911
 912 And later:
 913
 914     $c->log->info( 'Now logging with my own logger!' );
 915
 916 Your log class should implement the methods described in
 917 L<Catalyst::Log>.
 918
 919
 920 =head2 $c->debug
 921
 922 Returns 1 if debug mode is enabled, 0 otherwise.
 923
 924 You can enable debug mode in several ways:
 925
 926 =over
 927
 928 =item By calling myapp_server.pl with the -d flag
 929
 930 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 931
 932 =item The -Debug option in your MyApp.pm
 933
 934 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 935
 936 =back
 937
 938 Calling C<< $c->debug(1) >> has no effect.
 939
 940 =cut
 941
 942 sub debug { 0 }
 943
 944 =head2 $c->dispatcher
 945
 946 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 947
 948 =head2 $c->engine
 949
 950 Returns the engine instance. See L<Catalyst::Engine>.
 951
 952
 953 =head2 UTILITY METHODS
 954
 955 =head2 $c->path_to(@path)
 956
 957 Merges C<@path> with C<< $c->config->{home} >> and returns a
 958 L<Path::Class::Dir> object. Note you can usually use this object as
 959 a filename, but sometimes you will have to explicitly stringify it
 960 yourself by calling the C<< ->stringify >> method.
 961
 962 For example:
 963
 964     $c->path_to( 'db', 'sqlite.db' );
 965
 966 =cut
 967
 968 sub path_to {
 969     my ( $c, @path ) = @_;
 970     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 971     if ( -d $path ) { return $path }
 972     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 973 }
 974
 975 =head2 $c->plugin( $name, $class, @args )
 976
 977 Helper method for plugins. It creates a class data accessor/mutator and
 978 loads and instantiates the given class.
 979
 980     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 981
 982     $c->prototype->define_javascript_functions;
 983
 984 B<Note:> This method of adding plugins is deprecated. The ability
 985 to add plugins like this B<will be removed> in a Catalyst 5.81.
 986 Please do not use this functionality in new code.
 987
 988 =cut
 989
 990 sub plugin {
 991     my ( $class, $name, $plugin, @args ) = @_;
 992
 993     # See block comment in t/unit_core_plugin.t
 994     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 995
 996     $class->_register_plugin( $plugin, 1 );
 997
 998     eval { $plugin->import };
 999     $class->mk_classdata($name);
1000     my $obj;
1001     eval { $obj = $plugin->new(@args) };
1002
1003     if ($@) {
1004         Catalyst::Exception->throw( message =>
1005               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1006     }
1007
1008     $class->$name($obj);
1009     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1010       if $class->debug;
1011 }
1012
1013 =head2 MyApp->setup
1014
1015 Initializes the dispatcher and engine, loads any plugins, and loads the
1016 model, view, and controller components. You may also specify an array
1017 of plugins to load here, if you choose to not load them in the C<use
1018 Catalyst> line.
1019
1020     MyApp->setup;
1021     MyApp->setup( qw/-Debug/ );
1022
1023 =cut
1024
1025 sub setup {
1026     my ( $class, @arguments ) = @_;
1027     croak('Running setup more than once')
1028         if ( $class->setup_finished );
1029
1030     unless ( $class->isa('Catalyst') ) {
1031
1032         Catalyst::Exception->throw(
1033             message => qq/'$class' does not inherit from Catalyst/ );
1034     }
1035
1036     if ( $class->arguments ) {
1037         @arguments = ( @arguments, @{ $class->arguments } );
1038     }
1039
1040     # Process options
1041     my $flags = {};
1042
1043     foreach (@arguments) {
1044
1045         if (/^-Debug$/) {
1046             $flags->{log} =
1047               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1048         }
1049         elsif (/^-(\w+)=?(.*)$/) {
1050             $flags->{ lc $1 } = $2;
1051         }
1052         else {
1053             push @{ $flags->{plugins} }, $_;
1054         }
1055     }
1056
1057     $class->setup_home( delete $flags->{home} );
1058
1059     $class->setup_log( delete $flags->{log} );
1060     $class->setup_plugins( delete $flags->{plugins} );
1061     $class->setup_dispatcher( delete $flags->{dispatcher} );
1062     $class->setup_engine( delete $flags->{engine} );
1063     $class->setup_stats( delete $flags->{stats} );
1064
1065     for my $flag ( sort keys %{$flags} ) {
1066
1067         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1068             &$code( $class, delete $flags->{$flag} );
1069         }
1070         else {
1071             $class->log->warn(qq/Unknown flag "$flag"/);
1072         }
1073     }
1074
1075     eval { require Catalyst::Devel; };
1076     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1077         $class->log->warn(<<"EOF");
1078 You are running an old script!
1079
1080   Please update by running (this will overwrite existing files):
1081     catalyst.pl -force -scripts $class
1082
1083   or (this will not overwrite existing files):
1084     catalyst.pl -scripts $class
1085
1086 EOF
1087     }
1088
1089     if ( $class->debug ) {
1090         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1091
1092         if (@plugins) {
1093             my $column_width = Catalyst::Utils::term_width() - 6;
1094             my $t = Text::SimpleTable->new($column_width);
1095             $t->row($_) for @plugins;
1096             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1097         }
1098
1099         my $dispatcher = $class->dispatcher;
1100         my $engine     = $class->engine;
1101         my $home       = $class->config->{home};
1102
1103         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1104         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1105
1106         $home
1107           ? ( -d $home )
1108           ? $class->log->debug(qq/Found home "$home"/)
1109           : $class->log->debug(qq/Home "$home" doesn't exist/)
1110           : $class->log->debug(q/Couldn't find home/);
1111     }
1112
1113     # Call plugins setup, this is stupid and evil.
1114     # Also screws C3 badly on 5.10, hack to avoid.
1115     {
1116         no warnings qw/redefine/;
1117         local *setup = sub { };
1118         $class->setup unless $Catalyst::__AM_RESTARTING;
1119     }
1120
1121     # Initialize our data structure
1122     $class->components( {} );
1123
1124     $class->setup_components;
1125
1126     if ( $class->debug ) {
1127         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1128         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1129         for my $comp ( sort keys %{ $class->components } ) {
1130             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1131             $t->row( $comp, $type );
1132         }
1133         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1134           if ( keys %{ $class->components } );
1135     }
1136
1137     # Add our self to components, since we are also a component
1138     if( $class->isa('Catalyst::Controller') ){
1139       $class->components->{$class} = $class;
1140     }
1141
1142     $class->setup_actions;
1143
1144     if ( $class->debug ) {
1145         my $name = $class->config->{name} || 'Application';
1146         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1147     }
1148     $class->log->_flush() if $class->log->can('_flush');
1149
1150     # Make sure that the application class becomes immutable at this point,
1151     B::Hooks::EndOfScope::on_scope_end {
1152         return if $@;
1153         my $meta = Class::MOP::get_metaclass_by_name($class);
1154         if (
1155             $meta->is_immutable
1156             && ! { $meta->immutable_options }->{replace_constructor}
1157             && (
1158                    $class->isa('Class::Accessor::Fast')
1159                 || $class->isa('Class::Accessor')
1160             )
1161         ) {
1162             warn "You made your application class ($class) immutable, "
1163                 . "but did not inline the\nconstructor. "
1164                 . "This will break catalyst, as your app \@ISA "
1165                 . "Class::Accessor(::Fast)?\nPlease pass "
1166                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1167         }
1168         $meta->make_immutable(
1169             replace_constructor => 1,
1170         ) unless $meta->is_immutable;
1171     };
1172
1173     $class->setup_finalize;
1174 }
1175
1176
1177 =head2 $app->setup_finalize
1178
1179 A hook to attach modifiers to.
1180 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1181 Also better than C< setup_finished(); >, as that is a getter method.
1182
1183     sub setup_finalize {
1184
1185         my $app = shift;
1186
1187         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1188
1189         $app->next::method(@_);
1190
1191
1192     }
1193
1194 =cut
1195
1196 sub setup_finalize {
1197     my ($class) = @_;
1198     $class->setup_finished(1);
1199 }
1200
1201 =head2 $c->uri_for( $path, @args?, \%query_values? )
1202
1203 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1204
1205 Constructs an absolute L<URI> object based on the application root, the
1206 provided path, and the additional arguments and query parameters provided.
1207 When used as a string, provides a textual URI.
1208
1209 If the first argument is a string, it is taken as a public URI path relative
1210 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1211 relative to the application root (if it does). It is then merged with
1212 C<< $c->request->base >>; any C<@args> are appended as additional path
1213 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1214
1215 If the first argument is a L<Catalyst::Action> it represents an action which
1216 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1217 optional C<\@captures> argument (an arrayref) allows passing the captured
1218 variables that are needed to fill in the paths of Chained and Regex actions;
1219 once the path is resolved, C<uri_for> continues as though a path was
1220 provided, appending any arguments or parameters and creating an absolute
1221 URI.
1222
1223 The captures for the current request can be found in
1224 C<< $c->request->captures >>, and actions can be resolved using
1225 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1226 path, use C<< $c->uri_for_action >> instead.
1227
1228   # Equivalent to $c->req->uri
1229   $c->uri_for($c->action, $c->req->captures,
1230       @{ $c->req->args }, $c->req->params);
1231
1232   # For the Foo action in the Bar controller
1233   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1234
1235   # Path to a static resource
1236   $c->uri_for('/static/images/logo.png');
1237
1238 =cut
1239
1240 sub uri_for {
1241     my ( $c, $path, @args ) = @_;
1242
1243     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1244         $path = $path->path_prefix;
1245         $path =~ s{/+\z}{};
1246         $path .= '/';
1247     }
1248
1249     if ( blessed($path) ) { # action object
1250         my $captures = [ map { URI::Escape::uri_escape($_) }
1251                         ( scalar @args && ref $args[0] eq 'ARRAY'
1252                          ? @{ shift(@args) }
1253                          : ()) ];
1254         my $action = $path;
1255         $path = $c->dispatcher->uri_for_action($action, $captures);
1256         if (not defined $path) {
1257             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1258                 if $c->debug;
1259             return undef;
1260         }
1261         $path = '/' if $path eq '';
1262     }
1263
1264     undef($path) if (defined $path && $path eq '');
1265
1266     my $params =
1267       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1268
1269     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1270     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1271
1272     unshift(@args, $path);
1273
1274     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1275         my $namespace = $c->namespace;
1276         if (defined $path) { # cheesy hack to handle path '../foo'
1277            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1278         }
1279         unshift(@args, $namespace || '');
1280     }
1281
1282     # join args with '/', or a blank string
1283     my $args = join('/', grep { defined($_) } @args);
1284     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1285     $args =~ s!^/+!!;
1286     my $base = $c->req->base;
1287     my $class = ref($base);
1288     $base =~ s{(?<!/)$}{/};
1289
1290     my $query = '';
1291
1292     if (my @keys = keys %$params) {
1293       # somewhat lifted from URI::_query's query_form
1294       $query = '?'.join('&', map {
1295           my $val = $params->{$_};
1296           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1297           s/ /+/g;
1298           my $key = $_;
1299           $val = '' unless defined $val;
1300           (map {
1301               my $param = "$_";
1302               utf8::encode( $param ) if utf8::is_utf8($param);
1303               # using the URI::Escape pattern here so utf8 chars survive
1304               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1305               $param =~ s/ /+/g;
1306               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1307       } @keys);
1308     }
1309
1310     my $res = bless(\"${base}${args}${query}", $class);
1311     $res;
1312 }
1313
1314 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1315
1316 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1317
1318 =over
1319
1320 =item $path
1321
1322 A private path to the Catalyst action you want to create a URI for.
1323
1324 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1325 >> and passing the resulting C<$action> and the remaining arguments to C<<
1326 $c->uri_for >>.
1327
1328 You can also pass in a Catalyst::Action object, in which case it is passed to
1329 C<< $c->uri_for >>.
1330
1331 =back
1332
1333 =cut
1334
1335 sub uri_for_action {
1336     my ( $c, $path, @args ) = @_;
1337     my $action = blessed($path)
1338       ? $path
1339       : $c->dispatcher->get_action_by_path($path);
1340     unless (defined $action) {
1341       croak "Can't find action for path '$path'";
1342     }
1343     return $c->uri_for( $action, @args );
1344 }
1345
1346 =head2 $c->welcome_message
1347
1348 Returns the Catalyst welcome HTML page.
1349
1350 =cut
1351
1352 sub welcome_message {
1353     my $c      = shift;
1354     my $name   = $c->config->{name};
1355     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1356     my $prefix = Catalyst::Utils::appprefix( ref $c );
1357     $c->response->content_type('text/html; charset=utf-8');
1358     return <<"EOF";
1359 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1360     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1361 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1362     <head>
1363     <meta http-equiv="Content-Language" content="en" />
1364     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1365         <title>$name on Catalyst $VERSION</title>
1366         <style type="text/css">
1367             body {
1368                 color: #000;
1369                 background-color: #eee;
1370             }
1371             div#content {
1372                 width: 640px;
1373                 margin-left: auto;
1374                 margin-right: auto;
1375                 margin-top: 10px;
1376                 margin-bottom: 10px;
1377                 text-align: left;
1378                 background-color: #ccc;
1379                 border: 1px solid #aaa;
1380             }
1381             p, h1, h2 {
1382                 margin-left: 20px;
1383                 margin-right: 20px;
1384                 font-family: verdana, tahoma, sans-serif;
1385             }
1386             a {
1387                 font-family: verdana, tahoma, sans-serif;
1388             }
1389             :link, :visited {
1390                     text-decoration: none;
1391                     color: #b00;
1392                     border-bottom: 1px dotted #bbb;
1393             }
1394             :link:hover, :visited:hover {
1395                     color: #555;
1396             }
1397             div#topbar {
1398                 margin: 0px;
1399             }
1400             pre {
1401                 margin: 10px;
1402                 padding: 8px;
1403             }
1404             div#answers {
1405                 padding: 8px;
1406                 margin: 10px;
1407                 background-color: #fff;
1408                 border: 1px solid #aaa;
1409             }
1410             h1 {
1411                 font-size: 0.9em;
1412                 font-weight: normal;
1413                 text-align: center;
1414             }
1415             h2 {
1416                 font-size: 1.0em;
1417             }
1418             p {
1419                 font-size: 0.9em;
1420             }
1421             p img {
1422                 float: right;
1423                 margin-left: 10px;
1424             }
1425             span#appname {
1426                 font-weight: bold;
1427                 font-size: 1.6em;
1428             }
1429         </style>
1430     </head>
1431     <body>
1432         <div id="content">
1433             <div id="topbar">
1434                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1435                     $VERSION</h1>
1436              </div>
1437              <div id="answers">
1438                  <p>
1439                  <img src="$logo" alt="Catalyst Logo" />
1440                  </p>
1441                  <p>Welcome to the  world of Catalyst.
1442                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1443                     framework will make web development something you had
1444                     never expected it to be: Fun, rewarding, and quick.</p>
1445                  <h2>What to do now?</h2>
1446                  <p>That really depends  on what <b>you</b> want to do.
1447                     We do, however, provide you with a few starting points.</p>
1448                  <p>If you want to jump right into web development with Catalyst
1449                     you might want to start with a tutorial.</p>
1450 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1451 </pre>
1452 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1453 <pre>
1454 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1455 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1456 </code></pre>
1457                  <h2>What to do next?</h2>
1458                  <p>Next it's time to write an actual application. Use the
1459                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1460                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1461                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1462                     they can save you a lot of work.</p>
1463                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1464                     <p>Also, be sure to check out the vast and growing
1465                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1466                     you are likely to find what you need there.
1467                     </p>
1468
1469                  <h2>Need help?</h2>
1470                  <p>Catalyst has a very active community. Here are the main places to
1471                     get in touch with us.</p>
1472                  <ul>
1473                      <li>
1474                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1475                      </li>
1476                      <li>
1477                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1478                      </li>
1479                      <li>
1480                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1481                      </li>
1482                  </ul>
1483                  <h2>In conclusion</h2>
1484                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1485                     as we enjoyed making it. Please contact us if you have ideas
1486                     for improvement or other feedback.</p>
1487              </div>
1488          </div>
1489     </body>
1490 </html>
1491 EOF
1492 }
1493
1494 =head1 INTERNAL METHODS
1495
1496 These methods are not meant to be used by end users.
1497
1498 =head2 $c->components
1499
1500 Returns a hash of components.
1501
1502 =head2 $c->context_class
1503
1504 Returns or sets the context class.
1505
1506 =head2 $c->counter
1507
1508 Returns a hashref containing coderefs and execution counts (needed for
1509 deep recursion detection).
1510
1511 =head2 $c->depth
1512
1513 Returns the number of actions on the current internal execution stack.
1514
1515 =head2 $c->dispatch
1516
1517 Dispatches a request to actions.
1518
1519 =cut
1520
1521 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1522
1523 =head2 $c->dispatcher_class
1524
1525 Returns or sets the dispatcher class.
1526
1527 =head2 $c->dump_these
1528
1529 Returns a list of 2-element array references (name, structure) pairs
1530 that will be dumped on the error page in debug mode.
1531
1532 =cut
1533
1534 sub dump_these {
1535     my $c = shift;
1536     [ Request => $c->req ],
1537     [ Response => $c->res ],
1538     [ Stash => $c->stash ],
1539     [ Config => $c->config ];
1540 }
1541
1542 =head2 $c->engine_class
1543
1544 Returns or sets the engine class.
1545
1546 =head2 $c->execute( $class, $coderef )
1547
1548 Execute a coderef in given class and catch exceptions. Errors are available
1549 via $c->error.
1550
1551 =cut
1552
1553 sub execute {
1554     my ( $c, $class, $code ) = @_;
1555     $class = $c->component($class) || $class;
1556     $c->state(0);
1557
1558     if ( $c->depth >= $RECURSION ) {
1559         my $action = $code->reverse();
1560         $action = "/$action" unless $action =~ /->/;
1561         my $error = qq/Deep recursion detected calling "${action}"/;
1562         $c->log->error($error);
1563         $c->error($error);
1564         $c->state(0);
1565         return $c->state;
1566     }
1567
1568     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1569
1570     push( @{ $c->stack }, $code );
1571
1572     no warnings 'recursion';
1573     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1574
1575     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1576
1577     my $last = pop( @{ $c->stack } );
1578
1579     if ( my $error = $@ ) {
1580         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1581             $error->rethrow if $c->depth > 1;
1582         }
1583         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1584             $error->rethrow if $c->depth > 0;
1585         }
1586         else {
1587             unless ( ref $error ) {
1588                 no warnings 'uninitialized';
1589                 chomp $error;
1590                 my $class = $last->class;
1591                 my $name  = $last->name;
1592                 $error = qq/Caught exception in $class->$name "$error"/;
1593             }
1594             $c->error($error);
1595             $c->state(0);
1596         }
1597     }
1598     return $c->state;
1599 }
1600
1601 sub _stats_start_execute {
1602     my ( $c, $code ) = @_;
1603     my $appclass = ref($c) || $c;
1604     return if ( ( $code->name =~ /^_.*/ )
1605         && ( !$appclass->config->{show_internal_actions} ) );
1606
1607     my $action_name = $code->reverse();
1608     $c->counter->{$action_name}++;
1609
1610     my $action = $action_name;
1611     $action = "/$action" unless $action =~ /->/;
1612
1613     # determine if the call was the result of a forward
1614     # this is done by walking up the call stack and looking for a calling
1615     # sub of Catalyst::forward before the eval
1616     my $callsub = q{};
1617     for my $index ( 2 .. 11 ) {
1618         last
1619         if ( ( caller($index) )[0] eq 'Catalyst'
1620             && ( caller($index) )[3] eq '(eval)' );
1621
1622         if ( ( caller($index) )[3] =~ /forward$/ ) {
1623             $callsub = ( caller($index) )[3];
1624             $action  = "-> $action";
1625             last;
1626         }
1627     }
1628
1629     my $uid = $action_name . $c->counter->{$action_name};
1630
1631     # is this a root-level call or a forwarded call?
1632     if ( $callsub =~ /forward$/ ) {
1633         my $parent = $c->stack->[-1];
1634
1635         # forward, locate the caller
1636         if ( exists $c->counter->{"$parent"} ) {
1637             $c->stats->profile(
1638                 begin  => $action,
1639                 parent => "$parent" . $c->counter->{"$parent"},
1640                 uid    => $uid,
1641             );
1642         }
1643         else {
1644
1645             # forward with no caller may come from a plugin
1646             $c->stats->profile(
1647                 begin => $action,
1648                 uid   => $uid,
1649             );
1650         }
1651     }
1652     else {
1653
1654         # root-level call
1655         $c->stats->profile(
1656             begin => $action,
1657             uid   => $uid,
1658         );
1659     }
1660     return $action;
1661
1662 }
1663
1664 sub _stats_finish_execute {
1665     my ( $c, $info ) = @_;
1666     $c->stats->profile( end => $info );
1667 }
1668
1669 =head2 $c->finalize
1670
1671 Finalizes the request.
1672
1673 =cut
1674
1675 sub finalize {
1676     my $c = shift;
1677
1678     for my $error ( @{ $c->error } ) {
1679         $c->log->error($error);
1680     }
1681
1682     # Allow engine to handle finalize flow (for POE)
1683     my $engine = $c->engine;
1684     if ( my $code = $engine->can('finalize') ) {
1685         $engine->$code($c);
1686     }
1687     else {
1688
1689         $c->finalize_uploads;
1690
1691         # Error
1692         if ( $#{ $c->error } >= 0 ) {
1693             $c->finalize_error;
1694         }
1695
1696         $c->finalize_headers;
1697
1698         # HEAD request
1699         if ( $c->request->method eq 'HEAD' ) {
1700             $c->response->body('');
1701         }
1702
1703         $c->finalize_body;
1704     }
1705
1706     if ($c->use_stats) {
1707         my $elapsed = sprintf '%f', $c->stats->elapsed;
1708         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1709         $c->log->info(
1710             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1711     }
1712
1713     return $c->response->status;
1714 }
1715
1716 =head2 $c->finalize_body
1717
1718 Finalizes body.
1719
1720 =cut
1721
1722 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1723
1724 =head2 $c->finalize_cookies
1725
1726 Finalizes cookies.
1727
1728 =cut
1729
1730 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1731
1732 =head2 $c->finalize_error
1733
1734 Finalizes error.
1735
1736 =cut
1737
1738 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1739
1740 =head2 $c->finalize_headers
1741
1742 Finalizes headers.
1743
1744 =cut
1745
1746 sub finalize_headers {
1747     my $c = shift;
1748
1749     my $response = $c->response; #accessor calls can add up?
1750
1751     # Check if we already finalized headers
1752     return if $response->finalized_headers;
1753
1754     # Handle redirects
1755     if ( my $location = $response->redirect ) {
1756         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1757         $response->header( Location => $location );
1758
1759         if ( !$response->has_body ) {
1760             # Add a default body if none is already present
1761             $response->body(
1762                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1763             );
1764         }
1765     }
1766
1767     # Content-Length
1768     if ( $response->body && !$response->content_length ) {
1769
1770         # get the length from a filehandle
1771         if ( blessed( $response->body ) && $response->body->can('read') )
1772         {
1773             my $stat = stat $response->body;
1774             if ( $stat && $stat->size > 0 ) {
1775                 $response->content_length( $stat->size );
1776             }
1777             else {
1778                 $c->log->warn('Serving filehandle without a content-length');
1779             }
1780         }
1781         else {
1782             # everything should be bytes at this point, but just in case
1783             $response->content_length( bytes::length( $response->body ) );
1784         }
1785     }
1786
1787     # Errors
1788     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1789         $response->headers->remove_header("Content-Length");
1790         $response->body('');
1791     }
1792
1793     $c->finalize_cookies;
1794
1795     $c->engine->finalize_headers( $c, @_ );
1796
1797     # Done
1798     $response->finalized_headers(1);
1799 }
1800
1801 =head2 $c->finalize_output
1802
1803 An alias for finalize_body.
1804
1805 =head2 $c->finalize_read
1806
1807 Finalizes the input after reading is complete.
1808
1809 =cut
1810
1811 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1812
1813 =head2 $c->finalize_uploads
1814
1815 Finalizes uploads. Cleans up any temporary files.
1816
1817 =cut
1818
1819 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1820
1821 =head2 $c->get_action( $action, $namespace )
1822
1823 Gets an action in a given namespace.
1824
1825 =cut
1826
1827 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1828
1829 =head2 $c->get_actions( $action, $namespace )
1830
1831 Gets all actions of a given name in a namespace and all parent
1832 namespaces.
1833
1834 =cut
1835
1836 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1837
1838 =head2 $c->handle_request( $class, @arguments )
1839
1840 Called to handle each HTTP request.
1841
1842 =cut
1843
1844 sub handle_request {
1845     my ( $class, @arguments ) = @_;
1846
1847     # Always expect worst case!
1848     my $status = -1;
1849     eval {
1850         if ($class->debug) {
1851             my $secs = time - $START || 1;
1852             my $av = sprintf '%.3f', $COUNT / $secs;
1853             my $time = localtime time;
1854             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1855         }
1856
1857         my $c = $class->prepare(@arguments);
1858         $c->dispatch;
1859         $status = $c->finalize;
1860     };
1861
1862     if ( my $error = $@ ) {
1863         chomp $error;
1864         $class->log->error(qq/Caught exception in engine "$error"/);
1865     }
1866
1867     $COUNT++;
1868
1869     if(my $coderef = $class->log->can('_flush')){
1870         $class->log->$coderef();
1871     }
1872     return $status;
1873 }
1874
1875 =head2 $c->prepare( @arguments )
1876
1877 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1878 etc.).
1879
1880 =cut
1881
1882 sub prepare {
1883     my ( $class, @arguments ) = @_;
1884
1885     # XXX
1886     # After the app/ctxt split, this should become an attribute based on something passed
1887     # into the application.
1888     $class->context_class( ref $class || $class ) unless $class->context_class;
1889
1890     my $c = $class->context_class->new({});
1891
1892     # For on-demand data
1893     $c->request->_context($c);
1894     $c->response->_context($c);
1895
1896     #surely this is not the most efficient way to do things...
1897     $c->stats($class->stats_class->new)->enable($c->use_stats);
1898     if ( $c->debug ) {
1899         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1900     }
1901
1902     #XXX reuse coderef from can
1903     # Allow engine to direct the prepare flow (for POE)
1904     if ( $c->engine->can('prepare') ) {
1905         $c->engine->prepare( $c, @arguments );
1906     }
1907     else {
1908         $c->prepare_request(@arguments);
1909         $c->prepare_connection;
1910         $c->prepare_query_parameters;
1911         $c->prepare_headers;
1912         $c->prepare_cookies;
1913         $c->prepare_path;
1914
1915         # Prepare the body for reading, either by prepare_body
1916         # or the user, if they are using $c->read
1917         $c->prepare_read;
1918
1919         # Parse the body unless the user wants it on-demand
1920         unless ( ref($c)->config->{parse_on_demand} ) {
1921             $c->prepare_body;
1922         }
1923     }
1924
1925     my $method  = $c->req->method  || '';
1926     my $path    = $c->req->path;
1927     $path       = '/' unless length $path;
1928     my $address = $c->req->address || '';
1929
1930     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1931       if $c->debug;
1932
1933     $c->prepare_action;
1934
1935     return $c;
1936 }
1937
1938 =head2 $c->prepare_action
1939
1940 Prepares action. See L<Catalyst::Dispatcher>.
1941
1942 =cut
1943
1944 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1945
1946 =head2 $c->prepare_body
1947
1948 Prepares message body.
1949
1950 =cut
1951
1952 sub prepare_body {
1953     my $c = shift;
1954
1955     return if $c->request->_has_body;
1956
1957     # Initialize on-demand data
1958     $c->engine->prepare_body( $c, @_ );
1959     $c->prepare_parameters;
1960     $c->prepare_uploads;
1961
1962     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1963         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1964         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1965             my $param = $c->req->body_parameters->{$key};
1966             my $value = defined($param) ? $param : '';
1967             $t->row( $key,
1968                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1969         }
1970         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1971     }
1972 }
1973
1974 =head2 $c->prepare_body_chunk( $chunk )
1975
1976 Prepares a chunk of data before sending it to L<HTTP::Body>.
1977
1978 See L<Catalyst::Engine>.
1979
1980 =cut
1981
1982 sub prepare_body_chunk {
1983     my $c = shift;
1984     $c->engine->prepare_body_chunk( $c, @_ );
1985 }
1986
1987 =head2 $c->prepare_body_parameters
1988
1989 Prepares body parameters.
1990
1991 =cut
1992
1993 sub prepare_body_parameters {
1994     my $c = shift;
1995     $c->engine->prepare_body_parameters( $c, @_ );
1996 }
1997
1998 =head2 $c->prepare_connection
1999
2000 Prepares connection.
2001
2002 =cut
2003
2004 sub prepare_connection {
2005     my $c = shift;
2006     $c->engine->prepare_connection( $c, @_ );
2007 }
2008
2009 =head2 $c->prepare_cookies
2010
2011 Prepares cookies.
2012
2013 =cut
2014
2015 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2016
2017 =head2 $c->prepare_headers
2018
2019 Prepares headers.
2020
2021 =cut
2022
2023 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2024
2025 =head2 $c->prepare_parameters
2026
2027 Prepares parameters.
2028
2029 =cut
2030
2031 sub prepare_parameters {
2032     my $c = shift;
2033     $c->prepare_body_parameters;
2034     $c->engine->prepare_parameters( $c, @_ );
2035 }
2036
2037 =head2 $c->prepare_path
2038
2039 Prepares path and base.
2040
2041 =cut
2042
2043 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2044
2045 =head2 $c->prepare_query_parameters
2046
2047 Prepares query parameters.
2048
2049 =cut
2050
2051 sub prepare_query_parameters {
2052     my $c = shift;
2053
2054     $c->engine->prepare_query_parameters( $c, @_ );
2055
2056     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2057         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2058         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2059             my $param = $c->req->query_parameters->{$key};
2060             my $value = defined($param) ? $param : '';
2061             $t->row( $key,
2062                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2063         }
2064         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2065     }
2066 }
2067
2068 =head2 $c->prepare_read
2069
2070 Prepares the input for reading.
2071
2072 =cut
2073
2074 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2075
2076 =head2 $c->prepare_request
2077
2078 Prepares the engine request.
2079
2080 =cut
2081
2082 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2083
2084 =head2 $c->prepare_uploads
2085
2086 Prepares uploads.
2087
2088 =cut
2089
2090 sub prepare_uploads {
2091     my $c = shift;
2092
2093     $c->engine->prepare_uploads( $c, @_ );
2094
2095     if ( $c->debug && keys %{ $c->request->uploads } ) {
2096         my $t = Text::SimpleTable->new(
2097             [ 12, 'Parameter' ],
2098             [ 26, 'Filename' ],
2099             [ 18, 'Type' ],
2100             [ 9,  'Size' ]
2101         );
2102         for my $key ( sort keys %{ $c->request->uploads } ) {
2103             my $upload = $c->request->uploads->{$key};
2104             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2105                 $t->row( $key, $u->filename, $u->type, $u->size );
2106             }
2107         }
2108         $c->log->debug( "File Uploads are:\n" . $t->draw );
2109     }
2110 }
2111
2112 =head2 $c->prepare_write
2113
2114 Prepares the output for writing.
2115
2116 =cut
2117
2118 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2119
2120 =head2 $c->request_class
2121
2122 Returns or sets the request class.
2123
2124 =head2 $c->response_class
2125
2126 Returns or sets the response class.
2127
2128 =head2 $c->read( [$maxlength] )
2129
2130 Reads a chunk of data from the request body. This method is designed to
2131 be used in a while loop, reading C<$maxlength> bytes on every call.
2132 C<$maxlength> defaults to the size of the request if not specified.
2133
2134 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2135 directly.
2136
2137 Warning: If you use read(), Catalyst will not process the body,
2138 so you will not be able to access POST parameters or file uploads via
2139 $c->request.  You must handle all body parsing yourself.
2140
2141 =cut
2142
2143 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2144
2145 =head2 $c->run
2146
2147 Starts the engine.
2148
2149 =cut
2150
2151 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2152
2153 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2154
2155 Sets an action in a given namespace.
2156
2157 =cut
2158
2159 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2160
2161 =head2 $c->setup_actions($component)
2162
2163 Sets up actions for a component.
2164
2165 =cut
2166
2167 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2168
2169 =head2 $c->setup_components
2170
2171 This method is called internally to set up the application's components.
2172
2173 It finds modules by calling the L<locate_components> method, expands them to
2174 package names with the L<expand_component_module> method, and then installs
2175 each component into the application.
2176
2177 The C<setup_components> config option is passed to both of the above methods.
2178
2179 Installation of each component is performed by the L<setup_component> method,
2180 below.
2181
2182 =cut
2183
2184 sub setup_components {
2185     my $class = shift;
2186
2187     my $config  = $class->config->{ setup_components };
2188
2189     my @comps = sort { length $a <=> length $b }
2190                 $class->locate_components($config);
2191     my %comps = map { $_ => 1 } @comps;
2192
2193     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2194     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2195         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2196     ) if $deprecatedcatalyst_component_names;
2197
2198     for my $component ( @comps ) {
2199
2200         # We pass ignore_loaded here so that overlay files for (e.g.)
2201         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2202         # we know M::P::O found a file on disk so this is safe
2203
2204         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2205
2206         # Needs to be done as soon as the component is loaded, as loading a sub-component
2207         # (next time round the loop) can cause us to get the wrong metaclass..
2208         $class->_controller_init_base_classes($component);
2209     }
2210
2211     for my $component (@comps) {
2212         $class->components->{ $component } = $class->setup_component($component);
2213         for my $component ($class->expand_component_module( $component, $config )) {
2214             next if $comps{$component};
2215             $class->_controller_init_base_classes($component); # Also cover inner packages
2216             $class->components->{ $component } = $class->setup_component($component);
2217         }
2218     }
2219 }
2220
2221 =head2 $c->locate_components( $setup_component_config )
2222
2223 This method is meant to provide a list of component modules that should be
2224 setup for the application.  By default, it will use L<Module::Pluggable>.
2225
2226 Specify a C<setup_components> config option to pass additional options directly
2227 to L<Module::Pluggable>. To add additional search paths, specify a key named
2228 C<search_extra> as an array reference. Items in the array beginning with C<::>
2229 will have the application class name prepended to them.
2230
2231 =cut
2232
2233 sub locate_components {
2234     my $class  = shift;
2235     my $config = shift;
2236
2237     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2238     my $extra   = delete $config->{ search_extra } || [];
2239
2240     push @paths, @$extra;
2241
2242     my $locator = Module::Pluggable::Object->new(
2243         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2244         %$config
2245     );
2246
2247     my @comps = $locator->plugins;
2248
2249     return @comps;
2250 }
2251
2252 =head2 $c->expand_component_module( $component, $setup_component_config )
2253
2254 Components found by C<locate_components> will be passed to this method, which
2255 is expected to return a list of component (package) names to be set up.
2256
2257 =cut
2258
2259 sub expand_component_module {
2260     my ($class, $module) = @_;
2261     return Devel::InnerPackage::list_packages( $module );
2262 }
2263
2264 =head2 $c->setup_component
2265
2266 =cut
2267
2268 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2269 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2270 #         to be loaded. There are TODO tests in Moose for this, see
2271 #         f2391d17574eff81d911b97be15ea51080500003
2272 sub _controller_init_base_classes {
2273     my ($app_class, $component) = @_;
2274     return unless $component->isa('Catalyst::Controller');
2275     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2276         Moose::Meta::Class->initialize( $class )
2277             unless find_meta($class);
2278     }
2279 }
2280
2281 sub setup_component {
2282     my( $class, $component ) = @_;
2283
2284     unless ( $component->can( 'COMPONENT' ) ) {
2285         return $component;
2286     }
2287
2288     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2289     my $config = $class->config->{ $suffix } || {};
2290     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2291     # methods also pass it. local to avoid pointlessly shitting in config
2292     # for the debug screen, as $component is already the key name.
2293     local $config->{catalyst_component_name} = $component;
2294
2295     my $instance = eval { $component->COMPONENT( $class, $config ); };
2296
2297     if ( my $error = $@ ) {
2298         chomp $error;
2299         Catalyst::Exception->throw(
2300             message => qq/Couldn't instantiate component "$component", "$error"/
2301         );
2302     }
2303
2304     unless (blessed $instance) {
2305         my $metaclass = Moose::Util::find_meta($component);
2306         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2307         my $component_method_from = $method_meta->associated_metaclass->name;
2308         my $value = defined($instance) ? $instance : 'undef';
2309         Catalyst::Exception->throw(
2310             message =>
2311             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2312         );
2313     }
2314     return $instance;
2315 }
2316
2317 =head2 $c->setup_dispatcher
2318
2319 Sets up dispatcher.
2320
2321 =cut
2322
2323 sub setup_dispatcher {
2324     my ( $class, $dispatcher ) = @_;
2325
2326     if ($dispatcher) {
2327         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2328     }
2329
2330     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2331         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2332     }
2333
2334     unless ($dispatcher) {
2335         $dispatcher = $class->dispatcher_class;
2336     }
2337
2338     Class::MOP::load_class($dispatcher);
2339
2340     # dispatcher instance
2341     $class->dispatcher( $dispatcher->new );
2342 }
2343
2344 =head2 $c->setup_engine
2345
2346 Sets up engine.
2347
2348 =cut
2349
2350 sub setup_engine {
2351     my ( $class, $engine ) = @_;
2352
2353     if ($engine) {
2354         $engine = 'Catalyst::Engine::' . $engine;
2355     }
2356
2357     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2358         $engine = 'Catalyst::Engine::' . $env;
2359     }
2360
2361     if ( $ENV{MOD_PERL} ) {
2362         my $meta = Class::MOP::get_metaclass_by_name($class);
2363
2364         # create the apache method
2365         $meta->add_method('apache' => sub { shift->engine->apache });
2366
2367         my ( $software, $version ) =
2368           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2369
2370         $version =~ s/_//g;
2371         $version =~ s/(\.[^.]+)\./$1/g;
2372
2373         if ( $software eq 'mod_perl' ) {
2374
2375             if ( !$engine ) {
2376
2377                 if ( $version >= 1.99922 ) {
2378                     $engine = 'Catalyst::Engine::Apache2::MP20';
2379                 }
2380
2381                 elsif ( $version >= 1.9901 ) {
2382                     $engine = 'Catalyst::Engine::Apache2::MP19';
2383                 }
2384
2385                 elsif ( $version >= 1.24 ) {
2386                     $engine = 'Catalyst::Engine::Apache::MP13';
2387                 }
2388
2389                 else {
2390                     Catalyst::Exception->throw( message =>
2391                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2392                 }
2393
2394             }
2395
2396             # install the correct mod_perl handler
2397             if ( $version >= 1.9901 ) {
2398                 *handler = sub  : method {
2399                     shift->handle_request(@_);
2400                 };
2401             }
2402             else {
2403                 *handler = sub ($$) { shift->handle_request(@_) };
2404             }
2405
2406         }
2407
2408         elsif ( $software eq 'Zeus-Perl' ) {
2409             $engine = 'Catalyst::Engine::Zeus';
2410         }
2411
2412         else {
2413             Catalyst::Exception->throw(
2414                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2415         }
2416     }
2417
2418     unless ($engine) {
2419         $engine = $class->engine_class;
2420     }
2421
2422     Class::MOP::load_class($engine);
2423
2424     # check for old engines that are no longer compatible
2425     my $old_engine;
2426     if ( $engine->isa('Catalyst::Engine::Apache')
2427         && !Catalyst::Engine::Apache->VERSION )
2428     {
2429         $old_engine = 1;
2430     }
2431
2432     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2433         && Catalyst::Engine::Server->VERSION le '0.02' )
2434     {
2435         $old_engine = 1;
2436     }
2437
2438     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2439         && $engine->VERSION eq '0.01' )
2440     {
2441         $old_engine = 1;
2442     }
2443
2444     elsif ($engine->isa('Catalyst::Engine::Zeus')
2445         && $engine->VERSION eq '0.01' )
2446     {
2447         $old_engine = 1;
2448     }
2449
2450     if ($old_engine) {
2451         Catalyst::Exception->throw( message =>
2452               qq/Engine "$engine" is not supported by this version of Catalyst/
2453         );
2454     }
2455
2456     # engine instance
2457     $class->engine( $engine->new );
2458 }
2459
2460 =head2 $c->setup_home
2461
2462 Sets up the home directory.
2463
2464 =cut
2465
2466 sub setup_home {
2467     my ( $class, $home ) = @_;
2468
2469     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2470         $home = $env;
2471     }
2472
2473     $home ||= Catalyst::Utils::home($class);
2474
2475     if ($home) {
2476         #I remember recently being scolded for assigning config values like this
2477         $class->config->{home} ||= $home;
2478         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2479     }
2480 }
2481
2482 =head2 $c->setup_log
2483
2484 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2485 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2486 log to.
2487
2488 This method also installs a C<debug> method that returns a true value into the
2489 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2490 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2491
2492 Note that if the log has already been setup, by either a previous call to
2493 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2494 that this method won't actually set up the log object.
2495
2496 =cut
2497
2498 sub setup_log {
2499     my ( $class, $levels ) = @_;
2500
2501     $levels ||= '';
2502     $levels =~ s/^\s+//;
2503     $levels =~ s/\s+$//;
2504     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2505
2506     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2507     if ( defined $env_debug ) {
2508         $levels{debug} = 1 if $env_debug; # Ugly!
2509         delete($levels{debug}) unless $env_debug;
2510     }
2511
2512     unless ( $class->log ) {
2513         $class->log( Catalyst::Log->new(keys %levels) );
2514     }
2515
2516     if ( $levels{debug} ) {
2517         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2518         $class->log->debug('Debug messages enabled');
2519     }
2520 }
2521
2522 =head2 $c->setup_plugins
2523
2524 Sets up plugins.
2525
2526 =cut
2527
2528 =head2 $c->setup_stats
2529
2530 Sets up timing statistics class.
2531
2532 =cut
2533
2534 sub setup_stats {
2535     my ( $class, $stats ) = @_;
2536
2537     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2538
2539     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2540     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2541         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2542         $class->log->debug('Statistics enabled');
2543     }
2544 }
2545
2546
2547 =head2 $c->registered_plugins
2548
2549 Returns a sorted list of the plugins which have either been stated in the
2550 import list or which have been added via C<< MyApp->plugin(@args); >>.
2551
2552 If passed a given plugin name, it will report a boolean value indicating
2553 whether or not that plugin is loaded.  A fully qualified name is required if
2554 the plugin name does not begin with C<Catalyst::Plugin::>.
2555
2556  if ($c->registered_plugins('Some::Plugin')) {
2557      ...
2558  }
2559
2560 =cut
2561
2562 {
2563
2564     sub registered_plugins {
2565         my $proto = shift;
2566         return sort keys %{ $proto->_plugins } unless @_;
2567         my $plugin = shift;
2568         return 1 if exists $proto->_plugins->{$plugin};
2569         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2570     }
2571
2572     sub _register_plugin {
2573         my ( $proto, $plugin, $instant ) = @_;
2574         my $class = ref $proto || $proto;
2575
2576         Class::MOP::load_class( $plugin );
2577
2578         $proto->_plugins->{$plugin} = 1;
2579         unless ($instant) {
2580             no strict 'refs';
2581             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2582               my @superclasses = ($plugin, $meta->superclasses );
2583               $meta->superclasses(@superclasses);
2584             } else {
2585               unshift @{"$class\::ISA"}, $plugin;
2586             }
2587         }
2588         return $class;
2589     }
2590
2591     sub setup_plugins {
2592         my ( $class, $plugins ) = @_;
2593
2594         $class->_plugins( {} ) unless $class->_plugins;
2595         $plugins ||= [];
2596
2597         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2598
2599         for my $plugin ( reverse @plugins ) {
2600             Class::MOP::load_class($plugin);
2601             my $meta = find_meta($plugin);
2602             next if $meta && $meta->isa('Moose::Meta::Role');
2603
2604             $class->_register_plugin($plugin);
2605         }
2606
2607         my @roles =
2608             map { $_->name }
2609             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2610             map { find_meta($_) }
2611             @plugins;
2612
2613         Moose::Util::apply_all_roles(
2614             $class => @roles
2615         ) if @roles;
2616     }
2617 }
2618
2619 =head2 $c->stack
2620
2621 Returns an arrayref of the internal execution stack (actions that are
2622 currently executing).
2623
2624 =head2 $c->stats_class
2625
2626 Returns or sets the stats (timing statistics) class.
2627
2628 =head2 $c->use_stats
2629
2630 Returns 1 when stats collection is enabled.  Stats collection is enabled
2631 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2632 environment variable is set.
2633
2634 Note that this is a static method, not an accessor and should be overridden
2635 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2636
2637 =cut
2638
2639 sub use_stats { 0 }
2640
2641
2642 =head2 $c->write( $data )
2643
2644 Writes $data to the output stream. When using this method directly, you
2645 will need to manually set the C<Content-Length> header to the length of
2646 your output data, if known.
2647
2648 =cut
2649
2650 sub write {
2651     my $c = shift;
2652
2653     # Finalize headers if someone manually writes output
2654     $c->finalize_headers;
2655
2656     return $c->engine->write( $c, @_ );
2657 }
2658
2659 =head2 version
2660
2661 Returns the Catalyst version number. Mostly useful for "powered by"
2662 messages in template systems.
2663
2664 =cut
2665
2666 sub version { return $Catalyst::VERSION }
2667
2668 =head1 CONFIGURATION
2669
2670 There are a number of 'base' config variables which can be set:
2671
2672 =over
2673
2674 =item *
2675
2676 C<case_sensitive> - Makes private paths case sensitive. See L</CASE SENSITIVITY>.
2677
2678 =item *
2679
2680 C<default_model> - The default model picked if you say C<< $c->model >>. See L</$c->model($name)>.
2681
2682 =item *
2683
2684 C<default_view> - The default view to be rendered or returned when C<< $c->view >>. See L</$c->view($name)>.
2685 is called.
2686
2687 =item *
2688
2689 C<disable_component_resolution_regex_fallback> - Turns
2690 off the deprecated component resolution functionality so
2691 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2692 are called then regex search will not be attempted on string values and
2693 instead C<undef> will be returned.
2694
2695 =item *
2696
2697 C<home> - The application home directory. In an uninstalled application,
2698 this is the top level application directory. In an installed application,
2699 this will be the directory containing C<< MyApp.pm >>.
2700
2701 =item *
2702
2703 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2704
2705 =item *
2706
2707 C<name> - The name of the application in debug messages and the debug and
2708 welcome screens
2709
2710 =item *
2711
2712 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2713 until it is accessed. This allows you to (for example) check authentication (and reject
2714 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2715
2716 =item *
2717
2718 C<root> - The root directory for templates. Usually this is just a
2719 subdirectory of the home directory, but you can set it to change the
2720 templates to a different directory.
2721
2722 =item *
2723
2724 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2725 namespaces from which components will be loaded (and constructed and stored in
2726 C<< $c->components >>).
2727
2728 =item *
2729
2730 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2731 to be shown in hit debug tables in the test server.
2732
2733 =item *
2734
2735 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2736
2737 =back
2738
2739 =head1 INTERNAL ACTIONS
2740
2741 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2742 C<_ACTION>, and C<_END>. These are by default not shown in the private
2743 action table, but you can make them visible with a config parameter.
2744
2745     MyApp->config(show_internal_actions => 1);
2746
2747 =head1 CASE SENSITIVITY
2748
2749 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2750 mapped to C</foo/bar>. You can activate case sensitivity with a config
2751 parameter.
2752
2753     MyApp->config(case_sensitive => 1);
2754
2755 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2756
2757 =head1 ON-DEMAND PARSER
2758
2759 The request body is usually parsed at the beginning of a request,
2760 but if you want to handle input yourself, you can enable on-demand
2761 parsing with a config parameter.
2762
2763     MyApp->config(parse_on_demand => 1);
2764
2765 =head1 PROXY SUPPORT
2766
2767 Many production servers operate using the common double-server approach,
2768 with a lightweight frontend web server passing requests to a larger
2769 backend server. An application running on the backend server must deal
2770 with two problems: the remote user always appears to be C<127.0.0.1> and
2771 the server's hostname will appear to be C<localhost> regardless of the
2772 virtual host that the user connected through.
2773
2774 Catalyst will automatically detect this situation when you are running
2775 the frontend and backend servers on the same machine. The following
2776 changes are made to the request.
2777
2778     $c->req->address is set to the user's real IP address, as read from
2779     the HTTP X-Forwarded-For header.
2780
2781     The host value for $c->req->base and $c->req->uri is set to the real
2782     host, as read from the HTTP X-Forwarded-Host header.
2783
2784 Additionally, you may be running your backend application on an insecure
2785 connection (port 80) while your frontend proxy is running under SSL.  If there
2786 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2787 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2788 be created properly.
2789
2790 In the case of passing in:
2791
2792     X-Forwarded-Port: 443
2793
2794 All calls to C<uri_for> will result in an https link, as is expected.
2795
2796 Obviously, your web server must support these headers for this to work.
2797
2798 In a more complex server farm environment where you may have your
2799 frontend proxy server(s) on different machines, you will need to set a
2800 configuration option to tell Catalyst to read the proxied data from the
2801 headers.
2802
2803     MyApp->config(using_frontend_proxy => 1);
2804
2805 If you do not wish to use the proxy support at all, you may set:
2806
2807     MyApp->config(ignore_frontend_proxy => 1);
2808
2809 =head1 THREAD SAFETY
2810
2811 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2812 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2813 believe the Catalyst core to be thread-safe.
2814
2815 If you plan to operate in a threaded environment, remember that all other
2816 modules you are using must also be thread-safe. Some modules, most notably
2817 L<DBD::SQLite>, are not thread-safe.
2818
2819 =head1 SUPPORT
2820
2821 IRC:
2822
2823     Join #catalyst on irc.perl.org.
2824
2825 Mailing Lists:
2826
2827     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2828     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2829
2830 Web:
2831
2832     http://catalyst.perl.org
2833
2834 Wiki:
2835
2836     http://dev.catalyst.perl.org
2837
2838 =head1 SEE ALSO
2839
2840 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2841
2842 =head2 L<Catalyst::Manual> - The Catalyst Manual
2843
2844 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2845
2846 =head2 L<Catalyst::Engine> - Core engine
2847
2848 =head2 L<Catalyst::Log> - Log class.
2849
2850 =head2 L<Catalyst::Request> - Request object
2851
2852 =head2 L<Catalyst::Response> - Response object
2853
2854 =head2 L<Catalyst::Test> - The test suite.
2855
2856 =head1 PROJECT FOUNDER
2857
2858 sri: Sebastian Riedel <sri@cpan.org>
2859
2860 =head1 CONTRIBUTORS
2861
2862 abw: Andy Wardley
2863
2864 acme: Leon Brocard <leon@astray.com>
2865
2866 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
2867
2868 Andrew Bramble
2869
2870 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
2871
2872 Andrew Ruthven
2873
2874 andyg: Andy Grundman <andy@hybridized.org>
2875
2876 audreyt: Audrey Tang
2877
2878 bricas: Brian Cassidy <bricas@cpan.org>
2879
2880 Caelum: Rafael Kitover <rkitover@io.com>
2881
2882 chansen: Christian Hansen
2883
2884 chicks: Christopher Hicks
2885
2886 Chisel Wright C<pause@herlpacker.co.uk>
2887
2888 Danijel Milicevic C<me@danijel.de>
2889
2890 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
2891
2892 David Naughton, C<naughton@umn.edu>
2893
2894 David E. Wheeler
2895
2896 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2897
2898 Drew Taylor
2899
2900 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2901
2902 esskar: Sascha Kiefer
2903
2904 fireartist: Carl Franks <cfranks@cpan.org>
2905
2906 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
2907
2908 gabb: Danijel Milicevic
2909
2910 Gary Ashton Jones
2911
2912 Gavin Henry C<ghenry@perl.me.uk>
2913
2914 Geoff Richards
2915
2916 groditi: Guillermo Roditi <groditi@gmail.com>
2917
2918 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2919
2920 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2921
2922 jcamacho: Juan Camacho
2923
2924 jester: Jesse Sheidlower C<jester@panix.com>
2925
2926 jhannah: Jay Hannah <jay@jays.net>
2927
2928 Jody Belka
2929
2930 Johan Lindstrom
2931
2932 jon: Jon Schutz <jjschutz@cpan.org>
2933
2934 Jonathan Rockway C<< <jrockway@cpan.org> >>
2935
2936 Kieren Diment C<kd@totaldatasolution.com>
2937
2938 konobi: Scott McWhirter <konobi@cpan.org>
2939
2940 marcus: Marcus Ramberg <mramberg@cpan.org>
2941
2942 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2943
2944 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2945
2946 mugwump: Sam Vilain
2947
2948 naughton: David Naughton
2949
2950 ningu: David Kamholz <dkamholz@cpan.org>
2951
2952 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2953
2954 numa: Dan Sully <daniel@cpan.org>
2955
2956 obra: Jesse Vincent
2957
2958 omega: Andreas Marienborg
2959
2960 Oleg Kostyuk <cub.uanic@gmail.com>
2961
2962 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2963
2964 rafl: Florian Ragwitz <rafl@debian.org>
2965
2966 random: Roland Lammel <lammel@cpan.org>
2967
2968 Robert Sedlacek C<< <rs@474.at> >>
2969
2970 sky: Arthur Bergman
2971
2972 t0m: Tomas Doran <bobtfish@bobtfish.net>
2973
2974 Ulf Edvinsson
2975
2976 Viljo Marrandi C<vilts@yahoo.com>
2977
2978 Will Hawes C<info@whawes.co.uk>
2979
2980 willert: Sebastian Willert <willert@cpan.org>
2981
2982 Yuval Kogman, C<nothingmuch@woobling.org>
2983
2984 =head1 LICENSE
2985
2986 This library is free software. You can redistribute it and/or modify it under
2987 the same terms as Perl itself.
2988
2989 =cut
2990
2991 no Moose;
2992
2993 __PACKAGE__->meta->make_immutable;
2994
2995 1;