lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::LighttpdScriptNameFix;
  40
  41 BEGIN { require 5.008004; }
  42
  43 has stack => (is => 'ro', default => sub { [] });
  44 has stash => (is => 'rw', default => sub { {} });
  45 has state => (is => 'rw', default => 0);
  46 has stats => (is => 'rw');
  47 has action => (is => 'rw');
  48 has counter => (is => 'rw', default => sub { {} });
  49 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  50 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  51 has namespace => (is => 'rw');
  52
  53 sub depth { scalar @{ shift->stack || [] }; }
  54 sub comp { shift->component(@_) }
  55
  56 sub req {
  57     my $self = shift; return $self->request(@_);
  58 }
  59 sub res {
  60     my $self = shift; return $self->response(@_);
  61 }
  62
  63 # For backwards compatibility
  64 sub finalize_output { shift->finalize_body(@_) };
  65
  66 # For statistics
  67 our $COUNT     = 1;
  68 our $START     = time;
  69 our $RECURSION = 1000;
  70 our $DETACH    = Catalyst::Exception::Detach->new;
  71 our $GO        = Catalyst::Exception::Go->new;
  72
  73 #I imagine that very few of these really need to be class variables. if any.
  74 #maybe we should just make them attributes with a default?
  75 __PACKAGE__->mk_classdata($_)
  76   for qw/components arguments dispatcher engine log dispatcher_class
  77   engine_loader context_class request_class response_class stats_class
  78   setup_finished _psgi_app loading_psgi_file/;
  79
  80 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  81 __PACKAGE__->request_class('Catalyst::Request');
  82 __PACKAGE__->response_class('Catalyst::Response');
  83 __PACKAGE__->stats_class('Catalyst::Stats');
  84
  85 # Remember to update this in Catalyst::Runtime as well!
  86
  87 our $VERSION = '5.89003';
  88
  89 sub import {
  90     my ( $class, @arguments ) = @_;
  91
  92     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  93     # callers @ISA.
  94     return unless $class eq 'Catalyst';
  95
  96     my $caller = caller();
  97     return if $caller eq 'main';
  98
  99     my $meta = Moose::Meta::Class->initialize($caller);
 100     unless ( $caller->isa('Catalyst') ) {
 101         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 102         $meta->superclasses(@superclasses);
 103     }
 104     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 105     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 106
 107     unless( $meta->has_method('meta') ){
 108         if ($Moose::VERSION >= 1.15) {
 109             $meta->_add_meta_method('meta');
 110         }
 111         else {
 112             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 113         }
 114     }
 115
 116     $caller->arguments( [@arguments] );
 117     $caller->setup_home;
 118 }
 119
 120 sub _application { $_[0] }
 121
 122 =head1 NAME
 123
 124 Catalyst - The Elegant MVC Web Application Framework
 125
 126 =head1 SYNOPSIS
 127
 128 See the L<Catalyst::Manual> distribution for comprehensive
 129 documentation and tutorials.
 130
 131     # Install Catalyst::Devel for helpers and other development tools
 132     # use the helper to create a new application
 133     catalyst.pl MyApp
 134
 135     # add models, views, controllers
 136     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 137     script/myapp_create.pl view MyTemplate TT
 138     script/myapp_create.pl controller Search
 139
 140     # built in testserver -- use -r to restart automatically on changes
 141     # --help to see all available options
 142     script/myapp_server.pl
 143
 144     # command line testing interface
 145     script/myapp_test.pl /yada
 146
 147     ### in lib/MyApp.pm
 148     use Catalyst qw/-Debug/; # include plugins here as well
 149
 150     ### In lib/MyApp/Controller/Root.pm (autocreated)
 151     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 152         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 153         $c->stash->{template} = 'foo.tt'; # set the template
 154         # lookup something from db -- stash vars are passed to TT
 155         $c->stash->{data} =
 156           $c->model('Database::Foo')->search( { country => $args[0] } );
 157         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 158             $c->forward( 'bar' ); # process another action
 159             # do something else after forward returns
 160         }
 161     }
 162
 163     # The foo.tt TT template can use the stash data from the database
 164     [% WHILE (item = data.next) %]
 165         [% item.foo %]
 166     [% END %]
 167
 168     # called for /bar/of/soap, /bar/of/soap/10, etc.
 169     sub bar : Path('/bar/of/soap') { ... }
 170
 171     # called for all actions, from the top-most controller downwards
 172     sub auto : Private {
 173         my ( $self, $c ) = @_;
 174         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 175             $c->res->redirect( '/login' ); # require login
 176             return 0; # abort request and go immediately to end()
 177         }
 178         return 1; # success; carry on to next action
 179     }
 180
 181     # called after all actions are finished
 182     sub end : Private {
 183         my ( $self, $c ) = @_;
 184         if ( scalar @{ $c->error } ) { ... } # handle errors
 185         return if $c->res->body; # already have a response
 186         $c->forward( 'MyApp::View::TT' ); # render template
 187     }
 188
 189     ### in MyApp/Controller/Foo.pm
 190     # called for /foo/bar
 191     sub bar : Local { ... }
 192
 193     # called for /blargle
 194     sub blargle : Global { ... }
 195
 196     # an index action matches /foo, but not /foo/1, etc.
 197     sub index : Private { ... }
 198
 199     ### in MyApp/Controller/Foo/Bar.pm
 200     # called for /foo/bar/baz
 201     sub baz : Local { ... }
 202
 203     # first Root auto is called, then Foo auto, then this
 204     sub auto : Private { ... }
 205
 206     # powerful regular expression paths are also possible
 207     sub details : Regex('^product/(\w+)/details$') {
 208         my ( $self, $c ) = @_;
 209         # extract the (\w+) from the URI
 210         my $product = $c->req->captures->[0];
 211     }
 212
 213 See L<Catalyst::Manual::Intro> for additional information.
 214
 215 =head1 DESCRIPTION
 216
 217 Catalyst is a modern framework for making web applications without the
 218 pain usually associated with this process. This document is a reference
 219 to the main Catalyst application. If you are a new user, we suggest you
 220 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 221
 222 See L<Catalyst::Manual> for more documentation.
 223
 224 Catalyst plugins can be loaded by naming them as arguments to the "use
 225 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 226 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 227 C<My::Module>.
 228
 229     use Catalyst qw/My::Module/;
 230
 231 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 232 fully qualify the name by using a unary plus:
 233
 234     use Catalyst qw/
 235         My::Module
 236         +Fully::Qualified::Plugin::Name
 237     /;
 238
 239 Special flags like C<-Debug> and C<-Engine> can also be specified as
 240 arguments when Catalyst is loaded:
 241
 242     use Catalyst qw/-Debug My::Module/;
 243
 244 The position of plugins and flags in the chain is important, because
 245 they are loaded in the order in which they appear.
 246
 247 The following flags are supported:
 248
 249 =head2 -Debug
 250
 251 Enables debug output. You can also force this setting from the system
 252 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 253 settings override the application, with <MYAPP>_DEBUG having the highest
 254 priority.
 255
 256 This sets the log level to 'debug' and enables full debug output on the
 257 error screen. If you only want the latter, see L<< $c->debug >>.
 258
 259 =head2 -Engine
 260
 261 Forces Catalyst to use a specific engine. Omit the
 262 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 263
 264     use Catalyst qw/-Engine=CGI/;
 265
 266 =head2 -Home
 267
 268 Forces Catalyst to use a specific home directory, e.g.:
 269
 270     use Catalyst qw[-Home=/usr/mst];
 271
 272 This can also be done in the shell environment by setting either the
 273 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 274 is replaced with the uppercased name of your application, any "::" in
 275 the name will be replaced with underscores, e.g. MyApp::Web should use
 276 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 277
 278 If none of these are set, Catalyst will attempt to automatically detect the
 279 home directory. If you are working in a development environment, Catalyst
 280 will try and find the directory containing either Makefile.PL, Build.PL or
 281 dist.ini. If the application has been installed into the system (i.e.
 282 you have done C<make install>), then Catalyst will use the path to your
 283 application module, without the .pm extension (e.g., /foo/MyApp if your
 284 application was installed at /foo/MyApp.pm)
 285
 286 =head2 -Log
 287
 288     use Catalyst '-Log=warn,fatal,error';
 289
 290 Specifies a comma-delimited list of log levels.
 291
 292 =head2 -Stats
 293
 294 Enables statistics collection and reporting.
 295
 296    use Catalyst qw/-Stats=1/;
 297
 298 You can also force this setting from the system environment with CATALYST_STATS
 299 or <MYAPP>_STATS. The environment settings override the application, with
 300 <MYAPP>_STATS having the highest priority.
 301
 302 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 303
 304 =head1 METHODS
 305
 306 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 307
 308 =head2 $c->action
 309
 310 Returns a L<Catalyst::Action> object for the current action, which
 311 stringifies to the action name. See L<Catalyst::Action>.
 312
 313 =head2 $c->namespace
 314
 315 Returns the namespace of the current action, i.e., the URI prefix
 316 corresponding to the controller of the current action. For example:
 317
 318     # in Controller::Foo::Bar
 319     $c->namespace; # returns 'foo/bar';
 320
 321 =head2 $c->request
 322
 323 =head2 $c->req
 324
 325 Returns the current L<Catalyst::Request> object, giving access to
 326 information about the current client request (including parameters,
 327 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 328
 329 =head2 REQUEST FLOW HANDLING
 330
 331 =head2 $c->forward( $action [, \@arguments ] )
 332
 333 =head2 $c->forward( $class, $method, [, \@arguments ] )
 334
 335 Forwards processing to another action, by its private name. If you give a
 336 class name but no method, C<process()> is called. You may also optionally
 337 pass arguments in an arrayref. The action will receive the arguments in
 338 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 339 C<< $c->req->args >> will be restored to the previous values.
 340
 341 Any data C<return>ed from the action forwarded to, will be returned by the
 342 call to forward.
 343
 344     my $foodata = $c->forward('/foo');
 345     $c->forward('index');
 346     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 347     $c->forward('View::TT');
 348
 349 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 350 an C<< eval { } >> around the call (actually
 351 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 352 exceptions thrown by the called action non-fatal and pushing them onto
 353 $c->error instead. If you want C<die> to propagate you need to do something
 354 like:
 355
 356     $c->forward('foo');
 357     die join "\n", @{ $c->error } if @{ $c->error };
 358
 359 Or make sure to always return true values from your actions and write
 360 your code like this:
 361
 362     $c->forward('foo') || return;
 363
 364 Another note is that C<< $c->forward >> always returns a scalar because it
 365 actually returns $c->state which operates in a scalar context.
 366 Thus, something like:
 367
 368     return @array;
 369
 370 in an action that is forwarded to is going to return a scalar,
 371 i.e. how many items are in that array, which is probably not what you want.
 372 If you need to return an array then return a reference to it,
 373 or stash it like so:
 374
 375     $c->stash->{array} = \@array;
 376
 377 and access it from the stash.
 378
 379 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 380
 381 =cut
 382
 383 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 384
 385 =head2 $c->detach( $action [, \@arguments ] )
 386
 387 =head2 $c->detach( $class, $method, [, \@arguments ] )
 388
 389 =head2 $c->detach()
 390
 391 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 392 doesn't return to the previous action when processing is finished.
 393
 394 When called with no arguments it escapes the processing chain entirely.
 395
 396 =cut
 397
 398 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 399
 400 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 401
 402 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 403
 404 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 405 but does a full dispatch, instead of just calling the new C<$action> /
 406 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 407 you go to are called, just like a new request.
 408
 409 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 410 This means, for example, that C<< $c->action >> methods such as
 411 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 412 L<reverse|Catalyst::Action/reverse> return information for the visited action
 413 when they are invoked within the visited action.  This is different from the
 414 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 415 continues to use the $c->action object from the caller action even when
 416 invoked from the called action.
 417
 418 C<< $c->stash >> is kept unchanged.
 419
 420 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 421 allows you to "wrap" another action, just as it would have been called by
 422 dispatching from a URL, while the analogous
 423 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 424 transfer control to another action as if it had been reached directly from a URL.
 425
 426 =cut
 427
 428 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 429
 430 =head2 $c->go( $action [, \@captures, \@arguments ] )
 431
 432 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 433
 434 The relationship between C<go> and
 435 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 436 the relationship between
 437 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 438 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 439 C<< $c->go >> will perform a full dispatch on the specified action or method,
 440 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 441 C<go> escapes the processing of the current request chain on completion, and
 442 does not return to its caller.
 443
 444 @arguments are arguments to the final destination of $action. @captures are
 445 arguments to the intermediate steps, if any, on the way to the final sub of
 446 $action.
 447
 448 =cut
 449
 450 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 451
 452 =head2 $c->response
 453
 454 =head2 $c->res
 455
 456 Returns the current L<Catalyst::Response> object, see there for details.
 457
 458 =head2 $c->stash
 459
 460 Returns a hashref to the stash, which may be used to store data and pass
 461 it between components during a request. You can also set hash keys by
 462 passing arguments. The stash is automatically sent to the view. The
 463 stash is cleared at the end of a request; it cannot be used for
 464 persistent storage (for this you must use a session; see
 465 L<Catalyst::Plugin::Session> for a complete system integrated with
 466 Catalyst).
 467
 468     $c->stash->{foo} = $bar;
 469     $c->stash( { moose => 'majestic', qux => 0 } );
 470     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 471
 472     # stash is automatically passed to the view for use in a template
 473     $c->forward( 'MyApp::View::TT' );
 474
 475 =cut
 476
 477 around stash => sub {
 478     my $orig = shift;
 479     my $c = shift;
 480     my $stash = $orig->($c);
 481     if (@_) {
 482         my $new_stash = @_ > 1 ? {@_} : $_[0];
 483         croak('stash takes a hash or hashref') unless ref $new_stash;
 484         foreach my $key ( keys %$new_stash ) {
 485           $stash->{$key} = $new_stash->{$key};
 486         }
 487     }
 488
 489     return $stash;
 490 };
 491
 492
 493 =head2 $c->error
 494
 495 =head2 $c->error($error, ...)
 496
 497 =head2 $c->error($arrayref)
 498
 499 Returns an arrayref containing error messages.  If Catalyst encounters an
 500 error while processing a request, it stores the error in $c->error.  This
 501 method should only be used to store fatal error messages.
 502
 503     my @error = @{ $c->error };
 504
 505 Add a new error.
 506
 507     $c->error('Something bad happened');
 508
 509 =cut
 510
 511 sub error {
 512     my $c = shift;
 513     if ( $_[0] ) {
 514         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 515         croak @$error unless ref $c;
 516         push @{ $c->{error} }, @$error;
 517     }
 518     elsif ( defined $_[0] ) { $c->{error} = undef }
 519     return $c->{error} || [];
 520 }
 521
 522
 523 =head2 $c->state
 524
 525 Contains the return value of the last executed action.
 526 Note that << $c->state >> operates in a scalar context which means that all
 527 values it returns are scalar.
 528
 529 =head2 $c->clear_errors
 530
 531 Clear errors.  You probably don't want to clear the errors unless you are
 532 implementing a custom error screen.
 533
 534 This is equivalent to running
 535
 536     $c->error(0);
 537
 538 =cut
 539
 540 sub clear_errors {
 541     my $c = shift;
 542     $c->error(0);
 543 }
 544
 545 sub _comp_search_prefixes {
 546     my $c = shift;
 547     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 548 }
 549
 550 # search components given a name and some prefixes
 551 sub _comp_names_search_prefixes {
 552     my ( $c, $name, @prefixes ) = @_;
 553     my $appclass = ref $c || $c;
 554     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 555     $filter = qr/$filter/; # Compile regex now rather than once per loop
 556
 557     # map the original component name to the sub part that we will search against
 558     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 559         grep { /$filter/ } keys %{ $c->components };
 560
 561     # undef for a name will return all
 562     return keys %eligible if !defined $name;
 563
 564     my $query  = ref $name ? $name : qr/^$name$/i;
 565     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 566
 567     return @result if @result;
 568
 569     # if we were given a regexp to search against, we're done.
 570     return if ref $name;
 571
 572     # skip regexp fallback if configured
 573     return
 574         if $appclass->config->{disable_component_resolution_regex_fallback};
 575
 576     # regexp fallback
 577     $query  = qr/$name/i;
 578     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 579
 580     # no results? try against full names
 581     if( !@result ) {
 582         @result = grep { m{$query} } keys %eligible;
 583     }
 584
 585     # don't warn if we didn't find any results, it just might not exist
 586     if( @result ) {
 587         # Disgusting hack to work out correct method name
 588         my $warn_for = lc $prefixes[0];
 589         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 590            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 591            "component resolution is unreliable and unsafe.";
 592         my $short = $result[0];
 593         # remove the component namespace prefix
 594         $short =~ s/.*?(Model|Controller|View):://;
 595         my $shortmess = Carp::shortmess('');
 596         if ($shortmess =~ m#Catalyst/Plugin#) {
 597            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 598               "plugin's config";
 599         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 600            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 601               "component's config";
 602         } else {
 603            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 604               "but if you really wanted to search, pass in a regexp as the argument " .
 605               "like so: \$c->${warn_for}(qr/${name}/)";
 606         }
 607         $c->log->warn( "${msg}$shortmess" );
 608     }
 609
 610     return @result;
 611 }
 612
 613 # Find possible names for a prefix
 614 sub _comp_names {
 615     my ( $c, @prefixes ) = @_;
 616     my $appclass = ref $c || $c;
 617
 618     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 619
 620     my @names = map { s{$filter}{}; $_; }
 621         $c->_comp_names_search_prefixes( undef, @prefixes );
 622
 623     return @names;
 624 }
 625
 626 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 627 sub _filter_component {
 628     my ( $c, $comp, @args ) = @_;
 629
 630     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 631         return $comp->ACCEPT_CONTEXT( $c, @args );
 632     }
 633
 634     return $comp;
 635 }
 636
 637 =head2 COMPONENT ACCESSORS
 638
 639 =head2 $c->controller($name)
 640
 641 Gets a L<Catalyst::Controller> instance by name.
 642
 643     $c->controller('Foo')->do_stuff;
 644
 645 If the name is omitted, will return the controller for the dispatched
 646 action.
 647
 648 If you want to search for controllers, pass in a regexp as the argument.
 649
 650     # find all controllers that start with Foo
 651     my @foo_controllers = $c->controller(qr{^Foo});
 652
 653
 654 =cut
 655
 656 sub controller {
 657     my ( $c, $name, @args ) = @_;
 658
 659     my $appclass = ref($c) || $c;
 660     if( $name ) {
 661         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 662             my $comps = $c->components;
 663             my $check = $appclass."::Controller::".$name;
 664             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 665         }
 666         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 667         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 668         return $c->_filter_component( $result[ 0 ], @args );
 669     }
 670
 671     return $c->component( $c->action->class );
 672 }
 673
 674 =head2 $c->model($name)
 675
 676 Gets a L<Catalyst::Model> instance by name.
 677
 678     $c->model('Foo')->do_stuff;
 679
 680 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 681
 682 If the name is omitted, it will look for
 683  - a model object in $c->stash->{current_model_instance}, then
 684  - a model name in $c->stash->{current_model}, then
 685  - a config setting 'default_model', or
 686  - check if there is only one model, and return it if that's the case.
 687
 688 If you want to search for models, pass in a regexp as the argument.
 689
 690     # find all models that start with Foo
 691     my @foo_models = $c->model(qr{^Foo});
 692
 693 =cut
 694
 695 sub model {
 696     my ( $c, $name, @args ) = @_;
 697     my $appclass = ref($c) || $c;
 698     if( $name ) {
 699         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 700             my $comps = $c->components;
 701             my $check = $appclass."::Model::".$name;
 702             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 703         }
 704         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 705         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 706         return $c->_filter_component( $result[ 0 ], @args );
 707     }
 708
 709     if (ref $c) {
 710         return $c->stash->{current_model_instance}
 711           if $c->stash->{current_model_instance};
 712         return $c->model( $c->stash->{current_model} )
 713           if $c->stash->{current_model};
 714     }
 715     return $c->model( $appclass->config->{default_model} )
 716       if $appclass->config->{default_model};
 717
 718     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 719
 720     if( $rest ) {
 721         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 722         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 723         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 724         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 725         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 726     }
 727
 728     return $c->_filter_component( $comp );
 729 }
 730
 731
 732 =head2 $c->view($name)
 733
 734 Gets a L<Catalyst::View> instance by name.
 735
 736     $c->view('Foo')->do_stuff;
 737
 738 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 739
 740 If the name is omitted, it will look for
 741  - a view object in $c->stash->{current_view_instance}, then
 742  - a view name in $c->stash->{current_view}, then
 743  - a config setting 'default_view', or
 744  - check if there is only one view, and return it if that's the case.
 745
 746 If you want to search for views, pass in a regexp as the argument.
 747
 748     # find all views that start with Foo
 749     my @foo_views = $c->view(qr{^Foo});
 750
 751 =cut
 752
 753 sub view {
 754     my ( $c, $name, @args ) = @_;
 755
 756     my $appclass = ref($c) || $c;
 757     if( $name ) {
 758         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 759             my $comps = $c->components;
 760             my $check = $appclass."::View::".$name;
 761             if( exists $comps->{$check} ) {
 762                 return $c->_filter_component( $comps->{$check}, @args );
 763             }
 764             else {
 765                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 766             }
 767         }
 768         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 769         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 770         return $c->_filter_component( $result[ 0 ], @args );
 771     }
 772
 773     if (ref $c) {
 774         return $c->stash->{current_view_instance}
 775           if $c->stash->{current_view_instance};
 776         return $c->view( $c->stash->{current_view} )
 777           if $c->stash->{current_view};
 778     }
 779     return $c->view( $appclass->config->{default_view} )
 780       if $appclass->config->{default_view};
 781
 782     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 783
 784     if( $rest ) {
 785         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 786         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 787         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 788         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 789         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 790     }
 791
 792     return $c->_filter_component( $comp );
 793 }
 794
 795 =head2 $c->controllers
 796
 797 Returns the available names which can be passed to $c->controller
 798
 799 =cut
 800
 801 sub controllers {
 802     my ( $c ) = @_;
 803     return $c->_comp_names(qw/Controller C/);
 804 }
 805
 806 =head2 $c->models
 807
 808 Returns the available names which can be passed to $c->model
 809
 810 =cut
 811
 812 sub models {
 813     my ( $c ) = @_;
 814     return $c->_comp_names(qw/Model M/);
 815 }
 816
 817
 818 =head2 $c->views
 819
 820 Returns the available names which can be passed to $c->view
 821
 822 =cut
 823
 824 sub views {
 825     my ( $c ) = @_;
 826     return $c->_comp_names(qw/View V/);
 827 }
 828
 829 =head2 $c->comp($name)
 830
 831 =head2 $c->component($name)
 832
 833 Gets a component object by name. This method is not recommended,
 834 unless you want to get a specific component by full
 835 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 836 should be used instead.
 837
 838 If C<$name> is a regexp, a list of components matched against the full
 839 component name will be returned.
 840
 841 If Catalyst can't find a component by name, it will fallback to regex
 842 matching by default. To disable this behaviour set
 843 disable_component_resolution_regex_fallback to a true value.
 844
 845     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 846
 847 =cut
 848
 849 sub component {
 850     my ( $c, $name, @args ) = @_;
 851
 852     if( $name ) {
 853         my $comps = $c->components;
 854
 855         if( !ref $name ) {
 856             # is it the exact name?
 857             return $c->_filter_component( $comps->{ $name }, @args )
 858                        if exists $comps->{ $name };
 859
 860             # perhaps we just omitted "MyApp"?
 861             my $composed = ( ref $c || $c ) . "::${name}";
 862             return $c->_filter_component( $comps->{ $composed }, @args )
 863                        if exists $comps->{ $composed };
 864
 865             # search all of the models, views and controllers
 866             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 867             return $c->_filter_component( $comp, @args ) if $comp;
 868         }
 869
 870         return
 871             if $c->config->{disable_component_resolution_regex_fallback};
 872
 873         # This is here so $c->comp( '::M::' ) works
 874         my $query = ref $name ? $name : qr{$name}i;
 875
 876         my @result = grep { m{$query} } keys %{ $c->components };
 877         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 878
 879         if( $result[ 0 ] ) {
 880             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 881             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 882             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 883             return $c->_filter_component( $result[ 0 ], @args );
 884         }
 885
 886         # I would expect to return an empty list here, but that breaks back-compat
 887     }
 888
 889     # fallback
 890     return sort keys %{ $c->components };
 891 }
 892
 893 =head2 CLASS DATA AND HELPER CLASSES
 894
 895 =head2 $c->config
 896
 897 Returns or takes a hashref containing the application's configuration.
 898
 899     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 900
 901 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 902 like C<myapp.conf> in your applications home directory. See
 903 L<Catalyst::Plugin::ConfigLoader>.
 904
 905 =head3 Cascading configuration
 906
 907 The config method is present on all Catalyst components, and configuration
 908 will be merged when an application is started. Configuration loaded with
 909 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 910 followed by configuration in your top level C<MyApp> class. These two
 911 configurations are merged, and then configuration data whose hash key matches a
 912 component name is merged with configuration for that component.
 913
 914 The configuration for a component is then passed to the C<new> method when a
 915 component is constructed.
 916
 917 For example:
 918
 919     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 920     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 921
 922 will mean that C<MyApp::Model::Foo> receives the following data when
 923 constructed:
 924
 925     MyApp::Model::Foo->new({
 926         bar => 'baz',
 927         quux => 'frob',
 928         overrides => 'me',
 929     });
 930
 931 It's common practice to use a Moose attribute
 932 on the receiving component to access the config value.
 933
 934     package MyApp::Model::Foo;
 935
 936     use Moose;
 937
 938     # this attr will receive 'baz' at construction time
 939     has 'bar' => (
 940         is  => 'rw',
 941         isa => 'Str',
 942     );
 943
 944 You can then get the value 'baz' by calling $c->model('Foo')->bar
 945 (or $self->bar inside code in the model).
 946
 947 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 948 as a way of reading config within your code, as this B<will not> give you the
 949 correctly merged config back. You B<MUST> take the config values supplied to
 950 the constructor and use those instead.
 951
 952 =cut
 953
 954 around config => sub {
 955     my $orig = shift;
 956     my $c = shift;
 957
 958     croak('Setting config after setup has been run is not allowed.')
 959         if ( @_ and $c->setup_finished );
 960
 961     $c->$orig(@_);
 962 };
 963
 964 =head2 $c->log
 965
 966 Returns the logging object instance. Unless it is already set, Catalyst
 967 sets this up with a L<Catalyst::Log> object. To use your own log class,
 968 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 969 C<< __PACKAGE__->setup >>.
 970
 971  __PACKAGE__->log( MyLogger->new );
 972  __PACKAGE__->setup;
 973
 974 And later:
 975
 976     $c->log->info( 'Now logging with my own logger!' );
 977
 978 Your log class should implement the methods described in
 979 L<Catalyst::Log>.
 980
 981
 982 =head2 $c->debug
 983
 984 Returns 1 if debug mode is enabled, 0 otherwise.
 985
 986 You can enable debug mode in several ways:
 987
 988 =over
 989
 990 =item By calling myapp_server.pl with the -d flag
 991
 992 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 993
 994 =item The -Debug option in your MyApp.pm
 995
 996 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 997
 998 =back
 999
1000 The first three also set the log level to 'debug'.
1001
1002 Calling C<< $c->debug(1) >> has no effect.
1003
1004 =cut
1005
1006 sub debug { 0 }
1007
1008 =head2 $c->dispatcher
1009
1010 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1011
1012 =head2 $c->engine
1013
1014 Returns the engine instance. See L<Catalyst::Engine>.
1015
1016
1017 =head2 UTILITY METHODS
1018
1019 =head2 $c->path_to(@path)
1020
1021 Merges C<@path> with C<< $c->config->{home} >> and returns a
1022 L<Path::Class::Dir> object. Note you can usually use this object as
1023 a filename, but sometimes you will have to explicitly stringify it
1024 yourself by calling the C<< ->stringify >> method.
1025
1026 For example:
1027
1028     $c->path_to( 'db', 'sqlite.db' );
1029
1030 =cut
1031
1032 sub path_to {
1033     my ( $c, @path ) = @_;
1034     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1035     if ( -d $path ) { return $path }
1036     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1037 }
1038
1039 =head2 $c->plugin( $name, $class, @args )
1040
1041 Helper method for plugins. It creates a class data accessor/mutator and
1042 loads and instantiates the given class.
1043
1044     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1045
1046     $c->prototype->define_javascript_functions;
1047
1048 B<Note:> This method of adding plugins is deprecated. The ability
1049 to add plugins like this B<will be removed> in a Catalyst 5.81.
1050 Please do not use this functionality in new code.
1051
1052 =cut
1053
1054 sub plugin {
1055     my ( $class, $name, $plugin, @args ) = @_;
1056
1057     # See block comment in t/unit_core_plugin.t
1058     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1059
1060     $class->_register_plugin( $plugin, 1 );
1061
1062     eval { $plugin->import };
1063     $class->mk_classdata($name);
1064     my $obj;
1065     eval { $obj = $plugin->new(@args) };
1066
1067     if ($@) {
1068         Catalyst::Exception->throw( message =>
1069               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1070     }
1071
1072     $class->$name($obj);
1073     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1074       if $class->debug;
1075 }
1076
1077 =head2 MyApp->setup
1078
1079 Initializes the dispatcher and engine, loads any plugins, and loads the
1080 model, view, and controller components. You may also specify an array
1081 of plugins to load here, if you choose to not load them in the C<use
1082 Catalyst> line.
1083
1084     MyApp->setup;
1085     MyApp->setup( qw/-Debug/ );
1086
1087 =cut
1088
1089 sub setup {
1090     my ( $class, @arguments ) = @_;
1091     croak('Running setup more than once')
1092         if ( $class->setup_finished );
1093
1094     unless ( $class->isa('Catalyst') ) {
1095
1096         Catalyst::Exception->throw(
1097             message => qq/'$class' does not inherit from Catalyst/ );
1098     }
1099
1100     if ( $class->arguments ) {
1101         @arguments = ( @arguments, @{ $class->arguments } );
1102     }
1103
1104     # Process options
1105     my $flags = {};
1106
1107     foreach (@arguments) {
1108
1109         if (/^-Debug$/) {
1110             $flags->{log} =
1111               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1112         }
1113         elsif (/^-(\w+)=?(.*)$/) {
1114             $flags->{ lc $1 } = $2;
1115         }
1116         else {
1117             push @{ $flags->{plugins} }, $_;
1118         }
1119     }
1120
1121     $class->setup_home( delete $flags->{home} );
1122
1123     $class->setup_log( delete $flags->{log} );
1124     $class->setup_plugins( delete $flags->{plugins} );
1125     $class->setup_dispatcher( delete $flags->{dispatcher} );
1126     if (my $engine = delete $flags->{engine}) {
1127         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1128     }
1129     $class->setup_engine();
1130     $class->setup_stats( delete $flags->{stats} );
1131
1132     for my $flag ( sort keys %{$flags} ) {
1133
1134         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1135             &$code( $class, delete $flags->{$flag} );
1136         }
1137         else {
1138             $class->log->warn(qq/Unknown flag "$flag"/);
1139         }
1140     }
1141
1142     eval { require Catalyst::Devel; };
1143     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1144         $class->log->warn(<<"EOF");
1145 You are running an old script!
1146
1147   Please update by running (this will overwrite existing files):
1148     catalyst.pl -force -scripts $class
1149
1150   or (this will not overwrite existing files):
1151     catalyst.pl -scripts $class
1152
1153 EOF
1154     }
1155
1156     if ( $class->debug ) {
1157         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1158
1159         if (@plugins) {
1160             my $column_width = Catalyst::Utils::term_width() - 6;
1161             my $t = Text::SimpleTable->new($column_width);
1162             $t->row($_) for @plugins;
1163             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1164         }
1165
1166         my $dispatcher = $class->dispatcher;
1167         my $engine     = $class->engine;
1168         my $home       = $class->config->{home};
1169
1170         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1171         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1172
1173         $home
1174           ? ( -d $home )
1175           ? $class->log->debug(qq/Found home "$home"/)
1176           : $class->log->debug(qq/Home "$home" doesn't exist/)
1177           : $class->log->debug(q/Couldn't find home/);
1178     }
1179
1180     # Call plugins setup, this is stupid and evil.
1181     # Also screws C3 badly on 5.10, hack to avoid.
1182     {
1183         no warnings qw/redefine/;
1184         local *setup = sub { };
1185         $class->setup unless $Catalyst::__AM_RESTARTING;
1186     }
1187
1188     # Initialize our data structure
1189     $class->components( {} );
1190
1191     $class->setup_components;
1192
1193     if ( $class->debug ) {
1194         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1195         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1196         for my $comp ( sort keys %{ $class->components } ) {
1197             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1198             $t->row( $comp, $type );
1199         }
1200         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1201           if ( keys %{ $class->components } );
1202     }
1203
1204     # Add our self to components, since we are also a component
1205     if( $class->isa('Catalyst::Controller') ){
1206       $class->components->{$class} = $class;
1207     }
1208
1209     $class->setup_actions;
1210
1211     if ( $class->debug ) {
1212         my $name = $class->config->{name} || 'Application';
1213         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1214     }
1215
1216     # Make sure that the application class becomes immutable at this point,
1217     B::Hooks::EndOfScope::on_scope_end {
1218         return if $@;
1219         my $meta = Class::MOP::get_metaclass_by_name($class);
1220         if (
1221             $meta->is_immutable
1222             && ! { $meta->immutable_options }->{replace_constructor}
1223             && (
1224                    $class->isa('Class::Accessor::Fast')
1225                 || $class->isa('Class::Accessor')
1226             )
1227         ) {
1228             warn "You made your application class ($class) immutable, "
1229                 . "but did not inline the\nconstructor. "
1230                 . "This will break catalyst, as your app \@ISA "
1231                 . "Class::Accessor(::Fast)?\nPlease pass "
1232                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1233         }
1234         $meta->make_immutable(
1235             replace_constructor => 1,
1236         ) unless $meta->is_immutable;
1237     };
1238
1239     if ($class->config->{case_sensitive}) {
1240         $class->log->warn($class . "->config->{case_sensitive} is set.");
1241         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1242     }
1243
1244     $class->setup_finalize;
1245     # Should be the last thing we do so that user things hooking
1246     # setup_finalize can log..
1247     $class->log->_flush() if $class->log->can('_flush');
1248     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1249 }
1250
1251 =head2 $app->setup_finalize
1252
1253 A hook to attach modifiers to. This method does not do anything except set the
1254 C<setup_finished> accessor.
1255
1256 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1257
1258 Example:
1259
1260     after setup_finalize => sub {
1261         my $app = shift;
1262
1263         ## do stuff here..
1264     };
1265
1266 =cut
1267
1268 sub setup_finalize {
1269     my ($class) = @_;
1270     $class->setup_finished(1);
1271 }
1272
1273 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1274
1275 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1276
1277 Constructs an absolute L<URI> object based on the application root, the
1278 provided path, and the additional arguments and query parameters provided.
1279 When used as a string, provides a textual URI.  If you need more flexibility
1280 than this (i.e. the option to provide relative URIs etc.) see
1281 L<Catalyst::Plugin::SmartURI>.
1282
1283 If no arguments are provided, the URI for the current action is returned.
1284 To return the current action and also provide @args, use
1285 C<< $c->uri_for( $c->action, @args ) >>.
1286
1287 If the first argument is a string, it is taken as a public URI path relative
1288 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1289 relative to the application root (if it does). It is then merged with
1290 C<< $c->request->base >>; any C<@args> are appended as additional path
1291 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1292
1293 If the first argument is a L<Catalyst::Action> it represents an action which
1294 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1295 optional C<\@captures> argument (an arrayref) allows passing the captured
1296 variables that are needed to fill in the paths of Chained and Regex actions;
1297 once the path is resolved, C<uri_for> continues as though a path was
1298 provided, appending any arguments or parameters and creating an absolute
1299 URI.
1300
1301 The captures for the current request can be found in
1302 C<< $c->request->captures >>, and actions can be resolved using
1303 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1304 path, use C<< $c->uri_for_action >> instead.
1305
1306   # Equivalent to $c->req->uri
1307   $c->uri_for($c->action, $c->req->captures,
1308       @{ $c->req->args }, $c->req->params);
1309
1310   # For the Foo action in the Bar controller
1311   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1312
1313   # Path to a static resource
1314   $c->uri_for('/static/images/logo.png');
1315
1316 =cut
1317
1318 sub uri_for {
1319     my ( $c, $path, @args ) = @_;
1320
1321     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1322         $path = $path->path_prefix;
1323         $path =~ s{/+\z}{};
1324         $path .= '/';
1325     }
1326
1327     undef($path) if (defined $path && $path eq '');
1328
1329     my $params =
1330       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1331
1332     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1333     foreach my $arg (@args) {
1334         utf8::encode($arg) if utf8::is_utf8($arg);
1335         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1336     }
1337
1338     if ( blessed($path) ) { # action object
1339         s|/|%2F|g for @args;
1340         my $captures = [ map { s|/|%2F|g; $_; }
1341                         ( scalar @args && ref $args[0] eq 'ARRAY'
1342                          ? @{ shift(@args) }
1343                          : ()) ];
1344
1345         foreach my $capture (@$captures) {
1346             utf8::encode($capture) if utf8::is_utf8($capture);
1347             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1348         }
1349
1350         my $action = $path;
1351         $path = $c->dispatcher->uri_for_action($action, $captures);
1352         if (not defined $path) {
1353             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1354                 if $c->debug;
1355             return undef;
1356         }
1357         $path = '/' if $path eq '';
1358     }
1359
1360     unshift(@args, $path);
1361
1362     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1363         my $namespace = $c->namespace;
1364         if (defined $path) { # cheesy hack to handle path '../foo'
1365            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1366         }
1367         unshift(@args, $namespace || '');
1368     }
1369
1370     # join args with '/', or a blank string
1371     my $args = join('/', grep { defined($_) } @args);
1372     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1373     $args =~ s!^/+!!;
1374     my $base = $c->req->base;
1375     my $class = ref($base);
1376     $base =~ s{(?<!/)$}{/};
1377
1378     my $query = '';
1379
1380     if (my @keys = keys %$params) {
1381       # somewhat lifted from URI::_query's query_form
1382       $query = '?'.join('&', map {
1383           my $val = $params->{$_};
1384           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1385           s/ /+/g;
1386           my $key = $_;
1387           $val = '' unless defined $val;
1388           (map {
1389               my $param = "$_";
1390               utf8::encode( $param ) if utf8::is_utf8($param);
1391               # using the URI::Escape pattern here so utf8 chars survive
1392               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1393               $param =~ s/ /+/g;
1394               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1395       } @keys);
1396     }
1397
1398     my $res = bless(\"${base}${args}${query}", $class);
1399     $res;
1400 }
1401
1402 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1403
1404 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1405
1406 =over
1407
1408 =item $path
1409
1410 A private path to the Catalyst action you want to create a URI for.
1411
1412 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1413 >> and passing the resulting C<$action> and the remaining arguments to C<<
1414 $c->uri_for >>.
1415
1416 You can also pass in a Catalyst::Action object, in which case it is passed to
1417 C<< $c->uri_for >>.
1418
1419 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1420
1421 For example, if the action looks like:
1422
1423  package MyApp::Controller::Users;
1424
1425  sub lst : Path('the-list') {}
1426
1427 You can use:
1428
1429  $c->uri_for_action('/users/lst')
1430
1431 and it will create the URI /users/the-list.
1432
1433 =back
1434
1435 =cut
1436
1437 sub uri_for_action {
1438     my ( $c, $path, @args ) = @_;
1439     my $action = blessed($path)
1440       ? $path
1441       : $c->dispatcher->get_action_by_path($path);
1442     unless (defined $action) {
1443       croak "Can't find action for path '$path'";
1444     }
1445     return $c->uri_for( $action, @args );
1446 }
1447
1448 =head2 $c->welcome_message
1449
1450 Returns the Catalyst welcome HTML page.
1451
1452 =cut
1453
1454 sub welcome_message {
1455     my $c      = shift;
1456     my $name   = $c->config->{name};
1457     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1458     my $prefix = Catalyst::Utils::appprefix( ref $c );
1459     $c->response->content_type('text/html; charset=utf-8');
1460     return <<"EOF";
1461 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1462     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1463 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1464     <head>
1465     <meta http-equiv="Content-Language" content="en" />
1466     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1467         <title>$name on Catalyst $VERSION</title>
1468         <style type="text/css">
1469             body {
1470                 color: #000;
1471                 background-color: #eee;
1472             }
1473             div#content {
1474                 width: 640px;
1475                 margin-left: auto;
1476                 margin-right: auto;
1477                 margin-top: 10px;
1478                 margin-bottom: 10px;
1479                 text-align: left;
1480                 background-color: #ccc;
1481                 border: 1px solid #aaa;
1482             }
1483             p, h1, h2 {
1484                 margin-left: 20px;
1485                 margin-right: 20px;
1486                 font-family: verdana, tahoma, sans-serif;
1487             }
1488             a {
1489                 font-family: verdana, tahoma, sans-serif;
1490             }
1491             :link, :visited {
1492                     text-decoration: none;
1493                     color: #b00;
1494                     border-bottom: 1px dotted #bbb;
1495             }
1496             :link:hover, :visited:hover {
1497                     color: #555;
1498             }
1499             div#topbar {
1500                 margin: 0px;
1501             }
1502             pre {
1503                 margin: 10px;
1504                 padding: 8px;
1505             }
1506             div#answers {
1507                 padding: 8px;
1508                 margin: 10px;
1509                 background-color: #fff;
1510                 border: 1px solid #aaa;
1511             }
1512             h1 {
1513                 font-size: 0.9em;
1514                 font-weight: normal;
1515                 text-align: center;
1516             }
1517             h2 {
1518                 font-size: 1.0em;
1519             }
1520             p {
1521                 font-size: 0.9em;
1522             }
1523             p img {
1524                 float: right;
1525                 margin-left: 10px;
1526             }
1527             span#appname {
1528                 font-weight: bold;
1529                 font-size: 1.6em;
1530             }
1531         </style>
1532     </head>
1533     <body>
1534         <div id="content">
1535             <div id="topbar">
1536                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1537                     $VERSION</h1>
1538              </div>
1539              <div id="answers">
1540                  <p>
1541                  <img src="$logo" alt="Catalyst Logo" />
1542                  </p>
1543                  <p>Welcome to the  world of Catalyst.
1544                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1545                     framework will make web development something you had
1546                     never expected it to be: Fun, rewarding, and quick.</p>
1547                  <h2>What to do now?</h2>
1548                  <p>That really depends  on what <b>you</b> want to do.
1549                     We do, however, provide you with a few starting points.</p>
1550                  <p>If you want to jump right into web development with Catalyst
1551                     you might want to start with a tutorial.</p>
1552 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1553 </pre>
1554 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1555 <pre>
1556 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1557 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1558 </code></pre>
1559                  <h2>What to do next?</h2>
1560                  <p>Next it's time to write an actual application. Use the
1561                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1562                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1563                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1564                     they can save you a lot of work.</p>
1565                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1566                     <p>Also, be sure to check out the vast and growing
1567                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1568                     you are likely to find what you need there.
1569                     </p>
1570
1571                  <h2>Need help?</h2>
1572                  <p>Catalyst has a very active community. Here are the main places to
1573                     get in touch with us.</p>
1574                  <ul>
1575                      <li>
1576                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1577                      </li>
1578                      <li>
1579                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1580                      </li>
1581                      <li>
1582                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1583                      </li>
1584                  </ul>
1585                  <h2>In conclusion</h2>
1586                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1587                     as we enjoyed making it. Please contact us if you have ideas
1588                     for improvement or other feedback.</p>
1589              </div>
1590          </div>
1591     </body>
1592 </html>
1593 EOF
1594 }
1595
1596 =head1 INTERNAL METHODS
1597
1598 These methods are not meant to be used by end users.
1599
1600 =head2 $c->components
1601
1602 Returns a hash of components.
1603
1604 =head2 $c->context_class
1605
1606 Returns or sets the context class.
1607
1608 =head2 $c->counter
1609
1610 Returns a hashref containing coderefs and execution counts (needed for
1611 deep recursion detection).
1612
1613 =head2 $c->depth
1614
1615 Returns the number of actions on the current internal execution stack.
1616
1617 =head2 $c->dispatch
1618
1619 Dispatches a request to actions.
1620
1621 =cut
1622
1623 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1624
1625 =head2 $c->dispatcher_class
1626
1627 Returns or sets the dispatcher class.
1628
1629 =head2 $c->dump_these
1630
1631 Returns a list of 2-element array references (name, structure) pairs
1632 that will be dumped on the error page in debug mode.
1633
1634 =cut
1635
1636 sub dump_these {
1637     my $c = shift;
1638     [ Request => $c->req ],
1639     [ Response => $c->res ],
1640     [ Stash => $c->stash ],
1641     [ Config => $c->config ];
1642 }
1643
1644 =head2 $c->engine_class
1645
1646 Returns or sets the engine class.
1647
1648 =head2 $c->execute( $class, $coderef )
1649
1650 Execute a coderef in given class and catch exceptions. Errors are available
1651 via $c->error.
1652
1653 =cut
1654
1655 sub execute {
1656     my ( $c, $class, $code ) = @_;
1657     $class = $c->component($class) || $class;
1658     $c->state(0);
1659
1660     if ( $c->depth >= $RECURSION ) {
1661         my $action = $code->reverse();
1662         $action = "/$action" unless $action =~ /->/;
1663         my $error = qq/Deep recursion detected calling "${action}"/;
1664         $c->log->error($error);
1665         $c->error($error);
1666         $c->state(0);
1667         return $c->state;
1668     }
1669
1670     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1671
1672     push( @{ $c->stack }, $code );
1673
1674     no warnings 'recursion';
1675     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1676     #      I have no idea how, ergo $ret (which appears to fix the issue)
1677     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1678
1679     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1680
1681     my $last = pop( @{ $c->stack } );
1682
1683     if ( my $error = $@ ) {
1684         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1685             $error->rethrow if $c->depth > 1;
1686         }
1687         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1688             $error->rethrow if $c->depth > 0;
1689         }
1690         else {
1691             unless ( ref $error ) {
1692                 no warnings 'uninitialized';
1693                 chomp $error;
1694                 my $class = $last->class;
1695                 my $name  = $last->name;
1696                 $error = qq/Caught exception in $class->$name "$error"/;
1697             }
1698             $c->error($error);
1699         }
1700         $c->state(0);
1701     }
1702     return $c->state;
1703 }
1704
1705 sub _stats_start_execute {
1706     my ( $c, $code ) = @_;
1707     my $appclass = ref($c) || $c;
1708     return if ( ( $code->name =~ /^_.*/ )
1709         && ( !$appclass->config->{show_internal_actions} ) );
1710
1711     my $action_name = $code->reverse();
1712     $c->counter->{$action_name}++;
1713
1714     my $action = $action_name;
1715     $action = "/$action" unless $action =~ /->/;
1716
1717     # determine if the call was the result of a forward
1718     # this is done by walking up the call stack and looking for a calling
1719     # sub of Catalyst::forward before the eval
1720     my $callsub = q{};
1721     for my $index ( 2 .. 11 ) {
1722         last
1723         if ( ( caller($index) )[0] eq 'Catalyst'
1724             && ( caller($index) )[3] eq '(eval)' );
1725
1726         if ( ( caller($index) )[3] =~ /forward$/ ) {
1727             $callsub = ( caller($index) )[3];
1728             $action  = "-> $action";
1729             last;
1730         }
1731     }
1732
1733     my $uid = $action_name . $c->counter->{$action_name};
1734
1735     # is this a root-level call or a forwarded call?
1736     if ( $callsub =~ /forward$/ ) {
1737         my $parent = $c->stack->[-1];
1738
1739         # forward, locate the caller
1740         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1741             $c->stats->profile(
1742                 begin  => $action,
1743                 parent => "$parent" . $c->counter->{"$parent"},
1744                 uid    => $uid,
1745             );
1746         }
1747         else {
1748
1749             # forward with no caller may come from a plugin
1750             $c->stats->profile(
1751                 begin => $action,
1752                 uid   => $uid,
1753             );
1754         }
1755     }
1756     else {
1757
1758         # root-level call
1759         $c->stats->profile(
1760             begin => $action,
1761             uid   => $uid,
1762         );
1763     }
1764     return $action;
1765
1766 }
1767
1768 sub _stats_finish_execute {
1769     my ( $c, $info ) = @_;
1770     $c->stats->profile( end => $info );
1771 }
1772
1773 =head2 $c->finalize
1774
1775 Finalizes the request.
1776
1777 =cut
1778
1779 sub finalize {
1780     my $c = shift;
1781
1782     for my $error ( @{ $c->error } ) {
1783         $c->log->error($error);
1784     }
1785
1786     # Allow engine to handle finalize flow (for POE)
1787     my $engine = $c->engine;
1788     if ( my $code = $engine->can('finalize') ) {
1789         $engine->$code($c);
1790     }
1791     else {
1792
1793         $c->finalize_uploads;
1794
1795         # Error
1796         if ( $#{ $c->error } >= 0 ) {
1797             $c->finalize_error;
1798         }
1799
1800         $c->finalize_headers;
1801
1802         # HEAD request
1803         if ( $c->request->method eq 'HEAD' ) {
1804             $c->response->body('');
1805         }
1806
1807         $c->finalize_body;
1808     }
1809
1810     $c->log_response;
1811
1812     if ($c->use_stats) {
1813         my $elapsed = sprintf '%f', $c->stats->elapsed;
1814         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1815         $c->log->info(
1816             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1817     }
1818
1819     return $c->response->status;
1820 }
1821
1822 =head2 $c->finalize_body
1823
1824 Finalizes body.
1825
1826 =cut
1827
1828 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1829
1830 =head2 $c->finalize_cookies
1831
1832 Finalizes cookies.
1833
1834 =cut
1835
1836 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1837
1838 =head2 $c->finalize_error
1839
1840 Finalizes error.
1841
1842 =cut
1843
1844 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1845
1846 =head2 $c->finalize_headers
1847
1848 Finalizes headers.
1849
1850 =cut
1851
1852 sub finalize_headers {
1853     my $c = shift;
1854
1855     my $response = $c->response; #accessor calls can add up?
1856
1857     # Check if we already finalized headers
1858     return if $response->finalized_headers;
1859
1860     # Handle redirects
1861     if ( my $location = $response->redirect ) {
1862         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1863         $response->header( Location => $location );
1864
1865         if ( !$response->has_body ) {
1866             # Add a default body if none is already present
1867             $response->body(
1868                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1869             );
1870         }
1871     }
1872
1873     # Content-Length
1874     if ( defined $response->body && length $response->body && !$response->content_length ) {
1875
1876         # get the length from a filehandle
1877         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1878         {
1879             my $size = -s $response->body;
1880             if ( $size ) {
1881                 $response->content_length( $size );
1882             }
1883             else {
1884                 $c->log->warn('Serving filehandle without a content-length');
1885             }
1886         }
1887         else {
1888             # everything should be bytes at this point, but just in case
1889             $response->content_length( length( $response->body ) );
1890         }
1891     }
1892
1893     # Errors
1894     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1895         $response->headers->remove_header("Content-Length");
1896         $response->body('');
1897     }
1898
1899     $c->finalize_cookies;
1900
1901     $c->engine->finalize_headers( $c, @_ );
1902
1903     # Done
1904     $response->finalized_headers(1);
1905 }
1906
1907 =head2 $c->finalize_output
1908
1909 An alias for finalize_body.
1910
1911 =head2 $c->finalize_read
1912
1913 Finalizes the input after reading is complete.
1914
1915 =cut
1916
1917 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1918
1919 =head2 $c->finalize_uploads
1920
1921 Finalizes uploads. Cleans up any temporary files.
1922
1923 =cut
1924
1925 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1926
1927 =head2 $c->get_action( $action, $namespace )
1928
1929 Gets an action in a given namespace.
1930
1931 =cut
1932
1933 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1934
1935 =head2 $c->get_actions( $action, $namespace )
1936
1937 Gets all actions of a given name in a namespace and all parent
1938 namespaces.
1939
1940 =cut
1941
1942 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1943
1944 =head2 $app->handle_request( @arguments )
1945
1946 Called to handle each HTTP request.
1947
1948 =cut
1949
1950 sub handle_request {
1951     my ( $class, @arguments ) = @_;
1952
1953     # Always expect worst case!
1954     my $status = -1;
1955     try {
1956         if ($class->debug) {
1957             my $secs = time - $START || 1;
1958             my $av = sprintf '%.3f', $COUNT / $secs;
1959             my $time = localtime time;
1960             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1961         }
1962
1963         my $c = $class->prepare(@arguments);
1964         $c->dispatch;
1965         $status = $c->finalize;
1966     }
1967     catch {
1968         chomp(my $error = $_);
1969         $class->log->error(qq/Caught exception in engine "$error"/);
1970     };
1971
1972     $COUNT++;
1973
1974     if(my $coderef = $class->log->can('_flush')){
1975         $class->log->$coderef();
1976     }
1977     return $status;
1978 }
1979
1980 =head2 $c->prepare( @arguments )
1981
1982 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1983 etc.).
1984
1985 =cut
1986
1987 sub prepare {
1988     my ( $class, @arguments ) = @_;
1989
1990     # XXX
1991     # After the app/ctxt split, this should become an attribute based on something passed
1992     # into the application.
1993     $class->context_class( ref $class || $class ) unless $class->context_class;
1994
1995     my $c = $class->context_class->new({});
1996
1997     # For on-demand data
1998     $c->request->_context($c);
1999     $c->response->_context($c);
2000
2001     #surely this is not the most efficient way to do things...
2002     $c->stats($class->stats_class->new)->enable($c->use_stats);
2003     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2004         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2005     }
2006
2007     try {
2008         # Allow engine to direct the prepare flow (for POE)
2009         if ( my $prepare = $c->engine->can('prepare') ) {
2010             $c->engine->$prepare( $c, @arguments );
2011         }
2012         else {
2013             $c->prepare_request(@arguments);
2014             $c->prepare_connection;
2015             $c->prepare_query_parameters;
2016             $c->prepare_headers;
2017             $c->prepare_cookies;
2018             $c->prepare_path;
2019
2020             # Prepare the body for reading, either by prepare_body
2021             # or the user, if they are using $c->read
2022             $c->prepare_read;
2023
2024             # Parse the body unless the user wants it on-demand
2025             unless ( ref($c)->config->{parse_on_demand} ) {
2026                 $c->prepare_body;
2027             }
2028         }
2029     }
2030     # VERY ugly and probably shouldn't rely on ->finalize actually working
2031     catch {
2032         # failed prepare is always due to an invalid request, right?
2033         $c->response->status(400);
2034         $c->response->content_type('text/plain');
2035         $c->response->body('Bad Request');
2036         $c->finalize;
2037         die $_;
2038     };
2039
2040     my $method  = $c->req->method  || '';
2041     my $path    = $c->req->path;
2042     $path       = '/' unless length $path;
2043     my $address = $c->req->address || '';
2044
2045     $c->log_request;
2046
2047     $c->prepare_action;
2048
2049     return $c;
2050 }
2051
2052 =head2 $c->prepare_action
2053
2054 Prepares action. See L<Catalyst::Dispatcher>.
2055
2056 =cut
2057
2058 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2059
2060 =head2 $c->prepare_body
2061
2062 Prepares message body.
2063
2064 =cut
2065
2066 sub prepare_body {
2067     my $c = shift;
2068
2069     return if $c->request->_has_body;
2070
2071     # Initialize on-demand data
2072     $c->engine->prepare_body( $c, @_ );
2073     $c->prepare_parameters;
2074     $c->prepare_uploads;
2075 }
2076
2077 =head2 $c->prepare_body_chunk( $chunk )
2078
2079 Prepares a chunk of data before sending it to L<HTTP::Body>.
2080
2081 See L<Catalyst::Engine>.
2082
2083 =cut
2084
2085 sub prepare_body_chunk {
2086     my $c = shift;
2087     $c->engine->prepare_body_chunk( $c, @_ );
2088 }
2089
2090 =head2 $c->prepare_body_parameters
2091
2092 Prepares body parameters.
2093
2094 =cut
2095
2096 sub prepare_body_parameters {
2097     my $c = shift;
2098     $c->engine->prepare_body_parameters( $c, @_ );
2099 }
2100
2101 =head2 $c->prepare_connection
2102
2103 Prepares connection.
2104
2105 =cut
2106
2107 sub prepare_connection {
2108     my $c = shift;
2109     $c->engine->prepare_connection( $c, @_ );
2110 }
2111
2112 =head2 $c->prepare_cookies
2113
2114 Prepares cookies.
2115
2116 =cut
2117
2118 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2119
2120 =head2 $c->prepare_headers
2121
2122 Prepares headers.
2123
2124 =cut
2125
2126 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2127
2128 =head2 $c->prepare_parameters
2129
2130 Prepares parameters.
2131
2132 =cut
2133
2134 sub prepare_parameters {
2135     my $c = shift;
2136     $c->prepare_body_parameters;
2137     $c->engine->prepare_parameters( $c, @_ );
2138 }
2139
2140 =head2 $c->prepare_path
2141
2142 Prepares path and base.
2143
2144 =cut
2145
2146 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2147
2148 =head2 $c->prepare_query_parameters
2149
2150 Prepares query parameters.
2151
2152 =cut
2153
2154 sub prepare_query_parameters {
2155     my $c = shift;
2156
2157     $c->engine->prepare_query_parameters( $c, @_ );
2158 }
2159
2160 =head2 $c->log_request
2161
2162 Writes information about the request to the debug logs.  This includes:
2163
2164 =over 4
2165
2166 =item * Request method, path, and remote IP address
2167
2168 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2169
2170 =item * Request parameters
2171
2172 =item * File uploads
2173
2174 =back
2175
2176 =cut
2177
2178 sub log_request {
2179     my $c = shift;
2180
2181     return unless $c->debug;
2182
2183     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2184     my $request = $dump->[1];
2185
2186     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2187     $method ||= '';
2188     $path = '/' unless length $path;
2189     $address ||= '';
2190     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2191
2192     $c->log_request_headers($request->headers);
2193
2194     if ( my $keywords = $request->query_keywords ) {
2195         $c->log->debug("Query keywords are: $keywords");
2196     }
2197
2198     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2199
2200     $c->log_request_uploads($request);
2201 }
2202
2203 =head2 $c->log_response
2204
2205 Writes information about the response to the debug logs by calling
2206 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2207
2208 =cut
2209
2210 sub log_response {
2211     my $c = shift;
2212
2213     return unless $c->debug;
2214
2215     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2216     my $response = $dump->[1];
2217
2218     $c->log_response_status_line($response);
2219     $c->log_response_headers($response->headers);
2220 }
2221
2222 =head2 $c->log_response_status_line($response)
2223
2224 Writes one line of information about the response to the debug logs.  This includes:
2225
2226 =over 4
2227
2228 =item * Response status code
2229
2230 =item * Content-Type header (if present)
2231
2232 =item * Content-Length header (if present)
2233
2234 =back
2235
2236 =cut
2237
2238 sub log_response_status_line {
2239     my ($c, $response) = @_;
2240
2241     $c->log->debug(
2242         sprintf(
2243             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2244             $response->status                            || 'unknown',
2245             $response->headers->header('Content-Type')   || 'unknown',
2246             $response->headers->header('Content-Length') || 'unknown'
2247         )
2248     );
2249 }
2250
2251 =head2 $c->log_response_headers($headers);
2252
2253 Hook method which can be wrapped by plugins to log the response headers.
2254 No-op in the default implementation.
2255
2256 =cut
2257
2258 sub log_response_headers {}
2259
2260 =head2 $c->log_request_parameters( query => {}, body => {} )
2261
2262 Logs request parameters to debug logs
2263
2264 =cut
2265
2266 sub log_request_parameters {
2267     my $c          = shift;
2268     my %all_params = @_;
2269
2270     return unless $c->debug;
2271
2272     my $column_width = Catalyst::Utils::term_width() - 44;
2273     foreach my $type (qw(query body)) {
2274         my $params = $all_params{$type};
2275         next if ! keys %$params;
2276         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2277         for my $key ( sort keys %$params ) {
2278             my $param = $params->{$key};
2279             my $value = defined($param) ? $param : '';
2280             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2281         }
2282         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2283     }
2284 }
2285
2286 =head2 $c->log_request_uploads
2287
2288 Logs file uploads included in the request to the debug logs.
2289 The parameter name, filename, file type, and file size are all included in
2290 the debug logs.
2291
2292 =cut
2293
2294 sub log_request_uploads {
2295     my $c = shift;
2296     my $request = shift;
2297     return unless $c->debug;
2298     my $uploads = $request->uploads;
2299     if ( keys %$uploads ) {
2300         my $t = Text::SimpleTable->new(
2301             [ 12, 'Parameter' ],
2302             [ 26, 'Filename' ],
2303             [ 18, 'Type' ],
2304             [ 9,  'Size' ]
2305         );
2306         for my $key ( sort keys %$uploads ) {
2307             my $upload = $uploads->{$key};
2308             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2309                 $t->row( $key, $u->filename, $u->type, $u->size );
2310             }
2311         }
2312         $c->log->debug( "File Uploads are:\n" . $t->draw );
2313     }
2314 }
2315
2316 =head2 $c->log_request_headers($headers);
2317
2318 Hook method which can be wrapped by plugins to log the request headers.
2319 No-op in the default implementation.
2320
2321 =cut
2322
2323 sub log_request_headers {}
2324
2325 =head2 $c->log_headers($type => $headers)
2326
2327 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2328
2329 =cut
2330
2331 sub log_headers {
2332     my $c       = shift;
2333     my $type    = shift;
2334     my $headers = shift;    # an HTTP::Headers instance
2335
2336     return unless $c->debug;
2337
2338     my $column_width = Catalyst::Utils::term_width() - 28;
2339     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2340     $headers->scan(
2341         sub {
2342             my ( $name, $value ) = @_;
2343             $t->row( $name, $value );
2344         }
2345     );
2346     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2347 }
2348
2349
2350 =head2 $c->prepare_read
2351
2352 Prepares the input for reading.
2353
2354 =cut
2355
2356 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2357
2358 =head2 $c->prepare_request
2359
2360 Prepares the engine request.
2361
2362 =cut
2363
2364 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2365
2366 =head2 $c->prepare_uploads
2367
2368 Prepares uploads.
2369
2370 =cut
2371
2372 sub prepare_uploads {
2373     my $c = shift;
2374
2375     $c->engine->prepare_uploads( $c, @_ );
2376 }
2377
2378 =head2 $c->prepare_write
2379
2380 Prepares the output for writing.
2381
2382 =cut
2383
2384 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2385
2386 =head2 $c->request_class
2387
2388 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2389
2390 =head2 $c->response_class
2391
2392 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2393
2394 =head2 $c->read( [$maxlength] )
2395
2396 Reads a chunk of data from the request body. This method is designed to
2397 be used in a while loop, reading C<$maxlength> bytes on every call.
2398 C<$maxlength> defaults to the size of the request if not specified.
2399
2400 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2401 directly.
2402
2403 Warning: If you use read(), Catalyst will not process the body,
2404 so you will not be able to access POST parameters or file uploads via
2405 $c->request.  You must handle all body parsing yourself.
2406
2407 =cut
2408
2409 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2410
2411 =head2 $c->run
2412
2413 Starts the engine.
2414
2415 =cut
2416
2417 sub run {
2418   my $app = shift;
2419   $app->engine_loader->needs_psgi_engine_compat_hack ?
2420     $app->engine->run($app, @_) :
2421       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2422 }
2423
2424 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2425
2426 Sets an action in a given namespace.
2427
2428 =cut
2429
2430 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2431
2432 =head2 $c->setup_actions($component)
2433
2434 Sets up actions for a component.
2435
2436 =cut
2437
2438 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2439
2440 =head2 $c->setup_components
2441
2442 This method is called internally to set up the application's components.
2443
2444 It finds modules by calling the L<locate_components> method, expands them to
2445 package names with the L<expand_component_module> method, and then installs
2446 each component into the application.
2447
2448 The C<setup_components> config option is passed to both of the above methods.
2449
2450 Installation of each component is performed by the L<setup_component> method,
2451 below.
2452
2453 =cut
2454
2455 sub setup_components {
2456     my $class = shift;
2457
2458     my $config  = $class->config->{ setup_components };
2459
2460     my @comps = $class->locate_components($config);
2461     my %comps = map { $_ => 1 } @comps;
2462
2463     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2464     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2465         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2466     ) if $deprecatedcatalyst_component_names;
2467
2468     for my $component ( @comps ) {
2469
2470         # We pass ignore_loaded here so that overlay files for (e.g.)
2471         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2472         # we know M::P::O found a file on disk so this is safe
2473
2474         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2475     }
2476
2477     for my $component (@comps) {
2478         my $instance = $class->components->{ $component } = $class->setup_component($component);
2479         my @expanded_components = $instance->can('expand_modules')
2480             ? $instance->expand_modules( $component, $config )
2481             : $class->expand_component_module( $component, $config );
2482         for my $component (@expanded_components) {
2483             next if $comps{$component};
2484             $class->components->{ $component } = $class->setup_component($component);
2485         }
2486     }
2487 }
2488
2489 =head2 $c->locate_components( $setup_component_config )
2490
2491 This method is meant to provide a list of component modules that should be
2492 setup for the application.  By default, it will use L<Module::Pluggable>.
2493
2494 Specify a C<setup_components> config option to pass additional options directly
2495 to L<Module::Pluggable>. To add additional search paths, specify a key named
2496 C<search_extra> as an array reference. Items in the array beginning with C<::>
2497 will have the application class name prepended to them.
2498
2499 =cut
2500
2501 sub locate_components {
2502     my $class  = shift;
2503     my $config = shift;
2504
2505     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2506     my $extra   = delete $config->{ search_extra } || [];
2507
2508     push @paths, @$extra;
2509
2510     my $locator = Module::Pluggable::Object->new(
2511         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2512         %$config
2513     );
2514
2515     # XXX think about ditching this sort entirely
2516     my @comps = sort { length $a <=> length $b } $locator->plugins;
2517
2518     return @comps;
2519 }
2520
2521 =head2 $c->expand_component_module( $component, $setup_component_config )
2522
2523 Components found by C<locate_components> will be passed to this method, which
2524 is expected to return a list of component (package) names to be set up.
2525
2526 =cut
2527
2528 sub expand_component_module {
2529     my ($class, $module) = @_;
2530     return Devel::InnerPackage::list_packages( $module );
2531 }
2532
2533 =head2 $c->setup_component
2534
2535 =cut
2536
2537 sub setup_component {
2538     my( $class, $component ) = @_;
2539
2540     unless ( $component->can( 'COMPONENT' ) ) {
2541         return $component;
2542     }
2543
2544     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2545     my $config = $class->config->{ $suffix } || {};
2546     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2547     # methods also pass it. local to avoid pointlessly shitting in config
2548     # for the debug screen, as $component is already the key name.
2549     local $config->{catalyst_component_name} = $component;
2550
2551     my $instance = eval { $component->COMPONENT( $class, $config ); };
2552
2553     if ( my $error = $@ ) {
2554         chomp $error;
2555         Catalyst::Exception->throw(
2556             message => qq/Couldn't instantiate component "$component", "$error"/
2557         );
2558     }
2559
2560     unless (blessed $instance) {
2561         my $metaclass = Moose::Util::find_meta($component);
2562         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2563         my $component_method_from = $method_meta->associated_metaclass->name;
2564         my $value = defined($instance) ? $instance : 'undef';
2565         Catalyst::Exception->throw(
2566             message =>
2567             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2568         );
2569     }
2570     return $instance;
2571 }
2572
2573 =head2 $c->setup_dispatcher
2574
2575 Sets up dispatcher.
2576
2577 =cut
2578
2579 sub setup_dispatcher {
2580     my ( $class, $dispatcher ) = @_;
2581
2582     if ($dispatcher) {
2583         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2584     }
2585
2586     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2587         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2588     }
2589
2590     unless ($dispatcher) {
2591         $dispatcher = $class->dispatcher_class;
2592     }
2593
2594     Class::MOP::load_class($dispatcher);
2595
2596     # dispatcher instance
2597     $class->dispatcher( $dispatcher->new );
2598 }
2599
2600 =head2 $c->setup_engine
2601
2602 Sets up engine.
2603
2604 =cut
2605
2606 sub engine_class {
2607     my $class = shift;
2608     $class->engine_loader->catalyst_engine_class(@_);
2609 }
2610
2611 sub setup_engine {
2612     my ($class, $requested_engine) = @_;
2613
2614     $class->engine_loader(
2615         Catalyst::EngineLoader->new({
2616             application_name => $class,
2617             (defined $requested_engine
2618                  ? (requested_engine => $requested_engine) : ()),
2619         }),
2620     );
2621
2622     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2623     return if $class->loading_psgi_file;
2624
2625     my $engine = $class->engine_class;
2626     Class::MOP::load_class($engine);
2627
2628     if ($ENV{MOD_PERL}) {
2629         my $apache = $class->engine_loader->auto;
2630
2631         my $meta = find_meta($class);
2632         my $was_immutable = $meta->is_immutable;
2633         my %immutable_options = $meta->immutable_options;
2634         $meta->make_mutable if $was_immutable;
2635
2636         $meta->add_method(handler => sub {
2637             my $r = shift;
2638             my $psgi_app = $class->psgi_app;
2639             $apache->call_app($r, $psgi_app);
2640         });
2641
2642         $meta->make_immutable(%immutable_options) if $was_immutable;
2643     }
2644
2645     $class->engine( $engine->new );
2646
2647     return;
2648 }
2649
2650 sub _finalized_psgi_app {
2651     my ($app) = @_;
2652
2653     unless ($app->_psgi_app) {
2654         my $psgi_app = $app->_setup_psgi_app;
2655         $app->_psgi_app($psgi_app);
2656     }
2657
2658     return $app->_psgi_app;
2659 }
2660
2661 sub _setup_psgi_app {
2662     my ($app) = @_;
2663
2664     for my $home (Path::Class::Dir->new($app->config->{home})) {
2665         my $psgi_file = $home->file(
2666             Catalyst::Utils::appprefix($app) . '.psgi',
2667         );
2668
2669         next unless -e $psgi_file;
2670
2671         # If $psgi_file calls ->setup_engine, it's doing so to load
2672         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2673         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2674         # anyway. So set a flag (ick) that tells setup_engine not to populate
2675         # $c->engine or do any other things we might regret.
2676
2677         $app->loading_psgi_file(1);
2678         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2679         $app->loading_psgi_file(0);
2680
2681         return $psgi_app
2682             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2683
2684         warn <<"EOW";
2685 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2686
2687 Its content has been ignored. Please consult the Catalyst::Upgrading
2688 documentation on how to upgrade from Catalyst::Engine::PSGI.
2689 EOW
2690     }
2691
2692     return $app->apply_default_middlewares($app->psgi_app);
2693 }
2694
2695 =head2 $c->apply_default_middlewares
2696
2697 Adds the following L<Plack> middlewares to your application, since they are
2698 useful and commonly needed:
2699
2700 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2701 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2702 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2703 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2704 applied since this middleware is smart enough to conditionally apply itself).
2705
2706 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2707 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2708 $ENV{SCRIPT_NAME}
2709
2710 =cut
2711
2712
2713 sub apply_default_middlewares {
2714     my ($app, $psgi_app) = @_;
2715
2716     $psgi_app = Plack::Middleware::Conditional->wrap(
2717         $psgi_app,
2718         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2719         condition => sub {
2720             my ($env) = @_;
2721             return if $app->config->{ignore_frontend_proxy};
2722             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2723                 || $app->config->{using_frontend_proxy};
2724         },
2725     );
2726
2727     my $server_matches = sub {
2728         my ($re) = @_;
2729         return sub {
2730             my ($env) = @_;
2731             my $server = $env->{SERVER_SOFTWARE};
2732             return unless $server;
2733             return $server =~ $re ? 1 : 0;
2734         };
2735     };
2736
2737     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2738     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2739     $psgi_app = Plack::Middleware::LighttpdScriptNameFix->wrap($psgi_app);
2740
2741     $psgi_app = Plack::Middleware::Conditional->wrap(
2742         $psgi_app,
2743         condition => $server_matches->(qr/^nginx/),
2744         builder   => sub {
2745             my ($to_wrap) = @_;
2746             return sub {
2747                 my ($env) = @_;
2748                 my $script_name = $env->{SCRIPT_NAME};
2749                 $env->{PATH_INFO} =~ s/^$script_name//g;
2750                 return $to_wrap->($env);
2751             };
2752         },
2753     );
2754
2755     # we're applying this unconditionally as the middleware itself already makes
2756     # sure it doesn't fuck things up if it's not running under one of the right
2757     # IIS versions
2758     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2759
2760     return $psgi_app;
2761 }
2762
2763 =head2 $c->psgi_app
2764
2765 Returns a PSGI application code reference for the catalyst application
2766 C<$c>. This is the bare application without any middlewares
2767 applied. C<${myapp}.psgi> is not taken into account.
2768
2769 This is what you want to be using to retrieve the PSGI application code
2770 reference of your Catalyst application for use in F<.psgi> files.
2771
2772 =cut
2773
2774 sub psgi_app {
2775     my ($app) = @_;
2776     return $app->engine->build_psgi_app($app);
2777 }
2778
2779 =head2 $c->setup_home
2780
2781 Sets up the home directory.
2782
2783 =cut
2784
2785 sub setup_home {
2786     my ( $class, $home ) = @_;
2787
2788     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2789         $home = $env;
2790     }
2791
2792     $home ||= Catalyst::Utils::home($class);
2793
2794     if ($home) {
2795         #I remember recently being scolded for assigning config values like this
2796         $class->config->{home} ||= $home;
2797         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2798     }
2799 }
2800
2801 =head2 $c->setup_log
2802
2803 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2804 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2805 log to.
2806
2807 This method also installs a C<debug> method that returns a true value into the
2808 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2809 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2810
2811 Note that if the log has already been setup, by either a previous call to
2812 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2813 that this method won't actually set up the log object.
2814
2815 =cut
2816
2817 sub setup_log {
2818     my ( $class, $levels ) = @_;
2819
2820     $levels ||= '';
2821     $levels =~ s/^\s+//;
2822     $levels =~ s/\s+$//;
2823     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2824
2825     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2826     if ( defined $env_debug ) {
2827         $levels{debug} = 1 if $env_debug; # Ugly!
2828         delete($levels{debug}) unless $env_debug;
2829     }
2830
2831     unless ( $class->log ) {
2832         $class->log( Catalyst::Log->new(keys %levels) );
2833     }
2834
2835     if ( $levels{debug} ) {
2836         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2837         $class->log->debug('Debug messages enabled');
2838     }
2839 }
2840
2841 =head2 $c->setup_plugins
2842
2843 Sets up plugins.
2844
2845 =cut
2846
2847 =head2 $c->setup_stats
2848
2849 Sets up timing statistics class.
2850
2851 =cut
2852
2853 sub setup_stats {
2854     my ( $class, $stats ) = @_;
2855
2856     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2857
2858     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2859     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2860         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2861         $class->log->debug('Statistics enabled');
2862     }
2863 }
2864
2865
2866 =head2 $c->registered_plugins
2867
2868 Returns a sorted list of the plugins which have either been stated in the
2869 import list or which have been added via C<< MyApp->plugin(@args); >>.
2870
2871 If passed a given plugin name, it will report a boolean value indicating
2872 whether or not that plugin is loaded.  A fully qualified name is required if
2873 the plugin name does not begin with C<Catalyst::Plugin::>.
2874
2875  if ($c->registered_plugins('Some::Plugin')) {
2876      ...
2877  }
2878
2879 =cut
2880
2881 {
2882
2883     sub registered_plugins {
2884         my $proto = shift;
2885         return sort keys %{ $proto->_plugins } unless @_;
2886         my $plugin = shift;
2887         return 1 if exists $proto->_plugins->{$plugin};
2888         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2889     }
2890
2891     sub _register_plugin {
2892         my ( $proto, $plugin, $instant ) = @_;
2893         my $class = ref $proto || $proto;
2894
2895         Class::MOP::load_class( $plugin );
2896         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2897             if $plugin->isa( 'Catalyst::Component' );
2898         $proto->_plugins->{$plugin} = 1;
2899         unless ($instant) {
2900             my $meta = Class::MOP::get_metaclass_by_name($class);
2901             $meta->superclasses($plugin, $meta->superclasses);
2902         }
2903         return $class;
2904     }
2905
2906     sub setup_plugins {
2907         my ( $class, $plugins ) = @_;
2908
2909         $class->_plugins( {} ) unless $class->_plugins;
2910         $plugins = Data::OptList::mkopt($plugins || []);
2911
2912         my @plugins = map {
2913             [ Catalyst::Utils::resolve_namespace(
2914                   $class . '::Plugin',
2915                   'Catalyst::Plugin', $_->[0]
2916               ),
2917               $_->[1],
2918             ]
2919          } @{ $plugins };
2920
2921         for my $plugin ( reverse @plugins ) {
2922             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2923             my $meta = find_meta($plugin->[0]);
2924             next if $meta && $meta->isa('Moose::Meta::Role');
2925
2926             $class->_register_plugin($plugin->[0]);
2927         }
2928
2929         my @roles =
2930             map  { $_->[0]->name, $_->[1] }
2931             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2932             map  { [find_meta($_->[0]), $_->[1]] }
2933             @plugins;
2934
2935         Moose::Util::apply_all_roles(
2936             $class => @roles
2937         ) if @roles;
2938     }
2939 }
2940
2941 =head2 $c->stack
2942
2943 Returns an arrayref of the internal execution stack (actions that are
2944 currently executing).
2945
2946 =head2 $c->stats
2947
2948 Returns the current timing statistics object. By default Catalyst uses
2949 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2950 L<< stats_class|/"$c->stats_class" >>.
2951
2952 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2953 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2954 profile explicitly, although MyApp.pm still won't profile nor output anything
2955 by itself.
2956
2957 =head2 $c->stats_class
2958
2959 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2960
2961 =head2 $c->use_stats
2962
2963 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2964
2965 Note that this is a static method, not an accessor and should be overridden
2966 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2967
2968 =cut
2969
2970 sub use_stats { 0 }
2971
2972
2973 =head2 $c->write( $data )
2974
2975 Writes $data to the output stream. When using this method directly, you
2976 will need to manually set the C<Content-Length> header to the length of
2977 your output data, if known.
2978
2979 =cut
2980
2981 sub write {
2982     my $c = shift;
2983
2984     # Finalize headers if someone manually writes output
2985     $c->finalize_headers;
2986
2987     return $c->engine->write( $c, @_ );
2988 }
2989
2990 =head2 version
2991
2992 Returns the Catalyst version number. Mostly useful for "powered by"
2993 messages in template systems.
2994
2995 =cut
2996
2997 sub version { return $Catalyst::VERSION }
2998
2999 =head1 CONFIGURATION
3000
3001 There are a number of 'base' config variables which can be set:
3002
3003 =over
3004
3005 =item *
3006
3007 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3008
3009 =item *
3010
3011 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3012
3013 =item *
3014
3015 C<disable_component_resolution_regex_fallback> - Turns
3016 off the deprecated component resolution functionality so
3017 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3018 are called then regex search will not be attempted on string values and
3019 instead C<undef> will be returned.
3020
3021 =item *
3022
3023 C<home> - The application home directory. In an uninstalled application,
3024 this is the top level application directory. In an installed application,
3025 this will be the directory containing C<< MyApp.pm >>.
3026
3027 =item *
3028
3029 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3030
3031 =item *
3032
3033 C<name> - The name of the application in debug messages and the debug and
3034 welcome screens
3035
3036 =item *
3037
3038 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3039 until it is accessed. This allows you to (for example) check authentication (and reject
3040 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3041
3042 =item *
3043
3044 C<root> - The root directory for templates. Usually this is just a
3045 subdirectory of the home directory, but you can set it to change the
3046 templates to a different directory.
3047
3048 =item *
3049
3050 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3051 namespaces from which components will be loaded (and constructed and stored in
3052 C<< $c->components >>).
3053
3054 =item *
3055
3056 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3057 to be shown in hit debug tables in the test server.
3058
3059 =item *
3060
3061 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3062 variable should be used for determining the request path. See L<Catalyst::Engine::CGI/PATH DECODING>
3063 for more information.
3064
3065 =item *
3066
3067 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3068
3069 =back
3070
3071 =head1 INTERNAL ACTIONS
3072
3073 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3074 C<_ACTION>, and C<_END>. These are by default not shown in the private
3075 action table, but you can make them visible with a config parameter.
3076
3077     MyApp->config(show_internal_actions => 1);
3078
3079 =head1 ON-DEMAND PARSER
3080
3081 The request body is usually parsed at the beginning of a request,
3082 but if you want to handle input yourself, you can enable on-demand
3083 parsing with a config parameter.
3084
3085     MyApp->config(parse_on_demand => 1);
3086
3087 =head1 PROXY SUPPORT
3088
3089 Many production servers operate using the common double-server approach,
3090 with a lightweight frontend web server passing requests to a larger
3091 backend server. An application running on the backend server must deal
3092 with two problems: the remote user always appears to be C<127.0.0.1> and
3093 the server's hostname will appear to be C<localhost> regardless of the
3094 virtual host that the user connected through.
3095
3096 Catalyst will automatically detect this situation when you are running
3097 the frontend and backend servers on the same machine. The following
3098 changes are made to the request.
3099
3100     $c->req->address is set to the user's real IP address, as read from
3101     the HTTP X-Forwarded-For header.
3102
3103     The host value for $c->req->base and $c->req->uri is set to the real
3104     host, as read from the HTTP X-Forwarded-Host header.
3105
3106 Additionally, you may be running your backend application on an insecure
3107 connection (port 80) while your frontend proxy is running under SSL.  If there
3108 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3109 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3110 be created properly.
3111
3112 In the case of passing in:
3113
3114     X-Forwarded-Port: 443
3115
3116 All calls to C<uri_for> will result in an https link, as is expected.
3117
3118 Obviously, your web server must support these headers for this to work.
3119
3120 In a more complex server farm environment where you may have your
3121 frontend proxy server(s) on different machines, you will need to set a
3122 configuration option to tell Catalyst to read the proxied data from the
3123 headers.
3124
3125     MyApp->config(using_frontend_proxy => 1);
3126
3127 If you do not wish to use the proxy support at all, you may set:
3128
3129     MyApp->config(ignore_frontend_proxy => 1);
3130
3131 =head1 THREAD SAFETY
3132
3133 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3134 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3135 believe the Catalyst core to be thread-safe.
3136
3137 If you plan to operate in a threaded environment, remember that all other
3138 modules you are using must also be thread-safe. Some modules, most notably
3139 L<DBD::SQLite>, are not thread-safe.
3140
3141 =head1 SUPPORT
3142
3143 IRC:
3144
3145     Join #catalyst on irc.perl.org.
3146
3147 Mailing Lists:
3148
3149     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3150     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3151
3152 Web:
3153
3154     http://catalyst.perl.org
3155
3156 Wiki:
3157
3158     http://dev.catalyst.perl.org
3159
3160 =head1 SEE ALSO
3161
3162 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3163
3164 =head2 L<Catalyst::Manual> - The Catalyst Manual
3165
3166 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3167
3168 =head2 L<Catalyst::Engine> - Core engine
3169
3170 =head2 L<Catalyst::Log> - Log class.
3171
3172 =head2 L<Catalyst::Request> - Request object
3173
3174 =head2 L<Catalyst::Response> - Response object
3175
3176 =head2 L<Catalyst::Test> - The test suite.
3177
3178 =begin stopwords
3179
3180 =head1 PROJECT FOUNDER
3181
3182 sri: Sebastian Riedel <sri@cpan.org>
3183
3184 =head1 CONTRIBUTORS
3185
3186 abw: Andy Wardley
3187
3188 acme: Leon Brocard <leon@astray.com>
3189
3190 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3191
3192 Andrew Bramble
3193
3194 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3195
3196 Andrew Ruthven
3197
3198 andyg: Andy Grundman <andy@hybridized.org>
3199
3200 audreyt: Audrey Tang
3201
3202 bricas: Brian Cassidy <bricas@cpan.org>
3203
3204 Caelum: Rafael Kitover <rkitover@io.com>
3205
3206 chansen: Christian Hansen
3207
3208 chicks: Christopher Hicks
3209
3210 Chisel Wright C<pause@herlpacker.co.uk>
3211
3212 Danijel Milicevic C<me@danijel.de>
3213
3214 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3215
3216 David Naughton, C<naughton@umn.edu>
3217
3218 David E. Wheeler
3219
3220 dhoss: Devin Austin <dhoss@cpan.org>
3221
3222 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3223
3224 Drew Taylor
3225
3226 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3227
3228 esskar: Sascha Kiefer
3229
3230 fireartist: Carl Franks <cfranks@cpan.org>
3231
3232 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3233
3234 gabb: Danijel Milicevic
3235
3236 Gary Ashton Jones
3237
3238 Gavin Henry C<ghenry@perl.me.uk>
3239
3240 Geoff Richards
3241
3242 groditi: Guillermo Roditi <groditi@gmail.com>
3243
3244 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3245
3246 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3247
3248 jcamacho: Juan Camacho
3249
3250 jester: Jesse Sheidlower C<jester@panix.com>
3251
3252 jhannah: Jay Hannah <jay@jays.net>
3253
3254 Jody Belka
3255
3256 Johan Lindstrom
3257
3258 jon: Jon Schutz <jjschutz@cpan.org>
3259
3260 Jonathan Rockway C<< <jrockway@cpan.org> >>
3261
3262 Kieren Diment C<kd@totaldatasolution.com>
3263
3264 konobi: Scott McWhirter <konobi@cpan.org>
3265
3266 marcus: Marcus Ramberg <mramberg@cpan.org>
3267
3268 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3269
3270 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3271
3272 mugwump: Sam Vilain
3273
3274 naughton: David Naughton
3275
3276 ningu: David Kamholz <dkamholz@cpan.org>
3277
3278 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3279
3280 numa: Dan Sully <daniel@cpan.org>
3281
3282 obra: Jesse Vincent
3283
3284 Octavian Rasnita
3285
3286 omega: Andreas Marienborg
3287
3288 Oleg Kostyuk <cub.uanic@gmail.com>
3289
3290 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3291
3292 rafl: Florian Ragwitz <rafl@debian.org>
3293
3294 random: Roland Lammel <lammel@cpan.org>
3295
3296 Robert Sedlacek C<< <rs@474.at> >>
3297
3298 SpiceMan: Marcel Montes
3299
3300 sky: Arthur Bergman
3301
3302 szbalint: Balint Szilakszi <szbalint@cpan.org>
3303
3304 t0m: Tomas Doran <bobtfish@bobtfish.net>
3305
3306 Ulf Edvinsson
3307
3308 Viljo Marrandi C<vilts@yahoo.com>
3309
3310 Will Hawes C<info@whawes.co.uk>
3311
3312 willert: Sebastian Willert <willert@cpan.org>
3313
3314 wreis: Wallace Reis <wallace@reis.org.br>
3315
3316 Yuval Kogman, C<nothingmuch@woobling.org>
3317
3318 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3319
3320 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3321
3322 =end stopwords
3323
3324 =head1 COPYRIGHT
3325
3326 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3327
3328 =head1 LICENSE
3329
3330 This library is free software. You can redistribute it and/or modify it under
3331 the same terms as Perl itself.
3332
3333 =cut
3334
3335 no Moose;
3336
3337 __PACKAGE__->meta->make_immutable;
3338
3339 1;