lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object ();
  16 use NEXT;
  17 use Text::SimpleTable ();
  18 use Path::Class::Dir ();
  19 use Path::Class::File ();
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI ();
  22 use URI::http;
  23 use URI::https;
  24 use Scalar::Util qw/weaken blessed/;
  25 use Tree::Simple qw/use_weak_refs/;
  26 use Tree::Simple::Visitor::FindByUID;
  27 use attributes;
  28 use utf8;
  29 use Carp qw/croak carp/;
  30
  31 BEGIN { require 5.008001; }
  32
  33 __PACKAGE__->mk_accessors(
  34     qw/counter request response state action stack namespace stats/
  35 );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class stats_class
  56   setup_finished/;
  57
  58 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  59 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  60 __PACKAGE__->request_class('Catalyst::Request');
  61 __PACKAGE__->response_class('Catalyst::Response');
  62 __PACKAGE__->stats_class('Catalyst::Stats');
  63
  64 # Remember to update this in Catalyst::Runtime as well!
  65
  66 our $VERSION = '5.7014';
  67
  68 sub import {
  69     my ( $class, @arguments ) = @_;
  70
  71     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  72     # callers @ISA.
  73     return unless $class eq 'Catalyst';
  74
  75     my $caller = caller(0);
  76
  77     unless ( $caller->isa('Catalyst') ) {
  78         no strict 'refs';
  79         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  80     }
  81
  82     $caller->arguments( [@arguments] );
  83     $caller->setup_home;
  84 }
  85
  86 =head1 NAME
  87
  88 Catalyst - The Elegant MVC Web Application Framework
  89
  90 =head1 SYNOPSIS
  91
  92 See the L<Catalyst::Manual> distribution for comprehensive
  93 documentation and tutorials.
  94
  95     # Install Catalyst::Devel for helpers and other development tools
  96     # use the helper to create a new application
  97     catalyst.pl MyApp
  98
  99     # add models, views, controllers
 100     script/myapp_create.pl model MyDatabase DBIC::Schema create=dynamic dbi:SQLite:/path/to/db
 101     script/myapp_create.pl view MyTemplate TT
 102     script/myapp_create.pl controller Search
 103
 104     # built in testserver -- use -r to restart automatically on changes
 105     # --help to see all available options
 106     script/myapp_server.pl
 107
 108     # command line testing interface
 109     script/myapp_test.pl /yada
 110
 111     ### in lib/MyApp.pm
 112     use Catalyst qw/-Debug/; # include plugins here as well
 113
 114     ### In lib/MyApp/Controller/Root.pm (autocreated)
 115     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 116         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 117         $c->stash->{template} = 'foo.tt'; # set the template
 118         # lookup something from db -- stash vars are passed to TT
 119         $c->stash->{data} =
 120           $c->model('Database::Foo')->search( { country => $args[0] } );
 121         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 122             $c->forward( 'bar' ); # process another action
 123             # do something else after forward returns
 124         }
 125     }
 126
 127     # The foo.tt TT template can use the stash data from the database
 128     [% WHILE (item = data.next) %]
 129         [% item.foo %]
 130     [% END %]
 131
 132     # called for /bar/of/soap, /bar/of/soap/10, etc.
 133     sub bar : Path('/bar/of/soap') { ... }
 134
 135     # called for all actions, from the top-most controller downwards
 136     sub auto : Private {
 137         my ( $self, $c ) = @_;
 138         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 139             $c->res->redirect( '/login' ); # require login
 140             return 0; # abort request and go immediately to end()
 141         }
 142         return 1; # success; carry on to next action
 143     }
 144
 145     # called after all actions are finished
 146     sub end : Private {
 147         my ( $self, $c ) = @_;
 148         if ( scalar @{ $c->error } ) { ... } # handle errors
 149         return if $c->res->body; # already have a response
 150         $c->forward( 'MyApp::View::TT' ); # render template
 151     }
 152
 153     ### in MyApp/Controller/Foo.pm
 154     # called for /foo/bar
 155     sub bar : Local { ... }
 156
 157     # called for /blargle
 158     sub blargle : Global { ... }
 159
 160     # an index action matches /foo, but not /foo/1, etc.
 161     sub index : Private { ... }
 162
 163     ### in MyApp/Controller/Foo/Bar.pm
 164     # called for /foo/bar/baz
 165     sub baz : Local { ... }
 166
 167     # first Root auto is called, then Foo auto, then this
 168     sub auto : Private { ... }
 169
 170     # powerful regular expression paths are also possible
 171     sub details : Regex('^product/(\w+)/details$') {
 172         my ( $self, $c ) = @_;
 173         # extract the (\w+) from the URI
 174         my $product = $c->req->captures->[0];
 175     }
 176
 177 See L<Catalyst::Manual::Intro> for additional information.
 178
 179 =head1 DESCRIPTION
 180
 181 Catalyst is a modern framework for making web applications without the
 182 pain usually associated with this process. This document is a reference
 183 to the main Catalyst application. If you are a new user, we suggest you
 184 start with L<Catalyst::Manual::Tutorial> or L<Catalyst::Manual::Intro>.
 185
 186 See L<Catalyst::Manual> for more documentation.
 187
 188 Catalyst plugins can be loaded by naming them as arguments to the "use
 189 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 190 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 191 C<My::Module>.
 192
 193     use Catalyst qw/My::Module/;
 194
 195 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 196 fully qualify the name by using a unary plus:
 197
 198     use Catalyst qw/
 199         My::Module
 200         +Fully::Qualified::Plugin::Name
 201     /;
 202
 203 Special flags like C<-Debug> and C<-Engine> can also be specified as
 204 arguments when Catalyst is loaded:
 205
 206     use Catalyst qw/-Debug My::Module/;
 207
 208 The position of plugins and flags in the chain is important, because
 209 they are loaded in the order in which they appear.
 210
 211 The following flags are supported:
 212
 213 =head2 -Debug
 214
 215 Enables debug output. You can also force this setting from the system
 216 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment
 217 settings override the application, with <MYAPP>_DEBUG having the highest
 218 priority.
 219
 220 =head2 -Engine
 221
 222 Forces Catalyst to use a specific engine. Omit the
 223 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 224
 225     use Catalyst qw/-Engine=CGI/;
 226
 227 =head2 -Home
 228
 229 Forces Catalyst to use a specific home directory, e.g.:
 230
 231     use Catalyst qw[-Home=/usr/mst];
 232
 233 This can also be done in the shell environment by setting either the
 234 C<CATALYST_HOME> environment variable or C<MYAPP_HOME>; where C<MYAPP>
 235 is replaced with the uppercased name of your application, any "::" in
 236 the name will be replaced with underscores, e.g. MyApp::Web should use
 237 MYAPP_WEB_HOME. If both variables are set, the MYAPP_HOME one will be used.
 238
 239 =head2 -Log
 240
 241 Specifies log level.
 242
 243 =head2 -Stats
 244
 245 Enables statistics collection and reporting. You can also force this setting
 246 from the system environment with CATALYST_STATS or <MYAPP>_STATS. The
 247 environment settings override the application, with <MYAPP>_STATS having the
 248 highest priority.
 249
 250 e.g.
 251
 252    use Catalyst qw/-Stats=1/
 253
 254 =head1 METHODS
 255
 256 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 257
 258 =head2 $c->action
 259
 260 Returns a L<Catalyst::Action> object for the current action, which
 261 stringifies to the action name. See L<Catalyst::Action>.
 262
 263 =head2 $c->namespace
 264
 265 Returns the namespace of the current action, i.e., the URI prefix
 266 corresponding to the controller of the current action. For example:
 267
 268     # in Controller::Foo::Bar
 269     $c->namespace; # returns 'foo/bar';
 270
 271 =head2 $c->request
 272
 273 =head2 $c->req
 274
 275 Returns the current L<Catalyst::Request> object, giving access to
 276 information about the current client request (including parameters,
 277 cookies, HTTP headers, etc.). See L<Catalyst::Request>.
 278
 279 =head2 REQUEST FLOW HANDLING
 280
 281 =head2 $c->forward( $action [, \@arguments ] )
 282
 283 =head2 $c->forward( $class, $method, [, \@arguments ] )
 284
 285 Forwards processing to another action, by its private name. If you give a
 286 class name but no method, C<process()> is called. You may also optionally
 287 pass arguments in an arrayref. The action will receive the arguments in
 288 C<@_> and C<< $c->req->args >>. Upon returning from the function,
 289 C<< $c->req->args >> will be restored to the previous values.
 290
 291 Any data C<return>ed from the action forwarded to, will be returned by the
 292 call to forward.
 293
 294     my $foodata = $c->forward('/foo');
 295     $c->forward('index');
 296     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 297     $c->forward('MyApp::View::TT');
 298
 299 Note that forward implies an C<<eval { }>> around the call (actually
 300 C<execute> does), thus de-fatalizing all 'dies' within the called
 301 action. If you want C<die> to propagate you need to do something like:
 302
 303     $c->forward('foo');
 304     die $c->error if $c->error;
 305
 306 Or make sure to always return true values from your actions and write
 307 your code like this:
 308
 309     $c->forward('foo') || return;
 310
 311 =cut
 312
 313 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 314
 315 =head2 $c->detach( $action [, \@arguments ] )
 316
 317 =head2 $c->detach( $class, $method, [, \@arguments ] )
 318
 319 =head2 $c->detach()
 320
 321 The same as C<forward>, but doesn't return to the previous action when
 322 processing is finished.
 323
 324 When called with no arguments it escapes the processing chain entirely.
 325
 326 =cut
 327
 328 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 329
 330 =head2 $c->response
 331
 332 =head2 $c->res
 333
 334 Returns the current L<Catalyst::Response> object, see there for details.
 335
 336 =head2 $c->stash
 337
 338 Returns a hashref to the stash, which may be used to store data and pass
 339 it between components during a request. You can also set hash keys by
 340 passing arguments. The stash is automatically sent to the view. The
 341 stash is cleared at the end of a request; it cannot be used for
 342 persistent storage (for this you must use a session; see
 343 L<Catalyst::Plugin::Session> for a complete system integrated with
 344 Catalyst).
 345
 346     $c->stash->{foo} = $bar;
 347     $c->stash( { moose => 'majestic', qux => 0 } );
 348     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 349
 350     # stash is automatically passed to the view for use in a template
 351     $c->forward( 'MyApp::View::TT' );
 352
 353 =cut
 354
 355 sub stash {
 356     my $c = shift;
 357     if (@_) {
 358         my $stash = @_ > 1 ? {@_} : $_[0];
 359         croak('stash takes a hash or hashref') unless ref $stash;
 360         foreach my $key ( keys %$stash ) {
 361             $c->{stash}->{$key} = $stash->{$key};
 362         }
 363     }
 364     return $c->{stash};
 365 }
 366
 367 =head2 $c->error
 368
 369 =head2 $c->error($error, ...)
 370
 371 =head2 $c->error($arrayref)
 372
 373 Returns an arrayref containing error messages.  If Catalyst encounters an
 374 error while processing a request, it stores the error in $c->error.  This
 375 method should only be used to store fatal error messages.
 376
 377     my @error = @{ $c->error };
 378
 379 Add a new error.
 380
 381     $c->error('Something bad happened');
 382
 383 =cut
 384
 385 sub error {
 386     my $c = shift;
 387     if ( $_[0] ) {
 388         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 389         croak @$error unless ref $c;
 390         push @{ $c->{error} }, @$error;
 391     }
 392     elsif ( defined $_[0] ) { $c->{error} = undef }
 393     return $c->{error} || [];
 394 }
 395
 396
 397 =head2 $c->state
 398
 399 Contains the return value of the last executed action.
 400
 401 =head2 $c->clear_errors
 402
 403 Clear errors.  You probably don't want to clear the errors unless you are
 404 implementing a custom error screen.
 405
 406 This is equivalent to running
 407
 408     $c->error(0);
 409
 410 =cut
 411
 412 sub clear_errors {
 413     my $c = shift;
 414     $c->error(0);
 415 }
 416
 417 # search components given a name and some prefixes
 418 sub _comp_search_prefixes {
 419     my ( $c, $name, @prefixes ) = @_;
 420     my $appclass = ref $c || $c;
 421     my $filter   = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 422
 423     # map the original component name to the sub part that we will search against
 424     my %eligible = map { my $n = $_; $n =~ s{^$appclass\::[^:]+::}{}; $_ => $n; }
 425         grep { /$filter/ } keys %{ $c->components };
 426
 427     # undef for a name will return all
 428     return keys %eligible if !defined $name;
 429
 430     my $query  = ref $name ? $name : qr/^$name$/i;
 431     my @result = grep { $eligible{$_} =~ m{$query} } keys %eligible;
 432
 433     return map { $c->components->{ $_ } } @result if @result;
 434
 435     # if we were given a regexp to search against, we're done.
 436     return if ref $name;
 437
 438     # regexp fallback
 439     $query  = qr/$name/i;
 440     @result = grep { $eligible{ $_ } =~ m{$query} } keys %eligible;
 441
 442     # don't warn if we didn't find any results, it just might not exist
 443     if( @result ) {
 444         $c->log->warn( 'Relying on the regexp fallback behavior for component resolution' );
 445         $c->log->warn( 'is unreliable and unsafe. You have been warned' );
 446     }
 447
 448     return @result;
 449 }
 450
 451 # Find possible names for a prefix
 452 sub _comp_names {
 453     my ( $c, @prefixes ) = @_;
 454     my $appclass = ref $c || $c;
 455
 456     my $filter = "^${appclass}::(" . join( '|', @prefixes ) . ')::';
 457
 458     my @names = map { s{$filter}{}; $_; } $c->_comp_search_prefixes( undef, @prefixes );
 459     return @names;
 460 }
 461
 462 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 463 sub _filter_component {
 464     my ( $c, $comp, @args ) = @_;
 465
 466     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 467         return $comp->ACCEPT_CONTEXT( $c, @args );
 468     }
 469
 470     return $comp;
 471 }
 472
 473 =head2 COMPONENT ACCESSORS
 474
 475 =head2 $c->controller($name)
 476
 477 Gets a L<Catalyst::Controller> instance by name.
 478
 479     $c->controller('Foo')->do_stuff;
 480
 481 If the name is omitted, will return the controller for the dispatched
 482 action.
 483
 484 =cut
 485
 486 sub controller {
 487     my ( $c, $name, @args ) = @_;
 488
 489     if( $name ) {
 490         my @result = $c->_comp_search_prefixes( $name, qw/Controller C/ );
 491         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 492         return $c->_filter_component( $result[ 0 ], @args );
 493     }
 494
 495     return $c->component( $c->action->class );
 496 }
 497
 498 =head2 $c->model($name)
 499
 500 Gets a L<Catalyst::Model> instance by name.
 501
 502     $c->model('Foo')->do_stuff;
 503
 504 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 505
 506 If the name is omitted, it will look for
 507  - a model object in $c->stash{current_model_instance}, then
 508  - a model name in $c->stash->{current_model}, then
 509  - a config setting 'default_model', or
 510  - check if there is only one model, and return it if that's the case.
 511
 512 =cut
 513
 514 sub model {
 515     my ( $c, $name, @args ) = @_;
 516
 517     if( $name ) {
 518         my @result = $c->_comp_search_prefixes( $name, qw/Model M/ );
 519         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 520         return $c->_filter_component( $result[ 0 ], @args );
 521     }
 522
 523     if (ref $c) {
 524         return $c->stash->{current_model_instance}
 525           if $c->stash->{current_model_instance};
 526         return $c->model( $c->stash->{current_model} )
 527           if $c->stash->{current_model};
 528     }
 529     return $c->model( $c->config->{default_model} )
 530       if $c->config->{default_model};
 531
 532     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/Model M/);
 533
 534     if( $rest ) {
 535         $c->log->warn( 'Calling $c->model() will return a random model unless you specify one of:' );
 536         $c->log->warn( '* $c->config->{default_model} # the name of the default model to use' );
 537         $c->log->warn( '* $c->stash->{current_model} # the name of the model to use for this request' );
 538         $c->log->warn( '* $c->stash->{current_model_instance} # the instance of the model to use for this request' );
 539     }
 540
 541     return $c->_filter_component( $comp );
 542 }
 543
 544
 545 =head2 $c->view($name)
 546
 547 Gets a L<Catalyst::View> instance by name.
 548
 549     $c->view('Foo')->do_stuff;
 550
 551 Any extra arguments are directly passed to ACCEPT_CONTEXT.
 552
 553 If the name is omitted, it will look for
 554  - a view object in $c->stash{current_view_instance}, then
 555  - a view name in $c->stash->{current_view}, then
 556  - a config setting 'default_view', or
 557  - check if there is only one view, and return it if that's the case.
 558
 559 =cut
 560
 561 sub view {
 562     my ( $c, $name, @args ) = @_;
 563
 564     if( $name ) {
 565         my @result = $c->_comp_search_prefixes( $name, qw/View V/ );
 566         return map { $c->_filter_component( $_, @args ) } @result if ref $name;
 567         return $c->_filter_component( $result[ 0 ], @args );
 568     }
 569
 570     if (ref $c) {
 571         return $c->stash->{current_view_instance}
 572           if $c->stash->{current_view_instance};
 573         return $c->view( $c->stash->{current_view} )
 574           if $c->stash->{current_view};
 575     }
 576     return $c->view( $c->config->{default_view} )
 577       if $c->config->{default_view};
 578
 579     my( $comp, $rest ) = $c->_comp_search_prefixes( undef, qw/View V/);
 580
 581     if( $rest ) {
 582         $c->log->warn( 'Calling $c->view() will return a random view unless you specify one of:' );
 583         $c->log->warn( '* $c->config->{default_view} # the name of the default view to use' );
 584         $c->log->warn( '* $c->stash->{current_view} # the name of the view to use for this request' );
 585         $c->log->warn( '* $c->stash->{current_view_instance} # the instance of the view to use for this request' );
 586     }
 587
 588     return $c->_filter_component( $comp );
 589 }
 590
 591 =head2 $c->controllers
 592
 593 Returns the available names which can be passed to $c->controller
 594
 595 =cut
 596
 597 sub controllers {
 598     my ( $c ) = @_;
 599     return $c->_comp_names(qw/Controller C/);
 600 }
 601
 602 =head2 $c->models
 603
 604 Returns the available names which can be passed to $c->model
 605
 606 =cut
 607
 608 sub models {
 609     my ( $c ) = @_;
 610     return $c->_comp_names(qw/Model M/);
 611 }
 612
 613
 614 =head2 $c->views
 615
 616 Returns the available names which can be passed to $c->view
 617
 618 =cut
 619
 620 sub views {
 621     my ( $c ) = @_;
 622     return $c->_comp_names(qw/View V/);
 623 }
 624
 625 =head2 $c->comp($name)
 626
 627 =head2 $c->component($name)
 628
 629 Gets a component object by name. This method is not recommended,
 630 unless you want to get a specific component by full
 631 class. C<< $c->controller >>, C<< $c->model >>, and C<< $c->view >>
 632 should be used instead.
 633
 634 =cut
 635
 636 sub component {
 637     my ( $c, $name, @args ) = @_;
 638
 639     if( $name ) {
 640         my $comps = $c->components;
 641
 642         if( !ref $name ) {
 643             # is it the exact name?
 644             return $comps->{ $name } if exists $comps->{ $name };
 645
 646             # perhaps we just omitted "MyApp"?
 647             my $composed = ( ref $c || $c ) . "::${name}";
 648             return $comps->{ $composed } if exists $comps->{ $composed };
 649
 650             # search all of the models, views and controllers
 651             my( $comp ) = $c->_comp_search_prefixes( $name, qw/Model M Controller C View V/ );
 652             return $c->_filter_component( $comp, @args ) if $comp;
 653         }
 654
 655         # This is here so $c->comp( '::M::' ) works
 656         my $query = ref $name ? $name : qr{$name}i;
 657
 658         my @result = grep { m{$query} } keys %{ $c->components };
 659         return @result if ref $name;
 660         return $result[ 0 ] if $result[ 0 ];
 661
 662         # I would expect to return an empty list here, but that breaks back-compat
 663     }
 664
 665     # fallback
 666     return sort keys %{ $c->components };
 667 }
 668
 669 =head2 CLASS DATA AND HELPER CLASSES
 670
 671 =head2 $c->config
 672
 673 Returns or takes a hashref containing the application's configuration.
 674
 675     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 676
 677 You can also use a C<YAML>, C<XML> or C<Config::General> config file
 678 like myapp.yml in your applications home directory. See
 679 L<Catalyst::Plugin::ConfigLoader>.
 680
 681     ---
 682     db: dsn:SQLite:foo.db
 683
 684
 685 =cut
 686
 687 sub config {
 688     my $c = shift;
 689
 690     $c->log->warn("Setting config after setup has been run is not a good idea.")
 691       if ( @_ and $c->setup_finished );
 692
 693     $c->NEXT::config(@_);
 694 }
 695
 696 =head2 $c->log
 697
 698 Returns the logging object instance. Unless it is already set, Catalyst
 699 sets this up with a L<Catalyst::Log> object. To use your own log class,
 700 set the logger with the C<< __PACKAGE__->log >> method prior to calling
 701 C<< __PACKAGE__->setup >>.
 702
 703  __PACKAGE__->log( MyLogger->new );
 704  __PACKAGE__->setup;
 705
 706 And later:
 707
 708     $c->log->info( 'Now logging with my own logger!' );
 709
 710 Your log class should implement the methods described in
 711 L<Catalyst::Log>.
 712
 713
 714 =head2 $c->debug
 715
 716 Overload to enable debug messages (same as -Debug option).
 717
 718 Note that this is a static method, not an accessor and should be overloaded
 719 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 720
 721 =cut
 722
 723 sub debug { 0 }
 724
 725 =head2 $c->dispatcher
 726
 727 Returns the dispatcher instance. Stringifies to class name. See
 728 L<Catalyst::Dispatcher>.
 729
 730 =head2 $c->engine
 731
 732 Returns the engine instance. Stringifies to the class name. See
 733 L<Catalyst::Engine>.
 734
 735
 736 =head2 UTILITY METHODS
 737
 738 =head2 $c->path_to(@path)
 739
 740 Merges C<@path> with C<< $c->config->{home} >> and returns a
 741 L<Path::Class::Dir> object.
 742
 743 For example:
 744
 745     $c->path_to( 'db', 'sqlite.db' );
 746
 747 =cut
 748
 749 sub path_to {
 750     my ( $c, @path ) = @_;
 751     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 752     if ( -d $path ) { return $path }
 753     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 754 }
 755
 756 =head2 $c->plugin( $name, $class, @args )
 757
 758 Helper method for plugins. It creates a classdata accessor/mutator and
 759 loads and instantiates the given class.
 760
 761     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 762
 763     $c->prototype->define_javascript_functions;
 764
 765 =cut
 766
 767 sub plugin {
 768     my ( $class, $name, $plugin, @args ) = @_;
 769     $class->_register_plugin( $plugin, 1 );
 770
 771     eval { $plugin->import };
 772     $class->mk_classdata($name);
 773     my $obj;
 774     eval { $obj = $plugin->new(@args) };
 775
 776     if ($@) {
 777         Catalyst::Exception->throw( message =>
 778               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 779     }
 780
 781     $class->$name($obj);
 782     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 783       if $class->debug;
 784 }
 785
 786 =head2 MyApp->setup
 787
 788 Initializes the dispatcher and engine, loads any plugins, and loads the
 789 model, view, and controller components. You may also specify an array
 790 of plugins to load here, if you choose to not load them in the C<use
 791 Catalyst> line.
 792
 793     MyApp->setup;
 794     MyApp->setup( qw/-Debug/ );
 795
 796 =cut
 797
 798 sub setup {
 799     my ( $class, @arguments ) = @_;
 800
 801     $class->log->warn("Running setup twice is not a good idea.")
 802       if ( $class->setup_finished );
 803
 804     unless ( $class->isa('Catalyst') ) {
 805
 806         Catalyst::Exception->throw(
 807             message => qq/'$class' does not inherit from Catalyst/ );
 808     }
 809
 810     if ( $class->arguments ) {
 811         @arguments = ( @arguments, @{ $class->arguments } );
 812     }
 813
 814     # Process options
 815     my $flags = {};
 816
 817     foreach (@arguments) {
 818
 819         if (/^-Debug$/) {
 820             $flags->{log} =
 821               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 822         }
 823         elsif (/^-(\w+)=?(.*)$/) {
 824             $flags->{ lc $1 } = $2;
 825         }
 826         else {
 827             push @{ $flags->{plugins} }, $_;
 828         }
 829     }
 830
 831     $class->setup_home( delete $flags->{home} );
 832
 833     $class->setup_log( delete $flags->{log} );
 834     $class->setup_plugins( delete $flags->{plugins} );
 835     $class->setup_dispatcher( delete $flags->{dispatcher} );
 836     $class->setup_engine( delete $flags->{engine} );
 837     $class->setup_stats( delete $flags->{stats} );
 838
 839     for my $flag ( sort keys %{$flags} ) {
 840
 841         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 842             &$code( $class, delete $flags->{$flag} );
 843         }
 844         else {
 845             $class->log->warn(qq/Unknown flag "$flag"/);
 846         }
 847     }
 848
 849     eval { require Catalyst::Devel; };
 850     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 851         $class->log->warn(<<"EOF");
 852 You are running an old script!
 853
 854   Please update by running (this will overwrite existing files):
 855     catalyst.pl -force -scripts $class
 856
 857   or (this will not overwrite existing files):
 858     catalyst.pl -scripts $class
 859
 860 EOF
 861     }
 862
 863     if ( $class->debug ) {
 864         my @plugins = map { "$_  " . ( $_->VERSION || '' ) } $class->registered_plugins;
 865
 866         if (@plugins) {
 867             my $t = Text::SimpleTable->new(74);
 868             $t->row($_) for @plugins;
 869             $class->log->debug( "Loaded plugins:\n" . $t->draw . "\n" );
 870         }
 871
 872         my $dispatcher = $class->dispatcher;
 873         my $engine     = $class->engine;
 874         my $home       = $class->config->{home};
 875
 876         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 877         $class->log->debug(qq/Loaded engine "$engine"/);
 878
 879         $home
 880           ? ( -d $home )
 881           ? $class->log->debug(qq/Found home "$home"/)
 882           : $class->log->debug(qq/Home "$home" doesn't exist/)
 883           : $class->log->debug(q/Couldn't find home/);
 884     }
 885
 886     # Call plugins setup
 887     {
 888         no warnings qw/redefine/;
 889         local *setup = sub { };
 890         $class->setup;
 891     }
 892
 893     # Initialize our data structure
 894     $class->components( {} );
 895
 896     $class->setup_components;
 897
 898     if ( $class->debug ) {
 899         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 900         for my $comp ( sort keys %{ $class->components } ) {
 901             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 902             $t->row( $comp, $type );
 903         }
 904         $class->log->debug( "Loaded components:\n" . $t->draw . "\n" )
 905           if ( keys %{ $class->components } );
 906     }
 907
 908     # Add our self to components, since we are also a component
 909     $class->components->{$class} = $class;
 910
 911     $class->setup_actions;
 912
 913     if ( $class->debug ) {
 914         my $name = $class->config->{name} || 'Application';
 915         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 916     }
 917     $class->log->_flush() if $class->log->can('_flush');
 918
 919     $class->setup_finished(1);
 920 }
 921
 922 =head2 $c->uri_for( $path, @args?, \%query_values? )
 923
 924 Merges path with C<< $c->request->base >> for absolute URIs and with
 925 C<< $c->namespace >> for relative URIs, then returns a normalized L<URI>
 926 object. If any args are passed, they are added at the end of the path.
 927 If the last argument to C<uri_for> is a hash reference, it is assumed to
 928 contain GET parameter key/value pairs, which will be appended to the URI
 929 in standard fashion.
 930
 931 Note that uri_for is destructive to the passed hashref.  Subsequent calls
 932 with the same hashref may have unintended results.
 933
 934 Instead of C<$path>, you can also optionally pass a C<$action> object
 935 which will be resolved to a path using
 936 C<< $c->dispatcher->uri_for_action >>; if the first element of
 937 C<@args> is an arrayref it is treated as a list of captures to be passed
 938 to C<uri_for_action>.
 939
 940 =cut
 941
 942 sub uri_for {
 943     my ( $c, $path, @args ) = @_;
 944
 945     if ( Scalar::Util::blessed($path) ) { # action object
 946         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 947                          ? shift(@args)
 948                          : [] );
 949         $path = $c->dispatcher->uri_for_action($path, $captures);
 950         return undef unless defined($path);
 951         $path = '/' if $path eq '';
 952     }
 953
 954     undef($path) if (defined $path && $path eq '');
 955
 956     my $params =
 957       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 958
 959     carp "uri_for called with undef argument" if grep { ! defined $_ } @args;
 960     s/([^$URI::uric])/$URI::Escape::escapes{$1}/go for @args;
 961
 962     unshift(@args, $path);
 963
 964     unless (defined $path && $path =~ s!^/!!) { # in-place strip
 965         my $namespace = $c->namespace;
 966         if (defined $path) { # cheesy hack to handle path '../foo'
 967            $namespace =~ s{(?:^|/)[^/]+$}{} while $args[0] =~ s{^\.\./}{};
 968         }
 969         unshift(@args, $namespace || '');
 970     }
 971
 972     # join args with '/', or a blank string
 973     my $args = join('/', grep { defined($_) } @args);
 974     $args =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
 975     $args =~ s!^/!!;
 976     my $base = $c->req->base;
 977     my $class = ref($base);
 978     $base =~ s{(?<!/)$}{/};
 979
 980     my $query = '';
 981
 982     if (my @keys = keys %$params) {
 983       # somewhat lifted from URI::_query's query_form
 984       $query = '?'.join('&', map {
 985           my $val = $params->{$_};
 986           s/([;\/?:@&=+,\$\[\]%])/$URI::Escape::escapes{$1}/go;
 987           s/ /+/g;
 988           my $key = $_;
 989           $val = '' unless defined $val;
 990           (map {
 991               $_ = "$_";
 992               utf8::encode( $_ ) if utf8::is_utf8($_);
 993               # using the URI::Escape pattern here so utf8 chars survive
 994               s/([^A-Za-z0-9\-_.!~*'() ])/$URI::Escape::escapes{$1}/go;
 995               s/ /+/g;
 996               "${key}=$_"; } ( ref $val eq 'ARRAY' ? @$val : $val ));
 997       } @keys);
 998     }
 999
1000     my $res = bless(\"${base}${args}${query}", $class);
1001     $res;
1002 }
1003
1004 =head2 $c->welcome_message
1005
1006 Returns the Catalyst welcome HTML page.
1007
1008 =cut
1009
1010 sub welcome_message {
1011     my $c      = shift;
1012     my $name   = $c->config->{name};
1013     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
1014     my $prefix = Catalyst::Utils::appprefix( ref $c );
1015     $c->response->content_type('text/html; charset=utf-8');
1016     return <<"EOF";
1017 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
1018     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
1019 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
1020     <head>
1021     <meta http-equiv="Content-Language" content="en" />
1022     <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
1023         <title>$name on Catalyst $VERSION</title>
1024         <style type="text/css">
1025             body {
1026                 color: #000;
1027                 background-color: #eee;
1028             }
1029             div#content {
1030                 width: 640px;
1031                 margin-left: auto;
1032                 margin-right: auto;
1033                 margin-top: 10px;
1034                 margin-bottom: 10px;
1035                 text-align: left;
1036                 background-color: #ccc;
1037                 border: 1px solid #aaa;
1038             }
1039             p, h1, h2 {
1040                 margin-left: 20px;
1041                 margin-right: 20px;
1042                 font-family: verdana, tahoma, sans-serif;
1043             }
1044             a {
1045                 font-family: verdana, tahoma, sans-serif;
1046             }
1047             :link, :visited {
1048                     text-decoration: none;
1049                     color: #b00;
1050                     border-bottom: 1px dotted #bbb;
1051             }
1052             :link:hover, :visited:hover {
1053                     color: #555;
1054             }
1055             div#topbar {
1056                 margin: 0px;
1057             }
1058             pre {
1059                 margin: 10px;
1060                 padding: 8px;
1061             }
1062             div#answers {
1063                 padding: 8px;
1064                 margin: 10px;
1065                 background-color: #fff;
1066                 border: 1px solid #aaa;
1067             }
1068             h1 {
1069                 font-size: 0.9em;
1070                 font-weight: normal;
1071                 text-align: center;
1072             }
1073             h2 {
1074                 font-size: 1.0em;
1075             }
1076             p {
1077                 font-size: 0.9em;
1078             }
1079             p img {
1080                 float: right;
1081                 margin-left: 10px;
1082             }
1083             span#appname {
1084                 font-weight: bold;
1085                 font-size: 1.6em;
1086             }
1087         </style>
1088     </head>
1089     <body>
1090         <div id="content">
1091             <div id="topbar">
1092                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1093                     $VERSION</h1>
1094              </div>
1095              <div id="answers">
1096                  <p>
1097                  <img src="$logo" alt="Catalyst Logo" />
1098                  </p>
1099                  <p>Welcome to the  world of Catalyst.
1100                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1101                     framework will make web development something you had
1102                     never expected it to be: Fun, rewarding, and quick.</p>
1103                  <h2>What to do now?</h2>
1104                  <p>That really depends  on what <b>you</b> want to do.
1105                     We do, however, provide you with a few starting points.</p>
1106                  <p>If you want to jump right into web development with Catalyst
1107                     you might want to start with a tutorial.</p>
1108 <pre>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1109 </pre>
1110 <p>Afterwards you can go on to check out a more complete look at our features.</p>
1111 <pre>
1112 <code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst-Manual/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1113 <!-- Something else should go here, but the Catalyst::Manual link seems unhelpful -->
1114 </code></pre>
1115                  <h2>What to do next?</h2>
1116                  <p>Next it's time to write an actual application. Use the
1117                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1118                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1119                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1120                     they can save you a lot of work.</p>
1121                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1122                     <p>Also, be sure to check out the vast and growing
1123                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1124                     you are likely to find what you need there.
1125                     </p>
1126
1127                  <h2>Need help?</h2>
1128                  <p>Catalyst has a very active community. Here are the main places to
1129                     get in touch with us.</p>
1130                  <ul>
1131                      <li>
1132                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1133                      </li>
1134                      <li>
1135                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1136                      </li>
1137                      <li>
1138                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1139                      </li>
1140                  </ul>
1141                  <h2>In conclusion</h2>
1142                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1143                     as we enjoyed making it. Please contact us if you have ideas
1144                     for improvement or other feedback.</p>
1145              </div>
1146          </div>
1147     </body>
1148 </html>
1149 EOF
1150 }
1151
1152 =head1 INTERNAL METHODS
1153
1154 These methods are not meant to be used by end users.
1155
1156 =head2 $c->components
1157
1158 Returns a hash of components.
1159
1160 =head2 $c->context_class
1161
1162 Returns or sets the context class.
1163
1164 =head2 $c->counter
1165
1166 Returns a hashref containing coderefs and execution counts (needed for
1167 deep recursion detection).
1168
1169 =head2 $c->depth
1170
1171 Returns the number of actions on the current internal execution stack.
1172
1173 =head2 $c->dispatch
1174
1175 Dispatches a request to actions.
1176
1177 =cut
1178
1179 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1180
1181 =head2 $c->dispatcher_class
1182
1183 Returns or sets the dispatcher class.
1184
1185 =head2 $c->dump_these
1186
1187 Returns a list of 2-element array references (name, structure) pairs
1188 that will be dumped on the error page in debug mode.
1189
1190 =cut
1191
1192 sub dump_these {
1193     my $c = shift;
1194     [ Request => $c->req ],
1195     [ Response => $c->res ],
1196     [ Stash => $c->stash ],
1197     [ Config => $c->config ];
1198 }
1199
1200 =head2 $c->engine_class
1201
1202 Returns or sets the engine class.
1203
1204 =head2 $c->execute( $class, $coderef )
1205
1206 Execute a coderef in given class and catch exceptions. Errors are available
1207 via $c->error.
1208
1209 =cut
1210
1211 sub execute {
1212     my ( $c, $class, $code ) = @_;
1213     $class = $c->component($class) || $class;
1214     $c->state(0);
1215
1216     if ( $c->depth >= $RECURSION ) {
1217         my $action = "$code";
1218         $action = "/$action" unless $action =~ /->/;
1219         my $error = qq/Deep recursion detected calling "$action"/;
1220         $c->log->error($error);
1221         $c->error($error);
1222         $c->state(0);
1223         return $c->state;
1224     }
1225
1226     my $stats_info = $c->_stats_start_execute( $code ) if $c->use_stats;
1227
1228     push( @{ $c->stack }, $code );
1229
1230     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1231
1232     $c->_stats_finish_execute( $stats_info ) if $c->use_stats and $stats_info;
1233
1234     my $last = pop( @{ $c->stack } );
1235
1236     if ( my $error = $@ ) {
1237         if ( !ref($error) and $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1238         else {
1239             unless ( ref $error ) {
1240                 no warnings 'uninitialized';
1241                 chomp $error;
1242                 my $class = $last->class;
1243                 my $name  = $last->name;
1244                 $error = qq/Caught exception in $class->$name "$error"/;
1245             }
1246             $c->error($error);
1247             $c->state(0);
1248         }
1249     }
1250     return $c->state;
1251 }
1252
1253 sub _stats_start_execute {
1254     my ( $c, $code ) = @_;
1255
1256     return if ( ( $code->name =~ /^_.*/ )
1257         && ( !$c->config->{show_internal_actions} ) );
1258
1259     $c->counter->{"$code"}++;
1260
1261     my $action = "$code";
1262     $action = "/$action" unless $action =~ /->/;
1263
1264     # determine if the call was the result of a forward
1265     # this is done by walking up the call stack and looking for a calling
1266     # sub of Catalyst::forward before the eval
1267     my $callsub = q{};
1268     for my $index ( 2 .. 11 ) {
1269         last
1270         if ( ( caller($index) )[0] eq 'Catalyst'
1271             && ( caller($index) )[3] eq '(eval)' );
1272
1273         if ( ( caller($index) )[3] =~ /forward$/ ) {
1274             $callsub = ( caller($index) )[3];
1275             $action  = "-> $action";
1276             last;
1277         }
1278     }
1279
1280     my $uid = "$code" . $c->counter->{"$code"};
1281
1282     # is this a root-level call or a forwarded call?
1283     if ( $callsub =~ /forward$/ ) {
1284
1285         # forward, locate the caller
1286         if ( my $parent = $c->stack->[-1] ) {
1287             $c->stats->profile(
1288                 begin  => $action,
1289                 parent => "$parent" . $c->counter->{"$parent"},
1290                 uid    => $uid,
1291             );
1292         }
1293         else {
1294
1295             # forward with no caller may come from a plugin
1296             $c->stats->profile(
1297                 begin => $action,
1298                 uid   => $uid,
1299             );
1300         }
1301     }
1302     else {
1303
1304         # root-level call
1305         $c->stats->profile(
1306             begin => $action,
1307             uid   => $uid,
1308         );
1309     }
1310     return $action;
1311
1312 }
1313
1314 sub _stats_finish_execute {
1315     my ( $c, $info ) = @_;
1316     $c->stats->profile( end => $info );
1317 }
1318
1319 =head2 $c->_localize_fields( sub { }, \%keys );
1320
1321 =cut
1322
1323 sub _localize_fields {
1324     my ( $c, $localized, $code ) = ( @_ );
1325
1326     my $request = delete $localized->{request} || {};
1327     my $response = delete $localized->{response} || {};
1328
1329     local @{ $c }{ keys %$localized } = values %$localized;
1330     local @{ $c->request }{ keys %$request } = values %$request;
1331     local @{ $c->response }{ keys %$response } = values %$response;
1332
1333     $code->();
1334 }
1335
1336 =head2 $c->finalize
1337
1338 Finalizes the request.
1339
1340 =cut
1341
1342 sub finalize {
1343     my $c = shift;
1344
1345     for my $error ( @{ $c->error } ) {
1346         $c->log->error($error);
1347     }
1348
1349     # Allow engine to handle finalize flow (for POE)
1350     if ( $c->engine->can('finalize') ) {
1351         $c->engine->finalize($c);
1352     }
1353     else {
1354
1355         $c->finalize_uploads;
1356
1357         # Error
1358         if ( $#{ $c->error } >= 0 ) {
1359             $c->finalize_error;
1360         }
1361
1362         $c->finalize_headers;
1363
1364         # HEAD request
1365         if ( $c->request->method eq 'HEAD' ) {
1366             $c->response->body('');
1367         }
1368
1369         $c->finalize_body;
1370     }
1371
1372     if ($c->use_stats) {
1373         my $elapsed = sprintf '%f', $c->stats->elapsed;
1374         my $av = $elapsed == 0 ? '??' : sprintf '%.3f', 1 / $elapsed;
1375         $c->log->info(
1376             "Request took ${elapsed}s ($av/s)\n" . $c->stats->report . "\n" );
1377     }
1378
1379     return $c->response->status;
1380 }
1381
1382 =head2 $c->finalize_body
1383
1384 Finalizes body.
1385
1386 =cut
1387
1388 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1389
1390 =head2 $c->finalize_cookies
1391
1392 Finalizes cookies.
1393
1394 =cut
1395
1396 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1397
1398 =head2 $c->finalize_error
1399
1400 Finalizes error.
1401
1402 =cut
1403
1404 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1405
1406 =head2 $c->finalize_headers
1407
1408 Finalizes headers.
1409
1410 =cut
1411
1412 sub finalize_headers {
1413     my $c = shift;
1414
1415     # Check if we already finalized headers
1416     return if $c->response->{_finalized_headers};
1417
1418     # Handle redirects
1419     if ( my $location = $c->response->redirect ) {
1420         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1421         $c->response->header( Location => $location );
1422
1423         if ( !$c->response->body ) {
1424             # Add a default body if none is already present
1425             $c->response->body(
1426                 qq{<html><body><p>This item has moved <a href="$location">here</a>.</p></body></html>}
1427             );
1428         }
1429     }
1430
1431     # Content-Length
1432     if ( $c->response->body && !$c->response->content_length ) {
1433
1434         # get the length from a filehandle
1435         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1436         {
1437             my $stat = stat $c->response->body;
1438             if ( $stat && $stat->size > 0 ) {
1439                 $c->response->content_length( $stat->size );
1440             }
1441             else {
1442                 $c->log->warn('Serving filehandle without a content-length');
1443             }
1444         }
1445         else {
1446             # everything should be bytes at this point, but just in case
1447             $c->response->content_length( bytes::length( $c->response->body ) );
1448         }
1449     }
1450
1451     # Errors
1452     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1453         $c->response->headers->remove_header("Content-Length");
1454         $c->response->body('');
1455     }
1456
1457     $c->finalize_cookies;
1458
1459     $c->engine->finalize_headers( $c, @_ );
1460
1461     # Done
1462     $c->response->{_finalized_headers} = 1;
1463 }
1464
1465 =head2 $c->finalize_output
1466
1467 An alias for finalize_body.
1468
1469 =head2 $c->finalize_read
1470
1471 Finalizes the input after reading is complete.
1472
1473 =cut
1474
1475 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1476
1477 =head2 $c->finalize_uploads
1478
1479 Finalizes uploads. Cleans up any temporary files.
1480
1481 =cut
1482
1483 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1484
1485 =head2 $c->get_action( $action, $namespace )
1486
1487 Gets an action in a given namespace.
1488
1489 =cut
1490
1491 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1492
1493 =head2 $c->get_actions( $action, $namespace )
1494
1495 Gets all actions of a given name in a namespace and all parent
1496 namespaces.
1497
1498 =cut
1499
1500 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1501
1502 =head2 $c->handle_request( $class, @arguments )
1503
1504 Called to handle each HTTP request.
1505
1506 =cut
1507
1508 sub handle_request {
1509     my ( $class, @arguments ) = @_;
1510
1511     # Always expect worst case!
1512     my $status = -1;
1513     eval {
1514         if ($class->debug) {
1515             my $secs = time - $START || 1;
1516             my $av = sprintf '%.3f', $COUNT / $secs;
1517             my $time = localtime time;
1518             $class->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1519         }
1520
1521         my $c = $class->prepare(@arguments);
1522         $c->dispatch;
1523         $status = $c->finalize;
1524     };
1525
1526     if ( my $error = $@ ) {
1527         chomp $error;
1528         $class->log->error(qq/Caught exception in engine "$error"/);
1529     }
1530
1531     $COUNT++;
1532     $class->log->_flush() if $class->log->can('_flush');
1533     return $status;
1534 }
1535
1536 =head2 $c->prepare( @arguments )
1537
1538 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1539 etc.).
1540
1541 =cut
1542
1543 sub prepare {
1544     my ( $class, @arguments ) = @_;
1545
1546     $class->context_class( ref $class || $class ) unless $class->context_class;
1547     my $c = $class->context_class->new(
1548         {
1549             counter => {},
1550             stack   => [],
1551             request => $class->request_class->new(
1552                 {
1553                     arguments        => [],
1554                     body_parameters  => {},
1555                     cookies          => {},
1556                     headers          => HTTP::Headers->new,
1557                     parameters       => {},
1558                     query_parameters => {},
1559                     secure           => 0,
1560                     captures         => [],
1561                     uploads          => {}
1562                 }
1563             ),
1564             response => $class->response_class->new(
1565                 {
1566                     body    => '',
1567                     cookies => {},
1568                     headers => HTTP::Headers->new(),
1569                     status  => 200
1570                 }
1571             ),
1572             stash => {},
1573             state => 0
1574         }
1575     );
1576
1577     $c->stats($class->stats_class->new)->enable($c->use_stats);
1578     if ( $c->debug ) {
1579         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1580     }
1581
1582     # For on-demand data
1583     $c->request->{_context}  = $c;
1584     $c->response->{_context} = $c;
1585     weaken( $c->request->{_context} );
1586     weaken( $c->response->{_context} );
1587
1588     # Allow engine to direct the prepare flow (for POE)
1589     if ( $c->engine->can('prepare') ) {
1590         $c->engine->prepare( $c, @arguments );
1591     }
1592     else {
1593         $c->prepare_request(@arguments);
1594         $c->prepare_connection;
1595         $c->prepare_query_parameters;
1596         $c->prepare_headers;
1597         $c->prepare_cookies;
1598         $c->prepare_path;
1599
1600         # Prepare the body for reading, either by prepare_body
1601         # or the user, if they are using $c->read
1602         $c->prepare_read;
1603
1604         # Parse the body unless the user wants it on-demand
1605         unless ( $c->config->{parse_on_demand} ) {
1606             $c->prepare_body;
1607         }
1608     }
1609
1610     my $method  = $c->req->method  || '';
1611     my $path    = $c->req->path;
1612     $path       = '/' unless length $path;
1613     my $address = $c->req->address || '';
1614
1615     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1616       if $c->debug;
1617
1618     $c->prepare_action;
1619
1620     return $c;
1621 }
1622
1623 =head2 $c->prepare_action
1624
1625 Prepares action. See L<Catalyst::Dispatcher>.
1626
1627 =cut
1628
1629 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1630
1631 =head2 $c->prepare_body
1632
1633 Prepares message body.
1634
1635 =cut
1636
1637 sub prepare_body {
1638     my $c = shift;
1639
1640     # Do we run for the first time?
1641     return if defined $c->request->{_body};
1642
1643     # Initialize on-demand data
1644     $c->engine->prepare_body( $c, @_ );
1645     $c->prepare_parameters;
1646     $c->prepare_uploads;
1647
1648     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1649         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1650         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1651             my $param = $c->req->body_parameters->{$key};
1652             my $value = defined($param) ? $param : '';
1653             $t->row( $key,
1654                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1655         }
1656         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1657     }
1658 }
1659
1660 =head2 $c->prepare_body_chunk( $chunk )
1661
1662 Prepares a chunk of data before sending it to L<HTTP::Body>.
1663
1664 See L<Catalyst::Engine>.
1665
1666 =cut
1667
1668 sub prepare_body_chunk {
1669     my $c = shift;
1670     $c->engine->prepare_body_chunk( $c, @_ );
1671 }
1672
1673 =head2 $c->prepare_body_parameters
1674
1675 Prepares body parameters.
1676
1677 =cut
1678
1679 sub prepare_body_parameters {
1680     my $c = shift;
1681     $c->engine->prepare_body_parameters( $c, @_ );
1682 }
1683
1684 =head2 $c->prepare_connection
1685
1686 Prepares connection.
1687
1688 =cut
1689
1690 sub prepare_connection {
1691     my $c = shift;
1692     $c->engine->prepare_connection( $c, @_ );
1693 }
1694
1695 =head2 $c->prepare_cookies
1696
1697 Prepares cookies.
1698
1699 =cut
1700
1701 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1702
1703 =head2 $c->prepare_headers
1704
1705 Prepares headers.
1706
1707 =cut
1708
1709 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1710
1711 =head2 $c->prepare_parameters
1712
1713 Prepares parameters.
1714
1715 =cut
1716
1717 sub prepare_parameters {
1718     my $c = shift;
1719     $c->prepare_body_parameters;
1720     $c->engine->prepare_parameters( $c, @_ );
1721 }
1722
1723 =head2 $c->prepare_path
1724
1725 Prepares path and base.
1726
1727 =cut
1728
1729 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1730
1731 =head2 $c->prepare_query_parameters
1732
1733 Prepares query parameters.
1734
1735 =cut
1736
1737 sub prepare_query_parameters {
1738     my $c = shift;
1739
1740     $c->engine->prepare_query_parameters( $c, @_ );
1741
1742     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1743         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1744         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1745             my $param = $c->req->query_parameters->{$key};
1746             my $value = defined($param) ? $param : '';
1747             $t->row( $key,
1748                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1749         }
1750         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1751     }
1752 }
1753
1754 =head2 $c->prepare_read
1755
1756 Prepares the input for reading.
1757
1758 =cut
1759
1760 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1761
1762 =head2 $c->prepare_request
1763
1764 Prepares the engine request.
1765
1766 =cut
1767
1768 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1769
1770 =head2 $c->prepare_uploads
1771
1772 Prepares uploads.
1773
1774 =cut
1775
1776 sub prepare_uploads {
1777     my $c = shift;
1778
1779     $c->engine->prepare_uploads( $c, @_ );
1780
1781     if ( $c->debug && keys %{ $c->request->uploads } ) {
1782         my $t = Text::SimpleTable->new(
1783             [ 12, 'Parameter' ],
1784             [ 26, 'Filename' ],
1785             [ 18, 'Type' ],
1786             [ 9,  'Size' ]
1787         );
1788         for my $key ( sort keys %{ $c->request->uploads } ) {
1789             my $upload = $c->request->uploads->{$key};
1790             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1791                 $t->row( $key, $u->filename, $u->type, $u->size );
1792             }
1793         }
1794         $c->log->debug( "File Uploads are:\n" . $t->draw );
1795     }
1796 }
1797
1798 =head2 $c->prepare_write
1799
1800 Prepares the output for writing.
1801
1802 =cut
1803
1804 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1805
1806 =head2 $c->request_class
1807
1808 Returns or sets the request class.
1809
1810 =head2 $c->response_class
1811
1812 Returns or sets the response class.
1813
1814 =head2 $c->read( [$maxlength] )
1815
1816 Reads a chunk of data from the request body. This method is designed to
1817 be used in a while loop, reading C<$maxlength> bytes on every call.
1818 C<$maxlength> defaults to the size of the request if not specified.
1819
1820 You have to set C<< MyApp->config->{parse_on_demand} >> to use this
1821 directly.
1822
1823 Warning: If you use read(), Catalyst will not process the body,
1824 so you will not be able to access POST parameters or file uploads via
1825 $c->request.  You must handle all body parsing yourself.
1826
1827 =cut
1828
1829 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1830
1831 =head2 $c->run
1832
1833 Starts the engine.
1834
1835 =cut
1836
1837 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1838
1839 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1840
1841 Sets an action in a given namespace.
1842
1843 =cut
1844
1845 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1846
1847 =head2 $c->setup_actions($component)
1848
1849 Sets up actions for a component.
1850
1851 =cut
1852
1853 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1854
1855 =head2 $c->setup_components
1856
1857 Sets up components. Specify a C<setup_components> config option to pass
1858 additional options directly to L<Module::Pluggable>. To add additional
1859 search paths, specify a key named C<search_extra> as an array
1860 reference. Items in the array beginning with C<::> will have the
1861 application class name prepended to them.
1862
1863 =cut
1864
1865 sub setup_components {
1866     my $class = shift;
1867
1868     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1869     my $config  = $class->config->{ setup_components };
1870     my $extra   = delete $config->{ search_extra } || [];
1871
1872     push @paths, @$extra;
1873
1874     my $locator = Module::Pluggable::Object->new(
1875         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1876         %$config
1877     );
1878
1879     my @comps = sort { length $a <=> length $b } $locator->plugins;
1880     my %comps = map { $_ => 1 } @comps;
1881
1882     for my $component ( @comps ) {
1883
1884         # We pass ignore_loaded here so that overlay files for (e.g.)
1885         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
1886         # we know M::P::O found a file on disk so this is safe
1887
1888         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
1889
1890         my $module  = $class->setup_component( $component );
1891         my %modules = (
1892             $component => $module,
1893             map {
1894                 $_ => $class->setup_component( $_ )
1895             } grep {
1896               not exists $comps{$_}
1897             } Devel::InnerPackage::list_packages( $component )
1898         );
1899
1900         for my $key ( keys %modules ) {
1901             $class->components->{ $key } = $modules{ $key };
1902         }
1903     }
1904 }
1905
1906 =head2 $c->setup_component
1907
1908 =cut
1909
1910 sub setup_component {
1911     my( $class, $component ) = @_;
1912
1913     unless ( $component->can( 'COMPONENT' ) ) {
1914         return $component;
1915     }
1916
1917     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1918     my $config = $class->config->{ $suffix } || {};
1919
1920     my $instance = eval { $component->COMPONENT( $class, $config ); };
1921
1922     if ( my $error = $@ ) {
1923         chomp $error;
1924         Catalyst::Exception->throw(
1925             message => qq/Couldn't instantiate component "$component", "$error"/
1926         );
1927     }
1928
1929     Catalyst::Exception->throw(
1930         message =>
1931         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1932     ) unless eval { $instance->can( 'can' ) };
1933
1934     return $instance;
1935 }
1936
1937 =head2 $c->setup_dispatcher
1938
1939 Sets up dispatcher.
1940
1941 =cut
1942
1943 sub setup_dispatcher {
1944     my ( $class, $dispatcher ) = @_;
1945
1946     if ($dispatcher) {
1947         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1948     }
1949
1950     if ( my $env = Catalyst::Utils::env_value( $class, 'DISPATCHER' ) ) {
1951         $dispatcher = 'Catalyst::Dispatcher::' . $env;
1952     }
1953
1954     unless ($dispatcher) {
1955         $dispatcher = $class->dispatcher_class;
1956     }
1957
1958     unless (Class::Inspector->loaded($dispatcher)) {
1959         require Class::Inspector->filename($dispatcher);
1960     }
1961
1962     # dispatcher instance
1963     $class->dispatcher( $dispatcher->new );
1964 }
1965
1966 =head2 $c->setup_engine
1967
1968 Sets up engine.
1969
1970 =cut
1971
1972 sub setup_engine {
1973     my ( $class, $engine ) = @_;
1974
1975     if ($engine) {
1976         $engine = 'Catalyst::Engine::' . $engine;
1977     }
1978
1979     if ( my $env = Catalyst::Utils::env_value( $class, 'ENGINE' ) ) {
1980         $engine = 'Catalyst::Engine::' . $env;
1981     }
1982
1983     if ( $ENV{MOD_PERL} ) {
1984
1985         # create the apache method
1986         {
1987             no strict 'refs';
1988             *{"$class\::apache"} = sub { shift->engine->apache };
1989         }
1990
1991         my ( $software, $version ) =
1992           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1993
1994         $version =~ s/_//g;
1995         $version =~ s/(\.[^.]+)\./$1/g;
1996
1997         if ( $software eq 'mod_perl' ) {
1998
1999             if ( !$engine ) {
2000
2001                 if ( $version >= 1.99922 ) {
2002                     $engine = 'Catalyst::Engine::Apache2::MP20';
2003                 }
2004
2005                 elsif ( $version >= 1.9901 ) {
2006                     $engine = 'Catalyst::Engine::Apache2::MP19';
2007                 }
2008
2009                 elsif ( $version >= 1.24 ) {
2010                     $engine = 'Catalyst::Engine::Apache::MP13';
2011                 }
2012
2013                 else {
2014                     Catalyst::Exception->throw( message =>
2015                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
2016                 }
2017
2018             }
2019
2020             # install the correct mod_perl handler
2021             if ( $version >= 1.9901 ) {
2022                 *handler = sub  : method {
2023                     shift->handle_request(@_);
2024                 };
2025             }
2026             else {
2027                 *handler = sub ($$) { shift->handle_request(@_) };
2028             }
2029
2030         }
2031
2032         elsif ( $software eq 'Zeus-Perl' ) {
2033             $engine = 'Catalyst::Engine::Zeus';
2034         }
2035
2036         else {
2037             Catalyst::Exception->throw(
2038                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
2039         }
2040     }
2041
2042     unless ($engine) {
2043         $engine = $class->engine_class;
2044     }
2045
2046     unless (Class::Inspector->loaded($engine)) {
2047         require Class::Inspector->filename($engine);
2048     }
2049
2050     # check for old engines that are no longer compatible
2051     my $old_engine;
2052     if ( $engine->isa('Catalyst::Engine::Apache')
2053         && !Catalyst::Engine::Apache->VERSION )
2054     {
2055         $old_engine = 1;
2056     }
2057
2058     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2059         && Catalyst::Engine::Server->VERSION le '0.02' )
2060     {
2061         $old_engine = 1;
2062     }
2063
2064     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2065         && $engine->VERSION eq '0.01' )
2066     {
2067         $old_engine = 1;
2068     }
2069
2070     elsif ($engine->isa('Catalyst::Engine::Zeus')
2071         && $engine->VERSION eq '0.01' )
2072     {
2073         $old_engine = 1;
2074     }
2075
2076     if ($old_engine) {
2077         Catalyst::Exception->throw( message =>
2078               qq/Engine "$engine" is not supported by this version of Catalyst/
2079         );
2080     }
2081
2082     # engine instance
2083     $class->engine( $engine->new );
2084 }
2085
2086 =head2 $c->setup_home
2087
2088 Sets up the home directory.
2089
2090 =cut
2091
2092 sub setup_home {
2093     my ( $class, $home ) = @_;
2094
2095     if ( my $env = Catalyst::Utils::env_value( $class, 'HOME' ) ) {
2096         $home = $env;
2097     }
2098
2099     unless ($home) {
2100         $home = Catalyst::Utils::home($class);
2101     }
2102
2103     if ($home) {
2104         $class->config->{home} ||= $home;
2105         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2106     }
2107 }
2108
2109 =head2 $c->setup_log
2110
2111 Sets up log.
2112
2113 =cut
2114
2115 sub setup_log {
2116     my ( $class, $debug ) = @_;
2117
2118     unless ( $class->log ) {
2119         $class->log( Catalyst::Log->new );
2120     }
2121
2122     my $env_debug = Catalyst::Utils::env_value( $class, 'DEBUG' );
2123     if ( defined($env_debug) ? $env_debug : $debug ) {
2124         no strict 'refs';
2125         *{"$class\::debug"} = sub { 1 };
2126         $class->log->debug('Debug messages enabled');
2127     }
2128 }
2129
2130 =head2 $c->setup_plugins
2131
2132 Sets up plugins.
2133
2134 =cut
2135
2136 =head2 $c->setup_stats
2137
2138 Sets up timing statistics class.
2139
2140 =cut
2141
2142 sub setup_stats {
2143     my ( $class, $stats ) = @_;
2144
2145     Catalyst::Utils::ensure_class_loaded($class->stats_class);
2146
2147     my $env = Catalyst::Utils::env_value( $class, 'STATS' );
2148     if ( defined($env) ? $env : ($stats || $class->debug ) ) {
2149         no strict 'refs';
2150         *{"$class\::use_stats"} = sub { 1 };
2151         $class->log->debug('Statistics enabled');
2152     }
2153 }
2154
2155
2156 =head2 $c->registered_plugins
2157
2158 Returns a sorted list of the plugins which have either been stated in the
2159 import list or which have been added via C<< MyApp->plugin(@args); >>.
2160
2161 If passed a given plugin name, it will report a boolean value indicating
2162 whether or not that plugin is loaded.  A fully qualified name is required if
2163 the plugin name does not begin with C<Catalyst::Plugin::>.
2164
2165  if ($c->registered_plugins('Some::Plugin')) {
2166      ...
2167  }
2168
2169 =cut
2170
2171 {
2172
2173     sub registered_plugins {
2174         my $proto = shift;
2175         return sort keys %{ $proto->_plugins } unless @_;
2176         my $plugin = shift;
2177         return 1 if exists $proto->_plugins->{$plugin};
2178         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2179     }
2180
2181     sub _register_plugin {
2182         my ( $proto, $plugin, $instant ) = @_;
2183         my $class = ref $proto || $proto;
2184
2185         # no ignore_loaded here, the plugin may already have been
2186         # defined in memory and we don't want to error on "no file" if so
2187
2188         Catalyst::Utils::ensure_class_loaded( $plugin );
2189
2190         $proto->_plugins->{$plugin} = 1;
2191         unless ($instant) {
2192             no strict 'refs';
2193             unshift @{"$class\::ISA"}, $plugin;
2194         }
2195         return $class;
2196     }
2197
2198     sub setup_plugins {
2199         my ( $class, $plugins ) = @_;
2200
2201         $class->_plugins( {} ) unless $class->_plugins;
2202         $plugins ||= [];
2203         for my $plugin ( reverse @$plugins ) {
2204
2205             unless ( $plugin =~ s/\A\+// ) {
2206                 $plugin = "Catalyst::Plugin::$plugin";
2207             }
2208
2209             $class->_register_plugin($plugin);
2210         }
2211     }
2212 }
2213
2214 =head2 $c->stack
2215
2216 Returns an arrayref of the internal execution stack (actions that are
2217 currently executing).
2218
2219 =head2 $c->stats_class
2220
2221 Returns or sets the stats (timing statistics) class.
2222
2223 =head2 $c->use_stats
2224
2225 Returns 1 when stats collection is enabled.  Stats collection is enabled
2226 when the -Stats options is set, debug is on or when the <MYAPP>_STATS
2227 environment variable is set.
2228
2229 Note that this is a static method, not an accessor and should be overloaded
2230 by declaring "sub use_stats { 1 }" in your MyApp.pm, not by calling $c->use_stats(1).
2231
2232 =cut
2233
2234 sub use_stats { 0 }
2235
2236
2237 =head2 $c->write( $data )
2238
2239 Writes $data to the output stream. When using this method directly, you
2240 will need to manually set the C<Content-Length> header to the length of
2241 your output data, if known.
2242
2243 =cut
2244
2245 sub write {
2246     my $c = shift;
2247
2248     # Finalize headers if someone manually writes output
2249     $c->finalize_headers;
2250
2251     return $c->engine->write( $c, @_ );
2252 }
2253
2254 =head2 version
2255
2256 Returns the Catalyst version number. Mostly useful for "powered by"
2257 messages in template systems.
2258
2259 =cut
2260
2261 sub version { return $Catalyst::VERSION }
2262
2263 =head1 INTERNAL ACTIONS
2264
2265 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2266 C<_ACTION>, and C<_END>. These are by default not shown in the private
2267 action table, but you can make them visible with a config parameter.
2268
2269     MyApp->config->{show_internal_actions} = 1;
2270
2271 =head1 CASE SENSITIVITY
2272
2273 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2274 mapped to C</foo/bar>. You can activate case sensitivity with a config
2275 parameter.
2276
2277     MyApp->config->{case_sensitive} = 1;
2278
2279 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2280
2281 =head1 ON-DEMAND PARSER
2282
2283 The request body is usually parsed at the beginning of a request,
2284 but if you want to handle input yourself, you can enable on-demand
2285 parsing with a config parameter.
2286
2287     MyApp->config->{parse_on_demand} = 1;
2288
2289 =head1 PROXY SUPPORT
2290
2291 Many production servers operate using the common double-server approach,
2292 with a lightweight frontend web server passing requests to a larger
2293 backend server. An application running on the backend server must deal
2294 with two problems: the remote user always appears to be C<127.0.0.1> and
2295 the server's hostname will appear to be C<localhost> regardless of the
2296 virtual host that the user connected through.
2297
2298 Catalyst will automatically detect this situation when you are running
2299 the frontend and backend servers on the same machine. The following
2300 changes are made to the request.
2301
2302     $c->req->address is set to the user's real IP address, as read from
2303     the HTTP X-Forwarded-For header.
2304
2305     The host value for $c->req->base and $c->req->uri is set to the real
2306     host, as read from the HTTP X-Forwarded-Host header.
2307
2308 Obviously, your web server must support these headers for this to work.
2309
2310 In a more complex server farm environment where you may have your
2311 frontend proxy server(s) on different machines, you will need to set a
2312 configuration option to tell Catalyst to read the proxied data from the
2313 headers.
2314
2315     MyApp->config->{using_frontend_proxy} = 1;
2316
2317 If you do not wish to use the proxy support at all, you may set:
2318
2319     MyApp->config->{ignore_frontend_proxy} = 1;
2320
2321 =head1 THREAD SAFETY
2322
2323 Catalyst has been tested under Apache 2's threading C<mpm_worker>,
2324 C<mpm_winnt>, and the standalone forking HTTP server on Windows. We
2325 believe the Catalyst core to be thread-safe.
2326
2327 If you plan to operate in a threaded environment, remember that all other
2328 modules you are using must also be thread-safe. Some modules, most notably
2329 L<DBD::SQLite>, are not thread-safe.
2330
2331 =head1 SUPPORT
2332
2333 IRC:
2334
2335     Join #catalyst on irc.perl.org.
2336
2337 Mailing Lists:
2338
2339     http://lists.rawmode.org/mailman/listinfo/catalyst
2340     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2341
2342 Web:
2343
2344     http://catalyst.perl.org
2345
2346 Wiki:
2347
2348     http://dev.catalyst.perl.org
2349
2350 =head1 SEE ALSO
2351
2352 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2353
2354 =head2 L<Catalyst::Manual> - The Catalyst Manual
2355
2356 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2357
2358 =head2 L<Catalyst::Engine> - Core engine
2359
2360 =head2 L<Catalyst::Log> - Log class.
2361
2362 =head2 L<Catalyst::Request> - Request object
2363
2364 =head2 L<Catalyst::Response> - Response object
2365
2366 =head2 L<Catalyst::Test> - The test suite.
2367
2368 =head1 CREDITS
2369
2370 Andy Grundman
2371
2372 Andy Wardley
2373
2374 Andreas Marienborg
2375
2376 Andrew Bramble
2377
2378 Andrew Ford
2379
2380 Andrew Ruthven
2381
2382 Arthur Bergman
2383
2384 Autrijus Tang
2385
2386 Brian Cassidy
2387
2388 Carl Franks
2389
2390 Christian Hansen
2391
2392 Christopher Hicks
2393
2394 Dan Sully
2395
2396 Danijel Milicevic
2397
2398 David Kamholz
2399
2400 David Naughton
2401
2402 Drew Taylor
2403
2404 Gary Ashton Jones
2405
2406 Geoff Richards
2407
2408 Jesse Sheidlower
2409
2410 Jesse Vincent
2411
2412 Jody Belka
2413
2414 Johan Lindstrom
2415
2416 Juan Camacho
2417
2418 Leon Brocard
2419
2420 Marcus Ramberg
2421
2422 Matt S Trout
2423
2424 Robert Sedlacek
2425
2426 Sam Vilain
2427
2428 Sascha Kiefer
2429
2430 Sebastian Willert
2431
2432 Tatsuhiko Miyagawa
2433
2434 Ulf Edvinsson
2435
2436 Yuval Kogman
2437
2438 =head1 AUTHOR
2439
2440 Sebastian Riedel, C<sri@oook.de>
2441
2442 =head1 LICENSE
2443
2444 This library is free software, you can redistribute it and/or modify it under
2445 the same terms as Perl itself.
2446
2447 =cut
2448
2449 1;