lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Devel::InnerPackage ();
  18 use File::stat;
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use utf8;
  32 use Carp qw/croak carp shortmess/;
  33
  34 BEGIN { require 5.008004; }
  35
  36 has stack => (is => 'ro', default => sub { [] });
  37 has stash => (is => 'rw', default => sub { {} });
  38 has state => (is => 'rw', default => 0);
  39 has stats => (is => 'rw');
  40 has action => (is => 'rw');
  41 has counter => (is => 'rw', default => sub { {} });
  42 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  43 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  44 has namespace => (is => 'rw');
  45
  46 sub depth { scalar @{ shift->stack || [] }; }
  47 sub comp { shift->component(@_) }
  48
  49 sub req {
  50     my $self = shift; return $self->request(@_);
  51 }
  52 sub res {
  53     my $self = shift; return $self->response(@_);
  54 }
  55
  56 # For backwards compatibility
  57 sub finalize_output { shift->finalize_body(@_) };
  58
  59 # For statistics
  60 our $COUNT     = 1;
  61 our $START     = time;
  62 our $RECURSION = 1000;
  63 our $DETACH    = Catalyst::Exception::Detach->new;
  64 our $GO        = Catalyst::Exception::Go->new;
  65
  66 #I imagine that very few of these really need to be class variables. if any.
  67 #maybe we should just make them attributes with a default?
  68 __PACKAGE__->mk_classdata($_)
  69   for qw/components arguments dispatcher engine log dispatcher_class
  70   engine_class context_class request_class response_class stats_class
  71   setup_finished/;
  72
  73 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  74 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  75 __PACKAGE__->request_class('Catalyst::Request');
  76 __PACKAGE__->response_class('Catalyst::Response');
  77 __PACKAGE__->stats_class('Catalyst::Stats');
  78
  79 # Remember to update this in Catalyst::Runtime as well!
  80
  81 our $VERSION = '5.80021';
  82 our $PRETTY_VERSION = $VERSION;
  83
  84 $VERSION = eval $VERSION;
  85
  86 sub import {
  87     my ( $class, @arguments ) = @_;
  88
  89     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  90     # callers @ISA.
  91     return unless $class eq 'Catalyst';
  92
  93     my $caller = caller();
  94     return if $caller eq 'main';
  95
  96     my $meta = Moose::Meta::Class->initialize($caller);
  97     unless ( $caller->isa('Catalyst') ) {
  98         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
  99         $meta->superclasses(@superclasses);
 100     }
 101     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 102     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 103
 104     unless( $meta->has_method('meta') ){
 105         $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 106     }
 107
 108     $caller->arguments( [@arguments] );
 109     $caller->setup_home;
 110 }
 111
 112 sub _application { $_[0] }
 113
 114 =head1 NAME
 115
 116 Catalyst - The Elegant MVC Web Application Framework
 117
 118 =head1 SYNOPSIS
 119
 120 See the L<Catalyst::Manual> distribution for comprehensive
 121 documentation and tutorials.
 122
 123     # Install Catalyst::Devel for helpers and other development tools
 124     # use the helper to create a new application
 125     catalyst.pl MyApp
 126
 127     # add models, views, controllers
 128     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 129     script/myapp_create.pl view MyTemplate TT
 130     script/myapp_create.pl controller Search
 131
 132     # built in testserver -- use -r to restart automatically on changes
 133     # --help to see all available options
 134     script/myapp_server.pl
 135
 136     # command line testing interface
 137     script/myapp_test.pl /yada
 138
 139     ### in lib/MyApp.pm
 140     use Catalyst qw/-Debug/; # include plugins here as well
 141
 142     ### In lib/MyApp/Controller/Root.pm (autocreated)
 143     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 144         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 145         $c->stash->{template} = 'foo.tt'; # set the template
 146         # lookup something from db -- stash vars are passed to TT
 147         $c->stash->{data} =
 148           $c->model('Database::Foo')->search( { country => $args[0] } );
 149         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 150             $c->forward( 'bar' ); # process another action
 151             # do something else after forward returns
 152         }
 153     }
 154
 155     # The foo.tt TT template can use the stash data from the database
 156     [% WHILE (item = data.next) %]
 157         [% item.foo %]
 158     [% END %]
 159
 160     # called for /bar/of/soap, /bar/of/soap/10, etc.
 161     sub bar : Path('/bar/of/soap') { ... }
 162
 163     # called for all actions, from the top-most controller downwards
 164     sub auto : Private {
 165         my ( $self, $c ) = @_;
 166         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 167             $c->res->redirect( '/login' ); # require login
 168             return 0; # abort request and go immediately to end()
 169         }
 170         return 1; # success; carry on to next action
 171     }
 172
 173     # called after all actions are finished
 174     sub end : Private {
 175         my ( $self, $c ) = @_;
 176         if ( scalar @{ $c->error } ) { ... } # handle errors
 177         return if $c->res->body; # already have a response
 178         $c->forward( 'MyApp::View::TT' ); # render template
 179     }
 180
 181     ### in MyApp/Controller/Foo.pm
 182     # called for /foo/bar
 183     sub bar : Local { ... }
 184
 185     # called for /blargle
 186     sub blargle : Global { ... }
 187
 188     # an index action matches /foo, but not /foo/1, etc.
 189     sub index : Private { ... }
 190
 191     ### in MyApp/Controller/Foo/Bar.pm
 192     # called for /foo/bar/baz
 193     sub baz : Local { ... }
 194
 195     # first Root auto is called, then Foo auto, then this
 196     sub auto : Private { ... }
 197
 198     # powerful regular expression paths are also possible
 199     sub details : Regex('^product/(\w+)/details$') {
 200         my ( $self, $c ) = @_;
 201         # extract the (\w+) from the URI
 202         my $product = $c->req->captures->[0];
 203     }
 204
 205 See L<Catalyst::Manual::Intro> for additional information.
 206
 207 =head1 DESCRIPTION
 208
 209 Catalyst is a modern framework for making web applications without the
 210 pain usually associated with this process. This document is a reference
 211 to the main Catalyst application. If you are a new user, we suggest you
 212 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 213
 214 See L<Catalyst::Manual> for more documentation.
 215
 216 Catalyst plugins can be loaded by naming them as arguments to the "use
 217 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 218 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 219 C<My::Module>.
 220
 221     use Catalyst qw/My::Module/;
 222
 223 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 224 fully qualify the name by using a unary plus:
 225
 226     use Catalyst qw/
 227         My::Module
 228         +Fully::Qualified::Plugin::Name
 229     /;
 230
 231 Special flags like C<-Debug> and C<-Engine> can also be specified as
 232 arguments when Catalyst is loaded:
 233
 234     use Catalyst qw/-Debug My::Module/;
 235
 236 The position of plugins and flags in the chain is important, because
 237 they are loaded in the order in which they appear.
 238
 239 The following flags are supported:
 240
 241 =head2 -Debug
 242
 243 Enables debug output. You can also force this setting from the system
 244 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 245 settings override the application, with <MYAPP>_DEBUG having the highest
 246 priority.
 247
 248 This sets the log level to 'debug' and enables full debug output on the
 249 error screen. If you only want the latter, see L<< $c->debug >>.
 250
 251 =head2 -Engine
 252
 253 Forces Catalyst to use a specific engine. Omit the
 254 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 255
 256     use Catalyst qw/-Engine=CGI/;
 257
 258 =head2 -Home
 259
 260 Forces Catalyst to use a specific home directory, e.g.:
 261
 262     use Catalyst qw[-Home=/usr/mst];
 263
 264 This can also be done in the shell environment by setting either the
 265 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 266 is replaced with the uppercased name of your application, any "::" in
 267 the name will be replaced with underscores, e.g. MyApp::Web should use
 268 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 269
 270 If none of these are set, Catalyst will attempt to automatically detect the
 271 home directory. If you are working in a development envirnoment, Catalyst
 272 will try and find the directory containing either Makefile.PL, Build.PL or
 273 dist.ini. If the application has been installed into the system (i.e.
 274 you have done C<make install>), then Catalyst will use the path to your
 275 application module, without the .pm extension (ie, /foo/MyApp if your
 276 application was installed at /foo/MyApp.pm)
 277
 278 =head2 -Log
 279
 280     use Catalyst '-Log=warn,fatal,error';
 281
 282 Specifies a comma-delimited list of log levels.
 283
 284 =head2 -Stats
 285
 286 Enables statistics collection and reporting. You can also force this setting
 287 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 288 environment settings override the application, with <MYAPP>_STATS having the
 289 highest priority.
 290
 291 e.g.
 292
 293    use Catalyst qw/-Stats=1/
 294
 295 =head1 METHODS
 296
 297 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 298
 299 =head2 $c->action
 300
 301 Returns a L<Catalyst::Action> object for the current action, which
 302 stringifies to the action name. See L<Catalyst::Action>.
 303
 304 =head2 $c->namespace
 305
 306 Returns the namespace of the current action, i.e., the URI prefix
 307 corresponding to the controller of the current action. For example:
 308
 309     # in Controller::Foo::Bar
 310     $c->namespace; # returns 'foo/bar';
 311
 312 =head2 $c->request
 313
 314 =head2 $c->req
 315
 316 Returns the current L<Catalyst::Request> object, giving access to
 317 information about the current client request (including parameters,
 318 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 319
 320 =head2 REQUEST FLOW HANDLING
 321
 322 =head2 $c->forward( $action [, \@arguments ] )
 323
 324 =head2 $c->forward( $class, $method, [, \@arguments ] )
 325
 326 Forwards processing to another action, by its private name. If you give a
 327 class name but no method, C<process()> is called. You may also optionally
 328 pass arguments in an arrayref. The action will receive the arguments in
 329 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 330 C<< $c->req->args >> will be restored to the previous values.
 331
 332 Any data C<return>ed from the action forwarded to, will be returned by the
 333 call to forward.
 334
 335     my $foodata = $c->forward('/foo');
 336     $c->forward('index');
 337     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 338     $c->forward('View::TT');
 339
 340 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 341 an C<< eval { } >> around the call (actually
 342 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 343 all 'dies' within the called action. If you want C<die> to propagate you
 344 need to do something like:
 345
 346     $c->forward('foo');
 347     die join "\n", @{ $c->error } if @{ $c->error };
 348
 349 Or make sure to always return true values from your actions and write
 350 your code like this:
 351
 352     $c->forward('foo') || return;
 353
 354 Another note is that C<< $c->forward >> always returns a scalar because it
 355 actually returns $c->state which operates in a scalar context.
 356 Thus, something like:
 357
 358     return @array;
 359
 360 in an action that is forwarded to is going to return a scalar,
 361 i.e. how many items are in that array, which is probably not what you want.
 362 If you need to return an array then return a reference to it,
 363 or stash it like so:
 364
 365     $c->stash->{array} = \@array;
 366
 367 and access it from the stash.
 368
 369 =cut
 370
 371 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 372
 373 =head2 $c->detach( $action [, \@arguments ] )
 374
 375 =head2 $c->detach( $class, $method, [, \@arguments ] )
 376
 377 =head2 $c->detach()
 378
 379 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 380 doesn't return to the previous action when processing is finished.
 381
 382 When called with no arguments it escapes the processing chain entirely.
 383
 384 =cut
 385
 386 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 387
 388 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 389
 390 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 391
 392 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 393 but does a full dispatch, instead of just calling the new C<$action> /
 394 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 395 you go to are called, just like a new request.
 396
 397 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 398 This means, for example, that C<< $c->action >> methods such as
 399 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 400 L<reverse|Catalyst::Action/reverse> return information for the visited action
 401 when they are invoked within the visited action.  This is different from the
 402 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 403 continues to use the $c->action object from the caller action even when
 404 invoked from the callee.
 405
 406 C<< $c->stash >> is kept unchanged.
 407
 408 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 409 allows you to "wrap" another action, just as it would have been called by
 410 dispatching from a URL, while the analogous
 411 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 412 transfer control to another action as if it had been reached directly from a URL.
 413
 414 =cut
 415
 416 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 417
 418 =head2 $c->go( $action [, \@captures, \@arguments ] )
 419
 420 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 421
 422 The relationship between C<go> and
 423 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 424 the relationship between
 425 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 426 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 427 C<< $c->go >> will perform a full dispatch on the specified action or method,
 428 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 429 C<go> escapes the processing of the current request chain on completion, and
 430 does not return to its caller.
 431
 432 =cut
 433
 434 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 435
 436 =head2 $c->response
 437
 438 =head2 $c->res
 439
 440 Returns the current L<Catalyst::Response> object, see there for details.
 441
 442 =head2 $c->stash
 443
 444 Returns a hashref to the stash, which may be used to store data and pass
 445 it between components during a request. You can also set hash keys by
 446 passing arguments. The stash is automatically sent to the view. The
 447 stash is cleared at the end of a request; it cannot be used for
 448 persistent storage (for this you must use a session; see
 449 L<Catalyst::Plugin::Session> for a complete system integrated with
 450 Catalyst).
 451
 452     $c->stash->{foo} = $bar;
 453     $c->stash( { moose => 'majestic', qux => 0 } );
 454     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 455
 456     # stash is automatically passed to the view for use in a template
 457     $c->forward( 'MyApp::View::TT' );
 458
 459 =cut
 460
 461 around stash => sub {
 462     my $orig = shift;
 463     my $c = shift;
 464     my $stash = $orig->($c);
 465     if (@_) {
 466         my $new_stash = @_ > 1 ? {@_} : $_[0];
 467         croak('stash takes a hash or hashref') unless ref $new_stash;
 468         foreach my $key ( keys %$new_stash ) {
 469           $stash->{$key} = $new_stash->{$key};
 470         }
 471     }
 472
 473     return $stash;
 474 };
 475
 476
 477 =head2 $c->error
 478
 479 =head2 $c->error($error, ...)
 480
 481 =head2 $c->error($arrayref)
 482
 483 Returns an arrayref containing error messages.  If Catalyst encounters an
 484 error while processing a request, it stores the error in $c->error.  This
 485 method should only be used to store fatal error messages.
 486
 487     my @error = @{ $c->error };
 488
 489 Add a new error.
 490
 491     $c->error('Something bad happened');
 492
 493 =cut
 494
 495 sub error {
 496     my $c = shift;
 497     if ( $_[0] ) {
 498         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 499         croak @$error unless ref $c;
 500         push @{ $c->{error} }, @$error;
 501     }
 502     elsif ( defined $_[0] ) { $c->{error} = undef }
 503     return $c->{error} || [];
 504 }
 505
 506
 507 =head2 $c->state
 508
 509 Contains the return value of the last executed action.
 510 Note that << $c->state >> operates in a scalar context which means that all
 511 values it returns are scalar.
 512
 513 =head2 $c->clear_errors
 514
 515 Clear errors.  You probably don't want to clear the errors unless you are
 516 implementing a custom error screen.
 517
 518 This is equivalent to running
 519
 520     $c->error(0);
 521
 522 =cut
 523
 524 sub clear_errors {
 525     my $c = shift;
 526     $c->error(0);
 527 }
 528
 529 sub _comp_search_prefixes {
 530     my $c = shift;
 531     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 532 }
 533
 534 # search components given a name and some prefixes
 535 sub _comp_names_search_prefixes {
 536     my ( $c, $name, @prefixes ) = @_;
 537     my $appclass = ref $c || $c;
 538     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 539     $filter = qr/$filter/; # Compile regex now rather than once per loop
 540
 541     # map the original component name to the sub part that we will search against
 542     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 543         grep { /$filter/ } keys %{ $c->components };
 544
 545     # undef for a name will return all
 546     return keys %eligible if !defined $name;
 547
 548     my $query  = ref $name ? $name : qr/^$name$/i;
 549     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 550
 551     return @result if @result;
 552
 553     # if we were given a regexp to search against, we're done.
 554     return if ref $name;
 555
 556     # skip regexp fallback if configured
 557     return
 558         if $appclass->config->{disable_component_resolution_regex_fallback};
 559
 560     # regexp fallback
 561     $query  = qr/$name/i;
 562     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 563
 564     # no results? try against full names
 565     if( !@result ) {
 566         @result = grep { m{$query} } keys %eligible;
 567     }
 568
 569     # don't warn if we didn't find any results, it just might not exist
 570     if( @result ) {
 571         # Disgusting hack to work out correct method name
 572         my $warn_for = lc $prefixes[0];
 573         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 574            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 575            "component resolution is unreliable and unsafe.";
 576         my $short = $result[0];
 577         # remove the component namespace prefix
 578         $short =~ s/.*?(Model|Controller|View):://;
 579         my $shortmess = Carp::shortmess('');
 580         if ($shortmess =~ m#Catalyst/Plugin#) {
 581            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 582               "plugin's config";
 583         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 584            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 585               "component's config";
 586         } else {
 587            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 588               "but if you really wanted to search, pass in a regexp as the argument " .
 589               "like so: \$c->${warn_for}(qr/${name}/)";
 590         }
 591         $c->log->warn( "${msg}$shortmess" );
 592     }
 593
 594     return @result;
 595 }
 596
 597 # Find possible names for a prefix
 598 sub _comp_names {
 599     my ( $c, @prefixes ) = @_;
 600     my $appclass = ref $c || $c;
 601
 602     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 603
 604     my @names = map { s{$filter}{}; $_; }
 605         $c->_comp_names_search_prefixes( undef, @prefixes );
 606
 607     return @names;
 608 }
 609
 610 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 611 sub _filter_component {
 612     my ( $c, $comp, @args ) = @_;
 613
 614     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 615         return $comp->ACCEPT_CONTEXT( $c, @args );
 616     }
 617
 618     return $comp;
 619 }
 620
 621 =head2 COMPONENT ACCESSORS
 622
 623 =head2 $c->controller($name)
 624
 625 Gets a L<Catalyst::Controller> instance by name.
 626
 627     $c->controller('Foo')->do_stuff;
 628
 629 If the name is omitted, will return the controller for the dispatched
 630 action.
 631
 632 If you want to search for controllers, pass in a regexp as the argument.
 633
 634     # find all controllers that start with Foo
 635     my @foo_controllers = $c->controller(qr{^Foo});
 636
 637
 638 =cut
 639
 640 sub controller {
 641     my ( $c, $name, @args ) = @_;
 642
 643     my $appclass = ref($c) || $c;
 644     if( $name ) {
 645         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 646             my $comps = $c->components;
 647             my $check = $appclass."::Controller::".$name;
 648             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 649         }
 650         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 651         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 652         return $c->_filter_component( $result[ 0 ], @args );
 653     }
 654
 655     return $c->component( $c->action->class );
 656 }
 657
 658 =head2 $c->model($name)
 659
 660 Gets a L<Catalyst::Model> instance by name.
 661
 662     $c->model('Foo')->do_stuff;
 663
 664 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 665
 666 If the name is omitted, it will look for
 667  - a model object in $c->stash->{current_model_instance}, then
 668  - a model name in $c->stash->{current_model}, then
 669  - a config setting 'default_model', or
 670  - check if there is only one model, and return it if that's the case.
 671
 672 If you want to search for models, pass in a regexp as the argument.
 673
 674     # find all models that start with Foo
 675     my @foo_models = $c->model(qr{^Foo});
 676
 677 =cut
 678
 679 sub model {
 680     my ( $c, $name, @args ) = @_;
 681     my $appclass = ref($c) || $c;
 682     if( $name ) {
 683         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 684             my $comps = $c->components;
 685             my $check = $appclass."::Model::".$name;
 686             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 687         }
 688         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 689         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 690         return $c->_filter_component( $result[ 0 ], @args );
 691     }
 692
 693     if (ref $c) {
 694         return $c->stash->{current_model_instance}
 695           if $c->stash->{current_model_instance};
 696         return $c->model( $c->stash->{current_model} )
 697           if $c->stash->{current_model};
 698     }
 699     return $c->model( $appclass->config->{default_model} )
 700       if $appclass->config->{default_model};
 701
 702     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 703
 704     if( $rest ) {
 705         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 706         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 707         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 708         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 709         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 710     }
 711
 712     return $c->_filter_component( $comp );
 713 }
 714
 715
 716 =head2 $c->view($name)
 717
 718 Gets a L<Catalyst::View> instance by name.
 719
 720     $c->view('Foo')->do_stuff;
 721
 722 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 723
 724 If the name is omitted, it will look for
 725  - a view object in $c->stash->{current_view_instance}, then
 726  - a view name in $c->stash->{current_view}, then
 727  - a config setting 'default_view', or
 728  - check if there is only one view, and return it if that's the case.
 729
 730 If you want to search for views, pass in a regexp as the argument.
 731
 732     # find all views that start with Foo
 733     my @foo_views = $c->view(qr{^Foo});
 734
 735 =cut
 736
 737 sub view {
 738     my ( $c, $name, @args ) = @_;
 739
 740     my $appclass = ref($c) || $c;
 741     if( $name ) {
 742         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 743             my $comps = $c->components;
 744             my $check = $appclass."::View::".$name;
 745             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 746         }
 747         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 748         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 749         return $c->_filter_component( $result[ 0 ], @args );
 750     }
 751
 752     if (ref $c) {
 753         return $c->stash->{current_view_instance}
 754           if $c->stash->{current_view_instance};
 755         return $c->view( $c->stash->{current_view} )
 756           if $c->stash->{current_view};
 757     }
 758     return $c->view( $appclass->config->{default_view} )
 759       if $appclass->config->{default_view};
 760
 761     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 762
 763     if( $rest ) {
 764         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 765         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 766         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 767         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 768         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 769     }
 770
 771     return $c->_filter_component( $comp );
 772 }
 773
 774 =head2 $c->controllers
 775
 776 Returns the available names which can be passed to $c->controller
 777
 778 =cut
 779
 780 sub controllers {
 781     my ( $c ) = @_;
 782     return $c->_comp_names(qw/Controller C/);
 783 }
 784
 785 =head2 $c->models
 786
 787 Returns the available names which can be passed to $c->model
 788
 789 =cut
 790
 791 sub models {
 792     my ( $c ) = @_;
 793     return $c->_comp_names(qw/Model M/);
 794 }
 795
 796
 797 =head2 $c->views
 798
 799 Returns the available names which can be passed to $c->view
 800
 801 =cut
 802
 803 sub views {
 804     my ( $c ) = @_;
 805     return $c->_comp_names(qw/View V/);
 806 }
 807
 808 =head2 $c->comp($name)
 809
 810 =head2 $c->component($name)
 811
 812 Gets a component object by name. This method is not recommended,
 813 unless you want to get a specific component by full
 814 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 815 should be used instead.
 816
 817 If C<$name> is a regexp, a list of components matched against the full
 818 component name will be returned.
 819
 820 If Catalyst can't find a component by name, it will fallback to regex
 821 matching by default. To disable this behaviour set
 822 disable_component_resolution_regex_fallback to a true value.
 823
 824     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 825
 826 =cut
 827
 828 sub component {
 829     my ( $c, $name, @args ) = @_;
 830
 831     if( $name ) {
 832         my $comps = $c->components;
 833
 834         if( !ref $name ) {
 835             # is it the exact name?
 836             return $c->_filter_component( $comps->{ $name }, @args )
 837                        if exists $comps->{ $name };
 838
 839             # perhaps we just omitted "MyApp"?
 840             my $composed = ( ref $c || $c ) . "::${name}";
 841             return $c->_filter_component( $comps->{ $composed }, @args )
 842                        if exists $comps->{ $composed };
 843
 844             # search all of the models, views and controllers
 845             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 846             return $c->_filter_component( $comp, @args ) if $comp;
 847         }
 848
 849         # This is here so $c->comp( '::M::' ) works
 850         my $query = ref $name ? $name : qr{$name}i;
 851
 852         my @result = grep { m{$query} } keys %{ $c->components };
 853         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 854
 855         if( $result[ 0 ] ) {
 856             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 857             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 858             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 859             return $c->_filter_component( $result[ 0 ], @args );
 860         }
 861
 862         # I would expect to return an empty list here, but that breaks back-compat
 863     }
 864
 865     # fallback
 866     return sort keys %{ $c->components };
 867 }
 868
 869 =head2 CLASS DATA AND HELPER CLASSES
 870
 871 =head2 $c->config
 872
 873 Returns or takes a hashref containing the application's configuration.
 874
 875     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 876
 877 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 878 like C<myapp.conf> in your applications home directory. See
 879 L<Catalyst::Plugin::ConfigLoader>.
 880
 881 =head3 Cascading configuration
 882
 883 The config method is present on all Catalyst components, and configuration
 884 will be merged when an application is started. Configuration loaded with
 885 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 886 followed by configuration in your top level C<MyApp> class. These two
 887 configurations are merged, and then configuration data whose hash key matches a
 888 component name is merged with configuration for that component.
 889
 890 The configuration for a component is then passed to the C<new> method when a
 891 component is constructed.
 892
 893 For example:
 894
 895     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 896     MyApp::Model::Foo->config({ quux => 'frob', 'overrides => 'this' });
 897
 898 will mean that C<MyApp::Model::Foo> receives the following data when
 899 constructed:
 900
 901     MyApp::Model::Foo->new({
 902         bar => 'baz',
 903         quux => 'frob',
 904         overrides => 'me',
 905     });
 906
 907 =cut
 908
 909 around config => sub {
 910     my $orig = shift;
 911     my $c = shift;
 912
 913     croak('Setting config after setup has been run is not allowed.')
 914         if ( @_ and $c->setup_finished );
 915
 916     $c->$orig(@_);
 917 };
 918
 919 =head2 $c->log
 920
 921 Returns the logging object instance. Unless it is already set, Catalyst
 922 sets this up with a L<Catalyst::Log> object. To use your own log class,
 923 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 924 C<< __PACKAGE__->setup >>.
 925
 926  __PACKAGE__->log( MyLogger->new );
 927  __PACKAGE__->setup;
 928
 929 And later:
 930
 931     $c->log->info( 'Now logging with my own logger!' );
 932
 933 Your log class should implement the methods described in
 934 L<Catalyst::Log>.
 935
 936
 937 =head2 $c->debug
 938
 939 Returns 1 if debug mode is enabled, 0 otherwise.
 940
 941 You can enable debug mode in several ways:
 942
 943 =over
 944
 945 =item By calling myapp_server.pl with the -d flag
 946
 947 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 948
 949 =item The -Debug option in your MyApp.pm
 950
 951 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 952
 953 =back
 954
 955 The first three also set the log level to 'debug'.
 956
 957 Calling C<< $c->debug(1) >> has no effect.
 958
 959 =cut
 960
 961 sub debug { 0 }
 962
 963 =head2 $c->dispatcher
 964
 965 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 966
 967 =head2 $c->engine
 968
 969 Returns the engine instance. See L<Catalyst::Engine>.
 970
 971
 972 =head2 UTILITY METHODS
 973
 974 =head2 $c->path_to(@path)
 975
 976 Merges C<@path> with C<< $c->config->{home} >> and returns a
 977 L<Path::Class::Dir> object. Note you can usually use this object as
 978 a filename, but sometimes you will have to explicitly stringify it
 979 yourself by calling the C<< ->stringify >> method.
 980
 981 For example:
 982
 983     $c->path_to( 'db', 'sqlite.db' );
 984
 985 =cut
 986
 987 sub path_to {
 988     my ( $c, @path ) = @_;
 989     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 990     if ( -d $path ) { return $path }
 991     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 992 }
 993
 994 =head2 $c->plugin( $name, $class, @args )
 995
 996 Helper method for plugins. It creates a class data accessor/mutator and
 997 loads and instantiates the given class.
 998
 999     MyApp->plugin( 'prototype', 'HTML::Prototype' );
1000
1001     $c->prototype->define_javascript_functions;
1002
1003 B<Note:> This method of adding plugins is deprecated. The ability
1004 to add plugins like this B<will be removed> in a Catalyst 5.81.
1005 Please do not use this functionality in new code.
1006
1007 =cut
1008
1009 sub plugin {
1010     my ( $class, $name, $plugin, @args ) = @_;
1011
1012     # See block comment in t/unit_core_plugin.t
1013     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in Catalyst 5.81/);
1014
1015     $class->_register_plugin( $plugin, 1 );
1016
1017     eval { $plugin->import };
1018     $class->mk_classdata($name);
1019     my $obj;
1020     eval { $obj = $plugin->new(@args) };
1021
1022     if ($@) {
1023         Catalyst::Exception->throw( message =>
1024               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1025     }
1026
1027     $class->$name($obj);
1028     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1029       if $class->debug;
1030 }
1031
1032 =head2 MyApp->setup
1033
1034 Initializes the dispatcher and engine, loads any plugins, and loads the
1035 model, view, and controller components. You may also specify an array
1036 of plugins to load here, if you choose to not load them in the C<use
1037 Catalyst> line.
1038
1039     MyApp->setup;
1040     MyApp->setup( qw/-Debug/ );
1041
1042 =cut
1043
1044 sub setup {
1045     my ( $class, @arguments ) = @_;
1046     croak('Running setup more than once')
1047         if ( $class->setup_finished );
1048
1049     unless ( $class->isa('Catalyst') ) {
1050
1051         Catalyst::Exception->throw(
1052             message => qq/'$class' does not inherit from Catalyst/ );
1053     }
1054
1055     if ( $class->arguments ) {
1056         @arguments = ( @arguments, @{ $class->arguments } );
1057     }
1058
1059     # Process options
1060     my $flags = {};
1061
1062     foreach (@arguments) {
1063
1064         if (/^-Debug$/) {
1065             $flags->{log} =
1066               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1067         }
1068         elsif (/^-(\w+)=?(.*)$/) {
1069             $flags->{ lc $1 } = $2;
1070         }
1071         else {
1072             push @{ $flags->{plugins} }, $_;
1073         }
1074     }
1075
1076     $class->setup_home( delete $flags->{home} );
1077
1078     $class->setup_log( delete $flags->{log} );
1079     $class->setup_plugins( delete $flags->{plugins} );
1080     $class->setup_dispatcher( delete $flags->{dispatcher} );
1081     $class->setup_engine( delete $flags->{engine} );
1082     $class->setup_stats( delete $flags->{stats} );
1083
1084     for my $flag ( sort keys %{$flags} ) {
1085
1086         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1087             &$code( $class, delete $flags->{$flag} );
1088         }
1089         else {
1090             $class->log->warn(qq/Unknown flag "$flag"/);
1091         }
1092     }
1093
1094     eval { require Catalyst::Devel; };
1095     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1096         $class->log->warn(<<"EOF");
1097 You are running an old script!
1098
1099   Please update by running (this will overwrite existing files):
1100     catalyst.pl -force -scripts $class
1101
1102   or (this will not overwrite existing files):
1103     catalyst.pl -scripts $class
1104
1105 EOF
1106     }
1107
1108     if ( $class->debug ) {
1109         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1110
1111         if (@plugins) {
1112             my $column_width = Catalyst::Utils::term_width() - 6;
1113             my $t = Text::SimpleTable->new($column_width);
1114             $t->row($_) for @plugins;
1115             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1116         }
1117
1118         my $dispatcher = $class->dispatcher;
1119         my $engine     = $class->engine;
1120         my $home       = $class->config->{home};
1121
1122         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1123         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1124
1125         $home
1126           ? ( -d $home )
1127           ? $class->log->debug(qq/Found home "$home"/)
1128           : $class->log->debug(qq/Home "$home" doesn't exist/)
1129           : $class->log->debug(q/Couldn't find home/);
1130     }
1131
1132     # Call plugins setup, this is stupid and evil.
1133     # Also screws C3 badly on 5.10, hack to avoid.
1134     {
1135         no warnings qw/redefine/;
1136         local *setup = sub { };
1137         $class->setup unless $Catalyst::__AM_RESTARTING;
1138     }
1139
1140     # Initialize our data structure
1141     $class->components( {} );
1142
1143     $class->setup_components;
1144
1145     if ( $class->debug ) {
1146         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1147         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1148         for my $comp ( sort keys %{ $class->components } ) {
1149             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1150             $t->row( $comp, $type );
1151         }
1152         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1153           if ( keys %{ $class->components } );
1154     }
1155
1156     # Add our self to components, since we are also a component
1157     if( $class->isa('Catalyst::Controller') ){
1158       $class->components->{$class} = $class;
1159     }
1160
1161     $class->setup_actions;
1162
1163     if ( $class->debug ) {
1164         my $name = $class->config->{name} || 'Application';
1165         $class->log->info("$name powered by Catalyst $Catalyst::PRETTY_VERSION");
1166     }
1167
1168     # Make sure that the application class becomes immutable at this point,
1169     B::Hooks::EndOfScope::on_scope_end {
1170         return if $@;
1171         my $meta = Class::MOP::get_metaclass_by_name($class);
1172         if (
1173             $meta->is_immutable
1174             && ! { $meta->immutable_options }->{replace_constructor}
1175             && (
1176                    $class->isa('Class::Accessor::Fast')
1177                 || $class->isa('Class::Accessor')
1178             )
1179         ) {
1180             warn "You made your application class ($class) immutable, "
1181                 . "but did not inline the\nconstructor. "
1182                 . "This will break catalyst, as your app \@ISA "
1183                 . "Class::Accessor(::Fast)?\nPlease pass "
1184                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1185         }
1186         $meta->make_immutable(
1187             replace_constructor => 1,
1188         ) unless $meta->is_immutable;
1189     };
1190
1191     if ($class->config->{case_sensitive}) {
1192         $class->log->warn($class . "->config->{case_sensitive} is set.");
1193         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1194     }
1195
1196     $class->setup_finalize;
1197     # Should be the last thing we do so that user things hooking
1198     # setup_finalize can log..
1199     $class->log->_flush() if $class->log->can('_flush');
1200     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1201 }
1202
1203 =head2 $app->setup_finalize
1204
1205 A hook to attach modifiers to. This method does not do anything except set the
1206 C<setup_finished> accessor.
1207
1208 Applying method modifiers to the C<setup> method doesn't work, because of quirky thingsdone for plugin setup.
1209
1210 Example:
1211
1212     after setup_finalize => sub {
1213         my $app = shift;
1214
1215         ## do stuff here..
1216     };
1217
1218 =cut
1219
1220 sub setup_finalize {
1221     my ($class) = @_;
1222     $class->setup_finished(1);
1223 }
1224
1225 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1226
1227 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1228
1229 Constructs an absolute L<URI> object based on the application root, the
1230 provided path, and the additional arguments and query parameters provided.
1231 When used as a string, provides a textual URI.
1232
1233 If no arguments are provided, the URI for the current action is returned.
1234 To return the current action and also provide @args, use
1235 C<< $c->uri_for( $c->action, @args ) >>.
1236
1237 If the first argument is a string, it is taken as a public URI path relative
1238 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1239 relative to the application root (if it does). It is then merged with
1240 C<< $c->request->base >>; any C<@args> are appended as additional path
1241 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1242
1243 If the first argument is a L<Catalyst::Action> it represents an action which
1244 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1245 optional C<\@captures> argument (an arrayref) allows passing the captured
1246 variables that are needed to fill in the paths of Chained and Regex actions;
1247 once the path is resolved, C<uri_for> continues as though a path was
1248 provided, appending any arguments or parameters and creating an absolute
1249 URI.
1250
1251 The captures for the current request can be found in
1252 C<< $c->request->captures >>, and actions can be resolved using
1253 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1254 path, use C<< $c->uri_for_action >> instead.
1255
1256   # Equivalent to $c->req->uri
1257   $c->uri_for($c->action, $c->req->captures,
1258       @{ $c->req->args }, $c->req->params);
1259
1260   # For the Foo action in the Bar controller
1261   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1262
1263   # Path to a static resource
1264   $c->uri_for('/static/images/logo.png');
1265
1266 =cut
1267
1268 sub uri_for {
1269     my ( $c, $path, @args ) = @_;
1270
1271     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1272         $path = $path->path_prefix;
1273         $path =~ s{/+\z}{};
1274         $path .= '/';
1275     }
1276
1277     undef($path) if (defined $path && $path eq '');
1278
1279     my $params =
1280       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1281
1282     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1283     foreach my $arg (@args) {
1284         utf8::encode($arg) if utf8::is_utf8($arg);
1285     }
1286     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
1287     if (blessed $path) { # Action object only.
1288         s|/|%2F|g for @args;
1289     }
1290
1291     if ( blessed($path) ) { # action object
1292         my $captures = [ map { s|/|%2F|g; $_; }
1293                         ( scalar @args && ref $args[0] eq 'ARRAY'
1294                          ? @{ shift(@args) }
1295                          : ()) ];
1296
1297         foreach my $capture (@$captures) {
1298             utf8::encode($capture) if utf8::is_utf8($capture);
1299             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1300         }
1301
1302         my $action = $path;
1303         $path = $c->dispatcher->uri_for_action($action, $captures);
1304         if (not defined $path) {
1305             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1306                 if $c->debug;
1307             return undef;
1308         }
1309         $path = '/' if $path eq '';
1310     }
1311
1312     undef($path) if (defined $path && $path eq '');
1313
1314     unshift(@args, $path);
1315
1316     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1317         my $namespace = $c->namespace;
1318         if (defined $path) { # cheesy hack to handle path '../foo'
1319            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1320         }
1321         unshift(@args, $namespace || '');
1322     }
1323
1324     # join args with '/', or a blank string
1325     my $args = join('/', grep { defined($_) } @args);
1326     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1327     $args =~ s!^/+!!;
1328     my $base = $c->req->base;
1329     my $class = ref($base);
1330     $base =~ s{(?<!/)$}{/};
1331
1332     my $query = '';
1333
1334     if (my @keys = keys %$params) {
1335       # somewhat lifted from URI::_query's query_form
1336       $query = '?'.join('&', map {
1337           my $val = $params->{$_};
1338           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1339           s/ /+/g;
1340           my $key = $_;
1341           $val = '' unless defined $val;
1342           (map {
1343               my $param = "$_";
1344               utf8::encode( $param ) if utf8::is_utf8($param);
1345               # using the URI::Escape pattern here so utf8 chars survive
1346               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1347               $param =~ s/ /+/g;
1348               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1349       } @keys);
1350     }
1351
1352     my $res = bless(\"${base}${args}${query}", $class);
1353     $res;
1354 }
1355
1356 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1357
1358 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1359
1360 =over
1361
1362 =item $path
1363
1364 A private path to the Catalyst action you want to create a URI for.
1365
1366 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1367 >> and passing the resulting C<$action> and the remaining arguments to C<<
1368 $c->uri_for >>.
1369
1370 You can also pass in a Catalyst::Action object, in which case it is passed to
1371 C<< $c->uri_for >>.
1372
1373 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1374
1375 For example, if the action looks like:
1376
1377  package MyApp::Controller::Users;
1378
1379  sub lst : Path('the-list') {}
1380
1381 You can use:
1382
1383  $c->uri_for_action('/users/lst')
1384
1385 and it will create the URI /users/the-list.
1386
1387 =back
1388
1389 =cut
1390
1391 sub uri_for_action {
1392     my ( $c, $path, @args ) = @_;
1393     my $action = blessed($path)
1394       ? $path
1395       : $c->dispatcher->get_action_by_path($path);
1396     unless (defined $action) {
1397       croak "Can't find action for path '$path'";
1398     }
1399     return $c->uri_for( $action, @args );
1400 }
1401
1402 =head2 $c->welcome_message
1403
1404 Returns the Catalyst welcome HTML page.
1405
1406 =cut
1407
1408 sub welcome_message {
1409     my $c      = shift;
1410     my $name   = $c->config->{name};
1411     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1412     my $prefix = Catalyst::Utils::appprefix( ref $c );
1413     $c->response->content_type('text/html; charset=utf-8');
1414     return <<"EOF";
1415 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1416     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1417 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1418     <head>
1419     <meta http-equiv="Content-Language" content="en" />
1420     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1421         <title>$name on Catalyst $VERSION</title>
1422         <style type="text/css">
1423             body {
1424                 color: #000;
1425                 background-color: #eee;
1426             }
1427             div#content {
1428                 width: 640px;
1429                 margin-left: auto;
1430                 margin-right: auto;
1431                 margin-top: 10px;
1432                 margin-bottom: 10px;
1433                 text-align: left;
1434                 background-color: #ccc;
1435                 border: 1px solid #aaa;
1436             }
1437             p, h1, h2 {
1438                 margin-left: 20px;
1439                 margin-right: 20px;
1440                 font-family: verdana, tahoma, sans-serif;
1441             }
1442             a {
1443                 font-family: verdana, tahoma, sans-serif;
1444             }
1445             :link, :visited {
1446                     text-decoration: none;
1447                     color: #b00;
1448                     border-bottom: 1px dotted #bbb;
1449             }
1450             :link:hover, :visited:hover {
1451                     color: #555;
1452             }
1453             div#topbar {
1454                 margin: 0px;
1455             }
1456             pre {
1457                 margin: 10px;
1458                 padding: 8px;
1459             }
1460             div#answers {
1461                 padding: 8px;
1462                 margin: 10px;
1463                 background-color: #fff;
1464                 border: 1px solid #aaa;
1465             }
1466             h1 {
1467                 font-size: 0.9em;
1468                 font-weight: normal;
1469                 text-align: center;
1470             }
1471             h2 {
1472                 font-size: 1.0em;
1473             }
1474             p {
1475                 font-size: 0.9em;
1476             }
1477             p img {
1478                 float: right;
1479                 margin-left: 10px;
1480             }
1481             span#appname {
1482                 font-weight: bold;
1483                 font-size: 1.6em;
1484             }
1485         </style>
1486     </head>
1487     <body>
1488         <div id="content">
1489             <div id="topbar">
1490                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1491                     $VERSION</h1>
1492              </div>
1493              <div id="answers">
1494                  <p>
1495                  <img src="$logo" alt="Catalyst Logo" />
1496                  </p>
1497                  <p>Welcome to the  world of Catalyst.
1498                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1499                     framework will make web development something you had
1500                     never expected it to be: Fun, rewarding, and quick.</p>
1501                  <h2>What to do now?</h2>
1502                  <p>That really depends  on what <b>you</b> want to do.
1503                     We do, however, provide you with a few starting points.</p>
1504                  <p>If you want to jump right into web development with Catalyst
1505                     you might want to start with a tutorial.</p>
1506 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1507 </pre>
1508 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1509 <pre>
1510 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1511 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1512 </code></pre>
1513                  <h2>What to do next?</h2>
1514                  <p>Next it's time to write an actual application. Use the
1515                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1516                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1517                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1518                     they can save you a lot of work.</p>
1519                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1520                     <p>Also, be sure to check out the vast and growing
1521                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1522                     you are likely to find what you need there.
1523                     </p>
1524
1525                  <h2>Need help?</h2>
1526                  <p>Catalyst has a very active community. Here are the main places to
1527                     get in touch with us.</p>
1528                  <ul>
1529                      <li>
1530                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1531                      </li>
1532                      <li>
1533                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1534                      </li>
1535                      <li>
1536                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1537                      </li>
1538                  </ul>
1539                  <h2>In conclusion</h2>
1540                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1541                     as we enjoyed making it. Please contact us if you have ideas
1542                     for improvement or other feedback.</p>
1543              </div>
1544          </div>
1545     </body>
1546 </html>
1547 EOF
1548 }
1549
1550 =head1 INTERNAL METHODS
1551
1552 These methods are not meant to be used by end users.
1553
1554 =head2 $c->components
1555
1556 Returns a hash of components.
1557
1558 =head2 $c->context_class
1559
1560 Returns or sets the context class.
1561
1562 =head2 $c->counter
1563
1564 Returns a hashref containing coderefs and execution counts (needed for
1565 deep recursion detection).
1566
1567 =head2 $c->depth
1568
1569 Returns the number of actions on the current internal execution stack.
1570
1571 =head2 $c->dispatch
1572
1573 Dispatches a request to actions.
1574
1575 =cut
1576
1577 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1578
1579 =head2 $c->dispatcher_class
1580
1581 Returns or sets the dispatcher class.
1582
1583 =head2 $c->dump_these
1584
1585 Returns a list of 2-element array references (name, structure) pairs
1586 that will be dumped on the error page in debug mode.
1587
1588 =cut
1589
1590 sub dump_these {
1591     my $c = shift;
1592     [ Request => $c->req ],
1593     [ Response => $c->res ],
1594     [ Stash => $c->stash ],
1595     [ Config => $c->config ];
1596 }
1597
1598 =head2 $c->engine_class
1599
1600 Returns or sets the engine class.
1601
1602 =head2 $c->execute( $class, $coderef )
1603
1604 Execute a coderef in given class and catch exceptions. Errors are available
1605 via $c->error.
1606
1607 =cut
1608
1609 sub execute {
1610     my ( $c, $class, $code ) = @_;
1611     $class = $c->component($class) || $class;
1612     $c->state(0);
1613
1614     if ( $c->depth >= $RECURSION ) {
1615         my $action = $code->reverse();
1616         $action = "/$action" unless $action =~ /->/;
1617         my $error = qq/Deep recursion detected calling "${action}"/;
1618         $c->log->error($error);
1619         $c->error($error);
1620         $c->state(0);
1621         return $c->state;
1622     }
1623
1624     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1625
1626     push( @{ $c->stack }, $code );
1627
1628     no warnings 'recursion';
1629     eval { $c->state( $code->execute( $class, $c, @{ $c->req->args } ) || 0 ) };
1630
1631     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1632
1633     my $last = pop( @{ $c->stack } );
1634
1635     if ( my $error = $@ ) {
1636         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1637             $error->rethrow if $c->depth > 1;
1638         }
1639         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1640             $error->rethrow if $c->depth > 0;
1641         }
1642         else {
1643             unless ( ref $error ) {
1644                 no warnings 'uninitialized';
1645                 chomp $error;
1646                 my $class = $last->class;
1647                 my $name  = $last->name;
1648                 $error = qq/Caught exception in $class->$name "$error"/;
1649             }
1650             $c->error($error);
1651             $c->state(0);
1652         }
1653     }
1654     return $c->state;
1655 }
1656
1657 sub _stats_start_execute {
1658     my ( $c, $code ) = @_;
1659     my $appclass = ref($c) || $c;
1660     return if ( ( $code->name =~ /^_.*/ )
1661         && ( !$appclass->config->{show_internal_actions} ) );
1662
1663     my $action_name = $code->reverse();
1664     $c->counter->{$action_name}++;
1665
1666     my $action = $action_name;
1667     $action = "/$action" unless $action =~ /->/;
1668
1669     # determine if the call was the result of a forward
1670     # this is done by walking up the call stack and looking for a calling
1671     # sub of Catalyst::forward before the eval
1672     my $callsub = q{};
1673     for my $index ( 2 .. 11 ) {
1674         last
1675         if ( ( caller($index) )[0] eq 'Catalyst'
1676             && ( caller($index) )[3] eq '(eval)' );
1677
1678         if ( ( caller($index) )[3] =~ /forward$/ ) {
1679             $callsub = ( caller($index) )[3];
1680             $action  = "-> $action";
1681             last;
1682         }
1683     }
1684
1685     my $uid = $action_name . $c->counter->{$action_name};
1686
1687     # is this a root-level call or a forwarded call?
1688     if ( $callsub =~ /forward$/ ) {
1689         my $parent = $c->stack->[-1];
1690
1691         # forward, locate the caller
1692         if ( exists $c->counter->{"$parent"} ) {
1693             $c->stats->profile(
1694                 begin  => $action,
1695                 parent => "$parent" . $c->counter->{"$parent"},
1696                 uid    => $uid,
1697             );
1698         }
1699         else {
1700
1701             # forward with no caller may come from a plugin
1702             $c->stats->profile(
1703                 begin => $action,
1704                 uid   => $uid,
1705             );
1706         }
1707     }
1708     else {
1709
1710         # root-level call
1711         $c->stats->profile(
1712             begin => $action,
1713             uid   => $uid,
1714         );
1715     }
1716     return $action;
1717
1718 }
1719
1720 sub _stats_finish_execute {
1721     my ( $c, $info ) = @_;
1722     $c->stats->profile( end => $info );
1723 }
1724
1725 =head2 $c->finalize
1726
1727 Finalizes the request.
1728
1729 =cut
1730
1731 sub finalize {
1732     my $c = shift;
1733
1734     for my $error ( @{ $c->error } ) {
1735         $c->log->error($error);
1736     }
1737
1738     # Allow engine to handle finalize flow (for POE)
1739     my $engine = $c->engine;
1740     if ( my $code = $engine->can('finalize') ) {
1741         $engine->$code($c);
1742     }
1743     else {
1744
1745         $c->finalize_uploads;
1746
1747         # Error
1748         if ( $#{ $c->error } >= 0 ) {
1749             $c->finalize_error;
1750         }
1751
1752         $c->finalize_headers;
1753
1754         # HEAD request
1755         if ( $c->request->method eq 'HEAD' ) {
1756             $c->response->body('');
1757         }
1758
1759         $c->finalize_body;
1760     }
1761
1762     $c->log_response;
1763
1764     if ($c->use_stats) {
1765         my $elapsed = sprintf '%f', $c->stats->elapsed;
1766         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1767         $c->log->info(
1768             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1769     }
1770
1771     return $c->response->status;
1772 }
1773
1774 =head2 $c->finalize_body
1775
1776 Finalizes body.
1777
1778 =cut
1779
1780 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1781
1782 =head2 $c->finalize_cookies
1783
1784 Finalizes cookies.
1785
1786 =cut
1787
1788 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1789
1790 =head2 $c->finalize_error
1791
1792 Finalizes error.
1793
1794 =cut
1795
1796 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1797
1798 =head2 $c->finalize_headers
1799
1800 Finalizes headers.
1801
1802 =cut
1803
1804 sub finalize_headers {
1805     my $c = shift;
1806
1807     my $response = $c->response; #accessor calls can add up?
1808
1809     # Check if we already finalized headers
1810     return if $response->finalized_headers;
1811
1812     # Handle redirects
1813     if ( my $location = $response->redirect ) {
1814         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1815         $response->header( Location => $location );
1816
1817         if ( !$response->has_body ) {
1818             # Add a default body if none is already present
1819             $response->body(
1820                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1821             );
1822         }
1823     }
1824
1825     # Content-Length
1826     if ( $response->body && !$response->content_length ) {
1827
1828         # get the length from a filehandle
1829         if ( blessed( $response->body ) && $response->body->can('read') )
1830         {
1831             my $stat = stat $response->body;
1832             if ( $stat && $stat->size > 0 ) {
1833                 $response->content_length( $stat->size );
1834             }
1835             else {
1836                 $c->log->warn('Serving filehandle without a content-length');
1837             }
1838         }
1839         else {
1840             # everything should be bytes at this point, but just in case
1841             $response->content_length( length( $response->body ) );
1842         }
1843     }
1844
1845     # Errors
1846     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1847         $response->headers->remove_header("Content-Length");
1848         $response->body('');
1849     }
1850
1851     $c->finalize_cookies;
1852
1853     $c->engine->finalize_headers( $c, @_ );
1854
1855     # Done
1856     $response->finalized_headers(1);
1857 }
1858
1859 =head2 $c->finalize_output
1860
1861 An alias for finalize_body.
1862
1863 =head2 $c->finalize_read
1864
1865 Finalizes the input after reading is complete.
1866
1867 =cut
1868
1869 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1870
1871 =head2 $c->finalize_uploads
1872
1873 Finalizes uploads. Cleans up any temporary files.
1874
1875 =cut
1876
1877 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1878
1879 =head2 $c->get_action( $action, $namespace )
1880
1881 Gets an action in a given namespace.
1882
1883 =cut
1884
1885 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1886
1887 =head2 $c->get_actions( $action, $namespace )
1888
1889 Gets all actions of a given name in a namespace and all parent
1890 namespaces.
1891
1892 =cut
1893
1894 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1895
1896 =head2 $c->handle_request( $class, @arguments )
1897
1898 Called to handle each HTTP request.
1899
1900 =cut
1901
1902 sub handle_request {
1903     my ( $class, @arguments ) = @_;
1904
1905     # Always expect worst case!
1906     my $status = -1;
1907     eval {
1908         if ($class->debug) {
1909             my $secs = time - $START || 1;
1910             my $av = sprintf '%.3f', $COUNT / $secs;
1911             my $time = localtime time;
1912             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1913         }
1914
1915         my $c = $class->prepare(@arguments);
1916         $c->dispatch;
1917         $status = $c->finalize;
1918     };
1919
1920     if ( my $error = $@ ) {
1921         chomp $error;
1922         $class->log->error(qq/Caught exception in engine "$error"/);
1923     }
1924
1925     $COUNT++;
1926
1927     if(my $coderef = $class->log->can('_flush')){
1928         $class->log->$coderef();
1929     }
1930     return $status;
1931 }
1932
1933 =head2 $c->prepare( @arguments )
1934
1935 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1936 etc.).
1937
1938 =cut
1939
1940 sub prepare {
1941     my ( $class, @arguments ) = @_;
1942
1943     # XXX
1944     # After the app/ctxt split, this should become an attribute based on something passed
1945     # into the application.
1946     $class->context_class( ref $class || $class ) unless $class->context_class;
1947
1948     my $c = $class->context_class->new({});
1949
1950     # For on-demand data
1951     $c->request->_context($c);
1952     $c->response->_context($c);
1953
1954     #surely this is not the most efficient way to do things...
1955     $c->stats($class->stats_class->new)->enable($c->use_stats);
1956     if ( $c->debug ) {
1957         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1958     }
1959
1960     #XXX reuse coderef from can
1961     # Allow engine to direct the prepare flow (for POE)
1962     if ( $c->engine->can('prepare') ) {
1963         $c->engine->prepare( $c, @arguments );
1964     }
1965     else {
1966         $c->prepare_request(@arguments);
1967         $c->prepare_connection;
1968         $c->prepare_query_parameters;
1969         $c->prepare_headers;
1970         $c->prepare_cookies;
1971         $c->prepare_path;
1972
1973         # Prepare the body for reading, either by prepare_body
1974         # or the user, if they are using $c->read
1975         $c->prepare_read;
1976
1977         # Parse the body unless the user wants it on-demand
1978         unless ( ref($c)->config->{parse_on_demand} ) {
1979             $c->prepare_body;
1980         }
1981     }
1982
1983     my $method  = $c->req->method  || '';
1984     my $path    = $c->req->path;
1985     $path       = '/' unless length $path;
1986     my $address = $c->req->address || '';
1987
1988     $c->log_request;
1989
1990     $c->prepare_action;
1991
1992     return $c;
1993 }
1994
1995 =head2 $c->prepare_action
1996
1997 Prepares action. See L<Catalyst::Dispatcher>.
1998
1999 =cut
2000
2001 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2002
2003 =head2 $c->prepare_body
2004
2005 Prepares message body.
2006
2007 =cut
2008
2009 sub prepare_body {
2010     my $c = shift;
2011
2012     return if $c->request->_has_body;
2013
2014     # Initialize on-demand data
2015     $c->engine->prepare_body( $c, @_ );
2016     $c->prepare_parameters;
2017     $c->prepare_uploads;
2018 }
2019
2020 =head2 $c->prepare_body_chunk( $chunk )
2021
2022 Prepares a chunk of data before sending it to L<HTTP::Body>.
2023
2024 See L<Catalyst::Engine>.
2025
2026 =cut
2027
2028 sub prepare_body_chunk {
2029     my $c = shift;
2030     $c->engine->prepare_body_chunk( $c, @_ );
2031 }
2032
2033 =head2 $c->prepare_body_parameters
2034
2035 Prepares body parameters.
2036
2037 =cut
2038
2039 sub prepare_body_parameters {
2040     my $c = shift;
2041     $c->engine->prepare_body_parameters( $c, @_ );
2042 }
2043
2044 =head2 $c->prepare_connection
2045
2046 Prepares connection.
2047
2048 =cut
2049
2050 sub prepare_connection {
2051     my $c = shift;
2052     $c->engine->prepare_connection( $c, @_ );
2053 }
2054
2055 =head2 $c->prepare_cookies
2056
2057 Prepares cookies.
2058
2059 =cut
2060
2061 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2062
2063 =head2 $c->prepare_headers
2064
2065 Prepares headers.
2066
2067 =cut
2068
2069 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2070
2071 =head2 $c->prepare_parameters
2072
2073 Prepares parameters.
2074
2075 =cut
2076
2077 sub prepare_parameters {
2078     my $c = shift;
2079     $c->prepare_body_parameters;
2080     $c->engine->prepare_parameters( $c, @_ );
2081 }
2082
2083 =head2 $c->prepare_path
2084
2085 Prepares path and base.
2086
2087 =cut
2088
2089 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2090
2091 =head2 $c->prepare_query_parameters
2092
2093 Prepares query parameters.
2094
2095 =cut
2096
2097 sub prepare_query_parameters {
2098     my $c = shift;
2099
2100     $c->engine->prepare_query_parameters( $c, @_ );
2101 }
2102
2103 =head2 $c->log_request
2104
2105 Writes information about the request to the debug logs.  This includes:
2106
2107 =over 4
2108
2109 =item * Request method, path, and remote IP address
2110
2111 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2112
2113 =item * Request parameters
2114
2115 =item * File uploads
2116
2117 =back
2118
2119 =cut
2120
2121 sub log_request {
2122     my $c = shift;
2123
2124     return unless $c->debug;
2125
2126     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2127     my $request = $dump->[1];
2128
2129     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2130     $method ||= '';
2131     $path = '/' unless length $path;
2132     $address ||= '';
2133     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2134
2135     $c->log_request_headers($request->headers);
2136
2137     if ( my $keywords = $request->query_keywords ) {
2138         $c->log->debug("Query keywords are: $keywords");
2139     }
2140
2141     $c->log_request_parameters( query => $request->query_parameters, body => $request->body_parameters );
2142
2143     $c->log_request_uploads($request);
2144 }
2145
2146 =head2 $c->log_response
2147
2148 Writes information about the response to the debug logs by calling
2149 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2150
2151 =cut
2152
2153 sub log_response {
2154     my $c = shift;
2155
2156     return unless $c->debug;
2157
2158     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2159     my $response = $dump->[1];
2160
2161     $c->log_response_status_line($response);
2162     $c->log_response_headers($response->headers);
2163 }
2164
2165 =head2 $c->log_response_status_line($response)
2166
2167 Writes one line of information about the response to the debug logs.  This includes:
2168
2169 =over 4
2170
2171 =item * Response status code
2172
2173 =item * Content-Type header (if present)
2174
2175 =item * Content-Length header (if present)
2176
2177 =back
2178
2179 =cut
2180
2181 sub log_response_status_line {
2182     my ($c, $response) = @_;
2183
2184     $c->log->debug(
2185         sprintf(
2186             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2187             $response->status                            || 'unknown',
2188             $response->headers->header('Content-Type')   || 'unknown',
2189             $response->headers->header('Content-Length') || 'unknown'
2190         )
2191     );
2192 }
2193
2194 =head2 $c->log_response_headers($headers);
2195
2196 Hook method which can be wrapped by plugins to log the responseheaders.
2197 No-op in the default implementation.
2198
2199 =cut
2200
2201 sub log_response_headers {}
2202
2203 =head2 $c->log_request_parameters( query => {}, body => {} )
2204
2205 Logs request parameters to debug logs
2206
2207 =cut
2208
2209 sub log_request_parameters {
2210     my $c          = shift;
2211     my %all_params = @_;
2212
2213     return unless $c->debug;
2214
2215     my $column_width = Catalyst::Utils::term_width() - 44;
2216     foreach my $type (qw(query body)) {
2217         my $params = $all_params{$type};
2218         next if ! keys %$params;
2219         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2220         for my $key ( sort keys %$params ) {
2221             my $param = $params->{$key};
2222             my $value = defined($param) ? $param : '';
2223             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2224         }
2225         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2226     }
2227 }
2228
2229 =head2 $c->log_request_uploads
2230
2231 Logs file uploads included in the request to the debug logs.
2232 The parameter name, filename, file type, and file size are all included in
2233 the debug logs.
2234
2235 =cut
2236
2237 sub log_request_uploads {
2238     my $c = shift;
2239     my $request = shift;
2240     return unless $c->debug;
2241     my $uploads = $request->uploads;
2242     if ( keys %$uploads ) {
2243         my $t = Text::SimpleTable->new(
2244             [ 12, 'Parameter' ],
2245             [ 26, 'Filename' ],
2246             [ 18, 'Type' ],
2247             [ 9,  'Size' ]
2248         );
2249         for my $key ( sort keys %$uploads ) {
2250             my $upload = $uploads->{$key};
2251             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2252                 $t->row( $key, $u->filename, $u->type, $u->size );
2253             }
2254         }
2255         $c->log->debug( "File Uploads are:\n" . $t->draw );
2256     }
2257 }
2258
2259 =head2 $c->log_request_headers($headers);
2260
2261 Hook method which can be wrapped by plugins to log the request headers.
2262 No-op in the default implementation.
2263
2264 =cut
2265
2266 sub log_request_headers {}
2267
2268 =head2 $c->log_headers($type => $headers)
2269
2270 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2271
2272 =cut
2273
2274 sub log_headers {
2275     my $c       = shift;
2276     my $type    = shift;
2277     my $headers = shift;    # an HTTP::Headers instance
2278
2279     return unless $c->debug;
2280
2281     my $t = Text::SimpleTable->new( [ 35, 'Header Name' ], [ 40, 'Value' ] );
2282     $headers->scan(
2283         sub {
2284             my ( $name, $value ) = @_;
2285             $t->row( $name, $value );
2286         }
2287     );
2288     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2289 }
2290
2291
2292 =head2 $c->prepare_read
2293
2294 Prepares the input for reading.
2295
2296 =cut
2297
2298 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2299
2300 =head2 $c->prepare_request
2301
2302 Prepares the engine request.
2303
2304 =cut
2305
2306 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2307
2308 =head2 $c->prepare_uploads
2309
2310 Prepares uploads.
2311
2312 =cut
2313
2314 sub prepare_uploads {
2315     my $c = shift;
2316
2317     $c->engine->prepare_uploads( $c, @_ );
2318 }
2319
2320 =head2 $c->prepare_write
2321
2322 Prepares the output for writing.
2323
2324 =cut
2325
2326 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2327
2328 =head2 $c->request_class
2329
2330 Returns or sets the request class.
2331
2332 =head2 $c->response_class
2333
2334 Returns or sets the response class.
2335
2336 =head2 $c->read( [$maxlength] )
2337
2338 Reads a chunk of data from the request body. This method is designed to
2339 be used in a while loop, reading C<$maxlength> bytes on every call.
2340 C<$maxlength> defaults to the size of the request if not specified.
2341
2342 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2343 directly.
2344
2345 Warning: If you use read(), Catalyst will not process the body,
2346 so you will not be able to access POST parameters or file uploads via
2347 $c->request.  You must handle all body parsing yourself.
2348
2349 =cut
2350
2351 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2352
2353 =head2 $c->run
2354
2355 Starts the engine.
2356
2357 =cut
2358
2359 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
2360
2361 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2362
2363 Sets an action in a given namespace.
2364
2365 =cut
2366
2367 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2368
2369 =head2 $c->setup_actions($component)
2370
2371 Sets up actions for a component.
2372
2373 =cut
2374
2375 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2376
2377 =head2 $c->setup_components
2378
2379 This method is called internally to set up the application's components.
2380
2381 It finds modules by calling the L<locate_components> method, expands them to
2382 package names with the L<expand_component_module> method, and then installs
2383 each component into the application.
2384
2385 The C<setup_components> config option is passed to both of the above methods.
2386
2387 Installation of each component is performed by the L<setup_component> method,
2388 below.
2389
2390 =cut
2391
2392 sub setup_components {
2393     my $class = shift;
2394
2395     my $config  = $class->config->{ setup_components };
2396
2397     my @comps = sort { length $a <=> length $b }
2398                 $class->locate_components($config);
2399     my %comps = map { $_ => 1 } @comps;
2400
2401     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2402     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2403         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2404     ) if $deprecatedcatalyst_component_names;
2405
2406     for my $component ( @comps ) {
2407
2408         # We pass ignore_loaded here so that overlay files for (e.g.)
2409         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2410         # we know M::P::O found a file on disk so this is safe
2411
2412         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2413
2414         # Needs to be done as soon as the component is loaded, as loading a sub-component
2415         # (next time round the loop) can cause us to get the wrong metaclass..
2416         $class->_controller_init_base_classes($component);
2417     }
2418
2419     for my $component (@comps) {
2420         my $instance = $class->components->{ $component } = $class->setup_component($component);
2421         my @expanded_components = $instance->can('expand_modules')
2422             ? $instance->expand_modules( $component, $config )
2423             : $class->expand_component_module( $component, $config );
2424         for my $component (@expanded_components) {
2425             next if $comps{$component};
2426             $class->_controller_init_base_classes($component); # Also cover inner packages
2427             $class->components->{ $component } = $class->setup_component($component);
2428         }
2429     }
2430 }
2431
2432 =head2 $c->locate_components( $setup_component_config )
2433
2434 This method is meant to provide a list of component modules that should be
2435 setup for the application.  By default, it will use L<Module::Pluggable>.
2436
2437 Specify a C<setup_components> config option to pass additional options directly
2438 to L<Module::Pluggable>. To add additional search paths, specify a key named
2439 C<search_extra> as an array reference. Items in the array beginning with C<::>
2440 will have the application class name prepended to them.
2441
2442 =cut
2443
2444 sub locate_components {
2445     my $class  = shift;
2446     my $config = shift;
2447
2448     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2449     my $extra   = delete $config->{ search_extra } || [];
2450
2451     push @paths, @$extra;
2452
2453     my $locator = Module::Pluggable::Object->new(
2454         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2455         %$config
2456     );
2457
2458     my @comps = $locator->plugins;
2459
2460     return @comps;
2461 }
2462
2463 =head2 $c->expand_component_module( $component, $setup_component_config )
2464
2465 Components found by C<locate_components> will be passed to this method, which
2466 is expected to return a list of component (package) names to be set up.
2467
2468 =cut
2469
2470 sub expand_component_module {
2471     my ($class, $module) = @_;
2472     return Devel::InnerPackage::list_packages( $module );
2473 }
2474
2475 =head2 $c->setup_component
2476
2477 =cut
2478
2479 # FIXME - Ugly, ugly hack to ensure the we force initialize non-moose base classes
2480 #         nearest to Catalyst::Controller first, no matter what order stuff happens
2481 #         to be loaded. There are TODO tests in Moose for this, see
2482 #         f2391d17574eff81d911b97be15ea51080500003
2483 sub _controller_init_base_classes {
2484     my ($app_class, $component) = @_;
2485     return unless $component->isa('Catalyst::Controller');
2486     foreach my $class ( reverse @{ mro::get_linear_isa($component) } ) {
2487         Moose::Meta::Class->initialize( $class )
2488             unless find_meta($class);
2489     }
2490 }
2491
2492 sub setup_component {
2493     my( $class, $component ) = @_;
2494
2495     unless ( $component->can( 'COMPONENT' ) ) {
2496         return $component;
2497     }
2498
2499     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2500     my $config = $class->config->{ $suffix } || {};
2501     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2502     # methods also pass it. local to avoid pointlessly shitting in config
2503     # for the debug screen, as $component is already the key name.
2504     local $config->{catalyst_component_name} = $component;
2505
2506     my $instance = eval { $component->COMPONENT( $class, $config ); };
2507
2508     if ( my $error = $@ ) {
2509         chomp $error;
2510         Catalyst::Exception->throw(
2511             message => qq/Couldn't instantiate component "$component", "$error"/
2512         );
2513     }
2514
2515     unless (blessed $instance) {
2516         my $metaclass = Moose::Util::find_meta($component);
2517         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2518         my $component_method_from = $method_meta->associated_metaclass->name;
2519         my $value = defined($instance) ? $instance : 'undef';
2520         Catalyst::Exception->throw(
2521             message =>
2522             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2523         );
2524     }
2525     return $instance;
2526 }
2527
2528 =head2 $c->setup_dispatcher
2529
2530 Sets up dispatcher.
2531
2532 =cut
2533
2534 sub setup_dispatcher {
2535     my ( $class, $dispatcher ) = @_;
2536
2537     if ($dispatcher) {
2538         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2539     }
2540
2541     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2542         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2543     }
2544
2545     unless ($dispatcher) {
2546         $dispatcher = $class->dispatcher_class;
2547     }
2548
2549     Class::MOP::load_class($dispatcher);
2550
2551     # dispatcher instance
2552     $class->dispatcher( $dispatcher->new );
2553 }
2554
2555 =head2 $c->setup_engine
2556
2557 Sets up engine.
2558
2559 =cut
2560
2561 sub setup_engine {
2562     my ( $class, $engine ) = @_;
2563
2564     if ($engine) {
2565         $engine = 'Catalyst::Engine::' . $engine;
2566     }
2567
2568     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
2569         $engine = 'Catalyst::Engine::' . $env;
2570     }
2571
2572     if ( $ENV{MOD_PERL} ) {
2573         my $meta = Class::MOP::get_metaclass_by_name($class);
2574
2575         # create the apache method
2576         $meta->add_method('apache' => sub { shift->engine->apache });
2577
2578         my ( $software, $version ) =
2579           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
2580
2581         $version =~ s/_//g;
2582         $version =~ s/(\.[^.]+)\./$1/g;
2583
2584         if ( $software eq 'mod_perl' ) {
2585
2586             if ( !$engine ) {
2587
2588                 if ( $version >= 1.99922 ) {
2589                     $engine = 'Catalyst::Engine::Apache2::MP20';
2590                 }
2591
2592                 elsif ( $version >= 1.9901 ) {
2593                     $engine = 'Catalyst::Engine::Apache2::MP19';
2594                 }
2595
2596                 elsif ( $version >= 1.24 ) {
2597                     $engine = 'Catalyst::Engine::Apache::MP13';
2598                 }
2599
2600                 else {
2601                     Catalyst::Exception->throw( message =>
2602                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2603                 }
2604
2605             }
2606
2607             # install the correct mod_perl handler
2608             if ( $version >= 1.9901 ) {
2609                 *handler = sub  : method {
2610                     shift->handle_request(@_);
2611                 };
2612             }
2613             else {
2614                 *handler = sub ($$) { shift->handle_request(@_) };
2615             }
2616
2617         }
2618
2619         elsif ( $software eq 'Zeus-Perl' ) {
2620             $engine = 'Catalyst::Engine::Zeus';
2621         }
2622
2623         else {
2624             Catalyst::Exception->throw(
2625                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2626         }
2627     }
2628
2629     unless ($engine) {
2630         $engine = $class->engine_class;
2631     }
2632
2633     Class::MOP::load_class($engine);
2634
2635     # check for old engines that are no longer compatible
2636     my $old_engine;
2637     if ( $engine->isa('Catalyst::Engine::Apache')
2638         && !Catalyst::Engine::Apache->VERSION )
2639     {
2640         $old_engine = 1;
2641     }
2642
2643     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2644         && Catalyst::Engine::Server->VERSION le '0.02' )
2645     {
2646         $old_engine = 1;
2647     }
2648
2649     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2650         && $engine->VERSION eq '0.01' )
2651     {
2652         $old_engine = 1;
2653     }
2654
2655     elsif ($engine->isa('Catalyst::Engine::Zeus')
2656         && $engine->VERSION eq '0.01' )
2657     {
2658         $old_engine = 1;
2659     }
2660
2661     if ($old_engine) {
2662         Catalyst::Exception->throw( message =>
2663               qq/Engine "$engine" is not supported by this version of Catalyst/
2664         );
2665     }
2666
2667     # engine instance
2668     $class->engine( $engine->new );
2669 }
2670
2671 =head2 $c->setup_home
2672
2673 Sets up the home directory.
2674
2675 =cut
2676
2677 sub setup_home {
2678     my ( $class, $home ) = @_;
2679
2680     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2681         $home = $env;
2682     }
2683
2684     $home ||= Catalyst::Utils::home($class);
2685
2686     if ($home) {
2687         #I remember recently being scolded for assigning config values like this
2688         $class->config->{home} ||= $home;
2689         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2690     }
2691 }
2692
2693 =head2 $c->setup_log
2694
2695 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2696 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2697 log to.
2698
2699 This method also installs a C<debug> method that returns a true value into the
2700 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2701 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2702
2703 Note that if the log has already been setup, by either a previous call to
2704 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2705 that this method won't actually set up the log object.
2706
2707 =cut
2708
2709 sub setup_log {
2710     my ( $class, $levels ) = @_;
2711
2712     $levels ||= '';
2713     $levels =~ s/^\s+//;
2714     $levels =~ s/\s+$//;
2715     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2716
2717     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2718     if ( defined $env_debug ) {
2719         $levels{debug} = 1 if $env_debug; # Ugly!
2720         delete($levels{debug}) unless $env_debug;
2721     }
2722
2723     unless ( $class->log ) {
2724         $class->log( Catalyst::Log->new(keys %levels) );
2725     }
2726
2727     if ( $levels{debug} ) {
2728         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2729         $class->log->debug('Debug messages enabled');
2730     }
2731 }
2732
2733 =head2 $c->setup_plugins
2734
2735 Sets up plugins.
2736
2737 =cut
2738
2739 =head2 $c->setup_stats
2740
2741 Sets up timing statistics class.
2742
2743 =cut
2744
2745 sub setup_stats {
2746     my ( $class, $stats ) = @_;
2747
2748     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2749
2750     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2751     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2752         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2753         $class->log->debug('Statistics enabled');
2754     }
2755 }
2756
2757
2758 =head2 $c->registered_plugins
2759
2760 Returns a sorted list of the plugins which have either been stated in the
2761 import list or which have been added via C<< MyApp->plugin(@args); >>.
2762
2763 If passed a given plugin name, it will report a boolean value indicating
2764 whether or not that plugin is loaded.  A fully qualified name is required if
2765 the plugin name does not begin with C<Catalyst::Plugin::>.
2766
2767  if ($c->registered_plugins('Some::Plugin')) {
2768      ...
2769  }
2770
2771 =cut
2772
2773 {
2774
2775     sub registered_plugins {
2776         my $proto = shift;
2777         return sort keys %{ $proto->_plugins } unless @_;
2778         my $plugin = shift;
2779         return 1 if exists $proto->_plugins->{$plugin};
2780         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2781     }
2782
2783     sub _register_plugin {
2784         my ( $proto, $plugin, $instant ) = @_;
2785         my $class = ref $proto || $proto;
2786
2787         Class::MOP::load_class( $plugin );
2788         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is decated and will not work in 5.81" )
2789             if $plugin->isa( 'Catalyst::Component' );
2790         $proto->_plugins->{$plugin} = 1;
2791         unless ($instant) {
2792             no strict 'refs';
2793             if ( my $meta = Class::MOP::get_metaclass_by_name($class) ) {
2794               my @superclasses = ($plugin, $meta->superclasses );
2795               $meta->superclasses(@superclasses);
2796             } else {
2797               unshift @{"$class\::ISA"}, $plugin;
2798             }
2799         }
2800         return $class;
2801     }
2802
2803     sub setup_plugins {
2804         my ( $class, $plugins ) = @_;
2805
2806         $class->_plugins( {} ) unless $class->_plugins;
2807         $plugins ||= [];
2808
2809         my @plugins = Catalyst::Utils::resolve_namespace($class . '::Plugin', 'Catalyst::Plugin', @$plugins);
2810
2811         for my $plugin ( reverse @plugins ) {
2812             Class::MOP::load_class($plugin);
2813             my $meta = find_meta($plugin);
2814             next if $meta && $meta->isa('Moose::Meta::Role');
2815
2816             $class->_register_plugin($plugin);
2817         }
2818
2819         my @roles =
2820             map { $_->name }
2821             grep { $_ && blessed($_) && $_->isa('Moose::Meta::Role') }
2822             map { find_meta($_) }
2823             @plugins;
2824
2825         Moose::Util::apply_all_roles(
2826             $class => @roles
2827         ) if @roles;
2828     }
2829 }
2830
2831 =head2 $c->stack
2832
2833 Returns an arrayref of the internal execution stack (actions that are
2834 currently executing).
2835
2836 =head2 $c->stats_class
2837
2838 Returns or sets the stats (timing statistics) class.
2839
2840 =head2 $c->use_stats
2841
2842 Returns 1 when stats collection is enabled.  Stats collection is enabled
2843 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2844 environment variable is set.
2845
2846 Note that this is a static method, not an accessor and should be overridden
2847 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2848
2849 =cut
2850
2851 sub use_stats { 0 }
2852
2853
2854 =head2 $c->write( $data )
2855
2856 Writes $data to the output stream. When using this method directly, you
2857 will need to manually set the C<Content-Length> header to the length of
2858 your output data, if known.
2859
2860 =cut
2861
2862 sub write {
2863     my $c = shift;
2864
2865     # Finalize headers if someone manually writes output
2866     $c->finalize_headers;
2867
2868     return $c->engine->write( $c, @_ );
2869 }
2870
2871 =head2 version
2872
2873 Returns the Catalyst version number. Mostly useful for "powered by"
2874 messages in template systems.
2875
2876 =cut
2877
2878 sub version { return $Catalyst::VERSION }
2879
2880 =head1 CONFIGURATION
2881
2882 There are a number of 'base' config variables which can be set:
2883
2884 =over
2885
2886 =item *
2887
2888 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2889
2890 =item *
2891
2892 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2893
2894 =item *
2895
2896 C<disable_component_resolution_regex_fallback> - Turns
2897 off the deprecated component resolution functionality so
2898 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2899 are called then regex search will not be attempted on string values and
2900 instead C<undef> will be returned.
2901
2902 =item *
2903
2904 C<home> - The application home directory. In an uninstalled application,
2905 this is the top level application directory. In an installed application,
2906 this will be the directory containing C<< MyApp.pm >>.
2907
2908 =item *
2909
2910 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2911
2912 =item *
2913
2914 C<name> - The name of the application in debug messages and the debug and
2915 welcome screens
2916
2917 =item *
2918
2919 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2920 until it is accessed. This allows you to (for example) check authentication (and reject
2921 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2922
2923 =item *
2924
2925 C<root> - The root directory for templates. Usually this is just a
2926 subdirectory of the home directory, but you can set it to change the
2927 templates to a different directory.
2928
2929 =item *
2930
2931 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2932 namespaces from which components will be loaded (and constructed and stored in
2933 C<< $c->components >>).
2934
2935 =item *
2936
2937 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
2938 to be shown in hit debug tables in the test server.
2939
2940 =item *
2941
2942 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
2943
2944 =back
2945
2946 =head1 INTERNAL ACTIONS
2947
2948 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2949 C<_ACTION>, and C<_END>. These are by default not shown in the private
2950 action table, but you can make them visible with a config parameter.
2951
2952     MyApp->config(show_internal_actions => 1);
2953
2954 =head1 ON-DEMAND PARSER
2955
2956 The request body is usually parsed at the beginning of a request,
2957 but if you want to handle input yourself, you can enable on-demand
2958 parsing with a config parameter.
2959
2960     MyApp->config(parse_on_demand => 1);
2961
2962 =head1 PROXY SUPPORT
2963
2964 Many production servers operate using the common double-server approach,
2965 with a lightweight frontend web server passing requests to a larger
2966 backend server. An application running on the backend server must deal
2967 with two problems: the remote user always appears to be C<127.0.0.1> and
2968 the server's hostname will appear to be C<localhost> regardless of the
2969 virtual host that the user connected through.
2970
2971 Catalyst will automatically detect this situation when you are running
2972 the frontend and backend servers on the same machine. The following
2973 changes are made to the request.
2974
2975     $c->req->address is set to the user's real IP address, as read from
2976     the HTTP X-Forwarded-For header.
2977
2978     The host value for $c->req->base and $c->req->uri is set to the real
2979     host, as read from the HTTP X-Forwarded-Host header.
2980
2981 Additionally, you may be running your backend application on an insecure
2982 connection (port 80) while your frontend proxy is running under SSL.  If there
2983 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
2984 tell Catalyst what port the frontend listens on.  This will allow all URIs to
2985 be created properly.
2986
2987 In the case of passing in:
2988
2989     X-Forwarded-Port: 443
2990
2991 All calls to C<uri_for> will result in an https link, as is expected.
2992
2993 Obviously, your web server must support these headers for this to work.
2994
2995 In a more complex server farm environment where you may have your
2996 frontend proxy server(s) on different machines, you will need to set a
2997 configuration option to tell Catalyst to read the proxied data from the
2998 headers.
2999
3000     MyApp->config(using_frontend_proxy => 1);
3001
3002 If you do not wish to use the proxy support at all, you may set:
3003
3004     MyApp->config(ignore_frontend_proxy => 1);
3005
3006 =head1 THREAD SAFETY
3007
3008 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3009 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3010 believe the Catalyst core to be thread-safe.
3011
3012 If you plan to operate in a threaded environment, remember that all other
3013 modules you are using must also be thread-safe. Some modules, most notably
3014 L<DBD::SQLite>, are not thread-safe.
3015
3016 =head1 SUPPORT
3017
3018 IRC:
3019
3020     Join #catalyst on irc.perl.org.
3021
3022 Mailing Lists:
3023
3024     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3025     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3026
3027 Web:
3028
3029     http://catalyst.perl.org
3030
3031 Wiki:
3032
3033     http://dev.catalyst.perl.org
3034
3035 =head1 SEE ALSO
3036
3037 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3038
3039 =head2 L<Catalyst::Manual> - The Catalyst Manual
3040
3041 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3042
3043 =head2 L<Catalyst::Engine> - Core engine
3044
3045 =head2 L<Catalyst::Log> - Log class.
3046
3047 =head2 L<Catalyst::Request> - Request object
3048
3049 =head2 L<Catalyst::Response> - Response object
3050
3051 =head2 L<Catalyst::Test> - The test suite.
3052
3053 =head1 PROJECT FOUNDER
3054
3055 sri: Sebastian Riedel <sri@cpan.org>
3056
3057 =head1 CONTRIBUTORS
3058
3059 abw: Andy Wardley
3060
3061 acme: Leon Brocard <leon@astray.com>
3062
3063 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3064
3065 Andrew Bramble
3066
3067 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3068
3069 Andrew Ruthven
3070
3071 andyg: Andy Grundman <andy@hybridized.org>
3072
3073 audreyt: Audrey Tang
3074
3075 bricas: Brian Cassidy <bricas@cpan.org>
3076
3077 Caelum: Rafael Kitover <rkitover@io.com>
3078
3079 chansen: Christian Hansen
3080
3081 chicks: Christopher Hicks
3082
3083 Chisel Wright C<pause@herlpacker.co.uk>
3084
3085 Danijel Milicevic C<me@danijel.de>
3086
3087 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3088
3089 David Naughton, C<naughton@umn.edu>
3090
3091 David E. Wheeler
3092
3093 dhoss: Devin Austin <dhoss@cpan.org>
3094
3095 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3096
3097 Drew Taylor
3098
3099 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3100
3101 esskar: Sascha Kiefer
3102
3103 fireartist: Carl Franks <cfranks@cpan.org>
3104
3105 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3106
3107 gabb: Danijel Milicevic
3108
3109 Gary Ashton Jones
3110
3111 Gavin Henry C<ghenry@perl.me.uk>
3112
3113 Geoff Richards
3114
3115 groditi: Guillermo Roditi <groditi@gmail.com>
3116
3117 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3118
3119 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3120
3121 jcamacho: Juan Camacho
3122
3123 jester: Jesse Sheidlower C<jester@panix.com>
3124
3125 jhannah: Jay Hannah <jay@jays.net>
3126
3127 Jody Belka
3128
3129 Johan Lindstrom
3130
3131 jon: Jon Schutz <jjschutz@cpan.org>
3132
3133 Jonathan Rockway C<< <jrockway@cpan.org> >>
3134
3135 Kieren Diment C<kd@totaldatasolution.com>
3136
3137 konobi: Scott McWhirter <konobi@cpan.org>
3138
3139 marcus: Marcus Ramberg <mramberg@cpan.org>
3140
3141 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3142
3143 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3144
3145 mugwump: Sam Vilain
3146
3147 naughton: David Naughton
3148
3149 ningu: David Kamholz <dkamholz@cpan.org>
3150
3151 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3152
3153 numa: Dan Sully <daniel@cpan.org>
3154
3155 obra: Jesse Vincent
3156
3157 Octavian Rasnita
3158
3159 omega: Andreas Marienborg
3160
3161 Oleg Kostyuk <cub.uanic@gmail.com>
3162
3163 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3164
3165 rafl: Florian Ragwitz <rafl@debian.org>
3166
3167 random: Roland Lammel <lammel@cpan.org>
3168
3169 Robert Sedlacek C<< <rs@474.at> >>
3170
3171 sky: Arthur Bergman
3172
3173 szbalint: Balint Szilakszi <szbalint@cpan.org>
3174
3175 t0m: Tomas Doran <bobtfish@bobtfish.net>
3176
3177 Ulf Edvinsson
3178
3179 Viljo Marrandi C<vilts@yahoo.com>
3180
3181 Will Hawes C<info@whawes.co.uk>
3182
3183 willert: Sebastian Willert <willert@cpan.org>
3184
3185 Yuval Kogman, C<nothingmuch@woobling.org>
3186
3187 =head1 LICENSE
3188
3189 This library is free software. You can redistribute it and/or modify it under
3190 the same terms as Perl itself.
3191
3192 =cut
3193
3194 no Moose;
3195
3196 __PACKAGE__->meta->make_immutable;
3197
3198 1;