lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 extends 'Catalyst::Component';
   5 use bytes;
   6 use Scope::Upper ();
   7 use Catalyst::Exception;
   8 use Catalyst::Log;
   9 use Catalyst::Request;
  10 use Catalyst::Request::Upload;
  11 use Catalyst::Response;
  12 use Catalyst::Utils;
  13 use Catalyst::Controller;
  14 use Devel::InnerPackage ();
  15 use File::stat;
  16 use Module::Pluggable::Object ();
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp shortmess/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 has stack => (is => 'ro', default => sub { [] });
  34 has stash => (is => 'rw', default => sub { {} });
  35 has state => (is => 'rw', default => 0);
  36 has stats => (is => 'rw');
  37 has action => (is => 'rw');
  38 has counter => (is => 'rw', default => sub { {} });
  39 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  40 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  41 has namespace => (is => 'rw');
  42
  43 sub depth { scalar @{ shift->stack || [] }; }
  44 sub comp { shift->component(@_) }
  45
  46 sub req {
  47     # carp "the use of req() is deprecated in favour of request()";
  48     my $self = shift; return $self->request(@_);
  49 }
  50 sub res {
  51     # carp "the use of res() is deprecated in favour of response()";
  52     my $self = shift; return $self->response(@_);
  53 }
  54
  55 # For backwards compatibility
  56 sub finalize_output { shift->finalize_body(@_) };
  57
  58 # For statistics
  59 our $COUNT     = 1;
  60 our $START     = time;
  61 our $RECURSION = 1000;
  62 our $DETACH    = "catalyst_detach\n";
  63 our $GO        = "catalyst_go\n";
  64
  65 #I imagine that very few of these really need to be class variables. if any.
  66 #maybe we should just make them attributes with a default?
  67 __PACKAGE__->mk_classdata($_)
  68   for qw/components arguments dispatcher engine log dispatcher_class
  69   engine_class context_class request_class response_class stats_class
  70   setup_finished/;
  71
  72 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  73 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  74 __PACKAGE__->request_class('Catalyst::Request');
  75 __PACKAGE__->response_class('Catalyst::Response');
  76 __PACKAGE__->stats_class('Catalyst::Stats');
  77
  78 # Remember to update this in Catalyst::Runtime as well!
  79
  80 our $VERSION = '5.8000_05';
  81
  82 sub import {
  83     my ( $class, @arguments ) = @_;
  84
  85     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  86     # callers @ISA.
  87     return unless $class eq 'Catalyst';
  88
  89     my $caller = caller();
  90     return if $caller eq 'main';
  91     my $meta = Moose::Meta::Class->initialize($caller);
  92     #Moose->import({ into => $caller }); #do we want to do this?
  93
  94     unless ( $caller->isa('Catalyst') ) {
  95         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  96         $meta->superclasses(@superclasses);
  97     }
  98     unless( $meta->has_method('meta') ){
  99         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 100     }
 101
 102     $caller->arguments( [@arguments] );
 103     $caller->setup_home;
 104 }
 105
 106 =head1 NAME
 107
 108 Catalyst - The Elegant MVC Web Application Framework
 109
 110 =head1 SYNOPSIS
 111
 112 See the L<Catalyst::Manual> distribution for comprehensive
 113 documentation and tutorials.
 114
 115     # Install Catalyst::Devel for helpers and other development tools
 116     # use the helper to create a new application
 117     catalyst.pl MyApp
 118
 119     # add models, views, controllers
 120     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 121     script/myapp_create.pl view MyTemplate TT
 122     script/myapp_create.pl controller Search
 123
 124     # built in testserver -- use -r to restart automatically on changes
 125     # --help to see all available options
 126     script/myapp_server.pl
 127
 128     # command line testing interface
 129     script/myapp_test.pl /yada
 130
 131     ### in lib/MyApp.pm
 132     use Catalyst qw/-Debug/; # include plugins here as well
 133
 134     ### In lib/MyApp/Controller/Root.pm (autocreated)
 135     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 136         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 137         $c->stash->{template} = 'foo.tt'; # set the template
 138         # lookup something from db -- stash vars are passed to TT
 139         $c->stash->{data} =
 140           $c->model('Database::Foo')->search( { country => $args[0] } );
 141         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 142             $c->forward( 'bar' ); # process another action
 143             # do something else after forward returns
 144         }
 145     }
 146
 147     # The foo.tt TT template can use the stash data from the database
 148     [% WHILE (item = data.next) %]
 149         [% item.foo %]
 150     [% END %]
 151
 152     # called for /bar/of/soap, /bar/of/soap/10, etc.
 153     sub bar : Path('/bar/of/soap') { ... }
 154
 155     # called for all actions, from the top-most controller downwards
 156     sub auto : Private {
 157         my ( $self, $c ) = @_;
 158         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 159             $c->res->redirect( '/login' ); # require login
 160             return 0; # abort request and go immediately to end()
 161         }
 162         return 1; # success; carry on to next action
 163     }
 164
 165     # called after all actions are finished
 166     sub end : Private {
 167         my ( $self, $c ) = @_;
 168         if ( scalar @{ $c->error } ) { ... } # handle errors
 169         return if $c->res->body; # already have a response
 170         $c->forward( 'MyApp::View::TT' ); # render template
 171     }
 172
 173     ### in MyApp/Controller/Foo.pm
 174     # called for /foo/bar
 175     sub bar : Local { ... }
 176
 177     # called for /blargle
 178     sub blargle : Global { ... }
 179
 180     # an index action matches /foo, but not /foo/1, etc.
 181     sub index : Private { ... }
 182
 183     ### in MyApp/Controller/Foo/Bar.pm
 184     # called for /foo/bar/baz
 185     sub baz : Local { ... }
 186
 187     # first Root auto is called, then Foo auto, then this
 188     sub auto : Private { ... }
 189
 190     # powerful regular expression paths are also possible
 191     sub details : Regex('^product/(\w+)/details$') {
 192         my ( $self, $c ) = @_;
 193         # extract the (\w+) from the URI
 194         my $product = $c->req->captures->[0];
 195     }
 196
 197 See L<Catalyst::Manual::Intro> for additional information.
 198
 199 =head1 DESCRIPTION
 200
 201 Catalyst is a modern framework for making web applications without the
 202 pain usually associated with this process. This document is a reference
 203 to the main Catalyst application. If you are a new user, we suggest you
 204 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 205
 206 See L<Catalyst::Manual> for more documentation.
 207
 208 Catalyst plugins can be loaded by naming them as arguments to the "use
 209 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 210 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 211 C<My::Module>.
 212
 213     use Catalyst qw/My::Module/;
 214
 215 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 216 fully qualify the name by using a unary plus:
 217
 218     use Catalyst qw/
 219         My::Module
 220         +Fully::Qualified::Plugin::Name
 221     /;
 222
 223 Special flags like C<-Debug> and C<-Engine> can also be specified as
 224 arguments when Catalyst is loaded:
 225
 226     use Catalyst qw/-Debug My::Module/;
 227
 228 The position of plugins and flags in the chain is important, because
 229 they are loaded in the order in which they appear.
 230
 231 The following flags are supported:
 232
 233 =head2 -Debug
 234
 235 Enables debug output. You can also force this setting from the system
 236 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 237 settings override the application, with <MYAPP>_DEBUG having the highest
 238 priority.
 239
 240 =head2 -Engine
 241
 242 Forces Catalyst to use a specific engine. Omit the
 243 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 244
 245     use Catalyst qw/-Engine=CGI/;
 246
 247 =head2 -Home
 248
 249 Forces Catalyst to use a specific home directory, e.g.:
 250
 251     use Catalyst qw[-Home=/usr/mst];
 252
 253 This can also be done in the shell environment by setting either the
 254 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 255 is replaced with the uppercased name of your application, any "::" in
 256 the name will be replaced with underscores, e.g. MyApp::Web should use
 257 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 258
 259 =head2 -Log
 260
 261     use Catalyst '-Log=warn,fatal,error';
 262
 263 Specifies a comma-delimited list of log levels.
 264
 265 =head2 -Stats
 266
 267 Enables statistics collection and reporting. You can also force this setting
 268 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 269 environment settings override the application, with <MYAPP>_STATS having the
 270 highest priority.
 271
 272 e.g.
 273
 274    use Catalyst qw/-Stats=1/
 275
 276 =head1 METHODS
 277
 278 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 279
 280 =head2 $c->action
 281
 282 Returns a L<Catalyst::Action> object for the current action, which
 283 stringifies to the action name. See L<Catalyst::Action>.
 284
 285 =head2 $c->namespace
 286
 287 Returns the namespace of the current action, i.e., the URI prefix
 288 corresponding to the controller of the current action. For example:
 289
 290     # in Controller::Foo::Bar
 291     $c->namespace; # returns 'foo/bar';
 292
 293 =head2 $c->request
 294
 295 =head2 $c->req
 296
 297 Returns the current L<Catalyst::Request> object, giving access to
 298 information about the current client request (including parameters,
 299 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 300
 301 =head2 REQUEST FLOW HANDLING
 302
 303 =head2 $c->forward( $action [, \@arguments ] )
 304
 305 =head2 $c->forward( $class, $method, [, \@arguments ] )
 306
 307 Forwards processing to another action, by its private name. If you give a
 308 class name but no method, C<process()> is called. You may also optionally
 309 pass arguments in an arrayref. The action will receive the arguments in
 310 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 311 C<< $c->req->args >> will be restored to the previous values.
 312
 313 Any data C<return>ed from the action forwarded to, will be returned by the
 314 call to forward.
 315
 316     my $foodata = $c->forward('/foo');
 317     $c->forward('index');
 318     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 319     $c->forward('MyApp::View::TT');
 320
 321 Note that forward implies an C<<eval { }>> around the call (actually
 322 C<execute> does), thus de-fatalizing all 'dies' within the called
 323 action. If you want C<die> to propagate you need to do something like:
 324
 325     $c->forward('foo');
 326     die $c->error if $c->error;
 327
 328 Or make sure to always return true values from your actions and write
 329 your code like this:
 330
 331     $c->forward('foo') || return;
 332
 333 =cut
 334
 335 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 336
 337 =head2 $c->detach( $action [, \@arguments ] )
 338
 339 =head2 $c->detach( $class, $method, [, \@arguments ] )
 340
 341 =head2 $c->detach()
 342
 343 The same as C<forward>, but doesn't return to the previous action when
 344 processing is finished.
 345
 346 When called with no arguments it escapes the processing chain entirely.
 347
 348 =cut
 349
 350 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 351
 352 =head2 $c->visit( $action [, \@arguments ] )
 353
 354 =head2 $c->visit( $class, $method, [, \@arguments ] )
 355
 356 Almost the same as C<forward>, but does a full dispatch, instead of just
 357 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 358 C<auto> and the method you go to are called, just like a new request.
 359
 360 C<$c-E<gt>stash> is kept unchanged.
 361
 362 In effect, C<visit> allows you to "wrap" another action, just as it
 363 would have been called by dispatching from a URL, while the analogous
 364 C<go> allows you to transfer control to another action as if it had
 365 been reached directly from a URL.
 366
 367 =cut
 368
 369 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 370
 371 =head2 $c->go( $action [, \@arguments ] )
 372
 373 =head2 $c->go( $class, $method, [, \@arguments ] )
 374
 375 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 376 instead of just calling the new C<$action> /
 377 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 378 method you visit are called, just like a new request.
 379
 380 C<$c-E<gt>stash> is kept unchanged.
 381
 382 =cut
 383
 384 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 385
 386 =head2 $c->response
 387
 388 =head2 $c->res
 389
 390 Returns the current L<Catalyst::Response> object, see there for details.
 391
 392 =head2 $c->stash
 393
 394 Returns a hashref to the stash, which may be used to store data and pass
 395 it between components during a request. You can also set hash keys by
 396 passing arguments. The stash is automatically sent to the view. The
 397 stash is cleared at the end of a request; it cannot be used for
 398 persistent storage (for this you must use a session; see
 399 L<Catalyst::Plugin::Session> for a complete system integrated with
 400 Catalyst).
 401
 402     $c->stash->{foo} = $bar;
 403     $c->stash( { moose => 'majestic', qux => 0 } );
 404     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 405
 406     # stash is automatically passed to the view for use in a template
 407     $c->forward( 'MyApp::View::TT' );
 408
 409 =cut
 410
 411 around stash => sub {
 412     my $orig = shift;
 413     my $c = shift;
 414     my $stash = $orig->($c);
 415     if (@_) {
 416         my $new_stash = @_ > 1 ? {@_} : $_[0];
 417         croak('stash takes a hash or hashref') unless ref $new_stash;
 418         foreach my $key ( keys %$new_stash ) {
 419           $stash->{$key} = $new_stash->{$key};
 420         }
 421     }
 422
 423     return $stash;
 424 };
 425
 426
 427 =head2 $c->error
 428
 429 =head2 $c->error($error, ...)
 430
 431 =head2 $c->error($arrayref)
 432
 433 Returns an arrayref containing error messages.  If Catalyst encounters an
 434 error while processing a request, it stores the error in $c->error.  This
 435 method should only be used to store fatal error messages.
 436
 437     my @error = @{ $c->error };
 438
 439 Add a new error.
 440
 441     $c->error('Something bad happened');
 442
 443 =cut
 444
 445 sub error {
 446     my $c = shift;
 447     if ( $_[0] ) {
 448         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 449         croak @$error unless ref $c;
 450         push @{ $c->{error} }, @$error;
 451     }
 452     elsif ( defined $_[0] ) { $c->{error} = undef }
 453     return $c->{error} || [];
 454 }
 455
 456
 457 =head2 $c->state
 458
 459 Contains the return value of the last executed action.
 460
 461 =head2 $c->clear_errors
 462
 463 Clear errors.  You probably don't want to clear the errors unless you are
 464 implementing a custom error screen.
 465
 466 This is equivalent to running
 467
 468     $c->error(0);
 469
 470 =cut
 471
 472 sub clear_errors {
 473     my $c = shift;
 474     $c->error(0);
 475 }
 476
 477 # search components given a name and some prefixes
 478 sub _comp_search_prefixes {
 479     my ( $c, $name, @prefixes ) = @_;
 480     my $appclass = ref $c || $c;
 481     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 482
 483     # map the original component name to the sub part that we will search against
 484     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 485         grep { /$filter/ } keys %{ $c->components };
 486
 487     # undef for a name will return all
 488     return keys %eligible if !defined $name;
 489
 490     my $query  = ref $name ? $name : qr/^$name$/i;
 491     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 492
 493     return map { $c->components->{ $_ } } @result if @result;
 494
 495     # if we were given a regexp to search against, we're done.
 496     return if ref $name;
 497
 498     # regexp fallback
 499     $query  = qr/$name/i;
 500     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 501
 502     # no results? try against full names
 503     if( !@result ) {
 504         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 505     }
 506
 507     # don't warn if we didn't find any results, it just might not exist
 508     if( @result ) {
 509         my $msg = "Used regexp fallback for \$c->model('${name}'), which found '" .
 510            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 511            "component resolution is unreliable and unsafe.";
 512         my $short = $result[0];
 513         $short =~ s/.*?Model:://;
 514         my $shortmess = Carp::shortmess('');
 515         if ($shortmess =~ m#Catalyst/Plugin#) {
 516            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 517               "plugin's config";
 518         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 519            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 520               "component's config";
 521         } else {
 522            $msg .= " You probably meant \$c->model('$short') instead of \$c->model{'${name}'}, " .
 523               "but if you really wanted to search, pass in a regexp as the argument " .
 524               "like so: \$c->model(qr/${name}/)";
 525         }
 526         $c->log->warn( "${msg}$shortmess" );
 527     }
 528
 529     return @result;
 530 }
 531
 532 # Find possible names for a prefix
 533 sub _comp_names {
 534     my ( $c, @prefixes ) = @_;
 535     my $appclass = ref $c || $c;
 536
 537     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 538
 539     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 540     return @names;
 541 }
 542
 543 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 544 sub _filter_component {
 545     my ( $c, $comp, @args ) = @_;
 546
 547     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 548         return $comp->ACCEPT_CONTEXT( $c, @args );
 549     }
 550
 551     return $comp;
 552 }
 553
 554 =head2 COMPONENT ACCESSORS
 555
 556 =head2 $c->controller($name)
 557
 558 Gets a L<Catalyst::Controller> instance by name.
 559
 560     $c->controller('Foo')->do_stuff;
 561
 562 If the name is omitted, will return the controller for the dispatched
 563 action.
 564
 565 If you want to search for controllers, pass in a regexp as the argument.
 566
 567     # find all controllers that start with Foo
 568     my @foo_controllers = $c->controller(qr{^Foo});
 569
 570
 571 =cut
 572
 573 sub controller {
 574     my ( $c, $name, @args ) = @_;
 575
 576     if( $name ) {
 577         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 578         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 579         return $c->_filter_component( $result[ 0 ], @args );
 580     }
 581
 582     return $c->component( $c->action->class );
 583 }
 584
 585 =head2 $c->model($name)
 586
 587 Gets a L<Catalyst::Model> instance by name.
 588
 589     $c->model('Foo')->do_stuff;
 590
 591 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 592
 593 If the name is omitted, it will look for
 594  - a model object in $c->stash->{current_model_instance}, then
 595  - a model name in $c->stash->{current_model}, then
 596  - a config setting 'default_model', or
 597  - check if there is only one model, and return it if that's the case.
 598
 599 If you want to search for models, pass in a regexp as the argument.
 600
 601     # find all models that start with Foo
 602     my @foo_models = $c->model(qr{^Foo});
 603
 604 =cut
 605
 606 sub model {
 607     my ( $c, $name, @args ) = @_;
 608
 609     if( $name ) {
 610         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 611         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 612         return $c->_filter_component( $result[ 0 ], @args );
 613     }
 614
 615     if (ref $c) {
 616         return $c->stash->{current_model_instance}
 617           if $c->stash->{current_model_instance};
 618         return $c->model( $c->stash->{current_model} )
 619           if $c->stash->{current_model};
 620     }
 621     return $c->model( $c->config->{default_model} )
 622       if $c->config->{default_model};
 623
 624     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 625
 626     if( $rest ) {
 627         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 628         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 629         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 630         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 631         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 632     }
 633
 634     return $c->_filter_component( $comp );
 635 }
 636
 637
 638 =head2 $c->view($name)
 639
 640 Gets a L<Catalyst::View> instance by name.
 641
 642     $c->view('Foo')->do_stuff;
 643
 644 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 645
 646 If the name is omitted, it will look for
 647  - a view object in $c->stash->{current_view_instance}, then
 648  - a view name in $c->stash->{current_view}, then
 649  - a config setting 'default_view', or
 650  - check if there is only one view, and return it if that's the case.
 651
 652 If you want to search for views, pass in a regexp as the argument.
 653
 654     # find all views that start with Foo
 655     my @foo_views = $c->view(qr{^Foo});
 656
 657 =cut
 658
 659 sub view {
 660     my ( $c, $name, @args ) = @_;
 661
 662     if( $name ) {
 663         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 664         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 665         return $c->_filter_component( $result[ 0 ], @args );
 666     }
 667
 668     if (ref $c) {
 669         return $c->stash->{current_view_instance}
 670           if $c->stash->{current_view_instance};
 671         return $c->view( $c->stash->{current_view} )
 672           if $c->stash->{current_view};
 673     }
 674     return $c->view( $c->config->{default_view} )
 675       if $c->config->{default_view};
 676
 677     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 678
 679     if( $rest ) {
 680         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 681         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 682         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 683         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 684         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 685     }
 686
 687     return $c->_filter_component( $comp );
 688 }
 689
 690 =head2 $c->controllers
 691
 692 Returns the available names which can be passed to $c->controller
 693
 694 =cut
 695
 696 sub controllers {
 697     my ( $c ) = @_;
 698     return $c->_comp_names(qw/Controller C/);
 699 }
 700
 701 =head2 $c->models
 702
 703 Returns the available names which can be passed to $c->model
 704
 705 =cut
 706
 707 sub models {
 708     my ( $c ) = @_;
 709     return $c->_comp_names(qw/Model M/);
 710 }
 711
 712
 713 =head2 $c->views
 714
 715 Returns the available names which can be passed to $c->view
 716
 717 =cut
 718
 719 sub views {
 720     my ( $c ) = @_;
 721     return $c->_comp_names(qw/View V/);
 722 }
 723
 724 =head2 $c->comp($name)
 725
 726 =head2 $c->component($name)
 727
 728 Gets a component object by name. This method is not recommended,
 729 unless you want to get a specific component by full
 730 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 731 should be used instead.
 732
 733 If C<$name> is a regexp, a list of components matched against the full
 734 component name will be returned.
 735
 736 =cut
 737
 738 sub component {
 739     my ( $c, $name, @args ) = @_;
 740
 741     if( $name ) {
 742         my $comps = $c->components;
 743
 744         if( !ref $name ) {
 745             # is it the exact name?
 746             return $c->_filter_component( $comps->{ $name }, @args )
 747                        if exists $comps->{ $name };
 748
 749             # perhaps we just omitted "MyApp"?
 750             my $composed = ( ref $c || $c ) . "::${name}";
 751             return $c->_filter_component( $comps->{ $composed }, @args )
 752                        if exists $comps->{ $composed };
 753
 754             # search all of the models, views and controllers
 755             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 756             return $c->_filter_component( $comp, @args ) if $comp;
 757         }
 758
 759         # This is here so $c->comp( '::M::' ) works
 760         my $query = ref $name ? $name : qr{$name}i;
 761
 762         my @result = grep { m{$query} } keys %{ $c->components };
 763         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 764
 765         if( $result[ 0 ] ) {
 766             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 767             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 768             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 769             return $c->_filter_component( $result[ 0 ], @args );
 770         }
 771
 772         # I would expect to return an empty list here, but that breaks back-compat
 773     }
 774
 775     # fallback
 776     return sort keys %{ $c->components };
 777 }
 778
 779 =head2 CLASS DATA AND HELPER CLASSES
 780
 781 =head2 $c->config
 782
 783 Returns or takes a hashref containing the application's configuration.
 784
 785     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 786
 787 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 788 like myapp.yml in your applications home directory. See
 789 L<Catalyst::Plugin::ConfigLoader>.
 790
 791     ---
 792     db: dsn:SQLite:foo.db
 793
 794
 795 =cut
 796
 797 around config => sub {
 798     my $orig = shift;
 799     my $c = shift;
 800
 801     $c->log->warn("Setting config after setup has been run is not a good idea.")
 802       if ( @_ and $c->setup_finished );
 803
 804     $c->$orig(@_);
 805 };
 806
 807 =head2 $c->log
 808
 809 Returns the logging object instance. Unless it is already set, Catalyst
 810 sets this up with a L<Catalyst::Log> object. To use your own log class,
 811 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 812 C<< __PACKAGE__->setup >>.
 813
 814  __PACKAGE__->log( MyLogger->new );
 815  __PACKAGE__->setup;
 816
 817 And later:
 818
 819     $c->log->info( 'Now logging with my own logger!' );
 820
 821 Your log class should implement the methods described in
 822 L<Catalyst::Log>.
 823
 824
 825 =head2 $c->debug
 826
 827 Overload to enable debug messages (same as -Debug option).
 828
 829 Note that this is a static method, not an accessor and should be overloaded
 830 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 831
 832 =cut
 833
 834 sub debug { 0 }
 835
 836 =head2 $c->dispatcher
 837
 838 Returns the dispatcher instance. Stringifies to class name. See
 839 L<Catalyst::Dispatcher>.
 840
 841 =head2 $c->engine
 842
 843 Returns the engine instance. Stringifies to the class name. See
 844 L<Catalyst::Engine>.
 845
 846
 847 =head2 UTILITY METHODS
 848
 849 =head2 $c->path_to(@path)
 850
 851 Merges C<@path> with C<< $c->config->{home} >> and returns a
 852 L<Path::Class::Dir> object.
 853
 854 For example:
 855
 856     $c->path_to( 'db', 'sqlite.db' );
 857
 858 =cut
 859
 860 sub path_to {
 861     my ( $c, @path ) = @_;
 862     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 863     if ( -d $path ) { return $path }
 864     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 865 }
 866
 867 =head2 $c->plugin( $name, $class, @args )
 868
 869 Helper method for plugins. It creates a classdata accessor/mutator and
 870 loads and instantiates the given class.
 871
 872     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 873
 874     $c->prototype->define_javascript_functions;
 875
 876 B<Note:> This method of adding plugins is deprecated. The ability
 877 to add plugins like this B<will be removed> in a Catalyst 5.9.
 878 Please do not use this functionality in new code.
 879
 880 =cut
 881
 882 sub plugin {
 883     my ( $class, $name, $plugin, @args ) = @_;
 884
 885     # See block comment in t/unit_core_plugin.t
 886     $class->log->debug(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.9/);
 887
 888     $class->_register_plugin( $plugin, 1 );
 889
 890     eval { $plugin->import };
 891     $class->mk_classdata($name);
 892     my $obj;
 893     eval { $obj = $plugin->new(@args) };
 894
 895     if ($@) {
 896         Catalyst::Exception->throw( message =>
 897               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 898     }
 899
 900     $class->$name($obj);
 901     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 902       if $class->debug;
 903 }
 904
 905 =head2 MyApp->setup
 906
 907 Initializes the dispatcher and engine, loads any plugins, and loads the
 908 model, view, and controller components. You may also specify an array
 909 of plugins to load here, if you choose to not load them in the C<use
 910 Catalyst> line.
 911
 912     MyApp->setup;
 913     MyApp->setup( qw/-Debug/ );
 914
 915 =cut
 916
 917 sub setup {
 918     my ( $class, @arguments ) = @_;
 919     $class->log->warn("Running setup twice is not a good idea.")
 920       if ( $class->setup_finished );
 921
 922     unless ( $class->isa('Catalyst') ) {
 923
 924         Catalyst::Exception->throw(
 925             message => qq/'$class' does not inherit from Catalyst/ );
 926     }
 927
 928     if ( $class->arguments ) {
 929         @arguments = ( @arguments, @{ $class->arguments } );
 930     }
 931
 932     # Process options
 933     my $flags = {};
 934
 935     foreach (@arguments) {
 936
 937         if (/^-Debug$/) {
 938             $flags->{log} =
 939               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 940         }
 941         elsif (/^-(\w+)=?(.*)$/) {
 942             $flags->{ lc $1 } = $2;
 943         }
 944         else {
 945             push @{ $flags->{plugins} }, $_;
 946         }
 947     }
 948
 949     $class->setup_home( delete $flags->{home} );
 950
 951     $class->setup_log( delete $flags->{log} );
 952     $class->setup_plugins( delete $flags->{plugins} );
 953     $class->setup_dispatcher( delete $flags->{dispatcher} );
 954     $class->setup_engine( delete $flags->{engine} );
 955     $class->setup_stats( delete $flags->{stats} );
 956
 957     for my $flag ( sort keys %{$flags} ) {
 958
 959         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 960             &$code( $class, delete $flags->{$flag} );
 961         }
 962         else {
 963             $class->log->warn(qq/Unknown flag "$flag"/);
 964         }
 965     }
 966
 967     eval { require Catalyst::Devel; };
 968     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 969         $class->log->warn(<<"EOF");
 970 You are running an old script!
 971
 972   Please update by running (this will overwrite existing files):
 973     catalyst.pl -force -scripts $class
 974
 975   or (this will not overwrite existing files):
 976     catalyst.pl -scripts $class
 977
 978 EOF
 979     }
 980
 981     if ( $class->debug ) {
 982         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 983
 984         if (@plugins) {
 985             my $t = Text::SimpleTable->new(74);
 986             $t->row($_) for @plugins;
 987             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 988         }
 989
 990         my $dispatcher = $class->dispatcher;
 991         my $engine     = $class->engine;
 992         my $home       = $class->config->{home};
 993
 994         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
 995         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
 996
 997         $home
 998           ? ( -d $home )
 999           ? $class->log->debug(qq/Found home "$home"/)
1000           : $class->log->debug(qq/Home "$home" doesn't exist/)
1001           : $class->log->debug(q/Couldn't find home/);
1002     }
1003
1004     # Call plugins setup, this is stupid and evil.
1005     {
1006         no warnings qw/redefine/;
1007         local *setup = sub { };
1008         $class->setup;
1009     }
1010
1011     # Initialize our data structure
1012     $class->components( {} );
1013
1014     $class->setup_components;
1015
1016     if ( $class->debug ) {
1017         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
1018         for my $comp ( sort keys %{ $class->components } ) {
1019             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1020             $t->row( $comp, $type );
1021         }
1022         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1023           if ( keys %{ $class->components } );
1024     }
1025
1026     # Add our self to components, since we are also a component
1027     if( $class->isa('Catalyst::Controller') ){
1028       $class->components->{$class} = $class;
1029     }
1030
1031     $class->setup_actions;
1032
1033     if ( $class->debug ) {
1034         my $name = $class->config->{name} || 'Application';
1035         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1036     }
1037     $class->log->_flush() if $class->log->can('_flush');
1038
1039     # Make sure that the application class becomes immutable at this point,
1040     # which ensures that it gets an inlined constructor. This means that it
1041     # works even if the user has added a plugin which contains a new method.
1042     # Note however that we have to do the work on scope end, so that method
1043     # modifiers work correctly in MyApp (as you have to call setup _before_
1044     # applying modifiers).
1045     Scope::Upper::reap(sub {
1046         my $meta = Class::MOP::get_metaclass_by_name($class);
1047         $meta->make_immutable unless $meta->is_immutable;
1048     }, Scope::Upper::SCOPE(1));
1049
1050     $class->setup_finalize;
1051 }
1052
1053 sub setup_finalize {
1054     my ($class) = @_;
1055     $class->setup_finished(1);
1056 }
1057
1058 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1059
1060 =head2 $c->uri_for( $path, @args?, \%query_values? )
1061
1062 =over
1063
1064 =item $action
1065
1066 A Catalyst::Action object representing the Catalyst action you want to
1067 create a URI for. To get one for an action in the current controller,
1068 use C<< $c->action('someactionname') >>. To get one from different
1069 controller, fetch the controller using C<< $c->controller() >>, then
1070 call C<action_for> on it.
1071
1072 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1073 using C<< $c->req->captures >>.
1074
1075   # For the current action
1076   $c->uri_for($c->action, $c->req->captures);
1077
1078   # For the Foo action in the Bar controller
1079   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1080
1081 =back
1082
1083 =cut
1084
1085 sub uri_for {
1086     my ( $c, $path, @args ) = @_;
1087
1088     if ( Scalar::Util::blessed($path) ) { # action object
1089         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1090                          ? shift(@args)
1091                          : [] );
1092         $path = $c->dispatcher->uri_for_action($path, $captures);
1093         return undef unless defined($path);
1094         $path = '/' if $path eq '';
1095     }
1096
1097     undef($path) if (defined $path && $path eq '');
1098
1099     my $params =
1100       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1101
1102     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1103     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1104
1105     unshift(@args, $path);
1106
1107     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1108         my $namespace = $c->namespace;
1109         if (defined $path) { # cheesy hack to handle path '../foo'
1110            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1111         }
1112         unshift(@args, $namespace || '');
1113     }
1114
1115     # join args with '/', or a blank string
1116     my $args = join('/', grep { defined($_) } @args);
1117     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1118     $args =~ s!^/+!!;
1119     my $base = $c->req->base;
1120     my $class = ref($base);
1121     $base =~ s{(?<!/)$}{/};
1122
1123     my $query = '';
1124
1125     if (my @keys = keys %$params) {
1126       # somewhat lifted from URI::_query's query_form
1127       $query = '?'.join('&', map {
1128           my $val = $params->{$_};
1129           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1130           s/ /+/g;
1131           my $key = $_;
1132           $val = '' unless defined $val;
1133           (map {
1134               $_ = "$_";
1135               utf8::encode( $_ ) if utf8::is_utf8($_);
1136               # using the URI::Escape pattern here so utf8 chars survive
1137               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1138               s/ /+/g;
1139               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1140       } @keys);
1141     }
1142
1143     my $res = bless(\"${base}${args}${query}", $class);
1144     $res;
1145 }
1146
1147 =head2 $c->welcome_message
1148
1149 Returns the Catalyst welcome HTML page.
1150
1151 =cut
1152
1153 sub welcome_message {
1154     my $c      = shift;
1155     my $name   = $c->config->{name};
1156     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1157     my $prefix = Catalyst::Utils::appprefix( ref $c );
1158     $c->response->content_type('text/html; charset=utf-8');
1159     return <<"EOF";
1160 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1161     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1162 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1163     <head>
1164     <meta http-equiv="Content-Language" content="en" />
1165     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1166         <title>$name on Catalyst $VERSION</title>
1167         <style type="text/css">
1168             body {
1169                 color: #000;
1170                 background-color: #eee;
1171             }
1172             div#content {
1173                 width: 640px;
1174                 margin-left: auto;
1175                 margin-right: auto;
1176                 margin-top: 10px;
1177                 margin-bottom: 10px;
1178                 text-align: left;
1179                 background-color: #ccc;
1180                 border: 1px solid #aaa;
1181             }
1182             p, h1, h2 {
1183                 margin-left: 20px;
1184                 margin-right: 20px;
1185                 font-family: verdana, tahoma, sans-serif;
1186             }
1187             a {
1188                 font-family: verdana, tahoma, sans-serif;
1189             }
1190             :link, :visited {
1191                     text-decoration: none;
1192                     color: #b00;
1193                     border-bottom: 1px dotted #bbb;
1194             }
1195             :link:hover, :visited:hover {
1196                     color: #555;
1197             }
1198             div#topbar {
1199                 margin: 0px;
1200             }
1201             pre {
1202                 margin: 10px;
1203                 padding: 8px;
1204             }
1205             div#answers {
1206                 padding: 8px;
1207                 margin: 10px;
1208                 background-color: #fff;
1209                 border: 1px solid #aaa;
1210             }
1211             h1 {
1212                 font-size: 0.9em;
1213                 font-weight: normal;
1214                 text-align: center;
1215             }
1216             h2 {
1217                 font-size: 1.0em;
1218             }
1219             p {
1220                 font-size: 0.9em;
1221             }
1222             p img {
1223                 float: right;
1224                 margin-left: 10px;
1225             }
1226             span#appname {
1227                 font-weight: bold;
1228                 font-size: 1.6em;
1229             }
1230         </style>
1231     </head>
1232     <body>
1233         <div id="content">
1234             <div id="topbar">
1235                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1236                     $VERSION</h1>
1237              </div>
1238              <div id="answers">
1239                  <p>
1240                  <img src="$logo" alt="Catalyst Logo" />
1241                  </p>
1242                  <p>Welcome to the  world of Catalyst.
1243                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1244                     framework will make web development something you had
1245                     never expected it to be: Fun, rewarding, and quick.</p>
1246                  <h2>What to do now?</h2>
1247                  <p>That really depends  on what <b>you</b> want to do.
1248                     We do, however, provide you with a few starting points.</p>
1249                  <p>If you want to jump right into web development with Catalyst
1250                     you might want to start with a tutorial.</p>
1251 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1252 </pre>
1253 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1254 <pre>
1255 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1256 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1257 </code></pre>
1258                  <h2>What to do next?</h2>
1259                  <p>Next it's time to write an actual application. Use the
1260                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1261                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1262                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1263                     they can save you a lot of work.</p>
1264                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1265                     <p>Also, be sure to check out the vast and growing
1266                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1267                     you are likely to find what you need there.
1268                     </p>
1269
1270                  <h2>Need help?</h2>
1271                  <p>Catalyst has a very active community. Here are the main places to
1272                     get in touch with us.</p>
1273                  <ul>
1274                      <li>
1275                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1276                      </li>
1277                      <li>
1278                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1279                      </li>
1280                      <li>
1281                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1282                      </li>
1283                  </ul>
1284                  <h2>In conclusion</h2>
1285                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1286                     as we enjoyed making it. Please contact us if you have ideas
1287                     for improvement or other feedback.</p>
1288              </div>
1289          </div>
1290     </body>
1291 </html>
1292 EOF
1293 }
1294
1295 =head1 INTERNAL METHODS
1296
1297 These methods are not meant to be used by end users.
1298
1299 =head2 $c->components
1300
1301 Returns a hash of components.
1302
1303 =head2 $c->context_class
1304
1305 Returns or sets the context class.
1306
1307 =head2 $c->counter
1308
1309 Returns a hashref containing coderefs and execution counts (needed for
1310 deep recursion detection).
1311
1312 =head2 $c->depth
1313
1314 Returns the number of actions on the current internal execution stack.
1315
1316 =head2 $c->dispatch
1317
1318 Dispatches a request to actions.
1319
1320 =cut
1321
1322 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1323
1324 =head2 $c->dispatcher_class
1325
1326 Returns or sets the dispatcher class.
1327
1328 =head2 $c->dump_these
1329
1330 Returns a list of 2-element array references (name, structure) pairs
1331 that will be dumped on the error page in debug mode.
1332
1333 =cut
1334
1335 sub dump_these {
1336     my $c = shift;
1337     [ Request => $c->req ],
1338     [ Response => $c->res ],
1339     [ Stash => $c->stash ],
1340     [ Config => $c->config ];
1341 }
1342
1343 =head2 $c->engine_class
1344
1345 Returns or sets the engine class.
1346
1347 =head2 $c->execute( $class, $coderef )
1348
1349 Execute a coderef in given class and catch exceptions. Errors are available
1350 via $c->error.
1351
1352 =cut
1353
1354 sub execute {
1355     my ( $c, $class, $code ) = @_;
1356     $class = $c->component($class) || $class;
1357     $c->state(0);
1358
1359     if ( $c->depth >= $RECURSION ) {
1360         my $action = $code->reverse();
1361         $action = "/$action" unless $action =~ /->/;
1362         my $error = qq/Deep recursion detected calling "${action}"/;
1363         $c->log->error($error);
1364         $c->error($error);
1365         $c->state(0);
1366         return $c->state;
1367     }
1368
1369     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1370
1371     push( @{ $c->stack }, $code );
1372
1373     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1374
1375     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1376
1377     my $last = pop( @{ $c->stack } );
1378
1379     if ( my $error = $@ ) {
1380         if ( !ref($error) and $error eq $DETACH ) {
1381             die $DETACH if($c->depth > 1);
1382         }
1383         elsif ( !ref($error) and $error eq $GO ) {
1384             die $GO if($c->depth > 0);
1385         }
1386         else {
1387             unless ( ref $error ) {
1388                 no warnings 'uninitialized';
1389                 chomp $error;
1390                 my $class = $last->class;
1391                 my $name  = $last->name;
1392                 $error = qq/Caught exception in $class->$name "$error"/;
1393             }
1394             $c->error($error);
1395             $c->state(0);
1396         }
1397     }
1398     return $c->state;
1399 }
1400
1401 sub _stats_start_execute {
1402     my ( $c, $code ) = @_;
1403
1404     return if ( ( $code->name =~ /^_.*/ )
1405         && ( !$c->config->{show_internal_actions} ) );
1406
1407     my $action_name = $code->reverse();
1408     $c->counter->{$action_name}++;
1409
1410     my $action = $action_name;
1411     $action = "/$action" unless $action =~ /->/;
1412
1413     # determine if the call was the result of a forward
1414     # this is done by walking up the call stack and looking for a calling
1415     # sub of Catalyst::forward before the eval
1416     my $callsub = q{};
1417     for my $index ( 2 .. 11 ) {
1418         last
1419         if ( ( caller($index) )[0] eq 'Catalyst'
1420             && ( caller($index) )[3] eq '(eval)' );
1421
1422         if ( ( caller($index) )[3] =~ /forward$/ ) {
1423             $callsub = ( caller($index) )[3];
1424             $action  = "-> $action";
1425             last;
1426         }
1427     }
1428
1429     my $uid = $action_name . $c->counter->{$action_name};
1430
1431     # is this a root-level call or a forwarded call?
1432     if ( $callsub =~ /forward$/ ) {
1433
1434         # forward, locate the caller
1435         if ( my $parent = $c->stack->[-1] ) {
1436             $c->stats->profile(
1437                 begin  => $action,
1438                 parent => "$parent" . $c->counter->{"$parent"},
1439                 uid    => $uid,
1440             );
1441         }
1442         else {
1443
1444             # forward with no caller may come from a plugin
1445             $c->stats->profile(
1446                 begin => $action,
1447                 uid   => $uid,
1448             );
1449         }
1450     }
1451     else {
1452
1453         # root-level call
1454         $c->stats->profile(
1455             begin => $action,
1456             uid   => $uid,
1457         );
1458     }
1459     return $action;
1460
1461 }
1462
1463 sub _stats_finish_execute {
1464     my ( $c, $info ) = @_;
1465     $c->stats->profile( end => $info );
1466 }
1467
1468 =head2 $c->_localize_fields( sub { }, \%keys );
1469
1470 =cut
1471
1472 #Why does this exist? This is no longer safe and WILL NOT WORK.
1473 # it doesnt seem to be used anywhere. can we remove it?
1474 sub _localize_fields {
1475     my ( $c, $localized, $code ) = ( @_ );
1476
1477     my $request = delete $localized->{request} || {};
1478     my $response = delete $localized->{response} || {};
1479
1480     local @{ $c }{ keys %$localized } = values %$localized;
1481     local @{ $c->request }{ keys %$request } = values %$request;
1482     local @{ $c->response }{ keys %$response } = values %$response;
1483
1484     $code->();
1485 }
1486
1487 =head2 $c->finalize
1488
1489 Finalizes the request.
1490
1491 =cut
1492
1493 sub finalize {
1494     my $c = shift;
1495
1496     for my $error ( @{ $c->error } ) {
1497         $c->log->error($error);
1498     }
1499
1500     # Allow engine to handle finalize flow (for POE)
1501     my $engine = $c->engine;
1502     if ( my $code = $engine->can('finalize') ) {
1503         $engine->$code($c);
1504     }
1505     else {
1506
1507         $c->finalize_uploads;
1508
1509         # Error
1510         if ( $#{ $c->error } >= 0 ) {
1511             $c->finalize_error;
1512         }
1513
1514         $c->finalize_headers;
1515
1516         # HEAD request
1517         if ( $c->request->method eq 'HEAD' ) {
1518             $c->response->body('');
1519         }
1520
1521         $c->finalize_body;
1522     }
1523
1524     if ($c->use_stats) {
1525         my $elapsed = sprintf '%f', $c->stats->elapsed;
1526         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1527         $c->log->info(
1528             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1529     }
1530
1531     return $c->response->status;
1532 }
1533
1534 =head2 $c->finalize_body
1535
1536 Finalizes body.
1537
1538 =cut
1539
1540 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1541
1542 =head2 $c->finalize_cookies
1543
1544 Finalizes cookies.
1545
1546 =cut
1547
1548 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1549
1550 =head2 $c->finalize_error
1551
1552 Finalizes error.
1553
1554 =cut
1555
1556 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1557
1558 =head2 $c->finalize_headers
1559
1560 Finalizes headers.
1561
1562 =cut
1563
1564 sub finalize_headers {
1565     my $c = shift;
1566
1567     my $response = $c->response; #accessor calls can add up?
1568
1569     # Check if we already finalized headers
1570     return if $response->finalized_headers;
1571
1572     # Handle redirects
1573     if ( my $location = $response->redirect ) {
1574         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1575         $response->header( Location => $location );
1576
1577         if ( !$response->has_body ) {
1578             # Add a default body if none is already present
1579             $response->body(
1580                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1581             );
1582         }
1583     }
1584
1585     # Content-Length
1586     if ( $response->body && !$response->content_length ) {
1587
1588         # get the length from a filehandle
1589         if ( blessed( $response->body ) && $response->body->can('read') )
1590         {
1591             my $stat = stat $response->body;
1592             if ( $stat && $stat->size > 0 ) {
1593                 $response->content_length( $stat->size );
1594             }
1595             else {
1596                 $c->log->warn('Serving filehandle without a content-length');
1597             }
1598         }
1599         else {
1600             # everything should be bytes at this point, but just in case
1601             $response->content_length( bytes::length( $response->body ) );
1602         }
1603     }
1604
1605     # Errors
1606     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1607         $response->headers->remove_header("Content-Length");
1608         $response->body('');
1609     }
1610
1611     $c->finalize_cookies;
1612
1613     $c->engine->finalize_headers( $c, @_ );
1614
1615     # Done
1616     $response->finalized_headers(1);
1617 }
1618
1619 =head2 $c->finalize_output
1620
1621 An alias for finalize_body.
1622
1623 =head2 $c->finalize_read
1624
1625 Finalizes the input after reading is complete.
1626
1627 =cut
1628
1629 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1630
1631 =head2 $c->finalize_uploads
1632
1633 Finalizes uploads. Cleans up any temporary files.
1634
1635 =cut
1636
1637 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1638
1639 =head2 $c->get_action( $action, $namespace )
1640
1641 Gets an action in a given namespace.
1642
1643 =cut
1644
1645 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1646
1647 =head2 $c->get_actions( $action, $namespace )
1648
1649 Gets all actions of a given name in a namespace and all parent
1650 namespaces.
1651
1652 =cut
1653
1654 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1655
1656 =head2 $c->handle_request( $class, @arguments )
1657
1658 Called to handle each HTTP request.
1659
1660 =cut
1661
1662 sub handle_request {
1663     my ( $class, @arguments ) = @_;
1664
1665     # Always expect worst case!
1666     my $status = -1;
1667     eval {
1668         if ($class->debug) {
1669             my $secs = time - $START || 1;
1670             my $av = sprintf '%.3f', $COUNT / $secs;
1671             my $time = localtime time;
1672             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1673         }
1674
1675         my $c = $class->prepare(@arguments);
1676         $c->dispatch;
1677         $status = $c->finalize;
1678     };
1679
1680     if ( my $error = $@ ) {
1681         chomp $error;
1682         $class->log->error(qq/Caught exception in engine "$error"/);
1683     }
1684
1685     $COUNT++;
1686
1687     if(my $coderef = $class->log->can('_flush')){
1688         $class->log->$coderef();
1689     }
1690     return $status;
1691 }
1692
1693 =head2 $c->prepare( @arguments )
1694
1695 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1696 etc.).
1697
1698 =cut
1699
1700 sub prepare {
1701     my ( $class, @arguments ) = @_;
1702
1703     # XXX
1704     # After the app/ctxt split, this should become an attribute based on something passed
1705     # into the application.
1706     $class->context_class( ref $class || $class ) unless $class->context_class;
1707
1708     my $c = $class->context_class->new({});
1709
1710     # For on-demand data
1711     $c->request->_context($c);
1712     $c->response->_context($c);
1713
1714     #surely this is not the most efficient way to do things...
1715     $c->stats($class->stats_class->new)->enable($c->use_stats);
1716     if ( $c->debug ) {
1717         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1718     }
1719
1720     #XXX reuse coderef from can
1721     # Allow engine to direct the prepare flow (for POE)
1722     if ( $c->engine->can('prepare') ) {
1723         $c->engine->prepare( $c, @arguments );
1724     }
1725     else {
1726         $c->prepare_request(@arguments);
1727         $c->prepare_connection;
1728         $c->prepare_query_parameters;
1729         $c->prepare_headers;
1730         $c->prepare_cookies;
1731         $c->prepare_path;
1732
1733         # Prepare the body for reading, either by prepare_body
1734         # or the user, if they are using $c->read
1735         $c->prepare_read;
1736
1737         # Parse the body unless the user wants it on-demand
1738         unless ( $c->config->{parse_on_demand} ) {
1739             $c->prepare_body;
1740         }
1741     }
1742
1743     my $method  = $c->req->method  || '';
1744     my $path    = $c->req->path;
1745     $path       = '/' unless length $path;
1746     my $address = $c->req->address || '';
1747
1748     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1749       if $c->debug;
1750
1751     $c->prepare_action;
1752
1753     return $c;
1754 }
1755
1756 =head2 $c->prepare_action
1757
1758 Prepares action. See L<Catalyst::Dispatcher>.
1759
1760 =cut
1761
1762 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1763
1764 =head2 $c->prepare_body
1765
1766 Prepares message body.
1767
1768 =cut
1769
1770 sub prepare_body {
1771     my $c = shift;
1772
1773     return if $c->request->_has_body;
1774
1775     # Initialize on-demand data
1776     $c->engine->prepare_body( $c, @_ );
1777     $c->prepare_parameters;
1778     $c->prepare_uploads;
1779
1780     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1781         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1782         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1783             my $param = $c->req->body_parameters->{$key};
1784             my $value = defined($param) ? $param : '';
1785             $t->row( $key,
1786                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1787         }
1788         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1789     }
1790 }
1791
1792 =head2 $c->prepare_body_chunk( $chunk )
1793
1794 Prepares a chunk of data before sending it to L<HTTP::Body>.
1795
1796 See L<Catalyst::Engine>.
1797
1798 =cut
1799
1800 sub prepare_body_chunk {
1801     my $c = shift;
1802     $c->engine->prepare_body_chunk( $c, @_ );
1803 }
1804
1805 =head2 $c->prepare_body_parameters
1806
1807 Prepares body parameters.
1808
1809 =cut
1810
1811 sub prepare_body_parameters {
1812     my $c = shift;
1813     $c->engine->prepare_body_parameters( $c, @_ );
1814 }
1815
1816 =head2 $c->prepare_connection
1817
1818 Prepares connection.
1819
1820 =cut
1821
1822 sub prepare_connection {
1823     my $c = shift;
1824     $c->engine->prepare_connection( $c, @_ );
1825 }
1826
1827 =head2 $c->prepare_cookies
1828
1829 Prepares cookies.
1830
1831 =cut
1832
1833 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1834
1835 =head2 $c->prepare_headers
1836
1837 Prepares headers.
1838
1839 =cut
1840
1841 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1842
1843 =head2 $c->prepare_parameters
1844
1845 Prepares parameters.
1846
1847 =cut
1848
1849 sub prepare_parameters {
1850     my $c = shift;
1851     $c->prepare_body_parameters;
1852     $c->engine->prepare_parameters( $c, @_ );
1853 }
1854
1855 =head2 $c->prepare_path
1856
1857 Prepares path and base.
1858
1859 =cut
1860
1861 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1862
1863 =head2 $c->prepare_query_parameters
1864
1865 Prepares query parameters.
1866
1867 =cut
1868
1869 sub prepare_query_parameters {
1870     my $c = shift;
1871
1872     $c->engine->prepare_query_parameters( $c, @_ );
1873
1874     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1875         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1876         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1877             my $param = $c->req->query_parameters->{$key};
1878             my $value = defined($param) ? $param : '';
1879             $t->row( $key,
1880                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1881         }
1882         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1883     }
1884 }
1885
1886 =head2 $c->prepare_read
1887
1888 Prepares the input for reading.
1889
1890 =cut
1891
1892 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1893
1894 =head2 $c->prepare_request
1895
1896 Prepares the engine request.
1897
1898 =cut
1899
1900 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1901
1902 =head2 $c->prepare_uploads
1903
1904 Prepares uploads.
1905
1906 =cut
1907
1908 sub prepare_uploads {
1909     my $c = shift;
1910
1911     $c->engine->prepare_uploads( $c, @_ );
1912
1913     if ( $c->debug && keys %{ $c->request->uploads } ) {
1914         my $t = Text::SimpleTable->new(
1915             [ 12, 'Parameter' ],
1916             [ 26, 'Filename' ],
1917             [ 18, 'Type' ],
1918             [ 9,  'Size' ]
1919         );
1920         for my $key ( sort keys %{ $c->request->uploads } ) {
1921             my $upload = $c->request->uploads->{$key};
1922             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1923                 $t->row( $key, $u->filename, $u->type, $u->size );
1924             }
1925         }
1926         $c->log->debug( "File Uploads are:\n" . $t->draw );
1927     }
1928 }
1929
1930 =head2 $c->prepare_write
1931
1932 Prepares the output for writing.
1933
1934 =cut
1935
1936 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1937
1938 =head2 $c->request_class
1939
1940 Returns or sets the request class.
1941
1942 =head2 $c->response_class
1943
1944 Returns or sets the response class.
1945
1946 =head2 $c->read( [$maxlength] )
1947
1948 Reads a chunk of data from the request body. This method is designed to
1949 be used in a while loop, reading C<$maxlength> bytes on every call.
1950 C<$maxlength> defaults to the size of the request if not specified.
1951
1952 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1953 directly.
1954
1955 Warning: If you use read(), Catalyst will not process the body,
1956 so you will not be able to access POST parameters or file uploads via
1957 $c->request.  You must handle all body parsing yourself.
1958
1959 =cut
1960
1961 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1962
1963 =head2 $c->run
1964
1965 Starts the engine.
1966
1967 =cut
1968
1969 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1970
1971 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1972
1973 Sets an action in a given namespace.
1974
1975 =cut
1976
1977 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1978
1979 =head2 $c->setup_actions($component)
1980
1981 Sets up actions for a component.
1982
1983 =cut
1984
1985 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1986
1987 =head2 $c->setup_components
1988
1989 Sets up components. Specify a C<setup_components> config option to pass
1990 additional options directly to L<Module::Pluggable>. To add additional
1991 search paths, specify a key named C<search_extra> as an array
1992 reference. Items in the array beginning with C<::> will have the
1993 application class name prepended to them.
1994
1995 All components found will also have any
1996 L<Devel::InnerPackage|inner packages> loaded and set up as components.
1997 Note, that modules which are B<not> an I<inner package> of the main
1998 file namespace loaded will not be instantiated as components.
1999
2000 =cut
2001
2002 sub setup_components {
2003     my $class = shift;
2004
2005     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2006     my $config  = $class->config->{ setup_components };
2007     my $extra   = delete $config->{ search_extra } || [];
2008
2009     push @paths, @$extra;
2010
2011     my $locator = Module::Pluggable::Object->new(
2012         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2013         %$config
2014     );
2015
2016     my @comps = sort { length $a <=> length $b } $locator->plugins;
2017     my %comps = map { $_ => 1 } @comps;
2018
2019     for my $component ( @comps ) {
2020
2021         # We pass ignore_loaded here so that overlay files for (e.g.)
2022         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2023         # we know M::P::O found a file on disk so this is safe
2024
2025         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2026         #Class::MOP::load_class($component);
2027
2028         my $module  = $class->setup_component( $component );
2029         my %modules = (
2030             $component => $module,
2031             map {
2032                 $_ => $class->setup_component( $_ )
2033             } grep {
2034               not exists $comps{$_}
2035             } Devel::InnerPackage::list_packages( $component )
2036         );
2037
2038         for my $key ( keys %modules ) {
2039             $class->components->{ $key } = $modules{ $key };
2040         }
2041     }
2042 }
2043
2044 =head2 $c->setup_component
2045
2046 =cut
2047
2048 sub setup_component {
2049     my( $class, $component ) = @_;
2050
2051     unless ( $component->can( 'COMPONENT' ) ) {
2052         return $component;
2053     }
2054
2055     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2056     my $config = $class->config->{ $suffix } || {};
2057
2058     my $instance = eval { $component->COMPONENT( $class, $config ); };
2059
2060     if ( my $error = $@ ) {
2061         chomp $error;
2062         Catalyst::Exception->throw(
2063             message => qq/Couldn't instantiate component "$component", "$error"/
2064         );
2065     }
2066
2067     Catalyst::Exception->throw(
2068         message =>
2069         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2070     ) unless blessed($instance);
2071
2072     return $instance;
2073 }
2074
2075 =head2 $c->setup_dispatcher
2076
2077 Sets up dispatcher.
2078
2079 =cut
2080
2081 sub setup_dispatcher {
2082     my ( $class, $dispatcher ) = @_;
2083
2084     if ($dispatcher) {
2085         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2086     }
2087
2088     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2089         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2090     }
2091
2092     unless ($dispatcher) {
2093         $dispatcher = $class->dispatcher_class;
2094     }
2095
2096     Class::MOP::load_class($dispatcher);
2097
2098     # dispatcher instance
2099     $class->dispatcher( $dispatcher->new );
2100 }
2101
2102 =head2 $c->setup_engine
2103
2104 Sets up engine.
2105
2106 =cut
2107
2108 sub setup_engine {
2109     my ( $class, $engine ) = @_;
2110
2111     if ($engine) {
2112         $engine = 'Catalyst::Engine::' . $engine;
2113     }
2114
2115     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2116         $engine = 'Catalyst::Engine::' . $env;
2117     }
2118
2119     if ( $ENV{MOD_PERL} ) {
2120         my $meta = Class::MOP::get_metaclass_by_name($class);
2121
2122         # create the apache method
2123         $meta->add_method('apache' => sub { shift->engine->apache });
2124
2125         my ( $software, $version ) =
2126           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2127
2128         $version =~ s/_//g;
2129         $version =~ s/(\.[^.]+)\./$1/g;
2130
2131         if ( $software eq 'mod_perl' ) {
2132
2133             if ( !$engine ) {
2134
2135                 if ( $version >= 1.99922 ) {
2136                     $engine = 'Catalyst::Engine::Apache2::MP20';
2137                 }
2138
2139                 elsif ( $version >= 1.9901 ) {
2140                     $engine = 'Catalyst::Engine::Apache2::MP19';
2141                 }
2142
2143                 elsif ( $version >= 1.24 ) {
2144                     $engine = 'Catalyst::Engine::Apache::MP13';
2145                 }
2146
2147                 else {
2148                     Catalyst::Exception->throw( message =>
2149                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2150                 }
2151
2152             }
2153
2154             # install the correct mod_perl handler
2155             if ( $version >= 1.9901 ) {
2156                 *handler = sub  : method {
2157                     shift->handle_request(@_);
2158                 };
2159             }
2160             else {
2161                 *handler = sub ($$) { shift->handle_request(@_) };
2162             }
2163
2164         }
2165
2166         elsif ( $software eq 'Zeus-Perl' ) {
2167             $engine = 'Catalyst::Engine::Zeus';
2168         }
2169
2170         else {
2171             Catalyst::Exception->throw(
2172                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2173         }
2174     }
2175
2176     unless ($engine) {
2177         $engine = $class->engine_class;
2178     }
2179
2180     Class::MOP::load_class($engine);
2181
2182     # check for old engines that are no longer compatible
2183     my $old_engine;
2184     if ( $engine->isa('Catalyst::Engine::Apache')
2185         && !Catalyst::Engine::Apache->VERSION )
2186     {
2187         $old_engine = 1;
2188     }
2189
2190     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2191         && Catalyst::Engine::Server->VERSION le '0.02' )
2192     {
2193         $old_engine = 1;
2194     }
2195
2196     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2197         && $engine->VERSION eq '0.01' )
2198     {
2199         $old_engine = 1;
2200     }
2201
2202     elsif ($engine->isa('Catalyst::Engine::Zeus')
2203         && $engine->VERSION eq '0.01' )
2204     {
2205         $old_engine = 1;
2206     }
2207
2208     if ($old_engine) {
2209         Catalyst::Exception->throw( message =>
2210               qq/Engine "$engine" is not supported by this version of Catalyst/
2211         );
2212     }
2213
2214     # engine instance
2215     $class->engine( $engine->new );
2216 }
2217
2218 =head2 $c->setup_home
2219
2220 Sets up the home directory.
2221
2222 =cut
2223
2224 sub setup_home {
2225     my ( $class, $home ) = @_;
2226
2227     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2228         $home = $env;
2229     }
2230
2231     $home ||= Catalyst::Utils::home($class);
2232
2233     if ($home) {
2234         #I remember recently being scolded for assigning config values like this
2235         $class->config->{home} ||= $home;
2236         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2237     }
2238 }
2239
2240 =head2 $c->setup_log
2241
2242 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2243 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2244 log to.
2245
2246 This method also installs a C<debug> method that returns a true value into the
2247 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2248 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2249
2250 Note that if the log has already been setup, by either a previous call to
2251 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2252 that this method won't actually set up the log object.
2253
2254 =cut
2255
2256 sub setup_log {
2257     my ( $class, $levels ) = @_;
2258
2259     $levels ||= '';
2260     $levels =~ s/^\s+//;
2261     $levels =~ s/\s+$//;
2262     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels || '';
2263
2264     unless ( $class->log ) {
2265         $class->log( Catalyst::Log->new(keys %levels) );
2266     }
2267
2268     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2269     if ( defined($env_debug) or $levels{debug} ) {
2270         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2271         $class->log->debug('Debug messages enabled');
2272     }
2273 }
2274
2275 =head2 $c->setup_plugins
2276
2277 Sets up plugins.
2278
2279 =cut
2280
2281 =head2 $c->setup_stats
2282
2283 Sets up timing statistics class.
2284
2285 =cut
2286
2287 sub setup_stats {
2288     my ( $class, $stats ) = @_;
2289
2290     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2291
2292     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2293     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2294         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2295         $class->log->debug('Statistics enabled');
2296     }
2297 }
2298
2299
2300 =head2 $c->registered_plugins
2301
2302 Returns a sorted list of the plugins which have either been stated in the
2303 import list or which have been added via C<< MyApp->plugin(@args); >>.
2304
2305 If passed a given plugin name, it will report a boolean value indicating
2306 whether or not that plugin is loaded.  A fully qualified name is required if
2307 the plugin name does not begin with C<Catalyst::Plugin::>.
2308
2309  if ($c->registered_plugins('Some::Plugin')) {
2310      ...
2311  }
2312
2313 =cut
2314
2315 {
2316
2317     sub registered_plugins {
2318         my $proto = shift;
2319         return sort keys %{ $proto->_plugins } unless @_;
2320         my $plugin = shift;
2321         return 1 if exists $proto->_plugins->{$plugin};
2322         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2323     }
2324
2325     sub _register_plugin {
2326         my ( $proto, $plugin, $instant ) = @_;
2327         my $class = ref $proto || $proto;
2328
2329         # no ignore_loaded here, the plugin may already have been
2330         # defined in memory and we don't want to error on "no file" if so
2331
2332         Class::MOP::load_class( $plugin );
2333
2334         $proto->_plugins->{$plugin} = 1;
2335         unless ($instant) {
2336             no strict 'refs';
2337             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2338               my @superclasses = ($plugin, $meta->superclasses );
2339               $meta->superclasses(@superclasses);
2340             } else {
2341               unshift @{"$class\::ISA"}, $plugin;
2342             }
2343         }
2344         return $class;
2345     }
2346
2347     sub setup_plugins {
2348         my ( $class, $plugins ) = @_;
2349
2350         $class->_plugins( {} ) unless $class->_plugins;
2351         $plugins ||= [];
2352         for my $plugin ( reverse @$plugins ) {
2353
2354             unless ( $plugin =~ s/\A\+// ) {
2355                 $plugin = "Catalyst::Plugin::$plugin";
2356             }
2357
2358             $class->_register_plugin($plugin);
2359         }
2360     }
2361 }
2362
2363 =head2 $c->stack
2364
2365 Returns an arrayref of the internal execution stack (actions that are
2366 currently executing).
2367
2368 =head2 $c->stats_class
2369
2370 Returns or sets the stats (timing statistics) class.
2371
2372 =head2 $c->use_stats
2373
2374 Returns 1 when stats collection is enabled.  Stats collection is enabled
2375 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2376 environment variable is set.
2377
2378 Note that this is a static method, not an accessor and should be overloaded
2379 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2380
2381 =cut
2382
2383 sub use_stats { 0 }
2384
2385
2386 =head2 $c->write( $data )
2387
2388 Writes $data to the output stream. When using this method directly, you
2389 will need to manually set the C<Content-Length> header to the length of
2390 your output data, if known.
2391
2392 =cut
2393
2394 sub write {
2395     my $c = shift;
2396
2397     # Finalize headers if someone manually writes output
2398     $c->finalize_headers;
2399
2400     return $c->engine->write( $c, @_ );
2401 }
2402
2403 =head2 version
2404
2405 Returns the Catalyst version number. Mostly useful for "powered by"
2406 messages in template systems.
2407
2408 =cut
2409
2410 sub version { return $Catalyst::VERSION }
2411
2412 =head1 INTERNAL ACTIONS
2413
2414 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2415 C<_ACTION>, and C<_END>. These are by default not shown in the private
2416 action table, but you can make them visible with a config parameter.
2417
2418     MyApp->config->{show_internal_actions} = 1;
2419
2420 =head1 CASE SENSITIVITY
2421
2422 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2423 mapped to C</foo/bar>. You can activate case sensitivity with a config
2424 parameter.
2425
2426     MyApp->config->{case_sensitive} = 1;
2427
2428 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2429
2430 =head1 ON-DEMAND PARSER
2431
2432 The request body is usually parsed at the beginning of a request,
2433 but if you want to handle input yourself, you can enable on-demand
2434 parsing with a config parameter.
2435
2436     MyApp->config->{parse_on_demand} = 1;
2437
2438 =head1 PROXY SUPPORT
2439
2440 Many production servers operate using the common double-server approach,
2441 with a lightweight frontend web server passing requests to a larger
2442 backend server. An application running on the backend server must deal
2443 with two problems: the remote user always appears to be C<127.0.0.1> and
2444 the server's hostname will appear to be C<localhost> regardless of the
2445 virtual host that the user connected through.
2446
2447 Catalyst will automatically detect this situation when you are running
2448 the frontend and backend servers on the same machine. The following
2449 changes are made to the request.
2450
2451     $c->req->address is set to the user's real IP address, as read from
2452     the HTTP X-Forwarded-For header.
2453
2454     The host value for $c->req->base and $c->req->uri is set to the real
2455     host, as read from the HTTP X-Forwarded-Host header.
2456
2457 Obviously, your web server must support these headers for this to work.
2458
2459 In a more complex server farm environment where you may have your
2460 frontend proxy server(s) on different machines, you will need to set a
2461 configuration option to tell Catalyst to read the proxied data from the
2462 headers.
2463
2464     MyApp->config->{using_frontend_proxy} = 1;
2465
2466 If you do not wish to use the proxy support at all, you may set:
2467
2468     MyApp->config->{ignore_frontend_proxy} = 1;
2469
2470 =head1 THREAD SAFETY
2471
2472 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2473 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2474 believe the Catalyst core to be thread-safe.
2475
2476 If you plan to operate in a threaded environment, remember that all other
2477 modules you are using must also be thread-safe. Some modules, most notably
2478 L<DBD::SQLite>, are not thread-safe.
2479
2480 =head1 SUPPORT
2481
2482 IRC:
2483
2484     Join #catalyst on irc.perl.org.
2485
2486 Mailing Lists:
2487
2488     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2489     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2490
2491 Web:
2492
2493     http://catalyst.perl.org
2494
2495 Wiki:
2496
2497     http://dev.catalyst.perl.org
2498
2499 =head1 SEE ALSO
2500
2501 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2502
2503 =head2 L<Catalyst::Manual> - The Catalyst Manual
2504
2505 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2506
2507 =head2 L<Catalyst::Engine> - Core engine
2508
2509 =head2 L<Catalyst::Log> - Log class.
2510
2511 =head2 L<Catalyst::Request> - Request object
2512
2513 =head2 L<Catalyst::Response> - Response object
2514
2515 =head2 L<Catalyst::Test> - The test suite.
2516
2517 =head1 PROJECT FOUNDER
2518
2519 sri: Sebastian Riedel <sri@cpan.org>
2520
2521 =head1 CONTRIBUTORS
2522
2523 abw: Andy Wardley
2524
2525 acme: Leon Brocard <leon@astray.com>
2526
2527 Andrew Bramble
2528
2529 Andrew Ford
2530
2531 Andrew Ruthven
2532
2533 andyg: Andy Grundman <andy@hybridized.org>
2534
2535 audreyt: Audrey Tang
2536
2537 bricas: Brian Cassidy <bricas@cpan.org>
2538
2539 Caelum: Rafael Kitover <rkitover@io.com>
2540
2541 chansen: Christian Hansen
2542
2543 chicks: Christopher Hicks
2544
2545 David E. Wheeler
2546
2547 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2548
2549 Drew Taylor
2550
2551 esskar: Sascha Kiefer
2552
2553 fireartist: Carl Franks <cfranks@cpan.org>
2554
2555 gabb: Danijel Milicevic
2556
2557 Gary Ashton Jones
2558
2559 Geoff Richards
2560
2561 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2562
2563 jcamacho: Juan Camacho
2564
2565 jhannah: Jay Hannah <jay@jays.net>
2566
2567 Jody Belka
2568
2569 Johan Lindstrom
2570
2571 jon: Jon Schutz <jjschutz@cpan.org>
2572
2573 marcus: Marcus Ramberg <mramberg@cpan.org>
2574
2575 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2576
2577 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2578
2579 mugwump: Sam Vilain
2580
2581 naughton: David Naughton
2582
2583 ningu: David Kamholz <dkamholz@cpan.org>
2584
2585 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2586
2587 numa: Dan Sully <daniel@cpan.org>
2588
2589 obra: Jesse Vincent
2590
2591 omega: Andreas Marienborg
2592
2593 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2594
2595 rafl: Florian Ragwitz <rafl@debian.org>
2596
2597 sky: Arthur Bergman
2598
2599 the_jester: Jesse Sheidlower
2600
2601 t0m: Tomas Doran <bobtfish@bobtfish.net>
2602
2603 Ulf Edvinsson
2604
2605 willert: Sebastian Willert <willert@cpan.org>
2606
2607 =head1 LICENSE
2608
2609 This library is free software, you can redistribute it and/or modify it under
2610 the same terms as Perl itself.
2611
2612 =cut
2613
2614 no Moose;
2615
2616 __PACKAGE__->meta->make_immutable;
2617
2618 1;