lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::LighttpdScriptNameFix;
  40
  41 BEGIN { require 5.008004; }
  42
  43 has stack => (is => 'ro', default => sub { [] });
  44 has stash => (is => 'rw', default => sub { {} });
  45 has state => (is => 'rw', default => 0);
  46 has stats => (is => 'rw');
  47 has action => (is => 'rw');
  48 has counter => (is => 'rw', default => sub { {} });
  49 has request => (
  50     is => 'rw',
  51     default => sub {
  52         my $self = shift;
  53         my %p = ( _log => $self->log );
  54         $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  55         $self->request_class->new(\%p);
  56     },
  57     lazy => 1,
  58 );
  59 has response => (
  60     is => 'rw',
  61     default => sub {
  62         my $self = shift;
  63         $self->response_class->new({ _log => $self->log });
  64     },
  65     lazy => 1,
  66 );
  67 has namespace => (is => 'rw');
  68
  69 sub depth { scalar @{ shift->stack || [] }; }
  70 sub comp { shift->component(@_) }
  71
  72 sub req {
  73     my $self = shift; return $self->request(@_);
  74 }
  75 sub res {
  76     my $self = shift; return $self->response(@_);
  77 }
  78
  79 # For backwards compatibility
  80 sub finalize_output { shift->finalize_body(@_) };
  81
  82 # For statistics
  83 our $COUNT     = 1;
  84 our $START     = time;
  85 our $RECURSION = 1000;
  86 our $DETACH    = Catalyst::Exception::Detach->new;
  87 our $GO        = Catalyst::Exception::Go->new;
  88
  89 #I imagine that very few of these really need to be class variables. if any.
  90 #maybe we should just make them attributes with a default?
  91 __PACKAGE__->mk_classdata($_)
  92   for qw/components arguments dispatcher engine log dispatcher_class
  93   engine_loader context_class request_class response_class stats_class
  94   setup_finished _psgi_app loading_psgi_file run_options/;
  95
  96 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  97 __PACKAGE__->request_class('Catalyst::Request');
  98 __PACKAGE__->response_class('Catalyst::Response');
  99 __PACKAGE__->stats_class('Catalyst::Stats');
 100
 101 # Remember to update this in Catalyst::Runtime as well!
 102
 103 our $VERSION = '5.90008';
 104
 105 sub import {
 106     my ( $class, @arguments ) = @_;
 107
 108     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 109     # callers @ISA.
 110     return unless $class eq 'Catalyst';
 111
 112     my $caller = caller();
 113     return if $caller eq 'main';
 114
 115     my $meta = Moose::Meta::Class->initialize($caller);
 116     unless ( $caller->isa('Catalyst') ) {
 117         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 118         $meta->superclasses(@superclasses);
 119     }
 120     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 121     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 122
 123     unless( $meta->has_method('meta') ){
 124         if ($Moose::VERSION >= 1.15) {
 125             $meta->_add_meta_method('meta');
 126         }
 127         else {
 128             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 129         }
 130     }
 131
 132     $caller->arguments( [@arguments] );
 133     $caller->setup_home;
 134 }
 135
 136 sub _application { $_[0] }
 137
 138 =head1 NAME
 139
 140 Catalyst - The Elegant MVC Web Application Framework
 141
 142 =head1 SYNOPSIS
 143
 144 See the L<Catalyst::Manual> distribution for comprehensive
 145 documentation and tutorials.
 146
 147     # Install Catalyst::Devel for helpers and other development tools
 148     # use the helper to create a new application
 149     catalyst.pl MyApp
 150
 151     # add models, views, controllers
 152     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 153     script/myapp_create.pl view MyTemplate TT
 154     script/myapp_create.pl controller Search
 155
 156     # built in testserver -- use -r to restart automatically on changes
 157     # --help to see all available options
 158     script/myapp_server.pl
 159
 160     # command line testing interface
 161     script/myapp_test.pl /yada
 162
 163     ### in lib/MyApp.pm
 164     use Catalyst qw/-Debug/; # include plugins here as well
 165
 166     ### In lib/MyApp/Controller/Root.pm (autocreated)
 167     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 168         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 169         $c->stash->{template} = 'foo.tt'; # set the template
 170         # lookup something from db -- stash vars are passed to TT
 171         $c->stash->{data} =
 172           $c->model('Database::Foo')->search( { country => $args[0] } );
 173         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 174             $c->forward( 'bar' ); # process another action
 175             # do something else after forward returns
 176         }
 177     }
 178
 179     # The foo.tt TT template can use the stash data from the database
 180     [% WHILE (item = data.next) %]
 181         [% item.foo %]
 182     [% END %]
 183
 184     # called for /bar/of/soap, /bar/of/soap/10, etc.
 185     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 186
 187     # called after all actions are finished
 188     sub end : Action {
 189         my ( $self, $c ) = @_;
 190         if ( scalar @{ $c->error } ) { ... } # handle errors
 191         return if $c->res->body; # already have a response
 192         $c->forward( 'MyApp::View::TT' ); # render template
 193     }
 194
 195 See L<Catalyst::Manual::Intro> for additional information.
 196
 197 =head1 DESCRIPTION
 198
 199 Catalyst is a modern framework for making web applications without the
 200 pain usually associated with this process. This document is a reference
 201 to the main Catalyst application. If you are a new user, we suggest you
 202 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 203
 204 See L<Catalyst::Manual> for more documentation.
 205
 206 Catalyst plugins can be loaded by naming them as arguments to the "use
 207 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 208 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 209 C<My::Module>.
 210
 211     use Catalyst qw/My::Module/;
 212
 213 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 214 fully qualify the name by using a unary plus:
 215
 216     use Catalyst qw/
 217         My::Module
 218         +Fully::Qualified::Plugin::Name
 219     /;
 220
 221 Special flags like C<-Debug> can also be specified as
 222 arguments when Catalyst is loaded:
 223
 224     use Catalyst qw/-Debug My::Module/;
 225
 226 The position of plugins and flags in the chain is important, because
 227 they are loaded in the order in which they appear.
 228
 229 The following flags are supported:
 230
 231 =head2 -Debug
 232
 233 Enables debug output. You can also force this setting from the system
 234 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 235 settings override the application, with <MYAPP>_DEBUG having the highest
 236 priority.
 237
 238 This sets the log level to 'debug' and enables full debug output on the
 239 error screen. If you only want the latter, see L<< $c->debug >>.
 240
 241 =head2 -Home
 242
 243 Forces Catalyst to use a specific home directory, e.g.:
 244
 245     use Catalyst qw[-Home=/usr/mst];
 246
 247 This can also be done in the shell environment by setting either the
 248 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 249 is replaced with the uppercased name of your application, any "::" in
 250 the name will be replaced with underscores, e.g. MyApp::Web should use
 251 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 252
 253 If none of these are set, Catalyst will attempt to automatically detect the
 254 home directory. If you are working in a development environment, Catalyst
 255 will try and find the directory containing either Makefile.PL, Build.PL or
 256 dist.ini. If the application has been installed into the system (i.e.
 257 you have done C<make install>), then Catalyst will use the path to your
 258 application module, without the .pm extension (e.g., /foo/MyApp if your
 259 application was installed at /foo/MyApp.pm)
 260
 261 =head2 -Log
 262
 263     use Catalyst '-Log=warn,fatal,error';
 264
 265 Specifies a comma-delimited list of log levels.
 266
 267 =head2 -Stats
 268
 269 Enables statistics collection and reporting.
 270
 271    use Catalyst qw/-Stats=1/;
 272
 273 You can also force this setting from the system environment with CATALYST_STATS
 274 or <MYAPP>_STATS. The environment settings override the application, with
 275 <MYAPP>_STATS having the highest priority.
 276
 277 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 278
 279 =head1 METHODS
 280
 281 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 282
 283 =head2 $c->action
 284
 285 Returns a L<Catalyst::Action> object for the current action, which
 286 stringifies to the action name. See L<Catalyst::Action>.
 287
 288 =head2 $c->namespace
 289
 290 Returns the namespace of the current action, i.e., the URI prefix
 291 corresponding to the controller of the current action. For example:
 292
 293     # in Controller::Foo::Bar
 294     $c->namespace; # returns 'foo/bar';
 295
 296 =head2 $c->request
 297
 298 =head2 $c->req
 299
 300 Returns the current L<Catalyst::Request> object, giving access to
 301 information about the current client request (including parameters,
 302 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 303
 304 =head2 REQUEST FLOW HANDLING
 305
 306 =head2 $c->forward( $action [, \@arguments ] )
 307
 308 =head2 $c->forward( $class, $method, [, \@arguments ] )
 309
 310 Forwards processing to another action, by its private name. If you give a
 311 class name but no method, C<process()> is called. You may also optionally
 312 pass arguments in an arrayref. The action will receive the arguments in
 313 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 314 C<< $c->req->args >> will be restored to the previous values.
 315
 316 Any data C<return>ed from the action forwarded to, will be returned by the
 317 call to forward.
 318
 319     my $foodata = $c->forward('/foo');
 320     $c->forward('index');
 321     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 322     $c->forward('View::TT');
 323
 324 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 325 an C<< eval { } >> around the call (actually
 326 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 327 exceptions thrown by the called action non-fatal and pushing them onto
 328 $c->error instead. If you want C<die> to propagate you need to do something
 329 like:
 330
 331     $c->forward('foo');
 332     die join "\n", @{ $c->error } if @{ $c->error };
 333
 334 Or make sure to always return true values from your actions and write
 335 your code like this:
 336
 337     $c->forward('foo') || return;
 338
 339 Another note is that C<< $c->forward >> always returns a scalar because it
 340 actually returns $c->state which operates in a scalar context.
 341 Thus, something like:
 342
 343     return @array;
 344
 345 in an action that is forwarded to is going to return a scalar,
 346 i.e. how many items are in that array, which is probably not what you want.
 347 If you need to return an array then return a reference to it,
 348 or stash it like so:
 349
 350     $c->stash->{array} = \@array;
 351
 352 and access it from the stash.
 353
 354 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 355
 356 =cut
 357
 358 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 359
 360 =head2 $c->detach( $action [, \@arguments ] )
 361
 362 =head2 $c->detach( $class, $method, [, \@arguments ] )
 363
 364 =head2 $c->detach()
 365
 366 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 367 doesn't return to the previous action when processing is finished.
 368
 369 When called with no arguments it escapes the processing chain entirely.
 370
 371 =cut
 372
 373 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 374
 375 =head2 $c->visit( $action [, \@arguments ] )
 376
 377 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 378
 379 =head2 $c->visit( $class, $method, [, \@arguments ] )
 380
 381 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 382
 383 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 384 but does a full dispatch, instead of just calling the new C<$action> /
 385 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 386 you go to are called, just like a new request.
 387
 388 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 389 This means, for example, that C<< $c->action >> methods such as
 390 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 391 L<reverse|Catalyst::Action/reverse> return information for the visited action
 392 when they are invoked within the visited action.  This is different from the
 393 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 394 continues to use the $c->action object from the caller action even when
 395 invoked from the called action.
 396
 397 C<< $c->stash >> is kept unchanged.
 398
 399 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 400 allows you to "wrap" another action, just as it would have been called by
 401 dispatching from a URL, while the analogous
 402 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 403 transfer control to another action as if it had been reached directly from a URL.
 404
 405 =cut
 406
 407 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 408
 409 =head2 $c->go( $action [, \@arguments ] )
 410
 411 =head2 $c->go( $action [, \@captures, \@arguments ] )
 412
 413 =head2 $c->go( $class, $method, [, \@arguments ] )
 414
 415 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 416
 417 The relationship between C<go> and
 418 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 419 the relationship between
 420 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 421 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 422 C<< $c->go >> will perform a full dispatch on the specified action or method,
 423 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 424 C<go> escapes the processing of the current request chain on completion, and
 425 does not return to its caller.
 426
 427 @arguments are arguments to the final destination of $action. @captures are
 428 arguments to the intermediate steps, if any, on the way to the final sub of
 429 $action.
 430
 431 =cut
 432
 433 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 434
 435 =head2 $c->response
 436
 437 =head2 $c->res
 438
 439 Returns the current L<Catalyst::Response> object, see there for details.
 440
 441 =head2 $c->stash
 442
 443 Returns a hashref to the stash, which may be used to store data and pass
 444 it between components during a request. You can also set hash keys by
 445 passing arguments. The stash is automatically sent to the view. The
 446 stash is cleared at the end of a request; it cannot be used for
 447 persistent storage (for this you must use a session; see
 448 L<Catalyst::Plugin::Session> for a complete system integrated with
 449 Catalyst).
 450
 451     $c->stash->{foo} = $bar;
 452     $c->stash( { moose => 'majestic', qux => 0 } );
 453     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 454
 455     # stash is automatically passed to the view for use in a template
 456     $c->forward( 'MyApp::View::TT' );
 457
 458 =cut
 459
 460 around stash => sub {
 461     my $orig = shift;
 462     my $c = shift;
 463     my $stash = $orig->($c);
 464     if (@_) {
 465         my $new_stash = @_ > 1 ? {@_} : $_[0];
 466         croak('stash takes a hash or hashref') unless ref $new_stash;
 467         foreach my $key ( keys %$new_stash ) {
 468           $stash->{$key} = $new_stash->{$key};
 469         }
 470     }
 471
 472     return $stash;
 473 };
 474
 475
 476 =head2 $c->error
 477
 478 =head2 $c->error($error, ...)
 479
 480 =head2 $c->error($arrayref)
 481
 482 Returns an arrayref containing error messages.  If Catalyst encounters an
 483 error while processing a request, it stores the error in $c->error.  This
 484 method should only be used to store fatal error messages.
 485
 486     my @error = @{ $c->error };
 487
 488 Add a new error.
 489
 490     $c->error('Something bad happened');
 491
 492 =cut
 493
 494 sub error {
 495     my $c = shift;
 496     if ( $_[0] ) {
 497         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 498         croak @$error unless ref $c;
 499         push @{ $c->{error} }, @$error;
 500     }
 501     elsif ( defined $_[0] ) { $c->{error} = undef }
 502     return $c->{error} || [];
 503 }
 504
 505
 506 =head2 $c->state
 507
 508 Contains the return value of the last executed action.
 509 Note that << $c->state >> operates in a scalar context which means that all
 510 values it returns are scalar.
 511
 512 =head2 $c->clear_errors
 513
 514 Clear errors.  You probably don't want to clear the errors unless you are
 515 implementing a custom error screen.
 516
 517 This is equivalent to running
 518
 519     $c->error(0);
 520
 521 =cut
 522
 523 sub clear_errors {
 524     my $c = shift;
 525     $c->error(0);
 526 }
 527
 528 sub _comp_search_prefixes {
 529     my $c = shift;
 530     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 531 }
 532
 533 # search components given a name and some prefixes
 534 sub _comp_names_search_prefixes {
 535     my ( $c, $name, @prefixes ) = @_;
 536     my $appclass = ref $c || $c;
 537     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 538     $filter = qr/$filter/; # Compile regex now rather than once per loop
 539
 540     # map the original component name to the sub part that we will search against
 541     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 542         grep { /$filter/ } keys %{ $c->components };
 543
 544     # undef for a name will return all
 545     return keys %eligible if !defined $name;
 546
 547     my $query  = ref $name ? $name : qr/^$name$/i;
 548     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 549
 550     return @result if @result;
 551
 552     # if we were given a regexp to search against, we're done.
 553     return if ref $name;
 554
 555     # skip regexp fallback if configured
 556     return
 557         if $appclass->config->{disable_component_resolution_regex_fallback};
 558
 559     # regexp fallback
 560     $query  = qr/$name/i;
 561     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 562
 563     # no results? try against full names
 564     if( !@result ) {
 565         @result = grep { m{$query} } keys %eligible;
 566     }
 567
 568     # don't warn if we didn't find any results, it just might not exist
 569     if( @result ) {
 570         # Disgusting hack to work out correct method name
 571         my $warn_for = lc $prefixes[0];
 572         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 573            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 574            "component resolution is unreliable and unsafe.";
 575         my $short = $result[0];
 576         # remove the component namespace prefix
 577         $short =~ s/.*?(Model|Controller|View):://;
 578         my $shortmess = Carp::shortmess('');
 579         if ($shortmess =~ m#Catalyst/Plugin#) {
 580            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 581               "plugin's config";
 582         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 583            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 584               "component's config";
 585         } else {
 586            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 587               "but if you really wanted to search, pass in a regexp as the argument " .
 588               "like so: \$c->${warn_for}(qr/${name}/)";
 589         }
 590         $c->log->warn( "${msg}$shortmess" );
 591     }
 592
 593     return @result;
 594 }
 595
 596 # Find possible names for a prefix
 597 sub _comp_names {
 598     my ( $c, @prefixes ) = @_;
 599     my $appclass = ref $c || $c;
 600
 601     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 602
 603     my @names = map { s{$filter}{}; $_; }
 604         $c->_comp_names_search_prefixes( undef, @prefixes );
 605
 606     return @names;
 607 }
 608
 609 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 610 sub _filter_component {
 611     my ( $c, $comp, @args ) = @_;
 612
 613     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 614         return $comp->ACCEPT_CONTEXT( $c, @args );
 615     }
 616
 617     return $comp;
 618 }
 619
 620 =head2 COMPONENT ACCESSORS
 621
 622 =head2 $c->controller($name)
 623
 624 Gets a L<Catalyst::Controller> instance by name.
 625
 626     $c->controller('Foo')->do_stuff;
 627
 628 If the name is omitted, will return the controller for the dispatched
 629 action.
 630
 631 If you want to search for controllers, pass in a regexp as the argument.
 632
 633     # find all controllers that start with Foo
 634     my @foo_controllers = $c->controller(qr{^Foo});
 635
 636
 637 =cut
 638
 639 sub controller {
 640     my ( $c, $name, @args ) = @_;
 641
 642     my $appclass = ref($c) || $c;
 643     if( $name ) {
 644         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 645             my $comps = $c->components;
 646             my $check = $appclass."::Controller::".$name;
 647             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 648         }
 649         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 650         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 651         return $c->_filter_component( $result[ 0 ], @args );
 652     }
 653
 654     return $c->component( $c->action->class );
 655 }
 656
 657 =head2 $c->model($name)
 658
 659 Gets a L<Catalyst::Model> instance by name.
 660
 661     $c->model('Foo')->do_stuff;
 662
 663 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 664
 665 If the name is omitted, it will look for
 666  - a model object in $c->stash->{current_model_instance}, then
 667  - a model name in $c->stash->{current_model}, then
 668  - a config setting 'default_model', or
 669  - check if there is only one model, and return it if that's the case.
 670
 671 If you want to search for models, pass in a regexp as the argument.
 672
 673     # find all models that start with Foo
 674     my @foo_models = $c->model(qr{^Foo});
 675
 676 =cut
 677
 678 sub model {
 679     my ( $c, $name, @args ) = @_;
 680     my $appclass = ref($c) || $c;
 681     if( $name ) {
 682         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 683             my $comps = $c->components;
 684             my $check = $appclass."::Model::".$name;
 685             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 686         }
 687         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 688         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 689         return $c->_filter_component( $result[ 0 ], @args );
 690     }
 691
 692     if (ref $c) {
 693         return $c->stash->{current_model_instance}
 694           if $c->stash->{current_model_instance};
 695         return $c->model( $c->stash->{current_model} )
 696           if $c->stash->{current_model};
 697     }
 698     return $c->model( $appclass->config->{default_model} )
 699       if $appclass->config->{default_model};
 700
 701     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 702
 703     if( $rest ) {
 704         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 705         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 706         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 707         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 708         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 709     }
 710
 711     return $c->_filter_component( $comp );
 712 }
 713
 714
 715 =head2 $c->view($name)
 716
 717 Gets a L<Catalyst::View> instance by name.
 718
 719     $c->view('Foo')->do_stuff;
 720
 721 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 722
 723 If the name is omitted, it will look for
 724  - a view object in $c->stash->{current_view_instance}, then
 725  - a view name in $c->stash->{current_view}, then
 726  - a config setting 'default_view', or
 727  - check if there is only one view, and return it if that's the case.
 728
 729 If you want to search for views, pass in a regexp as the argument.
 730
 731     # find all views that start with Foo
 732     my @foo_views = $c->view(qr{^Foo});
 733
 734 =cut
 735
 736 sub view {
 737     my ( $c, $name, @args ) = @_;
 738
 739     my $appclass = ref($c) || $c;
 740     if( $name ) {
 741         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 742             my $comps = $c->components;
 743             my $check = $appclass."::View::".$name;
 744             if( exists $comps->{$check} ) {
 745                 return $c->_filter_component( $comps->{$check}, @args );
 746             }
 747             else {
 748                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 749             }
 750         }
 751         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 752         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 753         return $c->_filter_component( $result[ 0 ], @args );
 754     }
 755
 756     if (ref $c) {
 757         return $c->stash->{current_view_instance}
 758           if $c->stash->{current_view_instance};
 759         return $c->view( $c->stash->{current_view} )
 760           if $c->stash->{current_view};
 761     }
 762     return $c->view( $appclass->config->{default_view} )
 763       if $appclass->config->{default_view};
 764
 765     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 766
 767     if( $rest ) {
 768         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 769         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 770         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 771         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 772         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 773     }
 774
 775     return $c->_filter_component( $comp );
 776 }
 777
 778 =head2 $c->controllers
 779
 780 Returns the available names which can be passed to $c->controller
 781
 782 =cut
 783
 784 sub controllers {
 785     my ( $c ) = @_;
 786     return $c->_comp_names(qw/Controller C/);
 787 }
 788
 789 =head2 $c->models
 790
 791 Returns the available names which can be passed to $c->model
 792
 793 =cut
 794
 795 sub models {
 796     my ( $c ) = @_;
 797     return $c->_comp_names(qw/Model M/);
 798 }
 799
 800
 801 =head2 $c->views
 802
 803 Returns the available names which can be passed to $c->view
 804
 805 =cut
 806
 807 sub views {
 808     my ( $c ) = @_;
 809     return $c->_comp_names(qw/View V/);
 810 }
 811
 812 =head2 $c->comp($name)
 813
 814 =head2 $c->component($name)
 815
 816 Gets a component object by name. This method is not recommended,
 817 unless you want to get a specific component by full
 818 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 819 should be used instead.
 820
 821 If C<$name> is a regexp, a list of components matched against the full
 822 component name will be returned.
 823
 824 If Catalyst can't find a component by name, it will fallback to regex
 825 matching by default. To disable this behaviour set
 826 disable_component_resolution_regex_fallback to a true value.
 827
 828     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 829
 830 =cut
 831
 832 sub component {
 833     my ( $c, $name, @args ) = @_;
 834
 835     if( $name ) {
 836         my $comps = $c->components;
 837
 838         if( !ref $name ) {
 839             # is it the exact name?
 840             return $c->_filter_component( $comps->{ $name }, @args )
 841                        if exists $comps->{ $name };
 842
 843             # perhaps we just omitted "MyApp"?
 844             my $composed = ( ref $c || $c ) . "::${name}";
 845             return $c->_filter_component( $comps->{ $composed }, @args )
 846                        if exists $comps->{ $composed };
 847
 848             # search all of the models, views and controllers
 849             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 850             return $c->_filter_component( $comp, @args ) if $comp;
 851         }
 852
 853         return
 854             if $c->config->{disable_component_resolution_regex_fallback};
 855
 856         # This is here so $c->comp( '::M::' ) works
 857         my $query = ref $name ? $name : qr{$name}i;
 858
 859         my @result = grep { m{$query} } keys %{ $c->components };
 860         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 861
 862         if( $result[ 0 ] ) {
 863             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 864             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 865             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 866             return $c->_filter_component( $result[ 0 ], @args );
 867         }
 868
 869         # I would expect to return an empty list here, but that breaks back-compat
 870     }
 871
 872     # fallback
 873     return sort keys %{ $c->components };
 874 }
 875
 876 =head2 CLASS DATA AND HELPER CLASSES
 877
 878 =head2 $c->config
 879
 880 Returns or takes a hashref containing the application's configuration.
 881
 882     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 883
 884 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 885 like C<myapp.conf> in your applications home directory. See
 886 L<Catalyst::Plugin::ConfigLoader>.
 887
 888 =head3 Cascading configuration
 889
 890 The config method is present on all Catalyst components, and configuration
 891 will be merged when an application is started. Configuration loaded with
 892 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 893 followed by configuration in your top level C<MyApp> class. These two
 894 configurations are merged, and then configuration data whose hash key matches a
 895 component name is merged with configuration for that component.
 896
 897 The configuration for a component is then passed to the C<new> method when a
 898 component is constructed.
 899
 900 For example:
 901
 902     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 903     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 904
 905 will mean that C<MyApp::Model::Foo> receives the following data when
 906 constructed:
 907
 908     MyApp::Model::Foo->new({
 909         bar => 'baz',
 910         quux => 'frob',
 911         overrides => 'me',
 912     });
 913
 914 It's common practice to use a Moose attribute
 915 on the receiving component to access the config value.
 916
 917     package MyApp::Model::Foo;
 918
 919     use Moose;
 920
 921     # this attr will receive 'baz' at construction time
 922     has 'bar' => (
 923         is  => 'rw',
 924         isa => 'Str',
 925     );
 926
 927 You can then get the value 'baz' by calling $c->model('Foo')->bar
 928 (or $self->bar inside code in the model).
 929
 930 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 931 as a way of reading config within your code, as this B<will not> give you the
 932 correctly merged config back. You B<MUST> take the config values supplied to
 933 the constructor and use those instead.
 934
 935 =cut
 936
 937 around config => sub {
 938     my $orig = shift;
 939     my $c = shift;
 940
 941     croak('Setting config after setup has been run is not allowed.')
 942         if ( @_ and $c->setup_finished );
 943
 944     $c->$orig(@_);
 945 };
 946
 947 =head2 $c->log
 948
 949 Returns the logging object instance. Unless it is already set, Catalyst
 950 sets this up with a L<Catalyst::Log> object. To use your own log class,
 951 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 952 C<< __PACKAGE__->setup >>.
 953
 954  __PACKAGE__->log( MyLogger->new );
 955  __PACKAGE__->setup;
 956
 957 And later:
 958
 959     $c->log->info( 'Now logging with my own logger!' );
 960
 961 Your log class should implement the methods described in
 962 L<Catalyst::Log>.
 963
 964
 965 =head2 $c->debug
 966
 967 Returns 1 if debug mode is enabled, 0 otherwise.
 968
 969 You can enable debug mode in several ways:
 970
 971 =over
 972
 973 =item By calling myapp_server.pl with the -d flag
 974
 975 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 976
 977 =item The -Debug option in your MyApp.pm
 978
 979 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 980
 981 =back
 982
 983 The first three also set the log level to 'debug'.
 984
 985 Calling C<< $c->debug(1) >> has no effect.
 986
 987 =cut
 988
 989 sub debug { 0 }
 990
 991 =head2 $c->dispatcher
 992
 993 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 994
 995 =head2 $c->engine
 996
 997 Returns the engine instance. See L<Catalyst::Engine>.
 998
 999
1000 =head2 UTILITY METHODS
1001
1002 =head2 $c->path_to(@path)
1003
1004 Merges C<@path> with C<< $c->config->{home} >> and returns a
1005 L<Path::Class::Dir> object. Note you can usually use this object as
1006 a filename, but sometimes you will have to explicitly stringify it
1007 yourself by calling the C<< ->stringify >> method.
1008
1009 For example:
1010
1011     $c->path_to( 'db', 'sqlite.db' );
1012
1013 =cut
1014
1015 sub path_to {
1016     my ( $c, @path ) = @_;
1017     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1018     if ( -d $path ) { return $path }
1019     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1020 }
1021
1022 sub plugin {
1023     my ( $class, $name, $plugin, @args ) = @_;
1024
1025     # See block comment in t/unit_core_plugin.t
1026     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1027
1028     $class->_register_plugin( $plugin, 1 );
1029
1030     eval { $plugin->import };
1031     $class->mk_classdata($name);
1032     my $obj;
1033     eval { $obj = $plugin->new(@args) };
1034
1035     if ($@) {
1036         Catalyst::Exception->throw( message =>
1037               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1038     }
1039
1040     $class->$name($obj);
1041     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1042       if $class->debug;
1043 }
1044
1045 =head2 MyApp->setup
1046
1047 Initializes the dispatcher and engine, loads any plugins, and loads the
1048 model, view, and controller components. You may also specify an array
1049 of plugins to load here, if you choose to not load them in the C<use
1050 Catalyst> line.
1051
1052     MyApp->setup;
1053     MyApp->setup( qw/-Debug/ );
1054
1055 B<Note:> You B<should not> wrap this method with method modifiers
1056 or bad things will happen - wrap the C<setup_finalize> method instead.
1057
1058 =cut
1059
1060 sub setup {
1061     my ( $class, @arguments ) = @_;
1062     croak('Running setup more than once')
1063         if ( $class->setup_finished );
1064
1065     unless ( $class->isa('Catalyst') ) {
1066
1067         Catalyst::Exception->throw(
1068             message => qq/'$class' does not inherit from Catalyst/ );
1069     }
1070
1071     if ( $class->arguments ) {
1072         @arguments = ( @arguments, @{ $class->arguments } );
1073     }
1074
1075     # Process options
1076     my $flags = {};
1077
1078     foreach (@arguments) {
1079
1080         if (/^-Debug$/) {
1081             $flags->{log} =
1082               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1083         }
1084         elsif (/^-(\w+)=?(.*)$/) {
1085             $flags->{ lc $1 } = $2;
1086         }
1087         else {
1088             push @{ $flags->{plugins} }, $_;
1089         }
1090     }
1091
1092     $class->setup_home( delete $flags->{home} );
1093
1094     $class->setup_log( delete $flags->{log} );
1095     $class->setup_plugins( delete $flags->{plugins} );
1096     $class->setup_dispatcher( delete $flags->{dispatcher} );
1097     if (my $engine = delete $flags->{engine}) {
1098         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1099     }
1100     $class->setup_engine();
1101     $class->setup_stats( delete $flags->{stats} );
1102
1103     for my $flag ( sort keys %{$flags} ) {
1104
1105         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1106             &$code( $class, delete $flags->{$flag} );
1107         }
1108         else {
1109             $class->log->warn(qq/Unknown flag "$flag"/);
1110         }
1111     }
1112
1113     eval { require Catalyst::Devel; };
1114     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1115         $class->log->warn(<<"EOF");
1116 You are running an old script!
1117
1118   Please update by running (this will overwrite existing files):
1119     catalyst.pl -force -scripts $class
1120
1121   or (this will not overwrite existing files):
1122     catalyst.pl -scripts $class
1123
1124 EOF
1125     }
1126
1127     if ( $class->debug ) {
1128         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1129
1130         if (@plugins) {
1131             my $column_width = Catalyst::Utils::term_width() - 6;
1132             my $t = Text::SimpleTable->new($column_width);
1133             $t->row($_) for @plugins;
1134             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1135         }
1136
1137         my $dispatcher = $class->dispatcher;
1138         my $engine     = $class->engine;
1139         my $home       = $class->config->{home};
1140
1141         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1142         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1143
1144         $home
1145           ? ( -d $home )
1146           ? $class->log->debug(qq/Found home "$home"/)
1147           : $class->log->debug(qq/Home "$home" doesn't exist/)
1148           : $class->log->debug(q/Couldn't find home/);
1149     }
1150
1151     # Call plugins setup, this is stupid and evil.
1152     # Also screws C3 badly on 5.10, hack to avoid.
1153     {
1154         no warnings qw/redefine/;
1155         local *setup = sub { };
1156         $class->setup unless $Catalyst::__AM_RESTARTING;
1157     }
1158
1159     # Initialize our data structure
1160     $class->components( {} );
1161
1162     $class->setup_components;
1163
1164     if ( $class->debug ) {
1165         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1166         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1167         for my $comp ( sort keys %{ $class->components } ) {
1168             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1169             $t->row( $comp, $type );
1170         }
1171         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1172           if ( keys %{ $class->components } );
1173     }
1174
1175     # Add our self to components, since we are also a component
1176     if( $class->isa('Catalyst::Controller') ){
1177       $class->components->{$class} = $class;
1178     }
1179
1180     $class->setup_actions;
1181
1182     if ( $class->debug ) {
1183         my $name = $class->config->{name} || 'Application';
1184         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1185     }
1186
1187     # Make sure that the application class becomes immutable at this point,
1188     B::Hooks::EndOfScope::on_scope_end {
1189         return if $@;
1190         my $meta = Class::MOP::get_metaclass_by_name($class);
1191         if (
1192             $meta->is_immutable
1193             && ! { $meta->immutable_options }->{replace_constructor}
1194             && (
1195                    $class->isa('Class::Accessor::Fast')
1196                 || $class->isa('Class::Accessor')
1197             )
1198         ) {
1199             warn "You made your application class ($class) immutable, "
1200                 . "but did not inline the\nconstructor. "
1201                 . "This will break catalyst, as your app \@ISA "
1202                 . "Class::Accessor(::Fast)?\nPlease pass "
1203                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1204         }
1205         $meta->make_immutable(
1206             replace_constructor => 1,
1207         ) unless $meta->is_immutable;
1208     };
1209
1210     if ($class->config->{case_sensitive}) {
1211         $class->log->warn($class . "->config->{case_sensitive} is set.");
1212         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1213     }
1214
1215     $class->setup_finalize;
1216     # Should be the last thing we do so that user things hooking
1217     # setup_finalize can log..
1218     $class->log->_flush() if $class->log->can('_flush');
1219     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1220 }
1221
1222 =head2 $app->setup_finalize
1223
1224 A hook to attach modifiers to. This method does not do anything except set the
1225 C<setup_finished> accessor.
1226
1227 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1228
1229 Example:
1230
1231     after setup_finalize => sub {
1232         my $app = shift;
1233
1234         ## do stuff here..
1235     };
1236
1237 =cut
1238
1239 sub setup_finalize {
1240     my ($class) = @_;
1241     $class->setup_finished(1);
1242 }
1243
1244 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1245
1246 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1247
1248 Constructs an absolute L<URI> object based on the application root, the
1249 provided path, and the additional arguments and query parameters provided.
1250 When used as a string, provides a textual URI.  If you need more flexibility
1251 than this (i.e. the option to provide relative URIs etc.) see
1252 L<Catalyst::Plugin::SmartURI>.
1253
1254 If no arguments are provided, the URI for the current action is returned.
1255 To return the current action and also provide @args, use
1256 C<< $c->uri_for( $c->action, @args ) >>.
1257
1258 If the first argument is a string, it is taken as a public URI path relative
1259 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1260 relative to the application root (if it does). It is then merged with
1261 C<< $c->request->base >>; any C<@args> are appended as additional path
1262 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1263
1264 If the first argument is a L<Catalyst::Action> it represents an action which
1265 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1266 optional C<\@captures> argument (an arrayref) allows passing the captured
1267 variables that are needed to fill in the paths of Chained and Regex actions;
1268 once the path is resolved, C<uri_for> continues as though a path was
1269 provided, appending any arguments or parameters and creating an absolute
1270 URI.
1271
1272 The captures for the current request can be found in
1273 C<< $c->request->captures >>, and actions can be resolved using
1274 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1275 path, use C<< $c->uri_for_action >> instead.
1276
1277   # Equivalent to $c->req->uri
1278   $c->uri_for($c->action, $c->req->captures,
1279       @{ $c->req->args }, $c->req->params);
1280
1281   # For the Foo action in the Bar controller
1282   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1283
1284   # Path to a static resource
1285   $c->uri_for('/static/images/logo.png');
1286
1287 =cut
1288
1289 sub uri_for {
1290     my ( $c, $path, @args ) = @_;
1291
1292     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1293         $path = $path->path_prefix;
1294         $path =~ s{/+\z}{};
1295         $path .= '/';
1296     }
1297
1298     undef($path) if (defined $path && $path eq '');
1299
1300     my $params =
1301       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1302
1303     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1304     foreach my $arg (@args) {
1305         utf8::encode($arg) if utf8::is_utf8($arg);
1306         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1307     }
1308
1309     if ( blessed($path) ) { # action object
1310         s|/|%2F|g for @args;
1311         my $captures = [ map { s|/|%2F|g; $_; }
1312                         ( scalar @args && ref $args[0] eq 'ARRAY'
1313                          ? @{ shift(@args) }
1314                          : ()) ];
1315
1316         foreach my $capture (@$captures) {
1317             utf8::encode($capture) if utf8::is_utf8($capture);
1318             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1319         }
1320
1321         my $action = $path;
1322         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1323         if( !@args && $action->number_of_args ) {
1324             my $expanded_action = $c->dispatcher->expand_action( $action );
1325
1326             my $num_captures = $expanded_action->number_of_captures;
1327             unshift @args, splice @$captures, $num_captures;
1328         }
1329
1330        $path = $c->dispatcher->uri_for_action($action, $captures);
1331         if (not defined $path) {
1332             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1333                 if $c->debug;
1334             return undef;
1335         }
1336         $path = '/' if $path eq '';
1337     }
1338
1339     unshift(@args, $path);
1340
1341     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1342         my $namespace = $c->namespace;
1343         if (defined $path) { # cheesy hack to handle path '../foo'
1344            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1345         }
1346         unshift(@args, $namespace || '');
1347     }
1348
1349     # join args with '/', or a blank string
1350     my $args = join('/', grep { defined($_) } @args);
1351     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1352     $args =~ s!^/+!!;
1353     my $base = $c->req->base;
1354     my $class = ref($base);
1355     $base =~ s{(?<!/)$}{/};
1356
1357     my $query = '';
1358
1359     if (my @keys = keys %$params) {
1360       # somewhat lifted from URI::_query's query_form
1361       $query = '?'.join('&', map {
1362           my $val = $params->{$_};
1363           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1364           s/ /+/g;
1365           my $key = $_;
1366           $val = '' unless defined $val;
1367           (map {
1368               my $param = "$_";
1369               utf8::encode( $param ) if utf8::is_utf8($param);
1370               # using the URI::Escape pattern here so utf8 chars survive
1371               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1372               $param =~ s/ /+/g;
1373               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1374       } @keys);
1375     }
1376
1377     my $res = bless(\"${base}${args}${query}", $class);
1378     $res;
1379 }
1380
1381 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1382
1383 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1384
1385 =over
1386
1387 =item $path
1388
1389 A private path to the Catalyst action you want to create a URI for.
1390
1391 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1392 >> and passing the resulting C<$action> and the remaining arguments to C<<
1393 $c->uri_for >>.
1394
1395 You can also pass in a Catalyst::Action object, in which case it is passed to
1396 C<< $c->uri_for >>.
1397
1398 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1399
1400 For example, if the action looks like:
1401
1402  package MyApp::Controller::Users;
1403
1404  sub lst : Path('the-list') {}
1405
1406 You can use:
1407
1408  $c->uri_for_action('/users/lst')
1409
1410 and it will create the URI /users/the-list.
1411
1412 =item \@captures_and_args?
1413
1414 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1415 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1416 to interpolate all the parameters in the URI.
1417
1418 =item @args?
1419
1420 Optional list of extra arguments - can be supplied in the
1421 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1422 code.
1423
1424 Your action can have zero, a fixed or a variable number of args (e.g.
1425 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1426
1427 =item \%query_values?
1428
1429 Optional array reference of query parameters to append. E.g.
1430
1431   { foo => 'bar' }
1432
1433 will generate
1434
1435   /rest/of/your/uri?foo=bar
1436
1437 =back
1438
1439 =cut
1440
1441 sub uri_for_action {
1442     my ( $c, $path, @args ) = @_;
1443     my $action = blessed($path)
1444       ? $path
1445       : $c->dispatcher->get_action_by_path($path);
1446     unless (defined $action) {
1447       croak "Can't find action for path '$path'";
1448     }
1449     return $c->uri_for( $action, @args );
1450 }
1451
1452 =head2 $c->welcome_message
1453
1454 Returns the Catalyst welcome HTML page.
1455
1456 =cut
1457
1458 sub welcome_message {
1459     my $c      = shift;
1460     my $name   = $c->config->{name};
1461     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1462     my $prefix = Catalyst::Utils::appprefix( ref $c );
1463     $c->response->content_type('text/html; charset=utf-8');
1464     return <<"EOF";
1465 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1466     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1467 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1468     <head>
1469     <meta http-equiv="Content-Language" content="en" />
1470     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1471         <title>$name on Catalyst $VERSION</title>
1472         <style type="text/css">
1473             body {
1474                 color: #000;
1475                 background-color: #eee;
1476             }
1477             div#content {
1478                 width: 640px;
1479                 margin-left: auto;
1480                 margin-right: auto;
1481                 margin-top: 10px;
1482                 margin-bottom: 10px;
1483                 text-align: left;
1484                 background-color: #ccc;
1485                 border: 1px solid #aaa;
1486             }
1487             p, h1, h2 {
1488                 margin-left: 20px;
1489                 margin-right: 20px;
1490                 font-family: verdana, tahoma, sans-serif;
1491             }
1492             a {
1493                 font-family: verdana, tahoma, sans-serif;
1494             }
1495             :link, :visited {
1496                     text-decoration: none;
1497                     color: #b00;
1498                     border-bottom: 1px dotted #bbb;
1499             }
1500             :link:hover, :visited:hover {
1501                     color: #555;
1502             }
1503             div#topbar {
1504                 margin: 0px;
1505             }
1506             pre {
1507                 margin: 10px;
1508                 padding: 8px;
1509             }
1510             div#answers {
1511                 padding: 8px;
1512                 margin: 10px;
1513                 background-color: #fff;
1514                 border: 1px solid #aaa;
1515             }
1516             h1 {
1517                 font-size: 0.9em;
1518                 font-weight: normal;
1519                 text-align: center;
1520             }
1521             h2 {
1522                 font-size: 1.0em;
1523             }
1524             p {
1525                 font-size: 0.9em;
1526             }
1527             p img {
1528                 float: right;
1529                 margin-left: 10px;
1530             }
1531             span#appname {
1532                 font-weight: bold;
1533                 font-size: 1.6em;
1534             }
1535         </style>
1536     </head>
1537     <body>
1538         <div id="content">
1539             <div id="topbar">
1540                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1541                     $VERSION</h1>
1542              </div>
1543              <div id="answers">
1544                  <p>
1545                  <img src="$logo" alt="Catalyst Logo" />
1546                  </p>
1547                  <p>Welcome to the  world of Catalyst.
1548                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1549                     framework will make web development something you had
1550                     never expected it to be: Fun, rewarding, and quick.</p>
1551                  <h2>What to do now?</h2>
1552                  <p>That really depends  on what <b>you</b> want to do.
1553                     We do, however, provide you with a few starting points.</p>
1554                  <p>If you want to jump right into web development with Catalyst
1555                     you might want to start with a tutorial.</p>
1556 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1557 </pre>
1558 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1559 <pre>
1560 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1561 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1562 </code></pre>
1563                  <h2>What to do next?</h2>
1564                  <p>Next it's time to write an actual application. Use the
1565                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1566                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1567                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1568                     they can save you a lot of work.</p>
1569                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1570                     <p>Also, be sure to check out the vast and growing
1571                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1572                     you are likely to find what you need there.
1573                     </p>
1574
1575                  <h2>Need help?</h2>
1576                  <p>Catalyst has a very active community. Here are the main places to
1577                     get in touch with us.</p>
1578                  <ul>
1579                      <li>
1580                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1581                      </li>
1582                      <li>
1583                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1584                      </li>
1585                      <li>
1586                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1587                      </li>
1588                  </ul>
1589                  <h2>In conclusion</h2>
1590                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1591                     as we enjoyed making it. Please contact us if you have ideas
1592                     for improvement or other feedback.</p>
1593              </div>
1594          </div>
1595     </body>
1596 </html>
1597 EOF
1598 }
1599
1600 =head2 run_options
1601
1602 Contains a hash of options passed from the application script, including
1603 the original ARGV the script received, the processed values from that
1604 ARGV and any extra arguments to the script which were not processed.
1605
1606 This can be used to add custom options to your application's scripts
1607 and setup your application differently depending on the values of these
1608 options.
1609
1610 =head1 INTERNAL METHODS
1611
1612 These methods are not meant to be used by end users.
1613
1614 =head2 $c->components
1615
1616 Returns a hash of components.
1617
1618 =head2 $c->context_class
1619
1620 Returns or sets the context class.
1621
1622 =head2 $c->counter
1623
1624 Returns a hashref containing coderefs and execution counts (needed for
1625 deep recursion detection).
1626
1627 =head2 $c->depth
1628
1629 Returns the number of actions on the current internal execution stack.
1630
1631 =head2 $c->dispatch
1632
1633 Dispatches a request to actions.
1634
1635 =cut
1636
1637 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1638
1639 =head2 $c->dispatcher_class
1640
1641 Returns or sets the dispatcher class.
1642
1643 =head2 $c->dump_these
1644
1645 Returns a list of 2-element array references (name, structure) pairs
1646 that will be dumped on the error page in debug mode.
1647
1648 =cut
1649
1650 sub dump_these {
1651     my $c = shift;
1652     [ Request => $c->req ],
1653     [ Response => $c->res ],
1654     [ Stash => $c->stash ],
1655     [ Config => $c->config ];
1656 }
1657
1658 =head2 $c->engine_class
1659
1660 Returns or sets the engine class.
1661
1662 =head2 $c->execute( $class, $coderef )
1663
1664 Execute a coderef in given class and catch exceptions. Errors are available
1665 via $c->error.
1666
1667 =cut
1668
1669 sub execute {
1670     my ( $c, $class, $code ) = @_;
1671     $class = $c->component($class) || $class;
1672     $c->state(0);
1673
1674     if ( $c->depth >= $RECURSION ) {
1675         my $action = $code->reverse();
1676         $action = "/$action" unless $action =~ /->/;
1677         my $error = qq/Deep recursion detected calling "${action}"/;
1678         $c->log->error($error);
1679         $c->error($error);
1680         $c->state(0);
1681         return $c->state;
1682     }
1683
1684     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1685
1686     push( @{ $c->stack }, $code );
1687
1688     no warnings 'recursion';
1689     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1690     #      I have no idea how, ergo $ret (which appears to fix the issue)
1691     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1692
1693     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1694
1695     my $last = pop( @{ $c->stack } );
1696
1697     if ( my $error = $@ ) {
1698         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1699             $error->rethrow if $c->depth > 1;
1700         }
1701         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1702             $error->rethrow if $c->depth > 0;
1703         }
1704         else {
1705             unless ( ref $error ) {
1706                 no warnings 'uninitialized';
1707                 chomp $error;
1708                 my $class = $last->class;
1709                 my $name  = $last->name;
1710                 $error = qq/Caught exception in $class->$name "$error"/;
1711             }
1712             $c->error($error);
1713         }
1714         $c->state(0);
1715     }
1716     return $c->state;
1717 }
1718
1719 sub _stats_start_execute {
1720     my ( $c, $code ) = @_;
1721     my $appclass = ref($c) || $c;
1722     return if ( ( $code->name =~ /^_.*/ )
1723         && ( !$appclass->config->{show_internal_actions} ) );
1724
1725     my $action_name = $code->reverse();
1726     $c->counter->{$action_name}++;
1727
1728     my $action = $action_name;
1729     $action = "/$action" unless $action =~ /->/;
1730
1731     # determine if the call was the result of a forward
1732     # this is done by walking up the call stack and looking for a calling
1733     # sub of Catalyst::forward before the eval
1734     my $callsub = q{};
1735     for my $index ( 2 .. 11 ) {
1736         last
1737         if ( ( caller($index) )[0] eq 'Catalyst'
1738             && ( caller($index) )[3] eq '(eval)' );
1739
1740         if ( ( caller($index) )[3] =~ /forward$/ ) {
1741             $callsub = ( caller($index) )[3];
1742             $action  = "-> $action";
1743             last;
1744         }
1745     }
1746
1747     my $uid = $action_name . $c->counter->{$action_name};
1748
1749     # is this a root-level call or a forwarded call?
1750     if ( $callsub =~ /forward$/ ) {
1751         my $parent = $c->stack->[-1];
1752
1753         # forward, locate the caller
1754         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1755             $c->stats->profile(
1756                 begin  => $action,
1757                 parent => "$parent" . $c->counter->{"$parent"},
1758                 uid    => $uid,
1759             );
1760         }
1761         else {
1762
1763             # forward with no caller may come from a plugin
1764             $c->stats->profile(
1765                 begin => $action,
1766                 uid   => $uid,
1767             );
1768         }
1769     }
1770     else {
1771
1772         # root-level call
1773         $c->stats->profile(
1774             begin => $action,
1775             uid   => $uid,
1776         );
1777     }
1778     return $action;
1779
1780 }
1781
1782 sub _stats_finish_execute {
1783     my ( $c, $info ) = @_;
1784     $c->stats->profile( end => $info );
1785 }
1786
1787 =head2 $c->finalize
1788
1789 Finalizes the request.
1790
1791 =cut
1792
1793 sub finalize {
1794     my $c = shift;
1795
1796     for my $error ( @{ $c->error } ) {
1797         $c->log->error($error);
1798     }
1799
1800     # Allow engine to handle finalize flow (for POE)
1801     my $engine = $c->engine;
1802     if ( my $code = $engine->can('finalize') ) {
1803         $engine->$code($c);
1804     }
1805     else {
1806
1807         $c->finalize_uploads;
1808
1809         # Error
1810         if ( $#{ $c->error } >= 0 ) {
1811             $c->finalize_error;
1812         }
1813
1814         $c->finalize_headers;
1815
1816         # HEAD request
1817         if ( $c->request->method eq 'HEAD' ) {
1818             $c->response->body('');
1819         }
1820
1821         $c->finalize_body;
1822     }
1823
1824     $c->log_response;
1825
1826     if ($c->use_stats) {
1827         my $elapsed = sprintf '%f', $c->stats->elapsed;
1828         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1829         $c->log->info(
1830             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1831     }
1832
1833     return $c->response->status;
1834 }
1835
1836 =head2 $c->finalize_body
1837
1838 Finalizes body.
1839
1840 =cut
1841
1842 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1843
1844 =head2 $c->finalize_cookies
1845
1846 Finalizes cookies.
1847
1848 =cut
1849
1850 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1851
1852 =head2 $c->finalize_error
1853
1854 Finalizes error.
1855
1856 =cut
1857
1858 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1859
1860 =head2 $c->finalize_headers
1861
1862 Finalizes headers.
1863
1864 =cut
1865
1866 sub finalize_headers {
1867     my $c = shift;
1868
1869     my $response = $c->response; #accessor calls can add up?
1870
1871     # Check if we already finalized headers
1872     return if $response->finalized_headers;
1873
1874     # Handle redirects
1875     if ( my $location = $response->redirect ) {
1876         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1877         $response->header( Location => $location );
1878
1879         if ( !$response->has_body ) {
1880             # Add a default body if none is already present
1881             $response->body(<<"EOF");
1882 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1883 <html xmlns="http://www.w3.org/1999/xhtml">
1884   <head>
1885     <title>Moved</title>
1886   </head>
1887   <body>
1888      <p>This item has moved <a href="$location">here</a>.</p>
1889   </body>
1890 </html>
1891 EOF
1892             $response->content_type('text/html; charset=utf-8');
1893         }
1894     }
1895
1896     # Content-Length
1897     if ( defined $response->body && length $response->body && !$response->content_length ) {
1898
1899         # get the length from a filehandle
1900         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1901         {
1902             my $size = -s $response->body;
1903             if ( $size ) {
1904                 $response->content_length( $size );
1905             }
1906             else {
1907                 $c->log->warn('Serving filehandle without a content-length');
1908             }
1909         }
1910         else {
1911             # everything should be bytes at this point, but just in case
1912             $response->content_length( length( $response->body ) );
1913         }
1914     }
1915
1916     # Errors
1917     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1918         $response->headers->remove_header("Content-Length");
1919         $response->body('');
1920     }
1921
1922     $c->finalize_cookies;
1923
1924     $c->engine->finalize_headers( $c, @_ );
1925
1926     # Done
1927     $response->finalized_headers(1);
1928 }
1929
1930 =head2 $c->finalize_output
1931
1932 An alias for finalize_body.
1933
1934 =head2 $c->finalize_read
1935
1936 Finalizes the input after reading is complete.
1937
1938 =cut
1939
1940 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1941
1942 =head2 $c->finalize_uploads
1943
1944 Finalizes uploads. Cleans up any temporary files.
1945
1946 =cut
1947
1948 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1949
1950 =head2 $c->get_action( $action, $namespace )
1951
1952 Gets an action in a given namespace.
1953
1954 =cut
1955
1956 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1957
1958 =head2 $c->get_actions( $action, $namespace )
1959
1960 Gets all actions of a given name in a namespace and all parent
1961 namespaces.
1962
1963 =cut
1964
1965 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1966
1967 =head2 $app->handle_request( @arguments )
1968
1969 Called to handle each HTTP request.
1970
1971 =cut
1972
1973 sub handle_request {
1974     my ( $class, @arguments ) = @_;
1975
1976     # Always expect worst case!
1977     my $status = -1;
1978     try {
1979         if ($class->debug) {
1980             my $secs = time - $START || 1;
1981             my $av = sprintf '%.3f', $COUNT / $secs;
1982             my $time = localtime time;
1983             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1984         }
1985
1986         my $c = $class->prepare(@arguments);
1987         $c->dispatch;
1988         $status = $c->finalize;
1989     }
1990     catch {
1991         chomp(my $error = $_);
1992         $class->log->error(qq/Caught exception in engine "$error"/);
1993     };
1994
1995     $COUNT++;
1996
1997     if(my $coderef = $class->log->can('_flush')){
1998         $class->log->$coderef();
1999     }
2000     return $status;
2001 }
2002
2003 =head2 $class->prepare( @arguments )
2004
2005 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2006 etc.).
2007
2008 =cut
2009
2010 has _uploadtmp => (
2011     is => 'ro',
2012     predicate => '_has_uploadtmp',
2013 );
2014
2015 sub prepare {
2016     my ( $class, @arguments ) = @_;
2017
2018     # XXX
2019     # After the app/ctxt split, this should become an attribute based on something passed
2020     # into the application.
2021     $class->context_class( ref $class || $class ) unless $class->context_class;
2022
2023     my $uploadtmp = $class->config->{uploadtmp};
2024     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2025
2026     #surely this is not the most efficient way to do things...
2027     $c->stats($class->stats_class->new)->enable($c->use_stats);
2028     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2029         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2030     }
2031
2032     try {
2033         # Allow engine to direct the prepare flow (for POE)
2034         if ( my $prepare = $c->engine->can('prepare') ) {
2035             $c->engine->$prepare( $c, @arguments );
2036         }
2037         else {
2038             $c->prepare_request(@arguments);
2039             $c->prepare_connection;
2040             $c->prepare_query_parameters;
2041             $c->prepare_headers; # Just hooks, no longer needed - they just
2042             $c->prepare_cookies; # cause the lazy attribute on req to build
2043             $c->prepare_path;
2044
2045             # Prepare the body for reading, either by prepare_body
2046             # or the user, if they are using $c->read
2047             $c->prepare_read;
2048
2049             # Parse the body unless the user wants it on-demand
2050             unless ( ref($c)->config->{parse_on_demand} ) {
2051                 $c->prepare_body;
2052             }
2053         }
2054         $c->prepare_action;
2055     }
2056     # VERY ugly and probably shouldn't rely on ->finalize actually working
2057     catch {
2058         # failed prepare is always due to an invalid request, right?
2059         $c->response->status(400);
2060         $c->response->content_type('text/plain');
2061         $c->response->body('Bad Request');
2062         # Note we call finalize and then die here, which escapes
2063         # finalize being called in the enclosing block..
2064         # It in fact couldn't be called, as we don't return $c..
2065         # This is a mess - but I'm unsure you can fix this without
2066         # breaking compat for people doing crazy things (we should set
2067         # the 400 and just return the ctx here IMO, letting finalize get called
2068         # above...
2069         $c->finalize;
2070         die $_;
2071     };
2072
2073     $c->log_request;
2074
2075     return $c;
2076 }
2077
2078 =head2 $c->prepare_action
2079
2080 Prepares action. See L<Catalyst::Dispatcher>.
2081
2082 =cut
2083
2084 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2085
2086 =head2 $c->prepare_body
2087
2088 Prepares message body.
2089
2090 =cut
2091
2092 sub prepare_body {
2093     my $c = shift;
2094
2095     return if $c->request->_has_body;
2096
2097     # Initialize on-demand data
2098     $c->engine->prepare_body( $c, @_ );
2099     $c->prepare_parameters;
2100     $c->prepare_uploads;
2101 }
2102
2103 =head2 $c->prepare_body_chunk( $chunk )
2104
2105 Prepares a chunk of data before sending it to L<HTTP::Body>.
2106
2107 See L<Catalyst::Engine>.
2108
2109 =cut
2110
2111 sub prepare_body_chunk {
2112     my $c = shift;
2113     $c->engine->prepare_body_chunk( $c, @_ );
2114 }
2115
2116 =head2 $c->prepare_body_parameters
2117
2118 Prepares body parameters.
2119
2120 =cut
2121
2122 sub prepare_body_parameters {
2123     my $c = shift;
2124     $c->engine->prepare_body_parameters( $c, @_ );
2125 }
2126
2127 =head2 $c->prepare_connection
2128
2129 Prepares connection.
2130
2131 =cut
2132
2133 sub prepare_connection {
2134     my $c = shift;
2135     # XXX - This is called on the engine (not the request) to maintain
2136     #       Engine::PSGI back compat.
2137     $c->engine->prepare_connection($c);
2138 }
2139
2140 =head2 $c->prepare_cookies
2141
2142 Prepares cookies by ensuring that the attribute on the request
2143 object has been built.
2144
2145 =cut
2146
2147 sub prepare_cookies { my $c = shift; $c->request->cookies }
2148
2149 =head2 $c->prepare_headers
2150
2151 Prepares request headers by ensuring that the attribute on the request
2152 object has been built.
2153
2154 =cut
2155
2156 sub prepare_headers { my $c = shift; $c->request->headers }
2157
2158 =head2 $c->prepare_parameters
2159
2160 Prepares parameters.
2161
2162 =cut
2163
2164 sub prepare_parameters {
2165     my $c = shift;
2166     $c->prepare_body_parameters;
2167     $c->engine->prepare_parameters( $c, @_ );
2168 }
2169
2170 =head2 $c->prepare_path
2171
2172 Prepares path and base.
2173
2174 =cut
2175
2176 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2177
2178 =head2 $c->prepare_query_parameters
2179
2180 Prepares query parameters.
2181
2182 =cut
2183
2184 sub prepare_query_parameters {
2185     my $c = shift;
2186
2187     $c->engine->prepare_query_parameters( $c, @_ );
2188 }
2189
2190 =head2 $c->log_request
2191
2192 Writes information about the request to the debug logs.  This includes:
2193
2194 =over 4
2195
2196 =item * Request method, path, and remote IP address
2197
2198 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2199
2200 =item * Request parameters
2201
2202 =item * File uploads
2203
2204 =back
2205
2206 =cut
2207
2208 sub log_request {
2209     my $c = shift;
2210
2211     return unless $c->debug;
2212
2213     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2214     my $request = $dump->[1];
2215
2216     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2217     $method ||= '';
2218     $path = '/' unless length $path;
2219     $address ||= '';
2220     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2221
2222     $c->log_request_headers($request->headers);
2223
2224     if ( my $keywords = $request->query_keywords ) {
2225         $c->log->debug("Query keywords are: $keywords");
2226     }
2227
2228     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2229
2230     $c->log_request_uploads($request);
2231 }
2232
2233 =head2 $c->log_response
2234
2235 Writes information about the response to the debug logs by calling
2236 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2237
2238 =cut
2239
2240 sub log_response {
2241     my $c = shift;
2242
2243     return unless $c->debug;
2244
2245     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2246     my $response = $dump->[1];
2247
2248     $c->log_response_status_line($response);
2249     $c->log_response_headers($response->headers);
2250 }
2251
2252 =head2 $c->log_response_status_line($response)
2253
2254 Writes one line of information about the response to the debug logs.  This includes:
2255
2256 =over 4
2257
2258 =item * Response status code
2259
2260 =item * Content-Type header (if present)
2261
2262 =item * Content-Length header (if present)
2263
2264 =back
2265
2266 =cut
2267
2268 sub log_response_status_line {
2269     my ($c, $response) = @_;
2270
2271     $c->log->debug(
2272         sprintf(
2273             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2274             $response->status                            || 'unknown',
2275             $response->headers->header('Content-Type')   || 'unknown',
2276             $response->headers->header('Content-Length') || 'unknown'
2277         )
2278     );
2279 }
2280
2281 =head2 $c->log_response_headers($headers);
2282
2283 Hook method which can be wrapped by plugins to log the response headers.
2284 No-op in the default implementation.
2285
2286 =cut
2287
2288 sub log_response_headers {}
2289
2290 =head2 $c->log_request_parameters( query => {}, body => {} )
2291
2292 Logs request parameters to debug logs
2293
2294 =cut
2295
2296 sub log_request_parameters {
2297     my $c          = shift;
2298     my %all_params = @_;
2299
2300     return unless $c->debug;
2301
2302     my $column_width = Catalyst::Utils::term_width() - 44;
2303     foreach my $type (qw(query body)) {
2304         my $params = $all_params{$type};
2305         next if ! keys %$params;
2306         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2307         for my $key ( sort keys %$params ) {
2308             my $param = $params->{$key};
2309             my $value = defined($param) ? $param : '';
2310             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2311         }
2312         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2313     }
2314 }
2315
2316 =head2 $c->log_request_uploads
2317
2318 Logs file uploads included in the request to the debug logs.
2319 The parameter name, filename, file type, and file size are all included in
2320 the debug logs.
2321
2322 =cut
2323
2324 sub log_request_uploads {
2325     my $c = shift;
2326     my $request = shift;
2327     return unless $c->debug;
2328     my $uploads = $request->uploads;
2329     if ( keys %$uploads ) {
2330         my $t = Text::SimpleTable->new(
2331             [ 12, 'Parameter' ],
2332             [ 26, 'Filename' ],
2333             [ 18, 'Type' ],
2334             [ 9,  'Size' ]
2335         );
2336         for my $key ( sort keys %$uploads ) {
2337             my $upload = $uploads->{$key};
2338             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2339                 $t->row( $key, $u->filename, $u->type, $u->size );
2340             }
2341         }
2342         $c->log->debug( "File Uploads are:\n" . $t->draw );
2343     }
2344 }
2345
2346 =head2 $c->log_request_headers($headers);
2347
2348 Hook method which can be wrapped by plugins to log the request headers.
2349 No-op in the default implementation.
2350
2351 =cut
2352
2353 sub log_request_headers {}
2354
2355 =head2 $c->log_headers($type => $headers)
2356
2357 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2358
2359 =cut
2360
2361 sub log_headers {
2362     my $c       = shift;
2363     my $type    = shift;
2364     my $headers = shift;    # an HTTP::Headers instance
2365
2366     return unless $c->debug;
2367
2368     my $column_width = Catalyst::Utils::term_width() - 28;
2369     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2370     $headers->scan(
2371         sub {
2372             my ( $name, $value ) = @_;
2373             $t->row( $name, $value );
2374         }
2375     );
2376     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2377 }
2378
2379
2380 =head2 $c->prepare_read
2381
2382 Prepares the input for reading.
2383
2384 =cut
2385
2386 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2387
2388 =head2 $c->prepare_request
2389
2390 Prepares the engine request.
2391
2392 =cut
2393
2394 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2395
2396 =head2 $c->prepare_uploads
2397
2398 Prepares uploads.
2399
2400 =cut
2401
2402 sub prepare_uploads {
2403     my $c = shift;
2404
2405     $c->engine->prepare_uploads( $c, @_ );
2406 }
2407
2408 =head2 $c->prepare_write
2409
2410 Prepares the output for writing.
2411
2412 =cut
2413
2414 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2415
2416 =head2 $c->request_class
2417
2418 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2419
2420 =head2 $c->response_class
2421
2422 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2423
2424 =head2 $c->read( [$maxlength] )
2425
2426 Reads a chunk of data from the request body. This method is designed to
2427 be used in a while loop, reading C<$maxlength> bytes on every call.
2428 C<$maxlength> defaults to the size of the request if not specified.
2429
2430 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2431 directly.
2432
2433 Warning: If you use read(), Catalyst will not process the body,
2434 so you will not be able to access POST parameters or file uploads via
2435 $c->request.  You must handle all body parsing yourself.
2436
2437 =cut
2438
2439 sub read { my $c = shift; return $c->request->read( @_ ) }
2440
2441 =head2 $c->run
2442
2443 Starts the engine.
2444
2445 =cut
2446
2447 sub run {
2448   my $app = shift;
2449   $app->engine_loader->needs_psgi_engine_compat_hack ?
2450     $app->engine->run($app, @_) :
2451       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2452 }
2453
2454 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2455
2456 Sets an action in a given namespace.
2457
2458 =cut
2459
2460 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2461
2462 =head2 $c->setup_actions($component)
2463
2464 Sets up actions for a component.
2465
2466 =cut
2467
2468 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2469
2470 =head2 $c->setup_components
2471
2472 This method is called internally to set up the application's components.
2473
2474 It finds modules by calling the L<locate_components> method, expands them to
2475 package names with the L<expand_component_module> method, and then installs
2476 each component into the application.
2477
2478 The C<setup_components> config option is passed to both of the above methods.
2479
2480 Installation of each component is performed by the L<setup_component> method,
2481 below.
2482
2483 =cut
2484
2485 sub setup_components {
2486     my $class = shift;
2487
2488     my $config  = $class->config->{ setup_components };
2489
2490     my @comps = $class->locate_components($config);
2491     my %comps = map { $_ => 1 } @comps;
2492
2493     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2494     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2495         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2496     ) if $deprecatedcatalyst_component_names;
2497
2498     for my $component ( @comps ) {
2499
2500         # We pass ignore_loaded here so that overlay files for (e.g.)
2501         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2502         # we know M::P::O found a file on disk so this is safe
2503
2504         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2505     }
2506
2507     for my $component (@comps) {
2508         my $instance = $class->components->{ $component } = $class->setup_component($component);
2509         my @expanded_components = $instance->can('expand_modules')
2510             ? $instance->expand_modules( $component, $config )
2511             : $class->expand_component_module( $component, $config );
2512         for my $component (@expanded_components) {
2513             next if $comps{$component};
2514             $class->components->{ $component } = $class->setup_component($component);
2515         }
2516     }
2517 }
2518
2519 =head2 $c->locate_components( $setup_component_config )
2520
2521 This method is meant to provide a list of component modules that should be
2522 setup for the application.  By default, it will use L<Module::Pluggable>.
2523
2524 Specify a C<setup_components> config option to pass additional options directly
2525 to L<Module::Pluggable>. To add additional search paths, specify a key named
2526 C<search_extra> as an array reference. Items in the array beginning with C<::>
2527 will have the application class name prepended to them.
2528
2529 =cut
2530
2531 sub locate_components {
2532     my $class  = shift;
2533     my $config = shift;
2534
2535     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2536     my $extra   = delete $config->{ search_extra } || [];
2537
2538     push @paths, @$extra;
2539
2540     my $locator = Module::Pluggable::Object->new(
2541         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2542         %$config
2543     );
2544
2545     # XXX think about ditching this sort entirely
2546     my @comps = sort { length $a <=> length $b } $locator->plugins;
2547
2548     return @comps;
2549 }
2550
2551 =head2 $c->expand_component_module( $component, $setup_component_config )
2552
2553 Components found by C<locate_components> will be passed to this method, which
2554 is expected to return a list of component (package) names to be set up.
2555
2556 =cut
2557
2558 sub expand_component_module {
2559     my ($class, $module) = @_;
2560     return Devel::InnerPackage::list_packages( $module );
2561 }
2562
2563 =head2 $c->setup_component
2564
2565 =cut
2566
2567 sub setup_component {
2568     my( $class, $component ) = @_;
2569
2570     unless ( $component->can( 'COMPONENT' ) ) {
2571         return $component;
2572     }
2573
2574     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2575     my $config = $class->config->{ $suffix } || {};
2576     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2577     # methods also pass it. local to avoid pointlessly shitting in config
2578     # for the debug screen, as $component is already the key name.
2579     local $config->{catalyst_component_name} = $component;
2580
2581     my $instance = eval { $component->COMPONENT( $class, $config ); };
2582
2583     if ( my $error = $@ ) {
2584         chomp $error;
2585         Catalyst::Exception->throw(
2586             message => qq/Couldn't instantiate component "$component", "$error"/
2587         );
2588     }
2589
2590     unless (blessed $instance) {
2591         my $metaclass = Moose::Util::find_meta($component);
2592         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2593         my $component_method_from = $method_meta->associated_metaclass->name;
2594         my $value = defined($instance) ? $instance : 'undef';
2595         Catalyst::Exception->throw(
2596             message =>
2597             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2598         );
2599     }
2600     return $instance;
2601 }
2602
2603 =head2 $c->setup_dispatcher
2604
2605 Sets up dispatcher.
2606
2607 =cut
2608
2609 sub setup_dispatcher {
2610     my ( $class, $dispatcher ) = @_;
2611
2612     if ($dispatcher) {
2613         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2614     }
2615
2616     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2617         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2618     }
2619
2620     unless ($dispatcher) {
2621         $dispatcher = $class->dispatcher_class;
2622     }
2623
2624     Class::MOP::load_class($dispatcher);
2625
2626     # dispatcher instance
2627     $class->dispatcher( $dispatcher->new );
2628 }
2629
2630 =head2 $c->setup_engine
2631
2632 Sets up engine.
2633
2634 =cut
2635
2636 sub engine_class {
2637     my ($class, $requested_engine) = @_;
2638
2639     if (!$class->engine_loader || $requested_engine) {
2640         $class->engine_loader(
2641             Catalyst::EngineLoader->new({
2642                 application_name => $class,
2643                 (defined $requested_engine
2644                      ? (catalyst_engine_class => $requested_engine) : ()),
2645             }),
2646         );
2647     }
2648
2649     $class->engine_loader->catalyst_engine_class;
2650 }
2651
2652 sub setup_engine {
2653     my ($class, $requested_engine) = @_;
2654
2655     my $engine = do {
2656         my $loader = $class->engine_loader;
2657
2658         if (!$loader || $requested_engine) {
2659             $loader = Catalyst::EngineLoader->new({
2660                 application_name => $class,
2661                 (defined $requested_engine
2662                      ? (requested_engine => $requested_engine) : ()),
2663             }),
2664
2665             $class->engine_loader($loader);
2666         }
2667
2668         $loader->catalyst_engine_class;
2669     };
2670
2671     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2672     return if $class->loading_psgi_file;
2673
2674     Class::MOP::load_class($engine);
2675
2676     if ($ENV{MOD_PERL}) {
2677         my $apache = $class->engine_loader->auto;
2678
2679         my $meta = find_meta($class);
2680         my $was_immutable = $meta->is_immutable;
2681         my %immutable_options = $meta->immutable_options;
2682         $meta->make_mutable if $was_immutable;
2683
2684         $meta->add_method(handler => sub {
2685             my $r = shift;
2686             my $psgi_app = $class->_finalized_psgi_app;
2687             $apache->call_app($r, $psgi_app);
2688         });
2689
2690         $meta->make_immutable(%immutable_options) if $was_immutable;
2691     }
2692
2693     $class->engine( $engine->new );
2694
2695     return;
2696 }
2697
2698 sub _finalized_psgi_app {
2699     my ($app) = @_;
2700
2701     unless ($app->_psgi_app) {
2702         my $psgi_app = $app->_setup_psgi_app;
2703         $app->_psgi_app($psgi_app);
2704     }
2705
2706     return $app->_psgi_app;
2707 }
2708
2709 sub _setup_psgi_app {
2710     my ($app) = @_;
2711
2712     for my $home (Path::Class::Dir->new($app->config->{home})) {
2713         my $psgi_file = $home->file(
2714             Catalyst::Utils::appprefix($app) . '.psgi',
2715         );
2716
2717         next unless -e $psgi_file;
2718
2719         # If $psgi_file calls ->setup_engine, it's doing so to load
2720         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2721         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2722         # anyway. So set a flag (ick) that tells setup_engine not to populate
2723         # $c->engine or do any other things we might regret.
2724
2725         $app->loading_psgi_file(1);
2726         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2727         $app->loading_psgi_file(0);
2728
2729         return $psgi_app
2730             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2731
2732         warn <<"EOW";
2733 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2734
2735 Its content has been ignored. Please consult the Catalyst::Upgrading
2736 documentation on how to upgrade from Catalyst::Engine::PSGI.
2737 EOW
2738     }
2739
2740     return $app->apply_default_middlewares($app->psgi_app);
2741 }
2742
2743 =head2 $c->apply_default_middlewares
2744
2745 Adds the following L<Plack> middlewares to your application, since they are
2746 useful and commonly needed:
2747
2748 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2749 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2750 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2751 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2752 applied since this middleware is smart enough to conditionally apply itself).
2753
2754 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2755 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2756 $ENV{SCRIPT_NAME}
2757
2758 =cut
2759
2760
2761 sub apply_default_middlewares {
2762     my ($app, $psgi_app) = @_;
2763
2764     $psgi_app = Plack::Middleware::Conditional->wrap(
2765         $psgi_app,
2766         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2767         condition => sub {
2768             my ($env) = @_;
2769             return if $app->config->{ignore_frontend_proxy};
2770             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2771                 || $app->config->{using_frontend_proxy};
2772         },
2773     );
2774
2775     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2776     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2777     $psgi_app = Plack::Middleware::Conditional->wrap(
2778         $psgi_app,
2779         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2780         condition => sub {
2781             my ($env) = @_;
2782             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2783             return unless $1 < 4.23;
2784             1;
2785         },
2786     );
2787
2788     # we're applying this unconditionally as the middleware itself already makes
2789     # sure it doesn't fuck things up if it's not running under one of the right
2790     # IIS versions
2791     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2792
2793     return $psgi_app;
2794 }
2795
2796 =head2 $c->psgi_app
2797
2798 Returns a PSGI application code reference for the catalyst application
2799 C<$c>. This is the bare application without any middlewares
2800 applied. C<${myapp}.psgi> is not taken into account.
2801
2802 This is what you want to be using to retrieve the PSGI application code
2803 reference of your Catalyst application for use in F<.psgi> files.
2804
2805 =cut
2806
2807 sub psgi_app {
2808     my ($app) = @_;
2809     return $app->engine->build_psgi_app($app);
2810 }
2811
2812 =head2 $c->setup_home
2813
2814 Sets up the home directory.
2815
2816 =cut
2817
2818 sub setup_home {
2819     my ( $class, $home ) = @_;
2820
2821     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2822         $home = $env;
2823     }
2824
2825     $home ||= Catalyst::Utils::home($class);
2826
2827     if ($home) {
2828         #I remember recently being scolded for assigning config values like this
2829         $class->config->{home} ||= $home;
2830         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2831     }
2832 }
2833
2834 =head2 $c->setup_log
2835
2836 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2837 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2838 log to.
2839
2840 This method also installs a C<debug> method that returns a true value into the
2841 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2842 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2843
2844 Note that if the log has already been setup, by either a previous call to
2845 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2846 that this method won't actually set up the log object.
2847
2848 =cut
2849
2850 sub setup_log {
2851     my ( $class, $levels ) = @_;
2852
2853     $levels ||= '';
2854     $levels =~ s/^\s+//;
2855     $levels =~ s/\s+$//;
2856     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2857
2858     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2859     if ( defined $env_debug ) {
2860         $levels{debug} = 1 if $env_debug; # Ugly!
2861         delete($levels{debug}) unless $env_debug;
2862     }
2863
2864     unless ( $class->log ) {
2865         $class->log( Catalyst::Log->new(keys %levels) );
2866     }
2867
2868     if ( $levels{debug} ) {
2869         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2870         $class->log->debug('Debug messages enabled');
2871     }
2872 }
2873
2874 =head2 $c->setup_plugins
2875
2876 Sets up plugins.
2877
2878 =cut
2879
2880 =head2 $c->setup_stats
2881
2882 Sets up timing statistics class.
2883
2884 =cut
2885
2886 sub setup_stats {
2887     my ( $class, $stats ) = @_;
2888
2889     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2890
2891     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2892     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2893         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2894         $class->log->debug('Statistics enabled');
2895     }
2896 }
2897
2898
2899 =head2 $c->registered_plugins
2900
2901 Returns a sorted list of the plugins which have either been stated in the
2902 import list.
2903
2904 If passed a given plugin name, it will report a boolean value indicating
2905 whether or not that plugin is loaded.  A fully qualified name is required if
2906 the plugin name does not begin with C<Catalyst::Plugin::>.
2907
2908  if ($c->registered_plugins('Some::Plugin')) {
2909      ...
2910  }
2911
2912 =cut
2913
2914 {
2915
2916     sub registered_plugins {
2917         my $proto = shift;
2918         return sort keys %{ $proto->_plugins } unless @_;
2919         my $plugin = shift;
2920         return 1 if exists $proto->_plugins->{$plugin};
2921         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2922     }
2923
2924     sub _register_plugin {
2925         my ( $proto, $plugin, $instant ) = @_;
2926         my $class = ref $proto || $proto;
2927
2928         Class::MOP::load_class( $plugin );
2929         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2930             if $plugin->isa( 'Catalyst::Component' );
2931         $proto->_plugins->{$plugin} = 1;
2932         unless ($instant) {
2933             my $meta = Class::MOP::get_metaclass_by_name($class);
2934             $meta->superclasses($plugin, $meta->superclasses);
2935         }
2936         return $class;
2937     }
2938
2939     sub setup_plugins {
2940         my ( $class, $plugins ) = @_;
2941
2942         $class->_plugins( {} ) unless $class->_plugins;
2943         $plugins = Data::OptList::mkopt($plugins || []);
2944
2945         my @plugins = map {
2946             [ Catalyst::Utils::resolve_namespace(
2947                   $class . '::Plugin',
2948                   'Catalyst::Plugin', $_->[0]
2949               ),
2950               $_->[1],
2951             ]
2952          } @{ $plugins };
2953
2954         for my $plugin ( reverse @plugins ) {
2955             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2956             my $meta = find_meta($plugin->[0]);
2957             next if $meta && $meta->isa('Moose::Meta::Role');
2958
2959             $class->_register_plugin($plugin->[0]);
2960         }
2961
2962         my @roles =
2963             map  { $_->[0]->name, $_->[1] }
2964             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2965             map  { [find_meta($_->[0]), $_->[1]] }
2966             @plugins;
2967
2968         Moose::Util::apply_all_roles(
2969             $class => @roles
2970         ) if @roles;
2971     }
2972 }
2973
2974 =head2 $c->stack
2975
2976 Returns an arrayref of the internal execution stack (actions that are
2977 currently executing).
2978
2979 =head2 $c->stats
2980
2981 Returns the current timing statistics object. By default Catalyst uses
2982 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2983 L<< stats_class|/"$c->stats_class" >>.
2984
2985 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2986 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2987 profile explicitly, although MyApp.pm still won't profile nor output anything
2988 by itself.
2989
2990 =head2 $c->stats_class
2991
2992 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2993
2994 =head2 $c->use_stats
2995
2996 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2997
2998 Note that this is a static method, not an accessor and should be overridden
2999 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3000
3001 =cut
3002
3003 sub use_stats { 0 }
3004
3005
3006 =head2 $c->write( $data )
3007
3008 Writes $data to the output stream. When using this method directly, you
3009 will need to manually set the C<Content-Length> header to the length of
3010 your output data, if known.
3011
3012 =cut
3013
3014 sub write {
3015     my $c = shift;
3016
3017     # Finalize headers if someone manually writes output (for compat)
3018     $c->finalize_headers;
3019
3020     return $c->response->write( @_ );
3021 }
3022
3023 =head2 version
3024
3025 Returns the Catalyst version number. Mostly useful for "powered by"
3026 messages in template systems.
3027
3028 =cut
3029
3030 sub version { return $Catalyst::VERSION }
3031
3032 =head1 CONFIGURATION
3033
3034 There are a number of 'base' config variables which can be set:
3035
3036 =over
3037
3038 =item *
3039
3040 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3041
3042 =item *
3043
3044 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3045
3046 =item *
3047
3048 C<disable_component_resolution_regex_fallback> - Turns
3049 off the deprecated component resolution functionality so
3050 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3051 are called then regex search will not be attempted on string values and
3052 instead C<undef> will be returned.
3053
3054 =item *
3055
3056 C<home> - The application home directory. In an uninstalled application,
3057 this is the top level application directory. In an installed application,
3058 this will be the directory containing C<< MyApp.pm >>.
3059
3060 =item *
3061
3062 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3063
3064 =item *
3065
3066 C<name> - The name of the application in debug messages and the debug and
3067 welcome screens
3068
3069 =item *
3070
3071 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3072 until it is accessed. This allows you to (for example) check authentication (and reject
3073 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3074
3075 =item *
3076
3077 C<root> - The root directory for templates. Usually this is just a
3078 subdirectory of the home directory, but you can set it to change the
3079 templates to a different directory.
3080
3081 =item *
3082
3083 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3084 namespaces from which components will be loaded (and constructed and stored in
3085 C<< $c->components >>).
3086
3087 =item *
3088
3089 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3090 to be shown in hit debug tables in the test server.
3091
3092 =item *
3093
3094 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3095 variable should be used for determining the request path.
3096
3097 Most web server environments pass the requested path to the application using environment variables,
3098 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3099 exposed as C<< $c->request->base >>) and the request path below that base.
3100
3101 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3102 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3103
3104 =over
3105
3106 =item use_request_uri_for_path => 0
3107
3108 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3109 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3110 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3111 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3112
3113 However this method has the major disadvantage that it is impossible to correctly decode some elements
3114 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3115 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3116 can't distinguish / vs %2F in paths (in addition to other encoded values).
3117
3118 =item use_request_uri_for_path => 1
3119
3120 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3121 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3122 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3123
3124 Given that this method of path resolution is provably more correct, it is recommended that you use
3125 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3126 aware of the implications of not being able to handle encoded URI paths correctly.
3127
3128 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3129 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3130 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3131 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3132 C<< $c->request->base >> will be incorrect.
3133
3134 =back
3135
3136 =item *
3137
3138 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3139
3140 =back
3141
3142 =head1 INTERNAL ACTIONS
3143
3144 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3145 C<_ACTION>, and C<_END>. These are by default not shown in the private
3146 action table, but you can make them visible with a config parameter.
3147
3148     MyApp->config(show_internal_actions => 1);
3149
3150 =head1 ON-DEMAND PARSER
3151
3152 The request body is usually parsed at the beginning of a request,
3153 but if you want to handle input yourself, you can enable on-demand
3154 parsing with a config parameter.
3155
3156     MyApp->config(parse_on_demand => 1);
3157
3158 =head1 PROXY SUPPORT
3159
3160 Many production servers operate using the common double-server approach,
3161 with a lightweight frontend web server passing requests to a larger
3162 backend server. An application running on the backend server must deal
3163 with two problems: the remote user always appears to be C<127.0.0.1> and
3164 the server's hostname will appear to be C<localhost> regardless of the
3165 virtual host that the user connected through.
3166
3167 Catalyst will automatically detect this situation when you are running
3168 the frontend and backend servers on the same machine. The following
3169 changes are made to the request.
3170
3171     $c->req->address is set to the user's real IP address, as read from
3172     the HTTP X-Forwarded-For header.
3173
3174     The host value for $c->req->base and $c->req->uri is set to the real
3175     host, as read from the HTTP X-Forwarded-Host header.
3176
3177 Additionally, you may be running your backend application on an insecure
3178 connection (port 80) while your frontend proxy is running under SSL.  If there
3179 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3180 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3181 be created properly.
3182
3183 In the case of passing in:
3184
3185     X-Forwarded-Port: 443
3186
3187 All calls to C<uri_for> will result in an https link, as is expected.
3188
3189 Obviously, your web server must support these headers for this to work.
3190
3191 In a more complex server farm environment where you may have your
3192 frontend proxy server(s) on different machines, you will need to set a
3193 configuration option to tell Catalyst to read the proxied data from the
3194 headers.
3195
3196     MyApp->config(using_frontend_proxy => 1);
3197
3198 If you do not wish to use the proxy support at all, you may set:
3199
3200     MyApp->config(ignore_frontend_proxy => 0);
3201
3202 =head2 Note about psgi files
3203
3204 Note that if you supply your own .psgi file, calling
3205 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3206
3207 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3208 in your psgi, for example:
3209
3210     builder {
3211         enable "Plack::Middleware::ReverseProxy";
3212         MyApp->psgi_app
3213     };
3214
3215 This will unconditionally add the ReverseProxy support, or you need to call
3216 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3217 apply the support depending upon your config).
3218
3219 See L<Catalyst::PSGI> for more information.
3220
3221 =head1 THREAD SAFETY
3222
3223 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3224 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3225 believe the Catalyst core to be thread-safe.
3226
3227 If you plan to operate in a threaded environment, remember that all other
3228 modules you are using must also be thread-safe. Some modules, most notably
3229 L<DBD::SQLite>, are not thread-safe.
3230
3231 =head1 SUPPORT
3232
3233 IRC:
3234
3235     Join #catalyst on irc.perl.org.
3236
3237 Mailing Lists:
3238
3239     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3240     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3241
3242 Web:
3243
3244     http://catalyst.perl.org
3245
3246 Wiki:
3247
3248     http://dev.catalyst.perl.org
3249
3250 =head1 SEE ALSO
3251
3252 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3253
3254 =head2 L<Catalyst::Manual> - The Catalyst Manual
3255
3256 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3257
3258 =head2 L<Catalyst::Engine> - Core engine
3259
3260 =head2 L<Catalyst::Log> - Log class.
3261
3262 =head2 L<Catalyst::Request> - Request object
3263
3264 =head2 L<Catalyst::Response> - Response object
3265
3266 =head2 L<Catalyst::Test> - The test suite.
3267
3268 =head1 PROJECT FOUNDER
3269
3270 sri: Sebastian Riedel <sri@cpan.org>
3271
3272 =head1 CONTRIBUTORS
3273
3274 abw: Andy Wardley
3275
3276 acme: Leon Brocard <leon@astray.com>
3277
3278 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3279
3280 Andrew Bramble
3281
3282 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3283
3284 Andrew Ruthven
3285
3286 andyg: Andy Grundman <andy@hybridized.org>
3287
3288 audreyt: Audrey Tang
3289
3290 bricas: Brian Cassidy <bricas@cpan.org>
3291
3292 Caelum: Rafael Kitover <rkitover@io.com>
3293
3294 chansen: Christian Hansen
3295
3296 chicks: Christopher Hicks
3297
3298 Chisel Wright C<pause@herlpacker.co.uk>
3299
3300 Danijel Milicevic C<me@danijel.de>
3301
3302 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3303
3304 David Naughton, C<naughton@umn.edu>
3305
3306 David E. Wheeler
3307
3308 dhoss: Devin Austin <dhoss@cpan.org>
3309
3310 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3311
3312 Drew Taylor
3313
3314 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3315
3316 esskar: Sascha Kiefer
3317
3318 fireartist: Carl Franks <cfranks@cpan.org>
3319
3320 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3321
3322 gabb: Danijel Milicevic
3323
3324 Gary Ashton Jones
3325
3326 Gavin Henry C<ghenry@perl.me.uk>
3327
3328 Geoff Richards
3329
3330 groditi: Guillermo Roditi <groditi@gmail.com>
3331
3332 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3333
3334 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3335
3336 jcamacho: Juan Camacho
3337
3338 jester: Jesse Sheidlower C<jester@panix.com>
3339
3340 jhannah: Jay Hannah <jay@jays.net>
3341
3342 Jody Belka
3343
3344 Johan Lindstrom
3345
3346 jon: Jon Schutz <jjschutz@cpan.org>
3347
3348 Jonathan Rockway C<< <jrockway@cpan.org> >>
3349
3350 Kieren Diment C<kd@totaldatasolution.com>
3351
3352 konobi: Scott McWhirter <konobi@cpan.org>
3353
3354 marcus: Marcus Ramberg <mramberg@cpan.org>
3355
3356 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3357
3358 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3359
3360 mugwump: Sam Vilain
3361
3362 naughton: David Naughton
3363
3364 ningu: David Kamholz <dkamholz@cpan.org>
3365
3366 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3367
3368 numa: Dan Sully <daniel@cpan.org>
3369
3370 obra: Jesse Vincent
3371
3372 Octavian Rasnita
3373
3374 omega: Andreas Marienborg
3375
3376 Oleg Kostyuk <cub.uanic@gmail.com>
3377
3378 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3379
3380 rafl: Florian Ragwitz <rafl@debian.org>
3381
3382 random: Roland Lammel <lammel@cpan.org>
3383
3384 Robert Sedlacek C<< <rs@474.at> >>
3385
3386 SpiceMan: Marcel Montes
3387
3388 sky: Arthur Bergman
3389
3390 szbalint: Balint Szilakszi <szbalint@cpan.org>
3391
3392 t0m: Tomas Doran <bobtfish@bobtfish.net>
3393
3394 Ulf Edvinsson
3395
3396 Viljo Marrandi C<vilts@yahoo.com>
3397
3398 Will Hawes C<info@whawes.co.uk>
3399
3400 willert: Sebastian Willert <willert@cpan.org>
3401
3402 wreis: Wallace Reis <wallace@reis.org.br>
3403
3404 Yuval Kogman, C<nothingmuch@woobling.org>
3405
3406 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3407
3408 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3409
3410 =head1 COPYRIGHT
3411
3412 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3413
3414 =head1 LICENSE
3415
3416 This library is free software. You can redistribute it and/or modify it under
3417 the same terms as Perl itself.
3418
3419 =cut
3420
3421 no Moose;
3422
3423 __PACKAGE__->meta->make_immutable;
3424
3425 1;