lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use namespace::clean -except => 'meta';
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use HTML::Entities;
  27 use Tree::Simple qw/use_weak_refs/;
  28 use Tree::Simple::Visitor::FindByUID;
  29 use Class::C3::Adopt::NEXT;
  30 use List::MoreUtils qw/uniq/;
  31 use attributes;
  32 use String::RewritePrefix;
  33 use Catalyst::EngineLoader;
  34 use utf8;
  35 use Carp qw/croak carp shortmess/;
  36 use Try::Tiny;
  37 use Safe::Isa;
  38 use Moose::Util 'find_meta';
  39 use Plack::Middleware::Conditional;
  40 use Plack::Middleware::ReverseProxy;
  41 use Plack::Middleware::IIS6ScriptNameFix;
  42 use Plack::Middleware::IIS7KeepAliveFix;
  43 use Plack::Middleware::LighttpdScriptNameFix;
  44 use Plack::Middleware::ContentLength;
  45 use Plack::Middleware::Head;
  46 use Plack::Middleware::HTTPExceptions;
  47 use Plack::Middleware::FixMissingBodyInRedirect;
  48 use Plack::Middleware::MethodOverride;
  49 use Plack::Middleware::RemoveRedundantBody;
  50 use Plack::Util;
  51 use Class::Load 'load_class';
  52
  53 BEGIN { require 5.008003; }
  54
  55 has stack => (is => 'ro', default => sub { [] });
  56 has stash => (is => 'rw', default => sub { {} });
  57 has state => (is => 'rw', default => 0);
  58 has stats => (is => 'rw');
  59 has action => (is => 'rw');
  60 has counter => (is => 'rw', default => sub { {} });
  61 has request => (
  62     is => 'rw',
  63     default => sub {
  64         my $self = shift;
  65         $self->request_class->new($self->_build_request_constructor_args);
  66     },
  67     lazy => 1,
  68 );
  69 sub _build_request_constructor_args {
  70     my $self = shift;
  71     my %p = ( _log => $self->log );
  72     $p{_uploadtmp} = $self->_uploadtmp if $self->_has_uploadtmp;
  73     $p{data_handlers} = {$self->registered_data_handlers};
  74     $p{_use_hash_multivalue} = $self->config->{use_hash_multivalue_in_request}
  75       if $self->config->{use_hash_multivalue_in_request};
  76     \%p;
  77 }
  78
  79 has response => (
  80     is => 'rw',
  81     default => sub {
  82         my $self = shift;
  83         $self->response_class->new($self->_build_response_constructor_args);
  84     },
  85     lazy => 1,
  86 );
  87 sub _build_response_constructor_args {
  88     my $self = shift;
  89     { _log => $self->log };
  90 }
  91
  92 has namespace => (is => 'rw');
  93
  94 sub depth { scalar @{ shift->stack || [] }; }
  95 sub comp { shift->component(@_) }
  96
  97 sub req {
  98     my $self = shift; return $self->request(@_);
  99 }
 100 sub res {
 101     my $self = shift; return $self->response(@_);
 102 }
 103
 104 # For backwards compatibility
 105 sub finalize_output { shift->finalize_body(@_) };
 106
 107 # For statistics
 108 our $COUNT     = 1;
 109 our $START     = time;
 110 our $RECURSION = 1000;
 111 our $DETACH    = Catalyst::Exception::Detach->new;
 112 our $GO        = Catalyst::Exception::Go->new;
 113
 114 #I imagine that very few of these really need to be class variables. if any.
 115 #maybe we should just make them attributes with a default?
 116 __PACKAGE__->mk_classdata($_)
 117   for qw/components arguments dispatcher engine log dispatcher_class
 118   engine_loader context_class request_class response_class stats_class
 119   setup_finished _psgi_app loading_psgi_file run_options _psgi_middleware
 120   _data_handlers/;
 121
 122 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
 123 __PACKAGE__->request_class('Catalyst::Request');
 124 __PACKAGE__->response_class('Catalyst::Response');
 125 __PACKAGE__->stats_class('Catalyst::Stats');
 126
 127 # Remember to update this in Catalyst::Runtime as well!
 128
 129 our $VERSION = '5.90059_004';
 130
 131 sub import {
 132     my ( $class, @arguments ) = @_;
 133
 134     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
 135     # callers @ISA.
 136     return unless $class eq 'Catalyst';
 137
 138     my $caller = caller();
 139     return if $caller eq 'main';
 140
 141     my $meta = Moose::Meta::Class->initialize($caller);
 142     unless ( $caller->isa('Catalyst') ) {
 143         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 144         $meta->superclasses(@superclasses);
 145     }
 146     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 147     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 148
 149     unless( $meta->has_method('meta') ){
 150         if ($Moose::VERSION >= 1.15) {
 151             $meta->_add_meta_method('meta');
 152         }
 153         else {
 154             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 155         }
 156     }
 157
 158     $caller->arguments( [@arguments] );
 159     $caller->setup_home;
 160 }
 161
 162 sub _application { $_[0] }
 163
 164 =encoding UTF-8
 165
 166 =head1 NAME
 167
 168 Catalyst - The Elegant MVC Web Application Framework
 169
 170 =head1 SYNOPSIS
 171
 172 See the L<Catalyst::Manual> distribution for comprehensive
 173 documentation and tutorials.
 174
 175     # Install Catalyst::Devel for helpers and other development tools
 176     # use the helper to create a new application
 177     catalyst.pl MyApp
 178
 179     # add models, views, controllers
 180     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 181     script/myapp_create.pl view MyTemplate TT
 182     script/myapp_create.pl controller Search
 183
 184     # built in testserver -- use -r to restart automatically on changes
 185     # --help to see all available options
 186     script/myapp_server.pl
 187
 188     # command line testing interface
 189     script/myapp_test.pl /yada
 190
 191     ### in lib/MyApp.pm
 192     use Catalyst qw/-Debug/; # include plugins here as well
 193
 194     ### In lib/MyApp/Controller/Root.pm (autocreated)
 195     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 196         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 197         $c->stash->{template} = 'foo.tt'; # set the template
 198         # lookup something from db -- stash vars are passed to TT
 199         $c->stash->{data} =
 200           $c->model('Database::Foo')->search( { country => $args[0] } );
 201         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 202             $c->forward( 'bar' ); # process another action
 203             # do something else after forward returns
 204         }
 205     }
 206
 207     # The foo.tt TT template can use the stash data from the database
 208     [% WHILE (item = data.next) %]
 209         [% item.foo %]
 210     [% END %]
 211
 212     # called for /bar/of/soap, /bar/of/soap/10, etc.
 213     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 214
 215     # called after all actions are finished
 216     sub end : Action {
 217         my ( $self, $c ) = @_;
 218         if ( scalar @{ $c->error } ) { ... } # handle errors
 219         return if $c->res->body; # already have a response
 220         $c->forward( 'MyApp::View::TT' ); # render template
 221     }
 222
 223 See L<Catalyst::Manual::Intro> for additional information.
 224
 225 =head1 DESCRIPTION
 226
 227 Catalyst is a modern framework for making web applications without the
 228 pain usually associated with this process. This document is a reference
 229 to the main Catalyst application. If you are a new user, we suggest you
 230 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 231
 232 See L<Catalyst::Manual> for more documentation.
 233
 234 Catalyst plugins can be loaded by naming them as arguments to the "use
 235 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 236 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 237 C<My::Module>.
 238
 239     use Catalyst qw/My::Module/;
 240
 241 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 242 fully qualify the name by using a unary plus:
 243
 244     use Catalyst qw/
 245         My::Module
 246         +Fully::Qualified::Plugin::Name
 247     /;
 248
 249 Special flags like C<-Debug> can also be specified as
 250 arguments when Catalyst is loaded:
 251
 252     use Catalyst qw/-Debug My::Module/;
 253
 254 The position of plugins and flags in the chain is important, because
 255 they are loaded in the order in which they appear.
 256
 257 The following flags are supported:
 258
 259 =head2 -Debug
 260
 261 Enables debug output. You can also force this setting from the system
 262 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 263 settings override the application, with <MYAPP>_DEBUG having the highest
 264 priority.
 265
 266 This sets the log level to 'debug' and enables full debug output on the
 267 error screen. If you only want the latter, see L<< $c->debug >>.
 268
 269 =head2 -Home
 270
 271 Forces Catalyst to use a specific home directory, e.g.:
 272
 273     use Catalyst qw[-Home=/usr/mst];
 274
 275 This can also be done in the shell environment by setting either the
 276 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 277 is replaced with the uppercased name of your application, any "::" in
 278 the name will be replaced with underscores, e.g. MyApp::Web should use
 279 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 280
 281 If none of these are set, Catalyst will attempt to automatically detect the
 282 home directory. If you are working in a development environment, Catalyst
 283 will try and find the directory containing either Makefile.PL, Build.PL,
 284 dist.ini, or cpanfile. If the application has been installed into the system
 285 (i.e. you have done C<make install>), then Catalyst will use the path to your
 286 application module, without the .pm extension (e.g., /foo/MyApp if your
 287 application was installed at /foo/MyApp.pm)
 288
 289 =head2 -Log
 290
 291     use Catalyst '-Log=warn,fatal,error';
 292
 293 Specifies a comma-delimited list of log levels.
 294
 295 =head2 -Stats
 296
 297 Enables statistics collection and reporting.
 298
 299    use Catalyst qw/-Stats=1/;
 300
 301 You can also force this setting from the system environment with CATALYST_STATS
 302 or <MYAPP>_STATS. The environment settings override the application, with
 303 <MYAPP>_STATS having the highest priority.
 304
 305 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 306
 307 =head1 METHODS
 308
 309 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 310
 311 =head2 $c->action
 312
 313 Returns a L<Catalyst::Action> object for the current action, which
 314 stringifies to the action name. See L<Catalyst::Action>.
 315
 316 =head2 $c->namespace
 317
 318 Returns the namespace of the current action, i.e., the URI prefix
 319 corresponding to the controller of the current action. For example:
 320
 321     # in Controller::Foo::Bar
 322     $c->namespace; # returns 'foo/bar';
 323
 324 =head2 $c->request
 325
 326 =head2 $c->req
 327
 328 Returns the current L<Catalyst::Request> object, giving access to
 329 information about the current client request (including parameters,
 330 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 331
 332 =head2 REQUEST FLOW HANDLING
 333
 334 =head2 $c->forward( $action [, \@arguments ] )
 335
 336 =head2 $c->forward( $class, $method, [, \@arguments ] )
 337
 338 This is one way of calling another action (method) in the same or
 339 a different controller. You can also use C<< $self->my_method($c, @args) >>
 340 in the same controller or C<< $c->controller('MyController')->my_method($c, @args) >>
 341 in a different controller.
 342 The main difference is that 'forward' uses some of the Catalyst request
 343 cycle overhead, including debugging, which may be useful to you. On the
 344 other hand, there are some complications to using 'forward', restrictions
 345 on values returned from 'forward', and it may not handle errors as you prefer.
 346 Whether you use 'forward' or not is up to you; it is not considered superior to
 347 the other ways to call a method.
 348
 349 'forward' calls  another action, by its private name. If you give a
 350 class name but no method, C<process()> is called. You may also optionally
 351 pass arguments in an arrayref. The action will receive the arguments in
 352 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 353 C<< $c->req->args >> will be restored to the previous values.
 354
 355 Any data C<return>ed from the action forwarded to, will be returned by the
 356 call to forward.
 357
 358     my $foodata = $c->forward('/foo');
 359     $c->forward('index');
 360     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 361     $c->forward('View::TT');
 362
 363 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 364 an C<< eval { } >> around the call (actually
 365 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus rendering all
 366 exceptions thrown by the called action non-fatal and pushing them onto
 367 $c->error instead. If you want C<die> to propagate you need to do something
 368 like:
 369
 370     $c->forward('foo');
 371     die join "\n", @{ $c->error } if @{ $c->error };
 372
 373 Or make sure to always return true values from your actions and write
 374 your code like this:
 375
 376     $c->forward('foo') || return;
 377
 378 Another note is that C<< $c->forward >> always returns a scalar because it
 379 actually returns $c->state which operates in a scalar context.
 380 Thus, something like:
 381
 382     return @array;
 383
 384 in an action that is forwarded to is going to return a scalar,
 385 i.e. how many items are in that array, which is probably not what you want.
 386 If you need to return an array then return a reference to it,
 387 or stash it like so:
 388
 389     $c->stash->{array} = \@array;
 390
 391 and access it from the stash.
 392
 393 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 394
 395 =cut
 396
 397 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 398
 399 =head2 $c->detach( $action [, \@arguments ] )
 400
 401 =head2 $c->detach( $class, $method, [, \@arguments ] )
 402
 403 =head2 $c->detach()
 404
 405 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 406 doesn't return to the previous action when processing is finished.
 407
 408 When called with no arguments it escapes the processing chain entirely.
 409
 410 =cut
 411
 412 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 413
 414 =head2 $c->visit( $action [, \@arguments ] )
 415
 416 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 417
 418 =head2 $c->visit( $class, $method, [, \@arguments ] )
 419
 420 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 421
 422 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 423 but does a full dispatch, instead of just calling the new C<$action> /
 424 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 425 you go to are called, just like a new request.
 426
 427 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 428 This means, for example, that C<< $c->action >> methods such as
 429 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 430 L<reverse|Catalyst::Action/reverse> return information for the visited action
 431 when they are invoked within the visited action.  This is different from the
 432 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 433 continues to use the $c->action object from the caller action even when
 434 invoked from the called action.
 435
 436 C<< $c->stash >> is kept unchanged.
 437
 438 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 439 allows you to "wrap" another action, just as it would have been called by
 440 dispatching from a URL, while the analogous
 441 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 442 transfer control to another action as if it had been reached directly from a URL.
 443
 444 =cut
 445
 446 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 447
 448 =head2 $c->go( $action [, \@arguments ] )
 449
 450 =head2 $c->go( $action [, \@captures, \@arguments ] )
 451
 452 =head2 $c->go( $class, $method, [, \@arguments ] )
 453
 454 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 455
 456 The relationship between C<go> and
 457 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 458 the relationship between
 459 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 460 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 461 C<< $c->go >> will perform a full dispatch on the specified action or method,
 462 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 463 C<go> escapes the processing of the current request chain on completion, and
 464 does not return to its caller.
 465
 466 @arguments are arguments to the final destination of $action. @captures are
 467 arguments to the intermediate steps, if any, on the way to the final sub of
 468 $action.
 469
 470 =cut
 471
 472 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 473
 474 =head2 $c->response
 475
 476 =head2 $c->res
 477
 478 Returns the current L<Catalyst::Response> object, see there for details.
 479
 480 =head2 $c->stash
 481
 482 Returns a hashref to the stash, which may be used to store data and pass
 483 it between components during a request. You can also set hash keys by
 484 passing arguments. The stash is automatically sent to the view. The
 485 stash is cleared at the end of a request; it cannot be used for
 486 persistent storage (for this you must use a session; see
 487 L<Catalyst::Plugin::Session> for a complete system integrated with
 488 Catalyst).
 489
 490     $c->stash->{foo} = $bar;
 491     $c->stash( { moose => 'majestic', qux => 0 } );
 492     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 493
 494     # stash is automatically passed to the view for use in a template
 495     $c->forward( 'MyApp::View::TT' );
 496
 497 =cut
 498
 499 around stash => sub {
 500     my $orig = shift;
 501     my $c = shift;
 502     my $stash = $orig->($c);
 503     if (@_) {
 504         my $new_stash = @_ > 1 ? {@_} : $_[0];
 505         croak('stash takes a hash or hashref') unless ref $new_stash;
 506         foreach my $key ( keys %$new_stash ) {
 507           $stash->{$key} = $new_stash->{$key};
 508         }
 509     }
 510
 511     return $stash;
 512 };
 513
 514
 515 =head2 $c->error
 516
 517 =head2 $c->error($error, ...)
 518
 519 =head2 $c->error($arrayref)
 520
 521 Returns an arrayref containing error messages.  If Catalyst encounters an
 522 error while processing a request, it stores the error in $c->error.  This
 523 method should only be used to store fatal error messages.
 524
 525     my @error = @{ $c->error };
 526
 527 Add a new error.
 528
 529     $c->error('Something bad happened');
 530
 531 =cut
 532
 533 sub error {
 534     my $c = shift;
 535     if ( $_[0] ) {
 536         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 537         croak @$error unless ref $c;
 538         push @{ $c->{error} }, @$error;
 539     }
 540     elsif ( defined $_[0] ) { $c->{error} = undef }
 541     return $c->{error} || [];
 542 }
 543
 544
 545 =head2 $c->state
 546
 547 Contains the return value of the last executed action.
 548 Note that << $c->state >> operates in a scalar context which means that all
 549 values it returns are scalar.
 550
 551 =head2 $c->clear_errors
 552
 553 Clear errors.  You probably don't want to clear the errors unless you are
 554 implementing a custom error screen.
 555
 556 This is equivalent to running
 557
 558     $c->error(0);
 559
 560 =cut
 561
 562 sub clear_errors {
 563     my $c = shift;
 564     $c->error(0);
 565 }
 566
 567 sub _comp_search_prefixes {
 568     my $c = shift;
 569     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 570 }
 571
 572 # search components given a name and some prefixes
 573 sub _comp_names_search_prefixes {
 574     my ( $c, $name, @prefixes ) = @_;
 575     my $appclass = ref $c || $c;
 576     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 577     $filter = qr/$filter/; # Compile regex now rather than once per loop
 578
 579     # map the original component name to the sub part that we will search against
 580     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 581         grep { /$filter/ } keys %{ $c->components };
 582
 583     # undef for a name will return all
 584     return keys %eligible if !defined $name;
 585
 586     my $query  = $name->$_isa('Regexp') ? $name : qr/^$name$/i;
 587     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 588
 589     return @result if @result;
 590
 591     # if we were given a regexp to search against, we're done.
 592     return if $name->$_isa('Regexp');
 593
 594     # skip regexp fallback if configured
 595     return
 596         if $appclass->config->{disable_component_resolution_regex_fallback};
 597
 598     # regexp fallback
 599     $query  = qr/$name/i;
 600     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 601
 602     # no results? try against full names
 603     if( !@result ) {
 604         @result = grep { m{$query} } keys %eligible;
 605     }
 606
 607     # don't warn if we didn't find any results, it just might not exist
 608     if( @result ) {
 609         # Disgusting hack to work out correct method name
 610         my $warn_for = lc $prefixes[0];
 611         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 612            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 613            "component resolution is unreliable and unsafe.";
 614         my $short = $result[0];
 615         # remove the component namespace prefix
 616         $short =~ s/.*?(Model|Controller|View):://;
 617         my $shortmess = Carp::shortmess('');
 618         if ($shortmess =~ m#Catalyst/Plugin#) {
 619            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 620               "plugin's config";
 621         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 622            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 623               "component's config";
 624         } else {
 625            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 626               "but if you really wanted to search, pass in a regexp as the argument " .
 627               "like so: \$c->${warn_for}(qr/${name}/)";
 628         }
 629         $c->log->warn( "${msg}$shortmess" );
 630     }
 631
 632     return @result;
 633 }
 634
 635 # Find possible names for a prefix
 636 sub _comp_names {
 637     my ( $c, @prefixes ) = @_;
 638     my $appclass = ref $c || $c;
 639
 640     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 641
 642     my @names = map { s{$filter}{}; $_; }
 643         $c->_comp_names_search_prefixes( undef, @prefixes );
 644
 645     return @names;
 646 }
 647
 648 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 649 sub _filter_component {
 650     my ( $c, $comp, @args ) = @_;
 651
 652     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 653         return $comp->ACCEPT_CONTEXT( $c, @args );
 654     }
 655
 656     return $comp;
 657 }
 658
 659 =head2 COMPONENT ACCESSORS
 660
 661 =head2 $c->controller($name)
 662
 663 Gets a L<Catalyst::Controller> instance by name.
 664
 665     $c->controller('Foo')->do_stuff;
 666
 667 If the name is omitted, will return the controller for the dispatched
 668 action.
 669
 670 If you want to search for controllers, pass in a regexp as the argument.
 671
 672     # find all controllers that start with Foo
 673     my @foo_controllers = $c->controller(qr{^Foo});
 674
 675
 676 =cut
 677
 678 sub controller {
 679     my ( $c, $name, @args ) = @_;
 680
 681     my $appclass = ref($c) || $c;
 682     if( $name ) {
 683         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 684             my $comps = $c->components;
 685             my $check = $appclass."::Controller::".$name;
 686             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 687         }
 688         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 689         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 690         return $c->_filter_component( $result[ 0 ], @args );
 691     }
 692
 693     return $c->component( $c->action->class );
 694 }
 695
 696 =head2 $c->model($name)
 697
 698 Gets a L<Catalyst::Model> instance by name.
 699
 700     $c->model('Foo')->do_stuff;
 701
 702 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 703
 704 If the name is omitted, it will look for
 705  - a model object in $c->stash->{current_model_instance}, then
 706  - a model name in $c->stash->{current_model}, then
 707  - a config setting 'default_model', or
 708  - check if there is only one model, and return it if that's the case.
 709
 710 If you want to search for models, pass in a regexp as the argument.
 711
 712     # find all models that start with Foo
 713     my @foo_models = $c->model(qr{^Foo});
 714
 715 =cut
 716
 717 sub model {
 718     my ( $c, $name, @args ) = @_;
 719     my $appclass = ref($c) || $c;
 720     if( $name ) {
 721         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 722             my $comps = $c->components;
 723             my $check = $appclass."::Model::".$name;
 724             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 725         }
 726         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 727         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 728         return $c->_filter_component( $result[ 0 ], @args );
 729     }
 730
 731     if (ref $c) {
 732         return $c->stash->{current_model_instance}
 733           if $c->stash->{current_model_instance};
 734         return $c->model( $c->stash->{current_model} )
 735           if $c->stash->{current_model};
 736     }
 737     return $c->model( $appclass->config->{default_model} )
 738       if $appclass->config->{default_model};
 739
 740     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 741
 742     if( $rest ) {
 743         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 744         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 745         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 746         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 747         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 748     }
 749
 750     return $c->_filter_component( $comp );
 751 }
 752
 753
 754 =head2 $c->view($name)
 755
 756 Gets a L<Catalyst::View> instance by name.
 757
 758     $c->view('Foo')->do_stuff;
 759
 760 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 761
 762 If the name is omitted, it will look for
 763  - a view object in $c->stash->{current_view_instance}, then
 764  - a view name in $c->stash->{current_view}, then
 765  - a config setting 'default_view', or
 766  - check if there is only one view, and return it if that's the case.
 767
 768 If you want to search for views, pass in a regexp as the argument.
 769
 770     # find all views that start with Foo
 771     my @foo_views = $c->view(qr{^Foo});
 772
 773 =cut
 774
 775 sub view {
 776     my ( $c, $name, @args ) = @_;
 777
 778     my $appclass = ref($c) || $c;
 779     if( $name ) {
 780         unless ( $name->$_isa('Regexp') ) { # Direct component hash lookup to avoid costly regexps
 781             my $comps = $c->components;
 782             my $check = $appclass."::View::".$name;
 783             if( exists $comps->{$check} ) {
 784                 return $c->_filter_component( $comps->{$check}, @args );
 785             }
 786             else {
 787                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 788             }
 789         }
 790         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 791         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 792         return $c->_filter_component( $result[ 0 ], @args );
 793     }
 794
 795     if (ref $c) {
 796         return $c->stash->{current_view_instance}
 797           if $c->stash->{current_view_instance};
 798         return $c->view( $c->stash->{current_view} )
 799           if $c->stash->{current_view};
 800     }
 801     return $c->view( $appclass->config->{default_view} )
 802       if $appclass->config->{default_view};
 803
 804     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 805
 806     if( $rest ) {
 807         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 808         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 809         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 810         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 811         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 812     }
 813
 814     return $c->_filter_component( $comp );
 815 }
 816
 817 =head2 $c->controllers
 818
 819 Returns the available names which can be passed to $c->controller
 820
 821 =cut
 822
 823 sub controllers {
 824     my ( $c ) = @_;
 825     return $c->_comp_names(qw/Controller C/);
 826 }
 827
 828 =head2 $c->models
 829
 830 Returns the available names which can be passed to $c->model
 831
 832 =cut
 833
 834 sub models {
 835     my ( $c ) = @_;
 836     return $c->_comp_names(qw/Model M/);
 837 }
 838
 839
 840 =head2 $c->views
 841
 842 Returns the available names which can be passed to $c->view
 843
 844 =cut
 845
 846 sub views {
 847     my ( $c ) = @_;
 848     return $c->_comp_names(qw/View V/);
 849 }
 850
 851 =head2 $c->comp($name)
 852
 853 =head2 $c->component($name)
 854
 855 Gets a component object by name. This method is not recommended,
 856 unless you want to get a specific component by full
 857 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 858 should be used instead.
 859
 860 If C<$name> is a regexp, a list of components matched against the full
 861 component name will be returned.
 862
 863 If Catalyst can't find a component by name, it will fallback to regex
 864 matching by default. To disable this behaviour set
 865 disable_component_resolution_regex_fallback to a true value.
 866
 867     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 868
 869 =cut
 870
 871 sub component {
 872     my ( $c, $name, @args ) = @_;
 873
 874     if( $name ) {
 875         my $comps = $c->components;
 876
 877         if( !ref $name ) {
 878             # is it the exact name?
 879             return $c->_filter_component( $comps->{ $name }, @args )
 880                        if exists $comps->{ $name };
 881
 882             # perhaps we just omitted "MyApp"?
 883             my $composed = ( ref $c || $c ) . "::${name}";
 884             return $c->_filter_component( $comps->{ $composed }, @args )
 885                        if exists $comps->{ $composed };
 886
 887             # search all of the models, views and controllers
 888             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 889             return $c->_filter_component( $comp, @args ) if $comp;
 890         }
 891
 892         return
 893             if $c->config->{disable_component_resolution_regex_fallback};
 894
 895         # This is here so $c->comp( '::M::' ) works
 896         my $query = ref $name ? $name : qr{$name}i;
 897
 898         my @result = grep { m{$query} } keys %{ $c->components };
 899         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 900
 901         if( $result[ 0 ] ) {
 902             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 903             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 904             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 905             return $c->_filter_component( $result[ 0 ], @args );
 906         }
 907
 908         # I would expect to return an empty list here, but that breaks back-compat
 909     }
 910
 911     # fallback
 912     return sort keys %{ $c->components };
 913 }
 914
 915 =head2 CLASS DATA AND HELPER CLASSES
 916
 917 =head2 $c->config
 918
 919 Returns or takes a hashref containing the application's configuration.
 920
 921     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 922
 923 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 924 like C<myapp.conf> in your applications home directory. See
 925 L<Catalyst::Plugin::ConfigLoader>.
 926
 927 =head3 Cascading configuration
 928
 929 The config method is present on all Catalyst components, and configuration
 930 will be merged when an application is started. Configuration loaded with
 931 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 932 followed by configuration in your top level C<MyApp> class. These two
 933 configurations are merged, and then configuration data whose hash key matches a
 934 component name is merged with configuration for that component.
 935
 936 The configuration for a component is then passed to the C<new> method when a
 937 component is constructed.
 938
 939 For example:
 940
 941     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 942     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 943
 944 will mean that C<MyApp::Model::Foo> receives the following data when
 945 constructed:
 946
 947     MyApp::Model::Foo->new({
 948         bar => 'baz',
 949         quux => 'frob',
 950         overrides => 'me',
 951     });
 952
 953 It's common practice to use a Moose attribute
 954 on the receiving component to access the config value.
 955
 956     package MyApp::Model::Foo;
 957
 958     use Moose;
 959
 960     # this attr will receive 'baz' at construction time
 961     has 'bar' => (
 962         is  => 'rw',
 963         isa => 'Str',
 964     );
 965
 966 You can then get the value 'baz' by calling $c->model('Foo')->bar
 967 (or $self->bar inside code in the model).
 968
 969 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 970 as a way of reading config within your code, as this B<will not> give you the
 971 correctly merged config back. You B<MUST> take the config values supplied to
 972 the constructor and use those instead.
 973
 974 =cut
 975
 976 around config => sub {
 977     my $orig = shift;
 978     my $c = shift;
 979
 980     croak('Setting config after setup has been run is not allowed.')
 981         if ( @_ and $c->setup_finished );
 982
 983     $c->$orig(@_);
 984 };
 985
 986 =head2 $c->log
 987
 988 Returns the logging object instance. Unless it is already set, Catalyst
 989 sets this up with a L<Catalyst::Log> object. To use your own log class,
 990 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 991 C<< __PACKAGE__->setup >>.
 992
 993  __PACKAGE__->log( MyLogger->new );
 994  __PACKAGE__->setup;
 995
 996 And later:
 997
 998     $c->log->info( 'Now logging with my own logger!' );
 999
1000 Your log class should implement the methods described in
1001 L<Catalyst::Log>.
1002
1003
1004 =head2 $c->debug
1005
1006 Returns 1 if debug mode is enabled, 0 otherwise.
1007
1008 You can enable debug mode in several ways:
1009
1010 =over
1011
1012 =item By calling myapp_server.pl with the -d flag
1013
1014 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
1015
1016 =item The -Debug option in your MyApp.pm
1017
1018 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
1019
1020 =back
1021
1022 The first three also set the log level to 'debug'.
1023
1024 Calling C<< $c->debug(1) >> has no effect.
1025
1026 =cut
1027
1028 sub debug { 0 }
1029
1030 =head2 $c->dispatcher
1031
1032 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
1033
1034 =head2 $c->engine
1035
1036 Returns the engine instance. See L<Catalyst::Engine>.
1037
1038
1039 =head2 UTILITY METHODS
1040
1041 =head2 $c->path_to(@path)
1042
1043 Merges C<@path> with C<< $c->config->{home} >> and returns a
1044 L<Path::Class::Dir> object. Note you can usually use this object as
1045 a filename, but sometimes you will have to explicitly stringify it
1046 yourself by calling the C<< ->stringify >> method.
1047
1048 For example:
1049
1050     $c->path_to( 'db', 'sqlite.db' );
1051
1052 =cut
1053
1054 sub path_to {
1055     my ( $c, @path ) = @_;
1056     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
1057     if ( -d $path ) { return $path }
1058     else { return Path::Class::File->new( $c->config->{home}, @path ) }
1059 }
1060
1061 sub plugin {
1062     my ( $class, $name, $plugin, @args ) = @_;
1063
1064     # See block comment in t/unit_core_plugin.t
1065     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1066
1067     $class->_register_plugin( $plugin, 1 );
1068
1069     eval { $plugin->import };
1070     $class->mk_classdata($name);
1071     my $obj;
1072     eval { $obj = $plugin->new(@args) };
1073
1074     if ($@) {
1075         Catalyst::Exception->throw( message =>
1076               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1077     }
1078
1079     $class->$name($obj);
1080     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1081       if $class->debug;
1082 }
1083
1084 =head2 MyApp->setup
1085
1086 Initializes the dispatcher and engine, loads any plugins, and loads the
1087 model, view, and controller components. You may also specify an array
1088 of plugins to load here, if you choose to not load them in the C<use
1089 Catalyst> line.
1090
1091     MyApp->setup;
1092     MyApp->setup( qw/-Debug/ );
1093
1094 B<Note:> You B<should not> wrap this method with method modifiers
1095 or bad things will happen - wrap the C<setup_finalize> method instead.
1096
1097 =cut
1098
1099 sub setup {
1100     my ( $class, @arguments ) = @_;
1101     croak('Running setup more than once')
1102         if ( $class->setup_finished );
1103
1104     unless ( $class->isa('Catalyst') ) {
1105
1106         Catalyst::Exception->throw(
1107             message => qq/'$class' does not inherit from Catalyst/ );
1108     }
1109
1110     if ( $class->arguments ) {
1111         @arguments = ( @arguments, @{ $class->arguments } );
1112     }
1113
1114     # Process options
1115     my $flags = {};
1116
1117     foreach (@arguments) {
1118
1119         if (/^-Debug$/) {
1120             $flags->{log} =
1121               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1122         }
1123         elsif (/^-(\w+)=?(.*)$/) {
1124             $flags->{ lc $1 } = $2;
1125         }
1126         else {
1127             push @{ $flags->{plugins} }, $_;
1128         }
1129     }
1130
1131     $class->setup_home( delete $flags->{home} );
1132
1133     $class->setup_log( delete $flags->{log} );
1134     $class->setup_plugins( delete $flags->{plugins} );
1135
1136     # Call plugins setup, this is stupid and evil.
1137     # Also screws C3 badly on 5.10, hack to avoid.
1138     {
1139         no warnings qw/redefine/;
1140         local *setup = sub { };
1141         $class->setup unless $Catalyst::__AM_RESTARTING;
1142     }
1143
1144     $class->setup_middleware();
1145     $class->setup_data_handlers();
1146     $class->setup_dispatcher( delete $flags->{dispatcher} );
1147     if (my $engine = delete $flags->{engine}) {
1148         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1149     }
1150     $class->setup_engine();
1151     $class->setup_stats( delete $flags->{stats} );
1152
1153     for my $flag ( sort keys %{$flags} ) {
1154
1155         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1156             &$code( $class, delete $flags->{$flag} );
1157         }
1158         else {
1159             $class->log->warn(qq/Unknown flag "$flag"/);
1160         }
1161     }
1162
1163     eval { require Catalyst::Devel; };
1164     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1165         $class->log->warn(<<"EOF");
1166 You are running an old script!
1167
1168   Please update by running (this will overwrite existing files):
1169     catalyst.pl -force -scripts $class
1170
1171   or (this will not overwrite existing files):
1172     catalyst.pl -scripts $class
1173
1174 EOF
1175     }
1176
1177     # Initialize our data structure
1178     $class->components( {} );
1179
1180     $class->setup_components;
1181
1182     if ( $class->debug ) {
1183         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1184
1185         if (@plugins) {
1186             my $column_width = Catalyst::Utils::term_width() - 6;
1187             my $t = Text::SimpleTable->new($column_width);
1188             $t->row($_) for @plugins;
1189             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1190         }
1191
1192         my @middleware = map {
1193           ref $_ eq 'CODE' ?
1194             "Inline Coderef" :
1195               (ref($_) .'  '. ($_->can('VERSION') ? $_->VERSION || '' : '')
1196                 || '')  } $class->registered_middlewares;
1197
1198         if (@middleware) {
1199             my $column_width = Catalyst::Utils::term_width() - 6;
1200             my $t = Text::SimpleTable->new($column_width);
1201             $t->row($_) for @middleware;
1202             $class->log->debug( "Loaded PSGI Middleware:\n" . $t->draw . "\n" );
1203         }
1204
1205         my %dh = $class->registered_data_handlers;
1206         if (my @data_handlers = keys %dh) {
1207             my $column_width = Catalyst::Utils::term_width() - 6;
1208             my $t = Text::SimpleTable->new($column_width);
1209             $t->row($_) for @data_handlers;
1210             $class->log->debug( "Loaded Request Data Handlers:\n" . $t->draw . "\n" );
1211         }
1212
1213         my $dispatcher = $class->dispatcher;
1214         my $engine     = $class->engine;
1215         my $home       = $class->config->{home};
1216
1217         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1218         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1219
1220         $home
1221           ? ( -d $home )
1222           ? $class->log->debug(qq/Found home "$home"/)
1223           : $class->log->debug(qq/Home "$home" doesn't exist/)
1224           : $class->log->debug(q/Couldn't find home/);
1225
1226         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1227         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1228         for my $comp ( sort keys %{ $class->components } ) {
1229             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1230             $t->row( $comp, $type );
1231         }
1232         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1233           if ( keys %{ $class->components } );
1234     }
1235
1236     # Add our self to components, since we are also a component
1237     if( $class->isa('Catalyst::Controller') ){
1238       $class->components->{$class} = $class;
1239     }
1240
1241     $class->setup_actions;
1242
1243     if ( $class->debug ) {
1244         my $name = $class->config->{name} || 'Application';
1245         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1246     }
1247
1248     if ($class->config->{case_sensitive}) {
1249         $class->log->warn($class . "->config->{case_sensitive} is set.");
1250         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1251     }
1252
1253     $class->setup_finalize;
1254     # Should be the last thing we do so that user things hooking
1255     # setup_finalize can log..
1256     $class->log->_flush() if $class->log->can('_flush');
1257     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1258 }
1259
1260 =head2 $app->setup_finalize
1261
1262 A hook to attach modifiers to. This method does not do anything except set the
1263 C<setup_finished> accessor.
1264
1265 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1266
1267 Example:
1268
1269     after setup_finalize => sub {
1270         my $app = shift;
1271
1272         ## do stuff here..
1273     };
1274
1275 =cut
1276
1277 sub setup_finalize {
1278     my ($class) = @_;
1279     $class->setup_finished(1);
1280 }
1281
1282 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1283
1284 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1285
1286 Constructs an absolute L<URI> object based on the application root, the
1287 provided path, and the additional arguments and query parameters provided.
1288 When used as a string, provides a textual URI.  If you need more flexibility
1289 than this (i.e. the option to provide relative URIs etc.) see
1290 L<Catalyst::Plugin::SmartURI>.
1291
1292 If no arguments are provided, the URI for the current action is returned.
1293 To return the current action and also provide @args, use
1294 C<< $c->uri_for( $c->action, @args ) >>.
1295
1296 If the first argument is a string, it is taken as a public URI path relative
1297 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1298 relative to the application root (if it does). It is then merged with
1299 C<< $c->request->base >>; any C<@args> are appended as additional path
1300 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1301
1302 If the first argument is a L<Catalyst::Action> it represents an action which
1303 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1304 optional C<\@captures> argument (an arrayref) allows passing the captured
1305 variables that are needed to fill in the paths of Chained and Regex actions;
1306 once the path is resolved, C<uri_for> continues as though a path was
1307 provided, appending any arguments or parameters and creating an absolute
1308 URI.
1309
1310 The captures for the current request can be found in
1311 C<< $c->request->captures >>, and actions can be resolved using
1312 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1313 path, use C<< $c->uri_for_action >> instead.
1314
1315   # Equivalent to $c->req->uri
1316   $c->uri_for($c->action, $c->req->captures,
1317       @{ $c->req->args }, $c->req->params);
1318
1319   # For the Foo action in the Bar controller
1320   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1321
1322   # Path to a static resource
1323   $c->uri_for('/static/images/logo.png');
1324
1325 =cut
1326
1327 sub uri_for {
1328     my ( $c, $path, @args ) = @_;
1329
1330     if ( $path->$_isa('Catalyst::Controller') ) {
1331         $path = $path->path_prefix;
1332         $path =~ s{/+\z}{};
1333         $path .= '/';
1334     }
1335
1336     undef($path) if (defined $path && $path eq '');
1337
1338     my $params =
1339       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1340
1341     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1342     foreach my $arg (@args) {
1343         utf8::encode($arg) if utf8::is_utf8($arg);
1344         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1345     }
1346
1347     if ( $path->$_isa('Catalyst::Action') ) { # action object
1348         s|/|%2F|g for @args;
1349         my $captures = [ map { s|/|%2F|g; $_; }
1350                         ( scalar @args && ref $args[0] eq 'ARRAY'
1351                          ? @{ shift(@args) }
1352                          : ()) ];
1353
1354         foreach my $capture (@$captures) {
1355             utf8::encode($capture) if utf8::is_utf8($capture);
1356             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1357         }
1358
1359         my $action = $path;
1360         # ->uri_for( $action, \@captures_and_args, \%query_values? )
1361         if( !@args && $action->number_of_args ) {
1362             my $expanded_action = $c->dispatcher->expand_action( $action );
1363
1364             my $num_captures = $expanded_action->number_of_captures;
1365             unshift @args, splice @$captures, $num_captures;
1366         }
1367
1368        $path = $c->dispatcher->uri_for_action($action, $captures);
1369         if (not defined $path) {
1370             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1371                 if $c->debug;
1372             return undef;
1373         }
1374         $path = '/' if $path eq '';
1375     }
1376
1377     unshift(@args, $path);
1378
1379     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1380         my $namespace = $c->namespace;
1381         if (defined $path) { # cheesy hack to handle path '../foo'
1382            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1383         }
1384         unshift(@args, $namespace || '');
1385     }
1386
1387     # join args with '/', or a blank string
1388     my $args = join('/', grep { defined($_) } @args);
1389     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1390     $args =~ s!^/+!!;
1391
1392     my ($base, $class) = ('/', 'URI::_generic');
1393     if(blessed($c)) {
1394       $base = $c->req->base;
1395       $class = ref($base);
1396       $base =~ s{(?<!/)$}{/};
1397     }
1398
1399     my $query = '';
1400
1401     if (my @keys = keys %$params) {
1402       # somewhat lifted from URI::_query's query_form
1403       $query = '?'.join('&', map {
1404           my $val = $params->{$_};
1405           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1406           s/ /+/g;
1407           my $key = $_;
1408           $val = '' unless defined $val;
1409           (map {
1410               my $param = "$_";
1411               utf8::encode( $param ) if utf8::is_utf8($param);
1412               # using the URI::Escape pattern here so utf8 chars survive
1413               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1414               $param =~ s/ /+/g;
1415               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1416       } @keys);
1417     }
1418
1419     my $res = bless(\"${base}${args}${query}", $class);
1420     $res;
1421 }
1422
1423 =head2 $c->uri_for_action( $path, \@captures_and_args?, @args?, \%query_values? )
1424
1425 =head2 $c->uri_for_action( $action, \@captures_and_args?, @args?, \%query_values? )
1426
1427 =over
1428
1429 =item $path
1430
1431 A private path to the Catalyst action you want to create a URI for.
1432
1433 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1434 >> and passing the resulting C<$action> and the remaining arguments to C<<
1435 $c->uri_for >>.
1436
1437 You can also pass in a Catalyst::Action object, in which case it is passed to
1438 C<< $c->uri_for >>.
1439
1440 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1441
1442 For example, if the action looks like:
1443
1444  package MyApp::Controller::Users;
1445
1446  sub lst : Path('the-list') {}
1447
1448 You can use:
1449
1450  $c->uri_for_action('/users/lst')
1451
1452 and it will create the URI /users/the-list.
1453
1454 =item \@captures_and_args?
1455
1456 Optional array reference of Captures (i.e. C<<CaptureArgs or $c->req->captures>)
1457 and arguments to the request. Usually used with L<Catalyst::DispatchType::Chained>
1458 to interpolate all the parameters in the URI.
1459
1460 =item @args?
1461
1462 Optional list of extra arguments - can be supplied in the
1463 C<< \@captures_and_args? >> array ref, or here - whichever is easier for your
1464 code.
1465
1466 Your action can have zero, a fixed or a variable number of args (e.g.
1467 C<< Args(1) >> for a fixed number or C<< Args() >> for a variable number)..
1468
1469 =item \%query_values?
1470
1471 Optional array reference of query parameters to append. E.g.
1472
1473   { foo => 'bar' }
1474
1475 will generate
1476
1477   /rest/of/your/uri?foo=bar
1478
1479 =back
1480
1481 =cut
1482
1483 sub uri_for_action {
1484     my ( $c, $path, @args ) = @_;
1485     my $action = blessed($path)
1486       ? $path
1487       : $c->dispatcher->get_action_by_path($path);
1488     unless (defined $action) {
1489       croak "Can't find action for path '$path'";
1490     }
1491     return $c->uri_for( $action, @args );
1492 }
1493
1494 =head2 $c->welcome_message
1495
1496 Returns the Catalyst welcome HTML page.
1497
1498 =cut
1499
1500 sub welcome_message {
1501     my $c      = shift;
1502     my $name   = $c->config->{name};
1503     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1504     my $prefix = Catalyst::Utils::appprefix( ref $c );
1505     $c->response->content_type('text/html; charset=utf-8');
1506     return <<"EOF";
1507 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1508     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1509 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1510     <head>
1511     <meta http-equiv="Content-Language" content="en" />
1512     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1513         <title>$name on Catalyst $VERSION</title>
1514         <style type="text/css">
1515             body {
1516                 color: #000;
1517                 background-color: #eee;
1518             }
1519             div#content {
1520                 width: 640px;
1521                 margin-left: auto;
1522                 margin-right: auto;
1523                 margin-top: 10px;
1524                 margin-bottom: 10px;
1525                 text-align: left;
1526                 background-color: #ccc;
1527                 border: 1px solid #aaa;
1528             }
1529             p, h1, h2 {
1530                 margin-left: 20px;
1531                 margin-right: 20px;
1532                 font-family: verdana, tahoma, sans-serif;
1533             }
1534             a {
1535                 font-family: verdana, tahoma, sans-serif;
1536             }
1537             :link, :visited {
1538                     text-decoration: none;
1539                     color: #b00;
1540                     border-bottom: 1px dotted #bbb;
1541             }
1542             :link:hover, :visited:hover {
1543                     color: #555;
1544             }
1545             div#topbar {
1546                 margin: 0px;
1547             }
1548             pre {
1549                 margin: 10px;
1550                 padding: 8px;
1551             }
1552             div#answers {
1553                 padding: 8px;
1554                 margin: 10px;
1555                 background-color: #fff;
1556                 border: 1px solid #aaa;
1557             }
1558             h1 {
1559                 font-size: 0.9em;
1560                 font-weight: normal;
1561                 text-align: center;
1562             }
1563             h2 {
1564                 font-size: 1.0em;
1565             }
1566             p {
1567                 font-size: 0.9em;
1568             }
1569             p img {
1570                 float: right;
1571                 margin-left: 10px;
1572             }
1573             span#appname {
1574                 font-weight: bold;
1575                 font-size: 1.6em;
1576             }
1577         </style>
1578     </head>
1579     <body>
1580         <div id="content">
1581             <div id="topbar">
1582                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1583                     $VERSION</h1>
1584              </div>
1585              <div id="answers">
1586                  <p>
1587                  <img src="$logo" alt="Catalyst Logo" />
1588                  </p>
1589                  <p>Welcome to the  world of Catalyst.
1590                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1591                     framework will make web development something you had
1592                     never expected it to be: Fun, rewarding, and quick.</p>
1593                  <h2>What to do now?</h2>
1594                  <p>That really depends  on what <b>you</b> want to do.
1595                     We do, however, provide you with a few starting points.</p>
1596                  <p>If you want to jump right into web development with Catalyst
1597                     you might want to start with a tutorial.</p>
1598 <pre>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Tutorial">Catalyst::Manual::Tutorial</a></code>
1599 </pre>
1600 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1601 <pre>
1602 <code>perldoc <a href="https://metacpan.org/module/Catalyst::Manual::Intro">Catalyst::Manual::Intro</a>
1603 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1604 </code></pre>
1605                  <h2>What to do next?</h2>
1606                  <p>Next it's time to write an actual application. Use the
1607                     helper scripts to generate <a href="https://metacpan.org/search?q=Catalyst%3A%3AController">controllers</a>,
1608                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AModel">models</a>, and
1609                     <a href="https://metacpan.org/search?q=Catalyst%3A%3AView">views</a>;
1610                     they can save you a lot of work.</p>
1611                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1612                     <p>Also, be sure to check out the vast and growing
1613                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1614                     you are likely to find what you need there.
1615                     </p>
1616
1617                  <h2>Need help?</h2>
1618                  <p>Catalyst has a very active community. Here are the main places to
1619                     get in touch with us.</p>
1620                  <ul>
1621                      <li>
1622                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1623                      </li>
1624                      <li>
1625                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1626                      </li>
1627                      <li>
1628                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1629                      </li>
1630                  </ul>
1631                  <h2>In conclusion</h2>
1632                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1633                     as we enjoyed making it. Please contact us if you have ideas
1634                     for improvement or other feedback.</p>
1635              </div>
1636          </div>
1637     </body>
1638 </html>
1639 EOF
1640 }
1641
1642 =head2 run_options
1643
1644 Contains a hash of options passed from the application script, including
1645 the original ARGV the script received, the processed values from that
1646 ARGV and any extra arguments to the script which were not processed.
1647
1648 This can be used to add custom options to your application's scripts
1649 and setup your application differently depending on the values of these
1650 options.
1651
1652 =head1 INTERNAL METHODS
1653
1654 These methods are not meant to be used by end users.
1655
1656 =head2 $c->components
1657
1658 Returns a hash of components.
1659
1660 =head2 $c->context_class
1661
1662 Returns or sets the context class.
1663
1664 =head2 $c->counter
1665
1666 Returns a hashref containing coderefs and execution counts (needed for
1667 deep recursion detection).
1668
1669 =head2 $c->depth
1670
1671 Returns the number of actions on the current internal execution stack.
1672
1673 =head2 $c->dispatch
1674
1675 Dispatches a request to actions.
1676
1677 =cut
1678
1679 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1680
1681 =head2 $c->dispatcher_class
1682
1683 Returns or sets the dispatcher class.
1684
1685 =head2 $c->dump_these
1686
1687 Returns a list of 2-element array references (name, structure) pairs
1688 that will be dumped on the error page in debug mode.
1689
1690 =cut
1691
1692 sub dump_these {
1693     my $c = shift;
1694     [ Request => $c->req ],
1695     [ Response => $c->res ],
1696     [ Stash => $c->stash ],
1697     [ Config => $c->config ];
1698 }
1699
1700 =head2 $c->engine_class
1701
1702 Returns or sets the engine class.
1703
1704 =head2 $c->execute( $class, $coderef )
1705
1706 Execute a coderef in given class and catch exceptions. Errors are available
1707 via $c->error.
1708
1709 =cut
1710
1711 sub execute {
1712     my ( $c, $class, $code ) = @_;
1713     $class = $c->component($class) || $class;
1714     $c->state(0);
1715
1716     if ( $c->depth >= $RECURSION ) {
1717         my $action = $code->reverse();
1718         $action = "/$action" unless $action =~ /->/;
1719         my $error = qq/Deep recursion detected calling "${action}"/;
1720         $c->log->error($error);
1721         $c->error($error);
1722         $c->state(0);
1723         return $c->state;
1724     }
1725
1726     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1727
1728     push( @{ $c->stack }, $code );
1729
1730     no warnings 'recursion';
1731     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1732     #      I have no idea how, ergo $ret (which appears to fix the issue)
1733     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1734
1735     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1736
1737     my $last = pop( @{ $c->stack } );
1738
1739     if ( my $error = $@ ) {
1740         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1741             $error->rethrow if $c->depth > 1;
1742         }
1743         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1744             $error->rethrow if $c->depth > 0;
1745         }
1746         else {
1747             unless ( ref $error ) {
1748                 no warnings 'uninitialized';
1749                 chomp $error;
1750                 my $class = $last->class;
1751                 my $name  = $last->name;
1752                 $error = qq/Caught exception in $class->$name "$error"/;
1753             }
1754             $c->error($error);
1755         }
1756         $c->state(0);
1757     }
1758     return $c->state;
1759 }
1760
1761 sub _stats_start_execute {
1762     my ( $c, $code ) = @_;
1763     my $appclass = ref($c) || $c;
1764     return if ( ( $code->name =~ /^_.*/ )
1765         && ( !$appclass->config->{show_internal_actions} ) );
1766
1767     my $action_name = $code->reverse();
1768     $c->counter->{$action_name}++;
1769
1770     my $action = $action_name;
1771     $action = "/$action" unless $action =~ /->/;
1772
1773     # determine if the call was the result of a forward
1774     # this is done by walking up the call stack and looking for a calling
1775     # sub of Catalyst::forward before the eval
1776     my $callsub = q{};
1777     for my $index ( 2 .. 11 ) {
1778         last
1779         if ( ( caller($index) )[0] eq 'Catalyst'
1780             && ( caller($index) )[3] eq '(eval)' );
1781
1782         if ( ( caller($index) )[3] =~ /forward$/ ) {
1783             $callsub = ( caller($index) )[3];
1784             $action  = "-> $action";
1785             last;
1786         }
1787     }
1788
1789     my $uid = $action_name . $c->counter->{$action_name};
1790
1791     # is this a root-level call or a forwarded call?
1792     if ( $callsub =~ /forward$/ ) {
1793         my $parent = $c->stack->[-1];
1794
1795         # forward, locate the caller
1796         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1797             $c->stats->profile(
1798                 begin  => $action,
1799                 parent => "$parent" . $c->counter->{"$parent"},
1800                 uid    => $uid,
1801             );
1802         }
1803         else {
1804
1805             # forward with no caller may come from a plugin
1806             $c->stats->profile(
1807                 begin => $action,
1808                 uid   => $uid,
1809             );
1810         }
1811     }
1812     else {
1813
1814         # root-level call
1815         $c->stats->profile(
1816             begin => $action,
1817             uid   => $uid,
1818         );
1819     }
1820     return $action;
1821
1822 }
1823
1824 sub _stats_finish_execute {
1825     my ( $c, $info ) = @_;
1826     $c->stats->profile( end => $info );
1827 }
1828
1829 =head2 $c->finalize
1830
1831 Finalizes the request.
1832
1833 =cut
1834
1835 sub finalize {
1836     my $c = shift;
1837
1838     for my $error ( @{ $c->error } ) {
1839         $c->log->error($error);
1840     }
1841
1842     # Support skipping finalize for psgix.io style 'jailbreak'.  Used to support
1843     # stuff like cometd and websockets
1844
1845     if($c->request->_has_io_fh) {
1846       $c->log_response;
1847       return;
1848     }
1849
1850     # Allow engine to handle finalize flow (for POE)
1851     my $engine = $c->engine;
1852     if ( my $code = $engine->can('finalize') ) {
1853         $engine->$code($c);
1854     }
1855     else {
1856
1857         $c->finalize_uploads;
1858
1859         # Error
1860         if ( $#{ $c->error } >= 0 ) {
1861             $c->finalize_error;
1862         }
1863
1864         $c->finalize_headers unless $c->response->finalized_headers;
1865
1866         $c->finalize_body;
1867     }
1868
1869     $c->log_response;
1870
1871     if ($c->use_stats) {
1872         my $elapsed = $c->stats->elapsed;
1873         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1874         $c->log->info(
1875             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1876     }
1877
1878     return $c->response->status;
1879 }
1880
1881 =head2 $c->finalize_body
1882
1883 Finalizes body.
1884
1885 =cut
1886
1887 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1888
1889 =head2 $c->finalize_cookies
1890
1891 Finalizes cookies.
1892
1893 =cut
1894
1895 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1896
1897 =head2 $c->finalize_error
1898
1899 Finalizes error.  If there is only one error in L</error> and it is an object that
1900 does C<as_psgi> or C<code> we rethrow the error and presume it caught by middleware
1901 up the ladder.  Otherwise we return the debugging error page (in debug mode) or we
1902 return the default error page (production mode).
1903
1904 =cut
1905
1906 sub finalize_error {
1907     my $c = shift;
1908     if($#{$c->error} > 0) {
1909         $c->engine->finalize_error( $c, @_ );
1910     } else {
1911         my ($error) = @{$c->error};
1912         if(
1913           blessed $error &&
1914           ($error->can('as_psgi') || $error->can('code'))
1915         ) {
1916             # In the case where the error 'knows what it wants', becauses its PSGI
1917             # aware, just rethow and let middleware catch it
1918             $error->can('rethrow') ? $error->rethrow : croak $error;
1919             croak $error;
1920         } else {
1921             $c->engine->finalize_error( $c, @_ )
1922         }
1923     }
1924 }
1925
1926 =head2 $c->finalize_headers
1927
1928 Finalizes headers.
1929
1930 =cut
1931
1932 sub finalize_headers {
1933     my $c = shift;
1934
1935     my $response = $c->response; #accessor calls can add up?
1936
1937     # Check if we already finalized headers
1938     return if $response->finalized_headers;
1939
1940     # Handle redirects
1941     if ( my $location = $response->redirect ) {
1942         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1943         $response->header( Location => $location );
1944     }
1945
1946     # Remove incorrectly added body and content related meta data when returning
1947     # an information response, or a response the is required to not include a body
1948
1949     $c->finalize_cookies;
1950
1951     $c->response->finalize_headers();
1952
1953     # Done
1954     $response->finalized_headers(1);
1955 }
1956
1957 =head2 $c->finalize_output
1958
1959 An alias for finalize_body.
1960
1961 =head2 $c->finalize_read
1962
1963 Finalizes the input after reading is complete.
1964
1965 =cut
1966
1967 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1968
1969 =head2 $c->finalize_uploads
1970
1971 Finalizes uploads. Cleans up any temporary files.
1972
1973 =cut
1974
1975 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1976
1977 =head2 $c->get_action( $action, $namespace )
1978
1979 Gets an action in a given namespace.
1980
1981 =cut
1982
1983 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1984
1985 =head2 $c->get_actions( $action, $namespace )
1986
1987 Gets all actions of a given name in a namespace and all parent
1988 namespaces.
1989
1990 =cut
1991
1992 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1993
1994 =head2 $app->handle_request( @arguments )
1995
1996 Called to handle each HTTP request.
1997
1998 =cut
1999
2000 sub handle_request {
2001     my ( $class, @arguments ) = @_;
2002
2003     # Always expect worst case!
2004     my $status = -1;
2005     try {
2006         if ($class->debug) {
2007             my $secs = time - $START || 1;
2008             my $av = sprintf '%.3f', $COUNT / $secs;
2009             my $time = localtime time;
2010             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
2011         }
2012
2013         my $c = $class->prepare(@arguments);
2014         $c->dispatch;
2015         $status = $c->finalize;
2016     } catch {
2017         chomp(my $error = $_);
2018         $class->log->error(qq/Caught exception in engine "$error"/);
2019         #rethow if this can be handled by middleware
2020         if(blessed $error && ($error->can('as_psgi') || $error->can('code'))) {
2021             $error->can('rethrow') ? $error->rethrow : croak $error;
2022         }
2023     };
2024
2025     $COUNT++;
2026
2027     if(my $coderef = $class->log->can('_flush')){
2028         $class->log->$coderef();
2029     }
2030     return $status;
2031 }
2032
2033 =head2 $class->prepare( @arguments )
2034
2035 Creates a Catalyst context from an engine-specific request (Apache, CGI,
2036 etc.).
2037
2038 =cut
2039
2040 has _uploadtmp => (
2041     is => 'ro',
2042     predicate => '_has_uploadtmp',
2043 );
2044
2045 sub prepare {
2046     my ( $class, @arguments ) = @_;
2047
2048     # XXX
2049     # After the app/ctxt split, this should become an attribute based on something passed
2050     # into the application.
2051     $class->context_class( ref $class || $class ) unless $class->context_class;
2052
2053     my $uploadtmp = $class->config->{uploadtmp};
2054     my $c = $class->context_class->new({ $uploadtmp ? (_uploadtmp => $uploadtmp) : ()});
2055
2056     $c->response->_context($c);
2057
2058     #surely this is not the most efficient way to do things...
2059     $c->stats($class->stats_class->new)->enable($c->use_stats);
2060     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
2061         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
2062     }
2063
2064     try {
2065         # Allow engine to direct the prepare flow (for POE)
2066         if ( my $prepare = $c->engine->can('prepare') ) {
2067             $c->engine->$prepare( $c, @arguments );
2068         }
2069         else {
2070             $c->prepare_request(@arguments);
2071             $c->prepare_connection;
2072             $c->prepare_query_parameters;
2073             $c->prepare_headers; # Just hooks, no longer needed - they just
2074             $c->prepare_cookies; # cause the lazy attribute on req to build
2075             $c->prepare_path;
2076
2077             # Prepare the body for reading, either by prepare_body
2078             # or the user, if they are using $c->read
2079             $c->prepare_read;
2080
2081             # Parse the body unless the user wants it on-demand
2082             unless ( ref($c)->config->{parse_on_demand} ) {
2083                 $c->prepare_body;
2084             }
2085         }
2086         $c->prepare_action;
2087     }
2088     # VERY ugly and probably shouldn't rely on ->finalize actually working
2089     catch {
2090         # failed prepare is always due to an invalid request, right?
2091         $c->response->status(400);
2092         $c->response->content_type('text/plain');
2093         $c->response->body('Bad Request');
2094         # Note we call finalize and then die here, which escapes
2095         # finalize being called in the enclosing block..
2096         # It in fact couldn't be called, as we don't return $c..
2097         # This is a mess - but I'm unsure you can fix this without
2098         # breaking compat for people doing crazy things (we should set
2099         # the 400 and just return the ctx here IMO, letting finalize get called
2100         # above...
2101         $c->finalize;
2102         die $_;
2103     };
2104
2105     $c->log_request;
2106
2107     return $c;
2108 }
2109
2110 =head2 $c->prepare_action
2111
2112 Prepares action. See L<Catalyst::Dispatcher>.
2113
2114 =cut
2115
2116 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2117
2118 =head2 $c->prepare_body
2119
2120 Prepares message body.
2121
2122 =cut
2123
2124 sub prepare_body {
2125     my $c = shift;
2126
2127     return if $c->request->_has_body;
2128
2129     # Initialize on-demand data
2130     $c->engine->prepare_body( $c, @_ );
2131     $c->prepare_parameters;
2132     $c->prepare_uploads;
2133 }
2134
2135 =head2 $c->prepare_body_chunk( $chunk )
2136
2137 Prepares a chunk of data before sending it to L<HTTP::Body>.
2138
2139 See L<Catalyst::Engine>.
2140
2141 =cut
2142
2143 sub prepare_body_chunk {
2144     my $c = shift;
2145     $c->engine->prepare_body_chunk( $c, @_ );
2146 }
2147
2148 =head2 $c->prepare_body_parameters
2149
2150 Prepares body parameters.
2151
2152 =cut
2153
2154 sub prepare_body_parameters {
2155     my $c = shift;
2156     $c->engine->prepare_body_parameters( $c, @_ );
2157 }
2158
2159 =head2 $c->prepare_connection
2160
2161 Prepares connection.
2162
2163 =cut
2164
2165 sub prepare_connection {
2166     my $c = shift;
2167     # XXX - This is called on the engine (not the request) to maintain
2168     #       Engine::PSGI back compat.
2169     $c->engine->prepare_connection($c);
2170 }
2171
2172 =head2 $c->prepare_cookies
2173
2174 Prepares cookies by ensuring that the attribute on the request
2175 object has been built.
2176
2177 =cut
2178
2179 sub prepare_cookies { my $c = shift; $c->request->cookies }
2180
2181 =head2 $c->prepare_headers
2182
2183 Prepares request headers by ensuring that the attribute on the request
2184 object has been built.
2185
2186 =cut
2187
2188 sub prepare_headers { my $c = shift; $c->request->headers }
2189
2190 =head2 $c->prepare_parameters
2191
2192 Prepares parameters.
2193
2194 =cut
2195
2196 sub prepare_parameters {
2197     my $c = shift;
2198     $c->prepare_body_parameters;
2199     $c->engine->prepare_parameters( $c, @_ );
2200 }
2201
2202 =head2 $c->prepare_path
2203
2204 Prepares path and base.
2205
2206 =cut
2207
2208 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2209
2210 =head2 $c->prepare_query_parameters
2211
2212 Prepares query parameters.
2213
2214 =cut
2215
2216 sub prepare_query_parameters {
2217     my $c = shift;
2218
2219     $c->engine->prepare_query_parameters( $c, @_ );
2220 }
2221
2222 =head2 $c->log_request
2223
2224 Writes information about the request to the debug logs.  This includes:
2225
2226 =over 4
2227
2228 =item * Request method, path, and remote IP address
2229
2230 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2231
2232 =item * Request parameters
2233
2234 =item * File uploads
2235
2236 =back
2237
2238 =cut
2239
2240 sub log_request {
2241     my $c = shift;
2242
2243     return unless $c->debug;
2244
2245     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2246     my $request = $dump->[1];
2247
2248     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2249     $method ||= '';
2250     $path = '/' unless length $path;
2251     $address ||= '';
2252     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2253
2254     $c->log_request_headers($request->headers);
2255
2256     if ( my $keywords = $request->query_keywords ) {
2257         $c->log->debug("Query keywords are: $keywords");
2258     }
2259
2260     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2261
2262     $c->log_request_uploads($request);
2263 }
2264
2265 =head2 $c->log_response
2266
2267 Writes information about the response to the debug logs by calling
2268 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2269
2270 =cut
2271
2272 sub log_response {
2273     my $c = shift;
2274
2275     return unless $c->debug;
2276
2277     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2278     my $response = $dump->[1];
2279
2280     $c->log_response_status_line($response);
2281     $c->log_response_headers($response->headers);
2282 }
2283
2284 =head2 $c->log_response_status_line($response)
2285
2286 Writes one line of information about the response to the debug logs.  This includes:
2287
2288 =over 4
2289
2290 =item * Response status code
2291
2292 =item * Content-Type header (if present)
2293
2294 =item * Content-Length header (if present)
2295
2296 =back
2297
2298 =cut
2299
2300 sub log_response_status_line {
2301     my ($c, $response) = @_;
2302
2303     $c->log->debug(
2304         sprintf(
2305             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2306             $response->status                            || 'unknown',
2307             $response->headers->header('Content-Type')   || 'unknown',
2308             $response->headers->header('Content-Length') || 'unknown'
2309         )
2310     );
2311 }
2312
2313 =head2 $c->log_response_headers($headers);
2314
2315 Hook method which can be wrapped by plugins to log the response headers.
2316 No-op in the default implementation.
2317
2318 =cut
2319
2320 sub log_response_headers {}
2321
2322 =head2 $c->log_request_parameters( query => {}, body => {} )
2323
2324 Logs request parameters to debug logs
2325
2326 =cut
2327
2328 sub log_request_parameters {
2329     my $c          = shift;
2330     my %all_params = @_;
2331
2332     return unless $c->debug;
2333
2334     my $column_width = Catalyst::Utils::term_width() - 44;
2335     foreach my $type (qw(query body)) {
2336         my $params = $all_params{$type};
2337         next if ! keys %$params;
2338         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2339         for my $key ( sort keys %$params ) {
2340             my $param = $params->{$key};
2341             my $value = defined($param) ? $param : '';
2342             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2343         }
2344         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2345     }
2346 }
2347
2348 =head2 $c->log_request_uploads
2349
2350 Logs file uploads included in the request to the debug logs.
2351 The parameter name, filename, file type, and file size are all included in
2352 the debug logs.
2353
2354 =cut
2355
2356 sub log_request_uploads {
2357     my $c = shift;
2358     my $request = shift;
2359     return unless $c->debug;
2360     my $uploads = $request->uploads;
2361     if ( keys %$uploads ) {
2362         my $t = Text::SimpleTable->new(
2363             [ 12, 'Parameter' ],
2364             [ 26, 'Filename' ],
2365             [ 18, 'Type' ],
2366             [ 9,  'Size' ]
2367         );
2368         for my $key ( sort keys %$uploads ) {
2369             my $upload = $uploads->{$key};
2370             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2371                 $t->row( $key, $u->filename, $u->type, $u->size );
2372             }
2373         }
2374         $c->log->debug( "File Uploads are:\n" . $t->draw );
2375     }
2376 }
2377
2378 =head2 $c->log_request_headers($headers);
2379
2380 Hook method which can be wrapped by plugins to log the request headers.
2381 No-op in the default implementation.
2382
2383 =cut
2384
2385 sub log_request_headers {}
2386
2387 =head2 $c->log_headers($type => $headers)
2388
2389 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2390
2391 =cut
2392
2393 sub log_headers {
2394     my $c       = shift;
2395     my $type    = shift;
2396     my $headers = shift;    # an HTTP::Headers instance
2397
2398     return unless $c->debug;
2399
2400     my $column_width = Catalyst::Utils::term_width() - 28;
2401     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2402     $headers->scan(
2403         sub {
2404             my ( $name, $value ) = @_;
2405             $t->row( $name, $value );
2406         }
2407     );
2408     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2409 }
2410
2411
2412 =head2 $c->prepare_read
2413
2414 Prepares the input for reading.
2415
2416 =cut
2417
2418 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2419
2420 =head2 $c->prepare_request
2421
2422 Prepares the engine request.
2423
2424 =cut
2425
2426 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2427
2428 =head2 $c->prepare_uploads
2429
2430 Prepares uploads.
2431
2432 =cut
2433
2434 sub prepare_uploads {
2435     my $c = shift;
2436
2437     $c->engine->prepare_uploads( $c, @_ );
2438 }
2439
2440 =head2 $c->prepare_write
2441
2442 Prepares the output for writing.
2443
2444 =cut
2445
2446 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2447
2448 =head2 $c->request_class
2449
2450 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2451
2452 =head2 $c->response_class
2453
2454 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2455
2456 =head2 $c->read( [$maxlength] )
2457
2458 Reads a chunk of data from the request body. This method is designed to
2459 be used in a while loop, reading C<$maxlength> bytes on every call.
2460 C<$maxlength> defaults to the size of the request if not specified.
2461
2462 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2463 directly.
2464
2465 Warning: If you use read(), Catalyst will not process the body,
2466 so you will not be able to access POST parameters or file uploads via
2467 $c->request.  You must handle all body parsing yourself.
2468
2469 =cut
2470
2471 sub read { my $c = shift; return $c->request->read( @_ ) }
2472
2473 =head2 $c->run
2474
2475 Starts the engine.
2476
2477 =cut
2478
2479 sub run {
2480   my $app = shift;
2481   $app->_make_immutable_if_needed;
2482   $app->engine_loader->needs_psgi_engine_compat_hack ?
2483     $app->engine->run($app, @_) :
2484       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2485 }
2486
2487 sub _make_immutable_if_needed {
2488     my $class = shift;
2489     my $meta = find_meta($class);
2490     my $isa_ca = $class->isa('Class::Accessor::Fast') || $class->isa('Class::Accessor');
2491     if (
2492         $meta->is_immutable
2493         && ! { $meta->immutable_options }->{replace_constructor}
2494         && $isa_ca
2495     ) {
2496         warn("You made your application class ($class) immutable, "
2497             . "but did not inline the\nconstructor. "
2498             . "This will break catalyst, as your app \@ISA "
2499             . "Class::Accessor(::Fast)?\nPlease pass "
2500             . "(replace_constructor => 1)\nwhen making your class immutable.\n");
2501     }
2502     unless ($meta->is_immutable) {
2503         # XXX - FIXME warning here as you should make your app immutable yourself.
2504         $meta->make_immutable(
2505             replace_constructor => 1,
2506         );
2507     }
2508 }
2509
2510 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2511
2512 Sets an action in a given namespace.
2513
2514 =cut
2515
2516 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2517
2518 =head2 $c->setup_actions($component)
2519
2520 Sets up actions for a component.
2521
2522 =cut
2523
2524 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2525
2526 =head2 $c->setup_components
2527
2528 This method is called internally to set up the application's components.
2529
2530 It finds modules by calling the L<locate_components> method, expands them to
2531 package names with the L<expand_component_module> method, and then installs
2532 each component into the application.
2533
2534 The C<setup_components> config option is passed to both of the above methods.
2535
2536 Installation of each component is performed by the L<setup_component> method,
2537 below.
2538
2539 =cut
2540
2541 sub setup_components {
2542     my $class = shift;
2543
2544     my $config  = $class->config->{ setup_components };
2545
2546     my @comps = $class->locate_components($config);
2547     my %comps = map { $_ => 1 } @comps;
2548
2549     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2550     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2551         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2552     ) if $deprecatedcatalyst_component_names;
2553
2554     for my $component ( @comps ) {
2555
2556         # We pass ignore_loaded here so that overlay files for (e.g.)
2557         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2558         # we know M::P::O found a file on disk so this is safe
2559
2560         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2561     }
2562
2563     for my $component (@comps) {
2564         my $instance = $class->components->{ $component } = $class->setup_component($component);
2565         my @expanded_components = $instance->can('expand_modules')
2566             ? $instance->expand_modules( $component, $config )
2567             : $class->expand_component_module( $component, $config );
2568         for my $component (@expanded_components) {
2569             next if $comps{$component};
2570             $class->components->{ $component } = $class->setup_component($component);
2571         }
2572     }
2573 }
2574
2575 =head2 $c->locate_components( $setup_component_config )
2576
2577 This method is meant to provide a list of component modules that should be
2578 setup for the application.  By default, it will use L<Module::Pluggable>.
2579
2580 Specify a C<setup_components> config option to pass additional options directly
2581 to L<Module::Pluggable>. To add additional search paths, specify a key named
2582 C<search_extra> as an array reference. Items in the array beginning with C<::>
2583 will have the application class name prepended to them.
2584
2585 =cut
2586
2587 sub locate_components {
2588     my $class  = shift;
2589     my $config = shift;
2590
2591     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2592     my $extra   = delete $config->{ search_extra } || [];
2593
2594     push @paths, @$extra;
2595
2596     my $locator = Module::Pluggable::Object->new(
2597         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2598         %$config
2599     );
2600
2601     # XXX think about ditching this sort entirely
2602     my @comps = sort { length $a <=> length $b } $locator->plugins;
2603
2604     return @comps;
2605 }
2606
2607 =head2 $c->expand_component_module( $component, $setup_component_config )
2608
2609 Components found by C<locate_components> will be passed to this method, which
2610 is expected to return a list of component (package) names to be set up.
2611
2612 =cut
2613
2614 sub expand_component_module {
2615     my ($class, $module) = @_;
2616     return Devel::InnerPackage::list_packages( $module );
2617 }
2618
2619 =head2 $c->setup_component
2620
2621 =cut
2622
2623 sub setup_component {
2624     my( $class, $component ) = @_;
2625
2626     unless ( $component->can( 'COMPONENT' ) ) {
2627         return $component;
2628     }
2629
2630     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2631     my $config = $class->config->{ $suffix } || {};
2632     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2633     # methods also pass it. local to avoid pointlessly shitting in config
2634     # for the debug screen, as $component is already the key name.
2635     local $config->{catalyst_component_name} = $component;
2636
2637     my $instance = eval { $component->COMPONENT( $class, $config ); };
2638
2639     if ( my $error = $@ ) {
2640         chomp $error;
2641         Catalyst::Exception->throw(
2642             message => qq/Couldn't instantiate component "$component", "$error"/
2643         );
2644     }
2645
2646     unless (blessed $instance) {
2647         my $metaclass = Moose::Util::find_meta($component);
2648         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2649         my $component_method_from = $method_meta->associated_metaclass->name;
2650         my $value = defined($instance) ? $instance : 'undef';
2651         Catalyst::Exception->throw(
2652             message =>
2653             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2654         );
2655     }
2656     return $instance;
2657 }
2658
2659 =head2 $c->setup_dispatcher
2660
2661 Sets up dispatcher.
2662
2663 =cut
2664
2665 sub setup_dispatcher {
2666     my ( $class, $dispatcher ) = @_;
2667
2668     if ($dispatcher) {
2669         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2670     }
2671
2672     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2673         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2674     }
2675
2676     unless ($dispatcher) {
2677         $dispatcher = $class->dispatcher_class;
2678     }
2679
2680     load_class($dispatcher);
2681
2682     # dispatcher instance
2683     $class->dispatcher( $dispatcher->new );
2684 }
2685
2686 =head2 $c->setup_engine
2687
2688 Sets up engine.
2689
2690 =cut
2691
2692 sub engine_class {
2693     my ($class, $requested_engine) = @_;
2694
2695     if (!$class->engine_loader || $requested_engine) {
2696         $class->engine_loader(
2697             Catalyst::EngineLoader->new({
2698                 application_name => $class,
2699                 (defined $requested_engine
2700                      ? (catalyst_engine_class => $requested_engine) : ()),
2701             }),
2702         );
2703     }
2704
2705     $class->engine_loader->catalyst_engine_class;
2706 }
2707
2708 sub setup_engine {
2709     my ($class, $requested_engine) = @_;
2710
2711     my $engine = do {
2712         my $loader = $class->engine_loader;
2713
2714         if (!$loader || $requested_engine) {
2715             $loader = Catalyst::EngineLoader->new({
2716                 application_name => $class,
2717                 (defined $requested_engine
2718                      ? (requested_engine => $requested_engine) : ()),
2719             }),
2720
2721             $class->engine_loader($loader);
2722         }
2723
2724         $loader->catalyst_engine_class;
2725     };
2726
2727     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2728     return if $class->loading_psgi_file;
2729
2730     load_class($engine);
2731
2732     if ($ENV{MOD_PERL}) {
2733         my $apache = $class->engine_loader->auto;
2734
2735         my $meta = find_meta($class);
2736         my $was_immutable = $meta->is_immutable;
2737         my %immutable_options = $meta->immutable_options;
2738         $meta->make_mutable if $was_immutable;
2739
2740         $meta->add_method(handler => sub {
2741             my $r = shift;
2742             my $psgi_app = $class->_finalized_psgi_app;
2743             $apache->call_app($r, $psgi_app);
2744         });
2745
2746         $meta->make_immutable(%immutable_options) if $was_immutable;
2747     }
2748
2749     $class->engine( $engine->new );
2750
2751     return;
2752 }
2753
2754 ## This exists just to supply a prebuild psgi app for mod_perl and for the
2755 ## build in server support (back compat support for pre psgi port behavior).
2756 ## This is so that we don't build a new psgi app for each request when using
2757 ## the mod_perl handler or the built in servers (http and fcgi, etc).
2758
2759 sub _finalized_psgi_app {
2760     my ($app) = @_;
2761
2762     unless ($app->_psgi_app) {
2763         my $psgi_app = $app->_setup_psgi_app;
2764         $app->_psgi_app($psgi_app);
2765     }
2766
2767     return $app->_psgi_app;
2768 }
2769
2770 ## Look for a psgi file like 'myapp_web.psgi' (if the app is MyApp::Web) in the
2771 ## home directory and load that and return it (just assume it is doing the
2772 ## right thing :) ).  If that does not exist, call $app->psgi_app, wrap that
2773 ## in default_middleware and return it ( this is for backward compatibility
2774 ## with pre psgi port behavior ).
2775
2776 sub _setup_psgi_app {
2777     my ($app) = @_;
2778
2779     for my $home (Path::Class::Dir->new($app->config->{home})) {
2780         my $psgi_file = $home->file(
2781             Catalyst::Utils::appprefix($app) . '.psgi',
2782         );
2783
2784         next unless -e $psgi_file;
2785
2786         # If $psgi_file calls ->setup_engine, it's doing so to load
2787         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2788         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2789         # anyway. So set a flag (ick) that tells setup_engine not to populate
2790         # $c->engine or do any other things we might regret.
2791
2792         $app->loading_psgi_file(1);
2793         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2794         $app->loading_psgi_file(0);
2795
2796         return $psgi_app
2797             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2798
2799         warn <<"EOW";
2800 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2801
2802 Its content has been ignored. Please consult the Catalyst::Upgrading
2803 documentation on how to upgrade from Catalyst::Engine::PSGI.
2804 EOW
2805     }
2806
2807     return $app->apply_default_middlewares($app->psgi_app);
2808 }
2809
2810 =head2 $c->apply_default_middlewares
2811
2812 Adds the following L<Plack> middlewares to your application, since they are
2813 useful and commonly needed:
2814
2815 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2816 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2817 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2818 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2819 applied since this middleware is smart enough to conditionally apply itself).
2820
2821 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2822 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2823 $ENV{SCRIPT_NAME}
2824
2825 =cut
2826
2827
2828 sub apply_default_middlewares {
2829     my ($app, $psgi_app) = @_;
2830
2831     $psgi_app = Plack::Middleware::Conditional->wrap(
2832         $psgi_app,
2833         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2834         condition => sub {
2835             my ($env) = @_;
2836             return if $app->config->{ignore_frontend_proxy};
2837             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2838                 || $app->config->{using_frontend_proxy};
2839         },
2840     );
2841
2842     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2843     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2844     $psgi_app = Plack::Middleware::Conditional->wrap(
2845         $psgi_app,
2846         builder   => sub { Plack::Middleware::LighttpdScriptNameFix->wrap($_[0]) },
2847         condition => sub {
2848             my ($env) = @_;
2849             return unless $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!lighttpd[-/]1\.(\d+\.\d+)!;
2850             return unless $1 < 4.23;
2851             1;
2852         },
2853     );
2854
2855     # we're applying this unconditionally as the middleware itself already makes
2856     # sure it doesn't fuck things up if it's not running under one of the right
2857     # IIS versions
2858     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2859
2860     # And another IIS issue, this time with IIS7.
2861     $psgi_app = Plack::Middleware::Conditional->wrap(
2862         $psgi_app,
2863         builder => sub { Plack::Middleware::IIS7KeepAliveFix->wrap($_[0]) },
2864         condition => sub {
2865             my ($env) = @_;
2866             return $env->{SERVER_SOFTWARE} && $env->{SERVER_SOFTWARE} =~ m!IIS/7\.[0-9]!;
2867         },
2868     );
2869
2870     return $psgi_app;
2871 }
2872
2873 =head2 $c->psgi_app
2874
2875 Returns a PSGI application code reference for the catalyst application
2876 C<$c>. This is the bare application without any middlewares
2877 applied. C<${myapp}.psgi> is not taken into account.
2878
2879 This is what you want to be using to retrieve the PSGI application code
2880 reference of your Catalyst application for use in F<.psgi> files.
2881
2882 =cut
2883
2884 sub psgi_app {
2885     my ($app) = @_;
2886     my $psgi = $app->engine->build_psgi_app($app);
2887     return $app->Catalyst::Utils::apply_registered_middleware($psgi);
2888 }
2889
2890 =head2 $c->setup_home
2891
2892 Sets up the home directory.
2893
2894 =cut
2895
2896 sub setup_home {
2897     my ( $class, $home ) = @_;
2898
2899     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2900         $home = $env;
2901     }
2902
2903     $home ||= Catalyst::Utils::home($class);
2904
2905     if ($home) {
2906         #I remember recently being scolded for assigning config values like this
2907         $class->config->{home} ||= $home;
2908         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2909     }
2910 }
2911
2912 =head2 $c->setup_log
2913
2914 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2915 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2916 log to.
2917
2918 This method also installs a C<debug> method that returns a true value into the
2919 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2920 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2921
2922 Note that if the log has already been setup, by either a previous call to
2923 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2924 that this method won't actually set up the log object.
2925
2926 =cut
2927
2928 sub setup_log {
2929     my ( $class, $levels ) = @_;
2930
2931     $levels ||= '';
2932     $levels =~ s/^\s+//;
2933     $levels =~ s/\s+$//;
2934     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2935
2936     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2937     if ( defined $env_debug ) {
2938         $levels{debug} = 1 if $env_debug; # Ugly!
2939         delete($levels{debug}) unless $env_debug;
2940     }
2941
2942     unless ( $class->log ) {
2943         $class->log( Catalyst::Log->new(keys %levels) );
2944     }
2945
2946     if ( $levels{debug} ) {
2947         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2948         $class->log->debug('Debug messages enabled');
2949     }
2950 }
2951
2952 =head2 $c->setup_plugins
2953
2954 Sets up plugins.
2955
2956 =cut
2957
2958 =head2 $c->setup_stats
2959
2960 Sets up timing statistics class.
2961
2962 =cut
2963
2964 sub setup_stats {
2965     my ( $class, $stats ) = @_;
2966
2967     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2968
2969     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2970     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2971         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2972         $class->log->debug('Statistics enabled');
2973     }
2974 }
2975
2976
2977 =head2 $c->registered_plugins
2978
2979 Returns a sorted list of the plugins which have either been stated in the
2980 import list.
2981
2982 If passed a given plugin name, it will report a boolean value indicating
2983 whether or not that plugin is loaded.  A fully qualified name is required if
2984 the plugin name does not begin with C<Catalyst::Plugin::>.
2985
2986  if ($c->registered_plugins('Some::Plugin')) {
2987      ...
2988  }
2989
2990 =cut
2991
2992 {
2993
2994     sub registered_plugins {
2995         my $proto = shift;
2996         return sort keys %{ $proto->_plugins } unless @_;
2997         my $plugin = shift;
2998         return 1 if exists $proto->_plugins->{$plugin};
2999         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
3000     }
3001
3002     sub _register_plugin {
3003         my ( $proto, $plugin, $instant ) = @_;
3004         my $class = ref $proto || $proto;
3005
3006         load_class( $plugin );
3007         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
3008             if $plugin->isa( 'Catalyst::Component' );
3009         my $plugin_meta = Moose::Meta::Class->create($plugin);
3010         if (!$plugin_meta->has_method('new')
3011             && ( $plugin->isa('Class::Accessor::Fast') || $plugin->isa('Class::Accessor') ) ) {
3012             $plugin_meta->add_method('new', Moose::Object->meta->get_method('new'))
3013         }
3014         if (!$instant && !$proto->_plugins->{$plugin}) {
3015             my $meta = Class::MOP::get_metaclass_by_name($class);
3016             $meta->superclasses($plugin, $meta->superclasses);
3017         }
3018         $proto->_plugins->{$plugin} = 1;
3019         return $class;
3020     }
3021
3022     sub _default_plugins { return qw(Unicode::Encoding) }
3023
3024     sub setup_plugins {
3025         my ( $class, $plugins ) = @_;
3026
3027         $class->_plugins( {} ) unless $class->_plugins;
3028         $plugins = [ grep {
3029             m/Unicode::Encoding/ ? do {
3030                 $class->log->warn(
3031                     'Unicode::Encoding plugin is auto-applied,'
3032                     . ' please remove this from your appclass'
3033                     . ' and make sure to define "encoding" config'
3034                 );
3035                 unless (exists $class->config->{'encoding'}) {
3036                   $class->config->{'encoding'} = 'UTF-8';
3037                 }
3038                 () }
3039                 : $_
3040         } @$plugins ];
3041         push @$plugins, $class->_default_plugins;
3042         $plugins = Data::OptList::mkopt($plugins || []);
3043
3044         my @plugins = map {
3045             [ Catalyst::Utils::resolve_namespace(
3046                   $class . '::Plugin',
3047                   'Catalyst::Plugin', $_->[0]
3048               ),
3049               $_->[1],
3050             ]
3051          } @{ $plugins };
3052
3053         for my $plugin ( reverse @plugins ) {
3054             load_class($plugin->[0], $plugin->[1]);
3055             my $meta = find_meta($plugin->[0]);
3056             next if $meta && $meta->isa('Moose::Meta::Role');
3057
3058             $class->_register_plugin($plugin->[0]);
3059         }
3060
3061         my @roles =
3062             map  { $_->[0]->name, $_->[1] }
3063             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
3064             map  { [find_meta($_->[0]), $_->[1]] }
3065             @plugins;
3066
3067         Moose::Util::apply_all_roles(
3068             $class => @roles
3069         ) if @roles;
3070     }
3071 }
3072
3073 =head2 registered_middlewares
3074
3075 Read only accessor that returns an array of all the middleware in the order
3076 that they were added (which is the REVERSE of the order they will be applied).
3077
3078 The values returned will be either instances of L<Plack::Middleware> or of a
3079 compatible interface, or a coderef, which is assumed to be inlined middleware
3080
3081 =head2 setup_middleware (?@middleware)
3082
3083 Read configuration information stored in configuration key C<psgi_middleware> or
3084 from passed @args.
3085
3086 See under L</CONFIGURATION> information regarding C<psgi_middleware> and how
3087 to use it to enable L<Plack::Middleware>
3088
3089 This method is automatically called during 'setup' of your application, so
3090 you really don't need to invoke it.  However you may do so if you find the idea
3091 of loading middleware via configuration weird :).  For example:
3092
3093     package MyApp;
3094
3095     use Catalyst;
3096
3097     __PACKAGE__->setup_middleware('Head');
3098     __PACKAGE__->setup;
3099
3100 When we read middleware definitions from configuration, we reverse the list
3101 which sounds odd but is likely how you expect it to work if you have prior
3102 experience with L<Plack::Builder> or if you previously used the plugin
3103 L<Catalyst::Plugin::EnableMiddleware> (which is now considered deprecated)
3104
3105 =cut
3106
3107 sub registered_middlewares {
3108     my $class = shift;
3109     if(my $middleware = $class->_psgi_middleware) {
3110         return (
3111           Plack::Middleware::HTTPExceptions->new,
3112           Plack::Middleware::RemoveRedundantBody->new,
3113           Plack::Middleware::FixMissingBodyInRedirect->new,
3114           Plack::Middleware::ContentLength->new,
3115           Plack::Middleware::MethodOverride->new,
3116           Plack::Middleware::Head->new,
3117           @$middleware);
3118     } else {
3119         die "You cannot call ->registered_middlewares until middleware has been setup";
3120     }
3121 }
3122
3123 sub setup_middleware {
3124     my $class = shift;
3125     my @middleware_definitions = @_ ?
3126       @_ : reverse(@{$class->config->{'psgi_middleware'}||[]});
3127
3128     my @middleware = ();
3129     while(my $next = shift(@middleware_definitions)) {
3130         if(ref $next) {
3131             if(Scalar::Util::blessed $next && $next->can('wrap')) {
3132                 push @middleware, $next;
3133             } elsif(ref $next eq 'CODE') {
3134                 push @middleware, $next;
3135             } elsif(ref $next eq 'HASH') {
3136                 my $namespace = shift @middleware_definitions;
3137                 my $mw = $class->Catalyst::Utils::build_middleware($namespace, %$next);
3138                 push @middleware, $mw;
3139             } else {
3140               die "I can't handle middleware definition ${\ref $next}";
3141             }
3142         } else {
3143           my $mw = $class->Catalyst::Utils::build_middleware($next);
3144           push @middleware, $mw;
3145         }
3146     }
3147
3148     my @existing = @{$class->_psgi_middleware || []};
3149     $class->_psgi_middleware([@middleware,@existing,]);
3150 }
3151
3152 =head2 registered_data_handlers
3153
3154 A read only copy of registered Data Handlers returned as a Hash, where each key
3155 is a content type and each value is a subref that attempts to decode that content
3156 type.
3157
3158 =head2 setup_data_handlers (?@data_handler)
3159
3160 Read configuration information stored in configuration key C<data_handlers> or
3161 from passed @args.
3162
3163 See under L</CONFIGURATION> information regarding C<data_handlers>.
3164
3165 This method is automatically called during 'setup' of your application, so
3166 you really don't need to invoke it.
3167
3168 =head2 default_data_handlers
3169
3170 Default Data Handlers that come bundled with L<Catalyst>.  Currently there are
3171 only two default data handlers, for 'application/json' and an alternative to
3172 'application/x-www-form-urlencoded' which supposed nested form parameters via
3173 L<CGI::Struct> or via L<CGI::Struct::XS> IF you've installed it.
3174
3175 The 'application/json' data handler is used to parse incoming JSON into a Perl
3176 data structure.  It used either L<JSON::MaybeXS> or L<JSON>, depending on which
3177 is installed.  This allows you to fail back to L<JSON:PP>, which is a Pure Perl
3178 JSON decoder, and has the smallest dependency impact.
3179
3180 Because we don't wish to add more dependencies to L<Catalyst>, if you wish to
3181 use this new feature we recommend installing L<JSON> or L<JSON::MaybeXS> in
3182 order to get the best performance.  You should add either to your dependency
3183 list (Makefile.PL, dist.ini, cpanfile, etc.)
3184
3185 =cut
3186
3187 sub registered_data_handlers {
3188     my $class = shift;
3189     if(my $data_handlers = $class->_data_handlers) {
3190         return %$data_handlers;
3191     } else {
3192         die "You cannot call ->registered_data_handlers until data_handers has been setup";
3193     }
3194 }
3195
3196 sub setup_data_handlers {
3197     my ($class, %data_handler_callbacks) = @_;
3198     %data_handler_callbacks = (
3199       %{$class->default_data_handlers},
3200       %{$class->config->{'data_handlers'}||+{}},
3201       %data_handler_callbacks);
3202
3203     $class->_data_handlers(\%data_handler_callbacks);
3204 }
3205
3206 sub default_data_handlers {
3207     my ($class) = @_;
3208     return +{
3209       'application/x-www-form-urlencoded' => sub {
3210           my ($fh, $req) = @_;
3211           my $params = $req->_use_hash_multivalue ? $req->body_parameters->mixed : $req->body_parameters;
3212           Class::Load::load_first_existing_class('CGI::Struct::XS', 'CGI::Struct')
3213             ->can('build_cgi_struct')->($params);
3214       },
3215       'application/json' => sub {
3216           Class::Load::load_first_existing_class('JSON::MaybeXS', 'JSON')
3217             ->can('decode_json')->(do { local $/; $_->getline });
3218       },
3219     };
3220 }
3221
3222 =head2 $c->stack
3223
3224 Returns an arrayref of the internal execution stack (actions that are
3225 currently executing).
3226
3227 =head2 $c->stats
3228
3229 Returns the current timing statistics object. By default Catalyst uses
3230 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
3231 L<< stats_class|/"$c->stats_class" >>.
3232
3233 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
3234 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
3235 profile explicitly, although MyApp.pm still won't profile nor output anything
3236 by itself.
3237
3238 =head2 $c->stats_class
3239
3240 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
3241
3242 =head2 $c->use_stats
3243
3244 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
3245
3246 Note that this is a static method, not an accessor and should be overridden
3247 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
3248
3249 =cut
3250
3251 sub use_stats { 0 }
3252
3253
3254 =head2 $c->write( $data )
3255
3256 Writes $data to the output stream. When using this method directly, you
3257 will need to manually set the C<Content-Length> header to the length of
3258 your output data, if known.
3259
3260 =cut
3261
3262 sub write {
3263     my $c = shift;
3264
3265     # Finalize headers if someone manually writes output (for compat)
3266     $c->finalize_headers;
3267
3268     return $c->response->write( @_ );
3269 }
3270
3271 =head2 version
3272
3273 Returns the Catalyst version number. Mostly useful for "powered by"
3274 messages in template systems.
3275
3276 =cut
3277
3278 sub version { return $Catalyst::VERSION }
3279
3280 =head1 CONFIGURATION
3281
3282 There are a number of 'base' config variables which can be set:
3283
3284 =over
3285
3286 =item *
3287
3288 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
3289
3290 =item *
3291
3292 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
3293
3294 =item *
3295
3296 C<disable_component_resolution_regex_fallback> - Turns
3297 off the deprecated component resolution functionality so
3298 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
3299 are called then regex search will not be attempted on string values and
3300 instead C<undef> will be returned.
3301
3302 =item *
3303
3304 C<home> - The application home directory. In an uninstalled application,
3305 this is the top level application directory. In an installed application,
3306 this will be the directory containing C<< MyApp.pm >>.
3307
3308 =item *
3309
3310 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
3311
3312 =item *
3313
3314 C<name> - The name of the application in debug messages and the debug and
3315 welcome screens
3316
3317 =item *
3318
3319 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
3320 until it is accessed. This allows you to (for example) check authentication (and reject
3321 the upload) before actually receiving all the data. See L</ON-DEMAND PARSER>
3322
3323 =item *
3324
3325 C<root> - The root directory for templates. Usually this is just a
3326 subdirectory of the home directory, but you can set it to change the
3327 templates to a different directory.
3328
3329 =item *
3330
3331 C<search_extra> - Array reference passed to Module::Pluggable to for additional
3332 namespaces from which components will be loaded (and constructed and stored in
3333 C<< $c->components >>).
3334
3335 =item *
3336
3337 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3338 to be shown in hit debug tables in the test server.
3339
3340 =item *
3341
3342 C<use_request_uri_for_path> - Controls if the C<REQUEST_URI> or C<PATH_INFO> environment
3343 variable should be used for determining the request path.
3344
3345 Most web server environments pass the requested path to the application using environment variables,
3346 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3347 exposed as C<< $c->request->base >>) and the request path below that base.
3348
3349 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3350 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3351
3352 =over
3353
3354 =item use_request_uri_for_path => 0
3355
3356 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3357 The path is generated from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3358 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3359 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3360
3361 However this method has the major disadvantage that it is impossible to correctly decode some elements
3362 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3363 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3364 can't distinguish / vs %2F in paths (in addition to other encoded values).
3365
3366 =item use_request_uri_for_path => 1
3367
3368 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3369 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3370 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3371
3372 Given that this method of path resolution is provably more correct, it is recommended that you use
3373 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3374 aware of the implications of not being able to handle encoded URI paths correctly.
3375
3376 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3377 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3378 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3379 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3380 C<< $c->request->base >> will be incorrect.
3381
3382 =back
3383
3384 =item *
3385
3386 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3387
3388 =item *
3389
3390 C<encoding> - See L</ENCODING>
3391
3392 =item *
3393
3394 C<abort_chain_on_error_fix>
3395
3396 When there is an error in an action chain, the default behavior is to continue
3397 processing the remaining actions and then catch the error upon chain end.  This
3398 can lead to running actions when the application is in an unexpected state.  If
3399 you have this issue, setting this config value to true will promptly exit a
3400 chain when there is an error raised in any action (thus terminating the chain
3401 early.)
3402
3403 use like:
3404
3405     __PACKAGE__->config(abort_chain_on_error_fix => 1);
3406
3407 In the future this might become the default behavior.
3408
3409 =item *
3410
3411 C<use_hash_multivalue_in_request>
3412
3413 In L<Catalyst::Request> the methods C<query_parameters>, C<body_parametes>
3414 and C<parameters> return a hashref where values might be scalar or an arrayref
3415 depending on the incoming data.  In many cases this can be undesirable as it
3416 leads one to writing defensive code like the following:
3417
3418     my ($val) = ref($c->req->parameters->{a}) ?
3419       @{$c->req->parameters->{a}} :
3420         $c->req->parameters->{a};
3421
3422 Setting this configuration item to true will make L<Catalyst> populate the
3423 attributes underlying these methods with an instance of L<Hash::MultiValue>
3424 which is used by L<Plack::Request> and others to solve this very issue.  You
3425 may prefer this behavior to the default, if so enable this option (be warned
3426 if you enable it in a legacy application we are not sure if it is completely
3427 backwardly compatible).
3428
3429 =item *
3430
3431 C<psgi_middleware> - See L<PSGI MIDDLEWARE>.
3432
3433 =item *
3434
3435 C<data_handlers> - See L<DATA HANDLERS>.
3436
3437 =back
3438
3439 =head1 INTERNAL ACTIONS
3440
3441 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3442 C<_ACTION>, and C<_END>. These are by default not shown in the private
3443 action table, but you can make them visible with a config parameter.
3444
3445     MyApp->config(show_internal_actions => 1);
3446
3447 =head1 ON-DEMAND PARSER
3448
3449 The request body is usually parsed at the beginning of a request,
3450 but if you want to handle input yourself, you can enable on-demand
3451 parsing with a config parameter.
3452
3453     MyApp->config(parse_on_demand => 1);
3454
3455 =head1 PROXY SUPPORT
3456
3457 Many production servers operate using the common double-server approach,
3458 with a lightweight frontend web server passing requests to a larger
3459 backend server. An application running on the backend server must deal
3460 with two problems: the remote user always appears to be C<127.0.0.1> and
3461 the server's hostname will appear to be C<localhost> regardless of the
3462 virtual host that the user connected through.
3463
3464 Catalyst will automatically detect this situation when you are running
3465 the frontend and backend servers on the same machine. The following
3466 changes are made to the request.
3467
3468     $c->req->address is set to the user's real IP address, as read from
3469     the HTTP X-Forwarded-For header.
3470
3471     The host value for $c->req->base and $c->req->uri is set to the real
3472     host, as read from the HTTP X-Forwarded-Host header.
3473
3474 Additionally, you may be running your backend application on an insecure
3475 connection (port 80) while your frontend proxy is running under SSL.  If there
3476 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3477 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3478 be created properly.
3479
3480 In the case of passing in:
3481
3482     X-Forwarded-Port: 443
3483
3484 All calls to C<uri_for> will result in an https link, as is expected.
3485
3486 Obviously, your web server must support these headers for this to work.
3487
3488 In a more complex server farm environment where you may have your
3489 frontend proxy server(s) on different machines, you will need to set a
3490 configuration option to tell Catalyst to read the proxied data from the
3491 headers.
3492
3493     MyApp->config(using_frontend_proxy => 1);
3494
3495 If you do not wish to use the proxy support at all, you may set:
3496
3497     MyApp->config(ignore_frontend_proxy => 0);
3498
3499 =head2 Note about psgi files
3500
3501 Note that if you supply your own .psgi file, calling
3502 C<< MyApp->psgi_app(@_); >>, then B<this will not happen automatically>.
3503
3504 You either need to apply L<Plack::Middleware::ReverseProxy> yourself
3505 in your psgi, for example:
3506
3507     builder {
3508         enable "Plack::Middleware::ReverseProxy";
3509         MyApp->psgi_app
3510     };
3511
3512 This will unconditionally add the ReverseProxy support, or you need to call
3513 C<< $app = MyApp->apply_default_middlewares($app) >> (to conditionally
3514 apply the support depending upon your config).
3515
3516 See L<Catalyst::PSGI> for more information.
3517
3518 =head1 THREAD SAFETY
3519
3520 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3521 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3522 believe the Catalyst core to be thread-safe.
3523
3524 If you plan to operate in a threaded environment, remember that all other
3525 modules you are using must also be thread-safe. Some modules, most notably
3526 L<DBD::SQLite>, are not thread-safe.
3527
3528 =head1 DATA HANDLERS
3529
3530 The L<Catalyst::Request> object uses L<HTTP::Body> to populate 'classic' HTML
3531 form parameters and URL search query fields.  However it has become common
3532 for various alternative content types to be PUT or POSTed to your controllers
3533 and actions.  People working on RESTful APIs, or using AJAX often use JSON,
3534 XML and other content types when communicating with an application server.  In
3535 order to better support this use case, L<Catalyst> defines a global configuration
3536 option, C<data_handlers>, which lets you associate a content type with a coderef
3537 that parses that content type into something Perl can readily access.
3538
3539     package MyApp::Web;
3540
3541     use Catalyst;
3542     use JSON::Maybe;
3543
3544     __PACKAGE__->config(
3545       data_handlers => {
3546         'application/json' => sub { local $/; decode_json $_->getline },
3547       },
3548       ## Any other configuration.
3549     );
3550
3551     __PACKAGE__->setup;
3552
3553 By default L<Catalyst> comes with a generic JSON data handler similar to the
3554 example given above, which uses L<JSON::Maybe> to provide either L<JSON::PP>
3555 (a pure Perl, dependency free JSON parser) or L<Cpanel::JSON::XS> if you have
3556 it installed (if you want the faster XS parser, add it to you project Makefile.PL
3557 or dist.ini, cpanfile, etc.)
3558
3559 The C<data_handlers> configuation is a hashref whose keys are HTTP Content-Types
3560 (matched against the incoming request type using a regexp such as to be case
3561 insensitive) and whose values are coderefs that receive a localized version of
3562 C<$_> which is a filehandle object pointing to received body.
3563
3564 This feature is considered an early access release and we reserve the right
3565 to alter the interface in order to provide a performant and secure solution to
3566 alternative request body content.  Your reports welcomed!
3567
3568 =head1 PSGI MIDDLEWARE
3569
3570 You can define middleware, defined as L<Plack::Middleware> or a compatible
3571 interface in configuration.  Your middleware definitions are in the form of an
3572 arrayref under the configuration key C<psgi_middleware>.  Here's an example
3573 with details to follow:
3574
3575     package MyApp::Web;
3576
3577     use Catalyst;
3578     use Plack::Middleware::StackTrace;
3579
3580     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3581
3582     __PACKAGE__->config(
3583       'psgi_middleware', [
3584         'Debug',
3585         '+MyApp::Custom',
3586         $stacktrace_middleware,
3587         'Session' => {store => 'File'},
3588         sub {
3589           my $app = shift;
3590           return sub {
3591             my $env = shift;
3592             $env->{myapp.customkey} = 'helloworld';
3593             $app->($env);
3594           },
3595         },
3596       ],
3597     );
3598
3599     __PACKAGE__->setup;
3600
3601 So the general form is:
3602
3603     __PACKAGE__->config(psgi_middleware => \@middleware_definitions);
3604
3605 Where C<@middleware> is one or more of the following, applied in the REVERSE of
3606 the order listed (to make it function similarly to L<Plack::Builder>:
3607
3608 Alternatively, you may also define middleware by calling the L</setup_middleware>
3609 package method:
3610
3611     package MyApp::Web;
3612
3613     use Catalyst;
3614
3615     __PACKAGE__->setup_middleware( \@middleware_definitions);
3616     __PACKAGE__->setup;
3617
3618 In the case where you do both (use 'setup_middleware' and configuration) the
3619 package call to setup_middleware will be applied earlier (in other words its
3620 middleware will wrap closer to the application).  Keep this in mind since in
3621 some cases the order of middleware is important.
3622
3623 The two approaches are not exclusive.
3624
3625 =over 4
3626
3627 =item Middleware Object
3628
3629 An already initialized object that conforms to the L<Plack::Middleware>
3630 specification:
3631
3632     my $stacktrace_middleware = Plack::Middleware::StackTrace->new;
3633
3634     __PACKAGE__->config(
3635       'psgi_middleware', [
3636         $stacktrace_middleware,
3637       ]);
3638
3639
3640 =item coderef
3641
3642 A coderef that is an inlined middleware:
3643
3644     __PACKAGE__->config(
3645       'psgi_middleware', [
3646         sub {
3647           my $app = shift;
3648           return sub {
3649             my $env = shift;
3650             if($env->{PATH_INFO} =~m/forced/) {
3651               Plack::App::File
3652                 ->new(file=>TestApp->path_to(qw/share static forced.txt/))
3653                 ->call($env);
3654             } else {
3655               return $app->($env);
3656             }
3657          },
3658       },
3659     ]);
3660
3661
3662
3663 =item a scalar
3664
3665 We assume the scalar refers to a namespace after normalizing it using the
3666 following rules:
3667
3668 (1) If the scalar is prefixed with a "+" (as in C<+MyApp::Foo>) then the full string
3669 is assumed to be 'as is', and we just install and use the middleware.
3670
3671 (2) If the scalar begins with "Plack::Middleware" or your application namespace
3672 (the package name of your Catalyst application subclass), we also assume then
3673 that it is a full namespace, and use it.
3674
3675 (3) Lastly, we then assume that the scalar is a partial namespace, and attempt to
3676 resolve it first by looking for it under your application namespace (for example
3677 if you application is "MyApp::Web" and the scalar is "MyMiddleware", we'd look
3678 under "MyApp::Web::Middleware::MyMiddleware") and if we don't find it there, we
3679 will then look under the regular L<Plack::Middleware> namespace (i.e. for the
3680 previous we'd try "Plack::Middleware::MyMiddleware").  We look under your application
3681 namespace first to let you 'override' common L<Plack::Middleware> locally, should
3682 you find that a good idea.
3683
3684 Examples:
3685
3686     package MyApp::Web;
3687
3688     __PACKAGE__->config(
3689       'psgi_middleware', [
3690         'Debug',  ## MyAppWeb::Middleware::Debug->wrap or Plack::Middleware::Debug->wrap
3691         'Plack::Middleware::Stacktrace', ## Plack::Middleware::Stacktrace->wrap
3692         '+MyApp::Custom',  ## MyApp::Custom->wrap
3693       ],
3694     );
3695
3696 =item a scalar followed by a hashref
3697
3698 Just like the previous, except the following C<HashRef> is used as arguments
3699 to initialize the middleware object.
3700
3701     __PACKAGE__->config(
3702       'psgi_middleware', [
3703          'Session' => {store => 'File'},
3704     ]);
3705
3706 =back
3707
3708 Please see L<PSGI> for more on middleware.
3709
3710 =head1 ENCODING
3711
3712 On request, decodes all params from encoding into a sequence of
3713 logical characters. On response, encodes body into encoding.
3714
3715 =head2 Methods
3716
3717 =over 4
3718
3719 =item encoding
3720
3721 Returns an instance of an C<Encode> encoding
3722
3723     print $c->encoding->name
3724
3725 =item handle_unicode_encoding_exception ($exception_context)
3726
3727 Method called when decoding process for a request fails.
3728
3729 An C<$exception_context> hashref is provided to allow you to override the
3730 behaviour of your application when given data with incorrect encodings.
3731
3732 The default method throws exceptions in the case of invalid request parameters
3733 (resulting in a 500 error), but ignores errors in upload filenames.
3734
3735 The keys passed in the C<$exception_context> hash are:
3736
3737 =over
3738
3739 =item param_value
3740
3741 The value which was not able to be decoded.
3742
3743 =item error_msg
3744
3745 The exception received from L<Encode>.
3746
3747 =item encoding_step
3748
3749 What type of data was being decoded. Valid values are (currently)
3750 C<params> - for request parameters / arguments / captures
3751 and C<uploads> - for request upload filenames.
3752
3753 =back
3754
3755 =back
3756
3757 =head1 SUPPORT
3758
3759 IRC:
3760
3761     Join #catalyst on irc.perl.org.
3762
3763 Mailing Lists:
3764
3765     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3766     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3767
3768 Web:
3769
3770     http://catalyst.perl.org
3771
3772 Wiki:
3773
3774     http://dev.catalyst.perl.org
3775
3776 =head1 SEE ALSO
3777
3778 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3779
3780 =head2 L<Catalyst::Manual> - The Catalyst Manual
3781
3782 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3783
3784 =head2 L<Catalyst::Engine> - Core engine
3785
3786 =head2 L<Catalyst::Log> - Log class.
3787
3788 =head2 L<Catalyst::Request> - Request object
3789
3790 =head2 L<Catalyst::Response> - Response object
3791
3792 =head2 L<Catalyst::Test> - The test suite.
3793
3794 =head1 PROJECT FOUNDER
3795
3796 sri: Sebastian Riedel <sri@cpan.org>
3797
3798 =head1 CONTRIBUTORS
3799
3800 abw: Andy Wardley
3801
3802 acme: Leon Brocard <leon@astray.com>
3803
3804 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3805
3806 Andrew Bramble
3807
3808 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3809
3810 Andrew Ruthven
3811
3812 andyg: Andy Grundman <andy@hybridized.org>
3813
3814 audreyt: Audrey Tang
3815
3816 bricas: Brian Cassidy <bricas@cpan.org>
3817
3818 Caelum: Rafael Kitover <rkitover@io.com>
3819
3820 chansen: Christian Hansen
3821
3822 chicks: Christopher Hicks
3823
3824 Chisel Wright C<pause@herlpacker.co.uk>
3825
3826 Danijel Milicevic C<me@danijel.de>
3827
3828 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3829
3830 David Naughton, C<naughton@umn.edu>
3831
3832 David E. Wheeler
3833
3834 dhoss: Devin Austin <dhoss@cpan.org>
3835
3836 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3837
3838 Drew Taylor
3839
3840 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3841
3842 esskar: Sascha Kiefer
3843
3844 fireartist: Carl Franks <cfranks@cpan.org>
3845
3846 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3847
3848 gabb: Danijel Milicevic
3849
3850 Gary Ashton Jones
3851
3852 Gavin Henry C<ghenry@perl.me.uk>
3853
3854 Geoff Richards
3855
3856 groditi: Guillermo Roditi <groditi@gmail.com>
3857
3858 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3859
3860 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3861
3862 jcamacho: Juan Camacho
3863
3864 jester: Jesse Sheidlower C<jester@panix.com>
3865
3866 jhannah: Jay Hannah <jay@jays.net>
3867
3868 Jody Belka
3869
3870 Johan Lindstrom
3871
3872 jon: Jon Schutz <jjschutz@cpan.org>
3873
3874 Jonathan Rockway C<< <jrockway@cpan.org> >>
3875
3876 Kieren Diment C<kd@totaldatasolution.com>
3877
3878 konobi: Scott McWhirter <konobi@cpan.org>
3879
3880 marcus: Marcus Ramberg <mramberg@cpan.org>
3881
3882 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3883
3884 mgrimes: Mark Grimes <mgrimes@cpan.org>
3885
3886 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3887
3888 mugwump: Sam Vilain
3889
3890 naughton: David Naughton
3891
3892 ningu: David Kamholz <dkamholz@cpan.org>
3893
3894 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3895
3896 numa: Dan Sully <daniel@cpan.org>
3897
3898 obra: Jesse Vincent
3899
3900 Octavian Rasnita
3901
3902 omega: Andreas Marienborg
3903
3904 Oleg Kostyuk <cub.uanic@gmail.com>
3905
3906 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3907
3908 rafl: Florian Ragwitz <rafl@debian.org>
3909
3910 random: Roland Lammel <lammel@cpan.org>
3911
3912 Robert Sedlacek C<< <rs@474.at> >>
3913
3914 SpiceMan: Marcel Montes
3915
3916 sky: Arthur Bergman
3917
3918 szbalint: Balint Szilakszi <szbalint@cpan.org>
3919
3920 t0m: Tomas Doran <bobtfish@bobtfish.net>
3921
3922 Ulf Edvinsson
3923
3924 Viljo Marrandi C<vilts@yahoo.com>
3925
3926 Will Hawes C<info@whawes.co.uk>
3927
3928 willert: Sebastian Willert <willert@cpan.org>
3929
3930 wreis: Wallace Reis <wreis@cpan.org>
3931
3932 Yuval Kogman, C<nothingmuch@woobling.org>
3933
3934 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3935
3936 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3937
3938 Upasana <me@upasana.me>
3939
3940 =head1 COPYRIGHT
3941
3942 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3943
3944 =head1 LICENSE
3945
3946 This library is free software. You can redistribute it and/or modify it under
3947 the same terms as Perl itself.
3948
3949 =cut
3950
3951 no Moose;
3952
3953 __PACKAGE__->meta->make_immutable;
3954
3955 1;