lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use File::stat;
  14 use NEXT;
  15 use Text::SimpleTable;
  16 use Path::Class::Dir;
  17 use Path::Class::File;
  18 use Time::HiRes qw/gettimeofday tv_interval/;
  19 use URI;
  20 use Scalar::Util qw/weaken blessed/;
  21 use Tree::Simple qw/use_weak_refs/;
  22 use Tree::Simple::Visitor::FindByUID;
  23 use attributes;
  24 use utf8;
  25 use Carp qw/croak/;
  26
  27 BEGIN { require 5.008001; }
  28
  29 __PACKAGE__->mk_accessors(
  30     qw/counter request response state action stack namespace stats/
  31 );
  32
  33 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  34
  35 sub depth { scalar @{ shift->stack || [] }; }
  36
  37 # Laziness++
  38 *comp = \&component;
  39 *req  = \&request;
  40 *res  = \&response;
  41
  42 # For backwards compatibility
  43 *finalize_output = \&finalize_body;
  44
  45 # For statistics
  46 our $COUNT     = 1;
  47 our $START     = time;
  48 our $RECURSION = 1000;
  49 our $DETACH    = "catalyst_detach\n";
  50
  51 require Module::Pluggable::Fast;
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class setup_finished/;
  56
  57 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  58 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  59 __PACKAGE__->request_class('Catalyst::Request');
  60 __PACKAGE__->response_class('Catalyst::Response');
  61
  62 our $VERSION = '5.6902';
  63
  64 sub import {
  65     my ( $class, @arguments ) = @_;
  66
  67     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  68     # callers @ISA.
  69     return unless $class eq 'Catalyst';
  70
  71     my $caller = caller(0);
  72
  73     unless ( $caller->isa('Catalyst') ) {
  74         no strict 'refs';
  75         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  76     }
  77
  78     $caller->arguments( [@arguments] );
  79     $caller->setup_home;
  80 }
  81
  82 =head1 NAME
  83
  84 Catalyst - The Elegant MVC Web Application Framework
  85
  86 =head1 SYNOPSIS
  87
  88     # use the helper to create a new application
  89     catalyst.pl MyApp
  90
  91     # add models, views, controllers
  92     script/myapp_create.pl model Database DBIC::SchemaLoader dbi:SQLite:/path/to/db
  93     script/myapp_create.pl view TT TT
  94     script/myapp_create.pl controller Search
  95
  96     # built in testserver -- use -r to restart automatically on changes
  97     script/myapp_server.pl
  98
  99     # command line testing interface
 100     script/myapp_test.pl /yada
 101
 102     ### in lib/MyApp.pm
 103     use Catalyst qw/-Debug/; # include plugins here as well
 104
 105         ### In lib/MyApp/Controller/Root.pm (autocreated)
 106     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 107         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 108         $c->stash->{template} = 'foo.tt'; # set the template
 109         # lookup something from db -- stash vars are passed to TT
 110         $c->stash->{data} =
 111           $c->model('Database::Foo')->search( { country => $args[0] } );
 112         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 113             $c->forward( 'bar' ); # process another action
 114             # do something else after forward returns
 115         }
 116     }
 117
 118     # The foo.tt TT template can use the stash data from the database
 119     [% WHILE (item = data.next) %]
 120         [% item.foo %]
 121     [% END %]
 122
 123     # called for /bar/of/soap, /bar/of/soap/10, etc.
 124     sub bar : Path('/bar/of/soap') { ... }
 125
 126     # called for all actions, from the top-most controller downwards
 127     sub auto : Private {
 128         my ( $self, $c ) = @_;
 129         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 130             $c->res->redirect( '/login' ); # require login
 131             return 0; # abort request and go immediately to end()
 132         }
 133         return 1; # success; carry on to next action
 134     }
 135
 136     # called after all actions are finished
 137     sub end : Private {
 138         my ( $self, $c ) = @_;
 139         if ( scalar @{ $c->error } ) { ... } # handle errors
 140         return if $c->res->body; # already have a response
 141         $c->forward( 'MyApp::View::TT' ); # render template
 142     }
 143
 144     ### in MyApp/Controller/Foo.pm
 145     # called for /foo/bar
 146     sub bar : Local { ... }
 147
 148     # called for /blargle
 149     sub blargle : Global { ... }
 150
 151     # an index action matches /foo, but not /foo/1, etc.
 152     sub index : Private { ... }
 153
 154     ### in MyApp/Controller/Foo/Bar.pm
 155     # called for /foo/bar/baz
 156     sub baz : Local { ... }
 157
 158     # first Root auto is called, then Foo auto, then this
 159     sub auto : Private { ... }
 160
 161     # powerful regular expression paths are also possible
 162     sub details : Regex('^product/(\w+)/details$') {
 163         my ( $self, $c ) = @_;
 164         # extract the (\w+) from the URI
 165         my $product = $c->req->captures->[0];
 166     }
 167
 168 See L<Catalyst::Manual::Intro> for additional information.
 169
 170 =head1 DESCRIPTION
 171
 172 Catalyst is a modern framework for making web applications without the pain usually associated with this process. This document is a reference to the main Catalyst application. If you are a new user, we suggest you start with L<Catalyst::Manual::Tutorial> or  L<Catalyst::Manual::Intro>
 173
 174 See L<Catalyst::Manual> for more documentation.
 175
 176 Catalyst plugins can be loaded by naming them as arguments to the "use
 177 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 178 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 179 C<My::Module>.
 180
 181     use Catalyst qw/My::Module/;
 182
 183 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 184 fully qualify the name by using a unary plus:
 185
 186     use Catalyst qw/
 187         My::Module
 188         +Fully::Qualified::Plugin::Name
 189     /;
 190
 191 Special flags like C<-Debug> and C<-Engine> can also be specified as
 192 arguments when Catalyst is loaded:
 193
 194     use Catalyst qw/-Debug My::Module/;
 195
 196 The position of plugins and flags in the chain is important, because
 197 they are loaded in exactly the order in which they appear.
 198
 199 The following flags are supported:
 200
 201 =head2 -Debug
 202
 203 Enables debug output. You can also force this setting from the system
 204 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment settings
 205 override the app, with <MYAPP>_DEBUG having highest priority.
 206
 207 =head2 -Engine
 208
 209 Forces Catalyst to use a specific engine. Omit the
 210 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 211
 212     use Catalyst qw/-Engine=CGI/;
 213
 214 =head2 -Home
 215
 216 Forces Catalyst to use a specific home directory, e.g.:
 217
 218     use Catalyst qw[-Home=/usr/sri];
 219
 220 =head2 -Log
 221
 222 Specifies log level.
 223
 224 =head1 METHODS
 225
 226 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 227
 228 =head2 $c->action
 229
 230 Returns a L<Catalyst::Action> object for the current action, which
 231 stringifies to the action name. See L<Catalyst::Action>.
 232
 233 =head2 $c->namespace
 234
 235 Returns the namespace of the current action, i.e., the uri prefix
 236 corresponding to the controller of the current action. For example:
 237
 238     # in Controller::Foo::Bar
 239     $c->namespace; # returns 'foo/bar';
 240
 241 =head2 $c->request
 242
 243 =head2 $c->req
 244
 245 Returns the current L<Catalyst::Request> object. See
 246 L<Catalyst::Request>.
 247
 248 =head2 REQUEST FLOW HANDLING
 249
 250 =head2 $c->forward( $action [, \@arguments ] )
 251
 252 =head2 $c->forward( $class, $method, [, \@arguments ] )
 253
 254 Forwards processing to another action, by it's private name. If you give a
 255 class name but no method, C<process()> is called. You may also optionally
 256 pass arguments in an arrayref. The action will receive the arguments in
 257 C<@_> and C<$c-E<gt>req-E<gt>args>. Upon returning from the function,
 258 C<$c-E<gt>req-E<gt>args> will be restored to the previous values.
 259
 260 Any data C<return>ed from the action forwarded to, will be returned by the
 261 call to forward.
 262
 263     my $foodata = $c->forward('/foo');
 264     $c->forward('index');
 265     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 266     $c->forward('MyApp::View::TT');
 267
 268 Note that forward implies an C<<eval { }>> around the call (well, actually
 269 C<execute> does), thus de-fatalizing all 'dies' within the called action. If
 270 you want C<die> to propagate you need to do something like:
 271
 272     $c->forward('foo');
 273     die $c->error if $c->error;
 274
 275 Or make sure to always return true values from your actions and write your code
 276 like this:
 277
 278     $c->forward('foo') || return;
 279
 280 =cut
 281
 282 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 283
 284 =head2 $c->detach( $action [, \@arguments ] )
 285
 286 =head2 $c->detach( $class, $method, [, \@arguments ] )
 287
 288 The same as C<forward>, but doesn't return to the previous action when
 289 processing is finished.
 290
 291 =cut
 292
 293 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 294
 295 =head2 $c->response
 296
 297 =head2 $c->res
 298
 299 Returns the current L<Catalyst::Response> object.
 300
 301 =head2 $c->stash
 302
 303 Returns a hashref to the stash, which may be used to store data and pass
 304 it between components during a request. You can also set hash keys by
 305 passing arguments. The stash is automatically sent to the view. The
 306 stash is cleared at the end of a request; it cannot be used for
 307 persistent storage.
 308
 309     $c->stash->{foo} = $bar;
 310     $c->stash( { moose => 'majestic', qux => 0 } );
 311     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 312
 313     # stash is automatically passed to the view for use in a template
 314     $c->forward( 'MyApp::V::TT' );
 315
 316 =cut
 317
 318 sub stash {
 319     my $c = shift;
 320     if (@_) {
 321         my $stash = @_ > 1 ? {@_} : $_[0];
 322         croak('stash takes a hash or hashref') unless ref $stash;
 323         foreach my $key ( keys %$stash ) {
 324             $c->{stash}->{$key} = $stash->{$key};
 325         }
 326     }
 327     return $c->{stash};
 328 }
 329
 330 =head2 $c->error
 331
 332 =head2 $c->error($error, ...)
 333
 334 =head2 $c->error($arrayref)
 335
 336 Returns an arrayref containing error messages.  If Catalyst encounters an
 337 error while processing a request, it stores the error in $c->error.  This
 338 method should not be used to store non-fatal error messages.
 339
 340     my @error = @{ $c->error };
 341
 342 Add a new error.
 343
 344     $c->error('Something bad happened');
 345
 346 =cut
 347
 348 sub error {
 349     my $c = shift;
 350     if ( $_[0] ) {
 351         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 352         croak @$error unless ref $c;
 353         push @{ $c->{error} }, @$error;
 354     }
 355     elsif ( defined $_[0] ) { $c->{error} = undef }
 356     return $c->{error} || [];
 357 }
 358
 359
 360 =head2 $c->state
 361
 362 Contains the return value of the last executed action.
 363
 364 =head2 $c->clear_errors
 365
 366 Clear errors.  You probably don't want to clear the errors unless you are
 367 implementing a custom error screen.
 368
 369 This is equivalent to running
 370
 371     $c->error(0);
 372
 373 =cut
 374
 375 sub clear_errors {
 376     my $c = shift;
 377     $c->error(0);
 378 }
 379
 380
 381
 382
 383 # search via regex
 384 sub _comp_search {
 385     my ( $c, @names ) = @_;
 386
 387     foreach my $name (@names) {
 388         foreach my $component ( keys %{ $c->components } ) {
 389             return $c->components->{$component} if $component =~ /$name/i;
 390         }
 391     }
 392
 393     return undef;
 394 }
 395
 396 # try explicit component names
 397 sub _comp_explicit {
 398     my ( $c, @names ) = @_;
 399
 400     foreach my $try (@names) {
 401         return $c->components->{$try} if ( exists $c->components->{$try} );
 402     }
 403
 404     return undef;
 405 }
 406
 407 # like component, but try just these prefixes before regex searching,
 408 #  and do not try to return "sort keys %{ $c->components }"
 409 sub _comp_prefixes {
 410     my ( $c, $name, @prefixes ) = @_;
 411
 412     my $appclass = ref $c || $c;
 413
 414     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 415
 416     my $comp = $c->_comp_explicit(@names);
 417     return $comp if defined($comp);
 418     $comp = $c->_comp_search($name);
 419     return $comp;
 420 }
 421
 422 # Find possible names for a prefix
 423
 424 sub _comp_names {
 425     my ( $c, @prefixes ) = @_;
 426
 427     my $appclass = ref $c || $c;
 428
 429     my @pre = map { "${appclass}::${_}::" } @prefixes;
 430
 431     my @names;
 432
 433     COMPONENT: foreach my $comp ($c->component) {
 434         foreach my $p (@pre) {
 435             if ($comp =~ s/^$p//) {
 436                 push(@names, $comp);
 437                 next COMPONENT;
 438             }
 439         }
 440     }
 441
 442     return @names;
 443 }
 444
 445 # Return a component if only one matches.
 446 sub _comp_singular {
 447     my ( $c, @prefixes ) = @_;
 448
 449     my $appclass = ref $c || $c;
 450
 451     my ( $comp, $rest ) =
 452       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 453     return $comp unless $rest;
 454 }
 455
 456 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 457 sub _filter_component {
 458     my ( $c, $comp, @args ) = @_;
 459     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 460         return $comp->ACCEPT_CONTEXT( $c, @args );
 461     }
 462     else { return $comp }
 463 }
 464
 465 =head2 COMPONENT ACCESSORS
 466
 467 =head2 $c->controller($name)
 468
 469 Gets a L<Catalyst::Controller> instance by name.
 470
 471     $c->controller('Foo')->do_stuff;
 472
 473 If name is omitted, will return the controller for the dispatched action.
 474
 475 =cut
 476
 477 sub controller {
 478     my ( $c, $name, @args ) = @_;
 479     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 480         @args )
 481       if ($name);
 482     return $c->component( $c->action->class );
 483 }
 484
 485 =head2 $c->model($name)
 486
 487 Gets a L<Catalyst::Model> instance by name.
 488
 489     $c->model('Foo')->do_stuff;
 490
 491 If the name is omitted, it will look for a config setting 'default_model',
 492 or check if there is only one view, and return it if that's the case.
 493
 494 =cut
 495
 496 sub model {
 497     my ( $c, $name, @args ) = @_;
 498     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 499         @args )
 500       if $name;
 501     return $c->component( $c->config->{default_model} )
 502       if $c->config->{default_model};
 503     return $c->_filter_component( $c->_comp_singular(qw/Model M/), @args );
 504
 505 }
 506
 507 =head2 $c->controllers
 508
 509 Returns the available names which can be passed to $c->controller
 510
 511 =cut
 512
 513 sub controllers {
 514     my ( $c ) = @_;
 515     return $c->_comp_names(qw/Controller C/);
 516 }
 517
 518
 519 =head2 $c->view($name)
 520
 521 Gets a L<Catalyst::View> instance by name.
 522
 523     $c->view('Foo')->do_stuff;
 524
 525 If the name is omitted, it will look for a config setting 'default_view',
 526 or check if there is only one view, and forward to it if that's the case.
 527
 528 =cut
 529
 530 sub view {
 531     my ( $c, $name, @args ) = @_;
 532     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 533         @args )
 534       if $name;
 535     return $c->component( $c->config->{default_view} )
 536       if $c->config->{default_view};
 537     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 538 }
 539
 540 =head2 $c->models
 541
 542 Returns the available names which can be passed to $c->model
 543
 544 =cut
 545
 546 sub models {
 547     my ( $c ) = @_;
 548     return $c->_comp_names(qw/Model M/);
 549 }
 550
 551
 552 =head2 $c->views
 553
 554 Returns the available names which can be passed to $c->view
 555
 556 =cut
 557
 558 sub views {
 559     my ( $c ) = @_;
 560     return $c->_comp_names(qw/View V/);
 561 }
 562
 563 =head2 $c->comp($name)
 564
 565 =head2 $c->component($name)
 566
 567 Gets a component object by name. This method is no longer recommended,
 568 unless you want to get a specific component by full
 569 class. C<$c-E<gt>controller>, C<$c-E<gt>model>, and C<$c-E<gt>view>
 570 should be used instead.
 571
 572 =cut
 573
 574 sub component {
 575     my $c = shift;
 576
 577     if (@_) {
 578
 579         my $name = shift;
 580
 581         my $appclass = ref $c || $c;
 582
 583         my @names = (
 584             $name, "${appclass}::${name}",
 585             map { "${appclass}::${_}::${name}" }
 586               qw/Model M Controller C View V/
 587         );
 588
 589         my $comp = $c->_comp_explicit(@names);
 590         return $c->_filter_component( $comp, @_ ) if defined($comp);
 591
 592         $comp = $c->_comp_search($name);
 593         return $c->_filter_component( $comp, @_ ) if defined($comp);
 594     }
 595
 596     return sort keys %{ $c->components };
 597 }
 598
 599
 600
 601 =head2 CLASS DATA AND HELPER CLASSES
 602
 603 =head2 $c->config
 604
 605 Returns or takes a hashref containing the application's configuration.
 606
 607     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 608
 609 You can also use a L<YAML> config file like myapp.yml in your
 610 applications home directory.
 611
 612     ---
 613     db: dsn:SQLite:foo.db
 614
 615
 616 =cut
 617
 618 sub config {
 619     my $c = shift;
 620
 621     $c->log->warn("Setting config after setup has been run is not a good idea.")
 622       if ( @_ and $c->setup_finished );
 623
 624     $c->NEXT::config(@_);
 625 }
 626
 627 =head2 $c->log
 628
 629 Returns the logging object instance. Unless it is already set, Catalyst sets
 630 this up with a L<Catalyst::Log> object. To use your own log class, set the
 631 logger with the C<< __PACKAGE__->log >> method prior to calling
 632 C<< __PACKAGE__->setup >>.
 633
 634  __PACKAGE__->log( MyLogger->new );
 635  __PACKAGE__->setup;
 636
 637 And later:
 638
 639     $c->log->info( 'Now logging with my own logger!' );
 640
 641 Your log class should implement the methods described in the
 642 L<Catalyst::Log> man page.
 643
 644
 645 =head2 $c->debug
 646
 647 Overload to enable debug messages (same as -Debug option).
 648
 649 Note that this is a static method, not an accessor and should be overloaded
 650 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 651
 652 =cut
 653
 654 sub debug { 0 }
 655
 656 =head2 $c->dispatcher
 657
 658 Returns the dispatcher instance. Stringifies to class name. See
 659 L<Catalyst::Dispatcher>.
 660
 661 =head2 $c->engine
 662
 663 Returns the engine instance. Stringifies to the class name. See
 664 L<Catalyst::Engine>.
 665
 666
 667 =head2 UTILITY METHODS
 668
 669 =head2 $c->path_to(@path)
 670
 671 Merges C<@path> with C<$c-E<gt>config-E<gt>{home}> and returns a
 672 L<Path::Class> object.
 673
 674 For example:
 675
 676     $c->path_to( 'db', 'sqlite.db' );
 677
 678 =cut
 679
 680 sub path_to {
 681     my ( $c, @path ) = @_;
 682     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 683     if ( -d $path ) { return $path }
 684     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 685 }
 686
 687 =head2 $c->plugin( $name, $class, @args )
 688
 689 Helper method for plugins. It creates a classdata accessor/mutator and
 690 loads and instantiates the given class.
 691
 692     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 693
 694     $c->prototype->define_javascript_functions;
 695
 696 =cut
 697
 698 sub plugin {
 699     my ( $class, $name, $plugin, @args ) = @_;
 700     $class->_register_plugin( $plugin, 1 );
 701
 702     eval { $plugin->import };
 703     $class->mk_classdata($name);
 704     my $obj;
 705     eval { $obj = $plugin->new(@args) };
 706
 707     if ($@) {
 708         Catalyst::Exception->throw( message =>
 709               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 710     }
 711
 712     $class->$name($obj);
 713     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 714       if $class->debug;
 715 }
 716
 717 =head2 MyApp->setup
 718
 719 Initializes the dispatcher and engine, loads any plugins, and loads the
 720 model, view, and controller components. You may also specify an array
 721 of plugins to load here, if you choose to not load them in the C<use
 722 Catalyst> line.
 723
 724     MyApp->setup;
 725     MyApp->setup( qw/-Debug/ );
 726
 727 =cut
 728
 729 sub setup {
 730     my ( $class, @arguments ) = @_;
 731
 732     $class->log->warn("Running setup twice is not a good idea.")
 733       if ( $class->setup_finished );
 734
 735     unless ( $class->isa('Catalyst') ) {
 736
 737         Catalyst::Exception->throw(
 738             message => qq/'$class' does not inherit from Catalyst/ );
 739     }
 740
 741     if ( $class->arguments ) {
 742         @arguments = ( @arguments, @{ $class->arguments } );
 743     }
 744
 745     # Process options
 746     my $flags = {};
 747
 748     foreach (@arguments) {
 749
 750         if (/^-Debug$/) {
 751             $flags->{log} =
 752               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 753         }
 754         elsif (/^-(\w+)=?(.*)$/) {
 755             $flags->{ lc $1 } = $2;
 756         }
 757         else {
 758             push @{ $flags->{plugins} }, $_;
 759         }
 760     }
 761
 762     $class->setup_home( delete $flags->{home} );
 763
 764     $class->setup_log( delete $flags->{log} );
 765     $class->setup_plugins( delete $flags->{plugins} );
 766     $class->setup_dispatcher( delete $flags->{dispatcher} );
 767     $class->setup_engine( delete $flags->{engine} );
 768
 769     for my $flag ( sort keys %{$flags} ) {
 770
 771         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 772             &$code( $class, delete $flags->{$flag} );
 773         }
 774         else {
 775             $class->log->warn(qq/Unknown flag "$flag"/);
 776         }
 777     }
 778
 779     $class->log->warn(
 780         <<"EOF") if ( $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::CATALYST_SCRIPT_GEN ) );
 781 You are running an old script!
 782
 783   Please update by running (this will overwrite existing files):
 784     catalyst.pl -force -scripts $class
 785
 786   or (this will not overwrite existing files):
 787     catalyst.pl -scripts $class
 788 EOF
 789
 790     if ( $class->debug ) {
 791
 792         my @plugins = ();
 793
 794         {
 795             no strict 'refs';
 796             @plugins =
 797               map { $_ . ' ' . ( $_->VERSION || '' ) }
 798               grep { /^Catalyst::Plugin/ } @{"$class\::ISA"};
 799         }
 800
 801         if (@plugins) {
 802             my $t = Text::SimpleTable->new(74);
 803             $t->row($_) for @plugins;
 804             $class->log->debug( "Loaded plugins:\n" . $t->draw );
 805         }
 806
 807         my $dispatcher = $class->dispatcher;
 808         my $engine     = $class->engine;
 809         my $home       = $class->config->{home};
 810
 811         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 812         $class->log->debug(qq/Loaded engine "$engine"/);
 813
 814         $home
 815           ? ( -d $home )
 816           ? $class->log->debug(qq/Found home "$home"/)
 817           : $class->log->debug(qq/Home "$home" doesn't exist/)
 818           : $class->log->debug(q/Couldn't find home/);
 819     }
 820
 821     # Call plugins setup
 822     {
 823         no warnings qw/redefine/;
 824         local *setup = sub { };
 825         $class->setup;
 826     }
 827
 828     # Initialize our data structure
 829     $class->components( {} );
 830
 831     $class->setup_components;
 832
 833     if ( $class->debug ) {
 834         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 835         for my $comp ( sort keys %{ $class->components } ) {
 836             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 837             $t->row( $comp, $type );
 838         }
 839         $class->log->debug( "Loaded components:\n" . $t->draw )
 840           if ( keys %{ $class->components } );
 841     }
 842
 843     # Add our self to components, since we are also a component
 844     $class->components->{$class} = $class;
 845
 846     $class->setup_actions;
 847
 848     if ( $class->debug ) {
 849         my $name = $class->config->{name} || 'Application';
 850         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 851     }
 852     $class->log->_flush() if $class->log->can('_flush');
 853
 854     $class->setup_finished(1);
 855 }
 856
 857 =head2 $c->uri_for( $path, @args?, \%query_values? )
 858
 859 Merges path with C<$c-E<gt>request-E<gt>base> for absolute uri's and
 860 with C<$c-E<gt>namespace> for relative uri's, then returns a
 861 normalized L<URI> object. If any args are passed, they are added at the
 862 end of the path.  If the last argument to uri_for is a hash reference,
 863 it is assumed to contain GET parameter key/value pairs, which will be
 864 appended to the URI in standard fashion.
 865
 866 =cut
 867
 868 sub uri_for {
 869     my ( $c, $path, @args ) = @_;
 870     my $base     = $c->request->base->clone;
 871     my $basepath = $base->path;
 872     $basepath =~ s/\/$//;
 873     $basepath .= '/';
 874     my $namespace = $c->namespace || '';
 875
 876     # massage namespace, empty if absolute path
 877     $namespace =~ s/^\/// if $namespace;
 878     $namespace .= '/' if $namespace;
 879     $path ||= '';
 880     $namespace = '' if $path =~ /^\//;
 881     $path =~ s/^\///;
 882
 883     my $params =
 884       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 885
 886     for my $value ( values %$params ) {\r
 887         my $isa_ref = ref $value;\r
 888         if( $isa_ref and $isa_ref ne 'ARRAY' ) {\r
 889             croak( "Non-array reference ($isa_ref) passed to uri_for()" );\r
 890         }\r
 891         utf8::encode( $_ ) for grep { defined } $isa_ref ? @$value : $value;\r
 892     };
 893
 894     # join args with '/', or a blank string
 895     my $args = ( scalar @args ? '/' . join( '/', @args ) : '' );
 896     $args =~ s/^\/// unless $path;
 897     my $res =
 898       URI->new_abs( URI->new_abs( "$path$args", "$basepath$namespace" ), $base )
 899       ->canonical;
 900     $res->query_form(%$params);
 901     $res;
 902 }
 903
 904 =head2 $c->welcome_message
 905
 906 Returns the Catalyst welcome HTML page.
 907
 908 =cut
 909
 910 sub welcome_message {
 911     my $c      = shift;
 912     my $name   = $c->config->{name};
 913     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
 914     my $prefix = Catalyst::Utils::appprefix( ref $c );
 915     $c->response->content_type('text/html; charset=utf-8');
 916     return <<"EOF";
 917 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
 918     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 919 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 920     <head>
 921         <meta http-equiv="Content-Language" content="en" />
 922         <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
 923         <title>$name on Catalyst $VERSION</title>
 924         <style type="text/css">
 925             body {
 926                 color: #000;
 927                 background-color: #eee;
 928             }
 929             div#content {
 930                 width: 640px;
 931                 margin-left: auto;
 932                 margin-right: auto;
 933                 margin-top: 10px;
 934                 margin-bottom: 10px;
 935                 text-align: left;
 936                 background-color: #ccc;
 937                 border: 1px solid #aaa;
 938             }
 939             p, h1, h2 {
 940                 margin-left: 20px;
 941                 margin-right: 20px;
 942                 font-family: verdana, tahoma, sans-serif;
 943             }
 944             a {
 945                 font-family: verdana, tahoma, sans-serif;
 946             }
 947             :link, :visited {
 948                     text-decoration: none;
 949                     color: #b00;
 950                     border-bottom: 1px dotted #bbb;
 951             }
 952             :link:hover, :visited:hover {
 953                     color: #555;
 954             }
 955             div#topbar {
 956                 margin: 0px;
 957             }
 958             pre {
 959                 margin: 10px;
 960                 padding: 8px;
 961             }
 962             div#answers {
 963                 padding: 8px;
 964                 margin: 10px;
 965                 background-color: #fff;
 966                 border: 1px solid #aaa;
 967             }
 968             h1 {
 969                 font-size: 0.9em;
 970                 font-weight: normal;
 971                 text-align: center;
 972             }
 973             h2 {
 974                 font-size: 1.0em;
 975             }
 976             p {
 977                 font-size: 0.9em;
 978             }
 979             p img {
 980                 float: right;
 981                 margin-left: 10px;
 982             }
 983             span#appname {
 984                 font-weight: bold;
 985                 font-size: 1.6em;
 986             }
 987         </style>
 988     </head>
 989     <body>
 990         <div id="content">
 991             <div id="topbar">
 992                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
 993                     $VERSION</h1>
 994              </div>
 995              <div id="answers">
 996                  <p>
 997                  <img src="$logo" alt="Catalyst Logo" />
 998                  </p>
 999                  <p>Welcome to the wonderful world of Catalyst.
1000                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1001                     framework will make web development something you had
1002                     never expected it to be: Fun, rewarding, and quick.</p>
1003                  <h2>What to do now?</h2>
1004                  <p>That really depends  on what <b>you</b> want to do.
1005                     We do, however, provide you with a few starting points.</p>
1006                  <p>If you want to jump right into web development with Catalyst
1007                     you might want to check out the documentation.</p>
1008                  <pre><code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1009 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1010 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual.pod">Catalyst::Manual</a></code></pre>
1011                  <h2>What to do next?</h2>
1012                  <p>Next it's time to write an actual application. Use the
1013                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1014                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1015                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1016                     they can save you a lot of work.</p>
1017                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1018                     <p>Also, be sure to check out the vast and growing
1019                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1020                     you are likely to find what you need there.
1021                     </p>
1022
1023                  <h2>Need help?</h2>
1024                  <p>Catalyst has a very active community. Here are the main places to
1025                     get in touch with us.</p>
1026                  <ul>
1027                      <li>
1028                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1029                      </li>
1030                      <li>
1031                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1032                      </li>
1033                      <li>
1034                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1035                      </li>
1036                  </ul>
1037                  <h2>In conclusion</h2>
1038                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1039                     as we enjoyed making it. Please contact us if you have ideas
1040                     for improvement or other feedback.</p>
1041              </div>
1042          </div>
1043     </body>
1044 </html>
1045 EOF
1046 }
1047
1048 =head1 INTERNAL METHODS
1049
1050 These methods are not meant to be used by end users.
1051
1052 =head2 $c->components
1053
1054 Returns a hash of components.
1055
1056 =head2 $c->context_class
1057
1058 Returns or sets the context class.
1059
1060 =head2 $c->counter
1061
1062 Returns a hashref containing coderefs and execution counts (needed for
1063 deep recursion detection).
1064
1065 =head2 $c->depth
1066
1067 Returns the number of actions on the current internal execution stack.
1068
1069 =head2 $c->dispatch
1070
1071 Dispatches a request to actions.
1072
1073 =cut
1074
1075 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1076
1077 =head2 $c->dispatcher_class
1078
1079 Returns or sets the dispatcher class.
1080
1081 =head2 $c->dump_these
1082
1083 Returns a list of 2-element array references (name, structure) pairs
1084 that will be dumped on the error page in debug mode.
1085
1086 =cut
1087
1088 sub dump_these {
1089     my $c = shift;
1090     [ Request => $c->req ],
1091     [ Response => $c->res ],
1092     [ Stash => $c->stash ],
1093     [ Config => $c->config ];
1094 }
1095
1096 =head2 $c->engine_class
1097
1098 Returns or sets the engine class.
1099
1100 =head2 $c->execute( $class, $coderef )
1101
1102 Execute a coderef in given class and catch exceptions. Errors are available
1103 via $c->error.
1104
1105 =cut
1106
1107 sub execute {
1108     my ( $c, $class, $code ) = @_;
1109     $class = $c->component($class) || $class;
1110     $c->state(0);
1111
1112     if ( $c->depth >= $RECURSION ) {
1113         my $action = "$code";
1114         $action = "/$action" unless $action =~ /\-\>/;
1115         my $error = qq/Deep recursion detected calling "$action"/;
1116         $c->log->error($error);
1117         $c->error($error);
1118         $c->state(0);
1119         return $c->state;
1120     }
1121
1122     my $stats_info = $c->_stats_start_execute( $code );
1123
1124     push( @{ $c->stack }, $code );
1125
1126     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1127
1128     $c->_stats_finish_execute( $stats_info );
1129
1130     my $last = ${ $c->stack }[-1];
1131     pop( @{ $c->stack } );
1132
1133     if ( my $error = $@ ) {
1134         if ( $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1135         else {
1136             unless ( ref $error ) {
1137                 chomp $error;
1138                 my $class = $last->class;
1139                 my $name  = $last->name;
1140                 $error = qq/Caught exception in $class->$name "$error"/;
1141             }
1142             $c->error($error);
1143             $c->state(0);
1144         }
1145     }
1146     return $c->state;
1147 }
1148
1149 sub _stats_start_execute {
1150     my ( $c, $code ) = @_;
1151
1152     return unless $c->debug;
1153
1154     my $action = "$code";
1155
1156     $action = "/$action" unless $action =~ /\-\>/;
1157     $c->counter->{"$code"}++;
1158
1159     # determine if the call was the result of a forward
1160     # this is done by walking up the call stack and looking for a calling
1161     # sub of Catalyst::forward before the eval
1162     my $callsub = q{};
1163     for my $index ( 2 .. 11 ) {
1164         last
1165         if ( ( caller($index) )[0] eq 'Catalyst'
1166             && ( caller($index) )[3] eq '(eval)' );
1167
1168         if ( ( caller($index) )[3] =~ /forward$/ ) {
1169             $callsub = ( caller($index) )[3];
1170             $action  = "-> $action";
1171             last;
1172         }
1173     }
1174
1175     my $node = Tree::Simple->new(
1176         {
1177             action  => $action,
1178             elapsed => undef,     # to be filled in later
1179             comment => "",
1180         }
1181     );
1182     $node->setUID( "$code" . $c->counter->{"$code"} );
1183
1184     unless ( ( $code->name =~ /^_.*/ )
1185         && ( !$c->config->{show_internal_actions} ) )
1186     {
1187         # is this a root-level call or a forwarded call?
1188         if ( $callsub =~ /forward$/ ) {
1189
1190             # forward, locate the caller
1191             if ( my $parent = $c->stack->[-1] ) {
1192                 my $visitor = Tree::Simple::Visitor::FindByUID->new;
1193                 $visitor->searchForUID(
1194                     "$parent" . $c->counter->{"$parent"} );
1195                 $c->stats->accept($visitor);
1196                 if ( my $result = $visitor->getResult ) {
1197                     $result->addChild($node);
1198                 }
1199             }
1200             else {
1201
1202                 # forward with no caller may come from a plugin
1203                 $c->stats->addChild($node);
1204             }
1205         }
1206         else {
1207
1208             # root-level call
1209             $c->stats->addChild($node);
1210         }
1211     }
1212
1213     my $start = [gettimeofday];
1214     my $elapsed = tv_interval($start);
1215
1216     return {
1217         code    => $code,
1218         elapsed => $elapsed,
1219         start   => $start,
1220         node    => $node,
1221       }
1222 }
1223
1224 sub _stats_finish_execute {
1225     my ( $c, $info ) = @_;
1226
1227     return unless $c->debug;
1228
1229     my ( $code, $start, $elapsed ) = @{ $info }{qw/code start elapsed/};
1230
1231     unless ( ( $code->name =~ /^_.*/ )
1232         && ( !$c->config->{show_internal_actions} ) )
1233     {
1234
1235         # FindByUID uses an internal die, so we save the existing error
1236         my $error = $@;
1237
1238         # locate the node in the tree and update the elapsed time
1239         my $visitor = Tree::Simple::Visitor::FindByUID->new;
1240         $visitor->searchForUID( "$code" . $c->counter->{"$code"} );
1241         $c->stats->accept($visitor);
1242         if ( my $result = $visitor->getResult ) {
1243             my $value = $result->getNodeValue;
1244             $value->{elapsed} = sprintf( '%fs', $elapsed );
1245             $result->setNodeValue($value);
1246         }
1247
1248         # restore error
1249         $@ = $error || undef;
1250     }
1251 }
1252
1253 =head2 $c->_localize_fields( sub { }, \%keys );
1254
1255 =cut
1256
1257 sub _localize_fields {
1258     my ( $c, $localized, $code ) = ( @_ );
1259
1260     my $request = delete $localized->{request} || {};
1261     my $response = delete $localized->{response} || {};
1262
1263     local @{ $c }{ keys %$localized } = values %$localized;
1264     local @{ $c->request }{ keys %$request } = values %$request;
1265     local @{ $c->response }{ keys %$response } = values %$response;
1266
1267     $code->();
1268 }
1269
1270 =head2 $c->finalize
1271
1272 Finalizes the request.
1273
1274 =cut
1275
1276 sub finalize {
1277     my $c = shift;
1278
1279     for my $error ( @{ $c->error } ) {
1280         $c->log->error($error);
1281     }
1282
1283     # Allow engine to handle finalize flow (for POE)
1284     if ( $c->engine->can('finalize') ) {
1285         $c->engine->finalize($c);
1286     }
1287     else {
1288
1289         $c->finalize_uploads;
1290
1291         # Error
1292         if ( $#{ $c->error } >= 0 ) {
1293             $c->finalize_error;
1294         }
1295
1296         $c->finalize_headers;
1297
1298         # HEAD request
1299         if ( $c->request->method eq 'HEAD' ) {
1300             $c->response->body('');
1301         }
1302
1303         $c->finalize_body;
1304     }
1305
1306     return $c->response->status;
1307 }
1308
1309 =head2 $c->finalize_body
1310
1311 Finalizes body.
1312
1313 =cut
1314
1315 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1316
1317 =head2 $c->finalize_cookies
1318
1319 Finalizes cookies.
1320
1321 =cut
1322
1323 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1324
1325 =head2 $c->finalize_error
1326
1327 Finalizes error.
1328
1329 =cut
1330
1331 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1332
1333 =head2 $c->finalize_headers
1334
1335 Finalizes headers.
1336
1337 =cut
1338
1339 sub finalize_headers {
1340     my $c = shift;
1341
1342     # Check if we already finalized headers
1343     return if $c->response->{_finalized_headers};
1344
1345     # Handle redirects
1346     if ( my $location = $c->response->redirect ) {
1347         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1348         $c->response->header( Location => $location );
1349     }
1350
1351     # Content-Length
1352     if ( $c->response->body && !$c->response->content_length ) {
1353
1354         # get the length from a filehandle
1355         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1356         {
1357             if ( my $stat = stat $c->response->body ) {
1358                 $c->response->content_length( $stat->size );
1359             }
1360             else {
1361                 $c->log->warn('Serving filehandle without a content-length');
1362             }
1363         }
1364         else {
1365             $c->response->content_length( bytes::length( $c->response->body ) );
1366         }
1367     }
1368
1369     # Errors
1370     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1371         $c->response->headers->remove_header("Content-Length");
1372         $c->response->body('');
1373     }
1374
1375     $c->finalize_cookies;
1376
1377     $c->engine->finalize_headers( $c, @_ );
1378
1379     # Done
1380     $c->response->{_finalized_headers} = 1;
1381 }
1382
1383 =head2 $c->finalize_output
1384
1385 An alias for finalize_body.
1386
1387 =head2 $c->finalize_read
1388
1389 Finalizes the input after reading is complete.
1390
1391 =cut
1392
1393 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1394
1395 =head2 $c->finalize_uploads
1396
1397 Finalizes uploads. Cleans up any temporary files.
1398
1399 =cut
1400
1401 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1402
1403 =head2 $c->get_action( $action, $namespace )
1404
1405 Gets an action in a given namespace.
1406
1407 =cut
1408
1409 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1410
1411 =head2 $c->get_actions( $action, $namespace )
1412
1413 Gets all actions of a given name in a namespace and all parent
1414 namespaces.
1415
1416 =cut
1417
1418 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1419
1420 =head2 $c->handle_request( $class, @arguments )
1421
1422 Called to handle each HTTP request.
1423
1424 =cut
1425
1426 sub handle_request {
1427     my ( $class, @arguments ) = @_;
1428
1429     # Always expect worst case!
1430     my $status = -1;
1431     eval {
1432         my $stats = ( $class->debug ) ? Tree::Simple->new: q{};
1433
1434         my $handler = sub {
1435             my $c = $class->prepare(@arguments);
1436             $c->stats($stats);
1437             $c->dispatch;
1438             return $c->finalize;
1439         };
1440
1441         if ( $class->debug ) {
1442             my $start = [gettimeofday];
1443             $status = &$handler;
1444             my $elapsed = tv_interval $start;
1445             $elapsed = sprintf '%f', $elapsed;
1446             my $av = sprintf '%.3f',
1447               ( $elapsed == 0 ? '??' : ( 1 / $elapsed ) );
1448             my $t = Text::SimpleTable->new( [ 62, 'Action' ], [ 9, 'Time' ] );
1449
1450             $stats->traverse(
1451                 sub {
1452                     my $action = shift;
1453                     my $stat   = $action->getNodeValue;
1454                     $t->row( ( q{ } x $action->getDepth ) . $stat->{action} . $stat->{comment},
1455                         $stat->{elapsed} || '??' );
1456                 }
1457             );
1458
1459             $class->log->info(
1460                 "Request took ${elapsed}s ($av/s)\n" . $t->draw );
1461         }
1462         else { $status = &$handler }
1463
1464     };
1465
1466     if ( my $error = $@ ) {
1467         chomp $error;
1468         $class->log->error(qq/Caught exception in engine "$error"/);
1469     }
1470
1471     $COUNT++;
1472     $class->log->_flush() if $class->log->can('_flush');
1473     return $status;
1474 }
1475
1476 =head2 $c->prepare( @arguments )
1477
1478 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1479 etc.).
1480
1481 =cut
1482
1483 sub prepare {
1484     my ( $class, @arguments ) = @_;
1485
1486     $class->context_class( ref $class || $class ) unless $class->context_class;
1487     my $c = $class->context_class->new(
1488         {
1489             counter => {},
1490             stack   => [],
1491             request => $class->request_class->new(
1492                 {
1493                     arguments        => [],
1494                     body_parameters  => {},
1495                     cookies          => {},
1496                     headers          => HTTP::Headers->new,
1497                     parameters       => {},
1498                     query_parameters => {},
1499                     secure           => 0,
1500                     captures         => [],
1501                     uploads          => {}
1502                 }
1503             ),
1504             response => $class->response_class->new(
1505                 {
1506                     body    => '',
1507                     cookies => {},
1508                     headers => HTTP::Headers->new(),
1509                     status  => 200
1510                 }
1511             ),
1512             stash => {},
1513             state => 0
1514         }
1515     );
1516
1517     # For on-demand data
1518     $c->request->{_context}  = $c;
1519     $c->response->{_context} = $c;
1520     weaken( $c->request->{_context} );
1521     weaken( $c->response->{_context} );
1522
1523     if ( $c->debug ) {
1524         my $secs = time - $START || 1;
1525         my $av = sprintf '%.3f', $COUNT / $secs;
1526         my $time = localtime time;
1527         $c->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1528         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1529     }
1530
1531     # Allow engine to direct the prepare flow (for POE)
1532     if ( $c->engine->can('prepare') ) {
1533         $c->engine->prepare( $c, @arguments );
1534     }
1535     else {
1536         $c->prepare_request(@arguments);
1537         $c->prepare_connection;
1538         $c->prepare_query_parameters;
1539         $c->prepare_headers;
1540         $c->prepare_cookies;
1541         $c->prepare_path;
1542
1543         # On-demand parsing
1544         $c->prepare_body unless $c->config->{parse_on_demand};
1545     }
1546
1547     my $method  = $c->req->method  || '';
1548     my $path    = $c->req->path    || '/';
1549     my $address = $c->req->address || '';
1550
1551     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1552       if $c->debug;
1553
1554     $c->prepare_action;
1555
1556     return $c;
1557 }
1558
1559 =head2 $c->prepare_action
1560
1561 Prepares action. See L<Catalyst::Dispatcher>.
1562
1563 =cut
1564
1565 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1566
1567 =head2 $c->prepare_body
1568
1569 Prepares message body.
1570
1571 =cut
1572
1573 sub prepare_body {
1574     my $c = shift;
1575
1576     # Do we run for the first time?
1577     return if defined $c->request->{_body};
1578
1579     # Initialize on-demand data
1580     $c->engine->prepare_body( $c, @_ );
1581     $c->prepare_parameters;
1582     $c->prepare_uploads;
1583
1584     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1585         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1586         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1587             my $param = $c->req->body_parameters->{$key};
1588             my $value = defined($param) ? $param : '';
1589             $t->row( $key,
1590                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1591         }
1592         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1593     }
1594 }
1595
1596 =head2 $c->prepare_body_chunk( $chunk )
1597
1598 Prepares a chunk of data before sending it to L<HTTP::Body>.
1599
1600 See L<Catalyst::Engine>.
1601
1602 =cut
1603
1604 sub prepare_body_chunk {
1605     my $c = shift;
1606     $c->engine->prepare_body_chunk( $c, @_ );
1607 }
1608
1609 =head2 $c->prepare_body_parameters
1610
1611 Prepares body parameters.
1612
1613 =cut
1614
1615 sub prepare_body_parameters {
1616     my $c = shift;
1617     $c->engine->prepare_body_parameters( $c, @_ );
1618 }
1619
1620 =head2 $c->prepare_connection
1621
1622 Prepares connection.
1623
1624 =cut
1625
1626 sub prepare_connection {
1627     my $c = shift;
1628     $c->engine->prepare_connection( $c, @_ );
1629 }
1630
1631 =head2 $c->prepare_cookies
1632
1633 Prepares cookies.
1634
1635 =cut
1636
1637 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1638
1639 =head2 $c->prepare_headers
1640
1641 Prepares headers.
1642
1643 =cut
1644
1645 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1646
1647 =head2 $c->prepare_parameters
1648
1649 Prepares parameters.
1650
1651 =cut
1652
1653 sub prepare_parameters {
1654     my $c = shift;
1655     $c->prepare_body_parameters;
1656     $c->engine->prepare_parameters( $c, @_ );
1657 }
1658
1659 =head2 $c->prepare_path
1660
1661 Prepares path and base.
1662
1663 =cut
1664
1665 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1666
1667 =head2 $c->prepare_query_parameters
1668
1669 Prepares query parameters.
1670
1671 =cut
1672
1673 sub prepare_query_parameters {
1674     my $c = shift;
1675
1676     $c->engine->prepare_query_parameters( $c, @_ );
1677
1678     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1679         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1680         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1681             my $param = $c->req->query_parameters->{$key};
1682             my $value = defined($param) ? $param : '';
1683             $t->row( $key,
1684                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1685         }
1686         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1687     }
1688 }
1689
1690 =head2 $c->prepare_read
1691
1692 Prepares the input for reading.
1693
1694 =cut
1695
1696 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1697
1698 =head2 $c->prepare_request
1699
1700 Prepares the engine request.
1701
1702 =cut
1703
1704 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1705
1706 =head2 $c->prepare_uploads
1707
1708 Prepares uploads.
1709
1710 =cut
1711
1712 sub prepare_uploads {
1713     my $c = shift;
1714
1715     $c->engine->prepare_uploads( $c, @_ );
1716
1717     if ( $c->debug && keys %{ $c->request->uploads } ) {
1718         my $t = Text::SimpleTable->new(
1719             [ 12, 'Parameter' ],
1720             [ 26, 'Filename' ],
1721             [ 18, 'Type' ],
1722             [ 9,  'Size' ]
1723         );
1724         for my $key ( sort keys %{ $c->request->uploads } ) {
1725             my $upload = $c->request->uploads->{$key};
1726             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1727                 $t->row( $key, $u->filename, $u->type, $u->size );
1728             }
1729         }
1730         $c->log->debug( "File Uploads are:\n" . $t->draw );
1731     }
1732 }
1733
1734 =head2 $c->prepare_write
1735
1736 Prepares the output for writing.
1737
1738 =cut
1739
1740 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1741
1742 =head2 $c->request_class
1743
1744 Returns or sets the request class.
1745
1746 =head2 $c->response_class
1747
1748 Returns or sets the response class.
1749
1750 =head2 $c->read( [$maxlength] )
1751
1752 Reads a chunk of data from the request body. This method is designed to
1753 be used in a while loop, reading C<$maxlength> bytes on every call.
1754 C<$maxlength> defaults to the size of the request if not specified.
1755
1756 You have to set C<MyApp-E<gt>config-E<gt>{parse_on_demand}> to use this
1757 directly.
1758
1759 =cut
1760
1761 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1762
1763 =head2 $c->run
1764
1765 Starts the engine.
1766
1767 =cut
1768
1769 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1770
1771 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1772
1773 Sets an action in a given namespace.
1774
1775 =cut
1776
1777 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1778
1779 =head2 $c->setup_actions($component)
1780
1781 Sets up actions for a component.
1782
1783 =cut
1784
1785 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1786
1787 =head2 $c->setup_components
1788
1789 Sets up components.
1790
1791 =cut
1792
1793 sub setup_components {
1794     my $class = shift;
1795
1796     my $callback = sub {
1797         my ( $component, $context ) = @_;
1798
1799         unless ( $component->can('COMPONENT') ) {
1800             return $component;
1801         }
1802
1803         my $suffix = Catalyst::Utils::class2classsuffix($component);
1804         my $config = $class->config->{$suffix} || {};
1805
1806         my $instance;
1807
1808         eval { $instance = $component->COMPONENT( $context, $config ); };
1809
1810         if ( my $error = $@ ) {
1811
1812             chomp $error;
1813
1814             Catalyst::Exception->throw( message =>
1815                   qq/Couldn't instantiate component "$component", "$error"/ );
1816         }
1817
1818         Catalyst::Exception->throw( message =>
1819 qq/Couldn't instantiate component "$component", "COMPONENT() didn't return a object"/
1820           )
1821           unless ref $instance;
1822         return $instance;
1823     };
1824
1825     eval "package $class;\n" . q!Module::Pluggable::Fast->import(
1826             name   => '_catalyst_components',
1827             search => [
1828                 "$class\::Controller", "$class\::C",
1829                 "$class\::Model",      "$class\::M",
1830                 "$class\::View",       "$class\::V"
1831             ],
1832             callback => $callback
1833         );
1834     !;
1835
1836     if ( my $error = $@ ) {
1837
1838         chomp $error;
1839
1840         Catalyst::Exception->throw(
1841             message => qq/Couldn't load components "$error"/ );
1842     }
1843
1844     for my $component ( $class->_catalyst_components($class) ) {
1845         $class->components->{ ref $component || $component } = $component;
1846     }
1847 }
1848
1849 =head2 $c->setup_dispatcher
1850
1851 Sets up dispatcher.
1852
1853 =cut
1854
1855 sub setup_dispatcher {
1856     my ( $class, $dispatcher ) = @_;
1857
1858     if ($dispatcher) {
1859         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1860     }
1861
1862     if ( $ENV{CATALYST_DISPATCHER} ) {
1863         $dispatcher = 'Catalyst::Dispatcher::' . $ENV{CATALYST_DISPATCHER};
1864     }
1865
1866     if ( $ENV{ uc($class) . '_DISPATCHER' } ) {
1867         $dispatcher =
1868           'Catalyst::Dispatcher::' . $ENV{ uc($class) . '_DISPATCHER' };
1869     }
1870
1871     unless ($dispatcher) {
1872         $dispatcher = $class->dispatcher_class;
1873     }
1874
1875     unless (Class::Inspector->loaded($dispatcher)) {
1876         require Class::Inspector->filename($dispatcher);
1877     }
1878
1879     # dispatcher instance
1880     $class->dispatcher( $dispatcher->new );
1881 }
1882
1883 =head2 $c->setup_engine
1884
1885 Sets up engine.
1886
1887 =cut
1888
1889 sub setup_engine {
1890     my ( $class, $engine ) = @_;
1891
1892     if ($engine) {
1893         $engine = 'Catalyst::Engine::' . $engine;
1894     }
1895
1896     if ( $ENV{CATALYST_ENGINE} ) {
1897         $engine = 'Catalyst::Engine::' . $ENV{CATALYST_ENGINE};
1898     }
1899
1900     if ( $ENV{ uc($class) . '_ENGINE' } ) {
1901         $engine = 'Catalyst::Engine::' . $ENV{ uc($class) . '_ENGINE' };
1902     }
1903
1904     if ( $ENV{MOD_PERL} ) {
1905
1906         # create the apache method
1907         {
1908             no strict 'refs';
1909             *{"$class\::apache"} = sub { shift->engine->apache };
1910         }
1911
1912         my ( $software, $version ) =
1913           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1914
1915         $version =~ s/_//g;
1916         $version =~ s/(\.[^.]+)\./$1/g;
1917
1918         if ( $software eq 'mod_perl' ) {
1919
1920             if ( !$engine ) {
1921
1922                 if ( $version >= 1.99922 ) {
1923                     $engine = 'Catalyst::Engine::Apache2::MP20';
1924                 }
1925
1926                 elsif ( $version >= 1.9901 ) {
1927                     $engine = 'Catalyst::Engine::Apache2::MP19';
1928                 }
1929
1930                 elsif ( $version >= 1.24 ) {
1931                     $engine = 'Catalyst::Engine::Apache::MP13';
1932                 }
1933
1934                 else {
1935                     Catalyst::Exception->throw( message =>
1936                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
1937                 }
1938
1939             }
1940
1941             # install the correct mod_perl handler
1942             if ( $version >= 1.9901 ) {
1943                 *handler = sub  : method {
1944                     shift->handle_request(@_);
1945                 };
1946             }
1947             else {
1948                 *handler = sub ($$) { shift->handle_request(@_) };
1949             }
1950
1951         }
1952
1953         elsif ( $software eq 'Zeus-Perl' ) {
1954             $engine = 'Catalyst::Engine::Zeus';
1955         }
1956
1957         else {
1958             Catalyst::Exception->throw(
1959                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
1960         }
1961     }
1962
1963     unless ($engine) {
1964         $engine = $class->engine_class;
1965     }
1966
1967     unless (Class::Inspector->loaded($engine)) {
1968         require Class::Inspector->filename($engine);
1969     }
1970
1971     # check for old engines that are no longer compatible
1972     my $old_engine;
1973     if ( $engine->isa('Catalyst::Engine::Apache')
1974         && !Catalyst::Engine::Apache->VERSION )
1975     {
1976         $old_engine = 1;
1977     }
1978
1979     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
1980         && Catalyst::Engine::Server->VERSION le '0.02' )
1981     {
1982         $old_engine = 1;
1983     }
1984
1985     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
1986         && $engine->VERSION eq '0.01' )
1987     {
1988         $old_engine = 1;
1989     }
1990
1991     elsif ($engine->isa('Catalyst::Engine::Zeus')
1992         && $engine->VERSION eq '0.01' )
1993     {
1994         $old_engine = 1;
1995     }
1996
1997     if ($old_engine) {
1998         Catalyst::Exception->throw( message =>
1999               qq/Engine "$engine" is not supported by this version of Catalyst/
2000         );
2001     }
2002
2003     # engine instance
2004     $class->engine( $engine->new );
2005 }
2006
2007 =head2 $c->setup_home
2008
2009 Sets up the home directory.
2010
2011 =cut
2012
2013 sub setup_home {
2014     my ( $class, $home ) = @_;
2015
2016     if ( $ENV{CATALYST_HOME} ) {
2017         $home = $ENV{CATALYST_HOME};
2018     }
2019
2020     if ( $ENV{ uc($class) . '_HOME' } ) {
2021         $home = $ENV{ uc($class) . '_HOME' };
2022     }
2023
2024     unless ($home) {
2025         $home = Catalyst::Utils::home($class);
2026     }
2027
2028     if ($home) {
2029         $class->config->{home} ||= $home;
2030         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2031     }
2032 }
2033
2034 =head2 $c->setup_log
2035
2036 Sets up log.
2037
2038 =cut
2039
2040 sub setup_log {
2041     my ( $class, $debug ) = @_;
2042
2043     unless ( $class->log ) {
2044         $class->log( Catalyst::Log->new );
2045     }
2046
2047     my $app_flag = Catalyst::Utils::class2env($class) . '_DEBUG';
2048
2049     if (
2050           ( defined( $ENV{CATALYST_DEBUG} ) || defined( $ENV{$app_flag} ) )
2051         ? ( $ENV{CATALYST_DEBUG} || $ENV{$app_flag} )
2052         : $debug
2053       )
2054     {
2055         no strict 'refs';
2056         *{"$class\::debug"} = sub { 1 };
2057         $class->log->debug('Debug messages enabled');
2058     }
2059 }
2060
2061 =head2 $c->setup_plugins
2062
2063 Sets up plugins.
2064
2065 =cut
2066
2067 =head2 $c->registered_plugins
2068
2069 Returns a sorted list of the plugins which have either been stated in the
2070 import list or which have been added via C<< MyApp->plugin(@args); >>.
2071
2072 If passed a given plugin name, it will report a boolean value indicating
2073 whether or not that plugin is loaded.  A fully qualified name is required if
2074 the plugin name does not begin with C<Catalyst::Plugin::>.
2075
2076  if ($c->registered_plugins('Some::Plugin')) {
2077      ...
2078  }
2079
2080 =cut
2081
2082 {
2083
2084     sub registered_plugins {
2085         my $proto = shift;
2086         return sort keys %{ $proto->_plugins } unless @_;
2087         my $plugin = shift;
2088         return 1 if exists $proto->_plugins->{$plugin};
2089         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2090     }
2091
2092     sub _register_plugin {
2093         my ( $proto, $plugin, $instant ) = @_;
2094         my $class = ref $proto || $proto;
2095
2096         unless (Class::Inspector->loaded($plugin)) {
2097             require Class::Inspector->filename($plugin);
2098         }
2099
2100         $proto->_plugins->{$plugin} = 1;
2101         unless ($instant) {
2102             no strict 'refs';
2103             unshift @{"$class\::ISA"}, $plugin;
2104         }
2105         return $class;
2106     }
2107
2108     sub setup_plugins {
2109         my ( $class, $plugins ) = @_;
2110
2111         $class->_plugins( {} ) unless $class->_plugins;
2112         $plugins ||= [];
2113         for my $plugin ( reverse @$plugins ) {
2114
2115             unless ( $plugin =~ s/\A\+// ) {
2116                 $plugin = "Catalyst::Plugin::$plugin";
2117             }
2118
2119             $class->_register_plugin($plugin);
2120         }
2121     }
2122 }
2123
2124 =head2 $c->stack
2125
2126 Returns an arrayref of the internal execution stack (actions that are currently
2127 executing).
2128
2129 =head2 $c->write( $data )
2130
2131 Writes $data to the output stream. When using this method directly, you
2132 will need to manually set the C<Content-Length> header to the length of
2133 your output data, if known.
2134
2135 =cut
2136
2137 sub write {
2138     my $c = shift;
2139
2140     # Finalize headers if someone manually writes output
2141     $c->finalize_headers;
2142
2143     return $c->engine->write( $c, @_ );
2144 }
2145
2146 =head2 version
2147
2148 Returns the Catalyst version number. Mostly useful for "powered by"
2149 messages in template systems.
2150
2151 =cut
2152
2153 sub version { return $Catalyst::VERSION }
2154
2155 =head1 INTERNAL ACTIONS
2156
2157 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2158 C<_ACTION>, and C<_END>. These are by default not shown in the private
2159 action table, but you can make them visible with a config parameter.
2160
2161     MyApp->config->{show_internal_actions} = 1;
2162
2163 =head1 CASE SENSITIVITY
2164
2165 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2166 mapped to C</foo/bar>. You can activate case sensitivity with a config
2167 parameter.
2168
2169     MyApp->config->{case_sensitive} = 1;
2170
2171 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2172
2173 =head1 ON-DEMAND PARSER
2174
2175 The request body is usually parsed at the beginning of a request,
2176 but if you want to handle input yourself or speed things up a bit,
2177 you can enable on-demand parsing with a config parameter.
2178
2179     MyApp->config->{parse_on_demand} = 1;
2180
2181 =head1 PROXY SUPPORT
2182
2183 Many production servers operate using the common double-server approach,
2184 with a lightweight frontend web server passing requests to a larger
2185 backend server. An application running on the backend server must deal
2186 with two problems: the remote user always appears to be C<127.0.0.1> and
2187 the server's hostname will appear to be C<localhost> regardless of the
2188 virtual host that the user connected through.
2189
2190 Catalyst will automatically detect this situation when you are running
2191 the frontend and backend servers on the same machine. The following
2192 changes are made to the request.
2193
2194     $c->req->address is set to the user's real IP address, as read from
2195     the HTTP X-Forwarded-For header.
2196
2197     The host value for $c->req->base and $c->req->uri is set to the real
2198     host, as read from the HTTP X-Forwarded-Host header.
2199
2200 Obviously, your web server must support these headers for this to work.
2201
2202 In a more complex server farm environment where you may have your
2203 frontend proxy server(s) on different machines, you will need to set a
2204 configuration option to tell Catalyst to read the proxied data from the
2205 headers.
2206
2207     MyApp->config->{using_frontend_proxy} = 1;
2208
2209 If you do not wish to use the proxy support at all, you may set:
2210
2211     MyApp->config->{ignore_frontend_proxy} = 1;
2212
2213 =head1 THREAD SAFETY
2214
2215 Catalyst has been tested under Apache 2's threading mpm_worker, mpm_winnt,
2216 and the standalone forking HTTP server on Windows. We believe the Catalyst
2217 core to be thread-safe.
2218
2219 If you plan to operate in a threaded environment, remember that all other
2220 modules you are using must also be thread-safe. Some modules, most notably
2221 L<DBD::SQLite>, are not thread-safe.
2222
2223 =head1 SUPPORT
2224
2225 IRC:
2226
2227     Join #catalyst on irc.perl.org.
2228
2229 Mailing Lists:
2230
2231     http://lists.rawmode.org/mailman/listinfo/catalyst
2232     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2233
2234 Web:
2235
2236     http://catalyst.perl.org
2237
2238 Wiki:
2239
2240     http://dev.catalyst.perl.org
2241
2242 =head1 SEE ALSO
2243
2244 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2245
2246 =head2 L<Catalyst::Manual> - The Catalyst Manual
2247
2248 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2249
2250 =head2 L<Catalyst::Engine> - Core engine
2251
2252 =head2 L<Catalyst::Log> - Log class.
2253
2254 =head2 L<Catalyst::Request> - Request object
2255
2256 =head2 L<Catalyst::Response> - Response object
2257
2258 =head2 L<Catalyst::Test> - The test suite.
2259
2260 =head1 CREDITS
2261
2262 Andy Grundman
2263
2264 Andy Wardley
2265
2266 Andreas Marienborg
2267
2268 Andrew Bramble
2269
2270 Andrew Ford
2271
2272 Andrew Ruthven
2273
2274 Arthur Bergman
2275
2276 Autrijus Tang
2277
2278 Brian Cassidy
2279
2280 Carl Franks
2281
2282 Christian Hansen
2283
2284 Christopher Hicks
2285
2286 Dan Sully
2287
2288 Danijel Milicevic
2289
2290 David Kamholz
2291
2292 David Naughton
2293
2294 Drew Taylor
2295
2296 Gary Ashton Jones
2297
2298 Geoff Richards
2299
2300 Jesse Sheidlower
2301
2302 Jesse Vincent
2303
2304 Jody Belka
2305
2306 Johan Lindstrom
2307
2308 Juan Camacho
2309
2310 Leon Brocard
2311
2312 Marcus Ramberg
2313
2314 Matt S Trout
2315
2316 Robert Sedlacek
2317
2318 Sam Vilain
2319
2320 Sascha Kiefer
2321
2322 Tatsuhiko Miyagawa
2323
2324 Ulf Edvinsson
2325
2326 Yuval Kogman
2327
2328 =head1 AUTHOR
2329
2330 Sebastian Riedel, C<sri@oook.de>
2331
2332 =head1 LICENSE
2333
2334 This library is free software, you can redistribute it and/or modify it under
2335 the same terms as Perl itself.
2336
2337 =cut
2338
2339 1;