lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         $self->request_class->new($self->_build_request_constructor_args);
  67     },
  68     lazy => 1,
  69 );
  70 sub _build_request_constructor_args {
  71     my $self = shift;
  72     my %p = ( _log => $self->log );
  73     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  74     $p{data_handlers} = {$self->registered_data_handlers};
  75     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  76       if $self->config->{use_hash_multivalue_in_request};
  77     \%p;
  78 }
  79
  80 has response => (
  81     is => 'rw',
  82     default => sub {
  83         my $self = shift;
  84         $self->response_class->new($self->_build_response_constructor_args);
  85     },
  86     lazy => 1,
  87 );
  88 sub _build_response_constructor_args {
  89     return +{
  90       _log => $_[0]->log,
  91       encoding => $_[0]->encoding,
  92     };
  93 }
  94
  95 has namespace => (is => 'rw');
  96
  97 sub depth { scalar @{ shift->stack || [] }; }
  98 sub comp { shift->component(@_) }
  99
 100 sub req {
 101     my $self = shift; return $self->request(@_);
 102 }
 103 sub res {
 104     my $self = shift; return $self->response(@_);
 105 }
 106
 107 # For backwards compatibility
 108 sub finalize_output { shift->finalize_body(@_) };
 109
 110 # For statistics
 111 our $COUNT     = 1;
 112 our $START     = time;
 113 our $RECURSION = 1000;
 114 our $DETACH    = Catalyst::Exception::Detach->new;
 115 our $GO        = Catalyst::Exception::Go->new;
 116
 117 #I imagine that very few of these really need to be class variables. if any.
 118 #maybe we should just make them attributes with a default?
 119 __PACKAGE__->mk_classdata($_)
 120   for qw/components arguments dispatcher engine log dispatcher_class
 121   engine_loader context_class request_class response_class stats_class
 122   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 123   _data_handlers _encoding _encode_check finalized_default_middleware/;
 124
 125 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 126 __PACKAGE__->request_class('Catalyst::Request');
 127 __PACKAGE__->response_class('Catalyst::Response');
 128 __PACKAGE__->stats_class('Catalyst::Stats');
 129 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 130
 131 # Remember to update this in Catalyst::Runtime as well!
 132 our $VERSION = '5.90089_001';
 133 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 134
 135 sub import {
 136     my ( $class, @arguments ) = @_;
 137
 138     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 139     # callers @ISA.
 140     return unless $class eq 'Catalyst';
 141
 142     my $caller = caller();
 143     return if $caller eq 'main';
 144
 145     my $meta = Moose::Meta::Class->initialize($caller);
 146     unless ( $caller->isa('Catalyst') ) {
 147         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 148         $meta->superclasses(@superclasses);
 149     }
 150     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 151     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 152
 153     unless( $meta->has_method('meta') ){
 154         if ($Moose::VERSION >= 1.15) {
 155             $meta->_add_meta_method('meta');
 156         }
 157         else {
 158             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 159         }
 160     }
 161
 162     $caller->arguments( [@arguments] );
 163     $caller->setup_home;
 164 }
 165
 166 sub _application { $_[0] }
 167
 168 =encoding UTF-8
 169
 170 =head1 NAME
 171
 172 Catalyst - The Elegant MVC Web Application Framework
 173
 174 =head1 SYNOPSIS
 175
 176 See the L<Catalyst::Manual> distribution for comprehensive
 177 documentation and tutorials.
 178
 179     # Install Catalyst::Devel for helpers and other development tools
 180     # use the helper to create a new application
 181     catalyst.pl MyApp
 182
 183     # add models, views, controllers
 184     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 185     script/myapp_create.pl view MyTemplate TT
 186     script/myapp_create.pl controller Search
 187
 188     # built in testserver -- use -r to restart automatically on changes
 189     # --help to see all available options
 190     script/myapp_server.pl
 191
 192     # command line testing interface
 193     script/myapp_test.pl /yada
 194
 195     ### in lib/MyApp.pm
 196     use Catalyst qw/-Debug/; # include plugins here as well
 197
 198     ### In lib/MyApp/Controller/Root.pm (autocreated)
 199     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 200         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 201         $c->stash->{template} = 'foo.tt'; # set the template
 202         # lookup something from db -- stash vars are passed to TT
 203         $c->stash->{data} =
 204           $c->model('Database::Foo')->search( { country => $args[0] } );
 205         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 206             $c->forward( 'bar' ); # process another action
 207             # do something else after forward returns
 208         }
 209     }
 210
 211     # The foo.tt TT template can use the stash data from the database
 212     [% WHILE (item = data.next) %]
 213         [% item.foo %]
 214     [% END %]
 215
 216     # called for /bar/of/soap, /bar/of/soap/10, etc.
 217     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 218
 219     # called after all actions are finished
 220     sub end : Action {
 221         my ( $self, $c ) = @_;
 222         if ( scalar @{ $c->error } ) { ... } # handle errors
 223         return if $c->res->body; # already have a response
 224         $c->forward( 'MyApp::View::TT' ); # render template
 225     }
 226
 227 See L<Catalyst::Manual::Intro> for additional information.
 228
 229 =head1 DESCRIPTION
 230
 231 Catalyst is a modern framework for making web applications without the
 232 pain usually associated with this process. This document is a reference
 233 to the main Catalyst application. If you are a new user, we suggest you
 234 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 235
 236 See L<Catalyst::Manual> for more documentation.
 237
 238 Catalyst plugins can be loaded by naming them as arguments to the "use
 239 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 240 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 241 C<My::Module>.
 242
 243     use Catalyst qw/My::Module/;
 244
 245 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 246 fully qualify the name by using a unary plus:
 247
 248     use Catalyst qw/
 249         My::Module
 250         +Fully::Qualified::Plugin::Name
 251     /;
 252
 253 Special flags like C<-Debug> can also be specified as
 254 arguments when Catalyst is loaded:
 255
 256     use Catalyst qw/-Debug My::Module/;
 257
 258 The position of plugins and flags in the chain is important, because
 259 they are loaded in the order in which they appear.
 260
 261 The following flags are supported:
 262
 263 =head2 -Debug
 264
 265 Enables debug output. You can also force this setting from the system
 266 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 267 settings override the application, with <MYAPP>_DEBUG having the highest
 268 priority.
 269
 270 This sets the log level to 'debug' and enables full debug output on the
 271 error screen. If you only want the latter, see L<< $c->debug >>.
 272
 273 =head2 -Home
 274
 275 Forces Catalyst to use a specific home directory, e.g.:
 276
 277     use Catalyst qw[-Home=/usr/mst];
 278
 279 This can also be done in the shell environment by setting either the
 280 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 281 is replaced with the uppercased name of your application, any "::" in
 282 the name will be replaced with underscores, e.g. MyApp::Web should use
 283 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 284
 285 If none of these are set, Catalyst will attempt to automatically detect the
 286 home directory. If you are working in a development environment, Catalyst
 287 will try and find the directory containing either Makefile.PL, Build.PL,
 288 dist.ini, or cpanfile. If the application has been installed into the system
 289 (i.e. you have done C<make install>), then Catalyst will use the path to your
 290 application module, without the .pm extension (e.g., /foo/MyApp if your
 291 application was installed at /foo/MyApp.pm)
 292
 293 =head2 -Log
 294
 295     use Catalyst '-Log=warn,fatal,error';
 296
 297 Specifies a comma-delimited list of log levels.
 298
 299 =head2 -Stats
 300
 301 Enables statistics collection and reporting.
 302
 303    use Catalyst qw/-Stats=1/;
 304
 305 You can also force this setting from the system environment with CATALYST_STATS
 306 or <MYAPP>_STATS. The environment settings override the application, with
 307 <MYAPP>_STATS having the highest priority.
 308
 309 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 310
 311 =head1 METHODS
 312
 313 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 314
 315 =head2 $c->action
 316
 317 Returns a L<Catalyst::Action> object for the current action, which
 318 stringifies to the action name. See L<Catalyst::Action>.
 319
 320 =head2 $c->namespace
 321
 322 Returns the namespace of the current action, i.e., the URI prefix
 323 corresponding to the controller of the current action. For example:
 324
 325     # in Controller::Foo::Bar
 326     $c->namespace; # returns 'foo/bar';
 327
 328 =head2 $c->request
 329
 330 =head2 $c->req
 331
 332 Returns the current L<Catalyst::Request> object, giving access to
 333 information about the current client request (including parameters,
 334 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 335
 336 =head2 REQUEST FLOW HANDLING
 337
 338 =head2 $c->forward( $action [, \@arguments ] )
 339
 340 =head2 $c->forward( $class, $method, [, \@arguments ] )
 341
 342 This is one way of calling another action (method) in the same or
 343 a different controller. You can also use C<< $self->my_method($c, @args) >>
 344 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 345 in a different controller.
 346 The main difference is that 'forward' uses some of the Catalyst request
 347 cycle overhead, including debugging, which may be useful to you. On the
 348 other hand, there are some complications to using 'forward', restrictions
 349 on values returned from 'forward', and it may not handle errors as you prefer.
 350 Whether you use 'forward' or not is up to you; it is not considered superior to
 351 the other ways to call a method.
 352
 353 'forward' calls  another action, by its private name. If you give a
 354 class name but no method, C<process()> is called. You may also optionally
 355 pass arguments in an arrayref. The action will receive the arguments in
 356 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 357 C<< $c->req->args >> will be restored to the previous values.
 358
 359 Any data C<return>ed from the action forwarded to, will be returned by the
 360 call to forward.
 361
 362     my $foodata = $c->forward('/foo');
 363     $c->forward('index');
 364     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 365     $c->forward('View::TT');
 366
 367 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 368 an C<< eval { } >> around the call (actually
 369 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 370 exceptions thrown by the called action non-fatal and pushing them onto
 371 $c->error instead. If you want C<die> to propagate you need to do something
 372 like:
 373
 374     $c->forward('foo');
 375     die join "\n", @{ $c->error } if @{ $c->error };
 376
 377 Or make sure to always return true values from your actions and write
 378 your code like this:
 379
 380     $c->forward('foo') || return;
 381
 382 Another note is that C<< $c->forward >> always returns a scalar because it
 383 actually returns $c->state which operates in a scalar context.
 384 Thus, something like:
 385
 386     return @array;
 387
 388 in an action that is forwarded to is going to return a scalar,
 389 i.e. how many items are in that array, which is probably not what you want.
 390 If you need to return an array then return a reference to it,
 391 or stash it like so:
 392
 393     $c->stash->{array} = \@array;
 394
 395 and access it from the stash.
 396
 397 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 398
 399 =cut
 400
 401 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 402
 403 =head2 $c->detach( $action [, \@arguments ] )
 404
 405 =head2 $c->detach( $class, $method, [, \@arguments ] )
 406
 407 =head2 $c->detach()
 408
 409 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 410 doesn't return to the previous action when processing is finished.
 411
 412 When called with no arguments it escapes the processing chain entirely.
 413
 414 =cut
 415
 416 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 417
 418 =head2 $c->visit( $action [, \@arguments ] )
 419
 420 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 421
 422 =head2 $c->visit( $class, $method, [, \@arguments ] )
 423
 424 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 425
 426 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 427 but does a full dispatch, instead of just calling the new C<$action> /
 428 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 429 you go to are called, just like a new request.
 430
 431 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 432 This means, for example, that C<< $c->action >> methods such as
 433 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 434 L<reverse|Catalyst::Action/reverse> return information for the visited action
 435 when they are invoked within the visited action.  This is different from the
 436 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 437 continues to use the $c->action object from the caller action even when
 438 invoked from the called action.
 439
 440 C<< $c->stash >> is kept unchanged.
 441
 442 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 443 allows you to "wrap" another action, just as it would have been called by
 444 dispatching from a URL, while the analogous
 445 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 446 transfer control to another action as if it had been reached directly from a URL.
 447
 448 =cut
 449
 450 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 451
 452 =head2 $c->go( $action [, \@arguments ] )
 453
 454 =head2 $c->go( $action [, \@captures, \@arguments ] )
 455
 456 =head2 $c->go( $class, $method, [, \@arguments ] )
 457
 458 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 459
 460 The relationship between C<go> and
 461 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 462 the relationship between
 463 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 464 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 465 C<< $c->go >> will perform a full dispatch on the specified action or method,
 466 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 467 C<go> escapes the processing of the current request chain on completion, and
 468 does not return to its caller.
 469
 470 @arguments are arguments to the final destination of $action. @captures are
 471 arguments to the intermediate steps, if any, on the way to the final sub of
 472 $action.
 473
 474 =cut
 475
 476 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 477
 478 =head2 $c->response
 479
 480 =head2 $c->res
 481
 482 Returns the current L<Catalyst::Response> object, see there for details.
 483
 484 =head2 $c->stash
 485
 486 Returns a hashref to the stash, which may be used to store data and pass
 487 it between components during a request. You can also set hash keys by
 488 passing arguments. The stash is automatically sent to the view. The
 489 stash is cleared at the end of a request; it cannot be used for
 490 persistent storage (for this you must use a session; see
 491 L<Catalyst::Plugin::Session> for a complete system integrated with
 492 Catalyst).
 493
 494     $c->stash->{foo} = $bar;
 495     $c->stash( { moose => 'majestic', qux => 0 } );
 496     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 497
 498     # stash is automatically passed to the view for use in a template
 499     $c->forward( 'MyApp::View::TT' );
 500
 501 The stash hash is currently stored in the PSGI C<$env> and is managed by
 502 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 503 the stash can be accessed in sub applications mounted under your main
 504 L<Catalyst> application.  For example if you delegate the response of an
 505 action to another L<Catalyst> application, that sub application will have
 506 access to all the stash keys of the main one, and if can of course add
 507 more keys of its own.  However those new keys will not 'bubble' back up
 508 to the main application.
 509
 510 For more information the best thing to do is to review the test case:
 511 t/middleware-stash.t in the distribution /t directory.
 512
 513 =cut
 514
 515 sub stash {
 516   my $c = shift;
 517   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 518 }
 519
 520 =head2 $c->error
 521
 522 =head2 $c->error($error, ...)
 523
 524 =head2 $c->error($arrayref)
 525
 526 Returns an arrayref containing error messages.  If Catalyst encounters an
 527 error while processing a request, it stores the error in $c->error.  This
 528 method should only be used to store fatal error messages.
 529
 530     my @error = @{ $c->error };
 531
 532 Add a new error.
 533
 534     $c->error('Something bad happened');
 535
 536 Calling this will always return an arrayref (if there are no errors it
 537 will be an empty arrayref.
 538
 539 =cut
 540
 541 sub error {
 542     my $c = shift;
 543     if ( $_[0] ) {
 544         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 545         croak @$error unless ref $c;
 546         push @{ $c->{error} }, @$error;
 547     }
 548     elsif ( defined $_[0] ) { $c->{error} = undef }
 549     return $c->{error} || [];
 550 }
 551
 552
 553 =head2 $c->state
 554
 555 Contains the return value of the last executed action.
 556 Note that << $c->state >> operates in a scalar context which means that all
 557 values it returns are scalar.
 558
 559 =head2 $c->clear_errors
 560
 561 Clear errors.  You probably don't want to clear the errors unless you are
 562 implementing a custom error screen.
 563
 564 This is equivalent to running
 565
 566     $c->error(0);
 567
 568 =cut
 569
 570 sub clear_errors {
 571     my $c = shift;
 572     $c->error(0);
 573 }
 574
 575 =head2 $c->has_errors
 576
 577 Returns true if you have errors
 578
 579 =cut
 580
 581 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 582
 583 =head2 $c->last_error
 584
 585 Returns the most recent error in the stack (the one most recently added...)
 586 or nothing if there are no errors.
 587
 588 =cut
 589
 590 sub last_error { my ($err, @errs) = @{shift->error}; return $err }
 591
 592 =head2 shift_errors
 593
 594 shifts the most recently added error off the error stack and returns if.  Returns
 595 nothing if there are no more errors.
 596
 597 =cut
 598
 599 sub shift_errors {
 600     my ($self) = @_;
 601     my ($err, @errors) = @{$self->error};
 602     $self->{error} = \@errors;
 603     return $err;
 604 }
 605
 606 sub _comp_search_prefixes {
 607     my $c = shift;
 608     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 609 }
 610
 611 # search components given a name and some prefixes
 612 sub _comp_names_search_prefixes {
 613     my ( $c, $name, @prefixes ) = @_;
 614     my $appclass = ref $c || $c;
 615     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 616     $filter = qr/$filter/; # Compile regex now rather than once per loop
 617
 618     # map the original component name to the sub part that we will search against
 619     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 620         grep { /$filter/ } keys %{ $c->components };
 621
 622     # undef for a name will return all
 623     return keys %eligible if !defined $name;
 624
 625     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 626     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 627
 628     return @result if @result;
 629
 630     # if we were given a regexp to search against, we're done.
 631     return if $name->$_isa('Regexp');
 632
 633     # skip regexp fallback if configured
 634     return
 635         if $appclass->config->{disable_component_resolution_regex_fallback};
 636
 637     # regexp fallback
 638     $query  = qr/$name/i;
 639     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 640
 641     # no results? try against full names
 642     if( !@result ) {
 643         @result = grep { m{$query} } keys %eligible;
 644     }
 645
 646     # don't warn if we didn't find any results, it just might not exist
 647     if( @result ) {
 648         # Disgusting hack to work out correct method name
 649         my $warn_for = lc $prefixes[0];
 650         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 651            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 652            "component resolution is unreliable and unsafe.";
 653         my $short = $result[0];
 654         # remove the component namespace prefix
 655         $short =~ s/.*?(Model|Controller|View):://;
 656         my $shortmess = Carp::shortmess('');
 657         if ($shortmess =~ m#Catalyst/Plugin#) {
 658            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 659               "plugin's config";
 660         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 661            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 662               "component's config";
 663         } else {
 664            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 665               "but if you really wanted to search, pass in a regexp as the argument " .
 666               "like so: \$c->${warn_for}(qr/${name}/)";
 667         }
 668         $c->log->warn( "${msg}$shortmess" );
 669     }
 670
 671     return @result;
 672 }
 673
 674 # Find possible names for a prefix
 675 sub _comp_names {
 676     my ( $c, @prefixes ) = @_;
 677     my $appclass = ref $c || $c;
 678
 679     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 680
 681     my @names = map { s{$filter}{}; $_; }
 682         $c->_comp_names_search_prefixes( undef, @prefixes );
 683
 684     return @names;
 685 }
 686
 687 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 688 sub _filter_component {
 689     my ( $c, $comp, @args ) = @_;
 690
 691     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 692         return $comp->ACCEPT_CONTEXT( $c, @args );
 693     }
 694
 695     return $comp;
 696 }
 697
 698 =head2 COMPONENT ACCESSORS
 699
 700 =head2 $c->controller($name)
 701
 702 Gets a L<Catalyst::Controller> instance by name.
 703
 704     $c->controller('Foo')->do_stuff;
 705
 706 If the name is omitted, will return the controller for the dispatched
 707 action.
 708
 709 If you want to search for controllers, pass in a regexp as the argument.
 710
 711     # find all controllers that start with Foo
 712     my @foo_controllers = $c->controller(qr{^Foo});
 713
 714
 715 =cut
 716
 717 sub controller {
 718     my ( $c, $name, @args ) = @_;
 719
 720     my $appclass = ref($c) || $c;
 721     if( $name ) {
 722         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 723             my $comps = $c->components;
 724             my $check = $appclass."::Controller::".$name;
 725             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 726         }
 727         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 728         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 729         return $c->_filter_component( $result[ 0 ], @args );
 730     }
 731
 732     return $c->component( $c->action->class );
 733 }
 734
 735 =head2 $c->model($name)
 736
 737 Gets a L<Catalyst::Model> instance by name.
 738
 739     $c->model('Foo')->do_stuff;
 740
 741 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 742
 743 If the name is omitted, it will look for
 744  - a model object in $c->stash->{current_model_instance}, then
 745  - a model name in $c->stash->{current_model}, then
 746  - a config setting 'default_model', or
 747  - check if there is only one model, and return it if that's the case.
 748
 749 If you want to search for models, pass in a regexp as the argument.
 750
 751     # find all models that start with Foo
 752     my @foo_models = $c->model(qr{^Foo});
 753
 754 =cut
 755
 756 sub model {
 757     my ( $c, $name, @args ) = @_;
 758     my $appclass = ref($c) || $c;
 759     if( $name ) {
 760         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 761             my $comps = $c->components;
 762             my $check = $appclass."::Model::".$name;
 763             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 764         }
 765         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 766         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 767         return $c->_filter_component( $result[ 0 ], @args );
 768     }
 769
 770     if (ref $c) {
 771         return $c->stash->{current_model_instance}
 772           if $c->stash->{current_model_instance};
 773         return $c->model( $c->stash->{current_model} )
 774           if $c->stash->{current_model};
 775     }
 776     return $c->model( $appclass->config->{default_model} )
 777       if $appclass->config->{default_model};
 778
 779     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 780
 781     if( $rest ) {
 782         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 783         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 784         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 785         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 786         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 787     }
 788
 789     return $c->_filter_component( $comp );
 790 }
 791
 792
 793 =head2 $c->view($name)
 794
 795 Gets a L<Catalyst::View> instance by name.
 796
 797     $c->view('Foo')->do_stuff;
 798
 799 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 800
 801 If the name is omitted, it will look for
 802  - a view object in $c->stash->{current_view_instance}, then
 803  - a view name in $c->stash->{current_view}, then
 804  - a config setting 'default_view', or
 805  - check if there is only one view, and return it if that's the case.
 806
 807 If you want to search for views, pass in a regexp as the argument.
 808
 809     # find all views that start with Foo
 810     my @foo_views = $c->view(qr{^Foo});
 811
 812 =cut
 813
 814 sub view {
 815     my ( $c, $name, @args ) = @_;
 816
 817     my $appclass = ref($c) || $c;
 818     if( $name ) {
 819         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 820             my $comps = $c->components;
 821             my $check = $appclass."::View::".$name;
 822             if( exists $comps->{$check} ) {
 823                 return $c->_filter_component( $comps->{$check}, @args );
 824             }
 825             else {
 826                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 827             }
 828         }
 829         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 830         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 831         return $c->_filter_component( $result[ 0 ], @args );
 832     }
 833
 834     if (ref $c) {
 835         return $c->stash->{current_view_instance}
 836           if $c->stash->{current_view_instance};
 837         return $c->view( $c->stash->{current_view} )
 838           if $c->stash->{current_view};
 839     }
 840     return $c->view( $appclass->config->{default_view} )
 841       if $appclass->config->{default_view};
 842
 843     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 844
 845     if( $rest ) {
 846         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 847         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 848         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 849         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 850         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 851     }
 852
 853     return $c->_filter_component( $comp );
 854 }
 855
 856 =head2 $c->controllers
 857
 858 Returns the available names which can be passed to $c->controller
 859
 860 =cut
 861
 862 sub controllers {
 863     my ( $c ) = @_;
 864     return $c->_comp_names(qw/Controller C/);
 865 }
 866
 867 =head2 $c->models
 868
 869 Returns the available names which can be passed to $c->model
 870
 871 =cut
 872
 873 sub models {
 874     my ( $c ) = @_;
 875     return $c->_comp_names(qw/Model M/);
 876 }
 877
 878
 879 =head2 $c->views
 880
 881 Returns the available names which can be passed to $c->view
 882
 883 =cut
 884
 885 sub views {
 886     my ( $c ) = @_;
 887     return $c->_comp_names(qw/View V/);
 888 }
 889
 890 =head2 $c->comp($name)
 891
 892 =head2 $c->component($name)
 893
 894 Gets a component object by name. This method is not recommended,
 895 unless you want to get a specific component by full
 896 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 897 should be used instead.
 898
 899 If C<$name> is a regexp, a list of components matched against the full
 900 component name will be returned.
 901
 902 If Catalyst can't find a component by name, it will fallback to regex
 903 matching by default. To disable this behaviour set
 904 disable_component_resolution_regex_fallback to a true value.
 905
 906     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 907
 908 =cut
 909
 910 sub component {
 911     my ( $c, $name, @args ) = @_;
 912
 913     if( $name ) {
 914         my $comps = $c->components;
 915
 916         if( !ref $name ) {
 917             # is it the exact name?
 918             return $c->_filter_component( $comps->{ $name }, @args )
 919                        if exists $comps->{ $name };
 920
 921             # perhaps we just omitted "MyApp"?
 922             my $composed = ( ref $c || $c ) . "::${name}";
 923             return $c->_filter_component( $comps->{ $composed }, @args )
 924                        if exists $comps->{ $composed };
 925
 926             # search all of the models, views and controllers
 927             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 928             return $c->_filter_component( $comp, @args ) if $comp;
 929         }
 930
 931         return
 932             if $c->config->{disable_component_resolution_regex_fallback};
 933
 934         # This is here so $c->comp( '::M::' ) works
 935         my $query = ref $name ? $name : qr{$name}i;
 936
 937         my @result = grep { m{$query} } keys %{ $c->components };
 938         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 939
 940         if( $result[ 0 ] ) {
 941             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 942             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 943             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 944             return $c->_filter_component( $result[ 0 ], @args );
 945         }
 946
 947         # I would expect to return an empty list here, but that breaks back-compat
 948     }
 949
 950     # fallback
 951     return sort keys %{ $c->components };
 952 }
 953
 954 =head2 CLASS DATA AND HELPER CLASSES
 955
 956 =head2 $c->config
 957
 958 Returns or takes a hashref containing the application's configuration.
 959
 960     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 961
 962 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 963 like C<myapp.conf> in your applications home directory. See
 964 L<Catalyst::Plugin::ConfigLoader>.
 965
 966 =head3 Cascading configuration
 967
 968 The config method is present on all Catalyst components, and configuration
 969 will be merged when an application is started. Configuration loaded with
 970 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 971 followed by configuration in your top level C<MyApp> class. These two
 972 configurations are merged, and then configuration data whose hash key matches a
 973 component name is merged with configuration for that component.
 974
 975 The configuration for a component is then passed to the C<new> method when a
 976 component is constructed.
 977
 978 For example:
 979
 980     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 981     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 982
 983 will mean that C<MyApp::Model::Foo> receives the following data when
 984 constructed:
 985
 986     MyApp::Model::Foo->new({
 987         bar => 'baz',
 988         quux => 'frob',
 989         overrides => 'me',
 990     });
 991
 992 It's common practice to use a Moose attribute
 993 on the receiving component to access the config value.
 994
 995     package MyApp::Model::Foo;
 996
 997     use Moose;
 998
 999     # this attr will receive 'baz' at construction time
1000     has 'bar' => (
1001         is  => 'rw',
1002         isa => 'Str',
1003     );
1004
1005 You can then get the value 'baz' by calling $c->model('Foo')->bar
1006 (or $self->bar inside code in the model).
1007
1008 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1009 as a way of reading config within your code, as this B<will not> give you the
1010 correctly merged config back. You B<MUST> take the config values supplied to
1011 the constructor and use those instead.
1012
1013 =cut
1014
1015 around config => sub {
1016     my $orig = shift;
1017     my $c = shift;
1018
1019     croak('Setting config after setup has been run is not allowed.')
1020         if ( @_ and $c->setup_finished );
1021
1022     $c->$orig(@_);
1023 };
1024
1025 =head2 $c->log
1026
1027 Returns the logging object instance. Unless it is already set, Catalyst
1028 sets this up with a L<Catalyst::Log> object. To use your own log class,
1029 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1030 C<< __PACKAGE__->setup >>.
1031
1032  __PACKAGE__->log( MyLogger->new );
1033  __PACKAGE__->setup;
1034
1035 And later:
1036
1037     $c->log->info( 'Now logging with my own logger!' );
1038
1039 Your log class should implement the methods described in
1040 L<Catalyst::Log>.
1041
1042 =head2 has_encoding
1043
1044 Returned True if there's a valid encoding
1045
1046 =head2 clear_encoding
1047
1048 Clears the encoding for the current context
1049
1050 =head2 encoding
1051
1052 Sets or gets the application encoding.  Setting encoding takes either an
1053 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1054
1055 You would expect to get the encoding object back if you attempt to set it.  If
1056 there is a failure you will get undef returned and an error message in the log.
1057
1058 =cut
1059
1060 sub has_encoding { shift->encoding ? 1:0 }
1061
1062 sub clear_encoding {
1063     my $c = shift;
1064     if(blessed $c) {
1065         $c->encoding(undef);
1066     } else {
1067         $c->log->error("You can't clear encoding on the application");
1068     }
1069 }
1070
1071 sub encoding {
1072     my $c = shift;
1073     my $encoding;
1074
1075     if ( scalar @_ ) {
1076
1077         # Don't let one change this once we are too far into the response
1078         if(blessed $c && $c->res->finalized_headers) {
1079           Carp::croak("You may not change the encoding once the headers are finalized");
1080           return;
1081         }
1082
1083         # Let it be set to undef
1084         if (my $wanted = shift)  {
1085             $encoding = Encode::find_encoding($wanted)
1086               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1087             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1088         }
1089         else {
1090             binmode(STDERR);
1091         }
1092
1093         $encoding = ref $c
1094                   ? $c->{encoding} = $encoding
1095                   : $c->_encoding($encoding);
1096     } else {
1097       $encoding = ref $c && exists $c->{encoding}
1098                 ? $c->{encoding}
1099                 : $c->_encoding;
1100     }
1101
1102     return $encoding;
1103 }
1104
1105 =head2 $c->debug
1106
1107 Returns 1 if debug mode is enabled, 0 otherwise.
1108
1109 You can enable debug mode in several ways:
1110
1111 =over
1112
1113 =item By calling myapp_server.pl with the -d flag
1114
1115 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1116
1117 =item The -Debug option in your MyApp.pm
1118
1119 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1120
1121 =back
1122
1123 The first three also set the log level to 'debug'.
1124
1125 Calling C<< $c->debug(1) >> has no effect.
1126
1127 =cut
1128
1129 sub debug { 0 }
1130
1131 =head2 $c->dispatcher
1132
1133 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1134
1135 =head2 $c->engine
1136
1137 Returns the engine instance. See L<Catalyst::Engine>.
1138
1139
1140 =head2 UTILITY METHODS
1141
1142 =head2 $c->path_to(@path)
1143
1144 Merges C<@path> with C<< $c->config->{home} >> and returns a
1145 L<Path::Class::Dir> object. Note you can usually use this object as
1146 a filename, but sometimes you will have to explicitly stringify it
1147 yourself by calling the C<< ->stringify >> method.
1148
1149 For example:
1150
1151     $c->path_to( 'db', 'sqlite.db' );
1152
1153 =cut
1154
1155 sub path_to {
1156     my ( $c, @path ) = @_;
1157     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1158     if ( -d $path ) { return $path }
1159     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1160 }
1161
1162 sub plugin {
1163     my ( $class, $name, $plugin, @args ) = @_;
1164
1165     # See block comment in t/unit_core_plugin.t
1166     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1167
1168     $class->_register_plugin( $plugin, 1 );
1169
1170     eval { $plugin->import };
1171     $class->mk_classdata($name);
1172     my $obj;
1173     eval { $obj = $plugin->new(@args) };
1174
1175     if ($@) {
1176         Catalyst::Exception->throw( message =>
1177               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1178     }
1179
1180     $class->$name($obj);
1181     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1182       if $class->debug;
1183 }
1184
1185 =head2 MyApp->setup
1186
1187 Initializes the dispatcher and engine, loads any plugins, and loads the
1188 model, view, and controller components. You may also specify an array
1189 of plugins to load here, if you choose to not load them in the C<use
1190 Catalyst> line.
1191
1192     MyApp->setup;
1193     MyApp->setup( qw/-Debug/ );
1194
1195 B<Note:> You B<should not> wrap this method with method modifiers
1196 or bad things will happen - wrap the C<setup_finalize> method instead.
1197
1198 B<Note:> You can create a custom setup stage that will execute when the
1199 application is starting.  Use this to customize setup.
1200
1201     MyApp->setup(-Custom=value);
1202
1203     sub setup_custom {
1204       my ($class, $value) = @_;
1205     }
1206
1207 Can be handy if you want to hook into the setup phase.
1208
1209 =cut
1210
1211 sub setup {
1212     my ( $class, @arguments ) = @_;
1213     croak('Running setup more than once')
1214         if ( $class->setup_finished );
1215
1216     unless ( $class->isa('Catalyst') ) {
1217
1218         Catalyst::Exception->throw(
1219             message => qq/'$class' does not inherit from Catalyst/ );
1220     }
1221
1222     if ( $class->arguments ) {
1223         @arguments = ( @arguments, @{ $class->arguments } );
1224     }
1225
1226     # Process options
1227     my $flags = {};
1228
1229     foreach (@arguments) {
1230
1231         if (/^-Debug$/) {
1232             $flags->{log} =
1233               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1234         }
1235         elsif (/^-(\w+)=?(.*)$/) {
1236             $flags->{ lc $1 } = $2;
1237         }
1238         else {
1239             push @{ $flags->{plugins} }, $_;
1240         }
1241     }
1242
1243     $class->setup_home( delete $flags->{home} );
1244
1245     $class->setup_log( delete $flags->{log} );
1246     $class->setup_plugins( delete $flags->{plugins} );
1247
1248     $class->setup_data_handlers();
1249     $class->setup_dispatcher( delete $flags->{dispatcher} );
1250     if (my $engine = delete $flags->{engine}) {
1251         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1252     }
1253     $class->setup_engine();
1254     $class->setup_stats( delete $flags->{stats} );
1255
1256     for my $flag ( sort keys %{$flags} ) {
1257
1258         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1259             &$code( $class, delete $flags->{$flag} );
1260         }
1261         else {
1262             $class->log->warn(qq/Unknown flag "$flag"/);
1263         }
1264     }
1265
1266     eval { require Catalyst::Devel; };
1267     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1268         $class->log->warn(<<"EOF");
1269 You are running an old script!
1270
1271   Please update by running (this will overwrite existing files):
1272     catalyst.pl -force -scripts $class
1273
1274   or (this will not overwrite existing files):
1275     catalyst.pl -scripts $class
1276
1277 EOF
1278     }
1279
1280     # Call plugins setup, this is stupid and evil.
1281     # Also screws C3 badly on 5.10, hack to avoid.
1282     {
1283         no warnings qw/redefine/;
1284         local *setup = sub { };
1285         $class->setup unless $Catalyst::__AM_RESTARTING;
1286     }
1287
1288     # If you are expecting configuration info as part of your setup, it needs
1289     # to get called here and below, since we need the above line to support
1290     # ConfigLoader based configs.
1291
1292     $class->setup_encoding();
1293     $class->setup_middleware();
1294
1295     # Initialize our data structure
1296     $class->components( {} );
1297
1298     $class->setup_components;
1299
1300     if ( $class->debug ) {
1301         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1302
1303         if (@plugins) {
1304             my $column_width = Catalyst::Utils::term_width() - 6;
1305             my $t = Text::SimpleTable->new($column_width);
1306             $t->row($_) for @plugins;
1307             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1308         }
1309
1310         my @middleware = map {
1311           ref $_ eq 'CODE' ?
1312             "Inline Coderef" :
1313               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1314                 || '')  } $class->registered_middlewares;
1315
1316         if (@middleware) {
1317             my $column_width = Catalyst::Utils::term_width() - 6;
1318             my $t = Text::SimpleTable->new($column_width);
1319             $t->row($_) for @middleware;
1320             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1321         }
1322
1323         my %dh = $class->registered_data_handlers;
1324         if (my @data_handlers = keys %dh) {
1325             my $column_width = Catalyst::Utils::term_width() - 6;
1326             my $t = Text::SimpleTable->new($column_width);
1327             $t->row($_) for @data_handlers;
1328             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1329         }
1330
1331         my $dispatcher = $class->dispatcher;
1332         my $engine     = $class->engine;
1333         my $home       = $class->config->{home};
1334
1335         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1336         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1337
1338         $home
1339           ? ( -d $home )
1340           ? $class->log->debug(qq/Found home "$home"/)
1341           : $class->log->debug(qq/Home "$home" doesn't exist/)
1342           : $class->log->debug(q/Couldn't find home/);
1343
1344         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1345         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1346         for my $comp ( sort keys %{ $class->components } ) {
1347             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1348             $t->row( $comp, $type );
1349         }
1350         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1351           if ( keys %{ $class->components } );
1352     }
1353
1354     # Add our self to components, since we are also a component
1355     if( $class->isa('Catalyst::Controller') ){
1356       $class->components->{$class} = $class;
1357     }
1358
1359     $class->setup_actions;
1360
1361     if ( $class->debug ) {
1362         my $name = $class->config->{name} || 'Application';
1363         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1364     }
1365
1366     if ($class->config->{case_sensitive}) {
1367         $class->log->warn($class . "->config->{case_sensitive} is set.");
1368         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1369     }
1370
1371     $class->setup_finalize;
1372
1373     # Flush the log for good measure (in case something turned off 'autoflush' early)
1374     $class->log->_flush() if $class->log->can('_flush');
1375
1376     return $class || 1; # Just in case someone named their Application 0...
1377 }
1378
1379 =head2 $app->setup_finalize
1380
1381 A hook to attach modifiers to. This method does not do anything except set the
1382 C<setup_finished> accessor.
1383
1384 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1385
1386 Example:
1387
1388     after setup_finalize => sub {
1389         my $app = shift;
1390
1391         ## do stuff here..
1392     };
1393
1394 =cut
1395
1396 sub setup_finalize {
1397     my ($class) = @_;
1398     $class->setup_finished(1);
1399 }
1400
1401 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1402
1403 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1404
1405 =head2 $c->uri_for( $action, [@captures, @args], \%query_values? )
1406
1407 Constructs an absolute L<URI> object based on the application root, the
1408 provided path, and the additional arguments and query parameters provided.
1409 When used as a string, provides a textual URI.  If you need more flexibility
1410 than this (i.e. the option to provide relative URIs etc.) see
1411 L<Catalyst::Plugin::SmartURI>.
1412
1413 If no arguments are provided, the URI for the current action is returned.
1414 To return the current action and also provide @args, use
1415 C<< $c->uri_for( $c->action, @args ) >>.
1416
1417 If the first argument is a string, it is taken as a public URI path relative
1418 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1419 relative to the application root (if it does). It is then merged with
1420 C<< $c->request->base >>; any C<@args> are appended as additional path
1421 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1422
1423 If the first argument is a L<Catalyst::Action> it represents an action which
1424 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1425 optional C<\@captures> argument (an arrayref) allows passing the captured
1426 variables that are needed to fill in the paths of Chained and Regex actions;
1427 once the path is resolved, C<uri_for> continues as though a path was
1428 provided, appending any arguments or parameters and creating an absolute
1429 URI.
1430
1431 The captures for the current request can be found in
1432 C<< $c->request->captures >>, and actions can be resolved using
1433 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1434 path, use C<< $c->uri_for_action >> instead.
1435
1436   # Equivalent to $c->req->uri
1437   $c->uri_for($c->action, $c->req->captures,
1438       @{ $c->req->args }, $c->req->params);
1439
1440   # For the Foo action in the Bar controller
1441   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1442
1443   # Path to a static resource
1444   $c->uri_for('/static/images/logo.png');
1445
1446 In general the scheme of the generated URI object will follow the incoming request
1447 however if your targeted action or action chain has the Scheme attribute it will
1448 use that instead.
1449
1450 =cut
1451
1452 sub uri_for {
1453     my ( $c, $path, @args ) = @_;
1454
1455     if ( $path->$_isa('Catalyst::Controller') ) {
1456         $path = $path->path_prefix;
1457         $path =~ s{/+\z}{};
1458         $path .= '/';
1459     }
1460
1461     undef($path) if (defined $path && $path eq '');
1462
1463     my $params =
1464       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1465
1466     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1467
1468     my @encoded_args = ();
1469     foreach my $arg (@args) {
1470       if(ref($arg)||'' eq 'ARRAY') {
1471         push @encoded_args, [map {
1472           my $encoded = encode_utf8 $_;
1473           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1474          $encoded;
1475         } @$arg];
1476       } else {
1477         push @encoded_args, do {
1478           my $encoded = encode_utf8 $arg;
1479           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1480           $encoded;
1481         }
1482       }
1483     }
1484
1485     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1486     if ( $path->$_isa('Catalyst::Action') ) { # action object
1487         s|/|%2F|g for @encoded_args;
1488         my $captures = [ map { s|/|%2F|g; $_; }
1489                         ( scalar @encoded_args && ref $encoded_args[0] eq 'ARRAY'
1490                          ? @{ shift(@encoded_args) }
1491                          : ()) ];
1492
1493         my $action = $path;
1494         my $expanded_action = $c->dispatcher->expand_action( $action );
1495          my $num_captures = $expanded_action->number_of_captures;
1496
1497         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1498         if( !@encoded_args && $action->number_of_args ) {
1499           unshift @encoded_args, splice @$captures, $num_captures;
1500         }
1501
1502         if($num_captures) {
1503           unless($expanded_action->match_captures($c, $captures)) {
1504             carp "captures [@{$captures}] do not match the type constraints in action '$action'";
1505             return;
1506           }
1507         }
1508
1509         $path = $c->dispatcher->uri_for_action($action, $captures);
1510         if (not defined $path) {
1511             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1512                 if $c->debug;
1513             return undef;
1514         }
1515         $path = '/' if $path eq '';
1516
1517         # At this point @encoded_args is the remaining Args (all captures removed).
1518         if($expanded_action->has_args_constraints) {
1519           unless($expanded_action->match_args($c,\@encoded_args)) {
1520              carp "args [@encoded_args] do not match the type constraints in action '$expanded_action'";
1521              return;
1522           }
1523         }
1524     }
1525
1526     unshift(@encoded_args, $path);
1527
1528     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1529         my $namespace = $c->namespace;
1530         if (defined $path) { # cheesy hack to handle path '../foo'
1531            $namespace =~ s{(?:^|/)[^/]+$}{} while $encoded_args[0] =~ s{^\.\./}{};
1532         }
1533         unshift(@encoded_args, $namespace || '');
1534     }
1535
1536     # join args with '/', or a blank string
1537     my $args = join('/', grep { defined($_) } @encoded_args);
1538     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1539     $args =~ s!^/+!!;
1540
1541     my ($base, $class) = ('/', 'URI::_generic');
1542     if(blessed($c)) {
1543       $base = $c->req->base;
1544       if($target_action) {
1545         $target_action = $c->dispatcher->expand_action($target_action);
1546         if(my $s = $target_action->scheme) {
1547           $s = lc($s);
1548           $class = "URI::$s";
1549           $base->scheme($s);
1550         } else {
1551           $class = ref($base);
1552         }
1553       } else {
1554         $class = ref($base);
1555       }
1556
1557       $base =~ s{(?<!/)$}{/};
1558     }
1559
1560     my $query = '';
1561
1562     if (my @keys = keys %$params) {
1563       # somewhat lifted from URI::_query's query_form
1564       $query = '?'.join('&', map {
1565           my $val = $params->{$_};
1566           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1567           s/ /+/g;
1568           my $key = $_;
1569           $val = '' unless defined $val;
1570           (map {
1571               my $param = "$_";
1572               $param = encode_utf8($param);
1573               # using the URI::Escape pattern here so utf8 chars survive
1574               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1575               $param =~ s/ /+/g;
1576
1577               $key = encode_utf8($key);
1578               # using the URI::Escape pattern here so utf8 chars survive
1579               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1580               $key =~ s/ /+/g;
1581
1582               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1583       } @keys);
1584     }
1585
1586     #warn $base;
1587     #warn $args;
1588
1589     my $res = bless(\"${base}${args}${query}", $class);
1590     $res;
1591 }
1592
1593 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1594
1595 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1596
1597 =over
1598
1599 =item $path
1600
1601 A private path to the Catalyst action you want to create a URI for.
1602
1603 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1604 >> and passing the resulting C<$action> and the remaining arguments to C<<
1605 $c->uri_for >>.
1606
1607 You can also pass in a Catalyst::Action object, in which case it is passed to
1608 C<< $c->uri_for >>.
1609
1610 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1611
1612 For example, if the action looks like:
1613
1614  package MyApp::Controller::Users;
1615
1616  sub lst : Path('the-list') {}
1617
1618 You can use:
1619
1620  $c->uri_for_action('/users/lst')
1621
1622 and it will create the URI /users/the-list.
1623
1624 =item \@captures_and_args?
1625
1626 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1627 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1628 to interpolate all the parameters in the URI.
1629
1630 =item @args?
1631
1632 Optional list of extra arguments - can be supplied in the
1633 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1634 code.
1635
1636 Your action can have zero, a fixed or a variable number of args (e.g.
1637 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1638
1639 =item \%query_values?
1640
1641 Optional array reference of query parameters to append. E.g.
1642
1643   { foo => 'bar' }
1644
1645 will generate
1646
1647   /rest/of/your/uri?foo=bar
1648
1649 =back
1650
1651 =cut
1652
1653 sub uri_for_action {
1654     my ( $c, $path, @args ) = @_;
1655     my $action = blessed($path)
1656       ? $path
1657       : $c->dispatcher->get_action_by_path($path);
1658     unless (defined $action) {
1659       croak "Can't find action for path '$path'";
1660     }
1661     return $c->uri_for( $action, @args );
1662 }
1663
1664 =head2 $c->welcome_message
1665
1666 Returns the Catalyst welcome HTML page.
1667
1668 =cut
1669
1670 sub welcome_message {
1671     my $c      = shift;
1672     my $name   = $c->config->{name};
1673     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1674     my $prefix = Catalyst::Utils::appprefix( ref $c );
1675     $c->response->content_type('text/html; charset=utf-8');
1676     return <<"EOF";
1677 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1678     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1679 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1680     <head>
1681     <meta http-equiv="Content-Language" content="en" />
1682     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1683         <title>$name on Catalyst $VERSION</title>
1684         <style type="text/css">
1685             body {
1686                 color: #000;
1687                 background-color: #eee;
1688             }
1689             div#content {
1690                 width: 640px;
1691                 margin-left: auto;
1692                 margin-right: auto;
1693                 margin-top: 10px;
1694                 margin-bottom: 10px;
1695                 text-align: left;
1696                 background-color: #ccc;
1697                 border: 1px solid #aaa;
1698             }
1699             p, h1, h2 {
1700                 margin-left: 20px;
1701                 margin-right: 20px;
1702                 font-family: verdana, tahoma, sans-serif;
1703             }
1704             a {
1705                 font-family: verdana, tahoma, sans-serif;
1706             }
1707             :link, :visited {
1708                     text-decoration: none;
1709                     color: #b00;
1710                     border-bottom: 1px dotted #bbb;
1711             }
1712             :link:hover, :visited:hover {
1713                     color: #555;
1714             }
1715             div#topbar {
1716                 margin: 0px;
1717             }
1718             pre {
1719                 margin: 10px;
1720                 padding: 8px;
1721             }
1722             div#answers {
1723                 padding: 8px;
1724                 margin: 10px;
1725                 background-color: #fff;
1726                 border: 1px solid #aaa;
1727             }
1728             h1 {
1729                 font-size: 0.9em;
1730                 font-weight: normal;
1731                 text-align: center;
1732             }
1733             h2 {
1734                 font-size: 1.0em;
1735             }
1736             p {
1737                 font-size: 0.9em;
1738             }
1739             p img {
1740                 float: right;
1741                 margin-left: 10px;
1742             }
1743             span#appname {
1744                 font-weight: bold;
1745                 font-size: 1.6em;
1746             }
1747         </style>
1748     </head>
1749     <body>
1750         <div id="content">
1751             <div id="topbar">
1752                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1753                     $VERSION</h1>
1754              </div>
1755              <div id="answers">
1756                  <p>
1757                  <img src="$logo" alt="Catalyst Logo" />
1758                  </p>
1759                  <p>Welcome to the  world of Catalyst.
1760                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1761                     framework will make web development something you had
1762                     never expected it to be: Fun, rewarding, and quick.</p>
1763                  <h2>What to do now?</h2>
1764                  <p>That really depends  on what <b>you</b> want to do.
1765                     We do, however, provide you with a few starting points.</p>
1766                  <p>If you want to jump right into web development with Catalyst
1767                     you might want to start with a tutorial.</p>
1768 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1769 </pre>
1770 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1771 <pre>
1772 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1773 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1774 </code></pre>
1775                  <h2>What to do next?</h2>
1776                  <p>Next it's time to write an actual application. Use the
1777                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1778                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1779                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1780                     they can save you a lot of work.</p>
1781                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1782                     <p>Also, be sure to check out the vast and growing
1783                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1784                     you are likely to find what you need there.
1785                     </p>
1786
1787                  <h2>Need help?</h2>
1788                  <p>Catalyst has a very active community. Here are the main places to
1789                     get in touch with us.</p>
1790                  <ul>
1791                      <li>
1792                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1793                      </li>
1794                      <li>
1795                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1796                      </li>
1797                      <li>
1798                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1799                      </li>
1800                  </ul>
1801                  <h2>In conclusion</h2>
1802                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1803                     as we enjoyed making it. Please contact us if you have ideas
1804                     for improvement or other feedback.</p>
1805              </div>
1806          </div>
1807     </body>
1808 </html>
1809 EOF
1810 }
1811
1812 =head2 run_options
1813
1814 Contains a hash of options passed from the application script, including
1815 the original ARGV the script received, the processed values from that
1816 ARGV and any extra arguments to the script which were not processed.
1817
1818 This can be used to add custom options to your application's scripts
1819 and setup your application differently depending on the values of these
1820 options.
1821
1822 =head1 INTERNAL METHODS
1823
1824 These methods are not meant to be used by end users.
1825
1826 =head2 $c->components
1827
1828 Returns a hash of components.
1829
1830 =head2 $c->context_class
1831
1832 Returns or sets the context class.
1833
1834 =head2 $c->counter
1835
1836 Returns a hashref containing coderefs and execution counts (needed for
1837 deep recursion detection).
1838
1839 =head2 $c->depth
1840
1841 Returns the number of actions on the current internal execution stack.
1842
1843 =head2 $c->dispatch
1844
1845 Dispatches a request to actions.
1846
1847 =cut
1848
1849 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1850
1851 =head2 $c->dispatcher_class
1852
1853 Returns or sets the dispatcher class.
1854
1855 =head2 $c->dump_these
1856
1857 Returns a list of 2-element array references (name, structure) pairs
1858 that will be dumped on the error page in debug mode.
1859
1860 =cut
1861
1862 sub dump_these {
1863     my $c = shift;
1864     [ Request => $c->req ],
1865     [ Response => $c->res ],
1866     [ Stash => $c->stash ],
1867     [ Config => $c->config ];
1868 }
1869
1870 =head2 $c->engine_class
1871
1872 Returns or sets the engine class.
1873
1874 =head2 $c->execute( $class, $coderef )
1875
1876 Execute a coderef in given class and catch exceptions. Errors are available
1877 via $c->error.
1878
1879 =cut
1880
1881 sub execute {
1882     my ( $c, $class, $code ) = @_;
1883     $class = $c->component($class) || $class;
1884     $c->state(0);
1885
1886     if ( $c->depth >= $RECURSION ) {
1887         my $action = $code->reverse();
1888         $action = "/$action" unless $action =~ /->/;
1889         my $error = qq/Deep recursion detected calling "${action}"/;
1890         $c->log->error($error);
1891         $c->error($error);
1892         $c->state(0);
1893         return $c->state;
1894     }
1895
1896     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1897
1898     push( @{ $c->stack }, $code );
1899
1900     no warnings 'recursion';
1901     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1902     #      I have no idea how, ergo $ret (which appears to fix the issue)
1903     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1904
1905     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1906
1907     my $last = pop( @{ $c->stack } );
1908
1909     if ( my $error = $@ ) {
1910         #rethow if this can be handled by middleware
1911         if ( $c->_handle_http_exception($error) ) {
1912             foreach my $err (@{$c->error}) {
1913                 $c->log->error($err);
1914             }
1915             $c->clear_errors;
1916             $c->log->_flush if $c->log->can('_flush');
1917
1918             $error->can('rethrow') ? $error->rethrow : croak $error;
1919         }
1920         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1921             $error->rethrow if $c->depth > 1;
1922         }
1923         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1924             $error->rethrow if $c->depth > 0;
1925         }
1926         else {
1927             unless ( ref $error ) {
1928                 no warnings 'uninitialized';
1929                 chomp $error;
1930                 my $class = $last->class;
1931                 my $name  = $last->name;
1932                 $error = qq/Caught exception in $class->$name "$error"/;
1933             }
1934             $c->error($error);
1935         }
1936         $c->state(0);
1937     }
1938     return $c->state;
1939 }
1940
1941 sub _stats_start_execute {
1942     my ( $c, $code ) = @_;
1943     my $appclass = ref($c) || $c;
1944     return if ( ( $code->name =~ /^_.*/ )
1945         && ( !$appclass->config->{show_internal_actions} ) );
1946
1947     my $action_name = $code->reverse();
1948     $c->counter->{$action_name}++;
1949
1950     my $action = $action_name;
1951     $action = "/$action" unless $action =~ /->/;
1952
1953     # determine if the call was the result of a forward
1954     # this is done by walking up the call stack and looking for a calling
1955     # sub of Catalyst::forward before the eval
1956     my $callsub = q{};
1957     for my $index ( 2 .. 11 ) {
1958         last
1959         if ( ( caller($index) )[0] eq 'Catalyst'
1960             && ( caller($index) )[3] eq '(eval)' );
1961
1962         if ( ( caller($index) )[3] =~ /forward$/ ) {
1963             $callsub = ( caller($index) )[3];
1964             $action  = "-> $action";
1965             last;
1966         }
1967     }
1968
1969     my $uid = $action_name . $c->counter->{$action_name};
1970
1971     # is this a root-level call or a forwarded call?
1972     if ( $callsub =~ /forward$/ ) {
1973         my $parent = $c->stack->[-1];
1974
1975         # forward, locate the caller
1976         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1977             $c->stats->profile(
1978                 begin  => $action,
1979                 parent => "$parent" . $c->counter->{"$parent"},
1980                 uid    => $uid,
1981             );
1982         }
1983         else {
1984
1985             # forward with no caller may come from a plugin
1986             $c->stats->profile(
1987                 begin => $action,
1988                 uid   => $uid,
1989             );
1990         }
1991     }
1992     else {
1993
1994         # root-level call
1995         $c->stats->profile(
1996             begin => $action,
1997             uid   => $uid,
1998         );
1999     }
2000     return $action;
2001
2002 }
2003
2004 sub _stats_finish_execute {
2005     my ( $c, $info ) = @_;
2006     $c->stats->profile( end => $info );
2007 }
2008
2009 =head2 $c->finalize
2010
2011 Finalizes the request.
2012
2013 =cut
2014
2015 sub finalize {
2016     my $c = shift;
2017
2018     for my $error ( @{ $c->error } ) {
2019         $c->log->error($error);
2020     }
2021
2022     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2023     # stuff like cometd and websockets
2024
2025     if($c->request->_has_io_fh) {
2026       $c->log_response;
2027       return;
2028     }
2029
2030     # Allow engine to handle finalize flow (for POE)
2031     my $engine = $c->engine;
2032     if ( my $code = $engine->can('finalize') ) {
2033         $engine->$code($c);
2034     }
2035     else {
2036
2037         $c->finalize_uploads;
2038
2039         # Error
2040         if ( $#{ $c->error } >= 0 ) {
2041             $c->finalize_error;
2042         }
2043
2044         $c->finalize_encoding;
2045         $c->finalize_headers unless $c->response->finalized_headers;
2046         $c->finalize_body;
2047     }
2048
2049     $c->log_response;
2050
2051     if ($c->use_stats) {
2052         my $elapsed = $c->stats->elapsed;
2053         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2054         $c->log->info(
2055             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2056     }
2057
2058     return $c->response->status;
2059 }
2060
2061 =head2 $c->finalize_body
2062
2063 Finalizes body.
2064
2065 =cut
2066
2067 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2068
2069 =head2 $c->finalize_cookies
2070
2071 Finalizes cookies.
2072
2073 =cut
2074
2075 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2076
2077 =head2 $c->finalize_error
2078
2079 Finalizes error.  If there is only one error in L</error> and it is an object that
2080 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2081 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2082 return the default error page (production mode).
2083
2084 =cut
2085
2086 sub finalize_error {
2087     my $c = shift;
2088     if($#{$c->error} > 0) {
2089         $c->engine->finalize_error( $c, @_ );
2090     } else {
2091         my ($error) = @{$c->error};
2092         if ( $c->_handle_http_exception($error) ) {
2093             # In the case where the error 'knows what it wants', becauses its PSGI
2094             # aware, just rethow and let middleware catch it
2095             $error->can('rethrow') ? $error->rethrow : croak $error;
2096         } else {
2097             $c->engine->finalize_error( $c, @_ )
2098         }
2099     }
2100 }
2101
2102 =head2 $c->finalize_headers
2103
2104 Finalizes headers.
2105
2106 =cut
2107
2108 sub finalize_headers {
2109     my $c = shift;
2110
2111     my $response = $c->response; #accessor calls can add up?
2112
2113     # Check if we already finalized headers
2114     return if $response->finalized_headers;
2115
2116     # Handle redirects
2117     if ( my $location = $response->redirect ) {
2118         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2119         $response->header( Location => $location );
2120     }
2121
2122     # Remove incorrectly added body and content related meta data when returning
2123     # an information response, or a response the is required to not include a body
2124
2125     $c->finalize_cookies;
2126
2127     # This currently is a NOOP but I don't want to remove it since I guess people
2128     # might have Response subclasses that use it for something... (JNAP)
2129     $c->response->finalize_headers();
2130
2131     # Done
2132     $response->finalized_headers(1);
2133 }
2134
2135 =head2 $c->finalize_encoding
2136
2137 Make sure your body is encoded properly IF you set an encoding.  By
2138 default the encoding is UTF-8 but you can disable it by explicitly setting the
2139 encoding configuration value to undef.
2140
2141 We can only encode when the body is a scalar.  Methods for encoding via the
2142 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2143 are available).
2144
2145 See L</ENCODING>.
2146
2147 =cut
2148
2149 sub finalize_encoding {
2150     my $c = shift;
2151     my $res = $c->res || return;
2152
2153     # Warn if the set charset is different from the one you put into encoding.  We need
2154     # to do this early since encodable_response is false for this condition and we need
2155     # to match the debug output for backcompat (there's a test for this...) -JNAP
2156     if(
2157       $res->content_type_charset and $c->encoding and
2158       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2159     ) {
2160         my $ct = lc($res->content_type_charset);
2161         $c->log->debug("Catalyst encoding config is set to encode in '" .
2162             $c->encoding->mime_name .
2163             "', content type is '$ct', not encoding ");
2164     }
2165
2166     if(
2167       ($res->encodable_response) and
2168       (defined($res->body)) and
2169       (ref(\$res->body) eq 'SCALAR')
2170     ) {
2171         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2172
2173         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2174         # is false when the set charset is not the same as the encoding mimetype (maybe
2175         # confusing action at a distance here..
2176         # Don't try to set the charset if one already exists
2177         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2178           unless($c->res->content_type_charset);
2179     }
2180 }
2181
2182 =head2 $c->finalize_output
2183
2184 An alias for finalize_body.
2185
2186 =head2 $c->finalize_read
2187
2188 Finalizes the input after reading is complete.
2189
2190 =cut
2191
2192 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2193
2194 =head2 $c->finalize_uploads
2195
2196 Finalizes uploads. Cleans up any temporary files.
2197
2198 =cut
2199
2200 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2201
2202 =head2 $c->get_action( $action, $namespace )
2203
2204 Gets an action in a given namespace.
2205
2206 =cut
2207
2208 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2209
2210 =head2 $c->get_actions( $action, $namespace )
2211
2212 Gets all actions of a given name in a namespace and all parent
2213 namespaces.
2214
2215 =cut
2216
2217 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2218
2219 =head2 $app->handle_request( @arguments )
2220
2221 Called to handle each HTTP request.
2222
2223 =cut
2224
2225 sub handle_request {
2226     my ( $class, @arguments ) = @_;
2227
2228     # Always expect worst case!
2229     my $status = -1;
2230     try {
2231         if ($class->debug) {
2232             my $secs = time - $START || 1;
2233             my $av = sprintf '%.3f', $COUNT / $secs;
2234             my $time = localtime time;
2235             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2236         }
2237
2238         my $c = $class->prepare(@arguments);
2239         $c->dispatch;
2240         $status = $c->finalize;
2241     } catch {
2242         #rethow if this can be handled by middleware
2243         if ( $class->_handle_http_exception($_) ) {
2244             $_->can('rethrow') ? $_->rethrow : croak $_;
2245         }
2246         chomp(my $error = $_);
2247         $class->log->error(qq/Caught exception in engine "$error"/);
2248     };
2249
2250     $COUNT++;
2251
2252     if(my $coderef = $class->log->can('_flush')){
2253         $class->log->$coderef();
2254     }
2255     return $status;
2256 }
2257
2258 =head2 $class->prepare( @arguments )
2259
2260 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2261 etc.).
2262
2263 =cut
2264
2265 has _uploadtmp => (
2266     is => 'ro',
2267     predicate => '_has_uploadtmp',
2268 );
2269
2270 sub prepare {
2271     my ( $class, @arguments ) = @_;
2272
2273     # XXX
2274     # After the app/ctxt split, this should become an attribute based on something passed
2275     # into the application.
2276     $class->context_class( ref $class || $class ) unless $class->context_class;
2277
2278     my $uploadtmp = $class->config->{uploadtmp};
2279     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2280
2281     $c->response->_context($c);
2282
2283     #surely this is not the most efficient way to do things...
2284     $c->stats($class->stats_class->new)->enable($c->use_stats);
2285     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2286         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2287     }
2288
2289     try {
2290         # Allow engine to direct the prepare flow (for POE)
2291         if ( my $prepare = $c->engine->can('prepare') ) {
2292             $c->engine->$prepare( $c, @arguments );
2293         }
2294         else {
2295             $c->prepare_request(@arguments);
2296             $c->prepare_connection;
2297             $c->prepare_query_parameters;
2298             $c->prepare_headers; # Just hooks, no longer needed - they just
2299             $c->prepare_cookies; # cause the lazy attribute on req to build
2300             $c->prepare_path;
2301
2302             # Prepare the body for reading, either by prepare_body
2303             # or the user, if they are using $c->read
2304             $c->prepare_read;
2305
2306             # Parse the body unless the user wants it on-demand
2307             unless ( ref($c)->config->{parse_on_demand} ) {
2308                 $c->prepare_body;
2309             }
2310         }
2311         $c->prepare_action;
2312     }
2313     # VERY ugly and probably shouldn't rely on ->finalize actually working
2314     catch {
2315         # failed prepare is always due to an invalid request, right?
2316         $c->response->status(400);
2317         $c->response->content_type('text/plain');
2318         $c->response->body('Bad Request');
2319         # Note we call finalize and then die here, which escapes
2320         # finalize being called in the enclosing block..
2321         # It in fact couldn't be called, as we don't return $c..
2322         # This is a mess - but I'm unsure you can fix this without
2323         # breaking compat for people doing crazy things (we should set
2324         # the 400 and just return the ctx here IMO, letting finalize get called
2325         # above...
2326         $c->finalize;
2327         die $_;
2328     };
2329
2330     $c->log_request;
2331
2332     return $c;
2333 }
2334
2335 =head2 $c->prepare_action
2336
2337 Prepares action. See L<Catalyst::Dispatcher>.
2338
2339 =cut
2340
2341 sub prepare_action {
2342     my $c = shift;
2343     my $ret = $c->dispatcher->prepare_action( $c, @_);
2344
2345     if($c->encoding) {
2346         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2347           $_ = $c->_handle_param_unicode_decoding($_);
2348         }
2349     }
2350
2351     return $ret;
2352 }
2353
2354
2355 =head2 $c->prepare_body
2356
2357 Prepares message body.
2358
2359 =cut
2360
2361 sub prepare_body {
2362     my $c = shift;
2363
2364     return if $c->request->_has_body;
2365
2366     # Initialize on-demand data
2367     $c->engine->prepare_body( $c, @_ );
2368     $c->prepare_parameters;
2369     $c->prepare_uploads;
2370 }
2371
2372 =head2 $c->prepare_body_chunk( $chunk )
2373
2374 Prepares a chunk of data before sending it to L<HTTP::Body>.
2375
2376 See L<Catalyst::Engine>.
2377
2378 =cut
2379
2380 sub prepare_body_chunk {
2381     my $c = shift;
2382     $c->engine->prepare_body_chunk( $c, @_ );
2383 }
2384
2385 =head2 $c->prepare_body_parameters
2386
2387 Prepares body parameters.
2388
2389 =cut
2390
2391 sub prepare_body_parameters {
2392     my $c = shift;
2393     $c->request->prepare_body_parameters( $c, @_ );
2394 }
2395
2396 =head2 $c->prepare_connection
2397
2398 Prepares connection.
2399
2400 =cut
2401
2402 sub prepare_connection {
2403     my $c = shift;
2404     $c->request->prepare_connection($c);
2405 }
2406
2407 =head2 $c->prepare_cookies
2408
2409 Prepares cookies by ensuring that the attribute on the request
2410 object has been built.
2411
2412 =cut
2413
2414 sub prepare_cookies { my $c = shift; $c->request->cookies }
2415
2416 =head2 $c->prepare_headers
2417
2418 Prepares request headers by ensuring that the attribute on the request
2419 object has been built.
2420
2421 =cut
2422
2423 sub prepare_headers { my $c = shift; $c->request->headers }
2424
2425 =head2 $c->prepare_parameters
2426
2427 Prepares parameters.
2428
2429 =cut
2430
2431 sub prepare_parameters {
2432     my $c = shift;
2433     $c->prepare_body_parameters;
2434     $c->engine->prepare_parameters( $c, @_ );
2435 }
2436
2437 =head2 $c->prepare_path
2438
2439 Prepares path and base.
2440
2441 =cut
2442
2443 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2444
2445 =head2 $c->prepare_query_parameters
2446
2447 Prepares query parameters.
2448
2449 =cut
2450
2451 sub prepare_query_parameters {
2452     my $c = shift;
2453
2454     $c->engine->prepare_query_parameters( $c, @_ );
2455 }
2456
2457 =head2 $c->log_request
2458
2459 Writes information about the request to the debug logs.  This includes:
2460
2461 =over 4
2462
2463 =item * Request method, path, and remote IP address
2464
2465 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2466
2467 =item * Request parameters
2468
2469 =item * File uploads
2470
2471 =back
2472
2473 =cut
2474
2475 sub log_request {
2476     my $c = shift;
2477
2478     return unless $c->debug;
2479
2480     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2481     my $request = $dump->[1];
2482
2483     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2484     $method ||= '';
2485     $path = '/' unless length $path;
2486     $address ||= '';
2487
2488     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2489     $path = decode_utf8($path);
2490
2491     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2492
2493     $c->log_request_headers($request->headers);
2494
2495     if ( my $keywords = $request->query_keywords ) {
2496         $c->log->debug("Query keywords are: $keywords");
2497     }
2498
2499     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2500
2501     $c->log_request_uploads($request);
2502 }
2503
2504 =head2 $c->log_response
2505
2506 Writes information about the response to the debug logs by calling
2507 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2508
2509 =cut
2510
2511 sub log_response {
2512     my $c = shift;
2513
2514     return unless $c->debug;
2515
2516     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2517     my $response = $dump->[1];
2518
2519     $c->log_response_status_line($response);
2520     $c->log_response_headers($response->headers);
2521 }
2522
2523 =head2 $c->log_response_status_line($response)
2524
2525 Writes one line of information about the response to the debug logs.  This includes:
2526
2527 =over 4
2528
2529 =item * Response status code
2530
2531 =item * Content-Type header (if present)
2532
2533 =item * Content-Length header (if present)
2534
2535 =back
2536
2537 =cut
2538
2539 sub log_response_status_line {
2540     my ($c, $response) = @_;
2541
2542     $c->log->debug(
2543         sprintf(
2544             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2545             $response->status                            || 'unknown',
2546             $response->headers->header('Content-Type')   || 'unknown',
2547             $response->headers->header('Content-Length') || 'unknown'
2548         )
2549     );
2550 }
2551
2552 =head2 $c->log_response_headers($headers);
2553
2554 Hook method which can be wrapped by plugins to log the response headers.
2555 No-op in the default implementation.
2556
2557 =cut
2558
2559 sub log_response_headers {}
2560
2561 =head2 $c->log_request_parameters( query => {}, body => {} )
2562
2563 Logs request parameters to debug logs
2564
2565 =cut
2566
2567 sub log_request_parameters {
2568     my $c          = shift;
2569     my %all_params = @_;
2570
2571     return unless $c->debug;
2572
2573     my $column_width = Catalyst::Utils::term_width() - 44;
2574     foreach my $type (qw(query body)) {
2575         my $params = $all_params{$type};
2576         next if ! keys %$params;
2577         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2578         for my $key ( sort keys %$params ) {
2579             my $param = $params->{$key};
2580             my $value = defined($param) ? $param : '';
2581             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2582         }
2583         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2584     }
2585 }
2586
2587 =head2 $c->log_request_uploads
2588
2589 Logs file uploads included in the request to the debug logs.
2590 The parameter name, filename, file type, and file size are all included in
2591 the debug logs.
2592
2593 =cut
2594
2595 sub log_request_uploads {
2596     my $c = shift;
2597     my $request = shift;
2598     return unless $c->debug;
2599     my $uploads = $request->uploads;
2600     if ( keys %$uploads ) {
2601         my $t = Text::SimpleTable->new(
2602             [ 12, 'Parameter' ],
2603             [ 26, 'Filename' ],
2604             [ 18, 'Type' ],
2605             [ 9,  'Size' ]
2606         );
2607         for my $key ( sort keys %$uploads ) {
2608             my $upload = $uploads->{$key};
2609             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2610                 $t->row( $key, $u->filename, $u->type, $u->size );
2611             }
2612         }
2613         $c->log->debug( "File Uploads are:\n" . $t->draw );
2614     }
2615 }
2616
2617 =head2 $c->log_request_headers($headers);
2618
2619 Hook method which can be wrapped by plugins to log the request headers.
2620 No-op in the default implementation.
2621
2622 =cut
2623
2624 sub log_request_headers {}
2625
2626 =head2 $c->log_headers($type => $headers)
2627
2628 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2629
2630 =cut
2631
2632 sub log_headers {
2633     my $c       = shift;
2634     my $type    = shift;
2635     my $headers = shift;    # an HTTP::Headers instance
2636
2637     return unless $c->debug;
2638
2639     my $column_width = Catalyst::Utils::term_width() - 28;
2640     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2641     $headers->scan(
2642         sub {
2643             my ( $name, $value ) = @_;
2644             $t->row( $name, $value );
2645         }
2646     );
2647     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2648 }
2649
2650
2651 =head2 $c->prepare_read
2652
2653 Prepares the input for reading.
2654
2655 =cut
2656
2657 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2658
2659 =head2 $c->prepare_request
2660
2661 Prepares the engine request.
2662
2663 =cut
2664
2665 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2666
2667 =head2 $c->prepare_uploads
2668
2669 Prepares uploads.
2670
2671 =cut
2672
2673 sub prepare_uploads {
2674     my $c = shift;
2675     $c->engine->prepare_uploads( $c, @_ );
2676 }
2677
2678 =head2 $c->prepare_write
2679
2680 Prepares the output for writing.
2681
2682 =cut
2683
2684 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2685
2686 =head2 $c->request_class
2687
2688 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2689
2690 =head2 $c->response_class
2691
2692 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2693
2694 =head2 $c->read( [$maxlength] )
2695
2696 Reads a chunk of data from the request body. This method is designed to
2697 be used in a while loop, reading C<$maxlength> bytes on every call.
2698 C<$maxlength> defaults to the size of the request if not specified.
2699
2700 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2701 directly.
2702
2703 Warning: If you use read(), Catalyst will not process the body,
2704 so you will not be able to access POST parameters or file uploads via
2705 $c->request.  You must handle all body parsing yourself.
2706
2707 =cut
2708
2709 sub read { my $c = shift; return $c->request->read( @_ ) }
2710
2711 =head2 $c->run
2712
2713 Starts the engine.
2714
2715 =cut
2716
2717 sub run {
2718   my $app = shift;
2719   $app->_make_immutable_if_needed;
2720   $app->engine_loader->needs_psgi_engine_compat_hack ?
2721     $app->engine->run($app, @_) :
2722       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2723 }
2724
2725 sub _make_immutable_if_needed {
2726     my $class = shift;
2727     my $meta = find_meta($class);
2728     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2729     if (
2730         $meta->is_immutable
2731         && ! { $meta->immutable_options }->{replace_constructor}
2732         && $isa_ca
2733     ) {
2734         warn("You made your application class ($class) immutable, "
2735             . "but did not inline the\nconstructor. "
2736             . "This will break catalyst, as your app \@ISA "
2737             . "Class::Accessor(::Fast)?\nPlease pass "
2738             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2739     }
2740     unless ($meta->is_immutable) {
2741         # XXX - FIXME warning here as you should make your app immutable yourself.
2742         $meta->make_immutable(
2743             replace_constructor => 1,
2744         );
2745     }
2746 }
2747
2748 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2749
2750 Sets an action in a given namespace.
2751
2752 =cut
2753
2754 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2755
2756 =head2 $c->setup_actions($component)
2757
2758 Sets up actions for a component.
2759
2760 =cut
2761
2762 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2763
2764 =head2 $c->setup_components
2765
2766 This method is called internally to set up the application's components.
2767
2768 It finds modules by calling the L<locate_components> method, expands them to
2769 package names with the L<expand_component_module> method, and then installs
2770 each component into the application.
2771
2772 The C<setup_components> config option is passed to both of the above methods.
2773
2774 Installation of each component is performed by the L<setup_component> method,
2775 below.
2776
2777 =cut
2778
2779 sub setup_components {
2780     my $class = shift;
2781
2782     my $config  = $class->config->{ setup_components };
2783
2784     my @comps = $class->locate_components($config);
2785     my %comps = map { $_ => 1 } @comps;
2786
2787     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2788     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2789         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2790     ) if $deprecatedcatalyst_component_names;
2791
2792     for my $component ( @comps ) {
2793
2794         # We pass ignore_loaded here so that overlay files for (e.g.)
2795         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2796         # we know M::P::O found a file on disk so this is safe
2797
2798         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2799     }
2800
2801     for my $component (@comps) {
2802         my $instance = $class->components->{ $component } = $class->setup_component($component);
2803         my @expanded_components = $instance->can('expand_modules')
2804             ? $instance->expand_modules( $component, $config )
2805             : $class->expand_component_module( $component, $config );
2806         for my $component (@expanded_components) {
2807             next if $comps{$component};
2808             $class->components->{ $component } = $class->setup_component($component);
2809         }
2810     }
2811 }
2812
2813 =head2 $c->locate_components( $setup_component_config )
2814
2815 This method is meant to provide a list of component modules that should be
2816 setup for the application.  By default, it will use L<Module::Pluggable>.
2817
2818 Specify a C<setup_components> config option to pass additional options directly
2819 to L<Module::Pluggable>. To add additional search paths, specify a key named
2820 C<search_extra> as an array reference. Items in the array beginning with C<::>
2821 will have the application class name prepended to them.
2822
2823 =cut
2824
2825 sub locate_components {
2826     my $class  = shift;
2827     my $config = shift;
2828
2829     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2830     my $extra   = delete $config->{ search_extra } || [];
2831
2832     unshift @paths, @$extra;
2833
2834     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2835       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2836       %$config
2837     )->plugins } @paths;
2838
2839     return @comps;
2840 }
2841
2842 =head2 $c->expand_component_module( $component, $setup_component_config )
2843
2844 Components found by C<locate_components> will be passed to this method, which
2845 is expected to return a list of component (package) names to be set up.
2846
2847 =cut
2848
2849 sub expand_component_module {
2850     my ($class, $module) = @_;
2851     return Devel::InnerPackage::list_packages( $module );
2852 }
2853
2854 =head2 $c->setup_component
2855
2856 =cut
2857
2858 sub setup_component {
2859     my( $class, $component ) = @_;
2860
2861     unless ( $component->can( 'COMPONENT' ) ) {
2862         return $component;
2863     }
2864
2865     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2866     my $config = $class->config->{ $suffix } || {};
2867     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2868     # methods also pass it. local to avoid pointlessly shitting in config
2869     # for the debug screen, as $component is already the key name.
2870     local $config->{catalyst_component_name} = $component;
2871
2872     my $instance = eval { $component->COMPONENT( $class, $config ); };
2873
2874     if ( my $error = $@ ) {
2875         chomp $error;
2876         Catalyst::Exception->throw(
2877             message => qq/Couldn't instantiate component "$component", "$error"/
2878         );
2879     }
2880
2881     unless (blessed $instance) {
2882         my $metaclass = Moose::Util::find_meta($component);
2883         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2884         my $component_method_from = $method_meta->associated_metaclass->name;
2885         my $value = defined($instance) ? $instance : 'undef';
2886         Catalyst::Exception->throw(
2887             message =>
2888             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2889         );
2890     }
2891     return $instance;
2892 }
2893
2894 =head2 $c->setup_dispatcher
2895
2896 Sets up dispatcher.
2897
2898 =cut
2899
2900 sub setup_dispatcher {
2901     my ( $class, $dispatcher ) = @_;
2902
2903     if ($dispatcher) {
2904         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2905     }
2906
2907     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2908         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2909     }
2910
2911     unless ($dispatcher) {
2912         $dispatcher = $class->dispatcher_class;
2913     }
2914
2915     load_class($dispatcher);
2916
2917     # dispatcher instance
2918     $class->dispatcher( $dispatcher->new );
2919 }
2920
2921 =head2 $c->setup_engine
2922
2923 Sets up engine.
2924
2925 =cut
2926
2927 sub engine_class {
2928     my ($class, $requested_engine) = @_;
2929
2930     if (!$class->engine_loader || $requested_engine) {
2931         $class->engine_loader(
2932             Catalyst::EngineLoader->new({
2933                 application_name => $class,
2934                 (defined $requested_engine
2935                      ? (catalyst_engine_class => $requested_engine) : ()),
2936             }),
2937         );
2938     }
2939
2940     $class->engine_loader->catalyst_engine_class;
2941 }
2942
2943 sub setup_engine {
2944     my ($class, $requested_engine) = @_;
2945
2946     my $engine = do {
2947         my $loader = $class->engine_loader;
2948
2949         if (!$loader || $requested_engine) {
2950             $loader = Catalyst::EngineLoader->new({
2951                 application_name => $class,
2952                 (defined $requested_engine
2953                      ? (requested_engine => $requested_engine) : ()),
2954             }),
2955
2956             $class->engine_loader($loader);
2957         }
2958
2959         $loader->catalyst_engine_class;
2960     };
2961
2962     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2963     return if $class->loading_psgi_file;
2964
2965     load_class($engine);
2966
2967     if ($ENV{MOD_PERL}) {
2968         my $apache = $class->engine_loader->auto;
2969
2970         my $meta = find_meta($class);
2971         my $was_immutable = $meta->is_immutable;
2972         my %immutable_options = $meta->immutable_options;
2973         $meta->make_mutable if $was_immutable;
2974
2975         $meta->add_method(handler => sub {
2976             my $r = shift;
2977             my $psgi_app = $class->_finalized_psgi_app;
2978             $apache->call_app($r, $psgi_app);
2979         });
2980
2981         $meta->make_immutable(%immutable_options) if $was_immutable;
2982     }
2983
2984     $class->engine( $engine->new );
2985
2986     return;
2987 }
2988
2989 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2990 ## build in server support (back compat support for pre psgi port behavior).
2991 ## This is so that we don't build a new psgi app for each request when using
2992 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2993
2994 sub _finalized_psgi_app {
2995     my ($app) = @_;
2996
2997     unless ($app->_psgi_app) {
2998         my $psgi_app = $app->_setup_psgi_app;
2999         $app->_psgi_app($psgi_app);
3000     }
3001
3002     return $app->_psgi_app;
3003 }
3004
3005 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
3006 ## home directory and load that and return it (just assume it is doing the
3007 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
3008 ## in default_middleware and return it ( this is for backward compatibility
3009 ## with pre psgi port behavior ).
3010
3011 sub _setup_psgi_app {
3012     my ($app) = @_;
3013
3014     for my $home (Path::Class::Dir->new($app->config->{home})) {
3015         my $psgi_file = $home->file(
3016             Catalyst::Utils::appprefix($app) . '.psgi',
3017         );
3018
3019         next unless -e $psgi_file;
3020
3021         # If $psgi_file calls ->setup_engine, it's doing so to load
3022         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3023         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3024         # anyway. So set a flag (ick) that tells setup_engine not to populate
3025         # $c->engine or do any other things we might regret.
3026
3027         $app->loading_psgi_file(1);
3028         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3029         $app->loading_psgi_file(0);
3030
3031         return $psgi_app
3032             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3033
3034         warn <<"EOW";
3035 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3036
3037 Its content has been ignored. Please consult the Catalyst::Upgrading
3038 documentation on how to upgrade from Catalyst::Engine::PSGI.
3039 EOW
3040     }
3041
3042     return $app->apply_default_middlewares($app->psgi_app);
3043 }
3044
3045 =head2 $c->apply_default_middlewares
3046
3047 Adds the following L<Plack> middlewares to your application, since they are
3048 useful and commonly needed:
3049
3050 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3051 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3052 is smart enough to conditionally apply itself).
3053
3054 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3055 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3056 an indication that your server is running behind a proxy frontend.  However in
3057 2014 this is often not the case.  We preserve this code for backwards compatibility
3058 however I B<highly> recommend that if you are running the server behind a front
3059 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3060 setting to true for your environment configurations that run behind a proxy.  This
3061 way if you change your front end proxy address someday your code would inexplicably
3062 stop working as expected.
3063
3064 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3065 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3066 $ENV{SCRIPT_NAME}.
3067
3068 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3069 adding via C<registered_middleware> rather than this method.
3070
3071 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3072 general this is no longer a common case but we have this here for backward
3073 compatibility.
3074
3075 =cut
3076
3077
3078 sub apply_default_middlewares {
3079     my ($app, $psgi_app) = @_;
3080
3081     # Don't add this conditional IF we are explicitly saying we want the
3082     # frontend proxy support.  We don't need it here since if that is the
3083     # case it will be always loaded in the default_middleware.
3084
3085     unless($app->config->{using_frontend_proxy}) {
3086       $psgi_app = Plack::Middleware::Conditional->wrap(
3087           $psgi_app,
3088           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3089           condition => sub {
3090               my ($env) = @_;
3091               return if $app->config->{ignore_frontend_proxy};
3092               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3093           },
3094       );
3095     }
3096
3097     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3098     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3099     $psgi_app = Plack::Middleware::Conditional->wrap(
3100         $psgi_app,
3101         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3102         condition => sub {
3103             my ($env) = @_;
3104             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3105             return unless $1 < 4.23;
3106             1;
3107         },
3108     );
3109
3110     # we're applying this unconditionally as the middleware itself already makes
3111     # sure it doesn't fuck things up if it's not running under one of the right
3112     # IIS versions
3113     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3114
3115     # And another IIS issue, this time with IIS7.
3116     $psgi_app = Plack::Middleware::Conditional->wrap(
3117         $psgi_app,
3118         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3119         condition => sub {
3120             my ($env) = @_;
3121             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3122         },
3123     );
3124
3125     return $psgi_app;
3126 }
3127
3128 =head2 App->psgi_app
3129
3130 =head2 App->to_app
3131
3132 Returns a PSGI application code reference for the catalyst application
3133 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3134 method called.  We do however apply C<registered_middleware> since those are
3135 integral to how L<Catalyst> functions.  Also, unlike starting your application
3136 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3137 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3138 scripts in your $HOME directory.
3139
3140 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3141 port was done for v5.90000.  These are middlewares that are added to achieve
3142 backward compatibility with older applications.  If you start your application
3143 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3144 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3145 automatically.  This was done so that pre and post PSGI port applications would
3146 work the same way.
3147
3148 This is what you want to be using to retrieve the PSGI application code
3149 reference of your Catalyst application for use in a custom F<.psgi> or in your
3150 own created server modules.
3151
3152 =cut
3153
3154 *to_app = \&psgi_app;
3155
3156 sub psgi_app {
3157     my ($app) = @_;
3158     my $psgi = $app->engine->build_psgi_app($app);
3159     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3160 }
3161
3162 =head2 $c->setup_home
3163
3164 Sets up the home directory.
3165
3166 =cut
3167
3168 sub setup_home {
3169     my ( $class, $home ) = @_;
3170
3171     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3172         $home = $env;
3173     }
3174
3175     $home ||= Catalyst::Utils::home($class);
3176
3177     if ($home) {
3178         #I remember recently being scolded for assigning config values like this
3179         $class->config->{home} ||= $home;
3180         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3181     }
3182 }
3183
3184 =head2 $c->setup_encoding
3185
3186 Sets up the input/output encoding. See L<ENCODING>
3187
3188 =cut
3189
3190 sub setup_encoding {
3191     my $c = shift;
3192     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3193         # Ok, so the user has explicitly said "I don't want encoding..."
3194         return;
3195     } else {
3196       my $enc = defined($c->config->{encoding}) ?
3197         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3198       $c->encoding($enc);
3199     }
3200 }
3201
3202 =head2 handle_unicode_encoding_exception
3203
3204 Hook to let you customize how encoding errors are handled.  By default
3205 we just throw an exception.  Receives a hashref of debug information.
3206 Example:
3207
3208     $c->handle_unicode_encoding_exception({
3209         param_value => $value,
3210         error_msg => $_,
3211             encoding_step => 'params',
3212         });
3213
3214 =cut
3215
3216 sub handle_unicode_encoding_exception {
3217     my ( $self, $exception_ctx ) = @_;
3218     die $exception_ctx->{error_msg};
3219 }
3220
3221 # Some unicode helpers cargo culted from the old plugin.  These could likely
3222 # be neater.
3223
3224 sub _handle_unicode_decoding {
3225     my ( $self, $value ) = @_;
3226
3227     return unless defined $value;
3228
3229     ## I think this mess is to support the old nested
3230     if ( ref $value eq 'ARRAY' ) {
3231         foreach ( @$value ) {
3232             $_ = $self->_handle_unicode_decoding($_);
3233         }
3234         return $value;
3235     }
3236     elsif ( ref $value eq 'HASH' ) {
3237         foreach (keys %$value) {
3238             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3239             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3240
3241             # If the key was encoded we now have two (the original and current so
3242             # delete the original.
3243             delete $value->{$_} if $_ ne $encoded_key;
3244         }
3245         return $value;
3246     }
3247     else {
3248         return $self->_handle_param_unicode_decoding($value);
3249     }
3250 }
3251
3252 sub _handle_param_unicode_decoding {
3253     my ( $self, $value ) = @_;
3254     return unless defined $value; # not in love with just ignoring undefs - jnap
3255     return $value if blessed($value); #don't decode when the value is an object.
3256
3257     my $enc = $self->encoding;
3258     return try {
3259       $enc->decode( $value, $self->_encode_check );
3260     }
3261     catch {
3262         $self->handle_unicode_encoding_exception({
3263             param_value => $value,
3264             error_msg => $_,
3265             encoding_step => 'params',
3266         });
3267     };
3268 }
3269
3270 =head2 $c->setup_log
3271
3272 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3273 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3274 log to.
3275
3276 This method also installs a C<debug> method that returns a true value into the
3277 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3278 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3279
3280 Note that if the log has already been setup, by either a previous call to
3281 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3282 that this method won't actually set up the log object.
3283
3284 =cut
3285
3286 sub setup_log {
3287     my ( $class, $levels ) = @_;
3288
3289     $levels ||= '';
3290     $levels =~ s/^\s+//;
3291     $levels =~ s/\s+$//;
3292     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3293
3294     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3295     if ( defined $env_debug ) {
3296         $levels{debug} = 1 if $env_debug; # Ugly!
3297         delete($levels{debug}) unless $env_debug;
3298     }
3299
3300     unless ( $class->log ) {
3301         $class->log( Catalyst::Log->new(keys %levels) );
3302     }
3303
3304     if ( $levels{debug} ) {
3305         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3306         $class->log->debug('Debug messages enabled');
3307     }
3308 }
3309
3310 =head2 $c->setup_plugins
3311
3312 Sets up plugins.
3313
3314 =cut
3315
3316 =head2 $c->setup_stats
3317
3318 Sets up timing statistics class.
3319
3320 =cut
3321
3322 sub setup_stats {
3323     my ( $class, $stats ) = @_;
3324
3325     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3326
3327     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3328     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3329         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3330         $class->log->debug('Statistics enabled');
3331     }
3332 }
3333
3334
3335 =head2 $c->registered_plugins
3336
3337 Returns a sorted list of the plugins which have either been stated in the
3338 import list.
3339
3340 If passed a given plugin name, it will report a boolean value indicating
3341 whether or not that plugin is loaded.  A fully qualified name is required if
3342 the plugin name does not begin with C<Catalyst::Plugin::>.
3343
3344  if ($c->registered_plugins('Some::Plugin')) {
3345      ...
3346  }
3347
3348 =cut
3349
3350 {
3351
3352     sub registered_plugins {
3353         my $proto = shift;
3354         return sort keys %{ $proto->_plugins } unless @_;
3355         my $plugin = shift;
3356         return 1 if exists $proto->_plugins->{$plugin};
3357         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3358     }
3359
3360     sub _register_plugin {
3361         my ( $proto, $plugin, $instant ) = @_;
3362         my $class = ref $proto || $proto;
3363
3364         load_class( $plugin );
3365         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3366             if $plugin->isa( 'Catalyst::Component' );
3367         my $plugin_meta = Moose::Meta::Class->create($plugin);
3368         if (!$plugin_meta->has_method('new')
3369             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3370             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3371         }
3372         if (!$instant && !$proto->_plugins->{$plugin}) {
3373             my $meta = Class::MOP::get_metaclass_by_name($class);
3374             $meta->superclasses($plugin, $meta->superclasses);
3375         }
3376         $proto->_plugins->{$plugin} = 1;
3377         return $class;
3378     }
3379
3380     sub _default_plugins { return qw() }
3381
3382     sub setup_plugins {
3383         my ( $class, $plugins ) = @_;
3384
3385         $class->_plugins( {} ) unless $class->_plugins;
3386         $plugins = [ grep {
3387             m/Unicode::Encoding/ ? do {
3388                 $class->log->warn(
3389                     'Unicode::Encoding plugin is auto-applied,'
3390                     . ' please remove this from your appclass'
3391                     . ' and make sure to define "encoding" config'
3392                 );
3393                 unless (exists $class->config->{'encoding'}) {
3394                   $class->config->{'encoding'} = 'UTF-8';
3395                 }
3396                 () }
3397                 : $_
3398         } @$plugins ];
3399         push @$plugins, $class->_default_plugins;
3400         $plugins = Data::OptList::mkopt($plugins || []);
3401
3402         my @plugins = map {
3403             [ Catalyst::Utils::resolve_namespace(
3404                   $class . '::Plugin',
3405                   'Catalyst::Plugin', $_->[0]
3406               ),
3407               $_->[1],
3408             ]
3409          } @{ $plugins };
3410
3411         for my $plugin ( reverse @plugins ) {
3412             load_class($plugin->[0], $plugin->[1]);
3413             my $meta = find_meta($plugin->[0]);
3414             next if $meta && $meta->isa('Moose::Meta::Role');
3415
3416             $class->_register_plugin($plugin->[0]);
3417         }
3418
3419         my @roles =
3420             map  { $_->[0]->name, $_->[1] }
3421             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3422             map  { [find_meta($_->[0]), $_->[1]] }
3423             @plugins;
3424
3425         Moose::Util::apply_all_roles(
3426             $class => @roles
3427         ) if @roles;
3428     }
3429 }
3430
3431 =head2 default_middleware
3432
3433 Returns a list of instantiated PSGI middleware objects which is the default
3434 middleware that is active for this application (taking any configuration
3435 options into account, excluding your custom added middleware via the C<psgi_middleware>
3436 configuration option).  You can override this method if you wish to change
3437 the default middleware (although do so at risk since some middleware is vital
3438 to application function.)
3439
3440 The current default middleware list is:
3441
3442       Catalyst::Middleware::Stash
3443       Plack::Middleware::HTTPExceptions
3444       Plack::Middleware::RemoveRedundantBody
3445       Plack::Middleware::FixMissingBodyInRedirect
3446       Plack::Middleware::ContentLength
3447       Plack::Middleware::MethodOverride
3448       Plack::Middleware::Head
3449
3450 If the configuration setting C<using_frontend_proxy> is true we add:
3451
3452       Plack::Middleware::ReverseProxy
3453
3454 If the configuration setting C<using_frontend_proxy_path> is true we add:
3455
3456       Plack::Middleware::ReverseProxyPath
3457
3458 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3459 L<Catalyst> distribution so if you want to use this option you should add it to
3460 your project distribution file.
3461
3462 These middlewares will be added at L</setup_middleware> during the
3463 L</setup> phase of application startup.
3464
3465 =cut
3466
3467 sub default_middleware {
3468     my $class = shift;
3469     my @mw = (
3470       Catalyst::Middleware::Stash->new,
3471       Plack::Middleware::HTTPExceptions->new,
3472       Plack::Middleware::RemoveRedundantBody->new,
3473       Plack::Middleware::FixMissingBodyInRedirect->new,
3474       Plack::Middleware::ContentLength->new,
3475       Plack::Middleware::MethodOverride->new,
3476       Plack::Middleware::Head->new);
3477
3478     if($class->config->{using_frontend_proxy}) {
3479         push @mw, Plack::Middleware::ReverseProxy->new;
3480     }
3481
3482     if($class->config->{using_frontend_proxy_path}) {
3483         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3484             push @mw, Plack::Middleware::ReverseProxyPath->new;
3485         } else {
3486           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3487         }
3488     }
3489
3490     return @mw;
3491 }
3492
3493 =head2 registered_middlewares
3494
3495 Read only accessor that returns an array of all the middleware in the order
3496 that they were added (which is the REVERSE of the order they will be applied).
3497
3498 The values returned will be either instances of L<Plack::Middleware> or of a
3499 compatible interface, or a coderef, which is assumed to be inlined middleware
3500
3501 =head2 setup_middleware (?@middleware)
3502
3503 Read configuration information stored in configuration key C<psgi_middleware> or
3504 from passed @args.
3505
3506 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3507 to use it to enable L<Plack::Middleware>
3508
3509 This method is automatically called during 'setup' of your application, so
3510 you really don't need to invoke it.  However you may do so if you find the idea
3511 of loading middleware via configuration weird :).  For example:
3512
3513     package MyApp;
3514
3515     use Catalyst;
3516
3517     __PACKAGE__->setup_middleware('Head');
3518     __PACKAGE__->setup;
3519
3520 When we read middleware definitions from configuration, we reverse the list
3521 which sounds odd but is likely how you expect it to work if you have prior
3522 experience with L<Plack::Builder> or if you previously used the plugin
3523 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3524
3525 So basically your middleware handles an incoming request from the first
3526 registered middleware, down and handles the response from the last middleware
3527 up.
3528
3529 =cut
3530
3531 sub registered_middlewares {
3532     my $class = shift;
3533     if(my $middleware = $class->_psgi_middleware) {
3534         my @mw = ($class->default_middleware, @$middleware);
3535
3536         if($class->config->{using_frontend_proxy}) {
3537           push @mw, Plack::Middleware::ReverseProxy->new;
3538         }
3539
3540         return @mw;
3541     } else {
3542         die "You cannot call ->registered_middlewares until middleware has been setup";
3543     }
3544 }
3545
3546 sub setup_middleware {
3547     my $class = shift;
3548     my @middleware_definitions;
3549
3550     # If someone calls this method you can add middleware with args.  However if its
3551     # called without an arg we need to setup the configuration middleware.
3552     if(@_) {
3553       @middleware_definitions = reverse(@_);
3554     } else {
3555       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3556         unless $class->finalized_default_middleware;
3557       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3558     }
3559
3560     my @middleware = ();
3561     while(my $next = shift(@middleware_definitions)) {
3562         if(ref $next) {
3563             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3564                 push @middleware, $next;
3565             } elsif(ref $next eq 'CODE') {
3566                 push @middleware, $next;
3567             } elsif(ref $next eq 'HASH') {
3568                 my $namespace = shift @middleware_definitions;
3569                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3570                 push @middleware, $mw;
3571             } else {
3572               die "I can't handle middleware definition ${\ref $next}";
3573             }
3574         } else {
3575           my $mw = $class->Catalyst::Utils::build_middleware($next);
3576           push @middleware, $mw;
3577         }
3578     }
3579
3580     my @existing = @{$class->_psgi_middleware || []};
3581     $class->_psgi_middleware([@middleware,@existing,]);
3582 }
3583
3584 =head2 registered_data_handlers
3585
3586 A read only copy of registered Data Handlers returned as a Hash, where each key
3587 is a content type and each value is a subref that attempts to decode that content
3588 type.
3589
3590 =head2 setup_data_handlers (?@data_handler)
3591
3592 Read configuration information stored in configuration key C<data_handlers> or
3593 from passed @args.
3594
3595 See under L</CONFIGURATION> information regarding C<data_handlers>.
3596
3597 This method is automatically called during 'setup' of your application, so
3598 you really don't need to invoke it.
3599
3600 =head2 default_data_handlers
3601
3602 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3603 only two default data handlers, for 'application/json' and an alternative to
3604 'application/x-www-form-urlencoded' which supposed nested form parameters via
3605 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3606
3607 The 'application/json' data handler is used to parse incoming JSON into a Perl
3608 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3609 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3610 JSON decoder, and has the smallest dependency impact.
3611
3612 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3613 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3614 order to get the best performance.  You should add either to your dependency
3615 list (Makefile.PL, dist.ini, cpanfile, etc.)
3616
3617 =cut
3618
3619 sub registered_data_handlers {
3620     my $class = shift;
3621     if(my $data_handlers = $class->_data_handlers) {
3622         return %$data_handlers;
3623     } else {
3624         $class->setup_data_handlers;
3625         return $class->registered_data_handlers;
3626     }
3627 }
3628
3629 sub setup_data_handlers {
3630     my ($class, %data_handler_callbacks) = @_;
3631     %data_handler_callbacks = (
3632       %{$class->default_data_handlers},
3633       %{$class->config->{'data_handlers'}||+{}},
3634       %data_handler_callbacks);
3635
3636     $class->_data_handlers(\%data_handler_callbacks);
3637 }
3638
3639 sub default_data_handlers {
3640     my ($class) = @_;
3641     return +{
3642       'application/x-www-form-urlencoded' => sub {
3643           my ($fh, $req) = @_;
3644           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3645           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3646             ->can('build_cgi_struct')->($params);
3647       },
3648       'application/json' => sub {
3649           my ($fh, $req) = @_;
3650           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
3651           my $slurped;
3652           return eval {
3653             local $/;
3654             $slurped = $fh->getline;
3655             $parser->can("decode_json")->($slurped); # decode_json does utf8 decoding for us
3656           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
3657         },
3658     };
3659 }
3660
3661 sub _handle_http_exception {
3662     my ( $self, $error ) = @_;
3663     if (
3664            !$self->config->{always_catch_http_exceptions}
3665         && blessed $error
3666         && (
3667             $error->can('as_psgi')
3668             || (   $error->can('code')
3669                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
3670         )
3671       )
3672     {
3673         return 1;
3674     }
3675 }
3676
3677 =head2 $c->stack
3678
3679 Returns an arrayref of the internal execution stack (actions that are
3680 currently executing).
3681
3682 =head2 $c->stats
3683
3684 Returns the current timing statistics object. By default Catalyst uses
3685 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3686 L<< stats_class|/"$c->stats_class" >>.
3687
3688 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3689 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3690 profile explicitly, although MyApp.pm still won't profile nor output anything
3691 by itself.
3692
3693 =head2 $c->stats_class
3694
3695 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3696
3697 =head2 $c->use_stats
3698
3699 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3700
3701 Note that this is a static method, not an accessor and should be overridden
3702 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3703
3704 =cut
3705
3706 sub use_stats { 0 }
3707
3708
3709 =head2 $c->write( $data )
3710
3711 Writes $data to the output stream. When using this method directly, you
3712 will need to manually set the C<Content-Length> header to the length of
3713 your output data, if known.
3714
3715 =cut
3716
3717 sub write {
3718     my $c = shift;
3719
3720     # Finalize headers if someone manually writes output (for compat)
3721     $c->finalize_headers;
3722
3723     return $c->response->write( @_ );
3724 }
3725
3726 =head2 version
3727
3728 Returns the Catalyst version number. Mostly useful for "powered by"
3729 messages in template systems.
3730
3731 =cut
3732
3733 sub version { return $Catalyst::VERSION }
3734
3735 =head1 CONFIGURATION
3736
3737 There are a number of 'base' config variables which can be set:
3738
3739 =over
3740
3741 =item *
3742
3743 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
3744 rethrows errors conforming to the interface described by
3745 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
3746 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
3747
3748 =item *
3749
3750 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3751
3752 =item *
3753
3754 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3755
3756 =item *
3757
3758 C<disable_component_resolution_regex_fallback> - Turns
3759 off the deprecated component resolution functionality so
3760 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3761 are called then regex search will not be attempted on string values and
3762 instead C<undef> will be returned.
3763
3764 =item *
3765
3766 C<home> - The application home directory. In an uninstalled application,
3767 this is the top level application directory. In an installed application,
3768 this will be the directory containing C<< MyApp.pm >>.
3769
3770 =item *
3771
3772 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3773
3774 =item *
3775
3776 C<name> - The name of the application in debug messages and the debug and
3777 welcome screens
3778
3779 =item *
3780
3781 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3782 until it is accessed. This allows you to (for example) check authentication (and reject
3783 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3784
3785 =item *
3786
3787 C<root> - The root directory for templates. Usually this is just a
3788 subdirectory of the home directory, but you can set it to change the
3789 templates to a different directory.
3790
3791 =item *
3792
3793 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3794 namespaces from which components will be loaded (and constructed and stored in
3795 C<< $c->components >>).
3796
3797 =item *
3798
3799 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3800 to be shown in hit debug tables in the test server.
3801
3802 =item *
3803
3804 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3805 variable should be used for determining the request path.
3806
3807 Most web server environments pass the requested path to the application using environment variables,
3808 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3809 exposed as C<< $c->request->base >>) and the request path below that base.
3810
3811 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3812 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3813
3814 =over
3815
3816 =item use_request_uri_for_path => 0
3817
3818 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3819 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3820 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3821 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3822
3823 However this method has the major disadvantage that it is impossible to correctly decode some elements
3824 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3825 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3826 can't distinguish / vs %2F in paths (in addition to other encoded values).
3827
3828 =item use_request_uri_for_path => 1
3829
3830 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3831 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3832 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3833
3834 Given that this method of path resolution is provably more correct, it is recommended that you use
3835 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3836 aware of the implications of not being able to handle encoded URI paths correctly.
3837
3838 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3839 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3840 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3841 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3842 C<< $c->request->base >> will be incorrect.
3843
3844 =back
3845
3846 =item *
3847
3848 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3849
3850 =item *
3851
3852 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
3853 installed, otherwise log an error).  This is useful if your application is not running on the
3854 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
3855 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
3856 This has been done since not all people need this feature and we wish to restrict the growth of
3857 L<Catalyst> dependencies.
3858
3859 =item *
3860
3861 C<encoding> - See L</ENCODING>
3862
3863 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
3864 value to undef.
3865
3866 =item *
3867
3868 C<abort_chain_on_error_fix>
3869
3870 When there is an error in an action chain, the default behavior is to continue
3871 processing the remaining actions and then catch the error upon chain end.  This
3872 can lead to running actions when the application is in an unexpected state.  If
3873 you have this issue, setting this config value to true will promptly exit a
3874 chain when there is an error raised in any action (thus terminating the chain
3875 early.)
3876
3877 use like:
3878
3879     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3880
3881 In the future this might become the default behavior.
3882
3883 =item *
3884
3885 C<use_hash_multivalue_in_request>
3886
3887 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3888 and C<parameters> return a hashref where values might be scalar or an arrayref
3889 depending on the incoming data.  In many cases this can be undesirable as it
3890 leads one to writing defensive code like the following:
3891
3892     my ($val) = ref($c->req->parameters->{a}) ?
3893       @{$c->req->parameters->{a}} :
3894         $c->req->parameters->{a};
3895
3896 Setting this configuration item to true will make L<Catalyst> populate the
3897 attributes underlying these methods with an instance of L<Hash::MultiValue>
3898 which is used by L<Plack::Request> and others to solve this very issue.  You
3899 may prefer this behavior to the default, if so enable this option (be warned
3900 if you enable it in a legacy application we are not sure if it is completely
3901 backwardly compatible).
3902
3903 =item *
3904
3905 C<skip_complex_post_part_handling>
3906
3907 When creating body parameters from a POST, if we run into a multpart POST
3908 that does not contain uploads, but instead contains inlined complex data
3909 (very uncommon) we cannot reliably convert that into field => value pairs.  So
3910 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
3911 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
3912 to true (default is false).
3913
3914 =item *
3915
3916 C<skip_body_param_unicode_decoding>
3917
3918 Generally we decode incoming POST params based on your declared encoding (the
3919 default for this is to decode UTF-8).  If this is causing you trouble and you
3920 do not wish to turn all encoding support off (with the C<encoding> configuration
3921 parameter) you may disable this step atomically by setting this configuration
3922 parameter to true.
3923
3924 =item *
3925
3926 C<do_not_decode_query>
3927
3928 If true, then do not try to character decode any wide characters in your
3929 request URL query or keywords.  Most readings of the relevent specifications
3930 suggest these should be UTF-* encoded, which is the default that L<Catalyst>
3931 will use, hwoever if you are creating a lot of URLs manually or have external
3932 evil clients, this might cause you trouble.  If you find the changes introduced
3933 in Catalyst version 5.90080+ break some of your query code, you may disable
3934 the UTF-8 decoding globally using this configuration.
3935
3936 This setting takes precedence over C<default_query_encoding> and
3937 C<decode_query_using_global_encoding>
3938
3939 =item *
3940
3941 C<default_query_encoding>
3942
3943 By default we decode query and keywords in your request URL using UTF-8, which
3944 is our reading of the relevent specifications.  This setting allows one to
3945 specify a fixed value for how to decode your query.  You might need this if
3946 you are doing a lot of custom encoding of your URLs and not using UTF-8.
3947
3948 This setting take precedence over C<decode_query_using_global_encoding>.
3949
3950 =item *
3951
3952 C<decode_query_using_global_encoding>
3953
3954 Setting this to true will default your query decoding to whatever your
3955 general global encoding is (the default is UTF-8).
3956
3957 =item *
3958
3959 C<use_chained_args_0_special_case>
3960
3961 In older versions of Catalyst, when more than one action matched the same path
3962 AND all those matching actions declared Args(0), we'd break the tie by choosing
3963 the first action defined.  We now normalized how Args(0) works so that it
3964 follows the same rule as Args(N), which is to say when we need to break a tie
3965 we choose the LAST action defined.  If this breaks your code and you don't
3966 have time to update to follow the new normalized approach, you may set this
3967 value to true and it will globally revert to the original chaining behavior.
3968
3969 =item *
3970
3971 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3972
3973 =item *
3974
3975 C<data_handlers> - See L<DATA HANDLERS>.
3976
3977 =back
3978
3979 =head1 EXCEPTIONS
3980
3981 Generally when you throw an exception inside an Action (or somewhere in
3982 your stack, such as in a model that an Action is calling) that exception
3983 is caught by Catalyst and unless you either catch it yourself (via eval
3984 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3985 will eventually reach L</finalize_errors> and return either the debugging
3986 error stack page, or the default error page.  However, if your exception
3987 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3988 instead rethrow it so that it can be handled by that middleware (which
3989 is part of the default middleware).  For example this would allow
3990
3991     use HTTP::Throwable::Factory 'http_throw';
3992
3993     sub throws_exception :Local {
3994       my ($self, $c) = @_;
3995
3996       http_throw(SeeOther => { location =>
3997         $c->uri_for($self->action_for('redirect')) });
3998
3999     }
4000
4001 =head1 INTERNAL ACTIONS
4002
4003 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
4004 C<_ACTION>, and C<_END>. These are by default not shown in the private
4005 action table, but you can make them visible with a config parameter.
4006
4007     MyApp->config(show_internal_actions => 1);
4008
4009 =head1 ON-DEMAND PARSER
4010
4011 The request body is usually parsed at the beginning of a request,
4012 but if you want to handle input yourself, you can enable on-demand
4013 parsing with a config parameter.
4014
4015     MyApp->config(parse_on_demand => 1);
4016
4017 =head1 PROXY SUPPORT
4018
4019 Many production servers operate using the common double-server approach,
4020 with a lightweight frontend web server passing requests to a larger
4021 backend server. An application running on the backend server must deal
4022 with two problems: the remote user always appears to be C<127.0.0.1> and
4023 the server's hostname will appear to be C<localhost> regardless of the
4024 virtual host that the user connected through.
4025
4026 Catalyst will automatically detect this situation when you are running
4027 the frontend and backend servers on the same machine. The following
4028 changes are made to the request.
4029
4030     $c->req->address is set to the user's real IP address, as read from
4031     the HTTP X-Forwarded-For header.
4032
4033     The host value for $c->req->base and $c->req->uri is set to the real
4034     host, as read from the HTTP X-Forwarded-Host header.
4035
4036 Additionally, you may be running your backend application on an insecure
4037 connection (port 80) while your frontend proxy is running under SSL.  If there
4038 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
4039 tell Catalyst what port the frontend listens on.  This will allow all URIs to
4040 be created properly.
4041
4042 In the case of passing in:
4043
4044     X-Forwarded-Port: 443
4045
4046 All calls to C<uri_for> will result in an https link, as is expected.
4047
4048 Obviously, your web server must support these headers for this to work.
4049
4050 In a more complex server farm environment where you may have your
4051 frontend proxy server(s) on different machines, you will need to set a
4052 configuration option to tell Catalyst to read the proxied data from the
4053 headers.
4054
4055     MyApp->config(using_frontend_proxy => 1);
4056
4057 If you do not wish to use the proxy support at all, you may set:
4058
4059     MyApp->config(ignore_frontend_proxy => 0);
4060
4061 =head2 Note about psgi files
4062
4063 Note that if you supply your own .psgi file, calling
4064 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4065
4066 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4067 in your psgi, for example:
4068
4069     builder {
4070         enable "Plack::Middleware::ReverseProxy";
4071         MyApp->psgi_app
4072     };
4073
4074 This will unconditionally add the ReverseProxy support, or you need to call
4075 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4076 apply the support depending upon your config).
4077
4078 See L<Catalyst::PSGI> for more information.
4079
4080 =head1 THREAD SAFETY
4081
4082 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4083 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4084 believe the Catalyst core to be thread-safe.
4085
4086 If you plan to operate in a threaded environment, remember that all other
4087 modules you are using must also be thread-safe. Some modules, most notably
4088 L<DBD::SQLite>, are not thread-safe.
4089
4090 =head1 DATA HANDLERS
4091
4092 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4093 form parameters and URL search query fields.  However it has become common
4094 for various alternative content types to be PUT or POSTed to your controllers
4095 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4096 XML and other content types when communicating with an application server.  In
4097 order to better support this use case, L<Catalyst> defines a global configuration
4098 option, C<data_handlers>, which lets you associate a content type with a coderef
4099 that parses that content type into something Perl can readily access.
4100
4101     package MyApp::Web;
4102
4103     use Catalyst;
4104     use JSON::Maybe;
4105
4106     __PACKAGE__->config(
4107       data_handlers => {
4108         'application/json' => sub { local $/; decode_json $_->getline },
4109       },
4110       ## Any other configuration.
4111     );
4112
4113     __PACKAGE__->setup;
4114
4115 By default L<Catalyst> comes with a generic JSON data handler similar to the
4116 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4117 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4118 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4119 or dist.ini, cpanfile, etc.)
4120
4121 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4122 (matched against the incoming request type using a regexp such as to be case
4123 insensitive) and whose values are coderefs that receive a localized version of
4124 C<$_> which is a filehandle object pointing to received body.
4125
4126 This feature is considered an early access release and we reserve the right
4127 to alter the interface in order to provide a performant and secure solution to
4128 alternative request body content.  Your reports welcomed!
4129
4130 =head1 PSGI MIDDLEWARE
4131
4132 You can define middleware, defined as L<Plack::Middleware> or a compatible
4133 interface in configuration.  Your middleware definitions are in the form of an
4134 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4135 with details to follow:
4136
4137     package MyApp::Web;
4138
4139     use Catalyst;
4140     use Plack::Middleware::StackTrace;
4141
4142     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4143
4144     __PACKAGE__->config(
4145       'psgi_middleware', [
4146         'Debug',
4147         '+MyApp::Custom',
4148         $stacktrace_middleware,
4149         'Session' => {store => 'File'},
4150         sub {
4151           my $app = shift;
4152           return sub {
4153             my $env = shift;
4154             $env->{myapp.customkey} = 'helloworld';
4155             $app->($env);
4156           },
4157         },
4158       ],
4159     );
4160
4161     __PACKAGE__->setup;
4162
4163 So the general form is:
4164
4165     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4166
4167 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4168 the order listed (to make it function similarly to L<Plack::Builder>:
4169
4170 Alternatively, you may also define middleware by calling the L</setup_middleware>
4171 package method:
4172
4173     package MyApp::Web;
4174
4175     use Catalyst;
4176
4177     __PACKAGE__->setup_middleware( \@middleware_definitions);
4178     __PACKAGE__->setup;
4179
4180 In the case where you do both (use 'setup_middleware' and configuration) the
4181 package call to setup_middleware will be applied earlier (in other words its
4182 middleware will wrap closer to the application).  Keep this in mind since in
4183 some cases the order of middleware is important.
4184
4185 The two approaches are not exclusive.
4186
4187 =over 4
4188
4189 =item Middleware Object
4190
4191 An already initialized object that conforms to the L<Plack::Middleware>
4192 specification:
4193
4194     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4195
4196     __PACKAGE__->config(
4197       'psgi_middleware', [
4198         $stacktrace_middleware,
4199       ]);
4200
4201
4202 =item coderef
4203
4204 A coderef that is an inlined middleware:
4205
4206     __PACKAGE__->config(
4207       'psgi_middleware', [
4208         sub {
4209           my $app = shift;
4210           return sub {
4211             my $env = shift;
4212             if($env->{PATH_INFO} =~m/forced/) {
4213               Plack::App::File
4214                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4215                 ->call($env);
4216             } else {
4217               return $app->($env);
4218             }
4219          },
4220       },
4221     ]);
4222
4223
4224
4225 =item a scalar
4226
4227 We assume the scalar refers to a namespace after normalizing it using the
4228 following rules:
4229
4230 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4231 is assumed to be 'as is', and we just install and use the middleware.
4232
4233 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4234 (the package name of your Catalyst application subclass), we also assume then
4235 that it is a full namespace, and use it.
4236
4237 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4238 resolve it first by looking for it under your application namespace (for example
4239 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4240 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4241 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4242 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4243 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4244 you find that a good idea.
4245
4246 Examples:
4247
4248     package MyApp::Web;
4249
4250     __PACKAGE__->config(
4251       'psgi_middleware', [
4252         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4253         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4254         '+MyApp::Custom',  ## MyApp::Custom->wrap
4255       ],
4256     );
4257
4258 =item a scalar followed by a hashref
4259
4260 Just like the previous, except the following C<HashRef> is used as arguments
4261 to initialize the middleware object.
4262
4263     __PACKAGE__->config(
4264       'psgi_middleware', [
4265          'Session' => {store => 'File'},
4266     ]);
4267
4268 =back
4269
4270 Please see L<PSGI> for more on middleware.
4271
4272 =head1 ENCODING
4273
4274 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4275 and set to encode all body responses to UTF8 when possible and applicable.
4276 Following is documentation on this process.  If you are using an older
4277 version of L<Catalyst> you should review documentation for that version since
4278 a lot has changed.
4279
4280 By default encoding is now 'UTF-8'.  You may turn it off by setting
4281 the encoding configuration to undef.
4282
4283     MyApp->config(encoding => undef);
4284
4285 This is recommended for temporary backwards compatibility only.
4286
4287 Encoding is automatically applied when the content-type is set to
4288 a type that can be encoded.  Currently we encode when the content type
4289 matches the following regular expression:
4290
4291     $content_type =~ /^text|xml$|javascript$/
4292
4293 Encoding is set on the application, but it is copied to the context object
4294 so that you can override it on a request basis.
4295
4296 Be default we don't automatically encode 'application/json' since the most
4297 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4298 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4299 encoding issues.
4300
4301 If you are producing JSON response in an unconventional manner (such
4302 as via a template or manual strings) you should perform the UTF8 encoding
4303 manually as well such as to conform to the JSON specification.
4304
4305 NOTE: We also examine the value of $c->response->content_encoding.  If
4306 you set this (like for example 'gzip', and manually gzipping the body)
4307 we assume that you have done all the necessary encoding yourself, since
4308 we cannot encode the gzipped contents.  If you use a plugin like
4309 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4310 to have this function correctly  with the new UTF8 encoding code, or you
4311 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4312 a front end proxy.
4313
4314 =head2 Methods
4315
4316 =over 4
4317
4318 =item encoding
4319
4320 Returns an instance of an C<Encode> encoding
4321
4322     print $c->encoding->name
4323
4324 =item handle_unicode_encoding_exception ($exception_context)
4325
4326 Method called when decoding process for a request fails.
4327
4328 An C<$exception_context> hashref is provided to allow you to override the
4329 behaviour of your application when given data with incorrect encodings.
4330
4331 The default method throws exceptions in the case of invalid request parameters
4332 (resulting in a 500 error), but ignores errors in upload filenames.
4333
4334 The keys passed in the C<$exception_context> hash are:
4335
4336 =over
4337
4338 =item param_value
4339
4340 The value which was not able to be decoded.
4341
4342 =item error_msg
4343
4344 The exception received from L<Encode>.
4345
4346 =item encoding_step
4347
4348 What type of data was being decoded. Valid values are (currently)
4349 C<params> - for request parameters / arguments / captures
4350 and C<uploads> - for request upload filenames.
4351
4352 =back
4353
4354 =back
4355
4356 =head1 SUPPORT
4357
4358 IRC:
4359
4360     Join #catalyst on irc.perl.org.
4361
4362 Mailing Lists:
4363
4364     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4365     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4366
4367 Web:
4368
4369     http://catalyst.perl.org
4370
4371 Wiki:
4372
4373     http://dev.catalyst.perl.org
4374
4375 =head1 SEE ALSO
4376
4377 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4378
4379 =head2 L<Catalyst::Manual> - The Catalyst Manual
4380
4381 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4382
4383 =head2 L<Catalyst::Engine> - Core engine
4384
4385 =head2 L<Catalyst::Log> - Log class.
4386
4387 =head2 L<Catalyst::Request> - Request object
4388
4389 =head2 L<Catalyst::Response> - Response object
4390
4391 =head2 L<Catalyst::Test> - The test suite.
4392
4393 =head1 PROJECT FOUNDER
4394
4395 sri: Sebastian Riedel <sri@cpan.org>
4396
4397 =head1 CONTRIBUTORS
4398
4399 abw: Andy Wardley
4400
4401 acme: Leon Brocard <leon@astray.com>
4402
4403 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4404
4405 andrewalker: André Walker <andre@cpan.org>
4406
4407 Andrew Bramble
4408
4409 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4410
4411 Andrew Ruthven
4412
4413 andyg: Andy Grundman <andy@hybridized.org>
4414
4415 audreyt: Audrey Tang
4416
4417 bricas: Brian Cassidy <bricas@cpan.org>
4418
4419 Caelum: Rafael Kitover <rkitover@io.com>
4420
4421 chansen: Christian Hansen
4422
4423 chicks: Christopher Hicks
4424
4425 Chisel Wright C<pause@herlpacker.co.uk>
4426
4427 Danijel Milicevic C<me@danijel.de>
4428
4429 davewood: David Schmidt <davewood@cpan.org>
4430
4431 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4432
4433 David Naughton, C<naughton@umn.edu>
4434
4435 David E. Wheeler
4436
4437 dhoss: Devin Austin <dhoss@cpan.org>
4438
4439 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4440
4441 Drew Taylor
4442
4443 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4444
4445 esskar: Sascha Kiefer
4446
4447 fireartist: Carl Franks <cfranks@cpan.org>
4448
4449 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4450
4451 gabb: Danijel Milicevic
4452
4453 Gary Ashton Jones
4454
4455 Gavin Henry C<ghenry@perl.me.uk>
4456
4457 Geoff Richards
4458
4459 groditi: Guillermo Roditi <groditi@gmail.com>
4460
4461 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4462
4463 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4464
4465 jcamacho: Juan Camacho
4466
4467 jester: Jesse Sheidlower C<jester@panix.com>
4468
4469 jhannah: Jay Hannah <jay@jays.net>
4470
4471 Jody Belka
4472
4473 Johan Lindstrom
4474
4475 jon: Jon Schutz <jjschutz@cpan.org>
4476
4477 Jonathan Rockway C<< <jrockway@cpan.org> >>
4478
4479 Kieren Diment C<kd@totaldatasolution.com>
4480
4481 konobi: Scott McWhirter <konobi@cpan.org>
4482
4483 marcus: Marcus Ramberg <mramberg@cpan.org>
4484
4485 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4486
4487 mgrimes: Mark Grimes <mgrimes@cpan.org>
4488
4489 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4490
4491 mugwump: Sam Vilain
4492
4493 naughton: David Naughton
4494
4495 ningu: David Kamholz <dkamholz@cpan.org>
4496
4497 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4498
4499 numa: Dan Sully <daniel@cpan.org>
4500
4501 obra: Jesse Vincent
4502
4503 Octavian Rasnita
4504
4505 omega: Andreas Marienborg
4506
4507 Oleg Kostyuk <cub.uanic@gmail.com>
4508
4509 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4510
4511 rafl: Florian Ragwitz <rafl@debian.org>
4512
4513 random: Roland Lammel <lammel@cpan.org>
4514
4515 Robert Sedlacek C<< <rs@474.at> >>
4516
4517 SpiceMan: Marcel Montes
4518
4519 sky: Arthur Bergman
4520
4521 szbalint: Balint Szilakszi <szbalint@cpan.org>
4522
4523 t0m: Tomas Doran <bobtfish@bobtfish.net>
4524
4525 Ulf Edvinsson
4526
4527 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4528
4529 Viljo Marrandi C<vilts@yahoo.com>
4530
4531 Will Hawes C<info@whawes.co.uk>
4532
4533 willert: Sebastian Willert <willert@cpan.org>
4534
4535 wreis: Wallace Reis <wreis@cpan.org>
4536
4537 Yuval Kogman, C<nothingmuch@woobling.org>
4538
4539 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4540
4541 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4542
4543 Upasana <me@upasana.me>
4544
4545 John Napiorkowski (jnap) <jjnapiork@cpan.org>
4546
4547 =head1 COPYRIGHT
4548
4549 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
4550
4551 =head1 LICENSE
4552
4553 This library is free software. You can redistribute it and/or modify it under
4554 the same terms as Perl itself.
4555
4556 =cut
4557
4558 no Moose;
4559
4560 __PACKAGE__->meta->make_immutable;
4561
4562 1;