lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use File::stat;
  20 use Module::Pluggable::Object ();
  21 use Text::SimpleTable ();
  22 use Path::Class::Dir ();
  23 use Path::Class::File ();
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use utf8;
  33 use Carp qw/croak carp shortmess/;
  34
  35 BEGIN { require 5.008004; }
  36
  37 has stack => (is => 'ro', default => sub { [] });
  38 has stash => (is => 'rw', default => sub { {} });
  39 has state => (is => 'rw', default => 0);
  40 has stats => (is => 'rw');
  41 has action => (is => 'rw');
  42 has counter => (is => 'rw', default => sub { {} });
  43 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  44 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  45 has namespace => (is => 'rw');
  46
  47 sub depth { scalar @{ shift->stack || [] }; }
  48 sub comp { shift->component(@_) }
  49
  50 sub req {
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     my $self = shift; return $self->response(@_);
  55 }
  56
  57 # For backwards compatibility
  58 sub finalize_output { shift->finalize_body(@_) };
  59
  60 # For statistics
  61 our $COUNT     = 1;
  62 our $START     = time;
  63 our $RECURSION = 1000;
  64 our $DETACH    = Catalyst::Exception::Detach->new;
  65 our $GO        = Catalyst::Exception::Go->new;
  66
  67 #I imagine that very few of these really need to be class variables. if any.
  68 #maybe we should just make them attributes with a default?
  69 __PACKAGE__->mk_classdata($_)
  70   for qw/container components arguments dispatcher engine log dispatcher_class
  71   engine_class context_class request_class response_class stats_class
  72   setup_finished/;
  73
  74 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  75 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  76 __PACKAGE__->request_class('Catalyst::Request');
  77 __PACKAGE__->response_class('Catalyst::Response');
  78 __PACKAGE__->stats_class('Catalyst::Stats');
  79
  80 # Remember to update this in Catalyst::Runtime as well!
  81
  82 our $VERSION = '5.80032';
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         if ($Moose::VERSION >= 1.15) {
 104             $meta->_add_meta_method('meta');
 105         }
 106         else {
 107             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 108         }
 109     }
 110
 111     $caller->arguments( [@arguments] );
 112     $caller->setup_home;
 113 }
 114
 115 sub _application { $_[0] }
 116
 117 =head1 NAME
 118
 119 Catalyst - The Elegant MVC Web Application Framework
 120
 121 =head1 SYNOPSIS
 122
 123 See the L<Catalyst::Manual> distribution for comprehensive
 124 documentation and tutorials.
 125
 126     # Install Catalyst::Devel for helpers and other development tools
 127     # use the helper to create a new application
 128     catalyst.pl MyApp
 129
 130     # add models, views, controllers
 131     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 132     script/myapp_create.pl view MyTemplate TT
 133     script/myapp_create.pl controller Search
 134
 135     # built in testserver -- use -r to restart automatically on changes
 136     # --help to see all available options
 137     script/myapp_server.pl
 138
 139     # command line testing interface
 140     script/myapp_test.pl /yada
 141
 142     ### in lib/MyApp.pm
 143     use Catalyst qw/-Debug/; # include plugins here as well
 144
 145     ### In lib/MyApp/Controller/Root.pm (autocreated)
 146     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 147         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 148         $c->stash->{template} = 'foo.tt'; # set the template
 149         # lookup something from db -- stash vars are passed to TT
 150         $c->stash->{data} =
 151           $c->model('Database::Foo')->search( { country => $args[0] } );
 152         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 153             $c->forward( 'bar' ); # process another action
 154             # do something else after forward returns
 155         }
 156     }
 157
 158     # The foo.tt TT template can use the stash data from the database
 159     [% WHILE (item = data.next) %]
 160         [% item.foo %]
 161     [% END %]
 162
 163     # called for /bar/of/soap, /bar/of/soap/10, etc.
 164     sub bar : Path('/bar/of/soap') { ... }
 165
 166     # called for all actions, from the top-most controller downwards
 167     sub auto : Private {
 168         my ( $self, $c ) = @_;
 169         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 170             $c->res->redirect( '/login' ); # require login
 171             return 0; # abort request and go immediately to end()
 172         }
 173         return 1; # success; carry on to next action
 174     }
 175
 176     # called after all actions are finished
 177     sub end : Private {
 178         my ( $self, $c ) = @_;
 179         if ( scalar @{ $c->error } ) { ... } # handle errors
 180         return if $c->res->body; # already have a response
 181         $c->forward( 'MyApp::View::TT' ); # render template
 182     }
 183
 184     ### in MyApp/Controller/Foo.pm
 185     # called for /foo/bar
 186     sub bar : Local { ... }
 187
 188     # called for /blargle
 189     sub blargle : Global { ... }
 190
 191     # an index action matches /foo, but not /foo/1, etc.
 192     sub index : Private { ... }
 193
 194     ### in MyApp/Controller/Foo/Bar.pm
 195     # called for /foo/bar/baz
 196     sub baz : Local { ... }
 197
 198     # first Root auto is called, then Foo auto, then this
 199     sub auto : Private { ... }
 200
 201     # powerful regular expression paths are also possible
 202     sub details : Regex('^product/(\w+)/details$') {
 203         my ( $self, $c ) = @_;
 204         # extract the (\w+) from the URI
 205         my $product = $c->req->captures->[0];
 206     }
 207
 208 See L<Catalyst::Manual::Intro> for additional information.
 209
 210 =head1 DESCRIPTION
 211
 212 Catalyst is a modern framework for making web applications without the
 213 pain usually associated with this process. This document is a reference
 214 to the main Catalyst application. If you are a new user, we suggest you
 215 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 216
 217 See L<Catalyst::Manual> for more documentation.
 218
 219 Catalyst plugins can be loaded by naming them as arguments to the "use
 220 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 221 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 222 C<My::Module>.
 223
 224     use Catalyst qw/My::Module/;
 225
 226 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 227 fully qualify the name by using a unary plus:
 228
 229     use Catalyst qw/
 230         My::Module
 231         +Fully::Qualified::Plugin::Name
 232     /;
 233
 234 Special flags like C<-Debug> and C<-Engine> can also be specified as
 235 arguments when Catalyst is loaded:
 236
 237     use Catalyst qw/-Debug My::Module/;
 238
 239 The position of plugins and flags in the chain is important, because
 240 they are loaded in the order in which they appear.
 241
 242 The following flags are supported:
 243
 244 =head2 -Debug
 245
 246 Enables debug output. You can also force this setting from the system
 247 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 248 settings override the application, with <MYAPP>_DEBUG having the highest
 249 priority.
 250
 251 This sets the log level to 'debug' and enables full debug output on the
 252 error screen. If you only want the latter, see L<< $c->debug >>.
 253
 254 =head2 -Engine
 255
 256 Forces Catalyst to use a specific engine. Omit the
 257 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 258
 259     use Catalyst qw/-Engine=CGI/;
 260
 261 =head2 -Home
 262
 263 Forces Catalyst to use a specific home directory, e.g.:
 264
 265     use Catalyst qw[-Home=/usr/mst];
 266
 267 This can also be done in the shell environment by setting either the
 268 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 269 is replaced with the uppercased name of your application, any "::" in
 270 the name will be replaced with underscores, e.g. MyApp::Web should use
 271 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 272
 273 If none of these are set, Catalyst will attempt to automatically detect the
 274 home directory. If you are working in a development envirnoment, Catalyst
 275 will try and find the directory containing either Makefile.PL, Build.PL or
 276 dist.ini. If the application has been installed into the system (i.e.
 277 you have done C<make install>), then Catalyst will use the path to your
 278 application module, without the .pm extension (ie, /foo/MyApp if your
 279 application was installed at /foo/MyApp.pm)
 280
 281 =head2 -Log
 282
 283     use Catalyst '-Log=warn,fatal,error';
 284
 285 Specifies a comma-delimited list of log levels.
 286
 287 =head2 -Stats
 288
 289 Enables statistics collection and reporting.
 290
 291    use Catalyst qw/-Stats=1/;
 292
 293 You can also force this setting from the system environment with CATALYST_STATS
 294 or <MYAPP>_STATS. The environment settings override the application, with
 295 <MYAPP>_STATS having the highest priority.
 296
 297 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 298
 299 =head1 METHODS
 300
 301 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 302
 303 =head2 $c->action
 304
 305 Returns a L<Catalyst::Action> object for the current action, which
 306 stringifies to the action name. See L<Catalyst::Action>.
 307
 308 =head2 $c->namespace
 309
 310 Returns the namespace of the current action, i.e., the URI prefix
 311 corresponding to the controller of the current action. For example:
 312
 313     # in Controller::Foo::Bar
 314     $c->namespace; # returns 'foo/bar';
 315
 316 =head2 $c->request
 317
 318 =head2 $c->req
 319
 320 Returns the current L<Catalyst::Request> object, giving access to
 321 information about the current client request (including parameters,
 322 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 323
 324 =head2 REQUEST FLOW HANDLING
 325
 326 =head2 $c->forward( $action [, \@arguments ] )
 327
 328 =head2 $c->forward( $class, $method, [, \@arguments ] )
 329
 330 Forwards processing to another action, by its private name. If you give a
 331 class name but no method, C<process()> is called. You may also optionally
 332 pass arguments in an arrayref. The action will receive the arguments in
 333 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 334 C<< $c->req->args >> will be restored to the previous values.
 335
 336 Any data C<return>ed from the action forwarded to, will be returned by the
 337 call to forward.
 338
 339     my $foodata = $c->forward('/foo');
 340     $c->forward('index');
 341     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 342     $c->forward('View::TT');
 343
 344 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 345 an C<< eval { } >> around the call (actually
 346 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 347 all 'dies' within the called action. If you want C<die> to propagate you
 348 need to do something like:
 349
 350     $c->forward('foo');
 351     die join "\n", @{ $c->error } if @{ $c->error };
 352
 353 Or make sure to always return true values from your actions and write
 354 your code like this:
 355
 356     $c->forward('foo') || return;
 357
 358 Another note is that C<< $c->forward >> always returns a scalar because it
 359 actually returns $c->state which operates in a scalar context.
 360 Thus, something like:
 361
 362     return @array;
 363
 364 in an action that is forwarded to is going to return a scalar,
 365 i.e. how many items are in that array, which is probably not what you want.
 366 If you need to return an array then return a reference to it,
 367 or stash it like so:
 368
 369     $c->stash->{array} = \@array;
 370
 371 and access it from the stash.
 372
 373 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 374
 375 =cut
 376
 377 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 378
 379 =head2 $c->detach( $action [, \@arguments ] )
 380
 381 =head2 $c->detach( $class, $method, [, \@arguments ] )
 382
 383 =head2 $c->detach()
 384
 385 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 386 doesn't return to the previous action when processing is finished.
 387
 388 When called with no arguments it escapes the processing chain entirely.
 389
 390 =cut
 391
 392 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 393
 394 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the callee.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@captures, \@arguments ] )
 425
 426 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 427
 428 The relationship between C<go> and
 429 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 430 the relationship between
 431 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 432 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 433 C<< $c->go >> will perform a full dispatch on the specified action or method,
 434 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 435 C<go> escapes the processing of the current request chain on completion, and
 436 does not return to its caller.
 437
 438 @arguments are arguments to the final destination of $action. @captures are
 439 arguments to the intermediate steps, if any, on the way to the final sub of
 440 $action.
 441
 442 =cut
 443
 444 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 445
 446 =head2 $c->response
 447
 448 =head2 $c->res
 449
 450 Returns the current L<Catalyst::Response> object, see there for details.
 451
 452 =head2 $c->stash
 453
 454 Returns a hashref to the stash, which may be used to store data and pass
 455 it between components during a request. You can also set hash keys by
 456 passing arguments. The stash is automatically sent to the view. The
 457 stash is cleared at the end of a request; it cannot be used for
 458 persistent storage (for this you must use a session; see
 459 L<Catalyst::Plugin::Session> for a complete system integrated with
 460 Catalyst).
 461
 462     $c->stash->{foo} = $bar;
 463     $c->stash( { moose => 'majestic', qux => 0 } );
 464     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 465
 466     # stash is automatically passed to the view for use in a template
 467     $c->forward( 'MyApp::View::TT' );
 468
 469 =cut
 470
 471 around stash => sub {
 472     my $orig = shift;
 473     my $c = shift;
 474     my $stash = $orig->($c);
 475     if (@_) {
 476         my $new_stash = @_ > 1 ? {@_} : $_[0];
 477         croak('stash takes a hash or hashref') unless ref $new_stash;
 478         foreach my $key ( keys %$new_stash ) {
 479           $stash->{$key} = $new_stash->{$key};
 480         }
 481     }
 482
 483     return $stash;
 484 };
 485
 486
 487 =head2 $c->error
 488
 489 =head2 $c->error($error, ...)
 490
 491 =head2 $c->error($arrayref)
 492
 493 Returns an arrayref containing error messages.  If Catalyst encounters an
 494 error while processing a request, it stores the error in $c->error.  This
 495 method should only be used to store fatal error messages.
 496
 497     my @error = @{ $c->error };
 498
 499 Add a new error.
 500
 501     $c->error('Something bad happened');
 502
 503 =cut
 504
 505 sub error {
 506     my $c = shift;
 507     if ( $_[0] ) {
 508         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 509         croak @$error unless ref $c;
 510         push @{ $c->{error} }, @$error;
 511     }
 512     elsif ( defined $_[0] ) { $c->{error} = undef }
 513     return $c->{error} || [];
 514 }
 515
 516
 517 =head2 $c->state
 518
 519 Contains the return value of the last executed action.
 520 Note that << $c->state >> operates in a scalar context which means that all
 521 values it returns are scalar.
 522
 523 =head2 $c->clear_errors
 524
 525 Clear errors.  You probably don't want to clear the errors unless you are
 526 implementing a custom error screen.
 527
 528 This is equivalent to running
 529
 530     $c->error(0);
 531
 532 =cut
 533
 534 sub clear_errors {
 535     my $c = shift;
 536     $c->error(0);
 537 }
 538
 539 sub _comp_search_prefixes {
 540     my $c = shift;
 541     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 542 }
 543
 544 # search components given a name and some prefixes
 545 sub _comp_names_search_prefixes {
 546     my ( $c, $name, @prefixes ) = @_;
 547     my $appclass = ref $c || $c;
 548     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 549     $filter = qr/$filter/; # Compile regex now rather than once per loop
 550
 551     my @components = map { $c->container->get_sub_container($_)->get_service_list } qw(controller view model);
 552
 553     # map the original component name to the sub part that we will search against
 554     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 555         grep { /$filter/ } @components;
 556
 557     # undef for a name will return all
 558     return keys %eligible if !defined $name;
 559
 560     my $query  = ref $name ? $name : qr/^$name$/i;
 561     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 562
 563     return @result if @result;
 564
 565     # if we were given a regexp to search against, we're done.
 566     return if ref $name;
 567
 568     # skip regexp fallback if configured
 569     return
 570         if $appclass->config->{disable_component_resolution_regex_fallback};
 571
 572     # regexp fallback
 573     $query  = qr/$name/i;
 574     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 575
 576     # no results? try against full names
 577     if( !@result ) {
 578         @result = grep { m{$query} } keys %eligible;
 579     }
 580
 581     # don't warn if we didn't find any results, it just might not exist
 582     if( @result ) {
 583         # Disgusting hack to work out correct method name
 584         my $warn_for = lc $prefixes[0];
 585         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 586            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 587            "component resolution is unreliable and unsafe.";
 588         my $short = $result[0];
 589         # remove the component namespace prefix
 590         $short =~ s/.*?(Model|Controller|View):://;
 591         my $shortmess = Carp::shortmess('');
 592         if ($shortmess =~ m#Catalyst/Plugin#) {
 593            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 594               "plugin's config";
 595         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 596            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 597               "component's config";
 598         } else {
 599            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 600               "but if you really wanted to search, pass in a regexp as the argument " .
 601               "like so: \$c->${warn_for}(qr/${name}/)";
 602         }
 603         $c->log->warn( "${msg}$shortmess" );
 604     }
 605
 606     return @result;
 607 }
 608
 609 # Find possible names for a prefix
 610 sub _comp_names {
 611     my ( $c, @prefixes ) = @_;
 612     my $appclass = ref $c || $c;
 613
 614     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 615
 616     my @names = map { s{$filter}{}; $_; }
 617         $c->_comp_names_search_prefixes( undef, @prefixes );
 618
 619     return @names;
 620 }
 621
 622 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 623 sub _filter_component {
 624     my ( $c, $comp, @args ) = @_;
 625
 626     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 627         return $comp->ACCEPT_CONTEXT( $c, @args );
 628     }
 629
 630     return $comp;
 631 }
 632
 633 =head2 COMPONENT ACCESSORS
 634
 635 =head2 $c->controller($name)
 636
 637 Gets a L<Catalyst::Controller> instance by name.
 638
 639     $c->controller('Foo')->do_stuff;
 640
 641 If the name is omitted, will return the controller for the dispatched
 642 action.
 643
 644 If you want to search for controllers, pass in a regexp as the argument.
 645
 646     # find all controllers that start with Foo
 647     my @foo_controllers = $c->controller(qr{^Foo});
 648
 649
 650 =cut
 651
 652 sub controller {
 653     my ( $c, $name, @args ) = @_;
 654
 655     my $appclass = ref($c) || $c;
 656     if( $name ) {
 657         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 658             my $check = $appclass."::Controller::".$name;
 659             my $container = $c->container->get_sub_container('controller');
 660             return $c->_filter_component( $container->resolve(service => "$check"), @args )
 661                 if $container->has_service($check);
 662         }
 663         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 664         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 665         return $c->_filter_component( $result[ 0 ], @args );
 666     }
 667
 668     return $c->component( $c->action->class );
 669 }
 670
 671 =head2 $c->model($name)
 672
 673 Gets a L<Catalyst::Model> instance by name.
 674
 675     $c->model('Foo')->do_stuff;
 676
 677 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 678
 679 If the name is omitted, it will look for
 680  - a model object in $c->stash->{current_model_instance}, then
 681  - a model name in $c->stash->{current_model}, then
 682  - a config setting 'default_model', or
 683  - check if there is only one model, and return it if that's the case.
 684
 685 If you want to search for models, pass in a regexp as the argument.
 686
 687     # find all models that start with Foo
 688     my @foo_models = $c->model(qr{^Foo});
 689
 690 =cut
 691
 692 sub model {
 693     my ( $c, $name, @args ) = @_;
 694     my $appclass = ref($c) || $c;
 695     if( $name ) {
 696         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 697             my $check = $appclass."::Model::".$name;
 698             my $container = $c->container->get_sub_container('model');
 699             return $c->_filter_component( $container->resolve(service => "$check"), @args )
 700                 if $container->has_service($check);
 701         }
 702         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 703         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 704         return $c->_filter_component( $result[ 0 ], @args );
 705     }
 706
 707     if (ref $c) {
 708         return $c->stash->{current_model_instance}
 709           if $c->stash->{current_model_instance};
 710         return $c->model( $c->stash->{current_model} )
 711           if $c->stash->{current_model};
 712     }
 713     return $c->model( $appclass->config->{default_model} )
 714       if $appclass->config->{default_model};
 715
 716     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 717
 718     if( $rest ) {
 719         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 720         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 721         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 722         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 723         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 724     }
 725
 726     return $c->_filter_component( $comp );
 727 }
 728
 729
 730 =head2 $c->view($name)
 731
 732 Gets a L<Catalyst::View> instance by name.
 733
 734     $c->view('Foo')->do_stuff;
 735
 736 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 737
 738 If the name is omitted, it will look for
 739  - a view object in $c->stash->{current_view_instance}, then
 740  - a view name in $c->stash->{current_view}, then
 741  - a config setting 'default_view', or
 742  - check if there is only one view, and return it if that's the case.
 743
 744 If you want to search for views, pass in a regexp as the argument.
 745
 746     # find all views that start with Foo
 747     my @foo_views = $c->view(qr{^Foo});
 748
 749 =cut
 750
 751 sub view {
 752     my ( $c, $name, @args ) = @_;
 753
 754     my $appclass = ref($c) || $c;
 755     if( $name ) {
 756         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 757             my $check = $appclass."::View::".$name;
 758             my $container = $c->container->get_sub_container('view');
 759             if ($container->has_service($check)) {
 760
 761                 return $c->_filter_component( $container->get_service($check)->get, @args );
 762             }
 763             else {
 764                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 765             }
 766         }
 767         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 768         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 769         return $c->_filter_component( $result[ 0 ], @args );
 770     }
 771
 772     if (ref $c) {
 773         return $c->stash->{current_view_instance}
 774           if $c->stash->{current_view_instance};
 775         return $c->view( $c->stash->{current_view} )
 776           if $c->stash->{current_view};
 777     }
 778     return $c->view( $appclass->config->{default_view} )
 779       if $appclass->config->{default_view};
 780
 781     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 782
 783     if( $rest ) {
 784         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 785         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 786         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 787         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 788         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 789     }
 790
 791     return $c->_filter_component( $comp );
 792 }
 793
 794 =head2 $c->controllers
 795
 796 Returns the available names which can be passed to $c->controller
 797
 798 =cut
 799
 800 sub controllers {
 801     my ( $c ) = @_;
 802     return $c->container->get_sub_container('controller')->get_service_list;
 803 }
 804
 805 =head2 $c->models
 806
 807 Returns the available names which can be passed to $c->model
 808
 809 =cut
 810
 811 sub models {
 812     my ( $c ) = @_;
 813     return $c->container->get_sub_container('model')->get_service_list;
 814 }
 815
 816
 817 =head2 $c->views
 818
 819 Returns the available names which can be passed to $c->view
 820
 821 =cut
 822
 823 sub views {
 824     my ( $c ) = @_;
 825     return $c->container->get_sub_container('view')->get_service_list;
 826 }
 827
 828 =head2 $c->comp($name)
 829
 830 =head2 $c->component($name)
 831
 832 Gets a component object by name. This method is not recommended,
 833 unless you want to get a specific component by full
 834 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 835 should be used instead.
 836
 837 If C<$name> is a regexp, a list of components matched against the full
 838 component name will be returned.
 839
 840 If Catalyst can't find a component by name, it will fallback to regex
 841 matching by default. To disable this behaviour set
 842 disable_component_resolution_regex_fallback to a true value.
 843
 844     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 845
 846 =cut
 847
 848 sub component {
 849     my ( $c, $name, @args ) = @_;
 850
 851     if( $name ) {
 852         my $comps = $c->components;
 853
 854         if( !ref $name ) {
 855             # is it the exact name?
 856             return $c->_filter_component( $comps->{ $name }, @args )
 857                        if exists $comps->{ $name };
 858
 859             # perhaps we just omitted "MyApp"?
 860             my $composed = ( ref $c || $c ) . "::${name}";
 861             return $c->_filter_component( $comps->{ $composed }, @args )
 862                        if exists $comps->{ $composed };
 863
 864             # search all of the models, views and controllers
 865             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 866             return $c->_filter_component( $comp, @args ) if $comp;
 867         }
 868
 869         # This is here so $c->comp( '::M::' ) works
 870         my $query = ref $name ? $name : qr{$name}i;
 871
 872         my @result = grep { m{$query} } keys %{ $c->components };
 873         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 874
 875         if( $result[ 0 ] ) {
 876             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 877             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 878             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 879             return $c->_filter_component( $result[ 0 ], @args );
 880         }
 881
 882         # I would expect to return an empty list here, but that breaks back-compat
 883     }
 884
 885     # fallback
 886     return sort keys %{ $c->components };
 887 }
 888
 889 =head2 CLASS DATA AND HELPER CLASSES
 890
 891 =head2 $c->config
 892
 893 Returns or takes a hashref containing the application's configuration.
 894
 895     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 896
 897 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 898 like C<myapp.conf> in your applications home directory. See
 899 L<Catalyst::Plugin::ConfigLoader>.
 900
 901 =head3 Cascading configuration
 902
 903 The config method is present on all Catalyst components, and configuration
 904 will be merged when an application is started. Configuration loaded with
 905 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 906 followed by configuration in your top level C<MyApp> class. These two
 907 configurations are merged, and then configuration data whose hash key matches a
 908 component name is merged with configuration for that component.
 909
 910 The configuration for a component is then passed to the C<new> method when a
 911 component is constructed.
 912
 913 For example:
 914
 915     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 916     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 917
 918 will mean that C<MyApp::Model::Foo> receives the following data when
 919 constructed:
 920
 921     MyApp::Model::Foo->new({
 922         bar => 'baz',
 923         quux => 'frob',
 924         overrides => 'me',
 925     });
 926
 927 It's common practice to use a Moose attribute
 928 on the receiving component to access the config value.
 929
 930     package MyApp::Model::Foo;
 931
 932     use Moose;
 933
 934     # this attr will receive 'baz' at construction time
 935     has 'bar' => (
 936         is  => 'rw',
 937         isa => 'Str',
 938     );
 939
 940 You can then get the value 'baz' by calling $c->model('Foo')->bar
 941 (or $self->bar inside code in the model).
 942
 943 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 944 as a way of reading config within your code, as this B<will not> give you the
 945 correctly merged config back. You B<MUST> take the config values supplied to
 946 the constructor and use those instead.
 947
 948 =cut
 949
 950 around config => sub {
 951     my $orig = shift;
 952     my $c = shift;
 953
 954     croak('Setting config after setup has been run is not allowed.')
 955         if ( @_ and $c->setup_finished );
 956
 957     $c->$orig(@_);
 958 };
 959
 960 =head2 $c->log
 961
 962 Returns the logging object instance. Unless it is already set, Catalyst
 963 sets this up with a L<Catalyst::Log> object. To use your own log class,
 964 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 965 C<< __PACKAGE__->setup >>.
 966
 967  __PACKAGE__->log( MyLogger->new );
 968  __PACKAGE__->setup;
 969
 970 And later:
 971
 972     $c->log->info( 'Now logging with my own logger!' );
 973
 974 Your log class should implement the methods described in
 975 L<Catalyst::Log>.
 976
 977
 978 =head2 $c->debug
 979
 980 Returns 1 if debug mode is enabled, 0 otherwise.
 981
 982 You can enable debug mode in several ways:
 983
 984 =over
 985
 986 =item By calling myapp_server.pl with the -d flag
 987
 988 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 989
 990 =item The -Debug option in your MyApp.pm
 991
 992 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 993
 994 =back
 995
 996 The first three also set the log level to 'debug'.
 997
 998 Calling C<< $c->debug(1) >> has no effect.
 999
1000 =cut
1001
1002 sub debug { 0 }
1003
1004 =head2 $c->dispatcher
1005
1006 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1007
1008 =head2 $c->engine
1009
1010 Returns the engine instance. See L<Catalyst::Engine>.
1011
1012
1013 =head2 UTILITY METHODS
1014
1015 =head2 $c->path_to(@path)
1016
1017 Merges C<@path> with C<< $c->config->{home} >> and returns a
1018 L<Path::Class::Dir> object. Note you can usually use this object as
1019 a filename, but sometimes you will have to explicitly stringify it
1020 yourself by calling the C<< ->stringify >> method.
1021
1022 For example:
1023
1024     $c->path_to( 'db', 'sqlite.db' );
1025
1026 =cut
1027
1028 sub path_to {
1029     my ( $c, @path ) = @_;
1030     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1031     if ( -d $path ) { return $path }
1032     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1033 }
1034
1035 =head2 $c->plugin( $name, $class, @args )
1036
1037 Helper method for plugins. It creates a class data accessor/mutator and
1038 loads and instantiates the given class.
1039
1040     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1041
1042     $c->prototype->define_javascript_functions;
1043
1044 B<Note:> This method of adding plugins is deprecated. The ability
1045 to add plugins like this B<will be removed> in a Catalyst 5.81.
1046 Please do not use this functionality in new code.
1047
1048 =cut
1049
1050 sub plugin {
1051     my ( $class, $name, $plugin, @args ) = @_;
1052
1053     # See block comment in t/unit_core_plugin.t
1054     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1055
1056     $class->_register_plugin( $plugin, 1 );
1057
1058     eval { $plugin->import };
1059     $class->mk_classdata($name);
1060     my $obj;
1061     eval { $obj = $plugin->new(@args) };
1062
1063     if ($@) {
1064         Catalyst::Exception->throw( message =>
1065               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1066     }
1067
1068     $class->$name($obj);
1069     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1070       if $class->debug;
1071 }
1072
1073 =head2 MyApp->setup
1074
1075 Initializes the dispatcher and engine, loads any plugins, and loads the
1076 model, view, and controller components. You may also specify an array
1077 of plugins to load here, if you choose to not load them in the C<use
1078 Catalyst> line.
1079
1080     MyApp->setup;
1081     MyApp->setup( qw/-Debug/ );
1082
1083 =cut
1084
1085 sub setup {
1086     my ( $class, @arguments ) = @_;
1087     croak('Running setup more than once')
1088         if ( $class->setup_finished );
1089
1090     unless ( $class->isa('Catalyst') ) {
1091
1092         Catalyst::Exception->throw(
1093             message => qq/'$class' does not inherit from Catalyst/ );
1094     }
1095
1096     if ( $class->arguments ) {
1097         @arguments = ( @arguments, @{ $class->arguments } );
1098     }
1099
1100     # Process options
1101     my $flags = {};
1102
1103     foreach (@arguments) {
1104
1105         if (/^-Debug$/) {
1106             $flags->{log} =
1107               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1108         }
1109         elsif (/^-(\w+)=?(.*)$/) {
1110             $flags->{ lc $1 } = $2;
1111         }
1112         else {
1113             push @{ $flags->{plugins} }, $_;
1114         }
1115     }
1116
1117     $class->setup_config();
1118     $class->setup_home( delete $flags->{home} );
1119
1120     $class->setup_log( delete $flags->{log} );
1121     $class->setup_plugins( delete $flags->{plugins} );
1122     $class->setup_dispatcher( delete $flags->{dispatcher} );
1123     $class->setup_engine( delete $flags->{engine} );
1124     $class->setup_stats( delete $flags->{stats} );
1125
1126     for my $flag ( sort keys %{$flags} ) {
1127
1128         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1129             &$code( $class, delete $flags->{$flag} );
1130         }
1131         else {
1132             $class->log->warn(qq/Unknown flag "$flag"/);
1133         }
1134     }
1135
1136     eval { require Catalyst::Devel; };
1137     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1138         $class->log->warn(<<"EOF");
1139 You are running an old script!
1140
1141   Please update by running (this will overwrite existing files):
1142     catalyst.pl -force -scripts $class
1143
1144   or (this will not overwrite existing files):
1145     catalyst.pl -scripts $class
1146
1147 EOF
1148     }
1149
1150     if ( $class->debug ) {
1151         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1152
1153         if (@plugins) {
1154             my $column_width = Catalyst::Utils::term_width() - 6;
1155             my $t = Text::SimpleTable->new($column_width);
1156             $t->row($_) for @plugins;
1157             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1158         }
1159
1160         my $dispatcher = $class->dispatcher;
1161         my $engine     = $class->engine;
1162         my $home       = $class->config->{home};
1163
1164         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1165         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1166
1167         $home
1168           ? ( -d $home )
1169           ? $class->log->debug(qq/Found home "$home"/)
1170           : $class->log->debug(qq/Home "$home" doesn't exist/)
1171           : $class->log->debug(q/Couldn't find home/);
1172     }
1173
1174     # Call plugins setup, this is stupid and evil.
1175     # Also screws C3 badly on 5.10, hack to avoid.
1176     {
1177         no warnings qw/redefine/;
1178         local *setup = sub { };
1179         $class->setup unless $Catalyst::__AM_RESTARTING;
1180     }
1181
1182     # Initialize our data structure
1183     $class->components( {} );
1184
1185     $class->setup_components;
1186
1187     if ( $class->debug ) {
1188         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1189         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1190         for my $comp ( sort keys %{ $class->components } ) {
1191             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1192             $t->row( $comp, $type );
1193         }
1194         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1195           if ( keys %{ $class->components } );
1196     }
1197
1198     # Add our self to components, since we are also a component
1199     if( $class->isa('Catalyst::Controller') ){
1200       $class->components->{$class} = $class;
1201     }
1202
1203     $class->setup_actions;
1204
1205     if ( $class->debug ) {
1206         my $name = $class->config->{name} || 'Application';
1207         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1208     }
1209
1210     # Make sure that the application class becomes immutable at this point,
1211     B::Hooks::EndOfScope::on_scope_end {
1212         return if $@;
1213         my $meta = Class::MOP::get_metaclass_by_name($class);
1214         if (
1215             $meta->is_immutable
1216             && ! { $meta->immutable_options }->{replace_constructor}
1217             && (
1218                    $class->isa('Class::Accessor::Fast')
1219                 || $class->isa('Class::Accessor')
1220             )
1221         ) {
1222             warn "You made your application class ($class) immutable, "
1223                 . "but did not inline the\nconstructor. "
1224                 . "This will break catalyst, as your app \@ISA "
1225                 . "Class::Accessor(::Fast)?\nPlease pass "
1226                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1227         }
1228         $meta->make_immutable(
1229             replace_constructor => 1,
1230         ) unless $meta->is_immutable;
1231     };
1232
1233     if ($class->config->{case_sensitive}) {
1234         $class->log->warn($class . "->config->{case_sensitive} is set.");
1235         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1236     }
1237
1238     $class->setup_finalize;
1239     # Should be the last thing we do so that user things hooking
1240     # setup_finalize can log..
1241     $class->log->_flush() if $class->log->can('_flush');
1242     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1243 }
1244
1245 =head2 $app->setup_finalize
1246
1247 A hook to attach modifiers to. This method does not do anything except set the
1248 C<setup_finished> accessor.
1249
1250 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1251
1252 Example:
1253
1254     after setup_finalize => sub {
1255         my $app = shift;
1256
1257         ## do stuff here..
1258     };
1259
1260 =cut
1261
1262 sub setup_finalize {
1263     my ($class) = @_;
1264     $class->setup_finished(1);
1265 }
1266
1267 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1268
1269 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1270
1271 Constructs an absolute L<URI> object based on the application root, the
1272 provided path, and the additional arguments and query parameters provided.
1273 When used as a string, provides a textual URI.  If you need more flexibility
1274 than this (i.e. the option to provide relative URIs etc.) see
1275 L<Catalyst::Plugin::SmartURI>.
1276
1277 If no arguments are provided, the URI for the current action is returned.
1278 To return the current action and also provide @args, use
1279 C<< $c->uri_for( $c->action, @args ) >>.
1280
1281 If the first argument is a string, it is taken as a public URI path relative
1282 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1283 relative to the application root (if it does). It is then merged with
1284 C<< $c->request->base >>; any C<@args> are appended as additional path
1285 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1286
1287 If the first argument is a L<Catalyst::Action> it represents an action which
1288 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1289 optional C<\@captures> argument (an arrayref) allows passing the captured
1290 variables that are needed to fill in the paths of Chained and Regex actions;
1291 once the path is resolved, C<uri_for> continues as though a path was
1292 provided, appending any arguments or parameters and creating an absolute
1293 URI.
1294
1295 The captures for the current request can be found in
1296 C<< $c->request->captures >>, and actions can be resolved using
1297 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1298 path, use C<< $c->uri_for_action >> instead.
1299
1300   # Equivalent to $c->req->uri
1301   $c->uri_for($c->action, $c->req->captures,
1302       @{ $c->req->args }, $c->req->params);
1303
1304   # For the Foo action in the Bar controller
1305   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1306
1307   # Path to a static resource
1308   $c->uri_for('/static/images/logo.png');
1309
1310 =cut
1311
1312 sub uri_for {
1313     my ( $c, $path, @args ) = @_;
1314
1315     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1316         $path = $path->path_prefix;
1317         $path =~ s{/+\z}{};
1318         $path .= '/';
1319     }
1320
1321     undef($path) if (defined $path && $path eq '');
1322
1323     my $params =
1324       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1325
1326     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1327     foreach my $arg (@args) {
1328         utf8::encode($arg) if utf8::is_utf8($arg);
1329         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1330     }
1331
1332     if ( blessed($path) ) { # action object
1333         s|/|%2F|g for @args;
1334         my $captures = [ map { s|/|%2F|g; $_; }
1335                         ( scalar @args && ref $args[0] eq 'ARRAY'
1336                          ? @{ shift(@args) }
1337                          : ()) ];
1338
1339         foreach my $capture (@$captures) {
1340             utf8::encode($capture) if utf8::is_utf8($capture);
1341             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1342         }
1343
1344         my $action = $path;
1345         $path = $c->dispatcher->uri_for_action($action, $captures);
1346         if (not defined $path) {
1347             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1348                 if $c->debug;
1349             return undef;
1350         }
1351         $path = '/' if $path eq '';
1352     }
1353
1354     unshift(@args, $path);
1355
1356     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1357         my $namespace = $c->namespace;
1358         if (defined $path) { # cheesy hack to handle path '../foo'
1359            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1360         }
1361         unshift(@args, $namespace || '');
1362     }
1363
1364     # join args with '/', or a blank string
1365     my $args = join('/', grep { defined($_) } @args);
1366     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1367     $args =~ s!^/+!!;
1368     my $base = $c->req->base;
1369     my $class = ref($base);
1370     $base =~ s{(?<!/)$}{/};
1371
1372     my $query = '';
1373
1374     if (my @keys = keys %$params) {
1375       # somewhat lifted from URI::_query's query_form
1376       $query = '?'.join('&', map {
1377           my $val = $params->{$_};
1378           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1379           s/ /+/g;
1380           my $key = $_;
1381           $val = '' unless defined $val;
1382           (map {
1383               my $param = "$_";
1384               utf8::encode( $param ) if utf8::is_utf8($param);
1385               # using the URI::Escape pattern here so utf8 chars survive
1386               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1387               $param =~ s/ /+/g;
1388               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1389       } @keys);
1390     }
1391
1392     my $res = bless(\"${base}${args}${query}", $class);
1393     $res;
1394 }
1395
1396 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1397
1398 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1399
1400 =over
1401
1402 =item $path
1403
1404 A private path to the Catalyst action you want to create a URI for.
1405
1406 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1407 >> and passing the resulting C<$action> and the remaining arguments to C<<
1408 $c->uri_for >>.
1409
1410 You can also pass in a Catalyst::Action object, in which case it is passed to
1411 C<< $c->uri_for >>.
1412
1413 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1414
1415 For example, if the action looks like:
1416
1417  package MyApp::Controller::Users;
1418
1419  sub lst : Path('the-list') {}
1420
1421 You can use:
1422
1423  $c->uri_for_action('/users/lst')
1424
1425 and it will create the URI /users/the-list.
1426
1427 =back
1428
1429 =cut
1430
1431 sub uri_for_action {
1432     my ( $c, $path, @args ) = @_;
1433     my $action = blessed($path)
1434       ? $path
1435       : $c->dispatcher->get_action_by_path($path);
1436     unless (defined $action) {
1437       croak "Can't find action for path '$path'";
1438     }
1439     return $c->uri_for( $action, @args );
1440 }
1441
1442 =head2 $c->welcome_message
1443
1444 Returns the Catalyst welcome HTML page.
1445
1446 =cut
1447
1448 sub welcome_message {
1449     my $c      = shift;
1450     my $name   = $c->config->{name};
1451     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1452     my $prefix = Catalyst::Utils::appprefix( ref $c );
1453     $c->response->content_type('text/html; charset=utf-8');
1454     return <<"EOF";
1455 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1456     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1457 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1458     <head>
1459     <meta http-equiv="Content-Language" content="en" />
1460     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1461         <title>$name on Catalyst $VERSION</title>
1462         <style type="text/css">
1463             body {
1464                 color: #000;
1465                 background-color: #eee;
1466             }
1467             div#content {
1468                 width: 640px;
1469                 margin-left: auto;
1470                 margin-right: auto;
1471                 margin-top: 10px;
1472                 margin-bottom: 10px;
1473                 text-align: left;
1474                 background-color: #ccc;
1475                 border: 1px solid #aaa;
1476             }
1477             p, h1, h2 {
1478                 margin-left: 20px;
1479                 margin-right: 20px;
1480                 font-family: verdana, tahoma, sans-serif;
1481             }
1482             a {
1483                 font-family: verdana, tahoma, sans-serif;
1484             }
1485             :link, :visited {
1486                     text-decoration: none;
1487                     color: #b00;
1488                     border-bottom: 1px dotted #bbb;
1489             }
1490             :link:hover, :visited:hover {
1491                     color: #555;
1492             }
1493             div#topbar {
1494                 margin: 0px;
1495             }
1496             pre {
1497                 margin: 10px;
1498                 padding: 8px;
1499             }
1500             div#answers {
1501                 padding: 8px;
1502                 margin: 10px;
1503                 background-color: #fff;
1504                 border: 1px solid #aaa;
1505             }
1506             h1 {
1507                 font-size: 0.9em;
1508                 font-weight: normal;
1509                 text-align: center;
1510             }
1511             h2 {
1512                 font-size: 1.0em;
1513             }
1514             p {
1515                 font-size: 0.9em;
1516             }
1517             p img {
1518                 float: right;
1519                 margin-left: 10px;
1520             }
1521             span#appname {
1522                 font-weight: bold;
1523                 font-size: 1.6em;
1524             }
1525         </style>
1526     </head>
1527     <body>
1528         <div id="content">
1529             <div id="topbar">
1530                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1531                     $VERSION</h1>
1532              </div>
1533              <div id="answers">
1534                  <p>
1535                  <img src="$logo" alt="Catalyst Logo" />
1536                  </p>
1537                  <p>Welcome to the  world of Catalyst.
1538                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1539                     framework will make web development something you had
1540                     never expected it to be: Fun, rewarding, and quick.</p>
1541                  <h2>What to do now?</h2>
1542                  <p>That really depends  on what <b>you</b> want to do.
1543                     We do, however, provide you with a few starting points.</p>
1544                  <p>If you want to jump right into web development with Catalyst
1545                     you might want to start with a tutorial.</p>
1546 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1547 </pre>
1548 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1549 <pre>
1550 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1551 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1552 </code></pre>
1553                  <h2>What to do next?</h2>
1554                  <p>Next it's time to write an actual application. Use the
1555                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1556                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1557                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1558                     they can save you a lot of work.</p>
1559                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1560                     <p>Also, be sure to check out the vast and growing
1561                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1562                     you are likely to find what you need there.
1563                     </p>
1564
1565                  <h2>Need help?</h2>
1566                  <p>Catalyst has a very active community. Here are the main places to
1567                     get in touch with us.</p>
1568                  <ul>
1569                      <li>
1570                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1571                      </li>
1572                      <li>
1573                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1574                      </li>
1575                      <li>
1576                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1577                      </li>
1578                  </ul>
1579                  <h2>In conclusion</h2>
1580                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1581                     as we enjoyed making it. Please contact us if you have ideas
1582                     for improvement or other feedback.</p>
1583              </div>
1584          </div>
1585     </body>
1586 </html>
1587 EOF
1588 }
1589
1590 =head1 INTERNAL METHODS
1591
1592 These methods are not meant to be used by end users.
1593
1594 =head2 $c->components
1595
1596 Returns a hash of components.
1597
1598 =cut
1599
1600 around components => sub {
1601     my $orig  = shift;
1602     my $class = shift;
1603     my $comps = shift;
1604
1605     return $class->$orig if ( !$comps );
1606
1607 # FIXME: should this ugly kludge exist?
1608     $class->setup_config unless defined $class->container;
1609
1610 # FIXME: should there be a warning here, not to use this accessor to create the components?
1611     my $components = {};
1612
1613     my $containers;
1614     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
1615
1616     for my $component ( keys %$comps ) {
1617         $components->{ $component } = $comps->{$component};
1618
1619         my $type = _get_component_type($component);
1620
1621         $containers->{$type}->add_service(Bread::Board::BlockInjection->new( name => $component, block => sub { return $class->setup_component($component) } ));
1622     }
1623
1624     return $class->$orig($components);
1625 };
1626
1627 =head2 $c->context_class
1628
1629 Returns or sets the context class.
1630
1631 =head2 $c->counter
1632
1633 Returns a hashref containing coderefs and execution counts (needed for
1634 deep recursion detection).
1635
1636 =head2 $c->depth
1637
1638 Returns the number of actions on the current internal execution stack.
1639
1640 =head2 $c->dispatch
1641
1642 Dispatches a request to actions.
1643
1644 =cut
1645
1646 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1647
1648 =head2 $c->dispatcher_class
1649
1650 Returns or sets the dispatcher class.
1651
1652 =head2 $c->dump_these
1653
1654 Returns a list of 2-element array references (name, structure) pairs
1655 that will be dumped on the error page in debug mode.
1656
1657 =cut
1658
1659 sub dump_these {
1660     my $c = shift;
1661     [ Request => $c->req ],
1662     [ Response => $c->res ],
1663     [ Stash => $c->stash ],
1664     [ Config => $c->config ];
1665 }
1666
1667 =head2 $c->engine_class
1668
1669 Returns or sets the engine class.
1670
1671 =head2 $c->execute( $class, $coderef )
1672
1673 Execute a coderef in given class and catch exceptions. Errors are available
1674 via $c->error.
1675
1676 =cut
1677
1678 sub execute {
1679     my ( $c, $class, $code ) = @_;
1680     $class = $c->component($class) || $class;
1681     $c->state(0);
1682
1683     if ( $c->depth >= $RECURSION ) {
1684         my $action = $code->reverse();
1685         $action = "/$action" unless $action =~ /->/;
1686         my $error = qq/Deep recursion detected calling "${action}"/;
1687         $c->log->error($error);
1688         $c->error($error);
1689         $c->state(0);
1690         return $c->state;
1691     }
1692
1693     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1694
1695     push( @{ $c->stack }, $code );
1696
1697     no warnings 'recursion';
1698     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1699     #      I have no idea how, ergo $ret (which appears to fix the issue)
1700     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1701
1702     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1703
1704     my $last = pop( @{ $c->stack } );
1705
1706     if ( my $error = $@ ) {
1707         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1708             $error->rethrow if $c->depth > 1;
1709         }
1710         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1711             $error->rethrow if $c->depth > 0;
1712         }
1713         else {
1714             unless ( ref $error ) {
1715                 no warnings 'uninitialized';
1716                 chomp $error;
1717                 my $class = $last->class;
1718                 my $name  = $last->name;
1719                 $error = qq/Caught exception in $class->$name "$error"/;
1720             }
1721             $c->error($error);
1722         }
1723         $c->state(0);
1724     }
1725     return $c->state;
1726 }
1727
1728 sub _stats_start_execute {
1729     my ( $c, $code ) = @_;
1730     my $appclass = ref($c) || $c;
1731     return if ( ( $code->name =~ /^_.*/ )
1732         && ( !$appclass->config->{show_internal_actions} ) );
1733
1734     my $action_name = $code->reverse();
1735     $c->counter->{$action_name}++;
1736
1737     my $action = $action_name;
1738     $action = "/$action" unless $action =~ /->/;
1739
1740     # determine if the call was the result of a forward
1741     # this is done by walking up the call stack and looking for a calling
1742     # sub of Catalyst::forward before the eval
1743     my $callsub = q{};
1744     for my $index ( 2 .. 11 ) {
1745         last
1746         if ( ( caller($index) )[0] eq 'Catalyst'
1747             && ( caller($index) )[3] eq '(eval)' );
1748
1749         if ( ( caller($index) )[3] =~ /forward$/ ) {
1750             $callsub = ( caller($index) )[3];
1751             $action  = "-> $action";
1752             last;
1753         }
1754     }
1755
1756     my $uid = $action_name . $c->counter->{$action_name};
1757
1758     # is this a root-level call or a forwarded call?
1759     if ( $callsub =~ /forward$/ ) {
1760         my $parent = $c->stack->[-1];
1761
1762         # forward, locate the caller
1763         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1764             $c->stats->profile(
1765                 begin  => $action,
1766                 parent => "$parent" . $c->counter->{"$parent"},
1767                 uid    => $uid,
1768             );
1769         }
1770         else {
1771
1772             # forward with no caller may come from a plugin
1773             $c->stats->profile(
1774                 begin => $action,
1775                 uid   => $uid,
1776             );
1777         }
1778     }
1779     else {
1780
1781         # root-level call
1782         $c->stats->profile(
1783             begin => $action,
1784             uid   => $uid,
1785         );
1786     }
1787     return $action;
1788
1789 }
1790
1791 sub _stats_finish_execute {
1792     my ( $c, $info ) = @_;
1793     $c->stats->profile( end => $info );
1794 }
1795
1796 =head2 $c->finalize
1797
1798 Finalizes the request.
1799
1800 =cut
1801
1802 sub finalize {
1803     my $c = shift;
1804
1805     for my $error ( @{ $c->error } ) {
1806         $c->log->error($error);
1807     }
1808
1809     # Allow engine to handle finalize flow (for POE)
1810     my $engine = $c->engine;
1811     if ( my $code = $engine->can('finalize') ) {
1812         $engine->$code($c);
1813     }
1814     else {
1815
1816         $c->finalize_uploads;
1817
1818         # Error
1819         if ( $#{ $c->error } >= 0 ) {
1820             $c->finalize_error;
1821         }
1822
1823         $c->finalize_headers;
1824
1825         # HEAD request
1826         if ( $c->request->method eq 'HEAD' ) {
1827             $c->response->body('');
1828         }
1829
1830         $c->finalize_body;
1831     }
1832
1833     $c->log_response;
1834
1835     if ($c->use_stats) {
1836         my $elapsed = sprintf '%f', $c->stats->elapsed;
1837         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1838         $c->log->info(
1839             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1840     }
1841
1842     return $c->response->status;
1843 }
1844
1845 =head2 $c->finalize_body
1846
1847 Finalizes body.
1848
1849 =cut
1850
1851 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1852
1853 =head2 $c->finalize_cookies
1854
1855 Finalizes cookies.
1856
1857 =cut
1858
1859 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1860
1861 =head2 $c->finalize_error
1862
1863 Finalizes error.
1864
1865 =cut
1866
1867 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1868
1869 =head2 $c->finalize_headers
1870
1871 Finalizes headers.
1872
1873 =cut
1874
1875 sub finalize_headers {
1876     my $c = shift;
1877
1878     my $response = $c->response; #accessor calls can add up?
1879
1880     # Check if we already finalized headers
1881     return if $response->finalized_headers;
1882
1883     # Handle redirects
1884     if ( my $location = $response->redirect ) {
1885         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1886         $response->header( Location => $location );
1887
1888         if ( !$response->has_body ) {
1889             # Add a default body if none is already present
1890             $response->body(
1891                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1892             );
1893         }
1894     }
1895
1896     # Content-Length
1897     if ( defined $response->body && length $response->body && !$response->content_length ) {
1898
1899         # get the length from a filehandle
1900         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1901         {
1902             my $stat = stat $response->body;
1903             if ( $stat && $stat->size > 0 ) {
1904                 $response->content_length( $stat->size );
1905             }
1906             else {
1907                 $c->log->warn('Serving filehandle without a content-length');
1908             }
1909         }
1910         else {
1911             # everything should be bytes at this point, but just in case
1912             $response->content_length( length( $response->body ) );
1913         }
1914     }
1915
1916     # Errors
1917     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1918         $response->headers->remove_header("Content-Length");
1919         $response->body('');
1920     }
1921
1922     $c->finalize_cookies;
1923
1924     $c->engine->finalize_headers( $c, @_ );
1925
1926     # Done
1927     $response->finalized_headers(1);
1928 }
1929
1930 =head2 $c->finalize_output
1931
1932 An alias for finalize_body.
1933
1934 =head2 $c->finalize_read
1935
1936 Finalizes the input after reading is complete.
1937
1938 =cut
1939
1940 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1941
1942 =head2 $c->finalize_uploads
1943
1944 Finalizes uploads. Cleans up any temporary files.
1945
1946 =cut
1947
1948 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1949
1950 =head2 $c->get_action( $action, $namespace )
1951
1952 Gets an action in a given namespace.
1953
1954 =cut
1955
1956 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1957
1958 =head2 $c->get_actions( $action, $namespace )
1959
1960 Gets all actions of a given name in a namespace and all parent
1961 namespaces.
1962
1963 =cut
1964
1965 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1966
1967 =head2 $app->handle_request( @arguments )
1968
1969 Called to handle each HTTP request.
1970
1971 =cut
1972
1973 sub handle_request {
1974     my ( $class, @arguments ) = @_;
1975
1976     # Always expect worst case!
1977     my $status = -1;
1978     eval {
1979         if ($class->debug) {
1980             my $secs = time - $START || 1;
1981             my $av = sprintf '%.3f', $COUNT / $secs;
1982             my $time = localtime time;
1983             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1984         }
1985
1986         my $c = $class->prepare(@arguments);
1987         $c->dispatch;
1988         $status = $c->finalize;
1989     };
1990
1991     if ( my $error = $@ ) {
1992         chomp $error;
1993         $class->log->error(qq/Caught exception in engine "$error"/);
1994     }
1995
1996     $COUNT++;
1997
1998     if(my $coderef = $class->log->can('_flush')){
1999         $class->log->$coderef();
2000     }
2001     return $status;
2002 }
2003
2004 =head2 $c->prepare( @arguments )
2005
2006 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2007 etc.).
2008
2009 =cut
2010
2011 sub prepare {
2012     my ( $class, @arguments ) = @_;
2013
2014     # XXX
2015     # After the app/ctxt split, this should become an attribute based on something passed
2016     # into the application.
2017     $class->context_class( ref $class || $class ) unless $class->context_class;
2018
2019     my $c = $class->context_class->new({});
2020
2021     # For on-demand data
2022     $c->request->_context($c);
2023     $c->response->_context($c);
2024
2025     #surely this is not the most efficient way to do things...
2026     $c->stats($class->stats_class->new)->enable($c->use_stats);
2027     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2028         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2029     }
2030
2031     #XXX reuse coderef from can
2032     # Allow engine to direct the prepare flow (for POE)
2033     if ( $c->engine->can('prepare') ) {
2034         $c->engine->prepare( $c, @arguments );
2035     }
2036     else {
2037         $c->prepare_request(@arguments);
2038         $c->prepare_connection;
2039         $c->prepare_query_parameters;
2040         $c->prepare_headers;
2041         $c->prepare_cookies;
2042         $c->prepare_path;
2043
2044         # Prepare the body for reading, either by prepare_body
2045         # or the user, if they are using $c->read
2046         $c->prepare_read;
2047
2048         # Parse the body unless the user wants it on-demand
2049         unless ( ref($c)->config->{parse_on_demand} ) {
2050             $c->prepare_body;
2051         }
2052     }
2053
2054     my $method  = $c->req->method  || '';
2055     my $path    = $c->req->path;
2056     $path       = '/' unless length $path;
2057     my $address = $c->req->address || '';
2058
2059     $c->log_request;
2060
2061     $c->prepare_action;
2062
2063     return $c;
2064 }
2065
2066 =head2 $c->prepare_action
2067
2068 Prepares action. See L<Catalyst::Dispatcher>.
2069
2070 =cut
2071
2072 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2073
2074 =head2 $c->prepare_body
2075
2076 Prepares message body.
2077
2078 =cut
2079
2080 sub prepare_body {
2081     my $c = shift;
2082
2083     return if $c->request->_has_body;
2084
2085     # Initialize on-demand data
2086     $c->engine->prepare_body( $c, @_ );
2087     $c->prepare_parameters;
2088     $c->prepare_uploads;
2089 }
2090
2091 =head2 $c->prepare_body_chunk( $chunk )
2092
2093 Prepares a chunk of data before sending it to L<HTTP::Body>.
2094
2095 See L<Catalyst::Engine>.
2096
2097 =cut
2098
2099 sub prepare_body_chunk {
2100     my $c = shift;
2101     $c->engine->prepare_body_chunk( $c, @_ );
2102 }
2103
2104 =head2 $c->prepare_body_parameters
2105
2106 Prepares body parameters.
2107
2108 =cut
2109
2110 sub prepare_body_parameters {
2111     my $c = shift;
2112     $c->engine->prepare_body_parameters( $c, @_ );
2113 }
2114
2115 =head2 $c->prepare_connection
2116
2117 Prepares connection.
2118
2119 =cut
2120
2121 sub prepare_connection {
2122     my $c = shift;
2123     $c->engine->prepare_connection( $c, @_ );
2124 }
2125
2126 =head2 $c->prepare_cookies
2127
2128 Prepares cookies.
2129
2130 =cut
2131
2132 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2133
2134 =head2 $c->prepare_headers
2135
2136 Prepares headers.
2137
2138 =cut
2139
2140 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2141
2142 =head2 $c->prepare_parameters
2143
2144 Prepares parameters.
2145
2146 =cut
2147
2148 sub prepare_parameters {
2149     my $c = shift;
2150     $c->prepare_body_parameters;
2151     $c->engine->prepare_parameters( $c, @_ );
2152 }
2153
2154 =head2 $c->prepare_path
2155
2156 Prepares path and base.
2157
2158 =cut
2159
2160 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2161
2162 =head2 $c->prepare_query_parameters
2163
2164 Prepares query parameters.
2165
2166 =cut
2167
2168 sub prepare_query_parameters {
2169     my $c = shift;
2170
2171     $c->engine->prepare_query_parameters( $c, @_ );
2172 }
2173
2174 =head2 $c->log_request
2175
2176 Writes information about the request to the debug logs.  This includes:
2177
2178 =over 4
2179
2180 =item * Request method, path, and remote IP address
2181
2182 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2183
2184 =item * Request parameters
2185
2186 =item * File uploads
2187
2188 =back
2189
2190 =cut
2191
2192 sub log_request {
2193     my $c = shift;
2194
2195     return unless $c->debug;
2196
2197     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2198     my $request = $dump->[1];
2199
2200     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2201     $method ||= '';
2202     $path = '/' unless length $path;
2203     $address ||= '';
2204     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2205
2206     $c->log_request_headers($request->headers);
2207
2208     if ( my $keywords = $request->query_keywords ) {
2209         $c->log->debug("Query keywords are: $keywords");
2210     }
2211
2212     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2213
2214     $c->log_request_uploads($request);
2215 }
2216
2217 =head2 $c->log_response
2218
2219 Writes information about the response to the debug logs by calling
2220 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2221
2222 =cut
2223
2224 sub log_response {
2225     my $c = shift;
2226
2227     return unless $c->debug;
2228
2229     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2230     my $response = $dump->[1];
2231
2232     $c->log_response_status_line($response);
2233     $c->log_response_headers($response->headers);
2234 }
2235
2236 =head2 $c->log_response_status_line($response)
2237
2238 Writes one line of information about the response to the debug logs.  This includes:
2239
2240 =over 4
2241
2242 =item * Response status code
2243
2244 =item * Content-Type header (if present)
2245
2246 =item * Content-Length header (if present)
2247
2248 =back
2249
2250 =cut
2251
2252 sub log_response_status_line {
2253     my ($c, $response) = @_;
2254
2255     $c->log->debug(
2256         sprintf(
2257             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2258             $response->status                            || 'unknown',
2259             $response->headers->header('Content-Type')   || 'unknown',
2260             $response->headers->header('Content-Length') || 'unknown'
2261         )
2262     );
2263 }
2264
2265 =head2 $c->log_response_headers($headers);
2266
2267 Hook method which can be wrapped by plugins to log the responseheaders.
2268 No-op in the default implementation.
2269
2270 =cut
2271
2272 sub log_response_headers {}
2273
2274 =head2 $c->log_request_parameters( query => {}, body => {} )
2275
2276 Logs request parameters to debug logs
2277
2278 =cut
2279
2280 sub log_request_parameters {
2281     my $c          = shift;
2282     my %all_params = @_;
2283
2284     return unless $c->debug;
2285
2286     my $column_width = Catalyst::Utils::term_width() - 44;
2287     foreach my $type (qw(query body)) {
2288         my $params = $all_params{$type};
2289         next if ! keys %$params;
2290         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2291         for my $key ( sort keys %$params ) {
2292             my $param = $params->{$key};
2293             my $value = defined($param) ? $param : '';
2294             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2295         }
2296         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2297     }
2298 }
2299
2300 =head2 $c->log_request_uploads
2301
2302 Logs file uploads included in the request to the debug logs.
2303 The parameter name, filename, file type, and file size are all included in
2304 the debug logs.
2305
2306 =cut
2307
2308 sub log_request_uploads {
2309     my $c = shift;
2310     my $request = shift;
2311     return unless $c->debug;
2312     my $uploads = $request->uploads;
2313     if ( keys %$uploads ) {
2314         my $t = Text::SimpleTable->new(
2315             [ 12, 'Parameter' ],
2316             [ 26, 'Filename' ],
2317             [ 18, 'Type' ],
2318             [ 9,  'Size' ]
2319         );
2320         for my $key ( sort keys %$uploads ) {
2321             my $upload = $uploads->{$key};
2322             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2323                 $t->row( $key, $u->filename, $u->type, $u->size );
2324             }
2325         }
2326         $c->log->debug( "File Uploads are:\n" . $t->draw );
2327     }
2328 }
2329
2330 =head2 $c->log_request_headers($headers);
2331
2332 Hook method which can be wrapped by plugins to log the request headers.
2333 No-op in the default implementation.
2334
2335 =cut
2336
2337 sub log_request_headers {}
2338
2339 =head2 $c->log_headers($type => $headers)
2340
2341 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2342
2343 =cut
2344
2345 sub log_headers {
2346     my $c       = shift;
2347     my $type    = shift;
2348     my $headers = shift;    # an HTTP::Headers instance
2349
2350     return unless $c->debug;
2351
2352     my $column_width = Catalyst::Utils::term_width() - 28;
2353     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2354     $headers->scan(
2355         sub {
2356             my ( $name, $value ) = @_;
2357             $t->row( $name, $value );
2358         }
2359     );
2360     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2361 }
2362
2363
2364 =head2 $c->prepare_read
2365
2366 Prepares the input for reading.
2367
2368 =cut
2369
2370 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2371
2372 =head2 $c->prepare_request
2373
2374 Prepares the engine request.
2375
2376 =cut
2377
2378 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2379
2380 =head2 $c->prepare_uploads
2381
2382 Prepares uploads.
2383
2384 =cut
2385
2386 sub prepare_uploads {
2387     my $c = shift;
2388
2389     $c->engine->prepare_uploads( $c, @_ );
2390 }
2391
2392 =head2 $c->prepare_write
2393
2394 Prepares the output for writing.
2395
2396 =cut
2397
2398 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2399
2400 =head2 $c->request_class
2401
2402 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2403
2404 =head2 $c->response_class
2405
2406 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2407
2408 =head2 $c->read( [$maxlength] )
2409
2410 Reads a chunk of data from the request body. This method is designed to
2411 be used in a while loop, reading C<$maxlength> bytes on every call.
2412 C<$maxlength> defaults to the size of the request if not specified.
2413
2414 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2415 directly.
2416
2417 Warning: If you use read(), Catalyst will not process the body,
2418 so you will not be able to access POST parameters or file uploads via
2419 $c->request.  You must handle all body parsing yourself.
2420
2421 =cut
2422
2423 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2424
2425 =head2 $c->run
2426
2427 Starts the engine.
2428
2429 =cut
2430
2431 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2432
2433 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2434
2435 Sets an action in a given namespace.
2436
2437 =cut
2438
2439 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2440
2441 =head2 $c->setup_actions($component)
2442
2443 Sets up actions for a component.
2444
2445 =cut
2446
2447 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2448
2449 =head2 $c->setup_config
2450
2451 =cut
2452
2453 sub setup_config {
2454     my $class = shift;
2455
2456     my %args = %{$class->config || {} };
2457     my @container_classes = qw/MyApp::Container Catalyst::Container/;
2458     unshift @container_classes, delete $args{container_class} if exists $args{container_class};
2459
2460     my $container_class = Class::MOP::load_first_existing_class(@container_classes);
2461
2462     my $container = $container_class->new( %args, name => "$class" );
2463
2464     $container->add_sub_container(Bread::Board::Container->new( name => $_ )) for qw(model controller view);
2465     $class->container($container);
2466
2467     my $config = $container->fetch('config')->get;
2468     $class->config($config);
2469     $class->finalize_config; # back-compat
2470 }
2471
2472 =head $c->finalize_config
2473
2474 =cut
2475
2476 sub finalize_config { }
2477
2478 =head2 $c->setup_components
2479
2480 This method is called internally to set up the application's components.
2481
2482 It finds modules by calling the L<locate_components> method, expands them to
2483 package names with the L<expand_component_module> method, and then installs
2484 each component into the application.
2485
2486 The C<setup_components> config option is passed to both of the above methods.
2487
2488 Installation of each component is performed by the L<setup_component> method,
2489 below.
2490
2491 =cut
2492
2493 sub setup_components {
2494     my $class = shift;
2495
2496     my $config  = $class->config->{ setup_components };
2497
2498     my @comps = $class->locate_components($config);
2499     my %comps = map { $_ => 1 } @comps;
2500
2501     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2502     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2503         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2504     ) if $deprecatedcatalyst_component_names;
2505
2506     for my $component ( @comps ) {
2507
2508         # We pass ignore_loaded here so that overlay files for (e.g.)
2509         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2510         # we know M::P::O found a file on disk so this is safe
2511
2512         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2513     }
2514
2515     my $containers;
2516     $containers->{$_} = $class->container->get_sub_container($_) for qw(model view controller);
2517
2518     for my $component (@comps) {
2519         my $instance = $class->components->{ $component } = $class->setup_component($component);
2520         if ( my $type = _get_component_type($component) ) {
2521             $containers->{$type}->add_service(Bread::Board::BlockInjection->new( name => $component, block => sub { return $instance } ));
2522         }
2523         my @expanded_components = $instance->can('expand_modules')
2524             ? $instance->expand_modules( $component, $config )
2525             : $class->expand_component_module( $component, $config );
2526         for my $component (@expanded_components) {
2527             next if $comps{$component};
2528
2529             $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @expanded_components;
2530             $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2531                 qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2532             ) if $deprecatedcatalyst_component_names;
2533
2534             if (my $type = _get_component_type($component)) {
2535                 $containers->{$type}->add_service(Bread::Board::BlockInjection->new( name => $component, block => sub { return $class->setup_component($component) } ));
2536             }
2537
2538             $class->components->{ $component } = $class->setup_component($component);
2539         }
2540     }
2541 }
2542
2543 sub _get_component_type {
2544     my $component = shift;
2545     my @parts     = split /::/, $component;
2546
2547     for (@parts) {
2548         return 'controller' if /c|controller/i;
2549         return 'model'      if /m|model/i;
2550         return 'view'       if /v|view/i;
2551     }
2552 }
2553
2554 =head2 $c->locate_components( $setup_component_config )
2555
2556 This method is meant to provide a list of component modules that should be
2557 setup for the application.  By default, it will use L<Module::Pluggable>.
2558
2559 Specify a C<setup_components> config option to pass additional options directly
2560 to L<Module::Pluggable>. To add additional search paths, specify a key named
2561 C<search_extra> as an array reference. Items in the array beginning with C<::>
2562 will have the application class name prepended to them.
2563
2564 =cut
2565
2566 sub locate_components {
2567     my $class  = shift;
2568     my $config = shift;
2569
2570     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2571     my $extra   = delete $config->{ search_extra } || [];
2572
2573     push @paths, @$extra;
2574
2575     my $locator = Module::Pluggable::Object->new(
2576         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2577         %$config
2578     );
2579
2580     # XXX think about ditching this sort entirely
2581     my @comps = sort { length $a <=> length $b } $locator->plugins;
2582
2583     return @comps;
2584 }
2585
2586 =head2 $c->expand_component_module( $component, $setup_component_config )
2587
2588 Components found by C<locate_components> will be passed to this method, which
2589 is expected to return a list of component (package) names to be set up.
2590
2591 =cut
2592
2593 sub expand_component_module {
2594     my ($class, $module) = @_;
2595     return Devel::InnerPackage::list_packages( $module );
2596 }
2597
2598 =head2 $c->setup_component
2599
2600 =cut
2601
2602 sub setup_component {
2603     my( $class, $component ) = @_;
2604
2605     unless ( $component->can( 'COMPONENT' ) ) {
2606         return $component;
2607     }
2608
2609     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2610     my $config = $class->config->{ $suffix } || {};
2611     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2612     # methods also pass it. local to avoid pointlessly shitting in config
2613     # for the debug screen, as $component is already the key name.
2614     local $config->{catalyst_component_name} = $component;
2615
2616     my $instance = eval { $component->COMPONENT( $class, $config ); };
2617
2618     if ( my $error = $@ ) {
2619         chomp $error;
2620         Catalyst::Exception->throw(
2621             message => qq/Couldn't instantiate component "$component", "$error"/
2622         );
2623     }
2624
2625     unless (blessed $instance) {
2626         my $metaclass = Moose::Util::find_meta($component);
2627         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2628         my $component_method_from = $method_meta->associated_metaclass->name;
2629         my $value = defined($instance) ? $instance : 'undef';
2630         Catalyst::Exception->throw(
2631             message =>
2632             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2633         );
2634     }
2635     return $instance;
2636 }
2637
2638 =head2 $c->setup_dispatcher
2639
2640 Sets up dispatcher.
2641
2642 =cut
2643
2644 sub setup_dispatcher {
2645     my ( $class, $dispatcher ) = @_;
2646
2647     if ($dispatcher) {
2648         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2649     }
2650
2651     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2652         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2653     }
2654
2655     unless ($dispatcher) {
2656         $dispatcher = $class->dispatcher_class;
2657     }
2658
2659     Class::MOP::load_class($dispatcher);
2660
2661     # dispatcher instance
2662     $class->dispatcher( $dispatcher->new );
2663 }
2664
2665 =head2 $c->setup_engine
2666
2667 Sets up engine.
2668
2669 =cut
2670
2671 sub setup_engine {
2672     my ( $class, $engine ) = @_;
2673
2674     if ($engine) {
2675         $engine = 'Catalyst::Engine::' . $engine;
2676     }
2677
2678     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2679         $engine = 'Catalyst::Engine::' . $env;
2680     }
2681
2682     if ( $ENV{MOD_PERL} ) {
2683         my $meta = Class::MOP::get_metaclass_by_name($class);
2684
2685         # create the apache method
2686         $meta->add_method('apache' => sub { shift->engine->apache });
2687
2688         my ( $software, $version ) =
2689           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2690
2691         $version =~ s/_//g;
2692         $version =~ s/(\.[^.]+)\./$1/g;
2693
2694         if ( $software eq 'mod_perl' ) {
2695
2696             if ( !$engine ) {
2697
2698                 if ( $version >= 1.99922 ) {
2699                     $engine = 'Catalyst::Engine::Apache2::MP20';
2700                 }
2701
2702                 elsif ( $version >= 1.9901 ) {
2703                     $engine = 'Catalyst::Engine::Apache2::MP19';
2704                 }
2705
2706                 elsif ( $version >= 1.24 ) {
2707                     $engine = 'Catalyst::Engine::Apache::MP13';
2708                 }
2709
2710                 else {
2711                     Catalyst::Exception->throw( message =>
2712                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2713                 }
2714
2715             }
2716
2717             # install the correct mod_perl handler
2718             if ( $version >= 1.9901 ) {
2719                 *handler = sub  : method {
2720                     shift->handle_request(@_);
2721                 };
2722             }
2723             else {
2724                 *handler = sub ($$) { shift->handle_request(@_) };
2725             }
2726
2727         }
2728
2729         elsif ( $software eq 'Zeus-Perl' ) {
2730             $engine = 'Catalyst::Engine::Zeus';
2731         }
2732
2733         else {
2734             Catalyst::Exception->throw(
2735                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2736         }
2737     }
2738
2739     unless ($engine) {
2740         $engine = $class->engine_class;
2741     }
2742
2743     Class::MOP::load_class($engine);
2744
2745     # check for old engines that are no longer compatible
2746     my $old_engine;
2747     if ( $engine->isa('Catalyst::Engine::Apache')
2748         && !Catalyst::Engine::Apache->VERSION )
2749     {
2750         $old_engine = 1;
2751     }
2752
2753     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2754         && Catalyst::Engine::Server->VERSION le '0.02' )
2755     {
2756         $old_engine = 1;
2757     }
2758
2759     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2760         && $engine->VERSION eq '0.01' )
2761     {
2762         $old_engine = 1;
2763     }
2764
2765     elsif ($engine->isa('Catalyst::Engine::Zeus')
2766         && $engine->VERSION eq '0.01' )
2767     {
2768         $old_engine = 1;
2769     }
2770
2771     if ($old_engine) {
2772         Catalyst::Exception->throw( message =>
2773               qq/Engine "$engine" is not supported by this version of Catalyst/
2774         );
2775     }
2776
2777     # engine instance
2778     $class->engine( $engine->new );
2779 }
2780
2781 =head2 $c->setup_home
2782
2783 Sets up the home directory.
2784
2785 =cut
2786
2787 sub setup_home {
2788     my ( $class, $home ) = @_;
2789
2790     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2791         $home = $env;
2792     }
2793
2794     $home ||= Catalyst::Utils::home($class);
2795
2796     if ($home) {
2797         #I remember recently being scolded for assigning config values like this
2798         $class->config->{home} ||= $home;
2799         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2800     }
2801 }
2802
2803 =head2 $c->setup_log
2804
2805 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2806 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2807 log to.
2808
2809 This method also installs a C<debug> method that returns a true value into the
2810 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2811 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2812
2813 Note that if the log has already been setup, by either a previous call to
2814 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2815 that this method won't actually set up the log object.
2816
2817 =cut
2818
2819 sub setup_log {
2820     my ( $class, $levels ) = @_;
2821
2822     $levels ||= '';
2823     $levels =~ s/^\s+//;
2824     $levels =~ s/\s+$//;
2825     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2826
2827     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2828     if ( defined $env_debug ) {
2829         $levels{debug} = 1 if $env_debug; # Ugly!
2830         delete($levels{debug}) unless $env_debug;
2831     }
2832
2833     unless ( $class->log ) {
2834         $class->log( Catalyst::Log->new(keys %levels) );
2835     }
2836
2837     if ( $levels{debug} ) {
2838         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2839         $class->log->debug('Debug messages enabled');
2840     }
2841 }
2842
2843 =head2 $c->setup_plugins
2844
2845 Sets up plugins.
2846
2847 =cut
2848
2849 =head2 $c->setup_stats
2850
2851 Sets up timing statistics class.
2852
2853 =cut
2854
2855 sub setup_stats {
2856     my ( $class, $stats ) = @_;
2857
2858     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2859
2860     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2861     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2862         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2863         $class->log->debug('Statistics enabled');
2864     }
2865 }
2866
2867
2868 =head2 $c->registered_plugins
2869
2870 Returns a sorted list of the plugins which have either been stated in the
2871 import list or which have been added via C<< MyApp->plugin(@args); >>.
2872
2873 If passed a given plugin name, it will report a boolean value indicating
2874 whether or not that plugin is loaded.  A fully qualified name is required if
2875 the plugin name does not begin with C<Catalyst::Plugin::>.
2876
2877  if ($c->registered_plugins('Some::Plugin')) {
2878      ...
2879  }
2880
2881 =cut
2882
2883 {
2884
2885     sub registered_plugins {
2886         my $proto = shift;
2887         return sort keys %{ $proto->_plugins } unless @_;
2888         my $plugin = shift;
2889         return 1 if exists $proto->_plugins->{$plugin};
2890         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2891     }
2892
2893     sub _register_plugin {
2894         my ( $proto, $plugin, $instant ) = @_;
2895         my $class = ref $proto || $proto;
2896
2897         Class::MOP::load_class( $plugin );
2898         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2899             if $plugin->isa( 'Catalyst::Component' );
2900         $proto->_plugins->{$plugin} = 1;
2901         unless ($instant) {
2902             my $meta = Class::MOP::get_metaclass_by_name($class);
2903             $meta->superclasses($plugin, $meta->superclasses);
2904         }
2905         return $class;
2906     }
2907
2908     sub setup_plugins {
2909         my ( $class, $plugins ) = @_;
2910
2911         $class->_plugins( {} ) unless $class->_plugins;
2912         $plugins = Data::OptList::mkopt($plugins || []);
2913
2914         my @plugins = map {
2915             [ Catalyst::Utils::resolve_namespace(
2916                   $class . '::Plugin',
2917                   'Catalyst::Plugin', $_->[0]
2918               ),
2919               $_->[1],
2920             ]
2921          } @{ $plugins };
2922
2923         for my $plugin ( reverse @plugins ) {
2924             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2925             my $meta = find_meta($plugin->[0]);
2926             next if $meta && $meta->isa('Moose::Meta::Role');
2927
2928             $class->_register_plugin($plugin->[0]);
2929         }
2930
2931         my @roles =
2932             map  { $_->[0]->name, $_->[1] }
2933             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2934             map  { [find_meta($_->[0]), $_->[1]] }
2935             @plugins;
2936
2937         Moose::Util::apply_all_roles(
2938             $class => @roles
2939         ) if @roles;
2940     }
2941 }
2942
2943 =head2 $c->stack
2944
2945 Returns an arrayref of the internal execution stack (actions that are
2946 currently executing).
2947
2948 =head2 $c->stats
2949
2950 Returns the current timing statistics object. By default Catalyst uses
2951 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2952 L<< stats_class|/"$c->stats_class" >>.
2953
2954 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2955 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2956 profile explicitly, although MyApp.pm still won't profile nor output anything
2957 by itself.
2958
2959 =head2 $c->stats_class
2960
2961 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2962
2963 =head2 $c->use_stats
2964
2965 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2966
2967 Note that this is a static method, not an accessor and should be overridden
2968 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2969
2970 =cut
2971
2972 sub use_stats { 0 }
2973
2974
2975 =head2 $c->write( $data )
2976
2977 Writes $data to the output stream. When using this method directly, you
2978 will need to manually set the C<Content-Length> header to the length of
2979 your output data, if known.
2980
2981 =cut
2982
2983 sub write {
2984     my $c = shift;
2985
2986     # Finalize headers if someone manually writes output
2987     $c->finalize_headers;
2988
2989     return $c->engine->write( $c, @_ );
2990 }
2991
2992 =head2 version
2993
2994 Returns the Catalyst version number. Mostly useful for "powered by"
2995 messages in template systems.
2996
2997 =cut
2998
2999 sub version { return $Catalyst::VERSION }
3000
3001 =head1 CONFIGURATION
3002
3003 There are a number of 'base' config variables which can be set:
3004
3005 =over
3006
3007 =item *
3008
3009 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3010
3011 =item *
3012
3013 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3014
3015 =item *
3016
3017 C<disable_component_resolution_regex_fallback> - Turns
3018 off the deprecated component resolution functionality so
3019 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3020 are called then regex search will not be attempted on string values and
3021 instead C<undef> will be returned.
3022
3023 =item *
3024
3025 C<home> - The application home directory. In an uninstalled application,
3026 this is the top level application directory. In an installed application,
3027 this will be the directory containing C<< MyApp.pm >>.
3028
3029 =item *
3030
3031 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3032
3033 =item *
3034
3035 C<name> - The name of the application in debug messages and the debug and
3036 welcome screens
3037
3038 =item *
3039
3040 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3041 until it is accessed. This allows you to (for example) check authentication (and reject
3042 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
3043
3044 =item *
3045
3046 C<root> - The root directory for templates. Usually this is just a
3047 subdirectory of the home directory, but you can set it to change the
3048 templates to a different directory.
3049
3050 =item *
3051
3052 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3053 namespaces from which components will be loaded (and constructed and stored in
3054 C<< $c->components >>).
3055
3056 =item *
3057
3058 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3059 to be shown in hit debug tables in the test server.
3060
3061 =item *
3062
3063 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3064 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
3065 for more information.
3066
3067 =item *
3068
3069 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3070
3071 =back
3072
3073 =head1 INTERNAL ACTIONS
3074
3075 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3076 C<_ACTION>, and C<_END>. These are by default not shown in the private
3077 action table, but you can make them visible with a config parameter.
3078
3079     MyApp->config(show_internal_actions => 1);
3080
3081 =head1 ON-DEMAND PARSER
3082
3083 The request body is usually parsed at the beginning of a request,
3084 but if you want to handle input yourself, you can enable on-demand
3085 parsing with a config parameter.
3086
3087     MyApp->config(parse_on_demand => 1);
3088
3089 =head1 PROXY SUPPORT
3090
3091 Many production servers operate using the common double-server approach,
3092 with a lightweight frontend web server passing requests to a larger
3093 backend server. An application running on the backend server must deal
3094 with two problems: the remote user always appears to be C<127.0.0.1> and
3095 the server's hostname will appear to be C<localhost> regardless of the
3096 virtual host that the user connected through.
3097
3098 Catalyst will automatically detect this situation when you are running
3099 the frontend and backend servers on the same machine. The following
3100 changes are made to the request.
3101
3102     $c->req->address is set to the user's real IP address, as read from
3103     the HTTP X-Forwarded-For header.
3104
3105     The host value for $c->req->base and $c->req->uri is set to the real
3106     host, as read from the HTTP X-Forwarded-Host header.
3107
3108 Additionally, you may be running your backend application on an insecure
3109 connection (port 80) while your frontend proxy is running under SSL.  If there
3110 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3111 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3112 be created properly.
3113
3114 In the case of passing in:
3115
3116     X-Forwarded-Port: 443
3117
3118 All calls to C<uri_for> will result in an https link, as is expected.
3119
3120 Obviously, your web server must support these headers for this to work.
3121
3122 In a more complex server farm environment where you may have your
3123 frontend proxy server(s) on different machines, you will need to set a
3124 configuration option to tell Catalyst to read the proxied data from the
3125 headers.
3126
3127     MyApp->config(using_frontend_proxy => 1);
3128
3129 If you do not wish to use the proxy support at all, you may set:
3130
3131     MyApp->config(ignore_frontend_proxy => 1);
3132
3133 =head1 THREAD SAFETY
3134
3135 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3136 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3137 believe the Catalyst core to be thread-safe.
3138
3139 If you plan to operate in a threaded environment, remember that all other
3140 modules you are using must also be thread-safe. Some modules, most notably
3141 L<DBD::SQLite>, are not thread-safe.
3142
3143 =head1 SUPPORT
3144
3145 IRC:
3146
3147     Join #catalyst on irc.perl.org.
3148
3149 Mailing Lists:
3150
3151     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3152     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3153
3154 Web:
3155
3156     http://catalyst.perl.org
3157
3158 Wiki:
3159
3160     http://dev.catalyst.perl.org
3161
3162 =head1 SEE ALSO
3163
3164 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3165
3166 =head2 L<Catalyst::Manual> - The Catalyst Manual
3167
3168 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3169
3170 =head2 L<Catalyst::Engine> - Core engine
3171
3172 =head2 L<Catalyst::Log> - Log class.
3173
3174 =head2 L<Catalyst::Request> - Request object
3175
3176 =head2 L<Catalyst::Response> - Response object
3177
3178 =head2 L<Catalyst::Test> - The test suite.
3179
3180 =head1 PROJECT FOUNDER
3181
3182 sri: Sebastian Riedel <sri@cpan.org>
3183
3184 =head1 CONTRIBUTORS
3185
3186 abw: Andy Wardley
3187
3188 acme: Leon Brocard <leon@astray.com>
3189
3190 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3191
3192 Andrew Bramble
3193
3194 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3195
3196 Andrew Ruthven
3197
3198 andyg: Andy Grundman <andy@hybridized.org>
3199
3200 audreyt: Audrey Tang
3201
3202 bricas: Brian Cassidy <bricas@cpan.org>
3203
3204 Caelum: Rafael Kitover <rkitover@io.com>
3205
3206 chansen: Christian Hansen
3207
3208 chicks: Christopher Hicks
3209
3210 Chisel Wright C<pause@herlpacker.co.uk>
3211
3212 Danijel Milicevic C<me@danijel.de>
3213
3214 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3215
3216 David Naughton, C<naughton@umn.edu>
3217
3218 David E. Wheeler
3219
3220 dhoss: Devin Austin <dhoss@cpan.org>
3221
3222 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3223
3224 Drew Taylor
3225
3226 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3227
3228 esskar: Sascha Kiefer
3229
3230 fireartist: Carl Franks <cfranks@cpan.org>
3231
3232 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3233
3234 gabb: Danijel Milicevic
3235
3236 Gary Ashton Jones
3237
3238 Gavin Henry C<ghenry@perl.me.uk>
3239
3240 Geoff Richards
3241
3242 groditi: Guillermo Roditi <groditi@gmail.com>
3243
3244 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3245
3246 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3247
3248 jcamacho: Juan Camacho
3249
3250 jester: Jesse Sheidlower C<jester@panix.com>
3251
3252 jhannah: Jay Hannah <jay@jays.net>
3253
3254 Jody Belka
3255
3256 Johan Lindstrom
3257
3258 jon: Jon Schutz <jjschutz@cpan.org>
3259
3260 Jonathan Rockway C<< <jrockway@cpan.org> >>
3261
3262 Kieren Diment C<kd@totaldatasolution.com>
3263
3264 konobi: Scott McWhirter <konobi@cpan.org>
3265
3266 marcus: Marcus Ramberg <mramberg@cpan.org>
3267
3268 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3269
3270 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3271
3272 mugwump: Sam Vilain
3273
3274 naughton: David Naughton
3275
3276 ningu: David Kamholz <dkamholz@cpan.org>
3277
3278 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3279
3280 numa: Dan Sully <daniel@cpan.org>
3281
3282 obra: Jesse Vincent
3283
3284 Octavian Rasnita
3285
3286 omega: Andreas Marienborg
3287
3288 Oleg Kostyuk <cub.uanic@gmail.com>
3289
3290 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3291
3292 rafl: Florian Ragwitz <rafl@debian.org>
3293
3294 random: Roland Lammel <lammel@cpan.org>
3295
3296 Robert Sedlacek C<< <rs@474.at> >>
3297
3298 SpiceMan: Marcel Montes
3299
3300 sky: Arthur Bergman
3301
3302 szbalint: Balint Szilakszi <szbalint@cpan.org>
3303
3304 t0m: Tomas Doran <bobtfish@bobtfish.net>
3305
3306 Ulf Edvinsson
3307
3308 Viljo Marrandi C<vilts@yahoo.com>
3309
3310 Will Hawes C<info@whawes.co.uk>
3311
3312 willert: Sebastian Willert <willert@cpan.org>
3313
3314 wreis: Wallace Reis <wallace@reis.org.br>
3315
3316 Yuval Kogman, C<nothingmuch@woobling.org>
3317
3318 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3319
3320 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3321
3322 =head1 COPYRIGHT
3323
3324 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3325
3326 =head1 LICENSE
3327
3328 This library is free software. You can redistribute it and/or modify it under
3329 the same terms as Perl itself.
3330
3331 =cut
3332
3333 no Moose;
3334
3335 __PACKAGE__->meta->make_immutable;
3336
3337 1;