lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Plack::Middleware::Conditional;
  39 use Plack::Middleware::ReverseProxy;
  40 use Plack::Middleware::IIS6ScriptNameFix;
  41 use Plack::Middleware::IIS7KeepAliveFix;
  42 use Plack::Middleware::LighttpdScriptNameFix;
  43
  44 BEGIN { require 5.008003; }
  45
  46 has stack => (is => 'ro', default => sub { [] });
  47 has stash => (is => 'rw', default => sub { {} });
  48 has state => (is => 'rw', default => 0);
  49 has stats => (is => 'rw');
  50 has action => (is => 'rw');
  51 has counter => (is => 'rw', default => sub { {} });
  52 has request => (
  53     is => 'rw',
  54     default => sub {
  55         my $self = shift;
  56         $self->request_class->new($self->_build_request_constructor_args);
  57     },
  58     lazy => 1,
  59 );
  60 sub _build_request_constructor_args {
  61     my $self = shift;
  62     my %p = ( _log => $self->log );
  63     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  64     \%p;
  65 }
  66
  67 has response => (
  68     is => 'rw',
  69     default => sub {
  70         my $self = shift;
  71         $self->response_class->new($self->_build_response_constructor_args);
  72     },
  73     lazy => 1,
  74 );
  75 sub _build_response_constructor_args {
  76     my $self = shift;
  77     { _log => $self->log };
  78 }
  79
  80 has namespace => (is => 'rw');
  81
  82 sub depth { scalar @{ shift->stack || [] }; }
  83 sub comp { shift->component(@_) }
  84
  85 sub req {
  86     my $self = shift; return $self->request(@_);
  87 }
  88 sub res {
  89     my $self = shift; return $self->response(@_);
  90 }
  91
  92 # For backwards compatibility
  93 sub finalize_output { shift->finalize_body(@_) };
  94
  95 # For statistics
  96 our $COUNT     = 1;
  97 our $START     = time;
  98 our $RECURSION = 1000;
  99 our $DETACH    = Catalyst::Exception::Detach->new;
 100 our $GO        = Catalyst::Exception::Go->new;
 101
 102 #I imagine that very few of these really need to be class variables. if any.
 103 #maybe we should just make them attributes with a default?
 104 __PACKAGE__->mk_classdata($_)
 105   for qw/components arguments dispatcher engine log dispatcher_class
 106   engine_loader context_class request_class response_class stats_class
 107   setup_finished _psgi_app loading_psgi_file run_options/;
 108
 109 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 110 __PACKAGE__->request_class('Catalyst::Request');
 111 __PACKAGE__->response_class('Catalyst::Response');
 112 __PACKAGE__->stats_class('Catalyst::Stats');
 113
 114 # Remember to update this in Catalyst::Runtime as well!
 115
 116 our $VERSION = '5.90019';
 117
 118 sub import {
 119     my ( $class, @arguments ) = @_;
 120
 121     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 122     # callers @ISA.
 123     return unless $class eq 'Catalyst';
 124
 125     my $caller = caller();
 126     return if $caller eq 'main';
 127
 128     my $meta = Moose::Meta::Class->initialize($caller);
 129     unless ( $caller->isa('Catalyst') ) {
 130         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 131         $meta->superclasses(@superclasses);
 132     }
 133     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 134     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 135
 136     unless( $meta->has_method('meta') ){
 137         if ($Moose::VERSION >= 1.15) {
 138             $meta->_add_meta_method('meta');
 139         }
 140         else {
 141             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 142         }
 143     }
 144
 145     $caller->arguments( [@arguments] );
 146     $caller->setup_home;
 147 }
 148
 149 sub _application { $_[0] }
 150
 151 =encoding UTF-8
 152
 153 =head1 NAME
 154
 155 Catalyst - The Elegant MVC Web Application Framework
 156
 157 =head1 SYNOPSIS
 158
 159 See the L<Catalyst::Manual> distribution for comprehensive
 160 documentation and tutorials.
 161
 162     # Install Catalyst::Devel for helpers and other development tools
 163     # use the helper to create a new application
 164     catalyst.pl MyApp
 165
 166     # add models, views, controllers
 167     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 168     script/myapp_create.pl view MyTemplate TT
 169     script/myapp_create.pl controller Search
 170
 171     # built in testserver -- use -r to restart automatically on changes
 172     # --help to see all available options
 173     script/myapp_server.pl
 174
 175     # command line testing interface
 176     script/myapp_test.pl /yada
 177
 178     ### in lib/MyApp.pm
 179     use Catalyst qw/-Debug/; # include plugins here as well
 180
 181     ### In lib/MyApp/Controller/Root.pm (autocreated)
 182     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 183         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 184         $c->stash->{template} = 'foo.tt'; # set the template
 185         # lookup something from db -- stash vars are passed to TT
 186         $c->stash->{data} =
 187           $c->model('Database::Foo')->search( { country => $args[0] } );
 188         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 189             $c->forward( 'bar' ); # process another action
 190             # do something else after forward returns
 191         }
 192     }
 193
 194     # The foo.tt TT template can use the stash data from the database
 195     [% WHILE (item = data.next) %]
 196         [% item.foo %]
 197     [% END %]
 198
 199     # called for /bar/of/soap, /bar/of/soap/10, etc.
 200     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 201
 202     # called after all actions are finished
 203     sub end : Action {
 204         my ( $self, $c ) = @_;
 205         if ( scalar @{ $c->error } ) { ... } # handle errors
 206         return if $c->res->body; # already have a response
 207         $c->forward( 'MyApp::View::TT' ); # render template
 208     }
 209
 210 See L<Catalyst::Manual::Intro> for additional information.
 211
 212 =head1 DESCRIPTION
 213
 214 Catalyst is a modern framework for making web applications without the
 215 pain usually associated with this process. This document is a reference
 216 to the main Catalyst application. If you are a new user, we suggest you
 217 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 218
 219 See L<Catalyst::Manual> for more documentation.
 220
 221 Catalyst plugins can be loaded by naming them as arguments to the "use
 222 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 223 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 224 C<My::Module>.
 225
 226     use Catalyst qw/My::Module/;
 227
 228 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 229 fully qualify the name by using a unary plus:
 230
 231     use Catalyst qw/
 232         My::Module
 233         +Fully::Qualified::Plugin::Name
 234     /;
 235
 236 Special flags like C<-Debug> can also be specified as
 237 arguments when Catalyst is loaded:
 238
 239     use Catalyst qw/-Debug My::Module/;
 240
 241 The position of plugins and flags in the chain is important, because
 242 they are loaded in the order in which they appear.
 243
 244 The following flags are supported:
 245
 246 =head2 -Debug
 247
 248 Enables debug output. You can also force this setting from the system
 249 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 250 settings override the application, with <MYAPP>_DEBUG having the highest
 251 priority.
 252
 253 This sets the log level to 'debug' and enables full debug output on the
 254 error screen. If you only want the latter, see L<< $c->debug >>.
 255
 256 =head2 -Home
 257
 258 Forces Catalyst to use a specific home directory, e.g.:
 259
 260     use Catalyst qw[-Home=/usr/mst];
 261
 262 This can also be done in the shell environment by setting either the
 263 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 264 is replaced with the uppercased name of your application, any "::" in
 265 the name will be replaced with underscores, e.g. MyApp::Web should use
 266 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 267
 268 If none of these are set, Catalyst will attempt to automatically detect the
 269 home directory. If you are working in a development environment, Catalyst
 270 will try and find the directory containing either Makefile.PL, Build.PL or
 271 dist.ini. If the application has been installed into the system (i.e.
 272 you have done C<make install>), then Catalyst will use the path to your
 273 application module, without the .pm extension (e.g., /foo/MyApp if your
 274 application was installed at /foo/MyApp.pm)
 275
 276 =head2 -Log
 277
 278     use Catalyst '-Log=warn,fatal,error';
 279
 280 Specifies a comma-delimited list of log levels.
 281
 282 =head2 -Stats
 283
 284 Enables statistics collection and reporting.
 285
 286    use Catalyst qw/-Stats=1/;
 287
 288 You can also force this setting from the system environment with CATALYST_STATS
 289 or <MYAPP>_STATS. The environment settings override the application, with
 290 <MYAPP>_STATS having the highest priority.
 291
 292 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 293
 294 =head1 METHODS
 295
 296 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 297
 298 =head2 $c->action
 299
 300 Returns a L<Catalyst::Action> object for the current action, which
 301 stringifies to the action name. See L<Catalyst::Action>.
 302
 303 =head2 $c->namespace
 304
 305 Returns the namespace of the current action, i.e., the URI prefix
 306 corresponding to the controller of the current action. For example:
 307
 308     # in Controller::Foo::Bar
 309     $c->namespace; # returns 'foo/bar';
 310
 311 =head2 $c->request
 312
 313 =head2 $c->req
 314
 315 Returns the current L<Catalyst::Request> object, giving access to
 316 information about the current client request (including parameters,
 317 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 318
 319 =head2 REQUEST FLOW HANDLING
 320
 321 =head2 $c->forward( $action [, \@arguments ] )
 322
 323 =head2 $c->forward( $class, $method, [, \@arguments ] )
 324
 325 Forwards processing to another action, by its private name. If you give a
 326 class name but no method, C<process()> is called. You may also optionally
 327 pass arguments in an arrayref. The action will receive the arguments in
 328 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 329 C<< $c->req->args >> will be restored to the previous values.
 330
 331 Any data C<return>ed from the action forwarded to, will be returned by the
 332 call to forward.
 333
 334     my $foodata = $c->forward('/foo');
 335     $c->forward('index');
 336     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 337     $c->forward('View::TT');
 338
 339 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 340 an C<< eval { } >> around the call (actually
 341 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 342 exceptions thrown by the called action non-fatal and pushing them onto
 343 $c->error instead. If you want C<die> to propagate you need to do something
 344 like:
 345
 346     $c->forward('foo');
 347     die join "\n", @{ $c->error } if @{ $c->error };
 348
 349 Or make sure to always return true values from your actions and write
 350 your code like this:
 351
 352     $c->forward('foo') || return;
 353
 354 Another note is that C<< $c->forward >> always returns a scalar because it
 355 actually returns $c->state which operates in a scalar context.
 356 Thus, something like:
 357
 358     return @array;
 359
 360 in an action that is forwarded to is going to return a scalar,
 361 i.e. how many items are in that array, which is probably not what you want.
 362 If you need to return an array then return a reference to it,
 363 or stash it like so:
 364
 365     $c->stash->{array} = \@array;
 366
 367 and access it from the stash.
 368
 369 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 370
 371 =cut
 372
 373 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 374
 375 =head2 $c->detach( $action [, \@arguments ] )
 376
 377 =head2 $c->detach( $class, $method, [, \@arguments ] )
 378
 379 =head2 $c->detach()
 380
 381 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 382 doesn't return to the previous action when processing is finished.
 383
 384 When called with no arguments it escapes the processing chain entirely.
 385
 386 =cut
 387
 388 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 389
 390 =head2 $c->visit( $action [, \@arguments ] )
 391
 392 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 393
 394 =head2 $c->visit( $class, $method, [, \@arguments ] )
 395
 396 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 397
 398 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 399 but does a full dispatch, instead of just calling the new C<$action> /
 400 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 401 you go to are called, just like a new request.
 402
 403 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 404 This means, for example, that C<< $c->action >> methods such as
 405 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 406 L<reverse|Catalyst::Action/reverse> return information for the visited action
 407 when they are invoked within the visited action.  This is different from the
 408 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 409 continues to use the $c->action object from the caller action even when
 410 invoked from the called action.
 411
 412 C<< $c->stash >> is kept unchanged.
 413
 414 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 415 allows you to "wrap" another action, just as it would have been called by
 416 dispatching from a URL, while the analogous
 417 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 418 transfer control to another action as if it had been reached directly from a URL.
 419
 420 =cut
 421
 422 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 423
 424 =head2 $c->go( $action [, \@arguments ] )
 425
 426 =head2 $c->go( $action [, \@captures, \@arguments ] )
 427
 428 =head2 $c->go( $class, $method, [, \@arguments ] )
 429
 430 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 431
 432 The relationship between C<go> and
 433 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 434 the relationship between
 435 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 436 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 437 C<< $c->go >> will perform a full dispatch on the specified action or method,
 438 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 439 C<go> escapes the processing of the current request chain on completion, and
 440 does not return to its caller.
 441
 442 @arguments are arguments to the final destination of $action. @captures are
 443 arguments to the intermediate steps, if any, on the way to the final sub of
 444 $action.
 445
 446 =cut
 447
 448 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 449
 450 =head2 $c->response
 451
 452 =head2 $c->res
 453
 454 Returns the current L<Catalyst::Response> object, see there for details.
 455
 456 =head2 $c->stash
 457
 458 Returns a hashref to the stash, which may be used to store data and pass
 459 it between components during a request. You can also set hash keys by
 460 passing arguments. The stash is automatically sent to the view. The
 461 stash is cleared at the end of a request; it cannot be used for
 462 persistent storage (for this you must use a session; see
 463 L<Catalyst::Plugin::Session> for a complete system integrated with
 464 Catalyst).
 465
 466     $c->stash->{foo} = $bar;
 467     $c->stash( { moose => 'majestic', qux => 0 } );
 468     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 469
 470     # stash is automatically passed to the view for use in a template
 471     $c->forward( 'MyApp::View::TT' );
 472
 473 =cut
 474
 475 around stash => sub {
 476     my $orig = shift;
 477     my $c = shift;
 478     my $stash = $orig->($c);
 479     if (@_) {
 480         my $new_stash = @_ > 1 ? {@_} : $_[0];
 481         croak('stash takes a hash or hashref') unless ref $new_stash;
 482         foreach my $key ( keys %$new_stash ) {
 483           $stash->{$key} = $new_stash->{$key};
 484         }
 485     }
 486
 487     return $stash;
 488 };
 489
 490
 491 =head2 $c->error
 492
 493 =head2 $c->error($error, ...)
 494
 495 =head2 $c->error($arrayref)
 496
 497 Returns an arrayref containing error messages.  If Catalyst encounters an
 498 error while processing a request, it stores the error in $c->error.  This
 499 method should only be used to store fatal error messages.
 500
 501     my @error = @{ $c->error };
 502
 503 Add a new error.
 504
 505     $c->error('Something bad happened');
 506
 507 =cut
 508
 509 sub error {
 510     my $c = shift;
 511     if ( $_[0] ) {
 512         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 513         croak @$error unless ref $c;
 514         push @{ $c->{error} }, @$error;
 515     }
 516     elsif ( defined $_[0] ) { $c->{error} = undef }
 517     return $c->{error} || [];
 518 }
 519
 520
 521 =head2 $c->state
 522
 523 Contains the return value of the last executed action.
 524 Note that << $c->state >> operates in a scalar context which means that all
 525 values it returns are scalar.
 526
 527 =head2 $c->clear_errors
 528
 529 Clear errors.  You probably don't want to clear the errors unless you are
 530 implementing a custom error screen.
 531
 532 This is equivalent to running
 533
 534     $c->error(0);
 535
 536 =cut
 537
 538 sub clear_errors {
 539     my $c = shift;
 540     $c->error(0);
 541 }
 542
 543 sub _comp_search_prefixes {
 544     my $c = shift;
 545     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 546 }
 547
 548 # search components given a name and some prefixes
 549 sub _comp_names_search_prefixes {
 550     my ( $c, $name, @prefixes ) = @_;
 551     my $appclass = ref $c || $c;
 552     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 553     $filter = qr/$filter/; # Compile regex now rather than once per loop
 554
 555     # map the original component name to the sub part that we will search against
 556     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 557         grep { /$filter/ } keys %{ $c->components };
 558
 559     # undef for a name will return all
 560     return keys %eligible if !defined $name;
 561
 562     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 563     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 564
 565     return @result if @result;
 566
 567     # if we were given a regexp to search against, we're done.
 568     return if $name->$_isa('Regexp');
 569
 570     # skip regexp fallback if configured
 571     return
 572         if $appclass->config->{disable_component_resolution_regex_fallback};
 573
 574     # regexp fallback
 575     $query  = qr/$name/i;
 576     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 577
 578     # no results? try against full names
 579     if( !@result ) {
 580         @result = grep { m{$query} } keys %eligible;
 581     }
 582
 583     # don't warn if we didn't find any results, it just might not exist
 584     if( @result ) {
 585         # Disgusting hack to work out correct method name
 586         my $warn_for = lc $prefixes[0];
 587         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 588            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 589            "component resolution is unreliable and unsafe.";
 590         my $short = $result[0];
 591         # remove the component namespace prefix
 592         $short =~ s/.*?(Model|Controller|View):://;
 593         my $shortmess = Carp::shortmess('');
 594         if ($shortmess =~ m#Catalyst/Plugin#) {
 595            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 596               "plugin's config";
 597         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 598            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 599               "component's config";
 600         } else {
 601            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 602               "but if you really wanted to search, pass in a regexp as the argument " .
 603               "like so: \$c->${warn_for}(qr/${name}/)";
 604         }
 605         $c->log->warn( "${msg}$shortmess" );
 606     }
 607
 608     return @result;
 609 }
 610
 611 # Find possible names for a prefix
 612 sub _comp_names {
 613     my ( $c, @prefixes ) = @_;
 614     my $appclass = ref $c || $c;
 615
 616     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 617
 618     my @names = map { s{$filter}{}; $_; }
 619         $c->_comp_names_search_prefixes( undef, @prefixes );
 620
 621     return @names;
 622 }
 623
 624 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 625 sub _filter_component {
 626     my ( $c, $comp, @args ) = @_;
 627
 628     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 629         return $comp->ACCEPT_CONTEXT( $c, @args );
 630     }
 631
 632     return $comp;
 633 }
 634
 635 =head2 COMPONENT ACCESSORS
 636
 637 =head2 $c->controller($name)
 638
 639 Gets a L<Catalyst::Controller> instance by name.
 640
 641     $c->controller('Foo')->do_stuff;
 642
 643 If the name is omitted, will return the controller for the dispatched
 644 action.
 645
 646 If you want to search for controllers, pass in a regexp as the argument.
 647
 648     # find all controllers that start with Foo
 649     my @foo_controllers = $c->controller(qr{^Foo});
 650
 651
 652 =cut
 653
 654 sub controller {
 655     my ( $c, $name, @args ) = @_;
 656
 657     my $appclass = ref($c) || $c;
 658     if( $name ) {
 659         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 660             my $comps = $c->components;
 661             my $check = $appclass."::Controller::".$name;
 662             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 663         }
 664         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 665         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 666         return $c->_filter_component( $result[ 0 ], @args );
 667     }
 668
 669     return $c->component( $c->action->class );
 670 }
 671
 672 =head2 $c->model($name)
 673
 674 Gets a L<Catalyst::Model> instance by name.
 675
 676     $c->model('Foo')->do_stuff;
 677
 678 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 679
 680 If the name is omitted, it will look for
 681  - a model object in $c->stash->{current_model_instance}, then
 682  - a model name in $c->stash->{current_model}, then
 683  - a config setting 'default_model', or
 684  - check if there is only one model, and return it if that's the case.
 685
 686 If you want to search for models, pass in a regexp as the argument.
 687
 688     # find all models that start with Foo
 689     my @foo_models = $c->model(qr{^Foo});
 690
 691 =cut
 692
 693 sub model {
 694     my ( $c, $name, @args ) = @_;
 695     my $appclass = ref($c) || $c;
 696     if( $name ) {
 697         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 698             my $comps = $c->components;
 699             my $check = $appclass."::Model::".$name;
 700             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 701         }
 702         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 703         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 704         return $c->_filter_component( $result[ 0 ], @args );
 705     }
 706
 707     if (ref $c) {
 708         return $c->stash->{current_model_instance}
 709           if $c->stash->{current_model_instance};
 710         return $c->model( $c->stash->{current_model} )
 711           if $c->stash->{current_model};
 712     }
 713     return $c->model( $appclass->config->{default_model} )
 714       if $appclass->config->{default_model};
 715
 716     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 717
 718     if( $rest ) {
 719         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 720         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 721         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 722         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 723         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 724     }
 725
 726     return $c->_filter_component( $comp );
 727 }
 728
 729
 730 =head2 $c->view($name)
 731
 732 Gets a L<Catalyst::View> instance by name.
 733
 734     $c->view('Foo')->do_stuff;
 735
 736 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 737
 738 If the name is omitted, it will look for
 739  - a view object in $c->stash->{current_view_instance}, then
 740  - a view name in $c->stash->{current_view}, then
 741  - a config setting 'default_view', or
 742  - check if there is only one view, and return it if that's the case.
 743
 744 If you want to search for views, pass in a regexp as the argument.
 745
 746     # find all views that start with Foo
 747     my @foo_views = $c->view(qr{^Foo});
 748
 749 =cut
 750
 751 sub view {
 752     my ( $c, $name, @args ) = @_;
 753
 754     my $appclass = ref($c) || $c;
 755     if( $name ) {
 756         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 757             my $comps = $c->components;
 758             my $check = $appclass."::View::".$name;
 759             if( exists $comps->{$check} ) {
 760                 return $c->_filter_component( $comps->{$check}, @args );
 761             }
 762             else {
 763                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 764             }
 765         }
 766         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 767         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 768         return $c->_filter_component( $result[ 0 ], @args );
 769     }
 770
 771     if (ref $c) {
 772         return $c->stash->{current_view_instance}
 773           if $c->stash->{current_view_instance};
 774         return $c->view( $c->stash->{current_view} )
 775           if $c->stash->{current_view};
 776     }
 777     return $c->view( $appclass->config->{default_view} )
 778       if $appclass->config->{default_view};
 779
 780     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 781
 782     if( $rest ) {
 783         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 784         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 785         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 786         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 787         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 788     }
 789
 790     return $c->_filter_component( $comp );
 791 }
 792
 793 =head2 $c->controllers
 794
 795 Returns the available names which can be passed to $c->controller
 796
 797 =cut
 798
 799 sub controllers {
 800     my ( $c ) = @_;
 801     return $c->_comp_names(qw/Controller C/);
 802 }
 803
 804 =head2 $c->models
 805
 806 Returns the available names which can be passed to $c->model
 807
 808 =cut
 809
 810 sub models {
 811     my ( $c ) = @_;
 812     return $c->_comp_names(qw/Model M/);
 813 }
 814
 815
 816 =head2 $c->views
 817
 818 Returns the available names which can be passed to $c->view
 819
 820 =cut
 821
 822 sub views {
 823     my ( $c ) = @_;
 824     return $c->_comp_names(qw/View V/);
 825 }
 826
 827 =head2 $c->comp($name)
 828
 829 =head2 $c->component($name)
 830
 831 Gets a component object by name. This method is not recommended,
 832 unless you want to get a specific component by full
 833 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 834 should be used instead.
 835
 836 If C<$name> is a regexp, a list of components matched against the full
 837 component name will be returned.
 838
 839 If Catalyst can't find a component by name, it will fallback to regex
 840 matching by default. To disable this behaviour set
 841 disable_component_resolution_regex_fallback to a true value.
 842
 843     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 844
 845 =cut
 846
 847 sub component {
 848     my ( $c, $name, @args ) = @_;
 849
 850     if( $name ) {
 851         my $comps = $c->components;
 852
 853         if( !ref $name ) {
 854             # is it the exact name?
 855             return $c->_filter_component( $comps->{ $name }, @args )
 856                        if exists $comps->{ $name };
 857
 858             # perhaps we just omitted "MyApp"?
 859             my $composed = ( ref $c || $c ) . "::${name}";
 860             return $c->_filter_component( $comps->{ $composed }, @args )
 861                        if exists $comps->{ $composed };
 862
 863             # search all of the models, views and controllers
 864             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 865             return $c->_filter_component( $comp, @args ) if $comp;
 866         }
 867
 868         return
 869             if $c->config->{disable_component_resolution_regex_fallback};
 870
 871         # This is here so $c->comp( '::M::' ) works
 872         my $query = ref $name ? $name : qr{$name}i;
 873
 874         my @result = grep { m{$query} } keys %{ $c->components };
 875         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 876
 877         if( $result[ 0 ] ) {
 878             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 879             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 880             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 881             return $c->_filter_component( $result[ 0 ], @args );
 882         }
 883
 884         # I would expect to return an empty list here, but that breaks back-compat
 885     }
 886
 887     # fallback
 888     return sort keys %{ $c->components };
 889 }
 890
 891 =head2 CLASS DATA AND HELPER CLASSES
 892
 893 =head2 $c->config
 894
 895 Returns or takes a hashref containing the application's configuration.
 896
 897     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 898
 899 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 900 like C<myapp.conf> in your applications home directory. See
 901 L<Catalyst::Plugin::ConfigLoader>.
 902
 903 =head3 Cascading configuration
 904
 905 The config method is present on all Catalyst components, and configuration
 906 will be merged when an application is started. Configuration loaded with
 907 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 908 followed by configuration in your top level C<MyApp> class. These two
 909 configurations are merged, and then configuration data whose hash key matches a
 910 component name is merged with configuration for that component.
 911
 912 The configuration for a component is then passed to the C<new> method when a
 913 component is constructed.
 914
 915 For example:
 916
 917     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 918     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 919
 920 will mean that C<MyApp::Model::Foo> receives the following data when
 921 constructed:
 922
 923     MyApp::Model::Foo->new({
 924         bar => 'baz',
 925         quux => 'frob',
 926         overrides => 'me',
 927     });
 928
 929 It's common practice to use a Moose attribute
 930 on the receiving component to access the config value.
 931
 932     package MyApp::Model::Foo;
 933
 934     use Moose;
 935
 936     # this attr will receive 'baz' at construction time
 937     has 'bar' => (
 938         is  => 'rw',
 939         isa => 'Str',
 940     );
 941
 942 You can then get the value 'baz' by calling $c->model('Foo')->bar
 943 (or $self->bar inside code in the model).
 944
 945 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 946 as a way of reading config within your code, as this B<will not> give you the
 947 correctly merged config back. You B<MUST> take the config values supplied to
 948 the constructor and use those instead.
 949
 950 =cut
 951
 952 around config => sub {
 953     my $orig = shift;
 954     my $c = shift;
 955
 956     croak('Setting config after setup has been run is not allowed.')
 957         if ( @_ and $c->setup_finished );
 958
 959     $c->$orig(@_);
 960 };
 961
 962 =head2 $c->log
 963
 964 Returns the logging object instance. Unless it is already set, Catalyst
 965 sets this up with a L<Catalyst::Log> object. To use your own log class,
 966 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 967 C<< __PACKAGE__->setup >>.
 968
 969  __PACKAGE__->log( MyLogger->new );
 970  __PACKAGE__->setup;
 971
 972 And later:
 973
 974     $c->log->info( 'Now logging with my own logger!' );
 975
 976 Your log class should implement the methods described in
 977 L<Catalyst::Log>.
 978
 979
 980 =head2 $c->debug
 981
 982 Returns 1 if debug mode is enabled, 0 otherwise.
 983
 984 You can enable debug mode in several ways:
 985
 986 =over
 987
 988 =item By calling myapp_server.pl with the -d flag
 989
 990 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 991
 992 =item The -Debug option in your MyApp.pm
 993
 994 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 995
 996 =back
 997
 998 The first three also set the log level to 'debug'.
 999
1000 Calling C<< $c->debug(1) >> has no effect.
1001
1002 =cut
1003
1004 sub debug { 0 }
1005
1006 =head2 $c->dispatcher
1007
1008 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1009
1010 =head2 $c->engine
1011
1012 Returns the engine instance. See L<Catalyst::Engine>.
1013
1014
1015 =head2 UTILITY METHODS
1016
1017 =head2 $c->path_to(@path)
1018
1019 Merges C<@path> with C<< $c->config->{home} >> and returns a
1020 L<Path::Class::Dir> object. Note you can usually use this object as
1021 a filename, but sometimes you will have to explicitly stringify it
1022 yourself by calling the C<< ->stringify >> method.
1023
1024 For example:
1025
1026     $c->path_to( 'db', 'sqlite.db' );
1027
1028 =cut
1029
1030 sub path_to {
1031     my ( $c, @path ) = @_;
1032     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1033     if ( -d $path ) { return $path }
1034     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1035 }
1036
1037 sub plugin {
1038     my ( $class, $name, $plugin, @args ) = @_;
1039
1040     # See block comment in t/unit_core_plugin.t
1041     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1042
1043     $class->_register_plugin( $plugin, 1 );
1044
1045     eval { $plugin->import };
1046     $class->mk_classdata($name);
1047     my $obj;
1048     eval { $obj = $plugin->new(@args) };
1049
1050     if ($@) {
1051         Catalyst::Exception->throw( message =>
1052               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1053     }
1054
1055     $class->$name($obj);
1056     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1057       if $class->debug;
1058 }
1059
1060 =head2 MyApp->setup
1061
1062 Initializes the dispatcher and engine, loads any plugins, and loads the
1063 model, view, and controller components. You may also specify an array
1064 of plugins to load here, if you choose to not load them in the C<use
1065 Catalyst> line.
1066
1067     MyApp->setup;
1068     MyApp->setup( qw/-Debug/ );
1069
1070 B<Note:> You B<should not> wrap this method with method modifiers
1071 or bad things will happen - wrap the C<setup_finalize> method instead.
1072
1073 =cut
1074
1075 sub setup {
1076     my ( $class, @arguments ) = @_;
1077     croak('Running setup more than once')
1078         if ( $class->setup_finished );
1079
1080     unless ( $class->isa('Catalyst') ) {
1081
1082         Catalyst::Exception->throw(
1083             message => qq/'$class' does not inherit from Catalyst/ );
1084     }
1085
1086     if ( $class->arguments ) {
1087         @arguments = ( @arguments, @{ $class->arguments } );
1088     }
1089
1090     # Process options
1091     my $flags = {};
1092
1093     foreach (@arguments) {
1094
1095         if (/^-Debug$/) {
1096             $flags->{log} =
1097               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1098         }
1099         elsif (/^-(\w+)=?(.*)$/) {
1100             $flags->{ lc $1 } = $2;
1101         }
1102         else {
1103             push @{ $flags->{plugins} }, $_;
1104         }
1105     }
1106
1107     $class->setup_home( delete $flags->{home} );
1108
1109     $class->setup_log( delete $flags->{log} );
1110     $class->setup_plugins( delete $flags->{plugins} );
1111     $class->setup_dispatcher( delete $flags->{dispatcher} );
1112     if (my $engine = delete $flags->{engine}) {
1113         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1114     }
1115     $class->setup_engine();
1116     $class->setup_stats( delete $flags->{stats} );
1117
1118     for my $flag ( sort keys %{$flags} ) {
1119
1120         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1121             &$code( $class, delete $flags->{$flag} );
1122         }
1123         else {
1124             $class->log->warn(qq/Unknown flag "$flag"/);
1125         }
1126     }
1127
1128     eval { require Catalyst::Devel; };
1129     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1130         $class->log->warn(<<"EOF");
1131 You are running an old script!
1132
1133   Please update by running (this will overwrite existing files):
1134     catalyst.pl -force -scripts $class
1135
1136   or (this will not overwrite existing files):
1137     catalyst.pl -scripts $class
1138
1139 EOF
1140     }
1141
1142     if ( $class->debug ) {
1143         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1144
1145         if (@plugins) {
1146             my $column_width = Catalyst::Utils::term_width() - 6;
1147             my $t = Text::SimpleTable->new($column_width);
1148             $t->row($_) for @plugins;
1149             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1150         }
1151
1152         my $dispatcher = $class->dispatcher;
1153         my $engine     = $class->engine;
1154         my $home       = $class->config->{home};
1155
1156         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1157         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1158
1159         $home
1160           ? ( -d $home )
1161           ? $class->log->debug(qq/Found home "$home"/)
1162           : $class->log->debug(qq/Home "$home" doesn't exist/)
1163           : $class->log->debug(q/Couldn't find home/);
1164     }
1165
1166     # Call plugins setup, this is stupid and evil.
1167     # Also screws C3 badly on 5.10, hack to avoid.
1168     {
1169         no warnings qw/redefine/;
1170         local *setup = sub { };
1171         $class->setup unless $Catalyst::__AM_RESTARTING;
1172     }
1173
1174     # Initialize our data structure
1175     $class->components( {} );
1176
1177     $class->setup_components;
1178
1179     if ( $class->debug ) {
1180         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1181         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1182         for my $comp ( sort keys %{ $class->components } ) {
1183             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1184             $t->row( $comp, $type );
1185         }
1186         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1187           if ( keys %{ $class->components } );
1188     }
1189
1190     # Add our self to components, since we are also a component
1191     if( $class->isa('Catalyst::Controller') ){
1192       $class->components->{$class} = $class;
1193     }
1194
1195     $class->setup_actions;
1196
1197     if ( $class->debug ) {
1198         my $name = $class->config->{name} || 'Application';
1199         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1200     }
1201
1202     if ($class->config->{case_sensitive}) {
1203         $class->log->warn($class . "->config->{case_sensitive} is set.");
1204         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1205     }
1206
1207     $class->setup_finalize;
1208     # Should be the last thing we do so that user things hooking
1209     # setup_finalize can log..
1210     $class->log->_flush() if $class->log->can('_flush');
1211     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1212 }
1213
1214 =head2 $app->setup_finalize
1215
1216 A hook to attach modifiers to. This method does not do anything except set the
1217 C<setup_finished> accessor.
1218
1219 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1220
1221 Example:
1222
1223     after setup_finalize => sub {
1224         my $app = shift;
1225
1226         ## do stuff here..
1227     };
1228
1229 =cut
1230
1231 sub setup_finalize {
1232     my ($class) = @_;
1233     $class->setup_finished(1);
1234 }
1235
1236 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1237
1238 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1239
1240 Constructs an absolute L<URI> object based on the application root, the
1241 provided path, and the additional arguments and query parameters provided.
1242 When used as a string, provides a textual URI.  If you need more flexibility
1243 than this (i.e. the option to provide relative URIs etc.) see
1244 L<Catalyst::Plugin::SmartURI>.
1245
1246 If no arguments are provided, the URI for the current action is returned.
1247 To return the current action and also provide @args, use
1248 C<< $c->uri_for( $c->action, @args ) >>.
1249
1250 If the first argument is a string, it is taken as a public URI path relative
1251 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1252 relative to the application root (if it does). It is then merged with
1253 C<< $c->request->base >>; any C<@args> are appended as additional path
1254 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1255
1256 If the first argument is a L<Catalyst::Action> it represents an action which
1257 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1258 optional C<\@captures> argument (an arrayref) allows passing the captured
1259 variables that are needed to fill in the paths of Chained and Regex actions;
1260 once the path is resolved, C<uri_for> continues as though a path was
1261 provided, appending any arguments or parameters and creating an absolute
1262 URI.
1263
1264 The captures for the current request can be found in
1265 C<< $c->request->captures >>, and actions can be resolved using
1266 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1267 path, use C<< $c->uri_for_action >> instead.
1268
1269   # Equivalent to $c->req->uri
1270   $c->uri_for($c->action, $c->req->captures,
1271       @{ $c->req->args }, $c->req->params);
1272
1273   # For the Foo action in the Bar controller
1274   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1275
1276   # Path to a static resource
1277   $c->uri_for('/static/images/logo.png');
1278
1279 =cut
1280
1281 sub uri_for {
1282     my ( $c, $path, @args ) = @_;
1283
1284     if ( $path->$_isa('Catalyst::Controller') ) {
1285         $path = $path->path_prefix;
1286         $path =~ s{/+\z}{};
1287         $path .= '/';
1288     }
1289
1290     undef($path) if (defined $path && $path eq '');
1291
1292     my $params =
1293       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1294
1295     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1296     foreach my $arg (@args) {
1297         utf8::encode($arg) if utf8::is_utf8($arg);
1298         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1299     }
1300
1301     if ( $path->$_isa('Catalyst::Action') ) { # action object
1302         s|/|%2F|g for @args;
1303         my $captures = [ map { s|/|%2F|g; $_; }
1304                         ( scalar @args && ref $args[0] eq 'ARRAY'
1305                          ? @{ shift(@args) }
1306                          : ()) ];
1307
1308         foreach my $capture (@$captures) {
1309             utf8::encode($capture) if utf8::is_utf8($capture);
1310             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1311         }
1312
1313         my $action = $path;
1314         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1315         if( !@args && $action->number_of_args ) {
1316             my $expanded_action = $c->dispatcher->expand_action( $action );
1317
1318             my $num_captures = $expanded_action->number_of_captures;
1319             unshift @args, splice @$captures, $num_captures;
1320         }
1321
1322        $path = $c->dispatcher->uri_for_action($action, $captures);
1323         if (not defined $path) {
1324             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1325                 if $c->debug;
1326             return undef;
1327         }
1328         $path = '/' if $path eq '';
1329     }
1330
1331     unshift(@args, $path);
1332
1333     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1334         my $namespace = $c->namespace;
1335         if (defined $path) { # cheesy hack to handle path '../foo'
1336            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1337         }
1338         unshift(@args, $namespace || '');
1339     }
1340
1341     # join args with '/', or a blank string
1342     my $args = join('/', grep { defined($_) } @args);
1343     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1344     $args =~ s!^/+!!;
1345     my $base = $c->req->base;
1346     my $class = ref($base);
1347     $base =~ s{(?<!/)$}{/};
1348
1349     my $query = '';
1350
1351     if (my @keys = keys %$params) {
1352       # somewhat lifted from URI::_query's query_form
1353       $query = '?'.join('&', map {
1354           my $val = $params->{$_};
1355           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1356           s/ /+/g;
1357           my $key = $_;
1358           $val = '' unless defined $val;
1359           (map {
1360               my $param = "$_";
1361               utf8::encode( $param ) if utf8::is_utf8($param);
1362               # using the URI::Escape pattern here so utf8 chars survive
1363               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1364               $param =~ s/ /+/g;
1365               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1366       } @keys);
1367     }
1368
1369     my $res = bless(\"${base}${args}${query}", $class);
1370     $res;
1371 }
1372
1373 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1374
1375 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1376
1377 =over
1378
1379 =item $path
1380
1381 A private path to the Catalyst action you want to create a URI for.
1382
1383 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1384 >> and passing the resulting C<$action> and the remaining arguments to C<<
1385 $c->uri_for >>.
1386
1387 You can also pass in a Catalyst::Action object, in which case it is passed to
1388 C<< $c->uri_for >>.
1389
1390 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1391
1392 For example, if the action looks like:
1393
1394  package MyApp::Controller::Users;
1395
1396  sub lst : Path('the-list') {}
1397
1398 You can use:
1399
1400  $c->uri_for_action('/users/lst')
1401
1402 and it will create the URI /users/the-list.
1403
1404 =item \@captures_and_args?
1405
1406 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1407 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1408 to interpolate all the parameters in the URI.
1409
1410 =item @args?
1411
1412 Optional list of extra arguments - can be supplied in the
1413 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1414 code.
1415
1416 Your action can have zero, a fixed or a variable number of args (e.g.
1417 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1418
1419 =item \%query_values?
1420
1421 Optional array reference of query parameters to append. E.g.
1422
1423   { foo => 'bar' }
1424
1425 will generate
1426
1427   /rest/of/your/uri?foo=bar
1428
1429 =back
1430
1431 =cut
1432
1433 sub uri_for_action {
1434     my ( $c, $path, @args ) = @_;
1435     my $action = blessed($path)
1436       ? $path
1437       : $c->dispatcher->get_action_by_path($path);
1438     unless (defined $action) {
1439       croak "Can't find action for path '$path'";
1440     }
1441     return $c->uri_for( $action, @args );
1442 }
1443
1444 =head2 $c->welcome_message
1445
1446 Returns the Catalyst welcome HTML page.
1447
1448 =cut
1449
1450 sub welcome_message {
1451     my $c      = shift;
1452     my $name   = $c->config->{name};
1453     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1454     my $prefix = Catalyst::Utils::appprefix( ref $c );
1455     $c->response->content_type('text/html; charset=utf-8');
1456     return <<"EOF";
1457 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1458     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1459 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1460     <head>
1461     <meta http-equiv="Content-Language" content="en" />
1462     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1463         <title>$name on Catalyst $VERSION</title>
1464         <style type="text/css">
1465             body {
1466                 color: #000;
1467                 background-color: #eee;
1468             }
1469             div#content {
1470                 width: 640px;
1471                 margin-left: auto;
1472                 margin-right: auto;
1473                 margin-top: 10px;
1474                 margin-bottom: 10px;
1475                 text-align: left;
1476                 background-color: #ccc;
1477                 border: 1px solid #aaa;
1478             }
1479             p, h1, h2 {
1480                 margin-left: 20px;
1481                 margin-right: 20px;
1482                 font-family: verdana, tahoma, sans-serif;
1483             }
1484             a {
1485                 font-family: verdana, tahoma, sans-serif;
1486             }
1487             :link, :visited {
1488                     text-decoration: none;
1489                     color: #b00;
1490                     border-bottom: 1px dotted #bbb;
1491             }
1492             :link:hover, :visited:hover {
1493                     color: #555;
1494             }
1495             div#topbar {
1496                 margin: 0px;
1497             }
1498             pre {
1499                 margin: 10px;
1500                 padding: 8px;
1501             }
1502             div#answers {
1503                 padding: 8px;
1504                 margin: 10px;
1505                 background-color: #fff;
1506                 border: 1px solid #aaa;
1507             }
1508             h1 {
1509                 font-size: 0.9em;
1510                 font-weight: normal;
1511                 text-align: center;
1512             }
1513             h2 {
1514                 font-size: 1.0em;
1515             }
1516             p {
1517                 font-size: 0.9em;
1518             }
1519             p img {
1520                 float: right;
1521                 margin-left: 10px;
1522             }
1523             span#appname {
1524                 font-weight: bold;
1525                 font-size: 1.6em;
1526             }
1527         </style>
1528     </head>
1529     <body>
1530         <div id="content">
1531             <div id="topbar">
1532                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1533                     $VERSION</h1>
1534              </div>
1535              <div id="answers">
1536                  <p>
1537                  <img src="$logo" alt="Catalyst Logo" />
1538                  </p>
1539                  <p>Welcome to the  world of Catalyst.
1540                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1541                     framework will make web development something you had
1542                     never expected it to be: Fun, rewarding, and quick.</p>
1543                  <h2>What to do now?</h2>
1544                  <p>That really depends  on what <b>you</b> want to do.
1545                     We do, however, provide you with a few starting points.</p>
1546                  <p>If you want to jump right into web development with Catalyst
1547                     you might want to start with a tutorial.</p>
1548 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1549 </pre>
1550 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1551 <pre>
1552 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1553 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1554 </code></pre>
1555                  <h2>What to do next?</h2>
1556                  <p>Next it's time to write an actual application. Use the
1557                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1558                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1559                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1560                     they can save you a lot of work.</p>
1561                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1562                     <p>Also, be sure to check out the vast and growing
1563                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1564                     you are likely to find what you need there.
1565                     </p>
1566
1567                  <h2>Need help?</h2>
1568                  <p>Catalyst has a very active community. Here are the main places to
1569                     get in touch with us.</p>
1570                  <ul>
1571                      <li>
1572                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1573                      </li>
1574                      <li>
1575                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1576                      </li>
1577                      <li>
1578                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1579                      </li>
1580                  </ul>
1581                  <h2>In conclusion</h2>
1582                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1583                     as we enjoyed making it. Please contact us if you have ideas
1584                     for improvement or other feedback.</p>
1585              </div>
1586          </div>
1587     </body>
1588 </html>
1589 EOF
1590 }
1591
1592 =head2 run_options
1593
1594 Contains a hash of options passed from the application script, including
1595 the original ARGV the script received, the processed values from that
1596 ARGV and any extra arguments to the script which were not processed.
1597
1598 This can be used to add custom options to your application's scripts
1599 and setup your application differently depending on the values of these
1600 options.
1601
1602 =head1 INTERNAL METHODS
1603
1604 These methods are not meant to be used by end users.
1605
1606 =head2 $c->components
1607
1608 Returns a hash of components.
1609
1610 =head2 $c->context_class
1611
1612 Returns or sets the context class.
1613
1614 =head2 $c->counter
1615
1616 Returns a hashref containing coderefs and execution counts (needed for
1617 deep recursion detection).
1618
1619 =head2 $c->depth
1620
1621 Returns the number of actions on the current internal execution stack.
1622
1623 =head2 $c->dispatch
1624
1625 Dispatches a request to actions.
1626
1627 =cut
1628
1629 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1630
1631 =head2 $c->dispatcher_class
1632
1633 Returns or sets the dispatcher class.
1634
1635 =head2 $c->dump_these
1636
1637 Returns a list of 2-element array references (name, structure) pairs
1638 that will be dumped on the error page in debug mode.
1639
1640 =cut
1641
1642 sub dump_these {
1643     my $c = shift;
1644     [ Request => $c->req ],
1645     [ Response => $c->res ],
1646     [ Stash => $c->stash ],
1647     [ Config => $c->config ];
1648 }
1649
1650 =head2 $c->engine_class
1651
1652 Returns or sets the engine class.
1653
1654 =head2 $c->execute( $class, $coderef )
1655
1656 Execute a coderef in given class and catch exceptions. Errors are available
1657 via $c->error.
1658
1659 =cut
1660
1661 sub execute {
1662     my ( $c, $class, $code ) = @_;
1663     $class = $c->component($class) || $class;
1664     $c->state(0);
1665
1666     if ( $c->depth >= $RECURSION ) {
1667         my $action = $code->reverse();
1668         $action = "/$action" unless $action =~ /->/;
1669         my $error = qq/Deep recursion detected calling "${action}"/;
1670         $c->log->error($error);
1671         $c->error($error);
1672         $c->state(0);
1673         return $c->state;
1674     }
1675
1676     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1677
1678     push( @{ $c->stack }, $code );
1679
1680     no warnings 'recursion';
1681     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1682     #      I have no idea how, ergo $ret (which appears to fix the issue)
1683     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1684
1685     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1686
1687     my $last = pop( @{ $c->stack } );
1688
1689     if ( my $error = $@ ) {
1690         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1691             $error->rethrow if $c->depth > 1;
1692         }
1693         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1694             $error->rethrow if $c->depth > 0;
1695         }
1696         else {
1697             unless ( ref $error ) {
1698                 no warnings 'uninitialized';
1699                 chomp $error;
1700                 my $class = $last->class;
1701                 my $name  = $last->name;
1702                 $error = qq/Caught exception in $class->$name "$error"/;
1703             }
1704             $c->error($error);
1705         }
1706         $c->state(0);
1707     }
1708     return $c->state;
1709 }
1710
1711 sub _stats_start_execute {
1712     my ( $c, $code ) = @_;
1713     my $appclass = ref($c) || $c;
1714     return if ( ( $code->name =~ /^_.*/ )
1715         && ( !$appclass->config->{show_internal_actions} ) );
1716
1717     my $action_name = $code->reverse();
1718     $c->counter->{$action_name}++;
1719
1720     my $action = $action_name;
1721     $action = "/$action" unless $action =~ /->/;
1722
1723     # determine if the call was the result of a forward
1724     # this is done by walking up the call stack and looking for a calling
1725     # sub of Catalyst::forward before the eval
1726     my $callsub = q{};
1727     for my $index ( 2 .. 11 ) {
1728         last
1729         if ( ( caller($index) )[0] eq 'Catalyst'
1730             && ( caller($index) )[3] eq '(eval)' );
1731
1732         if ( ( caller($index) )[3] =~ /forward$/ ) {
1733             $callsub = ( caller($index) )[3];
1734             $action  = "-> $action";
1735             last;
1736         }
1737     }
1738
1739     my $uid = $action_name . $c->counter->{$action_name};
1740
1741     # is this a root-level call or a forwarded call?
1742     if ( $callsub =~ /forward$/ ) {
1743         my $parent = $c->stack->[-1];
1744
1745         # forward, locate the caller
1746         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1747             $c->stats->profile(
1748                 begin  => $action,
1749                 parent => "$parent" . $c->counter->{"$parent"},
1750                 uid    => $uid,
1751             );
1752         }
1753         else {
1754
1755             # forward with no caller may come from a plugin
1756             $c->stats->profile(
1757                 begin => $action,
1758                 uid   => $uid,
1759             );
1760         }
1761     }
1762     else {
1763
1764         # root-level call
1765         $c->stats->profile(
1766             begin => $action,
1767             uid   => $uid,
1768         );
1769     }
1770     return $action;
1771
1772 }
1773
1774 sub _stats_finish_execute {
1775     my ( $c, $info ) = @_;
1776     $c->stats->profile( end => $info );
1777 }
1778
1779 =head2 $c->finalize
1780
1781 Finalizes the request.
1782
1783 =cut
1784
1785 sub finalize {
1786     my $c = shift;
1787
1788     for my $error ( @{ $c->error } ) {
1789         $c->log->error($error);
1790     }
1791
1792     # Allow engine to handle finalize flow (for POE)
1793     my $engine = $c->engine;
1794     if ( my $code = $engine->can('finalize') ) {
1795         $engine->$code($c);
1796     }
1797     else {
1798
1799         $c->finalize_uploads;
1800
1801         # Error
1802         if ( $#{ $c->error } >= 0 ) {
1803             $c->finalize_error;
1804         }
1805
1806         $c->finalize_headers unless $c->response->finalized_headers;
1807
1808         # HEAD request
1809         if ( $c->request->method eq 'HEAD' ) {
1810             $c->response->body('');
1811         }
1812
1813         $c->finalize_body;
1814     }
1815
1816     $c->log_response;
1817
1818     if ($c->use_stats) {
1819         my $elapsed = sprintf '%f', $c->stats->elapsed;
1820         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1821         $c->log->info(
1822             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1823     }
1824
1825     return $c->response->status;
1826 }
1827
1828 =head2 $c->finalize_body
1829
1830 Finalizes body.
1831
1832 =cut
1833
1834 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1835
1836 =head2 $c->finalize_cookies
1837
1838 Finalizes cookies.
1839
1840 =cut
1841
1842 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1843
1844 =head2 $c->finalize_error
1845
1846 Finalizes error.
1847
1848 =cut
1849
1850 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1851
1852 =head2 $c->finalize_headers
1853
1854 Finalizes headers.
1855
1856 =cut
1857
1858 sub finalize_headers {
1859     my $c = shift;
1860
1861     my $response = $c->response; #accessor calls can add up?
1862
1863     # Check if we already finalized headers
1864     return if $response->finalized_headers;
1865
1866     # Handle redirects
1867     if ( my $location = $response->redirect ) {
1868         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1869         $response->header( Location => $location );
1870
1871         if ( !$response->has_body ) {
1872             # Add a default body if none is already present
1873             my $encoded_location = encode_entities($location);
1874             $response->body(<<"EOF");
1875 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1876 <html xmlns="http://www.w3.org/1999/xhtml">
1877   <head>
1878     <title>Moved</title>
1879   </head>
1880   <body>
1881      <p>This item has moved <a href="$encoded_location">here</a>.</p>
1882   </body>
1883 </html>
1884 EOF
1885             $response->content_type('text/html; charset=utf-8');
1886         }
1887     }
1888
1889     # Content-Length
1890     if ( defined $response->body && length $response->body && !$response->content_length ) {
1891
1892         # get the length from a filehandle
1893         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1894         {
1895             my $size = -s $response->body;
1896             if ( $size ) {
1897                 $response->content_length( $size );
1898             }
1899             else {
1900                 $c->log->warn('Serving filehandle without a content-length');
1901             }
1902         }
1903         else {
1904             # everything should be bytes at this point, but just in case
1905             $response->content_length( length( $response->body ) );
1906         }
1907     }
1908
1909     # Errors
1910     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1911         $response->headers->remove_header("Content-Length");
1912         $response->body('');
1913     }
1914
1915     $c->finalize_cookies;
1916
1917     $c->response->finalize_headers();
1918
1919     # Done
1920     $response->finalized_headers(1);
1921 }
1922
1923 =head2 $c->finalize_output
1924
1925 An alias for finalize_body.
1926
1927 =head2 $c->finalize_read
1928
1929 Finalizes the input after reading is complete.
1930
1931 =cut
1932
1933 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1934
1935 =head2 $c->finalize_uploads
1936
1937 Finalizes uploads. Cleans up any temporary files.
1938
1939 =cut
1940
1941 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1942
1943 =head2 $c->get_action( $action, $namespace )
1944
1945 Gets an action in a given namespace.
1946
1947 =cut
1948
1949 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1950
1951 =head2 $c->get_actions( $action, $namespace )
1952
1953 Gets all actions of a given name in a namespace and all parent
1954 namespaces.
1955
1956 =cut
1957
1958 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1959
1960 =head2 $app->handle_request( @arguments )
1961
1962 Called to handle each HTTP request.
1963
1964 =cut
1965
1966 sub handle_request {
1967     my ( $class, @arguments ) = @_;
1968
1969     # Always expect worst case!
1970     my $status = -1;
1971     try {
1972         if ($class->debug) {
1973             my $secs = time - $START || 1;
1974             my $av = sprintf '%.3f', $COUNT / $secs;
1975             my $time = localtime time;
1976             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1977         }
1978
1979         my $c = $class->prepare(@arguments);
1980         $c->dispatch;
1981         $status = $c->finalize;
1982     }
1983     catch {
1984         chomp(my $error = $_);
1985         $class->log->error(qq/Caught exception in engine "$error"/);
1986     };
1987
1988     $COUNT++;
1989
1990     if(my $coderef = $class->log->can('_flush')){
1991         $class->log->$coderef();
1992     }
1993     return $status;
1994 }
1995
1996 =head2 $class->prepare( @arguments )
1997
1998 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1999 etc.).
2000
2001 =cut
2002
2003 has _uploadtmp => (
2004     is => 'ro',
2005     predicate => '_has_uploadtmp',
2006 );
2007
2008 sub prepare {
2009     my ( $class, @arguments ) = @_;
2010
2011     # XXX
2012     # After the app/ctxt split, this should become an attribute based on something passed
2013     # into the application.
2014     $class->context_class( ref $class || $class ) unless $class->context_class;
2015
2016     my $uploadtmp = $class->config->{uploadtmp};
2017     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2018
2019     $c->response->_context($c);
2020
2021     #surely this is not the most efficient way to do things...
2022     $c->stats($class->stats_class->new)->enable($c->use_stats);
2023     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2024         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2025     }
2026
2027     try {
2028         # Allow engine to direct the prepare flow (for POE)
2029         if ( my $prepare = $c->engine->can('prepare') ) {
2030             $c->engine->$prepare( $c, @arguments );
2031         }
2032         else {
2033             $c->prepare_request(@arguments);
2034             $c->prepare_connection;
2035             $c->prepare_query_parameters;
2036             $c->prepare_headers; # Just hooks, no longer needed - they just
2037             $c->prepare_cookies; # cause the lazy attribute on req to build
2038             $c->prepare_path;
2039
2040             # Prepare the body for reading, either by prepare_body
2041             # or the user, if they are using $c->read
2042             $c->prepare_read;
2043
2044             # Parse the body unless the user wants it on-demand
2045             unless ( ref($c)->config->{parse_on_demand} ) {
2046                 $c->prepare_body;
2047             }
2048         }
2049         $c->prepare_action;
2050     }
2051     # VERY ugly and probably shouldn't rely on ->finalize actually working
2052     catch {
2053         # failed prepare is always due to an invalid request, right?
2054         $c->response->status(400);
2055         $c->response->content_type('text/plain');
2056         $c->response->body('Bad Request');
2057         # Note we call finalize and then die here, which escapes
2058         # finalize being called in the enclosing block..
2059         # It in fact couldn't be called, as we don't return $c..
2060         # This is a mess - but I'm unsure you can fix this without
2061         # breaking compat for people doing crazy things (we should set
2062         # the 400 and just return the ctx here IMO, letting finalize get called
2063         # above...
2064         $c->finalize;
2065         die $_;
2066     };
2067
2068     $c->log_request;
2069
2070     return $c;
2071 }
2072
2073 =head2 $c->prepare_action
2074
2075 Prepares action. See L<Catalyst::Dispatcher>.
2076
2077 =cut
2078
2079 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2080
2081 =head2 $c->prepare_body
2082
2083 Prepares message body.
2084
2085 =cut
2086
2087 sub prepare_body {
2088     my $c = shift;
2089
2090     return if $c->request->_has_body;
2091
2092     # Initialize on-demand data
2093     $c->engine->prepare_body( $c, @_ );
2094     $c->prepare_parameters;
2095     $c->prepare_uploads;
2096 }
2097
2098 =head2 $c->prepare_body_chunk( $chunk )
2099
2100 Prepares a chunk of data before sending it to L<HTTP::Body>.
2101
2102 See L<Catalyst::Engine>.
2103
2104 =cut
2105
2106 sub prepare_body_chunk {
2107     my $c = shift;
2108     $c->engine->prepare_body_chunk( $c, @_ );
2109 }
2110
2111 =head2 $c->prepare_body_parameters
2112
2113 Prepares body parameters.
2114
2115 =cut
2116
2117 sub prepare_body_parameters {
2118     my $c = shift;
2119     $c->engine->prepare_body_parameters( $c, @_ );
2120 }
2121
2122 =head2 $c->prepare_connection
2123
2124 Prepares connection.
2125
2126 =cut
2127
2128 sub prepare_connection {
2129     my $c = shift;
2130     # XXX - This is called on the engine (not the request) to maintain
2131     #       Engine::PSGI back compat.
2132     $c->engine->prepare_connection($c);
2133 }
2134
2135 =head2 $c->prepare_cookies
2136
2137 Prepares cookies by ensuring that the attribute on the request
2138 object has been built.
2139
2140 =cut
2141
2142 sub prepare_cookies { my $c = shift; $c->request->cookies }
2143
2144 =head2 $c->prepare_headers
2145
2146 Prepares request headers by ensuring that the attribute on the request
2147 object has been built.
2148
2149 =cut
2150
2151 sub prepare_headers { my $c = shift; $c->request->headers }
2152
2153 =head2 $c->prepare_parameters
2154
2155 Prepares parameters.
2156
2157 =cut
2158
2159 sub prepare_parameters {
2160     my $c = shift;
2161     $c->prepare_body_parameters;
2162     $c->engine->prepare_parameters( $c, @_ );
2163 }
2164
2165 =head2 $c->prepare_path
2166
2167 Prepares path and base.
2168
2169 =cut
2170
2171 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2172
2173 =head2 $c->prepare_query_parameters
2174
2175 Prepares query parameters.
2176
2177 =cut
2178
2179 sub prepare_query_parameters {
2180     my $c = shift;
2181
2182     $c->engine->prepare_query_parameters( $c, @_ );
2183 }
2184
2185 =head2 $c->log_request
2186
2187 Writes information about the request to the debug logs.  This includes:
2188
2189 =over 4
2190
2191 =item * Request method, path, and remote IP address
2192
2193 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2194
2195 =item * Request parameters
2196
2197 =item * File uploads
2198
2199 =back
2200
2201 =cut
2202
2203 sub log_request {
2204     my $c = shift;
2205
2206     return unless $c->debug;
2207
2208     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2209     my $request = $dump->[1];
2210
2211     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2212     $method ||= '';
2213     $path = '/' unless length $path;
2214     $address ||= '';
2215     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2216
2217     $c->log_request_headers($request->headers);
2218
2219     if ( my $keywords = $request->query_keywords ) {
2220         $c->log->debug("Query keywords are: $keywords");
2221     }
2222
2223     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2224
2225     $c->log_request_uploads($request);
2226 }
2227
2228 =head2 $c->log_response
2229
2230 Writes information about the response to the debug logs by calling
2231 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2232
2233 =cut
2234
2235 sub log_response {
2236     my $c = shift;
2237
2238     return unless $c->debug;
2239
2240     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2241     my $response = $dump->[1];
2242
2243     $c->log_response_status_line($response);
2244     $c->log_response_headers($response->headers);
2245 }
2246
2247 =head2 $c->log_response_status_line($response)
2248
2249 Writes one line of information about the response to the debug logs.  This includes:
2250
2251 =over 4
2252
2253 =item * Response status code
2254
2255 =item * Content-Type header (if present)
2256
2257 =item * Content-Length header (if present)
2258
2259 =back
2260
2261 =cut
2262
2263 sub log_response_status_line {
2264     my ($c, $response) = @_;
2265
2266     $c->log->debug(
2267         sprintf(
2268             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2269             $response->status                            || 'unknown',
2270             $response->headers->header('Content-Type')   || 'unknown',
2271             $response->headers->header('Content-Length') || 'unknown'
2272         )
2273     );
2274 }
2275
2276 =head2 $c->log_response_headers($headers);
2277
2278 Hook method which can be wrapped by plugins to log the response headers.
2279 No-op in the default implementation.
2280
2281 =cut
2282
2283 sub log_response_headers {}
2284
2285 =head2 $c->log_request_parameters( query => {}, body => {} )
2286
2287 Logs request parameters to debug logs
2288
2289 =cut
2290
2291 sub log_request_parameters {
2292     my $c          = shift;
2293     my %all_params = @_;
2294
2295     return unless $c->debug;
2296
2297     my $column_width = Catalyst::Utils::term_width() - 44;
2298     foreach my $type (qw(query body)) {
2299         my $params = $all_params{$type};
2300         next if ! keys %$params;
2301         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2302         for my $key ( sort keys %$params ) {
2303             my $param = $params->{$key};
2304             my $value = defined($param) ? $param : '';
2305             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2306         }
2307         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2308     }
2309 }
2310
2311 =head2 $c->log_request_uploads
2312
2313 Logs file uploads included in the request to the debug logs.
2314 The parameter name, filename, file type, and file size are all included in
2315 the debug logs.
2316
2317 =cut
2318
2319 sub log_request_uploads {
2320     my $c = shift;
2321     my $request = shift;
2322     return unless $c->debug;
2323     my $uploads = $request->uploads;
2324     if ( keys %$uploads ) {
2325         my $t = Text::SimpleTable->new(
2326             [ 12, 'Parameter' ],
2327             [ 26, 'Filename' ],
2328             [ 18, 'Type' ],
2329             [ 9,  'Size' ]
2330         );
2331         for my $key ( sort keys %$uploads ) {
2332             my $upload = $uploads->{$key};
2333             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2334                 $t->row( $key, $u->filename, $u->type, $u->size );
2335             }
2336         }
2337         $c->log->debug( "File Uploads are:\n" . $t->draw );
2338     }
2339 }
2340
2341 =head2 $c->log_request_headers($headers);
2342
2343 Hook method which can be wrapped by plugins to log the request headers.
2344 No-op in the default implementation.
2345
2346 =cut
2347
2348 sub log_request_headers {}
2349
2350 =head2 $c->log_headers($type => $headers)
2351
2352 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2353
2354 =cut
2355
2356 sub log_headers {
2357     my $c       = shift;
2358     my $type    = shift;
2359     my $headers = shift;    # an HTTP::Headers instance
2360
2361     return unless $c->debug;
2362
2363     my $column_width = Catalyst::Utils::term_width() - 28;
2364     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2365     $headers->scan(
2366         sub {
2367             my ( $name, $value ) = @_;
2368             $t->row( $name, $value );
2369         }
2370     );
2371     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2372 }
2373
2374
2375 =head2 $c->prepare_read
2376
2377 Prepares the input for reading.
2378
2379 =cut
2380
2381 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2382
2383 =head2 $c->prepare_request
2384
2385 Prepares the engine request.
2386
2387 =cut
2388
2389 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2390
2391 =head2 $c->prepare_uploads
2392
2393 Prepares uploads.
2394
2395 =cut
2396
2397 sub prepare_uploads {
2398     my $c = shift;
2399
2400     $c->engine->prepare_uploads( $c, @_ );
2401 }
2402
2403 =head2 $c->prepare_write
2404
2405 Prepares the output for writing.
2406
2407 =cut
2408
2409 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2410
2411 =head2 $c->request_class
2412
2413 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2414
2415 =head2 $c->response_class
2416
2417 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2418
2419 =head2 $c->read( [$maxlength] )
2420
2421 Reads a chunk of data from the request body. This method is designed to
2422 be used in a while loop, reading C<$maxlength> bytes on every call.
2423 C<$maxlength> defaults to the size of the request if not specified.
2424
2425 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2426 directly.
2427
2428 Warning: If you use read(), Catalyst will not process the body,
2429 so you will not be able to access POST parameters or file uploads via
2430 $c->request.  You must handle all body parsing yourself.
2431
2432 =cut
2433
2434 sub read { my $c = shift; return $c->request->read( @_ ) }
2435
2436 =head2 $c->run
2437
2438 Starts the engine.
2439
2440 =cut
2441
2442 sub run {
2443   my $app = shift;
2444   $app->_make_immutable_if_needed;
2445   $app->engine_loader->needs_psgi_engine_compat_hack ?
2446     $app->engine->run($app, @_) :
2447       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2448 }
2449
2450 sub _make_immutable_if_needed {
2451     my $class = shift;
2452     my $meta = Class::MOP::get_metaclass_by_name($class);
2453     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2454     if (
2455         $meta->is_immutable
2456         && ! { $meta->immutable_options }->{replace_constructor}
2457         && $isa_ca
2458     ) {
2459         warn("You made your application class ($class) immutable, "
2460             . "but did not inline the\nconstructor. "
2461             . "This will break catalyst, as your app \@ISA "
2462             . "Class::Accessor(::Fast)?\nPlease pass "
2463             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2464     }
2465     unless ($meta->is_immutable) {
2466         # XXX - FIXME warning here as you should make your app immutable yourself.
2467         $meta->make_immutable(
2468             replace_constructor => 1,
2469         );
2470     }
2471 }
2472
2473 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2474
2475 Sets an action in a given namespace.
2476
2477 =cut
2478
2479 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2480
2481 =head2 $c->setup_actions($component)
2482
2483 Sets up actions for a component.
2484
2485 =cut
2486
2487 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2488
2489 =head2 $c->setup_components
2490
2491 This method is called internally to set up the application's components.
2492
2493 It finds modules by calling the L<locate_components> method, expands them to
2494 package names with the L<expand_component_module> method, and then installs
2495 each component into the application.
2496
2497 The C<setup_components> config option is passed to both of the above methods.
2498
2499 Installation of each component is performed by the L<setup_component> method,
2500 below.
2501
2502 =cut
2503
2504 sub setup_components {
2505     my $class = shift;
2506
2507     my $config  = $class->config->{ setup_components };
2508
2509     my @comps = $class->locate_components($config);
2510     my %comps = map { $_ => 1 } @comps;
2511
2512     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2513     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2514         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2515     ) if $deprecatedcatalyst_component_names;
2516
2517     for my $component ( @comps ) {
2518
2519         # We pass ignore_loaded here so that overlay files for (e.g.)
2520         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2521         # we know M::P::O found a file on disk so this is safe
2522
2523         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2524     }
2525
2526     for my $component (@comps) {
2527         my $instance = $class->components->{ $component } = $class->setup_component($component);
2528         my @expanded_components = $instance->can('expand_modules')
2529             ? $instance->expand_modules( $component, $config )
2530             : $class->expand_component_module( $component, $config );
2531         for my $component (@expanded_components) {
2532             next if $comps{$component};
2533             $class->components->{ $component } = $class->setup_component($component);
2534         }
2535     }
2536 }
2537
2538 =head2 $c->locate_components( $setup_component_config )
2539
2540 This method is meant to provide a list of component modules that should be
2541 setup for the application.  By default, it will use L<Module::Pluggable>.
2542
2543 Specify a C<setup_components> config option to pass additional options directly
2544 to L<Module::Pluggable>. To add additional search paths, specify a key named
2545 C<search_extra> as an array reference. Items in the array beginning with C<::>
2546 will have the application class name prepended to them.
2547
2548 =cut
2549
2550 sub locate_components {
2551     my $class  = shift;
2552     my $config = shift;
2553
2554     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2555     my $extra   = delete $config->{ search_extra } || [];
2556
2557     push @paths, @$extra;
2558
2559     my $locator = Module::Pluggable::Object->new(
2560         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2561         %$config
2562     );
2563
2564     # XXX think about ditching this sort entirely
2565     my @comps = sort { length $a <=> length $b } $locator->plugins;
2566
2567     return @comps;
2568 }
2569
2570 =head2 $c->expand_component_module( $component, $setup_component_config )
2571
2572 Components found by C<locate_components> will be passed to this method, which
2573 is expected to return a list of component (package) names to be set up.
2574
2575 =cut
2576
2577 sub expand_component_module {
2578     my ($class, $module) = @_;
2579     return Devel::InnerPackage::list_packages( $module );
2580 }
2581
2582 =head2 $c->setup_component
2583
2584 =cut
2585
2586 sub setup_component {
2587     my( $class, $component ) = @_;
2588
2589     unless ( $component->can( 'COMPONENT' ) ) {
2590         return $component;
2591     }
2592
2593     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2594     my $config = $class->config->{ $suffix } || {};
2595     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2596     # methods also pass it. local to avoid pointlessly shitting in config
2597     # for the debug screen, as $component is already the key name.
2598     local $config->{catalyst_component_name} = $component;
2599
2600     my $instance = eval { $component->COMPONENT( $class, $config ); };
2601
2602     if ( my $error = $@ ) {
2603         chomp $error;
2604         Catalyst::Exception->throw(
2605             message => qq/Couldn't instantiate component "$component", "$error"/
2606         );
2607     }
2608
2609     unless (blessed $instance) {
2610         my $metaclass = Moose::Util::find_meta($component);
2611         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2612         my $component_method_from = $method_meta->associated_metaclass->name;
2613         my $value = defined($instance) ? $instance : 'undef';
2614         Catalyst::Exception->throw(
2615             message =>
2616             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2617         );
2618     }
2619     return $instance;
2620 }
2621
2622 =head2 $c->setup_dispatcher
2623
2624 Sets up dispatcher.
2625
2626 =cut
2627
2628 sub setup_dispatcher {
2629     my ( $class, $dispatcher ) = @_;
2630
2631     if ($dispatcher) {
2632         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2633     }
2634
2635     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2636         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2637     }
2638
2639     unless ($dispatcher) {
2640         $dispatcher = $class->dispatcher_class;
2641     }
2642
2643     Class::MOP::load_class($dispatcher);
2644
2645     # dispatcher instance
2646     $class->dispatcher( $dispatcher->new );
2647 }
2648
2649 =head2 $c->setup_engine
2650
2651 Sets up engine.
2652
2653 =cut
2654
2655 sub engine_class {
2656     my ($class, $requested_engine) = @_;
2657
2658     if (!$class->engine_loader || $requested_engine) {
2659         $class->engine_loader(
2660             Catalyst::EngineLoader->new({
2661                 application_name => $class,
2662                 (defined $requested_engine
2663                      ? (catalyst_engine_class => $requested_engine) : ()),
2664             }),
2665         );
2666     }
2667
2668     $class->engine_loader->catalyst_engine_class;
2669 }
2670
2671 sub setup_engine {
2672     my ($class, $requested_engine) = @_;
2673
2674     my $engine = do {
2675         my $loader = $class->engine_loader;
2676
2677         if (!$loader || $requested_engine) {
2678             $loader = Catalyst::EngineLoader->new({
2679                 application_name => $class,
2680                 (defined $requested_engine
2681                      ? (requested_engine => $requested_engine) : ()),
2682             }),
2683
2684             $class->engine_loader($loader);
2685         }
2686
2687         $loader->catalyst_engine_class;
2688     };
2689
2690     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2691     return if $class->loading_psgi_file;
2692
2693     Class::MOP::load_class($engine);
2694
2695     if ($ENV{MOD_PERL}) {
2696         my $apache = $class->engine_loader->auto;
2697
2698         my $meta = find_meta($class);
2699         my $was_immutable = $meta->is_immutable;
2700         my %immutable_options = $meta->immutable_options;
2701         $meta->make_mutable if $was_immutable;
2702
2703         $meta->add_method(handler => sub {
2704             my $r = shift;
2705             my $psgi_app = $class->_finalized_psgi_app;
2706             $apache->call_app($r, $psgi_app);
2707         });
2708
2709         $meta->make_immutable(%immutable_options) if $was_immutable;
2710     }
2711
2712     $class->engine( $engine->new );
2713
2714     return;
2715 }
2716
2717 sub _finalized_psgi_app {
2718     my ($app) = @_;
2719
2720     unless ($app->_psgi_app) {
2721         my $psgi_app = $app->_setup_psgi_app;
2722         $app->_psgi_app($psgi_app);
2723     }
2724
2725     return $app->_psgi_app;
2726 }
2727
2728 sub _setup_psgi_app {
2729     my ($app) = @_;
2730
2731     for my $home (Path::Class::Dir->new($app->config->{home})) {
2732         my $psgi_file = $home->file(
2733             Catalyst::Utils::appprefix($app) . '.psgi',
2734         );
2735
2736         next unless -e $psgi_file;
2737
2738         # If $psgi_file calls ->setup_engine, it's doing so to load
2739         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2740         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2741         # anyway. So set a flag (ick) that tells setup_engine not to populate
2742         # $c->engine or do any other things we might regret.
2743
2744         $app->loading_psgi_file(1);
2745         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2746         $app->loading_psgi_file(0);
2747
2748         return $psgi_app
2749             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2750
2751         warn <<"EOW";
2752 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2753
2754 Its content has been ignored. Please consult the Catalyst::Upgrading
2755 documentation on how to upgrade from Catalyst::Engine::PSGI.
2756 EOW
2757     }
2758
2759     return $app->apply_default_middlewares($app->psgi_app);
2760 }
2761
2762 =head2 $c->apply_default_middlewares
2763
2764 Adds the following L<Plack> middlewares to your application, since they are
2765 useful and commonly needed:
2766
2767 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2768 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2769 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2770 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2771 applied since this middleware is smart enough to conditionally apply itself).
2772
2773 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2774 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2775 $ENV{SCRIPT_NAME}
2776
2777 =cut
2778
2779
2780 sub apply_default_middlewares {
2781     my ($app, $psgi_app) = @_;
2782
2783     $psgi_app = Plack::Middleware::Conditional->wrap(
2784         $psgi_app,
2785         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2786         condition => sub {
2787             my ($env) = @_;
2788             return if $app->config->{ignore_frontend_proxy};
2789             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2790                 || $app->config->{using_frontend_proxy};
2791         },
2792     );
2793
2794     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2795     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2796     $psgi_app = Plack::Middleware::Conditional->wrap(
2797         $psgi_app,
2798         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2799         condition => sub {
2800             my ($env) = @_;
2801             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2802             return unless $1 < 4.23;
2803             1;
2804         },
2805     );
2806
2807     # we're applying this unconditionally as the middleware itself already makes
2808     # sure it doesn't fuck things up if it's not running under one of the right
2809     # IIS versions
2810     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2811
2812     # And another IIS issue, this time with IIS7.
2813     $psgi_app = Plack::Middleware::Conditional->wrap(
2814         $psgi_app,
2815         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2816         condition => sub {
2817             my ($env) = @_;
2818             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2819         },
2820     );
2821
2822     return $psgi_app;
2823 }
2824
2825 =head2 $c->psgi_app
2826
2827 Returns a PSGI application code reference for the catalyst application
2828 C<$c>. This is the bare application without any middlewares
2829 applied. C<${myapp}.psgi> is not taken into account.
2830
2831 This is what you want to be using to retrieve the PSGI application code
2832 reference of your Catalyst application for use in F<.psgi> files.
2833
2834 =cut
2835
2836 sub psgi_app {
2837     my ($app) = @_;
2838     return $app->engine->build_psgi_app($app);
2839 }
2840
2841 =head2 $c->setup_home
2842
2843 Sets up the home directory.
2844
2845 =cut
2846
2847 sub setup_home {
2848     my ( $class, $home ) = @_;
2849
2850     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2851         $home = $env;
2852     }
2853
2854     $home ||= Catalyst::Utils::home($class);
2855
2856     if ($home) {
2857         #I remember recently being scolded for assigning config values like this
2858         $class->config->{home} ||= $home;
2859         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2860     }
2861 }
2862
2863 =head2 $c->setup_log
2864
2865 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2866 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2867 log to.
2868
2869 This method also installs a C<debug> method that returns a true value into the
2870 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2871 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2872
2873 Note that if the log has already been setup, by either a previous call to
2874 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2875 that this method won't actually set up the log object.
2876
2877 =cut
2878
2879 sub setup_log {
2880     my ( $class, $levels ) = @_;
2881
2882     $levels ||= '';
2883     $levels =~ s/^\s+//;
2884     $levels =~ s/\s+$//;
2885     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2886
2887     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2888     if ( defined $env_debug ) {
2889         $levels{debug} = 1 if $env_debug; # Ugly!
2890         delete($levels{debug}) unless $env_debug;
2891     }
2892
2893     unless ( $class->log ) {
2894         $class->log( Catalyst::Log->new(keys %levels) );
2895     }
2896
2897     if ( $levels{debug} ) {
2898         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2899         $class->log->debug('Debug messages enabled');
2900     }
2901 }
2902
2903 =head2 $c->setup_plugins
2904
2905 Sets up plugins.
2906
2907 =cut
2908
2909 =head2 $c->setup_stats
2910
2911 Sets up timing statistics class.
2912
2913 =cut
2914
2915 sub setup_stats {
2916     my ( $class, $stats ) = @_;
2917
2918     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2919
2920     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2921     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2922         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2923         $class->log->debug('Statistics enabled');
2924     }
2925 }
2926
2927
2928 =head2 $c->registered_plugins
2929
2930 Returns a sorted list of the plugins which have either been stated in the
2931 import list.
2932
2933 If passed a given plugin name, it will report a boolean value indicating
2934 whether or not that plugin is loaded.  A fully qualified name is required if
2935 the plugin name does not begin with C<Catalyst::Plugin::>.
2936
2937  if ($c->registered_plugins('Some::Plugin')) {
2938      ...
2939  }
2940
2941 =cut
2942
2943 {
2944
2945     sub registered_plugins {
2946         my $proto = shift;
2947         return sort keys %{ $proto->_plugins } unless @_;
2948         my $plugin = shift;
2949         return 1 if exists $proto->_plugins->{$plugin};
2950         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2951     }
2952
2953     sub _register_plugin {
2954         my ( $proto, $plugin, $instant ) = @_;
2955         my $class = ref $proto || $proto;
2956
2957         Class::MOP::load_class( $plugin );
2958         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2959             if $plugin->isa( 'Catalyst::Component' );
2960         my $plugin_meta = Moose::Meta::Class->create($plugin);
2961         if (!$plugin_meta->has_method('new')
2962             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
2963             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
2964         }
2965         if (!$instant && !$proto->_plugins->{$plugin}) {
2966             my $meta = Class::MOP::get_metaclass_by_name($class);
2967             $meta->superclasses($plugin, $meta->superclasses);
2968         }
2969         $proto->_plugins->{$plugin} = 1;
2970         return $class;
2971     }
2972
2973     sub setup_plugins {
2974         my ( $class, $plugins ) = @_;
2975
2976         $class->_plugins( {} ) unless $class->_plugins;
2977         $plugins = Data::OptList::mkopt($plugins || []);
2978
2979         my @plugins = map {
2980             [ Catalyst::Utils::resolve_namespace(
2981                   $class . '::Plugin',
2982                   'Catalyst::Plugin', $_->[0]
2983               ),
2984               $_->[1],
2985             ]
2986          } @{ $plugins };
2987
2988         for my $plugin ( reverse @plugins ) {
2989             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2990             my $meta = find_meta($plugin->[0]);
2991             next if $meta && $meta->isa('Moose::Meta::Role');
2992
2993             $class->_register_plugin($plugin->[0]);
2994         }
2995
2996         my @roles =
2997             map  { $_->[0]->name, $_->[1] }
2998             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2999             map  { [find_meta($_->[0]), $_->[1]] }
3000             @plugins;
3001
3002         Moose::Util::apply_all_roles(
3003             $class => @roles
3004         ) if @roles;
3005     }
3006 }
3007
3008 =head2 $c->stack
3009
3010 Returns an arrayref of the internal execution stack (actions that are
3011 currently executing).
3012
3013 =head2 $c->stats
3014
3015 Returns the current timing statistics object. By default Catalyst uses
3016 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3017 L<< stats_class|/"$c->stats_class" >>.
3018
3019 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3020 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3021 profile explicitly, although MyApp.pm still won't profile nor output anything
3022 by itself.
3023
3024 =head2 $c->stats_class
3025
3026 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3027
3028 =head2 $c->use_stats
3029
3030 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3031
3032 Note that this is a static method, not an accessor and should be overridden
3033 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3034
3035 =cut
3036
3037 sub use_stats { 0 }
3038
3039
3040 =head2 $c->write( $data )
3041
3042 Writes $data to the output stream. When using this method directly, you
3043 will need to manually set the C<Content-Length> header to the length of
3044 your output data, if known.
3045
3046 =cut
3047
3048 sub write {
3049     my $c = shift;
3050
3051     # Finalize headers if someone manually writes output (for compat)
3052     $c->finalize_headers;
3053
3054     return $c->response->write( @_ );
3055 }
3056
3057 =head2 version
3058
3059 Returns the Catalyst version number. Mostly useful for "powered by"
3060 messages in template systems.
3061
3062 =cut
3063
3064 sub version { return $Catalyst::VERSION }
3065
3066 =head1 CONFIGURATION
3067
3068 There are a number of 'base' config variables which can be set:
3069
3070 =over
3071
3072 =item *
3073
3074 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3075
3076 =item *
3077
3078 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3079
3080 =item *
3081
3082 C<disable_component_resolution_regex_fallback> - Turns
3083 off the deprecated component resolution functionality so
3084 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3085 are called then regex search will not be attempted on string values and
3086 instead C<undef> will be returned.
3087
3088 =item *
3089
3090 C<home> - The application home directory. In an uninstalled application,
3091 this is the top level application directory. In an installed application,
3092 this will be the directory containing C<< MyApp.pm >>.
3093
3094 =item *
3095
3096 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3097
3098 =item *
3099
3100 C<name> - The name of the application in debug messages and the debug and
3101 welcome screens
3102
3103 =item *
3104
3105 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3106 until it is accessed. This allows you to (for example) check authentication (and reject
3107 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3108
3109 =item *
3110
3111 C<root> - The root directory for templates. Usually this is just a
3112 subdirectory of the home directory, but you can set it to change the
3113 templates to a different directory.
3114
3115 =item *
3116
3117 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3118 namespaces from which components will be loaded (and constructed and stored in
3119 C<< $c->components >>).
3120
3121 =item *
3122
3123 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3124 to be shown in hit debug tables in the test server.
3125
3126 =item *
3127
3128 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3129 variable should be used for determining the request path.
3130
3131 Most web server environments pass the requested path to the application using environment variables,
3132 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3133 exposed as C<< $c->request->base >>) and the request path below that base.
3134
3135 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3136 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3137
3138 =over
3139
3140 =item use_request_uri_for_path => 0
3141
3142 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3143 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3144 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3145 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3146
3147 However this method has the major disadvantage that it is impossible to correctly decode some elements
3148 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3149 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3150 can't distinguish / vs %2F in paths (in addition to other encoded values).
3151
3152 =item use_request_uri_for_path => 1
3153
3154 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3155 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3156 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3157
3158 Given that this method of path resolution is provably more correct, it is recommended that you use
3159 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3160 aware of the implications of not being able to handle encoded URI paths correctly.
3161
3162 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3163 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3164 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3165 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3166 C<< $c->request->base >> will be incorrect.
3167
3168 =back
3169
3170 =item *
3171
3172 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3173
3174 =back
3175
3176 =head1 INTERNAL ACTIONS
3177
3178 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3179 C<_ACTION>, and C<_END>. These are by default not shown in the private
3180 action table, but you can make them visible with a config parameter.
3181
3182     MyApp->config(show_internal_actions => 1);
3183
3184 =head1 ON-DEMAND PARSER
3185
3186 The request body is usually parsed at the beginning of a request,
3187 but if you want to handle input yourself, you can enable on-demand
3188 parsing with a config parameter.
3189
3190     MyApp->config(parse_on_demand => 1);
3191
3192 =head1 PROXY SUPPORT
3193
3194 Many production servers operate using the common double-server approach,
3195 with a lightweight frontend web server passing requests to a larger
3196 backend server. An application running on the backend server must deal
3197 with two problems: the remote user always appears to be C<127.0.0.1> and
3198 the server's hostname will appear to be C<localhost> regardless of the
3199 virtual host that the user connected through.
3200
3201 Catalyst will automatically detect this situation when you are running
3202 the frontend and backend servers on the same machine. The following
3203 changes are made to the request.
3204
3205     $c->req->address is set to the user's real IP address, as read from
3206     the HTTP X-Forwarded-For header.
3207
3208     The host value for $c->req->base and $c->req->uri is set to the real
3209     host, as read from the HTTP X-Forwarded-Host header.
3210
3211 Additionally, you may be running your backend application on an insecure
3212 connection (port 80) while your frontend proxy is running under SSL.  If there
3213 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3214 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3215 be created properly.
3216
3217 In the case of passing in:
3218
3219     X-Forwarded-Port: 443
3220
3221 All calls to C<uri_for> will result in an https link, as is expected.
3222
3223 Obviously, your web server must support these headers for this to work.
3224
3225 In a more complex server farm environment where you may have your
3226 frontend proxy server(s) on different machines, you will need to set a
3227 configuration option to tell Catalyst to read the proxied data from the
3228 headers.
3229
3230     MyApp->config(using_frontend_proxy => 1);
3231
3232 If you do not wish to use the proxy support at all, you may set:
3233
3234     MyApp->config(ignore_frontend_proxy => 0);
3235
3236 =head2 Note about psgi files
3237
3238 Note that if you supply your own .psgi file, calling
3239 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3240
3241 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3242 in your psgi, for example:
3243
3244     builder {
3245         enable "Plack::Middleware::ReverseProxy";
3246         MyApp->psgi_app
3247     };
3248
3249 This will unconditionally add the ReverseProxy support, or you need to call
3250 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3251 apply the support depending upon your config).
3252
3253 See L<Catalyst::PSGI> for more information.
3254
3255 =head1 THREAD SAFETY
3256
3257 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3258 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3259 believe the Catalyst core to be thread-safe.
3260
3261 If you plan to operate in a threaded environment, remember that all other
3262 modules you are using must also be thread-safe. Some modules, most notably
3263 L<DBD::SQLite>, are not thread-safe.
3264
3265 =head1 SUPPORT
3266
3267 IRC:
3268
3269     Join #catalyst on irc.perl.org.
3270
3271 Mailing Lists:
3272
3273     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3274     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3275
3276 Web:
3277
3278     http://catalyst.perl.org
3279
3280 Wiki:
3281
3282     http://dev.catalyst.perl.org
3283
3284 =head1 SEE ALSO
3285
3286 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3287
3288 =head2 L<Catalyst::Manual> - The Catalyst Manual
3289
3290 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3291
3292 =head2 L<Catalyst::Engine> - Core engine
3293
3294 =head2 L<Catalyst::Log> - Log class.
3295
3296 =head2 L<Catalyst::Request> - Request object
3297
3298 =head2 L<Catalyst::Response> - Response object
3299
3300 =head2 L<Catalyst::Test> - The test suite.
3301
3302 =head1 PROJECT FOUNDER
3303
3304 sri: Sebastian Riedel <sri@cpan.org>
3305
3306 =head1 CONTRIBUTORS
3307
3308 abw: Andy Wardley
3309
3310 acme: Leon Brocard <leon@astray.com>
3311
3312 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3313
3314 Andrew Bramble
3315
3316 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3317
3318 Andrew Ruthven
3319
3320 andyg: Andy Grundman <andy@hybridized.org>
3321
3322 audreyt: Audrey Tang
3323
3324 bricas: Brian Cassidy <bricas@cpan.org>
3325
3326 Caelum: Rafael Kitover <rkitover@io.com>
3327
3328 chansen: Christian Hansen
3329
3330 chicks: Christopher Hicks
3331
3332 Chisel Wright C<pause@herlpacker.co.uk>
3333
3334 Danijel Milicevic C<me@danijel.de>
3335
3336 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3337
3338 David Naughton, C<naughton@umn.edu>
3339
3340 David E. Wheeler
3341
3342 dhoss: Devin Austin <dhoss@cpan.org>
3343
3344 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3345
3346 Drew Taylor
3347
3348 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3349
3350 esskar: Sascha Kiefer
3351
3352 fireartist: Carl Franks <cfranks@cpan.org>
3353
3354 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3355
3356 gabb: Danijel Milicevic
3357
3358 Gary Ashton Jones
3359
3360 Gavin Henry C<ghenry@perl.me.uk>
3361
3362 Geoff Richards
3363
3364 groditi: Guillermo Roditi <groditi@gmail.com>
3365
3366 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3367
3368 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3369
3370 jcamacho: Juan Camacho
3371
3372 jester: Jesse Sheidlower C<jester@panix.com>
3373
3374 jhannah: Jay Hannah <jay@jays.net>
3375
3376 Jody Belka
3377
3378 Johan Lindstrom
3379
3380 jon: Jon Schutz <jjschutz@cpan.org>
3381
3382 Jonathan Rockway C<< <jrockway@cpan.org> >>
3383
3384 Kieren Diment C<kd@totaldatasolution.com>
3385
3386 konobi: Scott McWhirter <konobi@cpan.org>
3387
3388 marcus: Marcus Ramberg <mramberg@cpan.org>
3389
3390 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3391
3392 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3393
3394 mugwump: Sam Vilain
3395
3396 naughton: David Naughton
3397
3398 ningu: David Kamholz <dkamholz@cpan.org>
3399
3400 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3401
3402 numa: Dan Sully <daniel@cpan.org>
3403
3404 obra: Jesse Vincent
3405
3406 Octavian Rasnita
3407
3408 omega: Andreas Marienborg
3409
3410 Oleg Kostyuk <cub.uanic@gmail.com>
3411
3412 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3413
3414 rafl: Florian Ragwitz <rafl@debian.org>
3415
3416 random: Roland Lammel <lammel@cpan.org>
3417
3418 Robert Sedlacek C<< <rs@474.at> >>
3419
3420 SpiceMan: Marcel Montes
3421
3422 sky: Arthur Bergman
3423
3424 szbalint: Balint Szilakszi <szbalint@cpan.org>
3425
3426 t0m: Tomas Doran <bobtfish@bobtfish.net>
3427
3428 Ulf Edvinsson
3429
3430 Viljo Marrandi C<vilts@yahoo.com>
3431
3432 Will Hawes C<info@whawes.co.uk>
3433
3434 willert: Sebastian Willert <willert@cpan.org>
3435
3436 wreis: Wallace Reis <wallace@reis.org.br>
3437
3438 Yuval Kogman, C<nothingmuch@woobling.org>
3439
3440 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3441
3442 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3443
3444 =head1 COPYRIGHT
3445
3446 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3447
3448 =head1 LICENSE
3449
3450 This library is free software. You can redistribute it and/or modify it under
3451 the same terms as Perl itself.
3452
3453 =cut
3454
3455 no Moose;
3456
3457 __PACKAGE__->meta->make_immutable;
3458
3459 1;