lib/Catalyst.pm

   1 package Catalyst;
   2
   3 # we don't need really need this, but if we load it before MRO::Compat gets
   4 # loaded (via Moose and Class::MOP), we can avoid some nasty warnings
   5 use Class::C3;
   6
   7 use Moose;
   8 extends 'Catalyst::Component';
   9 use bytes;
  10 use Catalyst::Exception;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Devel::InnerPackage ();
  18 use File::stat;
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use Time::HiRes qw/gettimeofday tv_interval/;
  24 use URI ();
  25 use URI::http;
  26 use URI::https;
  27 use Scalar::Util qw/weaken blessed/;
  28 use Tree::Simple qw/use_weak_refs/;
  29 use Tree::Simple::Visitor::FindByUID;
  30 use attributes;
  31 use utf8;
  32 use Carp qw/croak carp/;
  33
  34 BEGIN { require 5.008001; }
  35
  36 has stack => (is => 'rw', default => sub { [] });
  37 has stash => (is => 'rw', default => sub { {} });
  38 has state => (is => 'rw', default => 0);
  39 has stats => (is => 'rw');
  40 has action => (is => 'rw');
  41 has counter => (is => 'rw', default => sub { {} });
  42 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  43 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  44 has namespace => (is => 'rw');
  45
  46 sub depth { scalar @{ shift->stack || [] }; }
  47 sub comp { shift->component(@_) }
  48
  49 sub req {
  50     # carp "the use of req() is deprecated in favour of request()";
  51     my $self = shift; return $self->request(@_);
  52 }
  53 sub res {
  54     # carp "the use of res() is deprecated in favour of response()";
  55     my $self = shift; return $self->response(@_);
  56 }
  57
  58 # For backwards compatibility
  59 sub finalize_output { shift->finalize_body(@_) };
  60
  61 # For statistics
  62 our $COUNT     = 1;
  63 our $START     = time;
  64 our $RECURSION = 1000;
  65 our $DETACH    = "catalyst_detach\n";
  66 our $GO        = "catalyst_go\n";
  67
  68 #I imagine that very few of these really need to be class variables. if any.
  69 #maybe we should just make them attributes with a default?
  70 __PACKAGE__->mk_classdata($_)
  71   for qw/components arguments dispatcher engine log dispatcher_class
  72   engine_class context_class request_class response_class stats_class
  73   setup_finished/;
  74
  75 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  76 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  77 __PACKAGE__->request_class('Catalyst::Request');
  78 __PACKAGE__->response_class('Catalyst::Response');
  79 __PACKAGE__->stats_class('Catalyst::Stats');
  80
  81 # Remember to update this in Catalyst::Runtime as well!
  82
  83 our $VERSION = '5.8000_04';
  84
  85 sub import {
  86     my ( $class, @arguments ) = @_;
  87
  88     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  89     # callers @ISA.
  90     return unless $class eq 'Catalyst';
  91
  92     my $caller = caller();
  93     return if $caller eq 'main';
  94     my $meta = Moose::Meta::Class->initialize($caller);
  95     #Moose->import({ into => $caller }); #do we want to do this?
  96
  97     unless ( $caller->isa('Catalyst') ) {
  98         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  99         $meta->superclasses(@superclasses);
 100     }
 101     unless( $meta->has_method('meta') ){
 102         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 103     }
 104
 105     $caller->arguments( [@arguments] );
 106     $caller->setup_home;
 107 }
 108
 109 =head1 NAME
 110
 111 Catalyst - The Elegant MVC Web Application Framework
 112
 113 =head1 SYNOPSIS
 114
 115 See the L<Catalyst::Manual> distribution for comprehensive
 116 documentation and tutorials.
 117
 118     # Install Catalyst::Devel for helpers and other development tools
 119     # use the helper to create a new application
 120     catalyst.pl MyApp
 121
 122     # add models, views, controllers
 123     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 124     script/myapp_create.pl view MyTemplate TT
 125     script/myapp_create.pl controller Search
 126
 127     # built in testserver -- use -r to restart automatically on changes
 128     # --help to see all available options
 129     script/myapp_server.pl
 130
 131     # command line testing interface
 132     script/myapp_test.pl /yada
 133
 134     ### in lib/MyApp.pm
 135     use Catalyst qw/-Debug/; # include plugins here as well
 136
 137     ### In lib/MyApp/Controller/Root.pm (autocreated)
 138     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 139         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 140         $c->stash->{template} = 'foo.tt'; # set the template
 141         # lookup something from db -- stash vars are passed to TT
 142         $c->stash->{data} =
 143           $c->model('Database::Foo')->search( { country => $args[0] } );
 144         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 145             $c->forward( 'bar' ); # process another action
 146             # do something else after forward returns
 147         }
 148     }
 149
 150     # The foo.tt TT template can use the stash data from the database
 151     [% WHILE (item = data.next) %]
 152         [% item.foo %]
 153     [% END %]
 154
 155     # called for /bar/of/soap, /bar/of/soap/10, etc.
 156     sub bar : Path('/bar/of/soap') { ... }
 157
 158     # called for all actions, from the top-most controller downwards
 159     sub auto : Private {
 160         my ( $self, $c ) = @_;
 161         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 162             $c->res->redirect( '/login' ); # require login
 163             return 0; # abort request and go immediately to end()
 164         }
 165         return 1; # success; carry on to next action
 166     }
 167
 168     # called after all actions are finished
 169     sub end : Private {
 170         my ( $self, $c ) = @_;
 171         if ( scalar @{ $c->error } ) { ... } # handle errors
 172         return if $c->res->body; # already have a response
 173         $c->forward( 'MyApp::View::TT' ); # render template
 174     }
 175
 176     ### in MyApp/Controller/Foo.pm
 177     # called for /foo/bar
 178     sub bar : Local { ... }
 179
 180     # called for /blargle
 181     sub blargle : Global { ... }
 182
 183     # an index action matches /foo, but not /foo/1, etc.
 184     sub index : Private { ... }
 185
 186     ### in MyApp/Controller/Foo/Bar.pm
 187     # called for /foo/bar/baz
 188     sub baz : Local { ... }
 189
 190     # first Root auto is called, then Foo auto, then this
 191     sub auto : Private { ... }
 192
 193     # powerful regular expression paths are also possible
 194     sub details : Regex('^product/(\w+)/details$') {
 195         my ( $self, $c ) = @_;
 196         # extract the (\w+) from the URI
 197         my $product = $c->req->captures->[0];
 198     }
 199
 200 See L<Catalyst::Manual::Intro> for additional information.
 201
 202 =head1 DESCRIPTION
 203
 204 Catalyst is a modern framework for making web applications without the
 205 pain usually associated with this process. This document is a reference
 206 to the main Catalyst application. If you are a new user, we suggest you
 207 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 208
 209 See L<Catalyst::Manual> for more documentation.
 210
 211 Catalyst plugins can be loaded by naming them as arguments to the "use
 212 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 213 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 214 C<My::Module>.
 215
 216     use Catalyst qw/My::Module/;
 217
 218 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 219 fully qualify the name by using a unary plus:
 220
 221     use Catalyst qw/
 222         My::Module
 223         +Fully::Qualified::Plugin::Name
 224     /;
 225
 226 Special flags like C<-Debug> and C<-Engine> can also be specified as
 227 arguments when Catalyst is loaded:
 228
 229     use Catalyst qw/-Debug My::Module/;
 230
 231 The position of plugins and flags in the chain is important, because
 232 they are loaded in the order in which they appear.
 233
 234 The following flags are supported:
 235
 236 =head2 -Debug
 237
 238 Enables debug output. You can also force this setting from the system
 239 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 240 settings override the application, with <MYAPP>_DEBUG having the highest
 241 priority.
 242
 243 =head2 -Engine
 244
 245 Forces Catalyst to use a specific engine. Omit the
 246 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 247
 248     use Catalyst qw/-Engine=CGI/;
 249
 250 =head2 -Home
 251
 252 Forces Catalyst to use a specific home directory, e.g.:
 253
 254     use Catalyst qw[-Home=/usr/mst];
 255
 256 This can also be done in the shell environment by setting either the
 257 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 258 is replaced with the uppercased name of your application, any "::" in
 259 the name will be replaced with underscores, e.g. MyApp::Web should use
 260 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 261
 262 =head2 -Log
 263
 264 Specifies log level.
 265
 266 =head2 -Stats
 267
 268 Enables statistics collection and reporting. You can also force this setting
 269 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 270 environment settings override the application, with <MYAPP>_STATS having the
 271 highest priority.
 272
 273 e.g.
 274
 275    use Catalyst qw/-Stats=1/
 276
 277 =head1 METHODS
 278
 279 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 280
 281 =head2 $c->action
 282
 283 Returns a L<Catalyst::Action> object for the current action, which
 284 stringifies to the action name. See L<Catalyst::Action>.
 285
 286 =head2 $c->namespace
 287
 288 Returns the namespace of the current action, i.e., the URI prefix
 289 corresponding to the controller of the current action. For example:
 290
 291     # in Controller::Foo::Bar
 292     $c->namespace; # returns 'foo/bar';
 293
 294 =head2 $c->request
 295
 296 =head2 $c->req
 297
 298 Returns the current L<Catalyst::Request> object, giving access to
 299 information about the current client request (including parameters,
 300 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 301
 302 =head2 REQUEST FLOW HANDLING
 303
 304 =head2 $c->forward( $action [, \@arguments ] )
 305
 306 =head2 $c->forward( $class, $method, [, \@arguments ] )
 307
 308 Forwards processing to another action, by its private name. If you give a
 309 class name but no method, C<process()> is called. You may also optionally
 310 pass arguments in an arrayref. The action will receive the arguments in
 311 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 312 C<< $c->req->args >> will be restored to the previous values.
 313
 314 Any data C<return>ed from the action forwarded to, will be returned by the
 315 call to forward.
 316
 317     my $foodata = $c->forward('/foo');
 318     $c->forward('index');
 319     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 320     $c->forward('MyApp::View::TT');
 321
 322 Note that forward implies an C<<eval { }>> around the call (actually
 323 C<execute> does), thus de-fatalizing all 'dies' within the called
 324 action. If you want C<die> to propagate you need to do something like:
 325
 326     $c->forward('foo');
 327     die $c->error if $c->error;
 328
 329 Or make sure to always return true values from your actions and write
 330 your code like this:
 331
 332     $c->forward('foo') || return;
 333
 334 =cut
 335
 336 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 337
 338 =head2 $c->detach( $action [, \@arguments ] )
 339
 340 =head2 $c->detach( $class, $method, [, \@arguments ] )
 341
 342 =head2 $c->detach()
 343
 344 The same as C<forward>, but doesn't return to the previous action when
 345 processing is finished.
 346
 347 When called with no arguments it escapes the processing chain entirely.
 348
 349 =cut
 350
 351 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 352
 353 =head2 $c->visit( $action [, \@arguments ] )
 354
 355 =head2 $c->visit( $class, $method, [, \@arguments ] )
 356
 357 Almost the same as C<forward>, but does a full dispatch, instead of just
 358 calling the new C<$action> / C<$class-E<gt>$method>. This means that C<begin>,
 359 C<auto> and the method you go to are called, just like a new request.
 360
 361 C<$c-E<gt>stash> is kept unchanged.
 362
 363 In effect, C<visit> allows you to "wrap" another action, just as it
 364 would have been called by dispatching from a URL, while the analogous
 365 C<go> allows you to transfer control to another action as if it had
 366 been reached directly from a URL.
 367
 368 =cut
 369
 370 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 371
 372 =head2 $c->go( $action [, \@arguments ] )
 373
 374 =head2 $c->go( $class, $method, [, \@arguments ] )
 375
 376 Almost the same as C<detach>, but does a full dispatch like C<visit>,
 377 instead of just calling the new C<$action> /
 378 C<$class-E<gt>$method>. This means that C<begin>, C<auto> and the
 379 method you visit are called, just like a new request.
 380
 381 C<$c-E<gt>stash> is kept unchanged.
 382
 383 =cut
 384
 385 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 386
 387 =head2 $c->response
 388
 389 =head2 $c->res
 390
 391 Returns the current L<Catalyst::Response> object, see there for details.
 392
 393 =head2 $c->stash
 394
 395 Returns a hashref to the stash, which may be used to store data and pass
 396 it between components during a request. You can also set hash keys by
 397 passing arguments. The stash is automatically sent to the view. The
 398 stash is cleared at the end of a request; it cannot be used for
 399 persistent storage (for this you must use a session; see
 400 L<Catalyst::Plugin::Session> for a complete system integrated with
 401 Catalyst).
 402
 403     $c->stash->{foo} = $bar;
 404     $c->stash( { moose => 'majestic', qux => 0 } );
 405     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 406
 407     # stash is automatically passed to the view for use in a template
 408     $c->forward( 'MyApp::View::TT' );
 409
 410 =cut
 411
 412 around stash => sub {
 413     my $orig = shift;
 414     my $c = shift;
 415     my $stash = $orig->($c);
 416     if (@_) {
 417         my $new_stash = @_ > 1 ? {@_} : $_[0];
 418         croak('stash takes a hash or hashref') unless ref $new_stash;
 419         foreach my $key ( keys %$new_stash ) {
 420           $stash->{$key} = $new_stash->{$key};
 421         }
 422     }
 423
 424     return $stash;
 425 };
 426
 427
 428 =head2 $c->error
 429
 430 =head2 $c->error($error, ...)
 431
 432 =head2 $c->error($arrayref)
 433
 434 Returns an arrayref containing error messages.  If Catalyst encounters an
 435 error while processing a request, it stores the error in $c->error.  This
 436 method should only be used to store fatal error messages.
 437
 438     my @error = @{ $c->error };
 439
 440 Add a new error.
 441
 442     $c->error('Something bad happened');
 443
 444 =cut
 445
 446 sub error {
 447     my $c = shift;
 448     if ( $_[0] ) {
 449         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 450         croak @$error unless ref $c;
 451         push @{ $c->{error} }, @$error;
 452     }
 453     elsif ( defined $_[0] ) { $c->{error} = undef }
 454     return $c->{error} || [];
 455 }
 456
 457
 458 =head2 $c->state
 459
 460 Contains the return value of the last executed action.
 461
 462 =head2 $c->clear_errors
 463
 464 Clear errors.  You probably don't want to clear the errors unless you are
 465 implementing a custom error screen.
 466
 467 This is equivalent to running
 468
 469     $c->error(0);
 470
 471 =cut
 472
 473 sub clear_errors {
 474     my $c = shift;
 475     $c->error(0);
 476 }
 477
 478 # search components given a name and some prefixes
 479 sub _comp_search_prefixes {
 480     my ( $c, $name, @prefixes ) = @_;
 481     my $appclass = ref $c || $c;
 482     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 483
 484     # map the original component name to the sub part that we will search against
 485     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 486         grep { /$filter/ } keys %{ $c->components };
 487
 488     # undef for a name will return all
 489     return keys %eligible if !defined $name;
 490
 491     my $query  = ref $name ? $name : qr/^$name$/i;
 492     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 493
 494     return map { $c->components->{ $_ } } @result if @result;
 495
 496     # if we were given a regexp to search against, we're done.
 497     return if ref $name;
 498
 499     # regexp fallback
 500     $query  = qr/$name/i;
 501     @result = map { $c->components->{ $_ } } grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 502
 503     # no results? try against full names
 504     if( !@result ) {
 505         @result = map { $c->components->{ $_ } } grep { m{$query} } keys %eligible;
 506     }
 507
 508     # don't warn if we didn't find any results, it just might not exist
 509     if( @result ) {
 510         $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 511         $c->log->warn( 'Relying on the regexp fallback behavior for component resolution is unreliable and unsafe.' );
 512         $c->log->warn( 'If you really want to search, pass in a regexp as the argument.' );
 513     }
 514
 515     return @result;
 516 }
 517
 518 # Find possible names for a prefix
 519 sub _comp_names {
 520     my ( $c, @prefixes ) = @_;
 521     my $appclass = ref $c || $c;
 522
 523     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 524
 525     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 526     return @names;
 527 }
 528
 529 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 530 sub _filter_component {
 531     my ( $c, $comp, @args ) = @_;
 532
 533     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 534         return $comp->ACCEPT_CONTEXT( $c, @args );
 535     }
 536
 537     return $comp;
 538 }
 539
 540 =head2 COMPONENT ACCESSORS
 541
 542 =head2 $c->controller($name)
 543
 544 Gets a L<Catalyst::Controller> instance by name.
 545
 546     $c->controller('Foo')->do_stuff;
 547
 548 If the name is omitted, will return the controller for the dispatched
 549 action.
 550
 551 If you want to search for controllers, pass in a regexp as the argument.
 552
 553     # find all controllers that start with Foo
 554     my @foo_controllers = $c->controller(qr{^Foo});
 555
 556
 557 =cut
 558
 559 sub controller {
 560     my ( $c, $name, @args ) = @_;
 561
 562     if( $name ) {
 563         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 564         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 565         return $c->_filter_component( $result[ 0 ], @args );
 566     }
 567
 568     return $c->component( $c->action->class );
 569 }
 570
 571 =head2 $c->model($name)
 572
 573 Gets a L<Catalyst::Model> instance by name.
 574
 575     $c->model('Foo')->do_stuff;
 576
 577 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 578
 579 If the name is omitted, it will look for
 580  - a model object in $c->stash->{current_model_instance}, then
 581  - a model name in $c->stash->{current_model}, then
 582  - a config setting 'default_model', or
 583  - check if there is only one model, and return it if that's the case.
 584
 585 If you want to search for models, pass in a regexp as the argument.
 586
 587     # find all models that start with Foo
 588     my @foo_models = $c->model(qr{^Foo});
 589
 590 =cut
 591
 592 sub model {
 593     my ( $c, $name, @args ) = @_;
 594
 595     if( $name ) {
 596         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 597         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 598         return $c->_filter_component( $result[ 0 ], @args );
 599     }
 600
 601     if (ref $c) {
 602         return $c->stash->{current_model_instance}
 603           if $c->stash->{current_model_instance};
 604         return $c->model( $c->stash->{current_model} )
 605           if $c->stash->{current_model};
 606     }
 607     return $c->model( $c->config->{default_model} )
 608       if $c->config->{default_model};
 609
 610     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 611
 612     if( $rest ) {
 613         $c->log->warn( 'Calling $c->model() will return a random model unless you specify one of:' );
 614         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 615         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 616         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 617         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 618     }
 619
 620     return $c->_filter_component( $comp );
 621 }
 622
 623
 624 =head2 $c->view($name)
 625
 626 Gets a L<Catalyst::View> instance by name.
 627
 628     $c->view('Foo')->do_stuff;
 629
 630 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 631
 632 If the name is omitted, it will look for
 633  - a view object in $c->stash->{current_view_instance}, then
 634  - a view name in $c->stash->{current_view}, then
 635  - a config setting 'default_view', or
 636  - check if there is only one view, and return it if that's the case.
 637
 638 If you want to search for views, pass in a regexp as the argument.
 639
 640     # find all views that start with Foo
 641     my @foo_views = $c->view(qr{^Foo});
 642
 643 =cut
 644
 645 sub view {
 646     my ( $c, $name, @args ) = @_;
 647
 648     if( $name ) {
 649         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 650         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 651         return $c->_filter_component( $result[ 0 ], @args );
 652     }
 653
 654     if (ref $c) {
 655         return $c->stash->{current_view_instance}
 656           if $c->stash->{current_view_instance};
 657         return $c->view( $c->stash->{current_view} )
 658           if $c->stash->{current_view};
 659     }
 660     return $c->view( $c->config->{default_view} )
 661       if $c->config->{default_view};
 662
 663     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 664
 665     if( $rest ) {
 666         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 667         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 668         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 669         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 670         $c->log->warn( 'NB: in version 5.80, the "random" behavior will not work at all.' );
 671     }
 672
 673     return $c->_filter_component( $comp );
 674 }
 675
 676 =head2 $c->controllers
 677
 678 Returns the available names which can be passed to $c->controller
 679
 680 =cut
 681
 682 sub controllers {
 683     my ( $c ) = @_;
 684     return $c->_comp_names(qw/Controller C/);
 685 }
 686
 687 =head2 $c->models
 688
 689 Returns the available names which can be passed to $c->model
 690
 691 =cut
 692
 693 sub models {
 694     my ( $c ) = @_;
 695     return $c->_comp_names(qw/Model M/);
 696 }
 697
 698
 699 =head2 $c->views
 700
 701 Returns the available names which can be passed to $c->view
 702
 703 =cut
 704
 705 sub views {
 706     my ( $c ) = @_;
 707     return $c->_comp_names(qw/View V/);
 708 }
 709
 710 =head2 $c->comp($name)
 711
 712 =head2 $c->component($name)
 713
 714 Gets a component object by name. This method is not recommended,
 715 unless you want to get a specific component by full
 716 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 717 should be used instead.
 718
 719 If C<$name> is a regexp, a list of components matched against the full
 720 component name will be returned.
 721
 722 =cut
 723
 724 sub component {
 725     my ( $c, $name, @args ) = @_;
 726
 727     if( $name ) {
 728         my $comps = $c->components;
 729
 730         if( !ref $name ) {
 731             # is it the exact name?
 732             return $c->_filter_component( $comps->{ $name }, @args )
 733                        if exists $comps->{ $name };
 734
 735             # perhaps we just omitted "MyApp"?
 736             my $composed = ( ref $c || $c ) . "::${name}";
 737             return $c->_filter_component( $comps->{ $composed }, @args )
 738                        if exists $comps->{ $composed };
 739
 740             # search all of the models, views and controllers
 741             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 742             return $c->_filter_component( $comp, @args ) if $comp;
 743         }
 744
 745         # This is here so $c->comp( '::M::' ) works
 746         my $query = ref $name ? $name : qr{$name}i;
 747
 748         my @result = grep { m{$query} } keys %{ $c->components };
 749         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 750
 751         if( $result[ 0 ] ) {
 752             $c->log->warn( qq(Found results for "${name}" using regexp fallback.) );
 753             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 754             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 755             return $c->_filter_component( $result[ 0 ], @args );
 756         }
 757
 758         # I would expect to return an empty list here, but that breaks back-compat
 759     }
 760
 761     # fallback
 762     return sort keys %{ $c->components };
 763 }
 764
 765 =head2 CLASS DATA AND HELPER CLASSES
 766
 767 =head2 $c->config
 768
 769 Returns or takes a hashref containing the application's configuration.
 770
 771     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 772
 773 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 774 like myapp.yml in your applications home directory. See
 775 L<Catalyst::Plugin::ConfigLoader>.
 776
 777     ---
 778     db: dsn:SQLite:foo.db
 779
 780
 781 =cut
 782
 783 around config => sub {
 784     my $orig = shift;
 785     my $c = shift;
 786
 787     $c->log->warn("Setting config after setup has been run is not a good idea.")
 788       if ( @_ and $c->setup_finished );
 789
 790     $c->$orig(@_);
 791 };
 792
 793 =head2 $c->log
 794
 795 Returns the logging object instance. Unless it is already set, Catalyst
 796 sets this up with a L<Catalyst::Log> object. To use your own log class,
 797 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 798 C<< __PACKAGE__->setup >>.
 799
 800  __PACKAGE__->log( MyLogger->new );
 801  __PACKAGE__->setup;
 802
 803 And later:
 804
 805     $c->log->info( 'Now logging with my own logger!' );
 806
 807 Your log class should implement the methods described in
 808 L<Catalyst::Log>.
 809
 810
 811 =head2 $c->debug
 812
 813 Overload to enable debug messages (same as -Debug option).
 814
 815 Note that this is a static method, not an accessor and should be overloaded
 816 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 817
 818 =cut
 819
 820 sub debug { 0 }
 821
 822 =head2 $c->dispatcher
 823
 824 Returns the dispatcher instance. Stringifies to class name. See
 825 L<Catalyst::Dispatcher>.
 826
 827 =head2 $c->engine
 828
 829 Returns the engine instance. Stringifies to the class name. See
 830 L<Catalyst::Engine>.
 831
 832
 833 =head2 UTILITY METHODS
 834
 835 =head2 $c->path_to(@path)
 836
 837 Merges C<@path> with C<< $c->config->{home} >> and returns a
 838 L<Path::Class::Dir> object.
 839
 840 For example:
 841
 842     $c->path_to( 'db', 'sqlite.db' );
 843
 844 =cut
 845
 846 sub path_to {
 847     my ( $c, @path ) = @_;
 848     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 849     if ( -d $path ) { return $path }
 850     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 851 }
 852
 853 =head2 $c->plugin( $name, $class, @args )
 854
 855 Helper method for plugins. It creates a classdata accessor/mutator and
 856 loads and instantiates the given class.
 857
 858     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 859
 860     $c->prototype->define_javascript_functions;
 861
 862 =cut
 863
 864 sub plugin {
 865     my ( $class, $name, $plugin, @args ) = @_;
 866     $class->_register_plugin( $plugin, 1 );
 867
 868     eval { $plugin->import };
 869     $class->mk_classdata($name);
 870     my $obj;
 871     eval { $obj = $plugin->new(@args) };
 872
 873     if ($@) {
 874         Catalyst::Exception->throw( message =>
 875               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 876     }
 877
 878     $class->$name($obj);
 879     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 880       if $class->debug;
 881 }
 882
 883 =head2 MyApp->setup
 884
 885 Initializes the dispatcher and engine, loads any plugins, and loads the
 886 model, view, and controller components. You may also specify an array
 887 of plugins to load here, if you choose to not load them in the C<use
 888 Catalyst> line.
 889
 890     MyApp->setup;
 891     MyApp->setup( qw/-Debug/ );
 892
 893 =cut
 894
 895 sub setup {
 896     my ( $class, @arguments ) = @_;
 897     $class->log->warn("Running setup twice is not a good idea.")
 898       if ( $class->setup_finished );
 899
 900     unless ( $class->isa('Catalyst') ) {
 901
 902         Catalyst::Exception->throw(
 903             message => qq/'$class' does not inherit from Catalyst/ );
 904     }
 905
 906     if ( $class->arguments ) {
 907         @arguments = ( @arguments, @{ $class->arguments } );
 908     }
 909
 910     # Process options
 911     my $flags = {};
 912
 913     foreach (@arguments) {
 914
 915         if (/^-Debug$/) {
 916             $flags->{log} =
 917               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 918         }
 919         elsif (/^-(\w+)=?(.*)$/) {
 920             $flags->{ lc $1 } = $2;
 921         }
 922         else {
 923             push @{ $flags->{plugins} }, $_;
 924         }
 925     }
 926
 927     $class->setup_home( delete $flags->{home} );
 928
 929     $class->setup_log( delete $flags->{log} );
 930     $class->setup_plugins( delete $flags->{plugins} );
 931     $class->setup_dispatcher( delete $flags->{dispatcher} );
 932     $class->setup_engine( delete $flags->{engine} );
 933     $class->setup_stats( delete $flags->{stats} );
 934
 935     for my $flag ( sort keys %{$flags} ) {
 936
 937         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 938             &$code( $class, delete $flags->{$flag} );
 939         }
 940         else {
 941             $class->log->warn(qq/Unknown flag "$flag"/);
 942         }
 943     }
 944
 945     eval { require Catalyst::Devel; };
 946     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 947         $class->log->warn(<<"EOF");
 948 You are running an old script!
 949
 950   Please update by running (this will overwrite existing files):
 951     catalyst.pl -force -scripts $class
 952
 953   or (this will not overwrite existing files):
 954     catalyst.pl -scripts $class
 955
 956 EOF
 957     }
 958
 959     if ( $class->debug ) {
 960         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 961
 962         if (@plugins) {
 963             my $t = Text::SimpleTable->new(74);
 964             $t->row($_) for @plugins;
 965             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 966         }
 967
 968         my $dispatcher = $class->dispatcher;
 969         my $engine     = $class->engine;
 970         my $home       = $class->config->{home};
 971
 972         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 973         $class->log->debug(qq/Loaded engine "$engine"/);
 974
 975         $home
 976           ? ( -d $home )
 977           ? $class->log->debug(qq/Found home "$home"/)
 978           : $class->log->debug(qq/Home "$home" doesn't exist/)
 979           : $class->log->debug(q/Couldn't find home/);
 980     }
 981
 982     # Call plugins setup
 983     {
 984         no warnings qw/redefine/;
 985         local *setup = sub { };
 986         $class->setup;
 987     }
 988
 989     # Initialize our data structure
 990     $class->components( {} );
 991
 992     $class->setup_components;
 993
 994     if ( $class->debug ) {
 995         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 996         for my $comp ( sort keys %{ $class->components } ) {
 997             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 998             $t->row( $comp, $type );
 999         }
1000         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1001           if ( keys %{ $class->components } );
1002     }
1003
1004     # Add our self to components, since we are also a component
1005     if( $class->isa('Catalyst::Controller') ){
1006       $class->components->{$class} = $class;
1007     }
1008
1009     $class->setup_actions;
1010
1011     if ( $class->debug ) {
1012         my $name = $class->config->{name} || 'Application';
1013         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1014     }
1015     $class->log->_flush() if $class->log->can('_flush');
1016
1017     $class->setup_finished(1);
1018 }
1019
1020 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1021
1022 =head2 $c->uri_for( $path, @args?, \%query_values? )
1023
1024 =over
1025
1026 =item $action
1027
1028 A Catalyst::Action object representing the Catalyst action you want to
1029 create a URI for. To get one for an action in the current controller,
1030 use C<< $c->action('someactionname') >>. To get one from different
1031 controller, fetch the controller using C<< $c->controller() >>, then
1032 call C<action_for> on it.
1033
1034 You can maintain the arguments captured by an action (e.g.: Regex, Chained)
1035 using C<< $c->req->captures >>.
1036
1037   # For the current action
1038   $c->uri_for($c->action, $c->req->captures);
1039
1040   # For the Foo action in the Bar controller
1041   $c->uri_for($c->controller->('Bar')->action_for('Foo'), $c->req->captures);
1042
1043 =back
1044
1045 =cut
1046
1047 sub uri_for {
1048     my ( $c, $path, @args ) = @_;
1049
1050     if ( Scalar::Util::blessed($path) ) { # action object
1051         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
1052                          ? shift(@args)
1053                          : [] );
1054         $path = $c->dispatcher->uri_for_action($path, $captures);
1055         return undef unless defined($path);
1056         $path = '/' if $path eq '';
1057     }
1058
1059     undef($path) if (defined $path && $path eq '');
1060
1061     my $params =
1062       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1063
1064     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1065     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1066
1067     unshift(@args, $path);
1068
1069     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1070         my $namespace = $c->namespace;
1071         if (defined $path) { # cheesy hack to handle path '../foo'
1072            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1073         }
1074         unshift(@args, $namespace || '');
1075     }
1076
1077     # join args with '/', or a blank string
1078     my $args = join('/', grep { defined($_) } @args);
1079     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1080     $args =~ s!^/+!!;
1081     my $base = $c->req->base;
1082     my $class = ref($base);
1083     $base =~ s{(?<!/)$}{/};
1084
1085     my $query = '';
1086
1087     if (my @keys = keys %$params) {
1088       # somewhat lifted from URI::_query's query_form
1089       $query = '?'.join('&', map {
1090           my $val = $params->{$_};
1091           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1092           s/ /+/g;
1093           my $key = $_;
1094           $val = '' unless defined $val;
1095           (map {
1096               $_ = "$_";
1097               utf8::encode( $_ ) if utf8::is_utf8($_);
1098               # using the URI::Escape pattern here so utf8 chars survive
1099               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1100               s/ /+/g;
1101               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1102       } @keys);
1103     }
1104
1105     my $res = bless(\"${base}${args}${query}", $class);
1106     $res;
1107 }
1108
1109 =head2 $c->welcome_message
1110
1111 Returns the Catalyst welcome HTML page.
1112
1113 =cut
1114
1115 sub welcome_message {
1116     my $c      = shift;
1117     my $name   = $c->config->{name};
1118     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1119     my $prefix = Catalyst::Utils::appprefix( ref $c );
1120     $c->response->content_type('text/html; charset=utf-8');
1121     return <<"EOF";
1122 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1123     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1124 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1125     <head>
1126     <meta http-equiv="Content-Language" content="en" />
1127     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1128         <title>$name on Catalyst $VERSION</title>
1129         <style type="text/css">
1130             body {
1131                 color: #000;
1132                 background-color: #eee;
1133             }
1134             div#content {
1135                 width: 640px;
1136                 margin-left: auto;
1137                 margin-right: auto;
1138                 margin-top: 10px;
1139                 margin-bottom: 10px;
1140                 text-align: left;
1141                 background-color: #ccc;
1142                 border: 1px solid #aaa;
1143             }
1144             p, h1, h2 {
1145                 margin-left: 20px;
1146                 margin-right: 20px;
1147                 font-family: verdana, tahoma, sans-serif;
1148             }
1149             a {
1150                 font-family: verdana, tahoma, sans-serif;
1151             }
1152             :link, :visited {
1153                     text-decoration: none;
1154                     color: #b00;
1155                     border-bottom: 1px dotted #bbb;
1156             }
1157             :link:hover, :visited:hover {
1158                     color: #555;
1159             }
1160             div#topbar {
1161                 margin: 0px;
1162             }
1163             pre {
1164                 margin: 10px;
1165                 padding: 8px;
1166             }
1167             div#answers {
1168                 padding: 8px;
1169                 margin: 10px;
1170                 background-color: #fff;
1171                 border: 1px solid #aaa;
1172             }
1173             h1 {
1174                 font-size: 0.9em;
1175                 font-weight: normal;
1176                 text-align: center;
1177             }
1178             h2 {
1179                 font-size: 1.0em;
1180             }
1181             p {
1182                 font-size: 0.9em;
1183             }
1184             p img {
1185                 float: right;
1186                 margin-left: 10px;
1187             }
1188             span#appname {
1189                 font-weight: bold;
1190                 font-size: 1.6em;
1191             }
1192         </style>
1193     </head>
1194     <body>
1195         <div id="content">
1196             <div id="topbar">
1197                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1198                     $VERSION</h1>
1199              </div>
1200              <div id="answers">
1201                  <p>
1202                  <img src="$logo" alt="Catalyst Logo" />
1203                  </p>
1204                  <p>Welcome to the  world of Catalyst.
1205                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1206                     framework will make web development something you had
1207                     never expected it to be: Fun, rewarding, and quick.</p>
1208                  <h2>What to do now?</h2>
1209                  <p>That really depends  on what <b>you</b> want to do.
1210                     We do, however, provide you with a few starting points.</p>
1211                  <p>If you want to jump right into web development with Catalyst
1212                     you might want to start with a tutorial.</p>
1213 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1214 </pre>
1215 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1216 <pre>
1217 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1218 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1219 </code></pre>
1220                  <h2>What to do next?</h2>
1221                  <p>Next it's time to write an actual application. Use the
1222                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1223                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1224                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1225                     they can save you a lot of work.</p>
1226                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1227                     <p>Also, be sure to check out the vast and growing
1228                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1229                     you are likely to find what you need there.
1230                     </p>
1231
1232                  <h2>Need help?</h2>
1233                  <p>Catalyst has a very active community. Here are the main places to
1234                     get in touch with us.</p>
1235                  <ul>
1236                      <li>
1237                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1238                      </li>
1239                      <li>
1240                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1241                      </li>
1242                      <li>
1243                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1244                      </li>
1245                  </ul>
1246                  <h2>In conclusion</h2>
1247                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1248                     as we enjoyed making it. Please contact us if you have ideas
1249                     for improvement or other feedback.</p>
1250              </div>
1251          </div>
1252     </body>
1253 </html>
1254 EOF
1255 }
1256
1257 =head1 INTERNAL METHODS
1258
1259 These methods are not meant to be used by end users.
1260
1261 =head2 $c->components
1262
1263 Returns a hash of components.
1264
1265 =head2 $c->context_class
1266
1267 Returns or sets the context class.
1268
1269 =head2 $c->counter
1270
1271 Returns a hashref containing coderefs and execution counts (needed for
1272 deep recursion detection).
1273
1274 =head2 $c->depth
1275
1276 Returns the number of actions on the current internal execution stack.
1277
1278 =head2 $c->dispatch
1279
1280 Dispatches a request to actions.
1281
1282 =cut
1283
1284 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1285
1286 =head2 $c->dispatcher_class
1287
1288 Returns or sets the dispatcher class.
1289
1290 =head2 $c->dump_these
1291
1292 Returns a list of 2-element array references (name, structure) pairs
1293 that will be dumped on the error page in debug mode.
1294
1295 =cut
1296
1297 sub dump_these {
1298     my $c = shift;
1299     [ Request => $c->req ],
1300     [ Response => $c->res ],
1301     [ Stash => $c->stash ],
1302     [ Config => $c->config ];
1303 }
1304
1305 =head2 $c->engine_class
1306
1307 Returns or sets the engine class.
1308
1309 =head2 $c->execute( $class, $coderef )
1310
1311 Execute a coderef in given class and catch exceptions. Errors are available
1312 via $c->error.
1313
1314 =cut
1315
1316 sub execute {
1317     my ( $c, $class, $code ) = @_;
1318     $class = $c->component($class) || $class;
1319     $c->state(0);
1320
1321     if ( $c->depth >= $RECURSION ) {
1322         my $action = $code->reverse();
1323         $action = "/$action" unless $action =~ /->/;
1324         my $error = qq/Deep recursion detected calling "${action}"/;
1325         $c->log->error($error);
1326         $c->error($error);
1327         $c->state(0);
1328         return $c->state;
1329     }
1330
1331     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1332
1333     push( @{ $c->stack }, $code );
1334
1335     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1336
1337     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1338
1339     my $last = pop( @{ $c->stack } );
1340
1341     if ( my $error = $@ ) {
1342         if ( !ref($error) and $error eq $DETACH ) {
1343             die $DETACH if($c->depth > 1);
1344         }
1345         elsif ( !ref($error) and $error eq $GO ) {
1346             die $GO if($c->depth > 0);
1347         }
1348         else {
1349             unless ( ref $error ) {
1350                 no warnings 'uninitialized';
1351                 chomp $error;
1352                 my $class = $last->class;
1353                 my $name  = $last->name;
1354                 $error = qq/Caught exception in $class->$name "$error"/;
1355             }
1356             $c->error($error);
1357             $c->state(0);
1358         }
1359     }
1360     return $c->state;
1361 }
1362
1363 sub _stats_start_execute {
1364     my ( $c, $code ) = @_;
1365
1366     return if ( ( $code->name =~ /^_.*/ )
1367         && ( !$c->config->{show_internal_actions} ) );
1368
1369     my $action_name = $code->reverse();
1370     $c->counter->{$action_name}++;
1371
1372     my $action = $action_name;
1373     $action = "/$action" unless $action =~ /->/;
1374
1375     # determine if the call was the result of a forward
1376     # this is done by walking up the call stack and looking for a calling
1377     # sub of Catalyst::forward before the eval
1378     my $callsub = q{};
1379     for my $index ( 2 .. 11 ) {
1380         last
1381         if ( ( caller($index) )[0] eq 'Catalyst'
1382             && ( caller($index) )[3] eq '(eval)' );
1383
1384         if ( ( caller($index) )[3] =~ /forward$/ ) {
1385             $callsub = ( caller($index) )[3];
1386             $action  = "-> $action";
1387             last;
1388         }
1389     }
1390
1391     my $uid = $action_name . $c->counter->{$action_name};
1392
1393     # is this a root-level call or a forwarded call?
1394     if ( $callsub =~ /forward$/ ) {
1395
1396         # forward, locate the caller
1397         if ( my $parent = $c->stack->[-1] ) {
1398             $c->stats->profile(
1399                 begin  => $action,
1400                 parent => "$parent" . $c->counter->{"$parent"},
1401                 uid    => $uid,
1402             );
1403         }
1404         else {
1405
1406             # forward with no caller may come from a plugin
1407             $c->stats->profile(
1408                 begin => $action,
1409                 uid   => $uid,
1410             );
1411         }
1412     }
1413     else {
1414
1415         # root-level call
1416         $c->stats->profile(
1417             begin => $action,
1418             uid   => $uid,
1419         );
1420     }
1421     return $action;
1422
1423 }
1424
1425 sub _stats_finish_execute {
1426     my ( $c, $info ) = @_;
1427     $c->stats->profile( end => $info );
1428 }
1429
1430 =head2 $c->_localize_fields( sub { }, \%keys );
1431
1432 =cut
1433
1434 #Why does this exist? This is no longer safe and WILL NOT WORK.
1435 # it doesnt seem to be used anywhere. can we remove it?
1436 sub _localize_fields {
1437     my ( $c, $localized, $code ) = ( @_ );
1438
1439     my $request = delete $localized->{request} || {};
1440     my $response = delete $localized->{response} || {};
1441
1442     local @{ $c }{ keys %$localized } = values %$localized;
1443     local @{ $c->request }{ keys %$request } = values %$request;
1444     local @{ $c->response }{ keys %$response } = values %$response;
1445
1446     $code->();
1447 }
1448
1449 =head2 $c->finalize
1450
1451 Finalizes the request.
1452
1453 =cut
1454
1455 sub finalize {
1456     my $c = shift;
1457
1458     for my $error ( @{ $c->error } ) {
1459         $c->log->error($error);
1460     }
1461
1462     # Allow engine to handle finalize flow (for POE)
1463     my $engine = $c->engine;
1464     if ( my $code = $engine->can('finalize') ) {
1465         $engine->$code($c);
1466     }
1467     else {
1468
1469         $c->finalize_uploads;
1470
1471         # Error
1472         if ( $#{ $c->error } >= 0 ) {
1473             $c->finalize_error;
1474         }
1475
1476         $c->finalize_headers;
1477
1478         # HEAD request
1479         if ( $c->request->method eq 'HEAD' ) {
1480             $c->response->body('');
1481         }
1482
1483         $c->finalize_body;
1484     }
1485
1486     if ($c->use_stats) {
1487         my $elapsed = sprintf '%f', $c->stats->elapsed;
1488         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1489         $c->log->info(
1490             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1491     }
1492
1493     return $c->response->status;
1494 }
1495
1496 =head2 $c->finalize_body
1497
1498 Finalizes body.
1499
1500 =cut
1501
1502 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1503
1504 =head2 $c->finalize_cookies
1505
1506 Finalizes cookies.
1507
1508 =cut
1509
1510 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1511
1512 =head2 $c->finalize_error
1513
1514 Finalizes error.
1515
1516 =cut
1517
1518 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1519
1520 =head2 $c->finalize_headers
1521
1522 Finalizes headers.
1523
1524 =cut
1525
1526 sub finalize_headers {
1527     my $c = shift;
1528
1529     my $response = $c->response; #accessor calls can add up?
1530
1531     # Check if we already finalized headers
1532     return if $response->finalized_headers;
1533
1534     # Handle redirects
1535     if ( my $location = $response->redirect ) {
1536         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1537         $response->header( Location => $location );
1538
1539         #Moose TODO: we should probably be using a predicate method here ?
1540         if ( !$response->body ) {
1541             # Add a default body if none is already present
1542             $response->body(
1543                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1544             );
1545         }
1546     }
1547
1548     # Content-Length
1549     if ( $response->body && !$response->content_length ) {
1550
1551         # get the length from a filehandle
1552         if ( blessed( $response->body ) && $response->body->can('read') )
1553         {
1554             my $stat = stat $response->body;
1555             if ( $stat && $stat->size > 0 ) {
1556                 $response->content_length( $stat->size );
1557             }
1558             else {
1559                 $c->log->warn('Serving filehandle without a content-length');
1560             }
1561         }
1562         else {
1563             # everything should be bytes at this point, but just in case
1564             $response->content_length( bytes::length( $response->body ) );
1565         }
1566     }
1567
1568     # Errors
1569     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1570         $response->headers->remove_header("Content-Length");
1571         $response->body('');
1572     }
1573
1574     $c->finalize_cookies;
1575
1576     $c->engine->finalize_headers( $c, @_ );
1577
1578     # Done
1579     $response->finalized_headers(1);
1580 }
1581
1582 =head2 $c->finalize_output
1583
1584 An alias for finalize_body.
1585
1586 =head2 $c->finalize_read
1587
1588 Finalizes the input after reading is complete.
1589
1590 =cut
1591
1592 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1593
1594 =head2 $c->finalize_uploads
1595
1596 Finalizes uploads. Cleans up any temporary files.
1597
1598 =cut
1599
1600 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1601
1602 =head2 $c->get_action( $action, $namespace )
1603
1604 Gets an action in a given namespace.
1605
1606 =cut
1607
1608 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1609
1610 =head2 $c->get_actions( $action, $namespace )
1611
1612 Gets all actions of a given name in a namespace and all parent
1613 namespaces.
1614
1615 =cut
1616
1617 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1618
1619 =head2 $c->handle_request( $class, @arguments )
1620
1621 Called to handle each HTTP request.
1622
1623 =cut
1624
1625 sub handle_request {
1626     my ( $class, @arguments ) = @_;
1627
1628     # Always expect worst case!
1629     my $status = -1;
1630     eval {
1631         if ($class->debug) {
1632             my $secs = time - $START || 1;
1633             my $av = sprintf '%.3f', $COUNT / $secs;
1634             my $time = localtime time;
1635             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1636         }
1637
1638         my $c = $class->prepare(@arguments);
1639         $c->dispatch;
1640         $status = $c->finalize;
1641     };
1642
1643     if ( my $error = $@ ) {
1644         chomp $error;
1645         $class->log->error(qq/Caught exception in engine "$error"/);
1646     }
1647
1648     $COUNT++;
1649
1650     if(my $coderef = $class->log->can('_flush')){
1651         $class->log->$coderef();
1652     }
1653     return $status;
1654 }
1655
1656 =head2 $c->prepare( @arguments )
1657
1658 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1659 etc.).
1660
1661 =cut
1662
1663 sub prepare {
1664     my ( $class, @arguments ) = @_;
1665
1666     # XXX
1667     # After the app/ctxt split, this should become an attribute based on something passed
1668     # into the application.
1669     $class->context_class( ref $class || $class ) unless $class->context_class;
1670
1671     my $c = $class->context_class->new({});
1672
1673     # For on-demand data
1674     $c->request->_context($c);
1675     $c->response->_context($c);
1676
1677     #surely this is not the most efficient way to do things...
1678     $c->stats($class->stats_class->new)->enable($c->use_stats);
1679     if ( $c->debug ) {
1680         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1681     }
1682
1683     #XXX reuse coderef from can
1684     # Allow engine to direct the prepare flow (for POE)
1685     if ( $c->engine->can('prepare') ) {
1686         $c->engine->prepare( $c, @arguments );
1687     }
1688     else {
1689         $c->prepare_request(@arguments);
1690         $c->prepare_connection;
1691         $c->prepare_query_parameters;
1692         $c->prepare_headers;
1693         $c->prepare_cookies;
1694         $c->prepare_path;
1695
1696         # Prepare the body for reading, either by prepare_body
1697         # or the user, if they are using $c->read
1698         $c->prepare_read;
1699
1700         # Parse the body unless the user wants it on-demand
1701         unless ( $c->config->{parse_on_demand} ) {
1702             $c->prepare_body;
1703         }
1704     }
1705
1706     my $method  = $c->req->method  || '';
1707     my $path    = $c->req->path;
1708     $path       = '/' unless length $path;
1709     my $address = $c->req->address || '';
1710
1711     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1712       if $c->debug;
1713
1714     $c->prepare_action;
1715
1716     return $c;
1717 }
1718
1719 =head2 $c->prepare_action
1720
1721 Prepares action. See L<Catalyst::Dispatcher>.
1722
1723 =cut
1724
1725 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1726
1727 =head2 $c->prepare_body
1728
1729 Prepares message body.
1730
1731 =cut
1732
1733 sub prepare_body {
1734     my $c = shift;
1735
1736     #Moose TODO: what is  _body ??
1737     # Do we run for the first time?
1738     return if defined $c->request->{_body};
1739
1740     # Initialize on-demand data
1741     $c->engine->prepare_body( $c, @_ );
1742     $c->prepare_parameters;
1743     $c->prepare_uploads;
1744
1745     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1746         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1747         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1748             my $param = $c->req->body_parameters->{$key};
1749             my $value = defined($param) ? $param : '';
1750             $t->row( $key,
1751                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1752         }
1753         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1754     }
1755 }
1756
1757 =head2 $c->prepare_body_chunk( $chunk )
1758
1759 Prepares a chunk of data before sending it to L<HTTP::Body>.
1760
1761 See L<Catalyst::Engine>.
1762
1763 =cut
1764
1765 sub prepare_body_chunk {
1766     my $c = shift;
1767     $c->engine->prepare_body_chunk( $c, @_ );
1768 }
1769
1770 =head2 $c->prepare_body_parameters
1771
1772 Prepares body parameters.
1773
1774 =cut
1775
1776 sub prepare_body_parameters {
1777     my $c = shift;
1778     $c->engine->prepare_body_parameters( $c, @_ );
1779 }
1780
1781 =head2 $c->prepare_connection
1782
1783 Prepares connection.
1784
1785 =cut
1786
1787 sub prepare_connection {
1788     my $c = shift;
1789     $c->engine->prepare_connection( $c, @_ );
1790 }
1791
1792 =head2 $c->prepare_cookies
1793
1794 Prepares cookies.
1795
1796 =cut
1797
1798 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1799
1800 =head2 $c->prepare_headers
1801
1802 Prepares headers.
1803
1804 =cut
1805
1806 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1807
1808 =head2 $c->prepare_parameters
1809
1810 Prepares parameters.
1811
1812 =cut
1813
1814 sub prepare_parameters {
1815     my $c = shift;
1816     $c->prepare_body_parameters;
1817     $c->engine->prepare_parameters( $c, @_ );
1818 }
1819
1820 =head2 $c->prepare_path
1821
1822 Prepares path and base.
1823
1824 =cut
1825
1826 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1827
1828 =head2 $c->prepare_query_parameters
1829
1830 Prepares query parameters.
1831
1832 =cut
1833
1834 sub prepare_query_parameters {
1835     my $c = shift;
1836
1837     $c->engine->prepare_query_parameters( $c, @_ );
1838
1839     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1840         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1841         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1842             my $param = $c->req->query_parameters->{$key};
1843             my $value = defined($param) ? $param : '';
1844             $t->row( $key,
1845                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1846         }
1847         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1848     }
1849 }
1850
1851 =head2 $c->prepare_read
1852
1853 Prepares the input for reading.
1854
1855 =cut
1856
1857 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1858
1859 =head2 $c->prepare_request
1860
1861 Prepares the engine request.
1862
1863 =cut
1864
1865 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1866
1867 =head2 $c->prepare_uploads
1868
1869 Prepares uploads.
1870
1871 =cut
1872
1873 sub prepare_uploads {
1874     my $c = shift;
1875
1876     $c->engine->prepare_uploads( $c, @_ );
1877
1878     if ( $c->debug && keys %{ $c->request->uploads } ) {
1879         my $t = Text::SimpleTable->new(
1880             [ 12, 'Parameter' ],
1881             [ 26, 'Filename' ],
1882             [ 18, 'Type' ],
1883             [ 9,  'Size' ]
1884         );
1885         for my $key ( sort keys %{ $c->request->uploads } ) {
1886             my $upload = $c->request->uploads->{$key};
1887             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1888                 $t->row( $key, $u->filename, $u->type, $u->size );
1889             }
1890         }
1891         $c->log->debug( "File Uploads are:\n" . $t->draw );
1892     }
1893 }
1894
1895 =head2 $c->prepare_write
1896
1897 Prepares the output for writing.
1898
1899 =cut
1900
1901 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1902
1903 =head2 $c->request_class
1904
1905 Returns or sets the request class.
1906
1907 =head2 $c->response_class
1908
1909 Returns or sets the response class.
1910
1911 =head2 $c->read( [$maxlength] )
1912
1913 Reads a chunk of data from the request body. This method is designed to
1914 be used in a while loop, reading C<$maxlength> bytes on every call.
1915 C<$maxlength> defaults to the size of the request if not specified.
1916
1917 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1918 directly.
1919
1920 Warning: If you use read(), Catalyst will not process the body,
1921 so you will not be able to access POST parameters or file uploads via
1922 $c->request.  You must handle all body parsing yourself.
1923
1924 =cut
1925
1926 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1927
1928 =head2 $c->run
1929
1930 Starts the engine.
1931
1932 =cut
1933
1934 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1935
1936 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1937
1938 Sets an action in a given namespace.
1939
1940 =cut
1941
1942 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1943
1944 =head2 $c->setup_actions($component)
1945
1946 Sets up actions for a component.
1947
1948 =cut
1949
1950 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1951
1952 =head2 $c->setup_components
1953
1954 Sets up components. Specify a C<setup_components> config option to pass
1955 additional options directly to L<Module::Pluggable>. To add additional
1956 search paths, specify a key named C<search_extra> as an array
1957 reference. Items in the array beginning with C<::> will have the
1958 application class name prepended to them.
1959
1960 All components found will also have any
1961 L<Devel::InnerPackage|inner packages> loaded and set up as components.
1962 Note, that modules which are B<not> an I<inner package> of the main
1963 file namespace loaded will not be instantiated as components.
1964
1965 =cut
1966
1967 sub setup_components {
1968     my $class = shift;
1969
1970     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1971     my $config  = $class->config->{ setup_components };
1972     my $extra   = delete $config->{ search_extra } || [];
1973
1974     push @paths, @$extra;
1975
1976     my $locator = Module::Pluggable::Object->new(
1977         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1978         %$config
1979     );
1980
1981     my @comps = sort { length $a <=> length $b } $locator->plugins;
1982     my %comps = map { $_ => 1 } @comps;
1983
1984     for my $component ( @comps ) {
1985
1986         # We pass ignore_loaded here so that overlay files for (e.g.)
1987         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1988         # we know M::P::O found a file on disk so this is safe
1989
1990         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1991         #Class::MOP::load_class($component);
1992
1993         my $module  = $class->setup_component( $component );
1994         my %modules = (
1995             $component => $module,
1996             map {
1997                 $_ => $class->setup_component( $_ )
1998             } grep {
1999               not exists $comps{$_}
2000             } Devel::InnerPackage::list_packages( $component )
2001         );
2002
2003         for my $key ( keys %modules ) {
2004             $class->components->{ $key } = $modules{ $key };
2005         }
2006     }
2007 }
2008
2009 =head2 $c->setup_component
2010
2011 =cut
2012
2013 sub setup_component {
2014     my( $class, $component ) = @_;
2015
2016     unless ( $component->can( 'COMPONENT' ) ) {
2017         return $component;
2018     }
2019
2020     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2021     my $config = $class->config->{ $suffix } || {};
2022
2023     my $instance = eval { $component->COMPONENT( $class, $config ); };
2024
2025     if ( my $error = $@ ) {
2026         chomp $error;
2027         Catalyst::Exception->throw(
2028             message => qq/Couldn't instantiate component "$component", "$error"/
2029         );
2030     }
2031
2032     Catalyst::Exception->throw(
2033         message =>
2034         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
2035     ) unless blessed($instance);
2036
2037     return $instance;
2038 }
2039
2040 =head2 $c->setup_dispatcher
2041
2042 Sets up dispatcher.
2043
2044 =cut
2045
2046 sub setup_dispatcher {
2047     my ( $class, $dispatcher ) = @_;
2048
2049     if ($dispatcher) {
2050         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2051     }
2052
2053     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2054         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2055     }
2056
2057     unless ($dispatcher) {
2058         $dispatcher = $class->dispatcher_class;
2059     }
2060
2061     Class::MOP::load_class($dispatcher);
2062
2063     # dispatcher instance
2064     $class->dispatcher( $dispatcher->new );
2065 }
2066
2067 =head2 $c->setup_engine
2068
2069 Sets up engine.
2070
2071 =cut
2072
2073 sub setup_engine {
2074     my ( $class, $engine ) = @_;
2075
2076     if ($engine) {
2077         $engine = 'Catalyst::Engine::' . $engine;
2078     }
2079
2080     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2081         $engine = 'Catalyst::Engine::' . $env;
2082     }
2083
2084     if ( $ENV{MOD_PERL} ) {
2085
2086         # create the apache method
2087         $class->meta->add_method('apache' => sub { shift->engine->apache });
2088
2089         my ( $software, $version ) =
2090           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2091
2092         $version =~ s/_//g;
2093         $version =~ s/(\.[^.]+)\./$1/g;
2094
2095         if ( $software eq 'mod_perl' ) {
2096
2097             if ( !$engine ) {
2098
2099                 if ( $version >= 1.99922 ) {
2100                     $engine = 'Catalyst::Engine::Apache2::MP20';
2101                 }
2102
2103                 elsif ( $version >= 1.9901 ) {
2104                     $engine = 'Catalyst::Engine::Apache2::MP19';
2105                 }
2106
2107                 elsif ( $version >= 1.24 ) {
2108                     $engine = 'Catalyst::Engine::Apache::MP13';
2109                 }
2110
2111                 else {
2112                     Catalyst::Exception->throw( message =>
2113                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2114                 }
2115
2116             }
2117
2118             # install the correct mod_perl handler
2119             if ( $version >= 1.9901 ) {
2120                 *handler = sub  : method {
2121                     shift->handle_request(@_);
2122                 };
2123             }
2124             else {
2125                 *handler = sub ($$) { shift->handle_request(@_) };
2126             }
2127
2128         }
2129
2130         elsif ( $software eq 'Zeus-Perl' ) {
2131             $engine = 'Catalyst::Engine::Zeus';
2132         }
2133
2134         else {
2135             Catalyst::Exception->throw(
2136                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2137         }
2138     }
2139
2140     unless ($engine) {
2141         $engine = $class->engine_class;
2142     }
2143
2144     Class::MOP::load_class($engine);
2145
2146     # check for old engines that are no longer compatible
2147     my $old_engine;
2148     if ( $engine->isa('Catalyst::Engine::Apache')
2149         && !Catalyst::Engine::Apache->VERSION )
2150     {
2151         $old_engine = 1;
2152     }
2153
2154     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2155         && Catalyst::Engine::Server->VERSION le '0.02' )
2156     {
2157         $old_engine = 1;
2158     }
2159
2160     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2161         && $engine->VERSION eq '0.01' )
2162     {
2163         $old_engine = 1;
2164     }
2165
2166     elsif ($engine->isa('Catalyst::Engine::Zeus')
2167         && $engine->VERSION eq '0.01' )
2168     {
2169         $old_engine = 1;
2170     }
2171
2172     if ($old_engine) {
2173         Catalyst::Exception->throw( message =>
2174               qq/Engine "$engine" is not supported by this version of Catalyst/
2175         );
2176     }
2177
2178     # engine instance
2179     $class->engine( $engine->new );
2180 }
2181
2182 =head2 $c->setup_home
2183
2184 Sets up the home directory.
2185
2186 =cut
2187
2188 sub setup_home {
2189     my ( $class, $home ) = @_;
2190
2191     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2192         $home = $env;
2193     }
2194
2195     $home ||= Catalyst::Utils::home($class);
2196
2197     if ($home) {
2198         #I remember recently being scolded for assigning config values like this
2199         $class->config->{home} ||= $home;
2200         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2201     }
2202 }
2203
2204 =head2 $c->setup_log
2205
2206 Sets up log.
2207
2208 =cut
2209
2210 sub setup_log {
2211     my ( $class, $debug ) = @_;
2212
2213     unless ( $class->log ) {
2214         $class->log( Catalyst::Log->new );
2215     }
2216
2217     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2218     if ( defined($env_debug) ? $env_debug : $debug ) {
2219         $class->meta->add_method('debug' => sub { 1 });
2220         $class->log->debug('Debug messages enabled');
2221     }
2222 }
2223
2224 =head2 $c->setup_plugins
2225
2226 Sets up plugins.
2227
2228 =cut
2229
2230 =head2 $c->setup_stats
2231
2232 Sets up timing statistics class.
2233
2234 =cut
2235
2236 sub setup_stats {
2237     my ( $class, $stats ) = @_;
2238
2239     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2240
2241     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2242     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2243         $class->meta->add_method('use_stats' => sub { 1 });
2244         $class->log->debug('Statistics enabled');
2245     }
2246 }
2247
2248
2249 =head2 $c->registered_plugins
2250
2251 Returns a sorted list of the plugins which have either been stated in the
2252 import list or which have been added via C<< MyApp->plugin(@args); >>.
2253
2254 If passed a given plugin name, it will report a boolean value indicating
2255 whether or not that plugin is loaded.  A fully qualified name is required if
2256 the plugin name does not begin with C<Catalyst::Plugin::>.
2257
2258  if ($c->registered_plugins('Some::Plugin')) {
2259      ...
2260  }
2261
2262 =cut
2263
2264 {
2265
2266     sub registered_plugins {
2267         my $proto = shift;
2268         return sort keys %{ $proto->_plugins } unless @_;
2269         my $plugin = shift;
2270         return 1 if exists $proto->_plugins->{$plugin};
2271         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2272     }
2273
2274     sub _register_plugin {
2275         my ( $proto, $plugin, $instant ) = @_;
2276         my $class = ref $proto || $proto;
2277
2278         # no ignore_loaded here, the plugin may already have been
2279         # defined in memory and we don't want to error on "no file" if so
2280
2281         Class::MOP::load_class( $plugin );
2282
2283         $proto->_plugins->{$plugin} = 1;
2284         unless ($instant) {
2285             no strict 'refs';
2286             if( $class->can('meta') ){
2287               my @superclasses = ($plugin, $class->meta->superclasses );
2288               $class->meta->superclasses(@superclasses);
2289             } else {
2290               unshift @{"$class\::ISA"}, $plugin;
2291             }
2292         }
2293         return $class;
2294     }
2295
2296     sub setup_plugins {
2297         my ( $class, $plugins ) = @_;
2298
2299         $class->_plugins( {} ) unless $class->_plugins;
2300         $plugins ||= [];
2301         for my $plugin ( reverse @$plugins ) {
2302
2303             unless ( $plugin =~ s/\A\+// ) {
2304                 $plugin = "Catalyst::Plugin::$plugin";
2305             }
2306
2307             $class->_register_plugin($plugin);
2308         }
2309     }
2310 }
2311
2312 =head2 $c->stack
2313
2314 Returns an arrayref of the internal execution stack (actions that are
2315 currently executing).
2316
2317 =head2 $c->stats_class
2318
2319 Returns or sets the stats (timing statistics) class.
2320
2321 =head2 $c->use_stats
2322
2323 Returns 1 when stats collection is enabled.  Stats collection is enabled
2324 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2325 environment variable is set.
2326
2327 Note that this is a static method, not an accessor and should be overloaded
2328 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2329
2330 =cut
2331
2332 sub use_stats { 0 }
2333
2334
2335 =head2 $c->write( $data )
2336
2337 Writes $data to the output stream. When using this method directly, you
2338 will need to manually set the C<Content-Length> header to the length of
2339 your output data, if known.
2340
2341 =cut
2342
2343 sub write {
2344     my $c = shift;
2345
2346     # Finalize headers if someone manually writes output
2347     $c->finalize_headers;
2348
2349     return $c->engine->write( $c, @_ );
2350 }
2351
2352 =head2 version
2353
2354 Returns the Catalyst version number. Mostly useful for "powered by"
2355 messages in template systems.
2356
2357 =cut
2358
2359 sub version { return $Catalyst::VERSION }
2360
2361 =head1 INTERNAL ACTIONS
2362
2363 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2364 C<_ACTION>, and C<_END>. These are by default not shown in the private
2365 action table, but you can make them visible with a config parameter.
2366
2367     MyApp->config->{show_internal_actions} = 1;
2368
2369 =head1 CASE SENSITIVITY
2370
2371 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2372 mapped to C</foo/bar>. You can activate case sensitivity with a config
2373 parameter.
2374
2375     MyApp->config->{case_sensitive} = 1;
2376
2377 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2378
2379 =head1 ON-DEMAND PARSER
2380
2381 The request body is usually parsed at the beginning of a request,
2382 but if you want to handle input yourself, you can enable on-demand
2383 parsing with a config parameter.
2384
2385     MyApp->config->{parse_on_demand} = 1;
2386
2387 =head1 PROXY SUPPORT
2388
2389 Many production servers operate using the common double-server approach,
2390 with a lightweight frontend web server passing requests to a larger
2391 backend server. An application running on the backend server must deal
2392 with two problems: the remote user always appears to be C<127.0.0.1> and
2393 the server's hostname will appear to be C<localhost> regardless of the
2394 virtual host that the user connected through.
2395
2396 Catalyst will automatically detect this situation when you are running
2397 the frontend and backend servers on the same machine. The following
2398 changes are made to the request.
2399
2400     $c->req->address is set to the user's real IP address, as read from
2401     the HTTP X-Forwarded-For header.
2402
2403     The host value for $c->req->base and $c->req->uri is set to the real
2404     host, as read from the HTTP X-Forwarded-Host header.
2405
2406 Obviously, your web server must support these headers for this to work.
2407
2408 In a more complex server farm environment where you may have your
2409 frontend proxy server(s) on different machines, you will need to set a
2410 configuration option to tell Catalyst to read the proxied data from the
2411 headers.
2412
2413     MyApp->config->{using_frontend_proxy} = 1;
2414
2415 If you do not wish to use the proxy support at all, you may set:
2416
2417     MyApp->config->{ignore_frontend_proxy} = 1;
2418
2419 =head1 THREAD SAFETY
2420
2421 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2422 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2423 believe the Catalyst core to be thread-safe.
2424
2425 If you plan to operate in a threaded environment, remember that all other
2426 modules you are using must also be thread-safe. Some modules, most notably
2427 L<DBD::SQLite>, are not thread-safe.
2428
2429 =head1 SUPPORT
2430
2431 IRC:
2432
2433     Join #catalyst on irc.perl.org.
2434
2435 Mailing Lists:
2436
2437     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
2438     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
2439
2440 Web:
2441
2442     http://catalyst.perl.org
2443
2444 Wiki:
2445
2446     http://dev.catalyst.perl.org
2447
2448 =head1 SEE ALSO
2449
2450 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2451
2452 =head2 L<Catalyst::Manual> - The Catalyst Manual
2453
2454 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2455
2456 =head2 L<Catalyst::Engine> - Core engine
2457
2458 =head2 L<Catalyst::Log> - Log class.
2459
2460 =head2 L<Catalyst::Request> - Request object
2461
2462 =head2 L<Catalyst::Response> - Response object
2463
2464 =head2 L<Catalyst::Test> - The test suite.
2465
2466 =head1 PROJECT FOUNDER
2467
2468 sri: Sebastian Riedel <sri@cpan.org>
2469
2470 =head1 CONTRIBUTORS
2471
2472 abw: Andy Wardley
2473
2474 acme: Leon Brocard <leon@astray.com>
2475
2476 Andrew Bramble
2477
2478 Andrew Ford
2479
2480 Andrew Ruthven
2481
2482 andyg: Andy Grundman <andy@hybridized.org>
2483
2484 audreyt: Audrey Tang
2485
2486 bricas: Brian Cassidy <bricas@cpan.org>
2487
2488 Caelum: Rafael Kitover <rkitover@io.com>
2489
2490 chansen: Christian Hansen
2491
2492 chicks: Christopher Hicks
2493
2494 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
2495
2496 Drew Taylor
2497
2498 esskar: Sascha Kiefer
2499
2500 fireartist: Carl Franks <cfranks@cpan.org>
2501
2502 gabb: Danijel Milicevic
2503
2504 Gary Ashton Jones
2505
2506 Geoff Richards
2507
2508 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
2509
2510 jcamacho: Juan Camacho
2511
2512 Jody Belka
2513
2514 Johan Lindstrom
2515
2516 jon: Jon Schutz <jjschutz@cpan.org>
2517
2518 marcus: Marcus Ramberg <mramberg@cpan.org>
2519
2520 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
2521
2522 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
2523
2524 mugwump: Sam Vilain
2525
2526 naughton: David Naughton
2527
2528 ningu: David Kamholz <dkamholz@cpan.org>
2529
2530 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
2531
2532 numa: Dan Sully <daniel@cpan.org>
2533
2534 obra: Jesse Vincent
2535
2536 omega: Andreas Marienborg
2537
2538 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
2539
2540 rafl: Florian Ragwitz <rafl@debian.org>
2541
2542 sky: Arthur Bergman
2543
2544 the_jester: Jesse Sheidlower
2545
2546 Ulf Edvinsson
2547
2548 willert: Sebastian Willert <willert@cpan.org>
2549
2550 =head1 LICENSE
2551
2552 This library is free software, you can redistribute it and/or modify it under
2553 the same terms as Perl itself.
2554
2555 =cut
2556
2557 no Moose;
2558
2559 __PACKAGE__->meta->make_immutable;
2560
2561 1;