lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39
  40 BEGIN { require 5.008004; }
  41
  42 has stack => (is => 'ro', default => sub { [] });
  43 has stash => (is => 'rw', default => sub { {} });
  44 has state => (is => 'rw', default => 0);
  45 has stats => (is => 'rw');
  46 has action => (is => 'rw');
  47 has counter => (is => 'rw', default => sub { {} });
  48 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  49 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  50 has namespace => (is => 'rw');
  51
  52 sub depth { scalar @{ shift->stack || [] }; }
  53 sub comp { shift->component(@_) }
  54
  55 sub req {
  56     my $self = shift; return $self->request(@_);
  57 }
  58 sub res {
  59     my $self = shift; return $self->response(@_);
  60 }
  61
  62 # For backwards compatibility
  63 sub finalize_output { shift->finalize_body(@_) };
  64
  65 # For statistics
  66 our $COUNT     = 1;
  67 our $START     = time;
  68 our $RECURSION = 1000;
  69 our $DETACH    = Catalyst::Exception::Detach->new;
  70 our $GO        = Catalyst::Exception::Go->new;
  71
  72 #I imagine that very few of these really need to be class variables. if any.
  73 #maybe we should just make them attributes with a default?
  74 __PACKAGE__->mk_classdata($_)
  75   for qw/components arguments dispatcher engine log dispatcher_class
  76   engine_loader context_class request_class response_class stats_class
  77   setup_finished _psgi_app/;
  78
  79 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  80 __PACKAGE__->request_class('Catalyst::Request');
  81 __PACKAGE__->response_class('Catalyst::Response');
  82 __PACKAGE__->stats_class('Catalyst::Stats');
  83
  84 # Remember to update this in Catalyst::Runtime as well!
  85
  86 our $VERSION = '5.89002';
  87
  88 sub import {
  89     my ( $class, @arguments ) = @_;
  90
  91     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  92     # callers @ISA.
  93     return unless $class eq 'Catalyst';
  94
  95     my $caller = caller();
  96     return if $caller eq 'main';
  97
  98     my $meta = Moose::Meta::Class->initialize($caller);
  99     unless ( $caller->isa('Catalyst') ) {
 100         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 101         $meta->superclasses(@superclasses);
 102     }
 103     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 104     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 105
 106     unless( $meta->has_method('meta') ){
 107         if ($Moose::VERSION >= 1.15) {
 108             $meta->_add_meta_method('meta');
 109         }
 110         else {
 111             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 112         }
 113     }
 114
 115     $caller->arguments( [@arguments] );
 116     $caller->setup_home;
 117 }
 118
 119 sub _application { $_[0] }
 120
 121 =head1 NAME
 122
 123 Catalyst - The Elegant MVC Web Application Framework
 124
 125 =head1 SYNOPSIS
 126
 127 See the L<Catalyst::Manual> distribution for comprehensive
 128 documentation and tutorials.
 129
 130     # Install Catalyst::Devel for helpers and other development tools
 131     # use the helper to create a new application
 132     catalyst.pl MyApp
 133
 134     # add models, views, controllers
 135     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 136     script/myapp_create.pl view MyTemplate TT
 137     script/myapp_create.pl controller Search
 138
 139     # built in testserver -- use -r to restart automatically on changes
 140     # --help to see all available options
 141     script/myapp_server.pl
 142
 143     # command line testing interface
 144     script/myapp_test.pl /yada
 145
 146     ### in lib/MyApp.pm
 147     use Catalyst qw/-Debug/; # include plugins here as well
 148
 149     ### In lib/MyApp/Controller/Root.pm (autocreated)
 150     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 151         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 152         $c->stash->{template} = 'foo.tt'; # set the template
 153         # lookup something from db -- stash vars are passed to TT
 154         $c->stash->{data} =
 155           $c->model('Database::Foo')->search( { country => $args[0] } );
 156         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 157             $c->forward( 'bar' ); # process another action
 158             # do something else after forward returns
 159         }
 160     }
 161
 162     # The foo.tt TT template can use the stash data from the database
 163     [% WHILE (item = data.next) %]
 164         [% item.foo %]
 165     [% END %]
 166
 167     # called for /bar/of/soap, /bar/of/soap/10, etc.
 168     sub bar : Path('/bar/of/soap') { ... }
 169
 170     # called for all actions, from the top-most controller downwards
 171     sub auto : Private {
 172         my ( $self, $c ) = @_;
 173         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 174             $c->res->redirect( '/login' ); # require login
 175             return 0; # abort request and go immediately to end()
 176         }
 177         return 1; # success; carry on to next action
 178     }
 179
 180     # called after all actions are finished
 181     sub end : Private {
 182         my ( $self, $c ) = @_;
 183         if ( scalar @{ $c->error } ) { ... } # handle errors
 184         return if $c->res->body; # already have a response
 185         $c->forward( 'MyApp::View::TT' ); # render template
 186     }
 187
 188     ### in MyApp/Controller/Foo.pm
 189     # called for /foo/bar
 190     sub bar : Local { ... }
 191
 192     # called for /blargle
 193     sub blargle : Global { ... }
 194
 195     # an index action matches /foo, but not /foo/1, etc.
 196     sub index : Private { ... }
 197
 198     ### in MyApp/Controller/Foo/Bar.pm
 199     # called for /foo/bar/baz
 200     sub baz : Local { ... }
 201
 202     # first Root auto is called, then Foo auto, then this
 203     sub auto : Private { ... }
 204
 205     # powerful regular expression paths are also possible
 206     sub details : Regex('^product/(\w+)/details$') {
 207         my ( $self, $c ) = @_;
 208         # extract the (\w+) from the URI
 209         my $product = $c->req->captures->[0];
 210     }
 211
 212 See L<Catalyst::Manual::Intro> for additional information.
 213
 214 =head1 DESCRIPTION
 215
 216 Catalyst is a modern framework for making web applications without the
 217 pain usually associated with this process. This document is a reference
 218 to the main Catalyst application. If you are a new user, we suggest you
 219 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 220
 221 See L<Catalyst::Manual> for more documentation.
 222
 223 Catalyst plugins can be loaded by naming them as arguments to the "use
 224 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 225 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 226 C<My::Module>.
 227
 228     use Catalyst qw/My::Module/;
 229
 230 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 231 fully qualify the name by using a unary plus:
 232
 233     use Catalyst qw/
 234         My::Module
 235         +Fully::Qualified::Plugin::Name
 236     /;
 237
 238 Special flags like C<-Debug> and C<-Engine> can also be specified as
 239 arguments when Catalyst is loaded:
 240
 241     use Catalyst qw/-Debug My::Module/;
 242
 243 The position of plugins and flags in the chain is important, because
 244 they are loaded in the order in which they appear.
 245
 246 The following flags are supported:
 247
 248 =head2 -Debug
 249
 250 Enables debug output. You can also force this setting from the system
 251 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 252 settings override the application, with <MYAPP>_DEBUG having the highest
 253 priority.
 254
 255 This sets the log level to 'debug' and enables full debug output on the
 256 error screen. If you only want the latter, see L<< $c->debug >>.
 257
 258 =head2 -Engine
 259
 260 Forces Catalyst to use a specific engine. Omit the
 261 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 262
 263     use Catalyst qw/-Engine=CGI/;
 264
 265 =head2 -Home
 266
 267 Forces Catalyst to use a specific home directory, e.g.:
 268
 269     use Catalyst qw[-Home=/usr/mst];
 270
 271 This can also be done in the shell environment by setting either the
 272 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 273 is replaced with the uppercased name of your application, any "::" in
 274 the name will be replaced with underscores, e.g. MyApp::Web should use
 275 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 276
 277 If none of these are set, Catalyst will attempt to automatically detect the
 278 home directory. If you are working in a development envirnoment, Catalyst
 279 will try and find the directory containing either Makefile.PL, Build.PL or
 280 dist.ini. If the application has been installed into the system (i.e.
 281 you have done C<make install>), then Catalyst will use the path to your
 282 application module, without the .pm extension (ie, /foo/MyApp if your
 283 application was installed at /foo/MyApp.pm)
 284
 285 =head2 -Log
 286
 287     use Catalyst '-Log=warn,fatal,error';
 288
 289 Specifies a comma-delimited list of log levels.
 290
 291 =head2 -Stats
 292
 293 Enables statistics collection and reporting.
 294
 295    use Catalyst qw/-Stats=1/;
 296
 297 You can also force this setting from the system environment with CATALYST_STATS
 298 or <MYAPP>_STATS. The environment settings override the application, with
 299 <MYAPP>_STATS having the highest priority.
 300
 301 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 302
 303 =head1 METHODS
 304
 305 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 306
 307 =head2 $c->action
 308
 309 Returns a L<Catalyst::Action> object for the current action, which
 310 stringifies to the action name. See L<Catalyst::Action>.
 311
 312 =head2 $c->namespace
 313
 314 Returns the namespace of the current action, i.e., the URI prefix
 315 corresponding to the controller of the current action. For example:
 316
 317     # in Controller::Foo::Bar
 318     $c->namespace; # returns 'foo/bar';
 319
 320 =head2 $c->request
 321
 322 =head2 $c->req
 323
 324 Returns the current L<Catalyst::Request> object, giving access to
 325 information about the current client request (including parameters,
 326 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 327
 328 =head2 REQUEST FLOW HANDLING
 329
 330 =head2 $c->forward( $action [, \@arguments ] )
 331
 332 =head2 $c->forward( $class, $method, [, \@arguments ] )
 333
 334 Forwards processing to another action, by its private name. If you give a
 335 class name but no method, C<process()> is called. You may also optionally
 336 pass arguments in an arrayref. The action will receive the arguments in
 337 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 338 C<< $c->req->args >> will be restored to the previous values.
 339
 340 Any data C<return>ed from the action forwarded to, will be returned by the
 341 call to forward.
 342
 343     my $foodata = $c->forward('/foo');
 344     $c->forward('index');
 345     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 346     $c->forward('View::TT');
 347
 348 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 349 an C<< eval { } >> around the call (actually
 350 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 351 all 'dies' within the called action. If you want C<die> to propagate you
 352 need to do something like:
 353
 354     $c->forward('foo');
 355     die join "\n", @{ $c->error } if @{ $c->error };
 356
 357 Or make sure to always return true values from your actions and write
 358 your code like this:
 359
 360     $c->forward('foo') || return;
 361
 362 Another note is that C<< $c->forward >> always returns a scalar because it
 363 actually returns $c->state which operates in a scalar context.
 364 Thus, something like:
 365
 366     return @array;
 367
 368 in an action that is forwarded to is going to return a scalar,
 369 i.e. how many items are in that array, which is probably not what you want.
 370 If you need to return an array then return a reference to it,
 371 or stash it like so:
 372
 373     $c->stash->{array} = \@array;
 374
 375 and access it from the stash.
 376
 377 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 378
 379 =cut
 380
 381 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 382
 383 =head2 $c->detach( $action [, \@arguments ] )
 384
 385 =head2 $c->detach( $class, $method, [, \@arguments ] )
 386
 387 =head2 $c->detach()
 388
 389 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 390 doesn't return to the previous action when processing is finished.
 391
 392 When called with no arguments it escapes the processing chain entirely.
 393
 394 =cut
 395
 396 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 397
 398 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 399
 400 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 401
 402 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 403 but does a full dispatch, instead of just calling the new C<$action> /
 404 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 405 you go to are called, just like a new request.
 406
 407 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 408 This means, for example, that C<< $c->action >> methods such as
 409 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 410 L<reverse|Catalyst::Action/reverse> return information for the visited action
 411 when they are invoked within the visited action.  This is different from the
 412 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 413 continues to use the $c->action object from the caller action even when
 414 invoked from the callee.
 415
 416 C<< $c->stash >> is kept unchanged.
 417
 418 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 419 allows you to "wrap" another action, just as it would have been called by
 420 dispatching from a URL, while the analogous
 421 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 422 transfer control to another action as if it had been reached directly from a URL.
 423
 424 =cut
 425
 426 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 427
 428 =head2 $c->go( $action [, \@captures, \@arguments ] )
 429
 430 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 431
 432 The relationship between C<go> and
 433 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 434 the relationship between
 435 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 436 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 437 C<< $c->go >> will perform a full dispatch on the specified action or method,
 438 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 439 C<go> escapes the processing of the current request chain on completion, and
 440 does not return to its caller.
 441
 442 @arguments are arguments to the final destination of $action. @captures are
 443 arguments to the intermediate steps, if any, on the way to the final sub of
 444 $action.
 445
 446 =cut
 447
 448 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 449
 450 =head2 $c->response
 451
 452 =head2 $c->res
 453
 454 Returns the current L<Catalyst::Response> object, see there for details.
 455
 456 =head2 $c->stash
 457
 458 Returns a hashref to the stash, which may be used to store data and pass
 459 it between components during a request. You can also set hash keys by
 460 passing arguments. The stash is automatically sent to the view. The
 461 stash is cleared at the end of a request; it cannot be used for
 462 persistent storage (for this you must use a session; see
 463 L<Catalyst::Plugin::Session> for a complete system integrated with
 464 Catalyst).
 465
 466     $c->stash->{foo} = $bar;
 467     $c->stash( { moose => 'majestic', qux => 0 } );
 468     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 469
 470     # stash is automatically passed to the view for use in a template
 471     $c->forward( 'MyApp::View::TT' );
 472
 473 =cut
 474
 475 around stash => sub {
 476     my $orig = shift;
 477     my $c = shift;
 478     my $stash = $orig->($c);
 479     if (@_) {
 480         my $new_stash = @_ > 1 ? {@_} : $_[0];
 481         croak('stash takes a hash or hashref') unless ref $new_stash;
 482         foreach my $key ( keys %$new_stash ) {
 483           $stash->{$key} = $new_stash->{$key};
 484         }
 485     }
 486
 487     return $stash;
 488 };
 489
 490
 491 =head2 $c->error
 492
 493 =head2 $c->error($error, ...)
 494
 495 =head2 $c->error($arrayref)
 496
 497 Returns an arrayref containing error messages.  If Catalyst encounters an
 498 error while processing a request, it stores the error in $c->error.  This
 499 method should only be used to store fatal error messages.
 500
 501     my @error = @{ $c->error };
 502
 503 Add a new error.
 504
 505     $c->error('Something bad happened');
 506
 507 =cut
 508
 509 sub error {
 510     my $c = shift;
 511     if ( $_[0] ) {
 512         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 513         croak @$error unless ref $c;
 514         push @{ $c->{error} }, @$error;
 515     }
 516     elsif ( defined $_[0] ) { $c->{error} = undef }
 517     return $c->{error} || [];
 518 }
 519
 520
 521 =head2 $c->state
 522
 523 Contains the return value of the last executed action.
 524 Note that << $c->state >> operates in a scalar context which means that all
 525 values it returns are scalar.
 526
 527 =head2 $c->clear_errors
 528
 529 Clear errors.  You probably don't want to clear the errors unless you are
 530 implementing a custom error screen.
 531
 532 This is equivalent to running
 533
 534     $c->error(0);
 535
 536 =cut
 537
 538 sub clear_errors {
 539     my $c = shift;
 540     $c->error(0);
 541 }
 542
 543 sub _comp_search_prefixes {
 544     my $c = shift;
 545     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 546 }
 547
 548 # search components given a name and some prefixes
 549 sub _comp_names_search_prefixes {
 550     my ( $c, $name, @prefixes ) = @_;
 551     my $appclass = ref $c || $c;
 552     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 553     $filter = qr/$filter/; # Compile regex now rather than once per loop
 554
 555     # map the original component name to the sub part that we will search against
 556     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 557         grep { /$filter/ } keys %{ $c->components };
 558
 559     # undef for a name will return all
 560     return keys %eligible if !defined $name;
 561
 562     my $query  = ref $name ? $name : qr/^$name$/i;
 563     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 564
 565     return @result if @result;
 566
 567     # if we were given a regexp to search against, we're done.
 568     return if ref $name;
 569
 570     # skip regexp fallback if configured
 571     return
 572         if $appclass->config->{disable_component_resolution_regex_fallback};
 573
 574     # regexp fallback
 575     $query  = qr/$name/i;
 576     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 577
 578     # no results? try against full names
 579     if( !@result ) {
 580         @result = grep { m{$query} } keys %eligible;
 581     }
 582
 583     # don't warn if we didn't find any results, it just might not exist
 584     if( @result ) {
 585         # Disgusting hack to work out correct method name
 586         my $warn_for = lc $prefixes[0];
 587         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 588            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 589            "component resolution is unreliable and unsafe.";
 590         my $short = $result[0];
 591         # remove the component namespace prefix
 592         $short =~ s/.*?(Model|Controller|View):://;
 593         my $shortmess = Carp::shortmess('');
 594         if ($shortmess =~ m#Catalyst/Plugin#) {
 595            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 596               "plugin's config";
 597         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 598            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 599               "component's config";
 600         } else {
 601            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 602               "but if you really wanted to search, pass in a regexp as the argument " .
 603               "like so: \$c->${warn_for}(qr/${name}/)";
 604         }
 605         $c->log->warn( "${msg}$shortmess" );
 606     }
 607
 608     return @result;
 609 }
 610
 611 # Find possible names for a prefix
 612 sub _comp_names {
 613     my ( $c, @prefixes ) = @_;
 614     my $appclass = ref $c || $c;
 615
 616     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 617
 618     my @names = map { s{$filter}{}; $_; }
 619         $c->_comp_names_search_prefixes( undef, @prefixes );
 620
 621     return @names;
 622 }
 623
 624 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 625 sub _filter_component {
 626     my ( $c, $comp, @args ) = @_;
 627
 628     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 629         return $comp->ACCEPT_CONTEXT( $c, @args );
 630     }
 631
 632     return $comp;
 633 }
 634
 635 =head2 COMPONENT ACCESSORS
 636
 637 =head2 $c->controller($name)
 638
 639 Gets a L<Catalyst::Controller> instance by name.
 640
 641     $c->controller('Foo')->do_stuff;
 642
 643 If the name is omitted, will return the controller for the dispatched
 644 action.
 645
 646 If you want to search for controllers, pass in a regexp as the argument.
 647
 648     # find all controllers that start with Foo
 649     my @foo_controllers = $c->controller(qr{^Foo});
 650
 651
 652 =cut
 653
 654 sub controller {
 655     my ( $c, $name, @args ) = @_;
 656
 657     my $appclass = ref($c) || $c;
 658     if( $name ) {
 659         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 660             my $comps = $c->components;
 661             my $check = $appclass."::Controller::".$name;
 662             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 663         }
 664         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 665         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 666         return $c->_filter_component( $result[ 0 ], @args );
 667     }
 668
 669     return $c->component( $c->action->class );
 670 }
 671
 672 =head2 $c->model($name)
 673
 674 Gets a L<Catalyst::Model> instance by name.
 675
 676     $c->model('Foo')->do_stuff;
 677
 678 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 679
 680 If the name is omitted, it will look for
 681  - a model object in $c->stash->{current_model_instance}, then
 682  - a model name in $c->stash->{current_model}, then
 683  - a config setting 'default_model', or
 684  - check if there is only one model, and return it if that's the case.
 685
 686 If you want to search for models, pass in a regexp as the argument.
 687
 688     # find all models that start with Foo
 689     my @foo_models = $c->model(qr{^Foo});
 690
 691 =cut
 692
 693 sub model {
 694     my ( $c, $name, @args ) = @_;
 695     my $appclass = ref($c) || $c;
 696     if( $name ) {
 697         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 698             my $comps = $c->components;
 699             my $check = $appclass."::Model::".$name;
 700             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 701         }
 702         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 703         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 704         return $c->_filter_component( $result[ 0 ], @args );
 705     }
 706
 707     if (ref $c) {
 708         return $c->stash->{current_model_instance}
 709           if $c->stash->{current_model_instance};
 710         return $c->model( $c->stash->{current_model} )
 711           if $c->stash->{current_model};
 712     }
 713     return $c->model( $appclass->config->{default_model} )
 714       if $appclass->config->{default_model};
 715
 716     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 717
 718     if( $rest ) {
 719         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 720         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 721         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 722         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 723         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 724     }
 725
 726     return $c->_filter_component( $comp );
 727 }
 728
 729
 730 =head2 $c->view($name)
 731
 732 Gets a L<Catalyst::View> instance by name.
 733
 734     $c->view('Foo')->do_stuff;
 735
 736 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 737
 738 If the name is omitted, it will look for
 739  - a view object in $c->stash->{current_view_instance}, then
 740  - a view name in $c->stash->{current_view}, then
 741  - a config setting 'default_view', or
 742  - check if there is only one view, and return it if that's the case.
 743
 744 If you want to search for views, pass in a regexp as the argument.
 745
 746     # find all views that start with Foo
 747     my @foo_views = $c->view(qr{^Foo});
 748
 749 =cut
 750
 751 sub view {
 752     my ( $c, $name, @args ) = @_;
 753
 754     my $appclass = ref($c) || $c;
 755     if( $name ) {
 756         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 757             my $comps = $c->components;
 758             my $check = $appclass."::View::".$name;
 759             if( exists $comps->{$check} ) {
 760                 return $c->_filter_component( $comps->{$check}, @args );
 761             }
 762             else {
 763                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 764             }
 765         }
 766         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 767         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 768         return $c->_filter_component( $result[ 0 ], @args );
 769     }
 770
 771     if (ref $c) {
 772         return $c->stash->{current_view_instance}
 773           if $c->stash->{current_view_instance};
 774         return $c->view( $c->stash->{current_view} )
 775           if $c->stash->{current_view};
 776     }
 777     return $c->view( $appclass->config->{default_view} )
 778       if $appclass->config->{default_view};
 779
 780     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 781
 782     if( $rest ) {
 783         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 784         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 785         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 786         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 787         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 788     }
 789
 790     return $c->_filter_component( $comp );
 791 }
 792
 793 =head2 $c->controllers
 794
 795 Returns the available names which can be passed to $c->controller
 796
 797 =cut
 798
 799 sub controllers {
 800     my ( $c ) = @_;
 801     return $c->_comp_names(qw/Controller C/);
 802 }
 803
 804 =head2 $c->models
 805
 806 Returns the available names which can be passed to $c->model
 807
 808 =cut
 809
 810 sub models {
 811     my ( $c ) = @_;
 812     return $c->_comp_names(qw/Model M/);
 813 }
 814
 815
 816 =head2 $c->views
 817
 818 Returns the available names which can be passed to $c->view
 819
 820 =cut
 821
 822 sub views {
 823     my ( $c ) = @_;
 824     return $c->_comp_names(qw/View V/);
 825 }
 826
 827 =head2 $c->comp($name)
 828
 829 =head2 $c->component($name)
 830
 831 Gets a component object by name. This method is not recommended,
 832 unless you want to get a specific component by full
 833 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 834 should be used instead.
 835
 836 If C<$name> is a regexp, a list of components matched against the full
 837 component name will be returned.
 838
 839 If Catalyst can't find a component by name, it will fallback to regex
 840 matching by default. To disable this behaviour set
 841 disable_component_resolution_regex_fallback to a true value.
 842
 843     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 844
 845 =cut
 846
 847 sub component {
 848     my ( $c, $name, @args ) = @_;
 849
 850     if( $name ) {
 851         my $comps = $c->components;
 852
 853         if( !ref $name ) {
 854             # is it the exact name?
 855             return $c->_filter_component( $comps->{ $name }, @args )
 856                        if exists $comps->{ $name };
 857
 858             # perhaps we just omitted "MyApp"?
 859             my $composed = ( ref $c || $c ) . "::${name}";
 860             return $c->_filter_component( $comps->{ $composed }, @args )
 861                        if exists $comps->{ $composed };
 862
 863             # search all of the models, views and controllers
 864             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 865             return $c->_filter_component( $comp, @args ) if $comp;
 866         }
 867
 868         # This is here so $c->comp( '::M::' ) works
 869         my $query = ref $name ? $name : qr{$name}i;
 870
 871         my @result = grep { m{$query} } keys %{ $c->components };
 872         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 873
 874         if( $result[ 0 ] ) {
 875             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 876             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 877             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 878             return $c->_filter_component( $result[ 0 ], @args );
 879         }
 880
 881         # I would expect to return an empty list here, but that breaks back-compat
 882     }
 883
 884     # fallback
 885     return sort keys %{ $c->components };
 886 }
 887
 888 =head2 CLASS DATA AND HELPER CLASSES
 889
 890 =head2 $c->config
 891
 892 Returns or takes a hashref containing the application's configuration.
 893
 894     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 895
 896 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 897 like C<myapp.conf> in your applications home directory. See
 898 L<Catalyst::Plugin::ConfigLoader>.
 899
 900 =head3 Cascading configuration
 901
 902 The config method is present on all Catalyst components, and configuration
 903 will be merged when an application is started. Configuration loaded with
 904 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 905 followed by configuration in your top level C<MyApp> class. These two
 906 configurations are merged, and then configuration data whose hash key matches a
 907 component name is merged with configuration for that component.
 908
 909 The configuration for a component is then passed to the C<new> method when a
 910 component is constructed.
 911
 912 For example:
 913
 914     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 915     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 916
 917 will mean that C<MyApp::Model::Foo> receives the following data when
 918 constructed:
 919
 920     MyApp::Model::Foo->new({
 921         bar => 'baz',
 922         quux => 'frob',
 923         overrides => 'me',
 924     });
 925
 926 It's common practice to use a Moose attribute
 927 on the receiving component to access the config value.
 928
 929     package MyApp::Model::Foo;
 930
 931     use Moose;
 932
 933     # this attr will receive 'baz' at construction time
 934     has 'bar' => (
 935         is  => 'rw',
 936         isa => 'Str',
 937     );
 938
 939 You can then get the value 'baz' by calling $c->model('Foo')->bar
 940 (or $self->bar inside code in the model).
 941
 942 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 943 as a way of reading config within your code, as this B<will not> give you the
 944 correctly merged config back. You B<MUST> take the config values supplied to
 945 the constructor and use those instead.
 946
 947 =cut
 948
 949 around config => sub {
 950     my $orig = shift;
 951     my $c = shift;
 952
 953     croak('Setting config after setup has been run is not allowed.')
 954         if ( @_ and $c->setup_finished );
 955
 956     $c->$orig(@_);
 957 };
 958
 959 =head2 $c->log
 960
 961 Returns the logging object instance. Unless it is already set, Catalyst
 962 sets this up with a L<Catalyst::Log> object. To use your own log class,
 963 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 964 C<< __PACKAGE__->setup >>.
 965
 966  __PACKAGE__->log( MyLogger->new );
 967  __PACKAGE__->setup;
 968
 969 And later:
 970
 971     $c->log->info( 'Now logging with my own logger!' );
 972
 973 Your log class should implement the methods described in
 974 L<Catalyst::Log>.
 975
 976
 977 =head2 $c->debug
 978
 979 Returns 1 if debug mode is enabled, 0 otherwise.
 980
 981 You can enable debug mode in several ways:
 982
 983 =over
 984
 985 =item By calling myapp_server.pl with the -d flag
 986
 987 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 988
 989 =item The -Debug option in your MyApp.pm
 990
 991 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 992
 993 =back
 994
 995 The first three also set the log level to 'debug'.
 996
 997 Calling C<< $c->debug(1) >> has no effect.
 998
 999 =cut
1000
1001 sub debug { 0 }
1002
1003 =head2 $c->dispatcher
1004
1005 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1006
1007 =head2 $c->engine
1008
1009 Returns the engine instance. See L<Catalyst::Engine>.
1010
1011
1012 =head2 UTILITY METHODS
1013
1014 =head2 $c->path_to(@path)
1015
1016 Merges C<@path> with C<< $c->config->{home} >> and returns a
1017 L<Path::Class::Dir> object. Note you can usually use this object as
1018 a filename, but sometimes you will have to explicitly stringify it
1019 yourself by calling the C<< ->stringify >> method.
1020
1021 For example:
1022
1023     $c->path_to( 'db', 'sqlite.db' );
1024
1025 =cut
1026
1027 sub path_to {
1028     my ( $c, @path ) = @_;
1029     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1030     if ( -d $path ) { return $path }
1031     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1032 }
1033
1034 =head2 $c->plugin( $name, $class, @args )
1035
1036 Helper method for plugins. It creates a class data accessor/mutator and
1037 loads and instantiates the given class.
1038
1039     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1040
1041     $c->prototype->define_javascript_functions;
1042
1043 B<Note:> This method of adding plugins is deprecated. The ability
1044 to add plugins like this B<will be removed> in a Catalyst 5.81.
1045 Please do not use this functionality in new code.
1046
1047 =cut
1048
1049 sub plugin {
1050     my ( $class, $name, $plugin, @args ) = @_;
1051
1052     # See block comment in t/unit_core_plugin.t
1053     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1054
1055     $class->_register_plugin( $plugin, 1 );
1056
1057     eval { $plugin->import };
1058     $class->mk_classdata($name);
1059     my $obj;
1060     eval { $obj = $plugin->new(@args) };
1061
1062     if ($@) {
1063         Catalyst::Exception->throw( message =>
1064               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1065     }
1066
1067     $class->$name($obj);
1068     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1069       if $class->debug;
1070 }
1071
1072 =head2 MyApp->setup
1073
1074 Initializes the dispatcher and engine, loads any plugins, and loads the
1075 model, view, and controller components. You may also specify an array
1076 of plugins to load here, if you choose to not load them in the C<use
1077 Catalyst> line.
1078
1079     MyApp->setup;
1080     MyApp->setup( qw/-Debug/ );
1081
1082 =cut
1083
1084 sub setup {
1085     my ( $class, @arguments ) = @_;
1086     croak('Running setup more than once')
1087         if ( $class->setup_finished );
1088
1089     unless ( $class->isa('Catalyst') ) {
1090
1091         Catalyst::Exception->throw(
1092             message => qq/'$class' does not inherit from Catalyst/ );
1093     }
1094
1095     if ( $class->arguments ) {
1096         @arguments = ( @arguments, @{ $class->arguments } );
1097     }
1098
1099     # Process options
1100     my $flags = {};
1101
1102     foreach (@arguments) {
1103
1104         if (/^-Debug$/) {
1105             $flags->{log} =
1106               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1107         }
1108         elsif (/^-(\w+)=?(.*)$/) {
1109             $flags->{ lc $1 } = $2;
1110         }
1111         else {
1112             push @{ $flags->{plugins} }, $_;
1113         }
1114     }
1115
1116     $class->setup_home( delete $flags->{home} );
1117
1118     $class->setup_log( delete $flags->{log} );
1119     $class->setup_plugins( delete $flags->{plugins} );
1120     $class->setup_dispatcher( delete $flags->{dispatcher} );
1121     if (my $engine = delete $flags->{engine}) {
1122         $class->log->warn("Specifying the engine in ->setup is no longer supported, XXX FIXME");
1123     }
1124     $class->setup_engine();
1125     $class->setup_stats( delete $flags->{stats} );
1126
1127     for my $flag ( sort keys %{$flags} ) {
1128
1129         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1130             &$code( $class, delete $flags->{$flag} );
1131         }
1132         else {
1133             $class->log->warn(qq/Unknown flag "$flag"/);
1134         }
1135     }
1136
1137     eval { require Catalyst::Devel; };
1138     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1139         $class->log->warn(<<"EOF");
1140 You are running an old script!
1141
1142   Please update by running (this will overwrite existing files):
1143     catalyst.pl -force -scripts $class
1144
1145   or (this will not overwrite existing files):
1146     catalyst.pl -scripts $class
1147
1148 EOF
1149     }
1150
1151     if ( $class->debug ) {
1152         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1153
1154         if (@plugins) {
1155             my $column_width = Catalyst::Utils::term_width() - 6;
1156             my $t = Text::SimpleTable->new($column_width);
1157             $t->row($_) for @plugins;
1158             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1159         }
1160
1161         my $dispatcher = $class->dispatcher;
1162         my $engine     = $class->engine;
1163         my $home       = $class->config->{home};
1164
1165         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1166         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1167
1168         $home
1169           ? ( -d $home )
1170           ? $class->log->debug(qq/Found home "$home"/)
1171           : $class->log->debug(qq/Home "$home" doesn't exist/)
1172           : $class->log->debug(q/Couldn't find home/);
1173     }
1174
1175     # Call plugins setup, this is stupid and evil.
1176     # Also screws C3 badly on 5.10, hack to avoid.
1177     {
1178         no warnings qw/redefine/;
1179         local *setup = sub { };
1180         $class->setup unless $Catalyst::__AM_RESTARTING;
1181     }
1182
1183     # Initialize our data structure
1184     $class->components( {} );
1185
1186     $class->setup_components;
1187
1188     if ( $class->debug ) {
1189         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1190         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1191         for my $comp ( sort keys %{ $class->components } ) {
1192             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1193             $t->row( $comp, $type );
1194         }
1195         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1196           if ( keys %{ $class->components } );
1197     }
1198
1199     # Add our self to components, since we are also a component
1200     if( $class->isa('Catalyst::Controller') ){
1201       $class->components->{$class} = $class;
1202     }
1203
1204     $class->setup_actions;
1205
1206     if ( $class->debug ) {
1207         my $name = $class->config->{name} || 'Application';
1208         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1209     }
1210
1211     # Make sure that the application class becomes immutable at this point,
1212     B::Hooks::EndOfScope::on_scope_end {
1213         return if $@;
1214         my $meta = Class::MOP::get_metaclass_by_name($class);
1215         if (
1216             $meta->is_immutable
1217             && ! { $meta->immutable_options }->{replace_constructor}
1218             && (
1219                    $class->isa('Class::Accessor::Fast')
1220                 || $class->isa('Class::Accessor')
1221             )
1222         ) {
1223             warn "You made your application class ($class) immutable, "
1224                 . "but did not inline the\nconstructor. "
1225                 . "This will break catalyst, as your app \@ISA "
1226                 . "Class::Accessor(::Fast)?\nPlease pass "
1227                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1228         }
1229         $meta->make_immutable(
1230             replace_constructor => 1,
1231         ) unless $meta->is_immutable;
1232     };
1233
1234     if ($class->config->{case_sensitive}) {
1235         $class->log->warn($class . "->config->{case_sensitive} is set.");
1236         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1237     }
1238
1239     $class->setup_finalize;
1240     # Should be the last thing we do so that user things hooking
1241     # setup_finalize can log..
1242     $class->log->_flush() if $class->log->can('_flush');
1243     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1244 }
1245
1246 =head2 $app->setup_finalize
1247
1248 A hook to attach modifiers to. This method does not do anything except set the
1249 C<setup_finished> accessor.
1250
1251 Applying method modifiers to the C<setup> method doesn't work, because of quirky thingsdone for plugin setup.
1252
1253 Example:
1254
1255     after setup_finalize => sub {
1256         my $app = shift;
1257
1258         ## do stuff here..
1259     };
1260
1261 =cut
1262
1263 sub setup_finalize {
1264     my ($class) = @_;
1265     $class->setup_finished(1);
1266 }
1267
1268 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1269
1270 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1271
1272 Constructs an absolute L<URI> object based on the application root, the
1273 provided path, and the additional arguments and query parameters provided.
1274 When used as a string, provides a textual URI.  If you need more flexibility
1275 than this (i.e. the option to provide relative URIs etc.) see
1276 L<Catalyst::Plugin::SmartURI>.
1277
1278 If no arguments are provided, the URI for the current action is returned.
1279 To return the current action and also provide @args, use
1280 C<< $c->uri_for( $c->action, @args ) >>.
1281
1282 If the first argument is a string, it is taken as a public URI path relative
1283 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1284 relative to the application root (if it does). It is then merged with
1285 C<< $c->request->base >>; any C<@args> are appended as additional path
1286 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1287
1288 If the first argument is a L<Catalyst::Action> it represents an action which
1289 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1290 optional C<\@captures> argument (an arrayref) allows passing the captured
1291 variables that are needed to fill in the paths of Chained and Regex actions;
1292 once the path is resolved, C<uri_for> continues as though a path was
1293 provided, appending any arguments or parameters and creating an absolute
1294 URI.
1295
1296 The captures for the current request can be found in
1297 C<< $c->request->captures >>, and actions can be resolved using
1298 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1299 path, use C<< $c->uri_for_action >> instead.
1300
1301   # Equivalent to $c->req->uri
1302   $c->uri_for($c->action, $c->req->captures,
1303       @{ $c->req->args }, $c->req->params);
1304
1305   # For the Foo action in the Bar controller
1306   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1307
1308   # Path to a static resource
1309   $c->uri_for('/static/images/logo.png');
1310
1311 =cut
1312
1313 sub uri_for {
1314     my ( $c, $path, @args ) = @_;
1315
1316     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1317         $path = $path->path_prefix;
1318         $path =~ s{/+\z}{};
1319         $path .= '/';
1320     }
1321
1322     undef($path) if (defined $path && $path eq '');
1323
1324     my $params =
1325       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1326
1327     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1328     foreach my $arg (@args) {
1329         utf8::encode($arg) if utf8::is_utf8($arg);
1330         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1331     }
1332
1333     if ( blessed($path) ) { # action object
1334         s|/|%2F|g for @args;
1335         my $captures = [ map { s|/|%2F|g; $_; }
1336                         ( scalar @args && ref $args[0] eq 'ARRAY'
1337                          ? @{ shift(@args) }
1338                          : ()) ];
1339
1340         foreach my $capture (@$captures) {
1341             utf8::encode($capture) if utf8::is_utf8($capture);
1342             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1343         }
1344
1345         my $action = $path;
1346         $path = $c->dispatcher->uri_for_action($action, $captures);
1347         if (not defined $path) {
1348             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1349                 if $c->debug;
1350             return undef;
1351         }
1352         $path = '/' if $path eq '';
1353     }
1354
1355     unshift(@args, $path);
1356
1357     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1358         my $namespace = $c->namespace;
1359         if (defined $path) { # cheesy hack to handle path '../foo'
1360            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1361         }
1362         unshift(@args, $namespace || '');
1363     }
1364
1365     # join args with '/', or a blank string
1366     my $args = join('/', grep { defined($_) } @args);
1367     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1368     $args =~ s!^/+!!;
1369     my $base = $c->req->base;
1370     my $class = ref($base);
1371     $base =~ s{(?<!/)$}{/};
1372
1373     my $query = '';
1374
1375     if (my @keys = keys %$params) {
1376       # somewhat lifted from URI::_query's query_form
1377       $query = '?'.join('&', map {
1378           my $val = $params->{$_};
1379           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1380           s/ /+/g;
1381           my $key = $_;
1382           $val = '' unless defined $val;
1383           (map {
1384               my $param = "$_";
1385               utf8::encode( $param ) if utf8::is_utf8($param);
1386               # using the URI::Escape pattern here so utf8 chars survive
1387               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1388               $param =~ s/ /+/g;
1389               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1390       } @keys);
1391     }
1392
1393     my $res = bless(\"${base}${args}${query}", $class);
1394     $res;
1395 }
1396
1397 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1398
1399 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1400
1401 =over
1402
1403 =item $path
1404
1405 A private path to the Catalyst action you want to create a URI for.
1406
1407 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1408 >> and passing the resulting C<$action> and the remaining arguments to C<<
1409 $c->uri_for >>.
1410
1411 You can also pass in a Catalyst::Action object, in which case it is passed to
1412 C<< $c->uri_for >>.
1413
1414 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1415
1416 For example, if the action looks like:
1417
1418  package MyApp::Controller::Users;
1419
1420  sub lst : Path('the-list') {}
1421
1422 You can use:
1423
1424  $c->uri_for_action('/users/lst')
1425
1426 and it will create the URI /users/the-list.
1427
1428 =back
1429
1430 =cut
1431
1432 sub uri_for_action {
1433     my ( $c, $path, @args ) = @_;
1434     my $action = blessed($path)
1435       ? $path
1436       : $c->dispatcher->get_action_by_path($path);
1437     unless (defined $action) {
1438       croak "Can't find action for path '$path'";
1439     }
1440     return $c->uri_for( $action, @args );
1441 }
1442
1443 =head2 $c->welcome_message
1444
1445 Returns the Catalyst welcome HTML page.
1446
1447 =cut
1448
1449 sub welcome_message {
1450     my $c      = shift;
1451     my $name   = $c->config->{name};
1452     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1453     my $prefix = Catalyst::Utils::appprefix( ref $c );
1454     $c->response->content_type('text/html; charset=utf-8');
1455     return <<"EOF";
1456 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1457     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1458 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1459     <head>
1460     <meta http-equiv="Content-Language" content="en" />
1461     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1462         <title>$name on Catalyst $VERSION</title>
1463         <style type="text/css">
1464             body {
1465                 color: #000;
1466                 background-color: #eee;
1467             }
1468             div#content {
1469                 width: 640px;
1470                 margin-left: auto;
1471                 margin-right: auto;
1472                 margin-top: 10px;
1473                 margin-bottom: 10px;
1474                 text-align: left;
1475                 background-color: #ccc;
1476                 border: 1px solid #aaa;
1477             }
1478             p, h1, h2 {
1479                 margin-left: 20px;
1480                 margin-right: 20px;
1481                 font-family: verdana, tahoma, sans-serif;
1482             }
1483             a {
1484                 font-family: verdana, tahoma, sans-serif;
1485             }
1486             :link, :visited {
1487                     text-decoration: none;
1488                     color: #b00;
1489                     border-bottom: 1px dotted #bbb;
1490             }
1491             :link:hover, :visited:hover {
1492                     color: #555;
1493             }
1494             div#topbar {
1495                 margin: 0px;
1496             }
1497             pre {
1498                 margin: 10px;
1499                 padding: 8px;
1500             }
1501             div#answers {
1502                 padding: 8px;
1503                 margin: 10px;
1504                 background-color: #fff;
1505                 border: 1px solid #aaa;
1506             }
1507             h1 {
1508                 font-size: 0.9em;
1509                 font-weight: normal;
1510                 text-align: center;
1511             }
1512             h2 {
1513                 font-size: 1.0em;
1514             }
1515             p {
1516                 font-size: 0.9em;
1517             }
1518             p img {
1519                 float: right;
1520                 margin-left: 10px;
1521             }
1522             span#appname {
1523                 font-weight: bold;
1524                 font-size: 1.6em;
1525             }
1526         </style>
1527     </head>
1528     <body>
1529         <div id="content">
1530             <div id="topbar">
1531                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1532                     $VERSION</h1>
1533              </div>
1534              <div id="answers">
1535                  <p>
1536                  <img src="$logo" alt="Catalyst Logo" />
1537                  </p>
1538                  <p>Welcome to the  world of Catalyst.
1539                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1540                     framework will make web development something you had
1541                     never expected it to be: Fun, rewarding, and quick.</p>
1542                  <h2>What to do now?</h2>
1543                  <p>That really depends  on what <b>you</b> want to do.
1544                     We do, however, provide you with a few starting points.</p>
1545                  <p>If you want to jump right into web development with Catalyst
1546                     you might want to start with a tutorial.</p>
1547 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1548 </pre>
1549 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1550 <pre>
1551 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1552 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1553 </code></pre>
1554                  <h2>What to do next?</h2>
1555                  <p>Next it's time to write an actual application. Use the
1556                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1557                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1558                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1559                     they can save you a lot of work.</p>
1560                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1561                     <p>Also, be sure to check out the vast and growing
1562                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1563                     you are likely to find what you need there.
1564                     </p>
1565
1566                  <h2>Need help?</h2>
1567                  <p>Catalyst has a very active community. Here are the main places to
1568                     get in touch with us.</p>
1569                  <ul>
1570                      <li>
1571                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1572                      </li>
1573                      <li>
1574                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1575                      </li>
1576                      <li>
1577                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1578                      </li>
1579                  </ul>
1580                  <h2>In conclusion</h2>
1581                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1582                     as we enjoyed making it. Please contact us if you have ideas
1583                     for improvement or other feedback.</p>
1584              </div>
1585          </div>
1586     </body>
1587 </html>
1588 EOF
1589 }
1590
1591 =head1 INTERNAL METHODS
1592
1593 These methods are not meant to be used by end users.
1594
1595 =head2 $c->components
1596
1597 Returns a hash of components.
1598
1599 =head2 $c->context_class
1600
1601 Returns or sets the context class.
1602
1603 =head2 $c->counter
1604
1605 Returns a hashref containing coderefs and execution counts (needed for
1606 deep recursion detection).
1607
1608 =head2 $c->depth
1609
1610 Returns the number of actions on the current internal execution stack.
1611
1612 =head2 $c->dispatch
1613
1614 Dispatches a request to actions.
1615
1616 =cut
1617
1618 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1619
1620 =head2 $c->dispatcher_class
1621
1622 Returns or sets the dispatcher class.
1623
1624 =head2 $c->dump_these
1625
1626 Returns a list of 2-element array references (name, structure) pairs
1627 that will be dumped on the error page in debug mode.
1628
1629 =cut
1630
1631 sub dump_these {
1632     my $c = shift;
1633     [ Request => $c->req ],
1634     [ Response => $c->res ],
1635     [ Stash => $c->stash ],
1636     [ Config => $c->config ];
1637 }
1638
1639 =head2 $c->engine_class
1640
1641 Returns or sets the engine class.
1642
1643 =head2 $c->execute( $class, $coderef )
1644
1645 Execute a coderef in given class and catch exceptions. Errors are available
1646 via $c->error.
1647
1648 =cut
1649
1650 sub execute {
1651     my ( $c, $class, $code ) = @_;
1652     $class = $c->component($class) || $class;
1653     $c->state(0);
1654
1655     if ( $c->depth >= $RECURSION ) {
1656         my $action = $code->reverse();
1657         $action = "/$action" unless $action =~ /->/;
1658         my $error = qq/Deep recursion detected calling "${action}"/;
1659         $c->log->error($error);
1660         $c->error($error);
1661         $c->state(0);
1662         return $c->state;
1663     }
1664
1665     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1666
1667     push( @{ $c->stack }, $code );
1668
1669     no warnings 'recursion';
1670     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1671     #      I have no idea how, ergo $ret (which appears to fix the issue)
1672     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1673
1674     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1675
1676     my $last = pop( @{ $c->stack } );
1677
1678     if ( my $error = $@ ) {
1679         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1680             $error->rethrow if $c->depth > 1;
1681         }
1682         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1683             $error->rethrow if $c->depth > 0;
1684         }
1685         else {
1686             unless ( ref $error ) {
1687                 no warnings 'uninitialized';
1688                 chomp $error;
1689                 my $class = $last->class;
1690                 my $name  = $last->name;
1691                 $error = qq/Caught exception in $class->$name "$error"/;
1692             }
1693             $c->error($error);
1694             $c->state(0);
1695         }
1696     }
1697     return $c->state;
1698 }
1699
1700 sub _stats_start_execute {
1701     my ( $c, $code ) = @_;
1702     my $appclass = ref($c) || $c;
1703     return if ( ( $code->name =~ /^_.*/ )
1704         && ( !$appclass->config->{show_internal_actions} ) );
1705
1706     my $action_name = $code->reverse();
1707     $c->counter->{$action_name}++;
1708
1709     my $action = $action_name;
1710     $action = "/$action" unless $action =~ /->/;
1711
1712     # determine if the call was the result of a forward
1713     # this is done by walking up the call stack and looking for a calling
1714     # sub of Catalyst::forward before the eval
1715     my $callsub = q{};
1716     for my $index ( 2 .. 11 ) {
1717         last
1718         if ( ( caller($index) )[0] eq 'Catalyst'
1719             && ( caller($index) )[3] eq '(eval)' );
1720
1721         if ( ( caller($index) )[3] =~ /forward$/ ) {
1722             $callsub = ( caller($index) )[3];
1723             $action  = "-> $action";
1724             last;
1725         }
1726     }
1727
1728     my $uid = $action_name . $c->counter->{$action_name};
1729
1730     # is this a root-level call or a forwarded call?
1731     if ( $callsub =~ /forward$/ ) {
1732         my $parent = $c->stack->[-1];
1733
1734         # forward, locate the caller
1735         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1736             $c->stats->profile(
1737                 begin  => $action,
1738                 parent => "$parent" . $c->counter->{"$parent"},
1739                 uid    => $uid,
1740             );
1741         }
1742         else {
1743
1744             # forward with no caller may come from a plugin
1745             $c->stats->profile(
1746                 begin => $action,
1747                 uid   => $uid,
1748             );
1749         }
1750     }
1751     else {
1752
1753         # root-level call
1754         $c->stats->profile(
1755             begin => $action,
1756             uid   => $uid,
1757         );
1758     }
1759     return $action;
1760
1761 }
1762
1763 sub _stats_finish_execute {
1764     my ( $c, $info ) = @_;
1765     $c->stats->profile( end => $info );
1766 }
1767
1768 =head2 $c->finalize
1769
1770 Finalizes the request.
1771
1772 =cut
1773
1774 sub finalize {
1775     my $c = shift;
1776
1777     for my $error ( @{ $c->error } ) {
1778         $c->log->error($error);
1779     }
1780
1781     # Allow engine to handle finalize flow (for POE)
1782     my $engine = $c->engine;
1783     if ( my $code = $engine->can('finalize') ) {
1784         $engine->$code($c);
1785     }
1786     else {
1787
1788         $c->finalize_uploads;
1789
1790         # Error
1791         if ( $#{ $c->error } >= 0 ) {
1792             $c->finalize_error;
1793         }
1794
1795         $c->finalize_headers;
1796
1797         # HEAD request
1798         if ( $c->request->method eq 'HEAD' ) {
1799             $c->response->body('');
1800         }
1801
1802         $c->finalize_body;
1803     }
1804
1805     $c->log_response;
1806
1807     if ($c->use_stats) {
1808         my $elapsed = sprintf '%f', $c->stats->elapsed;
1809         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1810         $c->log->info(
1811             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1812     }
1813
1814     return $c->response->status;
1815 }
1816
1817 =head2 $c->finalize_body
1818
1819 Finalizes body.
1820
1821 =cut
1822
1823 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1824
1825 =head2 $c->finalize_cookies
1826
1827 Finalizes cookies.
1828
1829 =cut
1830
1831 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1832
1833 =head2 $c->finalize_error
1834
1835 Finalizes error.
1836
1837 =cut
1838
1839 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1840
1841 =head2 $c->finalize_headers
1842
1843 Finalizes headers.
1844
1845 =cut
1846
1847 sub finalize_headers {
1848     my $c = shift;
1849
1850     my $response = $c->response; #accessor calls can add up?
1851
1852     # Check if we already finalized headers
1853     return if $response->finalized_headers;
1854
1855     # Handle redirects
1856     if ( my $location = $response->redirect ) {
1857         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1858         $response->header( Location => $location );
1859
1860         if ( !$response->has_body ) {
1861             # Add a default body if none is already present
1862             $response->body(
1863                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1864             );
1865         }
1866     }
1867
1868     # Content-Length
1869     if ( defined $response->body && length $response->body && !$response->content_length ) {
1870
1871         # get the length from a filehandle
1872         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1873         {
1874             my $size = -s $response->body;
1875             if ( $size ) {
1876                 $response->content_length( $size );
1877             }
1878             else {
1879                 $c->log->warn('Serving filehandle without a content-length');
1880             }
1881         }
1882         else {
1883             # everything should be bytes at this point, but just in case
1884             $response->content_length( length( $response->body ) );
1885         }
1886     }
1887
1888     # Errors
1889     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1890         $response->headers->remove_header("Content-Length");
1891         $response->body('');
1892     }
1893
1894     $c->finalize_cookies;
1895
1896     $c->engine->finalize_headers( $c, @_ );
1897
1898     # Done
1899     $response->finalized_headers(1);
1900 }
1901
1902 =head2 $c->finalize_output
1903
1904 An alias for finalize_body.
1905
1906 =head2 $c->finalize_read
1907
1908 Finalizes the input after reading is complete.
1909
1910 =cut
1911
1912 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1913
1914 =head2 $c->finalize_uploads
1915
1916 Finalizes uploads. Cleans up any temporary files.
1917
1918 =cut
1919
1920 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1921
1922 =head2 $c->get_action( $action, $namespace )
1923
1924 Gets an action in a given namespace.
1925
1926 =cut
1927
1928 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1929
1930 =head2 $c->get_actions( $action, $namespace )
1931
1932 Gets all actions of a given name in a namespace and all parent
1933 namespaces.
1934
1935 =cut
1936
1937 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1938
1939 =head2 $app->handle_request( @arguments )
1940
1941 Called to handle each HTTP request.
1942
1943 =cut
1944
1945 sub handle_request {
1946     my ( $class, @arguments ) = @_;
1947
1948     # Always expect worst case!
1949     my $status = -1;
1950     try {
1951         if ($class->debug) {
1952             my $secs = time - $START || 1;
1953             my $av = sprintf '%.3f', $COUNT / $secs;
1954             my $time = localtime time;
1955             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1956         }
1957
1958         my $c = $class->prepare(@arguments);
1959         $c->dispatch;
1960         $status = $c->finalize;
1961     }
1962     catch {
1963         chomp(my $error = $_);
1964         $class->log->error(qq/Caught exception in engine "$error"/);
1965     };
1966
1967     $COUNT++;
1968
1969     if(my $coderef = $class->log->can('_flush')){
1970         $class->log->$coderef();
1971     }
1972     return $status;
1973 }
1974
1975 =head2 $c->prepare( @arguments )
1976
1977 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1978 etc.).
1979
1980 =cut
1981
1982 sub prepare {
1983     my ( $class, @arguments ) = @_;
1984
1985     # XXX
1986     # After the app/ctxt split, this should become an attribute based on something passed
1987     # into the application.
1988     $class->context_class( ref $class || $class ) unless $class->context_class;
1989
1990     my $c = $class->context_class->new({});
1991
1992     # For on-demand data
1993     $c->request->_context($c);
1994     $c->response->_context($c);
1995
1996     #surely this is not the most efficient way to do things...
1997     $c->stats($class->stats_class->new)->enable($c->use_stats);
1998     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1999         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2000     }
2001
2002     try {
2003         # Allow engine to direct the prepare flow (for POE)
2004         if ( my $prepare = $c->engine->can('prepare') ) {
2005             $c->engine->$prepare( $c, @arguments );
2006         }
2007         else {
2008             $c->prepare_request(@arguments);
2009             $c->prepare_connection;
2010             $c->prepare_query_parameters;
2011             $c->prepare_headers;
2012             $c->prepare_cookies;
2013             $c->prepare_path;
2014
2015             # Prepare the body for reading, either by prepare_body
2016             # or the user, if they are using $c->read
2017             $c->prepare_read;
2018
2019             # Parse the body unless the user wants it on-demand
2020             unless ( ref($c)->config->{parse_on_demand} ) {
2021                 $c->prepare_body;
2022             }
2023         }
2024     }
2025     # VERY ugly and probably shouldn't rely on ->finalize actually working
2026     catch {
2027         # failed prepare is always due to an invalid request, right?
2028         $c->response->status(400);
2029         $c->response->content_type('text/plain');
2030         $c->response->body('Bad Request');
2031         $c->finalize;
2032         die $_;
2033     };
2034
2035     my $method  = $c->req->method  || '';
2036     my $path    = $c->req->path;
2037     $path       = '/' unless length $path;
2038     my $address = $c->req->address || '';
2039
2040     $c->log_request;
2041
2042     $c->prepare_action;
2043
2044     return $c;
2045 }
2046
2047 =head2 $c->prepare_action
2048
2049 Prepares action. See L<Catalyst::Dispatcher>.
2050
2051 =cut
2052
2053 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2054
2055 =head2 $c->prepare_body
2056
2057 Prepares message body.
2058
2059 =cut
2060
2061 sub prepare_body {
2062     my $c = shift;
2063
2064     return if $c->request->_has_body;
2065
2066     # Initialize on-demand data
2067     $c->engine->prepare_body( $c, @_ );
2068     $c->prepare_parameters;
2069     $c->prepare_uploads;
2070 }
2071
2072 =head2 $c->prepare_body_chunk( $chunk )
2073
2074 Prepares a chunk of data before sending it to L<HTTP::Body>.
2075
2076 See L<Catalyst::Engine>.
2077
2078 =cut
2079
2080 sub prepare_body_chunk {
2081     my $c = shift;
2082     $c->engine->prepare_body_chunk( $c, @_ );
2083 }
2084
2085 =head2 $c->prepare_body_parameters
2086
2087 Prepares body parameters.
2088
2089 =cut
2090
2091 sub prepare_body_parameters {
2092     my $c = shift;
2093     $c->engine->prepare_body_parameters( $c, @_ );
2094 }
2095
2096 =head2 $c->prepare_connection
2097
2098 Prepares connection.
2099
2100 =cut
2101
2102 sub prepare_connection {
2103     my $c = shift;
2104     $c->engine->prepare_connection( $c, @_ );
2105 }
2106
2107 =head2 $c->prepare_cookies
2108
2109 Prepares cookies.
2110
2111 =cut
2112
2113 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2114
2115 =head2 $c->prepare_headers
2116
2117 Prepares headers.
2118
2119 =cut
2120
2121 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2122
2123 =head2 $c->prepare_parameters
2124
2125 Prepares parameters.
2126
2127 =cut
2128
2129 sub prepare_parameters {
2130     my $c = shift;
2131     $c->prepare_body_parameters;
2132     $c->engine->prepare_parameters( $c, @_ );
2133 }
2134
2135 =head2 $c->prepare_path
2136
2137 Prepares path and base.
2138
2139 =cut
2140
2141 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2142
2143 =head2 $c->prepare_query_parameters
2144
2145 Prepares query parameters.
2146
2147 =cut
2148
2149 sub prepare_query_parameters {
2150     my $c = shift;
2151
2152     $c->engine->prepare_query_parameters( $c, @_ );
2153 }
2154
2155 =head2 $c->log_request
2156
2157 Writes information about the request to the debug logs.  This includes:
2158
2159 =over 4
2160
2161 =item * Request method, path, and remote IP address
2162
2163 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2164
2165 =item * Request parameters
2166
2167 =item * File uploads
2168
2169 =back
2170
2171 =cut
2172
2173 sub log_request {
2174     my $c = shift;
2175
2176     return unless $c->debug;
2177
2178     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2179     my $request = $dump->[1];
2180
2181     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2182     $method ||= '';
2183     $path = '/' unless length $path;
2184     $address ||= '';
2185     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2186
2187     $c->log_request_headers($request->headers);
2188
2189     if ( my $keywords = $request->query_keywords ) {
2190         $c->log->debug("Query keywords are: $keywords");
2191     }
2192
2193     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2194
2195     $c->log_request_uploads($request);
2196 }
2197
2198 =head2 $c->log_response
2199
2200 Writes information about the response to the debug logs by calling
2201 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2202
2203 =cut
2204
2205 sub log_response {
2206     my $c = shift;
2207
2208     return unless $c->debug;
2209
2210     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2211     my $response = $dump->[1];
2212
2213     $c->log_response_status_line($response);
2214     $c->log_response_headers($response->headers);
2215 }
2216
2217 =head2 $c->log_response_status_line($response)
2218
2219 Writes one line of information about the response to the debug logs.  This includes:
2220
2221 =over 4
2222
2223 =item * Response status code
2224
2225 =item * Content-Type header (if present)
2226
2227 =item * Content-Length header (if present)
2228
2229 =back
2230
2231 =cut
2232
2233 sub log_response_status_line {
2234     my ($c, $response) = @_;
2235
2236     $c->log->debug(
2237         sprintf(
2238             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2239             $response->status                            || 'unknown',
2240             $response->headers->header('Content-Type')   || 'unknown',
2241             $response->headers->header('Content-Length') || 'unknown'
2242         )
2243     );
2244 }
2245
2246 =head2 $c->log_response_headers($headers);
2247
2248 Hook method which can be wrapped by plugins to log the responseheaders.
2249 No-op in the default implementation.
2250
2251 =cut
2252
2253 sub log_response_headers {}
2254
2255 =head2 $c->log_request_parameters( query => {}, body => {} )
2256
2257 Logs request parameters to debug logs
2258
2259 =cut
2260
2261 sub log_request_parameters {
2262     my $c          = shift;
2263     my %all_params = @_;
2264
2265     return unless $c->debug;
2266
2267     my $column_width = Catalyst::Utils::term_width() - 44;
2268     foreach my $type (qw(query body)) {
2269         my $params = $all_params{$type};
2270         next if ! keys %$params;
2271         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2272         for my $key ( sort keys %$params ) {
2273             my $param = $params->{$key};
2274             my $value = defined($param) ? $param : '';
2275             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2276         }
2277         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2278     }
2279 }
2280
2281 =head2 $c->log_request_uploads
2282
2283 Logs file uploads included in the request to the debug logs.
2284 The parameter name, filename, file type, and file size are all included in
2285 the debug logs.
2286
2287 =cut
2288
2289 sub log_request_uploads {
2290     my $c = shift;
2291     my $request = shift;
2292     return unless $c->debug;
2293     my $uploads = $request->uploads;
2294     if ( keys %$uploads ) {
2295         my $t = Text::SimpleTable->new(
2296             [ 12, 'Parameter' ],
2297             [ 26, 'Filename' ],
2298             [ 18, 'Type' ],
2299             [ 9,  'Size' ]
2300         );
2301         for my $key ( sort keys %$uploads ) {
2302             my $upload = $uploads->{$key};
2303             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2304                 $t->row( $key, $u->filename, $u->type, $u->size );
2305             }
2306         }
2307         $c->log->debug( "File Uploads are:\n" . $t->draw );
2308     }
2309 }
2310
2311 =head2 $c->log_request_headers($headers);
2312
2313 Hook method which can be wrapped by plugins to log the request headers.
2314 No-op in the default implementation.
2315
2316 =cut
2317
2318 sub log_request_headers {}
2319
2320 =head2 $c->log_headers($type => $headers)
2321
2322 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2323
2324 =cut
2325
2326 sub log_headers {
2327     my $c       = shift;
2328     my $type    = shift;
2329     my $headers = shift;    # an HTTP::Headers instance
2330
2331     return unless $c->debug;
2332
2333     my $column_width = Catalyst::Utils::term_width() - 28;
2334     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2335     $headers->scan(
2336         sub {
2337             my ( $name, $value ) = @_;
2338             $t->row( $name, $value );
2339         }
2340     );
2341     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2342 }
2343
2344
2345 =head2 $c->prepare_read
2346
2347 Prepares the input for reading.
2348
2349 =cut
2350
2351 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2352
2353 =head2 $c->prepare_request
2354
2355 Prepares the engine request.
2356
2357 =cut
2358
2359 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2360
2361 =head2 $c->prepare_uploads
2362
2363 Prepares uploads.
2364
2365 =cut
2366
2367 sub prepare_uploads {
2368     my $c = shift;
2369
2370     $c->engine->prepare_uploads( $c, @_ );
2371 }
2372
2373 =head2 $c->prepare_write
2374
2375 Prepares the output for writing.
2376
2377 =cut
2378
2379 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2380
2381 =head2 $c->request_class
2382
2383 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2384
2385 =head2 $c->response_class
2386
2387 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2388
2389 =head2 $c->read( [$maxlength] )
2390
2391 Reads a chunk of data from the request body. This method is designed to
2392 be used in a while loop, reading C<$maxlength> bytes on every call.
2393 C<$maxlength> defaults to the size of the request if not specified.
2394
2395 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2396 directly.
2397
2398 Warning: If you use read(), Catalyst will not process the body,
2399 so you will not be able to access POST parameters or file uploads via
2400 $c->request.  You must handle all body parsing yourself.
2401
2402 =cut
2403
2404 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2405
2406 =head2 $c->run
2407
2408 Starts the engine.
2409
2410 =cut
2411
2412 sub run { my $c = shift; return $c->engine->run( $c, $c->_finalized_psgi_app, @_ ) }
2413
2414 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2415
2416 Sets an action in a given namespace.
2417
2418 =cut
2419
2420 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2421
2422 =head2 $c->setup_actions($component)
2423
2424 Sets up actions for a component.
2425
2426 =cut
2427
2428 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2429
2430 =head2 $c->setup_components
2431
2432 This method is called internally to set up the application's components.
2433
2434 It finds modules by calling the L<locate_components> method, expands them to
2435 package names with the L<expand_component_module> method, and then installs
2436 each component into the application.
2437
2438 The C<setup_components> config option is passed to both of the above methods.
2439
2440 Installation of each component is performed by the L<setup_component> method,
2441 below.
2442
2443 =cut
2444
2445 sub setup_components {
2446     my $class = shift;
2447
2448     my $config  = $class->config->{ setup_components };
2449
2450     my @comps = $class->locate_components($config);
2451     my %comps = map { $_ => 1 } @comps;
2452
2453     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2454     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2455         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2456     ) if $deprecatedcatalyst_component_names;
2457
2458     for my $component ( @comps ) {
2459
2460         # We pass ignore_loaded here so that overlay files for (e.g.)
2461         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2462         # we know M::P::O found a file on disk so this is safe
2463
2464         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2465     }
2466
2467     for my $component (@comps) {
2468         my $instance = $class->components->{ $component } = $class->setup_component($component);
2469         my @expanded_components = $instance->can('expand_modules')
2470             ? $instance->expand_modules( $component, $config )
2471             : $class->expand_component_module( $component, $config );
2472         for my $component (@expanded_components) {
2473             next if $comps{$component};
2474             $class->components->{ $component } = $class->setup_component($component);
2475         }
2476     }
2477 }
2478
2479 =head2 $c->locate_components( $setup_component_config )
2480
2481 This method is meant to provide a list of component modules that should be
2482 setup for the application.  By default, it will use L<Module::Pluggable>.
2483
2484 Specify a C<setup_components> config option to pass additional options directly
2485 to L<Module::Pluggable>. To add additional search paths, specify a key named
2486 C<search_extra> as an array reference. Items in the array beginning with C<::>
2487 will have the application class name prepended to them.
2488
2489 =cut
2490
2491 sub locate_components {
2492     my $class  = shift;
2493     my $config = shift;
2494
2495     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2496     my $extra   = delete $config->{ search_extra } || [];
2497
2498     push @paths, @$extra;
2499
2500     my $locator = Module::Pluggable::Object->new(
2501         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2502         %$config
2503     );
2504
2505     # XXX think about ditching this sort entirely
2506     my @comps = sort { length $a <=> length $b } $locator->plugins;
2507
2508     return @comps;
2509 }
2510
2511 =head2 $c->expand_component_module( $component, $setup_component_config )
2512
2513 Components found by C<locate_components> will be passed to this method, which
2514 is expected to return a list of component (package) names to be set up.
2515
2516 =cut
2517
2518 sub expand_component_module {
2519     my ($class, $module) = @_;
2520     return Devel::InnerPackage::list_packages( $module );
2521 }
2522
2523 =head2 $c->setup_component
2524
2525 =cut
2526
2527 sub setup_component {
2528     my( $class, $component ) = @_;
2529
2530     unless ( $component->can( 'COMPONENT' ) ) {
2531         return $component;
2532     }
2533
2534     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2535     my $config = $class->config->{ $suffix } || {};
2536     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2537     # methods also pass it. local to avoid pointlessly shitting in config
2538     # for the debug screen, as $component is already the key name.
2539     local $config->{catalyst_component_name} = $component;
2540
2541     my $instance = eval { $component->COMPONENT( $class, $config ); };
2542
2543     if ( my $error = $@ ) {
2544         chomp $error;
2545         Catalyst::Exception->throw(
2546             message => qq/Couldn't instantiate component "$component", "$error"/
2547         );
2548     }
2549
2550     unless (blessed $instance) {
2551         my $metaclass = Moose::Util::find_meta($component);
2552         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2553         my $component_method_from = $method_meta->associated_metaclass->name;
2554         my $value = defined($instance) ? $instance : 'undef';
2555         Catalyst::Exception->throw(
2556             message =>
2557             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2558         );
2559     }
2560     return $instance;
2561 }
2562
2563 =head2 $c->setup_dispatcher
2564
2565 Sets up dispatcher.
2566
2567 =cut
2568
2569 sub setup_dispatcher {
2570     my ( $class, $dispatcher ) = @_;
2571
2572     if ($dispatcher) {
2573         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2574     }
2575
2576     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2577         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2578     }
2579
2580     unless ($dispatcher) {
2581         $dispatcher = $class->dispatcher_class;
2582     }
2583
2584     Class::MOP::load_class($dispatcher);
2585
2586     # dispatcher instance
2587     $class->dispatcher( $dispatcher->new );
2588 }
2589
2590 =head2 $c->setup_engine
2591
2592 Sets up engine.
2593
2594 =cut
2595
2596 sub engine_class {
2597     my $class = shift;
2598     $class->engine_loader->catalyst_engine_class(@_);
2599 }
2600
2601 sub setup_engine {
2602     my ($class, $requested_engine) = @_;
2603
2604     $class->engine_loader(
2605         Catalyst::EngineLoader->new({
2606             application_name => $class,
2607             (defined $requested_engine
2608                  ? (requested_engine => $requested_engine) : ()),
2609         }),
2610     );
2611
2612     my $engine = $class->engine_class;
2613     Class::MOP::load_class($engine);
2614
2615     if ($ENV{MOD_PERL}) {
2616         my $apache = $class->engine_loader->auto;
2617         # FIXME - Immutable
2618         $class->meta->add_method(handler => sub {
2619             my $r = shift;
2620             my $psgi_app = $class->psgi_app;
2621             $apache->call_app($r, $psgi_app);
2622         });
2623     }
2624
2625     $class->engine( $engine->new );
2626
2627     return;
2628 }
2629
2630 sub _finalized_psgi_app {
2631     my ($app) = @_;
2632
2633     unless ($app->_psgi_app) {
2634         my $psgi_app = $app->_setup_psgi_app;
2635         $app->_psgi_app($psgi_app);
2636     }
2637
2638     return $app->_psgi_app;
2639 }
2640
2641 sub _setup_psgi_app {
2642     my ($app) = @_;
2643
2644     for my $home (Path::Class::Dir->new($app->config->{home})) {
2645         my $psgi_file = $home->file(
2646             Catalyst::Utils::appprefix($app) . '.psgi',
2647         );
2648
2649         next unless -e $psgi_file;
2650         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2651
2652         return $psgi_app
2653             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2654
2655         # load_psgi ran a .psgi file doing ->setup_engine('PSGI'). That's what
2656         # .psgi files generated by the old Engine::PSGI do. Those return an app
2657         # coderef calling into MyApp->run, which doesn't work anymore, so we're
2658         # just ignoring it and use the wrapped legacy psgi app
2659         warn <<"EOW";
2660 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2661
2662 Its content has been ignored. Please consult the Catalyst::Upgrading
2663 documentation on how to upgrade from Catalyst::Engine::PSGI.
2664 EOW
2665     }
2666
2667     return $app->_wrapped_legacy_psgi_app($app->psgi_app);
2668 }
2669
2670 # Note - this is for back compatibility. Catalyst should not know or care about
2671 #        how it's deployed. The recommended way of configuring this is now to
2672 #        use the ReverseProxy middleware yourself if you want it in a .psgi
2673 #        file.
2674 sub _wrapped_legacy_psgi_app {
2675     my ($app, $psgi_app) = @_;
2676
2677     $psgi_app = Plack::Middleware::Conditional->wrap(
2678         $psgi_app,
2679         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2680         condition => sub {
2681             my ($env) = @_;
2682             return if $app->config->{ignore_frontend_proxy};
2683             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2684                 || $app->config->{using_frontend_proxy};
2685         },
2686     );
2687
2688     my $server_matches = sub {
2689         my ($re) = @_;
2690         return sub {
2691             my ($env) = @_;
2692             my $server = $env->{SERVER_SOFTWARE};
2693             return unless $server;
2694             return $server =~ $re ? 1 : 0;
2695         };
2696     };
2697
2698     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2699     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2700     # Thanks to Mark Blythe for this fix
2701     #
2702     # Note that this has probably the same effect as
2703     # Plack::Middleware::LighttpdScriptNameFix and we should switch to that if
2704     # we can.
2705     $psgi_app = Plack::Middleware::Conditional->wrap(
2706         $psgi_app,
2707         condition => $server_matches->(qr/lighttpd/),
2708         builder   => sub {
2709             my ($to_wrap) = @_;
2710             return sub {
2711                 my ($env) = @_;
2712                 $env->{PATH_INFO} ||= delete $env->{SCRIPT_NAME};
2713                 return $to_wrap->($env);
2714             };
2715         },
2716     );
2717
2718     $psgi_app = Plack::Middleware::Conditional->wrap(
2719         $psgi_app,
2720         condition => $server_matches->(qr/^nginx/),
2721         builder   => sub {
2722             my ($to_wrap) = @_;
2723             return sub {
2724                 my ($env) = @_;
2725                 my $script_name = $env->{SCRIPT_NAME};
2726                 $env->{PATH_INFO} =~ s/^$script_name//g;
2727                 return $to_wrap->($env);
2728             };
2729         },
2730     );
2731
2732     # we're applying this unconditionally as the middleware itself already makes
2733     # sure it doesn't fuck things up if it's not running under one of the right
2734     # IIS versions
2735     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2736
2737     return $psgi_app;
2738 }
2739
2740 =head2 $c->psgi_app
2741
2742 Returns a PSGI application code reference for the catalyst application
2743 C<$c>. This is the bare application without any middlewares
2744 applied. C<${myapp}.psgi> is not taken into account.
2745
2746 This is what you want to be using to retrieve the PSGI application code
2747 reference of your Catalyst application for use in F<.psgi> files.
2748
2749 =cut
2750
2751 sub psgi_app {
2752     my ($app) = @_;
2753     return $app->engine->build_psgi_app($app);
2754 }
2755
2756 =head2 $c->setup_home
2757
2758 Sets up the home directory.
2759
2760 =cut
2761
2762 sub setup_home {
2763     my ( $class, $home ) = @_;
2764
2765     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2766         $home = $env;
2767     }
2768
2769     $home ||= Catalyst::Utils::home($class);
2770
2771     if ($home) {
2772         #I remember recently being scolded for assigning config values like this
2773         $class->config->{home} ||= $home;
2774         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2775     }
2776 }
2777
2778 =head2 $c->setup_log
2779
2780 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2781 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2782 log to.
2783
2784 This method also installs a C<debug> method that returns a true value into the
2785 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2786 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2787
2788 Note that if the log has already been setup, by either a previous call to
2789 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2790 that this method won't actually set up the log object.
2791
2792 =cut
2793
2794 sub setup_log {
2795     my ( $class, $levels ) = @_;
2796
2797     $levels ||= '';
2798     $levels =~ s/^\s+//;
2799     $levels =~ s/\s+$//;
2800     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2801
2802     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2803     if ( defined $env_debug ) {
2804         $levels{debug} = 1 if $env_debug; # Ugly!
2805         delete($levels{debug}) unless $env_debug;
2806     }
2807
2808     unless ( $class->log ) {
2809         $class->log( Catalyst::Log->new(keys %levels) );
2810     }
2811
2812     if ( $levels{debug} ) {
2813         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2814         $class->log->debug('Debug messages enabled');
2815     }
2816 }
2817
2818 =head2 $c->setup_plugins
2819
2820 Sets up plugins.
2821
2822 =cut
2823
2824 =head2 $c->setup_stats
2825
2826 Sets up timing statistics class.
2827
2828 =cut
2829
2830 sub setup_stats {
2831     my ( $class, $stats ) = @_;
2832
2833     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2834
2835     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2836     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2837         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2838         $class->log->debug('Statistics enabled');
2839     }
2840 }
2841
2842
2843 =head2 $c->registered_plugins
2844
2845 Returns a sorted list of the plugins which have either been stated in the
2846 import list or which have been added via C<< MyApp->plugin(@args); >>.
2847
2848 If passed a given plugin name, it will report a boolean value indicating
2849 whether or not that plugin is loaded.  A fully qualified name is required if
2850 the plugin name does not begin with C<Catalyst::Plugin::>.
2851
2852  if ($c->registered_plugins('Some::Plugin')) {
2853      ...
2854  }
2855
2856 =cut
2857
2858 {
2859
2860     sub registered_plugins {
2861         my $proto = shift;
2862         return sort keys %{ $proto->_plugins } unless @_;
2863         my $plugin = shift;
2864         return 1 if exists $proto->_plugins->{$plugin};
2865         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2866     }
2867
2868     sub _register_plugin {
2869         my ( $proto, $plugin, $instant ) = @_;
2870         my $class = ref $proto || $proto;
2871
2872         Class::MOP::load_class( $plugin );
2873         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2874             if $plugin->isa( 'Catalyst::Component' );
2875         $proto->_plugins->{$plugin} = 1;
2876         unless ($instant) {
2877             my $meta = Class::MOP::get_metaclass_by_name($class);
2878             $meta->superclasses($plugin, $meta->superclasses);
2879         }
2880         return $class;
2881     }
2882
2883     sub setup_plugins {
2884         my ( $class, $plugins ) = @_;
2885
2886         $class->_plugins( {} ) unless $class->_plugins;
2887         $plugins = Data::OptList::mkopt($plugins || []);
2888
2889         my @plugins = map {
2890             [ Catalyst::Utils::resolve_namespace(
2891                   $class . '::Plugin',
2892                   'Catalyst::Plugin', $_->[0]
2893               ),
2894               $_->[1],
2895             ]
2896          } @{ $plugins };
2897
2898         for my $plugin ( reverse @plugins ) {
2899             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2900             my $meta = find_meta($plugin->[0]);
2901             next if $meta && $meta->isa('Moose::Meta::Role');
2902
2903             $class->_register_plugin($plugin->[0]);
2904         }
2905
2906         my @roles =
2907             map  { $_->[0]->name, $_->[1] }
2908             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2909             map  { [find_meta($_->[0]), $_->[1]] }
2910             @plugins;
2911
2912         Moose::Util::apply_all_roles(
2913             $class => @roles
2914         ) if @roles;
2915     }
2916 }
2917
2918 =head2 $c->stack
2919
2920 Returns an arrayref of the internal execution stack (actions that are
2921 currently executing).
2922
2923 =head2 $c->stats
2924
2925 Returns the current timing statistics object. By default Catalyst uses
2926 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2927 L<< stats_class|/"$c->stats_class" >>.
2928
2929 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2930 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2931 profile explicitly, although MyApp.pm still won't profile nor output anything
2932 by itself.
2933
2934 =head2 $c->stats_class
2935
2936 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2937
2938 =head2 $c->use_stats
2939
2940 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2941
2942 Note that this is a static method, not an accessor and should be overridden
2943 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2944
2945 =cut
2946
2947 sub use_stats { 0 }
2948
2949
2950 =head2 $c->write( $data )
2951
2952 Writes $data to the output stream. When using this method directly, you
2953 will need to manually set the C<Content-Length> header to the length of
2954 your output data, if known.
2955
2956 =cut
2957
2958 sub write {
2959     my $c = shift;
2960
2961     # Finalize headers if someone manually writes output
2962     $c->finalize_headers;
2963
2964     return $c->engine->write( $c, @_ );
2965 }
2966
2967 =head2 version
2968
2969 Returns the Catalyst version number. Mostly useful for "powered by"
2970 messages in template systems.
2971
2972 =cut
2973
2974 sub version { return $Catalyst::VERSION }
2975
2976 =head1 CONFIGURATION
2977
2978 There are a number of 'base' config variables which can be set:
2979
2980 =over
2981
2982 =item *
2983
2984 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2985
2986 =item *
2987
2988 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2989
2990 =item *
2991
2992 C<disable_component_resolution_regex_fallback> - Turns
2993 off the deprecated component resolution functionality so
2994 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2995 are called then regex search will not be attempted on string values and
2996 instead C<undef> will be returned.
2997
2998 =item *
2999
3000 C<home> - The application home directory. In an uninstalled application,
3001 this is the top level application directory. In an installed application,
3002 this will be the directory containing C<< MyApp.pm >>.
3003
3004 =item *
3005
3006 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3007
3008 =item *
3009
3010 C<name> - The name of the application in debug messages and the debug and
3011 welcome screens
3012
3013 =item *
3014
3015 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3016 until it is accessed. This allows you to (for example) check authentication (and reject
3017 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
3018
3019 =item *
3020
3021 C<root> - The root directory for templates. Usually this is just a
3022 subdirectory of the home directory, but you can set it to change the
3023 templates to a different directory.
3024
3025 =item *
3026
3027 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3028 namespaces from which components will be loaded (and constructed and stored in
3029 C<< $c->components >>).
3030
3031 =item *
3032
3033 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3034 to be shown in hit debug tables in the test server.
3035
3036 =item *
3037
3038 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3039 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
3040 for more information.
3041
3042 =item *
3043
3044 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3045
3046 =back
3047
3048 =head1 INTERNAL ACTIONS
3049
3050 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3051 C<_ACTION>, and C<_END>. These are by default not shown in the private
3052 action table, but you can make them visible with a config parameter.
3053
3054     MyApp->config(show_internal_actions => 1);
3055
3056 =head1 ON-DEMAND PARSER
3057
3058 The request body is usually parsed at the beginning of a request,
3059 but if you want to handle input yourself, you can enable on-demand
3060 parsing with a config parameter.
3061
3062     MyApp->config(parse_on_demand => 1);
3063
3064 =head1 PROXY SUPPORT
3065
3066 Many production servers operate using the common double-server approach,
3067 with a lightweight frontend web server passing requests to a larger
3068 backend server. An application running on the backend server must deal
3069 with two problems: the remote user always appears to be C<127.0.0.1> and
3070 the server's hostname will appear to be C<localhost> regardless of the
3071 virtual host that the user connected through.
3072
3073 Catalyst will automatically detect this situation when you are running
3074 the frontend and backend servers on the same machine. The following
3075 changes are made to the request.
3076
3077     $c->req->address is set to the user's real IP address, as read from
3078     the HTTP X-Forwarded-For header.
3079
3080     The host value for $c->req->base and $c->req->uri is set to the real
3081     host, as read from the HTTP X-Forwarded-Host header.
3082
3083 Additionally, you may be running your backend application on an insecure
3084 connection (port 80) while your frontend proxy is running under SSL.  If there
3085 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3086 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3087 be created properly.
3088
3089 In the case of passing in:
3090
3091     X-Forwarded-Port: 443
3092
3093 All calls to C<uri_for> will result in an https link, as is expected.
3094
3095 Obviously, your web server must support these headers for this to work.
3096
3097 In a more complex server farm environment where you may have your
3098 frontend proxy server(s) on different machines, you will need to set a
3099 configuration option to tell Catalyst to read the proxied data from the
3100 headers.
3101
3102     MyApp->config(using_frontend_proxy => 1);
3103
3104 If you do not wish to use the proxy support at all, you may set:
3105
3106     MyApp->config(ignore_frontend_proxy => 1);
3107
3108 =head1 THREAD SAFETY
3109
3110 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3111 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3112 believe the Catalyst core to be thread-safe.
3113
3114 If you plan to operate in a threaded environment, remember that all other
3115 modules you are using must also be thread-safe. Some modules, most notably
3116 L<DBD::SQLite>, are not thread-safe.
3117
3118 =head1 SUPPORT
3119
3120 IRC:
3121
3122     Join #catalyst on irc.perl.org.
3123
3124 Mailing Lists:
3125
3126     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3127     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3128
3129 Web:
3130
3131     http://catalyst.perl.org
3132
3133 Wiki:
3134
3135     http://dev.catalyst.perl.org
3136
3137 =head1 SEE ALSO
3138
3139 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3140
3141 =head2 L<Catalyst::Manual> - The Catalyst Manual
3142
3143 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3144
3145 =head2 L<Catalyst::Engine> - Core engine
3146
3147 =head2 L<Catalyst::Log> - Log class.
3148
3149 =head2 L<Catalyst::Request> - Request object
3150
3151 =head2 L<Catalyst::Response> - Response object
3152
3153 =head2 L<Catalyst::Test> - The test suite.
3154
3155 =head1 PROJECT FOUNDER
3156
3157 sri: Sebastian Riedel <sri@cpan.org>
3158
3159 =head1 CONTRIBUTORS
3160
3161 abw: Andy Wardley
3162
3163 acme: Leon Brocard <leon@astray.com>
3164
3165 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3166
3167 Andrew Bramble
3168
3169 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3170
3171 Andrew Ruthven
3172
3173 andyg: Andy Grundman <andy@hybridized.org>
3174
3175 audreyt: Audrey Tang
3176
3177 bricas: Brian Cassidy <bricas@cpan.org>
3178
3179 Caelum: Rafael Kitover <rkitover@io.com>
3180
3181 chansen: Christian Hansen
3182
3183 chicks: Christopher Hicks
3184
3185 Chisel Wright C<pause@herlpacker.co.uk>
3186
3187 Danijel Milicevic C<me@danijel.de>
3188
3189 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3190
3191 David Naughton, C<naughton@umn.edu>
3192
3193 David E. Wheeler
3194
3195 dhoss: Devin Austin <dhoss@cpan.org>
3196
3197 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3198
3199 Drew Taylor
3200
3201 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3202
3203 esskar: Sascha Kiefer
3204
3205 fireartist: Carl Franks <cfranks@cpan.org>
3206
3207 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3208
3209 gabb: Danijel Milicevic
3210
3211 Gary Ashton Jones
3212
3213 Gavin Henry C<ghenry@perl.me.uk>
3214
3215 Geoff Richards
3216
3217 groditi: Guillermo Roditi <groditi@gmail.com>
3218
3219 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3220
3221 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3222
3223 jcamacho: Juan Camacho
3224
3225 jester: Jesse Sheidlower C<jester@panix.com>
3226
3227 jhannah: Jay Hannah <jay@jays.net>
3228
3229 Jody Belka
3230
3231 Johan Lindstrom
3232
3233 jon: Jon Schutz <jjschutz@cpan.org>
3234
3235 Jonathan Rockway C<< <jrockway@cpan.org> >>
3236
3237 Kieren Diment C<kd@totaldatasolution.com>
3238
3239 konobi: Scott McWhirter <konobi@cpan.org>
3240
3241 marcus: Marcus Ramberg <mramberg@cpan.org>
3242
3243 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3244
3245 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3246
3247 mugwump: Sam Vilain
3248
3249 naughton: David Naughton
3250
3251 ningu: David Kamholz <dkamholz@cpan.org>
3252
3253 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3254
3255 numa: Dan Sully <daniel@cpan.org>
3256
3257 obra: Jesse Vincent
3258
3259 Octavian Rasnita
3260
3261 omega: Andreas Marienborg
3262
3263 Oleg Kostyuk <cub.uanic@gmail.com>
3264
3265 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3266
3267 rafl: Florian Ragwitz <rafl@debian.org>
3268
3269 random: Roland Lammel <lammel@cpan.org>
3270
3271 Robert Sedlacek C<< <rs@474.at> >>
3272
3273 SpiceMan: Marcel Montes
3274
3275 sky: Arthur Bergman
3276
3277 szbalint: Balint Szilakszi <szbalint@cpan.org>
3278
3279 t0m: Tomas Doran <bobtfish@bobtfish.net>
3280
3281 Ulf Edvinsson
3282
3283 Viljo Marrandi C<vilts@yahoo.com>
3284
3285 Will Hawes C<info@whawes.co.uk>
3286
3287 willert: Sebastian Willert <willert@cpan.org>
3288
3289 wreis: Wallace Reis <wallace@reis.org.br>
3290
3291 Yuval Kogman, C<nothingmuch@woobling.org>
3292
3293 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3294
3295 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3296
3297 =head1 LICENSE
3298
3299 This library is free software. You can redistribute it and/or modify it under
3300 the same terms as Perl itself.
3301
3302 =cut
3303
3304 no Moose;
3305
3306 __PACKAGE__->meta->make_immutable;
3307
3308 1;