lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::LighttpdScriptNameFix;
  40
  41 BEGIN { require 5.008004; }
  42
  43 has stack => (is => 'ro', default => sub { [] });
  44 has stash => (is => 'rw', default => sub { {} });
  45 has state => (is => 'rw', default => 0);
  46 has stats => (is => 'rw');
  47 has action => (is => 'rw');
  48 has counter => (is => 'rw', default => sub { {} });
  49 has request => (
  50     is => 'rw',
  51     default => sub {
  52         my $self = shift;
  53         my %p = ( _log => $self->log );
  54         $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  55         $self->request_class->new(\%p);
  56     },
  57     lazy => 1,
  58 );
  59 has response => (
  60     is => 'rw',
  61     default => sub {
  62         my $self = shift;
  63         $self->response_class->new({ _log => $self->log });
  64     },
  65     lazy => 1,
  66 );
  67 has namespace => (is => 'rw');
  68
  69 sub depth { scalar @{ shift->stack || [] }; }
  70 sub comp { shift->component(@_) }
  71
  72 sub req {
  73     my $self = shift; return $self->request(@_);
  74 }
  75 sub res {
  76     my $self = shift; return $self->response(@_);
  77 }
  78
  79 # For backwards compatibility
  80 sub finalize_output { shift->finalize_body(@_) };
  81
  82 # For statistics
  83 our $COUNT     = 1;
  84 our $START     = time;
  85 our $RECURSION = 1000;
  86 our $DETACH    = Catalyst::Exception::Detach->new;
  87 our $GO        = Catalyst::Exception::Go->new;
  88
  89 #I imagine that very few of these really need to be class variables. if any.
  90 #maybe we should just make them attributes with a default?
  91 __PACKAGE__->mk_classdata($_)
  92   for qw/components arguments dispatcher engine log dispatcher_class
  93   engine_loader context_class request_class response_class stats_class
  94   setup_finished _psgi_app loading_psgi_file run_options/;
  95
  96 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  97 __PACKAGE__->request_class('Catalyst::Request');
  98 __PACKAGE__->response_class('Catalyst::Response');
  99 __PACKAGE__->stats_class('Catalyst::Stats');
 100
 101 # Remember to update this in Catalyst::Runtime as well!
 102
 103 our $VERSION = '5.90006';
 104
 105 sub import {
 106     my ( $class, @arguments ) = @_;
 107
 108     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 109     # callers @ISA.
 110     return unless $class eq 'Catalyst';
 111
 112     my $caller = caller();
 113     return if $caller eq 'main';
 114
 115     my $meta = Moose::Meta::Class->initialize($caller);
 116     unless ( $caller->isa('Catalyst') ) {
 117         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 118         $meta->superclasses(@superclasses);
 119     }
 120     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 121     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 122
 123     unless( $meta->has_method('meta') ){
 124         if ($Moose::VERSION >= 1.15) {
 125             $meta->_add_meta_method('meta');
 126         }
 127         else {
 128             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 129         }
 130     }
 131
 132     $caller->arguments( [@arguments] );
 133     $caller->setup_home;
 134 }
 135
 136 sub _application { $_[0] }
 137
 138 =head1 NAME
 139
 140 Catalyst - The Elegant MVC Web Application Framework
 141
 142 =head1 SYNOPSIS
 143
 144 See the L<Catalyst::Manual> distribution for comprehensive
 145 documentation and tutorials.
 146
 147     # Install Catalyst::Devel for helpers and other development tools
 148     # use the helper to create a new application
 149     catalyst.pl MyApp
 150
 151     # add models, views, controllers
 152     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 153     script/myapp_create.pl view MyTemplate TT
 154     script/myapp_create.pl controller Search
 155
 156     # built in testserver -- use -r to restart automatically on changes
 157     # --help to see all available options
 158     script/myapp_server.pl
 159
 160     # command line testing interface
 161     script/myapp_test.pl /yada
 162
 163     ### in lib/MyApp.pm
 164     use Catalyst qw/-Debug/; # include plugins here as well
 165
 166     ### In lib/MyApp/Controller/Root.pm (autocreated)
 167     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 168         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 169         $c->stash->{template} = 'foo.tt'; # set the template
 170         # lookup something from db -- stash vars are passed to TT
 171         $c->stash->{data} =
 172           $c->model('Database::Foo')->search( { country => $args[0] } );
 173         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 174             $c->forward( 'bar' ); # process another action
 175             # do something else after forward returns
 176         }
 177     }
 178
 179     # The foo.tt TT template can use the stash data from the database
 180     [% WHILE (item = data.next) %]
 181         [% item.foo %]
 182     [% END %]
 183
 184     # called for /bar/of/soap, /bar/of/soap/10, etc.
 185     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 186
 187     # called after all actions are finished
 188     sub end : Action {
 189         my ( $self, $c ) = @_;
 190         if ( scalar @{ $c->error } ) { ... } # handle errors
 191         return if $c->res->body; # already have a response
 192         $c->forward( 'MyApp::View::TT' ); # render template
 193     }
 194
 195 See L<Catalyst::Manual::Intro> for additional information.
 196
 197 =head1 DESCRIPTION
 198
 199 Catalyst is a modern framework for making web applications without the
 200 pain usually associated with this process. This document is a reference
 201 to the main Catalyst application. If you are a new user, we suggest you
 202 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 203
 204 See L<Catalyst::Manual> for more documentation.
 205
 206 Catalyst plugins can be loaded by naming them as arguments to the "use
 207 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 208 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 209 C<My::Module>.
 210
 211     use Catalyst qw/My::Module/;
 212
 213 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 214 fully qualify the name by using a unary plus:
 215
 216     use Catalyst qw/
 217         My::Module
 218         +Fully::Qualified::Plugin::Name
 219     /;
 220
 221 Special flags like C<-Debug> can also be specified as
 222 arguments when Catalyst is loaded:
 223
 224     use Catalyst qw/-Debug My::Module/;
 225
 226 The position of plugins and flags in the chain is important, because
 227 they are loaded in the order in which they appear.
 228
 229 The following flags are supported:
 230
 231 =head2 -Debug
 232
 233 Enables debug output. You can also force this setting from the system
 234 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 235 settings override the application, with <MYAPP>_DEBUG having the highest
 236 priority.
 237
 238 This sets the log level to 'debug' and enables full debug output on the
 239 error screen. If you only want the latter, see L<< $c->debug >>.
 240
 241 =head2 -Home
 242
 243 Forces Catalyst to use a specific home directory, e.g.:
 244
 245     use Catalyst qw[-Home=/usr/mst];
 246
 247 This can also be done in the shell environment by setting either the
 248 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 249 is replaced with the uppercased name of your application, any "::" in
 250 the name will be replaced with underscores, e.g. MyApp::Web should use
 251 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 252
 253 If none of these are set, Catalyst will attempt to automatically detect the
 254 home directory. If you are working in a development environment, Catalyst
 255 will try and find the directory containing either Makefile.PL, Build.PL or
 256 dist.ini. If the application has been installed into the system (i.e.
 257 you have done C<make install>), then Catalyst will use the path to your
 258 application module, without the .pm extension (e.g., /foo/MyApp if your
 259 application was installed at /foo/MyApp.pm)
 260
 261 =head2 -Log
 262
 263     use Catalyst '-Log=warn,fatal,error';
 264
 265 Specifies a comma-delimited list of log levels.
 266
 267 =head2 -Stats
 268
 269 Enables statistics collection and reporting.
 270
 271    use Catalyst qw/-Stats=1/;
 272
 273 You can also force this setting from the system environment with CATALYST_STATS
 274 or <MYAPP>_STATS. The environment settings override the application, with
 275 <MYAPP>_STATS having the highest priority.
 276
 277 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 278
 279 =head1 METHODS
 280
 281 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 282
 283 =head2 $c->action
 284
 285 Returns a L<Catalyst::Action> object for the current action, which
 286 stringifies to the action name. See L<Catalyst::Action>.
 287
 288 =head2 $c->namespace
 289
 290 Returns the namespace of the current action, i.e., the URI prefix
 291 corresponding to the controller of the current action. For example:
 292
 293     # in Controller::Foo::Bar
 294     $c->namespace; # returns 'foo/bar';
 295
 296 =head2 $c->request
 297
 298 =head2 $c->req
 299
 300 Returns the current L<Catalyst::Request> object, giving access to
 301 information about the current client request (including parameters,
 302 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 303
 304 =head2 REQUEST FLOW HANDLING
 305
 306 =head2 $c->forward( $action [, \@arguments ] )
 307
 308 =head2 $c->forward( $class, $method, [, \@arguments ] )
 309
 310 Forwards processing to another action, by its private name. If you give a
 311 class name but no method, C<process()> is called. You may also optionally
 312 pass arguments in an arrayref. The action will receive the arguments in
 313 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 314 C<< $c->req->args >> will be restored to the previous values.
 315
 316 Any data C<return>ed from the action forwarded to, will be returned by the
 317 call to forward.
 318
 319     my $foodata = $c->forward('/foo');
 320     $c->forward('index');
 321     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 322     $c->forward('View::TT');
 323
 324 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 325 an C<< eval { } >> around the call (actually
 326 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 327 exceptions thrown by the called action non-fatal and pushing them onto
 328 $c->error instead. If you want C<die> to propagate you need to do something
 329 like:
 330
 331     $c->forward('foo');
 332     die join "\n", @{ $c->error } if @{ $c->error };
 333
 334 Or make sure to always return true values from your actions and write
 335 your code like this:
 336
 337     $c->forward('foo') || return;
 338
 339 Another note is that C<< $c->forward >> always returns a scalar because it
 340 actually returns $c->state which operates in a scalar context.
 341 Thus, something like:
 342
 343     return @array;
 344
 345 in an action that is forwarded to is going to return a scalar,
 346 i.e. how many items are in that array, which is probably not what you want.
 347 If you need to return an array then return a reference to it,
 348 or stash it like so:
 349
 350     $c->stash->{array} = \@array;
 351
 352 and access it from the stash.
 353
 354 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 355
 356 =cut
 357
 358 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 359
 360 =head2 $c->detach( $action [, \@arguments ] )
 361
 362 =head2 $c->detach( $class, $method, [, \@arguments ] )
 363
 364 =head2 $c->detach()
 365
 366 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 367 doesn't return to the previous action when processing is finished.
 368
 369 When called with no arguments it escapes the processing chain entirely.
 370
 371 =cut
 372
 373 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 374
 375 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 376
 377 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 378
 379 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 380 but does a full dispatch, instead of just calling the new C<$action> /
 381 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 382 you go to are called, just like a new request.
 383
 384 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 385 This means, for example, that C<< $c->action >> methods such as
 386 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 387 L<reverse|Catalyst::Action/reverse> return information for the visited action
 388 when they are invoked within the visited action.  This is different from the
 389 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 390 continues to use the $c->action object from the caller action even when
 391 invoked from the called action.
 392
 393 C<< $c->stash >> is kept unchanged.
 394
 395 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 396 allows you to "wrap" another action, just as it would have been called by
 397 dispatching from a URL, while the analogous
 398 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 399 transfer control to another action as if it had been reached directly from a URL.
 400
 401 =cut
 402
 403 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 404
 405 =head2 $c->go( $action [, \@captures, \@arguments ] )
 406
 407 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 408
 409 The relationship between C<go> and
 410 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 411 the relationship between
 412 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 413 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 414 C<< $c->go >> will perform a full dispatch on the specified action or method,
 415 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 416 C<go> escapes the processing of the current request chain on completion, and
 417 does not return to its caller.
 418
 419 @arguments are arguments to the final destination of $action. @captures are
 420 arguments to the intermediate steps, if any, on the way to the final sub of
 421 $action.
 422
 423 =cut
 424
 425 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 426
 427 =head2 $c->response
 428
 429 =head2 $c->res
 430
 431 Returns the current L<Catalyst::Response> object, see there for details.
 432
 433 =head2 $c->stash
 434
 435 Returns a hashref to the stash, which may be used to store data and pass
 436 it between components during a request. You can also set hash keys by
 437 passing arguments. The stash is automatically sent to the view. The
 438 stash is cleared at the end of a request; it cannot be used for
 439 persistent storage (for this you must use a session; see
 440 L<Catalyst::Plugin::Session> for a complete system integrated with
 441 Catalyst).
 442
 443     $c->stash->{foo} = $bar;
 444     $c->stash( { moose => 'majestic', qux => 0 } );
 445     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 446
 447     # stash is automatically passed to the view for use in a template
 448     $c->forward( 'MyApp::View::TT' );
 449
 450 =cut
 451
 452 around stash => sub {
 453     my $orig = shift;
 454     my $c = shift;
 455     my $stash = $orig->($c);
 456     if (@_) {
 457         my $new_stash = @_ > 1 ? {@_} : $_[0];
 458         croak('stash takes a hash or hashref') unless ref $new_stash;
 459         foreach my $key ( keys %$new_stash ) {
 460           $stash->{$key} = $new_stash->{$key};
 461         }
 462     }
 463
 464     return $stash;
 465 };
 466
 467
 468 =head2 $c->error
 469
 470 =head2 $c->error($error, ...)
 471
 472 =head2 $c->error($arrayref)
 473
 474 Returns an arrayref containing error messages.  If Catalyst encounters an
 475 error while processing a request, it stores the error in $c->error.  This
 476 method should only be used to store fatal error messages.
 477
 478     my @error = @{ $c->error };
 479
 480 Add a new error.
 481
 482     $c->error('Something bad happened');
 483
 484 =cut
 485
 486 sub error {
 487     my $c = shift;
 488     if ( $_[0] ) {
 489         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 490         croak @$error unless ref $c;
 491         push @{ $c->{error} }, @$error;
 492     }
 493     elsif ( defined $_[0] ) { $c->{error} = undef }
 494     return $c->{error} || [];
 495 }
 496
 497
 498 =head2 $c->state
 499
 500 Contains the return value of the last executed action.
 501 Note that << $c->state >> operates in a scalar context which means that all
 502 values it returns are scalar.
 503
 504 =head2 $c->clear_errors
 505
 506 Clear errors.  You probably don't want to clear the errors unless you are
 507 implementing a custom error screen.
 508
 509 This is equivalent to running
 510
 511     $c->error(0);
 512
 513 =cut
 514
 515 sub clear_errors {
 516     my $c = shift;
 517     $c->error(0);
 518 }
 519
 520 sub _comp_search_prefixes {
 521     my $c = shift;
 522     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 523 }
 524
 525 # search components given a name and some prefixes
 526 sub _comp_names_search_prefixes {
 527     my ( $c, $name, @prefixes ) = @_;
 528     my $appclass = ref $c || $c;
 529     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 530     $filter = qr/$filter/; # Compile regex now rather than once per loop
 531
 532     # map the original component name to the sub part that we will search against
 533     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 534         grep { /$filter/ } keys %{ $c->components };
 535
 536     # undef for a name will return all
 537     return keys %eligible if !defined $name;
 538
 539     my $query  = ref $name ? $name : qr/^$name$/i;
 540     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 541
 542     return @result if @result;
 543
 544     # if we were given a regexp to search against, we're done.
 545     return if ref $name;
 546
 547     # skip regexp fallback if configured
 548     return
 549         if $appclass->config->{disable_component_resolution_regex_fallback};
 550
 551     # regexp fallback
 552     $query  = qr/$name/i;
 553     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 554
 555     # no results? try against full names
 556     if( !@result ) {
 557         @result = grep { m{$query} } keys %eligible;
 558     }
 559
 560     # don't warn if we didn't find any results, it just might not exist
 561     if( @result ) {
 562         # Disgusting hack to work out correct method name
 563         my $warn_for = lc $prefixes[0];
 564         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 565            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 566            "component resolution is unreliable and unsafe.";
 567         my $short = $result[0];
 568         # remove the component namespace prefix
 569         $short =~ s/.*?(Model|Controller|View):://;
 570         my $shortmess = Carp::shortmess('');
 571         if ($shortmess =~ m#Catalyst/Plugin#) {
 572            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 573               "plugin's config";
 574         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 575            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 576               "component's config";
 577         } else {
 578            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 579               "but if you really wanted to search, pass in a regexp as the argument " .
 580               "like so: \$c->${warn_for}(qr/${name}/)";
 581         }
 582         $c->log->warn( "${msg}$shortmess" );
 583     }
 584
 585     return @result;
 586 }
 587
 588 # Find possible names for a prefix
 589 sub _comp_names {
 590     my ( $c, @prefixes ) = @_;
 591     my $appclass = ref $c || $c;
 592
 593     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 594
 595     my @names = map { s{$filter}{}; $_; }
 596         $c->_comp_names_search_prefixes( undef, @prefixes );
 597
 598     return @names;
 599 }
 600
 601 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 602 sub _filter_component {
 603     my ( $c, $comp, @args ) = @_;
 604
 605     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 606         return $comp->ACCEPT_CONTEXT( $c, @args );
 607     }
 608
 609     return $comp;
 610 }
 611
 612 =head2 COMPONENT ACCESSORS
 613
 614 =head2 $c->controller($name)
 615
 616 Gets a L<Catalyst::Controller> instance by name.
 617
 618     $c->controller('Foo')->do_stuff;
 619
 620 If the name is omitted, will return the controller for the dispatched
 621 action.
 622
 623 If you want to search for controllers, pass in a regexp as the argument.
 624
 625     # find all controllers that start with Foo
 626     my @foo_controllers = $c->controller(qr{^Foo});
 627
 628
 629 =cut
 630
 631 sub controller {
 632     my ( $c, $name, @args ) = @_;
 633
 634     my $appclass = ref($c) || $c;
 635     if( $name ) {
 636         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 637             my $comps = $c->components;
 638             my $check = $appclass."::Controller::".$name;
 639             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 640         }
 641         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 642         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 643         return $c->_filter_component( $result[ 0 ], @args );
 644     }
 645
 646     return $c->component( $c->action->class );
 647 }
 648
 649 =head2 $c->model($name)
 650
 651 Gets a L<Catalyst::Model> instance by name.
 652
 653     $c->model('Foo')->do_stuff;
 654
 655 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 656
 657 If the name is omitted, it will look for
 658  - a model object in $c->stash->{current_model_instance}, then
 659  - a model name in $c->stash->{current_model}, then
 660  - a config setting 'default_model', or
 661  - check if there is only one model, and return it if that's the case.
 662
 663 If you want to search for models, pass in a regexp as the argument.
 664
 665     # find all models that start with Foo
 666     my @foo_models = $c->model(qr{^Foo});
 667
 668 =cut
 669
 670 sub model {
 671     my ( $c, $name, @args ) = @_;
 672     my $appclass = ref($c) || $c;
 673     if( $name ) {
 674         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 675             my $comps = $c->components;
 676             my $check = $appclass."::Model::".$name;
 677             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 678         }
 679         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 680         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 681         return $c->_filter_component( $result[ 0 ], @args );
 682     }
 683
 684     if (ref $c) {
 685         return $c->stash->{current_model_instance}
 686           if $c->stash->{current_model_instance};
 687         return $c->model( $c->stash->{current_model} )
 688           if $c->stash->{current_model};
 689     }
 690     return $c->model( $appclass->config->{default_model} )
 691       if $appclass->config->{default_model};
 692
 693     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 694
 695     if( $rest ) {
 696         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 697         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 698         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 699         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 700         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 701     }
 702
 703     return $c->_filter_component( $comp );
 704 }
 705
 706
 707 =head2 $c->view($name)
 708
 709 Gets a L<Catalyst::View> instance by name.
 710
 711     $c->view('Foo')->do_stuff;
 712
 713 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 714
 715 If the name is omitted, it will look for
 716  - a view object in $c->stash->{current_view_instance}, then
 717  - a view name in $c->stash->{current_view}, then
 718  - a config setting 'default_view', or
 719  - check if there is only one view, and return it if that's the case.
 720
 721 If you want to search for views, pass in a regexp as the argument.
 722
 723     # find all views that start with Foo
 724     my @foo_views = $c->view(qr{^Foo});
 725
 726 =cut
 727
 728 sub view {
 729     my ( $c, $name, @args ) = @_;
 730
 731     my $appclass = ref($c) || $c;
 732     if( $name ) {
 733         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 734             my $comps = $c->components;
 735             my $check = $appclass."::View::".$name;
 736             if( exists $comps->{$check} ) {
 737                 return $c->_filter_component( $comps->{$check}, @args );
 738             }
 739             else {
 740                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 741             }
 742         }
 743         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 744         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 745         return $c->_filter_component( $result[ 0 ], @args );
 746     }
 747
 748     if (ref $c) {
 749         return $c->stash->{current_view_instance}
 750           if $c->stash->{current_view_instance};
 751         return $c->view( $c->stash->{current_view} )
 752           if $c->stash->{current_view};
 753     }
 754     return $c->view( $appclass->config->{default_view} )
 755       if $appclass->config->{default_view};
 756
 757     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 758
 759     if( $rest ) {
 760         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 761         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 762         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 763         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 764         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 765     }
 766
 767     return $c->_filter_component( $comp );
 768 }
 769
 770 =head2 $c->controllers
 771
 772 Returns the available names which can be passed to $c->controller
 773
 774 =cut
 775
 776 sub controllers {
 777     my ( $c ) = @_;
 778     return $c->_comp_names(qw/Controller C/);
 779 }
 780
 781 =head2 $c->models
 782
 783 Returns the available names which can be passed to $c->model
 784
 785 =cut
 786
 787 sub models {
 788     my ( $c ) = @_;
 789     return $c->_comp_names(qw/Model M/);
 790 }
 791
 792
 793 =head2 $c->views
 794
 795 Returns the available names which can be passed to $c->view
 796
 797 =cut
 798
 799 sub views {
 800     my ( $c ) = @_;
 801     return $c->_comp_names(qw/View V/);
 802 }
 803
 804 =head2 $c->comp($name)
 805
 806 =head2 $c->component($name)
 807
 808 Gets a component object by name. This method is not recommended,
 809 unless you want to get a specific component by full
 810 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 811 should be used instead.
 812
 813 If C<$name> is a regexp, a list of components matched against the full
 814 component name will be returned.
 815
 816 If Catalyst can't find a component by name, it will fallback to regex
 817 matching by default. To disable this behaviour set
 818 disable_component_resolution_regex_fallback to a true value.
 819
 820     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 821
 822 =cut
 823
 824 sub component {
 825     my ( $c, $name, @args ) = @_;
 826
 827     if( $name ) {
 828         my $comps = $c->components;
 829
 830         if( !ref $name ) {
 831             # is it the exact name?
 832             return $c->_filter_component( $comps->{ $name }, @args )
 833                        if exists $comps->{ $name };
 834
 835             # perhaps we just omitted "MyApp"?
 836             my $composed = ( ref $c || $c ) . "::${name}";
 837             return $c->_filter_component( $comps->{ $composed }, @args )
 838                        if exists $comps->{ $composed };
 839
 840             # search all of the models, views and controllers
 841             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 842             return $c->_filter_component( $comp, @args ) if $comp;
 843         }
 844
 845         return
 846             if $c->config->{disable_component_resolution_regex_fallback};
 847
 848         # This is here so $c->comp( '::M::' ) works
 849         my $query = ref $name ? $name : qr{$name}i;
 850
 851         my @result = grep { m{$query} } keys %{ $c->components };
 852         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 853
 854         if( $result[ 0 ] ) {
 855             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 856             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 857             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 858             return $c->_filter_component( $result[ 0 ], @args );
 859         }
 860
 861         # I would expect to return an empty list here, but that breaks back-compat
 862     }
 863
 864     # fallback
 865     return sort keys %{ $c->components };
 866 }
 867
 868 =head2 CLASS DATA AND HELPER CLASSES
 869
 870 =head2 $c->config
 871
 872 Returns or takes a hashref containing the application's configuration.
 873
 874     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 875
 876 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 877 like C<myapp.conf> in your applications home directory. See
 878 L<Catalyst::Plugin::ConfigLoader>.
 879
 880 =head3 Cascading configuration
 881
 882 The config method is present on all Catalyst components, and configuration
 883 will be merged when an application is started. Configuration loaded with
 884 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 885 followed by configuration in your top level C<MyApp> class. These two
 886 configurations are merged, and then configuration data whose hash key matches a
 887 component name is merged with configuration for that component.
 888
 889 The configuration for a component is then passed to the C<new> method when a
 890 component is constructed.
 891
 892 For example:
 893
 894     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 895     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 896
 897 will mean that C<MyApp::Model::Foo> receives the following data when
 898 constructed:
 899
 900     MyApp::Model::Foo->new({
 901         bar => 'baz',
 902         quux => 'frob',
 903         overrides => 'me',
 904     });
 905
 906 It's common practice to use a Moose attribute
 907 on the receiving component to access the config value.
 908
 909     package MyApp::Model::Foo;
 910
 911     use Moose;
 912
 913     # this attr will receive 'baz' at construction time
 914     has 'bar' => (
 915         is  => 'rw',
 916         isa => 'Str',
 917     );
 918
 919 You can then get the value 'baz' by calling $c->model('Foo')->bar
 920 (or $self->bar inside code in the model).
 921
 922 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 923 as a way of reading config within your code, as this B<will not> give you the
 924 correctly merged config back. You B<MUST> take the config values supplied to
 925 the constructor and use those instead.
 926
 927 =cut
 928
 929 around config => sub {
 930     my $orig = shift;
 931     my $c = shift;
 932
 933     croak('Setting config after setup has been run is not allowed.')
 934         if ( @_ and $c->setup_finished );
 935
 936     $c->$orig(@_);
 937 };
 938
 939 =head2 $c->log
 940
 941 Returns the logging object instance. Unless it is already set, Catalyst
 942 sets this up with a L<Catalyst::Log> object. To use your own log class,
 943 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 944 C<< __PACKAGE__->setup >>.
 945
 946  __PACKAGE__->log( MyLogger->new );
 947  __PACKAGE__->setup;
 948
 949 And later:
 950
 951     $c->log->info( 'Now logging with my own logger!' );
 952
 953 Your log class should implement the methods described in
 954 L<Catalyst::Log>.
 955
 956
 957 =head2 $c->debug
 958
 959 Returns 1 if debug mode is enabled, 0 otherwise.
 960
 961 You can enable debug mode in several ways:
 962
 963 =over
 964
 965 =item By calling myapp_server.pl with the -d flag
 966
 967 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 968
 969 =item The -Debug option in your MyApp.pm
 970
 971 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 972
 973 =back
 974
 975 The first three also set the log level to 'debug'.
 976
 977 Calling C<< $c->debug(1) >> has no effect.
 978
 979 =cut
 980
 981 sub debug { 0 }
 982
 983 =head2 $c->dispatcher
 984
 985 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 986
 987 =head2 $c->engine
 988
 989 Returns the engine instance. See L<Catalyst::Engine>.
 990
 991
 992 =head2 UTILITY METHODS
 993
 994 =head2 $c->path_to(@path)
 995
 996 Merges C<@path> with C<< $c->config->{home} >> and returns a
 997 L<Path::Class::Dir> object. Note you can usually use this object as
 998 a filename, but sometimes you will have to explicitly stringify it
 999 yourself by calling the C<< ->stringify >> method.
1000
1001 For example:
1002
1003     $c->path_to( 'db', 'sqlite.db' );
1004
1005 =cut
1006
1007 sub path_to {
1008     my ( $c, @path ) = @_;
1009     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1010     if ( -d $path ) { return $path }
1011     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1012 }
1013
1014 sub plugin {
1015     my ( $class, $name, $plugin, @args ) = @_;
1016
1017     # See block comment in t/unit_core_plugin.t
1018     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1019
1020     $class->_register_plugin( $plugin, 1 );
1021
1022     eval { $plugin->import };
1023     $class->mk_classdata($name);
1024     my $obj;
1025     eval { $obj = $plugin->new(@args) };
1026
1027     if ($@) {
1028         Catalyst::Exception->throw( message =>
1029               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1030     }
1031
1032     $class->$name($obj);
1033     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1034       if $class->debug;
1035 }
1036
1037 =head2 MyApp->setup
1038
1039 Initializes the dispatcher and engine, loads any plugins, and loads the
1040 model, view, and controller components. You may also specify an array
1041 of plugins to load here, if you choose to not load them in the C<use
1042 Catalyst> line.
1043
1044     MyApp->setup;
1045     MyApp->setup( qw/-Debug/ );
1046
1047 B<Note:> You B<should not> wrap this method with method modifiers
1048 or bad things will happen - wrap the C<setup_finalize> method instead.
1049
1050 =cut
1051
1052 sub setup {
1053     my ( $class, @arguments ) = @_;
1054     croak('Running setup more than once')
1055         if ( $class->setup_finished );
1056
1057     unless ( $class->isa('Catalyst') ) {
1058
1059         Catalyst::Exception->throw(
1060             message => qq/'$class' does not inherit from Catalyst/ );
1061     }
1062
1063     if ( $class->arguments ) {
1064         @arguments = ( @arguments, @{ $class->arguments } );
1065     }
1066
1067     # Process options
1068     my $flags = {};
1069
1070     foreach (@arguments) {
1071
1072         if (/^-Debug$/) {
1073             $flags->{log} =
1074               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1075         }
1076         elsif (/^-(\w+)=?(.*)$/) {
1077             $flags->{ lc $1 } = $2;
1078         }
1079         else {
1080             push @{ $flags->{plugins} }, $_;
1081         }
1082     }
1083
1084     $class->setup_home( delete $flags->{home} );
1085
1086     $class->setup_log( delete $flags->{log} );
1087     $class->setup_plugins( delete $flags->{plugins} );
1088     $class->setup_dispatcher( delete $flags->{dispatcher} );
1089     if (my $engine = delete $flags->{engine}) {
1090         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1091     }
1092     $class->setup_engine();
1093     $class->setup_stats( delete $flags->{stats} );
1094
1095     for my $flag ( sort keys %{$flags} ) {
1096
1097         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1098             &$code( $class, delete $flags->{$flag} );
1099         }
1100         else {
1101             $class->log->warn(qq/Unknown flag "$flag"/);
1102         }
1103     }
1104
1105     eval { require Catalyst::Devel; };
1106     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1107         $class->log->warn(<<"EOF");
1108 You are running an old script!
1109
1110   Please update by running (this will overwrite existing files):
1111     catalyst.pl -force -scripts $class
1112
1113   or (this will not overwrite existing files):
1114     catalyst.pl -scripts $class
1115
1116 EOF
1117     }
1118
1119     if ( $class->debug ) {
1120         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1121
1122         if (@plugins) {
1123             my $column_width = Catalyst::Utils::term_width() - 6;
1124             my $t = Text::SimpleTable->new($column_width);
1125             $t->row($_) for @plugins;
1126             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1127         }
1128
1129         my $dispatcher = $class->dispatcher;
1130         my $engine     = $class->engine;
1131         my $home       = $class->config->{home};
1132
1133         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1134         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1135
1136         $home
1137           ? ( -d $home )
1138           ? $class->log->debug(qq/Found home "$home"/)
1139           : $class->log->debug(qq/Home "$home" doesn't exist/)
1140           : $class->log->debug(q/Couldn't find home/);
1141     }
1142
1143     # Call plugins setup, this is stupid and evil.
1144     # Also screws C3 badly on 5.10, hack to avoid.
1145     {
1146         no warnings qw/redefine/;
1147         local *setup = sub { };
1148         $class->setup unless $Catalyst::__AM_RESTARTING;
1149     }
1150
1151     # Initialize our data structure
1152     $class->components( {} );
1153
1154     $class->setup_components;
1155
1156     if ( $class->debug ) {
1157         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1158         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1159         for my $comp ( sort keys %{ $class->components } ) {
1160             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1161             $t->row( $comp, $type );
1162         }
1163         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1164           if ( keys %{ $class->components } );
1165     }
1166
1167     # Add our self to components, since we are also a component
1168     if( $class->isa('Catalyst::Controller') ){
1169       $class->components->{$class} = $class;
1170     }
1171
1172     $class->setup_actions;
1173
1174     if ( $class->debug ) {
1175         my $name = $class->config->{name} || 'Application';
1176         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1177     }
1178
1179     # Make sure that the application class becomes immutable at this point,
1180     B::Hooks::EndOfScope::on_scope_end {
1181         return if $@;
1182         my $meta = Class::MOP::get_metaclass_by_name($class);
1183         if (
1184             $meta->is_immutable
1185             && ! { $meta->immutable_options }->{replace_constructor}
1186             && (
1187                    $class->isa('Class::Accessor::Fast')
1188                 || $class->isa('Class::Accessor')
1189             )
1190         ) {
1191             warn "You made your application class ($class) immutable, "
1192                 . "but did not inline the\nconstructor. "
1193                 . "This will break catalyst, as your app \@ISA "
1194                 . "Class::Accessor(::Fast)?\nPlease pass "
1195                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1196         }
1197         $meta->make_immutable(
1198             replace_constructor => 1,
1199         ) unless $meta->is_immutable;
1200     };
1201
1202     if ($class->config->{case_sensitive}) {
1203         $class->log->warn($class . "->config->{case_sensitive} is set.");
1204         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1205     }
1206
1207     $class->setup_finalize;
1208     # Should be the last thing we do so that user things hooking
1209     # setup_finalize can log..
1210     $class->log->_flush() if $class->log->can('_flush');
1211     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1212 }
1213
1214 =head2 $app->setup_finalize
1215
1216 A hook to attach modifiers to. This method does not do anything except set the
1217 C<setup_finished> accessor.
1218
1219 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1220
1221 Example:
1222
1223     after setup_finalize => sub {
1224         my $app = shift;
1225
1226         ## do stuff here..
1227     };
1228
1229 =cut
1230
1231 sub setup_finalize {
1232     my ($class) = @_;
1233     $class->setup_finished(1);
1234 }
1235
1236 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1237
1238 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1239
1240 Constructs an absolute L<URI> object based on the application root, the
1241 provided path, and the additional arguments and query parameters provided.
1242 When used as a string, provides a textual URI.  If you need more flexibility
1243 than this (i.e. the option to provide relative URIs etc.) see
1244 L<Catalyst::Plugin::SmartURI>.
1245
1246 If no arguments are provided, the URI for the current action is returned.
1247 To return the current action and also provide @args, use
1248 C<< $c->uri_for( $c->action, @args ) >>.
1249
1250 If the first argument is a string, it is taken as a public URI path relative
1251 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1252 relative to the application root (if it does). It is then merged with
1253 C<< $c->request->base >>; any C<@args> are appended as additional path
1254 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1255
1256 If the first argument is a L<Catalyst::Action> it represents an action which
1257 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1258 optional C<\@captures> argument (an arrayref) allows passing the captured
1259 variables that are needed to fill in the paths of Chained and Regex actions;
1260 once the path is resolved, C<uri_for> continues as though a path was
1261 provided, appending any arguments or parameters and creating an absolute
1262 URI.
1263
1264 The captures for the current request can be found in
1265 C<< $c->request->captures >>, and actions can be resolved using
1266 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1267 path, use C<< $c->uri_for_action >> instead.
1268
1269   # Equivalent to $c->req->uri
1270   $c->uri_for($c->action, $c->req->captures,
1271       @{ $c->req->args }, $c->req->params);
1272
1273   # For the Foo action in the Bar controller
1274   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1275
1276   # Path to a static resource
1277   $c->uri_for('/static/images/logo.png');
1278
1279 =cut
1280
1281 sub uri_for {
1282     my ( $c, $path, @args ) = @_;
1283
1284     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1285         $path = $path->path_prefix;
1286         $path =~ s{/+\z}{};
1287         $path .= '/';
1288     }
1289
1290     undef($path) if (defined $path && $path eq '');
1291
1292     my $params =
1293       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1294
1295     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1296     foreach my $arg (@args) {
1297         utf8::encode($arg) if utf8::is_utf8($arg);
1298         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1299     }
1300
1301     if ( blessed($path) ) { # action object
1302         s|/|%2F|g for @args;
1303         my $captures = [ map { s|/|%2F|g; $_; }
1304                         ( scalar @args && ref $args[0] eq 'ARRAY'
1305                          ? @{ shift(@args) }
1306                          : ()) ];
1307
1308         foreach my $capture (@$captures) {
1309             utf8::encode($capture) if utf8::is_utf8($capture);
1310             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1311         }
1312
1313         my $action = $path;
1314         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1315         if( !@args && $action->number_of_args ) {
1316             my $expanded_action = $c->dispatcher->expand_action( $action );
1317
1318             my $num_captures = $expanded_action->number_of_captures;
1319             unshift @args, splice @$captures, $num_captures;
1320         }
1321
1322        $path = $c->dispatcher->uri_for_action($action, $captures);
1323         if (not defined $path) {
1324             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1325                 if $c->debug;
1326             return undef;
1327         }
1328         $path = '/' if $path eq '';
1329     }
1330
1331     unshift(@args, $path);
1332
1333     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1334         my $namespace = $c->namespace;
1335         if (defined $path) { # cheesy hack to handle path '../foo'
1336            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1337         }
1338         unshift(@args, $namespace || '');
1339     }
1340
1341     # join args with '/', or a blank string
1342     my $args = join('/', grep { defined($_) } @args);
1343     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1344     $args =~ s!^/+!!;
1345     my $base = $c->req->base;
1346     my $class = ref($base);
1347     $base =~ s{(?<!/)$}{/};
1348
1349     my $query = '';
1350
1351     if (my @keys = keys %$params) {
1352       # somewhat lifted from URI::_query's query_form
1353       $query = '?'.join('&', map {
1354           my $val = $params->{$_};
1355           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1356           s/ /+/g;
1357           my $key = $_;
1358           $val = '' unless defined $val;
1359           (map {
1360               my $param = "$_";
1361               utf8::encode( $param ) if utf8::is_utf8($param);
1362               # using the URI::Escape pattern here so utf8 chars survive
1363               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1364               $param =~ s/ /+/g;
1365               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1366       } @keys);
1367     }
1368
1369     my $res = bless(\"${base}${args}${query}", $class);
1370     $res;
1371 }
1372
1373 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1374
1375 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1376
1377 =over
1378
1379 =item $path
1380
1381 A private path to the Catalyst action you want to create a URI for.
1382
1383 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1384 >> and passing the resulting C<$action> and the remaining arguments to C<<
1385 $c->uri_for >>.
1386
1387 You can also pass in a Catalyst::Action object, in which case it is passed to
1388 C<< $c->uri_for >>.
1389
1390 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1391
1392 For example, if the action looks like:
1393
1394  package MyApp::Controller::Users;
1395
1396  sub lst : Path('the-list') {}
1397
1398 You can use:
1399
1400  $c->uri_for_action('/users/lst')
1401
1402 and it will create the URI /users/the-list.
1403
1404 =item \@captures_and_args?
1405
1406 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1407 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1408 to interpolate all the parameters in the URI.
1409
1410 =item @args?
1411
1412 Optional list of extra arguments - can be supplied in the
1413 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1414 code.
1415
1416 Your action can have zero, a fixed or a variable number of args (e.g.
1417 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1418
1419 =item \%query_values?
1420
1421 Optional array reference of query parameters to append. E.g.
1422
1423   { foo => 'bar' }
1424
1425 will generate
1426
1427   /rest/of/your/uri?foo=bar
1428
1429 =back
1430
1431 =cut
1432
1433 sub uri_for_action {
1434     my ( $c, $path, @args ) = @_;
1435     my $action = blessed($path)
1436       ? $path
1437       : $c->dispatcher->get_action_by_path($path);
1438     unless (defined $action) {
1439       croak "Can't find action for path '$path'";
1440     }
1441     return $c->uri_for( $action, @args );
1442 }
1443
1444 =head2 $c->welcome_message
1445
1446 Returns the Catalyst welcome HTML page.
1447
1448 =cut
1449
1450 sub welcome_message {
1451     my $c      = shift;
1452     my $name   = $c->config->{name};
1453     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1454     my $prefix = Catalyst::Utils::appprefix( ref $c );
1455     $c->response->content_type('text/html; charset=utf-8');
1456     return <<"EOF";
1457 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1458     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1459 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1460     <head>
1461     <meta http-equiv="Content-Language" content="en" />
1462     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1463         <title>$name on Catalyst $VERSION</title>
1464         <style type="text/css">
1465             body {
1466                 color: #000;
1467                 background-color: #eee;
1468             }
1469             div#content {
1470                 width: 640px;
1471                 margin-left: auto;
1472                 margin-right: auto;
1473                 margin-top: 10px;
1474                 margin-bottom: 10px;
1475                 text-align: left;
1476                 background-color: #ccc;
1477                 border: 1px solid #aaa;
1478             }
1479             p, h1, h2 {
1480                 margin-left: 20px;
1481                 margin-right: 20px;
1482                 font-family: verdana, tahoma, sans-serif;
1483             }
1484             a {
1485                 font-family: verdana, tahoma, sans-serif;
1486             }
1487             :link, :visited {
1488                     text-decoration: none;
1489                     color: #b00;
1490                     border-bottom: 1px dotted #bbb;
1491             }
1492             :link:hover, :visited:hover {
1493                     color: #555;
1494             }
1495             div#topbar {
1496                 margin: 0px;
1497             }
1498             pre {
1499                 margin: 10px;
1500                 padding: 8px;
1501             }
1502             div#answers {
1503                 padding: 8px;
1504                 margin: 10px;
1505                 background-color: #fff;
1506                 border: 1px solid #aaa;
1507             }
1508             h1 {
1509                 font-size: 0.9em;
1510                 font-weight: normal;
1511                 text-align: center;
1512             }
1513             h2 {
1514                 font-size: 1.0em;
1515             }
1516             p {
1517                 font-size: 0.9em;
1518             }
1519             p img {
1520                 float: right;
1521                 margin-left: 10px;
1522             }
1523             span#appname {
1524                 font-weight: bold;
1525                 font-size: 1.6em;
1526             }
1527         </style>
1528     </head>
1529     <body>
1530         <div id="content">
1531             <div id="topbar">
1532                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1533                     $VERSION</h1>
1534              </div>
1535              <div id="answers">
1536                  <p>
1537                  <img src="$logo" alt="Catalyst Logo" />
1538                  </p>
1539                  <p>Welcome to the  world of Catalyst.
1540                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1541                     framework will make web development something you had
1542                     never expected it to be: Fun, rewarding, and quick.</p>
1543                  <h2>What to do now?</h2>
1544                  <p>That really depends  on what <b>you</b> want to do.
1545                     We do, however, provide you with a few starting points.</p>
1546                  <p>If you want to jump right into web development with Catalyst
1547                     you might want to start with a tutorial.</p>
1548 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1549 </pre>
1550 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1551 <pre>
1552 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1553 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1554 </code></pre>
1555                  <h2>What to do next?</h2>
1556                  <p>Next it's time to write an actual application. Use the
1557                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1558                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1559                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1560                     they can save you a lot of work.</p>
1561                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1562                     <p>Also, be sure to check out the vast and growing
1563                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1564                     you are likely to find what you need there.
1565                     </p>
1566
1567                  <h2>Need help?</h2>
1568                  <p>Catalyst has a very active community. Here are the main places to
1569                     get in touch with us.</p>
1570                  <ul>
1571                      <li>
1572                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1573                      </li>
1574                      <li>
1575                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1576                      </li>
1577                      <li>
1578                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1579                      </li>
1580                  </ul>
1581                  <h2>In conclusion</h2>
1582                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1583                     as we enjoyed making it. Please contact us if you have ideas
1584                     for improvement or other feedback.</p>
1585              </div>
1586          </div>
1587     </body>
1588 </html>
1589 EOF
1590 }
1591
1592 =head2 run_options
1593
1594 Contains a hash of options passed from the application script, including
1595 the original ARGV the script received, the processed values from that
1596 ARGV and any extra arguments to the script which were not processed.
1597
1598 This can be used to add custom options to your application's scripts
1599 and setup your application differently depending on the values of these
1600 options.
1601
1602 =head1 INTERNAL METHODS
1603
1604 These methods are not meant to be used by end users.
1605
1606 =head2 $c->components
1607
1608 Returns a hash of components.
1609
1610 =head2 $c->context_class
1611
1612 Returns or sets the context class.
1613
1614 =head2 $c->counter
1615
1616 Returns a hashref containing coderefs and execution counts (needed for
1617 deep recursion detection).
1618
1619 =head2 $c->depth
1620
1621 Returns the number of actions on the current internal execution stack.
1622
1623 =head2 $c->dispatch
1624
1625 Dispatches a request to actions.
1626
1627 =cut
1628
1629 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1630
1631 =head2 $c->dispatcher_class
1632
1633 Returns or sets the dispatcher class.
1634
1635 =head2 $c->dump_these
1636
1637 Returns a list of 2-element array references (name, structure) pairs
1638 that will be dumped on the error page in debug mode.
1639
1640 =cut
1641
1642 sub dump_these {
1643     my $c = shift;
1644     [ Request => $c->req ],
1645     [ Response => $c->res ],
1646     [ Stash => $c->stash ],
1647     [ Config => $c->config ];
1648 }
1649
1650 =head2 $c->engine_class
1651
1652 Returns or sets the engine class.
1653
1654 =head2 $c->execute( $class, $coderef )
1655
1656 Execute a coderef in given class and catch exceptions. Errors are available
1657 via $c->error.
1658
1659 =cut
1660
1661 sub execute {
1662     my ( $c, $class, $code ) = @_;
1663     $class = $c->component($class) || $class;
1664     $c->state(0);
1665
1666     if ( $c->depth >= $RECURSION ) {
1667         my $action = $code->reverse();
1668         $action = "/$action" unless $action =~ /->/;
1669         my $error = qq/Deep recursion detected calling "${action}"/;
1670         $c->log->error($error);
1671         $c->error($error);
1672         $c->state(0);
1673         return $c->state;
1674     }
1675
1676     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1677
1678     push( @{ $c->stack }, $code );
1679
1680     no warnings 'recursion';
1681     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1682     #      I have no idea how, ergo $ret (which appears to fix the issue)
1683     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1684
1685     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1686
1687     my $last = pop( @{ $c->stack } );
1688
1689     if ( my $error = $@ ) {
1690         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1691             $error->rethrow if $c->depth > 1;
1692         }
1693         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1694             $error->rethrow if $c->depth > 0;
1695         }
1696         else {
1697             unless ( ref $error ) {
1698                 no warnings 'uninitialized';
1699                 chomp $error;
1700                 my $class = $last->class;
1701                 my $name  = $last->name;
1702                 $error = qq/Caught exception in $class->$name "$error"/;
1703             }
1704             $c->error($error);
1705         }
1706         $c->state(0);
1707     }
1708     return $c->state;
1709 }
1710
1711 sub _stats_start_execute {
1712     my ( $c, $code ) = @_;
1713     my $appclass = ref($c) || $c;
1714     return if ( ( $code->name =~ /^_.*/ )
1715         && ( !$appclass->config->{show_internal_actions} ) );
1716
1717     my $action_name = $code->reverse();
1718     $c->counter->{$action_name}++;
1719
1720     my $action = $action_name;
1721     $action = "/$action" unless $action =~ /->/;
1722
1723     # determine if the call was the result of a forward
1724     # this is done by walking up the call stack and looking for a calling
1725     # sub of Catalyst::forward before the eval
1726     my $callsub = q{};
1727     for my $index ( 2 .. 11 ) {
1728         last
1729         if ( ( caller($index) )[0] eq 'Catalyst'
1730             && ( caller($index) )[3] eq '(eval)' );
1731
1732         if ( ( caller($index) )[3] =~ /forward$/ ) {
1733             $callsub = ( caller($index) )[3];
1734             $action  = "-> $action";
1735             last;
1736         }
1737     }
1738
1739     my $uid = $action_name . $c->counter->{$action_name};
1740
1741     # is this a root-level call or a forwarded call?
1742     if ( $callsub =~ /forward$/ ) {
1743         my $parent = $c->stack->[-1];
1744
1745         # forward, locate the caller
1746         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1747             $c->stats->profile(
1748                 begin  => $action,
1749                 parent => "$parent" . $c->counter->{"$parent"},
1750                 uid    => $uid,
1751             );
1752         }
1753         else {
1754
1755             # forward with no caller may come from a plugin
1756             $c->stats->profile(
1757                 begin => $action,
1758                 uid   => $uid,
1759             );
1760         }
1761     }
1762     else {
1763
1764         # root-level call
1765         $c->stats->profile(
1766             begin => $action,
1767             uid   => $uid,
1768         );
1769     }
1770     return $action;
1771
1772 }
1773
1774 sub _stats_finish_execute {
1775     my ( $c, $info ) = @_;
1776     $c->stats->profile( end => $info );
1777 }
1778
1779 =head2 $c->finalize
1780
1781 Finalizes the request.
1782
1783 =cut
1784
1785 sub finalize {
1786     my $c = shift;
1787
1788     for my $error ( @{ $c->error } ) {
1789         $c->log->error($error);
1790     }
1791
1792     # Allow engine to handle finalize flow (for POE)
1793     my $engine = $c->engine;
1794     if ( my $code = $engine->can('finalize') ) {
1795         $engine->$code($c);
1796     }
1797     else {
1798
1799         $c->finalize_uploads;
1800
1801         # Error
1802         if ( $#{ $c->error } >= 0 ) {
1803             $c->finalize_error;
1804         }
1805
1806         $c->finalize_headers;
1807
1808         # HEAD request
1809         if ( $c->request->method eq 'HEAD' ) {
1810             $c->response->body('');
1811         }
1812
1813         $c->finalize_body;
1814     }
1815
1816     $c->log_response;
1817
1818     if ($c->use_stats) {
1819         my $elapsed = sprintf '%f', $c->stats->elapsed;
1820         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1821         $c->log->info(
1822             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1823     }
1824
1825     return $c->response->status;
1826 }
1827
1828 =head2 $c->finalize_body
1829
1830 Finalizes body.
1831
1832 =cut
1833
1834 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1835
1836 =head2 $c->finalize_cookies
1837
1838 Finalizes cookies.
1839
1840 =cut
1841
1842 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1843
1844 =head2 $c->finalize_error
1845
1846 Finalizes error.
1847
1848 =cut
1849
1850 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1851
1852 =head2 $c->finalize_headers
1853
1854 Finalizes headers.
1855
1856 =cut
1857
1858 sub finalize_headers {
1859     my $c = shift;
1860
1861     my $response = $c->response; #accessor calls can add up?
1862
1863     # Check if we already finalized headers
1864     return if $response->finalized_headers;
1865
1866     # Handle redirects
1867     if ( my $location = $response->redirect ) {
1868         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1869         $response->header( Location => $location );
1870
1871         if ( !$response->has_body ) {
1872             # Add a default body if none is already present
1873             $response->body(<<"EOF");
1874 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1875 <html xmlns="http://www.w3.org/1999/xhtml">
1876   <head>
1877     <title>Moved</title>
1878   </head>
1879   <body>
1880      <p>This item has moved <a href="$location">here</a>.</p>
1881   </body>
1882 </html>
1883 EOF
1884             $response->content_type('text/html; charset=utf-8');
1885         }
1886     }
1887
1888     # Content-Length
1889     if ( defined $response->body && length $response->body && !$response->content_length ) {
1890
1891         # get the length from a filehandle
1892         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1893         {
1894             my $size = -s $response->body;
1895             if ( $size ) {
1896                 $response->content_length( $size );
1897             }
1898             else {
1899                 $c->log->warn('Serving filehandle without a content-length');
1900             }
1901         }
1902         else {
1903             # everything should be bytes at this point, but just in case
1904             $response->content_length( length( $response->body ) );
1905         }
1906     }
1907
1908     # Errors
1909     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1910         $response->headers->remove_header("Content-Length");
1911         $response->body('');
1912     }
1913
1914     $c->finalize_cookies;
1915
1916     $c->engine->finalize_headers( $c, @_ );
1917
1918     # Done
1919     $response->finalized_headers(1);
1920 }
1921
1922 =head2 $c->finalize_output
1923
1924 An alias for finalize_body.
1925
1926 =head2 $c->finalize_read
1927
1928 Finalizes the input after reading is complete.
1929
1930 =cut
1931
1932 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1933
1934 =head2 $c->finalize_uploads
1935
1936 Finalizes uploads. Cleans up any temporary files.
1937
1938 =cut
1939
1940 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1941
1942 =head2 $c->get_action( $action, $namespace )
1943
1944 Gets an action in a given namespace.
1945
1946 =cut
1947
1948 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1949
1950 =head2 $c->get_actions( $action, $namespace )
1951
1952 Gets all actions of a given name in a namespace and all parent
1953 namespaces.
1954
1955 =cut
1956
1957 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1958
1959 =head2 $app->handle_request( @arguments )
1960
1961 Called to handle each HTTP request.
1962
1963 =cut
1964
1965 sub handle_request {
1966     my ( $class, @arguments ) = @_;
1967
1968     # Always expect worst case!
1969     my $status = -1;
1970     try {
1971         if ($class->debug) {
1972             my $secs = time - $START || 1;
1973             my $av = sprintf '%.3f', $COUNT / $secs;
1974             my $time = localtime time;
1975             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1976         }
1977
1978         my $c = $class->prepare(@arguments);
1979         $c->dispatch;
1980         $status = $c->finalize;
1981     }
1982     catch {
1983         chomp(my $error = $_);
1984         $class->log->error(qq/Caught exception in engine "$error"/);
1985     };
1986
1987     $COUNT++;
1988
1989     if(my $coderef = $class->log->can('_flush')){
1990         $class->log->$coderef();
1991     }
1992     return $status;
1993 }
1994
1995 =head2 $class->prepare( @arguments )
1996
1997 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1998 etc.).
1999
2000 =cut
2001
2002 has _uploadtmp => (
2003     is => 'ro',
2004     predicate => '_has_uploadtmp',
2005 );
2006
2007 sub prepare {
2008     my ( $class, @arguments ) = @_;
2009
2010     # XXX
2011     # After the app/ctxt split, this should become an attribute based on something passed
2012     # into the application.
2013     $class->context_class( ref $class || $class ) unless $class->context_class;
2014
2015     my $uploadtmp = $class->config->{uploadtmp};
2016     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2017
2018     #surely this is not the most efficient way to do things...
2019     $c->stats($class->stats_class->new)->enable($c->use_stats);
2020     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2021         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2022     }
2023
2024     try {
2025         # Allow engine to direct the prepare flow (for POE)
2026         if ( my $prepare = $c->engine->can('prepare') ) {
2027             $c->engine->$prepare( $c, @arguments );
2028         }
2029         else {
2030             $c->prepare_request(@arguments);
2031             $c->prepare_connection;
2032             $c->prepare_query_parameters;
2033             $c->prepare_path;
2034
2035             # Prepare the body for reading, either by prepare_body
2036             # or the user, if they are using $c->read
2037             $c->prepare_read;
2038
2039             # Parse the body unless the user wants it on-demand
2040             unless ( ref($c)->config->{parse_on_demand} ) {
2041                 $c->prepare_body;
2042             }
2043         }
2044     }
2045     # VERY ugly and probably shouldn't rely on ->finalize actually working
2046     catch {
2047         # failed prepare is always due to an invalid request, right?
2048         $c->response->status(400);
2049         $c->response->content_type('text/plain');
2050         $c->response->body('Bad Request');
2051         $c->finalize;
2052         die $_;
2053     };
2054
2055     my $method  = $c->req->method  || '';
2056     my $path    = $c->req->path;
2057     $path       = '/' unless length $path;
2058     my $address = $c->req->address || '';
2059
2060     $c->log_request;
2061
2062     $c->prepare_action;
2063
2064     return $c;
2065 }
2066
2067 =head2 $c->prepare_action
2068
2069 Prepares action. See L<Catalyst::Dispatcher>.
2070
2071 =cut
2072
2073 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2074
2075 =head2 $c->prepare_body
2076
2077 Prepares message body.
2078
2079 =cut
2080
2081 sub prepare_body {
2082     my $c = shift;
2083
2084     return if $c->request->_has_body;
2085
2086     # Initialize on-demand data
2087     $c->engine->prepare_body( $c, @_ );
2088     $c->prepare_parameters;
2089     $c->prepare_uploads;
2090 }
2091
2092 =head2 $c->prepare_body_chunk( $chunk )
2093
2094 Prepares a chunk of data before sending it to L<HTTP::Body>.
2095
2096 See L<Catalyst::Engine>.
2097
2098 =cut
2099
2100 sub prepare_body_chunk {
2101     my $c = shift;
2102     $c->engine->prepare_body_chunk( $c, @_ );
2103 }
2104
2105 =head2 $c->prepare_body_parameters
2106
2107 Prepares body parameters.
2108
2109 =cut
2110
2111 sub prepare_body_parameters {
2112     my $c = shift;
2113     $c->engine->prepare_body_parameters( $c, @_ );
2114 }
2115
2116 =head2 $c->prepare_connection
2117
2118 Prepares connection.
2119
2120 =cut
2121
2122 sub prepare_connection {
2123     my $c = shift;
2124     # XXX - This is called on the engine (not the request) to maintain
2125     #       Engine::PSGI back compat.
2126     $c->engine->prepare_connection($c);
2127 }
2128
2129 =head2 $c->prepare_parameters
2130
2131 Prepares parameters.
2132
2133 =cut
2134
2135 sub prepare_parameters {
2136     my $c = shift;
2137     $c->prepare_body_parameters;
2138     $c->engine->prepare_parameters( $c, @_ );
2139 }
2140
2141 =head2 $c->prepare_path
2142
2143 Prepares path and base.
2144
2145 =cut
2146
2147 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2148
2149 =head2 $c->prepare_query_parameters
2150
2151 Prepares query parameters.
2152
2153 =cut
2154
2155 sub prepare_query_parameters {
2156     my $c = shift;
2157
2158     $c->engine->prepare_query_parameters( $c, @_ );
2159 }
2160
2161 =head2 $c->log_request
2162
2163 Writes information about the request to the debug logs.  This includes:
2164
2165 =over 4
2166
2167 =item * Request method, path, and remote IP address
2168
2169 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2170
2171 =item * Request parameters
2172
2173 =item * File uploads
2174
2175 =back
2176
2177 =cut
2178
2179 sub log_request {
2180     my $c = shift;
2181
2182     return unless $c->debug;
2183
2184     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2185     my $request = $dump->[1];
2186
2187     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2188     $method ||= '';
2189     $path = '/' unless length $path;
2190     $address ||= '';
2191     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2192
2193     $c->log_request_headers($request->headers);
2194
2195     if ( my $keywords = $request->query_keywords ) {
2196         $c->log->debug("Query keywords are: $keywords");
2197     }
2198
2199     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2200
2201     $c->log_request_uploads($request);
2202 }
2203
2204 =head2 $c->log_response
2205
2206 Writes information about the response to the debug logs by calling
2207 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2208
2209 =cut
2210
2211 sub log_response {
2212     my $c = shift;
2213
2214     return unless $c->debug;
2215
2216     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2217     my $response = $dump->[1];
2218
2219     $c->log_response_status_line($response);
2220     $c->log_response_headers($response->headers);
2221 }
2222
2223 =head2 $c->log_response_status_line($response)
2224
2225 Writes one line of information about the response to the debug logs.  This includes:
2226
2227 =over 4
2228
2229 =item * Response status code
2230
2231 =item * Content-Type header (if present)
2232
2233 =item * Content-Length header (if present)
2234
2235 =back
2236
2237 =cut
2238
2239 sub log_response_status_line {
2240     my ($c, $response) = @_;
2241
2242     $c->log->debug(
2243         sprintf(
2244             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2245             $response->status                            || 'unknown',
2246             $response->headers->header('Content-Type')   || 'unknown',
2247             $response->headers->header('Content-Length') || 'unknown'
2248         )
2249     );
2250 }
2251
2252 =head2 $c->log_response_headers($headers);
2253
2254 Hook method which can be wrapped by plugins to log the response headers.
2255 No-op in the default implementation.
2256
2257 =cut
2258
2259 sub log_response_headers {}
2260
2261 =head2 $c->log_request_parameters( query => {}, body => {} )
2262
2263 Logs request parameters to debug logs
2264
2265 =cut
2266
2267 sub log_request_parameters {
2268     my $c          = shift;
2269     my %all_params = @_;
2270
2271     return unless $c->debug;
2272
2273     my $column_width = Catalyst::Utils::term_width() - 44;
2274     foreach my $type (qw(query body)) {
2275         my $params = $all_params{$type};
2276         next if ! keys %$params;
2277         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2278         for my $key ( sort keys %$params ) {
2279             my $param = $params->{$key};
2280             my $value = defined($param) ? $param : '';
2281             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2282         }
2283         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2284     }
2285 }
2286
2287 =head2 $c->log_request_uploads
2288
2289 Logs file uploads included in the request to the debug logs.
2290 The parameter name, filename, file type, and file size are all included in
2291 the debug logs.
2292
2293 =cut
2294
2295 sub log_request_uploads {
2296     my $c = shift;
2297     my $request = shift;
2298     return unless $c->debug;
2299     my $uploads = $request->uploads;
2300     if ( keys %$uploads ) {
2301         my $t = Text::SimpleTable->new(
2302             [ 12, 'Parameter' ],
2303             [ 26, 'Filename' ],
2304             [ 18, 'Type' ],
2305             [ 9,  'Size' ]
2306         );
2307         for my $key ( sort keys %$uploads ) {
2308             my $upload = $uploads->{$key};
2309             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2310                 $t->row( $key, $u->filename, $u->type, $u->size );
2311             }
2312         }
2313         $c->log->debug( "File Uploads are:\n" . $t->draw );
2314     }
2315 }
2316
2317 =head2 $c->log_request_headers($headers);
2318
2319 Hook method which can be wrapped by plugins to log the request headers.
2320 No-op in the default implementation.
2321
2322 =cut
2323
2324 sub log_request_headers {}
2325
2326 =head2 $c->log_headers($type => $headers)
2327
2328 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2329
2330 =cut
2331
2332 sub log_headers {
2333     my $c       = shift;
2334     my $type    = shift;
2335     my $headers = shift;    # an HTTP::Headers instance
2336
2337     return unless $c->debug;
2338
2339     my $column_width = Catalyst::Utils::term_width() - 28;
2340     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2341     $headers->scan(
2342         sub {
2343             my ( $name, $value ) = @_;
2344             $t->row( $name, $value );
2345         }
2346     );
2347     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2348 }
2349
2350
2351 =head2 $c->prepare_read
2352
2353 Prepares the input for reading.
2354
2355 =cut
2356
2357 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2358
2359 =head2 $c->prepare_request
2360
2361 Prepares the engine request.
2362
2363 =cut
2364
2365 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2366
2367 =head2 $c->prepare_uploads
2368
2369 Prepares uploads.
2370
2371 =cut
2372
2373 sub prepare_uploads {
2374     my $c = shift;
2375
2376     $c->engine->prepare_uploads( $c, @_ );
2377 }
2378
2379 =head2 $c->prepare_write
2380
2381 Prepares the output for writing.
2382
2383 =cut
2384
2385 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2386
2387 =head2 $c->request_class
2388
2389 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2390
2391 =head2 $c->response_class
2392
2393 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2394
2395 =head2 $c->read( [$maxlength] )
2396
2397 Reads a chunk of data from the request body. This method is designed to
2398 be used in a while loop, reading C<$maxlength> bytes on every call.
2399 C<$maxlength> defaults to the size of the request if not specified.
2400
2401 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2402 directly.
2403
2404 Warning: If you use read(), Catalyst will not process the body,
2405 so you will not be able to access POST parameters or file uploads via
2406 $c->request.  You must handle all body parsing yourself.
2407
2408 =cut
2409
2410 sub read { my $c = shift; return $c->request->read( @_ ) }
2411
2412 =head2 $c->run
2413
2414 Starts the engine.
2415
2416 =cut
2417
2418 sub run {
2419   my $app = shift;
2420   $app->engine_loader->needs_psgi_engine_compat_hack ?
2421     $app->engine->run($app, @_) :
2422       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2423 }
2424
2425 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2426
2427 Sets an action in a given namespace.
2428
2429 =cut
2430
2431 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2432
2433 =head2 $c->setup_actions($component)
2434
2435 Sets up actions for a component.
2436
2437 =cut
2438
2439 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2440
2441 =head2 $c->setup_components
2442
2443 This method is called internally to set up the application's components.
2444
2445 It finds modules by calling the L<locate_components> method, expands them to
2446 package names with the L<expand_component_module> method, and then installs
2447 each component into the application.
2448
2449 The C<setup_components> config option is passed to both of the above methods.
2450
2451 Installation of each component is performed by the L<setup_component> method,
2452 below.
2453
2454 =cut
2455
2456 sub setup_components {
2457     my $class = shift;
2458
2459     my $config  = $class->config->{ setup_components };
2460
2461     my @comps = $class->locate_components($config);
2462     my %comps = map { $_ => 1 } @comps;
2463
2464     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2465     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2466         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2467     ) if $deprecatedcatalyst_component_names;
2468
2469     for my $component ( @comps ) {
2470
2471         # We pass ignore_loaded here so that overlay files for (e.g.)
2472         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2473         # we know M::P::O found a file on disk so this is safe
2474
2475         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2476     }
2477
2478     for my $component (@comps) {
2479         my $instance = $class->components->{ $component } = $class->setup_component($component);
2480         my @expanded_components = $instance->can('expand_modules')
2481             ? $instance->expand_modules( $component, $config )
2482             : $class->expand_component_module( $component, $config );
2483         for my $component (@expanded_components) {
2484             next if $comps{$component};
2485             $class->components->{ $component } = $class->setup_component($component);
2486         }
2487     }
2488 }
2489
2490 =head2 $c->locate_components( $setup_component_config )
2491
2492 This method is meant to provide a list of component modules that should be
2493 setup for the application.  By default, it will use L<Module::Pluggable>.
2494
2495 Specify a C<setup_components> config option to pass additional options directly
2496 to L<Module::Pluggable>. To add additional search paths, specify a key named
2497 C<search_extra> as an array reference. Items in the array beginning with C<::>
2498 will have the application class name prepended to them.
2499
2500 =cut
2501
2502 sub locate_components {
2503     my $class  = shift;
2504     my $config = shift;
2505
2506     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2507     my $extra   = delete $config->{ search_extra } || [];
2508
2509     push @paths, @$extra;
2510
2511     my $locator = Module::Pluggable::Object->new(
2512         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2513         %$config
2514     );
2515
2516     # XXX think about ditching this sort entirely
2517     my @comps = sort { length $a <=> length $b } $locator->plugins;
2518
2519     return @comps;
2520 }
2521
2522 =head2 $c->expand_component_module( $component, $setup_component_config )
2523
2524 Components found by C<locate_components> will be passed to this method, which
2525 is expected to return a list of component (package) names to be set up.
2526
2527 =cut
2528
2529 sub expand_component_module {
2530     my ($class, $module) = @_;
2531     return Devel::InnerPackage::list_packages( $module );
2532 }
2533
2534 =head2 $c->setup_component
2535
2536 =cut
2537
2538 sub setup_component {
2539     my( $class, $component ) = @_;
2540
2541     unless ( $component->can( 'COMPONENT' ) ) {
2542         return $component;
2543     }
2544
2545     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2546     my $config = $class->config->{ $suffix } || {};
2547     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2548     # methods also pass it. local to avoid pointlessly shitting in config
2549     # for the debug screen, as $component is already the key name.
2550     local $config->{catalyst_component_name} = $component;
2551
2552     my $instance = eval { $component->COMPONENT( $class, $config ); };
2553
2554     if ( my $error = $@ ) {
2555         chomp $error;
2556         Catalyst::Exception->throw(
2557             message => qq/Couldn't instantiate component "$component", "$error"/
2558         );
2559     }
2560
2561     unless (blessed $instance) {
2562         my $metaclass = Moose::Util::find_meta($component);
2563         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2564         my $component_method_from = $method_meta->associated_metaclass->name;
2565         my $value = defined($instance) ? $instance : 'undef';
2566         Catalyst::Exception->throw(
2567             message =>
2568             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2569         );
2570     }
2571     return $instance;
2572 }
2573
2574 =head2 $c->setup_dispatcher
2575
2576 Sets up dispatcher.
2577
2578 =cut
2579
2580 sub setup_dispatcher {
2581     my ( $class, $dispatcher ) = @_;
2582
2583     if ($dispatcher) {
2584         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2585     }
2586
2587     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2588         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2589     }
2590
2591     unless ($dispatcher) {
2592         $dispatcher = $class->dispatcher_class;
2593     }
2594
2595     Class::MOP::load_class($dispatcher);
2596
2597     # dispatcher instance
2598     $class->dispatcher( $dispatcher->new );
2599 }
2600
2601 =head2 $c->setup_engine
2602
2603 Sets up engine.
2604
2605 =cut
2606
2607 sub engine_class {
2608     my ($class, $requested_engine) = @_;
2609
2610     if (!$class->engine_loader || $requested_engine) {
2611         $class->engine_loader(
2612             Catalyst::EngineLoader->new({
2613                 application_name => $class,
2614                 (defined $requested_engine
2615                      ? (catalyst_engine_class => $requested_engine) : ()),
2616             }),
2617         );
2618     }
2619
2620     $class->engine_loader->catalyst_engine_class;
2621 }
2622
2623 sub setup_engine {
2624     my ($class, $requested_engine) = @_;
2625
2626     my $engine = do {
2627         my $loader = $class->engine_loader;
2628
2629         if (!$loader || $requested_engine) {
2630             $loader = Catalyst::EngineLoader->new({
2631                 application_name => $class,
2632                 (defined $requested_engine
2633                      ? (requested_engine => $requested_engine) : ()),
2634             }),
2635
2636             $class->engine_loader($loader);
2637         }
2638
2639         $loader->catalyst_engine_class;
2640     };
2641
2642     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2643     return if $class->loading_psgi_file;
2644
2645     Class::MOP::load_class($engine);
2646
2647     if ($ENV{MOD_PERL}) {
2648         my $apache = $class->engine_loader->auto;
2649
2650         my $meta = find_meta($class);
2651         my $was_immutable = $meta->is_immutable;
2652         my %immutable_options = $meta->immutable_options;
2653         $meta->make_mutable if $was_immutable;
2654
2655         $meta->add_method(handler => sub {
2656             my $r = shift;
2657             my $psgi_app = $class->_finalized_psgi_app;
2658             $apache->call_app($r, $psgi_app);
2659         });
2660
2661         $meta->make_immutable(%immutable_options) if $was_immutable;
2662     }
2663
2664     $class->engine( $engine->new );
2665
2666     return;
2667 }
2668
2669 sub _finalized_psgi_app {
2670     my ($app) = @_;
2671
2672     unless ($app->_psgi_app) {
2673         my $psgi_app = $app->_setup_psgi_app;
2674         $app->_psgi_app($psgi_app);
2675     }
2676
2677     return $app->_psgi_app;
2678 }
2679
2680 sub _setup_psgi_app {
2681     my ($app) = @_;
2682
2683     for my $home (Path::Class::Dir->new($app->config->{home})) {
2684         my $psgi_file = $home->file(
2685             Catalyst::Utils::appprefix($app) . '.psgi',
2686         );
2687
2688         next unless -e $psgi_file;
2689
2690         # If $psgi_file calls ->setup_engine, it's doing so to load
2691         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2692         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2693         # anyway. So set a flag (ick) that tells setup_engine not to populate
2694         # $c->engine or do any other things we might regret.
2695
2696         $app->loading_psgi_file(1);
2697         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2698         $app->loading_psgi_file(0);
2699
2700         return $psgi_app
2701             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2702
2703         warn <<"EOW";
2704 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2705
2706 Its content has been ignored. Please consult the Catalyst::Upgrading
2707 documentation on how to upgrade from Catalyst::Engine::PSGI.
2708 EOW
2709     }
2710
2711     return $app->apply_default_middlewares($app->psgi_app);
2712 }
2713
2714 =head2 $c->apply_default_middlewares
2715
2716 Adds the following L<Plack> middlewares to your application, since they are
2717 useful and commonly needed:
2718
2719 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2720 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2721 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2722 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2723 applied since this middleware is smart enough to conditionally apply itself).
2724
2725 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2726 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2727 $ENV{SCRIPT_NAME}
2728
2729 =cut
2730
2731
2732 sub apply_default_middlewares {
2733     my ($app, $psgi_app) = @_;
2734
2735     $psgi_app = Plack::Middleware::Conditional->wrap(
2736         $psgi_app,
2737         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2738         condition => sub {
2739             my ($env) = @_;
2740             return if $app->config->{ignore_frontend_proxy};
2741             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2742                 || $app->config->{using_frontend_proxy};
2743         },
2744     );
2745
2746     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2747     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2748     $psgi_app = Plack::Middleware::LighttpdScriptNameFix->wrap($psgi_app);
2749
2750     # we're applying this unconditionally as the middleware itself already makes
2751     # sure it doesn't fuck things up if it's not running under one of the right
2752     # IIS versions
2753     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2754
2755     return $psgi_app;
2756 }
2757
2758 =head2 $c->psgi_app
2759
2760 Returns a PSGI application code reference for the catalyst application
2761 C<$c>. This is the bare application without any middlewares
2762 applied. C<${myapp}.psgi> is not taken into account.
2763
2764 This is what you want to be using to retrieve the PSGI application code
2765 reference of your Catalyst application for use in F<.psgi> files.
2766
2767 =cut
2768
2769 sub psgi_app {
2770     my ($app) = @_;
2771     return $app->engine->build_psgi_app($app);
2772 }
2773
2774 =head2 $c->setup_home
2775
2776 Sets up the home directory.
2777
2778 =cut
2779
2780 sub setup_home {
2781     my ( $class, $home ) = @_;
2782
2783     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2784         $home = $env;
2785     }
2786
2787     $home ||= Catalyst::Utils::home($class);
2788
2789     if ($home) {
2790         #I remember recently being scolded for assigning config values like this
2791         $class->config->{home} ||= $home;
2792         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2793     }
2794 }
2795
2796 =head2 $c->setup_log
2797
2798 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2799 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2800 log to.
2801
2802 This method also installs a C<debug> method that returns a true value into the
2803 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2804 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2805
2806 Note that if the log has already been setup, by either a previous call to
2807 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2808 that this method won't actually set up the log object.
2809
2810 =cut
2811
2812 sub setup_log {
2813     my ( $class, $levels ) = @_;
2814
2815     $levels ||= '';
2816     $levels =~ s/^\s+//;
2817     $levels =~ s/\s+$//;
2818     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2819
2820     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2821     if ( defined $env_debug ) {
2822         $levels{debug} = 1 if $env_debug; # Ugly!
2823         delete($levels{debug}) unless $env_debug;
2824     }
2825
2826     unless ( $class->log ) {
2827         $class->log( Catalyst::Log->new(keys %levels) );
2828     }
2829
2830     if ( $levels{debug} ) {
2831         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2832         $class->log->debug('Debug messages enabled');
2833     }
2834 }
2835
2836 =head2 $c->setup_plugins
2837
2838 Sets up plugins.
2839
2840 =cut
2841
2842 =head2 $c->setup_stats
2843
2844 Sets up timing statistics class.
2845
2846 =cut
2847
2848 sub setup_stats {
2849     my ( $class, $stats ) = @_;
2850
2851     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2852
2853     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2854     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2855         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2856         $class->log->debug('Statistics enabled');
2857     }
2858 }
2859
2860
2861 =head2 $c->registered_plugins
2862
2863 Returns a sorted list of the plugins which have either been stated in the
2864 import list.
2865
2866 If passed a given plugin name, it will report a boolean value indicating
2867 whether or not that plugin is loaded.  A fully qualified name is required if
2868 the plugin name does not begin with C<Catalyst::Plugin::>.
2869
2870  if ($c->registered_plugins('Some::Plugin')) {
2871      ...
2872  }
2873
2874 =cut
2875
2876 {
2877
2878     sub registered_plugins {
2879         my $proto = shift;
2880         return sort keys %{ $proto->_plugins } unless @_;
2881         my $plugin = shift;
2882         return 1 if exists $proto->_plugins->{$plugin};
2883         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2884     }
2885
2886     sub _register_plugin {
2887         my ( $proto, $plugin, $instant ) = @_;
2888         my $class = ref $proto || $proto;
2889
2890         Class::MOP::load_class( $plugin );
2891         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2892             if $plugin->isa( 'Catalyst::Component' );
2893         $proto->_plugins->{$plugin} = 1;
2894         unless ($instant) {
2895             my $meta = Class::MOP::get_metaclass_by_name($class);
2896             $meta->superclasses($plugin, $meta->superclasses);
2897         }
2898         return $class;
2899     }
2900
2901     sub setup_plugins {
2902         my ( $class, $plugins ) = @_;
2903
2904         $class->_plugins( {} ) unless $class->_plugins;
2905         $plugins = Data::OptList::mkopt($plugins || []);
2906
2907         my @plugins = map {
2908             [ Catalyst::Utils::resolve_namespace(
2909                   $class . '::Plugin',
2910                   'Catalyst::Plugin', $_->[0]
2911               ),
2912               $_->[1],
2913             ]
2914          } @{ $plugins };
2915
2916         for my $plugin ( reverse @plugins ) {
2917             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2918             my $meta = find_meta($plugin->[0]);
2919             next if $meta && $meta->isa('Moose::Meta::Role');
2920
2921             $class->_register_plugin($plugin->[0]);
2922         }
2923
2924         my @roles =
2925             map  { $_->[0]->name, $_->[1] }
2926             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2927             map  { [find_meta($_->[0]), $_->[1]] }
2928             @plugins;
2929
2930         Moose::Util::apply_all_roles(
2931             $class => @roles
2932         ) if @roles;
2933     }
2934 }
2935
2936 =head2 $c->stack
2937
2938 Returns an arrayref of the internal execution stack (actions that are
2939 currently executing).
2940
2941 =head2 $c->stats
2942
2943 Returns the current timing statistics object. By default Catalyst uses
2944 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2945 L<< stats_class|/"$c->stats_class" >>.
2946
2947 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2948 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2949 profile explicitly, although MyApp.pm still won't profile nor output anything
2950 by itself.
2951
2952 =head2 $c->stats_class
2953
2954 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2955
2956 =head2 $c->use_stats
2957
2958 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2959
2960 Note that this is a static method, not an accessor and should be overridden
2961 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2962
2963 =cut
2964
2965 sub use_stats { 0 }
2966
2967
2968 =head2 $c->write( $data )
2969
2970 Writes $data to the output stream. When using this method directly, you
2971 will need to manually set the C<Content-Length> header to the length of
2972 your output data, if known.
2973
2974 =cut
2975
2976 sub write {
2977     my $c = shift;
2978
2979     return $c->response->write( @_ );
2980 }
2981
2982 =head2 version
2983
2984 Returns the Catalyst version number. Mostly useful for "powered by"
2985 messages in template systems.
2986
2987 =cut
2988
2989 sub version { return $Catalyst::VERSION }
2990
2991 =head1 CONFIGURATION
2992
2993 There are a number of 'base' config variables which can be set:
2994
2995 =over
2996
2997 =item *
2998
2999 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3000
3001 =item *
3002
3003 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3004
3005 =item *
3006
3007 C<disable_component_resolution_regex_fallback> - Turns
3008 off the deprecated component resolution functionality so
3009 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3010 are called then regex search will not be attempted on string values and
3011 instead C<undef> will be returned.
3012
3013 =item *
3014
3015 C<home> - The application home directory. In an uninstalled application,
3016 this is the top level application directory. In an installed application,
3017 this will be the directory containing C<< MyApp.pm >>.
3018
3019 =item *
3020
3021 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3022
3023 =item *
3024
3025 C<name> - The name of the application in debug messages and the debug and
3026 welcome screens
3027
3028 =item *
3029
3030 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3031 until it is accessed. This allows you to (for example) check authentication (and reject
3032 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3033
3034 =item *
3035
3036 C<root> - The root directory for templates. Usually this is just a
3037 subdirectory of the home directory, but you can set it to change the
3038 templates to a different directory.
3039
3040 =item *
3041
3042 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3043 namespaces from which components will be loaded (and constructed and stored in
3044 C<< $c->components >>).
3045
3046 =item *
3047
3048 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3049 to be shown in hit debug tables in the test server.
3050
3051 =item *
3052
3053 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3054 variable should be used for determining the request path.
3055
3056 Most web server environments pass the requested path to the application using environment variables,
3057 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3058 exposed as C<< $c->request->base >>) and the request path below that base.
3059
3060 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3061 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3062
3063 =over
3064
3065 =item use_request_uri_for_path => 0
3066
3067 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3068 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3069 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3070 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3071
3072 However this method has the major disadvantage that it is impossible to correctly decode some elements
3073 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3074 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3075 can't distinguish / vs %2F in paths (in addition to other encoded values).
3076
3077 =item use_request_uri_for_path => 1
3078
3079 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3080 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3081 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3082
3083 Given that this method of path resolution is provably more correct, it is recommended that you use
3084 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3085 aware of the implications of not being able to handle encoded URI paths correctly.
3086
3087 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3088 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3089 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3090 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3091 C<< $c->request->base >> will be incorrect.
3092
3093 =back
3094
3095 =item *
3096
3097 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3098
3099 =back
3100
3101 =head1 INTERNAL ACTIONS
3102
3103 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3104 C<_ACTION>, and C<_END>. These are by default not shown in the private
3105 action table, but you can make them visible with a config parameter.
3106
3107     MyApp->config(show_internal_actions => 1);
3108
3109 =head1 ON-DEMAND PARSER
3110
3111 The request body is usually parsed at the beginning of a request,
3112 but if you want to handle input yourself, you can enable on-demand
3113 parsing with a config parameter.
3114
3115     MyApp->config(parse_on_demand => 1);
3116
3117 =head1 PROXY SUPPORT
3118
3119 Many production servers operate using the common double-server approach,
3120 with a lightweight frontend web server passing requests to a larger
3121 backend server. An application running on the backend server must deal
3122 with two problems: the remote user always appears to be C<127.0.0.1> and
3123 the server's hostname will appear to be C<localhost> regardless of the
3124 virtual host that the user connected through.
3125
3126 Catalyst will automatically detect this situation when you are running
3127 the frontend and backend servers on the same machine. The following
3128 changes are made to the request.
3129
3130     $c->req->address is set to the user's real IP address, as read from
3131     the HTTP X-Forwarded-For header.
3132
3133     The host value for $c->req->base and $c->req->uri is set to the real
3134     host, as read from the HTTP X-Forwarded-Host header.
3135
3136 Additionally, you may be running your backend application on an insecure
3137 connection (port 80) while your frontend proxy is running under SSL.  If there
3138 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3139 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3140 be created properly.
3141
3142 In the case of passing in:
3143
3144     X-Forwarded-Port: 443
3145
3146 All calls to C<uri_for> will result in an https link, as is expected.
3147
3148 Obviously, your web server must support these headers for this to work.
3149
3150 In a more complex server farm environment where you may have your
3151 frontend proxy server(s) on different machines, you will need to set a
3152 configuration option to tell Catalyst to read the proxied data from the
3153 headers.
3154
3155     MyApp->config(using_frontend_proxy => 1);
3156
3157 If you do not wish to use the proxy support at all, you may set:
3158
3159     MyApp->config(ignore_frontend_proxy => 0);
3160
3161 =head2 Note about psgi files
3162
3163 Note that if you supply your own .psgi file, calling
3164 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3165
3166 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3167 in your psgi, for example:
3168
3169     builder {
3170         enable "Plack::Middleware::ReverseProxy";
3171         MyApp->psgi_app
3172     };
3173
3174 This will unconditionally add the ReverseProxy support, or you need to call
3175 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3176 apply the support depending upon your config).
3177
3178 See L<Catalyst::PSGI> for more information.
3179
3180 =head1 THREAD SAFETY
3181
3182 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3183 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3184 believe the Catalyst core to be thread-safe.
3185
3186 If you plan to operate in a threaded environment, remember that all other
3187 modules you are using must also be thread-safe. Some modules, most notably
3188 L<DBD::SQLite>, are not thread-safe.
3189
3190 =head1 SUPPORT
3191
3192 IRC:
3193
3194     Join #catalyst on irc.perl.org.
3195
3196 Mailing Lists:
3197
3198     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3199     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3200
3201 Web:
3202
3203     http://catalyst.perl.org
3204
3205 Wiki:
3206
3207     http://dev.catalyst.perl.org
3208
3209 =head1 SEE ALSO
3210
3211 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3212
3213 =head2 L<Catalyst::Manual> - The Catalyst Manual
3214
3215 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3216
3217 =head2 L<Catalyst::Engine> - Core engine
3218
3219 =head2 L<Catalyst::Log> - Log class.
3220
3221 =head2 L<Catalyst::Request> - Request object
3222
3223 =head2 L<Catalyst::Response> - Response object
3224
3225 =head2 L<Catalyst::Test> - The test suite.
3226
3227 =begin stopwords
3228
3229 =head1 PROJECT FOUNDER
3230
3231 sri: Sebastian Riedel <sri@cpan.org>
3232
3233 =head1 CONTRIBUTORS
3234
3235 abw: Andy Wardley
3236
3237 acme: Leon Brocard <leon@astray.com>
3238
3239 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3240
3241 Andrew Bramble
3242
3243 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3244
3245 Andrew Ruthven
3246
3247 andyg: Andy Grundman <andy@hybridized.org>
3248
3249 audreyt: Audrey Tang
3250
3251 bricas: Brian Cassidy <bricas@cpan.org>
3252
3253 Caelum: Rafael Kitover <rkitover@io.com>
3254
3255 chansen: Christian Hansen
3256
3257 chicks: Christopher Hicks
3258
3259 Chisel Wright C<pause@herlpacker.co.uk>
3260
3261 Danijel Milicevic C<me@danijel.de>
3262
3263 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3264
3265 David Naughton, C<naughton@umn.edu>
3266
3267 David E. Wheeler
3268
3269 dhoss: Devin Austin <dhoss@cpan.org>
3270
3271 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3272
3273 Drew Taylor
3274
3275 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3276
3277 esskar: Sascha Kiefer
3278
3279 fireartist: Carl Franks <cfranks@cpan.org>
3280
3281 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3282
3283 gabb: Danijel Milicevic
3284
3285 Gary Ashton Jones
3286
3287 Gavin Henry C<ghenry@perl.me.uk>
3288
3289 Geoff Richards
3290
3291 groditi: Guillermo Roditi <groditi@gmail.com>
3292
3293 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3294
3295 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3296
3297 jcamacho: Juan Camacho
3298
3299 jester: Jesse Sheidlower C<jester@panix.com>
3300
3301 jhannah: Jay Hannah <jay@jays.net>
3302
3303 Jody Belka
3304
3305 Johan Lindstrom
3306
3307 jon: Jon Schutz <jjschutz@cpan.org>
3308
3309 Jonathan Rockway C<< <jrockway@cpan.org> >>
3310
3311 Kieren Diment C<kd@totaldatasolution.com>
3312
3313 konobi: Scott McWhirter <konobi@cpan.org>
3314
3315 marcus: Marcus Ramberg <mramberg@cpan.org>
3316
3317 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3318
3319 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3320
3321 mugwump: Sam Vilain
3322
3323 naughton: David Naughton
3324
3325 ningu: David Kamholz <dkamholz@cpan.org>
3326
3327 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3328
3329 numa: Dan Sully <daniel@cpan.org>
3330
3331 obra: Jesse Vincent
3332
3333 Octavian Rasnita
3334
3335 omega: Andreas Marienborg
3336
3337 Oleg Kostyuk <cub.uanic@gmail.com>
3338
3339 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3340
3341 rafl: Florian Ragwitz <rafl@debian.org>
3342
3343 random: Roland Lammel <lammel@cpan.org>
3344
3345 Robert Sedlacek C<< <rs@474.at> >>
3346
3347 SpiceMan: Marcel Montes
3348
3349 sky: Arthur Bergman
3350
3351 szbalint: Balint Szilakszi <szbalint@cpan.org>
3352
3353 t0m: Tomas Doran <bobtfish@bobtfish.net>
3354
3355 Ulf Edvinsson
3356
3357 Viljo Marrandi C<vilts@yahoo.com>
3358
3359 Will Hawes C<info@whawes.co.uk>
3360
3361 willert: Sebastian Willert <willert@cpan.org>
3362
3363 wreis: Wallace Reis <wallace@reis.org.br>
3364
3365 Yuval Kogman, C<nothingmuch@woobling.org>
3366
3367 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3368
3369 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3370
3371 =end stopwords
3372
3373 =head1 COPYRIGHT
3374
3375 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3376
3377 =head1 LICENSE
3378
3379 This library is free software. You can redistribute it and/or modify it under
3380 the same terms as Perl itself.
3381
3382 =cut
3383
3384 no Moose;
3385
3386 __PACKAGE__->meta->make_immutable;
3387
3388 1;