lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53
  54 BEGIN { require 5.008003; }
  55
  56 has stack => (is => 'ro', default => sub { [] });
  57 has state => (is => 'rw', default => 0);
  58 has stats => (is => 'rw');
  59 has action => (is => 'rw');
  60 has counter => (is => 'rw', default => sub { {} });
  61 has request => (
  62     is => 'rw',
  63     default => sub {
  64         my $self = shift;
  65         $self->request_class->new($self->_build_request_constructor_args);
  66     },
  67     lazy => 1,
  68 );
  69 sub _build_request_constructor_args {
  70     my $self = shift;
  71     my %p = ( _log => $self->log );
  72     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  73     $p{data_handlers} = {$self->registered_data_handlers};
  74     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  75       if $self->config->{use_hash_multivalue_in_request};
  76     \%p;
  77 }
  78
  79 has response => (
  80     is => 'rw',
  81     default => sub {
  82         my $self = shift;
  83         $self->response_class->new($self->_build_response_constructor_args);
  84     },
  85     lazy => 1,
  86 );
  87 sub _build_response_constructor_args {
  88     my $self = shift;
  89     { _log => $self->log };
  90 }
  91
  92 has namespace => (is => 'rw');
  93
  94 sub depth { scalar @{ shift->stack || [] }; }
  95 sub comp { shift->component(@_) }
  96
  97 sub req {
  98     my $self = shift; return $self->request(@_);
  99 }
 100 sub res {
 101     my $self = shift; return $self->response(@_);
 102 }
 103
 104 # For backwards compatibility
 105 sub finalize_output { shift->finalize_body(@_) };
 106
 107 # For statistics
 108 our $COUNT     = 1;
 109 our $START     = time;
 110 our $RECURSION = 1000;
 111 our $DETACH    = Catalyst::Exception::Detach->new;
 112 our $GO        = Catalyst::Exception::Go->new;
 113
 114 #I imagine that very few of these really need to be class variables. if any.
 115 #maybe we should just make them attributes with a default?
 116 __PACKAGE__->mk_classdata($_)
 117   for qw/components arguments dispatcher engine log dispatcher_class
 118   engine_loader context_class request_class response_class stats_class
 119   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 120   _data_handlers/;
 121
 122 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 123 __PACKAGE__->request_class('Catalyst::Request');
 124 __PACKAGE__->response_class('Catalyst::Response');
 125 __PACKAGE__->stats_class('Catalyst::Stats');
 126
 127 # Remember to update this in Catalyst::Runtime as well!
 128
 129 our $VERSION = '5.90069_002';
 130
 131 sub import {
 132     my ( $class, @arguments ) = @_;
 133
 134     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 135     # callers @ISA.
 136     return unless $class eq 'Catalyst';
 137
 138     my $caller = caller();
 139     return if $caller eq 'main';
 140
 141     my $meta = Moose::Meta::Class->initialize($caller);
 142     unless ( $caller->isa('Catalyst') ) {
 143         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 144         $meta->superclasses(@superclasses);
 145     }
 146     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 147     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 148
 149     unless( $meta->has_method('meta') ){
 150         if ($Moose::VERSION >= 1.15) {
 151             $meta->_add_meta_method('meta');
 152         }
 153         else {
 154             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 155         }
 156     }
 157
 158     $caller->arguments( [@arguments] );
 159     $caller->setup_home;
 160 }
 161
 162 sub _application { $_[0] }
 163
 164 =encoding UTF-8
 165
 166 =head1 NAME
 167
 168 Catalyst - The Elegant MVC Web Application Framework
 169
 170 =head1 SYNOPSIS
 171
 172 See the L<Catalyst::Manual> distribution for comprehensive
 173 documentation and tutorials.
 174
 175     # Install Catalyst::Devel for helpers and other development tools
 176     # use the helper to create a new application
 177     catalyst.pl MyApp
 178
 179     # add models, views, controllers
 180     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 181     script/myapp_create.pl view MyTemplate TT
 182     script/myapp_create.pl controller Search
 183
 184     # built in testserver -- use -r to restart automatically on changes
 185     # --help to see all available options
 186     script/myapp_server.pl
 187
 188     # command line testing interface
 189     script/myapp_test.pl /yada
 190
 191     ### in lib/MyApp.pm
 192     use Catalyst qw/-Debug/; # include plugins here as well
 193
 194     ### In lib/MyApp/Controller/Root.pm (autocreated)
 195     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 196         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 197         $c->stash->{template} = 'foo.tt'; # set the template
 198         # lookup something from db -- stash vars are passed to TT
 199         $c->stash->{data} =
 200           $c->model('Database::Foo')->search( { country => $args[0] } );
 201         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 202             $c->forward( 'bar' ); # process another action
 203             # do something else after forward returns
 204         }
 205     }
 206
 207     # The foo.tt TT template can use the stash data from the database
 208     [% WHILE (item = data.next) %]
 209         [% item.foo %]
 210     [% END %]
 211
 212     # called for /bar/of/soap, /bar/of/soap/10, etc.
 213     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 214
 215     # called after all actions are finished
 216     sub end : Action {
 217         my ( $self, $c ) = @_;
 218         if ( scalar @{ $c->error } ) { ... } # handle errors
 219         return if $c->res->body; # already have a response
 220         $c->forward( 'MyApp::View::TT' ); # render template
 221     }
 222
 223 See L<Catalyst::Manual::Intro> for additional information.
 224
 225 =head1 DESCRIPTION
 226
 227 Catalyst is a modern framework for making web applications without the
 228 pain usually associated with this process. This document is a reference
 229 to the main Catalyst application. If you are a new user, we suggest you
 230 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 231
 232 See L<Catalyst::Manual> for more documentation.
 233
 234 Catalyst plugins can be loaded by naming them as arguments to the "use
 235 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 236 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 237 C<My::Module>.
 238
 239     use Catalyst qw/My::Module/;
 240
 241 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 242 fully qualify the name by using a unary plus:
 243
 244     use Catalyst qw/
 245         My::Module
 246         +Fully::Qualified::Plugin::Name
 247     /;
 248
 249 Special flags like C<-Debug> can also be specified as
 250 arguments when Catalyst is loaded:
 251
 252     use Catalyst qw/-Debug My::Module/;
 253
 254 The position of plugins and flags in the chain is important, because
 255 they are loaded in the order in which they appear.
 256
 257 The following flags are supported:
 258
 259 =head2 -Debug
 260
 261 Enables debug output. You can also force this setting from the system
 262 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 263 settings override the application, with <MYAPP>_DEBUG having the highest
 264 priority.
 265
 266 This sets the log level to 'debug' and enables full debug output on the
 267 error screen. If you only want the latter, see L<< $c->debug >>.
 268
 269 =head2 -Home
 270
 271 Forces Catalyst to use a specific home directory, e.g.:
 272
 273     use Catalyst qw[-Home=/usr/mst];
 274
 275 This can also be done in the shell environment by setting either the
 276 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 277 is replaced with the uppercased name of your application, any "::" in
 278 the name will be replaced with underscores, e.g. MyApp::Web should use
 279 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 280
 281 If none of these are set, Catalyst will attempt to automatically detect the
 282 home directory. If you are working in a development environment, Catalyst
 283 will try and find the directory containing either Makefile.PL, Build.PL,
 284 dist.ini, or cpanfile. If the application has been installed into the system
 285 (i.e. you have done C<make install>), then Catalyst will use the path to your
 286 application module, without the .pm extension (e.g., /foo/MyApp if your
 287 application was installed at /foo/MyApp.pm)
 288
 289 =head2 -Log
 290
 291     use Catalyst '-Log=warn,fatal,error';
 292
 293 Specifies a comma-delimited list of log levels.
 294
 295 =head2 -Stats
 296
 297 Enables statistics collection and reporting.
 298
 299    use Catalyst qw/-Stats=1/;
 300
 301 You can also force this setting from the system environment with CATALYST_STATS
 302 or <MYAPP>_STATS. The environment settings override the application, with
 303 <MYAPP>_STATS having the highest priority.
 304
 305 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 306
 307 =head1 METHODS
 308
 309 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 310
 311 =head2 $c->action
 312
 313 Returns a L<Catalyst::Action> object for the current action, which
 314 stringifies to the action name. See L<Catalyst::Action>.
 315
 316 =head2 $c->namespace
 317
 318 Returns the namespace of the current action, i.e., the URI prefix
 319 corresponding to the controller of the current action. For example:
 320
 321     # in Controller::Foo::Bar
 322     $c->namespace; # returns 'foo/bar';
 323
 324 =head2 $c->request
 325
 326 =head2 $c->req
 327
 328 Returns the current L<Catalyst::Request> object, giving access to
 329 information about the current client request (including parameters,
 330 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 331
 332 =head2 REQUEST FLOW HANDLING
 333
 334 =head2 $c->forward( $action [, \@arguments ] )
 335
 336 =head2 $c->forward( $class, $method, [, \@arguments ] )
 337
 338 This is one way of calling another action (method) in the same or
 339 a different controller. You can also use C<< $self->my_method($c, @args) >>
 340 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 341 in a different controller.
 342 The main difference is that 'forward' uses some of the Catalyst request
 343 cycle overhead, including debugging, which may be useful to you. On the
 344 other hand, there are some complications to using 'forward', restrictions
 345 on values returned from 'forward', and it may not handle errors as you prefer.
 346 Whether you use 'forward' or not is up to you; it is not considered superior to
 347 the other ways to call a method.
 348
 349 'forward' calls  another action, by its private name. If you give a
 350 class name but no method, C<process()> is called. You may also optionally
 351 pass arguments in an arrayref. The action will receive the arguments in
 352 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 353 C<< $c->req->args >> will be restored to the previous values.
 354
 355 Any data C<return>ed from the action forwarded to, will be returned by the
 356 call to forward.
 357
 358     my $foodata = $c->forward('/foo');
 359     $c->forward('index');
 360     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 361     $c->forward('View::TT');
 362
 363 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 364 an C<< eval { } >> around the call (actually
 365 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 366 exceptions thrown by the called action non-fatal and pushing them onto
 367 $c->error instead. If you want C<die> to propagate you need to do something
 368 like:
 369
 370     $c->forward('foo');
 371     die join "\n", @{ $c->error } if @{ $c->error };
 372
 373 Or make sure to always return true values from your actions and write
 374 your code like this:
 375
 376     $c->forward('foo') || return;
 377
 378 Another note is that C<< $c->forward >> always returns a scalar because it
 379 actually returns $c->state which operates in a scalar context.
 380 Thus, something like:
 381
 382     return @array;
 383
 384 in an action that is forwarded to is going to return a scalar,
 385 i.e. how many items are in that array, which is probably not what you want.
 386 If you need to return an array then return a reference to it,
 387 or stash it like so:
 388
 389     $c->stash->{array} = \@array;
 390
 391 and access it from the stash.
 392
 393 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 394
 395 =cut
 396
 397 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 398
 399 =head2 $c->detach( $action [, \@arguments ] )
 400
 401 =head2 $c->detach( $class, $method, [, \@arguments ] )
 402
 403 =head2 $c->detach()
 404
 405 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 406 doesn't return to the previous action when processing is finished.
 407
 408 When called with no arguments it escapes the processing chain entirely.
 409
 410 =cut
 411
 412 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 413
 414 =head2 $c->visit( $action [, \@arguments ] )
 415
 416 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 417
 418 =head2 $c->visit( $class, $method, [, \@arguments ] )
 419
 420 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 421
 422 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 423 but does a full dispatch, instead of just calling the new C<$action> /
 424 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 425 you go to are called, just like a new request.
 426
 427 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 428 This means, for example, that C<< $c->action >> methods such as
 429 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 430 L<reverse|Catalyst::Action/reverse> return information for the visited action
 431 when they are invoked within the visited action.  This is different from the
 432 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 433 continues to use the $c->action object from the caller action even when
 434 invoked from the called action.
 435
 436 C<< $c->stash >> is kept unchanged.
 437
 438 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 439 allows you to "wrap" another action, just as it would have been called by
 440 dispatching from a URL, while the analogous
 441 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 442 transfer control to another action as if it had been reached directly from a URL.
 443
 444 =cut
 445
 446 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 447
 448 =head2 $c->go( $action [, \@arguments ] )
 449
 450 =head2 $c->go( $action [, \@captures, \@arguments ] )
 451
 452 =head2 $c->go( $class, $method, [, \@arguments ] )
 453
 454 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 455
 456 The relationship between C<go> and
 457 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 458 the relationship between
 459 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 460 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 461 C<< $c->go >> will perform a full dispatch on the specified action or method,
 462 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 463 C<go> escapes the processing of the current request chain on completion, and
 464 does not return to its caller.
 465
 466 @arguments are arguments to the final destination of $action. @captures are
 467 arguments to the intermediate steps, if any, on the way to the final sub of
 468 $action.
 469
 470 =cut
 471
 472 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 473
 474 =head2 $c->response
 475
 476 =head2 $c->res
 477
 478 Returns the current L<Catalyst::Response> object, see there for details.
 479
 480 =head2 $c->stash
 481
 482 Returns a hashref to the stash, which may be used to store data and pass
 483 it between components during a request. You can also set hash keys by
 484 passing arguments. The stash is automatically sent to the view. The
 485 stash is cleared at the end of a request; it cannot be used for
 486 persistent storage (for this you must use a session; see
 487 L<Catalyst::Plugin::Session> for a complete system integrated with
 488 Catalyst).
 489
 490     $c->stash->{foo} = $bar;
 491     $c->stash( { moose => 'majestic', qux => 0 } );
 492     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 493
 494     # stash is automatically passed to the view for use in a template
 495     $c->forward( 'MyApp::View::TT' );
 496
 497 =cut
 498
 499 sub stash {
 500   my $c = shift;
 501   my $stash = Catalyst::Middleware::Stash->get($c->req->env);
 502   if(@_) {
 503     my $new_stash = @_ > 1 ? {@_} : $_[0];
 504     croak('stash takes a hash or hashref') unless ref $new_stash;
 505     foreach my $key ( keys %$new_stash ) {
 506       $stash->{$key} = $new_stash->{$key};
 507     }
 508   }
 509   return $stash;
 510 }
 511
 512 =head2 $c->error
 513
 514 =head2 $c->error($error, ...)
 515
 516 =head2 $c->error($arrayref)
 517
 518 Returns an arrayref containing error messages.  If Catalyst encounters an
 519 error while processing a request, it stores the error in $c->error.  This
 520 method should only be used to store fatal error messages.
 521
 522     my @error = @{ $c->error };
 523
 524 Add a new error.
 525
 526     $c->error('Something bad happened');
 527
 528 =cut
 529
 530 sub error {
 531     my $c = shift;
 532     if ( $_[0] ) {
 533         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 534         croak @$error unless ref $c;
 535         push @{ $c->{error} }, @$error;
 536     }
 537     elsif ( defined $_[0] ) { $c->{error} = undef }
 538     return $c->{error} || [];
 539 }
 540
 541
 542 =head2 $c->state
 543
 544 Contains the return value of the last executed action.
 545 Note that << $c->state >> operates in a scalar context which means that all
 546 values it returns are scalar.
 547
 548 =head2 $c->clear_errors
 549
 550 Clear errors.  You probably don't want to clear the errors unless you are
 551 implementing a custom error screen.
 552
 553 This is equivalent to running
 554
 555     $c->error(0);
 556
 557 =cut
 558
 559 sub clear_errors {
 560     my $c = shift;
 561     $c->error(0);
 562 }
 563
 564 =head2 $c->has_errors
 565
 566 Returns true if you have errors
 567
 568 =cut
 569
 570 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 571
 572 sub _comp_search_prefixes {
 573     my $c = shift;
 574     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 575 }
 576
 577 # search components given a name and some prefixes
 578 sub _comp_names_search_prefixes {
 579     my ( $c, $name, @prefixes ) = @_;
 580     my $appclass = ref $c || $c;
 581     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 582     $filter = qr/$filter/; # Compile regex now rather than once per loop
 583
 584     # map the original component name to the sub part that we will search against
 585     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 586         grep { /$filter/ } keys %{ $c->components };
 587
 588     # undef for a name will return all
 589     return keys %eligible if !defined $name;
 590
 591     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 592     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 593
 594     return @result if @result;
 595
 596     # if we were given a regexp to search against, we're done.
 597     return if $name->$_isa('Regexp');
 598
 599     # skip regexp fallback if configured
 600     return
 601         if $appclass->config->{disable_component_resolution_regex_fallback};
 602
 603     # regexp fallback
 604     $query  = qr/$name/i;
 605     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 606
 607     # no results? try against full names
 608     if( !@result ) {
 609         @result = grep { m{$query} } keys %eligible;
 610     }
 611
 612     # don't warn if we didn't find any results, it just might not exist
 613     if( @result ) {
 614         # Disgusting hack to work out correct method name
 615         my $warn_for = lc $prefixes[0];
 616         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 617            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 618            "component resolution is unreliable and unsafe.";
 619         my $short = $result[0];
 620         # remove the component namespace prefix
 621         $short =~ s/.*?(Model|Controller|View):://;
 622         my $shortmess = Carp::shortmess('');
 623         if ($shortmess =~ m#Catalyst/Plugin#) {
 624            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 625               "plugin's config";
 626         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 627            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 628               "component's config";
 629         } else {
 630            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 631               "but if you really wanted to search, pass in a regexp as the argument " .
 632               "like so: \$c->${warn_for}(qr/${name}/)";
 633         }
 634         $c->log->warn( "${msg}$shortmess" );
 635     }
 636
 637     return @result;
 638 }
 639
 640 # Find possible names for a prefix
 641 sub _comp_names {
 642     my ( $c, @prefixes ) = @_;
 643     my $appclass = ref $c || $c;
 644
 645     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 646
 647     my @names = map { s{$filter}{}; $_; }
 648         $c->_comp_names_search_prefixes( undef, @prefixes );
 649
 650     return @names;
 651 }
 652
 653 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 654 sub _filter_component {
 655     my ( $c, $comp, @args ) = @_;
 656
 657     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 658         return $comp->ACCEPT_CONTEXT( $c, @args );
 659     }
 660
 661     return $comp;
 662 }
 663
 664 =head2 COMPONENT ACCESSORS
 665
 666 =head2 $c->controller($name)
 667
 668 Gets a L<Catalyst::Controller> instance by name.
 669
 670     $c->controller('Foo')->do_stuff;
 671
 672 If the name is omitted, will return the controller for the dispatched
 673 action.
 674
 675 If you want to search for controllers, pass in a regexp as the argument.
 676
 677     # find all controllers that start with Foo
 678     my @foo_controllers = $c->controller(qr{^Foo});
 679
 680
 681 =cut
 682
 683 sub controller {
 684     my ( $c, $name, @args ) = @_;
 685
 686     my $appclass = ref($c) || $c;
 687     if( $name ) {
 688         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 689             my $comps = $c->components;
 690             my $check = $appclass."::Controller::".$name;
 691             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 692         }
 693         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 694         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 695         return $c->_filter_component( $result[ 0 ], @args );
 696     }
 697
 698     return $c->component( $c->action->class );
 699 }
 700
 701 =head2 $c->model($name)
 702
 703 Gets a L<Catalyst::Model> instance by name.
 704
 705     $c->model('Foo')->do_stuff;
 706
 707 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 708
 709 If the name is omitted, it will look for
 710  - a model object in $c->stash->{current_model_instance}, then
 711  - a model name in $c->stash->{current_model}, then
 712  - a config setting 'default_model', or
 713  - check if there is only one model, and return it if that's the case.
 714
 715 If you want to search for models, pass in a regexp as the argument.
 716
 717     # find all models that start with Foo
 718     my @foo_models = $c->model(qr{^Foo});
 719
 720 =cut
 721
 722 sub model {
 723     my ( $c, $name, @args ) = @_;
 724     my $appclass = ref($c) || $c;
 725     if( $name ) {
 726         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 727             my $comps = $c->components;
 728             my $check = $appclass."::Model::".$name;
 729             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 730         }
 731         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 732         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 733         return $c->_filter_component( $result[ 0 ], @args );
 734     }
 735
 736     if (ref $c) {
 737         return $c->stash->{current_model_instance}
 738           if $c->stash->{current_model_instance};
 739         return $c->model( $c->stash->{current_model} )
 740           if $c->stash->{current_model};
 741     }
 742     return $c->model( $appclass->config->{default_model} )
 743       if $appclass->config->{default_model};
 744
 745     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 746
 747     if( $rest ) {
 748         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 749         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 750         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 751         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 752         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 753     }
 754
 755     return $c->_filter_component( $comp );
 756 }
 757
 758
 759 =head2 $c->view($name)
 760
 761 Gets a L<Catalyst::View> instance by name.
 762
 763     $c->view('Foo')->do_stuff;
 764
 765 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 766
 767 If the name is omitted, it will look for
 768  - a view object in $c->stash->{current_view_instance}, then
 769  - a view name in $c->stash->{current_view}, then
 770  - a config setting 'default_view', or
 771  - check if there is only one view, and return it if that's the case.
 772
 773 If you want to search for views, pass in a regexp as the argument.
 774
 775     # find all views that start with Foo
 776     my @foo_views = $c->view(qr{^Foo});
 777
 778 =cut
 779
 780 sub view {
 781     my ( $c, $name, @args ) = @_;
 782
 783     my $appclass = ref($c) || $c;
 784     if( $name ) {
 785         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 786             my $comps = $c->components;
 787             my $check = $appclass."::View::".$name;
 788             if( exists $comps->{$check} ) {
 789                 return $c->_filter_component( $comps->{$check}, @args );
 790             }
 791             else {
 792                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 793             }
 794         }
 795         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 796         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 797         return $c->_filter_component( $result[ 0 ], @args );
 798     }
 799
 800     if (ref $c) {
 801         return $c->stash->{current_view_instance}
 802           if $c->stash->{current_view_instance};
 803         return $c->view( $c->stash->{current_view} )
 804           if $c->stash->{current_view};
 805     }
 806     return $c->view( $appclass->config->{default_view} )
 807       if $appclass->config->{default_view};
 808
 809     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 810
 811     if( $rest ) {
 812         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 813         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 814         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 815         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 816         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 817     }
 818
 819     return $c->_filter_component( $comp );
 820 }
 821
 822 =head2 $c->controllers
 823
 824 Returns the available names which can be passed to $c->controller
 825
 826 =cut
 827
 828 sub controllers {
 829     my ( $c ) = @_;
 830     return $c->_comp_names(qw/Controller C/);
 831 }
 832
 833 =head2 $c->models
 834
 835 Returns the available names which can be passed to $c->model
 836
 837 =cut
 838
 839 sub models {
 840     my ( $c ) = @_;
 841     return $c->_comp_names(qw/Model M/);
 842 }
 843
 844
 845 =head2 $c->views
 846
 847 Returns the available names which can be passed to $c->view
 848
 849 =cut
 850
 851 sub views {
 852     my ( $c ) = @_;
 853     return $c->_comp_names(qw/View V/);
 854 }
 855
 856 =head2 $c->comp($name)
 857
 858 =head2 $c->component($name)
 859
 860 Gets a component object by name. This method is not recommended,
 861 unless you want to get a specific component by full
 862 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 863 should be used instead.
 864
 865 If C<$name> is a regexp, a list of components matched against the full
 866 component name will be returned.
 867
 868 If Catalyst can't find a component by name, it will fallback to regex
 869 matching by default. To disable this behaviour set
 870 disable_component_resolution_regex_fallback to a true value.
 871
 872     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 873
 874 =cut
 875
 876 sub component {
 877     my ( $c, $name, @args ) = @_;
 878
 879     if( $name ) {
 880         my $comps = $c->components;
 881
 882         if( !ref $name ) {
 883             # is it the exact name?
 884             return $c->_filter_component( $comps->{ $name }, @args )
 885                        if exists $comps->{ $name };
 886
 887             # perhaps we just omitted "MyApp"?
 888             my $composed = ( ref $c || $c ) . "::${name}";
 889             return $c->_filter_component( $comps->{ $composed }, @args )
 890                        if exists $comps->{ $composed };
 891
 892             # search all of the models, views and controllers
 893             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 894             return $c->_filter_component( $comp, @args ) if $comp;
 895         }
 896
 897         return
 898             if $c->config->{disable_component_resolution_regex_fallback};
 899
 900         # This is here so $c->comp( '::M::' ) works
 901         my $query = ref $name ? $name : qr{$name}i;
 902
 903         my @result = grep { m{$query} } keys %{ $c->components };
 904         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 905
 906         if( $result[ 0 ] ) {
 907             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 908             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 909             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 910             return $c->_filter_component( $result[ 0 ], @args );
 911         }
 912
 913         # I would expect to return an empty list here, but that breaks back-compat
 914     }
 915
 916     # fallback
 917     return sort keys %{ $c->components };
 918 }
 919
 920 =head2 CLASS DATA AND HELPER CLASSES
 921
 922 =head2 $c->config
 923
 924 Returns or takes a hashref containing the application's configuration.
 925
 926     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 927
 928 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 929 like C<myapp.conf> in your applications home directory. See
 930 L<Catalyst::Plugin::ConfigLoader>.
 931
 932 =head3 Cascading configuration
 933
 934 The config method is present on all Catalyst components, and configuration
 935 will be merged when an application is started. Configuration loaded with
 936 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 937 followed by configuration in your top level C<MyApp> class. These two
 938 configurations are merged, and then configuration data whose hash key matches a
 939 component name is merged with configuration for that component.
 940
 941 The configuration for a component is then passed to the C<new> method when a
 942 component is constructed.
 943
 944 For example:
 945
 946     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 947     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 948
 949 will mean that C<MyApp::Model::Foo> receives the following data when
 950 constructed:
 951
 952     MyApp::Model::Foo->new({
 953         bar => 'baz',
 954         quux => 'frob',
 955         overrides => 'me',
 956     });
 957
 958 It's common practice to use a Moose attribute
 959 on the receiving component to access the config value.
 960
 961     package MyApp::Model::Foo;
 962
 963     use Moose;
 964
 965     # this attr will receive 'baz' at construction time
 966     has 'bar' => (
 967         is  => 'rw',
 968         isa => 'Str',
 969     );
 970
 971 You can then get the value 'baz' by calling $c->model('Foo')->bar
 972 (or $self->bar inside code in the model).
 973
 974 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 975 as a way of reading config within your code, as this B<will not> give you the
 976 correctly merged config back. You B<MUST> take the config values supplied to
 977 the constructor and use those instead.
 978
 979 =cut
 980
 981 around config => sub {
 982     my $orig = shift;
 983     my $c = shift;
 984
 985     croak('Setting config after setup has been run is not allowed.')
 986         if ( @_ and $c->setup_finished );
 987
 988     $c->$orig(@_);
 989 };
 990
 991 =head2 $c->log
 992
 993 Returns the logging object instance. Unless it is already set, Catalyst
 994 sets this up with a L<Catalyst::Log> object. To use your own log class,
 995 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 996 C<< __PACKAGE__->setup >>.
 997
 998  __PACKAGE__->log( MyLogger->new );
 999  __PACKAGE__->setup;
1000
1001 And later:
1002
1003     $c->log->info( 'Now logging with my own logger!' );
1004
1005 Your log class should implement the methods described in
1006 L<Catalyst::Log>.
1007
1008
1009 =head2 $c->debug
1010
1011 Returns 1 if debug mode is enabled, 0 otherwise.
1012
1013 You can enable debug mode in several ways:
1014
1015 =over
1016
1017 =item By calling myapp_server.pl with the -d flag
1018
1019 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1020
1021 =item The -Debug option in your MyApp.pm
1022
1023 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1024
1025 =back
1026
1027 The first three also set the log level to 'debug'.
1028
1029 Calling C<< $c->debug(1) >> has no effect.
1030
1031 =cut
1032
1033 sub debug { 0 }
1034
1035 =head2 $c->dispatcher
1036
1037 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1038
1039 =head2 $c->engine
1040
1041 Returns the engine instance. See L<Catalyst::Engine>.
1042
1043
1044 =head2 UTILITY METHODS
1045
1046 =head2 $c->path_to(@path)
1047
1048 Merges C<@path> with C<< $c->config->{home} >> and returns a
1049 L<Path::Class::Dir> object. Note you can usually use this object as
1050 a filename, but sometimes you will have to explicitly stringify it
1051 yourself by calling the C<< ->stringify >> method.
1052
1053 For example:
1054
1055     $c->path_to( 'db', 'sqlite.db' );
1056
1057 =cut
1058
1059 sub path_to {
1060     my ( $c, @path ) = @_;
1061     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1062     if ( -d $path ) { return $path }
1063     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1064 }
1065
1066 sub plugin {
1067     my ( $class, $name, $plugin, @args ) = @_;
1068
1069     # See block comment in t/unit_core_plugin.t
1070     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1071
1072     $class->_register_plugin( $plugin, 1 );
1073
1074     eval { $plugin->import };
1075     $class->mk_classdata($name);
1076     my $obj;
1077     eval { $obj = $plugin->new(@args) };
1078
1079     if ($@) {
1080         Catalyst::Exception->throw( message =>
1081               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1082     }
1083
1084     $class->$name($obj);
1085     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1086       if $class->debug;
1087 }
1088
1089 =head2 MyApp->setup
1090
1091 Initializes the dispatcher and engine, loads any plugins, and loads the
1092 model, view, and controller components. You may also specify an array
1093 of plugins to load here, if you choose to not load them in the C<use
1094 Catalyst> line.
1095
1096     MyApp->setup;
1097     MyApp->setup( qw/-Debug/ );
1098
1099 B<Note:> You B<should not> wrap this method with method modifiers
1100 or bad things will happen - wrap the C<setup_finalize> method instead.
1101
1102 =cut
1103
1104 sub setup {
1105     my ( $class, @arguments ) = @_;
1106     croak('Running setup more than once')
1107         if ( $class->setup_finished );
1108
1109     unless ( $class->isa('Catalyst') ) {
1110
1111         Catalyst::Exception->throw(
1112             message => qq/'$class' does not inherit from Catalyst/ );
1113     }
1114
1115     if ( $class->arguments ) {
1116         @arguments = ( @arguments, @{ $class->arguments } );
1117     }
1118
1119     # Process options
1120     my $flags = {};
1121
1122     foreach (@arguments) {
1123
1124         if (/^-Debug$/) {
1125             $flags->{log} =
1126               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1127         }
1128         elsif (/^-(\w+)=?(.*)$/) {
1129             $flags->{ lc $1 } = $2;
1130         }
1131         else {
1132             push @{ $flags->{plugins} }, $_;
1133         }
1134     }
1135
1136     $class->setup_home( delete $flags->{home} );
1137
1138     $class->setup_log( delete $flags->{log} );
1139     $class->setup_plugins( delete $flags->{plugins} );
1140
1141     $class->setup_data_handlers();
1142     $class->setup_dispatcher( delete $flags->{dispatcher} );
1143     if (my $engine = delete $flags->{engine}) {
1144         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1145     }
1146     $class->setup_engine();
1147     $class->setup_stats( delete $flags->{stats} );
1148
1149     for my $flag ( sort keys %{$flags} ) {
1150
1151         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1152             &$code( $class, delete $flags->{$flag} );
1153         }
1154         else {
1155             $class->log->warn(qq/Unknown flag "$flag"/);
1156         }
1157     }
1158
1159     eval { require Catalyst::Devel; };
1160     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1161         $class->log->warn(<<"EOF");
1162 You are running an old script!
1163
1164   Please update by running (this will overwrite existing files):
1165     catalyst.pl -force -scripts $class
1166
1167   or (this will not overwrite existing files):
1168     catalyst.pl -scripts $class
1169
1170 EOF
1171     }
1172
1173     # Call plugins setup, this is stupid and evil.
1174     # Also screws C3 badly on 5.10, hack to avoid.
1175     {
1176         no warnings qw/redefine/;
1177         local *setup = sub { };
1178         $class->setup unless $Catalyst::__AM_RESTARTING;
1179     }
1180
1181     $class->setup_middleware();
1182
1183     # Initialize our data structure
1184     $class->components( {} );
1185
1186     $class->setup_components;
1187
1188     if ( $class->debug ) {
1189         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1190
1191         if (@plugins) {
1192             my $column_width = Catalyst::Utils::term_width() - 6;
1193             my $t = Text::SimpleTable->new($column_width);
1194             $t->row($_) for @plugins;
1195             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1196         }
1197
1198         my @middleware = map {
1199           ref $_ eq 'CODE' ?
1200             "Inline Coderef" :
1201               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1202                 || '')  } $class->registered_middlewares;
1203
1204         if (@middleware) {
1205             my $column_width = Catalyst::Utils::term_width() - 6;
1206             my $t = Text::SimpleTable->new($column_width);
1207             $t->row($_) for @middleware;
1208             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1209         }
1210
1211         my %dh = $class->registered_data_handlers;
1212         if (my @data_handlers = keys %dh) {
1213             my $column_width = Catalyst::Utils::term_width() - 6;
1214             my $t = Text::SimpleTable->new($column_width);
1215             $t->row($_) for @data_handlers;
1216             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1217         }
1218
1219         my $dispatcher = $class->dispatcher;
1220         my $engine     = $class->engine;
1221         my $home       = $class->config->{home};
1222
1223         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1224         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1225
1226         $home
1227           ? ( -d $home )
1228           ? $class->log->debug(qq/Found home "$home"/)
1229           : $class->log->debug(qq/Home "$home" doesn't exist/)
1230           : $class->log->debug(q/Couldn't find home/);
1231
1232         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1233         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1234         for my $comp ( sort keys %{ $class->components } ) {
1235             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1236             $t->row( $comp, $type );
1237         }
1238         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1239           if ( keys %{ $class->components } );
1240     }
1241
1242     # Add our self to components, since we are also a component
1243     if( $class->isa('Catalyst::Controller') ){
1244       $class->components->{$class} = $class;
1245     }
1246
1247     $class->setup_actions;
1248
1249     if ( $class->debug ) {
1250         my $name = $class->config->{name} || 'Application';
1251         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1252     }
1253
1254     if ($class->config->{case_sensitive}) {
1255         $class->log->warn($class . "->config->{case_sensitive} is set.");
1256         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1257     }
1258
1259     $class->setup_finalize;
1260
1261     # Flush the log for good measure (in case something turned off 'autoflush' early)
1262     $class->log->_flush() if $class->log->can('_flush');
1263
1264     return $class || 1; # Just in case someone named their Application 0...
1265 }
1266
1267 =head2 $app->setup_finalize
1268
1269 A hook to attach modifiers to. This method does not do anything except set the
1270 C<setup_finished> accessor.
1271
1272 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1273
1274 Example:
1275
1276     after setup_finalize => sub {
1277         my $app = shift;
1278
1279         ## do stuff here..
1280     };
1281
1282 =cut
1283
1284 sub setup_finalize {
1285     my ($class) = @_;
1286     $class->setup_finished(1);
1287 }
1288
1289 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1290
1291 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1292
1293 Constructs an absolute L<URI> object based on the application root, the
1294 provided path, and the additional arguments and query parameters provided.
1295 When used as a string, provides a textual URI.  If you need more flexibility
1296 than this (i.e. the option to provide relative URIs etc.) see
1297 L<Catalyst::Plugin::SmartURI>.
1298
1299 If no arguments are provided, the URI for the current action is returned.
1300 To return the current action and also provide @args, use
1301 C<< $c->uri_for( $c->action, @args ) >>.
1302
1303 If the first argument is a string, it is taken as a public URI path relative
1304 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1305 relative to the application root (if it does). It is then merged with
1306 C<< $c->request->base >>; any C<@args> are appended as additional path
1307 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1308
1309 If the first argument is a L<Catalyst::Action> it represents an action which
1310 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1311 optional C<\@captures> argument (an arrayref) allows passing the captured
1312 variables that are needed to fill in the paths of Chained and Regex actions;
1313 once the path is resolved, C<uri_for> continues as though a path was
1314 provided, appending any arguments or parameters and creating an absolute
1315 URI.
1316
1317 The captures for the current request can be found in
1318 C<< $c->request->captures >>, and actions can be resolved using
1319 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1320 path, use C<< $c->uri_for_action >> instead.
1321
1322   # Equivalent to $c->req->uri
1323   $c->uri_for($c->action, $c->req->captures,
1324       @{ $c->req->args }, $c->req->params);
1325
1326   # For the Foo action in the Bar controller
1327   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1328
1329   # Path to a static resource
1330   $c->uri_for('/static/images/logo.png');
1331
1332 =cut
1333
1334 sub uri_for {
1335     my ( $c, $path, @args ) = @_;
1336
1337     if ( $path->$_isa('Catalyst::Controller') ) {
1338         $path = $path->path_prefix;
1339         $path =~ s{/+\z}{};
1340         $path .= '/';
1341     }
1342
1343     undef($path) if (defined $path && $path eq '');
1344
1345     my $params =
1346       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1347
1348     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1349     foreach my $arg (@args) {
1350         utf8::encode($arg) if utf8::is_utf8($arg);
1351         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1352     }
1353
1354     if ( $path->$_isa('Catalyst::Action') ) { # action object
1355         s|/|%2F|g for @args;
1356         my $captures = [ map { s|/|%2F|g; $_; }
1357                         ( scalar @args && ref $args[0] eq 'ARRAY'
1358                          ? @{ shift(@args) }
1359                          : ()) ];
1360
1361         foreach my $capture (@$captures) {
1362             utf8::encode($capture) if utf8::is_utf8($capture);
1363             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1364         }
1365
1366         my $action = $path;
1367         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1368         if( !@args && $action->number_of_args ) {
1369             my $expanded_action = $c->dispatcher->expand_action( $action );
1370
1371             my $num_captures = $expanded_action->number_of_captures;
1372             unshift @args, splice @$captures, $num_captures;
1373         }
1374
1375        $path = $c->dispatcher->uri_for_action($action, $captures);
1376         if (not defined $path) {
1377             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1378                 if $c->debug;
1379             return undef;
1380         }
1381         $path = '/' if $path eq '';
1382     }
1383
1384     unshift(@args, $path);
1385
1386     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1387         my $namespace = $c->namespace;
1388         if (defined $path) { # cheesy hack to handle path '../foo'
1389            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1390         }
1391         unshift(@args, $namespace || '');
1392     }
1393
1394     # join args with '/', or a blank string
1395     my $args = join('/', grep { defined($_) } @args);
1396     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1397     $args =~ s!^/+!!;
1398
1399     my ($base, $class) = ('/', 'URI::_generic');
1400     if(blessed($c)) {
1401       $base = $c->req->base;
1402       $class = ref($base);
1403       $base =~ s{(?<!/)$}{/};
1404     }
1405
1406     my $query = '';
1407
1408     if (my @keys = keys %$params) {
1409       # somewhat lifted from URI::_query's query_form
1410       $query = '?'.join('&', map {
1411           my $val = $params->{$_};
1412           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1413           s/ /+/g;
1414           my $key = $_;
1415           $val = '' unless defined $val;
1416           (map {
1417               my $param = "$_";
1418               utf8::encode( $param ) if utf8::is_utf8($param);
1419               # using the URI::Escape pattern here so utf8 chars survive
1420               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1421               $param =~ s/ /+/g;
1422               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1423       } @keys);
1424     }
1425
1426     my $res = bless(\"${base}${args}${query}", $class);
1427     $res;
1428 }
1429
1430 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1431
1432 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1433
1434 =over
1435
1436 =item $path
1437
1438 A private path to the Catalyst action you want to create a URI for.
1439
1440 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1441 >> and passing the resulting C<$action> and the remaining arguments to C<<
1442 $c->uri_for >>.
1443
1444 You can also pass in a Catalyst::Action object, in which case it is passed to
1445 C<< $c->uri_for >>.
1446
1447 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1448
1449 For example, if the action looks like:
1450
1451  package MyApp::Controller::Users;
1452
1453  sub lst : Path('the-list') {}
1454
1455 You can use:
1456
1457  $c->uri_for_action('/users/lst')
1458
1459 and it will create the URI /users/the-list.
1460
1461 =item \@captures_and_args?
1462
1463 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1464 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1465 to interpolate all the parameters in the URI.
1466
1467 =item @args?
1468
1469 Optional list of extra arguments - can be supplied in the
1470 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1471 code.
1472
1473 Your action can have zero, a fixed or a variable number of args (e.g.
1474 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1475
1476 =item \%query_values?
1477
1478 Optional array reference of query parameters to append. E.g.
1479
1480   { foo => 'bar' }
1481
1482 will generate
1483
1484   /rest/of/your/uri?foo=bar
1485
1486 =back
1487
1488 =cut
1489
1490 sub uri_for_action {
1491     my ( $c, $path, @args ) = @_;
1492     my $action = blessed($path)
1493       ? $path
1494       : $c->dispatcher->get_action_by_path($path);
1495     unless (defined $action) {
1496       croak "Can't find action for path '$path'";
1497     }
1498     return $c->uri_for( $action, @args );
1499 }
1500
1501 =head2 $c->welcome_message
1502
1503 Returns the Catalyst welcome HTML page.
1504
1505 =cut
1506
1507 sub welcome_message {
1508     my $c      = shift;
1509     my $name   = $c->config->{name};
1510     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1511     my $prefix = Catalyst::Utils::appprefix( ref $c );
1512     $c->response->content_type('text/html; charset=utf-8');
1513     return <<"EOF";
1514 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1515     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1516 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1517     <head>
1518     <meta http-equiv="Content-Language" content="en" />
1519     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1520         <title>$name on Catalyst $VERSION</title>
1521         <style type="text/css">
1522             body {
1523                 color: #000;
1524                 background-color: #eee;
1525             }
1526             div#content {
1527                 width: 640px;
1528                 margin-left: auto;
1529                 margin-right: auto;
1530                 margin-top: 10px;
1531                 margin-bottom: 10px;
1532                 text-align: left;
1533                 background-color: #ccc;
1534                 border: 1px solid #aaa;
1535             }
1536             p, h1, h2 {
1537                 margin-left: 20px;
1538                 margin-right: 20px;
1539                 font-family: verdana, tahoma, sans-serif;
1540             }
1541             a {
1542                 font-family: verdana, tahoma, sans-serif;
1543             }
1544             :link, :visited {
1545                     text-decoration: none;
1546                     color: #b00;
1547                     border-bottom: 1px dotted #bbb;
1548             }
1549             :link:hover, :visited:hover {
1550                     color: #555;
1551             }
1552             div#topbar {
1553                 margin: 0px;
1554             }
1555             pre {
1556                 margin: 10px;
1557                 padding: 8px;
1558             }
1559             div#answers {
1560                 padding: 8px;
1561                 margin: 10px;
1562                 background-color: #fff;
1563                 border: 1px solid #aaa;
1564             }
1565             h1 {
1566                 font-size: 0.9em;
1567                 font-weight: normal;
1568                 text-align: center;
1569             }
1570             h2 {
1571                 font-size: 1.0em;
1572             }
1573             p {
1574                 font-size: 0.9em;
1575             }
1576             p img {
1577                 float: right;
1578                 margin-left: 10px;
1579             }
1580             span#appname {
1581                 font-weight: bold;
1582                 font-size: 1.6em;
1583             }
1584         </style>
1585     </head>
1586     <body>
1587         <div id="content">
1588             <div id="topbar">
1589                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1590                     $VERSION</h1>
1591              </div>
1592              <div id="answers">
1593                  <p>
1594                  <img src="$logo" alt="Catalyst Logo" />
1595                  </p>
1596                  <p>Welcome to the  world of Catalyst.
1597                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1598                     framework will make web development something you had
1599                     never expected it to be: Fun, rewarding, and quick.</p>
1600                  <h2>What to do now?</h2>
1601                  <p>That really depends  on what <b>you</b> want to do.
1602                     We do, however, provide you with a few starting points.</p>
1603                  <p>If you want to jump right into web development with Catalyst
1604                     you might want to start with a tutorial.</p>
1605 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1606 </pre>
1607 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1608 <pre>
1609 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1610 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1611 </code></pre>
1612                  <h2>What to do next?</h2>
1613                  <p>Next it's time to write an actual application. Use the
1614                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1615                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1616                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1617                     they can save you a lot of work.</p>
1618                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1619                     <p>Also, be sure to check out the vast and growing
1620                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1621                     you are likely to find what you need there.
1622                     </p>
1623
1624                  <h2>Need help?</h2>
1625                  <p>Catalyst has a very active community. Here are the main places to
1626                     get in touch with us.</p>
1627                  <ul>
1628                      <li>
1629                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1630                      </li>
1631                      <li>
1632                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1633                      </li>
1634                      <li>
1635                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1636                      </li>
1637                  </ul>
1638                  <h2>In conclusion</h2>
1639                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1640                     as we enjoyed making it. Please contact us if you have ideas
1641                     for improvement or other feedback.</p>
1642              </div>
1643          </div>
1644     </body>
1645 </html>
1646 EOF
1647 }
1648
1649 =head2 run_options
1650
1651 Contains a hash of options passed from the application script, including
1652 the original ARGV the script received, the processed values from that
1653 ARGV and any extra arguments to the script which were not processed.
1654
1655 This can be used to add custom options to your application's scripts
1656 and setup your application differently depending on the values of these
1657 options.
1658
1659 =head1 INTERNAL METHODS
1660
1661 These methods are not meant to be used by end users.
1662
1663 =head2 $c->components
1664
1665 Returns a hash of components.
1666
1667 =head2 $c->context_class
1668
1669 Returns or sets the context class.
1670
1671 =head2 $c->counter
1672
1673 Returns a hashref containing coderefs and execution counts (needed for
1674 deep recursion detection).
1675
1676 =head2 $c->depth
1677
1678 Returns the number of actions on the current internal execution stack.
1679
1680 =head2 $c->dispatch
1681
1682 Dispatches a request to actions.
1683
1684 =cut
1685
1686 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1687
1688 =head2 $c->dispatcher_class
1689
1690 Returns or sets the dispatcher class.
1691
1692 =head2 $c->dump_these
1693
1694 Returns a list of 2-element array references (name, structure) pairs
1695 that will be dumped on the error page in debug mode.
1696
1697 =cut
1698
1699 sub dump_these {
1700     my $c = shift;
1701     [ Request => $c->req ],
1702     [ Response => $c->res ],
1703     [ Stash => $c->stash ],
1704     [ Config => $c->config ];
1705 }
1706
1707 =head2 $c->engine_class
1708
1709 Returns or sets the engine class.
1710
1711 =head2 $c->execute( $class, $coderef )
1712
1713 Execute a coderef in given class and catch exceptions. Errors are available
1714 via $c->error.
1715
1716 =cut
1717
1718 sub execute {
1719     my ( $c, $class, $code ) = @_;
1720     $class = $c->component($class) || $class;
1721     $c->state(0);
1722
1723     if ( $c->depth >= $RECURSION ) {
1724         my $action = $code->reverse();
1725         $action = "/$action" unless $action =~ /->/;
1726         my $error = qq/Deep recursion detected calling "${action}"/;
1727         $c->log->error($error);
1728         $c->error($error);
1729         $c->state(0);
1730         return $c->state;
1731     }
1732
1733     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1734
1735     push( @{ $c->stack }, $code );
1736
1737     no warnings 'recursion';
1738     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1739     #      I have no idea how, ergo $ret (which appears to fix the issue)
1740     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1741
1742     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1743
1744     my $last = pop( @{ $c->stack } );
1745
1746     if ( my $error = $@ ) {
1747         #rethow if this can be handled by middleware
1748         if(blessed $error && ($error->can('as_psgi') || $error->can('code'))) {
1749             foreach my $err (@{$c->error}) {
1750                 $c->log->error($err);
1751             }
1752             $c->clear_errors;
1753             $c->log->_flush if $c->log->can('_flush');
1754
1755             $error->can('rethrow') ? $error->rethrow : croak $error;
1756         }
1757         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1758             $error->rethrow if $c->depth > 1;
1759         }
1760         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1761             $error->rethrow if $c->depth > 0;
1762         }
1763         else {
1764             unless ( ref $error ) {
1765                 no warnings 'uninitialized';
1766                 chomp $error;
1767                 my $class = $last->class;
1768                 my $name  = $last->name;
1769                 $error = qq/Caught exception in $class->$name "$error"/;
1770             }
1771             $c->error($error);
1772         }
1773         $c->state(0);
1774     }
1775     return $c->state;
1776 }
1777
1778 sub _stats_start_execute {
1779     my ( $c, $code ) = @_;
1780     my $appclass = ref($c) || $c;
1781     return if ( ( $code->name =~ /^_.*/ )
1782         && ( !$appclass->config->{show_internal_actions} ) );
1783
1784     my $action_name = $code->reverse();
1785     $c->counter->{$action_name}++;
1786
1787     my $action = $action_name;
1788     $action = "/$action" unless $action =~ /->/;
1789
1790     # determine if the call was the result of a forward
1791     # this is done by walking up the call stack and looking for a calling
1792     # sub of Catalyst::forward before the eval
1793     my $callsub = q{};
1794     for my $index ( 2 .. 11 ) {
1795         last
1796         if ( ( caller($index) )[0] eq 'Catalyst'
1797             && ( caller($index) )[3] eq '(eval)' );
1798
1799         if ( ( caller($index) )[3] =~ /forward$/ ) {
1800             $callsub = ( caller($index) )[3];
1801             $action  = "-> $action";
1802             last;
1803         }
1804     }
1805
1806     my $uid = $action_name . $c->counter->{$action_name};
1807
1808     # is this a root-level call or a forwarded call?
1809     if ( $callsub =~ /forward$/ ) {
1810         my $parent = $c->stack->[-1];
1811
1812         # forward, locate the caller
1813         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1814             $c->stats->profile(
1815                 begin  => $action,
1816                 parent => "$parent" . $c->counter->{"$parent"},
1817                 uid    => $uid,
1818             );
1819         }
1820         else {
1821
1822             # forward with no caller may come from a plugin
1823             $c->stats->profile(
1824                 begin => $action,
1825                 uid   => $uid,
1826             );
1827         }
1828     }
1829     else {
1830
1831         # root-level call
1832         $c->stats->profile(
1833             begin => $action,
1834             uid   => $uid,
1835         );
1836     }
1837     return $action;
1838
1839 }
1840
1841 sub _stats_finish_execute {
1842     my ( $c, $info ) = @_;
1843     $c->stats->profile( end => $info );
1844 }
1845
1846 =head2 $c->finalize
1847
1848 Finalizes the request.
1849
1850 =cut
1851
1852 sub finalize {
1853     my $c = shift;
1854
1855     for my $error ( @{ $c->error } ) {
1856         $c->log->error($error);
1857     }
1858
1859     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1860     # stuff like cometd and websockets
1861
1862     if($c->request->_has_io_fh) {
1863       $c->log_response;
1864       return;
1865     }
1866
1867     # Allow engine to handle finalize flow (for POE)
1868     my $engine = $c->engine;
1869     if ( my $code = $engine->can('finalize') ) {
1870         $engine->$code($c);
1871     }
1872     else {
1873
1874         $c->finalize_uploads;
1875
1876         # Error
1877         if ( $#{ $c->error } >= 0 ) {
1878             $c->finalize_error;
1879         }
1880
1881         $c->finalize_headers unless $c->response->finalized_headers;
1882
1883         $c->finalize_body;
1884     }
1885
1886     $c->log_response;
1887
1888     if ($c->use_stats) {
1889         my $elapsed = $c->stats->elapsed;
1890         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1891         $c->log->info(
1892             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1893     }
1894
1895     return $c->response->status;
1896 }
1897
1898 =head2 $c->finalize_body
1899
1900 Finalizes body.
1901
1902 =cut
1903
1904 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1905
1906 =head2 $c->finalize_cookies
1907
1908 Finalizes cookies.
1909
1910 =cut
1911
1912 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1913
1914 =head2 $c->finalize_error
1915
1916 Finalizes error.  If there is only one error in L</error> and it is an object that
1917 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
1918 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
1919 return the default error page (production mode).
1920
1921 =cut
1922
1923 sub finalize_error {
1924     my $c = shift;
1925     if($#{$c->error} > 0) {
1926         $c->engine->finalize_error( $c, @_ );
1927     } else {
1928         my ($error) = @{$c->error};
1929         if(
1930           blessed $error &&
1931           ($error->can('as_psgi') || $error->can('code'))
1932         ) {
1933             # In the case where the error 'knows what it wants', becauses its PSGI
1934             # aware, just rethow and let middleware catch it
1935             $error->can('rethrow') ? $error->rethrow : croak $error;
1936         } else {
1937             $c->engine->finalize_error( $c, @_ )
1938         }
1939     }
1940 }
1941
1942 =head2 $c->finalize_headers
1943
1944 Finalizes headers.
1945
1946 =cut
1947
1948 sub finalize_headers {
1949     my $c = shift;
1950
1951     my $response = $c->response; #accessor calls can add up?
1952
1953     # Check if we already finalized headers
1954     return if $response->finalized_headers;
1955
1956     # Handle redirects
1957     if ( my $location = $response->redirect ) {
1958         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1959         $response->header( Location => $location );
1960     }
1961
1962     # Remove incorrectly added body and content related meta data when returning
1963     # an information response, or a response the is required to not include a body
1964
1965     $c->finalize_cookies;
1966
1967     $c->response->finalize_headers();
1968
1969     # Done
1970     $response->finalized_headers(1);
1971 }
1972
1973 =head2 $c->finalize_output
1974
1975 An alias for finalize_body.
1976
1977 =head2 $c->finalize_read
1978
1979 Finalizes the input after reading is complete.
1980
1981 =cut
1982
1983 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1984
1985 =head2 $c->finalize_uploads
1986
1987 Finalizes uploads. Cleans up any temporary files.
1988
1989 =cut
1990
1991 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1992
1993 =head2 $c->get_action( $action, $namespace )
1994
1995 Gets an action in a given namespace.
1996
1997 =cut
1998
1999 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2000
2001 =head2 $c->get_actions( $action, $namespace )
2002
2003 Gets all actions of a given name in a namespace and all parent
2004 namespaces.
2005
2006 =cut
2007
2008 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2009
2010 =head2 $app->handle_request( @arguments )
2011
2012 Called to handle each HTTP request.
2013
2014 =cut
2015
2016 sub handle_request {
2017     my ( $class, @arguments ) = @_;
2018
2019     # Always expect worst case!
2020     my $status = -1;
2021     try {
2022         if ($class->debug) {
2023             my $secs = time - $START || 1;
2024             my $av = sprintf '%.3f', $COUNT / $secs;
2025             my $time = localtime time;
2026             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2027         }
2028
2029         my $c = $class->prepare(@arguments);
2030         $c->dispatch;
2031         $status = $c->finalize;
2032     } catch {
2033         #rethow if this can be handled by middleware
2034         if(blessed $_ && ($_->can('as_psgi') || $_->can('code'))) {
2035             $_->can('rethrow') ? $_->rethrow : croak $_;
2036         }
2037         chomp(my $error = $_);
2038         $class->log->error(qq/Caught exception in engine "$error"/);
2039     };
2040
2041     $COUNT++;
2042
2043     if(my $coderef = $class->log->can('_flush')){
2044         $class->log->$coderef();
2045     }
2046     return $status;
2047 }
2048
2049 =head2 $class->prepare( @arguments )
2050
2051 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2052 etc.).
2053
2054 =cut
2055
2056 has _uploadtmp => (
2057     is => 'ro',
2058     predicate => '_has_uploadtmp',
2059 );
2060
2061 sub prepare {
2062     my ( $class, @arguments ) = @_;
2063
2064     # XXX
2065     # After the app/ctxt split, this should become an attribute based on something passed
2066     # into the application.
2067     $class->context_class( ref $class || $class ) unless $class->context_class;
2068
2069     my $uploadtmp = $class->config->{uploadtmp};
2070     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2071
2072     $c->response->_context($c);
2073
2074     #surely this is not the most efficient way to do things...
2075     $c->stats($class->stats_class->new)->enable($c->use_stats);
2076     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2077         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2078     }
2079
2080     try {
2081         # Allow engine to direct the prepare flow (for POE)
2082         if ( my $prepare = $c->engine->can('prepare') ) {
2083             $c->engine->$prepare( $c, @arguments );
2084         }
2085         else {
2086             $c->prepare_request(@arguments);
2087             $c->prepare_connection;
2088             $c->prepare_query_parameters;
2089             $c->prepare_headers; # Just hooks, no longer needed - they just
2090             $c->prepare_cookies; # cause the lazy attribute on req to build
2091             $c->prepare_path;
2092
2093             # Prepare the body for reading, either by prepare_body
2094             # or the user, if they are using $c->read
2095             $c->prepare_read;
2096
2097             # Parse the body unless the user wants it on-demand
2098             unless ( ref($c)->config->{parse_on_demand} ) {
2099                 $c->prepare_body;
2100             }
2101         }
2102         $c->prepare_action;
2103     }
2104     # VERY ugly and probably shouldn't rely on ->finalize actually working
2105     catch {
2106         # failed prepare is always due to an invalid request, right?
2107         $c->response->status(400);
2108         $c->response->content_type('text/plain');
2109         $c->response->body('Bad Request');
2110         # Note we call finalize and then die here, which escapes
2111         # finalize being called in the enclosing block..
2112         # It in fact couldn't be called, as we don't return $c..
2113         # This is a mess - but I'm unsure you can fix this without
2114         # breaking compat for people doing crazy things (we should set
2115         # the 400 and just return the ctx here IMO, letting finalize get called
2116         # above...
2117         $c->finalize;
2118         die $_;
2119     };
2120
2121     $c->log_request;
2122
2123     return $c;
2124 }
2125
2126 =head2 $c->prepare_action
2127
2128 Prepares action. See L<Catalyst::Dispatcher>.
2129
2130 =cut
2131
2132 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2133
2134 =head2 $c->prepare_body
2135
2136 Prepares message body.
2137
2138 =cut
2139
2140 sub prepare_body {
2141     my $c = shift;
2142
2143     return if $c->request->_has_body;
2144
2145     # Initialize on-demand data
2146     $c->engine->prepare_body( $c, @_ );
2147     $c->prepare_parameters;
2148     $c->prepare_uploads;
2149 }
2150
2151 =head2 $c->prepare_body_chunk( $chunk )
2152
2153 Prepares a chunk of data before sending it to L<HTTP::Body>.
2154
2155 See L<Catalyst::Engine>.
2156
2157 =cut
2158
2159 sub prepare_body_chunk {
2160     my $c = shift;
2161     $c->engine->prepare_body_chunk( $c, @_ );
2162 }
2163
2164 =head2 $c->prepare_body_parameters
2165
2166 Prepares body parameters.
2167
2168 =cut
2169
2170 sub prepare_body_parameters {
2171     my $c = shift;
2172     $c->engine->prepare_body_parameters( $c, @_ );
2173 }
2174
2175 =head2 $c->prepare_connection
2176
2177 Prepares connection.
2178
2179 =cut
2180
2181 sub prepare_connection {
2182     my $c = shift;
2183     $c->request->prepare_connection($c);
2184 }
2185
2186 =head2 $c->prepare_cookies
2187
2188 Prepares cookies by ensuring that the attribute on the request
2189 object has been built.
2190
2191 =cut
2192
2193 sub prepare_cookies { my $c = shift; $c->request->cookies }
2194
2195 =head2 $c->prepare_headers
2196
2197 Prepares request headers by ensuring that the attribute on the request
2198 object has been built.
2199
2200 =cut
2201
2202 sub prepare_headers { my $c = shift; $c->request->headers }
2203
2204 =head2 $c->prepare_parameters
2205
2206 Prepares parameters.
2207
2208 =cut
2209
2210 sub prepare_parameters {
2211     my $c = shift;
2212     $c->prepare_body_parameters;
2213     $c->engine->prepare_parameters( $c, @_ );
2214 }
2215
2216 =head2 $c->prepare_path
2217
2218 Prepares path and base.
2219
2220 =cut
2221
2222 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2223
2224 =head2 $c->prepare_query_parameters
2225
2226 Prepares query parameters.
2227
2228 =cut
2229
2230 sub prepare_query_parameters {
2231     my $c = shift;
2232
2233     $c->engine->prepare_query_parameters( $c, @_ );
2234 }
2235
2236 =head2 $c->log_request
2237
2238 Writes information about the request to the debug logs.  This includes:
2239
2240 =over 4
2241
2242 =item * Request method, path, and remote IP address
2243
2244 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2245
2246 =item * Request parameters
2247
2248 =item * File uploads
2249
2250 =back
2251
2252 =cut
2253
2254 sub log_request {
2255     my $c = shift;
2256
2257     return unless $c->debug;
2258
2259     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2260     my $request = $dump->[1];
2261
2262     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2263     $method ||= '';
2264     $path = '/' unless length $path;
2265     $address ||= '';
2266     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2267
2268     $c->log_request_headers($request->headers);
2269
2270     if ( my $keywords = $request->query_keywords ) {
2271         $c->log->debug("Query keywords are: $keywords");
2272     }
2273
2274     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2275
2276     $c->log_request_uploads($request);
2277 }
2278
2279 =head2 $c->log_response
2280
2281 Writes information about the response to the debug logs by calling
2282 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2283
2284 =cut
2285
2286 sub log_response {
2287     my $c = shift;
2288
2289     return unless $c->debug;
2290
2291     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2292     my $response = $dump->[1];
2293
2294     $c->log_response_status_line($response);
2295     $c->log_response_headers($response->headers);
2296 }
2297
2298 =head2 $c->log_response_status_line($response)
2299
2300 Writes one line of information about the response to the debug logs.  This includes:
2301
2302 =over 4
2303
2304 =item * Response status code
2305
2306 =item * Content-Type header (if present)
2307
2308 =item * Content-Length header (if present)
2309
2310 =back
2311
2312 =cut
2313
2314 sub log_response_status_line {
2315     my ($c, $response) = @_;
2316
2317     $c->log->debug(
2318         sprintf(
2319             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2320             $response->status                            || 'unknown',
2321             $response->headers->header('Content-Type')   || 'unknown',
2322             $response->headers->header('Content-Length') || 'unknown'
2323         )
2324     );
2325 }
2326
2327 =head2 $c->log_response_headers($headers);
2328
2329 Hook method which can be wrapped by plugins to log the response headers.
2330 No-op in the default implementation.
2331
2332 =cut
2333
2334 sub log_response_headers {}
2335
2336 =head2 $c->log_request_parameters( query => {}, body => {} )
2337
2338 Logs request parameters to debug logs
2339
2340 =cut
2341
2342 sub log_request_parameters {
2343     my $c          = shift;
2344     my %all_params = @_;
2345
2346     return unless $c->debug;
2347
2348     my $column_width = Catalyst::Utils::term_width() - 44;
2349     foreach my $type (qw(query body)) {
2350         my $params = $all_params{$type};
2351         next if ! keys %$params;
2352         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2353         for my $key ( sort keys %$params ) {
2354             my $param = $params->{$key};
2355             my $value = defined($param) ? $param : '';
2356             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2357         }
2358         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2359     }
2360 }
2361
2362 =head2 $c->log_request_uploads
2363
2364 Logs file uploads included in the request to the debug logs.
2365 The parameter name, filename, file type, and file size are all included in
2366 the debug logs.
2367
2368 =cut
2369
2370 sub log_request_uploads {
2371     my $c = shift;
2372     my $request = shift;
2373     return unless $c->debug;
2374     my $uploads = $request->uploads;
2375     if ( keys %$uploads ) {
2376         my $t = Text::SimpleTable->new(
2377             [ 12, 'Parameter' ],
2378             [ 26, 'Filename' ],
2379             [ 18, 'Type' ],
2380             [ 9,  'Size' ]
2381         );
2382         for my $key ( sort keys %$uploads ) {
2383             my $upload = $uploads->{$key};
2384             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2385                 $t->row( $key, $u->filename, $u->type, $u->size );
2386             }
2387         }
2388         $c->log->debug( "File Uploads are:\n" . $t->draw );
2389     }
2390 }
2391
2392 =head2 $c->log_request_headers($headers);
2393
2394 Hook method which can be wrapped by plugins to log the request headers.
2395 No-op in the default implementation.
2396
2397 =cut
2398
2399 sub log_request_headers {}
2400
2401 =head2 $c->log_headers($type => $headers)
2402
2403 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2404
2405 =cut
2406
2407 sub log_headers {
2408     my $c       = shift;
2409     my $type    = shift;
2410     my $headers = shift;    # an HTTP::Headers instance
2411
2412     return unless $c->debug;
2413
2414     my $column_width = Catalyst::Utils::term_width() - 28;
2415     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2416     $headers->scan(
2417         sub {
2418             my ( $name, $value ) = @_;
2419             $t->row( $name, $value );
2420         }
2421     );
2422     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2423 }
2424
2425
2426 =head2 $c->prepare_read
2427
2428 Prepares the input for reading.
2429
2430 =cut
2431
2432 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2433
2434 =head2 $c->prepare_request
2435
2436 Prepares the engine request.
2437
2438 =cut
2439
2440 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2441
2442 =head2 $c->prepare_uploads
2443
2444 Prepares uploads.
2445
2446 =cut
2447
2448 sub prepare_uploads {
2449     my $c = shift;
2450
2451     $c->engine->prepare_uploads( $c, @_ );
2452 }
2453
2454 =head2 $c->prepare_write
2455
2456 Prepares the output for writing.
2457
2458 =cut
2459
2460 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2461
2462 =head2 $c->request_class
2463
2464 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2465
2466 =head2 $c->response_class
2467
2468 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2469
2470 =head2 $c->read( [$maxlength] )
2471
2472 Reads a chunk of data from the request body. This method is designed to
2473 be used in a while loop, reading C<$maxlength> bytes on every call.
2474 C<$maxlength> defaults to the size of the request if not specified.
2475
2476 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2477 directly.
2478
2479 Warning: If you use read(), Catalyst will not process the body,
2480 so you will not be able to access POST parameters or file uploads via
2481 $c->request.  You must handle all body parsing yourself.
2482
2483 =cut
2484
2485 sub read { my $c = shift; return $c->request->read( @_ ) }
2486
2487 =head2 $c->run
2488
2489 Starts the engine.
2490
2491 =cut
2492
2493 sub run {
2494   my $app = shift;
2495   $app->_make_immutable_if_needed;
2496   $app->engine_loader->needs_psgi_engine_compat_hack ?
2497     $app->engine->run($app, @_) :
2498       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2499 }
2500
2501 sub _make_immutable_if_needed {
2502     my $class = shift;
2503     my $meta = find_meta($class);
2504     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2505     if (
2506         $meta->is_immutable
2507         && ! { $meta->immutable_options }->{replace_constructor}
2508         && $isa_ca
2509     ) {
2510         warn("You made your application class ($class) immutable, "
2511             . "but did not inline the\nconstructor. "
2512             . "This will break catalyst, as your app \@ISA "
2513             . "Class::Accessor(::Fast)?\nPlease pass "
2514             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2515     }
2516     unless ($meta->is_immutable) {
2517         # XXX - FIXME warning here as you should make your app immutable yourself.
2518         $meta->make_immutable(
2519             replace_constructor => 1,
2520         );
2521     }
2522 }
2523
2524 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2525
2526 Sets an action in a given namespace.
2527
2528 =cut
2529
2530 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2531
2532 =head2 $c->setup_actions($component)
2533
2534 Sets up actions for a component.
2535
2536 =cut
2537
2538 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2539
2540 =head2 $c->setup_components
2541
2542 This method is called internally to set up the application's components.
2543
2544 It finds modules by calling the L<locate_components> method, expands them to
2545 package names with the L<expand_component_module> method, and then installs
2546 each component into the application.
2547
2548 The C<setup_components> config option is passed to both of the above methods.
2549
2550 Installation of each component is performed by the L<setup_component> method,
2551 below.
2552
2553 =cut
2554
2555 sub setup_components {
2556     my $class = shift;
2557
2558     my $config  = $class->config->{ setup_components };
2559
2560     my @comps = $class->locate_components($config);
2561     my %comps = map { $_ => 1 } @comps;
2562
2563     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2564     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2565         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2566     ) if $deprecatedcatalyst_component_names;
2567
2568     for my $component ( @comps ) {
2569
2570         # We pass ignore_loaded here so that overlay files for (e.g.)
2571         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2572         # we know M::P::O found a file on disk so this is safe
2573
2574         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2575     }
2576
2577     for my $component (@comps) {
2578         my $instance = $class->components->{ $component } = $class->setup_component($component);
2579         my @expanded_components = $instance->can('expand_modules')
2580             ? $instance->expand_modules( $component, $config )
2581             : $class->expand_component_module( $component, $config );
2582         for my $component (@expanded_components) {
2583             next if $comps{$component};
2584             $class->components->{ $component } = $class->setup_component($component);
2585         }
2586     }
2587 }
2588
2589 =head2 $c->locate_components( $setup_component_config )
2590
2591 This method is meant to provide a list of component modules that should be
2592 setup for the application.  By default, it will use L<Module::Pluggable>.
2593
2594 Specify a C<setup_components> config option to pass additional options directly
2595 to L<Module::Pluggable>. To add additional search paths, specify a key named
2596 C<search_extra> as an array reference. Items in the array beginning with C<::>
2597 will have the application class name prepended to them.
2598
2599 =cut
2600
2601 sub locate_components {
2602     my $class  = shift;
2603     my $config = shift;
2604
2605     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
2606     my $extra   = delete $config->{ search_extra } || [];
2607
2608     unshift @paths, @$extra;
2609
2610     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
2611       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
2612       %$config
2613     )->plugins } @paths;
2614
2615     return @comps;
2616 }
2617
2618 =head2 $c->expand_component_module( $component, $setup_component_config )
2619
2620 Components found by C<locate_components> will be passed to this method, which
2621 is expected to return a list of component (package) names to be set up.
2622
2623 =cut
2624
2625 sub expand_component_module {
2626     my ($class, $module) = @_;
2627     return Devel::InnerPackage::list_packages( $module );
2628 }
2629
2630 =head2 $c->setup_component
2631
2632 =cut
2633
2634 sub setup_component {
2635     my( $class, $component ) = @_;
2636
2637     unless ( $component->can( 'COMPONENT' ) ) {
2638         return $component;
2639     }
2640
2641     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2642     my $config = $class->config->{ $suffix } || {};
2643     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2644     # methods also pass it. local to avoid pointlessly shitting in config
2645     # for the debug screen, as $component is already the key name.
2646     local $config->{catalyst_component_name} = $component;
2647
2648     my $instance = eval { $component->COMPONENT( $class, $config ); };
2649
2650     if ( my $error = $@ ) {
2651         chomp $error;
2652         Catalyst::Exception->throw(
2653             message => qq/Couldn't instantiate component "$component", "$error"/
2654         );
2655     }
2656
2657     unless (blessed $instance) {
2658         my $metaclass = Moose::Util::find_meta($component);
2659         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2660         my $component_method_from = $method_meta->associated_metaclass->name;
2661         my $value = defined($instance) ? $instance : 'undef';
2662         Catalyst::Exception->throw(
2663             message =>
2664             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2665         );
2666     }
2667     return $instance;
2668 }
2669
2670 =head2 $c->setup_dispatcher
2671
2672 Sets up dispatcher.
2673
2674 =cut
2675
2676 sub setup_dispatcher {
2677     my ( $class, $dispatcher ) = @_;
2678
2679     if ($dispatcher) {
2680         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2681     }
2682
2683     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2684         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2685     }
2686
2687     unless ($dispatcher) {
2688         $dispatcher = $class->dispatcher_class;
2689     }
2690
2691     load_class($dispatcher);
2692
2693     # dispatcher instance
2694     $class->dispatcher( $dispatcher->new );
2695 }
2696
2697 =head2 $c->setup_engine
2698
2699 Sets up engine.
2700
2701 =cut
2702
2703 sub engine_class {
2704     my ($class, $requested_engine) = @_;
2705
2706     if (!$class->engine_loader || $requested_engine) {
2707         $class->engine_loader(
2708             Catalyst::EngineLoader->new({
2709                 application_name => $class,
2710                 (defined $requested_engine
2711                      ? (catalyst_engine_class => $requested_engine) : ()),
2712             }),
2713         );
2714     }
2715
2716     $class->engine_loader->catalyst_engine_class;
2717 }
2718
2719 sub setup_engine {
2720     my ($class, $requested_engine) = @_;
2721
2722     my $engine = do {
2723         my $loader = $class->engine_loader;
2724
2725         if (!$loader || $requested_engine) {
2726             $loader = Catalyst::EngineLoader->new({
2727                 application_name => $class,
2728                 (defined $requested_engine
2729                      ? (requested_engine => $requested_engine) : ()),
2730             }),
2731
2732             $class->engine_loader($loader);
2733         }
2734
2735         $loader->catalyst_engine_class;
2736     };
2737
2738     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2739     return if $class->loading_psgi_file;
2740
2741     load_class($engine);
2742
2743     if ($ENV{MOD_PERL}) {
2744         my $apache = $class->engine_loader->auto;
2745
2746         my $meta = find_meta($class);
2747         my $was_immutable = $meta->is_immutable;
2748         my %immutable_options = $meta->immutable_options;
2749         $meta->make_mutable if $was_immutable;
2750
2751         $meta->add_method(handler => sub {
2752             my $r = shift;
2753             my $psgi_app = $class->_finalized_psgi_app;
2754             $apache->call_app($r, $psgi_app);
2755         });
2756
2757         $meta->make_immutable(%immutable_options) if $was_immutable;
2758     }
2759
2760     $class->engine( $engine->new );
2761
2762     return;
2763 }
2764
2765 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2766 ## build in server support (back compat support for pre psgi port behavior).
2767 ## This is so that we don't build a new psgi app for each request when using
2768 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2769
2770 sub _finalized_psgi_app {
2771     my ($app) = @_;
2772
2773     unless ($app->_psgi_app) {
2774         my $psgi_app = $app->_setup_psgi_app;
2775         $app->_psgi_app($psgi_app);
2776     }
2777
2778     return $app->_psgi_app;
2779 }
2780
2781 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2782 ## home directory and load that and return it (just assume it is doing the
2783 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2784 ## in default_middleware and return it ( this is for backward compatibility
2785 ## with pre psgi port behavior ).
2786
2787 sub _setup_psgi_app {
2788     my ($app) = @_;
2789
2790     for my $home (Path::Class::Dir->new($app->config->{home})) {
2791         my $psgi_file = $home->file(
2792             Catalyst::Utils::appprefix($app) . '.psgi',
2793         );
2794
2795         next unless -e $psgi_file;
2796
2797         # If $psgi_file calls ->setup_engine, it's doing so to load
2798         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2799         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2800         # anyway. So set a flag (ick) that tells setup_engine not to populate
2801         # $c->engine or do any other things we might regret.
2802
2803         $app->loading_psgi_file(1);
2804         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2805         $app->loading_psgi_file(0);
2806
2807         return $psgi_app
2808             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2809
2810         warn <<"EOW";
2811 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2812
2813 Its content has been ignored. Please consult the Catalyst::Upgrading
2814 documentation on how to upgrade from Catalyst::Engine::PSGI.
2815 EOW
2816     }
2817
2818     return $app->apply_default_middlewares($app->psgi_app);
2819 }
2820
2821 =head2 $c->apply_default_middlewares
2822
2823 Adds the following L<Plack> middlewares to your application, since they are
2824 useful and commonly needed:
2825
2826 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2827 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2828 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2829 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2830 applied since this middleware is smart enough to conditionally apply itself).
2831
2832 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2833 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2834 $ENV{SCRIPT_NAME}
2835
2836 =cut
2837
2838
2839 sub apply_default_middlewares {
2840     my ($app, $psgi_app) = @_;
2841
2842     $psgi_app = Plack::Middleware::Conditional->wrap(
2843         $psgi_app,
2844         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2845         condition => sub {
2846             my ($env) = @_;
2847             return if $app->config->{ignore_frontend_proxy};
2848             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2849                 || $app->config->{using_frontend_proxy};
2850         },
2851     );
2852
2853     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2854     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2855     $psgi_app = Plack::Middleware::Conditional->wrap(
2856         $psgi_app,
2857         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2858         condition => sub {
2859             my ($env) = @_;
2860             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2861             return unless $1 < 4.23;
2862             1;
2863         },
2864     );
2865
2866     # we're applying this unconditionally as the middleware itself already makes
2867     # sure it doesn't fuck things up if it's not running under one of the right
2868     # IIS versions
2869     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2870
2871     # And another IIS issue, this time with IIS7.
2872     $psgi_app = Plack::Middleware::Conditional->wrap(
2873         $psgi_app,
2874         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2875         condition => sub {
2876             my ($env) = @_;
2877             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2878         },
2879     );
2880
2881     return $psgi_app;
2882 }
2883
2884 =head2 $c->psgi_app
2885
2886 Returns a PSGI application code reference for the catalyst application
2887 C<$c>. This is the bare application without any middlewares
2888 applied. C<${myapp}.psgi> is not taken into account.
2889
2890 This is what you want to be using to retrieve the PSGI application code
2891 reference of your Catalyst application for use in F<.psgi> files.
2892
2893 =cut
2894
2895 sub psgi_app {
2896     my ($app) = @_;
2897     my $psgi = $app->engine->build_psgi_app($app);
2898     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
2899 }
2900
2901 =head2 $c->setup_home
2902
2903 Sets up the home directory.
2904
2905 =cut
2906
2907 sub setup_home {
2908     my ( $class, $home ) = @_;
2909
2910     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2911         $home = $env;
2912     }
2913
2914     $home ||= Catalyst::Utils::home($class);
2915
2916     if ($home) {
2917         #I remember recently being scolded for assigning config values like this
2918         $class->config->{home} ||= $home;
2919         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2920     }
2921 }
2922
2923 =head2 $c->setup_log
2924
2925 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2926 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2927 log to.
2928
2929 This method also installs a C<debug> method that returns a true value into the
2930 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2931 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2932
2933 Note that if the log has already been setup, by either a previous call to
2934 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2935 that this method won't actually set up the log object.
2936
2937 =cut
2938
2939 sub setup_log {
2940     my ( $class, $levels ) = @_;
2941
2942     $levels ||= '';
2943     $levels =~ s/^\s+//;
2944     $levels =~ s/\s+$//;
2945     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2946
2947     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2948     if ( defined $env_debug ) {
2949         $levels{debug} = 1 if $env_debug; # Ugly!
2950         delete($levels{debug}) unless $env_debug;
2951     }
2952
2953     unless ( $class->log ) {
2954         $class->log( Catalyst::Log->new(keys %levels) );
2955     }
2956
2957     if ( $levels{debug} ) {
2958         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2959         $class->log->debug('Debug messages enabled');
2960     }
2961 }
2962
2963 =head2 $c->setup_plugins
2964
2965 Sets up plugins.
2966
2967 =cut
2968
2969 =head2 $c->setup_stats
2970
2971 Sets up timing statistics class.
2972
2973 =cut
2974
2975 sub setup_stats {
2976     my ( $class, $stats ) = @_;
2977
2978     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2979
2980     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2981     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2982         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2983         $class->log->debug('Statistics enabled');
2984     }
2985 }
2986
2987
2988 =head2 $c->registered_plugins
2989
2990 Returns a sorted list of the plugins which have either been stated in the
2991 import list.
2992
2993 If passed a given plugin name, it will report a boolean value indicating
2994 whether or not that plugin is loaded.  A fully qualified name is required if
2995 the plugin name does not begin with C<Catalyst::Plugin::>.
2996
2997  if ($c->registered_plugins('Some::Plugin')) {
2998      ...
2999  }
3000
3001 =cut
3002
3003 {
3004
3005     sub registered_plugins {
3006         my $proto = shift;
3007         return sort keys %{ $proto->_plugins } unless @_;
3008         my $plugin = shift;
3009         return 1 if exists $proto->_plugins->{$plugin};
3010         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3011     }
3012
3013     sub _register_plugin {
3014         my ( $proto, $plugin, $instant ) = @_;
3015         my $class = ref $proto || $proto;
3016
3017         load_class( $plugin );
3018         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3019             if $plugin->isa( 'Catalyst::Component' );
3020         my $plugin_meta = Moose::Meta::Class->create($plugin);
3021         if (!$plugin_meta->has_method('new')
3022             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3023             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3024         }
3025         if (!$instant && !$proto->_plugins->{$plugin}) {
3026             my $meta = Class::MOP::get_metaclass_by_name($class);
3027             $meta->superclasses($plugin, $meta->superclasses);
3028         }
3029         $proto->_plugins->{$plugin} = 1;
3030         return $class;
3031     }
3032
3033     sub _default_plugins { return qw(Unicode::Encoding) }
3034
3035     sub setup_plugins {
3036         my ( $class, $plugins ) = @_;
3037
3038         $class->_plugins( {} ) unless $class->_plugins;
3039         $plugins = [ grep {
3040             m/Unicode::Encoding/ ? do {
3041                 $class->log->warn(
3042                     'Unicode::Encoding plugin is auto-applied,'
3043                     . ' please remove this from your appclass'
3044                     . ' and make sure to define "encoding" config'
3045                 );
3046                 unless (exists $class->config->{'encoding'}) {
3047                   $class->config->{'encoding'} = 'UTF-8';
3048                 }
3049                 () }
3050                 : $_
3051         } @$plugins ];
3052         push @$plugins, $class->_default_plugins;
3053         $plugins = Data::OptList::mkopt($plugins || []);
3054
3055         my @plugins = map {
3056             [ Catalyst::Utils::resolve_namespace(
3057                   $class . '::Plugin',
3058                   'Catalyst::Plugin', $_->[0]
3059               ),
3060               $_->[1],
3061             ]
3062          } @{ $plugins };
3063
3064         for my $plugin ( reverse @plugins ) {
3065             load_class($plugin->[0], $plugin->[1]);
3066             my $meta = find_meta($plugin->[0]);
3067             next if $meta && $meta->isa('Moose::Meta::Role');
3068
3069             $class->_register_plugin($plugin->[0]);
3070         }
3071
3072         my @roles =
3073             map  { $_->[0]->name, $_->[1] }
3074             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3075             map  { [find_meta($_->[0]), $_->[1]] }
3076             @plugins;
3077
3078         Moose::Util::apply_all_roles(
3079             $class => @roles
3080         ) if @roles;
3081     }
3082 }
3083
3084 =head2 registered_middlewares
3085
3086 Read only accessor that returns an array of all the middleware in the order
3087 that they were added (which is the REVERSE of the order they will be applied).
3088
3089 The values returned will be either instances of L<Plack::Middleware> or of a
3090 compatible interface, or a coderef, which is assumed to be inlined middleware
3091
3092 =head2 setup_middleware (?@middleware)
3093
3094 Read configuration information stored in configuration key C<psgi_middleware> or
3095 from passed @args.
3096
3097 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3098 to use it to enable L<Plack::Middleware>
3099
3100 This method is automatically called during 'setup' of your application, so
3101 you really don't need to invoke it.  However you may do so if you find the idea
3102 of loading middleware via configuration weird :).  For example:
3103
3104     package MyApp;
3105
3106     use Catalyst;
3107
3108     __PACKAGE__->setup_middleware('Head');
3109     __PACKAGE__->setup;
3110
3111 When we read middleware definitions from configuration, we reverse the list
3112 which sounds odd but is likely how you expect it to work if you have prior
3113 experience with L<Plack::Builder> or if you previously used the plugin
3114 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3115
3116 So basically your middleware handles an incoming request from the first
3117 registered middleware, down and handles the response from the last middleware
3118 up.
3119
3120 =cut
3121
3122 sub registered_middlewares {
3123     my $class = shift;
3124     if(my $middleware = $class->_psgi_middleware) {
3125         return (
3126           Catalyst::Middleware::Stash->new,
3127           Plack::Middleware::HTTPExceptions->new,
3128           Plack::Middleware::RemoveRedundantBody->new,
3129           Plack::Middleware::FixMissingBodyInRedirect->new,
3130           Plack::Middleware::ContentLength->new,
3131           Plack::Middleware::MethodOverride->new,
3132           Plack::Middleware::Head->new,
3133           @$middleware);
3134     } else {
3135         die "You cannot call ->registered_middlewares until middleware has been setup";
3136     }
3137 }
3138
3139 sub setup_middleware {
3140     my $class = shift;
3141     my @middleware_definitions = @_ ?
3142       reverse(@_) : reverse(@{$class->config->{'psgi_middleware'}||[]});
3143
3144     my @middleware = ();
3145     while(my $next = shift(@middleware_definitions)) {
3146         if(ref $next) {
3147             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3148                 push @middleware, $next;
3149             } elsif(ref $next eq 'CODE') {
3150                 push @middleware, $next;
3151             } elsif(ref $next eq 'HASH') {
3152                 my $namespace = shift @middleware_definitions;
3153                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3154                 push @middleware, $mw;
3155             } else {
3156               die "I can't handle middleware definition ${\ref $next}";
3157             }
3158         } else {
3159           my $mw = $class->Catalyst::Utils::build_middleware($next);
3160           push @middleware, $mw;
3161         }
3162     }
3163
3164     my @existing = @{$class->_psgi_middleware || []};
3165     $class->_psgi_middleware([@middleware,@existing,]);
3166 }
3167
3168 =head2 registered_data_handlers
3169
3170 A read only copy of registered Data Handlers returned as a Hash, where each key
3171 is a content type and each value is a subref that attempts to decode that content
3172 type.
3173
3174 =head2 setup_data_handlers (?@data_handler)
3175
3176 Read configuration information stored in configuration key C<data_handlers> or
3177 from passed @args.
3178
3179 See under L</CONFIGURATION> information regarding C<data_handlers>.
3180
3181 This method is automatically called during 'setup' of your application, so
3182 you really don't need to invoke it.
3183
3184 =head2 default_data_handlers
3185
3186 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3187 only two default data handlers, for 'application/json' and an alternative to
3188 'application/x-www-form-urlencoded' which supposed nested form parameters via
3189 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3190
3191 The 'application/json' data handler is used to parse incoming JSON into a Perl
3192 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3193 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3194 JSON decoder, and has the smallest dependency impact.
3195
3196 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3197 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3198 order to get the best performance.  You should add either to your dependency
3199 list (Makefile.PL, dist.ini, cpanfile, etc.)
3200
3201 =cut
3202
3203 sub registered_data_handlers {
3204     my $class = shift;
3205     if(my $data_handlers = $class->_data_handlers) {
3206         return %$data_handlers;
3207     } else {
3208         $class->setup_data_handlers;
3209         return $class->registered_data_handlers;
3210     }
3211 }
3212
3213 sub setup_data_handlers {
3214     my ($class, %data_handler_callbacks) = @_;
3215     %data_handler_callbacks = (
3216       %{$class->default_data_handlers},
3217       %{$class->config->{'data_handlers'}||+{}},
3218       %data_handler_callbacks);
3219
3220     $class->_data_handlers(\%data_handler_callbacks);
3221 }
3222
3223 sub default_data_handlers {
3224     my ($class) = @_;
3225     return +{
3226       'application/x-www-form-urlencoded' => sub {
3227           my ($fh, $req) = @_;
3228           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3229           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3230             ->can('build_cgi_struct')->($params);
3231       },
3232       'application/json' => sub {
3233           Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON')
3234             ->can('decode_json')->(do { local $/; $_->getline });
3235       },
3236     };
3237 }
3238
3239 =head2 $c->stack
3240
3241 Returns an arrayref of the internal execution stack (actions that are
3242 currently executing).
3243
3244 =head2 $c->stats
3245
3246 Returns the current timing statistics object. By default Catalyst uses
3247 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3248 L<< stats_class|/"$c->stats_class" >>.
3249
3250 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3251 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3252 profile explicitly, although MyApp.pm still won't profile nor output anything
3253 by itself.
3254
3255 =head2 $c->stats_class
3256
3257 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3258
3259 =head2 $c->use_stats
3260
3261 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3262
3263 Note that this is a static method, not an accessor and should be overridden
3264 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3265
3266 =cut
3267
3268 sub use_stats { 0 }
3269
3270
3271 =head2 $c->write( $data )
3272
3273 Writes $data to the output stream. When using this method directly, you
3274 will need to manually set the C<Content-Length> header to the length of
3275 your output data, if known.
3276
3277 =cut
3278
3279 sub write {
3280     my $c = shift;
3281
3282     # Finalize headers if someone manually writes output (for compat)
3283     $c->finalize_headers;
3284
3285     return $c->response->write( @_ );
3286 }
3287
3288 =head2 version
3289
3290 Returns the Catalyst version number. Mostly useful for "powered by"
3291 messages in template systems.
3292
3293 =cut
3294
3295 sub version { return $Catalyst::VERSION }
3296
3297 =head1 CONFIGURATION
3298
3299 There are a number of 'base' config variables which can be set:
3300
3301 =over
3302
3303 =item *
3304
3305 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3306
3307 =item *
3308
3309 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3310
3311 =item *
3312
3313 C<disable_component_resolution_regex_fallback> - Turns
3314 off the deprecated component resolution functionality so
3315 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3316 are called then regex search will not be attempted on string values and
3317 instead C<undef> will be returned.
3318
3319 =item *
3320
3321 C<home> - The application home directory. In an uninstalled application,
3322 this is the top level application directory. In an installed application,
3323 this will be the directory containing C<< MyApp.pm >>.
3324
3325 =item *
3326
3327 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3328
3329 =item *
3330
3331 C<name> - The name of the application in debug messages and the debug and
3332 welcome screens
3333
3334 =item *
3335
3336 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3337 until it is accessed. This allows you to (for example) check authentication (and reject
3338 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3339
3340 =item *
3341
3342 C<root> - The root directory for templates. Usually this is just a
3343 subdirectory of the home directory, but you can set it to change the
3344 templates to a different directory.
3345
3346 =item *
3347
3348 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3349 namespaces from which components will be loaded (and constructed and stored in
3350 C<< $c->components >>).
3351
3352 =item *
3353
3354 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3355 to be shown in hit debug tables in the test server.
3356
3357 =item *
3358
3359 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3360 variable should be used for determining the request path.
3361
3362 Most web server environments pass the requested path to the application using environment variables,
3363 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3364 exposed as C<< $c->request->base >>) and the request path below that base.
3365
3366 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3367 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3368
3369 =over
3370
3371 =item use_request_uri_for_path => 0
3372
3373 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3374 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3375 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3376 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3377
3378 However this method has the major disadvantage that it is impossible to correctly decode some elements
3379 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3380 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3381 can't distinguish / vs %2F in paths (in addition to other encoded values).
3382
3383 =item use_request_uri_for_path => 1
3384
3385 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3386 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3387 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3388
3389 Given that this method of path resolution is provably more correct, it is recommended that you use
3390 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3391 aware of the implications of not being able to handle encoded URI paths correctly.
3392
3393 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3394 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3395 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3396 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3397 C<< $c->request->base >> will be incorrect.
3398
3399 =back
3400
3401 =item *
3402
3403 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3404
3405 =item *
3406
3407 C<encoding> - See L</ENCODING>
3408
3409 =item *
3410
3411 C<abort_chain_on_error_fix>
3412
3413 When there is an error in an action chain, the default behavior is to continue
3414 processing the remaining actions and then catch the error upon chain end.  This
3415 can lead to running actions when the application is in an unexpected state.  If
3416 you have this issue, setting this config value to true will promptly exit a
3417 chain when there is an error raised in any action (thus terminating the chain
3418 early.)
3419
3420 use like:
3421
3422     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3423
3424 In the future this might become the default behavior.
3425
3426 =item *
3427
3428 C<use_hash_multivalue_in_request>
3429
3430 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3431 and C<parameters> return a hashref where values might be scalar or an arrayref
3432 depending on the incoming data.  In many cases this can be undesirable as it
3433 leads one to writing defensive code like the following:
3434
3435     my ($val) = ref($c->req->parameters->{a}) ?
3436       @{$c->req->parameters->{a}} :
3437         $c->req->parameters->{a};
3438
3439 Setting this configuration item to true will make L<Catalyst> populate the
3440 attributes underlying these methods with an instance of L<Hash::MultiValue>
3441 which is used by L<Plack::Request> and others to solve this very issue.  You
3442 may prefer this behavior to the default, if so enable this option (be warned
3443 if you enable it in a legacy application we are not sure if it is completely
3444 backwardly compatible).
3445
3446 =item *
3447
3448 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3449
3450 =item *
3451
3452 C<data_handlers> - See L<DATA HANDLERS>.
3453
3454 =back
3455
3456 =head1 EXCEPTIONS
3457
3458 Generally when you throw an exception inside an Action (or somewhere in
3459 your stack, such as in a model that an Action is calling) that exception
3460 is caught by Catalyst and unless you either catch it yourself (via eval
3461 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
3462 will eventually reach L</finalize_errors> and return either the debugging
3463 error stack page, or the default error page.  However, if your exception
3464 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
3465 instead rethrow it so that it can be handled by that middleware (which
3466 is part of the default middleware).  For example this would allow
3467
3468     use HTTP::Throwable::Factory 'http_throw';
3469
3470     sub throws_exception :Local {
3471       my ($self, $c) = @_;
3472
3473       http_throw(SeeOther => { location =>
3474         $c->uri_for($self->action_for('redirect')) });
3475
3476     }
3477
3478 =head1 INTERNAL ACTIONS
3479
3480 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3481 C<_ACTION>, and C<_END>. These are by default not shown in the private
3482 action table, but you can make them visible with a config parameter.
3483
3484     MyApp->config(show_internal_actions => 1);
3485
3486 =head1 ON-DEMAND PARSER
3487
3488 The request body is usually parsed at the beginning of a request,
3489 but if you want to handle input yourself, you can enable on-demand
3490 parsing with a config parameter.
3491
3492     MyApp->config(parse_on_demand => 1);
3493
3494 =head1 PROXY SUPPORT
3495
3496 Many production servers operate using the common double-server approach,
3497 with a lightweight frontend web server passing requests to a larger
3498 backend server. An application running on the backend server must deal
3499 with two problems: the remote user always appears to be C<127.0.0.1> and
3500 the server's hostname will appear to be C<localhost> regardless of the
3501 virtual host that the user connected through.
3502
3503 Catalyst will automatically detect this situation when you are running
3504 the frontend and backend servers on the same machine. The following
3505 changes are made to the request.
3506
3507     $c->req->address is set to the user's real IP address, as read from
3508     the HTTP X-Forwarded-For header.
3509
3510     The host value for $c->req->base and $c->req->uri is set to the real
3511     host, as read from the HTTP X-Forwarded-Host header.
3512
3513 Additionally, you may be running your backend application on an insecure
3514 connection (port 80) while your frontend proxy is running under SSL.  If there
3515 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3516 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3517 be created properly.
3518
3519 In the case of passing in:
3520
3521     X-Forwarded-Port: 443
3522
3523 All calls to C<uri_for> will result in an https link, as is expected.
3524
3525 Obviously, your web server must support these headers for this to work.
3526
3527 In a more complex server farm environment where you may have your
3528 frontend proxy server(s) on different machines, you will need to set a
3529 configuration option to tell Catalyst to read the proxied data from the
3530 headers.
3531
3532     MyApp->config(using_frontend_proxy => 1);
3533
3534 If you do not wish to use the proxy support at all, you may set:
3535
3536     MyApp->config(ignore_frontend_proxy => 0);
3537
3538 =head2 Note about psgi files
3539
3540 Note that if you supply your own .psgi file, calling
3541 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3542
3543 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3544 in your psgi, for example:
3545
3546     builder {
3547         enable "Plack::Middleware::ReverseProxy";
3548         MyApp->psgi_app
3549     };
3550
3551 This will unconditionally add the ReverseProxy support, or you need to call
3552 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3553 apply the support depending upon your config).
3554
3555 See L<Catalyst::PSGI> for more information.
3556
3557 =head1 THREAD SAFETY
3558
3559 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3560 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3561 believe the Catalyst core to be thread-safe.
3562
3563 If you plan to operate in a threaded environment, remember that all other
3564 modules you are using must also be thread-safe. Some modules, most notably
3565 L<DBD::SQLite>, are not thread-safe.
3566
3567 =head1 DATA HANDLERS
3568
3569 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3570 form parameters and URL search query fields.  However it has become common
3571 for various alternative content types to be PUT or POSTed to your controllers
3572 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3573 XML and other content types when communicating with an application server.  In
3574 order to better support this use case, L<Catalyst> defines a global configuration
3575 option, C<data_handlers>, which lets you associate a content type with a coderef
3576 that parses that content type into something Perl can readily access.
3577
3578     package MyApp::Web;
3579
3580     use Catalyst;
3581     use JSON::Maybe;
3582
3583     __PACKAGE__->config(
3584       data_handlers => {
3585         'application/json' => sub { local $/; decode_json $_->getline },
3586       },
3587       ## Any other configuration.
3588     );
3589
3590     __PACKAGE__->setup;
3591
3592 By default L<Catalyst> comes with a generic JSON data handler similar to the
3593 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3594 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3595 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3596 or dist.ini, cpanfile, etc.)
3597
3598 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
3599 (matched against the incoming request type using a regexp such as to be case
3600 insensitive) and whose values are coderefs that receive a localized version of
3601 C<$_> which is a filehandle object pointing to received body.
3602
3603 This feature is considered an early access release and we reserve the right
3604 to alter the interface in order to provide a performant and secure solution to
3605 alternative request body content.  Your reports welcomed!
3606
3607 =head1 PSGI MIDDLEWARE
3608
3609 You can define middleware, defined as L<Plack::Middleware> or a compatible
3610 interface in configuration.  Your middleware definitions are in the form of an
3611 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3612 with details to follow:
3613
3614     package MyApp::Web;
3615
3616     use Catalyst;
3617     use Plack::Middleware::StackTrace;
3618
3619     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3620
3621     __PACKAGE__->config(
3622       'psgi_middleware', [
3623         'Debug',
3624         '+MyApp::Custom',
3625         $stacktrace_middleware,
3626         'Session' => {store => 'File'},
3627         sub {
3628           my $app = shift;
3629           return sub {
3630             my $env = shift;
3631             $env->{myapp.customkey} = 'helloworld';
3632             $app->($env);
3633           },
3634         },
3635       ],
3636     );
3637
3638     __PACKAGE__->setup;
3639
3640 So the general form is:
3641
3642     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3643
3644 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3645 the order listed (to make it function similarly to L<Plack::Builder>:
3646
3647 Alternatively, you may also define middleware by calling the L</setup_middleware>
3648 package method:
3649
3650     package MyApp::Web;
3651
3652     use Catalyst;
3653
3654     __PACKAGE__->setup_middleware( \@middleware_definitions);
3655     __PACKAGE__->setup;
3656
3657 In the case where you do both (use 'setup_middleware' and configuration) the
3658 package call to setup_middleware will be applied earlier (in other words its
3659 middleware will wrap closer to the application).  Keep this in mind since in
3660 some cases the order of middleware is important.
3661
3662 The two approaches are not exclusive.
3663
3664 =over 4
3665
3666 =item Middleware Object
3667
3668 An already initialized object that conforms to the L<Plack::Middleware>
3669 specification:
3670
3671     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3672
3673     __PACKAGE__->config(
3674       'psgi_middleware', [
3675         $stacktrace_middleware,
3676       ]);
3677
3678
3679 =item coderef
3680
3681 A coderef that is an inlined middleware:
3682
3683     __PACKAGE__->config(
3684       'psgi_middleware', [
3685         sub {
3686           my $app = shift;
3687           return sub {
3688             my $env = shift;
3689             if($env->{PATH_INFO} =~m/forced/) {
3690               Plack::App::File
3691                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3692                 ->call($env);
3693             } else {
3694               return $app->($env);
3695             }
3696          },
3697       },
3698     ]);
3699
3700
3701
3702 =item a scalar
3703
3704 We assume the scalar refers to a namespace after normalizing it using the
3705 following rules:
3706
3707 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3708 is assumed to be 'as is', and we just install and use the middleware.
3709
3710 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3711 (the package name of your Catalyst application subclass), we also assume then
3712 that it is a full namespace, and use it.
3713
3714 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3715 resolve it first by looking for it under your application namespace (for example
3716 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3717 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3718 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3719 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3720 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3721 you find that a good idea.
3722
3723 Examples:
3724
3725     package MyApp::Web;
3726
3727     __PACKAGE__->config(
3728       'psgi_middleware', [
3729         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3730         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3731         '+MyApp::Custom',  ## MyApp::Custom->wrap
3732       ],
3733     );
3734
3735 =item a scalar followed by a hashref
3736
3737 Just like the previous, except the following C<HashRef> is used as arguments
3738 to initialize the middleware object.
3739
3740     __PACKAGE__->config(
3741       'psgi_middleware', [
3742          'Session' => {store => 'File'},
3743     ]);
3744
3745 =back
3746
3747 Please see L<PSGI> for more on middleware.
3748
3749 =head1 ENCODING
3750
3751 On request, decodes all params from encoding into a sequence of
3752 logical characters. On response, encodes body into encoding.
3753
3754 =head2 Methods
3755
3756 =over 4
3757
3758 =item encoding
3759
3760 Returns an instance of an C<Encode> encoding
3761
3762     print $c->encoding->name
3763
3764 =item handle_unicode_encoding_exception ($exception_context)
3765
3766 Method called when decoding process for a request fails.
3767
3768 An C<$exception_context> hashref is provided to allow you to override the
3769 behaviour of your application when given data with incorrect encodings.
3770
3771 The default method throws exceptions in the case of invalid request parameters
3772 (resulting in a 500 error), but ignores errors in upload filenames.
3773
3774 The keys passed in the C<$exception_context> hash are:
3775
3776 =over
3777
3778 =item param_value
3779
3780 The value which was not able to be decoded.
3781
3782 =item error_msg
3783
3784 The exception received from L<Encode>.
3785
3786 =item encoding_step
3787
3788 What type of data was being decoded. Valid values are (currently)
3789 C<params> - for request parameters / arguments / captures
3790 and C<uploads> - for request upload filenames.
3791
3792 =back
3793
3794 =back
3795
3796 =head1 SUPPORT
3797
3798 IRC:
3799
3800     Join #catalyst on irc.perl.org.
3801
3802 Mailing Lists:
3803
3804     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3805     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3806
3807 Web:
3808
3809     http://catalyst.perl.org
3810
3811 Wiki:
3812
3813     http://dev.catalyst.perl.org
3814
3815 =head1 SEE ALSO
3816
3817 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3818
3819 =head2 L<Catalyst::Manual> - The Catalyst Manual
3820
3821 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3822
3823 =head2 L<Catalyst::Engine> - Core engine
3824
3825 =head2 L<Catalyst::Log> - Log class.
3826
3827 =head2 L<Catalyst::Request> - Request object
3828
3829 =head2 L<Catalyst::Response> - Response object
3830
3831 =head2 L<Catalyst::Test> - The test suite.
3832
3833 =head1 PROJECT FOUNDER
3834
3835 sri: Sebastian Riedel <sri@cpan.org>
3836
3837 =head1 CONTRIBUTORS
3838
3839 abw: Andy Wardley
3840
3841 acme: Leon Brocard <leon@astray.com>
3842
3843 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3844
3845 Andrew Bramble
3846
3847 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3848
3849 Andrew Ruthven
3850
3851 andyg: Andy Grundman <andy@hybridized.org>
3852
3853 audreyt: Audrey Tang
3854
3855 bricas: Brian Cassidy <bricas@cpan.org>
3856
3857 Caelum: Rafael Kitover <rkitover@io.com>
3858
3859 chansen: Christian Hansen
3860
3861 chicks: Christopher Hicks
3862
3863 Chisel Wright C<pause@herlpacker.co.uk>
3864
3865 Danijel Milicevic C<me@danijel.de>
3866
3867 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3868
3869 David Naughton, C<naughton@umn.edu>
3870
3871 David E. Wheeler
3872
3873 dhoss: Devin Austin <dhoss@cpan.org>
3874
3875 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3876
3877 Drew Taylor
3878
3879 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3880
3881 esskar: Sascha Kiefer
3882
3883 fireartist: Carl Franks <cfranks@cpan.org>
3884
3885 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3886
3887 gabb: Danijel Milicevic
3888
3889 Gary Ashton Jones
3890
3891 Gavin Henry C<ghenry@perl.me.uk>
3892
3893 Geoff Richards
3894
3895 groditi: Guillermo Roditi <groditi@gmail.com>
3896
3897 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3898
3899 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3900
3901 jcamacho: Juan Camacho
3902
3903 jester: Jesse Sheidlower C<jester@panix.com>
3904
3905 jhannah: Jay Hannah <jay@jays.net>
3906
3907 Jody Belka
3908
3909 Johan Lindstrom
3910
3911 jon: Jon Schutz <jjschutz@cpan.org>
3912
3913 Jonathan Rockway C<< <jrockway@cpan.org> >>
3914
3915 Kieren Diment C<kd@totaldatasolution.com>
3916
3917 konobi: Scott McWhirter <konobi@cpan.org>
3918
3919 marcus: Marcus Ramberg <mramberg@cpan.org>
3920
3921 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3922
3923 mgrimes: Mark Grimes <mgrimes@cpan.org>
3924
3925 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3926
3927 mugwump: Sam Vilain
3928
3929 naughton: David Naughton
3930
3931 ningu: David Kamholz <dkamholz@cpan.org>
3932
3933 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3934
3935 numa: Dan Sully <daniel@cpan.org>
3936
3937 obra: Jesse Vincent
3938
3939 Octavian Rasnita
3940
3941 omega: Andreas Marienborg
3942
3943 Oleg Kostyuk <cub.uanic@gmail.com>
3944
3945 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3946
3947 rafl: Florian Ragwitz <rafl@debian.org>
3948
3949 random: Roland Lammel <lammel@cpan.org>
3950
3951 Robert Sedlacek C<< <rs@474.at> >>
3952
3953 SpiceMan: Marcel Montes
3954
3955 sky: Arthur Bergman
3956
3957 szbalint: Balint Szilakszi <szbalint@cpan.org>
3958
3959 t0m: Tomas Doran <bobtfish@bobtfish.net>
3960
3961 Ulf Edvinsson
3962
3963 vanstyn: Henry Van Styn <vanstyn@cpan.org>
3964
3965 Viljo Marrandi C<vilts@yahoo.com>
3966
3967 Will Hawes C<info@whawes.co.uk>
3968
3969 willert: Sebastian Willert <willert@cpan.org>
3970
3971 wreis: Wallace Reis <wreis@cpan.org>
3972
3973 Yuval Kogman, C<nothingmuch@woobling.org>
3974
3975 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3976
3977 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3978
3979 Upasana <me@upasana.me>
3980
3981 =head1 COPYRIGHT
3982
3983 Copyright (c) 2005-2014, the above named PROJECT FOUNDER and CONTRIBUTORS.
3984
3985 =head1 LICENSE
3986
3987 This library is free software. You can redistribute it and/or modify it under
3988 the same terms as Perl itself.
3989
3990 =cut
3991
3992 no Moose;
3993
3994 __PACKAGE__->meta->make_immutable;
3995
3996 1;