lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80030';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 sub _comp_search_prefixes {
 540     my $c = shift;
 541     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 542 }
 543
 544 # search components given a name and some prefixes
 545 sub _comp_names_search_prefixes {
 546     my ( $c, $name, @prefixes ) = @_;
 547     my $appclass = ref $c || $c;
 548     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 549     $filter = qr/$filter/; # Compile regex now rather than once per loop
 550
 551     # map the original component name to the sub part that we will search against
 552     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 553         grep { /$filter/ } keys %{ $c->components };
 554
 555     # undef for a name will return all
 556     return keys %eligible if !defined $name;
 557
 558     my $query  = ref $name ? $name : qr/^$name$/i;
 559     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 560
 561     return @result if @result;
 562
 563     # if we were given a regexp to search against, we're done.
 564     return if ref $name;
 565
 566     # skip regexp fallback if configured
 567     return
 568         if $appclass->config->{disable_component_resolution_regex_fallback};
 569
 570     # regexp fallback
 571     $query  = qr/$name/i;
 572     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 573
 574     # no results? try against full names
 575     if( !@result ) {
 576         @result = grep { m{$query} } keys %eligible;
 577     }
 578
 579     # don't warn if we didn't find any results, it just might not exist
 580     if( @result ) {
 581         # Disgusting hack to work out correct method name
 582         my $warn_for = lc $prefixes[0];
 583         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 584            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 585            "component resolution is unreliable and unsafe.";
 586         my $short = $result[0];
 587         # remove the component namespace prefix
 588         $short =~ s/.*?(Model|Controller|View):://;
 589         my $shortmess = Carp::shortmess('');
 590         if ($shortmess =~ m#Catalyst/Plugin#) {
 591            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 592               "plugin's config";
 593         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 594            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 595               "component's config";
 596         } else {
 597            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 598               "but if you really wanted to search, pass in a regexp as the argument " .
 599               "like so: \$c->${warn_for}(qr/${name}/)";
 600         }
 601         $c->log->warn( "${msg}$shortmess" );
 602     }
 603
 604     return @result;
 605 }
 606
 607 # Find possible names for a prefix
 608 sub _comp_names {
 609     my ( $c, @prefixes ) = @_;
 610     my $appclass = ref $c || $c;
 611
 612     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 613
 614     my @names = map { s{$filter}{}; $_; }
 615         $c->_comp_names_search_prefixes( undef, @prefixes );
 616
 617     return @names;
 618 }
 619
 620 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 621 sub _filter_component {
 622     my ( $c, $comp, @args ) = @_;
 623
 624     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 625         return $comp->ACCEPT_CONTEXT( $c, @args );
 626     }
 627
 628     return $comp;
 629 }
 630
 631 =head2 COMPONENT ACCESSORS
 632
 633 =head2 $c->controller($name)
 634
 635 Gets a L<Catalyst::Controller> instance by name.
 636
 637     $c->controller('Foo')->do_stuff;
 638
 639 If the name is omitted, will return the controller for the dispatched
 640 action.
 641
 642 If you want to search for controllers, pass in a regexp as the argument.
 643
 644     # find all controllers that start with Foo
 645     my @foo_controllers = $c->controller(qr{^Foo});
 646
 647
 648 =cut
 649
 650 sub controller {
 651     my ( $c, $name, @args ) = @_;
 652
 653     my $appclass = ref($c) || $c;
 654     if( $name ) {
 655         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 656             my $comps = $c->components;
 657             my $check = $appclass."::Controller::".$name;
 658             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 659         }
 660         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 661         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 662         return $c->_filter_component( $result[ 0 ], @args );
 663     }
 664
 665     return $c->component( $c->action->class );
 666 }
 667
 668 =head2 $c->model($name)
 669
 670 Gets a L<Catalyst::Model> instance by name.
 671
 672     $c->model('Foo')->do_stuff;
 673
 674 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 675
 676 If the name is omitted, it will look for
 677  - a model object in $c->stash->{current_model_instance}, then
 678  - a model name in $c->stash->{current_model}, then
 679  - a config setting 'default_model', or
 680  - check if there is only one model, and return it if that's the case.
 681
 682 If you want to search for models, pass in a regexp as the argument.
 683
 684     # find all models that start with Foo
 685     my @foo_models = $c->model(qr{^Foo});
 686
 687 =cut
 688
 689 sub model {
 690     my ( $c, $name, @args ) = @_;
 691     my $appclass = ref($c) || $c;
 692     if( $name ) {
 693         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 694             my $comps = $c->components;
 695             my $check = $appclass."::Model::".$name;
 696             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 697         }
 698         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 699         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 700         return $c->_filter_component( $result[ 0 ], @args );
 701     }
 702
 703     if (ref $c) {
 704         return $c->stash->{current_model_instance}
 705           if $c->stash->{current_model_instance};
 706         return $c->model( $c->stash->{current_model} )
 707           if $c->stash->{current_model};
 708     }
 709     return $c->model( $appclass->config->{default_model} )
 710       if $appclass->config->{default_model};
 711
 712     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 713
 714     if( $rest ) {
 715         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 716         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 717         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 718         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 719         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 720     }
 721
 722     return $c->_filter_component( $comp );
 723 }
 724
 725
 726 =head2 $c->view($name)
 727
 728 Gets a L<Catalyst::View> instance by name.
 729
 730     $c->view('Foo')->do_stuff;
 731
 732 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 733
 734 If the name is omitted, it will look for
 735  - a view object in $c->stash->{current_view_instance}, then
 736  - a view name in $c->stash->{current_view}, then
 737  - a config setting 'default_view', or
 738  - check if there is only one view, and return it if that's the case.
 739
 740 If you want to search for views, pass in a regexp as the argument.
 741
 742     # find all views that start with Foo
 743     my @foo_views = $c->view(qr{^Foo});
 744
 745 =cut
 746
 747 sub view {
 748     my ( $c, $name, @args ) = @_;
 749
 750     my $appclass = ref($c) || $c;
 751     if( $name ) {
 752         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 753             my $comps = $c->components;
 754             my $check = $appclass."::View::".$name;
 755             if( exists $comps->{$check} ) {
 756                 return $c->_filter_component( $comps->{$check}, @args );
 757             }
 758             else {
 759                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 760             }
 761         }
 762         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 763         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 764         return $c->_filter_component( $result[ 0 ], @args );
 765     }
 766
 767     if (ref $c) {
 768         return $c->stash->{current_view_instance}
 769           if $c->stash->{current_view_instance};
 770         return $c->view( $c->stash->{current_view} )
 771           if $c->stash->{current_view};
 772     }
 773     return $c->view( $appclass->config->{default_view} )
 774       if $appclass->config->{default_view};
 775
 776     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 777
 778     if( $rest ) {
 779         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 780         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 781         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 782         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 783         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 784     }
 785
 786     return $c->_filter_component( $comp );
 787 }
 788
 789 =head2 $c->controllers
 790
 791 Returns the available names which can be passed to $c->controller
 792
 793 =cut
 794
 795 sub controllers {
 796     my ( $c ) = @_;
 797     return $c->_comp_names(qw/Controller C/);
 798 }
 799
 800 =head2 $c->models
 801
 802 Returns the available names which can be passed to $c->model
 803
 804 =cut
 805
 806 sub models {
 807     my ( $c ) = @_;
 808     return $c->_comp_names(qw/Model M/);
 809 }
 810
 811
 812 =head2 $c->views
 813
 814 Returns the available names which can be passed to $c->view
 815
 816 =cut
 817
 818 sub views {
 819     my ( $c ) = @_;
 820     return $c->_comp_names(qw/View V/);
 821 }
 822
 823 =head2 $c->comp($name)
 824
 825 =head2 $c->component($name)
 826
 827 Gets a component object by name. This method is not recommended,
 828 unless you want to get a specific component by full
 829 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 830 should be used instead.
 831
 832 If C<$name> is a regexp, a list of components matched against the full
 833 component name will be returned.
 834
 835 If Catalyst can't find a component by name, it will fallback to regex
 836 matching by default. To disable this behaviour set
 837 disable_component_resolution_regex_fallback to a true value.
 838
 839     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 840
 841 =cut
 842
 843 sub component {
 844     my ( $c, $name, @args ) = @_;
 845
 846     if( $name ) {
 847         my $comps = $c->components;
 848
 849         if( !ref $name ) {
 850             # is it the exact name?
 851             return $c->_filter_component( $comps->{ $name }, @args )
 852                        if exists $comps->{ $name };
 853
 854             # perhaps we just omitted "MyApp"?
 855             my $composed = ( ref $c || $c ) . "::${name}";
 856             return $c->_filter_component( $comps->{ $composed }, @args )
 857                        if exists $comps->{ $composed };
 858
 859             # search all of the models, views and controllers
 860             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 861             return $c->_filter_component( $comp, @args ) if $comp;
 862         }
 863
 864         # This is here so $c->comp( '::M::' ) works
 865         my $query = ref $name ? $name : qr{$name}i;
 866
 867         my @result = grep { m{$query} } keys %{ $c->components };
 868         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 869
 870         if( $result[ 0 ] ) {
 871             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 872             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 873             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 874             return $c->_filter_component( $result[ 0 ], @args );
 875         }
 876
 877         # I would expect to return an empty list here, but that breaks back-compat
 878     }
 879
 880     # fallback
 881     return sort keys %{ $c->components };
 882 }
 883
 884 =head2 CLASS DATA AND HELPER CLASSES
 885
 886 =head2 $c->config
 887
 888 Returns or takes a hashref containing the application's configuration.
 889
 890     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 891
 892 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 893 like C<myapp.conf> in your applications home directory. See
 894 L<Catalyst::Plugin::ConfigLoader>.
 895
 896 =head3 Cascading configuration
 897
 898 The config method is present on all Catalyst components, and configuration
 899 will be merged when an application is started. Configuration loaded with
 900 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 901 followed by configuration in your top level C<MyApp> class. These two
 902 configurations are merged, and then configuration data whose hash key matches a
 903 component name is merged with configuration for that component.
 904
 905 The configuration for a component is then passed to the C<new> method when a
 906 component is constructed.
 907
 908 For example:
 909
 910     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 911     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 912
 913 will mean that C<MyApp::Model::Foo> receives the following data when
 914 constructed:
 915
 916     MyApp::Model::Foo->new({
 917         bar => 'baz',
 918         quux => 'frob',
 919         overrides => 'me',
 920     });
 921
 922 It's common practice to use a Moose attribute
 923 on the receiving component to access the config value.
 924
 925     package MyApp::Model::Foo;
 926
 927     use Moose;
 928
 929     # this attr will receive 'baz' at construction time
 930     has 'bar' => (
 931         is  => 'rw',
 932         isa => 'Str',
 933     );
 934
 935 You can then get the value 'baz' by calling $c->model('Foo')->bar
 936 (or $self->bar inside code in the model).
 937
 938 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 939 as a way of reading config within your code, as this B<will not> give you the
 940 correctly merged config back. You B<MUST> take the config values supplied to
 941 the constructor and use those instead.
 942
 943 =cut
 944
 945 around config => sub {
 946     my $orig = shift;
 947     my $c = shift;
 948
 949     croak('Setting config after setup has been run is not allowed.')
 950         if ( @_ and $c->setup_finished );
 951
 952     $c->$orig(@_);
 953 };
 954
 955 =head2 $c->log
 956
 957 Returns the logging object instance. Unless it is already set, Catalyst
 958 sets this up with a L<Catalyst::Log> object. To use your own log class,
 959 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 960 C<< __PACKAGE__->setup >>.
 961
 962  __PACKAGE__->log( MyLogger->new );
 963  __PACKAGE__->setup;
 964
 965 And later:
 966
 967     $c->log->info( 'Now logging with my own logger!' );
 968
 969 Your log class should implement the methods described in
 970 L<Catalyst::Log>.
 971
 972
 973 =head2 $c->debug
 974
 975 Returns 1 if debug mode is enabled, 0 otherwise.
 976
 977 You can enable debug mode in several ways:
 978
 979 =over
 980
 981 =item By calling myapp_server.pl with the -d flag
 982
 983 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 984
 985 =item The -Debug option in your MyApp.pm
 986
 987 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 988
 989 =back
 990
 991 The first three also set the log level to 'debug'.
 992
 993 Calling C<< $c->debug(1) >> has no effect.
 994
 995 =cut
 996
 997 sub debug { 0 }
 998
 999 =head2 $c->dispatcher
1000
1001 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1002
1003 =head2 $c->engine
1004
1005 Returns the engine instance. See L<Catalyst::Engine>.
1006
1007
1008 =head2 UTILITY METHODS
1009
1010 =head2 $c->path_to(@path)
1011
1012 Merges C<@path> with C<< $c->config->{home} >> and returns a
1013 L<Path::Class::Dir> object. Note you can usually use this object as
1014 a filename, but sometimes you will have to explicitly stringify it
1015 yourself by calling the C<< ->stringify >> method.
1016
1017 For example:
1018
1019     $c->path_to( 'db', 'sqlite.db' );
1020
1021 =cut
1022
1023 sub path_to {
1024     my ( $c, @path ) = @_;
1025     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1026     if ( -d $path ) { return $path }
1027     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1028 }
1029
1030 =head2 $c->plugin( $name, $class, @args )
1031
1032 Helper method for plugins. It creates a class data accessor/mutator and
1033 loads and instantiates the given class.
1034
1035     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1036
1037     $c->prototype->define_javascript_functions;
1038
1039 B<Note:> This method of adding plugins is deprecated. The ability
1040 to add plugins like this B<will be removed> in a Catalyst 5.81.
1041 Please do not use this functionality in new code.
1042
1043 =cut
1044
1045 sub plugin {
1046     my ( $class, $name, $plugin, @args ) = @_;
1047
1048     # See block comment in t/unit_core_plugin.t
1049     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1050
1051     $class->_register_plugin( $plugin, 1 );
1052
1053     eval { $plugin->import };
1054     $class->mk_classdata($name);
1055     my $obj;
1056     eval { $obj = $plugin->new(@args) };
1057
1058     if ($@) {
1059         Catalyst::Exception->throw( message =>
1060               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1061     }
1062
1063     $class->$name($obj);
1064     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1065       if $class->debug;
1066 }
1067
1068 =head2 MyApp->setup
1069
1070 Initializes the dispatcher and engine, loads any plugins, and loads the
1071 model, view, and controller components. You may also specify an array
1072 of plugins to load here, if you choose to not load them in the C<use
1073 Catalyst> line.
1074
1075     MyApp->setup;
1076     MyApp->setup( qw/-Debug/ );
1077
1078 =cut
1079
1080 sub setup {
1081     my ( $class, @arguments ) = @_;
1082     croak('Running setup more than once')
1083         if ( $class->setup_finished );
1084
1085     unless ( $class->isa('Catalyst') ) {
1086
1087         Catalyst::Exception->throw(
1088             message => qq/'$class' does not inherit from Catalyst/ );
1089     }
1090
1091     if ( $class->arguments ) {
1092         @arguments = ( @arguments, @{ $class->arguments } );
1093     }
1094
1095     # Process options
1096     my $flags = {};
1097
1098     foreach (@arguments) {
1099
1100         if (/^-Debug$/) {
1101             $flags->{log} =
1102               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1103         }
1104         elsif (/^-(\w+)=?(.*)$/) {
1105             $flags->{ lc $1 } = $2;
1106         }
1107         else {
1108             push @{ $flags->{plugins} }, $_;
1109         }
1110     }
1111
1112     $class->setup_home( delete $flags->{home} );
1113
1114     $class->setup_log( delete $flags->{log} );
1115     $class->setup_plugins( delete $flags->{plugins} );
1116     $class->setup_dispatcher( delete $flags->{dispatcher} );
1117     $class->setup_engine( delete $flags->{engine} );
1118     $class->setup_stats( delete $flags->{stats} );
1119
1120     for my $flag ( sort keys %{$flags} ) {
1121
1122         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1123             &$code( $class, delete $flags->{$flag} );
1124         }
1125         else {
1126             $class->log->warn(qq/Unknown flag "$flag"/);
1127         }
1128     }
1129
1130     eval { require Catalyst::Devel; };
1131     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1132         $class->log->warn(<<"EOF");
1133 You are running an old script!
1134
1135   Please update by running (this will overwrite existing files):
1136     catalyst.pl -force -scripts $class
1137
1138   or (this will not overwrite existing files):
1139     catalyst.pl -scripts $class
1140
1141 EOF
1142     }
1143
1144     if ( $class->debug ) {
1145         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1146
1147         if (@plugins) {
1148             my $column_width = Catalyst::Utils::term_width() - 6;
1149             my $t = Text::SimpleTable->new($column_width);
1150             $t->row($_) for @plugins;
1151             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1152         }
1153
1154         my $dispatcher = $class->dispatcher;
1155         my $engine     = $class->engine;
1156         my $home       = $class->config->{home};
1157
1158         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1159         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1160
1161         $home
1162           ? ( -d $home )
1163           ? $class->log->debug(qq/Found home "$home"/)
1164           : $class->log->debug(qq/Home "$home" doesn't exist/)
1165           : $class->log->debug(q/Couldn't find home/);
1166     }
1167
1168     # Call plugins setup, this is stupid and evil.
1169     # Also screws C3 badly on 5.10, hack to avoid.
1170     {
1171         no warnings qw/redefine/;
1172         local *setup = sub { };
1173         $class->setup unless $Catalyst::__AM_RESTARTING;
1174     }
1175
1176     # Initialize our data structure
1177     $class->components( {} );
1178
1179     $class->setup_components;
1180
1181     if ( $class->debug ) {
1182         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1183         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1184         for my $comp ( sort keys %{ $class->components } ) {
1185             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1186             $t->row( $comp, $type );
1187         }
1188         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1189           if ( keys %{ $class->components } );
1190     }
1191
1192     # Add our self to components, since we are also a component
1193     if( $class->isa('Catalyst::Controller') ){
1194       $class->components->{$class} = $class;
1195     }
1196
1197     $class->setup_actions;
1198
1199     if ( $class->debug ) {
1200         my $name = $class->config->{name} || 'Application';
1201         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1202     }
1203
1204     # Make sure that the application class becomes immutable at this point,
1205     B::Hooks::EndOfScope::on_scope_end {
1206         return if $@;
1207         my $meta = Class::MOP::get_metaclass_by_name($class);
1208         if (
1209             $meta->is_immutable
1210             && ! { $meta->immutable_options }->{replace_constructor}
1211             && (
1212                    $class->isa('Class::Accessor::Fast')
1213                 || $class->isa('Class::Accessor')
1214             )
1215         ) {
1216             warn "You made your application class ($class) immutable, "
1217                 . "but did not inline the\nconstructor. "
1218                 . "This will break catalyst, as your app \@ISA "
1219                 . "Class::Accessor(::Fast)?\nPlease pass "
1220                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1221         }
1222         $meta->make_immutable(
1223             replace_constructor => 1,
1224         ) unless $meta->is_immutable;
1225     };
1226
1227     if ($class->config->{case_sensitive}) {
1228         $class->log->warn($class . "->config->{case_sensitive} is set.");
1229         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1230     }
1231
1232     $class->setup_finalize;
1233     # Should be the last thing we do so that user things hooking
1234     # setup_finalize can log..
1235     $class->log->_flush() if $class->log->can('_flush');
1236     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1237 }
1238
1239 =head2 $app->setup_finalize
1240
1241 A hook to attach modifiers to. This method does not do anything except set the
1242 C<setup_finished> accessor.
1243
1244 Applying method modifiers to the C<setup> method doesn't work, because of quirky thingsdone for plugin setup.
1245
1246 Example:
1247
1248     after setup_finalize => sub {
1249         my $app = shift;
1250
1251         ## do stuff here..
1252     };
1253
1254 =cut
1255
1256 sub setup_finalize {
1257     my ($class) = @_;
1258     $class->setup_finished(1);
1259 }
1260
1261 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1262
1263 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1264
1265 Constructs an absolute L<URI> object based on the application root, the
1266 provided path, and the additional arguments and query parameters provided.
1267 When used as a string, provides a textual URI.  If you need more flexibility
1268 than this (i.e. the option to provide relative URIs etc.) see
1269 L<Catalyst::Plugin::SmartURI>.
1270
1271 If no arguments are provided, the URI for the current action is returned.
1272 To return the current action and also provide @args, use
1273 C<< $c->uri_for( $c->action, @args ) >>.
1274
1275 If the first argument is a string, it is taken as a public URI path relative
1276 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1277 relative to the application root (if it does). It is then merged with
1278 C<< $c->request->base >>; any C<@args> are appended as additional path
1279 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1280
1281 If the first argument is a L<Catalyst::Action> it represents an action which
1282 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1283 optional C<\@captures> argument (an arrayref) allows passing the captured
1284 variables that are needed to fill in the paths of Chained and Regex actions;
1285 once the path is resolved, C<uri_for> continues as though a path was
1286 provided, appending any arguments or parameters and creating an absolute
1287 URI.
1288
1289 The captures for the current request can be found in
1290 C<< $c->request->captures >>, and actions can be resolved using
1291 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1292 path, use C<< $c->uri_for_action >> instead.
1293
1294   # Equivalent to $c->req->uri
1295   $c->uri_for($c->action, $c->req->captures,
1296       @{ $c->req->args }, $c->req->params);
1297
1298   # For the Foo action in the Bar controller
1299   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1300
1301   # Path to a static resource
1302   $c->uri_for('/static/images/logo.png');
1303
1304 =cut
1305
1306 sub uri_for {
1307     my ( $c, $path, @args ) = @_;
1308
1309     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1310         $path = $path->path_prefix;
1311         $path =~ s{/+\z}{};
1312         $path .= '/';
1313     }
1314
1315     undef($path) if (defined $path && $path eq '');
1316
1317     my $params =
1318       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1319
1320     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1321     foreach my $arg (@args) {
1322         utf8::encode($arg) if utf8::is_utf8($arg);
1323         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1324     }
1325
1326     if ( blessed($path) ) { # action object
1327         s|/|%2F|g for @args;
1328         my $captures = [ map { s|/|%2F|g; $_; }
1329                         ( scalar @args && ref $args[0] eq 'ARRAY'
1330                          ? @{ shift(@args) }
1331                          : ()) ];
1332
1333         foreach my $capture (@$captures) {
1334             utf8::encode($capture) if utf8::is_utf8($capture);
1335             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1336         }
1337
1338         my $action = $path;
1339         $path = $c->dispatcher->uri_for_action($action, $captures);
1340         if (not defined $path) {
1341             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1342                 if $c->debug;
1343             return undef;
1344         }
1345         $path = '/' if $path eq '';
1346     }
1347
1348     unshift(@args, $path);
1349
1350     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1351         my $namespace = $c->namespace;
1352         if (defined $path) { # cheesy hack to handle path '../foo'
1353            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1354         }
1355         unshift(@args, $namespace || '');
1356     }
1357
1358     # join args with '/', or a blank string
1359     my $args = join('/', grep { defined($_) } @args);
1360     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1361     $args =~ s!^/+!!;
1362     my $base = $c->req->base;
1363     my $class = ref($base);
1364     $base =~ s{(?<!/)$}{/};
1365
1366     my $query = '';
1367
1368     if (my @keys = keys %$params) {
1369       # somewhat lifted from URI::_query's query_form
1370       $query = '?'.join('&', map {
1371           my $val = $params->{$_};
1372           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1373           s/ /+/g;
1374           my $key = $_;
1375           $val = '' unless defined $val;
1376           (map {
1377               my $param = "$_";
1378               utf8::encode( $param ) if utf8::is_utf8($param);
1379               # using the URI::Escape pattern here so utf8 chars survive
1380               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1381               $param =~ s/ /+/g;
1382               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1383       } @keys);
1384     }
1385
1386     my $res = bless(\"${base}${args}${query}", $class);
1387     $res;
1388 }
1389
1390 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1391
1392 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1393
1394 =over
1395
1396 =item $path
1397
1398 A private path to the Catalyst action you want to create a URI for.
1399
1400 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1401 >> and passing the resulting C<$action> and the remaining arguments to C<<
1402 $c->uri_for >>.
1403
1404 You can also pass in a Catalyst::Action object, in which case it is passed to
1405 C<< $c->uri_for >>.
1406
1407 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1408
1409 For example, if the action looks like:
1410
1411  package MyApp::Controller::Users;
1412
1413  sub lst : Path('the-list') {}
1414
1415 You can use:
1416
1417  $c->uri_for_action('/users/lst')
1418
1419 and it will create the URI /users/the-list.
1420
1421 =back
1422
1423 =cut
1424
1425 sub uri_for_action {
1426     my ( $c, $path, @args ) = @_;
1427     my $action = blessed($path)
1428       ? $path
1429       : $c->dispatcher->get_action_by_path($path);
1430     unless (defined $action) {
1431       croak "Can't find action for path '$path'";
1432     }
1433     return $c->uri_for( $action, @args );
1434 }
1435
1436 =head2 $c->welcome_message
1437
1438 Returns the Catalyst welcome HTML page.
1439
1440 =cut
1441
1442 sub welcome_message {
1443     my $c      = shift;
1444     my $name   = $c->config->{name};
1445     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1446     my $prefix = Catalyst::Utils::appprefix( ref $c );
1447     $c->response->content_type('text/html; charset=utf-8');
1448     return <<"EOF";
1449 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1450     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1451 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1452     <head>
1453     <meta http-equiv="Content-Language" content="en" />
1454     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1455         <title>$name on Catalyst $VERSION</title>
1456         <style type="text/css">
1457             body {
1458                 color: #000;
1459                 background-color: #eee;
1460             }
1461             div#content {
1462                 width: 640px;
1463                 margin-left: auto;
1464                 margin-right: auto;
1465                 margin-top: 10px;
1466                 margin-bottom: 10px;
1467                 text-align: left;
1468                 background-color: #ccc;
1469                 border: 1px solid #aaa;
1470             }
1471             p, h1, h2 {
1472                 margin-left: 20px;
1473                 margin-right: 20px;
1474                 font-family: verdana, tahoma, sans-serif;
1475             }
1476             a {
1477                 font-family: verdana, tahoma, sans-serif;
1478             }
1479             :link, :visited {
1480                     text-decoration: none;
1481                     color: #b00;
1482                     border-bottom: 1px dotted #bbb;
1483             }
1484             :link:hover, :visited:hover {
1485                     color: #555;
1486             }
1487             div#topbar {
1488                 margin: 0px;
1489             }
1490             pre {
1491                 margin: 10px;
1492                 padding: 8px;
1493             }
1494             div#answers {
1495                 padding: 8px;
1496                 margin: 10px;
1497                 background-color: #fff;
1498                 border: 1px solid #aaa;
1499             }
1500             h1 {
1501                 font-size: 0.9em;
1502                 font-weight: normal;
1503                 text-align: center;
1504             }
1505             h2 {
1506                 font-size: 1.0em;
1507             }
1508             p {
1509                 font-size: 0.9em;
1510             }
1511             p img {
1512                 float: right;
1513                 margin-left: 10px;
1514             }
1515             span#appname {
1516                 font-weight: bold;
1517                 font-size: 1.6em;
1518             }
1519         </style>
1520     </head>
1521     <body>
1522         <div id="content">
1523             <div id="topbar">
1524                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1525                     $VERSION</h1>
1526              </div>
1527              <div id="answers">
1528                  <p>
1529                  <img src="$logo" alt="Catalyst Logo" />
1530                  </p>
1531                  <p>Welcome to the  world of Catalyst.
1532                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1533                     framework will make web development something you had
1534                     never expected it to be: Fun, rewarding, and quick.</p>
1535                  <h2>What to do now?</h2>
1536                  <p>That really depends  on what <b>you</b> want to do.
1537                     We do, however, provide you with a few starting points.</p>
1538                  <p>If you want to jump right into web development with Catalyst
1539                     you might want to start with a tutorial.</p>
1540 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1541 </pre>
1542 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1543 <pre>
1544 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1545 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1546 </code></pre>
1547                  <h2>What to do next?</h2>
1548                  <p>Next it's time to write an actual application. Use the
1549                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1550                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1551                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1552                     they can save you a lot of work.</p>
1553                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1554                     <p>Also, be sure to check out the vast and growing
1555                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1556                     you are likely to find what you need there.
1557                     </p>
1558
1559                  <h2>Need help?</h2>
1560                  <p>Catalyst has a very active community. Here are the main places to
1561                     get in touch with us.</p>
1562                  <ul>
1563                      <li>
1564                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1565                      </li>
1566                      <li>
1567                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1568                      </li>
1569                      <li>
1570                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1571                      </li>
1572                  </ul>
1573                  <h2>In conclusion</h2>
1574                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1575                     as we enjoyed making it. Please contact us if you have ideas
1576                     for improvement or other feedback.</p>
1577              </div>
1578          </div>
1579     </body>
1580 </html>
1581 EOF
1582 }
1583
1584 =head1 INTERNAL METHODS
1585
1586 These methods are not meant to be used by end users.
1587
1588 =head2 $c->components
1589
1590 Returns a hash of components.
1591
1592 =head2 $c->context_class
1593
1594 Returns or sets the context class.
1595
1596 =head2 $c->counter
1597
1598 Returns a hashref containing coderefs and execution counts (needed for
1599 deep recursion detection).
1600
1601 =head2 $c->depth
1602
1603 Returns the number of actions on the current internal execution stack.
1604
1605 =head2 $c->dispatch
1606
1607 Dispatches a request to actions.
1608
1609 =cut
1610
1611 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1612
1613 =head2 $c->dispatcher_class
1614
1615 Returns or sets the dispatcher class.
1616
1617 =head2 $c->dump_these
1618
1619 Returns a list of 2-element array references (name, structure) pairs
1620 that will be dumped on the error page in debug mode.
1621
1622 =cut
1623
1624 sub dump_these {
1625     my $c = shift;
1626     [ Request => $c->req ],
1627     [ Response => $c->res ],
1628     [ Stash => $c->stash ],
1629     [ Config => $c->config ];
1630 }
1631
1632 =head2 $c->engine_class
1633
1634 Returns or sets the engine class.
1635
1636 =head2 $c->execute( $class, $coderef )
1637
1638 Execute a coderef in given class and catch exceptions. Errors are available
1639 via $c->error.
1640
1641 =cut
1642
1643 sub execute {
1644     my ( $c, $class, $code ) = @_;
1645     $class = $c->component($class) || $class;
1646     $c->state(0);
1647
1648     if ( $c->depth >= $RECURSION ) {
1649         my $action = $code->reverse();
1650         $action = "/$action" unless $action =~ /->/;
1651         my $error = qq/Deep recursion detected calling "${action}"/;
1652         $c->log->error($error);
1653         $c->error($error);
1654         $c->state(0);
1655         return $c->state;
1656     }
1657
1658     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1659
1660     push( @{ $c->stack }, $code );
1661
1662     no warnings 'recursion';
1663     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1664
1665     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1666
1667     my $last = pop( @{ $c->stack } );
1668
1669     if ( my $error = $@ ) {
1670         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1671             $error->rethrow if $c->depth > 1;
1672         }
1673         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1674             $error->rethrow if $c->depth > 0;
1675         }
1676         else {
1677             unless ( ref $error ) {
1678                 no warnings 'uninitialized';
1679                 chomp $error;
1680                 my $class = $last->class;
1681                 my $name  = $last->name;
1682                 $error = qq/Caught exception in $class->$name "$error"/;
1683             }
1684             $c->error($error);
1685             $c->state(0);
1686         }
1687     }
1688     return $c->state;
1689 }
1690
1691 sub _stats_start_execute {
1692     my ( $c, $code ) = @_;
1693     my $appclass = ref($c) || $c;
1694     return if ( ( $code->name =~ /^_.*/ )
1695         && ( !$appclass->config->{show_internal_actions} ) );
1696
1697     my $action_name = $code->reverse();
1698     $c->counter->{$action_name}++;
1699
1700     my $action = $action_name;
1701     $action = "/$action" unless $action =~ /->/;
1702
1703     # determine if the call was the result of a forward
1704     # this is done by walking up the call stack and looking for a calling
1705     # sub of Catalyst::forward before the eval
1706     my $callsub = q{};
1707     for my $index ( 2 .. 11 ) {
1708         last
1709         if ( ( caller($index) )[0] eq 'Catalyst'
1710             && ( caller($index) )[3] eq '(eval)' );
1711
1712         if ( ( caller($index) )[3] =~ /forward$/ ) {
1713             $callsub = ( caller($index) )[3];
1714             $action  = "-> $action";
1715             last;
1716         }
1717     }
1718
1719     my $uid = $action_name . $c->counter->{$action_name};
1720
1721     # is this a root-level call or a forwarded call?
1722     if ( $callsub =~ /forward$/ ) {
1723         my $parent = $c->stack->[-1];
1724
1725         # forward, locate the caller
1726         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1727             $c->stats->profile(
1728                 begin  => $action,
1729                 parent => "$parent" . $c->counter->{"$parent"},
1730                 uid    => $uid,
1731             );
1732         }
1733         else {
1734
1735             # forward with no caller may come from a plugin
1736             $c->stats->profile(
1737                 begin => $action,
1738                 uid   => $uid,
1739             );
1740         }
1741     }
1742     else {
1743
1744         # root-level call
1745         $c->stats->profile(
1746             begin => $action,
1747             uid   => $uid,
1748         );
1749     }
1750     return $action;
1751
1752 }
1753
1754 sub _stats_finish_execute {
1755     my ( $c, $info ) = @_;
1756     $c->stats->profile( end => $info );
1757 }
1758
1759 =head2 $c->finalize
1760
1761 Finalizes the request.
1762
1763 =cut
1764
1765 sub finalize {
1766     my $c = shift;
1767
1768     for my $error ( @{ $c->error } ) {
1769         $c->log->error($error);
1770     }
1771
1772     # Allow engine to handle finalize flow (for POE)
1773     my $engine = $c->engine;
1774     if ( my $code = $engine->can('finalize') ) {
1775         $engine->$code($c);
1776     }
1777     else {
1778
1779         $c->finalize_uploads;
1780
1781         # Error
1782         if ( $#{ $c->error } >= 0 ) {
1783             $c->finalize_error;
1784         }
1785
1786         $c->finalize_headers;
1787
1788         # HEAD request
1789         if ( $c->request->method eq 'HEAD' ) {
1790             $c->response->body('');
1791         }
1792
1793         $c->finalize_body;
1794     }
1795
1796     $c->log_response;
1797
1798     if ($c->use_stats) {
1799         my $elapsed = sprintf '%f', $c->stats->elapsed;
1800         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1801         $c->log->info(
1802             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1803     }
1804
1805     return $c->response->status;
1806 }
1807
1808 =head2 $c->finalize_body
1809
1810 Finalizes body.
1811
1812 =cut
1813
1814 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1815
1816 =head2 $c->finalize_cookies
1817
1818 Finalizes cookies.
1819
1820 =cut
1821
1822 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1823
1824 =head2 $c->finalize_error
1825
1826 Finalizes error.
1827
1828 =cut
1829
1830 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1831
1832 =head2 $c->finalize_headers
1833
1834 Finalizes headers.
1835
1836 =cut
1837
1838 sub finalize_headers {
1839     my $c = shift;
1840
1841     my $response = $c->response; #accessor calls can add up?
1842
1843     # Check if we already finalized headers
1844     return if $response->finalized_headers;
1845
1846     # Handle redirects
1847     if ( my $location = $response->redirect ) {
1848         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1849         $response->header( Location => $location );
1850
1851         if ( !$response->has_body ) {
1852             # Add a default body if none is already present
1853             $response->body(
1854                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1855             );
1856         }
1857     }
1858
1859     # Content-Length
1860     if ( defined $response->body && length $response->body && !$response->content_length ) {
1861
1862         # get the length from a filehandle
1863         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1864         {
1865             my $stat = stat $response->body;
1866             if ( $stat && $stat->size > 0 ) {
1867                 $response->content_length( $stat->size );
1868             }
1869             else {
1870                 $c->log->warn('Serving filehandle without a content-length');
1871             }
1872         }
1873         else {
1874             # everything should be bytes at this point, but just in case
1875             $response->content_length( length( $response->body ) );
1876         }
1877     }
1878
1879     # Errors
1880     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1881         $response->headers->remove_header("Content-Length");
1882         $response->body('');
1883     }
1884
1885     $c->finalize_cookies;
1886
1887     $c->engine->finalize_headers( $c, @_ );
1888
1889     # Done
1890     $response->finalized_headers(1);
1891 }
1892
1893 =head2 $c->finalize_output
1894
1895 An alias for finalize_body.
1896
1897 =head2 $c->finalize_read
1898
1899 Finalizes the input after reading is complete.
1900
1901 =cut
1902
1903 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1904
1905 =head2 $c->finalize_uploads
1906
1907 Finalizes uploads. Cleans up any temporary files.
1908
1909 =cut
1910
1911 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1912
1913 =head2 $c->get_action( $action, $namespace )
1914
1915 Gets an action in a given namespace.
1916
1917 =cut
1918
1919 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1920
1921 =head2 $c->get_actions( $action, $namespace )
1922
1923 Gets all actions of a given name in a namespace and all parent
1924 namespaces.
1925
1926 =cut
1927
1928 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1929
1930 =head2 $app->handle_request( @arguments )
1931
1932 Called to handle each HTTP request.
1933
1934 =cut
1935
1936 sub handle_request {
1937     my ( $class, @arguments ) = @_;
1938
1939     # Always expect worst case!
1940     my $status = -1;
1941     eval {
1942         if ($class->debug) {
1943             my $secs = time - $START || 1;
1944             my $av = sprintf '%.3f', $COUNT / $secs;
1945             my $time = localtime time;
1946             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1947         }
1948
1949         my $c = $class->prepare(@arguments);
1950         $c->dispatch;
1951         $status = $c->finalize;
1952     };
1953
1954     if ( my $error = $@ ) {
1955         chomp $error;
1956         $class->log->error(qq/Caught exception in engine "$error"/);
1957     }
1958
1959     $COUNT++;
1960
1961     if(my $coderef = $class->log->can('_flush')){
1962         $class->log->$coderef();
1963     }
1964     return $status;
1965 }
1966
1967 =head2 $c->prepare( @arguments )
1968
1969 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1970 etc.).
1971
1972 =cut
1973
1974 sub prepare {
1975     my ( $class, @arguments ) = @_;
1976
1977     # XXX
1978     # After the app/ctxt split, this should become an attribute based on something passed
1979     # into the application.
1980     $class->context_class( ref $class || $class ) unless $class->context_class;
1981
1982     my $c = $class->context_class->new({});
1983
1984     # For on-demand data
1985     $c->request->_context($c);
1986     $c->response->_context($c);
1987
1988     #surely this is not the most efficient way to do things...
1989     $c->stats($class->stats_class->new)->enable($c->use_stats);
1990     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1991         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1992     }
1993
1994     #XXX reuse coderef from can
1995     # Allow engine to direct the prepare flow (for POE)
1996     if ( $c->engine->can('prepare') ) {
1997         $c->engine->prepare( $c, @arguments );
1998     }
1999     else {
2000         $c->prepare_request(@arguments);
2001         $c->prepare_connection;
2002         $c->prepare_query_parameters;
2003         $c->prepare_headers;
2004         $c->prepare_cookies;
2005         $c->prepare_path;
2006
2007         # Prepare the body for reading, either by prepare_body
2008         # or the user, if they are using $c->read
2009         $c->prepare_read;
2010
2011         # Parse the body unless the user wants it on-demand
2012         unless ( ref($c)->config->{parse_on_demand} ) {
2013             $c->prepare_body;
2014         }
2015     }
2016
2017     my $method  = $c->req->method  || '';
2018     my $path    = $c->req->path;
2019     $path       = '/' unless length $path;
2020     my $address = $c->req->address || '';
2021
2022     $c->log_request;
2023
2024     $c->prepare_action;
2025
2026     return $c;
2027 }
2028
2029 =head2 $c->prepare_action
2030
2031 Prepares action. See L<Catalyst::Dispatcher>.
2032
2033 =cut
2034
2035 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2036
2037 =head2 $c->prepare_body
2038
2039 Prepares message body.
2040
2041 =cut
2042
2043 sub prepare_body {
2044     my $c = shift;
2045
2046     return if $c->request->_has_body;
2047
2048     # Initialize on-demand data
2049     $c->engine->prepare_body( $c, @_ );
2050     $c->prepare_parameters;
2051     $c->prepare_uploads;
2052 }
2053
2054 =head2 $c->prepare_body_chunk( $chunk )
2055
2056 Prepares a chunk of data before sending it to L<HTTP::Body>.
2057
2058 See L<Catalyst::Engine>.
2059
2060 =cut
2061
2062 sub prepare_body_chunk {
2063     my $c = shift;
2064     $c->engine->prepare_body_chunk( $c, @_ );
2065 }
2066
2067 =head2 $c->prepare_body_parameters
2068
2069 Prepares body parameters.
2070
2071 =cut
2072
2073 sub prepare_body_parameters {
2074     my $c = shift;
2075     $c->engine->prepare_body_parameters( $c, @_ );
2076 }
2077
2078 =head2 $c->prepare_connection
2079
2080 Prepares connection.
2081
2082 =cut
2083
2084 sub prepare_connection {
2085     my $c = shift;
2086     $c->engine->prepare_connection( $c, @_ );
2087 }
2088
2089 =head2 $c->prepare_cookies
2090
2091 Prepares cookies.
2092
2093 =cut
2094
2095 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2096
2097 =head2 $c->prepare_headers
2098
2099 Prepares headers.
2100
2101 =cut
2102
2103 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2104
2105 =head2 $c->prepare_parameters
2106
2107 Prepares parameters.
2108
2109 =cut
2110
2111 sub prepare_parameters {
2112     my $c = shift;
2113     $c->prepare_body_parameters;
2114     $c->engine->prepare_parameters( $c, @_ );
2115 }
2116
2117 =head2 $c->prepare_path
2118
2119 Prepares path and base.
2120
2121 =cut
2122
2123 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2124
2125 =head2 $c->prepare_query_parameters
2126
2127 Prepares query parameters.
2128
2129 =cut
2130
2131 sub prepare_query_parameters {
2132     my $c = shift;
2133
2134     $c->engine->prepare_query_parameters( $c, @_ );
2135 }
2136
2137 =head2 $c->log_request
2138
2139 Writes information about the request to the debug logs.  This includes:
2140
2141 =over 4
2142
2143 =item * Request method, path, and remote IP address
2144
2145 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2146
2147 =item * Request parameters
2148
2149 =item * File uploads
2150
2151 =back
2152
2153 =cut
2154
2155 sub log_request {
2156     my $c = shift;
2157
2158     return unless $c->debug;
2159
2160     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2161     my $request = $dump->[1];
2162
2163     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2164     $method ||= '';
2165     $path = '/' unless length $path;
2166     $address ||= '';
2167     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2168
2169     $c->log_request_headers($request->headers);
2170
2171     if ( my $keywords = $request->query_keywords ) {
2172         $c->log->debug("Query keywords are: $keywords");
2173     }
2174
2175     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2176
2177     $c->log_request_uploads($request);
2178 }
2179
2180 =head2 $c->log_response
2181
2182 Writes information about the response to the debug logs by calling
2183 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2184
2185 =cut
2186
2187 sub log_response {
2188     my $c = shift;
2189
2190     return unless $c->debug;
2191
2192     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2193     my $response = $dump->[1];
2194
2195     $c->log_response_status_line($response);
2196     $c->log_response_headers($response->headers);
2197 }
2198
2199 =head2 $c->log_response_status_line($response)
2200
2201 Writes one line of information about the response to the debug logs.  This includes:
2202
2203 =over 4
2204
2205 =item * Response status code
2206
2207 =item * Content-Type header (if present)
2208
2209 =item * Content-Length header (if present)
2210
2211 =back
2212
2213 =cut
2214
2215 sub log_response_status_line {
2216     my ($c, $response) = @_;
2217
2218     $c->log->debug(
2219         sprintf(
2220             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2221             $response->status                            || 'unknown',
2222             $response->headers->header('Content-Type')   || 'unknown',
2223             $response->headers->header('Content-Length') || 'unknown'
2224         )
2225     );
2226 }
2227
2228 =head2 $c->log_response_headers($headers);
2229
2230 Hook method which can be wrapped by plugins to log the responseheaders.
2231 No-op in the default implementation.
2232
2233 =cut
2234
2235 sub log_response_headers {}
2236
2237 =head2 $c->log_request_parameters( query => {}, body => {} )
2238
2239 Logs request parameters to debug logs
2240
2241 =cut
2242
2243 sub log_request_parameters {
2244     my $c          = shift;
2245     my %all_params = @_;
2246
2247     return unless $c->debug;
2248
2249     my $column_width = Catalyst::Utils::term_width() - 44;
2250     foreach my $type (qw(query body)) {
2251         my $params = $all_params{$type};
2252         next if ! keys %$params;
2253         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2254         for my $key ( sort keys %$params ) {
2255             my $param = $params->{$key};
2256             my $value = defined($param) ? $param : '';
2257             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2258         }
2259         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2260     }
2261 }
2262
2263 =head2 $c->log_request_uploads
2264
2265 Logs file uploads included in the request to the debug logs.
2266 The parameter name, filename, file type, and file size are all included in
2267 the debug logs.
2268
2269 =cut
2270
2271 sub log_request_uploads {
2272     my $c = shift;
2273     my $request = shift;
2274     return unless $c->debug;
2275     my $uploads = $request->uploads;
2276     if ( keys %$uploads ) {
2277         my $t = Text::SimpleTable->new(
2278             [ 12, 'Parameter' ],
2279             [ 26, 'Filename' ],
2280             [ 18, 'Type' ],
2281             [ 9,  'Size' ]
2282         );
2283         for my $key ( sort keys %$uploads ) {
2284             my $upload = $uploads->{$key};
2285             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2286                 $t->row( $key, $u->filename, $u->type, $u->size );
2287             }
2288         }
2289         $c->log->debug( "File Uploads are:\n" . $t->draw );
2290     }
2291 }
2292
2293 =head2 $c->log_request_headers($headers);
2294
2295 Hook method which can be wrapped by plugins to log the request headers.
2296 No-op in the default implementation.
2297
2298 =cut
2299
2300 sub log_request_headers {}
2301
2302 =head2 $c->log_headers($type => $headers)
2303
2304 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2305
2306 =cut
2307
2308 sub log_headers {
2309     my $c       = shift;
2310     my $type    = shift;
2311     my $headers = shift;    # an HTTP::Headers instance
2312
2313     return unless $c->debug;
2314
2315     my $column_width = Catalyst::Utils::term_width() - 28;
2316     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2317     $headers->scan(
2318         sub {
2319             my ( $name, $value ) = @_;
2320             $t->row( $name, $value );
2321         }
2322     );
2323     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2324 }
2325
2326
2327 =head2 $c->prepare_read
2328
2329 Prepares the input for reading.
2330
2331 =cut
2332
2333 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2334
2335 =head2 $c->prepare_request
2336
2337 Prepares the engine request.
2338
2339 =cut
2340
2341 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2342
2343 =head2 $c->prepare_uploads
2344
2345 Prepares uploads.
2346
2347 =cut
2348
2349 sub prepare_uploads {
2350     my $c = shift;
2351
2352     $c->engine->prepare_uploads( $c, @_ );
2353 }
2354
2355 =head2 $c->prepare_write
2356
2357 Prepares the output for writing.
2358
2359 =cut
2360
2361 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2362
2363 =head2 $c->request_class
2364
2365 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2366
2367 =head2 $c->response_class
2368
2369 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2370
2371 =head2 $c->read( [$maxlength] )
2372
2373 Reads a chunk of data from the request body. This method is designed to
2374 be used in a while loop, reading C<$maxlength> bytes on every call.
2375 C<$maxlength> defaults to the size of the request if not specified.
2376
2377 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2378 directly.
2379
2380 Warning: If you use read(), Catalyst will not process the body,
2381 so you will not be able to access POST parameters or file uploads via
2382 $c->request.  You must handle all body parsing yourself.
2383
2384 =cut
2385
2386 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2387
2388 =head2 $c->run
2389
2390 Starts the engine.
2391
2392 =cut
2393
2394 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2395
2396 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2397
2398 Sets an action in a given namespace.
2399
2400 =cut
2401
2402 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2403
2404 =head2 $c->setup_actions($component)
2405
2406 Sets up actions for a component.
2407
2408 =cut
2409
2410 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2411
2412 =head2 $c->setup_components
2413
2414 This method is called internally to set up the application's components.
2415
2416 It finds modules by calling the L<locate_components> method, expands them to
2417 package names with the L<expand_component_module> method, and then installs
2418 each component into the application.
2419
2420 The C<setup_components> config option is passed to both of the above methods.
2421
2422 Installation of each component is performed by the L<setup_component> method,
2423 below.
2424
2425 =cut
2426
2427 sub setup_components {
2428     my $class = shift;
2429
2430     my $config  = $class->config->{ setup_components };
2431
2432     my @comps = $class->locate_components($config);
2433     my %comps = map { $_ => 1 } @comps;
2434
2435     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2436     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2437         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2438     ) if $deprecatedcatalyst_component_names;
2439
2440     for my $component ( @comps ) {
2441
2442         # We pass ignore_loaded here so that overlay files for (e.g.)
2443         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2444         # we know M::P::O found a file on disk so this is safe
2445
2446         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2447     }
2448
2449     for my $component (@comps) {
2450         my $instance = $class->components->{ $component } = $class->setup_component($component);
2451         my @expanded_components = $instance->can('expand_modules')
2452             ? $instance->expand_modules( $component, $config )
2453             : $class->expand_component_module( $component, $config );
2454         for my $component (@expanded_components) {
2455             next if $comps{$component};
2456             $class->components->{ $component } = $class->setup_component($component);
2457         }
2458     }
2459 }
2460
2461 =head2 $c->locate_components( $setup_component_config )
2462
2463 This method is meant to provide a list of component modules that should be
2464 setup for the application.  By default, it will use L<Module::Pluggable>.
2465
2466 Specify a C<setup_components> config option to pass additional options directly
2467 to L<Module::Pluggable>. To add additional search paths, specify a key named
2468 C<search_extra> as an array reference. Items in the array beginning with C<::>
2469 will have the application class name prepended to them.
2470
2471 =cut
2472
2473 sub locate_components {
2474     my $class  = shift;
2475     my $config = shift;
2476
2477     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2478     my $extra   = delete $config->{ search_extra } || [];
2479
2480     push @paths, @$extra;
2481
2482     my $locator = Module::Pluggable::Object->new(
2483         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2484         %$config
2485     );
2486
2487     # XXX think about ditching this sort entirely
2488     my @comps = sort { length $a <=> length $b } $locator->plugins;
2489
2490     return @comps;
2491 }
2492
2493 =head2 $c->expand_component_module( $component, $setup_component_config )
2494
2495 Components found by C<locate_components> will be passed to this method, which
2496 is expected to return a list of component (package) names to be set up.
2497
2498 =cut
2499
2500 sub expand_component_module {
2501     my ($class, $module) = @_;
2502     return Devel::InnerPackage::list_packages( $module );
2503 }
2504
2505 =head2 $c->setup_component
2506
2507 =cut
2508
2509 sub setup_component {
2510     my( $class, $component ) = @_;
2511
2512     unless ( $component->can( 'COMPONENT' ) ) {
2513         return $component;
2514     }
2515
2516     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2517     my $config = $class->config->{ $suffix } || {};
2518     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2519     # methods also pass it. local to avoid pointlessly shitting in config
2520     # for the debug screen, as $component is already the key name.
2521     local $config->{catalyst_component_name} = $component;
2522
2523     my $instance = eval { $component->COMPONENT( $class, $config ); };
2524
2525     if ( my $error = $@ ) {
2526         chomp $error;
2527         Catalyst::Exception->throw(
2528             message => qq/Couldn't instantiate component "$component", "$error"/
2529         );
2530     }
2531
2532     unless (blessed $instance) {
2533         my $metaclass = Moose::Util::find_meta($component);
2534         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2535         my $component_method_from = $method_meta->associated_metaclass->name;
2536         my $value = defined($instance) ? $instance : 'undef';
2537         Catalyst::Exception->throw(
2538             message =>
2539             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2540         );
2541     }
2542     return $instance;
2543 }
2544
2545 =head2 $c->setup_dispatcher
2546
2547 Sets up dispatcher.
2548
2549 =cut
2550
2551 sub setup_dispatcher {
2552     my ( $class, $dispatcher ) = @_;
2553
2554     if ($dispatcher) {
2555         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2556     }
2557
2558     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2559         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2560     }
2561
2562     unless ($dispatcher) {
2563         $dispatcher = $class->dispatcher_class;
2564     }
2565
2566     Class::MOP::load_class($dispatcher);
2567
2568     # dispatcher instance
2569     $class->dispatcher( $dispatcher->new );
2570 }
2571
2572 =head2 $c->setup_engine
2573
2574 Sets up engine.
2575
2576 =cut
2577
2578 sub setup_engine {
2579     my ( $class, $engine ) = @_;
2580
2581     if ($engine) {
2582         $engine = 'Catalyst::Engine::' . $engine;
2583     }
2584
2585     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2586         $engine = 'Catalyst::Engine::' . $env;
2587     }
2588
2589     if ( $ENV{MOD_PERL} ) {
2590         my $meta = Class::MOP::get_metaclass_by_name($class);
2591
2592         # create the apache method
2593         $meta->add_method('apache' => sub { shift->engine->apache });
2594
2595         my ( $software, $version ) =
2596           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2597
2598         $version =~ s/_//g;
2599         $version =~ s/(\.[^.]+)\./$1/g;
2600
2601         if ( $software eq 'mod_perl' ) {
2602
2603             if ( !$engine ) {
2604
2605                 if ( $version >= 1.99922 ) {
2606                     $engine = 'Catalyst::Engine::Apache2::MP20';
2607                 }
2608
2609                 elsif ( $version >= 1.9901 ) {
2610                     $engine = 'Catalyst::Engine::Apache2::MP19';
2611                 }
2612
2613                 elsif ( $version >= 1.24 ) {
2614                     $engine = 'Catalyst::Engine::Apache::MP13';
2615                 }
2616
2617                 else {
2618                     Catalyst::Exception->throw( message =>
2619                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2620                 }
2621
2622             }
2623
2624             # install the correct mod_perl handler
2625             if ( $version >= 1.9901 ) {
2626                 *handler = sub  : method {
2627                     shift->handle_request(@_);
2628                 };
2629             }
2630             else {
2631                 *handler = sub ($$) { shift->handle_request(@_) };
2632             }
2633
2634         }
2635
2636         elsif ( $software eq 'Zeus-Perl' ) {
2637             $engine = 'Catalyst::Engine::Zeus';
2638         }
2639
2640         else {
2641             Catalyst::Exception->throw(
2642                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2643         }
2644     }
2645
2646     unless ($engine) {
2647         $engine = $class->engine_class;
2648     }
2649
2650     Class::MOP::load_class($engine);
2651
2652     # check for old engines that are no longer compatible
2653     my $old_engine;
2654     if ( $engine->isa('Catalyst::Engine::Apache')
2655         && !Catalyst::Engine::Apache->VERSION )
2656     {
2657         $old_engine = 1;
2658     }
2659
2660     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2661         && Catalyst::Engine::Server->VERSION le '0.02' )
2662     {
2663         $old_engine = 1;
2664     }
2665
2666     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2667         && $engine->VERSION eq '0.01' )
2668     {
2669         $old_engine = 1;
2670     }
2671
2672     elsif ($engine->isa('Catalyst::Engine::Zeus')
2673         && $engine->VERSION eq '0.01' )
2674     {
2675         $old_engine = 1;
2676     }
2677
2678     if ($old_engine) {
2679         Catalyst::Exception->throw( message =>
2680               qq/Engine "$engine" is not supported by this version of Catalyst/
2681         );
2682     }
2683
2684     # engine instance
2685     $class->engine( $engine->new );
2686 }
2687
2688 =head2 $c->setup_home
2689
2690 Sets up the home directory.
2691
2692 =cut
2693
2694 sub setup_home {
2695     my ( $class, $home ) = @_;
2696
2697     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2698         $home = $env;
2699     }
2700
2701     $home ||= Catalyst::Utils::home($class);
2702
2703     if ($home) {
2704         #I remember recently being scolded for assigning config values like this
2705         $class->config->{home} ||= $home;
2706         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2707     }
2708 }
2709
2710 =head2 $c->setup_log
2711
2712 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2713 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2714 log to.
2715
2716 This method also installs a C<debug> method that returns a true value into the
2717 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2718 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2719
2720 Note that if the log has already been setup, by either a previous call to
2721 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2722 that this method won't actually set up the log object.
2723
2724 =cut
2725
2726 sub setup_log {
2727     my ( $class, $levels ) = @_;
2728
2729     $levels ||= '';
2730     $levels =~ s/^\s+//;
2731     $levels =~ s/\s+$//;
2732     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2733
2734     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2735     if ( defined $env_debug ) {
2736         $levels{debug} = 1 if $env_debug; # Ugly!
2737         delete($levels{debug}) unless $env_debug;
2738     }
2739
2740     unless ( $class->log ) {
2741         $class->log( Catalyst::Log->new(keys %levels) );
2742     }
2743
2744     if ( $levels{debug} ) {
2745         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2746         $class->log->debug('Debug messages enabled');
2747     }
2748 }
2749
2750 =head2 $c->setup_plugins
2751
2752 Sets up plugins.
2753
2754 =cut
2755
2756 =head2 $c->setup_stats
2757
2758 Sets up timing statistics class.
2759
2760 =cut
2761
2762 sub setup_stats {
2763     my ( $class, $stats ) = @_;
2764
2765     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2766
2767     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2768     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2769         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2770         $class->log->debug('Statistics enabled');
2771     }
2772 }
2773
2774
2775 =head2 $c->registered_plugins
2776
2777 Returns a sorted list of the plugins which have either been stated in the
2778 import list or which have been added via C<< MyApp->plugin(@args); >>.
2779
2780 If passed a given plugin name, it will report a boolean value indicating
2781 whether or not that plugin is loaded.  A fully qualified name is required if
2782 the plugin name does not begin with C<Catalyst::Plugin::>.
2783
2784  if ($c->registered_plugins('Some::Plugin')) {
2785      ...
2786  }
2787
2788 =cut
2789
2790 {
2791
2792     sub registered_plugins {
2793         my $proto = shift;
2794         return sort keys %{ $proto->_plugins } unless @_;
2795         my $plugin = shift;
2796         return 1 if exists $proto->_plugins->{$plugin};
2797         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2798     }
2799
2800     sub _register_plugin {
2801         my ( $proto, $plugin, $instant ) = @_;
2802         my $class = ref $proto || $proto;
2803
2804         Class::MOP::load_class( $plugin );
2805         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2806             if $plugin->isa( 'Catalyst::Component' );
2807         $proto->_plugins->{$plugin} = 1;
2808         unless ($instant) {
2809             my $meta = Class::MOP::get_metaclass_by_name($class);
2810             $meta->superclasses($plugin, $meta->superclasses);
2811         }
2812         return $class;
2813     }
2814
2815     sub setup_plugins {
2816         my ( $class, $plugins ) = @_;
2817
2818         $class->_plugins( {} ) unless $class->_plugins;
2819         $plugins = Data::OptList::mkopt($plugins || []);
2820
2821         my @plugins = map {
2822             [ Catalyst::Utils::resolve_namespace(
2823                   $class . '::Plugin',
2824                   'Catalyst::Plugin', $_->[0]
2825               ),
2826               $_->[1],
2827             ]
2828          } @{ $plugins };
2829
2830         for my $plugin ( reverse @plugins ) {
2831             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2832             my $meta = find_meta($plugin->[0]);
2833             next if $meta && $meta->isa('Moose::Meta::Role');
2834
2835             $class->_register_plugin($plugin->[0]);
2836         }
2837
2838         my @roles =
2839             map  { $_->[0]->name, $_->[1] }
2840             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2841             map  { [find_meta($_->[0]), $_->[1]] }
2842             @plugins;
2843
2844         Moose::Util::apply_all_roles(
2845             $class => @roles
2846         ) if @roles;
2847     }
2848 }
2849
2850 =head2 $c->stack
2851
2852 Returns an arrayref of the internal execution stack (actions that are
2853 currently executing).
2854
2855 =head2 $c->stats
2856
2857 Returns the current timing statistics object. By default Catalyst uses
2858 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2859 L<< stats_class|/"$c->stats_class" >>.
2860
2861 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2862 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2863 profile explicitly, although MyApp.pm still won't profile nor output anything
2864 by itself.
2865
2866 =head2 $c->stats_class
2867
2868 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2869
2870 =head2 $c->use_stats
2871
2872 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2873
2874 Note that this is a static method, not an accessor and should be overridden
2875 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2876
2877 =cut
2878
2879 sub use_stats { 0 }
2880
2881
2882 =head2 $c->write( $data )
2883
2884 Writes $data to the output stream. When using this method directly, you
2885 will need to manually set the C<Content-Length> header to the length of
2886 your output data, if known.
2887
2888 =cut
2889
2890 sub write {
2891     my $c = shift;
2892
2893     # Finalize headers if someone manually writes output
2894     $c->finalize_headers;
2895
2896     return $c->engine->write( $c, @_ );
2897 }
2898
2899 =head2 version
2900
2901 Returns the Catalyst version number. Mostly useful for "powered by"
2902 messages in template systems.
2903
2904 =cut
2905
2906 sub version { return $Catalyst::VERSION }
2907
2908 =head1 CONFIGURATION
2909
2910 There are a number of 'base' config variables which can be set:
2911
2912 =over
2913
2914 =item *
2915
2916 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2917
2918 =item *
2919
2920 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2921
2922 =item *
2923
2924 C<disable_component_resolution_regex_fallback> - Turns
2925 off the deprecated component resolution functionality so
2926 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2927 are called then regex search will not be attempted on string values and
2928 instead C<undef> will be returned.
2929
2930 =item *
2931
2932 C<home> - The application home directory. In an uninstalled application,
2933 this is the top level application directory. In an installed application,
2934 this will be the directory containing C<< MyApp.pm >>.
2935
2936 =item *
2937
2938 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2939
2940 =item *
2941
2942 C<name> - The name of the application in debug messages and the debug and
2943 welcome screens
2944
2945 =item *
2946
2947 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2948 until it is accessed. This allows you to (for example) check authentication (and reject
2949 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2950
2951 =item *
2952
2953 C<root> - The root directory for templates. Usually this is just a
2954 subdirectory of the home directory, but you can set it to change the
2955 templates to a different directory.
2956
2957 =item *
2958
2959 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2960 namespaces from which components will be loaded (and constructed and stored in
2961 C<< $c->components >>).
2962
2963 =item *
2964
2965 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2966 to be shown in hit debug tables in the test server.
2967
2968 =item *
2969
2970 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
2971 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
2972 for more information.
2973
2974 =item *
2975
2976 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2977
2978 =back
2979
2980 =head1 INTERNAL ACTIONS
2981
2982 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2983 C<_ACTION>, and C<_END>. These are by default not shown in the private
2984 action table, but you can make them visible with a config parameter.
2985
2986     MyApp->config(show_internal_actions => 1);
2987
2988 =head1 ON-DEMAND PARSER
2989
2990 The request body is usually parsed at the beginning of a request,
2991 but if you want to handle input yourself, you can enable on-demand
2992 parsing with a config parameter.
2993
2994     MyApp->config(parse_on_demand => 1);
2995
2996 =head1 PROXY SUPPORT
2997
2998 Many production servers operate using the common double-server approach,
2999 with a lightweight frontend web server passing requests to a larger
3000 backend server. An application running on the backend server must deal
3001 with two problems: the remote user always appears to be C<127.0.0.1> and
3002 the server's hostname will appear to be C<localhost> regardless of the
3003 virtual host that the user connected through.
3004
3005 Catalyst will automatically detect this situation when you are running
3006 the frontend and backend servers on the same machine. The following
3007 changes are made to the request.
3008
3009     $c->req->address is set to the user's real IP address, as read from
3010     the HTTP X-Forwarded-For header.
3011
3012     The host value for $c->req->base and $c->req->uri is set to the real
3013     host, as read from the HTTP X-Forwarded-Host header.
3014
3015 Additionally, you may be running your backend application on an insecure
3016 connection (port 80) while your frontend proxy is running under SSL.  If there
3017 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3018 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3019 be created properly.
3020
3021 In the case of passing in:
3022
3023     X-Forwarded-Port: 443
3024
3025 All calls to C<uri_for> will result in an https link, as is expected.
3026
3027 Obviously, your web server must support these headers for this to work.
3028
3029 In a more complex server farm environment where you may have your
3030 frontend proxy server(s) on different machines, you will need to set a
3031 configuration option to tell Catalyst to read the proxied data from the
3032 headers.
3033
3034     MyApp->config(using_frontend_proxy => 1);
3035
3036 If you do not wish to use the proxy support at all, you may set:
3037
3038     MyApp->config(ignore_frontend_proxy => 1);
3039
3040 =head1 THREAD SAFETY
3041
3042 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3043 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3044 believe the Catalyst core to be thread-safe.
3045
3046 If you plan to operate in a threaded environment, remember that all other
3047 modules you are using must also be thread-safe. Some modules, most notably
3048 L<DBD::SQLite>, are not thread-safe.
3049
3050 =head1 SUPPORT
3051
3052 IRC:
3053
3054     Join #catalyst on irc.perl.org.
3055
3056 Mailing Lists:
3057
3058     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3059     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3060
3061 Web:
3062
3063     http://catalyst.perl.org
3064
3065 Wiki:
3066
3067     http://dev.catalyst.perl.org
3068
3069 =head1 SEE ALSO
3070
3071 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3072
3073 =head2 L<Catalyst::Manual> - The Catalyst Manual
3074
3075 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3076
3077 =head2 L<Catalyst::Engine> - Core engine
3078
3079 =head2 L<Catalyst::Log> - Log class.
3080
3081 =head2 L<Catalyst::Request> - Request object
3082
3083 =head2 L<Catalyst::Response> - Response object
3084
3085 =head2 L<Catalyst::Test> - The test suite.
3086
3087 =head1 PROJECT FOUNDER
3088
3089 sri: Sebastian Riedel <sri@cpan.org>
3090
3091 =head1 CONTRIBUTORS
3092
3093 abw: Andy Wardley
3094
3095 acme: Leon Brocard <leon@astray.com>
3096
3097 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3098
3099 Andrew Bramble
3100
3101 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3102
3103 Andrew Ruthven
3104
3105 andyg: Andy Grundman <andy@hybridized.org>
3106
3107 audreyt: Audrey Tang
3108
3109 bricas: Brian Cassidy <bricas@cpan.org>
3110
3111 Caelum: Rafael Kitover <rkitover@io.com>
3112
3113 chansen: Christian Hansen
3114
3115 chicks: Christopher Hicks
3116
3117 Chisel Wright C<pause@herlpacker.co.uk>
3118
3119 Danijel Milicevic C<me@danijel.de>
3120
3121 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3122
3123 David Naughton, C<naughton@umn.edu>
3124
3125 David E. Wheeler
3126
3127 dhoss: Devin Austin <dhoss@cpan.org>
3128
3129 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3130
3131 Drew Taylor
3132
3133 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3134
3135 esskar: Sascha Kiefer
3136
3137 fireartist: Carl Franks <cfranks@cpan.org>
3138
3139 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3140
3141 gabb: Danijel Milicevic
3142
3143 Gary Ashton Jones
3144
3145 Gavin Henry C<ghenry@perl.me.uk>
3146
3147 Geoff Richards
3148
3149 groditi: Guillermo Roditi <groditi@gmail.com>
3150
3151 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3152
3153 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3154
3155 jcamacho: Juan Camacho
3156
3157 jester: Jesse Sheidlower C<jester@panix.com>
3158
3159 jhannah: Jay Hannah <jay@jays.net>
3160
3161 Jody Belka
3162
3163 Johan Lindstrom
3164
3165 jon: Jon Schutz <jjschutz@cpan.org>
3166
3167 Jonathan Rockway C<< <jrockway@cpan.org> >>
3168
3169 Kieren Diment C<kd@totaldatasolution.com>
3170
3171 konobi: Scott McWhirter <konobi@cpan.org>
3172
3173 marcus: Marcus Ramberg <mramberg@cpan.org>
3174
3175 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3176
3177 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3178
3179 mugwump: Sam Vilain
3180
3181 naughton: David Naughton
3182
3183 ningu: David Kamholz <dkamholz@cpan.org>
3184
3185 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3186
3187 numa: Dan Sully <daniel@cpan.org>
3188
3189 obra: Jesse Vincent
3190
3191 Octavian Rasnita
3192
3193 omega: Andreas Marienborg
3194
3195 Oleg Kostyuk <cub.uanic@gmail.com>
3196
3197 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3198
3199 rafl: Florian Ragwitz <rafl@debian.org>
3200
3201 random: Roland Lammel <lammel@cpan.org>
3202
3203 Robert Sedlacek C<< <rs@474.at> >>
3204
3205 SpiceMan: Marcel Montes
3206
3207 sky: Arthur Bergman
3208
3209 szbalint: Balint Szilakszi <szbalint@cpan.org>
3210
3211 t0m: Tomas Doran <bobtfish@bobtfish.net>
3212
3213 Ulf Edvinsson
3214
3215 Viljo Marrandi C<vilts@yahoo.com>
3216
3217 Will Hawes C<info@whawes.co.uk>
3218
3219 willert: Sebastian Willert <willert@cpan.org>
3220
3221 wreis: Wallace Reis <wallace@reis.org.br>
3222
3223 Yuval Kogman, C<nothingmuch@woobling.org>
3224
3225 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3226
3227 =head1 LICENSE
3228
3229 This library is free software. You can redistribute it and/or modify it under
3230 the same terms as Perl itself.
3231
3232 =cut
3233
3234 no Moose;
3235
3236 __PACKAGE__->meta->make_immutable;
3237
3238 1;