lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Catalyst::Middleware::Stash;
  51 use Plack::Util;
  52 use Class::Load 'load_class';
  53 use Encode 2.21 'decode_utf8', 'encode_utf8';
  54
  55 BEGIN { require 5.008003; }
  56
  57 has stack => (is => 'ro', default => sub { [] });
  58 has state => (is => 'rw', default => 0);
  59 has stats => (is => 'rw');
  60 has action => (is => 'rw');
  61 has counter => (is => 'rw', default => sub { {} });
  62 has request => (
  63     is => 'rw',
  64     default => sub {
  65         my $self = shift;
  66         my $class = ref $self;
  67         my $composed_request_class = $class->composed_request_class;
  68         return $composed_request_class->new( $self->_build_request_constructor_args);
  69     },
  70     lazy => 1,
  71 );
  72 sub _build_request_constructor_args {
  73     my $self = shift;
  74     my %p = ( _log => $self->log );
  75     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  76     $p{data_handlers} = {$self->registered_data_handlers};
  77     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  78       if $self->config->{use_hash_multivalue_in_request};
  79     \%p;
  80 }
  81
  82 sub composed_request_class {
  83   my $class = shift;
  84   my @traits = (@{$class->request_class_traits||[]}, @{$class->config->{request_class_traits}||[]});
  85
  86   # For each trait listed, figure out what the namespace is.  First we try the $trait
  87   # as it is in the config.  Then try $MyApp::TraitFor::Request:$trait. Last we try
  88   # Catalyst::TraitFor::Request::$trait.  If none load, throw error.
  89
  90   my $trait_ns = 'TraitFor::Request';
  91   my @normalized_traits = map {
  92     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
  93   } @traits;
  94
  95   return $class->_composed_request_class ||
  96     $class->_composed_request_class(Moose::Util::with_traits($class->request_class, @normalized_traits));
  97 }
  98
  99 has response => (
 100     is => 'rw',
 101     default => sub {
 102         my $self = shift;
 103         my $class = ref $self;
 104         my $composed_response_class = $class->composed_response_class;
 105         return $composed_response_class->new( $self->_build_response_constructor_args);
 106     },
 107     lazy => 1,
 108 );
 109 sub _build_response_constructor_args {
 110     return +{
 111       _log => $_[0]->log,
 112       encoding => $_[0]->encoding,
 113     };
 114 }
 115
 116 sub composed_response_class {
 117   my $class = shift;
 118   my @traits = (@{$class->response_class_traits||[]}, @{$class->config->{response_class_traits}||[]});
 119
 120   my $trait_ns = 'TraitFor::Response';
 121   my @normalized_traits = map {
 122     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 123   } @traits;
 124
 125   return $class->_composed_response_class ||
 126     $class->_composed_response_class(Moose::Util::with_traits($class->response_class, @normalized_traits));
 127 }
 128
 129 has namespace => (is => 'rw');
 130
 131 sub depth { scalar @{ shift->stack || [] }; }
 132 sub comp { shift->component(@_) }
 133
 134 sub req {
 135     my $self = shift; return $self->request(@_);
 136 }
 137 sub res {
 138     my $self = shift; return $self->response(@_);
 139 }
 140
 141 # For backwards compatibility
 142 sub finalize_output { shift->finalize_body(@_) };
 143
 144 # For statistics
 145 our $COUNT     = 1;
 146 our $START     = time;
 147 our $RECURSION = 1000;
 148 our $DETACH    = Catalyst::Exception::Detach->new;
 149 our $GO        = Catalyst::Exception::Go->new;
 150
 151 #I imagine that very few of these really
 152 #need to be class variables. if any.
 153 #maybe we should just make them attributes with a default?
 154 __PACKAGE__->mk_classdata($_)
 155   for qw/components arguments dispatcher engine log dispatcher_class
 156   engine_loader context_class request_class response_class stats_class
 157   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 158   _data_handlers _encoding _encode_check finalized_default_middleware
 159   request_class_traits response_class_traits stats_class_traits
 160   _composed_request_class _composed_response_class _composed_stats_class/;
 161
 162 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 163 __PACKAGE__->request_class('Catalyst::Request');
 164 __PACKAGE__->response_class('Catalyst::Response');
 165 __PACKAGE__->stats_class('Catalyst::Stats');
 166
 167 sub composed_stats_class {
 168   my $class = shift;
 169   my @traits = (@{$class->stats_class_traits||[]}, @{$class->config->{stats_class_traits}||[]});
 170
 171   my $trait_ns = 'TraitFor::Stats';
 172   my @normalized_traits = map {
 173     Class::Load::load_first_existing_class($_, $class.'::'.$trait_ns.'::'. $_, 'Catalyst::'.$trait_ns.'::'.$_)
 174   } @traits;
 175
 176   return $class->_composed_stats_class ||
 177     $class->_composed_stats_class(Moose::Util::with_traits($class->stats_class, @normalized_traits));
 178 }
 179
 180 __PACKAGE__->_encode_check(Encode::FB_CROAK | Encode::LEAVE_SRC);
 181
 182 # Remember to update this in Catalyst::Runtime as well!
 183 our $VERSION = '5.90092';
 184 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
 185
 186 sub import {
 187     my ( $class, @arguments ) = @_;
 188
 189     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 190     # callers @ISA.
 191     return unless $class eq 'Catalyst';
 192
 193     my $caller = caller();
 194     return if $caller eq 'main';
 195
 196     my $meta = Moose::Meta::Class->initialize($caller);
 197     unless ( $caller->isa('Catalyst') ) {
 198         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 199         $meta->superclasses(@superclasses);
 200     }
 201     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 202     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 203
 204     unless( $meta->has_method('meta') ){
 205         if ($Moose::VERSION >= 1.15) {
 206             $meta->_add_meta_method('meta');
 207         }
 208         else {
 209             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 210         }
 211     }
 212
 213     $caller->arguments( [@arguments] );
 214     $caller->setup_home;
 215 }
 216
 217 sub _application { $_[0] }
 218
 219 =encoding UTF-8
 220
 221 =head1 NAME
 222
 223 Catalyst - The Elegant MVC Web Application Framework
 224
 225 =for html
 226 <a href="https://badge.fury.io/pl/Catalyst-Runtime"><img src="https://badge.fury.io/pl/Catalyst-Runtime.svg" alt="CPAN version" height="18"></a>
 227 <a href="https://travis-ci.org/perl-catalyst/catalyst-runtime/"><img src="https://api.travis-ci.org/perl-catalyst/catalyst-runtime.png" alt="Catalyst></a>
 228 <a href="http://cpants.cpanauthors.org/dist/Catalyst-Runtime"><img src="http://cpants.cpanauthors.org/dist/Catalyst-Runtime.png" alt='Kwalitee Score' /></a>
 229
 230 =head1 SYNOPSIS
 231
 232 See the L<Catalyst::Manual> distribution for comprehensive
 233 documentation and tutorials.
 234
 235     # Install Catalyst::Devel for helpers and other development tools
 236     # use the helper to create a new application
 237     catalyst.pl MyApp
 238
 239     # add models, views, controllers
 240     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 241     script/myapp_create.pl view MyTemplate TT
 242     script/myapp_create.pl controller Search
 243
 244     # built in testserver -- use -r to restart automatically on changes
 245     # --help to see all available options
 246     script/myapp_server.pl
 247
 248     # command line testing interface
 249     script/myapp_test.pl /yada
 250
 251     ### in lib/MyApp.pm
 252     use Catalyst qw/-Debug/; # include plugins here as well
 253
 254     ### In lib/MyApp/Controller/Root.pm (autocreated)
 255     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 256         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 257         $c->stash->{template} = 'foo.tt'; # set the template
 258         # lookup something from db -- stash vars are passed to TT
 259         $c->stash->{data} =
 260           $c->model('Database::Foo')->search( { country => $args[0] } );
 261         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 262             $c->forward( 'bar' ); # process another action
 263             # do something else after forward returns
 264         }
 265     }
 266
 267     # The foo.tt TT template can use the stash data from the database
 268     [% WHILE (item = data.next) %]
 269         [% item.foo %]
 270     [% END %]
 271
 272     # called for /bar/of/soap, /bar/of/soap/10, etc.
 273     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 274
 275     # called after all actions are finished
 276     sub end : Action {
 277         my ( $self, $c ) = @_;
 278         if ( scalar @{ $c->error } ) { ... } # handle errors
 279         return if $c->res->body; # already have a response
 280         $c->forward( 'MyApp::View::TT' ); # render template
 281     }
 282
 283 See L<Catalyst::Manual::Intro> for additional information.
 284
 285 =head1 DESCRIPTION
 286
 287 Catalyst is a modern framework for making web applications without the
 288 pain usually associated with this process. This document is a reference
 289 to the main Catalyst application. If you are a new user, we suggest you
 290 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 291
 292 See L<Catalyst::Manual> for more documentation.
 293
 294 Catalyst plugins can be loaded by naming them as arguments to the "use
 295 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 296 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 297 C<My::Module>.
 298
 299     use Catalyst qw/My::Module/;
 300
 301 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 302 fully qualify the name by using a unary plus:
 303
 304     use Catalyst qw/
 305         My::Module
 306         +Fully::Qualified::Plugin::Name
 307     /;
 308
 309 Special flags like C<-Debug> can also be specified as
 310 arguments when Catalyst is loaded:
 311
 312     use Catalyst qw/-Debug My::Module/;
 313
 314 The position of plugins and flags in the chain is important, because
 315 they are loaded in the order in which they appear.
 316
 317 The following flags are supported:
 318
 319 =head2 -Debug
 320
 321 Enables debug output. You can also force this setting from the system
 322 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 323 settings override the application, with <MYAPP>_DEBUG having the highest
 324 priority.
 325
 326 This sets the log level to 'debug' and enables full debug output on the
 327 error screen. If you only want the latter, see L<< $c->debug >>.
 328
 329 =head2 -Home
 330
 331 Forces Catalyst to use a specific home directory, e.g.:
 332
 333     use Catalyst qw[-Home=/usr/mst];
 334
 335 This can also be done in the shell environment by setting either the
 336 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 337 is replaced with the uppercased name of your application, any "::" in
 338 the name will be replaced with underscores, e.g. MyApp::Web should use
 339 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 340
 341 If none of these are set, Catalyst will attempt to automatically detect the
 342 home directory. If you are working in a development environment, Catalyst
 343 will try and find the directory containing either Makefile.PL, Build.PL,
 344 dist.ini, or cpanfile. If the application has been installed into the system
 345 (i.e. you have done C<make install>), then Catalyst will use the path to your
 346 application module, without the .pm extension (e.g., /foo/MyApp if your
 347 application was installed at /foo/MyApp.pm)
 348
 349 =head2 -Log
 350
 351     use Catalyst '-Log=warn,fatal,error';
 352
 353 Specifies a comma-delimited list of log levels.
 354
 355 =head2 -Stats
 356
 357 Enables statistics collection and reporting.
 358
 359    use Catalyst qw/-Stats=1/;
 360
 361 You can also force this setting from the system environment with CATALYST_STATS
 362 or <MYAPP>_STATS. The environment settings override the application, with
 363 <MYAPP>_STATS having the highest priority.
 364
 365 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 366
 367 =head1 METHODS
 368
 369 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 370
 371 =head2 $c->action
 372
 373 Returns a L<Catalyst::Action> object for the current action, which
 374 stringifies to the action name. See L<Catalyst::Action>.
 375
 376 =head2 $c->namespace
 377
 378 Returns the namespace of the current action, i.e., the URI prefix
 379 corresponding to the controller of the current action. For example:
 380
 381     # in Controller::Foo::Bar
 382     $c->namespace; # returns 'foo/bar';
 383
 384 =head2 $c->request
 385
 386 =head2 $c->req
 387
 388 Returns the current L<Catalyst::Request> object, giving access to
 389 information about the current client request (including parameters,
 390 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 391
 392 =head2 REQUEST FLOW HANDLING
 393
 394 =head2 $c->forward( $action [, \@arguments ] )
 395
 396 =head2 $c->forward( $class, $method, [, \@arguments ] )
 397
 398 This is one way of calling another action (method) in the same or
 399 a different controller. You can also use C<< $self->my_method($c, @args) >>
 400 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 401 in a different controller.
 402 The main difference is that 'forward' uses some of the Catalyst request
 403 cycle overhead, including debugging, which may be useful to you. On the
 404 other hand, there are some complications to using 'forward', restrictions
 405 on values returned from 'forward', and it may not handle errors as you prefer.
 406 Whether you use 'forward' or not is up to you; it is not considered superior to
 407 the other ways to call a method.
 408
 409 'forward' calls  another action, by its private name. If you give a
 410 class name but no method, C<process()> is called. You may also optionally
 411 pass arguments in an arrayref. The action will receive the arguments in
 412 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 413 C<< $c->req->args >> will be restored to the previous values.
 414
 415 Any data C<return>ed from the action forwarded to, will be returned by the
 416 call to forward.
 417
 418     my $foodata = $c->forward('/foo');
 419     $c->forward('index');
 420     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 421     $c->forward('View::TT');
 422
 423 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 424 an C<< eval { } >> around the call (actually
 425 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 426 exceptions thrown by the called action non-fatal and pushing them onto
 427 $c->error instead. If you want C<die> to propagate you need to do something
 428 like:
 429
 430     $c->forward('foo');
 431     die join "\n", @{ $c->error } if @{ $c->error };
 432
 433 Or make sure to always return true values from your actions and write
 434 your code like this:
 435
 436     $c->forward('foo') || return;
 437
 438 Another note is that C<< $c->forward >> always returns a scalar because it
 439 actually returns $c->state which operates in a scalar context.
 440 Thus, something like:
 441
 442     return @array;
 443
 444 in an action that is forwarded to is going to return a scalar,
 445 i.e. how many items are in that array, which is probably not what you want.
 446 If you need to return an array then return a reference to it,
 447 or stash it like so:
 448
 449     $c->stash->{array} = \@array;
 450
 451 and access it from the stash.
 452
 453 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 454
 455 =cut
 456
 457 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 458
 459 =head2 $c->detach( $action [, \@arguments ] )
 460
 461 =head2 $c->detach( $class, $method, [, \@arguments ] )
 462
 463 =head2 $c->detach()
 464
 465 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 466 doesn't return to the previous action when processing is finished.
 467
 468 When called with no arguments it escapes the processing chain entirely.
 469
 470 =cut
 471
 472 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 473
 474 =head2 $c->visit( $action [, \@arguments ] )
 475
 476 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 477
 478 =head2 $c->visit( $class, $method, [, \@arguments ] )
 479
 480 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 481
 482 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 483 but does a full dispatch, instead of just calling the new C<$action> /
 484 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 485 you go to are called, just like a new request.
 486
 487 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 488 This means, for example, that C<< $c->action >> methods such as
 489 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 490 L<reverse|Catalyst::Action/reverse> return information for the visited action
 491 when they are invoked within the visited action.  This is different from the
 492 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 493 continues to use the $c->action object from the caller action even when
 494 invoked from the called action.
 495
 496 C<< $c->stash >> is kept unchanged.
 497
 498 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 499 allows you to "wrap" another action, just as it would have been called by
 500 dispatching from a URL, while the analogous
 501 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 502 transfer control to another action as if it had been reached directly from a URL.
 503
 504 =cut
 505
 506 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 507
 508 =head2 $c->go( $action [, \@arguments ] )
 509
 510 =head2 $c->go( $action [, \@captures, \@arguments ] )
 511
 512 =head2 $c->go( $class, $method, [, \@arguments ] )
 513
 514 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 515
 516 The relationship between C<go> and
 517 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 518 the relationship between
 519 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 520 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 521 C<< $c->go >> will perform a full dispatch on the specified action or method,
 522 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 523 C<go> escapes the processing of the current request chain on completion, and
 524 does not return to its cunless blessed $cunless blessed $caller.
 525
 526 @arguments are arguments to the final destination of $action. @captures are
 527 arguments to the intermediate steps, if any, on the way to the final sub of
 528 $action.
 529
 530 =cut
 531
 532 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 533
 534 =head2 $c->response
 535
 536 =head2 $c->res
 537
 538 Returns the current L<Catalyst::Response> object, see there for details.
 539
 540 =head2 $c->stash
 541
 542 Returns a hashref to the stash, which may be used to store data and pass
 543 it between components during a request. You can also set hash keys by
 544 passing arguments. The stash is automatically sent to the view. The
 545 stash is cleared at the end of a request; it cannot be used for
 546 persistent storage (for this you must use a session; see
 547 L<Catalyst::Plugin::Session> for a complete system integrated with
 548 Catalyst).
 549
 550     $c->stash->{foo} = $bar;
 551     $c->stash( { moose => 'majestic', qux => 0 } );
 552     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 553
 554     # stash is automatically passed to the view for use in a template
 555     $c->forward( 'MyApp::View::TT' );
 556
 557 The stash hash is currently stored in the PSGI C<$env> and is managed by
 558 L<Catalyst::Middleware::Stash>.  Since it's part of the C<$env> items in
 559 the stash can be accessed in sub applications mounted under your main
 560 L<Catalyst> application.  For example if you delegate the response of an
 561 action to another L<Catalyst> application, that sub application will have
 562 access to all the stash keys of the main one, and if can of course add
 563 more keys of its own.  However those new keys will not 'bubble' back up
 564 to the main application.
 565
 566 For more information the best thing to do is to review the test case:
 567 t/middleware-stash.t in the distribution /t directory.
 568
 569 =cut
 570
 571 sub stash {
 572   my $c = shift;
 573   $c->log->error("You are requesting the stash but you don't have a context") unless blessed $c;
 574   return Catalyst::Middleware::Stash::get_stash($c->req->env)->(@_);
 575 }
 576
 577 =head2 $c->error
 578
 579 =head2 $c->error($error, ...)
 580
 581 =head2 $c->error($arrayref)
 582
 583 Returns an arrayref containing error messages.  If Catalyst encounters an
 584 error while processing a request, it stores the error in $c->error.  This
 585 method should only be used to store fatal error messages.
 586
 587     my @error = @{ $c->error };
 588
 589 Add a new error.
 590
 591     $c->error('Something bad happened');
 592
 593 Calling this will always return an arrayref (if there are no errors it
 594 will be an empty arrayref.
 595
 596 =cut
 597
 598 sub error {
 599     my $c = shift;
 600     if ( $_[0] ) {
 601         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 602         croak @$error unless ref $c;
 603         push @{ $c->{error} }, @$error;
 604     }
 605     elsif ( defined $_[0] ) { $c->{error} = undef }
 606     return $c->{error} || [];
 607 }
 608
 609
 610 =head2 $c->state
 611
 612 Contains the return value of the last executed action.
 613 Note that << $c->state >> operates in a scalar context which means that all
 614 values it returns are scalar.
 615
 616 =head2 $c->clear_errors
 617
 618 Clear errors.  You probably don't want to clear the errors unless you are
 619 implementing a custom error screen.
 620
 621 This is equivalent to running
 622
 623     $c->error(0);
 624
 625 =cut
 626
 627 sub clear_errors {
 628     my $c = shift;
 629     $c->error(0);
 630 }
 631
 632 =head2 $c->has_errors
 633
 634 Returns true if you have errors
 635
 636 =cut
 637
 638 sub has_errors { scalar(@{shift->error}) ? 1:0 }
 639
 640 =head2 $c->last_error
 641
 642 Returns the most recent error in the stack (the one most recently added...)
 643 or nothing if there are no errors.
 644
 645 =cut
 646
 647 sub last_error { my ($err, @errs) = @{shift->error}; return $err }
 648
 649 =head2 shift_errors
 650
 651 shifts the most recently added error off the error stack and returns if.  Returns
 652 nothing if there are no more errors.
 653
 654 =cut
 655
 656 sub shift_errors {
 657     my ($self) = @_;
 658     my ($err, @errors) = @{$self->error};
 659     $self->{error} = \@errors;
 660     return $err;
 661 }
 662
 663 sub _comp_search_prefixes {
 664     my $c = shift;
 665     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 666 }
 667
 668 # search components given a name and some prefixes
 669 sub _comp_names_search_prefixes {
 670     my ( $c, $name, @prefixes ) = @_;
 671     my $appclass = ref $c || $c;
 672     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 673     $filter = qr/$filter/; # Compile regex now rather than once per loop
 674
 675     # map the original component name to the sub part that we will search against
 676     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 677         grep { /$filter/ } keys %{ $c->components };
 678
 679     # undef for a name will return all
 680     return keys %eligible if !defined $name;
 681
 682     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 683     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 684
 685     return @result if @result;
 686
 687     # if we were given a regexp to search against, we're done.
 688     return if $name->$_isa('Regexp');
 689
 690     # skip regexp fallback if configured
 691     return
 692         if $appclass->config->{disable_component_resolution_regex_fallback};
 693
 694     # regexp fallback
 695     $query  = qr/$name/i;
 696     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 697
 698     # no results? try against full names
 699     if( !@result ) {
 700         @result = grep { m{$query} } keys %eligible;
 701     }
 702
 703     # don't warn if we didn't find any results, it just might not exist
 704     if( @result ) {
 705         # Disgusting hack to work out correct method name
 706         my $warn_for = lc $prefixes[0];
 707         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 708            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 709            "component resolution is unreliable and unsafe.";
 710         my $short = $result[0];
 711         # remove the component namespace prefix
 712         $short =~ s/.*?(Model|Controller|View):://;
 713         my $shortmess = Carp::shortmess('');
 714         if ($shortmess =~ m#Catalyst/Plugin#) {
 715            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 716               "plugin's config";
 717         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 718            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 719               "component's config";
 720         } else {
 721            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 722               "but if you really wanted to search, pass in a regexp as the argument " .
 723               "like so: \$c->${warn_for}(qr/${name}/)";
 724         }
 725         $c->log->warn( "${msg}$shortmess" );
 726     }
 727
 728     return @result;
 729 }
 730
 731 # Find possible names for a prefix
 732 sub _comp_names {
 733     my ( $c, @prefixes ) = @_;
 734     my $appclass = ref $c || $c;
 735
 736     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 737
 738     my @names = map { s{$filter}{}; $_; }
 739         $c->_comp_names_search_prefixes( undef, @prefixes );
 740
 741     return @names;
 742 }
 743
 744 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 745
 746 sub _filter_component {
 747     my ( $c, $comp, @args ) = @_;
 748
 749     if(ref $comp eq 'CODE') {
 750       $comp = $comp->();
 751     }
 752
 753     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 754       return $comp->ACCEPT_CONTEXT( $c, @args );
 755     }
 756
 757     $c->log->warn("You called component '${\$comp->catalyst_component_name}' with arguments [@args], but this component does not ACCEPT_CONTEXT, so args are ignored.") if scalar(@args) && $c->debug;
 758
 759     return $comp;
 760 }
 761
 762 =head2 COMPONENT ACCESSORS
 763
 764 =head2 $c->controller($name)
 765
 766 Gets a L<Catalyst::Controller> instance by name.
 767
 768     $c->controller('Foo')->do_stuff;
 769
 770 If the name is omitted, will return the controller for the dispatched
 771 action.
 772
 773 If you want to search for controllers, pass in a regexp as the argument.
 774
 775     # find all controllers that start with Foo
 776     my @foo_controllers = $c->controller(qr{^Foo});
 777
 778
 779 =cut
 780
 781 sub controller {
 782     my ( $c, $name, @args ) = @_;
 783
 784     my $appclass = ref($c) || $c;
 785     if( $name ) {
 786         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 787             my $comps = $c->components;
 788             my $check = $appclass."::Controller::".$name;
 789             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 790         }
 791         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 792         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 793         return $c->_filter_component( $result[ 0 ], @args );
 794     }
 795
 796     return $c->component( $c->action->class );
 797 }
 798
 799 =head2 $c->model($name)
 800
 801 Gets a L<Catalyst::Model> instance by name.
 802
 803     $c->model('Foo')->do_stuff;
 804
 805 Any extra arguments are directly passed to ACCEPT_CONTEXT, if the model
 806 defines ACCEPT_CONTEXT.  If it does not, the args are discarded.
 807
 808 If the name is omitted, it will look for
 809  - a model object in $c->stash->{current_model_instance}, then
 810  - a model name in $c->stash->{current_model}, then
 811  - a config setting 'default_model', or
 812  - check if there is only one model, and return it if that's the case.
 813
 814 If you want to search for models, pass in a regexp as the argument.
 815
 816     # find all models that start with Foo
 817     my @foo_models = $c->model(qr{^Foo});
 818
 819 =cut
 820
 821 sub model {
 822     my ( $c, $name, @args ) = @_;
 823     my $appclass = ref($c) || $c;
 824     if( $name ) {
 825         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 826             my $comps = $c->components;
 827             my $check = $appclass."::Model::".$name;
 828             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 829         }
 830         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 831         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 832         return $c->_filter_component( $result[ 0 ], @args );
 833     }
 834
 835     if (ref $c) {
 836         return $c->stash->{current_model_instance}
 837           if $c->stash->{current_model_instance};
 838         return $c->model( $c->stash->{current_model} )
 839           if $c->stash->{current_model};
 840     }
 841     return $c->model( $appclass->config->{default_model} )
 842       if $appclass->config->{default_model};
 843
 844     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 845
 846     if( $rest ) {
 847         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 848         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 849         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 850         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 851         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 852     }
 853
 854     return $c->_filter_component( $comp );
 855 }
 856
 857
 858 =head2 $c->view($name)
 859
 860 Gets a L<Catalyst::View> instance by name.
 861
 862     $c->view('Foo')->do_stuff;
 863
 864 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 865
 866 If the name is omitted, it will look for
 867  - a view object in $c->stash->{current_view_instance}, then
 868  - a view name in $c->stash->{current_view}, then
 869  - a config setting 'default_view', or
 870  - check if there is only one view, and return it if that's the case.
 871
 872 If you want to search for views, pass in a regexp as the argument.
 873
 874     # find all views that start with Foo
 875     my @foo_views = $c->view(qr{^Foo});
 876
 877 =cut
 878
 879 sub view {
 880     my ( $c, $name, @args ) = @_;
 881
 882     my $appclass = ref($c) || $c;
 883     if( $name ) {
 884         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 885             my $comps = $c->components;
 886             my $check = $appclass."::View::".$name;
 887             if( exists $comps->{$check} ) {
 888                 return $c->_filter_component( $comps->{$check}, @args );
 889             }
 890             else {
 891                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 892             }
 893         }
 894         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 895         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 896         return $c->_filter_component( $result[ 0 ], @args );
 897     }
 898
 899     if (ref $c) {
 900         return $c->stash->{current_view_instance}
 901           if $c->stash->{current_view_instance};
 902         return $c->view( $c->stash->{current_view} )
 903           if $c->stash->{current_view};
 904     }
 905     return $c->view( $appclass->config->{default_view} )
 906       if $appclass->config->{default_view};
 907
 908     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 909
 910     if( $rest ) {
 911         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 912         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 913         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 914         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 915         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 916     }
 917
 918     return $c->_filter_component( $comp );
 919 }
 920
 921 =head2 $c->controllers
 922
 923 Returns the available names which can be passed to $c->controller
 924
 925 =cut
 926
 927 sub controllers {
 928     my ( $c ) = @_;
 929     return $c->_comp_names(qw/Controller C/);
 930 }
 931
 932 =head2 $c->models
 933
 934 Returns the available names which can be passed to $c->model
 935
 936 =cut
 937
 938 sub models {
 939     my ( $c ) = @_;
 940     return $c->_comp_names(qw/Model M/);
 941 }
 942
 943
 944 =head2 $c->views
 945
 946 Returns the available names which can be passed to $c->view
 947
 948 =cut
 949
 950 sub views {
 951     my ( $c ) = @_;
 952     return $c->_comp_names(qw/View V/);
 953 }
 954
 955 =head2 $c->comp($name)
 956
 957 =head2 $c->component($name)
 958
 959 Gets a component object by name. This method is not recommended,
 960 unless you want to get a specific component by full
 961 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 962 should be used instead.
 963
 964 If C<$name> is a regexp, a list of components matched against the full
 965 component name will be returned.
 966
 967 If Catalyst can't find a component by name, it will fallback to regex
 968 matching by default. To disable this behaviour set
 969 disable_component_resolution_regex_fallback to a true value.
 970
 971     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 972
 973 =cut
 974
 975 sub component {
 976     my ( $c, $name, @args ) = @_;
 977
 978     if( $name ) {
 979         my $comps = $c->components;
 980
 981         if( !ref $name ) {
 982             # is it the exact name?
 983             return $c->_filter_component( $comps->{ $name }, @args )
 984                        if exists $comps->{ $name };
 985
 986             # perhaps we just omitted "MyApp"?
 987             my $composed = ( ref $c || $c ) . "::${name}";
 988             return $c->_filter_component( $comps->{ $composed }, @args )
 989                        if exists $comps->{ $composed };
 990
 991             # search all of the models, views and controllers
 992             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 993             return $c->_filter_component( $comp, @args ) if $comp;
 994         }
 995
 996         return
 997             if $c->config->{disable_component_resolution_regex_fallback};
 998
 999         # This is here so $c->comp( '::M::' ) works
1000         my $query = ref $name ? $name : qr{$name}i;
1001
1002         my @result = grep { m{$query} } keys %{ $c->components };
1003         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
1004
1005         if( $result[ 0 ] ) {
1006             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
1007             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
1008             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
1009             return $c->_filter_component( $result[ 0 ], @args );
1010         }
1011
1012         # I would expect to return an empty list here, but that breaks back-compat
1013     }
1014
1015     # fallback
1016     return sort keys %{ $c->components };
1017 }
1018
1019 =head2 CLASS DATA AND HELPER CLASSES
1020
1021 =head2 $c->config
1022
1023 Returns or takes a hashref containing the application's configuration.
1024
1025     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
1026
1027 You can also use a C<YAML>, C<XML> or L<Config::General> config file
1028 like C<myapp.conf> in your applications home directory. See
1029 L<Catalyst::Plugin::ConfigLoader>.
1030
1031 =head3 Cascading configuration
1032
1033 The config method is present on all Catalyst components, and configuration
1034 will be merged when an application is started. Configuration loaded with
1035 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
1036 followed by configuration in your top level C<MyApp> class. These two
1037 configurations are merged, and then configuration data whose hash key matches a
1038 component name is merged with configuration for that component.
1039
1040 The configuration for a component is then passed to the C<new> method when a
1041 component is constructed.
1042
1043 For example:
1044
1045     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
1046     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
1047
1048 will mean that C<MyApp::Model::Foo> receives the following data when
1049 constructed:
1050
1051     MyApp::Model::Foo->new({
1052         bar => 'baz',
1053         quux => 'frob',
1054         overrides => 'me',
1055     });
1056
1057 It's common practice to use a Moose attribute
1058 on the receiving component to access the config value.
1059
1060     package MyApp::Model::Foo;
1061
1062     use Moose;
1063
1064     # this attr will receive 'baz' at construction time
1065     has 'bar' => (
1066         is  => 'rw',
1067         isa => 'Str',
1068     );
1069
1070 You can then get the value 'baz' by calling $c->model('Foo')->bar
1071 (or $self->bar inside code in the model).
1072
1073 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
1074 as a way of reading config within your code, as this B<will not> give you the
1075 correctly merged config back. You B<MUST> take the config values supplied to
1076 the constructor and use those instead.
1077
1078 =cut
1079
1080 around config => sub {
1081     my $orig = shift;
1082     my $c = shift;
1083
1084     croak('Setting config after setup has been run is not allowed.')
1085         if ( @_ and $c->setup_finished );
1086
1087     $c->$orig(@_);
1088 };
1089
1090 =head2 $c->log
1091
1092 Returns the logging object instance. Unless it is already set, Catalyst
1093 sets this up with a L<Catalyst::Log> object. To use your own log class,
1094 set the logger with the C<< __PACKAGE__->log >> method prior to calling
1095 C<< __PACKAGE__->setup >>.
1096
1097  __PACKAGE__->log( MyLogger->new );
1098  __PACKAGE__->setup;
1099
1100 And later:
1101
1102     $c->log->info( 'Now logging with my own logger!' );
1103
1104 Your log class should implement the methods described in
1105 L<Catalyst::Log>.
1106
1107 =head2 has_encoding
1108
1109 Returned True if there's a valid encoding
1110
1111 =head2 clear_encoding
1112
1113 Clears the encoding for the current context
1114
1115 =head2 encoding
1116
1117 Sets or gets the application encoding.  Setting encoding takes either an
1118 Encoding object or a string that we try to resolve via L<Encode::find_encoding>.
1119
1120 You would expect to get the encoding object back if you attempt to set it.  If
1121 there is a failure you will get undef returned and an error message in the log.
1122
1123 =cut
1124
1125 sub has_encoding { shift->encoding ? 1:0 }
1126
1127 sub clear_encoding {
1128     my $c = shift;
1129     if(blessed $c) {
1130         $c->encoding(undef);
1131     } else {
1132         $c->log->error("You can't clear encoding on the application");
1133     }
1134 }
1135
1136 sub encoding {
1137     my $c = shift;
1138     my $encoding;
1139
1140     if ( scalar @_ ) {
1141
1142         # Don't let one change this once we are too far into the response
1143         if(blessed $c && $c->res->finalized_headers) {
1144           Carp::croak("You may not change the encoding once the headers are finalized");
1145           return;
1146         }
1147
1148         # Let it be set to undef
1149         if (my $wanted = shift)  {
1150             $encoding = Encode::find_encoding($wanted)
1151               or Carp::croak( qq/Unknown encoding '$wanted'/ );
1152             binmode(STDERR, ':encoding(' . $encoding->name . ')');
1153         }
1154         else {
1155             binmode(STDERR);
1156         }
1157
1158         $encoding = ref $c
1159                   ? $c->{encoding} = $encoding
1160                   : $c->_encoding($encoding);
1161     } else {
1162       $encoding = ref $c && exists $c->{encoding}
1163                 ? $c->{encoding}
1164                 : $c->_encoding;
1165     }
1166
1167     return $encoding;
1168 }
1169
1170 =head2 $c->debug
1171
1172 Returns 1 if debug mode is enabled, 0 otherwise.
1173
1174 You can enable debug mode in several ways:
1175
1176 =over
1177
1178 =item By calling myapp_server.pl with the -d flag
1179
1180 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1181
1182 =item The -Debug option in your MyApp.pm
1183
1184 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1185
1186 =back
1187
1188 The first three also set the log level to 'debug'.
1189
1190 Calling C<< $c->debug(1) >> has no effect.
1191
1192 =cut
1193
1194 sub debug { 0 }
1195
1196 =head2 $c->dispatcher
1197
1198 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1199
1200 =head2 $c->engine
1201
1202 Returns the engine instance. See L<Catalyst::Engine>.
1203
1204
1205 =head2 UTILITY METHODS
1206
1207 =head2 $c->path_to(@path)
1208
1209 Merges C<@path> with C<< $c->config->{home} >> and returns a
1210 L<Path::Class::Dir> object. Note you can usually use this object as
1211 a filename, but sometimes you will have to explicitly stringify it
1212 yourself by calling the C<< ->stringify >> method.
1213
1214 For example:
1215
1216     $c->path_to( 'db', 'sqlite.db' );
1217
1218 =cut
1219
1220 sub path_to {
1221     my ( $c, @path ) = @_;
1222     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1223     if ( -d $path ) { return $path }
1224     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1225 }
1226
1227 sub plugin {
1228     my ( $class, $name, $plugin, @args ) = @_;
1229
1230     # See block comment in t/unit_core_plugin.t
1231     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1232
1233     $class->_register_plugin( $plugin, 1 );
1234
1235     eval { $plugin->import };
1236     $class->mk_classdata($name);
1237     my $obj;
1238     eval { $obj = $plugin->new(@args) };
1239
1240     if ($@) {
1241         Catalyst::Exception->throw( message =>
1242               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1243     }
1244
1245     $class->$name($obj);
1246     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1247       if $class->debug;
1248 }
1249
1250 =head2 MyApp->setup
1251
1252 Initializes the dispatcher and engine, loads any plugins, and loads the
1253 model, view, and controller components. You may also specify an array
1254 of plugins to load here, if you choose to not load them in the C<use
1255 Catalyst> line.
1256
1257     MyApp->setup;
1258     MyApp->setup( qw/-Debug/ );
1259
1260 B<Note:> You B<should not> wrap this method with method modifiers
1261 or bad things will happen - wrap the C<setup_finalize> method instead.
1262
1263 B<Note:> You can create a custom setup stage that will execute when the
1264 application is starting.  Use this to customize setup.
1265
1266     MyApp->setup(-Custom=value);
1267
1268     sub setup_custom {
1269       my ($class, $value) = @_;
1270     }
1271
1272 Can be handy if you want to hook into the setup phase.
1273
1274 =cut
1275
1276 sub setup {
1277     my ( $class, @arguments ) = @_;
1278     croak('Running setup more than once')
1279         if ( $class->setup_finished );
1280
1281     unless ( $class->isa('Catalyst') ) {
1282
1283         Catalyst::Exception->throw(
1284             message => qq/'$class' does not inherit from Catalyst/ );
1285     }
1286
1287     if ( $class->arguments ) {
1288         @arguments = ( @arguments, @{ $class->arguments } );
1289     }
1290
1291     # Process options
1292     my $flags = {};
1293
1294     foreach (@arguments) {
1295
1296         if (/^-Debug$/) {
1297             $flags->{log} =
1298               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1299         }
1300         elsif (/^-(\w+)=?(.*)$/) {
1301             $flags->{ lc $1 } = $2;
1302         }
1303         else {
1304             push @{ $flags->{plugins} }, $_;
1305         }
1306     }
1307
1308     $class->setup_home( delete $flags->{home} );
1309
1310     $class->setup_log( delete $flags->{log} );
1311     $class->setup_plugins( delete $flags->{plugins} );
1312
1313     $class->setup_data_handlers();
1314     $class->setup_dispatcher( delete $flags->{dispatcher} );
1315     if (my $engine = delete $flags->{engine}) {
1316         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1317     }
1318     $class->setup_engine();
1319     $class->setup_stats( delete $flags->{stats} );
1320
1321     for my $flag ( sort keys %{$flags} ) {
1322
1323         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1324             &$code( $class, delete $flags->{$flag} );
1325         }
1326         else {
1327             $class->log->warn(qq/Unknown flag "$flag"/);
1328         }
1329     }
1330
1331     eval { require Catalyst::Devel; };
1332     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1333         $class->log->warn(<<"EOF");
1334 You are running an old script!
1335
1336   Please update by running (this will overwrite existing files):
1337     catalyst.pl -force -scripts $class
1338
1339   or (this will not overwrite existing files):
1340     catalyst.pl -scripts $class
1341
1342 EOF
1343     }
1344
1345     # Call plugins setup, this is stupid and evil.
1346     # Also screws C3 badly on 5.10, hack to avoid.
1347     {
1348         no warnings qw/redefine/;
1349         local *setup = sub { };
1350         $class->setup unless $Catalyst::__AM_RESTARTING;
1351     }
1352
1353     # If you are expecting configuration info as part of your setup, it needs
1354     # to get called here and below, since we need the above line to support
1355     # ConfigLoader based configs.
1356
1357     $class->setup_encoding();
1358     $class->setup_middleware();
1359
1360     # Initialize our data structure
1361     $class->components( {} );
1362
1363     $class->setup_components;
1364
1365     if ( $class->debug ) {
1366         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1367
1368         if (@plugins) {
1369             my $column_width = Catalyst::Utils::term_width() - 6;
1370             my $t = Text::SimpleTable->new($column_width);
1371             $t->row($_) for @plugins;
1372             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1373         }
1374
1375         my @middleware = map {
1376           ref $_ eq 'CODE' ?
1377             "Inline Coderef" :
1378               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1379                 || '')  } $class->registered_middlewares;
1380
1381         if (@middleware) {
1382             my $column_width = Catalyst::Utils::term_width() - 6;
1383             my $t = Text::SimpleTable->new($column_width);
1384             $t->row($_) for @middleware;
1385             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1386         }
1387
1388         my %dh = $class->registered_data_handlers;
1389         if (my @data_handlers = keys %dh) {
1390             my $column_width = Catalyst::Utils::term_width() - 6;
1391             my $t = Text::SimpleTable->new($column_width);
1392             $t->row($_) for @data_handlers;
1393             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1394         }
1395
1396         my $dispatcher = $class->dispatcher;
1397         my $engine     = $class->engine;
1398         my $home       = $class->config->{home};
1399
1400         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1401         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1402
1403         $home
1404           ? ( -d $home )
1405           ? $class->log->debug(qq/Found home "$home"/)
1406           : $class->log->debug(qq/Home "$home" doesn't exist/)
1407           : $class->log->debug(q/Couldn't find home/);
1408
1409         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1410
1411         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1412         for my $comp ( sort keys %{ $class->components } ) {
1413             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1414             $t->row( $comp, $type );
1415         }
1416         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1417           if ( keys %{ $class->components } );
1418     }
1419
1420     # Add our self to components, since we are also a component
1421     if( $class->isa('Catalyst::Controller') ){
1422       $class->components->{$class} = $class;
1423     }
1424
1425     $class->setup_actions;
1426
1427     if ( $class->debug ) {
1428         my $name = $class->config->{name} || 'Application';
1429         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1430     }
1431
1432     if ($class->config->{case_sensitive}) {
1433         $class->log->warn($class . "->config->{case_sensitive} is set.");
1434         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1435     }
1436
1437     $class->setup_finalize;
1438
1439     # Flush the log for good measure (in case something turned off 'autoflush' early)
1440     $class->log->_flush() if $class->log->can('_flush');
1441
1442     return $class || 1; # Just in case someone named their Application 0...
1443 }
1444
1445 =head2 $app->setup_finalize
1446
1447 A hook to attach modifiers to. This method does not do anything except set the
1448 C<setup_finished> accessor.
1449
1450 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1451
1452 Example:
1453
1454     after setup_finalize => sub {
1455         my $app = shift;
1456
1457         ## do stuff here..
1458     };
1459
1460 =cut
1461
1462 sub setup_finalize {
1463     my ($class) = @_;
1464     $class->setup_finished(1);
1465 }
1466
1467 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1468
1469 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1470
1471 =head2 $c->uri_for( $action, [@captures, @args], \%query_values? )
1472
1473 Constructs an absolute L<URI> object based on the application root, the
1474 provided path, and the additional arguments and query parameters provided.
1475 When used as a string, provides a textual URI.  If you need more flexibility
1476 than this (i.e. the option to provide relative URIs etc.) see
1477 L<Catalyst::Plugin::SmartURI>.
1478
1479 If no arguments are provided, the URI for the current action is returned.
1480 To return the current action and also provide @args, use
1481 C<< $c->uri_for( $c->action, @args ) >>.
1482
1483 If the first argument is a string, it is taken as a public URI path relative
1484 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1485 relative to the application root (if it does). It is then merged with
1486 C<< $c->request->base >>; any C<@args> are appended as additional path
1487 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1488
1489 If the first argument is a L<Catalyst::Action> it represents an action which
1490 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1491 optional C<\@captures> argument (an arrayref) allows passing the captured
1492 variables that are needed to fill in the paths of Chained and Regex actions;
1493 once the path is resolved, C<uri_for> continues as though a path was
1494 provided, appending any arguments or parameters and creating an absolute
1495 URI.
1496
1497 The captures for the current request can be found in
1498 C<< $c->request->captures >>, and actions can be resolved using
1499 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1500 path, use C<< $c->uri_for_action >> instead.
1501
1502   # Equivalent to $c->req->uri
1503   $c->uri_for($c->action, $c->req->captures,
1504       @{ $c->req->args }, $c->req->params);
1505
1506   # For the Foo action in the Bar controller
1507   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1508
1509   # Path to a static resource
1510   $c->uri_for('/static/images/logo.png');
1511
1512 In general the scheme of the generated URI object will follow the incoming request
1513 however if your targeted action or action chain has the Scheme attribute it will
1514 use that instead.
1515
1516 Also, if the targeted Action or Action chain declares Args/CaptureArgs that have
1517 type constraints, we will require that your proposed URL verify on those declared
1518 constraints.
1519
1520 =cut
1521
1522 sub uri_for {
1523     my ( $c, $path, @args ) = @_;
1524
1525     if ( $path->$_isa('Catalyst::Controller') ) {
1526         $path = $path->path_prefix;
1527         $path =~ s{/+\z}{};
1528         $path .= '/';
1529     }
1530
1531     undef($path) if (defined $path && $path eq '');
1532
1533     my $params =
1534       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1535
1536     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1537
1538     my $target_action = $path->$_isa('Catalyst::Action') ? $path : undef;
1539     if ( $path->$_isa('Catalyst::Action') ) { # action object
1540         s|/|%2F|g for @args;
1541         my $captures = [ map { s|/|%2F|g; $_; }
1542                         ( scalar @args && ref $args[0] eq 'ARRAY'
1543                          ? @{ shift(@args) }
1544                          : ()) ];
1545
1546         my $action = $path;
1547         my $expanded_action = $c->dispatcher->expand_action( $action );
1548         my $num_captures = $expanded_action->number_of_captures;
1549
1550         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1551         if( !@args && $action->number_of_args ) {
1552           unshift @args, splice @$captures, $num_captures;
1553         }
1554
1555         if($num_captures) {
1556           unless($expanded_action->match_captures_constraints($c, $captures)) {
1557             carp "captures [@{$captures}] do not match the type constraints in actionchain ending with '$expanded_action'";
1558             return;
1559           }
1560         }
1561
1562         $path = $c->dispatcher->uri_for_action($action, $captures);
1563         if (not defined $path) {
1564             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1565                 if $c->debug;
1566             return undef;
1567         }
1568         $path = '/' if $path eq '';
1569
1570         # At this point @encoded_args is the remaining Args (all captures removed).
1571         if($expanded_action->has_args_constraints) {
1572           unless($expanded_action->match_args($c,\@args)) {
1573              carp "args [@args] do not match the type constraints in action '$expanded_action'";
1574              return;
1575           }
1576         }
1577     }
1578
1579     unshift(@args, $path);
1580
1581     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1582         my $namespace = $c->namespace;
1583         if (defined $path) { # cheesy hack to handle path '../foo'
1584            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1585         }
1586         unshift(@args, $namespace || '');
1587     }
1588
1589     # join args with '/', or a blank string
1590     my $args = join('/', grep { defined($_) } @args);
1591     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1592     $args =~ s!^/+!!;
1593
1594     my ($base, $class) = ('/', 'URI::_generic');
1595     if(blessed($c)) {
1596       $base = $c->req->base;
1597       if($target_action) {
1598         $target_action = $c->dispatcher->expand_action($target_action);
1599         if(my $s = $target_action->scheme) {
1600           $s = lc($s);
1601           $class = "URI::$s";
1602           $base->scheme($s);
1603         } else {
1604           $class = ref($base);
1605         }
1606       } else {
1607         $class = ref($base);
1608       }
1609
1610       $base =~ s{(?<!/)$}{/};
1611     }
1612
1613     my $query = '';
1614
1615     if (my @keys = keys %$params) {
1616       # somewhat lifted from URI::_query's query_form
1617       $query = '?'.join('&', map {
1618           my $val = $params->{$_};
1619           #s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go; ## Commented out because seems to lead to double encoding - JNAP
1620           s/ /+/g;
1621           my $key = $_;
1622           $val = '' unless defined $val;
1623           (map {
1624               my $param = "$_";
1625               $param = encode_utf8($param);
1626               # using the URI::Escape pattern here so utf8 chars survive
1627               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1628               $param =~ s/ /+/g;
1629
1630               $key = encode_utf8($key);
1631               # using the URI::Escape pattern here so utf8 chars survive
1632               $key =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1633               $key =~ s/ /+/g;
1634
1635               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1636       } @keys);
1637     }
1638
1639     $base = encode_utf8 $base;
1640     $base =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1641     $args = encode_utf8 $args;
1642     $args =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1643
1644     my $res = bless(\"${base}${args}${query}", $class);
1645     $res;
1646 }
1647
1648 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1649
1650 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1651
1652 =over
1653
1654 =item $path
1655
1656 A private path to the Catalyst action you want to create a URI for.
1657
1658 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1659 >> and passing the resulting C<$action> and the remaining arguments to C<<
1660 $c->uri_for >>.
1661
1662 You can also pass in a Catalyst::Action object, in which case it is passed to
1663 C<< $c->uri_for >>.
1664
1665 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1666
1667 For example, if the action looks like:
1668
1669  package MyApp::Controller::Users;
1670
1671  sub lst : Path('the-list') {}
1672
1673 You can use:
1674
1675  $c->uri_for_action('/users/lst')
1676
1677 and it will create the URI /users/the-list.
1678
1679 =item \@captures_and_args?
1680
1681 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1682 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1683 to interpolate all the parameters in the URI.
1684
1685 =item @args?
1686
1687 Optional list of extra arguments - can be supplied in the
1688 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1689 code.
1690
1691 Your action can have zero, a fixed or a variable number of args (e.g.
1692 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1693
1694 =item \%query_values?
1695
1696 Optional array reference of query parameters to append. E.g.
1697
1698   { foo => 'bar' }
1699
1700 will generate
1701
1702   /rest/of/your/uri?foo=bar
1703
1704 =back
1705
1706 =cut
1707
1708 sub uri_for_action {
1709     my ( $c, $path, @args ) = @_;
1710     my $action = blessed($path)
1711       ? $path
1712       : $c->dispatcher->get_action_by_path($path);
1713     unless (defined $action) {
1714       croak "Can't find action for path '$path'";
1715     }
1716     return $c->uri_for( $action, @args );
1717 }
1718
1719 =head2 $c->welcome_message
1720
1721 Returns the Catalyst welcome HTML page.
1722
1723 =cut
1724
1725 sub welcome_message {
1726     my $c      = shift;
1727     my $name   = $c->config->{name};
1728     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1729     my $prefix = Catalyst::Utils::appprefix( ref $c );
1730     $c->response->content_type('text/html; charset=utf-8');
1731     return <<"EOF";
1732 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1733     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1734 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1735     <head>
1736     <meta http-equiv="Content-Language" content="en" />
1737     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1738         <title>$name on Catalyst $VERSION</title>
1739         <style type="text/css">
1740             body {
1741                 color: #000;
1742                 background-color: #eee;
1743             }
1744             div#content {
1745                 width: 640px;
1746                 margin-left: auto;
1747                 margin-right: auto;
1748                 margin-top: 10px;
1749                 margin-bottom: 10px;
1750                 text-align: left;
1751                 background-color: #ccc;
1752                 border: 1px solid #aaa;
1753             }
1754             p, h1, h2 {
1755                 margin-left: 20px;
1756                 margin-right: 20px;
1757                 font-family: verdana, tahoma, sans-serif;
1758             }
1759             a {
1760                 font-family: verdana, tahoma, sans-serif;
1761             }
1762             :link, :visited {
1763                     text-decoration: none;
1764                     color: #b00;
1765                     border-bottom: 1px dotted #bbb;
1766             }
1767             :link:hover, :visited:hover {
1768                     color: #555;
1769             }
1770             div#topbar {
1771                 margin: 0px;
1772             }
1773             pre {
1774                 margin: 10px;
1775                 padding: 8px;
1776             }
1777             div#answers {
1778                 padding: 8px;
1779                 margin: 10px;
1780                 background-color: #fff;
1781                 border: 1px solid #aaa;
1782             }
1783             h1 {
1784                 font-size: 0.9em;
1785                 font-weight: normal;
1786                 text-align: center;
1787             }
1788             h2 {
1789                 font-size: 1.0em;
1790             }
1791             p {
1792                 font-size: 0.9em;
1793             }
1794             p img {
1795                 float: right;
1796                 margin-left: 10px;
1797             }
1798             span#appname {
1799                 font-weight: bold;
1800                 font-size: 1.6em;
1801             }
1802         </style>
1803     </head>
1804     <body>
1805         <div id="content">
1806             <div id="topbar">
1807                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1808                     $VERSION</h1>
1809              </div>
1810              <div id="answers">
1811                  <p>
1812                  <img src="$logo" alt="Catalyst Logo" />
1813                  </p>
1814                  <p>Welcome to the  world of Catalyst.
1815                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1816                     framework will make web development something you had
1817                     never expected it to be: Fun, rewarding, and quick.</p>
1818                  <h2>What to do now?</h2>
1819                  <p>That really depends  on what <b>you</b> want to do.
1820                     We do, however, provide you with a few starting points.</p>
1821                  <p>If you want to jump right into web development with Catalyst
1822                     you might want to start with a tutorial.</p>
1823 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1824 </pre>
1825 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1826 <pre>
1827 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1828 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1829 </code></pre>
1830                  <h2>What to do next?</h2>
1831                  <p>Next it's time to write an actual application. Use the
1832                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1833                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1834                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1835                     they can save you a lot of work.</p>
1836                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1837                     <p>Also, be sure to check out the vast and growing
1838                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1839                     you are likely to find what you need there.
1840                     </p>
1841
1842                  <h2>Need help?</h2>
1843                  <p>Catalyst has a very active community. Here are the main places to
1844                     get in touch with us.</p>
1845                  <ul>
1846                      <li>
1847                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1848                      </li>
1849                      <li>
1850                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1851                      </li>
1852                      <li>
1853                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1854                      </li>
1855                  </ul>
1856                  <h2>In conclusion</h2>
1857                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1858                     as we enjoyed making it. Please contact us if you have ideas
1859                     for improvement or other feedback.</p>
1860              </div>
1861          </div>
1862     </body>
1863 </html>
1864 EOF
1865 }
1866
1867 =head2 run_options
1868
1869 Contains a hash of options passed from the application script, including
1870 the original ARGV the script received, the processed values from that
1871 ARGV and any extra arguments to the script which were not processed.
1872
1873 This can be used to add custom options to your application's scripts
1874 and setup your application differently depending on the values of these
1875 options.
1876
1877 =head1 INTERNAL METHODS
1878
1879 These methods are not meant to be used by end users.
1880
1881 =head2 $c->components
1882
1883 Returns a hash of components.
1884
1885 =head2 $c->context_class
1886
1887 Returns or sets the context class.
1888
1889 =head2 $c->counter
1890
1891 Returns a hashref containing coderefs and execution counts (needed for
1892 deep recursion detection).
1893
1894 =head2 $c->depth
1895
1896 Returns the number of actions on the current internal execution stack.
1897
1898 =head2 $c->dispatch
1899
1900 Dispatches a request to actions.
1901
1902 =cut
1903
1904 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1905
1906 =head2 $c->dispatcher_class
1907
1908 Returns or sets the dispatcher class.
1909
1910 =head2 $c->dump_these
1911
1912 Returns a list of 2-element array references (name, structure) pairs
1913 that will be dumped on the error page in debug mode.
1914
1915 =cut
1916
1917 sub dump_these {
1918     my $c = shift;
1919     [ Request => $c->req ],
1920     [ Response => $c->res ],
1921     [ Stash => $c->stash ],
1922     [ Config => $c->config ];
1923 }
1924
1925 =head2 $c->engine_class
1926
1927 Returns or sets the engine class.
1928
1929 =head2 $c->execute( $class, $coderef )
1930
1931 Execute a coderef in given class and catch exceptions. Errors are available
1932 via $c->error.
1933
1934 =cut
1935
1936 sub execute {
1937     my ( $c, $class, $code ) = @_;
1938     $class = $c->component($class) || $class;
1939     $c->state(0);
1940
1941     if ( $c->depth >= $RECURSION ) {
1942         my $action = $code->reverse();
1943         $action = "/$action" unless $action =~ /->/;
1944         my $error = qq/Deep recursion detected calling "${action}"/;
1945         $c->log->error($error);
1946         $c->error($error);
1947         $c->state(0);
1948         return $c->state;
1949     }
1950
1951     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1952
1953     push( @{ $c->stack }, $code );
1954
1955     no warnings 'recursion';
1956     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1957     #      I have no idea how, ergo $ret (which appears to fix the issue)
1958     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1959
1960     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1961
1962     my $last = pop( @{ $c->stack } );
1963
1964     if ( my $error = $@ ) {
1965         #rethow if this can be handled by middleware
1966         if ( $c->_handle_http_exception($error) ) {
1967             foreach my $err (@{$c->error}) {
1968                 $c->log->error($err);
1969             }
1970             $c->clear_errors;
1971             $c->log->_flush if $c->log->can('_flush');
1972
1973             $error->can('rethrow') ? $error->rethrow : croak $error;
1974         }
1975         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1976             $error->rethrow if $c->depth > 1;
1977         }
1978         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1979             $error->rethrow if $c->depth > 0;
1980         }
1981         else {
1982             unless ( ref $error ) {
1983                 no warnings 'uninitialized';
1984                 chomp $error;
1985                 my $class = $last->class;
1986                 my $name  = $last->name;
1987                 $error = qq/Caught exception in $class->$name "$error"/;
1988             }
1989             $c->error($error);
1990         }
1991         $c->state(0);
1992     }
1993     return $c->state;
1994 }
1995
1996 sub _stats_start_execute {
1997     my ( $c, $code ) = @_;
1998     my $appclass = ref($c) || $c;
1999     return if ( ( $code->name =~ /^_.*/ )
2000         && ( !$appclass->config->{show_internal_actions} ) );
2001
2002     my $action_name = $code->reverse();
2003     $c->counter->{$action_name}++;
2004
2005     my $action = $action_name;
2006     $action = "/$action" unless $action =~ /->/;
2007
2008     # determine if the call was the result of a forward
2009     # this is done by walking up the call stack and looking for a calling
2010     # sub of Catalyst::forward before the eval
2011     my $callsub = q{};
2012     for my $index ( 2 .. 11 ) {
2013         last
2014         if ( ( caller($index) )[0] eq 'Catalyst'
2015             && ( caller($index) )[3] eq '(eval)' );
2016
2017         if ( ( caller($index) )[3] =~ /forward$/ ) {
2018             $callsub = ( caller($index) )[3];
2019             $action  = "-> $action";
2020             last;
2021         }
2022     }
2023
2024     my $uid = $action_name . $c->counter->{$action_name};
2025
2026     # is this a root-level call or a forwarded call?
2027     if ( $callsub =~ /forward$/ ) {
2028         my $parent = $c->stack->[-1];
2029
2030         # forward, locate the caller
2031         if ( defined $parent && exists $c->counter->{"$parent"} ) {
2032             $c->stats->profile(
2033                 begin  => $action,
2034                 parent => "$parent" . $c->counter->{"$parent"},
2035                 uid    => $uid,
2036             );
2037         }
2038         else {
2039
2040             # forward with no caller may come from a plugin
2041             $c->stats->profile(
2042                 begin => $action,
2043                 uid   => $uid,
2044             );
2045         }
2046     }
2047     else {
2048
2049         # root-level call
2050         $c->stats->profile(
2051             begin => $action,
2052             uid   => $uid,
2053         );
2054     }
2055     return $action;
2056
2057 }
2058
2059 sub _stats_finish_execute {
2060     my ( $c, $info ) = @_;
2061     $c->stats->profile( end => $info );
2062 }
2063
2064 =head2 $c->finalize
2065
2066 Finalizes the request.
2067
2068 =cut
2069
2070 sub finalize {
2071     my $c = shift;
2072
2073     for my $error ( @{ $c->error } ) {
2074         $c->log->error($error);
2075     }
2076
2077     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
2078     # stuff like cometd and websockets
2079
2080     if($c->request->_has_io_fh) {
2081       $c->log_response;
2082       return;
2083     }
2084
2085     # Allow engine to handle finalize flow (for POE)
2086     my $engine = $c->engine;
2087     if ( my $code = $engine->can('finalize') ) {
2088         $engine->$code($c);
2089     }
2090     else {
2091
2092         $c->finalize_uploads;
2093
2094         # Error
2095         if ( $#{ $c->error } >= 0 ) {
2096             $c->finalize_error;
2097         }
2098
2099         $c->finalize_encoding;
2100         $c->finalize_headers unless $c->response->finalized_headers;
2101         $c->finalize_body;
2102     }
2103
2104     $c->log_response;
2105
2106     if ($c->use_stats) {
2107         my $elapsed = $c->stats->elapsed;
2108         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
2109         $c->log->info(
2110             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
2111     }
2112
2113     return $c->response->status;
2114 }
2115
2116 =head2 $c->finalize_body
2117
2118 Finalizes body.
2119
2120 =cut
2121
2122 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
2123
2124 =head2 $c->finalize_cookies
2125
2126 Finalizes cookies.
2127
2128 =cut
2129
2130 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
2131
2132 =head2 $c->finalize_error
2133
2134 Finalizes error.  If there is only one error in L</error> and it is an object that
2135 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
2136 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
2137 return the default error page (production mode).
2138
2139 =cut
2140
2141 sub finalize_error {
2142     my $c = shift;
2143     if($#{$c->error} > 0) {
2144         $c->engine->finalize_error( $c, @_ );
2145     } else {
2146         my ($error) = @{$c->error};
2147         if ( $c->_handle_http_exception($error) ) {
2148             # In the case where the error 'knows what it wants', becauses its PSGI
2149             # aware, just rethow and let middleware catch it
2150             $error->can('rethrow') ? $error->rethrow : croak $error;
2151         } else {
2152             $c->engine->finalize_error( $c, @_ )
2153         }
2154     }
2155 }
2156
2157 =head2 $c->finalize_headers
2158
2159 Finalizes headers.
2160
2161 =cut
2162
2163 sub finalize_headers {
2164     my $c = shift;
2165
2166     my $response = $c->response; #accessor calls can add up?
2167
2168     # Check if we already finalized headers
2169     return if $response->finalized_headers;
2170
2171     # Handle redirects
2172     if ( my $location = $response->redirect ) {
2173         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
2174         $response->header( Location => $location );
2175     }
2176
2177     # Remove incorrectly added body and content related meta data when returning
2178     # an information response, or a response the is required to not include a body
2179
2180     $c->finalize_cookies;
2181
2182     # This currently is a NOOP but I don't want to remove it since I guess people
2183     # might have Response subclasses that use it for something... (JNAP)
2184     $c->response->finalize_headers();
2185
2186     # Done
2187     $response->finalized_headers(1);
2188 }
2189
2190 =head2 $c->finalize_encoding
2191
2192 Make sure your body is encoded properly IF you set an encoding.  By
2193 default the encoding is UTF-8 but you can disable it by explicitly setting the
2194 encoding configuration value to undef.
2195
2196 We can only encode when the body is a scalar.  Methods for encoding via the
2197 streaming interfaces (such as C<write> and C<write_fh> on L<Catalyst::Response>
2198 are available).
2199
2200 See L</ENCODING>.
2201
2202 =cut
2203
2204 sub finalize_encoding {
2205     my $c = shift;
2206     my $res = $c->res || return;
2207
2208     # Warn if the set charset is different from the one you put into encoding.  We need
2209     # to do this early since encodable_response is false for this condition and we need
2210     # to match the debug output for backcompat (there's a test for this...) -JNAP
2211     if(
2212       $res->content_type_charset and $c->encoding and
2213       (uc($c->encoding->mime_name) ne uc($res->content_type_charset))
2214     ) {
2215         my $ct = lc($res->content_type_charset);
2216         $c->log->debug("Catalyst encoding config is set to encode in '" .
2217             $c->encoding->mime_name .
2218             "', content type is '$ct', not encoding ");
2219     }
2220
2221     if(
2222       ($res->encodable_response) and
2223       (defined($res->body)) and
2224       (ref(\$res->body) eq 'SCALAR')
2225     ) {
2226         $c->res->body( $c->encoding->encode( $c->res->body, $c->_encode_check ) );
2227
2228         # Set the charset if necessary.  This might be a bit bonkers since encodable response
2229         # is false when the set charset is not the same as the encoding mimetype (maybe
2230         # confusing action at a distance here..
2231         # Don't try to set the charset if one already exists
2232         $c->res->content_type($c->res->content_type . "; charset=" . $c->encoding->mime_name)
2233           unless($c->res->content_type_charset);
2234     }
2235 }
2236
2237 =head2 $c->finalize_output
2238
2239 An alias for finalize_body.
2240
2241 =head2 $c->finalize_read
2242
2243 Finalizes the input after reading is complete.
2244
2245 =cut
2246
2247 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
2248
2249 =head2 $c->finalize_uploads
2250
2251 Finalizes uploads. Cleans up any temporary files.
2252
2253 =cut
2254
2255 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
2256
2257 =head2 $c->get_action( $action, $namespace )
2258
2259 Gets an action in a given namespace.
2260
2261 =cut
2262
2263 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
2264
2265 =head2 $c->get_actions( $action, $namespace )
2266
2267 Gets all actions of a given name in a namespace and all parent
2268 namespaces.
2269
2270 =cut
2271
2272 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
2273
2274 =head2 $app->handle_request( @arguments )
2275
2276 Called to handle each HTTP request.
2277
2278 =cut
2279
2280 sub handle_request {
2281     my ( $class, @arguments ) = @_;
2282
2283     # Always expect worst case!
2284     my $status = -1;
2285     try {
2286         if ($class->debug) {
2287             my $secs = time - $START || 1;
2288             my $av = sprintf '%.3f', $COUNT / $secs;
2289             my $time = localtime time;
2290             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2291         }
2292
2293         my $c = $class->prepare(@arguments);
2294         $c->dispatch;
2295         $status = $c->finalize;
2296     } catch {
2297         #rethow if this can be handled by middleware
2298         if ( $class->_handle_http_exception($_) ) {
2299             $_->can('rethrow') ? $_->rethrow : croak $_;
2300         }
2301         chomp(my $error = $_);
2302         $class->log->error(qq/Caught exception in engine "$error"/);
2303     };
2304
2305     $COUNT++;
2306
2307     if(my $coderef = $class->log->can('_flush')){
2308         $class->log->$coderef();
2309     }
2310     return $status;
2311 }
2312
2313 =head2 $class->prepare( @arguments )
2314
2315 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2316 etc.).
2317
2318 =cut
2319
2320 has _uploadtmp => (
2321     is => 'ro',
2322     predicate => '_has_uploadtmp',
2323 );
2324
2325 sub prepare {
2326     my ( $class, @arguments ) = @_;
2327
2328     # XXX
2329     # After the app/ctxt split, this should become an attribute based on something passed
2330     # into the application.
2331     $class->context_class( ref $class || $class ) unless $class->context_class;
2332
2333     my $uploadtmp = $class->config->{uploadtmp};
2334     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2335
2336     $c->response->_context($c);
2337
2338     $c->stats($class->stats_class->new)->enable($c->use_stats);
2339
2340     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2341         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2342     }
2343
2344     try {
2345         # Allow engine to direct the prepare flow (for POE)
2346         if ( my $prepare = $c->engine->can('prepare') ) {
2347             $c->engine->$prepare( $c, @arguments );
2348         }
2349         else {
2350             $c->prepare_request(@arguments);
2351             $c->prepare_connection;
2352             $c->prepare_query_parameters;
2353             $c->prepare_headers; # Just hooks, no longer needed - they just
2354             $c->prepare_cookies; # cause the lazy attribute on req to build
2355             $c->prepare_path;
2356
2357             # Prepare the body for reading, either by prepare_body
2358             # or the user, if they are using $c->read
2359             $c->prepare_read;
2360
2361             # Parse the body unless the user wants it on-demand
2362             unless ( ref($c)->config->{parse_on_demand} ) {
2363                 $c->prepare_body;
2364             }
2365         }
2366         $c->prepare_action;
2367     }
2368     # VERY ugly and probably shouldn't rely on ->finalize actually working
2369     catch {
2370         # failed prepare is always due to an invalid request, right?
2371         $c->response->status(400);
2372         $c->response->content_type('text/plain');
2373         $c->response->body('Bad Request');
2374         # Note we call finalize and then die here, which escapes
2375         # finalize being called in the enclosing block..
2376         # It in fact couldn't be called, as we don't return $c..
2377         # This is a mess - but I'm unsure you can fix this without
2378         # breaking compat for people doing crazy things (we should set
2379         # the 400 and just return the ctx here IMO, letting finalize get called
2380         # above...
2381         $c->finalize;
2382         die $_;
2383     };
2384
2385     $c->log_request;
2386
2387     return $c;
2388 }
2389
2390 =head2 $c->prepare_action
2391
2392 Prepares action. See L<Catalyst::Dispatcher>.
2393
2394 =cut
2395
2396 sub prepare_action {
2397     my $c = shift;
2398     my $ret = $c->dispatcher->prepare_action( $c, @_);
2399
2400     if($c->encoding) {
2401         foreach (@{$c->req->arguments}, @{$c->req->captures}) {
2402           $_ = $c->_handle_param_unicode_decoding($_);
2403         }
2404     }
2405
2406     return $ret;
2407 }
2408
2409
2410 =head2 $c->prepare_body
2411
2412 Prepares message body.
2413
2414 =cut
2415
2416 sub prepare_body {
2417     my $c = shift;
2418
2419     return if $c->request->_has_body;
2420
2421     # Initialize on-demand data
2422     $c->engine->prepare_body( $c, @_ );
2423     $c->prepare_parameters;
2424     $c->prepare_uploads;
2425 }
2426
2427 =head2 $c->prepare_body_chunk( $chunk )
2428
2429 Prepares a chunk of data before sending it to L<HTTP::Body>.
2430
2431 See L<Catalyst::Engine>.
2432
2433 =cut
2434
2435 sub prepare_body_chunk {
2436     my $c = shift;
2437     $c->engine->prepare_body_chunk( $c, @_ );
2438 }
2439
2440 =head2 $c->prepare_body_parameters
2441
2442 Prepares body parameters.
2443
2444 =cut
2445
2446 sub prepare_body_parameters {
2447     my $c = shift;
2448     $c->request->prepare_body_parameters( $c, @_ );
2449 }
2450
2451 =head2 $c->prepare_connection
2452
2453 Prepares connection.
2454
2455 =cut
2456
2457 sub prepare_connection {
2458     my $c = shift;
2459     $c->request->prepare_connection($c);
2460 }
2461
2462 =head2 $c->prepare_cookies
2463
2464 Prepares cookies by ensuring that the attribute on the request
2465 object has been built.
2466
2467 =cut
2468
2469 sub prepare_cookies { my $c = shift; $c->request->cookies }
2470
2471 =head2 $c->prepare_headers
2472
2473 Prepares request headers by ensuring that the attribute on the request
2474 object has been built.
2475
2476 =cut
2477
2478 sub prepare_headers { my $c = shift; $c->request->headers }
2479
2480 =head2 $c->prepare_parameters
2481
2482 Prepares parameters.
2483
2484 =cut
2485
2486 sub prepare_parameters {
2487     my $c = shift;
2488     $c->prepare_body_parameters;
2489     $c->engine->prepare_parameters( $c, @_ );
2490 }
2491
2492 =head2 $c->prepare_path
2493
2494 Prepares path and base.
2495
2496 =cut
2497
2498 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2499
2500 =head2 $c->prepare_query_parameters
2501
2502 Prepares query parameters.
2503
2504 =cut
2505
2506 sub prepare_query_parameters {
2507     my $c = shift;
2508
2509     $c->engine->prepare_query_parameters( $c, @_ );
2510 }
2511
2512 =head2 $c->log_request
2513
2514 Writes information about the request to the debug logs.  This includes:
2515
2516 =over 4
2517
2518 =item * Request method, path, and remote IP address
2519
2520 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2521
2522 =item * Request parameters
2523
2524 =item * File uploads
2525
2526 =back
2527
2528 =cut
2529
2530 sub log_request {
2531     my $c = shift;
2532
2533     return unless $c->debug;
2534
2535     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2536     my $request = $dump->[1];
2537
2538     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2539     $method ||= '';
2540     $path = '/' unless length $path;
2541     $address ||= '';
2542
2543     $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
2544     $path = decode_utf8($path);
2545
2546     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2547
2548     $c->log_request_headers($request->headers);
2549
2550     if ( my $keywords = $request->query_keywords ) {
2551         $c->log->debug("Query keywords are: $keywords");
2552     }
2553
2554     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2555
2556     $c->log_request_uploads($request);
2557 }
2558
2559 =head2 $c->log_response
2560
2561 Writes information about the response to the debug logs by calling
2562 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2563
2564 =cut
2565
2566 sub log_response {
2567     my $c = shift;
2568
2569     return unless $c->debug;
2570
2571     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2572     my $response = $dump->[1];
2573
2574     $c->log_response_status_line($response);
2575     $c->log_response_headers($response->headers);
2576 }
2577
2578 =head2 $c->log_response_status_line($response)
2579
2580 Writes one line of information about the response to the debug logs.  This includes:
2581
2582 =over 4
2583
2584 =item * Response status code
2585
2586 =item * Content-Type header (if present)
2587
2588 =item * Content-Length header (if present)
2589
2590 =back
2591
2592 =cut
2593
2594 sub log_response_status_line {
2595     my ($c, $response) = @_;
2596
2597     $c->log->debug(
2598         sprintf(
2599             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2600             $response->status                            || 'unknown',
2601             $response->headers->header('Content-Type')   || 'unknown',
2602             $response->headers->header('Content-Length') || 'unknown'
2603         )
2604     );
2605 }
2606
2607 =head2 $c->log_response_headers($headers);
2608
2609 Hook method which can be wrapped by plugins to log the response headers.
2610 No-op in the default implementation.
2611
2612 =cut
2613
2614 sub log_response_headers {}
2615
2616 =head2 $c->log_request_parameters( query => {}, body => {} )
2617
2618 Logs request parameters to debug logs
2619
2620 =cut
2621
2622 sub log_request_parameters {
2623     my $c          = shift;
2624     my %all_params = @_;
2625
2626     return unless $c->debug;
2627
2628     my $column_width = Catalyst::Utils::term_width() - 44;
2629     foreach my $type (qw(query body)) {
2630         my $params = $all_params{$type};
2631         next if ! keys %$params;
2632         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2633         for my $key ( sort keys %$params ) {
2634             my $param = $params->{$key};
2635             my $value = defined($param) ? $param : '';
2636             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2637         }
2638         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2639     }
2640 }
2641
2642 =head2 $c->log_request_uploads
2643
2644 Logs file uploads included in the request to the debug logs.
2645 The parameter name, filename, file type, and file size are all included in
2646 the debug logs.
2647
2648 =cut
2649
2650 sub log_request_uploads {
2651     my $c = shift;
2652     my $request = shift;
2653     return unless $c->debug;
2654     my $uploads = $request->uploads;
2655     if ( keys %$uploads ) {
2656         my $t = Text::SimpleTable->new(
2657             [ 12, 'Parameter' ],
2658             [ 26, 'Filename' ],
2659             [ 18, 'Type' ],
2660             [ 9,  'Size' ]
2661         );
2662         for my $key ( sort keys %$uploads ) {
2663             my $upload = $uploads->{$key};
2664             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2665                 $t->row( $key, $u->filename, $u->type, $u->size );
2666             }
2667         }
2668         $c->log->debug( "File Uploads are:\n" . $t->draw );
2669     }
2670 }
2671
2672 =head2 $c->log_request_headers($headers);
2673
2674 Hook method which can be wrapped by plugins to log the request headers.
2675 No-op in the default implementation.
2676
2677 =cut
2678
2679 sub log_request_headers {}
2680
2681 =head2 $c->log_headers($type => $headers)
2682
2683 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2684
2685 =cut
2686
2687 sub log_headers {
2688     my $c       = shift;
2689     my $type    = shift;
2690     my $headers = shift;    # an HTTP::Headers instance
2691
2692     return unless $c->debug;
2693
2694     my $column_width = Catalyst::Utils::term_width() - 28;
2695     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2696     $headers->scan(
2697         sub {
2698             my ( $name, $value ) = @_;
2699             $t->row( $name, $value );
2700         }
2701     );
2702     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2703 }
2704
2705
2706 =head2 $c->prepare_read
2707
2708 Prepares the input for reading.
2709
2710 =cut
2711
2712 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2713
2714 =head2 $c->prepare_request
2715
2716 Prepares the engine request.
2717
2718 =cut
2719
2720 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2721
2722 =head2 $c->prepare_uploads
2723
2724 Prepares uploads.
2725
2726 =cut
2727
2728 sub prepare_uploads {
2729     my $c = shift;
2730     $c->engine->prepare_uploads( $c, @_ );
2731 }
2732
2733 =head2 $c->prepare_write
2734
2735 Prepares the output for writing.
2736
2737 =cut
2738
2739 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2740
2741 =head2 $c->request_class
2742
2743 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2744
2745 =head2 $app->request_class_traits
2746
2747 An arrayref of L<Moose::Role>s which are applied to the request class.  You can
2748 name the full namespace of the role, or a namespace suffix, which will then
2749 be tried against the following standard namespace prefixes.
2750
2751     $MyApp::TraitFor::Request::$trait_suffix
2752     Catalyst::TraitFor::Request::$trait_suffix
2753
2754 So for example if you set:
2755
2756     MyApp->request_class_traits(['Foo']);
2757
2758 We try each possible role in turn (and throw an error if none load)
2759
2760     Foo
2761     MyApp::TraitFor::Request::Foo
2762     Catalyst::TraitFor::Request::Foo
2763
2764 The namespace part 'TraitFor::Request' was choosen to assist in backwards
2765 compatibility with L<CatalystX::RoleApplicator> which previously provided
2766 these features in a stand alone package.
2767
2768 =head2 $app->composed_request_class
2769
2770 This is the request class which has been composed with any request_class_traits.
2771
2772 =head2 $c->response_class
2773
2774 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2775
2776 =head2 $app->response_class_traits
2777
2778 An arrayref of L<Moose::Role>s which are applied to the response class.  You can
2779 name the full namespace of the role, or a namespace suffix, which will then
2780 be tried against the following standard namespace prefixes.
2781
2782     $MyApp::TraitFor::Response::$trait_suffix
2783     Catalyst::TraitFor::Response::$trait_suffix
2784
2785 So for example if you set:
2786
2787     MyApp->response_class_traits(['Foo']);
2788
2789 We try each possible role in turn (and throw an error if none load)
2790
2791     Foo
2792     MyApp::TraitFor::Response::Foo
2793     Catalyst::TraitFor::Responset::Foo
2794
2795 The namespace part 'TraitFor::Response' was choosen to assist in backwards
2796 compatibility with L<CatalystX::RoleApplicator> which previously provided
2797 these features in a stand alone package.
2798
2799
2800 =head2 $app->composed_response_class
2801
2802 This is the request class which has been composed with any response_class_traits.
2803
2804 =head2 $c->read( [$maxlength] )
2805
2806 Reads a chunk of data from the request body. This method is designed to
2807 be used in a while loop, reading C<$maxlength> bytes on every call.
2808 C<$maxlength> defaults to the size of the request if not specified.
2809
2810 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2811 directly.
2812
2813 Warning: If you use read(), Catalyst will not process the body,
2814 so you will not be able to access POST parameters or file uploads via
2815 $c->request.  You must handle all body parsing yourself.
2816
2817 =cut
2818
2819 sub read { my $c = shift; return $c->request->read( @_ ) }
2820
2821 =head2 $c->run
2822
2823 Starts the engine.
2824
2825 =cut
2826
2827 sub run {
2828   my $app = shift;
2829   $app->_make_immutable_if_needed;
2830   $app->engine_loader->needs_psgi_engine_compat_hack ?
2831     $app->engine->run($app, @_) :
2832       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2833 }
2834
2835 sub _make_immutable_if_needed {
2836     my $class = shift;
2837     my $meta = find_meta($class);
2838     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2839     if (
2840         $meta->is_immutable
2841         && ! { $meta->immutable_options }->{replace_constructor}
2842         && $isa_ca
2843     ) {
2844         warn("You made your application class ($class) immutable, "
2845             . "but did not inline the\nconstructor. "
2846             . "This will break catalyst, as your app \@ISA "
2847             . "Class::Accessor(::Fast)?\nPlease pass "
2848             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2849     }
2850     unless ($meta->is_immutable) {
2851         # XXX - FIXME warning here as you should make your app immutable yourself.
2852         $meta->make_immutable(
2853             replace_constructor => 1,
2854         );
2855     }
2856 }
2857
2858 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2859
2860 Sets an action in a given namespace.
2861
2862 =cut
2863
2864 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2865
2866 =head2 $c->setup_actions($component)
2867
2868 Sets up actions for a component.
2869
2870 =cut
2871
2872 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2873
2874 =head2 $c->setup_components
2875
2876 This method is called internally to set up the application's components.
2877
2878 It finds modules by calling the L<locate_components> method, expands them to
2879 package names with the L<expand_component_module> method, and then installs
2880 each component into the application.
2881
2882 The C<setup_components> config option is passed to both of the above methods.
2883
2884 Installation of each component is performed by the L<setup_component> method,
2885 below.
2886
2887 =cut
2888
2889 sub setup_components {
2890     my $class = shift;
2891
2892     my $config  = $class->config->{ setup_components };
2893
2894     my @comps = $class->locate_components($config);
2895     my %comps = map { $_ => 1 } @comps;
2896
2897     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2898     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2899         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2900     ) if $deprecatedcatalyst_component_names;
2901
2902     for my $component ( @comps ) {
2903
2904         # We pass ignore_loaded here so that overlay files for (e.g.)
2905         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2906         # we know M::P::O found a file on disk so this is safe
2907
2908         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2909     }
2910
2911     for my $component (@comps) {
2912         my $instance = $class->components->{ $component } = $class->delayed_setup_component($component);
2913     }
2914
2915     # Inject a component or wrap a stand alone class in an adaptor. This makes a list
2916     # of named components in the configuration that are not actually existing (not a
2917     # real file).
2918
2919     $class->setup_injected_components;
2920
2921     # All components are registered, now we need to 'init' them.
2922     foreach my $component_name (keys %{$class->components||+{}}) {
2923       $class->components->{$component_name} = $class->components->{$component_name}->() if
2924         (ref($class->components->{$component_name}) || '') eq 'CODE';
2925     }
2926 }
2927
2928 =head2 $app->setup_injected_components
2929
2930 Called by setup_compoents to setup components that are injected.
2931
2932 =cut
2933
2934 sub setup_injected_components {
2935     my ($class) = @_;
2936     my @injected_components = keys %{$class->config->{inject_components} ||+{}};
2937
2938     foreach my $injected_comp_name(@injected_components) {
2939         $class->setup_injected_component(
2940           $injected_comp_name,
2941           $class->config->{inject_components}->{$injected_comp_name});
2942     }
2943 }
2944
2945 =head2 $app->setup_injected_component( $injected_component_name, $config )
2946
2947 Setup a given injected component.
2948
2949 =cut
2950
2951 sub setup_injected_component {
2952     my ($class, $injected_comp_name, $config) = @_;
2953     if(my $component_class = $config->{from_component}) {
2954         my @roles = @{$config->{roles} ||[]};
2955         Catalyst::Utils::inject_component(
2956           into => $class,
2957           component => $component_class,
2958           (scalar(@roles) ? (traits => \@roles) : ()),
2959           as => $injected_comp_name);
2960     }
2961 }
2962
2963 =head2 $app->inject_component($MyApp_Component_name => \%args);
2964
2965 Add a component that is injected at setup:
2966
2967     MyApp->inject_component( 'Model::Foo' => { from_component => 'Common::Foo' } );
2968
2969 Must be called before ->setup.  Expects a component name for your
2970 current application and \%args where
2971
2972 =over 4
2973
2974 =item from_component
2975
2976 The target component being injected into your application
2977
2978 =item roles
2979
2980 An arrayref of L<Moose::Role>s that are applied to your component.
2981
2982 =back
2983
2984 Example
2985
2986     MyApp->inject_component(
2987       'Model::Foo' => {
2988         from_component => 'Common::Model::Foo',
2989         roles => ['Role1', 'Role2'],
2990       });
2991
2992 =head2 $app->inject_components
2993
2994 Inject a list of components:
2995
2996     MyApp->inject_components(
2997       'Model::FooOne' => {
2998         from_component => 'Common::Model::Foo',
2999         roles => ['Role1', 'Role2'],
3000       },
3001       'Model::FooTwo' => {
3002         from_component => 'Common::Model::Foo',
3003         roles => ['Role1', 'Role2'],
3004       });
3005
3006 =cut
3007
3008 sub inject_component {
3009   my ($app, $name, $args) = @_;
3010   die "Component $name exists" if
3011     $app->config->{inject_components}->{$name};
3012   $app->config->{inject_components}->{$name} = $args;
3013 }
3014
3015 sub inject_components {
3016   my $app = shift;
3017   while(@_) {
3018     $app->inject_component(shift, shift);
3019   }
3020 }
3021
3022 =head2 $c->locate_components( $setup_component_config )
3023
3024 This method is meant to provide a list of component modules that should be
3025 setup for the application.  By default, it will use L<Module::Pluggable>.
3026
3027 Specify a C<setup_components> config option to pass additional options directly
3028 to L<Module::Pluggable>. To add additional search paths, specify a key named
3029 C<search_extra> as an array reference. Items in the array beginning with C<::>
3030 will have the application class name prepended to them.
3031
3032 =cut
3033
3034 sub locate_components {
3035     my $class  = shift;
3036     my $config = shift;
3037
3038     my @paths   = qw( ::M ::Model ::V ::View ::C ::Controller );
3039     my $extra   = delete $config->{ search_extra } || [];
3040
3041     unshift @paths, @$extra;
3042
3043     my @comps = map { sort { length($a) <=> length($b) } Module::Pluggable::Object->new(
3044       search_path => [ map { s/^(?=::)/$class/; $_; } ($_) ],
3045       %$config
3046     )->plugins } @paths;
3047
3048     return @comps;
3049 }
3050
3051 =head2 $c->expand_component_module( $component, $setup_component_config )
3052
3053 Components found by C<locate_components> will be passed to this method, which
3054 is expected to return a list of component (package) names to be set up.
3055
3056 =cut
3057
3058 sub expand_component_module {
3059     my ($class, $module) = @_;
3060     return Devel::InnerPackage::list_packages( $module );
3061 }
3062
3063 =head2 $app->delayed_setup_component
3064
3065 Returns a coderef that points to a setup_component instance.  Used
3066 internally for when you want to delay setup until the first time
3067 the component is called.
3068
3069 =cut
3070
3071 sub delayed_setup_component {
3072   my($class, $component, @more) = @_;
3073   return sub {
3074     return my $instance = $class->setup_component($component, @more);
3075   };
3076 }
3077
3078 =head2 $c->setup_component
3079
3080 =cut
3081
3082 sub setup_component {
3083     my( $class, $component ) = @_;
3084
3085     unless ( $component->can( 'COMPONENT' ) ) {
3086         return $component;
3087     }
3088
3089     my $config = $class->config_for($component);
3090     # Stash catalyst_component_name in the config here, so that custom COMPONENT
3091     # methods also pass it. local to avoid pointlessly shitting in config
3092     # for the debug screen, as $component is already the key name.
3093     local $config->{catalyst_component_name} = $component;
3094
3095     my $instance = eval {
3096       $component->COMPONENT( $class, $config );
3097     } || do {
3098       my $error = $@;
3099       chomp $error;
3100       Catalyst::Exception->throw(
3101         message => qq/Couldn't instantiate component "$component", "$error"/
3102       );
3103     };
3104
3105     unless (blessed $instance) {
3106         my $metaclass = Moose::Util::find_meta($component);
3107         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
3108         my $component_method_from = $method_meta->associated_metaclass->name;
3109         my $value = defined($instance) ? $instance : 'undef';
3110         Catalyst::Exception->throw(
3111             message =>
3112             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
3113         );
3114     }
3115
3116     my @expanded_components = $instance->can('expand_modules')
3117       ? $instance->expand_modules( $component, $config )
3118       : $class->expand_component_module( $component, $config );
3119     for my $component (@expanded_components) {
3120       next if $class->components->{ $component };
3121       $class->components->{ $component } = $class->setup_component($component);
3122     }
3123
3124     return $instance;
3125 }
3126
3127 =head2 $app->config_for( $component_name )
3128
3129 Return the application level configuration (which is not yet merged with any
3130 local component configuration, via $component_class->config) for the named
3131 component or component object. Example:
3132
3133     MyApp->config(
3134       'Model::Foo' => { a => 1, b => 2},
3135     );
3136
3137     my $config = MyApp->config_for('MyApp::Model::Foo');
3138
3139 In this case $config is the hashref C< {a=>1, b=>2} >.
3140
3141 This is also handy for looking up configuration for a plugin, to make sure you follow
3142 existing L<Catalyst> standards for where a plugin should put its configuration.
3143
3144 =cut
3145
3146 sub config_for {
3147     my ($class, $component_name) = @_;
3148     my $component_suffix = Catalyst::Utils::class2classsuffix($component_name);
3149     my $config = $class->config->{ $component_suffix } || {};
3150
3151     return $config;
3152 }
3153
3154 =head2 $c->setup_dispatcher
3155
3156 Sets up dispatcher.
3157
3158 =cut
3159
3160 sub setup_dispatcher {
3161     my ( $class, $dispatcher ) = @_;
3162
3163     if ($dispatcher) {
3164         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
3165     }
3166
3167     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
3168         $dispatcher = 'Catalyst::Dispatcher::' . $env;
3169     }
3170
3171     unless ($dispatcher) {
3172         $dispatcher = $class->dispatcher_class;
3173     }
3174
3175     load_class($dispatcher);
3176
3177     # dispatcher instance
3178     $class->dispatcher( $dispatcher->new );
3179 }
3180
3181 =head2 $c->setup_engine
3182
3183 Sets up engine.
3184
3185 =cut
3186
3187 sub engine_class {
3188     my ($class, $requested_engine) = @_;
3189
3190     if (!$class->engine_loader || $requested_engine) {
3191         $class->engine_loader(
3192             Catalyst::EngineLoader->new({
3193                 application_name => $class,
3194                 (defined $requested_engine
3195                      ? (catalyst_engine_class => $requested_engine) : ()),
3196             }),
3197         );
3198     }
3199
3200     $class->engine_loader->catalyst_engine_class;
3201 }
3202
3203 sub setup_engine {
3204     my ($class, $requested_engine) = @_;
3205
3206     my $engine = do {
3207         my $loader = $class->engine_loader;
3208
3209         if (!$loader || $requested_engine) {
3210             $loader = Catalyst::EngineLoader->new({
3211                 application_name => $class,
3212                 (defined $requested_engine
3213                      ? (requested_engine => $requested_engine) : ()),
3214             }),
3215
3216             $class->engine_loader($loader);
3217         }
3218
3219         $loader->catalyst_engine_class;
3220     };
3221
3222     # Don't really setup_engine -- see _setup_psgi_app for explanation.
3223     return if $class->loading_psgi_file;
3224
3225     load_class($engine);
3226
3227     if ($ENV{MOD_PERL}) {
3228         my $apache = $class->engine_loader->auto;
3229
3230         my $meta = find_meta($class);
3231         my $was_immutable = $meta->is_immutable;
3232         my %immutable_options = $meta->immutable_options;
3233         $meta->make_mutable if $was_immutable;
3234
3235         $meta->add_method(handler => sub {
3236             my $r = shift;
3237             my $psgi_app = $class->_finalized_psgi_app;
3238             $apache->call_app($r, $psgi_app);
3239         });
3240
3241         $meta->make_immutable(%immutable_options) if $was_immutable;
3242     }
3243
3244     $class->engine( $engine->new );
3245
3246     return;
3247 }
3248
3249 ## This exists just to supply a prebuild psgi app for mod_perl and for the
3250 ## build in server support (back compat support for pre psgi port behavior).
3251 ## This is so that we don't build a new psgi app for each request when using
3252 ## the mod_perl handler or the built in servers (http and fcgi, etc).
3253
3254 sub _finalized_psgi_app {
3255     my ($app) = @_;
3256
3257     unless ($app->_psgi_app) {
3258         my $psgi_app = $app->_setup_psgi_app;
3259         $app->_psgi_app($psgi_app);
3260     }
3261
3262     return $app->_psgi_app;
3263 }
3264
3265 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
3266 ## home directory and load that and return it (just assume it is doing the
3267 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
3268 ## in default_middleware and return it ( this is for backward compatibility
3269 ## with pre psgi port behavior ).
3270
3271 sub _setup_psgi_app {
3272     my ($app) = @_;
3273
3274     for my $home (Path::Class::Dir->new($app->config->{home})) {
3275         my $psgi_file = $home->file(
3276             Catalyst::Utils::appprefix($app) . '.psgi',
3277         );
3278
3279         next unless -e $psgi_file;
3280
3281         # If $psgi_file calls ->setup_engine, it's doing so to load
3282         # Catalyst::Engine::PSGI. But if it does that, we're only going to
3283         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
3284         # anyway. So set a flag (ick) that tells setup_engine not to populate
3285         # $c->engine or do any other things we might regret.
3286
3287         $app->loading_psgi_file(1);
3288         my $psgi_app = Plack::Util::load_psgi($psgi_file);
3289         $app->loading_psgi_file(0);
3290
3291         return $psgi_app
3292             unless $app->engine_loader->needs_psgi_engine_compat_hack;
3293
3294         warn <<"EOW";
3295 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
3296
3297 Its content has been ignored. Please consult the Catalyst::Upgrading
3298 documentation on how to upgrade from Catalyst::Engine::PSGI.
3299 EOW
3300     }
3301
3302     return $app->apply_default_middlewares($app->psgi_app);
3303 }
3304
3305 =head2 $c->apply_default_middlewares
3306
3307 Adds the following L<Plack> middlewares to your application, since they are
3308 useful and commonly needed:
3309
3310 L<Plack::Middleware::LighttpdScriptNameFix> (if you are using Lighttpd),
3311 L<Plack::Middleware::IIS6ScriptNameFix> (always applied since this middleware
3312 is smart enough to conditionally apply itself).
3313
3314 We will also automatically add L<Plack::Middleware::ReverseProxy> if we notice
3315 that your HTTP $env variable C<REMOTE_ADDR> is '127.0.0.1'.  This is usually
3316 an indication that your server is running behind a proxy frontend.  However in
3317 2014 this is often not the case.  We preserve this code for backwards compatibility
3318 however I B<highly> recommend that if you are running the server behind a front
3319 end proxy that you clearly indicate so with the C<using_frontend_proxy> configuration
3320 setting to true for your environment configurations that run behind a proxy.  This
3321 way if you change your front end proxy address someday your code would inexplicably
3322 stop working as expected.
3323
3324 Additionally if we detect we are using Nginx, we add a bit of custom middleware
3325 to solve some problems with the way that server handles $ENV{PATH_INFO} and
3326 $ENV{SCRIPT_NAME}.
3327
3328 Please B<NOTE> that if you do use C<using_frontend_proxy> the middleware is now
3329 adding via C<registered_middleware> rather than this method.
3330
3331 If you are using Lighttpd or IIS6 you may wish to apply these middlewares.  In
3332 general this is no longer a common case but we have this here for backward
3333 compatibility.
3334
3335 =cut
3336
3337
3338 sub apply_default_middlewares {
3339     my ($app, $psgi_app) = @_;
3340
3341     # Don't add this conditional IF we are explicitly saying we want the
3342     # frontend proxy support.  We don't need it here since if that is the
3343     # case it will be always loaded in the default_middleware.
3344
3345     unless($app->config->{using_frontend_proxy}) {
3346       $psgi_app = Plack::Middleware::Conditional->wrap(
3347           $psgi_app,
3348           builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
3349           condition => sub {
3350               my ($env) = @_;
3351               return if $app->config->{ignore_frontend_proxy};
3352               return $env->{REMOTE_ADDR} eq '127.0.0.1';
3353           },
3354       );
3355     }
3356
3357     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
3358     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
3359     $psgi_app = Plack::Middleware::Conditional->wrap(
3360         $psgi_app,
3361         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
3362         condition => sub {
3363             my ($env) = @_;
3364             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
3365             return unless $1 < 4.23;
3366             1;
3367         },
3368     );
3369
3370     # we're applying this unconditionally as the middleware itself already makes
3371     # sure it doesn't fuck things up if it's not running under one of the right
3372     # IIS versions
3373     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
3374
3375     # And another IIS issue, this time with IIS7.
3376     $psgi_app = Plack::Middleware::Conditional->wrap(
3377         $psgi_app,
3378         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
3379         condition => sub {
3380             my ($env) = @_;
3381             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
3382         },
3383     );
3384
3385     return $psgi_app;
3386 }
3387
3388 =head2 App->psgi_app
3389
3390 =head2 App->to_app
3391
3392 Returns a PSGI application code reference for the catalyst application
3393 C<$c>. This is the bare application created without the C<apply_default_middlewares>
3394 method called.  We do however apply C<registered_middleware> since those are
3395 integral to how L<Catalyst> functions.  Also, unlike starting your application
3396 with a generated server script (via L<Catalyst::Devel> and C<catalyst.pl>) we do
3397 not attempt to return a valid L<PSGI> application using any existing C<${myapp}.psgi>
3398 scripts in your $HOME directory.
3399
3400 B<NOTE> C<apply_default_middlewares> was originally created when the first PSGI
3401 port was done for v5.90000.  These are middlewares that are added to achieve
3402 backward compatibility with older applications.  If you start your application
3403 using one of the supplied server scripts (generated with L<Catalyst::Devel> and
3404 the project skeleton script C<catalyst.pl>) we apply C<apply_default_middlewares>
3405 automatically.  This was done so that pre and post PSGI port applications would
3406 work the same way.
3407
3408 This is what you want to be using to retrieve the PSGI application code
3409 reference of your Catalyst application for use in a custom F<.psgi> or in your
3410 own created server modules.
3411
3412 =cut
3413
3414 *to_app = \&psgi_app;
3415
3416 sub psgi_app {
3417     my ($app) = @_;
3418     my $psgi = $app->engine->build_psgi_app($app);
3419     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
3420 }
3421
3422 =head2 $c->setup_home
3423
3424 Sets up the home directory.
3425
3426 =cut
3427
3428 sub setup_home {
3429     my ( $class, $home ) = @_;
3430
3431     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
3432         $home = $env;
3433     }
3434
3435     $home ||= Catalyst::Utils::home($class);
3436
3437     if ($home) {
3438         #I remember recently being scolded for assigning config values like this
3439         $class->config->{home} ||= $home;
3440         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
3441     }
3442 }
3443
3444 =head2 $c->setup_encoding
3445
3446 Sets up the input/output encoding. See L<ENCODING>
3447
3448 =cut
3449
3450 sub setup_encoding {
3451     my $c = shift;
3452     if( exists($c->config->{encoding}) && !defined($c->config->{encoding}) ) {
3453         # Ok, so the user has explicitly said "I don't want encoding..."
3454         return;
3455     } else {
3456       my $enc = defined($c->config->{encoding}) ?
3457         delete $c->config->{encoding} : 'UTF-8'; # not sure why we delete it... (JNAP)
3458       $c->encoding($enc);
3459     }
3460 }
3461
3462 =head2 handle_unicode_encoding_exception
3463
3464 Hook to let you customize how encoding errors are handled.  By default
3465 we just throw an exception.  Receives a hashref of debug information.
3466 Example:
3467
3468     $c->handle_unicode_encoding_exception({
3469         param_value => $value,
3470         error_msg => $_,
3471             encoding_step => 'params',
3472         });
3473
3474 =cut
3475
3476 sub handle_unicode_encoding_exception {
3477     my ( $self, $exception_ctx ) = @_;
3478     die $exception_ctx->{error_msg};
3479 }
3480
3481 # Some unicode helpers cargo culted from the old plugin.  These could likely
3482 # be neater.
3483
3484 sub _handle_unicode_decoding {
3485     my ( $self, $value ) = @_;
3486
3487     return unless defined $value;
3488
3489     ## I think this mess is to support the old nested
3490     if ( ref $value eq 'ARRAY' ) {
3491         foreach ( @$value ) {
3492             $_ = $self->_handle_unicode_decoding($_);
3493         }
3494         return $value;
3495     }
3496     elsif ( ref $value eq 'HASH' ) {
3497         foreach (keys %$value) {
3498             my $encoded_key = $self->_handle_param_unicode_decoding($_);
3499             $value->{$encoded_key} = $self->_handle_unicode_decoding($value->{$_});
3500
3501             # If the key was encoded we now have two (the original and current so
3502             # delete the original.
3503             delete $value->{$_} if $_ ne $encoded_key;
3504         }
3505         return $value;
3506     }
3507     else {
3508         return $self->_handle_param_unicode_decoding($value);
3509     }
3510 }
3511
3512 sub _handle_param_unicode_decoding {
3513     my ( $self, $value ) = @_;
3514     return unless defined $value; # not in love with just ignoring undefs - jnap
3515     return $value if blessed($value); #don't decode when the value is an object.
3516
3517     my $enc = $self->encoding;
3518     return try {
3519       $enc->decode( $value, $self->_encode_check );
3520     }
3521     catch {
3522         $self->handle_unicode_encoding_exception({
3523             param_value => $value,
3524             error_msg => $_,
3525             encoding_step => 'params',
3526         });
3527     };
3528 }
3529
3530 =head2 $c->setup_log
3531
3532 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
3533 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
3534 log to.
3535
3536 This method also installs a C<debug> method that returns a true value into the
3537 catalyst subclass if the "debug" level is passed in the comma-delimited list,
3538 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
3539
3540 Note that if the log has already been setup, by either a previous call to
3541 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
3542 that this method won't actually set up the log object.
3543
3544 =cut
3545
3546 sub setup_log {
3547     my ( $class, $levels ) = @_;
3548
3549     $levels ||= '';
3550     $levels =~ s/^\s+//;
3551     $levels =~ s/\s+$//;
3552     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
3553
3554     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
3555     if ( defined $env_debug ) {
3556         $levels{debug} = 1 if $env_debug; # Ugly!
3557         delete($levels{debug}) unless $env_debug;
3558     }
3559
3560     unless ( $class->log ) {
3561         $class->log( Catalyst::Log->new(keys %levels) );
3562     }
3563
3564     if ( $levels{debug} ) {
3565         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
3566         $class->log->debug('Debug messages enabled');
3567     }
3568 }
3569
3570 =head2 $c->setup_plugins
3571
3572 Sets up plugins.
3573
3574 =cut
3575
3576 =head2 $c->setup_stats
3577
3578 Sets up timing statistics class.
3579
3580 =cut
3581
3582 sub setup_stats {
3583     my ( $class, $stats ) = @_;
3584
3585     Catalyst::Utils::ensure_class_loaded($class->stats_class);
3586
3587     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
3588     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
3589         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
3590         $class->log->debug('Statistics enabled');
3591     }
3592 }
3593
3594
3595 =head2 $c->registered_plugins
3596
3597 Returns a sorted list of the plugins which have either been stated in the
3598 import list.
3599
3600 If passed a given plugin name, it will report a boolean value indicating
3601 whether or not that plugin is loaded.  A fully qualified name is required if
3602 the plugin name does not begin with C<Catalyst::Plugin::>.
3603
3604  if ($c->registered_plugins('Some::Plugin')) {
3605      ...
3606  }
3607
3608 =cut
3609
3610 {
3611
3612     sub registered_plugins {
3613         my $proto = shift;
3614         return sort keys %{ $proto->_plugins } unless @_;
3615         my $plugin = shift;
3616         return 1 if exists $proto->_plugins->{$plugin};
3617         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3618     }
3619
3620     sub _register_plugin {
3621         my ( $proto, $plugin, $instant ) = @_;
3622         my $class = ref $proto || $proto;
3623
3624         load_class( $plugin );
3625         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3626             if $plugin->isa( 'Catalyst::Component' );
3627         my $plugin_meta = Moose::Meta::Class->create($plugin);
3628         if (!$plugin_meta->has_method('new')
3629             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3630             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3631         }
3632         if (!$instant && !$proto->_plugins->{$plugin}) {
3633             my $meta = Class::MOP::get_metaclass_by_name($class);
3634             $meta->superclasses($plugin, $meta->superclasses);
3635         }
3636         $proto->_plugins->{$plugin} = 1;
3637         return $class;
3638     }
3639
3640     sub _default_plugins { return qw() }
3641
3642     sub setup_plugins {
3643         my ( $class, $plugins ) = @_;
3644
3645         $class->_plugins( {} ) unless $class->_plugins;
3646         $plugins = [ grep {
3647             m/Unicode::Encoding/ ? do {
3648                 $class->log->warn(
3649                     'Unicode::Encoding plugin is auto-applied,'
3650                     . ' please remove this from your appclass'
3651                     . ' and make sure to define "encoding" config'
3652                 );
3653                 unless (exists $class->config->{'encoding'}) {
3654                   $class->config->{'encoding'} = 'UTF-8';
3655                 }
3656                 () }
3657                 : $_
3658         } @$plugins ];
3659         push @$plugins, $class->_default_plugins;
3660         $plugins = Data::OptList::mkopt($plugins || []);
3661
3662         my @plugins = map {
3663             [ Catalyst::Utils::resolve_namespace(
3664                   $class . '::Plugin',
3665                   'Catalyst::Plugin', $_->[0]
3666               ),
3667               $_->[1],
3668             ]
3669          } @{ $plugins };
3670
3671         for my $plugin ( reverse @plugins ) {
3672             load_class($plugin->[0], $plugin->[1]);
3673             my $meta = find_meta($plugin->[0]);
3674             next if $meta && $meta->isa('Moose::Meta::Role');
3675
3676             $class->_register_plugin($plugin->[0]);
3677         }
3678
3679         my @roles =
3680             map  { $_->[0]->name, $_->[1] }
3681             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3682             map  { [find_meta($_->[0]), $_->[1]] }
3683             @plugins;
3684
3685         Moose::Util::apply_all_roles(
3686             $class => @roles
3687         ) if @roles;
3688     }
3689 }
3690
3691 =head2 default_middleware
3692
3693 Returns a list of instantiated PSGI middleware objects which is the default
3694 middleware that is active for this application (taking any configuration
3695 options into account, excluding your custom added middleware via the C<psgi_middleware>
3696 configuration option).  You can override this method if you wish to change
3697 the default middleware (although do so at risk since some middleware is vital
3698 to application function.)
3699
3700 The current default middleware list is:
3701
3702       Catalyst::Middleware::Stash
3703       Plack::Middleware::HTTPExceptions
3704       Plack::Middleware::RemoveRedundantBody
3705       Plack::Middleware::FixMissingBodyInRedirect
3706       Plack::Middleware::ContentLength
3707       Plack::Middleware::MethodOverride
3708       Plack::Middleware::Head
3709
3710 If the configuration setting C<using_frontend_proxy> is true we add:
3711
3712       Plack::Middleware::ReverseProxy
3713
3714 If the configuration setting C<using_frontend_proxy_path> is true we add:
3715
3716       Plack::Middleware::ReverseProxyPath
3717
3718 But B<NOTE> that L<Plack::Middleware::ReverseProxyPath> is not a dependency of the
3719 L<Catalyst> distribution so if you want to use this option you should add it to
3720 your project distribution file.
3721
3722 These middlewares will be added at L</setup_middleware> during the
3723 L</setup> phase of application startup.
3724
3725 =cut
3726
3727 sub default_middleware {
3728     my $class = shift;
3729     my @mw = (
3730       Catalyst::Middleware::Stash->new,
3731       Plack::Middleware::HTTPExceptions->new,
3732       Plack::Middleware::RemoveRedundantBody->new,
3733       Plack::Middleware::FixMissingBodyInRedirect->new,
3734       Plack::Middleware::ContentLength->new,
3735       Plack::Middleware::MethodOverride->new,
3736       Plack::Middleware::Head->new);
3737
3738     if($class->config->{using_frontend_proxy}) {
3739         push @mw, Plack::Middleware::ReverseProxy->new;
3740     }
3741
3742     if($class->config->{using_frontend_proxy_path}) {
3743         if(Class::Load::try_load_class('Plack::Middleware::ReverseProxyPath')) {
3744             push @mw, Plack::Middleware::ReverseProxyPath->new;
3745         } else {
3746           $class->log->error("Cannot use configuration 'using_frontend_proxy_path' because 'Plack::Middleware::ReverseProxyPath' is not installed");
3747         }
3748     }
3749
3750     return @mw;
3751 }
3752
3753 =head2 registered_middlewares
3754
3755 Read only accessor that returns an array of all the middleware in the order
3756 that they were added (which is the REVERSE of the order they will be applied).
3757
3758 The values returned will be either instances of L<Plack::Middleware> or of a
3759 compatible interface, or a coderef, which is assumed to be inlined middleware
3760
3761 =head2 setup_middleware (?@middleware)
3762
3763 Read configuration information stored in configuration key C<psgi_middleware> or
3764 from passed @args.
3765
3766 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3767 to use it to enable L<Plack::Middleware>
3768
3769 This method is automatically called during 'setup' of your application, so
3770 you really don't need to invoke it.  However you may do so if you find the idea
3771 of loading middleware via configuration weird :).  For example:
3772
3773     package MyApp;
3774
3775     use Catalyst;
3776
3777     __PACKAGE__->setup_middleware('Head');
3778     __PACKAGE__->setup;
3779
3780 When we read middleware definitions from configuration, we reverse the list
3781 which sounds odd but is likely how you expect it to work if you have prior
3782 experience with L<Plack::Builder> or if you previously used the plugin
3783 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3784
3785 So basically your middleware handles an incoming request from the first
3786 registered middleware, down and handles the response from the last middleware
3787 up.
3788
3789 =cut
3790
3791 sub registered_middlewares {
3792     my $class = shift;
3793     if(my $middleware = $class->_psgi_middleware) {
3794         my @mw = ($class->default_middleware, @$middleware);
3795
3796         if($class->config->{using_frontend_proxy}) {
3797           push @mw, Plack::Middleware::ReverseProxy->new;
3798         }
3799
3800         return @mw;
3801     } else {
3802         die "You cannot call ->registered_middlewares until middleware has been setup";
3803     }
3804 }
3805
3806 sub setup_middleware {
3807     my $class = shift;
3808     my @middleware_definitions;
3809
3810     # If someone calls this method you can add middleware with args.  However if its
3811     # called without an arg we need to setup the configuration middleware.
3812     if(@_) {
3813       @middleware_definitions = reverse(@_);
3814     } else {
3815       @middleware_definitions = reverse(@{$class->config->{'psgi_middleware'}||[]})
3816         unless $class->finalized_default_middleware;
3817       $class->finalized_default_middleware(1); # Only do this once, just in case some people call setup over and over...
3818     }
3819
3820     my @middleware = ();
3821     while(my $next = shift(@middleware_definitions)) {
3822         if(ref $next) {
3823             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3824                 push @middleware, $next;
3825             } elsif(ref $next eq 'CODE') {
3826                 push @middleware, $next;
3827             } elsif(ref $next eq 'HASH') {
3828                 my $namespace = shift @middleware_definitions;
3829                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3830                 push @middleware, $mw;
3831             } else {
3832               die "I can't handle middleware definition ${\ref $next}";
3833             }
3834         } else {
3835           my $mw = $class->Catalyst::Utils::build_middleware($next);
3836           push @middleware, $mw;
3837         }
3838     }
3839
3840     my @existing = @{$class->_psgi_middleware || []};
3841     $class->_psgi_middleware([@middleware,@existing,]);
3842 }
3843
3844 =head2 registered_data_handlers
3845
3846 A read only copy of registered Data Handlers returned as a Hash, where each key
3847 is a content type and each value is a subref that attempts to decode that content
3848 type.
3849
3850 =head2 setup_data_handlers (?@data_handler)
3851
3852 Read configuration information stored in configuration key C<data_handlers> or
3853 from passed @args.
3854
3855 See under L</CONFIGURATION> information regarding C<data_handlers>.
3856
3857 This method is automatically called during 'setup' of your application, so
3858 you really don't need to invoke it.
3859
3860 =head2 default_data_handlers
3861
3862 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3863 only two default data handlers, for 'application/json' and an alternative to
3864 'application/x-www-form-urlencoded' which supposed nested form parameters via
3865 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3866
3867 The 'application/json' data handler is used to parse incoming JSON into a Perl
3868 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3869 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3870 JSON decoder, and has the smallest dependency impact.
3871
3872 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3873 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3874 order to get the best performance.  You should add either to your dependency
3875 list (Makefile.PL, dist.ini, cpanfile, etc.)
3876
3877 =cut
3878
3879 sub registered_data_handlers {
3880     my $class = shift;
3881     if(my $data_handlers = $class->_data_handlers) {
3882         return %$data_handlers;
3883     } else {
3884         $class->setup_data_handlers;
3885         return $class->registered_data_handlers;
3886     }
3887 }
3888
3889 sub setup_data_handlers {
3890     my ($class, %data_handler_callbacks) = @_;
3891     %data_handler_callbacks = (
3892       %{$class->default_data_handlers},
3893       %{$class->config->{'data_handlers'}||+{}},
3894       %data_handler_callbacks);
3895
3896     $class->_data_handlers(\%data_handler_callbacks);
3897 }
3898
3899 sub default_data_handlers {
3900     my ($class) = @_;
3901     return +{
3902       'application/x-www-form-urlencoded' => sub {
3903           my ($fh, $req) = @_;
3904           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3905           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3906             ->can('build_cgi_struct')->($params);
3907       },
3908       'application/json' => sub {
3909           my ($fh, $req) = @_;
3910           my $parser = Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON');
3911           my $slurped;
3912           return eval {
3913             local $/;
3914             $slurped = $fh->getline;
3915             $parser->can("decode_json")->($slurped); # decode_json does utf8 decoding for us
3916           } || Catalyst::Exception->throw(sprintf "Error Parsing POST '%s', Error: %s", (defined($slurped) ? $slurped : 'undef') ,$@);
3917         },
3918     };
3919 }
3920
3921 sub _handle_http_exception {
3922     my ( $self, $error ) = @_;
3923     if (
3924            !$self->config->{always_catch_http_exceptions}
3925         && blessed $error
3926         && (
3927             $error->can('as_psgi')
3928             || (   $error->can('code')
3929                 && $error->code =~ m/^[1-5][0-9][0-9]$/ )
3930         )
3931       )
3932     {
3933         return 1;
3934     }
3935 }
3936
3937 =head2 $c->stack
3938
3939 Returns an arrayref of the internal execution stack (actions that are
3940 currently executing).
3941
3942 =head2 $c->stats
3943
3944 Returns the current timing statistics object. By default Catalyst uses
3945 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3946 L<< stats_class|/"$c->stats_class" >>.
3947
3948 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3949 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3950 profile explicitly, although MyApp.pm still won't profile nor output anything
3951 by itself.
3952
3953 =head2 $c->stats_class
3954
3955 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3956
3957 =head2 $app->stats_class_traits
3958
3959 A arrayref of L<Moose::Role>s that are applied to the stats_class before creating it.
3960
3961 =head2 $app->composed_stats_class
3962
3963 this is the stats_class composed with any 'stats_class_traits'.  You can
3964 name the full namespace of the role, or a namespace suffix, which will then
3965 be tried against the following standard namespace prefixes.
3966
3967     $MyApp::TraitFor::Stats::$trait_suffix
3968     Catalyst::TraitFor::Stats::$trait_suffix
3969
3970 So for example if you set:
3971
3972     MyApp->stats_class_traits(['Foo']);
3973
3974 We try each possible role in turn (and throw an error if none load)
3975
3976     Foo
3977     MyApp::TraitFor::Stats::Foo
3978     Catalyst::TraitFor::Stats::Foo
3979
3980 The namespace part 'TraitFor::Stats' was choosen to assist in backwards
3981 compatibility with L<CatalystX::RoleApplicator> which previously provided
3982 these features in a stand alone package.
3983
3984 =head2 $c->use_stats
3985
3986 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3987
3988 Note that this is a static method, not an accessor and should be overridden
3989 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3990
3991 =cut
3992
3993 sub use_stats { 0 }
3994
3995
3996 =head2 $c->write( $data )
3997
3998 Writes $data to the output stream. When using this method directly, you
3999 will need to manually set the C<Content-Length> header to the length of
4000 your output data, if known.
4001
4002 =cut
4003
4004 sub write {
4005     my $c = shift;
4006
4007     # Finalize headers if someone manually writes output (for compat)
4008     $c->finalize_headers;
4009
4010     return $c->response->write( @_ );
4011 }
4012
4013 =head2 version
4014
4015 Returns the Catalyst version number. Mostly useful for "powered by"
4016 messages in template systems.
4017
4018 =cut
4019
4020 sub version { return $Catalyst::VERSION }
4021
4022 =head1 CONFIGURATION
4023
4024 There are a number of 'base' config variables which can be set:
4025
4026 =over
4027
4028 =item *
4029
4030 C<always_catch_http_exceptions> - As of version 5.90060 Catalyst
4031 rethrows errors conforming to the interface described by
4032 L<Plack::Middleware::HTTPExceptions> and lets the middleware deal with it.
4033 Set true to get the deprecated behaviour and have Catalyst catch HTTP exceptions.
4034
4035 =item *
4036
4037 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
4038
4039 =item *
4040
4041 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
4042
4043 =item *
4044
4045 C<disable_component_resolution_regex_fallback> - Turns
4046 off the deprecated component resolution functionality so
4047 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
4048 are called then regex search will not be attempted on string values and
4049 instead C<undef> will be returned.
4050
4051 =item *
4052
4053 C<home> - The application home directory. In an uninstalled application,
4054 this is the top level application directory. In an installed application,
4055 this will be the directory containing C<< MyApp.pm >>.
4056
4057 =item *
4058
4059 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
4060
4061 =item *
4062
4063 C<name> - The name of the application in debug messages and the debug and
4064 welcome screens
4065
4066 =item *
4067
4068 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
4069 until it is accessed. This allows you to (for example) check authentication (and reject
4070 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
4071
4072 =item *
4073
4074 C<root> - The root directory for templates. Usually this is just a
4075 subdirectory of the home directory, but you can set it to change the
4076 templates to a different directory.
4077
4078 =item *
4079
4080 C<search_extra> - Array reference passed to Module::Pluggable to for additional
4081 namespaces from which components will be loaded (and constructed and stored in
4082 C<< $c->components >>).
4083
4084 =item *
4085
4086 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
4087 to be shown in hit debug tables in the test server.
4088
4089 =item *
4090
4091 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
4092 variable should be used for determining the request path.
4093
4094 Most web server environments pass the requested path to the application using environment variables,
4095 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
4096 exposed as C<< $c->request->base >>) and the request path below that base.
4097
4098 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
4099 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
4100
4101 =over
4102
4103 =item use_request_uri_for_path => 0
4104
4105 This is the default (and the) traditional method that Catalyst has used for determining the path information.
4106 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
4107 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
4108 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
4109
4110 However this method has the major disadvantage that it is impossible to correctly decode some elements
4111 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
4112 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
4113 can't distinguish / vs %2F in paths (in addition to other encoded values).
4114
4115 =item use_request_uri_for_path => 1
4116
4117 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
4118 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
4119 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
4120
4121 Given that this method of path resolution is provably more correct, it is recommended that you use
4122 this unless you have a specific need to deploy your application in a non-standard environment, and you are
4123 aware of the implications of not being able to handle encoded URI paths correctly.
4124
4125 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
4126 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
4127 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
4128 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
4129 C<< $c->request->base >> will be incorrect.
4130
4131 =back
4132
4133 =item *
4134
4135 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
4136
4137 =item *
4138
4139 C<using_frontend_proxy_path> - Enabled L<Plack::Middleware::ReverseProxyPath> on your application (if
4140 installed, otherwise log an error).  This is useful if your application is not running on the
4141 'root' (or /) of your host server.  B<NOTE> if you use this feature you should add the required
4142 middleware to your project dependency list since its not automatically a dependency of L<Catalyst>.
4143 This has been done since not all people need this feature and we wish to restrict the growth of
4144 L<Catalyst> dependencies.
4145
4146 =item *
4147
4148 C<encoding> - See L</ENCODING>
4149
4150 This now defaults to 'UTF-8'.  You my turn it off by setting this configuration
4151 value to undef.
4152
4153 =item *
4154
4155 C<abort_chain_on_error_fix>
4156
4157 When there is an error in an action chain, the default behavior is to continue
4158 processing the remaining actions and then catch the error upon chain end.  This
4159 can lead to running actions when the application is in an unexpected state.  If
4160 you have this issue, setting this config value to true will promptly exit a
4161 chain when there is an error raised in any action (thus terminating the chain
4162 early.)
4163
4164 use like:
4165
4166     __PACKAGE__->config(abort_chain_on_error_fix => 1);
4167
4168 In the future this might become the default behavior.
4169
4170 =item *
4171
4172 C<use_hash_multivalue_in_request>
4173
4174 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
4175 and C<parameters> return a hashref where values might be scalar or an arrayref
4176 depending on the incoming data.  In many cases this can be undesirable as it
4177 leads one to writing defensive code like the following:
4178
4179     my ($val) = ref($c->req->parameters->{a}) ?
4180       @{$c->req->parameters->{a}} :
4181         $c->req->parameters->{a};
4182
4183 Setting this configuration item to true will make L<Catalyst> populate the
4184 attributes underlying these methods with an instance of L<Hash::MultiValue>
4185 which is used by L<Plack::Request> and others to solve this very issue.  You
4186 may prefer this behavior to the default, if so enable this option (be warned
4187 if you enable it in a legacy application we are not sure if it is completely
4188 backwardly compatible).
4189
4190 =item *
4191
4192 C<skip_complex_post_part_handling>
4193
4194 When creating body parameters from a POST, if we run into a multpart POST
4195 that does not contain uploads, but instead contains inlined complex data
4196 (very uncommon) we cannot reliably convert that into field => value pairs.  So
4197 instead we create an instance of L<Catalyst::Request::PartData>.  If this causes
4198 issue for you, you can disable this by setting C<skip_complex_post_part_handling>
4199 to true (default is false).
4200
4201 =item *
4202
4203 C<skip_body_param_unicode_decoding>
4204
4205 Generally we decode incoming POST params based on your declared encoding (the
4206 default for this is to decode UTF-8).  If this is causing you trouble and you
4207 do not wish to turn all encoding support off (with the C<encoding> configuration
4208 parameter) you may disable this step atomically by setting this configuration
4209 parameter to true.
4210
4211 =item *
4212
4213 C<do_not_decode_query>
4214
4215 If true, then do not try to character decode any wide characters in your
4216 request URL query or keywords.  Most readings of the relevent specifications
4217 suggest these should be UTF-* encoded, which is the default that L<Catalyst>
4218 will use, hwoever if you are creating a lot of URLs manually or have external
4219 evil clients, this might cause you trouble.  If you find the changes introduced
4220 in Catalyst version 5.90080+ break some of your query code, you may disable
4221 the UTF-8 decoding globally using this configuration.
4222
4223 This setting takes precedence over C<default_query_encoding> and
4224 C<decode_query_using_global_encoding>
4225
4226 =item *
4227
4228 C<default_query_encoding>
4229
4230 By default we decode query and keywords in your request URL using UTF-8, which
4231 is our reading of the relevent specifications.  This setting allows one to
4232 specify a fixed value for how to decode your query.  You might need this if
4233 you are doing a lot of custom encoding of your URLs and not using UTF-8.
4234
4235 This setting take precedence over C<decode_query_using_global_encoding>.
4236
4237 =item *
4238
4239 C<decode_query_using_global_encoding>
4240
4241 Setting this to true will default your query decoding to whatever your
4242 general global encoding is (the default is UTF-8).
4243
4244 =item *
4245
4246 C<use_chained_args_0_special_case>
4247
4248 In older versions of Catalyst, when more than one action matched the same path
4249 AND all those matching actions declared Args(0), we'd break the tie by choosing
4250 the first action defined.  We now normalized how Args(0) works so that it
4251 follows the same rule as Args(N), which is to say when we need to break a tie
4252 we choose the LAST action defined.  If this breaks your code and you don't
4253 have time to update to follow the new normalized approach, you may set this
4254 value to true and it will globally revert to the original chaining behavior.
4255
4256 =item *
4257
4258 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
4259
4260 =item *
4261
4262 C<data_handlers> - See L<DATA HANDLERS>.
4263
4264 =item *
4265
4266 C<stats_class_traits>
4267
4268 An arrayref of L<Moose::Role>s that get componsed into your stats class.
4269
4270 =item *
4271
4272 C<request_class_traits>
4273
4274 An arrayref of L<Moose::Role>s that get componsed into your request class.
4275
4276 =item *
4277
4278 C<response_class_traits>
4279
4280 An arrayref of L<Moose::Role>s that get componsed into your response class.
4281
4282 =item *
4283
4284 C<inject_components>
4285
4286 A Hashref of L<Catalyst::Component> subclasses that are 'injected' into configuration.
4287 For example:
4288
4289     MyApp->config({
4290       inject_components => {
4291         'Controller::Err' => { from_component => 'Local::Controller::Errors' },
4292         'Model::Zoo' => { from_component => 'Local::Model::Foo' },
4293         'Model::Foo' => { from_component => 'Local::Model::Foo', roles => ['TestRole'] },
4294       },
4295       'Controller::Err' => { a => 100, b=>200, namespace=>'error' },
4296       'Model::Zoo' => { a => 2 },
4297       'Model::Foo' => { a => 100 },
4298     });
4299
4300 Generally L<Catalyst> looks for components in your Model/View or Controller directories.
4301 However for cases when you which to use an existing component and you don't need any
4302 customization (where for when you can apply a role to customize it) you may inject those
4303 components into your application.  Please note any configuration should be done 'in the
4304 normal way', with a key under configuration named after the component affix, as in the
4305 above example.
4306
4307 Using this type of injection allows you to construct significant amounts of your application
4308 with only configuration!.  This may or may not lead to increased code understanding.
4309
4310 Please not you may also call the ->inject_components application method as well, although
4311 you must do so BEFORE setup.
4312
4313 =back
4314
4315 =head1 EXCEPTIONS
4316
4317 Generally when you throw an exception inside an Action (or somewhere in
4318 your stack, such as in a model that an Action is calling) that exception
4319 is caught by Catalyst and unless you either catch it yourself (via eval
4320 or something like L<Try::Tiny> or by reviewing the L</error> stack, it
4321 will eventually reach L</finalize_errors> and return either the debugging
4322 error stack page, or the default error page.  However, if your exception
4323 can be caught by L<Plack::Middleware::HTTPExceptions>, L<Catalyst> will
4324 instead rethrow it so that it can be handled by that middleware (which
4325 is part of the default middleware).  For example this would allow
4326
4327     use HTTP::Throwable::Factory 'http_throw';
4328
4329     sub throws_exception :Local {
4330       my ($self, $c) = @_;
4331
4332       http_throw(SeeOther => { location =>
4333         $c->uri_for($self->action_for('redirect')) });
4334
4335     }
4336
4337 =head1 INTERNAL ACTIONS
4338
4339 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
4340 C<_ACTION>, and C<_END>. These are by default not shown in the private
4341 action table, but you can make them visible with a config parameter.
4342
4343     MyApp->config(show_internal_actions => 1);
4344
4345 =head1 ON-DEMAND PARSER
4346
4347 The request body is usually parsed at the beginning of a request,
4348 but if you want to handle input yourself, you can enable on-demand
4349 parsing with a config parameter.
4350
4351     MyApp->config(parse_on_demand => 1);
4352
4353 =head1 PROXY SUPPORT
4354
4355 Many production servers operate using the common double-server approach,
4356 with a lightweight frontend web server passing requests to a larger
4357 backend server. An application running on the backend server must deal
4358 with two problems: the remote user always appears to be C<127.0.0.1> and
4359 the server's hostname will appear to be C<localhost> regardless of the
4360 virtual host that the user connected through.
4361
4362 Catalyst will automatically detect this situation when you are running
4363 the frontend and backend servers on the same machine. The following
4364 changes are made to the request.
4365
4366     $c->req->address is set to the user's real IP address, as read from
4367     the HTTP X-Forwarded-For header.
4368
4369     The host value for $c->req->base and $c->req->uri is set to the real
4370     host, as read from the HTTP X-Forwarded-Host header.
4371
4372 Additionally, you may be running your backend application on an insecure
4373 connection (port 80) while your frontend proxy is running under SSL.  If there
4374 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
4375 tell Catalyst what port the frontend listens on.  This will allow all URIs to
4376 be created properly.
4377
4378 In the case of passing in:
4379
4380     X-Forwarded-Port: 443
4381
4382 All calls to C<uri_for> will result in an https link, as is expected.
4383
4384 Obviously, your web server must support these headers for this to work.
4385
4386 In a more complex server farm environment where you may have your
4387 frontend proxy server(s) on different machines, you will need to set a
4388 configuration option to tell Catalyst to read the proxied data from the
4389 headers.
4390
4391     MyApp->config(using_frontend_proxy => 1);
4392
4393 If you do not wish to use the proxy support at all, you may set:
4394
4395     MyApp->config(ignore_frontend_proxy => 0);
4396
4397 =head2 Note about psgi files
4398
4399 Note that if you supply your own .psgi file, calling
4400 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
4401
4402 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
4403 in your psgi, for example:
4404
4405     builder {
4406         enable "Plack::Middleware::ReverseProxy";
4407         MyApp->psgi_app
4408     };
4409
4410 This will unconditionally add the ReverseProxy support, or you need to call
4411 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
4412 apply the support depending upon your config).
4413
4414 See L<Catalyst::PSGI> for more information.
4415
4416 =head1 THREAD SAFETY
4417
4418 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
4419 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
4420 believe the Catalyst core to be thread-safe.
4421
4422 If you plan to operate in a threaded environment, remember that all other
4423 modules you are using must also be thread-safe. Some modules, most notably
4424 L<DBD::SQLite>, are not thread-safe.
4425
4426 =head1 DATA HANDLERS
4427
4428 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
4429 form parameters and URL search query fields.  However it has become common
4430 for various alternative content types to be PUT or POSTed to your controllers
4431 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
4432 XML and other content types when communicating with an application server.  In
4433 order to better support this use case, L<Catalyst> defines a global configuration
4434 option, C<data_handlers>, which lets you associate a content type with a coderef
4435 that parses that content type into something Perl can readily access.
4436
4437     package MyApp::Web;
4438
4439     use Catalyst;
4440     use JSON::Maybe;
4441
4442     __PACKAGE__->config(
4443       data_handlers => {
4444         'application/json' => sub { local $/; decode_json $_->getline },
4445       },
4446       ## Any other configuration.
4447     );
4448
4449     __PACKAGE__->setup;
4450
4451 By default L<Catalyst> comes with a generic JSON data handler similar to the
4452 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
4453 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
4454 it installed (if you want the faster XS parser, add it to you project Makefile.PL
4455 or dist.ini, cpanfile, etc.)
4456
4457 The C<data_handlers> configuration is a hashref whose keys are HTTP Content-Types
4458 (matched against the incoming request type using a regexp such as to be case
4459 insensitive) and whose values are coderefs that receive a localized version of
4460 C<$_> which is a filehandle object pointing to received body.
4461
4462 This feature is considered an early access release and we reserve the right
4463 to alter the interface in order to provide a performant and secure solution to
4464 alternative request body content.  Your reports welcomed!
4465
4466 =head1 PSGI MIDDLEWARE
4467
4468 You can define middleware, defined as L<Plack::Middleware> or a compatible
4469 interface in configuration.  Your middleware definitions are in the form of an
4470 arrayref under the configuration key C<psgi_middleware>.  Here's an example
4471 with details to follow:
4472
4473     package MyApp::Web;
4474
4475     use Catalyst;
4476     use Plack::Middleware::StackTrace;
4477
4478     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4479
4480     __PACKAGE__->config(
4481       'psgi_middleware', [
4482         'Debug',
4483         '+MyApp::Custom',
4484         $stacktrace_middleware,
4485         'Session' => {store => 'File'},
4486         sub {
4487           my $app = shift;
4488           return sub {
4489             my $env = shift;
4490             $env->{myapp.customkey} = 'helloworld';
4491             $app->($env);
4492           },
4493         },
4494       ],
4495     );
4496
4497     __PACKAGE__->setup;
4498
4499 So the general form is:
4500
4501     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
4502
4503 Where C<@middleware> is one or more of the following, applied in the REVERSE of
4504 the order listed (to make it function similarly to L<Plack::Builder>:
4505
4506 Alternatively, you may also define middleware by calling the L</setup_middleware>
4507 package method:
4508
4509     package MyApp::Web;
4510
4511     use Catalyst;
4512
4513     __PACKAGE__->setup_middleware( \@middleware_definitions);
4514     __PACKAGE__->setup;
4515
4516 In the case where you do both (use 'setup_middleware' and configuration) the
4517 package call to setup_middleware will be applied earlier (in other words its
4518 middleware will wrap closer to the application).  Keep this in mind since in
4519 some cases the order of middleware is important.
4520
4521 The two approaches are not exclusive.
4522
4523 =over 4
4524
4525 =item Middleware Object
4526
4527 An already initialized object that conforms to the L<Plack::Middleware>
4528 specification:
4529
4530     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
4531
4532     __PACKAGE__->config(
4533       'psgi_middleware', [
4534         $stacktrace_middleware,
4535       ]);
4536
4537
4538 =item coderef
4539
4540 A coderef that is an inlined middleware:
4541
4542     __PACKAGE__->config(
4543       'psgi_middleware', [
4544         sub {
4545           my $app = shift;
4546           return sub {
4547             my $env = shift;
4548             if($env->{PATH_INFO} =~m/forced/) {
4549               Plack::App::File
4550                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
4551                 ->call($env);
4552             } else {
4553               return $app->($env);
4554             }
4555          },
4556       },
4557     ]);
4558
4559
4560
4561 =item a scalar
4562
4563 We assume the scalar refers to a namespace after normalizing it using the
4564 following rules:
4565
4566 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
4567 is assumed to be 'as is', and we just install and use the middleware.
4568
4569 (2) If the scalar begins with "Plack::Middleware" or your application namespace
4570 (the package name of your Catalyst application subclass), we also assume then
4571 that it is a full namespace, and use it.
4572
4573 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
4574 resolve it first by looking for it under your application namespace (for example
4575 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
4576 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
4577 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
4578 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
4579 namespace first to let you 'override' common L<Plack::Middleware> locally, should
4580 you find that a good idea.
4581
4582 Examples:
4583
4584     package MyApp::Web;
4585
4586     __PACKAGE__->config(
4587       'psgi_middleware', [
4588         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
4589         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
4590         '+MyApp::Custom',  ## MyApp::Custom->wrap
4591       ],
4592     );
4593
4594 =item a scalar followed by a hashref
4595
4596 Just like the previous, except the following C<HashRef> is used as arguments
4597 to initialize the middleware object.
4598
4599     __PACKAGE__->config(
4600       'psgi_middleware', [
4601          'Session' => {store => 'File'},
4602     ]);
4603
4604 =back
4605
4606 Please see L<PSGI> for more on middleware.
4607
4608 =head1 ENCODING
4609
4610 Starting in L<Catalyst> version 5.90080 encoding is automatically enabled
4611 and set to encode all body responses to UTF8 when possible and applicable.
4612 Following is documentation on this process.  If you are using an older
4613 version of L<Catalyst> you should review documentation for that version since
4614 a lot has changed.
4615
4616 By default encoding is now 'UTF-8'.  You may turn it off by setting
4617 the encoding configuration to undef.
4618
4619     MyApp->config(encoding => undef);
4620
4621 This is recommended for temporary backwards compatibility only.
4622
4623 Encoding is automatically applied when the content-type is set to
4624 a type that can be encoded.  Currently we encode when the content type
4625 matches the following regular expression:
4626
4627     $content_type =~ /^text|xml$|javascript$/
4628
4629 Encoding is set on the application, but it is copied to the context object
4630 so that you can override it on a request basis.
4631
4632 Be default we don't automatically encode 'application/json' since the most
4633 common approaches to generating this type of response (Either via L<Catalyst::View::JSON>
4634 or L<Catalyst::Action::REST>) will do so already and we want to avoid double
4635 encoding issues.
4636
4637 If you are producing JSON response in an unconventional manner (such
4638 as via a template or manual strings) you should perform the UTF8 encoding
4639 manually as well such as to conform to the JSON specification.
4640
4641 NOTE: We also examine the value of $c->response->content_encoding.  If
4642 you set this (like for example 'gzip', and manually gzipping the body)
4643 we assume that you have done all the necessary encoding yourself, since
4644 we cannot encode the gzipped contents.  If you use a plugin like
4645 L<Catalyst::Plugin::Compress> you need to update to a modern version in order
4646 to have this function correctly  with the new UTF8 encoding code, or you
4647 can use L<Plack::Middleware::Deflater> or (probably best) do your compression on
4648 a front end proxy.
4649
4650 =head2 Methods
4651
4652 =over 4
4653
4654 =item encoding
4655
4656 Returns an instance of an C<Encode> encoding
4657
4658     print $c->encoding->name
4659
4660 =item handle_unicode_encoding_exception ($exception_context)
4661
4662 Method called when decoding process for a request fails.
4663
4664 An C<$exception_context> hashref is provided to allow you to override the
4665 behaviour of your application when given data with incorrect encodings.
4666
4667 The default method throws exceptions in the case of invalid request parameters
4668 (resulting in a 500 error), but ignores errors in upload filenames.
4669
4670 The keys passed in the C<$exception_context> hash are:
4671
4672 =over
4673
4674 =item param_value
4675
4676 The value which was not able to be decoded.
4677
4678 =item error_msg
4679
4680 The exception received from L<Encode>.
4681
4682 =item encoding_step
4683
4684 What type of data was being decoded. Valid values are (currently)
4685 C<params> - for request parameters / arguments / captures
4686 and C<uploads> - for request upload filenames.
4687
4688 =back
4689
4690 =back
4691
4692 =head1 SUPPORT
4693
4694 IRC:
4695
4696     Join #catalyst on irc.perl.org.
4697
4698 Mailing Lists:
4699
4700     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
4701     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
4702
4703 Web:
4704
4705     http://catalyst.perl.org
4706
4707 Wiki:
4708
4709     http://dev.catalyst.perl.org
4710
4711 =head1 SEE ALSO
4712
4713 =head2 L<Task::Catalyst> - All you need to start with Catalyst
4714
4715 =head2 L<Catalyst::Manual> - The Catalyst Manual
4716
4717 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
4718
4719 =head2 L<Catalyst::Engine> - Core engine
4720
4721 =head2 L<Catalyst::Log> - Log class.
4722
4723 =head2 L<Catalyst::Request> - Request object
4724
4725 =head2 L<Catalyst::Response> - Response object
4726
4727 =head2 L<Catalyst::Test> - The test suite.
4728
4729 =head1 PROJECT FOUNDER
4730
4731 sri: Sebastian Riedel <sri@cpan.org>
4732
4733 =head1 CONTRIBUTORS
4734
4735 abw: Andy Wardley
4736
4737 acme: Leon Brocard <leon@astray.com>
4738
4739 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
4740
4741 andrewalker: André Walker <andre@cpan.org>
4742
4743 Andrew Bramble
4744
4745 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
4746
4747 Andrew Ruthven
4748
4749 andyg: Andy Grundman <andy@hybridized.org>
4750
4751 audreyt: Audrey Tang
4752
4753 bricas: Brian Cassidy <bricas@cpan.org>
4754
4755 Caelum: Rafael Kitover <rkitover@io.com>
4756
4757 chansen: Christian Hansen
4758
4759 chicks: Christopher Hicks
4760
4761 Chisel Wright C<pause@herlpacker.co.uk>
4762
4763 Danijel Milicevic C<me@danijel.de>
4764
4765 davewood: David Schmidt <davewood@cpan.org>
4766
4767 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
4768
4769 David Naughton, C<naughton@umn.edu>
4770
4771 David E. Wheeler
4772
4773 dhoss: Devin Austin <dhoss@cpan.org>
4774
4775 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
4776
4777 Drew Taylor
4778
4779 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
4780
4781 esskar: Sascha Kiefer
4782
4783 fireartist: Carl Franks <cfranks@cpan.org>
4784
4785 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
4786
4787 gabb: Danijel Milicevic
4788
4789 Gary Ashton Jones
4790
4791 Gavin Henry C<ghenry@perl.me.uk>
4792
4793 Geoff Richards
4794
4795 groditi: Guillermo Roditi <groditi@gmail.com>
4796
4797 hobbs: Andrew Rodland <andrew@cleverdomain.org>
4798
4799 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
4800
4801 jcamacho: Juan Camacho
4802
4803 jester: Jesse Sheidlower C<jester@panix.com>
4804
4805 jhannah: Jay Hannah <jay@jays.net>
4806
4807 Jody Belka
4808
4809 Johan Lindstrom
4810
4811 jon: Jon Schutz <jjschutz@cpan.org>
4812
4813 Jonathan Rockway C<< <jrockway@cpan.org> >>
4814
4815 Kieren Diment C<kd@totaldatasolution.com>
4816
4817 konobi: Scott McWhirter <konobi@cpan.org>
4818
4819 marcus: Marcus Ramberg <mramberg@cpan.org>
4820
4821 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
4822
4823 mgrimes: Mark Grimes <mgrimes@cpan.org>
4824
4825 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
4826
4827 mugwump: Sam Vilain
4828
4829 naughton: David Naughton
4830
4831 ningu: David Kamholz <dkamholz@cpan.org>
4832
4833 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
4834
4835 numa: Dan Sully <daniel@cpan.org>
4836
4837 obra: Jesse Vincent
4838
4839 Octavian Rasnita
4840
4841 omega: Andreas Marienborg
4842
4843 Oleg Kostyuk <cub.uanic@gmail.com>
4844
4845 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
4846
4847 rafl: Florian Ragwitz <rafl@debian.org>
4848
4849 random: Roland Lammel <lammel@cpan.org>
4850
4851 Robert Sedlacek C<< <rs@474.at> >>
4852
4853 SpiceMan: Marcel Montes
4854
4855 sky: Arthur Bergman
4856
4857 szbalint: Balint Szilakszi <szbalint@cpan.org>
4858
4859 t0m: Tomas Doran <bobtfish@bobtfish.net>
4860
4861 Ulf Edvinsson
4862
4863 vanstyn: Henry Van Styn <vanstyn@cpan.org>
4864
4865 Viljo Marrandi C<vilts@yahoo.com>
4866
4867 Will Hawes C<info@whawes.co.uk>
4868
4869 willert: Sebastian Willert <willert@cpan.org>
4870
4871 wreis: Wallace Reis <wreis@cpan.org>
4872
4873 Yuval Kogman, C<nothingmuch@woobling.org>
4874
4875 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
4876
4877 dd070: Dhaval Dhanani <dhaval070@gmail.com>
4878
4879 Upasana <me@upasana.me>
4880
4881 John Napiorkowski (jnap) <jjnapiork@cpan.org>
4882
4883 =head1 COPYRIGHT
4884
4885 Copyright (c) 2005-2015, the above named PROJECT FOUNDER and CONTRIBUTORS.
4886
4887 =head1 LICENSE
4888
4889 This library is free software. You can redistribute it and/or modify it under
4890 the same terms as Perl itself.
4891
4892 =cut
4893
4894 no Moose;
4895
4896 __PACKAGE__->meta->make_immutable;
4897
4898 1;