lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use Scalar::Util qw/weaken blessed/;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use attributes;
  26 use utf8;
  27 use Carp qw/croak/;
  28
  29 BEGIN { require 5.008001; }
  30
  31 __PACKAGE__->mk_accessors(
  32     qw/counter request response state action stack namespace stats/
  33 );
  34
  35 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class setup_finished/;
  56
  57 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  58 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  59 __PACKAGE__->request_class('Catalyst::Request');
  60 __PACKAGE__->response_class('Catalyst::Response');
  61
  62 # Remember to update this in Catalyst::Runtime as well!
  63
  64 our $VERSION = '5.7006';
  65
  66 sub import {
  67     my ( $class, @arguments ) = @_;
  68
  69     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  70     # callers @ISA.
  71     return unless $class eq 'Catalyst';
  72
  73     my $caller = caller(0);
  74
  75     unless ( $caller->isa('Catalyst') ) {
  76         no strict 'refs';
  77         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  78     }
  79
  80     $caller->arguments( [@arguments] );
  81     $caller->setup_home;
  82 }
  83
  84 =head1 NAME
  85
  86 Catalyst - The Elegant MVC Web Application Framework
  87
  88 =head1 SYNOPSIS
  89
  90     # Install Catalyst::Devel for helpers and other development tools
  91     # use the helper to create a new application
  92     catalyst.pl MyApp
  93
  94     # add models, views, controllers
  95     script/myapp_create.pl model Database DBIC::SchemaLoader dbi:SQLite:/path/to/db
  96     script/myapp_create.pl view TT TT
  97     script/myapp_create.pl controller Search
  98
  99     # built in testserver -- use -r to restart automatically on changes
 100     script/myapp_server.pl
 101
 102     # command line testing interface
 103     script/myapp_test.pl /yada
 104
 105     ### in lib/MyApp.pm
 106     use Catalyst qw/-Debug/; # include plugins here as well
 107
 108         ### In lib/MyApp/Controller/Root.pm (autocreated)
 109     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 110         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 111         $c->stash->{template} = 'foo.tt'; # set the template
 112         # lookup something from db -- stash vars are passed to TT
 113         $c->stash->{data} =
 114           $c->model('Database::Foo')->search( { country => $args[0] } );
 115         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 116             $c->forward( 'bar' ); # process another action
 117             # do something else after forward returns
 118         }
 119     }
 120
 121     # The foo.tt TT template can use the stash data from the database
 122     [% WHILE (item = data.next) %]
 123         [% item.foo %]
 124     [% END %]
 125
 126     # called for /bar/of/soap, /bar/of/soap/10, etc.
 127     sub bar : Path('/bar/of/soap') { ... }
 128
 129     # called for all actions, from the top-most controller downwards
 130     sub auto : Private {
 131         my ( $self, $c ) = @_;
 132         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 133             $c->res->redirect( '/login' ); # require login
 134             return 0; # abort request and go immediately to end()
 135         }
 136         return 1; # success; carry on to next action
 137     }
 138
 139     # called after all actions are finished
 140     sub end : Private {
 141         my ( $self, $c ) = @_;
 142         if ( scalar @{ $c->error } ) { ... } # handle errors
 143         return if $c->res->body; # already have a response
 144         $c->forward( 'MyApp::View::TT' ); # render template
 145     }
 146
 147     ### in MyApp/Controller/Foo.pm
 148     # called for /foo/bar
 149     sub bar : Local { ... }
 150
 151     # called for /blargle
 152     sub blargle : Global { ... }
 153
 154     # an index action matches /foo, but not /foo/1, etc.
 155     sub index : Private { ... }
 156
 157     ### in MyApp/Controller/Foo/Bar.pm
 158     # called for /foo/bar/baz
 159     sub baz : Local { ... }
 160
 161     # first Root auto is called, then Foo auto, then this
 162     sub auto : Private { ... }
 163
 164     # powerful regular expression paths are also possible
 165     sub details : Regex('^product/(\w+)/details$') {
 166         my ( $self, $c ) = @_;
 167         # extract the (\w+) from the URI
 168         my $product = $c->req->captures->[0];
 169     }
 170
 171 See L<Catalyst::Manual::Intro> for additional information.
 172
 173 =head1 DESCRIPTION
 174
 175 Catalyst is a modern framework for making web applications without the
 176 pain usually associated with this process. This document is a reference
 177 to the main Catalyst application. If you are a new user, we suggest you
 178 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 179
 180 See L<Catalyst::Manual> for more documentation.
 181
 182 Catalyst plugins can be loaded by naming them as arguments to the "use
 183 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 184 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 185 C<My::Module>.
 186
 187     use Catalyst qw/My::Module/;
 188
 189 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 190 fully qualify the name by using a unary plus:
 191
 192     use Catalyst qw/
 193         My::Module
 194         +Fully::Qualified::Plugin::Name
 195     /;
 196
 197 Special flags like C<-Debug> and C<-Engine> can also be specified as
 198 arguments when Catalyst is loaded:
 199
 200     use Catalyst qw/-Debug My::Module/;
 201
 202 The position of plugins and flags in the chain is important, because
 203 they are loaded in the order in which they appear.
 204
 205 The following flags are supported:
 206
 207 =head2 -Debug
 208
 209 Enables debug output. You can also force this setting from the system
 210 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 211 settings override the application, with <MYAPP>_DEBUG having the highest
 212 priority.
 213
 214 =head2 -Engine
 215
 216 Forces Catalyst to use a specific engine. Omit the
 217 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 218
 219     use Catalyst qw/-Engine=CGI/;
 220
 221 =head2 -Home
 222
 223 Forces Catalyst to use a specific home directory, e.g.:
 224
 225     use Catalyst qw[-Home=/usr/mst];
 226
 227 =head2 -Log
 228
 229 Specifies log level.
 230
 231 =head1 METHODS
 232
 233 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 234
 235 =head2 $c->action
 236
 237 Returns a L<Catalyst::Action> object for the current action, which
 238 stringifies to the action name. See L<Catalyst::Action>.
 239
 240 =head2 $c->namespace
 241
 242 Returns the namespace of the current action, i.e., the URI prefix
 243 corresponding to the controller of the current action. For example:
 244
 245     # in Controller::Foo::Bar
 246     $c->namespace; # returns 'foo/bar';
 247
 248 =head2 $c->request
 249
 250 =head2 $c->req
 251
 252 Returns the current L<Catalyst::Request> object, giving access to
 253 information about the current client request (including parameters,
 254 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 255
 256 =head2 REQUEST FLOW HANDLING
 257
 258 =head2 $c->forward( $action [, \@arguments ] )
 259
 260 =head2 $c->forward( $class, $method, [, \@arguments ] )
 261
 262 Forwards processing to another action, by its private name. If you give a
 263 class name but no method, C<process()> is called. You may also optionally
 264 pass arguments in an arrayref. The action will receive the arguments in
 265 C<@_> and C<$c-E<gt>req-E<gt>args>. Upon returning from the function,
 266 C<$c-E<gt>req-E<gt>args> will be restored to the previous values.
 267
 268 Any data C<return>ed from the action forwarded to, will be returned by the
 269 call to forward.
 270
 271     my $foodata = $c->forward('/foo');
 272     $c->forward('index');
 273     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 274     $c->forward('MyApp::View::TT');
 275
 276 Note that forward implies an C<<eval { }>> around the call (actually
 277 C<execute> does), thus de-fatalizing all 'dies' within the called
 278 action. If you want C<die> to propagate you need to do something like:
 279
 280     $c->forward('foo');
 281     die $c->error if $c->error;
 282
 283 Or make sure to always return true values from your actions and write
 284 your code like this:
 285
 286     $c->forward('foo') || return;
 287
 288 =cut
 289
 290 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 291
 292 =head2 $c->detach( $action [, \@arguments ] )
 293
 294 =head2 $c->detach( $class, $method, [, \@arguments ] )
 295
 296 =head2 $c->detach()
 297
 298 The same as C<forward>, but doesn't return to the previous action when
 299 processing is finished.
 300
 301 When called with no arguments it escapes the processing chain entirely.
 302
 303 =cut
 304
 305 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 306
 307 =head2 $c->response
 308
 309 =head2 $c->res
 310
 311 Returns the current L<Catalyst::Response> object, q.v.
 312
 313 =head2 $c->stash
 314
 315 Returns a hashref to the stash, which may be used to store data and pass
 316 it between components during a request. You can also set hash keys by
 317 passing arguments. The stash is automatically sent to the view. The
 318 stash is cleared at the end of a request; it cannot be used for
 319 persistent storage (for this you must use a session; see
 320 L<Catalyst::Plugin::Session> for a complete system integrated with
 321 Catalyst).
 322
 323     $c->stash->{foo} = $bar;
 324     $c->stash( { moose => 'majestic', qux => 0 } );
 325     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 326
 327     # stash is automatically passed to the view for use in a template
 328     $c->forward( 'MyApp::V::TT' );
 329
 330 =cut
 331
 332 sub stash {
 333     my $c = shift;
 334     if (@_) {
 335         my $stash = @_ > 1 ? {@_} : $_[0];
 336         croak('stash takes a hash or hashref') unless ref $stash;
 337         foreach my $key ( keys %$stash ) {
 338             $c->{stash}->{$key} = $stash->{$key};
 339         }
 340     }
 341     return $c->{stash};
 342 }
 343
 344 =head2 $c->error
 345
 346 =head2 $c->error($error, ...)
 347
 348 =head2 $c->error($arrayref)
 349
 350 Returns an arrayref containing error messages.  If Catalyst encounters an
 351 error while processing a request, it stores the error in $c->error.  This
 352 method should not be used to store non-fatal error messages.
 353
 354     my @error = @{ $c->error };
 355
 356 Add a new error.
 357
 358     $c->error('Something bad happened');
 359
 360 =cut
 361
 362 sub error {
 363     my $c = shift;
 364     if ( $_[0] ) {
 365         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 366         croak @$error unless ref $c;
 367         push @{ $c->{error} }, @$error;
 368     }
 369     elsif ( defined $_[0] ) { $c->{error} = undef }
 370     return $c->{error} || [];
 371 }
 372
 373
 374 =head2 $c->state
 375
 376 Contains the return value of the last executed action.
 377
 378 =head2 $c->clear_errors
 379
 380 Clear errors.  You probably don't want to clear the errors unless you are
 381 implementing a custom error screen.
 382
 383 This is equivalent to running
 384
 385     $c->error(0);
 386
 387 =cut
 388
 389 sub clear_errors {
 390     my $c = shift;
 391     $c->error(0);
 392 }
 393
 394
 395 # search via regex
 396 sub _comp_search {
 397     my ( $c, @names ) = @_;
 398
 399     foreach my $name (@names) {
 400         foreach my $component ( keys %{ $c->components } ) {
 401             return $c->components->{$component} if $component =~ /$name/i;
 402         }
 403     }
 404
 405     return undef;
 406 }
 407
 408 # try explicit component names
 409 sub _comp_explicit {
 410     my ( $c, @names ) = @_;
 411
 412     foreach my $try (@names) {
 413         return $c->components->{$try} if ( exists $c->components->{$try} );
 414     }
 415
 416     return undef;
 417 }
 418
 419 # like component, but try just these prefixes before regex searching,
 420 #  and do not try to return "sort keys %{ $c->components }"
 421 sub _comp_prefixes {
 422     my ( $c, $name, @prefixes ) = @_;
 423
 424     my $appclass = ref $c || $c;
 425
 426     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 427
 428     my $comp = $c->_comp_explicit(@names);
 429     return $comp if defined($comp);
 430     $comp = $c->_comp_search($name);
 431     return $comp;
 432 }
 433
 434 # Find possible names for a prefix
 435
 436 sub _comp_names {
 437     my ( $c, @prefixes ) = @_;
 438
 439     my $appclass = ref $c || $c;
 440
 441     my @pre = map { "${appclass}::${_}::" } @prefixes;
 442
 443     my @names;
 444
 445     COMPONENT: foreach my $comp ($c->component) {
 446         foreach my $p (@pre) {
 447             if ($comp =~ s/^$p//) {
 448                 push(@names, $comp);
 449                 next COMPONENT;
 450             }
 451         }
 452     }
 453
 454     return @names;
 455 }
 456
 457 # Return a component if only one matches.
 458 sub _comp_singular {
 459     my ( $c, @prefixes ) = @_;
 460
 461     my $appclass = ref $c || $c;
 462
 463     my ( $comp, $rest ) =
 464       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 465     return $comp unless $rest;
 466 }
 467
 468 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 469 sub _filter_component {
 470     my ( $c, $comp, @args ) = @_;
 471     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 472         return $comp->ACCEPT_CONTEXT( $c, @args );
 473     }
 474     else { return $comp }
 475 }
 476
 477 =head2 COMPONENT ACCESSORS
 478
 479 =head2 $c->controller($name)
 480
 481 Gets a L<Catalyst::Controller> instance by name.
 482
 483     $c->controller('Foo')->do_stuff;
 484
 485 If the name is omitted, will return the controller for the dispatched
 486 action.
 487
 488 =cut
 489
 490 sub controller {
 491     my ( $c, $name, @args ) = @_;
 492     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 493         @args )
 494       if ($name);
 495     return $c->component( $c->action->class );
 496 }
 497
 498 =head2 $c->model($name)
 499
 500 Gets a L<Catalyst::Model> instance by name.
 501
 502     $c->model('Foo')->do_stuff;
 503
 504 If the name is omitted, it will look for
 505  - a model object in $c->stash{current_model_instance}, then
 506  - a model name in $c->stash->{current_model}, then
 507  - a config setting 'default_model', or
 508  - check if there is only one model, and return it if that's the case.
 509
 510 =cut
 511
 512 sub model {
 513     my ( $c, $name, @args ) = @_;
 514     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 515         @args )
 516       if $name;
 517     if (ref $c) {
 518         return $c->stash->{current_model_instance}
 519           if $c->stash->{current_model_instance};
 520         return $c->model( $c->stash->{current_model} )
 521           if $c->stash->{current_model};
 522         return $c->model( $c->config->{default_model} )
 523           if $c->config->{default_model};
 524     }
 525     return $c->_filter_component( $c->_comp_singular(qw/Model M/), @args );
 526
 527 }
 528
 529 =head2 $c->controllers
 530
 531 Returns the available names which can be passed to $c->controller
 532
 533 =cut
 534
 535 sub controllers {
 536     my ( $c ) = @_;
 537     return $c->_comp_names(qw/Controller C/);
 538 }
 539
 540
 541 =head2 $c->view($name)
 542
 543 Gets a L<Catalyst::View> instance by name.
 544
 545     $c->view('Foo')->do_stuff;
 546
 547 If the name is omitted, it will look for
 548  - a view object in $c->stash{current_view_instance}, then
 549  - a view name in $c->stash->{current_view}, then
 550  - a config setting 'default_view', or
 551  - check if there is only one view, and return it if that's the case.
 552
 553 =cut
 554
 555 sub view {
 556     my ( $c, $name, @args ) = @_;
 557     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 558         @args )
 559       if $name;
 560     if (ref $c) {
 561         return $c->stash->{current_view_instance}
 562           if $c->stash->{current_view_instance};
 563         return $c->view( $c->stash->{current_view} )
 564           if $c->stash->{current_view};
 565         return $c->view( $c->config->{default_view} )
 566           if $c->config->{default_view};
 567     }
 568     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 569 }
 570
 571 =head2 $c->models
 572
 573 Returns the available names which can be passed to $c->model
 574
 575 =cut
 576
 577 sub models {
 578     my ( $c ) = @_;
 579     return $c->_comp_names(qw/Model M/);
 580 }
 581
 582
 583 =head2 $c->views
 584
 585 Returns the available names which can be passed to $c->view
 586
 587 =cut
 588
 589 sub views {
 590     my ( $c ) = @_;
 591     return $c->_comp_names(qw/View V/);
 592 }
 593
 594 =head2 $c->comp($name)
 595
 596 =head2 $c->component($name)
 597
 598 Gets a component object by name. This method is no longer recommended,
 599 unless you want to get a specific component by full
 600 class. C<$c-E<gt>controller>, C<$c-E<gt>model>, and C<$c-E<gt>view>
 601 should be used instead.
 602
 603 =cut
 604
 605 sub component {
 606     my $c = shift;
 607
 608     if (@_) {
 609
 610         my $name = shift;
 611
 612         my $appclass = ref $c || $c;
 613
 614         my @names = (
 615             $name, "${appclass}::${name}",
 616             map { "${appclass}::${_}::${name}" }
 617               qw/Model M Controller C View V/
 618         );
 619
 620         my $comp = $c->_comp_explicit(@names);
 621         return $c->_filter_component( $comp, @_ ) if defined($comp);
 622
 623         $comp = $c->_comp_search($name);
 624         return $c->_filter_component( $comp, @_ ) if defined($comp);
 625     }
 626
 627     return sort keys %{ $c->components };
 628 }
 629
 630
 631
 632 =head2 CLASS DATA AND HELPER CLASSES
 633
 634 =head2 $c->config
 635
 636 Returns or takes a hashref containing the application's configuration.
 637
 638     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 639
 640 You can also use a L<YAML> config file like myapp.yml in your
 641 applications home directory.
 642
 643     ---
 644     db: dsn:SQLite:foo.db
 645
 646
 647 =cut
 648
 649 sub config {
 650     my $c = shift;
 651
 652     $c->log->warn("Setting config after setup has been run is not a good idea.")
 653       if ( @_ and $c->setup_finished );
 654
 655     $c->NEXT::config(@_);
 656 }
 657
 658 =head2 $c->log
 659
 660 Returns the logging object instance. Unless it is already set, Catalyst
 661 sets this up with a L<Catalyst::Log> object. To use your own log class,
 662 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 663 C<< __PACKAGE__->setup >>.
 664
 665  __PACKAGE__->log( MyLogger->new );
 666  __PACKAGE__->setup;
 667
 668 And later:
 669
 670     $c->log->info( 'Now logging with my own logger!' );
 671
 672 Your log class should implement the methods described in
 673 L<Catalyst::Log>.
 674
 675
 676 =head2 $c->debug
 677
 678 Overload to enable debug messages (same as -Debug option).
 679
 680 Note that this is a static method, not an accessor and should be overloaded
 681 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 682
 683 =cut
 684
 685 sub debug { 0 }
 686
 687 =head2 $c->dispatcher
 688
 689 Returns the dispatcher instance. Stringifies to class name. See
 690 L<Catalyst::Dispatcher>.
 691
 692 =head2 $c->engine
 693
 694 Returns the engine instance. Stringifies to the class name. See
 695 L<Catalyst::Engine>.
 696
 697
 698 =head2 UTILITY METHODS
 699
 700 =head2 $c->path_to(@path)
 701
 702 Merges C<@path> with C<$c-E<gt>config-E<gt>{home}> and returns a
 703 L<Path::Class> object.
 704
 705 For example:
 706
 707     $c->path_to( 'db', 'sqlite.db' );
 708
 709 =cut
 710
 711 sub path_to {
 712     my ( $c, @path ) = @_;
 713     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 714     if ( -d $path ) { return $path }
 715     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 716 }
 717
 718 =head2 $c->plugin( $name, $class, @args )
 719
 720 Helper method for plugins. It creates a classdata accessor/mutator and
 721 loads and instantiates the given class.
 722
 723     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 724
 725     $c->prototype->define_javascript_functions;
 726
 727 =cut
 728
 729 sub plugin {
 730     my ( $class, $name, $plugin, @args ) = @_;
 731     $class->_register_plugin( $plugin, 1 );
 732
 733     eval { $plugin->import };
 734     $class->mk_classdata($name);
 735     my $obj;
 736     eval { $obj = $plugin->new(@args) };
 737
 738     if ($@) {
 739         Catalyst::Exception->throw( message =>
 740               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 741     }
 742
 743     $class->$name($obj);
 744     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 745       if $class->debug;
 746 }
 747
 748 =head2 MyApp->setup
 749
 750 Initializes the dispatcher and engine, loads any plugins, and loads the
 751 model, view, and controller components. You may also specify an array
 752 of plugins to load here, if you choose to not load them in the C<use
 753 Catalyst> line.
 754
 755     MyApp->setup;
 756     MyApp->setup( qw/-Debug/ );
 757
 758 =cut
 759
 760 sub setup {
 761     my ( $class, @arguments ) = @_;
 762
 763     $class->log->warn("Running setup twice is not a good idea.")
 764       if ( $class->setup_finished );
 765
 766     unless ( $class->isa('Catalyst') ) {
 767
 768         Catalyst::Exception->throw(
 769             message => qq/'$class' does not inherit from Catalyst/ );
 770     }
 771
 772     if ( $class->arguments ) {
 773         @arguments = ( @arguments, @{ $class->arguments } );
 774     }
 775
 776     # Process options
 777     my $flags = {};
 778
 779     foreach (@arguments) {
 780
 781         if (/^-Debug$/) {
 782             $flags->{log} =
 783               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 784         }
 785         elsif (/^-(\w+)=?(.*)$/) {
 786             $flags->{ lc $1 } = $2;
 787         }
 788         else {
 789             push @{ $flags->{plugins} }, $_;
 790         }
 791     }
 792
 793     $class->setup_home( delete $flags->{home} );
 794
 795     $class->setup_log( delete $flags->{log} );
 796     $class->setup_plugins( delete $flags->{plugins} );
 797     $class->setup_dispatcher( delete $flags->{dispatcher} );
 798     $class->setup_engine( delete $flags->{engine} );
 799
 800     for my $flag ( sort keys %{$flags} ) {
 801
 802         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 803             &$code( $class, delete $flags->{$flag} );
 804         }
 805         else {
 806             $class->log->warn(qq/Unknown flag "$flag"/);
 807         }
 808     }
 809
 810     eval { require Catalyst::Devel; };
 811     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 812         $class->log->warn(<<"EOF");
 813 You are running an old script!
 814
 815   Please update by running (this will overwrite existing files):
 816     catalyst.pl -force -scripts $class
 817
 818   or (this will not overwrite existing files):
 819     catalyst.pl -scripts $class
 820
 821 EOF
 822     }
 823
 824     if ( $class->debug ) {
 825         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 826
 827         if (@plugins) {
 828             my $t = Text::SimpleTable->new(74);
 829             $t->row($_) for @plugins;
 830             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 831         }
 832
 833         my $dispatcher = $class->dispatcher;
 834         my $engine     = $class->engine;
 835         my $home       = $class->config->{home};
 836
 837         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 838         $class->log->debug(qq/Loaded engine "$engine"/);
 839
 840         $home
 841           ? ( -d $home )
 842           ? $class->log->debug(qq/Found home "$home"/)
 843           : $class->log->debug(qq/Home "$home" doesn't exist/)
 844           : $class->log->debug(q/Couldn't find home/);
 845     }
 846
 847     # Call plugins setup
 848     {
 849         no warnings qw/redefine/;
 850         local *setup = sub { };
 851         $class->setup;
 852     }
 853
 854     # Initialize our data structure
 855     $class->components( {} );
 856
 857     $class->setup_components;
 858
 859     if ( $class->debug ) {
 860         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 861         for my $comp ( sort keys %{ $class->components } ) {
 862             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 863             $t->row( $comp, $type );
 864         }
 865         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 866           if ( keys %{ $class->components } );
 867     }
 868
 869     # Add our self to components, since we are also a component
 870     $class->components->{$class} = $class;
 871
 872     $class->setup_actions;
 873
 874     if ( $class->debug ) {
 875         my $name = $class->config->{name} || 'Application';
 876         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 877     }
 878     $class->log->_flush() if $class->log->can('_flush');
 879
 880     $class->setup_finished(1);
 881 }
 882
 883 =head2 $c->uri_for( $path, @args?, \%query_values? )
 884
 885 Merges path with C<< $c->request->base >> for absolute URIs and with
 886 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 887 object. If any args are passed, they are added at the end of the path.
 888 If the last argument to C<uri_for> is a hash reference, it is assumed to
 889 contain GET parameter key/value pairs, which will be appended to the URI
 890 in standard fashion.
 891
 892 Instead of C<$path>, you can also optionally pass a C<$action> object
 893 which will be resolved to a path using
 894 C<< $c->dispatcher->uri_for_action >>; if the first element of
 895 C<@args> is an arrayref it is treated as a list of captures to be passed
 896 to C<uri_for_action>.
 897
 898 =cut
 899
 900 sub uri_for {
 901     my ( $c, $path, @args ) = @_;
 902     my $base     = $c->request->base->clone;
 903     my $basepath = $base->path;
 904     $basepath =~ s/\/$//;
 905     $basepath .= '/';
 906     my $namespace = $c->namespace || '';
 907
 908     if ( Scalar::Util::blessed($path) ) { # action object
 909         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 910                          ? shift(@args)
 911                          : [] );
 912         $path = $c->dispatcher->uri_for_action($path, $captures);
 913         return undef unless defined($path);
 914         $path = '/' if $path eq '';
 915     }
 916
 917     # massage namespace, empty if absolute path
 918     $namespace =~ s/^\/// if $namespace;
 919     $namespace .= '/' if $namespace;
 920     $path ||= '';
 921     $namespace = '' if $path =~ /^\//;
 922     $path =~ s/^\///;
 923
 924     my $params =
 925       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 926
 927     for my $value ( values %$params ) {
 928         next unless defined $value;
 929         for ( ref $value eq 'ARRAY' ? @$value : $value ) {
 930             $_ = "$_";
 931             utf8::encode( $_ );
 932         }
 933     };
 934
 935     # join args with '/', or a blank string
 936     my $args = ( scalar @args ? '/' . join( '/', @args ) : '' );
 937     $args =~ s/^\/// unless $path;
 938     my $res =
 939       URI->new_abs( URI->new_abs( "$path$args", "$basepath$namespace" ), $base )
 940       ->canonical;
 941     $res->query_form(%$params);
 942     $res;
 943 }
 944
 945 =head2 $c->welcome_message
 946
 947 Returns the Catalyst welcome HTML page.
 948
 949 =cut
 950
 951 sub welcome_message {
 952     my $c      = shift;
 953     my $name   = $c->config->{name};
 954     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
 955     my $prefix = Catalyst::Utils::appprefix( ref $c );
 956     $c->response->content_type('text/html; charset=utf-8');
 957     return <<"EOF";
 958 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
 959     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 960 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 961     <head>
 962         <meta http-equiv="Content-Language" content="en" />
 963         <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
 964         <title>$name on Catalyst $VERSION</title>
 965         <style type="text/css">
 966             body {
 967                 color: #000;
 968                 background-color: #eee;
 969             }
 970             div#content {
 971                 width: 640px;
 972                 margin-left: auto;
 973                 margin-right: auto;
 974                 margin-top: 10px;
 975                 margin-bottom: 10px;
 976                 text-align: left;
 977                 background-color: #ccc;
 978                 border: 1px solid #aaa;
 979             }
 980             p, h1, h2 {
 981                 margin-left: 20px;
 982                 margin-right: 20px;
 983                 font-family: verdana, tahoma, sans-serif;
 984             }
 985             a {
 986                 font-family: verdana, tahoma, sans-serif;
 987             }
 988             :link, :visited {
 989                     text-decoration: none;
 990                     color: #b00;
 991                     border-bottom: 1px dotted #bbb;
 992             }
 993             :link:hover, :visited:hover {
 994                     color: #555;
 995             }
 996             div#topbar {
 997                 margin: 0px;
 998             }
 999             pre {
1000                 margin: 10px;
1001                 padding: 8px;
1002             }
1003             div#answers {
1004                 padding: 8px;
1005                 margin: 10px;
1006                 background-color: #fff;
1007                 border: 1px solid #aaa;
1008             }
1009             h1 {
1010                 font-size: 0.9em;
1011                 font-weight: normal;
1012                 text-align: center;
1013             }
1014             h2 {
1015                 font-size: 1.0em;
1016             }
1017             p {
1018                 font-size: 0.9em;
1019             }
1020             p img {
1021                 float: right;
1022                 margin-left: 10px;
1023             }
1024             span#appname {
1025                 font-weight: bold;
1026                 font-size: 1.6em;
1027             }
1028         </style>
1029     </head>
1030     <body>
1031         <div id="content">
1032             <div id="topbar">
1033                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1034                     $VERSION</h1>
1035              </div>
1036              <div id="answers">
1037                  <p>
1038                  <img src="$logo" alt="Catalyst Logo" />
1039                  </p>
1040                  <p>Welcome to the wonderful world of Catalyst.
1041                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1042                     framework will make web development something you had
1043                     never expected it to be: Fun, rewarding, and quick.</p>
1044                  <h2>What to do now?</h2>
1045                  <p>That really depends  on what <b>you</b> want to do.
1046                     We do, however, provide you with a few starting points.</p>
1047                  <p>If you want to jump right into web development with Catalyst
1048                     you might want to check out the documentation.</p>
1049                  <pre><code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1050 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1051 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual.pod">Catalyst::Manual</a></code></pre>
1052                  <h2>What to do next?</h2>
1053                  <p>Next it's time to write an actual application. Use the
1054                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1055                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1056                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1057                     they can save you a lot of work.</p>
1058                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1059                     <p>Also, be sure to check out the vast and growing
1060                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1061                     you are likely to find what you need there.
1062                     </p>
1063
1064                  <h2>Need help?</h2>
1065                  <p>Catalyst has a very active community. Here are the main places to
1066                     get in touch with us.</p>
1067                  <ul>
1068                      <li>
1069                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1070                      </li>
1071                      <li>
1072                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1073                      </li>
1074                      <li>
1075                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1076                      </li>
1077                  </ul>
1078                  <h2>In conclusion</h2>
1079                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1080                     as we enjoyed making it. Please contact us if you have ideas
1081                     for improvement or other feedback.</p>
1082              </div>
1083          </div>
1084     </body>
1085 </html>
1086 EOF
1087 }
1088
1089 =head1 INTERNAL METHODS
1090
1091 These methods are not meant to be used by end users.
1092
1093 =head2 $c->components
1094
1095 Returns a hash of components.
1096
1097 =head2 $c->context_class
1098
1099 Returns or sets the context class.
1100
1101 =head2 $c->counter
1102
1103 Returns a hashref containing coderefs and execution counts (needed for
1104 deep recursion detection).
1105
1106 =head2 $c->depth
1107
1108 Returns the number of actions on the current internal execution stack.
1109
1110 =head2 $c->dispatch
1111
1112 Dispatches a request to actions.
1113
1114 =cut
1115
1116 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1117
1118 =head2 $c->dispatcher_class
1119
1120 Returns or sets the dispatcher class.
1121
1122 =head2 $c->dump_these
1123
1124 Returns a list of 2-element array references (name, structure) pairs
1125 that will be dumped on the error page in debug mode.
1126
1127 =cut
1128
1129 sub dump_these {
1130     my $c = shift;
1131     [ Request => $c->req ],
1132     [ Response => $c->res ],
1133     [ Stash => $c->stash ],
1134     [ Config => $c->config ];
1135 }
1136
1137 =head2 $c->engine_class
1138
1139 Returns or sets the engine class.
1140
1141 =head2 $c->execute( $class, $coderef )
1142
1143 Execute a coderef in given class and catch exceptions. Errors are available
1144 via $c->error.
1145
1146 =cut
1147
1148 sub execute {
1149     my ( $c, $class, $code ) = @_;
1150     $class = $c->component($class) || $class;
1151     $c->state(0);
1152
1153     if ( $c->depth >= $RECURSION ) {
1154         my $action = "$code";
1155         $action = "/$action" unless $action =~ /->/;
1156         my $error = qq/Deep recursion detected calling "$action"/;
1157         $c->log->error($error);
1158         $c->error($error);
1159         $c->state(0);
1160         return $c->state;
1161     }
1162
1163     my $stats_info = $c->_stats_start_execute( $code ) if $c->debug;
1164
1165     push( @{ $c->stack }, $code );
1166
1167     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1168
1169     $c->_stats_finish_execute( $stats_info ) if $c->debug and $stats_info;
1170
1171     my $last = pop( @{ $c->stack } );
1172
1173     if ( my $error = $@ ) {
1174         if ( !ref($error) and $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1175         else {
1176             unless ( ref $error ) {
1177                 no warnings 'uninitialized';
1178                 chomp $error;
1179                 my $class = $last->class;
1180                 my $name  = $last->name;
1181                 $error = qq/Caught exception in $class->$name "$error"/;
1182             }
1183             $c->error($error);
1184             $c->state(0);
1185         }
1186     }
1187     return $c->state;
1188 }
1189
1190 sub _stats_start_execute {
1191     my ( $c, $code ) = @_;
1192
1193     return if ( ( $code->name =~ /^_.*/ )
1194         && ( !$c->config->{show_internal_actions} ) );
1195
1196     $c->counter->{"$code"}++;
1197
1198     my $action = "$code";
1199     $action = "/$action" unless $action =~ /->/;
1200
1201     # determine if the call was the result of a forward
1202     # this is done by walking up the call stack and looking for a calling
1203     # sub of Catalyst::forward before the eval
1204     my $callsub = q{};
1205     for my $index ( 2 .. 11 ) {
1206         last
1207         if ( ( caller($index) )[0] eq 'Catalyst'
1208             && ( caller($index) )[3] eq '(eval)' );
1209
1210         if ( ( caller($index) )[3] =~ /forward$/ ) {
1211             $callsub = ( caller($index) )[3];
1212             $action  = "-> $action";
1213             last;
1214         }
1215     }
1216
1217     my $node = Tree::Simple->new(
1218         {
1219             action  => $action,
1220             elapsed => undef,     # to be filled in later
1221             comment => "",
1222         }
1223     );
1224     $node->setUID( "$code" . $c->counter->{"$code"} );
1225
1226     # is this a root-level call or a forwarded call?
1227     if ( $callsub =~ /forward$/ ) {
1228
1229         # forward, locate the caller
1230         if ( my $parent = $c->stack->[-1] ) {
1231             my $visitor = Tree::Simple::Visitor::FindByUID->new;
1232             $visitor->searchForUID(
1233                 "$parent" . $c->counter->{"$parent"} );
1234             $c->stats->accept($visitor);
1235             if ( my $result = $visitor->getResult ) {
1236                 $result->addChild($node);
1237             }
1238         }
1239         else {
1240
1241             # forward with no caller may come from a plugin
1242             $c->stats->addChild($node);
1243         }
1244     }
1245     else {
1246
1247         # root-level call
1248         $c->stats->addChild($node);
1249     }
1250
1251     return {
1252         start   => [gettimeofday],
1253         node    => $node,
1254     };
1255 }
1256
1257 sub _stats_finish_execute {
1258     my ( $c, $info ) = @_;
1259     my $elapsed = tv_interval $info->{start};
1260     my $value = $info->{node}->getNodeValue;
1261     $value->{elapsed} = sprintf( '%fs', $elapsed );
1262 }
1263
1264 =head2 $c->_localize_fields( sub { }, \%keys );
1265
1266 =cut
1267
1268 sub _localize_fields {
1269     my ( $c, $localized, $code ) = ( @_ );
1270
1271     my $request = delete $localized->{request} || {};
1272     my $response = delete $localized->{response} || {};
1273
1274     local @{ $c }{ keys %$localized } = values %$localized;
1275     local @{ $c->request }{ keys %$request } = values %$request;
1276     local @{ $c->response }{ keys %$response } = values %$response;
1277
1278     $code->();
1279 }
1280
1281 =head2 $c->finalize
1282
1283 Finalizes the request.
1284
1285 =cut
1286
1287 sub finalize {
1288     my $c = shift;
1289
1290     for my $error ( @{ $c->error } ) {
1291         $c->log->error($error);
1292     }
1293
1294     # Allow engine to handle finalize flow (for POE)
1295     if ( $c->engine->can('finalize') ) {
1296         $c->engine->finalize($c);
1297     }
1298     else {
1299
1300         $c->finalize_uploads;
1301
1302         # Error
1303         if ( $#{ $c->error } >= 0 ) {
1304             $c->finalize_error;
1305         }
1306
1307         $c->finalize_headers;
1308
1309         # HEAD request
1310         if ( $c->request->method eq 'HEAD' ) {
1311             $c->response->body('');
1312         }
1313
1314         $c->finalize_body;
1315     }
1316
1317     if ($c->debug) {
1318         my $elapsed = sprintf '%f', tv_interval($c->stats->getNodeValue);
1319         my $av = sprintf '%.3f', ( $elapsed == 0 ? '??' : ( 1 / $elapsed ) );
1320
1321         my $t = Text::SimpleTable->new( [ 62, 'Action' ], [ 9, 'Time' ] );
1322         $c->stats->traverse(
1323             sub {
1324                 my $action = shift;
1325                 my $stat   = $action->getNodeValue;
1326                 $t->row( ( q{ } x $action->getDepth ) . $stat->{action} . $stat->{comment},
1327                     $stat->{elapsed} || '??' );
1328             }
1329         );
1330
1331         $c->log->info(
1332             "Request took ${elapsed}s ($av/s)\n" . $t->draw . "\n" );
1333     }
1334
1335     return $c->response->status;
1336 }
1337
1338 =head2 $c->finalize_body
1339
1340 Finalizes body.
1341
1342 =cut
1343
1344 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1345
1346 =head2 $c->finalize_cookies
1347
1348 Finalizes cookies.
1349
1350 =cut
1351
1352 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1353
1354 =head2 $c->finalize_error
1355
1356 Finalizes error.
1357
1358 =cut
1359
1360 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1361
1362 =head2 $c->finalize_headers
1363
1364 Finalizes headers.
1365
1366 =cut
1367
1368 sub finalize_headers {
1369     my $c = shift;
1370
1371     # Check if we already finalized headers
1372     return if $c->response->{_finalized_headers};
1373
1374     # Handle redirects
1375     if ( my $location = $c->response->redirect ) {
1376         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1377         $c->response->header( Location => $location );
1378     }
1379
1380     # Content-Length
1381     if ( $c->response->body && !$c->response->content_length ) {
1382
1383         # get the length from a filehandle
1384         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1385         {
1386             if ( my $stat = stat $c->response->body ) {
1387                 $c->response->content_length( $stat->size );
1388             }
1389             else {
1390                 $c->log->warn('Serving filehandle without a content-length');
1391             }
1392         }
1393         else {
1394             $c->response->content_length( bytes::length( $c->response->body ) );
1395         }
1396     }
1397
1398     # Errors
1399     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1400         $c->response->headers->remove_header("Content-Length");
1401         $c->response->body('');
1402     }
1403
1404     $c->finalize_cookies;
1405
1406     $c->engine->finalize_headers( $c, @_ );
1407
1408     # Done
1409     $c->response->{_finalized_headers} = 1;
1410 }
1411
1412 =head2 $c->finalize_output
1413
1414 An alias for finalize_body.
1415
1416 =head2 $c->finalize_read
1417
1418 Finalizes the input after reading is complete.
1419
1420 =cut
1421
1422 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1423
1424 =head2 $c->finalize_uploads
1425
1426 Finalizes uploads. Cleans up any temporary files.
1427
1428 =cut
1429
1430 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1431
1432 =head2 $c->get_action( $action, $namespace )
1433
1434 Gets an action in a given namespace.
1435
1436 =cut
1437
1438 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1439
1440 =head2 $c->get_actions( $action, $namespace )
1441
1442 Gets all actions of a given name in a namespace and all parent
1443 namespaces.
1444
1445 =cut
1446
1447 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1448
1449 =head2 $c->handle_request( $class, @arguments )
1450
1451 Called to handle each HTTP request.
1452
1453 =cut
1454
1455 sub handle_request {
1456     my ( $class, @arguments ) = @_;
1457
1458     # Always expect worst case!
1459     my $status = -1;
1460     eval {
1461         if ($class->debug) {
1462             my $secs = time - $START || 1;
1463             my $av = sprintf '%.3f', $COUNT / $secs;
1464             my $time = localtime time;
1465             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1466         }
1467
1468         my $c = $class->prepare(@arguments);
1469         $c->dispatch;
1470         $status = $c->finalize;
1471     };
1472
1473     if ( my $error = $@ ) {
1474         chomp $error;
1475         $class->log->error(qq/Caught exception in engine "$error"/);
1476     }
1477
1478     $COUNT++;
1479     $class->log->_flush() if $class->log->can('_flush');
1480     return $status;
1481 }
1482
1483 =head2 $c->prepare( @arguments )
1484
1485 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1486 etc.).
1487
1488 =cut
1489
1490 sub prepare {
1491     my ( $class, @arguments ) = @_;
1492
1493     $class->context_class( ref $class || $class ) unless $class->context_class;
1494     my $c = $class->context_class->new(
1495         {
1496             counter => {},
1497             stack   => [],
1498             request => $class->request_class->new(
1499                 {
1500                     arguments        => [],
1501                     body_parameters  => {},
1502                     cookies          => {},
1503                     headers          => HTTP::Headers->new,
1504                     parameters       => {},
1505                     query_parameters => {},
1506                     secure           => 0,
1507                     captures         => [],
1508                     uploads          => {}
1509                 }
1510             ),
1511             response => $class->response_class->new(
1512                 {
1513                     body    => '',
1514                     cookies => {},
1515                     headers => HTTP::Headers->new(),
1516                     status  => 200
1517                 }
1518             ),
1519             stash => {},
1520             state => 0
1521         }
1522     );
1523
1524     if ( $c->debug ) {
1525         $c->stats(Tree::Simple->new([gettimeofday]));
1526         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1527     }
1528
1529     # For on-demand data
1530     $c->request->{_context}  = $c;
1531     $c->response->{_context} = $c;
1532     weaken( $c->request->{_context} );
1533     weaken( $c->response->{_context} );
1534
1535     # Allow engine to direct the prepare flow (for POE)
1536     if ( $c->engine->can('prepare') ) {
1537         $c->engine->prepare( $c, @arguments );
1538     }
1539     else {
1540         $c->prepare_request(@arguments);
1541         $c->prepare_connection;
1542         $c->prepare_query_parameters;
1543         $c->prepare_headers;
1544         $c->prepare_cookies;
1545         $c->prepare_path;
1546
1547         # On-demand parsing
1548         $c->prepare_body unless $c->config->{parse_on_demand};
1549     }
1550
1551     my $method  = $c->req->method  || '';
1552     my $path    = $c->req->path    || '/';
1553     my $address = $c->req->address || '';
1554
1555     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1556       if $c->debug;
1557
1558     $c->prepare_action;
1559
1560     return $c;
1561 }
1562
1563 =head2 $c->prepare_action
1564
1565 Prepares action. See L<Catalyst::Dispatcher>.
1566
1567 =cut
1568
1569 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1570
1571 =head2 $c->prepare_body
1572
1573 Prepares message body.
1574
1575 =cut
1576
1577 sub prepare_body {
1578     my $c = shift;
1579
1580     # Do we run for the first time?
1581     return if defined $c->request->{_body};
1582
1583     # Initialize on-demand data
1584     $c->engine->prepare_body( $c, @_ );
1585     $c->prepare_parameters;
1586     $c->prepare_uploads;
1587
1588     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1589         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1590         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1591             my $param = $c->req->body_parameters->{$key};
1592             my $value = defined($param) ? $param : '';
1593             $t->row( $key,
1594                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1595         }
1596         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1597     }
1598 }
1599
1600 =head2 $c->prepare_body_chunk( $chunk )
1601
1602 Prepares a chunk of data before sending it to L<HTTP::Body>.
1603
1604 See L<Catalyst::Engine>.
1605
1606 =cut
1607
1608 sub prepare_body_chunk {
1609     my $c = shift;
1610     $c->engine->prepare_body_chunk( $c, @_ );
1611 }
1612
1613 =head2 $c->prepare_body_parameters
1614
1615 Prepares body parameters.
1616
1617 =cut
1618
1619 sub prepare_body_parameters {
1620     my $c = shift;
1621     $c->engine->prepare_body_parameters( $c, @_ );
1622 }
1623
1624 =head2 $c->prepare_connection
1625
1626 Prepares connection.
1627
1628 =cut
1629
1630 sub prepare_connection {
1631     my $c = shift;
1632     $c->engine->prepare_connection( $c, @_ );
1633 }
1634
1635 =head2 $c->prepare_cookies
1636
1637 Prepares cookies.
1638
1639 =cut
1640
1641 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1642
1643 =head2 $c->prepare_headers
1644
1645 Prepares headers.
1646
1647 =cut
1648
1649 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1650
1651 =head2 $c->prepare_parameters
1652
1653 Prepares parameters.
1654
1655 =cut
1656
1657 sub prepare_parameters {
1658     my $c = shift;
1659     $c->prepare_body_parameters;
1660     $c->engine->prepare_parameters( $c, @_ );
1661 }
1662
1663 =head2 $c->prepare_path
1664
1665 Prepares path and base.
1666
1667 =cut
1668
1669 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1670
1671 =head2 $c->prepare_query_parameters
1672
1673 Prepares query parameters.
1674
1675 =cut
1676
1677 sub prepare_query_parameters {
1678     my $c = shift;
1679
1680     $c->engine->prepare_query_parameters( $c, @_ );
1681
1682     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1683         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1684         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1685             my $param = $c->req->query_parameters->{$key};
1686             my $value = defined($param) ? $param : '';
1687             $t->row( $key,
1688                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1689         }
1690         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1691     }
1692 }
1693
1694 =head2 $c->prepare_read
1695
1696 Prepares the input for reading.
1697
1698 =cut
1699
1700 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1701
1702 =head2 $c->prepare_request
1703
1704 Prepares the engine request.
1705
1706 =cut
1707
1708 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1709
1710 =head2 $c->prepare_uploads
1711
1712 Prepares uploads.
1713
1714 =cut
1715
1716 sub prepare_uploads {
1717     my $c = shift;
1718
1719     $c->engine->prepare_uploads( $c, @_ );
1720
1721     if ( $c->debug && keys %{ $c->request->uploads } ) {
1722         my $t = Text::SimpleTable->new(
1723             [ 12, 'Parameter' ],
1724             [ 26, 'Filename' ],
1725             [ 18, 'Type' ],
1726             [ 9,  'Size' ]
1727         );
1728         for my $key ( sort keys %{ $c->request->uploads } ) {
1729             my $upload = $c->request->uploads->{$key};
1730             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1731                 $t->row( $key, $u->filename, $u->type, $u->size );
1732             }
1733         }
1734         $c->log->debug( "File Uploads are:\n" . $t->draw );
1735     }
1736 }
1737
1738 =head2 $c->prepare_write
1739
1740 Prepares the output for writing.
1741
1742 =cut
1743
1744 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1745
1746 =head2 $c->request_class
1747
1748 Returns or sets the request class.
1749
1750 =head2 $c->response_class
1751
1752 Returns or sets the response class.
1753
1754 =head2 $c->read( [$maxlength] )
1755
1756 Reads a chunk of data from the request body. This method is designed to
1757 be used in a while loop, reading C<$maxlength> bytes on every call.
1758 C<$maxlength> defaults to the size of the request if not specified.
1759
1760 You have to set C<MyApp-E<gt>config-E<gt>{parse_on_demand}> to use this
1761 directly.
1762
1763 =cut
1764
1765 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1766
1767 =head2 $c->run
1768
1769 Starts the engine.
1770
1771 =cut
1772
1773 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1774
1775 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1776
1777 Sets an action in a given namespace.
1778
1779 =cut
1780
1781 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1782
1783 =head2 $c->setup_actions($component)
1784
1785 Sets up actions for a component.
1786
1787 =cut
1788
1789 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1790
1791 =head2 $c->setup_components
1792
1793 Sets up components. Specify a C<setup_components> config option to pass
1794 additional options directly to L<Module::Pluggable>. To add additional
1795 search paths, specify a key named C<search_extra> as an array
1796 reference. Items in the array beginning with C<::> will have the
1797 application class name prepended to them.
1798
1799 =cut
1800
1801 sub setup_components {
1802     my $class = shift;
1803
1804     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1805     my $config  = $class->config->{ setup_components };
1806     my $extra   = delete $config->{ search_extra } || [];
1807
1808     push @paths, @$extra;
1809
1810     my $locator = Module::Pluggable::Object->new(
1811         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1812         %$config
1813     );
1814
1815     for my $component ( sort { length $a <=> length $b } $locator->plugins ) {
1816         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1817
1818         my $module  = $class->setup_component( $component );
1819         my %modules = (
1820             $component => $module,
1821             map {
1822                 $_ => $class->setup_component( $_ )
1823             } Devel::InnerPackage::list_packages( $component )
1824         );
1825
1826         for my $key ( keys %modules ) {
1827             $class->components->{ $key } = $modules{ $key };
1828         }
1829     }
1830 }
1831
1832 =head2 $c->setup_component
1833
1834 =cut
1835
1836 sub setup_component {
1837     my( $class, $component ) = @_;
1838
1839     unless ( $component->can( 'COMPONENT' ) ) {
1840         return $component;
1841     }
1842
1843     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1844     my $config = $class->config->{ $suffix } || {};
1845
1846     my $instance = eval { $component->COMPONENT( $class, $config ); };
1847
1848     if ( my $error = $@ ) {
1849         chomp $error;
1850         Catalyst::Exception->throw(
1851             message => qq/Couldn't instantiate component "$component", "$error"/
1852         );
1853     }
1854
1855     Catalyst::Exception->throw(
1856         message =>
1857         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1858     ) unless eval { $instance->can( 'can' ) };
1859
1860     return $instance;
1861 }
1862
1863 =head2 $c->setup_dispatcher
1864
1865 Sets up dispatcher.
1866
1867 =cut
1868
1869 sub setup_dispatcher {
1870     my ( $class, $dispatcher ) = @_;
1871
1872     if ($dispatcher) {
1873         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1874     }
1875
1876     if ( $ENV{CATALYST_DISPATCHER} ) {
1877         $dispatcher = 'Catalyst::Dispatcher::' . $ENV{CATALYST_DISPATCHER};
1878     }
1879
1880     if ( $ENV{ uc($class) . '_DISPATCHER' } ) {
1881         $dispatcher =
1882           'Catalyst::Dispatcher::' . $ENV{ uc($class) . '_DISPATCHER' };
1883     }
1884
1885     unless ($dispatcher) {
1886         $dispatcher = $class->dispatcher_class;
1887     }
1888
1889     unless (Class::Inspector->loaded($dispatcher)) {
1890         require Class::Inspector->filename($dispatcher);
1891     }
1892
1893     # dispatcher instance
1894     $class->dispatcher( $dispatcher->new );
1895 }
1896
1897 =head2 $c->setup_engine
1898
1899 Sets up engine.
1900
1901 =cut
1902
1903 sub setup_engine {
1904     my ( $class, $engine ) = @_;
1905
1906     if ($engine) {
1907         $engine = 'Catalyst::Engine::' . $engine;
1908     }
1909
1910     if ( $ENV{CATALYST_ENGINE} ) {
1911         $engine = 'Catalyst::Engine::' . $ENV{CATALYST_ENGINE};
1912     }
1913
1914     if ( $ENV{ uc($class) . '_ENGINE' } ) {
1915         $engine = 'Catalyst::Engine::' . $ENV{ uc($class) . '_ENGINE' };
1916     }
1917
1918     if ( $ENV{MOD_PERL} ) {
1919
1920         # create the apache method
1921         {
1922             no strict 'refs';
1923             *{"$class\::apache"} = sub { shift->engine->apache };
1924         }
1925
1926         my ( $software, $version ) =
1927           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1928
1929         $version =~ s/_//g;
1930         $version =~ s/(\.[^.]+)\./$1/g;
1931
1932         if ( $software eq 'mod_perl' ) {
1933
1934             if ( !$engine ) {
1935
1936                 if ( $version >= 1.99922 ) {
1937                     $engine = 'Catalyst::Engine::Apache2::MP20';
1938                 }
1939
1940                 elsif ( $version >= 1.9901 ) {
1941                     $engine = 'Catalyst::Engine::Apache2::MP19';
1942                 }
1943
1944                 elsif ( $version >= 1.24 ) {
1945                     $engine = 'Catalyst::Engine::Apache::MP13';
1946                 }
1947
1948                 else {
1949                     Catalyst::Exception->throw( message =>
1950                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
1951                 }
1952
1953             }
1954
1955             # install the correct mod_perl handler
1956             if ( $version >= 1.9901 ) {
1957                 *handler = sub  : method {
1958                     shift->handle_request(@_);
1959                 };
1960             }
1961             else {
1962                 *handler = sub ($$) { shift->handle_request(@_) };
1963             }
1964
1965         }
1966
1967         elsif ( $software eq 'Zeus-Perl' ) {
1968             $engine = 'Catalyst::Engine::Zeus';
1969         }
1970
1971         else {
1972             Catalyst::Exception->throw(
1973                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
1974         }
1975     }
1976
1977     unless ($engine) {
1978         $engine = $class->engine_class;
1979     }
1980
1981     unless (Class::Inspector->loaded($engine)) {
1982         require Class::Inspector->filename($engine);
1983     }
1984
1985     # check for old engines that are no longer compatible
1986     my $old_engine;
1987     if ( $engine->isa('Catalyst::Engine::Apache')
1988         && !Catalyst::Engine::Apache->VERSION )
1989     {
1990         $old_engine = 1;
1991     }
1992
1993     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
1994         && Catalyst::Engine::Server->VERSION le '0.02' )
1995     {
1996         $old_engine = 1;
1997     }
1998
1999     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2000         && $engine->VERSION eq '0.01' )
2001     {
2002         $old_engine = 1;
2003     }
2004
2005     elsif ($engine->isa('Catalyst::Engine::Zeus')
2006         && $engine->VERSION eq '0.01' )
2007     {
2008         $old_engine = 1;
2009     }
2010
2011     if ($old_engine) {
2012         Catalyst::Exception->throw( message =>
2013               qq/Engine "$engine" is not supported by this version of Catalyst/
2014         );
2015     }
2016
2017     # engine instance
2018     $class->engine( $engine->new );
2019 }
2020
2021 =head2 $c->setup_home
2022
2023 Sets up the home directory.
2024
2025 =cut
2026
2027 sub setup_home {
2028     my ( $class, $home ) = @_;
2029
2030     if ( $ENV{CATALYST_HOME} ) {
2031         $home = $ENV{CATALYST_HOME};
2032     }
2033
2034     if ( $ENV{ uc($class) . '_HOME' } ) {
2035         $home = $ENV{ uc($class) . '_HOME' };
2036     }
2037
2038     unless ($home) {
2039         $home = Catalyst::Utils::home($class);
2040     }
2041
2042     if ($home) {
2043         $class->config->{home} ||= $home;
2044         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2045     }
2046 }
2047
2048 =head2 $c->setup_log
2049
2050 Sets up log.
2051
2052 =cut
2053
2054 sub setup_log {
2055     my ( $class, $debug ) = @_;
2056
2057     unless ( $class->log ) {
2058         $class->log( Catalyst::Log->new );
2059     }
2060
2061     my $app_flag = Catalyst::Utils::class2env($class) . '_DEBUG';
2062
2063     if (
2064           ( defined( $ENV{CATALYST_DEBUG} ) || defined( $ENV{$app_flag} ) )
2065         ? ( $ENV{CATALYST_DEBUG} || $ENV{$app_flag} )
2066         : $debug
2067       )
2068     {
2069         no strict 'refs';
2070         *{"$class\::debug"} = sub { 1 };
2071         $class->log->debug('Debug messages enabled');
2072     }
2073 }
2074
2075 =head2 $c->setup_plugins
2076
2077 Sets up plugins.
2078
2079 =cut
2080
2081 =head2 $c->registered_plugins
2082
2083 Returns a sorted list of the plugins which have either been stated in the
2084 import list or which have been added via C<< MyApp->plugin(@args); >>.
2085
2086 If passed a given plugin name, it will report a boolean value indicating
2087 whether or not that plugin is loaded.  A fully qualified name is required if
2088 the plugin name does not begin with C<Catalyst::Plugin::>.
2089
2090  if ($c->registered_plugins('Some::Plugin')) {
2091      ...
2092  }
2093
2094 =cut
2095
2096 {
2097
2098     sub registered_plugins {
2099         my $proto = shift;
2100         return sort keys %{ $proto->_plugins } unless @_;
2101         my $plugin = shift;
2102         return 1 if exists $proto->_plugins->{$plugin};
2103         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2104     }
2105
2106     sub _register_plugin {
2107         my ( $proto, $plugin, $instant ) = @_;
2108         my $class = ref $proto || $proto;
2109
2110         unless (Class::Inspector->loaded($plugin)) {
2111             require Class::Inspector->filename($plugin);
2112         }
2113
2114         $proto->_plugins->{$plugin} = 1;
2115         unless ($instant) {
2116             no strict 'refs';
2117             unshift @{"$class\::ISA"}, $plugin;
2118         }
2119         return $class;
2120     }
2121
2122     sub setup_plugins {
2123         my ( $class, $plugins ) = @_;
2124
2125         $class->_plugins( {} ) unless $class->_plugins;
2126         $plugins ||= [];
2127         for my $plugin ( reverse @$plugins ) {
2128
2129             unless ( $plugin =~ s/\A\+// ) {
2130                 $plugin = "Catalyst::Plugin::$plugin";
2131             }
2132
2133             $class->_register_plugin($plugin);
2134         }
2135     }
2136 }
2137
2138 =head2 $c->stack
2139
2140 Returns an arrayref of the internal execution stack (actions that are
2141 currently executing).
2142
2143 =head2 $c->write( $data )
2144
2145 Writes $data to the output stream. When using this method directly, you
2146 will need to manually set the C<Content-Length> header to the length of
2147 your output data, if known.
2148
2149 =cut
2150
2151 sub write {
2152     my $c = shift;
2153
2154     # Finalize headers if someone manually writes output
2155     $c->finalize_headers;
2156
2157     return $c->engine->write( $c, @_ );
2158 }
2159
2160 =head2 version
2161
2162 Returns the Catalyst version number. Mostly useful for "powered by"
2163 messages in template systems.
2164
2165 =cut
2166
2167 sub version { return $Catalyst::VERSION }
2168
2169 =head1 INTERNAL ACTIONS
2170
2171 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2172 C<_ACTION>, and C<_END>. These are by default not shown in the private
2173 action table, but you can make them visible with a config parameter.
2174
2175     MyApp->config->{show_internal_actions} = 1;
2176
2177 =head1 CASE SENSITIVITY
2178
2179 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2180 mapped to C</foo/bar>. You can activate case sensitivity with a config
2181 parameter.
2182
2183     MyApp->config->{case_sensitive} = 1;
2184
2185 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2186
2187 =head1 ON-DEMAND PARSER
2188
2189 The request body is usually parsed at the beginning of a request,
2190 but if you want to handle input yourself or speed things up a bit,
2191 you can enable on-demand parsing with a config parameter.
2192
2193     MyApp->config->{parse_on_demand} = 1;
2194
2195 =head1 PROXY SUPPORT
2196
2197 Many production servers operate using the common double-server approach,
2198 with a lightweight frontend web server passing requests to a larger
2199 backend server. An application running on the backend server must deal
2200 with two problems: the remote user always appears to be C<127.0.0.1> and
2201 the server's hostname will appear to be C<localhost> regardless of the
2202 virtual host that the user connected through.
2203
2204 Catalyst will automatically detect this situation when you are running
2205 the frontend and backend servers on the same machine. The following
2206 changes are made to the request.
2207
2208     $c->req->address is set to the user's real IP address, as read from
2209     the HTTP X-Forwarded-For header.
2210
2211     The host value for $c->req->base and $c->req->uri is set to the real
2212     host, as read from the HTTP X-Forwarded-Host header.
2213
2214 Obviously, your web server must support these headers for this to work.
2215
2216 In a more complex server farm environment where you may have your
2217 frontend proxy server(s) on different machines, you will need to set a
2218 configuration option to tell Catalyst to read the proxied data from the
2219 headers.
2220
2221     MyApp->config->{using_frontend_proxy} = 1;
2222
2223 If you do not wish to use the proxy support at all, you may set:
2224
2225     MyApp->config->{ignore_frontend_proxy} = 1;
2226
2227 =head1 THREAD SAFETY
2228
2229 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2230 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2231 believe the Catalyst core to be thread-safe.
2232
2233 If you plan to operate in a threaded environment, remember that all other
2234 modules you are using must also be thread-safe. Some modules, most notably
2235 L<DBD::SQLite>, are not thread-safe.
2236
2237 =head1 SUPPORT
2238
2239 IRC:
2240
2241     Join #catalyst on irc.perl.org.
2242
2243 Mailing Lists:
2244
2245     http://lists.rawmode.org/mailman/listinfo/catalyst
2246     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2247
2248 Web:
2249
2250     http://catalyst.perl.org
2251
2252 Wiki:
2253
2254     http://dev.catalyst.perl.org
2255
2256 =head1 SEE ALSO
2257
2258 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2259
2260 =head2 L<Catalyst::Manual> - The Catalyst Manual
2261
2262 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2263
2264 =head2 L<Catalyst::Engine> - Core engine
2265
2266 =head2 L<Catalyst::Log> - Log class.
2267
2268 =head2 L<Catalyst::Request> - Request object
2269
2270 =head2 L<Catalyst::Response> - Response object
2271
2272 =head2 L<Catalyst::Test> - The test suite.
2273
2274 =head1 CREDITS
2275
2276 Andy Grundman
2277
2278 Andy Wardley
2279
2280 Andreas Marienborg
2281
2282 Andrew Bramble
2283
2284 Andrew Ford
2285
2286 Andrew Ruthven
2287
2288 Arthur Bergman
2289
2290 Autrijus Tang
2291
2292 Brian Cassidy
2293
2294 Carl Franks
2295
2296 Christian Hansen
2297
2298 Christopher Hicks
2299
2300 Dan Sully
2301
2302 Danijel Milicevic
2303
2304 David Kamholz
2305
2306 David Naughton
2307
2308 Drew Taylor
2309
2310 Gary Ashton Jones
2311
2312 Geoff Richards
2313
2314 Jesse Sheidlower
2315
2316 Jesse Vincent
2317
2318 Jody Belka
2319
2320 Johan Lindstrom
2321
2322 Juan Camacho
2323
2324 Leon Brocard
2325
2326 Marcus Ramberg
2327
2328 Matt S Trout
2329
2330 Robert Sedlacek
2331
2332 Sam Vilain
2333
2334 Sascha Kiefer
2335
2336 Tatsuhiko Miyagawa
2337
2338 Ulf Edvinsson
2339
2340 Yuval Kogman
2341
2342 =head1 AUTHOR
2343
2344 Sebastian Riedel, C<sri@oook.de>
2345
2346 =head1 LICENSE
2347
2348 This library is free software, you can redistribute it and/or modify it under
2349 the same terms as Perl itself.
2350
2351 =cut
2352
2353 1;