lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/container components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80032';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 sub _comp_search_prefixes {
 540     my $c = shift;
 541     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 542 }
 543
 544 # search components given a name and some prefixes
 545 sub _comp_names_search_prefixes {
 546     my ( $c, $name, @prefixes ) = @_;
 547     my $appclass = ref $c || $c;
 548     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 549     $filter = qr/$filter/; # Compile regex now rather than once per loop
 550
 551     my @components = map { $c->container->get_sub_container($_)->get_service_list } qw(controller view model);
 552
 553     # map the original component name to the sub part that we will search against
 554     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 555         grep { /$filter/ } @components;
 556
 557     # undef for a name will return all
 558     return keys %eligible if !defined $name;
 559
 560     my $query  = ref $name ? $name : qr/^$name$/i;
 561     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 562
 563     return @result if @result;
 564
 565     # if we were given a regexp to search against, we're done.
 566     return if ref $name;
 567
 568     # skip regexp fallback if configured
 569     return
 570         if $appclass->config->{disable_component_resolution_regex_fallback};
 571
 572     # regexp fallback
 573     $query  = qr/$name/i;
 574     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 575
 576     # no results? try against full names
 577     if( !@result ) {
 578         @result = grep { m{$query} } keys %eligible;
 579     }
 580
 581     # don't warn if we didn't find any results, it just might not exist
 582     if( @result ) {
 583         # Disgusting hack to work out correct method name
 584         my $warn_for = lc $prefixes[0];
 585         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 586            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 587            "component resolution is unreliable and unsafe.";
 588         my $short = $result[0];
 589         # remove the component namespace prefix
 590         $short =~ s/.*?(Model|Controller|View):://;
 591         my $shortmess = Carp::shortmess('');
 592         if ($shortmess =~ m#Catalyst/Plugin#) {
 593            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 594               "plugin's config";
 595         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 596            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 597               "component's config";
 598         } else {
 599            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 600               "but if you really wanted to search, pass in a regexp as the argument " .
 601               "like so: \$c->${warn_for}(qr/${name}/)";
 602         }
 603         $c->log->warn( "${msg}$shortmess" );
 604     }
 605
 606     return @result;
 607 }
 608
 609 # Find possible names for a prefix
 610 sub _comp_names {
 611     my ( $c, @prefixes ) = @_;
 612     my $appclass = ref $c || $c;
 613
 614     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 615
 616     my @names = map { s{$filter}{}; $_; }
 617         $c->_comp_names_search_prefixes( undef, @prefixes );
 618
 619     return @names;
 620 }
 621
 622 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 623 sub _filter_component {
 624     my ( $c, $comp, @args ) = @_;
 625
 626     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 627         return $comp->ACCEPT_CONTEXT( $c, @args );
 628     }
 629
 630     return $comp;
 631 }
 632
 633 =head2 COMPONENT ACCESSORS
 634
 635 =head2 $c->controller($name)
 636
 637 Gets a L<Catalyst::Controller> instance by name.
 638
 639     $c->controller('Foo')->do_stuff;
 640
 641 If the name is omitted, will return the controller for the dispatched
 642 action.
 643
 644 If you want to search for controllers, pass in a regexp as the argument.
 645
 646     # find all controllers that start with Foo
 647     my @foo_controllers = $c->controller(qr{^Foo});
 648
 649
 650 =cut
 651
 652 sub controller {
 653     my ( $c, $name, @args ) = @_;
 654
 655     my $appclass = ref($c) || $c;
 656     if( $name ) {
 657         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 658             my $check = $appclass."::Controller::".$name;
 659             my $container = $c->container->get_sub_container('controller');
 660             return $c->_filter_component( $container->resolve(service => "$check"), @args )
 661                 if $container->has_service($check);
 662         }
 663         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 664         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 665         return $c->_filter_component( $result[ 0 ], @args );
 666     }
 667
 668     return $c->component( $c->action->class );
 669 }
 670
 671 =head2 $c->model($name)
 672
 673 Gets a L<Catalyst::Model> instance by name.
 674
 675     $c->model('Foo')->do_stuff;
 676
 677 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 678
 679 If the name is omitted, it will look for
 680  - a model object in $c->stash->{current_model_instance}, then
 681  - a model name in $c->stash->{current_model}, then
 682  - a config setting 'default_model', or
 683  - check if there is only one model, and return it if that's the case.
 684
 685 If you want to search for models, pass in a regexp as the argument.
 686
 687     # find all models that start with Foo
 688     my @foo_models = $c->model(qr{^Foo});
 689
 690 =cut
 691
 692 sub model {
 693     my ( $c, $name, @args ) = @_;
 694     my $appclass = ref($c) || $c;
 695     if( $name ) {
 696         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 697             my $check = $appclass."::Model::".$name;
 698             my $container = $c->container->get_sub_container('model');
 699             return $c->_filter_component( $container->resolve(service => "$check"), @args )
 700                 if $container->has_service($check);
 701         }
 702         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 703         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 704         return $c->_filter_component( $result[ 0 ], @args );
 705     }
 706
 707     if (ref $c) {
 708         return $c->stash->{current_model_instance}
 709           if $c->stash->{current_model_instance};
 710         return $c->model( $c->stash->{current_model} )
 711           if $c->stash->{current_model};
 712     }
 713     return $c->model( $appclass->config->{default_model} )
 714       if $appclass->config->{default_model};
 715
 716     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 717
 718     if( $rest ) {
 719         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 720         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 721         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 722         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 723         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 724     }
 725
 726     return $c->_filter_component( $comp );
 727 }
 728
 729
 730 =head2 $c->view($name)
 731
 732 Gets a L<Catalyst::View> instance by name.
 733
 734     $c->view('Foo')->do_stuff;
 735
 736 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 737
 738 If the name is omitted, it will look for
 739  - a view object in $c->stash->{current_view_instance}, then
 740  - a view name in $c->stash->{current_view}, then
 741  - a config setting 'default_view', or
 742  - check if there is only one view, and return it if that's the case.
 743
 744 If you want to search for views, pass in a regexp as the argument.
 745
 746     # find all views that start with Foo
 747     my @foo_views = $c->view(qr{^Foo});
 748
 749 =cut
 750
 751 sub view {
 752     my ( $c, $name, @args ) = @_;
 753
 754     my $appclass = ref($c) || $c;
 755     if( $name ) {
 756         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 757             my $check = $appclass."::View::".$name;
 758             my $container = $c->container->get_sub_container('view');
 759             if ($container->has_service($check)) {
 760
 761                 return $c->_filter_component( $container->resolve(service => $check), @args );
 762             }
 763             else {
 764                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 765             }
 766         }
 767         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 768         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 769         return $c->_filter_component( $result[ 0 ], @args );
 770     }
 771
 772     if (ref $c) {
 773         return $c->stash->{current_view_instance}
 774           if $c->stash->{current_view_instance};
 775         return $c->view( $c->stash->{current_view} )
 776           if $c->stash->{current_view};
 777     }
 778     return $c->view( $appclass->config->{default_view} )
 779       if $appclass->config->{default_view};
 780
 781     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 782
 783     if( $rest ) {
 784         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 785         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 786         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 787         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 788         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 789     }
 790
 791     return $c->_filter_component( $comp );
 792 }
 793
 794 =head2 $c->controllers
 795
 796 Returns the available names which can be passed to $c->controller
 797
 798 =cut
 799
 800 sub controllers {
 801     my ( $c ) = @_;
 802     return $c->container->get_sub_container('controller')->get_service_list;
 803 }
 804
 805 =head2 $c->models
 806
 807 Returns the available names which can be passed to $c->model
 808
 809 =cut
 810
 811 sub models {
 812     my ( $c ) = @_;
 813     return $c->container->get_sub_container('model')->get_service_list;
 814 }
 815
 816
 817 =head2 $c->views
 818
 819 Returns the available names which can be passed to $c->view
 820
 821 =cut
 822
 823 sub views {
 824     my ( $c ) = @_;
 825     return $c->container->get_sub_container('view')->get_service_list;
 826 }
 827
 828 =head2 $c->comp($name)
 829
 830 =head2 $c->component($name)
 831
 832 Gets a component object by name. This method is not recommended,
 833 unless you want to get a specific component by full
 834 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 835 should be used instead.
 836
 837 If C<$name> is a regexp, a list of components matched against the full
 838 component name will be returned.
 839
 840 If Catalyst can't find a component by name, it will fallback to regex
 841 matching by default. To disable this behaviour set
 842 disable_component_resolution_regex_fallback to a true value.
 843
 844     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 845
 846 =cut
 847
 848 sub component {
 849     my ( $c, $name, @args ) = @_;
 850
 851     if( $name ) {
 852         my $comps = $c->components;
 853
 854         if( !ref $name ) {
 855             # is it the exact name?
 856             return $c->_filter_component( $comps->{ $name }, @args )
 857                        if exists $comps->{ $name };
 858
 859             # perhaps we just omitted "MyApp"?
 860             my $composed = ( ref $c || $c ) . "::${name}";
 861             return $c->_filter_component( $comps->{ $composed }, @args )
 862                        if exists $comps->{ $composed };
 863
 864             # search all of the models, views and controllers
 865             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 866             return $c->_filter_component( $comp, @args ) if $comp;
 867         }
 868
 869         return
 870             if $c->config->{disable_component_resolution_regex_fallback};
 871
 872         # This is here so $c->comp( '::M::' ) works
 873         my $query = ref $name ? $name : qr{$name}i;
 874
 875         my @result = grep { m{$query} } keys %{ $c->components };
 876         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 877
 878         if( $result[ 0 ] ) {
 879             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 880             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 881             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 882             return $c->_filter_component( $result[ 0 ], @args );
 883         }
 884
 885         # I would expect to return an empty list here, but that breaks back-compat
 886     }
 887
 888     # fallback
 889     return sort keys %{ $c->components };
 890 }
 891
 892 =head2 CLASS DATA AND HELPER CLASSES
 893
 894 =head2 $c->config
 895
 896 Returns or takes a hashref containing the application's configuration.
 897
 898     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 899
 900 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 901 like C<myapp.conf> in your applications home directory. See
 902 L<Catalyst::Plugin::ConfigLoader>.
 903
 904 =head3 Cascading configuration
 905
 906 The config method is present on all Catalyst components, and configuration
 907 will be merged when an application is started. Configuration loaded with
 908 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 909 followed by configuration in your top level C<MyApp> class. These two
 910 configurations are merged, and then configuration data whose hash key matches a
 911 component name is merged with configuration for that component.
 912
 913 The configuration for a component is then passed to the C<new> method when a
 914 component is constructed.
 915
 916 For example:
 917
 918     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 919     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 920
 921 will mean that C<MyApp::Model::Foo> receives the following data when
 922 constructed:
 923
 924     MyApp::Model::Foo->new({
 925         bar => 'baz',
 926         quux => 'frob',
 927         overrides => 'me',
 928     });
 929
 930 It's common practice to use a Moose attribute
 931 on the receiving component to access the config value.
 932
 933     package MyApp::Model::Foo;
 934
 935     use Moose;
 936
 937     # this attr will receive 'baz' at construction time
 938     has 'bar' => (
 939         is  => 'rw',
 940         isa => 'Str',
 941     );
 942
 943 You can then get the value 'baz' by calling $c->model('Foo')->bar
 944 (or $self->bar inside code in the model).
 945
 946 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 947 as a way of reading config within your code, as this B<will not> give you the
 948 correctly merged config back. You B<MUST> take the config values supplied to
 949 the constructor and use those instead.
 950
 951 =cut
 952
 953 around config => sub {
 954     my $orig = shift;
 955     my $c = shift;
 956
 957     croak('Setting config after setup has been run is not allowed.')
 958         if ( @_ and $c->setup_finished );
 959
 960     $c->$orig(@_);
 961 };
 962
 963 =head2 $c->log
 964
 965 Returns the logging object instance. Unless it is already set, Catalyst
 966 sets this up with a L<Catalyst::Log> object. To use your own log class,
 967 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 968 C<< __PACKAGE__->setup >>.
 969
 970  __PACKAGE__->log( MyLogger->new );
 971  __PACKAGE__->setup;
 972
 973 And later:
 974
 975     $c->log->info( 'Now logging with my own logger!' );
 976
 977 Your log class should implement the methods described in
 978 L<Catalyst::Log>.
 979
 980
 981 =head2 $c->debug
 982
 983 Returns 1 if debug mode is enabled, 0 otherwise.
 984
 985 You can enable debug mode in several ways:
 986
 987 =over
 988
 989 =item By calling myapp_server.pl with the -d flag
 990
 991 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 992
 993 =item The -Debug option in your MyApp.pm
 994
 995 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 996
 997 =back
 998
 999 The first three also set the log level to 'debug'.
1000
1001 Calling C<< $c->debug(1) >> has no effect.
1002
1003 =cut
1004
1005 sub debug { 0 }
1006
1007 =head2 $c->dispatcher
1008
1009 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1010
1011 =head2 $c->engine
1012
1013 Returns the engine instance. See L<Catalyst::Engine>.
1014
1015
1016 =head2 UTILITY METHODS
1017
1018 =head2 $c->path_to(@path)
1019
1020 Merges C<@path> with C<< $c->config->{home} >> and returns a
1021 L<Path::Class::Dir> object. Note you can usually use this object as
1022 a filename, but sometimes you will have to explicitly stringify it
1023 yourself by calling the C<< ->stringify >> method.
1024
1025 For example:
1026
1027     $c->path_to( 'db', 'sqlite.db' );
1028
1029 =cut
1030
1031 sub path_to {
1032     my ( $c, @path ) = @_;
1033     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1034     if ( -d $path ) { return $path }
1035     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1036 }
1037
1038 =head2 $c->plugin( $name, $class, @args )
1039
1040 Helper method for plugins. It creates a class data accessor/mutator and
1041 loads and instantiates the given class.
1042
1043     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1044
1045     $c->prototype->define_javascript_functions;
1046
1047 B<Note:> This method of adding plugins is deprecated. The ability
1048 to add plugins like this B<will be removed> in a Catalyst 5.81.
1049 Please do not use this functionality in new code.
1050
1051 =cut
1052
1053 sub plugin {
1054     my ( $class, $name, $plugin, @args ) = @_;
1055
1056     # See block comment in t/unit_core_plugin.t
1057     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1058
1059     $class->_register_plugin( $plugin, 1 );
1060
1061     eval { $plugin->import };
1062     $class->mk_classdata($name);
1063     my $obj;
1064     eval { $obj = $plugin->new(@args) };
1065
1066     if ($@) {
1067         Catalyst::Exception->throw( message =>
1068               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1069     }
1070
1071     $class->$name($obj);
1072     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1073       if $class->debug;
1074 }
1075
1076 =head2 MyApp->setup
1077
1078 Initializes the dispatcher and engine, loads any plugins, and loads the
1079 model, view, and controller components. You may also specify an array
1080 of plugins to load here, if you choose to not load them in the C<use
1081 Catalyst> line.
1082
1083     MyApp->setup;
1084     MyApp->setup( qw/-Debug/ );
1085
1086 =cut
1087
1088 sub setup {
1089     my ( $class, @arguments ) = @_;
1090     croak('Running setup more than once')
1091         if ( $class->setup_finished );
1092
1093     unless ( $class->isa('Catalyst') ) {
1094
1095         Catalyst::Exception->throw(
1096             message => qq/'$class' does not inherit from Catalyst/ );
1097     }
1098
1099     if ( $class->arguments ) {
1100         @arguments = ( @arguments, @{ $class->arguments } );
1101     }
1102
1103     # Process options
1104     my $flags = {};
1105
1106     foreach (@arguments) {
1107
1108         if (/^-Debug$/) {
1109             $flags->{log} =
1110               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1111         }
1112         elsif (/^-(\w+)=?(.*)$/) {
1113             $flags->{ lc $1 } = $2;
1114         }
1115         else {
1116             push @{ $flags->{plugins} }, $_;
1117         }
1118     }
1119
1120     $class->setup_config();
1121     $class->setup_home( delete $flags->{home} );
1122
1123     $class->setup_log( delete $flags->{log} );
1124     $class->setup_plugins( delete $flags->{plugins} );
1125     $class->setup_dispatcher( delete $flags->{dispatcher} );
1126     $class->setup_engine( delete $flags->{engine} );
1127     $class->setup_stats( delete $flags->{stats} );
1128
1129     for my $flag ( sort keys %{$flags} ) {
1130
1131         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1132             &$code( $class, delete $flags->{$flag} );
1133         }
1134         else {
1135             $class->log->warn(qq/Unknown flag "$flag"/);
1136         }
1137     }
1138
1139     eval { require Catalyst::Devel; };
1140     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1141         $class->log->warn(<<"EOF");
1142 You are running an old script!
1143
1144   Please update by running (this will overwrite existing files):
1145     catalyst.pl -force -scripts $class
1146
1147   or (this will not overwrite existing files):
1148     catalyst.pl -scripts $class
1149
1150 EOF
1151     }
1152
1153     if ( $class->debug ) {
1154         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1155
1156         if (@plugins) {
1157             my $column_width = Catalyst::Utils::term_width() - 6;
1158             my $t = Text::SimpleTable->new($column_width);
1159             $t->row($_) for @plugins;
1160             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1161         }
1162
1163         my $dispatcher = $class->dispatcher;
1164         my $engine     = $class->engine;
1165         my $home       = $class->config->{home};
1166
1167         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1168         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1169
1170         $home
1171           ? ( -d $home )
1172           ? $class->log->debug(qq/Found home "$home"/)
1173           : $class->log->debug(qq/Home "$home" doesn't exist/)
1174           : $class->log->debug(q/Couldn't find home/);
1175     }
1176
1177     # Call plugins setup, this is stupid and evil.
1178     # Also screws C3 badly on 5.10, hack to avoid.
1179     {
1180         no warnings qw/redefine/;
1181         local *setup = sub { };
1182         $class->setup unless $Catalyst::__AM_RESTARTING;
1183     }
1184
1185     # Initialize our data structure
1186     $class->components( {} );
1187
1188     $class->setup_components;
1189
1190     if ( $class->debug ) {
1191         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1192         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1193         for my $comp ( sort keys %{ $class->components } ) {
1194             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1195             $t->row( $comp, $type );
1196         }
1197         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1198           if ( keys %{ $class->components } );
1199     }
1200
1201     # Add our self to components, since we are also a component
1202     if( $class->isa('Catalyst::Controller') ){
1203       $class->components->{$class} = $class;
1204     }
1205
1206     $class->setup_actions;
1207
1208     if ( $class->debug ) {
1209         my $name = $class->config->{name} || 'Application';
1210         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1211     }
1212
1213     # Make sure that the application class becomes immutable at this point,
1214     B::Hooks::EndOfScope::on_scope_end {
1215         return if $@;
1216         my $meta = Class::MOP::get_metaclass_by_name($class);
1217         if (
1218             $meta->is_immutable
1219             && ! { $meta->immutable_options }->{replace_constructor}
1220             && (
1221                    $class->isa('Class::Accessor::Fast')
1222                 || $class->isa('Class::Accessor')
1223             )
1224         ) {
1225             warn "You made your application class ($class) immutable, "
1226                 . "but did not inline the\nconstructor. "
1227                 . "This will break catalyst, as your app \@ISA "
1228                 . "Class::Accessor(::Fast)?\nPlease pass "
1229                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1230         }
1231         $meta->make_immutable(
1232             replace_constructor => 1,
1233         ) unless $meta->is_immutable;
1234     };
1235
1236     if ($class->config->{case_sensitive}) {
1237         $class->log->warn($class . "->config->{case_sensitive} is set.");
1238         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1239     }
1240
1241     $class->setup_finalize;
1242     # Should be the last thing we do so that user things hooking
1243     # setup_finalize can log..
1244     $class->log->_flush() if $class->log->can('_flush');
1245     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1246 }
1247
1248 =head2 $app->setup_finalize
1249
1250 A hook to attach modifiers to. This method does not do anything except set the
1251 C<setup_finished> accessor.
1252
1253 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1254
1255 Example:
1256
1257     after setup_finalize => sub {
1258         my $app = shift;
1259
1260         ## do stuff here..
1261     };
1262
1263 =cut
1264
1265 sub setup_finalize {
1266     my ($class) = @_;
1267     $class->setup_finished(1);
1268 }
1269
1270 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1271
1272 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1273
1274 Constructs an absolute L<URI> object based on the application root, the
1275 provided path, and the additional arguments and query parameters provided.
1276 When used as a string, provides a textual URI.  If you need more flexibility
1277 than this (i.e. the option to provide relative URIs etc.) see
1278 L<Catalyst::Plugin::SmartURI>.
1279
1280 If no arguments are provided, the URI for the current action is returned.
1281 To return the current action and also provide @args, use
1282 C<< $c->uri_for( $c->action, @args ) >>.
1283
1284 If the first argument is a string, it is taken as a public URI path relative
1285 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1286 relative to the application root (if it does). It is then merged with
1287 C<< $c->request->base >>; any C<@args> are appended as additional path
1288 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1289
1290 If the first argument is a L<Catalyst::Action> it represents an action which
1291 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1292 optional C<\@captures> argument (an arrayref) allows passing the captured
1293 variables that are needed to fill in the paths of Chained and Regex actions;
1294 once the path is resolved, C<uri_for> continues as though a path was
1295 provided, appending any arguments or parameters and creating an absolute
1296 URI.
1297
1298 The captures for the current request can be found in
1299 C<< $c->request->captures >>, and actions can be resolved using
1300 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1301 path, use C<< $c->uri_for_action >> instead.
1302
1303   # Equivalent to $c->req->uri
1304   $c->uri_for($c->action, $c->req->captures,
1305       @{ $c->req->args }, $c->req->params);
1306
1307   # For the Foo action in the Bar controller
1308   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1309
1310   # Path to a static resource
1311   $c->uri_for('/static/images/logo.png');
1312
1313 =cut
1314
1315 sub uri_for {
1316     my ( $c, $path, @args ) = @_;
1317
1318     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1319         $path = $path->path_prefix;
1320         $path =~ s{/+\z}{};
1321         $path .= '/';
1322     }
1323
1324     undef($path) if (defined $path && $path eq '');
1325
1326     my $params =
1327       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1328
1329     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1330     foreach my $arg (@args) {
1331         utf8::encode($arg) if utf8::is_utf8($arg);
1332         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1333     }
1334
1335     if ( blessed($path) ) { # action object
1336         s|/|%2F|g for @args;
1337         my $captures = [ map { s|/|%2F|g; $_; }
1338                         ( scalar @args && ref $args[0] eq 'ARRAY'
1339                          ? @{ shift(@args) }
1340                          : ()) ];
1341
1342         foreach my $capture (@$captures) {
1343             utf8::encode($capture) if utf8::is_utf8($capture);
1344             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1345         }
1346
1347         my $action = $path;
1348         $path = $c->dispatcher->uri_for_action($action, $captures);
1349         if (not defined $path) {
1350             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1351                 if $c->debug;
1352             return undef;
1353         }
1354         $path = '/' if $path eq '';
1355     }
1356
1357     unshift(@args, $path);
1358
1359     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1360         my $namespace = $c->namespace;
1361         if (defined $path) { # cheesy hack to handle path '../foo'
1362            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1363         }
1364         unshift(@args, $namespace || '');
1365     }
1366
1367     # join args with '/', or a blank string
1368     my $args = join('/', grep { defined($_) } @args);
1369     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1370     $args =~ s!^/+!!;
1371     my $base = $c->req->base;
1372     my $class = ref($base);
1373     $base =~ s{(?<!/)$}{/};
1374
1375     my $query = '';
1376
1377     if (my @keys = keys %$params) {
1378       # somewhat lifted from URI::_query's query_form
1379       $query = '?'.join('&', map {
1380           my $val = $params->{$_};
1381           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1382           s/ /+/g;
1383           my $key = $_;
1384           $val = '' unless defined $val;
1385           (map {
1386               my $param = "$_";
1387               utf8::encode( $param ) if utf8::is_utf8($param);
1388               # using the URI::Escape pattern here so utf8 chars survive
1389               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1390               $param =~ s/ /+/g;
1391               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1392       } @keys);
1393     }
1394
1395     my $res = bless(\"${base}${args}${query}", $class);
1396     $res;
1397 }
1398
1399 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1400
1401 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1402
1403 =over
1404
1405 =item $path
1406
1407 A private path to the Catalyst action you want to create a URI for.
1408
1409 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1410 >> and passing the resulting C<$action> and the remaining arguments to C<<
1411 $c->uri_for >>.
1412
1413 You can also pass in a Catalyst::Action object, in which case it is passed to
1414 C<< $c->uri_for >>.
1415
1416 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1417
1418 For example, if the action looks like:
1419
1420  package MyApp::Controller::Users;
1421
1422  sub lst : Path('the-list') {}
1423
1424 You can use:
1425
1426  $c->uri_for_action('/users/lst')
1427
1428 and it will create the URI /users/the-list.
1429
1430 =back
1431
1432 =cut
1433
1434 sub uri_for_action {
1435     my ( $c, $path, @args ) = @_;
1436     my $action = blessed($path)
1437       ? $path
1438       : $c->dispatcher->get_action_by_path($path);
1439     unless (defined $action) {
1440       croak "Can't find action for path '$path'";
1441     }
1442     return $c->uri_for( $action, @args );
1443 }
1444
1445 =head2 $c->welcome_message
1446
1447 Returns the Catalyst welcome HTML page.
1448
1449 =cut
1450
1451 sub welcome_message {
1452     my $c      = shift;
1453     my $name   = $c->config->{name};
1454     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1455     my $prefix = Catalyst::Utils::appprefix( ref $c );
1456     $c->response->content_type('text/html; charset=utf-8');
1457     return <<"EOF";
1458 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1459     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1460 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1461     <head>
1462     <meta http-equiv="Content-Language" content="en" />
1463     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1464         <title>$name on Catalyst $VERSION</title>
1465         <style type="text/css">
1466             body {
1467                 color: #000;
1468                 background-color: #eee;
1469             }
1470             div#content {
1471                 width: 640px;
1472                 margin-left: auto;
1473                 margin-right: auto;
1474                 margin-top: 10px;
1475                 margin-bottom: 10px;
1476                 text-align: left;
1477                 background-color: #ccc;
1478                 border: 1px solid #aaa;
1479             }
1480             p, h1, h2 {
1481                 margin-left: 20px;
1482                 margin-right: 20px;
1483                 font-family: verdana, tahoma, sans-serif;
1484             }
1485             a {
1486                 font-family: verdana, tahoma, sans-serif;
1487             }
1488             :link, :visited {
1489                     text-decoration: none;
1490                     color: #b00;
1491                     border-bottom: 1px dotted #bbb;
1492             }
1493             :link:hover, :visited:hover {
1494                     color: #555;
1495             }
1496             div#topbar {
1497                 margin: 0px;
1498             }
1499             pre {
1500                 margin: 10px;
1501                 padding: 8px;
1502             }
1503             div#answers {
1504                 padding: 8px;
1505                 margin: 10px;
1506                 background-color: #fff;
1507                 border: 1px solid #aaa;
1508             }
1509             h1 {
1510                 font-size: 0.9em;
1511                 font-weight: normal;
1512                 text-align: center;
1513             }
1514             h2 {
1515                 font-size: 1.0em;
1516             }
1517             p {
1518                 font-size: 0.9em;
1519             }
1520             p img {
1521                 float: right;
1522                 margin-left: 10px;
1523             }
1524             span#appname {
1525                 font-weight: bold;
1526                 font-size: 1.6em;
1527             }
1528         </style>
1529     </head>
1530     <body>
1531         <div id="content">
1532             <div id="topbar">
1533                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1534                     $VERSION</h1>
1535              </div>
1536              <div id="answers">
1537                  <p>
1538                  <img src="$logo" alt="Catalyst Logo" />
1539                  </p>
1540                  <p>Welcome to the  world of Catalyst.
1541                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1542                     framework will make web development something you had
1543                     never expected it to be: Fun, rewarding, and quick.</p>
1544                  <h2>What to do now?</h2>
1545                  <p>That really depends  on what <b>you</b> want to do.
1546                     We do, however, provide you with a few starting points.</p>
1547                  <p>If you want to jump right into web development with Catalyst
1548                     you might want to start with a tutorial.</p>
1549 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1550 </pre>
1551 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1552 <pre>
1553 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1554 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1555 </code></pre>
1556                  <h2>What to do next?</h2>
1557                  <p>Next it's time to write an actual application. Use the
1558                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1559                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1560                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1561                     they can save you a lot of work.</p>
1562                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1563                     <p>Also, be sure to check out the vast and growing
1564                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1565                     you are likely to find what you need there.
1566                     </p>
1567
1568                  <h2>Need help?</h2>
1569                  <p>Catalyst has a very active community. Here are the main places to
1570                     get in touch with us.</p>
1571                  <ul>
1572                      <li>
1573                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1574                      </li>
1575                      <li>
1576                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1577                      </li>
1578                      <li>
1579                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1580                      </li>
1581                  </ul>
1582                  <h2>In conclusion</h2>
1583                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1584                     as we enjoyed making it. Please contact us if you have ideas
1585                     for improvement or other feedback.</p>
1586              </div>
1587          </div>
1588     </body>
1589 </html>
1590 EOF
1591 }
1592
1593 =head1 INTERNAL METHODS
1594
1595 These methods are not meant to be used by end users.
1596
1597 =head2 $c->components
1598
1599 Returns a hash of components.
1600
1601 =cut
1602
1603 around components => sub {
1604     my $orig  = shift;
1605     my $class = shift;
1606     my $comps = shift;
1607
1608     return $class->$orig if ( !$comps );
1609
1610 # FIXME: should this ugly kludge exist?
1611     $class->setup_config unless defined $class->container;
1612
1613 # FIXME: should there be a warning here, not to use this accessor to create the components?
1614     my $components = {};
1615
1616     my $containers;
1617     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
1618
1619     for my $component ( keys %$comps ) {
1620         $components->{ $component } = $comps->{$component};
1621
1622         my ($type, $name) = _get_component_type_name($component);
1623
1624 # FIXME: shouldn't the service name be $name?
1625         $containers->{$type}->add_service(Bread::Board::BlockInjection->new( name => $component, block => sub { return $class->setup_component($component) } ));
1626     }
1627
1628     return $class->$orig($components);
1629 };
1630
1631 =head2 $c->context_class
1632
1633 Returns or sets the context class.
1634
1635 =head2 $c->counter
1636
1637 Returns a hashref containing coderefs and execution counts (needed for
1638 deep recursion detection).
1639
1640 =head2 $c->depth
1641
1642 Returns the number of actions on the current internal execution stack.
1643
1644 =head2 $c->dispatch
1645
1646 Dispatches a request to actions.
1647
1648 =cut
1649
1650 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1651
1652 =head2 $c->dispatcher_class
1653
1654 Returns or sets the dispatcher class.
1655
1656 =head2 $c->dump_these
1657
1658 Returns a list of 2-element array references (name, structure) pairs
1659 that will be dumped on the error page in debug mode.
1660
1661 =cut
1662
1663 sub dump_these {
1664     my $c = shift;
1665     [ Request => $c->req ],
1666     [ Response => $c->res ],
1667     [ Stash => $c->stash ],
1668     [ Config => $c->config ];
1669 }
1670
1671 =head2 $c->engine_class
1672
1673 Returns or sets the engine class.
1674
1675 =head2 $c->execute( $class, $coderef )
1676
1677 Execute a coderef in given class and catch exceptions. Errors are available
1678 via $c->error.
1679
1680 =cut
1681
1682 sub execute {
1683     my ( $c, $class, $code ) = @_;
1684     $class = $c->component($class) || $class;
1685     $c->state(0);
1686
1687     if ( $c->depth >= $RECURSION ) {
1688         my $action = $code->reverse();
1689         $action = "/$action" unless $action =~ /->/;
1690         my $error = qq/Deep recursion detected calling "${action}"/;
1691         $c->log->error($error);
1692         $c->error($error);
1693         $c->state(0);
1694         return $c->state;
1695     }
1696
1697     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1698
1699     push( @{ $c->stack }, $code );
1700
1701     no warnings 'recursion';
1702     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1703     #      I have no idea how, ergo $ret (which appears to fix the issue)
1704     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1705
1706     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1707
1708     my $last = pop( @{ $c->stack } );
1709
1710     if ( my $error = $@ ) {
1711         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1712             $error->rethrow if $c->depth > 1;
1713         }
1714         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1715             $error->rethrow if $c->depth > 0;
1716         }
1717         else {
1718             unless ( ref $error ) {
1719                 no warnings 'uninitialized';
1720                 chomp $error;
1721                 my $class = $last->class;
1722                 my $name  = $last->name;
1723                 $error = qq/Caught exception in $class->$name "$error"/;
1724             }
1725             $c->error($error);
1726         }
1727         $c->state(0);
1728     }
1729     return $c->state;
1730 }
1731
1732 sub _stats_start_execute {
1733     my ( $c, $code ) = @_;
1734     my $appclass = ref($c) || $c;
1735     return if ( ( $code->name =~ /^_.*/ )
1736         && ( !$appclass->config->{show_internal_actions} ) );
1737
1738     my $action_name = $code->reverse();
1739     $c->counter->{$action_name}++;
1740
1741     my $action = $action_name;
1742     $action = "/$action" unless $action =~ /->/;
1743
1744     # determine if the call was the result of a forward
1745     # this is done by walking up the call stack and looking for a calling
1746     # sub of Catalyst::forward before the eval
1747     my $callsub = q{};
1748     for my $index ( 2 .. 11 ) {
1749         last
1750         if ( ( caller($index) )[0] eq 'Catalyst'
1751             && ( caller($index) )[3] eq '(eval)' );
1752
1753         if ( ( caller($index) )[3] =~ /forward$/ ) {
1754             $callsub = ( caller($index) )[3];
1755             $action  = "-> $action";
1756             last;
1757         }
1758     }
1759
1760     my $uid = $action_name . $c->counter->{$action_name};
1761
1762     # is this a root-level call or a forwarded call?
1763     if ( $callsub =~ /forward$/ ) {
1764         my $parent = $c->stack->[-1];
1765
1766         # forward, locate the caller
1767         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1768             $c->stats->profile(
1769                 begin  => $action,
1770                 parent => "$parent" . $c->counter->{"$parent"},
1771                 uid    => $uid,
1772             );
1773         }
1774         else {
1775
1776             # forward with no caller may come from a plugin
1777             $c->stats->profile(
1778                 begin => $action,
1779                 uid   => $uid,
1780             );
1781         }
1782     }
1783     else {
1784
1785         # root-level call
1786         $c->stats->profile(
1787             begin => $action,
1788             uid   => $uid,
1789         );
1790     }
1791     return $action;
1792
1793 }
1794
1795 sub _stats_finish_execute {
1796     my ( $c, $info ) = @_;
1797     $c->stats->profile( end => $info );
1798 }
1799
1800 =head2 $c->finalize
1801
1802 Finalizes the request.
1803
1804 =cut
1805
1806 sub finalize {
1807     my $c = shift;
1808
1809     for my $error ( @{ $c->error } ) {
1810         $c->log->error($error);
1811     }
1812
1813     # Allow engine to handle finalize flow (for POE)
1814     my $engine = $c->engine;
1815     if ( my $code = $engine->can('finalize') ) {
1816         $engine->$code($c);
1817     }
1818     else {
1819
1820         $c->finalize_uploads;
1821
1822         # Error
1823         if ( $#{ $c->error } >= 0 ) {
1824             $c->finalize_error;
1825         }
1826
1827         $c->finalize_headers;
1828
1829         # HEAD request
1830         if ( $c->request->method eq 'HEAD' ) {
1831             $c->response->body('');
1832         }
1833
1834         $c->finalize_body;
1835     }
1836
1837     $c->log_response;
1838
1839     if ($c->use_stats) {
1840         my $elapsed = sprintf '%f', $c->stats->elapsed;
1841         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1842         $c->log->info(
1843             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1844     }
1845
1846     return $c->response->status;
1847 }
1848
1849 =head2 $c->finalize_body
1850
1851 Finalizes body.
1852
1853 =cut
1854
1855 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1856
1857 =head2 $c->finalize_cookies
1858
1859 Finalizes cookies.
1860
1861 =cut
1862
1863 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1864
1865 =head2 $c->finalize_error
1866
1867 Finalizes error.
1868
1869 =cut
1870
1871 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1872
1873 =head2 $c->finalize_headers
1874
1875 Finalizes headers.
1876
1877 =cut
1878
1879 sub finalize_headers {
1880     my $c = shift;
1881
1882     my $response = $c->response; #accessor calls can add up?
1883
1884     # Check if we already finalized headers
1885     return if $response->finalized_headers;
1886
1887     # Handle redirects
1888     if ( my $location = $response->redirect ) {
1889         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1890         $response->header( Location => $location );
1891
1892         if ( !$response->has_body ) {
1893             # Add a default body if none is already present
1894             $response->body(
1895                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1896             );
1897         }
1898     }
1899
1900     # Content-Length
1901     if ( defined $response->body && length $response->body && !$response->content_length ) {
1902
1903         # get the length from a filehandle
1904         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1905         {
1906             my $stat = stat $response->body;
1907             if ( $stat && $stat->size > 0 ) {
1908                 $response->content_length( $stat->size );
1909             }
1910             else {
1911                 $c->log->warn('Serving filehandle without a content-length');
1912             }
1913         }
1914         else {
1915             # everything should be bytes at this point, but just in case
1916             $response->content_length( length( $response->body ) );
1917         }
1918     }
1919
1920     # Errors
1921     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1922         $response->headers->remove_header("Content-Length");
1923         $response->body('');
1924     }
1925
1926     $c->finalize_cookies;
1927
1928     $c->engine->finalize_headers( $c, @_ );
1929
1930     # Done
1931     $response->finalized_headers(1);
1932 }
1933
1934 =head2 $c->finalize_output
1935
1936 An alias for finalize_body.
1937
1938 =head2 $c->finalize_read
1939
1940 Finalizes the input after reading is complete.
1941
1942 =cut
1943
1944 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1945
1946 =head2 $c->finalize_uploads
1947
1948 Finalizes uploads. Cleans up any temporary files.
1949
1950 =cut
1951
1952 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1953
1954 =head2 $c->get_action( $action, $namespace )
1955
1956 Gets an action in a given namespace.
1957
1958 =cut
1959
1960 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1961
1962 =head2 $c->get_actions( $action, $namespace )
1963
1964 Gets all actions of a given name in a namespace and all parent
1965 namespaces.
1966
1967 =cut
1968
1969 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1970
1971 =head2 $app->handle_request( @arguments )
1972
1973 Called to handle each HTTP request.
1974
1975 =cut
1976
1977 sub handle_request {
1978     my ( $class, @arguments ) = @_;
1979
1980     # Always expect worst case!
1981     my $status = -1;
1982     eval {
1983         if ($class->debug) {
1984             my $secs = time - $START || 1;
1985             my $av = sprintf '%.3f', $COUNT / $secs;
1986             my $time = localtime time;
1987             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1988         }
1989
1990         my $c = $class->prepare(@arguments);
1991         $c->dispatch;
1992         $status = $c->finalize;
1993     };
1994
1995     if ( my $error = $@ ) {
1996         chomp $error;
1997         $class->log->error(qq/Caught exception in engine "$error"/);
1998     }
1999
2000     $COUNT++;
2001
2002     if(my $coderef = $class->log->can('_flush')){
2003         $class->log->$coderef();
2004     }
2005     return $status;
2006 }
2007
2008 =head2 $c->prepare( @arguments )
2009
2010 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2011 etc.).
2012
2013 =cut
2014
2015 sub prepare {
2016     my ( $class, @arguments ) = @_;
2017
2018     # XXX
2019     # After the app/ctxt split, this should become an attribute based on something passed
2020     # into the application.
2021     $class->context_class( ref $class || $class ) unless $class->context_class;
2022
2023     my $c = $class->context_class->new({});
2024
2025     # For on-demand data
2026     $c->request->_context($c);
2027     $c->response->_context($c);
2028
2029     #surely this is not the most efficient way to do things...
2030     $c->stats($class->stats_class->new)->enable($c->use_stats);
2031     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2032         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2033     }
2034
2035     #XXX reuse coderef from can
2036     # Allow engine to direct the prepare flow (for POE)
2037     if ( $c->engine->can('prepare') ) {
2038         $c->engine->prepare( $c, @arguments );
2039     }
2040     else {
2041         $c->prepare_request(@arguments);
2042         $c->prepare_connection;
2043         $c->prepare_query_parameters;
2044         $c->prepare_headers;
2045         $c->prepare_cookies;
2046         $c->prepare_path;
2047
2048         # Prepare the body for reading, either by prepare_body
2049         # or the user, if they are using $c->read
2050         $c->prepare_read;
2051
2052         # Parse the body unless the user wants it on-demand
2053         unless ( ref($c)->config->{parse_on_demand} ) {
2054             $c->prepare_body;
2055         }
2056     }
2057
2058     my $method  = $c->req->method  || '';
2059     my $path    = $c->req->path;
2060     $path       = '/' unless length $path;
2061     my $address = $c->req->address || '';
2062
2063     $c->log_request;
2064
2065     $c->prepare_action;
2066
2067     return $c;
2068 }
2069
2070 =head2 $c->prepare_action
2071
2072 Prepares action. See L<Catalyst::Dispatcher>.
2073
2074 =cut
2075
2076 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2077
2078 =head2 $c->prepare_body
2079
2080 Prepares message body.
2081
2082 =cut
2083
2084 sub prepare_body {
2085     my $c = shift;
2086
2087     return if $c->request->_has_body;
2088
2089     # Initialize on-demand data
2090     $c->engine->prepare_body( $c, @_ );
2091     $c->prepare_parameters;
2092     $c->prepare_uploads;
2093 }
2094
2095 =head2 $c->prepare_body_chunk( $chunk )
2096
2097 Prepares a chunk of data before sending it to L<HTTP::Body>.
2098
2099 See L<Catalyst::Engine>.
2100
2101 =cut
2102
2103 sub prepare_body_chunk {
2104     my $c = shift;
2105     $c->engine->prepare_body_chunk( $c, @_ );
2106 }
2107
2108 =head2 $c->prepare_body_parameters
2109
2110 Prepares body parameters.
2111
2112 =cut
2113
2114 sub prepare_body_parameters {
2115     my $c = shift;
2116     $c->engine->prepare_body_parameters( $c, @_ );
2117 }
2118
2119 =head2 $c->prepare_connection
2120
2121 Prepares connection.
2122
2123 =cut
2124
2125 sub prepare_connection {
2126     my $c = shift;
2127     $c->engine->prepare_connection( $c, @_ );
2128 }
2129
2130 =head2 $c->prepare_cookies
2131
2132 Prepares cookies.
2133
2134 =cut
2135
2136 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2137
2138 =head2 $c->prepare_headers
2139
2140 Prepares headers.
2141
2142 =cut
2143
2144 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2145
2146 =head2 $c->prepare_parameters
2147
2148 Prepares parameters.
2149
2150 =cut
2151
2152 sub prepare_parameters {
2153     my $c = shift;
2154     $c->prepare_body_parameters;
2155     $c->engine->prepare_parameters( $c, @_ );
2156 }
2157
2158 =head2 $c->prepare_path
2159
2160 Prepares path and base.
2161
2162 =cut
2163
2164 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2165
2166 =head2 $c->prepare_query_parameters
2167
2168 Prepares query parameters.
2169
2170 =cut
2171
2172 sub prepare_query_parameters {
2173     my $c = shift;
2174
2175     $c->engine->prepare_query_parameters( $c, @_ );
2176 }
2177
2178 =head2 $c->log_request
2179
2180 Writes information about the request to the debug logs.  This includes:
2181
2182 =over 4
2183
2184 =item * Request method, path, and remote IP address
2185
2186 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2187
2188 =item * Request parameters
2189
2190 =item * File uploads
2191
2192 =back
2193
2194 =cut
2195
2196 sub log_request {
2197     my $c = shift;
2198
2199     return unless $c->debug;
2200
2201     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2202     my $request = $dump->[1];
2203
2204     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2205     $method ||= '';
2206     $path = '/' unless length $path;
2207     $address ||= '';
2208     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2209
2210     $c->log_request_headers($request->headers);
2211
2212     if ( my $keywords = $request->query_keywords ) {
2213         $c->log->debug("Query keywords are: $keywords");
2214     }
2215
2216     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2217
2218     $c->log_request_uploads($request);
2219 }
2220
2221 =head2 $c->log_response
2222
2223 Writes information about the response to the debug logs by calling
2224 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2225
2226 =cut
2227
2228 sub log_response {
2229     my $c = shift;
2230
2231     return unless $c->debug;
2232
2233     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2234     my $response = $dump->[1];
2235
2236     $c->log_response_status_line($response);
2237     $c->log_response_headers($response->headers);
2238 }
2239
2240 =head2 $c->log_response_status_line($response)
2241
2242 Writes one line of information about the response to the debug logs.  This includes:
2243
2244 =over 4
2245
2246 =item * Response status code
2247
2248 =item * Content-Type header (if present)
2249
2250 =item * Content-Length header (if present)
2251
2252 =back
2253
2254 =cut
2255
2256 sub log_response_status_line {
2257     my ($c, $response) = @_;
2258
2259     $c->log->debug(
2260         sprintf(
2261             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2262             $response->status                            || 'unknown',
2263             $response->headers->header('Content-Type')   || 'unknown',
2264             $response->headers->header('Content-Length') || 'unknown'
2265         )
2266     );
2267 }
2268
2269 =head2 $c->log_response_headers($headers);
2270
2271 Hook method which can be wrapped by plugins to log the responseheaders.
2272 No-op in the default implementation.
2273
2274 =cut
2275
2276 sub log_response_headers {}
2277
2278 =head2 $c->log_request_parameters( query => {}, body => {} )
2279
2280 Logs request parameters to debug logs
2281
2282 =cut
2283
2284 sub log_request_parameters {
2285     my $c          = shift;
2286     my %all_params = @_;
2287
2288     return unless $c->debug;
2289
2290     my $column_width = Catalyst::Utils::term_width() - 44;
2291     foreach my $type (qw(query body)) {
2292         my $params = $all_params{$type};
2293         next if ! keys %$params;
2294         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2295         for my $key ( sort keys %$params ) {
2296             my $param = $params->{$key};
2297             my $value = defined($param) ? $param : '';
2298             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2299         }
2300         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2301     }
2302 }
2303
2304 =head2 $c->log_request_uploads
2305
2306 Logs file uploads included in the request to the debug logs.
2307 The parameter name, filename, file type, and file size are all included in
2308 the debug logs.
2309
2310 =cut
2311
2312 sub log_request_uploads {
2313     my $c = shift;
2314     my $request = shift;
2315     return unless $c->debug;
2316     my $uploads = $request->uploads;
2317     if ( keys %$uploads ) {
2318         my $t = Text::SimpleTable->new(
2319             [ 12, 'Parameter' ],
2320             [ 26, 'Filename' ],
2321             [ 18, 'Type' ],
2322             [ 9,  'Size' ]
2323         );
2324         for my $key ( sort keys %$uploads ) {
2325             my $upload = $uploads->{$key};
2326             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2327                 $t->row( $key, $u->filename, $u->type, $u->size );
2328             }
2329         }
2330         $c->log->debug( "File Uploads are:\n" . $t->draw );
2331     }
2332 }
2333
2334 =head2 $c->log_request_headers($headers);
2335
2336 Hook method which can be wrapped by plugins to log the request headers.
2337 No-op in the default implementation.
2338
2339 =cut
2340
2341 sub log_request_headers {}
2342
2343 =head2 $c->log_headers($type => $headers)
2344
2345 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2346
2347 =cut
2348
2349 sub log_headers {
2350     my $c       = shift;
2351     my $type    = shift;
2352     my $headers = shift;    # an HTTP::Headers instance
2353
2354     return unless $c->debug;
2355
2356     my $column_width = Catalyst::Utils::term_width() - 28;
2357     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2358     $headers->scan(
2359         sub {
2360             my ( $name, $value ) = @_;
2361             $t->row( $name, $value );
2362         }
2363     );
2364     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2365 }
2366
2367
2368 =head2 $c->prepare_read
2369
2370 Prepares the input for reading.
2371
2372 =cut
2373
2374 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2375
2376 =head2 $c->prepare_request
2377
2378 Prepares the engine request.
2379
2380 =cut
2381
2382 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2383
2384 =head2 $c->prepare_uploads
2385
2386 Prepares uploads.
2387
2388 =cut
2389
2390 sub prepare_uploads {
2391     my $c = shift;
2392
2393     $c->engine->prepare_uploads( $c, @_ );
2394 }
2395
2396 =head2 $c->prepare_write
2397
2398 Prepares the output for writing.
2399
2400 =cut
2401
2402 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2403
2404 =head2 $c->request_class
2405
2406 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2407
2408 =head2 $c->response_class
2409
2410 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2411
2412 =head2 $c->read( [$maxlength] )
2413
2414 Reads a chunk of data from the request body. This method is designed to
2415 be used in a while loop, reading C<$maxlength> bytes on every call.
2416 C<$maxlength> defaults to the size of the request if not specified.
2417
2418 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2419 directly.
2420
2421 Warning: If you use read(), Catalyst will not process the body,
2422 so you will not be able to access POST parameters or file uploads via
2423 $c->request.  You must handle all body parsing yourself.
2424
2425 =cut
2426
2427 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2428
2429 =head2 $c->run
2430
2431 Starts the engine.
2432
2433 =cut
2434
2435 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2436
2437 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2438
2439 Sets an action in a given namespace.
2440
2441 =cut
2442
2443 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2444
2445 =head2 $c->setup_actions($component)
2446
2447 Sets up actions for a component.
2448
2449 =cut
2450
2451 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2452
2453 =head2 $c->setup_config
2454
2455 =cut
2456
2457 sub setup_config {
2458     my $class = shift;
2459
2460     my %args = %{ $class->config || {} };
2461
2462     my @container_classes = ( "${class}::Container", 'Catalyst::Container');
2463     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2464
2465     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2466
2467     my $container = $container_class->new( %args, name => "$class" );
2468     $class->container($container);
2469
2470     my $config = $container->resolve(service => 'config');
2471     $class->config($config);
2472     $class->finalize_config; # back-compat
2473 }
2474
2475 =head $c->finalize_config
2476
2477 =cut
2478
2479 sub finalize_config { }
2480
2481 =head2 $c->setup_components
2482
2483 This method is called internally to set up the application's components.
2484
2485 It finds modules by calling the L<locate_components> method, expands them to
2486 package names with the L<expand_component_module> method, and then installs
2487 each component into the application.
2488
2489 The C<setup_components> config option is passed to both of the above methods.
2490
2491 Installation of each component is performed by the L<setup_component> method,
2492 below.
2493
2494 =cut
2495
2496 sub setup_components {
2497     my $class = shift;
2498
2499     my $config  = $class->config->{ setup_components };
2500
2501     my @comps = $class->locate_components($config);
2502     my %comps = map { $_ => 1 } @comps;
2503
2504     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2505     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2506         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2507     ) if $deprecatedcatalyst_component_names;
2508
2509     for my $component ( @comps ) {
2510
2511         # We pass ignore_loaded here so that overlay files for (e.g.)
2512         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2513         # we know M::P::O found a file on disk so this is safe
2514
2515         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2516     }
2517
2518     my $containers;
2519     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
2520
2521     for my $component (@comps) {
2522         my $instance = $class->components->{ $component } = $class->setup_component($component);
2523         if ( my ($type, $name) = _get_component_type_name($component) ) {
2524 # FIXME: shouldn't the service name be $name?
2525             $containers->{$type}->add_service(Bread::Board::BlockInjection->new( name => $component, block => sub { return $instance } ));
2526         }
2527         my @expanded_components = $instance->can('expand_modules')
2528             ? $instance->expand_modules( $component, $config )
2529             : $class->expand_component_module( $component, $config );
2530         for my $component (@expanded_components) {
2531             next if $comps{$component};
2532
2533             $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @expanded_components;
2534             $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2535                 qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2536             ) if $deprecatedcatalyst_component_names;
2537
2538             if (my ($type, $name) = _get_component_type_name($component)) {
2539                 $containers->{$type}->add_service(Bread::Board::BlockInjection->new( name => $component, block => sub { return $class->setup_component($component) } ));
2540             }
2541
2542             $class->components->{ $component } = $class->setup_component($component);
2543         }
2544     }
2545 }
2546
2547 sub _get_component_type_name {
2548     my $component = shift;
2549     my @parts     = split /::/, $component;
2550
2551     while (my $type = shift @parts) {
2552         return ('controller', join '::', @parts)
2553             if $type =~ /^(c|controller)$/i;
2554
2555         return ('model', join '::', @parts)
2556             if $type =~ /^(m|model)$/i;
2557
2558         return ('view', join '::', @parts)
2559             if $type =~ /^(v|view)$/i;
2560     }
2561 }
2562
2563 =head2 $c->locate_components( $setup_component_config )
2564
2565 This method is meant to provide a list of component modules that should be
2566 setup for the application.  By default, it will use L<Module::Pluggable>.
2567
2568 Specify a C<setup_components> config option to pass additional options directly
2569 to L<Module::Pluggable>. To add additional search paths, specify a key named
2570 C<search_extra> as an array reference. Items in the array beginning with C<::>
2571 will have the application class name prepended to them.
2572
2573 =cut
2574
2575 sub locate_components {
2576     my $class  = shift;
2577     my $config = shift;
2578
2579     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2580     my $extra   = delete $config->{ search_extra } || [];
2581
2582     push @paths, @$extra;
2583
2584     my $locator = Module::Pluggable::Object->new(
2585         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2586         %$config
2587     );
2588
2589     # XXX think about ditching this sort entirely
2590     my @comps = sort { length $a <=> length $b } $locator->plugins;
2591
2592     return @comps;
2593 }
2594
2595 =head2 $c->expand_component_module( $component, $setup_component_config )
2596
2597 Components found by C<locate_components> will be passed to this method, which
2598 is expected to return a list of component (package) names to be set up.
2599
2600 =cut
2601
2602 sub expand_component_module {
2603     my ($class, $module) = @_;
2604     return Devel::InnerPackage::list_packages( $module );
2605 }
2606
2607 =head2 $c->setup_component
2608
2609 =cut
2610
2611 sub setup_component {
2612     my( $class, $component ) = @_;
2613
2614     unless ( $component->can( 'COMPONENT' ) ) {
2615         return $component;
2616     }
2617
2618     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2619     my $config = $class->config->{ $suffix } || {};
2620     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2621     # methods also pass it. local to avoid pointlessly shitting in config
2622     # for the debug screen, as $component is already the key name.
2623     local $config->{catalyst_component_name} = $component;
2624
2625     my $instance = eval { $component->COMPONENT( $class, $config ); };
2626
2627     if ( my $error = $@ ) {
2628         chomp $error;
2629         Catalyst::Exception->throw(
2630             message => qq/Couldn't instantiate component "$component", "$error"/
2631         );
2632     }
2633     elsif (!blessed $instance) {
2634         my $metaclass = Moose::Util::find_meta($component);
2635         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2636         my $component_method_from = $method_meta->associated_metaclass->name;
2637         my $value = defined($instance) ? $instance : 'undef';
2638         Catalyst::Exception->throw(
2639             message =>
2640             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2641         );
2642     }
2643
2644     return $instance;
2645 }
2646
2647 =head2 $c->setup_dispatcher
2648
2649 Sets up dispatcher.
2650
2651 =cut
2652
2653 sub setup_dispatcher {
2654     my ( $class, $dispatcher ) = @_;
2655
2656     if ($dispatcher) {
2657         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2658     }
2659
2660     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2661         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2662     }
2663
2664     unless ($dispatcher) {
2665         $dispatcher = $class->dispatcher_class;
2666     }
2667
2668     Class::MOP::load_class($dispatcher);
2669
2670     # dispatcher instance
2671     $class->dispatcher( $dispatcher->new );
2672 }
2673
2674 =head2 $c->setup_engine
2675
2676 Sets up engine.
2677
2678 =cut
2679
2680 sub setup_engine {
2681     my ( $class, $engine ) = @_;
2682
2683     if ($engine) {
2684         $engine = 'Catalyst::Engine::' . $engine;
2685     }
2686
2687     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2688         $engine = 'Catalyst::Engine::' . $env;
2689     }
2690
2691     if ( $ENV{MOD_PERL} ) {
2692         my $meta = Class::MOP::get_metaclass_by_name($class);
2693
2694         # create the apache method
2695         $meta->add_method('apache' => sub { shift->engine->apache });
2696
2697         my ( $software, $version ) =
2698           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2699
2700         $version =~ s/_//g;
2701         $version =~ s/(\.[^.]+)\./$1/g;
2702
2703         if ( $software eq 'mod_perl' ) {
2704
2705             if ( !$engine ) {
2706
2707                 if ( $version >= 1.99922 ) {
2708                     $engine = 'Catalyst::Engine::Apache2::MP20';
2709                 }
2710
2711                 elsif ( $version >= 1.9901 ) {
2712                     $engine = 'Catalyst::Engine::Apache2::MP19';
2713                 }
2714
2715                 elsif ( $version >= 1.24 ) {
2716                     $engine = 'Catalyst::Engine::Apache::MP13';
2717                 }
2718
2719                 else {
2720                     Catalyst::Exception->throw( message =>
2721                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2722                 }
2723
2724             }
2725
2726             # install the correct mod_perl handler
2727             if ( $version >= 1.9901 ) {
2728                 *handler = sub  : method {
2729                     shift->handle_request(@_);
2730                 };
2731             }
2732             else {
2733                 *handler = sub ($$) { shift->handle_request(@_) };
2734             }
2735
2736         }
2737
2738         elsif ( $software eq 'Zeus-Perl' ) {
2739             $engine = 'Catalyst::Engine::Zeus';
2740         }
2741
2742         else {
2743             Catalyst::Exception->throw(
2744                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2745         }
2746     }
2747
2748     unless ($engine) {
2749         $engine = $class->engine_class;
2750     }
2751
2752     Class::MOP::load_class($engine);
2753
2754     # check for old engines that are no longer compatible
2755     my $old_engine;
2756     if ( $engine->isa('Catalyst::Engine::Apache')
2757         && !Catalyst::Engine::Apache->VERSION )
2758     {
2759         $old_engine = 1;
2760     }
2761
2762     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2763         && Catalyst::Engine::Server->VERSION le '0.02' )
2764     {
2765         $old_engine = 1;
2766     }
2767
2768     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2769         && $engine->VERSION eq '0.01' )
2770     {
2771         $old_engine = 1;
2772     }
2773
2774     elsif ($engine->isa('Catalyst::Engine::Zeus')
2775         && $engine->VERSION eq '0.01' )
2776     {
2777         $old_engine = 1;
2778     }
2779
2780     if ($old_engine) {
2781         Catalyst::Exception->throw( message =>
2782               qq/Engine "$engine" is not supported by this version of Catalyst/
2783         );
2784     }
2785
2786     # engine instance
2787     $class->engine( $engine->new );
2788 }
2789
2790 =head2 $c->setup_home
2791
2792 Sets up the home directory.
2793
2794 =cut
2795
2796 sub setup_home {
2797     my ( $class, $home ) = @_;
2798
2799     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2800         $home = $env;
2801     }
2802
2803     $home ||= Catalyst::Utils::home($class);
2804
2805     if ($home) {
2806         #I remember recently being scolded for assigning config values like this
2807         $class->config->{home} ||= $home;
2808         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2809     }
2810 }
2811
2812 =head2 $c->setup_log
2813
2814 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2815 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2816 log to.
2817
2818 This method also installs a C<debug> method that returns a true value into the
2819 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2820 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2821
2822 Note that if the log has already been setup, by either a previous call to
2823 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2824 that this method won't actually set up the log object.
2825
2826 =cut
2827
2828 sub setup_log {
2829     my ( $class, $levels ) = @_;
2830
2831     $levels ||= '';
2832     $levels =~ s/^\s+//;
2833     $levels =~ s/\s+$//;
2834     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2835
2836     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2837     if ( defined $env_debug ) {
2838         $levels{debug} = 1 if $env_debug; # Ugly!
2839         delete($levels{debug}) unless $env_debug;
2840     }
2841
2842     unless ( $class->log ) {
2843         $class->log( Catalyst::Log->new(keys %levels) );
2844     }
2845
2846     if ( $levels{debug} ) {
2847         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2848         $class->log->debug('Debug messages enabled');
2849     }
2850 }
2851
2852 =head2 $c->setup_plugins
2853
2854 Sets up plugins.
2855
2856 =cut
2857
2858 =head2 $c->setup_stats
2859
2860 Sets up timing statistics class.
2861
2862 =cut
2863
2864 sub setup_stats {
2865     my ( $class, $stats ) = @_;
2866
2867     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2868
2869     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2870     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2871         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2872         $class->log->debug('Statistics enabled');
2873     }
2874 }
2875
2876
2877 =head2 $c->registered_plugins
2878
2879 Returns a sorted list of the plugins which have either been stated in the
2880 import list or which have been added via C<< MyApp->plugin(@args); >>.
2881
2882 If passed a given plugin name, it will report a boolean value indicating
2883 whether or not that plugin is loaded.  A fully qualified name is required if
2884 the plugin name does not begin with C<Catalyst::Plugin::>.
2885
2886  if ($c->registered_plugins('Some::Plugin')) {
2887      ...
2888  }
2889
2890 =cut
2891
2892 {
2893
2894     sub registered_plugins {
2895         my $proto = shift;
2896         return sort keys %{ $proto->_plugins } unless @_;
2897         my $plugin = shift;
2898         return 1 if exists $proto->_plugins->{$plugin};
2899         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2900     }
2901
2902     sub _register_plugin {
2903         my ( $proto, $plugin, $instant ) = @_;
2904         my $class = ref $proto || $proto;
2905
2906         Class::MOP::load_class( $plugin );
2907         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2908             if $plugin->isa( 'Catalyst::Component' );
2909         $proto->_plugins->{$plugin} = 1;
2910         unless ($instant) {
2911             my $meta = Class::MOP::get_metaclass_by_name($class);
2912             $meta->superclasses($plugin, $meta->superclasses);
2913         }
2914         return $class;
2915     }
2916
2917     sub setup_plugins {
2918         my ( $class, $plugins ) = @_;
2919
2920         $class->_plugins( {} ) unless $class->_plugins;
2921         $plugins = Data::OptList::mkopt($plugins || []);
2922
2923         my @plugins = map {
2924             [ Catalyst::Utils::resolve_namespace(
2925                   $class . '::Plugin',
2926                   'Catalyst::Plugin', $_->[0]
2927               ),
2928               $_->[1],
2929             ]
2930          } @{ $plugins };
2931
2932         for my $plugin ( reverse @plugins ) {
2933             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2934             my $meta = find_meta($plugin->[0]);
2935             next if $meta && $meta->isa('Moose::Meta::Role');
2936
2937             $class->_register_plugin($plugin->[0]);
2938         }
2939
2940         my @roles =
2941             map  { $_->[0]->name, $_->[1] }
2942             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2943             map  { [find_meta($_->[0]), $_->[1]] }
2944             @plugins;
2945
2946         Moose::Util::apply_all_roles(
2947             $class => @roles
2948         ) if @roles;
2949     }
2950 }
2951
2952 =head2 $c->stack
2953
2954 Returns an arrayref of the internal execution stack (actions that are
2955 currently executing).
2956
2957 =head2 $c->stats
2958
2959 Returns the current timing statistics object. By default Catalyst uses
2960 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2961 L<< stats_class|/"$c->stats_class" >>.
2962
2963 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2964 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2965 profile explicitly, although MyApp.pm still won't profile nor output anything
2966 by itself.
2967
2968 =head2 $c->stats_class
2969
2970 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2971
2972 =head2 $c->use_stats
2973
2974 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2975
2976 Note that this is a static method, not an accessor and should be overridden
2977 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2978
2979 =cut
2980
2981 sub use_stats { 0 }
2982
2983
2984 =head2 $c->write( $data )
2985
2986 Writes $data to the output stream. When using this method directly, you
2987 will need to manually set the C<Content-Length> header to the length of
2988 your output data, if known.
2989
2990 =cut
2991
2992 sub write {
2993     my $c = shift;
2994
2995     # Finalize headers if someone manually writes output
2996     $c->finalize_headers;
2997
2998     return $c->engine->write( $c, @_ );
2999 }
3000
3001 =head2 version
3002
3003 Returns the Catalyst version number. Mostly useful for "powered by"
3004 messages in template systems.
3005
3006 =cut
3007
3008 sub version { return $Catalyst::VERSION }
3009
3010 =head1 CONFIGURATION
3011
3012 There are a number of 'base' config variables which can be set:
3013
3014 =over
3015
3016 =item *
3017
3018 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3019
3020 =item *
3021
3022 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3023
3024 =item *
3025
3026 C<disable_component_resolution_regex_fallback> - Turns
3027 off the deprecated component resolution functionality so
3028 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3029 are called then regex search will not be attempted on string values and
3030 instead C<undef> will be returned.
3031
3032 =item *
3033
3034 C<home> - The application home directory. In an uninstalled application,
3035 this is the top level application directory. In an installed application,
3036 this will be the directory containing C<< MyApp.pm >>.
3037
3038 =item *
3039
3040 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3041
3042 =item *
3043
3044 C<name> - The name of the application in debug messages and the debug and
3045 welcome screens
3046
3047 =item *
3048
3049 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3050 until it is accessed. This allows you to (for example) check authentication (and reject
3051 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
3052
3053 =item *
3054
3055 C<root> - The root directory for templates. Usually this is just a
3056 subdirectory of the home directory, but you can set it to change the
3057 templates to a different directory.
3058
3059 =item *
3060
3061 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3062 namespaces from which components will be loaded (and constructed and stored in
3063 C<< $c->components >>).
3064
3065 =item *
3066
3067 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3068 to be shown in hit debug tables in the test server.
3069
3070 =item *
3071
3072 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3073 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
3074 for more information.
3075
3076 =item *
3077
3078 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3079
3080 =back
3081
3082 =head1 INTERNAL ACTIONS
3083
3084 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3085 C<_ACTION>, and C<_END>. These are by default not shown in the private
3086 action table, but you can make them visible with a config parameter.
3087
3088     MyApp->config(show_internal_actions => 1);
3089
3090 =head1 ON-DEMAND PARSER
3091
3092 The request body is usually parsed at the beginning of a request,
3093 but if you want to handle input yourself, you can enable on-demand
3094 parsing with a config parameter.
3095
3096     MyApp->config(parse_on_demand => 1);
3097
3098 =head1 PROXY SUPPORT
3099
3100 Many production servers operate using the common double-server approach,
3101 with a lightweight frontend web server passing requests to a larger
3102 backend server. An application running on the backend server must deal
3103 with two problems: the remote user always appears to be C<127.0.0.1> and
3104 the server's hostname will appear to be C<localhost> regardless of the
3105 virtual host that the user connected through.
3106
3107 Catalyst will automatically detect this situation when you are running
3108 the frontend and backend servers on the same machine. The following
3109 changes are made to the request.
3110
3111     $c->req->address is set to the user's real IP address, as read from
3112     the HTTP X-Forwarded-For header.
3113
3114     The host value for $c->req->base and $c->req->uri is set to the real
3115     host, as read from the HTTP X-Forwarded-Host header.
3116
3117 Additionally, you may be running your backend application on an insecure
3118 connection (port 80) while your frontend proxy is running under SSL.  If there
3119 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3120 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3121 be created properly.
3122
3123 In the case of passing in:
3124
3125     X-Forwarded-Port: 443
3126
3127 All calls to C<uri_for> will result in an https link, as is expected.
3128
3129 Obviously, your web server must support these headers for this to work.
3130
3131 In a more complex server farm environment where you may have your
3132 frontend proxy server(s) on different machines, you will need to set a
3133 configuration option to tell Catalyst to read the proxied data from the
3134 headers.
3135
3136     MyApp->config(using_frontend_proxy => 1);
3137
3138 If you do not wish to use the proxy support at all, you may set:
3139
3140     MyApp->config(ignore_frontend_proxy => 1);
3141
3142 =head1 THREAD SAFETY
3143
3144 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3145 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3146 believe the Catalyst core to be thread-safe.
3147
3148 If you plan to operate in a threaded environment, remember that all other
3149 modules you are using must also be thread-safe. Some modules, most notably
3150 L<DBD::SQLite>, are not thread-safe.
3151
3152 =head1 SUPPORT
3153
3154 IRC:
3155
3156     Join #catalyst on irc.perl.org.
3157
3158 Mailing Lists:
3159
3160     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3161     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3162
3163 Web:
3164
3165     http://catalyst.perl.org
3166
3167 Wiki:
3168
3169     http://dev.catalyst.perl.org
3170
3171 =head1 SEE ALSO
3172
3173 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3174
3175 =head2 L<Catalyst::Manual> - The Catalyst Manual
3176
3177 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3178
3179 =head2 L<Catalyst::Engine> - Core engine
3180
3181 =head2 L<Catalyst::Log> - Log class.
3182
3183 =head2 L<Catalyst::Request> - Request object
3184
3185 =head2 L<Catalyst::Response> - Response object
3186
3187 =head2 L<Catalyst::Test> - The test suite.
3188
3189 =head1 PROJECT FOUNDER
3190
3191 sri: Sebastian Riedel <sri@cpan.org>
3192
3193 =head1 CONTRIBUTORS
3194
3195 abw: Andy Wardley
3196
3197 acme: Leon Brocard <leon@astray.com>
3198
3199 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3200
3201 Andrew Bramble
3202
3203 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3204
3205 Andrew Ruthven
3206
3207 andyg: Andy Grundman <andy@hybridized.org>
3208
3209 audreyt: Audrey Tang
3210
3211 bricas: Brian Cassidy <bricas@cpan.org>
3212
3213 Caelum: Rafael Kitover <rkitover@io.com>
3214
3215 chansen: Christian Hansen
3216
3217 chicks: Christopher Hicks
3218
3219 Chisel Wright C<pause@herlpacker.co.uk>
3220
3221 Danijel Milicevic C<me@danijel.de>
3222
3223 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3224
3225 David Naughton, C<naughton@umn.edu>
3226
3227 David E. Wheeler
3228
3229 dhoss: Devin Austin <dhoss@cpan.org>
3230
3231 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3232
3233 Drew Taylor
3234
3235 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3236
3237 esskar: Sascha Kiefer
3238
3239 fireartist: Carl Franks <cfranks@cpan.org>
3240
3241 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3242
3243 gabb: Danijel Milicevic
3244
3245 Gary Ashton Jones
3246
3247 Gavin Henry C<ghenry@perl.me.uk>
3248
3249 Geoff Richards
3250
3251 groditi: Guillermo Roditi <groditi@gmail.com>
3252
3253 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3254
3255 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3256
3257 jcamacho: Juan Camacho
3258
3259 jester: Jesse Sheidlower C<jester@panix.com>
3260
3261 jhannah: Jay Hannah <jay@jays.net>
3262
3263 Jody Belka
3264
3265 Johan Lindstrom
3266
3267 jon: Jon Schutz <jjschutz@cpan.org>
3268
3269 Jonathan Rockway C<< <jrockway@cpan.org> >>
3270
3271 Kieren Diment C<kd@totaldatasolution.com>
3272
3273 konobi: Scott McWhirter <konobi@cpan.org>
3274
3275 marcus: Marcus Ramberg <mramberg@cpan.org>
3276
3277 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3278
3279 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3280
3281 mugwump: Sam Vilain
3282
3283 naughton: David Naughton
3284
3285 ningu: David Kamholz <dkamholz@cpan.org>
3286
3287 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3288
3289 numa: Dan Sully <daniel@cpan.org>
3290
3291 obra: Jesse Vincent
3292
3293 Octavian Rasnita
3294
3295 omega: Andreas Marienborg
3296
3297 Oleg Kostyuk <cub.uanic@gmail.com>
3298
3299 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3300
3301 rafl: Florian Ragwitz <rafl@debian.org>
3302
3303 random: Roland Lammel <lammel@cpan.org>
3304
3305 Robert Sedlacek C<< <rs@474.at> >>
3306
3307 SpiceMan: Marcel Montes
3308
3309 sky: Arthur Bergman
3310
3311 szbalint: Balint Szilakszi <szbalint@cpan.org>
3312
3313 t0m: Tomas Doran <bobtfish@bobtfish.net>
3314
3315 Ulf Edvinsson
3316
3317 Viljo Marrandi C<vilts@yahoo.com>
3318
3319 Will Hawes C<info@whawes.co.uk>
3320
3321 willert: Sebastian Willert <willert@cpan.org>
3322
3323 wreis: Wallace Reis <wallace@reis.org.br>
3324
3325 Yuval Kogman, C<nothingmuch@woobling.org>
3326
3327 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3328
3329 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3330
3331 =head1 COPYRIGHT
3332
3333 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3334
3335 =head1 LICENSE
3336
3337 This library is free software. You can redistribute it and/or modify it under
3338 the same terms as Perl itself.
3339
3340 =cut
3341
3342 no Moose;
3343
3344 __PACKAGE__->meta->make_immutable;
3345
3346 1;