lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Devel::InnerPackage ();
  18 use File::stat;
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use utf8;
  32 use Carp qw/croak carp shortmess/;
  33
  34 BEGIN { require 5.008004; }
  35
  36 has stack => (is => 'ro', default => sub { [] });
  37 has stash => (is => 'rw', default => sub { {} });
  38 has state => (is => 'rw', default => 0);
  39 has stats => (is => 'rw');
  40 has action => (is => 'rw');
  41 has counter => (is => 'rw', default => sub { {} });
  42 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  43 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  44 has namespace => (is => 'rw');
  45
  46 sub depth { scalar @{ shift->stack || [] }; }
  47 sub comp { shift->component(@_) }
  48
  49 sub req {
  50     my $self = shift; return $self->request(@_);
  51 }
  52 sub res {
  53     my $self = shift; return $self->response(@_);
  54 }
  55
  56 # For backwards compatibility
  57 sub finalize_output { shift->finalize_body(@_) };
  58
  59 # For statistics
  60 our $COUNT     = 1;
  61 our $START     = time;
  62 our $RECURSION = 1000;
  63 our $DETACH    = Catalyst::Exception::Detach->new;
  64 our $GO        = Catalyst::Exception::Go->new;
  65
  66 #I imagine that very few of these really need to be class variables. if any.
  67 #maybe we should just make them attributes with a default?
  68 __PACKAGE__->mk_classdata($_)
  69   for qw/components arguments dispatcher engine log dispatcher_class
  70   engine_class context_class request_class response_class stats_class
  71   setup_finished/;
  72
  73 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  74 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  75 __PACKAGE__->request_class('Catalyst::Request');
  76 __PACKAGE__->response_class('Catalyst::Response');
  77 __PACKAGE__->stats_class('Catalyst::Stats');
  78
  79 # Remember to update this in Catalyst::Runtime as well!
  80
  81 our $VERSION = '5.80019';
  82 $VERSION = eval $VERSION;
  83
  84 sub import {
  85     my ( $class, @arguments ) = @_;
  86
  87     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  88     # callers @ISA.
  89     return unless $class eq 'Catalyst';
  90
  91     my $caller = caller();
  92     return if $caller eq 'main';
  93
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     unless ( $caller->isa('Catalyst') ) {
  96         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  97         $meta->superclasses(@superclasses);
  98     }
  99     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 100     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 101
 102     unless( $meta->has_method('meta') ){
 103         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 104     }
 105
 106     $caller->arguments( [@arguments] );
 107     $caller->setup_home;
 108 }
 109
 110 sub _application { $_[0] }
 111
 112 =head1 NAME
 113
 114 Catalyst - The Elegant MVC Web Application Framework
 115
 116 =head1 SYNOPSIS
 117
 118 See the L<Catalyst::Manual> distribution for comprehensive
 119 documentation and tutorials.
 120
 121     # Install Catalyst::Devel for helpers and other development tools
 122     # use the helper to create a new application
 123     catalyst.pl MyApp
 124
 125     # add models, views, controllers
 126     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 127     script/myapp_create.pl view MyTemplate TT
 128     script/myapp_create.pl controller Search
 129
 130     # built in testserver -- use -r to restart automatically on changes
 131     # --help to see all available options
 132     script/myapp_server.pl
 133
 134     # command line testing interface
 135     script/myapp_test.pl /yada
 136
 137     ### in lib/MyApp.pm
 138     use Catalyst qw/-Debug/; # include plugins here as well
 139
 140     ### In lib/MyApp/Controller/Root.pm (autocreated)
 141     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 142         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 143         $c->stash->{template} = 'foo.tt'; # set the template
 144         # lookup something from db -- stash vars are passed to TT
 145         $c->stash->{data} =
 146           $c->model('Database::Foo')->search( { country => $args[0] } );
 147         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 148             $c->forward( 'bar' ); # process another action
 149             # do something else after forward returns
 150         }
 151     }
 152
 153     # The foo.tt TT template can use the stash data from the database
 154     [% WHILE (item = data.next) %]
 155         [% item.foo %]
 156     [% END %]
 157
 158     # called for /bar/of/soap, /bar/of/soap/10, etc.
 159     sub bar : Path('/bar/of/soap') { ... }
 160
 161     # called for all actions, from the top-most controller downwards
 162     sub auto : Private {
 163         my ( $self, $c ) = @_;
 164         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 165             $c->res->redirect( '/login' ); # require login
 166             return 0; # abort request and go immediately to end()
 167         }
 168         return 1; # success; carry on to next action
 169     }
 170
 171     # called after all actions are finished
 172     sub end : Private {
 173         my ( $self, $c ) = @_;
 174         if ( scalar @{ $c->error } ) { ... } # handle errors
 175         return if $c->res->body; # already have a response
 176         $c->forward( 'MyApp::View::TT' ); # render template
 177     }
 178
 179     ### in MyApp/Controller/Foo.pm
 180     # called for /foo/bar
 181     sub bar : Local { ... }
 182
 183     # called for /blargle
 184     sub blargle : Global { ... }
 185
 186     # an index action matches /foo, but not /foo/1, etc.
 187     sub index : Private { ... }
 188
 189     ### in MyApp/Controller/Foo/Bar.pm
 190     # called for /foo/bar/baz
 191     sub baz : Local { ... }
 192
 193     # first Root auto is called, then Foo auto, then this
 194     sub auto : Private { ... }
 195
 196     # powerful regular expression paths are also possible
 197     sub details : Regex('^product/(\w+)/details$') {
 198         my ( $self, $c ) = @_;
 199         # extract the (\w+) from the URI
 200         my $product = $c->req->captures->[0];
 201     }
 202
 203 See L<Catalyst::Manual::Intro> for additional information.
 204
 205 =head1 DESCRIPTION
 206
 207 Catalyst is a modern framework for making web applications without the
 208 pain usually associated with this process. This document is a reference
 209 to the main Catalyst application. If you are a new user, we suggest you
 210 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 211
 212 See L<Catalyst::Manual> for more documentation.
 213
 214 Catalyst plugins can be loaded by naming them as arguments to the "use
 215 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 216 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 217 C<My::Module>.
 218
 219     use Catalyst qw/My::Module/;
 220
 221 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 222 fully qualify the name by using a unary plus:
 223
 224     use Catalyst qw/
 225         My::Module
 226         +Fully::Qualified::Plugin::Name
 227     /;
 228
 229 Special flags like C<-Debug> and C<-Engine> can also be specified as
 230 arguments when Catalyst is loaded:
 231
 232     use Catalyst qw/-Debug My::Module/;
 233
 234 The position of plugins and flags in the chain is important, because
 235 they are loaded in the order in which they appear.
 236
 237 The following flags are supported:
 238
 239 =head2 -Debug
 240
 241 Enables debug output. You can also force this setting from the system
 242 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 243 settings override the application, with <MYAPP>_DEBUG having the highest
 244 priority.
 245
 246 This sets the log level to 'debug' and enables full debug output on the
 247 error screen. If you only want the latter, see L<< $c->debug >>.
 248
 249 =head2 -Engine
 250
 251 Forces Catalyst to use a specific engine. Omit the
 252 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 253
 254     use Catalyst qw/-Engine=CGI/;
 255
 256 =head2 -Home
 257
 258 Forces Catalyst to use a specific home directory, e.g.:
 259
 260     use Catalyst qw[-Home=/usr/mst];
 261
 262 This can also be done in the shell environment by setting either the
 263 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 264 is replaced with the uppercased name of your application, any "::" in
 265 the name will be replaced with underscores, e.g. MyApp::Web should use
 266 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 267
 268 If none of these are set, Catalyst will attempt to automatically detect the
 269 home directory. If you are working in a development envirnoment, Catalyst
 270 will try and find the directory containing either Makefile.PL, Build.PL or
 271 dist.ini. If the application has been installed into the system (i.e.
 272 you have done C<make install>), then Catalyst will use the path to your
 273 application module, without the .pm extension (ie, /foo/MyApp if your
 274 application was installed at /foo/MyApp.pm)
 275
 276 =head2 -Log
 277
 278     use Catalyst '-Log=warn,fatal,error';
 279
 280 Specifies a comma-delimited list of log levels.
 281
 282 =head2 -Stats
 283
 284 Enables statistics collection and reporting. You can also force this setting
 285 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 286 environment settings override the application, with <MYAPP>_STATS having the
 287 highest priority.
 288
 289 e.g.
 290
 291    use Catalyst qw/-Stats=1/
 292
 293 =head1 METHODS
 294
 295 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 296
 297 =head2 $c->action
 298
 299 Returns a L<Catalyst::Action> object for the current action, which
 300 stringifies to the action name. See L<Catalyst::Action>.
 301
 302 =head2 $c->namespace
 303
 304 Returns the namespace of the current action, i.e., the URI prefix
 305 corresponding to the controller of the current action. For example:
 306
 307     # in Controller::Foo::Bar
 308     $c->namespace; # returns 'foo/bar';
 309
 310 =head2 $c->request
 311
 312 =head2 $c->req
 313
 314 Returns the current L<Catalyst::Request> object, giving access to
 315 information about the current client request (including parameters,
 316 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 317
 318 =head2 REQUEST FLOW HANDLING
 319
 320 =head2 $c->forward( $action [, \@arguments ] )
 321
 322 =head2 $c->forward( $class, $method, [, \@arguments ] )
 323
 324 Forwards processing to another action, by its private name. If you give a
 325 class name but no method, C<process()> is called. You may also optionally
 326 pass arguments in an arrayref. The action will receive the arguments in
 327 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 328 C<< $c->req->args >> will be restored to the previous values.
 329
 330 Any data C<return>ed from the action forwarded to, will be returned by the
 331 call to forward.
 332
 333     my $foodata = $c->forward('/foo');
 334     $c->forward('index');
 335     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 336     $c->forward('View::TT');
 337
 338 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 339 an C<< eval { } >> around the call (actually
 340 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 341 all 'dies' within the called action. If you want C<die> to propagate you
 342 need to do something like:
 343
 344     $c->forward('foo');
 345     die join "\n", @{ $c->error } if @{ $c->error };
 346
 347 Or make sure to always return true values from your actions and write
 348 your code like this:
 349
 350     $c->forward('foo') || return;
 351
 352 Another note is that C<< $c->forward >> always returns a scalar because it
 353 actually returns $c->state which operates in a scalar context.
 354 Thus, something like:
 355
 356     return @array;
 357
 358 in an action that is forwarded to is going to return a scalar,
 359 i.e. how many items are in that array, which is probably not what you want.
 360 If you need to return an array then return a reference to it,
 361 or stash it like so:
 362
 363     $c->stash->{array} = \@array;
 364
 365 and access it from the stash.
 366
 367 =cut
 368
 369 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 370
 371 =head2 $c->detach( $action [, \@arguments ] )
 372
 373 =head2 $c->detach( $class, $method, [, \@arguments ] )
 374
 375 =head2 $c->detach()
 376
 377 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 378 doesn't return to the previous action when processing is finished.
 379
 380 When called with no arguments it escapes the processing chain entirely.
 381
 382 =cut
 383
 384 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 385
 386 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 387
 388 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 389
 390 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 391 but does a full dispatch, instead of just calling the new C<$action> /
 392 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 393 you go to are called, just like a new request.
 394
 395 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 396 This means, for example, that C<< $c->action >> methods such as
 397 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 398 L<reverse|Catalyst::Action/reverse> return information for the visited action
 399 when they are invoked within the visited action.  This is different from the
 400 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 401 continues to use the $c->action object from the caller action even when
 402 invoked from the callee.
 403
 404 C<< $c->stash >> is kept unchanged.
 405
 406 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 407 allows you to "wrap" another action, just as it would have been called by
 408 dispatching from a URL, while the analogous
 409 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 410 transfer control to another action as if it had been reached directly from a URL.
 411
 412 =cut
 413
 414 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 415
 416 =head2 $c->go( $action [, \@captures, \@arguments ] )
 417
 418 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 419
 420 The relationship between C<go> and
 421 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 422 the relationship between
 423 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 424 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 425 C<< $c->go >> will perform a full dispatch on the specified action or method,
 426 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 427 C<go> escapes the processing of the current request chain on completion, and
 428 does not return to its caller.
 429
 430 =cut
 431
 432 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 433
 434 =head2 $c->response
 435
 436 =head2 $c->res
 437
 438 Returns the current L<Catalyst::Response> object, see there for details.
 439
 440 =head2 $c->stash
 441
 442 Returns a hashref to the stash, which may be used to store data and pass
 443 it between components during a request. You can also set hash keys by
 444 passing arguments. The stash is automatically sent to the view. The
 445 stash is cleared at the end of a request; it cannot be used for
 446 persistent storage (for this you must use a session; see
 447 L<Catalyst::Plugin::Session> for a complete system integrated with
 448 Catalyst).
 449
 450     $c->stash->{foo} = $bar;
 451     $c->stash( { moose => 'majestic', qux => 0 } );
 452     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 453
 454     # stash is automatically passed to the view for use in a template
 455     $c->forward( 'MyApp::View::TT' );
 456
 457 =cut
 458
 459 around stash => sub {
 460     my $orig = shift;
 461     my $c = shift;
 462     my $stash = $orig->($c);
 463     if (@_) {
 464         my $new_stash = @_ > 1 ? {@_} : $_[0];
 465         croak('stash takes a hash or hashref') unless ref $new_stash;
 466         foreach my $key ( keys %$new_stash ) {
 467           $stash->{$key} = $new_stash->{$key};
 468         }
 469     }
 470
 471     return $stash;
 472 };
 473
 474
 475 =head2 $c->error
 476
 477 =head2 $c->error($error, ...)
 478
 479 =head2 $c->error($arrayref)
 480
 481 Returns an arrayref containing error messages.  If Catalyst encounters an
 482 error while processing a request, it stores the error in $c->error.  This
 483 method should only be used to store fatal error messages.
 484
 485     my @error = @{ $c->error };
 486
 487 Add a new error.
 488
 489     $c->error('Something bad happened');
 490
 491 =cut
 492
 493 sub error {
 494     my $c = shift;
 495     if ( $_[0] ) {
 496         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 497         croak @$error unless ref $c;
 498         push @{ $c->{error} }, @$error;
 499     }
 500     elsif ( defined $_[0] ) { $c->{error} = undef }
 501     return $c->{error} || [];
 502 }
 503
 504
 505 =head2 $c->state
 506
 507 Contains the return value of the last executed action.
 508 Note that << $c->state >> operates in a scalar context which means that all
 509 values it returns are scalar.
 510
 511 =head2 $c->clear_errors
 512
 513 Clear errors.  You probably don't want to clear the errors unless you are
 514 implementing a custom error screen.
 515
 516 This is equivalent to running
 517
 518     $c->error(0);
 519
 520 =cut
 521
 522 sub clear_errors {
 523     my $c = shift;
 524     $c->error(0);
 525 }
 526
 527 sub _comp_search_prefixes {
 528     my $c = shift;
 529     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 530 }
 531
 532 # search components given a name and some prefixes
 533 sub _comp_names_search_prefixes {
 534     my ( $c, $name, @prefixes ) = @_;
 535     my $appclass = ref $c || $c;
 536     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 537     $filter = qr/$filter/; # Compile regex now rather than once per loop
 538
 539     # map the original component name to the sub part that we will search against
 540     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 541         grep { /$filter/ } keys %{ $c->components };
 542
 543     # undef for a name will return all
 544     return keys %eligible if !defined $name;
 545
 546     my $query  = ref $name ? $name : qr/^$name$/i;
 547     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 548
 549     return @result if @result;
 550
 551     # if we were given a regexp to search against, we're done.
 552     return if ref $name;
 553
 554     # skip regexp fallback if configured
 555     return
 556         if $appclass->config->{disable_component_resolution_regex_fallback};
 557
 558     # regexp fallback
 559     $query  = qr/$name/i;
 560     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 561
 562     # no results? try against full names
 563     if( !@result ) {
 564         @result = grep { m{$query} } keys %eligible;
 565     }
 566
 567     # don't warn if we didn't find any results, it just might not exist
 568     if( @result ) {
 569         # Disgusting hack to work out correct method name
 570         my $warn_for = lc $prefixes[0];
 571         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 572            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 573            "component resolution is unreliable and unsafe.";
 574         my $short = $result[0];
 575         # remove the component namespace prefix
 576         $short =~ s/.*?(Model|Controller|View):://;
 577         my $shortmess = Carp::shortmess('');
 578         if ($shortmess =~ m#Catalyst/Plugin#) {
 579            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 580               "plugin's config";
 581         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 582            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 583               "component's config";
 584         } else {
 585            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 586               "but if you really wanted to search, pass in a regexp as the argument " .
 587               "like so: \$c->${warn_for}(qr/${name}/)";
 588         }
 589         $c->log->warn( "${msg}$shortmess" );
 590     }
 591
 592     return @result;
 593 }
 594
 595 # Find possible names for a prefix
 596 sub _comp_names {
 597     my ( $c, @prefixes ) = @_;
 598     my $appclass = ref $c || $c;
 599
 600     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 601
 602     my @names = map { s{$filter}{}; $_; }
 603         $c->_comp_names_search_prefixes( undef, @prefixes );
 604
 605     return @names;
 606 }
 607
 608 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 609 sub _filter_component {
 610     my ( $c, $comp, @args ) = @_;
 611
 612     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 613         return $comp->ACCEPT_CONTEXT( $c, @args );
 614     }
 615
 616     return $comp;
 617 }
 618
 619 =head2 COMPONENT ACCESSORS
 620
 621 =head2 $c->controller($name)
 622
 623 Gets a L<Catalyst::Controller> instance by name.
 624
 625     $c->controller('Foo')->do_stuff;
 626
 627 If the name is omitted, will return the controller for the dispatched
 628 action.
 629
 630 If you want to search for controllers, pass in a regexp as the argument.
 631
 632     # find all controllers that start with Foo
 633     my @foo_controllers = $c->controller(qr{^Foo});
 634
 635
 636 =cut
 637
 638 sub controller {
 639     my ( $c, $name, @args ) = @_;
 640
 641     if( $name ) {
 642         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 643         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 644         return $c->_filter_component( $result[ 0 ], @args );
 645     }
 646
 647     return $c->component( $c->action->class );
 648 }
 649
 650 =head2 $c->model($name)
 651
 652 Gets a L<Catalyst::Model> instance by name.
 653
 654     $c->model('Foo')->do_stuff;
 655
 656 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 657
 658 If the name is omitted, it will look for
 659  - a model object in $c->stash->{current_model_instance}, then
 660  - a model name in $c->stash->{current_model}, then
 661  - a config setting 'default_model', or
 662  - check if there is only one model, and return it if that's the case.
 663
 664 If you want to search for models, pass in a regexp as the argument.
 665
 666     # find all models that start with Foo
 667     my @foo_models = $c->model(qr{^Foo});
 668
 669 =cut
 670
 671 sub model {
 672     my ( $c, $name, @args ) = @_;
 673     my $appclass = ref($c) || $c;
 674     if( $name ) {
 675         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 676         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 677         return $c->_filter_component( $result[ 0 ], @args );
 678     }
 679
 680     if (ref $c) {
 681         return $c->stash->{current_model_instance}
 682           if $c->stash->{current_model_instance};
 683         return $c->model( $c->stash->{current_model} )
 684           if $c->stash->{current_model};
 685     }
 686     return $c->model( $appclass->config->{default_model} )
 687       if $appclass->config->{default_model};
 688
 689     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 690
 691     if( $rest ) {
 692         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 693         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 694         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 695         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 696         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 697     }
 698
 699     return $c->_filter_component( $comp );
 700 }
 701
 702
 703 =head2 $c->view($name)
 704
 705 Gets a L<Catalyst::View> instance by name.
 706
 707     $c->view('Foo')->do_stuff;
 708
 709 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 710
 711 If the name is omitted, it will look for
 712  - a view object in $c->stash->{current_view_instance}, then
 713  - a view name in $c->stash->{current_view}, then
 714  - a config setting 'default_view', or
 715  - check if there is only one view, and return it if that's the case.
 716
 717 If you want to search for views, pass in a regexp as the argument.
 718
 719     # find all views that start with Foo
 720     my @foo_views = $c->view(qr{^Foo});
 721
 722 =cut
 723
 724 sub view {
 725     my ( $c, $name, @args ) = @_;
 726
 727     my $appclass = ref($c) || $c;
 728     if( $name ) {
 729         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 730         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 731         return $c->_filter_component( $result[ 0 ], @args );
 732     }
 733
 734     if (ref $c) {
 735         return $c->stash->{current_view_instance}
 736           if $c->stash->{current_view_instance};
 737         return $c->view( $c->stash->{current_view} )
 738           if $c->stash->{current_view};
 739     }
 740     return $c->view( $appclass->config->{default_view} )
 741       if $appclass->config->{default_view};
 742
 743     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 744
 745     if( $rest ) {
 746         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 747         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 748         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 749         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 750         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 751     }
 752
 753     return $c->_filter_component( $comp );
 754 }
 755
 756 =head2 $c->controllers
 757
 758 Returns the available names which can be passed to $c->controller
 759
 760 =cut
 761
 762 sub controllers {
 763     my ( $c ) = @_;
 764     return $c->_comp_names(qw/Controller C/);
 765 }
 766
 767 =head2 $c->models
 768
 769 Returns the available names which can be passed to $c->model
 770
 771 =cut
 772
 773 sub models {
 774     my ( $c ) = @_;
 775     return $c->_comp_names(qw/Model M/);
 776 }
 777
 778
 779 =head2 $c->views
 780
 781 Returns the available names which can be passed to $c->view
 782
 783 =cut
 784
 785 sub views {
 786     my ( $c ) = @_;
 787     return $c->_comp_names(qw/View V/);
 788 }
 789
 790 =head2 $c->comp($name)
 791
 792 =head2 $c->component($name)
 793
 794 Gets a component object by name. This method is not recommended,
 795 unless you want to get a specific component by full
 796 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 797 should be used instead.
 798
 799 If C<$name> is a regexp, a list of components matched against the full
 800 component name will be returned.
 801
 802 If Catalyst can't find a component by name, it will fallback to regex
 803 matching by default. To disable this behaviour set
 804 disable_component_resolution_regex_fallback to a true value.
 805
 806     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 807
 808 =cut
 809
 810 sub component {
 811     my ( $c, $name, @args ) = @_;
 812
 813     if( $name ) {
 814         my $comps = $c->components;
 815
 816         if( !ref $name ) {
 817             # is it the exact name?
 818             return $c->_filter_component( $comps->{ $name }, @args )
 819                        if exists $comps->{ $name };
 820
 821             # perhaps we just omitted "MyApp"?
 822             my $composed = ( ref $c || $c ) . "::${name}";
 823             return $c->_filter_component( $comps->{ $composed }, @args )
 824                        if exists $comps->{ $composed };
 825
 826             # search all of the models, views and controllers
 827             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 828             return $c->_filter_component( $comp, @args ) if $comp;
 829         }
 830
 831         # This is here so $c->comp( '::M::' ) works
 832         my $query = ref $name ? $name : qr{$name}i;
 833
 834         my @result = grep { m{$query} } keys %{ $c->components };
 835         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 836
 837         if( $result[ 0 ] ) {
 838             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 839             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 840             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 841             return $c->_filter_component( $result[ 0 ], @args );
 842         }
 843
 844         # I would expect to return an empty list here, but that breaks back-compat
 845     }
 846
 847     # fallback
 848     return sort keys %{ $c->components };
 849 }
 850
 851 =head2 CLASS DATA AND HELPER CLASSES
 852
 853 =head2 $c->config
 854
 855 Returns or takes a hashref containing the application's configuration.
 856
 857     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 858
 859 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 860 like C<myapp.conf> in your applications home directory. See
 861 L<Catalyst::Plugin::ConfigLoader>.
 862
 863 =head3 Cascading configuration
 864
 865 The config method is present on all Catalyst components, and configuration
 866 will be merged when an application is started. Configuration loaded with
 867 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 868 followed by configuration in your top level C<MyApp> class. These two
 869 configurations are merged, and then configuration data whose hash key matches a
 870 component name is merged with configuration for that component.
 871
 872 The configuration for a component is then passed to the C<new> method when a
 873 component is constructed.
 874
 875 For example:
 876
 877     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 878     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 879
 880 will mean that C<MyApp::Model::Foo> receives the following data when
 881 constructed:
 882
 883     MyApp::Model::Foo->new({
 884         bar => 'baz',
 885         quux => 'frob',
 886         overrides => 'me',
 887     });
 888
 889 =cut
 890
 891 around config => sub {
 892     my $orig = shift;
 893     my $c = shift;
 894
 895     croak('Setting config after setup has been run is not allowed.')
 896         if ( @_ and $c->setup_finished );
 897
 898     $c->$orig(@_);
 899 };
 900
 901 =head2 $c->log
 902
 903 Returns the logging object instance. Unless it is already set, Catalyst
 904 sets this up with a L<Catalyst::Log> object. To use your own log class,
 905 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 906 C<< __PACKAGE__->setup >>.
 907
 908  __PACKAGE__->log( MyLogger->new );
 909  __PACKAGE__->setup;
 910
 911 And later:
 912
 913     $c->log->info( 'Now logging with my own logger!' );
 914
 915 Your log class should implement the methods described in
 916 L<Catalyst::Log>.
 917
 918
 919 =head2 $c->debug
 920
 921 Returns 1 if debug mode is enabled, 0 otherwise.
 922
 923 You can enable debug mode in several ways:
 924
 925 =over
 926
 927 =item By calling myapp_server.pl with the -d flag
 928
 929 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 930
 931 =item The -Debug option in your MyApp.pm
 932
 933 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 934
 935 =back
 936
 937 The first three also set the log level to 'debug'.
 938
 939 Calling C<< $c->debug(1) >> has no effect.
 940
 941 =cut
 942
 943 sub debug { 0 }
 944
 945 =head2 $c->dispatcher
 946
 947 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 948
 949 =head2 $c->engine
 950
 951 Returns the engine instance. See L<Catalyst::Engine>.
 952
 953
 954 =head2 UTILITY METHODS
 955
 956 =head2 $c->path_to(@path)
 957
 958 Merges C<@path> with C<< $c->config->{home} >> and returns a
 959 L<Path::Class::Dir> object. Note you can usually use this object as
 960 a filename, but sometimes you will have to explicitly stringify it
 961 yourself by calling the C<< ->stringify >> method.
 962
 963 For example:
 964
 965     $c->path_to( 'db', 'sqlite.db' );
 966
 967 =cut
 968
 969 sub path_to {
 970     my ( $c, @path ) = @_;
 971     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 972     if ( -d $path ) { return $path }
 973     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 974 }
 975
 976 =head2 $c->plugin( $name, $class, @args )
 977
 978 Helper method for plugins. It creates a class data accessor/mutator and
 979 loads and instantiates the given class.
 980
 981     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 982
 983     $c->prototype->define_javascript_functions;
 984
 985 B<Note:> This method of adding plugins is deprecated. The ability
 986 to add plugins like this B<will be removed> in a Catalyst 5.81.
 987 Please do not use this functionality in new code.
 988
 989 =cut
 990
 991 sub plugin {
 992     my ( $class, $name, $plugin, @args ) = @_;
 993
 994     # See block comment in t/unit_core_plugin.t
 995     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
 996
 997     $class->_register_plugin( $plugin, 1 );
 998
 999     eval { $plugin->import };
1000     $class->mk_classdata($name);
1001     my $obj;
1002     eval { $obj = $plugin->new(@args) };
1003
1004     if ($@) {
1005         Catalyst::Exception->throw( message =>
1006               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1007     }
1008
1009     $class->$name($obj);
1010     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1011       if $class->debug;
1012 }
1013
1014 =head2 MyApp->setup
1015
1016 Initializes the dispatcher and engine, loads any plugins, and loads the
1017 model, view, and controller components. You may also specify an array
1018 of plugins to load here, if you choose to not load them in the C<use
1019 Catalyst> line.
1020
1021     MyApp->setup;
1022     MyApp->setup( qw/-Debug/ );
1023
1024 =cut
1025
1026 sub setup {
1027     my ( $class, @arguments ) = @_;
1028     croak('Running setup more than once')
1029         if ( $class->setup_finished );
1030
1031     unless ( $class->isa('Catalyst') ) {
1032
1033         Catalyst::Exception->throw(
1034             message => qq/'$class' does not inherit from Catalyst/ );
1035     }
1036
1037     if ( $class->arguments ) {
1038         @arguments = ( @arguments, @{ $class->arguments } );
1039     }
1040
1041     # Process options
1042     my $flags = {};
1043
1044     foreach (@arguments) {
1045
1046         if (/^-Debug$/) {
1047             $flags->{log} =
1048               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1049         }
1050         elsif (/^-(\w+)=?(.*)$/) {
1051             $flags->{ lc $1 } = $2;
1052         }
1053         else {
1054             push @{ $flags->{plugins} }, $_;
1055         }
1056     }
1057
1058     $class->setup_home( delete $flags->{home} );
1059
1060     $class->setup_log( delete $flags->{log} );
1061     $class->setup_plugins( delete $flags->{plugins} );
1062     $class->setup_dispatcher( delete $flags->{dispatcher} );
1063     $class->setup_engine( delete $flags->{engine} );
1064     $class->setup_stats( delete $flags->{stats} );
1065
1066     for my $flag ( sort keys %{$flags} ) {
1067
1068         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1069             &$code( $class, delete $flags->{$flag} );
1070         }
1071         else {
1072             $class->log->warn(qq/Unknown flag "$flag"/);
1073         }
1074     }
1075
1076     eval { require Catalyst::Devel; };
1077     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1078         $class->log->warn(<<"EOF");
1079 You are running an old script!
1080
1081   Please update by running (this will overwrite existing files):
1082     catalyst.pl -force -scripts $class
1083
1084   or (this will not overwrite existing files):
1085     catalyst.pl -scripts $class
1086
1087 EOF
1088     }
1089
1090     if ( $class->debug ) {
1091         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1092
1093         if (@plugins) {
1094             my $column_width = Catalyst::Utils::term_width() - 6;
1095             my $t = Text::SimpleTable->new($column_width);
1096             $t->row($_) for @plugins;
1097             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1098         }
1099
1100         my $dispatcher = $class->dispatcher;
1101         my $engine     = $class->engine;
1102         my $home       = $class->config->{home};
1103
1104         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1105         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1106
1107         $home
1108           ? ( -d $home )
1109           ? $class->log->debug(qq/Found home "$home"/)
1110           : $class->log->debug(qq/Home "$home" doesn't exist/)
1111           : $class->log->debug(q/Couldn't find home/);
1112     }
1113
1114     # Call plugins setup, this is stupid and evil.
1115     # Also screws C3 badly on 5.10, hack to avoid.
1116     {
1117         no warnings qw/redefine/;
1118         local *setup = sub { };
1119         $class->setup unless $Catalyst::__AM_RESTARTING;
1120     }
1121
1122     # Initialize our data structure
1123     $class->components( {} );
1124
1125     $class->setup_components;
1126
1127     if ( $class->debug ) {
1128         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1129         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1130         for my $comp ( sort keys %{ $class->components } ) {
1131             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1132             $t->row( $comp, $type );
1133         }
1134         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1135           if ( keys %{ $class->components } );
1136     }
1137
1138     # Add our self to components, since we are also a component
1139     if( $class->isa('Catalyst::Controller') ){
1140       $class->components->{$class} = $class;
1141     }
1142
1143     $class->setup_actions;
1144
1145     if ( $class->debug ) {
1146         my $name = $class->config->{name} || 'Application';
1147         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1148     }
1149
1150     # Make sure that the application class becomes immutable at this point,
1151     B::Hooks::EndOfScope::on_scope_end {
1152         return if $@;
1153         my $meta = Class::MOP::get_metaclass_by_name($class);
1154         if (
1155             $meta->is_immutable
1156             && ! { $meta->immutable_options }->{replace_constructor}
1157             && (
1158                    $class->isa('Class::Accessor::Fast')
1159                 || $class->isa('Class::Accessor')
1160             )
1161         ) {
1162             warn "You made your application class ($class) immutable, "
1163                 . "but did not inline the\nconstructor. "
1164                 . "This will break catalyst, as your app \@ISA "
1165                 . "Class::Accessor(::Fast)?\nPlease pass "
1166                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1167         }
1168         $meta->make_immutable(
1169             replace_constructor => 1,
1170         ) unless $meta->is_immutable;
1171     };
1172
1173     if ($class->config->{case_sensitive}) {
1174         $class->log->warn($class . "->config->{case_sensitive} is set.");
1175         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1176     }
1177
1178     $class->setup_finalize;
1179     # Should be the last thing we do so that user things hooking
1180     # setup_finalize can log..
1181     $class->log->_flush() if $class->log->can('_flush');
1182     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1183 }
1184
1185
1186 =head2 $app->setup_finalize
1187
1188 A hook to attach modifiers to.
1189 Using C<< after setup => sub{}; >> doesn't work, because of quirky things done for plugin setup.
1190 Also better than C< setup_finished(); >, as that is a getter method.
1191
1192     sub setup_finalize {
1193
1194         my $app = shift;
1195
1196         ## do stuff, i.e., determine a primary key column for sessions stored in a DB
1197
1198         $app->next::method(@_);
1199
1200
1201     }
1202
1203 =cut
1204
1205 sub setup_finalize {
1206     my ($class) = @_;
1207     $class->setup_finished(1);
1208 }
1209
1210 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1211
1212 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1213
1214 Constructs an absolute L<URI> object based on the application root, the
1215 provided path, and the additional arguments and query parameters provided.
1216 When used as a string, provides a textual URI.
1217
1218 If no arguments are provided, the URI for the current action is returned.
1219 To return the current action and also provide @args, use
1220 C<< $c->uri_for( $c->action, @args ) >>.
1221
1222 If the first argument is a string, it is taken as a public URI path relative
1223 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1224 relative to the application root (if it does). It is then merged with
1225 C<< $c->request->base >>; any C<@args> are appended as additional path
1226 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1227
1228 If the first argument is a L<Catalyst::Action> it represents an action which
1229 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1230 optional C<\@captures> argument (an arrayref) allows passing the captured
1231 variables that are needed to fill in the paths of Chained and Regex actions;
1232 once the path is resolved, C<uri_for> continues as though a path was
1233 provided, appending any arguments or parameters and creating an absolute
1234 URI.
1235
1236 The captures for the current request can be found in
1237 C<< $c->request->captures >>, and actions can be resolved using
1238 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1239 path, use C<< $c->uri_for_action >> instead.
1240
1241   # Equivalent to $c->req->uri
1242   $c->uri_for($c->action, $c->req->captures,
1243       @{ $c->req->args }, $c->req->params);
1244
1245   # For the Foo action in the Bar controller
1246   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1247
1248   # Path to a static resource
1249   $c->uri_for('/static/images/logo.png');
1250
1251 =cut
1252
1253 sub uri_for {
1254     my ( $c, $path, @args ) = @_;
1255
1256     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1257         $path = $path->path_prefix;
1258         $path =~ s{/+\z}{};
1259         $path .= '/';
1260     }
1261
1262     undef($path) if (defined $path && $path eq '');
1263
1264     my $params =
1265       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1266
1267     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1268     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1269     if (blessed $path) { # Action object only.
1270         s|/|%2F|g for @args;
1271     }
1272
1273     if ( blessed($path) ) { # action object
1274         my $captures = [ map { s|/|%2F|g; $_; }
1275                         ( scalar @args && ref $args[0] eq 'ARRAY'
1276                          ? @{ shift(@args) }
1277                          : ()) ];
1278         my $action = $path;
1279         $path = $c->dispatcher->uri_for_action($action, $captures);
1280         if (not defined $path) {
1281             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1282                 if $c->debug;
1283             return undef;
1284         }
1285         $path = '/' if $path eq '';
1286     }
1287
1288     unshift(@args, $path);
1289
1290     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1291         my $namespace = $c->namespace;
1292         if (defined $path) { # cheesy hack to handle path '../foo'
1293            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1294         }
1295         unshift(@args, $namespace || '');
1296     }
1297
1298     # join args with '/', or a blank string
1299     my $args = join('/', grep { defined($_) } @args);
1300     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1301     $args =~ s!^/+!!;
1302     my $base = $c->req->base;
1303     my $class = ref($base);
1304     $base =~ s{(?<!/)$}{/};
1305
1306     my $query = '';
1307
1308     if (my @keys = keys %$params) {
1309       # somewhat lifted from URI::_query's query_form
1310       $query = '?'.join('&', map {
1311           my $val = $params->{$_};
1312           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1313           s/ /+/g;
1314           my $key = $_;
1315           $val = '' unless defined $val;
1316           (map {
1317               my $param = "$_";
1318               utf8::encode( $param ) if utf8::is_utf8($param);
1319               # using the URI::Escape pattern here so utf8 chars survive
1320               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1321               $param =~ s/ /+/g;
1322               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1323       } @keys);
1324     }
1325
1326     my $res = bless(\"${base}${args}${query}", $class);
1327     $res;
1328 }
1329
1330 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1331
1332 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1333
1334 =over
1335
1336 =item $path
1337
1338 A private path to the Catalyst action you want to create a URI for.
1339
1340 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1341 >> and passing the resulting C<$action> and the remaining arguments to C<<
1342 $c->uri_for >>.
1343
1344 You can also pass in a Catalyst::Action object, in which case it is passed to
1345 C<< $c->uri_for >>.
1346
1347 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1348
1349 For example, if the action looks like:
1350
1351  package MyApp::Controller::Users;
1352
1353  sub lst : Path('the-list') {}
1354
1355 You can use:
1356
1357  $c->uri_for_action('/users/lst')
1358
1359 and it will create the URI /users/the-list.
1360
1361 =back
1362
1363 =cut
1364
1365 sub uri_for_action {
1366     my ( $c, $path, @args ) = @_;
1367     my $action = blessed($path)
1368       ? $path
1369       : $c->dispatcher->get_action_by_path($path);
1370     unless (defined $action) {
1371       croak "Can't find action for path '$path'";
1372     }
1373     return $c->uri_for( $action, @args );
1374 }
1375
1376 =head2 $c->welcome_message
1377
1378 Returns the Catalyst welcome HTML page.
1379
1380 =cut
1381
1382 sub welcome_message {
1383     my $c      = shift;
1384     my $name   = $c->config->{name};
1385     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1386     my $prefix = Catalyst::Utils::appprefix( ref $c );
1387     $c->response->content_type('text/html; charset=utf-8');
1388     return <<"EOF";
1389 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1390     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1391 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1392     <head>
1393     <meta http-equiv="Content-Language" content="en" />
1394     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1395         <title>$name on Catalyst $VERSION</title>
1396         <style type="text/css">
1397             body {
1398                 color: #000;
1399                 background-color: #eee;
1400             }
1401             div#content {
1402                 width: 640px;
1403                 margin-left: auto;
1404                 margin-right: auto;
1405                 margin-top: 10px;
1406                 margin-bottom: 10px;
1407                 text-align: left;
1408                 background-color: #ccc;
1409                 border: 1px solid #aaa;
1410             }
1411             p, h1, h2 {
1412                 margin-left: 20px;
1413                 margin-right: 20px;
1414                 font-family: verdana, tahoma, sans-serif;
1415             }
1416             a {
1417                 font-family: verdana, tahoma, sans-serif;
1418             }
1419             :link, :visited {
1420                     text-decoration: none;
1421                     color: #b00;
1422                     border-bottom: 1px dotted #bbb;
1423             }
1424             :link:hover, :visited:hover {
1425                     color: #555;
1426             }
1427             div#topbar {
1428                 margin: 0px;
1429             }
1430             pre {
1431                 margin: 10px;
1432                 padding: 8px;
1433             }
1434             div#answers {
1435                 padding: 8px;
1436                 margin: 10px;
1437                 background-color: #fff;
1438                 border: 1px solid #aaa;
1439             }
1440             h1 {
1441                 font-size: 0.9em;
1442                 font-weight: normal;
1443                 text-align: center;
1444             }
1445             h2 {
1446                 font-size: 1.0em;
1447             }
1448             p {
1449                 font-size: 0.9em;
1450             }
1451             p img {
1452                 float: right;
1453                 margin-left: 10px;
1454             }
1455             span#appname {
1456                 font-weight: bold;
1457                 font-size: 1.6em;
1458             }
1459         </style>
1460     </head>
1461     <body>
1462         <div id="content">
1463             <div id="topbar">
1464                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1465                     $VERSION</h1>
1466              </div>
1467              <div id="answers">
1468                  <p>
1469                  <img src="$logo" alt="Catalyst Logo" />
1470                  </p>
1471                  <p>Welcome to the  world of Catalyst.
1472                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1473                     framework will make web development something you had
1474                     never expected it to be: Fun, rewarding, and quick.</p>
1475                  <h2>What to do now?</h2>
1476                  <p>That really depends  on what <b>you</b> want to do.
1477                     We do, however, provide you with a few starting points.</p>
1478                  <p>If you want to jump right into web development with Catalyst
1479                     you might want to start with a tutorial.</p>
1480 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1481 </pre>
1482 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1483 <pre>
1484 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1485 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1486 </code></pre>
1487                  <h2>What to do next?</h2>
1488                  <p>Next it's time to write an actual application. Use the
1489                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1490                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1491                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1492                     they can save you a lot of work.</p>
1493                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1494                     <p>Also, be sure to check out the vast and growing
1495                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1496                     you are likely to find what you need there.
1497                     </p>
1498
1499                  <h2>Need help?</h2>
1500                  <p>Catalyst has a very active community. Here are the main places to
1501                     get in touch with us.</p>
1502                  <ul>
1503                      <li>
1504                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1505                      </li>
1506                      <li>
1507                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1508                      </li>
1509                      <li>
1510                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1511                      </li>
1512                  </ul>
1513                  <h2>In conclusion</h2>
1514                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1515                     as we enjoyed making it. Please contact us if you have ideas
1516                     for improvement or other feedback.</p>
1517              </div>
1518          </div>
1519     </body>
1520 </html>
1521 EOF
1522 }
1523
1524 =head1 INTERNAL METHODS
1525
1526 These methods are not meant to be used by end users.
1527
1528 =head2 $c->components
1529
1530 Returns a hash of components.
1531
1532 =head2 $c->context_class
1533
1534 Returns or sets the context class.
1535
1536 =head2 $c->counter
1537
1538 Returns a hashref containing coderefs and execution counts (needed for
1539 deep recursion detection).
1540
1541 =head2 $c->depth
1542
1543 Returns the number of actions on the current internal execution stack.
1544
1545 =head2 $c->dispatch
1546
1547 Dispatches a request to actions.
1548
1549 =cut
1550
1551 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1552
1553 =head2 $c->dispatcher_class
1554
1555 Returns or sets the dispatcher class.
1556
1557 =head2 $c->dump_these
1558
1559 Returns a list of 2-element array references (name, structure) pairs
1560 that will be dumped on the error page in debug mode.
1561
1562 =cut
1563
1564 sub dump_these {
1565     my $c = shift;
1566     [ Request => $c->req ],
1567     [ Response => $c->res ],
1568     [ Stash => $c->stash ],
1569     [ Config => $c->config ];
1570 }
1571
1572 =head2 $c->engine_class
1573
1574 Returns or sets the engine class.
1575
1576 =head2 $c->execute( $class, $coderef )
1577
1578 Execute a coderef in given class and catch exceptions. Errors are available
1579 via $c->error.
1580
1581 =cut
1582
1583 sub execute {
1584     my ( $c, $class, $code ) = @_;
1585     $class = $c->component($class) || $class;
1586     $c->state(0);
1587
1588     if ( $c->depth >= $RECURSION ) {
1589         my $action = $code->reverse();
1590         $action = "/$action" unless $action =~ /->/;
1591         my $error = qq/Deep recursion detected calling "${action}"/;
1592         $c->log->error($error);
1593         $c->error($error);
1594         $c->state(0);
1595         return $c->state;
1596     }
1597
1598     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1599
1600     push( @{ $c->stack }, $code );
1601
1602     no warnings 'recursion';
1603     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1604
1605     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1606
1607     my $last = pop( @{ $c->stack } );
1608
1609     if ( my $error = $@ ) {
1610         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1611             $error->rethrow if $c->depth > 1;
1612         }
1613         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1614             $error->rethrow if $c->depth > 0;
1615         }
1616         else {
1617             unless ( ref $error ) {
1618                 no warnings 'uninitialized';
1619                 chomp $error;
1620                 my $class = $last->class;
1621                 my $name  = $last->name;
1622                 $error = qq/Caught exception in $class->$name "$error"/;
1623             }
1624             $c->error($error);
1625             $c->state(0);
1626         }
1627     }
1628     return $c->state;
1629 }
1630
1631 sub _stats_start_execute {
1632     my ( $c, $code ) = @_;
1633     my $appclass = ref($c) || $c;
1634     return if ( ( $code->name =~ /^_.*/ )
1635         && ( !$appclass->config->{show_internal_actions} ) );
1636
1637     my $action_name = $code->reverse();
1638     $c->counter->{$action_name}++;
1639
1640     my $action = $action_name;
1641     $action = "/$action" unless $action =~ /->/;
1642
1643     # determine if the call was the result of a forward
1644     # this is done by walking up the call stack and looking for a calling
1645     # sub of Catalyst::forward before the eval
1646     my $callsub = q{};
1647     for my $index ( 2 .. 11 ) {
1648         last
1649         if ( ( caller($index) )[0] eq 'Catalyst'
1650             && ( caller($index) )[3] eq '(eval)' );
1651
1652         if ( ( caller($index) )[3] =~ /forward$/ ) {
1653             $callsub = ( caller($index) )[3];
1654             $action  = "-> $action";
1655             last;
1656         }
1657     }
1658
1659     my $uid = $action_name . $c->counter->{$action_name};
1660
1661     # is this a root-level call or a forwarded call?
1662     if ( $callsub =~ /forward$/ ) {
1663         my $parent = $c->stack->[-1];
1664
1665         # forward, locate the caller
1666         if ( exists $c->counter->{"$parent"} ) {
1667             $c->stats->profile(
1668                 begin  => $action,
1669                 parent => "$parent" . $c->counter->{"$parent"},
1670                 uid    => $uid,
1671             );
1672         }
1673         else {
1674
1675             # forward with no caller may come from a plugin
1676             $c->stats->profile(
1677                 begin => $action,
1678                 uid   => $uid,
1679             );
1680         }
1681     }
1682     else {
1683
1684         # root-level call
1685         $c->stats->profile(
1686             begin => $action,
1687             uid   => $uid,
1688         );
1689     }
1690     return $action;
1691
1692 }
1693
1694 sub _stats_finish_execute {
1695     my ( $c, $info ) = @_;
1696     $c->stats->profile( end => $info );
1697 }
1698
1699 =head2 $c->finalize
1700
1701 Finalizes the request.
1702
1703 =cut
1704
1705 sub finalize {
1706     my $c = shift;
1707
1708     for my $error ( @{ $c->error } ) {
1709         $c->log->error($error);
1710     }
1711
1712     # Allow engine to handle finalize flow (for POE)
1713     my $engine = $c->engine;
1714     if ( my $code = $engine->can('finalize') ) {
1715         $engine->$code($c);
1716     }
1717     else {
1718
1719         $c->finalize_uploads;
1720
1721         # Error
1722         if ( $#{ $c->error } >= 0 ) {
1723             $c->finalize_error;
1724         }
1725
1726         $c->finalize_headers;
1727
1728         # HEAD request
1729         if ( $c->request->method eq 'HEAD' ) {
1730             $c->response->body('');
1731         }
1732
1733         $c->finalize_body;
1734     }
1735
1736     if ($c->use_stats) {
1737         my $elapsed = sprintf '%f', $c->stats->elapsed;
1738         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1739         $c->log->info(
1740             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1741     }
1742
1743     return $c->response->status;
1744 }
1745
1746 =head2 $c->finalize_body
1747
1748 Finalizes body.
1749
1750 =cut
1751
1752 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1753
1754 =head2 $c->finalize_cookies
1755
1756 Finalizes cookies.
1757
1758 =cut
1759
1760 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1761
1762 =head2 $c->finalize_error
1763
1764 Finalizes error.
1765
1766 =cut
1767
1768 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1769
1770 =head2 $c->finalize_headers
1771
1772 Finalizes headers.
1773
1774 =cut
1775
1776 sub finalize_headers {
1777     my $c = shift;
1778
1779     my $response = $c->response; #accessor calls can add up?
1780
1781     # Check if we already finalized headers
1782     return if $response->finalized_headers;
1783
1784     # Handle redirects
1785     if ( my $location = $response->redirect ) {
1786         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1787         $response->header( Location => $location );
1788
1789         if ( !$response->has_body ) {
1790             # Add a default body if none is already present
1791             $response->body(
1792                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1793             );
1794         }
1795     }
1796
1797     # Content-Length
1798     if ( $response->body && !$response->content_length ) {
1799
1800         # get the length from a filehandle
1801         if ( blessed( $response->body ) && $response->body->can('read') )
1802         {
1803             my $stat = stat $response->body;
1804             if ( $stat && $stat->size > 0 ) {
1805                 $response->content_length( $stat->size );
1806             }
1807             else {
1808                 $c->log->warn('Serving filehandle without a content-length');
1809             }
1810         }
1811         else {
1812             # everything should be bytes at this point, but just in case
1813             $response->content_length( length( $response->body ) );
1814         }
1815     }
1816
1817     # Errors
1818     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1819         $response->headers->remove_header("Content-Length");
1820         $response->body('');
1821     }
1822
1823     $c->finalize_cookies;
1824
1825     $c->engine->finalize_headers( $c, @_ );
1826
1827     # Done
1828     $response->finalized_headers(1);
1829 }
1830
1831 =head2 $c->finalize_output
1832
1833 An alias for finalize_body.
1834
1835 =head2 $c->finalize_read
1836
1837 Finalizes the input after reading is complete.
1838
1839 =cut
1840
1841 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1842
1843 =head2 $c->finalize_uploads
1844
1845 Finalizes uploads. Cleans up any temporary files.
1846
1847 =cut
1848
1849 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1850
1851 =head2 $c->get_action( $action, $namespace )
1852
1853 Gets an action in a given namespace.
1854
1855 =cut
1856
1857 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1858
1859 =head2 $c->get_actions( $action, $namespace )
1860
1861 Gets all actions of a given name in a namespace and all parent
1862 namespaces.
1863
1864 =cut
1865
1866 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1867
1868 =head2 $c->handle_request( $class, @arguments )
1869
1870 Called to handle each HTTP request.
1871
1872 =cut
1873
1874 sub handle_request {
1875     my ( $class, @arguments ) = @_;
1876
1877     # Always expect worst case!
1878     my $status = -1;
1879     eval {
1880         if ($class->debug) {
1881             my $secs = time - $START || 1;
1882             my $av = sprintf '%.3f', $COUNT / $secs;
1883             my $time = localtime time;
1884             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1885         }
1886
1887         my $c = $class->prepare(@arguments);
1888         $c->dispatch;
1889         $status = $c->finalize;
1890     };
1891
1892     if ( my $error = $@ ) {
1893         chomp $error;
1894         $class->log->error(qq/Caught exception in engine "$error"/);
1895     }
1896
1897     $COUNT++;
1898
1899     if(my $coderef = $class->log->can('_flush')){
1900         $class->log->$coderef();
1901     }
1902     return $status;
1903 }
1904
1905 =head2 $c->prepare( @arguments )
1906
1907 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1908 etc.).
1909
1910 =cut
1911
1912 sub prepare {
1913     my ( $class, @arguments ) = @_;
1914
1915     # XXX
1916     # After the app/ctxt split, this should become an attribute based on something passed
1917     # into the application.
1918     $class->context_class( ref $class || $class ) unless $class->context_class;
1919
1920     my $c = $class->context_class->new({});
1921
1922     # For on-demand data
1923     $c->request->_context($c);
1924     $c->response->_context($c);
1925
1926     #surely this is not the most efficient way to do things...
1927     $c->stats($class->stats_class->new)->enable($c->use_stats);
1928     if ( $c->debug ) {
1929         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1930     }
1931
1932     #XXX reuse coderef from can
1933     # Allow engine to direct the prepare flow (for POE)
1934     if ( $c->engine->can('prepare') ) {
1935         $c->engine->prepare( $c, @arguments );
1936     }
1937     else {
1938         $c->prepare_request(@arguments);
1939         $c->prepare_connection;
1940         $c->prepare_query_parameters;
1941         $c->prepare_headers;
1942         $c->prepare_cookies;
1943         $c->prepare_path;
1944
1945         # Prepare the body for reading, either by prepare_body
1946         # or the user, if they are using $c->read
1947         $c->prepare_read;
1948
1949         # Parse the body unless the user wants it on-demand
1950         unless ( ref($c)->config->{parse_on_demand} ) {
1951             $c->prepare_body;
1952         }
1953     }
1954
1955     my $method  = $c->req->method  || '';
1956     my $path    = $c->req->path;
1957     $path       = '/' unless length $path;
1958     my $address = $c->req->address || '';
1959
1960     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1961       if $c->debug;
1962
1963     $c->prepare_action;
1964
1965     return $c;
1966 }
1967
1968 =head2 $c->prepare_action
1969
1970 Prepares action. See L<Catalyst::Dispatcher>.
1971
1972 =cut
1973
1974 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1975
1976 =head2 $c->prepare_body
1977
1978 Prepares message body.
1979
1980 =cut
1981
1982 sub prepare_body {
1983     my $c = shift;
1984
1985     return if $c->request->_has_body;
1986
1987     # Initialize on-demand data
1988     $c->engine->prepare_body( $c, @_ );
1989     $c->prepare_parameters;
1990     $c->prepare_uploads;
1991
1992     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1993         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1994         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1995             my $param = $c->req->body_parameters->{$key};
1996             my $value = defined($param) ? $param : '';
1997             $t->row( $key,
1998                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1999         }
2000         $c->log->debug( "Body Parameters are:\n" . $t->draw );
2001     }
2002 }
2003
2004 =head2 $c->prepare_body_chunk( $chunk )
2005
2006 Prepares a chunk of data before sending it to L<HTTP::Body>.
2007
2008 See L<Catalyst::Engine>.
2009
2010 =cut
2011
2012 sub prepare_body_chunk {
2013     my $c = shift;
2014     $c->engine->prepare_body_chunk( $c, @_ );
2015 }
2016
2017 =head2 $c->prepare_body_parameters
2018
2019 Prepares body parameters.
2020
2021 =cut
2022
2023 sub prepare_body_parameters {
2024     my $c = shift;
2025     $c->engine->prepare_body_parameters( $c, @_ );
2026 }
2027
2028 =head2 $c->prepare_connection
2029
2030 Prepares connection.
2031
2032 =cut
2033
2034 sub prepare_connection {
2035     my $c = shift;
2036     $c->engine->prepare_connection( $c, @_ );
2037 }
2038
2039 =head2 $c->prepare_cookies
2040
2041 Prepares cookies.
2042
2043 =cut
2044
2045 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2046
2047 =head2 $c->prepare_headers
2048
2049 Prepares headers.
2050
2051 =cut
2052
2053 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2054
2055 =head2 $c->prepare_parameters
2056
2057 Prepares parameters.
2058
2059 =cut
2060
2061 sub prepare_parameters {
2062     my $c = shift;
2063     $c->prepare_body_parameters;
2064     $c->engine->prepare_parameters( $c, @_ );
2065 }
2066
2067 =head2 $c->prepare_path
2068
2069 Prepares path and base.
2070
2071 =cut
2072
2073 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2074
2075 =head2 $c->prepare_query_parameters
2076
2077 Prepares query parameters.
2078
2079 =cut
2080
2081 sub prepare_query_parameters {
2082     my $c = shift;
2083
2084     $c->engine->prepare_query_parameters( $c, @_ );
2085
2086     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
2087         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
2088         for my $key ( sort keys %{ $c->req->query_parameters } ) {
2089             my $param = $c->req->query_parameters->{$key};
2090             my $value = defined($param) ? $param : '';
2091             $t->row( $key,
2092                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2093         }
2094         $c->log->debug( "Query Parameters are:\n" . $t->draw );
2095     }
2096 }
2097
2098 =head2 $c->prepare_read
2099
2100 Prepares the input for reading.
2101
2102 =cut
2103
2104 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2105
2106 =head2 $c->prepare_request
2107
2108 Prepares the engine request.
2109
2110 =cut
2111
2112 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2113
2114 =head2 $c->prepare_uploads
2115
2116 Prepares uploads.
2117
2118 =cut
2119
2120 sub prepare_uploads {
2121     my $c = shift;
2122
2123     $c->engine->prepare_uploads( $c, @_ );
2124
2125     if ( $c->debug && keys %{ $c->request->uploads } ) {
2126         my $t = Text::SimpleTable->new(
2127             [ 12, 'Parameter' ],
2128             [ 26, 'Filename' ],
2129             [ 18, 'Type' ],
2130             [ 9,  'Size' ]
2131         );
2132         for my $key ( sort keys %{ $c->request->uploads } ) {
2133             my $upload = $c->request->uploads->{$key};
2134             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2135                 $t->row( $key, $u->filename, $u->type, $u->size );
2136             }
2137         }
2138         $c->log->debug( "File Uploads are:\n" . $t->draw );
2139     }
2140 }
2141
2142 =head2 $c->prepare_write
2143
2144 Prepares the output for writing.
2145
2146 =cut
2147
2148 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2149
2150 =head2 $c->request_class
2151
2152 Returns or sets the request class.
2153
2154 =head2 $c->response_class
2155
2156 Returns or sets the response class.
2157
2158 =head2 $c->read( [$maxlength] )
2159
2160 Reads a chunk of data from the request body. This method is designed to
2161 be used in a while loop, reading C<$maxlength> bytes on every call.
2162 C<$maxlength> defaults to the size of the request if not specified.
2163
2164 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2165 directly.
2166
2167 Warning: If you use read(), Catalyst will not process the body,
2168 so you will not be able to access POST parameters or file uploads via
2169 $c->request.  You must handle all body parsing yourself.
2170
2171 =cut
2172
2173 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2174
2175 =head2 $c->run
2176
2177 Starts the engine.
2178
2179 =cut
2180
2181 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2182
2183 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2184
2185 Sets an action in a given namespace.
2186
2187 =cut
2188
2189 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2190
2191 =head2 $c->setup_actions($component)
2192
2193 Sets up actions for a component.
2194
2195 =cut
2196
2197 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2198
2199 =head2 $c->setup_components
2200
2201 This method is called internally to set up the application's components.
2202
2203 It finds modules by calling the L<locate_components> method, expands them to
2204 package names with the L<expand_component_module> method, and then installs
2205 each component into the application.
2206
2207 The C<setup_components> config option is passed to both of the above methods.
2208
2209 Installation of each component is performed by the L<setup_component> method,
2210 below.
2211
2212 =cut
2213
2214 sub setup_components {
2215     my $class = shift;
2216
2217     my $config  = $class->config->{ setup_components };
2218
2219     my @comps = sort { length $a <=> length $b }
2220                 $class->locate_components($config);
2221     my %comps = map { $_ => 1 } @comps;
2222
2223     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2224     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2225         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2226     ) if $deprecatedcatalyst_component_names;
2227
2228     for my $component ( @comps ) {
2229
2230         # We pass ignore_loaded here so that overlay files for (e.g.)
2231         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2232         # we know M::P::O found a file on disk so this is safe
2233
2234         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2235
2236         # Needs to be done as soon as the component is loaded, as loading a sub-component
2237         # (next time round the loop) can cause us to get the wrong metaclass..
2238         $class->_controller_init_base_classes($component);
2239     }
2240
2241     for my $component (@comps) {
2242         my $instance = $class->components->{ $component } = $class->setup_component($component);
2243         my @expanded_components = $instance->can('expand_modules')
2244             ? $instance->expand_modules( $component, $config )
2245             : $class->expand_component_module( $component, $config );
2246         for my $component (@expanded_components) {
2247             next if $comps{$component};
2248             $class->_controller_init_base_classes($component); # Also cover inner packages
2249             $class->components->{ $component } = $class->setup_component($component);
2250         }
2251     }
2252 }
2253
2254 =head2 $c->locate_components( $setup_component_config )
2255
2256 This method is meant to provide a list of component modules that should be
2257 setup for the application.  By default, it will use L<Module::Pluggable>.
2258
2259 Specify a C<setup_components> config option to pass additional options directly
2260 to L<Module::Pluggable>. To add additional search paths, specify a key named
2261 C<search_extra> as an array reference. Items in the array beginning with C<::>
2262 will have the application class name prepended to them.
2263
2264 =cut
2265
2266 sub locate_components {
2267     my $class  = shift;
2268     my $config = shift;
2269
2270     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2271     my $extra   = delete $config->{ search_extra } || [];
2272
2273     push @paths, @$extra;
2274
2275     my $locator = Module::Pluggable::Object->new(
2276         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2277         %$config
2278     );
2279
2280     my @comps = $locator->plugins;
2281
2282     return @comps;
2283 }
2284
2285 =head2 $c->expand_component_module( $component, $setup_component_config )
2286
2287 Components found by C<locate_components> will be passed to this method, which
2288 is expected to return a list of component (package) names to be set up.
2289
2290 =cut
2291
2292 sub expand_component_module {
2293     my ($class, $module) = @_;
2294     return Devel::InnerPackage::list_packages( $module );
2295 }
2296
2297 =head2 $c->setup_component
2298
2299 =cut
2300
2301 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2302 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2303 #         to be loaded. There are TODO tests in Moose for this, see
2304 #         f2391d17574eff81d911b97be15ea51080500003
2305 sub _controller_init_base_classes {
2306     my ($app_class, $component) = @_;
2307     return unless $component->isa('Catalyst::Controller');
2308     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2309         Moose::Meta::Class->initialize( $class )
2310             unless find_meta($class);
2311     }
2312 }
2313
2314 sub setup_component {
2315     my( $class, $component ) = @_;
2316
2317     unless ( $component->can( 'COMPONENT' ) ) {
2318         return $component;
2319     }
2320
2321     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2322     my $config = $class->config->{ $suffix } || {};
2323     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2324     # methods also pass it. local to avoid pointlessly shitting in config
2325     # for the debug screen, as $component is already the key name.
2326     local $config->{catalyst_component_name} = $component;
2327
2328     my $instance = eval { $component->COMPONENT( $class, $config ); };
2329
2330     if ( my $error = $@ ) {
2331         chomp $error;
2332         Catalyst::Exception->throw(
2333             message => qq/Couldn't instantiate component "$component", "$error"/
2334         );
2335     }
2336
2337     unless (blessed $instance) {
2338         my $metaclass = Moose::Util::find_meta($component);
2339         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2340         my $component_method_from = $method_meta->associated_metaclass->name;
2341         my $value = defined($instance) ? $instance : 'undef';
2342         Catalyst::Exception->throw(
2343             message =>
2344             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2345         );
2346     }
2347     return $instance;
2348 }
2349
2350 =head2 $c->setup_dispatcher
2351
2352 Sets up dispatcher.
2353
2354 =cut
2355
2356 sub setup_dispatcher {
2357     my ( $class, $dispatcher ) = @_;
2358
2359     if ($dispatcher) {
2360         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2361     }
2362
2363     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2364         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2365     }
2366
2367     unless ($dispatcher) {
2368         $dispatcher = $class->dispatcher_class;
2369     }
2370
2371     Class::MOP::load_class($dispatcher);
2372
2373     # dispatcher instance
2374     $class->dispatcher( $dispatcher->new );
2375 }
2376
2377 =head2 $c->setup_engine
2378
2379 Sets up engine.
2380
2381 =cut
2382
2383 sub setup_engine {
2384     my ( $class, $engine ) = @_;
2385
2386     if ($engine) {
2387         $engine = 'Catalyst::Engine::' . $engine;
2388     }
2389
2390     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2391         $engine = 'Catalyst::Engine::' . $env;
2392     }
2393
2394     if ( $ENV{MOD_PERL} ) {
2395         my $meta = Class::MOP::get_metaclass_by_name($class);
2396
2397         # create the apache method
2398         $meta->add_method('apache' => sub { shift->engine->apache });
2399
2400         my ( $software, $version ) =
2401           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2402
2403         $version =~ s/_//g;
2404         $version =~ s/(\.[^.]+)\./$1/g;
2405
2406         if ( $software eq 'mod_perl' ) {
2407
2408             if ( !$engine ) {
2409
2410                 if ( $version >= 1.99922 ) {
2411                     $engine = 'Catalyst::Engine::Apache2::MP20';
2412                 }
2413
2414                 elsif ( $version >= 1.9901 ) {
2415                     $engine = 'Catalyst::Engine::Apache2::MP19';
2416                 }
2417
2418                 elsif ( $version >= 1.24 ) {
2419                     $engine = 'Catalyst::Engine::Apache::MP13';
2420                 }
2421
2422                 else {
2423                     Catalyst::Exception->throw( message =>
2424                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2425                 }
2426
2427             }
2428
2429             # install the correct mod_perl handler
2430             if ( $version >= 1.9901 ) {
2431                 *handler = sub  : method {
2432                     shift->handle_request(@_);
2433                 };
2434             }
2435             else {
2436                 *handler = sub ($$) { shift->handle_request(@_) };
2437             }
2438
2439         }
2440
2441         elsif ( $software eq 'Zeus-Perl' ) {
2442             $engine = 'Catalyst::Engine::Zeus';
2443         }
2444
2445         else {
2446             Catalyst::Exception->throw(
2447                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2448         }
2449     }
2450
2451     unless ($engine) {
2452         $engine = $class->engine_class;
2453     }
2454
2455     Class::MOP::load_class($engine);
2456
2457     # check for old engines that are no longer compatible
2458     my $old_engine;
2459     if ( $engine->isa('Catalyst::Engine::Apache')
2460         && !Catalyst::Engine::Apache->VERSION )
2461     {
2462         $old_engine = 1;
2463     }
2464
2465     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2466         && Catalyst::Engine::Server->VERSION le '0.02' )
2467     {
2468         $old_engine = 1;
2469     }
2470
2471     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2472         && $engine->VERSION eq '0.01' )
2473     {
2474         $old_engine = 1;
2475     }
2476
2477     elsif ($engine->isa('Catalyst::Engine::Zeus')
2478         && $engine->VERSION eq '0.01' )
2479     {
2480         $old_engine = 1;
2481     }
2482
2483     if ($old_engine) {
2484         Catalyst::Exception->throw( message =>
2485               qq/Engine "$engine" is not supported by this version of Catalyst/
2486         );
2487     }
2488
2489     # engine instance
2490     $class->engine( $engine->new );
2491 }
2492
2493 =head2 $c->setup_home
2494
2495 Sets up the home directory.
2496
2497 =cut
2498
2499 sub setup_home {
2500     my ( $class, $home ) = @_;
2501
2502     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2503         $home = $env;
2504     }
2505
2506     $home ||= Catalyst::Utils::home($class);
2507
2508     if ($home) {
2509         #I remember recently being scolded for assigning config values like this
2510         $class->config->{home} ||= $home;
2511         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2512     }
2513 }
2514
2515 =head2 $c->setup_log
2516
2517 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2518 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2519 log to.
2520
2521 This method also installs a C<debug> method that returns a true value into the
2522 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2523 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2524
2525 Note that if the log has already been setup, by either a previous call to
2526 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2527 that this method won't actually set up the log object.
2528
2529 =cut
2530
2531 sub setup_log {
2532     my ( $class, $levels ) = @_;
2533
2534     $levels ||= '';
2535     $levels =~ s/^\s+//;
2536     $levels =~ s/\s+$//;
2537     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2538
2539     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2540     if ( defined $env_debug ) {
2541         $levels{debug} = 1 if $env_debug; # Ugly!
2542         delete($levels{debug}) unless $env_debug;
2543     }
2544
2545     unless ( $class->log ) {
2546         $class->log( Catalyst::Log->new(keys %levels) );
2547     }
2548
2549     if ( $levels{debug} ) {
2550         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2551         $class->log->debug('Debug messages enabled');
2552     }
2553 }
2554
2555 =head2 $c->setup_plugins
2556
2557 Sets up plugins.
2558
2559 =cut
2560
2561 =head2 $c->setup_stats
2562
2563 Sets up timing statistics class.
2564
2565 =cut
2566
2567 sub setup_stats {
2568     my ( $class, $stats ) = @_;
2569
2570     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2571
2572     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2573     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2574         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2575         $class->log->debug('Statistics enabled');
2576     }
2577 }
2578
2579
2580 =head2 $c->registered_plugins
2581
2582 Returns a sorted list of the plugins which have either been stated in the
2583 import list or which have been added via C<< MyApp->plugin(@args); >>.
2584
2585 If passed a given plugin name, it will report a boolean value indicating
2586 whether or not that plugin is loaded.  A fully qualified name is required if
2587 the plugin name does not begin with C<Catalyst::Plugin::>.
2588
2589  if ($c->registered_plugins('Some::Plugin')) {
2590      ...
2591  }
2592
2593 =cut
2594
2595 {
2596
2597     sub registered_plugins {
2598         my $proto = shift;
2599         return sort keys %{ $proto->_plugins } unless @_;
2600         my $plugin = shift;
2601         return 1 if exists $proto->_plugins->{$plugin};
2602         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2603     }
2604
2605     sub _register_plugin {
2606         my ( $proto, $plugin, $instant ) = @_;
2607         my $class = ref $proto || $proto;
2608
2609         Class::MOP::load_class( $plugin );
2610         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2611             if $plugin->isa( 'Catalyst::Component' );
2612         $proto->_plugins->{$plugin} = 1;
2613         unless ($instant) {
2614             no strict 'refs';
2615             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2616               my @superclasses = ($plugin, $meta->superclasses );
2617               $meta->superclasses(@superclasses);
2618             } else {
2619               unshift @{"$class\::ISA"}, $plugin;
2620             }
2621         }
2622         return $class;
2623     }
2624
2625     sub setup_plugins {
2626         my ( $class, $plugins ) = @_;
2627
2628         $class->_plugins( {} ) unless $class->_plugins;
2629         $plugins ||= [];
2630
2631         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2632
2633         for my $plugin ( reverse @plugins ) {
2634             Class::MOP::load_class($plugin);
2635             my $meta = find_meta($plugin);
2636             next if $meta && $meta->isa('Moose::Meta::Role');
2637
2638             $class->_register_plugin($plugin);
2639         }
2640
2641         my @roles =
2642             map { $_->name }
2643             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2644             map { find_meta($_) }
2645             @plugins;
2646
2647         Moose::Util::apply_all_roles(
2648             $class => @roles
2649         ) if @roles;
2650     }
2651 }
2652
2653 =head2 $c->stack
2654
2655 Returns an arrayref of the internal execution stack (actions that are
2656 currently executing).
2657
2658 =head2 $c->stats_class
2659
2660 Returns or sets the stats (timing statistics) class.
2661
2662 =head2 $c->use_stats
2663
2664 Returns 1 when stats collection is enabled.  Stats collection is enabled
2665 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2666 environment variable is set.
2667
2668 Note that this is a static method, not an accessor and should be overridden
2669 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2670
2671 =cut
2672
2673 sub use_stats { 0 }
2674
2675
2676 =head2 $c->write( $data )
2677
2678 Writes $data to the output stream. When using this method directly, you
2679 will need to manually set the C<Content-Length> header to the length of
2680 your output data, if known.
2681
2682 =cut
2683
2684 sub write {
2685     my $c = shift;
2686
2687     # Finalize headers if someone manually writes output
2688     $c->finalize_headers;
2689
2690     return $c->engine->write( $c, @_ );
2691 }
2692
2693 =head2 version
2694
2695 Returns the Catalyst version number. Mostly useful for "powered by"
2696 messages in template systems.
2697
2698 =cut
2699
2700 sub version { return $Catalyst::VERSION }
2701
2702 =head1 CONFIGURATION
2703
2704 There are a number of 'base' config variables which can be set:
2705
2706 =over
2707
2708 =item *
2709
2710 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2711
2712 =item *
2713
2714 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2715
2716 =item *
2717
2718 C<disable_component_resolution_regex_fallback> - Turns
2719 off the deprecated component resolution functionality so
2720 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2721 are called then regex search will not be attempted on string values and
2722 instead C<undef> will be returned.
2723
2724 =item *
2725
2726 C<home> - The application home directory. In an uninstalled application,
2727 this is the top level application directory. In an installed application,
2728 this will be the directory containing C<< MyApp.pm >>.
2729
2730 =item *
2731
2732 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2733
2734 =item *
2735
2736 C<name> - The name of the application in debug messages and the debug and
2737 welcome screens
2738
2739 =item *
2740
2741 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2742 until it is accessed. This allows you to (for example) check authentication (and reject
2743 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2744
2745 =item *
2746
2747 C<root> - The root directory for templates. Usually this is just a
2748 subdirectory of the home directory, but you can set it to change the
2749 templates to a different directory.
2750
2751 =item *
2752
2753 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2754 namespaces from which components will be loaded (and constructed and stored in
2755 C<< $c->components >>).
2756
2757 =item *
2758
2759 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2760 to be shown in hit debug tables in the test server.
2761
2762 =item *
2763
2764 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2765
2766 =back
2767
2768 =head1 INTERNAL ACTIONS
2769
2770 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2771 C<_ACTION>, and C<_END>. These are by default not shown in the private
2772 action table, but you can make them visible with a config parameter.
2773
2774     MyApp->config(show_internal_actions => 1);
2775
2776 =head1 ON-DEMAND PARSER
2777
2778 The request body is usually parsed at the beginning of a request,
2779 but if you want to handle input yourself, you can enable on-demand
2780 parsing with a config parameter.
2781
2782     MyApp->config(parse_on_demand => 1);
2783
2784 =head1 PROXY SUPPORT
2785
2786 Many production servers operate using the common double-server approach,
2787 with a lightweight frontend web server passing requests to a larger
2788 backend server. An application running on the backend server must deal
2789 with two problems: the remote user always appears to be C<127.0.0.1> and
2790 the server's hostname will appear to be C<localhost> regardless of the
2791 virtual host that the user connected through.
2792
2793 Catalyst will automatically detect this situation when you are running
2794 the frontend and backend servers on the same machine. The following
2795 changes are made to the request.
2796
2797     $c->req->address is set to the user's real IP address, as read from
2798     the HTTP X-Forwarded-For header.
2799
2800     The host value for $c->req->base and $c->req->uri is set to the real
2801     host, as read from the HTTP X-Forwarded-Host header.
2802
2803 Additionally, you may be running your backend application on an insecure
2804 connection (port 80) while your frontend proxy is running under SSL.  If there
2805 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2806 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2807 be created properly.
2808
2809 In the case of passing in:
2810
2811     X-Forwarded-Port: 443
2812
2813 All calls to C<uri_for> will result in an https link, as is expected.
2814
2815 Obviously, your web server must support these headers for this to work.
2816
2817 In a more complex server farm environment where you may have your
2818 frontend proxy server(s) on different machines, you will need to set a
2819 configuration option to tell Catalyst to read the proxied data from the
2820 headers.
2821
2822     MyApp->config(using_frontend_proxy => 1);
2823
2824 If you do not wish to use the proxy support at all, you may set:
2825
2826     MyApp->config(ignore_frontend_proxy => 1);
2827
2828 =head1 THREAD SAFETY
2829
2830 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2831 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2832 believe the Catalyst core to be thread-safe.
2833
2834 If you plan to operate in a threaded environment, remember that all other
2835 modules you are using must also be thread-safe. Some modules, most notably
2836 L<DBD::SQLite>, are not thread-safe.
2837
2838 =head1 SUPPORT
2839
2840 IRC:
2841
2842     Join #catalyst on irc.perl.org.
2843
2844 Mailing Lists:
2845
2846     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2847     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2848
2849 Web:
2850
2851     http://catalyst.perl.org
2852
2853 Wiki:
2854
2855     http://dev.catalyst.perl.org
2856
2857 =head1 SEE ALSO
2858
2859 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2860
2861 =head2 L<Catalyst::Manual> - The Catalyst Manual
2862
2863 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
2864
2865 =head2 L<Catalyst::Engine> - Core engine
2866
2867 =head2 L<Catalyst::Log> - Log class.
2868
2869 =head2 L<Catalyst::Request> - Request object
2870
2871 =head2 L<Catalyst::Response> - Response object
2872
2873 =head2 L<Catalyst::Test> - The test suite.
2874
2875 =head1 PROJECT FOUNDER
2876
2877 sri: Sebastian Riedel <sri@cpan.org>
2878
2879 =head1 CONTRIBUTORS
2880
2881 abw: Andy Wardley
2882
2883 acme: Leon Brocard <leon@astray.com>
2884
2885 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
2886
2887 Andrew Bramble
2888
2889 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
2890
2891 Andrew Ruthven
2892
2893 andyg: Andy Grundman <andy@hybridized.org>
2894
2895 audreyt: Audrey Tang
2896
2897 bricas: Brian Cassidy <bricas@cpan.org>
2898
2899 Caelum: Rafael Kitover <rkitover@io.com>
2900
2901 chansen: Christian Hansen
2902
2903 chicks: Christopher Hicks
2904
2905 Chisel Wright C<pause@herlpacker.co.uk>
2906
2907 Danijel Milicevic C<me@danijel.de>
2908
2909 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
2910
2911 David Naughton, C<naughton@umn.edu>
2912
2913 David E. Wheeler
2914
2915 dhoss: Devin Austin <dhoss@cpan.org>
2916
2917 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2918
2919 Drew Taylor
2920
2921 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
2922
2923 esskar: Sascha Kiefer
2924
2925 fireartist: Carl Franks <cfranks@cpan.org>
2926
2927 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
2928
2929 gabb: Danijel Milicevic
2930
2931 Gary Ashton Jones
2932
2933 Gavin Henry C<ghenry@perl.me.uk>
2934
2935 Geoff Richards
2936
2937 groditi: Guillermo Roditi <groditi@gmail.com>
2938
2939 hobbs: Andrew Rodland <andrew@cleverdomain.org>
2940
2941 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2942
2943 jcamacho: Juan Camacho
2944
2945 jester: Jesse Sheidlower C<jester@panix.com>
2946
2947 jhannah: Jay Hannah <jay@jays.net>
2948
2949 Jody Belka
2950
2951 Johan Lindstrom
2952
2953 jon: Jon Schutz <jjschutz@cpan.org>
2954
2955 Jonathan Rockway C<< <jrockway@cpan.org> >>
2956
2957 Kieren Diment C<kd@totaldatasolution.com>
2958
2959 konobi: Scott McWhirter <konobi@cpan.org>
2960
2961 marcus: Marcus Ramberg <mramberg@cpan.org>
2962
2963 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2964
2965 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2966
2967 mugwump: Sam Vilain
2968
2969 naughton: David Naughton
2970
2971 ningu: David Kamholz <dkamholz@cpan.org>
2972
2973 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2974
2975 numa: Dan Sully <daniel@cpan.org>
2976
2977 obra: Jesse Vincent
2978
2979 Octavian Rasnita
2980
2981 omega: Andreas Marienborg
2982
2983 Oleg Kostyuk <cub.uanic@gmail.com>
2984
2985 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2986
2987 rafl: Florian Ragwitz <rafl@debian.org>
2988
2989 random: Roland Lammel <lammel@cpan.org>
2990
2991 Robert Sedlacek C<< <rs@474.at> >>
2992
2993 sky: Arthur Bergman
2994
2995 t0m: Tomas Doran <bobtfish@bobtfish.net>
2996
2997 Ulf Edvinsson
2998
2999 Viljo Marrandi C<vilts@yahoo.com>
3000
3001 Will Hawes C<info@whawes.co.uk>
3002
3003 willert: Sebastian Willert <willert@cpan.org>
3004
3005 Yuval Kogman, C<nothingmuch@woobling.org>
3006
3007 =head1 LICENSE
3008
3009 This library is free software. You can redistribute it and/or modify it under
3010 the same terms as Perl itself.
3011
3012 =cut
3013
3014 no Moose;
3015
3016 __PACKAGE__->meta->make_immutable;
3017
3018 1;