lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use Moose;
   4 use Moose::Meta::Class ();
   5 extends 'Catalyst::Component';
   6 use Moose::Util qw/find_meta/;
   7 use B::Hooks::EndOfScope ();
   8 use Catalyst::Exception;
   9 use Catalyst::Exception::Detach;
  10 use Catalyst::Exception::Go;
  11 use Catalyst::Log;
  12 use Catalyst::Request;
  13 use Catalyst::Request::Upload;
  14 use Catalyst::Response;
  15 use Catalyst::Utils;
  16 use Catalyst::Controller;
  17 use Data::OptList;
  18 use Devel::InnerPackage ();
  19 use Module::Pluggable::Object ();
  20 use Text::SimpleTable ();
  21 use Path::Class::Dir ();
  22 use Path::Class::File ();
  23 use URI ();
  24 use URI::http;
  25 use URI::https;
  26 use Tree::Simple qw/use_weak_refs/;
  27 use Tree::Simple::Visitor::FindByUID;
  28 use Class::C3::Adopt::NEXT;
  29 use List::MoreUtils qw/uniq/;
  30 use attributes;
  31 use String::RewritePrefix;
  32 use Catalyst::EngineLoader;
  33 use utf8;
  34 use Carp qw/croak carp shortmess/;
  35 use Try::Tiny;
  36 use Plack::Middleware::Conditional;
  37 use Plack::Middleware::ReverseProxy;
  38 use Plack::Middleware::IIS6ScriptNameFix;
  39 use Plack::Middleware::LighttpdScriptNameFix;
  40
  41 BEGIN { require 5.008004; }
  42
  43 has stack => (is => 'ro', default => sub { [] });
  44 has stash => (is => 'rw', default => sub { {} });
  45 has state => (is => 'rw', default => 0);
  46 has stats => (is => 'rw');
  47 has action => (is => 'rw');
  48 has counter => (is => 'rw', default => sub { {} });
  49 has request => (is => 'rw', default => sub { $_[0]->request_class->new({}) }, required => 1, lazy => 1);
  50 has response => (is => 'rw', default => sub { $_[0]->response_class->new({}) }, required => 1, lazy => 1);
  51 has namespace => (is => 'rw');
  52
  53 sub depth { scalar @{ shift->stack || [] }; }
  54 sub comp { shift->component(@_) }
  55
  56 sub req {
  57     my $self = shift; return $self->request(@_);
  58 }
  59 sub res {
  60     my $self = shift; return $self->response(@_);
  61 }
  62
  63 # For backwards compatibility
  64 sub finalize_output { shift->finalize_body(@_) };
  65
  66 # For statistics
  67 our $COUNT     = 1;
  68 our $START     = time;
  69 our $RECURSION = 1000;
  70 our $DETACH    = Catalyst::Exception::Detach->new;
  71 our $GO        = Catalyst::Exception::Go->new;
  72
  73 #I imagine that very few of these really need to be class variables. if any.
  74 #maybe we should just make them attributes with a default?
  75 __PACKAGE__->mk_classdata($_)
  76   for qw/components arguments dispatcher engine log dispatcher_class
  77   engine_loader context_class request_class response_class stats_class
  78   setup_finished _psgi_app loading_psgi_file/;
  79
  80 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  81 __PACKAGE__->request_class('Catalyst::Request');
  82 __PACKAGE__->response_class('Catalyst::Response');
  83 __PACKAGE__->stats_class('Catalyst::Stats');
  84
  85 # Remember to update this in Catalyst::Runtime as well!
  86
  87 our $VERSION = '5.90004';
  88
  89 sub import {
  90     my ( $class, @arguments ) = @_;
  91
  92     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  93     # callers @ISA.
  94     return unless $class eq 'Catalyst';
  95
  96     my $caller = caller();
  97     return if $caller eq 'main';
  98
  99     my $meta = Moose::Meta::Class->initialize($caller);
 100     unless ( $caller->isa('Catalyst') ) {
 101         my @superclasses = ($meta->superclasses, $class, 'Catalyst::Controller');
 102         $meta->superclasses(@superclasses);
 103     }
 104     # Avoid possible C3 issues if 'Moose::Object' is already on RHS of MyApp
 105     $meta->superclasses(grep { $_ ne 'Moose::Object' } $meta->superclasses);
 106
 107     unless( $meta->has_method('meta') ){
 108         if ($Moose::VERSION >= 1.15) {
 109             $meta->_add_meta_method('meta');
 110         }
 111         else {
 112             $meta->add_method(meta => sub { Moose::Meta::Class->initialize("${caller}") } );
 113         }
 114     }
 115
 116     $caller->arguments( [@arguments] );
 117     $caller->setup_home;
 118 }
 119
 120 sub _application { $_[0] }
 121
 122 =head1 NAME
 123
 124 Catalyst - The Elegant MVC Web Application Framework
 125
 126 =head1 SYNOPSIS
 127
 128 See the L<Catalyst::Manual> distribution for comprehensive
 129 documentation and tutorials.
 130
 131     # Install Catalyst::Devel for helpers and other development tools
 132     # use the helper to create a new application
 133     catalyst.pl MyApp
 134
 135     # add models, views, controllers
 136     script/myapp_create.pl model MyDatabase DBIC::Schema create=static dbi:SQLite:/path/to/db
 137     script/myapp_create.pl view MyTemplate TT
 138     script/myapp_create.pl controller Search
 139
 140     # built in testserver -- use -r to restart automatically on changes
 141     # --help to see all available options
 142     script/myapp_server.pl
 143
 144     # command line testing interface
 145     script/myapp_test.pl /yada
 146
 147     ### in lib/MyApp.pm
 148     use Catalyst qw/-Debug/; # include plugins here as well
 149
 150     ### In lib/MyApp/Controller/Root.pm (autocreated)
 151     sub foo : Chained('/') Args() { # called for /foo, /foo/1, /foo/1/2, etc.
 152         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 153         $c->stash->{template} = 'foo.tt'; # set the template
 154         # lookup something from db -- stash vars are passed to TT
 155         $c->stash->{data} =
 156           $c->model('Database::Foo')->search( { country => $args[0] } );
 157         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 158             $c->forward( 'bar' ); # process another action
 159             # do something else after forward returns
 160         }
 161     }
 162
 163     # The foo.tt TT template can use the stash data from the database
 164     [% WHILE (item = data.next) %]
 165         [% item.foo %]
 166     [% END %]
 167
 168     # called for /bar/of/soap, /bar/of/soap/10, etc.
 169     sub bar : Chained('/') PathPart('/bar/of/soap') Args() { ... }
 170
 171     # called after all actions are finished
 172     sub end : Action {
 173         my ( $self, $c ) = @_;
 174         if ( scalar @{ $c->error } ) { ... } # handle errors
 175         return if $c->res->body; # already have a response
 176         $c->forward( 'MyApp::View::TT' ); # render template
 177     }
 178
 179 See L<Catalyst::Manual::Intro> for additional information.
 180
 181 =head1 DESCRIPTION
 182
 183 Catalyst is a modern framework for making web applications without the
 184 pain usually associated with this process. This document is a reference
 185 to the main Catalyst application. If you are a new user, we suggest you
 186 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 187
 188 See L<Catalyst::Manual> for more documentation.
 189
 190 Catalyst plugins can be loaded by naming them as arguments to the "use
 191 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 192 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 193 C<My::Module>.
 194
 195     use Catalyst qw/My::Module/;
 196
 197 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 198 fully qualify the name by using a unary plus:
 199
 200     use Catalyst qw/
 201         My::Module
 202         +Fully::Qualified::Plugin::Name
 203     /;
 204
 205 Special flags like C<-Debug> can also be specified as
 206 arguments when Catalyst is loaded:
 207
 208     use Catalyst qw/-Debug My::Module/;
 209
 210 The position of plugins and flags in the chain is important, because
 211 they are loaded in the order in which they appear.
 212
 213 The following flags are supported:
 214
 215 =head2 -Debug
 216
 217 Enables debug output. You can also force this setting from the system
 218 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 219 settings override the application, with <MYAPP>_DEBUG having the highest
 220 priority.
 221
 222 This sets the log level to 'debug' and enables full debug output on the
 223 error screen. If you only want the latter, see L<< $c->debug >>.
 224
 225 =head2 -Home
 226
 227 Forces Catalyst to use a specific home directory, e.g.:
 228
 229     use Catalyst qw[-Home=/usr/mst];
 230
 231 This can also be done in the shell environment by setting either the
 232 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 233 is replaced with the uppercased name of your application, any "::" in
 234 the name will be replaced with underscores, e.g. MyApp::Web should use
 235 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 236
 237 If none of these are set, Catalyst will attempt to automatically detect the
 238 home directory. If you are working in a development envirnoment, Catalyst
 239 will try and find the directory containing either Makefile.PL, Build.PL or
 240 dist.ini. If the application has been installed into the system (i.e.
 241 you have done C<make install>), then Catalyst will use the path to your
 242 application module, without the .pm extension (ie, /foo/MyApp if your
 243 application was installed at /foo/MyApp.pm)
 244
 245 =head2 -Log
 246
 247     use Catalyst '-Log=warn,fatal,error';
 248
 249 Specifies a comma-delimited list of log levels.
 250
 251 =head2 -Stats
 252
 253 Enables statistics collection and reporting.
 254
 255    use Catalyst qw/-Stats=1/;
 256
 257 You can also force this setting from the system environment with CATALYST_STATS
 258 or <MYAPP>_STATS. The environment settings override the application, with
 259 <MYAPP>_STATS having the highest priority.
 260
 261 Stats are also enabled if L<< debugging |/"-Debug" >> is enabled.
 262
 263 =head1 METHODS
 264
 265 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 266
 267 =head2 $c->action
 268
 269 Returns a L<Catalyst::Action> object for the current action, which
 270 stringifies to the action name. See L<Catalyst::Action>.
 271
 272 =head2 $c->namespace
 273
 274 Returns the namespace of the current action, i.e., the URI prefix
 275 corresponding to the controller of the current action. For example:
 276
 277     # in Controller::Foo::Bar
 278     $c->namespace; # returns 'foo/bar';
 279
 280 =head2 $c->request
 281
 282 =head2 $c->req
 283
 284 Returns the current L<Catalyst::Request> object, giving access to
 285 information about the current client request (including parameters,
 286 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 287
 288 =head2 REQUEST FLOW HANDLING
 289
 290 =head2 $c->forward( $action [, \@arguments ] )
 291
 292 =head2 $c->forward( $class, $method, [, \@arguments ] )
 293
 294 Forwards processing to another action, by its private name. If you give a
 295 class name but no method, C<process()> is called. You may also optionally
 296 pass arguments in an arrayref. The action will receive the arguments in
 297 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 298 C<< $c->req->args >> will be restored to the previous values.
 299
 300 Any data C<return>ed from the action forwarded to, will be returned by the
 301 call to forward.
 302
 303     my $foodata = $c->forward('/foo');
 304     $c->forward('index');
 305     $c->forward(qw/Model::DBIC::Foo do_stuff/);
 306     $c->forward('View::TT');
 307
 308 Note that L<< forward|/"$c->forward( $action [, \@arguments ] )" >> implies
 309 an C<< eval { } >> around the call (actually
 310 L<< execute|/"$c->execute( $class, $coderef )" >> does), thus de-fatalizing
 311 all 'dies' within the called action. If you want C<die> to propagate you
 312 need to do something like:
 313
 314     $c->forward('foo');
 315     die join "\n", @{ $c->error } if @{ $c->error };
 316
 317 Or make sure to always return true values from your actions and write
 318 your code like this:
 319
 320     $c->forward('foo') || return;
 321
 322 Another note is that C<< $c->forward >> always returns a scalar because it
 323 actually returns $c->state which operates in a scalar context.
 324 Thus, something like:
 325
 326     return @array;
 327
 328 in an action that is forwarded to is going to return a scalar,
 329 i.e. how many items are in that array, which is probably not what you want.
 330 If you need to return an array then return a reference to it,
 331 or stash it like so:
 332
 333     $c->stash->{array} = \@array;
 334
 335 and access it from the stash.
 336
 337 Keep in mind that the C<end> method used is that of the caller action. So a C<$c-E<gt>detach> inside a forwarded action would run the C<end> method from the original action requested.
 338
 339 =cut
 340
 341 sub forward { my $c = shift; no warnings 'recursion'; $c->dispatcher->forward( $c, @_ ) }
 342
 343 =head2 $c->detach( $action [, \@arguments ] )
 344
 345 =head2 $c->detach( $class, $method, [, \@arguments ] )
 346
 347 =head2 $c->detach()
 348
 349 The same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, but
 350 doesn't return to the previous action when processing is finished.
 351
 352 When called with no arguments it escapes the processing chain entirely.
 353
 354 =cut
 355
 356 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 357
 358 =head2 $c->visit( $action [, \@captures, \@arguments ] )
 359
 360 =head2 $c->visit( $class, $method, [, \@captures, \@arguments ] )
 361
 362 Almost the same as L<< forward|/"$c->forward( $action [, \@arguments ] )" >>,
 363 but does a full dispatch, instead of just calling the new C<$action> /
 364 C<< $class->$method >>. This means that C<begin>, C<auto> and the method
 365 you go to are called, just like a new request.
 366
 367 In addition both C<< $c->action >> and C<< $c->namespace >> are localized.
 368 This means, for example, that C<< $c->action >> methods such as
 369 L<name|Catalyst::Action/name>, L<class|Catalyst::Action/class> and
 370 L<reverse|Catalyst::Action/reverse> return information for the visited action
 371 when they are invoked within the visited action.  This is different from the
 372 behavior of L<< forward|/"$c->forward( $action [, \@arguments ] )" >>, which
 373 continues to use the $c->action object from the caller action even when
 374 invoked from the callee.
 375
 376 C<< $c->stash >> is kept unchanged.
 377
 378 In effect, L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >>
 379 allows you to "wrap" another action, just as it would have been called by
 380 dispatching from a URL, while the analogous
 381 L<< go|/"$c->go( $action [, \@captures, \@arguments ] )" >> allows you to
 382 transfer control to another action as if it had been reached directly from a URL.
 383
 384 =cut
 385
 386 sub visit { my $c = shift; $c->dispatcher->visit( $c, @_ ) }
 387
 388 =head2 $c->go( $action [, \@captures, \@arguments ] )
 389
 390 =head2 $c->go( $class, $method, [, \@captures, \@arguments ] )
 391
 392 The relationship between C<go> and
 393 L<< visit|/"$c->visit( $action [, \@captures, \@arguments ] )" >> is the same as
 394 the relationship between
 395 L<< forward|/"$c->forward( $class, $method, [, \@arguments ] )" >> and
 396 L<< detach|/"$c->detach( $action [, \@arguments ] )" >>. Like C<< $c->visit >>,
 397 C<< $c->go >> will perform a full dispatch on the specified action or method,
 398 with localized C<< $c->action >> and C<< $c->namespace >>. Like C<detach>,
 399 C<go> escapes the processing of the current request chain on completion, and
 400 does not return to its caller.
 401
 402 @arguments are arguments to the final destination of $action. @captures are
 403 arguments to the intermediate steps, if any, on the way to the final sub of
 404 $action.
 405
 406 =cut
 407
 408 sub go { my $c = shift; $c->dispatcher->go( $c, @_ ) }
 409
 410 =head2 $c->response
 411
 412 =head2 $c->res
 413
 414 Returns the current L<Catalyst::Response> object, see there for details.
 415
 416 =head2 $c->stash
 417
 418 Returns a hashref to the stash, which may be used to store data and pass
 419 it between components during a request. You can also set hash keys by
 420 passing arguments. The stash is automatically sent to the view. The
 421 stash is cleared at the end of a request; it cannot be used for
 422 persistent storage (for this you must use a session; see
 423 L<Catalyst::Plugin::Session> for a complete system integrated with
 424 Catalyst).
 425
 426     $c->stash->{foo} = $bar;
 427     $c->stash( { moose => 'majestic', qux => 0 } );
 428     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 429
 430     # stash is automatically passed to the view for use in a template
 431     $c->forward( 'MyApp::View::TT' );
 432
 433 =cut
 434
 435 around stash => sub {
 436     my $orig = shift;
 437     my $c = shift;
 438     my $stash = $orig->($c);
 439     if (@_) {
 440         my $new_stash = @_ > 1 ? {@_} : $_[0];
 441         croak('stash takes a hash or hashref') unless ref $new_stash;
 442         foreach my $key ( keys %$new_stash ) {
 443           $stash->{$key} = $new_stash->{$key};
 444         }
 445     }
 446
 447     return $stash;
 448 };
 449
 450
 451 =head2 $c->error
 452
 453 =head2 $c->error($error, ...)
 454
 455 =head2 $c->error($arrayref)
 456
 457 Returns an arrayref containing error messages.  If Catalyst encounters an
 458 error while processing a request, it stores the error in $c->error.  This
 459 method should only be used to store fatal error messages.
 460
 461     my @error = @{ $c->error };
 462
 463 Add a new error.
 464
 465     $c->error('Something bad happened');
 466
 467 =cut
 468
 469 sub error {
 470     my $c = shift;
 471     if ( $_[0] ) {
 472         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 473         croak @$error unless ref $c;
 474         push @{ $c->{error} }, @$error;
 475     }
 476     elsif ( defined $_[0] ) { $c->{error} = undef }
 477     return $c->{error} || [];
 478 }
 479
 480
 481 =head2 $c->state
 482
 483 Contains the return value of the last executed action.
 484 Note that << $c->state >> operates in a scalar context which means that all
 485 values it returns are scalar.
 486
 487 =head2 $c->clear_errors
 488
 489 Clear errors.  You probably don't want to clear the errors unless you are
 490 implementing a custom error screen.
 491
 492 This is equivalent to running
 493
 494     $c->error(0);
 495
 496 =cut
 497
 498 sub clear_errors {
 499     my $c = shift;
 500     $c->error(0);
 501 }
 502
 503 sub _comp_search_prefixes {
 504     my $c = shift;
 505     return map $c->components->{ $_ }, $c->_comp_names_search_prefixes(@_);
 506 }
 507
 508 # search components given a name and some prefixes
 509 sub _comp_names_search_prefixes {
 510     my ( $c, $name, @prefixes ) = @_;
 511     my $appclass = ref $c || $c;
 512     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 513     $filter = qr/$filter/; # Compile regex now rather than once per loop
 514
 515     # map the original component name to the sub part that we will search against
 516     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 517         grep { /$filter/ } keys %{ $c->components };
 518
 519     # undef for a name will return all
 520     return keys %eligible if !defined $name;
 521
 522     my $query  = ref $name ? $name : qr/^$name$/i;
 523     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 524
 525     return @result if @result;
 526
 527     # if we were given a regexp to search against, we're done.
 528     return if ref $name;
 529
 530     # skip regexp fallback if configured
 531     return
 532         if $appclass->config->{disable_component_resolution_regex_fallback};
 533
 534     # regexp fallback
 535     $query  = qr/$name/i;
 536     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 537
 538     # no results? try against full names
 539     if( !@result ) {
 540         @result = grep { m{$query} } keys %eligible;
 541     }
 542
 543     # don't warn if we didn't find any results, it just might not exist
 544     if( @result ) {
 545         # Disgusting hack to work out correct method name
 546         my $warn_for = lc $prefixes[0];
 547         my $msg = "Used regexp fallback for \$c->${warn_for}('${name}'), which found '" .
 548            (join '", "', @result) . "'. Relying on regexp fallback behavior for " .
 549            "component resolution is unreliable and unsafe.";
 550         my $short = $result[0];
 551         # remove the component namespace prefix
 552         $short =~ s/.*?(Model|Controller|View):://;
 553         my $shortmess = Carp::shortmess('');
 554         if ($shortmess =~ m#Catalyst/Plugin#) {
 555            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 556               "plugin's config";
 557         } elsif ($shortmess =~ m#Catalyst/lib/(View|Controller)#) {
 558            $msg .= " You probably need to set '$short' instead of '${name}' in this " .
 559               "component's config";
 560         } else {
 561            $msg .= " You probably meant \$c->${warn_for}('$short') instead of \$c->${warn_for}('${name}'), " .
 562               "but if you really wanted to search, pass in a regexp as the argument " .
 563               "like so: \$c->${warn_for}(qr/${name}/)";
 564         }
 565         $c->log->warn( "${msg}$shortmess" );
 566     }
 567
 568     return @result;
 569 }
 570
 571 # Find possible names for a prefix
 572 sub _comp_names {
 573     my ( $c, @prefixes ) = @_;
 574     my $appclass = ref $c || $c;
 575
 576     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 577
 578     my @names = map { s{$filter}{}; $_; }
 579         $c->_comp_names_search_prefixes( undef, @prefixes );
 580
 581     return @names;
 582 }
 583
 584 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 585 sub _filter_component {
 586     my ( $c, $comp, @args ) = @_;
 587
 588     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 589         return $comp->ACCEPT_CONTEXT( $c, @args );
 590     }
 591
 592     return $comp;
 593 }
 594
 595 =head2 COMPONENT ACCESSORS
 596
 597 =head2 $c->controller($name)
 598
 599 Gets a L<Catalyst::Controller> instance by name.
 600
 601     $c->controller('Foo')->do_stuff;
 602
 603 If the name is omitted, will return the controller for the dispatched
 604 action.
 605
 606 If you want to search for controllers, pass in a regexp as the argument.
 607
 608     # find all controllers that start with Foo
 609     my @foo_controllers = $c->controller(qr{^Foo});
 610
 611
 612 =cut
 613
 614 sub controller {
 615     my ( $c, $name, @args ) = @_;
 616
 617     my $appclass = ref($c) || $c;
 618     if( $name ) {
 619         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 620             my $comps = $c->components;
 621             my $check = $appclass."::Controller::".$name;
 622             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 623         }
 624         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 625         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 626         return $c->_filter_component( $result[ 0 ], @args );
 627     }
 628
 629     return $c->component( $c->action->class );
 630 }
 631
 632 =head2 $c->model($name)
 633
 634 Gets a L<Catalyst::Model> instance by name.
 635
 636     $c->model('Foo')->do_stuff;
 637
 638 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 639
 640 If the name is omitted, it will look for
 641  - a model object in $c->stash->{current_model_instance}, then
 642  - a model name in $c->stash->{current_model}, then
 643  - a config setting 'default_model', or
 644  - check if there is only one model, and return it if that's the case.
 645
 646 If you want to search for models, pass in a regexp as the argument.
 647
 648     # find all models that start with Foo
 649     my @foo_models = $c->model(qr{^Foo});
 650
 651 =cut
 652
 653 sub model {
 654     my ( $c, $name, @args ) = @_;
 655     my $appclass = ref($c) || $c;
 656     if( $name ) {
 657         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 658             my $comps = $c->components;
 659             my $check = $appclass."::Model::".$name;
 660             return $c->_filter_component( $comps->{$check}, @args ) if exists $comps->{$check};
 661         }
 662         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 663         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 664         return $c->_filter_component( $result[ 0 ], @args );
 665     }
 666
 667     if (ref $c) {
 668         return $c->stash->{current_model_instance}
 669           if $c->stash->{current_model_instance};
 670         return $c->model( $c->stash->{current_model} )
 671           if $c->stash->{current_model};
 672     }
 673     return $c->model( $appclass->config->{default_model} )
 674       if $appclass->config->{default_model};
 675
 676     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 677
 678     if( $rest ) {
 679         $c->log->warn( Carp::shortmess('Calling $c->model() will return a random model unless you specify one of:') );
 680         $c->log->warn( '* $c->config(default_model => "the name of the default model to use")' );
 681         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 682         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 683         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 684     }
 685
 686     return $c->_filter_component( $comp );
 687 }
 688
 689
 690 =head2 $c->view($name)
 691
 692 Gets a L<Catalyst::View> instance by name.
 693
 694     $c->view('Foo')->do_stuff;
 695
 696 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 697
 698 If the name is omitted, it will look for
 699  - a view object in $c->stash->{current_view_instance}, then
 700  - a view name in $c->stash->{current_view}, then
 701  - a config setting 'default_view', or
 702  - check if there is only one view, and return it if that's the case.
 703
 704 If you want to search for views, pass in a regexp as the argument.
 705
 706     # find all views that start with Foo
 707     my @foo_views = $c->view(qr{^Foo});
 708
 709 =cut
 710
 711 sub view {
 712     my ( $c, $name, @args ) = @_;
 713
 714     my $appclass = ref($c) || $c;
 715     if( $name ) {
 716         unless ( ref($name) ) { # Direct component hash lookup to avoid costly regexps
 717             my $comps = $c->components;
 718             my $check = $appclass."::View::".$name;
 719             if( exists $comps->{$check} ) {
 720                 return $c->_filter_component( $comps->{$check}, @args );
 721             }
 722             else {
 723                 $c->log->warn( "Attempted to use view '$check', but does not exist" );
 724             }
 725         }
 726         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 727         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 728         return $c->_filter_component( $result[ 0 ], @args );
 729     }
 730
 731     if (ref $c) {
 732         return $c->stash->{current_view_instance}
 733           if $c->stash->{current_view_instance};
 734         return $c->view( $c->stash->{current_view} )
 735           if $c->stash->{current_view};
 736     }
 737     return $c->view( $appclass->config->{default_view} )
 738       if $appclass->config->{default_view};
 739
 740     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 741
 742     if( $rest ) {
 743         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 744         $c->log->warn( '* $c->config(default_view => "the name of the default view to use")' );
 745         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 746         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 747         $c->log->warn( 'NB: in version 5.81, the "random" behavior will not work at all.' );
 748     }
 749
 750     return $c->_filter_component( $comp );
 751 }
 752
 753 =head2 $c->controllers
 754
 755 Returns the available names which can be passed to $c->controller
 756
 757 =cut
 758
 759 sub controllers {
 760     my ( $c ) = @_;
 761     return $c->_comp_names(qw/Controller C/);
 762 }
 763
 764 =head2 $c->models
 765
 766 Returns the available names which can be passed to $c->model
 767
 768 =cut
 769
 770 sub models {
 771     my ( $c ) = @_;
 772     return $c->_comp_names(qw/Model M/);
 773 }
 774
 775
 776 =head2 $c->views
 777
 778 Returns the available names which can be passed to $c->view
 779
 780 =cut
 781
 782 sub views {
 783     my ( $c ) = @_;
 784     return $c->_comp_names(qw/View V/);
 785 }
 786
 787 =head2 $c->comp($name)
 788
 789 =head2 $c->component($name)
 790
 791 Gets a component object by name. This method is not recommended,
 792 unless you want to get a specific component by full
 793 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 794 should be used instead.
 795
 796 If C<$name> is a regexp, a list of components matched against the full
 797 component name will be returned.
 798
 799 If Catalyst can't find a component by name, it will fallback to regex
 800 matching by default. To disable this behaviour set
 801 disable_component_resolution_regex_fallback to a true value.
 802
 803     __PACKAGE__->config( disable_component_resolution_regex_fallback => 1 );
 804
 805 =cut
 806
 807 sub component {
 808     my ( $c, $name, @args ) = @_;
 809
 810     if( $name ) {
 811         my $comps = $c->components;
 812
 813         if( !ref $name ) {
 814             # is it the exact name?
 815             return $c->_filter_component( $comps->{ $name }, @args )
 816                        if exists $comps->{ $name };
 817
 818             # perhaps we just omitted "MyApp"?
 819             my $composed = ( ref $c || $c ) . "::${name}";
 820             return $c->_filter_component( $comps->{ $composed }, @args )
 821                        if exists $comps->{ $composed };
 822
 823             # search all of the models, views and controllers
 824             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 825             return $c->_filter_component( $comp, @args ) if $comp;
 826         }
 827
 828         return
 829             if $c->config->{disable_component_resolution_regex_fallback};
 830
 831         # This is here so $c->comp( '::M::' ) works
 832         my $query = ref $name ? $name : qr{$name}i;
 833
 834         my @result = grep { m{$query} } keys %{ $c->components };
 835         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 836
 837         if( $result[ 0 ] ) {
 838             $c->log->warn( Carp::shortmess(qq(Found results for "${name}" using regexp fallback)) );
 839             $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 840             $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 841             return $c->_filter_component( $result[ 0 ], @args );
 842         }
 843
 844         # I would expect to return an empty list here, but that breaks back-compat
 845     }
 846
 847     # fallback
 848     return sort keys %{ $c->components };
 849 }
 850
 851 =head2 CLASS DATA AND HELPER CLASSES
 852
 853 =head2 $c->config
 854
 855 Returns or takes a hashref containing the application's configuration.
 856
 857     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 858
 859 You can also use a C<YAML>, C<XML> or L<Config::General> config file
 860 like C<myapp.conf> in your applications home directory. See
 861 L<Catalyst::Plugin::ConfigLoader>.
 862
 863 =head3 Cascading configuration
 864
 865 The config method is present on all Catalyst components, and configuration
 866 will be merged when an application is started. Configuration loaded with
 867 L<Catalyst::Plugin::ConfigLoader> takes precedence over other configuration,
 868 followed by configuration in your top level C<MyApp> class. These two
 869 configurations are merged, and then configuration data whose hash key matches a
 870 component name is merged with configuration for that component.
 871
 872 The configuration for a component is then passed to the C<new> method when a
 873 component is constructed.
 874
 875 For example:
 876
 877     MyApp->config({ 'Model::Foo' => { bar => 'baz', overrides => 'me' } });
 878     MyApp::Model::Foo->config({ quux => 'frob', overrides => 'this' });
 879
 880 will mean that C<MyApp::Model::Foo> receives the following data when
 881 constructed:
 882
 883     MyApp::Model::Foo->new({
 884         bar => 'baz',
 885         quux => 'frob',
 886         overrides => 'me',
 887     });
 888
 889 It's common practice to use a Moose attribute
 890 on the receiving component to access the config value.
 891
 892     package MyApp::Model::Foo;
 893
 894     use Moose;
 895
 896     # this attr will receive 'baz' at construction time
 897     has 'bar' => (
 898         is  => 'rw',
 899         isa => 'Str',
 900     );
 901
 902 You can then get the value 'baz' by calling $c->model('Foo')->bar
 903 (or $self->bar inside code in the model).
 904
 905 B<NOTE:> you MUST NOT call C<< $self->config >> or C<< __PACKAGE__->config >>
 906 as a way of reading config within your code, as this B<will not> give you the
 907 correctly merged config back. You B<MUST> take the config values supplied to
 908 the constructor and use those instead.
 909
 910 =cut
 911
 912 around config => sub {
 913     my $orig = shift;
 914     my $c = shift;
 915
 916     croak('Setting config after setup has been run is not allowed.')
 917         if ( @_ and $c->setup_finished );
 918
 919     $c->$orig(@_);
 920 };
 921
 922 =head2 $c->log
 923
 924 Returns the logging object instance. Unless it is already set, Catalyst
 925 sets this up with a L<Catalyst::Log> object. To use your own log class,
 926 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 927 C<< __PACKAGE__->setup >>.
 928
 929  __PACKAGE__->log( MyLogger->new );
 930  __PACKAGE__->setup;
 931
 932 And later:
 933
 934     $c->log->info( 'Now logging with my own logger!' );
 935
 936 Your log class should implement the methods described in
 937 L<Catalyst::Log>.
 938
 939
 940 =head2 $c->debug
 941
 942 Returns 1 if debug mode is enabled, 0 otherwise.
 943
 944 You can enable debug mode in several ways:
 945
 946 =over
 947
 948 =item By calling myapp_server.pl with the -d flag
 949
 950 =item With the environment variables MYAPP_DEBUG, or CATALYST_DEBUG
 951
 952 =item The -Debug option in your MyApp.pm
 953
 954 =item By declaring C<sub debug { 1 }> in your MyApp.pm.
 955
 956 =back
 957
 958 The first three also set the log level to 'debug'.
 959
 960 Calling C<< $c->debug(1) >> has no effect.
 961
 962 =cut
 963
 964 sub debug { 0 }
 965
 966 =head2 $c->dispatcher
 967
 968 Returns the dispatcher instance. See L<Catalyst::Dispatcher>.
 969
 970 =head2 $c->engine
 971
 972 Returns the engine instance. See L<Catalyst::Engine>.
 973
 974
 975 =head2 UTILITY METHODS
 976
 977 =head2 $c->path_to(@path)
 978
 979 Merges C<@path> with C<< $c->config->{home} >> and returns a
 980 L<Path::Class::Dir> object. Note you can usually use this object as
 981 a filename, but sometimes you will have to explicitly stringify it
 982 yourself by calling the C<< ->stringify >> method.
 983
 984 For example:
 985
 986     $c->path_to( 'db', 'sqlite.db' );
 987
 988 =cut
 989
 990 sub path_to {
 991     my ( $c, @path ) = @_;
 992     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 993     if ( -d $path ) { return $path }
 994     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 995 }
 996
 997 sub plugin {
 998     my ( $class, $name, $plugin, @args ) = @_;
 999
1000     # See block comment in t/unit_core_plugin.t
1001     $class->log->warn(qq/Adding plugin using the ->plugin method is deprecated, and will be removed in a future release/);
1002
1003     $class->_register_plugin( $plugin, 1 );
1004
1005     eval { $plugin->import };
1006     $class->mk_classdata($name);
1007     my $obj;
1008     eval { $obj = $plugin->new(@args) };
1009
1010     if ($@) {
1011         Catalyst::Exception->throw( message =>
1012               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
1013     }
1014
1015     $class->$name($obj);
1016     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
1017       if $class->debug;
1018 }
1019
1020 =head2 MyApp->setup
1021
1022 Initializes the dispatcher and engine, loads any plugins, and loads the
1023 model, view, and controller components. You may also specify an array
1024 of plugins to load here, if you choose to not load them in the C<use
1025 Catalyst> line.
1026
1027     MyApp->setup;
1028     MyApp->setup( qw/-Debug/ );
1029
1030 =cut
1031
1032 sub setup {
1033     my ( $class, @arguments ) = @_;
1034     croak('Running setup more than once')
1035         if ( $class->setup_finished );
1036
1037     unless ( $class->isa('Catalyst') ) {
1038
1039         Catalyst::Exception->throw(
1040             message => qq/'$class' does not inherit from Catalyst/ );
1041     }
1042
1043     if ( $class->arguments ) {
1044         @arguments = ( @arguments, @{ $class->arguments } );
1045     }
1046
1047     # Process options
1048     my $flags = {};
1049
1050     foreach (@arguments) {
1051
1052         if (/^-Debug$/) {
1053             $flags->{log} =
1054               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
1055         }
1056         elsif (/^-(\w+)=?(.*)$/) {
1057             $flags->{ lc $1 } = $2;
1058         }
1059         else {
1060             push @{ $flags->{plugins} }, $_;
1061         }
1062     }
1063
1064     $class->setup_home( delete $flags->{home} );
1065
1066     $class->setup_log( delete $flags->{log} );
1067     $class->setup_plugins( delete $flags->{plugins} );
1068     $class->setup_dispatcher( delete $flags->{dispatcher} );
1069     if (my $engine = delete $flags->{engine}) {
1070         $class->log->warn("Specifying the engine in ->setup is no longer supported, see Catalyst::Upgrading");
1071     }
1072     $class->setup_engine();
1073     $class->setup_stats( delete $flags->{stats} );
1074
1075     for my $flag ( sort keys %{$flags} ) {
1076
1077         if ( my $code = $class->can( 'setup_' . $flag ) ) {
1078             &$code( $class, delete $flags->{$flag} );
1079         }
1080         else {
1081             $class->log->warn(qq/Unknown flag "$flag"/);
1082         }
1083     }
1084
1085     eval { require Catalyst::Devel; };
1086     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
1087         $class->log->warn(<<"EOF");
1088 You are running an old script!
1089
1090   Please update by running (this will overwrite existing files):
1091     catalyst.pl -force -scripts $class
1092
1093   or (this will not overwrite existing files):
1094     catalyst.pl -scripts $class
1095
1096 EOF
1097     }
1098
1099     if ( $class->debug ) {
1100         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
1101
1102         if (@plugins) {
1103             my $column_width = Catalyst::Utils::term_width() - 6;
1104             my $t = Text::SimpleTable->new($column_width);
1105             $t->row($_) for @plugins;
1106             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
1107         }
1108
1109         my $dispatcher = $class->dispatcher;
1110         my $engine     = $class->engine;
1111         my $home       = $class->config->{home};
1112
1113         $class->log->debug(sprintf(q/Loaded dispatcher "%s"/, blessed($dispatcher)));
1114         $class->log->debug(sprintf(q/Loaded engine "%s"/, blessed($engine)));
1115
1116         $home
1117           ? ( -d $home )
1118           ? $class->log->debug(qq/Found home "$home"/)
1119           : $class->log->debug(qq/Home "$home" doesn't exist/)
1120           : $class->log->debug(q/Couldn't find home/);
1121     }
1122
1123     # Call plugins setup, this is stupid and evil.
1124     # Also screws C3 badly on 5.10, hack to avoid.
1125     {
1126         no warnings qw/redefine/;
1127         local *setup = sub { };
1128         $class->setup unless $Catalyst::__AM_RESTARTING;
1129     }
1130
1131     # Initialize our data structure
1132     $class->components( {} );
1133
1134     $class->setup_components;
1135
1136     if ( $class->debug ) {
1137         my $column_width = Catalyst::Utils::term_width() - 8 - 9;
1138         my $t = Text::SimpleTable->new( [ $column_width, 'Class' ], [ 8, 'Type' ] );
1139         for my $comp ( sort keys %{ $class->components } ) {
1140             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
1141             $t->row( $comp, $type );
1142         }
1143         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
1144           if ( keys %{ $class->components } );
1145     }
1146
1147     # Add our self to components, since we are also a component
1148     if( $class->isa('Catalyst::Controller') ){
1149       $class->components->{$class} = $class;
1150     }
1151
1152     $class->setup_actions;
1153
1154     if ( $class->debug ) {
1155         my $name = $class->config->{name} || 'Application';
1156         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
1157     }
1158
1159     # Make sure that the application class becomes immutable at this point,
1160     B::Hooks::EndOfScope::on_scope_end {
1161         return if $@;
1162         my $meta = Class::MOP::get_metaclass_by_name($class);
1163         if (
1164             $meta->is_immutable
1165             && ! { $meta->immutable_options }->{replace_constructor}
1166             && (
1167                    $class->isa('Class::Accessor::Fast')
1168                 || $class->isa('Class::Accessor')
1169             )
1170         ) {
1171             warn "You made your application class ($class) immutable, "
1172                 . "but did not inline the\nconstructor. "
1173                 . "This will break catalyst, as your app \@ISA "
1174                 . "Class::Accessor(::Fast)?\nPlease pass "
1175                 . "(replace_constructor => 1)\nwhen making your class immutable.\n";
1176         }
1177         $meta->make_immutable(
1178             replace_constructor => 1,
1179         ) unless $meta->is_immutable;
1180     };
1181
1182     if ($class->config->{case_sensitive}) {
1183         $class->log->warn($class . "->config->{case_sensitive} is set.");
1184         $class->log->warn("This setting is deprecated and planned to be removed in Catalyst 5.81.");
1185     }
1186
1187     $class->setup_finalize;
1188     # Should be the last thing we do so that user things hooking
1189     # setup_finalize can log..
1190     $class->log->_flush() if $class->log->can('_flush');
1191     return 1; # Explicit return true as people have __PACKAGE__->setup as the last thing in their class. HATE.
1192 }
1193
1194 =head2 $app->setup_finalize
1195
1196 A hook to attach modifiers to. This method does not do anything except set the
1197 C<setup_finished> accessor.
1198
1199 Applying method modifiers to the C<setup> method doesn't work, because of quirky things done for plugin setup.
1200
1201 Example:
1202
1203     after setup_finalize => sub {
1204         my $app = shift;
1205
1206         ## do stuff here..
1207     };
1208
1209 =cut
1210
1211 sub setup_finalize {
1212     my ($class) = @_;
1213     $class->setup_finished(1);
1214 }
1215
1216 =head2 $c->uri_for( $path?, @args?, \%query_values? )
1217
1218 =head2 $c->uri_for( $action, \@captures?, @args?, \%query_values? )
1219
1220 Constructs an absolute L<URI> object based on the application root, the
1221 provided path, and the additional arguments and query parameters provided.
1222 When used as a string, provides a textual URI.  If you need more flexibility
1223 than this (i.e. the option to provide relative URIs etc.) see
1224 L<Catalyst::Plugin::SmartURI>.
1225
1226 If no arguments are provided, the URI for the current action is returned.
1227 To return the current action and also provide @args, use
1228 C<< $c->uri_for( $c->action, @args ) >>.
1229
1230 If the first argument is a string, it is taken as a public URI path relative
1231 to C<< $c->namespace >> (if it doesn't begin with a forward slash) or
1232 relative to the application root (if it does). It is then merged with
1233 C<< $c->request->base >>; any C<@args> are appended as additional path
1234 components; and any C<%query_values> are appended as C<?foo=bar> parameters.
1235
1236 If the first argument is a L<Catalyst::Action> it represents an action which
1237 will have its path resolved using C<< $c->dispatcher->uri_for_action >>. The
1238 optional C<\@captures> argument (an arrayref) allows passing the captured
1239 variables that are needed to fill in the paths of Chained and Regex actions;
1240 once the path is resolved, C<uri_for> continues as though a path was
1241 provided, appending any arguments or parameters and creating an absolute
1242 URI.
1243
1244 The captures for the current request can be found in
1245 C<< $c->request->captures >>, and actions can be resolved using
1246 C<< Catalyst::Controller->action_for($name) >>. If you have a private action
1247 path, use C<< $c->uri_for_action >> instead.
1248
1249   # Equivalent to $c->req->uri
1250   $c->uri_for($c->action, $c->req->captures,
1251       @{ $c->req->args }, $c->req->params);
1252
1253   # For the Foo action in the Bar controller
1254   $c->uri_for($c->controller('Bar')->action_for('Foo'));
1255
1256   # Path to a static resource
1257   $c->uri_for('/static/images/logo.png');
1258
1259 =cut
1260
1261 sub uri_for {
1262     my ( $c, $path, @args ) = @_;
1263
1264     if (blessed($path) && $path->isa('Catalyst::Controller')) {
1265         $path = $path->path_prefix;
1266         $path =~ s{/+\z}{};
1267         $path .= '/';
1268     }
1269
1270     undef($path) if (defined $path && $path eq '');
1271
1272     my $params =
1273       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
1274
1275     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
1276     foreach my $arg (@args) {
1277         utf8::encode($arg) if utf8::is_utf8($arg);
1278         $arg =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1279     }
1280
1281     if ( blessed($path) ) { # action object
1282         s|/|%2F|g for @args;
1283         my $captures = [ map { s|/|%2F|g; $_; }
1284                         ( scalar @args && ref $args[0] eq 'ARRAY'
1285                          ? @{ shift(@args) }
1286                          : ()) ];
1287
1288         foreach my $capture (@$captures) {
1289             utf8::encode($capture) if utf8::is_utf8($capture);
1290             $capture =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
1291         }
1292
1293         my $action = $path;
1294         $path = $c->dispatcher->uri_for_action($action, $captures);
1295         if (not defined $path) {
1296             $c->log->debug(qq/Can't find uri_for action '$action' @$captures/)
1297                 if $c->debug;
1298             return undef;
1299         }
1300         $path = '/' if $path eq '';
1301     }
1302
1303     unshift(@args, $path);
1304
1305     unless (defined $path && $path =~ s!^/!!) { # in-place strip
1306         my $namespace = $c->namespace;
1307         if (defined $path) { # cheesy hack to handle path '../foo'
1308            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
1309         }
1310         unshift(@args, $namespace || '');
1311     }
1312
1313     # join args with '/', or a blank string
1314     my $args = join('/', grep { defined($_) } @args);
1315     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
1316     $args =~ s!^/+!!;
1317     my $base = $c->req->base;
1318     my $class = ref($base);
1319     $base =~ s{(?<!/)$}{/};
1320
1321     my $query = '';
1322
1323     if (my @keys = keys %$params) {
1324       # somewhat lifted from URI::_query's query_form
1325       $query = '?'.join('&', map {
1326           my $val = $params->{$_};
1327           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
1328           s/ /+/g;
1329           my $key = $_;
1330           $val = '' unless defined $val;
1331           (map {
1332               my $param = "$_";
1333               utf8::encode( $param ) if utf8::is_utf8($param);
1334               # using the URI::Escape pattern here so utf8 chars survive
1335               $param =~ s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
1336               $param =~ s/ /+/g;
1337               "${key}=$param"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
1338       } @keys);
1339     }
1340
1341     my $res = bless(\"${base}${args}${query}", $class);
1342     $res;
1343 }
1344
1345 =head2 $c->uri_for_action( $path, \@captures?, @args?, \%query_values? )
1346
1347 =head2 $c->uri_for_action( $action, \@captures?, @args?, \%query_values? )
1348
1349 =over
1350
1351 =item $path
1352
1353 A private path to the Catalyst action you want to create a URI for.
1354
1355 This is a shortcut for calling C<< $c->dispatcher->get_action_by_path($path)
1356 >> and passing the resulting C<$action> and the remaining arguments to C<<
1357 $c->uri_for >>.
1358
1359 You can also pass in a Catalyst::Action object, in which case it is passed to
1360 C<< $c->uri_for >>.
1361
1362 Note that although the path looks like a URI that dispatches to the wanted action, it is not a URI, but an internal path to that action.
1363
1364 For example, if the action looks like:
1365
1366  package MyApp::Controller::Users;
1367
1368  sub lst : Path('the-list') {}
1369
1370 You can use:
1371
1372  $c->uri_for_action('/users/lst')
1373
1374 and it will create the URI /users/the-list.
1375
1376 =back
1377
1378 =cut
1379
1380 sub uri_for_action {
1381     my ( $c, $path, @args ) = @_;
1382     my $action = blessed($path)
1383       ? $path
1384       : $c->dispatcher->get_action_by_path($path);
1385     unless (defined $action) {
1386       croak "Can't find action for path '$path'";
1387     }
1388     return $c->uri_for( $action, @args );
1389 }
1390
1391 =head2 $c->welcome_message
1392
1393 Returns the Catalyst welcome HTML page.
1394
1395 =cut
1396
1397 sub welcome_message {
1398     my $c      = shift;
1399     my $name   = $c->config->{name};
1400     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1401     my $prefix = Catalyst::Utils::appprefix( ref $c );
1402     $c->response->content_type('text/html; charset=utf-8');
1403     return <<"EOF";
1404 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1405     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1406 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1407     <head>
1408     <meta http-equiv="Content-Language" content="en" />
1409     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1410         <title>$name on Catalyst $VERSION</title>
1411         <style type="text/css">
1412             body {
1413                 color: #000;
1414                 background-color: #eee;
1415             }
1416             div#content {
1417                 width: 640px;
1418                 margin-left: auto;
1419                 margin-right: auto;
1420                 margin-top: 10px;
1421                 margin-bottom: 10px;
1422                 text-align: left;
1423                 background-color: #ccc;
1424                 border: 1px solid #aaa;
1425             }
1426             p, h1, h2 {
1427                 margin-left: 20px;
1428                 margin-right: 20px;
1429                 font-family: verdana, tahoma, sans-serif;
1430             }
1431             a {
1432                 font-family: verdana, tahoma, sans-serif;
1433             }
1434             :link, :visited {
1435                     text-decoration: none;
1436                     color: #b00;
1437                     border-bottom: 1px dotted #bbb;
1438             }
1439             :link:hover, :visited:hover {
1440                     color: #555;
1441             }
1442             div#topbar {
1443                 margin: 0px;
1444             }
1445             pre {
1446                 margin: 10px;
1447                 padding: 8px;
1448             }
1449             div#answers {
1450                 padding: 8px;
1451                 margin: 10px;
1452                 background-color: #fff;
1453                 border: 1px solid #aaa;
1454             }
1455             h1 {
1456                 font-size: 0.9em;
1457                 font-weight: normal;
1458                 text-align: center;
1459             }
1460             h2 {
1461                 font-size: 1.0em;
1462             }
1463             p {
1464                 font-size: 0.9em;
1465             }
1466             p img {
1467                 float: right;
1468                 margin-left: 10px;
1469             }
1470             span#appname {
1471                 font-weight: bold;
1472                 font-size: 1.6em;
1473             }
1474         </style>
1475     </head>
1476     <body>
1477         <div id="content">
1478             <div id="topbar">
1479                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1480                     $VERSION</h1>
1481              </div>
1482              <div id="answers">
1483                  <p>
1484                  <img src="$logo" alt="Catalyst Logo" />
1485                  </p>
1486                  <p>Welcome to the  world of Catalyst.
1487                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1488                     framework will make web development something you had
1489                     never expected it to be: Fun, rewarding, and quick.</p>
1490                  <h2>What to do now?</h2>
1491                  <p>That really depends  on what <b>you</b> want to do.
1492                     We do, however, provide you with a few starting points.</p>
1493                  <p>If you want to jump right into web development with Catalyst
1494                     you might want to start with a tutorial.</p>
1495 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1496 </pre>
1497 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1498 <pre>
1499 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1500 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1501 </code></pre>
1502                  <h2>What to do next?</h2>
1503                  <p>Next it's time to write an actual application. Use the
1504                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1505                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1506                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1507                     they can save you a lot of work.</p>
1508                     <pre><code>script/${prefix}_create.pl --help</code></pre>
1509                     <p>Also, be sure to check out the vast and growing
1510                     collection of <a href="http://search.cpan.org/search?query=Catalyst">plugins for Catalyst on CPAN</a>;
1511                     you are likely to find what you need there.
1512                     </p>
1513
1514                  <h2>Need help?</h2>
1515                  <p>Catalyst has a very active community. Here are the main places to
1516                     get in touch with us.</p>
1517                  <ul>
1518                      <li>
1519                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1520                      </li>
1521                      <li>
1522                          <a href="http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst">Mailing-List</a>
1523                      </li>
1524                      <li>
1525                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1526                      </li>
1527                  </ul>
1528                  <h2>In conclusion</h2>
1529                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1530                     as we enjoyed making it. Please contact us if you have ideas
1531                     for improvement or other feedback.</p>
1532              </div>
1533          </div>
1534     </body>
1535 </html>
1536 EOF
1537 }
1538
1539 =head1 INTERNAL METHODS
1540
1541 These methods are not meant to be used by end users.
1542
1543 =head2 $c->components
1544
1545 Returns a hash of components.
1546
1547 =head2 $c->context_class
1548
1549 Returns or sets the context class.
1550
1551 =head2 $c->counter
1552
1553 Returns a hashref containing coderefs and execution counts (needed for
1554 deep recursion detection).
1555
1556 =head2 $c->depth
1557
1558 Returns the number of actions on the current internal execution stack.
1559
1560 =head2 $c->dispatch
1561
1562 Dispatches a request to actions.
1563
1564 =cut
1565
1566 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1567
1568 =head2 $c->dispatcher_class
1569
1570 Returns or sets the dispatcher class.
1571
1572 =head2 $c->dump_these
1573
1574 Returns a list of 2-element array references (name, structure) pairs
1575 that will be dumped on the error page in debug mode.
1576
1577 =cut
1578
1579 sub dump_these {
1580     my $c = shift;
1581     [ Request => $c->req ],
1582     [ Response => $c->res ],
1583     [ Stash => $c->stash ],
1584     [ Config => $c->config ];
1585 }
1586
1587 =head2 $c->engine_class
1588
1589 Returns or sets the engine class.
1590
1591 =head2 $c->execute( $class, $coderef )
1592
1593 Execute a coderef in given class and catch exceptions. Errors are available
1594 via $c->error.
1595
1596 =cut
1597
1598 sub execute {
1599     my ( $c, $class, $code ) = @_;
1600     $class = $c->component($class) || $class;
1601     $c->state(0);
1602
1603     if ( $c->depth >= $RECURSION ) {
1604         my $action = $code->reverse();
1605         $action = "/$action" unless $action =~ /->/;
1606         my $error = qq/Deep recursion detected calling "${action}"/;
1607         $c->log->error($error);
1608         $c->error($error);
1609         $c->state(0);
1610         return $c->state;
1611     }
1612
1613     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1614
1615     push( @{ $c->stack }, $code );
1616
1617     no warnings 'recursion';
1618     # N.B. This used to be combined, but I have seen $c get clobbered if so, and
1619     #      I have no idea how, ergo $ret (which appears to fix the issue)
1620     eval { my $ret = $code->execute( $class, $c, @{ $c->req->args } ) || 0; $c->state( $ret ) };
1621
1622     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1623
1624     my $last = pop( @{ $c->stack } );
1625
1626     if ( my $error = $@ ) {
1627         if ( blessed($error) and $error->isa('Catalyst::Exception::Detach') ) {
1628             $error->rethrow if $c->depth > 1;
1629         }
1630         elsif ( blessed($error) and $error->isa('Catalyst::Exception::Go') ) {
1631             $error->rethrow if $c->depth > 0;
1632         }
1633         else {
1634             unless ( ref $error ) {
1635                 no warnings 'uninitialized';
1636                 chomp $error;
1637                 my $class = $last->class;
1638                 my $name  = $last->name;
1639                 $error = qq/Caught exception in $class->$name "$error"/;
1640             }
1641             $c->error($error);
1642         }
1643         $c->state(0);
1644     }
1645     return $c->state;
1646 }
1647
1648 sub _stats_start_execute {
1649     my ( $c, $code ) = @_;
1650     my $appclass = ref($c) || $c;
1651     return if ( ( $code->name =~ /^_.*/ )
1652         && ( !$appclass->config->{show_internal_actions} ) );
1653
1654     my $action_name = $code->reverse();
1655     $c->counter->{$action_name}++;
1656
1657     my $action = $action_name;
1658     $action = "/$action" unless $action =~ /->/;
1659
1660     # determine if the call was the result of a forward
1661     # this is done by walking up the call stack and looking for a calling
1662     # sub of Catalyst::forward before the eval
1663     my $callsub = q{};
1664     for my $index ( 2 .. 11 ) {
1665         last
1666         if ( ( caller($index) )[0] eq 'Catalyst'
1667             && ( caller($index) )[3] eq '(eval)' );
1668
1669         if ( ( caller($index) )[3] =~ /forward$/ ) {
1670             $callsub = ( caller($index) )[3];
1671             $action  = "-> $action";
1672             last;
1673         }
1674     }
1675
1676     my $uid = $action_name . $c->counter->{$action_name};
1677
1678     # is this a root-level call or a forwarded call?
1679     if ( $callsub =~ /forward$/ ) {
1680         my $parent = $c->stack->[-1];
1681
1682         # forward, locate the caller
1683         if ( defined $parent && exists $c->counter->{"$parent"} ) {
1684             $c->stats->profile(
1685                 begin  => $action,
1686                 parent => "$parent" . $c->counter->{"$parent"},
1687                 uid    => $uid,
1688             );
1689         }
1690         else {
1691
1692             # forward with no caller may come from a plugin
1693             $c->stats->profile(
1694                 begin => $action,
1695                 uid   => $uid,
1696             );
1697         }
1698     }
1699     else {
1700
1701         # root-level call
1702         $c->stats->profile(
1703             begin => $action,
1704             uid   => $uid,
1705         );
1706     }
1707     return $action;
1708
1709 }
1710
1711 sub _stats_finish_execute {
1712     my ( $c, $info ) = @_;
1713     $c->stats->profile( end => $info );
1714 }
1715
1716 =head2 $c->finalize
1717
1718 Finalizes the request.
1719
1720 =cut
1721
1722 sub finalize {
1723     my $c = shift;
1724
1725     for my $error ( @{ $c->error } ) {
1726         $c->log->error($error);
1727     }
1728
1729     # Allow engine to handle finalize flow (for POE)
1730     my $engine = $c->engine;
1731     if ( my $code = $engine->can('finalize') ) {
1732         $engine->$code($c);
1733     }
1734     else {
1735
1736         $c->finalize_uploads;
1737
1738         # Error
1739         if ( $#{ $c->error } >= 0 ) {
1740             $c->finalize_error;
1741         }
1742
1743         $c->finalize_headers;
1744
1745         # HEAD request
1746         if ( $c->request->method eq 'HEAD' ) {
1747             $c->response->body('');
1748         }
1749
1750         $c->finalize_body;
1751     }
1752
1753     $c->log_response;
1754
1755     if ($c->use_stats) {
1756         my $elapsed = sprintf '%f', $c->stats->elapsed;
1757         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1758         $c->log->info(
1759             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1760     }
1761
1762     return $c->response->status;
1763 }
1764
1765 =head2 $c->finalize_body
1766
1767 Finalizes body.
1768
1769 =cut
1770
1771 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1772
1773 =head2 $c->finalize_cookies
1774
1775 Finalizes cookies.
1776
1777 =cut
1778
1779 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1780
1781 =head2 $c->finalize_error
1782
1783 Finalizes error.
1784
1785 =cut
1786
1787 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1788
1789 =head2 $c->finalize_headers
1790
1791 Finalizes headers.
1792
1793 =cut
1794
1795 sub finalize_headers {
1796     my $c = shift;
1797
1798     my $response = $c->response; #accessor calls can add up?
1799
1800     # Check if we already finalized headers
1801     return if $response->finalized_headers;
1802
1803     # Handle redirects
1804     if ( my $location = $response->redirect ) {
1805         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1806         $response->header( Location => $location );
1807
1808         if ( !$response->has_body ) {
1809             # Add a default body if none is already present
1810             $response->body(<<"EOF");
1811 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1812 <html xmlns="http://www.w3.org/1999/xhtml">
1813   <head>
1814     <title>Moved</title>
1815   </head>
1816   <body>
1817      <p>This item has moved <a href="$location">here</a>.</p>
1818   </body>
1819 </html>
1820 EOF
1821             $response->content_type('text/html; charset=utf-8');
1822         }
1823     }
1824
1825     # Content-Length
1826     if ( defined $response->body && length $response->body && !$response->content_length ) {
1827
1828         # get the length from a filehandle
1829         if ( blessed( $response->body ) && $response->body->can('read') || ref( $response->body ) eq 'GLOB' )
1830         {
1831             my $size = -s $response->body;
1832             if ( $size ) {
1833                 $response->content_length( $size );
1834             }
1835             else {
1836                 $c->log->warn('Serving filehandle without a content-length');
1837             }
1838         }
1839         else {
1840             # everything should be bytes at this point, but just in case
1841             $response->content_length( length( $response->body ) );
1842         }
1843     }
1844
1845     # Errors
1846     if ( $response->status =~ /^(1\d\d|[23]04)$/ ) {
1847         $response->headers->remove_header("Content-Length");
1848         $response->body('');
1849     }
1850
1851     $c->finalize_cookies;
1852
1853     $c->engine->finalize_headers( $c, @_ );
1854
1855     # Done
1856     $response->finalized_headers(1);
1857 }
1858
1859 =head2 $c->finalize_output
1860
1861 An alias for finalize_body.
1862
1863 =head2 $c->finalize_read
1864
1865 Finalizes the input after reading is complete.
1866
1867 =cut
1868
1869 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1870
1871 =head2 $c->finalize_uploads
1872
1873 Finalizes uploads. Cleans up any temporary files.
1874
1875 =cut
1876
1877 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1878
1879 =head2 $c->get_action( $action, $namespace )
1880
1881 Gets an action in a given namespace.
1882
1883 =cut
1884
1885 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1886
1887 =head2 $c->get_actions( $action, $namespace )
1888
1889 Gets all actions of a given name in a namespace and all parent
1890 namespaces.
1891
1892 =cut
1893
1894 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1895
1896 =head2 $app->handle_request( @arguments )
1897
1898 Called to handle each HTTP request.
1899
1900 =cut
1901
1902 sub handle_request {
1903     my ( $class, @arguments ) = @_;
1904
1905     # Always expect worst case!
1906     my $status = -1;
1907     try {
1908         if ($class->debug) {
1909             my $secs = time - $START || 1;
1910             my $av = sprintf '%.3f', $COUNT / $secs;
1911             my $time = localtime time;
1912             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1913         }
1914
1915         my $c = $class->prepare(@arguments);
1916         $c->dispatch;
1917         $status = $c->finalize;
1918     }
1919     catch {
1920         chomp(my $error = $_);
1921         $class->log->error(qq/Caught exception in engine "$error"/);
1922     };
1923
1924     $COUNT++;
1925
1926     if(my $coderef = $class->log->can('_flush')){
1927         $class->log->$coderef();
1928     }
1929     return $status;
1930 }
1931
1932 =head2 $class->prepare( @arguments )
1933
1934 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1935 etc.).
1936
1937 =cut
1938
1939 sub prepare {
1940     my ( $class, @arguments ) = @_;
1941
1942     # XXX
1943     # After the app/ctxt split, this should become an attribute based on something passed
1944     # into the application.
1945     $class->context_class( ref $class || $class ) unless $class->context_class;
1946
1947     my $c = $class->context_class->new({});
1948
1949     # For on-demand data
1950     $c->request->_context($c);
1951     $c->response->_context($c);
1952
1953     #surely this is not the most efficient way to do things...
1954     $c->stats($class->stats_class->new)->enable($c->use_stats);
1955     if ( $c->debug || $c->config->{enable_catalyst_header} ) {
1956         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1957     }
1958
1959     try {
1960         # Allow engine to direct the prepare flow (for POE)
1961         if ( my $prepare = $c->engine->can('prepare') ) {
1962             $c->engine->$prepare( $c, @arguments );
1963         }
1964         else {
1965             $c->prepare_request(@arguments);
1966             $c->prepare_connection;
1967             $c->prepare_query_parameters;
1968             $c->prepare_headers;
1969             $c->prepare_cookies;
1970             $c->prepare_path;
1971
1972             # Prepare the body for reading, either by prepare_body
1973             # or the user, if they are using $c->read
1974             $c->prepare_read;
1975
1976             # Parse the body unless the user wants it on-demand
1977             unless ( ref($c)->config->{parse_on_demand} ) {
1978                 $c->prepare_body;
1979             }
1980         }
1981     }
1982     # VERY ugly and probably shouldn't rely on ->finalize actually working
1983     catch {
1984         # failed prepare is always due to an invalid request, right?
1985         $c->response->status(400);
1986         $c->response->content_type('text/plain');
1987         $c->response->body('Bad Request');
1988         $c->finalize;
1989         die $_;
1990     };
1991
1992     my $method  = $c->req->method  || '';
1993     my $path    = $c->req->path;
1994     $path       = '/' unless length $path;
1995     my $address = $c->req->address || '';
1996
1997     $c->log_request;
1998
1999     $c->prepare_action;
2000
2001     return $c;
2002 }
2003
2004 =head2 $c->prepare_action
2005
2006 Prepares action. See L<Catalyst::Dispatcher>.
2007
2008 =cut
2009
2010 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
2011
2012 =head2 $c->prepare_body
2013
2014 Prepares message body.
2015
2016 =cut
2017
2018 sub prepare_body {
2019     my $c = shift;
2020
2021     return if $c->request->_has_body;
2022
2023     # Initialize on-demand data
2024     $c->engine->prepare_body( $c, @_ );
2025     $c->prepare_parameters;
2026     $c->prepare_uploads;
2027 }
2028
2029 =head2 $c->prepare_body_chunk( $chunk )
2030
2031 Prepares a chunk of data before sending it to L<HTTP::Body>.
2032
2033 See L<Catalyst::Engine>.
2034
2035 =cut
2036
2037 sub prepare_body_chunk {
2038     my $c = shift;
2039     $c->engine->prepare_body_chunk( $c, @_ );
2040 }
2041
2042 =head2 $c->prepare_body_parameters
2043
2044 Prepares body parameters.
2045
2046 =cut
2047
2048 sub prepare_body_parameters {
2049     my $c = shift;
2050     $c->engine->prepare_body_parameters( $c, @_ );
2051 }
2052
2053 =head2 $c->prepare_connection
2054
2055 Prepares connection.
2056
2057 =cut
2058
2059 sub prepare_connection {
2060     my $c = shift;
2061     $c->engine->prepare_connection( $c, @_ );
2062 }
2063
2064 =head2 $c->prepare_cookies
2065
2066 Prepares cookies.
2067
2068 =cut
2069
2070 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
2071
2072 =head2 $c->prepare_headers
2073
2074 Prepares headers.
2075
2076 =cut
2077
2078 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
2079
2080 =head2 $c->prepare_parameters
2081
2082 Prepares parameters.
2083
2084 =cut
2085
2086 sub prepare_parameters {
2087     my $c = shift;
2088     $c->prepare_body_parameters;
2089     $c->engine->prepare_parameters( $c, @_ );
2090 }
2091
2092 =head2 $c->prepare_path
2093
2094 Prepares path and base.
2095
2096 =cut
2097
2098 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
2099
2100 =head2 $c->prepare_query_parameters
2101
2102 Prepares query parameters.
2103
2104 =cut
2105
2106 sub prepare_query_parameters {
2107     my $c = shift;
2108
2109     $c->engine->prepare_query_parameters( $c, @_ );
2110 }
2111
2112 =head2 $c->log_request
2113
2114 Writes information about the request to the debug logs.  This includes:
2115
2116 =over 4
2117
2118 =item * Request method, path, and remote IP address
2119
2120 =item * Query keywords (see L<Catalyst::Request/query_keywords>)
2121
2122 =item * Request parameters
2123
2124 =item * File uploads
2125
2126 =back
2127
2128 =cut
2129
2130 sub log_request {
2131     my $c = shift;
2132
2133     return unless $c->debug;
2134
2135     my($dump) = grep {$_->[0] eq 'Request' } $c->dump_these;
2136     my $request = $dump->[1];
2137
2138     my ( $method, $path, $address ) = ( $request->method, $request->path, $request->address );
2139     $method ||= '';
2140     $path = '/' unless length $path;
2141     $address ||= '';
2142     $c->log->debug(qq/"$method" request for "$path" from "$address"/);
2143
2144     $c->log_request_headers($request->headers);
2145
2146     if ( my $keywords = $request->query_keywords ) {
2147         $c->log->debug("Query keywords are: $keywords");
2148     }
2149
2150     $c->log_request_parameters( query => $request->query_parameters, $request->_has_body ? (body => $request->body_parameters) : () );
2151
2152     $c->log_request_uploads($request);
2153 }
2154
2155 =head2 $c->log_response
2156
2157 Writes information about the response to the debug logs by calling
2158 C<< $c->log_response_status_line >> and C<< $c->log_response_headers >>.
2159
2160 =cut
2161
2162 sub log_response {
2163     my $c = shift;
2164
2165     return unless $c->debug;
2166
2167     my($dump) = grep {$_->[0] eq 'Response' } $c->dump_these;
2168     my $response = $dump->[1];
2169
2170     $c->log_response_status_line($response);
2171     $c->log_response_headers($response->headers);
2172 }
2173
2174 =head2 $c->log_response_status_line($response)
2175
2176 Writes one line of information about the response to the debug logs.  This includes:
2177
2178 =over 4
2179
2180 =item * Response status code
2181
2182 =item * Content-Type header (if present)
2183
2184 =item * Content-Length header (if present)
2185
2186 =back
2187
2188 =cut
2189
2190 sub log_response_status_line {
2191     my ($c, $response) = @_;
2192
2193     $c->log->debug(
2194         sprintf(
2195             'Response Code: %s; Content-Type: %s; Content-Length: %s',
2196             $response->status                            || 'unknown',
2197             $response->headers->header('Content-Type')   || 'unknown',
2198             $response->headers->header('Content-Length') || 'unknown'
2199         )
2200     );
2201 }
2202
2203 =head2 $c->log_response_headers($headers);
2204
2205 Hook method which can be wrapped by plugins to log the responseheaders.
2206 No-op in the default implementation.
2207
2208 =cut
2209
2210 sub log_response_headers {}
2211
2212 =head2 $c->log_request_parameters( query => {}, body => {} )
2213
2214 Logs request parameters to debug logs
2215
2216 =cut
2217
2218 sub log_request_parameters {
2219     my $c          = shift;
2220     my %all_params = @_;
2221
2222     return unless $c->debug;
2223
2224     my $column_width = Catalyst::Utils::term_width() - 44;
2225     foreach my $type (qw(query body)) {
2226         my $params = $all_params{$type};
2227         next if ! keys %$params;
2228         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ $column_width, 'Value' ] );
2229         for my $key ( sort keys %$params ) {
2230             my $param = $params->{$key};
2231             my $value = defined($param) ? $param : '';
2232             $t->row( $key, ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
2233         }
2234         $c->log->debug( ucfirst($type) . " Parameters are:\n" . $t->draw );
2235     }
2236 }
2237
2238 =head2 $c->log_request_uploads
2239
2240 Logs file uploads included in the request to the debug logs.
2241 The parameter name, filename, file type, and file size are all included in
2242 the debug logs.
2243
2244 =cut
2245
2246 sub log_request_uploads {
2247     my $c = shift;
2248     my $request = shift;
2249     return unless $c->debug;
2250     my $uploads = $request->uploads;
2251     if ( keys %$uploads ) {
2252         my $t = Text::SimpleTable->new(
2253             [ 12, 'Parameter' ],
2254             [ 26, 'Filename' ],
2255             [ 18, 'Type' ],
2256             [ 9,  'Size' ]
2257         );
2258         for my $key ( sort keys %$uploads ) {
2259             my $upload = $uploads->{$key};
2260             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
2261                 $t->row( $key, $u->filename, $u->type, $u->size );
2262             }
2263         }
2264         $c->log->debug( "File Uploads are:\n" . $t->draw );
2265     }
2266 }
2267
2268 =head2 $c->log_request_headers($headers);
2269
2270 Hook method which can be wrapped by plugins to log the request headers.
2271 No-op in the default implementation.
2272
2273 =cut
2274
2275 sub log_request_headers {}
2276
2277 =head2 $c->log_headers($type => $headers)
2278
2279 Logs L<HTTP::Headers> (either request or response) to the debug logs.
2280
2281 =cut
2282
2283 sub log_headers {
2284     my $c       = shift;
2285     my $type    = shift;
2286     my $headers = shift;    # an HTTP::Headers instance
2287
2288     return unless $c->debug;
2289
2290     my $column_width = Catalyst::Utils::term_width() - 28;
2291     my $t = Text::SimpleTable->new( [ 15, 'Header Name' ], [ $column_width, 'Value' ] );
2292     $headers->scan(
2293         sub {
2294             my ( $name, $value ) = @_;
2295             $t->row( $name, $value );
2296         }
2297     );
2298     $c->log->debug( ucfirst($type) . " Headers:\n" . $t->draw );
2299 }
2300
2301
2302 =head2 $c->prepare_read
2303
2304 Prepares the input for reading.
2305
2306 =cut
2307
2308 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
2309
2310 =head2 $c->prepare_request
2311
2312 Prepares the engine request.
2313
2314 =cut
2315
2316 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
2317
2318 =head2 $c->prepare_uploads
2319
2320 Prepares uploads.
2321
2322 =cut
2323
2324 sub prepare_uploads {
2325     my $c = shift;
2326
2327     $c->engine->prepare_uploads( $c, @_ );
2328 }
2329
2330 =head2 $c->prepare_write
2331
2332 Prepares the output for writing.
2333
2334 =cut
2335
2336 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
2337
2338 =head2 $c->request_class
2339
2340 Returns or sets the request class. Defaults to L<Catalyst::Request>.
2341
2342 =head2 $c->response_class
2343
2344 Returns or sets the response class. Defaults to L<Catalyst::Response>.
2345
2346 =head2 $c->read( [$maxlength] )
2347
2348 Reads a chunk of data from the request body. This method is designed to
2349 be used in a while loop, reading C<$maxlength> bytes on every call.
2350 C<$maxlength> defaults to the size of the request if not specified.
2351
2352 You have to set C<< MyApp->config(parse_on_demand => 1) >> to use this
2353 directly.
2354
2355 Warning: If you use read(), Catalyst will not process the body,
2356 so you will not be able to access POST parameters or file uploads via
2357 $c->request.  You must handle all body parsing yourself.
2358
2359 =cut
2360
2361 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
2362
2363 =head2 $c->run
2364
2365 Starts the engine.
2366
2367 =cut
2368
2369 sub run {
2370   my $app = shift;
2371   $app->engine_loader->needs_psgi_engine_compat_hack ?
2372     $app->engine->run($app, @_) :
2373       $app->engine->run( $app, $app->_finalized_psgi_app, @_ );
2374 }
2375
2376 =head2 $c->set_action( $action, $code, $namespace, $attrs )
2377
2378 Sets an action in a given namespace.
2379
2380 =cut
2381
2382 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
2383
2384 =head2 $c->setup_actions($component)
2385
2386 Sets up actions for a component.
2387
2388 =cut
2389
2390 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
2391
2392 =head2 $c->setup_components
2393
2394 This method is called internally to set up the application's components.
2395
2396 It finds modules by calling the L<locate_components> method, expands them to
2397 package names with the L<expand_component_module> method, and then installs
2398 each component into the application.
2399
2400 The C<setup_components> config option is passed to both of the above methods.
2401
2402 Installation of each component is performed by the L<setup_component> method,
2403 below.
2404
2405 =cut
2406
2407 sub setup_components {
2408     my $class = shift;
2409
2410     my $config  = $class->config->{ setup_components };
2411
2412     my @comps = $class->locate_components($config);
2413     my %comps = map { $_ => 1 } @comps;
2414
2415     my $deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @comps;
2416     $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
2417         qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
2418     ) if $deprecatedcatalyst_component_names;
2419
2420     for my $component ( @comps ) {
2421
2422         # We pass ignore_loaded here so that overlay files for (e.g.)
2423         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
2424         # we know M::P::O found a file on disk so this is safe
2425
2426         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
2427     }
2428
2429     for my $component (@comps) {
2430         my $instance = $class->components->{ $component } = $class->setup_component($component);
2431         my @expanded_components = $instance->can('expand_modules')
2432             ? $instance->expand_modules( $component, $config )
2433             : $class->expand_component_module( $component, $config );
2434         for my $component (@expanded_components) {
2435             next if $comps{$component};
2436             $class->components->{ $component } = $class->setup_component($component);
2437         }
2438     }
2439 }
2440
2441 =head2 $c->locate_components( $setup_component_config )
2442
2443 This method is meant to provide a list of component modules that should be
2444 setup for the application.  By default, it will use L<Module::Pluggable>.
2445
2446 Specify a C<setup_components> config option to pass additional options directly
2447 to L<Module::Pluggable>. To add additional search paths, specify a key named
2448 C<search_extra> as an array reference. Items in the array beginning with C<::>
2449 will have the application class name prepended to them.
2450
2451 =cut
2452
2453 sub locate_components {
2454     my $class  = shift;
2455     my $config = shift;
2456
2457     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
2458     my $extra   = delete $config->{ search_extra } || [];
2459
2460     push @paths, @$extra;
2461
2462     my $locator = Module::Pluggable::Object->new(
2463         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
2464         %$config
2465     );
2466
2467     # XXX think about ditching this sort entirely
2468     my @comps = sort { length $a <=> length $b } $locator->plugins;
2469
2470     return @comps;
2471 }
2472
2473 =head2 $c->expand_component_module( $component, $setup_component_config )
2474
2475 Components found by C<locate_components> will be passed to this method, which
2476 is expected to return a list of component (package) names to be set up.
2477
2478 =cut
2479
2480 sub expand_component_module {
2481     my ($class, $module) = @_;
2482     return Devel::InnerPackage::list_packages( $module );
2483 }
2484
2485 =head2 $c->setup_component
2486
2487 =cut
2488
2489 sub setup_component {
2490     my( $class, $component ) = @_;
2491
2492     unless ( $component->can( 'COMPONENT' ) ) {
2493         return $component;
2494     }
2495
2496     my $suffix = Catalyst::Utils::class2classsuffix( $component );
2497     my $config = $class->config->{ $suffix } || {};
2498     # Stash catalyst_component_name in the config here, so that custom COMPONENT
2499     # methods also pass it. local to avoid pointlessly shitting in config
2500     # for the debug screen, as $component is already the key name.
2501     local $config->{catalyst_component_name} = $component;
2502
2503     my $instance = eval { $component->COMPONENT( $class, $config ); };
2504
2505     if ( my $error = $@ ) {
2506         chomp $error;
2507         Catalyst::Exception->throw(
2508             message => qq/Couldn't instantiate component "$component", "$error"/
2509         );
2510     }
2511
2512     unless (blessed $instance) {
2513         my $metaclass = Moose::Util::find_meta($component);
2514         my $method_meta = $metaclass->find_method_by_name('COMPONENT');
2515         my $component_method_from = $method_meta->associated_metaclass->name;
2516         my $value = defined($instance) ? $instance : 'undef';
2517         Catalyst::Exception->throw(
2518             message =>
2519             qq/Couldn't instantiate component "$component", COMPONENT() method (from $component_method_from) didn't return an object-like value (value was $value)./
2520         );
2521     }
2522     return $instance;
2523 }
2524
2525 =head2 $c->setup_dispatcher
2526
2527 Sets up dispatcher.
2528
2529 =cut
2530
2531 sub setup_dispatcher {
2532     my ( $class, $dispatcher ) = @_;
2533
2534     if ($dispatcher) {
2535         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
2536     }
2537
2538     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
2539         $dispatcher = 'Catalyst::Dispatcher::' . $env;
2540     }
2541
2542     unless ($dispatcher) {
2543         $dispatcher = $class->dispatcher_class;
2544     }
2545
2546     Class::MOP::load_class($dispatcher);
2547
2548     # dispatcher instance
2549     $class->dispatcher( $dispatcher->new );
2550 }
2551
2552 =head2 $c->setup_engine
2553
2554 Sets up engine.
2555
2556 =cut
2557
2558 sub engine_class {
2559     my ($class, $requested_engine) = @_;
2560
2561     if (!$class->engine_loader || $requested_engine) {
2562         $class->engine_loader(
2563             Catalyst::EngineLoader->new({
2564                 application_name => $class,
2565                 (defined $requested_engine
2566                      ? (catalyst_engine_class => $requested_engine) : ()),
2567             }),
2568         );
2569     }
2570
2571     $class->engine_loader->catalyst_engine_class;
2572 }
2573
2574 sub setup_engine {
2575     my ($class, $requested_engine) = @_;
2576
2577     my $engine = do {
2578         my $loader = $class->engine_loader;
2579
2580         if (!$loader || $requested_engine) {
2581             $loader = Catalyst::EngineLoader->new({
2582                 application_name => $class,
2583                 (defined $requested_engine
2584                      ? (requested_engine => $requested_engine) : ()),
2585             }),
2586
2587             $class->engine_loader($loader);
2588         }
2589
2590         $loader->catalyst_engine_class;
2591     };
2592
2593     # Don't really setup_engine -- see _setup_psgi_app for explanation.
2594     return if $class->loading_psgi_file;
2595
2596     Class::MOP::load_class($engine);
2597
2598     if ($ENV{MOD_PERL}) {
2599         my $apache = $class->engine_loader->auto;
2600
2601         my $meta = find_meta($class);
2602         my $was_immutable = $meta->is_immutable;
2603         my %immutable_options = $meta->immutable_options;
2604         $meta->make_mutable if $was_immutable;
2605
2606         $meta->add_method(handler => sub {
2607             my $r = shift;
2608             my $psgi_app = $class->psgi_app;
2609             $apache->call_app($r, $psgi_app);
2610         });
2611
2612         $meta->make_immutable(%immutable_options) if $was_immutable;
2613     }
2614
2615     $class->engine( $engine->new );
2616
2617     return;
2618 }
2619
2620 sub _finalized_psgi_app {
2621     my ($app) = @_;
2622
2623     unless ($app->_psgi_app) {
2624         my $psgi_app = $app->_setup_psgi_app;
2625         $app->_psgi_app($psgi_app);
2626     }
2627
2628     return $app->_psgi_app;
2629 }
2630
2631 sub _setup_psgi_app {
2632     my ($app) = @_;
2633
2634     for my $home (Path::Class::Dir->new($app->config->{home})) {
2635         my $psgi_file = $home->file(
2636             Catalyst::Utils::appprefix($app) . '.psgi',
2637         );
2638
2639         next unless -e $psgi_file;
2640
2641         # If $psgi_file calls ->setup_engine, it's doing so to load
2642         # Catalyst::Engine::PSGI. But if it does that, we're only going to
2643         # throw away the loaded PSGI-app and load the 5.9 Catalyst::Engine
2644         # anyway. So set a flag (ick) that tells setup_engine not to populate
2645         # $c->engine or do any other things we might regret.
2646
2647         $app->loading_psgi_file(1);
2648         my $psgi_app = Plack::Util::load_psgi($psgi_file);
2649         $app->loading_psgi_file(0);
2650
2651         return $psgi_app
2652             unless $app->engine_loader->needs_psgi_engine_compat_hack;
2653
2654         warn <<"EOW";
2655 Found a legacy Catalyst::Engine::PSGI .psgi file at ${psgi_file}.
2656
2657 Its content has been ignored. Please consult the Catalyst::Upgrading
2658 documentation on how to upgrade from Catalyst::Engine::PSGI.
2659 EOW
2660     }
2661
2662     return $app->apply_default_middlewares($app->psgi_app);
2663 }
2664
2665 =head2 $c->apply_default_middlewares
2666
2667 Adds the following L<Plack> middlewares to your application, since they are
2668 useful and commonly needed:
2669
2670 L<Plack::Middleware::ReverseProxy>, (conditionally added based on the status
2671 of your $ENV{REMOTE_ADDR}, and can be forced on with C<using_frontend_proxy>
2672 or forced off with C<ignore_frontend_proxy>), L<Plack::Middleware::LighttpdScriptNameFix>
2673 (if you are using Lighttpd), L<Plack::Middleware::IIS6ScriptNameFix> (always
2674 applied since this middleware is smart enough to conditionally apply itself).
2675
2676 Additionally if we detect we are using Nginx, we add a bit of custom middleware
2677 to solve some problems with the way that server handles $ENV{PATH_INFO} and
2678 $ENV{SCRIPT_NAME}
2679
2680 =cut
2681
2682
2683 sub apply_default_middlewares {
2684     my ($app, $psgi_app) = @_;
2685
2686     $psgi_app = Plack::Middleware::Conditional->wrap(
2687         $psgi_app,
2688         builder   => sub { Plack::Middleware::ReverseProxy->wrap($_[0]) },
2689         condition => sub {
2690             my ($env) = @_;
2691             return if $app->config->{ignore_frontend_proxy};
2692             return $env->{REMOTE_ADDR} eq '127.0.0.1'
2693                 || $app->config->{using_frontend_proxy};
2694         },
2695     );
2696
2697     # If we're running under Lighttpd, swap PATH_INFO and SCRIPT_NAME
2698     # http://lists.scsys.co.uk/pipermail/catalyst/2006-June/008361.html
2699     $psgi_app = Plack::Middleware::LighttpdScriptNameFix->wrap($psgi_app);
2700
2701     # we're applying this unconditionally as the middleware itself already makes
2702     # sure it doesn't fuck things up if it's not running under one of the right
2703     # IIS versions
2704     $psgi_app = Plack::Middleware::IIS6ScriptNameFix->wrap($psgi_app);
2705
2706     return $psgi_app;
2707 }
2708
2709 =head2 $c->psgi_app
2710
2711 Returns a PSGI application code reference for the catalyst application
2712 C<$c>. This is the bare application without any middlewares
2713 applied. C<${myapp}.psgi> is not taken into account.
2714
2715 This is what you want to be using to retrieve the PSGI application code
2716 reference of your Catalyst application for use in F<.psgi> files.
2717
2718 =cut
2719
2720 sub psgi_app {
2721     my ($app) = @_;
2722     return $app->engine->build_psgi_app($app);
2723 }
2724
2725 =head2 $c->setup_home
2726
2727 Sets up the home directory.
2728
2729 =cut
2730
2731 sub setup_home {
2732     my ( $class, $home ) = @_;
2733
2734     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2735         $home = $env;
2736     }
2737
2738     $home ||= Catalyst::Utils::home($class);
2739
2740     if ($home) {
2741         #I remember recently being scolded for assigning config values like this
2742         $class->config->{home} ||= $home;
2743         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2744     }
2745 }
2746
2747 =head2 $c->setup_log
2748
2749 Sets up log by instantiating a L<Catalyst::Log|Catalyst::Log> object and
2750 passing it to C<log()>. Pass in a comma-delimited list of levels to set the
2751 log to.
2752
2753 This method also installs a C<debug> method that returns a true value into the
2754 catalyst subclass if the "debug" level is passed in the comma-delimited list,
2755 or if the C<$CATALYST_DEBUG> environment variable is set to a true value.
2756
2757 Note that if the log has already been setup, by either a previous call to
2758 C<setup_log> or by a call such as C<< __PACKAGE__->log( MyLogger->new ) >>,
2759 that this method won't actually set up the log object.
2760
2761 =cut
2762
2763 sub setup_log {
2764     my ( $class, $levels ) = @_;
2765
2766     $levels ||= '';
2767     $levels =~ s/^\s+//;
2768     $levels =~ s/\s+$//;
2769     my %levels = map { $_ => 1 } split /\s*,\s*/, $levels;
2770
2771     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2772     if ( defined $env_debug ) {
2773         $levels{debug} = 1 if $env_debug; # Ugly!
2774         delete($levels{debug}) unless $env_debug;
2775     }
2776
2777     unless ( $class->log ) {
2778         $class->log( Catalyst::Log->new(keys %levels) );
2779     }
2780
2781     if ( $levels{debug} ) {
2782         Class::MOP::get_metaclass_by_name($class)->add_method('debug' => sub { 1 });
2783         $class->log->debug('Debug messages enabled');
2784     }
2785 }
2786
2787 =head2 $c->setup_plugins
2788
2789 Sets up plugins.
2790
2791 =cut
2792
2793 =head2 $c->setup_stats
2794
2795 Sets up timing statistics class.
2796
2797 =cut
2798
2799 sub setup_stats {
2800     my ( $class, $stats ) = @_;
2801
2802     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2803
2804     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2805     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2806         Class::MOP::get_metaclass_by_name($class)->add_method('use_stats' => sub { 1 });
2807         $class->log->debug('Statistics enabled');
2808     }
2809 }
2810
2811
2812 =head2 $c->registered_plugins
2813
2814 Returns a sorted list of the plugins which have either been stated in the
2815 import list.
2816
2817 If passed a given plugin name, it will report a boolean value indicating
2818 whether or not that plugin is loaded.  A fully qualified name is required if
2819 the plugin name does not begin with C<Catalyst::Plugin::>.
2820
2821  if ($c->registered_plugins('Some::Plugin')) {
2822      ...
2823  }
2824
2825 =cut
2826
2827 {
2828
2829     sub registered_plugins {
2830         my $proto = shift;
2831         return sort keys %{ $proto->_plugins } unless @_;
2832         my $plugin = shift;
2833         return 1 if exists $proto->_plugins->{$plugin};
2834         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2835     }
2836
2837     sub _register_plugin {
2838         my ( $proto, $plugin, $instant ) = @_;
2839         my $class = ref $proto || $proto;
2840
2841         Class::MOP::load_class( $plugin );
2842         $class->log->warn( "$plugin inherits from 'Catalyst::Component' - this is deprecated and will not work in 5.81" )
2843             if $plugin->isa( 'Catalyst::Component' );
2844         $proto->_plugins->{$plugin} = 1;
2845         unless ($instant) {
2846             my $meta = Class::MOP::get_metaclass_by_name($class);
2847             $meta->superclasses($plugin, $meta->superclasses);
2848         }
2849         return $class;
2850     }
2851
2852     sub setup_plugins {
2853         my ( $class, $plugins ) = @_;
2854
2855         $class->_plugins( {} ) unless $class->_plugins;
2856         $plugins = Data::OptList::mkopt($plugins || []);
2857
2858         my @plugins = map {
2859             [ Catalyst::Utils::resolve_namespace(
2860                   $class . '::Plugin',
2861                   'Catalyst::Plugin', $_->[0]
2862               ),
2863               $_->[1],
2864             ]
2865          } @{ $plugins };
2866
2867         for my $plugin ( reverse @plugins ) {
2868             Class::MOP::load_class($plugin->[0], $plugin->[1]);
2869             my $meta = find_meta($plugin->[0]);
2870             next if $meta && $meta->isa('Moose::Meta::Role');
2871
2872             $class->_register_plugin($plugin->[0]);
2873         }
2874
2875         my @roles =
2876             map  { $_->[0]->name, $_->[1] }
2877             grep { blessed($_->[0]) && $_->[0]->isa('Moose::Meta::Role') }
2878             map  { [find_meta($_->[0]), $_->[1]] }
2879             @plugins;
2880
2881         Moose::Util::apply_all_roles(
2882             $class => @roles
2883         ) if @roles;
2884     }
2885 }
2886
2887 =head2 $c->stack
2888
2889 Returns an arrayref of the internal execution stack (actions that are
2890 currently executing).
2891
2892 =head2 $c->stats
2893
2894 Returns the current timing statistics object. By default Catalyst uses
2895 L<Catalyst::Stats|Catalyst::Stats>, but can be set otherwise with
2896 L<< stats_class|/"$c->stats_class" >>.
2897
2898 Even if L<< -Stats|/"-Stats" >> is not enabled, the stats object is still
2899 available. By enabling it with C< $c->stats->enabled(1) >, it can be used to
2900 profile explicitly, although MyApp.pm still won't profile nor output anything
2901 by itself.
2902
2903 =head2 $c->stats_class
2904
2905 Returns or sets the stats (timing statistics) class. L<Catalyst::Stats|Catalyst::Stats> is used by default.
2906
2907 =head2 $c->use_stats
2908
2909 Returns 1 when L<< stats collection|/"-Stats" >> is enabled.
2910
2911 Note that this is a static method, not an accessor and should be overridden
2912 by declaring C<sub use_stats { 1 }> in your MyApp.pm, not by calling C<< $c->use_stats(1) >>.
2913
2914 =cut
2915
2916 sub use_stats { 0 }
2917
2918
2919 =head2 $c->write( $data )
2920
2921 Writes $data to the output stream. When using this method directly, you
2922 will need to manually set the C<Content-Length> header to the length of
2923 your output data, if known.
2924
2925 =cut
2926
2927 sub write {
2928     my $c = shift;
2929
2930     # Finalize headers if someone manually writes output
2931     $c->finalize_headers;
2932
2933     return $c->engine->write( $c, @_ );
2934 }
2935
2936 =head2 version
2937
2938 Returns the Catalyst version number. Mostly useful for "powered by"
2939 messages in template systems.
2940
2941 =cut
2942
2943 sub version { return $Catalyst::VERSION }
2944
2945 =head1 CONFIGURATION
2946
2947 There are a number of 'base' config variables which can be set:
2948
2949 =over
2950
2951 =item *
2952
2953 C<default_model> - The default model picked if you say C<< $c->model >>. See L<< /$c->model($name) >>.
2954
2955 =item *
2956
2957 C<default_view> - The default view to be rendered or returned when C<< $c->view >> is called. See L<< /$c->view($name) >>.
2958
2959 =item *
2960
2961 C<disable_component_resolution_regex_fallback> - Turns
2962 off the deprecated component resolution functionality so
2963 that if any of the component methods (e.g. C<< $c->controller('Foo') >>)
2964 are called then regex search will not be attempted on string values and
2965 instead C<undef> will be returned.
2966
2967 =item *
2968
2969 C<home> - The application home directory. In an uninstalled application,
2970 this is the top level application directory. In an installed application,
2971 this will be the directory containing C<< MyApp.pm >>.
2972
2973 =item *
2974
2975 C<ignore_frontend_proxy> - See L</PROXY SUPPORT>
2976
2977 =item *
2978
2979 C<name> - The name of the application in debug messages and the debug and
2980 welcome screens
2981
2982 =item *
2983
2984 C<parse_on_demand> - The request body (for example file uploads) will not be parsed
2985 until it is accessed. This allows you to (for example) check authentication (and reject
2986 the upload) before actually recieving all the data. See L</ON-DEMAND PARSER>
2987
2988 =item *
2989
2990 C<root> - The root directory for templates. Usually this is just a
2991 subdirectory of the home directory, but you can set it to change the
2992 templates to a different directory.
2993
2994 =item *
2995
2996 C<search_extra> - Array reference passed to Module::Pluggable to for additional
2997 namespaces from which components will be loaded (and constructed and stored in
2998 C<< $c->components >>).
2999
3000 =item *
3001
3002 C<show_internal_actions> - If true, causes internal actions such as C<< _DISPATCH >>
3003 to be shown in hit debug tables in the test server.
3004
3005 =item *
3006
3007 C<use_request_uri_for_path> - Controlls if the C<REQUEST_URI> or C<PATH_INFO> environment
3008 variable should be used for determining the request path.
3009
3010 Most web server environments pass the requested path to the application using environment variables,
3011 from which Catalyst has to reconstruct the request base (i.e. the top level path to / in the application,
3012 exposed as C<< $c->request->base >>) and the request path below that base.
3013
3014 There are two methods of doing this, both of which have advantages and disadvantages. Which method is used
3015 is determined by the C<< $c->config(use_request_uri_for_path) >> setting (which can either be true or false).
3016
3017 =over
3018
3019 =item use_request_uri_for_path => 0
3020
3021 This is the default (and the) traditional method that Catalyst has used for determining the path information.
3022 The path is synthesised from a combination of the C<PATH_INFO> and C<SCRIPT_NAME> environment variables.
3023 The allows the application to behave correctly when C<mod_rewrite> is being used to redirect requests
3024 into the application, as these variables are adjusted by mod_rewrite to take account for the redirect.
3025
3026 However this method has the major disadvantage that it is impossible to correctly decode some elements
3027 of the path, as RFC 3875 says: "C<< Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
3028 contain path-segment parameters. >>" This means PATH_INFO is B<always> decoded, and therefore Catalyst
3029 can't distinguish / vs %2F in paths (in addition to other encoded values).
3030
3031 =item use_request_uri_for_path => 1
3032
3033 This method uses the C<REQUEST_URI> and C<SCRIPT_NAME> environment variables. As C<REQUEST_URI> is never
3034 decoded, this means that applications using this mode can correctly handle URIs including the %2F character
3035 (i.e. with C<AllowEncodedSlashes> set to C<On> in Apache).
3036
3037 Given that this method of path resolution is provably more correct, it is recommended that you use
3038 this unless you have a specific need to deploy your application in a non-standard environment, and you are
3039 aware of the implications of not being able to handle encoded URI paths correctly.
3040
3041 However it also means that in a number of cases when the app isn't installed directly at a path, but instead
3042 is having paths rewritten into it (e.g. as a .cgi/fcgi in a public_html directory, with mod_rewrite in a
3043 .htaccess file, or when SSI is used to rewrite pages into the app, or when sub-paths of the app are exposed
3044 at other URIs than that which the app is 'normally' based at with C<mod_rewrite>), the resolution of
3045 C<< $c->request->base >> will be incorrect.
3046
3047 =back
3048
3049 =item *
3050
3051 C<using_frontend_proxy> - See L</PROXY SUPPORT>.
3052
3053 =back
3054
3055 =head1 INTERNAL ACTIONS
3056
3057 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
3058 C<_ACTION>, and C<_END>. These are by default not shown in the private
3059 action table, but you can make them visible with a config parameter.
3060
3061     MyApp->config(show_internal_actions => 1);
3062
3063 =head1 ON-DEMAND PARSER
3064
3065 The request body is usually parsed at the beginning of a request,
3066 but if you want to handle input yourself, you can enable on-demand
3067 parsing with a config parameter.
3068
3069     MyApp->config(parse_on_demand => 1);
3070
3071 =head1 PROXY SUPPORT
3072
3073 Many production servers operate using the common double-server approach,
3074 with a lightweight frontend web server passing requests to a larger
3075 backend server. An application running on the backend server must deal
3076 with two problems: the remote user always appears to be C<127.0.0.1> and
3077 the server's hostname will appear to be C<localhost> regardless of the
3078 virtual host that the user connected through.
3079
3080 Catalyst will automatically detect this situation when you are running
3081 the frontend and backend servers on the same machine. The following
3082 changes are made to the request.
3083
3084     $c->req->address is set to the user's real IP address, as read from
3085     the HTTP X-Forwarded-For header.
3086
3087     The host value for $c->req->base and $c->req->uri is set to the real
3088     host, as read from the HTTP X-Forwarded-Host header.
3089
3090 Additionally, you may be running your backend application on an insecure
3091 connection (port 80) while your frontend proxy is running under SSL.  If there
3092 is a discrepancy in the ports, use the HTTP header C<X-Forwarded-Port> to
3093 tell Catalyst what port the frontend listens on.  This will allow all URIs to
3094 be created properly.
3095
3096 In the case of passing in:
3097
3098     X-Forwarded-Port: 443
3099
3100 All calls to C<uri_for> will result in an https link, as is expected.
3101
3102 Obviously, your web server must support these headers for this to work.
3103
3104 In a more complex server farm environment where you may have your
3105 frontend proxy server(s) on different machines, you will need to set a
3106 configuration option to tell Catalyst to read the proxied data from the
3107 headers.
3108
3109     MyApp->config(using_frontend_proxy => 1);
3110
3111 If you do not wish to use the proxy support at all, you may set:
3112
3113     MyApp->config(ignore_frontend_proxy => 1);
3114
3115 =head1 THREAD SAFETY
3116
3117 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
3118 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
3119 believe the Catalyst core to be thread-safe.
3120
3121 If you plan to operate in a threaded environment, remember that all other
3122 modules you are using must also be thread-safe. Some modules, most notably
3123 L<DBD::SQLite>, are not thread-safe.
3124
3125 =head1 SUPPORT
3126
3127 IRC:
3128
3129     Join #catalyst on irc.perl.org.
3130
3131 Mailing Lists:
3132
3133     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst
3134     http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/catalyst-dev
3135
3136 Web:
3137
3138     http://catalyst.perl.org
3139
3140 Wiki:
3141
3142     http://dev.catalyst.perl.org
3143
3144 =head1 SEE ALSO
3145
3146 =head2 L<Task::Catalyst> - All you need to start with Catalyst
3147
3148 =head2 L<Catalyst::Manual> - The Catalyst Manual
3149
3150 =head2 L<Catalyst::Component>, L<Catalyst::Controller> - Base classes for components
3151
3152 =head2 L<Catalyst::Engine> - Core engine
3153
3154 =head2 L<Catalyst::Log> - Log class.
3155
3156 =head2 L<Catalyst::Request> - Request object
3157
3158 =head2 L<Catalyst::Response> - Response object
3159
3160 =head2 L<Catalyst::Test> - The test suite.
3161
3162 =head1 PROJECT FOUNDER
3163
3164 sri: Sebastian Riedel <sri@cpan.org>
3165
3166 =head1 CONTRIBUTORS
3167
3168 abw: Andy Wardley
3169
3170 acme: Leon Brocard <leon@astray.com>
3171
3172 abraxxa: Alexander Hartmaier <abraxxa@cpan.org>
3173
3174 Andrew Bramble
3175
3176 Andrew Ford E<lt>A.Ford@ford-mason.co.ukE<gt>
3177
3178 Andrew Ruthven
3179
3180 andyg: Andy Grundman <andy@hybridized.org>
3181
3182 audreyt: Audrey Tang
3183
3184 bricas: Brian Cassidy <bricas@cpan.org>
3185
3186 Caelum: Rafael Kitover <rkitover@io.com>
3187
3188 chansen: Christian Hansen
3189
3190 chicks: Christopher Hicks
3191
3192 Chisel Wright C<pause@herlpacker.co.uk>
3193
3194 Danijel Milicevic C<me@danijel.de>
3195
3196 David Kamholz E<lt>dkamholz@cpan.orgE<gt>
3197
3198 David Naughton, C<naughton@umn.edu>
3199
3200 David E. Wheeler
3201
3202 dhoss: Devin Austin <dhoss@cpan.org>
3203
3204 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
3205
3206 Drew Taylor
3207
3208 dwc: Daniel Westermann-Clark <danieltwc@cpan.org>
3209
3210 esskar: Sascha Kiefer
3211
3212 fireartist: Carl Franks <cfranks@cpan.org>
3213
3214 frew: Arthur Axel "fREW" Schmidt <frioux@gmail.com>
3215
3216 gabb: Danijel Milicevic
3217
3218 Gary Ashton Jones
3219
3220 Gavin Henry C<ghenry@perl.me.uk>
3221
3222 Geoff Richards
3223
3224 groditi: Guillermo Roditi <groditi@gmail.com>
3225
3226 hobbs: Andrew Rodland <andrew@cleverdomain.org>
3227
3228 ilmari: Dagfinn Ilmari Mannsåker <ilmari@ilmari.org>
3229
3230 jcamacho: Juan Camacho
3231
3232 jester: Jesse Sheidlower C<jester@panix.com>
3233
3234 jhannah: Jay Hannah <jay@jays.net>
3235
3236 Jody Belka
3237
3238 Johan Lindstrom
3239
3240 jon: Jon Schutz <jjschutz@cpan.org>
3241
3242 Jonathan Rockway C<< <jrockway@cpan.org> >>
3243
3244 Kieren Diment C<kd@totaldatasolution.com>
3245
3246 konobi: Scott McWhirter <konobi@cpan.org>
3247
3248 marcus: Marcus Ramberg <mramberg@cpan.org>
3249
3250 miyagawa: Tatsuhiko Miyagawa <miyagawa@bulknews.net>
3251
3252 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
3253
3254 mugwump: Sam Vilain
3255
3256 naughton: David Naughton
3257
3258 ningu: David Kamholz <dkamholz@cpan.org>
3259
3260 nothingmuch: Yuval Kogman <nothingmuch@woobling.org>
3261
3262 numa: Dan Sully <daniel@cpan.org>
3263
3264 obra: Jesse Vincent
3265
3266 Octavian Rasnita
3267
3268 omega: Andreas Marienborg
3269
3270 Oleg Kostyuk <cub.uanic@gmail.com>
3271
3272 phaylon: Robert Sedlacek <phaylon@dunkelheit.at>
3273
3274 rafl: Florian Ragwitz <rafl@debian.org>
3275
3276 random: Roland Lammel <lammel@cpan.org>
3277
3278 Robert Sedlacek C<< <rs@474.at> >>
3279
3280 SpiceMan: Marcel Montes
3281
3282 sky: Arthur Bergman
3283
3284 szbalint: Balint Szilakszi <szbalint@cpan.org>
3285
3286 t0m: Tomas Doran <bobtfish@bobtfish.net>
3287
3288 Ulf Edvinsson
3289
3290 Viljo Marrandi C<vilts@yahoo.com>
3291
3292 Will Hawes C<info@whawes.co.uk>
3293
3294 willert: Sebastian Willert <willert@cpan.org>
3295
3296 wreis: Wallace Reis <wallace@reis.org.br>
3297
3298 Yuval Kogman, C<nothingmuch@woobling.org>
3299
3300 rainboxx: Matthias Dietrich, C<perl@rainboxx.de>
3301
3302 dd070: Dhaval Dhanani <dhaval070@gmail.com>
3303
3304 =head1 COPYRIGHT
3305
3306 Copyright (c) 2005, the above named PROJECT FOUNDER and CONTRIBUTORS.
3307
3308 =head1 LICENSE
3309
3310 This library is free software. You can redistribute it and/or modify it under
3311 the same terms as Perl itself.
3312
3313 =cut
3314
3315 no Moose;
3316
3317 __PACKAGE__->meta->make_immutable;
3318
3319 1;