lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         $self->request_class->new($self->_build_request_constructor_args);
  67     },
  68     lazy => 1,
  69 );
  70 sub _build_request_constructor_args {
  71     my $self = shift;
  72     my %p = ( _log => $self->log );
  73     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  74     $p{data_handlers} = {$self->registered_data_handlers};
  75     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  76       if $self->config->{use_hash_multivalue_in_request};
  77     \%p;
  78 }
  79
  80 has response => (
  81     is => 'rw',
  82     default => sub {
  83         my $self = shift;
  84         $self->response_class->new($self->_build_response_constructor_args);
  85     },
  86     lazy => 1,
  87 );
  88 sub _build_response_constructor_args {
  89     return +{
  90       _log => $_[0]->log,
  91       encoding => $_[0]->encoding,
  92     };
  93 }
  94
  95 has namespace => (is => 'rw');
  96
  97 sub depth { scalar @{ shift->stack || [] }; }
  98 sub comp { shift->component(@_) }
  99
 100 sub req {
 101     my $self = shift; return $self->request(@_);
 102 }
 103 sub res {
 104     my $self = shift; return $self->response(@_);
 105 }
 106
 107 # For backwards compatibility
 108 sub finalize_output { shift->finalize_body(@_) };
 109
 110 # For statistics
 111 our $COUNT     = 1;
 112 our $START     = time;
 113 our $RECURSION = 1000;
 114 our $DETACH    = Catalyst::Exception::Detach->new;
 115 our $GO        = Catalyst::Exception::Go->new;
 116
 117 #I imagine that very few of these really need to be class variables. if any.
 118 #maybe we should just make them attributes with a default?
 119 __PACKAGE__->mk_classdata($_)
 120   for qw/components arguments dispatcher engine log dispatcher_class
 121   engine_loader context_class request_class response_class stats_class
 122   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 123   _data_handlers _encoding _encode_check/;
 124
 125 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 126 __PACKAGE__->request_class('Catalyst::Request');
 127 __PACKAGE__->response_class('Catalyst::Response');
 128 __PACKAGE__->stats_class('Catalyst::Stats');
 129 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 130
 131 # Remember to update this in Catalyst::Runtime as well!
 132 our $VERSION = '5.90079_005';
 133 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 134
 135 sub import {
 136     my ( $class, @arguments ) = @_;
 137
 138     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 139     # callers @ISA.
 140     return unless $class eq 'Catalyst';
 141
 142     my $caller = caller();
 143     return if $caller eq 'main';
 144
 145     my $meta = Moose::Meta::Class->initialize($caller);
 146     unless ( $caller->isa('Catalyst') ) {
 147         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 148         $meta->superclasses(@superclasses);
 149     }
 150     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 151     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 152
 153     unless( $meta->has_method('meta') ){
 154         if ($Moose::VERSION >= 1.15) {
 155             $meta->_add_meta_method('meta');
 156         }
 157         else {
 158             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 159         }
 160     }
 161
 162     $caller->arguments( [@arguments] );
 163     $caller->setup_home;
 164 }
 165
 166 sub _application { $_[0] }
 167
 168 =encoding UTF-8
 169
 170 =head1 NAME
 171
 172 Catalyst - The Elegant MVC Web Application Framework
 173
 174 =head1 SYNOPSIS
 175
 176 See the L<Catalyst::Manual> distribution for comprehensive
 177 documentation and tutorials.
 178
 179     # Install Catalyst::Devel for helpers and other development tools
 180     # use the helper to create a new application
 181     catalyst.pl MyApp
 182
 183     # add models, views, controllers
 184     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 185     script/myapp_create.pl view MyTemplate TT
 186     script/myapp_create.pl controller Search
 187
 188     # built in testserver -- use -r to restart automatically on changes
 189     # --help to see all available options
 190     script/myapp_server.pl
 191
 192     # command line testing interface
 193     script/myapp_test.pl /yada
 194
 195     ### in lib/MyApp.pm
 196     use Catalyst qw/-Debug/; # include plugins here as well
 197
 198     ### In lib/MyApp/Controller/Root.pm (autocreated)
 199     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 200         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 201         $c->stash->{template} = 'foo.tt'; # set the template
 202         # lookup something from db -- stash vars are passed to TT
 203         $c->stash->{data} =
 204           $c->model('Database::Foo')->search( { country => $args[0] } );
 205         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 206             $c->forward( 'bar' ); # process another action
 207             # do something else after forward returns
 208         }
 209     }
 210
 211     # The foo.tt TT template can use the stash data from the database
 212     [% WHILE (item = data.next) %]
 213         [% item.foo %]
 214     [% END %]
 215
 216     # called for /bar/of/soap, /bar/of/soap/10, etc.
 217     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 218
 219     # called after all actions are finished
 220     sub end : Action {
 221         my ( $self, $c ) = @_;
 222         if ( scalar @{ $c->error } ) { ... } # handle errors
 223         return if $c->res->body; # already have a response
 224         $c->forward( 'MyApp::View::TT' ); # render template
 225     }
 226
 227 See L<Catalyst::Manual::Intro> for additional information.
 228
 229 =head1 DESCRIPTION
 230
 231 Catalyst is a modern framework for making web applications without the
 232 pain usually associated with this process. This document is a reference
 233 to the main Catalyst application. If you are a new user, we suggest you
 234 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 235
 236 See L<Catalyst::Manual> for more documentation.
 237
 238 Catalyst plugins can be loaded by naming them as arguments to the "use
 239 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 240 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 241 C<My::Module>.
 242
 243     use Catalyst qw/My::Module/;
 244
 245 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 246 fully qualify the name by using a unary plus:
 247
 248     use Catalyst qw/
 249         My::Module
 250         +Fully::Qualified::Plugin::Name
 251     /;
 252
 253 Special flags like C<-Debug> can also be specified as
 254 arguments when Catalyst is loaded:
 255
 256     use Catalyst qw/-Debug My::Module/;
 257
 258 The position of plugins and flags in the chain is important, because
 259 they are loaded in the order in which they appear.
 260
 261 The following flags are supported:
 262
 263 =head2 -Debug
 264
 265 Enables debug output. You can also force this setting from the system
 266 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 267 settings override the application, with <MYAPP>_DEBUG having the highest
 268 priority.
 269
 270 This sets the log level to 'debug' and enables full debug output on the
 271 error screen. If you only want the latter, see L<< $c->debug >>.
 272
 273 =head2 -Home
 274
 275 Forces Catalyst to use a specific home directory, e.g.:
 276
 277     use Catalyst qw[-Home=/usr/mst];
 278
 279 This can also be done in the shell environment by setting either the
 280 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 281 is replaced with the uppercased name of your application, any "::" in
 282 the name will be replaced with underscores, e.g. MyApp::Web should use
 283 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 284
 285 If none of these are set, Catalyst will attempt to automatically detect the
 286 home directory. If you are working in a development environment, Catalyst
 287 will try and find the directory containing either Makefile.PL, Build.PL,
 288 dist.ini, or cpanfile. If the application has been installed into the system
 289 (i.e. you have done C<make install>), then Catalyst will use the path to your
 290 application module, without the .pm extension (e.g., /foo/MyApp if your
 291 application was installed at /foo/MyApp.pm)
 292
 293 =head2 -Log
 294
 295     use Catalyst '-Log=warn,fatal,error';
 296
 297 Specifies a comma-delimited list of log levels.
 298
 299 =head2 -Stats
 300
 301 Enables statistics collection and reporting.
 302
 303    use Catalyst qw/-Stats=1/;
 304
 305 You can also force this setting from the system environment with CATALYST_STATS
 306 or <MYAPP>_STATS. The environment settings override the application, with
 307 <MYAPP>_STATS having the highest priority.
 308
 309 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 310
 311 =head1 METHODS
 312
 313 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 314
 315 =head2 $c->action
 316
 317 Returns a L<Catalyst::Action> object for the current action, which
 318 stringifies to the action name. See L<Catalyst::Action>.
 319
 320 =head2 $c->namespace
 321
 322 Returns the namespace of the current action, i.e., the URI prefix
 323 corresponding to the controller of the current action. For example:
 324
 325     # in Controller::Foo::Bar
 326     $c->namespace; # returns 'foo/bar';
 327
 328 =head2 $c->request
 329
 330 =head2 $c->req
 331
 332 Returns the current L<Catalyst::Request> object, giving access to
 333 information about the current client request (including parameters,
 334 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 335
 336 =head2 REQUEST FLOW HANDLING
 337
 338 =head2 $c->forward( $action [, \@arguments ] )
 339
 340 =head2 $c->forward( $class, $method, [, \@arguments ] )
 341
 342 This is one way of calling another action (method) in the same or
 343 a different controller. You can also use C<< $self->my_method($c, @args) >>
 344 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 345 in a different controller.
 346 The main difference is that 'forward' uses some of the Catalyst request
 347 cycle overhead, including debugging, which may be useful to you. On the
 348 other hand, there are some complications to using 'forward', restrictions
 349 on values returned from 'forward', and it may not handle errors as you prefer.
 350 Whether you use 'forward' or not is up to you; it is not considered superior to
 351 the other ways to call a method.
 352
 353 'forward' calls  another action, by its private name. If you give a
 354 class name but no method, C<process()> is called. You may also optionally
 355 pass arguments in an arrayref. The action will receive the arguments in
 356 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 357 C<< $c->req->args >> will be restored to the previous values.
 358
 359 Any data C<return>ed from the action forwarded to, will be returned by the
 360 call to forward.
 361
 362     my $foodata = $c->forward('/foo');
 363     $c->forward('index');
 364     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 365     $c->forward('View::TT');
 366
 367 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 368 an C<< eval { } >> around the call (actually
 369 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 370 exceptions thrown by the called action non-fatal and pushing them onto
 371 $c->error instead. If you want C<die> to propagate you need to do something
 372 like:
 373
 374     $c->forward('foo');
 375     die join "\n", @{ $c->error } if @{ $c->error };
 376
 377 Or make sure to always return true values from your actions and write
 378 your code like this:
 379
 380     $c->forward('foo') || return;
 381
 382 Another note is that C<< $c->forward >> always returns a scalar because it
 383 actually returns $c->state which operates in a scalar context.
 384 Thus, something like:
 385
 386     return @array;
 387
 388 in an action that is forwarded to is going to return a scalar,
 389 i.e. how many items are in that array, which is probably not what you want.
 390 If you need to return an array then return a reference to it,
 391 or stash it like so:
 392
 393     $c->stash->{array} = \@array;
 394
 395 and access it from the stash.
 396
 397 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 398
 399 =cut
 400
 401 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 402
 403 =head2 $c->detach( $action [, \@arguments ] )
 404
 405 =head2 $c->detach( $class, $method, [, \@arguments ] )
 406
 407 =head2 $c->detach()
 408
 409 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 410 doesn't return to the previous action when processing is finished.
 411
 412 When called with no arguments it escapes the processing chain entirely.
 413
 414 =cut
 415
 416 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 417
 418 =head2 $c->visit( $action [, \@arguments ] )
 419
 420 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 421
 422 =head2 $c->visit( $class, $method, [, \@arguments ] )
 423
 424 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 425
 426 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 427 but does a full dispatch, instead of just calling the new C<$action> /
 428 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 429 you go to are called, just like a new request.
 430
 431 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 432 This means, for example, that C<< $c->action >> methods such as
 433 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 434 L<reverse|Catalyst::Action/reverse> return information for the visited action
 435 when they are invoked within the visited action.  This is different from the
 436 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 437 continues to use the $c->action object from the caller action even when
 438 invoked from the called action.
 439
 440 C<< $c->stash >> is kept unchanged.
 441
 442 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 443 allows you to "wrap" another action, just as it would have been called by
 444 dispatching from a URL, while the analogous
 445 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 446 transfer control to another action as if it had been reached directly from a URL.
 447
 448 =cut
 449
 450 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 451
 452 =head2 $c->go( $action [, \@arguments ] )
 453
 454 =head2 $c->go( $action [, \@captures, \@arguments ] )
 455
 456 =head2 $c->go( $class, $method, [, \@arguments ] )
 457
 458 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 459
 460 The relationship between C<go> and
 461 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 462 the relationship between
 463 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 464 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 465 C<< $c->go >> will perform a full dispatch on the specified action or method,
 466 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 467 C<go> escapes the processing of the current request chain on completion, and
 468 does not return to its caller.
 469
 470 @arguments are arguments to the final destination of $action. @captures are
 471 arguments to the intermediate steps, if any, on the way to the final sub of
 472 $action.
 473
 474 =cut
 475
 476 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 477
 478 =head2 $c->response
 479
 480 =head2 $c->res
 481
 482 Returns the current L<Catalyst::Response> object, see there for details.
 483
 484 =head2 $c->stash
 485
 486 Returns a hashref to the stash, which may be used to store data and pass
 487 it between components during a request. You can also set hash keys by
 488 passing arguments. The stash is automatically sent to the view. The
 489 stash is cleared at the end of a request; it cannot be used for
 490 persistent storage (for this you must use a session; see
 491 L<Catalyst::Plugin::Session> for a complete system integrated with
 492 Catalyst).
 493
 494     $c->stash->{foo} = $bar;
 495     $c->stash( { moose => 'majestic', qux => 0 } );
 496     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 497
 498     # stash is automatically passed to the view for use in a template
 499     $c->forward( 'MyApp::View::TT' );
 500
 501 The stash hash is currently stored in the PSGI C<$env> and is managed by
 502 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 503 the stash can be accessed in sub applications mounted under your main
 504 L<Catalyst> application.  For example if you delegate the response of an
 505 action to another L<Catalyst> application, that sub application will have
 506 access to all the stash keys of the main one, and if can of course add
 507 more keys of its own.  However those new keys will not 'bubble' back up
 508 to the main application.
 509
 510 For more information the best thing to do is to review the test case:
 511 t/middleware-stash.t in the distribution /t directory.
 512
 513 =cut
 514
 515 sub stash {
 516   my $c = shift;
 517   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 518 }
 519
 520 =head2 $c->error
 521
 522 =head2 $c->error($error, ...)
 523
 524 =head2 $c->error($arrayref)
 525
 526 Returns an arrayref containing error messages.  If Catalyst encounters an
 527 error while processing a request, it stores the error in $c->error.  This
 528 method should only be used to store fatal error messages.
 529
 530     my @error = @{ $c->error };
 531
 532 Add a new error.
 533
 534     $c->error('Something bad happened');
 535
 536 Calling this will always return an arrayref (if there are no errors it
 537 will be an empty arrayref.
 538
 539 =cut
 540
 541 sub error {
 542     my $c = shift;
 543     if ( $_[0] ) {
 544         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 545         croak @$error unless ref $c;
 546         push @{ $c->{error} }, @$error;
 547     }
 548     elsif ( defined $_[0] ) { $c->{error} = undef }
 549     return $c->{error} || [];
 550 }
 551
 552
 553 =head2 $c->state
 554
 555 Contains the return value of the last executed action.
 556 Note that << $c->state >> operates in a scalar context which means that all
 557 values it returns are scalar.
 558
 559 =head2 $c->clear_errors
 560
 561 Clear errors.  You probably don't want to clear the errors unless you are
 562 implementing a custom error screen.
 563
 564 This is equivalent to running
 565
 566     $c->error(0);
 567
 568 =cut
 569
 570 sub clear_errors {
 571     my $c = shift;
 572     $c->error(0);
 573 }
 574
 575 =head2 $c->has_errors
 576
 577 Returns true if you have errors
 578
 579 =cut
 580
 581 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 582
 583 =head2 $c->last_error
 584
 585 Returns the most recent error in the stack (the one most recently added...)
 586 or nothing if there are no errors.
 587
 588 =cut
 589
 590 sub last_error { my ($err, @errs) = @{shift->error}; return $err }
 591
 592 =head2 shift_errors
 593
 594 shifts the most recently added error off the error stack and returns if.  Returns
 595 nothing if there are nomore errors.
 596
 597 =cut
 598
 599 sub shift_errors {
 600     my ($self) = @_;
 601     my ($err, @errors) = @{$self->error};
 602     $self->{error} = \@errors;
 603     return $err;
 604 }
 605
 606 sub _comp_search_prefixes {
 607     my $c = shift;
 608     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 609 }
 610
 611 # search components given a name and some prefixes
 612 sub _comp_names_search_prefixes {
 613     my ( $c, $name, @prefixes ) = @_;
 614     my $appclass = ref $c || $c;
 615     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 616     $filter = qr/$filter/; # Compile regex now rather than once per loop
 617
 618     # map the original component name to the sub part that we will search against
 619     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 620         grep { /$filter/ } keys %{ $c->components };
 621
 622     # undef for a name will return all
 623     return keys %eligible if !defined $name;
 624
 625     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 626     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 627
 628     return @result if @result;
 629
 630     # if we were given a regexp to search against, we're done.
 631     return if $name->$_isa('Regexp');
 632
 633     # skip regexp fallback if configured
 634     return
 635         if $appclass->config->{disable_component_resolution_regex_fallback};
 636
 637     # regexp fallback
 638     $query  = qr/$name/i;
 639     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 640
 641     # no results? try against full names
 642     if( !@result ) {
 643         @result = grep { m{$query} } keys %eligible;
 644     }
 645
 646     # don't warn if we didn't find any results, it just might not exist
 647     if( @result ) {
 648         # Disgusting hack to work out correct method name
 649         my $warn_for = lc $prefixes[0];
 650         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 651            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 652            "component resolution is unreliable and unsafe.";
 653         my $short = $result[0];
 654         # remove the component namespace prefix
 655         $short =~ s/.*?(Model|Controller|View):://;
 656         my $shortmess = Carp::shortmess('');
 657         if ($shortmess =~ m#Catalyst/Plugin#) {
 658            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 659               "plugin's config";
 660         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 661            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 662               "component's config";
 663         } else {
 664            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 665               "but if you really wanted to search, pass in a regexp as the argument " .
 666               "like so: \$c->${warn_for}(qr/${name}/)";
 667         }
 668         $c->log->warn( "${msg}$shortmess" );
 669     }
 670
 671     return @result;
 672 }
 673
 674 # Find possible names for a prefix
 675 sub _comp_names {
 676     my ( $c, @prefixes ) = @_;
 677     my $appclass = ref $c || $c;
 678
 679     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 680
 681     my @names = map { s{$filter}{}; $_; }
 682         $c->_comp_names_search_prefixes( undef, @prefixes );
 683
 684     return @names;
 685 }
 686
 687 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 688 sub _filter_component {
 689     my ( $c, $comp, @args ) = @_;
 690
 691     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 692         return $comp->ACCEPT_CONTEXT( $c, @args );
 693     }
 694
 695     return $comp;
 696 }
 697
 698 =head2 COMPONENT ACCESSORS
 699
 700 =head2 $c->controller($name)
 701
 702 Gets a L<Catalyst::Controller> instance by name.
 703
 704     $c->controller('Foo')->do_stuff;
 705
 706 If the name is omitted, will return the controller for the dispatched
 707 action.
 708
 709 If you want to search for controllers, pass in a regexp as the argument.
 710
 711     # find all controllers that start with Foo
 712     my @foo_controllers = $c->controller(qr{^Foo});
 713
 714
 715 =cut
 716
 717 sub controller {
 718     my ( $c, $name, @args ) = @_;
 719
 720     my $appclass = ref($c) || $c;
 721     if( $name ) {
 722         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 723             my $comps = $c->components;
 724             my $check = $appclass."::Controller::".$name;
 725             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 726         }
 727         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 728         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 729         return $c->_filter_component( $result[ 0 ], @args );
 730     }
 731
 732     return $c->component( $c->action->class );
 733 }
 734
 735 =head2 $c->model($name)
 736
 737 Gets a L<Catalyst::Model> instance by name.
 738
 739     $c->model('Foo')->do_stuff;
 740
 741 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 742
 743 If the name is omitted, it will look for
 744  - a model object in $c->stash->{current_model_instance}, then
 745  - a model name in $c->stash->{current_model}, then
 746  - a config setting 'default_model', or
 747  - check if there is only one model, and return it if that's the case.
 748
 749 If you want to search for models, pass in a regexp as the argument.
 750
 751     # find all models that start with Foo
 752     my @foo_models = $c->model(qr{^Foo});
 753
 754 =cut
 755
 756 sub model {
 757     my ( $c, $name, @args ) = @_;
 758     my $appclass = ref($c) || $c;
 759     if( $name ) {
 760         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 761             my $comps = $c->components;
 762             my $check = $appclass."::Model::".$name;
 763             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 764         }
 765         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 766         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 767         return $c->_filter_component( $result[ 0 ], @args );
 768     }
 769
 770     if (ref $c) {
 771         return $c->stash->{current_model_instance}
 772           if $c->stash->{current_model_instance};
 773         return $c->model( $c->stash->{current_model} )
 774           if $c->stash->{current_model};
 775     }
 776     return $c->model( $appclass->config->{default_model} )
 777       if $appclass->config->{default_model};
 778
 779     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 780
 781     if( $rest ) {
 782         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 783         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 784         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 785         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 786         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 787     }
 788
 789     return $c->_filter_component( $comp );
 790 }
 791
 792
 793 =head2 $c->view($name)
 794
 795 Gets a L<Catalyst::View> instance by name.
 796
 797     $c->view('Foo')->do_stuff;
 798
 799 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 800
 801 If the name is omitted, it will look for
 802  - a view object in $c->stash->{current_view_instance}, then
 803  - a view name in $c->stash->{current_view}, then
 804  - a config setting 'default_view', or
 805  - check if there is only one view, and return it if that's the case.
 806
 807 If you want to search for views, pass in a regexp as the argument.
 808
 809     # find all views that start with Foo
 810     my @foo_views = $c->view(qr{^Foo});
 811
 812 =cut
 813
 814 sub view {
 815     my ( $c, $name, @args ) = @_;
 816
 817     my $appclass = ref($c) || $c;
 818     if( $name ) {
 819         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 820             my $comps = $c->components;
 821             my $check = $appclass."::View::".$name;
 822             if( exists $comps->{$check} ) {
 823                 return $c->_filter_component( $comps->{$check}, @args );
 824             }
 825             else {
 826                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 827             }
 828         }
 829         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 830         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 831         return $c->_filter_component( $result[ 0 ], @args );
 832     }
 833
 834     if (ref $c) {
 835         return $c->stash->{current_view_instance}
 836           if $c->stash->{current_view_instance};
 837         return $c->view( $c->stash->{current_view} )
 838           if $c->stash->{current_view};
 839     }
 840     return $c->view( $appclass->config->{default_view} )
 841       if $appclass->config->{default_view};
 842
 843     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 844
 845     if( $rest ) {
 846         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 847         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 848         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 849         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 850         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 851     }
 852
 853     return $c->_filter_component( $comp );
 854 }
 855
 856 =head2 $c->controllers
 857
 858 Returns the available names which can be passed to $c->controller
 859
 860 =cut
 861
 862 sub controllers {
 863     my ( $c ) = @_;
 864     return $c->_comp_names(qw/Controller C/);
 865 }
 866
 867 =head2 $c->models
 868
 869 Returns the available names which can be passed to $c->model
 870
 871 =cut
 872
 873 sub models {
 874     my ( $c ) = @_;
 875     return $c->_comp_names(qw/Model M/);
 876 }
 877
 878
 879 =head2 $c->views
 880
 881 Returns the available names which can be passed to $c->view
 882
 883 =cut
 884
 885 sub views {
 886     my ( $c ) = @_;
 887     return $c->_comp_names(qw/View V/);
 888 }
 889
 890 =head2 $c->comp($name)
 891
 892 =head2 $c->component($name)
 893
 894 Gets a component object by name. This method is not recommended,
 895 unless you want to get a specific component by full
 896 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 897 should be used instead.
 898
 899 If C<$name> is a regexp, a list of components matched against the full
 900 component name will be returned.
 901
 902 If Catalyst can't find a component by name, it will fallback to regex
 903 matching by default. To disable this behaviour set
 904 disable_component_resolution_regex_fallback to a true value.
 905
 906     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 907
 908 =cut
 909
 910 sub component {
 911     my ( $c, $name, @args ) = @_;
 912
 913     if( $name ) {
 914         my $comps = $c->components;
 915
 916         if( !ref $name ) {
 917             # is it the exact name?
 918             return $c->_filter_component( $comps->{ $name }, @args )
 919                        if exists $comps->{ $name };
 920
 921             # perhaps we just omitted "MyApp"?
 922             my $composed = ( ref $c || $c ) . "::${name}";
 923             return $c->_filter_component( $comps->{ $composed }, @args )
 924                        if exists $comps->{ $composed };
 925
 926             # search all of the models, views and controllers
 927             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 928             return $c->_filter_component( $comp, @args ) if $comp;
 929         }
 930
 931         return
 932             if $c->config->{disable_component_resolution_regex_fallback};
 933
 934         # This is here so $c->comp( '::M::' ) works
 935         my $query = ref $name ? $name : qr{$name}i;
 936
 937         my @result = grep { m{$query} } keys %{ $c->components };
 938         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 939
 940         if( $result[ 0 ] ) {
 941             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 942             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 943             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 944             return $c->_filter_component( $result[ 0 ], @args );
 945         }
 946
 947         # I would expect to return an empty list here, but that breaks back-compat
 948     }
 949
 950     # fallback
 951     return sort keys %{ $c->components };
 952 }
 953
 954 =head2 CLASS DATA AND HELPER CLASSES
 955
 956 =head2 $c->config
 957
 958 Returns or takes a hashref containing the application's configuration.
 959
 960     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 961
 962 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 963 like C<myapp.conf> in your applications home directory. See
 964 L<Catalyst::Plugin::ConfigLoader>.
 965
 966 =head3 Cascading configuration
 967
 968 The config method is present on all Catalyst components, and configuration
 969 will be merged when an application is started. Configuration loaded with
 970 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 971 followed by configuration in your top level C<MyApp> class. These two
 972 configurations are merged, and then configuration data whose hash key matches a
 973 component name is merged with configuration for that component.
 974
 975 The configuration for a component is then passed to the C<new> method when a
 976 component is constructed.
 977
 978 For example:
 979
 980     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 981     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 982
 983 will mean that C<MyApp::Model::Foo> receives the following data when
 984 constructed:
 985
 986     MyApp::Model::Foo->new({
 987         bar => 'baz',
 988         quux => 'frob',
 989         overrides => 'me',
 990     });
 991
 992 It's common practice to use a Moose attribute
 993 on the receiving component to access the config value.
 994
 995     package MyApp::Model::Foo;
 996
 997     use Moose;
 998
 999     # this attr will receive 'baz' at construction time
1000     has 'bar' => (
1001         is  => 'rw',
1002         isa => 'Str',
1003     );
1004
1005 You can then get the value 'baz' by calling $c->model('Foo')->bar
1006 (or $self->bar inside code in the model).
1007
1008 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1009 as a way of reading config within your code, as this B<will not> give you the
1010 correctly merged config back. You B<MUST> take the config values supplied to
1011 the constructor and use those instead.
1012
1013 =cut
1014
1015 around config => sub {
1016     my $orig = shift;
1017     my $c = shift;
1018
1019     croak('Setting config after setup has been run is not allowed.')
1020         if ( @_ and $c->setup_finished );
1021
1022     $c->$orig(@_);
1023 };
1024
1025 =head2 $c->log
1026
1027 Returns the logging object instance. Unless it is already set, Catalyst
1028 sets this up with a L<Catalyst::Log> object. To use your own log class,
1029 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1030 C<< __PACKAGE__->setup >>.
1031
1032  __PACKAGE__->log( MyLogger->new );
1033  __PACKAGE__->setup;
1034
1035 And later:
1036
1037     $c->log->info( 'Now logging with my own logger!' );
1038
1039 Your log class should implement the methods described in
1040 L<Catalyst::Log>.
1041
1042 =head2 has_encoding
1043
1044 Returned True if there's a valid encoding
1045
1046 =head2 clear_encoding
1047
1048 Clears the encoding for the current context
1049
1050 =head2 encoding
1051
1052 Sets or gets the application encoding.
1053
1054 =cut
1055
1056 sub has_encoding { shift->encoding ? 1:0 }
1057
1058 sub clear_encoding {
1059     my $c = shift;
1060     if(blessed $c) {
1061         $c->encoding(undef);
1062     } else {
1063         $c->debug->error("You can't clear encoding on the application");
1064     }
1065 }
1066
1067 sub encoding {
1068     my $c = shift;
1069     my $encoding;
1070
1071     if ( scalar @_ ) {
1072         # Let it be set to undef
1073         if (my $wanted = shift)  {
1074             $encoding = Encode::find_encoding($wanted)
1075               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1076             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1077         }
1078         else {
1079             binmode(STDERR);
1080         }
1081
1082         $encoding = ref $c
1083                   ? $c->{encoding} = $encoding
1084                   : $c->_encoding($encoding);
1085     } else {
1086       $encoding = ref $c && exists $c->{encoding}
1087                 ? $c->{encoding}
1088                 : $c->_encoding;
1089     }
1090
1091     return $encoding;
1092 }
1093
1094 =head2 $c->debug
1095
1096 Returns 1 if debug mode is enabled, 0 otherwise.
1097
1098 You can enable debug mode in several ways:
1099
1100 =over
1101
1102 =item By calling myapp_server.pl with the -d flag
1103
1104 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1105
1106 =item The -Debug option in your MyApp.pm
1107
1108 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1109
1110 =back
1111
1112 The first three also set the log level to 'debug'.
1113
1114 Calling C<< $c->debug(1) >> has no effect.
1115
1116 =cut
1117
1118 sub debug { 0 }
1119
1120 =head2 $c->dispatcher
1121
1122 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1123
1124 =head2 $c->engine
1125
1126 Returns the engine instance. See L<Catalyst::Engine>.
1127
1128
1129 =head2 UTILITY METHODS
1130
1131 =head2 $c->path_to(@path)
1132
1133 Merges C<@path> with C<< $c->config->{home} >> and returns a
1134 L<Path::Class::Dir> object. Note you can usually use this object as
1135 a filename, but sometimes you will have to explicitly stringify it
1136 yourself by calling the C<< ->stringify >> method.
1137
1138 For example:
1139
1140     $c->path_to( 'db', 'sqlite.db' );
1141
1142 =cut
1143
1144 sub path_to {
1145     my ( $c, @path ) = @_;
1146     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1147     if ( -d $path ) { return $path }
1148     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1149 }
1150
1151 sub plugin {
1152     my ( $class, $name, $plugin, @args ) = @_;
1153
1154     # See block comment in t/unit_core_plugin.t
1155     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1156
1157     $class->_register_plugin( $plugin, 1 );
1158
1159     eval { $plugin->import };
1160     $class->mk_classdata($name);
1161     my $obj;
1162     eval { $obj = $plugin->new(@args) };
1163
1164     if ($@) {
1165         Catalyst::Exception->throw( message =>
1166               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1167     }
1168
1169     $class->$name($obj);
1170     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1171       if $class->debug;
1172 }
1173
1174 =head2 MyApp->setup
1175
1176 Initializes the dispatcher and engine, loads any plugins, and loads the
1177 model, view, and controller components. You may also specify an array
1178 of plugins to load here, if you choose to not load them in the C<use
1179 Catalyst> line.
1180
1181     MyApp->setup;
1182     MyApp->setup( qw/-Debug/ );
1183
1184 B<Note:> You B<should not> wrap this method with method modifiers
1185 or bad things will happen - wrap the C<setup_finalize> method instead.
1186
1187 =cut
1188
1189 sub setup {
1190     my ( $class, @arguments ) = @_;
1191     croak('Running setup more than once')
1192         if ( $class->setup_finished );
1193
1194     unless ( $class->isa('Catalyst') ) {
1195
1196         Catalyst::Exception->throw(
1197             message => qq/'$class' does not inherit from Catalyst/ );
1198     }
1199
1200     if ( $class->arguments ) {
1201         @arguments = ( @arguments, @{ $class->arguments } );
1202     }
1203
1204     # Process options
1205     my $flags = {};
1206
1207     foreach (@arguments) {
1208
1209         if (/^-Debug$/) {
1210             $flags->{log} =
1211               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1212         }
1213         elsif (/^-(\w+)=?(.*)$/) {
1214             $flags->{ lc $1 } = $2;
1215         }
1216         else {
1217             push @{ $flags->{plugins} }, $_;
1218         }
1219     }
1220
1221     $class->setup_home( delete $flags->{home} );
1222
1223     $class->setup_log( delete $flags->{log} );
1224     $class->setup_plugins( delete $flags->{plugins} );
1225
1226     $class->setup_data_handlers();
1227     $class->setup_dispatcher( delete $flags->{dispatcher} );
1228     if (my $engine = delete $flags->{engine}) {
1229         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1230     }
1231     $class->setup_engine();
1232     $class->setup_stats( delete $flags->{stats} );
1233
1234     for my $flag ( sort keys %{$flags} ) {
1235
1236         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1237             &$code( $class, delete $flags->{$flag} );
1238         }
1239         else {
1240             $class->log->warn(qq/Unknown flag "$flag"/);
1241         }
1242     }
1243
1244     eval { require Catalyst::Devel; };
1245     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1246         $class->log->warn(<<"EOF");
1247 You are running an old script!
1248
1249   Please update by running (this will overwrite existing files):
1250     catalyst.pl -force -scripts $class
1251
1252   or (this will not overwrite existing files):
1253     catalyst.pl -scripts $class
1254
1255 EOF
1256     }
1257
1258     # Call plugins setup, this is stupid and evil.
1259     # Also screws C3 badly on 5.10, hack to avoid.
1260     {
1261         no warnings qw/redefine/;
1262         local *setup = sub { };
1263         $class->setup unless $Catalyst::__AM_RESTARTING;
1264     }
1265
1266     # If you are expecting configuration info as part of your setup, it needs
1267     # to get called here and below, since we need the above line to support
1268     # ConfigLoader based configs.
1269
1270     $class->setup_encoding();
1271     $class->setup_middleware();
1272
1273     # Initialize our data structure
1274     $class->components( {} );
1275
1276     $class->setup_components;
1277
1278     if ( $class->debug ) {
1279         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1280
1281         if (@plugins) {
1282             my $column_width = Catalyst::Utils::term_width() - 6;
1283             my $t = Text::SimpleTable->new($column_width);
1284             $t->row($_) for @plugins;
1285             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1286         }
1287
1288         my @middleware = map {
1289           ref $_ eq 'CODE' ?
1290             "Inline Coderef" :
1291               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1292                 || '')  } $class->registered_middlewares;
1293
1294         if (@middleware) {
1295             my $column_width = Catalyst::Utils::term_width() - 6;
1296             my $t = Text::SimpleTable->new($column_width);
1297             $t->row($_) for @middleware;
1298             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1299         }
1300
1301         my %dh = $class->registered_data_handlers;
1302         if (my @data_handlers = keys %dh) {
1303             my $column_width = Catalyst::Utils::term_width() - 6;
1304             my $t = Text::SimpleTable->new($column_width);
1305             $t->row($_) for @data_handlers;
1306             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1307         }
1308
1309         my $dispatcher = $class->dispatcher;
1310         my $engine     = $class->engine;
1311         my $home       = $class->config->{home};
1312
1313         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1314         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1315
1316         $home
1317           ? ( -d $home )
1318           ? $class->log->debug(qq/Found home "$home"/)
1319           : $class->log->debug(qq/Home "$home" doesn't exist/)
1320           : $class->log->debug(q/Couldn't find home/);
1321
1322         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1323         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1324         for my $comp ( sort keys %{ $class->components } ) {
1325             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1326             $t->row( $comp, $type );
1327         }
1328         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1329           if ( keys %{ $class->components } );
1330     }
1331
1332     # Add our self to components, since we are also a component
1333     if( $class->isa('Catalyst::Controller') ){
1334       $class->components->{$class} = $class;
1335     }
1336
1337     $class->setup_actions;
1338
1339     if ( $class->debug ) {
1340         my $name = $class->config->{name} || 'Application';
1341         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1342     }
1343
1344     if ($class->config->{case_sensitive}) {
1345         $class->log->warn($class . "->config->{case_sensitive} is set.");
1346         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1347     }
1348
1349     $class->setup_finalize;
1350
1351     # Flush the log for good measure (in case something turned off 'autoflush' early)
1352     $class->log->_flush() if $class->log->can('_flush');
1353
1354     return $class || 1; # Just in case someone named their Application 0...
1355 }
1356
1357 =head2 $app->setup_finalize
1358
1359 A hook to attach modifiers to. This method does not do anything except set the
1360 C<setup_finished> accessor.
1361
1362 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1363
1364 Example:
1365
1366     after setup_finalize => sub {
1367         my $app = shift;
1368
1369         ## do stuff here..
1370     };
1371
1372 =cut
1373
1374 sub setup_finalize {
1375     my ($class) = @_;
1376     $class->setup_finished(1);
1377 }
1378
1379 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1380
1381 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1382
1383 =head2 $c->uri_for( $action, [@captures, @args], \%query_values? )
1384
1385 Constructs an absolute L<URI> object based on the application root, the
1386 provided path, and the additional arguments and query parameters provided.
1387 When used as a string, provides a textual URI.  If you need more flexibility
1388 than this (i.e. the option to provide relative URIs etc.) see
1389 L<Catalyst::Plugin::SmartURI>.
1390
1391 If no arguments are provided, the URI for the current action is returned.
1392 To return the current action and also provide @args, use
1393 C<< $c->uri_for( $c->action, @args ) >>.
1394
1395 If the first argument is a string, it is taken as a public URI path relative
1396 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1397 relative to the application root (if it does). It is then merged with
1398 C<< $c->request->base >>; any C<@args> are appended as additional path
1399 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1400
1401 If the first argument is a L<Catalyst::Action> it represents an action which
1402 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1403 optional C<\@captures> argument (an arrayref) allows passing the captured
1404 variables that are needed to fill in the paths of Chained and Regex actions;
1405 once the path is resolved, C<uri_for> continues as though a path was
1406 provided, appending any arguments or parameters and creating an absolute
1407 URI.
1408
1409 The captures for the current request can be found in
1410 C<< $c->request->captures >>, and actions can be resolved using
1411 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1412 path, use C<< $c->uri_for_action >> instead.
1413
1414   # Equivalent to $c->req->uri
1415   $c->uri_for($c->action, $c->req->captures,
1416       @{ $c->req->args }, $c->req->params);
1417
1418   # For the Foo action in the Bar controller
1419   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1420
1421   # Path to a static resource
1422   $c->uri_for('/static/images/logo.png');
1423
1424 In general the scheme of the generated URI object will follow the incoming request
1425 however if your targeted action or action chain has the Scheme attribute it will
1426 use that instead.
1427
1428 =cut
1429
1430 sub uri_for {
1431     my ( $c, $path, @args ) = @_;
1432
1433     if ( $path->$_isa('Catalyst::Controller') ) {
1434         $path = $path->path_prefix;
1435         $path =~ s{/+\z}{};
1436         $path .= '/';
1437     }
1438
1439     undef($path) if (defined $path && $path eq '');
1440
1441     my $params =
1442       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1443
1444     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1445
1446     my @encoded_args = ();
1447     foreach my $arg (@args) {
1448       if(ref($arg)||'' eq 'ARRAY') {
1449         push @encoded_args, [map {
1450           my $encoded = encode_utf8 $_;
1451           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1452          $encoded;
1453         } @$arg];
1454       } else {
1455         push @encoded_args, do {
1456           my $encoded = encode_utf8 $arg;
1457           $encoded =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1458           $encoded;
1459         }
1460       }
1461     }
1462
1463     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1464     if ( $path->$_isa('Catalyst::Action') ) { # action object
1465         s|/|%2F|g for @encoded_args;
1466         my $captures = [ map { s|/|%2F|g; $_; }
1467                         ( scalar @encoded_args && ref $encoded_args[0] eq 'ARRAY'
1468                          ? @{ shift(@encoded_args) }
1469                          : ()) ];
1470
1471         my $action = $path;
1472         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1473         if( !@encoded_args && $action->number_of_args ) {
1474             my $expanded_action = $c->dispatcher->expand_action( $action );
1475             my $num_captures = $expanded_action->number_of_captures;
1476             unshift @encoded_args, splice @$captures, $num_captures;
1477         }
1478
1479        $path = $c->dispatcher->uri_for_action($action, $captures);
1480         if (not defined $path) {
1481             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1482                 if $c->debug;
1483             return undef;
1484         }
1485         $path = '/' if $path eq '';
1486     }
1487
1488     unshift(@encoded_args, $path);
1489
1490     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1491         my $namespace = $c->namespace;
1492         if (defined $path) { # cheesy hack to handle path '../foo'
1493            $namespace =~ s{(?:^|/)[^/]+$}{} while $encoded_args[0] =~ s{^\.\./}{};
1494         }
1495         unshift(@encoded_args, $namespace || '');
1496     }
1497
1498     # join args with '/', or a blank string
1499     my $args = join('/', grep { defined($_) } @encoded_args);
1500     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1501     $args =~ s!^/+!!;
1502
1503     my ($base, $class) = ('/', 'URI::_generic');
1504     if(blessed($c)) {
1505       $base = $c->req->base;
1506       if($target_action) {
1507         $target_action = $c->dispatcher->expand_action($target_action);
1508         if(my $s = $target_action->scheme) {
1509           $s = lc($s);
1510           $class = "URI::$s";
1511           $base->scheme($s);
1512         } else {
1513           $class = ref($base);
1514         }
1515       } else {
1516         $class = ref($base);
1517       }
1518
1519       $base =~ s{(?<!/)$}{/};
1520     }
1521
1522     my $query = '';
1523
1524     if (my @keys = keys %$params) {
1525       # somewhat lifted from URI::_query's query_form
1526       $query = '?'.join('&', map {
1527           my $val = $params->{$_};
1528           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1529           s/ /+/g;
1530           my $key = $_;
1531           $val = '' unless defined $val;
1532           (map {
1533               my $param = "$_";
1534               $param = encode_utf8($param);
1535               # using the URI::Escape pattern here so utf8 chars survive
1536               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1537               $param =~ s/ /+/g;
1538
1539               $key = encode_utf8($key);
1540               # using the URI::Escape pattern here so utf8 chars survive
1541               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1542               $key =~ s/ /+/g;
1543
1544               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1545       } @keys);
1546     }
1547
1548     my $res = bless(\"${base}${args}${query}", $class);
1549     $res;
1550 }
1551
1552 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1553
1554 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1555
1556 =over
1557
1558 =item $path
1559
1560 A private path to the Catalyst action you want to create a URI for.
1561
1562 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1563 >> and passing the resulting C<$action> and the remaining arguments to C<<
1564 $c->uri_for >>.
1565
1566 You can also pass in a Catalyst::Action object, in which case it is passed to
1567 C<< $c->uri_for >>.
1568
1569 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1570
1571 For example, if the action looks like:
1572
1573  package MyApp::Controller::Users;
1574
1575  sub lst : Path('the-list') {}
1576
1577 You can use:
1578
1579  $c->uri_for_action('/users/lst')
1580
1581 and it will create the URI /users/the-list.
1582
1583 =item \@captures_and_args?
1584
1585 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1586 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1587 to interpolate all the parameters in the URI.
1588
1589 =item @args?
1590
1591 Optional list of extra arguments - can be supplied in the
1592 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1593 code.
1594
1595 Your action can have zero, a fixed or a variable number of args (e.g.
1596 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1597
1598 =item \%query_values?
1599
1600 Optional array reference of query parameters to append. E.g.
1601
1602   { foo => 'bar' }
1603
1604 will generate
1605
1606   /rest/of/your/uri?foo=bar
1607
1608 =back
1609
1610 =cut
1611
1612 sub uri_for_action {
1613     my ( $c, $path, @args ) = @_;
1614     my $action = blessed($path)
1615       ? $path
1616       : $c->dispatcher->get_action_by_path($path);
1617     unless (defined $action) {
1618       croak "Can't find action for path '$path'";
1619     }
1620     return $c->uri_for( $action, @args );
1621 }
1622
1623 =head2 $c->welcome_message
1624
1625 Returns the Catalyst welcome HTML page.
1626
1627 =cut
1628
1629 sub welcome_message {
1630     my $c      = shift;
1631     my $name   = $c->config->{name};
1632     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1633     my $prefix = Catalyst::Utils::appprefix( ref $c );
1634     $c->response->content_type('text/html; charset=utf-8');
1635     return <<"EOF";
1636 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1637     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1638 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1639     <head>
1640     <meta http-equiv="Content-Language" content="en" />
1641     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1642         <title>$name on Catalyst $VERSION</title>
1643         <style type="text/css">
1644             body {
1645                 color: #000;
1646                 background-color: #eee;
1647             }
1648             div#content {
1649                 width: 640px;
1650                 margin-left: auto;
1651                 margin-right: auto;
1652                 margin-top: 10px;
1653                 margin-bottom: 10px;
1654                 text-align: left;
1655                 background-color: #ccc;
1656                 border: 1px solid #aaa;
1657             }
1658             p, h1, h2 {
1659                 margin-left: 20px;
1660                 margin-right: 20px;
1661                 font-family: verdana, tahoma, sans-serif;
1662             }
1663             a {
1664                 font-family: verdana, tahoma, sans-serif;
1665             }
1666             :link, :visited {
1667                     text-decoration: none;
1668                     color: #b00;
1669                     border-bottom: 1px dotted #bbb;
1670             }
1671             :link:hover, :visited:hover {
1672                     color: #555;
1673             }
1674             div#topbar {
1675                 margin: 0px;
1676             }
1677             pre {
1678                 margin: 10px;
1679                 padding: 8px;
1680             }
1681             div#answers {
1682                 padding: 8px;
1683                 margin: 10px;
1684                 background-color: #fff;
1685                 border: 1px solid #aaa;
1686             }
1687             h1 {
1688                 font-size: 0.9em;
1689                 font-weight: normal;
1690                 text-align: center;
1691             }
1692             h2 {
1693                 font-size: 1.0em;
1694             }
1695             p {
1696                 font-size: 0.9em;
1697             }
1698             p img {
1699                 float: right;
1700                 margin-left: 10px;
1701             }
1702             span#appname {
1703                 font-weight: bold;
1704                 font-size: 1.6em;
1705             }
1706         </style>
1707     </head>
1708     <body>
1709         <div id="content">
1710             <div id="topbar">
1711                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1712                     $VERSION</h1>
1713              </div>
1714              <div id="answers">
1715                  <p>
1716                  <img src="$logo" alt="Catalyst Logo" />
1717                  </p>
1718                  <p>Welcome to the  world of Catalyst.
1719                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1720                     framework will make web development something you had
1721                     never expected it to be: Fun, rewarding, and quick.</p>
1722                  <h2>What to do now?</h2>
1723                  <p>That really depends  on what <b>you</b> want to do.
1724                     We do, however, provide you with a few starting points.</p>
1725                  <p>If you want to jump right into web development with Catalyst
1726                     you might want to start with a tutorial.</p>
1727 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1728 </pre>
1729 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1730 <pre>
1731 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1732 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1733 </code></pre>
1734                  <h2>What to do next?</h2>
1735                  <p>Next it's time to write an actual application. Use the
1736                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1737                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1738                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1739                     they can save you a lot of work.</p>
1740                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1741                     <p>Also, be sure to check out the vast and growing
1742                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1743                     you are likely to find what you need there.
1744                     </p>
1745
1746                  <h2>Need help?</h2>
1747                  <p>Catalyst has a very active community. Here are the main places to
1748                     get in touch with us.</p>
1749                  <ul>
1750                      <li>
1751                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1752                      </li>
1753                      <li>
1754                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1755                      </li>
1756                      <li>
1757                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1758                      </li>
1759                  </ul>
1760                  <h2>In conclusion</h2>
1761                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1762                     as we enjoyed making it. Please contact us if you have ideas
1763                     for improvement or other feedback.</p>
1764              </div>
1765          </div>
1766     </body>
1767 </html>
1768 EOF
1769 }
1770
1771 =head2 run_options
1772
1773 Contains a hash of options passed from the application script, including
1774 the original ARGV the script received, the processed values from that
1775 ARGV and any extra arguments to the script which were not processed.
1776
1777 This can be used to add custom options to your application's scripts
1778 and setup your application differently depending on the values of these
1779 options.
1780
1781 =head1 INTERNAL METHODS
1782
1783 These methods are not meant to be used by end users.
1784
1785 =head2 $c->components
1786
1787 Returns a hash of components.
1788
1789 =head2 $c->context_class
1790
1791 Returns or sets the context class.
1792
1793 =head2 $c->counter
1794
1795 Returns a hashref containing coderefs and execution counts (needed for
1796 deep recursion detection).
1797
1798 =head2 $c->depth
1799
1800 Returns the number of actions on the current internal execution stack.
1801
1802 =head2 $c->dispatch
1803
1804 Dispatches a request to actions.
1805
1806 =cut
1807
1808 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1809
1810 =head2 $c->dispatcher_class
1811
1812 Returns or sets the dispatcher class.
1813
1814 =head2 $c->dump_these
1815
1816 Returns a list of 2-element array references (name, structure) pairs
1817 that will be dumped on the error page in debug mode.
1818
1819 =cut
1820
1821 sub dump_these {
1822     my $c = shift;
1823     [ Request => $c->req ],
1824     [ Response => $c->res ],
1825     [ Stash => $c->stash ],
1826     [ Config => $c->config ];
1827 }
1828
1829 =head2 $c->engine_class
1830
1831 Returns or sets the engine class.
1832
1833 =head2 $c->execute( $class, $coderef )
1834
1835 Execute a coderef in given class and catch exceptions. Errors are available
1836 via $c->error.
1837
1838 =cut
1839
1840 sub execute {
1841     my ( $c, $class, $code ) = @_;
1842     $class = $c->component($class) || $class;
1843     $c->state(0);
1844
1845     if ( $c->depth >= $RECURSION ) {
1846         my $action = $code->reverse();
1847         $action = "/$action" unless $action =~ /->/;
1848         my $error = qq/Deep recursion detected calling "${action}"/;
1849         $c->log->error($error);
1850         $c->error($error);
1851         $c->state(0);
1852         return $c->state;
1853     }
1854
1855     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1856
1857     push( @{ $c->stack }, $code );
1858
1859     no warnings 'recursion';
1860     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1861     #      I have no idea how, ergo $ret (which appears to fix the issue)
1862     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1863
1864     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1865
1866     my $last = pop( @{ $c->stack } );
1867
1868     if ( my $error = $@ ) {
1869         #rethow if this can be handled by middleware
1870         if ( $c->_handle_http_exception($error) ) {
1871             foreach my $err (@{$c->error}) {
1872                 $c->log->error($err);
1873             }
1874             $c->clear_errors;
1875             $c->log->_flush if $c->log->can('_flush');
1876
1877             $error->can('rethrow') ? $error->rethrow : croak $error;
1878         }
1879         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1880             $error->rethrow if $c->depth > 1;
1881         }
1882         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1883             $error->rethrow if $c->depth > 0;
1884         }
1885         else {
1886             unless ( ref $error ) {
1887                 no warnings 'uninitialized';
1888                 chomp $error;
1889                 my $class = $last->class;
1890                 my $name  = $last->name;
1891                 $error = qq/Caught exception in $class->$name "$error"/;
1892             }
1893             $c->error($error);
1894         }
1895         $c->state(0);
1896     }
1897     return $c->state;
1898 }
1899
1900 sub _stats_start_execute {
1901     my ( $c, $code ) = @_;
1902     my $appclass = ref($c) || $c;
1903     return if ( ( $code->name =~ /^_.*/ )
1904         && ( !$appclass->config->{show_internal_actions} ) );
1905
1906     my $action_name = $code->reverse();
1907     $c->counter->{$action_name}++;
1908
1909     my $action = $action_name;
1910     $action = "/$action" unless $action =~ /->/;
1911
1912     # determine if the call was the result of a forward
1913     # this is done by walking up the call stack and looking for a calling
1914     # sub of Catalyst::forward before the eval
1915     my $callsub = q{};
1916     for my $index ( 2 .. 11 ) {
1917         last
1918         if ( ( caller($index) )[0] eq 'Catalyst'
1919             && ( caller($index) )[3] eq '(eval)' );
1920
1921         if ( ( caller($index) )[3] =~ /forward$/ ) {
1922             $callsub = ( caller($index) )[3];
1923             $action  = "-> $action";
1924             last;
1925         }
1926     }
1927
1928     my $uid = $action_name . $c->counter->{$action_name};
1929
1930     # is this a root-level call or a forwarded call?
1931     if ( $callsub =~ /forward$/ ) {
1932         my $parent = $c->stack->[-1];
1933
1934         # forward, locate the caller
1935         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1936             $c->stats->profile(
1937                 begin  => $action,
1938                 parent => "$parent" . $c->counter->{"$parent"},
1939                 uid    => $uid,
1940             );
1941         }
1942         else {
1943
1944             # forward with no caller may come from a plugin
1945             $c->stats->profile(
1946                 begin => $action,
1947                 uid   => $uid,
1948             );
1949         }
1950     }
1951     else {
1952
1953         # root-level call
1954         $c->stats->profile(
1955             begin => $action,
1956             uid   => $uid,
1957         );
1958     }
1959     return $action;
1960
1961 }
1962
1963 sub _stats_finish_execute {
1964     my ( $c, $info ) = @_;
1965     $c->stats->profile( end => $info );
1966 }
1967
1968 =head2 $c->finalize
1969
1970 Finalizes the request.
1971
1972 =cut
1973
1974 sub finalize {
1975     my $c = shift;
1976
1977     for my $error ( @{ $c->error } ) {
1978         $c->log->error($error);
1979     }
1980
1981     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1982     # stuff like cometd and websockets
1983
1984     if($c->request->_has_io_fh) {
1985       $c->log_response;
1986       return;
1987     }
1988
1989     # Allow engine to handle finalize flow (for POE)
1990     my $engine = $c->engine;
1991     if ( my $code = $engine->can('finalize') ) {
1992         $engine->$code($c);
1993     }
1994     else {
1995
1996         $c->finalize_uploads;
1997
1998         # Error
1999         if ( $#{ $c->error } >= 0 ) {
2000             $c->finalize_error;
2001         }
2002
2003         $c->finalize_encoding;
2004         $c->finalize_headers unless $c->response->finalized_headers;
2005         $c->finalize_body;
2006     }
2007
2008     $c->log_response;
2009
2010     if ($c->use_stats) {
2011         my $elapsed = $c->stats->elapsed;
2012         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2013         $c->log->info(
2014             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2015     }
2016
2017     return $c->response->status;
2018 }
2019
2020 =head2 $c->finalize_body
2021
2022 Finalizes body.
2023
2024 =cut
2025
2026 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2027
2028 =head2 $c->finalize_cookies
2029
2030 Finalizes cookies.
2031
2032 =cut
2033
2034 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2035
2036 =head2 $c->finalize_error
2037
2038 Finalizes error.  If there is only one error in L</error> and it is an object that
2039 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2040 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2041 return the default error page (production mode).
2042
2043 =cut
2044
2045 sub finalize_error {
2046     my $c = shift;
2047     if($#{$c->error} > 0) {
2048         $c->engine->finalize_error( $c, @_ );
2049     } else {
2050         my ($error) = @{$c->error};
2051         if ( $c->_handle_http_exception($error) ) {
2052             # In the case where the error 'knows what it wants', becauses its PSGI
2053             # aware, just rethow and let middleware catch it
2054             $error->can('rethrow') ? $error->rethrow : croak $error;
2055         } else {
2056             $c->engine->finalize_error( $c, @_ )
2057         }
2058     }
2059 }
2060
2061 =head2 $c->finalize_headers
2062
2063 Finalizes headers.
2064
2065 =cut
2066
2067 sub finalize_headers {
2068     my $c = shift;
2069
2070     my $response = $c->response; #accessor calls can add up?
2071
2072     # Check if we already finalized headers
2073     return if $response->finalized_headers;
2074
2075     # Handle redirects
2076     if ( my $location = $response->redirect ) {
2077         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2078         $response->header( Location => $location );
2079     }
2080
2081     # Remove incorrectly added body and content related meta data when returning
2082     # an information response, or a response the is required to not include a body
2083
2084     $c->finalize_cookies;
2085
2086     # This currently is a NOOP but I don't want to remove it since I guess people
2087     # might have Response subclasses that use it for something... (JNAP)
2088     $c->response->finalize_headers();
2089
2090     # Done
2091     $response->finalized_headers(1);
2092 }
2093
2094 =head2 $c->finalize_encoding
2095
2096 Make sure your body is encoded properly IF you set an encoding.  By
2097 default the encoding is UTF-8 but you can disable it by explictly setting the
2098 encoding configuration value to undef.
2099
2100 We can only encode when the body is a scalar.  Methods for encoding via the
2101 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2102 are available).
2103
2104 See L</ENCODING>.
2105
2106 =cut
2107
2108 sub finalize_encoding {
2109     my $c = shift;
2110     my $res = $c->res || return;
2111
2112     # Warn if the set charset is different from the one you put into encoding.  We need
2113     # to do this early since encodable_response is false for this condition and we need
2114     # to match the debug output for backcompat (there's a test for this...) -JNAP
2115     if(
2116       $res->content_type_charset and $c->encoding and
2117       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2118     ) {
2119         my $ct = lc($res->content_type_charset);
2120         $c->log->debug("Catalyst encoding config is set to encode in '" .
2121             $c->encoding->mime_name .
2122             "', content type is '$ct', not encoding ");
2123     }
2124
2125     if(
2126       ($res->encodable_response) and
2127       (defined($res->body)) and
2128       (ref(\$res->body) eq 'SCALAR')
2129     ) {
2130         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2131
2132         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2133         # is false when the set charset is not the same as the encoding mimetype (maybe
2134         # confusing action at a distance here..
2135         # Don't try to set the charset if one already exists
2136         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2137           unless($c->res->content_type_charset);
2138     }
2139 }
2140
2141 =head2 $c->finalize_output
2142
2143 An alias for finalize_body.
2144
2145 =head2 $c->finalize_read
2146
2147 Finalizes the input after reading is complete.
2148
2149 =cut
2150
2151 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2152
2153 =head2 $c->finalize_uploads
2154
2155 Finalizes uploads. Cleans up any temporary files.
2156
2157 =cut
2158
2159 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2160
2161 =head2 $c->get_action( $action, $namespace )
2162
2163 Gets an action in a given namespace.
2164
2165 =cut
2166
2167 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2168
2169 =head2 $c->get_actions( $action, $namespace )
2170
2171 Gets all actions of a given name in a namespace and all parent
2172 namespaces.
2173
2174 =cut
2175
2176 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2177
2178 =head2 $app->handle_request( @arguments )
2179
2180 Called to handle each HTTP request.
2181
2182 =cut
2183
2184 sub handle_request {
2185     my ( $class, @arguments ) = @_;
2186
2187     # Always expect worst case!
2188     my $status = -1;
2189     try {
2190         if ($class->debug) {
2191             my $secs = time - $START || 1;
2192             my $av = sprintf '%.3f', $COUNT / $secs;
2193             my $time = localtime time;
2194             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2195         }
2196
2197         my $c = $class->prepare(@arguments);
2198         $c->dispatch;
2199         $status = $c->finalize;
2200     } catch {
2201         #rethow if this can be handled by middleware
2202         if ( $class->_handle_http_exception($_) ) {
2203             $_->can('rethrow') ? $_->rethrow : croak $_;
2204         }
2205         chomp(my $error = $_);
2206         $class->log->error(qq/Caught exception in engine "$error"/);
2207     };
2208
2209     $COUNT++;
2210
2211     if(my $coderef = $class->log->can('_flush')){
2212         $class->log->$coderef();
2213     }
2214     return $status;
2215 }
2216
2217 =head2 $class->prepare( @arguments )
2218
2219 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2220 etc.).
2221
2222 =cut
2223
2224 has _uploadtmp => (
2225     is => 'ro',
2226     predicate => '_has_uploadtmp',
2227 );
2228
2229 sub prepare {
2230     my ( $class, @arguments ) = @_;
2231
2232     # XXX
2233     # After the app/ctxt split, this should become an attribute based on something passed
2234     # into the application.
2235     $class->context_class( ref $class || $class ) unless $class->context_class;
2236
2237     my $uploadtmp = $class->config->{uploadtmp};
2238     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2239
2240     $c->response->_context($c);
2241
2242     #surely this is not the most efficient way to do things...
2243     $c->stats($class->stats_class->new)->enable($c->use_stats);
2244     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2245         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2246     }
2247
2248     try {
2249         # Allow engine to direct the prepare flow (for POE)
2250         if ( my $prepare = $c->engine->can('prepare') ) {
2251             $c->engine->$prepare( $c, @arguments );
2252         }
2253         else {
2254             $c->prepare_request(@arguments);
2255             $c->prepare_connection;
2256             $c->prepare_query_parameters;
2257             $c->prepare_headers; # Just hooks, no longer needed - they just
2258             $c->prepare_cookies; # cause the lazy attribute on req to build
2259             $c->prepare_path;
2260
2261             # Prepare the body for reading, either by prepare_body
2262             # or the user, if they are using $c->read
2263             $c->prepare_read;
2264
2265             # Parse the body unless the user wants it on-demand
2266             unless ( ref($c)->config->{parse_on_demand} ) {
2267                 $c->prepare_body;
2268             }
2269         }
2270         $c->prepare_action;
2271     }
2272     # VERY ugly and probably shouldn't rely on ->finalize actually working
2273     catch {
2274         # failed prepare is always due to an invalid request, right?
2275         $c->response->status(400);
2276         $c->response->content_type('text/plain');
2277         $c->response->body('Bad Request');
2278         # Note we call finalize and then die here, which escapes
2279         # finalize being called in the enclosing block..
2280         # It in fact couldn't be called, as we don't return $c..
2281         # This is a mess - but I'm unsure you can fix this without
2282         # breaking compat for people doing crazy things (we should set
2283         # the 400 and just return the ctx here IMO, letting finalize get called
2284         # above...
2285         $c->finalize;
2286         die $_;
2287     };
2288
2289     $c->log_request;
2290
2291     return $c;
2292 }
2293
2294 =head2 $c->prepare_action
2295
2296 Prepares action. See L<Catalyst::Dispatcher>.
2297
2298 =cut
2299
2300 sub prepare_action {
2301     my $c = shift;
2302     my $ret = $c->dispatcher->prepare_action( $c, @_);
2303
2304     if($c->encoding) {
2305         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2306           $_ = $c->_handle_param_unicode_decoding($_);
2307         }
2308     }
2309
2310     return $ret;
2311 }
2312
2313
2314 =head2 $c->prepare_body
2315
2316 Prepares message body.
2317
2318 =cut
2319
2320 sub prepare_body {
2321     my $c = shift;
2322
2323     return if $c->request->_has_body;
2324
2325     # Initialize on-demand data
2326     $c->engine->prepare_body( $c, @_ );
2327     $c->prepare_parameters;
2328     $c->prepare_uploads;
2329 }
2330
2331 =head2 $c->prepare_body_chunk( $chunk )
2332
2333 Prepares a chunk of data before sending it to L<HTTP::Body>.
2334
2335 See L<Catalyst::Engine>.
2336
2337 =cut
2338
2339 sub prepare_body_chunk {
2340     my $c = shift;
2341     $c->engine->prepare_body_chunk( $c, @_ );
2342 }
2343
2344 =head2 $c->prepare_body_parameters
2345
2346 Prepares body parameters.
2347
2348 =cut
2349
2350 sub prepare_body_parameters {
2351     my $c = shift;
2352     $c->request->prepare_body_parameters( $c, @_ );
2353 }
2354
2355 =head2 $c->prepare_connection
2356
2357 Prepares connection.
2358
2359 =cut
2360
2361 sub prepare_connection {
2362     my $c = shift;
2363     $c->request->prepare_connection($c);
2364 }
2365
2366 =head2 $c->prepare_cookies
2367
2368 Prepares cookies by ensuring that the attribute on the request
2369 object has been built.
2370
2371 =cut
2372
2373 sub prepare_cookies { my $c = shift; $c->request->cookies }
2374
2375 =head2 $c->prepare_headers
2376
2377 Prepares request headers by ensuring that the attribute on the request
2378 object has been built.
2379
2380 =cut
2381
2382 sub prepare_headers { my $c = shift; $c->request->headers }
2383
2384 =head2 $c->prepare_parameters
2385
2386 Prepares parameters.
2387
2388 =cut
2389
2390 sub prepare_parameters {
2391     my $c = shift;
2392     $c->prepare_body_parameters;
2393     $c->engine->prepare_parameters( $c, @_ );
2394 }
2395
2396 =head2 $c->prepare_path
2397
2398 Prepares path and base.
2399
2400 =cut
2401
2402 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2403
2404 =head2 $c->prepare_query_parameters
2405
2406 Prepares query parameters.
2407
2408 =cut
2409
2410 sub prepare_query_parameters {
2411     my $c = shift;
2412
2413     $c->engine->prepare_query_parameters( $c, @_ );
2414 }
2415
2416 =head2 $c->log_request
2417
2418 Writes information about the request to the debug logs.  This includes:
2419
2420 =over 4
2421
2422 =item * Request method, path, and remote IP address
2423
2424 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2425
2426 =item * Request parameters
2427
2428 =item * File uploads
2429
2430 =back
2431
2432 =cut
2433
2434 sub log_request {
2435     my $c = shift;
2436
2437     return unless $c->debug;
2438
2439     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2440     my $request = $dump->[1];
2441
2442     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2443     $method ||= '';
2444     $path = '/' unless length $path;
2445     $address ||= '';
2446
2447     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2448     $path = decode_utf8($path);
2449
2450     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2451
2452     $c->log_request_headers($request->headers);
2453
2454     if ( my $keywords = $request->query_keywords ) {
2455         $c->log->debug("Query keywords are: $keywords");
2456     }
2457
2458     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2459
2460     $c->log_request_uploads($request);
2461 }
2462
2463 =head2 $c->log_response
2464
2465 Writes information about the response to the debug logs by calling
2466 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2467
2468 =cut
2469
2470 sub log_response {
2471     my $c = shift;
2472
2473     return unless $c->debug;
2474
2475     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2476     my $response = $dump->[1];
2477
2478     $c->log_response_status_line($response);
2479     $c->log_response_headers($response->headers);
2480 }
2481
2482 =head2 $c->log_response_status_line($response)
2483
2484 Writes one line of information about the response to the debug logs.  This includes:
2485
2486 =over 4
2487
2488 =item * Response status code
2489
2490 =item * Content-Type header (if present)
2491
2492 =item * Content-Length header (if present)
2493
2494 =back
2495
2496 =cut
2497
2498 sub log_response_status_line {
2499     my ($c, $response) = @_;
2500
2501     $c->log->debug(
2502         sprintf(
2503             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2504             $response->status                            || 'unknown',
2505             $response->headers->header('Content-Type')   || 'unknown',
2506             $response->headers->header('Content-Length') || 'unknown'
2507         )
2508     );
2509 }
2510
2511 =head2 $c->log_response_headers($headers);
2512
2513 Hook method which can be wrapped by plugins to log the response headers.
2514 No-op in the default implementation.
2515
2516 =cut
2517
2518 sub log_response_headers {}
2519
2520 =head2 $c->log_request_parameters( query => {}, body => {} )
2521
2522 Logs request parameters to debug logs
2523
2524 =cut
2525
2526 sub log_request_parameters {
2527     my $c          = shift;
2528     my %all_params = @_;
2529
2530     return unless $c->debug;
2531
2532     my $column_width = Catalyst::Utils::term_width() - 44;
2533     foreach my $type (qw(query body)) {
2534         my $params = $all_params{$type};
2535         next if ! keys %$params;
2536         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2537         for my $key ( sort keys %$params ) {
2538             my $param = $params->{$key};
2539             my $value = defined($param) ? $param : '';
2540             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2541         }
2542         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2543     }
2544 }
2545
2546 =head2 $c->log_request_uploads
2547
2548 Logs file uploads included in the request to the debug logs.
2549 The parameter name, filename, file type, and file size are all included in
2550 the debug logs.
2551
2552 =cut
2553
2554 sub log_request_uploads {
2555     my $c = shift;
2556     my $request = shift;
2557     return unless $c->debug;
2558     my $uploads = $request->uploads;
2559     if ( keys %$uploads ) {
2560         my $t = Text::SimpleTable->new(
2561             [ 12, 'Parameter' ],
2562             [ 26, 'Filename' ],
2563             [ 18, 'Type' ],
2564             [ 9,  'Size' ]
2565         );
2566         for my $key ( sort keys %$uploads ) {
2567             my $upload = $uploads->{$key};
2568             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2569                 $t->row( $key, $u->filename, $u->type, $u->size );
2570             }
2571         }
2572         $c->log->debug( "File Uploads are:\n" . $t->draw );
2573     }
2574 }
2575
2576 =head2 $c->log_request_headers($headers);
2577
2578 Hook method which can be wrapped by plugins to log the request headers.
2579 No-op in the default implementation.
2580
2581 =cut
2582
2583 sub log_request_headers {}
2584
2585 =head2 $c->log_headers($type => $headers)
2586
2587 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2588
2589 =cut
2590
2591 sub log_headers {
2592     my $c       = shift;
2593     my $type    = shift;
2594     my $headers = shift;    # an HTTP::Headers instance
2595
2596     return unless $c->debug;
2597
2598     my $column_width = Catalyst::Utils::term_width() - 28;
2599     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2600     $headers->scan(
2601         sub {
2602             my ( $name, $value ) = @_;
2603             $t->row( $name, $value );
2604         }
2605     );
2606     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2607 }
2608
2609
2610 =head2 $c->prepare_read
2611
2612 Prepares the input for reading.
2613
2614 =cut
2615
2616 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2617
2618 =head2 $c->prepare_request
2619
2620 Prepares the engine request.
2621
2622 =cut
2623
2624 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2625
2626 =head2 $c->prepare_uploads
2627
2628 Prepares uploads.
2629
2630 =cut
2631
2632 sub prepare_uploads {
2633     my $c = shift;
2634     $c->engine->prepare_uploads( $c, @_ );
2635 }
2636
2637 =head2 $c->prepare_write
2638
2639 Prepares the output for writing.
2640
2641 =cut
2642
2643 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2644
2645 =head2 $c->request_class
2646
2647 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2648
2649 =head2 $c->response_class
2650
2651 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2652
2653 =head2 $c->read( [$maxlength] )
2654
2655 Reads a chunk of data from the request body. This method is designed to
2656 be used in a while loop, reading C<$maxlength> bytes on every call.
2657 C<$maxlength> defaults to the size of the request if not specified.
2658
2659 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2660 directly.
2661
2662 Warning: If you use read(), Catalyst will not process the body,
2663 so you will not be able to access POST parameters or file uploads via
2664 $c->request.  You must handle all body parsing yourself.
2665
2666 =cut
2667
2668 sub read { my $c = shift; return $c->request->read( @_ ) }
2669
2670 =head2 $c->run
2671
2672 Starts the engine.
2673
2674 =cut
2675
2676 sub run {
2677   my $app = shift;
2678   $app->_make_immutable_if_needed;
2679   $app->engine_loader->needs_psgi_engine_compat_hack ?
2680     $app->engine->run($app, @_) :
2681       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2682 }
2683
2684 sub _make_immutable_if_needed {
2685     my $class = shift;
2686     my $meta = find_meta($class);
2687     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2688     if (
2689         $meta->is_immutable
2690         && ! { $meta->immutable_options }->{replace_constructor}
2691         && $isa_ca
2692     ) {
2693         warn("You made your application class ($class) immutable, "
2694             . "but did not inline the\nconstructor. "
2695             . "This will break catalyst, as your app \@ISA "
2696             . "Class::Accessor(::Fast)?\nPlease pass "
2697             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2698     }
2699     unless ($meta->is_immutable) {
2700         # XXX - FIXME warning here as you should make your app immutable yourself.
2701         $meta->make_immutable(
2702             replace_constructor => 1,
2703         );
2704     }
2705 }
2706
2707 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2708
2709 Sets an action in a given namespace.
2710
2711 =cut
2712
2713 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2714
2715 =head2 $c->setup_actions($component)
2716
2717 Sets up actions for a component.
2718
2719 =cut
2720
2721 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2722
2723 =head2 $c->setup_components
2724
2725 This method is called internally to set up the application's components.
2726
2727 It finds modules by calling the L<locate_components> method, expands them to
2728 package names with the L<expand_component_module> method, and then installs
2729 each component into the application.
2730
2731 The C<setup_components> config option is passed to both of the above methods.
2732
2733 Installation of each component is performed by the L<setup_component> method,
2734 below.
2735
2736 =cut
2737
2738 sub setup_components {
2739     my $class = shift;
2740
2741     my $config  = $class->config->{ setup_components };
2742
2743     my @comps = $class->locate_components($config);
2744     my %comps = map { $_ => 1 } @comps;
2745
2746     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2747     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2748         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2749     ) if $deprecatedcatalyst_component_names;
2750
2751     for my $component ( @comps ) {
2752
2753         # We pass ignore_loaded here so that overlay files for (e.g.)
2754         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2755         # we know M::P::O found a file on disk so this is safe
2756
2757         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2758     }
2759
2760     for my $component (@comps) {
2761         my $instance = $class->components->{ $component } = $class->setup_component($component);
2762         my @expanded_components = $instance->can('expand_modules')
2763             ? $instance->expand_modules( $component, $config )
2764             : $class->expand_component_module( $component, $config );
2765         for my $component (@expanded_components) {
2766             next if $comps{$component};
2767             $class->components->{ $component } = $class->setup_component($component);
2768         }
2769     }
2770 }
2771
2772 =head2 $c->locate_components( $setup_component_config )
2773
2774 This method is meant to provide a list of component modules that should be
2775 setup for the application.  By default, it will use L<Module::Pluggable>.
2776
2777 Specify a C<setup_components> config option to pass additional options directly
2778 to L<Module::Pluggable>. To add additional search paths, specify a key named
2779 C<search_extra> as an array reference. Items in the array beginning with C<::>
2780 will have the application class name prepended to them.
2781
2782 =cut
2783
2784 sub locate_components {
2785     my $class  = shift;
2786     my $config = shift;
2787
2788     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2789     my $extra   = delete $config->{ search_extra } || [];
2790
2791     unshift @paths, @$extra;
2792
2793     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2794       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2795       %$config
2796     )->plugins } @paths;
2797
2798     return @comps;
2799 }
2800
2801 =head2 $c->expand_component_module( $component, $setup_component_config )
2802
2803 Components found by C<locate_components> will be passed to this method, which
2804 is expected to return a list of component (package) names to be set up.
2805
2806 =cut
2807
2808 sub expand_component_module {
2809     my ($class, $module) = @_;
2810     return Devel::InnerPackage::list_packages( $module );
2811 }
2812
2813 =head2 $c->setup_component
2814
2815 =cut
2816
2817 sub setup_component {
2818     my( $class, $component ) = @_;
2819
2820     unless ( $component->can( 'COMPONENT' ) ) {
2821         return $component;
2822     }
2823
2824     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2825     my $config = $class->config->{ $suffix } || {};
2826     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2827     # methods also pass it. local to avoid pointlessly shitting in config
2828     # for the debug screen, as $component is already the key name.
2829     local $config->{catalyst_component_name} = $component;
2830
2831     my $instance = eval { $component->COMPONENT( $class, $config ); };
2832
2833     if ( my $error = $@ ) {
2834         chomp $error;
2835         Catalyst::Exception->throw(
2836             message => qq/Couldn't instantiate component "$component", "$error"/
2837         );
2838     }
2839
2840     unless (blessed $instance) {
2841         my $metaclass = Moose::Util::find_meta($component);
2842         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2843         my $component_method_from = $method_meta->associated_metaclass->name;
2844         my $value = defined($instance) ? $instance : 'undef';
2845         Catalyst::Exception->throw(
2846             message =>
2847             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2848         );
2849     }
2850     return $instance;
2851 }
2852
2853 =head2 $c->setup_dispatcher
2854
2855 Sets up dispatcher.
2856
2857 =cut
2858
2859 sub setup_dispatcher {
2860     my ( $class, $dispatcher ) = @_;
2861
2862     if ($dispatcher) {
2863         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2864     }
2865
2866     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2867         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2868     }
2869
2870     unless ($dispatcher) {
2871         $dispatcher = $class->dispatcher_class;
2872     }
2873
2874     load_class($dispatcher);
2875
2876     # dispatcher instance
2877     $class->dispatcher( $dispatcher->new );
2878 }
2879
2880 =head2 $c->setup_engine
2881
2882 Sets up engine.
2883
2884 =cut
2885
2886 sub engine_class {
2887     my ($class, $requested_engine) = @_;
2888
2889     if (!$class->engine_loader || $requested_engine) {
2890         $class->engine_loader(
2891             Catalyst::EngineLoader->new({
2892                 application_name => $class,
2893                 (defined $requested_engine
2894                      ? (catalyst_engine_class => $requested_engine) : ()),
2895             }),
2896         );
2897     }
2898
2899     $class->engine_loader->catalyst_engine_class;
2900 }
2901
2902 sub setup_engine {
2903     my ($class, $requested_engine) = @_;
2904
2905     my $engine = do {
2906         my $loader = $class->engine_loader;
2907
2908         if (!$loader || $requested_engine) {
2909             $loader = Catalyst::EngineLoader->new({
2910                 application_name => $class,
2911                 (defined $requested_engine
2912                      ? (requested_engine => $requested_engine) : ()),
2913             }),
2914
2915             $class->engine_loader($loader);
2916         }
2917
2918         $loader->catalyst_engine_class;
2919     };
2920
2921     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2922     return if $class->loading_psgi_file;
2923
2924     load_class($engine);
2925
2926     if ($ENV{MOD_PERL}) {
2927         my $apache = $class->engine_loader->auto;
2928
2929         my $meta = find_meta($class);
2930         my $was_immutable = $meta->is_immutable;
2931         my %immutable_options = $meta->immutable_options;
2932         $meta->make_mutable if $was_immutable;
2933
2934         $meta->add_method(handler => sub {
2935             my $r = shift;
2936             my $psgi_app = $class->_finalized_psgi_app;
2937             $apache->call_app($r, $psgi_app);
2938         });
2939
2940         $meta->make_immutable(%immutable_options) if $was_immutable;
2941     }
2942
2943     $class->engine( $engine->new );
2944
2945     return;
2946 }
2947
2948 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2949 ## build in server support (back compat support for pre psgi port behavior).
2950 ## This is so that we don't build a new psgi app for each request when using
2951 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2952
2953 sub _finalized_psgi_app {
2954     my ($app) = @_;
2955
2956     unless ($app->_psgi_app) {
2957         my $psgi_app = $app->_setup_psgi_app;
2958         $app->_psgi_app($psgi_app);
2959     }
2960
2961     return $app->_psgi_app;
2962 }
2963
2964 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2965 ## home directory and load that and return it (just assume it is doing the
2966 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2967 ## in default_middleware and return it ( this is for backward compatibility
2968 ## with pre psgi port behavior ).
2969
2970 sub _setup_psgi_app {
2971     my ($app) = @_;
2972
2973     for my $home (Path::Class::Dir->new($app->config->{home})) {
2974         my $psgi_file = $home->file(
2975             Catalyst::Utils::appprefix($app) . '.psgi',
2976         );
2977
2978         next unless -e $psgi_file;
2979
2980         # If $psgi_file calls ->setup_engine, it's doing so to load
2981         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2982         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2983         # anyway. So set a flag (ick) that tells setup_engine not to populate
2984         # $c->engine or do any other things we might regret.
2985
2986         $app->loading_psgi_file(1);
2987         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2988         $app->loading_psgi_file(0);
2989
2990         return $psgi_app
2991             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2992
2993         warn <<"EOW";
2994 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2995
2996 Its content has been ignored. Please consult the Catalyst::Upgrading
2997 documentation on how to upgrade from Catalyst::Engine::PSGI.
2998 EOW
2999     }
3000
3001     return $app->apply_default_middlewares($app->psgi_app);
3002 }
3003
3004 =head2 $c->apply_default_middlewares
3005
3006 Adds the following L<Plack> middlewares to your application, since they are
3007 useful and commonly needed:
3008
3009 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3010 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3011 is smart enough to conditionally apply itself).
3012
3013 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3014 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3015 an indication that your server is running behind a proxy frontend.  However in
3016 2014 this is often not the case.  We preserve this code for backwards compatibility
3017 however I B<highly> recommend that if you are running the server behind a front
3018 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3019 setting to true for your environment configurations that run behind a proxy.  This
3020 way if you change your front end proxy address someday your code would inexplicably
3021 stop working as expected.
3022
3023 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3024 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3025 $ENV{SCRIPT_NAME}.
3026
3027 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3028 adding via C<registered_middleware> rather than this method.
3029
3030 If you are using Lighttp or IIS6 you may wish to apply these middlewares.  In
3031 general this is no longer a common case but we have this here for backward
3032 compatibility.
3033
3034 =cut
3035
3036
3037 sub apply_default_middlewares {
3038     my ($app, $psgi_app) = @_;
3039
3040     # Don't add this conditional IF we are explicitly saying we want the
3041     # frontend proxy support.  We don't need it here since if that is the
3042     # case it will be always loaded in the default_middleware.
3043
3044     unless($app->config->{using_frontend_proxy}) {
3045       $psgi_app = Plack::Middleware::Conditional->wrap(
3046           $psgi_app,
3047           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3048           condition => sub {
3049               my ($env) = @_;
3050               return if $app->config->{ignore_frontend_proxy};
3051               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3052           },
3053       );
3054     }
3055
3056     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3057     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3058     $psgi_app = Plack::Middleware::Conditional->wrap(
3059         $psgi_app,
3060         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3061         condition => sub {
3062             my ($env) = @_;
3063             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3064             return unless $1 < 4.23;
3065             1;
3066         },
3067     );
3068
3069     # we're applying this unconditionally as the middleware itself already makes
3070     # sure it doesn't fuck things up if it's not running under one of the right
3071     # IIS versions
3072     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3073
3074     # And another IIS issue, this time with IIS7.
3075     $psgi_app = Plack::Middleware::Conditional->wrap(
3076         $psgi_app,
3077         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3078         condition => sub {
3079             my ($env) = @_;
3080             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3081         },
3082     );
3083
3084     return $psgi_app;
3085 }
3086
3087 =head2 App->psgi_app
3088
3089 =head2 App->to_app
3090
3091 Returns a PSGI application code reference for the catalyst application
3092 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3093 method called.  We do however apply C<registered_middleware> since those are
3094 integral to how L<Catalyst> functions.  Also, unlike starting your application
3095 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3096 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3097 scripts in your $HOME directory.
3098
3099 B<NOTE> C<apply_default_middlewares> was orginally created when the first PSGI
3100 port was done for v5.90000.  These are middlewares that are added to achieve
3101 backward compatibility with older applications.  If you start your application
3102 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3103 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3104 automatically.  This was done so that pre and post PSGI port applications would
3105 work the same way.
3106
3107 This is what you want to be using to retrieve the PSGI application code
3108 reference of your Catalyst application for use in a custom F<.psgi> or in your
3109 own created server modules.
3110
3111 =cut
3112
3113 *to_app = \&psgi_app;
3114
3115 sub psgi_app {
3116     my ($app) = @_;
3117     my $psgi = $app->engine->build_psgi_app($app);
3118     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3119 }
3120
3121 =head2 $c->setup_home
3122
3123 Sets up the home directory.
3124
3125 =cut
3126
3127 sub setup_home {
3128     my ( $class, $home ) = @_;
3129
3130     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3131         $home = $env;
3132     }
3133
3134     $home ||= Catalyst::Utils::home($class);
3135
3136     if ($home) {
3137         #I remember recently being scolded for assigning config values like this
3138         $class->config->{home} ||= $home;
3139         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3140     }
3141 }
3142
3143 =head2 $c->setup_encoding
3144
3145 Sets up the input/output encoding. See L<ENCODING>
3146
3147 =cut
3148
3149 sub setup_encoding {
3150     my $c = shift;
3151     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3152         # Ok, so the user has explicitly said "I don't want encoding..."
3153         return;
3154     } else {
3155       my $enc = defined($c->config->{encoding}) ?
3156         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3157       $c->encoding($enc);
3158     }
3159 }
3160
3161 =head2 handle_unicode_encoding_exception
3162
3163 Hook to let you customize how encoding errors are handled.  By default
3164 we just throw an exception.  Receives a hashref of debug information.
3165 Example:
3166
3167     $c->handle_unicode_encoding_exception({
3168         param_value => $value,
3169         error_msg => $_,
3170             encoding_step => 'params',
3171         });
3172
3173 =cut
3174
3175 sub handle_unicode_encoding_exception {
3176     my ( $self, $exception_ctx ) = @_;
3177     die $exception_ctx->{error_msg};
3178 }
3179
3180 # Some unicode helpers cargo culted from the old plugin.  These could likely
3181 # be neater.
3182
3183 sub _handle_unicode_decoding {
3184     my ( $self, $value ) = @_;
3185
3186     return unless defined $value;
3187
3188     ## I think this mess is to support the old nested
3189     if ( ref $value eq 'ARRAY' ) {
3190         foreach ( @$value ) {
3191             $_ = $self->_handle_unicode_decoding($_);
3192         }
3193         return $value;
3194     }
3195     elsif ( ref $value eq 'HASH' ) {
3196         foreach (keys %$value) {
3197             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3198             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3199
3200             # If the key was encoded we now have two (the original and current so
3201             # delete the original.
3202             delete $value->{$_} if $_ ne $encoded_key;
3203         }
3204         return $value;
3205     }
3206     else {
3207         return $self->_handle_param_unicode_decoding($value);
3208     }
3209 }
3210
3211 sub _handle_param_unicode_decoding {
3212     my ( $self, $value ) = @_;
3213     return unless defined $value; # not in love with just ignoring undefs - jnap
3214
3215     my $enc = $self->encoding;
3216     return try {
3217       $enc->decode( $value, $self->_encode_check );
3218     }
3219     catch {
3220         $self->handle_unicode_encoding_exception({
3221             param_value => $value,
3222             error_msg => $_,
3223             encoding_step => 'params',
3224         });
3225     };
3226 }
3227
3228 =head2 $c->setup_log
3229
3230 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3231 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3232 log to.
3233
3234 This method also installs a C<debug> method that returns a true value into the
3235 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3236 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3237
3238 Note that if the log has already been setup, by either a previous call to
3239 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3240 that this method won't actually set up the log object.
3241
3242 =cut
3243
3244 sub setup_log {
3245     my ( $class, $levels ) = @_;
3246
3247     $levels ||= '';
3248     $levels =~ s/^\s+//;
3249     $levels =~ s/\s+$//;
3250     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3251
3252     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3253     if ( defined $env_debug ) {
3254         $levels{debug} = 1 if $env_debug; # Ugly!
3255         delete($levels{debug}) unless $env_debug;
3256     }
3257
3258     unless ( $class->log ) {
3259         $class->log( Catalyst::Log->new(keys %levels) );
3260     }
3261
3262     if ( $levels{debug} ) {
3263         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3264         $class->log->debug('Debug messages enabled');
3265     }
3266 }
3267
3268 =head2 $c->setup_plugins
3269
3270 Sets up plugins.
3271
3272 =cut
3273
3274 =head2 $c->setup_stats
3275
3276 Sets up timing statistics class.
3277
3278 =cut
3279
3280 sub setup_stats {
3281     my ( $class, $stats ) = @_;
3282
3283     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3284
3285     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3286     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3287         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3288         $class->log->debug('Statistics enabled');
3289     }
3290 }
3291
3292
3293 =head2 $c->registered_plugins
3294
3295 Returns a sorted list of the plugins which have either been stated in the
3296 import list.
3297
3298 If passed a given plugin name, it will report a boolean value indicating
3299 whether or not that plugin is loaded.  A fully qualified name is required if
3300 the plugin name does not begin with C<Catalyst::Plugin::>.
3301
3302  if ($c->registered_plugins('Some::Plugin')) {
3303      ...
3304  }
3305
3306 =cut
3307
3308 {
3309
3310     sub registered_plugins {
3311         my $proto = shift;
3312         return sort keys %{ $proto->_plugins } unless @_;
3313         my $plugin = shift;
3314         return 1 if exists $proto->_plugins->{$plugin};
3315         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3316     }
3317
3318     sub _register_plugin {
3319         my ( $proto, $plugin, $instant ) = @_;
3320         my $class = ref $proto || $proto;
3321
3322         load_class( $plugin );
3323         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3324             if $plugin->isa( 'Catalyst::Component' );
3325         my $plugin_meta = Moose::Meta::Class->create($plugin);
3326         if (!$plugin_meta->has_method('new')
3327             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3328             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3329         }
3330         if (!$instant && !$proto->_plugins->{$plugin}) {
3331             my $meta = Class::MOP::get_metaclass_by_name($class);
3332             $meta->superclasses($plugin, $meta->superclasses);
3333         }
3334         $proto->_plugins->{$plugin} = 1;
3335         return $class;
3336     }
3337
3338     sub _default_plugins { return qw() }
3339
3340     sub setup_plugins {
3341         my ( $class, $plugins ) = @_;
3342
3343         $class->_plugins( {} ) unless $class->_plugins;
3344         $plugins = [ grep {
3345             m/Unicode::Encoding/ ? do {
3346                 $class->log->warn(
3347                     'Unicode::Encoding plugin is auto-applied,'
3348                     . ' please remove this from your appclass'
3349                     . ' and make sure to define "encoding" config'
3350                 );
3351                 unless (exists $class->config->{'encoding'}) {
3352                   $class->config->{'encoding'} = 'UTF-8';
3353                 }
3354                 () }
3355                 : $_
3356         } @$plugins ];
3357         push @$plugins, $class->_default_plugins;
3358         $plugins = Data::OptList::mkopt($plugins || []);
3359
3360         my @plugins = map {
3361             [ Catalyst::Utils::resolve_namespace(
3362                   $class . '::Plugin',
3363                   'Catalyst::Plugin', $_->[0]
3364               ),
3365               $_->[1],
3366             ]
3367          } @{ $plugins };
3368
3369         for my $plugin ( reverse @plugins ) {
3370             load_class($plugin->[0], $plugin->[1]);
3371             my $meta = find_meta($plugin->[0]);
3372             next if $meta && $meta->isa('Moose::Meta::Role');
3373
3374             $class->_register_plugin($plugin->[0]);
3375         }
3376
3377         my @roles =
3378             map  { $_->[0]->name, $_->[1] }
3379             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3380             map  { [find_meta($_->[0]), $_->[1]] }
3381             @plugins;
3382
3383         Moose::Util::apply_all_roles(
3384             $class => @roles
3385         ) if @roles;
3386     }
3387 }
3388
3389 =head2 default_middleware
3390
3391 Returns a list of instantiated PSGI middleware objects which is the default
3392 middleware that is active for this application (taking any configuration
3393 options into account, excluding your custom added middleware via the C<psgi_middleware>
3394 configuration option).  You can override this method if you wish to change
3395 the default middleware (although do so at risk since some middleware is vital
3396 to application function.)
3397
3398 The current default middleware list is:
3399
3400       Catalyst::Middleware::Stash
3401       Plack::Middleware::HTTPExceptions
3402       Plack::Middleware::RemoveRedundantBody
3403       Plack::Middleware::FixMissingBodyInRedirect
3404       Plack::Middleware::ContentLength
3405       Plack::Middleware::MethodOverride
3406       Plack::Middleware::Head
3407
3408 If the configuration setting C<using_frontend_proxy> is true we add:
3409
3410       Plack::Middleware::ReverseProxy
3411
3412 If the configuration setting C<using_frontend_proxy_path> is true we add:
3413
3414       Plack::Middleware::ReverseProxyPath
3415
3416 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3417 L<Catalyst> distribution so if you want to use this option you should add it to
3418 your project distribution file.
3419
3420 These middlewares will be added at L</setup_middleware> during the
3421 L</setup> phase of application startup.
3422
3423 =cut
3424
3425 sub default_middleware {
3426     my $class = shift;
3427     my @mw = (
3428       Catalyst::Middleware::Stash->new,
3429       Plack::Middleware::HTTPExceptions->new,
3430       Plack::Middleware::RemoveRedundantBody->new,
3431       Plack::Middleware::FixMissingBodyInRedirect->new,
3432       Plack::Middleware::ContentLength->new,
3433       Plack::Middleware::MethodOverride->new,
3434       Plack::Middleware::Head->new);
3435
3436     if($class->config->{using_frontend_proxy}) {
3437         push @mw, Plack::Middleware::ReverseProxy->new;
3438     }
3439
3440     if($class->config->{using_frontend_proxy_path}) {
3441         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3442             push @mw, Plack::Middleware::ReverseProxyPath->new;
3443         } else {
3444           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3445         }
3446     }
3447
3448     return @mw;
3449 }
3450
3451 =head2 registered_middlewares
3452
3453 Read only accessor that returns an array of all the middleware in the order
3454 that they were added (which is the REVERSE of the order they will be applied).
3455
3456 The values returned will be either instances of L<Plack::Middleware> or of a
3457 compatible interface, or a coderef, which is assumed to be inlined middleware
3458
3459 =head2 setup_middleware (?@middleware)
3460
3461 Read configuration information stored in configuration key C<psgi_middleware> or
3462 from passed @args.
3463
3464 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3465 to use it to enable L<Plack::Middleware>
3466
3467 This method is automatically called during 'setup' of your application, so
3468 you really don't need to invoke it.  However you may do so if you find the idea
3469 of loading middleware via configuration weird :).  For example:
3470
3471     package MyApp;
3472
3473     use Catalyst;
3474
3475     __PACKAGE__->setup_middleware('Head');
3476     __PACKAGE__->setup;
3477
3478 When we read middleware definitions from configuration, we reverse the list
3479 which sounds odd but is likely how you expect it to work if you have prior
3480 experience with L<Plack::Builder> or if you previously used the plugin
3481 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3482
3483 So basically your middleware handles an incoming request from the first
3484 registered middleware, down and handles the response from the last middleware
3485 up.
3486
3487 =cut
3488
3489 sub registered_middlewares {
3490     my $class = shift;
3491     if(my $middleware = $class->_psgi_middleware) {
3492         my @mw = ($class->default_middleware, @$middleware);
3493
3494         if($class->config->{using_frontend_proxy}) {
3495           push @mw, Plack::Middleware::ReverseProxy->new;
3496         }
3497
3498         return @mw;
3499     } else {
3500         die "You cannot call ->registered_middlewares until middleware has been setup";
3501     }
3502 }
3503
3504 sub setup_middleware {
3505     my $class = shift;
3506     my @middleware_definitions;
3507
3508     # If someone calls this method you can add middleware with args.  However if its
3509     # called without an arg we need to setup the configuration middleware.
3510     if(@_) {
3511       @middleware_definitions = reverse(@_);
3512     } else {
3513       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3514         unless $class->config->{__configured_from_psgi_middleware};
3515       $class->config->{__configured_from_psgi_middleware} = 1; # Only do this once, just in case some people call setup over and over...
3516     }
3517
3518     my @middleware = ();
3519     while(my $next = shift(@middleware_definitions)) {
3520         if(ref $next) {
3521             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3522                 push @middleware, $next;
3523             } elsif(ref $next eq 'CODE') {
3524                 push @middleware, $next;
3525             } elsif(ref $next eq 'HASH') {
3526                 my $namespace = shift @middleware_definitions;
3527                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3528                 push @middleware, $mw;
3529             } else {
3530               die "I can't handle middleware definition ${\ref $next}";
3531             }
3532         } else {
3533           my $mw = $class->Catalyst::Utils::build_middleware($next);
3534           push @middleware, $mw;
3535         }
3536     }
3537
3538     my @existing = @{$class->_psgi_middleware || []};
3539     $class->_psgi_middleware([@middleware,@existing,]);
3540 }
3541
3542 =head2 registered_data_handlers
3543
3544 A read only copy of registered Data Handlers returned as a Hash, where each key
3545 is a content type and each value is a subref that attempts to decode that content
3546 type.
3547
3548 =head2 setup_data_handlers (?@data_handler)
3549
3550 Read configuration information stored in configuration key C<data_handlers> or
3551 from passed @args.
3552
3553 See under L</CONFIGURATION> information regarding C<data_handlers>.
3554
3555 This method is automatically called during 'setup' of your application, so
3556 you really don't need to invoke it.
3557
3558 =head2 default_data_handlers
3559
3560 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3561 only two default data handlers, for 'application/json' and an alternative to
3562 'application/x-www-form-urlencoded' which supposed nested form parameters via
3563 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3564
3565 The 'application/json' data handler is used to parse incoming JSON into a Perl
3566 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3567 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3568 JSON decoder, and has the smallest dependency impact.
3569
3570 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3571 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3572 order to get the best performance.  You should add either to your dependency
3573 list (Makefile.PL, dist.ini, cpanfile, etc.)
3574
3575 =cut
3576
3577 sub registered_data_handlers {
3578     my $class = shift;
3579     if(my $data_handlers = $class->_data_handlers) {
3580         return %$data_handlers;
3581     } else {
3582         $class->setup_data_handlers;
3583         return $class->registered_data_handlers;
3584     }
3585 }
3586
3587 sub setup_data_handlers {
3588     my ($class, %data_handler_callbacks) = @_;
3589     %data_handler_callbacks = (
3590       %{$class->default_data_handlers},
3591       %{$class->config->{'data_handlers'}||+{}},
3592       %data_handler_callbacks);
3593
3594     $class->_data_handlers(\%data_handler_callbacks);
3595 }
3596
3597 sub default_data_handlers {
3598     my ($class) = @_;
3599     return +{
3600       'application/x-www-form-urlencoded' => sub {
3601           my ($fh, $req) = @_;
3602           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3603           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3604             ->can('build_cgi_struct')->($params);
3605       },
3606       'application/json' => sub {
3607           my ($fh, $req) = @_;
3608           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
3609           my $slurped;
3610           return eval {
3611             local $/;
3612             $slurped = $fh->getline;
3613             $parser->can("decode_json")->($slurped);
3614           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
3615         },
3616     };
3617 }
3618
3619 sub _handle_http_exception {
3620     my ( $self, $error ) = @_;
3621     if (
3622            !$self->config->{always_catch_http_exceptions}
3623         && blessed $error
3624         && (
3625             $error->can('as_psgi')
3626             || (   $error->can('code')
3627                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
3628         )
3629       )
3630     {
3631         return 1;
3632     }
3633 }
3634
3635 =head2 $c->stack
3636
3637 Returns an arrayref of the internal execution stack (actions that are
3638 currently executing).
3639
3640 =head2 $c->stats
3641
3642 Returns the current timing statistics object. By default Catalyst uses
3643 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3644 L<< stats_class|/"$c->stats_class" >>.
3645
3646 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3647 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3648 profile explicitly, although MyApp.pm still won't profile nor output anything
3649 by itself.
3650
3651 =head2 $c->stats_class
3652
3653 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3654
3655 =head2 $c->use_stats
3656
3657 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3658
3659 Note that this is a static method, not an accessor and should be overridden
3660 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3661
3662 =cut
3663
3664 sub use_stats { 0 }
3665
3666
3667 =head2 $c->write( $data )
3668
3669 Writes $data to the output stream. When using this method directly, you
3670 will need to manually set the C<Content-Length> header to the length of
3671 your output data, if known.
3672
3673 =cut
3674
3675 sub write {
3676     my $c = shift;
3677
3678     # Finalize headers if someone manually writes output (for compat)
3679     $c->finalize_headers;
3680
3681     return $c->response->write( @_ );
3682 }
3683
3684 =head2 version
3685
3686 Returns the Catalyst version number. Mostly useful for "powered by"
3687 messages in template systems.
3688
3689 =cut
3690
3691 sub version { return $Catalyst::VERSION }
3692
3693 =head1 CONFIGURATION
3694
3695 There are a number of 'base' config variables which can be set:
3696
3697 =over
3698
3699 =item *
3700
3701 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
3702 rethrows errors conforming to the interface described by
3703 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
3704 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
3705
3706 =item *
3707
3708 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3709
3710 =item *
3711
3712 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3713
3714 =item *
3715
3716 C<disable_component_resolution_regex_fallback> - Turns
3717 off the deprecated component resolution functionality so
3718 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3719 are called then regex search will not be attempted on string values and
3720 instead C<undef> will be returned.
3721
3722 =item *
3723
3724 C<home> - The application home directory. In an uninstalled application,
3725 this is the top level application directory. In an installed application,
3726 this will be the directory containing C<< MyApp.pm >>.
3727
3728 =item *
3729
3730 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3731
3732 =item *
3733
3734 C<name> - The name of the application in debug messages and the debug and
3735 welcome screens
3736
3737 =item *
3738
3739 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3740 until it is accessed. This allows you to (for example) check authentication (and reject
3741 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3742
3743 =item *
3744
3745 C<root> - The root directory for templates. Usually this is just a
3746 subdirectory of the home directory, but you can set it to change the
3747 templates to a different directory.
3748
3749 =item *
3750
3751 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3752 namespaces from which components will be loaded (and constructed and stored in
3753 C<< $c->components >>).
3754
3755 =item *
3756
3757 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3758 to be shown in hit debug tables in the test server.
3759
3760 =item *
3761
3762 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3763 variable should be used for determining the request path.
3764
3765 Most web server environments pass the requested path to the application using environment variables,
3766 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3767 exposed as C<< $c->request->base >>) and the request path below that base.
3768
3769 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3770 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3771
3772 =over
3773
3774 =item use_request_uri_for_path => 0
3775
3776 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3777 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3778 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3779 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3780
3781 However this method has the major disadvantage that it is impossible to correctly decode some elements
3782 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3783 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3784 can't distinguish / vs %2F in paths (in addition to other encoded values).
3785
3786 =item use_request_uri_for_path => 1
3787
3788 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3789 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3790 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3791
3792 Given that this method of path resolution is provably more correct, it is recommended that you use
3793 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3794 aware of the implications of not being able to handle encoded URI paths correctly.
3795
3796 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3797 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3798 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3799 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3800 C<< $c->request->base >> will be incorrect.
3801
3802 =back
3803
3804 =item *
3805
3806 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3807
3808 =item *
3809
3810 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
3811 installed, otherwise log an error).  This is useful if your application is not running on the
3812 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
3813 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
3814 This has been done since not all people need this feature and we wish to restrict the growth of
3815 L<Catalyst> dependencies.
3816
3817 =item *
3818
3819 C<encoding> - See L</ENCODING>
3820
3821 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
3822 value to undef.
3823
3824 =item *
3825
3826 C<abort_chain_on_error_fix>
3827
3828 When there is an error in an action chain, the default behavior is to continue
3829 processing the remaining actions and then catch the error upon chain end.  This
3830 can lead to running actions when the application is in an unexpected state.  If
3831 you have this issue, setting this config value to true will promptly exit a
3832 chain when there is an error raised in any action (thus terminating the chain
3833 early.)
3834
3835 use like:
3836
3837     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3838
3839 In the future this might become the default behavior.
3840
3841 =item *
3842
3843 C<use_hash_multivalue_in_request>
3844
3845 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3846 and C<parameters> return a hashref where values might be scalar or an arrayref
3847 depending on the incoming data.  In many cases this can be undesirable as it
3848 leads one to writing defensive code like the following:
3849
3850     my ($val) = ref($c->req->parameters->{a}) ?
3851       @{$c->req->parameters->{a}} :
3852         $c->req->parameters->{a};
3853
3854 Setting this configuration item to true will make L<Catalyst> populate the
3855 attributes underlying these methods with an instance of L<Hash::MultiValue>
3856 which is used by L<Plack::Request> and others to solve this very issue.  You
3857 may prefer this behavior to the default, if so enable this option (be warned
3858 if you enable it in a legacy application we are not sure if it is completely
3859 backwardly compatible).
3860
3861 =item *
3862
3863 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3864
3865 =item *
3866
3867 C<data_handlers> - See L<DATA HANDLERS>.
3868
3869 =back
3870
3871 =head1 EXCEPTIONS
3872
3873 Generally when you throw an exception inside an Action (or somewhere in
3874 your stack, such as in a model that an Action is calling) that exception
3875 is caught by Catalyst and unless you either catch it yourself (via eval
3876 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3877 will eventually reach L</finalize_errors> and return either the debugging
3878 error stack page, or the default error page.  However, if your exception
3879 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3880 instead rethrow it so that it can be handled by that middleware (which
3881 is part of the default middleware).  For example this would allow
3882
3883     use HTTP::Throwable::Factory 'http_throw';
3884
3885     sub throws_exception :Local {
3886       my ($self, $c) = @_;
3887
3888       http_throw(SeeOther => { location =>
3889         $c->uri_for($self->action_for('redirect')) });
3890
3891     }
3892
3893 =head1 INTERNAL ACTIONS
3894
3895 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3896 C<_ACTION>, and C<_END>. These are by default not shown in the private
3897 action table, but you can make them visible with a config parameter.
3898
3899     MyApp->config(show_internal_actions => 1);
3900
3901 =head1 ON-DEMAND PARSER
3902
3903 The request body is usually parsed at the beginning of a request,
3904 but if you want to handle input yourself, you can enable on-demand
3905 parsing with a config parameter.
3906
3907     MyApp->config(parse_on_demand => 1);
3908
3909 =head1 PROXY SUPPORT
3910
3911 Many production servers operate using the common double-server approach,
3912 with a lightweight frontend web server passing requests to a larger
3913 backend server. An application running on the backend server must deal
3914 with two problems: the remote user always appears to be C<127.0.0.1> and
3915 the server's hostname will appear to be C<localhost> regardless of the
3916 virtual host that the user connected through.
3917
3918 Catalyst will automatically detect this situation when you are running
3919 the frontend and backend servers on the same machine. The following
3920 changes are made to the request.
3921
3922     $c->req->address is set to the user's real IP address, as read from
3923     the HTTP X-Forwarded-For header.
3924
3925     The host value for $c->req->base and $c->req->uri is set to the real
3926     host, as read from the HTTP X-Forwarded-Host header.
3927
3928 Additionally, you may be running your backend application on an insecure
3929 connection (port 80) while your frontend proxy is running under SSL.  If there
3930 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3931 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3932 be created properly.
3933
3934 In the case of passing in:
3935
3936     X-Forwarded-Port: 443
3937
3938 All calls to C<uri_for> will result in an https link, as is expected.
3939
3940 Obviously, your web server must support these headers for this to work.
3941
3942 In a more complex server farm environment where you may have your
3943 frontend proxy server(s) on different machines, you will need to set a
3944 configuration option to tell Catalyst to read the proxied data from the
3945 headers.
3946
3947     MyApp->config(using_frontend_proxy => 1);
3948
3949 If you do not wish to use the proxy support at all, you may set:
3950
3951     MyApp->config(ignore_frontend_proxy => 0);
3952
3953 =head2 Note about psgi files
3954
3955 Note that if you supply your own .psgi file, calling
3956 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3957
3958 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3959 in your psgi, for example:
3960
3961     builder {
3962         enable "Plack::Middleware::ReverseProxy";
3963         MyApp->psgi_app
3964     };
3965
3966 This will unconditionally add the ReverseProxy support, or you need to call
3967 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3968 apply the support depending upon your config).
3969
3970 See L<Catalyst::PSGI> for more information.
3971
3972 =head1 THREAD SAFETY
3973
3974 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3975 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3976 believe the Catalyst core to be thread-safe.
3977
3978 If you plan to operate in a threaded environment, remember that all other
3979 modules you are using must also be thread-safe. Some modules, most notably
3980 L<DBD::SQLite>, are not thread-safe.
3981
3982 =head1 DATA HANDLERS
3983
3984 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3985 form parameters and URL search query fields.  However it has become common
3986 for various alternative content types to be PUT or POSTed to your controllers
3987 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3988 XML and other content types when communicating with an application server.  In
3989 order to better support this use case, L<Catalyst> defines a global configuration
3990 option, C<data_handlers>, which lets you associate a content type with a coderef
3991 that parses that content type into something Perl can readily access.
3992
3993     package MyApp::Web;
3994
3995     use Catalyst;
3996     use JSON::Maybe;
3997
3998     __PACKAGE__->config(
3999       data_handlers => {
4000         'application/json' => sub { local $/; decode_json $_->getline },
4001       },
4002       ## Any other configuration.
4003     );
4004
4005     __PACKAGE__->setup;
4006
4007 By default L<Catalyst> comes with a generic JSON data handler similar to the
4008 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4009 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4010 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4011 or dist.ini, cpanfile, etc.)
4012
4013 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4014 (matched against the incoming request type using a regexp such as to be case
4015 insensitive) and whose values are coderefs that receive a localized version of
4016 C<$_> which is a filehandle object pointing to received body.
4017
4018 This feature is considered an early access release and we reserve the right
4019 to alter the interface in order to provide a performant and secure solution to
4020 alternative request body content.  Your reports welcomed!
4021
4022 =head1 PSGI MIDDLEWARE
4023
4024 You can define middleware, defined as L<Plack::Middleware> or a compatible
4025 interface in configuration.  Your middleware definitions are in the form of an
4026 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4027 with details to follow:
4028
4029     package MyApp::Web;
4030
4031     use Catalyst;
4032     use Plack::Middleware::StackTrace;
4033
4034     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4035
4036     __PACKAGE__->config(
4037       'psgi_middleware', [
4038         'Debug',
4039         '+MyApp::Custom',
4040         $stacktrace_middleware,
4041         'Session' => {store => 'File'},
4042         sub {
4043           my $app = shift;
4044           return sub {
4045             my $env = shift;
4046             $env->{myapp.customkey} = 'helloworld';
4047             $app->($env);
4048           },
4049         },
4050       ],
4051     );
4052
4053     __PACKAGE__->setup;
4054
4055 So the general form is:
4056
4057     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4058
4059 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4060 the order listed (to make it function similarly to L<Plack::Builder>:
4061
4062 Alternatively, you may also define middleware by calling the L</setup_middleware>
4063 package method:
4064
4065     package MyApp::Web;
4066
4067     use Catalyst;
4068
4069     __PACKAGE__->setup_middleware( \@middleware_definitions);
4070     __PACKAGE__->setup;
4071
4072 In the case where you do both (use 'setup_middleware' and configuration) the
4073 package call to setup_middleware will be applied earlier (in other words its
4074 middleware will wrap closer to the application).  Keep this in mind since in
4075 some cases the order of middleware is important.
4076
4077 The two approaches are not exclusive.
4078
4079 =over 4
4080
4081 =item Middleware Object
4082
4083 An already initialized object that conforms to the L<Plack::Middleware>
4084 specification:
4085
4086     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4087
4088     __PACKAGE__->config(
4089       'psgi_middleware', [
4090         $stacktrace_middleware,
4091       ]);
4092
4093
4094 =item coderef
4095
4096 A coderef that is an inlined middleware:
4097
4098     __PACKAGE__->config(
4099       'psgi_middleware', [
4100         sub {
4101           my $app = shift;
4102           return sub {
4103             my $env = shift;
4104             if($env->{PATH_INFO} =~m/forced/) {
4105               Plack::App::File
4106                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4107                 ->call($env);
4108             } else {
4109               return $app->($env);
4110             }
4111          },
4112       },
4113     ]);
4114
4115
4116
4117 =item a scalar
4118
4119 We assume the scalar refers to a namespace after normalizing it using the
4120 following rules:
4121
4122 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4123 is assumed to be 'as is', and we just install and use the middleware.
4124
4125 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4126 (the package name of your Catalyst application subclass), we also assume then
4127 that it is a full namespace, and use it.
4128
4129 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4130 resolve it first by looking for it under your application namespace (for example
4131 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4132 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4133 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4134 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4135 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4136 you find that a good idea.
4137
4138 Examples:
4139
4140     package MyApp::Web;
4141
4142     __PACKAGE__->config(
4143       'psgi_middleware', [
4144         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4145         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4146         '+MyApp::Custom',  ## MyApp::Custom->wrap
4147       ],
4148     );
4149
4150 =item a scalar followed by a hashref
4151
4152 Just like the previous, except the following C<HashRef> is used as arguments
4153 to initialize the middleware object.
4154
4155     __PACKAGE__->config(
4156       'psgi_middleware', [
4157          'Session' => {store => 'File'},
4158     ]);
4159
4160 =back
4161
4162 Please see L<PSGI> for more on middleware.
4163
4164 =head1 ENCODING
4165
4166 On request, decodes all params from encoding into a sequence of
4167 logical characters. On response, encodes body into encoding.
4168
4169 By default encoding is now 'UTF-8'.  You may turn it off by setting
4170 the encoding configuration to undef.
4171
4172 Encoding is automatically applied when the content-type is set to
4173 a type that can be encoded.  Currently we encode when the content type
4174 matches the following regular expression:
4175
4176     $content_type =~ /^text|xml$|javascript$/
4177
4178 Encoding is set on the application, but it is copied to the context object
4179 so that you can override it on a request basis.
4180
4181 Be default we don't automatically encode 'application/json' since the most
4182 popular JSON encoders (such as L<JSON::MaybeXS> which is the library that
4183 L<Catalyst> can make use of) will do the UTF8 encoding and decoding automatically.
4184 Having it on in Catalyst could result in double encoding.
4185
4186 If you are producing JSON response in an unconventional manner (such
4187 as via a template or manual strings) you should perform the UTF8 encoding
4188 manually as well such as to conform to the JSON specification.
4189
4190 NOTE: We also examine the value of $c->response->content_encoding.  If
4191 you set this (like for example 'gzip', and manually gzipping the body)
4192 we assume that you have done all the neccessary encoding yourself, since
4193 we cannot encode the gzipped contents.  If you use a plugin like
4194 L<Catalyst::Plugin::Compress> we will be updating that plugin to work
4195 with the new UTF8 encoding code, or you can use L<Plack::Middleware::Deflater>
4196 or (probably best) do your compression on a front end proxy.
4197
4198 =head2 Methods
4199
4200 =over 4
4201
4202 =item encoding
4203
4204 Returns an instance of an C<Encode> encoding
4205
4206     print $c->encoding->name
4207
4208 =item handle_unicode_encoding_exception ($exception_context)
4209
4210 Method called when decoding process for a request fails.
4211
4212 An C<$exception_context> hashref is provided to allow you to override the
4213 behaviour of your application when given data with incorrect encodings.
4214
4215 The default method throws exceptions in the case of invalid request parameters
4216 (resulting in a 500 error), but ignores errors in upload filenames.
4217
4218 The keys passed in the C<$exception_context> hash are:
4219
4220 =over
4221
4222 =item param_value
4223
4224 The value which was not able to be decoded.
4225
4226 =item error_msg
4227
4228 The exception received from L<Encode>.
4229
4230 =item encoding_step
4231
4232 What type of data was being decoded. Valid values are (currently)
4233 C<params> - for request parameters / arguments / captures
4234 and C<uploads> - for request upload filenames.
4235
4236 =back
4237
4238 =back
4239
4240 =head1 SUPPORT
4241
4242 IRC:
4243
4244     Join #catalyst on irc.perl.org.
4245
4246 Mailing Lists:
4247
4248     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4249     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4250
4251 Web:
4252
4253     http://catalyst.perl.org
4254
4255 Wiki:
4256
4257     http://dev.catalyst.perl.org
4258
4259 =head1 SEE ALSO
4260
4261 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4262
4263 =head2 L<Catalyst::Manual> - The Catalyst Manual
4264
4265 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4266
4267 =head2 L<Catalyst::Engine> - Core engine
4268
4269 =head2 L<Catalyst::Log> - Log class.
4270
4271 =head2 L<Catalyst::Request> - Request object
4272
4273 =head2 L<Catalyst::Response> - Response object
4274
4275 =head2 L<Catalyst::Test> - The test suite.
4276
4277 =head1 PROJECT FOUNDER
4278
4279 sri: Sebastian Riedel <sri@cpan.org>
4280
4281 =head1 CONTRIBUTORS
4282
4283 abw: Andy Wardley
4284
4285 acme: Leon Brocard <leon@astray.com>
4286
4287 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4288
4289 Andrew Bramble
4290
4291 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4292
4293 Andrew Ruthven
4294
4295 andyg: Andy Grundman <andy@hybridized.org>
4296
4297 audreyt: Audrey Tang
4298
4299 bricas: Brian Cassidy <bricas@cpan.org>
4300
4301 Caelum: Rafael Kitover <rkitover@io.com>
4302
4303 chansen: Christian Hansen
4304
4305 chicks: Christopher Hicks
4306
4307 Chisel Wright C<pause@herlpacker.co.uk>
4308
4309 Danijel Milicevic C<me@danijel.de>
4310
4311 davewood: David Schmidt <davewood@cpan.org>
4312
4313 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4314
4315 David Naughton, C<naughton@umn.edu>
4316
4317 David E. Wheeler
4318
4319 dhoss: Devin Austin <dhoss@cpan.org>
4320
4321 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4322
4323 Drew Taylor
4324
4325 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4326
4327 esskar: Sascha Kiefer
4328
4329 fireartist: Carl Franks <cfranks@cpan.org>
4330
4331 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4332
4333 gabb: Danijel Milicevic
4334
4335 Gary Ashton Jones
4336
4337 Gavin Henry C<ghenry@perl.me.uk>
4338
4339 Geoff Richards
4340
4341 groditi: Guillermo Roditi <groditi@gmail.com>
4342
4343 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4344
4345 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4346
4347 jcamacho: Juan Camacho
4348
4349 jester: Jesse Sheidlower C<jester@panix.com>
4350
4351 jhannah: Jay Hannah <jay@jays.net>
4352
4353 Jody Belka
4354
4355 Johan Lindstrom
4356
4357 jon: Jon Schutz <jjschutz@cpan.org>
4358
4359 Jonathan Rockway C<< <jrockway@cpan.org> >>
4360
4361 Kieren Diment C<kd@totaldatasolution.com>
4362
4363 konobi: Scott McWhirter <konobi@cpan.org>
4364
4365 marcus: Marcus Ramberg <mramberg@cpan.org>
4366
4367 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4368
4369 mgrimes: Mark Grimes <mgrimes@cpan.org>
4370
4371 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4372
4373 mugwump: Sam Vilain
4374
4375 naughton: David Naughton
4376
4377 ningu: David Kamholz <dkamholz@cpan.org>
4378
4379 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4380
4381 numa: Dan Sully <daniel@cpan.org>
4382
4383 obra: Jesse Vincent
4384
4385 Octavian Rasnita
4386
4387 omega: Andreas Marienborg
4388
4389 Oleg Kostyuk <cub.uanic@gmail.com>
4390
4391 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4392
4393 rafl: Florian Ragwitz <rafl@debian.org>
4394
4395 random: Roland Lammel <lammel@cpan.org>
4396
4397 Robert Sedlacek C<< <rs@474.at> >>
4398
4399 SpiceMan: Marcel Montes
4400
4401 sky: Arthur Bergman
4402
4403 szbalint: Balint Szilakszi <szbalint@cpan.org>
4404
4405 t0m: Tomas Doran <bobtfish@bobtfish.net>
4406
4407 Ulf Edvinsson
4408
4409 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4410
4411 Viljo Marrandi C<vilts@yahoo.com>
4412
4413 Will Hawes C<info@whawes.co.uk>
4414
4415 willert: Sebastian Willert <willert@cpan.org>
4416
4417 wreis: Wallace Reis <wreis@cpan.org>
4418
4419 Yuval Kogman, C<nothingmuch@woobling.org>
4420
4421 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4422
4423 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4424
4425 Upasana <me@upasana.me>
4426
4427 =head1 COPYRIGHT
4428
4429 Copyright (c) 2005-2014, the above named PROJECT FOUNDER and CONTRIBUTORS.
4430
4431 =head1 LICENSE
4432
4433 This library is free software. You can redistribute it and/or modify it under
4434 the same terms as Perl itself.
4435
4436 =cut
4437
4438 no Moose;
4439
4440 __PACKAGE__->meta->make_immutable;
4441
4442 1;