lib/Catalyst.pm

   1 package Catalyst;
   2
   3 use strict;
   4 use base 'Catalyst::Component';
   5 use bytes;
   6 use Catalyst::Exception;
   7 use Catalyst::Log;
   8 use Catalyst::Request;
   9 use Catalyst::Request::Upload;
  10 use Catalyst::Response;
  11 use Catalyst::Utils;
  12 use Catalyst::Controller;
  13 use Devel::InnerPackage ();
  14 use File::stat;
  15 use Module::Pluggable::Object;
  16 use NEXT;
  17 use Text::SimpleTable;
  18 use Path::Class::Dir;
  19 use Path::Class::File;
  20 use Time::HiRes qw/gettimeofday tv_interval/;
  21 use URI;
  22 use Scalar::Util qw/weaken blessed/;
  23 use Tree::Simple qw/use_weak_refs/;
  24 use Tree::Simple::Visitor::FindByUID;
  25 use attributes;
  26 use utf8;
  27 use Carp qw/croak/;
  28
  29 BEGIN { require 5.008001; }
  30
  31 __PACKAGE__->mk_accessors(
  32     qw/counter request response state action stack namespace stats/
  33 );
  34
  35 attributes->import( __PACKAGE__, \&namespace, 'lvalue' );
  36
  37 sub depth { scalar @{ shift->stack || [] }; }
  38
  39 # Laziness++
  40 *comp = \&component;
  41 *req  = \&request;
  42 *res  = \&response;
  43
  44 # For backwards compatibility
  45 *finalize_output = \&finalize_body;
  46
  47 # For statistics
  48 our $COUNT     = 1;
  49 our $START     = time;
  50 our $RECURSION = 1000;
  51 our $DETACH    = "catalyst_detach\n";
  52
  53 __PACKAGE__->mk_classdata($_)
  54   for qw/components arguments dispatcher engine log dispatcher_class
  55   engine_class context_class request_class response_class setup_finished/;
  56
  57 __PACKAGE__->dispatcher_class('Catalyst::Dispatcher');
  58 __PACKAGE__->engine_class('Catalyst::Engine::CGI');
  59 __PACKAGE__->request_class('Catalyst::Request');
  60 __PACKAGE__->response_class('Catalyst::Response');
  61
  62 # Remember to update this in Catalyst::Runtime as well!
  63
  64 our $VERSION = '5.70_01';
  65
  66 sub import {
  67     my ( $class, @arguments ) = @_;
  68
  69     # We have to limit $class to Catalyst to avoid pushing Catalyst upon every
  70     # callers @ISA.
  71     return unless $class eq 'Catalyst';
  72
  73     my $caller = caller(0);
  74
  75     unless ( $caller->isa('Catalyst') ) {
  76         no strict 'refs';
  77         push @{"$caller\::ISA"}, $class, 'Catalyst::Controller';
  78     }
  79
  80     $caller->arguments( [@arguments] );
  81     $caller->setup_home;
  82 }
  83
  84 =head1 NAME
  85
  86 Catalyst - The Elegant MVC Web Application Framework
  87
  88 =head1 SYNOPSIS
  89
  90     # use the helper to create a new application
  91     catalyst.pl MyApp
  92
  93     # add models, views, controllers
  94     script/myapp_create.pl model Database DBIC::SchemaLoader dbi:SQLite:/path/to/db
  95     script/myapp_create.pl view TT TT
  96     script/myapp_create.pl controller Search
  97
  98     # built in testserver -- use -r to restart automatically on changes
  99     script/myapp_server.pl
 100
 101     # command line testing interface
 102     script/myapp_test.pl /yada
 103
 104     ### in lib/MyApp.pm
 105     use Catalyst qw/-Debug/; # include plugins here as well
 106
 107         ### In lib/MyApp/Controller/Root.pm (autocreated)
 108     sub foo : Global { # called for /foo, /foo/1, /foo/1/2, etc.
 109         my ( $self, $c, @args ) = @_; # args are qw/1 2/ for /foo/1/2
 110         $c->stash->{template} = 'foo.tt'; # set the template
 111         # lookup something from db -- stash vars are passed to TT
 112         $c->stash->{data} =
 113           $c->model('Database::Foo')->search( { country => $args[0] } );
 114         if ( $c->req->params->{bar} ) { # access GET or POST parameters
 115             $c->forward( 'bar' ); # process another action
 116             # do something else after forward returns
 117         }
 118     }
 119
 120     # The foo.tt TT template can use the stash data from the database
 121     [% WHILE (item = data.next) %]
 122         [% item.foo %]
 123     [% END %]
 124
 125     # called for /bar/of/soap, /bar/of/soap/10, etc.
 126     sub bar : Path('/bar/of/soap') { ... }
 127
 128     # called for all actions, from the top-most controller downwards
 129     sub auto : Private {
 130         my ( $self, $c ) = @_;
 131         if ( !$c->user_exists ) { # Catalyst::Plugin::Authentication
 132             $c->res->redirect( '/login' ); # require login
 133             return 0; # abort request and go immediately to end()
 134         }
 135         return 1; # success; carry on to next action
 136     }
 137
 138     # called after all actions are finished
 139     sub end : Private {
 140         my ( $self, $c ) = @_;
 141         if ( scalar @{ $c->error } ) { ... } # handle errors
 142         return if $c->res->body; # already have a response
 143         $c->forward( 'MyApp::View::TT' ); # render template
 144     }
 145
 146     ### in MyApp/Controller/Foo.pm
 147     # called for /foo/bar
 148     sub bar : Local { ... }
 149
 150     # called for /blargle
 151     sub blargle : Global { ... }
 152
 153     # an index action matches /foo, but not /foo/1, etc.
 154     sub index : Private { ... }
 155
 156     ### in MyApp/Controller/Foo/Bar.pm
 157     # called for /foo/bar/baz
 158     sub baz : Local { ... }
 159
 160     # first Root auto is called, then Foo auto, then this
 161     sub auto : Private { ... }
 162
 163     # powerful regular expression paths are also possible
 164     sub details : Regex('^product/(\w+)/details$') {
 165         my ( $self, $c ) = @_;
 166         # extract the (\w+) from the URI
 167         my $product = $c->req->captures->[0];
 168     }
 169
 170 See L<Catalyst::Manual::Intro> for additional information.
 171
 172 =head1 DESCRIPTION
 173
 174 Catalyst is a modern framework for making web applications without the pain usually associated with this process. This document is a reference to the main Catalyst application. If you are a new user, we suggest you start with L<Catalyst::Manual::Tutorial> or  L<Catalyst::Manual::Intro>
 175
 176 See L<Catalyst::Manual> for more documentation.
 177
 178 Catalyst plugins can be loaded by naming them as arguments to the "use
 179 Catalyst" statement. Omit the C<Catalyst::Plugin::> prefix from the
 180 plugin name, i.e., C<Catalyst::Plugin::My::Module> becomes
 181 C<My::Module>.
 182
 183     use Catalyst qw/My::Module/;
 184
 185 If your plugin starts with a name other than C<Catalyst::Plugin::>, you can
 186 fully qualify the name by using a unary plus:
 187
 188     use Catalyst qw/
 189         My::Module
 190         +Fully::Qualified::Plugin::Name
 191     /;
 192
 193 Special flags like C<-Debug> and C<-Engine> can also be specified as
 194 arguments when Catalyst is loaded:
 195
 196     use Catalyst qw/-Debug My::Module/;
 197
 198 The position of plugins and flags in the chain is important, because
 199 they are loaded in exactly the order in which they appear.
 200
 201 The following flags are supported:
 202
 203 =head2 -Debug
 204
 205 Enables debug output. You can also force this setting from the system
 206 environment with CATALYST_DEBUG or <MYAPP>_DEBUG. The environment settings
 207 override the app, with <MYAPP>_DEBUG having highest priority.
 208
 209 =head2 -Engine
 210
 211 Forces Catalyst to use a specific engine. Omit the
 212 C<Catalyst::Engine::> prefix of the engine name, i.e.:
 213
 214     use Catalyst qw/-Engine=CGI/;
 215
 216 =head2 -Home
 217
 218 Forces Catalyst to use a specific home directory, e.g.:
 219
 220     use Catalyst qw[-Home=/usr/sri];
 221
 222 =head2 -Log
 223
 224 Specifies log level.
 225
 226 =head1 METHODS
 227
 228 =head2 INFORMATION ABOUT THE CURRENT REQUEST
 229
 230 =head2 $c->action
 231
 232 Returns a L<Catalyst::Action> object for the current action, which
 233 stringifies to the action name. See L<Catalyst::Action>.
 234
 235 =head2 $c->namespace
 236
 237 Returns the namespace of the current action, i.e., the uri prefix
 238 corresponding to the controller of the current action. For example:
 239
 240     # in Controller::Foo::Bar
 241     $c->namespace; # returns 'foo/bar';
 242
 243 =head2 $c->request
 244
 245 =head2 $c->req
 246
 247 Returns the current L<Catalyst::Request> object. See
 248 L<Catalyst::Request>.
 249
 250 =head2 REQUEST FLOW HANDLING
 251
 252 =head2 $c->forward( $action [, \@arguments ] )
 253
 254 =head2 $c->forward( $class, $method, [, \@arguments ] )
 255
 256 Forwards processing to another action, by it's private name. If you give a
 257 class name but no method, C<process()> is called. You may also optionally
 258 pass arguments in an arrayref. The action will receive the arguments in
 259 C<@_> and C<$c-E<gt>req-E<gt>args>. Upon returning from the function,
 260 C<$c-E<gt>req-E<gt>args> will be restored to the previous values.
 261
 262 Any data C<return>ed from the action forwarded to, will be returned by the
 263 call to forward.
 264
 265     my $foodata = $c->forward('/foo');
 266     $c->forward('index');
 267     $c->forward(qw/MyApp::Model::DBIC::Foo do_stuff/);
 268     $c->forward('MyApp::View::TT');
 269
 270 Note that forward implies an C<<eval { }>> around the call (well, actually
 271 C<execute> does), thus de-fatalizing all 'dies' within the called action. If
 272 you want C<die> to propagate you need to do something like:
 273
 274     $c->forward('foo');
 275     die $c->error if $c->error;
 276
 277 Or make sure to always return true values from your actions and write your code
 278 like this:
 279
 280     $c->forward('foo') || return;
 281
 282 =cut
 283
 284 sub forward { my $c = shift; $c->dispatcher->forward( $c, @_ ) }
 285
 286 =head2 $c->detach( $action [, \@arguments ] )
 287
 288 =head2 $c->detach( $class, $method, [, \@arguments ] )
 289
 290 The same as C<forward>, but doesn't return to the previous action when
 291 processing is finished.
 292
 293 =cut
 294
 295 sub detach { my $c = shift; $c->dispatcher->detach( $c, @_ ) }
 296
 297 =head2 $c->response
 298
 299 =head2 $c->res
 300
 301 Returns the current L<Catalyst::Response> object.
 302
 303 =head2 $c->stash
 304
 305 Returns a hashref to the stash, which may be used to store data and pass
 306 it between components during a request. You can also set hash keys by
 307 passing arguments. The stash is automatically sent to the view. The
 308 stash is cleared at the end of a request; it cannot be used for
 309 persistent storage.
 310
 311     $c->stash->{foo} = $bar;
 312     $c->stash( { moose => 'majestic', qux => 0 } );
 313     $c->stash( bar => 1, gorch => 2 ); # equivalent to passing a hashref
 314
 315     # stash is automatically passed to the view for use in a template
 316     $c->forward( 'MyApp::V::TT' );
 317
 318 =cut
 319
 320 sub stash {
 321     my $c = shift;
 322     if (@_) {
 323         my $stash = @_ > 1 ? {@_} : $_[0];
 324         croak('stash takes a hash or hashref') unless ref $stash;
 325         foreach my $key ( keys %$stash ) {
 326             $c->{stash}->{$key} = $stash->{$key};
 327         }
 328     }
 329     return $c->{stash};
 330 }
 331
 332 =head2 $c->error
 333
 334 =head2 $c->error($error, ...)
 335
 336 =head2 $c->error($arrayref)
 337
 338 Returns an arrayref containing error messages.  If Catalyst encounters an
 339 error while processing a request, it stores the error in $c->error.  This
 340 method should not be used to store non-fatal error messages.
 341
 342     my @error = @{ $c->error };
 343
 344 Add a new error.
 345
 346     $c->error('Something bad happened');
 347
 348 =cut
 349
 350 sub error {
 351     my $c = shift;
 352     if ( $_[0] ) {
 353         my $error = ref $_[0] eq 'ARRAY' ? $_[0] : [@_];
 354         croak @$error unless ref $c;
 355         push @{ $c->{error} }, @$error;
 356     }
 357     elsif ( defined $_[0] ) { $c->{error} = undef }
 358     return $c->{error} || [];
 359 }
 360
 361
 362 =head2 $c->state
 363
 364 Contains the return value of the last executed action.
 365
 366 =head2 $c->clear_errors
 367
 368 Clear errors.  You probably don't want to clear the errors unless you are
 369 implementing a custom error screen.
 370
 371 This is equivalent to running
 372
 373     $c->error(0);
 374
 375 =cut
 376
 377 sub clear_errors {
 378     my $c = shift;
 379     $c->error(0);
 380 }
 381
 382
 383
 384
 385 # search via regex
 386 sub _comp_search {
 387     my ( $c, @names ) = @_;
 388
 389     foreach my $name (@names) {
 390         foreach my $component ( keys %{ $c->components } ) {
 391             return $c->components->{$component} if $component =~ /$name/i;
 392         }
 393     }
 394
 395     return undef;
 396 }
 397
 398 # try explicit component names
 399 sub _comp_explicit {
 400     my ( $c, @names ) = @_;
 401
 402     foreach my $try (@names) {
 403         return $c->components->{$try} if ( exists $c->components->{$try} );
 404     }
 405
 406     return undef;
 407 }
 408
 409 # like component, but try just these prefixes before regex searching,
 410 #  and do not try to return "sort keys %{ $c->components }"
 411 sub _comp_prefixes {
 412     my ( $c, $name, @prefixes ) = @_;
 413
 414     my $appclass = ref $c || $c;
 415
 416     my @names = map { "${appclass}::${_}::${name}" } @prefixes;
 417
 418     my $comp = $c->_comp_explicit(@names);
 419     return $comp if defined($comp);
 420     $comp = $c->_comp_search($name);
 421     return $comp;
 422 }
 423
 424 # Find possible names for a prefix
 425
 426 sub _comp_names {
 427     my ( $c, @prefixes ) = @_;
 428
 429     my $appclass = ref $c || $c;
 430
 431     my @pre = map { "${appclass}::${_}::" } @prefixes;
 432
 433     my @names;
 434
 435     COMPONENT: foreach my $comp ($c->component) {
 436         foreach my $p (@pre) {
 437             if ($comp =~ s/^$p//) {
 438                 push(@names, $comp);
 439                 next COMPONENT;
 440             }
 441         }
 442     }
 443
 444     return @names;
 445 }
 446
 447 # Return a component if only one matches.
 448 sub _comp_singular {
 449     my ( $c, @prefixes ) = @_;
 450
 451     my $appclass = ref $c || $c;
 452
 453     my ( $comp, $rest ) =
 454       map { $c->_comp_search("^${appclass}::${_}::") } @prefixes;
 455     return $comp unless $rest;
 456 }
 457
 458 # Filter a component before returning by calling ACCEPT_CONTEXT if available
 459 sub _filter_component {
 460     my ( $c, $comp, @args ) = @_;
 461     if ( eval { $comp->can('ACCEPT_CONTEXT'); } ) {
 462         return $comp->ACCEPT_CONTEXT( $c, @args );
 463     }
 464     else { return $comp }
 465 }
 466
 467 =head2 COMPONENT ACCESSORS
 468
 469 =head2 $c->controller($name)
 470
 471 Gets a L<Catalyst::Controller> instance by name.
 472
 473     $c->controller('Foo')->do_stuff;
 474
 475 If name is omitted, will return the controller for the dispatched action.
 476
 477 =cut
 478
 479 sub controller {
 480     my ( $c, $name, @args ) = @_;
 481     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Controller C/ ),
 482         @args )
 483       if ($name);
 484     return $c->component( $c->action->class );
 485 }
 486
 487 =head2 $c->model($name)
 488
 489 Gets a L<Catalyst::Model> instance by name.
 490
 491     $c->model('Foo')->do_stuff;
 492
 493 If the name is omitted, it will look for a config setting 'default_model',
 494 or check if there is only one view, and return it if that's the case.
 495
 496 =cut
 497
 498 sub model {
 499     my ( $c, $name, @args ) = @_;
 500     return $c->_filter_component( $c->_comp_prefixes( $name, qw/Model M/ ),
 501         @args )
 502       if $name;
 503     return $c->component( $c->config->{default_model} )
 504       if $c->config->{default_model};
 505     return $c->_filter_component( $c->_comp_singular(qw/Model M/), @args );
 506
 507 }
 508
 509 =head2 $c->controllers
 510
 511 Returns the available names which can be passed to $c->controller
 512
 513 =cut
 514
 515 sub controllers {
 516     my ( $c ) = @_;
 517     return $c->_comp_names(qw/Controller C/);
 518 }
 519
 520
 521 =head2 $c->view($name)
 522
 523 Gets a L<Catalyst::View> instance by name.
 524
 525     $c->view('Foo')->do_stuff;
 526
 527 If the name is omitted, it will look for a config setting 'default_view',
 528 or check if there is only one view, and forward to it if that's the case.
 529
 530 =cut
 531
 532 sub view {
 533     my ( $c, $name, @args ) = @_;
 534     return $c->_filter_component( $c->_comp_prefixes( $name, qw/View V/ ),
 535         @args )
 536       if $name;
 537     return $c->component( $c->config->{default_view} )
 538       if $c->config->{default_view};
 539     return $c->_filter_component( $c->_comp_singular(qw/View V/) );
 540 }
 541
 542 =head2 $c->models
 543
 544 Returns the available names which can be passed to $c->model
 545
 546 =cut
 547
 548 sub models {
 549     my ( $c ) = @_;
 550     return $c->_comp_names(qw/Model M/);
 551 }
 552
 553
 554 =head2 $c->views
 555
 556 Returns the available names which can be passed to $c->view
 557
 558 =cut
 559
 560 sub views {
 561     my ( $c ) = @_;
 562     return $c->_comp_names(qw/View V/);
 563 }
 564
 565 =head2 $c->comp($name)
 566
 567 =head2 $c->component($name)
 568
 569 Gets a component object by name. This method is no longer recommended,
 570 unless you want to get a specific component by full
 571 class. C<$c-E<gt>controller>, C<$c-E<gt>model>, and C<$c-E<gt>view>
 572 should be used instead.
 573
 574 =cut
 575
 576 sub component {
 577     my $c = shift;
 578
 579     if (@_) {
 580
 581         my $name = shift;
 582
 583         my $appclass = ref $c || $c;
 584
 585         my @names = (
 586             $name, "${appclass}::${name}",
 587             map { "${appclass}::${_}::${name}" }
 588               qw/Model M Controller C View V/
 589         );
 590
 591         my $comp = $c->_comp_explicit(@names);
 592         return $c->_filter_component( $comp, @_ ) if defined($comp);
 593
 594         $comp = $c->_comp_search($name);
 595         return $c->_filter_component( $comp, @_ ) if defined($comp);
 596     }
 597
 598     return sort keys %{ $c->components };
 599 }
 600
 601
 602
 603 =head2 CLASS DATA AND HELPER CLASSES
 604
 605 =head2 $c->config
 606
 607 Returns or takes a hashref containing the application's configuration.
 608
 609     __PACKAGE__->config( { db => 'dsn:SQLite:foo.db' } );
 610
 611 You can also use a L<YAML> config file like myapp.yml in your
 612 applications home directory.
 613
 614     ---
 615     db: dsn:SQLite:foo.db
 616
 617
 618 =cut
 619
 620 sub config {
 621     my $c = shift;
 622
 623     $c->log->warn("Setting config after setup has been run is not a good idea.")
 624       if ( @_ and $c->setup_finished );
 625
 626     $c->NEXT::config(@_);
 627 }
 628
 629 =head2 $c->log
 630
 631 Returns the logging object instance. Unless it is already set, Catalyst sets
 632 this up with a L<Catalyst::Log> object. To use your own log class, set the
 633 logger with the C<< __PACKAGE__->log >> method prior to calling
 634 C<< __PACKAGE__->setup >>.
 635
 636  __PACKAGE__->log( MyLogger->new );
 637  __PACKAGE__->setup;
 638
 639 And later:
 640
 641     $c->log->info( 'Now logging with my own logger!' );
 642
 643 Your log class should implement the methods described in the
 644 L<Catalyst::Log> man page.
 645
 646
 647 =head2 $c->debug
 648
 649 Overload to enable debug messages (same as -Debug option).
 650
 651 Note that this is a static method, not an accessor and should be overloaded
 652 by declaring "sub debug { 1 }" in your MyApp.pm, not by calling $c->debug(1).
 653
 654 =cut
 655
 656 sub debug { 0 }
 657
 658 =head2 $c->dispatcher
 659
 660 Returns the dispatcher instance. Stringifies to class name. See
 661 L<Catalyst::Dispatcher>.
 662
 663 =head2 $c->engine
 664
 665 Returns the engine instance. Stringifies to the class name. See
 666 L<Catalyst::Engine>.
 667
 668
 669 =head2 UTILITY METHODS
 670
 671 =head2 $c->path_to(@path)
 672
 673 Merges C<@path> with C<$c-E<gt>config-E<gt>{home}> and returns a
 674 L<Path::Class> object.
 675
 676 For example:
 677
 678     $c->path_to( 'db', 'sqlite.db' );
 679
 680 =cut
 681
 682 sub path_to {
 683     my ( $c, @path ) = @_;
 684     my $path = Path::Class::Dir->new( $c->config->{home}, @path );
 685     if ( -d $path ) { return $path }
 686     else { return Path::Class::File->new( $c->config->{home}, @path ) }
 687 }
 688
 689 =head2 $c->plugin( $name, $class, @args )
 690
 691 Helper method for plugins. It creates a classdata accessor/mutator and
 692 loads and instantiates the given class.
 693
 694     MyApp->plugin( 'prototype', 'HTML::Prototype' );
 695
 696     $c->prototype->define_javascript_functions;
 697
 698 =cut
 699
 700 sub plugin {
 701     my ( $class, $name, $plugin, @args ) = @_;
 702     $class->_register_plugin( $plugin, 1 );
 703
 704     eval { $plugin->import };
 705     $class->mk_classdata($name);
 706     my $obj;
 707     eval { $obj = $plugin->new(@args) };
 708
 709     if ($@) {
 710         Catalyst::Exception->throw( message =>
 711               qq/Couldn't instantiate instant plugin "$plugin", "$@"/ );
 712     }
 713
 714     $class->$name($obj);
 715     $class->log->debug(qq/Initialized instant plugin "$plugin" as "$name"/)
 716       if $class->debug;
 717 }
 718
 719 =head2 MyApp->setup
 720
 721 Initializes the dispatcher and engine, loads any plugins, and loads the
 722 model, view, and controller components. You may also specify an array
 723 of plugins to load here, if you choose to not load them in the C<use
 724 Catalyst> line.
 725
 726     MyApp->setup;
 727     MyApp->setup( qw/-Debug/ );
 728
 729 =cut
 730
 731 sub setup {
 732     my ( $class, @arguments ) = @_;
 733
 734     $class->log->warn("Running setup twice is not a good idea.")
 735       if ( $class->setup_finished );
 736
 737     unless ( $class->isa('Catalyst') ) {
 738
 739         Catalyst::Exception->throw(
 740             message => qq/'$class' does not inherit from Catalyst/ );
 741     }
 742
 743     if ( $class->arguments ) {
 744         @arguments = ( @arguments, @{ $class->arguments } );
 745     }
 746
 747     # Process options
 748     my $flags = {};
 749
 750     foreach (@arguments) {
 751
 752         if (/^-Debug$/) {
 753             $flags->{log} =
 754               ( $flags->{log} ) ? 'debug,' . $flags->{log} : 'debug';
 755         }
 756         elsif (/^-(\w+)=?(.*)$/) {
 757             $flags->{ lc $1 } = $2;
 758         }
 759         else {
 760             push @{ $flags->{plugins} }, $_;
 761         }
 762     }
 763
 764     $class->setup_home( delete $flags->{home} );
 765
 766     $class->setup_log( delete $flags->{log} );
 767     $class->setup_plugins( delete $flags->{plugins} );
 768     $class->setup_dispatcher( delete $flags->{dispatcher} );
 769     $class->setup_engine( delete $flags->{engine} );
 770
 771     for my $flag ( sort keys %{$flags} ) {
 772
 773         if ( my $code = $class->can( 'setup_' . $flag ) ) {
 774             &$code( $class, delete $flags->{$flag} );
 775         }
 776         else {
 777             $class->log->warn(qq/Unknown flag "$flag"/);
 778         }
 779     }
 780
 781     eval { require Catalyst::Devel; };
 782     if( !$@ && $ENV{CATALYST_SCRIPT_GEN} && ( $ENV{CATALYST_SCRIPT_GEN} < $Catalyst::Devel::CATALYST_SCRIPT_GEN ) ) {
 783         $class->log->warn(<<"EOF");
 784 You are running an old script!
 785
 786   Please update by running (this will overwrite existing files):
 787     catalyst.pl -force -scripts $class
 788
 789   or (this will not overwrite existing files):
 790     catalyst.pl -scripts $class
 791 EOF
 792     }
 793
 794     if ( $class->debug ) {
 795
 796         my @plugins = ();
 797
 798         {
 799             no strict 'refs';
 800             @plugins =
 801               map { $_ . ' ' . ( $_->VERSION || '' ) }
 802               grep { /^Catalyst::Plugin/ } @{"$class\::ISA"};
 803         }
 804
 805         if (@plugins) {
 806             my $t = Text::SimpleTable->new(74);
 807             $t->row($_) for @plugins;
 808             $class->log->debug( "Loaded plugins:\n" . $t->draw );
 809         }
 810
 811         my $dispatcher = $class->dispatcher;
 812         my $engine     = $class->engine;
 813         my $home       = $class->config->{home};
 814
 815         $class->log->debug(qq/Loaded dispatcher "$dispatcher"/);
 816         $class->log->debug(qq/Loaded engine "$engine"/);
 817
 818         $home
 819           ? ( -d $home )
 820           ? $class->log->debug(qq/Found home "$home"/)
 821           : $class->log->debug(qq/Home "$home" doesn't exist/)
 822           : $class->log->debug(q/Couldn't find home/);
 823     }
 824
 825     # Call plugins setup
 826     {
 827         no warnings qw/redefine/;
 828         local *setup = sub { };
 829         $class->setup;
 830     }
 831
 832     # Initialize our data structure
 833     $class->components( {} );
 834
 835     $class->setup_components;
 836
 837     if ( $class->debug ) {
 838         my $t = Text::SimpleTable->new( [ 63, 'Class' ], [ 8, 'Type' ] );
 839         for my $comp ( sort keys %{ $class->components } ) {
 840             my $type = ref $class->components->{$comp} ? 'instance' : 'class';
 841             $t->row( $comp, $type );
 842         }
 843         $class->log->debug( "Loaded components:\n" . $t->draw )
 844           if ( keys %{ $class->components } );
 845     }
 846
 847     # Add our self to components, since we are also a component
 848     $class->components->{$class} = $class;
 849
 850     $class->setup_actions;
 851
 852     if ( $class->debug ) {
 853         my $name = $class->config->{name} || 'Application';
 854         $class->log->info("$name powered by Catalyst $Catalyst::VERSION");
 855     }
 856     $class->log->_flush() if $class->log->can('_flush');
 857
 858     $class->setup_finished(1);
 859 }
 860
 861 =head2 $c->uri_for( $path, @args?, \%query_values? )
 862
 863 Merges path with C<$c-E<gt>request-E<gt>base> for absolute uri's and
 864 with C<$c-E<gt>namespace> for relative uri's, then returns a
 865 normalized L<URI> object. If any args are passed, they are added at the
 866 end of the path.  If the last argument to uri_for is a hash reference,
 867 it is assumed to contain GET parameter key/value pairs, which will be
 868 appended to the URI in standard fashion.
 869
 870 Instead of $path, you can also optionally pass a $action object which will
 871 be resolved to a path using $c->dispatcher->uri_for_action; if the first
 872 element of @args is an arrayref it is treated as a list of captures to be
 873 passed to uri_for_action.
 874
 875 =cut
 876
 877 sub uri_for {
 878     my ( $c, $path, @args ) = @_;
 879     my $base     = $c->request->base->clone;
 880     my $basepath = $base->path;
 881     $basepath =~ s/\/$//;
 882     $basepath .= '/';
 883     my $namespace = $c->namespace || '';
 884
 885     if ( Scalar::Util::blessed($path) ) { # action object
 886         my $captures = ( scalar @args && ref $args[0] eq 'ARRAY'
 887                          ? shift(@args)
 888                          : [] );
 889         $path = $c->dispatcher->uri_for_action($path, $captures);
 890         return undef unless defined($path);
 891     }
 892
 893     # massage namespace, empty if absolute path
 894     $namespace =~ s/^\/// if $namespace;
 895     $namespace .= '/' if $namespace;
 896     $path ||= '';
 897     $namespace = '' if $path =~ /^\//;
 898     $path =~ s/^\///;
 899
 900     my $params =
 901       ( scalar @args && ref $args[$#args] eq 'HASH' ? pop @args : {} );
 902
 903     for my $value ( values %$params ) {\r
 904         my $isa_ref = ref $value;\r
 905         if( $isa_ref and $isa_ref ne 'ARRAY' ) {\r
 906             croak( "Non-array reference ($isa_ref) passed to uri_for()" );\r
 907         }\r
 908         utf8::encode( $_ ) for grep { defined } $isa_ref ? @$value : $value;\r
 909     };
 910
 911     # join args with '/', or a blank string
 912     my $args = ( scalar @args ? '/' . join( '/', @args ) : '' );
 913     $args =~ s/^\/// unless $path;
 914     my $res =
 915       URI->new_abs( URI->new_abs( "$path$args", "$basepath$namespace" ), $base )
 916       ->canonical;
 917     $res->query_form(%$params);
 918     $res;
 919 }
 920
 921 =head2 $c->welcome_message
 922
 923 Returns the Catalyst welcome HTML page.
 924
 925 =cut
 926
 927 sub welcome_message {
 928     my $c      = shift;
 929     my $name   = $c->config->{name};
 930     my $logo   = $c->uri_for('/static/images/catalyst_logo.png');
 931     my $prefix = Catalyst::Utils::appprefix( ref $c );
 932     $c->response->content_type('text/html; charset=utf-8');
 933     return <<"EOF";
 934 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
 935     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 936 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 937     <head>
 938         <meta http-equiv="Content-Language" content="en" />
 939         <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
 940         <title>$name on Catalyst $VERSION</title>
 941         <style type="text/css">
 942             body {
 943                 color: #000;
 944                 background-color: #eee;
 945             }
 946             div#content {
 947                 width: 640px;
 948                 margin-left: auto;
 949                 margin-right: auto;
 950                 margin-top: 10px;
 951                 margin-bottom: 10px;
 952                 text-align: left;
 953                 background-color: #ccc;
 954                 border: 1px solid #aaa;
 955             }
 956             p, h1, h2 {
 957                 margin-left: 20px;
 958                 margin-right: 20px;
 959                 font-family: verdana, tahoma, sans-serif;
 960             }
 961             a {
 962                 font-family: verdana, tahoma, sans-serif;
 963             }
 964             :link, :visited {
 965                     text-decoration: none;
 966                     color: #b00;
 967                     border-bottom: 1px dotted #bbb;
 968             }
 969             :link:hover, :visited:hover {
 970                     color: #555;
 971             }
 972             div#topbar {
 973                 margin: 0px;
 974             }
 975             pre {
 976                 margin: 10px;
 977                 padding: 8px;
 978             }
 979             div#answers {
 980                 padding: 8px;
 981                 margin: 10px;
 982                 background-color: #fff;
 983                 border: 1px solid #aaa;
 984             }
 985             h1 {
 986                 font-size: 0.9em;
 987                 font-weight: normal;
 988                 text-align: center;
 989             }
 990             h2 {
 991                 font-size: 1.0em;
 992             }
 993             p {
 994                 font-size: 0.9em;
 995             }
 996             p img {
 997                 float: right;
 998                 margin-left: 10px;
 999             }
1000             span#appname {
1001                 font-weight: bold;
1002                 font-size: 1.6em;
1003             }
1004         </style>
1005     </head>
1006     <body>
1007         <div id="content">
1008             <div id="topbar">
1009                 <h1><span id="appname">$name</span> on <a href="http://catalyst.perl.org">Catalyst</a>
1010                     $VERSION</h1>
1011              </div>
1012              <div id="answers">
1013                  <p>
1014                  <img src="$logo" alt="Catalyst Logo" />
1015                  </p>
1016                  <p>Welcome to the wonderful world of Catalyst.
1017                     This <a href="http://en.wikipedia.org/wiki/MVC">MVC</a>
1018                     framework will make web development something you had
1019                     never expected it to be: Fun, rewarding, and quick.</p>
1020                  <h2>What to do now?</h2>
1021                  <p>That really depends  on what <b>you</b> want to do.
1022                     We do, however, provide you with a few starting points.</p>
1023                  <p>If you want to jump right into web development with Catalyst
1024                     you might want to check out the documentation.</p>
1025                  <pre><code>perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Intro.pod">Catalyst::Manual::Intro</a>
1026 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual/Tutorial.pod">Catalyst::Manual::Tutorial</a></code>
1027 perldoc <a href="http://cpansearch.perl.org/dist/Catalyst/lib/Catalyst/Manual.pod">Catalyst::Manual</a></code></pre>
1028                  <h2>What to do next?</h2>
1029                  <p>Next it's time to write an actual application. Use the
1030                     helper scripts to generate <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AController%3A%3A&amp;mode=all">controllers</a>,
1031                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AModel%3A%3A&amp;mode=all">models</a>, and
1032                     <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3AView%3A%3A&amp;mode=all">views</a>;
1033                     they can save you a lot of work.</p>
1034                     <pre><code>script/${prefix}_create.pl -help</code></pre>
1035                     <p>Also, be sure to check out the vast and growing
1036                     collection of <a href="http://cpansearch.perl.org/search?query=Catalyst%3A%3APlugin%3A%3A&amp;mode=all">plugins for Catalyst on CPAN</a>;
1037                     you are likely to find what you need there.
1038                     </p>
1039
1040                  <h2>Need help?</h2>
1041                  <p>Catalyst has a very active community. Here are the main places to
1042                     get in touch with us.</p>
1043                  <ul>
1044                      <li>
1045                          <a href="http://dev.catalyst.perl.org">Wiki</a>
1046                      </li>
1047                      <li>
1048                          <a href="http://lists.rawmode.org/mailman/listinfo/catalyst">Mailing-List</a>
1049                      </li>
1050                      <li>
1051                          <a href="irc://irc.perl.org/catalyst">IRC channel #catalyst on irc.perl.org</a>
1052                      </li>
1053                  </ul>
1054                  <h2>In conclusion</h2>
1055                  <p>The Catalyst team hopes you will enjoy using Catalyst as much
1056                     as we enjoyed making it. Please contact us if you have ideas
1057                     for improvement or other feedback.</p>
1058              </div>
1059          </div>
1060     </body>
1061 </html>
1062 EOF
1063 }
1064
1065 =head1 INTERNAL METHODS
1066
1067 These methods are not meant to be used by end users.
1068
1069 =head2 $c->components
1070
1071 Returns a hash of components.
1072
1073 =head2 $c->context_class
1074
1075 Returns or sets the context class.
1076
1077 =head2 $c->counter
1078
1079 Returns a hashref containing coderefs and execution counts (needed for
1080 deep recursion detection).
1081
1082 =head2 $c->depth
1083
1084 Returns the number of actions on the current internal execution stack.
1085
1086 =head2 $c->dispatch
1087
1088 Dispatches a request to actions.
1089
1090 =cut
1091
1092 sub dispatch { my $c = shift; $c->dispatcher->dispatch( $c, @_ ) }
1093
1094 =head2 $c->dispatcher_class
1095
1096 Returns or sets the dispatcher class.
1097
1098 =head2 $c->dump_these
1099
1100 Returns a list of 2-element array references (name, structure) pairs
1101 that will be dumped on the error page in debug mode.
1102
1103 =cut
1104
1105 sub dump_these {
1106     my $c = shift;
1107     [ Request => $c->req ],
1108     [ Response => $c->res ],
1109     [ Stash => $c->stash ],
1110     [ Config => $c->config ];
1111 }
1112
1113 =head2 $c->engine_class
1114
1115 Returns or sets the engine class.
1116
1117 =head2 $c->execute( $class, $coderef )
1118
1119 Execute a coderef in given class and catch exceptions. Errors are available
1120 via $c->error.
1121
1122 =cut
1123
1124 sub execute {
1125     my ( $c, $class, $code ) = @_;
1126     $class = $c->component($class) || $class;
1127     $c->state(0);
1128
1129     if ( $c->depth >= $RECURSION ) {
1130         my $action = "$code";
1131         $action = "/$action" unless $action =~ /\-\>/;
1132         my $error = qq/Deep recursion detected calling "$action"/;
1133         $c->log->error($error);
1134         $c->error($error);
1135         $c->state(0);
1136         return $c->state;
1137     }
1138
1139     my $stats_info = $c->_stats_start_execute( $code );
1140
1141     push( @{ $c->stack }, $code );
1142
1143     eval { $c->state( &$code( $class, $c, @{ $c->req->args } ) || 0 ) };
1144
1145     $c->_stats_finish_execute( $stats_info );
1146
1147     my $last = ${ $c->stack }[-1];
1148     pop( @{ $c->stack } );
1149
1150     if ( my $error = $@ ) {
1151         if ( $error eq $DETACH ) { die $DETACH if $c->depth > 1 }
1152         else {
1153             unless ( ref $error ) {
1154                 chomp $error;
1155                 my $class = $last->class;
1156                 my $name  = $last->name;
1157                 $error = qq/Caught exception in $class->$name "$error"/;
1158             }
1159             $c->error($error);
1160             $c->state(0);
1161         }
1162     }
1163     return $c->state;
1164 }
1165
1166 sub _stats_start_execute {
1167     my ( $c, $code ) = @_;
1168
1169     return unless $c->debug;
1170
1171     my $action = "$code";
1172
1173     $action = "/$action" unless $action =~ /\-\>/;
1174     $c->counter->{"$code"}++;
1175
1176     # determine if the call was the result of a forward
1177     # this is done by walking up the call stack and looking for a calling
1178     # sub of Catalyst::forward before the eval
1179     my $callsub = q{};
1180     for my $index ( 2 .. 11 ) {
1181         last
1182         if ( ( caller($index) )[0] eq 'Catalyst'
1183             && ( caller($index) )[3] eq '(eval)' );
1184
1185         if ( ( caller($index) )[3] =~ /forward$/ ) {
1186             $callsub = ( caller($index) )[3];
1187             $action  = "-> $action";
1188             last;
1189         }
1190     }
1191
1192     my $node = Tree::Simple->new(
1193         {
1194             action  => $action,
1195             elapsed => undef,     # to be filled in later
1196             comment => "",
1197         }
1198     );
1199     $node->setUID( "$code" . $c->counter->{"$code"} );
1200
1201     unless ( ( $code->name =~ /^_.*/ )
1202         && ( !$c->config->{show_internal_actions} ) )
1203     {
1204         # is this a root-level call or a forwarded call?
1205         if ( $callsub =~ /forward$/ ) {
1206
1207             # forward, locate the caller
1208             if ( my $parent = $c->stack->[-1] ) {
1209                 my $visitor = Tree::Simple::Visitor::FindByUID->new;
1210                 $visitor->searchForUID(
1211                     "$parent" . $c->counter->{"$parent"} );
1212                 $c->stats->accept($visitor);
1213                 if ( my $result = $visitor->getResult ) {
1214                     $result->addChild($node);
1215                 }
1216             }
1217             else {
1218
1219                 # forward with no caller may come from a plugin
1220                 $c->stats->addChild($node);
1221             }
1222         }
1223         else {
1224
1225             # root-level call
1226             $c->stats->addChild($node);
1227         }
1228     }
1229
1230     my $start = [gettimeofday];
1231     my $elapsed = tv_interval($start);
1232
1233     return {
1234         code    => $code,
1235         elapsed => $elapsed,
1236         start   => $start,
1237         node    => $node,
1238       }
1239 }
1240
1241 sub _stats_finish_execute {
1242     my ( $c, $info ) = @_;
1243
1244     return unless $c->debug;
1245
1246     my ( $code, $start, $elapsed ) = @{ $info }{qw/code start elapsed/};
1247
1248     unless ( ( $code->name =~ /^_.*/ )
1249         && ( !$c->config->{show_internal_actions} ) )
1250     {
1251
1252         # FindByUID uses an internal die, so we save the existing error
1253         my $error = $@;
1254
1255         # locate the node in the tree and update the elapsed time
1256         my $visitor = Tree::Simple::Visitor::FindByUID->new;
1257         $visitor->searchForUID( "$code" . $c->counter->{"$code"} );
1258         $c->stats->accept($visitor);
1259         if ( my $result = $visitor->getResult ) {
1260             my $value = $result->getNodeValue;
1261             $value->{elapsed} = sprintf( '%fs', $elapsed );
1262             $result->setNodeValue($value);
1263         }
1264
1265         # restore error
1266         $@ = $error || undef;
1267     }
1268 }
1269
1270 =head2 $c->_localize_fields( sub { }, \%keys );
1271
1272 =cut
1273
1274 sub _localize_fields {
1275     my ( $c, $localized, $code ) = ( @_ );
1276
1277     my $request = delete $localized->{request} || {};
1278     my $response = delete $localized->{response} || {};
1279
1280     local @{ $c }{ keys %$localized } = values %$localized;
1281     local @{ $c->request }{ keys %$request } = values %$request;
1282     local @{ $c->response }{ keys %$response } = values %$response;
1283
1284     $code->();
1285 }
1286
1287 =head2 $c->finalize
1288
1289 Finalizes the request.
1290
1291 =cut
1292
1293 sub finalize {
1294     my $c = shift;
1295
1296     for my $error ( @{ $c->error } ) {
1297         $c->log->error($error);
1298     }
1299
1300     # Allow engine to handle finalize flow (for POE)
1301     if ( $c->engine->can('finalize') ) {
1302         $c->engine->finalize($c);
1303     }
1304     else {
1305
1306         $c->finalize_uploads;
1307
1308         # Error
1309         if ( $#{ $c->error } >= 0 ) {
1310             $c->finalize_error;
1311         }
1312
1313         $c->finalize_headers;
1314
1315         # HEAD request
1316         if ( $c->request->method eq 'HEAD' ) {
1317             $c->response->body('');
1318         }
1319
1320         $c->finalize_body;
1321     }
1322
1323     return $c->response->status;
1324 }
1325
1326 =head2 $c->finalize_body
1327
1328 Finalizes body.
1329
1330 =cut
1331
1332 sub finalize_body { my $c = shift; $c->engine->finalize_body( $c, @_ ) }
1333
1334 =head2 $c->finalize_cookies
1335
1336 Finalizes cookies.
1337
1338 =cut
1339
1340 sub finalize_cookies { my $c = shift; $c->engine->finalize_cookies( $c, @_ ) }
1341
1342 =head2 $c->finalize_error
1343
1344 Finalizes error.
1345
1346 =cut
1347
1348 sub finalize_error { my $c = shift; $c->engine->finalize_error( $c, @_ ) }
1349
1350 =head2 $c->finalize_headers
1351
1352 Finalizes headers.
1353
1354 =cut
1355
1356 sub finalize_headers {
1357     my $c = shift;
1358
1359     # Check if we already finalized headers
1360     return if $c->response->{_finalized_headers};
1361
1362     # Handle redirects
1363     if ( my $location = $c->response->redirect ) {
1364         $c->log->debug(qq/Redirecting to "$location"/) if $c->debug;
1365         $c->response->header( Location => $location );
1366     }
1367
1368     # Content-Length
1369     if ( $c->response->body && !$c->response->content_length ) {
1370
1371         # get the length from a filehandle
1372         if ( blessed( $c->response->body ) && $c->response->body->can('read') )
1373         {
1374             if ( my $stat = stat $c->response->body ) {
1375                 $c->response->content_length( $stat->size );
1376             }
1377             else {
1378                 $c->log->warn('Serving filehandle without a content-length');
1379             }
1380         }
1381         else {
1382             $c->response->content_length( bytes::length( $c->response->body ) );
1383         }
1384     }
1385
1386     # Errors
1387     if ( $c->response->status =~ /^(1\d\d|[23]04)$/ ) {
1388         $c->response->headers->remove_header("Content-Length");
1389         $c->response->body('');
1390     }
1391
1392     $c->finalize_cookies;
1393
1394     $c->engine->finalize_headers( $c, @_ );
1395
1396     # Done
1397     $c->response->{_finalized_headers} = 1;
1398 }
1399
1400 =head2 $c->finalize_output
1401
1402 An alias for finalize_body.
1403
1404 =head2 $c->finalize_read
1405
1406 Finalizes the input after reading is complete.
1407
1408 =cut
1409
1410 sub finalize_read { my $c = shift; $c->engine->finalize_read( $c, @_ ) }
1411
1412 =head2 $c->finalize_uploads
1413
1414 Finalizes uploads. Cleans up any temporary files.
1415
1416 =cut
1417
1418 sub finalize_uploads { my $c = shift; $c->engine->finalize_uploads( $c, @_ ) }
1419
1420 =head2 $c->get_action( $action, $namespace )
1421
1422 Gets an action in a given namespace.
1423
1424 =cut
1425
1426 sub get_action { my $c = shift; $c->dispatcher->get_action(@_) }
1427
1428 =head2 $c->get_actions( $action, $namespace )
1429
1430 Gets all actions of a given name in a namespace and all parent
1431 namespaces.
1432
1433 =cut
1434
1435 sub get_actions { my $c = shift; $c->dispatcher->get_actions( $c, @_ ) }
1436
1437 =head2 $c->handle_request( $class, @arguments )
1438
1439 Called to handle each HTTP request.
1440
1441 =cut
1442
1443 sub handle_request {
1444     my ( $class, @arguments ) = @_;
1445
1446     # Always expect worst case!
1447     my $status = -1;
1448     eval {
1449         my $stats = ( $class->debug ) ? Tree::Simple->new: q{};
1450
1451         my $handler = sub {
1452             my $c = $class->prepare(@arguments);
1453             $c->stats($stats);
1454             $c->dispatch;
1455             return $c->finalize;
1456         };
1457
1458         if ( $class->debug ) {
1459             my $start = [gettimeofday];
1460             $status = &$handler;
1461             my $elapsed = tv_interval $start;
1462             $elapsed = sprintf '%f', $elapsed;
1463             my $av = sprintf '%.3f',
1464               ( $elapsed == 0 ? '??' : ( 1 / $elapsed ) );
1465             my $t = Text::SimpleTable->new( [ 62, 'Action' ], [ 9, 'Time' ] );
1466
1467             $stats->traverse(
1468                 sub {
1469                     my $action = shift;
1470                     my $stat   = $action->getNodeValue;
1471                     $t->row( ( q{ } x $action->getDepth ) . $stat->{action} . $stat->{comment},
1472                         $stat->{elapsed} || '??' );
1473                 }
1474             );
1475
1476             $class->log->info(
1477                 "Request took ${elapsed}s ($av/s)\n" . $t->draw );
1478         }
1479         else { $status = &$handler }
1480
1481     };
1482
1483     if ( my $error = $@ ) {
1484         chomp $error;
1485         $class->log->error(qq/Caught exception in engine "$error"/);
1486     }
1487
1488     $COUNT++;
1489     $class->log->_flush() if $class->log->can('_flush');
1490     return $status;
1491 }
1492
1493 =head2 $c->prepare( @arguments )
1494
1495 Creates a Catalyst context from an engine-specific request (Apache, CGI,
1496 etc.).
1497
1498 =cut
1499
1500 sub prepare {
1501     my ( $class, @arguments ) = @_;
1502
1503     $class->context_class( ref $class || $class ) unless $class->context_class;
1504     my $c = $class->context_class->new(
1505         {
1506             counter => {},
1507             stack   => [],
1508             request => $class->request_class->new(
1509                 {
1510                     arguments        => [],
1511                     body_parameters  => {},
1512                     cookies          => {},
1513                     headers          => HTTP::Headers->new,
1514                     parameters       => {},
1515                     query_parameters => {},
1516                     secure           => 0,
1517                     captures         => [],
1518                     uploads          => {}
1519                 }
1520             ),
1521             response => $class->response_class->new(
1522                 {
1523                     body    => '',
1524                     cookies => {},
1525                     headers => HTTP::Headers->new(),
1526                     status  => 200
1527                 }
1528             ),
1529             stash => {},
1530             state => 0
1531         }
1532     );
1533
1534     # For on-demand data
1535     $c->request->{_context}  = $c;
1536     $c->response->{_context} = $c;
1537     weaken( $c->request->{_context} );
1538     weaken( $c->response->{_context} );
1539
1540     if ( $c->debug ) {
1541         my $secs = time - $START || 1;
1542         my $av = sprintf '%.3f', $COUNT / $secs;
1543         my $time = localtime time;
1544         $c->log->info("*** Request $COUNT ($av/s) [$$] [$time] ***");
1545         $c->res->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
1546     }
1547
1548     # Allow engine to direct the prepare flow (for POE)
1549     if ( $c->engine->can('prepare') ) {
1550         $c->engine->prepare( $c, @arguments );
1551     }
1552     else {
1553         $c->prepare_request(@arguments);
1554         $c->prepare_connection;
1555         $c->prepare_query_parameters;
1556         $c->prepare_headers;
1557         $c->prepare_cookies;
1558         $c->prepare_path;
1559
1560         # On-demand parsing
1561         $c->prepare_body unless $c->config->{parse_on_demand};
1562     }
1563
1564     my $method  = $c->req->method  || '';
1565     my $path    = $c->req->path    || '/';
1566     my $address = $c->req->address || '';
1567
1568     $c->log->debug(qq/"$method" request for "$path" from "$address"/)
1569       if $c->debug;
1570
1571     $c->prepare_action;
1572
1573     return $c;
1574 }
1575
1576 =head2 $c->prepare_action
1577
1578 Prepares action. See L<Catalyst::Dispatcher>.
1579
1580 =cut
1581
1582 sub prepare_action { my $c = shift; $c->dispatcher->prepare_action( $c, @_ ) }
1583
1584 =head2 $c->prepare_body
1585
1586 Prepares message body.
1587
1588 =cut
1589
1590 sub prepare_body {
1591     my $c = shift;
1592
1593     # Do we run for the first time?
1594     return if defined $c->request->{_body};
1595
1596     # Initialize on-demand data
1597     $c->engine->prepare_body( $c, @_ );
1598     $c->prepare_parameters;
1599     $c->prepare_uploads;
1600
1601     if ( $c->debug && keys %{ $c->req->body_parameters } ) {
1602         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1603         for my $key ( sort keys %{ $c->req->body_parameters } ) {
1604             my $param = $c->req->body_parameters->{$key};
1605             my $value = defined($param) ? $param : '';
1606             $t->row( $key,
1607                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1608         }
1609         $c->log->debug( "Body Parameters are:\n" . $t->draw );
1610     }
1611 }
1612
1613 =head2 $c->prepare_body_chunk( $chunk )
1614
1615 Prepares a chunk of data before sending it to L<HTTP::Body>.
1616
1617 See L<Catalyst::Engine>.
1618
1619 =cut
1620
1621 sub prepare_body_chunk {
1622     my $c = shift;
1623     $c->engine->prepare_body_chunk( $c, @_ );
1624 }
1625
1626 =head2 $c->prepare_body_parameters
1627
1628 Prepares body parameters.
1629
1630 =cut
1631
1632 sub prepare_body_parameters {
1633     my $c = shift;
1634     $c->engine->prepare_body_parameters( $c, @_ );
1635 }
1636
1637 =head2 $c->prepare_connection
1638
1639 Prepares connection.
1640
1641 =cut
1642
1643 sub prepare_connection {
1644     my $c = shift;
1645     $c->engine->prepare_connection( $c, @_ );
1646 }
1647
1648 =head2 $c->prepare_cookies
1649
1650 Prepares cookies.
1651
1652 =cut
1653
1654 sub prepare_cookies { my $c = shift; $c->engine->prepare_cookies( $c, @_ ) }
1655
1656 =head2 $c->prepare_headers
1657
1658 Prepares headers.
1659
1660 =cut
1661
1662 sub prepare_headers { my $c = shift; $c->engine->prepare_headers( $c, @_ ) }
1663
1664 =head2 $c->prepare_parameters
1665
1666 Prepares parameters.
1667
1668 =cut
1669
1670 sub prepare_parameters {
1671     my $c = shift;
1672     $c->prepare_body_parameters;
1673     $c->engine->prepare_parameters( $c, @_ );
1674 }
1675
1676 =head2 $c->prepare_path
1677
1678 Prepares path and base.
1679
1680 =cut
1681
1682 sub prepare_path { my $c = shift; $c->engine->prepare_path( $c, @_ ) }
1683
1684 =head2 $c->prepare_query_parameters
1685
1686 Prepares query parameters.
1687
1688 =cut
1689
1690 sub prepare_query_parameters {
1691     my $c = shift;
1692
1693     $c->engine->prepare_query_parameters( $c, @_ );
1694
1695     if ( $c->debug && keys %{ $c->request->query_parameters } ) {
1696         my $t = Text::SimpleTable->new( [ 35, 'Parameter' ], [ 36, 'Value' ] );
1697         for my $key ( sort keys %{ $c->req->query_parameters } ) {
1698             my $param = $c->req->query_parameters->{$key};
1699             my $value = defined($param) ? $param : '';
1700             $t->row( $key,
1701                 ref $value eq 'ARRAY' ? ( join ', ', @$value ) : $value );
1702         }
1703         $c->log->debug( "Query Parameters are:\n" . $t->draw );
1704     }
1705 }
1706
1707 =head2 $c->prepare_read
1708
1709 Prepares the input for reading.
1710
1711 =cut
1712
1713 sub prepare_read { my $c = shift; $c->engine->prepare_read( $c, @_ ) }
1714
1715 =head2 $c->prepare_request
1716
1717 Prepares the engine request.
1718
1719 =cut
1720
1721 sub prepare_request { my $c = shift; $c->engine->prepare_request( $c, @_ ) }
1722
1723 =head2 $c->prepare_uploads
1724
1725 Prepares uploads.
1726
1727 =cut
1728
1729 sub prepare_uploads {
1730     my $c = shift;
1731
1732     $c->engine->prepare_uploads( $c, @_ );
1733
1734     if ( $c->debug && keys %{ $c->request->uploads } ) {
1735         my $t = Text::SimpleTable->new(
1736             [ 12, 'Parameter' ],
1737             [ 26, 'Filename' ],
1738             [ 18, 'Type' ],
1739             [ 9,  'Size' ]
1740         );
1741         for my $key ( sort keys %{ $c->request->uploads } ) {
1742             my $upload = $c->request->uploads->{$key};
1743             for my $u ( ref $upload eq 'ARRAY' ? @{$upload} : ($upload) ) {
1744                 $t->row( $key, $u->filename, $u->type, $u->size );
1745             }
1746         }
1747         $c->log->debug( "File Uploads are:\n" . $t->draw );
1748     }
1749 }
1750
1751 =head2 $c->prepare_write
1752
1753 Prepares the output for writing.
1754
1755 =cut
1756
1757 sub prepare_write { my $c = shift; $c->engine->prepare_write( $c, @_ ) }
1758
1759 =head2 $c->request_class
1760
1761 Returns or sets the request class.
1762
1763 =head2 $c->response_class
1764
1765 Returns or sets the response class.
1766
1767 =head2 $c->read( [$maxlength] )
1768
1769 Reads a chunk of data from the request body. This method is designed to
1770 be used in a while loop, reading C<$maxlength> bytes on every call.
1771 C<$maxlength> defaults to the size of the request if not specified.
1772
1773 You have to set C<MyApp-E<gt>config-E<gt>{parse_on_demand}> to use this
1774 directly.
1775
1776 =cut
1777
1778 sub read { my $c = shift; return $c->engine->read( $c, @_ ) }
1779
1780 =head2 $c->run
1781
1782 Starts the engine.
1783
1784 =cut
1785
1786 sub run { my $c = shift; return $c->engine->run( $c, @_ ) }
1787
1788 =head2 $c->set_action( $action, $code, $namespace, $attrs )
1789
1790 Sets an action in a given namespace.
1791
1792 =cut
1793
1794 sub set_action { my $c = shift; $c->dispatcher->set_action( $c, @_ ) }
1795
1796 =head2 $c->setup_actions($component)
1797
1798 Sets up actions for a component.
1799
1800 =cut
1801
1802 sub setup_actions { my $c = shift; $c->dispatcher->setup_actions( $c, @_ ) }
1803
1804 =head2 $c->setup_components
1805
1806 Sets up components. Specify a C<setup_components> config option to pass additional options
1807 directly to L<Module::Pluggable>. To add additional search paths, specify a key named
1808 C<search_extra> as an array reference. Items in the array beginning with C<::> will have the
1809 application class name prepended to them.
1810
1811 =cut
1812
1813 sub setup_components {
1814     my $class = shift;
1815
1816     my @paths   = qw( ::Controller ::C ::Model ::M ::View ::V );
1817     my $config  = $class->config->{ setup_components };
1818     my $extra   = delete $config->{ search_extra } || [];
1819
1820     push @paths, @$extra;
1821
1822     my $locator = Module::Pluggable::Object->new(
1823         search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
1824         %$config
1825     );
1826
1827     for my $component ( sort { length $a <=> length $b } $locator->plugins ) {
1828         Catalyst::Utils::ensure_class_loaded( $component );
1829
1830         my $module  = $class->setup_component( $component );
1831         my %modules = (
1832             $component => $module,
1833             map {
1834                 $_ => $class->setup_component( $_ )
1835             } Devel::InnerPackage::list_packages( $component )
1836         );
1837
1838         for my $key ( keys %modules ) {
1839             $class->components->{ $key } = $modules{ $key };
1840         }
1841     }
1842 }
1843
1844 =head2 $c->setup_component
1845
1846 =cut
1847
1848 sub setup_component {
1849     my( $class, $component ) = @_;
1850
1851     unless ( $component->can( 'COMPONENT' ) ) {
1852         return $component;
1853     }
1854
1855     my $suffix = Catalyst::Utils::class2classsuffix( $component );
1856     my $config = $class->config->{ $suffix } || {};
1857
1858     my $instance = eval { $component->COMPONENT( $class, $config ); };
1859
1860     if ( my $error = $@ ) {
1861         chomp $error;
1862         Catalyst::Exception->throw(
1863             message => qq/Couldn't instantiate component "$component", "$error"/
1864         );
1865     }
1866
1867     Catalyst::Exception->throw(
1868         message =>
1869         qq/Couldn't instantiate component "$component", "COMPONENT() didn't return an object-like value"/
1870     ) unless eval { $instance->can( 'can' ) };
1871
1872     return $instance;
1873 }
1874
1875 =head2 $c->setup_dispatcher
1876
1877 Sets up dispatcher.
1878
1879 =cut
1880
1881 sub setup_dispatcher {
1882     my ( $class, $dispatcher ) = @_;
1883
1884     if ($dispatcher) {
1885         $dispatcher = 'Catalyst::Dispatcher::' . $dispatcher;
1886     }
1887
1888     if ( $ENV{CATALYST_DISPATCHER} ) {
1889         $dispatcher = 'Catalyst::Dispatcher::' . $ENV{CATALYST_DISPATCHER};
1890     }
1891
1892     if ( $ENV{ uc($class) . '_DISPATCHER' } ) {
1893         $dispatcher =
1894           'Catalyst::Dispatcher::' . $ENV{ uc($class) . '_DISPATCHER' };
1895     }
1896
1897     unless ($dispatcher) {
1898         $dispatcher = $class->dispatcher_class;
1899     }
1900
1901     unless (Class::Inspector->loaded($dispatcher)) {
1902         require Class::Inspector->filename($dispatcher);
1903     }
1904
1905     # dispatcher instance
1906     $class->dispatcher( $dispatcher->new );
1907 }
1908
1909 =head2 $c->setup_engine
1910
1911 Sets up engine.
1912
1913 =cut
1914
1915 sub setup_engine {
1916     my ( $class, $engine ) = @_;
1917
1918     if ($engine) {
1919         $engine = 'Catalyst::Engine::' . $engine;
1920     }
1921
1922     if ( $ENV{CATALYST_ENGINE} ) {
1923         $engine = 'Catalyst::Engine::' . $ENV{CATALYST_ENGINE};
1924     }
1925
1926     if ( $ENV{ uc($class) . '_ENGINE' } ) {
1927         $engine = 'Catalyst::Engine::' . $ENV{ uc($class) . '_ENGINE' };
1928     }
1929
1930     if ( $ENV{MOD_PERL} ) {
1931
1932         # create the apache method
1933         {
1934             no strict 'refs';
1935             *{"$class\::apache"} = sub { shift->engine->apache };
1936         }
1937
1938         my ( $software, $version ) =
1939           $ENV{MOD_PERL} =~ /^(\S+)\/(\d+(?:[\.\_]\d+)+)/;
1940
1941         $version =~ s/_//g;
1942         $version =~ s/(\.[^.]+)\./$1/g;
1943
1944         if ( $software eq 'mod_perl' ) {
1945
1946             if ( !$engine ) {
1947
1948                 if ( $version >= 1.99922 ) {
1949                     $engine = 'Catalyst::Engine::Apache2::MP20';
1950                 }
1951
1952                 elsif ( $version >= 1.9901 ) {
1953                     $engine = 'Catalyst::Engine::Apache2::MP19';
1954                 }
1955
1956                 elsif ( $version >= 1.24 ) {
1957                     $engine = 'Catalyst::Engine::Apache::MP13';
1958                 }
1959
1960                 else {
1961                     Catalyst::Exception->throw( message =>
1962                           qq/Unsupported mod_perl version: $ENV{MOD_PERL}/ );
1963                 }
1964
1965             }
1966
1967             # install the correct mod_perl handler
1968             if ( $version >= 1.9901 ) {
1969                 *handler = sub  : method {
1970                     shift->handle_request(@_);
1971                 };
1972             }
1973             else {
1974                 *handler = sub ($$) { shift->handle_request(@_) };
1975             }
1976
1977         }
1978
1979         elsif ( $software eq 'Zeus-Perl' ) {
1980             $engine = 'Catalyst::Engine::Zeus';
1981         }
1982
1983         else {
1984             Catalyst::Exception->throw(
1985                 message => qq/Unsupported mod_perl: $ENV{MOD_PERL}/ );
1986         }
1987     }
1988
1989     unless ($engine) {
1990         $engine = $class->engine_class;
1991     }
1992
1993     unless (Class::Inspector->loaded($engine)) {
1994         require Class::Inspector->filename($engine);
1995     }
1996
1997     # check for old engines that are no longer compatible
1998     my $old_engine;
1999     if ( $engine->isa('Catalyst::Engine::Apache')
2000         && !Catalyst::Engine::Apache->VERSION )
2001     {
2002         $old_engine = 1;
2003     }
2004
2005     elsif ( $engine->isa('Catalyst::Engine::Server::Base')
2006         && Catalyst::Engine::Server->VERSION le '0.02' )
2007     {
2008         $old_engine = 1;
2009     }
2010
2011     elsif ($engine->isa('Catalyst::Engine::HTTP::POE')
2012         && $engine->VERSION eq '0.01' )
2013     {
2014         $old_engine = 1;
2015     }
2016
2017     elsif ($engine->isa('Catalyst::Engine::Zeus')
2018         && $engine->VERSION eq '0.01' )
2019     {
2020         $old_engine = 1;
2021     }
2022
2023     if ($old_engine) {
2024         Catalyst::Exception->throw( message =>
2025               qq/Engine "$engine" is not supported by this version of Catalyst/
2026         );
2027     }
2028
2029     # engine instance
2030     $class->engine( $engine->new );
2031 }
2032
2033 =head2 $c->setup_home
2034
2035 Sets up the home directory.
2036
2037 =cut
2038
2039 sub setup_home {
2040     my ( $class, $home ) = @_;
2041
2042     if ( $ENV{CATALYST_HOME} ) {
2043         $home = $ENV{CATALYST_HOME};
2044     }
2045
2046     if ( $ENV{ uc($class) . '_HOME' } ) {
2047         $home = $ENV{ uc($class) . '_HOME' };
2048     }
2049
2050     unless ($home) {
2051         $home = Catalyst::Utils::home($class);
2052     }
2053
2054     if ($home) {
2055         $class->config->{home} ||= $home;
2056         $class->config->{root} ||= Path::Class::Dir->new($home)->subdir('root');
2057     }
2058 }
2059
2060 =head2 $c->setup_log
2061
2062 Sets up log.
2063
2064 =cut
2065
2066 sub setup_log {
2067     my ( $class, $debug ) = @_;
2068
2069     unless ( $class->log ) {
2070         $class->log( Catalyst::Log->new );
2071     }
2072
2073     my $app_flag = Catalyst::Utils::class2env($class) . '_DEBUG';
2074
2075     if (
2076           ( defined( $ENV{CATALYST_DEBUG} ) || defined( $ENV{$app_flag} ) )
2077         ? ( $ENV{CATALYST_DEBUG} || $ENV{$app_flag} )
2078         : $debug
2079       )
2080     {
2081         no strict 'refs';
2082         *{"$class\::debug"} = sub { 1 };
2083         $class->log->debug('Debug messages enabled');
2084     }
2085 }
2086
2087 =head2 $c->setup_plugins
2088
2089 Sets up plugins.
2090
2091 =cut
2092
2093 =head2 $c->registered_plugins
2094
2095 Returns a sorted list of the plugins which have either been stated in the
2096 import list or which have been added via C<< MyApp->plugin(@args); >>.
2097
2098 If passed a given plugin name, it will report a boolean value indicating
2099 whether or not that plugin is loaded.  A fully qualified name is required if
2100 the plugin name does not begin with C<Catalyst::Plugin::>.
2101
2102  if ($c->registered_plugins('Some::Plugin')) {
2103      ...
2104  }
2105
2106 =cut
2107
2108 {
2109
2110     sub registered_plugins {
2111         my $proto = shift;
2112         return sort keys %{ $proto->_plugins } unless @_;
2113         my $plugin = shift;
2114         return 1 if exists $proto->_plugins->{$plugin};
2115         return exists $proto->_plugins->{"Catalyst::Plugin::$plugin"};
2116     }
2117
2118     sub _register_plugin {
2119         my ( $proto, $plugin, $instant ) = @_;
2120         my $class = ref $proto || $proto;
2121
2122         unless (Class::Inspector->loaded($plugin)) {
2123             require Class::Inspector->filename($plugin);
2124         }
2125
2126         $proto->_plugins->{$plugin} = 1;
2127         unless ($instant) {
2128             no strict 'refs';
2129             unshift @{"$class\::ISA"}, $plugin;
2130         }
2131         return $class;
2132     }
2133
2134     sub setup_plugins {
2135         my ( $class, $plugins ) = @_;
2136
2137         $class->_plugins( {} ) unless $class->_plugins;
2138         $plugins ||= [];
2139         for my $plugin ( reverse @$plugins ) {
2140
2141             unless ( $plugin =~ s/\A\+// ) {
2142                 $plugin = "Catalyst::Plugin::$plugin";
2143             }
2144
2145             $class->_register_plugin($plugin);
2146         }
2147     }
2148 }
2149
2150 =head2 $c->stack
2151
2152 Returns an arrayref of the internal execution stack (actions that are currently
2153 executing).
2154
2155 =head2 $c->write( $data )
2156
2157 Writes $data to the output stream. When using this method directly, you
2158 will need to manually set the C<Content-Length> header to the length of
2159 your output data, if known.
2160
2161 =cut
2162
2163 sub write {
2164     my $c = shift;
2165
2166     # Finalize headers if someone manually writes output
2167     $c->finalize_headers;
2168
2169     return $c->engine->write( $c, @_ );
2170 }
2171
2172 =head2 version
2173
2174 Returns the Catalyst version number. Mostly useful for "powered by"
2175 messages in template systems.
2176
2177 =cut
2178
2179 sub version { return $Catalyst::VERSION }
2180
2181 =head1 INTERNAL ACTIONS
2182
2183 Catalyst uses internal actions like C<_DISPATCH>, C<_BEGIN>, C<_AUTO>,
2184 C<_ACTION>, and C<_END>. These are by default not shown in the private
2185 action table, but you can make them visible with a config parameter.
2186
2187     MyApp->config->{show_internal_actions} = 1;
2188
2189 =head1 CASE SENSITIVITY
2190
2191 By default Catalyst is not case sensitive, so C<MyApp::C::FOO::Bar> is
2192 mapped to C</foo/bar>. You can activate case sensitivity with a config
2193 parameter.
2194
2195     MyApp->config->{case_sensitive} = 1;
2196
2197 This causes C<MyApp::C::Foo::Bar> to map to C</Foo/Bar>.
2198
2199 =head1 ON-DEMAND PARSER
2200
2201 The request body is usually parsed at the beginning of a request,
2202 but if you want to handle input yourself or speed things up a bit,
2203 you can enable on-demand parsing with a config parameter.
2204
2205     MyApp->config->{parse_on_demand} = 1;
2206
2207 =head1 PROXY SUPPORT
2208
2209 Many production servers operate using the common double-server approach,
2210 with a lightweight frontend web server passing requests to a larger
2211 backend server. An application running on the backend server must deal
2212 with two problems: the remote user always appears to be C<127.0.0.1> and
2213 the server's hostname will appear to be C<localhost> regardless of the
2214 virtual host that the user connected through.
2215
2216 Catalyst will automatically detect this situation when you are running
2217 the frontend and backend servers on the same machine. The following
2218 changes are made to the request.
2219
2220     $c->req->address is set to the user's real IP address, as read from
2221     the HTTP X-Forwarded-For header.
2222
2223     The host value for $c->req->base and $c->req->uri is set to the real
2224     host, as read from the HTTP X-Forwarded-Host header.
2225
2226 Obviously, your web server must support these headers for this to work.
2227
2228 In a more complex server farm environment where you may have your
2229 frontend proxy server(s) on different machines, you will need to set a
2230 configuration option to tell Catalyst to read the proxied data from the
2231 headers.
2232
2233     MyApp->config->{using_frontend_proxy} = 1;
2234
2235 If you do not wish to use the proxy support at all, you may set:
2236
2237     MyApp->config->{ignore_frontend_proxy} = 1;
2238
2239 =head1 THREAD SAFETY
2240
2241 Catalyst has been tested under Apache 2's threading mpm_worker, mpm_winnt,
2242 and the standalone forking HTTP server on Windows. We believe the Catalyst
2243 core to be thread-safe.
2244
2245 If you plan to operate in a threaded environment, remember that all other
2246 modules you are using must also be thread-safe. Some modules, most notably
2247 L<DBD::SQLite>, are not thread-safe.
2248
2249 =head1 SUPPORT
2250
2251 IRC:
2252
2253     Join #catalyst on irc.perl.org.
2254
2255 Mailing Lists:
2256
2257     http://lists.rawmode.org/mailman/listinfo/catalyst
2258     http://lists.rawmode.org/mailman/listinfo/catalyst-dev
2259
2260 Web:
2261
2262     http://catalyst.perl.org
2263
2264 Wiki:
2265
2266     http://dev.catalyst.perl.org
2267
2268 =head1 SEE ALSO
2269
2270 =head2 L<Task::Catalyst> - All you need to start with Catalyst
2271
2272 =head2 L<Catalyst::Manual> - The Catalyst Manual
2273
2274 =head2 L<Catalyst::Component>, L<Catalyst::Base> - Base classes for components
2275
2276 =head2 L<Catalyst::Engine> - Core engine
2277
2278 =head2 L<Catalyst::Log> - Log class.
2279
2280 =head2 L<Catalyst::Request> - Request object
2281
2282 =head2 L<Catalyst::Response> - Response object
2283
2284 =head2 L<Catalyst::Test> - The test suite.
2285
2286 =head1 CREDITS
2287
2288 Andy Grundman
2289
2290 Andy Wardley
2291
2292 Andreas Marienborg
2293
2294 Andrew Bramble
2295
2296 Andrew Ford
2297
2298 Andrew Ruthven
2299
2300 Arthur Bergman
2301
2302 Autrijus Tang
2303
2304 Brian Cassidy
2305
2306 Carl Franks
2307
2308 Christian Hansen
2309
2310 Christopher Hicks
2311
2312 Dan Sully
2313
2314 Danijel Milicevic
2315
2316 David Kamholz
2317
2318 David Naughton
2319
2320 Drew Taylor
2321
2322 Gary Ashton Jones
2323
2324 Geoff Richards
2325
2326 Jesse Sheidlower
2327
2328 Jesse Vincent
2329
2330 Jody Belka
2331
2332 Johan Lindstrom
2333
2334 Juan Camacho
2335
2336 Leon Brocard
2337
2338 Marcus Ramberg
2339
2340 Matt S Trout
2341
2342 Robert Sedlacek
2343
2344 Sam Vilain
2345
2346 Sascha Kiefer
2347
2348 Tatsuhiko Miyagawa
2349
2350 Ulf Edvinsson
2351
2352 Yuval Kogman
2353
2354 =head1 AUTHOR
2355
2356 Sebastian Riedel, C<sri@oook.de>
2357
2358 =head1 LICENSE
2359
2360 This library is free software, you can redistribute it and/or modify it under
2361 the same terms as Perl itself.
2362
2363 =cut
2364
2365 1;